our $TODO should be local $::TODO, revealing a bug in the de-commenting regexp.
[perl.git] / lib / overload.pm
1 package overload;
2
3 our $VERSION = '1.07';
4
5 sub nil {}
6
7 sub OVERLOAD {
8   $package = shift;
9   my %arg = @_;
10   my ($sub, $fb);
11   $ {$package . "::OVERLOAD"}{dummy}++; # Register with magic by touching.
12   *{$package . "::()"} = \&nil; # Make it findable via fetchmethod.
13   for (keys %arg) {
14     if ($_ eq 'fallback') {
15       $fb = $arg{$_};
16     } else {
17       $sub = $arg{$_};
18       if (not ref $sub and $sub !~ /::/) {
19         $ {$package . "::(" . $_} = $sub;
20         $sub = \&nil;
21       }
22       #print STDERR "Setting `$ {'package'}::\cO$_' to \\&`$sub'.\n";
23       *{$package . "::(" . $_} = \&{ $sub };
24     }
25   }
26   ${$package . "::()"} = $fb; # Make it findable too (fallback only).
27 }
28
29 sub import {
30   $package = (caller())[0];
31   # *{$package . "::OVERLOAD"} = \&OVERLOAD;
32   shift;
33   $package->overload::OVERLOAD(@_);
34 }
35
36 sub unimport {
37   $package = (caller())[0];
38   ${$package . "::OVERLOAD"}{dummy}++; # Upgrade the table
39   shift;
40   for (@_) {
41     if ($_ eq 'fallback') {
42       undef $ {$package . "::()"};
43     } else {
44       delete $ {$package . "::"}{"(" . $_};
45     }
46   }
47 }
48
49 sub Overloaded {
50   my $package = shift;
51   $package = ref $package if ref $package;
52   $package->can('()');
53 }
54
55 sub ov_method {
56   my $globref = shift;
57   return undef unless $globref;
58   my $sub = \&{*$globref};
59   return $sub if $sub ne \&nil;
60   return shift->can($ {*$globref});
61 }
62
63 sub OverloadedStringify {
64   my $package = shift;
65   $package = ref $package if ref $package;
66   #$package->can('(""')
67   ov_method mycan($package, '(""'), $package
68     or ov_method mycan($package, '(0+'), $package
69     or ov_method mycan($package, '(bool'), $package
70     or ov_method mycan($package, '(nomethod'), $package;
71 }
72
73 sub Method {
74   my $package = shift;
75   if(ref $package) {
76     local $@;
77     local $!;
78     require Scalar::Util;
79     $package = Scalar::Util::blessed($package);
80     return undef if !defined $package;
81   }
82   #my $meth = $package->can('(' . shift);
83   ov_method mycan($package, '(' . shift), $package;
84   #return $meth if $meth ne \&nil;
85   #return $ {*{$meth}};
86 }
87
88 sub AddrRef {
89   my $package = ref $_[0];
90   return "$_[0]" unless $package;
91
92   local $@;
93   local $!;
94   require Scalar::Util;
95   my $class = Scalar::Util::blessed($_[0]);
96   my $class_prefix = defined($class) ? "$class=" : "";
97   my $type = Scalar::Util::reftype($_[0]);
98   my $addr = Scalar::Util::refaddr($_[0]);
99   return sprintf("$class_prefix$type(0x%x)", $addr);
100 }
101
102 *StrVal = *AddrRef;
103
104 sub mycan {                             # Real can would leave stubs.
105   my ($package, $meth) = @_;
106
107   local $@;
108   local $!;
109   require mro;
110
111   my $mro = mro::get_linear_isa($package);
112   foreach my $p (@$mro) {
113     my $fqmeth = $p . q{::} . $meth;
114     return \*{$fqmeth} if defined &{$fqmeth};
115   }
116
117   return undef;
118 }
119
120 %constants = (
121               'integer'   =>  0x1000, # HINT_NEW_INTEGER
122               'float'     =>  0x2000, # HINT_NEW_FLOAT
123               'binary'    =>  0x4000, # HINT_NEW_BINARY
124               'q'         =>  0x8000, # HINT_NEW_STRING
125               'qr'        => 0x10000, # HINT_NEW_RE
126              );
127
128 %ops = ( with_assign      => "+ - * / % ** << >> x .",
129          assign           => "+= -= *= /= %= **= <<= >>= x= .=",
130          num_comparison   => "< <= >  >= == !=",
131          '3way_comparison'=> "<=> cmp",
132          str_comparison   => "lt le gt ge eq ne",
133          binary           => '& &= | |= ^ ^=',
134          unary            => "neg ! ~",
135          mutators         => '++ --',
136          func             => "atan2 cos sin exp abs log sqrt int",
137          conversion       => 'bool "" 0+',
138          iterators        => '<>',
139          filetest         => "-X",
140          dereferencing    => '${} @{} %{} &{} *{}',
141          special          => 'nomethod fallback =');
142
143 use warnings::register;
144 sub constant {
145   # Arguments: what, sub
146   while (@_) {
147     if (@_ == 1) {
148         warnings::warnif ("Odd number of arguments for overload::constant");
149         last;
150     }
151     elsif (!exists $constants {$_ [0]}) {
152         warnings::warnif ("`$_[0]' is not an overloadable type");
153     }
154     elsif (!ref $_ [1] || "$_[1]" !~ /(^|=)CODE\(0x[0-9a-f]+\)$/) {
155         # Can't use C<ref $_[1] eq "CODE"> above as code references can be
156         # blessed, and C<ref> would return the package the ref is blessed into.
157         if (warnings::enabled) {
158             $_ [1] = "undef" unless defined $_ [1];
159             warnings::warn ("`$_[1]' is not a code reference");
160         }
161     }
162     else {
163         $^H{$_[0]} = $_[1];
164         $^H |= $constants{$_[0]};
165     }
166     shift, shift;
167   }
168 }
169
170 sub remove_constant {
171   # Arguments: what, sub
172   while (@_) {
173     delete $^H{$_[0]};
174     $^H &= ~ $constants{$_[0]};
175     shift, shift;
176   }
177 }
178
179 1;
180
181 __END__
182
183 =head1 NAME
184
185 overload - Package for overloading Perl operations
186
187 =head1 SYNOPSIS
188
189     package SomeThing;
190
191     use overload
192         '+' => \&myadd,
193         '-' => \&mysub;
194         # etc
195     ...
196
197     package main;
198     $a = SomeThing->new( 57 );
199     $b=5+$a;
200     ...
201     if (overload::Overloaded $b) {...}
202     ...
203     $strval = overload::StrVal $b;
204
205 =head1 DESCRIPTION
206
207 This pragma allows overloading of Perl's operators for a class.
208 To overload built-in functions, see L<perlsub/Overriding Built-in Functions> instead.
209
210 =head2 Declaration of overloaded functions
211
212 The compilation directive
213
214     package Number;
215     use overload
216         "+" => \&add,
217         "*=" => "muas";
218
219 declares function Number::add() for addition, and method muas() in
220 the "class" C<Number> (or one of its base classes)
221 for the assignment form C<*=> of multiplication.
222
223 Arguments of this directive come in (key, value) pairs.  Legal values
224 are values legal inside a C<&{ ... }> call, so the name of a
225 subroutine, a reference to a subroutine, or an anonymous subroutine
226 will all work.  Note that values specified as strings are
227 interpreted as methods, not subroutines.  Legal keys are listed below.
228
229 The subroutine C<add> will be called to execute C<$a+$b> if $a
230 is a reference to an object blessed into the package C<Number>, or if $a is
231 not an object from a package with defined mathemagic addition, but $b is a
232 reference to a C<Number>.  It can also be called in other situations, like
233 C<$a+=7>, or C<$a++>.  See L<MAGIC AUTOGENERATION>.  (Mathemagical
234 methods refer to methods triggered by an overloaded mathematical
235 operator.)
236
237 Since overloading respects inheritance via the @ISA hierarchy, the
238 above declaration would also trigger overloading of C<+> and C<*=> in
239 all the packages which inherit from C<Number>.
240
241 =head2 Calling Conventions for Binary Operations
242
243 The functions specified in the C<use overload ...> directive are called
244 with three (in one particular case with four, see L<Last Resort>)
245 arguments.  If the corresponding operation is binary, then the first
246 two arguments are the two arguments of the operation.  However, due to
247 general object calling conventions, the first argument should always be
248 an object in the package, so in the situation of C<7+$a>, the
249 order of the arguments is interchanged.  It probably does not matter
250 when implementing the addition method, but whether the arguments
251 are reversed is vital to the subtraction method.  The method can
252 query this information by examining the third argument, which can take
253 three different values:
254
255 =over 7
256
257 =item FALSE
258
259 the order of arguments is as in the current operation.
260
261 =item TRUE
262
263 the arguments are reversed.
264
265 =item C<undef>
266
267 the current operation is an assignment variant (as in
268 C<$a+=7>), but the usual function is called instead.  This additional
269 information can be used to generate some optimizations.  Compare
270 L<Calling Conventions for Mutators>.
271
272 =back
273
274 =head2 Calling Conventions for Unary Operations
275
276 Unary operation are considered binary operations with the second
277 argument being C<undef>.  Thus the functions that overloads C<{"++"}>
278 is called with arguments C<($a,undef,'')> when $a++ is executed.
279
280 =head2 Calling Conventions for Mutators
281
282 Two types of mutators have different calling conventions:
283
284 =over
285
286 =item C<++> and C<-->
287
288 The routines which implement these operators are expected to actually
289 I<mutate> their arguments.  So, assuming that $obj is a reference to a
290 number,
291
292   sub incr { my $n = $ {$_[0]}; ++$n; $_[0] = bless \$n}
293
294 is an appropriate implementation of overloaded C<++>.  Note that
295
296   sub incr { ++$ {$_[0]} ; shift }
297
298 is OK if used with preincrement and with postincrement. (In the case
299 of postincrement a copying will be performed, see L<Copy Constructor>.)
300
301 =item C<x=> and other assignment versions
302
303 There is nothing special about these methods.  They may change the
304 value of their arguments, and may leave it as is.  The result is going
305 to be assigned to the value in the left-hand-side if different from
306 this value.
307
308 This allows for the same method to be used as overloaded C<+=> and
309 C<+>.  Note that this is I<allowed>, but not recommended, since by the
310 semantic of L<"Fallback"> Perl will call the method for C<+> anyway,
311 if C<+=> is not overloaded.
312
313 =back
314
315 B<Warning.>  Due to the presence of assignment versions of operations,
316 routines which may be called in assignment context may create
317 self-referential structures.  Currently Perl will not free self-referential
318 structures until cycles are C<explicitly> broken.  You may get problems
319 when traversing your structures too.
320
321 Say,
322
323   use overload '+' => sub { bless [ \$_[0], \$_[1] ] };
324
325 is asking for trouble, since for code C<$obj += $foo> the subroutine
326 is called as C<$obj = add($obj, $foo, undef)>, or C<$obj = [\$obj,
327 \$foo]>.  If using such a subroutine is an important optimization, one
328 can overload C<+=> explicitly by a non-"optimized" version, or switch
329 to non-optimized version if C<not defined $_[2]> (see
330 L<Calling Conventions for Binary Operations>).
331
332 Even if no I<explicit> assignment-variants of operators are present in
333 the script, they may be generated by the optimizer.  Say, C<",$obj,"> or
334 C<',' . $obj . ','> may be both optimized to
335
336   my $tmp = ',' . $obj;    $tmp .= ',';
337
338 =head2 Overloadable Operations
339
340 The following symbols can be specified in C<use overload> directive:
341
342 =over 5
343
344 =item * I<Arithmetic operations>
345
346     "+", "+=", "-", "-=", "*", "*=", "/", "/=", "%", "%=",
347     "**", "**=", "<<", "<<=", ">>", ">>=", "x", "x=", ".", ".=",
348
349 For these operations a substituted non-assignment variant can be called if
350 the assignment variant is not available.  Methods for operations C<+>,
351 C<->, C<+=>, and C<-=> can be called to automatically generate
352 increment and decrement methods.  The operation C<-> can be used to
353 autogenerate missing methods for unary minus or C<abs>.
354
355 See L<"MAGIC AUTOGENERATION">, L<"Calling Conventions for Mutators"> and
356 L<"Calling Conventions for Binary Operations">) for details of these
357 substitutions.
358
359 =item * I<Comparison operations>
360
361     "<",  "<=", ">",  ">=", "==", "!=", "<=>",
362     "lt", "le", "gt", "ge", "eq", "ne", "cmp",
363
364 If the corresponding "spaceship" variant is available, it can be
365 used to substitute for the missing operation.  During C<sort>ing
366 arrays, C<cmp> is used to compare values subject to C<use overload>.
367
368 =item * I<Bit operations>
369
370     "&", "&=", "^", "^=", "|", "|=", "neg", "!", "~",
371
372 C<neg> stands for unary minus.  If the method for C<neg> is not
373 specified, it can be autogenerated using the method for
374 subtraction. If the method for C<!> is not specified, it can be
375 autogenerated using the methods for C<bool>, or C<"">, or C<0+>.
376
377 The same remarks in L<"Arithmetic operations"> about
378 assignment-variants and autogeneration apply for
379 bit operations C<"&">, C<"^">, and C<"|"> as well.
380
381 =item * I<Increment and decrement>
382
383     "++", "--",
384
385 If undefined, addition and subtraction methods can be
386 used instead.  These operations are called both in prefix and
387 postfix form.
388
389 =item * I<Transcendental functions>
390
391     "atan2", "cos", "sin", "exp", "abs", "log", "sqrt", "int"
392
393 If C<abs> is unavailable, it can be autogenerated using methods
394 for "E<lt>" or "E<lt>=E<gt>" combined with either unary minus or subtraction.
395
396 Note that traditionally the Perl function L<int> rounds to 0, thus for
397 floating-point-like types one should follow the same semantic.  If
398 C<int> is unavailable, it can be autogenerated using the overloading of
399 C<0+>.
400
401 =item * I<Boolean, string and numeric conversion>
402
403     'bool', '""', '0+',
404
405 If one or two of these operations are not overloaded, the remaining ones can
406 be used instead.  C<bool> is used in the flow control operators
407 (like C<while>) and for the ternary C<?:> operation.  These functions can
408 return any arbitrary Perl value.  If the corresponding operation for this value
409 is overloaded too, that operation will be called again with this value.
410
411 As a special case if the overload returns the object itself then it will
412 be used directly. An overloaded conversion returning the object is
413 probably a bug, because you're likely to get something that looks like
414 C<YourPackage=HASH(0x8172b34)>.
415
416 =item * I<Iteration>
417
418     "<>"
419
420 If not overloaded, the argument will be converted to a filehandle or
421 glob (which may require a stringification).  The same overloading
422 happens both for the I<read-filehandle> syntax C<E<lt>$varE<gt>> and
423 I<globbing> syntax C<E<lt>${var}E<gt>>.
424
425 B<BUGS> Even in list context, the iterator is currently called only
426 once and with scalar context.
427
428 =item * I<File tests>
429
430     "-X"
431
432 This overload is used for all the filetest operators (C<-f>, C<-x> and
433 so on: see L<perlfunc/-X> for the full list). Even though these are
434 unary operators, the method will be called with a second argument which
435 is a single letter indicating which test was performed. Note that the
436 overload key is the literal string C<"-X">: you can't provide separate
437 overloads for the different tests.
438
439 Calling an overloaded filetest operator does not affect the stat value
440 associated with the special filehandle C<_>. It still refers to the
441 result of the last C<stat>, C<lstat> or unoverloaded filetest.
442
443 If not overloaded, these operators will fall back to the default
444 behaviour even without C<< fallback => 1 >>. This means that if the
445 object is a blessed glob or blessed IO ref it will be treated as a
446 filehandle, otherwise string overloading will be invoked and the result
447 treated as a filename.
448
449 This overload was introduced in perl 5.12.
450
451 =item * I<Dereferencing>
452
453     '${}', '@{}', '%{}', '&{}', '*{}'.
454
455 If not overloaded, the argument will be dereferenced I<as is>, thus
456 should be of correct type.  These functions should return a reference
457 of correct type, or another object with overloaded dereferencing.
458
459 As a special case if the overload returns the object itself then it
460 will be used directly (provided it is the correct type).
461
462 The dereference operators must be specified explicitly they will not be passed to
463 "nomethod".
464
465 =item * I<Special>
466
467     "nomethod", "fallback", "=", "~~",
468
469 see L<SPECIAL SYMBOLS FOR C<use overload>>.
470
471 =back
472
473 See L<"Fallback"> for an explanation of when a missing method can be
474 autogenerated.
475
476 A computer-readable form of the above table is available in the hash
477 %overload::ops, with values being space-separated lists of names:
478
479  with_assign      => '+ - * / % ** << >> x .',
480  assign           => '+= -= *= /= %= **= <<= >>= x= .=',
481  num_comparison   => '< <= > >= == !=',
482  '3way_comparison'=> '<=> cmp',
483  str_comparison   => 'lt le gt ge eq ne',
484  binary           => '& &= | |= ^ ^=',
485  unary            => 'neg ! ~',
486  mutators         => '++ --',
487  func             => 'atan2 cos sin exp abs log sqrt',
488  conversion       => 'bool "" 0+',
489  iterators        => '<>',
490  filetest         => '-X',
491  dereferencing    => '${} @{} %{} &{} *{}',
492  special          => 'nomethod fallback ='
493
494 =head2 Inheritance and overloading
495
496 Inheritance interacts with overloading in two ways.
497
498 =over
499
500 =item Strings as values of C<use overload> directive
501
502 If C<value> in
503
504   use overload key => value;
505
506 is a string, it is interpreted as a method name.
507
508 =item Overloading of an operation is inherited by derived classes
509
510 Any class derived from an overloaded class is also overloaded.  The
511 set of overloaded methods is the union of overloaded methods of all
512 the ancestors. If some method is overloaded in several ancestor, then
513 which description will be used is decided by the usual inheritance
514 rules:
515
516 If C<A> inherits from C<B> and C<C> (in this order), C<B> overloads
517 C<+> with C<\&D::plus_sub>, and C<C> overloads C<+> by C<"plus_meth">,
518 then the subroutine C<D::plus_sub> will be called to implement
519 operation C<+> for an object in package C<A>.
520
521 =back
522
523 Note that since the value of the C<fallback> key is not a subroutine,
524 its inheritance is not governed by the above rules.  In the current
525 implementation, the value of C<fallback> in the first overloaded
526 ancestor is used, but this is accidental and subject to change.
527
528 =head1 SPECIAL SYMBOLS FOR C<use overload>
529
530 Three keys are recognized by Perl that are not covered by the above
531 description.
532
533 =head2 Last Resort
534
535 C<"nomethod"> should be followed by a reference to a function of four
536 parameters.  If defined, it is called when the overloading mechanism
537 cannot find a method for some operation.  The first three arguments of
538 this function coincide with the arguments for the corresponding method if
539 it were found, the fourth argument is the symbol
540 corresponding to the missing method.  If several methods are tried,
541 the last one is used.  Say, C<1-$a> can be equivalent to
542
543         &nomethodMethod($a,1,1,"-")
544
545 if the pair C<"nomethod" =E<gt> "nomethodMethod"> was specified in the
546 C<use overload> directive.
547
548 The C<"nomethod"> mechanism is I<not> used for the dereference operators
549 ( ${} @{} %{} &{} *{} ).
550
551
552 If some operation cannot be resolved, and there is no function
553 assigned to C<"nomethod">, then an exception will be raised via die()--
554 unless C<"fallback"> was specified as a key in C<use overload> directive.
555
556
557 =head2 Fallback
558
559 The key C<"fallback"> governs what to do if a method for a particular
560 operation is not found.  Three different cases are possible depending on
561 the value of C<"fallback">:
562
563 =over 16
564
565 =item * C<undef>
566
567 Perl tries to use a
568 substituted method (see L<MAGIC AUTOGENERATION>).  If this fails, it
569 then tries to calls C<"nomethod"> value; if missing, an exception
570 will be raised.
571
572 =item * TRUE
573
574 The same as for the C<undef> value, but no exception is raised.  Instead,
575 it silently reverts to what it would have done were there no C<use overload>
576 present.
577
578 =item * defined, but FALSE
579
580 No autogeneration is tried.  Perl tries to call
581 C<"nomethod"> value, and if this is missing, raises an exception.
582
583 =back
584
585 B<Note.> C<"fallback"> inheritance via @ISA is not carved in stone
586 yet, see L<"Inheritance and overloading">.
587
588 =head2 Smart Match
589
590 The key C<"~~"> allows you to override the smart matching used by
591 the switch construct. See L<feature>.
592
593 =head2 Copy Constructor
594
595 The value for C<"="> is a reference to a function with three
596 arguments, i.e., it looks like the other values in C<use
597 overload>. However, it does not overload the Perl assignment
598 operator. This would go against Camel hair.
599
600 This operation is called in the situations when a mutator is applied
601 to a reference that shares its object with some other reference, such
602 as
603
604         $a=$b;
605         ++$a;
606
607 To make this change $a and not change $b, a copy of C<$$a> is made,
608 and $a is assigned a reference to this new object.  This operation is
609 done during execution of the C<++$a>, and not during the assignment,
610 (so before the increment C<$$a> coincides with C<$$b>).  This is only
611 done if C<++> is expressed via a method for C<'++'> or C<'+='> (or
612 C<nomethod>).  Note that if this operation is expressed via C<'+'>
613 a nonmutator, i.e., as in
614
615         $a=$b;
616         $a=$a+1;
617
618 then C<$a> does not reference a new copy of C<$$a>, since $$a does not
619 appear as lvalue when the above code is executed.
620
621 If the copy constructor is required during the execution of some mutator,
622 but a method for C<'='> was not specified, it can be autogenerated as a
623 string copy if the object is a plain scalar or a simple assignment if it
624 is not.
625
626 =over 5
627
628 =item B<Example>
629
630 The actually executed code for
631
632         $a=$b;
633         Something else which does not modify $a or $b....
634         ++$a;
635
636 may be
637
638         $a=$b;
639         Something else which does not modify $a or $b....
640         $a = $a->clone(undef,"");
641         $a->incr(undef,"");
642
643 if $b was mathemagical, and C<'++'> was overloaded with C<\&incr>,
644 C<'='> was overloaded with C<\&clone>.
645
646 =back
647
648 Same behaviour is triggered by C<$b = $a++>, which is consider a synonym for
649 C<$b = $a; ++$a>.
650
651 =head1 MAGIC AUTOGENERATION
652
653 If a method for an operation is not found, and the value for  C<"fallback"> is
654 TRUE or undefined, Perl tries to autogenerate a substitute method for
655 the missing operation based on the defined operations.  Autogenerated method
656 substitutions are possible for the following operations:
657
658 =over 16
659
660 =item I<Assignment forms of arithmetic operations>
661
662 C<$a+=$b> can use the method for C<"+"> if the method for C<"+=">
663 is not defined.
664
665 =item I<Conversion operations>
666
667 String, numeric, and boolean conversion are calculated in terms of one
668 another if not all of them are defined.
669
670 =item I<Increment and decrement>
671
672 The C<++$a> operation can be expressed in terms of C<$a+=1> or C<$a+1>,
673 and C<$a--> in terms of C<$a-=1> and C<$a-1>.
674
675 =item C<abs($a)>
676
677 can be expressed in terms of C<$aE<lt>0> and C<-$a> (or C<0-$a>).
678
679 =item I<Unary minus>
680
681 can be expressed in terms of subtraction.
682
683 =item I<Negation>
684
685 C<!> and C<not> can be expressed in terms of boolean conversion, or
686 string or numerical conversion.
687
688 =item I<Concatenation>
689
690 can be expressed in terms of string conversion.
691
692 =item I<Comparison operations>
693
694 can be expressed in terms of its "spaceship" counterpart: either
695 C<E<lt>=E<gt>> or C<cmp>:
696
697     <, >, <=, >=, ==, !=        in terms of <=>
698     lt, gt, le, ge, eq, ne      in terms of cmp
699
700 =item I<Iterator>
701
702     <>                          in terms of builtin operations
703
704 =item I<Dereferencing>
705
706     ${} @{} %{} &{} *{}         in terms of builtin operations
707
708 =item I<Copy operator>
709
710 can be expressed in terms of an assignment to the dereferenced value, if this
711 value is a scalar and not a reference, or simply a reference assignment
712 otherwise.
713
714 =back
715
716 =head1 Minimal set of overloaded operations
717
718 Since some operations can be automatically generated from others, there is
719 a minimal set of operations that need to be overloaded in order to have
720 the complete set of overloaded operations at one's disposal.
721 Of course, the autogenerated operations may not do exactly what the user
722 expects. See L<MAGIC AUTOGENERATION> above. The minimal set is:
723
724     + - * / % ** << >> x
725     <=> cmp
726     & | ^ ~
727     atan2 cos sin exp log sqrt int
728
729 Additionally, you need to define at least one of string, boolean or
730 numeric conversions because any one can be used to emulate the others.
731 The string conversion can also be used to emulate concatenation.
732
733 =head1 Losing overloading
734
735 The restriction for the comparison operation is that even if, for example,
736 `C<cmp>' should return a blessed reference, the autogenerated `C<lt>'
737 function will produce only a standard logical value based on the
738 numerical value of the result of `C<cmp>'.  In particular, a working
739 numeric conversion is needed in this case (possibly expressed in terms of
740 other conversions).
741
742 Similarly, C<.=>  and C<x=> operators lose their mathemagical properties
743 if the string conversion substitution is applied.
744
745 When you chop() a mathemagical object it is promoted to a string and its
746 mathemagical properties are lost.  The same can happen with other
747 operations as well.
748
749 =head1 Run-time Overloading
750
751 Since all C<use> directives are executed at compile-time, the only way to
752 change overloading during run-time is to
753
754     eval 'use overload "+" => \&addmethod';
755
756 You can also use
757
758     eval 'no overload "+", "--", "<="';
759
760 though the use of these constructs during run-time is questionable.
761
762 =head1 Public functions
763
764 Package C<overload.pm> provides the following public functions:
765
766 =over 5
767
768 =item overload::StrVal(arg)
769
770 Gives string value of C<arg> as in absence of stringify overloading. If you
771 are using this to get the address of a reference (useful for checking if two
772 references point to the same thing) then you may be better off using
773 C<Scalar::Util::refaddr()>, which is faster.
774
775 =item overload::Overloaded(arg)
776
777 Returns true if C<arg> is subject to overloading of some operations.
778
779 =item overload::Method(obj,op)
780
781 Returns C<undef> or a reference to the method that implements C<op>.
782
783 =back
784
785 =head1 Overloading constants
786
787 For some applications, the Perl parser mangles constants too much.
788 It is possible to hook into this process via C<overload::constant()>
789 and C<overload::remove_constant()> functions.
790
791 These functions take a hash as an argument.  The recognized keys of this hash
792 are:
793
794 =over 8
795
796 =item integer
797
798 to overload integer constants,
799
800 =item float
801
802 to overload floating point constants,
803
804 =item binary
805
806 to overload octal and hexadecimal constants,
807
808 =item q
809
810 to overload C<q>-quoted strings, constant pieces of C<qq>- and C<qx>-quoted
811 strings and here-documents,
812
813 =item qr
814
815 to overload constant pieces of regular expressions.
816
817 =back
818
819 The corresponding values are references to functions which take three arguments:
820 the first one is the I<initial> string form of the constant, the second one
821 is how Perl interprets this constant, the third one is how the constant is used.
822 Note that the initial string form does not
823 contain string delimiters, and has backslashes in backslash-delimiter
824 combinations stripped (thus the value of delimiter is not relevant for
825 processing of this string).  The return value of this function is how this
826 constant is going to be interpreted by Perl.  The third argument is undefined
827 unless for overloaded C<q>- and C<qr>- constants, it is C<q> in single-quote
828 context (comes from strings, regular expressions, and single-quote HERE
829 documents), it is C<tr> for arguments of C<tr>/C<y> operators,
830 it is C<s> for right-hand side of C<s>-operator, and it is C<qq> otherwise.
831
832 Since an expression C<"ab$cd,,"> is just a shortcut for C<'ab' . $cd . ',,'>,
833 it is expected that overloaded constant strings are equipped with reasonable
834 overloaded catenation operator, otherwise absurd results will result.
835 Similarly, negative numbers are considered as negations of positive constants.
836
837 Note that it is probably meaningless to call the functions overload::constant()
838 and overload::remove_constant() from anywhere but import() and unimport() methods.
839 From these methods they may be called as
840
841         sub import {
842           shift;
843           return unless @_;
844           die "unknown import: @_" unless @_ == 1 and $_[0] eq ':constant';
845           overload::constant integer => sub {Math::BigInt->new(shift)};
846         }
847
848 =head1 IMPLEMENTATION
849
850 What follows is subject to change RSN.
851
852 The table of methods for all operations is cached in magic for the
853 symbol table hash for the package.  The cache is invalidated during
854 processing of C<use overload>, C<no overload>, new function
855 definitions, and changes in @ISA. However, this invalidation remains
856 unprocessed until the next C<bless>ing into the package. Hence if you
857 want to change overloading structure dynamically, you'll need an
858 additional (fake) C<bless>ing to update the table.
859
860 (Every SVish thing has a magic queue, and magic is an entry in that
861 queue.  This is how a single variable may participate in multiple
862 forms of magic simultaneously.  For instance, environment variables
863 regularly have two forms at once: their %ENV magic and their taint
864 magic. However, the magic which implements overloading is applied to
865 the stashes, which are rarely used directly, thus should not slow down
866 Perl.)
867
868 If an object belongs to a package using overload, it carries a special
869 flag.  Thus the only speed penalty during arithmetic operations without
870 overloading is the checking of this flag.
871
872 In fact, if C<use overload> is not present, there is almost no overhead
873 for overloadable operations, so most programs should not suffer
874 measurable performance penalties.  A considerable effort was made to
875 minimize the overhead when overload is used in some package, but the
876 arguments in question do not belong to packages using overload.  When
877 in doubt, test your speed with C<use overload> and without it.  So far
878 there have been no reports of substantial speed degradation if Perl is
879 compiled with optimization turned on.
880
881 There is no size penalty for data if overload is not used. The only
882 size penalty if overload is used in some package is that I<all> the
883 packages acquire a magic during the next C<bless>ing into the
884 package. This magic is three-words-long for packages without
885 overloading, and carries the cache table if the package is overloaded.
886
887 Copying (C<$a=$b>) is shallow; however, a one-level-deep copying is
888 carried out before any operation that can imply an assignment to the
889 object $a (or $b) refers to, like C<$a++>.  You can override this
890 behavior by defining your own copy constructor (see L<"Copy Constructor">).
891
892 It is expected that arguments to methods that are not explicitly supposed
893 to be changed are constant (but this is not enforced).
894
895 =head1 Metaphor clash
896
897 One may wonder why the semantic of overloaded C<=> is so counter intuitive.
898 If it I<looks> counter intuitive to you, you are subject to a metaphor
899 clash.
900
901 Here is a Perl object metaphor:
902
903 I<  object is a reference to blessed data>
904
905 and an arithmetic metaphor:
906
907 I<  object is a thing by itself>.
908
909 The I<main> problem of overloading C<=> is the fact that these metaphors
910 imply different actions on the assignment C<$a = $b> if $a and $b are
911 objects.  Perl-think implies that $a becomes a reference to whatever
912 $b was referencing.  Arithmetic-think implies that the value of "object"
913 $a is changed to become the value of the object $b, preserving the fact
914 that $a and $b are separate entities.
915
916 The difference is not relevant in the absence of mutators.  After
917 a Perl-way assignment an operation which mutates the data referenced by $a
918 would change the data referenced by $b too.  Effectively, after
919 C<$a = $b> values of $a and $b become I<indistinguishable>.
920
921 On the other hand, anyone who has used algebraic notation knows the
922 expressive power of the arithmetic metaphor.  Overloading works hard
923 to enable this metaphor while preserving the Perlian way as far as
924 possible.  Since it is not possible to freely mix two contradicting
925 metaphors, overloading allows the arithmetic way to write things I<as
926 far as all the mutators are called via overloaded access only>.  The
927 way it is done is described in L<Copy Constructor>.
928
929 If some mutator methods are directly applied to the overloaded values,
930 one may need to I<explicitly unlink> other values which references the
931 same value:
932
933     $a = Data->new(23);
934     ...
935     $b = $a;            # $b is "linked" to $a
936     ...
937     $a = $a->clone;     # Unlink $b from $a
938     $a->increment_by(4);
939
940 Note that overloaded access makes this transparent:
941
942     $a = Data->new(23);
943     $b = $a;            # $b is "linked" to $a
944     $a += 4;            # would unlink $b automagically
945
946 However, it would not make
947
948     $a = Data->new(23);
949     $a = 4;             # Now $a is a plain 4, not 'Data'
950
951 preserve "objectness" of $a.  But Perl I<has> a way to make assignments
952 to an object do whatever you want.  It is just not the overload, but
953 tie()ing interface (see L<perlfunc/tie>).  Adding a FETCH() method
954 which returns the object itself, and STORE() method which changes the
955 value of the object, one can reproduce the arithmetic metaphor in its
956 completeness, at least for variables which were tie()d from the start.
957
958 (Note that a workaround for a bug may be needed, see L<"BUGS">.)
959
960 =head1 Cookbook
961
962 Please add examples to what follows!
963
964 =head2 Two-face scalars
965
966 Put this in F<two_face.pm> in your Perl library directory:
967
968   package two_face;             # Scalars with separate string and
969                                 # numeric values.
970   sub new { my $p = shift; bless [@_], $p }
971   use overload '""' => \&str, '0+' => \&num, fallback => 1;
972   sub num {shift->[1]}
973   sub str {shift->[0]}
974
975 Use it as follows:
976
977   require two_face;
978   my $seven = two_face->new("vii", 7);
979   printf "seven=$seven, seven=%d, eight=%d\n", $seven, $seven+1;
980   print "seven contains `i'\n" if $seven =~ /i/;
981
982 (The second line creates a scalar which has both a string value, and a
983 numeric value.)  This prints:
984
985   seven=vii, seven=7, eight=8
986   seven contains `i'
987
988 =head2 Two-face references
989
990 Suppose you want to create an object which is accessible as both an
991 array reference and a hash reference.
992
993   package two_refs;
994   use overload '%{}' => \&gethash, '@{}' => sub { $ {shift()} };
995   sub new {
996     my $p = shift;
997     bless \ [@_], $p;
998   }
999   sub gethash {
1000     my %h;
1001     my $self = shift;
1002     tie %h, ref $self, $self;
1003     \%h;
1004   }
1005
1006   sub TIEHASH { my $p = shift; bless \ shift, $p }
1007   my %fields;
1008   my $i = 0;
1009   $fields{$_} = $i++ foreach qw{zero one two three};
1010   sub STORE {
1011     my $self = ${shift()};
1012     my $key = $fields{shift()};
1013     defined $key or die "Out of band access";
1014     $$self->[$key] = shift;
1015   }
1016   sub FETCH {
1017     my $self = ${shift()};
1018     my $key = $fields{shift()};
1019     defined $key or die "Out of band access";
1020     $$self->[$key];
1021   }
1022
1023 Now one can access an object using both the array and hash syntax:
1024
1025   my $bar = two_refs->new(3,4,5,6);
1026   $bar->[2] = 11;
1027   $bar->{two} == 11 or die 'bad hash fetch';
1028
1029 Note several important features of this example.  First of all, the
1030 I<actual> type of $bar is a scalar reference, and we do not overload
1031 the scalar dereference.  Thus we can get the I<actual> non-overloaded
1032 contents of $bar by just using C<$$bar> (what we do in functions which
1033 overload dereference).  Similarly, the object returned by the
1034 TIEHASH() method is a scalar reference.
1035
1036 Second, we create a new tied hash each time the hash syntax is used.
1037 This allows us not to worry about a possibility of a reference loop,
1038 which would lead to a memory leak.
1039
1040 Both these problems can be cured.  Say, if we want to overload hash
1041 dereference on a reference to an object which is I<implemented> as a
1042 hash itself, the only problem one has to circumvent is how to access
1043 this I<actual> hash (as opposed to the I<virtual> hash exhibited by the
1044 overloaded dereference operator).  Here is one possible fetching routine:
1045
1046   sub access_hash {
1047     my ($self, $key) = (shift, shift);
1048     my $class = ref $self;
1049     bless $self, 'overload::dummy'; # Disable overloading of %{}
1050     my $out = $self->{$key};
1051     bless $self, $class;        # Restore overloading
1052     $out;
1053   }
1054
1055 To remove creation of the tied hash on each access, one may an extra
1056 level of indirection which allows a non-circular structure of references:
1057
1058   package two_refs1;
1059   use overload '%{}' => sub { ${shift()}->[1] },
1060                '@{}' => sub { ${shift()}->[0] };
1061   sub new {
1062     my $p = shift;
1063     my $a = [@_];
1064     my %h;
1065     tie %h, $p, $a;
1066     bless \ [$a, \%h], $p;
1067   }
1068   sub gethash {
1069     my %h;
1070     my $self = shift;
1071     tie %h, ref $self, $self;
1072     \%h;
1073   }
1074
1075   sub TIEHASH { my $p = shift; bless \ shift, $p }
1076   my %fields;
1077   my $i = 0;
1078   $fields{$_} = $i++ foreach qw{zero one two three};
1079   sub STORE {
1080     my $a = ${shift()};
1081     my $key = $fields{shift()};
1082     defined $key or die "Out of band access";
1083     $a->[$key] = shift;
1084   }
1085   sub FETCH {
1086     my $a = ${shift()};
1087     my $key = $fields{shift()};
1088     defined $key or die "Out of band access";
1089     $a->[$key];
1090   }
1091
1092 Now if $baz is overloaded like this, then C<$baz> is a reference to a
1093 reference to the intermediate array, which keeps a reference to an
1094 actual array, and the access hash.  The tie()ing object for the access
1095 hash is a reference to a reference to the actual array, so
1096
1097 =over
1098
1099 =item *
1100
1101 There are no loops of references.
1102
1103 =item *
1104
1105 Both "objects" which are blessed into the class C<two_refs1> are
1106 references to a reference to an array, thus references to a I<scalar>.
1107 Thus the accessor expression C<$$foo-E<gt>[$ind]> involves no
1108 overloaded operations.
1109
1110 =back
1111
1112 =head2 Symbolic calculator
1113
1114 Put this in F<symbolic.pm> in your Perl library directory:
1115
1116   package symbolic;             # Primitive symbolic calculator
1117   use overload nomethod => \&wrap;
1118
1119   sub new { shift; bless ['n', @_] }
1120   sub wrap {
1121     my ($obj, $other, $inv, $meth) = @_;
1122     ($obj, $other) = ($other, $obj) if $inv;
1123     bless [$meth, $obj, $other];
1124   }
1125
1126 This module is very unusual as overloaded modules go: it does not
1127 provide any usual overloaded operators, instead it provides the L<Last
1128 Resort> operator C<nomethod>.  In this example the corresponding
1129 subroutine returns an object which encapsulates operations done over
1130 the objects: C<< symbolic->new(3) >> contains C<['n', 3]>, C<< 2 +
1131 symbolic->new(3) >> contains C<['+', 2, ['n', 3]]>.
1132
1133 Here is an example of the script which "calculates" the side of
1134 circumscribed octagon using the above package:
1135
1136   require symbolic;
1137   my $iter = 1;                 # 2**($iter+2) = 8
1138   my $side = symbolic->new(1);
1139   my $cnt = $iter;
1140
1141   while ($cnt--) {
1142     $side = (sqrt(1 + $side**2) - 1)/$side;
1143   }
1144   print "OK\n";
1145
1146 The value of $side is
1147
1148   ['/', ['-', ['sqrt', ['+', 1, ['**', ['n', 1], 2]],
1149                        undef], 1], ['n', 1]]
1150
1151 Note that while we obtained this value using a nice little script,
1152 there is no simple way to I<use> this value.  In fact this value may
1153 be inspected in debugger (see L<perldebug>), but only if
1154 C<bareStringify> B<O>ption is set, and not via C<p> command.
1155
1156 If one attempts to print this value, then the overloaded operator
1157 C<""> will be called, which will call C<nomethod> operator.  The
1158 result of this operator will be stringified again, but this result is
1159 again of type C<symbolic>, which will lead to an infinite loop.
1160
1161 Add a pretty-printer method to the module F<symbolic.pm>:
1162
1163   sub pretty {
1164     my ($meth, $a, $b) = @{+shift};
1165     $a = 'u' unless defined $a;
1166     $b = 'u' unless defined $b;
1167     $a = $a->pretty if ref $a;
1168     $b = $b->pretty if ref $b;
1169     "[$meth $a $b]";
1170   }
1171
1172 Now one can finish the script by
1173
1174   print "side = ", $side->pretty, "\n";
1175
1176 The method C<pretty> is doing object-to-string conversion, so it
1177 is natural to overload the operator C<""> using this method.  However,
1178 inside such a method it is not necessary to pretty-print the
1179 I<components> $a and $b of an object.  In the above subroutine
1180 C<"[$meth $a $b]"> is a catenation of some strings and components $a
1181 and $b.  If these components use overloading, the catenation operator
1182 will look for an overloaded operator C<.>; if not present, it will
1183 look for an overloaded operator C<"">.  Thus it is enough to use
1184
1185   use overload nomethod => \&wrap, '""' => \&str;
1186   sub str {
1187     my ($meth, $a, $b) = @{+shift};
1188     $a = 'u' unless defined $a;
1189     $b = 'u' unless defined $b;
1190     "[$meth $a $b]";
1191   }
1192
1193 Now one can change the last line of the script to
1194
1195   print "side = $side\n";
1196
1197 which outputs
1198
1199   side = [/ [- [sqrt [+ 1 [** [n 1 u] 2]] u] 1] [n 1 u]]
1200
1201 and one can inspect the value in debugger using all the possible
1202 methods.
1203
1204 Something is still amiss: consider the loop variable $cnt of the
1205 script.  It was a number, not an object.  We cannot make this value of
1206 type C<symbolic>, since then the loop will not terminate.
1207
1208 Indeed, to terminate the cycle, the $cnt should become false.
1209 However, the operator C<bool> for checking falsity is overloaded (this
1210 time via overloaded C<"">), and returns a long string, thus any object
1211 of type C<symbolic> is true.  To overcome this, we need a way to
1212 compare an object to 0.  In fact, it is easier to write a numeric
1213 conversion routine.
1214
1215 Here is the text of F<symbolic.pm> with such a routine added (and
1216 slightly modified str()):
1217
1218   package symbolic;             # Primitive symbolic calculator
1219   use overload
1220     nomethod => \&wrap, '""' => \&str, '0+' => \&num;
1221
1222   sub new { shift; bless ['n', @_] }
1223   sub wrap {
1224     my ($obj, $other, $inv, $meth) = @_;
1225     ($obj, $other) = ($other, $obj) if $inv;
1226     bless [$meth, $obj, $other];
1227   }
1228   sub str {
1229     my ($meth, $a, $b) = @{+shift};
1230     $a = 'u' unless defined $a;
1231     if (defined $b) {
1232       "[$meth $a $b]";
1233     } else {
1234       "[$meth $a]";
1235     }
1236   }
1237   my %subr = ( n => sub {$_[0]},
1238                sqrt => sub {sqrt $_[0]},
1239                '-' => sub {shift() - shift()},
1240                '+' => sub {shift() + shift()},
1241                '/' => sub {shift() / shift()},
1242                '*' => sub {shift() * shift()},
1243                '**' => sub {shift() ** shift()},
1244              );
1245   sub num {
1246     my ($meth, $a, $b) = @{+shift};
1247     my $subr = $subr{$meth}
1248       or die "Do not know how to ($meth) in symbolic";
1249     $a = $a->num if ref $a eq __PACKAGE__;
1250     $b = $b->num if ref $b eq __PACKAGE__;
1251     $subr->($a,$b);
1252   }
1253
1254 All the work of numeric conversion is done in %subr and num().  Of
1255 course, %subr is not complete, it contains only operators used in the
1256 example below.  Here is the extra-credit question: why do we need an
1257 explicit recursion in num()?  (Answer is at the end of this section.)
1258
1259 Use this module like this:
1260
1261   require symbolic;
1262   my $iter = symbolic->new(2);  # 16-gon
1263   my $side = symbolic->new(1);
1264   my $cnt = $iter;
1265
1266   while ($cnt) {
1267     $cnt = $cnt - 1;            # Mutator `--' not implemented
1268     $side = (sqrt(1 + $side**2) - 1)/$side;
1269   }
1270   printf "%s=%f\n", $side, $side;
1271   printf "pi=%f\n", $side*(2**($iter+2));
1272
1273 It prints (without so many line breaks)
1274
1275   [/ [- [sqrt [+ 1 [** [/ [- [sqrt [+ 1 [** [n 1] 2]]] 1]
1276                           [n 1]] 2]]] 1]
1277      [/ [- [sqrt [+ 1 [** [n 1] 2]]] 1] [n 1]]]=0.198912
1278   pi=3.182598
1279
1280 The above module is very primitive.  It does not implement
1281 mutator methods (C<++>, C<-=> and so on), does not do deep copying
1282 (not required without mutators!), and implements only those arithmetic
1283 operations which are used in the example.
1284
1285 To implement most arithmetic operations is easy; one should just use
1286 the tables of operations, and change the code which fills %subr to
1287
1288   my %subr = ( 'n' => sub {$_[0]} );
1289   foreach my $op (split " ", $overload::ops{with_assign}) {
1290     $subr{$op} = $subr{"$op="} = eval "sub {shift() $op shift()}";
1291   }
1292   my @bins = qw(binary 3way_comparison num_comparison str_comparison);
1293   foreach my $op (split " ", "@overload::ops{ @bins }") {
1294     $subr{$op} = eval "sub {shift() $op shift()}";
1295   }
1296   foreach my $op (split " ", "@overload::ops{qw(unary func)}") {
1297     print "defining `$op'\n";
1298     $subr{$op} = eval "sub {$op shift()}";
1299   }
1300
1301 Due to L<Calling Conventions for Mutators>, we do not need anything
1302 special to make C<+=> and friends work, except filling C<+=> entry of
1303 %subr, and defining a copy constructor (needed since Perl has no
1304 way to know that the implementation of C<'+='> does not mutate
1305 the argument, compare L<Copy Constructor>).
1306
1307 To implement a copy constructor, add C<< '=' => \&cpy >> to C<use overload>
1308 line, and code (this code assumes that mutators change things one level
1309 deep only, so recursive copying is not needed):
1310
1311   sub cpy {
1312     my $self = shift;
1313     bless [@$self], ref $self;
1314   }
1315
1316 To make C<++> and C<--> work, we need to implement actual mutators,
1317 either directly, or in C<nomethod>.  We continue to do things inside
1318 C<nomethod>, thus add
1319
1320     if ($meth eq '++' or $meth eq '--') {
1321       @$obj = ($meth, (bless [@$obj]), 1); # Avoid circular reference
1322       return $obj;
1323     }
1324
1325 after the first line of wrap().  This is not a most effective
1326 implementation, one may consider
1327
1328   sub inc { $_[0] = bless ['++', shift, 1]; }
1329
1330 instead.
1331
1332 As a final remark, note that one can fill %subr by
1333
1334   my %subr = ( 'n' => sub {$_[0]} );
1335   foreach my $op (split " ", $overload::ops{with_assign}) {
1336     $subr{$op} = $subr{"$op="} = eval "sub {shift() $op shift()}";
1337   }
1338   my @bins = qw(binary 3way_comparison num_comparison str_comparison);
1339   foreach my $op (split " ", "@overload::ops{ @bins }") {
1340     $subr{$op} = eval "sub {shift() $op shift()}";
1341   }
1342   foreach my $op (split " ", "@overload::ops{qw(unary func)}") {
1343     $subr{$op} = eval "sub {$op shift()}";
1344   }
1345   $subr{'++'} = $subr{'+'};
1346   $subr{'--'} = $subr{'-'};
1347
1348 This finishes implementation of a primitive symbolic calculator in
1349 50 lines of Perl code.  Since the numeric values of subexpressions
1350 are not cached, the calculator is very slow.
1351
1352 Here is the answer for the exercise: In the case of str(), we need no
1353 explicit recursion since the overloaded C<.>-operator will fall back
1354 to an existing overloaded operator C<"">.  Overloaded arithmetic
1355 operators I<do not> fall back to numeric conversion if C<fallback> is
1356 not explicitly requested.  Thus without an explicit recursion num()
1357 would convert C<['+', $a, $b]> to C<$a + $b>, which would just rebuild
1358 the argument of num().
1359
1360 If you wonder why defaults for conversion are different for str() and
1361 num(), note how easy it was to write the symbolic calculator.  This
1362 simplicity is due to an appropriate choice of defaults.  One extra
1363 note: due to the explicit recursion num() is more fragile than sym():
1364 we need to explicitly check for the type of $a and $b.  If components
1365 $a and $b happen to be of some related type, this may lead to problems.
1366
1367 =head2 I<Really> symbolic calculator
1368
1369 One may wonder why we call the above calculator symbolic.  The reason
1370 is that the actual calculation of the value of expression is postponed
1371 until the value is I<used>.
1372
1373 To see it in action, add a method
1374
1375   sub STORE {
1376     my $obj = shift;
1377     $#$obj = 1;
1378     @$obj->[0,1] = ('=', shift);
1379   }
1380
1381 to the package C<symbolic>.  After this change one can do
1382
1383   my $a = symbolic->new(3);
1384   my $b = symbolic->new(4);
1385   my $c = sqrt($a**2 + $b**2);
1386
1387 and the numeric value of $c becomes 5.  However, after calling
1388
1389   $a->STORE(12);  $b->STORE(5);
1390
1391 the numeric value of $c becomes 13.  There is no doubt now that the module
1392 symbolic provides a I<symbolic> calculator indeed.
1393
1394 To hide the rough edges under the hood, provide a tie()d interface to the
1395 package C<symbolic> (compare with L<Metaphor clash>).  Add methods
1396
1397   sub TIESCALAR { my $pack = shift; $pack->new(@_) }
1398   sub FETCH { shift }
1399   sub nop {  }          # Around a bug
1400
1401 (the bug is described in L<"BUGS">).  One can use this new interface as
1402
1403   tie $a, 'symbolic', 3;
1404   tie $b, 'symbolic', 4;
1405   $a->nop;  $b->nop;    # Around a bug
1406
1407   my $c = sqrt($a**2 + $b**2);
1408
1409 Now numeric value of $c is 5.  After C<$a = 12; $b = 5> the numeric value
1410 of $c becomes 13.  To insulate the user of the module add a method
1411
1412   sub vars { my $p = shift; tie($_, $p), $_->nop foreach @_; }
1413
1414 Now
1415
1416   my ($a, $b);
1417   symbolic->vars($a, $b);
1418   my $c = sqrt($a**2 + $b**2);
1419
1420   $a = 3; $b = 4;
1421   printf "c5  %s=%f\n", $c, $c;
1422
1423   $a = 12; $b = 5;
1424   printf "c13  %s=%f\n", $c, $c;
1425
1426 shows that the numeric value of $c follows changes to the values of $a
1427 and $b.
1428
1429 =head1 AUTHOR
1430
1431 Ilya Zakharevich E<lt>F<ilya@math.mps.ohio-state.edu>E<gt>.
1432
1433 =head1 SEE ALSO
1434
1435 The L<overloading> pragma can be used to enable or disable overloaded
1436 operations within a lexical scope.
1437
1438 =head1 DIAGNOSTICS
1439
1440 When Perl is run with the B<-Do> switch or its equivalent, overloading
1441 induces diagnostic messages.
1442
1443 Using the C<m> command of Perl debugger (see L<perldebug>) one can
1444 deduce which operations are overloaded (and which ancestor triggers
1445 this overloading). Say, if C<eq> is overloaded, then the method C<(eq>
1446 is shown by debugger. The method C<()> corresponds to the C<fallback>
1447 key (in fact a presence of this method shows that this package has
1448 overloading enabled, and it is what is used by the C<Overloaded>
1449 function of module C<overload>).
1450
1451 The module might issue the following warnings:
1452
1453 =over 4
1454
1455 =item Odd number of arguments for overload::constant
1456
1457 (W) The call to overload::constant contained an odd number of arguments.
1458 The arguments should come in pairs.
1459
1460 =item `%s' is not an overloadable type
1461
1462 (W) You tried to overload a constant type the overload package is unaware of.
1463
1464 =item `%s' is not a code reference
1465
1466 (W) The second (fourth, sixth, ...) argument of overload::constant needs
1467 to be a code reference. Either an anonymous subroutine, or a reference
1468 to a subroutine.
1469
1470 =back
1471
1472 =head1 BUGS
1473
1474 Because it is used for overloading, the per-package hash %OVERLOAD now
1475 has a special meaning in Perl. The symbol table is filled with names
1476 looking like line-noise.
1477
1478 For the purpose of inheritance every overloaded package behaves as if
1479 C<fallback> is present (possibly undefined). This may create
1480 interesting effects if some package is not overloaded, but inherits
1481 from two overloaded packages.
1482
1483 Relation between overloading and tie()ing is broken.  Overloading is
1484 triggered or not basing on the I<previous> class of tie()d value.
1485
1486 This happens because the presence of overloading is checked too early,
1487 before any tie()d access is attempted.  If the FETCH()ed class of the
1488 tie()d value does not change, a simple workaround is to access the value
1489 immediately after tie()ing, so that after this call the I<previous> class
1490 coincides with the current one.
1491
1492 B<Needed:> a way to fix this without a speed penalty.
1493
1494 Barewords are not covered by overloaded string constants.
1495
1496 This document is confusing.  There are grammos and misleading language
1497 used in places.  It would seem a total rewrite is needed.
1498
1499 =cut
1500