Hash::Util tests should check if Hash::Util has been built, not
[perl.git] / pod / perlop.pod
1 =head1 NAME
2 X<operator>
3
4 perlop - Perl operators and precedence
5
6 =head1 DESCRIPTION
7
8 =head2 Operator Precedence and Associativity 
9 X<operator, precedence> X<precedence> X<associativity>
10
11 Operator precedence and associativity work in Perl more or less like
12 they do in mathematics.
13
14 I<Operator precedence> means some operators are evaluated before
15 others.  For example, in C<2 + 4 * 5>, the multiplication has higher
16 precedence so C<4 * 5> is evaluated first yielding C<2 + 20 ==
17 22> and not C<6 * 5 == 30>.
18
19 I<Operator associativity> defines what happens if a sequence of the
20 same operators is used one after another: whether the evaluator will
21 evaluate the left operations first or the right.  For example, in C<8
22 - 4 - 2>, subtraction is left associative so Perl evaluates the
23 expression left to right.  C<8 - 4> is evaluated first making the
24 expression C<4 - 2 == 2> and not C<8 - 2 == 6>.
25
26 Perl operators have the following associativity and precedence,
27 listed from highest precedence to lowest.  Operators borrowed from
28 C keep the same precedence relationship with each other, even where
29 C's precedence is slightly screwy.  (This makes learning Perl easier
30 for C folks.)  With very few exceptions, these all operate on scalar
31 values only, not array values.
32
33     left        terms and list operators (leftward)
34     left        ->
35     nonassoc    ++ --
36     right       **
37     right       ! ~ \ and unary + and -
38     left        =~ !~
39     left        * / % x
40     left        + - .
41     left        << >>
42     nonassoc    named unary operators
43     nonassoc    < > <= >= lt gt le ge
44     nonassoc    == != <=> eq ne cmp ~~
45     left        &
46     left        | ^
47     left        &&
48     left        || //
49     nonassoc    ..  ...
50     right       ?:
51     right       = += -= *= etc.
52     left        , =>
53     nonassoc    list operators (rightward)
54     right       not
55     left        and
56     left        or xor err
57
58 In the following sections, these operators are covered in precedence order.
59
60 Many operators can be overloaded for objects.  See L<overload>.
61
62 =head2 Terms and List Operators (Leftward)
63 X<list operator> X<operator, list> X<term>
64
65 A TERM has the highest precedence in Perl.  They include variables,
66 quote and quote-like operators, any expression in parentheses,
67 and any function whose arguments are parenthesized.  Actually, there
68 aren't really functions in this sense, just list operators and unary
69 operators behaving as functions because you put parentheses around
70 the arguments.  These are all documented in L<perlfunc>.
71
72 If any list operator (print(), etc.) or any unary operator (chdir(), etc.)
73 is followed by a left parenthesis as the next token, the operator and
74 arguments within parentheses are taken to be of highest precedence,
75 just like a normal function call.
76
77 In the absence of parentheses, the precedence of list operators such as
78 C<print>, C<sort>, or C<chmod> is either very high or very low depending on
79 whether you are looking at the left side or the right side of the operator.
80 For example, in
81
82     @ary = (1, 3, sort 4, 2);
83     print @ary;         # prints 1324
84
85 the commas on the right of the sort are evaluated before the sort,
86 but the commas on the left are evaluated after.  In other words,
87 list operators tend to gobble up all arguments that follow, and
88 then act like a simple TERM with regard to the preceding expression.
89 Be careful with parentheses:
90
91     # These evaluate exit before doing the print:
92     print($foo, exit);  # Obviously not what you want.
93     print $foo, exit;   # Nor is this.
94
95     # These do the print before evaluating exit:
96     (print $foo), exit; # This is what you want.
97     print($foo), exit;  # Or this.
98     print ($foo), exit; # Or even this.
99
100 Also note that
101
102     print ($foo & 255) + 1, "\n";
103
104 probably doesn't do what you expect at first glance.  The parentheses
105 enclose the argument list for C<print> which is evaluated (printing
106 the result of C<$foo & 255>).  Then one is added to the return value
107 of C<print> (usually 1).  The result is something like this:
108
109     1 + 1, "\n";    # Obviously not what you meant.
110
111 To do what you meant properly, you must write:
112
113     print(($foo & 255) + 1, "\n");
114
115 See L<Named Unary Operators> for more discussion of this.
116
117 Also parsed as terms are the C<do {}> and C<eval {}> constructs, as
118 well as subroutine and method calls, and the anonymous
119 constructors C<[]> and C<{}>.
120
121 See also L<Quote and Quote-like Operators> toward the end of this section,
122 as well as L<"I/O Operators">.
123
124 =head2 The Arrow Operator
125 X<arrow> X<dereference> X<< -> >>
126
127 "C<< -> >>" is an infix dereference operator, just as it is in C
128 and C++.  If the right side is either a C<[...]>, C<{...}>, or a
129 C<(...)> subscript, then the left side must be either a hard or
130 symbolic reference to an array, a hash, or a subroutine respectively.
131 (Or technically speaking, a location capable of holding a hard
132 reference, if it's an array or hash reference being used for
133 assignment.)  See L<perlreftut> and L<perlref>.
134
135 Otherwise, the right side is a method name or a simple scalar
136 variable containing either the method name or a subroutine reference,
137 and the left side must be either an object (a blessed reference)
138 or a class name (that is, a package name).  See L<perlobj>.
139
140 =head2 Auto-increment and Auto-decrement
141 X<increment> X<auto-increment> X<++> X<decrement> X<auto-decrement> X<-->
142
143 "++" and "--" work as in C.  That is, if placed before a variable,
144 they increment or decrement the variable by one before returning the
145 value, and if placed after, increment or decrement after returning the
146 value.
147
148     $i = 0;  $j = 0;
149     print $i++;  # prints 0
150     print ++$j;  # prints 1
151
152 Note that just as in C, Perl doesn't define B<when> the variable is
153 incremented or decremented. You just know it will be done sometime 
154 before or after the value is returned. This also means that modifying
155 a variable twice in the same statement will lead to undefined behaviour.
156 Avoid statements like:
157
158     $i = $i ++;
159     print ++ $i + $i ++;
160
161 Perl will not guarantee what the result of the above statements is.
162
163 The auto-increment operator has a little extra builtin magic to it.  If
164 you increment a variable that is numeric, or that has ever been used in
165 a numeric context, you get a normal increment.  If, however, the
166 variable has been used in only string contexts since it was set, and
167 has a value that is not the empty string and matches the pattern
168 C</^[a-zA-Z]*[0-9]*\z/>, the increment is done as a string, preserving each
169 character within its range, with carry:
170
171     print ++($foo = '99');      # prints '100'
172     print ++($foo = 'a0');      # prints 'a1'
173     print ++($foo = 'Az');      # prints 'Ba'
174     print ++($foo = 'zz');      # prints 'aaa'
175
176 C<undef> is always treated as numeric, and in particular is changed
177 to C<0> before incrementing (so that a post-increment of an undef value
178 will return C<0> rather than C<undef>).
179
180 The auto-decrement operator is not magical.
181
182 =head2 Exponentiation
183 X<**> X<exponentiation> X<power>
184
185 Binary "**" is the exponentiation operator.  It binds even more
186 tightly than unary minus, so -2**4 is -(2**4), not (-2)**4. (This is
187 implemented using C's pow(3) function, which actually works on doubles
188 internally.)
189
190 =head2 Symbolic Unary Operators
191 X<unary operator> X<operator, unary>
192
193 Unary "!" performs logical negation, i.e., "not".  See also C<not> for a lower
194 precedence version of this.
195 X<!>
196
197 Unary "-" performs arithmetic negation if the operand is numeric.  If
198 the operand is an identifier, a string consisting of a minus sign
199 concatenated with the identifier is returned.  Otherwise, if the string
200 starts with a plus or minus, a string starting with the opposite sign
201 is returned.  One effect of these rules is that -bareword is equivalent
202 to the string "-bareword".  If, however, the string begins with a
203 non-alphabetic character (exluding "+" or "-"), Perl will attempt to convert
204 the string to a numeric and the arithmetic negation is performed. If the
205 string cannot be cleanly converted to a numeric, Perl will give the warning
206 B<Argument "the string" isn't numeric in negation (-) at ...>.
207 X<-> X<negation, arithmetic>
208
209 Unary "~" performs bitwise negation, i.e., 1's complement.  For
210 example, C<0666 & ~027> is 0640.  (See also L<Integer Arithmetic> and
211 L<Bitwise String Operators>.)  Note that the width of the result is
212 platform-dependent: ~0 is 32 bits wide on a 32-bit platform, but 64
213 bits wide on a 64-bit platform, so if you are expecting a certain bit
214 width, remember to use the & operator to mask off the excess bits.
215 X<~> X<negation, binary>
216
217 Unary "+" has no effect whatsoever, even on strings.  It is useful
218 syntactically for separating a function name from a parenthesized expression
219 that would otherwise be interpreted as the complete list of function
220 arguments.  (See examples above under L<Terms and List Operators (Leftward)>.)
221 X<+>
222
223 Unary "\" creates a reference to whatever follows it.  See L<perlreftut>
224 and L<perlref>.  Do not confuse this behavior with the behavior of
225 backslash within a string, although both forms do convey the notion
226 of protecting the next thing from interpolation.
227 X<\> X<reference> X<backslash>
228
229 =head2 Binding Operators
230 X<binding> X<operator, binding> X<=~> X<!~>
231
232 Binary "=~" binds a scalar expression to a pattern match.  Certain operations
233 search or modify the string $_ by default.  This operator makes that kind
234 of operation work on some other string.  The right argument is a search
235 pattern, substitution, or transliteration.  The left argument is what is
236 supposed to be searched, substituted, or transliterated instead of the default
237 $_.  When used in scalar context, the return value generally indicates the
238 success of the operation.  Behavior in list context depends on the particular
239 operator.  See L</"Regexp Quote-Like Operators"> for details and 
240 L<perlretut> for examples using these operators.
241
242 If the right argument is an expression rather than a search pattern,
243 substitution, or transliteration, it is interpreted as a search pattern at run
244 time.
245
246 Binary "!~" is just like "=~" except the return value is negated in
247 the logical sense.
248
249 =head2 Multiplicative Operators
250 X<operator, multiplicative>
251
252 Binary "*" multiplies two numbers.
253 X<*>
254
255 Binary "/" divides two numbers.
256 X</> X<slash>
257
258 Binary "%" computes the modulus of two numbers.  Given integer
259 operands C<$a> and C<$b>: If C<$b> is positive, then C<$a % $b> is
260 C<$a> minus the largest multiple of C<$b> that is not greater than
261 C<$a>.  If C<$b> is negative, then C<$a % $b> is C<$a> minus the
262 smallest multiple of C<$b> that is not less than C<$a> (i.e. the
263 result will be less than or equal to zero). 
264 Note that when C<use integer> is in scope, "%" gives you direct access
265 to the modulus operator as implemented by your C compiler.  This
266 operator is not as well defined for negative operands, but it will
267 execute faster.
268 X<%> X<remainder> X<modulus> X<mod>
269
270 Binary "x" is the repetition operator.  In scalar context or if the left
271 operand is not enclosed in parentheses, it returns a string consisting
272 of the left operand repeated the number of times specified by the right
273 operand.  In list context, if the left operand is enclosed in
274 parentheses or is a list formed by C<qw/STRING/>, it repeats the list.
275 If the right operand is zero or negative, it returns an empty string
276 or an empty list, depending on the context.
277 X<x>
278
279     print '-' x 80;             # print row of dashes
280
281     print "\t" x ($tab/8), ' ' x ($tab%8);      # tab over
282
283     @ones = (1) x 80;           # a list of 80 1's
284     @ones = (5) x @ones;        # set all elements to 5
285
286
287 =head2 Additive Operators
288 X<operator, additive>
289
290 Binary "+" returns the sum of two numbers.
291 X<+>
292
293 Binary "-" returns the difference of two numbers.
294 X<->
295
296 Binary "." concatenates two strings.
297 X<string, concatenation> X<concatenation>
298 X<cat> X<concat> X<concatenate> X<.>
299
300 =head2 Shift Operators
301 X<shift operator> X<operator, shift> X<<< << >>>
302 X<<< >> >>> X<right shift> X<left shift> X<bitwise shift>
303 X<shl> X<shr> X<shift, right> X<shift, left>
304
305 Binary "<<" returns the value of its left argument shifted left by the
306 number of bits specified by the right argument.  Arguments should be
307 integers.  (See also L<Integer Arithmetic>.)
308
309 Binary ">>" returns the value of its left argument shifted right by
310 the number of bits specified by the right argument.  Arguments should
311 be integers.  (See also L<Integer Arithmetic>.)
312
313 Note that both "<<" and ">>" in Perl are implemented directly using
314 "<<" and ">>" in C.  If C<use integer> (see L<Integer Arithmetic>) is
315 in force then signed C integers are used, else unsigned C integers are
316 used.  Either way, the implementation isn't going to generate results
317 larger than the size of the integer type Perl was built with (32 bits
318 or 64 bits).
319
320 The result of overflowing the range of the integers is undefined
321 because it is undefined also in C.  In other words, using 32-bit
322 integers, C<< 1 << 32 >> is undefined.  Shifting by a negative number
323 of bits is also undefined.
324
325 =head2 Named Unary Operators
326 X<operator, named unary>
327
328 The various named unary operators are treated as functions with one
329 argument, with optional parentheses.
330
331 If any list operator (print(), etc.) or any unary operator (chdir(), etc.)
332 is followed by a left parenthesis as the next token, the operator and
333 arguments within parentheses are taken to be of highest precedence,
334 just like a normal function call.  For example,
335 because named unary operators are higher precedence than ||:
336
337     chdir $foo    || die;       # (chdir $foo) || die
338     chdir($foo)   || die;       # (chdir $foo) || die
339     chdir ($foo)  || die;       # (chdir $foo) || die
340     chdir +($foo) || die;       # (chdir $foo) || die
341
342 but, because * is higher precedence than named operators:
343
344     chdir $foo * 20;    # chdir ($foo * 20)
345     chdir($foo) * 20;   # (chdir $foo) * 20
346     chdir ($foo) * 20;  # (chdir $foo) * 20
347     chdir +($foo) * 20; # chdir ($foo * 20)
348
349     rand 10 * 20;       # rand (10 * 20)
350     rand(10) * 20;      # (rand 10) * 20
351     rand (10) * 20;     # (rand 10) * 20
352     rand +(10) * 20;    # rand (10 * 20)
353
354 Regarding precedence, the filetest operators, like C<-f>, C<-M>, etc. are
355 treated like named unary operators, but they don't follow this functional
356 parenthesis rule.  That means, for example, that C<-f($file).".bak"> is
357 equivalent to C<-f "$file.bak">.
358 X<-X> X<filetest> X<operator, filetest>
359
360 See also L<"Terms and List Operators (Leftward)">.
361
362 =head2 Relational Operators
363 X<relational operator> X<operator, relational>
364
365 Binary "<" returns true if the left argument is numerically less than
366 the right argument.
367 X<< < >>
368
369 Binary ">" returns true if the left argument is numerically greater
370 than the right argument.
371 X<< > >>
372
373 Binary "<=" returns true if the left argument is numerically less than
374 or equal to the right argument.
375 X<< <= >>
376
377 Binary ">=" returns true if the left argument is numerically greater
378 than or equal to the right argument.
379 X<< >= >>
380
381 Binary "lt" returns true if the left argument is stringwise less than
382 the right argument.
383 X<< lt >>
384
385 Binary "gt" returns true if the left argument is stringwise greater
386 than the right argument.
387 X<< gt >>
388
389 Binary "le" returns true if the left argument is stringwise less than
390 or equal to the right argument.
391 X<< le >>
392
393 Binary "ge" returns true if the left argument is stringwise greater
394 than or equal to the right argument.
395 X<< ge >>
396
397 =head2 Equality Operators
398 X<equality> X<equal> X<equals> X<operator, equality>
399
400 Binary "==" returns true if the left argument is numerically equal to
401 the right argument.
402 X<==>
403
404 Binary "!=" returns true if the left argument is numerically not equal
405 to the right argument.
406 X<!=>
407
408 Binary "<=>" returns -1, 0, or 1 depending on whether the left
409 argument is numerically less than, equal to, or greater than the right
410 argument.  If your platform supports NaNs (not-a-numbers) as numeric
411 values, using them with "<=>" returns undef.  NaN is not "<", "==", ">",
412 "<=" or ">=" anything (even NaN), so those 5 return false. NaN != NaN
413 returns true, as does NaN != anything else. If your platform doesn't
414 support NaNs then NaN is just a string with numeric value 0.
415 X<< <=> >> X<spaceship>
416
417     perl -le '$a = "NaN"; print "No NaN support here" if $a == $a'
418     perl -le '$a = "NaN"; print "NaN support here" if $a != $a'
419
420 Binary "eq" returns true if the left argument is stringwise equal to
421 the right argument.
422 X<eq>
423
424 Binary "ne" returns true if the left argument is stringwise not equal
425 to the right argument.
426 X<ne>
427
428 Binary "cmp" returns -1, 0, or 1 depending on whether the left
429 argument is stringwise less than, equal to, or greater than the right
430 argument.
431 X<cmp>
432
433 Binary "~~" does a smart match between its arguments. Smart matching
434 is described in L<perlsyn/"Smart Matching in Detail">.
435 This operator is only available if you enable the "~~" feature:
436 see L<feature> for more information.
437 X<~~>
438
439 "lt", "le", "ge", "gt" and "cmp" use the collation (sort) order specified
440 by the current locale if C<use locale> is in effect.  See L<perllocale>.
441
442 =head2 Bitwise And
443 X<operator, bitwise, and> X<bitwise and> X<&>
444
445 Binary "&" returns its operands ANDed together bit by bit.
446 (See also L<Integer Arithmetic> and L<Bitwise String Operators>.)
447
448 Note that "&" has lower priority than relational operators, so for example
449 the brackets are essential in a test like
450
451         print "Even\n" if ($x & 1) == 0;
452
453 =head2 Bitwise Or and Exclusive Or
454 X<operator, bitwise, or> X<bitwise or> X<|> X<operator, bitwise, xor>
455 X<bitwise xor> X<^>
456
457 Binary "|" returns its operands ORed together bit by bit.
458 (See also L<Integer Arithmetic> and L<Bitwise String Operators>.)
459
460 Binary "^" returns its operands XORed together bit by bit.
461 (See also L<Integer Arithmetic> and L<Bitwise String Operators>.)
462
463 Note that "|" and "^" have lower priority than relational operators, so
464 for example the brackets are essential in a test like
465
466         print "false\n" if (8 | 2) != 10;
467
468 =head2 C-style Logical And
469 X<&&> X<logical and> X<operator, logical, and>
470
471 Binary "&&" performs a short-circuit logical AND operation.  That is,
472 if the left operand is false, the right operand is not even evaluated.
473 Scalar or list context propagates down to the right operand if it
474 is evaluated.
475
476 =head2 C-style Logical Or
477 X<||> X<operator, logical, or>
478
479 Binary "||" performs a short-circuit logical OR operation.  That is,
480 if the left operand is true, the right operand is not even evaluated.
481 Scalar or list context propagates down to the right operand if it
482 is evaluated.
483
484 =head2 C-style Logical Defined-Or
485 X<//> X<operator, logical, defined-or>
486
487 Although it has no direct equivalent in C, Perl's C<//> operator is related
488 to its C-style or.  In fact, it's exactly the same as C<||>, except that it 
489 tests the left hand side's definedness instead of its truth.  Thus, C<$a // $b>
490 is similar to C<defined($a) || $b> (except that it returns the value of C<$a> 
491 rather than the value of C<defined($a)>) and is exactly equivalent to 
492 C<defined($a) ? $a : $b>.  This is very useful for providing default values
493 for variables.  If you actually want to test if at least one of C<$a> and 
494 C<$b> is defined, use C<defined($a // $b)>.
495
496 The C<||>, C<//> and C<&&> operators return the last value evaluated
497 (unlike C's C<||> and C<&&>, which return 0 or 1). Thus, a reasonably
498 portable way to find out the home directory might be:
499
500     $home = $ENV{'HOME'} // $ENV{'LOGDIR'} //
501         (getpwuid($<))[7] // die "You're homeless!\n";
502
503 In particular, this means that you shouldn't use this
504 for selecting between two aggregates for assignment:
505
506     @a = @b || @c;              # this is wrong
507     @a = scalar(@b) || @c;      # really meant this
508     @a = @b ? @b : @c;          # this works fine, though
509
510 As more readable alternatives to C<&&>, C<//> and C<||> when used for
511 control flow, Perl provides C<and>, C<err> and C<or> operators (see below).
512 The short-circuit behavior is identical.  The precedence of "and", "err" 
513 and "or" is much lower, however, so that you can safely use them after a
514 list operator without the need for parentheses:
515
516     unlink "alpha", "beta", "gamma"
517             or gripe(), next LINE;
518
519 With the C-style operators that would have been written like this:
520
521     unlink("alpha", "beta", "gamma")
522             || (gripe(), next LINE);
523
524 Using "or" for assignment is unlikely to do what you want; see below.
525
526 =head2 Range Operators
527 X<operator, range> X<range> X<..> X<...>
528
529 Binary ".." is the range operator, which is really two different
530 operators depending on the context.  In list context, it returns a
531 list of values counting (up by ones) from the left value to the right
532 value.  If the left value is greater than the right value then it
533 returns the empty list.  The range operator is useful for writing
534 C<foreach (1..10)> loops and for doing slice operations on arrays. In
535 the current implementation, no temporary array is created when the
536 range operator is used as the expression in C<foreach> loops, but older
537 versions of Perl might burn a lot of memory when you write something
538 like this:
539
540     for (1 .. 1_000_000) {
541         # code
542     }
543
544 The range operator also works on strings, using the magical auto-increment,
545 see below.
546
547 In scalar context, ".." returns a boolean value.  The operator is
548 bistable, like a flip-flop, and emulates the line-range (comma) operator
549 of B<sed>, B<awk>, and various editors.  Each ".." operator maintains its
550 own boolean state.  It is false as long as its left operand is false.
551 Once the left operand is true, the range operator stays true until the
552 right operand is true, I<AFTER> which the range operator becomes false
553 again.  It doesn't become false till the next time the range operator is
554 evaluated.  It can test the right operand and become false on the same
555 evaluation it became true (as in B<awk>), but it still returns true once.
556 If you don't want it to test the right operand till the next
557 evaluation, as in B<sed>, just use three dots ("...") instead of
558 two.  In all other regards, "..." behaves just like ".." does.
559
560 The right operand is not evaluated while the operator is in the
561 "false" state, and the left operand is not evaluated while the
562 operator is in the "true" state.  The precedence is a little lower
563 than || and &&.  The value returned is either the empty string for
564 false, or a sequence number (beginning with 1) for true.  The
565 sequence number is reset for each range encountered.  The final
566 sequence number in a range has the string "E0" appended to it, which
567 doesn't affect its numeric value, but gives you something to search
568 for if you want to exclude the endpoint.  You can exclude the
569 beginning point by waiting for the sequence number to be greater
570 than 1.
571
572 If either operand of scalar ".." is a constant expression,
573 that operand is considered true if it is equal (C<==>) to the current
574 input line number (the C<$.> variable).
575
576 To be pedantic, the comparison is actually C<int(EXPR) == int(EXPR)>,
577 but that is only an issue if you use a floating point expression; when
578 implicitly using C<$.> as described in the previous paragraph, the
579 comparison is C<int(EXPR) == int($.)> which is only an issue when C<$.>
580 is set to a floating point value and you are not reading from a file.
581 Furthermore, C<"span" .. "spat"> or C<2.18 .. 3.14> will not do what
582 you want in scalar context because each of the operands are evaluated
583 using their integer representation.
584
585 Examples:
586
587 As a scalar operator:
588
589     if (101 .. 200) { print; } # print 2nd hundred lines, short for
590                                #   if ($. == 101 .. $. == 200) ...
591
592     next LINE if (1 .. /^$/);  # skip header lines, short for
593                                #   ... if ($. == 1 .. /^$/);
594                                # (typically in a loop labeled LINE)
595
596     s/^/> / if (/^$/ .. eof());  # quote body
597
598     # parse mail messages
599     while (<>) {
600         $in_header =   1  .. /^$/;
601         $in_body   = /^$/ .. eof;
602         if ($in_header) {
603             # ...
604         } else { # in body
605             # ...
606         }
607     } continue {
608         close ARGV if eof;             # reset $. each file
609     }
610
611 Here's a simple example to illustrate the difference between
612 the two range operators:
613
614     @lines = ("   - Foo",
615               "01 - Bar",
616               "1  - Baz",
617               "   - Quux");
618
619     foreach (@lines) {
620         if (/0/ .. /1/) {
621             print "$_\n";
622         }
623     }
624
625 This program will print only the line containing "Bar". If
626 the range operator is changed to C<...>, it will also print the
627 "Baz" line.
628
629 And now some examples as a list operator:
630
631     for (101 .. 200) { print; } # print $_ 100 times
632     @foo = @foo[0 .. $#foo];    # an expensive no-op
633     @foo = @foo[$#foo-4 .. $#foo];      # slice last 5 items
634
635 The range operator (in list context) makes use of the magical
636 auto-increment algorithm if the operands are strings.  You
637 can say
638
639     @alphabet = ('A' .. 'Z');
640
641 to get all normal letters of the English alphabet, or
642
643     $hexdigit = (0 .. 9, 'a' .. 'f')[$num & 15];
644
645 to get a hexadecimal digit, or
646
647     @z2 = ('01' .. '31');  print $z2[$mday];
648
649 to get dates with leading zeros.  If the final value specified is not
650 in the sequence that the magical increment would produce, the sequence
651 goes until the next value would be longer than the final value
652 specified.
653
654 Because each operand is evaluated in integer form, C<2.18 .. 3.14> will
655 return two elements in list context.
656
657     @list = (2.18 .. 3.14); # same as @list = (2 .. 3);
658
659 =head2 Conditional Operator
660 X<operator, conditional> X<operator, ternary> X<ternary> X<?:>
661
662 Ternary "?:" is the conditional operator, just as in C.  It works much
663 like an if-then-else.  If the argument before the ? is true, the
664 argument before the : is returned, otherwise the argument after the :
665 is returned.  For example:
666
667     printf "I have %d dog%s.\n", $n,
668             ($n == 1) ? '' : "s";
669
670 Scalar or list context propagates downward into the 2nd
671 or 3rd argument, whichever is selected.
672
673     $a = $ok ? $b : $c;  # get a scalar
674     @a = $ok ? @b : @c;  # get an array
675     $a = $ok ? @b : @c;  # oops, that's just a count!
676
677 The operator may be assigned to if both the 2nd and 3rd arguments are
678 legal lvalues (meaning that you can assign to them):
679
680     ($a_or_b ? $a : $b) = $c;
681
682 Because this operator produces an assignable result, using assignments
683 without parentheses will get you in trouble.  For example, this:
684
685     $a % 2 ? $a += 10 : $a += 2
686
687 Really means this:
688
689     (($a % 2) ? ($a += 10) : $a) += 2
690
691 Rather than this:
692
693     ($a % 2) ? ($a += 10) : ($a += 2)
694
695 That should probably be written more simply as:
696
697     $a += ($a % 2) ? 10 : 2;
698
699 =head2 Assignment Operators
700 X<assignment> X<operator, assignment> X<=> X<**=> X<+=> X<*=> X<&=>
701 X<<< <<= >>> X<&&=> X<-=> X</=> X<|=> X<<< >>= >>> X<||=> X<//=> X<.=>
702 X<%=> X<^=> X<x=>
703
704 "=" is the ordinary assignment operator.
705
706 Assignment operators work as in C.  That is,
707
708     $a += 2;
709
710 is equivalent to
711
712     $a = $a + 2;
713
714 although without duplicating any side effects that dereferencing the lvalue
715 might trigger, such as from tie().  Other assignment operators work similarly.
716 The following are recognized:
717
718     **=    +=    *=    &=    <<=    &&=
719            -=    /=    |=    >>=    ||=
720            .=    %=    ^=           //=
721                  x=
722
723 Although these are grouped by family, they all have the precedence
724 of assignment.
725
726 Unlike in C, the scalar assignment operator produces a valid lvalue.
727 Modifying an assignment is equivalent to doing the assignment and
728 then modifying the variable that was assigned to.  This is useful
729 for modifying a copy of something, like this:
730
731     ($tmp = $global) =~ tr [A-Z] [a-z];
732
733 Likewise,
734
735     ($a += 2) *= 3;
736
737 is equivalent to
738
739     $a += 2;
740     $a *= 3;
741
742 Similarly, a list assignment in list context produces the list of
743 lvalues assigned to, and a list assignment in scalar context returns
744 the number of elements produced by the expression on the right hand
745 side of the assignment.
746
747 =head2 Comma Operator
748 X<comma> X<operator, comma> X<,>
749
750 Binary "," is the comma operator.  In scalar context it evaluates
751 its left argument, throws that value away, then evaluates its right
752 argument and returns that value.  This is just like C's comma operator.
753
754 In list context, it's just the list argument separator, and inserts
755 both its arguments into the list.
756
757 The C<< => >> operator is a synonym for the comma, but forces any word
758 (consisting entirely of word characters) to its left to be interpreted
759 as a string (as of 5.001).  This includes words that might otherwise be
760 considered a constant or function call.
761
762     use constant FOO => "something";
763
764     my %h = ( FOO => 23 );
765
766 is equivalent to:
767
768     my %h = ("FOO", 23);
769
770 It is I<NOT>:
771
772     my %h = ("something", 23);
773
774 If the argument on the left is not a word, it is first interpreted as
775 an expression, and then the string value of that is used.
776
777 The C<< => >> operator is helpful in documenting the correspondence
778 between keys and values in hashes, and other paired elements in lists.
779
780         %hash = ( $key => $value );
781         login( $username => $password );
782
783 =head2 List Operators (Rightward)
784 X<operator, list, rightward> X<list operator>
785
786 On the right side of a list operator, it has very low precedence,
787 such that it controls all comma-separated expressions found there.
788 The only operators with lower precedence are the logical operators
789 "and", "or", and "not", which may be used to evaluate calls to list
790 operators without the need for extra parentheses:
791
792     open HANDLE, "filename"
793         or die "Can't open: $!\n";
794
795 See also discussion of list operators in L<Terms and List Operators (Leftward)>.
796
797 =head2 Logical Not
798 X<operator, logical, not> X<not>
799
800 Unary "not" returns the logical negation of the expression to its right.
801 It's the equivalent of "!" except for the very low precedence.
802
803 =head2 Logical And
804 X<operator, logical, and> X<and>
805
806 Binary "and" returns the logical conjunction of the two surrounding
807 expressions.  It's equivalent to && except for the very low
808 precedence.  This means that it short-circuits: i.e., the right
809 expression is evaluated only if the left expression is true.
810
811 =head2 Logical or, Defined or, and Exclusive Or
812 X<operator, logical, or> X<operator, logical, xor> X<operator, logical, err>
813 X<operator, logical, defined or> X<operator, logical, exclusive or>
814 X<or> X<xor> X<err>
815
816 Binary "or" returns the logical disjunction of the two surrounding
817 expressions.  It's equivalent to || except for the very low precedence.
818 This makes it useful for control flow
819
820     print FH $data              or die "Can't write to FH: $!";
821
822 This means that it short-circuits: i.e., the right expression is evaluated
823 only if the left expression is false.  Due to its precedence, you should
824 probably avoid using this for assignment, only for control flow.
825
826     $a = $b or $c;              # bug: this is wrong
827     ($a = $b) or $c;            # really means this
828     $a = $b || $c;              # better written this way
829
830 However, when it's a list-context assignment and you're trying to use
831 "||" for control flow, you probably need "or" so that the assignment
832 takes higher precedence.
833
834     @info = stat($file) || die;     # oops, scalar sense of stat!
835     @info = stat($file) or die;     # better, now @info gets its due
836
837 Then again, you could always use parentheses.
838
839 Binary "err" is equivalent to C<//>--it's just like binary "or", except it
840 tests its left argument's definedness instead of its truth.  There are two
841 ways to remember "err":  either because many functions return C<undef> on
842 an B<err>or, or as a sort of correction:  C<$a = ($b err 'default')>. This
843 keyword is only available when the 'err' feature is enabled: see
844 L<feature> for more information.
845
846 Binary "xor" returns the exclusive-OR of the two surrounding expressions.
847 It cannot short circuit, of course.
848
849 =head2 C Operators Missing From Perl
850 X<operator, missing from perl> X<&> X<*>
851 X<typecasting> X<(TYPE)>
852
853 Here is what C has that Perl doesn't:
854
855 =over 8
856
857 =item unary &
858
859 Address-of operator.  (But see the "\" operator for taking a reference.)
860
861 =item unary *
862
863 Dereference-address operator. (Perl's prefix dereferencing
864 operators are typed: $, @, %, and &.)
865
866 =item (TYPE)
867
868 Type-casting operator.
869
870 =back
871
872 =head2 Quote and Quote-like Operators
873 X<operator, quote> X<operator, quote-like> X<q> X<qq> X<qx> X<qw> X<m> 
874 X<qr> X<s> X<tr> X<'> X<''> X<"> X<""> X<//> X<`> X<``> X<<< << >>>
875 X<escape sequence> X<escape>
876
877
878 While we usually think of quotes as literal values, in Perl they
879 function as operators, providing various kinds of interpolating and
880 pattern matching capabilities.  Perl provides customary quote characters
881 for these behaviors, but also provides a way for you to choose your
882 quote character for any of them.  In the following table, a C<{}> represents
883 any pair of delimiters you choose.
884
885     Customary  Generic        Meaning        Interpolates
886         ''       q{}          Literal             no
887         ""      qq{}          Literal             yes
888         ``      qx{}          Command             yes*
889                 qw{}         Word list            no
890         //       m{}       Pattern match          yes*
891                 qr{}          Pattern             yes*
892                  s{}{}      Substitution          yes*
893                 tr{}{}    Transliteration         no (but see below)
894         <<EOF                 here-doc            yes*
895
896         * unless the delimiter is ''.
897
898 Non-bracketing delimiters use the same character fore and aft, but the four
899 sorts of brackets (round, angle, square, curly) will all nest, which means
900 that
901
902         q{foo{bar}baz}
903
904 is the same as
905
906         'foo{bar}baz'
907
908 Note, however, that this does not always work for quoting Perl code:
909
910         $s = q{ if($a eq "}") ... }; # WRONG
911
912 is a syntax error. The C<Text::Balanced> module (from CPAN, and
913 starting from Perl 5.8 part of the standard distribution) is able
914 to do this properly.
915
916 There can be whitespace between the operator and the quoting
917 characters, except when C<#> is being used as the quoting character.
918 C<q#foo#> is parsed as the string C<foo>, while C<q #foo#> is the
919 operator C<q> followed by a comment.  Its argument will be taken
920 from the next line.  This allows you to write:
921
922     s {foo}  # Replace foo
923       {bar}  # with bar.
924
925 The following escape sequences are available in constructs that interpolate
926 and in transliterations.
927 X<\t> X<\n> X<\r> X<\f> X<\b> X<\a> X<\e> X<\x> X<\0> X<\c> X<\N>
928
929     \t          tab             (HT, TAB)
930     \n          newline         (NL)
931     \r          return          (CR)
932     \f          form feed       (FF)
933     \b          backspace       (BS)
934     \a          alarm (bell)    (BEL)
935     \e          escape          (ESC)
936     \033        octal char      (ESC)
937     \x1b        hex char        (ESC)
938     \x{263a}    wide hex char   (SMILEY)
939     \c[         control char    (ESC)
940     \N{name}    named Unicode character
941
942 B<NOTE>: Unlike C and other languages, Perl has no \v escape sequence for
943 the vertical tab (VT - ASCII 11).
944
945 The following escape sequences are available in constructs that interpolate
946 but not in transliterations.
947 X<\l> X<\u> X<\L> X<\U> X<\E> X<\Q>
948
949     \l          lowercase next char
950     \u          uppercase next char
951     \L          lowercase till \E
952     \U          uppercase till \E
953     \E          end case modification
954     \Q          quote non-word characters till \E
955
956 If C<use locale> is in effect, the case map used by C<\l>, C<\L>,
957 C<\u> and C<\U> is taken from the current locale.  See L<perllocale>.
958 If Unicode (for example, C<\N{}> or wide hex characters of 0x100 or
959 beyond) is being used, the case map used by C<\l>, C<\L>, C<\u> and
960 C<\U> is as defined by Unicode.  For documentation of C<\N{name}>,
961 see L<charnames>.
962
963 All systems use the virtual C<"\n"> to represent a line terminator,
964 called a "newline".  There is no such thing as an unvarying, physical
965 newline character.  It is only an illusion that the operating system,
966 device drivers, C libraries, and Perl all conspire to preserve.  Not all
967 systems read C<"\r"> as ASCII CR and C<"\n"> as ASCII LF.  For example,
968 on a Mac, these are reversed, and on systems without line terminator,
969 printing C<"\n"> may emit no actual data.  In general, use C<"\n"> when
970 you mean a "newline" for your system, but use the literal ASCII when you
971 need an exact character.  For example, most networking protocols expect
972 and prefer a CR+LF (C<"\015\012"> or C<"\cM\cJ">) for line terminators,
973 and although they often accept just C<"\012">, they seldom tolerate just
974 C<"\015">.  If you get in the habit of using C<"\n"> for networking,
975 you may be burned some day.
976 X<newline> X<line terminator> X<eol> X<end of line>
977 X<\n> X<\r> X<\r\n>
978
979 For constructs that do interpolate, variables beginning with "C<$>"
980 or "C<@>" are interpolated.  Subscripted variables such as C<$a[3]> or
981 C<< $href->{key}[0] >> are also interpolated, as are array and hash slices.
982 But method calls such as C<< $obj->meth >> are not.
983
984 Interpolating an array or slice interpolates the elements in order,
985 separated by the value of C<$">, so is equivalent to interpolating
986 C<join $", @array>.    "Punctuation" arrays such as C<@+> are only
987 interpolated if the name is enclosed in braces C<@{+}>.
988
989 You cannot include a literal C<$> or C<@> within a C<\Q> sequence. 
990 An unescaped C<$> or C<@> interpolates the corresponding variable, 
991 while escaping will cause the literal string C<\$> to be inserted.
992 You'll need to write something like C<m/\Quser\E\@\Qhost/>. 
993
994 Patterns are subject to an additional level of interpretation as a
995 regular expression.  This is done as a second pass, after variables are
996 interpolated, so that regular expressions may be incorporated into the
997 pattern from the variables.  If this is not what you want, use C<\Q> to
998 interpolate a variable literally.
999
1000 Apart from the behavior described above, Perl does not expand
1001 multiple levels of interpolation.  In particular, contrary to the
1002 expectations of shell programmers, back-quotes do I<NOT> interpolate
1003 within double quotes, nor do single quotes impede evaluation of
1004 variables when used within double quotes.
1005
1006 =head2 Regexp Quote-Like Operators
1007 X<operator, regexp>
1008
1009 Here are the quote-like operators that apply to pattern
1010 matching and related activities.
1011
1012 =over 8
1013
1014 =item ?PATTERN?
1015 X<?>
1016
1017 This is just like the C</pattern/> search, except that it matches only
1018 once between calls to the reset() operator.  This is a useful
1019 optimization when you want to see only the first occurrence of
1020 something in each file of a set of files, for instance.  Only C<??>
1021 patterns local to the current package are reset.
1022
1023     while (<>) {
1024         if (?^$?) {
1025                             # blank line between header and body
1026         }
1027     } continue {
1028         reset if eof;       # clear ?? status for next file
1029     }
1030
1031 This usage is vaguely deprecated, which means it just might possibly
1032 be removed in some distant future version of Perl, perhaps somewhere
1033 around the year 2168.
1034
1035 =item m/PATTERN/cgimosx
1036 X<m> X<operator, match> 
1037 X<regexp, options> X<regexp> X<regex, options> X<regex> 
1038 X</c> X</i> X</m> X</o> X</s> X</x>
1039
1040 =item /PATTERN/cgimosx
1041
1042 Searches a string for a pattern match, and in scalar context returns
1043 true if it succeeds, false if it fails.  If no string is specified
1044 via the C<=~> or C<!~> operator, the $_ string is searched.  (The
1045 string specified with C<=~> need not be an lvalue--it may be the
1046 result of an expression evaluation, but remember the C<=~> binds
1047 rather tightly.)  See also L<perlre>.  See L<perllocale> for
1048 discussion of additional considerations that apply when C<use locale>
1049 is in effect.
1050
1051 Options are:
1052
1053     c   Do not reset search position on a failed match when /g is in effect.
1054     g   Match globally, i.e., find all occurrences.
1055     i   Do case-insensitive pattern matching.
1056     m   Treat string as multiple lines.
1057     o   Compile pattern only once.
1058     s   Treat string as single line.
1059     x   Use extended regular expressions.
1060
1061 If "/" is the delimiter then the initial C<m> is optional.  With the C<m>
1062 you can use any pair of non-alphanumeric, non-whitespace characters 
1063 as delimiters.  This is particularly useful for matching path names
1064 that contain "/", to avoid LTS (leaning toothpick syndrome).  If "?" is
1065 the delimiter, then the match-only-once rule of C<?PATTERN?> applies.
1066 If "'" is the delimiter, no interpolation is performed on the PATTERN.
1067
1068 PATTERN may contain variables, which will be interpolated (and the
1069 pattern recompiled) every time the pattern search is evaluated, except
1070 for when the delimiter is a single quote.  (Note that C<$(>, C<$)>, and
1071 C<$|> are not interpolated because they look like end-of-string tests.)
1072 If you want such a pattern to be compiled only once, add a C</o> after
1073 the trailing delimiter.  This avoids expensive run-time recompilations,
1074 and is useful when the value you are interpolating won't change over
1075 the life of the script.  However, mentioning C</o> constitutes a promise
1076 that you won't change the variables in the pattern.  If you change them,
1077 Perl won't even notice.  See also L<"qr/STRING/imosx">.
1078
1079 If the PATTERN evaluates to the empty string, the last
1080 I<successfully> matched regular expression is used instead. In this
1081 case, only the C<g> and C<c> flags on the empty pattern is honoured -
1082 the other flags are taken from the original pattern. If no match has
1083 previously succeeded, this will (silently) act instead as a genuine
1084 empty pattern (which will always match).
1085
1086 Note that it's possible to confuse Perl into thinking C<//> (the empty 
1087 regex) is really C<//> (the defined-or operator).  Perl is usually pretty 
1088 good about this, but some pathological cases might trigger this, such as 
1089 C<$a///> (is that C<($a) / (//)> or C<$a // />?) and C<print $fh //> 
1090 (C<print $fh(//> or C<print($fh //>?).  In all of these examples, Perl 
1091 will assume you meant defined-or.  If you meant the empty regex, just 
1092 use parentheses or spaces to disambiguate, or even prefix the empty 
1093 regex with an C<m> (so C<//> becomes C<m//>).
1094
1095 If the C</g> option is not used, C<m//> in list context returns a
1096 list consisting of the subexpressions matched by the parentheses in the
1097 pattern, i.e., (C<$1>, C<$2>, C<$3>...).  (Note that here C<$1> etc. are
1098 also set, and that this differs from Perl 4's behavior.)  When there are
1099 no parentheses in the pattern, the return value is the list C<(1)> for
1100 success.  With or without parentheses, an empty list is returned upon
1101 failure.
1102
1103 Examples:
1104
1105     open(TTY, '/dev/tty');
1106     <TTY> =~ /^y/i && foo();    # do foo if desired
1107
1108     if (/Version: *([0-9.]*)/) { $version = $1; }
1109
1110     next if m#^/usr/spool/uucp#;
1111
1112     # poor man's grep
1113     $arg = shift;
1114     while (<>) {
1115         print if /$arg/o;       # compile only once
1116     }
1117
1118     if (($F1, $F2, $Etc) = ($foo =~ /^(\S+)\s+(\S+)\s*(.*)/))
1119
1120 This last example splits $foo into the first two words and the
1121 remainder of the line, and assigns those three fields to $F1, $F2, and
1122 $Etc.  The conditional is true if any variables were assigned, i.e., if
1123 the pattern matched.
1124
1125 The C</g> modifier specifies global pattern matching--that is,
1126 matching as many times as possible within the string.  How it behaves
1127 depends on the context.  In list context, it returns a list of the
1128 substrings matched by any capturing parentheses in the regular
1129 expression.  If there are no parentheses, it returns a list of all
1130 the matched strings, as if there were parentheses around the whole
1131 pattern.
1132
1133 In scalar context, each execution of C<m//g> finds the next match,
1134 returning true if it matches, and false if there is no further match.
1135 The position after the last match can be read or set using the pos()
1136 function; see L<perlfunc/pos>.   A failed match normally resets the
1137 search position to the beginning of the string, but you can avoid that
1138 by adding the C</c> modifier (e.g. C<m//gc>).  Modifying the target
1139 string also resets the search position.
1140
1141 You can intermix C<m//g> matches with C<m/\G.../g>, where C<\G> is a
1142 zero-width assertion that matches the exact position where the previous
1143 C<m//g>, if any, left off.  Without the C</g> modifier, the C<\G> assertion
1144 still anchors at pos(), but the match is of course only attempted once.
1145 Using C<\G> without C</g> on a target string that has not previously had a
1146 C</g> match applied to it is the same as using the C<\A> assertion to match
1147 the beginning of the string.  Note also that, currently, C<\G> is only
1148 properly supported when anchored at the very beginning of the pattern.
1149
1150 Examples:
1151
1152     # list context
1153     ($one,$five,$fifteen) = (`uptime` =~ /(\d+\.\d+)/g);
1154
1155     # scalar context
1156     $/ = "";
1157     while (defined($paragraph = <>)) {
1158         while ($paragraph =~ /[a-z]['")]*[.!?]+['")]*\s/g) {
1159             $sentences++;
1160         }
1161     }
1162     print "$sentences\n";
1163
1164     # using m//gc with \G
1165     $_ = "ppooqppqq";
1166     while ($i++ < 2) {
1167         print "1: '";
1168         print $1 while /(o)/gc; print "', pos=", pos, "\n";
1169         print "2: '";
1170         print $1 if /\G(q)/gc;  print "', pos=", pos, "\n";
1171         print "3: '";
1172         print $1 while /(p)/gc; print "', pos=", pos, "\n";
1173     }
1174     print "Final: '$1', pos=",pos,"\n" if /\G(.)/;
1175
1176 The last example should print:
1177
1178     1: 'oo', pos=4
1179     2: 'q', pos=5
1180     3: 'pp', pos=7
1181     1: '', pos=7
1182     2: 'q', pos=8
1183     3: '', pos=8
1184     Final: 'q', pos=8
1185
1186 Notice that the final match matched C<q> instead of C<p>, which a match
1187 without the C<\G> anchor would have done. Also note that the final match
1188 did not update C<pos> -- C<pos> is only updated on a C</g> match. If the
1189 final match did indeed match C<p>, it's a good bet that you're running an
1190 older (pre-5.6.0) Perl.
1191
1192 A useful idiom for C<lex>-like scanners is C</\G.../gc>.  You can
1193 combine several regexps like this to process a string part-by-part,
1194 doing different actions depending on which regexp matched.  Each
1195 regexp tries to match where the previous one leaves off.
1196
1197  $_ = <<'EOL';
1198       $url = new URI::URL "http://www/";   die if $url eq "xXx";
1199  EOL
1200  LOOP:
1201     {
1202       print(" digits"),         redo LOOP if /\G\d+\b[,.;]?\s*/gc;
1203       print(" lowercase"),      redo LOOP if /\G[a-z]+\b[,.;]?\s*/gc;
1204       print(" UPPERCASE"),      redo LOOP if /\G[A-Z]+\b[,.;]?\s*/gc;
1205       print(" Capitalized"),    redo LOOP if /\G[A-Z][a-z]+\b[,.;]?\s*/gc;
1206       print(" MiXeD"),          redo LOOP if /\G[A-Za-z]+\b[,.;]?\s*/gc;
1207       print(" alphanumeric"),   redo LOOP if /\G[A-Za-z0-9]+\b[,.;]?\s*/gc;
1208       print(" line-noise"),     redo LOOP if /\G[^A-Za-z0-9]+/gc;
1209       print ". That's all!\n";
1210     }
1211
1212 Here is the output (split into several lines):
1213
1214  line-noise lowercase line-noise lowercase UPPERCASE line-noise
1215  UPPERCASE line-noise lowercase line-noise lowercase line-noise
1216  lowercase lowercase line-noise lowercase lowercase line-noise
1217  MiXeD line-noise. That's all!
1218
1219 =item q/STRING/
1220 X<q> X<quote, double> X<'> X<''>
1221
1222 =item C<'STRING'>
1223
1224 A single-quoted, literal string.  A backslash represents a backslash
1225 unless followed by the delimiter or another backslash, in which case
1226 the delimiter or backslash is interpolated.
1227
1228     $foo = q!I said, "You said, 'She said it.'"!;
1229     $bar = q('This is it.');
1230     $baz = '\n';                # a two-character string
1231
1232 =item qq/STRING/
1233 X<qq> X<quote, double> X<"> X<"">
1234
1235 =item "STRING"
1236
1237 A double-quoted, interpolated string.
1238
1239     $_ .= qq
1240      (*** The previous line contains the naughty word "$1".\n)
1241                 if /\b(tcl|java|python)\b/i;      # :-)
1242     $baz = "\n";                # a one-character string
1243
1244 =item qr/STRING/imosx
1245 X<qr> X</i> X</m> X</o> X</s> X</x>
1246
1247 This operator quotes (and possibly compiles) its I<STRING> as a regular
1248 expression.  I<STRING> is interpolated the same way as I<PATTERN>
1249 in C<m/PATTERN/>.  If "'" is used as the delimiter, no interpolation
1250 is done.  Returns a Perl value which may be used instead of the
1251 corresponding C</STRING/imosx> expression.
1252
1253 For example,
1254
1255     $rex = qr/my.STRING/is;
1256     s/$rex/foo/;
1257
1258 is equivalent to
1259
1260     s/my.STRING/foo/is;
1261
1262 The result may be used as a subpattern in a match:
1263
1264     $re = qr/$pattern/;
1265     $string =~ /foo${re}bar/;   # can be interpolated in other patterns
1266     $string =~ $re;             # or used standalone
1267     $string =~ /$re/;           # or this way
1268
1269 Since Perl may compile the pattern at the moment of execution of qr()
1270 operator, using qr() may have speed advantages in some situations,
1271 notably if the result of qr() is used standalone:
1272
1273     sub match {
1274         my $patterns = shift;
1275         my @compiled = map qr/$_/i, @$patterns;
1276         grep {
1277             my $success = 0;
1278             foreach my $pat (@compiled) {
1279                 $success = 1, last if /$pat/;
1280             }
1281             $success;
1282         } @_;
1283     }
1284
1285 Precompilation of the pattern into an internal representation at
1286 the moment of qr() avoids a need to recompile the pattern every
1287 time a match C</$pat/> is attempted.  (Perl has many other internal
1288 optimizations, but none would be triggered in the above example if
1289 we did not use qr() operator.)
1290
1291 Options are:
1292
1293     i   Do case-insensitive pattern matching.
1294     m   Treat string as multiple lines.
1295     o   Compile pattern only once.
1296     s   Treat string as single line.
1297     x   Use extended regular expressions.
1298
1299 See L<perlre> for additional information on valid syntax for STRING, and
1300 for a detailed look at the semantics of regular expressions.
1301
1302 =item qx/STRING/
1303 X<qx> X<`> X<``> X<backtick>
1304
1305 =item `STRING`
1306
1307 A string which is (possibly) interpolated and then executed as a
1308 system command with C</bin/sh> or its equivalent.  Shell wildcards,
1309 pipes, and redirections will be honored.  The collected standard
1310 output of the command is returned; standard error is unaffected.  In
1311 scalar context, it comes back as a single (potentially multi-line)
1312 string, or undef if the command failed.  In list context, returns a
1313 list of lines (however you've defined lines with $/ or
1314 $INPUT_RECORD_SEPARATOR), or an empty list if the command failed.
1315
1316 Because backticks do not affect standard error, use shell file descriptor
1317 syntax (assuming the shell supports this) if you care to address this.
1318 To capture a command's STDERR and STDOUT together:
1319
1320     $output = `cmd 2>&1`;
1321
1322 To capture a command's STDOUT but discard its STDERR:
1323
1324     $output = `cmd 2>/dev/null`;
1325
1326 To capture a command's STDERR but discard its STDOUT (ordering is
1327 important here):
1328
1329     $output = `cmd 2>&1 1>/dev/null`;
1330
1331 To exchange a command's STDOUT and STDERR in order to capture the STDERR
1332 but leave its STDOUT to come out the old STDERR:
1333
1334     $output = `cmd 3>&1 1>&2 2>&3 3>&-`;
1335
1336 To read both a command's STDOUT and its STDERR separately, it's easiest
1337 to redirect them separately to files, and then read from those files
1338 when the program is done:
1339
1340     system("program args 1>program.stdout 2>program.stderr");
1341
1342 Using single-quote as a delimiter protects the command from Perl's
1343 double-quote interpolation, passing it on to the shell instead:
1344
1345     $perl_info  = qx(ps $$);            # that's Perl's $$
1346     $shell_info = qx'ps $$';            # that's the new shell's $$
1347
1348 How that string gets evaluated is entirely subject to the command
1349 interpreter on your system.  On most platforms, you will have to protect
1350 shell metacharacters if you want them treated literally.  This is in
1351 practice difficult to do, as it's unclear how to escape which characters.
1352 See L<perlsec> for a clean and safe example of a manual fork() and exec()
1353 to emulate backticks safely.
1354
1355 On some platforms (notably DOS-like ones), the shell may not be
1356 capable of dealing with multiline commands, so putting newlines in
1357 the string may not get you what you want.  You may be able to evaluate
1358 multiple commands in a single line by separating them with the command
1359 separator character, if your shell supports that (e.g. C<;> on many Unix
1360 shells; C<&> on the Windows NT C<cmd> shell).
1361
1362 Beginning with v5.6.0, Perl will attempt to flush all files opened for
1363 output before starting the child process, but this may not be supported
1364 on some platforms (see L<perlport>).  To be safe, you may need to set
1365 C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method of
1366 C<IO::Handle> on any open handles.
1367
1368 Beware that some command shells may place restrictions on the length
1369 of the command line.  You must ensure your strings don't exceed this
1370 limit after any necessary interpolations.  See the platform-specific
1371 release notes for more details about your particular environment.
1372
1373 Using this operator can lead to programs that are difficult to port,
1374 because the shell commands called vary between systems, and may in
1375 fact not be present at all.  As one example, the C<type> command under
1376 the POSIX shell is very different from the C<type> command under DOS.
1377 That doesn't mean you should go out of your way to avoid backticks
1378 when they're the right way to get something done.  Perl was made to be
1379 a glue language, and one of the things it glues together is commands.
1380 Just understand what you're getting yourself into.
1381
1382 See L<"I/O Operators"> for more discussion.
1383
1384 =item qw/STRING/
1385 X<qw> X<quote, list> X<quote, words>
1386
1387 Evaluates to a list of the words extracted out of STRING, using embedded
1388 whitespace as the word delimiters.  It can be understood as being roughly
1389 equivalent to:
1390
1391     split(' ', q/STRING/);
1392
1393 the differences being that it generates a real list at compile time, and
1394 in scalar context it returns the last element in the list.  So
1395 this expression:
1396
1397     qw(foo bar baz)
1398
1399 is semantically equivalent to the list:
1400
1401     'foo', 'bar', 'baz'
1402
1403 Some frequently seen examples:
1404
1405     use POSIX qw( setlocale localeconv )
1406     @EXPORT = qw( foo bar baz );
1407
1408 A common mistake is to try to separate the words with comma or to
1409 put comments into a multi-line C<qw>-string.  For this reason, the
1410 C<use warnings> pragma and the B<-w> switch (that is, the C<$^W> variable) 
1411 produces warnings if the STRING contains the "," or the "#" character.
1412
1413 =item s/PATTERN/REPLACEMENT/egimosx
1414 X<substitute> X<substitution> X<replace> X<regexp, replace>
1415 X<regexp, substitute> X</e> X</g> X</i> X</m> X</o> X</s> X</x>
1416
1417 Searches a string for a pattern, and if found, replaces that pattern
1418 with the replacement text and returns the number of substitutions
1419 made.  Otherwise it returns false (specifically, the empty string).
1420
1421 If no string is specified via the C<=~> or C<!~> operator, the C<$_>
1422 variable is searched and modified.  (The string specified with C<=~> must
1423 be scalar variable, an array element, a hash element, or an assignment
1424 to one of those, i.e., an lvalue.)
1425
1426 If the delimiter chosen is a single quote, no interpolation is
1427 done on either the PATTERN or the REPLACEMENT.  Otherwise, if the
1428 PATTERN contains a $ that looks like a variable rather than an
1429 end-of-string test, the variable will be interpolated into the pattern
1430 at run-time.  If you want the pattern compiled only once the first time
1431 the variable is interpolated, use the C</o> option.  If the pattern
1432 evaluates to the empty string, the last successfully executed regular
1433 expression is used instead.  See L<perlre> for further explanation on these.
1434 See L<perllocale> for discussion of additional considerations that apply
1435 when C<use locale> is in effect.
1436
1437 Options are:
1438
1439     e   Evaluate the right side as an expression.
1440     g   Replace globally, i.e., all occurrences.
1441     i   Do case-insensitive pattern matching.
1442     m   Treat string as multiple lines.
1443     o   Compile pattern only once.
1444     s   Treat string as single line.
1445     x   Use extended regular expressions.
1446
1447 Any non-alphanumeric, non-whitespace delimiter may replace the
1448 slashes.  If single quotes are used, no interpretation is done on the
1449 replacement string (the C</e> modifier overrides this, however).  Unlike
1450 Perl 4, Perl 5 treats backticks as normal delimiters; the replacement
1451 text is not evaluated as a command.  If the
1452 PATTERN is delimited by bracketing quotes, the REPLACEMENT has its own
1453 pair of quotes, which may or may not be bracketing quotes, e.g.,
1454 C<s(foo)(bar)> or C<< s<foo>/bar/ >>.  A C</e> will cause the
1455 replacement portion to be treated as a full-fledged Perl expression
1456 and evaluated right then and there.  It is, however, syntax checked at
1457 compile-time. A second C<e> modifier will cause the replacement portion
1458 to be C<eval>ed before being run as a Perl expression.
1459
1460 Examples:
1461
1462     s/\bgreen\b/mauve/g;                # don't change wintergreen
1463
1464     $path =~ s|/usr/bin|/usr/local/bin|;
1465
1466     s/Login: $foo/Login: $bar/; # run-time pattern
1467
1468     ($foo = $bar) =~ s/this/that/;      # copy first, then change
1469
1470     $count = ($paragraph =~ s/Mister\b/Mr./g);  # get change-count
1471
1472     $_ = 'abc123xyz';
1473     s/\d+/$&*2/e;               # yields 'abc246xyz'
1474     s/\d+/sprintf("%5d",$&)/e;  # yields 'abc  246xyz'
1475     s/\w/$& x 2/eg;             # yields 'aabbcc  224466xxyyzz'
1476
1477     s/%(.)/$percent{$1}/g;      # change percent escapes; no /e
1478     s/%(.)/$percent{$1} || $&/ge;       # expr now, so /e
1479     s/^=(\w+)/&pod($1)/ge;      # use function call
1480
1481     # expand variables in $_, but dynamics only, using
1482     # symbolic dereferencing
1483     s/\$(\w+)/${$1}/g;
1484
1485     # Add one to the value of any numbers in the string
1486     s/(\d+)/1 + $1/eg;
1487
1488     # This will expand any embedded scalar variable
1489     # (including lexicals) in $_ : First $1 is interpolated
1490     # to the variable name, and then evaluated
1491     s/(\$\w+)/$1/eeg;
1492
1493     # Delete (most) C comments.
1494     $program =~ s {
1495         /\*     # Match the opening delimiter.
1496         .*?     # Match a minimal number of characters.
1497         \*/     # Match the closing delimiter.
1498     } []gsx;
1499
1500     s/^\s*(.*?)\s*$/$1/;        # trim whitespace in $_, expensively
1501
1502     for ($variable) {           # trim whitespace in $variable, cheap
1503         s/^\s+//;
1504         s/\s+$//;
1505     }
1506
1507     s/([^ ]*) *([^ ]*)/$2 $1/;  # reverse 1st two fields
1508
1509 Note the use of $ instead of \ in the last example.  Unlike
1510 B<sed>, we use the \<I<digit>> form in only the left hand side.
1511 Anywhere else it's $<I<digit>>.
1512
1513 Occasionally, you can't use just a C</g> to get all the changes
1514 to occur that you might want.  Here are two common cases:
1515
1516     # put commas in the right places in an integer
1517     1 while s/(\d)(\d\d\d)(?!\d)/$1,$2/g;  
1518
1519     # expand tabs to 8-column spacing
1520     1 while s/\t+/' ' x (length($&)*8 - length($`)%8)/e;
1521
1522 =item tr/SEARCHLIST/REPLACEMENTLIST/cds
1523 X<tr> X<y> X<transliterate> X</c> X</d> X</s>
1524
1525 =item y/SEARCHLIST/REPLACEMENTLIST/cds
1526
1527 Transliterates all occurrences of the characters found in the search list
1528 with the corresponding character in the replacement list.  It returns
1529 the number of characters replaced or deleted.  If no string is
1530 specified via the =~ or !~ operator, the $_ string is transliterated.  (The
1531 string specified with =~ must be a scalar variable, an array element, a
1532 hash element, or an assignment to one of those, i.e., an lvalue.)
1533
1534 A character range may be specified with a hyphen, so C<tr/A-J/0-9/> 
1535 does the same replacement as C<tr/ACEGIBDFHJ/0246813579/>.
1536 For B<sed> devotees, C<y> is provided as a synonym for C<tr>.  If the
1537 SEARCHLIST is delimited by bracketing quotes, the REPLACEMENTLIST has
1538 its own pair of quotes, which may or may not be bracketing quotes,
1539 e.g., C<tr[A-Z][a-z]> or C<tr(+\-*/)/ABCD/>.
1540
1541 Note that C<tr> does B<not> do regular expression character classes
1542 such as C<\d> or C<[:lower:]>.  The <tr> operator is not equivalent to
1543 the tr(1) utility.  If you want to map strings between lower/upper
1544 cases, see L<perlfunc/lc> and L<perlfunc/uc>, and in general consider
1545 using the C<s> operator if you need regular expressions.
1546
1547 Note also that the whole range idea is rather unportable between
1548 character sets--and even within character sets they may cause results
1549 you probably didn't expect.  A sound principle is to use only ranges
1550 that begin from and end at either alphabets of equal case (a-e, A-E),
1551 or digits (0-4).  Anything else is unsafe.  If in doubt, spell out the
1552 character sets in full.
1553
1554 Options:
1555
1556     c   Complement the SEARCHLIST.
1557     d   Delete found but unreplaced characters.
1558     s   Squash duplicate replaced characters.
1559
1560 If the C</c> modifier is specified, the SEARCHLIST character set
1561 is complemented.  If the C</d> modifier is specified, any characters
1562 specified by SEARCHLIST not found in REPLACEMENTLIST are deleted.
1563 (Note that this is slightly more flexible than the behavior of some
1564 B<tr> programs, which delete anything they find in the SEARCHLIST,
1565 period.) If the C</s> modifier is specified, sequences of characters
1566 that were transliterated to the same character are squashed down
1567 to a single instance of the character.
1568
1569 If the C</d> modifier is used, the REPLACEMENTLIST is always interpreted
1570 exactly as specified.  Otherwise, if the REPLACEMENTLIST is shorter
1571 than the SEARCHLIST, the final character is replicated till it is long
1572 enough.  If the REPLACEMENTLIST is empty, the SEARCHLIST is replicated.
1573 This latter is useful for counting characters in a class or for
1574 squashing character sequences in a class.
1575
1576 Examples:
1577
1578     $ARGV[1] =~ tr/A-Z/a-z/;    # canonicalize to lower case
1579
1580     $cnt = tr/*/*/;             # count the stars in $_
1581
1582     $cnt = $sky =~ tr/*/*/;     # count the stars in $sky
1583
1584     $cnt = tr/0-9//;            # count the digits in $_
1585
1586     tr/a-zA-Z//s;               # bookkeeper -> bokeper
1587
1588     ($HOST = $host) =~ tr/a-z/A-Z/;
1589
1590     tr/a-zA-Z/ /cs;             # change non-alphas to single space
1591
1592     tr [\200-\377]
1593        [\000-\177];             # delete 8th bit
1594
1595 If multiple transliterations are given for a character, only the
1596 first one is used:
1597
1598     tr/AAA/XYZ/
1599
1600 will transliterate any A to X.
1601
1602 Because the transliteration table is built at compile time, neither
1603 the SEARCHLIST nor the REPLACEMENTLIST are subjected to double quote
1604 interpolation.  That means that if you want to use variables, you
1605 must use an eval():
1606
1607     eval "tr/$oldlist/$newlist/";
1608     die $@ if $@;
1609
1610     eval "tr/$oldlist/$newlist/, 1" or die $@;
1611
1612 =item <<EOF
1613 X<here-doc> X<heredoc> X<here-document> X<<< << >>>
1614
1615 A line-oriented form of quoting is based on the shell "here-document"
1616 syntax.  Following a C<< << >> you specify a string to terminate
1617 the quoted material, and all lines following the current line down to
1618 the terminating string are the value of the item.  The terminating
1619 string may be either an identifier (a word), or some quoted text.  If
1620 quoted, the type of quotes you use determines the treatment of the
1621 text, just as in regular quoting.  An unquoted identifier works like
1622 double quotes.  There must be no space between the C<< << >> and
1623 the identifier, unless the identifier is quoted.  (If you put a space it
1624 will be treated as a null identifier, which is valid, and matches the first
1625 empty line.)  The terminating string must appear by itself (unquoted and
1626 with no surrounding whitespace) on the terminating line.
1627
1628        print <<EOF;
1629     The price is $Price.
1630     EOF
1631
1632        print << "EOF"; # same as above
1633     The price is $Price.
1634     EOF
1635
1636        print << `EOC`; # execute commands
1637     echo hi there
1638     echo lo there
1639     EOC
1640
1641        print <<"foo", <<"bar"; # you can stack them
1642     I said foo.
1643     foo
1644     I said bar.
1645     bar
1646
1647        myfunc(<< "THIS", 23, <<'THAT');
1648     Here's a line
1649     or two.
1650     THIS
1651     and here's another.
1652     THAT
1653
1654 Just don't forget that you have to put a semicolon on the end
1655 to finish the statement, as Perl doesn't know you're not going to
1656 try to do this:
1657
1658        print <<ABC
1659     179231
1660     ABC
1661        + 20;
1662
1663 If you want your here-docs to be indented with the 
1664 rest of the code, you'll need to remove leading whitespace
1665 from each line manually:
1666
1667     ($quote = <<'FINIS') =~ s/^\s+//gm;
1668        The Road goes ever on and on, 
1669        down from the door where it began.
1670     FINIS
1671
1672 If you use a here-doc within a delimited construct, such as in C<s///eg>,
1673 the quoted material must come on the lines following the final delimiter.
1674 So instead of
1675
1676     s/this/<<E . 'that'
1677     the other
1678     E
1679      . 'more '/eg;
1680
1681 you have to write
1682
1683     s/this/<<E . 'that' 
1684      . 'more '/eg; 
1685     the other 
1686     E 
1687
1688 If the terminating identifier is on the last line of the program, you
1689 must be sure there is a newline after it; otherwise, Perl will give the
1690 warning B<Can't find string terminator "END" anywhere before EOF...>.
1691
1692 Additionally, the quoting rules for the identifier are not related to
1693 Perl's quoting rules -- C<q()>, C<qq()>, and the like are not supported
1694 in place of C<''> and C<"">, and the only interpolation is for backslashing
1695 the quoting character:
1696
1697     print << "abc\"def";
1698     testing...
1699     abc"def
1700
1701 Finally, quoted strings cannot span multiple lines.  The general rule is
1702 that the identifier must be a string literal.  Stick with that, and you
1703 should be safe.
1704
1705 =back
1706
1707 =head2 Gory details of parsing quoted constructs
1708 X<quote, gory details>
1709
1710 When presented with something that might have several different
1711 interpretations, Perl uses the B<DWIM> (that's "Do What I Mean")
1712 principle to pick the most probable interpretation.  This strategy
1713 is so successful that Perl programmers often do not suspect the
1714 ambivalence of what they write.  But from time to time, Perl's
1715 notions differ substantially from what the author honestly meant.
1716
1717 This section hopes to clarify how Perl handles quoted constructs.
1718 Although the most common reason to learn this is to unravel labyrinthine
1719 regular expressions, because the initial steps of parsing are the
1720 same for all quoting operators, they are all discussed together.
1721
1722 The most important Perl parsing rule is the first one discussed
1723 below: when processing a quoted construct, Perl first finds the end
1724 of that construct, then interprets its contents.  If you understand
1725 this rule, you may skip the rest of this section on the first
1726 reading.  The other rules are likely to contradict the user's
1727 expectations much less frequently than this first one.
1728
1729 Some passes discussed below are performed concurrently, but because
1730 their results are the same, we consider them individually.  For different
1731 quoting constructs, Perl performs different numbers of passes, from
1732 one to five, but these passes are always performed in the same order.
1733
1734 =over 4
1735
1736 =item Finding the end
1737
1738 The first pass is finding the end of the quoted construct, whether
1739 it be a multicharacter delimiter C<"\nEOF\n"> in the C<<<EOF>
1740 construct, a C</> that terminates a C<qq//> construct, a C<]> which
1741 terminates C<qq[]> construct, or a C<< > >> which terminates a
1742 fileglob started with C<< < >>.
1743
1744 When searching for single-character non-pairing delimiters, such
1745 as C</>, combinations of C<\\> and C<\/> are skipped.  However,
1746 when searching for single-character pairing delimiter like C<[>,
1747 combinations of C<\\>, C<\]>, and C<\[> are all skipped, and nested
1748 C<[>, C<]> are skipped as well.  When searching for multicharacter
1749 delimiters, nothing is skipped.
1750
1751 For constructs with three-part delimiters (C<s///>, C<y///>, and
1752 C<tr///>), the search is repeated once more.
1753
1754 During this search no attention is paid to the semantics of the construct.
1755 Thus:
1756
1757     "$hash{"$foo/$bar"}"
1758
1759 or:
1760
1761     m/ 
1762       bar       # NOT a comment, this slash / terminated m//!
1763      /x
1764
1765 do not form legal quoted expressions.   The quoted part ends on the
1766 first C<"> and C</>, and the rest happens to be a syntax error.
1767 Because the slash that terminated C<m//> was followed by a C<SPACE>,
1768 the example above is not C<m//x>, but rather C<m//> with no C</x>
1769 modifier.  So the embedded C<#> is interpreted as a literal C<#>.
1770
1771 Also no attention is paid to C<\c\> during this search.
1772 Thus the second C<\> in C<qq/\c\/> is interpreted as a part of C<\/>,
1773 and the following C</> is not recognized as a delimiter.
1774 Instead, use C<\034> or C<\x1c> at the end of quoted constructs.
1775
1776 =item Removal of backslashes before delimiters
1777
1778 During the second pass, text between the starting and ending
1779 delimiters is copied to a safe location, and the C<\> is removed
1780 from combinations consisting of C<\> and delimiter--or delimiters,
1781 meaning both starting and ending delimiters will should these differ.
1782 This removal does not happen for multi-character delimiters.
1783 Note that the combination C<\\> is left intact, just as it was.
1784
1785 Starting from this step no information about the delimiters is
1786 used in parsing.
1787
1788 =item Interpolation
1789 X<interpolation>
1790
1791 The next step is interpolation in the text obtained, which is now
1792 delimiter-independent.  There are four different cases.
1793
1794 =over 4
1795
1796 =item C<<<'EOF'>, C<m''>, C<s'''>, C<tr///>, C<y///>
1797
1798 No interpolation is performed.
1799
1800 =item C<''>, C<q//>
1801
1802 The only interpolation is removal of C<\> from pairs C<\\>.
1803
1804 =item C<"">, C<``>, C<qq//>, C<qx//>, C<< <file*glob> >>
1805
1806 C<\Q>, C<\U>, C<\u>, C<\L>, C<\l> (possibly paired with C<\E>) are
1807 converted to corresponding Perl constructs.  Thus, C<"$foo\Qbaz$bar">
1808 is converted to C<$foo . (quotemeta("baz" . $bar))> internally.
1809 The other combinations are replaced with appropriate expansions.
1810
1811 Let it be stressed that I<whatever falls between C<\Q> and C<\E>>
1812 is interpolated in the usual way.  Something like C<"\Q\\E"> has
1813 no C<\E> inside.  instead, it has C<\Q>, C<\\>, and C<E>, so the
1814 result is the same as for C<"\\\\E">.  As a general rule, backslashes
1815 between C<\Q> and C<\E> may lead to counterintuitive results.  So,
1816 C<"\Q\t\E"> is converted to C<quotemeta("\t")>, which is the same
1817 as C<"\\\t"> (since TAB is not alphanumeric).  Note also that:
1818
1819   $str = '\t';
1820   return "\Q$str";
1821
1822 may be closer to the conjectural I<intention> of the writer of C<"\Q\t\E">.
1823
1824 Interpolated scalars and arrays are converted internally to the C<join> and
1825 C<.> catenation operations.  Thus, C<"$foo XXX '@arr'"> becomes:
1826
1827   $foo . " XXX '" . (join $", @arr) . "'";
1828
1829 All operations above are performed simultaneously, left to right.
1830
1831 Because the result of C<"\Q STRING \E"> has all metacharacters
1832 quoted, there is no way to insert a literal C<$> or C<@> inside a
1833 C<\Q\E> pair.  If protected by C<\>, C<$> will be quoted to became
1834 C<"\\\$">; if not, it is interpreted as the start of an interpolated
1835 scalar.
1836
1837 Note also that the interpolation code needs to make a decision on
1838 where the interpolated scalar ends.  For instance, whether 
1839 C<< "a $b -> {c}" >> really means:
1840
1841   "a " . $b . " -> {c}";
1842
1843 or:
1844
1845   "a " . $b -> {c};
1846
1847 Most of the time, the longest possible text that does not include
1848 spaces between components and which contains matching braces or
1849 brackets.  because the outcome may be determined by voting based
1850 on heuristic estimators, the result is not strictly predictable.
1851 Fortunately, it's usually correct for ambiguous cases.
1852
1853 =item C<?RE?>, C</RE/>, C<m/RE/>, C<s/RE/foo/>, 
1854
1855 Processing of C<\Q>, C<\U>, C<\u>, C<\L>, C<\l>, and interpolation
1856 happens (almost) as with C<qq//> constructs, but the substitution
1857 of C<\> followed by RE-special chars (including C<\>) is not
1858 performed.  Moreover, inside C<(?{BLOCK})>, C<(?# comment )>, and
1859 a C<#>-comment in a C<//x>-regular expression, no processing is
1860 performed whatsoever.  This is the first step at which the presence
1861 of the C<//x> modifier is relevant.
1862
1863 Interpolation has several quirks: C<$|>, C<$(>, and C<$)> are not
1864 interpolated, and constructs C<$var[SOMETHING]> are voted (by several
1865 different estimators) to be either an array element or C<$var>
1866 followed by an RE alternative.  This is where the notation
1867 C<${arr[$bar]}> comes handy: C</${arr[0-9]}/> is interpreted as
1868 array element C<-9>, not as a regular expression from the variable
1869 C<$arr> followed by a digit, which would be the interpretation of
1870 C</$arr[0-9]/>.  Since voting among different estimators may occur,
1871 the result is not predictable.
1872
1873 It is at this step that C<\1> is begrudgingly converted to C<$1> in
1874 the replacement text of C<s///> to correct the incorrigible
1875 I<sed> hackers who haven't picked up the saner idiom yet.  A warning
1876 is emitted if the C<use warnings> pragma or the B<-w> command-line flag
1877 (that is, the C<$^W> variable) was set.
1878
1879 The lack of processing of C<\\> creates specific restrictions on
1880 the post-processed text.  If the delimiter is C</>, one cannot get
1881 the combination C<\/> into the result of this step.  C</> will
1882 finish the regular expression, C<\/> will be stripped to C</> on
1883 the previous step, and C<\\/> will be left as is.  Because C</> is
1884 equivalent to C<\/> inside a regular expression, this does not
1885 matter unless the delimiter happens to be character special to the
1886 RE engine, such as in C<s*foo*bar*>, C<m[foo]>, or C<?foo?>; or an
1887 alphanumeric char, as in:
1888
1889   m m ^ a \s* b mmx;
1890
1891 In the RE above, which is intentionally obfuscated for illustration, the
1892 delimiter is C<m>, the modifier is C<mx>, and after backslash-removal the
1893 RE is the same as for C<m/ ^ a \s* b /mx>.  There's more than one 
1894 reason you're encouraged to restrict your delimiters to non-alphanumeric,
1895 non-whitespace choices.
1896
1897 =back
1898
1899 This step is the last one for all constructs except regular expressions,
1900 which are processed further.
1901
1902 =item Interpolation of regular expressions
1903 X<regexp, interpolation>
1904
1905 Previous steps were performed during the compilation of Perl code,
1906 but this one happens at run time--although it may be optimized to
1907 be calculated at compile time if appropriate.  After preprocessing
1908 described above, and possibly after evaluation if catenation,
1909 joining, casing translation, or metaquoting are involved, the
1910 resulting I<string> is passed to the RE engine for compilation.
1911
1912 Whatever happens in the RE engine might be better discussed in L<perlre>,
1913 but for the sake of continuity, we shall do so here.
1914
1915 This is another step where the presence of the C<//x> modifier is
1916 relevant.  The RE engine scans the string from left to right and
1917 converts it to a finite automaton.
1918
1919 Backslashed characters are either replaced with corresponding
1920 literal strings (as with C<\{>), or else they generate special nodes
1921 in the finite automaton (as with C<\b>).  Characters special to the
1922 RE engine (such as C<|>) generate corresponding nodes or groups of
1923 nodes.  C<(?#...)> comments are ignored.  All the rest is either
1924 converted to literal strings to match, or else is ignored (as is
1925 whitespace and C<#>-style comments if C<//x> is present).
1926
1927 Parsing of the bracketed character class construct, C<[...]>, is
1928 rather different than the rule used for the rest of the pattern.
1929 The terminator of this construct is found using the same rules as
1930 for finding the terminator of a C<{}>-delimited construct, the only
1931 exception being that C<]> immediately following C<[> is treated as
1932 though preceded by a backslash.  Similarly, the terminator of
1933 C<(?{...})> is found using the same rules as for finding the
1934 terminator of a C<{}>-delimited construct.
1935
1936 It is possible to inspect both the string given to RE engine and the
1937 resulting finite automaton.  See the arguments C<debug>/C<debugcolor>
1938 in the C<use L<re>> pragma, as well as Perl's B<-Dr> command-line
1939 switch documented in L<perlrun/"Command Switches">.
1940
1941 =item Optimization of regular expressions
1942 X<regexp, optimization>
1943
1944 This step is listed for completeness only.  Since it does not change
1945 semantics, details of this step are not documented and are subject
1946 to change without notice.  This step is performed over the finite
1947 automaton that was generated during the previous pass.
1948
1949 It is at this stage that C<split()> silently optimizes C</^/> to
1950 mean C</^/m>.
1951
1952 =back
1953
1954 =head2 I/O Operators
1955 X<operator, i/o> X<operator, io> X<io> X<while> X<filehandle>
1956 X<< <> >> X<@ARGV>
1957
1958 There are several I/O operators you should know about.
1959
1960 A string enclosed by backticks (grave accents) first undergoes
1961 double-quote interpolation.  It is then interpreted as an external
1962 command, and the output of that command is the value of the
1963 backtick string, like in a shell.  In scalar context, a single string
1964 consisting of all output is returned.  In list context, a list of
1965 values is returned, one per line of output.  (You can set C<$/> to use
1966 a different line terminator.)  The command is executed each time the
1967 pseudo-literal is evaluated.  The status value of the command is
1968 returned in C<$?> (see L<perlvar> for the interpretation of C<$?>).
1969 Unlike in B<csh>, no translation is done on the return data--newlines
1970 remain newlines.  Unlike in any of the shells, single quotes do not
1971 hide variable names in the command from interpretation.  To pass a
1972 literal dollar-sign through to the shell you need to hide it with a
1973 backslash.  The generalized form of backticks is C<qx//>.  (Because
1974 backticks always undergo shell expansion as well, see L<perlsec> for
1975 security concerns.)
1976 X<qx> X<`> X<``> X<backtick> X<glob>
1977
1978 In scalar context, evaluating a filehandle in angle brackets yields
1979 the next line from that file (the newline, if any, included), or
1980 C<undef> at end-of-file or on error.  When C<$/> is set to C<undef>
1981 (sometimes known as file-slurp mode) and the file is empty, it
1982 returns C<''> the first time, followed by C<undef> subsequently.
1983
1984 Ordinarily you must assign the returned value to a variable, but
1985 there is one situation where an automatic assignment happens.  If
1986 and only if the input symbol is the only thing inside the conditional
1987 of a C<while> statement (even if disguised as a C<for(;;)> loop),
1988 the value is automatically assigned to the global variable $_,
1989 destroying whatever was there previously.  (This may seem like an
1990 odd thing to you, but you'll use the construct in almost every Perl
1991 script you write.)  The $_ variable is not implicitly localized.
1992 You'll have to put a C<local $_;> before the loop if you want that
1993 to happen.
1994
1995 The following lines are equivalent:
1996
1997     while (defined($_ = <STDIN>)) { print; }
1998     while ($_ = <STDIN>) { print; }
1999     while (<STDIN>) { print; }
2000     for (;<STDIN>;) { print; }
2001     print while defined($_ = <STDIN>);
2002     print while ($_ = <STDIN>);
2003     print while <STDIN>;
2004
2005 This also behaves similarly, but avoids $_ :
2006
2007     while (my $line = <STDIN>) { print $line }    
2008
2009 In these loop constructs, the assigned value (whether assignment
2010 is automatic or explicit) is then tested to see whether it is
2011 defined.  The defined test avoids problems where line has a string
2012 value that would be treated as false by Perl, for example a "" or
2013 a "0" with no trailing newline.  If you really mean for such values
2014 to terminate the loop, they should be tested for explicitly:
2015
2016     while (($_ = <STDIN>) ne '0') { ... }
2017     while (<STDIN>) { last unless $_; ... }
2018
2019 In other boolean contexts, C<< <I<filehandle>> >> without an
2020 explicit C<defined> test or comparison elicit a warning if the 
2021 C<use warnings> pragma or the B<-w>
2022 command-line switch (the C<$^W> variable) is in effect.
2023
2024 The filehandles STDIN, STDOUT, and STDERR are predefined.  (The
2025 filehandles C<stdin>, C<stdout>, and C<stderr> will also work except
2026 in packages, where they would be interpreted as local identifiers
2027 rather than global.)  Additional filehandles may be created with
2028 the open() function, amongst others.  See L<perlopentut> and
2029 L<perlfunc/open> for details on this.
2030 X<stdin> X<stdout> X<sterr>
2031
2032 If a <FILEHANDLE> is used in a context that is looking for
2033 a list, a list comprising all input lines is returned, one line per
2034 list element.  It's easy to grow to a rather large data space this
2035 way, so use with care.
2036
2037 <FILEHANDLE> may also be spelled C<readline(*FILEHANDLE)>.
2038 See L<perlfunc/readline>.
2039
2040 The null filehandle <> is special: it can be used to emulate the
2041 behavior of B<sed> and B<awk>.  Input from <> comes either from
2042 standard input, or from each file listed on the command line.  Here's
2043 how it works: the first time <> is evaluated, the @ARGV array is
2044 checked, and if it is empty, C<$ARGV[0]> is set to "-", which when opened
2045 gives you standard input.  The @ARGV array is then processed as a list
2046 of filenames.  The loop
2047
2048     while (<>) {
2049         ...                     # code for each line
2050     }
2051
2052 is equivalent to the following Perl-like pseudo code:
2053
2054     unshift(@ARGV, '-') unless @ARGV;
2055     while ($ARGV = shift) {
2056         open(ARGV, $ARGV);
2057         while (<ARGV>) {
2058             ...         # code for each line
2059         }
2060     }
2061
2062 except that it isn't so cumbersome to say, and will actually work.
2063 It really does shift the @ARGV array and put the current filename
2064 into the $ARGV variable.  It also uses filehandle I<ARGV>
2065 internally--<> is just a synonym for <ARGV>, which
2066 is magical.  (The pseudo code above doesn't work because it treats
2067 <ARGV> as non-magical.)
2068
2069 You can modify @ARGV before the first <> as long as the array ends up
2070 containing the list of filenames you really want.  Line numbers (C<$.>)
2071 continue as though the input were one big happy file.  See the example
2072 in L<perlfunc/eof> for how to reset line numbers on each file.
2073
2074 If you want to set @ARGV to your own list of files, go right ahead.  
2075 This sets @ARGV to all plain text files if no @ARGV was given:
2076
2077     @ARGV = grep { -f && -T } glob('*') unless @ARGV;
2078
2079 You can even set them to pipe commands.  For example, this automatically
2080 filters compressed arguments through B<gzip>:
2081
2082     @ARGV = map { /\.(gz|Z)$/ ? "gzip -dc < $_ |" : $_ } @ARGV;
2083
2084 If you want to pass switches into your script, you can use one of the
2085 Getopts modules or put a loop on the front like this:
2086
2087     while ($_ = $ARGV[0], /^-/) {
2088         shift;
2089         last if /^--$/;
2090         if (/^-D(.*)/) { $debug = $1 }
2091         if (/^-v/)     { $verbose++  }
2092         # ...           # other switches
2093     }
2094
2095     while (<>) {
2096         # ...           # code for each line
2097     }
2098
2099 The <> symbol will return C<undef> for end-of-file only once.  
2100 If you call it again after this, it will assume you are processing another 
2101 @ARGV list, and if you haven't set @ARGV, will read input from STDIN.
2102
2103 If what the angle brackets contain is a simple scalar variable (e.g.,
2104 <$foo>), then that variable contains the name of the
2105 filehandle to input from, or its typeglob, or a reference to the
2106 same.  For example:
2107
2108     $fh = \*STDIN;
2109     $line = <$fh>;
2110
2111 If what's within the angle brackets is neither a filehandle nor a simple
2112 scalar variable containing a filehandle name, typeglob, or typeglob
2113 reference, it is interpreted as a filename pattern to be globbed, and
2114 either a list of filenames or the next filename in the list is returned,
2115 depending on context.  This distinction is determined on syntactic
2116 grounds alone.  That means C<< <$x> >> is always a readline() from
2117 an indirect handle, but C<< <$hash{key}> >> is always a glob().
2118 That's because $x is a simple scalar variable, but C<$hash{key}> is
2119 not--it's a hash element.  Even C<< <$x > >> (note the extra space)
2120 is treated as C<glob("$x ")>, not C<readline($x)>.
2121
2122 One level of double-quote interpretation is done first, but you can't
2123 say C<< <$foo> >> because that's an indirect filehandle as explained
2124 in the previous paragraph.  (In older versions of Perl, programmers
2125 would insert curly brackets to force interpretation as a filename glob:
2126 C<< <${foo}> >>.  These days, it's considered cleaner to call the
2127 internal function directly as C<glob($foo)>, which is probably the right
2128 way to have done it in the first place.)  For example:
2129
2130     while (<*.c>) {
2131         chmod 0644, $_;
2132     }
2133
2134 is roughly equivalent to:
2135
2136     open(FOO, "echo *.c | tr -s ' \t\r\f' '\\012\\012\\012\\012'|");
2137     while (<FOO>) {
2138         chomp;
2139         chmod 0644, $_;
2140     }
2141
2142 except that the globbing is actually done internally using the standard
2143 C<File::Glob> extension.  Of course, the shortest way to do the above is:
2144
2145     chmod 0644, <*.c>;
2146
2147 A (file)glob evaluates its (embedded) argument only when it is
2148 starting a new list.  All values must be read before it will start
2149 over.  In list context, this isn't important because you automatically
2150 get them all anyway.  However, in scalar context the operator returns
2151 the next value each time it's called, or C<undef> when the list has
2152 run out.  As with filehandle reads, an automatic C<defined> is
2153 generated when the glob occurs in the test part of a C<while>,
2154 because legal glob returns (e.g. a file called F<0>) would otherwise
2155 terminate the loop.  Again, C<undef> is returned only once.  So if
2156 you're expecting a single value from a glob, it is much better to
2157 say
2158
2159     ($file) = <blurch*>;
2160
2161 than
2162
2163     $file = <blurch*>;
2164
2165 because the latter will alternate between returning a filename and
2166 returning false.
2167
2168 If you're trying to do variable interpolation, it's definitely better
2169 to use the glob() function, because the older notation can cause people
2170 to become confused with the indirect filehandle notation.
2171
2172     @files = glob("$dir/*.[ch]");
2173     @files = glob($files[$i]);
2174
2175 =head2 Constant Folding
2176 X<constant folding> X<folding>
2177
2178 Like C, Perl does a certain amount of expression evaluation at
2179 compile time whenever it determines that all arguments to an
2180 operator are static and have no side effects.  In particular, string
2181 concatenation happens at compile time between literals that don't do
2182 variable substitution.  Backslash interpolation also happens at
2183 compile time.  You can say
2184
2185     'Now is the time for all' . "\n" .
2186         'good men to come to.'
2187
2188 and this all reduces to one string internally.  Likewise, if
2189 you say
2190
2191     foreach $file (@filenames) {
2192         if (-s $file > 5 + 100 * 2**16) {  }
2193     }
2194
2195 the compiler will precompute the number which that expression
2196 represents so that the interpreter won't have to.
2197
2198 =head2 No-ops
2199 X<no-op> X<nop>
2200
2201 Perl doesn't officially have a no-op operator, but the bare constants
2202 C<0> and C<1> are special-cased to not produce a warning in a void
2203 context, so you can for example safely do
2204
2205     1 while foo();
2206
2207 =head2 Bitwise String Operators
2208 X<operator, bitwise, string>
2209
2210 Bitstrings of any size may be manipulated by the bitwise operators
2211 (C<~ | & ^>).
2212
2213 If the operands to a binary bitwise op are strings of different
2214 sizes, B<|> and B<^> ops act as though the shorter operand had
2215 additional zero bits on the right, while the B<&> op acts as though
2216 the longer operand were truncated to the length of the shorter.
2217 The granularity for such extension or truncation is one or more
2218 bytes.
2219
2220     # ASCII-based examples 
2221     print "j p \n" ^ " a h";            # prints "JAPH\n"
2222     print "JA" | "  ph\n";              # prints "japh\n"
2223     print "japh\nJunk" & '_____';       # prints "JAPH\n";
2224     print 'p N$' ^ " E<H\n";            # prints "Perl\n";
2225
2226 If you are intending to manipulate bitstrings, be certain that
2227 you're supplying bitstrings: If an operand is a number, that will imply
2228 a B<numeric> bitwise operation.  You may explicitly show which type of
2229 operation you intend by using C<""> or C<0+>, as in the examples below.
2230
2231     $foo =  150  |  105;        # yields 255  (0x96 | 0x69 is 0xFF)
2232     $foo = '150' |  105;        # yields 255
2233     $foo =  150  | '105';       # yields 255
2234     $foo = '150' | '105';       # yields string '155' (under ASCII)
2235
2236     $baz = 0+$foo & 0+$bar;     # both ops explicitly numeric
2237     $biz = "$foo" ^ "$bar";     # both ops explicitly stringy
2238
2239 See L<perlfunc/vec> for information on how to manipulate individual bits
2240 in a bit vector.
2241
2242 =head2 Integer Arithmetic
2243 X<integer>
2244
2245 By default, Perl assumes that it must do most of its arithmetic in
2246 floating point.  But by saying
2247
2248     use integer;
2249
2250 you may tell the compiler that it's okay to use integer operations
2251 (if it feels like it) from here to the end of the enclosing BLOCK.
2252 An inner BLOCK may countermand this by saying
2253
2254     no integer;
2255
2256 which lasts until the end of that BLOCK.  Note that this doesn't
2257 mean everything is only an integer, merely that Perl may use integer
2258 operations if it is so inclined.  For example, even under C<use
2259 integer>, if you take the C<sqrt(2)>, you'll still get C<1.4142135623731>
2260 or so.
2261
2262 Used on numbers, the bitwise operators ("&", "|", "^", "~", "<<",
2263 and ">>") always produce integral results.  (But see also 
2264 L<Bitwise String Operators>.)  However, C<use integer> still has meaning for
2265 them.  By default, their results are interpreted as unsigned integers, but
2266 if C<use integer> is in effect, their results are interpreted
2267 as signed integers.  For example, C<~0> usually evaluates to a large
2268 integral value.  However, C<use integer; ~0> is C<-1> on two's-complement
2269 machines.
2270
2271 =head2 Floating-point Arithmetic
2272 X<floating-point> X<floating point> X<float> X<real>
2273
2274 While C<use integer> provides integer-only arithmetic, there is no
2275 analogous mechanism to provide automatic rounding or truncation to a
2276 certain number of decimal places.  For rounding to a certain number
2277 of digits, sprintf() or printf() is usually the easiest route.
2278 See L<perlfaq4>.
2279
2280 Floating-point numbers are only approximations to what a mathematician
2281 would call real numbers.  There are infinitely more reals than floats,
2282 so some corners must be cut.  For example:
2283
2284     printf "%.20g\n", 123456789123456789;
2285     #        produces 123456789123456784
2286
2287 Testing for exact equality of floating-point equality or inequality is
2288 not a good idea.  Here's a (relatively expensive) work-around to compare
2289 whether two floating-point numbers are equal to a particular number of
2290 decimal places.  See Knuth, volume II, for a more robust treatment of
2291 this topic.
2292
2293     sub fp_equal {
2294         my ($X, $Y, $POINTS) = @_;
2295         my ($tX, $tY);
2296         $tX = sprintf("%.${POINTS}g", $X);
2297         $tY = sprintf("%.${POINTS}g", $Y);
2298         return $tX eq $tY;
2299     }
2300
2301 The POSIX module (part of the standard perl distribution) implements
2302 ceil(), floor(), and other mathematical and trigonometric functions.
2303 The Math::Complex module (part of the standard perl distribution)
2304 defines mathematical functions that work on both the reals and the
2305 imaginary numbers.  Math::Complex not as efficient as POSIX, but
2306 POSIX can't work with complex numbers.
2307
2308 Rounding in financial applications can have serious implications, and
2309 the rounding method used should be specified precisely.  In these
2310 cases, it probably pays not to trust whichever system rounding is
2311 being used by Perl, but to instead implement the rounding function you
2312 need yourself.
2313
2314 =head2 Bigger Numbers
2315 X<number, arbitrary precision>
2316
2317 The standard Math::BigInt and Math::BigFloat modules provide
2318 variable-precision arithmetic and overloaded operators, although
2319 they're currently pretty slow. At the cost of some space and
2320 considerable speed, they avoid the normal pitfalls associated with
2321 limited-precision representations.
2322
2323     use Math::BigInt;
2324     $x = Math::BigInt->new('123456789123456789');
2325     print $x * $x;
2326
2327     # prints +15241578780673678515622620750190521
2328
2329 There are several modules that let you calculate with (bound only by
2330 memory and cpu-time) unlimited or fixed precision. There are also
2331 some non-standard modules that provide faster implementations via
2332 external C libraries.
2333
2334 Here is a short, but incomplete summary:
2335
2336         Math::Fraction          big, unlimited fractions like 9973 / 12967
2337         Math::String            treat string sequences like numbers
2338         Math::FixedPrecision    calculate with a fixed precision
2339         Math::Currency          for currency calculations
2340         Bit::Vector             manipulate bit vectors fast (uses C)
2341         Math::BigIntFast        Bit::Vector wrapper for big numbers
2342         Math::Pari              provides access to the Pari C library
2343         Math::BigInteger        uses an external C library
2344         Math::Cephes            uses external Cephes C library (no big numbers)
2345         Math::Cephes::Fraction  fractions via the Cephes library
2346         Math::GMP               another one using an external C library
2347
2348 Choose wisely.
2349
2350 =cut