RE: How to load a "loadable object" that has a non-default file extension ?
[perl.git] / pod / perlvar.pod
1 =head1 NAME
2
3 perlvar - Perl predefined variables
4
5 =head1 DESCRIPTION
6
7 =head2 Predefined Names
8
9 The following names have special meaning to Perl.  Most 
10 punctuation names have reasonable mnemonics, or analogs in the
11 shells.  Nevertheless, if you wish to use long variable names,
12 you need only say
13
14     use English;
15
16 at the top of your program. This aliases all the short names to the long
17 names in the current package. Some even have medium names, generally
18 borrowed from B<awk>. In general, it's best to use the
19
20     use English '-no_match_vars';
21
22 invocation if you don't need $PREMATCH, $MATCH, or $POSTMATCH, as it avoids
23 a certain performance hit with the use of regular expressions. See
24 L<English>.
25
26 Variables that depend on the currently selected filehandle may be set by
27 calling an appropriate object method on the IO::Handle object, although
28 this is less efficient than using the regular built-in variables. (Summary
29 lines below for this contain the word HANDLE.) First you must say
30
31     use IO::Handle;
32
33 after which you may use either
34
35     method HANDLE EXPR
36
37 or more safely,
38
39     HANDLE->method(EXPR)
40
41 Each method returns the old value of the IO::Handle attribute.
42 The methods each take an optional EXPR, which, if supplied, specifies the
43 new value for the IO::Handle attribute in question.  If not supplied,
44 most methods do nothing to the current value--except for
45 autoflush(), which will assume a 1 for you, just to be different.
46
47 Because loading in the IO::Handle class is an expensive operation, you should
48 learn how to use the regular built-in variables.
49
50 A few of these variables are considered "read-only".  This means that if
51 you try to assign to this variable, either directly or indirectly through
52 a reference, you'll raise a run-time exception.
53
54 You should be very careful when modifying the default values of most
55 special variables described in this document. In most cases you want
56 to localize these variables before changing them, since if you don't,
57 the change may affect other modules which rely on the default values
58 of the special variables that you have changed. This is one of the
59 correct ways to read the whole file at once:
60
61     open my $fh, "foo" or die $!;
62     local $/; # enable localized slurp mode
63     my $content = <$fh>;
64     close $fh;
65
66 But the following code is quite bad:
67
68     open my $fh, "foo" or die $!;
69     undef $/; # enable slurp mode
70     my $content = <$fh>;
71     close $fh;
72
73 since some other module, may want to read data from some file in the
74 default "line mode", so if the code we have just presented has been
75 executed, the global value of C<$/> is now changed for any other code
76 running inside the same Perl interpreter.
77
78 Usually when a variable is localized you want to make sure that this
79 change affects the shortest scope possible. So unless you are already
80 inside some short C<{}> block, you should create one yourself. For
81 example:
82
83     my $content = '';
84     open my $fh, "foo" or die $!;
85     {
86         local $/;
87         $content = <$fh>;
88     }
89     close $fh;
90
91 Here is an example of how your own code can go broken:
92
93     for (1..5){
94         nasty_break();
95         print "$_ ";
96     }
97     sub nasty_break {
98         $_ = 5;
99         # do something with $_
100     }
101
102 You probably expect this code to print:
103
104     1 2 3 4 5
105
106 but instead you get:
107
108     5 5 5 5 5
109
110 Why? Because nasty_break() modifies C<$_> without localizing it
111 first. The fix is to add local():
112
113         local $_ = 5;
114
115 It's easy to notice the problem in such a short example, but in more
116 complicated code you are looking for trouble if you don't localize
117 changes to the special variables.
118
119 The following list is ordered by scalar variables first, then the
120 arrays, then the hashes.
121
122 =over 8
123
124 =item $ARG
125
126 =item $_
127 X<$_> X<$ARG>
128
129 The default input and pattern-searching space.  The following pairs are
130 equivalent:
131
132     while (<>) {...}    # equivalent only in while!
133     while (defined($_ = <>)) {...}
134
135     /^Subject:/
136     $_ =~ /^Subject:/
137
138     tr/a-z/A-Z/
139     $_ =~ tr/a-z/A-Z/
140
141     chomp
142     chomp($_)
143
144 Here are the places where Perl will assume $_ even if you
145 don't use it:
146
147 =over 3
148
149 =item *
150
151 The following functions:
152
153 abs, alarm, chomp chop, chr, chroot, cos, defined, eval, exp, glob,
154 hex, int, lc, lcfirst, length, log, lstat, mkdir, ord, pos, print,
155 quotemeta, readlink, readpipe, ref, require, reverse, rmdir, sin, split, 
156 sqrt, stat, study, uc, ucfirst, unlink, unpack.
157
158 =item *
159
160 All file tests (C<-f>, C<-d>) except for C<-t>, which defaults to STDIN.
161 See L<perlfunc/-X>
162
163
164 =item *
165
166 The pattern matching operations C<m//>, C<s///>, and C<tr///> when used
167 without an C<=~> operator.
168
169 =item *
170
171 The default iterator variable in a C<foreach> loop if no other
172 variable is supplied.
173
174 =item *
175
176 The implicit iterator variable in the grep() and map() functions.
177
178 =item *
179
180 The implicit variable of given().
181
182 =item *
183
184 The default place to put an input record when a C<< <FH> >>
185 operation's result is tested by itself as the sole criterion of a C<while>
186 test.  Outside a C<while> test, this will not happen.
187
188 =back
189
190 As C<$_> is a global variable, this may lead in some cases to unwanted
191 side-effects.  As of perl 5.9.1, you can now use a lexical version of
192 C<$_> by declaring it in a file or in a block with C<my>.  Moreover,
193 declaring C<our $_> restores the global C<$_> in the current scope.
194
195 (Mnemonic: underline is understood in certain operations.)
196
197 =back
198
199 =over 8
200
201 =item $a
202
203 =item $b
204 X<$a> X<$b>
205
206 Special package variables when using sort(), see L<perlfunc/sort>.
207 Because of this specialness $a and $b don't need to be declared
208 (using use vars, or our()) even when using the C<strict 'vars'> pragma.
209 Don't lexicalize them with C<my $a> or C<my $b> if you want to be
210 able to use them in the sort() comparison block or function.
211
212 =back
213
214 =over 8
215
216 =item $<I<digits>>
217 X<$1> X<$2> X<$3>
218
219 Contains the subpattern from the corresponding set of capturing
220 parentheses from the last pattern match, not counting patterns
221 matched in nested blocks that have been exited already.  (Mnemonic:
222 like \digits.)  These variables are all read-only and dynamically
223 scoped to the current BLOCK.
224
225 =item $MATCH
226
227 =item $&
228 X<$&> X<$MATCH>
229
230 The string matched by the last successful pattern match (not counting
231 any matches hidden within a BLOCK or eval() enclosed by the current
232 BLOCK).  (Mnemonic: like & in some editors.)  This variable is read-only
233 and dynamically scoped to the current BLOCK.
234
235 The use of this variable anywhere in a program imposes a considerable
236 performance penalty on all regular expression matches.  See L</BUGS>.
237
238 See L</@-> for a replacement.
239
240 =item ${^MATCH}
241 X<${^MATCH}>
242
243 This is similar to C<$&> (C<$POSTMATCH>) except that it does not incur the
244 performance penalty associated with that variable, and is only guaranteed
245 to return a defined value when the pattern was compiled or executed with
246 the C</p> modifier.
247
248 =item $PREMATCH
249
250 =item $`
251 X<$`> X<$PREMATCH>
252
253 The string preceding whatever was matched by the last successful
254 pattern match (not counting any matches hidden within a BLOCK or eval
255 enclosed by the current BLOCK).  (Mnemonic: C<`> often precedes a quoted
256 string.)  This variable is read-only.
257
258 The use of this variable anywhere in a program imposes a considerable
259 performance penalty on all regular expression matches.  See L</BUGS>.
260
261 See L</@-> for a replacement.
262
263 =item ${^PREMATCH}
264 X<${^PREMATCH}>
265
266 This is similar to C<$`> ($PREMATCH) except that it does not incur the
267 performance penalty associated with that variable, and is only guaranteed
268 to return a defined value when the pattern was compiled or executed with
269 the C</p> modifier.
270
271 =item $POSTMATCH
272
273 =item $'
274 X<$'> X<$POSTMATCH>
275
276 The string following whatever was matched by the last successful
277 pattern match (not counting any matches hidden within a BLOCK or eval()
278 enclosed by the current BLOCK).  (Mnemonic: C<'> often follows a quoted
279 string.)  Example:
280
281     local $_ = 'abcdefghi';
282     /def/;
283     print "$`:$&:$'\n";         # prints abc:def:ghi
284
285 This variable is read-only and dynamically scoped to the current BLOCK.
286
287 The use of this variable anywhere in a program imposes a considerable
288 performance penalty on all regular expression matches.  See L</BUGS>.
289
290 See L</@-> for a replacement.
291
292 =item ${^POSTMATCH}
293 X<${^POSTMATCH}>
294
295 This is similar to C<$'> (C<$POSTMATCH>) except that it does not incur the
296 performance penalty associated with that variable, and is only guaranteed
297 to return a defined value when the pattern was compiled or executed with
298 the C</p> modifier.
299
300 =item $LAST_PAREN_MATCH
301
302 =item $+
303 X<$+> X<$LAST_PAREN_MATCH>
304
305 The text matched by the last bracket of the last successful search pattern.
306 This is useful if you don't know which one of a set of alternative patterns
307 matched. For example:
308
309     /Version: (.*)|Revision: (.*)/ && ($rev = $+);
310
311 (Mnemonic: be positive and forward looking.)
312 This variable is read-only and dynamically scoped to the current BLOCK.
313
314 =item $LAST_SUBMATCH_RESULT
315
316 =item $^N
317 X<$^N>
318
319 The text matched by the used group most-recently closed (i.e. the group
320 with the rightmost closing parenthesis) of the last successful search
321 pattern.  (Mnemonic: the (possibly) Nested parenthesis that most
322 recently closed.)
323
324 This is primarily used inside C<(?{...})> blocks for examining text
325 recently matched. For example, to effectively capture text to a variable
326 (in addition to C<$1>, C<$2>, etc.), replace C<(...)> with
327
328      (?:(...)(?{ $var = $^N }))
329
330 By setting and then using C<$var> in this way relieves you from having to
331 worry about exactly which numbered set of parentheses they are.
332
333 This variable is dynamically scoped to the current BLOCK.
334
335 =item @LAST_MATCH_END
336
337 =item @+
338 X<@+> X<@LAST_MATCH_END>
339
340 This array holds the offsets of the ends of the last successful
341 submatches in the currently active dynamic scope.  C<$+[0]> is
342 the offset into the string of the end of the entire match.  This
343 is the same value as what the C<pos> function returns when called
344 on the variable that was matched against.  The I<n>th element
345 of this array holds the offset of the I<n>th submatch, so
346 C<$+[1]> is the offset past where $1 ends, C<$+[2]> the offset
347 past where $2 ends, and so on.  You can use C<$#+> to determine
348 how many subgroups were in the last successful match.  See the
349 examples given for the C<@-> variable.
350
351 =item %+
352 X<%+>
353
354 Similar to C<@+>, the C<%+> hash allows access to the named capture
355 buffers, should they exist, in the last successful match in the
356 currently active dynamic scope.
357
358 For example, C<$+{foo}> is equivalent to C<$1> after the following match:
359
360   'foo' =~ /(?<foo>foo)/;
361
362 The keys of the C<%+> hash list only the names of buffers that have
363 captured (and that are thus associated to defined values).
364
365 The underlying behaviour of C<%+> is provided by the
366 L<Tie::Hash::NamedCapture> module.
367
368 B<Note:> C<%-> and C<%+> are tied views into a common internal hash
369 associated with the last successful regular expression. Therefore mixing
370 iterative access to them via C<each> may have unpredictable results.
371 Likewise, if the last successful match changes, then the results may be
372 surprising.
373
374 =item HANDLE->input_line_number(EXPR)
375
376 =item $INPUT_LINE_NUMBER
377
378 =item $NR
379
380 =item $.
381 X<$.> X<$NR> X<$INPUT_LINE_NUMBER> X<line number>
382
383 Current line number for the last filehandle accessed.
384
385 Each filehandle in Perl counts the number of lines that have been read
386 from it.  (Depending on the value of C<$/>, Perl's idea of what
387 constitutes a line may not match yours.)  When a line is read from a
388 filehandle (via readline() or C<< <> >>), or when tell() or seek() is
389 called on it, C<$.> becomes an alias to the line counter for that
390 filehandle.
391
392 You can adjust the counter by assigning to C<$.>, but this will not
393 actually move the seek pointer.  I<Localizing C<$.> will not localize
394 the filehandle's line count>.  Instead, it will localize perl's notion
395 of which filehandle C<$.> is currently aliased to.
396
397 C<$.> is reset when the filehandle is closed, but B<not> when an open
398 filehandle is reopened without an intervening close().  For more
399 details, see L<perlop/"IE<sol>O Operators">.  Because C<< <> >> never does
400 an explicit close, line numbers increase across ARGV files (but see
401 examples in L<perlfunc/eof>).
402
403 You can also use C<< HANDLE->input_line_number(EXPR) >> to access the
404 line counter for a given filehandle without having to worry about
405 which handle you last accessed.
406
407 (Mnemonic: many programs use "." to mean the current line number.)
408
409 =item IO::Handle->input_record_separator(EXPR)
410
411 =item $INPUT_RECORD_SEPARATOR
412
413 =item $RS
414
415 =item $/
416 X<$/> X<$RS> X<$INPUT_RECORD_SEPARATOR>
417
418 The input record separator, newline by default.  This 
419 influences Perl's idea of what a "line" is.  Works like B<awk>'s RS
420 variable, including treating empty lines as a terminator if set to
421 the null string.  (An empty line cannot contain any spaces
422 or tabs.)  You may set it to a multi-character string to match a
423 multi-character terminator, or to C<undef> to read through the end
424 of file.  Setting it to C<"\n\n"> means something slightly
425 different than setting to C<"">, if the file contains consecutive
426 empty lines.  Setting to C<""> will treat two or more consecutive
427 empty lines as a single empty line.  Setting to C<"\n\n"> will
428 blindly assume that the next input character belongs to the next
429 paragraph, even if it's a newline.  (Mnemonic: / delimits
430 line boundaries when quoting poetry.)
431
432     local $/;           # enable "slurp" mode
433     local $_ = <FH>;    # whole file now here
434     s/\n[ \t]+/ /g;
435
436 Remember: the value of C<$/> is a string, not a regex.  B<awk> has to be
437 better for something. :-)
438
439 Setting C<$/> to a reference to an integer, scalar containing an integer, or
440 scalar that's convertible to an integer will attempt to read records
441 instead of lines, with the maximum record size being the referenced
442 integer.  So this:
443
444     local $/ = \32768; # or \"32768", or \$var_containing_32768
445     open my $fh, $myfile or die $!;
446     local $_ = <$fh>;
447
448 will read a record of no more than 32768 bytes from FILE.  If you're
449 not reading from a record-oriented file (or your OS doesn't have
450 record-oriented files), then you'll likely get a full chunk of data
451 with every read.  If a record is larger than the record size you've
452 set, you'll get the record back in pieces.  Trying to set the record
453 size to zero or less will cause reading in the (rest of the) whole file.
454
455 On VMS, record reads are done with the equivalent of C<sysread>,
456 so it's best not to mix record and non-record reads on the same
457 file.  (This is unlikely to be a problem, because any file you'd
458 want to read in record mode is probably unusable in line mode.)
459 Non-VMS systems do normal I/O, so it's safe to mix record and
460 non-record reads of a file.
461
462 See also L<perlport/"Newlines">.  Also see C<$.>.
463
464 =item HANDLE->autoflush(EXPR)
465
466 =item $OUTPUT_AUTOFLUSH
467
468 =item $|
469 X<$|> X<autoflush> X<flush> X<$OUTPUT_AUTOFLUSH>
470
471 If set to nonzero, forces a flush right away and after every write
472 or print on the currently selected output channel.  Default is 0
473 (regardless of whether the channel is really buffered by the
474 system or not; C<$|> tells you only whether you've asked Perl
475 explicitly to flush after each write).  STDOUT will
476 typically be line buffered if output is to the terminal and block
477 buffered otherwise.  Setting this variable is useful primarily when
478 you are outputting to a pipe or socket, such as when you are running
479 a Perl program under B<rsh> and want to see the output as it's
480 happening.  This has no effect on input buffering.  See L<perlfunc/getc>
481 for that.  (Mnemonic: when you want your pipes to be piping hot.)
482
483 =item IO::Handle->output_field_separator EXPR
484
485 =item $OUTPUT_FIELD_SEPARATOR
486
487 =item $OFS
488
489 =item $,
490 X<$,> X<$OFS> X<$OUTPUT_FIELD_SEPARATOR>
491
492 The output field separator for the print operator.  If defined, this
493 value is printed between each of print's arguments.  Default is C<undef>.
494 (Mnemonic: what is printed when there is a "," in your print statement.)
495
496 =item IO::Handle->output_record_separator EXPR
497
498 =item $OUTPUT_RECORD_SEPARATOR
499
500 =item $ORS
501
502 =item $\
503 X<$\> X<$ORS> X<$OUTPUT_RECORD_SEPARATOR>
504
505 The output record separator for the print operator.  If defined, this
506 value is printed after the last of print's arguments.  Default is C<undef>.
507 (Mnemonic: you set C<$\> instead of adding "\n" at the end of the print.
508 Also, it's just like C<$/>, but it's what you get "back" from Perl.)
509
510 =item $LIST_SEPARATOR
511
512 =item $"
513 X<$"> X<$LIST_SEPARATOR>
514
515 This is like C<$,> except that it applies to array and slice values
516 interpolated into a double-quoted string (or similar interpreted
517 string).  Default is a space.  (Mnemonic: obvious, I think.)
518
519 =item $SUBSCRIPT_SEPARATOR
520
521 =item $SUBSEP
522
523 =item $;
524 X<$;> X<$SUBSEP> X<SUBSCRIPT_SEPARATOR>
525
526 The subscript separator for multidimensional array emulation.  If you
527 refer to a hash element as
528
529     $foo{$a,$b,$c}
530
531 it really means
532
533     $foo{join($;, $a, $b, $c)}
534
535 But don't put
536
537     @foo{$a,$b,$c}      # a slice--note the @
538
539 which means
540
541     ($foo{$a},$foo{$b},$foo{$c})
542
543 Default is "\034", the same as SUBSEP in B<awk>.  If your
544 keys contain binary data there might not be any safe value for C<$;>.
545 (Mnemonic: comma (the syntactic subscript separator) is a
546 semi-semicolon.  Yeah, I know, it's pretty lame, but C<$,> is already
547 taken for something more important.)
548
549 Consider using "real" multidimensional arrays as described
550 in L<perllol>.
551
552 =item HANDLE->format_page_number(EXPR)
553
554 =item $FORMAT_PAGE_NUMBER
555
556 =item $%
557 X<$%> X<$FORMAT_PAGE_NUMBER>
558
559 The current page number of the currently selected output channel.
560 Used with formats.
561 (Mnemonic: % is page number in B<nroff>.)
562
563 =item HANDLE->format_lines_per_page(EXPR)
564
565 =item $FORMAT_LINES_PER_PAGE
566
567 =item $=
568 X<$=> X<$FORMAT_LINES_PER_PAGE>
569
570 The current page length (printable lines) of the currently selected
571 output channel.  Default is 60.  
572 Used with formats.
573 (Mnemonic: = has horizontal lines.)
574
575 =item HANDLE->format_lines_left(EXPR)
576
577 =item $FORMAT_LINES_LEFT
578
579 =item $-
580 X<$-> X<$FORMAT_LINES_LEFT>
581
582 The number of lines left on the page of the currently selected output
583 channel.  
584 Used with formats.
585 (Mnemonic: lines_on_page - lines_printed.)
586
587 =item @LAST_MATCH_START
588
589 =item @-
590 X<@-> X<@LAST_MATCH_START>
591
592 $-[0] is the offset of the start of the last successful match.
593 C<$-[>I<n>C<]> is the offset of the start of the substring matched by
594 I<n>-th subpattern, or undef if the subpattern did not match.
595
596 Thus after a match against $_, $& coincides with C<substr $_, $-[0],
597 $+[0] - $-[0]>.  Similarly, $I<n> coincides with C<substr $_, $-[n],
598 $+[n] - $-[n]> if C<$-[n]> is defined, and $+ coincides with
599 C<substr $_, $-[$#-], $+[$#-] - $-[$#-]>.  One can use C<$#-> to find the last
600 matched subgroup in the last successful match.  Contrast with
601 C<$#+>, the number of subgroups in the regular expression.  Compare
602 with C<@+>.
603
604 This array holds the offsets of the beginnings of the last
605 successful submatches in the currently active dynamic scope.
606 C<$-[0]> is the offset into the string of the beginning of the
607 entire match.  The I<n>th element of this array holds the offset
608 of the I<n>th submatch, so C<$-[1]> is the offset where $1
609 begins, C<$-[2]> the offset where $2 begins, and so on.
610
611 After a match against some variable $var:
612
613 =over 5
614
615 =item C<$`> is the same as C<substr($var, 0, $-[0])>
616
617 =item C<$&> is the same as C<substr($var, $-[0], $+[0] - $-[0])>
618
619 =item C<$'> is the same as C<substr($var, $+[0])>
620
621 =item C<$1> is the same as C<substr($var, $-[1], $+[1] - $-[1])>  
622
623 =item C<$2> is the same as C<substr($var, $-[2], $+[2] - $-[2])>
624
625 =item C<$3> is the same as C<substr($var, $-[3], $+[3] - $-[3])>
626
627 =back
628
629 =item %-
630 X<%->
631
632 Similar to C<%+>, this variable allows access to the named capture buffers
633 in the last successful match in the currently active dynamic scope. To
634 each capture buffer name found in the regular expression, it associates a
635 reference to an array containing the list of values captured by all
636 buffers with that name (should there be several of them), in the order
637 where they appear.
638
639 Here's an example:
640
641     if ('1234' =~ /(?<A>1)(?<B>2)(?<A>3)(?<B>4)/) {
642         foreach my $bufname (sort keys %-) {
643             my $ary = $-{$bufname};
644             foreach my $idx (0..$#$ary) {
645                 print "\$-{$bufname}[$idx] : ",
646                       (defined($ary->[$idx]) ? "'$ary->[$idx]'" : "undef"),
647                       "\n";
648             }
649         }
650     }
651
652 would print out:
653
654     $-{A}[0] : '1'
655     $-{A}[1] : '3'
656     $-{B}[0] : '2'
657     $-{B}[1] : '4'
658
659 The keys of the C<%-> hash correspond to all buffer names found in
660 the regular expression.
661
662 The behaviour of C<%-> is implemented via the
663 L<Tie::Hash::NamedCapture> module.
664
665 B<Note:> C<%-> and C<%+> are tied views into a common internal hash
666 associated with the last successful regular expression. Therefore mixing
667 iterative access to them via C<each> may have unpredictable results.
668 Likewise, if the last successful match changes, then the results may be
669 surprising.
670
671 =item HANDLE->format_name(EXPR)
672
673 =item $FORMAT_NAME
674
675 =item $~
676 X<$~> X<$FORMAT_NAME>
677
678 The name of the current report format for the currently selected output
679 channel.  Default is the name of the filehandle.  (Mnemonic: brother to
680 C<$^>.)
681
682 =item HANDLE->format_top_name(EXPR)
683
684 =item $FORMAT_TOP_NAME
685
686 =item $^
687 X<$^> X<$FORMAT_TOP_NAME>
688
689 The name of the current top-of-page format for the currently selected
690 output channel.  Default is the name of the filehandle with _TOP
691 appended.  (Mnemonic: points to top of page.)
692
693 =item IO::Handle->format_line_break_characters EXPR
694
695 =item $FORMAT_LINE_BREAK_CHARACTERS
696
697 =item $:
698 X<$:> X<FORMAT_LINE_BREAK_CHARACTERS>
699
700 The current set of characters after which a string may be broken to
701 fill continuation fields (starting with ^) in a format.  Default is
702 S<" \n-">, to break on whitespace or hyphens.  (Mnemonic: a "colon" in
703 poetry is a part of a line.)
704
705 =item IO::Handle->format_formfeed EXPR
706
707 =item $FORMAT_FORMFEED
708
709 =item $^L
710 X<$^L> X<$FORMAT_FORMFEED>
711
712 What formats output as a form feed.  Default is \f.
713
714 =item $ACCUMULATOR
715
716 =item $^A
717 X<$^A> X<$ACCUMULATOR>
718
719 The current value of the write() accumulator for format() lines.  A format
720 contains formline() calls that put their result into C<$^A>.  After
721 calling its format, write() prints out the contents of C<$^A> and empties.
722 So you never really see the contents of C<$^A> unless you call
723 formline() yourself and then look at it.  See L<perlform> and
724 L<perlfunc/formline()>.
725
726 =item $CHILD_ERROR
727
728 =item $?
729 X<$?> X<$CHILD_ERROR>
730
731 The status returned by the last pipe close, backtick (C<``>) command,
732 successful call to wait() or waitpid(), or from the system()
733 operator.  This is just the 16-bit status word returned by the
734 traditional Unix wait() system call (or else is made up to look like it).  Thus, the
735 exit value of the subprocess is really (C<<< $? >> 8 >>>), and
736 C<$? & 127> gives which signal, if any, the process died from, and
737 C<$? & 128> reports whether there was a core dump.  (Mnemonic:
738 similar to B<sh> and B<ksh>.)
739
740 Additionally, if the C<h_errno> variable is supported in C, its value
741 is returned via $? if any C<gethost*()> function fails.
742
743 If you have installed a signal handler for C<SIGCHLD>, the
744 value of C<$?> will usually be wrong outside that handler.
745
746 Inside an C<END> subroutine C<$?> contains the value that is going to be
747 given to C<exit()>.  You can modify C<$?> in an C<END> subroutine to
748 change the exit status of your program.  For example:
749
750     END {
751         $? = 1 if $? == 255;  # die would make it 255
752     } 
753
754 Under VMS, the pragma C<use vmsish 'status'> makes C<$?> reflect the
755 actual VMS exit status, instead of the default emulation of POSIX
756 status; see L<perlvms/$?> for details.
757
758 Also see L<Error Indicators>.
759
760 =item ${^CHILD_ERROR_NATIVE}
761 X<$^CHILD_ERROR_NATIVE>
762
763 The native status returned by the last pipe close, backtick (C<``>)
764 command, successful call to wait() or waitpid(), or from the system()
765 operator.  On POSIX-like systems this value can be decoded with the
766 WIFEXITED, WEXITSTATUS, WIFSIGNALED, WTERMSIG, WIFSTOPPED, WSTOPSIG
767 and WIFCONTINUED functions provided by the L<POSIX> module.
768
769 Under VMS this reflects the actual VMS exit status; i.e. it is the same
770 as $? when the pragma C<use vmsish 'status'> is in effect.
771
772 =item ${^ENCODING}
773 X<$^ENCODING>
774
775 The I<object reference> to the Encode object that is used to convert
776 the source code to Unicode.  Thanks to this variable your perl script
777 does not have to be written in UTF-8.  Default is I<undef>.  The direct
778 manipulation of this variable is highly discouraged.
779
780 =item $OS_ERROR
781
782 =item $ERRNO
783
784 =item $!
785 X<$!> X<$ERRNO> X<$OS_ERROR>
786
787 If used numerically, yields the current value of the C C<errno>
788 variable, or in other words, if a system or library call fails, it
789 sets this variable.  This means that the value of C<$!> is meaningful
790 only I<immediately> after a B<failure>:
791
792     if (open(FH, $filename)) {
793         # Here $! is meaningless.
794         ...
795     } else {
796         # ONLY here is $! meaningful.
797         ...
798         # Already here $! might be meaningless.
799     }
800     # Since here we might have either success or failure,
801     # here $! is meaningless.
802
803 In the above I<meaningless> stands for anything: zero, non-zero,
804 C<undef>.  A successful system or library call does B<not> set
805 the variable to zero.
806
807 If used as a string, yields the corresponding system error string.
808 You can assign a number to C<$!> to set I<errno> if, for instance,
809 you want C<"$!"> to return the string for error I<n>, or you want
810 to set the exit value for the die() operator.  (Mnemonic: What just
811 went bang?)
812
813 Also see L<Error Indicators>.
814
815 =item %OS_ERROR
816
817 =item %ERRNO
818
819 =item %!
820 X<%!>
821
822 Each element of C<%!> has a true value only if C<$!> is set to that
823 value.  For example, C<$!{ENOENT}> is true if and only if the current
824 value of C<$!> is C<ENOENT>; that is, if the most recent error was
825 "No such file or directory" (or its moral equivalent: not all operating
826 systems give that exact error, and certainly not all languages).
827 To check if a particular key is meaningful on your system, use
828 C<exists $!{the_key}>; for a list of legal keys, use C<keys %!>.
829 See L<Errno> for more information, and also see above for the
830 validity of C<$!>.
831
832 =item $EXTENDED_OS_ERROR
833
834 =item $^E
835 X<$^E> X<$EXTENDED_OS_ERROR>
836
837 Error information specific to the current operating system.  At
838 the moment, this differs from C<$!> under only VMS, OS/2, and Win32
839 (and for MacPerl).  On all other platforms, C<$^E> is always just
840 the same as C<$!>.
841
842 Under VMS, C<$^E> provides the VMS status value from the last
843 system error.  This is more specific information about the last
844 system error than that provided by C<$!>.  This is particularly
845 important when C<$!> is set to B<EVMSERR>.
846
847 Under OS/2, C<$^E> is set to the error code of the last call to
848 OS/2 API either via CRT, or directly from perl.
849
850 Under Win32, C<$^E> always returns the last error information
851 reported by the Win32 call C<GetLastError()> which describes
852 the last error from within the Win32 API.  Most Win32-specific
853 code will report errors via C<$^E>.  ANSI C and Unix-like calls
854 set C<errno> and so most portable Perl code will report errors
855 via C<$!>. 
856
857 Caveats mentioned in the description of C<$!> generally apply to
858 C<$^E>, also.  (Mnemonic: Extra error explanation.)
859
860 Also see L<Error Indicators>.
861
862 =item $EVAL_ERROR
863
864 =item $@
865 X<$@> X<$EVAL_ERROR>
866
867 The Perl syntax error message from the last eval() operator.
868 If $@ is the null string, the last eval() parsed and executed
869 correctly (although the operations you invoked may have failed in the
870 normal fashion).  (Mnemonic: Where was the syntax error "at"?)
871
872 Warning messages are not collected in this variable.  You can,
873 however, set up a routine to process warnings by setting C<$SIG{__WARN__}>
874 as described below.
875
876 Also see L<Error Indicators>.
877
878 =item $PROCESS_ID
879
880 =item $PID
881
882 =item $$
883 X<$$> X<$PID> X<$PROCESS_ID>
884
885 The process number of the Perl running this script.  You should
886 consider this variable read-only, although it will be altered
887 across fork() calls.  (Mnemonic: same as shells.)
888
889 Note for Linux users: on Linux, the C functions C<getpid()> and
890 C<getppid()> return different values from different threads. In order to
891 be portable, this behavior is not reflected by C<$$>, whose value remains
892 consistent across threads. If you want to call the underlying C<getpid()>,
893 you may use the CPAN module C<Linux::Pid>.
894
895 =item $REAL_USER_ID
896
897 =item $UID
898
899 =item $<
900 X<< $< >> X<$UID> X<$REAL_USER_ID>
901
902 The real uid of this process.  (Mnemonic: it's the uid you came I<from>,
903 if you're running setuid.)  You can change both the real uid and
904 the effective uid at the same time by using POSIX::setuid().  Since
905 changes to $< require a system call, check $! after a change attempt to 
906 detect any possible errors.
907
908 =item $EFFECTIVE_USER_ID
909
910 =item $EUID
911
912 =item $>
913 X<< $> >> X<$EUID> X<$EFFECTIVE_USER_ID>
914
915 The effective uid of this process.  Example:
916
917     $< = $>;            # set real to effective uid
918     ($<,$>) = ($>,$<);  # swap real and effective uid
919
920 You can change both the effective uid and the real uid at the same
921 time by using POSIX::setuid().  Changes to $> require a check to $!
922 to detect any possible errors after an attempted change. 
923
924 (Mnemonic: it's the uid you went I<to>, if you're running setuid.)
925 C<< $< >> and C<< $> >> can be swapped only on machines
926 supporting setreuid().
927
928 =item $REAL_GROUP_ID
929
930 =item $GID
931
932 =item $(
933 X<$(> X<$GID> X<$REAL_GROUP_ID>
934
935 The real gid of this process.  If you are on a machine that supports
936 membership in multiple groups simultaneously, gives a space separated
937 list of groups you are in.  The first number is the one returned by
938 getgid(), and the subsequent ones by getgroups(), one of which may be
939 the same as the first number.
940
941 However, a value assigned to C<$(> must be a single number used to
942 set the real gid.  So the value given by C<$(> should I<not> be assigned
943 back to C<$(> without being forced numeric, such as by adding zero. Note
944 that this is different to the effective gid (C<$)>) which does take a
945 list.
946
947 You can change both the real gid and the effective gid at the same
948 time by using POSIX::setgid().  Changes to $( require a check to $!
949 to detect any possible errors after an attempted change.
950
951 (Mnemonic: parentheses are used to I<group> things.  The real gid is the
952 group you I<left>, if you're running setgid.)
953
954 =item $EFFECTIVE_GROUP_ID
955
956 =item $EGID
957
958 =item $)
959 X<$)> X<$EGID> X<$EFFECTIVE_GROUP_ID>
960
961 The effective gid of this process.  If you are on a machine that
962 supports membership in multiple groups simultaneously, gives a space
963 separated list of groups you are in.  The first number is the one
964 returned by getegid(), and the subsequent ones by getgroups(), one of
965 which may be the same as the first number.
966
967 Similarly, a value assigned to C<$)> must also be a space-separated
968 list of numbers.  The first number sets the effective gid, and
969 the rest (if any) are passed to setgroups().  To get the effect of an
970 empty list for setgroups(), just repeat the new effective gid; that is,
971 to force an effective gid of 5 and an effectively empty setgroups()
972 list, say C< $) = "5 5" >.
973
974 You can change both the effective gid and the real gid at the same
975 time by using POSIX::setgid() (use only a single numeric argument).
976 Changes to $) require a check to $! to detect any possible errors
977 after an attempted change.
978
979 (Mnemonic: parentheses are used to I<group> things.  The effective gid
980 is the group that's I<right> for you, if you're running setgid.)
981
982 C<< $< >>, C<< $> >>, C<$(> and C<$)> can be set only on
983 machines that support the corresponding I<set[re][ug]id()> routine.  C<$(>
984 and C<$)> can be swapped only on machines supporting setregid().
985
986 =item $PROGRAM_NAME
987
988 =item $0
989 X<$0> X<$PROGRAM_NAME>
990
991 Contains the name of the program being executed.
992
993 On some (read: not all) operating systems assigning to C<$0> modifies
994 the argument area that the C<ps> program sees.  On some platforms you
995 may have to use special C<ps> options or a different C<ps> to see the
996 changes.  Modifying the $0 is more useful as a way of indicating the
997 current program state than it is for hiding the program you're
998 running.  (Mnemonic: same as B<sh> and B<ksh>.)
999
1000 Note that there are platform specific limitations on the maximum
1001 length of C<$0>.  In the most extreme case it may be limited to the
1002 space occupied by the original C<$0>.
1003
1004 In some platforms there may be arbitrary amount of padding, for
1005 example space characters, after the modified name as shown by C<ps>.
1006 In some platforms this padding may extend all the way to the original
1007 length of the argument area, no matter what you do (this is the case
1008 for example with Linux 2.2).
1009
1010 Note for BSD users: setting C<$0> does not completely remove "perl"
1011 from the ps(1) output.  For example, setting C<$0> to C<"foobar"> may
1012 result in C<"perl: foobar (perl)"> (whether both the C<"perl: "> prefix
1013 and the " (perl)" suffix are shown depends on your exact BSD variant
1014 and version).  This is an operating system feature, Perl cannot help it.
1015
1016 In multithreaded scripts Perl coordinates the threads so that any
1017 thread may modify its copy of the C<$0> and the change becomes visible
1018 to ps(1) (assuming the operating system plays along).  Note that
1019 the view of C<$0> the other threads have will not change since they
1020 have their own copies of it.
1021
1022 =item $[
1023 X<$[>
1024
1025 The index of the first element in an array, and of the first character
1026 in a substring.  Default is 0, but you could theoretically set it
1027 to 1 to make Perl behave more like B<awk> (or Fortran) when
1028 subscripting and when evaluating the index() and substr() functions.
1029 (Mnemonic: [ begins subscripts.)
1030
1031 As of release 5 of Perl, assignment to C<$[> is treated as a compiler
1032 directive, and cannot influence the behavior of any other file.
1033 (That's why you can only assign compile-time constants to it.)
1034 Its use is highly discouraged.
1035
1036 Note that, unlike other compile-time directives (such as L<strict>),
1037 assignment to C<$[> can be seen from outer lexical scopes in the same file.
1038 However, you can use local() on it to strictly bind its value to a
1039 lexical block.
1040
1041 =item $]
1042 X<$]>
1043
1044 The version + patchlevel / 1000 of the Perl interpreter.  This variable
1045 can be used to determine whether the Perl interpreter executing a
1046 script is in the right range of versions.  (Mnemonic: Is this version
1047 of perl in the right bracket?)  Example:
1048
1049     warn "No checksumming!\n" if $] < 3.019;
1050
1051 See also the documentation of C<use VERSION> and C<require VERSION>
1052 for a convenient way to fail if the running Perl interpreter is too old.
1053
1054 The floating point representation can sometimes lead to inaccurate
1055 numeric comparisons.  See C<$^V> for a more modern representation of
1056 the Perl version that allows accurate string comparisons.
1057
1058 =item $COMPILING
1059
1060 =item $^C
1061 X<$^C> X<$COMPILING>
1062
1063 The current value of the flag associated with the B<-c> switch.
1064 Mainly of use with B<-MO=...> to allow code to alter its behavior
1065 when being compiled, such as for example to AUTOLOAD at compile
1066 time rather than normal, deferred loading.  Setting
1067 C<$^C = 1> is similar to calling C<B::minus_c>.
1068
1069 =item $DEBUGGING
1070
1071 =item $^D
1072 X<$^D> X<$DEBUGGING>
1073
1074 The current value of the debugging flags.  (Mnemonic: value of B<-D>
1075 switch.) May be read or set. Like its command-line equivalent, you can use
1076 numeric or symbolic values, eg C<$^D = 10> or C<$^D = "st">.
1077
1078 =item ${^RE_DEBUG_FLAGS}
1079
1080 The current value of the regex debugging flags. Set to 0 for no debug output
1081 even when the re 'debug' module is loaded. See L<re> for details.
1082
1083 =item ${^RE_TRIE_MAXBUF}
1084
1085 Controls how certain regex optimisations are applied and how much memory they
1086 utilize. This value by default is 65536 which corresponds to a 512kB temporary
1087 cache. Set this to a higher value to trade memory for speed when matching
1088 large alternations. Set it to a lower value if you want the optimisations to
1089 be as conservative of memory as possible but still occur, and set it to a
1090 negative value to prevent the optimisation and conserve the most memory.
1091 Under normal situations this variable should be of no interest to you.
1092
1093 =item $SYSTEM_FD_MAX
1094
1095 =item $^F
1096 X<$^F> X<$SYSTEM_FD_MAX>
1097
1098 The maximum system file descriptor, ordinarily 2.  System file
1099 descriptors are passed to exec()ed processes, while higher file
1100 descriptors are not.  Also, during an open(), system file descriptors are
1101 preserved even if the open() fails.  (Ordinary file descriptors are
1102 closed before the open() is attempted.)  The close-on-exec
1103 status of a file descriptor will be decided according to the value of
1104 C<$^F> when the corresponding file, pipe, or socket was opened, not the
1105 time of the exec().
1106
1107 =item $^H
1108
1109 WARNING: This variable is strictly for internal use only.  Its availability,
1110 behavior, and contents are subject to change without notice.
1111
1112 This variable contains compile-time hints for the Perl interpreter.  At the
1113 end of compilation of a BLOCK the value of this variable is restored to the
1114 value when the interpreter started to compile the BLOCK.
1115
1116 When perl begins to parse any block construct that provides a lexical scope
1117 (e.g., eval body, required file, subroutine body, loop body, or conditional
1118 block), the existing value of $^H is saved, but its value is left unchanged.
1119 When the compilation of the block is completed, it regains the saved value.
1120 Between the points where its value is saved and restored, code that
1121 executes within BEGIN blocks is free to change the value of $^H.
1122
1123 This behavior provides the semantic of lexical scoping, and is used in,
1124 for instance, the C<use strict> pragma.
1125
1126 The contents should be an integer; different bits of it are used for
1127 different pragmatic flags.  Here's an example:
1128
1129     sub add_100 { $^H |= 0x100 }
1130
1131     sub foo {
1132         BEGIN { add_100() }
1133         bar->baz($boon);
1134     }
1135
1136 Consider what happens during execution of the BEGIN block.  At this point
1137 the BEGIN block has already been compiled, but the body of foo() is still
1138 being compiled.  The new value of $^H will therefore be visible only while
1139 the body of foo() is being compiled.
1140
1141 Substitution of the above BEGIN block with:
1142
1143     BEGIN { require strict; strict->import('vars') }
1144
1145 demonstrates how C<use strict 'vars'> is implemented.  Here's a conditional
1146 version of the same lexical pragma:
1147
1148     BEGIN { require strict; strict->import('vars') if $condition }
1149
1150 =item %^H
1151
1152 The %^H hash provides the same scoping semantic as $^H.  This makes it
1153 useful for implementation of lexically scoped pragmas. See L<perlpragma>.
1154
1155 =item $INPLACE_EDIT
1156
1157 =item $^I
1158 X<$^I> X<$INPLACE_EDIT>
1159
1160 The current value of the inplace-edit extension.  Use C<undef> to disable
1161 inplace editing.  (Mnemonic: value of B<-i> switch.)
1162
1163 =item $^M
1164 X<$^M>
1165
1166 By default, running out of memory is an untrappable, fatal error.
1167 However, if suitably built, Perl can use the contents of C<$^M>
1168 as an emergency memory pool after die()ing.  Suppose that your Perl
1169 were compiled with C<-DPERL_EMERGENCY_SBRK> and used Perl's malloc.
1170 Then
1171
1172     $^M = 'a' x (1 << 16);
1173
1174 would allocate a 64K buffer for use in an emergency.  See the
1175 F<INSTALL> file in the Perl distribution for information on how to
1176 add custom C compilation flags when compiling perl.  To discourage casual
1177 use of this advanced feature, there is no L<English|English> long name for
1178 this variable.
1179
1180 =item $OSNAME
1181
1182 =item $^O
1183 X<$^O> X<$OSNAME>
1184
1185 The name of the operating system under which this copy of Perl was
1186 built, as determined during the configuration process.  The value
1187 is identical to C<$Config{'osname'}>.  See also L<Config> and the 
1188 B<-V> command-line switch documented in L<perlrun>.
1189
1190 In Windows platforms, $^O is not very helpful: since it is always
1191 C<MSWin32>, it doesn't tell the difference between
1192 95/98/ME/NT/2000/XP/CE/.NET.  Use Win32::GetOSName() or
1193 Win32::GetOSVersion() (see L<Win32> and L<perlport>) to distinguish
1194 between the variants.
1195
1196 =item ${^OPEN}
1197
1198 An internal variable used by PerlIO.  A string in two parts, separated
1199 by a C<\0> byte, the first part describes the input layers, the second
1200 part describes the output layers.
1201
1202 =item $PERLDB
1203
1204 =item $^P
1205 X<$^P> X<$PERLDB>
1206
1207 The internal variable for debugging support.  The meanings of the
1208 various bits are subject to change, but currently indicate:
1209
1210 =over 6
1211
1212 =item 0x01
1213
1214 Debug subroutine enter/exit.
1215
1216 =item 0x02
1217
1218 Line-by-line debugging.
1219
1220 =item 0x04
1221
1222 Switch off optimizations.
1223
1224 =item 0x08
1225
1226 Preserve more data for future interactive inspections.
1227
1228 =item 0x10
1229
1230 Keep info about source lines on which a subroutine is defined.
1231
1232 =item 0x20
1233
1234 Start with single-step on.
1235
1236 =item 0x40
1237
1238 Use subroutine address instead of name when reporting.
1239
1240 =item 0x80
1241
1242 Report C<goto &subroutine> as well.
1243
1244 =item 0x100
1245
1246 Provide informative "file" names for evals based on the place they were compiled.
1247
1248 =item 0x200
1249
1250 Provide informative names to anonymous subroutines based on the place they
1251 were compiled.
1252
1253 =item 0x400
1254
1255 Debug assertion subroutines enter/exit.
1256
1257 =back
1258
1259 Some bits may be relevant at compile-time only, some at
1260 run-time only.  This is a new mechanism and the details may change.
1261
1262 =item $LAST_REGEXP_CODE_RESULT
1263
1264 =item $^R
1265 X<$^R> X<$LAST_REGEXP_CODE_RESULT>
1266
1267 The result of evaluation of the last successful C<(?{ code })>
1268 regular expression assertion (see L<perlre>).  May be written to.
1269
1270 =item $EXCEPTIONS_BEING_CAUGHT
1271
1272 =item $^S
1273 X<$^S> X<$EXCEPTIONS_BEING_CAUGHT>
1274
1275 Current state of the interpreter.
1276
1277     $^S         State
1278     ---------   -------------------
1279     undef       Parsing module/eval
1280     true (1)    Executing an eval
1281     false (0)   Otherwise
1282
1283 The first state may happen in $SIG{__DIE__} and $SIG{__WARN__} handlers.
1284
1285 =item $BASETIME
1286
1287 =item $^T
1288 X<$^T> X<$BASETIME>
1289
1290 The time at which the program began running, in seconds since the
1291 epoch (beginning of 1970).  The values returned by the B<-M>, B<-A>,
1292 and B<-C> filetests are based on this value.
1293
1294 =item ${^TAINT}
1295
1296 Reflects if taint mode is on or off.  1 for on (the program was run with
1297 B<-T>), 0 for off, -1 when only taint warnings are enabled (i.e. with
1298 B<-t> or B<-TU>).  This variable is read-only.
1299
1300 =item ${^UNICODE}
1301
1302 Reflects certain Unicode settings of Perl.  See L<perlrun>
1303 documentation for the C<-C> switch for more information about
1304 the possible values. This variable is set during Perl startup
1305 and is thereafter read-only.
1306
1307 =item ${^UTF8CACHE}
1308
1309 This variable controls the state of the internal UTF-8 offset caching code.
1310 1 for on (the default), 0 for off, -1 to debug the caching code by checking
1311 all its results against linear scans, and panicking on any discrepancy.
1312
1313 =item ${^UTF8LOCALE}
1314
1315 This variable indicates whether an UTF-8 locale was detected by perl at
1316 startup. This information is used by perl when it's in
1317 adjust-utf8ness-to-locale mode (as when run with the C<-CL> command-line
1318 switch); see L<perlrun> for more info on this.
1319
1320 =item $PERL_VERSION
1321
1322 =item $^V
1323 X<$^V> X<$PERL_VERSION>
1324
1325 The revision, version, and subversion of the Perl interpreter, represented
1326 as a C<version> object.
1327
1328 This variable first appeared in perl 5.6.0; earlier versions of perl will
1329 see an undefined value. Before perl 5.10.0 $^V was represented as a v-string.
1330
1331 $^V can be used to determine whether the Perl interpreter executing a
1332 script is in the right range of versions.  (Mnemonic: use ^V for Version
1333 Control.)  Example:
1334
1335     warn "Hashes not randomized!\n" if !$^V or $^V lt v5.8.1
1336
1337 To convert C<$^V> into its string representation use sprintf()'s
1338 C<"%vd"> conversion:
1339
1340     printf "version is v%vd\n", $^V;  # Perl's version
1341
1342 See the documentation of C<use VERSION> and C<require VERSION>
1343 for a convenient way to fail if the running Perl interpreter is too old.
1344
1345 See also C<$]> for an older representation of the Perl version.
1346
1347 =item $WARNING
1348
1349 =item $^W
1350 X<$^W> X<$WARNING>
1351
1352 The current value of the warning switch, initially true if B<-w>
1353 was used, false otherwise, but directly modifiable.  (Mnemonic:
1354 related to the B<-w> switch.)  See also L<warnings>.
1355
1356 =item ${^WARNING_BITS}
1357
1358 The current set of warning checks enabled by the C<use warnings> pragma.
1359 See the documentation of C<warnings> for more details.
1360
1361 =item ${^WIN32_SLOPPY_STAT}
1362
1363 If this variable is set to a true value, then stat() on Windows will
1364 not try to open the file. This means that the link count cannot be
1365 determined and file attributes may be out of date if additional
1366 hardlinks to the file exist. On the other hand, not opening the file
1367 is considerably faster, especially for files on network drives.
1368
1369 This variable could be set in the F<sitecustomize.pl> file to
1370 configure the local Perl installation to use "sloppy" stat() by
1371 default.  See L<perlrun> for more information about site
1372 customization.
1373
1374 =item $EXECUTABLE_NAME
1375
1376 =item $^X
1377 X<$^X> X<$EXECUTABLE_NAME>
1378
1379 The name used to execute the current copy of Perl, from C's
1380 C<argv[0]> or (where supported) F</proc/self/exe>.
1381
1382 Depending on the host operating system, the value of $^X may be
1383 a relative or absolute pathname of the perl program file, or may
1384 be the string used to invoke perl but not the pathname of the
1385 perl program file.  Also, most operating systems permit invoking
1386 programs that are not in the PATH environment variable, so there
1387 is no guarantee that the value of $^X is in PATH.  For VMS, the
1388 value may or may not include a version number.
1389
1390 You usually can use the value of $^X to re-invoke an independent
1391 copy of the same perl that is currently running, e.g.,
1392
1393   @first_run = `$^X -le "print int rand 100 for 1..100"`;
1394
1395 But recall that not all operating systems support forking or
1396 capturing of the output of commands, so this complex statement
1397 may not be portable.
1398
1399 It is not safe to use the value of $^X as a path name of a file,
1400 as some operating systems that have a mandatory suffix on
1401 executable files do not require use of the suffix when invoking
1402 a command.  To convert the value of $^X to a path name, use the
1403 following statements:
1404
1405   # Build up a set of file names (not command names).
1406   use Config;
1407   $this_perl = $^X;
1408   if ($^O ne 'VMS')
1409      {$this_perl .= $Config{_exe}
1410           unless $this_perl =~ m/$Config{_exe}$/i;}
1411
1412 Because many operating systems permit anyone with read access to
1413 the Perl program file to make a copy of it, patch the copy, and
1414 then execute the copy, the security-conscious Perl programmer
1415 should take care to invoke the installed copy of perl, not the
1416 copy referenced by $^X.  The following statements accomplish
1417 this goal, and produce a pathname that can be invoked as a
1418 command or referenced as a file.
1419
1420   use Config;
1421   $secure_perl_path = $Config{perlpath};
1422   if ($^O ne 'VMS')
1423      {$secure_perl_path .= $Config{_exe}
1424           unless $secure_perl_path =~ m/$Config{_exe}$/i;}
1425
1426 =item ARGV
1427 X<ARGV>
1428
1429 The special filehandle that iterates over command-line filenames in
1430 C<@ARGV>. Usually written as the null filehandle in the angle operator
1431 C<< <> >>. Note that currently C<ARGV> only has its magical effect
1432 within the C<< <> >> operator; elsewhere it is just a plain filehandle
1433 corresponding to the last file opened by C<< <> >>. In particular,
1434 passing C<\*ARGV> as a parameter to a function that expects a filehandle
1435 may not cause your function to automatically read the contents of all the
1436 files in C<@ARGV>.
1437
1438 =item $ARGV
1439 X<$ARGV>
1440
1441 contains the name of the current file when reading from <>.
1442
1443 =item @ARGV
1444 X<@ARGV>
1445
1446 The array @ARGV contains the command-line arguments intended for
1447 the script.  C<$#ARGV> is generally the number of arguments minus
1448 one, because C<$ARGV[0]> is the first argument, I<not> the program's
1449 command name itself.  See C<$0> for the command name.
1450
1451 =item ARGVOUT
1452 X<ARGVOUT>
1453
1454 The special filehandle that points to the currently open output file
1455 when doing edit-in-place processing with B<-i>.  Useful when you have
1456 to do a lot of inserting and don't want to keep modifying $_.  See
1457 L<perlrun> for the B<-i> switch.
1458
1459 =item @F
1460 X<@F>
1461
1462 The array @F contains the fields of each line read in when autosplit
1463 mode is turned on.  See L<perlrun> for the B<-a> switch.  This array
1464 is package-specific, and must be declared or given a full package name
1465 if not in package main when running under C<strict 'vars'>.
1466
1467 =item @INC
1468 X<@INC>
1469
1470 The array @INC contains the list of places that the C<do EXPR>,
1471 C<require>, or C<use> constructs look for their library files.  It
1472 initially consists of the arguments to any B<-I> command-line
1473 switches, followed by the default Perl library, probably
1474 F</usr/local/lib/perl>, followed by ".", to represent the current
1475 directory.  ("." will not be appended if taint checks are enabled, either by
1476 C<-T> or by C<-t>.)  If you need to modify this at runtime, you should use
1477 the C<use lib> pragma to get the machine-dependent library properly
1478 loaded also:
1479
1480     use lib '/mypath/libdir/';
1481     use SomeMod;
1482
1483 You can also insert hooks into the file inclusion system by putting Perl
1484 code directly into @INC.  Those hooks may be subroutine references, array
1485 references or blessed objects.  See L<perlfunc/require> for details.
1486
1487 =item @ARG
1488
1489 =item @_
1490 X<@_> X<@ARG>
1491
1492 Within a subroutine the array @_ contains the parameters passed to that
1493 subroutine.  See L<perlsub>.
1494
1495 =item %INC
1496 X<%INC>
1497
1498 The hash %INC contains entries for each filename included via the
1499 C<do>, C<require>, or C<use> operators.  The key is the filename
1500 you specified (with module names converted to pathnames), and the
1501 value is the location of the file found.  The C<require>
1502 operator uses this hash to determine whether a particular file has
1503 already been included.
1504
1505 If the file was loaded via a hook (e.g. a subroutine reference, see
1506 L<perlfunc/require> for a description of these hooks), this hook is
1507 by default inserted into %INC in place of a filename.  Note, however,
1508 that the hook may have set the %INC entry by itself to provide some more
1509 specific info.
1510
1511 =item %ENV
1512
1513 =item $ENV{expr}
1514 X<%ENV>
1515
1516 The hash %ENV contains your current environment.  Setting a
1517 value in C<ENV> changes the environment for any child processes
1518 you subsequently fork() off.
1519
1520 =item %SIG
1521
1522 =item $SIG{expr}
1523 X<%SIG>
1524
1525 The hash C<%SIG> contains signal handlers for signals.  For example:
1526
1527     sub handler {       # 1st argument is signal name
1528         my($sig) = @_;
1529         print "Caught a SIG$sig--shutting down\n";
1530         close(LOG);
1531         exit(0);
1532     }
1533
1534     $SIG{'INT'}  = \&handler;
1535     $SIG{'QUIT'} = \&handler;
1536     ...
1537     $SIG{'INT'}  = 'DEFAULT';   # restore default action
1538     $SIG{'QUIT'} = 'IGNORE';    # ignore SIGQUIT
1539
1540 Using a value of C<'IGNORE'> usually has the effect of ignoring the
1541 signal, except for the C<CHLD> signal.  See L<perlipc> for more about
1542 this special case.
1543
1544 Here are some other examples:
1545
1546     $SIG{"PIPE"} = "Plumber";   # assumes main::Plumber (not recommended)
1547     $SIG{"PIPE"} = \&Plumber;   # just fine; assume current Plumber
1548     $SIG{"PIPE"} = *Plumber;    # somewhat esoteric
1549     $SIG{"PIPE"} = Plumber();   # oops, what did Plumber() return??
1550
1551 Be sure not to use a bareword as the name of a signal handler,
1552 lest you inadvertently call it. 
1553
1554 If your system has the sigaction() function then signal handlers are
1555 installed using it.  This means you get reliable signal handling.
1556
1557 The default delivery policy of signals changed in Perl 5.8.0 from 
1558 immediate (also known as "unsafe") to deferred, also known as 
1559 "safe signals".  See L<perlipc> for more information.
1560
1561 Certain internal hooks can be also set using the %SIG hash.  The
1562 routine indicated by C<$SIG{__WARN__}> is called when a warning message is
1563 about to be printed.  The warning message is passed as the first
1564 argument.  The presence of a C<__WARN__> hook causes the ordinary printing
1565 of warnings to C<STDERR> to be suppressed.  You can use this to save warnings
1566 in a variable, or turn warnings into fatal errors, like this:
1567
1568     local $SIG{__WARN__} = sub { die $_[0] };
1569     eval $proggie;
1570
1571 As the C<'IGNORE'> hook is not supported by C<__WARN__>, you can
1572 disable warnings using the empty subroutine:
1573
1574     local $SIG{__WARN__} = sub {};
1575
1576 The routine indicated by C<$SIG{__DIE__}> is called when a fatal exception
1577 is about to be thrown.  The error message is passed as the first
1578 argument.  When a C<__DIE__> hook routine returns, the exception
1579 processing continues as it would have in the absence of the hook,
1580 unless the hook routine itself exits via a C<goto>, a loop exit, or a C<die()>.
1581 The C<__DIE__> handler is explicitly disabled during the call, so that you
1582 can die from a C<__DIE__> handler.  Similarly for C<__WARN__>.
1583
1584 Due to an implementation glitch, the C<$SIG{__DIE__}> hook is called
1585 even inside an eval().  Do not use this to rewrite a pending exception
1586 in C<$@>, or as a bizarre substitute for overriding C<CORE::GLOBAL::die()>.
1587 This strange action at a distance may be fixed in a future release
1588 so that C<$SIG{__DIE__}> is only called if your program is about
1589 to exit, as was the original intent.  Any other use is deprecated.
1590
1591 C<__DIE__>/C<__WARN__> handlers are very special in one respect:
1592 they may be called to report (probable) errors found by the parser.
1593 In such a case the parser may be in inconsistent state, so any
1594 attempt to evaluate Perl code from such a handler will probably
1595 result in a segfault.  This means that warnings or errors that
1596 result from parsing Perl should be used with extreme caution, like
1597 this:
1598
1599     require Carp if defined $^S;
1600     Carp::confess("Something wrong") if defined &Carp::confess;
1601     die "Something wrong, but could not load Carp to give backtrace...
1602          To see backtrace try starting Perl with -MCarp switch";
1603
1604 Here the first line will load Carp I<unless> it is the parser who
1605 called the handler.  The second line will print backtrace and die if
1606 Carp was available.  The third line will be executed only if Carp was
1607 not available.
1608
1609 See L<perlfunc/die>, L<perlfunc/warn>, L<perlfunc/eval>, and
1610 L<warnings> for additional information.
1611
1612 =back
1613
1614 =head2 Error Indicators
1615 X<error> X<exception>
1616
1617 The variables C<$@>, C<$!>, C<$^E>, and C<$?> contain information
1618 about different types of error conditions that may appear during
1619 execution of a Perl program.  The variables are shown ordered by
1620 the "distance" between the subsystem which reported the error and
1621 the Perl process.  They correspond to errors detected by the Perl
1622 interpreter, C library, operating system, or an external program,
1623 respectively.
1624
1625 To illustrate the differences between these variables, consider the 
1626 following Perl expression, which uses a single-quoted string:
1627
1628     eval q{
1629         open my $pipe, "/cdrom/install |" or die $!;
1630         my @res = <$pipe>;
1631         close $pipe or die "bad pipe: $?, $!";
1632     };
1633
1634 After execution of this statement all 4 variables may have been set.  
1635
1636 C<$@> is set if the string to be C<eval>-ed did not compile (this
1637 may happen if C<open> or C<close> were imported with bad prototypes),
1638 or if Perl code executed during evaluation die()d .  In these cases
1639 the value of $@ is the compile error, or the argument to C<die>
1640 (which will interpolate C<$!> and C<$?>).  (See also L<Fatal>,
1641 though.)
1642
1643 When the eval() expression above is executed, open(), C<< <PIPE> >>,
1644 and C<close> are translated to calls in the C run-time library and
1645 thence to the operating system kernel.  C<$!> is set to the C library's
1646 C<errno> if one of these calls fails. 
1647
1648 Under a few operating systems, C<$^E> may contain a more verbose
1649 error indicator, such as in this case, "CDROM tray not closed."
1650 Systems that do not support extended error messages leave C<$^E>
1651 the same as C<$!>.
1652
1653 Finally, C<$?> may be set to non-0 value if the external program
1654 F</cdrom/install> fails.  The upper eight bits reflect specific
1655 error conditions encountered by the program (the program's exit()
1656 value).   The lower eight bits reflect mode of failure, like signal
1657 death and core dump information  See wait(2) for details.  In
1658 contrast to C<$!> and C<$^E>, which are set only if error condition
1659 is detected, the variable C<$?> is set on each C<wait> or pipe
1660 C<close>, overwriting the old value.  This is more like C<$@>, which
1661 on every eval() is always set on failure and cleared on success.
1662
1663 For more details, see the individual descriptions at C<$@>, C<$!>, C<$^E>,
1664 and C<$?>.
1665
1666 =head2 Technical Note on the Syntax of Variable Names
1667
1668 Variable names in Perl can have several formats.  Usually, they
1669 must begin with a letter or underscore, in which case they can be
1670 arbitrarily long (up to an internal limit of 251 characters) and
1671 may contain letters, digits, underscores, or the special sequence
1672 C<::> or C<'>.  In this case, the part before the last C<::> or
1673 C<'> is taken to be a I<package qualifier>; see L<perlmod>.
1674
1675 Perl variable names may also be a sequence of digits or a single
1676 punctuation or control character.  These names are all reserved for
1677 special uses by Perl; for example, the all-digits names are used
1678 to hold data captured by backreferences after a regular expression
1679 match.  Perl has a special syntax for the single-control-character
1680 names: It understands C<^X> (caret C<X>) to mean the control-C<X>
1681 character.  For example, the notation C<$^W> (dollar-sign caret
1682 C<W>) is the scalar variable whose name is the single character
1683 control-C<W>.  This is better than typing a literal control-C<W>
1684 into your program.
1685
1686 Finally, new in Perl 5.6, Perl variable names may be alphanumeric
1687 strings that begin with control characters (or better yet, a caret).
1688 These variables must be written in the form C<${^Foo}>; the braces
1689 are not optional.  C<${^Foo}> denotes the scalar variable whose
1690 name is a control-C<F> followed by two C<o>'s.  These variables are
1691 reserved for future special uses by Perl, except for the ones that
1692 begin with C<^_> (control-underscore or caret-underscore).  No
1693 control-character name that begins with C<^_> will acquire a special
1694 meaning in any future version of Perl; such names may therefore be
1695 used safely in programs.  C<$^_> itself, however, I<is> reserved.
1696
1697 Perl identifiers that begin with digits, control characters, or
1698 punctuation characters are exempt from the effects of the C<package>
1699 declaration and are always forced to be in package C<main>; they are
1700 also exempt from C<strict 'vars'> errors.  A few other names are also
1701 exempt in these ways:
1702
1703         ENV             STDIN
1704         INC             STDOUT
1705         ARGV            STDERR
1706         ARGVOUT         _
1707         SIG
1708
1709 In particular, the new special C<${^_XYZ}> variables are always taken
1710 to be in package C<main>, regardless of any C<package> declarations
1711 presently in scope.  
1712
1713 =head1 BUGS
1714
1715 Due to an unfortunate accident of Perl's implementation, C<use
1716 English> imposes a considerable performance penalty on all regular
1717 expression matches in a program, regardless of whether they occur
1718 in the scope of C<use English>.  For that reason, saying C<use
1719 English> in libraries is strongly discouraged.  See the
1720 Devel::SawAmpersand module documentation from CPAN
1721 ( http://www.cpan.org/modules/by-module/Devel/ )
1722 for more information. Writing C<use English '-no_match_vars';>
1723 avoids the performance penalty.
1724
1725 Having to even think about the C<$^S> variable in your exception
1726 handlers is simply wrong.  C<$SIG{__DIE__}> as currently implemented
1727 invites grievous and difficult to track down errors.  Avoid it
1728 and use an C<END{}> or CORE::GLOBAL::die override instead.