gv.c:require_tie_mod: Create namesv only when needed
[perl.git] / perly.y
1 /*    perly.y
2  *
3  *    Copyright (c) 1991-2002, 2003, 2004, 2005, 2006 Larry Wall
4  *    Copyright (c) 2007, 2008, 2009, 2010, 2011 by Larry Wall and others
5  *
6  *    You may distribute under the terms of either the GNU General Public
7  *    License or the Artistic License, as specified in the README file.
8  *
9  */
10
11 /*
12  * 'I see,' laughed Strider.  'I look foul and feel fair.  Is that it?
13  *  All that is gold does not glitter, not all those who wander are lost.'
14  *
15  *     [p.171 of _The Lord of the Rings_, I/x: "Strider"]
16  */
17
18 /*
19  * This file holds the grammar for the Perl language. If edited, you need
20  * to run regen_perly.pl, which re-creates the files perly.h, perly.tab
21  * and perly.act which are derived from this.
22  *
23  * The main job of of this grammar is to call the various newFOO()
24  * functions in op.c to build a syntax tree of OP structs.
25  * It relies on the lexer in toke.c to do the tokenizing.
26  *
27  * Note: due to the way that the cleanup code works WRT to freeing ops on
28  * the parse stack, it is dangerous to assign to the $n variables within
29  * an action.
30  */
31
32 /*  Make the parser re-entrant. */
33
34 %pure-parser
35
36 %start grammar
37
38 %union {
39     I32 ival; /* __DEFAULT__ (marker for regen_perly.pl;
40                                 must always be 1st union member) */
41     char *pval;
42     OP *opval;
43     GV *gvval;
44 }
45
46 %token <ival> GRAMPROG GRAMEXPR GRAMBLOCK GRAMBARESTMT GRAMFULLSTMT GRAMSTMTSEQ
47
48 %token <ival> '{' '}' '[' ']' '-' '+' '@' '%' '&' '=' '.'
49
50 %token <opval> BAREWORD METHOD FUNCMETH THING PMFUNC PRIVATEREF QWLIST
51 %token <opval> FUNC0OP FUNC0SUB UNIOPSUB LSTOPSUB
52 %token <opval> PLUGEXPR PLUGSTMT
53 %token <pval> LABEL
54 %token <ival> FORMAT SUB ANONSUB PACKAGE USE
55 %token <ival> WHILE UNTIL IF UNLESS ELSE ELSIF CONTINUE FOR
56 %token <ival> GIVEN WHEN DEFAULT
57 %token <ival> LOOPEX DOTDOT YADAYADA
58 %token <ival> FUNC0 FUNC1 FUNC UNIOP LSTOP
59 %token <ival> RELOP EQOP MULOP ADDOP
60 %token <ival> DOLSHARP DO HASHBRACK NOAMP
61 %token <ival> LOCAL MY REQUIRE
62 %token <ival> COLONATTR FORMLBRACK FORMRBRACK
63
64 %type <ival> grammar remember mremember
65 %type <ival>  startsub startanonsub startformsub
66
67 %type <ival> mintro
68
69 %type <opval> stmtseq fullstmt labfullstmt barestmt block mblock else
70 %type <opval> expr term subscripted scalar ary hsh arylen star amper sideff
71 %type <opval> sliceme kvslice gelem
72 %type <opval> listexpr nexpr texpr iexpr mexpr mnexpr
73 %type <opval> optlistexpr optexpr optrepl indirob listop method
74 %type <opval> formname subname proto optsubbody cont my_scalar my_var
75 %type <opval> refgen_topic formblock
76 %type <opval> subattrlist myattrlist myattrterm myterm
77 %type <opval> termbinop termunop anonymous termdo
78 %type <ival>  sigslurpsigil
79 %type <opval> sigvarname sigdefault sigscalarelem sigslurpelem
80 %type <opval> sigelem siglist siglistornull subsignature 
81 %type <opval> formstmtseq formline formarg
82
83 %nonassoc <ival> PREC_LOW
84 %nonassoc LOOPEX
85
86 %left <ival> OROP DOROP
87 %left <ival> ANDOP
88 %right <ival> NOTOP
89 %nonassoc LSTOP LSTOPSUB
90 %left <ival> ','
91 %right <ival> ASSIGNOP
92 %right <ival> '?' ':'
93 %nonassoc DOTDOT YADAYADA
94 %left <ival> OROR DORDOR
95 %left <ival> ANDAND
96 %left <ival> BITOROP
97 %left <ival> BITANDOP
98 %nonassoc EQOP
99 %nonassoc RELOP
100 %nonassoc UNIOP UNIOPSUB
101 %nonassoc REQUIRE
102 %left <ival> SHIFTOP
103 %left ADDOP
104 %left MULOP
105 %left <ival> MATCHOP
106 %right <ival> '!' '~' UMINUS REFGEN
107 %right <ival> POWOP
108 %nonassoc <ival> PREINC PREDEC POSTINC POSTDEC POSTJOIN
109 %left <ival> ARROW
110 %nonassoc <ival> ')'
111 %left <ival> '('
112 %left '[' '{'
113
114 %% /* RULES */
115
116 /* Top-level choice of what kind of thing yyparse was called to parse */
117 grammar :       GRAMPROG
118                         {
119                           parser->expect = XSTATE;
120                         }
121                 remember stmtseq
122                         {
123                           newPROG(block_end($3,$4));
124                           PL_compiling.cop_seq = 0;
125                           $$ = 0;
126                         }
127         |       GRAMEXPR
128                         {
129                           parser->expect = XTERM;
130                         }
131                 optexpr
132                         {
133                           PL_eval_root = $3;
134                           $$ = 0;
135                         }
136         |       GRAMBLOCK
137                         {
138                           parser->expect = XBLOCK;
139                         }
140                 block
141                         {
142                           PL_pad_reset_pending = TRUE;
143                           PL_eval_root = $3;
144                           $$ = 0;
145                           yyunlex();
146                           parser->yychar = YYEOF;
147                         }
148         |       GRAMBARESTMT
149                         {
150                           parser->expect = XSTATE;
151                         }
152                 barestmt
153                         {
154                           PL_pad_reset_pending = TRUE;
155                           PL_eval_root = $3;
156                           $$ = 0;
157                           yyunlex();
158                           parser->yychar = YYEOF;
159                         }
160         |       GRAMFULLSTMT
161                         {
162                           parser->expect = XSTATE;
163                         }
164                 fullstmt
165                         {
166                           PL_pad_reset_pending = TRUE;
167                           PL_eval_root = $3;
168                           $$ = 0;
169                           yyunlex();
170                           parser->yychar = YYEOF;
171                         }
172         |       GRAMSTMTSEQ
173                         {
174                           parser->expect = XSTATE;
175                         }
176                 stmtseq
177                         {
178                           PL_eval_root = $3;
179                           $$ = 0;
180                         }
181         ;
182
183 /* An ordinary block */
184 block   :       '{' remember stmtseq '}'
185                         { if (parser->copline > (line_t)$1)
186                               parser->copline = (line_t)$1;
187                           $$ = block_end($2, $3);
188                         }
189         ;
190
191 /* format body */
192 formblock:      '=' remember ';' FORMRBRACK formstmtseq ';' '.'
193                         { if (parser->copline > (line_t)$1)
194                               parser->copline = (line_t)$1;
195                           $$ = block_end($2, $5);
196                         }
197         ;
198
199 remember:       /* NULL */      /* start a full lexical scope */
200                         { $$ = block_start(TRUE);
201                           parser->parsed_sub = 0; }
202         ;
203
204 mblock  :       '{' mremember stmtseq '}'
205                         { if (parser->copline > (line_t)$1)
206                               parser->copline = (line_t)$1;
207                           $$ = block_end($2, $3);
208                         }
209         ;
210
211 mremember:      /* NULL */      /* start a partial lexical scope */
212                         { $$ = block_start(FALSE);
213                           parser->parsed_sub = 0; }
214         ;
215
216 /* A sequence of statements in the program */
217 stmtseq :       /* NULL */
218                         { $$ = (OP*)NULL; }
219         |       stmtseq fullstmt
220                         {   $$ = op_append_list(OP_LINESEQ, $1, $2);
221                             PL_pad_reset_pending = TRUE;
222                             if ($1 && $2)
223                                 PL_hints |= HINT_BLOCK_SCOPE;
224                         }
225         ;
226
227 /* A sequence of format lines */
228 formstmtseq:    /* NULL */
229                         { $$ = (OP*)NULL; }
230         |       formstmtseq formline
231                         {   $$ = op_append_list(OP_LINESEQ, $1, $2);
232                             PL_pad_reset_pending = TRUE;
233                             if ($1 && $2)
234                                 PL_hints |= HINT_BLOCK_SCOPE;
235                         }
236         ;
237
238 /* A statement in the program, including optional labels */
239 fullstmt:       barestmt
240                         {
241                           $$ = $1 ? newSTATEOP(0, NULL, $1) : NULL;
242                         }
243         |       labfullstmt
244                         { $$ = $1; }
245         ;
246
247 labfullstmt:    LABEL barestmt
248                         {
249                           $$ = newSTATEOP(SVf_UTF8 * $1[strlen($1)+1], $1, $2);
250                         }
251         |       LABEL labfullstmt
252                         {
253                           $$ = newSTATEOP(SVf_UTF8 * $1[strlen($1)+1], $1, $2);
254                         }
255         ;
256
257 /* A bare statement, lacking label and other aspects of state op */
258 barestmt:       PLUGSTMT
259                         { $$ = $1; }
260         |       FORMAT startformsub formname formblock
261                         {
262                           CV *fmtcv = PL_compcv;
263                           newFORM($2, $3, $4);
264                           $$ = (OP*)NULL;
265                           if (CvOUTSIDE(fmtcv) && !CvEVAL(CvOUTSIDE(fmtcv))) {
266                               pad_add_weakref(fmtcv);
267                           }
268                           parser->parsed_sub = 1;
269                         }
270         |       SUB subname startsub
271                         {
272                           if ($2->op_type == OP_CONST) {
273                             const char *const name =
274                                 SvPV_nolen_const(((SVOP*)$2)->op_sv);
275                             if (strEQ(name, "BEGIN") || strEQ(name, "END")
276                               || strEQ(name, "INIT") || strEQ(name, "CHECK")
277                               || strEQ(name, "UNITCHECK"))
278                               CvSPECIAL_on(PL_compcv);
279                           }
280                           else
281                           /* State subs inside anonymous subs need to be
282                              clonable themselves. */
283                           if (CvANON(CvOUTSIDE(PL_compcv))
284                            || CvCLONE(CvOUTSIDE(PL_compcv))
285                            || !PadnameIsSTATE(PadlistNAMESARRAY(CvPADLIST(
286                                                 CvOUTSIDE(PL_compcv)
287                                              ))[$2->op_targ]))
288                               CvCLONE_on(PL_compcv);
289                           parser->in_my = 0;
290                           parser->in_my_stash = NULL;
291                         }
292                 proto subattrlist optsubbody
293                         {
294                           SvREFCNT_inc_simple_void(PL_compcv);
295                           $2->op_type == OP_CONST
296                               ? newATTRSUB($3, $2, $5, $6, $7)
297                               : newMYSUB($3, $2, $5, $6, $7)
298                           ;
299                           $$ = (OP*)NULL;
300                           intro_my();
301                           parser->parsed_sub = 1;
302                         }
303         |       SUB subname startsub
304                         {
305                           if ($2->op_type == OP_CONST) {
306                             const char *const name =
307                                 SvPV_nolen_const(((SVOP*)$2)->op_sv);
308                             if (strEQ(name, "BEGIN") || strEQ(name, "END")
309                               || strEQ(name, "INIT") || strEQ(name, "CHECK")
310                               || strEQ(name, "UNITCHECK"))
311                               CvSPECIAL_on(PL_compcv);
312                           }
313                           else
314                           /* State subs inside anonymous subs need to be
315                              clonable themselves. */
316                           if (CvANON(CvOUTSIDE(PL_compcv))
317                            || CvCLONE(CvOUTSIDE(PL_compcv))
318                            || !PadnameIsSTATE(PadlistNAMESARRAY(CvPADLIST(
319                                                 CvOUTSIDE(PL_compcv)
320                                              ))[$2->op_targ]))
321                               CvCLONE_on(PL_compcv);
322                           parser->in_my = 0;
323                           parser->in_my_stash = NULL;
324                         }
325                 remember subsignature subattrlist '{' stmtseq '}'
326                         {
327                           OP *body;
328                           if (parser->copline > (line_t)$8)
329                               parser->copline = (line_t)$8;
330                           body = block_end($5,
331                                 op_append_list(OP_LINESEQ, $6, $9));
332
333                           SvREFCNT_inc_simple_void(PL_compcv);
334                           $2->op_type == OP_CONST
335                               ? newATTRSUB($3, $2, NULL, $7, body)
336                               : newMYSUB($3, $2, NULL, $7, body)
337                           ;
338                           $$ = (OP*)NULL;
339                           intro_my();
340                           parser->parsed_sub = 1;
341                         }
342         |       PACKAGE BAREWORD BAREWORD ';'
343                         {
344                           package($3);
345                           if ($2)
346                               package_version($2);
347                           $$ = (OP*)NULL;
348                         }
349         |       USE startsub
350                         { CvSPECIAL_on(PL_compcv); /* It's a BEGIN {} */ }
351                 BAREWORD BAREWORD optlistexpr ';'
352                         {
353                           SvREFCNT_inc_simple_void(PL_compcv);
354                           utilize($1, $2, $4, $5, $6);
355                           parser->parsed_sub = 1;
356                           $$ = (OP*)NULL;
357                         }
358         |       IF '(' remember mexpr ')' mblock else
359                         {
360                           $$ = block_end($3,
361                               newCONDOP(0, $4, op_scope($6), $7));
362                           parser->copline = (line_t)$1;
363                         }
364         |       UNLESS '(' remember mexpr ')' mblock else
365                         {
366                           $$ = block_end($3,
367                               newCONDOP(0, $4, $7, op_scope($6)));
368                           parser->copline = (line_t)$1;
369                         }
370         |       GIVEN '(' remember mexpr ')' mblock
371                         {
372                           $$ = block_end($3, newGIVENOP($4, op_scope($6), 0));
373                           parser->copline = (line_t)$1;
374                         }
375         |       WHEN '(' remember mexpr ')' mblock
376                         { $$ = block_end($3, newWHENOP($4, op_scope($6))); }
377         |       DEFAULT block
378                         { $$ = newWHENOP(0, op_scope($2)); }
379         |       WHILE '(' remember texpr ')' mintro mblock cont
380                         {
381                           $$ = block_end($3,
382                                   newWHILEOP(0, 1, (LOOP*)(OP*)NULL,
383                                       $4, $7, $8, $6));
384                           parser->copline = (line_t)$1;
385                         }
386         |       UNTIL '(' remember iexpr ')' mintro mblock cont
387                         {
388                           $$ = block_end($3,
389                                   newWHILEOP(0, 1, (LOOP*)(OP*)NULL,
390                                       $4, $7, $8, $6));
391                           parser->copline = (line_t)$1;
392                         }
393         |       FOR '(' remember mnexpr ';'
394                         { parser->expect = XTERM; }
395                 texpr ';'
396                         { parser->expect = XTERM; }
397                 mintro mnexpr ')'
398                 mblock
399                         {
400                           OP *initop = $4;
401                           OP *forop = newWHILEOP(0, 1, (LOOP*)(OP*)NULL,
402                                       scalar($7), $13, $11, $10);
403                           if (initop) {
404                               forop = op_prepend_elem(OP_LINESEQ, initop,
405                                   op_append_elem(OP_LINESEQ,
406                                       newOP(OP_UNSTACK, OPf_SPECIAL),
407                                       forop));
408                           }
409                           PL_hints |= HINT_BLOCK_SCOPE;
410                           $$ = block_end($3, forop);
411                           parser->copline = (line_t)$1;
412                         }
413         |       FOR MY remember my_scalar '(' mexpr ')' mblock cont
414                         {
415                           $$ = block_end($3, newFOROP(0, $4, $6, $8, $9));
416                           parser->copline = (line_t)$1;
417                         }
418         |       FOR scalar '(' remember mexpr ')' mblock cont
419                         {
420                           $$ = block_end($4, newFOROP(0,
421                                       op_lvalue($2, OP_ENTERLOOP), $5, $7, $8));
422                           parser->copline = (line_t)$1;
423                         }
424         |       FOR my_refgen remember my_var
425                         { parser->in_my = 0; $<opval>$ = my($4); }
426                 '(' mexpr ')' mblock cont
427                         {
428                           $$ = block_end(
429                                 $3,
430                                 newFOROP(0,
431                                          op_lvalue(
432                                             newUNOP(OP_REFGEN, 0,
433                                                     $<opval>5),
434                                             OP_ENTERLOOP),
435                                          $7, $9, $10)
436                           );
437                           parser->copline = (line_t)$1;
438                         }
439         |       FOR REFGEN refgen_topic '(' remember mexpr ')' mblock cont
440                         {
441                           $$ = block_end($5, newFOROP(
442                                 0, op_lvalue(newUNOP(OP_REFGEN, 0,
443                                                      $3),
444                                              OP_ENTERLOOP), $6, $8, $9));
445                           parser->copline = (line_t)$1;
446                         }
447         |       FOR '(' remember mexpr ')' mblock cont
448                         {
449                           $$ = block_end($3,
450                                   newFOROP(0, (OP*)NULL, $4, $6, $7));
451                           parser->copline = (line_t)$1;
452                         }
453         |       block cont
454                         {
455                           /* a block is a loop that happens once */
456                           $$ = newWHILEOP(0, 1, (LOOP*)(OP*)NULL,
457                                   (OP*)NULL, $1, $2, 0);
458                         }
459         |       PACKAGE BAREWORD BAREWORD '{' remember
460                         {
461                           package($3);
462                           if ($2) {
463                               package_version($2);
464                           }
465                         }
466                 stmtseq '}'
467                         {
468                           /* a block is a loop that happens once */
469                           $$ = newWHILEOP(0, 1, (LOOP*)(OP*)NULL,
470                                   (OP*)NULL, block_end($5, $7), (OP*)NULL, 0);
471                           if (parser->copline > (line_t)$4)
472                               parser->copline = (line_t)$4;
473                         }
474         |       sideff ';'
475                         {
476                           $$ = $1;
477                         }
478         |       ';'
479                         {
480                           $$ = (OP*)NULL;
481                           parser->copline = NOLINE;
482                         }
483         ;
484
485 /* Format line */
486 formline:       THING formarg
487                         { OP *list;
488                           if ($2) {
489                               OP *term = $2;
490                               list = op_append_elem(OP_LIST, $1, term);
491                           }
492                           else {
493                               list = $1;
494                           }
495                           if (parser->copline == NOLINE)
496                                parser->copline = CopLINE(PL_curcop)-1;
497                           else parser->copline--;
498                           $$ = newSTATEOP(0, NULL,
499                                           op_convert_list(OP_FORMLINE, 0, list));
500                         }
501         ;
502
503 formarg :       /* NULL */
504                         { $$ = NULL; }
505         |       FORMLBRACK stmtseq FORMRBRACK
506                         { $$ = op_unscope($2); }
507         ;
508
509 /* An expression which may have a side-effect */
510 sideff  :       error
511                         { $$ = (OP*)NULL; }
512         |       expr
513                         { $$ = $1; }
514         |       expr IF expr
515                         { $$ = newLOGOP(OP_AND, 0, $3, $1); }
516         |       expr UNLESS expr
517                         { $$ = newLOGOP(OP_OR, 0, $3, $1); }
518         |       expr WHILE expr
519                         { $$ = newLOOPOP(OPf_PARENS, 1, scalar($3), $1); }
520         |       expr UNTIL iexpr
521                         { $$ = newLOOPOP(OPf_PARENS, 1, $3, $1); }
522         |       expr FOR expr
523                         { $$ = newFOROP(0, (OP*)NULL, $3, $1, (OP*)NULL);
524                           parser->copline = (line_t)$2; }
525         |       expr WHEN expr
526                         { $$ = newWHENOP($3, op_scope($1)); }
527         ;
528
529 /* else and elsif blocks */
530 else    :       /* NULL */
531                         { $$ = (OP*)NULL; }
532         |       ELSE mblock
533                         {
534                           ($2)->op_flags |= OPf_PARENS;
535                           $$ = op_scope($2);
536                         }
537         |       ELSIF '(' mexpr ')' mblock else
538                         { parser->copline = (line_t)$1;
539                             $$ = newCONDOP(0,
540                                 newSTATEOP(OPf_SPECIAL,NULL,$3),
541                                 op_scope($5), $6);
542                           PL_hints |= HINT_BLOCK_SCOPE;
543                         }
544         ;
545
546 /* Continue blocks */
547 cont    :       /* NULL */
548                         { $$ = (OP*)NULL; }
549         |       CONTINUE block
550                         { $$ = op_scope($2); }
551         ;
552
553 /* determine whether there are any new my declarations */
554 mintro  :       /* NULL */
555                         { $$ = (PL_min_intro_pending &&
556                             PL_max_intro_pending >=  PL_min_intro_pending);
557                           intro_my(); }
558
559 /* Normal expression */
560 nexpr   :       /* NULL */
561                         { $$ = (OP*)NULL; }
562         |       sideff
563         ;
564
565 /* Boolean expression */
566 texpr   :       /* NULL means true */
567                         { YYSTYPE tmplval;
568                           (void)scan_num("1", &tmplval);
569                           $$ = tmplval.opval; }
570         |       expr
571         ;
572
573 /* Inverted boolean expression */
574 iexpr   :       expr
575                         { $$ = invert(scalar($1)); }
576         ;
577
578 /* Expression with its own lexical scope */
579 mexpr   :       expr
580                         { $$ = $1; intro_my(); }
581         ;
582
583 mnexpr  :       nexpr
584                         { $$ = $1; intro_my(); }
585         ;
586
587 formname:       BAREWORD        { $$ = $1; }
588         |       /* NULL */      { $$ = (OP*)NULL; }
589         ;
590
591 startsub:       /* NULL */      /* start a regular subroutine scope */
592                         { $$ = start_subparse(FALSE, 0);
593                             SAVEFREESV(PL_compcv); }
594
595         ;
596
597 startanonsub:   /* NULL */      /* start an anonymous subroutine scope */
598                         { $$ = start_subparse(FALSE, CVf_ANON);
599                             SAVEFREESV(PL_compcv); }
600         ;
601
602 startformsub:   /* NULL */      /* start a format subroutine scope */
603                         { $$ = start_subparse(TRUE, 0);
604                             SAVEFREESV(PL_compcv); }
605         ;
606
607 /* Name of a subroutine - must be a bareword, could be special */
608 subname :       BAREWORD
609         |       PRIVATEREF
610         ;
611
612 /* Subroutine prototype */
613 proto   :       /* NULL */
614                         { $$ = (OP*)NULL; }
615         |       THING
616         ;
617
618 /* Optional list of subroutine attributes */
619 subattrlist:    /* NULL */
620                         { $$ = (OP*)NULL; }
621         |       COLONATTR THING
622                         { $$ = $2; }
623         |       COLONATTR
624                         { $$ = (OP*)NULL; }
625         ;
626
627 /* List of attributes for a "my" variable declaration */
628 myattrlist:     COLONATTR THING
629                         { $$ = $2; }
630         |       COLONATTR
631                         { $$ = (OP*)NULL; }
632         ;
633
634
635
636 /* --------------------------------------
637  * subroutine signature parsing
638  */
639
640 /* the '' or 'foo' part of a '$' or '@foo' etc signature variable  */
641 sigvarname:   /* NULL */
642                         { $$ = (OP*)NULL; }
643         |       PRIVATEREF
644                         { $$ = $1; }
645         ;
646
647 sigslurpsigil:
648                 '@'
649                         { $$ = '@'; }
650         |       '%'
651                         { $$ = '%'; }
652
653 /* @, %, @foo, %foo */
654 sigslurpelem: sigslurpsigil sigvarname sigdefault/* def only to catch errors */ 
655                         {
656                             I32 sigil   = $1;
657                             OP *var     = $2;
658                             OP *defexpr = $3;
659
660                             if (parser->sig_slurpy)
661                                 yyerror("Multiple slurpy parameters not allowed");
662                             parser->sig_slurpy = (char)sigil;
663
664                             if (defexpr)
665                                 yyerror("A slurpy parameter may not have "
666                                         "a default value");
667
668                             $$ = var ? newSTATEOP(0, NULL, var) : (OP*)NULL;
669                         }
670         ;
671
672 /* default part of sub signature scalar element: i.e. '= default_expr' */
673 sigdefault:     /* NULL */
674                         { $$ = (OP*)NULL; }
675         |       ASSIGNOP
676                         { $$ = newOP(OP_NULL, 0); }
677         |       ASSIGNOP term
678                         { $$ = $2; }
679
680
681 /* subroutine signature scalar element: e.g. '$x', '$=', '$x = $default' */
682 sigscalarelem:
683                 '$' sigvarname sigdefault
684                         {
685                             OP *var     = $2;
686                             OP *defexpr = $3;
687
688                             if (parser->sig_slurpy)
689                                 yyerror("Slurpy parameter not last");
690
691                             parser->sig_elems++;
692
693                             if (defexpr) {
694                                 parser->sig_optelems++;
695
696                                 if (   defexpr->op_type == OP_NULL
697                                     && !(defexpr->op_flags & OPf_KIDS))
698                                 {
699                                     /* handle '$=' special case */
700                                     if (var)
701                                         yyerror("Optional parameter "
702                                                     "lacks default expression");
703                                     op_free(defexpr);
704                                 }
705                                 else { 
706                                     /* a normal '=default' expression */ 
707                                     OP *defop = (OP*)alloc_LOGOP(OP_ARGDEFELEM,
708                                                         defexpr,
709                                                         LINKLIST(defexpr));
710                                     /* re-purpose op_targ to hold @_ index */
711                                     defop->op_targ =
712                                         (PADOFFSET)(parser->sig_elems - 1);
713
714                                     if (var) {
715                                         var->op_flags |= OPf_STACKED;
716                                         (void)op_sibling_splice(var,
717                                                         NULL, 0, defop);
718                                         scalar(defop);
719                                     }
720                                     else
721                                         var = newUNOP(OP_NULL, 0, defop);
722
723                                     LINKLIST(var);
724                                     /* NB: normally the first child of a
725                                      * logop is executed before the logop,
726                                      * and it pushes a boolean result
727                                      * ready for the logop. For ARGDEFELEM,
728                                      * the op itself does the boolean
729                                      * calculation, so set the first op to
730                                      * it instead.
731                                      */
732                                     var->op_next = defop;
733                                     defexpr->op_next = var;
734                                 }
735                             }
736                             else {
737                                 if (parser->sig_optelems)
738                                     yyerror("Mandatory parameter "
739                                             "follows optional parameter");
740                             }
741
742                             $$ = var ? newSTATEOP(0, NULL, var) : (OP*)NULL;
743                         }
744         ;
745
746
747 /* subroutine signature element: e.g. '$x = $default' or '%h' */
748 sigelem:        sigscalarelem
749                         { parser->expect = XSIGVAR; $$ = $1; }
750         |       sigslurpelem
751                         { parser->expect = XSIGVAR; $$ = $1; }
752         ;
753
754 /* list of subroutine signature elements */
755 siglist:
756                 siglist ','
757                         { $$ = $1; }
758         |       siglist ',' sigelem
759                         {
760                           $$ = op_append_list(OP_LINESEQ, $1, $3);
761                         }
762         |       sigelem  %prec PREC_LOW
763                         { $$ = $1; }
764         ;
765
766 /* () or (....) */
767 siglistornull:          /* NULL */
768                         { $$ = (OP*)NULL; }
769         |       siglist
770                         { $$ = $1; }
771
772 /* Subroutine signature */
773 subsignature:   '('
774                         {
775                             ENTER;
776                             SAVEIV(parser->sig_elems);
777                             SAVEIV(parser->sig_optelems);
778                             SAVEI8(parser->sig_slurpy);
779                             parser->sig_elems    = 0;
780                             parser->sig_optelems = 0;
781                             parser->sig_slurpy   = 0;
782                             parser->expect = XSIGVAR;
783                         }
784                 siglistornull
785                 ')'
786                         {
787                             OP            *sigops = $3;
788                             UNOP_AUX_item *aux;
789                             OP            *check;
790
791                             assert(FEATURE_SIGNATURES_IS_ENABLED);
792
793                             /* We shouldn't get here otherwise */
794                             Perl_ck_warner_d(aTHX_
795                                 packWARN(WARN_EXPERIMENTAL__SIGNATURES),
796                                 "The signatures feature is experimental");
797
798                             aux = (UNOP_AUX_item*)PerlMemShared_malloc(
799                                 sizeof(UNOP_AUX_item) * 3);
800                             aux[0].iv = parser->sig_elems;
801                             aux[1].iv = parser->sig_optelems;
802                             aux[2].iv = parser->sig_slurpy;
803                             check = newUNOP_AUX(OP_ARGCHECK, 0, NULL, aux);
804                             sigops = op_prepend_elem(OP_LINESEQ, check, sigops);
805                             sigops = op_prepend_elem(OP_LINESEQ,
806                                                 newSTATEOP(0, NULL, NULL),
807                                                 sigops);
808                             /* a nextstate at the end handles context
809                              * correctly for an empty sub body */
810                             $$ = op_append_elem(OP_LINESEQ,
811                                                 sigops,
812                                                 newSTATEOP(0, NULL, NULL));
813
814                             parser->expect = XATTRBLOCK;
815                             LEAVE;
816                         }
817         ;
818
819
820
821 /* Optional subroutine body, for named subroutine declaration */
822 optsubbody:     block
823         |       ';'     { $$ = (OP*)NULL; }
824         ;
825
826 /* Ordinary expressions; logical combinations */
827 expr    :       expr ANDOP expr
828                         { $$ = newLOGOP(OP_AND, 0, $1, $3); }
829         |       expr OROP expr
830                         { $$ = newLOGOP($2, 0, $1, $3); }
831         |       expr DOROP expr
832                         { $$ = newLOGOP(OP_DOR, 0, $1, $3); }
833         |       listexpr %prec PREC_LOW
834         ;
835
836 /* Expressions are a list of terms joined by commas */
837 listexpr:       listexpr ','
838                         { $$ = $1; }
839         |       listexpr ',' term
840                         {
841                           OP* term = $3;
842                           $$ = op_append_elem(OP_LIST, $1, term);
843                         }
844         |       term %prec PREC_LOW
845         ;
846
847 /* List operators */
848 listop  :       LSTOP indirob listexpr /* map {...} @args or print $fh @args */
849                         { $$ = op_convert_list($1, OPf_STACKED,
850                                 op_prepend_elem(OP_LIST, newGVREF($1,$2), $3) );
851                         }
852         |       FUNC '(' indirob expr ')'      /* print ($fh @args */
853                         { $$ = op_convert_list($1, OPf_STACKED,
854                                 op_prepend_elem(OP_LIST, newGVREF($1,$3), $4) );
855                         }
856         |       term ARROW method '(' optexpr ')' /* $foo->bar(list) */
857                         { $$ = op_convert_list(OP_ENTERSUB, OPf_STACKED,
858                                 op_append_elem(OP_LIST,
859                                     op_prepend_elem(OP_LIST, scalar($1), $5),
860                                     newMETHOP(OP_METHOD, 0, $3)));
861                         }
862         |       term ARROW method                     /* $foo->bar */
863                         { $$ = op_convert_list(OP_ENTERSUB, OPf_STACKED,
864                                 op_append_elem(OP_LIST, scalar($1),
865                                     newMETHOP(OP_METHOD, 0, $3)));
866                         }
867         |       METHOD indirob optlistexpr           /* new Class @args */
868                         { $$ = op_convert_list(OP_ENTERSUB, OPf_STACKED,
869                                 op_append_elem(OP_LIST,
870                                     op_prepend_elem(OP_LIST, $2, $3),
871                                     newMETHOP(OP_METHOD, 0, $1)));
872                         }
873         |       FUNCMETH indirob '(' optexpr ')'    /* method $object (@args) */
874                         { $$ = op_convert_list(OP_ENTERSUB, OPf_STACKED,
875                                 op_append_elem(OP_LIST,
876                                     op_prepend_elem(OP_LIST, $2, $4),
877                                     newMETHOP(OP_METHOD, 0, $1)));
878                         }
879         |       LSTOP optlistexpr                    /* print @args */
880                         { $$ = op_convert_list($1, 0, $2); }
881         |       FUNC '(' optexpr ')'                 /* print (@args) */
882                         { $$ = op_convert_list($1, 0, $3); }
883         |       LSTOPSUB startanonsub block /* sub f(&@);   f { foo } ... */
884                         { SvREFCNT_inc_simple_void(PL_compcv);
885                           $<opval>$ = newANONATTRSUB($2, 0, (OP*)NULL, $3); }
886                     optlistexpr         %prec LSTOP  /* ... @bar */
887                         { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
888                                  op_append_elem(OP_LIST,
889                                    op_prepend_elem(OP_LIST, $<opval>4, $5), $1));
890                         }
891         ;
892
893 /* Names of methods. May use $object->$methodname */
894 method  :       METHOD
895         |       scalar
896         ;
897
898 /* Some kind of subscripted expression */
899 subscripted:    gelem '{' expr ';' '}'        /* *main::{something} */
900                         /* In this and all the hash accessors, ';' is
901                          * provided by the tokeniser */
902                         { $$ = newBINOP(OP_GELEM, 0, $1, scalar($3)); }
903         |       scalar '[' expr ']'          /* $array[$element] */
904                         { $$ = newBINOP(OP_AELEM, 0, oopsAV($1), scalar($3));
905                         }
906         |       term ARROW '[' expr ']'      /* somearef->[$element] */
907                         { $$ = newBINOP(OP_AELEM, 0,
908                                         ref(newAVREF($1),OP_RV2AV),
909                                         scalar($4));
910                         }
911         |       subscripted '[' expr ']'    /* $foo->[$bar]->[$baz] */
912                         { $$ = newBINOP(OP_AELEM, 0,
913                                         ref(newAVREF($1),OP_RV2AV),
914                                         scalar($3));
915                         }
916         |       scalar '{' expr ';' '}'    /* $foo{bar();} */
917                         { $$ = newBINOP(OP_HELEM, 0, oopsHV($1), jmaybe($3));
918                         }
919         |       term ARROW '{' expr ';' '}' /* somehref->{bar();} */
920                         { $$ = newBINOP(OP_HELEM, 0,
921                                         ref(newHVREF($1),OP_RV2HV),
922                                         jmaybe($4)); }
923         |       subscripted '{' expr ';' '}' /* $foo->[bar]->{baz;} */
924                         { $$ = newBINOP(OP_HELEM, 0,
925                                         ref(newHVREF($1),OP_RV2HV),
926                                         jmaybe($3)); }
927         |       term ARROW '(' ')'          /* $subref->() */
928                         { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
929                                    newCVREF(0, scalar($1))); }
930         |       term ARROW '(' expr ')'     /* $subref->(@args) */
931                         { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
932                                    op_append_elem(OP_LIST, $4,
933                                        newCVREF(0, scalar($1)))); }
934
935         |       subscripted '(' expr ')'   /* $foo->{bar}->(@args) */
936                         { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
937                                    op_append_elem(OP_LIST, $3,
938                                                newCVREF(0, scalar($1)))); }
939         |       subscripted '(' ')'        /* $foo->{bar}->() */
940                         { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
941                                    newCVREF(0, scalar($1))); }
942         |       '(' expr ')' '[' expr ']'            /* list slice */
943                         { $$ = newSLICEOP(0, $5, $2); }
944         |       QWLIST '[' expr ']'            /* list literal slice */
945                         { $$ = newSLICEOP(0, $3, $1); }
946         |       '(' ')' '[' expr ']'                 /* empty list slice! */
947                         { $$ = newSLICEOP(0, $4, (OP*)NULL); }
948     ;
949
950 /* Binary operators between terms */
951 termbinop:      term ASSIGNOP term                     /* $x = $y */
952                         { $$ = newASSIGNOP(OPf_STACKED, $1, $2, $3); }
953         |       term POWOP term                        /* $x ** $y */
954                         { $$ = newBINOP($2, 0, scalar($1), scalar($3)); }
955         |       term MULOP term                        /* $x * $y, $x x $y */
956                         {   if ($2 != OP_REPEAT)
957                                 scalar($1);
958                             $$ = newBINOP($2, 0, $1, scalar($3));
959                         }
960         |       term ADDOP term                        /* $x + $y */
961                         { $$ = newBINOP($2, 0, scalar($1), scalar($3)); }
962         |       term SHIFTOP term                      /* $x >> $y, $x << $y */
963                         { $$ = newBINOP($2, 0, scalar($1), scalar($3)); }
964         |       term RELOP term                        /* $x > $y, etc. */
965                         { $$ = newBINOP($2, 0, scalar($1), scalar($3)); }
966         |       term EQOP term                         /* $x == $y, $x eq $y */
967                         { $$ = newBINOP($2, 0, scalar($1), scalar($3)); }
968         |       term BITANDOP term                     /* $x & $y */
969                         { $$ = newBINOP($2, 0, scalar($1), scalar($3)); }
970         |       term BITOROP term                      /* $x | $y */
971                         { $$ = newBINOP($2, 0, scalar($1), scalar($3)); }
972         |       term DOTDOT term                       /* $x..$y, $x...$y */
973                         { $$ = newRANGE($2, scalar($1), scalar($3)); }
974         |       term ANDAND term                       /* $x && $y */
975                         { $$ = newLOGOP(OP_AND, 0, $1, $3); }
976         |       term OROR term                         /* $x || $y */
977                         { $$ = newLOGOP(OP_OR, 0, $1, $3); }
978         |       term DORDOR term                       /* $x // $y */
979                         { $$ = newLOGOP(OP_DOR, 0, $1, $3); }
980         |       term MATCHOP term                      /* $x =~ /$y/ */
981                         { $$ = bind_match($2, $1, $3); }
982     ;
983
984 /* Unary operators and terms */
985 termunop : '-' term %prec UMINUS                       /* -$x */
986                         { $$ = newUNOP(OP_NEGATE, 0, scalar($2)); }
987         |       '+' term %prec UMINUS                  /* +$x */
988                         { $$ = $2; }
989
990         |       '!' term                               /* !$x */
991                         { $$ = newUNOP(OP_NOT, 0, scalar($2)); }
992         |       '~' term                               /* ~$x */
993                         { $$ = newUNOP($1, 0, scalar($2)); }
994         |       term POSTINC                           /* $x++ */
995                         { $$ = newUNOP(OP_POSTINC, 0,
996                                         op_lvalue(scalar($1), OP_POSTINC)); }
997         |       term POSTDEC                           /* $x-- */
998                         { $$ = newUNOP(OP_POSTDEC, 0,
999                                         op_lvalue(scalar($1), OP_POSTDEC));}
1000         |       term POSTJOIN    /* implicit join after interpolated ->@ */
1001                         { $$ = op_convert_list(OP_JOIN, 0,
1002                                        op_append_elem(
1003                                         OP_LIST,
1004                                         newSVREF(scalar(
1005                                             newSVOP(OP_CONST,0,
1006                                                     newSVpvs("\""))
1007                                         )),
1008                                         $1
1009                                        ));
1010                         }
1011         |       PREINC term                            /* ++$x */
1012                         { $$ = newUNOP(OP_PREINC, 0,
1013                                         op_lvalue(scalar($2), OP_PREINC)); }
1014         |       PREDEC term                            /* --$x */
1015                         { $$ = newUNOP(OP_PREDEC, 0,
1016                                         op_lvalue(scalar($2), OP_PREDEC)); }
1017
1018     ;
1019
1020 /* Constructors for anonymous data */
1021 anonymous:      '[' expr ']'
1022                         { $$ = newANONLIST($2); }
1023         |       '[' ']'
1024                         { $$ = newANONLIST((OP*)NULL);}
1025         |       HASHBRACK expr ';' '}'  %prec '(' /* { foo => "Bar" } */
1026                         { $$ = newANONHASH($2); }
1027         |       HASHBRACK ';' '}'       %prec '(' /* { } (';' by tokener) */
1028                         { $$ = newANONHASH((OP*)NULL); }
1029         |       ANONSUB startanonsub proto subattrlist block            %prec '('
1030                         { SvREFCNT_inc_simple_void(PL_compcv);
1031                           $$ = newANONATTRSUB($2, $3, $4, $5); }
1032         |       ANONSUB startanonsub remember subsignature subattrlist '{' stmtseq '}'  %prec '('
1033                         {
1034                           OP *body;
1035                           if (parser->copline > (line_t)$6)
1036                               parser->copline = (line_t)$6;
1037                           body = block_end($3,
1038                                 op_append_list(OP_LINESEQ, $4, $7));
1039                           SvREFCNT_inc_simple_void(PL_compcv);
1040                           $$ = newANONATTRSUB($2, NULL, $5, body);
1041                         }
1042
1043     ;
1044
1045 /* Things called with "do" */
1046 termdo  :       DO term %prec UNIOP                     /* do $filename */
1047                         { $$ = dofile($2, $1);}
1048         |       DO block        %prec '('               /* do { code */
1049                         { $$ = newUNOP(OP_NULL, OPf_SPECIAL, op_scope($2));}
1050         ;
1051
1052 term    :       termbinop
1053         |       termunop
1054         |       anonymous
1055         |       termdo
1056         |       term '?' term ':' term
1057                         { $$ = newCONDOP(0, $1, $3, $5); }
1058         |       REFGEN term                          /* \$x, \@y, \%z */
1059                         { $$ = newUNOP(OP_REFGEN, 0, $2); }
1060         |       MY REFGEN term
1061                         { $$ = newUNOP(OP_REFGEN, 0, localize($3,1)); }
1062         |       myattrterm      %prec UNIOP
1063                         { $$ = $1; }
1064         |       LOCAL term      %prec UNIOP
1065                         { $$ = localize($2,0); }
1066         |       '(' expr ')'
1067                         { $$ = sawparens($2); }
1068         |       QWLIST
1069                         { $$ = $1; }
1070         |       '(' ')'
1071                         { $$ = sawparens(newNULLLIST()); }
1072         |       scalar  %prec '('
1073                         { $$ = $1; }
1074         |       star    %prec '('
1075                         { $$ = $1; }
1076         |       hsh     %prec '('
1077                         { $$ = $1; }
1078         |       ary     %prec '('
1079                         { $$ = $1; }
1080         |       arylen  %prec '('                    /* $#x, $#{ something } */
1081                         { $$ = newUNOP(OP_AV2ARYLEN, 0, ref($1, OP_AV2ARYLEN));}
1082         |       subscripted
1083                         { $$ = $1; }
1084         |       sliceme '[' expr ']'                     /* array slice */
1085                         { $$ = op_prepend_elem(OP_ASLICE,
1086                                 newOP(OP_PUSHMARK, 0),
1087                                     newLISTOP(OP_ASLICE, 0,
1088                                         list($3),
1089                                         ref($1, OP_ASLICE)));
1090                           if ($$ && $1)
1091                               $$->op_private |=
1092                                   $1->op_private & OPpSLICEWARNING;
1093                         }
1094         |       kvslice '[' expr ']'                 /* array key/value slice */
1095                         { $$ = op_prepend_elem(OP_KVASLICE,
1096                                 newOP(OP_PUSHMARK, 0),
1097                                     newLISTOP(OP_KVASLICE, 0,
1098                                         list($3),
1099                                         ref(oopsAV($1), OP_KVASLICE)));
1100                           if ($$ && $1)
1101                               $$->op_private |=
1102                                   $1->op_private & OPpSLICEWARNING;
1103                         }
1104         |       sliceme '{' expr ';' '}'                 /* @hash{@keys} */
1105                         { $$ = op_prepend_elem(OP_HSLICE,
1106                                 newOP(OP_PUSHMARK, 0),
1107                                     newLISTOP(OP_HSLICE, 0,
1108                                         list($3),
1109                                         ref(oopsHV($1), OP_HSLICE)));
1110                           if ($$ && $1)
1111                               $$->op_private |=
1112                                   $1->op_private & OPpSLICEWARNING;
1113                         }
1114         |       kvslice '{' expr ';' '}'                 /* %hash{@keys} */
1115                         { $$ = op_prepend_elem(OP_KVHSLICE,
1116                                 newOP(OP_PUSHMARK, 0),
1117                                     newLISTOP(OP_KVHSLICE, 0,
1118                                         list($3),
1119                                         ref($1, OP_KVHSLICE)));
1120                           if ($$ && $1)
1121                               $$->op_private |=
1122                                   $1->op_private & OPpSLICEWARNING;
1123                         }
1124         |       THING   %prec '('
1125                         { $$ = $1; }
1126         |       amper                                /* &foo; */
1127                         { $$ = newUNOP(OP_ENTERSUB, 0, scalar($1)); }
1128         |       amper '(' ')'                 /* &foo() or foo() */
1129                         { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED, scalar($1));
1130                         }
1131         |       amper '(' expr ')'          /* &foo(@args) or foo(@args) */
1132                         {
1133                           $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
1134                                 op_append_elem(OP_LIST, $3, scalar($1)));
1135                         }
1136         |       NOAMP subname optlistexpr       /* foo @args (no parens) */
1137                         { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
1138                             op_append_elem(OP_LIST, $3, scalar($2)));
1139                         }
1140         |       term ARROW '$' '*'
1141                         { $$ = newSVREF($1); }
1142         |       term ARROW '@' '*'
1143                         { $$ = newAVREF($1); }
1144         |       term ARROW '%' '*'
1145                         { $$ = newHVREF($1); }
1146         |       term ARROW '&' '*'
1147                         { $$ = newUNOP(OP_ENTERSUB, 0,
1148                                        scalar(newCVREF($3,$1))); }
1149         |       term ARROW '*' '*'      %prec '('
1150                         { $$ = newGVREF(0,$1); }
1151         |       LOOPEX  /* loop exiting command (goto, last, dump, etc) */
1152                         { $$ = newOP($1, OPf_SPECIAL);
1153                             PL_hints |= HINT_BLOCK_SCOPE; }
1154         |       LOOPEX term
1155                         { $$ = newLOOPEX($1,$2); }
1156         |       NOTOP listexpr                       /* not $foo */
1157                         { $$ = newUNOP(OP_NOT, 0, scalar($2)); }
1158         |       UNIOP                                /* Unary op, $_ implied */
1159                         { $$ = newOP($1, 0); }
1160         |       UNIOP block                          /* eval { foo }* */
1161                         { $$ = newUNOP($1, 0, $2); }
1162         |       UNIOP term                           /* Unary op */
1163                         { $$ = newUNOP($1, 0, $2); }
1164         |       REQUIRE                              /* require, $_ implied */
1165                         { $$ = newOP(OP_REQUIRE, $1 ? OPf_SPECIAL : 0); }
1166         |       REQUIRE term                         /* require Foo */
1167                         { $$ = newUNOP(OP_REQUIRE, $1 ? OPf_SPECIAL : 0, $2); }
1168         |       UNIOPSUB
1169                         { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED, scalar($1)); }
1170         |       UNIOPSUB term                        /* Sub treated as unop */
1171                         { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
1172                             op_append_elem(OP_LIST, $2, scalar($1))); }
1173         |       FUNC0                                /* Nullary operator */
1174                         { $$ = newOP($1, 0); }
1175         |       FUNC0 '(' ')'
1176                         { $$ = newOP($1, 0);}
1177         |       FUNC0OP       /* Same as above, but op created in toke.c */
1178                         { $$ = $1; }
1179         |       FUNC0OP '(' ')'
1180                         { $$ = $1; }
1181         |       FUNC0SUB                             /* Sub treated as nullop */
1182                         { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED, scalar($1)); }
1183         |       FUNC1 '(' ')'                        /* not () */
1184                         { $$ = ($1 == OP_NOT)
1185                           ? newUNOP($1, 0, newSVOP(OP_CONST, 0, newSViv(0)))
1186                           : newOP($1, OPf_SPECIAL); }
1187         |       FUNC1 '(' expr ')'                   /* not($foo) */
1188                         { $$ = newUNOP($1, 0, $3); }
1189         |       PMFUNC /* m//, s///, qr//, tr/// */
1190                         {
1191                             if (   $1->op_type != OP_TRANS
1192                                 && $1->op_type != OP_TRANSR
1193                                 && (((PMOP*)$1)->op_pmflags & PMf_HAS_CV))
1194                             {
1195                                 $<ival>$ = start_subparse(FALSE, CVf_ANON);
1196                                 SAVEFREESV(PL_compcv);
1197                             } else
1198                                 $<ival>$ = 0;
1199                         }
1200                     '(' listexpr optrepl ')'
1201                         { $$ = pmruntime($1, $4, $5, 1, $<ival>2); }
1202         |       BAREWORD
1203         |       listop
1204         |       YADAYADA
1205                         {
1206                           $$ = newLISTOP(OP_DIE, 0, newOP(OP_PUSHMARK, 0),
1207                                 newSVOP(OP_CONST, 0, newSVpvs("Unimplemented")));
1208                         }
1209         |       PLUGEXPR
1210         ;
1211
1212 /* "my" declarations, with optional attributes */
1213 myattrterm:     MY myterm myattrlist
1214                         { $$ = my_attrs($2,$3); }
1215         |       MY myterm
1216                         { $$ = localize($2,1); }
1217         |       MY REFGEN myterm myattrlist
1218                         { $$ = newUNOP(OP_REFGEN, 0, my_attrs($3,$4)); }
1219         ;
1220
1221 /* Things that can be "my"'d */
1222 myterm  :       '(' expr ')'
1223                         { $$ = sawparens($2); }
1224         |       '(' ')'
1225                         { $$ = sawparens(newNULLLIST()); }
1226
1227         |       scalar  %prec '('
1228                         { $$ = $1; }
1229         |       hsh     %prec '('
1230                         { $$ = $1; }
1231         |       ary     %prec '('
1232                         { $$ = $1; }
1233         ;
1234
1235 /* Basic list expressions */
1236 optlistexpr:    /* NULL */ %prec PREC_LOW
1237                         { $$ = (OP*)NULL; }
1238         |       listexpr    %prec PREC_LOW
1239                         { $$ = $1; }
1240         ;
1241
1242 optexpr:        /* NULL */
1243                         { $$ = (OP*)NULL; }
1244         |       expr
1245                         { $$ = $1; }
1246         ;
1247
1248 optrepl:        /* NULL */
1249                         { $$ = (OP*)NULL; }
1250         |       '/' expr
1251                         { $$ = $2; }
1252         ;
1253
1254 /* A little bit of trickery to make "for my $foo (@bar)" actually be
1255    lexical */
1256 my_scalar:      scalar
1257                         { parser->in_my = 0; $$ = my($1); }
1258         ;
1259
1260 my_var  :       scalar
1261         |       ary
1262         |       hsh
1263         ;
1264
1265 refgen_topic:   my_var
1266         |       amper
1267         ;
1268
1269 my_refgen:      MY REFGEN
1270         |       REFGEN MY
1271         ;
1272
1273 amper   :       '&' indirob
1274                         { $$ = newCVREF($1,$2); }
1275         ;
1276
1277 scalar  :       '$' indirob
1278                         { $$ = newSVREF($2); }
1279         ;
1280
1281 ary     :       '@' indirob
1282                         { $$ = newAVREF($2);
1283                           if ($$) $$->op_private |= $1;
1284                         }
1285         ;
1286
1287 hsh     :       '%' indirob
1288                         { $$ = newHVREF($2);
1289                           if ($$) $$->op_private |= $1;
1290                         }
1291         ;
1292
1293 arylen  :       DOLSHARP indirob
1294                         { $$ = newAVREF($2); }
1295         |       term ARROW DOLSHARP '*'
1296                         { $$ = newAVREF($1); }
1297         ;
1298
1299 star    :       '*' indirob
1300                         { $$ = newGVREF(0,$2); }
1301         ;
1302
1303 sliceme :       ary
1304         |       term ARROW '@'
1305                         { $$ = newAVREF($1); }
1306         ;
1307
1308 kvslice :       hsh
1309         |       term ARROW '%'
1310                         { $$ = newHVREF($1); }
1311         ;
1312
1313 gelem   :       star
1314         |       term ARROW '*'
1315                         { $$ = newGVREF(0,$1); }
1316         ;
1317
1318 /* Indirect objects */
1319 indirob :       BAREWORD
1320                         { $$ = scalar($1); }
1321         |       scalar %prec PREC_LOW
1322                         { $$ = scalar($1); }
1323         |       block
1324                         { $$ = op_scope($1); }
1325
1326         |       PRIVATEREF
1327                         { $$ = $1; }
1328         ;