Move Pod::Simple from ext/ to cpan/
[perl.git] / t / TEST
1 #!./perl
2
3 # This is written in a peculiar style, since we're trying to avoid
4 # most of the constructs we'll be testing for.  (This comment is
5 # probably obsolete on the avoidance side, though still currrent
6 # on the peculiarity side.)
7
8 # t/TEST and t/harness need to share code. The logical way to do this would be
9 # to have the common code in a file both require or use. However, t/TEST needs
10 # to still work, to generate test results, even if require isn't working, so
11 # we cannot do that. t/harness has no such restriction, so it is quite
12 # acceptable to have it require t/TEST.
13
14 # In which case, we need to stop t/TEST actually running tests, as all
15 # t/harness needs are its subroutines.
16
17
18 # directories with special sets of test switches
19 my %dir_to_switch =
20     (base => '',
21      comp => '',
22      run => '',
23      '../ext/File-Glob/t' => '-I.. -MTestInit', # FIXME - tests assume t/
24      );
25
26 # I think in the end I'd like "not absolute" to be the default", as it saves
27 # some fakery within TestInit which can peturb tests, and takes CPU.
28 my %no_abs =
29     ('../cpan/Pod-Parser' => 1,
30     );
31               
32 my %temp_no_core =
33     ('../cpan/B-Debug' => 1,
34      '../cpan/Compress-Raw-Bzip2' => 1,
35      '../cpan/Compress-Raw-Zlib' => 1,
36      '../cpan/Devel-PPPort' => 1,
37      '../cpan/Getopt-Long' => 1,
38      '../cpan/IO-Compress' => 1,
39      '../cpan/Math-BigInt' => 1,
40      '../cpan/Math-BigRat' => 1,
41      '../cpan/MIME-Base64' => 1,
42      '../cpan/NEXT' => 1,
43      '../cpan/parent' => 1,
44      '../cpan/Parse-CPAN-Meta' => 1,
45      '../cpan/Pod-Simple' => 1,
46      '../cpan/podlators' => 1,
47      '../ext/Test-Simple' => 1,
48      '../cpan/Tie-RefHash' => 1,
49      '../ext/Time-HiRes' => 1,
50      '../cpan/Unicode-Collate' => 1,
51      '../cpan/Unicode-Normalize' => 1,
52     );
53
54 if ($::do_nothing) {
55     return 1;
56 }
57
58 # Location to put the Valgrind log.
59 my $Valgrind_Log = 'current.valgrind';
60
61 $| = 1;
62
63 # for testing TEST only
64 #BEGIN { require '../lib/strict.pm'; "strict"->import() };
65 #BEGIN { require '../lib/warnings.pm'; "warnings"->import() };
66
67 delete $ENV{PERL5LIB};
68 delete $ENV{PERLLIB};
69 delete $ENV{PERL5OPT};
70
71 # remove empty elements due to insertion of empty symbols via "''p1'" syntax
72 @ARGV = grep($_,@ARGV) if $^O eq 'VMS';
73 our $show_elapsed_time = $ENV{HARNESS_TIMER} || 0;
74
75 # Cheesy version of Getopt::Std.  We can't replace it with that, because we
76 # can't rely on require working.
77 {
78     my @argv = ();
79     foreach my $idx (0..$#ARGV) {
80         push( @argv, $ARGV[$idx] ), next unless $ARGV[$idx] =~ /^-(\S+)$/;
81         $::benchmark = 1 if $1 eq 'benchmark';
82         $::core    = 1 if $1 eq 'core';
83         $::verbose = 1 if $1 eq 'v';
84         $::torture = 1 if $1 eq 'torture';
85         $::with_utf8 = 1 if $1 eq 'utf8';
86         $::with_utf16 = 1 if $1 eq 'utf16';
87         $::taintwarn = 1 if $1 eq 'taintwarn';
88         $ENV{PERL_CORE_MINITEST} = 1 if $1 eq 'minitest';
89         if ($1 =~ /^deparse(,.+)?$/) {
90             $::deparse = 1;
91             $::deparse_opts = $1;
92         }
93     }
94     @ARGV = @argv;
95 }
96
97 chdir 't' if -f 't/TEST';
98 if (-f 'TEST' && -f 'harness' && -d '../lib') {
99     @INC = '../lib';
100 }
101
102 die "You need to run \"make test\" first to set things up.\n"
103   unless -e 'perl' or -e 'perl.exe' or -e 'perl.pm';
104
105 if ($ENV{PERL_3LOG}) { # Tru64 third(1) tool, see perlhack
106     unless (-x 'perl.third') {
107         unless (-x '../perl.third') {
108             die "You need to run \"make perl.third first.\n";
109         }
110         else {
111             print "Symlinking ../perl.third as perl.third...\n";
112             die "Failed to symlink: $!\n"
113                 unless symlink("../perl.third", "perl.third");
114             die "Symlinked but no executable perl.third: $!\n"
115                 unless -x 'perl.third';
116         }
117     }
118 }
119
120 # check leakage for embedders
121 $ENV{PERL_DESTRUCT_LEVEL} = 2 unless exists $ENV{PERL_DESTRUCT_LEVEL};
122
123 $ENV{EMXSHELL} = 'sh';        # For OS/2
124
125 if ($show_elapsed_time) { require Time::HiRes }
126
127 my %skip = (
128             '.' => 1,
129             '..' => 1,
130             'CVS' => 1,
131             'RCS' => 1,
132             'SCCS' => 1,
133             '.svn' => 1,
134            );
135
136 # Roll your own File::Find!
137 sub _find_tests {
138     my($dir) = @_;
139     opendir DIR, $dir or die "Trouble opening $dir: $!";
140     foreach my $f (sort { $a cmp $b } readdir DIR) {
141         next if $skip{$f};
142
143         my $fullpath = "$dir/$f";
144
145         if (-d $fullpath) {
146             _find_tests($fullpath);
147         } elsif ($f =~ /\.t$/) {
148             push @ARGV, $fullpath;
149         }
150     }
151 }
152
153
154 # Scan the text of the test program to find switches and special options
155 # we might need to apply.
156 sub _scan_test {
157     my($test, $type) = @_;
158
159     open(my $script, "<", $test) or die "Can't read $test.\n";
160     my $first_line = <$script>;
161
162     $first_line =~ tr/\0//d if $::with_utf16;
163
164     my $switch = "";
165     if ($first_line =~ /#!.*\bperl.*\s-\w*([tT])/) {
166         $switch = "-$1";
167     } else {
168         if ($::taintwarn) {
169             # not all tests are expected to pass with this option
170             $switch = '-t';
171         } else {
172             $switch = '';
173         }
174     }
175
176     my $file_opts = "";
177     if ($type eq 'deparse') {
178         # Look for #line directives which change the filename
179         while (<$script>) {
180             $file_opts .= ",-f$3$4"
181               if /^#\s*line\s+(\d+)\s+((\w+)|"([^"]+)")/;
182         }
183     }
184
185     close $script;
186
187     my $perl = './perl';
188     my $lib  = '../lib';
189     my $run_dir;
190     my $return_dir;
191
192     $test =~ /^(.+)\/[^\/]+/;
193     my $dir = $1;
194     my $testswitch = $dir_to_switch{$dir};
195     if (!defined $testswitch) {
196         if ($test =~ s!^(\.\./(?:cpan|dist|ext)/[^/]+)/t!t!) {
197             $run_dir = $1;
198             $return_dir = '../../t';
199             $lib = '../../lib';
200             $perl = '../../t/perl';
201             $testswitch = "-I../.. -MTestInit=U2T";
202             if (!$no_abs{$run_dir}) {
203                 $testswitch = $testswitch . ',A';
204             }
205             if ($temp_no_core{$run_dir}) {
206                 $testswitch = $testswitch . ',NC';
207             }
208         } else {
209             $testswitch = '-I.. -MTestInit';  # -T will remove . from @INC
210         }
211     }
212
213     my $utf8 = $::with_utf8 ? "-I$lib -Mutf8" : '';
214
215     my %options = (
216         perl => $perl,
217         lib => $lib,
218         test => $test,
219         run_dir => $run_dir,
220         return_dir => $return_dir,
221         testswitch => $testswitch,
222         utf8 => $utf8,
223         file => $file_opts,
224         switch => $switch,
225     );
226
227     return \%options;
228 }
229
230 sub _cmd {
231     my($options, $type) = @_;
232
233     my $test = $options->{test};
234
235     my $cmd;
236     if ($type eq 'deparse') {
237         my $perl = "$options->{perl} $options->{testswitch}";
238         my $lib = $options->{lib};
239
240         $cmd = (
241           "$perl $options->{switch} -I$lib -MO=-qq,Deparse,-sv1.,".
242           "-l$::deparse_opts$options->{file} ".
243           "$test > $test.dp ".
244           "&& $perl $options->{switch} -I$lib $test.dp"
245         );
246     }
247     elsif ($type eq 'perl') {
248         my $perl = $options->{perl};
249         my $redir = $^O eq 'VMS' ? '2>&1' : '';
250
251         if ($ENV{PERL_VALGRIND}) {
252             my $valgrind = $ENV{VALGRIND} // 'valgrind';
253             my $vg_opts = $ENV{VG_OPTS}
254               //  "--suppressions=perl.supp --leak-check=yes "
255                 . "--leak-resolution=high --show-reachable=yes "
256                   . "--num-callers=50";
257             $perl = "$valgrind --log-fd=3 $vg_opts $perl";
258             $redir = "3>$Valgrind_Log";
259         }
260
261         my $args = "$options->{testswitch} $options->{switch} $options->{utf8}";
262         $cmd = $perl . _quote_args($args) . " $test $redir";
263     }
264
265     return $cmd;
266 }
267
268 sub _before_fork {
269     my ($options) = @_;
270
271     if ($options->{run_dir}) {
272         my $run_dir = $options->{run_dir};
273         chdir $run_dir or die "Can't chdir to '$run_dir': $!";
274     }
275
276     return;
277 }
278
279 sub _after_fork {
280     my ($options) = @_;
281
282     if ($options->{return_dir}) {
283         my $return_dir = $options->{return_dir};
284         chdir $return_dir
285            or die "Can't chdir from '$options->{run_dir}' to '$return_dir': $!";
286     }
287
288     return;
289 }
290
291 sub _run_test {
292     my ($test, $type) = @_;
293
294     my $options = _scan_test($test, $type);
295     # $test might have changed if we're in ext/Foo, so don't use it anymore
296     # from now on. Use $options->{test} instead.
297
298     _before_fork($options);
299
300     my $cmd = _cmd($options, $type);
301
302     open(my $results, "$cmd |") or print "can't run '$cmd': $!.\n";
303
304     _after_fork($options);
305
306     # Our environment may force us to use UTF-8, but we can't be sure that
307     # anything we're reading from will be generating (well formed) UTF-8
308     # This may not be the best way - possibly we should unset ${^OPEN} up
309     # top?
310     binmode $results;
311
312     return $results;
313 }
314
315 sub _quote_args {
316     my ($args) = @_;
317     my $argstring = '';
318
319     foreach (split(/\s+/,$args)) {
320        # In VMS protect with doublequotes because otherwise
321        # DCL will lowercase -- unless already doublequoted.
322        $_ = q(").$_.q(") if ($^O eq 'VMS') && !/^\"/ && length($_) > 0;
323        $argstring .= ' ' . $_;
324     }
325     return $argstring;
326 }
327
328 sub _populate_hash {
329     return unless defined $_[0];
330     return map {$_, 1} split /\s+/, $_[0];
331 }
332
333 sub _tests_from_manifest {
334     my ($extensions, $known_extensions) = @_;
335     my %skip;
336     my %extensions = _populate_hash($extensions);
337     my %known_extensions = _populate_hash($known_extensions);
338
339     foreach (keys %known_extensions) {
340         $skip{$_}++ unless $extensions{$_};
341     }
342
343     my @results;
344     my $mani = '../MANIFEST';
345     if (open(MANI, $mani)) {
346         while (<MANI>) {
347             if (m!^((?:cpan|dist|ext)/(\S+)/+(?:[^/\s]+\.t|test\.pl)|lib/\S+?(?:\.t|test\.pl))\s!) {
348                 my $t = $1;
349                 my $extension = $2;
350                 if (!$::core || $t =~ m!^lib/[a-z]!) {
351                     if (defined $extension) {
352                         $extension =~ s!/t$!!;
353                         # XXX Do I want to warn that I'm skipping these?
354                         next if $skip{$extension};
355                         my $flat_extension = $extension;
356                         $flat_extension =~ s!-!/!g;
357                         next if $skip{$flat_extension}; # Foo/Bar may live in Foo-Bar
358                     }
359                     my $path = "../$t";
360                     push @results, $path;
361                     $::path_to_name{$path} = $t;
362                 }
363             }
364         }
365         close MANI;
366     } else {
367         warn "$0: cannot open $mani: $!\n";
368     }
369     return @results;
370 }
371
372 unless (@ARGV) {
373     # base first, as TEST bails out if that can't run
374     # then comp, to validate that require works
375     # then run, to validate that -M works
376     # then we know we can -MTestInit for everything else, making life simpler
377     foreach my $dir (qw(base comp run cmd io re op uni mro)) {
378         _find_tests($dir);
379     }
380     _find_tests("lib") unless $::core;
381     # Config.pm may be broken for make minitest. And this is only a refinement
382     # for skipping tests on non-default builds, so it is allowed to fail.
383     # What we want to to is make a list of extensions which we did not build.
384     my $configsh = '../config.sh';
385     my ($extensions, $known_extensions);
386     if (-f $configsh) {
387         open FH, $configsh or die "Can't open $configsh: $!";
388         while (<FH>) {
389             if (/^extensions=['"](.*)['"]$/) {
390                 $extensions = $1;
391             }
392             elsif (/^known_extensions=['"](.*)['"]$/) {
393                 $known_extensions = $1;
394             }
395         }
396         if (!defined $known_extensions) {
397             warn "No known_extensions line found in $configsh";
398         }
399         if (!defined $extensions) {
400             warn "No extensions line found in $configsh";
401         }
402     }
403     # The "complex" constructions of list return from a subroutine, and push of
404     # a list, might fail if perl is really hosed, but they aren't needed for
405     # make minitest, and the building of extensions will likely also fail if
406     # something is that badly wrong.
407     push @ARGV, _tests_from_manifest($extensions, $known_extensions);
408     unless ($::core) {
409         _find_tests('x2p');
410         _find_tests('porting');
411         _find_tests('japh') if $::torture;
412         _find_tests('t/benchmark') if $::benchmark or $ENV{PERL_BENCHMARK};
413     }
414 }
415
416 if ($::deparse) {
417     _testprogs('deparse', '',   @ARGV);
418 }
419 elsif ($::with_utf16) {
420     for my $e (0, 1) {
421         for my $b (0, 1) {
422             print STDERR "# ENDIAN $e BOM $b\n";
423             my @UARGV;
424             for my $a (@ARGV) {
425                 my $u = $a . "." . ($e ? "l" : "b") . "e" . ($b ? "b" : "");
426                 my $f = $e ? "v" : "n";
427                 push @UARGV, $u;
428                 unlink($u);
429                 if (open(A, $a)) {
430                     if (open(U, ">$u")) {
431                         print U pack("$f", 0xFEFF) if $b;
432                         while (<A>) {
433                             print U pack("$f*", unpack("C*", $_));
434                         }
435                         close(U);
436                     }
437                     close(A);
438                 }
439             }
440             _testprogs('perl', '', @UARGV);
441             unlink(@UARGV);
442         }
443     }
444 }
445 else {
446     _testprogs('perl',    '',   @ARGV);
447 }
448
449 sub _testprogs {
450     my ($type, $args, @tests) = @_;
451
452     print <<'EOT' if ($type eq 'deparse');
453 ------------------------------------------------------------------------------
454 TESTING DEPARSER
455 ------------------------------------------------------------------------------
456 EOT
457
458     $::bad_files = 0;
459
460     foreach my $t (@tests) {
461       unless (exists $::path_to_name{$t}) {
462         my $tname = "t/$t";
463         $::path_to_name{$t} = $tname;
464       }
465     }
466     my $maxlen = 0;
467     foreach (@::path_to_name{@tests}) {
468         s/\.\w+\z/./;
469         my $len = length ;
470         $maxlen = $len if $len > $maxlen;
471     }
472     # + 3 : we want three dots between the test name and the "ok"
473     my $dotdotdot = $maxlen + 3 ;
474     my $valgrind = 0;
475     my $total_files = @tests;
476     my $good_files = 0;
477     my $tested_files  = 0;
478     my $totmax = 0;
479     my %failed_tests;
480
481     while (my $test = shift @tests) {
482         my $test_start_time = $show_elapsed_time ? Time::HiRes::time() : 0;
483
484         if ($test =~ /^$/) {
485             next;
486         }
487         if ($type eq 'deparse') {
488             if ($test eq "comp/redef.t") {
489                 # Redefinition happens at compile time
490                 next;
491             }
492             elsif ($test =~ m{lib/Switch/t/}) {
493                 # B::Deparse doesn't support source filtering
494                 next;
495             }
496         }
497         my $te = $::path_to_name{$test} . '.'
498                     x ($dotdotdot - length($::path_to_name{$test}));
499
500         if ($^O ne 'VMS') {  # defer printing on VMS due to piping bug
501             print $te;
502             $te = '';
503         }
504
505         my $results = _run_test($test, $type);
506
507         my $failure;
508         my $next = 0;
509         my $seen_leader = 0;
510         my $seen_ok = 0;
511         my $trailing_leader = 0;
512         my $max;
513         my %todo;
514         while (<$results>) {
515             next if /^\s*$/; # skip blank lines
516             if (/^1..$/ && ($^O eq 'VMS')) {
517                 # VMS pipe bug inserts blank lines.
518                 my $l2 = <RESULTS>;
519                 if ($l2 =~ /^\s*$/) {
520                     $l2 = <RESULTS>;
521                 }
522                 $_ = '1..' . $l2;
523             }
524             if ($::verbose) {
525                 print $_;
526             }
527             unless (/^\#/) {
528                 if ($trailing_leader) {
529                     # shouldn't be anything following a postfix 1..n
530                     $failure = 'FAILED--extra output after trailing 1..n';
531                     last;
532                 }
533                 if (/^1\.\.([0-9]+)( todo ([\d ]+))?/) {
534                     if ($seen_leader) {
535                         $failure = 'FAILED--seen duplicate leader';
536                         last;
537                     }
538                     $max = $1;
539                     %todo = map { $_ => 1 } split / /, $3 if $3;
540                     $totmax += $max;
541                     $tested_files++;
542                     if ($seen_ok) {
543                         # 1..n appears at end of file
544                         $trailing_leader = 1;
545                         if ($next != $max) {
546                             $failure = "FAILED--expected $max tests, saw $next";
547                             last;
548                         }
549                     }
550                     else {
551                         $next = 0;
552                     }
553                     $seen_leader = 1;
554                 }
555                 else {
556                     if (/^(not )?ok(?: (\d+))?[^\#]*(\s*\#.*)?/) {
557                         unless ($seen_leader) {
558                             unless ($seen_ok) {
559                                 $next = 0;
560                             }
561                         }
562                         $seen_ok = 1;
563                         $next++;
564                         my($not, $num, $extra, $istodo) = ($1, $2, $3, 0);
565                         $num = $next unless $num;
566
567                         if ($num == $next) {
568
569                             # SKIP is essentially the same as TODO for t/TEST
570                             # this still conforms to TAP:
571                             # http://search.cpan.org/dist/TAP/TAP.pm
572                             $extra and $istodo = $extra =~ /#\s*(?:TODO|SKIP)\b/;
573                             $istodo = 1 if $todo{$num};
574
575                             if( $not && !$istodo ) {
576                                 $failure = "FAILED at test $num";
577                                 last;
578                             }
579                         }
580                         else {
581                             $failure ="FAILED--expected test $next, saw test $num";
582                             last;
583                         }
584                     }
585                     elsif (/^Bail out!\s*(.*)/i) { # magic words
586                         die "FAILED--Further testing stopped" . ($1 ? ": $1\n" : ".\n");
587                     }
588                     else {
589                         # module tests are allowed extra output,
590                         # because Test::Harness allows it
591                         next if $test =~ /^\W*(cpan|dist|ext|lib)\b/;
592                         $failure = "FAILED--unexpected output at test $next";
593                         last;
594                     }
595                 }
596             }
597         }
598         close $results;
599
600         if (not defined $failure) {
601             $failure = 'FAILED--no leader found' unless $seen_leader;
602         }
603
604         if ($ENV{PERL_VALGRIND}) {
605             my @valgrind;
606             if (-e $Valgrind_Log) {
607                 if (open(V, $Valgrind_Log)) {
608                     @valgrind = <V>;
609                     close V;
610                 } else {
611                     warn "$0: Failed to open '$Valgrind_Log': $!\n";
612                 }
613             }
614             if ($ENV{VG_OPTS} =~ /cachegrind/) {
615                 if (rename $Valgrind_Log, "$test.valgrind") {
616                     $valgrind++;
617                 } else {
618                     warn "$0: Failed to create '$test.valgrind': $!\n";
619                 }
620             }
621             elsif (@valgrind) {
622                 my $leaks = 0;
623                 my $errors = 0;
624                 for my $i (0..$#valgrind) {
625                     local $_ = $valgrind[$i];
626                     if (/^==\d+== ERROR SUMMARY: (\d+) errors? /) {
627                         $errors += $1;   # there may be multiple error summaries
628                     } elsif (/^==\d+== LEAK SUMMARY:/) {
629                         for my $off (1 .. 4) {
630                             if ($valgrind[$i+$off] =~
631                                 /(?:lost|reachable):\s+\d+ bytes in (\d+) blocks/) {
632                                 $leaks += $1;
633                             }
634                         }
635                     }
636                 }
637                 if ($errors or $leaks) {
638                     if (rename $Valgrind_Log, "$test.valgrind") {
639                         $valgrind++;
640                     } else {
641                         warn "$0: Failed to create '$test.valgrind': $!\n";
642                     }
643                 }
644             } else {
645                 warn "No valgrind output?\n";
646             }
647             if (-e $Valgrind_Log) {
648                 unlink $Valgrind_Log
649                     or warn "$0: Failed to unlink '$Valgrind_Log': $!\n";
650             }
651         }
652         if ($type eq 'deparse') {
653             unlink "./$test.dp";
654         }
655         if ($ENV{PERL_3LOG}) {
656             my $tpp = $test;
657             $tpp =~ s:^\.\./::;
658             $tpp =~ s:/:_:g;
659             $tpp =~ s:\.t$:.3log:;
660             rename("perl.3log", $tpp) ||
661                 die "rename: perl3.log to $tpp: $!\n";
662         }
663         if (not defined $failure and $next != $max) {
664             $failure="FAILED--expected $max tests, saw $next";
665         }
666
667         if( !defined $failure  # don't mask a test failure
668             and $? )
669         {
670             $failure = "FAILED--non-zero wait status: $?";
671         }
672
673         if (defined $failure) {
674             print "${te}$failure\n";
675             $::bad_files++;
676             if ($test =~ /^base/) {
677                 die "Failed a basic test ($test) -- cannot continue.\n";
678             }
679             ++$failed_tests{$test};
680         }
681         else {
682             if ($max) {
683                 my $elapsed;
684                 if ( $show_elapsed_time ) {
685                     $elapsed = sprintf( " %8.0f ms", (Time::HiRes::time() - $test_start_time) * 1000 );
686                 }
687                 else {
688                     $elapsed = "";
689                 }
690                 print "${te}ok$elapsed\n";
691                 $good_files++;
692             }
693             else {
694                 print "${te}skipped\n";
695                 $tested_files -= 1;
696             }
697         }
698     } # while tests
699
700     if ($::bad_files == 0) {
701         if ($good_files) {
702             print "All tests successful.\n";
703             # XXX add mention of 'perlbug -ok' ?
704         }
705         else {
706             die "FAILED--no tests were run for some reason.\n";
707         }
708     }
709     else {
710         my $pct = $tested_files ? sprintf("%.2f", ($tested_files - $::bad_files) / $tested_files * 100) : "0.00";
711         my $s = $::bad_files == 1 ? "" : "s";
712         warn "Failed $::bad_files test$s out of $tested_files, $pct% okay.\n";
713         for my $test ( sort keys %failed_tests ) {
714             print "\t$test\n";
715         }
716         warn <<'SHRDLU_1';
717 ### Since not all tests were successful, you may want to run some of
718 ### them individually and examine any diagnostic messages they produce.
719 ### See the INSTALL document's section on "make test".
720 SHRDLU_1
721         warn <<'SHRDLU_2' if $good_files / $total_files > 0.8;
722 ### You have a good chance to get more information by running
723 ###   ./perl harness
724 ### in the 't' directory since most (>=80%) of the tests succeeded.
725 SHRDLU_2
726         if (eval {require Config; import Config; 1}) {
727             if ($::Config{usedl} && (my $p = $::Config{ldlibpthname})) {
728                 warn <<SHRDLU_3;
729 ### You may have to set your dynamic library search path,
730 ### $p, to point to the build directory:
731 SHRDLU_3
732                 if (exists $ENV{$p} && $ENV{$p} ne '') {
733                     warn <<SHRDLU_4a;
734 ###   setenv $p `pwd`:\$$p; cd t; ./perl harness
735 ###   $p=`pwd`:\$$p; export $p; cd t; ./perl harness
736 ###   export $p=`pwd`:\$$p; cd t; ./perl harness
737 SHRDLU_4a
738                 } else {
739                     warn <<SHRDLU_4b;
740 ###   setenv $p `pwd`; cd t; ./perl harness
741 ###   $p=`pwd`; export $p; cd t; ./perl harness
742 ###   export $p=`pwd`; cd t; ./perl harness
743 SHRDLU_4b
744                 }
745                 warn <<SHRDLU_5;
746 ### for csh-style shells, like tcsh; or for traditional/modern
747 ### Bourne-style shells, like bash, ksh, and zsh, respectively.
748 SHRDLU_5
749             }
750         }
751     }
752     my ($user,$sys,$cuser,$csys) = times;
753     print sprintf("u=%.2f  s=%.2f  cu=%.2f  cs=%.2f  scripts=%d  tests=%d\n",
754         $user,$sys,$cuser,$csys,$tested_files,$totmax);
755     if ($ENV{PERL_VALGRIND}) {
756         my $s = $valgrind == 1 ? '' : 's';
757         print "$valgrind valgrind report$s created.\n", ;
758     }
759 }
760 exit ($::bad_files != 0);
761
762 # ex: set ts=8 sts=4 sw=4 noet: