perl 5.003_03: perl.h
[perl.git] / pod / perlfunc.pod
1 =head1 NAME
2
3 perlfunc - Perl builtin functions
4
5 =head1 DESCRIPTION
6
7 The functions in this section can serve as terms in an expression.
8 They fall into two major categories: list operators and named unary
9 operators.  These differ in their precedence relationship with a
10 following comma.  (See the precedence table in L<perlop>.)  List
11 operators take more than one argument, while unary operators can never
12 take more than one argument.  Thus, a comma terminates the argument of
13 a unary operator, but merely separates the arguments of a list
14 operator.  A unary operator generally provides a scalar context to its
15 argument, while a list operator may provide either scalar and list
16 contexts for its arguments.  If it does both, the scalar arguments will
17 be first, and the list argument will follow.  (Note that there can only
18 ever be one list argument.)  For instance, splice() has three scalar
19 arguments followed by a list.
20
21 In the syntax descriptions that follow, list operators that expect a
22 list (and provide list context for the elements of the list) are shown
23 with LIST as an argument.  Such a list may consist of any combination
24 of scalar arguments or list values; the list values will be included
25 in the list as if each individual element were interpolated at that
26 point in the list, forming a longer single-dimensional list value.
27 Elements of the LIST should be separated by commas.
28
29 Any function in the list below may be used either with or without
30 parentheses around its arguments.  (The syntax descriptions omit the
31 parens.)  If you use the parens, the simple (but occasionally
32 surprising) rule is this: It I<LOOKS> like a function, therefore it I<IS> a
33 function, and precedence doesn't matter.  Otherwise it's a list
34 operator or unary operator, and precedence does matter.  And whitespace
35 between the function and left parenthesis doesn't count--so you need to
36 be careful sometimes:
37
38     print 1+2+3;        # Prints 6.
39     print(1+2) + 3;     # Prints 3.
40     print (1+2)+3;      # Also prints 3!
41     print +(1+2)+3;     # Prints 6.
42     print ((1+2)+3);    # Prints 6.
43
44 If you run Perl with the B<-w> switch it can warn you about this.  For
45 example, the third line above produces:
46
47     print (...) interpreted as function at - line 1.
48     Useless use of integer addition in void context at - line 1.
49
50 For functions that can be used in either a scalar or list context,
51 non-abortive failure is generally indicated in a scalar context by
52 returning the undefined value, and in a list context by returning the
53 null list.
54
55 Remember the following rule:
56
57 =over 8
58
59 =item  
60
61 I<THERE IS NO GENERAL RULE FOR CONVERTING A LIST INTO A SCALAR!>
62
63 =back
64
65 Each operator and function decides which sort of value it would be most
66 appropriate to return in a scalar context.  Some operators return the
67 length of the list that would have been returned in a list context.  Some
68 operators return the first value in the list.  Some operators return the
69 last value in the list.  Some operators return a count of successful
70 operations.  In general, they do what you want, unless you want
71 consistency.
72
73 =head2 Perl Functions by Category
74
75 Here are Perl's functions (including things that look like
76 functions, like some of the keywords and named operators)
77 arranged by category.  Some functions appear in more
78 than one place.
79
80 =over
81
82 =item Functions for SCALARs or strings
83
84 chomp, chop, chr, crypt, hex, index, lc, lcfirst, length,
85 oct, ord, pack, q/STRING/, qq/STRING/, reverse, rindex,
86 sprintf, substr, tr///, uc, ucfirst, y///
87
88 =item Regular expressions and pattern matching
89
90 m//, pos, quotemeta, s///, split, study
91
92 =item Numeric functions
93
94 abs, atan2, cos, exp, hex, int, log, oct, rand, sin, sqrt,
95 srand
96
97 =item Functions for real @ARRAYs
98
99 pop, push, shift, splice, unshift
100
101 =item Functions for list data
102
103 grep, join, map, qw/STRING/, reverse, sort, unpack
104
105 =item Functions for real %HASHes
106
107 delete, each, exists, keys, values
108
109 =item Input and output functions
110
111 binmode, close, closedir, dbmclose, dbmopen, die, eof,
112 fileno, flock, format, getc, print, printf, read, readdir,
113 rewinddir, seek, seekdir, select, syscall, sysread,
114 syswrite, tell, telldir, truncate, warn, write
115
116 =item Functions for fixed length data or records
117
118 pack, read, syscall, sysread, syswrite, unpack, vec
119
120 =item Functions for filehandles, files, or directories
121
122 I<-X>, chdir, chmod, chown, chroot, fcntl, glob, ioctl, link,
123 lstat, mkdir, open, opendir, readlink, rename, rmdir,
124 stat, symlink, umask, unlink, utime
125
126 =item Keywords related to the control flow of your perl program
127
128 caller, continue, die, do, dump, eval, exit, goto, last,
129 next, redo, return, sub, wantarray
130
131 =item Keywords related to scoping 
132
133 caller, import, local, my, package, use
134
135 =item Miscellaneous functions
136
137 defined, dump, eval, formline, local, my, reset, scalar,
138 undef, wantarray
139
140 =item Functions for processes and process groups
141
142 alarm, exec, fork, getpgrp, getppid, getpriority, kill,
143 pipe, qx/STRING/, setpgrp, setpriority, sleep, system,
144 times, wait, waitpid
145
146 =item Keywords related to perl modules
147
148 do, import, no, package, require, use
149
150 =item Keywords related to classes and object-orientedness
151
152 bless, dbmclose, dbmopen, package, ref, tie, tied, untie, use
153
154 =item Low-level socket functions
155
156 accept, bind, connect, getpeername, getsockname,
157 getsockopt, listen, recv, send, setsockopt, shutdown,
158 socket, socketpair
159
160 =item System V interprocess communication functions
161
162 msgctl, msgget, msgrcv, msgsnd, semctl, semget, semop,
163 shmctl, shmget, shmread, shmwrite
164
165 =item Fetching user and group info
166
167 endgrent, endhostent, endnetent, endpwent, getgrent,
168 getgrgid, getgrnam, getlogin, getpwent, getpwnam,
169 getpwuid, setgrent, setpwent
170
171 =item Fetching network info
172
173 endprotoent, endservent, gethostbyaddr, gethostbyname,
174 gethostent, getnetbyaddr, getnetbyname, getnetent,
175 getprotobyname, getprotobynumber, getprotoent,
176 getservbyname, getservbyport, getservent, sethostent,
177 setnetent, setprotoent, setservent
178
179 =item Time-related functions
180
181 gmtime, localtime, time, times
182
183 =item Functions new in perl5
184
185 abs, bless, chomp, chr, exists, formline, glob, import, lc,
186 lcfirst, map, my, no, prototype, qx, qw, readline, readpipe,
187 ref, sub*, sysopen, tie, tied, uc, ucfirst, untie, use
188
189 * - C<sub> was a keyword in perl4, but in perl5 it is an
190 operator which can be used in expressions.
191
192 =item Functions obsoleted in perl5
193
194 dbmclose, dbmopen
195
196
197 =back
198
199 =head2 Alphabetical Listing of Perl Functions
200
201
202 =over 8
203
204 =item -X FILEHANDLE
205
206 =item -X EXPR
207
208 =item -X
209
210 A file test, where X is one of the letters listed below.  This unary
211 operator takes one argument, either a filename or a filehandle, and
212 tests the associated file to see if something is true about it.  If the
213 argument is omitted, tests $_, except for C<-t>, which tests STDIN.
214 Unless otherwise documented, it returns C<1> for TRUE and C<''> for FALSE, or
215 the undefined value if the file doesn't exist.  Despite the funny
216 names, precedence is the same as any other named unary operator, and
217 the argument may be parenthesized like any other unary operator.  The
218 operator may be any of:
219
220     -r  File is readable by effective uid/gid.
221     -w  File is writable by effective uid/gid.
222     -x  File is executable by effective uid/gid.
223     -o  File is owned by effective uid.
224
225     -R  File is readable by real uid/gid.
226     -W  File is writable by real uid/gid.
227     -X  File is executable by real uid/gid.
228     -O  File is owned by real uid.
229
230     -e  File exists.
231     -z  File has zero size.
232     -s  File has non-zero size (returns size).
233
234     -f  File is a plain file.
235     -d  File is a directory.
236     -l  File is a symbolic link.
237     -p  File is a named pipe (FIFO).
238     -S  File is a socket.
239     -b  File is a block special file.
240     -c  File is a character special file.
241     -t  Filehandle is opened to a tty.
242
243     -u  File has setuid bit set.
244     -g  File has setgid bit set.
245     -k  File has sticky bit set.
246
247     -T  File is a text file.
248     -B  File is a binary file (opposite of -T).
249
250     -M  Age of file in days when script started.
251     -A  Same for access time.
252     -C  Same for inode change time.
253
254 The interpretation of the file permission operators C<-r>, C<-R>, C<-w>,
255 C<-W>, C<-x> and C<-X> is based solely on the mode of the file and the
256 uids and gids of the user.  There may be other reasons you can't actually
257 read, write or execute the file.  Also note that, for the superuser,
258 C<-r>, C<-R>, C<-w> and C<-W> always return 1, and C<-x> and C<-X> return
259 1 if any execute bit is set in the mode.  Scripts run by the superuser may
260 thus need to do a stat() in order to determine the actual mode of the
261 file, or temporarily set the uid to something else.
262
263 Example:
264
265     while (<>) {
266         chop;
267         next unless -f $_;      # ignore specials
268         ...
269     }
270
271 Note that C<-s/a/b/> does not do a negated substitution.  Saying
272 C<-exp($foo)> still works as expected, however--only single letters
273 following a minus are interpreted as file tests.
274
275 The C<-T> and C<-B> switches work as follows.  The first block or so of the
276 file is examined for odd characters such as strange control codes or
277 characters with the high bit set.  If too many odd characters (>30%)
278 are found, it's a C<-B> file, otherwise it's a C<-T> file.  Also, any file
279 containing null in the first block is considered a binary file.  If C<-T>
280 or C<-B> is used on a filehandle, the current stdio buffer is examined
281 rather than the first block.  Both C<-T> and C<-B> return TRUE on a null
282 file, or a file at EOF when testing a filehandle.  Because you have to 
283 read a file to do the C<-T> test, on most occasions you want to use a C<-f>
284 against the file first, as in C<next unless -f $file && -T $file>.
285
286 If any of the file tests (or either the stat() or lstat() operators) are given the
287 special filehandle consisting of a solitary underline, then the stat
288 structure of the previous file test (or stat operator) is used, saving
289 a system call.  (This doesn't work with C<-t>, and you need to remember
290 that lstat() and C<-l> will leave values in the stat structure for the
291 symbolic link, not the real file.)  Example:
292
293     print "Can do.\n" if -r $a || -w _ || -x _;
294
295     stat($filename);
296     print "Readable\n" if -r _;
297     print "Writable\n" if -w _;
298     print "Executable\n" if -x _;
299     print "Setuid\n" if -u _;
300     print "Setgid\n" if -g _;
301     print "Sticky\n" if -k _;
302     print "Text\n" if -T _;
303     print "Binary\n" if -B _;
304
305 =item abs VALUE
306
307 Returns the absolute value of its argument.
308
309 =item accept NEWSOCKET,GENERICSOCKET
310
311 Accepts an incoming socket connect, just as the accept(2) system call
312 does.  Returns the packed address if it succeeded, FALSE otherwise.
313 See example in L<perlipc/"Sockets: Client/Server Communication">.
314
315 =item alarm SECONDS
316
317 Arranges to have a SIGALRM delivered to this process after the
318 specified number of seconds have elapsed.  (On some machines,
319 unfortunately, the elapsed time may be up to one second less than you
320 specified because of how seconds are counted.)  Only one timer may be
321 counting at once.  Each call disables the previous timer, and an
322 argument of 0 may be supplied to cancel the previous timer without
323 starting a new one.  The returned value is the amount of time remaining
324 on the previous timer.
325
326 For delays of finer granularity than one second, you may use Perl's
327 syscall() interface to access setitimer(2) if your system supports it, 
328 or else see L</select()> below.  It is not advised to intermix alarm() 
329 and sleep() calls.
330
331 =item atan2 Y,X
332
333 Returns the arctangent of Y/X in the range -PI to PI.
334
335 =item bind SOCKET,NAME
336
337 Binds a network address to a socket, just as the bind system call
338 does.  Returns TRUE if it succeeded, FALSE otherwise.  NAME should be a
339 packed address of the appropriate type for the socket.  See the examples in
340 L<perlipc/"Sockets: Client/Server Communication">.
341
342 =item binmode FILEHANDLE
343
344 Arranges for the file to be read or written in "binary" mode in operating
345 systems that distinguish between binary and text files.  Files that are
346 not in binary mode have CR LF sequences translated to LF on input and LF
347 translated to CR LF on output.  Binmode has no effect under Unix; in DOS
348 and similarly archaic systems, it may be imperative--otherwise your
349 DOS-damaged C library may mangle your file.  The key distinction between
350 systems that need binmode and those that don't is their text file
351 formats.  Systems like Unix and Plan9 that delimit lines with a single
352 character, and that encode that character in C as '\n', do not need
353 C<binmode>.  The rest need it.  If FILEHANDLE is an expression, the value
354 is taken as the name of the filehandle.
355
356 =item bless REF,CLASSNAME
357
358 =item bless REF
359
360 This function tells the referenced object (passed as REF) that it is now
361 an object in the CLASSNAME package--or the current package if no CLASSNAME
362 is specified, which is often the case.  It returns the reference for
363 convenience, since a bless() is often the last thing in a constructor.
364 Always use the two-argument version if the function doing the blessing
365 might be inherited by a derived class.  See L<perlobj> for more about the
366 blessing (and blessings) of objects.
367
368 =item caller EXPR
369
370 =item caller
371
372 Returns the context of the current subroutine call.  In a scalar context,
373 returns TRUE if there is a caller, that is, if we're in a subroutine or
374 eval() or require(), and FALSE otherwise.  In a list context, returns
375
376     ($package, $filename, $line) = caller;
377
378 With EXPR, it returns some extra information that the debugger uses to
379 print a stack trace.  The value of EXPR indicates how many call frames
380 to go back before the current one.
381
382     ($package, $filename, $line,
383      $subroutine, $hasargs, $wantargs) = caller($i);
384
385 Furthermore, when called from within the DB package, caller returns more
386 detailed information: it sets the list variable @DB::args to be the
387 arguments with which that subroutine was invoked.
388
389 =item chdir EXPR
390
391 Changes the working directory to EXPR, if possible.  If EXPR is
392 omitted, changes to home directory.  Returns TRUE upon success, FALSE
393 otherwise.  See example under die().
394
395 =item chmod LIST
396
397 Changes the permissions of a list of files.  The first element of the
398 list must be the numerical mode, which should probably be an octal
399 number.  Returns the number of files successfully changed.
400
401     $cnt = chmod 0755, 'foo', 'bar';
402     chmod 0755, @executables;
403
404 =item chomp VARIABLE
405
406 =item chomp LIST
407
408 =item chomp
409
410 This is a slightly safer version of chop (see below).  It removes any
411 line ending that corresponds to the current value of C<$/> (also known as
412 $INPUT_RECORD_SEPARATOR in the C<English> module).  It returns the number
413 of characters removed.  It's often used to remove the newline from the
414 end of an input record when you're worried that the final record may be
415 missing its newline.  When in paragraph mode (C<$/ = "">), it removes all
416 trailing newlines from the string.  If VARIABLE is omitted, it chomps
417 $_.  Example:
418
419     while (<>) {
420         chomp;  # avoid \n on last field
421         @array = split(/:/);
422         ...
423     }
424
425 You can actually chomp anything that's an lvalue, including an assignment:
426
427     chomp($cwd = `pwd`);
428     chomp($answer = <STDIN>);
429
430 If you chomp a list, each element is chomped, and the total number of
431 characters removed is returned.
432
433 =item chop VARIABLE
434
435 =item chop LIST
436
437 =item chop
438
439 Chops off the last character of a string and returns the character
440 chopped.  It's used primarily to remove the newline from the end of an
441 input record, but is much more efficient than C<s/\n//> because it neither
442 scans nor copies the string.  If VARIABLE is omitted, chops $_.
443 Example:
444
445     while (<>) {
446         chop;   # avoid \n on last field
447         @array = split(/:/);
448         ...
449     }
450
451 You can actually chop anything that's an lvalue, including an assignment:
452
453     chop($cwd = `pwd`);
454     chop($answer = <STDIN>);
455
456 If you chop a list, each element is chopped.  Only the value of the
457 last chop is returned.
458
459 Note that chop returns the last character.  To return all but the last
460 character, use C<substr($string, 0, -1)>.
461
462 =item chown LIST
463
464 Changes the owner (and group) of a list of files.  The first two
465 elements of the list must be the I<NUMERICAL> uid and gid, in that order.
466 Returns the number of files successfully changed.
467
468     $cnt = chown $uid, $gid, 'foo', 'bar';
469     chown $uid, $gid, @filenames;
470
471 Here's an example that looks up non-numeric uids in the passwd file:
472
473     print "User: ";
474     chop($user = <STDIN>);
475     print "Files: "
476     chop($pattern = <STDIN>);
477
478     ($login,$pass,$uid,$gid) = getpwnam($user)
479         or die "$user not in passwd file";
480
481     @ary = <${pattern}>;        # expand filenames
482     chown $uid, $gid, @ary;
483
484 On most systems, you are not allowed to change the ownership of the 
485 file unless you're the superuser, although you should be able to change
486 the group to any of your secondary groups.  On insecure systems, these
487 restrictions may be relaxed, but this is not a portable assumption.
488
489 =item chr NUMBER
490
491 Returns the character represented by that NUMBER in the character set.
492 For example, C<chr(65)> is "A" in ASCII.
493
494 =item chroot FILENAME
495
496 This function works as the system call by the same name: it makes the
497 named directory the new root directory for all further pathnames that
498 begin with a "/" by your process and all of its children.  (It doesn't
499 change your current working directory is unaffected.)  For security
500 reasons, this call is restricted to the superuser.  If FILENAME is
501 omitted, does chroot to $_.
502
503 =item close FILEHANDLE
504
505 Closes the file or pipe associated with the file handle, returning TRUE
506 only if stdio successfully flushes buffers and closes the system file
507 descriptor.  You don't have to close FILEHANDLE if you are immediately
508 going to do another open() on it, since open() will close it for you.  (See
509 open().)  However, an explicit close on an input file resets the line
510 counter ($.), while the implicit close done by open() does not.  Also,
511 closing a pipe will wait for the process executing on the pipe to
512 complete, in case you want to look at the output of the pipe
513 afterwards.  Closing a pipe explicitly also puts the status value of
514 the command into C<$?>.  Example:
515
516     open(OUTPUT, '|sort >foo'); # pipe to sort
517     ...                         # print stuff to output
518     close OUTPUT;               # wait for sort to finish
519     open(INPUT, 'foo');         # get sort's results
520
521 FILEHANDLE may be an expression whose value gives the real filehandle name.
522
523 =item closedir DIRHANDLE
524
525 Closes a directory opened by opendir().
526
527 =item connect SOCKET,NAME
528
529 Attempts to connect to a remote socket, just as the connect system call
530 does.  Returns TRUE if it succeeded, FALSE otherwise.  NAME should be a
531 packed address of the appropriate type for the socket.  See the examples in
532 L<perlipc/"Sockets: Client/Server Communication">.
533
534 =item continue BLOCK
535
536 Actually a flow control statement rather than a function.  If there is a
537 C<continue> BLOCK attached to a BLOCK (typically in a C<while> or
538 C<foreach>), it is always executed just before the conditional is about to
539 be evaluated again, just like the third part of a C<for> loop in C.  Thus
540 it can be used to increment a loop variable, even when the loop has been
541 continued via the C<next> statement (which is similar to the C C<continue>
542 statement).
543
544 =item cos EXPR
545
546 Returns the cosine of EXPR (expressed in radians).  If EXPR is omitted
547 takes cosine of $_.
548
549 =item crypt PLAINTEXT,SALT
550
551 Encrypts a string exactly like the crypt(3) function in the C library
552 (assuming that you actually have a version there that has not been
553 extirpated as a potential munition).  This can prove useful for checking
554 the password file for lousy passwords, amongst other things.  Only the
555 guys wearing white hats should do this.
556
557 Here's an example that makes sure that whoever runs this program knows
558 their own password:
559
560     $pwd = (getpwuid($<))[1];
561     $salt = substr($pwd, 0, 2);
562
563     system "stty -echo";
564     print "Password: ";
565     chop($word = <STDIN>);
566     print "\n";
567     system "stty echo";
568
569     if (crypt($word, $salt) ne $pwd) {
570         die "Sorry...\n";
571     } else {
572         print "ok\n";
573     } 
574
575 Of course, typing in your own password to whoever asks you 
576 for it is unwise.
577
578 =item dbmclose ASSOC_ARRAY
579
580 [This function has been superseded by the untie() function.]
581
582 Breaks the binding between a DBM file and an associative array.
583
584 =item dbmopen ASSOC,DBNAME,MODE
585
586 [This function has been superseded by the tie() function.]
587
588 This binds a dbm(3), ndbm(3), sdbm(3), gdbm(), or Berkeley DB file to an
589 associative array.  ASSOC is the name of the associative array.  (Unlike
590 normal open, the first argument is I<NOT> a filehandle, even though it
591 looks like one).  DBNAME is the name of the database (without the F<.dir>
592 or F<.pag> extension if any).  If the database does not exist, it is
593 created with protection specified by MODE (as modified by the umask()).
594 If your system only supports the older DBM functions, you may perform only
595 one dbmopen() in your program.  In older versions of Perl, if your system
596 had neither DBM nor ndbm, calling dbmopen() produced a fatal error; it now
597 falls back to sdbm(3).
598
599 If you don't have write access to the DBM file, you can only read
600 associative array variables, not set them.  If you want to test whether
601 you can write, either use file tests or try setting a dummy array entry
602 inside an eval(), which will trap the error.
603
604 Note that functions such as keys() and values() may return huge array
605 values when used on large DBM files.  You may prefer to use the each()
606 function to iterate over large DBM files.  Example:
607
608     # print out history file offsets
609     dbmopen(%HIST,'/usr/lib/news/history',0666);
610     while (($key,$val) = each %HIST) {
611         print $key, ' = ', unpack('L',$val), "\n";
612     }
613     dbmclose(%HIST);
614
615 See also L<AnyDBM_File> for a more general description of the pros and
616 cons of the various dbm apparoches, as well as L<DB_File> for a particularly
617 rich implementation.
618
619 =item defined EXPR
620
621 Returns a boolean value saying whether EXPR has a real value
622 or not.  Many operations return the undefined value under exceptional
623 conditions, such as end of file, uninitialized variable, system error
624 and such.  This function allows you to distinguish between an undefined
625 null scalar and a defined null scalar with operations that might return
626 a real null string, such as referencing elements of an array.  You may
627 also check to see if arrays or subroutines exist.  Use of defined on
628 predefined variables is not guaranteed to produce intuitive results.
629
630 When used on a hash array element, it tells you whether the value
631 is defined, not whether the key exists in the hash.  Use exists() for that.
632
633 Examples:
634
635     print if defined $switch{'D'};
636     print "$val\n" while defined($val = pop(@ary));
637     die "Can't readlink $sym: $!"
638         unless defined($value = readlink $sym);
639     eval '@foo = ()' if defined(@foo);
640     die "No XYZ package defined" unless defined %_XYZ;
641     sub foo { defined &$bar ? &$bar(@_) : die "No bar"; }
642
643 See also undef().
644
645 Note: many folks tend to overuse defined(), and then are surprised to
646 discover that the number 0 and the null string are, in fact, defined
647 concepts.  For example, if you say
648
649     "ab" =~ /a(.*)b/;
650
651 the pattern match succeeds, and $1 is defined, despite the fact that it
652 matched "nothing".  But it didn't really match nothing--rather, it
653 matched something that happened to be 0 characters long.  This is all
654 very above-board and honest.  When a function returns an undefined value,
655 it's an admission that it couldn't give you an honest answer.  So
656 you should only use defined() when you're questioning the integrity
657 of what you're trying to do.  At other times, a simple comparison to
658 0 or "" is what you want.
659
660 =item delete EXPR
661
662 Deletes the specified value from its hash array.  Returns the deleted
663 value, or the undefined value if nothing was deleted.  Deleting from
664 C<$ENV{}> modifies the environment.  Deleting from an array tied to a DBM
665 file deletes the entry from the DBM file.  (But deleting from a tie()d
666 hash doesn't necessarily return anything.)
667
668 The following deletes all the values of an associative array:
669
670     foreach $key (keys %ARRAY) {
671         delete $ARRAY{$key};
672     }
673
674 (But it would be faster to use the undef() command.)  Note that the
675 EXPR can be arbitrarily complicated as long as the final operation is
676 a hash key lookup:
677
678     delete $ref->[$x][$y]{$key};
679
680 =item die LIST
681
682 Outside of an eval(), prints the value of LIST to C<STDERR> and exits with
683 the current value of $! (errno).  If $! is 0, exits with the value of
684 C<($? E<gt>E<gt> 8)> (backtick `command` status).  If C<($? E<gt>E<gt> 8)> is 0,
685 exits with 255.  Inside an eval(), the error message is stuffed into C<$@>,
686 and the eval() is terminated with the undefined value; this makes die()
687 the way to raise an exception.
688
689 Equivalent examples:
690
691     die "Can't cd to spool: $!\n" unless chdir '/usr/spool/news';
692     chdir '/usr/spool/news' or die "Can't cd to spool: $!\n" 
693
694 If the value of EXPR does not end in a newline, the current script line
695 number and input line number (if any) are also printed, and a newline
696 is supplied.  Hint: sometimes appending ", stopped" to your message
697 will cause it to make better sense when the string "at foo line 123" is
698 appended.  Suppose you are running script "canasta".
699
700     die "/etc/games is no good";
701     die "/etc/games is no good, stopped";
702
703 produce, respectively
704
705     /etc/games is no good at canasta line 123.
706     /etc/games is no good, stopped at canasta line 123.
707
708 See also exit() and warn().
709
710 =item do BLOCK
711
712 Not really a function.  Returns the value of the last command in the
713 sequence of commands indicated by BLOCK.  When modified by a loop
714 modifier, executes the BLOCK once before testing the loop condition.
715 (On other statements the loop modifiers test the conditional first.)
716
717 =item do SUBROUTINE(LIST)
718
719 A deprecated form of subroutine call.  See L<perlsub>.
720
721 =item do EXPR
722
723 Uses the value of EXPR as a filename and executes the contents of the
724 file as a Perl script.  Its primary use is to include subroutines
725 from a Perl subroutine library.
726
727     do 'stat.pl';
728
729 is just like
730
731     eval `cat stat.pl`;
732
733 except that it's more efficient, more concise, keeps track of the
734 current filename for error messages, and searches all the B<-I>
735 libraries if the file isn't in the current directory (see also the @INC
736 array in L<perlvar/Predefined Names>).  It's the same, however, in that it does
737 reparse the file every time you call it, so you probably don't want to
738 do this inside a loop.
739
740 Note that inclusion of library modules is better done with the
741 use() and require() operators, which also do error checking
742 and raise an exception if there's a problem.
743
744 =item dump LABEL
745
746 This causes an immediate core dump.  Primarily this is so that you can
747 use the B<undump> program to turn your core dump into an executable binary
748 after having initialized all your variables at the beginning of the
749 program.  When the new binary is executed it will begin by executing a
750 C<goto LABEL> (with all the restrictions that C<goto> suffers).  Think of
751 it as a goto with an intervening core dump and reincarnation.  If LABEL
752 is omitted, restarts the program from the top.  WARNING: any files
753 opened at the time of the dump will NOT be open any more when the
754 program is reincarnated, with possible resulting confusion on the part
755 of Perl.  See also B<-u> option in L<perlrun>.
756
757 Example:
758
759     #!/usr/bin/perl
760     require 'getopt.pl';
761     require 'stat.pl';
762     %days = (
763         'Sun' => 1,
764         'Mon' => 2,
765         'Tue' => 3,
766         'Wed' => 4,
767         'Thu' => 5,
768         'Fri' => 6,
769         'Sat' => 7,
770     );
771
772     dump QUICKSTART if $ARGV[0] eq '-d';
773
774     QUICKSTART:
775     Getopt('f');
776
777 =item each ASSOC_ARRAY
778
779 When called in a list context, returns a 2-element array consisting
780 of the key and value for the next element of an associative array,
781 so that you can iterate over it.  When called in a scalar context,
782 returns the key only for the next element in the associative array.
783 Entries are returned in an apparently random order.  When the array is
784 entirely read, a null array is returned in list context (which when
785 assigned produces a FALSE (0) value), and C<undef> is returned in a
786 scalar context.  The next call to each() after that will start
787 iterating again.  The iterator can be reset only by reading all the
788 elements from the array.  You should not add elements to an array while
789 you're iterating over it.  There is a single iterator for each
790 associative array, shared by all each(), keys() and values() function
791 calls in the program.  The following prints out your environment like
792 the printenv(1) program, only in a different order:
793
794     while (($key,$value) = each %ENV) {
795         print "$key=$value\n";
796     }
797
798 See also keys() and values().
799
800 =item eof FILEHANDLE
801
802 =item eof ()
803
804 =item eof
805
806 Returns 1 if the next read on FILEHANDLE will return end of file, or if
807 FILEHANDLE is not open.  FILEHANDLE may be an expression whose value
808 gives the real filehandle name.  (Note that this function actually
809 reads a character and then ungetc()s it, so it is not very useful in an
810 interactive context.)  Do not read from a terminal file (or call
811 C<eof(FILEHANDLE)> on it) after end-of-file is reached.  Filetypes such
812 as terminals may lose the end-of-file condition if you do.
813
814 An C<eof> without an argument uses the last file read as argument.
815 Empty parentheses () may be used to indicate
816 the pseudofile formed of the files listed on the command line, i.e.
817 C<eof()> is reasonable to use inside a while (E<lt>E<gt>) loop to detect the end
818 of only the last file.  Use C<eof(ARGV)> or eof without the parentheses to
819 test I<EACH> file in a while (E<lt>E<gt>) loop.  Examples:
820
821     # reset line numbering on each input file
822     while (<>) {
823         print "$.\t$_";
824         close(ARGV) if (eof);   # Not eof().
825     }
826
827     # insert dashes just before last line of last file
828     while (<>) {
829         if (eof()) {
830             print "--------------\n";
831             close(ARGV);        # close or break; is needed if we
832                                 # are reading from the terminal
833         }
834         print;
835     }
836
837 Practical hint: you almost never need to use C<eof> in Perl, because the
838 input operators return undef when they run out of data.  
839
840 =item eval EXPR
841
842 =item eval BLOCK
843
844 EXPR is parsed and executed as if it were a little Perl program.  It
845 is executed in the context of the current Perl program, so that any
846 variable settings, subroutine or format definitions remain afterwards.
847 The value returned is the value of the last expression evaluated, or a
848 return statement may be used, just as with subroutines.
849
850 If there is a syntax error or runtime error, or a die() statement is
851 executed, an undefined value is returned by eval(), and C<$@> is set to the
852 error message.  If there was no error, C<$@> is guaranteed to be a null
853 string.  If EXPR is omitted, evaluates $_.  The final semicolon, if
854 any, may be omitted from the expression.
855
856 Note that, since eval() traps otherwise-fatal errors, it is useful for
857 determining whether a particular feature (such as socket() or symlink())
858 is implemented.  It is also Perl's exception trapping mechanism, where
859 the die operator is used to raise exceptions.
860
861 If the code to be executed doesn't vary, you may use the eval-BLOCK
862 form to trap run-time errors without incurring the penalty of
863 recompiling each time.  The error, if any, is still returned in C<$@>.
864 Examples:
865
866     # make divide-by-zero non-fatal
867     eval { $answer = $a / $b; }; warn $@ if $@;
868
869     # same thing, but less efficient
870     eval '$answer = $a / $b'; warn $@ if $@;
871
872     # a compile-time error
873     eval { $answer = };
874
875     # a run-time error
876     eval '$answer =';   # sets $@
877
878 With an eval(), you should be especially careful to remember what's 
879 being looked at when:
880
881     eval $x;            # CASE 1
882     eval "$x";          # CASE 2
883
884     eval '$x';          # CASE 3
885     eval { $x };        # CASE 4
886
887     eval "\$$x++"       # CASE 5
888     $$x++;              # CASE 6
889
890 Cases 1 and 2 above behave identically: they run the code contained in the
891 variable $x.  (Although case 2 has misleading double quotes making the
892 reader wonder what else might be happening (nothing is).) Cases 3 and 4
893 likewise behave in the same way: they run the code <$x>, which does
894 nothing at all.  (Case 4 is preferred for purely visual reasons.) Case 5
895 is a place where normally you I<WOULD> like to use double quotes, except
896 that in that particular situation, you can just use symbolic references
897 instead, as in case 6.
898
899 =item exec LIST
900
901 The exec() function executes a system command I<AND NEVER RETURNS>.  Use
902 the system() function if you want it to return.
903
904 If there is more than one argument in LIST, or if LIST is an array with
905 more than one value, calls execvp(3) with the arguments in LIST.  If
906 there is only one scalar argument, the argument is checked for shell
907 metacharacters.  If there are any, the entire argument is passed to
908 C</bin/sh -c> for parsing.  If there are none, the argument is split
909 into words and passed directly to execvp(), which is more efficient.
910 Note: exec() and system() do not flush your output buffer, so you may
911 need to set C<$|> to avoid lost output.  Examples:
912
913     exec '/bin/echo', 'Your arguments are: ', @ARGV;
914     exec "sort $outfile | uniq";
915
916 If you don't really want to execute the first argument, but want to lie
917 to the program you are executing about its own name, you can specify
918 the program you actually want to run as an "indirect object" (without a
919 comma) in front of the LIST.  (This always forces interpretation of the
920 LIST as a multi-valued list, even if there is only a single scalar in
921 the list.)  Example:
922
923     $shell = '/bin/csh';
924     exec $shell '-sh';          # pretend it's a login shell
925
926 or, more directly,
927
928     exec {'/bin/csh'} '-sh';    # pretend it's a login shell
929
930 =item exists EXPR
931
932 Returns TRUE if the specified hash key exists in its hash array, even
933 if the corresponding value is undefined.
934
935     print "Exists\n" if exists $array{$key};
936     print "Defined\n" if defined $array{$key};
937     print "True\n" if $array{$key};
938
939 A hash element can only be TRUE if it's defined, and defined if
940 it exists, but the reverse doesn't necessarily hold true.
941
942 Note that the EXPR can be arbitrarily complicated as long as the final
943 operation is a hash key lookup:
944
945     if (exists $ref->[$x][$y]{$key}) { ... }
946
947 =item exit EXPR
948
949 Evaluates EXPR and exits immediately with that value.  (Actually, it
950 calls any defined C<END> routines first, but the C<END> routines may not
951 abort the exit.  Likewise any object destructors that need to be called
952 are called before exit.)  Example:
953
954     $ans = <STDIN>;
955     exit 0 if $ans =~ /^[Xx]/;
956
957 See also die().  If EXPR is omitted, exits with 0 status.
958
959 =item exp EXPR
960
961 Returns I<e> (the natural logarithm base) to the power of EXPR.  
962 If EXPR is omitted, gives C<exp($_)>.
963
964 =item fcntl FILEHANDLE,FUNCTION,SCALAR
965
966 Implements the fcntl(2) function.  You'll probably have to say
967
968     use Fcntl;
969
970 first to get the correct function definitions.  Argument processing and
971 value return works just like ioctl() below.  Note that fcntl() will produce
972 a fatal error if used on a machine that doesn't implement fcntl(2).
973 For example:
974
975     use Fcntl;
976     fcntl($filehandle, F_GETLK, $packed_return_buffer);
977
978 =item fileno FILEHANDLE
979
980 Returns the file descriptor for a filehandle.  This is useful for
981 constructing bitmaps for select().  If FILEHANDLE is an expression, the
982 value is taken as the name of the filehandle.
983
984 =item flock FILEHANDLE,OPERATION
985
986 Calls flock(2) on FILEHANDLE.  See L<flock(2)> for definition of
987 OPERATION.  Returns TRUE for success, FALSE on failure.  Will produce a
988 fatal error if used on a machine that doesn't implement either flock(2) or
989 fcntl(2). The fcntl(2) system call will be automatically used if flock(2)
990 is missing from your system.  This makes flock() the portable file locking
991 strategy, although it will only lock entire files, not records.  Note also
992 that some versions of flock() cannot lock things over the network; you
993 would need to use the more system-specific fcntl() for that.
994
995 Here's a mailbox appender for BSD systems.
996
997     $LOCK_SH = 1;
998     $LOCK_EX = 2;
999     $LOCK_NB = 4;
1000     $LOCK_UN = 8;
1001
1002     sub lock {
1003         flock(MBOX,$LOCK_EX);
1004         # and, in case someone appended
1005         # while we were waiting...
1006         seek(MBOX, 0, 2);
1007     }
1008
1009     sub unlock {
1010         flock(MBOX,$LOCK_UN);
1011     }
1012
1013     open(MBOX, ">>/usr/spool/mail/$ENV{'USER'}")
1014             or die "Can't open mailbox: $!";
1015
1016     lock();
1017     print MBOX $msg,"\n\n";
1018     unlock();
1019
1020 See also L<DB_File> for other flock() examples.
1021
1022 =item fork
1023
1024 Does a fork(2) system call.  Returns the child pid to the parent process
1025 and 0 to the child process, or C<undef> if the fork is unsuccessful.
1026 Note: unflushed buffers remain unflushed in both processes, which means
1027 you may need to set C<$|> ($AUTOFLUSH in English) or call the 
1028 autoflush() FileHandle method to avoid duplicate output.
1029
1030 If you fork() without ever waiting on your children, you will accumulate
1031 zombies:
1032
1033     $SIG{CHLD} = sub { wait };
1034
1035 There's also the double-fork trick (error checking on 
1036 fork() returns omitted);
1037
1038     unless ($pid = fork) {
1039         unless (fork) {
1040             exec "what you really wanna do";
1041             die "no exec";
1042             # ... or ...
1043             ## (some_perl_code_here)
1044             exit 0;
1045         }
1046         exit 0;
1047     }
1048     waitpid($pid,0);
1049
1050 See also L<perlipc> for more examples of forking and reaping
1051 moribund children.
1052
1053 =item format
1054
1055 Declare a picture format with use by the write() function.  For
1056 example:
1057
1058     format Something = 
1059         Test: @<<<<<<<< @||||| @>>>>>
1060               $str,     $%,    '$' . int($num)
1061     .
1062
1063     $str = "widget";
1064     $num = $cost/$quantiy;
1065     $~ = 'Something';
1066     write;
1067
1068 See L<perlform> for many details and examples.
1069
1070
1071 =item formline PICTURE, LIST
1072
1073 This is an internal function used by C<format>s, though you may call it
1074 too.  It formats (see L<perlform>) a list of values according to the
1075 contents of PICTURE, placing the output into the format output
1076 accumulator, C<$^A> (or $ACCUMULATOR in English).
1077 Eventually, when a write() is done, the contents of
1078 C<$^A> are written to some filehandle, but you could also read C<$^A>
1079 yourself and then set C<$^A> back to "".  Note that a format typically
1080 does one formline() per line of form, but the formline() function itself
1081 doesn't care how many newlines are embedded in the PICTURE.  This means
1082 that the C<~> and C<~~> tokens will treat the entire PICTURE as a single line.
1083 You may therefore need to use multiple formlines to implement a single
1084 record format, just like the format compiler.
1085
1086 Be careful if you put double quotes around the picture, since an "C<@>"
1087 character may be taken to mean the beginning of an array name.
1088 formline() always returns TRUE.  See L<perlform> for other examples.
1089
1090 =item getc FILEHANDLE
1091
1092 =item getc
1093
1094 Returns the next character from the input file attached to FILEHANDLE,
1095 or a null string at end of file.  If FILEHANDLE is omitted, reads from STDIN.
1096 This is not particularly efficient.  It cannot be used to get unbuffered
1097 single-characters, however.  For that, try something more like:
1098
1099     if ($BSD_STYLE) {
1100         system "stty cbreak </dev/tty >/dev/tty 2>&1";
1101     }
1102     else {
1103         system "stty", '-icanon', 'eol', "\001"; 
1104     }
1105
1106     $key = getc(STDIN);
1107
1108     if ($BSD_STYLE) {
1109         system "stty -cbreak </dev/tty >/dev/tty 2>&1";
1110     }
1111     else {
1112         system "stty", 'icanon', 'eol', '^@'; # ascii null
1113     }
1114     print "\n";
1115
1116 Determination of whether to whether $BSD_STYLE should be set 
1117 is left as an exercise to the reader.  
1118
1119 See also the C<Term::ReadKey> module from your nearest CPAN site;
1120 details on CPAN can be found on L<perlmod/CPAN> 
1121
1122 =item getlogin
1123
1124 Returns the current login from F</etc/utmp>, if any.  If null, use
1125 getpwuid().  
1126
1127     $login = getlogin || (getpwuid($<))[0] || "Kilroy";
1128
1129 Do not consider getlogin() for authentication: it is not as
1130 secure as getpwuid().
1131
1132 =item getpeername SOCKET
1133
1134 Returns the packed sockaddr address of other end of the SOCKET connection.
1135
1136     use Socket;
1137     $hersockaddr    = getpeername(SOCK);
1138     ($port, $iaddr) = unpack_sockaddr_in($hersockaddr);
1139     $herhostname    = gethostbyaddr($iaddr, AF_INET);
1140     $herstraddr     = inet_ntoa($iaddr);
1141
1142 =item getpgrp PID
1143
1144 Returns the current process group for the specified PID, 0 for the
1145 current process.  Will raise an exception if used on a machine that
1146 doesn't implement getpgrp(2).  If PID is omitted, returns process
1147 group of current process.
1148
1149 =item getppid
1150
1151 Returns the process id of the parent process.
1152
1153 =item getpriority WHICH,WHO
1154
1155 Returns the current priority for a process, a process group, or a user.
1156 (See L<getpriority(2)>.)  Will raise a fatal exception if used on a
1157 machine that doesn't implement getpriority(2).
1158
1159 =item getpwnam NAME
1160
1161 =item getgrnam NAME
1162
1163 =item gethostbyname NAME
1164
1165 =item getnetbyname NAME
1166
1167 =item getprotobyname NAME
1168
1169 =item getpwuid UID
1170
1171 =item getgrgid GID
1172
1173 =item getservbyname NAME,PROTO
1174
1175 =item gethostbyaddr ADDR,ADDRTYPE
1176
1177 =item getnetbyaddr ADDR,ADDRTYPE
1178
1179 =item getprotobynumber NUMBER
1180
1181 =item getservbyport PORT,PROTO
1182
1183 =item getpwent
1184
1185 =item getgrent
1186
1187 =item gethostent
1188
1189 =item getnetent
1190
1191 =item getprotoent
1192
1193 =item getservent
1194
1195 =item setpwent
1196
1197 =item setgrent
1198
1199 =item sethostent STAYOPEN
1200
1201 =item setnetent STAYOPEN
1202
1203 =item setprotoent STAYOPEN
1204
1205 =item setservent STAYOPEN
1206
1207 =item endpwent
1208
1209 =item endgrent
1210
1211 =item endhostent
1212
1213 =item endnetent
1214
1215 =item endprotoent
1216
1217 =item endservent
1218
1219 These routines perform the same functions as their counterparts in the
1220 system library.  Within a list context, the return values from the
1221 various get routines are as follows:
1222
1223     ($name,$passwd,$uid,$gid,
1224        $quota,$comment,$gcos,$dir,$shell) = getpw*
1225     ($name,$passwd,$gid,$members) = getgr*
1226     ($name,$aliases,$addrtype,$length,@addrs) = gethost*
1227     ($name,$aliases,$addrtype,$net) = getnet*
1228     ($name,$aliases,$proto) = getproto*
1229     ($name,$aliases,$port,$proto) = getserv*
1230
1231 (If the entry doesn't exist you get a null list.)
1232
1233 Within a scalar context, you get the name, unless the function was a
1234 lookup by name, in which case you get the other thing, whatever it is.
1235 (If the entry doesn't exist you get the undefined value.)  For example:
1236
1237     $uid = getpwnam
1238     $name = getpwuid
1239     $name = getpwent
1240     $gid = getgrnam
1241     $name = getgrgid
1242     $name = getgrent
1243     etc.
1244
1245 The $members value returned by I<getgr*()> is a space separated list of
1246 the login names of the members of the group.
1247
1248 For the I<gethost*()> functions, if the C<h_errno> variable is supported in
1249 C, it will be returned to you via C<$?> if the function call fails.  The
1250 @addrs value returned by a successful call is a list of the raw
1251 addresses returned by the corresponding system library call.  In the
1252 Internet domain, each address is four bytes long and you can unpack it
1253 by saying something like:
1254
1255     ($a,$b,$c,$d) = unpack('C4',$addr[0]);
1256
1257 =item getsockname SOCKET
1258
1259 Returns the packed sockaddr address of this end of the SOCKET connection.
1260
1261     use Socket;
1262     $mysockaddr = getsockname(SOCK);
1263     ($port, $myaddr) = unpack_sockaddr_in($mysockaddr);
1264
1265 =item getsockopt SOCKET,LEVEL,OPTNAME
1266
1267 Returns the socket option requested, or undefined if there is an error.
1268
1269 =item glob EXPR
1270
1271 Returns the value of EXPR with filename expansions such as a shell
1272 would do.  This is the internal function implementing the <*.*>
1273 operator, except it's easier to use.
1274
1275 =item gmtime EXPR
1276
1277 Converts a time as returned by the time function to a 9-element array
1278 with the time localized for the standard Greenwich timezone.  
1279 Typically used as follows:
1280
1281
1282     ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst) =
1283                                             gmtime(time);
1284
1285 All array elements are numeric, and come straight out of a struct tm.
1286 In particular this means that $mon has the range 0..11 and $wday has
1287 the range 0..6.  If EXPR is omitted, does C<gmtime(time())>.
1288
1289 =item goto LABEL
1290
1291 =item goto EXPR
1292
1293 =item goto &NAME
1294
1295 The goto-LABEL form finds the statement labeled with LABEL and resumes
1296 execution there.  It may not be used to go into any construct that
1297 requires initialization, such as a subroutine or a foreach loop.  It
1298 also can't be used to go into a construct that is optimized away.  It
1299 can be used to go almost anywhere else within the dynamic scope,
1300 including out of subroutines, but it's usually better to use some other
1301 construct such as last or die.  The author of Perl has never felt the
1302 need to use this form of goto (in Perl, that is--C is another matter).
1303
1304 The goto-EXPR form expects a label name, whose scope will be resolved
1305 dynamically.  This allows for computed gotos per FORTRAN, but isn't
1306 necessarily recommended if you're optimizing for maintainability:
1307
1308     goto ("FOO", "BAR", "GLARCH")[$i];
1309
1310 The goto-&NAME form is highly magical, and substitutes a call to the
1311 named subroutine for the currently running subroutine.  This is used by
1312 AUTOLOAD subroutines that wish to load another subroutine and then
1313 pretend that the other subroutine had been called in the first place
1314 (except that any modifications to @_ in the current subroutine are
1315 propagated to the other subroutine.)  After the goto, not even caller()
1316 will be able to tell that this routine was called first.
1317
1318 =item grep BLOCK LIST
1319
1320 =item grep EXPR,LIST
1321
1322 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
1323 $_ to each element) and returns the list value consisting of those
1324 elements for which the expression evaluated to TRUE.  In a scalar
1325 context, returns the number of times the expression was TRUE.
1326
1327     @foo = grep(!/^#/, @bar);    # weed out comments
1328
1329 or equivalently,
1330
1331     @foo = grep {!/^#/} @bar;    # weed out comments
1332
1333 Note that, since $_ is a reference into the list value, it can be used
1334 to modify the elements of the array.  While this is useful and
1335 supported, it can cause bizarre results if the LIST is not a named
1336 array.
1337
1338 =item hex EXPR
1339
1340 Interprets EXPR as a hex string and returns the corresponding decimal
1341 value.  (To convert strings that might start with 0 or 0x see
1342 oct().)  If EXPR is omitted, uses $_.
1343
1344 =item import
1345
1346 There is no built-in import() function.  It is merely an ordinary
1347 method (subroutine) defined (or inherited) by modules that wish to export
1348 names to another module.  The use() function calls the import() method
1349 for the package used.  See also L</use>, L<perlmod>, and L<Exporter>.
1350
1351 =item index STR,SUBSTR,POSITION
1352
1353 =item index STR,SUBSTR
1354
1355 Returns the position of the first occurrence of SUBSTR in STR at or after
1356 POSITION.  If POSITION is omitted, starts searching from the beginning of
1357 the string.  The return value is based at 0 (or whatever you've set the $[
1358 variable to--but don't do that).  If the substring is not found, returns
1359 one less than the base, ordinarily -1.
1360
1361 =item int EXPR
1362
1363 Returns the integer portion of EXPR.  If EXPR is omitted, uses $_.
1364
1365 =item ioctl FILEHANDLE,FUNCTION,SCALAR
1366
1367 Implements the ioctl(2) function.  You'll probably have to say
1368
1369     require "ioctl.ph"; # probably in /usr/local/lib/perl/ioctl.ph
1370
1371 first to get the correct function definitions.  If F<ioctl.ph> doesn't
1372 exist or doesn't have the correct definitions you'll have to roll your
1373 own, based on your C header files such as F<E<lt>sys/ioctl.hE<gt>>.
1374 (There is a Perl script called B<h2ph> that comes with the Perl kit which
1375 may help you in this, but it's non-trivial.)  SCALAR will be read and/or
1376 written depending on the FUNCTION--a pointer to the string value of SCALAR
1377 will be passed as the third argument of the actual ioctl call.  (If SCALAR
1378 has no string value but does have a numeric value, that value will be
1379 passed rather than a pointer to the string value.  To guarantee this to be
1380 TRUE, add a 0 to the scalar before using it.)  The pack() and unpack()
1381 functions are useful for manipulating the values of structures used by
1382 ioctl().  The following example sets the erase character to DEL.
1383
1384     require 'ioctl.ph';
1385     $getp = &TIOCGETP;
1386     die "NO TIOCGETP" if $@ || !$getp;
1387     $sgttyb_t = "ccccs";                # 4 chars and a short
1388     if (ioctl(STDIN,$getp,$sgttyb)) {
1389         @ary = unpack($sgttyb_t,$sgttyb);
1390         $ary[2] = 127;
1391         $sgttyb = pack($sgttyb_t,@ary);
1392         ioctl(STDIN,&TIOCSETP,$sgttyb)
1393             || die "Can't ioctl: $!";
1394     }
1395
1396 The return value of ioctl (and fcntl) is as follows:
1397
1398         if OS returns:          then Perl returns:
1399             -1                    undefined value
1400              0                  string "0 but true"
1401         anything else               that number
1402
1403 Thus Perl returns TRUE on success and FALSE on failure, yet you can
1404 still easily determine the actual value returned by the operating
1405 system:
1406
1407     ($retval = ioctl(...)) || ($retval = -1);
1408     printf "System returned %d\n", $retval;
1409
1410 =item join EXPR,LIST
1411
1412 Joins the separate strings of LIST or ARRAY into a single string with
1413 fields separated by the value of EXPR, and returns the string.
1414 Example:
1415
1416     $_ = join(':', $login,$passwd,$uid,$gid,$gcos,$home,$shell);
1417
1418 See L<perlfunc/split>.
1419
1420 =item keys ASSOC_ARRAY
1421
1422 Returns a normal array consisting of all the keys of the named
1423 associative array.  (In a scalar context, returns the number of keys.)
1424 The keys are returned in an apparently random order, but it is the same
1425 order as either the values() or each() function produces (given that
1426 the associative array has not been modified).  Here is yet another way
1427 to print your environment:
1428
1429     @keys = keys %ENV;
1430     @values = values %ENV;
1431     while ($#keys >= 0) {
1432         print pop(@keys), '=', pop(@values), "\n";
1433     }
1434
1435 or how about sorted by key:
1436
1437     foreach $key (sort(keys %ENV)) {
1438         print $key, '=', $ENV{$key}, "\n";
1439     }
1440
1441 To sort an array by value, you'll need to use a C<sort{}>
1442 function.  Here's a descending numeric sort of a hash by its values:
1443
1444     foreach $key (sort { $hash{$b} <=> $hash{$a} } keys %hash)) {
1445         printf "%4d %s\n", $hash{$key}, $key;
1446     }
1447
1448 =item kill LIST
1449
1450 Sends a signal to a list of processes.  The first element of 
1451 the list must be the signal to send.  Returns the number of 
1452 processes successfully signaled.
1453
1454     $cnt = kill 1, $child1, $child2;
1455     kill 9, @goners;
1456
1457 Unlike in the shell, in Perl if the I<SIGNAL> is negative, it kills
1458 process groups instead of processes.  (On System V, a negative I<PROCESS>
1459 number will also kill process groups, but that's not portable.)  That
1460 means you usually want to use positive not negative signals.  You may also
1461 use a signal name in quotes.  See L<perlipc/"Signals"> for details.
1462
1463 =item last LABEL
1464
1465 =item last
1466
1467 The C<last> command is like the C<break> statement in C (as used in
1468 loops); it immediately exits the loop in question.  If the LABEL is
1469 omitted, the command refers to the innermost enclosing loop.  The
1470 C<continue> block, if any, is not executed:
1471
1472     LINE: while (<STDIN>) {
1473         last LINE if /^$/;      # exit when done with header
1474         ...
1475     }
1476
1477 =item lc EXPR
1478
1479 Returns an lowercased version of EXPR.  This is the internal function
1480 implementing the \L escape in double-quoted strings.  
1481 Should respect any POSIX setlocale() settings.
1482
1483 =item lcfirst EXPR
1484
1485 Returns the value of EXPR with the first character lowercased.  This is
1486 the internal function implementing the \l escape in double-quoted strings.
1487 Should respect any POSIX setlocale() settings.
1488
1489 =item length EXPR
1490
1491 Returns the length in characters of the value of EXPR.  If EXPR is
1492 omitted, returns length of $_.
1493
1494 =item link OLDFILE,NEWFILE
1495
1496 Creates a new filename linked to the old filename.  Returns 1 for
1497 success, 0 otherwise.
1498
1499 =item listen SOCKET,QUEUESIZE
1500
1501 Does the same thing that the listen system call does.  Returns TRUE if
1502 it succeeded, FALSE otherwise.  See example in L<perlipc/"Sockets: Client/Server Communication">.
1503
1504 =item local EXPR
1505
1506 A local modifies the listed variables to be local to the enclosing block,
1507 subroutine, C<eval{}> or C<do>.  If more than one value is listed, the
1508 list must be placed in parens.  See L<perlsub/"Temporary Values via
1509 local()"> for details.
1510
1511 But you really probably want to be using my() instead, because local() isn't
1512 what most people think of as "local").  See L<perlsub/"Private Variables
1513 via my()"> for details.
1514
1515 =item localtime EXPR
1516
1517 Converts a time as returned by the time function to a 9-element array
1518 with the time analyzed for the local timezone.  Typically used as
1519 follows:
1520
1521     ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst) =
1522                                                 localtime(time);
1523
1524 All array elements are numeric, and come straight out of a struct tm.
1525 In particular this means that $mon has the range 0..11 and $wday has
1526 the range 0..6.  If EXPR is omitted, does localtime(time).
1527
1528 In a scalar context, prints out the ctime(3) value:
1529
1530     $now_string = localtime;  # e.g. "Thu Oct 13 04:54:34 1994"
1531
1532 Also see the F<timelocal.pl> library, and the strftime(3) function available
1533 via the POSIX module.
1534
1535 =item log EXPR
1536
1537 Returns logarithm (base I<e>) of EXPR.  If EXPR is omitted, returns log
1538 of $_.
1539
1540 =item lstat FILEHANDLE
1541
1542 =item lstat EXPR
1543
1544 Does the same thing as the stat() function, but stats a symbolic link
1545 instead of the file the symbolic link points to.  If symbolic links are
1546 unimplemented on your system, a normal stat() is done.
1547
1548 =item m//
1549
1550 The match operator.  See L<perlop>.
1551
1552 =item map BLOCK LIST
1553
1554 =item map EXPR,LIST
1555
1556 Evaluates the BLOCK or EXPR for each element of LIST (locally setting $_ to each
1557 element) and returns the list value composed of the results of each such
1558 evaluation.  Evaluates BLOCK or EXPR in a list context, so each element of LIST
1559 may produce zero, one, or more elements in the returned value.
1560
1561     @chars = map(chr, @nums);
1562
1563 translates a list of numbers to the corresponding characters.  And
1564
1565     %hash = map { getkey($_) => $_ } @array;
1566
1567 is just a funny way to write
1568
1569     %hash = ();
1570     foreach $_ (@array) {
1571         $hash{getkey($_)} = $_;
1572     }
1573
1574 =item mkdir FILENAME,MODE
1575
1576 Creates the directory specified by FILENAME, with permissions specified
1577 by MODE (as modified by umask).  If it succeeds it returns 1, otherwise
1578 it returns 0 and sets $! (errno).
1579
1580 =item msgctl ID,CMD,ARG
1581
1582 Calls the System V IPC function msgctl(2).  If CMD is &IPC_STAT, then ARG
1583 must be a variable which will hold the returned msqid_ds structure.
1584 Returns like ioctl: the undefined value for error, "0 but true" for
1585 zero, or the actual return value otherwise.
1586
1587 =item msgget KEY,FLAGS
1588
1589 Calls the System V IPC function msgget(2).  Returns the message queue id,
1590 or the undefined value if there is an error.
1591
1592 =item msgsnd ID,MSG,FLAGS
1593
1594 Calls the System V IPC function msgsnd to send the message MSG to the
1595 message queue ID.  MSG must begin with the long integer message type,
1596 which may be created with C<pack("l", $type)>.  Returns TRUE if
1597 successful, or FALSE if there is an error.
1598
1599 =item msgrcv ID,VAR,SIZE,TYPE,FLAGS
1600
1601 Calls the System V IPC function msgrcv to receive a message from
1602 message queue ID into variable VAR with a maximum message size of
1603 SIZE.  Note that if a message is received, the message type will be the
1604 first thing in VAR, and the maximum length of VAR is SIZE plus the size
1605 of the message type.  Returns TRUE if successful, or FALSE if there is
1606 an error.
1607
1608 =item my EXPR
1609
1610 A "my" declares the listed variables to be local (lexically) to the
1611 enclosing block, subroutine, C<eval>, or C<do/require/use>'d file.  If
1612 more than one value is listed, the list must be placed in parens.  See
1613 L<perlsub/"Private Variables via my()"> for details.
1614
1615 =item next LABEL
1616
1617 =item next
1618
1619 The C<next> command is like the C<continue> statement in C; it starts
1620 the next iteration of the loop:
1621
1622     LINE: while (<STDIN>) {
1623         next LINE if /^#/;      # discard comments
1624         ...
1625     }
1626
1627 Note that if there were a C<continue> block on the above, it would get
1628 executed even on discarded lines.  If the LABEL is omitted, the command
1629 refers to the innermost enclosing loop.
1630
1631 =item no Module LIST
1632
1633 See the "use" function, which "no" is the opposite of.
1634
1635 =item oct EXPR
1636
1637 Interprets EXPR as an octal string and returns the corresponding
1638 decimal value.  (If EXPR happens to start off with 0x, interprets it as
1639 a hex string instead.)  The following will handle decimal, octal, and
1640 hex in the standard Perl or C notation:
1641
1642     $val = oct($val) if $val =~ /^0/;
1643
1644 If EXPR is omitted, uses $_.
1645
1646 =item open FILEHANDLE,EXPR
1647
1648 =item open FILEHANDLE
1649
1650 Opens the file whose filename is given by EXPR, and associates it with
1651 FILEHANDLE.  If FILEHANDLE is an expression, its value is used as the name
1652 of the real filehandle wanted.  If EXPR is omitted, the scalar variable of
1653 the same name as the FILEHANDLE contains the filename.  If the filename
1654 begins with "<" or nothing, the file is opened for input.  If the filename
1655 begins with ">", the file is opened for output.  If the filename begins
1656 with ">>", the file is opened for appending.  You can put a '+' in front
1657 of the '>' or '<' to indicate that you want both read and write access to
1658 the file; thus '+<' is usually preferred for read/write updates--the '+>'
1659 mode would clobber the file first.  These correspond to the fopen(3) modes
1660 of 'r', 'r+', 'w', 'w+', 'a', and 'a+'.
1661
1662 If the filename begins with "|", the filename is interpreted
1663 as a command to which output is to be piped, and if the filename ends with
1664 a "|", the filename is interpreted See L<perlipc/"Using open() for IPC">
1665 for more examples of this.  as command which pipes input to us.  (You may
1666 not have a raw open() to a command that pipes both in I<and> out, but see L<open2>,
1667 L<open3>, and L<perlipc/"Bidirectional Communication"> for alternatives.)
1668
1669 Opening '-' opens STDIN and opening '>-' opens STDOUT.  Open returns
1670 non-zero upon success, the undefined value otherwise.  If the open
1671 involved a pipe, the return value happens to be the pid of the
1672 subprocess.  
1673
1674 If you're unfortunate enough to be running Perl on a system that
1675 distinguishes between text files and binary files (modern operating
1676 systems don't care), then you should check out L</binmode> for tips for
1677 dealing with this.  The key distinction between systems that need binmode
1678 and those that don't is their text file formats.  Systems like Unix and
1679 Plan9 that delimit lines with a single character, and that encode that
1680 character in C as '\n', do not need C<binmode>.  The rest need it.
1681
1682 Examples:
1683
1684     $ARTICLE = 100;
1685     open ARTICLE or die "Can't find article $ARTICLE: $!\n";
1686     while (<ARTICLE>) {...
1687
1688     open(LOG, '>>/usr/spool/news/twitlog'); # (log is reserved)
1689
1690     open(DBASE, '+<dbase.mine');            # open for update
1691
1692     open(ARTICLE, "caesar <$article |");    # decrypt article
1693
1694     open(EXTRACT, "|sort >/tmp/Tmp$$");     # $$ is our process id
1695
1696     # process argument list of files along with any includes
1697
1698     foreach $file (@ARGV) {
1699         process($file, 'fh00');
1700     }
1701
1702     sub process {
1703         local($filename, $input) = @_;
1704         $input++;               # this is a string increment
1705         unless (open($input, $filename)) {
1706             print STDERR "Can't open $filename: $!\n";
1707             return;
1708         }
1709
1710         while (<$input>) {              # note use of indirection
1711             if (/^#include "(.*)"/) {
1712                 process($1, $input);
1713                 next;
1714             }
1715             ...         # whatever
1716         }
1717     }
1718
1719 You may also, in the Bourne shell tradition, specify an EXPR beginning
1720 with ">&", in which case the rest of the string is interpreted as the
1721 name of a filehandle (or file descriptor, if numeric) which is to be
1722 duped and opened.  You may use & after >, >>, <, +>, +>> and +<.  The
1723 mode you specify should match the mode of the original filehandle.
1724 (Duping a filehandle does not take into acount any existing contents of
1725 stdio buffers.)
1726 Here is a script that saves, redirects, and restores STDOUT and
1727 STDERR:
1728
1729     #!/usr/bin/perl
1730     open(SAVEOUT, ">&STDOUT");
1731     open(SAVEERR, ">&STDERR");
1732
1733     open(STDOUT, ">foo.out") || die "Can't redirect stdout";
1734     open(STDERR, ">&STDOUT") || die "Can't dup stdout";
1735
1736     select(STDERR); $| = 1;     # make unbuffered
1737     select(STDOUT); $| = 1;     # make unbuffered
1738
1739     print STDOUT "stdout 1\n";  # this works for
1740     print STDERR "stderr 1\n";  # subprocesses too
1741
1742     close(STDOUT);
1743     close(STDERR);
1744
1745     open(STDOUT, ">&SAVEOUT");
1746     open(STDERR, ">&SAVEERR");
1747
1748     print STDOUT "stdout 2\n";
1749     print STDERR "stderr 2\n";
1750
1751
1752 If you specify "<&=N", where N is a number, then Perl will do an
1753 equivalent of C's fdopen() of that file descriptor; this is more
1754 parsimonious of file descriptors.  For example:
1755
1756     open(FILEHANDLE, "<&=$fd")
1757
1758 If you open a pipe on the command "-", i.e. either "|-" or "-|", then
1759 there is an implicit fork done, and the return value of open is the pid
1760 of the child within the parent process, and 0 within the child
1761 process.  (Use defined($pid) to determine whether the open was successful.)
1762 The filehandle behaves normally for the parent, but i/o to that
1763 filehandle is piped from/to the STDOUT/STDIN of the child process.
1764 In the child process the filehandle isn't opened--i/o happens from/to
1765 the new STDOUT or STDIN.  Typically this is used like the normal
1766 piped open when you want to exercise more control over just how the
1767 pipe command gets executed, such as when you are running setuid, and
1768 don't want to have to scan shell commands for metacharacters.  
1769 The following pairs are more or less equivalent:
1770
1771     open(FOO, "|tr '[a-z]' '[A-Z]'");
1772     open(FOO, "|-") || exec 'tr', '[a-z]', '[A-Z]';
1773
1774     open(FOO, "cat -n '$file'|");
1775     open(FOO, "-|") || exec 'cat', '-n', $file;
1776
1777 See L<perlipc/"Safe Pipe Opens"> for more examples of this.
1778
1779 Explicitly closing any piped filehandle causes the parent process to
1780 wait for the child to finish, and returns the status value in $?.
1781 Note: on any operation which may do a fork, unflushed buffers remain
1782 unflushed in both processes, which means you may need to set $| to
1783 avoid duplicate output.
1784
1785 Using the FileHandle constructor from the FileHandle package,
1786 you can generate anonymous filehandles which have the scope of whatever
1787 variables hold references to them, and automatically close whenever
1788 and however you leave that scope:
1789
1790     use FileHandle;
1791     ...
1792     sub read_myfile_munged {
1793         my $ALL = shift;
1794         my $handle = new FileHandle;
1795         open($handle, "myfile") or die "myfile: $!";
1796         $first = <$handle>
1797             or return ();     # Automatically closed here.
1798         mung $first or die "mung failed";       # Or here.
1799         return $first, <$handle> if $ALL;       # Or here.
1800         $first;                                 # Or here.
1801     }
1802
1803 The filename that is passed to open will have leading and trailing
1804 whitespace deleted.  In order to open a file with arbitrary weird
1805 characters in it, it's necessary to protect any leading and trailing
1806 whitespace thusly:
1807
1808     $file =~ s#^(\s)#./$1#;
1809     open(FOO, "< $file\0");
1810
1811 If you want a "real" C open() (see L<open(2)> on your system), then
1812 you should use the sysopen() function.  This is another way to
1813 protect your filenames from interpretation.  For example:
1814
1815     use FileHandle;
1816     sysopen(HANDLE, $path, O_RDWR|O_CREAT|O_EXCL, 0700)
1817         or die "sysopen $path: $!";
1818     HANDLE->autoflush(1);
1819     HANDLE->print("stuff $$\n");
1820     seek(HANDLE, 0, 0);
1821     print "File contains: ", <HANDLE>;
1822
1823 See L</seek()> for some details about mixing reading and writing.
1824
1825 =item opendir DIRHANDLE,EXPR
1826
1827 Opens a directory named EXPR for processing by readdir(), telldir(),
1828 seekdir(), rewinddir() and closedir().  Returns TRUE if successful.
1829 DIRHANDLEs have their own namespace separate from FILEHANDLEs.
1830
1831 =item ord EXPR
1832
1833 Returns the numeric ascii value of the first character of EXPR.  If
1834 EXPR is omitted, uses $_.
1835
1836 =item pack TEMPLATE,LIST
1837
1838 Takes an array or list of values and packs it into a binary structure,
1839 returning the string containing the structure.  The TEMPLATE is a
1840 sequence of characters that give the order and type of values, as
1841 follows:
1842
1843     A   An ascii string, will be space padded.
1844     a   An ascii string, will be null padded.
1845     b   A bit string (ascending bit order, like vec()).
1846     B   A bit string (descending bit order).
1847     h   A hex string (low nybble first).
1848     H   A hex string (high nybble first).
1849
1850     c   A signed char value.
1851     C   An unsigned char value.
1852     s   A signed short value.
1853     S   An unsigned short value.
1854     i   A signed integer value.
1855     I   An unsigned integer value.
1856     l   A signed long value.
1857     L   An unsigned long value.
1858
1859     n   A short in "network" order.
1860     N   A long in "network" order.
1861     v   A short in "VAX" (little-endian) order.
1862     V   A long in "VAX" (little-endian) order.
1863
1864     f   A single-precision float in the native format.
1865     d   A double-precision float in the native format.
1866
1867     p   A pointer to a null-terminated string.
1868     P   A pointer to a structure (fixed-length string).
1869
1870     u   A uuencoded string.
1871
1872     x   A null byte.
1873     X   Back up a byte.
1874     @   Null fill to absolute position.
1875
1876 Each letter may optionally be followed by a number which gives a repeat
1877 count.  With all types except "a", "A", "b", "B", "h" and "H", and "P" the
1878 pack function will gobble up that many values from the LIST.  A * for the
1879 repeat count means to use however many items are left.  The "a" and "A"
1880 types gobble just one value, but pack it as a string of length count,
1881 padding with nulls or spaces as necessary.  (When unpacking, "A" strips
1882 trailing spaces and nulls, but "a" does not.)  Likewise, the "b" and "B"
1883 fields pack a string that many bits long.  The "h" and "H" fields pack a
1884 string that many nybbles long.  The "P" packs a pointer to a structure of
1885 the size indicated by the length.  Real numbers (floats and doubles) are
1886 in the native machine format only; due to the multiplicity of floating
1887 formats around, and the lack of a standard "network" representation, no
1888 facility for interchange has been made.  This means that packed floating
1889 point data written on one machine may not be readable on another - even if
1890 both use IEEE floating point arithmetic (as the endian-ness of the memory
1891 representation is not part of the IEEE spec).  Note that Perl uses doubles
1892 internally for all numeric calculation, and converting from double into
1893 float and thence back to double again will lose precision (i.e.
1894 C<unpack("f", pack("f", $foo)>) will not in general equal $foo).
1895
1896 Examples:
1897
1898     $foo = pack("cccc",65,66,67,68);
1899     # foo eq "ABCD"
1900     $foo = pack("c4",65,66,67,68);
1901     # same thing
1902
1903     $foo = pack("ccxxcc",65,66,67,68);
1904     # foo eq "AB\0\0CD"
1905
1906     $foo = pack("s2",1,2);
1907     # "\1\0\2\0" on little-endian
1908     # "\0\1\0\2" on big-endian
1909
1910     $foo = pack("a4","abcd","x","y","z");
1911     # "abcd"
1912
1913     $foo = pack("aaaa","abcd","x","y","z");
1914     # "axyz"
1915
1916     $foo = pack("a14","abcdefg");
1917     # "abcdefg\0\0\0\0\0\0\0"
1918
1919     $foo = pack("i9pl", gmtime);
1920     # a real struct tm (on my system anyway)
1921
1922     sub bintodec {
1923         unpack("N", pack("B32", substr("0" x 32 . shift, -32)));
1924     }
1925
1926 The same template may generally also be used in the unpack function.
1927
1928 =item package NAMESPACE
1929
1930 Declares the compilation unit as being in the given namespace.  The scope
1931 of the package declaration is from the declaration itself through the end of
1932 the enclosing block (the same scope as the local() operator).  All further
1933 unqualified dynamic identifiers will be in this namespace.  A package
1934 statement only affects dynamic variables--including those you've used
1935 local() on--but I<not> lexical variables created with my().  Typically it
1936 would be the first declaration in a file to be included by the C<require>
1937 or C<use> operator.  You can switch into a package in more than one place;
1938 it merely influences which symbol table is used by the compiler for the
1939 rest of that block.  You can refer to variables and filehandles in other
1940 packages by prefixing the identifier with the package name and a double
1941 colon:  C<$Package::Variable>.  If the package name is null, the C<main>
1942 package as assumed.  That is, C<$::sail> is equivalent to C<$main::sail>.
1943
1944 See L<perlmod/"Packages"> for more information about packages, modules,
1945 and classes.  See L<perlsub> for other scoping issues.
1946
1947 =item pipe READHANDLE,WRITEHANDLE
1948
1949 Opens a pair of connected pipes like the corresponding system call.
1950 Note that if you set up a loop of piped processes, deadlock can occur
1951 unless you are very careful.  In addition, note that Perl's pipes use
1952 stdio buffering, so you may need to set $| to flush your WRITEHANDLE
1953 after each command, depending on the application.
1954
1955 See L<open2>, L<open3>, and L<perlipc/"Bidirectional Communication">
1956 for examples of such things.
1957
1958 =item pop ARRAY
1959
1960 Pops and returns the last value of the array, shortening the array by
1961 1.  Has a similar effect to
1962
1963     $tmp = $ARRAY[$#ARRAY--];
1964
1965 If there are no elements in the array, returns the undefined value.
1966 If ARRAY is omitted, pops the
1967 @ARGV array in the main program, and the @_ array in subroutines, just
1968 like shift().
1969
1970 =item pos SCALAR
1971
1972 Returns the offset of where the last C<m//g> search left off for the variable
1973 in question.  May be modified to change that offset.
1974
1975 =item print FILEHANDLE LIST
1976
1977 =item print LIST
1978
1979 =item print
1980
1981 Prints a string or a comma-separated list of strings.  Returns TRUE
1982 if successful.  FILEHANDLE may be a scalar variable name, in which case
1983 the variable contains the name of or a reference to the filehandle, thus introducing one
1984 level of indirection.  (NOTE: If FILEHANDLE is a variable and the next
1985 token is a term, it may be misinterpreted as an operator unless you
1986 interpose a + or put parens around the arguments.)  If FILEHANDLE is
1987 omitted, prints by default to standard output (or to the last selected
1988 output channel--see L</select>).  If LIST is also omitted, prints $_ to
1989 STDOUT.  To set the default output channel to something other than
1990 STDOUT use the select operation.  Note that, because print takes a
1991 LIST, anything in the LIST is evaluated in a list context, and any
1992 subroutine that you call will have one or more of its expressions
1993 evaluated in a list context.  Also be careful not to follow the print
1994 keyword with a left parenthesis unless you want the corresponding right
1995 parenthesis to terminate the arguments to the print--interpose a + or
1996 put parens around all the arguments.
1997
1998 Note that if you're storing FILEHANDLES in an array or other expression,
1999 you will have to use a block returning its value instead:
2000
2001     print { $files[$i] } "stuff\n";
2002     print { $OK ? STDOUT : STDERR } "stuff\n";
2003
2004 =item printf FILEHANDLE LIST
2005
2006 =item printf LIST
2007
2008 Equivalent to a "print FILEHANDLE sprintf(LIST)".  The first argument
2009 of the list will be interpreted as the printf format.
2010
2011 =item prototype FUNCTION
2012
2013 Returns the prototype of a function as a string (or C<undef> if the
2014 function has no prototype).  FUNCTION is a reference to the the
2015 function whose prototype you want to retrieve.
2016
2017 =item push ARRAY,LIST
2018
2019 Treats ARRAY as a stack, and pushes the values of LIST
2020 onto the end of ARRAY.  The length of ARRAY increases by the length of
2021 LIST.  Has the same effect as
2022
2023     for $value (LIST) {
2024         $ARRAY[++$#ARRAY] = $value;
2025     }
2026
2027 but is more efficient.  Returns the new number of elements in the array.
2028
2029 =item q/STRING/
2030
2031 =item qq/STRING/
2032
2033 =item qx/STRING/
2034
2035 =item qw/STRING/
2036
2037 Generalized quotes.  See L<perlop>.
2038
2039 =item quotemeta EXPR
2040
2041 Returns the value of EXPR with with all regular expression
2042 metacharacters backslashed.  This is the internal function implementing
2043 the \Q escape in double-quoted strings.
2044
2045 =item rand EXPR
2046
2047 =item rand
2048
2049 Returns a random fractional number between 0 and the value of EXPR.
2050 (EXPR should be positive.)  If EXPR is omitted, returns a value between 
2051 0 and 1.  This function produces repeatable sequences unless srand() 
2052 is invoked.  See also srand().
2053
2054 (Note: if your rand function consistently returns numbers that are too
2055 large or too small, then your version of Perl was probably compiled
2056 with the wrong number of RANDBITS.  As a workaround, you can usually
2057 multiply EXPR by the correct power of 2 to get the range you want.
2058 This will make your script unportable, however.  It's better to recompile
2059 if you can.)
2060
2061 =item read FILEHANDLE,SCALAR,LENGTH,OFFSET
2062
2063 =item read FILEHANDLE,SCALAR,LENGTH
2064
2065 Attempts to read LENGTH bytes of data into variable SCALAR from the
2066 specified FILEHANDLE.  Returns the number of bytes actually read, or
2067 undef if there was an error.  SCALAR will be grown or shrunk to the
2068 length actually read.  An OFFSET may be specified to place the read
2069 data at some other place than the beginning of the string.  This call
2070 is actually implemented in terms of stdio's fread call.  To get a true
2071 read system call, see sysread().
2072
2073 =item readdir DIRHANDLE
2074
2075 Returns the next directory entry for a directory opened by opendir().
2076 If used in a list context, returns all the rest of the entries in the
2077 directory.  If there are no more entries, returns an undefined value in
2078 a scalar context or a null list in a list context.
2079
2080 If you're planning to filetest the return values out of a readdir(), you'd
2081 better prepend the directory in question.  Otherwise, since we didn't
2082 chdir() there, it would have been testing the wrong file.
2083
2084     opendir(DIR, $some_dir) || die "can't opendir $some_dir: $!";
2085     @dots = grep { /^\./ && -f "$some_dir/$_" } readdir(DIR);
2086     closedir DIR;
2087
2088 =item readlink EXPR
2089
2090 Returns the value of a symbolic link, if symbolic links are
2091 implemented.  If not, gives a fatal error.  If there is some system
2092 error, returns the undefined value and sets $! (errno).  If EXPR is
2093 omitted, uses $_.
2094
2095 =item recv SOCKET,SCALAR,LEN,FLAGS
2096
2097 Receives a message on a socket.  Attempts to receive LENGTH bytes of
2098 data into variable SCALAR from the specified SOCKET filehandle.
2099 Actually does a C recvfrom(), so that it can returns the address of the
2100 sender.  Returns the undefined value if there's an error.  SCALAR will
2101 be grown or shrunk to the length actually read.  Takes the same flags
2102 as the system call of the same name.  
2103 See L<perlipc/"UDP: Message Passing"> for examples.
2104
2105 =item redo LABEL
2106
2107 =item redo
2108
2109 The C<redo> command restarts the loop block without evaluating the
2110 conditional again.  The C<continue> block, if any, is not executed.  If
2111 the LABEL is omitted, the command refers to the innermost enclosing
2112 loop.  This command is normally used by programs that want to lie to
2113 themselves about what was just input:
2114
2115     # a simpleminded Pascal comment stripper
2116     # (warning: assumes no { or } in strings)
2117     LINE: while (<STDIN>) {
2118         while (s|({.*}.*){.*}|$1 |) {}
2119         s|{.*}| |;
2120         if (s|{.*| |) {
2121             $front = $_;
2122             while (<STDIN>) {
2123                 if (/}/) {      # end of comment?
2124                     s|^|$front{|;
2125                     redo LINE;
2126                 }
2127             }
2128         }
2129         print;
2130     }
2131
2132 =item ref EXPR
2133
2134 Returns a TRUE value if EXPR is a reference, FALSE otherwise.  The value
2135 returned depends on the type of thing the reference is a reference to.
2136 Builtin types include:
2137
2138     REF
2139     SCALAR
2140     ARRAY
2141     HASH
2142     CODE
2143     GLOB
2144
2145 If the referenced object has been blessed into a package, then that package 
2146 name is returned instead.  You can think of ref() as a typeof() operator.
2147
2148     if (ref($r) eq "HASH") {
2149         print "r is a reference to an associative array.\n";
2150     } 
2151     if (!ref ($r) {
2152         print "r is not a reference at all.\n";
2153     } 
2154
2155 See also L<perlref>.
2156
2157 =item rename OLDNAME,NEWNAME
2158
2159 Changes the name of a file.  Returns 1 for success, 0 otherwise.  Will
2160 not work across filesystem boundaries.
2161
2162 =item require EXPR
2163
2164 =item require
2165
2166 Demands some semantics specified by EXPR, or by $_ if EXPR is not
2167 supplied.  If EXPR is numeric, demands that the current version of Perl
2168 ($] or $PERL_VERSION) be equal or greater than EXPR.
2169
2170 Otherwise, demands that a library file be included if it hasn't already
2171 been included.  The file is included via the do-FILE mechanism, which is
2172 essentially just a variety of eval().  Has semantics similar to the following
2173 subroutine:
2174
2175     sub require {
2176         local($filename) = @_;
2177         return 1 if $INC{$filename};
2178         local($realfilename,$result);
2179         ITER: {
2180             foreach $prefix (@INC) {
2181                 $realfilename = "$prefix/$filename";
2182                 if (-f $realfilename) {
2183                     $result = do $realfilename;
2184                     last ITER;
2185                 }
2186             }
2187             die "Can't find $filename in \@INC";
2188         }
2189         die $@ if $@;
2190         die "$filename did not return true value" unless $result;
2191         $INC{$filename} = $realfilename;
2192         $result;
2193     }
2194
2195 Note that the file will not be included twice under the same specified
2196 name.  The file must return TRUE as the last statement to indicate
2197 successful execution of any initialization code, so it's customary to
2198 end such a file with "1;" unless you're sure it'll return TRUE
2199 otherwise.  But it's better just to put the "C<1;>", in case you add more
2200 statements.
2201
2202 If EXPR is a bare word, the require assumes a "F<.pm>" extension and
2203 replaces "F<::>" with "F</>" in the filename for you,
2204 to make it easy to load standard modules.  This form of loading of 
2205 modules does not risk altering your namespace.
2206
2207 For a yet-more-powerful import facility, see L</use> and 
2208 L<perlmod>.
2209
2210 =item reset EXPR
2211
2212 =item reset
2213
2214 Generally used in a C<continue> block at the end of a loop to clear
2215 variables and reset ?? searches so that they work again.  The
2216 expression is interpreted as a list of single characters (hyphens
2217 allowed for ranges).  All variables and arrays beginning with one of
2218 those letters are reset to their pristine state.  If the expression is
2219 omitted, one-match searches (?pattern?) are reset to match again.  Only
2220 resets variables or searches in the current package.  Always returns
2221 1.  Examples:
2222
2223     reset 'X';          # reset all X variables
2224     reset 'a-z';        # reset lower case variables
2225     reset;              # just reset ?? searches
2226
2227 Resetting "A-Z" is not recommended since you'll wipe out your
2228 ARGV and ENV arrays.  Only resets package variables--lexical variables
2229 are unaffected, but they clean themselves up on scope exit anyway,
2230 so you'll probably want to use them instead.  See L</my>.
2231
2232 =item return LIST
2233
2234 Returns from a subroutine or eval with the value specified.  (Note that
2235 in the absence of a return a subroutine or eval() will automatically
2236 return the value of the last expression evaluated.)
2237
2238 =item reverse LIST
2239
2240 In a list context, returns a list value consisting of the elements
2241 of LIST in the opposite order.  In a scalar context, returns a string
2242 value consisting of the bytes of the first element of LIST in the
2243 opposite order.   
2244
2245     print reverse <>;                   # line tac 
2246
2247     undef $/;
2248     print scalar reverse scalar <>;     # byte tac
2249
2250 =item rewinddir DIRHANDLE
2251
2252 Sets the current position to the beginning of the directory for the
2253 readdir() routine on DIRHANDLE.
2254
2255 =item rindex STR,SUBSTR,POSITION
2256
2257 =item rindex STR,SUBSTR
2258
2259 Works just like index except that it returns the position of the LAST
2260 occurrence of SUBSTR in STR.  If POSITION is specified, returns the
2261 last occurrence at or before that position.
2262
2263 =item rmdir FILENAME
2264
2265 Deletes the directory specified by FILENAME if it is empty.  If it
2266 succeeds it returns 1, otherwise it returns 0 and sets $! (errno).  If
2267 FILENAME is omitted, uses $_.
2268
2269 =item s///
2270
2271 The substitution operator.  See L<perlop>.
2272
2273 =item scalar EXPR
2274
2275 Forces EXPR to be interpreted in a scalar context and returns the value
2276 of EXPR.  
2277
2278     @counts = ( scalar @a, scalar @b, scalar @c );
2279
2280 There is no equivalent operator to force an expression to 
2281 be interpolated in a list context because it's in practice never
2282 needed.  If you really wanted to do so, however, you could use
2283 the construction C<@{[ (some expression) ]}>, but usually a simple
2284 C<(some expression)> suffices.
2285
2286 =item seek FILEHANDLE,POSITION,WHENCE
2287
2288 Randomly positions the file pointer for FILEHANDLE, just like the fseek()
2289 call of stdio.  FILEHANDLE may be an expression whose value gives the name
2290 of the filehandle.  The values for WHENCE are 0 to set the file pointer to
2291 POSITION, 1 to set the it to current plus POSITION, and 2 to set it to EOF
2292 plus offset.  You may use the values SEEK_SET, SEEK_CUR, and SEEK_END for
2293 this from POSIX module.  Returns 1 upon success, 0 otherwise.
2294
2295 On some systems you have to do a seek whenever you switch between reading
2296 and writing.  Amongst other things, this may have the effect of calling
2297 stdio's clearerr(3).  A "whence" of 1 (SEEK_CUR) is useful for not moving
2298 the file pointer:
2299
2300     seek(TEST,0,1);
2301
2302 This is also useful for applications emulating C<tail -f>.  Once you hit
2303 EOF on your read, and then sleep for a while, you might have to stick in a
2304 seek() to reset things.  First the simple trick listed above to clear the
2305 filepointer.  The seek() doesn't change the current position, but it
2306 I<does> clear the end-of-file condition on the handle, so that the next
2307 C<E<lt>FILEE<gt>> makes Perl try again to read something.  Hopefully.
2308
2309 If that doesn't work (some stdios are particularly cantankerous), then
2310 you may need something more like this:
2311
2312     for (;;) {
2313         for ($curpos = tell(FILE); $_ = <FILE>; $curpos = tell(FILE)) {
2314             # search for some stuff and put it into files
2315         }
2316         sleep($for_a_while);
2317         seek(FILE, $curpos, 0);
2318     }
2319
2320 =item seekdir DIRHANDLE,POS
2321
2322 Sets the current position for the readdir() routine on DIRHANDLE.  POS
2323 must be a value returned by telldir().  Has the same caveats about
2324 possible directory compaction as the corresponding system library
2325 routine.
2326
2327 =item select FILEHANDLE
2328
2329 =item select
2330
2331 Returns the currently selected filehandle.  Sets the current default
2332 filehandle for output, if FILEHANDLE is supplied.  This has two
2333 effects: first, a C<write> or a C<print> without a filehandle will
2334 default to this FILEHANDLE.  Second, references to variables related to
2335 output will refer to this output channel.  For example, if you have to
2336 set the top of form format for more than one output channel, you might
2337 do the following:
2338
2339     select(REPORT1);
2340     $^ = 'report1_top';
2341     select(REPORT2);
2342     $^ = 'report2_top';
2343
2344 FILEHANDLE may be an expression whose value gives the name of the
2345 actual filehandle.  Thus:
2346
2347     $oldfh = select(STDERR); $| = 1; select($oldfh);
2348
2349 Some programmers may prefer to think of filehandles as objects with
2350 methods, preferring to write the last example as:
2351
2352     use FileHandle;
2353     STDERR->autoflush(1);
2354
2355 =item select RBITS,WBITS,EBITS,TIMEOUT
2356
2357 This calls the select(2) system call with the bitmasks specified, which
2358 can be constructed using fileno() and vec(), along these lines:
2359
2360     $rin = $win = $ein = '';
2361     vec($rin,fileno(STDIN),1) = 1;
2362     vec($win,fileno(STDOUT),1) = 1;
2363     $ein = $rin | $win;
2364
2365 If you want to select on many filehandles you might wish to write a
2366 subroutine:
2367
2368     sub fhbits {
2369         local(@fhlist) = split(' ',$_[0]);
2370         local($bits);
2371         for (@fhlist) {
2372             vec($bits,fileno($_),1) = 1;
2373         }
2374         $bits;
2375     }
2376     $rin = fhbits('STDIN TTY SOCK');
2377
2378 The usual idiom is:
2379
2380     ($nfound,$timeleft) =
2381       select($rout=$rin, $wout=$win, $eout=$ein, $timeout);
2382
2383 or to block until something becomes ready just do this 
2384
2385     $nfound = select($rout=$rin, $wout=$win, $eout=$ein, undef);
2386
2387 Most systems do not both to return anything useful in $timeleft, so
2388 calling select() in a scalar context just returns $nfound.
2389
2390 Any of the bitmasks can also be undef.  The timeout, if specified, is
2391 in seconds, which may be fractional.  Note: not all implementations are
2392 capable of returning the $timeleft.  If not, they always return
2393 $timeleft equal to the supplied $timeout.
2394
2395 You can effect a 250-millisecond sleep this way:
2396
2397     select(undef, undef, undef, 0.25);
2398
2399 B<WARNING>: Do not attempt to mix buffered I/O (like read() or <FH>)
2400 with select().  You have to use sysread() instead.
2401
2402 =item semctl ID,SEMNUM,CMD,ARG
2403
2404 Calls the System V IPC function semctl.  If CMD is &IPC_STAT or
2405 &GETALL, then ARG must be a variable which will hold the returned
2406 semid_ds structure or semaphore value array.  Returns like ioctl: the
2407 undefined value for error, "0 but true" for zero, or the actual return
2408 value otherwise.
2409
2410 =item semget KEY,NSEMS,FLAGS
2411
2412 Calls the System V IPC function semget.  Returns the semaphore id, or
2413 the undefined value if there is an error.
2414
2415 =item semop KEY,OPSTRING
2416
2417 Calls the System V IPC function semop to perform semaphore operations
2418 such as signaling and waiting.  OPSTRING must be a packed array of
2419 semop structures.  Each semop structure can be generated with
2420 C<pack("sss", $semnum, $semop, $semflag)>.  The number of semaphore
2421 operations is implied by the length of OPSTRING.  Returns TRUE if
2422 successful, or FALSE if there is an error.  As an example, the
2423 following code waits on semaphore $semnum of semaphore id $semid:
2424
2425     $semop = pack("sss", $semnum, -1, 0);
2426     die "Semaphore trouble: $!\n" unless semop($semid, $semop);
2427
2428 To signal the semaphore, replace "-1" with "1".
2429
2430 =item send SOCKET,MSG,FLAGS,TO
2431
2432 =item send SOCKET,MSG,FLAGS
2433
2434 Sends a message on a socket.  Takes the same flags as the system call
2435 of the same name.  On unconnected sockets you must specify a
2436 destination to send TO, in which case it does a C sendto().  Returns
2437 the number of characters sent, or the undefined value if there is an
2438 error.
2439 See L<perlipc/"UDP: Message Passing"> for examples.
2440
2441 =item setpgrp PID,PGRP
2442
2443 Sets the current process group for the specified PID, 0 for the current
2444 process.  Will produce a fatal error if used on a machine that doesn't
2445 implement setpgrp(2).
2446
2447 =item setpriority WHICH,WHO,PRIORITY
2448
2449 Sets the current priority for a process, a process group, or a user.
2450 (See setpriority(2).)  Will produce a fatal error if used on a machine
2451 that doesn't implement setpriority(2).
2452
2453 =item setsockopt SOCKET,LEVEL,OPTNAME,OPTVAL
2454
2455 Sets the socket option requested.  Returns undefined if there is an
2456 error.  OPTVAL may be specified as undef if you don't want to pass an
2457 argument.
2458
2459 =item shift ARRAY
2460
2461 =item shift
2462
2463 Shifts the first value of the array off and returns it, shortening the
2464 array by 1 and moving everything down.  If there are no elements in the
2465 array, returns the undefined value.  If ARRAY is omitted, shifts the
2466 @ARGV array in the main program, and the @_ array in subroutines.
2467 (This is determined lexically.)  See also unshift(), push(), and pop().
2468 Shift() and unshift() do the same thing to the left end of an array
2469 that push() and pop() do to the right end.
2470
2471 =item shmctl ID,CMD,ARG
2472
2473 Calls the System V IPC function shmctl.  If CMD is &IPC_STAT, then ARG
2474 must be a variable which will hold the returned shmid_ds structure.
2475 Returns like ioctl: the undefined value for error, "0 but true" for
2476 zero, or the actual return value otherwise.
2477
2478 =item shmget KEY,SIZE,FLAGS
2479
2480 Calls the System V IPC function shmget.  Returns the shared memory
2481 segment id, or the undefined value if there is an error.
2482
2483 =item shmread ID,VAR,POS,SIZE
2484
2485 =item shmwrite ID,STRING,POS,SIZE
2486
2487 Reads or writes the System V shared memory segment ID starting at
2488 position POS for size SIZE by attaching to it, copying in/out, and
2489 detaching from it.  When reading, VAR must be a variable which will
2490 hold the data read.  When writing, if STRING is too long, only SIZE
2491 bytes are used; if STRING is too short, nulls are written to fill out
2492 SIZE bytes.  Return TRUE if successful, or FALSE if there is an error.
2493
2494 =item shutdown SOCKET,HOW
2495
2496 Shuts down a socket connection in the manner indicated by HOW, which
2497 has the same interpretation as in the system call of the same name.
2498
2499 =item sin EXPR
2500
2501 Returns the sine of EXPR (expressed in radians).  If EXPR is omitted,
2502 returns sine of $_.
2503
2504 =item sleep EXPR
2505
2506 =item sleep
2507
2508 Causes the script to sleep for EXPR seconds, or forever if no EXPR.
2509 May be interrupted by sending the process a SIGALRM.  Returns the
2510 number of seconds actually slept.  You probably cannot mix alarm() and
2511 sleep() calls, since sleep() is often implemented using alarm().
2512
2513 On some older systems, it may sleep up to a full second less than what
2514 you requested, depending on how it counts seconds.  Most modern systems
2515 always sleep the full amount.
2516
2517 For delays of finer granularity than one second, you may use Perl's
2518 syscall() interface to access setitimer(2) if your system supports it, 
2519 or else see L</select()> below.  
2520
2521 =item socket SOCKET,DOMAIN,TYPE,PROTOCOL
2522
2523 Opens a socket of the specified kind and attaches it to filehandle
2524 SOCKET.  DOMAIN, TYPE and PROTOCOL are specified the same as for the
2525 system call of the same name.  You should "use Socket;" first to get
2526 the proper definitions imported.  See the example in L<perlipc/"Sockets: Client/Server Communication">.
2527
2528 =item socketpair SOCKET1,SOCKET2,DOMAIN,TYPE,PROTOCOL
2529
2530 Creates an unnamed pair of sockets in the specified domain, of the
2531 specified type.  DOMAIN, TYPE and PROTOCOL are specified the same as
2532 for the system call of the same name.  If unimplemented, yields a fatal
2533 error.  Returns TRUE if successful.
2534
2535 =item sort SUBNAME LIST
2536
2537 =item sort BLOCK LIST
2538
2539 =item sort LIST
2540
2541 Sorts the LIST and returns the sorted list value.  Nonexistent values
2542 of arrays are stripped out.  If SUBNAME or BLOCK is omitted, sorts
2543 in standard string comparison order.  If SUBNAME is specified, it
2544 gives the name of a subroutine that returns an integer less than, equal
2545 to, or greater than 0, depending on how the elements of the array are
2546 to be ordered.  (The <=> and cmp operators are extremely useful in such
2547 routines.)  SUBNAME may be a scalar variable name, in which case the
2548 value provides the name of the subroutine to use.  In place of a
2549 SUBNAME, you can provide a BLOCK as an anonymous, in-line sort
2550 subroutine.
2551
2552 In the interests of efficiency the normal calling code for subroutines is
2553 bypassed, with the following effects: the subroutine may not be a
2554 recursive subroutine, and the two elements to be compared are passed into
2555 the subroutine not via @_ but as the package global variables $a and
2556 $b (see example below).  They are passed by reference, so don't
2557 modify $a and $b.  And don't try to declare them as lexicals either.
2558
2559 Examples:
2560
2561     # sort lexically
2562     @articles = sort @files;
2563
2564     # same thing, but with explicit sort routine
2565     @articles = sort {$a cmp $b} @files;
2566
2567     # now case-insensitively
2568     @articles = sort { uc($a) cmp uc($b)} @files;
2569
2570     # same thing in reversed order
2571     @articles = sort {$b cmp $a} @files;
2572
2573     # sort numerically ascending
2574     @articles = sort {$a <=> $b} @files;
2575
2576     # sort numerically descending
2577     @articles = sort {$b <=> $a} @files;
2578
2579     # sort using explicit subroutine name
2580     sub byage {
2581         $age{$a} <=> $age{$b};  # presuming integers
2582     }
2583     @sortedclass = sort byage @class;
2584
2585     # this sorts the %age associative arrays by value 
2586     # instead of key using an inline function
2587     @eldest = sort { $age{$b} <=> $age{$a} } keys %age;
2588
2589     sub backwards { $b cmp $a; }
2590     @harry = ('dog','cat','x','Cain','Abel');
2591     @george = ('gone','chased','yz','Punished','Axed');
2592     print sort @harry;
2593             # prints AbelCaincatdogx
2594     print sort backwards @harry;
2595             # prints xdogcatCainAbel
2596     print sort @george, 'to', @harry;
2597             # prints AbelAxedCainPunishedcatchaseddoggonetoxyz
2598
2599     # inefficiently sort by descending numeric compare using 
2600     # the first integer after the first = sign, or the 
2601     # whole record case-insensitively otherwise
2602
2603     @new = sort {
2604         ($b =~ /=(\d+)/)[0] <=> ($a =~ /=(\d+)/)[0]
2605                             ||
2606                     uc($a)  cmp  uc($b)
2607     } @old;
2608
2609     # same thing, but much more efficiently;
2610     # we'll build auxiliary indices instead
2611     # for speed
2612     @nums = @caps = ();
2613     for (@old) { 
2614         push @nums, /=(\d+)/;
2615         push @caps, uc($_);
2616     } 
2617
2618     @new = @old[ sort {
2619                         $nums[$b] <=> $nums[$a]
2620                                  ||
2621                         $caps[$a] cmp $caps[$b]
2622                        } 0..$#old
2623                ];
2624
2625     # same thing using a Schwartzian Transform (no temps)
2626     @new = map { $_->[0] }
2627         sort { $b->[1] <=> $a->[1]
2628                         ||
2629                $a->[2] cmp $b->[2]
2630         } map { [$_, /=(\d+)/, uc($_)] } @old;
2631
2632 If you're and using strict, you I<MUST NOT> declare $a
2633 and $b as lexicals.  They are package globals.  That means
2634 if you're in the C<main> package, it's
2635
2636     @articles = sort {$main::b <=> $main::a} @files;
2637
2638 or just
2639
2640     @articles = sort {$::b <=> $::a} @files;
2641
2642 but if you're in the C<FooPack> package, it's
2643
2644     @articles = sort {$FooPack::b <=> $FooPack::a} @files;
2645
2646 =item splice ARRAY,OFFSET,LENGTH,LIST
2647
2648 =item splice ARRAY,OFFSET,LENGTH
2649
2650 =item splice ARRAY,OFFSET
2651
2652 Removes the elements designated by OFFSET and LENGTH from an array, and
2653 replaces them with the elements of LIST, if any.  Returns the elements
2654 removed from the array.  The array grows or shrinks as necessary.  If
2655 LENGTH is omitted, removes everything from OFFSET onward.  The
2656 following equivalencies hold (assuming $[ == 0):
2657
2658     push(@a,$x,$y)      splice(@a,$#a+1,0,$x,$y)
2659     pop(@a)             splice(@a,-1)
2660     shift(@a)           splice(@a,0,1)
2661     unshift(@a,$x,$y)   splice(@a,0,0,$x,$y)
2662     $a[$x] = $y         splice(@a,$x,1,$y);
2663
2664 Example, assuming array lengths are passed before arrays:
2665
2666     sub aeq {   # compare two list values
2667         local(@a) = splice(@_,0,shift);
2668         local(@b) = splice(@_,0,shift);
2669         return 0 unless @a == @b;       # same len?
2670         while (@a) {
2671             return 0 if pop(@a) ne pop(@b);
2672         }
2673         return 1;
2674     }
2675     if (&aeq($len,@foo[1..$len],0+@bar,@bar)) { ... }
2676
2677 =item split /PATTERN/,EXPR,LIMIT
2678
2679 =item split /PATTERN/,EXPR
2680
2681 =item split /PATTERN/
2682
2683 =item split
2684
2685 Splits a string into an array of strings, and returns it.
2686
2687 If not in a list context, returns the number of fields found and splits into
2688 the @_ array.  (In a list context, you can force the split into @_ by
2689 using C<??> as the pattern delimiters, but it still returns the array
2690 value.)  The use of implicit split to @_ is deprecated, however.
2691
2692 If EXPR is omitted, splits the $_ string.  If PATTERN is also omitted,
2693 splits on whitespace (after skipping any leading whitespace).  Anything
2694 matching PATTERN is taken to be a delimiter separating the fields.  (Note
2695 that the delimiter may be longer than one character.)  If LIMIT is
2696 specified and is not negative, splits into no more than that many fields
2697 (though it may split into fewer).  If LIMIT is unspecified, trailing null
2698 fields are stripped (which potential users of pop() would do well to
2699 remember).  If LIMIT is negative, it is treated as if an arbitrarily large
2700 LIMIT had been specified.
2701
2702 A pattern matching the null string (not to be confused with
2703 a null pattern C<//>, which is just one member of the set of patterns
2704 matching a null string) will split the value of EXPR into separate
2705 characters at each point it matches that way.  For example:
2706
2707     print join(':', split(/ */, 'hi there'));
2708
2709 produces the output 'h:i:t:h:e:r:e'.
2710
2711 The LIMIT parameter can be used to partially split a line
2712
2713     ($login, $passwd, $remainder) = split(/:/, $_, 3);
2714
2715 When assigning to a list, if LIMIT is omitted, Perl supplies a LIMIT
2716 one larger than the number of variables in the list, to avoid
2717 unnecessary work.  For the list above LIMIT would have been 4 by
2718 default.  In time critical applications it behooves you not to split
2719 into more fields than you really need.
2720
2721 If the PATTERN contains parentheses, additional array elements are
2722 created from each matching substring in the delimiter.
2723
2724     split(/([,-])/, "1-10,20", 3);
2725
2726 produces the list value
2727
2728     (1, '-', 10, ',', 20)
2729
2730 If you had the entire header of a normal Unix email message in $header, 
2731 you could split it up into fields and their values this way:
2732
2733     $header =~ s/\n\s+/ /g;  # fix continuation lines
2734     %hdrs   =  (UNIX_FROM => split /^(.*?):\s*/m, $header);
2735
2736 The pattern C</PATTERN/> may be replaced with an expression to specify
2737 patterns that vary at runtime.  (To do runtime compilation only once,
2738 use C</$variable/o>.)
2739
2740 As a special case, specifying a PATTERN of space (C<' '>) will split on
2741 white space just as split with no arguments does.  Thus, split(' ') can
2742 be used to emulate B<awk>'s default behavior, whereas C<split(/ /)>
2743 will give you as many null initial fields as there are leading spaces.
2744 A split on /\s+/ is like a split(' ') except that any leading
2745 whitespace produces a null first field.  A split with no arguments
2746 really does a C<split(' ', $_)> internally.
2747
2748 Example:
2749
2750     open(passwd, '/etc/passwd');
2751     while (<passwd>) {
2752         ($login, $passwd, $uid, $gid, $gcos, 
2753             $home, $shell) = split(/:/);
2754         ...
2755     }
2756
2757 (Note that $shell above will still have a newline on it.  See L</chop>, 
2758 L</chomp>, and L</join>.)
2759
2760 =item sprintf FORMAT,LIST
2761
2762 Returns a string formatted by the usual printf conventions of the C
2763 language.  See L<sprintf(3)> or L<printf(3)> on your system for details.
2764 (The * character for an indirectly specified length is not
2765 supported, but you can get the same effect by interpolating a variable
2766 into the pattern.)  Some C libraries' implementations of sprintf() can
2767 dump core when fed ludicrous arguments.
2768
2769 =item sqrt EXPR
2770
2771 Return the square root of EXPR.  If EXPR is omitted, returns square
2772 root of $_.
2773
2774 =item srand EXPR
2775
2776 Sets the random number seed for the C<rand> operator.  If EXPR is omitted,
2777 uses a semirandom value based on the current time and process ID, among
2778 other things.  Of course, you'd need something much more random than that for
2779 cryptographic purposes, since it's easy to guess the current time.
2780 Checksumming the compressed output of rapidly changing operating system
2781 status programs is the usual method.  Examples are posted regularly to
2782 the comp.security.unix newsgroup.
2783
2784 =item stat FILEHANDLE
2785
2786 =item stat EXPR
2787
2788 Returns a 13-element array giving the status info for a file, either the
2789 file opened via FILEHANDLE, or named by EXPR.  Returns a null list if
2790 the stat fails.  Typically used as follows:
2791
2792     ($dev,$ino,$mode,$nlink,$uid,$gid,$rdev,$size,
2793        $atime,$mtime,$ctime,$blksize,$blocks)
2794            = stat($filename);
2795
2796 Not all fields are supported on all filesystem types.  Here are the 
2797 meaning of the fields:
2798
2799   dev       device number of filesystem 
2800   ino       inode number 
2801   mode      file mode  (type and permissions)
2802   nlink     number of (hard) links to the file 
2803   uid       numeric user ID of file's owner 
2804   gid       numer group ID of file's owner 
2805   rdev      the device identifier (special files only)
2806   size      total size of file, in bytes 
2807   atime     last access time since the epoch
2808   mtime     last modify time since the epoch
2809   ctime     inode change time (NOT creation type!) since the epoch
2810   blksize   preferred blocksize for file system I/O
2811   blocks    actual number of blocks allocated
2812
2813 (The epoch was at 00:00 January 1, 1970 GMT.)
2814
2815 If stat is passed the special filehandle consisting of an underline, no
2816 stat is done, but the current contents of the stat structure from the
2817 last stat or filetest are returned.  Example:
2818
2819     if (-x $file && (($d) = stat(_)) && $d < 0) {
2820         print "$file is executable NFS file\n";
2821     }
2822
2823 (This only works on machines for which the device number is negative under NFS.)
2824
2825 =item study SCALAR
2826
2827 =item study
2828
2829 Takes extra time to study SCALAR ($_ if unspecified) in anticipation of
2830 doing many pattern matches on the string before it is next modified.
2831 This may or may not save time, depending on the nature and number of
2832 patterns you are searching on, and on the distribution of character
2833 frequencies in the string to be searched--you probably want to compare
2834 runtimes with and without it to see which runs faster.  Those loops
2835 which scan for many short constant strings (including the constant
2836 parts of more complex patterns) will benefit most.  You may have only
2837 one study active at a time--if you study a different scalar the first
2838 is "unstudied".  (The way study works is this: a linked list of every
2839 character in the string to be searched is made, so we know, for
2840 example, where all the 'k' characters are.  From each search string,
2841 the rarest character is selected, based on some static frequency tables
2842 constructed from some C programs and English text.  Only those places
2843 that contain this "rarest" character are examined.)
2844
2845 For example, here is a loop which inserts index producing entries
2846 before any line containing a certain pattern:
2847
2848     while (<>) {
2849         study;
2850         print ".IX foo\n" if /\bfoo\b/;
2851         print ".IX bar\n" if /\bbar\b/;
2852         print ".IX blurfl\n" if /\bblurfl\b/;
2853         ...
2854         print;
2855     }
2856
2857 In searching for /\bfoo\b/, only those locations in $_ that contain "f"
2858 will be looked at, because "f" is rarer than "o".  In general, this is
2859 a big win except in pathological cases.  The only question is whether
2860 it saves you more time than it took to build the linked list in the
2861 first place.
2862
2863 Note that if you have to look for strings that you don't know till
2864 runtime, you can build an entire loop as a string and eval that to
2865 avoid recompiling all your patterns all the time.  Together with
2866 undefining $/ to input entire files as one record, this can be very
2867 fast, often faster than specialized programs like fgrep(1).  The following
2868 scans a list of files (@files) for a list of words (@words), and prints
2869 out the names of those files that contain a match:
2870
2871     $search = 'while (<>) { study;';
2872     foreach $word (@words) {
2873         $search .= "++\$seen{\$ARGV} if /\\b$word\\b/;\n";
2874     }
2875     $search .= "}";
2876     @ARGV = @files;
2877     undef $/;
2878     eval $search;               # this screams
2879     $/ = "\n";          # put back to normal input delim
2880     foreach $file (sort keys(%seen)) {
2881         print $file, "\n";
2882     }
2883
2884 =item sub BLOCK
2885
2886 =item sub NAME
2887
2888 =item sub NAME BLOCK
2889
2890 This is subroutine definition, not a real function I<per se>.  With just a
2891 NAME (and possibly prototypes), it's just a forward declaration.  Without
2892 a NAME, it's an anonymous function declaration, and does actually return a
2893 value: the CODE ref of the closure you just created. See L<perlsub> and
2894 L<perlref> for details.
2895
2896 =item substr EXPR,OFFSET,LEN
2897
2898 =item substr EXPR,OFFSET
2899
2900 Extracts a substring out of EXPR and returns it.  First character is at
2901 offset 0, or whatever you've set $[ to.  If OFFSET is negative, starts
2902 that far from the end of the string.  If LEN is omitted, returns
2903 everything to the end of the string.  If LEN is negative, leaves that
2904 many characters off the end of the string.
2905
2906 You can use the substr() function
2907 as an lvalue, in which case EXPR must be an lvalue.  If you assign
2908 something shorter than LEN, the string will shrink, and if you assign
2909 something longer than LEN, the string will grow to accommodate it.  To
2910 keep the string the same length you may need to pad or chop your value
2911 using sprintf().
2912
2913 =item symlink OLDFILE,NEWFILE
2914
2915 Creates a new filename symbolically linked to the old filename.
2916 Returns 1 for success, 0 otherwise.  On systems that don't support
2917 symbolic links, produces a fatal error at run time.  To check for that,
2918 use eval:
2919
2920     $symlink_exists = (eval 'symlink("","");', $@ eq '');
2921
2922 =item syscall LIST
2923
2924 Calls the system call specified as the first element of the list,
2925 passing the remaining elements as arguments to the system call.  If
2926 unimplemented, produces a fatal error.  The arguments are interpreted
2927 as follows: if a given argument is numeric, the argument is passed as
2928 an int.  If not, the pointer to the string value is passed.  You are
2929 responsible to make sure a string is pre-extended long enough to
2930 receive any result that might be written into a string.  If your
2931 integer arguments are not literals and have never been interpreted in a
2932 numeric context, you may need to add 0 to them to force them to look
2933 like numbers.
2934
2935     require 'syscall.ph';               # may need to run h2ph
2936     syscall(&SYS_write, fileno(STDOUT), "hi there\n", 9);
2937
2938 Note that Perl only supports passing of up to 14 arguments to your system call,
2939 which in practice should usually suffice.
2940
2941 =item sysopen FILEHANDLE,FILENAME,MODE
2942
2943 =item sysopen FILEHANDLE,FILENAME,MODE,PERMS
2944
2945 Opens the file whose filename is given by FILENAME, and associates it
2946 with FILEHANDLE.  If FILEHANDLE is an expression, its value is used as
2947 the name of the real filehandle wanted.  This function calls the
2948 underlying operating system's C<open> function with the parameters
2949 FILENAME, MODE, PERMS.
2950
2951 The possible values and flag bits of the MODE parameter are
2952 system-dependent; they are available via the standard module C<Fcntl>.
2953 However, for historical reasons, some values are universal: zero means
2954 read-only, one means write-only, and two means read/write.
2955
2956 If the file named by FILENAME does not exist and the C<open> call
2957 creates it (typically because MODE includes the O_CREAT flag), then
2958 the value of PERMS specifies the permissions of the newly created
2959 file.  If PERMS is omitted, the default value is 0666, which allows
2960 read and write for all.  This default is reasonable: see C<umask>.
2961
2962 =item sysread FILEHANDLE,SCALAR,LENGTH,OFFSET
2963
2964 =item sysread FILEHANDLE,SCALAR,LENGTH
2965
2966 Attempts to read LENGTH bytes of data into variable SCALAR from the
2967 specified FILEHANDLE, using the system call read(2).  It bypasses
2968 stdio, so mixing this with other kinds of reads may cause confusion.
2969 Returns the number of bytes actually read, or undef if there was an
2970 error.  SCALAR will be grown or shrunk to the length actually read.  An
2971 OFFSET may be specified to place the read data at some other place than
2972 the beginning of the string.
2973
2974 =item system LIST
2975
2976 Does exactly the same thing as "exec LIST" except that a fork is done
2977 first, and the parent process waits for the child process to complete.
2978 Note that argument processing varies depending on the number of
2979 arguments.  The return value is the exit status of the program as
2980 returned by the wait() call.  To get the actual exit value divide by
2981 256.  See also L</exec>.  This is I<NOT> what you want to use to capture 
2982 the output from a command, for that you should merely use backticks, as
2983 described in L<perlop/"`STRING`">.
2984
2985 =item syswrite FILEHANDLE,SCALAR,LENGTH,OFFSET
2986
2987 =item syswrite FILEHANDLE,SCALAR,LENGTH
2988
2989 Attempts to write LENGTH bytes of data from variable SCALAR to the
2990 specified FILEHANDLE, using the system call write(2).  It bypasses
2991 stdio, so mixing this with prints may cause confusion.  Returns the
2992 number of bytes actually written, or undef if there was an error.  An
2993 OFFSET may be specified to get the write data from some other place than
2994 the beginning of the string.
2995
2996 =item tell FILEHANDLE
2997
2998 =item tell
2999
3000 Returns the current file position for FILEHANDLE.  FILEHANDLE may be an
3001 expression whose value gives the name of the actual filehandle.  If
3002 FILEHANDLE is omitted, assumes the file last read.
3003
3004 =item telldir DIRHANDLE
3005
3006 Returns the current position of the readdir() routines on DIRHANDLE.
3007 Value may be given to seekdir() to access a particular location in a
3008 directory.  Has the same caveats about possible directory compaction as
3009 the corresponding system library routine.
3010
3011 =item tie VARIABLE,CLASSNAME,LIST
3012
3013 This function binds a variable to a package class that will provide the
3014 implementation for the variable.  VARIABLE is the name of the variable
3015 to be enchanted.  CLASSNAME is the name of a class implementing objects
3016 of correct type.  Any additional arguments are passed to the "new"
3017 method of the class (meaning TIESCALAR, TIEARRAY, or TIEHASH).
3018 Typically these are arguments such as might be passed to the dbm_open()
3019 function of C.  The object returned by the "new" method is also
3020 returned by the tie() function, which would be useful if you want to
3021 access other methods in CLASSNAME.
3022
3023 Note that functions such as keys() and values() may return huge array
3024 values when used on large objects, like DBM files.  You may prefer to
3025 use the each() function to iterate over such.  Example:
3026
3027     # print out history file offsets
3028     use NDBM_File;
3029     tie(%HIST, 'NDBM_File', '/usr/lib/news/history', 1, 0);
3030     while (($key,$val) = each %HIST) {
3031         print $key, ' = ', unpack('L',$val), "\n";
3032     }
3033     untie(%HIST);
3034
3035 A class implementing an associative array should have the following
3036 methods:
3037
3038     TIEHASH classname, LIST
3039     DESTROY this
3040     FETCH this, key
3041     STORE this, key, value
3042     DELETE this, key
3043     EXISTS this, key
3044     FIRSTKEY this
3045     NEXTKEY this, lastkey
3046
3047 A class implementing an ordinary array should have the following methods:
3048
3049     TIEARRAY classname, LIST
3050     DESTROY this
3051     FETCH this, key
3052     STORE this, key, value
3053     [others TBD]
3054
3055 A class implementing a scalar should have the following methods:
3056
3057     TIESCALAR classname, LIST
3058     DESTROY this
3059     FETCH this, 
3060     STORE this, value
3061
3062 Unlike dbmopen(), the tie() function will not use or require a module
3063 for you--you need to do that explicitly yourself.  See L<DB_File>
3064 or the F<Config> module for interesting tie() implementations.
3065
3066 =item tied VARIABLE
3067
3068 Returns a reference to the object underlying VARIABLE (the same value
3069 that was originally returned by the tie() call which bound the variable
3070 to a package.)  Returns the undefined value if VARIABLE isn't tied to a
3071 package.
3072
3073 =item time
3074
3075 Returns the number of non-leap seconds since whatever time the system
3076 considers to be the epoch (that's 00:00:00, January 1, 1904 for MacOS,
3077 and 00:00:00 UTC, January 1, 1970 for most other systems).
3078 Suitable for feeding to gmtime() and localtime().
3079
3080 =item times
3081
3082 Returns a four-element array giving the user and system times, in
3083 seconds, for this process and the children of this process.
3084
3085     ($user,$system,$cuser,$csystem) = times;
3086
3087 =item tr///
3088
3089 The translation operator.  See L<perlop>.
3090
3091 =item truncate FILEHANDLE,LENGTH
3092
3093 =item truncate EXPR,LENGTH
3094
3095 Truncates the file opened on FILEHANDLE, or named by EXPR, to the
3096 specified length.  Produces a fatal error if truncate isn't implemented
3097 on your system.
3098
3099 =item uc EXPR
3100
3101 Returns an uppercased version of EXPR.  This is the internal function
3102 implementing the \U escape in double-quoted strings.
3103 Should respect any POSIX setlocale() settings.
3104
3105 =item ucfirst EXPR
3106
3107 Returns the value of EXPR with the first character uppercased.  This is
3108 the internal function implementing the \u escape in double-quoted strings.
3109 Should respect any POSIX setlocale() settings.
3110
3111 =item umask EXPR
3112
3113 =item umask
3114
3115 Sets the umask for the process and returns the old one.  If EXPR is
3116 omitted, merely returns current umask.
3117
3118 =item undef EXPR
3119
3120 =item undef
3121
3122 Undefines the value of EXPR, which must be an lvalue.  Use only on a
3123 scalar value, an entire array, or a subroutine name (using "&").  (Using undef()
3124 will probably not do what you expect on most predefined variables or
3125 DBM list values, so don't do that.)  Always returns the undefined value.  You can omit
3126 the EXPR, in which case nothing is undefined, but you still get an
3127 undefined value that you could, for instance, return from a
3128 subroutine.  Examples:
3129
3130     undef $foo;
3131     undef $bar{'blurfl'};
3132     undef @ary;
3133     undef %assoc;
3134     undef &mysub;
3135     return (wantarray ? () : undef) if $they_blew_it;
3136
3137 =item unlink LIST
3138
3139 Deletes a list of files.  Returns the number of files successfully
3140 deleted.
3141
3142     $cnt = unlink 'a', 'b', 'c';
3143     unlink @goners;
3144     unlink <*.bak>;
3145
3146 Note: unlink will not delete directories unless you are superuser and
3147 the B<-U> flag is supplied to Perl.  Even if these conditions are
3148 met, be warned that unlinking a directory can inflict damage on your
3149 filesystem.  Use rmdir instead.
3150
3151 =item unpack TEMPLATE,EXPR
3152
3153 Unpack does the reverse of pack: it takes a string representing a
3154 structure and expands it out into a list value, returning the array
3155 value.  (In a scalar context, it merely returns the first value
3156 produced.)  The TEMPLATE has the same format as in the pack function.
3157 Here's a subroutine that does substring:
3158
3159     sub substr {
3160         local($what,$where,$howmuch) = @_;
3161         unpack("x$where a$howmuch", $what);
3162     }
3163
3164 and then there's
3165
3166     sub ordinal { unpack("c",$_[0]); } # same as ord()
3167
3168 In addition, you may prefix a field with a %<number> to indicate that
3169 you want a <number>-bit checksum of the items instead of the items
3170 themselves.  Default is a 16-bit checksum.  For example, the following
3171 computes the same number as the System V sum program:
3172
3173     while (<>) {
3174         $checksum += unpack("%16C*", $_);
3175     }
3176     $checksum %= 65536;
3177
3178 The following efficiently counts the number of set bits in a bit vector:
3179
3180     $setbits = unpack("%32b*", $selectmask);
3181
3182 =item untie VARIABLE
3183
3184 Breaks the binding between a variable and a package.  (See tie().)
3185
3186 =item unshift ARRAY,LIST
3187
3188 Does the opposite of a C<shift>.  Or the opposite of a C<push>,
3189 depending on how you look at it.  Prepends list to the front of the
3190 array, and returns the new number of elements in the array.
3191
3192     unshift(ARGV, '-e') unless $ARGV[0] =~ /^-/;
3193
3194 Note the LIST is prepended whole, not one element at a time, so the
3195 prepended elements stay in the same order.  Use reverse to do the
3196 reverse.
3197
3198 =item use Module LIST
3199
3200 =item use Module
3201
3202 =item use Module VERSION LIST
3203
3204 =item use VERSION
3205
3206 Imports some semantics into the current package from the named module,
3207 generally by aliasing certain subroutine or variable names into your
3208 package.  It is exactly equivalent to
3209
3210     BEGIN { require Module; import Module LIST; }
3211
3212 except that Module I<must> be a bare word.
3213
3214 If the first argument to C<use> is a number, it is treated as a version
3215 number instead of a module name.  If the version of the Perl interpreter
3216 is less than VERSION, then an error message is printed and Perl exits
3217 immediately.  This is often useful if you need to check the current
3218 Perl version before C<use>ing library modules which have changed in
3219 incompatible ways from older versions of Perl.  (We try not to do
3220 this more than we have to.)
3221
3222 The BEGIN forces the require and import to happen at compile time.  The
3223 require makes sure the module is loaded into memory if it hasn't been
3224 yet.  The import is not a builtin--it's just an ordinary static method
3225 call into the "Module" package to tell the module to import the list of
3226 features back into the current package.  The module can implement its
3227 import method any way it likes, though most modules just choose to
3228 derive their import method via inheritance from the Exporter class that
3229 is defined in the Exporter module. See L<Exporter>.
3230
3231 If you don't want your namespace altered, explicitly supply an empty list:
3232
3233     use Module ();
3234
3235 That is exactly equivalent to
3236
3237     BEGIN { require Module; }
3238
3239 If the VERSION argument is present between Module and LIST, then the
3240 C<use> will fail if the C<$VERSION> variable in package Module is
3241 less than VERSION.
3242
3243 Because this is a wide-open interface, pragmas (compiler directives)
3244 are also implemented this way.  Currently implemented pragmas are:
3245
3246     use integer;
3247     use diagnostics;
3248     use sigtrap qw(SEGV BUS);
3249     use strict  qw(subs vars refs);
3250     use subs    qw(afunc blurfl);
3251
3252 These pseudomodules import semantics into the current block scope, unlike
3253 ordinary modules, which import symbols into the current package (which are
3254 effective through the end of the file).
3255
3256 There's a corresponding "no" command that unimports meanings imported
3257 by use, i.e. it calls C<unimport Module LIST> instead of C<import>.
3258
3259     no integer;
3260     no strict 'refs';
3261
3262 See L<perlmod> for a list of standard modules and pragmas.
3263
3264 =item utime LIST
3265
3266 Changes the access and modification times on each file of a list of
3267 files.  The first two elements of the list must be the NUMERICAL access
3268 and modification times, in that order.  Returns the number of files
3269 successfully changed.  The inode modification time of each file is set
3270 to the current time.  Example of a "touch" command:
3271
3272     #!/usr/bin/perl
3273     $now = time;
3274     utime $now, $now, @ARGV;
3275
3276 =item values ASSOC_ARRAY
3277
3278 Returns a normal array consisting of all the values of the named
3279 associative array.  (In a scalar context, returns the number of
3280 values.)  The values are returned in an apparently random order, but it
3281 is the same order as either the keys() or each() function would produce
3282 on the same array.  See also keys(), each(), and sort().
3283
3284 =item vec EXPR,OFFSET,BITS
3285
3286 Treats the string in EXPR as a vector of unsigned integers, and
3287 returns the value of the bitfield specified by OFFSET.  BITS specifies
3288 the number of bits that are reserved for each entry in the bit
3289 vector. This must be a power of two from 1 to 32. vec() may also be
3290 assigned to, in which case parens are needed to give the expression
3291 the correct precedence as in
3292
3293     vec($image, $max_x * $x + $y, 8) = 3;
3294
3295 Vectors created with vec() can also be manipulated with the logical
3296 operators |, & and ^, which will assume a bit vector operation is
3297 desired when both operands are strings.
3298
3299 To transform a bit vector into a string or array of 0's and 1's, use these:
3300
3301     $bits = unpack("b*", $vector);
3302     @bits = split(//, unpack("b*", $vector));
3303
3304 If you know the exact length in bits, it can be used in place of the *.
3305
3306 =item wait
3307
3308 Waits for a child process to terminate and returns the pid of the
3309 deceased process, or -1 if there are no child processes.  The status is
3310 returned in $?.
3311
3312 =item waitpid PID,FLAGS
3313
3314 Waits for a particular child process to terminate and returns the pid
3315 of the deceased process, or -1 if there is no such child process.  The
3316 status is returned in $?.  If you say
3317
3318     use POSIX "wait_h";
3319     ...
3320     waitpid(-1,&WNOHANG);
3321
3322 then you can do a non-blocking wait for any process.  Non-blocking wait
3323 is only available on machines supporting either the waitpid(2) or
3324 wait4(2) system calls.  However, waiting for a particular pid with
3325 FLAGS of 0 is implemented everywhere.  (Perl emulates the system call
3326 by remembering the status values of processes that have exited but have
3327 not been harvested by the Perl script yet.)
3328
3329 =item wantarray
3330
3331 Returns TRUE if the context of the currently executing subroutine is
3332 looking for a list value.  Returns FALSE if the context is looking
3333 for a scalar.
3334
3335     return wantarray ? () : undef;
3336
3337 =item warn LIST
3338
3339 Produces a message on STDERR just like die(), but doesn't exit or
3340 on an exception.
3341
3342 =item write FILEHANDLE
3343
3344 =item write EXPR
3345
3346 =item write
3347
3348 Writes a formatted record (possibly multi-line) to the specified file,
3349 using the format associated with that file.  By default the format for
3350 a file is the one having the same name is the filehandle, but the
3351 format for the current output channel (see the select() function) may be set
3352 explicitly by assigning the name of the format to the $~ variable.
3353
3354 Top of form processing is handled automatically:  if there is
3355 insufficient room on the current page for the formatted record, the
3356 page is advanced by writing a form feed, a special top-of-page format
3357 is used to format the new page header, and then the record is written.
3358 By default the top-of-page format is the name of the filehandle with
3359 "_TOP" appended, but it may be dynamically set to the format of your
3360 choice by assigning the name to the $^ variable while the filehandle is
3361 selected.  The number of lines remaining on the current page is in
3362 variable $-, which can be set to 0 to force a new page.
3363
3364 If FILEHANDLE is unspecified, output goes to the current default output
3365 channel, which starts out as STDOUT but may be changed by the
3366 C<select> operator.  If the FILEHANDLE is an EXPR, then the expression
3367 is evaluated and the resulting string is used to look up the name of
3368 the FILEHANDLE at run time.  For more on formats, see L<perlform>.
3369
3370 Note that write is I<NOT> the opposite of read.  Unfortunately.
3371
3372 =item y///
3373
3374 The translation operator.  See L<perlop>.
3375
3376 =back