(perl #131836) avoid a use-after-free after parsing a "sub" keyword
[perl.git] / t / test.pl
1 #
2 # t/test.pl - most of Test::More functionality without the fuss
3
4
5 # NOTE:
6 #
7 # Do not rely on features found only in more modern Perls here, as some CPAN
8 # distributions copy this file and must operate on older Perls. Similarly, keep
9 # things, simple as this may be run under fairly broken circumstances. For
10 # example, increment ($x++) has a certain amount of cleverness for things like
11 #
12 #   $x = 'zz';
13 #   $x++; # $x eq 'aaa';
14 #
15 # This stands more chance of breaking than just a simple
16 #
17 #   $x = $x + 1
18 #
19 # In this file, we use the latter "Baby Perl" approach, and increment
20 # will be worked over by t/op/inc.t
21
22 $Level = 1;
23 my $test = 1;
24 my $planned;
25 my $noplan;
26 my $Perl;       # Safer version of $^X set by which_perl()
27
28 # This defines ASCII/UTF-8 vs EBCDIC/UTF-EBCDIC
29 $::IS_ASCII  = ord 'A' ==  65;
30 $::IS_EBCDIC = ord 'A' == 193;
31
32 $TODO = 0;
33 $NO_ENDING = 0;
34 $Tests_Are_Passing = 1;
35
36 # Use this instead of print to avoid interference while testing globals.
37 sub _print {
38     local($\, $", $,) = (undef, ' ', '');
39     print STDOUT @_;
40 }
41
42 sub _print_stderr {
43     local($\, $", $,) = (undef, ' ', '');
44     print STDERR @_;
45 }
46
47 sub plan {
48     my $n;
49     if (@_ == 1) {
50         $n = shift;
51         if ($n eq 'no_plan') {
52           undef $n;
53           $noplan = 1;
54         }
55     } else {
56         my %plan = @_;
57         $plan{skip_all} and skip_all($plan{skip_all});
58         $n = $plan{tests};
59     }
60     _print "1..$n\n" unless $noplan;
61     $planned = $n;
62 }
63
64
65 # Set the plan at the end.  See Test::More::done_testing.
66 sub done_testing {
67     my $n = $test - 1;
68     $n = shift if @_;
69
70     _print "1..$n\n";
71     $planned = $n;
72 }
73
74
75 END {
76     my $ran = $test - 1;
77     if (!$NO_ENDING) {
78         if (defined $planned && $planned != $ran) {
79             _print_stderr
80                 "# Looks like you planned $planned tests but ran $ran.\n";
81         } elsif ($noplan) {
82             _print "1..$ran\n";
83         }
84     }
85 }
86
87 sub _diag {
88     return unless @_;
89     my @mess = _comment(@_);
90     $TODO ? _print(@mess) : _print_stderr(@mess);
91 }
92
93 # Use this instead of "print STDERR" when outputting failure diagnostic
94 # messages
95 sub diag {
96     _diag(@_);
97 }
98
99 # Use this instead of "print" when outputting informational messages
100 sub note {
101     return unless @_;
102     _print( _comment(@_) );
103 }
104
105 sub is_miniperl {
106     return !defined &DynaLoader::boot_DynaLoader;
107 }
108
109 sub set_up_inc {
110     # Don’t clobber @INC under miniperl
111     @INC = () unless is_miniperl;
112     unshift @INC, @_;
113 }
114
115 sub _comment {
116     return map { /^#/ ? "$_\n" : "# $_\n" }
117            map { split /\n/ } @_;
118 }
119
120 sub _have_dynamic_extension {
121     my $extension = shift;
122     unless (eval {require Config; 1}) {
123         warn "test.pl had problems loading Config: $@";
124         return 1;
125     }
126     $extension =~ s!::!/!g;
127     return 1 if ($Config::Config{extensions} =~ /\b$extension\b/);
128 }
129
130 sub skip_all {
131     if (@_) {
132         _print "1..0 # Skip @_\n";
133     } else {
134         _print "1..0\n";
135     }
136     exit(0);
137 }
138
139 sub skip_all_if_miniperl {
140     skip_all(@_) if is_miniperl();
141 }
142
143 sub skip_all_without_dynamic_extension {
144     my ($extension) = @_;
145     skip_all("no dynamic loading on miniperl, no $extension") if is_miniperl();
146     return if &_have_dynamic_extension;
147     skip_all("$extension was not built");
148 }
149
150 sub skip_all_without_perlio {
151     skip_all('no PerlIO') unless PerlIO::Layer->find('perlio');
152 }
153
154 sub skip_all_without_config {
155     unless (eval {require Config; 1}) {
156         warn "test.pl had problems loading Config: $@";
157         return;
158     }
159     foreach (@_) {
160         next if $Config::Config{$_};
161         my $key = $_; # Need to copy, before trying to modify.
162         $key =~ s/^use//;
163         $key =~ s/^d_//;
164         skip_all("no $key");
165     }
166 }
167
168 sub skip_all_without_unicode_tables { # (but only under miniperl)
169     if (is_miniperl()) {
170         skip_all_if_miniperl("Unicode tables not built yet")
171             unless eval 'require "unicore/Heavy.pl"';
172     }
173 }
174
175 sub find_git_or_skip {
176     my ($source_dir, $reason);
177     if (-d '.git') {
178         $source_dir = '.';
179     } elsif (-l 'MANIFEST' && -l 'AUTHORS') {
180         my $where = readlink 'MANIFEST';
181         die "Can't readling MANIFEST: $!" unless defined $where;
182         die "Confusing symlink target for MANIFEST, '$where'"
183             unless $where =~ s!/MANIFEST\z!!;
184         if (-d "$where/.git") {
185             # Looks like we are in a symlink tree
186             if (exists $ENV{GIT_DIR}) {
187                 diag("Found source tree at $where, but \$ENV{GIT_DIR} is $ENV{GIT_DIR}. Not changing it");
188             } else {
189                 note("Found source tree at $where, setting \$ENV{GIT_DIR}");
190                 $ENV{GIT_DIR} = "$where/.git";
191             }
192             $source_dir = $where;
193         }
194     } elsif (exists $ENV{GIT_DIR}) {
195         my $commit = '8d063cd8450e59ea1c611a2f4f5a21059a2804f1';
196         my $out = `git rev-parse --verify --quiet '$commit^{commit}'`;
197         chomp $out;
198         if($out eq $commit) {
199             $source_dir = '.'
200         }
201     }
202     if ($source_dir) {
203         my $version_string = `git --version`;
204         if (defined $version_string
205               && $version_string =~ /\Agit version (\d+\.\d+\.\d+)(.*)/) {
206             return $source_dir if eval "v$1 ge v1.5.0";
207             # If you have earlier than 1.5.0 and it works, change this test
208             $reason = "in git checkout, but git version '$1$2' too old";
209         } else {
210             $reason = "in git checkout, but cannot run git";
211         }
212     } else {
213         $reason = 'not being run from a git checkout';
214     }
215     skip_all($reason) if $_[0] && $_[0] eq 'all';
216     skip($reason, @_);
217 }
218
219 sub BAIL_OUT {
220     my ($reason) = @_;
221     _print("Bail out!  $reason\n");
222     exit 255;
223 }
224
225 sub _ok {
226     my ($pass, $where, $name, @mess) = @_;
227     # Do not try to microoptimize by factoring out the "not ".
228     # VMS will avenge.
229     my $out;
230     if ($name) {
231         # escape out '#' or it will interfere with '# skip' and such
232         $name =~ s/#/\\#/g;
233         $out = $pass ? "ok $test - $name" : "not ok $test - $name";
234     } else {
235         $out = $pass ? "ok $test" : "not ok $test";
236     }
237
238     if ($TODO) {
239         $out = $out . " # TODO $TODO";
240     } else {
241         $Tests_Are_Passing = 0 unless $pass;
242     }
243
244     _print "$out\n";
245
246     if ($pass) {
247         note @mess; # Ensure that the message is properly escaped.
248     }
249     else {
250         my $msg = "# Failed test $test - ";
251         $msg.= "$name " if $name;
252         $msg .= "$where\n";
253         _diag $msg;
254         _diag @mess;
255     }
256
257     $test = $test + 1; # don't use ++
258
259     return $pass;
260 }
261
262 sub _where {
263     my @caller = caller($Level);
264     return "at $caller[1] line $caller[2]";
265 }
266
267 # DON'T use this for matches. Use like() instead.
268 sub ok ($@) {
269     my ($pass, $name, @mess) = @_;
270     _ok($pass, _where(), $name, @mess);
271 }
272
273 sub _q {
274     my $x = shift;
275     return 'undef' unless defined $x;
276     my $q = $x;
277     $q =~ s/\\/\\\\/g;
278     $q =~ s/'/\\'/g;
279     return "'$q'";
280 }
281
282 sub _qq {
283     my $x = shift;
284     return defined $x ? '"' . display ($x) . '"' : 'undef';
285 };
286
287 # Support pre-5.10 Perls, for the benefit of CPAN dists that copy this file.
288 # Note that chr(90) exists in both ASCII ("Z") and EBCDIC ("!").
289 my $chars_template = defined(eval { pack "W*", 90 }) ? "W*" : "U*";
290 eval 'sub re::is_regexp { ref($_[0]) eq "Regexp" }'
291     if !defined &re::is_regexp;
292
293 # keys are the codes \n etc map to, values are 2 char strings such as \n
294 my %backslash_escape;
295 foreach my $x (split //, 'nrtfa\\\'"') {
296     $backslash_escape{ord eval "\"\\$x\""} = "\\$x";
297 }
298 # A way to display scalars containing control characters and Unicode.
299 # Trying to avoid setting $_, or relying on local $_ to work.
300 sub display {
301     my @result;
302     foreach my $x (@_) {
303         if (defined $x and not ref $x) {
304             my $y = '';
305             foreach my $c (unpack($chars_template, $x)) {
306                 if ($c > 255) {
307                     $y = $y . sprintf "\\x{%x}", $c;
308                 } elsif ($backslash_escape{$c}) {
309                     $y = $y . $backslash_escape{$c};
310                 } else {
311                     my $z = chr $c; # Maybe we can get away with a literal...
312
313                     if ($z !~ /[^[:^print:][:^ascii:]]/) {
314                         # The pattern above is equivalent (by de Morgan's
315                         # laws) to:
316                         #     $z !~ /(?[ [:print:] & [:ascii:] ])/
317                         # or, $z is not an ascii printable character
318
319                         # Use octal for characters with small ordinals that
320                         # are traditionally expressed as octal: the controls
321                         # below space, which on EBCDIC are almost all the
322                         # controls, but on ASCII don't include DEL nor the C1
323                         # controls.
324                         if ($c < ord " ") {
325                             $z = sprintf "\\%03o", $c;
326                         } else {
327                             $z = sprintf "\\x{%x}", $c;
328                         }
329                     }
330                     $y = $y . $z;
331                 }
332             }
333             $x = $y;
334         }
335         return $x unless wantarray;
336         push @result, $x;
337     }
338     return @result;
339 }
340
341 sub is ($$@) {
342     my ($got, $expected, $name, @mess) = @_;
343
344     my $pass;
345     if( !defined $got || !defined $expected ) {
346         # undef only matches undef
347         $pass = !defined $got && !defined $expected;
348     }
349     else {
350         $pass = $got eq $expected;
351     }
352
353     unless ($pass) {
354         unshift(@mess, "#      got "._qq($got)."\n",
355                        "# expected "._qq($expected)."\n");
356     }
357     _ok($pass, _where(), $name, @mess);
358 }
359
360 sub isnt ($$@) {
361     my ($got, $isnt, $name, @mess) = @_;
362
363     my $pass;
364     if( !defined $got || !defined $isnt ) {
365         # undef only matches undef
366         $pass = defined $got || defined $isnt;
367     }
368     else {
369         $pass = $got ne $isnt;
370     }
371
372     unless( $pass ) {
373         unshift(@mess, "# it should not be "._qq($got)."\n",
374                        "# but it is.\n");
375     }
376     _ok($pass, _where(), $name, @mess);
377 }
378
379 sub cmp_ok ($$$@) {
380     my($got, $type, $expected, $name, @mess) = @_;
381
382     my $pass;
383     {
384         local $^W = 0;
385         local($@,$!);   # don't interfere with $@
386                         # eval() sometimes resets $!
387         $pass = eval "\$got $type \$expected";
388     }
389     unless ($pass) {
390         # It seems Irix long doubles can have 2147483648 and 2147483648
391         # that stringify to the same thing but are actually numerically
392         # different. Display the numbers if $type isn't a string operator,
393         # and the numbers are stringwise the same.
394         # (all string operators have alphabetic names, so tr/a-z// is true)
395         # This will also show numbers for some unneeded cases, but will
396         # definitely be helpful for things such as == and <= that fail
397         if ($got eq $expected and $type !~ tr/a-z//) {
398             unshift @mess, "# $got - $expected = " . ($got - $expected) . "\n";
399         }
400         unshift(@mess, "#      got "._qq($got)."\n",
401                        "# expected $type "._qq($expected)."\n");
402     }
403     _ok($pass, _where(), $name, @mess);
404 }
405
406 # Check that $got is within $range of $expected
407 # if $range is 0, then check it's exact
408 # else if $expected is 0, then $range is an absolute value
409 # otherwise $range is a fractional error.
410 # Here $range must be numeric, >= 0
411 # Non numeric ranges might be a useful future extension. (eg %)
412 sub within ($$$@) {
413     my ($got, $expected, $range, $name, @mess) = @_;
414     my $pass;
415     if (!defined $got or !defined $expected or !defined $range) {
416         # This is a fail, but doesn't need extra diagnostics
417     } elsif ($got !~ tr/0-9// or $expected !~ tr/0-9// or $range !~ tr/0-9//) {
418         # This is a fail
419         unshift @mess, "# got, expected and range must be numeric\n";
420     } elsif ($range < 0) {
421         # This is also a fail
422         unshift @mess, "# range must not be negative\n";
423     } elsif ($range == 0) {
424         # Within 0 is ==
425         $pass = $got == $expected;
426     } elsif ($expected == 0) {
427         # If expected is 0, treat range as absolute
428         $pass = ($got <= $range) && ($got >= - $range);
429     } else {
430         my $diff = $got - $expected;
431         $pass = abs ($diff / $expected) < $range;
432     }
433     unless ($pass) {
434         if ($got eq $expected) {
435             unshift @mess, "# $got - $expected = " . ($got - $expected) . "\n";
436         }
437         unshift@mess, "#      got "._qq($got)."\n",
438                       "# expected "._qq($expected)." (within "._qq($range).")\n";
439     }
440     _ok($pass, _where(), $name, @mess);
441 }
442
443 # Note: this isn't quite as fancy as Test::More::like().
444
445 sub like   ($$@) { like_yn (0,@_) }; # 0 for -
446 sub unlike ($$@) { like_yn (1,@_) }; # 1 for un-
447
448 sub like_yn ($$$@) {
449     my ($flip, undef, $expected, $name, @mess) = @_;
450
451     # We just accept like(..., qr/.../), not like(..., '...'), and
452     # definitely not like(..., '/.../') like
453     # Test::Builder::maybe_regex() does.
454     unless (re::is_regexp($expected)) {
455         die "PANIC: The value '$expected' isn't a regexp. The like() function needs a qr// pattern, not a string";
456     }
457
458     my $pass;
459     $pass = $_[1] =~ /$expected/ if !$flip;
460     $pass = $_[1] !~ /$expected/ if $flip;
461     my $display_got = $_[1];
462     $display_got = display($display_got);
463     my $display_expected = $expected;
464     $display_expected = display($display_expected);
465     unless ($pass) {
466         unshift(@mess, "#      got '$display_got'\n",
467                 $flip
468                 ? "# expected !~ /$display_expected/\n"
469                 : "# expected /$display_expected/\n");
470     }
471     local $Level = $Level + 1;
472     _ok($pass, _where(), $name, @mess);
473 }
474
475 sub pass {
476     _ok(1, '', @_);
477 }
478
479 sub fail {
480     _ok(0, _where(), @_);
481 }
482
483 sub curr_test {
484     $test = shift if @_;
485     return $test;
486 }
487
488 sub next_test {
489   my $retval = $test;
490   $test = $test + 1; # don't use ++
491   $retval;
492 }
493
494 # Note: can't pass multipart messages since we try to
495 # be compatible with Test::More::skip().
496 sub skip {
497     my $why = shift;
498     my $n   = @_ ? shift : 1;
499     my $bad_swap;
500     my $both_zero;
501     {
502       local $^W = 0;
503       $bad_swap = $why > 0 && $n == 0;
504       $both_zero = $why == 0 && $n == 0;
505     }
506     if ($bad_swap || $both_zero || @_) {
507       my $arg = "'$why', '$n'";
508       if (@_) {
509         $arg .= join(", ", '', map { qq['$_'] } @_);
510       }
511       die qq[$0: expected skip(why, count), got skip($arg)\n];
512     }
513     for (1..$n) {
514         _print "ok $test # skip $why\n";
515         $test = $test + 1;
516     }
517     local $^W = 0;
518     last SKIP;
519 }
520
521 sub skip_if_miniperl {
522     skip(@_) if is_miniperl();
523 }
524
525 sub skip_without_dynamic_extension {
526     my $extension = shift;
527     skip("no dynamic loading on miniperl, no extension $extension", @_)
528         if is_miniperl();
529     return if &_have_dynamic_extension($extension);
530     skip("extension $extension was not built", @_);
531 }
532
533 sub todo_skip {
534     my $why = shift;
535     my $n   = @_ ? shift : 1;
536
537     for (1..$n) {
538         _print "not ok $test # TODO & SKIP $why\n";
539         $test = $test + 1;
540     }
541     local $^W = 0;
542     last TODO;
543 }
544
545 sub eq_array {
546     my ($ra, $rb) = @_;
547     return 0 unless $#$ra == $#$rb;
548     for my $i (0..$#$ra) {
549         next     if !defined $ra->[$i] && !defined $rb->[$i];
550         return 0 if !defined $ra->[$i];
551         return 0 if !defined $rb->[$i];
552         return 0 unless $ra->[$i] eq $rb->[$i];
553     }
554     return 1;
555 }
556
557 sub eq_hash {
558   my ($orig, $suspect) = @_;
559   my $fail;
560   while (my ($key, $value) = each %$suspect) {
561     # Force a hash recompute if this perl's internals can cache the hash key.
562     $key = "" . $key;
563     if (exists $orig->{$key}) {
564       if (
565         defined $orig->{$key} != defined $value
566         || (defined $value && $orig->{$key} ne $value)
567       ) {
568         _print "# key ", _qq($key), " was ", _qq($orig->{$key}),
569                      " now ", _qq($value), "\n";
570         $fail = 1;
571       }
572     } else {
573       _print "# key ", _qq($key), " is ", _qq($value),
574                    ", not in original.\n";
575       $fail = 1;
576     }
577   }
578   foreach (keys %$orig) {
579     # Force a hash recompute if this perl's internals can cache the hash key.
580     $_ = "" . $_;
581     next if (exists $suspect->{$_});
582     _print "# key ", _qq($_), " was ", _qq($orig->{$_}), " now missing.\n";
583     $fail = 1;
584   }
585   !$fail;
586 }
587
588 # We only provide a subset of the Test::More functionality.
589 sub require_ok ($) {
590     my ($require) = @_;
591     if ($require =~ tr/[A-Za-z0-9:.]//c) {
592         fail("Invalid character in \"$require\", passed to require_ok");
593     } else {
594         eval <<REQUIRE_OK;
595 require $require;
596 REQUIRE_OK
597         is($@, '', _where(), "require $require");
598     }
599 }
600
601 sub use_ok ($) {
602     my ($use) = @_;
603     if ($use =~ tr/[A-Za-z0-9:.]//c) {
604         fail("Invalid character in \"$use\", passed to use");
605     } else {
606         eval <<USE_OK;
607 use $use;
608 USE_OK
609         is($@, '', _where(), "use $use");
610     }
611 }
612
613 # runperl - Runs a separate perl interpreter and returns its output.
614 # Arguments :
615 #   switches => [ command-line switches ]
616 #   nolib    => 1 # don't use -I../lib (included by default)
617 #   non_portable => Don't warn if a one liner contains quotes
618 #   prog     => one-liner (avoid quotes)
619 #   progs    => [ multi-liner (avoid quotes) ]
620 #   progfile => perl script
621 #   stdin    => string to feed the stdin (or undef to redirect from /dev/null)
622 #   stderr   => If 'devnull' suppresses stderr, if other TRUE value redirect
623 #               stderr to stdout
624 #   args     => [ command-line arguments to the perl program ]
625 #   verbose  => print the command line
626
627 my $is_mswin    = $^O eq 'MSWin32';
628 my $is_netware  = $^O eq 'NetWare';
629 my $is_vms      = $^O eq 'VMS';
630 my $is_cygwin   = $^O eq 'cygwin';
631
632 sub _quote_args {
633     my ($runperl, $args) = @_;
634
635     foreach (@$args) {
636         # In VMS protect with doublequotes because otherwise
637         # DCL will lowercase -- unless already doublequoted.
638        $_ = q(").$_.q(") if $is_vms && !/^\"/ && length($_) > 0;
639        $runperl = $runperl . ' ' . $_;
640     }
641     return $runperl;
642 }
643
644 sub _create_runperl { # Create the string to qx in runperl().
645     my %args = @_;
646     my $runperl = which_perl();
647     if ($runperl =~ m/\s/) {
648         $runperl = qq{"$runperl"};
649     }
650     #- this allows, for example, to set PERL_RUNPERL_DEBUG=/usr/bin/valgrind
651     if ($ENV{PERL_RUNPERL_DEBUG}) {
652         $runperl = "$ENV{PERL_RUNPERL_DEBUG} $runperl";
653     }
654     unless ($args{nolib}) {
655         $runperl = $runperl . ' "-I../lib" "-I." '; # doublequotes because of VMS
656     }
657     if ($args{switches}) {
658         local $Level = 2;
659         die "test.pl:runperl(): 'switches' must be an ARRAYREF " . _where()
660             unless ref $args{switches} eq "ARRAY";
661         $runperl = _quote_args($runperl, $args{switches});
662     }
663     if (defined $args{prog}) {
664         die "test.pl:runperl(): both 'prog' and 'progs' cannot be used " . _where()
665             if defined $args{progs};
666         $args{progs} = [split /\n/, $args{prog}, -1]
667     }
668     if (defined $args{progs}) {
669         die "test.pl:runperl(): 'progs' must be an ARRAYREF " . _where()
670             unless ref $args{progs} eq "ARRAY";
671         foreach my $prog (@{$args{progs}}) {
672             if (!$args{non_portable}) {
673                 if ($prog =~ tr/'"//) {
674                     warn "quotes in prog >>$prog<< are not portable";
675                 }
676                 if ($prog =~ /^([<>|]|2>)/) {
677                     warn "Initial $1 in prog >>$prog<< is not portable";
678                 }
679                 if ($prog =~ /&\z/) {
680                     warn "Trailing & in prog >>$prog<< is not portable";
681                 }
682             }
683             if ($is_mswin || $is_netware || $is_vms) {
684                 $runperl = $runperl . qq ( -e "$prog" );
685             }
686             else {
687                 $runperl = $runperl . qq ( -e '$prog' );
688             }
689         }
690     } elsif (defined $args{progfile}) {
691         $runperl = $runperl . qq( "$args{progfile}");
692     } else {
693         # You probably didn't want to be sucking in from the upstream stdin
694         die "test.pl:runperl(): none of prog, progs, progfile, args, "
695             . " switches or stdin specified"
696             unless defined $args{args} or defined $args{switches}
697                 or defined $args{stdin};
698     }
699     if (defined $args{stdin}) {
700         # so we don't try to put literal newlines and crs onto the
701         # command line.
702         $args{stdin} =~ s/\n/\\n/g;
703         $args{stdin} =~ s/\r/\\r/g;
704
705         if ($is_mswin || $is_netware || $is_vms) {
706             $runperl = qq{$Perl -e "print qq(} .
707                 $args{stdin} . q{)" | } . $runperl;
708         }
709         else {
710             $runperl = qq{$Perl -e 'print qq(} .
711                 $args{stdin} . q{)' | } . $runperl;
712         }
713     } elsif (exists $args{stdin}) {
714         # Using the pipe construction above can cause fun on systems which use
715         # ksh as /bin/sh, as ksh does pipes differently (with one less process)
716         # With sh, for the command line 'perl -e 'print qq()' | perl -e ...'
717         # the sh process forks two children, which use exec to start the two
718         # perl processes. The parent shell process persists for the duration of
719         # the pipeline, and the second perl process starts with no children.
720         # With ksh (and zsh), the shell saves a process by forking a child for
721         # just the first perl process, and execing itself to start the second.
722         # This means that the second perl process starts with one child which
723         # it didn't create. This causes "fun" when if the tests assume that
724         # wait (or waitpid) will only return information about processes
725         # started within the test.
726         # They also cause fun on VMS, where the pipe implementation returns
727         # the exit code of the process at the front of the pipeline, not the
728         # end. This messes up any test using OPTION FATAL.
729         # Hence it's useful to have a way to make STDIN be at eof without
730         # needing a pipeline, so that the fork tests have a sane environment
731         # without these surprises.
732
733         # /dev/null appears to be surprisingly portable.
734         $runperl = $runperl . ($is_mswin ? ' <nul' : ' </dev/null');
735     }
736     if (defined $args{args}) {
737         $runperl = _quote_args($runperl, $args{args});
738     }
739     if (exists $args{stderr} && $args{stderr} eq 'devnull') {
740         $runperl = $runperl . ($is_mswin ? ' 2>nul' : ' 2>/dev/null');
741     }
742     elsif ($args{stderr}) {
743         $runperl = $runperl . ' 2>&1';
744     }
745     if ($args{verbose}) {
746         my $runperldisplay = $runperl;
747         $runperldisplay =~ s/\n/\n\#/g;
748         _print_stderr "# $runperldisplay\n";
749     }
750     return $runperl;
751 }
752
753 # sub run_perl {} is alias to below
754 sub runperl {
755     die "test.pl:runperl() does not take a hashref"
756         if ref $_[0] and ref $_[0] eq 'HASH';
757     my $runperl = &_create_runperl;
758     my $result;
759
760     my $tainted = ${^TAINT};
761     my %args = @_;
762     exists $args{switches} && grep m/^-T$/, @{$args{switches}} and $tainted = $tainted + 1;
763
764     if ($tainted) {
765         # We will assume that if you're running under -T, you really mean to
766         # run a fresh perl, so we'll brute force launder everything for you
767         my $sep;
768
769         if (! eval {require Config; 1}) {
770             warn "test.pl had problems loading Config: $@";
771             $sep = ':';
772         } else {
773             $sep = $Config::Config{path_sep};
774         }
775
776         my @keys = grep {exists $ENV{$_}} qw(CDPATH IFS ENV BASH_ENV);
777         local @ENV{@keys} = ();
778         # Untaint, plus take out . and empty string:
779         local $ENV{'DCL$PATH'} = $1 if $is_vms && exists($ENV{'DCL$PATH'}) && ($ENV{'DCL$PATH'} =~ /(.*)/s);
780         $ENV{PATH} =~ /(.*)/s;
781         local $ENV{PATH} =
782             join $sep, grep { $_ ne "" and $_ ne "." and -d $_ and
783                 ($is_mswin or $is_vms or !(stat && (stat _)[2]&0022)) }
784                     split quotemeta ($sep), $1;
785         if ($is_cygwin) {   # Must have /bin under Cygwin
786             if (length $ENV{PATH}) {
787                 $ENV{PATH} = $ENV{PATH} . $sep;
788             }
789             $ENV{PATH} = $ENV{PATH} . '/bin';
790         }
791         $runperl =~ /(.*)/s;
792         $runperl = $1;
793
794         $result = `$runperl`;
795     } else {
796         $result = `$runperl`;
797     }
798     $result =~ s/\n\n/\n/g if $is_vms; # XXX pipes sometimes double these
799     return $result;
800 }
801
802 # Nice alias
803 *run_perl = *run_perl = \&runperl; # shut up "used only once" warning
804
805 sub DIE {
806     _print_stderr "# @_\n";
807     exit 1;
808 }
809
810 # A somewhat safer version of the sometimes wrong $^X.
811 sub which_perl {
812     unless (defined $Perl) {
813         $Perl = $^X;
814
815         # VMS should have 'perl' aliased properly
816         return $Perl if $is_vms;
817
818         my $exe;
819         if (! eval {require Config; 1}) {
820             warn "test.pl had problems loading Config: $@";
821             $exe = '';
822         } else {
823             $exe = $Config::Config{_exe};
824         }
825        $exe = '' unless defined $exe;
826
827         # This doesn't absolutize the path: beware of future chdirs().
828         # We could do File::Spec->abs2rel() but that does getcwd()s,
829         # which is a bit heavyweight to do here.
830
831         if ($Perl =~ /^perl\Q$exe\E$/i) {
832             my $perl = "perl$exe";
833             if (! eval {require File::Spec; 1}) {
834                 warn "test.pl had problems loading File::Spec: $@";
835                 $Perl = "./$perl";
836             } else {
837                 $Perl = File::Spec->catfile(File::Spec->curdir(), $perl);
838             }
839         }
840
841         # Build up the name of the executable file from the name of
842         # the command.
843
844         if ($Perl !~ /\Q$exe\E$/i) {
845             $Perl = $Perl . $exe;
846         }
847
848         warn "which_perl: cannot find $Perl from $^X" unless -f $Perl;
849
850         # For subcommands to use.
851         $ENV{PERLEXE} = $Perl;
852     }
853     return $Perl;
854 }
855
856 sub unlink_all {
857     my $count = 0;
858     foreach my $file (@_) {
859         1 while unlink $file;
860         if( -f $file ){
861             _print_stderr "# Couldn't unlink '$file': $!\n";
862         }else{
863             $count = $count + 1; # don't use ++
864         }
865     }
866     $count;
867 }
868
869 # _num_to_alpha - Returns a string of letters representing a positive integer.
870 # Arguments :
871 #   number to convert
872 #   maximum number of letters
873
874 # returns undef if the number is negative
875 # returns undef if the number of letters is greater than the maximum wanted
876
877 # _num_to_alpha( 0) eq 'A';
878 # _num_to_alpha( 1) eq 'B';
879 # _num_to_alpha(25) eq 'Z';
880 # _num_to_alpha(26) eq 'AA';
881 # _num_to_alpha(27) eq 'AB';
882
883 my @letters = qw(A B C D E F G H I J K L M N O P Q R S T U V W X Y Z);
884
885 # Avoid ++ -- ranges split negative numbers
886 sub _num_to_alpha{
887     my($num,$max_char) = @_;
888     return unless $num >= 0;
889     my $alpha = '';
890     my $char_count = 0;
891     $max_char = 0 if $max_char < 0;
892
893     while( 1 ){
894         $alpha = $letters[ $num % 26 ] . $alpha;
895         $num = int( $num / 26 );
896         last if $num == 0;
897         $num = $num - 1;
898
899         # char limit
900         next unless $max_char;
901         $char_count = $char_count + 1;
902         return if $char_count == $max_char;
903     }
904     return $alpha;
905 }
906
907 my %tmpfiles;
908 END { unlink_all keys %tmpfiles }
909
910 # A regexp that matches the tempfile names
911 $::tempfile_regexp = 'tmp\d+[A-Z][A-Z]?';
912
913 # Avoid ++, avoid ranges, avoid split //
914 my $tempfile_count = 0;
915 sub tempfile {
916     while(1){
917         my $try = "tmp$$";
918         my $alpha = _num_to_alpha($tempfile_count,2);
919         last unless defined $alpha;
920         $try = $try . $alpha;
921         $tempfile_count = $tempfile_count + 1;
922
923         # Need to note all the file names we allocated, as a second request may
924         # come before the first is created.
925         if (!$tmpfiles{$try} && !-e $try) {
926             # We have a winner
927             $tmpfiles{$try} = 1;
928             return $try;
929         }
930     }
931     die "Can't find temporary file name starting \"tmp$$\"";
932 }
933
934 # register_tempfile - Adds a list of files to be removed at the end of the current test file
935 # Arguments :
936 #   a list of files to be removed later
937
938 # returns a count of how many file names were actually added
939
940 # Reuses %tmpfiles so that tempfile() will also skip any files added here
941 # even if the file doesn't exist yet.
942
943 sub register_tempfile {
944     my $count = 0;
945     for( @_ ){
946         if( $tmpfiles{$_} ){
947             _print_stderr "# Temporary file '$_' already added\n";
948         }else{
949             $tmpfiles{$_} = 1;
950             $count = $count + 1;
951         }
952     }
953     return $count;
954 }
955
956 # This is the temporary file for fresh_perl
957 my $tmpfile = tempfile();
958
959 sub fresh_perl {
960     my($prog, $runperl_args) = @_;
961
962     # Run 'runperl' with the complete perl program contained in '$prog', and
963     # arguments in the hash referred to by '$runperl_args'.  The results are
964     # returned, with $? set to the exit code.  Unless overridden, stderr is
965     # redirected to stdout.
966
967     die sprintf "Third argument to fresh_perl_.* must be hashref of args to fresh_perl (or {})"
968         unless !(defined $runperl_args) || ref($runperl_args) eq 'HASH';
969
970     # Given the choice of the mis-parsable {}
971     # (we want an anon hash, but a borked lexer might think that it's a block)
972     # or relying on taking a reference to a lexical
973     # (\ might be mis-parsed, and the reference counting on the pad may go
974     #  awry)
975     # it feels like the least-worse thing is to assume that auto-vivification
976     # works. At least, this is only going to be a run-time failure, so won't
977     # affect tests using this file but not this function.
978     $runperl_args->{progfile} ||= $tmpfile;
979     $runperl_args->{stderr}     = 1 unless exists $runperl_args->{stderr};
980
981     open TEST, '>', $tmpfile or die "Cannot open $tmpfile: $!";
982     binmode TEST, ':utf8' if $runperl_args->{wide_chars};
983     print TEST $prog;
984     close TEST or die "Cannot close $tmpfile: $!";
985
986     my $results = runperl(%$runperl_args);
987     my $status = $?;    # Not necessary to save this, but it makes it clear to
988                         # future maintainers.
989
990     # Clean up the results into something a bit more predictable.
991     $results  =~ s/\n+$//;
992     $results =~ s/at\s+$::tempfile_regexp\s+line/at - line/g;
993     $results =~ s/of\s+$::tempfile_regexp\s+aborted/of - aborted/g;
994
995     # bison says 'parse error' instead of 'syntax error',
996     # various yaccs may or may not capitalize 'syntax'.
997     $results =~ s/^(syntax|parse) error/syntax error/mig;
998
999     if ($is_vms) {
1000         # some tests will trigger VMS messages that won't be expected
1001         $results =~ s/\n?%[A-Z]+-[SIWEF]-[A-Z]+,.*//;
1002
1003         # pipes double these sometimes
1004         $results =~ s/\n\n/\n/g;
1005     }
1006
1007     $? = $status;
1008     return $results;
1009 }
1010
1011
1012 sub _fresh_perl {
1013     my($prog, $action, $expect, $runperl_args, $name) = @_;
1014
1015     my $results = fresh_perl($prog, $runperl_args);
1016     my $status = $?;
1017
1018     # Use the first line of the program as a name if none was given
1019     unless( $name ) {
1020         ($first_line, $name) = $prog =~ /^((.{1,50}).*)/;
1021         $name = $name . '...' if length $first_line > length $name;
1022     }
1023
1024     # Historically this was implemented using a closure, but then that means
1025     # that the tests for closures avoid using this code. Given that there
1026     # are exactly two callers, doing exactly two things, the simpler approach
1027     # feels like a better trade off.
1028     my $pass;
1029     if ($action eq 'eq') {
1030         $pass = is($results, $expect, $name);
1031     } elsif ($action eq '=~') {
1032         $pass = like($results, $expect, $name);
1033     } else {
1034         die "_fresh_perl can't process action '$action'";
1035     }
1036         
1037     unless ($pass) {
1038         _diag "# PROG: \n$prog\n";
1039         _diag "# STATUS: $status\n";
1040     }
1041
1042     return $pass;
1043 }
1044
1045 #
1046 # fresh_perl_is
1047 #
1048 # Combination of run_perl() and is().
1049 #
1050
1051 sub fresh_perl_is {
1052     my($prog, $expected, $runperl_args, $name) = @_;
1053
1054     # _fresh_perl() is going to clip the trailing newlines off the result.
1055     # This will make it so the test author doesn't have to know that.
1056     $expected =~ s/\n+$//;
1057
1058     local $Level = 2;
1059     _fresh_perl($prog, 'eq', $expected, $runperl_args, $name);
1060 }
1061
1062 #
1063 # fresh_perl_like
1064 #
1065 # Combination of run_perl() and like().
1066 #
1067
1068 sub fresh_perl_like {
1069     my($prog, $expected, $runperl_args, $name) = @_;
1070     local $Level = 2;
1071     _fresh_perl($prog, '=~', $expected, $runperl_args, $name);
1072 }
1073
1074 # Many tests use the same format in __DATA__ or external files to specify a
1075 # sequence of (fresh) tests to run, extra files they may temporarily need, and
1076 # what the expected output is.  Putting it here allows common code to serve
1077 # these multiple tests.
1078 #
1079 # Each program is source code to run followed by an "EXPECT" line, followed
1080 # by the expected output.
1081 #
1082 # The first line of the code to run may be a command line switch such as -wE
1083 # or -0777 (alphanumerics only; only one cluster, beginning with a minus is
1084 # allowed).  Later lines may contain (note the '# ' on each):
1085 #   # TODO reason for todo
1086 #   # SKIP reason for skip
1087 #   # SKIP ?code to test if this should be skipped
1088 #   # NAME name of the test (as with ok($ok, $name))
1089 #
1090 # The expected output may contain:
1091 #   OPTION list of options
1092 #   OPTIONS list of options
1093 #
1094 # The possible options for OPTION may be:
1095 #   regex - the expected output is a regular expression
1096 #   random - all lines match but in any order
1097 #   fatal - the code will fail fatally (croak, die)
1098 #
1099 # If the actual output contains a line "SKIPPED" the test will be
1100 # skipped.
1101 #
1102 # If the actual output contains a line "PREFIX", any output starting with that
1103 # line will be ignored when comparing with the expected output
1104 #
1105 # If the global variable $FATAL is true then OPTION fatal is the
1106 # default.
1107
1108 sub _setup_one_file {
1109     my $fh = shift;
1110     # Store the filename as a program that started at line 0.
1111     # Real files count lines starting at line 1.
1112     my @these = (0, shift);
1113     my ($lineno, $current);
1114     while (<$fh>) {
1115         if ($_ eq "########\n") {
1116             if (defined $current) {
1117                 push @these, $lineno, $current;
1118             }
1119             undef $current;
1120         } else {
1121             if (!defined $current) {
1122                 $lineno = $.;
1123             }
1124             $current .= $_;
1125         }
1126     }
1127     if (defined $current) {
1128         push @these, $lineno, $current;
1129     }
1130     ((scalar @these) / 2 - 1, @these);
1131 }
1132
1133 sub setup_multiple_progs {
1134     my ($tests, @prgs);
1135     foreach my $file (@_) {
1136         next if $file =~ /(?:~|\.orig|,v)$/;
1137         next if $file =~ /perlio$/ && !PerlIO::Layer->find('perlio');
1138         next if -d $file;
1139
1140         open my $fh, '<', $file or die "Cannot open $file: $!\n" ;
1141         my $found;
1142         while (<$fh>) {
1143             if (/^__END__/) {
1144                 $found = $found + 1; # don't use ++
1145                 last;
1146             }
1147         }
1148         # This is an internal error, and should never happen. All bar one of
1149         # the files had an __END__ marker to signal the end of their preamble,
1150         # although for some it wasn't technically necessary as they have no
1151         # tests. It might be possible to process files without an __END__ by
1152         # seeking back to the start and treating the whole file as tests, but
1153         # it's simpler and more reliable just to make the rule that all files
1154         # must have __END__ in. This should never fail - a file without an
1155         # __END__ should not have been checked in, because the regression tests
1156         # would not have passed.
1157         die "Could not find '__END__' in $file"
1158             unless $found;
1159
1160         my ($t, @p) = _setup_one_file($fh, $file);
1161         $tests += $t;
1162         push @prgs, @p;
1163
1164         close $fh
1165             or die "Cannot close $file: $!\n";
1166     }
1167     return ($tests, @prgs);
1168 }
1169
1170 sub run_multiple_progs {
1171     my $up = shift;
1172     my @prgs;
1173     if ($up) {
1174         # The tests in lib run in a temporary subdirectory of t, and always
1175         # pass in a list of "programs" to run
1176         @prgs = @_;
1177     } else {
1178         # The tests below t run in t and pass in a file handle. In theory we
1179         # can pass (caller)[1] as the second argument to report errors with
1180         # the filename of our caller, as the handle is always DATA. However,
1181         # line numbers in DATA count from the __END__ token, so will be wrong.
1182         # Which is more confusing than not providing line numbers. So, for now,
1183         # don't provide line numbers. No obvious clean solution - one hack
1184         # would be to seek DATA back to the start and read to the __END__ token,
1185         # but that feels almost like we should just open $0 instead.
1186
1187         # Not going to rely on undef in list assignment.
1188         my $dummy;
1189         ($dummy, @prgs) = _setup_one_file(shift);
1190     }
1191
1192     my $tmpfile = tempfile();
1193
1194     my ($file, $line);
1195   PROGRAM:
1196     while (defined ($line = shift @prgs)) {
1197         $_ = shift @prgs;
1198         unless ($line) {
1199             $file = $_;
1200             if (defined $file) {
1201                 print "# From $file\n";
1202             }
1203             next;
1204         }
1205         my $switch = "";
1206         my @temps ;
1207         my @temp_path;
1208         if (s/^(\s*-\w+)//) {
1209             $switch = $1;
1210         }
1211         my ($prog, $expected) = split(/\nEXPECT(?:\n|$)/, $_, 2);
1212
1213         my %reason;
1214         foreach my $what (qw(skip todo)) {
1215             $prog =~ s/^#\s*\U$what\E\s*(.*)\n//m and $reason{$what} = $1;
1216             # If the SKIP reason starts ? then it's taken as a code snippet to
1217             # evaluate. This provides the flexibility to have conditional SKIPs
1218             if ($reason{$what} && $reason{$what} =~ s/^\?//) {
1219                 my $temp = eval $reason{$what};
1220                 if ($@) {
1221                     die "# In \U$what\E code reason:\n# $reason{$what}\n$@";
1222                 }
1223                 $reason{$what} = $temp;
1224             }
1225         }
1226
1227         my $name = '';
1228         if ($prog =~ s/^#\s*NAME\s+(.+)\n//m) {
1229             $name = $1;
1230         }
1231
1232         if ($reason{skip}) {
1233         SKIP:
1234           {
1235             skip($name ? "$name - $reason{skip}" : $reason{skip}, 1);
1236           }
1237           next PROGRAM;
1238         }
1239
1240         if ($prog =~ /--FILE--/) {
1241             my @files = split(/\n?--FILE--\s*([^\s\n]*)\s*\n/, $prog) ;
1242             shift @files ;
1243             die "Internal error: test $_ didn't split into pairs, got " .
1244                 scalar(@files) . "[" . join("%%%%", @files) ."]\n"
1245                     if @files % 2;
1246             while (@files > 2) {
1247                 my $filename = shift @files;
1248                 my $code = shift @files;
1249                 push @temps, $filename;
1250                 if ($filename =~ m#(.*)/# && $filename !~ m#^\.\./#) {
1251                     require File::Path;
1252                     File::Path::mkpath($1);
1253                     push(@temp_path, $1);
1254                 }
1255                 open my $fh, '>', $filename or die "Cannot open $filename: $!\n";
1256                 print $fh $code;
1257                 close $fh or die "Cannot close $filename: $!\n";
1258             }
1259             shift @files;
1260             $prog = shift @files;
1261         }
1262
1263         open my $fh, '>', $tmpfile or die "Cannot open >$tmpfile: $!";
1264         print $fh q{
1265         BEGIN {
1266             push @INC, '.';
1267             open STDERR, '>&', STDOUT
1268               or die "Can't dup STDOUT->STDERR: $!;";
1269         }
1270         };
1271         print $fh "\n#line 1\n";  # So the line numbers don't get messed up.
1272         print $fh $prog,"\n";
1273         close $fh or die "Cannot close $tmpfile: $!";
1274         my $results = runperl( stderr => 1, progfile => $tmpfile,
1275                                stdin => undef, $up
1276                                ? (switches => ["-I$up/lib", $switch], nolib => 1)
1277                                : (switches => [$switch])
1278                                 );
1279         my $status = $?;
1280         $results =~ s/\n+$//;
1281         # allow expected output to be written as if $prog is on STDIN
1282         $results =~ s/$::tempfile_regexp/-/g;
1283         if ($^O eq 'VMS') {
1284             # some tests will trigger VMS messages that won't be expected
1285             $results =~ s/\n?%[A-Z]+-[SIWEF]-[A-Z]+,.*//;
1286
1287             # pipes double these sometimes
1288             $results =~ s/\n\n/\n/g;
1289         }
1290         # bison says 'parse error' instead of 'syntax error',
1291         # various yaccs may or may not capitalize 'syntax'.
1292         $results =~ s/^(syntax|parse) error/syntax error/mig;
1293         # allow all tests to run when there are leaks
1294         $results =~ s/Scalars leaked: \d+\n//g;
1295
1296         $expected =~ s/\n+$//;
1297         my $prefix = ($results =~ s#^PREFIX(\n|$)##) ;
1298         # any special options? (OPTIONS foo bar zap)
1299         my $option_regex = 0;
1300         my $option_random = 0;
1301         my $fatal = $FATAL;
1302         if ($expected =~ s/^OPTIONS? (.+)\n//) {
1303             foreach my $option (split(' ', $1)) {
1304                 if ($option eq 'regex') { # allow regular expressions
1305                     $option_regex = 1;
1306                 }
1307                 elsif ($option eq 'random') { # all lines match, but in any order
1308                     $option_random = 1;
1309                 }
1310                 elsif ($option eq 'fatal') { # perl should fail
1311                     $fatal = 1;
1312                 }
1313                 else {
1314                     die "$0: Unknown OPTION '$option'\n";
1315                 }
1316             }
1317         }
1318         die "$0: can't have OPTION regex and random\n"
1319             if $option_regex + $option_random > 1;
1320         my $ok = 0;
1321         if ($results =~ s/^SKIPPED\n//) {
1322             print "$results\n" ;
1323             $ok = 1;
1324         }
1325         else {
1326             if ($option_random) {
1327                 my @got = sort split "\n", $results;
1328                 my @expected = sort split "\n", $expected;
1329
1330                 $ok = "@got" eq "@expected";
1331             }
1332             elsif ($option_regex) {
1333                 $ok = $results =~ /^$expected/;
1334             }
1335             elsif ($prefix) {
1336                 $ok = $results =~ /^\Q$expected/;
1337             }
1338             else {
1339                 $ok = $results eq $expected;
1340             }
1341
1342             if ($ok && $fatal && !($status >> 8)) {
1343                 $ok = 0;
1344             }
1345         }
1346
1347         local $::TODO = $reason{todo};
1348
1349         unless ($ok) {
1350             my $err_line = "PROG: $switch\n$prog\n" .
1351                            "EXPECTED:\n$expected\n";
1352             $err_line   .= "EXIT STATUS: != 0\n" if $fatal;
1353             $err_line   .= "GOT:\n$results\n";
1354             $err_line   .= "EXIT STATUS: " . ($status >> 8) . "\n" if $fatal;
1355             if ($::TODO) {
1356                 $err_line =~ s/^/# /mg;
1357                 print $err_line;  # Harness can't filter it out from STDERR.
1358             }
1359             else {
1360                 print STDERR $err_line;
1361             }
1362         }
1363
1364         if (defined $file) {
1365             _ok($ok, "at $file line $line", $name);
1366         } else {
1367             # We don't have file and line number data for the test, so report
1368             # errors as coming from our caller.
1369             local $Level = $Level + 1;
1370             ok($ok, $name);
1371         }
1372
1373         foreach (@temps) {
1374             unlink $_ if $_;
1375         }
1376         foreach (@temp_path) {
1377             File::Path::rmtree $_ if -d $_;
1378         }
1379     }
1380 }
1381
1382 sub can_ok ($@) {
1383     my($proto, @methods) = @_;
1384     my $class = ref $proto || $proto;
1385
1386     unless( @methods ) {
1387         return _ok( 0, _where(), "$class->can(...)" );
1388     }
1389
1390     my @nok = ();
1391     foreach my $method (@methods) {
1392         local($!, $@);  # don't interfere with caller's $@
1393                         # eval sometimes resets $!
1394         eval { $proto->can($method) } || push @nok, $method;
1395     }
1396
1397     my $name;
1398     $name = @methods == 1 ? "$class->can('$methods[0]')"
1399                           : "$class->can(...)";
1400
1401     _ok( !@nok, _where(), $name );
1402 }
1403
1404
1405 # Call $class->new( @$args ); and run the result through object_ok.
1406 # See Test::More::new_ok
1407 sub new_ok {
1408     my($class, $args, $obj_name) = @_;
1409     $args ||= [];
1410     $object_name = "The object" unless defined $obj_name;
1411
1412     local $Level = $Level + 1;
1413
1414     my $obj;
1415     my $ok = eval { $obj = $class->new(@$args); 1 };
1416     my $error = $@;
1417
1418     if($ok) {
1419         object_ok($obj, $class, $object_name);
1420     }
1421     else {
1422         ok( 0, "new() died" );
1423         diag("Error was:  $@");
1424     }
1425
1426     return $obj;
1427
1428 }
1429
1430
1431 sub isa_ok ($$;$) {
1432     my($object, $class, $obj_name) = @_;
1433
1434     my $diag;
1435     $obj_name = 'The object' unless defined $obj_name;
1436     my $name = "$obj_name isa $class";
1437     if( !defined $object ) {
1438         $diag = "$obj_name isn't defined";
1439     }
1440     else {
1441         my $whatami = ref $object ? 'object' : 'class';
1442
1443         # We can't use UNIVERSAL::isa because we want to honor isa() overrides
1444         local($@, $!);  # eval sometimes resets $!
1445         my $rslt = eval { $object->isa($class) };
1446         my $error = $@;  # in case something else blows away $@
1447
1448         if( $error ) {
1449             if( $error =~ /^Can't call method "isa" on unblessed reference/ ) {
1450                 # It's an unblessed reference
1451                 $obj_name = 'The reference' unless defined $obj_name;
1452                 if( !UNIVERSAL::isa($object, $class) ) {
1453                     my $ref = ref $object;
1454                     $diag = "$obj_name isn't a '$class' it's a '$ref'";
1455                 }
1456             }
1457             elsif( $error =~ /Can't call method "isa" without a package/ ) {
1458                 # It's something that can't even be a class
1459                 $obj_name = 'The thing' unless defined $obj_name;
1460                 $diag = "$obj_name isn't a class or reference";
1461             }
1462             else {
1463                 die <<WHOA;
1464 WHOA! I tried to call ->isa on your object and got some weird error.
1465 This should never happen.  Please contact the author immediately.
1466 Here's the error.
1467 $@
1468 WHOA
1469             }
1470         }
1471         elsif( !$rslt ) {
1472             $obj_name = "The $whatami" unless defined $obj_name;
1473             my $ref = ref $object;
1474             $diag = "$obj_name isn't a '$class' it's a '$ref'";
1475         }
1476     }
1477
1478     _ok( !$diag, _where(), $name );
1479 }
1480
1481
1482 sub class_ok {
1483     my($class, $isa, $class_name) = @_;
1484
1485     # Written so as to count as one test
1486     local $Level = $Level + 1;
1487     if( ref $class ) {
1488         ok( 0, "$class is a reference, not a class name" );
1489     }
1490     else {
1491         isa_ok($class, $isa, $class_name);
1492     }
1493 }
1494
1495
1496 sub object_ok {
1497     my($obj, $isa, $obj_name) = @_;
1498
1499     local $Level = $Level + 1;
1500     if( !ref $obj ) {
1501         ok( 0, "$obj is not a reference" );
1502     }
1503     else {
1504         isa_ok($obj, $isa, $obj_name);
1505     }
1506 }
1507
1508
1509 # Purposefully avoiding a closure.
1510 sub __capture {
1511     push @::__capture, join "", @_;
1512 }
1513     
1514 sub capture_warnings {
1515     my $code = shift;
1516
1517     local @::__capture;
1518     local $SIG {__WARN__} = \&__capture;
1519     &$code;
1520     return @::__capture;
1521 }
1522
1523 # This will generate a variable number of tests.
1524 # Use done_testing() instead of a fixed plan.
1525 sub warnings_like {
1526     my ($code, $expect, $name) = @_;
1527     local $Level = $Level + 1;
1528
1529     my @w = capture_warnings($code);
1530
1531     cmp_ok(scalar @w, '==', scalar @$expect, $name);
1532     foreach my $e (@$expect) {
1533         if (ref $e) {
1534             like(shift @w, $e, $name);
1535         } else {
1536             is(shift @w, $e, $name);
1537         }
1538     }
1539     if (@w) {
1540         diag("Saw these additional warnings:");
1541         diag($_) foreach @w;
1542     }
1543 }
1544
1545 sub _fail_excess_warnings {
1546     my($expect, $got, $name) = @_;
1547     local $Level = $Level + 1;
1548     # This will fail, and produce diagnostics
1549     is($expect, scalar @$got, $name);
1550     diag("Saw these warnings:");
1551     diag($_) foreach @$got;
1552 }
1553
1554 sub warning_is {
1555     my ($code, $expect, $name) = @_;
1556     die sprintf "Expect must be a string or undef, not a %s reference", ref $expect
1557         if ref $expect;
1558     local $Level = $Level + 1;
1559     my @w = capture_warnings($code);
1560     if (@w > 1) {
1561         _fail_excess_warnings(0 + defined $expect, \@w, $name);
1562     } else {
1563         is($w[0], $expect, $name);
1564     }
1565 }
1566
1567 sub warning_like {
1568     my ($code, $expect, $name) = @_;
1569     die sprintf "Expect must be a regexp object"
1570         unless ref $expect eq 'Regexp';
1571     local $Level = $Level + 1;
1572     my @w = capture_warnings($code);
1573     if (@w > 1) {
1574         _fail_excess_warnings(0 + defined $expect, \@w, $name);
1575     } else {
1576         like($w[0], $expect, $name);
1577     }
1578 }
1579
1580 # Set a watchdog to timeout the entire test file
1581 # NOTE:  If the test file uses 'threads', then call the watchdog() function
1582 #        _AFTER_ the 'threads' module is loaded.
1583 sub watchdog ($;$)
1584 {
1585     my $timeout = shift;
1586     my $method  = shift || "";
1587     my $timeout_msg = 'Test process timed out - terminating';
1588
1589     # Valgrind slows perl way down so give it more time before dying.
1590     $timeout *= 10 if $ENV{PERL_VALGRIND};
1591
1592     my $pid_to_kill = $$;   # PID for this process
1593
1594     if ($method eq "alarm") {
1595         goto WATCHDOG_VIA_ALARM;
1596     }
1597
1598     # shut up use only once warning
1599     my $threads_on = $threads::threads && $threads::threads;
1600
1601     # Don't use a watchdog process if 'threads' is loaded -
1602     #   use a watchdog thread instead
1603     if (!$threads_on || $method eq "process") {
1604
1605         # On Windows and VMS, try launching a watchdog process
1606         #   using system(1, ...) (see perlport.pod)
1607         if ($is_mswin || $is_vms) {
1608             # On Windows, try to get the 'real' PID
1609             if ($is_mswin) {
1610                 eval { require Win32; };
1611                 if (defined(&Win32::GetCurrentProcessId)) {
1612                     $pid_to_kill = Win32::GetCurrentProcessId();
1613                 }
1614             }
1615
1616             # If we still have a fake PID, we can't use this method at all
1617             return if ($pid_to_kill <= 0);
1618
1619             # Launch watchdog process
1620             my $watchdog;
1621             eval {
1622                 local $SIG{'__WARN__'} = sub {
1623                     _diag("Watchdog warning: $_[0]");
1624                 };
1625                 my $sig = $is_vms ? 'TERM' : 'KILL';
1626                 my $prog = "sleep($timeout);" .
1627                            "warn qq/# $timeout_msg" . '\n/;' .
1628                            "kill(q/$sig/, $pid_to_kill);";
1629
1630                 # On Windows use the indirect object plus LIST form to guarantee
1631                 # that perl is launched directly rather than via the shell (see
1632                 # perlfunc.pod), and ensure that the LIST has multiple elements
1633                 # since the indirect object plus COMMANDSTRING form seems to
1634                 # hang (see perl #121283). Don't do this on VMS, which doesn't
1635                 # support the LIST form at all.
1636                 if ($is_mswin) {
1637                     my $runperl = which_perl();
1638                     if ($runperl =~ m/\s/) {
1639                         $runperl = qq{"$runperl"};
1640                     }
1641                     $watchdog = system({ $runperl } 1, $runperl, '-e', $prog);
1642                 }
1643                 else {
1644                     my $cmd = _create_runperl(prog => $prog);
1645                     $watchdog = system(1, $cmd);
1646                 }
1647             };
1648             if ($@ || ($watchdog <= 0)) {
1649                 _diag('Failed to start watchdog');
1650                 _diag($@) if $@;
1651                 undef($watchdog);
1652                 return;
1653             }
1654
1655             # Add END block to parent to terminate and
1656             #   clean up watchdog process
1657             eval("END { local \$! = 0; local \$? = 0;
1658                         wait() if kill('KILL', $watchdog); };");
1659             return;
1660         }
1661
1662         # Try using fork() to generate a watchdog process
1663         my $watchdog;
1664         eval { $watchdog = fork() };
1665         if (defined($watchdog)) {
1666             if ($watchdog) {   # Parent process
1667                 # Add END block to parent to terminate and
1668                 #   clean up watchdog process
1669                 eval "END { local \$! = 0; local \$? = 0;
1670                             wait() if kill('KILL', $watchdog); };";
1671                 return;
1672             }
1673
1674             ### Watchdog process code
1675
1676             # Load POSIX if available
1677             eval { require POSIX; };
1678
1679             # Execute the timeout
1680             sleep($timeout - 2) if ($timeout > 2);   # Workaround for perlbug #49073
1681             sleep(2);
1682
1683             # Kill test process if still running
1684             if (kill(0, $pid_to_kill)) {
1685                 _diag($timeout_msg);
1686                 kill('KILL', $pid_to_kill);
1687                 if ($is_cygwin) {
1688                     # sometimes the above isn't enough on cygwin
1689                     sleep 1; # wait a little, it might have worked after all
1690                     system("/bin/kill -f $pid_to_kill");
1691                 }
1692             }
1693
1694             # Don't execute END block (added at beginning of this file)
1695             $NO_ENDING = 1;
1696
1697             # Terminate ourself (i.e., the watchdog)
1698             POSIX::_exit(1) if (defined(&POSIX::_exit));
1699             exit(1);
1700         }
1701
1702         # fork() failed - fall through and try using a thread
1703     }
1704
1705     # Use a watchdog thread because either 'threads' is loaded,
1706     #   or fork() failed
1707     if (eval {require threads; 1}) {
1708         'threads'->create(sub {
1709                 # Load POSIX if available
1710                 eval { require POSIX; };
1711
1712                 # Execute the timeout
1713                 my $time_left = $timeout;
1714                 do {
1715                     $time_left = $time_left - sleep($time_left);
1716                 } while ($time_left > 0);
1717
1718                 # Kill the parent (and ourself)
1719                 select(STDERR); $| = 1;
1720                 _diag($timeout_msg);
1721                 POSIX::_exit(1) if (defined(&POSIX::_exit));
1722                 my $sig = $is_vms ? 'TERM' : 'KILL';
1723                 kill($sig, $pid_to_kill);
1724             })->detach();
1725         return;
1726     }
1727
1728     # If everything above fails, then just use an alarm timeout
1729 WATCHDOG_VIA_ALARM:
1730     if (eval { alarm($timeout); 1; }) {
1731         # Load POSIX if available
1732         eval { require POSIX; };
1733
1734         # Alarm handler will do the actual 'killing'
1735         $SIG{'ALRM'} = sub {
1736             select(STDERR); $| = 1;
1737             _diag($timeout_msg);
1738             POSIX::_exit(1) if (defined(&POSIX::_exit));
1739             my $sig = $is_vms ? 'TERM' : 'KILL';
1740             kill($sig, $pid_to_kill);
1741         };
1742     }
1743 }
1744
1745 1;