Improve comment for skipped test on Solaris in t/io/eintr.t
[perl.git] / t / io / eintr.t
1 #!./perl
2
3 # If a read or write is interrupted by a signal, Perl will call the
4 # signal handler and then attempt to restart the call. If the handler does
5 # something nasty like close the handle or pop layers, make sure that the
6 # read/write handles this gracefully (for some definition of 'graceful':
7 # principally, don't segfault).
8
9 BEGIN {
10     chdir 't' if -d 't';
11     @INC = '../lib';
12 }
13
14 use warnings;
15 use strict;
16 use Config;
17
18 require './test.pl';
19
20 my $piped;
21 eval {
22         pipe my $in, my $out;
23         $piped = 1;
24 };
25 if (!$piped) {
26         skip_all('pipe not implemented');
27         exit 0;
28 }
29 unless (exists  $Config{'d_alarm'}) {
30         skip_all('alarm not implemented');
31         exit 0;
32 }
33
34 # XXX for some reason the stdio layer doesn't seem to interrupt
35 # write system call when the alarm triggers.  This makes the tests
36 # hang.
37
38 if (exists $ENV{PERLIO} && $ENV{PERLIO} =~ /stdio/  ) {
39         skip_all('stdio not supported for this script');
40         exit 0;
41 }
42
43 # on Win32, alarm() won't interrupt the read/write call.
44 # Similar issues with VMS.
45 # On FreeBSD, writes to pipes of 8192 bytes or more use a mechanism
46 # that is not interruptible (see perl #85842 and #84688).
47 # "close during print" also hangs on Solaris 8 (but not 10 or 11).
48
49 if ($^O eq 'VMS' || $^O eq 'MSWin32' || $^O eq 'cygwin' || $^O eq 'freebsd' || 
50      ($^O eq 'solaris' && $Config{osvers} eq '2.8') ) {
51         skip_all('various portability issues');
52         exit 0;
53 }
54
55 my ($in, $out, $st, $sigst, $buf);
56
57 plan(tests => 10);
58
59
60 # make two handles that will always block
61
62 sub fresh_io {
63         undef $in; undef $out; # use fresh handles each time
64         pipe $in, $out;
65         $sigst = "";
66 }
67
68 $SIG{PIPE} = 'IGNORE';
69
70 # close during read
71
72 fresh_io;
73 $SIG{ALRM} = sub { $sigst = close($in) ? "ok" : "nok" };
74 alarm(1);
75 $st = read($in, $buf, 1);
76 alarm(0);
77 is($sigst, 'ok', 'read/close: sig handler close status');
78 ok(!$st, 'read/close: read status');
79 ok(!close($in), 'read/close: close status');
80
81 # die during read
82
83 fresh_io;
84 $SIG{ALRM} = sub { die };
85 alarm(1);
86 $st = eval { read($in, $buf, 1) };
87 alarm(0);
88 ok(!$st, 'read/die: read status');
89 ok(close($in), 'read/die: close status');
90
91 # close during print
92
93 fresh_io;
94 $SIG{ALRM} = sub { $sigst = close($out) ? "ok" : "nok" };
95 $buf = "a" x 1_000_000 . "\n"; # bigger than any pipe buffer hopefully
96 select $out; $| = 1; select STDOUT;
97 alarm(1);
98 $st = print $out $buf;
99 alarm(0);
100 is($sigst, 'nok', 'print/close: sig handler close status');
101 ok(!$st, 'print/close: print status');
102 ok(!close($out), 'print/close: close status');
103
104 # die during print
105
106 fresh_io;
107 $SIG{ALRM} = sub { die };
108 $buf = "a" x 1_000_000 . "\n"; # bigger than any pipe buffer hopefully
109 select $out; $| = 1; select STDOUT;
110 alarm(1);
111 $st = eval { print $out $buf };
112 alarm(0);
113 ok(!$st, 'print/die: print status');
114 # the close will hang since there's data to flush, so use alarm
115 alarm(1);
116 ok(!eval {close($out)}, 'print/die: close status');
117 alarm(0);
118
119 # close during close
120
121 # Apparently there's nothing in standard Linux that can cause an
122 # EINTR in close(2); but run the code below just in case it does on some
123 # platform, just to see if it segfaults.
124 fresh_io;
125 $SIG{ALRM} = sub { $sigst = close($in) ? "ok" : "nok" };
126 alarm(1);
127 close $in;
128 alarm(0);
129
130 # die during close
131
132 fresh_io;
133 $SIG{ALRM} = sub { die };
134 alarm(1);
135 eval { close $in };
136 alarm(0);
137
138 # vim: ts=4 sts=4 sw=4: