Time::Local in blead has diverged from CPAN. Update the version number to a dev release
[perl.git] / utils / perlbug.PL
1 #!/usr/local/bin/perl
2
3 use Config;
4 use File::Basename qw(&basename &dirname);
5 use Cwd;
6 use File::Spec::Functions;
7
8 # List explicitly here the variables you want Configure to
9 # generate.  Metaconfig only looks for shell variables, so you
10 # have to mention them as if they were shell variables, not
11 # %Config entries.  Thus you write
12 #  $startperl
13 # to ensure Configure will look for $Config{startperl}.
14 #  $perlpath
15
16 # This forces PL files to create target in same directory as PL file.
17 # This is so that make depend always knows where to find PL derivatives.
18 $origdir = cwd;
19 chdir dirname($0);
20 $file = basename($0, '.PL');
21 $file .= '.com' if $^O eq 'VMS';
22
23 open OUT, ">$file" or die "Can't create $file: $!";
24
25 # extract patchlevel.h information
26
27 open PATCH_LEVEL, "<" . catfile(updir, "patchlevel.h")
28     or die "Can't open patchlevel.h: $!";
29
30 my $patchlevel_date = (stat PATCH_LEVEL)[9];
31
32 while (<PATCH_LEVEL>) {
33     last if $_ =~ /^\s*static\s+(?:const\s+)?char.*?local_patches\[\]\s*=\s*{\s*$/;
34 }
35
36 if (! defined($_)) {
37     warn "Warning: local_patches section not found in patchlevel.h\n";
38 }
39
40 my @patches;
41 while (<PATCH_LEVEL>) {
42     last if /^\s*}/;
43     next if /^\s*#/;  # preprocessor stuff
44     next if /PERL_GIT_UNPUSHED_COMMITS/;    # XXX expand instead
45     next if /PERL_GIT_UNCOMMITTED_CHANGES/; # XXX expand instead
46     chomp;
47     s/^\s+,?\s*"?//;
48     s/"?\s*,?$//;
49     s/(['\\])/\\$1/g;
50     push @patches, $_ unless $_ eq 'NULL';
51 }
52 my $patch_desc = "'" . join("',\n    '", @patches) . "'";
53 my $patch_tags = join "", map /(\S+)/ ? "+$1 " : (), @patches;
54
55 close(PATCH_LEVEL) or die "Error closing patchlevel.h: $!";
56
57 # TO DO (prehaps): store/embed $Config::config_sh into perlbug. When perlbug is
58 # used, compare $Config::config_sh with the stored version. If they differ then
59 # append a list of individual differences to the bug report.
60
61
62 print "Extracting $file (with variable substitutions)\n";
63
64 # In this section, perl variables will be expanded during extraction.
65 # You can use $Config{...} to use Configure variables.
66
67 my $extract_version = sprintf("%vd", $^V);
68
69 print OUT <<"!GROK!THIS!";
70 $Config{startperl}
71     eval 'exec $Config{perlpath} -S \$0 \${1+"\$@"}'
72         if \$running_under_some_shell;
73
74 my \$config_tag1 = '$extract_version - $Config{cf_time}';
75
76 my \$patchlevel_date = $patchlevel_date;
77 my \$patch_tags = '$patch_tags';
78 my \@patches = (
79     $patch_desc
80 );
81 !GROK!THIS!
82
83 # In the following, perl variables are not expanded during extraction.
84
85 print OUT <<'!NO!SUBS!';
86
87 use warnings;
88 no warnings 'once'; # Eventually, the $::opt_ stuff should get cleaned up
89 use strict;
90 use Config;
91 use File::Spec;         # keep perlbug Perl 5.005 compatible
92 use Getopt::Std;
93 use File::Basename 'basename';
94
95 sub paraprint;
96
97 BEGIN {
98     eval { require Mail::Send;};
99     $::HaveSend = ($@ eq "");
100     eval { require Mail::Util; } ;
101     $::HaveUtil = ($@ eq "");
102     # use secure tempfiles wherever possible
103     eval { require File::Temp; };
104     $::HaveTemp = ($@ eq "");
105     eval { require Module::CoreList; };
106     $::HaveCoreList = ($@ eq "");
107 };
108
109 my $Version = "1.39";
110
111 # Changed in 1.06 to skip Mail::Send and Mail::Util if not available.
112 # Changed in 1.07 to see more sendmail execs, and added pipe output.
113 # Changed in 1.08 to use correct address for sendmail.
114 # Changed in 1.09 to close the REP file before calling it up in the editor.
115 #                 Also removed some old comments duplicated elsewhere.
116 # Changed in 1.10 to run under VMS without Mail::Send; also fixed
117 #                 temp filename generation.
118 # Changed in 1.11 to clean up some text and removed Mail::Send deactivator.
119 # Changed in 1.12 to check for editor errors, make save/send distinction
120 #                 clearer and add $ENV{REPLYTO}.
121 # Changed in 1.13 to hopefully make it more difficult to accidentally
122 #                 send mail
123 # Changed in 1.14 to make the prompts a little more clear on providing
124 #                 helpful information. Also let file read fail gracefully.
125 # Changed in 1.15 to add warnings to stop people using perlbug for non-bugs.
126 #                 Also report selected environment variables.
127 # Changed in 1.16 to include @INC, and allow user to re-edit if no changes.
128 # Changed in 1.17 Win32 support added.  GSAR 97-04-12
129 # Changed in 1.18 add '-ok' option for reporting build success. CFR 97-06-18
130 # Changed in 1.19 '-ok' default not '-v'
131 #                 add local patch information
132 #                 warn on '-ok' if this is an old system; add '-okay'
133 # Changed in 1.20 Added patchlevel.h reading and version/config checks
134 # Changed in 1.21 Added '-nok' for reporting build failure DFD 98-05-05
135 # Changed in 1.22 Heavy reformatting & minor bugfixes HVDS 98-05-10
136 # Changed in 1.23 Restore -ok(ay): say 'success'; don't prompt
137 # Changed in 1.24 Added '-F<file>' to save report HVDS 98-07-01
138 # Changed in 1.25 Warn on failure to open save file. HVDS 98-07-12
139 # Changed in 1.26 Don't require -t STDIN for -ok. HVDS 98-07-15
140 # Changed in 1.27 Added Mac OS and File::Spec support CNANDOR 99-07-27
141 # Changed in 1.28 Additional questions for Perlbugtron RFOLEY 20.03.2000
142 # Changed in 1.29 Perlbug(tron): auto(-ok), short prompts RFOLEY 05-05-2000
143 # Changed in 1.30 Added warnings on failure to open files MSTEVENS 13-07-2000
144 # Changed in 1.31 Add checks on close().Fix my $var unless. TJENNESS 26-07-2000
145 # Changed in 1.32 Use File::Spec->tmpdir TJENNESS 20-08-2000
146 # Changed in 1.33 Don't require -t STDOUT for -ok.
147 # Changed in 1.34 Added Message-Id RFOLEY 18-06-2002 
148 # Changed in 1.35 Use File::Temp (patch from Solar Designer) NWCLARK 28-02-2004
149 # Changed in 1.36 Initial Module::CoreList support Alexandr Ciornii 11-07-2007
150 # Changed in 1.37 Killed some string evals, rewrote most prose JESSE 2008-06-08
151 # Changed in 1.38 Actually enforce the CoreList check,
152 #                 Record the module the user enters if they do so
153 #                 Refactor prompts to use common code           JESSE 2008-06-08
154 # Changed in 1.39 Trap mail sending failures (simple ones) so   JESSE 2008-06-08
155 #                 users might be able to recover their bug reports
156 #                 Refactor mail sending routines
157 #                 Unify message building code
158 #                 Unify message header building
159 #                 Fix "module" prompting to not squish "category" prompting 
160 #                 use warnings; (except 'once' warnings)
161 #                 Unified report fingerprint/change detection code
162 #                 Removed some labeled 'gotos'
163 #TODO:
164 #       make sure failure (transmission-wise) of Mail::Send is accounted for.
165 #       (This may work now. Unsure of the original author's issue -JESSE 2008-06-08)
166 #       - Test -b option
167
168 my( $file, $usefile, $cc, $address, $bugaddress, $testaddress, $thanksaddress,
169     $filename, $messageid, $domain, $subject, $from, $verbose, $ed, $outfile,
170     $fh, $me, $body, $andcc, %REP, $ok, $thanks, $progname,
171     $Is_MacOS, $Is_MSWin32, $Is_Linux, $Is_VMS, $Is_OpenBSD,
172     $report_about_module, $category, $severity,
173
174 );
175
176 my $perl_version = $^V ? sprintf("%vd", $^V) : $];
177
178 my $config_tag2 = "$perl_version - $Config{cf_time}";
179
180 Init();
181
182 if ($::opt_h) { Help(); exit; }
183 if ($::opt_d) { Dump(*STDOUT); exit; }
184 if (!-t STDIN && !($ok and not $::opt_n)) {
185     paraprint <<"EOF";
186 Please use $progname interactively. If you want to
187 include a file, you can use the -f switch.
188 EOF
189     die "\n";
190 }
191
192 Query();
193 Edit() unless $usefile || ($ok and not $::opt_n);
194 NowWhat();
195 if ($outfile) {
196     save_message_to_disk($outfile);
197 } else {
198     Send();
199     if ($thanks) {
200         print "\nThank you for taking the time to send a thank-you message!\n\n";
201     } else {
202         print "\nThank you for taking the time to file a bug report!\n\n";
203     }
204 }
205
206 exit;
207
208 sub ask_for_alternatives { # (category|severity)
209     my $name = shift;
210     my %alts = (
211         'category' => {
212             'default' => 'core',
213             'ok'      => 'install',
214             # Inevitably some of these will end up in RT whatever we do:
215             'thanks'  => 'thanks',
216             'opts'    => [qw(core docs install library utilities)], # patch, notabug
217         },
218         'severity' => {
219             'default' => 'low',
220             'ok'      => 'none',
221             'thanks'  => 'none',
222             'opts'    => [qw(critical high medium low wishlist none)], # zero
223         },
224     );
225     die "Invalid alternative ($name) requested\n" unless grep(/^$name$/, keys %alts);
226     my $alt = "";
227     my $what = $ok || $thanks;
228     if ($what) {
229         $alt = $alts{$name}{$what};
230     } else {
231         my @alts = @{$alts{$name}{'opts'}};
232     print "\n\n";
233         paraprint <<EOF;
234 Please pick a $name from the following list:
235
236     @alts
237 EOF
238         my $err = 0;
239         do {
240             if ($err++ > 5) {
241                 die "Invalid $name: aborting.\n";
242             }
243         $alt = _prompt('', "\u$name", $alts{$name}{'default'});
244                 $alt ||= $alts{$name}{'default'};
245         } while !((($alt) = grep(/^$alt/i, @alts)));
246     }
247     lc $alt;
248 }
249
250 sub Init {
251     # -------- Setup --------
252
253     $Is_MSWin32 = $^O eq 'MSWin32';
254     $Is_VMS = $^O eq 'VMS';
255     $Is_Linux = lc($^O) eq 'linux';
256     $Is_OpenBSD = lc($^O) eq 'openbsd';
257     $Is_MacOS = $^O eq 'MacOS';
258
259     @ARGV = split m/\s+/,
260         MacPerl::Ask('Provide command line args here (-h for help):')
261         if $Is_MacOS && $MacPerl::Version =~ /App/;
262
263     if (!getopts("Adhva:s:b:f:F:r:e:SCc:to:n:T")) { Help(); exit; };
264
265     # This comment is needed to notify metaconfig that we are
266     # using the $perladmin, $cf_by, and $cf_time definitions.
267
268     # -------- Configuration ---------
269
270     # perlbug address
271     $bugaddress = 'perlbug@perl.org';
272
273     # Test address
274     $testaddress = 'perlbug-test@perl.org';
275
276     # Thanks address
277     $thanksaddress = 'perl-thanks@perl.org';
278
279     if (basename ($0) =~ /^perlthanks/i) {
280         # invoked as perlthanks
281         $::opt_T = 1;
282         $::opt_C = 1; # don't send a copy to the local admin
283     }
284
285     if ($::opt_T) {
286         $thanks = 'thanks';
287     }
288     
289     $progname = $thanks ? 'perlthanks' : 'perlbug';
290     # Target address
291     $address = $::opt_a || ($::opt_t ? $testaddress
292                             : $thanks ? $thanksaddress : $bugaddress);
293
294     # Users address, used in message and in Reply-To header
295     $from = $::opt_r || "";
296
297     # Include verbose configuration information
298     $verbose = $::opt_v || 0;
299
300     # Subject of bug-report message
301     $subject = $::opt_s || "";
302
303     # Send a file
304     $usefile = ($::opt_f || 0);
305
306     # File to send as report
307     $file = $::opt_f || "";
308
309     # File to output to
310     $outfile = $::opt_F || "";
311
312     # Body of report
313     $body = $::opt_b || "";
314         
315     # Editor
316     $ed = $::opt_e || $ENV{VISUAL} || $ENV{EDITOR} || $ENV{EDIT}
317         || ($Is_VMS && "edit/tpu")
318         || ($Is_MSWin32 && "notepad")
319         || ($Is_MacOS && '')
320         || "vi";
321
322     # Not OK - provide build failure template by finessing OK report
323     if ($::opt_n) {
324         if (substr($::opt_n, 0, 2) eq 'ok' )    {
325             $::opt_o = substr($::opt_n, 1);
326         } else {
327             Help();
328             exit();
329         }
330     }
331
332     # OK - send "OK" report for build on this system
333     $ok = '';
334     if ($::opt_o) {
335         if ($::opt_o eq 'k' or $::opt_o eq 'kay') {
336             my $age = time - $patchlevel_date;
337             if ($::opt_o eq 'k' and $age > 60 * 24 * 60 * 60 ) {
338                 my $date = localtime $patchlevel_date;
339                 print <<"EOF";
340 "perlbug -ok" and "perlbug -nok" do not report on Perl versions which
341 are more than 60 days old.  This Perl version was constructed on
342 $date.  If you really want to report this, use
343 "perlbug -okay" or "perlbug -nokay".
344 EOF
345                 exit();
346             }
347             # force these options
348             unless ($::opt_n) {
349                 $::opt_S = 1; # don't prompt for send
350                 $::opt_b = 1; # we have a body
351                 $body = "Perl reported to build OK on this system.\n";
352             }
353             $::opt_C = 1; # don't send a copy to the local admin
354             $::opt_s = 1; # we have a subject line
355             $subject = ($::opt_n ? 'Not ' : '')
356                     . "OK: perl $perl_version ${patch_tags}on"
357                     ." $::Config{'archname'} $::Config{'osvers'} $subject";
358             $ok = 'ok';
359         } else {
360             Help();
361             exit();
362         }
363     }
364
365     # Possible administrator addresses, in order of confidence
366     # (Note that cf_email is not mentioned to metaconfig, since
367     # we don't really want it. We'll just take it if we have to.)
368     #
369     # This has to be after the $ok stuff above because of the way
370     # that $::opt_C is forced.
371     $cc = $::opt_C ? "" : (
372         $::opt_c || $::Config{'perladmin'}
373         || $::Config{'cf_email'} || $::Config{'cf_by'}
374     );
375
376     if ($::HaveUtil) {
377                 $domain = Mail::Util::maildomain();
378     } elsif ($Is_MSWin32) {
379                 $domain = $ENV{'USERDOMAIN'};
380     } else {
381                 require Sys::Hostname;
382                 $domain = Sys::Hostname::hostname();
383     }
384
385     # Message-Id - rjsf
386     $messageid = "<$::Config{'version'}_${$}_".time."\@$domain>"; 
387
388     # My username
389     $me = $Is_MSWin32 ? $ENV{'USERNAME'}
390             : $^O eq 'os2' ? $ENV{'USER'} || $ENV{'LOGNAME'}
391             : $Is_MacOS ? $ENV{'USER'}
392             : eval { getpwuid($<) };    # May be missing
393
394     $from = $::Config{'cf_email'}
395        if !$from && $::Config{'cf_email'} && $::Config{'cf_by'} && $me &&
396                ($me eq $::Config{'cf_by'});
397 } # sub Init
398
399 sub Query {
400     # Explain what perlbug is
401     unless ($ok) {
402         if ($thanks) {
403             paraprint <<'EOF';
404 This program provides an easy way to send a thank-you message back to the
405 authors and maintainers of perl.
406
407 If you wish to submit a bug report, please run it without the -T flag
408 (or run the program perlbug rather than perlthanks)
409 EOF
410         } else {
411             paraprint <<"EOF";
412 This program provides an easy way to create a message reporting a
413 bug in the core perl distribution (along with tests or patches)
414 to the volunteers who maintain perl at $address.  To send a thank-you
415 note to $thanksaddress instead of a bug report, please run 'perlthanks'.
416
417 Please do not use $0 to send test messages, test whether perl
418 works, or to report bugs in perl modules from CPAN.
419
420 For help using perl, try posting to the Usenet newsgroup 
421 comp.lang.perl.misc.
422 EOF
423         }
424     }
425
426     # Prompt for subject of message, if needed
427     
428     if ($subject && TrivialSubject($subject)) {
429         $subject = '';
430     }
431
432     unless ($subject) {
433             print 
434 "First of all, please provide a subject for the message.\n";
435         if ( not $thanks)  {
436             paraprint <<EOF;
437 This should be a concise description of your bug or problem
438 which will help the volunteers working to improve perl to categorize
439 and resolve the issue.  Be as specific and descriptive as
440 you can. A subject like "perl bug" or "perl problem" will make it
441 much less likely that your issue gets the attention it deserves.
442 EOF
443         }
444
445         my $err = 0;
446         do {
447         $subject = _prompt('','Subject');
448             if ($err++ == 5) {
449                 if ($thanks) {
450                     $subject = 'Thanks for Perl';
451                 } else {
452                     die "Aborting.\n";
453                 }
454             }
455         } while (TrivialSubject($subject));
456     }
457
458     # Prompt for return address, if needed
459     unless ($from) {
460         # Try and guess return address
461         my $guess;
462
463         $guess = $ENV{'REPLY-TO'} || $ENV{'REPLYTO'} || '';
464         if ($Is_MacOS) {
465             require Mac::InternetConfig;
466             $guess = $Mac::InternetConfig::InternetConfig{
467                 Mac::InternetConfig::kICEmail()
468             };
469         }
470
471         unless ($guess) {
472                 # move $domain to where we can use it elsewhere 
473         if ($domain) {
474                 if ($Is_VMS && !$::Config{'d_socket'}) {
475                     $guess = "$domain\:\:$me";
476                 } else {
477                     $guess = "$me\@$domain" if $domain;
478                 }
479             }
480         }
481
482         if ($guess) {
483             unless ($ok) {
484                 paraprint <<EOF;
485 Perl's developers may need your email address to contact you for
486 further information about your issue or to inform you when it is
487 resolved.  If the default shown is not your email address, please
488 correct it.
489 EOF
490             }
491         } else {
492             paraprint <<EOF;
493 Please enter your full internet email address so that Perl's
494 developers can contact you with questions about your issue or to
495 inform you that it has been resolved.
496 EOF
497         }
498
499         if ($ok && $guess) {
500             # use it
501             $from = $guess;
502         } else {
503             # verify it
504         $from = _prompt('','Your address',$guess);
505             $from = $guess if $from eq '';
506         }
507     }
508
509     if ($from eq $cc or $me eq $cc) {
510         # Try not to copy ourselves
511         $cc = "yourself";
512     }
513
514     # Prompt for administrator address, unless an override was given
515     if( !$::opt_C and !$::opt_c ) {
516         my $description =  <<EOF;
517 $0 can send a copy of this report to your local perl
518 administrator.  If the address below is wrong, please correct it,
519 or enter 'none' or 'yourself' to not send a copy.
520 EOF
521         my $entry = _prompt($description, "Local perl administrator", $cc);
522
523         if ($entry ne "") {
524             $cc = $entry;
525             $cc = '' if $me eq $cc;
526         }
527     }
528
529     $cc = '' if $cc =~ /^(none|yourself|me|myself|ourselves)$/i;
530     if ($cc) { 
531         $andcc = " and $cc" 
532     } else {
533         $andcc = ''
534     }
535
536     # Prompt for editor, if no override is given
537 editor:
538     unless ($::opt_e || $::opt_f || $::opt_b) {
539
540     my $description;
541
542         chomp (my $common_end = <<"EOF");
543 You will probably want to use a text editor to enter the body of
544 your report. If "$ed" is the editor you want to use, then just press
545 Enter, otherwise type in the name of the editor you would like to
546 use.
547
548 If you have already composed the body of your report, you may enter
549 "file", and $0 will prompt you to enter the name of the file
550 containing your report.
551 EOF
552
553         if ($thanks) {
554             $description = <<"EOF";
555 It's now time to compose your thank-you message.
556
557 Some information about your local perl configuration will automatically
558 be included at the end of your message, because we're curious about
559 the different ways that people build and use perl. If you'd rather
560 not share this information, you're welcome to delete it.
561
562 $common_end
563 EOF
564         } else {
565             $description =  <<"EOF";
566 It's now time to compose your bug report. Try to make the report
567 concise but descriptive. Please include any detail which you think
568 might be relevant or might help the volunteers working to improve
569 perl. If you are reporting something that does not work as you think
570 it should, please try to include examples of the actual result and of
571 what you expected.
572
573 Some information about your local perl configuration will automatically
574 be included at the end of your report. If you are using an unusual
575 version of perl, it would be useful if you could confirm that you
576 can replicate the problem on a standard build of perl as well.
577
578 $common_end
579 EOF
580         }
581
582     my $entry = _prompt($description, "Editor", $ed);
583         $usefile = 0;
584         if ($entry eq "file") {
585             $usefile = 1;
586         } elsif ($entry ne "") {
587             $ed = $entry;
588         }
589     }
590     if ($::HaveCoreList && !$ok && !$thanks) {
591         my $description =  <<EOF;
592 If your bug is about a Perl module rather than a core language
593 feature, please enter its name here. If it's not, just hit Enter
594 to skip this question.
595 EOF
596
597     my $entry = '';
598         while ($entry eq '') {
599         $entry = _prompt($description, 'Module');
600             my $first_release = Module::CoreList->first_release($entry);
601             if ($entry and not $first_release) {
602                 paraprint <<EOF;
603 $entry is not a "core" Perl module. Please check that you entered
604 its name correctly. If it is correct, quit this program, try searching
605 for $entry on http://rt.cpan.org, and report your issue there.
606 EOF
607
608             $entry = '';
609         } elsif (my $bug_tracker = $Module::CoreList::bug_tracker{$entry}) {
610                 paraprint <<"EOF";
611 $entry included with core Perl is copied directly from the CPAN distribution.
612 Please report bugs in $entry directly to its maintainers using $bug_tracker
613 EOF
614             $entry = '';
615         } elsif ($entry) {
616                 $category ||= 'library';
617                 $report_about_module = $entry;
618             last;
619         } else {
620             last;
621         }
622         }
623     }
624
625     # Prompt for category of bug
626     $category ||= ask_for_alternatives('category');
627
628     # Prompt for severity of bug
629     $severity ||= ask_for_alternatives('severity');
630
631     # Generate scratch file to edit report in
632     $filename = filename();
633
634     # Prompt for file to read report from, if needed
635     if ($usefile and !$file) {
636 filename:
637         my $description = <<EOF;
638 What is the name of the file that contains your report?
639 EOF
640         my $entry = _prompt($description, "Filename");
641
642         if ($entry eq "") {
643             paraprint <<EOF;
644 It seems you didn't enter a filename. Please choose to use a text
645 editor or enter a filename.
646 EOF
647             goto editor;
648         }
649
650         unless (-f $entry and -r $entry) {
651             paraprint <<EOF;
652 '$entry' doesn't seem to be a readable file.  You may have mistyped
653 its name or may not have permission to read it.
654
655 If you don't want to use a file as the content of your report, just
656 hit Enter and you'll be able to select a text editor instead.
657 EOF
658             goto filename;
659         }
660         $file = $entry;
661     }
662
663     # Generate report
664     open(REP,">$filename") or die "Unable to create report file '$filename': $!\n";
665     my $reptype = !$ok ? ($thanks ? 'thank-you' : 'bug')
666         : $::opt_n ? "build failure" : "success";
667
668     print REP <<EOF;
669 This is a $reptype report for perl from $from,
670 generated with the help of perlbug $Version running under perl $perl_version.
671
672 EOF
673
674     if ($body) {
675         print REP $body;
676     } elsif ($usefile) {
677         open(F, "<$file")
678                 or die "Unable to read report file from '$file': $!\n";
679         while (<F>) {
680             print REP $_
681         }
682         close(F) or die "Error closing '$file': $!";
683     } else {
684         if ($thanks) {
685             print REP <<'EOF';
686
687 -----------------------------------------------------------------
688 [Please enter your thank-you message here]
689
690
691
692 [You're welcome to delete anything below this line]
693 -----------------------------------------------------------------
694 EOF
695         } else {
696             print REP <<'EOF';
697
698 -----------------------------------------------------------------
699 [Please describe your issue here]
700
701
702
703 [Please do not change anything below this line]
704 -----------------------------------------------------------------
705 EOF
706         }
707     }
708     Dump(*REP);
709     close(REP) or die "Error closing report file: $!";
710
711     # Set up an initial report fingerprint so we can compare it later
712     _fingerprint_lines_in_report();
713
714 } # sub Query
715
716 sub Dump {
717     local(*OUT) = @_;
718
719     print OUT <<EFF;
720 ---
721 Flags:
722     category=$category
723     severity=$severity
724 EFF
725
726     if ($report_about_module ) { 
727         print OUT <<EFF;
728     module=$report_about_module
729 EFF
730     }
731     if ($::opt_A) {
732         print OUT <<EFF;
733     ack=no
734 EFF
735     }
736     print OUT <<EFF;
737 ---
738 EFF
739     print OUT "This perlbug was built using Perl $config_tag1\n",
740             "It is being executed now by  Perl $config_tag2.\n\n"
741         if $config_tag2 ne $config_tag1;
742
743     print OUT <<EOF;
744 Site configuration information for perl $perl_version:
745
746 EOF
747     if ($::Config{cf_by} and $::Config{cf_time}) {
748         print OUT "Configured by $::Config{cf_by} at $::Config{cf_time}.\n\n";
749     }
750     print OUT Config::myconfig;
751
752     if (@patches) {
753         print OUT join "\n    ", "Locally applied patches:", @patches;
754         print OUT "\n";
755     };
756
757     print OUT <<EOF;
758
759 ---
760 \@INC for perl $perl_version:
761 EOF
762     for my $i (@INC) {
763         print OUT "    $i\n";
764     }
765
766     print OUT <<EOF;
767
768 ---
769 Environment for perl $perl_version:
770 EOF
771     my @env =
772         qw(PATH LD_LIBRARY_PATH LANG PERL_BADLANG SHELL HOME LOGDIR LANGUAGE);
773     push @env, $Config{ldlibpthname} if $Config{ldlibpthname} ne '';
774     push @env, grep /^(?:PERL|LC_|LANG|CYGWIN)/, keys %ENV;
775     my %env;
776     @env{@env} = @env;
777     for my $env (sort keys %env) {
778         print OUT "    $env",
779                 exists $ENV{$env} ? "=$ENV{$env}" : ' (unset)',
780                 "\n";
781     }
782     if ($verbose) {
783         print OUT "\nComplete configuration data for perl $perl_version:\n\n";
784         my $value;
785         foreach (sort keys %::Config) {
786             $value = $::Config{$_};
787             $value =~ s/'/\\'/g;
788             print OUT "$_='$value'\n";
789         }
790     }
791 } # sub Dump
792
793 sub Edit {
794     # Edit the report
795     if ($usefile || $body) {
796         my $description = "Please make sure that the name of the editor you want to use is correct.";
797         my $entry = _prompt($description, 'Editor', $ed);
798         $ed = $entry unless $entry eq '';
799     }
800
801     _edit_file($ed);
802 }
803
804 sub _edit_file {
805     my $editor = shift;
806
807     my $report_written = 0;
808
809     while ( !$report_written ) {
810         if ($Is_MacOS) {
811             require ExtUtils::MakeMaker;
812             ExtUtils::MM_MacOS::launch_file($filename);
813             _prompt('', "Press Enter when done." );
814         } else {    # we're not on oldschool mac os
815             my $exit_status = system("$editor $filename");
816             if ($exit_status) {
817                 my $desc = <<EOF;
818 The editor you chose ('$editor') could not be run!
819
820 If you mistyped its name, please enter it now, otherwise just press Enter.
821 EOF
822                 my $entry = _prompt( $desc, 'Editor', $editor );
823                 if ( $entry ne "" ) {
824                     $editor = $entry;
825                     next;
826                 } else {
827                     paraprint <<EOF;
828 You may want to save your report to a file, so you can edit and
829 mail it later.
830 EOF
831                     return;
832                 }
833             }
834         }
835         return if ( $ok and not $::opt_n ) || $body;
836
837         # Check that we have a report that has some, eh, report in it.
838
839         unless ( _fingerprint_lines_in_report() ) {
840             my $description = <<EOF;
841 It looks like you didn't enter a report. You may [r]etry your edit
842 or [c]ancel this report.
843 EOF
844             my $action = _prompt( $description, "Action (Retry/Cancel) " );
845             if ( $action =~ /^[re]/i ) {    # <R>etry <E>dit
846                 next;
847             } elsif ( $action =~ /^[cq]/i ) {    # <C>ancel, <Q>uit
848                 Cancel();                        # cancel exits
849             }
850         }
851         # Ok. the user did what they needed to;
852         return;
853
854     }
855 }
856
857
858 sub Cancel {
859     1 while unlink($filename);  # remove all versions under VMS
860     print "\nQuitting without sending your message.\n";
861     exit(0);
862 }
863
864 sub NowWhat {
865     # Report is done, prompt for further action
866     if( !$::opt_S ) {
867         while(1) {
868             my $menu = <<EOF;
869
870
871 You have finished composing your message. At this point, you have 
872 a few options. You can:
873
874     * [Se]end the message to $address$andcc, 
875     * [D]isplay the message on the screen,
876     * [R]e-edit the message
877     * Display or change the message's [su]bject
878     * Save the message to a [f]ile to mail at another time
879     * [Q]uit without sending a message
880
881 EOF
882       retry:
883         print $menu;
884             my $action =  _prompt('', "Action (Send/Display/Edit/Subject/Save to File)");;
885         print "\n";
886             if ($action =~ /^(f|sa)/i) { # <F>ile/<Sa>ve
887             if ( SaveMessage() ) { exit }
888             } elsif ($action =~ /^(d|l|sh)/i ) { # <D>isplay, <L>ist, <Sh>ow
889                 # Display the message
890                 open(REP, "<$filename") or die "Couldn't open file '$filename': $!\n";
891                 while (<REP>) { print $_ }
892                 close(REP) or die "Error closing report file '$filename': $!";
893             } elsif ($action =~ /^su/i) { # <Su>bject
894                 my $reply = _prompt( "Subject: $subject", "If the above subject is fine, press Enter. Otherwise, type a replacement now\nSubject");
895                 if ($reply ne '') {
896                     unless (TrivialSubject($reply)) {
897                         $subject = $reply;
898                         print "Subject: $subject\n";
899                     }
900                 }
901             } elsif ($action =~ /^se/i) { # <S>end
902                 # Send the message
903                 my $reply =  _prompt( "Are you certain you want to send this message?", 'Please type "yes" if you are','no');
904                 if ($reply =~ /^yes$/) {
905                     last;
906                 } else {
907                     paraprint <<EOF;
908 You didn't type "yes", so your message has not yet been sent.
909 EOF
910                 }
911             } elsif ($action =~ /^[er]/i) { # <E>dit, <R>e-edit
912                 # edit the message
913                 Edit();
914             } elsif ($action =~ /^[qc]/i) { # <C>ancel, <Q>uit
915                 Cancel();
916             } elsif ($action =~ /^s/i) {
917                 paraprint <<EOF;
918 The command you entered was ambiguous. Please type "send", "save" or "subject".
919 EOF
920             }
921         }
922     }
923 } # sub NowWhat
924
925 sub TrivialSubject {
926     my $subject = shift;
927     if ($subject =~
928         /^(y(es)?|no?|help|perl( (bug|problem))?|bug|problem)$/i ||
929         length($subject) < 4 ||
930         $subject !~ /\s/) {
931         print "\nThe subject you entered wasn't very descriptive. Please try again.\n\n";
932         return 1;
933     } else {
934         return 0;
935     }
936 }
937
938 sub SaveMessage {
939     my $file_save = $outfile || "$progname.rep";
940     my $file = _prompt( '', "Name of file to save message in", $file_save );
941     save_message_to_disk($file) || return undef;
942     print "\n";
943     paraprint <<EOF;
944 A copy of your message has been saved in '$file' for you to
945 send to '$address' with your normal mail client.
946 EOF
947 }
948
949 sub Send {
950
951     # Message has been accepted for transmission -- Send the message
952
953     # on linux certain "mail" implementations won't accept the subject
954     # as "~s subject" and thus the Subject header will be corrupted
955     # so don't use Mail::Send to be safe
956     eval {
957         if ( $::HaveSend && !$Is_Linux && !$Is_OpenBSD ) {
958             _send_message_mailsend();
959         } elsif ($Is_VMS) {
960             _send_message_vms();
961         } else {
962             _send_message_sendmail();
963         }
964     };
965
966     if ( my $error = $@ ) {
967         paraprint <<EOF;
968 $0 has detected an error while trying to send your message: $error.
969
970 Your message may not have been sent. You will now have a chance to save a copy to disk.
971 EOF
972         SaveMessage();
973         return;
974     }
975
976     1 while unlink($filename);    # remove all versions under VMS
977 }    # sub Send
978
979 sub Help {
980     print <<EOF;
981
982 This program is designed to help you generate and send bug reports
983 (and thank-you notes) about perl5 and the modules which ship with it.
984
985 In most cases, you can just run "$0" interactively from a command
986 line without any special arguments and follow the prompts.
987
988 Advanced usage:
989
990 $0  [-v] [-a address] [-s subject] [-b body | -f inpufile ] [ -F outputfile ]
991     [-r returnaddress] [-e editor] [-c adminaddress | -C] [-S] [-t] [-h]
992 $0  [-v] [-r returnaddress] [-A] [-ok | -okay | -nok | -nokay]
993
994
995 Options:
996
997   -v    Include Verbose configuration data in the report
998   -f    File containing the body of the report. Use this to
999         quickly send a prepared message.
1000   -F    File to output the resulting mail message to, instead of mailing.
1001   -S    Send without asking for confirmation.
1002   -a    Address to send the report to. Defaults to '$address'.
1003   -c    Address to send copy of report to. Defaults to '$cc'.
1004   -C    Don't send copy to administrator.
1005   -s    Subject to include with the message. You will be prompted
1006         if you don't supply one on the command line.
1007   -b    Body of the report. If not included on the command line, or
1008         in a file with -f, you will get a chance to edit the message.
1009   -r    Your return address. The program will ask you to confirm
1010         this if you don't give it here.
1011   -e    Editor to use.
1012   -t    Test mode. The target address defaults to '$testaddress'.
1013   -T    Thank-you mode. The target address defaults to '$thanksaddress'.
1014   -d    Data mode.  This prints out your configuration data, without mailing
1015         anything. You can use this with -v to get more complete data.
1016   -A    Don't send a bug received acknowledgement to the return address.
1017   -ok   Report successful build on this system to perl porters
1018         (use alone or with -v). Only use -ok if *everything* was ok:
1019         if there were *any* problems at all, use -nok.
1020   -okay As -ok but allow report from old builds.
1021   -nok  Report unsuccessful build on this system to perl porters
1022         (use alone or with -v). You must describe what went wrong
1023         in the body of the report which you will be asked to edit.
1024   -nokay As -nok but allow report from old builds.
1025   -h    Print this help message.
1026
1027 EOF
1028 }
1029
1030 sub filename {
1031     if ($::HaveTemp) {
1032         # Good. Use a secure temp file
1033         my ($fh, $filename) = File::Temp::tempfile(UNLINK => 1);
1034         close($fh);
1035         return $filename;
1036     } else {
1037         # Bah. Fall back to doing things less securely.
1038         my $dir = File::Spec->tmpdir();
1039         $filename = "bugrep0$$";
1040         $filename++ while -e File::Spec->catfile($dir, $filename);
1041         $filename = File::Spec->catfile($dir, $filename);
1042     }
1043 }
1044
1045 sub paraprint {
1046     my @paragraphs = split /\n{2,}/, "@_";
1047     for (@paragraphs) {   # implicit local $_
1048         s/(\S)\s*\n/$1 /g;
1049         write;
1050         print "\n";
1051     }
1052 }
1053
1054 sub _prompt {
1055     my ($explanation, $prompt, $default) = (@_);
1056     if ($explanation) {
1057         print "\n\n";
1058         paraprint $explanation;
1059     }
1060     print $prompt. ($default ? " [$default]" :''). ": ";
1061         my $result = scalar(<>);
1062     chomp($result);
1063         $result =~ s/^\s*(.*?)\s*$/$1/s;
1064     if ($default && $result eq '') {
1065         return $default;
1066     } else {
1067         return $result;
1068     }
1069 }
1070
1071 sub _build_header {
1072     my %attr = (@_);
1073
1074     my $head = '';
1075     for my $header (keys %attr) {
1076         $head .= "$header: ".$attr{$header}."\n";
1077     }
1078     return $head;
1079 }
1080
1081 sub _message_headers {
1082     my %headers = ( To => $address, Subject => $subject );
1083     $headers{'Cc'}         = $cc        if ($cc);
1084     $headers{'Message-Id'} = $messageid if ($messageid);
1085     $headers{'Reply-To'}   = $from      if ($from);
1086     return \%headers;
1087 }
1088
1089 sub build_complete_message {
1090     my $content = _build_header(%{_message_headers()}) . "\n\n";
1091     open( REP, "<$filename" ) or die "Couldn't open file '$filename': $!\n";
1092     while (<REP>) { $content .= $_; }
1093     close(REP) or die "Error closing report file '$filename': $!";
1094     return $content;
1095 }
1096
1097 sub save_message_to_disk {
1098     my $file = shift;
1099
1100             open OUTFILE, ">$file" or do { warn  "Couldn't open '$file': $!\n"; return undef};
1101         print OUTFILE build_complete_message();
1102         close(OUTFILE) or do { warn  "Error closing $file: $!"; return undef };
1103             print "\nMessage saved.\n";
1104         return 1;
1105 }
1106
1107 sub _send_message_vms {
1108     if (   ( $address =~ /@/ and $address !~ /^\w+%"/ )
1109         or ( $cc =~ /@/ and $cc !~ /^\w+%"/ ) ) {
1110         my $prefix;
1111         foreach ( qw[ IN MX SMTP UCX PONY WINS ], '' ) {
1112             $prefix = "$_%", last if $ENV{"MAIL\$PROTOCOL_$_"};
1113         }
1114         $address = qq[${prefix}"$address"] unless $address =~ /^\w+%"/;
1115         $cc = qq[${prefix}"$cc"] unless !$cc || $cc =~ /^\w+%"/;
1116     }
1117     $subject =~ s/"/""/g;
1118     $address =~ s/"/""/g;
1119     $cc      =~ s/"/""/g;
1120     my $sts = system(qq[mail/Subject="$subject" $filename. "$address","$cc"]);
1121     if ($sts) {
1122         die "Can't spawn off mail (leaving bug report in $filename): $sts";
1123     }
1124 }
1125
1126 sub _send_message_mailsend {
1127     my $msg = Mail::Send->new();
1128     my %headers = %{_message_headers()};
1129     for my $key ( keys %headers) {
1130         $msg->add($key => $headers{$key});
1131     }
1132
1133     $fh = $msg->open;
1134     open(REP, "<$filename") or die "Couldn't open '$filename': $!\n";
1135     while (<REP>) { print $fh $_ }
1136     close(REP) or die "Error closing $filename: $!";
1137     $fh->close;
1138
1139     print "\nMessage sent.\n";
1140 }
1141
1142 sub _probe_for_sendmail {
1143     my $sendmail = "";
1144     for (qw(/usr/lib/sendmail /usr/sbin/sendmail /usr/ucblib/sendmail)) {
1145         $sendmail = $_, last if -e $_;
1146     }
1147     if ( $^O eq 'os2' and $sendmail eq "" ) {
1148         my $path = $ENV{PATH};
1149         $path =~ s:\\:/:;
1150         my @path = split /$Config{'path_sep'}/, $path;
1151         for (@path) {
1152             $sendmail = "$_/sendmail",     last if -e "$_/sendmail";
1153             $sendmail = "$_/sendmail.exe", last if -e "$_/sendmail.exe";
1154         }
1155     }
1156     return $sendmail;
1157 }
1158
1159 sub _send_message_sendmail {
1160     my $sendmail = _probe_for_sendmail();
1161     unless ($sendmail) {
1162         paraprint(<<"EOF"), die "\n";
1163 It appears that there is no program which looks like "sendmail" on
1164 your system and that the Mail::Send library from CPAN isn't available.
1165 Because of this, there's no easy way to automatically send your
1166 message.
1167
1168 A copy of your message has been saved in '$filename' for you to
1169 send to '$address' with your normal mail client.
1170 EOF
1171     }
1172
1173     open( SENDMAIL, "|$sendmail -t -oi" )
1174         || die "'|$sendmail -t -oi' failed: $!";
1175     print SENDMAIL build_complete_message();
1176     if ( close(SENDMAIL) ) {
1177         print "\nMessage sent\n";
1178     } else {
1179         warn "\nSendmail returned status '", $? >> 8, "'\n";
1180     }
1181 }
1182
1183
1184
1185 # a strange way to check whether any significant editing
1186 # has been done: check whether any new non-empty lines
1187 # have been added.
1188
1189 sub _fingerprint_lines_in_report {
1190     my $new_lines = 0;
1191     # read in the report template once so that
1192     # we can track whether the user does any editing.
1193     # yes, *all* whitespace is ignored.
1194
1195     open(REP, "<$filename") or die "Unable to open report file '$filename': $!\n";
1196     while (my $line = <REP>) {
1197         $line =~ s/\s+//g;
1198         $new_lines++ if (!$REP{$line});
1199
1200     }
1201     close(REP) or die "Error closing report file '$filename': $!";
1202     # returns the number of lines with content that wasn't there when last we looked
1203     return $new_lines;
1204 }
1205
1206
1207
1208 format STDOUT =
1209 ^<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< ~~
1210 $_
1211 .
1212
1213 __END__
1214
1215 =head1 NAME
1216
1217 perlbug - how to submit bug reports on Perl
1218
1219 =head1 SYNOPSIS
1220
1221 B<perlbug>
1222
1223 B<perlbug> S<[ B<-v> ]> S<[ B<-a> I<address> ]> S<[ B<-s> I<subject> ]>
1224 S<[ B<-b> I<body> | B<-f> I<inputfile> ]> S<[ B<-F> I<outputfile> ]>
1225 S<[ B<-r> I<returnaddress> ]>
1226 S<[ B<-e> I<editor> ]> S<[ B<-c> I<adminaddress> | B<-C> ]>
1227 S<[ B<-S> ]> S<[ B<-t> ]>  S<[ B<-d> ]>  S<[ B<-A> ]>  S<[ B<-h> ]> S<[ B<-T> ]>
1228
1229 B<perlbug> S<[ B<-v> ]> S<[ B<-r> I<returnaddress> ]>
1230  S<[ B<-A> ]> S<[ B<-ok> | B<-okay> | B<-nok> | B<-nokay> ]>
1231
1232 B<perlthanks>
1233
1234 =head1 DESCRIPTION
1235
1236
1237 This program is designed to help you generate and send bug reports
1238 (and thank-you notes) about perl5 and the modules which ship with it.
1239
1240 In most cases, you can just run it interactively from a command
1241 line without any special arguments and follow the prompts.
1242
1243 If you have found a bug with a non-standard port (one that was not
1244 part of the I<standard distribution>), a binary distribution, or a
1245 non-core module (such as Tk, DBI, etc), then please see the
1246 documentation that came with that distribution to determine the
1247 correct place to report bugs.
1248
1249 If you are unable to send your report using B<perlbug> (most likely
1250 because your system doesn't have a way to send mail that perlbug
1251 recognizes), you may be able to use this tool to compose your report
1252 and save it to a file which you can then send to B<perlbug@perl.org>
1253 using your regular mail client.
1254
1255 In extreme cases, B<perlbug> may not work well enough on your system
1256 to guide you through composing a bug report. In those cases, you
1257 may be able to use B<perlbug -d> to get system configuration
1258 information to include in a manually composed bug report to
1259 B<perlbug@perl.org>.
1260
1261
1262 When reporting a bug, please run through this checklist:
1263
1264 =over 4
1265
1266 =item What version of Perl you are running?
1267
1268 Type C<perl -v> at the command line to find out.
1269
1270 =item Are you running the latest released version of perl?
1271
1272 Look at http://www.perl.org/ to find out.  If you are not using the
1273 latest released version, please try to replicate your bug on the
1274 latest stable release.
1275
1276 Note that reports about bugs in old versions of Perl, especially
1277 those which indicate you haven't also tested the current stable
1278 release of Perl, are likely to receive less attention from the
1279 volunteers who build and maintain Perl than reports about bugs in
1280 the current release.
1281
1282 This tool isn't apropriate for reporting bugs in any version
1283 prior to Perl 5.0.
1284
1285 =item Are you sure what you have is a bug?
1286
1287 A significant number of the bug reports we get turn out to be
1288 documented features in Perl.  Make sure the issue you've run into
1289 isn't intentional by glancing through the documentation that comes
1290 with the Perl distribution.
1291
1292 Given the sheer volume of Perl documentation, this isn't a trivial
1293 undertaking, but if you can point to documentation that suggests
1294 the behaviour you're seeing is I<wrong>, your issue is likely to
1295 receive more attention. You may want to start with B<perldoc>
1296 L<perltrap> for pointers to common traps that new (and experienced)
1297 Perl programmers run into.
1298
1299 If you're unsure of the meaning of an error message you've run
1300 across, B<perldoc> L<perldiag> for an explanation.  If the message
1301 isn't in perldiag, it probably isn't generated by Perl.  You may
1302 have luck consulting your operating system documentation instead.
1303
1304 If you are on a non-UNIX platform B<perldoc> L<perlport>, as some
1305 features may be unimplemented or work differently.
1306
1307 You may be able to figure out what's going wrong using the Perl
1308 debugger.  For information about how to use the debugger B<perldoc>
1309 L<perldebug>.
1310
1311 =item Do you have a proper test case?
1312
1313 The easier it is to reproduce your bug, the more likely it will be
1314 fixed -- if nobody can duplicate your problem, it probably won't be 
1315 addressed.
1316
1317 A good test case has most of these attributes: short, simple code;
1318 few dependencies on external commands, modules, or libraries; no
1319 platform-dependent code (unless it's a platform-specific bug);
1320 clear, simple documentation.
1321
1322 A good test case is almost always a good candidate to be included in
1323 Perl's test suite.  If you have the time, consider writing your test case so
1324 that it can be easily included into the standard test suite.
1325
1326 =item Have you included all relevant information?
1327
1328 Be sure to include the B<exact> error messages, if any.
1329 "Perl gave an error" is not an exact error message.
1330
1331 If you get a core dump (or equivalent), you may use a debugger
1332 (B<dbx>, B<gdb>, etc) to produce a stack trace to include in the bug
1333 report.  
1334
1335 NOTE: unless your Perl has been compiled with debug info
1336 (often B<-g>), the stack trace is likely to be somewhat hard to use
1337 because it will most probably contain only the function names and not
1338 their arguments.  If possible, recompile your Perl with debug info and
1339 reproduce the crash and the stack trace.
1340
1341 =item Can you describe the bug in plain English?
1342
1343 The easier it is to understand a reproducible bug, the more likely
1344 it will be fixed.  Any insight you can provide into the problem
1345 will help a great deal.  In other words, try to analyze the problem
1346 (to the extent you can) and report your discoveries.
1347
1348 =item Can you fix the bug yourself?
1349
1350 A bug report which I<includes a patch to fix it> will almost
1351 definitely be fixed.  When sending a patch, please use the C<diff>
1352 program with the C<-u> option to generate "unified" diff files.
1353 Bug reports with patches are likely to receive significantly more
1354 attention and interest than those without patches.
1355
1356 Your patch may be returned with requests for changes, or requests for more
1357 detailed explanations about your fix.
1358
1359 Here are a few hints for creating high-quality patches:
1360
1361 Make sure the patch is not reversed (the first argument to diff is
1362 typically the original file, the second argument your changed file).
1363 Make sure you test your patch by applying it with the C<patch>
1364 program before you send it on its way.  Try to follow the same style
1365 as the code you are trying to patch.  Make sure your patch really
1366 does work (C<make test>, if the thing you're patching is covered
1367 by Perl's test suite).
1368
1369 =item Can you use C<perlbug> to submit the report?
1370
1371 B<perlbug> will, amongst other things, ensure your report includes
1372 crucial information about your version of perl.  If C<perlbug> is
1373 unable to mail your report after you have typed it in, you may have
1374 to compose the message yourself, add the output produced by C<perlbug
1375 -d> and email it to B<perlbug@perl.org>.  If, for some reason, you
1376 cannot run C<perlbug> at all on your system, be sure to include the
1377 entire output produced by running C<perl -V> (note the uppercase V).
1378
1379 Whether you use C<perlbug> or send the email manually, please make
1380 your Subject line informative.  "a bug" is not informative.  Neither
1381 is "perl crashes" nor is "HELP!!!".  These don't help.  A compact
1382 description of what's wrong is fine.
1383
1384 =item Can you use C<perlbug> to submit a thank-you note?
1385
1386 Yes, you can do this by either using the C<-T> option, or by invoking
1387 the program as C<perlthanks>. Thank-you notes are good. It makes people
1388 smile. 
1389
1390 =back
1391
1392 Having done your bit, please be prepared to wait, to be told the
1393 bug is in your code, or possibly to get no reply at all.  The
1394 volunteers who maintain Perl are busy folks, so if your problem is
1395 an obvious bug in your own code, is difficult to understand or is
1396 a duplicate of an existing report, you may not receive a personal
1397 reply.
1398
1399 If it is important to you that your bug be fixed, do monitor the
1400 perl5-porters@perl.org mailing list and the commit logs to development
1401 versions of Perl, and encourage the maintainers with kind words or
1402 offers of frosty beverages.  (Please do be kind to the maintainers.
1403 Harassing or flaming them is likely to have the opposite effect of
1404 the one you want.)
1405
1406 Feel free to update the ticket about your bug on http://rt.perl.org
1407 if a new version of Perl is released and your bug is still present.
1408
1409 =head1 OPTIONS
1410
1411 =over 8
1412
1413 =item B<-a>
1414
1415 Address to send the report to.  Defaults to B<perlbug@perl.org>.
1416
1417 =item B<-A>
1418
1419 Don't send a bug received acknowledgement to the reply address.
1420 Generally it is only a sensible to use this option if you are a
1421 perl maintainer actively watching perl porters for your message to
1422 arrive.
1423
1424 =item B<-b>
1425
1426 Body of the report.  If not included on the command line, or
1427 in a file with B<-f>, you will get a chance to edit the message.
1428
1429 =item B<-C>
1430
1431 Don't send copy to administrator.
1432
1433 =item B<-c>
1434
1435 Address to send copy of report to.  Defaults to the address of the
1436 local perl administrator (recorded when perl was built).
1437
1438 =item B<-d>
1439
1440 Data mode (the default if you redirect or pipe output).  This prints out
1441 your configuration data, without mailing anything.  You can use this
1442 with B<-v> to get more complete data.
1443
1444 =item B<-e>
1445
1446 Editor to use.
1447
1448 =item B<-f>
1449
1450 File containing the body of the report.  Use this to quickly send a
1451 prepared message.
1452
1453 =item B<-F>
1454
1455 File to output the results to instead of sending as an email. Useful
1456 particularly when running perlbug on a machine with no direct internet
1457 connection.
1458
1459 =item B<-h>
1460
1461 Prints a brief summary of the options.
1462
1463 =item B<-ok>
1464
1465 Report successful build on this system to perl porters. Forces B<-S>
1466 and B<-C>. Forces and supplies values for B<-s> and B<-b>. Only
1467 prompts for a return address if it cannot guess it (for use with
1468 B<make>). Honors return address specified with B<-r>.  You can use this
1469 with B<-v> to get more complete data.   Only makes a report if this
1470 system is less than 60 days old.
1471
1472 =item B<-okay>
1473
1474 As B<-ok> except it will report on older systems.
1475
1476 =item B<-nok>
1477
1478 Report unsuccessful build on this system.  Forces B<-C>.  Forces and
1479 supplies a value for B<-s>, then requires you to edit the report
1480 and say what went wrong.  Alternatively, a prepared report may be
1481 supplied using B<-f>.  Only prompts for a return address if it
1482 cannot guess it (for use with B<make>). Honors return address
1483 specified with B<-r>.  You can use this with B<-v> to get more
1484 complete data.  Only makes a report if this system is less than 60
1485 days old.
1486
1487 =item B<-nokay>
1488
1489 As B<-nok> except it will report on older systems.
1490
1491 =item B<-r>
1492
1493 Your return address.  The program will ask you to confirm its default
1494 if you don't use this option.
1495
1496 =item B<-S>
1497
1498 Send without asking for confirmation.
1499
1500 =item B<-s>
1501
1502 Subject to include with the message.  You will be prompted if you don't
1503 supply one on the command line.
1504
1505 =item B<-t>
1506
1507 Test mode.  The target address defaults to B<perlbug-test@perl.org>.
1508
1509 =item B<-T>
1510
1511 Send a thank-you note instead of a bug report. 
1512
1513 =item B<-v>
1514
1515 Include verbose configuration data in the report.
1516
1517 =back
1518
1519 =head1 AUTHORS
1520
1521 Kenneth Albanowski (E<lt>kjahds@kjahds.comE<gt>), subsequently
1522 I<doc>tored by Gurusamy Sarathy (E<lt>gsar@activestate.comE<gt>),
1523 Tom Christiansen (E<lt>tchrist@perl.comE<gt>), Nathan Torkington
1524 (E<lt>gnat@frii.comE<gt>), Charles F. Randall (E<lt>cfr@pobox.comE<gt>),
1525 Mike Guy (E<lt>mjtg@cam.a.ukE<gt>), Dominic Dunlop
1526 (E<lt>domo@computer.orgE<gt>), Hugo van der Sanden (E<lt>hv@crypt.org<gt>),
1527 Jarkko Hietaniemi (E<lt>jhi@iki.fiE<gt>), Chris Nandor
1528 (E<lt>pudge@pobox.comE<gt>), Jon Orwant (E<lt>orwant@media.mit.eduE<gt>,
1529 Richard Foley (E<lt>richard.foley@rfi.netE<gt>), and Jesse Vincent
1530 (E<lt>jesse@bestpractical.com<gt>).
1531
1532 =head1 SEE ALSO
1533
1534 perl(1), perldebug(1), perldiag(1), perlport(1), perltrap(1),
1535 diff(1), patch(1), dbx(1), gdb(1)
1536
1537 =head1 BUGS
1538
1539 None known (guess what must have been used to report them?)
1540
1541 =cut
1542
1543 !NO!SUBS!
1544
1545 close OUT or die "Can't close $file: $!";
1546 chmod 0755, $file or die "Can't reset permissions for $file: $!\n";
1547 exec("$Config{'eunicefix'} $file") if $Config{'eunicefix'} ne ':';
1548 chdir $origdir;