378a74c1922af283f176e24e9c31321f34bd054e
[perl.git] / pod / perlop.pod
1 =head1 NAME
2 X<operator>
3
4 perlop - Perl operators and precedence
5
6 =head1 DESCRIPTION
7
8 =head2 Operator Precedence and Associativity
9 X<operator, precedence> X<precedence> X<associativity>
10
11 Operator precedence and associativity work in Perl more or less like
12 they do in mathematics.
13
14 I<Operator precedence> means some operators are evaluated before
15 others.  For example, in C<2 + 4 * 5>, the multiplication has higher
16 precedence so C<4 * 5> is evaluated first yielding C<2 + 20 ==
17 22> and not C<6 * 5 == 30>.
18
19 I<Operator associativity> defines what happens if a sequence of the
20 same operators is used one after another: whether the evaluator will
21 evaluate the left operations first or the right.  For example, in C<8
22 - 4 - 2>, subtraction is left associative so Perl evaluates the
23 expression left to right.  C<8 - 4> is evaluated first making the
24 expression C<4 - 2 == 2> and not C<8 - 2 == 6>.
25
26 Perl operators have the following associativity and precedence,
27 listed from highest precedence to lowest.  Operators borrowed from
28 C keep the same precedence relationship with each other, even where
29 C's precedence is slightly screwy.  (This makes learning Perl easier
30 for C folks.)  With very few exceptions, these all operate on scalar
31 values only, not array values.
32
33     left        terms and list operators (leftward)
34     left        ->
35     nonassoc    ++ --
36     right       **
37     right       ! ~ \ and unary + and -
38     left        =~ !~
39     left        * / % x
40     left        + - .
41     left        << >>
42     nonassoc    named unary operators
43     nonassoc    < > <= >= lt gt le ge
44     nonassoc    == != <=> eq ne cmp ~~
45     left        &
46     left        | ^
47     left        &&
48     left        || //
49     nonassoc    ..  ...
50     right       ?:
51     right       = += -= *= etc.
52     left        , =>
53     nonassoc    list operators (rightward)
54     right       not
55     left        and
56     left        or xor
57
58 In the following sections, these operators are covered in precedence order.
59
60 Many operators can be overloaded for objects.  See L<overload>.
61
62 =head2 Terms and List Operators (Leftward)
63 X<list operator> X<operator, list> X<term>
64
65 A TERM has the highest precedence in Perl.  They include variables,
66 quote and quote-like operators, any expression in parentheses,
67 and any function whose arguments are parenthesized.  Actually, there
68 aren't really functions in this sense, just list operators and unary
69 operators behaving as functions because you put parentheses around
70 the arguments.  These are all documented in L<perlfunc>.
71
72 If any list operator (print(), etc.) or any unary operator (chdir(), etc.)
73 is followed by a left parenthesis as the next token, the operator and
74 arguments within parentheses are taken to be of highest precedence,
75 just like a normal function call.
76
77 In the absence of parentheses, the precedence of list operators such as
78 C<print>, C<sort>, or C<chmod> is either very high or very low depending on
79 whether you are looking at the left side or the right side of the operator.
80 For example, in
81
82     @ary = (1, 3, sort 4, 2);
83     print @ary;         # prints 1324
84
85 the commas on the right of the sort are evaluated before the sort,
86 but the commas on the left are evaluated after.  In other words,
87 list operators tend to gobble up all arguments that follow, and
88 then act like a simple TERM with regard to the preceding expression.
89 Be careful with parentheses:
90
91     # These evaluate exit before doing the print:
92     print($foo, exit);  # Obviously not what you want.
93     print $foo, exit;   # Nor is this.
94
95     # These do the print before evaluating exit:
96     (print $foo), exit; # This is what you want.
97     print($foo), exit;  # Or this.
98     print ($foo), exit; # Or even this.
99
100 Also note that
101
102     print ($foo & 255) + 1, "\n";
103
104 probably doesn't do what you expect at first glance.  The parentheses
105 enclose the argument list for C<print> which is evaluated (printing
106 the result of C<$foo & 255>).  Then one is added to the return value
107 of C<print> (usually 1).  The result is something like this:
108
109     1 + 1, "\n";    # Obviously not what you meant.
110
111 To do what you meant properly, you must write:
112
113     print(($foo & 255) + 1, "\n");
114
115 See L<Named Unary Operators> for more discussion of this.
116
117 Also parsed as terms are the C<do {}> and C<eval {}> constructs, as
118 well as subroutine and method calls, and the anonymous
119 constructors C<[]> and C<{}>.
120
121 See also L<Quote and Quote-like Operators> toward the end of this section,
122 as well as L</"I/O Operators">.
123
124 =head2 The Arrow Operator
125 X<arrow> X<dereference> X<< -> >>
126
127 "C<< -> >>" is an infix dereference operator, just as it is in C
128 and C++.  If the right side is either a C<[...]>, C<{...}>, or a
129 C<(...)> subscript, then the left side must be either a hard or
130 symbolic reference to an array, a hash, or a subroutine respectively.
131 (Or technically speaking, a location capable of holding a hard
132 reference, if it's an array or hash reference being used for
133 assignment.)  See L<perlreftut> and L<perlref>.
134
135 Otherwise, the right side is a method name or a simple scalar
136 variable containing either the method name or a subroutine reference,
137 and the left side must be either an object (a blessed reference)
138 or a class name (that is, a package name).  See L<perlobj>.
139
140 =head2 Auto-increment and Auto-decrement
141 X<increment> X<auto-increment> X<++> X<decrement> X<auto-decrement> X<-->
142
143 "++" and "--" work as in C.  That is, if placed before a variable,
144 they increment or decrement the variable by one before returning the
145 value, and if placed after, increment or decrement after returning the
146 value.
147
148     $i = 0;  $j = 0;
149     print $i++;  # prints 0
150     print ++$j;  # prints 1
151
152 Note that just as in C, Perl doesn't define B<when> the variable is
153 incremented or decremented. You just know it will be done sometime
154 before or after the value is returned. This also means that modifying
155 a variable twice in the same statement will lead to undefined behaviour.
156 Avoid statements like:
157
158     $i = $i ++;
159     print ++ $i + $i ++;
160
161 Perl will not guarantee what the result of the above statements is.
162
163 The auto-increment operator has a little extra builtin magic to it.  If
164 you increment a variable that is numeric, or that has ever been used in
165 a numeric context, you get a normal increment.  If, however, the
166 variable has been used in only string contexts since it was set, and
167 has a value that is not the empty string and matches the pattern
168 C</^[a-zA-Z]*[0-9]*\z/>, the increment is done as a string, preserving each
169 character within its range, with carry:
170
171     print ++($foo = '99');      # prints '100'
172     print ++($foo = 'a0');      # prints 'a1'
173     print ++($foo = 'Az');      # prints 'Ba'
174     print ++($foo = 'zz');      # prints 'aaa'
175
176 C<undef> is always treated as numeric, and in particular is changed
177 to C<0> before incrementing (so that a post-increment of an undef value
178 will return C<0> rather than C<undef>).
179
180 The auto-decrement operator is not magical.
181
182 =head2 Exponentiation
183 X<**> X<exponentiation> X<power>
184
185 Binary "**" is the exponentiation operator.  It binds even more
186 tightly than unary minus, so -2**4 is -(2**4), not (-2)**4. (This is
187 implemented using C's pow(3) function, which actually works on doubles
188 internally.)
189
190 =head2 Symbolic Unary Operators
191 X<unary operator> X<operator, unary>
192
193 Unary "!" performs logical negation, i.e., "not".  See also C<not> for a lower
194 precedence version of this.
195 X<!>
196
197 Unary "-" performs arithmetic negation if the operand is numeric.  If
198 the operand is an identifier, a string consisting of a minus sign
199 concatenated with the identifier is returned.  Otherwise, if the string
200 starts with a plus or minus, a string starting with the opposite sign
201 is returned.  One effect of these rules is that -bareword is equivalent
202 to the string "-bareword".  If, however, the string begins with a
203 non-alphabetic character (excluding "+" or "-"), Perl will attempt to convert
204 the string to a numeric and the arithmetic negation is performed. If the
205 string cannot be cleanly converted to a numeric, Perl will give the warning
206 B<Argument "the string" isn't numeric in negation (-) at ...>.
207 X<-> X<negation, arithmetic>
208
209 Unary "~" performs bitwise negation, i.e., 1's complement.  For
210 example, C<0666 & ~027> is 0640.  (See also L<Integer Arithmetic> and
211 L<Bitwise String Operators>.)  Note that the width of the result is
212 platform-dependent: ~0 is 32 bits wide on a 32-bit platform, but 64
213 bits wide on a 64-bit platform, so if you are expecting a certain bit
214 width, remember to use the & operator to mask off the excess bits.
215 X<~> X<negation, binary>
216
217 Unary "+" has no effect whatsoever, even on strings.  It is useful
218 syntactically for separating a function name from a parenthesized expression
219 that would otherwise be interpreted as the complete list of function
220 arguments.  (See examples above under L<Terms and List Operators (Leftward)>.)
221 X<+>
222
223 Unary "\" creates a reference to whatever follows it.  See L<perlreftut>
224 and L<perlref>.  Do not confuse this behavior with the behavior of
225 backslash within a string, although both forms do convey the notion
226 of protecting the next thing from interpolation.
227 X<\> X<reference> X<backslash>
228
229 =head2 Binding Operators
230 X<binding> X<operator, binding> X<=~> X<!~>
231
232 Binary "=~" binds a scalar expression to a pattern match.  Certain operations
233 search or modify the string $_ by default.  This operator makes that kind
234 of operation work on some other string.  The right argument is a search
235 pattern, substitution, or transliteration.  The left argument is what is
236 supposed to be searched, substituted, or transliterated instead of the default
237 $_.  When used in scalar context, the return value generally indicates the
238 success of the operation.  Behavior in list context depends on the particular
239 operator.  See L</"Regexp Quote-Like Operators"> for details and
240 L<perlretut> for examples using these operators.
241
242 If the right argument is an expression rather than a search pattern,
243 substitution, or transliteration, it is interpreted as a search pattern at run
244 time. Note that this means that its contents will be interpolated twice, so
245
246   '\\' =~ q'\\';
247
248 is not ok, as the regex engine will end up trying to compile the
249 pattern C<\>, which it will consider a syntax error.
250
251 Binary "!~" is just like "=~" except the return value is negated in
252 the logical sense.
253
254 =head2 Multiplicative Operators
255 X<operator, multiplicative>
256
257 Binary "*" multiplies two numbers.
258 X<*>
259
260 Binary "/" divides two numbers.
261 X</> X<slash>
262
263 Binary "%" is the modulo operator, which computes the division
264 remainder of its first argument with respect to its second argument.
265 Given integer
266 operands C<$a> and C<$b>: If C<$b> is positive, then C<$a % $b> is
267 C<$a> minus the largest multiple of C<$b> less than or equal to
268 C<$a>.  If C<$b> is negative, then C<$a % $b> is C<$a> minus the
269 smallest multiple of C<$b> that is not less than C<$a> (i.e. the
270 result will be less than or equal to zero).  If the operands
271 C<$a> and C<$b> are floating point values and the absolute value of
272 C<$b> (that is C<abs($b)>) is less than C<(UV_MAX + 1)>, only
273 the integer portion of C<$a> and C<$b> will be used in the operation
274 (Note: here C<UV_MAX> means the maximum of the unsigned integer type).
275 If the absolute value of the right operand (C<abs($b)>) is greater than
276 or equal to C<(UV_MAX + 1)>, "%" computes the floating-point remainder
277 C<$r> in the equation C<($r = $a - $i*$b)> where C<$i> is a certain
278 integer that makes C<$r> have the same sign as the right operand
279 C<$b> (B<not> as the left operand C<$a> like C function C<fmod()>)
280 and the absolute value less than that of C<$b>.
281 Note that when C<use integer> is in scope, "%" gives you direct access
282 to the modulo operator as implemented by your C compiler.  This
283 operator is not as well defined for negative operands, but it will
284 execute faster.
285 X<%> X<remainder> X<modulo> X<mod>
286
287 Binary "x" is the repetition operator.  In scalar context or if the left
288 operand is not enclosed in parentheses, it returns a string consisting
289 of the left operand repeated the number of times specified by the right
290 operand.  In list context, if the left operand is enclosed in
291 parentheses or is a list formed by C<qw/STRING/>, it repeats the list.
292 If the right operand is zero or negative, it returns an empty string
293 or an empty list, depending on the context.
294 X<x>
295
296     print '-' x 80;             # print row of dashes
297
298     print "\t" x ($tab/8), ' ' x ($tab%8);      # tab over
299
300     @ones = (1) x 80;           # a list of 80 1's
301     @ones = (5) x @ones;        # set all elements to 5
302
303
304 =head2 Additive Operators
305 X<operator, additive>
306
307 Binary "+" returns the sum of two numbers.
308 X<+>
309
310 Binary "-" returns the difference of two numbers.
311 X<->
312
313 Binary "." concatenates two strings.
314 X<string, concatenation> X<concatenation>
315 X<cat> X<concat> X<concatenate> X<.>
316
317 =head2 Shift Operators
318 X<shift operator> X<operator, shift> X<<< << >>>
319 X<<< >> >>> X<right shift> X<left shift> X<bitwise shift>
320 X<shl> X<shr> X<shift, right> X<shift, left>
321
322 Binary "<<" returns the value of its left argument shifted left by the
323 number of bits specified by the right argument.  Arguments should be
324 integers.  (See also L<Integer Arithmetic>.)
325
326 Binary ">>" returns the value of its left argument shifted right by
327 the number of bits specified by the right argument.  Arguments should
328 be integers.  (See also L<Integer Arithmetic>.)
329
330 Note that both "<<" and ">>" in Perl are implemented directly using
331 "<<" and ">>" in C.  If C<use integer> (see L<Integer Arithmetic>) is
332 in force then signed C integers are used, else unsigned C integers are
333 used.  Either way, the implementation isn't going to generate results
334 larger than the size of the integer type Perl was built with (32 bits
335 or 64 bits).
336
337 The result of overflowing the range of the integers is undefined
338 because it is undefined also in C.  In other words, using 32-bit
339 integers, C<< 1 << 32 >> is undefined.  Shifting by a negative number
340 of bits is also undefined.
341
342 =head2 Named Unary Operators
343 X<operator, named unary>
344
345 The various named unary operators are treated as functions with one
346 argument, with optional parentheses.
347
348 If any list operator (print(), etc.) or any unary operator (chdir(), etc.)
349 is followed by a left parenthesis as the next token, the operator and
350 arguments within parentheses are taken to be of highest precedence,
351 just like a normal function call.  For example,
352 because named unary operators are higher precedence than ||:
353
354     chdir $foo    || die;       # (chdir $foo) || die
355     chdir($foo)   || die;       # (chdir $foo) || die
356     chdir ($foo)  || die;       # (chdir $foo) || die
357     chdir +($foo) || die;       # (chdir $foo) || die
358
359 but, because * is higher precedence than named operators:
360
361     chdir $foo * 20;    # chdir ($foo * 20)
362     chdir($foo) * 20;   # (chdir $foo) * 20
363     chdir ($foo) * 20;  # (chdir $foo) * 20
364     chdir +($foo) * 20; # chdir ($foo * 20)
365
366     rand 10 * 20;       # rand (10 * 20)
367     rand(10) * 20;      # (rand 10) * 20
368     rand (10) * 20;     # (rand 10) * 20
369     rand +(10) * 20;    # rand (10 * 20)
370
371 Regarding precedence, the filetest operators, like C<-f>, C<-M>, etc. are
372 treated like named unary operators, but they don't follow this functional
373 parenthesis rule.  That means, for example, that C<-f($file).".bak"> is
374 equivalent to C<-f "$file.bak">.
375 X<-X> X<filetest> X<operator, filetest>
376
377 See also L<"Terms and List Operators (Leftward)">.
378
379 =head2 Relational Operators
380 X<relational operator> X<operator, relational>
381
382 Binary "<" returns true if the left argument is numerically less than
383 the right argument.
384 X<< < >>
385
386 Binary ">" returns true if the left argument is numerically greater
387 than the right argument.
388 X<< > >>
389
390 Binary "<=" returns true if the left argument is numerically less than
391 or equal to the right argument.
392 X<< <= >>
393
394 Binary ">=" returns true if the left argument is numerically greater
395 than or equal to the right argument.
396 X<< >= >>
397
398 Binary "lt" returns true if the left argument is stringwise less than
399 the right argument.
400 X<< lt >>
401
402 Binary "gt" returns true if the left argument is stringwise greater
403 than the right argument.
404 X<< gt >>
405
406 Binary "le" returns true if the left argument is stringwise less than
407 or equal to the right argument.
408 X<< le >>
409
410 Binary "ge" returns true if the left argument is stringwise greater
411 than or equal to the right argument.
412 X<< ge >>
413
414 =head2 Equality Operators
415 X<equality> X<equal> X<equals> X<operator, equality>
416
417 Binary "==" returns true if the left argument is numerically equal to
418 the right argument.
419 X<==>
420
421 Binary "!=" returns true if the left argument is numerically not equal
422 to the right argument.
423 X<!=>
424
425 Binary "<=>" returns -1, 0, or 1 depending on whether the left
426 argument is numerically less than, equal to, or greater than the right
427 argument.  If your platform supports NaNs (not-a-numbers) as numeric
428 values, using them with "<=>" returns undef.  NaN is not "<", "==", ">",
429 "<=" or ">=" anything (even NaN), so those 5 return false. NaN != NaN
430 returns true, as does NaN != anything else. If your platform doesn't
431 support NaNs then NaN is just a string with numeric value 0.
432 X<< <=> >> X<spaceship>
433
434     perl -le '$a = "NaN"; print "No NaN support here" if $a == $a'
435     perl -le '$a = "NaN"; print "NaN support here" if $a != $a'
436
437 Binary "eq" returns true if the left argument is stringwise equal to
438 the right argument.
439 X<eq>
440
441 Binary "ne" returns true if the left argument is stringwise not equal
442 to the right argument.
443 X<ne>
444
445 Binary "cmp" returns -1, 0, or 1 depending on whether the left
446 argument is stringwise less than, equal to, or greater than the right
447 argument.
448 X<cmp>
449
450 Binary "~~" does a smart match between its arguments. Smart matching
451 is described in L<perlsyn/"Smart matching in detail">.
452 X<~~>
453
454 "lt", "le", "ge", "gt" and "cmp" use the collation (sort) order specified
455 by the current locale if C<use locale> is in effect.  See L<perllocale>.
456
457 =head2 Bitwise And
458 X<operator, bitwise, and> X<bitwise and> X<&>
459
460 Binary "&" returns its operands ANDed together bit by bit.
461 (See also L<Integer Arithmetic> and L<Bitwise String Operators>.)
462
463 Note that "&" has lower priority than relational operators, so for example
464 the brackets are essential in a test like
465
466         print "Even\n" if ($x & 1) == 0;
467
468 =head2 Bitwise Or and Exclusive Or
469 X<operator, bitwise, or> X<bitwise or> X<|> X<operator, bitwise, xor>
470 X<bitwise xor> X<^>
471
472 Binary "|" returns its operands ORed together bit by bit.
473 (See also L<Integer Arithmetic> and L<Bitwise String Operators>.)
474
475 Binary "^" returns its operands XORed together bit by bit.
476 (See also L<Integer Arithmetic> and L<Bitwise String Operators>.)
477
478 Note that "|" and "^" have lower priority than relational operators, so
479 for example the brackets are essential in a test like
480
481         print "false\n" if (8 | 2) != 10;
482
483 =head2 C-style Logical And
484 X<&&> X<logical and> X<operator, logical, and>
485
486 Binary "&&" performs a short-circuit logical AND operation.  That is,
487 if the left operand is false, the right operand is not even evaluated.
488 Scalar or list context propagates down to the right operand if it
489 is evaluated.
490
491 =head2 C-style Logical Or
492 X<||> X<operator, logical, or>
493
494 Binary "||" performs a short-circuit logical OR operation.  That is,
495 if the left operand is true, the right operand is not even evaluated.
496 Scalar or list context propagates down to the right operand if it
497 is evaluated.
498
499 =head2 C-style Logical Defined-Or
500 X<//> X<operator, logical, defined-or>
501
502 Although it has no direct equivalent in C, Perl's C<//> operator is related
503 to its C-style or.  In fact, it's exactly the same as C<||>, except that it
504 tests the left hand side's definedness instead of its truth.  Thus, C<$a // $b>
505 is similar to C<defined($a) || $b> (except that it returns the value of C<$a>
506 rather than the value of C<defined($a)>) and is exactly equivalent to
507 C<defined($a) ? $a : $b>.  This is very useful for providing default values
508 for variables.  If you actually want to test if at least one of C<$a> and
509 C<$b> is defined, use C<defined($a // $b)>.
510
511 The C<||>, C<//> and C<&&> operators return the last value evaluated
512 (unlike C's C<||> and C<&&>, which return 0 or 1). Thus, a reasonably
513 portable way to find out the home directory might be:
514
515     $home = $ENV{'HOME'} // $ENV{'LOGDIR'} //
516         (getpwuid($<))[7] // die "You're homeless!\n";
517
518 In particular, this means that you shouldn't use this
519 for selecting between two aggregates for assignment:
520
521     @a = @b || @c;              # this is wrong
522     @a = scalar(@b) || @c;      # really meant this
523     @a = @b ? @b : @c;          # this works fine, though
524
525 As more readable alternatives to C<&&> and C<||> when used for
526 control flow, Perl provides the C<and> and C<or> operators (see below).
527 The short-circuit behavior is identical.  The precedence of "and"
528 and "or" is much lower, however, so that you can safely use them after a
529 list operator without the need for parentheses:
530
531     unlink "alpha", "beta", "gamma"
532             or gripe(), next LINE;
533
534 With the C-style operators that would have been written like this:
535
536     unlink("alpha", "beta", "gamma")
537             || (gripe(), next LINE);
538
539 Using "or" for assignment is unlikely to do what you want; see below.
540
541 =head2 Range Operators
542 X<operator, range> X<range> X<..> X<...>
543
544 Binary ".." is the range operator, which is really two different
545 operators depending on the context.  In list context, it returns a
546 list of values counting (up by ones) from the left value to the right
547 value.  If the left value is greater than the right value then it
548 returns the empty list.  The range operator is useful for writing
549 C<foreach (1..10)> loops and for doing slice operations on arrays. In
550 the current implementation, no temporary array is created when the
551 range operator is used as the expression in C<foreach> loops, but older
552 versions of Perl might burn a lot of memory when you write something
553 like this:
554
555     for (1 .. 1_000_000) {
556         # code
557     }
558
559 The range operator also works on strings, using the magical auto-increment,
560 see below.
561
562 In scalar context, ".." returns a boolean value.  The operator is
563 bistable, like a flip-flop, and emulates the line-range (comma) operator
564 of B<sed>, B<awk>, and various editors.  Each ".." operator maintains its
565 own boolean state.  It is false as long as its left operand is false.
566 Once the left operand is true, the range operator stays true until the
567 right operand is true, I<AFTER> which the range operator becomes false
568 again.  It doesn't become false till the next time the range operator is
569 evaluated.  It can test the right operand and become false on the same
570 evaluation it became true (as in B<awk>), but it still returns true once.
571 If you don't want it to test the right operand until the next
572 evaluation, as in B<sed>, just use three dots ("...") instead of
573 two.  In all other regards, "..." behaves just like ".." does.
574
575 The right operand is not evaluated while the operator is in the
576 "false" state, and the left operand is not evaluated while the
577 operator is in the "true" state.  The precedence is a little lower
578 than || and &&.  The value returned is either the empty string for
579 false, or a sequence number (beginning with 1) for true.  The
580 sequence number is reset for each range encountered.  The final
581 sequence number in a range has the string "E0" appended to it, which
582 doesn't affect its numeric value, but gives you something to search
583 for if you want to exclude the endpoint.  You can exclude the
584 beginning point by waiting for the sequence number to be greater
585 than 1.
586
587 If either operand of scalar ".." is a constant expression,
588 that operand is considered true if it is equal (C<==>) to the current
589 input line number (the C<$.> variable).
590
591 To be pedantic, the comparison is actually C<int(EXPR) == int(EXPR)>,
592 but that is only an issue if you use a floating point expression; when
593 implicitly using C<$.> as described in the previous paragraph, the
594 comparison is C<int(EXPR) == int($.)> which is only an issue when C<$.>
595 is set to a floating point value and you are not reading from a file.
596 Furthermore, C<"span" .. "spat"> or C<2.18 .. 3.14> will not do what
597 you want in scalar context because each of the operands are evaluated
598 using their integer representation.
599
600 Examples:
601
602 As a scalar operator:
603
604     if (101 .. 200) { print; } # print 2nd hundred lines, short for
605                                #   if ($. == 101 .. $. == 200) ...
606
607     next LINE if (1 .. /^$/);  # skip header lines, short for
608                                #   ... if ($. == 1 .. /^$/);
609                                # (typically in a loop labeled LINE)
610
611     s/^/> / if (/^$/ .. eof());  # quote body
612
613     # parse mail messages
614     while (<>) {
615         $in_header =   1  .. /^$/;
616         $in_body   = /^$/ .. eof;
617         if ($in_header) {
618             # ...
619         } else { # in body
620             # ...
621         }
622     } continue {
623         close ARGV if eof;             # reset $. each file
624     }
625
626 Here's a simple example to illustrate the difference between
627 the two range operators:
628
629     @lines = ("   - Foo",
630               "01 - Bar",
631               "1  - Baz",
632               "   - Quux");
633
634     foreach (@lines) {
635         if (/0/ .. /1/) {
636             print "$_\n";
637         }
638     }
639
640 This program will print only the line containing "Bar". If
641 the range operator is changed to C<...>, it will also print the
642 "Baz" line.
643
644 And now some examples as a list operator:
645
646     for (101 .. 200) { print; } # print $_ 100 times
647     @foo = @foo[0 .. $#foo];    # an expensive no-op
648     @foo = @foo[$#foo-4 .. $#foo];      # slice last 5 items
649
650 The range operator (in list context) makes use of the magical
651 auto-increment algorithm if the operands are strings.  You
652 can say
653
654     @alphabet = ('A' .. 'Z');
655
656 to get all normal letters of the English alphabet, or
657
658     $hexdigit = (0 .. 9, 'a' .. 'f')[$num & 15];
659
660 to get a hexadecimal digit, or
661
662     @z2 = ('01' .. '31');  print $z2[$mday];
663
664 to get dates with leading zeros.
665
666 If the final value specified is not in the sequence that the magical
667 increment would produce, the sequence goes until the next value would
668 be longer than the final value specified.
669
670 If the initial value specified isn't part of a magical increment
671 sequence (that is, a non-empty string matching "/^[a-zA-Z]*[0-9]*\z/"),
672 only the initial value will be returned.  So the following will only
673 return an alpha:
674
675     use charnames 'greek';
676     my @greek_small =  ("\N{alpha}" .. "\N{omega}");
677
678 To get lower-case greek letters, use this instead:
679
680     my @greek_small =  map { chr } ( ord("\N{alpha}") .. ord("\N{omega}") );
681
682 Because each operand is evaluated in integer form, C<2.18 .. 3.14> will
683 return two elements in list context.
684
685     @list = (2.18 .. 3.14); # same as @list = (2 .. 3);
686
687 =head2 Conditional Operator
688 X<operator, conditional> X<operator, ternary> X<ternary> X<?:>
689
690 Ternary "?:" is the conditional operator, just as in C.  It works much
691 like an if-then-else.  If the argument before the ? is true, the
692 argument before the : is returned, otherwise the argument after the :
693 is returned.  For example:
694
695     printf "I have %d dog%s.\n", $n,
696             ($n == 1) ? '' : "s";
697
698 Scalar or list context propagates downward into the 2nd
699 or 3rd argument, whichever is selected.
700
701     $a = $ok ? $b : $c;  # get a scalar
702     @a = $ok ? @b : @c;  # get an array
703     $a = $ok ? @b : @c;  # oops, that's just a count!
704
705 The operator may be assigned to if both the 2nd and 3rd arguments are
706 legal lvalues (meaning that you can assign to them):
707
708     ($a_or_b ? $a : $b) = $c;
709
710 Because this operator produces an assignable result, using assignments
711 without parentheses will get you in trouble.  For example, this:
712
713     $a % 2 ? $a += 10 : $a += 2
714
715 Really means this:
716
717     (($a % 2) ? ($a += 10) : $a) += 2
718
719 Rather than this:
720
721     ($a % 2) ? ($a += 10) : ($a += 2)
722
723 That should probably be written more simply as:
724
725     $a += ($a % 2) ? 10 : 2;
726
727 =head2 Assignment Operators
728 X<assignment> X<operator, assignment> X<=> X<**=> X<+=> X<*=> X<&=>
729 X<<< <<= >>> X<&&=> X<-=> X</=> X<|=> X<<< >>= >>> X<||=> X<//=> X<.=>
730 X<%=> X<^=> X<x=>
731
732 "=" is the ordinary assignment operator.
733
734 Assignment operators work as in C.  That is,
735
736     $a += 2;
737
738 is equivalent to
739
740     $a = $a + 2;
741
742 although without duplicating any side effects that dereferencing the lvalue
743 might trigger, such as from tie().  Other assignment operators work similarly.
744 The following are recognized:
745
746     **=    +=    *=    &=    <<=    &&=
747            -=    /=    |=    >>=    ||=
748            .=    %=    ^=           //=
749                  x=
750
751 Although these are grouped by family, they all have the precedence
752 of assignment.
753
754 Unlike in C, the scalar assignment operator produces a valid lvalue.
755 Modifying an assignment is equivalent to doing the assignment and
756 then modifying the variable that was assigned to.  This is useful
757 for modifying a copy of something, like this:
758
759     ($tmp = $global) =~ tr [A-Z] [a-z];
760
761 Likewise,
762
763     ($a += 2) *= 3;
764
765 is equivalent to
766
767     $a += 2;
768     $a *= 3;
769
770 Similarly, a list assignment in list context produces the list of
771 lvalues assigned to, and a list assignment in scalar context returns
772 the number of elements produced by the expression on the right hand
773 side of the assignment.
774
775 =head2 Comma Operator
776 X<comma> X<operator, comma> X<,>
777
778 Binary "," is the comma operator.  In scalar context it evaluates
779 its left argument, throws that value away, then evaluates its right
780 argument and returns that value.  This is just like C's comma operator.
781
782 In list context, it's just the list argument separator, and inserts
783 both its arguments into the list.  These arguments are also evaluated
784 from left to right.
785
786 The C<< => >> operator is a synonym for the comma, but forces any word
787 (consisting entirely of word characters) to its left to be interpreted
788 as a string (as of 5.001).  This includes words that might otherwise be
789 considered a constant or function call.
790
791     use constant FOO => "something";
792
793     my %h = ( FOO => 23 );
794
795 is equivalent to:
796
797     my %h = ("FOO", 23);
798
799 It is I<NOT>:
800
801     my %h = ("something", 23);
802
803 If the argument on the left is not a word, it is first interpreted as
804 an expression, and then the string value of that is used.
805
806 The C<< => >> operator is helpful in documenting the correspondence
807 between keys and values in hashes, and other paired elements in lists.
808
809         %hash = ( $key => $value );
810         login( $username => $password );
811
812 =head2 Yada Yada Operators
813 X<...> X<... operator> X<!!!> X<!!! operator> X<???> X<??? operator>
814 X<yada yada operator>
815
816 The yada yada operators are placeholders for code.  They parse without error,
817 but when executed either throw an exception or a warning.
818
819 The C<...> operator takes no arguments.  When executed, it throws an exception
820 with the text C<Unimplemented>:
821
822     sub foo { ... }
823     foo();
824
825     Unimplemented at <file> line <line number>.
826
827 The C<!!!> operator is similar, but it takes one argument, a string to use as
828 the text of the exception:
829
830     sub bar { !!! "Don't call me, Ishmael!" }
831     bar();
832
833     Don't call me, Ishmael! at <file> line <line number>.
834
835 The C<???> operator also takes one argument, but it emits a warning instead of
836 throwing an exception:
837
838     sub baz { ??? "Who are you?  Wnat do you want?" }
839     baz();
840     say "Why are you here?";
841
842     Who are you?  What do you want? at <file> line <line number>.
843     Why are you here?
844
845 =head2 List Operators (Rightward)
846 X<operator, list, rightward> X<list operator>
847
848 On the right side of a list operator, it has very low precedence,
849 such that it controls all comma-separated expressions found there.
850 The only operators with lower precedence are the logical operators
851 "and", "or", and "not", which may be used to evaluate calls to list
852 operators without the need for extra parentheses:
853
854     open HANDLE, "filename"
855         or die "Can't open: $!\n";
856
857 See also discussion of list operators in L<Terms and List Operators (Leftward)>.
858
859 =head2 Logical Not
860 X<operator, logical, not> X<not>
861
862 Unary "not" returns the logical negation of the expression to its right.
863 It's the equivalent of "!" except for the very low precedence.
864
865 =head2 Logical And
866 X<operator, logical, and> X<and>
867
868 Binary "and" returns the logical conjunction of the two surrounding
869 expressions.  It's equivalent to && except for the very low
870 precedence.  This means that it short-circuits: i.e., the right
871 expression is evaluated only if the left expression is true.
872
873 =head2 Logical or, Defined or, and Exclusive Or
874 X<operator, logical, or> X<operator, logical, xor>
875 X<operator, logical, defined or> X<operator, logical, exclusive or>
876 X<or> X<xor>
877
878 Binary "or" returns the logical disjunction of the two surrounding
879 expressions.  It's equivalent to || except for the very low precedence.
880 This makes it useful for control flow
881
882     print FH $data              or die "Can't write to FH: $!";
883
884 This means that it short-circuits: i.e., the right expression is evaluated
885 only if the left expression is false.  Due to its precedence, you should
886 probably avoid using this for assignment, only for control flow.
887
888     $a = $b or $c;              # bug: this is wrong
889     ($a = $b) or $c;            # really means this
890     $a = $b || $c;              # better written this way
891
892 However, when it's a list-context assignment and you're trying to use
893 "||" for control flow, you probably need "or" so that the assignment
894 takes higher precedence.
895
896     @info = stat($file) || die;     # oops, scalar sense of stat!
897     @info = stat($file) or die;     # better, now @info gets its due
898
899 Then again, you could always use parentheses.
900
901 Binary "xor" returns the exclusive-OR of the two surrounding expressions.
902 It cannot short circuit, of course.
903
904 =head2 C Operators Missing From Perl
905 X<operator, missing from perl> X<&> X<*>
906 X<typecasting> X<(TYPE)>
907
908 Here is what C has that Perl doesn't:
909
910 =over 8
911
912 =item unary &
913
914 Address-of operator.  (But see the "\" operator for taking a reference.)
915
916 =item unary *
917
918 Dereference-address operator. (Perl's prefix dereferencing
919 operators are typed: $, @, %, and &.)
920
921 =item (TYPE)
922
923 Type-casting operator.
924
925 =back
926
927 =head2 Quote and Quote-like Operators
928 X<operator, quote> X<operator, quote-like> X<q> X<qq> X<qx> X<qw> X<m>
929 X<qr> X<s> X<tr> X<'> X<''> X<"> X<""> X<//> X<`> X<``> X<<< << >>>
930 X<escape sequence> X<escape>
931
932
933 While we usually think of quotes as literal values, in Perl they
934 function as operators, providing various kinds of interpolating and
935 pattern matching capabilities.  Perl provides customary quote characters
936 for these behaviors, but also provides a way for you to choose your
937 quote character for any of them.  In the following table, a C<{}> represents
938 any pair of delimiters you choose.
939
940     Customary  Generic        Meaning        Interpolates
941         ''       q{}          Literal             no
942         ""      qq{}          Literal             yes
943         ``      qx{}          Command             yes*
944                 qw{}         Word list            no
945         //       m{}       Pattern match          yes*
946                 qr{}          Pattern             yes*
947                  s{}{}      Substitution          yes*
948                 tr{}{}    Transliteration         no (but see below)
949         <<EOF                 here-doc            yes*
950
951         * unless the delimiter is ''.
952
953 Non-bracketing delimiters use the same character fore and aft, but the four
954 sorts of brackets (round, angle, square, curly) will all nest, which means
955 that
956
957         q{foo{bar}baz}
958
959 is the same as
960
961         'foo{bar}baz'
962
963 Note, however, that this does not always work for quoting Perl code:
964
965         $s = q{ if($a eq "}") ... }; # WRONG
966
967 is a syntax error. The C<Text::Balanced> module (from CPAN, and
968 starting from Perl 5.8 part of the standard distribution) is able
969 to do this properly.
970
971 There can be whitespace between the operator and the quoting
972 characters, except when C<#> is being used as the quoting character.
973 C<q#foo#> is parsed as the string C<foo>, while C<q #foo#> is the
974 operator C<q> followed by a comment.  Its argument will be taken
975 from the next line.  This allows you to write:
976
977     s {foo}  # Replace foo
978       {bar}  # with bar.
979
980 The following escape sequences are available in constructs that interpolate
981 and in transliterations.
982 X<\t> X<\n> X<\r> X<\f> X<\b> X<\a> X<\e> X<\x> X<\0> X<\c> X<\N>
983
984     \t          tab             (HT, TAB)
985     \n          newline         (NL)
986     \r          return          (CR)
987     \f          form feed       (FF)
988     \b          backspace       (BS)
989     \a          alarm (bell)    (BEL)
990     \e          escape          (ESC)
991     \033        octal char      (example: ESC)
992     \x1b        hex char        (example: ESC)
993     \x{263a}    wide hex char   (example: SMILEY)
994     \c[         control char    (example: ESC)
995     \N{name}    named Unicode character
996
997 The character following C<\c> is mapped to some other character by
998 converting letters to upper case and then (on ASCII systems) by inverting
999 the 7th bit (0x40). The most interesting range is from '@' to '_'
1000 (0x40 through 0x5F), resulting in a control character from 0x00
1001 through 0x1F. A '?' maps to the DEL character. On EBCDIC systems only
1002 '@', the letters, '[', '\', ']', '^', '_' and '?' will work, resulting
1003 in 0x00 through 0x1F and 0x7F.
1004
1005 B<NOTE>: Unlike C and other languages, Perl has no \v escape sequence for
1006 the vertical tab (VT - ASCII 11), but you may use C<\ck> or C<\x0b>.
1007
1008 The following escape sequences are available in constructs that interpolate
1009 but not in transliterations.
1010 X<\l> X<\u> X<\L> X<\U> X<\E> X<\Q>
1011
1012     \l          lowercase next char
1013     \u          uppercase next char
1014     \L          lowercase till \E
1015     \U          uppercase till \E
1016     \E          end case modification
1017     \Q          quote non-word characters till \E
1018
1019 If C<use locale> is in effect, the case map used by C<\l>, C<\L>,
1020 C<\u> and C<\U> is taken from the current locale.  See L<perllocale>.
1021 If Unicode (for example, C<\N{}> or wide hex characters of 0x100 or
1022 beyond) is being used, the case map used by C<\l>, C<\L>, C<\u> and
1023 C<\U> is as defined by Unicode.  For documentation of C<\N{name}>,
1024 see L<charnames>.
1025
1026 All systems use the virtual C<"\n"> to represent a line terminator,
1027 called a "newline".  There is no such thing as an unvarying, physical
1028 newline character.  It is only an illusion that the operating system,
1029 device drivers, C libraries, and Perl all conspire to preserve.  Not all
1030 systems read C<"\r"> as ASCII CR and C<"\n"> as ASCII LF.  For example,
1031 on a Mac, these are reversed, and on systems without line terminator,
1032 printing C<"\n"> may emit no actual data.  In general, use C<"\n"> when
1033 you mean a "newline" for your system, but use the literal ASCII when you
1034 need an exact character.  For example, most networking protocols expect
1035 and prefer a CR+LF (C<"\015\012"> or C<"\cM\cJ">) for line terminators,
1036 and although they often accept just C<"\012">, they seldom tolerate just
1037 C<"\015">.  If you get in the habit of using C<"\n"> for networking,
1038 you may be burned some day.
1039 X<newline> X<line terminator> X<eol> X<end of line>
1040 X<\n> X<\r> X<\r\n>
1041
1042 For constructs that do interpolate, variables beginning with "C<$>"
1043 or "C<@>" are interpolated.  Subscripted variables such as C<$a[3]> or
1044 C<< $href->{key}[0] >> are also interpolated, as are array and hash slices.
1045 But method calls such as C<< $obj->meth >> are not.
1046
1047 Interpolating an array or slice interpolates the elements in order,
1048 separated by the value of C<$">, so is equivalent to interpolating
1049 C<join $", @array>.    "Punctuation" arrays such as C<@*> are only
1050 interpolated if the name is enclosed in braces C<@{*}>, but special
1051 arrays C<@_>, C<@+>, and C<@-> are interpolated, even without braces.
1052
1053 You cannot include a literal C<$> or C<@> within a C<\Q> sequence.
1054 An unescaped C<$> or C<@> interpolates the corresponding variable,
1055 while escaping will cause the literal string C<\$> to be inserted.
1056 You'll need to write something like C<m/\Quser\E\@\Qhost/>.
1057
1058 Patterns are subject to an additional level of interpretation as a
1059 regular expression.  This is done as a second pass, after variables are
1060 interpolated, so that regular expressions may be incorporated into the
1061 pattern from the variables.  If this is not what you want, use C<\Q> to
1062 interpolate a variable literally.
1063
1064 Apart from the behavior described above, Perl does not expand
1065 multiple levels of interpolation.  In particular, contrary to the
1066 expectations of shell programmers, back-quotes do I<NOT> interpolate
1067 within double quotes, nor do single quotes impede evaluation of
1068 variables when used within double quotes.
1069
1070 =head2 Regexp Quote-Like Operators
1071 X<operator, regexp>
1072
1073 Here are the quote-like operators that apply to pattern
1074 matching and related activities.
1075
1076 =over 8
1077
1078 =item qr/STRING/msixpo
1079 X<qr> X</i> X</m> X</o> X</s> X</x> X</p>
1080
1081 This operator quotes (and possibly compiles) its I<STRING> as a regular
1082 expression.  I<STRING> is interpolated the same way as I<PATTERN>
1083 in C<m/PATTERN/>.  If "'" is used as the delimiter, no interpolation
1084 is done.  Returns a Perl value which may be used instead of the
1085 corresponding C</STRING/msixpo> expression. The returned value is a
1086 normalized version of the original pattern. It magically differs from
1087 a string containing the same characters: C<ref(qr/x/)> returns "Regexp",
1088 even though dereferencing the result returns undef.
1089
1090 For example,
1091
1092     $rex = qr/my.STRING/is;
1093     print $rex;                 # prints (?si-xm:my.STRING)
1094     s/$rex/foo/;
1095
1096 is equivalent to
1097
1098     s/my.STRING/foo/is;
1099
1100 The result may be used as a subpattern in a match:
1101
1102     $re = qr/$pattern/;
1103     $string =~ /foo${re}bar/;   # can be interpolated in other patterns
1104     $string =~ $re;             # or used standalone
1105     $string =~ /$re/;           # or this way
1106
1107 Since Perl may compile the pattern at the moment of execution of qr()
1108 operator, using qr() may have speed advantages in some situations,
1109 notably if the result of qr() is used standalone:
1110
1111     sub match {
1112         my $patterns = shift;
1113         my @compiled = map qr/$_/i, @$patterns;
1114         grep {
1115             my $success = 0;
1116             foreach my $pat (@compiled) {
1117                 $success = 1, last if /$pat/;
1118             }
1119             $success;
1120         } @_;
1121     }
1122
1123 Precompilation of the pattern into an internal representation at
1124 the moment of qr() avoids a need to recompile the pattern every
1125 time a match C</$pat/> is attempted.  (Perl has many other internal
1126 optimizations, but none would be triggered in the above example if
1127 we did not use qr() operator.)
1128
1129 Options are:
1130
1131     m   Treat string as multiple lines.
1132     s   Treat string as single line. (Make . match a newline)
1133     i   Do case-insensitive pattern matching.
1134     x   Use extended regular expressions.
1135     p   When matching preserve a copy of the matched string so
1136         that ${^PREMATCH}, ${^MATCH}, ${^POSTMATCH} will be defined.
1137     o   Compile pattern only once.
1138
1139 If a precompiled pattern is embedded in a larger pattern then the effect
1140 of 'msixp' will be propagated appropriately.  The effect of the 'o'
1141 modifier has is not propagated, being restricted to those patterns
1142 explicitly using it.
1143
1144 See L<perlre> for additional information on valid syntax for STRING, and
1145 for a detailed look at the semantics of regular expressions.
1146
1147 =item m/PATTERN/msixpogc
1148 X<m> X<operator, match>
1149 X<regexp, options> X<regexp> X<regex, options> X<regex>
1150 X</m> X</s> X</i> X</x> X</p> X</o> X</g> X</c>
1151
1152 =item /PATTERN/msixpogc
1153
1154 Searches a string for a pattern match, and in scalar context returns
1155 true if it succeeds, false if it fails.  If no string is specified
1156 via the C<=~> or C<!~> operator, the $_ string is searched.  (The
1157 string specified with C<=~> need not be an lvalue--it may be the
1158 result of an expression evaluation, but remember the C<=~> binds
1159 rather tightly.)  See also L<perlre>.  See L<perllocale> for
1160 discussion of additional considerations that apply when C<use locale>
1161 is in effect.
1162
1163 Options are as described in C<qr//>; in addition, the following match
1164 process modifiers are available:
1165
1166     g   Match globally, i.e., find all occurrences.
1167     c   Do not reset search position on a failed match when /g is in effect.
1168
1169 If "/" is the delimiter then the initial C<m> is optional.  With the C<m>
1170 you can use any pair of non-alphanumeric, non-whitespace characters
1171 as delimiters.  This is particularly useful for matching path names
1172 that contain "/", to avoid LTS (leaning toothpick syndrome).  If "?" is
1173 the delimiter, then the match-only-once rule of C<?PATTERN?> applies.
1174 If "'" is the delimiter, no interpolation is performed on the PATTERN.
1175
1176 PATTERN may contain variables, which will be interpolated (and the
1177 pattern recompiled) every time the pattern search is evaluated, except
1178 for when the delimiter is a single quote.  (Note that C<$(>, C<$)>, and
1179 C<$|> are not interpolated because they look like end-of-string tests.)
1180 If you want such a pattern to be compiled only once, add a C</o> after
1181 the trailing delimiter.  This avoids expensive run-time recompilations,
1182 and is useful when the value you are interpolating won't change over
1183 the life of the script.  However, mentioning C</o> constitutes a promise
1184 that you won't change the variables in the pattern.  If you change them,
1185 Perl won't even notice.  See also L<"qr/STRING/msixpo">.
1186
1187 =item The empty pattern //
1188
1189 If the PATTERN evaluates to the empty string, the last
1190 I<successfully> matched regular expression is used instead. In this
1191 case, only the C<g> and C<c> flags on the empty pattern is honoured -
1192 the other flags are taken from the original pattern. If no match has
1193 previously succeeded, this will (silently) act instead as a genuine
1194 empty pattern (which will always match).
1195
1196 Note that it's possible to confuse Perl into thinking C<//> (the empty
1197 regex) is really C<//> (the defined-or operator).  Perl is usually pretty
1198 good about this, but some pathological cases might trigger this, such as
1199 C<$a///> (is that C<($a) / (//)> or C<$a // />?) and C<print $fh //>
1200 (C<print $fh(//> or C<print($fh //>?).  In all of these examples, Perl
1201 will assume you meant defined-or.  If you meant the empty regex, just
1202 use parentheses or spaces to disambiguate, or even prefix the empty
1203 regex with an C<m> (so C<//> becomes C<m//>).
1204
1205 =item Matching in list context
1206
1207 If the C</g> option is not used, C<m//> in list context returns a
1208 list consisting of the subexpressions matched by the parentheses in the
1209 pattern, i.e., (C<$1>, C<$2>, C<$3>...).  (Note that here C<$1> etc. are
1210 also set, and that this differs from Perl 4's behavior.)  When there are
1211 no parentheses in the pattern, the return value is the list C<(1)> for
1212 success.  With or without parentheses, an empty list is returned upon
1213 failure.
1214
1215 Examples:
1216
1217     open(TTY, '/dev/tty');
1218     <TTY> =~ /^y/i && foo();    # do foo if desired
1219
1220     if (/Version: *([0-9.]*)/) { $version = $1; }
1221
1222     next if m#^/usr/spool/uucp#;
1223
1224     # poor man's grep
1225     $arg = shift;
1226     while (<>) {
1227         print if /$arg/o;       # compile only once
1228     }
1229
1230     if (($F1, $F2, $Etc) = ($foo =~ /^(\S+)\s+(\S+)\s*(.*)/))
1231
1232 This last example splits $foo into the first two words and the
1233 remainder of the line, and assigns those three fields to $F1, $F2, and
1234 $Etc.  The conditional is true if any variables were assigned, i.e., if
1235 the pattern matched.
1236
1237 The C</g> modifier specifies global pattern matching--that is,
1238 matching as many times as possible within the string.  How it behaves
1239 depends on the context.  In list context, it returns a list of the
1240 substrings matched by any capturing parentheses in the regular
1241 expression.  If there are no parentheses, it returns a list of all
1242 the matched strings, as if there were parentheses around the whole
1243 pattern.
1244
1245 In scalar context, each execution of C<m//g> finds the next match,
1246 returning true if it matches, and false if there is no further match.
1247 The position after the last match can be read or set using the pos()
1248 function; see L<perlfunc/pos>.   A failed match normally resets the
1249 search position to the beginning of the string, but you can avoid that
1250 by adding the C</c> modifier (e.g. C<m//gc>).  Modifying the target
1251 string also resets the search position.
1252
1253 =item \G assertion
1254
1255 You can intermix C<m//g> matches with C<m/\G.../g>, where C<\G> is a
1256 zero-width assertion that matches the exact position where the previous
1257 C<m//g>, if any, left off.  Without the C</g> modifier, the C<\G> assertion
1258 still anchors at pos(), but the match is of course only attempted once.
1259 Using C<\G> without C</g> on a target string that has not previously had a
1260 C</g> match applied to it is the same as using the C<\A> assertion to match
1261 the beginning of the string.  Note also that, currently, C<\G> is only
1262 properly supported when anchored at the very beginning of the pattern.
1263
1264 Examples:
1265
1266     # list context
1267     ($one,$five,$fifteen) = (`uptime` =~ /(\d+\.\d+)/g);
1268
1269     # scalar context
1270     $/ = "";
1271     while (defined($paragraph = <>)) {
1272         while ($paragraph =~ /[a-z]['")]*[.!?]+['")]*\s/g) {
1273             $sentences++;
1274         }
1275     }
1276     print "$sentences\n";
1277
1278     # using m//gc with \G
1279     $_ = "ppooqppqq";
1280     while ($i++ < 2) {
1281         print "1: '";
1282         print $1 while /(o)/gc; print "', pos=", pos, "\n";
1283         print "2: '";
1284         print $1 if /\G(q)/gc;  print "', pos=", pos, "\n";
1285         print "3: '";
1286         print $1 while /(p)/gc; print "', pos=", pos, "\n";
1287     }
1288     print "Final: '$1', pos=",pos,"\n" if /\G(.)/;
1289
1290 The last example should print:
1291
1292     1: 'oo', pos=4
1293     2: 'q', pos=5
1294     3: 'pp', pos=7
1295     1: '', pos=7
1296     2: 'q', pos=8
1297     3: '', pos=8
1298     Final: 'q', pos=8
1299
1300 Notice that the final match matched C<q> instead of C<p>, which a match
1301 without the C<\G> anchor would have done. Also note that the final match
1302 did not update C<pos> -- C<pos> is only updated on a C</g> match. If the
1303 final match did indeed match C<p>, it's a good bet that you're running an
1304 older (pre-5.6.0) Perl.
1305
1306 A useful idiom for C<lex>-like scanners is C</\G.../gc>.  You can
1307 combine several regexps like this to process a string part-by-part,
1308 doing different actions depending on which regexp matched.  Each
1309 regexp tries to match where the previous one leaves off.
1310
1311  $_ = <<'EOL';
1312       $url = URI::URL->new( "http://www/" );   die if $url eq "xXx";
1313  EOL
1314  LOOP:
1315     {
1316       print(" digits"),         redo LOOP if /\G\d+\b[,.;]?\s*/gc;
1317       print(" lowercase"),      redo LOOP if /\G[a-z]+\b[,.;]?\s*/gc;
1318       print(" UPPERCASE"),      redo LOOP if /\G[A-Z]+\b[,.;]?\s*/gc;
1319       print(" Capitalized"),    redo LOOP if /\G[A-Z][a-z]+\b[,.;]?\s*/gc;
1320       print(" MiXeD"),          redo LOOP if /\G[A-Za-z]+\b[,.;]?\s*/gc;
1321       print(" alphanumeric"),   redo LOOP if /\G[A-Za-z0-9]+\b[,.;]?\s*/gc;
1322       print(" line-noise"),     redo LOOP if /\G[^A-Za-z0-9]+/gc;
1323       print ". That's all!\n";
1324     }
1325
1326 Here is the output (split into several lines):
1327
1328  line-noise lowercase line-noise lowercase UPPERCASE line-noise
1329  UPPERCASE line-noise lowercase line-noise lowercase line-noise
1330  lowercase lowercase line-noise lowercase lowercase line-noise
1331  MiXeD line-noise. That's all!
1332
1333 =item ?PATTERN?
1334 X<?>
1335
1336 This is just like the C</pattern/> search, except that it matches only
1337 once between calls to the reset() operator.  This is a useful
1338 optimization when you want to see only the first occurrence of
1339 something in each file of a set of files, for instance.  Only C<??>
1340 patterns local to the current package are reset.
1341
1342     while (<>) {
1343         if (?^$?) {
1344                             # blank line between header and body
1345         }
1346     } continue {
1347         reset if eof;       # clear ?? status for next file
1348     }
1349
1350 This usage is vaguely deprecated, which means it just might possibly
1351 be removed in some distant future version of Perl, perhaps somewhere
1352 around the year 2168.
1353
1354 =item s/PATTERN/REPLACEMENT/msixpogce
1355 X<substitute> X<substitution> X<replace> X<regexp, replace>
1356 X<regexp, substitute> X</m> X</s> X</i> X</x> X</p> X</o> X</g> X</c> X</e>
1357
1358 Searches a string for a pattern, and if found, replaces that pattern
1359 with the replacement text and returns the number of substitutions
1360 made.  Otherwise it returns false (specifically, the empty string).
1361
1362 If no string is specified via the C<=~> or C<!~> operator, the C<$_>
1363 variable is searched and modified.  (The string specified with C<=~> must
1364 be scalar variable, an array element, a hash element, or an assignment
1365 to one of those, i.e., an lvalue.)
1366
1367 If the delimiter chosen is a single quote, no interpolation is
1368 done on either the PATTERN or the REPLACEMENT.  Otherwise, if the
1369 PATTERN contains a $ that looks like a variable rather than an
1370 end-of-string test, the variable will be interpolated into the pattern
1371 at run-time.  If you want the pattern compiled only once the first time
1372 the variable is interpolated, use the C</o> option.  If the pattern
1373 evaluates to the empty string, the last successfully executed regular
1374 expression is used instead.  See L<perlre> for further explanation on these.
1375 See L<perllocale> for discussion of additional considerations that apply
1376 when C<use locale> is in effect.
1377
1378 Options are as with m// with the addition of the following replacement
1379 specific options:
1380
1381     e   Evaluate the right side as an expression.
1382     ee  Evaluate the right side as a string then eval the result
1383
1384 Any non-alphanumeric, non-whitespace delimiter may replace the
1385 slashes.  If single quotes are used, no interpretation is done on the
1386 replacement string (the C</e> modifier overrides this, however).  Unlike
1387 Perl 4, Perl 5 treats backticks as normal delimiters; the replacement
1388 text is not evaluated as a command.  If the
1389 PATTERN is delimited by bracketing quotes, the REPLACEMENT has its own
1390 pair of quotes, which may or may not be bracketing quotes, e.g.,
1391 C<s(foo)(bar)> or C<< s<foo>/bar/ >>.  A C</e> will cause the
1392 replacement portion to be treated as a full-fledged Perl expression
1393 and evaluated right then and there.  It is, however, syntax checked at
1394 compile-time. A second C<e> modifier will cause the replacement portion
1395 to be C<eval>ed before being run as a Perl expression.
1396
1397 Examples:
1398
1399     s/\bgreen\b/mauve/g;                # don't change wintergreen
1400
1401     $path =~ s|/usr/bin|/usr/local/bin|;
1402
1403     s/Login: $foo/Login: $bar/; # run-time pattern
1404
1405     ($foo = $bar) =~ s/this/that/;      # copy first, then change
1406
1407     $count = ($paragraph =~ s/Mister\b/Mr./g);  # get change-count
1408
1409     $_ = 'abc123xyz';
1410     s/\d+/$&*2/e;               # yields 'abc246xyz'
1411     s/\d+/sprintf("%5d",$&)/e;  # yields 'abc  246xyz'
1412     s/\w/$& x 2/eg;             # yields 'aabbcc  224466xxyyzz'
1413
1414     s/%(.)/$percent{$1}/g;      # change percent escapes; no /e
1415     s/%(.)/$percent{$1} || $&/ge;       # expr now, so /e
1416     s/^=(\w+)/pod($1)/ge;       # use function call
1417
1418     # expand variables in $_, but dynamics only, using
1419     # symbolic dereferencing
1420     s/\$(\w+)/${$1}/g;
1421
1422     # Add one to the value of any numbers in the string
1423     s/(\d+)/1 + $1/eg;
1424
1425     # This will expand any embedded scalar variable
1426     # (including lexicals) in $_ : First $1 is interpolated
1427     # to the variable name, and then evaluated
1428     s/(\$\w+)/$1/eeg;
1429
1430     # Delete (most) C comments.
1431     $program =~ s {
1432         /\*     # Match the opening delimiter.
1433         .*?     # Match a minimal number of characters.
1434         \*/     # Match the closing delimiter.
1435     } []gsx;
1436
1437     s/^\s*(.*?)\s*$/$1/;        # trim whitespace in $_, expensively
1438
1439     for ($variable) {           # trim whitespace in $variable, cheap
1440         s/^\s+//;
1441         s/\s+$//;
1442     }
1443
1444     s/([^ ]*) *([^ ]*)/$2 $1/;  # reverse 1st two fields
1445
1446 Note the use of $ instead of \ in the last example.  Unlike
1447 B<sed>, we use the \<I<digit>> form in only the left hand side.
1448 Anywhere else it's $<I<digit>>.
1449
1450 Occasionally, you can't use just a C</g> to get all the changes
1451 to occur that you might want.  Here are two common cases:
1452
1453     # put commas in the right places in an integer
1454     1 while s/(\d)(\d\d\d)(?!\d)/$1,$2/g;
1455
1456     # expand tabs to 8-column spacing
1457     1 while s/\t+/' ' x (length($&)*8 - length($`)%8)/e;
1458
1459 =back
1460
1461 =head2 Quote-Like Operators
1462 X<operator, quote-like>
1463
1464 =over 4
1465
1466 =item q/STRING/
1467 X<q> X<quote, single> X<'> X<''>
1468
1469 =item 'STRING'
1470
1471 A single-quoted, literal string.  A backslash represents a backslash
1472 unless followed by the delimiter or another backslash, in which case
1473 the delimiter or backslash is interpolated.
1474
1475     $foo = q!I said, "You said, 'She said it.'"!;
1476     $bar = q('This is it.');
1477     $baz = '\n';                # a two-character string
1478
1479 =item qq/STRING/
1480 X<qq> X<quote, double> X<"> X<"">
1481
1482 =item "STRING"
1483
1484 A double-quoted, interpolated string.
1485
1486     $_ .= qq
1487      (*** The previous line contains the naughty word "$1".\n)
1488                 if /\b(tcl|java|python)\b/i;      # :-)
1489     $baz = "\n";                # a one-character string
1490
1491 =item qx/STRING/
1492 X<qx> X<`> X<``> X<backtick>
1493
1494 =item `STRING`
1495
1496 A string which is (possibly) interpolated and then executed as a
1497 system command with C</bin/sh> or its equivalent.  Shell wildcards,
1498 pipes, and redirections will be honored.  The collected standard
1499 output of the command is returned; standard error is unaffected.  In
1500 scalar context, it comes back as a single (potentially multi-line)
1501 string, or undef if the command failed.  In list context, returns a
1502 list of lines (however you've defined lines with $/ or
1503 $INPUT_RECORD_SEPARATOR), or an empty list if the command failed.
1504
1505 Because backticks do not affect standard error, use shell file descriptor
1506 syntax (assuming the shell supports this) if you care to address this.
1507 To capture a command's STDERR and STDOUT together:
1508
1509     $output = `cmd 2>&1`;
1510
1511 To capture a command's STDOUT but discard its STDERR:
1512
1513     $output = `cmd 2>/dev/null`;
1514
1515 To capture a command's STDERR but discard its STDOUT (ordering is
1516 important here):
1517
1518     $output = `cmd 2>&1 1>/dev/null`;
1519
1520 To exchange a command's STDOUT and STDERR in order to capture the STDERR
1521 but leave its STDOUT to come out the old STDERR:
1522
1523     $output = `cmd 3>&1 1>&2 2>&3 3>&-`;
1524
1525 To read both a command's STDOUT and its STDERR separately, it's easiest
1526 to redirect them separately to files, and then read from those files
1527 when the program is done:
1528
1529     system("program args 1>program.stdout 2>program.stderr");
1530
1531 The STDIN filehandle used by the command is inherited from Perl's STDIN.
1532 For example:
1533
1534     open BLAM, "blam" || die "Can't open: $!";
1535     open STDIN, "<&BLAM";
1536     print `sort`;
1537
1538 will print the sorted contents of the file "blam".
1539
1540 Using single-quote as a delimiter protects the command from Perl's
1541 double-quote interpolation, passing it on to the shell instead:
1542
1543     $perl_info  = qx(ps $$);            # that's Perl's $$
1544     $shell_info = qx'ps $$';            # that's the new shell's $$
1545
1546 How that string gets evaluated is entirely subject to the command
1547 interpreter on your system.  On most platforms, you will have to protect
1548 shell metacharacters if you want them treated literally.  This is in
1549 practice difficult to do, as it's unclear how to escape which characters.
1550 See L<perlsec> for a clean and safe example of a manual fork() and exec()
1551 to emulate backticks safely.
1552
1553 On some platforms (notably DOS-like ones), the shell may not be
1554 capable of dealing with multiline commands, so putting newlines in
1555 the string may not get you what you want.  You may be able to evaluate
1556 multiple commands in a single line by separating them with the command
1557 separator character, if your shell supports that (e.g. C<;> on many Unix
1558 shells; C<&> on the Windows NT C<cmd> shell).
1559
1560 Beginning with v5.6.0, Perl will attempt to flush all files opened for
1561 output before starting the child process, but this may not be supported
1562 on some platforms (see L<perlport>).  To be safe, you may need to set
1563 C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method of
1564 C<IO::Handle> on any open handles.
1565
1566 Beware that some command shells may place restrictions on the length
1567 of the command line.  You must ensure your strings don't exceed this
1568 limit after any necessary interpolations.  See the platform-specific
1569 release notes for more details about your particular environment.
1570
1571 Using this operator can lead to programs that are difficult to port,
1572 because the shell commands called vary between systems, and may in
1573 fact not be present at all.  As one example, the C<type> command under
1574 the POSIX shell is very different from the C<type> command under DOS.
1575 That doesn't mean you should go out of your way to avoid backticks
1576 when they're the right way to get something done.  Perl was made to be
1577 a glue language, and one of the things it glues together is commands.
1578 Just understand what you're getting yourself into.
1579
1580 See L</"I/O Operators"> for more discussion.
1581
1582 =item qw/STRING/
1583 X<qw> X<quote, list> X<quote, words>
1584
1585 Evaluates to a list of the words extracted out of STRING, using embedded
1586 whitespace as the word delimiters.  It can be understood as being roughly
1587 equivalent to:
1588
1589     split(' ', q/STRING/);
1590
1591 the differences being that it generates a real list at compile time, and
1592 in scalar context it returns the last element in the list.  So
1593 this expression:
1594
1595     qw(foo bar baz)
1596
1597 is semantically equivalent to the list:
1598
1599     'foo', 'bar', 'baz'
1600
1601 Some frequently seen examples:
1602
1603     use POSIX qw( setlocale localeconv )
1604     @EXPORT = qw( foo bar baz );
1605
1606 A common mistake is to try to separate the words with comma or to
1607 put comments into a multi-line C<qw>-string.  For this reason, the
1608 C<use warnings> pragma and the B<-w> switch (that is, the C<$^W> variable)
1609 produces warnings if the STRING contains the "," or the "#" character.
1610
1611
1612 =item tr/SEARCHLIST/REPLACEMENTLIST/cds
1613 X<tr> X<y> X<transliterate> X</c> X</d> X</s>
1614
1615 =item y/SEARCHLIST/REPLACEMENTLIST/cds
1616
1617 Transliterates all occurrences of the characters found in the search list
1618 with the corresponding character in the replacement list.  It returns
1619 the number of characters replaced or deleted.  If no string is
1620 specified via the =~ or !~ operator, the $_ string is transliterated.  (The
1621 string specified with =~ must be a scalar variable, an array element, a
1622 hash element, or an assignment to one of those, i.e., an lvalue.)
1623
1624 A character range may be specified with a hyphen, so C<tr/A-J/0-9/>
1625 does the same replacement as C<tr/ACEGIBDFHJ/0246813579/>.
1626 For B<sed> devotees, C<y> is provided as a synonym for C<tr>.  If the
1627 SEARCHLIST is delimited by bracketing quotes, the REPLACEMENTLIST has
1628 its own pair of quotes, which may or may not be bracketing quotes,
1629 e.g., C<tr[A-Z][a-z]> or C<tr(+\-*/)/ABCD/>.
1630
1631 Note that C<tr> does B<not> do regular expression character classes
1632 such as C<\d> or C<[:lower:]>.  The C<tr> operator is not equivalent to
1633 the tr(1) utility.  If you want to map strings between lower/upper
1634 cases, see L<perlfunc/lc> and L<perlfunc/uc>, and in general consider
1635 using the C<s> operator if you need regular expressions.
1636
1637 Note also that the whole range idea is rather unportable between
1638 character sets--and even within character sets they may cause results
1639 you probably didn't expect.  A sound principle is to use only ranges
1640 that begin from and end at either alphabets of equal case (a-e, A-E),
1641 or digits (0-4).  Anything else is unsafe.  If in doubt, spell out the
1642 character sets in full.
1643
1644 Options:
1645
1646     c   Complement the SEARCHLIST.
1647     d   Delete found but unreplaced characters.
1648     s   Squash duplicate replaced characters.
1649
1650 If the C</c> modifier is specified, the SEARCHLIST character set
1651 is complemented.  If the C</d> modifier is specified, any characters
1652 specified by SEARCHLIST not found in REPLACEMENTLIST are deleted.
1653 (Note that this is slightly more flexible than the behavior of some
1654 B<tr> programs, which delete anything they find in the SEARCHLIST,
1655 period.) If the C</s> modifier is specified, sequences of characters
1656 that were transliterated to the same character are squashed down
1657 to a single instance of the character.
1658
1659 If the C</d> modifier is used, the REPLACEMENTLIST is always interpreted
1660 exactly as specified.  Otherwise, if the REPLACEMENTLIST is shorter
1661 than the SEARCHLIST, the final character is replicated till it is long
1662 enough.  If the REPLACEMENTLIST is empty, the SEARCHLIST is replicated.
1663 This latter is useful for counting characters in a class or for
1664 squashing character sequences in a class.
1665
1666 Examples:
1667
1668     $ARGV[1] =~ tr/A-Z/a-z/;    # canonicalize to lower case
1669
1670     $cnt = tr/*/*/;             # count the stars in $_
1671
1672     $cnt = $sky =~ tr/*/*/;     # count the stars in $sky
1673
1674     $cnt = tr/0-9//;            # count the digits in $_
1675
1676     tr/a-zA-Z//s;               # bookkeeper -> bokeper
1677
1678     ($HOST = $host) =~ tr/a-z/A-Z/;
1679
1680     tr/a-zA-Z/ /cs;             # change non-alphas to single space
1681
1682     tr [\200-\377]
1683        [\000-\177];             # delete 8th bit
1684
1685 If multiple transliterations are given for a character, only the
1686 first one is used:
1687
1688     tr/AAA/XYZ/
1689
1690 will transliterate any A to X.
1691
1692 Because the transliteration table is built at compile time, neither
1693 the SEARCHLIST nor the REPLACEMENTLIST are subjected to double quote
1694 interpolation.  That means that if you want to use variables, you
1695 must use an eval():
1696
1697     eval "tr/$oldlist/$newlist/";
1698     die $@ if $@;
1699
1700     eval "tr/$oldlist/$newlist/, 1" or die $@;
1701
1702 =item <<EOF
1703 X<here-doc> X<heredoc> X<here-document> X<<< << >>>
1704
1705 A line-oriented form of quoting is based on the shell "here-document"
1706 syntax.  Following a C<< << >> you specify a string to terminate
1707 the quoted material, and all lines following the current line down to
1708 the terminating string are the value of the item.
1709
1710 The terminating string may be either an identifier (a word), or some
1711 quoted text.  An unquoted identifier works like double quotes.
1712 There may not be a space between the C<< << >> and the identifier,
1713 unless the identifier is explicitly quoted.  (If you put a space it
1714 will be treated as a null identifier, which is valid, and matches the
1715 first empty line.)  The terminating string must appear by itself
1716 (unquoted and with no surrounding whitespace) on the terminating line.
1717
1718 If the terminating string is quoted, the type of quotes used determine
1719 the treatment of the text.
1720
1721 =over 4
1722
1723 =item Double Quotes
1724
1725 Double quotes indicate that the text will be interpolated using exactly
1726 the same rules as normal double quoted strings.
1727
1728        print <<EOF;
1729     The price is $Price.
1730     EOF
1731
1732        print << "EOF"; # same as above
1733     The price is $Price.
1734     EOF
1735
1736
1737 =item Single Quotes
1738
1739 Single quotes indicate the text is to be treated literally with no
1740 interpolation of its content. This is similar to single quoted
1741 strings except that backslashes have no special meaning, with C<\\>
1742 being treated as two backslashes and not one as they would in every
1743 other quoting construct.
1744
1745 This is the only form of quoting in perl where there is no need
1746 to worry about escaping content, something that code generators
1747 can and do make good use of.
1748
1749 =item Backticks
1750
1751 The content of the here doc is treated just as it would be if the
1752 string were embedded in backticks. Thus the content is interpolated
1753 as though it were double quoted and then executed via the shell, with
1754 the results of the execution returned.
1755
1756        print << `EOC`; # execute command and get results
1757     echo hi there
1758     EOC
1759
1760 =back
1761
1762 It is possible to stack multiple here-docs in a row:
1763
1764        print <<"foo", <<"bar"; # you can stack them
1765     I said foo.
1766     foo
1767     I said bar.
1768     bar
1769
1770        myfunc(<< "THIS", 23, <<'THAT');
1771     Here's a line
1772     or two.
1773     THIS
1774     and here's another.
1775     THAT
1776
1777 Just don't forget that you have to put a semicolon on the end
1778 to finish the statement, as Perl doesn't know you're not going to
1779 try to do this:
1780
1781        print <<ABC
1782     179231
1783     ABC
1784        + 20;
1785
1786 If you want to remove the line terminator from your here-docs,
1787 use C<chomp()>.
1788
1789     chomp($string = <<'END');
1790     This is a string.
1791     END
1792
1793 If you want your here-docs to be indented with the rest of the code,
1794 you'll need to remove leading whitespace from each line manually:
1795
1796     ($quote = <<'FINIS') =~ s/^\s+//gm;
1797        The Road goes ever on and on,
1798        down from the door where it began.
1799     FINIS
1800
1801 If you use a here-doc within a delimited construct, such as in C<s///eg>,
1802 the quoted material must come on the lines following the final delimiter.
1803 So instead of
1804
1805     s/this/<<E . 'that'
1806     the other
1807     E
1808      . 'more '/eg;
1809
1810 you have to write
1811
1812     s/this/<<E . 'that'
1813      . 'more '/eg;
1814     the other
1815     E
1816
1817 If the terminating identifier is on the last line of the program, you
1818 must be sure there is a newline after it; otherwise, Perl will give the
1819 warning B<Can't find string terminator "END" anywhere before EOF...>.
1820
1821 Additionally, the quoting rules for the end of string identifier are not
1822 related to Perl's quoting rules -- C<q()>, C<qq()>, and the like are not
1823 supported in place of C<''> and C<"">, and the only interpolation is for
1824 backslashing the quoting character:
1825
1826     print << "abc\"def";
1827     testing...
1828     abc"def
1829
1830 Finally, quoted strings cannot span multiple lines.  The general rule is
1831 that the identifier must be a string literal.  Stick with that, and you
1832 should be safe.
1833
1834 =back
1835
1836 =head2 Gory details of parsing quoted constructs
1837 X<quote, gory details>
1838
1839 When presented with something that might have several different
1840 interpretations, Perl uses the B<DWIM> (that's "Do What I Mean")
1841 principle to pick the most probable interpretation.  This strategy
1842 is so successful that Perl programmers often do not suspect the
1843 ambivalence of what they write.  But from time to time, Perl's
1844 notions differ substantially from what the author honestly meant.
1845
1846 This section hopes to clarify how Perl handles quoted constructs.
1847 Although the most common reason to learn this is to unravel labyrinthine
1848 regular expressions, because the initial steps of parsing are the
1849 same for all quoting operators, they are all discussed together.
1850
1851 The most important Perl parsing rule is the first one discussed
1852 below: when processing a quoted construct, Perl first finds the end
1853 of that construct, then interprets its contents.  If you understand
1854 this rule, you may skip the rest of this section on the first
1855 reading.  The other rules are likely to contradict the user's
1856 expectations much less frequently than this first one.
1857
1858 Some passes discussed below are performed concurrently, but because
1859 their results are the same, we consider them individually.  For different
1860 quoting constructs, Perl performs different numbers of passes, from
1861 one to four, but these passes are always performed in the same order.
1862
1863 =over 4
1864
1865 =item Finding the end
1866
1867 The first pass is finding the end of the quoted construct, where
1868 the information about the delimiters is used in parsing.
1869 During this search, text between the starting and ending delimiters
1870 is copied to a safe location. The text copied gets delimiter-independent.
1871
1872 If the construct is a here-doc, the ending delimiter is a line
1873 that has a terminating string as the content. Therefore C<<<EOF> is
1874 terminated by C<EOF> immediately followed by C<"\n"> and starting
1875 from the first column of the terminating line.
1876 When searching for the terminating line of a here-doc, nothing
1877 is skipped. In other words, lines after the here-doc syntax
1878 are compared with the terminating string line by line.
1879
1880 For the constructs except here-docs, single characters are used as starting
1881 and ending delimiters. If the starting delimiter is an opening punctuation
1882 (that is C<(>, C<[>, C<{>, or C<< < >>), the ending delimiter is the
1883 corresponding closing punctuation (that is C<)>, C<]>, C<}>, or C<< > >>).
1884 If the starting delimiter is an unpaired character like C</> or a closing
1885 punctuation, the ending delimiter is same as the starting delimiter.
1886 Therefore a C</> terminates a C<qq//> construct, while a C<]> terminates
1887 C<qq[]> and C<qq]]> constructs.
1888
1889 When searching for single-character delimiters, escaped delimiters
1890 and C<\\> are skipped. For example, while searching for terminating C</>,
1891 combinations of C<\\> and C<\/> are skipped.  If the delimiters are
1892 bracketing, nested pairs are also skipped.  For example, while searching
1893 for closing C<]> paired with the opening C<[>, combinations of C<\\>, C<\]>,
1894 and C<\[> are all skipped, and nested C<[> and C<]> are skipped as well.
1895 However, when backslashes are used as the delimiters (like C<qq\\> and
1896 C<tr\\\>), nothing is skipped.
1897 During the search for the end, backslashes that escape delimiters
1898 are removed (exactly speaking, they are not copied to the safe location).
1899
1900 For constructs with three-part delimiters (C<s///>, C<y///>, and
1901 C<tr///>), the search is repeated once more.
1902 If the first delimiter is not an opening punctuation, three delimiters must
1903 be same such as C<s!!!> and C<tr)))>, in which case the second delimiter
1904 terminates the left part and starts the right part at once.
1905 If the left part is delimited by bracketing punctuations (that is C<()>,
1906 C<[]>, C<{}>, or C<< <> >>), the right part needs another pair of
1907 delimiters such as C<s(){}> and C<tr[]//>.  In these cases, whitespaces
1908 and comments are allowed between both parts, though the comment must follow
1909 at least one whitespace; otherwise a character expected as the start of
1910 the comment may be regarded as the starting delimiter of the right part.
1911
1912 During this search no attention is paid to the semantics of the construct.
1913 Thus:
1914
1915     "$hash{"$foo/$bar"}"
1916
1917 or:
1918
1919     m/
1920       bar       # NOT a comment, this slash / terminated m//!
1921      /x
1922
1923 do not form legal quoted expressions.   The quoted part ends on the
1924 first C<"> and C</>, and the rest happens to be a syntax error.
1925 Because the slash that terminated C<m//> was followed by a C<SPACE>,
1926 the example above is not C<m//x>, but rather C<m//> with no C</x>
1927 modifier.  So the embedded C<#> is interpreted as a literal C<#>.
1928
1929 Also no attention is paid to C<\c\> (multichar control char syntax) during
1930 this search. Thus the second C<\> in C<qq/\c\/> is interpreted as a part
1931 of C<\/>, and the following C</> is not recognized as a delimiter.
1932 Instead, use C<\034> or C<\x1c> at the end of quoted constructs.
1933
1934 =item Interpolation
1935 X<interpolation>
1936
1937 The next step is interpolation in the text obtained, which is now
1938 delimiter-independent.  There are multiple cases.
1939
1940 =over 4
1941
1942 =item C<<<'EOF'>
1943
1944 No interpolation is performed.
1945 Note that the combination C<\\> is left intact, since escaped delimiters
1946 are not available for here-docs.
1947
1948 =item  C<m''>, the pattern of C<s'''>
1949
1950 No interpolation is performed at this stage.
1951 Any backslashed sequences including C<\\> are treated at the stage
1952 to L</"parsing regular expressions">.
1953
1954 =item C<''>, C<q//>, C<tr'''>, C<y'''>, the replacement of C<s'''>
1955
1956 The only interpolation is removal of C<\> from pairs of C<\\>.
1957 Therefore C<-> in C<tr'''> and C<y'''> is treated literally
1958 as a hyphen and no character range is available.
1959 C<\1> in the replacement of C<s'''> does not work as C<$1>.
1960
1961 =item C<tr///>, C<y///>
1962
1963 No variable interpolation occurs.  String modifying combinations for
1964 case and quoting such as C<\Q>, C<\U>, and C<\E> are not recognized.
1965 The other escape sequences such as C<\200> and C<\t> and backslashed
1966 characters such as C<\\> and C<\-> are converted to appropriate literals.
1967 The character C<-> is treated specially and therefore C<\-> is treated
1968 as a literal C<->.
1969
1970 =item C<"">, C<``>, C<qq//>, C<qx//>, C<< <file*glob> >>, C<<<"EOF">
1971
1972 C<\Q>, C<\U>, C<\u>, C<\L>, C<\l> (possibly paired with C<\E>) are
1973 converted to corresponding Perl constructs.  Thus, C<"$foo\Qbaz$bar">
1974 is converted to C<$foo . (quotemeta("baz" . $bar))> internally.
1975 The other escape sequences such as C<\200> and C<\t> and backslashed
1976 characters such as C<\\> and C<\-> are replaced with appropriate
1977 expansions.
1978
1979 Let it be stressed that I<whatever falls between C<\Q> and C<\E>>
1980 is interpolated in the usual way.  Something like C<"\Q\\E"> has
1981 no C<\E> inside.  instead, it has C<\Q>, C<\\>, and C<E>, so the
1982 result is the same as for C<"\\\\E">.  As a general rule, backslashes
1983 between C<\Q> and C<\E> may lead to counterintuitive results.  So,
1984 C<"\Q\t\E"> is converted to C<quotemeta("\t")>, which is the same
1985 as C<"\\\t"> (since TAB is not alphanumeric).  Note also that:
1986
1987   $str = '\t';
1988   return "\Q$str";
1989
1990 may be closer to the conjectural I<intention> of the writer of C<"\Q\t\E">.
1991
1992 Interpolated scalars and arrays are converted internally to the C<join> and
1993 C<.> catenation operations.  Thus, C<"$foo XXX '@arr'"> becomes:
1994
1995   $foo . " XXX '" . (join $", @arr) . "'";
1996
1997 All operations above are performed simultaneously, left to right.
1998
1999 Because the result of C<"\Q STRING \E"> has all metacharacters
2000 quoted, there is no way to insert a literal C<$> or C<@> inside a
2001 C<\Q\E> pair.  If protected by C<\>, C<$> will be quoted to became
2002 C<"\\\$">; if not, it is interpreted as the start of an interpolated
2003 scalar.
2004
2005 Note also that the interpolation code needs to make a decision on
2006 where the interpolated scalar ends.  For instance, whether
2007 C<< "a $b -> {c}" >> really means:
2008
2009   "a " . $b . " -> {c}";
2010
2011 or:
2012
2013   "a " . $b -> {c};
2014
2015 Most of the time, the longest possible text that does not include
2016 spaces between components and which contains matching braces or
2017 brackets.  because the outcome may be determined by voting based
2018 on heuristic estimators, the result is not strictly predictable.
2019 Fortunately, it's usually correct for ambiguous cases.
2020
2021 =item the replacement of C<s///>
2022
2023 Processing of C<\Q>, C<\U>, C<\u>, C<\L>, C<\l>, and interpolation
2024 happens as with C<qq//> constructs.
2025
2026 It is at this step that C<\1> is begrudgingly converted to C<$1> in
2027 the replacement text of C<s///>, in order to correct the incorrigible
2028 I<sed> hackers who haven't picked up the saner idiom yet.  A warning
2029 is emitted if the C<use warnings> pragma or the B<-w> command-line flag
2030 (that is, the C<$^W> variable) was set.
2031
2032 =item C<RE> in C<?RE?>, C</RE/>, C<m/RE/>, C<s/RE/foo/>,
2033
2034 Processing of C<\Q>, C<\U>, C<\u>, C<\L>, C<\l>, C<\E>,
2035 and interpolation happens (almost) as with C<qq//> constructs.
2036
2037 However any other combinations of C<\> followed by a character
2038 are not substituted but only skipped, in order to parse them
2039 as regular expressions at the following step.
2040 As C<\c> is skipped at this step, C<@> of C<\c@> in RE is possibly
2041 treated as an array symbol (for example C<@foo>),
2042 even though the same text in C<qq//> gives interpolation of C<\c@>.
2043
2044 Moreover, inside C<(?{BLOCK})>, C<(?# comment )>, and
2045 a C<#>-comment in a C<//x>-regular expression, no processing is
2046 performed whatsoever.  This is the first step at which the presence
2047 of the C<//x> modifier is relevant.
2048
2049 Interpolation in patterns has several quirks: C<$|>, C<$(>, C<$)>, C<@+>
2050 and C<@-> are not interpolated, and constructs C<$var[SOMETHING]> are
2051 voted (by several different estimators) to be either an array element
2052 or C<$var> followed by an RE alternative.  This is where the notation
2053 C<${arr[$bar]}> comes handy: C</${arr[0-9]}/> is interpreted as
2054 array element C<-9>, not as a regular expression from the variable
2055 C<$arr> followed by a digit, which would be the interpretation of
2056 C</$arr[0-9]/>.  Since voting among different estimators may occur,
2057 the result is not predictable.
2058
2059 The lack of processing of C<\\> creates specific restrictions on
2060 the post-processed text.  If the delimiter is C</>, one cannot get
2061 the combination C<\/> into the result of this step.  C</> will
2062 finish the regular expression, C<\/> will be stripped to C</> on
2063 the previous step, and C<\\/> will be left as is.  Because C</> is
2064 equivalent to C<\/> inside a regular expression, this does not
2065 matter unless the delimiter happens to be character special to the
2066 RE engine, such as in C<s*foo*bar*>, C<m[foo]>, or C<?foo?>; or an
2067 alphanumeric char, as in:
2068
2069   m m ^ a \s* b mmx;
2070
2071 In the RE above, which is intentionally obfuscated for illustration, the
2072 delimiter is C<m>, the modifier is C<mx>, and after delimiter-removal the
2073 RE is the same as for C<m/ ^ a \s* b /mx>.  There's more than one
2074 reason you're encouraged to restrict your delimiters to non-alphanumeric,
2075 non-whitespace choices.
2076
2077 =back
2078
2079 This step is the last one for all constructs except regular expressions,
2080 which are processed further.
2081
2082 =item parsing regular expressions
2083 X<regexp, parse>
2084
2085 Previous steps were performed during the compilation of Perl code,
2086 but this one happens at run time--although it may be optimized to
2087 be calculated at compile time if appropriate.  After preprocessing
2088 described above, and possibly after evaluation if concatenation,
2089 joining, casing translation, or metaquoting are involved, the
2090 resulting I<string> is passed to the RE engine for compilation.
2091
2092 Whatever happens in the RE engine might be better discussed in L<perlre>,
2093 but for the sake of continuity, we shall do so here.
2094
2095 This is another step where the presence of the C<//x> modifier is
2096 relevant.  The RE engine scans the string from left to right and
2097 converts it to a finite automaton.
2098
2099 Backslashed characters are either replaced with corresponding
2100 literal strings (as with C<\{>), or else they generate special nodes
2101 in the finite automaton (as with C<\b>).  Characters special to the
2102 RE engine (such as C<|>) generate corresponding nodes or groups of
2103 nodes.  C<(?#...)> comments are ignored.  All the rest is either
2104 converted to literal strings to match, or else is ignored (as is
2105 whitespace and C<#>-style comments if C<//x> is present).
2106
2107 Parsing of the bracketed character class construct, C<[...]>, is
2108 rather different than the rule used for the rest of the pattern.
2109 The terminator of this construct is found using the same rules as
2110 for finding the terminator of a C<{}>-delimited construct, the only
2111 exception being that C<]> immediately following C<[> is treated as
2112 though preceded by a backslash.  Similarly, the terminator of
2113 C<(?{...})> is found using the same rules as for finding the
2114 terminator of a C<{}>-delimited construct.
2115
2116 It is possible to inspect both the string given to RE engine and the
2117 resulting finite automaton.  See the arguments C<debug>/C<debugcolor>
2118 in the C<use L<re>> pragma, as well as Perl's B<-Dr> command-line
2119 switch documented in L<perlrun/"Command Switches">.
2120
2121 =item Optimization of regular expressions
2122 X<regexp, optimization>
2123
2124 This step is listed for completeness only.  Since it does not change
2125 semantics, details of this step are not documented and are subject
2126 to change without notice.  This step is performed over the finite
2127 automaton that was generated during the previous pass.
2128
2129 It is at this stage that C<split()> silently optimizes C</^/> to
2130 mean C</^/m>.
2131
2132 =back
2133
2134 =head2 I/O Operators
2135 X<operator, i/o> X<operator, io> X<io> X<while> X<filehandle>
2136 X<< <> >> X<@ARGV>
2137
2138 There are several I/O operators you should know about.
2139
2140 A string enclosed by backticks (grave accents) first undergoes
2141 double-quote interpolation.  It is then interpreted as an external
2142 command, and the output of that command is the value of the
2143 backtick string, like in a shell.  In scalar context, a single string
2144 consisting of all output is returned.  In list context, a list of
2145 values is returned, one per line of output.  (You can set C<$/> to use
2146 a different line terminator.)  The command is executed each time the
2147 pseudo-literal is evaluated.  The status value of the command is
2148 returned in C<$?> (see L<perlvar> for the interpretation of C<$?>).
2149 Unlike in B<csh>, no translation is done on the return data--newlines
2150 remain newlines.  Unlike in any of the shells, single quotes do not
2151 hide variable names in the command from interpretation.  To pass a
2152 literal dollar-sign through to the shell you need to hide it with a
2153 backslash.  The generalized form of backticks is C<qx//>.  (Because
2154 backticks always undergo shell expansion as well, see L<perlsec> for
2155 security concerns.)
2156 X<qx> X<`> X<``> X<backtick> X<glob>
2157
2158 In scalar context, evaluating a filehandle in angle brackets yields
2159 the next line from that file (the newline, if any, included), or
2160 C<undef> at end-of-file or on error.  When C<$/> is set to C<undef>
2161 (sometimes known as file-slurp mode) and the file is empty, it
2162 returns C<''> the first time, followed by C<undef> subsequently.
2163
2164 Ordinarily you must assign the returned value to a variable, but
2165 there is one situation where an automatic assignment happens.  If
2166 and only if the input symbol is the only thing inside the conditional
2167 of a C<while> statement (even if disguised as a C<for(;;)> loop),
2168 the value is automatically assigned to the global variable $_,
2169 destroying whatever was there previously.  (This may seem like an
2170 odd thing to you, but you'll use the construct in almost every Perl
2171 script you write.)  The $_ variable is not implicitly localized.
2172 You'll have to put a C<local $_;> before the loop if you want that
2173 to happen.
2174
2175 The following lines are equivalent:
2176
2177     while (defined($_ = <STDIN>)) { print; }
2178     while ($_ = <STDIN>) { print; }
2179     while (<STDIN>) { print; }
2180     for (;<STDIN>;) { print; }
2181     print while defined($_ = <STDIN>);
2182     print while ($_ = <STDIN>);
2183     print while <STDIN>;
2184
2185 This also behaves similarly, but avoids $_ :
2186
2187     while (my $line = <STDIN>) { print $line }
2188
2189 In these loop constructs, the assigned value (whether assignment
2190 is automatic or explicit) is then tested to see whether it is
2191 defined.  The defined test avoids problems where line has a string
2192 value that would be treated as false by Perl, for example a "" or
2193 a "0" with no trailing newline.  If you really mean for such values
2194 to terminate the loop, they should be tested for explicitly:
2195
2196     while (($_ = <STDIN>) ne '0') { ... }
2197     while (<STDIN>) { last unless $_; ... }
2198
2199 In other boolean contexts, C<< <I<filehandle>> >> without an
2200 explicit C<defined> test or comparison elicit a warning if the
2201 C<use warnings> pragma or the B<-w>
2202 command-line switch (the C<$^W> variable) is in effect.
2203
2204 The filehandles STDIN, STDOUT, and STDERR are predefined.  (The
2205 filehandles C<stdin>, C<stdout>, and C<stderr> will also work except
2206 in packages, where they would be interpreted as local identifiers
2207 rather than global.)  Additional filehandles may be created with
2208 the open() function, amongst others.  See L<perlopentut> and
2209 L<perlfunc/open> for details on this.
2210 X<stdin> X<stdout> X<sterr>
2211
2212 If a <FILEHANDLE> is used in a context that is looking for
2213 a list, a list comprising all input lines is returned, one line per
2214 list element.  It's easy to grow to a rather large data space this
2215 way, so use with care.
2216
2217 <FILEHANDLE> may also be spelled C<readline(*FILEHANDLE)>.
2218 See L<perlfunc/readline>.
2219
2220 The null filehandle <> is special: it can be used to emulate the
2221 behavior of B<sed> and B<awk>.  Input from <> comes either from
2222 standard input, or from each file listed on the command line.  Here's
2223 how it works: the first time <> is evaluated, the @ARGV array is
2224 checked, and if it is empty, C<$ARGV[0]> is set to "-", which when opened
2225 gives you standard input.  The @ARGV array is then processed as a list
2226 of filenames.  The loop
2227
2228     while (<>) {
2229         ...                     # code for each line
2230     }
2231
2232 is equivalent to the following Perl-like pseudo code:
2233
2234     unshift(@ARGV, '-') unless @ARGV;
2235     while ($ARGV = shift) {
2236         open(ARGV, $ARGV);
2237         while (<ARGV>) {
2238             ...         # code for each line
2239         }
2240     }
2241
2242 except that it isn't so cumbersome to say, and will actually work.
2243 It really does shift the @ARGV array and put the current filename
2244 into the $ARGV variable.  It also uses filehandle I<ARGV>
2245 internally--<> is just a synonym for <ARGV>, which
2246 is magical.  (The pseudo code above doesn't work because it treats
2247 <ARGV> as non-magical.)
2248
2249 You can modify @ARGV before the first <> as long as the array ends up
2250 containing the list of filenames you really want.  Line numbers (C<$.>)
2251 continue as though the input were one big happy file.  See the example
2252 in L<perlfunc/eof> for how to reset line numbers on each file.
2253
2254 If you want to set @ARGV to your own list of files, go right ahead.
2255 This sets @ARGV to all plain text files if no @ARGV was given:
2256
2257     @ARGV = grep { -f && -T } glob('*') unless @ARGV;
2258
2259 You can even set them to pipe commands.  For example, this automatically
2260 filters compressed arguments through B<gzip>:
2261
2262     @ARGV = map { /\.(gz|Z)$/ ? "gzip -dc < $_ |" : $_ } @ARGV;
2263
2264 If you want to pass switches into your script, you can use one of the
2265 Getopts modules or put a loop on the front like this:
2266
2267     while ($_ = $ARGV[0], /^-/) {
2268         shift;
2269         last if /^--$/;
2270         if (/^-D(.*)/) { $debug = $1 }
2271         if (/^-v/)     { $verbose++  }
2272         # ...           # other switches
2273     }
2274
2275     while (<>) {
2276         # ...           # code for each line
2277     }
2278
2279 The <> symbol will return C<undef> for end-of-file only once.
2280 If you call it again after this, it will assume you are processing another
2281 @ARGV list, and if you haven't set @ARGV, will read input from STDIN.
2282
2283 If what the angle brackets contain is a simple scalar variable (e.g.,
2284 <$foo>), then that variable contains the name of the
2285 filehandle to input from, or its typeglob, or a reference to the
2286 same.  For example:
2287
2288     $fh = \*STDIN;
2289     $line = <$fh>;
2290
2291 If what's within the angle brackets is neither a filehandle nor a simple
2292 scalar variable containing a filehandle name, typeglob, or typeglob
2293 reference, it is interpreted as a filename pattern to be globbed, and
2294 either a list of filenames or the next filename in the list is returned,
2295 depending on context.  This distinction is determined on syntactic
2296 grounds alone.  That means C<< <$x> >> is always a readline() from
2297 an indirect handle, but C<< <$hash{key}> >> is always a glob().
2298 That's because $x is a simple scalar variable, but C<$hash{key}> is
2299 not--it's a hash element.  Even C<< <$x > >> (note the extra space)
2300 is treated as C<glob("$x ")>, not C<readline($x)>.
2301
2302 One level of double-quote interpretation is done first, but you can't
2303 say C<< <$foo> >> because that's an indirect filehandle as explained
2304 in the previous paragraph.  (In older versions of Perl, programmers
2305 would insert curly brackets to force interpretation as a filename glob:
2306 C<< <${foo}> >>.  These days, it's considered cleaner to call the
2307 internal function directly as C<glob($foo)>, which is probably the right
2308 way to have done it in the first place.)  For example:
2309
2310     while (<*.c>) {
2311         chmod 0644, $_;
2312     }
2313
2314 is roughly equivalent to:
2315
2316     open(FOO, "echo *.c | tr -s ' \t\r\f' '\\012\\012\\012\\012'|");
2317     while (<FOO>) {
2318         chomp;
2319         chmod 0644, $_;
2320     }
2321
2322 except that the globbing is actually done internally using the standard
2323 C<File::Glob> extension.  Of course, the shortest way to do the above is:
2324
2325     chmod 0644, <*.c>;
2326
2327 A (file)glob evaluates its (embedded) argument only when it is
2328 starting a new list.  All values must be read before it will start
2329 over.  In list context, this isn't important because you automatically
2330 get them all anyway.  However, in scalar context the operator returns
2331 the next value each time it's called, or C<undef> when the list has
2332 run out.  As with filehandle reads, an automatic C<defined> is
2333 generated when the glob occurs in the test part of a C<while>,
2334 because legal glob returns (e.g. a file called F<0>) would otherwise
2335 terminate the loop.  Again, C<undef> is returned only once.  So if
2336 you're expecting a single value from a glob, it is much better to
2337 say
2338
2339     ($file) = <blurch*>;
2340
2341 than
2342
2343     $file = <blurch*>;
2344
2345 because the latter will alternate between returning a filename and
2346 returning false.
2347
2348 If you're trying to do variable interpolation, it's definitely better
2349 to use the glob() function, because the older notation can cause people
2350 to become confused with the indirect filehandle notation.
2351
2352     @files = glob("$dir/*.[ch]");
2353     @files = glob($files[$i]);
2354
2355 =head2 Constant Folding
2356 X<constant folding> X<folding>
2357
2358 Like C, Perl does a certain amount of expression evaluation at
2359 compile time whenever it determines that all arguments to an
2360 operator are static and have no side effects.  In particular, string
2361 concatenation happens at compile time between literals that don't do
2362 variable substitution.  Backslash interpolation also happens at
2363 compile time.  You can say
2364
2365     'Now is the time for all' . "\n" .
2366         'good men to come to.'
2367
2368 and this all reduces to one string internally.  Likewise, if
2369 you say
2370
2371     foreach $file (@filenames) {
2372         if (-s $file > 5 + 100 * 2**16) {  }
2373     }
2374
2375 the compiler will precompute the number which that expression
2376 represents so that the interpreter won't have to.
2377
2378 =head2 No-ops
2379 X<no-op> X<nop>
2380
2381 Perl doesn't officially have a no-op operator, but the bare constants
2382 C<0> and C<1> are special-cased to not produce a warning in a void
2383 context, so you can for example safely do
2384
2385     1 while foo();
2386
2387 =head2 Bitwise String Operators
2388 X<operator, bitwise, string>
2389
2390 Bitstrings of any size may be manipulated by the bitwise operators
2391 (C<~ | & ^>).
2392
2393 If the operands to a binary bitwise op are strings of different
2394 sizes, B<|> and B<^> ops act as though the shorter operand had
2395 additional zero bits on the right, while the B<&> op acts as though
2396 the longer operand were truncated to the length of the shorter.
2397 The granularity for such extension or truncation is one or more
2398 bytes.
2399
2400     # ASCII-based examples
2401     print "j p \n" ^ " a h";            # prints "JAPH\n"
2402     print "JA" | "  ph\n";              # prints "japh\n"
2403     print "japh\nJunk" & '_____';       # prints "JAPH\n";
2404     print 'p N$' ^ " E<H\n";            # prints "Perl\n";
2405
2406 If you are intending to manipulate bitstrings, be certain that
2407 you're supplying bitstrings: If an operand is a number, that will imply
2408 a B<numeric> bitwise operation.  You may explicitly show which type of
2409 operation you intend by using C<""> or C<0+>, as in the examples below.
2410
2411     $foo =  150  |  105;        # yields 255  (0x96 | 0x69 is 0xFF)
2412     $foo = '150' |  105;        # yields 255
2413     $foo =  150  | '105';       # yields 255
2414     $foo = '150' | '105';       # yields string '155' (under ASCII)
2415
2416     $baz = 0+$foo & 0+$bar;     # both ops explicitly numeric
2417     $biz = "$foo" ^ "$bar";     # both ops explicitly stringy
2418
2419 See L<perlfunc/vec> for information on how to manipulate individual bits
2420 in a bit vector.
2421
2422 =head2 Integer Arithmetic
2423 X<integer>
2424
2425 By default, Perl assumes that it must do most of its arithmetic in
2426 floating point.  But by saying
2427
2428     use integer;
2429
2430 you may tell the compiler that it's okay to use integer operations
2431 (if it feels like it) from here to the end of the enclosing BLOCK.
2432 An inner BLOCK may countermand this by saying
2433
2434     no integer;
2435
2436 which lasts until the end of that BLOCK.  Note that this doesn't
2437 mean everything is only an integer, merely that Perl may use integer
2438 operations if it is so inclined.  For example, even under C<use
2439 integer>, if you take the C<sqrt(2)>, you'll still get C<1.4142135623731>
2440 or so.
2441
2442 Used on numbers, the bitwise operators ("&", "|", "^", "~", "<<",
2443 and ">>") always produce integral results.  (But see also
2444 L<Bitwise String Operators>.)  However, C<use integer> still has meaning for
2445 them.  By default, their results are interpreted as unsigned integers, but
2446 if C<use integer> is in effect, their results are interpreted
2447 as signed integers.  For example, C<~0> usually evaluates to a large
2448 integral value.  However, C<use integer; ~0> is C<-1> on two's-complement
2449 machines.
2450
2451 =head2 Floating-point Arithmetic
2452 X<floating-point> X<floating point> X<float> X<real>
2453
2454 While C<use integer> provides integer-only arithmetic, there is no
2455 analogous mechanism to provide automatic rounding or truncation to a
2456 certain number of decimal places.  For rounding to a certain number
2457 of digits, sprintf() or printf() is usually the easiest route.
2458 See L<perlfaq4>.
2459
2460 Floating-point numbers are only approximations to what a mathematician
2461 would call real numbers.  There are infinitely more reals than floats,
2462 so some corners must be cut.  For example:
2463
2464     printf "%.20g\n", 123456789123456789;
2465     #        produces 123456789123456784
2466
2467 Testing for exact equality of floating-point equality or inequality is
2468 not a good idea.  Here's a (relatively expensive) work-around to compare
2469 whether two floating-point numbers are equal to a particular number of
2470 decimal places.  See Knuth, volume II, for a more robust treatment of
2471 this topic.
2472
2473     sub fp_equal {
2474         my ($X, $Y, $POINTS) = @_;
2475         my ($tX, $tY);
2476         $tX = sprintf("%.${POINTS}g", $X);
2477         $tY = sprintf("%.${POINTS}g", $Y);
2478         return $tX eq $tY;
2479     }
2480
2481 The POSIX module (part of the standard perl distribution) implements
2482 ceil(), floor(), and other mathematical and trigonometric functions.
2483 The Math::Complex module (part of the standard perl distribution)
2484 defines mathematical functions that work on both the reals and the
2485 imaginary numbers.  Math::Complex not as efficient as POSIX, but
2486 POSIX can't work with complex numbers.
2487
2488 Rounding in financial applications can have serious implications, and
2489 the rounding method used should be specified precisely.  In these
2490 cases, it probably pays not to trust whichever system rounding is
2491 being used by Perl, but to instead implement the rounding function you
2492 need yourself.
2493
2494 =head2 Bigger Numbers
2495 X<number, arbitrary precision>
2496
2497 The standard Math::BigInt and Math::BigFloat modules provide
2498 variable-precision arithmetic and overloaded operators, although
2499 they're currently pretty slow. At the cost of some space and
2500 considerable speed, they avoid the normal pitfalls associated with
2501 limited-precision representations.
2502
2503     use Math::BigInt;
2504     $x = Math::BigInt->new('123456789123456789');
2505     print $x * $x;
2506
2507     # prints +15241578780673678515622620750190521
2508
2509 There are several modules that let you calculate with (bound only by
2510 memory and cpu-time) unlimited or fixed precision. There are also
2511 some non-standard modules that provide faster implementations via
2512 external C libraries.
2513
2514 Here is a short, but incomplete summary:
2515
2516         Math::Fraction          big, unlimited fractions like 9973 / 12967
2517         Math::String            treat string sequences like numbers
2518         Math::FixedPrecision    calculate with a fixed precision
2519         Math::Currency          for currency calculations
2520         Bit::Vector             manipulate bit vectors fast (uses C)
2521         Math::BigIntFast        Bit::Vector wrapper for big numbers
2522         Math::Pari              provides access to the Pari C library
2523         Math::BigInteger        uses an external C library
2524         Math::Cephes            uses external Cephes C library (no big numbers)
2525         Math::Cephes::Fraction  fractions via the Cephes library
2526         Math::GMP               another one using an external C library
2527
2528 Choose wisely.
2529
2530 =cut