Hash::Util tests should check if Hash::Util has been built, not
[perl.git] / pod / perlfunc.pod
1 =head1 NAME
2 X<function>
3
4 perlfunc - Perl builtin functions
5
6 =head1 DESCRIPTION
7
8 The functions in this section can serve as terms in an expression.
9 They fall into two major categories: list operators and named unary
10 operators.  These differ in their precedence relationship with a
11 following comma.  (See the precedence table in L<perlop>.)  List
12 operators take more than one argument, while unary operators can never
13 take more than one argument.  Thus, a comma terminates the argument of
14 a unary operator, but merely separates the arguments of a list
15 operator.  A unary operator generally provides a scalar context to its
16 argument, while a list operator may provide either scalar or list
17 contexts for its arguments.  If it does both, the scalar arguments will
18 be first, and the list argument will follow.  (Note that there can ever
19 be only one such list argument.)  For instance, splice() has three scalar
20 arguments followed by a list, whereas gethostbyname() has four scalar
21 arguments.
22
23 In the syntax descriptions that follow, list operators that expect a
24 list (and provide list context for the elements of the list) are shown
25 with LIST as an argument.  Such a list may consist of any combination
26 of scalar arguments or list values; the list values will be included
27 in the list as if each individual element were interpolated at that
28 point in the list, forming a longer single-dimensional list value.
29 Commas should separate elements of the LIST.
30
31 Any function in the list below may be used either with or without
32 parentheses around its arguments.  (The syntax descriptions omit the
33 parentheses.)  If you use the parentheses, the simple (but occasionally
34 surprising) rule is this: It I<looks> like a function, therefore it I<is> a
35 function, and precedence doesn't matter.  Otherwise it's a list
36 operator or unary operator, and precedence does matter.  And whitespace
37 between the function and left parenthesis doesn't count--so you need to
38 be careful sometimes:
39
40     print 1+2+4;        # Prints 7.
41     print(1+2) + 4;     # Prints 3.
42     print (1+2)+4;      # Also prints 3!
43     print +(1+2)+4;     # Prints 7.
44     print ((1+2)+4);    # Prints 7.
45
46 If you run Perl with the B<-w> switch it can warn you about this.  For
47 example, the third line above produces:
48
49     print (...) interpreted as function at - line 1.
50     Useless use of integer addition in void context at - line 1.
51
52 A few functions take no arguments at all, and therefore work as neither
53 unary nor list operators.  These include such functions as C<time>
54 and C<endpwent>.  For example, C<time+86_400> always means
55 C<time() + 86_400>.
56
57 For functions that can be used in either a scalar or list context,
58 nonabortive failure is generally indicated in a scalar context by
59 returning the undefined value, and in a list context by returning the
60 null list.
61
62 Remember the following important rule: There is B<no rule> that relates
63 the behavior of an expression in list context to its behavior in scalar
64 context, or vice versa.  It might do two totally different things.
65 Each operator and function decides which sort of value it would be most
66 appropriate to return in scalar context.  Some operators return the
67 length of the list that would have been returned in list context.  Some
68 operators return the first value in the list.  Some operators return the
69 last value in the list.  Some operators return a count of successful
70 operations.  In general, they do what you want, unless you want
71 consistency.
72 X<context>
73
74 A named array in scalar context is quite different from what would at
75 first glance appear to be a list in scalar context.  You can't get a list
76 like C<(1,2,3)> into being in scalar context, because the compiler knows
77 the context at compile time.  It would generate the scalar comma operator
78 there, not the list construction version of the comma.  That means it
79 was never a list to start with.
80
81 In general, functions in Perl that serve as wrappers for system calls
82 of the same name (like chown(2), fork(2), closedir(2), etc.) all return
83 true when they succeed and C<undef> otherwise, as is usually mentioned
84 in the descriptions below.  This is different from the C interfaces,
85 which return C<-1> on failure.  Exceptions to this rule are C<wait>,
86 C<waitpid>, and C<syscall>.  System calls also set the special C<$!>
87 variable on failure.  Other functions do not, except accidentally.
88
89 =head2 Perl Functions by Category
90 X<function>
91
92 Here are Perl's functions (including things that look like
93 functions, like some keywords and named operators)
94 arranged by category.  Some functions appear in more
95 than one place.
96
97 =over 4
98
99 =item Functions for SCALARs or strings
100 X<scalar> X<string> X<character>
101
102 C<chomp>, C<chop>, C<chr>, C<crypt>, C<hex>, C<index>, C<lc>, C<lcfirst>,
103 C<length>, C<oct>, C<ord>, C<pack>, C<q/STRING/>, C<qq/STRING/>, C<reverse>,
104 C<rindex>, C<sprintf>, C<substr>, C<tr///>, C<uc>, C<ucfirst>, C<y///>
105
106 =item Regular expressions and pattern matching
107 X<regular expression> X<regex> X<regexp>
108
109 C<m//>, C<pos>, C<quotemeta>, C<s///>, C<split>, C<study>, C<qr//>
110
111 =item Numeric functions
112 X<numeric> X<number> X<trigonometric> X<trigonometry>
113
114 C<abs>, C<atan2>, C<cos>, C<exp>, C<hex>, C<int>, C<log>, C<oct>, C<rand>,
115 C<sin>, C<sqrt>, C<srand>
116
117 =item Functions for real @ARRAYs
118 X<array>
119
120 C<pop>, C<push>, C<shift>, C<splice>, C<unshift>
121
122 =item Functions for list data
123 X<list>
124
125 C<grep>, C<join>, C<map>, C<qw/STRING/>, C<reverse>, C<sort>, C<unpack>
126
127 =item Functions for real %HASHes
128 X<hash>
129
130 C<delete>, C<each>, C<exists>, C<keys>, C<values>
131
132 =item Input and output functions
133 X<I/O> X<input> X<output> X<dbm>
134
135 C<binmode>, C<close>, C<closedir>, C<dbmclose>, C<dbmopen>, C<die>, C<eof>,
136 C<fileno>, C<flock>, C<format>, C<getc>, C<print>, C<printf>, C<read>,
137 C<readdir>, C<rewinddir>, C<say>, C<seek>, C<seekdir>, C<select>, C<syscall>,
138 C<sysread>, C<sysseek>, C<syswrite>, C<tell>, C<telldir>, C<truncate>,
139 C<warn>, C<write>
140
141 =item Functions for fixed length data or records
142
143 C<pack>, C<read>, C<syscall>, C<sysread>, C<syswrite>, C<unpack>, C<vec>
144
145 =item Functions for filehandles, files, or directories
146 X<file> X<filehandle> X<directory> X<pipe> X<link> X<symlink>
147
148 C<-I<X>>, C<chdir>, C<chmod>, C<chown>, C<chroot>, C<fcntl>, C<glob>,
149 C<ioctl>, C<link>, C<lstat>, C<mkdir>, C<open>, C<opendir>,
150 C<readlink>, C<rename>, C<rmdir>, C<stat>, C<symlink>, C<sysopen>,
151 C<umask>, C<unlink>, C<utime>
152
153 =item Keywords related to the control flow of your Perl program
154 X<control flow>
155
156 C<caller>, C<continue>, C<die>, C<do>, C<dump>, C<eval>, C<exit>,
157 C<goto>, C<last>, C<next>, C<redo>, C<return>, C<sub>, C<wantarray>
158
159 =item Keywords related to switch
160
161 C<break>, C<continue>
162
163 (These are only available if you enable the "switch" feature.
164 See L<feature> and L<perlsyn/"Switch statements">.)
165
166 =item Keywords related to scoping
167
168 C<caller>, C<import>, C<local>, C<my>, C<our>, C<package>, C<use>
169
170 =item Miscellaneous functions
171
172 C<defined>, C<dump>, C<eval>, C<formline>, C<local>, C<my>, C<our>, C<reset>,
173 C<scalar>, C<undef>, C<wantarray>
174
175 =item Functions for processes and process groups
176 X<process> X<pid> X<process id>
177
178 C<alarm>, C<exec>, C<fork>, C<getpgrp>, C<getppid>, C<getpriority>, C<kill>,
179 C<pipe>, C<qx/STRING/>, C<setpgrp>, C<setpriority>, C<sleep>, C<system>,
180 C<times>, C<wait>, C<waitpid>
181
182 =item Keywords related to perl modules
183 X<module>
184
185 C<do>, C<import>, C<no>, C<package>, C<require>, C<use>
186
187 =item Keywords related to classes and object-orientedness
188 X<object> X<class> X<package>
189
190 C<bless>, C<dbmclose>, C<dbmopen>, C<package>, C<ref>, C<tie>, C<tied>,
191 C<untie>, C<use>
192
193 =item Low-level socket functions
194 X<socket> X<sock>
195
196 C<accept>, C<bind>, C<connect>, C<getpeername>, C<getsockname>,
197 C<getsockopt>, C<listen>, C<recv>, C<send>, C<setsockopt>, C<shutdown>,
198 C<socket>, C<socketpair>
199
200 =item System V interprocess communication functions
201 X<IPC> X<System V> X<semaphore> X<shared memory> X<memory> X<message>
202
203 C<msgctl>, C<msgget>, C<msgrcv>, C<msgsnd>, C<semctl>, C<semget>, C<semop>,
204 C<shmctl>, C<shmget>, C<shmread>, C<shmwrite>
205
206 =item Fetching user and group info
207 X<user> X<group> X<password> X<uid> X<gid>  X<passwd> X</etc/passwd>
208
209 C<endgrent>, C<endhostent>, C<endnetent>, C<endpwent>, C<getgrent>,
210 C<getgrgid>, C<getgrnam>, C<getlogin>, C<getpwent>, C<getpwnam>,
211 C<getpwuid>, C<setgrent>, C<setpwent>
212
213 =item Fetching network info
214 X<network> X<protocol> X<host> X<hostname> X<IP> X<address> X<service>
215
216 C<endprotoent>, C<endservent>, C<gethostbyaddr>, C<gethostbyname>,
217 C<gethostent>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
218 C<getprotobyname>, C<getprotobynumber>, C<getprotoent>,
219 C<getservbyname>, C<getservbyport>, C<getservent>, C<sethostent>,
220 C<setnetent>, C<setprotoent>, C<setservent>
221
222 =item Time-related functions
223 X<time> X<date>
224
225 C<gmtime>, C<localtime>, C<time>, C<times>
226
227 =item Functions new in perl5
228 X<perl5>
229
230 C<abs>, C<bless>, C<chomp>, C<chr>, C<exists>, C<formline>, C<glob>,
231 C<import>, C<lc>, C<lcfirst>, C<map>, C<my>, C<no>, C<our>, C<prototype>,
232 C<qx>, C<qw>, C<readline>, C<readpipe>, C<ref>, C<sub*>, C<sysopen>, C<tie>,
233 C<tied>, C<uc>, C<ucfirst>, C<untie>, C<use>
234
235 * - C<sub> was a keyword in perl4, but in perl5 it is an
236 operator, which can be used in expressions.
237
238 =item Functions obsoleted in perl5
239
240 C<dbmclose>, C<dbmopen>
241
242 =back
243
244 =head2 Portability
245 X<portability> X<Unix> X<portable>
246
247 Perl was born in Unix and can therefore access all common Unix
248 system calls.  In non-Unix environments, the functionality of some
249 Unix system calls may not be available, or details of the available
250 functionality may differ slightly.  The Perl functions affected
251 by this are:
252
253 C<-X>, C<binmode>, C<chmod>, C<chown>, C<chroot>, C<crypt>,
254 C<dbmclose>, C<dbmopen>, C<dump>, C<endgrent>, C<endhostent>,
255 C<endnetent>, C<endprotoent>, C<endpwent>, C<endservent>, C<exec>,
256 C<fcntl>, C<flock>, C<fork>, C<getgrent>, C<getgrgid>, C<gethostbyname>,
257 C<gethostent>, C<getlogin>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
258 C<getppid>, C<getpgrp>, C<getpriority>, C<getprotobynumber>,
259 C<getprotoent>, C<getpwent>, C<getpwnam>, C<getpwuid>,
260 C<getservbyport>, C<getservent>, C<getsockopt>, C<glob>, C<ioctl>,
261 C<kill>, C<link>, C<lstat>, C<msgctl>, C<msgget>, C<msgrcv>,
262 C<msgsnd>, C<open>, C<pipe>, C<readlink>, C<rename>, C<select>, C<semctl>,
263 C<semget>, C<semop>, C<setgrent>, C<sethostent>, C<setnetent>,
264 C<setpgrp>, C<setpriority>, C<setprotoent>, C<setpwent>,
265 C<setservent>, C<setsockopt>, C<shmctl>, C<shmget>, C<shmread>,
266 C<shmwrite>, C<socket>, C<socketpair>,
267 C<stat>, C<symlink>, C<syscall>, C<sysopen>, C<system>,
268 C<times>, C<truncate>, C<umask>, C<unlink>,
269 C<utime>, C<wait>, C<waitpid>
270
271 For more information about the portability of these functions, see
272 L<perlport> and other available platform-specific documentation.
273
274 =head2 Alphabetical Listing of Perl Functions
275
276 =over 8
277
278 =item -X FILEHANDLE
279 X<-r>X<-w>X<-x>X<-o>X<-R>X<-W>X<-X>X<-O>X<-e>X<-z>X<-s>X<-f>X<-d>X<-l>X<-p>
280 X<-S>X<-b>X<-c>X<-t>X<-u>X<-g>X<-k>X<-T>X<-B>X<-M>X<-A>X<-C>
281
282 =item -X EXPR
283
284 =item -X
285
286 A file test, where X is one of the letters listed below.  This unary
287 operator takes one argument, either a filename or a filehandle, and
288 tests the associated file to see if something is true about it.  If the
289 argument is omitted, tests C<$_>, except for C<-t>, which tests STDIN.
290 Unless otherwise documented, it returns C<1> for true and C<''> for false, or
291 the undefined value if the file doesn't exist.  Despite the funny
292 names, precedence is the same as any other named unary operator, and
293 the argument may be parenthesized like any other unary operator.  The
294 operator may be any of:
295
296     -r  File is readable by effective uid/gid.
297     -w  File is writable by effective uid/gid.
298     -x  File is executable by effective uid/gid.
299     -o  File is owned by effective uid.
300
301     -R  File is readable by real uid/gid.
302     -W  File is writable by real uid/gid.
303     -X  File is executable by real uid/gid.
304     -O  File is owned by real uid.
305
306     -e  File exists.
307     -z  File has zero size (is empty).
308     -s  File has nonzero size (returns size in bytes).
309
310     -f  File is a plain file.
311     -d  File is a directory.
312     -l  File is a symbolic link.
313     -p  File is a named pipe (FIFO), or Filehandle is a pipe.
314     -S  File is a socket.
315     -b  File is a block special file.
316     -c  File is a character special file.
317     -t  Filehandle is opened to a tty.
318
319     -u  File has setuid bit set.
320     -g  File has setgid bit set.
321     -k  File has sticky bit set.
322
323     -T  File is an ASCII text file (heuristic guess).
324     -B  File is a "binary" file (opposite of -T).
325
326     -M  Script start time minus file modification time, in days.
327     -A  Same for access time.
328     -C  Same for inode change time (Unix, may differ for other platforms)
329
330 Example:
331
332     while (<>) {
333         chomp;
334         next unless -f $_;      # ignore specials
335         #...
336     }
337
338 The interpretation of the file permission operators C<-r>, C<-R>,
339 C<-w>, C<-W>, C<-x>, and C<-X> is by default based solely on the mode
340 of the file and the uids and gids of the user.  There may be other
341 reasons you can't actually read, write, or execute the file.  Such
342 reasons may be for example network filesystem access controls, ACLs
343 (access control lists), read-only filesystems, and unrecognized
344 executable formats.
345
346 Also note that, for the superuser on the local filesystems, the C<-r>,
347 C<-R>, C<-w>, and C<-W> tests always return 1, and C<-x> and C<-X> return 1
348 if any execute bit is set in the mode.  Scripts run by the superuser
349 may thus need to do a stat() to determine the actual mode of the file,
350 or temporarily set their effective uid to something else.
351
352 If you are using ACLs, there is a pragma called C<filetest> that may
353 produce more accurate results than the bare stat() mode bits.
354 When under the C<use filetest 'access'> the above-mentioned filetests
355 will test whether the permission can (not) be granted using the
356 access() family of system calls.  Also note that the C<-x> and C<-X> may
357 under this pragma return true even if there are no execute permission
358 bits set (nor any extra execute permission ACLs).  This strangeness is
359 due to the underlying system calls' definitions.  Read the
360 documentation for the C<filetest> pragma for more information.
361
362 Note that C<-s/a/b/> does not do a negated substitution.  Saying
363 C<-exp($foo)> still works as expected, however--only single letters
364 following a minus are interpreted as file tests.
365
366 The C<-T> and C<-B> switches work as follows.  The first block or so of the
367 file is examined for odd characters such as strange control codes or
368 characters with the high bit set.  If too many strange characters (>30%)
369 are found, it's a C<-B> file; otherwise it's a C<-T> file.  Also, any file
370 containing null in the first block is considered a binary file.  If C<-T>
371 or C<-B> is used on a filehandle, the current IO buffer is examined
372 rather than the first block.  Both C<-T> and C<-B> return true on a null
373 file, or a file at EOF when testing a filehandle.  Because you have to
374 read a file to do the C<-T> test, on most occasions you want to use a C<-f>
375 against the file first, as in C<next unless -f $file && -T $file>.
376
377 If any of the file tests (or either the C<stat> or C<lstat> operators) are given
378 the special filehandle consisting of a solitary underline, then the stat
379 structure of the previous file test (or stat operator) is used, saving
380 a system call.  (This doesn't work with C<-t>, and you need to remember
381 that lstat() and C<-l> will leave values in the stat structure for the
382 symbolic link, not the real file.)  (Also, if the stat buffer was filled by
383 an C<lstat> call, C<-T> and C<-B> will reset it with the results of C<stat _>).
384 Example:
385
386     print "Can do.\n" if -r $a || -w _ || -x _;
387
388     stat($filename);
389     print "Readable\n" if -r _;
390     print "Writable\n" if -w _;
391     print "Executable\n" if -x _;
392     print "Setuid\n" if -u _;
393     print "Setgid\n" if -g _;
394     print "Sticky\n" if -k _;
395     print "Text\n" if -T _;
396     print "Binary\n" if -B _;
397
398 As of Perl 5.9.1, as a form of purely syntactic sugar, you can stack file
399 test operators, in a way that C<-f -w -x $file> is equivalent to
400 C<-x $file && -w _ && -f _>. (This is only syntax fancy: if you use
401 the return value of C<-f $file> as an argument to another filetest
402 operator, no special magic will happen.)
403
404 =item abs VALUE
405 X<abs> X<absolute>
406
407 =item abs
408
409 Returns the absolute value of its argument.
410 If VALUE is omitted, uses C<$_>.
411
412 =item accept NEWSOCKET,GENERICSOCKET
413 X<accept>
414
415 Accepts an incoming socket connect, just as the accept(2) system call
416 does.  Returns the packed address if it succeeded, false otherwise.
417 See the example in L<perlipc/"Sockets: Client/Server Communication">.
418
419 On systems that support a close-on-exec flag on files, the flag will
420 be set for the newly opened file descriptor, as determined by the
421 value of $^F.  See L<perlvar/$^F>.
422
423 =item alarm SECONDS
424 X<alarm>
425 X<SIGALRM>
426 X<timer>
427
428 =item alarm
429
430 Arranges to have a SIGALRM delivered to this process after the
431 specified number of wallclock seconds has elapsed.  If SECONDS is not
432 specified, the value stored in C<$_> is used. (On some machines,
433 unfortunately, the elapsed time may be up to one second less or more
434 than you specified because of how seconds are counted, and process
435 scheduling may delay the delivery of the signal even further.)
436
437 Only one timer may be counting at once.  Each call disables the
438 previous timer, and an argument of C<0> may be supplied to cancel the
439 previous timer without starting a new one.  The returned value is the
440 amount of time remaining on the previous timer.
441
442 For delays of finer granularity than one second, you may use Perl's
443 four-argument version of select() leaving the first three arguments
444 undefined, or you might be able to use the C<syscall> interface to
445 access setitimer(2) if your system supports it.  The Time::HiRes
446 module (from CPAN, and starting from Perl 5.8 part of the standard
447 distribution) may also prove useful.
448
449 It is usually a mistake to intermix C<alarm> and C<sleep> calls.
450 (C<sleep> may be internally implemented in your system with C<alarm>)
451
452 If you want to use C<alarm> to time out a system call you need to use an
453 C<eval>/C<die> pair.  You can't rely on the alarm causing the system call to
454 fail with C<$!> set to C<EINTR> because Perl sets up signal handlers to
455 restart system calls on some systems.  Using C<eval>/C<die> always works,
456 modulo the caveats given in L<perlipc/"Signals">.
457
458     eval {
459         local $SIG{ALRM} = sub { die "alarm\n" }; # NB: \n required
460         alarm $timeout;
461         $nread = sysread SOCKET, $buffer, $size;
462         alarm 0;
463     };
464     if ($@) {
465         die unless $@ eq "alarm\n";   # propagate unexpected errors
466         # timed out
467     }
468     else {
469         # didn't
470     }
471
472 For more information see L<perlipc>.
473
474 =item atan2 Y,X
475 X<atan2> X<arctangent> X<tan> X<tangent>
476
477 Returns the arctangent of Y/X in the range -PI to PI.
478
479 For the tangent operation, you may use the C<Math::Trig::tan>
480 function, or use the familiar relation:
481
482     sub tan { sin($_[0]) / cos($_[0])  }
483
484 Note that atan2(0, 0) is not well-defined.
485
486 =item bind SOCKET,NAME
487 X<bind>
488
489 Binds a network address to a socket, just as the bind system call
490 does.  Returns true if it succeeded, false otherwise.  NAME should be a
491 packed address of the appropriate type for the socket.  See the examples in
492 L<perlipc/"Sockets: Client/Server Communication">.
493
494 =item binmode FILEHANDLE, LAYER
495 X<binmode> X<binary> X<text> X<DOS> X<Windows>
496
497 =item binmode FILEHANDLE
498
499 Arranges for FILEHANDLE to be read or written in "binary" or "text"
500 mode on systems where the run-time libraries distinguish between
501 binary and text files.  If FILEHANDLE is an expression, the value is
502 taken as the name of the filehandle.  Returns true on success,
503 otherwise it returns C<undef> and sets C<$!> (errno).
504
505 On some systems (in general, DOS and Windows-based systems) binmode()
506 is necessary when you're not working with a text file.  For the sake
507 of portability it is a good idea to always use it when appropriate,
508 and to never use it when it isn't appropriate.  Also, people can
509 set their I/O to be by default UTF-8 encoded Unicode, not bytes.
510
511 In other words: regardless of platform, use binmode() on binary data,
512 like for example images.
513
514 If LAYER is present it is a single string, but may contain multiple
515 directives. The directives alter the behaviour of the file handle.
516 When LAYER is present using binmode on text file makes sense.
517
518 If LAYER is omitted or specified as C<:raw> the filehandle is made
519 suitable for passing binary data. This includes turning off possible CRLF
520 translation and marking it as bytes (as opposed to Unicode characters).
521 Note that, despite what may be implied in I<"Programming Perl"> (the
522 Camel) or elsewhere, C<:raw> is I<not> the simply inverse of C<:crlf>
523 -- other layers which would affect binary nature of the stream are
524 I<also> disabled. See L<PerlIO>, L<perlrun> and the discussion about the
525 PERLIO environment variable.
526
527 The C<:bytes>, C<:crlf>, and C<:utf8>, and any other directives of the
528 form C<:...>, are called I/O I<layers>.  The C<open> pragma can be used to
529 establish default I/O layers.  See L<open>.
530
531 I<The LAYER parameter of the binmode() function is described as "DISCIPLINE"
532 in "Programming Perl, 3rd Edition".  However, since the publishing of this
533 book, by many known as "Camel III", the consensus of the naming of this
534 functionality has moved from "discipline" to "layer".  All documentation
535 of this version of Perl therefore refers to "layers" rather than to
536 "disciplines".  Now back to the regularly scheduled documentation...>
537
538 To mark FILEHANDLE as UTF-8, use C<:utf8>.
539
540 In general, binmode() should be called after open() but before any I/O
541 is done on the filehandle.  Calling binmode() will normally flush any
542 pending buffered output data (and perhaps pending input data) on the
543 handle.  An exception to this is the C<:encoding> layer that
544 changes the default character encoding of the handle, see L<open>.
545 The C<:encoding> layer sometimes needs to be called in
546 mid-stream, and it doesn't flush the stream.  The C<:encoding>
547 also implicitly pushes on top of itself the C<:utf8> layer because
548 internally Perl will operate on UTF-8 encoded Unicode characters.
549
550 The operating system, device drivers, C libraries, and Perl run-time
551 system all work together to let the programmer treat a single
552 character (C<\n>) as the line terminator, irrespective of the external
553 representation.  On many operating systems, the native text file
554 representation matches the internal representation, but on some
555 platforms the external representation of C<\n> is made up of more than
556 one character.
557
558 Mac OS, all variants of Unix, and Stream_LF files on VMS use a single
559 character to end each line in the external representation of text (even
560 though that single character is CARRIAGE RETURN on Mac OS and LINE FEED
561 on Unix and most VMS files). In other systems like OS/2, DOS and the
562 various flavors of MS-Windows your program sees a C<\n> as a simple C<\cJ>,
563 but what's stored in text files are the two characters C<\cM\cJ>.  That
564 means that, if you don't use binmode() on these systems, C<\cM\cJ>
565 sequences on disk will be converted to C<\n> on input, and any C<\n> in
566 your program will be converted back to C<\cM\cJ> on output.  This is what
567 you want for text files, but it can be disastrous for binary files.
568
569 Another consequence of using binmode() (on some systems) is that
570 special end-of-file markers will be seen as part of the data stream.
571 For systems from the Microsoft family this means that if your binary
572 data contains C<\cZ>, the I/O subsystem will regard it as the end of
573 the file, unless you use binmode().
574
575 binmode() is not only important for readline() and print() operations,
576 but also when using read(), seek(), sysread(), syswrite() and tell()
577 (see L<perlport> for more details).  See the C<$/> and C<$\> variables
578 in L<perlvar> for how to manually set your input and output
579 line-termination sequences.
580
581 =item bless REF,CLASSNAME
582 X<bless>
583
584 =item bless REF
585
586 This function tells the thingy referenced by REF that it is now an object
587 in the CLASSNAME package.  If CLASSNAME is omitted, the current package
588 is used.  Because a C<bless> is often the last thing in a constructor,
589 it returns the reference for convenience.  Always use the two-argument
590 version if a derived class might inherit the function doing the blessing.
591 See L<perltoot> and L<perlobj> for more about the blessing (and blessings)
592 of objects.
593
594 Consider always blessing objects in CLASSNAMEs that are mixed case.
595 Namespaces with all lowercase names are considered reserved for
596 Perl pragmata.  Builtin types have all uppercase names. To prevent
597 confusion, you may wish to avoid such package names as well.  Make sure
598 that CLASSNAME is a true value.
599
600 See L<perlmod/"Perl Modules">.
601
602 =item break
603
604 Break out of a C<given()> block.
605
606 This keyword is enabled by the "switch" feature: see L<feature>
607 for more information.
608
609 =item caller EXPR
610 X<caller> X<call stack> X<stack> X<stack trace>
611
612 =item caller
613
614 Returns the context of the current subroutine call.  In scalar context,
615 returns the caller's package name if there is a caller, that is, if
616 we're in a subroutine or C<eval> or C<require>, and the undefined value
617 otherwise.  In list context, returns
618
619     ($package, $filename, $line) = caller;
620
621 With EXPR, it returns some extra information that the debugger uses to
622 print a stack trace.  The value of EXPR indicates how many call frames
623 to go back before the current one.
624
625     ($package, $filename, $line, $subroutine, $hasargs,
626     $wantarray, $evaltext, $is_require, $hints, $bitmask) = caller($i);
627
628 Here $subroutine may be C<(eval)> if the frame is not a subroutine
629 call, but an C<eval>.  In such a case additional elements $evaltext and
630 C<$is_require> are set: C<$is_require> is true if the frame is created by a
631 C<require> or C<use> statement, $evaltext contains the text of the
632 C<eval EXPR> statement.  In particular, for an C<eval BLOCK> statement,
633 $filename is C<(eval)>, but $evaltext is undefined.  (Note also that
634 each C<use> statement creates a C<require> frame inside an C<eval EXPR>
635 frame.)  $subroutine may also be C<(unknown)> if this particular
636 subroutine happens to have been deleted from the symbol table.
637 C<$hasargs> is true if a new instance of C<@_> was set up for the frame.
638 C<$hints> and C<$bitmask> contain pragmatic hints that the caller was
639 compiled with.  The C<$hints> and C<$bitmask> values are subject to change
640 between versions of Perl, and are not meant for external use.
641
642 Furthermore, when called from within the DB package, caller returns more
643 detailed information: it sets the list variable C<@DB::args> to be the
644 arguments with which the subroutine was invoked.
645
646 Be aware that the optimizer might have optimized call frames away before
647 C<caller> had a chance to get the information.  That means that C<caller(N)>
648 might not return information about the call frame you expect it do, for
649 C<< N > 1 >>.  In particular, C<@DB::args> might have information from the
650 previous time C<caller> was called.
651
652 =item chdir EXPR
653 X<chdir>
654 X<cd>
655
656 =item chdir FILEHANDLE
657
658 =item chdir DIRHANDLE
659
660 =item chdir
661
662 Changes the working directory to EXPR, if possible. If EXPR is omitted,
663 changes to the directory specified by C<$ENV{HOME}>, if set; if not,
664 changes to the directory specified by C<$ENV{LOGDIR}>. (Under VMS, the
665 variable C<$ENV{SYS$LOGIN}> is also checked, and used if it is set.) If
666 neither is set, C<chdir> does nothing. It returns true upon success,
667 false otherwise. See the example under C<die>.
668
669 On systems that support fchdir, you might pass a file handle or
670 directory handle as argument.  On systems that don't support fchdir,
671 passing handles produces a fatal error at run time.
672
673 =item chmod LIST
674 X<chmod> X<permission> X<mode>
675
676 Changes the permissions of a list of files.  The first element of the
677 list must be the numerical mode, which should probably be an octal
678 number, and which definitely should I<not> be a string of octal digits:
679 C<0644> is okay, C<'0644'> is not.  Returns the number of files
680 successfully changed.  See also L</oct>, if all you have is a string.
681
682     $cnt = chmod 0755, 'foo', 'bar';
683     chmod 0755, @executables;
684     $mode = '0644'; chmod $mode, 'foo';      # !!! sets mode to
685                                              # --w----r-T
686     $mode = '0644'; chmod oct($mode), 'foo'; # this is better
687     $mode = 0644;   chmod $mode, 'foo';      # this is best
688
689 On systems that support fchmod, you might pass file handles among the
690 files.  On systems that don't support fchmod, passing file handles
691 produces a fatal error at run time.   The file handles must be passed
692 as globs or references to be recognized.  Barewords are considered
693 file names.
694
695     open(my $fh, "<", "foo");
696     my $perm = (stat $fh)[2] & 07777;
697     chmod($perm | 0600, $fh);
698
699 You can also import the symbolic C<S_I*> constants from the Fcntl
700 module:
701
702     use Fcntl ':mode';
703
704     chmod S_IRWXU|S_IRGRP|S_IXGRP|S_IROTH|S_IXOTH, @executables;
705     # This is identical to the chmod 0755 of the above example.
706
707 =item chomp VARIABLE
708 X<chomp> X<INPUT_RECORD_SEPARATOR> X<$/> X<newline> X<eol>
709
710 =item chomp( LIST )
711
712 =item chomp
713
714 This safer version of L</chop> removes any trailing string
715 that corresponds to the current value of C<$/> (also known as
716 $INPUT_RECORD_SEPARATOR in the C<English> module).  It returns the total
717 number of characters removed from all its arguments.  It's often used to
718 remove the newline from the end of an input record when you're worried
719 that the final record may be missing its newline.  When in paragraph
720 mode (C<$/ = "">), it removes all trailing newlines from the string.
721 When in slurp mode (C<$/ = undef>) or fixed-length record mode (C<$/> is
722 a reference to an integer or the like, see L<perlvar>) chomp() won't
723 remove anything.
724 If VARIABLE is omitted, it chomps C<$_>.  Example:
725
726     while (<>) {
727         chomp;  # avoid \n on last field
728         @array = split(/:/);
729         # ...
730     }
731
732 If VARIABLE is a hash, it chomps the hash's values, but not its keys.
733
734 You can actually chomp anything that's an lvalue, including an assignment:
735
736     chomp($cwd = `pwd`);
737     chomp($answer = <STDIN>);
738
739 If you chomp a list, each element is chomped, and the total number of
740 characters removed is returned.
741
742 If the C<encoding> pragma is in scope then the lengths returned are
743 calculated from the length of C<$/> in Unicode characters, which is not
744 always the same as the length of C<$/> in the native encoding.
745
746 Note that parentheses are necessary when you're chomping anything
747 that is not a simple variable.  This is because C<chomp $cwd = `pwd`;>
748 is interpreted as C<(chomp $cwd) = `pwd`;>, rather than as
749 C<chomp( $cwd = `pwd` )> which you might expect.  Similarly,
750 C<chomp $a, $b> is interpreted as C<chomp($a), $b> rather than
751 as C<chomp($a, $b)>.
752
753 =item chop VARIABLE
754 X<chop>
755
756 =item chop( LIST )
757
758 =item chop
759
760 Chops off the last character of a string and returns the character
761 chopped.  It is much more efficient than C<s/.$//s> because it neither
762 scans nor copies the string.  If VARIABLE is omitted, chops C<$_>.
763 If VARIABLE is a hash, it chops the hash's values, but not its keys.
764
765 You can actually chop anything that's an lvalue, including an assignment.
766
767 If you chop a list, each element is chopped.  Only the value of the
768 last C<chop> is returned.
769
770 Note that C<chop> returns the last character.  To return all but the last
771 character, use C<substr($string, 0, -1)>.
772
773 See also L</chomp>.
774
775 =item chown LIST
776 X<chown> X<owner> X<user> X<group>
777
778 Changes the owner (and group) of a list of files.  The first two
779 elements of the list must be the I<numeric> uid and gid, in that
780 order.  A value of -1 in either position is interpreted by most
781 systems to leave that value unchanged.  Returns the number of files
782 successfully changed.
783
784     $cnt = chown $uid, $gid, 'foo', 'bar';
785     chown $uid, $gid, @filenames;
786
787 On systems that support fchown, you might pass file handles among the
788 files.  On systems that don't support fchown, passing file handles
789 produces a fatal error at run time.  The file handles must be passed
790 as globs or references to be recognized.  Barewords are considered
791 file names.
792
793 Here's an example that looks up nonnumeric uids in the passwd file:
794
795     print "User: ";
796     chomp($user = <STDIN>);
797     print "Files: ";
798     chomp($pattern = <STDIN>);
799
800     ($login,$pass,$uid,$gid) = getpwnam($user)
801         or die "$user not in passwd file";
802
803     @ary = glob($pattern);      # expand filenames
804     chown $uid, $gid, @ary;
805
806 On most systems, you are not allowed to change the ownership of the
807 file unless you're the superuser, although you should be able to change
808 the group to any of your secondary groups.  On insecure systems, these
809 restrictions may be relaxed, but this is not a portable assumption.
810 On POSIX systems, you can detect this condition this way:
811
812     use POSIX qw(sysconf _PC_CHOWN_RESTRICTED);
813     $can_chown_giveaway = not sysconf(_PC_CHOWN_RESTRICTED);
814
815 =item chr NUMBER
816 X<chr> X<character> X<ASCII> X<Unicode>
817
818 =item chr
819
820 Returns the character represented by that NUMBER in the character set.
821 For example, C<chr(65)> is C<"A"> in either ASCII or Unicode, and
822 chr(0x263a) is a Unicode smiley face.  Note that characters from 128
823 to 255 (inclusive) are by default not encoded in UTF-8 Unicode for
824 backward compatibility reasons (but see L<encoding>).
825
826 Negative values give the Unicode replacement character (chr(0xfffd)),
827 except under the L<bytes> pragma, where low eight bits of the value
828 (truncated to an integer) are used.
829
830 If NUMBER is omitted, uses C<$_>.
831
832 For the reverse, use L</ord>.
833
834 Note that under the C<bytes> pragma the NUMBER is masked to
835 the low eight bits.
836
837 See L<perlunicode> and L<encoding> for more about Unicode.
838
839 =item chroot FILENAME
840 X<chroot> X<root>
841
842 =item chroot
843
844 This function works like the system call by the same name: it makes the
845 named directory the new root directory for all further pathnames that
846 begin with a C</> by your process and all its children.  (It doesn't
847 change your current working directory, which is unaffected.)  For security
848 reasons, this call is restricted to the superuser.  If FILENAME is
849 omitted, does a C<chroot> to C<$_>.
850
851 =item close FILEHANDLE
852 X<close>
853
854 =item close
855
856 Closes the file or pipe associated with the file handle, returning
857 true only if IO buffers are successfully flushed and closes the system
858 file descriptor.  Closes the currently selected filehandle if the
859 argument is omitted.
860
861 You don't have to close FILEHANDLE if you are immediately going to do
862 another C<open> on it, because C<open> will close it for you.  (See
863 C<open>.)  However, an explicit C<close> on an input file resets the line
864 counter (C<$.>), while the implicit close done by C<open> does not.
865
866 If the file handle came from a piped open, C<close> will additionally
867 return false if one of the other system calls involved fails, or if the
868 program exits with non-zero status.  (If the only problem was that the
869 program exited non-zero, C<$!> will be set to C<0>.)  Closing a pipe
870 also waits for the process executing on the pipe to complete, in case you
871 want to look at the output of the pipe afterwards, and
872 implicitly puts the exit status value of that command into C<$?> and
873 C<${^CHILD_ERROR_NATIVE}>.
874
875 Prematurely closing the read end of a pipe (i.e. before the process
876 writing to it at the other end has closed it) will result in a
877 SIGPIPE being delivered to the writer.  If the other end can't
878 handle that, be sure to read all the data before closing the pipe.
879
880 Example:
881
882     open(OUTPUT, '|sort >foo')  # pipe to sort
883         or die "Can't start sort: $!";
884     #...                        # print stuff to output
885     close OUTPUT                # wait for sort to finish
886         or warn $! ? "Error closing sort pipe: $!"
887                    : "Exit status $? from sort";
888     open(INPUT, 'foo')          # get sort's results
889         or die "Can't open 'foo' for input: $!";
890
891 FILEHANDLE may be an expression whose value can be used as an indirect
892 filehandle, usually the real filehandle name.
893
894 =item closedir DIRHANDLE
895 X<closedir>
896
897 Closes a directory opened by C<opendir> and returns the success of that
898 system call.
899
900 =item connect SOCKET,NAME
901 X<connect>
902
903 Attempts to connect to a remote socket, just as the connect system call
904 does.  Returns true if it succeeded, false otherwise.  NAME should be a
905 packed address of the appropriate type for the socket.  See the examples in
906 L<perlipc/"Sockets: Client/Server Communication">.
907
908 =item continue BLOCK
909 X<continue>
910
911 =item continue
912
913 C<continue> is actually a flow control statement rather than a function.  If
914 there is a C<continue> BLOCK attached to a BLOCK (typically in a C<while> or
915 C<foreach>), it is always executed just before the conditional is about to
916 be evaluated again, just like the third part of a C<for> loop in C.  Thus
917 it can be used to increment a loop variable, even when the loop has been
918 continued via the C<next> statement (which is similar to the C C<continue>
919 statement).
920
921 C<last>, C<next>, or C<redo> may appear within a C<continue>
922 block.  C<last> and C<redo> will behave as if they had been executed within
923 the main block.  So will C<next>, but since it will execute a C<continue>
924 block, it may be more entertaining.
925
926     while (EXPR) {
927         ### redo always comes here
928         do_something;
929     } continue {
930         ### next always comes here
931         do_something_else;
932         # then back the top to re-check EXPR
933     }
934     ### last always comes here
935
936 Omitting the C<continue> section is semantically equivalent to using an
937 empty one, logically enough.  In that case, C<next> goes directly back
938 to check the condition at the top of the loop.
939
940 If the "switch" feature is enabled, C<continue> is also a
941 function that will break out of the current C<when> or C<default>
942 block, and fall through to the next case. See L<feature> and
943 L<perlsyn/"Switch statements"> for more information.
944
945
946 =item cos EXPR
947 X<cos> X<cosine> X<acos> X<arccosine>
948
949 =item cos
950
951 Returns the cosine of EXPR (expressed in radians).  If EXPR is omitted,
952 takes cosine of C<$_>.
953
954 For the inverse cosine operation, you may use the C<Math::Trig::acos()>
955 function, or use this relation:
956
957     sub acos { atan2( sqrt(1 - $_[0] * $_[0]), $_[0] ) }
958
959 =item crypt PLAINTEXT,SALT
960 X<crypt> X<digest> X<hash> X<salt> X<plaintext> X<password>
961 X<decrypt> X<cryptography> X<passwd>
962
963 Creates a digest string exactly like the crypt(3) function in the C
964 library (assuming that you actually have a version there that has not
965 been extirpated as a potential munitions).
966
967 crypt() is a one-way hash function.  The PLAINTEXT and SALT is turned
968 into a short string, called a digest, which is returned.  The same
969 PLAINTEXT and SALT will always return the same string, but there is no
970 (known) way to get the original PLAINTEXT from the hash.  Small
971 changes in the PLAINTEXT or SALT will result in large changes in the
972 digest.
973
974 There is no decrypt function.  This function isn't all that useful for
975 cryptography (for that, look for F<Crypt> modules on your nearby CPAN
976 mirror) and the name "crypt" is a bit of a misnomer.  Instead it is
977 primarily used to check if two pieces of text are the same without
978 having to transmit or store the text itself.  An example is checking
979 if a correct password is given.  The digest of the password is stored,
980 not the password itself.  The user types in a password that is
981 crypt()'d with the same salt as the stored digest.  If the two digests
982 match the password is correct.
983
984 When verifying an existing digest string you should use the digest as
985 the salt (like C<crypt($plain, $digest) eq $digest>).  The SALT used
986 to create the digest is visible as part of the digest.  This ensures
987 crypt() will hash the new string with the same salt as the digest.
988 This allows your code to work with the standard L<crypt|/crypt> and
989 with more exotic implementations.  In other words, do not assume
990 anything about the returned string itself, or how many bytes in the
991 digest matter.
992
993 Traditionally the result is a string of 13 bytes: two first bytes of
994 the salt, followed by 11 bytes from the set C<[./0-9A-Za-z]>, and only
995 the first eight bytes of the digest string mattered, but alternative
996 hashing schemes (like MD5), higher level security schemes (like C2),
997 and implementations on non-UNIX platforms may produce different
998 strings.
999
1000 When choosing a new salt create a random two character string whose
1001 characters come from the set C<[./0-9A-Za-z]> (like C<join '', ('.',
1002 '/', 0..9, 'A'..'Z', 'a'..'z')[rand 64, rand 64]>).  This set of
1003 characters is just a recommendation; the characters allowed in
1004 the salt depend solely on your system's crypt library, and Perl can't
1005 restrict what salts C<crypt()> accepts.
1006
1007 Here's an example that makes sure that whoever runs this program knows
1008 their password:
1009
1010     $pwd = (getpwuid($<))[1];
1011
1012     system "stty -echo";
1013     print "Password: ";
1014     chomp($word = <STDIN>);
1015     print "\n";
1016     system "stty echo";
1017
1018     if (crypt($word, $pwd) ne $pwd) {
1019         die "Sorry...\n";
1020     } else {
1021         print "ok\n";
1022     }
1023
1024 Of course, typing in your own password to whoever asks you
1025 for it is unwise.
1026
1027 The L<crypt|/crypt> function is unsuitable for hashing large quantities
1028 of data, not least of all because you can't get the information
1029 back.  Look at the L<Digest> module for more robust algorithms.
1030
1031 If using crypt() on a Unicode string (which I<potentially> has
1032 characters with codepoints above 255), Perl tries to make sense
1033 of the situation by trying to downgrade (a copy of the string)
1034 the string back to an eight-bit byte string before calling crypt()
1035 (on that copy).  If that works, good.  If not, crypt() dies with
1036 C<Wide character in crypt>.
1037
1038 =item dbmclose HASH
1039 X<dbmclose>
1040
1041 [This function has been largely superseded by the C<untie> function.]
1042
1043 Breaks the binding between a DBM file and a hash.
1044
1045 =item dbmopen HASH,DBNAME,MASK
1046 X<dbmopen> X<dbm> X<ndbm> X<sdbm> X<gdbm>
1047
1048 [This function has been largely superseded by the C<tie> function.]
1049
1050 This binds a dbm(3), ndbm(3), sdbm(3), gdbm(3), or Berkeley DB file to a
1051 hash.  HASH is the name of the hash.  (Unlike normal C<open>, the first
1052 argument is I<not> a filehandle, even though it looks like one).  DBNAME
1053 is the name of the database (without the F<.dir> or F<.pag> extension if
1054 any).  If the database does not exist, it is created with protection
1055 specified by MASK (as modified by the C<umask>).  If your system supports
1056 only the older DBM functions, you may perform only one C<dbmopen> in your
1057 program.  In older versions of Perl, if your system had neither DBM nor
1058 ndbm, calling C<dbmopen> produced a fatal error; it now falls back to
1059 sdbm(3).
1060
1061 If you don't have write access to the DBM file, you can only read hash
1062 variables, not set them.  If you want to test whether you can write,
1063 either use file tests or try setting a dummy hash entry inside an C<eval>,
1064 which will trap the error.
1065
1066 Note that functions such as C<keys> and C<values> may return huge lists
1067 when used on large DBM files.  You may prefer to use the C<each>
1068 function to iterate over large DBM files.  Example:
1069
1070     # print out history file offsets
1071     dbmopen(%HIST,'/usr/lib/news/history',0666);
1072     while (($key,$val) = each %HIST) {
1073         print $key, ' = ', unpack('L',$val), "\n";
1074     }
1075     dbmclose(%HIST);
1076
1077 See also L<AnyDBM_File> for a more general description of the pros and
1078 cons of the various dbm approaches, as well as L<DB_File> for a particularly
1079 rich implementation.
1080
1081 You can control which DBM library you use by loading that library
1082 before you call dbmopen():
1083
1084     use DB_File;
1085     dbmopen(%NS_Hist, "$ENV{HOME}/.netscape/history.db")
1086         or die "Can't open netscape history file: $!";
1087
1088 =item defined EXPR
1089 X<defined> X<undef> X<undefined>
1090
1091 =item defined
1092
1093 Returns a Boolean value telling whether EXPR has a value other than
1094 the undefined value C<undef>.  If EXPR is not present, C<$_> will be
1095 checked.
1096
1097 Many operations return C<undef> to indicate failure, end of file,
1098 system error, uninitialized variable, and other exceptional
1099 conditions.  This function allows you to distinguish C<undef> from
1100 other values.  (A simple Boolean test will not distinguish among
1101 C<undef>, zero, the empty string, and C<"0">, which are all equally
1102 false.)  Note that since C<undef> is a valid scalar, its presence
1103 doesn't I<necessarily> indicate an exceptional condition: C<pop>
1104 returns C<undef> when its argument is an empty array, I<or> when the
1105 element to return happens to be C<undef>.
1106
1107 You may also use C<defined(&func)> to check whether subroutine C<&func>
1108 has ever been defined.  The return value is unaffected by any forward
1109 declarations of C<&func>.  Note that a subroutine which is not defined
1110 may still be callable: its package may have an C<AUTOLOAD> method that
1111 makes it spring into existence the first time that it is called -- see
1112 L<perlsub>.
1113
1114 Use of C<defined> on aggregates (hashes and arrays) is deprecated.  It
1115 used to report whether memory for that aggregate has ever been
1116 allocated.  This behavior may disappear in future versions of Perl.
1117 You should instead use a simple test for size:
1118
1119     if (@an_array) { print "has array elements\n" }
1120     if (%a_hash)   { print "has hash members\n"   }
1121
1122 When used on a hash element, it tells you whether the value is defined,
1123 not whether the key exists in the hash.  Use L</exists> for the latter
1124 purpose.
1125
1126 Examples:
1127
1128     print if defined $switch{'D'};
1129     print "$val\n" while defined($val = pop(@ary));
1130     die "Can't readlink $sym: $!"
1131         unless defined($value = readlink $sym);
1132     sub foo { defined &$bar ? &$bar(@_) : die "No bar"; }
1133     $debugging = 0 unless defined $debugging;
1134
1135 Note:  Many folks tend to overuse C<defined>, and then are surprised to
1136 discover that the number C<0> and C<""> (the zero-length string) are, in fact,
1137 defined values.  For example, if you say
1138
1139     "ab" =~ /a(.*)b/;
1140
1141 The pattern match succeeds, and C<$1> is defined, despite the fact that it
1142 matched "nothing".  It didn't really fail to match anything.  Rather, it
1143 matched something that happened to be zero characters long.  This is all
1144 very above-board and honest.  When a function returns an undefined value,
1145 it's an admission that it couldn't give you an honest answer.  So you
1146 should use C<defined> only when you're questioning the integrity of what
1147 you're trying to do.  At other times, a simple comparison to C<0> or C<""> is
1148 what you want.
1149
1150 See also L</undef>, L</exists>, L</ref>.
1151
1152 =item delete EXPR
1153 X<delete>
1154
1155 Given an expression that specifies a hash element, array element, hash slice,
1156 or array slice, deletes the specified element(s) from the hash or array.
1157 In the case of an array, if the array elements happen to be at the end,
1158 the size of the array will shrink to the highest element that tests
1159 true for exists() (or 0 if no such element exists).
1160
1161 Returns a list with the same number of elements as the number of elements
1162 for which deletion was attempted.  Each element of that list consists of
1163 either the value of the element deleted, or the undefined value.  In scalar
1164 context, this means that you get the value of the last element deleted (or
1165 the undefined value if that element did not exist).
1166
1167     %hash = (foo => 11, bar => 22, baz => 33);
1168     $scalar = delete $hash{foo};             # $scalar is 11
1169     $scalar = delete @hash{qw(foo bar)};     # $scalar is 22
1170     @array  = delete @hash{qw(foo bar baz)}; # @array  is (undef,undef,33)
1171
1172 Deleting from C<%ENV> modifies the environment.  Deleting from
1173 a hash tied to a DBM file deletes the entry from the DBM file.  Deleting
1174 from a C<tie>d hash or array may not necessarily return anything.
1175
1176 Deleting an array element effectively returns that position of the array
1177 to its initial, uninitialized state.  Subsequently testing for the same
1178 element with exists() will return false.  Also, deleting array elements
1179 in the middle of an array will not shift the index of the elements
1180 after them down.  Use splice() for that.  See L</exists>.
1181
1182 The following (inefficiently) deletes all the values of %HASH and @ARRAY:
1183
1184     foreach $key (keys %HASH) {
1185         delete $HASH{$key};
1186     }
1187
1188     foreach $index (0 .. $#ARRAY) {
1189         delete $ARRAY[$index];
1190     }
1191
1192 And so do these:
1193
1194     delete @HASH{keys %HASH};
1195
1196     delete @ARRAY[0 .. $#ARRAY];
1197
1198 But both of these are slower than just assigning the empty list
1199 or undefining %HASH or @ARRAY:
1200
1201     %HASH = ();         # completely empty %HASH
1202     undef %HASH;        # forget %HASH ever existed
1203
1204     @ARRAY = ();        # completely empty @ARRAY
1205     undef @ARRAY;       # forget @ARRAY ever existed
1206
1207 Note that the EXPR can be arbitrarily complicated as long as the final
1208 operation is a hash element, array element,  hash slice, or array slice
1209 lookup:
1210
1211     delete $ref->[$x][$y]{$key};
1212     delete @{$ref->[$x][$y]}{$key1, $key2, @morekeys};
1213
1214     delete $ref->[$x][$y][$index];
1215     delete @{$ref->[$x][$y]}[$index1, $index2, @moreindices];
1216
1217 =item die LIST
1218 X<die> X<throw> X<exception> X<raise> X<$@> X<abort>
1219
1220 Outside an C<eval>, prints the value of LIST to C<STDERR> and
1221 exits with the current value of C<$!> (errno).  If C<$!> is C<0>,
1222 exits with the value of C<<< ($? >> 8) >>> (backtick `command`
1223 status).  If C<<< ($? >> 8) >>> is C<0>, exits with C<255>.  Inside
1224 an C<eval(),> the error message is stuffed into C<$@> and the
1225 C<eval> is terminated with the undefined value.  This makes
1226 C<die> the way to raise an exception.
1227
1228 Equivalent examples:
1229
1230     die "Can't cd to spool: $!\n" unless chdir '/usr/spool/news';
1231     chdir '/usr/spool/news' or die "Can't cd to spool: $!\n"
1232
1233 If the last element of LIST does not end in a newline, the current
1234 script line number and input line number (if any) are also printed,
1235 and a newline is supplied.  Note that the "input line number" (also
1236 known as "chunk") is subject to whatever notion of "line" happens to
1237 be currently in effect, and is also available as the special variable
1238 C<$.>.  See L<perlvar/"$/"> and L<perlvar/"$.">.
1239
1240 Hint: sometimes appending C<", stopped"> to your message will cause it
1241 to make better sense when the string C<"at foo line 123"> is appended.
1242 Suppose you are running script "canasta".
1243
1244     die "/etc/games is no good";
1245     die "/etc/games is no good, stopped";
1246
1247 produce, respectively
1248
1249     /etc/games is no good at canasta line 123.
1250     /etc/games is no good, stopped at canasta line 123.
1251
1252 See also exit(), warn(), and the Carp module.
1253
1254 If LIST is empty and C<$@> already contains a value (typically from a
1255 previous eval) that value is reused after appending C<"\t...propagated">.
1256 This is useful for propagating exceptions:
1257
1258     eval { ... };
1259     die unless $@ =~ /Expected exception/;
1260
1261 If LIST is empty and C<$@> contains an object reference that has a
1262 C<PROPAGATE> method, that method will be called with additional file
1263 and line number parameters.  The return value replaces the value in
1264 C<$@>.  i.e. as if C<< $@ = eval { $@->PROPAGATE(__FILE__, __LINE__) }; >>
1265 were called.
1266
1267 If C<$@> is empty then the string C<"Died"> is used.
1268
1269 die() can also be called with a reference argument.  If this happens to be
1270 trapped within an eval(), $@ contains the reference.  This behavior permits
1271 a more elaborate exception handling implementation using objects that
1272 maintain arbitrary state about the nature of the exception.  Such a scheme
1273 is sometimes preferable to matching particular string values of $@ using
1274 regular expressions.  Here's an example:
1275
1276     use Scalar::Util 'blessed';
1277
1278     eval { ... ; die Some::Module::Exception->new( FOO => "bar" ) };
1279     if ($@) {
1280         if (blessed($@) && $@->isa("Some::Module::Exception")) {
1281             # handle Some::Module::Exception
1282         }
1283         else {
1284             # handle all other possible exceptions
1285         }
1286     }
1287
1288 Because perl will stringify uncaught exception messages before displaying
1289 them, you may want to overload stringification operations on such custom
1290 exception objects.  See L<overload> for details about that.
1291
1292 You can arrange for a callback to be run just before the C<die>
1293 does its deed, by setting the C<$SIG{__DIE__}> hook.  The associated
1294 handler will be called with the error text and can change the error
1295 message, if it sees fit, by calling C<die> again.  See
1296 L<perlvar/$SIG{expr}> for details on setting C<%SIG> entries, and
1297 L<"eval BLOCK"> for some examples.  Although this feature was 
1298 to be run only right before your program was to exit, this is not
1299 currently the case--the C<$SIG{__DIE__}> hook is currently called
1300 even inside eval()ed blocks/strings!  If one wants the hook to do
1301 nothing in such situations, put
1302
1303         die @_ if $^S;
1304
1305 as the first line of the handler (see L<perlvar/$^S>).  Because
1306 this promotes strange action at a distance, this counterintuitive
1307 behavior may be fixed in a future release.
1308
1309 =item do BLOCK
1310 X<do> X<block>
1311
1312 Not really a function.  Returns the value of the last command in the
1313 sequence of commands indicated by BLOCK.  When modified by the C<while> or
1314 C<until> loop modifier, executes the BLOCK once before testing the loop
1315 condition. (On other statements the loop modifiers test the conditional
1316 first.)
1317
1318 C<do BLOCK> does I<not> count as a loop, so the loop control statements
1319 C<next>, C<last>, or C<redo> cannot be used to leave or restart the block.
1320 See L<perlsyn> for alternative strategies.
1321
1322 =item do SUBROUTINE(LIST)
1323 X<do>
1324
1325 This form of subroutine call is deprecated.  See L<perlsub>.
1326
1327 =item do EXPR
1328 X<do>
1329
1330 Uses the value of EXPR as a filename and executes the contents of the
1331 file as a Perl script.
1332
1333     do 'stat.pl';
1334
1335 is just like
1336
1337     eval `cat stat.pl`;
1338
1339 except that it's more efficient and concise, keeps track of the current
1340 filename for error messages, searches the @INC directories, and updates
1341 C<%INC> if the file is found.  See L<perlvar/Predefined Names> for these
1342 variables.  It also differs in that code evaluated with C<do FILENAME>
1343 cannot see lexicals in the enclosing scope; C<eval STRING> does.  It's the
1344 same, however, in that it does reparse the file every time you call it,
1345 so you probably don't want to do this inside a loop.
1346
1347 If C<do> cannot read the file, it returns undef and sets C<$!> to the
1348 error.  If C<do> can read the file but cannot compile it, it
1349 returns undef and sets an error message in C<$@>.   If the file is
1350 successfully compiled, C<do> returns the value of the last expression
1351 evaluated.
1352
1353 Note that inclusion of library modules is better done with the
1354 C<use> and C<require> operators, which also do automatic error checking
1355 and raise an exception if there's a problem.
1356
1357 You might like to use C<do> to read in a program configuration
1358 file.  Manual error checking can be done this way:
1359
1360     # read in config files: system first, then user
1361     for $file ("/share/prog/defaults.rc",
1362                "$ENV{HOME}/.someprogrc")
1363    {
1364         unless ($return = do $file) {
1365             warn "couldn't parse $file: $@" if $@;
1366             warn "couldn't do $file: $!"    unless defined $return;
1367             warn "couldn't run $file"       unless $return;
1368         }
1369     }
1370
1371 =item dump LABEL
1372 X<dump> X<core> X<undump>
1373
1374 =item dump
1375
1376 This function causes an immediate core dump.  See also the B<-u>
1377 command-line switch in L<perlrun>, which does the same thing.
1378 Primarily this is so that you can use the B<undump> program (not
1379 supplied) to turn your core dump into an executable binary after
1380 having initialized all your variables at the beginning of the
1381 program.  When the new binary is executed it will begin by executing
1382 a C<goto LABEL> (with all the restrictions that C<goto> suffers).
1383 Think of it as a goto with an intervening core dump and reincarnation.
1384 If C<LABEL> is omitted, restarts the program from the top.
1385
1386 B<WARNING>: Any files opened at the time of the dump will I<not>
1387 be open any more when the program is reincarnated, with possible
1388 resulting confusion on the part of Perl.
1389
1390 This function is now largely obsolete, partly because it's very
1391 hard to convert a core file into an executable, and because the
1392 real compiler backends for generating portable bytecode and compilable
1393 C code have superseded it.  That's why you should now invoke it as
1394 C<CORE::dump()>, if you don't want to be warned against a possible
1395 typo.
1396
1397 If you're looking to use L<dump> to speed up your program, consider
1398 generating bytecode or native C code as described in L<perlcc>.  If
1399 you're just trying to accelerate a CGI script, consider using the
1400 C<mod_perl> extension to B<Apache>, or the CPAN module, CGI::Fast.
1401 You might also consider autoloading or selfloading, which at least
1402 make your program I<appear> to run faster.
1403
1404 =item each HASH
1405 X<each> X<hash, iterator>
1406
1407 When called in list context, returns a 2-element list consisting of the
1408 key and value for the next element of a hash, so that you can iterate over
1409 it.  When called in scalar context, returns only the key for the next
1410 element in the hash.
1411
1412 Entries are returned in an apparently random order.  The actual random
1413 order is subject to change in future versions of perl, but it is
1414 guaranteed to be in the same order as either the C<keys> or C<values>
1415 function would produce on the same (unmodified) hash.  Since Perl
1416 5.8.1 the ordering is different even between different runs of Perl
1417 for security reasons (see L<perlsec/"Algorithmic Complexity Attacks">).
1418
1419 When the hash is entirely read, a null array is returned in list context
1420 (which when assigned produces a false (C<0>) value), and C<undef> in
1421 scalar context.  The next call to C<each> after that will start iterating
1422 again.  There is a single iterator for each hash, shared by all C<each>,
1423 C<keys>, and C<values> function calls in the program; it can be reset by
1424 reading all the elements from the hash, or by evaluating C<keys HASH> or
1425 C<values HASH>.  If you add or delete elements of a hash while you're
1426 iterating over it, you may get entries skipped or duplicated, so
1427 don't.  Exception: It is always safe to delete the item most recently
1428 returned by C<each()>, which means that the following code will work:
1429
1430         while (($key, $value) = each %hash) {
1431           print $key, "\n";
1432           delete $hash{$key};   # This is safe
1433         }
1434
1435 The following prints out your environment like the printenv(1) program,
1436 only in a different order:
1437
1438     while (($key,$value) = each %ENV) {
1439         print "$key=$value\n";
1440     }
1441
1442 See also C<keys>, C<values> and C<sort>.
1443
1444 =item eof FILEHANDLE
1445 X<eof>
1446 X<end of file>
1447 X<end-of-file>
1448
1449 =item eof ()
1450
1451 =item eof
1452
1453 Returns 1 if the next read on FILEHANDLE will return end of file, or if
1454 FILEHANDLE is not open.  FILEHANDLE may be an expression whose value
1455 gives the real filehandle.  (Note that this function actually
1456 reads a character and then C<ungetc>s it, so isn't very useful in an
1457 interactive context.)  Do not read from a terminal file (or call
1458 C<eof(FILEHANDLE)> on it) after end-of-file is reached.  File types such
1459 as terminals may lose the end-of-file condition if you do.
1460
1461 An C<eof> without an argument uses the last file read.  Using C<eof()>
1462 with empty parentheses is very different.  It refers to the pseudo file
1463 formed from the files listed on the command line and accessed via the
1464 C<< <> >> operator.  Since C<< <> >> isn't explicitly opened,
1465 as a normal filehandle is, an C<eof()> before C<< <> >> has been
1466 used will cause C<@ARGV> to be examined to determine if input is
1467 available.   Similarly, an C<eof()> after C<< <> >> has returned
1468 end-of-file will assume you are processing another C<@ARGV> list,
1469 and if you haven't set C<@ARGV>, will read input from C<STDIN>;
1470 see L<perlop/"I/O Operators">.
1471
1472 In a C<< while (<>) >> loop, C<eof> or C<eof(ARGV)> can be used to
1473 detect the end of each file, C<eof()> will only detect the end of the
1474 last file.  Examples:
1475
1476     # reset line numbering on each input file
1477     while (<>) {
1478         next if /^\s*#/;        # skip comments
1479         print "$.\t$_";
1480     } continue {
1481         close ARGV  if eof;     # Not eof()!
1482     }
1483
1484     # insert dashes just before last line of last file
1485     while (<>) {
1486         if (eof()) {            # check for end of last file
1487             print "--------------\n";
1488         }
1489         print;
1490         last if eof();          # needed if we're reading from a terminal
1491     }
1492
1493 Practical hint: you almost never need to use C<eof> in Perl, because the
1494 input operators typically return C<undef> when they run out of data, or if
1495 there was an error.
1496
1497 =item eval EXPR
1498 X<eval> X<try> X<catch> X<evaluate> X<parse> X<execute>
1499
1500 =item eval BLOCK
1501
1502 =item eval
1503
1504 In the first form, the return value of EXPR is parsed and executed as if it
1505 were a little Perl program.  The value of the expression (which is itself
1506 determined within scalar context) is first parsed, and if there weren't any
1507 errors, executed in the lexical context of the current Perl program, so
1508 that any variable settings or subroutine and format definitions remain
1509 afterwards.  Note that the value is parsed every time the C<eval> executes.
1510 If EXPR is omitted, evaluates C<$_>.  This form is typically used to
1511 delay parsing and subsequent execution of the text of EXPR until run time.
1512
1513 In the second form, the code within the BLOCK is parsed only once--at the
1514 same time the code surrounding the C<eval> itself was parsed--and executed
1515 within the context of the current Perl program.  This form is typically
1516 used to trap exceptions more efficiently than the first (see below), while
1517 also providing the benefit of checking the code within BLOCK at compile
1518 time.
1519
1520 The final semicolon, if any, may be omitted from the value of EXPR or within
1521 the BLOCK.
1522
1523 In both forms, the value returned is the value of the last expression
1524 evaluated inside the mini-program; a return statement may be also used, just
1525 as with subroutines.  The expression providing the return value is evaluated
1526 in void, scalar, or list context, depending on the context of the C<eval> 
1527 itself.  See L</wantarray> for more on how the evaluation context can be 
1528 determined.
1529
1530 If there is a syntax error or runtime error, or a C<die> statement is
1531 executed, an undefined value is returned by C<eval>, and C<$@> is set to the
1532 error message.  If there was no error, C<$@> is guaranteed to be a null
1533 string.  Beware that using C<eval> neither silences perl from printing
1534 warnings to STDERR, nor does it stuff the text of warning messages into C<$@>.
1535 To do either of those, you have to use the C<$SIG{__WARN__}> facility, or
1536 turn off warnings inside the BLOCK or EXPR using S<C<no warnings 'all'>>.
1537 See L</warn>, L<perlvar>, L<warnings> and L<perllexwarn>.
1538
1539 Note that, because C<eval> traps otherwise-fatal errors, it is useful for
1540 determining whether a particular feature (such as C<socket> or C<symlink>)
1541 is implemented.  It is also Perl's exception trapping mechanism, where
1542 the die operator is used to raise exceptions.
1543
1544 If the code to be executed doesn't vary, you may use the eval-BLOCK
1545 form to trap run-time errors without incurring the penalty of
1546 recompiling each time.  The error, if any, is still returned in C<$@>.
1547 Examples:
1548
1549     # make divide-by-zero nonfatal
1550     eval { $answer = $a / $b; }; warn $@ if $@;
1551
1552     # same thing, but less efficient
1553     eval '$answer = $a / $b'; warn $@ if $@;
1554
1555     # a compile-time error
1556     eval { $answer = };                 # WRONG
1557
1558     # a run-time error
1559     eval '$answer =';   # sets $@
1560
1561 Using the C<eval{}> form as an exception trap in libraries does have some
1562 issues.  Due to the current arguably broken state of C<__DIE__> hooks, you
1563 may wish not to trigger any C<__DIE__> hooks that user code may have installed.
1564 You can use the C<local $SIG{__DIE__}> construct for this purpose,
1565 as shown in this example:
1566
1567     # a very private exception trap for divide-by-zero
1568     eval { local $SIG{'__DIE__'}; $answer = $a / $b; };
1569     warn $@ if $@;
1570
1571 This is especially significant, given that C<__DIE__> hooks can call
1572 C<die> again, which has the effect of changing their error messages:
1573
1574     # __DIE__ hooks may modify error messages
1575     {
1576        local $SIG{'__DIE__'} =
1577               sub { (my $x = $_[0]) =~ s/foo/bar/g; die $x };
1578        eval { die "foo lives here" };
1579        print $@ if $@;                # prints "bar lives here"
1580     }
1581
1582 Because this promotes action at a distance, this counterintuitive behavior
1583 may be fixed in a future release.
1584
1585 With an C<eval>, you should be especially careful to remember what's
1586 being looked at when:
1587
1588     eval $x;            # CASE 1
1589     eval "$x";          # CASE 2
1590
1591     eval '$x';          # CASE 3
1592     eval { $x };        # CASE 4
1593
1594     eval "\$$x++";      # CASE 5
1595     $$x++;              # CASE 6
1596
1597 Cases 1 and 2 above behave identically: they run the code contained in
1598 the variable $x.  (Although case 2 has misleading double quotes making
1599 the reader wonder what else might be happening (nothing is).)  Cases 3
1600 and 4 likewise behave in the same way: they run the code C<'$x'>, which
1601 does nothing but return the value of $x.  (Case 4 is preferred for
1602 purely visual reasons, but it also has the advantage of compiling at
1603 compile-time instead of at run-time.)  Case 5 is a place where
1604 normally you I<would> like to use double quotes, except that in this
1605 particular situation, you can just use symbolic references instead, as
1606 in case 6.
1607
1608 C<eval BLOCK> does I<not> count as a loop, so the loop control statements
1609 C<next>, C<last>, or C<redo> cannot be used to leave or restart the block.
1610
1611 Note that as a very special case, an C<eval ''> executed within the C<DB>
1612 package doesn't see the usual surrounding lexical scope, but rather the
1613 scope of the first non-DB piece of code that called it. You don't normally
1614 need to worry about this unless you are writing a Perl debugger.
1615
1616 =item exec LIST
1617 X<exec> X<execute>
1618
1619 =item exec PROGRAM LIST
1620
1621 The C<exec> function executes a system command I<and never returns>--
1622 use C<system> instead of C<exec> if you want it to return.  It fails and
1623 returns false only if the command does not exist I<and> it is executed
1624 directly instead of via your system's command shell (see below).
1625
1626 Since it's a common mistake to use C<exec> instead of C<system>, Perl
1627 warns you if there is a following statement which isn't C<die>, C<warn>,
1628 or C<exit> (if C<-w> is set  -  but you always do that).   If you
1629 I<really> want to follow an C<exec> with some other statement, you
1630 can use one of these styles to avoid the warning:
1631
1632     exec ('foo')   or print STDERR "couldn't exec foo: $!";
1633     { exec ('foo') }; print STDERR "couldn't exec foo: $!";
1634
1635 If there is more than one argument in LIST, or if LIST is an array
1636 with more than one value, calls execvp(3) with the arguments in LIST.
1637 If there is only one scalar argument or an array with one element in it,
1638 the argument is checked for shell metacharacters, and if there are any,
1639 the entire argument is passed to the system's command shell for parsing
1640 (this is C</bin/sh -c> on Unix platforms, but varies on other platforms).
1641 If there are no shell metacharacters in the argument, it is split into
1642 words and passed directly to C<execvp>, which is more efficient.
1643 Examples:
1644
1645     exec '/bin/echo', 'Your arguments are: ', @ARGV;
1646     exec "sort $outfile | uniq";
1647
1648 If you don't really want to execute the first argument, but want to lie
1649 to the program you are executing about its own name, you can specify
1650 the program you actually want to run as an "indirect object" (without a
1651 comma) in front of the LIST.  (This always forces interpretation of the
1652 LIST as a multivalued list, even if there is only a single scalar in
1653 the list.)  Example:
1654
1655     $shell = '/bin/csh';
1656     exec $shell '-sh';          # pretend it's a login shell
1657
1658 or, more directly,
1659
1660     exec {'/bin/csh'} '-sh';    # pretend it's a login shell
1661
1662 When the arguments get executed via the system shell, results will
1663 be subject to its quirks and capabilities.  See L<perlop/"`STRING`">
1664 for details.
1665
1666 Using an indirect object with C<exec> or C<system> is also more
1667 secure.  This usage (which also works fine with system()) forces
1668 interpretation of the arguments as a multivalued list, even if the
1669 list had just one argument.  That way you're safe from the shell
1670 expanding wildcards or splitting up words with whitespace in them.
1671
1672     @args = ( "echo surprise" );
1673
1674     exec @args;               # subject to shell escapes
1675                                 # if @args == 1
1676     exec { $args[0] } @args;  # safe even with one-arg list
1677
1678 The first version, the one without the indirect object, ran the I<echo>
1679 program, passing it C<"surprise"> an argument.  The second version
1680 didn't--it tried to run a program literally called I<"echo surprise">,
1681 didn't find it, and set C<$?> to a non-zero value indicating failure.
1682
1683 Beginning with v5.6.0, Perl will attempt to flush all files opened for
1684 output before the exec, but this may not be supported on some platforms
1685 (see L<perlport>).  To be safe, you may need to set C<$|> ($AUTOFLUSH
1686 in English) or call the C<autoflush()> method of C<IO::Handle> on any
1687 open handles in order to avoid lost output.
1688
1689 Note that C<exec> will not call your C<END> blocks, nor will it call
1690 any C<DESTROY> methods in your objects.
1691
1692 =item exists EXPR
1693 X<exists> X<autovivification>
1694
1695 Given an expression that specifies a hash element or array element,
1696 returns true if the specified element in the hash or array has ever
1697 been initialized, even if the corresponding value is undefined.  The
1698 element is not autovivified if it doesn't exist.
1699
1700     print "Exists\n"    if exists $hash{$key};
1701     print "Defined\n"   if defined $hash{$key};
1702     print "True\n"      if $hash{$key};
1703
1704     print "Exists\n"    if exists $array[$index];
1705     print "Defined\n"   if defined $array[$index];
1706     print "True\n"      if $array[$index];
1707
1708 A hash or array element can be true only if it's defined, and defined if
1709 it exists, but the reverse doesn't necessarily hold true.
1710
1711 Given an expression that specifies the name of a subroutine,
1712 returns true if the specified subroutine has ever been declared, even
1713 if it is undefined.  Mentioning a subroutine name for exists or defined
1714 does not count as declaring it.  Note that a subroutine which does not
1715 exist may still be callable: its package may have an C<AUTOLOAD>
1716 method that makes it spring into existence the first time that it is
1717 called -- see L<perlsub>.
1718
1719     print "Exists\n"    if exists &subroutine;
1720     print "Defined\n"   if defined &subroutine;
1721
1722 Note that the EXPR can be arbitrarily complicated as long as the final
1723 operation is a hash or array key lookup or subroutine name:
1724
1725     if (exists $ref->{A}->{B}->{$key})  { }
1726     if (exists $hash{A}{B}{$key})       { }
1727
1728     if (exists $ref->{A}->{B}->[$ix])   { }
1729     if (exists $hash{A}{B}[$ix])        { }
1730
1731     if (exists &{$ref->{A}{B}{$key}})   { }
1732
1733 Although the deepest nested array or hash will not spring into existence
1734 just because its existence was tested, any intervening ones will.
1735 Thus C<< $ref->{"A"} >> and C<< $ref->{"A"}->{"B"} >> will spring
1736 into existence due to the existence test for the $key element above.
1737 This happens anywhere the arrow operator is used, including even:
1738
1739     undef $ref;
1740     if (exists $ref->{"Some key"})      { }
1741     print $ref;             # prints HASH(0x80d3d5c)
1742
1743 This surprising autovivification in what does not at first--or even
1744 second--glance appear to be an lvalue context may be fixed in a future
1745 release.
1746
1747 Use of a subroutine call, rather than a subroutine name, as an argument
1748 to exists() is an error.
1749
1750     exists &sub;        # OK
1751     exists &sub();      # Error
1752
1753 =item exit EXPR
1754 X<exit> X<terminate> X<abort>
1755
1756 =item exit
1757
1758 Evaluates EXPR and exits immediately with that value.    Example:
1759
1760     $ans = <STDIN>;
1761     exit 0 if $ans =~ /^[Xx]/;
1762
1763 See also C<die>.  If EXPR is omitted, exits with C<0> status.  The only
1764 universally recognized values for EXPR are C<0> for success and C<1>
1765 for error; other values are subject to interpretation depending on the
1766 environment in which the Perl program is running.  For example, exiting
1767 69 (EX_UNAVAILABLE) from a I<sendmail> incoming-mail filter will cause
1768 the mailer to return the item undelivered, but that's not true everywhere.
1769
1770 Don't use C<exit> to abort a subroutine if there's any chance that
1771 someone might want to trap whatever error happened.  Use C<die> instead,
1772 which can be trapped by an C<eval>.
1773
1774 The exit() function does not always exit immediately.  It calls any
1775 defined C<END> routines first, but these C<END> routines may not
1776 themselves abort the exit.  Likewise any object destructors that need to
1777 be called are called before the real exit.  If this is a problem, you
1778 can call C<POSIX:_exit($status)> to avoid END and destructor processing.
1779 See L<perlmod> for details.
1780
1781 =item exp EXPR
1782 X<exp> X<exponential> X<antilog> X<antilogarithm> X<e>
1783
1784 =item exp
1785
1786 Returns I<e> (the natural logarithm base) to the power of EXPR.
1787 If EXPR is omitted, gives C<exp($_)>.
1788
1789 =item fcntl FILEHANDLE,FUNCTION,SCALAR
1790 X<fcntl>
1791
1792 Implements the fcntl(2) function.  You'll probably have to say
1793
1794     use Fcntl;
1795
1796 first to get the correct constant definitions.  Argument processing and
1797 value return works just like C<ioctl> below.
1798 For example:
1799
1800     use Fcntl;
1801     fcntl($filehandle, F_GETFL, $packed_return_buffer)
1802         or die "can't fcntl F_GETFL: $!";
1803
1804 You don't have to check for C<defined> on the return from C<fcntl>.
1805 Like C<ioctl>, it maps a C<0> return from the system call into
1806 C<"0 but true"> in Perl.  This string is true in boolean context and C<0>
1807 in numeric context.  It is also exempt from the normal B<-w> warnings
1808 on improper numeric conversions.
1809
1810 Note that C<fcntl> will produce a fatal error if used on a machine that
1811 doesn't implement fcntl(2).  See the Fcntl module or your fcntl(2)
1812 manpage to learn what functions are available on your system.
1813
1814 Here's an example of setting a filehandle named C<REMOTE> to be
1815 non-blocking at the system level.  You'll have to negotiate C<$|>
1816 on your own, though.
1817
1818     use Fcntl qw(F_GETFL F_SETFL O_NONBLOCK);
1819
1820     $flags = fcntl(REMOTE, F_GETFL, 0)
1821                 or die "Can't get flags for the socket: $!\n";
1822
1823     $flags = fcntl(REMOTE, F_SETFL, $flags | O_NONBLOCK)
1824                 or die "Can't set flags for the socket: $!\n";
1825
1826 =item fileno FILEHANDLE
1827 X<fileno>
1828
1829 Returns the file descriptor for a filehandle, or undefined if the
1830 filehandle is not open.  This is mainly useful for constructing
1831 bitmaps for C<select> and low-level POSIX tty-handling operations.
1832 If FILEHANDLE is an expression, the value is taken as an indirect
1833 filehandle, generally its name.
1834
1835 You can use this to find out whether two handles refer to the
1836 same underlying descriptor:
1837
1838     if (fileno(THIS) == fileno(THAT)) {
1839         print "THIS and THAT are dups\n";
1840     }
1841
1842 (Filehandles connected to memory objects via new features of C<open> may
1843 return undefined even though they are open.)
1844
1845
1846 =item flock FILEHANDLE,OPERATION
1847 X<flock> X<lock> X<locking>
1848
1849 Calls flock(2), or an emulation of it, on FILEHANDLE.  Returns true
1850 for success, false on failure.  Produces a fatal error if used on a
1851 machine that doesn't implement flock(2), fcntl(2) locking, or lockf(3).
1852 C<flock> is Perl's portable file locking interface, although it locks
1853 only entire files, not records.
1854
1855 Two potentially non-obvious but traditional C<flock> semantics are
1856 that it waits indefinitely until the lock is granted, and that its locks
1857 B<merely advisory>.  Such discretionary locks are more flexible, but offer
1858 fewer guarantees.  This means that programs that do not also use C<flock>
1859 may modify files locked with C<flock>.  See L<perlport>, 
1860 your port's specific documentation, or your system-specific local manpages
1861 for details.  It's best to assume traditional behavior if you're writing
1862 portable programs.  (But if you're not, you should as always feel perfectly
1863 free to write for your own system's idiosyncrasies (sometimes called
1864 "features").  Slavish adherence to portability concerns shouldn't get
1865 in the way of your getting your job done.)
1866
1867 OPERATION is one of LOCK_SH, LOCK_EX, or LOCK_UN, possibly combined with
1868 LOCK_NB.  These constants are traditionally valued 1, 2, 8 and 4, but
1869 you can use the symbolic names if you import them from the Fcntl module,
1870 either individually, or as a group using the ':flock' tag.  LOCK_SH
1871 requests a shared lock, LOCK_EX requests an exclusive lock, and LOCK_UN
1872 releases a previously requested lock.  If LOCK_NB is bitwise-or'ed with
1873 LOCK_SH or LOCK_EX then C<flock> will return immediately rather than blocking
1874 waiting for the lock (check the return status to see if you got it).
1875
1876 To avoid the possibility of miscoordination, Perl now flushes FILEHANDLE
1877 before locking or unlocking it.
1878
1879 Note that the emulation built with lockf(3) doesn't provide shared
1880 locks, and it requires that FILEHANDLE be open with write intent.  These
1881 are the semantics that lockf(3) implements.  Most if not all systems
1882 implement lockf(3) in terms of fcntl(2) locking, though, so the
1883 differing semantics shouldn't bite too many people.
1884
1885 Note that the fcntl(2) emulation of flock(3) requires that FILEHANDLE
1886 be open with read intent to use LOCK_SH and requires that it be open
1887 with write intent to use LOCK_EX.
1888
1889 Note also that some versions of C<flock> cannot lock things over the
1890 network; you would need to use the more system-specific C<fcntl> for
1891 that.  If you like you can force Perl to ignore your system's flock(2)
1892 function, and so provide its own fcntl(2)-based emulation, by passing
1893 the switch C<-Ud_flock> to the F<Configure> program when you configure
1894 perl.
1895
1896 Here's a mailbox appender for BSD systems.
1897
1898     use Fcntl ':flock'; # import LOCK_* constants
1899
1900     sub lock {
1901         flock(MBOX,LOCK_EX);
1902         # and, in case someone appended
1903         # while we were waiting...
1904         seek(MBOX, 0, 2);
1905     }
1906
1907     sub unlock {
1908         flock(MBOX,LOCK_UN);
1909     }
1910
1911     open(MBOX, ">>/usr/spool/mail/$ENV{'USER'}")
1912             or die "Can't open mailbox: $!";
1913
1914     lock();
1915     print MBOX $msg,"\n\n";
1916     unlock();
1917
1918 On systems that support a real flock(), locks are inherited across fork()
1919 calls, whereas those that must resort to the more capricious fcntl()
1920 function lose the locks, making it harder to write servers.
1921
1922 See also L<DB_File> for other flock() examples.
1923
1924 =item fork
1925 X<fork> X<child> X<parent>
1926
1927 Does a fork(2) system call to create a new process running the
1928 same program at the same point.  It returns the child pid to the
1929 parent process, C<0> to the child process, or C<undef> if the fork is
1930 unsuccessful.  File descriptors (and sometimes locks on those descriptors)
1931 are shared, while everything else is copied.  On most systems supporting
1932 fork(), great care has gone into making it extremely efficient (for
1933 example, using copy-on-write technology on data pages), making it the
1934 dominant paradigm for multitasking over the last few decades.
1935
1936 Beginning with v5.6.0, Perl will attempt to flush all files opened for
1937 output before forking the child process, but this may not be supported
1938 on some platforms (see L<perlport>).  To be safe, you may need to set
1939 C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method of
1940 C<IO::Handle> on any open handles in order to avoid duplicate output.
1941
1942 If you C<fork> without ever waiting on your children, you will
1943 accumulate zombies.  On some systems, you can avoid this by setting
1944 C<$SIG{CHLD}> to C<"IGNORE">.  See also L<perlipc> for more examples of
1945 forking and reaping moribund children.
1946
1947 Note that if your forked child inherits system file descriptors like
1948 STDIN and STDOUT that are actually connected by a pipe or socket, even
1949 if you exit, then the remote server (such as, say, a CGI script or a
1950 backgrounded job launched from a remote shell) won't think you're done.
1951 You should reopen those to F</dev/null> if it's any issue.
1952
1953 =item format
1954 X<format>
1955
1956 Declare a picture format for use by the C<write> function.  For
1957 example:
1958
1959     format Something =
1960         Test: @<<<<<<<< @||||| @>>>>>
1961               $str,     $%,    '$' . int($num)
1962     .
1963
1964     $str = "widget";
1965     $num = $cost/$quantity;
1966     $~ = 'Something';
1967     write;
1968
1969 See L<perlform> for many details and examples.
1970
1971 =item formline PICTURE,LIST
1972 X<formline>
1973
1974 This is an internal function used by C<format>s, though you may call it,
1975 too.  It formats (see L<perlform>) a list of values according to the
1976 contents of PICTURE, placing the output into the format output
1977 accumulator, C<$^A> (or C<$ACCUMULATOR> in English).
1978 Eventually, when a C<write> is done, the contents of
1979 C<$^A> are written to some filehandle.  You could also read C<$^A>
1980 and then set C<$^A> back to C<"">.  Note that a format typically
1981 does one C<formline> per line of form, but the C<formline> function itself
1982 doesn't care how many newlines are embedded in the PICTURE.  This means
1983 that the C<~> and C<~~> tokens will treat the entire PICTURE as a single line.
1984 You may therefore need to use multiple formlines to implement a single
1985 record format, just like the format compiler.
1986
1987 Be careful if you put double quotes around the picture, because an C<@>
1988 character may be taken to mean the beginning of an array name.
1989 C<formline> always returns true.  See L<perlform> for other examples.
1990
1991 =item getc FILEHANDLE
1992 X<getc> X<getchar>
1993
1994 =item getc
1995
1996 Returns the next character from the input file attached to FILEHANDLE,
1997 or the undefined value at end of file, or if there was an error (in
1998 the latter case C<$!> is set).  If FILEHANDLE is omitted, reads from
1999 STDIN.  This is not particularly efficient.  However, it cannot be
2000 used by itself to fetch single characters without waiting for the user
2001 to hit enter.  For that, try something more like:
2002
2003     if ($BSD_STYLE) {
2004         system "stty cbreak </dev/tty >/dev/tty 2>&1";
2005     }
2006     else {
2007         system "stty", '-icanon', 'eol', "\001";
2008     }
2009
2010     $key = getc(STDIN);
2011
2012     if ($BSD_STYLE) {
2013         system "stty -cbreak </dev/tty >/dev/tty 2>&1";
2014     }
2015     else {
2016         system "stty", 'icanon', 'eol', '^@'; # ASCII null
2017     }
2018     print "\n";
2019
2020 Determination of whether $BSD_STYLE should be set
2021 is left as an exercise to the reader.
2022
2023 The C<POSIX::getattr> function can do this more portably on
2024 systems purporting POSIX compliance.  See also the C<Term::ReadKey>
2025 module from your nearest CPAN site; details on CPAN can be found on
2026 L<perlmodlib/CPAN>.
2027
2028 =item getlogin
2029 X<getlogin> X<login>
2030
2031 This implements the C library function of the same name, which on most
2032 systems returns the current login from F</etc/utmp>, if any.  If null,
2033 use C<getpwuid>.
2034
2035     $login = getlogin || getpwuid($<) || "Kilroy";
2036
2037 Do not consider C<getlogin> for authentication: it is not as
2038 secure as C<getpwuid>.
2039
2040 =item getpeername SOCKET
2041 X<getpeername> X<peer>
2042
2043 Returns the packed sockaddr address of other end of the SOCKET connection.
2044
2045     use Socket;
2046     $hersockaddr    = getpeername(SOCK);
2047     ($port, $iaddr) = sockaddr_in($hersockaddr);
2048     $herhostname    = gethostbyaddr($iaddr, AF_INET);
2049     $herstraddr     = inet_ntoa($iaddr);
2050
2051 =item getpgrp PID
2052 X<getpgrp> X<group>
2053
2054 Returns the current process group for the specified PID.  Use
2055 a PID of C<0> to get the current process group for the
2056 current process.  Will raise an exception if used on a machine that
2057 doesn't implement getpgrp(2).  If PID is omitted, returns process
2058 group of current process.  Note that the POSIX version of C<getpgrp>
2059 does not accept a PID argument, so only C<PID==0> is truly portable.
2060
2061 =item getppid
2062 X<getppid> X<parent> X<pid>
2063
2064 Returns the process id of the parent process.
2065
2066 Note for Linux users: on Linux, the C functions C<getpid()> and
2067 C<getppid()> return different values from different threads. In order to
2068 be portable, this behavior is not reflected by the perl-level function
2069 C<getppid()>, that returns a consistent value across threads. If you want
2070 to call the underlying C<getppid()>, you may use the CPAN module
2071 C<Linux::Pid>.
2072
2073 =item getpriority WHICH,WHO
2074 X<getpriority> X<priority> X<nice>
2075
2076 Returns the current priority for a process, a process group, or a user.
2077 (See L<getpriority(2)>.)  Will raise a fatal exception if used on a
2078 machine that doesn't implement getpriority(2).
2079
2080 =item getpwnam NAME
2081 X<getpwnam> X<getgrnam> X<gethostbyname> X<getnetbyname> X<getprotobyname>
2082 X<getpwuid> X<getgrgid> X<getservbyname> X<gethostbyaddr> X<getnetbyaddr>
2083 X<getprotobynumber> X<getservbyport> X<getpwent> X<getgrent> X<gethostent>
2084 X<getnetent> X<getprotoent> X<getservent> X<setpwent> X<setgrent> X<sethostent>
2085 X<setnetent> X<setprotoent> X<setservent> X<endpwent> X<endgrent> X<endhostent>
2086 X<endnetent> X<endprotoent> X<endservent> 
2087
2088 =item getgrnam NAME
2089
2090 =item gethostbyname NAME
2091
2092 =item getnetbyname NAME
2093
2094 =item getprotobyname NAME
2095
2096 =item getpwuid UID
2097
2098 =item getgrgid GID
2099
2100 =item getservbyname NAME,PROTO
2101
2102 =item gethostbyaddr ADDR,ADDRTYPE
2103
2104 =item getnetbyaddr ADDR,ADDRTYPE
2105
2106 =item getprotobynumber NUMBER
2107
2108 =item getservbyport PORT,PROTO
2109
2110 =item getpwent
2111
2112 =item getgrent
2113
2114 =item gethostent
2115
2116 =item getnetent
2117
2118 =item getprotoent
2119
2120 =item getservent
2121
2122 =item setpwent
2123
2124 =item setgrent
2125
2126 =item sethostent STAYOPEN
2127
2128 =item setnetent STAYOPEN
2129
2130 =item setprotoent STAYOPEN
2131
2132 =item setservent STAYOPEN
2133
2134 =item endpwent
2135
2136 =item endgrent
2137
2138 =item endhostent
2139
2140 =item endnetent
2141
2142 =item endprotoent
2143
2144 =item endservent
2145
2146 These routines perform the same functions as their counterparts in the
2147 system library.  In list context, the return values from the
2148 various get routines are as follows:
2149
2150     ($name,$passwd,$uid,$gid,
2151        $quota,$comment,$gcos,$dir,$shell,$expire) = getpw*
2152     ($name,$passwd,$gid,$members) = getgr*
2153     ($name,$aliases,$addrtype,$length,@addrs) = gethost*
2154     ($name,$aliases,$addrtype,$net) = getnet*
2155     ($name,$aliases,$proto) = getproto*
2156     ($name,$aliases,$port,$proto) = getserv*
2157
2158 (If the entry doesn't exist you get a null list.)
2159
2160 The exact meaning of the $gcos field varies but it usually contains
2161 the real name of the user (as opposed to the login name) and other
2162 information pertaining to the user.  Beware, however, that in many
2163 system users are able to change this information and therefore it
2164 cannot be trusted and therefore the $gcos is tainted (see
2165 L<perlsec>).  The $passwd and $shell, user's encrypted password and
2166 login shell, are also tainted, because of the same reason.
2167
2168 In scalar context, you get the name, unless the function was a
2169 lookup by name, in which case you get the other thing, whatever it is.
2170 (If the entry doesn't exist you get the undefined value.)  For example:
2171
2172     $uid   = getpwnam($name);
2173     $name  = getpwuid($num);
2174     $name  = getpwent();
2175     $gid   = getgrnam($name);
2176     $name  = getgrgid($num);
2177     $name  = getgrent();
2178     #etc.
2179
2180 In I<getpw*()> the fields $quota, $comment, and $expire are special
2181 cases in the sense that in many systems they are unsupported.  If the
2182 $quota is unsupported, it is an empty scalar.  If it is supported, it
2183 usually encodes the disk quota.  If the $comment field is unsupported,
2184 it is an empty scalar.  If it is supported it usually encodes some
2185 administrative comment about the user.  In some systems the $quota
2186 field may be $change or $age, fields that have to do with password
2187 aging.  In some systems the $comment field may be $class.  The $expire
2188 field, if present, encodes the expiration period of the account or the
2189 password.  For the availability and the exact meaning of these fields
2190 in your system, please consult your getpwnam(3) documentation and your
2191 F<pwd.h> file.  You can also find out from within Perl what your
2192 $quota and $comment fields mean and whether you have the $expire field
2193 by using the C<Config> module and the values C<d_pwquota>, C<d_pwage>,
2194 C<d_pwchange>, C<d_pwcomment>, and C<d_pwexpire>.  Shadow password
2195 files are only supported if your vendor has implemented them in the
2196 intuitive fashion that calling the regular C library routines gets the
2197 shadow versions if you're running under privilege or if there exists
2198 the shadow(3) functions as found in System V (this includes Solaris
2199 and Linux.)  Those systems that implement a proprietary shadow password
2200 facility are unlikely to be supported.
2201
2202 The $members value returned by I<getgr*()> is a space separated list of
2203 the login names of the members of the group.
2204
2205 For the I<gethost*()> functions, if the C<h_errno> variable is supported in
2206 C, it will be returned to you via C<$?> if the function call fails.  The
2207 C<@addrs> value returned by a successful call is a list of the raw
2208 addresses returned by the corresponding system library call.  In the
2209 Internet domain, each address is four bytes long and you can unpack it
2210 by saying something like:
2211
2212     ($a,$b,$c,$d) = unpack('W4',$addr[0]);
2213
2214 The Socket library makes this slightly easier:
2215
2216     use Socket;
2217     $iaddr = inet_aton("127.1"); # or whatever address
2218     $name  = gethostbyaddr($iaddr, AF_INET);
2219
2220     # or going the other way
2221     $straddr = inet_ntoa($iaddr);
2222
2223 If you get tired of remembering which element of the return list
2224 contains which return value, by-name interfaces are provided
2225 in standard modules: C<File::stat>, C<Net::hostent>, C<Net::netent>,
2226 C<Net::protoent>, C<Net::servent>, C<Time::gmtime>, C<Time::localtime>,
2227 and C<User::grent>.  These override the normal built-ins, supplying
2228 versions that return objects with the appropriate names
2229 for each field.  For example:
2230
2231    use File::stat;
2232    use User::pwent;
2233    $is_his = (stat($filename)->uid == pwent($whoever)->uid);
2234
2235 Even though it looks like they're the same method calls (uid),
2236 they aren't, because a C<File::stat> object is different from
2237 a C<User::pwent> object.
2238
2239 =item getsockname SOCKET
2240 X<getsockname>
2241
2242 Returns the packed sockaddr address of this end of the SOCKET connection,
2243 in case you don't know the address because you have several different
2244 IPs that the connection might have come in on.
2245
2246     use Socket;
2247     $mysockaddr = getsockname(SOCK);
2248     ($port, $myaddr) = sockaddr_in($mysockaddr);
2249     printf "Connect to %s [%s]\n",
2250        scalar gethostbyaddr($myaddr, AF_INET),
2251        inet_ntoa($myaddr);
2252
2253 =item getsockopt SOCKET,LEVEL,OPTNAME
2254 X<getsockopt>
2255
2256 Queries the option named OPTNAME associated with SOCKET at a given LEVEL.
2257 Options may exist at multiple protocol levels depending on the socket
2258 type, but at least the uppermost socket level SOL_SOCKET (defined in the
2259 C<Socket> module) will exist. To query options at another level the
2260 protocol number of the appropriate protocol controlling the option
2261 should be supplied. For example, to indicate that an option is to be
2262 interpreted by the TCP protocol, LEVEL should be set to the protocol
2263 number of TCP, which you can get using getprotobyname.
2264
2265 The call returns a packed string representing the requested socket option,
2266 or C<undef> if there is an error (the error reason will be in $!). What
2267 exactly is in the packed string depends in the LEVEL and OPTNAME, consult
2268 your system documentation for details. A very common case however is that
2269 the option is an integer, in which case the result will be a packed
2270 integer which you can decode using unpack with the C<i> (or C<I>) format.
2271
2272 An example testing if Nagle's algorithm is turned on on a socket:
2273
2274     use Socket qw(:all);
2275
2276     defined(my $tcp = getprotobyname("tcp"))
2277         or die "Could not determine the protocol number for tcp";
2278     # my $tcp = IPPROTO_TCP; # Alternative
2279     my $packed = getsockopt($socket, $tcp, TCP_NODELAY)
2280         or die "Could not query TCP_NODELAY socket option: $!";
2281     my $nodelay = unpack("I", $packed);
2282     print "Nagle's algorithm is turned ", $nodelay ? "off\n" : "on\n";
2283
2284
2285 =item glob EXPR
2286 X<glob> X<wildcard> X<filename, expansion> X<expand>
2287
2288 =item glob
2289
2290 In list context, returns a (possibly empty) list of filename expansions on
2291 the value of EXPR such as the standard Unix shell F</bin/csh> would do. In
2292 scalar context, glob iterates through such filename expansions, returning
2293 undef when the list is exhausted. This is the internal function
2294 implementing the C<< <*.c> >> operator, but you can use it directly. If
2295 EXPR is omitted, C<$_> is used.  The C<< <*.c> >> operator is discussed in
2296 more detail in L<perlop/"I/O Operators">.
2297
2298 Beginning with v5.6.0, this operator is implemented using the standard
2299 C<File::Glob> extension.  See L<File::Glob> for details.
2300
2301 =item gmtime EXPR
2302 X<gmtime> X<UTC> X<Greenwich>
2303
2304 =item gmtime
2305
2306 Converts a time as returned by the time function to an 9-element list
2307 with the time localized for the standard Greenwich time zone.
2308 Typically used as follows:
2309
2310     #  0    1    2     3     4    5     6     7     8
2311     ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst) =
2312                                             gmtime(time);
2313
2314 All list elements are numeric, and come straight out of the C `struct
2315 tm'.  $sec, $min, and $hour are the seconds, minutes, and hours of the
2316 specified time.  $mday is the day of the month, and $mon is the month
2317 itself, in the range C<0..11> with 0 indicating January and 11
2318 indicating December.  $year is the number of years since 1900.  That
2319 is, $year is C<123> in year 2023.  $wday is the day of the week, with
2320 0 indicating Sunday and 3 indicating Wednesday.  $yday is the day of
2321 the year, in the range C<0..364> (or C<0..365> in leap years).  $isdst
2322 is always C<0>.
2323
2324 Note that the $year element is I<not> simply the last two digits of
2325 the year.  If you assume it is then you create non-Y2K-compliant
2326 programs--and you wouldn't want to do that, would you?
2327
2328 The proper way to get a complete 4-digit year is simply:
2329
2330         $year += 1900;
2331
2332 And to get the last two digits of the year (e.g., '01' in 2001) do:
2333
2334         $year = sprintf("%02d", $year % 100);
2335
2336 If EXPR is omitted, C<gmtime()> uses the current time (C<gmtime(time)>).
2337
2338 In scalar context, C<gmtime()> returns the ctime(3) value:
2339
2340     $now_string = gmtime;  # e.g., "Thu Oct 13 04:54:34 1994"
2341
2342 If you need local time instead of GMT use the L</localtime> builtin. 
2343 See also the C<timegm> function provided by the C<Time::Local> module,
2344 and the strftime(3) and mktime(3) functions available via the L<POSIX> module.
2345
2346 This scalar value is B<not> locale dependent (see L<perllocale>), but is
2347 instead a Perl builtin.  To get somewhat similar but locale dependent date
2348 strings, see the example in L</localtime>.
2349
2350 See L<perlport/gmtime> for portability concerns.
2351
2352 =item goto LABEL
2353 X<goto> X<jump> X<jmp>
2354
2355 =item goto EXPR
2356
2357 =item goto &NAME
2358
2359 The C<goto-LABEL> form finds the statement labeled with LABEL and resumes
2360 execution there.  It may not be used to go into any construct that
2361 requires initialization, such as a subroutine or a C<foreach> loop.  It
2362 also can't be used to go into a construct that is optimized away,
2363 or to get out of a block or subroutine given to C<sort>.
2364 It can be used to go almost anywhere else within the dynamic scope,
2365 including out of subroutines, but it's usually better to use some other
2366 construct such as C<last> or C<die>.  The author of Perl has never felt the
2367 need to use this form of C<goto> (in Perl, that is--C is another matter).
2368 (The difference being that C does not offer named loops combined with
2369 loop control.  Perl does, and this replaces most structured uses of C<goto>
2370 in other languages.)
2371
2372 The C<goto-EXPR> form expects a label name, whose scope will be resolved
2373 dynamically.  This allows for computed C<goto>s per FORTRAN, but isn't
2374 necessarily recommended if you're optimizing for maintainability:
2375
2376     goto ("FOO", "BAR", "GLARCH")[$i];
2377
2378 The C<goto-&NAME> form is quite different from the other forms of
2379 C<goto>.  In fact, it isn't a goto in the normal sense at all, and
2380 doesn't have the stigma associated with other gotos.  Instead, it
2381 exits the current subroutine (losing any changes set by local()) and
2382 immediately calls in its place the named subroutine using the current
2383 value of @_.  This is used by C<AUTOLOAD> subroutines that wish to
2384 load another subroutine and then pretend that the other subroutine had
2385 been called in the first place (except that any modifications to C<@_>
2386 in the current subroutine are propagated to the other subroutine.)
2387 After the C<goto>, not even C<caller> will be able to tell that this
2388 routine was called first.
2389
2390 NAME needn't be the name of a subroutine; it can be a scalar variable
2391 containing a code reference, or a block that evaluates to a code
2392 reference.
2393
2394 =item grep BLOCK LIST
2395 X<grep>
2396
2397 =item grep EXPR,LIST
2398
2399 This is similar in spirit to, but not the same as, grep(1) and its
2400 relatives.  In particular, it is not limited to using regular expressions.
2401
2402 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
2403 C<$_> to each element) and returns the list value consisting of those
2404 elements for which the expression evaluated to true.  In scalar
2405 context, returns the number of times the expression was true.
2406
2407     @foo = grep(!/^#/, @bar);    # weed out comments
2408
2409 or equivalently,
2410
2411     @foo = grep {!/^#/} @bar;    # weed out comments
2412
2413 Note that C<$_> is an alias to the list value, so it can be used to
2414 modify the elements of the LIST.  While this is useful and supported,
2415 it can cause bizarre results if the elements of LIST are not variables.
2416 Similarly, grep returns aliases into the original list, much as a for
2417 loop's index variable aliases the list elements.  That is, modifying an
2418 element of a list returned by grep (for example, in a C<foreach>, C<map>
2419 or another C<grep>) actually modifies the element in the original list.
2420 This is usually something to be avoided when writing clear code.
2421
2422 If C<$_> is lexical in the scope where the C<grep> appears (because it has
2423 been declared with C<my $_>) then, in addition to being locally aliased to
2424 the list elements, C<$_> keeps being lexical inside the block; i.e. it
2425 can't be seen from the outside, avoiding any potential side-effects.
2426
2427 See also L</map> for a list composed of the results of the BLOCK or EXPR.
2428
2429 =item hex EXPR
2430 X<hex> X<hexadecimal>
2431
2432 =item hex
2433
2434 Interprets EXPR as a hex string and returns the corresponding value.
2435 (To convert strings that might start with either C<0>, C<0x>, or C<0b>, see
2436 L</oct>.)  If EXPR is omitted, uses C<$_>.
2437
2438     print hex '0xAf'; # prints '175'
2439     print hex 'aF';   # same
2440
2441 Hex strings may only represent integers.  Strings that would cause
2442 integer overflow trigger a warning.  Leading whitespace is not stripped,
2443 unlike oct(). To present something as hex, look into L</printf>,
2444 L</sprintf>, or L</unpack>.
2445
2446 =item import LIST
2447 X<import>
2448
2449 There is no builtin C<import> function.  It is just an ordinary
2450 method (subroutine) defined (or inherited) by modules that wish to export
2451 names to another module.  The C<use> function calls the C<import> method
2452 for the package used.  See also L</use>, L<perlmod>, and L<Exporter>.
2453
2454 =item index STR,SUBSTR,POSITION
2455 X<index> X<indexOf> X<InStr>
2456
2457 =item index STR,SUBSTR
2458
2459 The index function searches for one string within another, but without
2460 the wildcard-like behavior of a full regular-expression pattern match.
2461 It returns the position of the first occurrence of SUBSTR in STR at
2462 or after POSITION.  If POSITION is omitted, starts searching from the
2463 beginning of the string.  POSITION before the beginning of the string
2464 or after its end is treated as if it were the beginning or the end,
2465 respectively.  POSITION and the return value are based at C<0> (or whatever
2466 you've set the C<$[> variable to--but don't do that).  If the substring
2467 is not found, C<index> returns one less than the base, ordinarily C<-1>.
2468
2469 =item int EXPR
2470 X<int> X<integer> X<truncate> X<trunc>
2471
2472 =item int
2473
2474 Returns the integer portion of EXPR.  If EXPR is omitted, uses C<$_>.
2475 You should not use this function for rounding: one because it truncates
2476 towards C<0>, and two because machine representations of floating point
2477 numbers can sometimes produce counterintuitive results.  For example,
2478 C<int(-6.725/0.025)> produces -268 rather than the correct -269; that's
2479 because it's really more like -268.99999999999994315658 instead.  Usually,
2480 the C<sprintf>, C<printf>, or the C<POSIX::floor> and C<POSIX::ceil>
2481 functions will serve you better than will int().
2482
2483 =item ioctl FILEHANDLE,FUNCTION,SCALAR
2484 X<ioctl>
2485
2486 Implements the ioctl(2) function.  You'll probably first have to say
2487
2488     require "sys/ioctl.ph";     # probably in $Config{archlib}/sys/ioctl.ph
2489
2490 to get the correct function definitions.  If F<sys/ioctl.ph> doesn't
2491 exist or doesn't have the correct definitions you'll have to roll your
2492 own, based on your C header files such as F<< <sys/ioctl.h> >>.
2493 (There is a Perl script called B<h2ph> that comes with the Perl kit that
2494 may help you in this, but it's nontrivial.)  SCALAR will be read and/or
2495 written depending on the FUNCTION--a pointer to the string value of SCALAR
2496 will be passed as the third argument of the actual C<ioctl> call.  (If SCALAR
2497 has no string value but does have a numeric value, that value will be
2498 passed rather than a pointer to the string value.  To guarantee this to be
2499 true, add a C<0> to the scalar before using it.)  The C<pack> and C<unpack>
2500 functions may be needed to manipulate the values of structures used by
2501 C<ioctl>.
2502
2503 The return value of C<ioctl> (and C<fcntl>) is as follows:
2504
2505         if OS returns:          then Perl returns:
2506             -1                    undefined value
2507              0                  string "0 but true"
2508         anything else               that number
2509
2510 Thus Perl returns true on success and false on failure, yet you can
2511 still easily determine the actual value returned by the operating
2512 system:
2513
2514     $retval = ioctl(...) || -1;
2515     printf "System returned %d\n", $retval;
2516
2517 The special string C<"0 but true"> is exempt from B<-w> complaints
2518 about improper numeric conversions.
2519
2520 =item join EXPR,LIST
2521 X<join>
2522
2523 Joins the separate strings of LIST into a single string with fields
2524 separated by the value of EXPR, and returns that new string.  Example:
2525
2526     $rec = join(':', $login,$passwd,$uid,$gid,$gcos,$home,$shell);
2527
2528 Beware that unlike C<split>, C<join> doesn't take a pattern as its
2529 first argument.  Compare L</split>.
2530
2531 =item keys HASH
2532 X<keys> X<key>
2533
2534 Returns a list consisting of all the keys of the named hash.
2535 (In scalar context, returns the number of keys.)
2536
2537 The keys are returned in an apparently random order.  The actual
2538 random order is subject to change in future versions of perl, but it
2539 is guaranteed to be the same order as either the C<values> or C<each>
2540 function produces (given that the hash has not been modified).  Since
2541 Perl 5.8.1 the ordering is different even between different runs of
2542 Perl for security reasons (see L<perlsec/"Algorithmic Complexity
2543 Attacks">).
2544
2545 As a side effect, calling keys() resets the HASH's internal iterator
2546 (see L</each>).  In particular, calling keys() in void context resets
2547 the iterator with no other overhead.
2548
2549 Here is yet another way to print your environment:
2550
2551     @keys = keys %ENV;
2552     @values = values %ENV;
2553     while (@keys) {
2554         print pop(@keys), '=', pop(@values), "\n";
2555     }
2556
2557 or how about sorted by key:
2558
2559     foreach $key (sort(keys %ENV)) {
2560         print $key, '=', $ENV{$key}, "\n";
2561     }
2562
2563 The returned values are copies of the original keys in the hash, so
2564 modifying them will not affect the original hash.  Compare L</values>.
2565
2566 To sort a hash by value, you'll need to use a C<sort> function.
2567 Here's a descending numeric sort of a hash by its values:
2568
2569     foreach $key (sort { $hash{$b} <=> $hash{$a} } keys %hash) {
2570         printf "%4d %s\n", $hash{$key}, $key;
2571     }
2572
2573 As an lvalue C<keys> allows you to increase the number of hash buckets
2574 allocated for the given hash.  This can gain you a measure of efficiency if
2575 you know the hash is going to get big.  (This is similar to pre-extending
2576 an array by assigning a larger number to $#array.)  If you say
2577
2578     keys %hash = 200;
2579
2580 then C<%hash> will have at least 200 buckets allocated for it--256 of them,
2581 in fact, since it rounds up to the next power of two.  These
2582 buckets will be retained even if you do C<%hash = ()>, use C<undef
2583 %hash> if you want to free the storage while C<%hash> is still in scope.
2584 You can't shrink the number of buckets allocated for the hash using
2585 C<keys> in this way (but you needn't worry about doing this by accident,
2586 as trying has no effect).
2587
2588 See also C<each>, C<values> and C<sort>.
2589
2590 =item kill SIGNAL, LIST
2591 X<kill> X<signal>
2592
2593 Sends a signal to a list of processes.  Returns the number of
2594 processes successfully signaled (which is not necessarily the
2595 same as the number actually killed).
2596
2597     $cnt = kill 1, $child1, $child2;
2598     kill 9, @goners;
2599
2600 If SIGNAL is zero, no signal is sent to the process, but the kill(2)
2601 system call will check whether it's possible to send a signal to it (that
2602 means, to be brief, that the process is owned by the same user, or we are
2603 the super-user).  This is a useful way to check that a child process is
2604 alive and hasn't changed its UID.  See L<perlport> for notes on the
2605 portability of this construct.
2606
2607 Unlike in the shell, if SIGNAL is negative, it kills
2608 process groups instead of processes.  (On System V, a negative I<PROCESS>
2609 number will also kill process groups, but that's not portable.)  That
2610 means you usually want to use positive not negative signals.  You may also
2611 use a signal name in quotes.
2612
2613 See L<perlipc/"Signals"> for more details.
2614
2615 =item last LABEL
2616 X<last> X<break>
2617
2618 =item last
2619
2620 The C<last> command is like the C<break> statement in C (as used in
2621 loops); it immediately exits the loop in question.  If the LABEL is
2622 omitted, the command refers to the innermost enclosing loop.  The
2623 C<continue> block, if any, is not executed:
2624
2625     LINE: while (<STDIN>) {
2626         last LINE if /^$/;      # exit when done with header
2627         #...
2628     }
2629
2630 C<last> cannot be used to exit a block which returns a value such as
2631 C<eval {}>, C<sub {}> or C<do {}>, and should not be used to exit
2632 a grep() or map() operation.
2633
2634 Note that a block by itself is semantically identical to a loop
2635 that executes once.  Thus C<last> can be used to effect an early
2636 exit out of such a block.
2637
2638 See also L</continue> for an illustration of how C<last>, C<next>, and
2639 C<redo> work.
2640
2641 =item lc EXPR
2642 X<lc> X<lowercase>
2643
2644 =item lc
2645
2646 Returns a lowercased version of EXPR.  This is the internal function
2647 implementing the C<\L> escape in double-quoted strings.  Respects
2648 current LC_CTYPE locale if C<use locale> in force.  See L<perllocale>
2649 and L<perlunicode> for more details about locale and Unicode support.
2650
2651 If EXPR is omitted, uses C<$_>.
2652
2653 =item lcfirst EXPR
2654 X<lcfirst> X<lowercase>
2655
2656 =item lcfirst
2657
2658 Returns the value of EXPR with the first character lowercased.  This
2659 is the internal function implementing the C<\l> escape in
2660 double-quoted strings.  Respects current LC_CTYPE locale if C<use
2661 locale> in force.  See L<perllocale> and L<perlunicode> for more
2662 details about locale and Unicode support.
2663
2664 If EXPR is omitted, uses C<$_>.
2665
2666 =item length EXPR
2667 X<length> X<size>
2668
2669 =item length
2670
2671 Returns the length in I<characters> of the value of EXPR.  If EXPR is
2672 omitted, returns length of C<$_>.  Note that this cannot be used on
2673 an entire array or hash to find out how many elements these have.
2674 For that, use C<scalar @array> and C<scalar keys %hash> respectively.
2675
2676 Note the I<characters>: if the EXPR is in Unicode, you will get the
2677 number of characters, not the number of bytes.  To get the length
2678 in bytes, use C<do { use bytes; length(EXPR) }>, see L<bytes>.
2679
2680 =item link OLDFILE,NEWFILE
2681 X<link>
2682
2683 Creates a new filename linked to the old filename.  Returns true for
2684 success, false otherwise.
2685
2686 =item listen SOCKET,QUEUESIZE
2687 X<listen>
2688
2689 Does the same thing that the listen system call does.  Returns true if
2690 it succeeded, false otherwise.  See the example in
2691 L<perlipc/"Sockets: Client/Server Communication">.
2692
2693 =item local EXPR
2694 X<local>
2695
2696 You really probably want to be using C<my> instead, because C<local> isn't
2697 what most people think of as "local".  See
2698 L<perlsub/"Private Variables via my()"> for details.
2699
2700 A local modifies the listed variables to be local to the enclosing
2701 block, file, or eval.  If more than one value is listed, the list must
2702 be placed in parentheses.  See L<perlsub/"Temporary Values via local()">
2703 for details, including issues with tied arrays and hashes.
2704
2705 =item localtime EXPR
2706 X<localtime>
2707
2708 =item localtime
2709
2710 Converts a time as returned by the time function to a 9-element list
2711 with the time analyzed for the local time zone.  Typically used as
2712 follows:
2713
2714     #  0    1    2     3     4    5     6     7     8
2715     ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst) =
2716                                                 localtime(time);
2717
2718 All list elements are numeric, and come straight out of the C `struct
2719 tm'.  C<$sec>, C<$min>, and C<$hour> are the seconds, minutes, and hours
2720 of the specified time.
2721
2722 C<$mday> is the day of the month, and C<$mon> is the month itself, in
2723 the range C<0..11> with 0 indicating January and 11 indicating December.
2724 This makes it easy to get a month name from a list:
2725
2726     my @abbr = qw( Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec );
2727     print "$abbr[$mon] $mday";
2728     # $mon=9, $mday=18 gives "Oct 18"
2729
2730 C<$year> is the number of years since 1900, not just the last two digits
2731 of the year.  That is, C<$year> is C<123> in year 2023.  The proper way
2732 to get a complete 4-digit year is simply:
2733
2734     $year += 1900;
2735
2736 To get the last two digits of the year (e.g., '01' in 2001) do:
2737
2738     $year = sprintf("%02d", $year % 100);
2739
2740 C<$wday> is the day of the week, with 0 indicating Sunday and 3 indicating
2741 Wednesday.  C<$yday> is the day of the year, in the range C<0..364>
2742 (or C<0..365> in leap years.)
2743
2744 C<$isdst> is true if the specified time occurs during Daylight Saving
2745 Time, false otherwise.
2746
2747 If EXPR is omitted, C<localtime()> uses the current time (C<localtime(time)>).
2748
2749 In scalar context, C<localtime()> returns the ctime(3) value:
2750
2751     $now_string = localtime;  # e.g., "Thu Oct 13 04:54:34 1994"
2752
2753 This scalar value is B<not> locale dependent but is a Perl builtin. For GMT
2754 instead of local time use the L</gmtime> builtin. See also the
2755 C<Time::Local> module (to convert the second, minutes, hours, ... back to
2756 the integer value returned by time()), and the L<POSIX> module's strftime(3)
2757 and mktime(3) functions.
2758
2759 To get somewhat similar but locale dependent date strings, set up your
2760 locale environment variables appropriately (please see L<perllocale>) and
2761 try for example:
2762
2763     use POSIX qw(strftime);
2764     $now_string = strftime "%a %b %e %H:%M:%S %Y", localtime;
2765     # or for GMT formatted appropriately for your locale:
2766     $now_string = strftime "%a %b %e %H:%M:%S %Y", gmtime;
2767
2768 Note that the C<%a> and C<%b>, the short forms of the day of the week
2769 and the month of the year, may not necessarily be three characters wide.
2770
2771 See L<perlport/localtime> for portability concerns.
2772
2773 =item lock THING
2774 X<lock>
2775
2776 This function places an advisory lock on a shared variable, or referenced
2777 object contained in I<THING> until the lock goes out of scope.
2778
2779 lock() is a "weak keyword" : this means that if you've defined a function
2780 by this name (before any calls to it), that function will be called
2781 instead. (However, if you've said C<use threads>, lock() is always a
2782 keyword.) See L<threads>.
2783
2784 =item log EXPR
2785 X<log> X<logarithm> X<e> X<ln> X<base>
2786
2787 =item log
2788
2789 Returns the natural logarithm (base I<e>) of EXPR.  If EXPR is omitted,
2790 returns log of C<$_>.  To get the log of another base, use basic algebra:
2791 The base-N log of a number is equal to the natural log of that number
2792 divided by the natural log of N.  For example:
2793
2794     sub log10 {
2795         my $n = shift;
2796         return log($n)/log(10);
2797     }
2798
2799 See also L</exp> for the inverse operation.
2800
2801 =item lstat EXPR
2802 X<lstat>
2803
2804 =item lstat
2805
2806 Does the same thing as the C<stat> function (including setting the
2807 special C<_> filehandle) but stats a symbolic link instead of the file
2808 the symbolic link points to.  If symbolic links are unimplemented on
2809 your system, a normal C<stat> is done.  For much more detailed
2810 information, please see the documentation for C<stat>.
2811
2812 If EXPR is omitted, stats C<$_>.
2813
2814 =item m//
2815
2816 The match operator.  See L<perlop>.
2817
2818 =item map BLOCK LIST
2819 X<map>
2820
2821 =item map EXPR,LIST
2822
2823 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
2824 C<$_> to each element) and returns the list value composed of the
2825 results of each such evaluation.  In scalar context, returns the
2826 total number of elements so generated.  Evaluates BLOCK or EXPR in
2827 list context, so each element of LIST may produce zero, one, or
2828 more elements in the returned value.
2829
2830     @chars = map(chr, @nums);
2831
2832 translates a list of numbers to the corresponding characters.  And
2833
2834     %hash = map { getkey($_) => $_ } @array;
2835
2836 is just a funny way to write
2837
2838     %hash = ();
2839     foreach $_ (@array) {
2840         $hash{getkey($_)} = $_;
2841     }
2842
2843 Note that C<$_> is an alias to the list value, so it can be used to
2844 modify the elements of the LIST.  While this is useful and supported,
2845 it can cause bizarre results if the elements of LIST are not variables.
2846 Using a regular C<foreach> loop for this purpose would be clearer in
2847 most cases.  See also L</grep> for an array composed of those items of
2848 the original list for which the BLOCK or EXPR evaluates to true.
2849
2850 If C<$_> is lexical in the scope where the C<map> appears (because it has
2851 been declared with C<my $_>) then, in addition to being locally aliased to
2852 the list elements, C<$_> keeps being lexical inside the block; i.e. it
2853 can't be seen from the outside, avoiding any potential side-effects.
2854
2855 C<{> starts both hash references and blocks, so C<map { ...> could be either
2856 the start of map BLOCK LIST or map EXPR, LIST. Because perl doesn't look
2857 ahead for the closing C<}> it has to take a guess at which its dealing with
2858 based what it finds just after the C<{>. Usually it gets it right, but if it
2859 doesn't it won't realize something is wrong until it gets to the C<}> and
2860 encounters the missing (or unexpected) comma. The syntax error will be
2861 reported close to the C<}> but you'll need to change something near the C<{>
2862 such as using a unary C<+> to give perl some help:
2863
2864     %hash = map {  "\L$_", 1  } @array  # perl guesses EXPR.  wrong
2865     %hash = map { +"\L$_", 1  } @array  # perl guesses BLOCK. right
2866     %hash = map { ("\L$_", 1) } @array  # this also works
2867     %hash = map {  lc($_), 1  } @array  # as does this.
2868     %hash = map +( lc($_), 1 ), @array  # this is EXPR and works!
2869
2870     %hash = map  ( lc($_), 1 ), @array  # evaluates to (1, @array)
2871
2872 or to force an anon hash constructor use C<+{>
2873
2874    @hashes = map +{ lc($_), 1 }, @array # EXPR, so needs , at end
2875
2876 and you get list of anonymous hashes each with only 1 entry.
2877
2878 =item mkdir FILENAME,MASK
2879 X<mkdir> X<md> X<directory, create>
2880
2881 =item mkdir FILENAME
2882
2883 =item mkdir
2884
2885 Creates the directory specified by FILENAME, with permissions
2886 specified by MASK (as modified by C<umask>).  If it succeeds it
2887 returns true, otherwise it returns false and sets C<$!> (errno).
2888 If omitted, MASK defaults to 0777. If omitted, FILENAME defaults
2889 to C<$_>.
2890
2891 In general, it is better to create directories with permissive MASK,
2892 and let the user modify that with their C<umask>, than it is to supply
2893 a restrictive MASK and give the user no way to be more permissive.
2894 The exceptions to this rule are when the file or directory should be
2895 kept private (mail files, for instance).  The perlfunc(1) entry on
2896 C<umask> discusses the choice of MASK in more detail.
2897
2898 Note that according to the POSIX 1003.1-1996 the FILENAME may have any
2899 number of trailing slashes.  Some operating and filesystems do not get
2900 this right, so Perl automatically removes all trailing slashes to keep
2901 everyone happy.
2902
2903 =item msgctl ID,CMD,ARG
2904 X<msgctl>
2905
2906 Calls the System V IPC function msgctl(2).  You'll probably have to say
2907
2908     use IPC::SysV;
2909
2910 first to get the correct constant definitions.  If CMD is C<IPC_STAT>,
2911 then ARG must be a variable that will hold the returned C<msqid_ds>
2912 structure.  Returns like C<ioctl>: the undefined value for error,
2913 C<"0 but true"> for zero, or the actual return value otherwise.  See also
2914 L<perlipc/"SysV IPC">, C<IPC::SysV>, and C<IPC::Semaphore> documentation.
2915
2916 =item msgget KEY,FLAGS
2917 X<msgget>
2918
2919 Calls the System V IPC function msgget(2).  Returns the message queue
2920 id, or the undefined value if there is an error.  See also
2921 L<perlipc/"SysV IPC"> and C<IPC::SysV> and C<IPC::Msg> documentation.
2922
2923 =item msgrcv ID,VAR,SIZE,TYPE,FLAGS
2924 X<msgrcv>
2925
2926 Calls the System V IPC function msgrcv to receive a message from
2927 message queue ID into variable VAR with a maximum message size of
2928 SIZE.  Note that when a message is received, the message type as a
2929 native long integer will be the first thing in VAR, followed by the
2930 actual message.  This packing may be opened with C<unpack("l! a*")>.
2931 Taints the variable.  Returns true if successful, or false if there is
2932 an error.  See also L<perlipc/"SysV IPC">, C<IPC::SysV>, and
2933 C<IPC::SysV::Msg> documentation.
2934
2935 =item msgsnd ID,MSG,FLAGS
2936 X<msgsnd>
2937
2938 Calls the System V IPC function msgsnd to send the message MSG to the
2939 message queue ID.  MSG must begin with the native long integer message
2940 type, and be followed by the length of the actual message, and finally
2941 the message itself.  This kind of packing can be achieved with
2942 C<pack("l! a*", $type, $message)>.  Returns true if successful,
2943 or false if there is an error.  See also C<IPC::SysV>
2944 and C<IPC::SysV::Msg> documentation.
2945
2946 =item my EXPR
2947 X<my>
2948
2949 =item my TYPE EXPR
2950
2951 =item my EXPR : ATTRS
2952
2953 =item my TYPE EXPR : ATTRS
2954
2955 A C<my> declares the listed variables to be local (lexically) to the
2956 enclosing block, file, or C<eval>.  If more than one value is listed,
2957 the list must be placed in parentheses.
2958
2959 The exact semantics and interface of TYPE and ATTRS are still
2960 evolving.  TYPE is currently bound to the use of C<fields> pragma,
2961 and attributes are handled using the C<attributes> pragma, or starting
2962 from Perl 5.8.0 also via the C<Attribute::Handlers> module.  See
2963 L<perlsub/"Private Variables via my()"> for details, and L<fields>,
2964 L<attributes>, and L<Attribute::Handlers>.
2965
2966 =item next LABEL
2967 X<next> X<continue>
2968
2969 =item next
2970
2971 The C<next> command is like the C<continue> statement in C; it starts
2972 the next iteration of the loop:
2973
2974     LINE: while (<STDIN>) {
2975         next LINE if /^#/;      # discard comments
2976         #...
2977     }
2978
2979 Note that if there were a C<continue> block on the above, it would get
2980 executed even on discarded lines.  If the LABEL is omitted, the command
2981 refers to the innermost enclosing loop.
2982
2983 C<next> cannot be used to exit a block which returns a value such as
2984 C<eval {}>, C<sub {}> or C<do {}>, and should not be used to exit
2985 a grep() or map() operation.
2986
2987 Note that a block by itself is semantically identical to a loop
2988 that executes once.  Thus C<next> will exit such a block early.
2989
2990 See also L</continue> for an illustration of how C<last>, C<next>, and
2991 C<redo> work.
2992
2993 =item no Module VERSION LIST
2994 X<no>
2995
2996 =item no Module VERSION
2997
2998 =item no Module LIST
2999
3000 =item no Module
3001
3002 See the C<use> function, of which C<no> is the opposite.
3003
3004 =item oct EXPR
3005 X<oct> X<octal> X<hex> X<hexadecimal> X<binary> X<bin>
3006
3007 =item oct
3008
3009 Interprets EXPR as an octal string and returns the corresponding
3010 value.  (If EXPR happens to start off with C<0x>, interprets it as a
3011 hex string.  If EXPR starts off with C<0b>, it is interpreted as a
3012 binary string.  Leading whitespace is ignored in all three cases.)
3013 The following will handle decimal, binary, octal, and hex in the standard
3014 Perl or C notation:
3015
3016     $val = oct($val) if $val =~ /^0/;
3017
3018 If EXPR is omitted, uses C<$_>.   To go the other way (produce a number
3019 in octal), use sprintf() or printf():
3020
3021     $perms = (stat("filename"))[2] & 07777;
3022     $oct_perms = sprintf "%lo", $perms;
3023
3024 The oct() function is commonly used when a string such as C<644> needs
3025 to be converted into a file mode, for example. (Although perl will
3026 automatically convert strings into numbers as needed, this automatic
3027 conversion assumes base 10.)
3028
3029 =item open FILEHANDLE,EXPR
3030 X<open> X<pipe> X<file, open> X<fopen>
3031
3032 =item open FILEHANDLE,MODE,EXPR
3033
3034 =item open FILEHANDLE,MODE,EXPR,LIST
3035
3036 =item open FILEHANDLE,MODE,REFERENCE
3037
3038 =item open FILEHANDLE
3039
3040 Opens the file whose filename is given by EXPR, and associates it with
3041 FILEHANDLE.
3042
3043 (The following is a comprehensive reference to open(): for a gentler
3044 introduction you may consider L<perlopentut>.)
3045
3046 If FILEHANDLE is an undefined scalar variable (or array or hash element)
3047 the variable is assigned a reference to a new anonymous filehandle,
3048 otherwise if FILEHANDLE is an expression, its value is used as the name of
3049 the real filehandle wanted.  (This is considered a symbolic reference, so
3050 C<use strict 'refs'> should I<not> be in effect.)
3051
3052 If EXPR is omitted, the scalar variable of the same name as the
3053 FILEHANDLE contains the filename.  (Note that lexical variables--those
3054 declared with C<my>--will not work for this purpose; so if you're
3055 using C<my>, specify EXPR in your call to open.)
3056
3057 If three or more arguments are specified then the mode of opening and
3058 the file name are separate. If MODE is C<< '<' >> or nothing, the file
3059 is opened for input.  If MODE is C<< '>' >>, the file is truncated and
3060 opened for output, being created if necessary.  If MODE is C<<< '>>' >>>,
3061 the file is opened for appending, again being created if necessary.
3062
3063 You can put a C<'+'> in front of the C<< '>' >> or C<< '<' >> to
3064 indicate that you want both read and write access to the file; thus
3065 C<< '+<' >> is almost always preferred for read/write updates--the C<<
3066 '+>' >> mode would clobber the file first.  You can't usually use
3067 either read-write mode for updating textfiles, since they have
3068 variable length records.  See the B<-i> switch in L<perlrun> for a
3069 better approach.  The file is created with permissions of C<0666>
3070 modified by the process' C<umask> value.
3071
3072 These various prefixes correspond to the fopen(3) modes of C<'r'>,
3073 C<'r+'>, C<'w'>, C<'w+'>, C<'a'>, and C<'a+'>.
3074
3075 In the 2-arguments (and 1-argument) form of the call the mode and
3076 filename should be concatenated (in this order), possibly separated by
3077 spaces.  It is possible to omit the mode in these forms if the mode is
3078 C<< '<' >>.
3079
3080 If the filename begins with C<'|'>, the filename is interpreted as a
3081 command to which output is to be piped, and if the filename ends with a
3082 C<'|'>, the filename is interpreted as a command which pipes output to
3083 us.  See L<perlipc/"Using open() for IPC">
3084 for more examples of this.  (You are not allowed to C<open> to a command
3085 that pipes both in I<and> out, but see L<IPC::Open2>, L<IPC::Open3>,
3086 and L<perlipc/"Bidirectional Communication with Another Process">
3087 for alternatives.)
3088
3089 For three or more arguments if MODE is C<'|-'>, the filename is
3090 interpreted as a command to which output is to be piped, and if MODE
3091 is C<'-|'>, the filename is interpreted as a command which pipes
3092 output to us.  In the 2-arguments (and 1-argument) form one should
3093 replace dash (C<'-'>) with the command.
3094 See L<perlipc/"Using open() for IPC"> for more examples of this.
3095 (You are not allowed to C<open> to a command that pipes both in I<and>
3096 out, but see L<IPC::Open2>, L<IPC::Open3>, and
3097 L<perlipc/"Bidirectional Communication"> for alternatives.)
3098
3099 In the three-or-more argument form of pipe opens, if LIST is specified
3100 (extra arguments after the command name) then LIST becomes arguments
3101 to the command invoked if the platform supports it.  The meaning of
3102 C<open> with more than three arguments for non-pipe modes is not yet
3103 specified. Experimental "layers" may give extra LIST arguments
3104 meaning.
3105
3106 In the 2-arguments (and 1-argument) form opening C<'-'> opens STDIN
3107 and opening C<< '>-' >> opens STDOUT.
3108
3109 You may use the three-argument form of open to specify IO "layers"
3110 (sometimes also referred to as "disciplines") to be applied to the handle
3111 that affect how the input and output are processed (see L<open> and
3112 L<PerlIO> for more details). For example
3113
3114   open(FH, "<:utf8", "file")
3115
3116 will open the UTF-8 encoded file containing Unicode characters,
3117 see L<perluniintro>. Note that if layers are specified in the
3118 three-arg form then default layers stored in ${^OPEN} (see L<perlvar>;
3119 usually set by the B<open> pragma or the switch B<-CioD>) are ignored.
3120
3121 Open returns nonzero upon success, the undefined value otherwise.  If
3122 the C<open> involved a pipe, the return value happens to be the pid of
3123 the subprocess.
3124
3125 If you're running Perl on a system that distinguishes between text
3126 files and binary files, then you should check out L</binmode> for tips
3127 for dealing with this.  The key distinction between systems that need
3128 C<binmode> and those that don't is their text file formats.  Systems
3129 like Unix, Mac OS, and Plan 9, which delimit lines with a single
3130 character, and which encode that character in C as C<"\n">, do not
3131 need C<binmode>.  The rest need it.
3132
3133 When opening a file, it's usually a bad idea to continue normal execution
3134 if the request failed, so C<open> is frequently used in connection with
3135 C<die>.  Even if C<die> won't do what you want (say, in a CGI script,
3136 where you want to make a nicely formatted error message (but there are
3137 modules that can help with that problem)) you should always check
3138 the return value from opening a file.  The infrequent exception is when
3139 working with an unopened filehandle is actually what you want to do.
3140
3141 As a special case the 3-arg form with a read/write mode and the third
3142 argument being C<undef>:
3143
3144     open(TMP, "+>", undef) or die ...
3145
3146 opens a filehandle to an anonymous temporary file.  Also using "+<"
3147 works for symmetry, but you really should consider writing something
3148 to the temporary file first.  You will need to seek() to do the
3149 reading.
3150
3151 Since v5.8.0, perl has built using PerlIO by default.  Unless you've
3152 changed this (i.e. Configure -Uuseperlio), you can open file handles to
3153 "in memory" files held in Perl scalars via:
3154
3155     open($fh, '>', \$variable) || ..
3156
3157 Though if you try to re-open C<STDOUT> or C<STDERR> as an "in memory"
3158 file, you have to close it first:
3159
3160     close STDOUT;
3161     open STDOUT, '>', \$variable or die "Can't open STDOUT: $!";
3162
3163 Examples:
3164
3165     $ARTICLE = 100;
3166     open ARTICLE or die "Can't find article $ARTICLE: $!\n";
3167     while (<ARTICLE>) {...
3168
3169     open(LOG, '>>/usr/spool/news/twitlog');     # (log is reserved)
3170     # if the open fails, output is discarded
3171
3172     open(DBASE, '+<', 'dbase.mine')             # open for update
3173         or die "Can't open 'dbase.mine' for update: $!";
3174
3175     open(DBASE, '+<dbase.mine')                 # ditto
3176         or die "Can't open 'dbase.mine' for update: $!";
3177
3178     open(ARTICLE, '-|', "caesar <$article")     # decrypt article
3179         or die "Can't start caesar: $!";
3180
3181     open(ARTICLE, "caesar <$article |")         # ditto
3182         or die "Can't start caesar: $!";
3183
3184     open(EXTRACT, "|sort >Tmp$$")               # $$ is our process id
3185         or die "Can't start sort: $!";
3186
3187     # in memory files
3188     open(MEMORY,'>', \$var)
3189         or die "Can't open memory file: $!";
3190     print MEMORY "foo!\n";                      # output will end up in $var
3191
3192     # process argument list of files along with any includes
3193
3194     foreach $file (@ARGV) {
3195         process($file, 'fh00');
3196     }
3197
3198     sub process {
3199         my($filename, $input) = @_;
3200         $input++;               # this is a string increment
3201         unless (open($input, $filename)) {
3202             print STDERR "Can't open $filename: $!\n";
3203             return;
3204         }
3205
3206         local $_;
3207         while (<$input>) {              # note use of indirection
3208             if (/^#include "(.*)"/) {
3209                 process($1, $input);
3210                 next;
3211             }
3212             #...                # whatever
3213         }
3214     }
3215
3216 See L<perliol> for detailed info on PerlIO.
3217
3218 You may also, in the Bourne shell tradition, specify an EXPR beginning
3219 with C<< '>&' >>, in which case the rest of the string is interpreted
3220 as the name of a filehandle (or file descriptor, if numeric) to be
3221 duped (as L<dup(2)>) and opened.  You may use C<&> after C<< > >>,
3222 C<<< >> >>>, C<< < >>, C<< +> >>, C<<< +>> >>>, and C<< +< >>.
3223 The mode you specify should match the mode of the original filehandle.
3224 (Duping a filehandle does not take into account any existing contents
3225 of IO buffers.) If you use the 3-arg form then you can pass either a
3226 number, the name of a filehandle or the normal "reference to a glob".
3227
3228 Here is a script that saves, redirects, and restores C<STDOUT> and
3229 C<STDERR> using various methods:
3230
3231     #!/usr/bin/perl
3232     open my $oldout, ">&STDOUT"     or die "Can't dup STDOUT: $!";
3233     open OLDERR,     ">&", \*STDERR or die "Can't dup STDERR: $!";
3234
3235     open STDOUT, '>', "foo.out" or die "Can't redirect STDOUT: $!";
3236     open STDERR, ">&STDOUT"     or die "Can't dup STDOUT: $!";
3237
3238     select STDERR; $| = 1;      # make unbuffered
3239     select STDOUT; $| = 1;      # make unbuffered
3240
3241     print STDOUT "stdout 1\n";  # this works for
3242     print STDERR "stderr 1\n";  # subprocesses too
3243
3244     open STDOUT, ">&", $oldout or die "Can't dup \$oldout: $!";
3245     open STDERR, ">&OLDERR"    or die "Can't dup OLDERR: $!";
3246
3247     print STDOUT "stdout 2\n";
3248     print STDERR "stderr 2\n";
3249
3250 If you specify C<< '<&=X' >>, where C<X> is a file descriptor number
3251 or a filehandle, then Perl will do an equivalent of C's C<fdopen> of
3252 that file descriptor (and not call L<dup(2)>); this is more
3253 parsimonious of file descriptors.  For example:
3254
3255     # open for input, reusing the fileno of $fd
3256     open(FILEHANDLE, "<&=$fd")
3257
3258 or
3259
3260     open(FILEHANDLE, "<&=", $fd)
3261
3262 or
3263
3264     # open for append, using the fileno of OLDFH
3265     open(FH, ">>&=", OLDFH)
3266
3267 or
3268
3269     open(FH, ">>&=OLDFH")
3270
3271 Being parsimonious on filehandles is also useful (besides being
3272 parsimonious) for example when something is dependent on file
3273 descriptors, like for example locking using flock().  If you do just
3274 C<< open(A, '>>&B') >>, the filehandle A will not have the same file
3275 descriptor as B, and therefore flock(A) will not flock(B), and vice
3276 versa.  But with C<< open(A, '>>&=B') >> the filehandles will share
3277 the same file descriptor.
3278
3279 Note that if you are using Perls older than 5.8.0, Perl will be using
3280 the standard C libraries' fdopen() to implement the "=" functionality.
3281 On many UNIX systems fdopen() fails when file descriptors exceed a
3282 certain value, typically 255.  For Perls 5.8.0 and later, PerlIO is
3283 most often the default.
3284
3285 You can see whether Perl has been compiled with PerlIO or not by
3286 running C<perl -V> and looking for C<useperlio=> line.  If C<useperlio>
3287 is C<define>, you have PerlIO, otherwise you don't.
3288
3289 If you open a pipe on the command C<'-'>, i.e., either C<'|-'> or C<'-|'>
3290 with 2-arguments (or 1-argument) form of open(), then
3291 there is an implicit fork done, and the return value of open is the pid
3292 of the child within the parent process, and C<0> within the child
3293 process.  (Use C<defined($pid)> to determine whether the open was successful.)
3294 The filehandle behaves normally for the parent, but i/o to that
3295 filehandle is piped from/to the STDOUT/STDIN of the child process.
3296 In the child process the filehandle isn't opened--i/o happens from/to
3297 the new STDOUT or STDIN.  Typically this is used like the normal
3298 piped open when you want to exercise more control over just how the
3299 pipe command gets executed, such as when you are running setuid, and
3300 don't want to have to scan shell commands for metacharacters.
3301 The following triples are more or less equivalent:
3302
3303     open(FOO, "|tr '[a-z]' '[A-Z]'");
3304     open(FOO, '|-', "tr '[a-z]' '[A-Z]'");
3305     open(FOO, '|-') || exec 'tr', '[a-z]', '[A-Z]';
3306     open(FOO, '|-', "tr", '[a-z]', '[A-Z]');
3307
3308     open(FOO, "cat -n '$file'|");
3309     open(FOO, '-|', "cat -n '$file'");
3310     open(FOO, '-|') || exec 'cat', '-n', $file;
3311     open(FOO, '-|', "cat", '-n', $file);
3312
3313 The last example in each block shows the pipe as "list form", which is
3314 not yet supported on all platforms.  A good rule of thumb is that if
3315 your platform has true C<fork()> (in other words, if your platform is
3316 UNIX) you can use the list form.
3317
3318 See L<perlipc/"Safe Pipe Opens"> for more examples of this.
3319
3320 Beginning with v5.6.0, Perl will attempt to flush all files opened for
3321 output before any operation that may do a fork, but this may not be
3322 supported on some platforms (see L<perlport>).  To be safe, you may need
3323 to set C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method
3324 of C<IO::Handle> on any open handles.
3325
3326 On systems that support a close-on-exec flag on files, the flag will
3327 be set for the newly opened file descriptor as determined by the value
3328 of $^F.  See L<perlvar/$^F>.
3329
3330 Closing any piped filehandle causes the parent process to wait for the
3331 child to finish, and returns the status value in C<$?> and
3332 C<${^CHILD_ERROR_NATIVE}>.
3333
3334 The filename passed to 2-argument (or 1-argument) form of open() will
3335 have leading and trailing whitespace deleted, and the normal
3336 redirection characters honored.  This property, known as "magic open",
3337 can often be used to good effect.  A user could specify a filename of
3338 F<"rsh cat file |">, or you could change certain filenames as needed:
3339
3340     $filename =~ s/(.*\.gz)\s*$/gzip -dc < $1|/;
3341     open(FH, $filename) or die "Can't open $filename: $!";
3342
3343 Use 3-argument form to open a file with arbitrary weird characters in it,
3344
3345     open(FOO, '<', $file);
3346
3347 otherwise it's necessary to protect any leading and trailing whitespace:
3348
3349     $file =~ s#^(\s)#./$1#;
3350     open(FOO, "< $file\0");
3351
3352 (this may not work on some bizarre filesystems).  One should
3353 conscientiously choose between the I<magic> and 3-arguments form
3354 of open():
3355
3356     open IN, $ARGV[0];
3357
3358 will allow the user to specify an argument of the form C<"rsh cat file |">,
3359 but will not work on a filename which happens to have a trailing space, while
3360
3361     open IN, '<', $ARGV[0];
3362
3363 will have exactly the opposite restrictions.
3364
3365 If you want a "real" C C<open> (see L<open(2)> on your system), then you
3366 should use the C<sysopen> function, which involves no such magic (but
3367 may use subtly different filemodes than Perl open(), which is mapped
3368 to C fopen()).  This is
3369 another way to protect your filenames from interpretation.  For example:
3370
3371     use IO::Handle;
3372     sysopen(HANDLE, $path, O_RDWR|O_CREAT|O_EXCL)
3373         or die "sysopen $path: $!";
3374     $oldfh = select(HANDLE); $| = 1; select($oldfh);
3375     print HANDLE "stuff $$\n";
3376     seek(HANDLE, 0, 0);
3377     print "File contains: ", <HANDLE>;
3378
3379 Using the constructor from the C<IO::Handle> package (or one of its
3380 subclasses, such as C<IO::File> or C<IO::Socket>), you can generate anonymous
3381 filehandles that have the scope of whatever variables hold references to
3382 them, and automatically close whenever and however you leave that scope:
3383
3384     use IO::File;
3385     #...
3386     sub read_myfile_munged {
3387         my $ALL = shift;
3388         my $handle = new IO::File;
3389         open($handle, "myfile") or die "myfile: $!";
3390         $first = <$handle>
3391             or return ();     # Automatically closed here.
3392         mung $first or die "mung failed";       # Or here.
3393         return $first, <$handle> if $ALL;       # Or here.
3394         $first;                                 # Or here.
3395     }
3396
3397 See L</seek> for some details about mixing reading and writing.
3398
3399 =item opendir DIRHANDLE,EXPR
3400 X<opendir>
3401
3402 Opens a directory named EXPR for processing by C<readdir>, C<telldir>,
3403 C<seekdir>, C<rewinddir>, and C<closedir>.  Returns true if successful.
3404 DIRHANDLE may be an expression whose value can be used as an indirect
3405 dirhandle, usually the real dirhandle name.  If DIRHANDLE is an undefined
3406 scalar variable (or array or hash element), the variable is assigned a
3407 reference to a new anonymous dirhandle.
3408 DIRHANDLEs have their own namespace separate from FILEHANDLEs.
3409
3410 =item ord EXPR
3411 X<ord> X<encoding>
3412
3413 =item ord
3414
3415 Returns the numeric (the native 8-bit encoding, like ASCII or EBCDIC,
3416 or Unicode) value of the first character of EXPR.  If EXPR is omitted,
3417 uses C<$_>.
3418
3419 For the reverse, see L</chr>.
3420 See L<perlunicode> and L<encoding> for more about Unicode.
3421
3422 =item our EXPR
3423 X<our> X<global>
3424
3425 =item our EXPR TYPE
3426
3427 =item our EXPR : ATTRS
3428
3429 =item our TYPE EXPR : ATTRS
3430
3431 C<our> associates a simple name with a package variable in the current
3432 package for use within the current scope.  When C<use strict 'vars'> is in
3433 effect, C<our> lets you use declared global variables without qualifying
3434 them with package names, within the lexical scope of the C<our> declaration.
3435 In this way C<our> differs from C<use vars>, which is package scoped.
3436
3437 Unlike C<my>, which both allocates storage for a variable and associates
3438 a simple name with that storage for use within the current scope, C<our>
3439 associates a simple name with a package variable in the current package,
3440 for use within the current scope.  In other words, C<our> has the same
3441 scoping rules as C<my>, but does not necessarily create a
3442 variable.
3443
3444 If more than one value is listed, the list must be placed
3445 in parentheses.
3446
3447     our $foo;
3448     our($bar, $baz);
3449
3450 An C<our> declaration declares a global variable that will be visible
3451 across its entire lexical scope, even across package boundaries.  The
3452 package in which the variable is entered is determined at the point
3453 of the declaration, not at the point of use.  This means the following
3454 behavior holds:
3455
3456     package Foo;
3457     our $bar;           # declares $Foo::bar for rest of lexical scope
3458     $bar = 20;
3459
3460     package Bar;
3461     print $bar;         # prints 20, as it refers to $Foo::bar
3462
3463 Multiple C<our> declarations with the same name in the same lexical
3464 scope are allowed if they are in different packages.  If they happen
3465 to be in the same package, Perl will emit warnings if you have asked
3466 for them, just like multiple C<my> declarations.  Unlike a second
3467 C<my> declaration, which will bind the name to a fresh variable, a
3468 second C<our> declaration in the same package, in the same scope, is
3469 merely redundant.
3470
3471     use warnings;
3472     package Foo;
3473     our $bar;           # declares $Foo::bar for rest of lexical scope
3474     $bar = 20;
3475
3476     package Bar;
3477     our $bar = 30;      # declares $Bar::bar for rest of lexical scope
3478     print $bar;         # prints 30
3479
3480     our $bar;           # emits warning but has no other effect
3481     print $bar;         # still prints 30
3482
3483 An C<our> declaration may also have a list of attributes associated
3484 with it.
3485
3486 The exact semantics and interface of TYPE and ATTRS are still
3487 evolving.  TYPE is currently bound to the use of C<fields> pragma,
3488 and attributes are handled using the C<attributes> pragma, or starting
3489 from Perl 5.8.0 also via the C<Attribute::Handlers> module.  See
3490 L<perlsub/"Private Variables via my()"> for details, and L<fields>,
3491 L<attributes>, and L<Attribute::Handlers>.
3492
3493 The only currently recognized C<our()> attribute is C<unique> which
3494 indicates that a single copy of the global is to be used by all
3495 interpreters should the program happen to be running in a
3496 multi-interpreter environment. (The default behaviour would be for
3497 each interpreter to have its own copy of the global.)  Examples:
3498
3499     our @EXPORT : unique = qw(foo);
3500     our %EXPORT_TAGS : unique = (bar => [qw(aa bb cc)]);
3501     our $VERSION : unique = "1.00";
3502
3503 Note that this attribute also has the effect of making the global
3504 readonly when the first new interpreter is cloned (for example,
3505 when the first new thread is created).
3506
3507 Multi-interpreter environments can come to being either through the
3508 fork() emulation on Windows platforms, or by embedding perl in a
3509 multi-threaded application.  The C<unique> attribute does nothing in
3510 all other environments.
3511
3512 Warning: the current implementation of this attribute operates on the
3513 typeglob associated with the variable; this means that C<our $x : unique>
3514 also has the effect of C<our @x : unique; our %x : unique>. This may be
3515 subject to change.
3516
3517 =item pack TEMPLATE,LIST
3518 X<pack>
3519
3520 Takes a LIST of values and converts it into a string using the rules
3521 given by the TEMPLATE.  The resulting string is the concatenation of
3522 the converted values.  Typically, each converted value looks
3523 like its machine-level representation.  For example, on 32-bit machines
3524 an integer may be represented by a sequence of 4 bytes that will be 
3525 converted to a sequence of 4 characters.
3526
3527 The TEMPLATE is a sequence of characters that give the order and type
3528 of values, as follows:
3529
3530     a   A string with arbitrary binary data, will be null padded.
3531     A   A text (ASCII) string, will be space padded.
3532     Z   A null terminated (ASCIZ) string, will be null padded.
3533
3534     b   A bit string (ascending bit order inside each byte, like vec()).
3535     B   A bit string (descending bit order inside each byte).
3536     h   A hex string (low nybble first).
3537     H   A hex string (high nybble first).
3538
3539     c   A signed char (8-bit) value.
3540     C   An unsigned C char (octet) even under Unicode. Should normally not
3541         be used. See U and W instead.
3542     W   An unsigned char value (can be greater than 255).
3543
3544     s   A signed short (16-bit) value.
3545     S   An unsigned short value.
3546
3547     l   A signed long (32-bit) value.
3548     L   An unsigned long value.
3549
3550     q   A signed quad (64-bit) value.
3551     Q   An unsigned quad value.
3552           (Quads are available only if your system supports 64-bit
3553            integer values _and_ if Perl has been compiled to support those.
3554            Causes a fatal error otherwise.)
3555
3556     i   A signed integer value.
3557     I   A unsigned integer value.
3558           (This 'integer' is _at_least_ 32 bits wide.  Its exact
3559            size depends on what a local C compiler calls 'int'.)
3560  
3561     n   An unsigned short (16-bit) in "network" (big-endian) order.
3562     N   An unsigned long (32-bit) in "network" (big-endian) order.
3563     v   An unsigned short (16-bit) in "VAX" (little-endian) order.
3564     V   An unsigned long (32-bit) in "VAX" (little-endian) order.
3565
3566     j   A Perl internal signed integer value (IV).
3567     J   A Perl internal unsigned integer value (UV).
3568
3569     f   A single-precision float in the native format.
3570     d   A double-precision float in the native format.
3571
3572     F   A Perl internal floating point value (NV) in the native format
3573     D   A long double-precision float in the native format.
3574           (Long doubles are available only if your system supports long
3575            double values _and_ if Perl has been compiled to support those.
3576            Causes a fatal error otherwise.)
3577
3578     p   A pointer to a null-terminated string.
3579     P   A pointer to a structure (fixed-length string).
3580
3581     u   A uuencoded string.
3582     U   A Unicode character number.  Encodes to UTF-8 internally
3583         (or UTF-EBCDIC in EBCDIC platforms).
3584
3585     w   A BER compressed integer (not an ASN.1 BER, see perlpacktut for
3586         details).  Its bytes represent an unsigned integer in base 128,
3587         most significant digit first, with as few digits as possible.  Bit
3588         eight (the high bit) is set on each byte except the last.
3589
3590     x   A null byte.
3591     X   Back up a byte.
3592     @   Null fill or truncate to absolute position, counted from the
3593         start of the innermost ()-group.
3594     .   Null fill or truncate to absolute position specified by value.
3595     (   Start of a ()-group.
3596
3597 One or more of the modifiers below may optionally follow some letters in the
3598 TEMPLATE (the second column lists the letters for which the modifier is
3599 valid):
3600
3601     !   sSlLiI     Forces native (short, long, int) sizes instead
3602                    of fixed (16-/32-bit) sizes.
3603
3604         xX         Make x and X act as alignment commands.
3605
3606         nNvV       Treat integers as signed instead of unsigned.
3607
3608         @.         Specify position as byte offset in the internal
3609                    representation of the packed string. Efficient but
3610                    dangerous.
3611
3612     >   sSiIlLqQ   Force big-endian byte-order on the type.
3613         jJfFdDpP   (The "big end" touches the construct.)
3614
3615     <   sSiIlLqQ   Force little-endian byte-order on the type.
3616         jJfFdDpP   (The "little end" touches the construct.)
3617
3618 The C<E<gt>> and C<E<lt>> modifiers can also be used on C<()>-groups,
3619 in which case they force a certain byte-order on all components of
3620 that group, including subgroups.
3621
3622 The following rules apply:
3623
3624 =over 8
3625
3626 =item *
3627
3628 Each letter may optionally be followed by a number giving a repeat
3629 count.  With all types except C<a>, C<A>, C<Z>, C<b>, C<B>, C<h>,
3630 C<H>, C<@>, C<.>, C<x>, C<X> and C<P> the pack function will gobble up
3631 that many values from the LIST.  A C<*> for the repeat count means to
3632 use however many items are left, except for C<@>, C<x>, C<X>, where it
3633 is equivalent to C<0>, for <.> where it means relative to string start
3634 and C<u>, where it is equivalent to 1 (or 45, which is the same).
3635 A numeric repeat count may optionally be enclosed in brackets, as in
3636 C<pack 'C[80]', @arr>.
3637
3638 One can replace the numeric repeat count by a template enclosed in brackets;
3639 then the packed length of this template in bytes is used as a count.
3640 For example, C<x[L]> skips a long (it skips the number of bytes in a long);
3641 the template C<$t X[$t] $t> unpack()s twice what $t unpacks.
3642 If the template in brackets contains alignment commands (such as C<x![d]>),
3643 its packed length is calculated as if the start of the template has the maximal
3644 possible alignment.
3645
3646 When used with C<Z>, C<*> results in the addition of a trailing null
3647 byte (so the packed result will be one longer than the byte C<length>
3648 of the item).
3649
3650 When used with C<@>, the repeat count represents an offset from the start
3651 of the innermost () group.
3652
3653 When used with C<.>, the repeat count is used to determine the starting
3654 position from where the value offset is calculated. If the repeat count
3655 is 0, it's relative to the current position. If the repeat count is C<*>,
3656 the offset is relative to the start of the packed string. And if its an
3657 integer C<n> the offset is relative to the start of the n-th innermost
3658 () group (or the start of the string if C<n> is bigger then the group
3659 level).
3660
3661 The repeat count for C<u> is interpreted as the maximal number of bytes
3662 to encode per line of output, with 0, 1 and 2 replaced by 45. The repeat 
3663 count should not be more than 65.
3664
3665 =item *
3666
3667 The C<a>, C<A>, and C<Z> types gobble just one value, but pack it as a
3668 string of length count, padding with nulls or spaces as necessary.  When
3669 unpacking, C<A> strips trailing whitespace and nulls, C<Z> strips everything
3670 after the first null, and C<a> returns data verbatim.
3671
3672 If the value-to-pack is too long, it is truncated.  If too long and an
3673 explicit count is provided, C<Z> packs only C<$count-1> bytes, followed
3674 by a null byte.  Thus C<Z> always packs a trailing null (except when the
3675 count is 0).
3676
3677 =item *
3678
3679 Likewise, the C<b> and C<B> fields pack a string that many bits long.
3680 Each character of the input field of pack() generates 1 bit of the result.
3681 Each result bit is based on the least-significant bit of the corresponding
3682 input character, i.e., on C<ord($char)%2>.  In particular, characters C<"0">
3683 and C<"1"> generate bits 0 and 1, as do characters C<"\0"> and C<"\1">.
3684
3685 Starting from the beginning of the input string of pack(), each 8-tuple
3686 of characters is converted to 1 character of output.  With format C<b>
3687 the first character of the 8-tuple determines the least-significant bit of a
3688 character, and with format C<B> it determines the most-significant bit of
3689 a character.
3690
3691 If the length of the input string is not exactly divisible by 8, the
3692 remainder is packed as if the input string were padded by null characters
3693 at the end.  Similarly, during unpack()ing the "extra" bits are ignored.
3694
3695 If the input string of pack() is longer than needed, extra characters are 
3696 ignored. A C<*> for the repeat count of pack() means to use all the 
3697 characters of the input field.  On unpack()ing the bits are converted to a 
3698 string of C<"0">s and C<"1">s.
3699
3700 =item *
3701
3702 The C<h> and C<H> fields pack a string that many nybbles (4-bit groups,
3703 representable as hexadecimal digits, 0-9a-f) long.
3704
3705 Each character of the input field of pack() generates 4 bits of the result.
3706 For non-alphabetical characters the result is based on the 4 least-significant
3707 bits of the input character, i.e., on C<ord($char)%16>.  In particular,
3708 characters C<"0"> and C<"1"> generate nybbles 0 and 1, as do bytes
3709 C<"\0"> and C<"\1">.  For characters C<"a".."f"> and C<"A".."F"> the result
3710 is compatible with the usual hexadecimal digits, so that C<"a"> and
3711 C<"A"> both generate the nybble C<0xa==10>.  The result for characters
3712 C<"g".."z"> and C<"G".."Z"> is not well-defined.
3713
3714 Starting from the beginning of the input string of pack(), each pair
3715 of characters is converted to 1 character of output.  With format C<h> the
3716 first character of the pair determines the least-significant nybble of the
3717 output character, and with format C<H> it determines the most-significant
3718 nybble.
3719
3720 If the length of the input string is not even, it behaves as if padded
3721 by a null character at the end.  Similarly, during unpack()ing the "extra"
3722 nybbles are ignored.
3723
3724 If the input string of pack() is longer than needed, extra characters are
3725 ignored.
3726 A C<*> for the repeat count of pack() means to use all the characters of
3727 the input field.  On unpack()ing the nybbles are converted to a string
3728 of hexadecimal digits.
3729
3730 =item *
3731
3732 The C<p> type packs a pointer to a null-terminated string.  You are
3733 responsible for ensuring the string is not a temporary value (which can
3734 potentially get deallocated before you get around to using the packed result).
3735 The C<P> type packs a pointer to a structure of the size indicated by the
3736 length.  A NULL pointer is created if the corresponding value for C<p> or
3737 C<P> is C<undef>, similarly for unpack().
3738
3739 If your system has a strange pointer size (i.e. a pointer is neither as
3740 big as an int nor as big as a long), it may not be possible to pack or
3741 unpack pointers in big- or little-endian byte order.  Attempting to do
3742 so will result in a fatal error.
3743
3744 =item *
3745
3746 The C</> template character allows packing and unpacking of a sequence of
3747 items where the packed structure contains a packed item count followed by 
3748 the packed items themselves.
3749 You write I<length-item>C</>I<sequence-item>.
3750
3751 The I<length-item> can be any C<pack> template letter, and describes
3752 how the length value is packed.  The ones likely to be of most use are
3753 integer-packing ones like C<n> (for Java strings), C<w> (for ASN.1 or
3754 SNMP) and C<N> (for Sun XDR).
3755
3756 For C<pack>, the I<sequence-item> may have a repeat count, in which case
3757 the minimum of that and the number of available items is used as argument
3758 for the I<length-item>. If it has no repeat count or uses a '*', the number
3759 of available items is used. For C<unpack> the repeat count is always obtained
3760 by decoding the packed item count, and the I<sequence-item> must not have a
3761 repeat count.
3762
3763 If the I<sequence-item> refers to a string type (C<"A">, C<"a"> or C<"Z">),
3764 the I<length-item> is a string length, not a number of strings. If there is
3765 an explicit repeat count for pack, the packed string will be adjusted to that
3766 given length.
3767
3768     unpack 'W/a', "\04Gurusamy";        gives ('Guru')
3769     unpack 'a3/A* A*', '007 Bond  J ';  gives (' Bond', 'J')
3770     pack 'n/a* w/a','hello,','world';   gives "\000\006hello,\005world"
3771     pack 'a/W2', ord('a') .. ord('z');  gives '2ab'
3772
3773 The I<length-item> is not returned explicitly from C<unpack>.
3774
3775 Adding a count to the I<length-item> letter is unlikely to do anything
3776 useful, unless that letter is C<A>, C<a> or C<Z>.  Packing with a
3777 I<length-item> of C<a> or C<Z> may introduce C<"\000"> characters,
3778 which Perl does not regard as legal in numeric strings.
3779
3780 =item *
3781
3782 The integer types C<s>, C<S>, C<l>, and C<L> may be
3783 followed by a C<!> modifier to signify native shorts or
3784 longs--as you can see from above for example a bare C<l> does mean
3785 exactly 32 bits, the native C<long> (as seen by the local C compiler)
3786 may be larger.  This is an issue mainly in 64-bit platforms.  You can
3787 see whether using C<!> makes any difference by
3788
3789         print length(pack("s")), " ", length(pack("s!")), "\n";
3790         print length(pack("l")), " ", length(pack("l!")), "\n";
3791
3792 C<i!> and C<I!> also work but only because of completeness;
3793 they are identical to C<i> and C<I>.
3794
3795 The actual sizes (in bytes) of native shorts, ints, longs, and long
3796 longs on the platform where Perl was built are also available via
3797 L<Config>:
3798
3799        use Config;
3800        print $Config{shortsize},    "\n";
3801        print $Config{intsize},      "\n";
3802        print $Config{longsize},     "\n";
3803        print $Config{longlongsize}, "\n";
3804
3805 (The C<$Config{longlongsize}> will be undefined if your system does
3806 not support long longs.)
3807
3808 =item *
3809
3810 The integer formats C<s>, C<S>, C<i>, C<I>, C<l>, C<L>, C<j>, and C<J>
3811 are inherently non-portable between processors and operating systems
3812 because they obey the native byteorder and endianness.  For example a
3813 4-byte integer 0x12345678 (305419896 decimal) would be ordered natively
3814 (arranged in and handled by the CPU registers) into bytes as
3815
3816         0x12 0x34 0x56 0x78     # big-endian
3817         0x78 0x56 0x34 0x12     # little-endian
3818
3819 Basically, the Intel and VAX CPUs are little-endian, while everybody
3820 else, for example Motorola m68k/88k, PPC, Sparc, HP PA, Power, and
3821 Cray are big-endian.  Alpha and MIPS can be either: Digital/Compaq
3822 used/uses them in little-endian mode; SGI/Cray uses them in big-endian
3823 mode.
3824
3825 The names `big-endian' and `little-endian' are comic references to
3826 the classic "Gulliver's Travels" (via the paper "On Holy Wars and a
3827 Plea for Peace" by Danny Cohen, USC/ISI IEN 137, April 1, 1980) and
3828 the egg-eating habits of the Lilliputians.
3829
3830 Some systems may have even weirder byte orders such as
3831
3832         0x56 0x78 0x12 0x34
3833         0x34 0x12 0x78 0x56
3834
3835 You can see your system's preference with
3836
3837         print join(" ", map { sprintf "%#02x", $_ }
3838                             unpack("W*",pack("L",0x12345678))), "\n";
3839
3840 The byteorder on the platform where Perl was built is also available
3841 via L<Config>:
3842
3843         use Config;
3844         print $Config{byteorder}, "\n";
3845
3846 Byteorders C<'1234'> and C<'12345678'> are little-endian, C<'4321'>
3847 and C<'87654321'> are big-endian.
3848
3849 If you want portable packed integers you can either use the formats
3850 C<n>, C<N>, C<v>, and C<V>, or you can use the C<E<gt>> and C<E<lt>>
3851 modifiers.  These modifiers are only available as of perl 5.9.2.
3852 See also L<perlport>.
3853
3854 =item *
3855
3856 All integer and floating point formats as well as C<p> and C<P> and
3857 C<()>-groups may be followed by the C<E<gt>> or C<E<lt>> modifiers
3858 to force big- or little- endian byte-order, respectively.
3859 This is especially useful, since C<n>, C<N>, C<v> and C<V> don't cover
3860 signed integers, 64-bit integers and floating point values.  However,
3861 there are some things to keep in mind.
3862
3863 Exchanging signed integers between different platforms only works
3864 if all platforms store them in the same format.  Most platforms store
3865 signed integers in two's complement, so usually this is not an issue.
3866
3867 The C<E<gt>> or C<E<lt>> modifiers can only be used on floating point
3868 formats on big- or little-endian machines.  Otherwise, attempting to
3869 do so will result in a fatal error.
3870
3871 Forcing big- or little-endian byte-order on floating point values for
3872 data exchange can only work if all platforms are using the same
3873 binary representation (e.g. IEEE floating point format).  Even if all
3874 platforms are using IEEE, there may be subtle differences.  Being able
3875 to use C<E<gt>> or C<E<lt>> on floating point values can be very useful,
3876 but also very dangerous if you don't know exactly what you're doing.
3877 It is definitely not a general way to portably store floating point
3878 values.
3879
3880 When using C<E<gt>> or C<E<lt>> on an C<()>-group, this will affect
3881 all types inside the group that accept the byte-order modifiers,
3882 including all subgroups.  It will silently be ignored for all other
3883 types.  You are not allowed to override the byte-order within a group
3884 that already has a byte-order modifier suffix.
3885
3886 =item *
3887
3888 Real numbers (floats and doubles) are in the native machine format only;
3889 due to the multiplicity of floating formats around, and the lack of a
3890 standard "network" representation, no facility for interchange has been
3891 made.  This means that packed floating point data written on one machine
3892 may not be readable on another - even if both use IEEE floating point
3893 arithmetic (as the endian-ness of the memory representation is not part
3894 of the IEEE spec).  See also L<perlport>.
3895
3896 If you know exactly what you're doing, you can use the C<E<gt>> or C<E<lt>>
3897 modifiers to force big- or little-endian byte-order on floating point values.
3898
3899 Note that Perl uses doubles (or long doubles, if configured) internally for
3900 all numeric calculation, and converting from double into float and thence back
3901 to double again will lose precision (i.e., C<unpack("f", pack("f", $foo)>)
3902 will not in general equal $foo).
3903
3904 =item *
3905
3906 Pack and unpack can operate in two modes, character mode (C<C0> mode) where
3907 the packed string is processed per character and UTF-8 mode (C<U0> mode)
3908 where the packed string is processed in its UTF-8-encoded Unicode form on
3909 a byte by byte basis. Character mode is the default unless the format string 
3910 starts with an C<U>. You can switch mode at any moment with an explicit 
3911 C<C0> or C<U0> in the format. A mode is in effect until the next mode switch 
3912 or until the end of the ()-group in which it was entered.
3913
3914 =item *
3915
3916 You must yourself do any alignment or padding by inserting for example
3917 enough C<'x'>es while packing.  There is no way to pack() and unpack()
3918 could know where the characters are going to or coming from.  Therefore
3919 C<pack> (and C<unpack>) handle their output and input as flat
3920 sequences of characters.
3921
3922 =item *
3923
3924 A ()-group is a sub-TEMPLATE enclosed in parentheses.  A group may
3925 take a repeat count, both as postfix, and for unpack() also via the C</>
3926 template character. Within each repetition of a group, positioning with
3927 C<@> starts again at 0. Therefore, the result of
3928
3929     pack( '@1A((@2A)@3A)', 'a', 'b', 'c' )
3930
3931 is the string "\0a\0\0bc".
3932
3933 =item *
3934
3935 C<x> and C<X> accept C<!> modifier.  In this case they act as
3936 alignment commands: they jump forward/back to the closest position
3937 aligned at a multiple of C<count> characters. For example, to pack() or
3938 unpack() C's C<struct {char c; double d; char cc[2]}> one may need to
3939 use the template C<W x![d] d W[2]>; this assumes that doubles must be
3940 aligned on the double's size.
3941
3942 For alignment commands C<count> of 0 is equivalent to C<count> of 1;
3943 both result in no-ops.
3944
3945 =item *
3946
3947 C<n>, C<N>, C<v> and C<V> accept the C<!> modifier. In this case they
3948 will represent signed 16-/32-bit integers in big-/little-endian order.
3949 This is only portable if all platforms sharing the packed data use the
3950 same binary representation for signed integers (e.g. all platforms are
3951 using two's complement representation).
3952
3953 =item *
3954
3955 A comment in a TEMPLATE starts with C<#> and goes to the end of line.
3956 White space may be used to separate pack codes from each other, but
3957 modifiers and a repeat count must follow immediately.
3958
3959 =item *
3960
3961 If TEMPLATE requires more arguments to pack() than actually given, pack()
3962 assumes additional C<""> arguments.  If TEMPLATE requires fewer arguments
3963 to pack() than actually given, extra arguments are ignored.
3964
3965 =back
3966
3967 Examples:
3968
3969     $foo = pack("WWWW",65,66,67,68);
3970     # foo eq "ABCD"
3971     $foo = pack("W4",65,66,67,68);
3972     # same thing
3973     $foo = pack("W4",0x24b6,0x24b7,0x24b8,0x24b9);
3974     # same thing with Unicode circled letters.
3975     $foo = pack("U4",0x24b6,0x24b7,0x24b8,0x24b9);
3976     # same thing with Unicode circled letters. You don't get the UTF-8
3977     # bytes because the U at the start of the format caused a switch to
3978     # U0-mode, so the UTF-8 bytes get joined into characters
3979     $foo = pack("C0U4",0x24b6,0x24b7,0x24b8,0x24b9);
3980     # foo eq "\xe2\x92\xb6\xe2\x92\xb7\xe2\x92\xb8\xe2\x92\xb9"
3981     # This is the UTF-8 encoding of the string in the previous example
3982
3983     $foo = pack("ccxxcc",65,66,67,68);
3984     # foo eq "AB\0\0CD"
3985
3986     # note: the above examples featuring "W" and "c" are true
3987     # only on ASCII and ASCII-derived systems such as ISO Latin 1
3988     # and UTF-8.  In EBCDIC the first example would be
3989     # $foo = pack("WWWW",193,194,195,196);
3990
3991     $foo = pack("s2",1,2);
3992     # "\1\0\2\0" on little-endian
3993     # "\0\1\0\2" on big-endian
3994
3995     $foo = pack("a4","abcd","x","y","z");
3996     # "abcd"
3997
3998     $foo = pack("aaaa","abcd","x","y","z");
3999     # "axyz"
4000
4001     $foo = pack("a14","abcdefg");
4002     # "abcdefg\0\0\0\0\0\0\0"
4003
4004     $foo = pack("i9pl", gmtime);
4005     # a real struct tm (on my system anyway)
4006
4007     $utmp_template = "Z8 Z8 Z16 L";
4008     $utmp = pack($utmp_template, @utmp1);
4009     # a struct utmp (BSDish)
4010
4011     @utmp2 = unpack($utmp_template, $utmp);
4012     # "@utmp1" eq "@utmp2"
4013
4014     sub bintodec {
4015         unpack("N", pack("B32", substr("0" x 32 . shift, -32)));
4016     }
4017
4018     $foo = pack('sx2l', 12, 34);
4019     # short 12, two zero bytes padding, long 34
4020     $bar = pack('s@4l', 12, 34);
4021     # short 12, zero fill to position 4, long 34
4022     # $foo eq $bar
4023     $baz = pack('s.l', 12, 4, 34);
4024     # short 12, zero fill to position 4, long 34
4025
4026     $foo = pack('nN', 42, 4711);
4027     # pack big-endian 16- and 32-bit unsigned integers
4028     $foo = pack('S>L>', 42, 4711);
4029     # exactly the same
4030     $foo = pack('s<l<', -42, 4711);
4031     # pack little-endian 16- and 32-bit signed integers
4032     $foo = pack('(sl)<', -42, 4711);
4033     # exactly the same
4034
4035 The same template may generally also be used in unpack().
4036
4037 =item package NAMESPACE
4038 X<package> X<module> X<namespace>
4039
4040 =item package
4041
4042 Declares the compilation unit as being in the given namespace.  The scope
4043 of the package declaration is from the declaration itself through the end
4044 of the enclosing block, file, or eval (the same as the C<my> operator).
4045 All further unqualified dynamic identifiers will be in this namespace.
4046 A package statement affects only dynamic variables--including those
4047 you've used C<local> on--but I<not> lexical variables, which are created
4048 with C<my>.  Typically it would be the first declaration in a file to
4049 be included by the C<require> or C<use> operator.  You can switch into a
4050 package in more than one place; it merely influences which symbol table
4051 is used by the compiler for the rest of that block.  You can refer to
4052 variables and filehandles in other packages by prefixing the identifier
4053 with the package name and a double colon:  C<$Package::Variable>.
4054 If the package name is null, the C<main> package as assumed.  That is,
4055 C<$::sail> is equivalent to C<$main::sail> (as well as to C<$main'sail>,
4056 still seen in older code).
4057
4058 If NAMESPACE is omitted, then there is no current package, and all
4059 identifiers must be fully qualified or lexicals.  However, you are
4060 strongly advised not to make use of this feature. Its use can cause
4061 unexpected behaviour, even crashing some versions of Perl. It is
4062 deprecated, and will be removed from a future release.
4063
4064 See L<perlmod/"Packages"> for more information about packages, modules,
4065 and classes.  See L<perlsub> for other scoping issues.
4066
4067 =item pipe READHANDLE,WRITEHANDLE
4068 X<pipe>
4069
4070 Opens a pair of connected pipes like the corresponding system call.
4071 Note that if you set up a loop of piped processes, deadlock can occur
4072 unless you are very careful.  In addition, note that Perl's pipes use
4073 IO buffering, so you may need to set C<$|> to flush your WRITEHANDLE
4074 after each command, depending on the application.
4075
4076 See L<IPC::Open2>, L<IPC::Open3>, and L<perlipc/"Bidirectional Communication">
4077 for examples of such things.
4078
4079 On systems that support a close-on-exec flag on files, the flag will be set
4080 for the newly opened file descriptors as determined by the value of $^F.
4081 See L<perlvar/$^F>.
4082
4083 =item pop ARRAY
4084 X<pop> X<stack>
4085
4086 =item pop
4087
4088 Pops and returns the last value of the array, shortening the array by
4089 one element.  Has an effect similar to
4090
4091     $ARRAY[$#ARRAY--]
4092
4093 If there are no elements in the array, returns the undefined value
4094 (although this may happen at other times as well).  If ARRAY is
4095 omitted, pops the C<@ARGV> array in the main program, and the C<@_>
4096 array in subroutines, just like C<shift>.
4097
4098 =item pos SCALAR
4099 X<pos> X<match, position>
4100
4101 =item pos
4102
4103 Returns the offset of where the last C<m//g> search left off for the variable
4104 in question (C<$_> is used when the variable is not specified).  Note that
4105 0 is a valid match offset.  C<undef> indicates that the search position
4106 is reset (usually due to match failure, but can also be because no match has
4107 yet been performed on the scalar). C<pos> directly accesses the location used
4108 by the regexp engine to store the offset, so assigning to C<pos> will change
4109 that offset, and so will also influence the C<\G> zero-width assertion in
4110 regular expressions. Because a failed C<m//gc> match doesn't reset the offset,
4111 the return from C<pos> won't change either in this case.  See L<perlre> and
4112 L<perlop>.
4113
4114 =item print FILEHANDLE LIST
4115 X<print>
4116
4117 =item print LIST
4118
4119 =item print
4120
4121 Prints a string or a list of strings.  Returns true if successful.
4122 FILEHANDLE may be a scalar variable name, in which case the variable
4123 contains the name of or a reference to the filehandle, thus introducing
4124 one level of indirection.  (NOTE: If FILEHANDLE is a variable and
4125 the next token is a term, it may be misinterpreted as an operator
4126 unless you interpose a C<+> or put parentheses around the arguments.)
4127 If FILEHANDLE is omitted, prints by default to standard output (or
4128 to the last selected output channel--see L</select>).  If LIST is
4129 also omitted, prints C<$_> to the currently selected output channel.
4130 To set the default output channel to something other than STDOUT
4131 use the select operation.  The current value of C<$,> (if any) is
4132 printed between each LIST item.  The current value of C<$\> (if
4133 any) is printed after the entire LIST has been printed.  Because
4134 print takes a LIST, anything in the LIST is evaluated in list
4135 context, and any subroutine that you call will have one or more of
4136 its expressions evaluated in list context.  Also be careful not to
4137 follow the print keyword with a left parenthesis unless you want
4138 the corresponding right parenthesis to terminate the arguments to
4139 the print--interpose a C<+> or put parentheses around all the
4140 arguments.
4141
4142 Note that if you're storing FILEHANDLEs in an array, or if you're using
4143 any other expression more complex than a scalar variable to retrieve it,
4144 you will have to use a block returning the filehandle value instead:
4145
4146     print { $files[$i] } "stuff\n";
4147     print { $OK ? STDOUT : STDERR } "stuff\n";
4148
4149 =item printf FILEHANDLE FORMAT, LIST
4150 X<printf>
4151
4152 =item printf FORMAT, LIST
4153
4154 Equivalent to C<print FILEHANDLE sprintf(FORMAT, LIST)>, except that C<$\>
4155 (the output record separator) is not appended.  The first argument
4156 of the list will be interpreted as the C<printf> format. See C<sprintf>
4157 for an explanation of the format argument. If C<use locale> is in effect,
4158 the character used for the decimal point in formatted real numbers is
4159 affected by the LC_NUMERIC locale.  See L<perllocale>.
4160
4161 Don't fall into the trap of using a C<printf> when a simple
4162 C<print> would do.  The C<print> is more efficient and less
4163 error prone.
4164
4165 =item prototype FUNCTION
4166 X<prototype>
4167
4168 Returns the prototype of a function as a string (or C<undef> if the
4169 function has no prototype).  FUNCTION is a reference to, or the name of,
4170 the function whose prototype you want to retrieve.
4171
4172 If FUNCTION is a string starting with C<CORE::>, the rest is taken as a
4173 name for Perl builtin.  If the builtin is not I<overridable> (such as
4174 C<qw//>) or its arguments cannot be expressed by a prototype (such as
4175 C<system>) returns C<undef> because the builtin does not really behave
4176 like a Perl function.  Otherwise, the string describing the equivalent
4177 prototype is returned.
4178
4179 =item push ARRAY,LIST
4180 X<push>, X<stack>
4181
4182 Treats ARRAY as a stack, and pushes the values of LIST
4183 onto the end of ARRAY.  The length of ARRAY increases by the length of
4184 LIST.  Has the same effect as
4185
4186     for $value (LIST) {
4187         $ARRAY[++$#ARRAY] = $value;
4188     }
4189
4190 but is more efficient.  Returns the number of elements in the array following
4191 the completed C<push>.
4192
4193 =item q/STRING/
4194
4195 =item qq/STRING/
4196
4197 =item qr/STRING/
4198
4199 =item qx/STRING/
4200
4201 =item qw/STRING/
4202
4203 Generalized quotes.  See L<perlop/"Regexp Quote-Like Operators">.
4204
4205 =item quotemeta EXPR
4206 X<quotemeta> X<metacharacter>
4207
4208 =item quotemeta
4209
4210 Returns the value of EXPR with all non-"word"
4211 characters backslashed.  (That is, all characters not matching
4212 C</[A-Za-z_0-9]/> will be preceded by a backslash in the
4213 returned string, regardless of any locale settings.)
4214 This is the internal function implementing
4215 the C<\Q> escape in double-quoted strings.
4216
4217 If EXPR is omitted, uses C<$_>.
4218
4219 =item rand EXPR
4220 X<rand> X<random>
4221
4222 =item rand
4223
4224 Returns a random fractional number greater than or equal to C<0> and less
4225 than the value of EXPR.  (EXPR should be positive.)  If EXPR is
4226 omitted, the value C<1> is used.  Currently EXPR with the value C<0> is
4227 also special-cased as C<1> - this has not been documented before perl 5.8.0
4228 and is subject to change in future versions of perl.  Automatically calls
4229 C<srand> unless C<srand> has already been called.  See also C<srand>.
4230
4231 Apply C<int()> to the value returned by C<rand()> if you want random
4232 integers instead of random fractional numbers.  For example,
4233
4234     int(rand(10))
4235
4236 returns a random integer between C<0> and C<9>, inclusive.
4237
4238 (Note: If your rand function consistently returns numbers that are too
4239 large or too small, then your version of Perl was probably compiled
4240 with the wrong number of RANDBITS.)
4241
4242 =item read FILEHANDLE,SCALAR,LENGTH,OFFSET
4243 X<read>
4244
4245 =item read FILEHANDLE,SCALAR,LENGTH
4246
4247 Attempts to read LENGTH I<characters> of data into variable SCALAR
4248 from the specified FILEHANDLE.  Returns the number of characters
4249 actually read, C<0> at end of file, or undef if there was an error (in
4250 the latter case C<$!> is also set).  SCALAR will be grown or shrunk 
4251 so that the last character actually read is the last character of the
4252 scalar after the read.
4253
4254 An OFFSET may be specified to place the read data at some place in the
4255 string other than the beginning.  A negative OFFSET specifies
4256 placement at that many characters counting backwards from the end of
4257 the string.  A positive OFFSET greater than the length of SCALAR
4258 results in the string being padded to the required size with C<"\0">
4259 bytes before the result of the read is appended.
4260
4261 The call is actually implemented in terms of either Perl's or system's
4262 fread() call.  To get a true read(2) system call, see C<sysread>.
4263
4264 Note the I<characters>: depending on the status of the filehandle,
4265 either (8-bit) bytes or characters are read.  By default all
4266 filehandles operate on bytes, but for example if the filehandle has
4267 been opened with the C<:utf8> I/O layer (see L</open>, and the C<open>
4268 pragma, L<open>), the I/O will operate on UTF-8 encoded Unicode
4269 characters, not bytes.  Similarly for the C<:encoding> pragma:
4270 in that case pretty much any characters can be read.
4271
4272 =item readdir DIRHANDLE
4273 X<readdir>
4274
4275 Returns the next directory entry for a directory opened by C<opendir>.
4276 If used in list context, returns all the rest of the entries in the
4277 directory.  If there are no more entries, returns an undefined value in
4278 scalar context or a null list in list context.
4279
4280 If you're planning to filetest the return values out of a C<readdir>, you'd
4281 better prepend the directory in question.  Otherwise, because we didn't
4282 C<chdir> there, it would have been testing the wrong file.
4283
4284     opendir(DIR, $some_dir) || die "can't opendir $some_dir: $!";
4285     @dots = grep { /^\./ && -f "$some_dir/$_" } readdir(DIR);
4286     closedir DIR;
4287
4288 =item readline EXPR
4289 X<readline> X<gets> X<fgets>
4290
4291 Reads from the filehandle whose typeglob is contained in EXPR.  In scalar
4292 context, each call reads and returns the next line, until end-of-file is
4293 reached, whereupon the subsequent call returns undef.  In list context,
4294 reads until end-of-file is reached and returns a list of lines.  Note that
4295 the notion of "line" used here is however you may have defined it
4296 with C<$/> or C<$INPUT_RECORD_SEPARATOR>).  See L<perlvar/"$/">.
4297
4298 When C<$/> is set to C<undef>, when readline() is in scalar
4299 context (i.e. file slurp mode), and when an empty file is read, it
4300 returns C<''> the first time, followed by C<undef> subsequently.
4301
4302 This is the internal function implementing the C<< <EXPR> >>
4303 operator, but you can use it directly.  The C<< <EXPR> >>
4304 operator is discussed in more detail in L<perlop/"I/O Operators">.
4305
4306     $line = <STDIN>;
4307     $line = readline(*STDIN);           # same thing
4308
4309 If readline encounters an operating system error, C<$!> will be set with the
4310 corresponding error message.  It can be helpful to check C<$!> when you are
4311 reading from filehandles you don't trust, such as a tty or a socket.  The
4312 following example uses the operator form of C<readline>, and takes the necessary
4313 steps to ensure that C<readline> was successful.
4314
4315     for (;;) {
4316         undef $!;
4317         unless (defined( $line = <> )) {
4318             die $! if $!;
4319             last; # reached EOF
4320         }
4321         # ...
4322     }
4323
4324 =item readlink EXPR
4325 X<readlink>
4326
4327 =item readlink
4328
4329 Returns the value of a symbolic link, if symbolic links are
4330 implemented.  If not, gives a fatal error.  If there is some system
4331 error, returns the undefined value and sets C<$!> (errno).  If EXPR is
4332 omitted, uses C<$_>.
4333
4334 =item readpipe EXPR
4335 X<readpipe>
4336
4337 EXPR is executed as a system command.
4338 The collected standard output of the command is returned.
4339 In scalar context, it comes back as a single (potentially
4340 multi-line) string.  In list context, returns a list of lines
4341 (however you've defined lines with C<$/> or C<$INPUT_RECORD_SEPARATOR>).
4342 This is the internal function implementing the C<qx/EXPR/>
4343 operator, but you can use it directly.  The C<qx/EXPR/>
4344 operator is discussed in more detail in L<perlop/"I/O Operators">.
4345
4346 =item recv SOCKET,SCALAR,LENGTH,FLAGS
4347 X<recv>
4348
4349 Receives a message on a socket.  Attempts to receive LENGTH characters
4350 of data into variable SCALAR from the specified SOCKET filehandle.
4351 SCALAR will be grown or shrunk to the length actually read.  Takes the
4352 same flags as the system call of the same name.  Returns the address
4353 of the sender if SOCKET's protocol supports this; returns an empty
4354 string otherwise.  If there's an error, returns the undefined value.
4355 This call is actually implemented in terms of recvfrom(2) system call.
4356 See L<perlipc/"UDP: Message Passing"> for examples.
4357
4358 Note the I<characters>: depending on the status of the socket, either
4359 (8-bit) bytes or characters are received.  By default all sockets
4360 operate on bytes, but for example if the socket has been changed using
4361 binmode() to operate with the C<:utf8> I/O layer (see the C<open>
4362 pragma, L<open>), the I/O will operate on UTF-8 encoded Unicode
4363 characters, not bytes.  Similarly for the C<:encoding> pragma:
4364 in that case pretty much any characters can be read.
4365
4366 =item redo LABEL
4367 X<redo>
4368
4369 =item redo
4370
4371 The C<redo> command restarts the loop block without evaluating the
4372 conditional again.  The C<continue> block, if any, is not executed.  If
4373 the LABEL is omitted, the command refers to the innermost enclosing
4374 loop.  Programs that want to lie to themselves about what was just input 
4375 normally use this command:
4376
4377     # a simpleminded Pascal comment stripper
4378     # (warning: assumes no { or } in strings)
4379     LINE: while (<STDIN>) {
4380         while (s|({.*}.*){.*}|$1 |) {}
4381         s|{.*}| |;
4382         if (s|{.*| |) {
4383             $front = $_;
4384             while (<STDIN>) {
4385                 if (/}/) {      # end of comment?
4386                     s|^|$front\{|;
4387                     redo LINE;
4388                 }
4389             }
4390         }
4391         print;
4392     }
4393
4394 C<redo> cannot be used to retry a block which returns a value such as
4395 C<eval {}>, C<sub {}> or C<do {}>, and should not be used to exit
4396 a grep() or map() operation.
4397
4398 Note that a block by itself is semantically identical to a loop
4399 that executes once.  Thus C<redo> inside such a block will effectively
4400 turn it into a looping construct.
4401
4402 See also L</continue> for an illustration of how C<last>, C<next>, and
4403 C<redo> work.
4404
4405 =item ref EXPR
4406 X<ref> X<reference>
4407
4408 =item ref
4409
4410 Returns a non-empty string if EXPR is a reference, the empty
4411 string otherwise. If EXPR
4412 is not specified, C<$_> will be used.  The value returned depends on the
4413 type of thing the reference is a reference to.
4414 Builtin types include:
4415
4416     SCALAR
4417     ARRAY
4418     HASH
4419     CODE
4420     REF
4421     GLOB
4422     LVALUE
4423
4424 If the referenced object has been blessed into a package, then that package
4425 name is returned instead.  You can think of C<ref> as a C<typeof> operator.
4426
4427     if (ref($r) eq "HASH") {
4428         print "r is a reference to a hash.\n";
4429     }
4430     unless (ref($r)) {
4431         print "r is not a reference at all.\n";
4432     }
4433
4434 See also L<perlref>.
4435
4436 =item rename OLDNAME,NEWNAME
4437 X<rename> X<move> X<mv> X<ren>
4438
4439 Changes the name of a file; an existing file NEWNAME will be
4440 clobbered.  Returns true for success, false otherwise.
4441
4442 Behavior of this function varies wildly depending on your system
4443 implementation.  For example, it will usually not work across file system
4444 boundaries, even though the system I<mv> command sometimes compensates
4445 for this.  Other restrictions include whether it works on directories,
4446 open files, or pre-existing files.  Check L<perlport> and either the
4447 rename(2) manpage or equivalent system documentation for details.
4448
4449 =item require VERSION
4450 X<require>
4451
4452 =item require EXPR
4453
4454 =item require
4455
4456 Demands a version of Perl specified by VERSION, or demands some semantics
4457 specified by EXPR or by C<$_> if EXPR is not supplied.
4458
4459 VERSION may be either a numeric argument such as 5.006, which will be
4460 compared to C<$]>, or a literal of the form v5.6.1, which will be compared
4461 to C<$^V> (aka $PERL_VERSION).  A fatal error is produced at run time if
4462 VERSION is greater than the version of the current Perl interpreter.
4463 Compare with L</use>, which can do a similar check at compile time.
4464
4465 Specifying VERSION as a literal of the form v5.6.1 should generally be
4466 avoided, because it leads to misleading error messages under earlier
4467 versions of Perl that do not support this syntax.  The equivalent numeric
4468 version should be used instead.
4469
4470     require v5.6.1;     # run time version check
4471     require 5.6.1;      # ditto
4472     require 5.006_001;  # ditto; preferred for backwards compatibility
4473
4474 Otherwise, C<require> demands that a library file be included if it
4475 hasn't already been included.  The file is included via the do-FILE
4476 mechanism, which is essentially just a variety of C<eval>.  Has
4477 semantics similar to the following subroutine:
4478
4479     sub require {
4480        my ($filename) = @_;
4481        if (exists $INC{$filename}) {
4482            return 1 if $INC{$filename};
4483            die "Compilation failed in require";
4484        }
4485        my ($realfilename,$result);
4486        ITER: {
4487            foreach $prefix (@INC) {
4488                $realfilename = "$prefix/$filename";
4489                if (-f $realfilename) {
4490                    $INC{$filename} = $realfilename;
4491                    $result = do $realfilename;
4492                    last ITER;
4493                }
4494            }
4495            die "Can't find $filename in \@INC";
4496        }
4497        if ($@) {
4498            $INC{$filename} = undef;
4499            die $@;
4500        } elsif (!$result) {
4501            delete $INC{$filename};
4502            die "$filename did not return true value";
4503        } else {
4504            return $result;
4505        }
4506     }
4507
4508 Note that the file will not be included twice under the same specified
4509 name.
4510
4511 The file must return true as the last statement to indicate
4512 successful execution of any initialization code, so it's customary to
4513 end such a file with C<1;> unless you're sure it'll return true
4514 otherwise.  But it's better just to put the C<1;>, in case you add more
4515 statements.
4516
4517 If EXPR is a bareword, the require assumes a "F<.pm>" extension and
4518 replaces "F<::>" with "F</>" in the filename for you,
4519 to make it easy to load standard modules.  This form of loading of
4520 modules does not risk altering your namespace.
4521
4522 In other words, if you try this:
4523
4524         require Foo::Bar;    # a splendid bareword
4525
4526 The require function will actually look for the "F<Foo/Bar.pm>" file in the
4527 directories specified in the C<@INC> array.
4528
4529 But if you try this:
4530
4531         $class = 'Foo::Bar';
4532         require $class;      # $class is not a bareword
4533     #or
4534         require "Foo::Bar";  # not a bareword because of the ""
4535
4536 The require function will look for the "F<Foo::Bar>" file in the @INC array and
4537 will complain about not finding "F<Foo::Bar>" there.  In this case you can do:
4538
4539         eval "require $class";
4540
4541 Now that you understand how C<require> looks for files in the case of
4542 a bareword argument, there is a little extra functionality going on
4543 behind the scenes.  Before C<require> looks for a "F<.pm>" extension,
4544 it will first look for a filename with a "F<.pmc>" extension.  A file
4545 with this extension is assumed to be Perl bytecode generated by
4546 L<B::Bytecode|B::Bytecode>.  If this file is found, and its modification
4547 time is newer than a coinciding "F<.pm>" non-compiled file, it will be
4548 loaded in place of that non-compiled file ending in a "F<.pm>" extension.
4549
4550 You can also insert hooks into the import facility, by putting directly
4551 Perl code into the @INC array.  There are three forms of hooks: subroutine
4552 references, array references and blessed objects.
4553
4554 Subroutine references are the simplest case.  When the inclusion system
4555 walks through @INC and encounters a subroutine, this subroutine gets
4556 called with two parameters, the first being a reference to itself, and the
4557 second the name of the file to be included (e.g. "F<Foo/Bar.pm>").  The
4558 subroutine should return C<undef> or a filehandle, from which the file to
4559 include will be read.  If C<undef> is returned, C<require> will look at
4560 the remaining elements of @INC.
4561
4562 If the hook is an array reference, its first element must be a subroutine
4563 reference.  This subroutine is called as above, but the first parameter is
4564 the array reference.  This enables to pass indirectly some arguments to
4565 the subroutine.
4566
4567 In other words, you can write:
4568
4569     push @INC, \&my_sub;
4570     sub my_sub {
4571         my ($coderef, $filename) = @_;  # $coderef is \&my_sub
4572         ...
4573     }
4574
4575 or:
4576
4577     push @INC, [ \&my_sub, $x, $y, ... ];
4578     sub my_sub {
4579         my ($arrayref, $filename) = @_;
4580         # Retrieve $x, $y, ...
4581         my @parameters = @$arrayref[1..$#$arrayref];
4582         ...
4583     }
4584
4585 If the hook is an object, it must provide an INC method that will be
4586 called as above, the first parameter being the object itself.  (Note that
4587 you must fully qualify the sub's name, as it is always forced into package
4588 C<main>.)  Here is a typical code layout:
4589
4590     # In Foo.pm
4591     package Foo;
4592     sub new { ... }
4593     sub Foo::INC {
4594         my ($self, $filename) = @_;
4595         ...
4596     }
4597
4598     # In the main program
4599     push @INC, new Foo(...);
4600
4601 Note that these hooks are also permitted to set the %INC entry
4602 corresponding to the files they have loaded. See L<perlvar/%INC>.
4603
4604 For a yet-more-powerful import facility, see L</use> and L<perlmod>.
4605
4606 =item reset EXPR
4607 X<reset>
4608
4609 =item reset
4610
4611 Generally used in a C<continue> block at the end of a loop to clear
4612 variables and reset C<??> searches so that they work again.  The
4613 expression is interpreted as a list of single characters (hyphens
4614 allowed for ranges).  All variables and arrays beginning with one of
4615 those letters are reset to their pristine state.  If the expression is
4616 omitted, one-match searches (C<?pattern?>) are reset to match again.  Resets
4617 only variables or searches in the current package.  Always returns
4618 1.  Examples:
4619
4620     reset 'X';          # reset all X variables
4621     reset 'a-z';        # reset lower case variables
4622     reset;              # just reset ?one-time? searches
4623
4624 Resetting C<"A-Z"> is not recommended because you'll wipe out your
4625 C<@ARGV> and C<@INC> arrays and your C<%ENV> hash.  Resets only package
4626 variables--lexical variables are unaffected, but they clean themselves
4627 up on scope exit anyway, so you'll probably want to use them instead.
4628 See L</my>.
4629
4630 =item return EXPR
4631 X<return>
4632
4633 =item return
4634
4635 Returns from a subroutine, C<eval>, or C<do FILE> with the value
4636 given in EXPR.  Evaluation of EXPR may be in list, scalar, or void
4637 context, depending on how the return value will be used, and the context
4638 may vary from one execution to the next (see C<wantarray>).  If no EXPR
4639 is given, returns an empty list in list context, the undefined value in
4640 scalar context, and (of course) nothing at all in a void context.
4641
4642 (Note that in the absence of an explicit C<return>, a subroutine, eval,
4643 or do FILE will automatically return the value of the last expression
4644 evaluated.)
4645
4646 =item reverse LIST
4647 X<reverse> X<rev> X<invert>
4648
4649 In list context, returns a list value consisting of the elements
4650 of LIST in the opposite order.  In scalar context, concatenates the
4651 elements of LIST and returns a string value with all characters
4652 in the opposite order.
4653
4654     print reverse <>;           # line tac, last line first
4655
4656     undef $/;                &n