(perl #131836) avoid a use-after-free after parsing a "sub" keyword
[perl.git] / Porting / cmpVERSION.pl
1 #!/usr/bin/perl -w
2
3 #
4 # cmpVERSION - compare the current Perl source tree and a given tag
5 # for modules that have identical version numbers but different contents.
6 #
7 # with -d option, output the diffs too
8 # with -x option, exclude files from modules where blead is not upstream
9 #
10 # (after all, there are tools like core-cpan-diff that can already deal with
11 # them)
12 #
13 # Original by slaven@rezic.de, modified by jhi and matt.w.johnson@gmail.com.
14 # Adaptation to produce TAP by Abigail, folded back into this file by Nicholas
15
16 use strict;
17 use 5.006;
18
19 use ExtUtils::MakeMaker;
20 use File::Spec::Functions qw(devnull);
21 use Getopt::Long;
22
23 my ($diffs, $exclude_upstream, $tag_to_compare, $tap);
24 unless (GetOptions('diffs' => \$diffs,
25                    'exclude|x' => \$exclude_upstream,
26                    'tag=s' => \$tag_to_compare,
27                    'tap' => \$tap,
28                    ) && @ARGV == 0) {
29     die "usage: $0 [ -d -x --tag TAG --tap]";
30 }
31
32 die "$0: This does not look like a Perl directory\n"
33     unless -f "perl.h" && -d "Porting";
34 die "$0: 'This is a Perl directory but does not look like Git working directory\n"
35     unless (-d ".git" || (exists $ENV{GIT_DIR} && -d $ENV{GIT_DIR}));
36
37 my $null = devnull();
38
39 unless (defined $tag_to_compare) {
40     my $check = 'HEAD';
41     while(1) {
42         $check = `git describe --abbrev=0 $check 2>$null`;
43         chomp $check;
44         last unless $check =~ /-RC/;
45         $check .= '~1';
46     }
47     $tag_to_compare = $check;
48     # Thanks to David Golden for this suggestion.
49
50 }
51
52 unless (length $tag_to_compare) {
53     die "$0: Git found, but no Git tags found\n"
54         unless $tap;
55     print "1..0 # SKIP: Git found, but no Git tags found\n";
56     exit 0;
57 }
58
59 my $tag_exists = `git --no-pager tag -l $tag_to_compare 2>$null`;
60 chomp $tag_exists;
61
62 unless ($tag_exists eq $tag_to_compare) {
63     die "$0: '$tag_to_compare' is not a known Git tag\n" unless $tap;
64     print "1..0 # SKIP: '$tag_to_compare' is not a known Git tag\n";
65     exit 0;
66 }
67
68 my %upstream_files;
69 if ($exclude_upstream) {
70     unshift @INC, 'Porting';
71     require Maintainers;
72
73     for my $m (grep {!defined $Maintainers::Modules{$_}{UPSTREAM}
74                          or $Maintainers::Modules{$_}{UPSTREAM} ne 'blead'}
75                keys %Maintainers::Modules) {
76         $upstream_files{$_} = 1 for Maintainers::get_module_files($m);
77     }
78 }
79
80 # Files to skip from the check for one reason or another,
81 # usually because they pull in their version from some other file.
82 my %skip;
83 @skip{
84     'cpan/ExtUtils-Install/t/lib/MakeMaker/Test/Setup/BFD.pm', # just a test module
85     'cpan/ExtUtils-MakeMaker/t/lib/MakeMaker/Test/Setup/BFD.pm', # just a test module
86     'cpan/ExtUtils-MakeMaker/t/lib/MakeMaker/Test/Setup/XS.pm',  # just a test module
87     'cpan/IO-Compress/lib/File/GlobMapper.pm', # upstream needs to supply $VERSION
88     'cpan/Math-BigInt/t/Math/BigFloat/Subclass.pm', # just a test module
89     'cpan/Math-BigInt/t/Math/BigInt/BareCalc.pm',   # just a test module
90     'cpan/Math-BigInt/t/Math/BigInt/Scalar.pm',     # just a test module
91     'cpan/Math-BigInt/t/Math/BigInt/Subclass.pm',   # just a test module
92     'cpan/Math-BigRat/t/Math/BigRat/Test.pm',       # just a test module
93     'cpan/podlators/t/lib/Test/Podlators.pm',       # just a test module
94     'cpan/podlators/t/lib/Test/RRA.pm',             # just a test module
95     'cpan/podlators/t/lib/Test/RRA/Config.pm',      # just a test module
96     'cpan/version/t/coretests.pm', # just a test module
97     'dist/Attribute-Handlers/demo/MyClass.pm', # it's just demonstration code
98     'dist/Exporter/lib/Exporter/Heavy.pm',
99     'dist/Module-CoreList/lib/Module/CoreList.pm',
100     'dist/Module-CoreList/lib/Module/CoreList/TieHashDelta.pm',
101     'dist/Module-CoreList/lib/Module/CoreList/Utils.pm',
102     'lib/Carp/Heavy.pm',
103     'lib/Config.pm',            # no version number but contents will vary
104     'win32/FindExt.pm',
105 } = ();
106
107 # Files to skip just for particular version(s),
108 # usually due to some # mix-up
109
110 my %skip_versions = (
111            # 'some/sample/file.pm' => [ '1.23', '1.24' ],
112           );
113
114 my $skip_dirs = qr|^t/lib|;
115
116 sub pm_file_from_xs {
117     my $xs = shift;
118
119     foreach my $try (sub {
120                          # First try a .pm at the same level as the .xs file
121                          # with the same basename
122                          return shift =~ s/\.xs\z//r;
123                      },
124                      sub {
125                          # Try for a (different) .pm at the same level, based
126                          # on the directory name:
127                          my ($path) = shift =~ m!^(.*)/!;
128                          my ($last) = $path =~ m!([^-/]+)\z!;
129                          return "$path/$last";
130                      },
131                      sub {
132                          # Try to work out the extension's full package, and
133                          # look for a .pm in lib/ based on that:
134                          my ($path) = shift =~ m!^(.*)/!;
135                          my ($last) = $path =~ m!([^/]+)\z!;
136                          $last = 'List-Util' if $last eq 'Scalar-List-Utils';
137                          $last =~ tr !-!/!;
138                          return "$path/lib/$last";
139                      }) {
140         # For all cases, first look to see if the .pm file is generated.
141         my $base = $try->($xs);
142         return "${base}_pm.PL" if -f "${base}_pm.PL";
143         return "${base}.pm" if -f "${base}.pm";
144     }
145
146     die "No idea which .pm file corresponds to '$xs', so aborting";
147 }
148
149 # Key is the .pm file from which we check the version.
150 # Value is a reference to an array of files to check for differences
151 # The trivial case is a pure perl module, where the array holds one element,
152 # the perl module's file. The "fun" comes with XS modules, and the real fun
153 # with XS modules with more than one XS file, and "interesting" layouts.
154
155 my %module_diffs;
156
157 foreach (`git --no-pager diff --name-only $tag_to_compare --diff-filter=ACMRTUXB`) {
158     chomp;
159     next unless m/^(.*)\//;
160     my $this_dir = $1;
161     next if $this_dir =~ $skip_dirs || exists $skip{$_};
162     next if exists $upstream_files{$_};
163     if (/\.pm\z/ || m|^lib/.*\.pl\z| || /_pm\.PL\z/) {
164         push @{$module_diffs{$_}}, $_;
165     } elsif (/\.xs\z/ && !/\bt\b/) {
166         push @{$module_diffs{pm_file_from_xs($_)}}, $_;
167     }
168 }
169
170 unless (%module_diffs) {
171     print "1..1\nok 1 - No difference found\n" if $tap;
172     exit;
173 }
174
175 printf "1..%d\n" => scalar keys %module_diffs if $tap;
176 print "#\n# Comparing against $tag_to_compare ....\n#\n" if $tap;
177
178 my $count;
179 my $diff_cmd = "git --no-pager diff $tag_to_compare ";
180 my $q = ($^O eq 'MSWin32' || $^O eq 'NetWare' || $^O eq 'VMS') ? '"' : "'";
181 my (@diff);
182
183 foreach my $pm_file (sort keys %module_diffs) {
184     # git has already told us that the files differ, so no need to grab each as
185     # a blob from git, and do the comparison ourselves.
186     my $pm_version = eval {MM->parse_version($pm_file)};
187     my $orig_pm_content = get_file_from_git($pm_file, $tag_to_compare);
188     my $orig_pm_version = eval {MM->parse_version(\$orig_pm_content)};
189     ++$count;
190
191     if (!defined $orig_pm_version || $orig_pm_version eq 'undef') { # sigh
192         print "ok $count - SKIP Can't parse \$VERSION in $pm_file\n"
193           if $tap;
194     } elsif (!defined $pm_version || $pm_version eq 'undef') {
195         my $nok = "not ok $count - in $pm_file version was $orig_pm_version, now unparsable\n";
196         print $nok if $tap;
197         print STDERR "# $nok\n";
198     } elsif ($pm_version ne $orig_pm_version) { # good
199         print "ok $count - $pm_file\n" if $tap;
200     } else {
201         if ($tap) {
202             print "#\n# " . '-' x 75 . "\n"
203             . "# Version number ($pm_version) unchanged since"
204             . " $tag_to_compare, but contents have changed:\n#\n";
205             foreach (sort @{$module_diffs{$pm_file}}) {
206                 print "# $_" for `$diff_cmd $q$_$q`;
207             }
208             print "# " . '-' x 75 . "\n";
209
210             if (exists $skip_versions{$pm_file}
211                 and grep $pm_version eq $_, @{$skip_versions{$pm_file}}) {
212                 print "ok $count - SKIP $pm_file version $pm_version\n";
213             } else {
214                 my $nok = "not ok $count - $pm_file version $pm_version\n";
215                 print $nok;
216                 print STDERR "# $nok";
217             }
218         } else {
219             push @diff, @{$module_diffs{$pm_file}};
220             print "$pm_file version $pm_version\n";
221         }
222     }
223 }
224
225 sub get_file_from_git {
226     my ($file, $tag) = @_;
227     local $/;
228
229     use open IN => ':raw';
230     return scalar `git --no-pager show $tag:$file 2>$null`;
231 }
232
233 if ($diffs) {
234     for (sort @diff) {
235         print "\n";
236         system "$diff_cmd $q$_$q";
237     }
238 }