Make tests for gmagic on sub exit count fetches
[perl.git] / t / op / gmagic.t
1 #!./perl -w
2
3 BEGIN {
4     chdir 't' if -d 't';
5     @INC = '../lib';
6     require './test.pl';
7 }
8
9 use strict;
10
11 tie my $c => 'Tie::Monitor';
12
13 sub expected_tie_calls {
14     my ($obj, $rexp, $wexp, $tn) = @_;
15     local $::Level = $::Level + 1;
16     my ($rgot, $wgot) = $obj->init();
17     is ($rgot, $rexp, $tn ? "number of fetches when $tn" : ());
18     is ($wgot, $wexp, $tn ? "number of stores when $tn" : ());
19 }
20
21 # Use ok() instead of is(), cmp_ok() etc, to strictly control number of accesses
22 my($r, $s);
23 ok($r = $c + 0 == 0, 'the thing itself');
24 expected_tie_calls(tied $c, 1, 0);
25 ok($r = "$c" eq '0', 'the thing itself');
26 expected_tie_calls(tied $c, 1, 0);
27
28 ok($c . 'x' eq '0x', 'concat');
29 expected_tie_calls(tied $c, 1, 0);
30 ok('x' . $c eq 'x0', 'concat');
31 expected_tie_calls(tied $c, 1, 0);
32 $s = $c . $c;
33 ok($s eq '00', 'concat');
34 expected_tie_calls(tied $c, 2, 0);
35 $r = 'x';
36 $s = $c = $r . 'y';
37 ok($s eq 'xy', 'concat');
38 expected_tie_calls(tied $c, 1, 1);
39 $s = $c = $c . 'x';
40 ok($s eq '0x', 'concat');
41 expected_tie_calls(tied $c, 2, 1);
42 $s = $c = 'x' . $c;
43 ok($s eq 'x0', 'concat');
44 expected_tie_calls(tied $c, 2, 1);
45 $s = $c = $c . $c;
46 ok($s eq '00', 'concat');
47 expected_tie_calls(tied $c, 3, 1);
48
49 $s = chop($c);
50 ok($s eq '0', 'multiple magic in core functions');
51 expected_tie_calls(tied $c, 1, 1);
52
53 $c = *strat;
54 $s = $c;
55 ok($s eq *strat,
56    'Assignment should not ignore magic when the last thing assigned was a glob');
57 expected_tie_calls(tied $c, 1, 1);
58
59 # A plain *foo should not call get-magic on *foo.
60 # This method of scalar-tying an immutable glob relies on details of the
61 # current implementation that are subject to change. This test may need to
62 # be rewritten if they do change.
63 my $tyre = tie $::{gelp} => 'Tie::Monitor';
64 # Compilation of this eval autovivifies the *gelp glob.
65 eval '$tyre->init(0); () = \*gelp';
66 my($rgot, $wgot) = $tyre->init(0);
67 ok($rgot == 0, 'a plain *foo causes no get-magic');
68 ok($wgot == 0, 'a plain *foo causes no set-magic');
69
70 # get-magic when exiting a non-lvalue sub in potentially autovivify-
71 # ing context
72 {
73   no strict;
74
75   my $tied_to = tie $_{elem}, "Tie::Monitor";
76   () = sub { delete $_{elem} }->()->[3];
77   expected_tie_calls $tied_to, 1, 0,
78      'mortal magic var is implicitly returned in autoviv context';
79
80   $tied_to = tie $_{elem}, "Tie::Monitor";
81   () = sub { return delete $_{elem} }->()->[3];
82   expected_tie_calls $tied_to, 1, 0,
83       'mortal magic var is explicitly returned in autoviv context';
84 }
85
86 done_testing();
87
88 # adapted from Tie::Counter by Abigail
89 package Tie::Monitor;
90
91 sub TIESCALAR {
92     my($class, $value) = @_;
93     bless {
94         read => 0,
95         write => 0,
96         values => [ 0 ],
97     };
98 }
99
100 sub FETCH {
101     my $self = shift;
102     ++$self->{read};
103     $self->{values}[$#{ $self->{values} }];
104 }
105
106 sub STORE {
107     my($self, $value) = @_;
108     ++$self->{write};
109     push @{ $self->{values} }, $value;
110 }
111
112 sub init {
113     my $self = shift;
114     my @results = ($self->{read}, $self->{write});
115     $self->{read} = $self->{write} = 0;
116     $self->{values} = [ 0 ];
117     @results;
118 }