39c18e5844e90a37515acda82356ebd5542b6bd1
[perl.git] / lib / perl5db.pl
1
2 =head1 NAME 
3
4 perl5db.pl - the perl debugger
5
6 =head1 SYNOPSIS
7
8     perl -d  your_Perl_script
9
10 =head1 DESCRIPTION
11
12 C<perl5db.pl> is the perl debugger. It is loaded automatically by Perl when
13 you invoke a script with C<perl -d>. This documentation tries to outline the
14 structure and services provided by C<perl5db.pl>, and to describe how you
15 can use them.
16
17 =head1 GENERAL NOTES
18
19 The debugger can look pretty forbidding to many Perl programmers. There are
20 a number of reasons for this, many stemming out of the debugger's history.
21
22 When the debugger was first written, Perl didn't have a lot of its nicer
23 features - no references, no lexical variables, no closures, no object-oriented
24 programming. So a lot of the things one would normally have done using such
25 features was done using global variables, globs and the C<local()> operator 
26 in creative ways.
27
28 Some of these have survived into the current debugger; a few of the more
29 interesting and still-useful idioms are noted in this section, along with notes
30 on the comments themselves.
31
32 =head2 Why not use more lexicals?
33
34 Experienced Perl programmers will note that the debugger code tends to use
35 mostly package globals rather than lexically-scoped variables. This is done
36 to allow a significant amount of control of the debugger from outside the
37 debugger itself.       
38
39 Unfortunately, though the variables are accessible, they're not well
40 documented, so it's generally been a decision that hasn't made a lot of
41 difference to most users. Where appropriate, comments have been added to
42 make variables more accessible and usable, with the understanding that these
43 I<are> debugger internals, and are therefore subject to change. Future
44 development should probably attempt to replace the globals with a well-defined
45 API, but for now, the variables are what we've got.
46
47 =head2 Automated variable stacking via C<local()>
48
49 As you may recall from reading C<perlfunc>, the C<local()> operator makes a 
50 temporary copy of a variable in the current scope. When the scope ends, the
51 old copy is restored. This is often used in the debugger to handle the 
52 automatic stacking of variables during recursive calls:
53
54      sub foo {
55         local $some_global++;
56
57         # Do some stuff, then ...
58         return;
59      }
60
61 What happens is that on entry to the subroutine, C<$some_global> is localized,
62 then altered. When the subroutine returns, Perl automatically undoes the 
63 localization, restoring the previous value. Voila, automatic stack management.
64
65 The debugger uses this trick a I<lot>. Of particular note is C<DB::eval>, 
66 which lets the debugger get control inside of C<eval>'ed code. The debugger
67 localizes a saved copy of C<$@> inside the subroutine, which allows it to
68 keep C<$@> safe until it C<DB::eval> returns, at which point the previous
69 value of C<$@> is restored. This makes it simple (well, I<simpler>) to keep 
70 track of C<$@> inside C<eval>s which C<eval> other C<eval's>.
71
72 In any case, watch for this pattern. It occurs fairly often.
73
74 =head2 The C<^> trick
75
76 This is used to cleverly reverse the sense of a logical test depending on 
77 the value of an auxiliary variable. For instance, the debugger's C<S>
78 (search for subroutines by pattern) allows you to negate the pattern 
79 like this:
80
81    # Find all non-'foo' subs:
82    S !/foo/      
83
84 Boolean algebra states that the truth table for XOR looks like this:
85
86 =over 4
87
88 =item * 0 ^ 0 = 0 
89
90 (! not present and no match) --> false, don't print
91
92 =item * 0 ^ 1 = 1 
93
94 (! not present and matches) --> true, print
95
96 =item * 1 ^ 0 = 1 
97
98 (! present and no match) --> true, print
99
100 =item * 1 ^ 1 = 0 
101
102 (! present and matches) --> false, don't print
103
104 =back
105
106 As you can see, the first pair applies when C<!> isn't supplied, and
107 the second pair applies when it is. The XOR simply allows us to
108 compact a more complicated if-then-elseif-else into a more elegant 
109 (but perhaps overly clever) single test. After all, it needed this
110 explanation...
111
112 =head2 FLAGS, FLAGS, FLAGS
113
114 There is a certain C programming legacy in the debugger. Some variables,
115 such as C<$single>, C<$trace>, and C<$frame>, have I<magical> values composed
116 of 1, 2, 4, etc. (powers of 2) OR'ed together. This allows several pieces
117 of state to be stored independently in a single scalar. 
118
119 A test like
120
121     if ($scalar & 4) ...
122
123 is checking to see if the appropriate bit is on. Since each bit can be 
124 "addressed" independently in this way, C<$scalar> is acting sort of like
125 an array of bits. Obviously, since the contents of C<$scalar> are just a 
126 bit-pattern, we can save and restore it easily (it will just look like
127 a number).
128
129 The problem, is of course, that this tends to leave magic numbers scattered
130 all over your program whenever a bit is set, cleared, or checked. So why do 
131 it?
132
133 =over 4
134
135 =item *
136
137 First, doing an arithmetical or bitwise operation on a scalar is
138 just about the fastest thing you can do in Perl: C<use constant> actually
139 creates a subroutine call, and array and hash lookups are much slower. Is
140 this over-optimization at the expense of readability? Possibly, but the 
141 debugger accesses these  variables a I<lot>. Any rewrite of the code will
142 probably have to benchmark alternate implementations and see which is the
143 best balance of readability and speed, and then document how it actually 
144 works.
145
146 =item *
147
148 Second, it's very easy to serialize a scalar number. This is done in 
149 the restart code; the debugger state variables are saved in C<%ENV> and then
150 restored when the debugger is restarted. Having them be just numbers makes
151 this trivial. 
152
153 =item *
154
155 Third, some of these variables are being shared with the Perl core 
156 smack in the middle of the interpreter's execution loop. It's much faster for 
157 a C program (like the interpreter) to check a bit in a scalar than to access 
158 several different variables (or a Perl array).
159
160 =back
161
162 =head2 What are those C<XXX> comments for?
163
164 Any comment containing C<XXX> means that the comment is either somewhat
165 speculative - it's not exactly clear what a given variable or chunk of 
166 code is doing, or that it is incomplete - the basics may be clear, but the
167 subtleties are not completely documented.
168
169 Send in a patch if you can clear up, fill out, or clarify an C<XXX>.
170
171 =head1 DATA STRUCTURES MAINTAINED BY CORE         
172
173 There are a number of special data structures provided to the debugger by
174 the Perl interpreter.
175
176 The array C<@{$main::{'_<'.$filename}}> (aliased locally to C<@dbline>
177 via glob assignment) contains the text from C<$filename>, with each
178 element corresponding to a single line of C<$filename>. Additionally,
179 breakable lines will be dualvars with the numeric component being the
180 memory address of a COP node. Non-breakable lines are dualvar to 0.
181
182 The hash C<%{'_<'.$filename}> (aliased locally to C<%dbline> via glob 
183 assignment) contains breakpoints and actions.  The keys are line numbers; 
184 you can set individual values, but not the whole hash. The Perl interpreter 
185 uses this hash to determine where breakpoints have been set. Any true value is
186 considered to be a breakpoint; C<perl5db.pl> uses C<$break_condition\0$action>.
187 Values are magical in numeric context: 1 if the line is breakable, 0 if not.
188
189 The scalar C<${"_<$filename"}> simply contains the string C<_<$filename>.
190 This is also the case for evaluated strings that contain subroutines, or
191 which are currently being executed.  The $filename for C<eval>ed strings looks
192 like C<(eval 34).
193
194 =head1 DEBUGGER STARTUP
195
196 When C<perl5db.pl> starts, it reads an rcfile (C<perl5db.ini> for
197 non-interactive sessions, C<.perldb> for interactive ones) that can set a number
198 of options. In addition, this file may define a subroutine C<&afterinit>
199 that will be executed (in the debugger's context) after the debugger has 
200 initialized itself.
201
202 Next, it checks the C<PERLDB_OPTS> environment variable and treats its 
203 contents as the argument of a C<o> command in the debugger.
204
205 =head2 STARTUP-ONLY OPTIONS
206
207 The following options can only be specified at startup.
208 To set them in your rcfile, add a call to
209 C<&parse_options("optionName=new_value")>.
210
211 =over 4
212
213 =item * TTY 
214
215 the TTY to use for debugging i/o.
216
217 =item * noTTY 
218
219 if set, goes in NonStop mode.  On interrupt, if TTY is not set,
220 uses the value of noTTY or F<$HOME/.perldbtty$$> to find TTY using
221 Term::Rendezvous.  Current variant is to have the name of TTY in this
222 file.
223
224 =item * ReadLine 
225
226 if false, a dummy ReadLine is used, so you can debug
227 ReadLine applications.
228
229 =item * NonStop 
230
231 if true, no i/o is performed until interrupt.
232
233 =item * LineInfo 
234
235 file or pipe to print line number info to.  If it is a
236 pipe, a short "emacs like" message is used.
237
238 =item * RemotePort 
239
240 host:port to connect to on remote host for remote debugging.
241
242 =item * HistFile
243
244 file to store session history to. There is no default and so no
245 history file is written unless this variable is explicitly set.
246
247 =item * HistSize
248
249 number of commands to store to the file specified in C<HistFile>.
250 Default is 100.
251
252 =back
253
254 =head3 SAMPLE RCFILE
255
256  &parse_options("NonStop=1 LineInfo=db.out");
257   sub afterinit { $trace = 1; }
258
259 The script will run without human intervention, putting trace
260 information into C<db.out>.  (If you interrupt it, you had better
261 reset C<LineInfo> to something I<interactive>!)
262
263 =head1 INTERNALS DESCRIPTION
264
265 =head2 DEBUGGER INTERFACE VARIABLES
266
267 Perl supplies the values for C<%sub>.  It effectively inserts
268 a C<&DB::DB();> in front of each place that can have a
269 breakpoint. At each subroutine call, it calls C<&DB::sub> with
270 C<$DB::sub> set to the called subroutine. It also inserts a C<BEGIN
271 {require 'perl5db.pl'}> before the first line.
272
273 After each C<require>d file is compiled, but before it is executed, a
274 call to C<&DB::postponed($main::{'_<'.$filename})> is done. C<$filename>
275 is the expanded name of the C<require>d file (as found via C<%INC>).
276
277 =head3 IMPORTANT INTERNAL VARIABLES
278
279 =head4 C<$CreateTTY>
280
281 Used to control when the debugger will attempt to acquire another TTY to be
282 used for input. 
283
284 =over   
285
286 =item * 1 -  on C<fork()>
287
288 =item * 2 - debugger is started inside debugger
289
290 =item * 4 -  on startup
291
292 =back
293
294 =head4 C<$doret>
295
296 The value -2 indicates that no return value should be printed.
297 Any other positive value causes C<DB::sub> to print return values.
298
299 =head4 C<$evalarg>
300
301 The item to be eval'ed by C<DB::eval>. Used to prevent messing with the current
302 contents of C<@_> when C<DB::eval> is called.
303
304 =head4 C<$frame>
305
306 Determines what messages (if any) will get printed when a subroutine (or eval)
307 is entered or exited. 
308
309 =over 4
310
311 =item * 0 -  No enter/exit messages
312
313 =item * 1 - Print I<entering> messages on subroutine entry
314
315 =item * 2 - Adds exit messages on subroutine exit. If no other flag is on, acts like 1+2.
316
317 =item * 4 - Extended messages: C<< <in|out> I<context>=I<fully-qualified sub name> from I<file>:I<line> >>. If no other flag is on, acts like 1+4.
318
319 =item * 8 - Adds parameter information to messages, and overloaded stringify and tied FETCH is enabled on the printed arguments. Ignored if C<4> is not on.
320
321 =item * 16 - Adds C<I<context> return from I<subname>: I<value>> messages on subroutine/eval exit. Ignored if C<4> is is not on.
322
323 =back
324
325 To get everything, use C<$frame=30> (or C<o f=30> as a debugger command).
326 The debugger internally juggles the value of C<$frame> during execution to
327 protect external modules that the debugger uses from getting traced.
328
329 =head4 C<$level>
330
331 Tracks current debugger nesting level. Used to figure out how many 
332 C<E<lt>E<gt>> pairs to surround the line number with when the debugger 
333 outputs a prompt. Also used to help determine if the program has finished
334 during command parsing.
335
336 =head4 C<$onetimeDump>
337
338 Controls what (if anything) C<DB::eval()> will print after evaluating an
339 expression.
340
341 =over 4
342
343 =item * C<undef> - don't print anything
344
345 =item * C<dump> - use C<dumpvar.pl> to display the value returned
346
347 =item * C<methods> - print the methods callable on the first item returned
348
349 =back
350
351 =head4 C<$onetimeDumpDepth>
352
353 Controls how far down C<dumpvar.pl> will go before printing C<...> while
354 dumping a structure. Numeric. If C<undef>, print all levels.
355
356 =head4 C<$signal>
357
358 Used to track whether or not an C<INT> signal has been detected. C<DB::DB()>,
359 which is called before every statement, checks this and puts the user into
360 command mode if it finds C<$signal> set to a true value.
361
362 =head4 C<$single>
363
364 Controls behavior during single-stepping. Stacked in C<@stack> on entry to
365 each subroutine; popped again at the end of each subroutine.
366
367 =over 4 
368
369 =item * 0 - run continuously.
370
371 =item * 1 - single-step, go into subs. The C<s> command.
372
373 =item * 2 - single-step, don't go into subs. The C<n> command.
374
375 =item * 4 - print current sub depth (turned on to force this when C<too much
376 recursion> occurs.
377
378 =back
379
380 =head4 C<$trace>
381
382 Controls the output of trace information. 
383
384 =over 4
385
386 =item * 1 - The C<t> command was entered to turn on tracing (every line executed is printed)
387
388 =item * 2 - watch expressions are active
389
390 =item * 4 - user defined a C<watchfunction()> in C<afterinit()>
391
392 =back
393
394 =head4 C<$slave_editor>
395
396 1 if C<LINEINFO> was directed to a pipe; 0 otherwise.
397
398 =head4 C<@cmdfhs>
399
400 Stack of filehandles that C<DB::readline()> will read commands from.
401 Manipulated by the debugger's C<source> command and C<DB::readline()> itself.
402
403 =head4 C<@dbline>
404
405 Local alias to the magical line array, C<@{$main::{'_<'.$filename}}> , 
406 supplied by the Perl interpreter to the debugger. Contains the source.
407
408 =head4 C<@old_watch>
409
410 Previous values of watch expressions. First set when the expression is
411 entered; reset whenever the watch expression changes.
412
413 =head4 C<@saved>
414
415 Saves important globals (C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>, C<$\>, C<$^W>)
416 so that the debugger can substitute safe values while it's running, and
417 restore them when it returns control.
418
419 =head4 C<@stack>
420
421 Saves the current value of C<$single> on entry to a subroutine.
422 Manipulated by the C<c> command to turn off tracing in all subs above the
423 current one.
424
425 =head4 C<@to_watch>
426
427 The 'watch' expressions: to be evaluated before each line is executed.
428
429 =head4 C<@typeahead>
430
431 The typeahead buffer, used by C<DB::readline>.
432
433 =head4 C<%alias>
434
435 Command aliases. Stored as character strings to be substituted for a command
436 entered.
437
438 =head4 C<%break_on_load>
439
440 Keys are file names, values are 1 (break when this file is loaded) or undef
441 (don't break when it is loaded).
442
443 =head4 C<%dbline>
444
445 Keys are line numbers, values are C<condition\0action>. If used in numeric
446 context, values are 0 if not breakable, 1 if breakable, no matter what is
447 in the actual hash entry.
448
449 =head4 C<%had_breakpoints>
450
451 Keys are file names; values are bitfields:
452
453 =over 4 
454
455 =item * 1 - file has a breakpoint in it.
456
457 =item * 2 - file has an action in it.
458
459 =back
460
461 A zero or undefined value means this file has neither.
462
463 =head4 C<%option>
464
465 Stores the debugger options. These are character string values.
466
467 =head4 C<%postponed>
468
469 Saves breakpoints for code that hasn't been compiled yet.
470 Keys are subroutine names, values are:
471
472 =over 4
473
474 =item * C<compile> - break when this sub is compiled
475
476 =item * C<< break +0 if <condition> >> - break (conditionally) at the start of this routine. The condition will be '1' if no condition was specified.
477
478 =back
479
480 =head4 C<%postponed_file>
481
482 This hash keeps track of breakpoints that need to be set for files that have
483 not yet been compiled. Keys are filenames; values are references to hashes.
484 Each of these hashes is keyed by line number, and its values are breakpoint
485 definitions (C<condition\0action>).
486
487 =head1 DEBUGGER INITIALIZATION
488
489 The debugger's initialization actually jumps all over the place inside this
490 package. This is because there are several BEGIN blocks (which of course 
491 execute immediately) spread through the code. Why is that? 
492
493 The debugger needs to be able to change some things and set some things up 
494 before the debugger code is compiled; most notably, the C<$deep> variable that
495 C<DB::sub> uses to tell when a program has recursed deeply. In addition, the
496 debugger has to turn off warnings while the debugger code is compiled, but then
497 restore them to their original setting before the program being debugged begins
498 executing.
499
500 The first C<BEGIN> block simply turns off warnings by saving the current
501 setting of C<$^W> and then setting it to zero. The second one initializes
502 the debugger variables that are needed before the debugger begins executing.
503 The third one puts C<$^X> back to its former value. 
504
505 We'll detail the second C<BEGIN> block later; just remember that if you need
506 to initialize something before the debugger starts really executing, that's
507 where it has to go.
508
509 =cut
510
511 package DB;
512
513 use strict;
514
515 BEGIN {eval 'use IO::Handle'};  # Needed for flush only? breaks under miniperl
516
517 BEGIN {
518     require feature;
519     $^V =~ /^v(\d+\.\d+)/;
520     feature->import(":$1");
521 }
522
523 # Debugger for Perl 5.00x; perl5db.pl patch level:
524 use vars qw($VERSION $header);
525
526 $VERSION = '1.39_03';
527
528 $header = "perl5db.pl version $VERSION";
529
530 =head1 DEBUGGER ROUTINES
531
532 =head2 C<DB::eval()>
533
534 This function replaces straight C<eval()> inside the debugger; it simplifies
535 the process of evaluating code in the user's context.
536
537 The code to be evaluated is passed via the package global variable 
538 C<$DB::evalarg>; this is done to avoid fiddling with the contents of C<@_>.
539
540 Before we do the C<eval()>, we preserve the current settings of C<$trace>,
541 C<$single>, C<$^D> and C<$usercontext>.  The latter contains the
542 preserved values of C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>, C<$\>, C<$^W> and the
543 user's current package, grabbed when C<DB::DB> got control.  This causes the
544 proper context to be used when the eval is actually done.  Afterward, we
545 restore C<$trace>, C<$single>, and C<$^D>.
546
547 Next we need to handle C<$@> without getting confused. We save C<$@> in a
548 local lexical, localize C<$saved[0]> (which is where C<save()> will put 
549 C<$@>), and then call C<save()> to capture C<$@>, C<$!>, C<$^E>, C<$,>, 
550 C<$/>, C<$\>, and C<$^W>) and set C<$,>, C<$/>, C<$\>, and C<$^W> to values
551 considered sane by the debugger. If there was an C<eval()> error, we print 
552 it on the debugger's output. If C<$onetimedump> is defined, we call 
553 C<dumpit> if it's set to 'dump', or C<methods> if it's set to 
554 'methods'. Setting it to something else causes the debugger to do the eval 
555 but not print the result - handy if you want to do something else with it 
556 (the "watch expressions" code does this to get the value of the watch
557 expression but not show it unless it matters).
558
559 In any case, we then return the list of output from C<eval> to the caller, 
560 and unwinding restores the former version of C<$@> in C<@saved> as well 
561 (the localization of C<$saved[0]> goes away at the end of this scope).
562
563 =head3 Parameters and variables influencing execution of DB::eval()
564
565 C<DB::eval> isn't parameterized in the standard way; this is to keep the
566 debugger's calls to C<DB::eval()> from mucking with C<@_>, among other things.
567 The variables listed below influence C<DB::eval()>'s execution directly. 
568
569 =over 4
570
571 =item C<$evalarg> - the thing to actually be eval'ed
572
573 =item C<$trace> - Current state of execution tracing
574
575 =item C<$single> - Current state of single-stepping
576
577 =item C<$onetimeDump> - what is to be displayed after the evaluation 
578
579 =item C<$onetimeDumpDepth> - how deep C<dumpit()> should go when dumping results
580
581 =back
582
583 The following variables are altered by C<DB::eval()> during its execution. They
584 are "stacked" via C<local()>, enabling recursive calls to C<DB::eval()>. 
585
586 =over 4
587
588 =item C<@res> - used to capture output from actual C<eval>.
589
590 =item C<$otrace> - saved value of C<$trace>.
591
592 =item C<$osingle> - saved value of C<$single>.      
593
594 =item C<$od> - saved value of C<$^D>.
595
596 =item C<$saved[0]> - saved value of C<$@>.
597
598 =item $\ - for output of C<$@> if there is an evaluation error.      
599
600 =back
601
602 =head3 The problem of lexicals
603
604 The context of C<DB::eval()> presents us with some problems. Obviously,
605 we want to be 'sandboxed' away from the debugger's internals when we do
606 the eval, but we need some way to control how punctuation variables and
607 debugger globals are used. 
608
609 We can't use local, because the code inside C<DB::eval> can see localized
610 variables; and we can't use C<my> either for the same reason. The code
611 in this routine compromises and uses C<my>.
612
613 After this routine is over, we don't have user code executing in the debugger's
614 context, so we can use C<my> freely.
615
616 =cut
617
618 ############################################## Begin lexical danger zone
619
620 # 'my' variables used here could leak into (that is, be visible in)
621 # the context that the code being evaluated is executing in. This means that
622 # the code could modify the debugger's variables.
623 #
624 # Fiddling with the debugger's context could be Bad. We insulate things as
625 # much as we can.
626
627 use vars qw(
628     @args
629     %break_on_load
630     @cmdfhs
631     $CommandSet
632     $CreateTTY
633     $DBGR
634     @dbline
635     $dbline
636     %dbline
637     $dieLevel
638     $evalarg
639     $filename
640     $frame
641     $hist
642     $histfile
643     $histsize
644     $ImmediateStop
645     $IN
646     $inhibit_exit
647     @ini_INC
648     $ini_warn
649     $line
650     $maxtrace
651     $od
652     $onetimeDump
653     $onetimedumpDepth
654     %option
655     @options
656     $osingle
657     $otrace
658     $OUT
659     $packname
660     $pager
661     $post
662     %postponed
663     $prc
664     $pre
665     $pretype
666     $psh
667     @RememberOnROptions
668     $remoteport
669     @res
670     $rl
671     @saved
672     $signal
673     $signalLevel
674     $single
675     $start
676     $sub
677     %sub
678     $subname
679     $term
680     $trace
681     $usercontext
682     $warnLevel
683     $window
684 );
685
686 # Used to save @ARGV and extract any debugger-related flags.
687 use vars qw(@ARGS);
688
689 # Used to prevent multiple entries to diesignal()
690 # (if for instance diesignal() itself dies)
691 use vars qw($panic);
692
693 # Used to prevent the debugger from running nonstop
694 # after a restart
695 use vars qw($second_time);
696
697 sub _calc_usercontext {
698     my ($package) = @_;
699
700     # Cancel strict completely for the evaluated code, so the code
701     # the user evaluates won't be affected by it. (Shlomi Fish)
702     return 'no strict; ($@, $!, $^E, $,, $/, $\, $^W) = @saved;'
703     . "package $package;";    # this won't let them modify, alas
704 }
705
706 sub eval {
707
708     # 'my' would make it visible from user code
709     #    but so does local! --tchrist
710     # Remember: this localizes @DB::res, not @main::res.
711     local @res;
712     {
713
714         # Try to keep the user code from messing  with us. Save these so that
715         # even if the eval'ed code changes them, we can put them back again.
716         # Needed because the user could refer directly to the debugger's
717         # package globals (and any 'my' variables in this containing scope)
718         # inside the eval(), and we want to try to stay safe.
719         local $otrace  = $trace;
720         local $osingle = $single;
721         local $od      = $^D;
722
723         # Untaint the incoming eval() argument.
724         { ($evalarg) = $evalarg =~ /(.*)/s; }
725
726         # $usercontext built in DB::DB near the comment
727         # "set up the context for DB::eval ..."
728         # Evaluate and save any results.
729         @res = eval "$usercontext $evalarg;\n";  # '\n' for nice recursive debug
730
731         # Restore those old values.
732         $trace  = $otrace;
733         $single = $osingle;
734         $^D     = $od;
735     }
736
737     # Save the current value of $@, and preserve it in the debugger's copy
738     # of the saved precious globals.
739     my $at = $@;
740
741     # Since we're only saving $@, we only have to localize the array element
742     # that it will be stored in.
743     local $saved[0];    # Preserve the old value of $@
744     eval { &DB::save };
745
746     # Now see whether we need to report an error back to the user.
747     if ($at) {
748         local $\ = '';
749         print $OUT $at;
750     }
751
752     # Display as required by the caller. $onetimeDump and $onetimedumpDepth
753     # are package globals.
754     elsif ($onetimeDump) {
755         if ( $onetimeDump eq 'dump' ) {
756             local $option{dumpDepth} = $onetimedumpDepth
757               if defined $onetimedumpDepth;
758             dumpit( $OUT, \@res );
759         }
760         elsif ( $onetimeDump eq 'methods' ) {
761             methods( $res[0] );
762         }
763     } ## end elsif ($onetimeDump)
764     @res;
765 } ## end sub eval
766
767 ############################################## End lexical danger zone
768
769 # After this point it is safe to introduce lexicals.
770 # The code being debugged will be executing in its own context, and
771 # can't see the inside of the debugger.
772 #
773 # However, one should not overdo it: leave as much control from outside as
774 # possible. If you make something a lexical, it's not going to be addressable
775 # from outside the debugger even if you know its name.
776
777 # This file is automatically included if you do perl -d.
778 # It's probably not useful to include this yourself.
779 #
780 # Before venturing further into these twisty passages, it is
781 # wise to read the perldebguts man page or risk the ire of dragons.
782 #
783 # (It should be noted that perldebguts will tell you a lot about
784 # the underlying mechanics of how the debugger interfaces into the
785 # Perl interpreter, but not a lot about the debugger itself. The new
786 # comments in this code try to address this problem.)
787
788 # Note that no subroutine call is possible until &DB::sub is defined
789 # (for subroutines defined outside of the package DB). In fact the same is
790 # true if $deep is not defined.
791
792 # Enhanced by ilya@math.ohio-state.edu (Ilya Zakharevich)
793
794 # modified Perl debugger, to be run from Emacs in perldb-mode
795 # Ray Lischner (uunet!mntgfx!lisch) as of 5 Nov 1990
796 # Johan Vromans -- upgrade to 4.0 pl 10
797 # Ilya Zakharevich -- patches after 5.001 (and some before ;-)
798 ########################################################################
799
800 =head1 DEBUGGER INITIALIZATION
801
802 The debugger starts up in phases.
803
804 =head2 BASIC SETUP
805
806 First, it initializes the environment it wants to run in: turning off
807 warnings during its own compilation, defining variables which it will need
808 to avoid warnings later, setting itself up to not exit when the program
809 terminates, and defaulting to printing return values for the C<r> command.
810
811 =cut
812
813 # Needed for the statement after exec():
814 #
815 # This BEGIN block is simply used to switch off warnings during debugger
816 # compilation. Probably it would be better practice to fix the warnings,
817 # but this is how it's done at the moment.
818
819 BEGIN {
820     $ini_warn = $^W;
821     $^W       = 0;
822 }    # Switch compilation warnings off until another BEGIN.
823
824 local ($^W) = 0;    # Switch run-time warnings off during init.
825
826 =head2 THREADS SUPPORT
827
828 If we are running under a threaded Perl, we require threads and threads::shared
829 if the environment variable C<PERL5DB_THREADED> is set, to enable proper
830 threaded debugger control.  C<-dt> can also be used to set this.
831
832 Each new thread will be announced and the debugger prompt will always inform
833 you of each new thread created.  It will also indicate the thread id in which
834 we are currently running within the prompt like this:
835
836         [tid] DB<$i>
837
838 Where C<[tid]> is an integer thread id and C<$i> is the familiar debugger
839 command prompt.  The prompt will show: C<[0]> when running under threads, but
840 not actually in a thread.  C<[tid]> is consistent with C<gdb> usage.
841
842 While running under threads, when you set or delete a breakpoint (etc.), this
843 will apply to all threads, not just the currently running one.  When you are 
844 in a currently executing thread, you will stay there until it completes.  With
845 the current implementation it is not currently possible to hop from one thread
846 to another.
847
848 The C<e> and C<E> commands are currently fairly minimal - see C<h e> and C<h E>.
849
850 Note that threading support was built into the debugger as of Perl version
851 C<5.8.6> and debugger version C<1.2.8>.
852
853 =cut
854
855 BEGIN {
856   # ensure we can share our non-threaded variables or no-op
857   if ($ENV{PERL5DB_THREADED}) {
858         require threads;
859         require threads::shared;
860         import threads::shared qw(share);
861         $DBGR;
862         share(\$DBGR);
863         lock($DBGR);
864         print "Threads support enabled\n";
865   } else {
866         *lock  = sub(*) {};
867         *share = sub(*) {};
868   }
869 }
870
871 # This would probably be better done with "use vars", but that wasn't around
872 # when this code was originally written. (Neither was "use strict".) And on
873 # the principle of not fiddling with something that was working, this was
874 # left alone.
875 warn(               # Do not ;-)
876     # These variables control the execution of 'dumpvar.pl'.
877     $dumpvar::hashDepth,
878     $dumpvar::arrayDepth,
879     $dumpvar::dumpDBFiles,
880     $dumpvar::dumpPackages,
881     $dumpvar::quoteHighBit,
882     $dumpvar::printUndef,
883     $dumpvar::globPrint,
884     $dumpvar::usageOnly,
885
886     # used to control die() reporting in diesignal()
887     $Carp::CarpLevel,
888
889
890   )
891   if 0;
892
893 # without threads, $filename is not defined until DB::DB is called
894 foreach my $k (keys (%INC)) {
895         &share(\$main::{'_<'.$filename}) if defined $filename;
896 };
897
898 # Command-line + PERLLIB:
899 # Save the contents of @INC before they are modified elsewhere.
900 @ini_INC = @INC;
901
902 # This was an attempt to clear out the previous values of various
903 # trapped errors. Apparently it didn't help. XXX More info needed!
904 # $prevwarn = $prevdie = $prevbus = $prevsegv = ''; # Does not help?!
905
906 # We set these variables to safe values. We don't want to blindly turn
907 # off warnings, because other packages may still want them.
908 $trace = $signal = $single = 0;    # Uninitialized warning suppression
909                                    # (local $^W cannot help - other packages!).
910
911 # Default to not exiting when program finishes; print the return
912 # value when the 'r' command is used to return from a subroutine.
913 $inhibit_exit = $option{PrintRet} = 1;
914
915 use vars qw($trace_to_depth);
916
917 # Default to 1 so the prompt will display the first line.
918 $trace_to_depth = 1;
919
920 =head1 OPTION PROCESSING
921
922 The debugger's options are actually spread out over the debugger itself and 
923 C<dumpvar.pl>; some of these are variables to be set, while others are 
924 subs to be called with a value. To try to make this a little easier to
925 manage, the debugger uses a few data structures to define what options
926 are legal and how they are to be processed.
927
928 First, the C<@options> array defines the I<names> of all the options that
929 are to be accepted.
930
931 =cut
932
933 @options = qw(
934   CommandSet   HistFile      HistSize
935   hashDepth    arrayDepth    dumpDepth
936   DumpDBFiles  DumpPackages  DumpReused
937   compactDump  veryCompact   quote
938   HighBit      undefPrint    globPrint
939   PrintRet     UsageOnly     frame
940   AutoTrace    TTY           noTTY
941   ReadLine     NonStop       LineInfo
942   maxTraceLen  recallCommand ShellBang
943   pager        tkRunning     ornaments
944   signalLevel  warnLevel     dieLevel
945   inhibit_exit ImmediateStop bareStringify
946   CreateTTY    RemotePort    windowSize
947   DollarCaretP
948 );
949
950 @RememberOnROptions = qw(DollarCaretP);
951
952 =pod
953
954 Second, C<optionVars> lists the variables that each option uses to save its
955 state.
956
957 =cut
958
959 use vars qw(%optionVars);
960
961 %optionVars = (
962     hashDepth     => \$dumpvar::hashDepth,
963     arrayDepth    => \$dumpvar::arrayDepth,
964     CommandSet    => \$CommandSet,
965     DumpDBFiles   => \$dumpvar::dumpDBFiles,
966     DumpPackages  => \$dumpvar::dumpPackages,
967     DumpReused    => \$dumpvar::dumpReused,
968     HighBit       => \$dumpvar::quoteHighBit,
969     undefPrint    => \$dumpvar::printUndef,
970     globPrint     => \$dumpvar::globPrint,
971     UsageOnly     => \$dumpvar::usageOnly,
972     CreateTTY     => \$CreateTTY,
973     bareStringify => \$dumpvar::bareStringify,
974     frame         => \$frame,
975     AutoTrace     => \$trace,
976     inhibit_exit  => \$inhibit_exit,
977     maxTraceLen   => \$maxtrace,
978     ImmediateStop => \$ImmediateStop,
979     RemotePort    => \$remoteport,
980     windowSize    => \$window,
981     HistFile      => \$histfile,
982     HistSize      => \$histsize,
983 );
984
985 =pod
986
987 Third, C<%optionAction> defines the subroutine to be called to process each
988 option.
989
990 =cut 
991
992 use vars qw(%optionAction);
993
994 %optionAction = (
995     compactDump   => \&dumpvar::compactDump,
996     veryCompact   => \&dumpvar::veryCompact,
997     quote         => \&dumpvar::quote,
998     TTY           => \&TTY,
999     noTTY         => \&noTTY,
1000     ReadLine      => \&ReadLine,
1001     NonStop       => \&NonStop,
1002     LineInfo      => \&LineInfo,
1003     recallCommand => \&recallCommand,
1004     ShellBang     => \&shellBang,
1005     pager         => \&pager,
1006     signalLevel   => \&signalLevel,
1007     warnLevel     => \&warnLevel,
1008     dieLevel      => \&dieLevel,
1009     tkRunning     => \&tkRunning,
1010     ornaments     => \&ornaments,
1011     RemotePort    => \&RemotePort,
1012     DollarCaretP  => \&DollarCaretP,
1013 );
1014
1015 =pod
1016
1017 Last, the C<%optionRequire> notes modules that must be C<require>d if an
1018 option is used.
1019
1020 =cut
1021
1022 # Note that this list is not complete: several options not listed here
1023 # actually require that dumpvar.pl be loaded for them to work, but are
1024 # not in the table. A subsequent patch will correct this problem; for
1025 # the moment, we're just recommenting, and we are NOT going to change
1026 # function.
1027 use vars qw(%optionRequire);
1028
1029 %optionRequire = (
1030     compactDump => 'dumpvar.pl',
1031     veryCompact => 'dumpvar.pl',
1032     quote       => 'dumpvar.pl',
1033 );
1034
1035 =pod
1036
1037 There are a number of initialization-related variables which can be set
1038 by putting code to set them in a BEGIN block in the C<PERL5DB> environment
1039 variable. These are:
1040
1041 =over 4
1042
1043 =item C<$rl> - readline control XXX needs more explanation
1044
1045 =item C<$warnLevel> - whether or not debugger takes over warning handling
1046
1047 =item C<$dieLevel> - whether or not debugger takes over die handling
1048
1049 =item C<$signalLevel> - whether or not debugger takes over signal handling
1050
1051 =item C<$pre> - preprompt actions (array reference)
1052
1053 =item C<$post> - postprompt actions (array reference)
1054
1055 =item C<$pretype>
1056
1057 =item C<$CreateTTY> - whether or not to create a new TTY for this debugger
1058
1059 =item C<$CommandSet> - which command set to use (defaults to new, documented set)
1060
1061 =back
1062
1063 =cut
1064
1065 # These guys may be defined in $ENV{PERL5DB} :
1066 $rl          = 1     unless defined $rl;
1067 $warnLevel   = 1     unless defined $warnLevel;
1068 $dieLevel    = 1     unless defined $dieLevel;
1069 $signalLevel = 1     unless defined $signalLevel;
1070 $pre         = []    unless defined $pre;
1071 $post        = []    unless defined $post;
1072 $pretype     = []    unless defined $pretype;
1073 $CreateTTY   = 3     unless defined $CreateTTY;
1074 $CommandSet  = '580' unless defined $CommandSet;
1075
1076 share($rl);
1077 share($warnLevel);
1078 share($dieLevel);
1079 share($signalLevel);
1080 share($pre);
1081 share($post);
1082 share($pretype);
1083 share($rl);
1084 share($CreateTTY);
1085 share($CommandSet);
1086
1087 =pod
1088
1089 The default C<die>, C<warn>, and C<signal> handlers are set up.
1090
1091 =cut
1092
1093 warnLevel($warnLevel);
1094 dieLevel($dieLevel);
1095 signalLevel($signalLevel);
1096
1097 =pod
1098
1099 The pager to be used is needed next. We try to get it from the
1100 environment first.  If it's not defined there, we try to find it in
1101 the Perl C<Config.pm>.  If it's not there, we default to C<more>. We
1102 then call the C<pager()> function to save the pager name.
1103
1104 =cut
1105
1106 # This routine makes sure $pager is set up so that '|' can use it.
1107 pager(
1108
1109     # If PAGER is defined in the environment, use it.
1110     defined $ENV{PAGER}
1111     ? $ENV{PAGER}
1112
1113       # If not, see if Config.pm defines it.
1114     : eval { require Config }
1115       && defined $Config::Config{pager}
1116     ? $Config::Config{pager}
1117
1118       # If not, fall back to 'more'.
1119     : 'more'
1120   )
1121   unless defined $pager;
1122
1123 =pod
1124
1125 We set up the command to be used to access the man pages, the command
1126 recall character (C<!> unless otherwise defined) and the shell escape
1127 character (C<!> unless otherwise defined). Yes, these do conflict, and
1128 neither works in the debugger at the moment.
1129
1130 =cut
1131
1132 setman();
1133
1134 # Set up defaults for command recall and shell escape (note:
1135 # these currently don't work in linemode debugging).
1136 &recallCommand("!") unless defined $prc;
1137 &shellBang("!")     unless defined $psh;
1138
1139 =pod
1140
1141 We then set up the gigantic string containing the debugger help.
1142 We also set the limit on the number of arguments we'll display during a
1143 trace.
1144
1145 =cut
1146
1147 sethelp();
1148
1149 # If we didn't get a default for the length of eval/stack trace args,
1150 # set it here.
1151 $maxtrace = 400 unless defined $maxtrace;
1152
1153 =head2 SETTING UP THE DEBUGGER GREETING
1154
1155 The debugger I<greeting> helps to inform the user how many debuggers are
1156 running, and whether the current debugger is the primary or a child.
1157
1158 If we are the primary, we just hang onto our pid so we'll have it when
1159 or if we start a child debugger. If we are a child, we'll set things up
1160 so we'll have a unique greeting and so the parent will give us our own
1161 TTY later.
1162
1163 We save the current contents of the C<PERLDB_PIDS> environment variable
1164 because we mess around with it. We'll also need to hang onto it because
1165 we'll need it if we restart.
1166
1167 Child debuggers make a label out of the current PID structure recorded in
1168 PERLDB_PIDS plus the new PID. They also mark themselves as not having a TTY
1169 yet so the parent will give them one later via C<resetterm()>.
1170
1171 =cut
1172
1173 # Save the current contents of the environment; we're about to
1174 # much with it. We'll need this if we have to restart.
1175 use vars qw($ini_pids);
1176 $ini_pids = $ENV{PERLDB_PIDS};
1177
1178 use vars qw ($pids $term_pid);
1179
1180 if ( defined $ENV{PERLDB_PIDS} ) {
1181
1182     # We're a child. Make us a label out of the current PID structure
1183     # recorded in PERLDB_PIDS plus our (new) PID. Mark us as not having
1184     # a term yet so the parent will give us one later via resetterm().
1185
1186     my $env_pids = $ENV{PERLDB_PIDS};
1187     $pids = "[$env_pids]";
1188
1189     # Unless we are on OpenVMS, all programs under the DCL shell run under
1190     # the same PID.
1191
1192     if (($^O eq 'VMS') && ($env_pids =~ /\b$$\b/)) {
1193         $term_pid         = $$;
1194     }
1195     else {
1196         $ENV{PERLDB_PIDS} .= "->$$";
1197         $term_pid = -1;
1198     }
1199
1200 } ## end if (defined $ENV{PERLDB_PIDS...
1201 else {
1202
1203     # We're the parent PID. Initialize PERLDB_PID in case we end up with a
1204     # child debugger, and mark us as the parent, so we'll know to set up
1205     # more TTY's is we have to.
1206     $ENV{PERLDB_PIDS} = "$$";
1207     $pids             = "[pid=$$]";
1208     $term_pid         = $$;
1209 }
1210
1211 use vars qw($pidprompt);
1212 $pidprompt = '';
1213
1214 # Sets up $emacs as a synonym for $slave_editor.
1215 use vars qw($slave_editor);
1216 *emacs = $slave_editor if $slave_editor;    # May be used in afterinit()...
1217
1218 =head2 READING THE RC FILE
1219
1220 The debugger will read a file of initialization options if supplied. If    
1221 running interactively, this is C<.perldb>; if not, it's C<perldb.ini>.
1222
1223 =cut      
1224
1225 # As noted, this test really doesn't check accurately that the debugger
1226 # is running at a terminal or not.
1227
1228 my $dev_tty = '/dev/tty';
1229    $dev_tty = 'TT:' if ($^O eq 'VMS');
1230 use vars qw($rcfile);
1231 if ( -e $dev_tty ) {                      # this is the wrong metric!
1232     $rcfile = ".perldb";
1233 }
1234 else {
1235     $rcfile = "perldb.ini";
1236 }
1237
1238 =pod
1239
1240 The debugger does a safety test of the file to be read. It must be owned
1241 either by the current user or root, and must only be writable by the owner.
1242
1243 =cut
1244
1245 # This wraps a safety test around "do" to read and evaluate the init file.
1246 #
1247 # This isn't really safe, because there's a race
1248 # between checking and opening.  The solution is to
1249 # open and fstat the handle, but then you have to read and
1250 # eval the contents.  But then the silly thing gets
1251 # your lexical scope, which is unfortunate at best.
1252 sub safe_do {
1253     my $file = shift;
1254
1255     # Just exactly what part of the word "CORE::" don't you understand?
1256     local $SIG{__WARN__};
1257     local $SIG{__DIE__};
1258
1259     unless ( is_safe_file($file) ) {
1260         CORE::warn <<EO_GRIPE;
1261 perldb: Must not source insecure rcfile $file.
1262         You or the superuser must be the owner, and it must not 
1263         be writable by anyone but its owner.
1264 EO_GRIPE
1265         return;
1266     } ## end unless (is_safe_file($file...
1267
1268     do $file;
1269     CORE::warn("perldb: couldn't parse $file: $@") if $@;
1270 } ## end sub safe_do
1271
1272 # This is the safety test itself.
1273 #
1274 # Verifies that owner is either real user or superuser and that no
1275 # one but owner may write to it.  This function is of limited use
1276 # when called on a path instead of upon a handle, because there are
1277 # no guarantees that filename (by dirent) whose file (by ino) is
1278 # eventually accessed is the same as the one tested.
1279 # Assumes that the file's existence is not in doubt.
1280 sub is_safe_file {
1281     my $path = shift;
1282     stat($path) || return;    # mysteriously vaporized
1283     my ( $dev, $ino, $mode, $nlink, $uid, $gid ) = stat(_);
1284
1285     return 0 if $uid != 0 && $uid != $<;
1286     return 0 if $mode & 022;
1287     return 1;
1288 } ## end sub is_safe_file
1289
1290 # If the rcfile (whichever one we decided was the right one to read)
1291 # exists, we safely do it.
1292 if ( -f $rcfile ) {
1293     safe_do("./$rcfile");
1294 }
1295
1296 # If there isn't one here, try the user's home directory.
1297 elsif ( defined $ENV{HOME} && -f "$ENV{HOME}/$rcfile" ) {
1298     safe_do("$ENV{HOME}/$rcfile");
1299 }
1300
1301 # Else try the login directory.
1302 elsif ( defined $ENV{LOGDIR} && -f "$ENV{LOGDIR}/$rcfile" ) {
1303     safe_do("$ENV{LOGDIR}/$rcfile");
1304 }
1305
1306 # If the PERLDB_OPTS variable has options in it, parse those out next.
1307 if ( defined $ENV{PERLDB_OPTS} ) {
1308     parse_options( $ENV{PERLDB_OPTS} );
1309 }
1310
1311 =pod
1312
1313 The last thing we do during initialization is determine which subroutine is
1314 to be used to obtain a new terminal when a new debugger is started. Right now,
1315 the debugger only handles TCP sockets, X11, OS/2, amd Mac OS X
1316 (darwin).
1317
1318 =cut
1319
1320 # Set up the get_fork_TTY subroutine to be aliased to the proper routine.
1321 # Works if you're running an xterm or xterm-like window, or you're on
1322 # OS/2, or on Mac OS X. This may need some expansion.
1323
1324 if (not defined &get_fork_TTY)       # only if no routine exists
1325 {
1326     if ( defined $remoteport ) {                 
1327                                                  # Expect an inetd-like server
1328         *get_fork_TTY = \&socket_get_fork_TTY;   # to listen to us
1329     }
1330     elsif (defined $ENV{TERM}                    # If we know what kind
1331                                                  # of terminal this is,
1332         and $ENV{TERM} eq 'xterm'                # and it's an xterm,
1333         and defined $ENV{DISPLAY}                # and what display it's on,
1334       )
1335     {
1336         *get_fork_TTY = \&xterm_get_fork_TTY;    # use the xterm version
1337     }
1338     elsif ( $^O eq 'os2' ) {                     # If this is OS/2,
1339         *get_fork_TTY = \&os2_get_fork_TTY;      # use the OS/2 version
1340     }
1341     elsif ( $^O eq 'darwin'                      # If this is Mac OS X
1342             and defined $ENV{TERM_PROGRAM}       # and we're running inside
1343             and $ENV{TERM_PROGRAM}
1344                 eq 'Apple_Terminal'              # Terminal.app
1345             )
1346     {
1347         *get_fork_TTY = \&macosx_get_fork_TTY;   # use the Mac OS X version
1348     }
1349 } ## end if (not defined &get_fork_TTY...
1350
1351 # untaint $^O, which may have been tainted by the last statement.
1352 # see bug [perl #24674]
1353 $^O =~ m/^(.*)\z/;
1354 $^O = $1;
1355
1356 # Here begin the unreadable code.  It needs fixing.
1357
1358 =head2 RESTART PROCESSING
1359
1360 This section handles the restart command. When the C<R> command is invoked, it
1361 tries to capture all of the state it can into environment variables, and
1362 then sets C<PERLDB_RESTART>. When we start executing again, we check to see
1363 if C<PERLDB_RESTART> is there; if so, we reload all the information that
1364 the R command stuffed into the environment variables.
1365
1366   PERLDB_RESTART   - flag only, contains no restart data itself.       
1367   PERLDB_HIST      - command history, if it's available
1368   PERLDB_ON_LOAD   - breakpoints set by the rc file
1369   PERLDB_POSTPONE  - subs that have been loaded/not executed, and have actions
1370   PERLDB_VISITED   - files that had breakpoints
1371   PERLDB_FILE_...  - breakpoints for a file
1372   PERLDB_OPT       - active options
1373   PERLDB_INC       - the original @INC
1374   PERLDB_PRETYPE   - preprompt debugger actions
1375   PERLDB_PRE       - preprompt Perl code
1376   PERLDB_POST      - post-prompt Perl code
1377   PERLDB_TYPEAHEAD - typeahead captured by readline()
1378
1379 We chug through all these variables and plug the values saved in them
1380 back into the appropriate spots in the debugger.
1381
1382 =cut
1383
1384 use vars qw(@hist @truehist %postponed_file @typeahead);
1385
1386 if ( exists $ENV{PERLDB_RESTART} ) {
1387
1388     # We're restarting, so we don't need the flag that says to restart anymore.
1389     delete $ENV{PERLDB_RESTART};
1390
1391     # $restart = 1;
1392     @hist          = get_list('PERLDB_HIST');
1393     %break_on_load = get_list("PERLDB_ON_LOAD");
1394     %postponed     = get_list("PERLDB_POSTPONE");
1395
1396         share(@hist);
1397         share(@truehist);
1398         share(%break_on_load);
1399         share(%postponed);
1400
1401     # restore breakpoints/actions
1402     my @had_breakpoints = get_list("PERLDB_VISITED");
1403     for my $file_idx ( 0 .. $#had_breakpoints ) {
1404         my $filename = $had_breakpoints[$file_idx];
1405         my %pf = get_list("PERLDB_FILE_$file_idx");
1406         $postponed_file{ $filename } = \%pf if %pf;
1407         my @lines = sort {$a <=> $b} keys(%pf);
1408         my @enabled_statuses = get_list("PERLDB_FILE_ENABLED_$file_idx");
1409         for my $line_idx (0 .. $#lines) {
1410             _set_breakpoint_enabled_status(
1411                 $filename,
1412                 $lines[$line_idx],
1413                 ($enabled_statuses[$line_idx] ? 1 : ''),
1414             );
1415         }
1416     }
1417
1418     # restore options
1419     my %opt = get_list("PERLDB_OPT");
1420     my ( $opt, $val );
1421     while ( ( $opt, $val ) = each %opt ) {
1422         $val =~ s/[\\\']/\\$1/g;
1423         parse_options("$opt'$val'");
1424     }
1425
1426     # restore original @INC
1427     @INC     = get_list("PERLDB_INC");
1428     @ini_INC = @INC;
1429
1430     # return pre/postprompt actions and typeahead buffer
1431     $pretype   = [ get_list("PERLDB_PRETYPE") ];
1432     $pre       = [ get_list("PERLDB_PRE") ];
1433     $post      = [ get_list("PERLDB_POST") ];
1434     @typeahead = get_list( "PERLDB_TYPEAHEAD", @typeahead );
1435 } ## end if (exists $ENV{PERLDB_RESTART...
1436
1437 =head2 SETTING UP THE TERMINAL
1438
1439 Now, we'll decide how the debugger is going to interact with the user.
1440 If there's no TTY, we set the debugger to run non-stop; there's not going
1441 to be anyone there to enter commands.
1442
1443 =cut
1444
1445 use vars qw($notty $runnonstop $console $tty $LINEINFO);
1446 use vars qw($lineinfo $doccmd);
1447
1448 if ($notty) {
1449     $runnonstop = 1;
1450         share($runnonstop);
1451 }
1452
1453 =pod
1454
1455 If there is a TTY, we have to determine who it belongs to before we can
1456 proceed. If this is a slave editor or graphical debugger (denoted by
1457 the first command-line switch being '-emacs'), we shift this off and
1458 set C<$rl> to 0 (XXX ostensibly to do straight reads).
1459
1460 =cut
1461
1462 else {
1463
1464     # Is Perl being run from a slave editor or graphical debugger?
1465     # If so, don't use readline, and set $slave_editor = 1.
1466     $slave_editor =
1467       ( ( defined $main::ARGV[0] ) and ( $main::ARGV[0] eq '-emacs' ) );
1468     $rl = 0, shift(@main::ARGV) if $slave_editor;
1469
1470     #require Term::ReadLine;
1471
1472 =pod
1473
1474 We then determine what the console should be on various systems:
1475
1476 =over 4
1477
1478 =item * Cygwin - We use C<stdin> instead of a separate device.
1479
1480 =cut
1481
1482     if ( $^O eq 'cygwin' ) {
1483
1484         # /dev/tty is binary. use stdin for textmode
1485         undef $console;
1486     }
1487
1488 =item * Unix - use C</dev/tty>.
1489
1490 =cut
1491
1492     elsif ( -e "/dev/tty" ) {
1493         $console = "/dev/tty";
1494     }
1495
1496 =item * Windows or MSDOS - use C<con>.
1497
1498 =cut
1499
1500     elsif ( $^O eq 'dos' or -e "con" or $^O eq 'MSWin32' ) {
1501         $console = "con";
1502     }
1503
1504 =item * VMS - use C<sys$command>.
1505
1506 =cut
1507
1508     else {
1509
1510         # everything else is ...
1511         $console = "sys\$command";
1512     }
1513
1514 =pod
1515
1516 =back
1517
1518 Several other systems don't use a specific console. We C<undef $console>
1519 for those (Windows using a slave editor/graphical debugger, NetWare, OS/2
1520 with a slave editor, Epoc).
1521
1522 =cut
1523
1524     if ( ( $^O eq 'MSWin32' ) and ( $slave_editor or defined $ENV{EMACS} ) ) {
1525
1526         # /dev/tty is binary. use stdin for textmode
1527         $console = undef;
1528     }
1529
1530     if ( $^O eq 'NetWare' ) {
1531
1532         # /dev/tty is binary. use stdin for textmode
1533         $console = undef;
1534     }
1535
1536     # In OS/2, we need to use STDIN to get textmode too, even though
1537     # it pretty much looks like Unix otherwise.
1538     if ( defined $ENV{OS2_SHELL} and ( $slave_editor or $ENV{WINDOWID} ) )
1539     {    # In OS/2
1540         $console = undef;
1541     }
1542
1543     # EPOC also falls into the 'got to use STDIN' camp.
1544     if ( $^O eq 'epoc' ) {
1545         $console = undef;
1546     }
1547
1548 =pod
1549
1550 If there is a TTY hanging around from a parent, we use that as the console.
1551
1552 =cut
1553
1554     $console = $tty if defined $tty;
1555
1556 =head2 SOCKET HANDLING   
1557
1558 The debugger is capable of opening a socket and carrying out a debugging
1559 session over the socket.
1560
1561 If C<RemotePort> was defined in the options, the debugger assumes that it
1562 should try to start a debugging session on that port. It builds the socket
1563 and then tries to connect the input and output filehandles to it.
1564
1565 =cut
1566
1567     # Handle socket stuff.
1568
1569     if ( defined $remoteport ) {
1570
1571         # If RemotePort was defined in the options, connect input and output
1572         # to the socket.
1573         $IN = $OUT = connect_remoteport();
1574     } ## end if (defined $remoteport)
1575
1576 =pod
1577
1578 If no C<RemotePort> was defined, and we want to create a TTY on startup,
1579 this is probably a situation where multiple debuggers are running (for example,
1580 a backticked command that starts up another debugger). We create a new IN and
1581 OUT filehandle, and do the necessary mojo to create a new TTY if we know how
1582 and if we can.
1583
1584 =cut
1585
1586     # Non-socket.
1587     else {
1588
1589         # Two debuggers running (probably a system or a backtick that invokes
1590         # the debugger itself under the running one). create a new IN and OUT
1591         # filehandle, and do the necessary mojo to create a new tty if we
1592         # know how, and we can.
1593         create_IN_OUT(4) if $CreateTTY & 4;
1594         if ($console) {
1595
1596             # If we have a console, check to see if there are separate ins and
1597             # outs to open. (They are assumed identical if not.)
1598
1599             my ( $i, $o ) = split /,/, $console;
1600             $o = $i unless defined $o;
1601
1602             # read/write on in, or just read, or read on STDIN.
1603             open( IN,      "+<$i" )
1604               || open( IN, "<$i" )
1605               || open( IN, "<&STDIN" );
1606
1607             # read/write/create/clobber out, or write/create/clobber out,
1608             # or merge with STDERR, or merge with STDOUT.
1609                  open( OUT, "+>$o" )
1610               || open( OUT, ">$o" )
1611               || open( OUT, ">&STDERR" )
1612               || open( OUT, ">&STDOUT" );    # so we don't dongle stdout
1613
1614         } ## end if ($console)
1615         elsif ( not defined $console ) {
1616
1617             # No console. Open STDIN.
1618             open( IN, "<&STDIN" );
1619
1620             # merge with STDERR, or with STDOUT.
1621             open( OUT,      ">&STDERR" )
1622               || open( OUT, ">&STDOUT" );    # so we don't dongle stdout
1623             $console = 'STDIN/OUT';
1624         } ## end elsif (not defined $console)
1625
1626         # Keep copies of the filehandles so that when the pager runs, it
1627         # can close standard input without clobbering ours.
1628         $IN = \*IN, $OUT = \*OUT if $console or not defined $console;
1629     } ## end elsif (from if(defined $remoteport))
1630
1631     # Unbuffer DB::OUT. We need to see responses right away.
1632     my $previous = select($OUT);
1633     $| = 1;                                  # for DB::OUT
1634     select($previous);
1635
1636     # Line info goes to debugger output unless pointed elsewhere.
1637     # Pointing elsewhere makes it possible for slave editors to
1638     # keep track of file and position. We have both a filehandle
1639     # and a I/O description to keep track of.
1640     $LINEINFO = $OUT     unless defined $LINEINFO;
1641     $lineinfo = $console unless defined $lineinfo;
1642         # share($LINEINFO); # <- unable to share globs
1643         share($lineinfo);   # 
1644
1645 =pod
1646
1647 To finish initialization, we show the debugger greeting,
1648 and then call the C<afterinit()> subroutine if there is one.
1649
1650 =cut
1651
1652     # Show the debugger greeting.
1653     $header =~ s/.Header: ([^,]+),v(\s+\S+\s+\S+).*$/$1$2/;
1654     unless ($runnonstop) {
1655         local $\ = '';
1656         local $, = '';
1657         if ( $term_pid eq '-1' ) {
1658             print $OUT "\nDaughter DB session started...\n";
1659         }
1660         else {
1661             print $OUT "\nLoading DB routines from $header\n";
1662             print $OUT (
1663                 "Editor support ",
1664                 $slave_editor ? "enabled" : "available", ".\n"
1665             );
1666             print $OUT
1667 "\nEnter h or 'h h' for help, or '$doccmd perldebug' for more help.\n\n";
1668         } ## end else [ if ($term_pid eq '-1')
1669     } ## end unless ($runnonstop)
1670 } ## end else [ if ($notty)
1671
1672 # XXX This looks like a bug to me.
1673 # Why copy to @ARGS and then futz with @args?
1674 @ARGS = @ARGV;
1675 # for (@args) {
1676     # Make sure backslashes before single quotes are stripped out, and
1677     # keep args unless they are numeric (XXX why?)
1678     # s/\'/\\\'/g;                      # removed while not justified understandably
1679     # s/(.*)/'$1'/ unless /^-?[\d.]+$/; # ditto
1680 # }
1681
1682 # If there was an afterinit() sub defined, call it. It will get
1683 # executed in our scope, so it can fiddle with debugger globals.
1684 if ( defined &afterinit ) {    # May be defined in $rcfile
1685     &afterinit();
1686 }
1687
1688 # Inform us about "Stack dump during die enabled ..." in dieLevel().
1689 use vars qw($I_m_init);
1690
1691 $I_m_init = 1;
1692
1693 ############################################################ Subroutines
1694
1695 =head1 SUBROUTINES
1696
1697 =head2 DB
1698
1699 This gigantic subroutine is the heart of the debugger. Called before every
1700 statement, its job is to determine if a breakpoint has been reached, and
1701 stop if so; read commands from the user, parse them, and execute
1702 them, and then send execution off to the next statement.
1703
1704 Note that the order in which the commands are processed is very important;
1705 some commands earlier in the loop will actually alter the C<$cmd> variable
1706 to create other commands to be executed later. This is all highly I<optimized>
1707 but can be confusing. Check the comments for each C<$cmd ... && do {}> to
1708 see what's happening in any given command.
1709
1710 =cut
1711
1712 use vars qw(
1713     $action
1714     %alias
1715     $cmd
1716     $doret
1717     $fall_off_end
1718     $file
1719     $filename_ini
1720     $finished
1721     %had_breakpoints
1722     $incr
1723     $laststep
1724     $level
1725     $max
1726     @old_watch
1727     $package
1728     $rc
1729     $sh
1730     @stack
1731     $stack_depth
1732     @to_watch
1733     $try
1734     $end
1735 );
1736
1737 sub DB {
1738
1739     # lock the debugger and get the thread id for the prompt
1740         lock($DBGR);
1741         my $tid;
1742         my $position;
1743         my ($prefix, $after, $infix);
1744         my $pat;
1745
1746         if ($ENV{PERL5DB_THREADED}) {
1747                 $tid = eval { "[".threads->tid."]" };
1748         }
1749
1750     # Check for whether we should be running continuously or not.
1751     # _After_ the perl program is compiled, $single is set to 1:
1752     if ( $single and not $second_time++ ) {
1753
1754         # Options say run non-stop. Run until we get an interrupt.
1755         if ($runnonstop) {    # Disable until signal
1756                 # If there's any call stack in place, turn off single
1757                 # stepping into subs throughout the stack.
1758             for my $i (0 .. $stack_depth) {
1759                 $stack[ $i++ ] &= ~1;
1760             }
1761
1762             # And we are now no longer in single-step mode.
1763             $single = 0;
1764
1765             # If we simply returned at this point, we wouldn't get
1766             # the trace info. Fall on through.
1767             # return;
1768         } ## end if ($runnonstop)
1769
1770         elsif ($ImmediateStop) {
1771
1772             # We are supposed to stop here; XXX probably a break.
1773             $ImmediateStop = 0;    # We've processed it; turn it off
1774             $signal        = 1;    # Simulate an interrupt to force
1775                                    # us into the command loop
1776         }
1777     } ## end if ($single and not $second_time...
1778
1779     # If we're in single-step mode, or an interrupt (real or fake)
1780     # has occurred, turn off non-stop mode.
1781     $runnonstop = 0 if $single or $signal;
1782
1783     # Preserve current values of $@, $!, $^E, $,, $/, $\, $^W.
1784     # The code being debugged may have altered them.
1785     &save;
1786
1787     # Since DB::DB gets called after every line, we can use caller() to
1788     # figure out where we last were executing. Sneaky, eh? This works because
1789     # caller is returning all the extra information when called from the
1790     # debugger.
1791     local ( $package, $filename, $line ) = caller;
1792     $filename_ini = $filename;
1793
1794     # set up the context for DB::eval, so it can properly execute
1795     # code on behalf of the user. We add the package in so that the
1796     # code is eval'ed in the proper package (not in the debugger!).
1797     local $usercontext = _calc_usercontext($package);
1798
1799     # Create an alias to the active file magical array to simplify
1800     # the code here.
1801     local (*dbline) = $main::{ '_<' . $filename };
1802
1803     # Last line in the program.
1804     $max = $#dbline;
1805
1806     # if we have something here, see if we should break.
1807     if ( $dbline{$line}
1808         && _is_breakpoint_enabled($filename, $line)
1809         && ( my ( $stop, $action ) = split( /\0/, $dbline{$line} ) ) )
1810     {
1811
1812         # Stop if the stop criterion says to just stop.
1813         if ( $stop eq '1' ) {
1814             $signal |= 1;
1815         }
1816
1817         # It's a conditional stop; eval it in the user's context and
1818         # see if we should stop. If so, remove the one-time sigil.
1819         elsif ($stop) {
1820             $evalarg = "\$DB::signal |= 1 if do {$stop}";
1821             &eval;
1822             # If the breakpoint is temporary, then delete its enabled status.
1823             if ($dbline{$line} =~ s/;9($|\0)/$1/) {
1824                 _cancel_breakpoint_temp_enabled_status($filename, $line);
1825             }
1826         }
1827     } ## end if ($dbline{$line} && ...
1828
1829     # Preserve the current stop-or-not, and see if any of the W
1830     # (watch expressions) has changed.
1831     my $was_signal = $signal;
1832
1833     # If we have any watch expressions ...
1834     if ( $trace & 2 ) {
1835         for my $n (0 .. $#to_watch) {
1836             $evalarg = $to_watch[$n];
1837             local $onetimeDump;    # Tell DB::eval() to not output results
1838
1839             # Fix context DB::eval() wants to return an array, but
1840             # we need a scalar here.
1841             my ($val) = join( "', '", &eval );
1842             $val = ( ( defined $val ) ? "'$val'" : 'undef' );
1843
1844             # Did it change?
1845             if ( $val ne $old_watch[$n] ) {
1846
1847                 # Yep! Show the difference, and fake an interrupt.
1848                 $signal = 1;
1849                 print $OUT <<EOP;
1850 Watchpoint $n:\t$to_watch[$n] changed:
1851     old value:\t$old_watch[$n]
1852     new value:\t$val
1853 EOP
1854                 $old_watch[$n] = $val;
1855             } ## end if ($val ne $old_watch...
1856         } ## end for my $n (0 ..
1857     } ## end if ($trace & 2)
1858
1859 =head2 C<watchfunction()>
1860
1861 C<watchfunction()> is a function that can be defined by the user; it is a
1862 function which will be run on each entry to C<DB::DB>; it gets the 
1863 current package, filename, and line as its parameters.
1864
1865 The watchfunction can do anything it likes; it is executing in the 
1866 debugger's context, so it has access to all of the debugger's internal
1867 data structures and functions.
1868
1869 C<watchfunction()> can control the debugger's actions. Any of the following
1870 will cause the debugger to return control to the user's program after
1871 C<watchfunction()> executes:
1872
1873 =over 4 
1874
1875 =item *
1876
1877 Returning a false value from the C<watchfunction()> itself.
1878
1879 =item *
1880
1881 Altering C<$single> to a false value.
1882
1883 =item *
1884
1885 Altering C<$signal> to a false value.
1886
1887 =item *
1888
1889 Turning off the C<4> bit in C<$trace> (this also disables the
1890 check for C<watchfunction()>. This can be done with
1891
1892     $trace &= ~4;
1893
1894 =back
1895
1896 =cut
1897
1898     # If there's a user-defined DB::watchfunction, call it with the
1899     # current package, filename, and line. The function executes in
1900     # the DB:: package.
1901     if ( $trace & 4 ) {    # User-installed watch
1902         return
1903           if watchfunction( $package, $filename, $line )
1904           and not $single
1905           and not $was_signal
1906           and not( $trace & ~4 );
1907     } ## end if ($trace & 4)
1908
1909     # Pick up any alteration to $signal in the watchfunction, and
1910     # turn off the signal now.
1911     $was_signal = $signal;
1912     $signal     = 0;
1913
1914 =head2 GETTING READY TO EXECUTE COMMANDS
1915
1916 The debugger decides to take control if single-step mode is on, the
1917 C<t> command was entered, or the user generated a signal. If the program
1918 has fallen off the end, we set things up so that entering further commands
1919 won't cause trouble, and we say that the program is over.
1920
1921 =cut
1922
1923     # Make sure that we always print if asked for explicitly regardless
1924     # of $trace_to_depth .
1925     my $explicit_stop = ($single || $was_signal);
1926
1927     # Check to see if we should grab control ($single true,
1928     # trace set appropriately, or we got a signal).
1929     if ( $explicit_stop || ( $trace & 1 ) ) {
1930
1931         # Yes, grab control.
1932         if ($slave_editor) {
1933
1934             # Tell the editor to update its position.
1935             $position = "\032\032$filename:$line:0\n";
1936             print_lineinfo($position);
1937         }
1938
1939 =pod
1940
1941 Special check: if we're in package C<DB::fake>, we've gone through the 
1942 C<END> block at least once. We set up everything so that we can continue
1943 to enter commands and have a valid context to be in.
1944
1945 =cut
1946
1947         elsif ( $package eq 'DB::fake' ) {
1948
1949             # Fallen off the end already.
1950             $term || &setterm;
1951             print_help(<<EOP);
1952 Debugged program terminated.  Use B<q> to quit or B<R> to restart,
1953   use B<o> I<inhibit_exit> to avoid stopping after program termination,
1954   B<h q>, B<h R> or B<h o> to get additional info.  
1955 EOP
1956
1957             # Set the DB::eval context appropriately.
1958             $package     = 'main';
1959             $usercontext = _calc_usercontext($package);
1960         } ## end elsif ($package eq 'DB::fake')
1961
1962 =pod
1963
1964 If the program hasn't finished executing, we scan forward to the
1965 next executable line, print that out, build the prompt from the file and line
1966 number information, and print that.   
1967
1968 =cut
1969
1970         else {
1971
1972
1973             # Still somewhere in the midst of execution. Set up the
1974             #  debugger prompt.
1975             $sub =~ s/\'/::/;    # Swap Perl 4 package separators (') to
1976                                  # Perl 5 ones (sorry, we don't print Klingon
1977                                  #module names)
1978
1979             $prefix = $sub =~ /::/ ? "" : ($package . '::');
1980             $prefix .= "$sub($filename:";
1981             $after = ( $dbline[$line] =~ /\n$/ ? '' : "\n" );
1982
1983             # Break up the prompt if it's really long.
1984             if ( length($prefix) > 30 ) {
1985                 $position = "$prefix$line):\n$line:\t$dbline[$line]$after";
1986                 $prefix   = "";
1987                 $infix    = ":\t";
1988             }
1989             else {
1990                 $infix    = "):\t";
1991                 $position = "$prefix$line$infix$dbline[$line]$after";
1992             }
1993
1994             # Print current line info, indenting if necessary.
1995             if ($frame) {
1996                 print_lineinfo( ' ' x $stack_depth,
1997                     "$line:\t$dbline[$line]$after" );
1998             }
1999             else {
2000                 depth_print_lineinfo($explicit_stop, $position);
2001             }
2002
2003             # Scan forward, stopping at either the end or the next
2004             # unbreakable line.
2005             {
2006                 my $i = $line + 1;
2007                 while ( $i <= $max && $dbline[$i] == 0 )
2008             {    #{ vi
2009
2010                 # Drop out on null statements, block closers, and comments.
2011                 last if $dbline[$i] =~ /^\s*[\;\}\#\n]/;
2012
2013                 # Drop out if the user interrupted us.
2014                 last if $signal;
2015
2016                 # Append a newline if the line doesn't have one. Can happen
2017                 # in eval'ed text, for instance.
2018                 $after = ( $dbline[$i] =~ /\n$/ ? '' : "\n" );
2019
2020                 # Next executable line.
2021                 my $incr_pos = "$prefix$i$infix$dbline[$i]$after";
2022                 $position .= $incr_pos;
2023                 if ($frame) {
2024
2025                     # Print it indented if tracing is on.
2026                     print_lineinfo( ' ' x $stack_depth,
2027                         "$i:\t$dbline[$i]$after" );
2028                 }
2029                 else {
2030                     depth_print_lineinfo($explicit_stop, $incr_pos);
2031                 }
2032             }
2033             continue
2034             {
2035                 $i++;
2036             }## end while ($i = $line + 1 ; $i...
2037             }
2038         } ## end else [ if ($slave_editor)
2039     } ## end if ($single || ($trace...
2040
2041 =pod
2042
2043 If there's an action to be executed for the line we stopped at, execute it.
2044 If there are any preprompt actions, execute those as well.      
2045
2046 =cut
2047
2048     # If there's an action, do it now.
2049     $evalarg = $action, &eval if $action;
2050
2051     # Are we nested another level (e.g., did we evaluate a function
2052     # that had a breakpoint in it at the debugger prompt)?
2053     if ( $single || $was_signal ) {
2054
2055         # Yes, go down a level.
2056         local $level = $level + 1;
2057
2058         # Do any pre-prompt actions.
2059         foreach $evalarg (@$pre) {
2060             &eval;
2061         }
2062
2063         # Complain about too much recursion if we passed the limit.
2064         print $OUT $stack_depth . " levels deep in subroutine calls!\n"
2065           if $single & 4;
2066
2067         # The line we're currently on. Set $incr to -1 to stay here
2068         # until we get a command that tells us to advance.
2069         $start = $line;
2070         $incr  = -1;      # for backward motion.
2071
2072         # Tack preprompt debugger actions ahead of any actual input.
2073         @typeahead = ( @$pretype, @typeahead );
2074
2075 =head2 WHERE ARE WE?
2076
2077 XXX Relocate this section?
2078
2079 The debugger normally shows the line corresponding to the current line of
2080 execution. Sometimes, though, we want to see the next line, or to move elsewhere
2081 in the file. This is done via the C<$incr>, C<$start>, and C<$max> variables.
2082
2083 C<$incr> controls by how many lines the I<current> line should move forward
2084 after a command is executed. If set to -1, this indicates that the I<current>
2085 line shouldn't change.
2086
2087 C<$start> is the I<current> line. It is used for things like knowing where to
2088 move forwards or backwards from when doing an C<L> or C<-> command.
2089
2090 C<$max> tells the debugger where the last line of the current file is. It's
2091 used to terminate loops most often.
2092
2093 =head2 THE COMMAND LOOP
2094
2095 Most of C<DB::DB> is actually a command parsing and dispatch loop. It comes
2096 in two parts:
2097
2098 =over 4
2099
2100 =item *
2101
2102 The outer part of the loop, starting at the C<CMD> label. This loop
2103 reads a command and then executes it.
2104
2105 =item *
2106
2107 The inner part of the loop, starting at the C<PIPE> label. This part
2108 is wholly contained inside the C<CMD> block and only executes a command.
2109 Used to handle commands running inside a pager.
2110
2111 =back
2112
2113 So why have two labels to restart the loop? Because sometimes, it's easier to
2114 have a command I<generate> another command and then re-execute the loop to do
2115 the new command. This is faster, but perhaps a bit more convoluted.
2116
2117 =cut
2118
2119         # The big command dispatch loop. It keeps running until the
2120         # user yields up control again.
2121         #
2122         # If we have a terminal for input, and we get something back
2123         # from readline(), keep on processing.
2124         my $piped;
2125         my $selected;
2126
2127       CMD:
2128         while (
2129
2130             # We have a terminal, or can get one ...
2131             ( $term || &setterm ),
2132
2133             # ... and it belogs to this PID or we get one for this PID ...
2134             ( $term_pid == $$ or resetterm(1) ),
2135
2136             # ... and we got a line of command input ...
2137             defined(
2138                 $cmd = &readline(
2139                         "$pidprompt $tid DB"
2140                       . ( '<' x $level )
2141                       . ( $#hist + 1 )
2142                       . ( '>' x $level ) . " "
2143                 )
2144             )
2145           )
2146         {
2147
2148                         share($cmd);
2149             # ... try to execute the input as debugger commands.
2150
2151             # Don't stop running.
2152             $single = 0;
2153
2154             # No signal is active.
2155             $signal = 0;
2156
2157             # Handle continued commands (ending with \):
2158             $cmd =~ s/\\$/\n/ && do {
2159                 $cmd .= &readline("  cont: ");
2160                 redo CMD;
2161             };
2162
2163 =head4 The null command
2164
2165 A newline entered by itself means I<re-execute the last command>. We grab the
2166 command out of C<$laststep> (where it was recorded previously), and copy it
2167 back into C<$cmd> to be executed below. If there wasn't any previous command,
2168 we'll do nothing below (no command will match). If there was, we also save it
2169 in the command history and fall through to allow the command parsing to pick
2170 it up.
2171
2172 =cut
2173
2174             # Empty input means repeat the last command.
2175             $cmd =~ /^$/ && ( $cmd = $laststep );
2176             chomp($cmd);    # get rid of the annoying extra newline
2177             push( @hist, $cmd ) if length($cmd) > 1;
2178             push( @truehist, $cmd );
2179                         share(@hist);
2180                         share(@truehist);
2181
2182             # This is a restart point for commands that didn't arrive
2183             # via direct user input. It allows us to 'redo PIPE' to
2184             # re-execute command processing without reading a new command.
2185           PIPE: {
2186                 $cmd =~ s/^\s+//s;    # trim annoying leading whitespace
2187                 $cmd =~ s/\s+$//s;    # trim annoying trailing whitespace
2188                 my ($i) = split( /\s+/, $cmd );
2189
2190 =head3 COMMAND ALIASES
2191
2192 The debugger can create aliases for commands (these are stored in the
2193 C<%alias> hash). Before a command is executed, the command loop looks it up
2194 in the alias hash and substitutes the contents of the alias for the command,
2195 completely replacing it.
2196
2197 =cut
2198
2199                 # See if there's an alias for the command, and set it up if so.
2200                 if ( $alias{$i} ) {
2201
2202                     # Squelch signal handling; we want to keep control here
2203                     # if something goes loco during the alias eval.
2204                     local $SIG{__DIE__};
2205                     local $SIG{__WARN__};
2206
2207                     # This is a command, so we eval it in the DEBUGGER's
2208                     # scope! Otherwise, we can't see the special debugger
2209                     # variables, or get to the debugger's subs. (Well, we
2210                     # _could_, but why make it even more complicated?)
2211                     eval "\$cmd =~ $alias{$i}";
2212                     if ($@) {
2213                         local $\ = '';
2214                         print $OUT "Couldn't evaluate '$i' alias: $@";
2215                         next CMD;
2216                     }
2217                 } ## end if ($alias{$i})
2218
2219 =head3 MAIN-LINE COMMANDS
2220
2221 All of these commands work up to and after the program being debugged has
2222 terminated. 
2223
2224 =head4 C<q> - quit
2225
2226 Quit the debugger. This entails setting the C<$fall_off_end> flag, so we don't 
2227 try to execute further, cleaning any restart-related stuff out of the
2228 environment, and executing with the last value of C<$?>.
2229
2230 =cut
2231
2232                 $cmd =~ /^q$/ && do {
2233                     $fall_off_end = 1;
2234                     clean_ENV();
2235                     exit $?;
2236                 };
2237
2238 =head4 C<t> - trace [n]
2239
2240 Turn tracing on or off. Inverts the appropriate bit in C<$trace> (q.v.).
2241 If level is specified, set C<$trace_to_depth>.
2242
2243 =cut
2244
2245                 $cmd =~ /^t(?:\s+(\d+))?$/ && do {
2246                     my $levels = $1;
2247                     $trace ^= 1;
2248                     local $\ = '';
2249                     $trace_to_depth = $levels ? $stack_depth + $levels : 1E9;
2250                     print $OUT "Trace = "
2251                       . ( ( $trace & 1 )
2252                       ? ( $levels ? "on (to level $trace_to_depth)" : "on" )
2253                       : "off" ) . "\n";
2254                     next CMD;
2255                 };
2256
2257 =head4 C<S> - list subroutines matching/not matching a pattern
2258
2259 Walks through C<%sub>, checking to see whether or not to print the name.
2260
2261 =cut
2262
2263                 $cmd =~ /^S(\s+(!)?(.+))?$/ && do {
2264
2265                     my $Srev     = defined $2;     # Reverse scan?
2266                     my $Spatt    = $3;             # The pattern (if any) to use.
2267                     my $Snocheck = !defined $1;    # No args - print all subs.
2268
2269                     # Need to make these sane here.
2270                     local $\ = '';
2271                     local $, = '';
2272
2273                     # Search through the debugger's magical hash of subs.
2274                     # If $nocheck is true, just print the sub name.
2275                     # Otherwise, check it against the pattern. We then use
2276                     # the XOR trick to reverse the condition as required.
2277                     foreach $subname ( sort( keys %sub ) ) {
2278                         if ( $Snocheck or $Srev ^ ( $subname =~ /$Spatt/ ) ) {
2279                             print $OUT $subname, "\n";
2280                         }
2281                     }
2282                     next CMD;
2283                 };
2284
2285 =head4 C<X> - list variables in current package
2286
2287 Since the C<V> command actually processes this, just change this to the 
2288 appropriate C<V> command and fall through.
2289
2290 =cut
2291
2292                 $cmd =~ s/^X\b/V $package/;
2293
2294 =head4 C<V> - list variables
2295
2296 Uses C<dumpvar.pl> to dump out the current values for selected variables. 
2297
2298 =cut
2299
2300                 # Bare V commands get the currently-being-debugged package
2301                 # added.
2302                 $cmd =~ /^V$/ && do {
2303                     $cmd = "V $package";
2304                 };
2305
2306                 # V - show variables in package.
2307                 $cmd =~ /^V\b\s*(\S+)\s*(.*)/ && do {
2308
2309                     # Save the currently selected filehandle and
2310                     # force output to debugger's filehandle (dumpvar
2311                     # just does "print" for output).
2312                     my $savout = select($OUT);
2313
2314                     # Grab package name and variables to dump.
2315                     $packname = $1;
2316                     my @vars     = split( ' ', $2 );
2317
2318                     # If main::dumpvar isn't here, get it.
2319                     do 'dumpvar.pl' || die $@ unless defined &main::dumpvar;
2320                     if ( defined &main::dumpvar ) {
2321
2322                         # We got it. Turn off subroutine entry/exit messages
2323                         # for the moment, along with return values.
2324                         local $frame = 0;
2325                         local $doret = -2;
2326
2327                         # must detect sigpipe failures  - not catching
2328                         # then will cause the debugger to die.
2329                         eval {
2330                             &main::dumpvar(
2331                                 $packname,
2332                                 defined $option{dumpDepth}
2333                                 ? $option{dumpDepth}
2334                                 : -1,    # assume -1 unless specified
2335                                 @vars
2336                             );
2337                         };
2338
2339                         # The die doesn't need to include the $@, because
2340                         # it will automatically get propagated for us.
2341                         if ($@) {
2342                             die unless $@ =~ /dumpvar print failed/;
2343                         }
2344                     } ## end if (defined &main::dumpvar)
2345                     else {
2346
2347                         # Couldn't load dumpvar.
2348                         print $OUT "dumpvar.pl not available.\n";
2349                     }
2350
2351                     # Restore the output filehandle, and go round again.
2352                     select($savout);
2353                     next CMD;
2354                 };
2355
2356 =head4 C<x> - evaluate and print an expression
2357
2358 Hands the expression off to C<DB::eval>, setting it up to print the value
2359 via C<dumpvar.pl> instead of just printing it directly.
2360
2361 =cut
2362
2363                 $cmd =~ s/^x\b/ / && do {    # Remainder gets done by DB::eval()
2364                     $onetimeDump = 'dump';    # main::dumpvar shows the output
2365
2366                     # handle special  "x 3 blah" syntax XXX propagate
2367                     # doc back to special variables.
2368                     if ( $cmd =~ s/^\s*(\d+)(?=\s)/ / ) {
2369                         $onetimedumpDepth = $1;
2370                     }
2371                 };
2372
2373 =head4 C<m> - print methods
2374
2375 Just uses C<DB::methods> to determine what methods are available.
2376
2377 =cut
2378
2379                 $cmd =~ s/^m\s+([\w:]+)\s*$/ / && do {
2380                     methods($1);
2381                     next CMD;
2382                 };
2383
2384                 # m expr - set up DB::eval to do the work
2385                 $cmd =~ s/^m\b/ / && do {    # Rest gets done by DB::eval()
2386                     $onetimeDump = 'methods';   #  method output gets used there
2387                 };
2388
2389 =head4 C<f> - switch files
2390
2391 =cut
2392
2393                 $cmd =~ /^f\b\s*(.*)/ && do {
2394                     $file = $1;
2395                     $file =~ s/\s+$//;
2396
2397                     # help for no arguments (old-style was return from sub).
2398                     if ( !$file ) {
2399                         print $OUT
2400                           "The old f command is now the r command.\n";    # hint
2401                         print $OUT "The new f command switches filenames.\n";
2402                         next CMD;
2403                     } ## end if (!$file)
2404
2405                     # if not in magic file list, try a close match.
2406                     if ( !defined $main::{ '_<' . $file } ) {
2407                         if ( ($try) = grep( m#^_<.*$file#, keys %main:: ) ) {
2408                             {
2409                                 $try = substr( $try, 2 );
2410                                 print $OUT "Choosing $try matching '$file':\n";
2411                                 $file = $try;
2412                             }
2413                         } ## end if (($try) = grep(m#^_<.*$file#...
2414                     } ## end if (!defined $main::{ ...
2415
2416                     # If not successfully switched now, we failed.
2417                     if ( !defined $main::{ '_<' . $file } ) {
2418                         print $OUT "No file matching '$file' is loaded.\n";
2419                         next CMD;
2420                     }
2421
2422                     # We switched, so switch the debugger internals around.
2423                     elsif ( $file ne $filename ) {
2424                         *dbline   = $main::{ '_<' . $file };
2425                         $max      = $#dbline;
2426                         $filename = $file;
2427                         $start    = 1;
2428                         $cmd      = "l";
2429                     } ## end elsif ($file ne $filename)
2430
2431                     # We didn't switch; say we didn't.
2432                     else {
2433                         print $OUT "Already in $file.\n";
2434                         next CMD;
2435                     }
2436                 };
2437
2438 =head4 C<.> - return to last-executed line.
2439
2440 We set C<$incr> to -1 to indicate that the debugger shouldn't move ahead,
2441 and then we look up the line in the magical C<%dbline> hash.
2442
2443 =cut
2444
2445                 # . command.
2446                 $cmd =~ /^\.$/ && do {
2447                     $incr = -1;    # stay at current line
2448
2449                     # Reset everything to the old location.
2450                     $start    = $line;
2451                     $filename = $filename_ini;
2452                     *dbline   = $main::{ '_<' . $filename };
2453                     $max      = $#dbline;
2454
2455                     # Now where are we?
2456                     print_lineinfo($position);
2457                     next CMD;
2458                 };
2459
2460 =head4 C<-> - back one window
2461
2462 We change C<$start> to be one window back; if we go back past the first line,
2463 we set it to be the first line. We ser C<$incr> to put us back at the
2464 currently-executing line, and then put a C<l $start +> (list one window from
2465 C<$start>) in C<$cmd> to be executed later.
2466
2467 =cut
2468
2469                 # - - back a window.
2470                 $cmd =~ /^-$/ && do {
2471
2472                     # back up by a window; go to 1 if back too far.
2473                     $start -= $incr + $window + 1;
2474                     $start = 1 if $start <= 0;
2475                     $incr  = $window - 1;
2476
2477                     # Generate and execute a "l +" command (handled below).
2478                     $cmd = 'l ' . ($start) . '+';
2479                 };
2480
2481 =head3 PRE-580 COMMANDS VS. NEW COMMANDS: C<a, A, b, B, h, l, L, M, o, O, P, v, w, W, E<lt>, E<lt>E<lt>, {, {{>
2482
2483 In Perl 5.8.0, a realignment of the commands was done to fix up a number of
2484 problems, most notably that the default case of several commands destroying
2485 the user's work in setting watchpoints, actions, etc. We wanted, however, to
2486 retain the old commands for those who were used to using them or who preferred
2487 them. At this point, we check for the new commands and call C<cmd_wrapper> to
2488 deal with them instead of processing them in-line.
2489
2490 =cut
2491
2492                 # All of these commands were remapped in perl 5.8.0;
2493                 # we send them off to the secondary dispatcher (see below).
2494                 $cmd =~ /^([aAbBeEhilLMoOPvwW]\b|[<>\{]{1,2})\s*(.*)/so && do {
2495                     &cmd_wrapper( $1, $2, $line );
2496                     next CMD;
2497                 };
2498
2499 =head4 C<y> - List lexicals in higher scope
2500
2501 Uses C<PadWalker> to find the lexicals supplied as arguments in a scope    
2502 above the current one and then displays then using C<dumpvar.pl>.
2503
2504 =cut
2505
2506                 $cmd =~ /^y(?:\s+(\d*)\s*(.*))?$/ && do {
2507
2508                     # See if we've got the necessary support.
2509                     eval { require PadWalker; PadWalker->VERSION(0.08) }
2510                       or &warn(
2511                         $@ =~ /locate/
2512                         ? "PadWalker module not found - please install\n"
2513                         : $@
2514                       )
2515                       and next CMD;
2516
2517                     # Load up dumpvar if we don't have it. If we can, that is.
2518                     do 'dumpvar.pl' || die $@ unless defined &main::dumpvar;
2519                     defined &main::dumpvar
2520                       or print $OUT "dumpvar.pl not available.\n"
2521                       and next CMD;
2522
2523                     # Got all the modules we need. Find them and print them.
2524                     my @vars = split( ' ', $2 || '' );
2525
2526                     # Find the pad.
2527                     my $h = eval { PadWalker::peek_my( ( $1 || 0 ) + 1 ) };
2528
2529                     # Oops. Can't find it.
2530                     $@ and $@ =~ s/ at .*//, &warn($@), next CMD;
2531
2532                     # Show the desired vars with dumplex().
2533                     my $savout = select($OUT);
2534
2535                     # Have dumplex dump the lexicals.
2536                     dumpvar::dumplex( $_, $h->{$_},
2537                         defined $option{dumpDepth} ? $option{dumpDepth} : -1,
2538                         @vars )
2539                       for sort keys %$h;
2540                     select($savout);
2541                     next CMD;
2542                 };
2543
2544 =head3 COMMANDS NOT WORKING AFTER PROGRAM ENDS
2545
2546 All of the commands below this point don't work after the program being
2547 debugged has ended. All of them check to see if the program has ended; this
2548 allows the commands to be relocated without worrying about a 'line of
2549 demarcation' above which commands can be entered anytime, and below which
2550 they can't.
2551
2552 =head4 C<n> - single step, but don't trace down into subs
2553
2554 Done by setting C<$single> to 2, which forces subs to execute straight through
2555 when entered (see C<DB::sub>). We also save the C<n> command in C<$laststep>,
2556 so a null command knows what to re-execute. 
2557
2558 =cut
2559
2560                 # n - next
2561                 $cmd =~ /^n$/ && do {
2562                     end_report(), next CMD if $finished and $level <= 1;
2563
2564                     # Single step, but don't enter subs.
2565                     $single = 2;
2566
2567                     # Save for empty command (repeat last).
2568                     $laststep = $cmd;
2569                     last CMD;
2570                 };
2571
2572 =head4 C<s> - single-step, entering subs
2573
2574 Sets C<$single> to 1, which causes C<DB::sub> to continue tracing inside     
2575 subs. Also saves C<s> as C<$lastcmd>.
2576
2577 =cut
2578
2579                 # s - single step.
2580                 $cmd =~ /^s$/ && do {
2581
2582                     # Get out and restart the command loop if program
2583                     # has finished.
2584                     end_report(), next CMD if $finished and $level <= 1;
2585
2586                     # Single step should enter subs.
2587                     $single = 1;
2588
2589                     # Save for empty command (repeat last).
2590                     $laststep = $cmd;
2591                     last CMD;
2592                 };
2593
2594 =head4 C<c> - run continuously, setting an optional breakpoint
2595
2596 Most of the code for this command is taken up with locating the optional
2597 breakpoint, which is either a subroutine name or a line number. We set
2598 the appropriate one-time-break in C<@dbline> and then turn off single-stepping
2599 in this and all call levels above this one.
2600
2601 =cut
2602
2603                 # c - start continuous execution.
2604                 $cmd =~ /^c\b\s*([\w:]*)\s*$/ && do {
2605
2606                     # Hey, show's over. The debugged program finished
2607                     # executing already.
2608                     end_report(), next CMD if $finished and $level <= 1;
2609
2610                     # Capture the place to put a one-time break.
2611                     $subname = $i = $1;
2612
2613                     #  Probably not needed, since we finish an interactive
2614                     #  sub-session anyway...
2615                     # local $filename = $filename;
2616                     # local *dbline = *dbline; # XXX Would this work?!
2617                     #
2618                     # The above question wonders if localizing the alias
2619                     # to the magic array works or not. Since it's commented
2620                     # out, we'll just leave that to speculation for now.
2621
2622                     # If the "subname" isn't all digits, we'll assume it
2623                     # is a subroutine name, and try to find it.
2624                     if ( $subname =~ /\D/ ) {    # subroutine name
2625                             # Qualify it to the current package unless it's
2626                             # already qualified.
2627                         $subname = $package . "::" . $subname
2628                           unless $subname =~ /::/;
2629
2630                         # find_sub will return "file:line_number" corresponding
2631                         # to where the subroutine is defined; we call find_sub,
2632                         # break up the return value, and assign it in one
2633                         # operation.
2634                         ( $file, $i ) = ( find_sub($subname) =~ /^(.*):(.*)$/ );
2635
2636                         # Force the line number to be numeric.
2637                         $i += 0;
2638
2639                         # If we got a line number, we found the sub.
2640                         if ($i) {
2641
2642                             # Switch all the debugger's internals around so
2643                             # we're actually working with that file.
2644                             $filename = $file;
2645                             *dbline   = $main::{ '_<' . $filename };
2646
2647                             # Mark that there's a breakpoint in this file.
2648                             $had_breakpoints{$filename} |= 1;
2649
2650                             # Scan forward to the first executable line
2651                             # after the 'sub whatever' line.
2652                             $max = $#dbline;
2653                             ++$i while $dbline[$i] == 0 && $i < $max;
2654                         } ## end if ($i)
2655
2656                         # We didn't find a sub by that name.
2657                         else {
2658                             print $OUT "Subroutine $subname not found.\n";
2659                             next CMD;
2660                         }
2661                     } ## end if ($subname =~ /\D/)
2662
2663                     # At this point, either the subname was all digits (an
2664                     # absolute line-break request) or we've scanned through
2665                     # the code following the definition of the sub, looking
2666                     # for an executable, which we may or may not have found.
2667                     #
2668                     # If $i (which we set $subname from) is non-zero, we
2669                     # got a request to break at some line somewhere. On
2670                     # one hand, if there wasn't any real subroutine name
2671                     # involved, this will be a request to break in the current
2672                     # file at the specified line, so we have to check to make
2673                     # sure that the line specified really is breakable.
2674                     #
2675                     # On the other hand, if there was a subname supplied, the
2676                     # preceding block has moved us to the proper file and
2677                     # location within that file, and then scanned forward
2678                     # looking for the next executable line. We have to make
2679                     # sure that one was found.
2680                     #
2681                     # On the gripping hand, we can't do anything unless the
2682                     # current value of $i points to a valid breakable line.
2683                     # Check that.
2684                     if ($i) {
2685
2686                         # Breakable?
2687                         if ( $dbline[$i] == 0 ) {
2688                             print $OUT "Line $i not breakable.\n";
2689                             next CMD;
2690                         }
2691
2692                         # Yes. Set up the one-time-break sigil.
2693                         $dbline{$i} =~ s/($|\0)/;9$1/;  # add one-time-only b.p.
2694                         _enable_breakpoint_temp_enabled_status($filename, $i);
2695                     } ## end if ($i)
2696
2697                     # Turn off stack tracing from here up.
2698                     for my $i (0 .. $stack_depth) {
2699                         $stack[ $i ] &= ~1;
2700                     }
2701                     last CMD;
2702                 };
2703
2704 =head4 C<r> - return from a subroutine
2705
2706 For C<r> to work properly, the debugger has to stop execution again
2707 immediately after the return is executed. This is done by forcing
2708 single-stepping to be on in the call level above the current one. If
2709 we are printing return values when a C<r> is executed, set C<$doret>
2710 appropriately, and force us out of the command loop.
2711
2712 =cut
2713
2714                 # r - return from the current subroutine.
2715                 $cmd =~ /^r$/ && do {
2716
2717                     # Can't do anything if the program's over.
2718                     end_report(), next CMD if $finished and $level <= 1;
2719
2720                     # Turn on stack trace.
2721                     $stack[$stack_depth] |= 1;
2722
2723                     # Print return value unless the stack is empty.
2724                     $doret = $option{PrintRet} ? $stack_depth - 1 : -2;
2725                     last CMD;
2726                 };
2727
2728 =head4 C<T> - stack trace
2729
2730 Just calls C<DB::print_trace>.
2731
2732 =cut
2733
2734                 $cmd =~ /^T$/ && do {
2735                     print_trace( $OUT, 1 );    # skip DB
2736                     next CMD;
2737                 };
2738
2739 =head4 C<w> - List window around current line.
2740
2741 Just calls C<DB::cmd_w>.
2742
2743 =cut
2744
2745                 $cmd =~ /^w\b\s*(.*)/s && do { &cmd_w( 'w', $1 ); next CMD; };
2746
2747 =head4 C<W> - watch-expression processing.
2748
2749 Just calls C<DB::cmd_W>. 
2750
2751 =cut
2752
2753                 $cmd =~ /^W\b\s*(.*)/s && do { &cmd_W( 'W', $1 ); next CMD; };
2754
2755 =head4 C</> - search forward for a string in the source
2756
2757 We take the argument and treat it as a pattern. If it turns out to be a 
2758 bad one, we return the error we got from trying to C<eval> it and exit.
2759 If not, we create some code to do the search and C<eval> it so it can't 
2760 mess us up.
2761
2762 =cut
2763
2764                 $cmd =~ /^\/(.*)$/ && do {
2765
2766                     # The pattern as a string.
2767                     use vars qw($inpat);
2768                     $inpat = $1;
2769
2770                     # Remove the final slash.
2771                     $inpat =~ s:([^\\])/$:$1:;
2772
2773                     # If the pattern isn't null ...
2774                     if ( $inpat ne "" ) {
2775
2776                         # Turn of warn and die procesing for a bit.
2777                         local $SIG{__DIE__};
2778                         local $SIG{__WARN__};
2779
2780                         # Create the pattern.
2781                         eval '$inpat =~ m' . "\a$inpat\a";
2782                         if ( $@ ne "" ) {
2783
2784                             # Oops. Bad pattern. No biscuit.
2785                             # Print the eval error and go back for more
2786                             # commands.
2787                             print $OUT "$@";
2788                             next CMD;
2789                         }
2790                         $pat = $inpat;
2791                     } ## end if ($inpat ne "")
2792
2793                     # Set up to stop on wrap-around.
2794                     $end = $start;
2795
2796                     # Don't move off the current line.
2797                     $incr = -1;
2798
2799                     # Done in eval so nothing breaks if the pattern
2800                     # does something weird.
2801                     eval '
2802                         for (;;) {
2803                             # Move ahead one line.
2804                             ++$start;
2805
2806                             # Wrap if we pass the last line.
2807                             $start = 1 if ($start > $max);
2808
2809                             # Stop if we have gotten back to this line again,
2810                             last if ($start == $end);
2811
2812                             # A hit! (Note, though, that we are doing
2813                             # case-insensitive matching. Maybe a qr//
2814                             # expression would be better, so the user could
2815                             # do case-sensitive matching if desired.
2816                             if ($dbline[$start] =~ m' . "\a$pat\a" . 'i) {
2817                                 if ($slave_editor) {
2818                                     # Handle proper escaping in the slave.
2819                                     print $OUT "\032\032$filename:$start:0\n";
2820                                 } 
2821                                 else {
2822                                     # Just print the line normally.
2823                                     print $OUT "$start:\t",$dbline[$start],"\n";
2824                                 }
2825                                 # And quit since we found something.
2826                                 last;
2827                             }
2828                          } ';
2829
2830                     # If we wrapped, there never was a match.
2831                     print $OUT "/$pat/: not found\n" if ( $start == $end );
2832                     next CMD;
2833                 };
2834
2835 =head4 C<?> - search backward for a string in the source
2836
2837 Same as for C</>, except the loop runs backwards.
2838
2839 =cut
2840
2841                 # ? - backward pattern search.
2842                 $cmd =~ /^\?(.*)$/ && do {
2843
2844                     # Get the pattern, remove trailing question mark.
2845                     my $inpat = $1;
2846                     $inpat =~ s:([^\\])\?$:$1:;
2847
2848                     # If we've got one ...
2849                     if ( $inpat ne "" ) {
2850
2851                         # Turn off die & warn handlers.
2852                         local $SIG{__DIE__};
2853                         local $SIG{__WARN__};
2854                         eval '$inpat =~ m' . "\a$inpat\a";
2855
2856                         if ( $@ ne "" ) {
2857
2858                             # Ouch. Not good. Print the error.
2859                             print $OUT $@;
2860                             next CMD;
2861                         }
2862                         $pat = $inpat;
2863                     } ## end if ($inpat ne "")
2864
2865                     # Where we are now is where to stop after wraparound.
2866                     $end = $start;
2867
2868                     # Don't move away from this line.
2869                     $incr = -1;
2870
2871                     # Search inside the eval to prevent pattern badness
2872                     # from killing us.
2873                     eval '
2874                         for (;;) {
2875                             # Back up a line.
2876                             --$start;
2877
2878                             # Wrap if we pass the first line.
2879
2880                             $start = $max if ($start <= 0);
2881
2882                             # Quit if we get back where we started,
2883                             last if ($start == $end);
2884
2885                             # Match?
2886                             if ($dbline[$start] =~ m' . "\a$pat\a" . 'i) {
2887                                 if ($slave_editor) {
2888                                     # Yep, follow slave editor requirements.
2889                                     print $OUT "\032\032$filename:$start:0\n";
2890                                 } 
2891                                 else {
2892                                     # Yep, just print normally.
2893                                     print $OUT "$start:\t",$dbline[$start],"\n";
2894                                 }
2895
2896                                 # Found, so done.
2897                                 last;
2898                             }
2899                         } ';
2900
2901                     # Say we failed if the loop never found anything,
2902                     print $OUT "?$pat?: not found\n" if ( $start == $end );
2903                     next CMD;
2904                 };
2905
2906 =head4 C<$rc> - Recall command
2907
2908 Manages the commands in C<@hist> (which is created if C<Term::ReadLine> reports
2909 that the terminal supports history). It find the the command required, puts it
2910 into C<$cmd>, and redoes the loop to execute it.
2911
2912 =cut
2913
2914                 # $rc - recall command.
2915                 $cmd =~ /^$rc+\s*(-)?(\d+)?$/ && do {
2916
2917                     # No arguments, take one thing off history.
2918                     pop(@hist) if length($cmd) > 1;
2919
2920                     # Relative (- found)?
2921                     #  Y - index back from most recent (by 1 if bare minus)
2922                     #  N - go to that particular command slot or the last
2923                     #      thing if nothing following.
2924                     $i = $1 ? ( $#hist - ( $2 || 1 ) ) : ( $2 || $#hist );
2925
2926                     # Pick out the command desired.
2927                     $cmd = $hist[$i];
2928
2929                     # Print the command to be executed and restart the loop
2930                     # with that command in the buffer.
2931                     print $OUT $cmd, "\n";
2932                     redo CMD;
2933                 };
2934
2935 =head4 C<$sh$sh> - C<system()> command
2936
2937 Calls the C<DB::system()> to handle the command. This keeps the C<STDIN> and
2938 C<STDOUT> from getting messed up.
2939
2940 =cut
2941
2942                 # $sh$sh - run a shell command (if it's all ASCII).
2943                 # Can't run shell commands with Unicode in the debugger, hmm.
2944                 $cmd =~ /^$sh$sh\s*([\x00-\xff]*)/ && do {
2945
2946                     # System it.
2947                     &system($1);
2948                     next CMD;
2949                 };
2950
2951 =head4 C<$rc I<pattern> $rc> - Search command history
2952
2953 Another command to manipulate C<@hist>: this one searches it with a pattern.
2954 If a command is found, it is placed in C<$cmd> and executed via C<redo>.
2955
2956 =cut
2957
2958                 # $rc pattern $rc - find a command in the history.
2959                 $cmd =~ /^$rc([^$rc].*)$/ && do {
2960
2961                     # Create the pattern to use.
2962                     $pat = "^$1";
2963
2964                     # Toss off last entry if length is >1 (and it always is).
2965                     pop(@hist) if length($cmd) > 1;
2966
2967                     # Look backward through the history.
2968                     $i = $#hist;
2969                     while ($i) {
2970
2971                         # Stop if we find it.
2972                         last if $hist[$i] =~ /$pat/;
2973                     }
2974                     continue {
2975                         $i--;
2976                     }
2977
2978                     if ( !$i ) {
2979
2980                         # Never found it.
2981                         print $OUT "No such command!\n\n";
2982                         next CMD;
2983                     }
2984
2985                     # Found it. Put it in the buffer, print it, and process it.
2986                     $cmd = $hist[$i];
2987                     print $OUT $cmd, "\n";
2988                     redo CMD;
2989                 };
2990
2991 =head4 C<$sh> - Invoke a shell     
2992
2993 Uses C<DB::system> to invoke a shell.
2994
2995 =cut
2996
2997                 # $sh - start a shell.
2998                 $cmd =~ /^$sh$/ && do {
2999
3000                     # Run the user's shell. If none defined, run Bourne.
3001                     # We resume execution when the shell terminates.
3002                     &system( $ENV{SHELL} || "/bin/sh" );
3003                     next CMD;
3004                 };
3005
3006 =head4 C<$sh I<command>> - Force execution of a command in a shell
3007
3008 Like the above, but the command is passed to the shell. Again, we use
3009 C<DB::system> to avoid problems with C<STDIN> and C<STDOUT>.
3010
3011 =cut
3012
3013                 # $sh command - start a shell and run a command in it.
3014                 $cmd =~ /^$sh\s*([\x00-\xff]*)/ && do {
3015
3016                     # XXX: using csh or tcsh destroys sigint retvals!
3017                     #&system($1);  # use this instead
3018
3019                     # use the user's shell, or Bourne if none defined.
3020                     &system( $ENV{SHELL} || "/bin/sh", "-c", $1 );
3021                     next CMD;
3022                 };
3023
3024 =head4 C<H> - display commands in history
3025
3026 Prints the contents of C<@hist> (if any).
3027
3028 =cut
3029
3030                 $cmd =~ /^H\b\s*\*/ && do {
3031                     @hist = @truehist = ();
3032                     print $OUT "History cleansed\n";
3033                     next CMD;
3034                 };
3035
3036                 $cmd =~ /^H\b\s*(-(\d+))?/ && do {
3037
3038                     # Anything other than negative numbers is ignored by
3039                     # the (incorrect) pattern, so this test does nothing.
3040                     $end = $2 ? ( $#hist - $2 ) : 0;
3041
3042                     # Set to the minimum if less than zero.
3043                     $hist = 0 if $hist < 0;
3044
3045                     # Start at the end of the array.
3046                     # Stay in while we're still above the ending value.
3047                     # Tick back by one each time around the loop.
3048                     $i = $#hist;
3049                     while ( $i > $end ) {
3050
3051                         # Print the command  unless it has no arguments.
3052                         print $OUT "$i: ", $hist[$i], "\n"
3053                           unless $hist[$i] =~ /^.?$/;
3054                     }
3055                     continue {
3056                         $i--;
3057                     }
3058                     next CMD;
3059                 };
3060
3061 =head4 C<man, doc, perldoc> - look up documentation
3062
3063 Just calls C<runman()> to print the appropriate document.
3064
3065 =cut
3066
3067                 # man, perldoc, doc - show manual pages.
3068                 $cmd =~ /^(?:man|(?:perl)?doc)\b(?:\s+([^(]*))?$/ && do {
3069                     runman($1);
3070                     next CMD;
3071                 };
3072
3073 =head4 C<p> - print
3074
3075 Builds a C<print EXPR> expression in the C<$cmd>; this will get executed at
3076 the bottom of the loop.
3077
3078 =cut
3079
3080                 # p - print (no args): print $_.
3081                 $cmd =~ s/^p$/print {\$DB::OUT} \$_/;
3082
3083                 # p - print the given expression.
3084                 $cmd =~ s/^p\b/print {\$DB::OUT} /;
3085
3086 =head4 C<=> - define command alias
3087
3088 Manipulates C<%alias> to add or list command aliases.
3089
3090 =cut
3091
3092                 # = - set up a command alias.
3093                 $cmd =~ s/^=\s*// && do {
3094                     my @keys;
3095                     if ( length $cmd == 0 ) {
3096
3097                         # No args, get current aliases.
3098                         @keys = sort keys %alias;
3099                     }
3100                     elsif ( my ( $k, $v ) = ( $cmd =~ /^(\S+)\s+(\S.*)/ ) ) {
3101
3102                         # Creating a new alias. $k is alias name, $v is
3103                         # alias value.
3104
3105                         # can't use $_ or kill //g state
3106                         for my $x ( $k, $v ) {
3107
3108                             # Escape "alarm" characters.
3109                             $x =~ s/\a/\\a/g;
3110                         }
3111
3112                         # Substitute key for value, using alarm chars
3113                         # as separators (which is why we escaped them in
3114                         # the command).
3115                         $alias{$k} = "s\a$k\a$v\a";
3116
3117                         # Turn off standard warn and die behavior.
3118                         local $SIG{__DIE__};
3119                         local $SIG{__WARN__};
3120
3121                         # Is it valid Perl?
3122                         unless ( eval "sub { s\a$k\a$v\a }; 1" ) {
3123
3124                             # Nope. Bad alias. Say so and get out.
3125                             print $OUT "Can't alias $k to $v: $@\n";
3126                             delete $alias{$k};
3127                             next CMD;
3128                         }
3129
3130                         # We'll only list the new one.
3131                         @keys = ($k);
3132                     } ## end elsif (my ($k, $v) = ($cmd...
3133
3134                     # The argument is the alias to list.
3135                     else {
3136                         @keys = ($cmd);
3137                     }
3138
3139                     # List aliases.
3140                     for my $k (@keys) {
3141
3142                         # Messy metaquoting: Trim the substitution code off.
3143                         # We use control-G as the delimiter because it's not
3144                         # likely to appear in the alias.
3145                         if ( ( my $v = $alias{$k} ) =~ s\as\a$k\a(.*)\a$\a1\a ) {
3146
3147                             # Print the alias.
3148                             print $OUT "$k\t= $1\n";
3149                         }
3150                         elsif ( defined $alias{$k} ) {
3151
3152                             # Couldn't trim it off; just print the alias code.
3153                             print $OUT "$k\t$alias{$k}\n";
3154                         }
3155                         else {
3156
3157                             # No such, dude.
3158                             print "No alias for $k\n";
3159                         }
3160                     } ## end for my $k (@keys)
3161                     next CMD;
3162                 };
3163
3164 =head4 C<source> - read commands from a file.
3165
3166 Opens a lexical filehandle and stacks it on C<@cmdfhs>; C<DB::readline> will
3167 pick it up.
3168
3169 =cut
3170
3171                 # source - read commands from a file (or pipe!) and execute.
3172                 $cmd =~ /^source\s+(.*\S)/ && do {
3173                     if ( open my $fh, $1 ) {
3174
3175                         # Opened OK; stick it in the list of file handles.
3176                         push @cmdfhs, $fh;
3177                     }
3178                     else {
3179
3180                         # Couldn't open it.
3181                         &warn("Can't execute '$1': $!\n");
3182                     }
3183                     next CMD;
3184                 };
3185
3186                 $cmd =~ /^(enable|disable)\s+(\S+)\s*$/ && do {
3187                     my ($cmd, $position) = ($1, $2);
3188
3189                     my ($fn, $line_num);
3190                     if ($position =~ m{\A\d+\z})
3191                     {
3192                         $fn = $filename;
3193                         $line_num = $position;
3194                     }
3195                     elsif ($position =~ m{\A(.*):(\d+)\z})
3196                     {
3197                         ($fn, $line_num) = ($1, $2);
3198                     }
3199                     else
3200                     {
3201                         &warn("Wrong spec for enable/disable argument.\n");
3202                     }
3203
3204                     if (defined($fn)) {
3205                         if (_has_breakpoint_data_ref($fn, $line_num)) {
3206                             _set_breakpoint_enabled_status($fn, $line_num,
3207                                 ($cmd eq 'enable' ? 1 : '')
3208                             );
3209                         }
3210                         else {
3211                             &warn("No breakpoint set at ${fn}:${line_num}\n");
3212                         }
3213                     }
3214
3215                     next CMD;
3216                 };
3217
3218 =head4 C<save> - send current history to a file
3219
3220 Takes the complete history, (not the shrunken version you see with C<H>),
3221 and saves it to the given filename, so it can be replayed using C<source>.
3222
3223 Note that all C<^(save|source)>'s are commented out with a view to minimise recursion.
3224
3225 =cut
3226
3227                 # save source - write commands to a file for later use
3228                 $cmd =~ /^save\s*(.*)$/ && do {
3229                     my $file = $1 || '.perl5dbrc';    # default?
3230                     if ( open my $fh, "> $file" ) {
3231
3232                        # chomp to remove extraneous newlines from source'd files
3233                         chomp( my @truelist =
3234                               map { m/^\s*(save|source)/ ? "#$_" : $_ }
3235                               @truehist );
3236                         print $fh join( "\n", @truelist );
3237                         print "commands saved in $file\n";
3238                     }
3239                     else {
3240                         &warn("Can't save debugger commands in '$1': $!\n");
3241                     }
3242                     next CMD;
3243                 };
3244
3245 =head4 C<R> - restart
3246
3247 Restart the debugger session. 
3248
3249 =head4 C<rerun> - rerun the current session
3250
3251 Return to any given position in the B<true>-history list
3252
3253 =cut
3254
3255                 # R - restart execution.
3256                 # rerun - controlled restart execution.
3257                 $cmd =~ /^(R|rerun\s*(.*))$/ && do {
3258                     my @args = ($1 eq 'R' ? restart() : rerun($2));
3259
3260                     # Close all non-system fds for a clean restart.  A more
3261                     # correct method would be to close all fds that were not
3262                     # open when the process started, but this seems to be
3263                     # hard.  See "debugger 'R'estart and open database
3264                     # connections" on p5p.
3265
3266                     my $max_fd = 1024; # default if POSIX can't be loaded
3267                     if (eval { require POSIX }) {
3268                         eval { $max_fd = POSIX::sysconf(POSIX::_SC_OPEN_MAX()) };
3269                     }
3270
3271                     if (defined $max_fd) {
3272                         foreach ($^F+1 .. $max_fd-1) {
3273                             next unless open FD_TO_CLOSE, "<&=$_";
3274                             close(FD_TO_CLOSE);
3275                         }
3276                     }
3277
3278                     # And run Perl again.  We use exec() to keep the
3279                     # PID stable (and that way $ini_pids is still valid).
3280                     exec(@args) || print $OUT "exec failed: $!\n";
3281
3282                     last CMD;
3283                 };
3284
3285 =head4 C<|, ||> - pipe output through the pager.
3286
3287 For C<|>, we save C<OUT> (the debugger's output filehandle) and C<STDOUT>
3288 (the program's standard output). For C<||>, we only save C<OUT>. We open a
3289 pipe to the pager (restoring the output filehandles if this fails). If this
3290 is the C<|> command, we also set up a C<SIGPIPE> handler which will simply 
3291 set C<$signal>, sending us back into the debugger.
3292
3293 We then trim off the pipe symbols and C<redo> the command loop at the
3294 C<PIPE> label, causing us to evaluate the command in C<$cmd> without
3295 reading another.
3296
3297 =cut
3298
3299                 # || - run command in the pager, with output to DB::OUT.
3300                 $cmd =~ /^\|\|?\s*[^|]/ && do {
3301                     if ( $pager =~ /^\|/ ) {
3302
3303                         # Default pager is into a pipe. Redirect I/O.
3304                         open( SAVEOUT, ">&STDOUT" )
3305                           || &warn("Can't save STDOUT");
3306                         open( STDOUT, ">&OUT" )
3307                           || &warn("Can't redirect STDOUT");
3308                     } ## end if ($pager =~ /^\|/)
3309                     else {
3310
3311                         # Not into a pipe. STDOUT is safe.
3312                         open( SAVEOUT, ">&OUT" ) || &warn("Can't save DB::OUT");
3313                     }
3314
3315                     # Fix up environment to record we have less if so.
3316                     fix_less();
3317
3318                     unless ( $piped = open( OUT, $pager ) ) {
3319
3320                         # Couldn't open pipe to pager.
3321                         &warn("Can't pipe output to '$pager'");
3322                         if ( $pager =~ /^\|/ ) {
3323
3324                             # Redirect I/O back again.
3325                             open( OUT, ">&STDOUT" )    # XXX: lost message
3326                               || &warn("Can't restore DB::OUT");
3327                             open( STDOUT, ">&SAVEOUT" )
3328                               || &warn("Can't restore STDOUT");
3329                             close(SAVEOUT);
3330                         } ## end if ($pager =~ /^\|/)
3331                         else {
3332
3333                             # Redirect I/O. STDOUT already safe.
3334                             open( OUT, ">&STDOUT" )    # XXX: lost message
3335                               || &warn("Can't restore DB::OUT");
3336                         }
3337                         next CMD;
3338                     } ## end unless ($piped = open(OUT,...
3339
3340                     # Set up broken-pipe handler if necessary.
3341                     $SIG{PIPE} = \&DB::catch
3342                       if $pager =~ /^\|/
3343                       && ( "" eq $SIG{PIPE} || "DEFAULT" eq $SIG{PIPE} );
3344
3345                     # Save current filehandle, unbuffer out, and put it back.
3346                     $selected = select(OUT);
3347                     $|        = 1;
3348
3349                     # Don't put it back if pager was a pipe.
3350                     select($selected), $selected = "" unless $cmd =~ /^\|\|/;
3351
3352                     # Trim off the pipe symbols and run the command now.
3353                     $cmd =~ s/^\|+\s*//;
3354                     redo PIPE;
3355                 };
3356
3357 =head3 END OF COMMAND PARSING
3358
3359 Anything left in C<$cmd> at this point is a Perl expression that we want to 
3360 evaluate. We'll always evaluate in the user's context, and fully qualify 
3361 any variables we might want to address in the C<DB> package.
3362
3363 =cut
3364
3365                 # t - turn trace on.
3366                 $cmd =~ s/^t\s+(\d+)?/\$DB::trace |= 1;\n/ && do {
3367                     $trace_to_depth = $1 ? $stack_depth||0 + $1 : 1E9;
3368                 };
3369
3370                 # s - single-step. Remember the last command was 's'.
3371                 $cmd =~ s/^s\s/\$DB::single = 1;\n/ && do { $laststep = 's' };
3372
3373                 # n - single-step, but not into subs. Remember last command
3374                 # was 'n'.
3375                 $cmd =~ s/^n\s/\$DB::single = 2;\n/ && do { $laststep = 'n' };
3376
3377             }    # PIPE:
3378
3379             # Make sure the flag that says "the debugger's running" is
3380             # still on, to make sure we get control again.
3381             $evalarg = "\$^D = \$^D | \$DB::db_stop;\n$cmd";
3382
3383             # Run *our* eval that executes in the caller's context.
3384             &eval;
3385
3386             # Turn off the one-time-dump stuff now.
3387             if ($onetimeDump) {
3388                 $onetimeDump      = undef;
3389                 $onetimedumpDepth = undef;
3390             }
3391             elsif ( $term_pid == $$ ) {
3392                 eval {          # May run under miniperl, when not available...
3393                     STDOUT->flush();
3394                     STDERR->flush();
3395                 };
3396
3397                 # XXX If this is the master pid, print a newline.
3398                 print $OUT "\n";
3399             }
3400         } ## end while (($term || &setterm...
3401
3402 =head3 POST-COMMAND PROCESSING
3403
3404 After each command, we check to see if the command output was piped anywhere.
3405 If so, we go through the necessary code to unhook the pipe and go back to
3406 our standard filehandles for input and output.
3407
3408 =cut
3409
3410         continue {    # CMD:
3411
3412             # At the end of every command:
3413             if ($piped) {
3414
3415                 # Unhook the pipe mechanism now.
3416                 if ( $pager =~ /^\|/ ) {
3417
3418                     # No error from the child.
3419                     $? = 0;
3420
3421                     # we cannot warn here: the handle is missing --tchrist
3422                     close(OUT) || print SAVEOUT "\nCan't close DB::OUT\n";
3423
3424                     # most of the $? crud was coping with broken cshisms
3425                     # $? is explicitly set to 0, so this never runs.
3426                     if ($?) {
3427                         print SAVEOUT "Pager '$pager' failed: ";
3428                         if ( $? == -1 ) {
3429                             print SAVEOUT "shell returned -1\n";
3430                         }
3431                         elsif ( $? >> 8 ) {
3432                             print SAVEOUT ( $? & 127 )
3433                               ? " (SIG#" . ( $? & 127 ) . ")"
3434                               : "", ( $? & 128 ) ? " -- core dumped" : "", "\n";
3435                         }
3436                         else {
3437                             print SAVEOUT "status ", ( $? >> 8 ), "\n";
3438                         }
3439                     } ## end if ($?)
3440
3441                     # Reopen filehandle for our output (if we can) and
3442                     # restore STDOUT (if we can).
3443                     open( OUT, ">&STDOUT" ) || &warn("Can't restore DB::OUT");
3444                     open( STDOUT, ">&SAVEOUT" )
3445                       || &warn("Can't restore STDOUT");
3446
3447                     # Turn off pipe exception handler if necessary.
3448                     $SIG{PIPE} = "DEFAULT" if $SIG{PIPE} eq \&DB::catch;
3449
3450                     # Will stop ignoring SIGPIPE if done like nohup(1)
3451                     # does SIGINT but Perl doesn't give us a choice.
3452                 } ## end if ($pager =~ /^\|/)
3453                 else {
3454
3455                     # Non-piped "pager". Just restore STDOUT.
3456                     open( OUT, ">&SAVEOUT" ) || &warn("Can't restore DB::OUT");
3457                 }
3458
3459                 # Close filehandle pager was using, restore the normal one
3460                 # if necessary,
3461                 close(SAVEOUT);
3462                 select($selected), $selected = "" unless $selected eq "";
3463
3464                 # No pipes now.
3465                 $piped = "";
3466             } ## end if ($piped)
3467         }    # CMD:
3468
3469 =head3 COMMAND LOOP TERMINATION
3470
3471 When commands have finished executing, we come here. If the user closed the
3472 input filehandle, we turn on C<$fall_off_end> to emulate a C<q> command. We
3473 evaluate any post-prompt items. We restore C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>,
3474 C<$\>, and C<$^W>, and return a null list as expected by the Perl interpreter.
3475 The interpreter will then execute the next line and then return control to us
3476 again.
3477
3478 =cut
3479
3480         # No more commands? Quit.
3481         $fall_off_end = 1 unless defined $cmd;    # Emulate 'q' on EOF
3482
3483         # Evaluate post-prompt commands.
3484         foreach $evalarg (@$post) {
3485             &eval;
3486         }
3487     }    # if ($single || $signal)
3488
3489     # Put the user's globals back where you found them.
3490     ( $@, $!, $^E, $,, $/, $\, $^W ) = @saved;
3491     ();
3492 } ## end sub DB
3493
3494 # The following code may be executed now:
3495 # BEGIN {warn 4}
3496
3497 =head2 sub
3498
3499 C<sub> is called whenever a subroutine call happens in the program being 
3500 debugged. The variable C<$DB::sub> contains the name of the subroutine
3501 being called.
3502
3503 The core function of this subroutine is to actually call the sub in the proper
3504 context, capturing its output. This of course causes C<DB::DB> to get called
3505 again, repeating until the subroutine ends and returns control to C<DB::sub>
3506 again. Once control returns, C<DB::sub> figures out whether or not to dump the
3507 return value, and returns its captured copy of the return value as its own
3508 return value. The value then feeds back into the program being debugged as if
3509 C<DB::sub> hadn't been there at all.
3510
3511 C<sub> does all the work of printing the subroutine entry and exit messages
3512 enabled by setting C<$frame>. It notes what sub the autoloader got called for,
3513 and also prints the return value if needed (for the C<r> command and if 
3514 the 16 bit is set in C<$frame>).
3515
3516 It also tracks the subroutine call depth by saving the current setting of
3517 C<$single> in the C<@stack> package global; if this exceeds the value in
3518 C<$deep>, C<sub> automatically turns on printing of the current depth by
3519 setting the C<4> bit in C<$single>. In any case, it keeps the current setting
3520 of stop/don't stop on entry to subs set as it currently is set.
3521
3522 =head3 C<caller()> support
3523
3524 If C<caller()> is called from the package C<DB>, it provides some
3525 additional data, in the following order:
3526
3527 =over 4
3528
3529 =item * C<$package>
3530
3531 The package name the sub was in
3532
3533 =item * C<$filename>
3534
3535 The filename it was defined in
3536
3537 =item * C<$line>
3538
3539 The line number it was defined on
3540
3541 =item * C<$subroutine>
3542
3543 The subroutine name; C<(eval)> if an C<eval>().
3544
3545 =item * C<$hasargs>
3546
3547 1 if it has arguments, 0 if not
3548
3549 =item * C<$wantarray>
3550
3551 1 if array context, 0 if scalar context
3552
3553 =item * C<$evaltext>
3554
3555 The C<eval>() text, if any (undefined for C<eval BLOCK>)
3556
3557 =item * C<$is_require>
3558
3559 frame was created by a C<use> or C<require> statement
3560
3561 =item * C<$hints>
3562
3563 pragma information; subject to change between versions
3564
3565 =item * C<$bitmask>
3566
3567 pragma information; subject to change between versions
3568
3569 =item * C<@DB::args>
3570
3571 arguments with which the subroutine was invoked
3572
3573 =back
3574
3575 =cut
3576
3577 use vars qw($deep);
3578
3579 # We need to fully qualify the name ("DB::sub") to make "use strict;"
3580 # happy. -- Shlomi Fish
3581 sub DB::sub {
3582         # Do not use a regex in this subroutine -> results in corrupted memory
3583         # See: [perl #66110]
3584
3585         # lock ourselves under threads
3586         lock($DBGR);
3587
3588     # Whether or not the autoloader was running, a scalar to put the
3589     # sub's return value in (if needed), and an array to put the sub's
3590     # return value in (if needed).
3591     my ( $al, $ret, @ret ) = "";
3592         if ($sub eq 'threads::new' && $ENV{PERL5DB_THREADED}) {
3593                 print "creating new thread\n"; 
3594         }
3595
3596     # If the last ten characters are '::AUTOLOAD', note we've traced
3597     # into AUTOLOAD for $sub.
3598     if ( length($sub) > 10 && substr( $sub, -10, 10 ) eq '::AUTOLOAD' ) {
3599         no strict 'refs';
3600         $al = " for $$sub" if defined $$sub;
3601     }
3602
3603     # We stack the stack pointer and then increment it to protect us
3604     # from a situation that might unwind a whole bunch of call frames
3605     # at once. Localizing the stack pointer means that it will automatically
3606     # unwind the same amount when multiple stack frames are unwound.
3607     local $stack_depth = $stack_depth + 1;    # Protect from non-local exits
3608
3609     # Expand @stack.
3610     $#stack = $stack_depth;
3611
3612     # Save current single-step setting.
3613     $stack[-1] = $single;
3614
3615     # Turn off all flags except single-stepping.
3616     $single &= 1;
3617
3618     # If we've gotten really deeply recursed, turn on the flag that will
3619     # make us stop with the 'deep recursion' message.
3620     $single |= 4 if $stack_depth == $deep;
3621
3622     # If frame messages are on ...
3623     (
3624         $frame & 4    # Extended frame entry message
3625         ? (
3626             print_lineinfo( ' ' x ( $stack_depth - 1 ), "in  " ),
3627
3628             # Why -1? But it works! :-(
3629             # Because print_trace will call add 1 to it and then call
3630             # dump_trace; this results in our skipping -1+1 = 0 stack frames
3631             # in dump_trace.
3632             print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3633           )
3634         : print_lineinfo( ' ' x ( $stack_depth - 1 ), "entering $sub$al\n" )
3635
3636           # standard frame entry message
3637       )
3638       if $frame;
3639
3640     # Determine the sub's return type, and capture appropriately.
3641     if (wantarray) {
3642
3643         # Called in array context. call sub and capture output.
3644         # DB::DB will recursively get control again if appropriate; we'll come
3645         # back here when the sub is finished.
3646         {
3647             no strict 'refs';
3648             @ret = &$sub;
3649         }
3650
3651         # Pop the single-step value back off the stack.
3652         $single |= $stack[ $stack_depth-- ];
3653
3654         # Check for exit trace messages...
3655         (
3656             $frame & 4    # Extended exit message
3657             ? (
3658                 print_lineinfo( ' ' x $stack_depth, "out " ),
3659                 print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3660               )
3661             : print_lineinfo( ' ' x $stack_depth, "exited $sub$al\n" )
3662
3663               # Standard exit message
3664           )
3665           if $frame & 2;
3666
3667         # Print the return info if we need to.
3668         if ( $doret eq $stack_depth or $frame & 16 ) {
3669
3670             # Turn off output record separator.
3671             local $\ = '';
3672             my $fh = ( $doret eq $stack_depth ? $OUT : $LINEINFO );
3673
3674             # Indent if we're printing because of $frame tracing.
3675             print $fh ' ' x $stack_depth if $frame & 16;
3676
3677             # Print the return value.
3678             print $fh "list context return from $sub:\n";
3679             dumpit( $fh, \@ret );
3680
3681             # And don't print it again.
3682             $doret = -2;
3683         } ## end if ($doret eq $stack_depth...
3684             # And we have to return the return value now.
3685         @ret;
3686     } ## end if (wantarray)
3687
3688     # Scalar context.
3689     else {
3690         if ( defined wantarray ) {
3691         no strict 'refs';
3692             # Save the value if it's wanted at all.
3693             $ret = &$sub;
3694         }
3695         else {
3696         no strict 'refs';
3697             # Void return, explicitly.
3698             &$sub;
3699             undef $ret;
3700         }
3701
3702         # Pop the single-step value off the stack.
3703         $single |= $stack[ $stack_depth-- ];
3704
3705         # If we're doing exit messages...
3706         (
3707             $frame & 4    # Extended messages
3708             ? (
3709                 print_lineinfo( ' ' x $stack_depth, "out " ),
3710                 print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3711               )
3712             : print_lineinfo( ' ' x $stack_depth, "exited $sub$al\n" )
3713
3714               # Standard messages
3715           )
3716           if $frame & 2;
3717
3718         # If we are supposed to show the return value... same as before.
3719         if ( $doret eq $stack_depth or $frame & 16 and defined wantarray ) {
3720             local $\ = '';
3721             my $fh = ( $doret eq $stack_depth ? $OUT : $LINEINFO );
3722             print $fh ( ' ' x $stack_depth ) if $frame & 16;
3723             print $fh (
3724                 defined wantarray
3725                 ? "scalar context return from $sub: "
3726                 : "void context return from $sub\n"
3727             );
3728             dumpit( $fh, $ret ) if defined wantarray;
3729             $doret = -2;
3730         } ## end if ($doret eq $stack_depth...
3731
3732         # Return the appropriate scalar value.
3733         $ret;
3734     } ## end else [ if (wantarray)
3735 } ## end sub _sub
3736
3737 sub lsub : lvalue {
3738
3739     no strict 'refs';
3740
3741         # lock ourselves under threads
3742         lock($DBGR);
3743
3744     # Whether or not the autoloader was running, a scalar to put the
3745     # sub's return value in (if needed), and an array to put the sub's
3746     # return value in (if needed).
3747     my ( $al, $ret, @ret ) = "";
3748         if ($sub =~ /^threads::new$/ && $ENV{PERL5DB_THREADED}) {
3749                 print "creating new thread\n";
3750         }
3751
3752     # If the last ten characters are C'::AUTOLOAD', note we've traced
3753     # into AUTOLOAD for $sub.
3754     if ( length($sub) > 10 && substr( $sub, -10, 10 ) eq '::AUTOLOAD' ) {
3755         $al = " for $$sub";
3756     }
3757
3758     # We stack the stack pointer and then increment it to protect us
3759     # from a situation that might unwind a whole bunch of call frames
3760     # at once. Localizing the stack pointer means that it will automatically
3761     # unwind the same amount when multiple stack frames are unwound.
3762     local $stack_depth = $stack_depth + 1;    # Protect from non-local exits
3763
3764     # Expand @stack.
3765     $#stack = $stack_depth;
3766
3767     # Save current single-step setting.
3768     $stack[-1] = $single;
3769
3770     # Turn off all flags except single-stepping.
3771     $single &= 1;
3772
3773     # If we've gotten really deeply recursed, turn on the flag that will
3774     # make us stop with the 'deep recursion' message.
3775     $single |= 4 if $stack_depth == $deep;
3776
3777     # If frame messages are on ...
3778     (
3779         $frame & 4    # Extended frame entry message
3780         ? (
3781             print_lineinfo( ' ' x ( $stack_depth - 1 ), "in  " ),
3782
3783             # Why -1? But it works! :-(
3784             # Because print_trace will call add 1 to it and then call
3785             # dump_trace; this results in our skipping -1+1 = 0 stack frames
3786             # in dump_trace.
3787             print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3788           )
3789         : print_lineinfo( ' ' x ( $stack_depth - 1 ), "entering $sub$al\n" )
3790
3791           # standard frame entry message
3792       )
3793       if $frame;
3794
3795     # Pop the single-step value back off the stack.
3796     $single |= $stack[ $stack_depth-- ];
3797
3798     # call the original lvalue sub.
3799     &$sub;
3800 }
3801
3802 # Abstracting common code from multiple places elsewhere:
3803 sub depth_print_lineinfo {
3804     my $always_print = shift;
3805
3806     print_lineinfo( @_ ) if ($always_print or $stack_depth < $trace_to_depth);
3807 }
3808
3809 =head1 EXTENDED COMMAND HANDLING AND THE COMMAND API
3810
3811 In Perl 5.8.0, there was a major realignment of the commands and what they did,
3812 Most of the changes were to systematize the command structure and to eliminate
3813 commands that threw away user input without checking.
3814
3815 The following sections describe the code added to make it easy to support 
3816 multiple command sets with conflicting command names. This section is a start 
3817 at unifying all command processing to make it simpler to develop commands.
3818
3819 Note that all the cmd_[a-zA-Z] subroutines require the command name, a line 
3820 number, and C<$dbline> (the current line) as arguments.
3821
3822 Support functions in this section which have multiple modes of failure C<die> 
3823 on error; the rest simply return a false value.
3824
3825 The user-interface functions (all of the C<cmd_*> functions) just output
3826 error messages.
3827
3828 =head2 C<%set>
3829
3830 The C<%set> hash defines the mapping from command letter to subroutine
3831 name suffix. 
3832
3833 C<%set> is a two-level hash, indexed by set name and then by command name.
3834 Note that trying to set the CommandSet to C<foobar> simply results in the
3835 5.8.0 command set being used, since there's no top-level entry for C<foobar>.
3836
3837 =cut 
3838
3839 ### The API section
3840
3841 my %set = (    #
3842     'pre580' => {
3843         'a' => 'pre580_a',
3844         'A' => 'pre580_null',
3845         'b' => 'pre580_b',
3846         'B' => 'pre580_null',
3847         'd' => 'pre580_null',
3848         'D' => 'pre580_D',
3849         'h' => 'pre580_h',
3850         'M' => 'pre580_null',
3851         'O' => 'o',
3852         'o' => 'pre580_null',
3853         'v' => 'M',
3854         'w' => 'v',
3855         'W' => 'pre580_W',
3856     },
3857     'pre590' => {
3858         '<'  => 'pre590_prepost',
3859         '<<' => 'pre590_prepost',
3860         '>'  => 'pre590_prepost',
3861         '>>' => 'pre590_prepost',
3862         '{'  => 'pre590_prepost',
3863         '{{' => 'pre590_prepost',
3864     },
3865 );
3866
3867 my %breakpoints_data;
3868
3869 sub _has_breakpoint_data_ref {
3870     my ($filename, $line) = @_;
3871
3872     return (
3873         exists( $breakpoints_data{$filename} )
3874             and
3875         exists( $breakpoints_data{$filename}{$line} )
3876     );
3877 }
3878
3879 sub _get_breakpoint_data_ref {
3880     my ($filename, $line) = @_;
3881
3882     return ($breakpoints_data{$filename}{$line} ||= +{});
3883 }
3884
3885 sub _delete_breakpoint_data_ref {
3886     my ($filename, $line) = @_;
3887
3888     delete($breakpoints_data{$filename}{$line});
3889     if (! scalar(keys( %{$breakpoints_data{$filename}} )) ) {
3890         delete($breakpoints_data{$filename});
3891     }
3892
3893     return;
3894 }
3895
3896 sub _set_breakpoint_enabled_status {
3897     my ($filename, $line, $status) = @_;
3898
3899     _get_breakpoint_data_ref($filename, $line)->{'enabled'} =
3900         ($status ? 1 : '')
3901         ;
3902
3903     return;
3904 }
3905
3906 sub _enable_breakpoint_temp_enabled_status {
3907     my ($filename, $line) = @_;
3908
3909     _get_breakpoint_data_ref($filename, $line)->{'temp_enabled'} = 1;
3910
3911     return;
3912 }
3913
3914 sub _cancel_breakpoint_temp_enabled_status {
3915     my ($filename, $line) = @_;
3916
3917     my $ref = _get_breakpoint_data_ref($filename, $line);
3918     
3919     delete ($ref->{'temp_enabled'});
3920
3921     if (! %$ref) {
3922         _delete_breakpoint_data_ref($filename, $line);
3923     }
3924
3925     return;
3926 }
3927
3928 sub _is_breakpoint_enabled {
3929     my ($filename, $line) = @_;
3930
3931     my $data_ref = _get_breakpoint_data_ref($filename, $line);
3932     return ($data_ref->{'enabled'} || $data_ref->{'temp_enabled'});
3933 }
3934
3935 =head2 C<cmd_wrapper()> (API)
3936
3937 C<cmd_wrapper()> allows the debugger to switch command sets 
3938 depending on the value of the C<CommandSet> option. 
3939
3940 It tries to look up the command in the C<%set> package-level I<lexical>
3941 (which means external entities can't fiddle with it) and create the name of 
3942 the sub to call based on the value found in the hash (if it's there). I<All> 
3943 of the commands to be handled in a set have to be added to C<%set>; if they 
3944 aren't found, the 5.8.0 equivalent is called (if there is one).
3945
3946 This code uses symbolic references. 
3947
3948 =cut
3949
3950 sub cmd_wrapper {
3951     my $cmd      = shift;
3952     my $line     = shift;
3953     my $dblineno = shift;
3954
3955     # Assemble the command subroutine's name by looking up the
3956     # command set and command name in %set. If we can't find it,
3957     # default to the older version of the command.
3958     my $call = 'cmd_'
3959       . ( $set{$CommandSet}{$cmd}
3960           || ( $cmd =~ /^[<>{]+/o ? 'prepost' : $cmd ) );
3961
3962     # Call the command subroutine, call it by name.
3963     return __PACKAGE__->can($call)->( $cmd, $line, $dblineno );
3964 } ## end sub cmd_wrapper
3965
3966 =head3 C<cmd_a> (command)
3967
3968 The C<a> command handles pre-execution actions. These are associated with a
3969 particular line, so they're stored in C<%dbline>. We default to the current 
3970 line if none is specified. 
3971
3972 =cut
3973
3974 sub cmd_a {
3975     my $cmd    = shift;
3976     my $line   = shift || '';    # [.|line] expr
3977     my $dbline = shift;
3978
3979     # If it's dot (here), or not all digits,  use the current line.
3980     $line =~ s/^(\.|(?:[^\d]))/$dbline/;
3981
3982     # Should be a line number followed by an expression.
3983     if ( $line =~ /^\s*(\d*)\s*(\S.+)/ ) {
3984         my ( $lineno, $expr ) = ( $1, $2 );
3985
3986         # If we have an expression ...
3987         if ( length $expr ) {
3988
3989             # ... but the line isn't breakable, complain.
3990             if ( $dbline[$lineno] == 0 ) {
3991                 print $OUT
3992                   "Line $lineno($dbline[$lineno]) does not have an action?\n";
3993             }
3994             else {
3995
3996                 # It's executable. Record that the line has an action.
3997                 $had_breakpoints{$filename} |= 2;
3998
3999                 # Remove any action, temp breakpoint, etc.
4000                 $dbline{$lineno} =~ s/\0[^\0]*//;
4001
4002                 # Add the action to the line.
4003                 $dbline{$lineno} .= "\0" . action($expr);
4004             }
4005         } ## end if (length $expr)
4006     } ## end if ($line =~ /^\s*(\d*)\s*(\S.+)/)
4007     else {
4008
4009         # Syntax wrong.
4010         print $OUT
4011           "Adding an action requires an optional lineno and an expression\n"
4012           ;    # hint
4013     }
4014 } ## end sub cmd_a
4015
4016 =head3 C<cmd_A> (command)
4017
4018 Delete actions. Similar to above, except the delete code is in a separate
4019 subroutine, C<delete_action>.
4020
4021 =cut
4022
4023 sub cmd_A {
4024     my $cmd    = shift;
4025     my $line   = shift || '';
4026     my $dbline = shift;
4027
4028     # Dot is this line.
4029     $line =~ s/^\./$dbline/;
4030
4031     # Call delete_action with a null param to delete them all.
4032     # The '1' forces the eval to be true. It'll be false only
4033     # if delete_action blows up for some reason, in which case
4034     # we print $@ and get out.
4035     if ( $line eq '*' ) {
4036         eval { &delete_action(); 1 } or print $OUT $@ and return;
4037     }
4038
4039     # There's a real line  number. Pass it to delete_action.
4040     # Error trapping is as above.
4041     elsif ( $line =~ /^(\S.*)/ ) {
4042         eval { &delete_action($1); 1 } or print $OUT $@ and return;
4043     }
4044
4045     # Swing and a miss. Bad syntax.
4046     else {
4047         print $OUT
4048           "Deleting an action requires a line number, or '*' for all\n" ; # hint
4049     }
4050 } ## end sub cmd_A
4051
4052 =head3 C<delete_action> (API)
4053
4054 C<delete_action> accepts either a line number or C<undef>. If a line number
4055 is specified, we check for the line being executable (if it's not, it 
4056 couldn't have had an  action). If it is, we just take the action off (this
4057 will get any kind of an action, including breakpoints).
4058
4059 =cut
4060
4061 sub delete_action {
4062     my $i = shift;
4063     if ( defined($i) ) {
4064
4065         # Can there be one?
4066         die "Line $i has no action .\n" if $dbline[$i] == 0;
4067
4068         # Nuke whatever's there.
4069         $dbline{$i} =~ s/\0[^\0]*//;    # \^a
4070         delete $dbline{$i} if $dbline{$i} eq '';
4071     }
4072     else {
4073         print $OUT "Deleting all actions...\n";
4074         for my $file ( keys %had_breakpoints ) {
4075             local *dbline = $main::{ '_<' . $file };
4076             $max = $#dbline;
4077             my $was;
4078             for $i (1 .. $max) {
4079                 if ( defined $dbline{$i} ) {
4080                     $dbline{$i} =~ s/\0[^\0]*//;
4081                     delete $dbline{$i} if $dbline{$i} eq '';
4082                 }
4083                 unless ( $had_breakpoints{$file} &= ~2 ) {
4084                     delete $had_breakpoints{$file};
4085                 }
4086             } ## end for ($i = 1 .. $max)
4087         } ## end for my $file (keys %had_breakpoints)
4088     } ## end else [ if (defined($i))
4089 } ## end sub delete_action
4090
4091 =head3 C<cmd_b> (command)
4092
4093 Set breakpoints. Since breakpoints can be set in so many places, in so many
4094 ways, conditionally or not, the breakpoint code is kind of complex. Mostly,
4095 we try to parse the command type, and then shuttle it off to an appropriate
4096 subroutine to actually do the work of setting the breakpoint in the right
4097 place.
4098
4099 =cut
4100
4101 sub cmd_b {
4102     my $cmd    = shift;
4103     my $line   = shift;    # [.|line] [cond]
4104     my $dbline = shift;
4105
4106     # Make . the current line number if it's there..
4107     $line =~ s/^\.(\s|\z)/$dbline$1/;
4108
4109     # No line number, no condition. Simple break on current line.
4110     if ( $line =~ /^\s*$/ ) {
4111         &cmd_b_line( $dbline, 1 );
4112     }
4113
4114     # Break on load for a file.
4115     elsif ( $line =~ /^load\b\s*(.*)/ ) {
4116         my $file = $1;
4117         $file =~ s/\s+$//;
4118         &cmd_b_load($file);
4119     }
4120
4121     # b compile|postpone <some sub> [<condition>]
4122     # The interpreter actually traps this one for us; we just put the
4123     # necessary condition in the %postponed hash.
4124     elsif ( $line =~ /^(postpone|compile)\b\s*([':A-Za-z_][':\w]*)\s*(.*)/ ) {
4125
4126         # Capture the condition if there is one. Make it true if none.
4127         my $cond = length $3 ? $3 : '1';
4128
4129         # Save the sub name and set $break to 1 if $1 was 'postpone', 0
4130         # if it was 'compile'.
4131         my ( $subname, $break ) = ( $2, $1 eq 'postpone' );
4132
4133         # De-Perl4-ify the name - ' separators to ::.
4134         $subname =~ s/\'/::/g;
4135
4136         # Qualify it into the current package unless it's already qualified.
4137         $subname = "${package}::" . $subname unless $subname =~ /::/;
4138
4139         # Add main if it starts with ::.
4140         $subname = "main" . $subname if substr( $subname, 0, 2 ) eq "::";
4141
4142         # Save the break type for this sub.
4143         $postponed{$subname} = $break ? "break +0 if $cond" : "compile";
4144     } ## end elsif ($line =~ ...
4145     # b <filename>:<line> [<condition>]
4146     elsif ($line =~ /\A(\S+[^:]):(\d+)\s*(.*)/ms) {
4147         my ($filename, $line_num, $cond) = ($1, $2, $3);
4148         cmd_b_filename_line(
4149             $filename,
4150             $line_num, 
4151             (length($cond) ? $cond : '1'),
4152         );
4153     }
4154     # b <sub name> [<condition>]
4155     elsif ( $line =~ /^([':A-Za-z_][':\w]*(?:\[.*\])?)\s*(.*)/ ) {
4156
4157         #
4158         $subname = $1;
4159         my $cond = length $2 ? $2 : '1';
4160         &cmd_b_sub( $subname, $cond );
4161     }
4162
4163     # b <line> [<condition>].
4164     elsif ( $line =~ /^(\d*)\s*(.*)/ ) {
4165
4166         # Capture the line. If none, it's the current line.
4167         $line = $1 || $dbline;
4168
4169         # If there's no condition, make it '1'.
4170         my $cond = length $2 ? $2 : '1';
4171
4172         # Break on line.
4173         &cmd_b_line( $line, $cond );
4174     }
4175
4176     # Line didn't make sense.
4177     else {
4178         print "confused by line($line)?\n";
4179     }
4180 } ## end sub cmd_b
4181
4182 =head3 C<break_on_load> (API)
4183
4184 We want to break when this file is loaded. Mark this file in the
4185 C<%break_on_load> hash, and note that it has a breakpoint in 
4186 C<%had_breakpoints>.
4187
4188 =cut
4189
4190 sub break_on_load {
4191     my $file = shift;
4192     $break_on_load{$file} = 1;
4193     $had_breakpoints{$file} |= 1;
4194 }
4195
4196 =head3 C<report_break_on_load> (API)
4197
4198 Gives us an array of filenames that are set to break on load. Note that 
4199 only files with break-on-load are in here, so simply showing the keys
4200 suffices.
4201
4202 =cut
4203
4204 sub report_break_on_load {
4205     sort keys %break_on_load;
4206 }
4207
4208 =head3 C<cmd_b_load> (command)
4209
4210 We take the file passed in and try to find it in C<%INC> (which maps modules
4211 to files they came from). We mark those files for break-on-load via 
4212 C<break_on_load> and then report that it was done.
4213
4214 =cut
4215
4216 sub cmd_b_load {
4217     my $file = shift;
4218     my @files;
4219
4220     # This is a block because that way we can use a redo inside it
4221     # even without there being any looping structure at all outside it.
4222     {
4223
4224         # Save short name and full path if found.
4225         push @files, $file;
4226         push @files, $::INC{$file} if $::INC{$file};
4227
4228         # Tack on .pm and do it again unless there was a '.' in the name
4229         # already.
4230         $file .= '.pm', redo unless $file =~ /\./;
4231     }
4232
4233     # Do the real work here.
4234     break_on_load($_) for @files;
4235
4236     # All the files that have break-on-load breakpoints.
4237     @files = report_break_on_load;
4238
4239     # Normalize for the purposes of our printing this.
4240     local $\ = '';
4241     local $" = ' ';
4242     print $OUT "Will stop on load of '@files'.\n";
4243 } ## end sub cmd_b_load
4244
4245 =head3 C<$filename_error> (API package global)
4246
4247 Several of the functions we need to implement in the API need to work both
4248 on the current file and on other files. We don't want to duplicate code, so
4249 C<$filename_error> is used to contain the name of the file that's being 
4250 worked on (if it's not the current one).
4251
4252 We can now build functions in pairs: the basic function works on the current
4253 file, and uses C<$filename_error> as part of its error message. Since this is
4254 initialized to C<"">, no filename will appear when we are working on the
4255 current file.
4256
4257 The second function is a wrapper which does the following:
4258
4259 =over 4 
4260
4261 =item *
4262
4263 Localizes C<$filename_error> and sets it to the name of the file to be processed.
4264
4265 =item *
4266
4267 Localizes the C<*dbline> glob and reassigns it to point to the file we want to process. 
4268
4269 =item *
4270
4271 Calls the first function. 
4272
4273 The first function works on the I<current> file (i.e., the one we changed to),
4274 and prints C<$filename_error> in the error message (the name of the other file)
4275 if it needs to. When the functions return, C<*dbline> is restored to point
4276 to the actual current file (the one we're executing in) and
4277 C<$filename_error> is restored to C<"">. This restores everything to
4278 the way it was before the second function was called at all.
4279
4280 See the comments in C<breakable_line> and C<breakable_line_in_file> for more
4281 details.
4282
4283 =back
4284
4285 =cut
4286
4287 use vars qw($filename_error);
4288 $filename_error = '';
4289
4290 =head3 breakable_line(from, to) (API)
4291
4292 The subroutine decides whether or not a line in the current file is breakable.
4293 It walks through C<@dbline> within the range of lines specified, looking for
4294 the first line that is breakable.
4295
4296 If C<$to> is greater than C<$from>, the search moves forwards, finding the 
4297 first line I<after> C<$to> that's breakable, if there is one.
4298
4299 If C<$from> is greater than C<$to>, the search goes I<backwards>, finding the
4300 first line I<before> C<$to> that's breakable, if there is one.
4301
4302 =cut
4303
4304 sub breakable_line {
4305
4306     my ( $from, $to ) = @_;
4307
4308     # $i is the start point. (Where are the FORTRAN programs of yesteryear?)
4309     my $i = $from;
4310
4311     # If there are at least 2 arguments, we're trying to search a range.
4312     if ( @_ >= 2 ) {
4313
4314         # $delta is positive for a forward search, negative for a backward one.
4315         my $delta = $from < $to ? +1 : -1;
4316
4317         # Keep us from running off the ends of the file.
4318         my $limit = $delta > 0 ? $#dbline : 1;
4319
4320         # Clever test. If you're a mathematician, it's obvious why this
4321         # test works. If not:
4322         # If $delta is positive (going forward), $limit will be $#dbline.
4323         #    If $to is less than $limit, ($limit - $to) will be positive, times
4324         #    $delta of 1 (positive), so the result is > 0 and we should use $to
4325         #    as the stopping point.
4326         #
4327         #    If $to is greater than $limit, ($limit - $to) is negative,
4328         #    times $delta of 1 (positive), so the result is < 0 and we should
4329         #    use $limit ($#dbline) as the stopping point.
4330         #
4331         # If $delta is negative (going backward), $limit will be 1.
4332         #    If $to is zero, ($limit - $to) will be 1, times $delta of -1
4333         #    (negative) so the result is > 0, and we use $to as the stopping
4334         #    point.
4335         #
4336         #    If $to is less than zero, ($limit - $to) will be positive,
4337         #    times $delta of -1 (negative), so the result is not > 0, and
4338         #    we use $limit (1) as the stopping point.
4339         #
4340         #    If $to is 1, ($limit - $to) will zero, times $delta of -1
4341         #    (negative), still giving zero; the result is not > 0, and
4342         #    we use $limit (1) as the stopping point.
4343         #
4344         #    if $to is >1, ($limit - $to) will be negative, times $delta of -1
4345         #    (negative), giving a positive (>0) value, so we'll set $limit to
4346         #    $to.
4347
4348         $limit = $to if ( $limit - $to ) * $delta > 0;
4349
4350         # The real search loop.
4351         # $i starts at $from (the point we want to start searching from).
4352         # We move through @dbline in the appropriate direction (determined
4353         # by $delta: either -1 (back) or +1 (ahead).
4354         # We stay in as long as we haven't hit an executable line
4355         # ($dbline[$i] == 0 means not executable) and we haven't reached
4356         # the limit yet (test similar to the above).
4357         $i += $delta while $dbline[$i] == 0 and ( $limit - $i ) * $delta > 0;
4358
4359     } ## end if (@_ >= 2)
4360
4361     # If $i points to a line that is executable, return that.
4362     return $i unless $dbline[$i] == 0;
4363
4364     # Format the message and print it: no breakable lines in range.
4365     my ( $pl, $upto ) = ( '', '' );
4366     ( $pl, $upto ) = ( 's', "..$to" ) if @_ >= 2 and $from != $to;
4367
4368     # If there's a filename in filename_error, we'll see it.
4369     # If not, not.
4370     die "Line$pl $from$upto$filename_error not breakable\n";
4371 } ## end sub breakable_line
4372
4373 =head3 breakable_line_in_filename(file, from, to) (API)
4374
4375 Like C<breakable_line>, but look in another file.
4376
4377 =cut
4378
4379 sub breakable_line_in_filename {
4380
4381     # Capture the file name.
4382     my ($f) = shift;
4383
4384     # Swap the magic line array over there temporarily.
4385     local *dbline = $main::{ '_<' . $f };
4386
4387     # If there's an error, it's in this other file.
4388     local $filename_error = " of '$f'";
4389
4390     # Find the breakable line.
4391     breakable_line(@_);
4392
4393     # *dbline and $filename_error get restored when this block ends.
4394
4395 } ## end sub breakable_line_in_filename
4396
4397 =head3 break_on_line(lineno, [condition]) (API)
4398
4399 Adds a breakpoint with the specified condition (or 1 if no condition was 
4400 specified) to the specified line. Dies if it can't.
4401
4402 =cut
4403
4404 sub break_on_line {
4405     my ( $i, $cond ) = @_;
4406
4407     # Always true if no condition supplied.
4408     $cond = 1 unless @_ >= 2;
4409
4410     my $inii  = $i;
4411     my $after = '';
4412     my $pl    = '';
4413
4414     # Woops, not a breakable line. $filename_error allows us to say
4415     # if it was in a different file.
4416     die "Line $i$filename_error not breakable.\n" if $dbline[$i] == 0;
4417
4418     # Mark this file as having breakpoints in it.
4419     $had_breakpoints{$filename} |= 1;
4420
4421     # If there is an action or condition here already ...
4422     if ( $dbline{$i} ) {
4423
4424         # ... swap this condition for the existing one.
4425         $dbline{$i} =~ s/^[^\0]*/$cond/;
4426     }
4427     else {
4428
4429         # Nothing here - just add the condition.
4430         $dbline{$i} = $cond;
4431
4432         _set_breakpoint_enabled_status($filename, $i, 1);
4433     }
4434 } ## end sub break_on_line
4435
4436 =head3 cmd_b_line(line, [condition]) (command)
4437
4438 Wrapper for C<break_on_line>. Prints the failure message if it 
4439 doesn't work.
4440
4441 =cut 
4442
4443 sub cmd_b_line {
4444     eval { break_on_line(@_); 1 } or do {
4445         local $\ = '';
4446         print $OUT $@ and return;
4447     };
4448 } ## end sub cmd_b_line
4449
4450 =head3 cmd_b_filename_line(line, [condition]) (command)
4451
4452 Wrapper for C<break_on_filename_line>. Prints the failure message if it 
4453 doesn't work.
4454
4455 =cut 
4456
4457 sub cmd_b_filename_line {
4458     eval { break_on_filename_line(@_); 1 } or do {
4459         local $\ = '';
4460         print $OUT $@ and return;
4461     };
4462 }
4463
4464 =head3 break_on_filename_line(file, line, [condition]) (API)
4465
4466 Switches to the file specified and then calls C<break_on_line> to set 
4467 the breakpoint.
4468
4469 =cut
4470
4471 sub break_on_filename_line {
4472     my ( $f, $i, $cond ) = @_;
4473
4474     # Always true if condition left off.
4475     $cond = 1 unless @_ >= 3;
4476
4477     # Switch the magical hash temporarily.
4478     local *dbline = $main::{ '_<' . $f };
4479
4480     # Localize the variables that break_on_line uses to make its message.
4481     local $filename_error = " of '$f'";
4482     local $filename       = $f;
4483
4484     # Add the breakpoint.
4485     break_on_line( $i, $cond );
4486 } ## end sub break_on_filename_line
4487
4488 =head3 break_on_filename_line_range(file, from, to, [condition]) (API)
4489
4490 Switch to another file, search the range of lines specified for an 
4491 executable one, and put a breakpoint on the first one you find.
4492
4493 =cut
4494
4495 sub break_on_filename_line_range {
4496     my ( $f, $from, $to, $cond ) = @_;
4497
4498     # Find a breakable line if there is one.
4499     my $i = breakable_line_in_filename( $f, $from, $to );
4500
4501     # Always true if missing.
4502     $cond = 1 unless @_ >= 3;
4503
4504     # Add the breakpoint.
4505     break_on_filename_line( $f, $i, $cond );
4506 } ## end sub break_on_filename_line_range
4507
4508 =head3 subroutine_filename_lines(subname, [condition]) (API)
4509
4510 Search for a subroutine within a given file. The condition is ignored.
4511 Uses C<find_sub> to locate the desired subroutine.
4512
4513 =cut
4514
4515 sub subroutine_filename_lines {
4516     my ( $subname, $cond ) = @_;
4517
4518     # Returned value from find_sub() is fullpathname:startline-endline.
4519     # The match creates the list (fullpathname, start, end). Falling off
4520     # the end of the subroutine returns this implicitly.
4521     find_sub($subname) =~ /^(.*):(\d+)-(\d+)$/;
4522 } ## end sub subroutine_filename_lines
4523
4524 =head3 break_subroutine(subname) (API)
4525
4526 Places a break on the first line possible in the specified subroutine. Uses
4527 C<subroutine_filename_lines> to find the subroutine, and 
4528 C<break_on_filename_line_range> to place the break.
4529
4530 =cut
4531
4532 sub break_subroutine {
4533     my $subname = shift;
4534
4535     # Get filename, st