perlop: Add note about (?[])
[perl.git] / pod / perlop.pod
1 =head1 NAME
2 X<operator>
3
4 perlop - Perl operators and precedence
5
6 =head1 DESCRIPTION
7
8 In Perl, the operator determines what operation is performed,
9 independent of the type of the operands. For example C<$a + $b>
10 is always a numeric addition, and if C<$a> or C<$b> do not contain
11 numbers, an attempt is made to convert them to numbers first.
12
13 This is in contrast to many other dynamic languages, where the
14 operation is determined by the type of the first argument. It also
15 means that Perl has two versions of some operators, one for numeric
16 and one for string comparison. For example C<$a == $b> compares
17 two numbers for equality, and C<$a eq $b> compares two strings.
18
19 There are a few exceptions though: C<x> can be either string
20 repetition or list repetition, depending on the type of the left
21 operand, and C<&>, C<|> and C<^> can be either string or numeric bit
22 operations.
23
24 =head2 Operator Precedence and Associativity
25 X<operator, precedence> X<precedence> X<associativity>
26
27 Operator precedence and associativity work in Perl more or less like
28 they do in mathematics.
29
30 I<Operator precedence> means some operators are evaluated before
31 others.  For example, in C<2 + 4 * 5>, the multiplication has higher
32 precedence so C<4 * 5> is evaluated first yielding C<2 + 20 ==
33 22> and not C<6 * 5 == 30>.
34
35 I<Operator associativity> defines what happens if a sequence of the
36 same operators is used one after another: whether the evaluator will
37 evaluate the left operations first or the right.  For example, in C<8
38 - 4 - 2>, subtraction is left associative so Perl evaluates the
39 expression left to right.  C<8 - 4> is evaluated first making the
40 expression C<4 - 2 == 2> and not C<8 - 2 == 6>.
41
42 Perl operators have the following associativity and precedence,
43 listed from highest precedence to lowest.  Operators borrowed from
44 C keep the same precedence relationship with each other, even where
45 C's precedence is slightly screwy.  (This makes learning Perl easier
46 for C folks.)  With very few exceptions, these all operate on scalar
47 values only, not array values.
48
49     left        terms and list operators (leftward)
50     left        ->
51     nonassoc    ++ --
52     right       **
53     right       ! ~ \ and unary + and -
54     left        =~ !~
55     left        * / % x
56     left        + - .
57     left        << >>
58     nonassoc    named unary operators
59     nonassoc    < > <= >= lt gt le ge
60     nonassoc    == != <=> eq ne cmp ~~
61     left        &
62     left        | ^
63     left        &&
64     left        || //
65     nonassoc    ..  ...
66     right       ?:
67     right       = += -= *= etc. goto last next redo dump
68     left        , =>
69     nonassoc    list operators (rightward)
70     right       not
71     left        and
72     left        or xor
73
74 In the following sections, these operators are covered in precedence order.
75
76 Many operators can be overloaded for objects.  See L<overload>.
77
78 =head2 Terms and List Operators (Leftward)
79 X<list operator> X<operator, list> X<term>
80
81 A TERM has the highest precedence in Perl.  They include variables,
82 quote and quote-like operators, any expression in parentheses,
83 and any function whose arguments are parenthesized.  Actually, there
84 aren't really functions in this sense, just list operators and unary
85 operators behaving as functions because you put parentheses around
86 the arguments.  These are all documented in L<perlfunc>.
87
88 If any list operator (print(), etc.) or any unary operator (chdir(), etc.)
89 is followed by a left parenthesis as the next token, the operator and
90 arguments within parentheses are taken to be of highest precedence,
91 just like a normal function call.
92
93 In the absence of parentheses, the precedence of list operators such as
94 C<print>, C<sort>, or C<chmod> is either very high or very low depending on
95 whether you are looking at the left side or the right side of the operator.
96 For example, in
97
98     @ary = (1, 3, sort 4, 2);
99     print @ary;         # prints 1324
100
101 the commas on the right of the sort are evaluated before the sort,
102 but the commas on the left are evaluated after.  In other words,
103 list operators tend to gobble up all arguments that follow, and
104 then act like a simple TERM with regard to the preceding expression.
105 Be careful with parentheses:
106
107     # These evaluate exit before doing the print:
108     print($foo, exit);  # Obviously not what you want.
109     print $foo, exit;   # Nor is this.
110
111     # These do the print before evaluating exit:
112     (print $foo), exit; # This is what you want.
113     print($foo), exit;  # Or this.
114     print ($foo), exit; # Or even this.
115
116 Also note that
117
118     print ($foo & 255) + 1, "\n";
119
120 probably doesn't do what you expect at first glance.  The parentheses
121 enclose the argument list for C<print> which is evaluated (printing
122 the result of C<$foo & 255>).  Then one is added to the return value
123 of C<print> (usually 1).  The result is something like this:
124
125     1 + 1, "\n";    # Obviously not what you meant.
126
127 To do what you meant properly, you must write:
128
129     print(($foo & 255) + 1, "\n");
130
131 See L<Named Unary Operators> for more discussion of this.
132
133 Also parsed as terms are the C<do {}> and C<eval {}> constructs, as
134 well as subroutine and method calls, and the anonymous
135 constructors C<[]> and C<{}>.
136
137 See also L<Quote and Quote-like Operators> toward the end of this section,
138 as well as L</"I/O Operators">.
139
140 =head2 The Arrow Operator
141 X<arrow> X<dereference> X<< -> >>
142
143 "C<< -> >>" is an infix dereference operator, just as it is in C
144 and C++.  If the right side is either a C<[...]>, C<{...}>, or a
145 C<(...)> subscript, then the left side must be either a hard or
146 symbolic reference to an array, a hash, or a subroutine respectively.
147 (Or technically speaking, a location capable of holding a hard
148 reference, if it's an array or hash reference being used for
149 assignment.)  See L<perlreftut> and L<perlref>.
150
151 Otherwise, the right side is a method name or a simple scalar
152 variable containing either the method name or a subroutine reference,
153 and the left side must be either an object (a blessed reference)
154 or a class name (that is, a package name).  See L<perlobj>.
155
156 The dereferencing cases (as opposed to method-calling cases) are
157 somewhat extended by the experimental C<postderef> feature.  For the
158 details of that feature, consult L<perlref/Postfix Dereference Syntax>.
159
160 =head2 Auto-increment and Auto-decrement
161 X<increment> X<auto-increment> X<++> X<decrement> X<auto-decrement> X<-->
162
163 "++" and "--" work as in C.  That is, if placed before a variable,
164 they increment or decrement the variable by one before returning the
165 value, and if placed after, increment or decrement after returning the
166 value.
167
168     $i = 0;  $j = 0;
169     print $i++;  # prints 0
170     print ++$j;  # prints 1
171
172 Note that just as in C, Perl doesn't define B<when> the variable is
173 incremented or decremented. You just know it will be done sometime
174 before or after the value is returned. This also means that modifying
175 a variable twice in the same statement will lead to undefined behavior.
176 Avoid statements like:
177
178     $i = $i ++;
179     print ++ $i + $i ++;
180
181 Perl will not guarantee what the result of the above statements is.
182
183 The auto-increment operator has a little extra builtin magic to it.  If
184 you increment a variable that is numeric, or that has ever been used in
185 a numeric context, you get a normal increment.  If, however, the
186 variable has been used in only string contexts since it was set, and
187 has a value that is not the empty string and matches the pattern
188 C</^[a-zA-Z]*[0-9]*\z/>, the increment is done as a string, preserving each
189 character within its range, with carry:
190
191     print ++($foo = "99");      # prints "100"
192     print ++($foo = "a0");      # prints "a1"
193     print ++($foo = "Az");      # prints "Ba"
194     print ++($foo = "zz");      # prints "aaa"
195
196 C<undef> is always treated as numeric, and in particular is changed
197 to C<0> before incrementing (so that a post-increment of an undef value
198 will return C<0> rather than C<undef>).
199
200 The auto-decrement operator is not magical.
201
202 =head2 Exponentiation
203 X<**> X<exponentiation> X<power>
204
205 Binary "**" is the exponentiation operator.  It binds even more
206 tightly than unary minus, so -2**4 is -(2**4), not (-2)**4. (This is
207 implemented using C's pow(3) function, which actually works on doubles
208 internally.)
209
210 =head2 Symbolic Unary Operators
211 X<unary operator> X<operator, unary>
212
213 Unary "!" performs logical negation, that is, "not".  See also C<not> for a lower
214 precedence version of this.
215 X<!>
216
217 Unary "-" performs arithmetic negation if the operand is numeric,
218 including any string that looks like a number.  If the operand is
219 an identifier, a string consisting of a minus sign concatenated
220 with the identifier is returned.  Otherwise, if the string starts
221 with a plus or minus, a string starting with the opposite sign is
222 returned.  One effect of these rules is that -bareword is equivalent
223 to the string "-bareword".  If, however, the string begins with a
224 non-alphabetic character (excluding "+" or "-"), Perl will attempt to convert
225 the string to a numeric and the arithmetic negation is performed. If the
226 string cannot be cleanly converted to a numeric, Perl will give the warning
227 B<Argument "the string" isn't numeric in negation (-) at ...>.
228 X<-> X<negation, arithmetic>
229
230 Unary "~" performs bitwise negation, that is, 1's complement.  For
231 example, C<0666 & ~027> is 0640.  (See also L<Integer Arithmetic> and
232 L<Bitwise String Operators>.)  Note that the width of the result is
233 platform-dependent: ~0 is 32 bits wide on a 32-bit platform, but 64
234 bits wide on a 64-bit platform, so if you are expecting a certain bit
235 width, remember to use the "&" operator to mask off the excess bits.
236 X<~> X<negation, binary>
237
238 When complementing strings, if all characters have ordinal values under
239 256, then their complements will, also.  But if they do not, all
240 characters will be in either 32- or 64-bit complements, depending on your
241 architecture.  So for example, C<~"\x{3B1}"> is C<"\x{FFFF_FC4E}"> on
242 32-bit machines and C<"\x{FFFF_FFFF_FFFF_FC4E}"> on 64-bit machines.
243
244 Unary "+" has no effect whatsoever, even on strings.  It is useful
245 syntactically for separating a function name from a parenthesized expression
246 that would otherwise be interpreted as the complete list of function
247 arguments.  (See examples above under L<Terms and List Operators (Leftward)>.)
248 X<+>
249
250 Unary "\" creates a reference to whatever follows it.  See L<perlreftut>
251 and L<perlref>.  Do not confuse this behavior with the behavior of
252 backslash within a string, although both forms do convey the notion
253 of protecting the next thing from interpolation.
254 X<\> X<reference> X<backslash>
255
256 =head2 Binding Operators
257 X<binding> X<operator, binding> X<=~> X<!~>
258
259 Binary "=~" binds a scalar expression to a pattern match.  Certain operations
260 search or modify the string $_ by default.  This operator makes that kind
261 of operation work on some other string.  The right argument is a search
262 pattern, substitution, or transliteration.  The left argument is what is
263 supposed to be searched, substituted, or transliterated instead of the default
264 $_.  When used in scalar context, the return value generally indicates the
265 success of the operation.  The exceptions are substitution (s///)
266 and transliteration (y///) with the C</r> (non-destructive) option,
267 which cause the B<r>eturn value to be the result of the substitution.
268 Behavior in list context depends on the particular operator.
269 See L</"Regexp Quote-Like Operators"> for details and L<perlretut> for
270 examples using these operators.
271
272 If the right argument is an expression rather than a search pattern,
273 substitution, or transliteration, it is interpreted as a search pattern at run
274 time. Note that this means that its contents will be interpolated twice, so
275
276     '\\' =~ q'\\';
277
278 is not ok, as the regex engine will end up trying to compile the
279 pattern C<\>, which it will consider a syntax error.
280
281 Binary "!~" is just like "=~" except the return value is negated in
282 the logical sense.
283
284 Binary "!~" with a non-destructive substitution (s///r) or transliteration
285 (y///r) is a syntax error.
286
287 =head2 Multiplicative Operators
288 X<operator, multiplicative>
289
290 Binary "*" multiplies two numbers.
291 X<*>
292
293 Binary "/" divides two numbers.
294 X</> X<slash>
295
296 Binary "%" is the modulo operator, which computes the division
297 remainder of its first argument with respect to its second argument.
298 Given integer
299 operands C<$a> and C<$b>: If C<$b> is positive, then C<$a % $b> is
300 C<$a> minus the largest multiple of C<$b> less than or equal to
301 C<$a>.  If C<$b> is negative, then C<$a % $b> is C<$a> minus the
302 smallest multiple of C<$b> that is not less than C<$a> (that is, the
303 result will be less than or equal to zero).  If the operands
304 C<$a> and C<$b> are floating point values and the absolute value of
305 C<$b> (that is C<abs($b)>) is less than C<(UV_MAX + 1)>, only
306 the integer portion of C<$a> and C<$b> will be used in the operation
307 (Note: here C<UV_MAX> means the maximum of the unsigned integer type).
308 If the absolute value of the right operand (C<abs($b)>) is greater than
309 or equal to C<(UV_MAX + 1)>, "%" computes the floating-point remainder
310 C<$r> in the equation C<($r = $a - $i*$b)> where C<$i> is a certain
311 integer that makes C<$r> have the same sign as the right operand
312 C<$b> (B<not> as the left operand C<$a> like C function C<fmod()>)
313 and the absolute value less than that of C<$b>.
314 Note that when C<use integer> is in scope, "%" gives you direct access
315 to the modulo operator as implemented by your C compiler.  This
316 operator is not as well defined for negative operands, but it will
317 execute faster.
318 X<%> X<remainder> X<modulo> X<mod>
319
320 Binary "x" is the repetition operator.  In scalar context or if the left
321 operand is not enclosed in parentheses, it returns a string consisting
322 of the left operand repeated the number of times specified by the right
323 operand.  In list context, if the left operand is enclosed in
324 parentheses or is a list formed by C<qw/STRING/>, it repeats the list.
325 If the right operand is zero or negative, it returns an empty string
326 or an empty list, depending on the context.
327 X<x>
328
329     print '-' x 80;             # print row of dashes
330
331     print "\t" x ($tab/8), ' ' x ($tab%8);      # tab over
332
333     @ones = (1) x 80;           # a list of 80 1's
334     @ones = (5) x @ones;        # set all elements to 5
335
336
337 =head2 Additive Operators
338 X<operator, additive>
339
340 Binary C<+> returns the sum of two numbers.
341 X<+>
342
343 Binary C<-> returns the difference of two numbers.
344 X<->
345
346 Binary C<.> concatenates two strings.
347 X<string, concatenation> X<concatenation>
348 X<cat> X<concat> X<concatenate> X<.>
349
350 =head2 Shift Operators
351 X<shift operator> X<operator, shift> X<<< << >>>
352 X<<< >> >>> X<right shift> X<left shift> X<bitwise shift>
353 X<shl> X<shr> X<shift, right> X<shift, left>
354
355 Binary C<<< << >>> returns the value of its left argument shifted left by the
356 number of bits specified by the right argument.  Arguments should be
357 integers.  (See also L<Integer Arithmetic>.)
358
359 Binary C<<< >> >>> returns the value of its left argument shifted right by
360 the number of bits specified by the right argument.  Arguments should
361 be integers.  (See also L<Integer Arithmetic>.)
362
363 Note that both C<<< << >>> and C<<< >> >>> in Perl are implemented directly using
364 C<<< << >>> and C<<< >> >>>  in C.  If C<use integer> (see L<Integer Arithmetic>) is
365 in force then signed C integers are used, else unsigned C integers are
366 used.  Either way, the implementation isn't going to generate results
367 larger than the size of the integer type Perl was built with (32 bits
368 or 64 bits).
369
370 The result of overflowing the range of the integers is undefined
371 because it is undefined also in C.  In other words, using 32-bit
372 integers, C<< 1 << 32 >> is undefined.  Shifting by a negative number
373 of bits is also undefined.
374
375 If you get tired of being subject to your platform's native integers,
376 the C<use bigint> pragma neatly sidesteps the issue altogether:
377
378     print 20 << 20;  # 20971520
379     print 20 << 40;  # 5120 on 32-bit machines, 
380                      # 21990232555520 on 64-bit machines
381     use bigint;
382     print 20 << 100; # 25353012004564588029934064107520
383
384 =head2 Named Unary Operators
385 X<operator, named unary>
386
387 The various named unary operators are treated as functions with one
388 argument, with optional parentheses.
389
390 If any list operator (print(), etc.) or any unary operator (chdir(), etc.)
391 is followed by a left parenthesis as the next token, the operator and
392 arguments within parentheses are taken to be of highest precedence,
393 just like a normal function call.  For example,
394 because named unary operators are higher precedence than C<||>:
395
396     chdir $foo    || die;       # (chdir $foo) || die
397     chdir($foo)   || die;       # (chdir $foo) || die
398     chdir ($foo)  || die;       # (chdir $foo) || die
399     chdir +($foo) || die;       # (chdir $foo) || die
400
401 but, because * is higher precedence than named operators:
402
403     chdir $foo * 20;    # chdir ($foo * 20)
404     chdir($foo) * 20;   # (chdir $foo) * 20
405     chdir ($foo) * 20;  # (chdir $foo) * 20
406     chdir +($foo) * 20; # chdir ($foo * 20)
407
408     rand 10 * 20;       # rand (10 * 20)
409     rand(10) * 20;      # (rand 10) * 20
410     rand (10) * 20;     # (rand 10) * 20
411     rand +(10) * 20;    # rand (10 * 20)
412
413 Regarding precedence, the filetest operators, like C<-f>, C<-M>, etc. are
414 treated like named unary operators, but they don't follow this functional
415 parenthesis rule.  That means, for example, that C<-f($file).".bak"> is
416 equivalent to C<-f "$file.bak">.
417 X<-X> X<filetest> X<operator, filetest>
418
419 See also L<"Terms and List Operators (Leftward)">.
420
421 =head2 Relational Operators
422 X<relational operator> X<operator, relational>
423
424 Perl operators that return true or false generally return values 
425 that can be safely used as numbers.  For example, the relational
426 operators in this section and the equality operators in the next
427 one return C<1> for true and a special version of the defined empty
428 string, C<"">, which counts as a zero but is exempt from warnings
429 about improper numeric conversions, just as C<"0 but true"> is.
430
431 Binary "<" returns true if the left argument is numerically less than
432 the right argument.
433 X<< < >>
434
435 Binary ">" returns true if the left argument is numerically greater
436 than the right argument.
437 X<< > >>
438
439 Binary "<=" returns true if the left argument is numerically less than
440 or equal to the right argument.
441 X<< <= >>
442
443 Binary ">=" returns true if the left argument is numerically greater
444 than or equal to the right argument.
445 X<< >= >>
446
447 Binary "lt" returns true if the left argument is stringwise less than
448 the right argument.
449 X<< lt >>
450
451 Binary "gt" returns true if the left argument is stringwise greater
452 than the right argument.
453 X<< gt >>
454
455 Binary "le" returns true if the left argument is stringwise less than
456 or equal to the right argument.
457 X<< le >>
458
459 Binary "ge" returns true if the left argument is stringwise greater
460 than or equal to the right argument.
461 X<< ge >>
462
463 =head2 Equality Operators
464 X<equality> X<equal> X<equals> X<operator, equality>
465
466 Binary "==" returns true if the left argument is numerically equal to
467 the right argument.
468 X<==>
469
470 Binary "!=" returns true if the left argument is numerically not equal
471 to the right argument.
472 X<!=>
473
474 Binary "<=>" returns -1, 0, or 1 depending on whether the left
475 argument is numerically less than, equal to, or greater than the right
476 argument.  If your platform supports NaNs (not-a-numbers) as numeric
477 values, using them with "<=>" returns undef.  NaN is not "<", "==", ">",
478 "<=" or ">=" anything (even NaN), so those 5 return false. NaN != NaN
479 returns true, as does NaN != anything else. If your platform doesn't
480 support NaNs then NaN is just a string with numeric value 0.
481 X<< <=> >> X<spaceship>
482
483     $ perl -le '$a = "NaN"; print "No NaN support here" if $a == $a'
484     $ perl -le '$a = "NaN"; print "NaN support here" if $a != $a'
485
486 (Note that the L<bigint>, L<bigrat>, and L<bignum> pragmas all 
487 support "NaN".)
488
489 Binary "eq" returns true if the left argument is stringwise equal to
490 the right argument.
491 X<eq>
492
493 Binary "ne" returns true if the left argument is stringwise not equal
494 to the right argument.
495 X<ne>
496
497 Binary "cmp" returns -1, 0, or 1 depending on whether the left
498 argument is stringwise less than, equal to, or greater than the right
499 argument.
500 X<cmp>
501
502 Binary "~~" does a smartmatch between its arguments.  Smart matching
503 is described in the next section.
504 X<~~>
505
506 "lt", "le", "ge", "gt" and "cmp" use the collation (sort) order specified
507 by the current locale if a legacy C<use locale> (but not
508 C<use locale ':not_characters'>) is in effect.  See
509 L<perllocale>.  Do not mix these with Unicode, only with legacy binary
510 encodings.  The standard L<Unicode::Collate> and
511 L<Unicode::Collate::Locale> modules offer much more powerful solutions to
512 collation issues.
513
514 =head2 Smartmatch Operator
515
516 First available in Perl 5.10.1 (the 5.10.0 version behaved differently),
517 binary C<~~> does a "smartmatch" between its arguments.  This is mostly
518 used implicitly in the C<when> construct described in L<perlsyn>, although
519 not all C<when> clauses call the smartmatch operator.  Unique among all of
520 Perl's operators, the smartmatch operator can recurse.
521
522 It is also unique in that all other Perl operators impose a context
523 (usually string or numeric context) on their operands, autoconverting
524 those operands to those imposed contexts.  In contrast, smartmatch
525 I<infers> contexts from the actual types of its operands and uses that
526 type information to select a suitable comparison mechanism.
527
528 The C<~~> operator compares its operands "polymorphically", determining how
529 to compare them according to their actual types (numeric, string, array,
530 hash, etc.)  Like the equality operators with which it shares the same
531 precedence, C<~~> returns 1 for true and C<""> for false.  It is often best
532 read aloud as "in", "inside of", or "is contained in", because the left
533 operand is often looked for I<inside> the right operand.  That makes the
534 order of the operands to the smartmatch operand often opposite that of
535 the regular match operator.  In other words, the "smaller" thing is usually
536 placed in the left operand and the larger one in the right.
537
538 The behavior of a smartmatch depends on what type of things its arguments
539 are, as determined by the following table.  The first row of the table
540 whose types apply determines the smartmatch behavior.  Because what
541 actually happens is mostly determined by the type of the second operand,
542 the table is sorted on the right operand instead of on the left.
543
544  Left      Right      Description and pseudocode                               
545  ===============================================================
546  Any       undef      check whether Any is undefined                    
547                 like: !defined Any
548
549  Any       Object     invoke ~~ overloading on Object, or die
550
551  Right operand is an ARRAY:
552
553  Left      Right      Description and pseudocode                               
554  ===============================================================
555  ARRAY1    ARRAY2     recurse on paired elements of ARRAY1 and ARRAY2[2]
556                 like: (ARRAY1[0] ~~ ARRAY2[0])
557                         && (ARRAY1[1] ~~ ARRAY2[1]) && ...
558  HASH      ARRAY      any ARRAY elements exist as HASH keys             
559                 like: grep { exists HASH->{$_} } ARRAY
560  Regexp    ARRAY      any ARRAY elements pattern match Regexp
561                 like: grep { /Regexp/ } ARRAY
562  undef     ARRAY      undef in ARRAY                                    
563                 like: grep { !defined } ARRAY
564  Any       ARRAY      smartmatch each ARRAY element[3]                   
565                 like: grep { Any ~~ $_ } ARRAY
566
567  Right operand is a HASH:
568
569  Left      Right      Description and pseudocode                               
570  ===============================================================
571  HASH1     HASH2      all same keys in both HASHes                      
572                 like: keys HASH1 ==
573                          grep { exists HASH2->{$_} } keys HASH1
574  ARRAY     HASH       any ARRAY elements exist as HASH keys             
575                 like: grep { exists HASH->{$_} } ARRAY
576  Regexp    HASH       any HASH keys pattern match Regexp                
577                 like: grep { /Regexp/ } keys HASH
578  undef     HASH       always false (undef can't be a key)               
579                 like: 0 == 1
580  Any       HASH       HASH key existence                                
581                 like: exists HASH->{Any}
582
583  Right operand is CODE:
584
585  Left      Right      Description and pseudocode                               
586  ===============================================================
587  ARRAY     CODE       sub returns true on all ARRAY elements[1]
588                 like: !grep { !CODE->($_) } ARRAY
589  HASH      CODE       sub returns true on all HASH keys[1]
590                 like: !grep { !CODE->($_) } keys HASH
591  Any       CODE       sub passed Any returns true              
592                 like: CODE->(Any)
593
594 Right operand is a Regexp:
595
596  Left      Right      Description and pseudocode                               
597  ===============================================================
598  ARRAY     Regexp     any ARRAY elements match Regexp                   
599                 like: grep { /Regexp/ } ARRAY
600  HASH      Regexp     any HASH keys match Regexp                        
601                 like: grep { /Regexp/ } keys HASH
602  Any       Regexp     pattern match                                     
603                 like: Any =~ /Regexp/
604
605  Other:
606
607  Left      Right      Description and pseudocode                               
608  ===============================================================
609  Object    Any        invoke ~~ overloading on Object,
610                       or fall back to...
611
612  Any       Num        numeric equality                                  
613                  like: Any == Num
614  Num       nummy[4]    numeric equality
615                  like: Num == nummy
616  undef     Any        check whether undefined
617                  like: !defined(Any)
618  Any       Any        string equality                                   
619                  like: Any eq Any
620
621
622 Notes:
623
624 =over
625
626 =item 1.
627 Empty hashes or arrays match. 
628
629 =item 2.
630 That is, each element smartmatches the element of the same index in the other array.[3]
631
632 =item 3.
633 If a circular reference is found, fall back to referential equality. 
634
635 =item 4.
636 Either an actual number, or a string that looks like one.
637
638 =back
639
640 The smartmatch implicitly dereferences any non-blessed hash or array
641 reference, so the C<I<HASH>> and C<I<ARRAY>> entries apply in those cases.
642 For blessed references, the C<I<Object>> entries apply.  Smartmatches
643 involving hashes only consider hash keys, never hash values.
644
645 The "like" code entry is not always an exact rendition.  For example, the
646 smartmatch operator short-circuits whenever possible, but C<grep> does
647 not.  Also, C<grep> in scalar context returns the number of matches, but
648 C<~~> returns only true or false.
649
650 Unlike most operators, the smartmatch operator knows to treat C<undef>
651 specially:
652
653     use v5.10.1;
654     @array = (1, 2, 3, undef, 4, 5);
655     say "some elements undefined" if undef ~~ @array;
656
657 Each operand is considered in a modified scalar context, the modification
658 being that array and hash variables are passed by reference to the
659 operator, which implicitly dereferences them.  Both elements
660 of each pair are the same:
661
662     use v5.10.1;
663
664     my %hash = (red    => 1, blue   => 2, green  => 3,
665                 orange => 4, yellow => 5, purple => 6,
666                 black  => 7, grey   => 8, white  => 9);
667
668     my @array = qw(red blue green);
669
670     say "some array elements in hash keys" if  @array ~~  %hash;
671     say "some array elements in hash keys" if \@array ~~ \%hash;
672
673     say "red in array" if "red" ~~  @array;
674     say "red in array" if "red" ~~ \@array;
675
676     say "some keys end in e" if /e$/ ~~  %hash;
677     say "some keys end in e" if /e$/ ~~ \%hash;
678
679 Two arrays smartmatch if each element in the first array smartmatches
680 (that is, is "in") the corresponding element in the second array,
681 recursively.
682
683     use v5.10.1;
684     my @little = qw(red blue green);
685     my @bigger = ("red", "blue", [ "orange", "green" ] );
686     if (@little ~~ @bigger) {  # true!
687         say "little is contained in bigger";
688     } 
689
690 Because the smartmatch operator recurses on nested arrays, this
691 will still report that "red" is in the array.
692
693     use v5.10.1;
694     my @array = qw(red blue green);
695     my $nested_array = [[[[[[[ @array ]]]]]]];
696     say "red in array" if "red" ~~ $nested_array;
697
698 If two arrays smartmatch each other, then they are deep
699 copies of each others' values, as this example reports:
700
701     use v5.12.0;
702     my @a = (0, 1, 2, [3, [4, 5], 6], 7); 
703     my @b = (0, 1, 2, [3, [4, 5], 6], 7); 
704
705     if (@a ~~ @b && @b ~~ @a) {
706         say "a and b are deep copies of each other";
707     } 
708     elsif (@a ~~ @b) {
709         say "a smartmatches in b";
710     } 
711     elsif (@b ~~ @a) {
712         say "b smartmatches in a";
713     } 
714     else {
715         say "a and b don't smartmatch each other at all";
716     } 
717
718
719 If you were to set C<$b[3] = 4>, then instead of reporting that "a and b
720 are deep copies of each other", it now reports that "b smartmatches in a".
721 That because the corresponding position in C<@a> contains an array that
722 (eventually) has a 4 in it.
723
724 Smartmatching one hash against another reports whether both contain the
725 same keys, no more and no less. This could be used to see whether two
726 records have the same field names, without caring what values those fields
727 might have.  For example:
728
729     use v5.10.1;
730     sub make_dogtag {
731         state $REQUIRED_FIELDS = { name=>1, rank=>1, serial_num=>1 };
732
733         my ($class, $init_fields) = @_;
734
735         die "Must supply (only) name, rank, and serial number"
736             unless $init_fields ~~ $REQUIRED_FIELDS;
737
738         ...
739     }
740
741 or, if other non-required fields are allowed, use ARRAY ~~ HASH:
742
743     use v5.10.1;
744     sub make_dogtag {
745         state $REQUIRED_FIELDS = { name=>1, rank=>1, serial_num=>1 };
746
747         my ($class, $init_fields) = @_;
748
749         die "Must supply (at least) name, rank, and serial number"
750             unless [keys %{$init_fields}] ~~ $REQUIRED_FIELDS;
751
752         ...
753     }
754
755 The smartmatch operator is most often used as the implicit operator of a
756 C<when> clause.  See the section on "Switch Statements" in L<perlsyn>.
757
758 =head3 Smartmatching of Objects
759
760 To avoid relying on an object's underlying representation, if the
761 smartmatch's right operand is an object that doesn't overload C<~~>,
762 it raises the exception "C<Smartmatching a non-overloaded object
763 breaks encapsulation>". That's because one has no business digging
764 around to see whether something is "in" an object. These are all
765 illegal on objects without a C<~~> overload:
766
767     %hash ~~ $object
768        42 ~~ $object
769    "fred" ~~ $object
770
771 However, you can change the way an object is smartmatched by overloading
772 the C<~~> operator. This is allowed to extend the usual smartmatch semantics.
773 For objects that do have an C<~~> overload, see L<overload>.
774
775 Using an object as the left operand is allowed, although not very useful.
776 Smartmatching rules take precedence over overloading, so even if the
777 object in the left operand has smartmatch overloading, this will be
778 ignored.  A left operand that is a non-overloaded object falls back on a
779 string or numeric comparison of whatever the C<ref> operator returns.  That
780 means that
781
782     $object ~~ X
783
784 does I<not> invoke the overload method with C<I<X>> as an argument.
785 Instead the above table is consulted as normal, and based on the type of
786 C<I<X>>, overloading may or may not be invoked.  For simple strings or
787 numbers, in becomes equivalent to this:
788
789     $object ~~ $number          ref($object) == $number
790     $object ~~ $string          ref($object) eq $string 
791
792 For example, this reports that the handle smells IOish
793 (but please don't really do this!):
794
795     use IO::Handle;
796     my $fh = IO::Handle->new();
797     if ($fh ~~ /\bIO\b/) {
798         say "handle smells IOish";
799     } 
800
801 That's because it treats C<$fh> as a string like
802 C<"IO::Handle=GLOB(0x8039e0)">, then pattern matches against that.
803
804 =head2 Bitwise And
805 X<operator, bitwise, and> X<bitwise and> X<&>
806
807 Binary "&" returns its operands ANDed together bit by bit.
808 (See also L<Integer Arithmetic> and L<Bitwise String Operators>.)
809
810 Note that "&" has lower priority than relational operators, so for example
811 the parentheses are essential in a test like
812
813     print "Even\n" if ($x & 1) == 0;
814
815 =head2 Bitwise Or and Exclusive Or
816 X<operator, bitwise, or> X<bitwise or> X<|> X<operator, bitwise, xor>
817 X<bitwise xor> X<^>
818
819 Binary "|" returns its operands ORed together bit by bit.
820 (See also L<Integer Arithmetic> and L<Bitwise String Operators>.)
821
822 Binary "^" returns its operands XORed together bit by bit.
823 (See also L<Integer Arithmetic> and L<Bitwise String Operators>.)
824
825 Note that "|" and "^" have lower priority than relational operators, so
826 for example the brackets are essential in a test like
827
828     print "false\n" if (8 | 2) != 10;
829
830 =head2 C-style Logical And
831 X<&&> X<logical and> X<operator, logical, and>
832
833 Binary "&&" performs a short-circuit logical AND operation.  That is,
834 if the left operand is false, the right operand is not even evaluated.
835 Scalar or list context propagates down to the right operand if it
836 is evaluated.
837
838 =head2 C-style Logical Or
839 X<||> X<operator, logical, or>
840
841 Binary "||" performs a short-circuit logical OR operation.  That is,
842 if the left operand is true, the right operand is not even evaluated.
843 Scalar or list context propagates down to the right operand if it
844 is evaluated.
845
846 =head2 Logical Defined-Or
847 X<//> X<operator, logical, defined-or>
848
849 Although it has no direct equivalent in C, Perl's C<//> operator is related
850 to its C-style or.  In fact, it's exactly the same as C<||>, except that it
851 tests the left hand side's definedness instead of its truth.  Thus,
852 C<< EXPR1 // EXPR2 >> returns the value of C<< EXPR1 >> if it's defined,
853 otherwise, the value of C<< EXPR2 >> is returned. (C<< EXPR1 >> is evaluated
854 in scalar context, C<< EXPR2 >> in the context of C<< // >> itself). Usually,
855 this is the same result as C<< defined(EXPR1) ? EXPR1 : EXPR2 >> (except that
856 the ternary-operator form can be used as a lvalue, while C<< EXPR1 // EXPR2 >>
857 cannot). This is very useful for
858 providing default values for variables.  If you actually want to test if
859 at least one of C<$a> and C<$b> is defined, use C<defined($a // $b)>.
860
861 The C<||>, C<//> and C<&&> operators return the last value evaluated
862 (unlike C's C<||> and C<&&>, which return 0 or 1). Thus, a reasonably
863 portable way to find out the home directory might be:
864
865     $home =  $ENV{HOME}
866           // $ENV{LOGDIR}
867           // (getpwuid($<))[7]
868           // die "You're homeless!\n";
869
870 In particular, this means that you shouldn't use this
871 for selecting between two aggregates for assignment:
872
873     @a = @b || @c;              # this is wrong
874     @a = scalar(@b) || @c;      # really meant this
875     @a = @b ? @b : @c;          # this works fine, though
876
877 As alternatives to C<&&> and C<||> when used for
878 control flow, Perl provides the C<and> and C<or> operators (see below).
879 The short-circuit behavior is identical.  The precedence of "and"
880 and "or" is much lower, however, so that you can safely use them after a
881 list operator without the need for parentheses:
882
883     unlink "alpha", "beta", "gamma"
884             or gripe(), next LINE;
885
886 With the C-style operators that would have been written like this:
887
888     unlink("alpha", "beta", "gamma")
889             || (gripe(), next LINE);
890
891 It would be even more readable to write that this way:
892
893     unless(unlink("alpha", "beta", "gamma")) {
894         gripe();
895         next LINE;
896     } 
897
898 Using "or" for assignment is unlikely to do what you want; see below.
899
900 =head2 Range Operators
901 X<operator, range> X<range> X<..> X<...>
902
903 Binary ".." is the range operator, which is really two different
904 operators depending on the context.  In list context, it returns a
905 list of values counting (up by ones) from the left value to the right
906 value.  If the left value is greater than the right value then it
907 returns the empty list.  The range operator is useful for writing
908 C<foreach (1..10)> loops and for doing slice operations on arrays. In
909 the current implementation, no temporary array is created when the
910 range operator is used as the expression in C<foreach> loops, but older
911 versions of Perl might burn a lot of memory when you write something
912 like this:
913
914     for (1 .. 1_000_000) {
915         # code
916     }
917
918 The range operator also works on strings, using the magical
919 auto-increment, see below.
920
921 In scalar context, ".." returns a boolean value.  The operator is
922 bistable, like a flip-flop, and emulates the line-range (comma)
923 operator of B<sed>, B<awk>, and various editors. Each ".." operator
924 maintains its own boolean state, even across calls to a subroutine
925 that contains it. It is false as long as its left operand is false.
926 Once the left operand is true, the range operator stays true until the
927 right operand is true, I<AFTER> which the range operator becomes false
928 again.  It doesn't become false till the next time the range operator
929 is evaluated.  It can test the right operand and become false on the
930 same evaluation it became true (as in B<awk>), but it still returns
931 true once. If you don't want it to test the right operand until the
932 next evaluation, as in B<sed>, just use three dots ("...") instead of
933 two.  In all other regards, "..." behaves just like ".." does.
934
935 The right operand is not evaluated while the operator is in the
936 "false" state, and the left operand is not evaluated while the
937 operator is in the "true" state.  The precedence is a little lower
938 than || and &&.  The value returned is either the empty string for
939 false, or a sequence number (beginning with 1) for true.  The sequence
940 number is reset for each range encountered.  The final sequence number
941 in a range has the string "E0" appended to it, which doesn't affect
942 its numeric value, but gives you something to search for if you want
943 to exclude the endpoint.  You can exclude the beginning point by
944 waiting for the sequence number to be greater than 1.
945
946 If either operand of scalar ".." is a constant expression,
947 that operand is considered true if it is equal (C<==>) to the current
948 input line number (the C<$.> variable).
949
950 To be pedantic, the comparison is actually C<int(EXPR) == int(EXPR)>,
951 but that is only an issue if you use a floating point expression; when
952 implicitly using C<$.> as described in the previous paragraph, the
953 comparison is C<int(EXPR) == int($.)> which is only an issue when C<$.>
954 is set to a floating point value and you are not reading from a file.
955 Furthermore, C<"span" .. "spat"> or C<2.18 .. 3.14> will not do what
956 you want in scalar context because each of the operands are evaluated
957 using their integer representation.
958
959 Examples:
960
961 As a scalar operator:
962
963     if (101 .. 200) { print; } # print 2nd hundred lines, short for
964                                #  if ($. == 101 .. $. == 200) { print; }
965
966     next LINE if (1 .. /^$/);  # skip header lines, short for
967                                #   next LINE if ($. == 1 .. /^$/);
968                                # (typically in a loop labeled LINE)
969
970     s/^/> / if (/^$/ .. eof());  # quote body
971
972     # parse mail messages
973     while (<>) {
974         $in_header =   1  .. /^$/;
975         $in_body   = /^$/ .. eof;
976         if ($in_header) {
977             # do something
978         } else { # in body
979             # do something else
980         }
981     } continue {
982         close ARGV if eof;             # reset $. each file
983     }
984
985 Here's a simple example to illustrate the difference between
986 the two range operators:
987
988     @lines = ("   - Foo",
989               "01 - Bar",
990               "1  - Baz",
991               "   - Quux");
992
993     foreach (@lines) {
994         if (/0/ .. /1/) {
995             print "$_\n";
996         }
997     }
998
999 This program will print only the line containing "Bar". If
1000 the range operator is changed to C<...>, it will also print the
1001 "Baz" line.
1002
1003 And now some examples as a list operator:
1004
1005     for (101 .. 200) { print }      # print $_ 100 times
1006     @foo = @foo[0 .. $#foo];        # an expensive no-op
1007     @foo = @foo[$#foo-4 .. $#foo];  # slice last 5 items
1008
1009 The range operator (in list context) makes use of the magical
1010 auto-increment algorithm if the operands are strings.  You
1011 can say
1012
1013     @alphabet = ("A" .. "Z");
1014
1015 to get all normal letters of the English alphabet, or
1016
1017     $hexdigit = (0 .. 9, "a" .. "f")[$num & 15];
1018
1019 to get a hexadecimal digit, or
1020
1021     @z2 = ("01" .. "31");
1022     print $z2[$mday];
1023
1024 to get dates with leading zeros.
1025
1026 If the final value specified is not in the sequence that the magical
1027 increment would produce, the sequence goes until the next value would
1028 be longer than the final value specified.
1029
1030 If the initial value specified isn't part of a magical increment
1031 sequence (that is, a non-empty string matching C</^[a-zA-Z]*[0-9]*\z/>),
1032 only the initial value will be returned.  So the following will only
1033 return an alpha:
1034
1035     use charnames "greek";
1036     my @greek_small =  ("\N{alpha}" .. "\N{omega}");
1037
1038 To get the 25 traditional lowercase Greek letters, including both sigmas,
1039 you could use this instead:
1040
1041     use charnames "greek";
1042     my @greek_small =  map { chr } ( ord("\N{alpha}") 
1043                                         ..
1044                                      ord("\N{omega}") 
1045                                    );
1046
1047 However, because there are I<many> other lowercase Greek characters than
1048 just those, to match lowercase Greek characters in a regular expression,
1049 you could use the pattern C</(?:(?=\p{Greek})\p{Lower})+/> (or the
1050 L<experimental feature|perlrecharclass/Extended Bracketed Character
1051 Classes> C<S</(?[ \p{Greek} & \p{Lower} ])+/>>).
1052
1053 Because each operand is evaluated in integer form, C<2.18 .. 3.14> will
1054 return two elements in list context.
1055
1056     @list = (2.18 .. 3.14); # same as @list = (2 .. 3);
1057
1058 =head2 Conditional Operator
1059 X<operator, conditional> X<operator, ternary> X<ternary> X<?:>
1060
1061 Ternary "?:" is the conditional operator, just as in C.  It works much
1062 like an if-then-else.  If the argument before the ? is true, the
1063 argument before the : is returned, otherwise the argument after the :
1064 is returned.  For example:
1065
1066     printf "I have %d dog%s.\n", $n,
1067             ($n == 1) ? "" : "s";
1068
1069 Scalar or list context propagates downward into the 2nd
1070 or 3rd argument, whichever is selected.
1071
1072     $a = $ok ? $b : $c;  # get a scalar
1073     @a = $ok ? @b : @c;  # get an array
1074     $a = $ok ? @b : @c;  # oops, that's just a count!
1075
1076 The operator may be assigned to if both the 2nd and 3rd arguments are
1077 legal lvalues (meaning that you can assign to them):
1078
1079     ($a_or_b ? $a : $b) = $c;
1080
1081 Because this operator produces an assignable result, using assignments
1082 without parentheses will get you in trouble.  For example, this:
1083
1084     $a % 2 ? $a += 10 : $a += 2
1085
1086 Really means this:
1087
1088     (($a % 2) ? ($a += 10) : $a) += 2
1089
1090 Rather than this:
1091
1092     ($a % 2) ? ($a += 10) : ($a += 2)
1093
1094 That should probably be written more simply as:
1095
1096     $a += ($a % 2) ? 10 : 2;
1097
1098 =head2 Assignment Operators
1099 X<assignment> X<operator, assignment> X<=> X<**=> X<+=> X<*=> X<&=>
1100 X<<< <<= >>> X<&&=> X<-=> X</=> X<|=> X<<< >>= >>> X<||=> X<//=> X<.=>
1101 X<%=> X<^=> X<x=>
1102
1103 "=" is the ordinary assignment operator.
1104
1105 Assignment operators work as in C.  That is,
1106
1107     $a += 2;
1108
1109 is equivalent to
1110
1111     $a = $a + 2;
1112
1113 although without duplicating any side effects that dereferencing the lvalue
1114 might trigger, such as from tie().  Other assignment operators work similarly.
1115 The following are recognized:
1116
1117     **=    +=    *=    &=    <<=    &&=
1118            -=    /=    |=    >>=    ||=
1119            .=    %=    ^=           //=
1120                  x=
1121
1122 Although these are grouped by family, they all have the precedence
1123 of assignment.
1124
1125 Unlike in C, the scalar assignment operator produces a valid lvalue.
1126 Modifying an assignment is equivalent to doing the assignment and
1127 then modifying the variable that was assigned to.  This is useful
1128 for modifying a copy of something, like this:
1129
1130     ($tmp = $global) =~ tr/13579/24680/;
1131
1132 Although as of 5.14, that can be also be accomplished this way:
1133
1134     use v5.14;
1135     $tmp = ($global =~  tr/13579/24680/r);
1136
1137 Likewise,
1138
1139     ($a += 2) *= 3;
1140
1141 is equivalent to
1142
1143     $a += 2;
1144     $a *= 3;
1145
1146 Similarly, a list assignment in list context produces the list of
1147 lvalues assigned to, and a list assignment in scalar context returns
1148 the number of elements produced by the expression on the right hand
1149 side of the assignment.
1150
1151 =head2 Comma Operator
1152 X<comma> X<operator, comma> X<,>
1153
1154 Binary "," is the comma operator.  In scalar context it evaluates
1155 its left argument, throws that value away, then evaluates its right
1156 argument and returns that value.  This is just like C's comma operator.
1157
1158 In list context, it's just the list argument separator, and inserts
1159 both its arguments into the list.  These arguments are also evaluated
1160 from left to right.
1161
1162 The C<< => >> operator is a synonym for the comma except that it causes a
1163 word on its left to be interpreted as a string if it begins with a letter
1164 or underscore and is composed only of letters, digits and underscores.
1165 This includes operands that might otherwise be interpreted as operators,
1166 constants, single number v-strings or function calls. If in doubt about
1167 this behavior, the left operand can be quoted explicitly.
1168
1169 Otherwise, the C<< => >> operator behaves exactly as the comma operator
1170 or list argument separator, according to context.
1171
1172 For example:
1173
1174     use constant FOO => "something";
1175
1176     my %h = ( FOO => 23 );
1177
1178 is equivalent to:
1179
1180     my %h = ("FOO", 23);
1181
1182 It is I<NOT>:
1183
1184     my %h = ("something", 23);
1185
1186 The C<< => >> operator is helpful in documenting the correspondence
1187 between keys and values in hashes, and other paired elements in lists.
1188
1189     %hash = ( $key => $value );
1190     login( $username => $password );
1191
1192 The special quoting behavior ignores precedence, and hence may apply to
1193 I<part> of the left operand:
1194
1195     print time.shift => "bbb";
1196
1197 That example prints something like "1314363215shiftbbb", because the
1198 C<< => >> implicitly quotes the C<shift> immediately on its left, ignoring
1199 the fact that C<time.shift> is the entire left operand.
1200
1201 =head2 List Operators (Rightward)
1202 X<operator, list, rightward> X<list operator>
1203
1204 On the right side of a list operator, the comma has very low precedence,
1205 such that it controls all comma-separated expressions found there.
1206 The only operators with lower precedence are the logical operators
1207 "and", "or", and "not", which may be used to evaluate calls to list
1208 operators without the need for parentheses:
1209
1210     open HANDLE, "< :utf8", "filename" or die "Can't open: $!\n";
1211
1212 However, some people find that code harder to read than writing
1213 it with parentheses:
1214
1215     open(HANDLE, "< :utf8", "filename") or die "Can't open: $!\n";
1216
1217 in which case you might as well just use the more customary "||" operator:
1218
1219     open(HANDLE, "< :utf8", "filename") || die "Can't open: $!\n";
1220
1221 See also discussion of list operators in L<Terms and List Operators (Leftward)>.
1222
1223 =head2 Logical Not
1224 X<operator, logical, not> X<not>
1225
1226 Unary "not" returns the logical negation of the expression to its right.
1227 It's the equivalent of "!" except for the very low precedence.
1228
1229 =head2 Logical And
1230 X<operator, logical, and> X<and>
1231
1232 Binary "and" returns the logical conjunction of the two surrounding
1233 expressions.  It's equivalent to C<&&> except for the very low
1234 precedence.  This means that it short-circuits: the right
1235 expression is evaluated only if the left expression is true.
1236
1237 =head2 Logical or and Exclusive Or
1238 X<operator, logical, or> X<operator, logical, xor>
1239 X<operator, logical, exclusive or>
1240 X<or> X<xor>
1241
1242 Binary "or" returns the logical disjunction of the two surrounding
1243 expressions.  It's equivalent to C<||> except for the very low precedence.
1244 This makes it useful for control flow:
1245
1246     print FH $data              or die "Can't write to FH: $!";
1247
1248 This means that it short-circuits: the right expression is evaluated
1249 only if the left expression is false.  Due to its precedence, you must
1250 be careful to avoid using it as replacement for the C<||> operator.
1251 It usually works out better for flow control than in assignments:
1252
1253     $a = $b or $c;              # bug: this is wrong
1254     ($a = $b) or $c;            # really means this
1255     $a = $b || $c;              # better written this way
1256
1257 However, when it's a list-context assignment and you're trying to use
1258 C<||> for control flow, you probably need "or" so that the assignment
1259 takes higher precedence.
1260
1261     @info = stat($file) || die;     # oops, scalar sense of stat!
1262     @info = stat($file) or die;     # better, now @info gets its due
1263
1264 Then again, you could always use parentheses.
1265
1266 Binary C<xor> returns the exclusive-OR of the two surrounding expressions.
1267 It cannot short-circuit (of course).
1268
1269 There is no low precedence operator for defined-OR.
1270
1271 =head2 C Operators Missing From Perl
1272 X<operator, missing from perl> X<&> X<*>
1273 X<typecasting> X<(TYPE)>
1274
1275 Here is what C has that Perl doesn't:
1276
1277 =over 8
1278
1279 =item unary &
1280
1281 Address-of operator.  (But see the "\" operator for taking a reference.)
1282
1283 =item unary *
1284
1285 Dereference-address operator. (Perl's prefix dereferencing
1286 operators are typed: $, @, %, and &.)
1287
1288 =item (TYPE)
1289
1290 Type-casting operator.
1291
1292 =back
1293
1294 =head2 Quote and Quote-like Operators
1295 X<operator, quote> X<operator, quote-like> X<q> X<qq> X<qx> X<qw> X<m>
1296 X<qr> X<s> X<tr> X<'> X<''> X<"> X<""> X<//> X<`> X<``> X<<< << >>>
1297 X<escape sequence> X<escape>
1298
1299 While we usually think of quotes as literal values, in Perl they
1300 function as operators, providing various kinds of interpolating and
1301 pattern matching capabilities.  Perl provides customary quote characters
1302 for these behaviors, but also provides a way for you to choose your
1303 quote character for any of them.  In the following table, a C<{}> represents
1304 any pair of delimiters you choose.
1305
1306     Customary  Generic        Meaning        Interpolates
1307         ''       q{}          Literal             no
1308         ""      qq{}          Literal             yes
1309         ``      qx{}          Command             yes*
1310                 qw{}         Word list            no
1311         //       m{}       Pattern match          yes*
1312                 qr{}          Pattern             yes*
1313                  s{}{}      Substitution          yes*
1314                 tr{}{}    Transliteration         no (but see below)
1315                  y{}{}    Transliteration         no (but see below)
1316         <<EOF                 here-doc            yes*
1317
1318         * unless the delimiter is ''.
1319
1320 Non-bracketing delimiters use the same character fore and aft, but the four
1321 sorts of ASCII brackets (round, angle, square, curly) all nest, which means
1322 that
1323
1324     q{foo{bar}baz}
1325
1326 is the same as
1327
1328     'foo{bar}baz'
1329
1330 Note, however, that this does not always work for quoting Perl code:
1331
1332     $s = q{ if($a eq "}") ... }; # WRONG
1333
1334 is a syntax error. The C<Text::Balanced> module (standard as of v5.8,
1335 and from CPAN before then) is able to do this properly.
1336
1337 There can be whitespace between the operator and the quoting
1338 characters, except when C<#> is being used as the quoting character.
1339 C<q#foo#> is parsed as the string C<foo>, while C<q #foo#> is the
1340 operator C<q> followed by a comment.  Its argument will be taken
1341 from the next line.  This allows you to write:
1342
1343     s {foo}  # Replace foo
1344       {bar}  # with bar.
1345
1346 The following escape sequences are available in constructs that interpolate,
1347 and in transliterations:
1348 X<\t> X<\n> X<\r> X<\f> X<\b> X<\a> X<\e> X<\x> X<\0> X<\c> X<\N> X<\N{}>
1349 X<\o{}>
1350
1351     Sequence     Note  Description
1352     \t                  tab               (HT, TAB)
1353     \n                  newline           (NL)
1354     \r                  return            (CR)
1355     \f                  form feed         (FF)
1356     \b                  backspace         (BS)
1357     \a                  alarm (bell)      (BEL)
1358     \e                  escape            (ESC)
1359     \x{263A}     [1,8]  hex char          (example: SMILEY)
1360     \x1b         [2,8]  restricted range hex char (example: ESC)
1361     \N{name}     [3]    named Unicode character or character sequence
1362     \N{U+263D}   [4,8]  Unicode character (example: FIRST QUARTER MOON)
1363     \c[          [5]    control char      (example: chr(27))
1364     \o{23072}    [6,8]  octal char        (example: SMILEY)
1365     \033         [7,8]  restricted range octal char  (example: ESC)
1366
1367 =over 4
1368
1369 =item [1]
1370
1371 The result is the character specified by the hexadecimal number between
1372 the braces.  See L</[8]> below for details on which character.
1373
1374 Only hexadecimal digits are valid between the braces. If an invalid
1375 character is encountered, a warning will be issued and the invalid
1376 character and all subsequent characters (valid or invalid) within the
1377 braces will be discarded.
1378
1379 If there are no valid digits between the braces, the generated character is
1380 the NULL character (C<\x{00}>).  However, an explicit empty brace (C<\x{}>)
1381 will not cause a warning (currently).
1382
1383 =item [2]
1384
1385 The result is the character specified by the hexadecimal number in the range
1386 0x00 to 0xFF.  See L</[8]> below for details on which character.
1387
1388 Only hexadecimal digits are valid following C<\x>.  When C<\x> is followed
1389 by fewer than two valid digits, any valid digits will be zero-padded.  This
1390 means that C<\x7> will be interpreted as C<\x07>, and a lone <\x> will be
1391 interpreted as C<\x00>.  Except at the end of a string, having fewer than
1392 two valid digits will result in a warning.  Note that although the warning
1393 says the illegal character is ignored, it is only ignored as part of the
1394 escape and will still be used as the subsequent character in the string.
1395 For example:
1396
1397   Original    Result    Warns?
1398   "\x7"       "\x07"    no
1399   "\x"        "\x00"    no
1400   "\x7q"      "\x07q"   yes
1401   "\xq"       "\x00q"   yes
1402
1403 =item [3]
1404
1405 The result is the Unicode character or character sequence given by I<name>.
1406 See L<charnames>.
1407
1408 =item [4]
1409
1410 C<\N{U+I<hexadecimal number>}> means the Unicode character whose Unicode code
1411 point is I<hexadecimal number>.
1412
1413 =item [5]
1414
1415 The character following C<\c> is mapped to some other character as shown in the
1416 table:
1417
1418  Sequence   Value
1419    \c@      chr(0)
1420    \cA      chr(1)
1421    \ca      chr(1)
1422    \cB      chr(2)
1423    \cb      chr(2)
1424    ...
1425    \cZ      chr(26)
1426    \cz      chr(26)
1427    \c[      chr(27)
1428    \c]      chr(29)
1429    \c^      chr(30)
1430    \c?      chr(127)
1431
1432 In other words, it's the character whose code point has had 64 xor'd with
1433 its uppercase.  C<\c?> is DELETE because C<ord("?") ^ 64> is 127, and
1434 C<\c@> is NULL because the ord of "@" is 64, so xor'ing 64 itself produces 0.
1435
1436 Also, C<\c\I<X>> yields C< chr(28) . "I<X>"> for any I<X>, but cannot come at the
1437 end of a string, because the backslash would be parsed as escaping the end
1438 quote.
1439
1440 On ASCII platforms, the resulting characters from the list above are the
1441 complete set of ASCII controls.  This isn't the case on EBCDIC platforms; see
1442 L<perlebcdic/OPERATOR DIFFERENCES> for the complete list of what these
1443 sequences mean on both ASCII and EBCDIC platforms.
1444
1445 Use of any other character following the "c" besides those listed above is
1446 discouraged, and some are deprecated with the intention of removing
1447 those in a later Perl version.  What happens for any of these
1448 other characters currently though, is that the value is derived by xor'ing
1449 with the seventh bit, which is 64.
1450
1451 To get platform independent controls, you can use C<\N{...}>.
1452
1453 =item [6]
1454
1455 The result is the character specified by the octal number between the braces.
1456 See L</[8]> below for details on which character.
1457
1458 If a character that isn't an octal digit is encountered, a warning is raised,
1459 and the value is based on the octal digits before it, discarding it and all
1460 following characters up to the closing brace.  It is a fatal error if there are
1461 no octal digits at all.
1462
1463 =item [7]
1464
1465 The result is the character specified by the three-digit octal number in the
1466 range 000 to 777 (but best to not use above 077, see next paragraph).  See
1467 L</[8]> below for details on which character.
1468
1469 Some contexts allow 2 or even 1 digit, but any usage without exactly
1470 three digits, the first being a zero, may give unintended results.  (For
1471 example, in a regular expression it may be confused with a backreference;
1472 see L<perlrebackslash/Octal escapes>.)  Starting in Perl 5.14, you may
1473 use C<\o{}> instead, which avoids all these problems.  Otherwise, it is best to
1474 use this construct only for ordinals C<\077> and below, remembering to pad to
1475 the left with zeros to make three digits.  For larger ordinals, either use
1476 C<\o{}>, or convert to something else, such as to hex and use C<\x{}>
1477 instead.
1478
1479 Having fewer than 3 digits may lead to a misleading warning message that says
1480 that what follows is ignored.  For example, C<"\128"> in the ASCII character set
1481 is equivalent to the two characters C<"\n8">, but the warning C<Illegal octal
1482 digit '8' ignored> will be thrown.  If C<"\n8"> is what you want, you can
1483 avoid this warning by padding your octal number with C<0>'s: C<"\0128">.
1484
1485 =item [8]
1486
1487 Several constructs above specify a character by a number.  That number
1488 gives the character's position in the character set encoding (indexed from 0).
1489 This is called synonymously its ordinal, code position, or code point.  Perl
1490 works on platforms that have a native encoding currently of either ASCII/Latin1
1491 or EBCDIC, each of which allow specification of 256 characters.  In general, if
1492 the number is 255 (0xFF, 0377) or below, Perl interprets this in the platform's
1493 native encoding.  If the number is 256 (0x100, 0400) or above, Perl interprets
1494 it as a Unicode code point and the result is the corresponding Unicode
1495 character.  For example C<\x{50}> and C<\o{120}> both are the number 80 in
1496 decimal, which is less than 256, so the number is interpreted in the native
1497 character set encoding.  In ASCII the character in the 80th position (indexed
1498 from 0) is the letter "P", and in EBCDIC it is the ampersand symbol "&".
1499 C<\x{100}> and C<\o{400}> are both 256 in decimal, so the number is interpreted
1500 as a Unicode code point no matter what the native encoding is.  The name of the
1501 character in the 256th position (indexed by 0) in Unicode is
1502 C<LATIN CAPITAL LETTER A WITH MACRON>.
1503
1504 There are a couple of exceptions to the above rule.  S<C<\N{U+I<hex number>}>> is
1505 always interpreted as a Unicode code point, so that C<\N{U+0050}> is "P" even
1506 on EBCDIC platforms.  And if L<C<S<use encoding>>|encoding> is in effect, the
1507 number is considered to be in that encoding, and is translated from that into
1508 the platform's native encoding if there is a corresponding native character;
1509 otherwise to Unicode.
1510
1511 =back
1512
1513 B<NOTE>: Unlike C and other languages, Perl has no C<\v> escape sequence for
1514 the vertical tab (VT, which is 11 in both ASCII and EBCDIC), but you may
1515 use C<\ck> or
1516 C<\x0b>.  (C<\v>
1517 does have meaning in regular expression patterns in Perl, see L<perlre>.)
1518
1519 The following escape sequences are available in constructs that interpolate,
1520 but not in transliterations.
1521 X<\l> X<\u> X<\L> X<\U> X<\E> X<\Q> X<\F>
1522
1523     \l          lowercase next character only
1524     \u          titlecase (not uppercase!) next character only
1525     \L          lowercase all characters till \E or end of string
1526     \U          uppercase all characters till \E or end of string
1527     \F          foldcase all characters till \E or end of string
1528     \Q          quote (disable) pattern metacharacters till \E or
1529                 end of string
1530     \E          end either case modification or quoted section
1531                 (whichever was last seen)
1532
1533 See L<perlfunc/quotemeta> for the exact definition of characters that
1534 are quoted by C<\Q>.
1535
1536 C<\L>, C<\U>, C<\F>, and C<\Q> can stack, in which case you need one
1537 C<\E> for each.  For example:
1538
1539  say"This \Qquoting \ubusiness \Uhere isn't quite\E done yet,\E is it?";
1540  This quoting\ Business\ HERE\ ISN\'T\ QUITE\ done\ yet\, is it?
1541
1542 If C<use locale> is in effect (but not C<use locale ':not_characters'>),
1543 the case map used by C<\l>, C<\L>,
1544 C<\u>, and C<\U> is taken from the current locale.  See L<perllocale>.
1545 If Unicode (for example, C<\N{}> or code points of 0x100 or
1546 beyond) is being used, the case map used by C<\l>, C<\L>, C<\u>, and
1547 C<\U> is as defined by Unicode.  That means that case-mapping
1548 a single character can sometimes produce several characters.
1549 Under C<use locale>, C<\F> produces the same results as C<\L>.
1550
1551 All systems use the virtual C<"\n"> to represent a line terminator,
1552 called a "newline".  There is no such thing as an unvarying, physical
1553 newline character.  It is only an illusion that the operating system,
1554 device drivers, C libraries, and Perl all conspire to preserve.  Not all
1555 systems read C<"\r"> as ASCII CR and C<"\n"> as ASCII LF.  For example,
1556 on the ancient Macs (pre-MacOS X) of yesteryear, these used to be reversed,
1557 and on systems without line terminator,
1558 printing C<"\n"> might emit no actual data.  In general, use C<"\n"> when
1559 you mean a "newline" for your system, but use the literal ASCII when you
1560 need an exact character.  For example, most networking protocols expect
1561 and prefer a CR+LF (C<"\015\012"> or C<"\cM\cJ">) for line terminators,
1562 and although they often accept just C<"\012">, they seldom tolerate just
1563 C<"\015">.  If you get in the habit of using C<"\n"> for networking,
1564 you may be burned some day.
1565 X<newline> X<line terminator> X<eol> X<end of line>
1566 X<\n> X<\r> X<\r\n>
1567
1568 For constructs that do interpolate, variables beginning with "C<$>"
1569 or "C<@>" are interpolated.  Subscripted variables such as C<$a[3]> or
1570 C<< $href->{key}[0] >> are also interpolated, as are array and hash slices.
1571 But method calls such as C<< $obj->meth >> are not.
1572
1573 Interpolating an array or slice interpolates the elements in order,
1574 separated by the value of C<$">, so is equivalent to interpolating
1575 C<join $", @array>.  "Punctuation" arrays such as C<@*> are usually
1576 interpolated only if the name is enclosed in braces C<@{*}>, but the
1577 arrays C<@_>, C<@+>, and C<@-> are interpolated even without braces.
1578
1579 For double-quoted strings, the quoting from C<\Q> is applied after
1580 interpolation and escapes are processed.
1581
1582     "abc\Qfoo\tbar$s\Exyz"
1583
1584 is equivalent to
1585
1586     "abc" . quotemeta("foo\tbar$s") . "xyz"
1587
1588 For the pattern of regex operators (C<qr//>, C<m//> and C<s///>),
1589 the quoting from C<\Q> is applied after interpolation is processed,
1590 but before escapes are processed. This allows the pattern to match
1591 literally (except for C<$> and C<@>). For example, the following matches:
1592
1593     '\s\t' =~ /\Q\s\t/
1594
1595 Because C<$> or C<@> trigger interpolation, you'll need to use something
1596 like C</\Quser\E\@\Qhost/> to match them literally.
1597
1598 Patterns are subject to an additional level of interpretation as a
1599 regular expression.  This is done as a second pass, after variables are
1600 interpolated, so that regular expressions may be incorporated into the
1601 pattern from the variables.  If this is not what you want, use C<\Q> to
1602 interpolate a variable literally.
1603
1604 Apart from the behavior described above, Perl does not expand
1605 multiple levels of interpolation.  In particular, contrary to the
1606 expectations of shell programmers, back-quotes do I<NOT> interpolate
1607 within double quotes, nor do single quotes impede evaluation of
1608 variables when used within double quotes.
1609
1610 =head2 Regexp Quote-Like Operators
1611 X<operator, regexp>
1612
1613 Here are the quote-like operators that apply to pattern
1614 matching and related activities.
1615
1616 =over 8
1617
1618 =item qr/STRING/msixpodual
1619 X<qr> X</i> X</m> X</o> X</s> X</x> X</p>
1620
1621 This operator quotes (and possibly compiles) its I<STRING> as a regular
1622 expression.  I<STRING> is interpolated the same way as I<PATTERN>
1623 in C<m/PATTERN/>.  If "'" is used as the delimiter, no interpolation
1624 is done.  Returns a Perl value which may be used instead of the
1625 corresponding C</STRING/msixpodual> expression. The returned value is a
1626 normalized version of the original pattern. It magically differs from
1627 a string containing the same characters: C<ref(qr/x/)> returns "Regexp";
1628 however, dereferencing it is not well defined (you currently get the 
1629 normalized version of the original pattern, but this may change).
1630
1631
1632 For example,
1633
1634     $rex = qr/my.STRING/is;
1635     print $rex;                 # prints (?si-xm:my.STRING)
1636     s/$rex/foo/;
1637
1638 is equivalent to
1639
1640     s/my.STRING/foo/is;
1641
1642 The result may be used as a subpattern in a match:
1643
1644     $re = qr/$pattern/;
1645     $string =~ /foo${re}bar/;   # can be interpolated in other
1646                                 # patterns
1647     $string =~ $re;             # or used standalone
1648     $string =~ /$re/;           # or this way
1649
1650 Since Perl may compile the pattern at the moment of execution of the qr()
1651 operator, using qr() may have speed advantages in some situations,
1652 notably if the result of qr() is used standalone:
1653
1654     sub match {
1655         my $patterns = shift;
1656         my @compiled = map qr/$_/i, @$patterns;
1657         grep {
1658             my $success = 0;
1659             foreach my $pat (@compiled) {
1660                 $success = 1, last if /$pat/;
1661             }
1662             $success;
1663         } @_;
1664     }
1665
1666 Precompilation of the pattern into an internal representation at
1667 the moment of qr() avoids a need to recompile the pattern every
1668 time a match C</$pat/> is attempted.  (Perl has many other internal
1669 optimizations, but none would be triggered in the above example if
1670 we did not use qr() operator.)
1671
1672 Options (specified by the following modifiers) are:
1673
1674     m   Treat string as multiple lines.
1675     s   Treat string as single line. (Make . match a newline)
1676     i   Do case-insensitive pattern matching.
1677     x   Use extended regular expressions.
1678     p   When matching preserve a copy of the matched string so
1679         that ${^PREMATCH}, ${^MATCH}, ${^POSTMATCH} will be
1680         defined.
1681     o   Compile pattern only once.
1682     a   ASCII-restrict: Use ASCII for \d, \s, \w; specifying two
1683         a's further restricts /i matching so that no ASCII
1684         character will match a non-ASCII one.
1685     l   Use the locale.
1686     u   Use Unicode rules.
1687     d   Use Unicode or native charset, as in 5.12 and earlier.
1688
1689 If a precompiled pattern is embedded in a larger pattern then the effect
1690 of "msixpluad" will be propagated appropriately.  The effect the "o"
1691 modifier has is not propagated, being restricted to those patterns
1692 explicitly using it.
1693
1694 The last four modifiers listed above, added in Perl 5.14,
1695 control the character set semantics, but C</a> is the only one you are likely
1696 to want to specify explicitly; the other three are selected
1697 automatically by various pragmas.
1698
1699 See L<perlre> for additional information on valid syntax for STRING, and
1700 for a detailed look at the semantics of regular expressions.  In
1701 particular, all modifiers except the largely obsolete C</o> are further
1702 explained in L<perlre/Modifiers>.  C</o> is described in the next section.
1703
1704 =item m/PATTERN/msixpodualgc
1705 X<m> X<operator, match>
1706 X<regexp, options> X<regexp> X<regex, options> X<regex>
1707 X</m> X</s> X</i> X</x> X</p> X</o> X</g> X</c>
1708
1709 =item /PATTERN/msixpodualgc
1710
1711 Searches a string for a pattern match, and in scalar context returns
1712 true if it succeeds, false if it fails.  If no string is specified
1713 via the C<=~> or C<!~> operator, the $_ string is searched.  (The
1714 string specified with C<=~> need not be an lvalue--it may be the
1715 result of an expression evaluation, but remember the C<=~> binds
1716 rather tightly.)  See also L<perlre>.
1717
1718 Options are as described in C<qr//> above; in addition, the following match
1719 process modifiers are available:
1720
1721  g  Match globally, i.e., find all occurrences.
1722  c  Do not reset search position on a failed match when /g is
1723     in effect.
1724
1725 If "/" is the delimiter then the initial C<m> is optional.  With the C<m>
1726 you can use any pair of non-whitespace (ASCII) characters
1727 as delimiters.  This is particularly useful for matching path names
1728 that contain "/", to avoid LTS (leaning toothpick syndrome).  If "?" is
1729 the delimiter, then a match-only-once rule applies,
1730 described in C<m?PATTERN?> below. If "'" (single quote) is the delimiter,
1731 no interpolation is performed on the PATTERN.
1732 When using a character valid in an identifier, whitespace is required
1733 after the C<m>.
1734
1735 PATTERN may contain variables, which will be interpolated
1736 every time the pattern search is evaluated, except
1737 for when the delimiter is a single quote.  (Note that C<$(>, C<$)>, and
1738 C<$|> are not interpolated because they look like end-of-string tests.)
1739 Perl will not recompile the pattern unless an interpolated
1740 variable that it contains changes.  You can force Perl to skip the
1741 test and never recompile by adding a C</o> (which stands for "once")
1742 after the trailing delimiter.
1743 Once upon a time, Perl would recompile regular expressions
1744 unnecessarily, and this modifier was useful to tell it not to do so, in the
1745 interests of speed.  But now, the only reasons to use C</o> are either:
1746
1747 =over
1748
1749 =item 1
1750
1751 The variables are thousands of characters long and you know that they
1752 don't change, and you need to wring out the last little bit of speed by
1753 having Perl skip testing for that.  (There is a maintenance penalty for
1754 doing this, as mentioning C</o> constitutes a promise that you won't
1755 change the variables in the pattern.  If you do change them, Perl won't
1756 even notice.)
1757
1758 =item 2
1759
1760 you want the pattern to use the initial values of the variables
1761 regardless of whether they change or not.  (But there are saner ways
1762 of accomplishing this than using C</o>.)
1763
1764 =item 3
1765
1766 If the pattern contains embedded code, such as
1767
1768     use re 'eval';
1769     $code = 'foo(?{ $x })';
1770     /$code/
1771
1772 then perl will recompile each time, even though the pattern string hasn't
1773 changed, to ensure that the current value of C<$x> is seen each time.
1774 Use C</o> if you want to avoid this.
1775
1776 =back
1777
1778 The bottom line is that using C</o> is almost never a good idea.
1779
1780 =item The empty pattern //
1781
1782 If the PATTERN evaluates to the empty string, the last
1783 I<successfully> matched regular expression is used instead. In this
1784 case, only the C<g> and C<c> flags on the empty pattern are honored;
1785 the other flags are taken from the original pattern. If no match has
1786 previously succeeded, this will (silently) act instead as a genuine
1787 empty pattern (which will always match).
1788
1789 Note that it's possible to confuse Perl into thinking C<//> (the empty
1790 regex) is really C<//> (the defined-or operator).  Perl is usually pretty
1791 good about this, but some pathological cases might trigger this, such as
1792 C<$a///> (is that C<($a) / (//)> or C<$a // />?) and C<print $fh //>
1793 (C<print $fh(//> or C<print($fh //>?).  In all of these examples, Perl
1794 will assume you meant defined-or.  If you meant the empty regex, just
1795 use parentheses or spaces to disambiguate, or even prefix the empty
1796 regex with an C<m> (so C<//> becomes C<m//>).
1797
1798 =item Matching in list context
1799
1800 If the C</g> option is not used, C<m//> in list context returns a
1801 list consisting of the subexpressions matched by the parentheses in the
1802 pattern, that is, (C<$1>, C<$2>, C<$3>...)  (Note that here C<$1> etc. are
1803 also set).  When there are no parentheses in the pattern, the return
1804 value is the list C<(1)> for success.  
1805 With or without parentheses, an empty list is returned upon failure.
1806
1807 Examples:
1808
1809  open(TTY, "+</dev/tty")
1810     || die "can't access /dev/tty: $!";
1811
1812  <TTY> =~ /^y/i && foo();       # do foo if desired
1813
1814  if (/Version: *([0-9.]*)/) { $version = $1; }
1815
1816  next if m#^/usr/spool/uucp#;
1817
1818  # poor man's grep
1819  $arg = shift;
1820  while (<>) {
1821     print if /$arg/o; # compile only once (no longer needed!)
1822  }
1823
1824  if (($F1, $F2, $Etc) = ($foo =~ /^(\S+)\s+(\S+)\s*(.*)/))
1825
1826 This last example splits $foo into the first two words and the
1827 remainder of the line, and assigns those three fields to $F1, $F2, and
1828 $Etc.  The conditional is true if any variables were assigned; that is,
1829 if the pattern matched.
1830
1831 The C</g> modifier specifies global pattern matching--that is,
1832 matching as many times as possible within the string. How it behaves
1833 depends on the context. In list context, it returns a list of the
1834 substrings matched by any capturing parentheses in the regular
1835 expression. If there are no parentheses, it returns a list of all
1836 the matched strings, as if there were parentheses around the whole
1837 pattern.
1838
1839 In scalar context, each execution of C<m//g> finds the next match,
1840 returning true if it matches, and false if there is no further match.
1841 The position after the last match can be read or set using the C<pos()>
1842 function; see L<perlfunc/pos>. A failed match normally resets the
1843 search position to the beginning of the string, but you can avoid that
1844 by adding the C</c> modifier (for example, C<m//gc>). Modifying the target
1845 string also resets the search position.
1846
1847 =item \G assertion
1848
1849 You can intermix C<m//g> matches with C<m/\G.../g>, where C<\G> is a
1850 zero-width assertion that matches the exact position where the
1851 previous C<m//g>, if any, left off. Without the C</g> modifier, the
1852 C<\G> assertion still anchors at C<pos()> as it was at the start of
1853 the operation (see L<perlfunc/pos>), but the match is of course only
1854 attempted once. Using C<\G> without C</g> on a target string that has
1855 not previously had a C</g> match applied to it is the same as using
1856 the C<\A> assertion to match the beginning of the string.  Note also
1857 that, currently, C<\G> is only properly supported when anchored at the
1858 very beginning of the pattern.
1859
1860 Examples:
1861
1862     # list context
1863     ($one,$five,$fifteen) = (`uptime` =~ /(\d+\.\d+)/g);
1864
1865     # scalar context
1866     local $/ = "";
1867     while ($paragraph = <>) {
1868         while ($paragraph =~ /\p{Ll}['")]*[.!?]+['")]*\s/g) {
1869             $sentences++;
1870         }
1871     }
1872     say $sentences;
1873
1874 Here's another way to check for sentences in a paragraph:
1875
1876  my $sentence_rx = qr{
1877     (?: (?<= ^ ) | (?<= \s ) )  # after start-of-string or
1878                                 # whitespace
1879     \p{Lu}                      # capital letter
1880     .*?                         # a bunch of anything
1881     (?<= \S )                   # that ends in non-
1882                                 # whitespace
1883     (?<! \b [DMS]r  )           # but isn't a common abbr.
1884     (?<! \b Mrs )
1885     (?<! \b Sra )
1886     (?<! \b St  )
1887     [.?!]                       # followed by a sentence
1888                                 # ender
1889     (?= $ | \s )                # in front of end-of-string
1890                                 # or whitespace
1891  }sx;
1892  local $/ = "";
1893  while (my $paragraph = <>) {
1894     say "NEW PARAGRAPH";
1895     my $count = 0;
1896     while ($paragraph =~ /($sentence_rx)/g) {
1897         printf "\tgot sentence %d: <%s>\n", ++$count, $1;
1898     }
1899  }
1900
1901 Here's how to use C<m//gc> with C<\G>:
1902
1903     $_ = "ppooqppqq";
1904     while ($i++ < 2) {
1905         print "1: '";
1906         print $1 while /(o)/gc; print "', pos=", pos, "\n";
1907         print "2: '";
1908         print $1 if /\G(q)/gc;  print "', pos=", pos, "\n";
1909         print "3: '";
1910         print $1 while /(p)/gc; print "', pos=", pos, "\n";
1911     }
1912     print "Final: '$1', pos=",pos,"\n" if /\G(.)/;
1913
1914 The last example should print:
1915
1916     1: 'oo', pos=4
1917     2: 'q', pos=5
1918     3: 'pp', pos=7
1919     1: '', pos=7
1920     2: 'q', pos=8
1921     3: '', pos=8
1922     Final: 'q', pos=8
1923
1924 Notice that the final match matched C<q> instead of C<p>, which a match
1925 without the C<\G> anchor would have done. Also note that the final match
1926 did not update C<pos>. C<pos> is only updated on a C</g> match. If the
1927 final match did indeed match C<p>, it's a good bet that you're running a
1928 very old (pre-5.6.0) version of Perl.
1929
1930 A useful idiom for C<lex>-like scanners is C</\G.../gc>.  You can
1931 combine several regexps like this to process a string part-by-part,
1932 doing different actions depending on which regexp matched.  Each
1933 regexp tries to match where the previous one leaves off.
1934
1935  $_ = <<'EOL';
1936     $url = URI::URL->new( "http://example.com/" );
1937     die if $url eq "xXx";
1938  EOL
1939
1940  LOOP: {
1941      print(" digits"),       redo LOOP if /\G\d+\b[,.;]?\s*/gc;
1942      print(" lowercase"),    redo LOOP
1943                                     if /\G\p{Ll}+\b[,.;]?\s*/gc;
1944      print(" UPPERCASE"),    redo LOOP
1945                                     if /\G\p{Lu}+\b[,.;]?\s*/gc;
1946      print(" Capitalized"),  redo LOOP
1947                               if /\G\p{Lu}\p{Ll}+\b[,.;]?\s*/gc;
1948      print(" MiXeD"),        redo LOOP if /\G\pL+\b[,.;]?\s*/gc;
1949      print(" alphanumeric"), redo LOOP
1950                             if /\G[\p{Alpha}\pN]+\b[,.;]?\s*/gc;
1951      print(" line-noise"),   redo LOOP if /\G\W+/gc;
1952      print ". That's all!\n";
1953  }
1954
1955 Here is the output (split into several lines):
1956
1957  line-noise lowercase line-noise UPPERCASE line-noise UPPERCASE
1958  line-noise lowercase line-noise lowercase line-noise lowercase
1959  lowercase line-noise lowercase lowercase line-noise lowercase
1960  lowercase line-noise MiXeD line-noise. That's all!
1961
1962 =item m?PATTERN?msixpodualgc
1963 X<?> X<operator, match-once>
1964
1965 =item ?PATTERN?msixpodualgc
1966
1967 This is just like the C<m/PATTERN/> search, except that it matches
1968 only once between calls to the reset() operator.  This is a useful
1969 optimization when you want to see only the first occurrence of
1970 something in each file of a set of files, for instance.  Only C<m??>
1971 patterns local to the current package are reset.
1972
1973     while (<>) {
1974         if (m?^$?) {
1975                             # blank line between header and body
1976         }
1977     } continue {
1978         reset if eof;       # clear m?? status for next file
1979     }
1980
1981 Another example switched the first "latin1" encoding it finds
1982 to "utf8" in a pod file:
1983
1984     s//utf8/ if m? ^ =encoding \h+ \K latin1 ?x;
1985
1986 The match-once behavior is controlled by the match delimiter being
1987 C<?>; with any other delimiter this is the normal C<m//> operator.  
1988
1989 For historical reasons, the leading C<m> in C<m?PATTERN?> is optional,
1990 but the resulting C<?PATTERN?> syntax is deprecated, will warn on
1991 usage and might be removed from a future stable release of Perl (without
1992 further notice!).
1993
1994 =item s/PATTERN/REPLACEMENT/msixpodualgcer
1995 X<substitute> X<substitution> X<replace> X<regexp, replace>
1996 X<regexp, substitute> X</m> X</s> X</i> X</x> X</p> X</o> X</g> X</c> X</e> X</r>
1997
1998 Searches a string for a pattern, and if found, replaces that pattern
1999 with the replacement text and returns the number of substitutions
2000 made.  Otherwise it returns false (specifically, the empty string).
2001
2002 If the C</r> (non-destructive) option is used then it runs the
2003 substitution on a copy of the string and instead of returning the
2004 number of substitutions, it returns the copy whether or not a
2005 substitution occurred.  The original string is never changed when
2006 C</r> is used.  The copy will always be a plain string, even if the
2007 input is an object or a tied variable.
2008
2009 If no string is specified via the C<=~> or C<!~> operator, the C<$_>
2010 variable is searched and modified.  Unless the C</r> option is used,
2011 the string specified must be a scalar variable, an array element, a
2012 hash element, or an assignment to one of those; that is, some sort of
2013 scalar lvalue.
2014
2015 If the delimiter chosen is a single quote, no interpolation is
2016 done on either the PATTERN or the REPLACEMENT.  Otherwise, if the
2017 PATTERN contains a $ that looks like a variable rather than an
2018 end-of-string test, the variable will be interpolated into the pattern
2019 at run-time.  If you want the pattern compiled only once the first time
2020 the variable is interpolated, use the C</o> option.  If the pattern
2021 evaluates to the empty string, the last successfully executed regular
2022 expression is used instead.  See L<perlre> for further explanation on these.
2023
2024 Options are as with m// with the addition of the following replacement
2025 specific options:
2026
2027     e   Evaluate the right side as an expression.
2028     ee  Evaluate the right side as a string then eval the
2029         result.
2030     r   Return substitution and leave the original string
2031         untouched.
2032
2033 Any non-whitespace delimiter may replace the slashes.  Add space after
2034 the C<s> when using a character allowed in identifiers.  If single quotes
2035 are used, no interpretation is done on the replacement string (the C</e>
2036 modifier overrides this, however).  Note that Perl treats backticks
2037 as normal delimiters; the replacement text is not evaluated as a command.
2038 If the PATTERN is delimited by bracketing quotes, the REPLACEMENT has
2039 its own pair of quotes, which may or may not be bracketing quotes, for example,
2040 C<s(foo)(bar)> or C<< s<foo>/bar/ >>.  A C</e> will cause the
2041 replacement portion to be treated as a full-fledged Perl expression
2042 and evaluated right then and there.  It is, however, syntax checked at
2043 compile-time. A second C<e> modifier will cause the replacement portion
2044 to be C<eval>ed before being run as a Perl expression.
2045
2046 Examples:
2047
2048     s/\bgreen\b/mauve/g;              # don't change wintergreen
2049
2050     $path =~ s|/usr/bin|/usr/local/bin|;
2051
2052     s/Login: $foo/Login: $bar/; # run-time pattern
2053
2054     ($foo = $bar) =~ s/this/that/;      # copy first, then
2055                                         # change
2056     ($foo = "$bar") =~ s/this/that/;    # convert to string,
2057                                         # copy, then change
2058     $foo = $bar =~ s/this/that/r;       # Same as above using /r
2059     $foo = $bar =~ s/this/that/r
2060                 =~ s/that/the other/r;  # Chained substitutes
2061                                         # using /r
2062     @foo = map { s/this/that/r } @bar   # /r is very useful in
2063                                         # maps
2064
2065     $count = ($paragraph =~ s/Mister\b/Mr./g);  # get change-cnt
2066
2067     $_ = 'abc123xyz';
2068     s/\d+/$&*2/e;               # yields 'abc246xyz'
2069     s/\d+/sprintf("%5d",$&)/e;  # yields 'abc  246xyz'
2070     s/\w/$& x 2/eg;             # yields 'aabbcc  224466xxyyzz'
2071
2072     s/%(.)/$percent{$1}/g;      # change percent escapes; no /e
2073     s/%(.)/$percent{$1} || $&/ge;       # expr now, so /e
2074     s/^=(\w+)/pod($1)/ge;       # use function call
2075
2076     $_ = 'abc123xyz';
2077     $a = s/abc/def/r;           # $a is 'def123xyz' and
2078                                 # $_ remains 'abc123xyz'.
2079
2080     # expand variables in $_, but dynamics only, using
2081     # symbolic dereferencing
2082     s/\$(\w+)/${$1}/g;
2083
2084     # Add one to the value of any numbers in the string
2085     s/(\d+)/1 + $1/eg;
2086
2087     # Titlecase words in the last 30 characters only
2088     substr($str, -30) =~ s/\b(\p{Alpha}+)\b/\u\L$1/g;
2089
2090     # This will expand any embedded scalar variable
2091     # (including lexicals) in $_ : First $1 is interpolated
2092     # to the variable name, and then evaluated
2093     s/(\$\w+)/$1/eeg;
2094
2095     # Delete (most) C comments.
2096     $program =~ s {
2097         /\*     # Match the opening delimiter.
2098         .*?     # Match a minimal number of characters.
2099         \*/     # Match the closing delimiter.
2100     } []gsx;
2101
2102     s/^\s*(.*?)\s*$/$1/;        # trim whitespace in $_,
2103                                 # expensively
2104
2105     for ($variable) {           # trim whitespace in $variable,
2106                                 # cheap
2107         s/^\s+//;
2108         s/\s+$//;
2109     }
2110
2111     s/([^ ]*) *([^ ]*)/$2 $1/;  # reverse 1st two fields
2112
2113 Note the use of $ instead of \ in the last example.  Unlike
2114 B<sed>, we use the \<I<digit>> form in only the left hand side.
2115 Anywhere else it's $<I<digit>>.
2116
2117 Occasionally, you can't use just a C</g> to get all the changes
2118 to occur that you might want.  Here are two common cases:
2119
2120     # put commas in the right places in an integer
2121     1 while s/(\d)(\d\d\d)(?!\d)/$1,$2/g;
2122
2123     # expand tabs to 8-column spacing
2124     1 while s/\t+/' ' x (length($&)*8 - length($`)%8)/e;
2125
2126 =back
2127
2128 =head2 Quote-Like Operators
2129 X<operator, quote-like>
2130
2131 =over 4
2132
2133 =item q/STRING/
2134 X<q> X<quote, single> X<'> X<''>
2135
2136 =item 'STRING'
2137
2138 A single-quoted, literal string.  A backslash represents a backslash
2139 unless followed by the delimiter or another backslash, in which case
2140 the delimiter or backslash is interpolated.
2141
2142     $foo = q!I said, "You said, 'She said it.'"!;
2143     $bar = q('This is it.');
2144     $baz = '\n';                # a two-character string
2145
2146 =item qq/STRING/
2147 X<qq> X<quote, double> X<"> X<"">
2148
2149 =item "STRING"
2150
2151 A double-quoted, interpolated string.
2152
2153     $_ .= qq
2154      (*** The previous line contains the naughty word "$1".\n)
2155                 if /\b(tcl|java|python)\b/i;      # :-)
2156     $baz = "\n";                # a one-character string
2157
2158 =item qx/STRING/
2159 X<qx> X<`> X<``> X<backtick>
2160
2161 =item `STRING`
2162
2163 A string which is (possibly) interpolated and then executed as a
2164 system command with F</bin/sh> or its equivalent.  Shell wildcards,
2165 pipes, and redirections will be honored.  The collected standard
2166 output of the command is returned; standard error is unaffected.  In
2167 scalar context, it comes back as a single (potentially multi-line)
2168 string, or undef if the command failed.  In list context, returns a
2169 list of lines (however you've defined lines with $/ or
2170 $INPUT_RECORD_SEPARATOR), or an empty list if the command failed.
2171
2172 Because backticks do not affect standard error, use shell file descriptor
2173 syntax (assuming the shell supports this) if you care to address this.
2174 To capture a command's STDERR and STDOUT together:
2175
2176     $output = `cmd 2>&1`;
2177
2178 To capture a command's STDOUT but discard its STDERR:
2179
2180     $output = `cmd 2>/dev/null`;
2181
2182 To capture a command's STDERR but discard its STDOUT (ordering is
2183 important here):
2184
2185     $output = `cmd 2>&1 1>/dev/null`;
2186
2187 To exchange a command's STDOUT and STDERR in order to capture the STDERR
2188 but leave its STDOUT to come out the old STDERR:
2189
2190     $output = `cmd 3>&1 1>&2 2>&3 3>&-`;
2191
2192 To read both a command's STDOUT and its STDERR separately, it's easiest
2193 to redirect them separately to files, and then read from those files
2194 when the program is done:
2195
2196     system("program args 1>program.stdout 2>program.stderr");
2197
2198 The STDIN filehandle used by the command is inherited from Perl's STDIN.
2199 For example:
2200
2201     open(SPLAT, "stuff")   || die "can't open stuff: $!";
2202     open(STDIN, "<&SPLAT") || die "can't dupe SPLAT: $!";
2203     print STDOUT `sort`;
2204
2205 will print the sorted contents of the file named F<"stuff">.
2206
2207 Using single-quote as a delimiter protects the command from Perl's
2208 double-quote interpolation, passing it on to the shell instead:
2209
2210     $perl_info  = qx(ps $$);            # that's Perl's $$
2211     $shell_info = qx'ps $$';            # that's the new shell's $$
2212
2213 How that string gets evaluated is entirely subject to the command
2214 interpreter on your system.  On most platforms, you will have to protect
2215 shell metacharacters if you want them treated literally.  This is in
2216 practice difficult to do, as it's unclear how to escape which characters.
2217 See L<perlsec> for a clean and safe example of a manual fork() and exec()
2218 to emulate backticks safely.
2219
2220 On some platforms (notably DOS-like ones), the shell may not be
2221 capable of dealing with multiline commands, so putting newlines in
2222 the string may not get you what you want.  You may be able to evaluate
2223 multiple commands in a single line by separating them with the command
2224 separator character, if your shell supports that (for example, C<;> on 
2225 many Unix shells and C<&> on the Windows NT C<cmd> shell).
2226
2227 Perl will attempt to flush all files opened for
2228 output before starting the child process, but this may not be supported
2229 on some platforms (see L<perlport>).  To be safe, you may need to set
2230 C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method of
2231 C<IO::Handle> on any open handles.
2232
2233 Beware that some command shells may place restrictions on the length
2234 of the command line.  You must ensure your strings don't exceed this
2235 limit after any necessary interpolations.  See the platform-specific
2236 release notes for more details about your particular environment.
2237
2238 Using this operator can lead to programs that are difficult to port,
2239 because the shell commands called vary between systems, and may in
2240 fact not be present at all.  As one example, the C<type> command under
2241 the POSIX shell is very different from the C<type> command under DOS.
2242 That doesn't mean you should go out of your way to avoid backticks
2243 when they're the right way to get something done.  Perl was made to be
2244 a glue language, and one of the things it glues together is commands.
2245 Just understand what you're getting yourself into.
2246
2247 See L</"I/O Operators"> for more discussion.
2248
2249 =item qw/STRING/
2250 X<qw> X<quote, list> X<quote, words>
2251
2252 Evaluates to a list of the words extracted out of STRING, using embedded
2253 whitespace as the word delimiters.  It can be understood as being roughly
2254 equivalent to:
2255
2256     split(" ", q/STRING/);
2257
2258 the differences being that it generates a real list at compile time, and
2259 in scalar context it returns the last element in the list.  So
2260 this expression:
2261
2262     qw(foo bar baz)
2263
2264 is semantically equivalent to the list:
2265
2266     "foo", "bar", "baz"
2267
2268 Some frequently seen examples:
2269
2270     use POSIX qw( setlocale localeconv )
2271     @EXPORT = qw( foo bar baz );
2272
2273 A common mistake is to try to separate the words with comma or to
2274 put comments into a multi-line C<qw>-string.  For this reason, the
2275 C<use warnings> pragma and the B<-w> switch (that is, the C<$^W> variable)
2276 produces warnings if the STRING contains the "," or the "#" character.
2277
2278 =item tr/SEARCHLIST/REPLACEMENTLIST/cdsr
2279 X<tr> X<y> X<transliterate> X</c> X</d> X</s>
2280
2281 =item y/SEARCHLIST/REPLACEMENTLIST/cdsr
2282
2283 Transliterates all occurrences of the characters found in the search list
2284 with the corresponding character in the replacement list.  It returns
2285 the number of characters replaced or deleted.  If no string is
2286 specified via the C<=~> or C<!~> operator, the $_ string is transliterated.
2287
2288 If the C</r> (non-destructive) option is present, a new copy of the string
2289 is made and its characters transliterated, and this copy is returned no
2290 matter whether it was modified or not: the original string is always
2291 left unchanged.  The new copy is always a plain string, even if the input
2292 string is an object or a tied variable.
2293
2294 Unless the C</r> option is used, the string specified with C<=~> must be a
2295 scalar variable, an array element, a hash element, or an assignment to one
2296 of those; in other words, an lvalue.
2297
2298 A character range may be specified with a hyphen, so C<tr/A-J/0-9/>
2299 does the same replacement as C<tr/ACEGIBDFHJ/0246813579/>.
2300 For B<sed> devotees, C<y> is provided as a synonym for C<tr>.  If the
2301 SEARCHLIST is delimited by bracketing quotes, the REPLACEMENTLIST has
2302 its own pair of quotes, which may or may not be bracketing quotes;
2303 for example, C<tr[aeiouy][yuoiea]> or C<tr(+\-*/)/ABCD/>.
2304
2305 Note that C<tr> does B<not> do regular expression character classes such as
2306 C<\d> or C<\pL>.  The C<tr> operator is not equivalent to the tr(1)
2307 utility.  If you want to map strings between lower/upper cases, see
2308 L<perlfunc/lc> and L<perlfunc/uc>, and in general consider using the C<s>
2309 operator if you need regular expressions.  The C<\U>, C<\u>, C<\L>, and
2310 C<\l> string-interpolation escapes on the right side of a substitution
2311 operator will perform correct case-mappings, but C<tr[a-z][A-Z]> will not
2312 (except sometimes on legacy 7-bit data).
2313
2314 Note also that the whole range idea is rather unportable between
2315 character sets--and even within character sets they may cause results
2316 you probably didn't expect.  A sound principle is to use only ranges
2317 that begin from and end at either alphabets of equal case (a-e, A-E),
2318 or digits (0-4).  Anything else is unsafe.  If in doubt, spell out the
2319 character sets in full.
2320
2321 Options:
2322
2323     c   Complement the SEARCHLIST.
2324     d   Delete found but unreplaced characters.
2325     s   Squash duplicate replaced characters.
2326     r   Return the modified string and leave the original string
2327         untouched.
2328
2329 If the C</c> modifier is specified, the SEARCHLIST character set
2330 is complemented.  If the C</d> modifier is specified, any characters
2331 specified by SEARCHLIST not found in REPLACEMENTLIST are deleted.
2332 (Note that this is slightly more flexible than the behavior of some
2333 B<tr> programs, which delete anything they find in the SEARCHLIST,
2334 period.) If the C</s> modifier is specified, sequences of characters
2335 that were transliterated to the same character are squashed down
2336 to a single instance of the character.
2337
2338 If the C</d> modifier is used, the REPLACEMENTLIST is always interpreted
2339 exactly as specified.  Otherwise, if the REPLACEMENTLIST is shorter
2340 than the SEARCHLIST, the final character is replicated till it is long
2341 enough.  If the REPLACEMENTLIST is empty, the SEARCHLIST is replicated.
2342 This latter is useful for counting characters in a class or for
2343 squashing character sequences in a class.
2344
2345 Examples:
2346
2347     $ARGV[1] =~ tr/A-Z/a-z/;    # canonicalize to lower case ASCII
2348
2349     $cnt = tr/*/*/;             # count the stars in $_
2350
2351     $cnt = $sky =~ tr/*/*/;     # count the stars in $sky
2352
2353     $cnt = tr/0-9//;            # count the digits in $_
2354
2355     tr/a-zA-Z//s;               # bookkeeper -> bokeper
2356
2357     ($HOST = $host) =~ tr/a-z/A-Z/;
2358      $HOST = $host  =~ tr/a-z/A-Z/r;   # same thing
2359
2360     $HOST = $host =~ tr/a-z/A-Z/r    # chained with s///r
2361                   =~ s/:/ -p/r;
2362
2363     tr/a-zA-Z/ /cs;             # change non-alphas to single space
2364
2365     @stripped = map tr/a-zA-Z/ /csr, @original;
2366                                 # /r with map
2367
2368     tr [\200-\377]
2369        [\000-\177];             # wickedly delete 8th bit
2370
2371 If multiple transliterations are given for a character, only the
2372 first one is used:
2373
2374     tr/AAA/XYZ/
2375
2376 will transliterate any A to X.
2377
2378 Because the transliteration table is built at compile time, neither
2379 the SEARCHLIST nor the REPLACEMENTLIST are subjected to double quote
2380 interpolation.  That means that if you want to use variables, you
2381 must use an eval():
2382
2383     eval "tr/$oldlist/$newlist/";
2384     die $@ if $@;
2385
2386     eval "tr/$oldlist/$newlist/, 1" or die $@;
2387
2388 =item <<EOF
2389 X<here-doc> X<heredoc> X<here-document> X<<< << >>>
2390
2391 A line-oriented form of quoting is based on the shell "here-document"
2392 syntax.  Following a C<< << >> you specify a string to terminate
2393 the quoted material, and all lines following the current line down to
2394 the terminating string are the value of the item.
2395
2396 The terminating string may be either an identifier (a word), or some
2397 quoted text.  An unquoted identifier works like double quotes.
2398 There may not be a space between the C<< << >> and the identifier,
2399 unless the identifier is explicitly quoted.  (If you put a space it
2400 will be treated as a null identifier, which is valid, and matches the
2401 first empty line.)  The terminating string must appear by itself
2402 (unquoted and with no surrounding whitespace) on the terminating line.
2403
2404 If the terminating string is quoted, the type of quotes used determine
2405 the treatment of the text.
2406
2407 =over 4
2408
2409 =item Double Quotes
2410
2411 Double quotes indicate that the text will be interpolated using exactly
2412 the same rules as normal double quoted strings.
2413
2414        print <<EOF;
2415     The price is $Price.
2416     EOF
2417
2418        print << "EOF"; # same as above
2419     The price is $Price.
2420     EOF
2421
2422
2423 =item Single Quotes
2424
2425 Single quotes indicate the text is to be treated literally with no
2426 interpolation of its content. This is similar to single quoted
2427 strings except that backslashes have no special meaning, with C<\\>
2428 being treated as two backslashes and not one as they would in every
2429 other quoting construct.
2430
2431 Just as in the shell, a backslashed bareword following the C<<< << >>>
2432 means the same thing as a single-quoted string does:
2433
2434         $cost = <<'VISTA';  # hasta la ...
2435     That'll be $10 please, ma'am.
2436     VISTA
2437
2438         $cost = <<\VISTA;   # Same thing!
2439     That'll be $10 please, ma'am.
2440     VISTA
2441
2442 This is the only form of quoting in perl where there is no need
2443 to worry about escaping content, something that code generators
2444 can and do make good use of.
2445
2446 =item Backticks
2447
2448 The content of the here doc is treated just as it would be if the
2449 string were embedded in backticks. Thus the content is interpolated
2450 as though it were double quoted and then executed via the shell, with
2451 the results of the execution returned.
2452
2453        print << `EOC`; # execute command and get results
2454     echo hi there
2455     EOC
2456
2457 =back
2458
2459 It is possible to stack multiple here-docs in a row:
2460
2461        print <<"foo", <<"bar"; # you can stack them
2462     I said foo.
2463     foo
2464     I said bar.
2465     bar
2466
2467        myfunc(<< "THIS", 23, <<'THAT');
2468     Here's a line
2469     or two.
2470     THIS
2471     and here's another.
2472     THAT
2473
2474 Just don't forget that you have to put a semicolon on the end
2475 to finish the statement, as Perl doesn't know you're not going to
2476 try to do this:
2477
2478        print <<ABC
2479     179231
2480     ABC
2481        + 20;
2482
2483 If you want to remove the line terminator from your here-docs,
2484 use C<chomp()>.
2485
2486     chomp($string = <<'END');
2487     This is a string.
2488     END
2489
2490 If you want your here-docs to be indented with the rest of the code,
2491 you'll need to remove leading whitespace from each line manually:
2492
2493     ($quote = <<'FINIS') =~ s/^\s+//gm;
2494        The Road goes ever on and on,
2495        down from the door where it began.
2496     FINIS
2497
2498 If you use a here-doc within a delimited construct, such as in C<s///eg>,
2499 the quoted material must still come on the line following the
2500 C<<< <<FOO >>> marker, which means it may be inside the delimited
2501 construct:
2502
2503     s/this/<<E . 'that'
2504     the other
2505     E
2506      . 'more '/eg;
2507
2508 It works this way as of Perl 5.18.  Historically, it was inconsistent, and
2509 you would have to write
2510
2511     s/this/<<E . 'that'
2512      . 'more '/eg;
2513     the other
2514     E
2515
2516 outside of string evals.
2517
2518 Additionally, quoting rules for the end-of-string identifier are
2519 unrelated to Perl's quoting rules. C<q()>, C<qq()>, and the like are not
2520 supported in place of C<''> and C<"">, and the only interpolation is for
2521 backslashing the quoting character:
2522
2523     print << "abc\"def";
2524     testing...
2525     abc"def
2526
2527 Finally, quoted strings cannot span multiple lines.  The general rule is
2528 that the identifier must be a string literal.  Stick with that, and you
2529 should be safe.
2530
2531 =back
2532
2533 =head2 Gory details of parsing quoted constructs
2534 X<quote, gory details>
2535
2536 When presented with something that might have several different
2537 interpretations, Perl uses the B<DWIM> (that's "Do What I Mean")
2538 principle to pick the most probable interpretation.  This strategy
2539 is so successful that Perl programmers often do not suspect the
2540 ambivalence of what they write.  But from time to time, Perl's
2541 notions differ substantially from what the author honestly meant.
2542
2543 This section hopes to clarify how Perl handles quoted constructs.
2544 Although the most common reason to learn this is to unravel labyrinthine
2545 regular expressions, because the initial steps of parsing are the
2546 same for all quoting operators, they are all discussed together.
2547
2548 The most important Perl parsing rule is the first one discussed
2549 below: when processing a quoted construct, Perl first finds the end
2550 of that construct, then interprets its contents.  If you understand
2551 this rule, you may skip the rest of this section on the first
2552 reading.  The other rules are likely to contradict the user's
2553 expectations much less frequently than this first one.
2554
2555 Some passes discussed below are performed concurrently, but because
2556 their results are the same, we consider them individually.  For different
2557 quoting constructs, Perl performs different numbers of passes, from
2558 one to four, but these passes are always performed in the same order.
2559
2560 =over 4
2561
2562 =item Finding the end
2563
2564 The first pass is finding the end of the quoted construct, where
2565 the information about the delimiters is used in parsing.
2566 During this search, text between the starting and ending delimiters
2567 is copied to a safe location. The text copied gets delimiter-independent.
2568
2569 If the construct is a here-doc, the ending delimiter is a line
2570 that has a terminating string as the content. Therefore C<<<EOF> is
2571 terminated by C<EOF> immediately followed by C<"\n"> and starting
2572 from the first column of the terminating line.
2573 When searching for the terminating line of a here-doc, nothing
2574 is skipped. In other words, lines after the here-doc syntax
2575 are compared with the terminating string line by line.
2576
2577 For the constructs except here-docs, single characters are used as starting
2578 and ending delimiters. If the starting delimiter is an opening punctuation
2579 (that is C<(>, C<[>, C<{>, or C<< < >>), the ending delimiter is the
2580 corresponding closing punctuation (that is C<)>, C<]>, C<}>, or C<< > >>).
2581 If the starting delimiter is an unpaired character like C</> or a closing
2582 punctuation, the ending delimiter is same as the starting delimiter.
2583 Therefore a C</> terminates a C<qq//> construct, while a C<]> terminates
2584 C<qq[]> and C<qq]]> constructs.
2585
2586 When searching for single-character delimiters, escaped delimiters
2587 and C<\\> are skipped.  For example, while searching for terminating C</>,
2588 combinations of C<\\> and C<\/> are skipped.  If the delimiters are
2589 bracketing, nested pairs are also skipped.  For example, while searching
2590 for closing C<]> paired with the opening C<[>, combinations of C<\\>, C<\]>,
2591 and C<\[> are all skipped, and nested C<[> and C<]> are skipped as well.
2592 However, when backslashes are used as the delimiters (like C<qq\\> and
2593 C<tr\\\>), nothing is skipped.
2594 During the search for the end, backslashes that escape delimiters or
2595 other backslashes are removed (exactly speaking, they are not copied to the
2596 safe location).
2597
2598 For constructs with three-part delimiters (C<s///>, C<y///>, and
2599 C<tr///>), the search is repeated once more.
2600 If the first delimiter is not an opening punctuation, three delimiters must
2601 be same such as C<s!!!> and C<tr)))>, in which case the second delimiter
2602 terminates the left part and starts the right part at once.
2603 If the left part is delimited by bracketing punctuation (that is C<()>,
2604 C<[]>, C<{}>, or C<< <> >>), the right part needs another pair of
2605 delimiters such as C<s(){}> and C<tr[]//>.  In these cases, whitespace
2606 and comments are allowed between both parts, though the comment must follow
2607 at least one whitespace character; otherwise a character expected as the 
2608 start of the comment may be regarded as the starting delimiter of the right part.
2609
2610 During this search no attention is paid to the semantics of the construct.
2611 Thus:
2612
2613     "$hash{"$foo/$bar"}"
2614
2615 or:
2616
2617     m/
2618       bar       # NOT a comment, this slash / terminated m//!
2619      /x
2620
2621 do not form legal quoted expressions.   The quoted part ends on the
2622 first C<"> and C</>, and the rest happens to be a syntax error.
2623 Because the slash that terminated C<m//> was followed by a C<SPACE>,
2624 the example above is not C<m//x>, but rather C<m//> with no C</x>
2625 modifier.  So the embedded C<#> is interpreted as a literal C<#>.
2626
2627 Also no attention is paid to C<\c\> (multichar control char syntax) during
2628 this search. Thus the second C<\> in C<qq/\c\/> is interpreted as a part
2629 of C<\/>, and the following C</> is not recognized as a delimiter.
2630 Instead, use C<\034> or C<\x1c> at the end of quoted constructs.
2631
2632 =item Interpolation
2633 X<interpolation>
2634
2635 The next step is interpolation in the text obtained, which is now
2636 delimiter-independent.  There are multiple cases.
2637
2638 =over 4
2639
2640 =item C<<<'EOF'>
2641
2642 No interpolation is performed.
2643 Note that the combination C<\\> is left intact, since escaped delimiters
2644 are not available for here-docs.
2645
2646 =item  C<m''>, the pattern of C<s'''>
2647
2648 No interpolation is performed at this stage.
2649 Any backslashed sequences including C<\\> are treated at the stage
2650 to L</"parsing regular expressions">.
2651
2652 =item C<''>, C<q//>, C<tr'''>, C<y'''>, the replacement of C<s'''>
2653
2654 The only interpolation is removal of C<\> from pairs of C<\\>.
2655 Therefore C<-> in C<tr'''> and C<y'''> is treated literally
2656 as a hyphen and no character range is available.
2657 C<\1> in the replacement of C<s'''> does not work as C<$1>.
2658
2659 =item C<tr///>, C<y///>
2660
2661 No variable interpolation occurs.  String modifying combinations for
2662 case and quoting such as C<\Q>, C<\U>, and C<\E> are not recognized.
2663 The other escape sequences such as C<\200> and C<\t> and backslashed
2664 characters such as C<\\> and C<\-> are converted to appropriate literals.
2665 The character C<-> is treated specially and therefore C<\-> is treated
2666 as a literal C<->.
2667
2668 =item C<"">, C<``>, C<qq//>, C<qx//>, C<< <file*glob> >>, C<<<"EOF">
2669
2670 C<\Q>, C<\U>, C<\u>, C<\L>, C<\l>, C<\F> (possibly paired with C<\E>) are
2671 converted to corresponding Perl constructs.  Thus, C<"$foo\Qbaz$bar">
2672 is converted to C<$foo . (quotemeta("baz" . $bar))> internally.
2673 The other escape sequences such as C<\200> and C<\t> and backslashed
2674 characters such as C<\\> and C<\-> are replaced with appropriate
2675 expansions.
2676
2677 Let it be stressed that I<whatever falls between C<\Q> and C<\E>>
2678 is interpolated in the usual way.  Something like C<"\Q\\E"> has
2679 no C<\E> inside.  Instead, it has C<\Q>, C<\\>, and C<E>, so the
2680 result is the same as for C<"\\\\E">.  As a general rule, backslashes
2681 between C<\Q> and C<\E> may lead to counterintuitive results.  So,
2682 C<"\Q\t\E"> is converted to C<quotemeta("\t")>, which is the same
2683 as C<"\\\t"> (since TAB is not alphanumeric).  Note also that:
2684
2685   $str = '\t';
2686   return "\Q$str";
2687
2688 may be closer to the conjectural I<intention> of the writer of C<"\Q\t\E">.
2689
2690 Interpolated scalars and arrays are converted internally to the C<join> and
2691 C<.> catenation operations.  Thus, C<"$foo XXX '@arr'"> becomes:
2692
2693   $foo . " XXX '" . (join $", @arr) . "'";
2694
2695 All operations above are performed simultaneously, left to right.
2696
2697 Because the result of C<"\Q STRING \E"> has all metacharacters
2698 quoted, there is no way to insert a literal C<$> or C<@> inside a
2699 C<\Q\E> pair.  If protected by C<\>, C<$> will be quoted to became
2700 C<"\\\$">; if not, it is interpreted as the start of an interpolated
2701 scalar.
2702
2703 Note also that the interpolation code needs to make a decision on
2704 where the interpolated scalar ends.  For instance, whether
2705 C<< "a $b -> {c}" >> really means:
2706
2707   "a " . $b . " -> {c}";
2708
2709 or:
2710
2711   "a " . $b -> {c};
2712
2713 Most of the time, the longest possible text that does not include
2714 spaces between components and which contains matching braces or
2715 brackets.  because the outcome may be determined by voting based
2716 on heuristic estimators, the result is not strictly predictable.
2717 Fortunately, it's usually correct for ambiguous cases.
2718
2719 =item the replacement of C<s///>
2720
2721 Processing of C<\Q>, C<\U>, C<\u>, C<\L>, C<\l>, C<\F> and interpolation
2722 happens as with C<qq//> constructs.
2723
2724 It is at this step that C<\1> is begrudgingly converted to C<$1> in
2725 the replacement text of C<s///>, in order to correct the incorrigible
2726 I<sed> hackers who haven't picked up the saner idiom yet.  A warning
2727 is emitted if the C<use warnings> pragma or the B<-w> command-line flag
2728 (that is, the C<$^W> variable) was set.
2729
2730 =item C<RE> in C<?RE?>, C</RE/>, C<m/RE/>, C<s/RE/foo/>,
2731
2732 Processing of C<\Q>, C<\U>, C<\u>, C<\L>, C<\l>, C<\F>, C<\E>,
2733 and interpolation happens (almost) as with C<qq//> constructs.
2734
2735 Processing of C<\N{...}> is also done here, and compiled into an intermediate
2736 form for the regex compiler.  (This is because, as mentioned below, the regex
2737 compilation may be done at execution time, and C<\N{...}> is a compile-time
2738 construct.)
2739
2740 However any other combinations of C<\> followed by a character
2741 are not substituted but only skipped, in order to parse them
2742 as regular expressions at the following step.
2743 As C<\c> is skipped at this step, C<@> of C<\c@> in RE is possibly
2744 treated as an array symbol (for example C<@foo>),
2745 even though the same text in C<qq//> gives interpolation of C<\c@>.
2746
2747 Code blocks such as C<(?{BLOCK})> are handled by temporarily passing control
2748 back to the perl parser, in a similar way that an interpolated array
2749 subscript expression such as C<"foo$array[1+f("[xyz")]bar"> would be.
2750
2751 Moreover, inside C<(?{BLOCK})>, C<(?# comment )>, and
2752 a C<#>-comment in a C<//x>-regular expression, no processing is
2753 performed whatsoever.  This is the first step at which the presence
2754 of the C<//x> modifier is relevant.
2755
2756 Interpolation in patterns has several quirks: C<$|>, C<$(>, C<$)>, C<@+>
2757 and C<@-> are not interpolated, and constructs C<$var[SOMETHING]> are
2758 voted (by several different estimators) to be either an array element
2759 or C<$var> followed by an RE alternative.  This is where the notation
2760 C<${arr[$bar]}> comes handy: C</${arr[0-9]}/> is interpreted as
2761 array element C<-9>, not as a regular expression from the variable
2762 C<$arr> followed by a digit, which would be the interpretation of
2763 C</$arr[0-9]/>.  Since voting among different estimators may occur,
2764 the result is not predictable.
2765
2766 The lack of processing of C<\\> creates specific restrictions on
2767 the post-processed text.  If the delimiter is C</>, one cannot get
2768 the combination C<\/> into the result of this step.  C</> will
2769 finish the regular expression, C<\/> will be stripped to C</> on
2770 the previous step, and C<\\/> will be left as is.  Because C</> is
2771 equivalent to C<\/> inside a regular expression, this does not
2772 matter unless the delimiter happens to be character special to the
2773 RE engine, such as in C<s*foo*bar*>, C<m[foo]>, or C<?foo?>; or an
2774 alphanumeric char, as in:
2775
2776   m m ^ a \s* b mmx;
2777
2778 In the RE above, which is intentionally obfuscated for illustration, the
2779 delimiter is C<m>, the modifier is C<mx>, and after delimiter-removal the
2780 RE is the same as for C<m/ ^ a \s* b /mx>.  There's more than one
2781 reason you're encouraged to restrict your delimiters to non-alphanumeric,
2782 non-whitespace choices.
2783
2784 =back
2785
2786 This step is the last one for all constructs except regular expressions,
2787 which are processed further.
2788
2789 =item parsing regular expressions
2790 X<regexp, parse>
2791
2792 Previous steps were performed during the compilation of Perl code,
2793 but this one happens at run time, although it may be optimized to
2794 be calculated at compile time if appropriate.  After preprocessing
2795 described above, and possibly after evaluation if concatenation,
2796 joining, casing translation, or metaquoting are involved, the
2797 resulting I<string> is passed to the RE engine for compilation.
2798
2799 Whatever happens in the RE engine might be better discussed in L<perlre>,
2800 but for the sake of continuity, we shall do so here.
2801
2802 This is another step where the presence of the C<//x> modifier is
2803 relevant.  The RE engine scans the string from left to right and
2804 converts it to a finite automaton.
2805
2806 Backslashed characters are either replaced with corresponding
2807 literal strings (as with C<\{>), or else they generate special nodes
2808 in the finite automaton (as with C<\b>).  Characters special to the
2809 RE engine (such as C<|>) generate corresponding nodes or groups of
2810 nodes.  C<(?#...)> comments are ignored.  All the rest is either
2811 converted to literal strings to match, or else is ignored (as is
2812 whitespace and C<#>-style comments if C<//x> is present).
2813
2814 Parsing of the bracketed character class construct, C<[...]>, is
2815 rather different than the rule used for the rest of the pattern.
2816 The terminator of this construct is found using the same rules as
2817 for finding the terminator of a C<{}>-delimited construct, the only
2818 exception being that C<]> immediately following C<[> is treated as
2819 though preceded by a backslash.
2820
2821 The terminator of runtime C<(?{...})> is found by temporarily switching
2822 control to the perl parser, which should stop at the point where the
2823 logically balancing terminating C<}> is found.
2824
2825 It is possible to inspect both the string given to RE engine and the
2826 resulting finite automaton.  See the arguments C<debug>/C<debugcolor>
2827 in the C<use L<re>> pragma, as well as Perl's B<-Dr> command-line
2828 switch documented in L<perlrun/"Command Switches">.
2829
2830 =item Optimization of regular expressions
2831 X<regexp, optimization>
2832
2833 This step is listed for completeness only.  Since it does not change
2834 semantics, details of this step are not documented and are subject
2835 to change without notice.  This step is performed over the finite
2836 automaton that was generated during the previous pass.
2837
2838 It is at this stage that C<split()> silently optimizes C</^/> to
2839 mean C</^/m>.
2840
2841 =back
2842
2843 =head2 I/O Operators
2844 X<operator, i/o> X<operator, io> X<io> X<while> X<filehandle>
2845 X<< <> >> X<@ARGV>
2846
2847 There are several I/O operators you should know about.
2848
2849 A string enclosed by backticks (grave accents) first undergoes
2850 double-quote interpolation.  It is then interpreted as an external
2851 command, and the output of that command is the value of the
2852 backtick string, like in a shell.  In scalar context, a single string
2853 consisting of all output is returned.  In list context, a list of
2854 values is returned, one per line of output.  (You can set C<$/> to use
2855 a different line terminator.)  The command is executed each time the
2856 pseudo-literal is evaluated.  The status value of the command is
2857 returned in C<$?> (see L<perlvar> for the interpretation of C<$?>).
2858 Unlike in B<csh>, no translation is done on the return data--newlines
2859 remain newlines.  Unlike in any of the shells, single quotes do not
2860 hide variable names in the command from interpretation.  To pass a
2861 literal dollar-sign through to the shell you need to hide it with a
2862 backslash.  The generalized form of backticks is C<qx//>.  (Because
2863 backticks always undergo shell expansion as well, see L<perlsec> for
2864 security concerns.)
2865 X<qx> X<`> X<``> X<backtick> X<glob>
2866
2867 In scalar context, evaluating a filehandle in angle brackets yields
2868 the next line from that file (the newline, if any, included), or
2869 C<undef> at end-of-file or on error.  When C<$/> is set to C<undef>
2870 (sometimes known as file-slurp mode) and the file is empty, it
2871 returns C<''> the first time, followed by C<undef> subsequently.
2872
2873 Ordinarily you must assign the returned value to a variable, but
2874 there is one situation where an automatic assignment happens.  If
2875 and only if the input symbol is the only thing inside the conditional
2876 of a C<while> statement (even if disguised as a C<for(;;)> loop),
2877 the value is automatically assigned to the global variable $_,
2878 destroying whatever was there previously.  (This may seem like an
2879 odd thing to you, but you'll use the construct in almost every Perl
2880 script you write.)  The $_ variable is not implicitly localized.
2881 You'll have to put a C<local $_;> before the loop if you want that
2882 to happen.
2883
2884 The following lines are equivalent:
2885
2886     while (defined($_ = <STDIN>)) { print; }
2887     while ($_ = <STDIN>) { print; }
2888     while (<STDIN>) { print; }
2889     for (;<STDIN>;) { print; }
2890     print while defined($_ = <STDIN>);
2891     print while ($_ = <STDIN>);
2892     print while <STDIN>;
2893
2894 This also behaves similarly, but assigns to a lexical variable 
2895 instead of to C<$_>:
2896
2897     while (my $line = <STDIN>) { print $line }
2898
2899 In these loop constructs, the assigned value (whether assignment
2900 is automatic or explicit) is then tested to see whether it is
2901 defined.  The defined test avoids problems where the line has a string
2902 value that would be treated as false by Perl; for example a "" or
2903 a "0" with no trailing newline.  If you really mean for such values
2904 to terminate the loop, they should be tested for explicitly:
2905
2906     while (($_ = <STDIN>) ne '0') { ... }
2907     while (<STDIN>) { last unless $_; ... }
2908
2909 In other boolean contexts, C<< <FILEHANDLE> >> without an
2910 explicit C<defined> test or comparison elicits a warning if the
2911 C<use warnings> pragma or the B<-w>
2912 command-line switch (the C<$^W> variable) is in effect.
2913
2914 The filehandles STDIN, STDOUT, and STDERR are predefined.  (The
2915 filehandles C<stdin>, C<stdout>, and C<stderr> will also work except
2916 in packages, where they would be interpreted as local identifiers
2917 rather than global.)  Additional filehandles may be created with
2918 the open() function, amongst others.  See L<perlopentut> and
2919 L<perlfunc/open> for details on this.
2920 X<stdin> X<stdout> X<sterr>
2921
2922 If a <FILEHANDLE> is used in a context that is looking for
2923 a list, a list comprising all input lines is returned, one line per
2924 list element.  It's easy to grow to a rather large data space this
2925 way, so use with care.
2926
2927 <FILEHANDLE> may also be spelled C<readline(*FILEHANDLE)>.
2928 See L<perlfunc/readline>.
2929
2930 The null filehandle <> is special: it can be used to emulate the
2931 behavior of B<sed> and B<awk>, and any other Unix filter program
2932 that takes a list of filenames, doing the same to each line
2933 of input from all of them.  Input from <> comes either from
2934 standard input, or from each file listed on the command line.  Here's
2935 how it works: the first time <> is evaluated, the @ARGV array is
2936 checked, and if it is empty, C<$ARGV[0]> is set to "-", which when opened
2937 gives you standard input.  The @ARGV array is then processed as a list
2938 of filenames.  The loop
2939
2940     while (<>) {
2941         ...                     # code for each line
2942     }
2943
2944 is equivalent to the following Perl-like pseudo code:
2945
2946     unshift(@ARGV, '-') unless @ARGV;
2947     while ($ARGV = shift) {
2948         open(ARGV, $ARGV);
2949         while (<ARGV>) {
2950             ...         # code for each line
2951         }
2952     }
2953
2954 except that it isn't so cumbersome to say, and will actually work.
2955 It really does shift the @ARGV array and put the current filename
2956 into the $ARGV variable.  It also uses filehandle I<ARGV>
2957 internally. <> is just a synonym for <ARGV>, which
2958 is magical.  (The pseudo code above doesn't work because it treats
2959 <ARGV> as non-magical.)
2960
2961 Since the null filehandle uses the two argument form of L<perlfunc/open>
2962 it interprets special characters, so if you have a script like this:
2963
2964     while (<>) {
2965         print;
2966     }
2967
2968 and call it with C<perl dangerous.pl 'rm -rfv *|'>, it actually opens a
2969 pipe, executes the C<rm> command and reads C<rm>'s output from that pipe.
2970 If you want all items in C<@ARGV> to be interpreted as file names, you
2971 can use the module C<ARGV::readonly> from CPAN.
2972
2973 You can modify @ARGV before the first <> as long as the array ends up
2974 containing the list of filenames you really want.  Line numbers (C<$.>)
2975 continue as though the input were one big happy file.  See the example
2976 in L<perlfunc/eof> for how to reset line numbers on each file.
2977
2978 If you want to set @ARGV to your own list of files, go right ahead.
2979 This sets @ARGV to all plain text files if no @ARGV was given:
2980
2981     @ARGV = grep { -f && -T } glob('*') unless @ARGV;
2982
2983 You can even set them to pipe commands.  For example, this automatically
2984 filters compressed arguments through B<gzip>:
2985
2986     @ARGV = map { /\.(gz|Z)$/ ? "gzip -dc < $_ |" : $_ } @ARGV;
2987
2988 If you want to pass switches into your script, you can use one of the
2989 Getopts modules or put a loop on the front like this:
2990
2991     while ($_ = $ARGV[0], /^-/) {
2992         shift;
2993         last if /^--$/;
2994         if (/^-D(.*)/) { $debug = $1 }
2995         if (/^-v/)     { $verbose++  }
2996         # ...           # other switches
2997     }
2998
2999     while (<>) {
3000         # ...           # code for each line
3001     }
3002
3003 The <> symbol will return C<undef> for end-of-file only once.
3004 If you call it again after this, it will assume you are processing another
3005 @ARGV list, and if you haven't set @ARGV, will read input from STDIN.
3006
3007 If what the angle brackets contain is a simple scalar variable (for example,
3008 <$foo>), then that variable contains the name of the
3009 filehandle to input from, or its typeglob, or a reference to the
3010 same.  For example:
3011
3012     $fh = \*STDIN;
3013     $line = <$fh>;
3014
3015 If what's within the angle brackets is neither a filehandle nor a simple
3016 scalar variable containing a filehandle name, typeglob, or typeglob
3017 reference, it is interpreted as a filename pattern to be globbed, and
3018 either a list of filenames or the next filename in the list is returned,
3019 depending on context.  This distinction is determined on syntactic
3020 grounds alone.  That means C<< <$x> >> is always a readline() from
3021 an indirect handle, but C<< <$hash{key}> >> is always a glob().
3022 That's because $x is a simple scalar variable, but C<$hash{key}> is
3023 not--it's a hash element.  Even C<< <$x > >> (note the extra space)
3024 is treated as C<glob("$x ")>, not C<readline($x)>.
3025
3026 One level of double-quote interpretation is done first, but you can't
3027 say C<< <$foo> >> because that's an indirect filehandle as explained
3028 in the previous paragraph.  (In older versions of Perl, programmers
3029 would insert curly brackets to force interpretation as a filename glob:
3030 C<< <${foo}> >>.  These days, it's considered cleaner to call the
3031 internal function directly as C<glob($foo)>, which is probably the right
3032 way to have done it in the first place.)  For example:
3033
3034     while (<*.c>) {
3035         chmod 0644, $_;
3036     }
3037
3038 is roughly equivalent to:
3039
3040     open(FOO, "echo *.c | tr -s ' \t\r\f' '\\012\\012\\012\\012'|");
3041     while (<FOO>) {
3042         chomp;
3043         chmod 0644, $_;
3044     }
3045
3046 except that the globbing is actually done internally using the standard
3047 C<File::Glob> extension.  Of course, the shortest way to do the above is:
3048
3049     chmod 0644, <*.c>;
3050
3051 A (file)glob evaluates its (embedded) argument only when it is
3052 starting a new list.  All values must be read before it will start
3053 over.  In list context, this isn't important because you automatically
3054 get them all anyway.  However, in scalar context the operator returns
3055 the next value each time it's called, or C<undef> when the list has
3056 run out.  As with filehandle reads, an automatic C<defined> is
3057 generated when the glob occurs in the test part of a C<while>,
3058 because legal glob returns (for example,
3059 a file called F<0>) would otherwise
3060 terminate the loop.  Again, C<undef> is returned only once.  So if
3061 you're expecting a single value from a glob, it is much better to
3062 say
3063
3064     ($file) = <blurch*>;
3065
3066 than
3067
3068     $file = <blurch*>;
3069
3070 because the latter will alternate between returning a filename and
3071 returning false.
3072
3073 If you're trying to do variable interpolation, it's definitely better
3074 to use the glob() function, because the older notation can cause people
3075 to become confused with the indirect filehandle notation.
3076
3077     @files = glob("$dir/*.[ch]");
3078     @files = glob($files[$i]);
3079
3080 =head2 Constant Folding
3081 X<constant folding> X<folding>
3082
3083 Like C, Perl does a certain amount of expression evaluation at
3084 compile time whenever it determines that all arguments to an
3085 operator are static and have no side effects.  In particular, string
3086 concatenation happens at compile time between literals that don't do
3087 variable substitution.  Backslash interpolation also happens at
3088 compile time.  You can say
3089
3090       'Now is the time for all'
3091     . "\n" 
3092     .  'good men to come to.'
3093
3094 and this all reduces to one string internally.  Likewise, if
3095 you say
3096
3097     foreach $file (@filenames) {
3098         if (-s $file > 5 + 100 * 2**16) {  }
3099     }
3100
3101 the compiler precomputes the number which that expression
3102 represents so that the interpreter won't have to.
3103
3104 =head2 No-ops
3105 X<no-op> X<nop>
3106
3107 Perl doesn't officially have a no-op operator, but the bare constants
3108 C<0> and C<1> are special-cased not to produce a warning in void
3109 context, so you can for example safely do
3110
3111     1 while foo();
3112
3113 =head2 Bitwise String Operators
3114 X<operator, bitwise, string>
3115
3116 Bitstrings of any size may be manipulated by the bitwise operators
3117 (C<~ | & ^>).
3118
3119 If the operands to a binary bitwise op are strings of different
3120 sizes, B<|> and B<^> ops act as though the shorter operand had
3121 additional zero bits on the right, while the B<&> op acts as though
3122 the longer operand were truncated to the length of the shorter.
3123 The granularity for such extension or truncation is one or more
3124 bytes.
3125
3126     # ASCII-based examples
3127     print "j p \n" ^ " a h";            # prints "JAPH\n"
3128     print "JA" | "  ph\n";              # prints "japh\n"
3129     print "japh\nJunk" & '_____';       # prints "JAPH\n";
3130     print 'p N$' ^ " E<H\n";            # prints "Perl\n";
3131
3132 If you are intending to manipulate bitstrings, be certain that
3133 you're supplying bitstrings: If an operand is a number, that will imply
3134 a B<numeric> bitwise operation.  You may explicitly show which type of
3135 operation you intend by using C<""> or C<0+>, as in the examples below.
3136
3137     $foo =  150  |  105;        # yields 255  (0x96 | 0x69 is 0xFF)
3138     $foo = '150' |  105;        # yields 255
3139     $foo =  150  | '105';       # yields 255
3140     $foo = '150' | '105';       # yields string '155' (under ASCII)
3141
3142     $baz = 0+$foo & 0+$bar;     # both ops explicitly numeric
3143     $biz = "$foo" ^ "$bar";     # both ops explicitly stringy
3144
3145 See L<perlfunc/vec> for information on how to manipulate individual bits
3146 in a bit vector.
3147
3148 =head2 Integer Arithmetic
3149 X<integer>
3150
3151 By default, Perl assumes that it must do most of its arithmetic in
3152 floating point.  But by saying
3153
3154     use integer;
3155
3156 you may tell the compiler to use integer operations
3157 (see L<integer> for a detailed explanation) from here to the end of
3158 the enclosing BLOCK.  An inner BLOCK may countermand this by saying
3159
3160     no integer;
3161
3162 which lasts until the end of that BLOCK.  Note that this doesn't
3163 mean everything is an integer, merely that Perl will use integer
3164 operations for arithmetic, comparison, and bitwise operators.  For
3165 example, even under C<use integer>, if you take the C<sqrt(2)>, you'll
3166 still get C<1.4142135623731> or so.
3167
3168 Used on numbers, the bitwise operators ("&", "|", "^", "~", "<<",
3169 and ">>") always produce integral results.  (But see also
3170 L<Bitwise String Operators>.)  However, C<use integer> still has meaning for
3171 them.  By default, their results are interpreted as unsigned integers, but
3172 if C<use integer> is in effect, their results are interpreted
3173 as signed integers.  For example, C<~0> usually evaluates to a large
3174 integral value.  However, C<use integer; ~0> is C<-1> on two's-complement
3175 machines.
3176
3177 =head2 Floating-point Arithmetic
3178
3179 X<floating-point> X<floating point> X<float> X<real>
3180
3181 While C<use integer> provides integer-only arithmetic, there is no
3182 analogous mechanism to provide automatic rounding or truncation to a
3183 certain number of decimal places.  For rounding to a certain number
3184 of digits, sprintf() or printf() is usually the easiest route.
3185 See L<perlfaq4>.
3186
3187 Floating-point numbers are only approximations to what a mathematician
3188 would call real numbers.  There are infinitely more reals than floats,
3189 so some corners must be cut.  For example:
3190
3191     printf "%.20g\n", 123456789123456789;
3192     #        produces 123456789123456784
3193
3194 Testing for exact floating-point equality or inequality is not a
3195 good idea.  Here's a (relatively expensive) work-around to compare
3196 whether two floating-point numbers are equal to a particular number of
3197 decimal places.  See Knuth, volume II, for a more robust treatment of
3198 this topic.
3199
3200     sub fp_equal {
3201         my ($X, $Y, $POINTS) = @_;
3202         my ($tX, $tY);
3203         $tX = sprintf("%.${POINTS}g", $X);
3204         $tY = sprintf("%.${POINTS}g", $Y);
3205         return $tX eq $tY;
3206     }
3207
3208 The POSIX module (part of the standard perl distribution) implements
3209 ceil(), floor(), and other mathematical and trigonometric functions.
3210 The Math::Complex module (part of the standard perl distribution)
3211 defines mathematical functions that work on both the reals and the
3212 imaginary numbers.  Math::Complex not as efficient as POSIX, but
3213 POSIX can't work with complex numbers.
3214
3215 Rounding in financial applications can have serious implications, and
3216 the rounding method used should be specified precisely.  In these
3217 cases, it probably pays not to trust whichever system rounding is
3218 being used by Perl, but to instead implement the rounding function you
3219 need yourself.
3220
3221 =head2 Bigger Numbers
3222 X<number, arbitrary precision>
3223
3224 The standard C<Math::BigInt>, C<Math::BigRat>, and C<Math::BigFloat> modules,
3225 along with the C<bignum>, C<bigint>, and C<bigrat> pragmas, provide
3226 variable-precision arithmetic and overloaded operators, although
3227 they're currently pretty slow. At the cost of some space and
3228 considerable speed, they avoid the normal pitfalls associated with
3229 limited-precision representations.
3230
3231         use 5.010;
3232         use bigint;  # easy interface to Math::BigInt
3233         $x = 123456789123456789;
3234         say $x * $x;
3235     +15241578780673678515622620750190521
3236
3237 Or with rationals:
3238
3239         use 5.010;
3240         use bigrat;
3241         $a = 3/22;
3242         $b = 4/6;
3243         say "a/b is ", $a/$b;
3244         say "a*b is ", $a*$b;
3245     a/b is 9/44
3246     a*b is 1/11
3247
3248 Several modules let you calculate with (bound only by memory and CPU time)
3249 unlimited or fixed precision. There are also some non-standard modules that
3250 provide faster implementations via external C libraries.
3251
3252 Here is a short, but incomplete summary:
3253
3254   Math::String           treat string sequences like numbers
3255   Math::FixedPrecision   calculate with a fixed precision
3256   Math::Currency         for currency calculations
3257   Bit::Vector            manipulate bit vectors fast (uses C)
3258   Math::BigIntFast       Bit::Vector wrapper for big numbers
3259   Math::Pari             provides access to the Pari C library
3260   Math::Cephes           uses the external Cephes C library (no
3261                          big numbers)
3262   Math::Cephes::Fraction fractions via the Cephes library
3263   Math::GMP              another one using an external C library
3264   Math::GMPz             an alternative interface to libgmp's big ints
3265   Math::GMPq             an interface to libgmp's fraction numbers
3266   Math::GMPf             an interface to libgmp's floating point numbers
3267
3268 Choose wisely.
3269
3270 =cut