RE: How to load a "loadable object" that has a non-default file extension ?
[perl.git] / win32 / config_sh.PL
1 use FindExt;
2 # take a semicolon separated path list and turn it into a quoted
3 # list of paths that Text::Parsewords will grok
4 sub mungepath {
5     my $p = shift;
6     # remove leading/trailing semis/spaces
7     $p =~ s/^[ ;]+//;
8     $p =~ s/[ ;]+$//;
9     $p =~ s/'/"/g;
10     my @p = map { $_ = "\"$_\"" if /\s/ and !/^".*"$/; $_ } split /;/, $p;
11     return join(' ', @p);
12 }
13
14 # generate an array of option strings from command-line args
15 # or an option file
16 #    -- added by BKS, 10-17-1999 to fix command-line overflow problems
17 sub loadopts {
18     if ($ARGV[0] =~ /--cfgsh-option-file/) {
19         shift @ARGV;
20         my $optfile = shift @ARGV;
21         local (*F);
22         open OPTF, $optfile or die "Can't open $optfile: $!\n";
23         my @opts;
24         chomp(my $line = <OPTF>);
25         my @vars = split(/\t+~\t+/, $line);
26         for (@vars) {
27             push(@opts, $_) unless (/^\s*$/);
28         }
29         close OPTF;
30         return \@opts;
31     }
32     else {
33         return \@ARGV;
34     }
35 }
36
37 my %opt;
38
39 my $optref = loadopts();
40 while (@{$optref} && $optref->[0] =~ /^([\w_]+)=(.*)$/) {
41     $opt{$1}=$2;
42     shift(@{$optref});
43 }
44
45 FindExt::scan_ext("../ext");
46 FindExt::scan_ext("ext") if -d 'ext';  # also look in win32/ext/ if it exists
47 FindExt::set_static_extensions(split ' ', $opt{'static_ext'});
48
49 $opt{'nonxs_ext'}        = join(' ',FindExt::nonxs_ext()) || ' ';
50 $opt{'static_ext'}       = join(' ',FindExt::static_ext()) || ' ';
51 $opt{'dynamic_ext'}      = join(' ',FindExt::dynamic_ext()) || ' ';
52 $opt{'extensions'}       = join(' ',FindExt::extensions()) || ' ';
53 $opt{'known_extensions'} = join(' ',FindExt::known_extensions()) || ' ';
54
55 my $pl_h = '../patchlevel.h';
56
57 if (-e $pl_h) {
58     open PL, "<$pl_h" or die "Can't open $pl_h: $!";
59     while (<PL>) {
60         if (/^#\s*define\s+(PERL_\w+)\s+([\d.]+)/) {
61             $opt{$1} = $2;
62         }
63     }
64     close PL;
65 }
66 else {
67     die "Can't find $pl_h: $!";
68 }
69
70 my $patch_file = '../.patch';
71
72 if (-e $patch_file) {
73     open my $fh, "<", $patch_file or die "Can't open $patch_file: $!";
74     chomp($opt{PERL_PATCHLEVEL} = <$fh>);
75     close $fh;
76 }
77
78 $opt{VERSION} = "$opt{PERL_REVISION}.$opt{PERL_VERSION}.$opt{PERL_SUBVERSION}";
79 $opt{INST_VER} =~ s|~VERSION~|$opt{VERSION}|g;
80 $opt{'version_patchlevel_string'} = "version $opt{PERL_VERSION} subversion $opt{PERL_SUBVERSION}";
81 $opt{'version_patchlevel_string'} .= " patchlevel $opt{PERL_PATCHLEVEL}" if exists $opt{PERL_PATCHLEVEL};
82
83 my $ver = `ver 2>nul`;
84 if ($ver =~ /Version (\d+\.\d+)/) {
85     $opt{'osvers'} = $1;
86 }
87 else {
88     $opt{'osvers'} = '4.0';
89 }
90
91 if (exists $opt{cc}) {
92     # cl and bcc32 version detection borrowed from Test::Smoke's configsmoke.pl
93     if ($opt{cc} eq 'cl') {
94         my $output = `cl --version 2>&1`;
95         $opt{ccversion} = $output =~ /^.*Version\s+([\d.]+)/ ? $1 : '?';
96     }
97     elsif ($opt{cc} eq 'bcc32') {
98         my $output = `bcc32 --version 2>&1`;
99         $opt{ccversion} = $output =~ /([\d.]+)/ ? $1 : '?';
100     }
101     elsif ($opt{cc} eq 'gcc') {
102         chomp($opt{gccversion} = `gcc -dumpversion`);
103     }
104 }
105
106 $opt{'cf_by'} = $ENV{USERNAME} unless $opt{'cf_by'};
107 $opt{'cf_email'} = $opt{'cf_by'} . '@' . (gethostbyname('localhost'))[0]
108         unless $opt{'cf_email'};
109 $opt{'usemymalloc'} = 'y' if $opt{'d_mymalloc'} eq 'define';
110
111 $opt{libpth} = mungepath($opt{libpth}) if exists $opt{libpth};
112 $opt{incpath} = mungepath($opt{incpath}) if exists $opt{incpath};
113
114 # some functions are not available on Win9x
115 unless (defined $ENV{SYSTEMROOT}) { # SystemRoot has been introduced by WinNT
116     $opt{d_flock} = 'undef';
117     $opt{d_link} = 'undef';
118 }
119
120 if ($opt{uselargefiles} ne 'define') {
121     $opt{lseeksize} = 4;
122     $opt{lseektype} = 'off_t';
123 }
124
125 if ($opt{useithreads} eq 'define' && $opt{ccflags} =~ /-DPERL_IMPLICIT_SYS\b/) {
126     $opt{d_pseudofork} = 'define';
127 }
128
129 while (<>) {
130     s/~([\w_]+)~/$opt{$1}/g;
131     if (/^([\w_]+)=(.*)$/) {
132         my($k,$v) = ($1,$2);
133         # this depends on cf_time being empty in the template (or we'll
134         # get a loop)
135         if ($k eq 'cf_time') {
136             $_ = "$k='" . localtime(time) . "'\n" if $v =~ /^\s*'\s*'/;
137         }
138         elsif (exists $opt{$k}) {
139             $_ = "$k='$opt{$k}'\n";
140         }
141     }
142     print;
143 }