document the specific value of $!{E...}
[perl.git] / pod / perlvar.pod
1 =head1 NAME
2
3 perlvar - Perl predefined variables
4
5 =head1 DESCRIPTION
6
7 =head2 The Syntax of Variable Names
8
9 Variable names in Perl can have several formats.  Usually, they
10 must begin with a letter or underscore, in which case they can be
11 arbitrarily long (up to an internal limit of 251 characters) and
12 may contain letters, digits, underscores, or the special sequence
13 C<::> or C<'>.  In this case, the part before the last C<::> or
14 C<'> is taken to be a I<package qualifier>; see L<perlmod>.
15 A Unicode letter that is not ASCII is not considered to be a letter
16 unless S<C<"use utf8">> is in effect, and somewhat more complicated
17 rules apply; see L<perldata/Identifier parsing> for details.
18
19 Perl variable names may also be a sequence of digits, a single
20 punctuation character, or the two-character sequence: C<^> (caret or
21 CIRCUMFLEX ACCENT) followed by any one of the characters C<[][A-Z^_?\]>.
22 These names are all reserved for
23 special uses by Perl; for example, the all-digits names are used
24 to hold data captured by backreferences after a regular expression
25 match.
26
27 Since Perl v5.6.0, Perl variable names may also be alphanumeric strings
28 preceded by a caret.  These must all be written in the form C<${^Foo}>;
29 the braces are not optional.  C<${^Foo}> denotes the scalar variable
30 whose name is considered to be a control-C<F> followed by two C<o>'s.
31 These variables are
32 reserved for future special uses by Perl, except for the ones that
33 begin with C<^_> (caret-underscore).  No
34 name that begins with C<^_> will acquire a special
35 meaning in any future version of Perl; such names may therefore be
36 used safely in programs.  C<$^_> itself, however, I<is> reserved.
37
38 Perl identifiers that begin with digits or
39 punctuation characters are exempt from the effects of the C<package>
40 declaration and are always forced to be in package C<main>; they are
41 also exempt from C<strict 'vars'> errors.  A few other names are also
42 exempt in these ways:
43
44     ENV      STDIN
45     INC      STDOUT
46     ARGV     STDERR
47     ARGVOUT
48     SIG
49
50 In particular, the special C<${^_XYZ}> variables are always taken
51 to be in package C<main>, regardless of any C<package> declarations
52 presently in scope.
53
54 =head1 SPECIAL VARIABLES
55
56 The following names have special meaning to Perl.  Most punctuation
57 names have reasonable mnemonics, or analogs in the shells.
58 Nevertheless, if you wish to use long variable names, you need only say:
59
60     use English;
61
62 at the top of your program.  This aliases all the short names to the long
63 names in the current package.  Some even have medium names, generally
64 borrowed from B<awk>.  For more info, please see L<English>.
65
66 Before you continue, note the sort order for variables.  In general, we
67 first list the variables in case-insensitive, almost-lexigraphical
68 order (ignoring the C<{> or C<^> preceding words, as in C<${^UNICODE}>
69 or C<$^T>), although C<$_> and C<@_> move up to the top of the pile.
70 For variables with the same identifier, we list it in order of scalar,
71 array, hash, and bareword.
72
73 =head2 General Variables
74
75 =over 8
76
77 =item $ARG
78
79 =item $_
80 X<$_> X<$ARG>
81
82 The default input and pattern-searching space.  The following pairs are
83 equivalent:
84
85     while (<>) {...}    # equivalent only in while!
86     while (defined($_ = <>)) {...}
87
88     /^Subject:/
89     $_ =~ /^Subject:/
90
91     tr/a-z/A-Z/
92     $_ =~ tr/a-z/A-Z/
93
94     chomp
95     chomp($_)
96
97 Here are the places where Perl will assume C<$_> even if you don't use it:
98
99 =over 3
100
101 =item *
102
103 The following functions use C<$_> as a default argument:
104
105 abs, alarm, chomp, chop, chr, chroot,
106 cos, defined, eval, evalbytes, exp, fc, glob, hex, int, lc,
107 lcfirst, length, log, lstat, mkdir, oct, ord, pos, print, printf,
108 quotemeta, readlink, readpipe, ref, require, reverse (in scalar context only),
109 rmdir, say, sin, split (for its second
110 argument), sqrt, stat, study, uc, ucfirst,
111 unlink, unpack.
112
113 =item *
114
115 All file tests (C<-f>, C<-d>) except for C<-t>, which defaults to STDIN.
116 See L<perlfunc/-X>
117
118 =item *
119
120 The pattern matching operations C<m//>, C<s///> and C<tr///> (aka C<y///>)
121 when used without an C<=~> operator.
122
123 =item *
124
125 The default iterator variable in a C<foreach> loop if no other
126 variable is supplied.
127
128 =item *
129
130 The implicit iterator variable in the C<grep()> and C<map()> functions.
131
132 =item *
133
134 The implicit variable of C<given()>.
135
136 =item *
137
138 The default place to put the next value or input record
139 when a C<< <FH> >>, C<readline>, C<readdir> or C<each>
140 operation's result is tested by itself as the sole criterion of a C<while>
141 test.  Outside a C<while> test, this will not happen.
142
143 =back
144
145 C<$_> is by default a global variable.  However, as
146 of perl v5.10.0, you can use a lexical version of
147 C<$_> by declaring it in a file or in a block with C<my>.  Moreover,
148 declaring C<our $_> restores the global C<$_> in the current scope.  Though
149 this seemed like a good idea at the time it was introduced, lexical C<$_>
150 actually causes more problems than it solves.  If you call a function that
151 expects to be passed information via C<$_>, it may or may not work,
152 depending on how the function is written, there not being any easy way to
153 solve this.  Just avoid lexical C<$_>, unless you are feeling particularly
154 masochistic.  For this reason lexical C<$_> is still experimental and will
155 produce a warning unless warnings have been disabled.  As with other
156 experimental features, the behavior of lexical C<$_> is subject to change
157 without notice, including change into a fatal error.
158
159 Mnemonic: underline is understood in certain operations.
160
161 =item @ARG
162
163 =item @_
164 X<@_> X<@ARG>
165
166 Within a subroutine the array C<@_> contains the parameters passed to
167 that subroutine.  Inside a subroutine, C<@_> is the default array for
168 the array operators C<pop> and C<shift>.
169
170 See L<perlsub>.
171
172 =item $LIST_SEPARATOR
173
174 =item $"
175 X<$"> X<$LIST_SEPARATOR>
176
177 When an array or an array slice is interpolated into a double-quoted
178 string or a similar context such as C</.../>, its elements are
179 separated by this value.  Default is a space.  For example, this:
180
181     print "The array is: @array\n";
182
183 is equivalent to this:
184
185     print "The array is: " . join($", @array) . "\n";
186
187 Mnemonic: works in double-quoted context.
188
189 =item $PROCESS_ID
190
191 =item $PID
192
193 =item $$
194 X<$$> X<$PID> X<$PROCESS_ID>
195
196 The process number of the Perl running this script.  Though you I<can> set
197 this variable, doing so is generally discouraged, although it can be
198 invaluable for some testing purposes.  It will be reset automatically
199 across C<fork()> calls.
200
201 Note for Linux and Debian GNU/kFreeBSD users: Before Perl v5.16.0 perl
202 would emulate POSIX semantics on Linux systems using LinuxThreads, a
203 partial implementation of POSIX Threads that has since been superseded
204 by the Native POSIX Thread Library (NPTL).
205
206 LinuxThreads is now obsolete on Linux, and caching C<getpid()>
207 like this made embedding perl unnecessarily complex (since you'd have
208 to manually update the value of $$), so now C<$$> and C<getppid()>
209 will always return the same values as the underlying C library.
210
211 Debian GNU/kFreeBSD systems also used LinuxThreads up until and
212 including the 6.0 release, but after that moved to FreeBSD thread
213 semantics, which are POSIX-like.
214
215 To see if your system is affected by this discrepancy check if
216 C<getconf GNU_LIBPTHREAD_VERSION | grep -q NPTL> returns a false
217 value.  NTPL threads preserve the POSIX semantics.
218
219 Mnemonic: same as shells.
220
221 =item $PROGRAM_NAME
222
223 =item $0
224 X<$0> X<$PROGRAM_NAME>
225
226 Contains the name of the program being executed.
227
228 On some (but not all) operating systems assigning to C<$0> modifies
229 the argument area that the C<ps> program sees.  On some platforms you
230 may have to use special C<ps> options or a different C<ps> to see the
231 changes.  Modifying the C<$0> is more useful as a way of indicating the
232 current program state than it is for hiding the program you're
233 running.
234
235 Note that there are platform-specific limitations on the maximum
236 length of C<$0>.  In the most extreme case it may be limited to the
237 space occupied by the original C<$0>.
238
239 In some platforms there may be arbitrary amount of padding, for
240 example space characters, after the modified name as shown by C<ps>.
241 In some platforms this padding may extend all the way to the original
242 length of the argument area, no matter what you do (this is the case
243 for example with Linux 2.2).
244
245 Note for BSD users: setting C<$0> does not completely remove "perl"
246 from the ps(1) output.  For example, setting C<$0> to C<"foobar"> may
247 result in C<"perl: foobar (perl)"> (whether both the C<"perl: "> prefix
248 and the " (perl)" suffix are shown depends on your exact BSD variant
249 and version).  This is an operating system feature, Perl cannot help it.
250
251 In multithreaded scripts Perl coordinates the threads so that any
252 thread may modify its copy of the C<$0> and the change becomes visible
253 to ps(1) (assuming the operating system plays along).  Note that
254 the view of C<$0> the other threads have will not change since they
255 have their own copies of it.
256
257 If the program has been given to perl via the switches C<-e> or C<-E>,
258 C<$0> will contain the string C<"-e">.
259
260 On Linux as of perl v5.14.0 the legacy process name will be set with
261 C<prctl(2)>, in addition to altering the POSIX name via C<argv[0]> as
262 perl has done since version 4.000.  Now system utilities that read the
263 legacy process name such as ps, top and killall will recognize the
264 name you set when assigning to C<$0>.  The string you supply will be
265 cut off at 16 bytes, this is a limitation imposed by Linux.
266
267 Mnemonic: same as B<sh> and B<ksh>.
268
269 =item $REAL_GROUP_ID
270
271 =item $GID
272
273 =item $(
274 X<$(> X<$GID> X<$REAL_GROUP_ID>
275
276 The real gid of this process.  If you are on a machine that supports
277 membership in multiple groups simultaneously, gives a space separated
278 list of groups you are in.  The first number is the one returned by
279 C<getgid()>, and the subsequent ones by C<getgroups()>, one of which may be
280 the same as the first number.
281
282 However, a value assigned to C<$(> must be a single number used to
283 set the real gid.  So the value given by C<$(> should I<not> be assigned
284 back to C<$(> without being forced numeric, such as by adding zero.  Note
285 that this is different to the effective gid (C<$)>) which does take a
286 list.
287
288 You can change both the real gid and the effective gid at the same
289 time by using C<POSIX::setgid()>.  Changes
290 to C<$(> require a check to C<$!>
291 to detect any possible errors after an attempted change.
292
293 Mnemonic: parentheses are used to I<group> things.  The real gid is the
294 group you I<left>, if you're running setgid.
295
296 =item $EFFECTIVE_GROUP_ID
297
298 =item $EGID
299
300 =item $)
301 X<$)> X<$EGID> X<$EFFECTIVE_GROUP_ID>
302
303 The effective gid of this process.  If you are on a machine that
304 supports membership in multiple groups simultaneously, gives a space
305 separated list of groups you are in.  The first number is the one
306 returned by C<getegid()>, and the subsequent ones by C<getgroups()>,
307 one of which may be the same as the first number.
308
309 Similarly, a value assigned to C<$)> must also be a space-separated
310 list of numbers.  The first number sets the effective gid, and
311 the rest (if any) are passed to C<setgroups()>.  To get the effect of an
312 empty list for C<setgroups()>, just repeat the new effective gid; that is,
313 to force an effective gid of 5 and an effectively empty C<setgroups()>
314 list, say C< $) = "5 5" >.
315
316 You can change both the effective gid and the real gid at the same
317 time by using C<POSIX::setgid()> (use only a single numeric argument).
318 Changes to C<$)> require a check to C<$!> to detect any possible errors
319 after an attempted change.
320
321 C<< $< >>, C<< $> >>, C<$(> and C<$)> can be set only on
322 machines that support the corresponding I<set[re][ug]id()> routine.  C<$(>
323 and C<$)> can be swapped only on machines supporting C<setregid()>.
324
325 Mnemonic: parentheses are used to I<group> things.  The effective gid
326 is the group that's I<right> for you, if you're running setgid.
327
328 =item $REAL_USER_ID
329
330 =item $UID
331
332 =item $<
333 X<< $< >> X<$UID> X<$REAL_USER_ID>
334
335 The real uid of this process.  You can change both the real uid and the
336 effective uid at the same time by using C<POSIX::setuid()>.  Since
337 changes to C<< $< >> require a system call, check C<$!> after a change
338 attempt to detect any possible errors.
339
340 Mnemonic: it's the uid you came I<from>, if you're running setuid.
341
342 =item $EFFECTIVE_USER_ID
343
344 =item $EUID
345
346 =item $>
347 X<< $> >> X<$EUID> X<$EFFECTIVE_USER_ID>
348
349 The effective uid of this process.  For example:
350
351     $< = $>;            # set real to effective uid
352     ($<,$>) = ($>,$<);  # swap real and effective uids
353
354 You can change both the effective uid and the real uid at the same
355 time by using C<POSIX::setuid()>.  Changes to C<< $> >> require a check
356 to C<$!> to detect any possible errors after an attempted change.
357
358 C<< $< >> and C<< $> >> can be swapped only on machines
359 supporting C<setreuid()>.
360
361 Mnemonic: it's the uid you went I<to>, if you're running setuid.
362
363 =item $SUBSCRIPT_SEPARATOR
364
365 =item $SUBSEP
366
367 =item $;
368 X<$;> X<$SUBSEP> X<SUBSCRIPT_SEPARATOR>
369
370 The subscript separator for multidimensional array emulation.  If you
371 refer to a hash element as
372
373     $foo{$x,$y,$z}
374
375 it really means
376
377     $foo{join($;, $x, $y, $z)}
378
379 But don't put
380
381     @foo{$x,$y,$z}      # a slice--note the @
382
383 which means
384
385     ($foo{$x},$foo{$y},$foo{$z})
386
387 Default is "\034", the same as SUBSEP in B<awk>.  If your keys contain
388 binary data there might not be any safe value for C<$;>.
389
390 Consider using "real" multidimensional arrays as described
391 in L<perllol>.
392
393 Mnemonic: comma (the syntactic subscript separator) is a semi-semicolon.
394
395 =item $a
396
397 =item $b
398 X<$a> X<$b>
399
400 Special package variables when using C<sort()>, see L<perlfunc/sort>.
401 Because of this specialness C<$a> and C<$b> don't need to be declared
402 (using C<use vars>, or C<our()>) even when using the C<strict 'vars'>
403 pragma.  Don't lexicalize them with C<my $a> or C<my $b> if you want to
404 be able to use them in the C<sort()> comparison block or function.
405
406 =item %ENV
407 X<%ENV>
408
409 The hash C<%ENV> contains your current environment.  Setting a
410 value in C<ENV> changes the environment for any child processes
411 you subsequently C<fork()> off.
412
413 As of v5.18.0, both keys and values stored in C<%ENV> are stringified.
414
415     my $foo = 1;
416     $ENV{'bar'} = \$foo;
417     if( ref $ENV{'bar'} ) {
418         say "Pre 5.18.0 Behaviour";
419     } else {
420         say "Post 5.18.0 Behaviour";
421     }
422
423 Previously, only child processes received stringified values:
424
425     my $foo = 1;
426     $ENV{'bar'} = \$foo;
427
428     # Always printed 'non ref'
429     system($^X, '-e',
430            q/print ( ref $ENV{'bar'}  ? 'ref' : 'non ref' ) /);
431
432 This happens because you can't really share arbitrary data structures with
433 foreign processes.
434
435 =item $OLD_PERL_VERSION
436
437 =item $]
438 X<$]> X<$OLD_PERL_VERSION>
439
440 The revision, version, and subversion of the Perl interpreter, represented
441 as a decimal of the form 5.XXXYYY, where XXX is the version / 1e3 and YYY
442 is the subversion / 1e6.  For example, Perl v5.10.1 would be "5.010001".
443
444 This variable can be used to determine whether the Perl interpreter
445 executing a script is in the right range of versions:
446
447     warn "No PerlIO!\n" if $] lt '5.008';
448
449 When comparing C<$]>, string comparison operators are B<highly
450 recommended>.  The inherent limitations of binary floating point
451 representation can sometimes lead to incorrect comparisons for some
452 numbers on some architectures.
453
454 See also the documentation of C<use VERSION> and C<require VERSION>
455 for a convenient way to fail if the running Perl interpreter is too old.
456
457 See L</$^V> for a representation of the Perl version as a L<version>
458 object, which allows more flexible string comparisons.
459
460 The main advantage of C<$]> over C<$^V> is that it works the same on any
461 version of Perl.  The disadvantages are that it can't easily be compared
462 to versions in other formats (e.g. literal v-strings, "v1.2.3" or
463 version objects) and numeric comparisons can occasionally fail; it's good
464 for string literal version checks and bad for comparing to a variable
465 that hasn't been sanity-checked.
466
467 The C<$OLD_PERL_VERSION> form was added in Perl v5.20.0 for historical
468 reasons but its use is discouraged. (If your reason to use C<$]> is to
469 run code on old perls then referring to it as C<$OLD_PERL_VERSION> would
470 be self-defeating.)
471
472 Mnemonic: Is this version of perl in the right bracket?
473
474 =item $SYSTEM_FD_MAX
475
476 =item $^F
477 X<$^F> X<$SYSTEM_FD_MAX>
478
479 The maximum system file descriptor, ordinarily 2.  System file
480 descriptors are passed to C<exec()>ed processes, while higher file
481 descriptors are not.  Also, during an
482 C<open()>, system file descriptors are
483 preserved even if the C<open()> fails (ordinary file descriptors are
484 closed before the C<open()> is attempted).  The close-on-exec
485 status of a file descriptor will be decided according to the value of
486 C<$^F> when the corresponding file, pipe, or socket was opened, not the
487 time of the C<exec()>.
488
489 =item @F
490 X<@F>
491
492 The array C<@F> contains the fields of each line read in when autosplit
493 mode is turned on.  See L<perlrun> for the B<-a> switch.  This array
494 is package-specific, and must be declared or given a full package name
495 if not in package main when running under C<strict 'vars'>.
496
497 =item @INC
498 X<@INC>
499
500 The array C<@INC> contains the list of places that the C<do EXPR>,
501 C<require>, or C<use> constructs look for their library files.  It
502 initially consists of the arguments to any B<-I> command-line
503 switches, followed by the default Perl library, probably
504 F</usr/local/lib/perl>, followed by ".", to represent the current
505 directory.  ("." will not be appended if taint checks are enabled,
506 either by C<-T> or by C<-t>.)  If you need to modify this at runtime,
507 you should use the C<use lib> pragma to get the machine-dependent
508 library properly loaded also:
509
510     use lib '/mypath/libdir/';
511     use SomeMod;
512
513 You can also insert hooks into the file inclusion system by putting Perl
514 code directly into C<@INC>.  Those hooks may be subroutine references,
515 array references or blessed objects.  See L<perlfunc/require> for details.
516
517 =item %INC
518 X<%INC>
519
520 The hash C<%INC> contains entries for each filename included via the
521 C<do>, C<require>, or C<use> operators.  The key is the filename
522 you specified (with module names converted to pathnames), and the
523 value is the location of the file found.  The C<require>
524 operator uses this hash to determine whether a particular file has
525 already been included.
526
527 If the file was loaded via a hook (e.g. a subroutine reference, see
528 L<perlfunc/require> for a description of these hooks), this hook is
529 by default inserted into C<%INC> in place of a filename.  Note, however,
530 that the hook may have set the C<%INC> entry by itself to provide some more
531 specific info.
532
533 =item $INPLACE_EDIT
534
535 =item $^I
536 X<$^I> X<$INPLACE_EDIT>
537
538 The current value of the inplace-edit extension.  Use C<undef> to disable
539 inplace editing.
540
541 Mnemonic: value of B<-i> switch.
542
543 =item $^M
544 X<$^M>
545
546 By default, running out of memory is an untrappable, fatal error.
547 However, if suitably built, Perl can use the contents of C<$^M>
548 as an emergency memory pool after C<die()>ing.  Suppose that your Perl
549 were compiled with C<-DPERL_EMERGENCY_SBRK> and used Perl's malloc.
550 Then
551
552     $^M = 'a' x (1 << 16);
553
554 would allocate a 64K buffer for use in an emergency.  See the
555 F<INSTALL> file in the Perl distribution for information on how to
556 add custom C compilation flags when compiling perl.  To discourage casual
557 use of this advanced feature, there is no L<English|English> long name for
558 this variable.
559
560 This variable was added in Perl 5.004.
561
562 =item $OSNAME
563
564 =item $^O
565 X<$^O> X<$OSNAME>
566
567 The name of the operating system under which this copy of Perl was
568 built, as determined during the configuration process.  For examples
569 see L<perlport/PLATFORMS>.
570
571 The value is identical to C<$Config{'osname'}>.  See also L<Config>
572 and the B<-V> command-line switch documented in L<perlrun>.
573
574 In Windows platforms, C<$^O> is not very helpful: since it is always
575 C<MSWin32>, it doesn't tell the difference between
576 95/98/ME/NT/2000/XP/CE/.NET.  Use C<Win32::GetOSName()> or
577 Win32::GetOSVersion() (see L<Win32> and L<perlport>) to distinguish
578 between the variants.
579
580 This variable was added in Perl 5.003.
581
582 =item %SIG
583 X<%SIG>
584
585 The hash C<%SIG> contains signal handlers for signals.  For example:
586
587     sub handler {   # 1st argument is signal name
588         my($sig) = @_;
589         print "Caught a SIG$sig--shutting down\n";
590         close(LOG);
591         exit(0);
592         }
593
594     $SIG{'INT'}  = \&handler;
595     $SIG{'QUIT'} = \&handler;
596     ...
597     $SIG{'INT'}  = 'DEFAULT';   # restore default action
598     $SIG{'QUIT'} = 'IGNORE';    # ignore SIGQUIT
599
600 Using a value of C<'IGNORE'> usually has the effect of ignoring the
601 signal, except for the C<CHLD> signal.  See L<perlipc> for more about
602 this special case.
603
604 Here are some other examples:
605
606     $SIG{"PIPE"} = "Plumber";   # assumes main::Plumber (not
607                                 # recommended)
608     $SIG{"PIPE"} = \&Plumber;   # just fine; assume current
609                                 # Plumber
610     $SIG{"PIPE"} = *Plumber;    # somewhat esoteric
611     $SIG{"PIPE"} = Plumber();   # oops, what did Plumber()
612                                 # return??
613
614 Be sure not to use a bareword as the name of a signal handler,
615 lest you inadvertently call it.
616
617 If your system has the C<sigaction()> function then signal handlers
618 are installed using it.  This means you get reliable signal handling.
619
620 The default delivery policy of signals changed in Perl v5.8.0 from
621 immediate (also known as "unsafe") to deferred, also known as "safe
622 signals".  See L<perlipc> for more information.
623
624 Certain internal hooks can be also set using the C<%SIG> hash.  The
625 routine indicated by C<$SIG{__WARN__}> is called when a warning
626 message is about to be printed.  The warning message is passed as the
627 first argument.  The presence of a C<__WARN__> hook causes the
628 ordinary printing of warnings to C<STDERR> to be suppressed.  You can
629 use this to save warnings in a variable, or turn warnings into fatal
630 errors, like this:
631
632     local $SIG{__WARN__} = sub { die $_[0] };
633     eval $proggie;
634
635 As the C<'IGNORE'> hook is not supported by C<__WARN__>, you can
636 disable warnings using the empty subroutine:
637
638     local $SIG{__WARN__} = sub {};
639
640 The routine indicated by C<$SIG{__DIE__}> is called when a fatal
641 exception is about to be thrown.  The error message is passed as the
642 first argument.  When a C<__DIE__> hook routine returns, the exception
643 processing continues as it would have in the absence of the hook,
644 unless the hook routine itself exits via a C<goto &sub>, a loop exit,
645 or a C<die()>.  The C<__DIE__> handler is explicitly disabled during
646 the call, so that you can die from a C<__DIE__> handler.  Similarly
647 for C<__WARN__>.
648
649 Due to an implementation glitch, the C<$SIG{__DIE__}> hook is called
650 even inside an C<eval()>.  Do not use this to rewrite a pending
651 exception in C<$@>, or as a bizarre substitute for overriding
652 C<CORE::GLOBAL::die()>.  This strange action at a distance may be fixed
653 in a future release so that C<$SIG{__DIE__}> is only called if your
654 program is about to exit, as was the original intent.  Any other use is
655 deprecated.
656
657 C<__DIE__>/C<__WARN__> handlers are very special in one respect: they
658 may be called to report (probable) errors found by the parser.  In such
659 a case the parser may be in inconsistent state, so any attempt to
660 evaluate Perl code from such a handler will probably result in a
661 segfault.  This means that warnings or errors that result from parsing
662 Perl should be used with extreme caution, like this:
663
664     require Carp if defined $^S;
665     Carp::confess("Something wrong") if defined &Carp::confess;
666     die "Something wrong, but could not load Carp to give "
667       . "backtrace...\n\t"
668       . "To see backtrace try starting Perl with -MCarp switch";
669
670 Here the first line will load C<Carp> I<unless> it is the parser who
671 called the handler.  The second line will print backtrace and die if
672 C<Carp> was available.  The third line will be executed only if C<Carp> was
673 not available.
674
675 Having to even think about the C<$^S> variable in your exception
676 handlers is simply wrong.  C<$SIG{__DIE__}> as currently implemented
677 invites grievous and difficult to track down errors.  Avoid it
678 and use an C<END{}> or CORE::GLOBAL::die override instead.
679
680 See L<perlfunc/die>, L<perlfunc/warn>, L<perlfunc/eval>, and
681 L<warnings> for additional information.
682
683 =item $BASETIME
684
685 =item $^T
686 X<$^T> X<$BASETIME>
687
688 The time at which the program began running, in seconds since the
689 epoch (beginning of 1970).  The values returned by the B<-M>, B<-A>,
690 and B<-C> filetests are based on this value.
691
692 =item $PERL_VERSION
693
694 =item $^V
695 X<$^V> X<$PERL_VERSION>
696
697 The revision, version, and subversion of the Perl interpreter,
698 represented as a L<version> object.
699
700 This variable first appeared in perl v5.6.0; earlier versions of perl
701 will see an undefined value.  Before perl v5.10.0 C<$^V> was represented
702 as a v-string rather than a L<version> object.
703
704 C<$^V> can be used to determine whether the Perl interpreter executing
705 a script is in the right range of versions.  For example:
706
707     warn "Hashes not randomized!\n" if !$^V or $^V lt v5.8.1
708
709 While version objects overload stringification, to portably convert
710 C<$^V> into its string representation, use C<sprintf()>'s C<"%vd">
711 conversion, which works for both v-strings or version objects:
712
713     printf "version is v%vd\n", $^V;  # Perl's version
714
715 See the documentation of C<use VERSION> and C<require VERSION>
716 for a convenient way to fail if the running Perl interpreter is too old.
717
718 See also C<$]> for a decimal representation of the Perl version.
719
720 The main advantage of C<$^V> over C<$]> is that, for Perl v5.10.0 or
721 later, it overloads operators, allowing easy comparison against other
722 version representations (e.g. decimal, literal v-string, "v1.2.3", or
723 objects).  The disadvantage is that prior to v5.10.0, it was only a
724 literal v-string, which can't be easily printed or compared.
725
726 Mnemonic: use ^V for a version object.
727
728 =item ${^WIN32_SLOPPY_STAT}
729 X<${^WIN32_SLOPPY_STAT}> X<sitecustomize> X<sitecustomize.pl>
730
731 If this variable is set to a true value, then C<stat()> on Windows will
732 not try to open the file.  This means that the link count cannot be
733 determined and file attributes may be out of date if additional
734 hardlinks to the file exist.  On the other hand, not opening the file
735 is considerably faster, especially for files on network drives.
736
737 This variable could be set in the F<sitecustomize.pl> file to
738 configure the local Perl installation to use "sloppy" C<stat()> by
739 default.  See the documentation for B<-f> in
740 L<perlrun|perlrun/"Command Switches"> for more information about site
741 customization.
742
743 This variable was added in Perl v5.10.0.
744
745 =item $EXECUTABLE_NAME
746
747 =item $^X
748 X<$^X> X<$EXECUTABLE_NAME>
749
750 The name used to execute the current copy of Perl, from C's
751 C<argv[0]> or (where supported) F</proc/self/exe>.
752
753 Depending on the host operating system, the value of C<$^X> may be
754 a relative or absolute pathname of the perl program file, or may
755 be the string used to invoke perl but not the pathname of the
756 perl program file.  Also, most operating systems permit invoking
757 programs that are not in the PATH environment variable, so there
758 is no guarantee that the value of C<$^X> is in PATH.  For VMS, the
759 value may or may not include a version number.
760
761 You usually can use the value of C<$^X> to re-invoke an independent
762 copy of the same perl that is currently running, e.g.,
763
764     @first_run = `$^X -le "print int rand 100 for 1..100"`;
765
766 But recall that not all operating systems support forking or
767 capturing of the output of commands, so this complex statement
768 may not be portable.
769
770 It is not safe to use the value of C<$^X> as a path name of a file,
771 as some operating systems that have a mandatory suffix on
772 executable files do not require use of the suffix when invoking
773 a command.  To convert the value of C<$^X> to a path name, use the
774 following statements:
775
776     # Build up a set of file names (not command names).
777     use Config;
778     my $this_perl = $^X;
779     if ($^O ne 'VMS') {
780         $this_perl .= $Config{_exe}
781           unless $this_perl =~ m/$Config{_exe}$/i;
782         }
783
784 Because many operating systems permit anyone with read access to
785 the Perl program file to make a copy of it, patch the copy, and
786 then execute the copy, the security-conscious Perl programmer
787 should take care to invoke the installed copy of perl, not the
788 copy referenced by C<$^X>.  The following statements accomplish
789 this goal, and produce a pathname that can be invoked as a
790 command or referenced as a file.
791
792     use Config;
793     my $secure_perl_path = $Config{perlpath};
794     if ($^O ne 'VMS') {
795         $secure_perl_path .= $Config{_exe}
796             unless $secure_perl_path =~ m/$Config{_exe}$/i;
797         }
798
799 =back
800
801 =head2 Variables related to regular expressions
802
803 Most of the special variables related to regular expressions are side
804 effects.  Perl sets these variables when it has a successful match, so
805 you should check the match result before using them.  For instance:
806
807     if( /P(A)TT(ER)N/ ) {
808         print "I found $1 and $2\n";
809         }
810
811 These variables are read-only and dynamically-scoped, unless we note
812 otherwise.
813
814 The dynamic nature of the regular expression variables means that
815 their value is limited to the block that they are in, as demonstrated
816 by this bit of code:
817
818     my $outer = 'Wallace and Grommit';
819     my $inner = 'Mutt and Jeff';
820
821     my $pattern = qr/(\S+) and (\S+)/;
822
823     sub show_n { print "\$1 is $1; \$2 is $2\n" }
824
825     {
826     OUTER:
827         show_n() if $outer =~ m/$pattern/;
828
829         INNER: {
830             show_n() if $inner =~ m/$pattern/;
831             }
832
833         show_n();
834     }
835
836 The output shows that while in the C<OUTER> block, the values of C<$1>
837 and C<$2> are from the match against C<$outer>.  Inside the C<INNER>
838 block, the values of C<$1> and C<$2> are from the match against
839 C<$inner>, but only until the end of the block (i.e. the dynamic
840 scope).  After the C<INNER> block completes, the values of C<$1> and
841 C<$2> return to the values for the match against C<$outer> even though
842 we have not made another match:
843
844     $1 is Wallace; $2 is Grommit
845     $1 is Mutt; $2 is Jeff
846     $1 is Wallace; $2 is Grommit
847
848 =head3 Performance issues
849
850 Traditionally in Perl, any use of any of the three variables  C<$`>, C<$&>
851 or C<$'> (or their C<use English> equivalents) anywhere in the code, caused
852 all subsequent successful pattern matches to make a copy of the matched
853 string, in case the code might subsequently access one of those variables.
854 This imposed a considerable performance penalty across the whole program,
855 so generally the use of these variables has been discouraged.
856
857 In Perl 5.6.0 the C<@-> and C<@+> dynamic arrays were introduced that
858 supply the indices of successful matches. So you could for example do
859 this:
860
861     $str =~ /pattern/;
862
863     print $`, $&, $'; # bad: perfomance hit
864
865     print             # good: no perfomance hit
866         substr($str, 0,     $-[0]),
867         substr($str, $-[0], $+[0]-$-[0]),
868         substr($str, $+[0]);
869
870 In Perl 5.10.0 the C</p> match operator flag and the C<${^PREMATCH}>,
871 C<${^MATCH}>, and C<${^POSTMATCH}> variables were introduced, that allowed
872 you to suffer the penalties only on patterns marked with C</p>.
873
874 In Perl 5.18.0 onwards, perl started noting the presence of each of the
875 three variables separately, and only copied that part of the string
876 required; so in
877
878     $`; $&; "abcdefgh" =~ /d/
879
880 perl would only copy the "abcd" part of the string. That could make a big
881 difference in something like
882
883     $str = 'x' x 1_000_000;
884     $&; # whoops
885     $str =~ /x/g # one char copied a million times, not a million chars
886
887 In Perl 5.20.0 a new copy-on-write system was enabled by default, which
888 finally fixes all performance issues with these three variables, and makes
889 them safe to use anywhere.
890
891 The C<Devel::NYTProf> and C<Devel::FindAmpersand> modules can help you
892 find uses of these problematic match variables in your code.
893
894 =over 8
895
896 =item $<I<digits>> ($1, $2, ...)
897 X<$1> X<$2> X<$3>
898
899 Contains the subpattern from the corresponding set of capturing
900 parentheses from the last successful pattern match, not counting patterns
901 matched in nested blocks that have been exited already.
902
903 These variables are read-only and dynamically-scoped.
904
905 Mnemonic: like \digits.
906
907 =item $MATCH
908
909 =item $&
910 X<$&> X<$MATCH>
911
912 The string matched by the last successful pattern match (not counting
913 any matches hidden within a BLOCK or C<eval()> enclosed by the current
914 BLOCK).
915
916 See L</Performance issues> above for the serious performance implications
917 of using this variable (even once) in your code.
918
919 This variable is read-only and dynamically-scoped.
920
921 Mnemonic: like C<&> in some editors.
922
923 =item ${^MATCH}
924 X<${^MATCH}>
925
926 This is similar to C<$&> (C<$MATCH>) except that it does not incur the
927 performance penalty associated with that variable.
928
929 See L</Performance issues> above.
930
931 In Perl v5.18 and earlier, it is only guaranteed
932 to return a defined value when the pattern was compiled or executed with
933 the C</p> modifier.  In Perl v5.20, the C</p> modifier does nothing, so
934 C<${^MATCH}> does the same thing as C<$MATCH>.
935
936 This variable was added in Perl v5.10.0.
937
938 This variable is read-only and dynamically-scoped.
939
940 =item $PREMATCH
941
942 =item $`
943 X<$`> X<$PREMATCH> X<${^PREMATCH}>
944
945 The string preceding whatever was matched by the last successful
946 pattern match, not counting any matches hidden within a BLOCK or C<eval>
947 enclosed by the current BLOCK.
948
949 See L</Performance issues> above for the serious performance implications
950 of using this variable (even once) in your code.
951
952 This variable is read-only and dynamically-scoped.
953
954 Mnemonic: C<`> often precedes a quoted string.
955
956 =item ${^PREMATCH}
957 X<$`> X<${^PREMATCH}>
958
959 This is similar to C<$`> ($PREMATCH) except that it does not incur the
960 performance penalty associated with that variable.
961
962 See L</Performance issues> above.
963
964 In Perl v5.18 and earlier, it is only guaranteed
965 to return a defined value when the pattern was compiled or executed with
966 the C</p> modifier.  In Perl v5.20, the C</p> modifier does nothing, so
967 C<${^PREMATCH}> does the same thing as C<$PREMATCH>.
968
969 This variable was added in Perl v5.10.0.
970
971 This variable is read-only and dynamically-scoped.
972
973 =item $POSTMATCH
974
975 =item $'
976 X<$'> X<$POSTMATCH> X<${^POSTMATCH}> X<@->
977
978 The string following whatever was matched by the last successful
979 pattern match (not counting any matches hidden within a BLOCK or C<eval()>
980 enclosed by the current BLOCK).  Example:
981
982     local $_ = 'abcdefghi';
983     /def/;
984     print "$`:$&:$'\n";         # prints abc:def:ghi
985
986 See L</Performance issues> above for the serious performance implications
987 of using this variable (even once) in your code.
988
989 This variable is read-only and dynamically-scoped.
990
991 Mnemonic: C<'> often follows a quoted string.
992
993 =item ${^POSTMATCH}
994 X<${^POSTMATCH}> X<$'> X<$POSTMATCH>
995
996 This is similar to C<$'> (C<$POSTMATCH>) except that it does not incur the
997 performance penalty associated with that variable.
998
999 See L</Performance issues> above.
1000
1001 In Perl v5.18 and earlier, it is only guaranteed
1002 to return a defined value when the pattern was compiled or executed with
1003 the C</p> modifier.  In Perl v5.20, the C</p> modifier does nothing, so
1004 C<${^POSTMATCH}> does the same thing as C<$POSTMATCH>.
1005
1006 This variable was added in Perl v5.10.0.
1007
1008 This variable is read-only and dynamically-scoped.
1009
1010 =item $LAST_PAREN_MATCH
1011
1012 =item $+
1013 X<$+> X<$LAST_PAREN_MATCH>
1014
1015 The text matched by the last bracket of the last successful search pattern.
1016 This is useful if you don't know which one of a set of alternative patterns
1017 matched.  For example:
1018
1019     /Version: (.*)|Revision: (.*)/ && ($rev = $+);
1020
1021 This variable is read-only and dynamically-scoped.
1022
1023 Mnemonic: be positive and forward looking.
1024
1025 =item $LAST_SUBMATCH_RESULT
1026
1027 =item $^N
1028 X<$^N> X<$LAST_SUBMATCH_RESULT>
1029
1030 The text matched by the used group most-recently closed (i.e. the group
1031 with the rightmost closing parenthesis) of the last successful search
1032 pattern.
1033
1034 This is primarily used inside C<(?{...})> blocks for examining text
1035 recently matched.  For example, to effectively capture text to a variable
1036 (in addition to C<$1>, C<$2>, etc.), replace C<(...)> with
1037
1038     (?:(...)(?{ $var = $^N }))
1039
1040 By setting and then using C<$var> in this way relieves you from having to
1041 worry about exactly which numbered set of parentheses they are.
1042
1043 This variable was added in Perl v5.8.0.
1044
1045 Mnemonic: the (possibly) Nested parenthesis that most recently closed.
1046
1047 =item @LAST_MATCH_END
1048
1049 =item @+
1050 X<@+> X<@LAST_MATCH_END>
1051
1052 This array holds the offsets of the ends of the last successful
1053 submatches in the currently active dynamic scope.  C<$+[0]> is
1054 the offset into the string of the end of the entire match.  This
1055 is the same value as what the C<pos> function returns when called
1056 on the variable that was matched against.  The I<n>th element
1057 of this array holds the offset of the I<n>th submatch, so
1058 C<$+[1]> is the offset past where C<$1> ends, C<$+[2]> the offset
1059 past where C<$2> ends, and so on.  You can use C<$#+> to determine
1060 how many subgroups were in the last successful match.  See the
1061 examples given for the C<@-> variable.
1062
1063 This variable was added in Perl v5.6.0.
1064
1065 =item %LAST_PAREN_MATCH
1066
1067 =item %+
1068 X<%+> X<%LAST_PAREN_MATCH>
1069
1070 Similar to C<@+>, the C<%+> hash allows access to the named capture
1071 buffers, should they exist, in the last successful match in the
1072 currently active dynamic scope.
1073
1074 For example, C<$+{foo}> is equivalent to C<$1> after the following match:
1075
1076     'foo' =~ /(?<foo>foo)/;
1077
1078 The keys of the C<%+> hash list only the names of buffers that have
1079 captured (and that are thus associated to defined values).
1080
1081 The underlying behaviour of C<%+> is provided by the
1082 L<Tie::Hash::NamedCapture> module.
1083
1084 B<Note:> C<%-> and C<%+> are tied views into a common internal hash
1085 associated with the last successful regular expression.  Therefore mixing
1086 iterative access to them via C<each> may have unpredictable results.
1087 Likewise, if the last successful match changes, then the results may be
1088 surprising.
1089
1090 This variable was added in Perl v5.10.0.
1091
1092 This variable is read-only and dynamically-scoped.
1093
1094 =item @LAST_MATCH_START
1095
1096 =item @-
1097 X<@-> X<@LAST_MATCH_START>
1098
1099 C<$-[0]> is the offset of the start of the last successful match.
1100 C<$-[>I<n>C<]> is the offset of the start of the substring matched by
1101 I<n>-th subpattern, or undef if the subpattern did not match.
1102
1103 Thus, after a match against C<$_>, C<$&> coincides with C<substr $_, $-[0],
1104 $+[0] - $-[0]>.  Similarly, $I<n> coincides with C<substr $_, $-[n],
1105 $+[n] - $-[n]> if C<$-[n]> is defined, and $+ coincides with
1106 C<substr $_, $-[$#-], $+[$#-] - $-[$#-]>.  One can use C<$#-> to find the
1107 last matched subgroup in the last successful match.  Contrast with
1108 C<$#+>, the number of subgroups in the regular expression.  Compare
1109 with C<@+>.
1110
1111 This array holds the offsets of the beginnings of the last
1112 successful submatches in the currently active dynamic scope.
1113 C<$-[0]> is the offset into the string of the beginning of the
1114 entire match.  The I<n>th element of this array holds the offset
1115 of the I<n>th submatch, so C<$-[1]> is the offset where C<$1>
1116 begins, C<$-[2]> the offset where C<$2> begins, and so on.
1117
1118 After a match against some variable C<$var>:
1119
1120 =over 5
1121
1122 =item C<$`> is the same as C<substr($var, 0, $-[0])>
1123
1124 =item C<$&> is the same as C<substr($var, $-[0], $+[0] - $-[0])>
1125
1126 =item C<$'> is the same as C<substr($var, $+[0])>
1127
1128 =item C<$1> is the same as C<substr($var, $-[1], $+[1] - $-[1])>
1129
1130 =item C<$2> is the same as C<substr($var, $-[2], $+[2] - $-[2])>
1131
1132 =item C<$3> is the same as C<substr($var, $-[3], $+[3] - $-[3])>
1133
1134 =back
1135
1136 This variable was added in Perl v5.6.0.
1137
1138 =item %-
1139 X<%->
1140
1141 Similar to C<%+>, this variable allows access to the named capture groups
1142 in the last successful match in the currently active dynamic scope.  To
1143 each capture group name found in the regular expression, it associates a
1144 reference to an array containing the list of values captured by all
1145 buffers with that name (should there be several of them), in the order
1146 where they appear.
1147
1148 Here's an example:
1149
1150     if ('1234' =~ /(?<A>1)(?<B>2)(?<A>3)(?<B>4)/) {
1151         foreach my $bufname (sort keys %-) {
1152             my $ary = $-{$bufname};
1153             foreach my $idx (0..$#$ary) {
1154                 print "\$-{$bufname}[$idx] : ",
1155                       (defined($ary->[$idx])
1156                           ? "'$ary->[$idx]'"
1157                           : "undef"),
1158                       "\n";
1159             }
1160         }
1161     }
1162
1163 would print out:
1164
1165     $-{A}[0] : '1'
1166     $-{A}[1] : '3'
1167     $-{B}[0] : '2'
1168     $-{B}[1] : '4'
1169
1170 The keys of the C<%-> hash correspond to all buffer names found in
1171 the regular expression.
1172
1173 The behaviour of C<%-> is implemented via the
1174 L<Tie::Hash::NamedCapture> module.
1175
1176 B<Note:> C<%-> and C<%+> are tied views into a common internal hash
1177 associated with the last successful regular expression.  Therefore mixing
1178 iterative access to them via C<each> may have unpredictable results.
1179 Likewise, if the last successful match changes, then the results may be
1180 surprising.
1181
1182 This variable was added in Perl v5.10.0.
1183
1184 This variable is read-only and dynamically-scoped.
1185
1186 =item $LAST_REGEXP_CODE_RESULT
1187
1188 =item $^R
1189 X<$^R> X<$LAST_REGEXP_CODE_RESULT>
1190
1191 The result of evaluation of the last successful C<(?{ code })>
1192 regular expression assertion (see L<perlre>).  May be written to.
1193
1194 This variable was added in Perl 5.005.
1195
1196 =item ${^RE_DEBUG_FLAGS}
1197 X<${^RE_DEBUG_FLAGS}>
1198
1199 The current value of the regex debugging flags.  Set to 0 for no debug output
1200 even when the C<re 'debug'> module is loaded.  See L<re> for details.
1201
1202 This variable was added in Perl v5.10.0.
1203
1204 =item ${^RE_TRIE_MAXBUF}
1205 X<${^RE_TRIE_MAXBUF}>
1206
1207 Controls how certain regex optimisations are applied and how much memory they
1208 utilize.  This value by default is 65536 which corresponds to a 512kB
1209 temporary cache.  Set this to a higher value to trade
1210 memory for speed when matching large alternations.  Set
1211 it to a lower value if you want the optimisations to
1212 be as conservative of memory as possible but still occur, and set it to a
1213 negative value to prevent the optimisation and conserve the most memory.
1214 Under normal situations this variable should be of no interest to you.
1215
1216 This variable was added in Perl v5.10.0.
1217
1218 =back
1219
1220 =head2 Variables related to filehandles
1221
1222 Variables that depend on the currently selected filehandle may be set
1223 by calling an appropriate object method on the C<IO::Handle> object,
1224 although this is less efficient than using the regular built-in
1225 variables.  (Summary lines below for this contain the word HANDLE.)
1226 First you must say
1227
1228     use IO::Handle;
1229
1230 after which you may use either
1231
1232     method HANDLE EXPR
1233
1234 or more safely,
1235
1236     HANDLE->method(EXPR)
1237
1238 Each method returns the old value of the C<IO::Handle> attribute.  The
1239 methods each take an optional EXPR, which, if supplied, specifies the
1240 new value for the C<IO::Handle> attribute in question.  If not
1241 supplied, most methods do nothing to the current value--except for
1242 C<autoflush()>, which will assume a 1 for you, just to be different.
1243
1244 Because loading in the C<IO::Handle> class is an expensive operation,
1245 you should learn how to use the regular built-in variables.
1246
1247 A few of these variables are considered "read-only".  This means that
1248 if you try to assign to this variable, either directly or indirectly
1249 through a reference, you'll raise a run-time exception.
1250
1251 You should be very careful when modifying the default values of most
1252 special variables described in this document.  In most cases you want
1253 to localize these variables before changing them, since if you don't,
1254 the change may affect other modules which rely on the default values
1255 of the special variables that you have changed.  This is one of the
1256 correct ways to read the whole file at once:
1257
1258     open my $fh, "<", "foo" or die $!;
1259     local $/; # enable localized slurp mode
1260     my $content = <$fh>;
1261     close $fh;
1262
1263 But the following code is quite bad:
1264
1265     open my $fh, "<", "foo" or die $!;
1266     undef $/; # enable slurp mode
1267     my $content = <$fh>;
1268     close $fh;
1269
1270 since some other module, may want to read data from some file in the
1271 default "line mode", so if the code we have just presented has been
1272 executed, the global value of C<$/> is now changed for any other code
1273 running inside the same Perl interpreter.
1274
1275 Usually when a variable is localized you want to make sure that this
1276 change affects the shortest scope possible.  So unless you are already
1277 inside some short C<{}> block, you should create one yourself.  For
1278 example:
1279
1280     my $content = '';
1281     open my $fh, "<", "foo" or die $!;
1282     {
1283         local $/;
1284         $content = <$fh>;
1285     }
1286     close $fh;
1287
1288 Here is an example of how your own code can go broken:
1289
1290     for ( 1..3 ){
1291         $\ = "\r\n";
1292         nasty_break();
1293         print "$_";
1294     }
1295
1296     sub nasty_break {
1297         $\ = "\f";
1298         # do something with $_
1299     }
1300
1301 You probably expect this code to print the equivalent of
1302
1303     "1\r\n2\r\n3\r\n"
1304
1305 but instead you get:
1306
1307     "1\f2\f3\f"
1308
1309 Why? Because C<nasty_break()> modifies C<$\> without localizing it
1310 first.  The value you set in  C<nasty_break()> is still there when you
1311 return.  The fix is to add C<local()> so the value doesn't leak out of
1312 C<nasty_break()>:
1313
1314     local $\ = "\f";
1315
1316 It's easy to notice the problem in such a short example, but in more
1317 complicated code you are looking for trouble if you don't localize
1318 changes to the special variables.
1319
1320 =over 8
1321
1322 =item $ARGV
1323 X<$ARGV>
1324
1325 Contains the name of the current file when reading from C<< <> >>.
1326
1327 =item @ARGV
1328 X<@ARGV>
1329
1330 The array C<@ARGV> contains the command-line arguments intended for
1331 the script.  C<$#ARGV> is generally the number of arguments minus
1332 one, because C<$ARGV[0]> is the first argument, I<not> the program's
1333 command name itself.  See L</$0> for the command name.
1334
1335 =item ARGV
1336 X<ARGV>
1337
1338 The special filehandle that iterates over command-line filenames in
1339 C<@ARGV>.  Usually written as the null filehandle in the angle operator
1340 C<< <> >>.  Note that currently C<ARGV> only has its magical effect
1341 within the C<< <> >> operator; elsewhere it is just a plain filehandle
1342 corresponding to the last file opened by C<< <> >>.  In particular,
1343 passing C<\*ARGV> as a parameter to a function that expects a filehandle
1344 may not cause your function to automatically read the contents of all the
1345 files in C<@ARGV>.
1346
1347 =item ARGVOUT
1348 X<ARGVOUT>
1349
1350 The special filehandle that points to the currently open output file
1351 when doing edit-in-place processing with B<-i>.  Useful when you have
1352 to do a lot of inserting and don't want to keep modifying C<$_>.  See
1353 L<perlrun> for the B<-i> switch.
1354
1355 =item IO::Handle->output_field_separator( EXPR )
1356
1357 =item $OUTPUT_FIELD_SEPARATOR
1358
1359 =item $OFS
1360
1361 =item $,
1362 X<$,> X<$OFS> X<$OUTPUT_FIELD_SEPARATOR>
1363
1364 The output field separator for the print operator.  If defined, this
1365 value is printed between each of print's arguments.  Default is C<undef>.
1366
1367 You cannot call C<output_field_separator()> on a handle, only as a
1368 static method.  See L<IO::Handle|IO::Handle>.
1369
1370 Mnemonic: what is printed when there is a "," in your print statement.
1371
1372 =item HANDLE->input_line_number( EXPR )
1373
1374 =item $INPUT_LINE_NUMBER
1375
1376 =item $NR
1377
1378 =item $.
1379 X<$.> X<$NR> X<$INPUT_LINE_NUMBER> X<line number>
1380
1381 Current line number for the last filehandle accessed.
1382
1383 Each filehandle in Perl counts the number of lines that have been read
1384 from it.  (Depending on the value of C<$/>, Perl's idea of what
1385 constitutes a line may not match yours.)  When a line is read from a
1386 filehandle (via C<readline()> or C<< <> >>), or when C<tell()> or
1387 C<seek()> is called on it, C<$.> becomes an alias to the line counter
1388 for that filehandle.
1389
1390 You can adjust the counter by assigning to C<$.>, but this will not
1391 actually move the seek pointer.  I<Localizing C<$.> will not localize
1392 the filehandle's line count>.  Instead, it will localize perl's notion
1393 of which filehandle C<$.> is currently aliased to.
1394
1395 C<$.> is reset when the filehandle is closed, but B<not> when an open
1396 filehandle is reopened without an intervening C<close()>.  For more
1397 details, see L<perlop/"IE<sol>O Operators">.  Because C<< <> >> never does
1398 an explicit close, line numbers increase across C<ARGV> files (but see
1399 examples in L<perlfunc/eof>).
1400
1401 You can also use C<< HANDLE->input_line_number(EXPR) >> to access the
1402 line counter for a given filehandle without having to worry about
1403 which handle you last accessed.
1404
1405 Mnemonic: many programs use "." to mean the current line number.
1406
1407 =item IO::Handle->input_record_separator( EXPR )
1408
1409 =item $INPUT_RECORD_SEPARATOR
1410
1411 =item $RS
1412
1413 =item $/
1414 X<$/> X<$RS> X<$INPUT_RECORD_SEPARATOR>
1415
1416 The input record separator, newline by default.  This influences Perl's
1417 idea of what a "line" is.  Works like B<awk>'s RS variable, including
1418 treating empty lines as a terminator if set to the null string (an
1419 empty line cannot contain any spaces or tabs).  You may set it to a
1420 multi-character string to match a multi-character terminator, or to
1421 C<undef> to read through the end of file.  Setting it to C<"\n\n">
1422 means something slightly different than setting to C<"">, if the file
1423 contains consecutive empty lines.  Setting to C<""> will treat two or
1424 more consecutive empty lines as a single empty line.  Setting to
1425 C<"\n\n"> will blindly assume that the next input character belongs to
1426 the next paragraph, even if it's a newline.
1427
1428     local $/;           # enable "slurp" mode
1429     local $_ = <FH>;    # whole file now here
1430     s/\n[ \t]+/ /g;
1431
1432 Remember: the value of C<$/> is a string, not a regex.  B<awk> has to
1433 be better for something. :-)
1434
1435 Setting C<$/> to a reference to an integer, scalar containing an
1436 integer, or scalar that's convertible to an integer will attempt to
1437 read records instead of lines, with the maximum record size being the
1438 referenced integer number of characters.  So this:
1439
1440     local $/ = \32768; # or \"32768", or \$var_containing_32768
1441     open my $fh, "<", $myfile or die $!;
1442     local $_ = <$fh>;
1443
1444 will read a record of no more than 32768 characters from $fh.  If you're
1445 not reading from a record-oriented file (or your OS doesn't have
1446 record-oriented files), then you'll likely get a full chunk of data
1447 with every read.  If a record is larger than the record size you've
1448 set, you'll get the record back in pieces.  Trying to set the record
1449 size to zero or less is deprecated and will cause $/ to have the value
1450 of "undef", which will cause reading in the (rest of the) whole file.
1451
1452 As of 5.19.9 setting C<$/> to any other form of reference will throw a
1453 fatal exception. This is in preparation for supporting new ways to set
1454 C<$/> in the future.
1455
1456 On VMS only, record reads bypass PerlIO layers and any associated
1457 buffering, so you must not mix record and non-record reads on the
1458 same filehandle.  Record mode mixes with line mode only when the
1459 same buffering layer is in use for both modes.
1460
1461 You cannot call C<input_record_separator()> on a handle, only as a
1462 static method.  See L<IO::Handle|IO::Handle>.
1463
1464 See also L<perlport/"Newlines">.  Also see L</$.>.
1465
1466 Mnemonic: / delimits line boundaries when quoting poetry.
1467
1468 =item IO::Handle->output_record_separator( EXPR )
1469
1470 =item $OUTPUT_RECORD_SEPARATOR
1471
1472 =item $ORS
1473
1474 =item $\
1475 X<$\> X<$ORS> X<$OUTPUT_RECORD_SEPARATOR>
1476
1477 The output record separator for the print operator.  If defined, this
1478 value is printed after the last of print's arguments.  Default is C<undef>.
1479
1480 You cannot call C<output_record_separator()> on a handle, only as a
1481 static method.  See L<IO::Handle|IO::Handle>.
1482
1483 Mnemonic: you set C<$\> instead of adding "\n" at the end of the print.
1484 Also, it's just like C<$/>, but it's what you get "back" from Perl.
1485
1486 =item HANDLE->autoflush( EXPR )
1487
1488 =item $OUTPUT_AUTOFLUSH
1489
1490 =item $|
1491 X<$|> X<autoflush> X<flush> X<$OUTPUT_AUTOFLUSH>
1492
1493 If set to nonzero, forces a flush right away and after every write or
1494 print on the currently selected output channel.  Default is 0
1495 (regardless of whether the channel is really buffered by the system or
1496 not; C<$|> tells you only whether you've asked Perl explicitly to
1497 flush after each write).  STDOUT will typically be line buffered if
1498 output is to the terminal and block buffered otherwise.  Setting this
1499 variable is useful primarily when you are outputting to a pipe or
1500 socket, such as when you are running a Perl program under B<rsh> and
1501 want to see the output as it's happening.  This has no effect on input
1502 buffering.  See L<perlfunc/getc> for that.  See L<perlfunc/select> on
1503 how to select the output channel.  See also L<IO::Handle>.
1504
1505 Mnemonic: when you want your pipes to be piping hot.
1506
1507 =item ${^LAST_FH}
1508 X<${^LAST_FH}>
1509
1510 This read-only variable contains a reference to the last-read filehandle.
1511 This is set by C<< <HANDLE> >>, C<readline>, C<tell>, C<eof> and C<seek>.
1512 This is the same handle that C<$.> and C<tell> and C<eof> without arguments
1513 use.  It is also the handle used when Perl appends ", <STDIN> line 1" to
1514 an error or warning message.
1515
1516 This variable was added in Perl v5.18.0.
1517
1518 =back
1519
1520 =head3 Variables related to formats
1521
1522 The special variables for formats are a subset of those for
1523 filehandles.  See L<perlform> for more information about Perl's
1524 formats.
1525
1526 =over 8
1527
1528 =item $ACCUMULATOR
1529
1530 =item $^A
1531 X<$^A> X<$ACCUMULATOR>
1532
1533 The current value of the C<write()> accumulator for C<format()> lines.
1534 A format contains C<formline()> calls that put their result into
1535 C<$^A>.  After calling its format, C<write()> prints out the contents
1536 of C<$^A> and empties.  So you never really see the contents of C<$^A>
1537 unless you call C<formline()> yourself and then look at it.  See
1538 L<perlform> and L<perlfunc/"formline PICTURE,LIST">.
1539
1540 =item IO::Handle->format_formfeed(EXPR)
1541
1542 =item $FORMAT_FORMFEED
1543
1544 =item $^L
1545 X<$^L> X<$FORMAT_FORMFEED>
1546
1547 What formats output as a form feed.  The default is C<\f>.
1548
1549 You cannot call C<format_formfeed()> on a handle, only as a static
1550 method.  See L<IO::Handle|IO::Handle>.
1551
1552 =item HANDLE->format_page_number(EXPR)
1553
1554 =item $FORMAT_PAGE_NUMBER
1555
1556 =item $%
1557 X<$%> X<$FORMAT_PAGE_NUMBER>
1558
1559 The current page number of the currently selected output channel.
1560
1561 Mnemonic: C<%> is page number in B<nroff>.
1562
1563 =item HANDLE->format_lines_left(EXPR)
1564
1565 =item $FORMAT_LINES_LEFT
1566
1567 =item $-
1568 X<$-> X<$FORMAT_LINES_LEFT>
1569
1570 The number of lines left on the page of the currently selected output
1571 channel.
1572
1573 Mnemonic: lines_on_page - lines_printed.
1574
1575 =item IO::Handle->format_line_break_characters EXPR
1576
1577 =item $FORMAT_LINE_BREAK_CHARACTERS
1578
1579 =item $:
1580 X<$:> X<FORMAT_LINE_BREAK_CHARACTERS>
1581
1582 The current set of characters after which a string may be broken to
1583 fill continuation fields (starting with C<^>) in a format.  The default is
1584 S<" \n-">, to break on a space, newline, or a hyphen.
1585
1586 You cannot call C<format_line_break_characters()> on a handle, only as
1587 a static method.  See L<IO::Handle|IO::Handle>.
1588
1589 Mnemonic: a "colon" in poetry is a part of a line.
1590
1591 =item HANDLE->format_lines_per_page(EXPR)
1592
1593 =item $FORMAT_LINES_PER_PAGE
1594
1595 =item $=
1596 X<$=> X<$FORMAT_LINES_PER_PAGE>
1597
1598 The current page length (printable lines) of the currently selected
1599 output channel.  The default is 60.
1600
1601 Mnemonic: = has horizontal lines.
1602
1603 =item HANDLE->format_top_name(EXPR)
1604
1605 =item $FORMAT_TOP_NAME
1606
1607 =item $^
1608 X<$^> X<$FORMAT_TOP_NAME>
1609
1610 The name of the current top-of-page format for the currently selected
1611 output channel.  The default is the name of the filehandle with C<_TOP>
1612 appended.  For example, the default format top name for the C<STDOUT>
1613 filehandle is C<STDOUT_TOP>.
1614
1615 Mnemonic: points to top of page.
1616
1617 =item HANDLE->format_name(EXPR)
1618
1619 =item $FORMAT_NAME
1620
1621 =item $~
1622 X<$~> X<$FORMAT_NAME>
1623
1624 The name of the current report format for the currently selected
1625 output channel.  The default format name is the same as the filehandle
1626 name.  For example, the default format name for the C<STDOUT>
1627 filehandle is just C<STDOUT>.
1628
1629 Mnemonic: brother to C<$^>.
1630
1631 =back
1632
1633 =head2 Error Variables
1634 X<error> X<exception>
1635
1636 The variables C<$@>, C<$!>, C<$^E>, and C<$?> contain information
1637 about different types of error conditions that may appear during
1638 execution of a Perl program.  The variables are shown ordered by
1639 the "distance" between the subsystem which reported the error and
1640 the Perl process.  They correspond to errors detected by the Perl
1641 interpreter, C library, operating system, or an external program,
1642 respectively.
1643
1644 To illustrate the differences between these variables, consider the
1645 following Perl expression, which uses a single-quoted string.  After
1646 execution of this statement, perl may have set all four special error
1647 variables:
1648
1649     eval q{
1650         open my $pipe, "/cdrom/install |" or die $!;
1651         my @res = <$pipe>;
1652         close $pipe or die "bad pipe: $?, $!";
1653     };
1654
1655 When perl executes the C<eval()> expression, it translates the
1656 C<open()>, C<< <PIPE> >>, and C<close> calls in the C run-time library
1657 and thence to the operating system kernel.  perl sets C<$!> to
1658 the C library's C<errno> if one of these calls fails.
1659
1660 C<$@> is set if the string to be C<eval>-ed did not compile (this may
1661 happen if C<open> or C<close> were imported with bad prototypes), or
1662 if Perl code executed during evaluation C<die()>d.  In these cases the
1663 value of C<$@> is the compile error, or the argument to C<die> (which
1664 will interpolate C<$!> and C<$?>).  (See also L<Fatal>, though.)
1665
1666 Under a few operating systems, C<$^E> may contain a more verbose error
1667 indicator, such as in this case, "CDROM tray not closed."  Systems that
1668 do not support extended error messages leave C<$^E> the same as C<$!>.
1669
1670 Finally, C<$?> may be set to non-0 value if the external program
1671 F</cdrom/install> fails.  The upper eight bits reflect specific error
1672 conditions encountered by the program (the program's C<exit()> value).
1673 The lower eight bits reflect mode of failure, like signal death and
1674 core dump information.  See L<wait(2)> for details.  In contrast to
1675 C<$!> and C<$^E>, which are set only if error condition is detected,
1676 the variable C<$?> is set on each C<wait> or pipe C<close>,
1677 overwriting the old value.  This is more like C<$@>, which on every
1678 C<eval()> is always set on failure and cleared on success.
1679
1680 For more details, see the individual descriptions at C<$@>, C<$!>,
1681 C<$^E>, and C<$?>.
1682
1683 =over 8
1684
1685 =item ${^CHILD_ERROR_NATIVE}
1686 X<$^CHILD_ERROR_NATIVE>
1687
1688 The native status returned by the last pipe close, backtick (C<``>)
1689 command, successful call to C<wait()> or C<waitpid()>, or from the
1690 C<system()> operator.  On POSIX-like systems this value can be decoded
1691 with the WIFEXITED, WEXITSTATUS, WIFSIGNALED, WTERMSIG, WIFSTOPPED,
1692 WSTOPSIG and WIFCONTINUED functions provided by the L<POSIX> module.
1693
1694 Under VMS this reflects the actual VMS exit status; i.e. it is the
1695 same as C<$?> when the pragma C<use vmsish 'status'> is in effect.
1696
1697 This variable was added in Perl v5.10.0.
1698
1699 =item $EXTENDED_OS_ERROR
1700
1701 =item $^E
1702 X<$^E> X<$EXTENDED_OS_ERROR>
1703
1704 Error information specific to the current operating system.  At the
1705 moment, this differs from C<$!> under only VMS, OS/2, and Win32 (and
1706 for MacPerl).  On all other platforms, C<$^E> is always just the same
1707 as C<$!>.
1708
1709 Under VMS, C<$^E> provides the VMS status value from the last system
1710 error.  This is more specific information about the last system error
1711 than that provided by C<$!>.  This is particularly important when C<$!>
1712 is set to B<EVMSERR>.
1713
1714 Under OS/2, C<$^E> is set to the error code of the last call to OS/2
1715 API either via CRT, or directly from perl.
1716
1717 Under Win32, C<$^E> always returns the last error information reported
1718 by the Win32 call C<GetLastError()> which describes the last error
1719 from within the Win32 API.  Most Win32-specific code will report errors
1720 via C<$^E>.  ANSI C and Unix-like calls set C<errno> and so most
1721 portable Perl code will report errors via C<$!>.
1722
1723 Caveats mentioned in the description of C<$!> generally apply to
1724 C<$^E>, also.
1725
1726 This variable was added in Perl 5.003.
1727
1728 Mnemonic: Extra error explanation.
1729
1730 =item $EXCEPTIONS_BEING_CAUGHT
1731
1732 =item $^S
1733 X<$^S> X<$EXCEPTIONS_BEING_CAUGHT>
1734
1735 Current state of the interpreter.
1736
1737         $^S         State
1738         ---------   -------------------------------------
1739         undef       Parsing module, eval, or main program
1740         true (1)    Executing an eval
1741         false (0)   Otherwise
1742
1743 The first state may happen in C<$SIG{__DIE__}> and C<$SIG{__WARN__}>
1744 handlers.
1745
1746 The English name $EXCEPTIONS_BEING_CAUGHT is slightly misleading, because
1747 the C<undef> value does not indicate whether exceptions are being caught,
1748 since compilation of the main program does not catch exceptions.
1749
1750 This variable was added in Perl 5.004.
1751
1752 =item $WARNING
1753
1754 =item $^W
1755 X<$^W> X<$WARNING>
1756
1757 The current value of the warning switch, initially true if B<-w> was
1758 used, false otherwise, but directly modifiable.
1759
1760 See also L<warnings>.
1761
1762 Mnemonic: related to the B<-w> switch.
1763
1764 =item ${^WARNING_BITS}
1765 X<${^WARNING_BITS}>
1766
1767 The current set of warning checks enabled by the C<use warnings> pragma.
1768 It has the same scoping as the C<$^H> and C<%^H> variables.  The exact
1769 values are considered internal to the L<warnings> pragma and may change
1770 between versions of Perl.
1771
1772 This variable was added in Perl v5.6.0.
1773
1774 =item $OS_ERROR
1775
1776 =item $ERRNO
1777
1778 =item $!
1779 X<$!> X<$ERRNO> X<$OS_ERROR>
1780
1781 When referenced, C<$!> retrieves the current value
1782 of the C C<errno> integer variable.
1783 If C<$!> is assigned a numerical value, that value is stored in C<errno>.
1784 When referenced as a string, C<$!> yields the system error string
1785 corresponding to C<errno>.
1786
1787 Many system or library calls set C<errno> if they fail,
1788 to indicate the cause of failure.  They usually do B<not>
1789 set C<errno> to zero if they succeed.  This means C<errno>,
1790 hence C<$!>, is meaningful only I<immediately> after a B<failure>:
1791
1792     if (open my $fh, "<", $filename) {
1793                 # Here $! is meaningless.
1794                 ...
1795     }
1796     else {
1797                 # ONLY here is $! meaningful.
1798                 ...
1799                 # Already here $! might be meaningless.
1800     }
1801     # Since here we might have either success or failure,
1802     # $! is meaningless.
1803
1804 Here, I<meaningless> means that C<$!> may be unrelated to the outcome
1805 of the C<open()> operator.  Assignment to C<$!> is similarly ephemeral.
1806 It can be used immediately before invoking the C<die()> operator,
1807 to set the exit value, or to inspect the system error string
1808 corresponding to error I<n>, or to restore C<$!> to a meaningful state.
1809
1810 Mnemonic: What just went bang?
1811
1812 =item %OS_ERROR
1813
1814 =item %ERRNO
1815
1816 =item %!
1817 X<%!> X<%OS_ERROR> X<%ERRNO>
1818
1819 Each element of C<%!> has a true value only if C<$!> is set to that
1820 value.  For example, C<$!{ENOENT}> is true if and only if the current
1821 value of C<$!> is C<ENOENT>; that is, if the most recent error was "No
1822 such file or directory" (or its moral equivalent: not all operating
1823 systems give that exact error, and certainly not all languages).  The
1824 specific true value is not guaranteed, but in the past has generally
1825 been the numeric value of C<$!>.  To check if a particular key is
1826 meaningful on your system, use C<exists $!{the_key}>; for a list of legal
1827 keys, use C<keys %!>.  See L<Errno> for more information, and also see
1828 L</$!>.
1829
1830 This variable was added in Perl 5.005.
1831
1832 =item $CHILD_ERROR
1833
1834 =item $?
1835 X<$?> X<$CHILD_ERROR>
1836
1837 The status returned by the last pipe close, backtick (C<``>) command,
1838 successful call to C<wait()> or C<waitpid()>, or from the C<system()>
1839 operator.  This is just the 16-bit status word returned by the
1840 traditional Unix C<wait()> system call (or else is made up to look
1841 like it).  Thus, the exit value of the subprocess is really (C<<< $? >>
1842 8 >>>), and C<$? & 127> gives which signal, if any, the process died
1843 from, and C<$? & 128> reports whether there was a core dump.
1844
1845 Additionally, if the C<h_errno> variable is supported in C, its value
1846 is returned via C<$?> if any C<gethost*()> function fails.
1847
1848 If you have installed a signal handler for C<SIGCHLD>, the
1849 value of C<$?> will usually be wrong outside that handler.
1850
1851 Inside an C<END> subroutine C<$?> contains the value that is going to be
1852 given to C<exit()>.  You can modify C<$?> in an C<END> subroutine to
1853 change the exit status of your program.  For example:
1854
1855     END {
1856         $? = 1 if $? == 255;  # die would make it 255
1857     }
1858
1859 Under VMS, the pragma C<use vmsish 'status'> makes C<$?> reflect the
1860 actual VMS exit status, instead of the default emulation of POSIX
1861 status; see L<perlvms/$?> for details.
1862
1863 Mnemonic: similar to B<sh> and B<ksh>.
1864
1865 =item $EVAL_ERROR
1866
1867 =item $@
1868 X<$@> X<$EVAL_ERROR>
1869
1870 The Perl syntax error message from the
1871 last C<eval()> operator.  If C<$@> is
1872 the null string, the last C<eval()> parsed and executed correctly
1873 (although the operations you invoked may have failed in the normal
1874 fashion).
1875
1876 Warning messages are not collected in this variable.  You can, however,
1877 set up a routine to process warnings by setting C<$SIG{__WARN__}> as
1878 described in L</%SIG>.
1879
1880 Mnemonic: Where was the syntax error "at"?
1881
1882 =back
1883
1884 =head2 Variables related to the interpreter state
1885
1886 These variables provide information about the current interpreter state.
1887
1888 =over 8
1889
1890 =item $COMPILING
1891
1892 =item $^C
1893 X<$^C> X<$COMPILING>
1894
1895 The current value of the flag associated with the B<-c> switch.
1896 Mainly of use with B<-MO=...> to allow code to alter its behavior
1897 when being compiled, such as for example to C<AUTOLOAD> at compile
1898 time rather than normal, deferred loading.  Setting
1899 C<$^C = 1> is similar to calling C<B::minus_c>.
1900
1901 This variable was added in Perl v5.6.0.
1902
1903 =item $DEBUGGING
1904
1905 =item $^D
1906 X<$^D> X<$DEBUGGING>
1907
1908 The current value of the debugging flags.  May be read or set.  Like its
1909 command-line equivalent, you can use numeric or symbolic values, eg
1910 C<$^D = 10> or C<$^D = "st">.
1911
1912 Mnemonic: value of B<-D> switch.
1913
1914 =item ${^ENCODING}
1915 X<${^ENCODING}>
1916
1917 DEPRECATED!!!
1918
1919 The I<object reference> to the C<Encode> object that is used to convert
1920 the source code to Unicode.  Thanks to this variable your Perl script
1921 does not have to be written in UTF-8.  Default is C<undef>.
1922
1923 Setting this variable to any other value than C<undef> is deprecated due
1924 to fundamental defects in its design and implementation.  It is planned
1925 to remove it from a future Perl version.  Its purpose was to allow your
1926 non-ASCII Perl scripts to not have to be written in UTF-8; this was
1927 useful before editors that worked on UTF-8 encoded text were common, but
1928 that was long ago.  It causes problems, such as affecting the operation
1929 of other modules that aren't expecting it, causing general mayhem.  Its
1930 use can lead to segfaults.
1931
1932 If you need something like this functionality, you should use the
1933 L<encoding> pragma, which is also deprecated, but has fewer nasty side
1934 effects.
1935
1936 If you are coming here because code of yours is being adversely affected
1937 by someone's use of this variable, you can usually work around it by
1938 doing this:
1939
1940  local ${^ENCODING};
1941
1942 near the beginning of the functions that are getting broken.  This
1943 undefines the variable during the scope of execution of the including
1944 function.
1945
1946 This variable was added in Perl 5.8.2.
1947
1948 =item ${^GLOBAL_PHASE}
1949 X<${^GLOBAL_PHASE}>
1950
1951 The current phase of the perl interpreter.
1952
1953 Possible values are:
1954
1955 =over 8
1956
1957 =item CONSTRUCT
1958
1959 The C<PerlInterpreter*> is being constructed via C<perl_construct>.  This
1960 value is mostly there for completeness and for use via the
1961 underlying C variable C<PL_phase>.  It's not really possible for Perl
1962 code to be executed unless construction of the interpreter is
1963 finished.
1964
1965 =item START
1966
1967 This is the global compile-time.  That includes, basically, every
1968 C<BEGIN> block executed directly or indirectly from during the
1969 compile-time of the top-level program.
1970
1971 This phase is not called "BEGIN" to avoid confusion with
1972 C<BEGIN>-blocks, as those are executed during compile-time of any
1973 compilation unit, not just the top-level program.  A new, localised
1974 compile-time entered at run-time, for example by constructs as
1975 C<eval "use SomeModule"> are not global interpreter phases, and
1976 therefore aren't reflected by C<${^GLOBAL_PHASE}>.
1977
1978 =item CHECK
1979
1980 Execution of any C<CHECK> blocks.
1981
1982 =item INIT
1983
1984 Similar to "CHECK", but for C<INIT>-blocks, not C<CHECK> blocks.
1985
1986 =item RUN
1987
1988 The main run-time, i.e. the execution of C<PL_main_root>.
1989
1990 =item END
1991
1992 Execution of any C<END> blocks.
1993
1994 =item DESTRUCT
1995
1996 Global destruction.
1997
1998 =back
1999
2000 Also note that there's no value for UNITCHECK-blocks.  That's because
2001 those are run for each compilation unit individually, and therefore is
2002 not a global interpreter phase.
2003
2004 Not every program has to go through each of the possible phases, but
2005 transition from one phase to another can only happen in the order
2006 described in the above list.
2007
2008 An example of all of the phases Perl code can see:
2009
2010     BEGIN { print "compile-time: ${^GLOBAL_PHASE}\n" }
2011
2012     INIT  { print "init-time: ${^GLOBAL_PHASE}\n" }
2013
2014     CHECK { print "check-time: ${^GLOBAL_PHASE}\n" }
2015
2016     {
2017         package Print::Phase;
2018
2019         sub new {
2020             my ($class, $time) = @_;
2021             return bless \$time, $class;
2022         }
2023
2024         sub DESTROY {
2025             my $self = shift;
2026             print "$$self: ${^GLOBAL_PHASE}\n";
2027         }
2028     }
2029
2030     print "run-time: ${^GLOBAL_PHASE}\n";
2031
2032     my $runtime = Print::Phase->new(
2033         "lexical variables are garbage collected before END"
2034     );
2035
2036     END   { print "end-time: ${^GLOBAL_PHASE}\n" }
2037
2038     our $destruct = Print::Phase->new(
2039         "package variables are garbage collected after END"
2040     );
2041
2042 This will print out
2043
2044     compile-time: START
2045     check-time: CHECK
2046     init-time: INIT
2047     run-time: RUN
2048     lexical variables are garbage collected before END: RUN
2049     end-time: END
2050     package variables are garbage collected after END: DESTRUCT
2051
2052 This variable was added in Perl 5.14.0.
2053
2054 =item $^H
2055 X<$^H>
2056
2057 WARNING: This variable is strictly for
2058 internal use only.  Its availability,
2059 behavior, and contents are subject to change without notice.
2060
2061 This variable contains compile-time hints for the Perl interpreter.  At the
2062 end of compilation of a BLOCK the value of this variable is restored to the
2063 value when the interpreter started to compile the BLOCK.
2064
2065 When perl begins to parse any block construct that provides a lexical scope
2066 (e.g., eval body, required file, subroutine body, loop body, or conditional
2067 block), the existing value of C<$^H> is saved, but its value is left unchanged.
2068 When the compilation of the block is completed, it regains the saved value.
2069 Between the points where its value is saved and restored, code that
2070 executes within BEGIN blocks is free to change the value of C<$^H>.
2071
2072 This behavior provides the semantic of lexical scoping, and is used in,
2073 for instance, the C<use strict> pragma.
2074
2075 The contents should be an integer; different bits of it are used for
2076 different pragmatic flags.  Here's an example:
2077
2078     sub add_100 { $^H |= 0x100 }
2079
2080     sub foo {
2081         BEGIN { add_100() }
2082         bar->baz($boon);
2083     }
2084
2085 Consider what happens during execution of the BEGIN block.  At this point
2086 the BEGIN block has already been compiled, but the body of C<foo()> is still
2087 being compiled.  The new value of C<$^H>
2088 will therefore be visible only while
2089 the body of C<foo()> is being compiled.
2090
2091 Substitution of C<BEGIN { add_100() }> block with:
2092
2093     BEGIN { require strict; strict->import('vars') }
2094
2095 demonstrates how C<use strict 'vars'> is implemented.  Here's a conditional
2096 version of the same lexical pragma:
2097
2098     BEGIN {
2099         require strict; strict->import('vars') if $condition
2100     }
2101
2102 This variable was added in Perl 5.003.
2103
2104 =item %^H
2105 X<%^H>
2106
2107 The C<%^H> hash provides the same scoping semantic as C<$^H>.  This makes
2108 it useful for implementation of lexically scoped pragmas.  See
2109 L<perlpragma>.   All the entries are stringified when accessed at
2110 runtime, so only simple values can be accommodated.  This means no
2111 pointers to objects, for example.
2112
2113 When putting items into C<%^H>, in order to avoid conflicting with other
2114 users of the hash there is a convention regarding which keys to use.
2115 A module should use only keys that begin with the module's name (the
2116 name of its main package) and a "/" character.  For example, a module
2117 C<Foo::Bar> should use keys such as C<Foo::Bar/baz>.
2118
2119 This variable was added in Perl v5.6.0.
2120
2121 =item ${^OPEN}
2122 X<${^OPEN}>
2123
2124 An internal variable used by PerlIO.  A string in two parts, separated
2125 by a C<\0> byte, the first part describes the input layers, the second
2126 part describes the output layers.
2127
2128 This variable was added in Perl v5.8.0.
2129
2130 =item $PERLDB
2131
2132 =item $^P
2133 X<$^P> X<$PERLDB>
2134
2135 The internal variable for debugging support.  The meanings of the
2136 various bits are subject to change, but currently indicate:
2137
2138 =over 6
2139
2140 =item 0x01
2141
2142 Debug subroutine enter/exit.
2143
2144 =item 0x02
2145
2146 Line-by-line debugging.  Causes C<DB::DB()> subroutine to be called for
2147 each statement executed.  Also causes saving source code lines (like
2148 0x400).
2149
2150 =item 0x04
2151
2152 Switch off optimizations.
2153
2154 =item 0x08
2155
2156 Preserve more data for future interactive inspections.
2157
2158 =item 0x10
2159
2160 Keep info about source lines on which a subroutine is defined.
2161
2162 =item 0x20
2163
2164 Start with single-step on.
2165
2166 =item 0x40
2167
2168 Use subroutine address instead of name when reporting.
2169
2170 =item 0x80
2171
2172 Report C<goto &subroutine> as well.
2173
2174 =item 0x100
2175
2176 Provide informative "file" names for evals based on the place they were compiled.
2177
2178 =item 0x200
2179
2180 Provide informative names to anonymous subroutines based on the place they
2181 were compiled.
2182
2183 =item 0x400
2184
2185 Save source code lines into C<@{"_<$filename"}>.
2186
2187 =item 0x800
2188
2189 When saving source, include evals that generate no subroutines.
2190
2191 =item 0x1000
2192
2193 When saving source, include source that did not compile.
2194
2195 =back
2196
2197 Some bits may be relevant at compile-time only, some at
2198 run-time only.  This is a new mechanism and the details may change.
2199 See also L<perldebguts>.
2200
2201 =item ${^TAINT}
2202 X<${^TAINT}>
2203
2204 Reflects if taint mode is on or off.  1 for on (the program was run with
2205 B<-T>), 0 for off, -1 when only taint warnings are enabled (i.e. with
2206 B<-t> or B<-TU>).
2207
2208 This variable is read-only.
2209
2210 This variable was added in Perl v5.8.0.
2211
2212 =item ${^UNICODE}
2213 X<${^UNICODE}>
2214
2215 Reflects certain Unicode settings of Perl.  See L<perlrun>
2216 documentation for the C<-C> switch for more information about
2217 the possible values.
2218
2219 This variable is set during Perl startup and is thereafter read-only.
2220
2221 This variable was added in Perl v5.8.2.
2222
2223 =item ${^UTF8CACHE}
2224 X<${^UTF8CACHE}>
2225
2226 This variable controls the state of the internal UTF-8 offset caching code.
2227 1 for on (the default), 0 for off, -1 to debug the caching code by checking
2228 all its results against linear scans, and panicking on any discrepancy.
2229
2230 This variable was added in Perl v5.8.9.  It is subject to change or
2231 removal without notice, but is currently used to avoid recalculating the
2232 boundaries of multi-byte UTF-8-encoded characters.
2233
2234 =item ${^UTF8LOCALE}
2235 X<${^UTF8LOCALE}>
2236
2237 This variable indicates whether a UTF-8 locale was detected by perl at
2238 startup.  This information is used by perl when it's in
2239 adjust-utf8ness-to-locale mode (as when run with the C<-CL> command-line
2240 switch); see L<perlrun> for more info on this.
2241
2242 This variable was added in Perl v5.8.8.
2243
2244 =back
2245
2246 =head2 Deprecated and removed variables
2247
2248 Deprecating a variable announces the intent of the perl maintainers to
2249 eventually remove the variable from the language.  It may still be
2250 available despite its status.  Using a deprecated variable triggers
2251 a warning.
2252
2253 Once a variable is removed, its use triggers an error telling you
2254 the variable is unsupported.
2255
2256 See L<perldiag> for details about error messages.
2257
2258 =over 8
2259
2260 =item $#
2261 X<$#>
2262
2263 C<$#> was a variable that could be used to format printed numbers.
2264 After a deprecation cycle, its magic was removed in Perl v5.10.0 and
2265 using it now triggers a warning: C<$# is no longer supported>.
2266
2267 This is not the sigil you use in front of an array name to get the
2268 last index, like C<$#array>.  That's still how you get the last index
2269 of an array in Perl.  The two have nothing to do with each other.
2270
2271 Deprecated in Perl 5.
2272
2273 Removed in Perl v5.10.0.
2274
2275 =item $*
2276 X<$*>
2277
2278 C<$*> was a variable that you could use to enable multiline matching.
2279 After a deprecation cycle, its magic was removed in Perl v5.10.0.
2280 Using it now triggers a warning: C<$* is no longer supported>.
2281 You should use the C</s> and C</m> regexp modifiers instead.
2282
2283 Deprecated in Perl 5.
2284
2285 Removed in Perl v5.10.0.
2286
2287 =item $[
2288 X<$[>
2289
2290 This variable stores the index of the first element in an array, and
2291 of the first character in a substring.  The default is 0, but you could
2292 theoretically set it to 1 to make Perl behave more like B<awk> (or Fortran)
2293 when subscripting and when evaluating the index() and substr() functions.
2294
2295 As of release 5 of Perl, assignment to C<$[> is treated as a compiler
2296 directive, and cannot influence the behavior of any other file.
2297 (That's why you can only assign compile-time constants to it.)
2298 Its use is highly discouraged.
2299
2300 Prior to Perl v5.10.0, assignment to C<$[> could be seen from outer lexical
2301 scopes in the same file, unlike other compile-time directives (such as
2302 L<strict>).  Using local() on it would bind its value strictly to a lexical
2303 block.  Now it is always lexically scoped.
2304
2305 As of Perl v5.16.0, it is implemented by the L<arybase> module.  See
2306 L<arybase> for more details on its behaviour.
2307
2308 Under C<use v5.16>, or C<no feature "array_base">, C<$[> no longer has any
2309 effect, and always contains 0.  Assigning 0 to it is permitted, but any
2310 other value will produce an error.
2311
2312 Mnemonic: [ begins subscripts.
2313
2314 Deprecated in Perl v5.12.0.
2315
2316 =back
2317
2318 =cut