uniprops.pod: restore properties counts
[perl.git] / lib / unicore / mktables
1 #!/usr/bin/perl -w
2
3 # !!!!!!!!!!!!!!       IF YOU MODIFY THIS FILE       !!!!!!!!!!!!!!!!!!!!!!!!!
4 # Any files created or read by this program should be listed in 'mktables.lst'
5 # Use -makelist to regenerate it.
6
7 # Needs 'no overloading' to run faster on miniperl.  Code commented out at the
8 # subroutine objaddr can be used instead to work as far back (untested) as
9 # 5.8: needs pack "U".  But almost all occurrences of objaddr have been
10 # removed in favor of using 'no overloading'.  You also would have to go
11 # through and replace occurrences like:
12 #       my $addr = do { no overloading; pack 'J', $self; }
13 # with
14 #       my $addr = main::objaddr $self;
15 # (or reverse commit 9b01bafde4b022706c3d6f947a0963f821b2e50b
16 # that instituted the change to main::objaddr, and subsequent commits that
17 # changed 0+$self to pack 'J', $self.)
18
19 my $start_time;
20 BEGIN { # Get the time the script started running; do it at compiliation to
21         # get it as close as possible
22     $start_time= time;
23 }
24
25
26 require 5.010_001;
27 use strict;
28 use warnings;
29 use Carp;
30 use Config;
31 use File::Find;
32 use File::Path;
33 use File::Spec;
34 use Text::Tabs;
35
36 sub DEBUG () { 0 }  # Set to 0 for production; 1 for development
37 my $debugging_build = $Config{"ccflags"} =~ /-DDEBUGGING/;
38
39 ##########################################################################
40 #
41 # mktables -- create the runtime Perl Unicode files (lib/unicore/.../*.pl),
42 # from the Unicode database files (lib/unicore/.../*.txt),  It also generates
43 # a pod file and a .t file
44 #
45 # The structure of this file is:
46 #   First these introductory comments; then
47 #   code needed for everywhere, such as debugging stuff; then
48 #   code to handle input parameters; then
49 #   data structures likely to be of external interest (some of which depend on
50 #       the input parameters, so follows them; then
51 #   more data structures and subroutine and package (class) definitions; then
52 #   the small actual loop to process the input files and finish up; then
53 #   a __DATA__ section, for the .t tests
54 #
55 # This program works on all releases of Unicode through at least 6.0.  The
56 # outputs have been scrutinized most intently for release 5.1.  The others
57 # have been checked for somewhat more than just sanity.  It can handle all
58 # existing Unicode character properties in those releases.
59 #
60 # This program is mostly about Unicode character (or code point) properties.
61 # A property describes some attribute or quality of a code point, like if it
62 # is lowercase or not, its name, what version of Unicode it was first defined
63 # in, or what its uppercase equivalent is.  Unicode deals with these disparate
64 # possibilities by making all properties into mappings from each code point
65 # into some corresponding value.  In the case of it being lowercase or not,
66 # the mapping is either to 'Y' or 'N' (or various synonyms thereof).  Each
67 # property maps each Unicode code point to a single value, called a "property
68 # value".  (Hence each Unicode property is a true mathematical function with
69 # exactly one value per code point.)
70 #
71 # When using a property in a regular expression, what is desired isn't the
72 # mapping of the code point to its property's value, but the reverse (or the
73 # mathematical "inverse relation"): starting with the property value, "Does a
74 # code point map to it?"  These are written in a "compound" form:
75 # \p{property=value}, e.g., \p{category=punctuation}.  This program generates
76 # files containing the lists of code points that map to each such regular
77 # expression property value, one file per list
78 #
79 # There is also a single form shortcut that Perl adds for many of the commonly
80 # used properties.  This happens for all binary properties, plus script,
81 # general_category, and block properties.
82 #
83 # Thus the outputs of this program are files.  There are map files, mostly in
84 # the 'To' directory; and there are list files for use in regular expression
85 # matching, all in subdirectories of the 'lib' directory, with each
86 # subdirectory being named for the property that the lists in it are for.
87 # Bookkeeping, test, and documentation files are also generated.
88
89 my $matches_directory = 'lib';   # Where match (\p{}) files go.
90 my $map_directory = 'To';        # Where map files go.
91
92 # DATA STRUCTURES
93 #
94 # The major data structures of this program are Property, of course, but also
95 # Table.  There are two kinds of tables, very similar to each other.
96 # "Match_Table" is the data structure giving the list of code points that have
97 # a particular property value, mentioned above.  There is also a "Map_Table"
98 # data structure which gives the property's mapping from code point to value.
99 # There are two structures because the match tables need to be combined in
100 # various ways, such as constructing unions, intersections, complements, etc.,
101 # and the map ones don't.  And there would be problems, perhaps subtle, if
102 # a map table were inadvertently operated on in some of those ways.
103 # The use of separate classes with operations defined on one but not the other
104 # prevents accidentally confusing the two.
105 #
106 # At the heart of each table's data structure is a "Range_List", which is just
107 # an ordered list of "Ranges", plus ancillary information, and methods to
108 # operate on them.  A Range is a compact way to store property information.
109 # Each range has a starting code point, an ending code point, and a value that
110 # is meant to apply to all the code points between the two end points,
111 # inclusive.  For a map table, this value is the property value for those
112 # code points.  Two such ranges could be written like this:
113 #   0x41 .. 0x5A, 'Upper',
114 #   0x61 .. 0x7A, 'Lower'
115 #
116 # Each range also has a type used as a convenience to classify the values.
117 # Most ranges in this program will be Type 0, or normal, but there are some
118 # ranges that have a non-zero type.  These are used only in map tables, and
119 # are for mappings that don't fit into the normal scheme of things.  Mappings
120 # that require a hash entry to communicate with utf8.c are one example;
121 # another example is mappings for charnames.pm to use which indicate a name
122 # that is algorithmically determinable from its code point (and vice-versa).
123 # These are used to significantly compact these tables, instead of listing
124 # each one of the tens of thousands individually.
125 #
126 # In a match table, the value of a range is irrelevant (and hence the type as
127 # well, which will always be 0), and arbitrarily set to the null string.
128 # Using the example above, there would be two match tables for those two
129 # entries, one named Upper would contain the 0x41..0x5A range, and the other
130 # named Lower would contain 0x61..0x7A.
131 #
132 # Actually, there are two types of range lists, "Range_Map" is the one
133 # associated with map tables, and "Range_List" with match tables.
134 # Again, this is so that methods can be defined on one and not the other so as
135 # to prevent operating on them in incorrect ways.
136 #
137 # Eventually, most tables are written out to files to be read by utf8_heavy.pl
138 # in the perl core.  All tables could in theory be written, but some are
139 # suppressed because there is no current practical use for them.  It is easy
140 # to change which get written by changing various lists that are near the top
141 # of the actual code in this file.  The table data structures contain enough
142 # ancillary information to allow them to be treated as separate entities for
143 # writing, such as the path to each one's file.  There is a heading in each
144 # map table that gives the format of its entries, and what the map is for all
145 # the code points missing from it.  (This allows tables to be more compact.)
146 #
147 # The Property data structure contains one or more tables.  All properties
148 # contain a map table (except the $perl property which is a
149 # pseudo-property containing only match tables), and any properties that
150 # are usable in regular expression matches also contain various matching
151 # tables, one for each value the property can have.  A binary property can
152 # have two values, True and False (or Y and N, which are preferred by Unicode
153 # terminology).  Thus each of these properties will have a map table that
154 # takes every code point and maps it to Y or N (but having ranges cuts the
155 # number of entries in that table way down), and two match tables, one
156 # which has a list of all the code points that map to Y, and one for all the
157 # code points that map to N.  (For each of these, a third table is also
158 # generated for the pseudo Perl property.  It contains the identical code
159 # points as the Y table, but can be written, not in the compound form, but in
160 # a "single" form like \p{IsUppercase}.)  Many properties are binary, but some
161 # properties have several possible values, some have many, and properties like
162 # Name have a different value for every named code point.  Those will not,
163 # unless the controlling lists are changed, have their match tables written
164 # out.  But all the ones which can be used in regular expression \p{} and \P{}
165 # constructs will.  Generally a property will have either its map table or its
166 # match tables written but not both.  Again, what gets written is controlled
167 # by lists which can easily be changed.  Properties have a 'Type', like
168 # binary, or string, or enum depending on how many match tables there are and
169 # the content of the maps.  This 'Type' is different than a range 'Type', so
170 # don't get confused by the two concepts having the same name.
171 #
172 # For information about the Unicode properties, see Unicode's UAX44 document:
173
174 my $unicode_reference_url = 'http://www.unicode.org/reports/tr44/';
175
176 # As stated earlier, this program will work on any release of Unicode so far.
177 # Most obvious problems in earlier data have NOT been corrected except when
178 # necessary to make Perl or this program work reasonably.  For example, no
179 # folding information was given in early releases, so this program uses the
180 # substitute of lower case, just so that a regular expression with the /i
181 # option will do something that actually gives the right results in many
182 # cases.  There are also a couple other corrections for version 1.1.5,
183 # commented at the point they are made.  As an example of corrections that
184 # weren't made (but could be) is this statement from DerivedAge.txt: "The
185 # supplementary private use code points and the non-character code points were
186 # assigned in version 2.0, but not specifically listed in the UCD until
187 # versions 3.0 and 3.1 respectively."  (To be precise it was 3.0.1 not 3.0.0)
188 # More information on Unicode version glitches is further down in these
189 # introductory comments.
190 #
191 # This program works on all non-provisional properties as of 6.0, though the
192 # files for some are suppressed from apparent lack of demand for them.  You
193 # can change which are output by changing lists in this program.
194 #
195 # The old version of mktables emphasized the term "Fuzzy" to mean Unicode's
196 # loose matchings rules (from Unicode TR18):
197 #
198 #    The recommended names for UCD properties and property values are in
199 #    PropertyAliases.txt [Prop] and PropertyValueAliases.txt
200 #    [PropValue]. There are both abbreviated names and longer, more
201 #    descriptive names. It is strongly recommended that both names be
202 #    recognized, and that loose matching of property names be used,
203 #    whereby the case distinctions, whitespace, hyphens, and underbar
204 #    are ignored.
205 # The program still allows Fuzzy to override its determination of if loose
206 # matching should be used, but it isn't currently used, as it is no longer
207 # needed; the calculations it makes are good enough.
208 #
209 # SUMMARY OF HOW IT WORKS:
210 #
211 #   Process arguments
212 #
213 #   A list is constructed containing each input file that is to be processed
214 #
215 #   Each file on the list is processed in a loop, using the associated handler
216 #   code for each:
217 #        The PropertyAliases.txt and PropValueAliases.txt files are processed
218 #            first.  These files name the properties and property values.
219 #            Objects are created of all the property and property value names
220 #            that the rest of the input should expect, including all synonyms.
221 #        The other input files give mappings from properties to property
222 #           values.  That is, they list code points and say what the mapping
223 #           is under the given property.  Some files give the mappings for
224 #           just one property; and some for many.  This program goes through
225 #           each file and populates the properties from them.  Some properties
226 #           are listed in more than one file, and Unicode has set up a
227 #           precedence as to which has priority if there is a conflict.  Thus
228 #           the order of processing matters, and this program handles the
229 #           conflict possibility by processing the overriding input files
230 #           last, so that if necessary they replace earlier values.
231 #        After this is all done, the program creates the property mappings not
232 #            furnished by Unicode, but derivable from what it does give.
233 #        The tables of code points that match each property value in each
234 #            property that is accessible by regular expressions are created.
235 #        The Perl-defined properties are created and populated.  Many of these
236 #            require data determined from the earlier steps
237 #        Any Perl-defined synonyms are created, and name clashes between Perl
238 #            and Unicode are reconciled and warned about.
239 #        All the properties are written to files
240 #        Any other files are written, and final warnings issued.
241 #
242 # For clarity, a number of operators have been overloaded to work on tables:
243 #   ~ means invert (take all characters not in the set).  The more
244 #       conventional '!' is not used because of the possibility of confusing
245 #       it with the actual boolean operation.
246 #   + means union
247 #   - means subtraction
248 #   & means intersection
249 # The precedence of these is the order listed.  Parentheses should be
250 # copiously used.  These are not a general scheme.  The operations aren't
251 # defined for a number of things, deliberately, to avoid getting into trouble.
252 # Operations are done on references and affect the underlying structures, so
253 # that the copy constructors for them have been overloaded to not return a new
254 # clone, but the input object itself.
255 #
256 # The bool operator is deliberately not overloaded to avoid confusion with
257 # "should it mean if the object merely exists, or also is non-empty?".
258 #
259 # WHY CERTAIN DESIGN DECISIONS WERE MADE
260 #
261 # This program needs to be able to run under miniperl.  Therefore, it uses a
262 # minimum of other modules, and hence implements some things itself that could
263 # be gotten from CPAN
264 #
265 # This program uses inputs published by the Unicode Consortium.  These can
266 # change incompatibly between releases without the Perl maintainers realizing
267 # it.  Therefore this program is now designed to try to flag these.  It looks
268 # at the directories where the inputs are, and flags any unrecognized files.
269 # It keeps track of all the properties in the files it handles, and flags any
270 # that it doesn't know how to handle.  It also flags any input lines that
271 # don't match the expected syntax, among other checks.
272 #
273 # It is also designed so if a new input file matches one of the known
274 # templates, one hopefully just needs to add it to a list to have it
275 # processed.
276 #
277 # As mentioned earlier, some properties are given in more than one file.  In
278 # particular, the files in the extracted directory are supposedly just
279 # reformattings of the others.  But they contain information not easily
280 # derivable from the other files, including results for Unihan, which this
281 # program doesn't ordinarily look at, and for unassigned code points.  They
282 # also have historically had errors or been incomplete.  In an attempt to
283 # create the best possible data, this program thus processes them first to
284 # glean information missing from the other files; then processes those other
285 # files to override any errors in the extracted ones.  Much of the design was
286 # driven by this need to store things and then possibly override them.
287 #
288 # It tries to keep fatal errors to a minimum, to generate something usable for
289 # testing purposes.  It always looks for files that could be inputs, and will
290 # warn about any that it doesn't know how to handle (the -q option suppresses
291 # the warning).
292 #
293 # Why have files written out for binary 'N' matches?
294 #   For binary properties, if you know the mapping for either Y or N; the
295 #   other is trivial to construct, so could be done at Perl run-time by just
296 #   complementing the result, instead of having a file for it.  That is, if
297 #   someone types in \p{foo: N}, Perl could translate that to \P{foo: Y} and
298 #   not need a file.   The problem is communicating to Perl that a given
299 #   property is binary.  Perl can't figure it out from looking at the N (or
300 #   No), as some non-binary properties have these as property values.  So
301 #   rather than inventing a way to communicate this info back to the core,
302 #   which would have required changes there as well, it was simpler just to
303 #   add the extra tables.
304 #
305 # Why is there more than one type of range?
306 #   This simplified things.  There are some very specialized code points that
307 #   have to be handled specially for output, such as Hangul syllable names.
308 #   By creating a range type (done late in the development process), it
309 #   allowed this to be stored with the range, and overridden by other input.
310 #   Originally these were stored in another data structure, and it became a
311 #   mess trying to decide if a second file that was for the same property was
312 #   overriding the earlier one or not.
313 #
314 # Why are there two kinds of tables, match and map?
315 #   (And there is a base class shared by the two as well.)  As stated above,
316 #   they actually are for different things.  Development proceeded much more
317 #   smoothly when I (khw) realized the distinction.  Map tables are used to
318 #   give the property value for every code point (actually every code point
319 #   that doesn't map to a default value).  Match tables are used for regular
320 #   expression matches, and are essentially the inverse mapping.  Separating
321 #   the two allows more specialized methods, and error checks so that one
322 #   can't just take the intersection of two map tables, for example, as that
323 #   is nonsensical.
324 #
325 # There are no match tables generated for matches of the null string.  These
326 # would look like qr/\p{JSN=}/ currently without modifying the regex code.
327 # Perhaps something like them could be added if necessary.  The JSN does have
328 # a real code point U+110B that maps to the null string, but it is a
329 # contributory property, and therefore not output by default.  And it's easily
330 # handled so far by making the null string the default where it is a
331 # possibility.
332 #
333 # DEBUGGING
334 #
335 # This program is written so it will run under miniperl.  Occasionally changes
336 # will cause an error where the backtrace doesn't work well under miniperl.
337 # To diagnose the problem, you can instead run it under regular perl, if you
338 # have one compiled.
339 #
340 # There is a good trace facility.  To enable it, first sub DEBUG must be set
341 # to return true.  Then a line like
342 #
343 # local $to_trace = 1 if main::DEBUG;
344 #
345 # can be added to enable tracing in its lexical scope or until you insert
346 # another line:
347 #
348 # local $to_trace = 0 if main::DEBUG;
349 #
350 # then use a line like "trace $a, @b, %c, ...;
351 #
352 # Some of the more complex subroutines already have trace statements in them.
353 # Permanent trace statements should be like:
354 #
355 # trace ... if main::DEBUG && $to_trace;
356 #
357 # If there is just one or a few files that you're debugging, you can easily
358 # cause most everything else to be skipped.  Change the line
359 #
360 # my $debug_skip = 0;
361 #
362 # to 1, and every file whose object is in @input_file_objects and doesn't have
363 # a, 'non_skip => 1,' in its constructor will be skipped.
364 #
365 # To compare the output tables, it may be useful to specify the -annotate
366 # flag.  This causes the tables to expand so there is one entry for each
367 # non-algorithmically named code point giving, currently its name, and its
368 # graphic representation if printable (and you have a font that knows about
369 # it).  This makes it easier to see what the particular code points are in
370 # each output table.  The tables are usable, but because they don't have
371 # ranges (for the most part), a Perl using them will run slower.  Non-named
372 # code points are annotated with a description of their status, and contiguous
373 # ones with the same description will be output as a range rather than
374 # individually.  Algorithmically named characters are also output as ranges,
375 # except when there are just a few contiguous ones.
376 #
377 # FUTURE ISSUES
378 #
379 # The program would break if Unicode were to change its names so that
380 # interior white space, underscores, or dashes differences were significant
381 # within property and property value names.
382 #
383 # It might be easier to use the xml versions of the UCD if this program ever
384 # would need heavy revision, and the ability to handle old versions was not
385 # required.
386 #
387 # There is the potential for name collisions, in that Perl has chosen names
388 # that Unicode could decide it also likes.  There have been such collisions in
389 # the past, with mostly Perl deciding to adopt the Unicode definition of the
390 # name.  However in the 5.2 Unicode beta testing, there were a number of such
391 # collisions, which were withdrawn before the final release, because of Perl's
392 # and other's protests.  These all involved new properties which began with
393 # 'Is'.  Based on the protests, Unicode is unlikely to try that again.  Also,
394 # many of the Perl-defined synonyms, like Any, Word, etc, are listed in a
395 # Unicode document, so they are unlikely to be used by Unicode for another
396 # purpose.  However, they might try something beginning with 'In', or use any
397 # of the other Perl-defined properties.  This program will warn you of name
398 # collisions, and refuse to generate tables with them, but manual intervention
399 # will be required in this event.  One scheme that could be implemented, if
400 # necessary, would be to have this program generate another file, or add a
401 # field to mktables.lst that gives the date of first definition of a property.
402 # Each new release of Unicode would use that file as a basis for the next
403 # iteration.  And the Perl synonym addition code could sort based on the age
404 # of the property, so older properties get priority, and newer ones that clash
405 # would be refused; hence existing code would not be impacted, and some other
406 # synonym would have to be used for the new property.  This is ugly, and
407 # manual intervention would certainly be easier to do in the short run; lets
408 # hope it never comes to this.
409 #
410 # A NOTE ON UNIHAN
411 #
412 # This program can generate tables from the Unihan database.  But it doesn't
413 # by default, letting the CPAN module Unicode::Unihan handle them.  Prior to
414 # version 5.2, this database was in a single file, Unihan.txt.  In 5.2 the
415 # database was split into 8 different files, all beginning with the letters
416 # 'Unihan'.  This program will read those file(s) if present, but it needs to
417 # know which of the many properties in the file(s) should have tables created
418 # for them.  It will create tables for any properties listed in
419 # PropertyAliases.txt and PropValueAliases.txt, plus any listed in the
420 # @cjk_properties array and the @cjk_property_values array.  Thus, if a
421 # property you want is not in those files of the release you are building
422 # against, you must add it to those two arrays.  Starting in 4.0, the
423 # Unicode_Radical_Stroke was listed in those files, so if the Unihan database
424 # is present in the directory, a table will be generated for that property.
425 # In 5.2, several more properties were added.  For your convenience, the two
426 # arrays are initialized with all the 6.0 listed properties that are also in
427 # earlier releases.  But these are commented out.  You can just uncomment the
428 # ones you want, or use them as a template for adding entries for other
429 # properties.
430 #
431 # You may need to adjust the entries to suit your purposes.  setup_unihan(),
432 # and filter_unihan_line() are the functions where this is done.  This program
433 # already does some adjusting to make the lines look more like the rest of the
434 # Unicode DB;  You can see what that is in filter_unihan_line()
435 #
436 # There is a bug in the 3.2 data file in which some values for the
437 # kPrimaryNumeric property have commas and an unexpected comment.  A filter
438 # could be added for these; or for a particular installation, the Unihan.txt
439 # file could be edited to fix them.
440 #
441 # HOW TO ADD A FILE TO BE PROCESSED
442 #
443 # A new file from Unicode needs to have an object constructed for it in
444 # @input_file_objects, probably at the end or at the end of the extracted
445 # ones.  The program should warn you if its name will clash with others on
446 # restrictive file systems, like DOS.  If so, figure out a better name, and
447 # add lines to the README.perl file giving that.  If the file is a character
448 # property, it should be in the format that Unicode has by default
449 # standardized for such files for the more recently introduced ones.
450 # If so, the Input_file constructor for @input_file_objects can just be the
451 # file name and release it first appeared in.  If not, then it should be
452 # possible to construct an each_line_handler() to massage the line into the
453 # standardized form.
454 #
455 # For non-character properties, more code will be needed.  You can look at
456 # the existing entries for clues.
457 #
458 # UNICODE VERSIONS NOTES
459 #
460 # The Unicode UCD has had a number of errors in it over the versions.  And
461 # these remain, by policy, in the standard for that version.  Therefore it is
462 # risky to correct them, because code may be expecting the error.  So this
463 # program doesn't generally make changes, unless the error breaks the Perl
464 # core.  As an example, some versions of 2.1.x Jamo.txt have the wrong value
465 # for U+1105, which causes real problems for the algorithms for Jamo
466 # calculations, so it is changed here.
467 #
468 # But it isn't so clear cut as to what to do about concepts that are
469 # introduced in a later release; should they extend back to earlier releases
470 # where the concept just didn't exist?  It was easier to do this than to not,
471 # so that's what was done.  For example, the default value for code points not
472 # in the files for various properties was probably undefined until changed by
473 # some version.  No_Block for blocks is such an example.  This program will
474 # assign No_Block even in Unicode versions that didn't have it.  This has the
475 # benefit that code being written doesn't have to special case earlier
476 # versions; and the detriment that it doesn't match the Standard precisely for
477 # the affected versions.
478 #
479 # Here are some observations about some of the issues in early versions:
480 #
481 # The number of code points in \p{alpha} halve in 2.1.9.  It turns out that
482 # the reason is that the CJK block starting at 4E00 was removed from PropList,
483 # and was not put back in until 3.1.0
484 #
485 # Unicode introduced the synonym Space for White_Space in 4.1.  Perl has
486 # always had a \p{Space}.  In release 3.2 only, they are not synonymous.  The
487 # reason is that 3.2 introduced U+205F=medium math space, which was not
488 # classed as white space, but Perl figured out that it should have been. 4.0
489 # reclassified it correctly.
490 #
491 # Another change between 3.2 and 4.0 is the CCC property value ATBL.  In 3.2
492 # this was erroneously a synonym for 202.  In 4.0, ATB became 202, and ATBL
493 # was left with no code points, as all the ones that mapped to 202 stayed
494 # mapped to 202.  Thus if your program used the numeric name for the class,
495 # it would not have been affected, but if it used the mnemonic, it would have
496 # been.
497 #
498 # \p{Script=Hrkt} (Katakana_Or_Hiragana) came in 4.0.1.  Before that code
499 # points which eventually came to have this script property value, instead
500 # mapped to "Unknown".  But in the next release all these code points were
501 # moved to \p{sc=common} instead.
502 #
503 # The default for missing code points for BidiClass is complicated.  Starting
504 # in 3.1.1, the derived file DBidiClass.txt handles this, but this program
505 # tries to do the best it can for earlier releases.  It is done in
506 # process_PropertyAliases()
507 #
508 ##############################################################################
509
510 my $UNDEF = ':UNDEF:';  # String to print out for undefined values in tracing
511                         # and errors
512 my $MAX_LINE_WIDTH = 78;
513
514 # Debugging aid to skip most files so as to not be distracted by them when
515 # concentrating on the ones being debugged.  Add
516 # non_skip => 1,
517 # to the constructor for those files you want processed when you set this.
518 # Files with a first version number of 0 are special: they are always
519 # processed regardless of the state of this flag.
520 my $debug_skip = 0;
521
522 # Set to 1 to enable tracing.
523 our $to_trace = 0;
524
525 { # Closure for trace: debugging aid
526     my $print_caller = 1;        # ? Include calling subroutine name
527     my $main_with_colon = 'main::';
528     my $main_colon_length = length($main_with_colon);
529
530     sub trace {
531         return unless $to_trace;        # Do nothing if global flag not set
532
533         my @input = @_;
534
535         local $DB::trace = 0;
536         $DB::trace = 0;          # Quiet 'used only once' message
537
538         my $line_number;
539
540         # Loop looking up the stack to get the first non-trace caller
541         my $caller_line;
542         my $caller_name;
543         my $i = 0;
544         do {
545             $line_number = $caller_line;
546             (my $pkg, my $file, $caller_line, my $caller) = caller $i++;
547             $caller = $main_with_colon unless defined $caller;
548
549             $caller_name = $caller;
550
551             # get rid of pkg
552             $caller_name =~ s/.*:://;
553             if (substr($caller_name, 0, $main_colon_length)
554                 eq $main_with_colon)
555             {
556                 $caller_name = substr($caller_name, $main_colon_length);
557             }
558
559         } until ($caller_name ne 'trace');
560
561         # If the stack was empty, we were called from the top level
562         $caller_name = 'main' if ($caller_name eq ""
563                                     || $caller_name eq 'trace');
564
565         my $output = "";
566         foreach my $string (@input) {
567             #print STDERR __LINE__, ": ", join ", ", @input, "\n";
568             if (ref $string eq 'ARRAY' || ref $string eq 'HASH') {
569                 $output .= simple_dumper($string);
570             }
571             else {
572                 $string = "$string" if ref $string;
573                 $string = $UNDEF unless defined $string;
574                 chomp $string;
575                 $string = '""' if $string eq "";
576                 $output .= " " if $output ne ""
577                                 && $string ne ""
578                                 && substr($output, -1, 1) ne " "
579                                 && substr($string, 0, 1) ne " ";
580                 $output .= $string;
581             }
582         }
583
584         print STDERR sprintf "%4d: ", $line_number if defined $line_number;
585         print STDERR "$caller_name: " if $print_caller;
586         print STDERR $output, "\n";
587         return;
588     }
589 }
590
591 # This is for a rarely used development feature that allows you to compare two
592 # versions of the Unicode standard without having to deal with changes caused
593 # by the code points introduced in the later verson.  Change the 0 to a SINGLE
594 # dotted Unicode release number (e.g. 2.1).  Only code points introduced in
595 # that release and earlier will be used; later ones are thrown away.  You use
596 # the version number of the earliest one you want to compare; then run this
597 # program on directory structures containing each release, and compare the
598 # outputs.  These outputs will therefore include only the code points common
599 # to both releases, and you can see the changes caused just by the underlying
600 # release semantic changes.  For versions earlier than 3.2, you must copy a
601 # version of DAge.txt into the directory.
602 my $string_compare_versions = DEBUG && 0; #  e.g., v2.1;
603 my $compare_versions = DEBUG
604                        && $string_compare_versions
605                        && pack "C*", split /\./, $string_compare_versions;
606
607 sub uniques {
608     # Returns non-duplicated input values.  From "Perl Best Practices:
609     # Encapsulated Cleverness".  p. 455 in first edition.
610
611     my %seen;
612     # Arguably this breaks encapsulation, if the goal is to permit multiple
613     # distinct objects to stringify to the same value, and be interchangeable.
614     # However, for this program, no two objects stringify identically, and all
615     # lists passed to this function are either objects or strings. So this
616     # doesn't affect correctness, but it does give a couple of percent speedup.
617     no overloading;
618     return grep { ! $seen{$_}++ } @_;
619 }
620
621 $0 = File::Spec->canonpath($0);
622
623 my $make_test_script = 0;      # ? Should we output a test script
624 my $write_unchanged_files = 0; # ? Should we update the output files even if
625                                #    we don't think they have changed
626 my $use_directory = "";        # ? Should we chdir somewhere.
627 my $pod_directory;             # input directory to store the pod file.
628 my $pod_file = 'perluniprops';
629 my $t_path;                     # Path to the .t test file
630 my $file_list = 'mktables.lst'; # File to store input and output file names.
631                                # This is used to speed up the build, by not
632                                # executing the main body of the program if
633                                # nothing on the list has changed since the
634                                # previous build
635 my $make_list = 1;             # ? Should we write $file_list.  Set to always
636                                # make a list so that when the pumpking is
637                                # preparing a release, s/he won't have to do
638                                # special things
639 my $glob_list = 0;             # ? Should we try to include unknown .txt files
640                                # in the input.
641 my $output_range_counts = $debugging_build;   # ? Should we include the number
642                                               # of code points in ranges in
643                                               # the output
644 my $annotate = 0;              # ? Should character names be in the output
645
646 # Verbosity levels; 0 is quiet
647 my $NORMAL_VERBOSITY = 1;
648 my $PROGRESS = 2;
649 my $VERBOSE = 3;
650
651 my $verbosity = $NORMAL_VERBOSITY;
652
653 # Process arguments
654 while (@ARGV) {
655     my $arg = shift @ARGV;
656     if ($arg eq '-v') {
657         $verbosity = $VERBOSE;
658     }
659     elsif ($arg eq '-p') {
660         $verbosity = $PROGRESS;
661         $| = 1;     # Flush buffers as we go.
662     }
663     elsif ($arg eq '-q') {
664         $verbosity = 0;
665     }
666     elsif ($arg eq '-w') {
667         $write_unchanged_files = 1; # update the files even if havent changed
668     }
669     elsif ($arg eq '-check') {
670         my $this = shift @ARGV;
671         my $ok = shift @ARGV;
672         if ($this ne $ok) {
673             print "Skipping as check params are not the same.\n";
674             exit(0);
675         }
676     }
677     elsif ($arg eq '-P' && defined ($pod_directory = shift)) {
678         -d $pod_directory or croak "Directory '$pod_directory' doesn't exist";
679     }
680     elsif ($arg eq '-maketest' || ($arg eq '-T' && defined ($t_path = shift)))
681     {
682         $make_test_script = 1;
683     }
684     elsif ($arg eq '-makelist') {
685         $make_list = 1;
686     }
687     elsif ($arg eq '-C' && defined ($use_directory = shift)) {
688         -d $use_directory or croak "Unknown directory '$use_directory'";
689     }
690     elsif ($arg eq '-L') {
691
692         # Existence not tested until have chdir'd
693         $file_list = shift;
694     }
695     elsif ($arg eq '-globlist') {
696         $glob_list = 1;
697     }
698     elsif ($arg eq '-c') {
699         $output_range_counts = ! $output_range_counts
700     }
701     elsif ($arg eq '-annotate') {
702         $annotate = 1;
703         $debugging_build = 1;
704         $output_range_counts = 1;
705     }
706     else {
707         my $with_c = 'with';
708         $with_c .= 'out' if $output_range_counts;   # Complements the state
709         croak <<END;
710 usage: $0 [-c|-p|-q|-v|-w] [-C dir] [-L filelist] [ -P pod_dir ]
711           [ -T test_file_path ] [-globlist] [-makelist] [-maketest]
712           [-check A B ]
713   -c          : Output comments $with_c number of code points in ranges
714   -q          : Quiet Mode: Only output serious warnings.
715   -p          : Set verbosity level to normal plus show progress.
716   -v          : Set Verbosity level high:  Show progress and non-serious
717                 warnings
718   -w          : Write files regardless
719   -C dir      : Change to this directory before proceeding. All relative paths
720                 except those specified by the -P and -T options will be done
721                 with respect to this directory.
722   -P dir      : Output $pod_file file to directory 'dir'.
723   -T path     : Create a test script as 'path'; overrides -maketest
724   -L filelist : Use alternate 'filelist' instead of standard one
725   -globlist   : Take as input all non-Test *.txt files in current and sub
726                 directories
727   -maketest   : Make test script 'TestProp.pl' in current (or -C directory),
728                 overrides -T
729   -makelist   : Rewrite the file list $file_list based on current setup
730   -annotate   : Output an annotation for each character in the table files;
731                 useful for debugging mktables, looking at diffs; but is slow,
732                 memory intensive; resulting tables are usable but slow and
733                 very large.
734   -check A B  : Executes $0 only if A and B are the same
735 END
736     }
737 }
738
739 # Stores the most-recently changed file.  If none have changed, can skip the
740 # build
741 my $most_recent = (stat $0)[9];   # Do this before the chdir!
742
743 # Change directories now, because need to read 'version' early.
744 if ($use_directory) {
745     if ($pod_directory && ! File::Spec->file_name_is_absolute($pod_directory)) {
746         $pod_directory = File::Spec->rel2abs($pod_directory);
747     }
748     if ($t_path && ! File::Spec->file_name_is_absolute($t_path)) {
749         $t_path = File::Spec->rel2abs($t_path);
750     }
751     chdir $use_directory or croak "Failed to chdir to '$use_directory':$!";
752     if ($pod_directory && File::Spec->file_name_is_absolute($pod_directory)) {
753         $pod_directory = File::Spec->abs2rel($pod_directory);
754     }
755     if ($t_path && File::Spec->file_name_is_absolute($t_path)) {
756         $t_path = File::Spec->abs2rel($t_path);
757     }
758 }
759
760 # Get Unicode version into regular and v-string.  This is done now because
761 # various tables below get populated based on it.  These tables are populated
762 # here to be near the top of the file, and so easily seeable by those needing
763 # to modify things.
764 open my $VERSION, "<", "version"
765                     or croak "$0: can't open required file 'version': $!\n";
766 my $string_version = <$VERSION>;
767 close $VERSION;
768 chomp $string_version;
769 my $v_version = pack "C*", split /\./, $string_version;        # v string
770
771 # The following are the complete names of properties with property values that
772 # are known to not match any code points in some versions of Unicode, but that
773 # may change in the future so they should be matchable, hence an empty file is
774 # generated for them.
775 my @tables_that_may_be_empty = (
776                                 'Joining_Type=Left_Joining',
777                                 );
778 push @tables_that_may_be_empty, 'Script=Common' if $v_version le v4.0.1;
779 push @tables_that_may_be_empty, 'Title' if $v_version lt v2.0.0;
780 push @tables_that_may_be_empty, 'Script=Katakana_Or_Hiragana'
781                                                     if $v_version ge v4.1.0;
782
783 # The lists below are hashes, so the key is the item in the list, and the
784 # value is the reason why it is in the list.  This makes generation of
785 # documentation easier.
786
787 my %why_suppressed;  # No file generated for these.
788
789 # Files aren't generated for empty extraneous properties.  This is arguable.
790 # Extraneous properties generally come about because a property is no longer
791 # used in a newer version of Unicode.  If we generated a file without code
792 # points, programs that used to work on that property will still execute
793 # without errors.  It just won't ever match (or will always match, with \P{}).
794 # This means that the logic is now likely wrong.  I (khw) think its better to
795 # find this out by getting an error message.  Just move them to the table
796 # above to change this behavior
797 my %why_suppress_if_empty_warn_if_not = (
798
799    # It is the only property that has ever officially been removed from the
800    # Standard.  The database never contained any code points for it.
801    'Special_Case_Condition' => 'Obsolete',
802
803    # Apparently never official, but there were code points in some versions of
804    # old-style PropList.txt
805    'Non_Break' => 'Obsolete',
806 );
807
808 # These would normally go in the warn table just above, but they were changed
809 # a long time before this program was written, so warnings about them are
810 # moot.
811 if ($v_version gt v3.2.0) {
812     push @tables_that_may_be_empty,
813                                 'Canonical_Combining_Class=Attached_Below_Left'
814 }
815
816 # These are listed in the Property aliases file in 6.0, but Unihan is ignored
817 # unless explicitly added.
818 if ($v_version ge v5.2.0) {
819     my $unihan = 'Unihan; remove from list if using Unihan';
820     foreach my $table (qw (
821                            kAccountingNumeric
822                            kOtherNumeric
823                            kPrimaryNumeric
824                            kCompatibilityVariant
825                            kIICore
826                            kIRG_GSource
827                            kIRG_HSource
828                            kIRG_JSource
829                            kIRG_KPSource
830                            kIRG_MSource
831                            kIRG_KSource
832                            kIRG_TSource
833                            kIRG_USource
834                            kIRG_VSource
835                            kRSUnicode
836                         ))
837     {
838         $why_suppress_if_empty_warn_if_not{$table} = $unihan;
839     }
840 }
841
842 # Properties that this program ignores.
843 my @unimplemented_properties = (
844 'Unicode_Radical_Stroke'    # Remove if changing to handle this one.
845 );
846
847 # There are several types of obsolete properties defined by Unicode.  These
848 # must be hand-edited for every new Unicode release.
849 my %why_deprecated;  # Generates a deprecated warning message if used.
850 my %why_stabilized;  # Documentation only
851 my %why_obsolete;    # Documentation only
852
853 {   # Closure
854     my $simple = 'Perl uses the more complete version of this property';
855     my $unihan = 'Unihan properties are by default not enabled in the Perl core.  Instead use CPAN: Unicode::Unihan';
856
857     my $other_properties = 'other properties';
858     my $contributory = "Used by Unicode internally for generating $other_properties and not intended to be used stand-alone";
859     my $why_no_expand  = "Deprecated by Unicode: less useful than UTF-specific calculations",
860
861     %why_deprecated = (
862         'Grapheme_Link' => 'Deprecated by Unicode:  Duplicates ccc=vr (Canonical_Combining_Class=Virama)',
863         'Jamo_Short_Name' => $contributory,
864         'Line_Break=Surrogate' => 'Deprecated by Unicode because surrogates should never appear in well-formed text, and therefore shouldn\'t be the basis for line breaking',
865         'Other_Alphabetic' => $contributory,
866         'Other_Default_Ignorable_Code_Point' => $contributory,
867         'Other_Grapheme_Extend' => $contributory,
868         'Other_ID_Continue' => $contributory,
869         'Other_ID_Start' => $contributory,
870         'Other_Lowercase' => $contributory,
871         'Other_Math' => $contributory,
872         'Other_Uppercase' => $contributory,
873     );
874
875     %why_suppressed = (
876         # There is a lib/unicore/Decomposition.pl (used by Normalize.pm) which
877         # contains the same information, but without the algorithmically
878         # determinable Hangul syllables'.  This file is not published, so it's
879         # existence is not noted in the comment.
880         'Decomposition_Mapping' => 'Accessible via Unicode::Normalize',
881
882         'ISO_Comment' => 'Apparently no demand for it, but can access it through Unicode::UCD::charinfo.  Obsoleted, and code points for it removed in Unicode 5.2',
883         'Unicode_1_Name' => "$simple, and no apparent demand for it, but can access it through Unicode::UCD::charinfo.  If there is no later name for a code point, then this one is used instead in charnames",
884
885         'Simple_Case_Folding' => "$simple.  Can access this through Unicode::UCD::casefold",
886         'Simple_Lowercase_Mapping' => "$simple.  Can access this through Unicode::UCD::charinfo",
887         'Simple_Titlecase_Mapping' => "$simple.  Can access this through Unicode::UCD::charinfo",
888         'Simple_Uppercase_Mapping' => "$simple.  Can access this through Unicode::UCD::charinfo",
889
890         'Name' => "Accessible via 'use charnames;'",
891         'Name_Alias' => "Accessible via 'use charnames;'",
892
893         FC_NFKC_Closure => 'Supplanted in usage by NFKC_Casefold; otherwise not useful',
894         Expands_On_NFC => $why_no_expand,
895         Expands_On_NFD => $why_no_expand,
896         Expands_On_NFKC => $why_no_expand,
897         Expands_On_NFKD => $why_no_expand,
898     );
899
900     # The following are suppressed because they were made contributory or
901     # deprecated by Unicode before Perl ever thought about supporting them.
902     foreach my $property ('Jamo_Short_Name', 'Grapheme_Link') {
903         $why_suppressed{$property} = $why_deprecated{$property};
904     }
905
906     # Customize the message for all the 'Other_' properties
907     foreach my $property (keys %why_deprecated) {
908         next if (my $main_property = $property) !~ s/^Other_//;
909         $why_deprecated{$property} =~ s/$other_properties/the $main_property property (which should be used instead)/;
910     }
911 }
912
913 if ($v_version ge 4.0.0) {
914     $why_stabilized{'Hyphen'} = 'Use the Line_Break property instead; see www.unicode.org/reports/tr14';
915     if ($v_version ge 6.0.0) {
916         $why_deprecated{'Hyphen'} = 'Supplanted by Line_Break property values; see www.unicode.org/reports/tr14';
917     }
918 }
919 if ($v_version ge 5.2.0 && $v_version lt 6.0.0) {
920     $why_obsolete{'ISO_Comment'} = 'Code points for it have been removed';
921     if ($v_version ge 6.0.0) {
922         $why_deprecated{'ISO_Comment'} = 'No longer needed for chart generation; otherwise not useful, and code points for it have been removed';
923     }
924 }
925
926 # Probably obsolete forever
927 if ($v_version ge v4.1.0) {
928     $why_suppressed{'Script=Katakana_Or_Hiragana'} = 'Obsolete.  All code points previously matched by this have been moved to "Script=Common"';
929 }
930
931 # This program can create files for enumerated-like properties, such as
932 # 'Numeric_Type'.  This file would be the same format as for a string
933 # property, with a mapping from code point to its value, so you could look up,
934 # for example, the script a code point is in.  But no one so far wants this
935 # mapping, or they have found another way to get it since this is a new
936 # feature.  So no file is generated except if it is in this list.
937 my @output_mapped_properties = split "\n", <<END;
938 END
939
940 # If you are using the Unihan database, you need to add the properties that
941 # you want to extract from it to this table.  For your convenience, the
942 # properties in the 6.0 PropertyAliases.txt file are listed, commented out
943 my @cjk_properties = split "\n", <<'END';
944 #cjkAccountingNumeric; kAccountingNumeric
945 #cjkOtherNumeric; kOtherNumeric
946 #cjkPrimaryNumeric; kPrimaryNumeric
947 #cjkCompatibilityVariant; kCompatibilityVariant
948 #cjkIICore ; kIICore
949 #cjkIRG_GSource; kIRG_GSource
950 #cjkIRG_HSource; kIRG_HSource
951 #cjkIRG_JSource; kIRG_JSource
952 #cjkIRG_KPSource; kIRG_KPSource
953 #cjkIRG_KSource; kIRG_KSource
954 #cjkIRG_TSource; kIRG_TSource
955 #cjkIRG_USource; kIRG_USource
956 #cjkIRG_VSource; kIRG_VSource
957 #cjkRSUnicode; kRSUnicode                ; Unicode_Radical_Stroke; URS
958 END
959
960 # Similarly for the property values.  For your convenience, the lines in the
961 # 6.0 PropertyAliases.txt file are listed.  Just remove the first BUT NOT both
962 # '#' marks
963 my @cjk_property_values = split "\n", <<'END';
964 ## @missing: 0000..10FFFF; cjkAccountingNumeric; NaN
965 ## @missing: 0000..10FFFF; cjkCompatibilityVariant; <code point>
966 ## @missing: 0000..10FFFF; cjkIICore; <none>
967 ## @missing: 0000..10FFFF; cjkIRG_GSource; <none>
968 ## @missing: 0000..10FFFF; cjkIRG_HSource; <none>
969 ## @missing: 0000..10FFFF; cjkIRG_JSource; <none>
970 ## @missing: 0000..10FFFF; cjkIRG_KPSource; <none>
971 ## @missing: 0000..10FFFF; cjkIRG_KSource; <none>
972 ## @missing: 0000..10FFFF; cjkIRG_TSource; <none>
973 ## @missing: 0000..10FFFF; cjkIRG_USource; <none>
974 ## @missing: 0000..10FFFF; cjkIRG_VSource; <none>
975 ## @missing: 0000..10FFFF; cjkOtherNumeric; NaN
976 ## @missing: 0000..10FFFF; cjkPrimaryNumeric; NaN
977 ## @missing: 0000..10FFFF; cjkRSUnicode; <none>
978 END
979
980 # The input files don't list every code point.  Those not listed are to be
981 # defaulted to some value.  Below are hard-coded what those values are for
982 # non-binary properties as of 5.1.  Starting in 5.0, there are
983 # machine-parsable comment lines in the files the give the defaults; so this
984 # list shouldn't have to be extended.  The claim is that all missing entries
985 # for binary properties will default to 'N'.  Unicode tried to change that in
986 # 5.2, but the beta period produced enough protest that they backed off.
987 #
988 # The defaults for the fields that appear in UnicodeData.txt in this hash must
989 # be in the form that it expects.  The others may be synonyms.
990 my $CODE_POINT = '<code point>';
991 my %default_mapping = (
992     Age => "Unassigned",
993     # Bidi_Class => Complicated; set in code
994     Bidi_Mirroring_Glyph => "",
995     Block => 'No_Block',
996     Canonical_Combining_Class => 0,
997     Case_Folding => $CODE_POINT,
998     Decomposition_Mapping => $CODE_POINT,
999     Decomposition_Type => 'None',
1000     East_Asian_Width => "Neutral",
1001     FC_NFKC_Closure => $CODE_POINT,
1002     General_Category => 'Cn',
1003     Grapheme_Cluster_Break => 'Other',
1004     Hangul_Syllable_Type => 'NA',
1005     ISO_Comment => "",
1006     Jamo_Short_Name => "",
1007     Joining_Group => "No_Joining_Group",
1008     # Joining_Type => Complicated; set in code
1009     kIICore => 'N',   #                       Is converted to binary
1010     #Line_Break => Complicated; set in code
1011     Lowercase_Mapping => $CODE_POINT,
1012     Name => "",
1013     Name_Alias => "",
1014     NFC_QC => 'Yes',
1015     NFD_QC => 'Yes',
1016     NFKC_QC => 'Yes',
1017     NFKD_QC => 'Yes',
1018     Numeric_Type => 'None',
1019     Numeric_Value => 'NaN',
1020     Script => ($v_version le 4.1.0) ? 'Common' : 'Unknown',
1021     Sentence_Break => 'Other',
1022     Simple_Case_Folding => $CODE_POINT,
1023     Simple_Lowercase_Mapping => $CODE_POINT,
1024     Simple_Titlecase_Mapping => $CODE_POINT,
1025     Simple_Uppercase_Mapping => $CODE_POINT,
1026     Titlecase_Mapping => $CODE_POINT,
1027     Unicode_1_Name => "",
1028     Unicode_Radical_Stroke => "",
1029     Uppercase_Mapping => $CODE_POINT,
1030     Word_Break => 'Other',
1031 );
1032
1033 # Below are files that Unicode furnishes, but this program ignores, and why
1034 my %ignored_files = (
1035     'CJKRadicals.txt' => 'Unihan data',
1036     'Index.txt' => 'An index, not actual data',
1037     'NamedSqProv.txt' => 'Not officially part of the Unicode standard; Append it to NamedSequences.txt if you want to process the contents.',
1038     'NamesList.txt' => 'Just adds commentary',
1039     'NormalizationCorrections.txt' => 'Data is already in other files.',
1040     'Props.txt' => 'Adds nothing to PropList.txt; only in very early releases',
1041     'ReadMe.txt' => 'Just comments',
1042     'README.TXT' => 'Just comments',
1043     'StandardizedVariants.txt' => 'Only for glyph changes, not a Unicode character property.  Does not fit into current scheme where one code point is mapped',
1044     'EmojiSources.txt' => 'Not of general utility: for Japanese legacy cell-phone applications',
1045     'IndicMatraCategory.txt' => 'Provisional',
1046     'IndicSyllabicCategory.txt' => 'Provisional',
1047     'ScriptExtensions.txt' => 'Provisional',
1048 );
1049
1050 ### End of externally interesting definitions, except for @input_file_objects
1051
1052 my $HEADER=<<"EOF";
1053 # !!!!!!!   DO NOT EDIT THIS FILE   !!!!!!!
1054 # This file is machine-generated by $0 from the Unicode
1055 # database, Version $string_version.  Any changes made here will be lost!
1056 EOF
1057
1058 my $INTERNAL_ONLY=<<"EOF";
1059
1060 # !!!!!!!   INTERNAL PERL USE ONLY   !!!!!!!
1061 # This file is for internal use by the Perl program only.  The format and even
1062 # the name or existence of this file are subject to change without notice.
1063 # Don't use it directly.
1064 EOF
1065
1066 my $DEVELOPMENT_ONLY=<<"EOF";
1067 # !!!!!!!   DEVELOPMENT USE ONLY   !!!!!!!
1068 # This file contains information artificially constrained to code points
1069 # present in Unicode release $string_compare_versions.
1070 # IT CANNOT BE RELIED ON.  It is for use during development only and should
1071 # not be used for production.
1072
1073 EOF
1074
1075 my $LAST_UNICODE_CODEPOINT_STRING = "10FFFF";
1076 my $LAST_UNICODE_CODEPOINT = hex $LAST_UNICODE_CODEPOINT_STRING;
1077 my $MAX_UNICODE_CODEPOINTS = $LAST_UNICODE_CODEPOINT + 1;
1078
1079 # Matches legal code point.  4-6 hex numbers, If there are 6, the first
1080 # two must be 10; if there are 5, the first must not be a 0.  Written this way
1081 # to decrease backtracking
1082 my $code_point_re =
1083         qr/ \b (?: 10[0-9A-F]{4} | [1-9A-F][0-9A-F]{4} | [0-9A-F]{4} ) \b/x;
1084
1085 # This matches the beginning of the line in the Unicode db files that give the
1086 # defaults for code points not listed (i.e., missing) in the file.  The code
1087 # depends on this ending with a semi-colon, so it can assume it is a valid
1088 # field when the line is split() by semi-colons
1089 my $missing_defaults_prefix =
1090             qr/^#\s+\@missing:\s+0000\.\.$LAST_UNICODE_CODEPOINT_STRING\s*;/;
1091
1092 # Property types.  Unicode has more types, but these are sufficient for our
1093 # purposes.
1094 my $UNKNOWN = -1;   # initialized to illegal value
1095 my $NON_STRING = 1; # Either binary or enum
1096 my $BINARY = 2;
1097 my $ENUM = 3;       # Include catalog
1098 my $STRING = 4;     # Anything else: string or misc
1099
1100 # Some input files have lines that give default values for code points not
1101 # contained in the file.  Sometimes these should be ignored.
1102 my $NO_DEFAULTS = 0;        # Must evaluate to false
1103 my $NOT_IGNORED = 1;
1104 my $IGNORED = 2;
1105
1106 # Range types.  Each range has a type.  Most ranges are type 0, for normal,
1107 # and will appear in the main body of the tables in the output files, but
1108 # there are other types of ranges as well, listed below, that are specially
1109 # handled.   There are pseudo-types as well that will never be stored as a
1110 # type, but will affect the calculation of the type.
1111
1112 # 0 is for normal, non-specials
1113 my $MULTI_CP = 1;           # Sequence of more than code point
1114 my $HANGUL_SYLLABLE = 2;
1115 my $CP_IN_NAME = 3;         # The NAME contains the code point appended to it.
1116 my $NULL = 4;               # The map is to the null string; utf8.c can't
1117                             # handle these, nor is there an accepted syntax
1118                             # for them in \p{} constructs
1119 my $COMPUTE_NO_MULTI_CP = 5; # Pseudo-type; means that ranges that would
1120                              # otherwise be $MULTI_CP type are instead type 0
1121
1122 # process_generic_property_file() can accept certain overrides in its input.
1123 # Each of these must begin AND end with $CMD_DELIM.
1124 my $CMD_DELIM = "\a";
1125 my $REPLACE_CMD = 'replace';    # Override the Replace
1126 my $MAP_TYPE_CMD = 'map_type';  # Override the Type
1127
1128 my $NO = 0;
1129 my $YES = 1;
1130
1131 # Values for the Replace argument to add_range.
1132 # $NO                      # Don't replace; add only the code points not
1133                            # already present.
1134 my $IF_NOT_EQUIVALENT = 1; # Replace only under certain conditions; details in
1135                            # the comments at the subroutine definition.
1136 my $UNCONDITIONALLY = 2;   # Replace without conditions.
1137 my $MULTIPLE = 4;          # Don't replace, but add a duplicate record if
1138                            # already there
1139
1140 # Flags to give property statuses.  The phrases are to remind maintainers that
1141 # if the flag is changed, the indefinite article referring to it in the
1142 # documentation may need to be as well.
1143 my $NORMAL = "";
1144 my $SUPPRESSED = 'z';   # The character should never actually be seen, since
1145                         # it is suppressed
1146 my $PLACEHOLDER = 'P';  # Implies no pod entry generated
1147 my $DEPRECATED = 'D';
1148 my $a_bold_deprecated = "a 'B<$DEPRECATED>'";
1149 my $A_bold_deprecated = "A 'B<$DEPRECATED>'";
1150 my $DISCOURAGED = 'X';
1151 my $a_bold_discouraged = "an 'B<$DISCOURAGED>'";
1152 my $A_bold_discouraged = "An 'B<$DISCOURAGED>'";
1153 my $STRICTER = 'T';
1154 my $a_bold_stricter = "a 'B<$STRICTER>'";
1155 my $A_bold_stricter = "A 'B<$STRICTER>'";
1156 my $STABILIZED = 'S';
1157 my $a_bold_stabilized = "an 'B<$STABILIZED>'";
1158 my $A_bold_stabilized = "An 'B<$STABILIZED>'";
1159 my $OBSOLETE = 'O';
1160 my $a_bold_obsolete = "an 'B<$OBSOLETE>'";
1161 my $A_bold_obsolete = "An 'B<$OBSOLETE>'";
1162
1163 my %status_past_participles = (
1164     $DISCOURAGED => 'discouraged',
1165     $SUPPRESSED => 'should never be generated',
1166     $STABILIZED => 'stabilized',
1167     $OBSOLETE => 'obsolete',
1168     $DEPRECATED => 'deprecated',
1169 );
1170
1171 # The format of the values of the tables:
1172 my $EMPTY_FORMAT = "";
1173 my $BINARY_FORMAT = 'b';
1174 my $DECIMAL_FORMAT = 'd';
1175 my $FLOAT_FORMAT = 'f';
1176 my $INTEGER_FORMAT = 'i';
1177 my $HEX_FORMAT = 'x';
1178 my $RATIONAL_FORMAT = 'r';
1179 my $STRING_FORMAT = 's';
1180 my $DECOMP_STRING_FORMAT = 'c';
1181
1182 my %map_table_formats = (
1183     $BINARY_FORMAT => 'binary',
1184     $DECIMAL_FORMAT => 'single decimal digit',
1185     $FLOAT_FORMAT => 'floating point number',
1186     $INTEGER_FORMAT => 'integer',
1187     $HEX_FORMAT => 'positive hex whole number; a code point',
1188     $RATIONAL_FORMAT => 'rational: an integer or a fraction',
1189     $STRING_FORMAT => 'string',
1190     $DECOMP_STRING_FORMAT => 'Perl\'s internal (Normalize.pm) decomposition mapping',
1191 );
1192
1193 # Unicode didn't put such derived files in a separate directory at first.
1194 my $EXTRACTED_DIR = (-d 'extracted') ? 'extracted' : "";
1195 my $EXTRACTED = ($EXTRACTED_DIR) ? "$EXTRACTED_DIR/" : "";
1196 my $AUXILIARY = 'auxiliary';
1197
1198 # Hashes that will eventually go into Heavy.pl for the use of utf8_heavy.pl
1199 my %loose_to_file_of;       # loosely maps table names to their respective
1200                             # files
1201 my %stricter_to_file_of;    # same; but for stricter mapping.
1202 my %nv_floating_to_rational; # maps numeric values floating point numbers to
1203                              # their rational equivalent
1204 my %loose_property_name_of; # Loosely maps property names to standard form
1205
1206 # These constants names and values were taken from the Unicode standard,
1207 # version 5.1, section 3.12.  They are used in conjunction with Hangul
1208 # syllables.  The '_string' versions are so generated tables can retain the
1209 # hex format, which is the more familiar value
1210 my $SBase_string = "0xAC00";
1211 my $SBase = CORE::hex $SBase_string;
1212 my $LBase_string = "0x1100";
1213 my $LBase = CORE::hex $LBase_string;
1214 my $VBase_string = "0x1161";
1215 my $VBase = CORE::hex $VBase_string;
1216 my $TBase_string = "0x11A7";
1217 my $TBase = CORE::hex $TBase_string;
1218 my $SCount = 11172;
1219 my $LCount = 19;
1220 my $VCount = 21;
1221 my $TCount = 28;
1222 my $NCount = $VCount * $TCount;
1223
1224 # For Hangul syllables;  These store the numbers from Jamo.txt in conjunction
1225 # with the above published constants.
1226 my %Jamo;
1227 my %Jamo_L;     # Leading consonants
1228 my %Jamo_V;     # Vowels
1229 my %Jamo_T;     # Trailing consonants
1230
1231 my @backslash_X_tests;     # List of tests read in for testing \X
1232 my @unhandled_properties;  # Will contain a list of properties found in
1233                            # the input that we didn't process.
1234 my @match_properties;      # Properties that have match tables, to be
1235                            # listed in the pod
1236 my @map_properties;        # Properties that get map files written
1237 my @named_sequences;       # NamedSequences.txt contents.
1238 my %potential_files;       # Generated list of all .txt files in the directory
1239                            # structure so we can warn if something is being
1240                            # ignored.
1241 my @files_actually_output; # List of files we generated.
1242 my @more_Names;            # Some code point names are compound; this is used
1243                            # to store the extra components of them.
1244 my $MIN_FRACTION_LENGTH = 3; # How many digits of a floating point number at
1245                            # the minimum before we consider it equivalent to a
1246                            # candidate rational
1247 my $MAX_FLOATING_SLOP = 10 ** - $MIN_FRACTION_LENGTH; # And in floating terms
1248
1249 # These store references to certain commonly used property objects
1250 my $gc;
1251 my $perl;
1252 my $block;
1253 my $perl_charname;
1254 my $print;
1255
1256 # Are there conflicting names because of beginning with 'In_', or 'Is_'
1257 my $has_In_conflicts = 0;
1258 my $has_Is_conflicts = 0;
1259
1260 sub internal_file_to_platform ($) {
1261     # Convert our file paths which have '/' separators to those of the
1262     # platform.
1263
1264     my $file = shift;
1265     return undef unless defined $file;
1266
1267     return File::Spec->join(split '/', $file);
1268 }
1269
1270 sub file_exists ($) {   # platform independent '-e'.  This program internally
1271                         # uses slash as a path separator.
1272     my $file = shift;
1273     return 0 if ! defined $file;
1274     return -e internal_file_to_platform($file);
1275 }
1276
1277 sub objaddr($) {
1278     # Returns the address of the blessed input object.
1279     # It doesn't check for blessedness because that would do a string eval
1280     # every call, and the program is structured so that this is never called
1281     # for a non-blessed object.
1282
1283     no overloading; # If overloaded, numifying below won't work.
1284
1285     # Numifying a ref gives its address.
1286     return pack 'J', $_[0];
1287 }
1288
1289 # These are used only if $annotate is true.
1290 # The entire range of Unicode characters is examined to populate these
1291 # after all the input has been processed.  But most can be skipped, as they
1292 # have the same descriptive phrases, such as being unassigned
1293 my @viacode;            # Contains the 1 million character names
1294 my @printable;          # boolean: And are those characters printable?
1295 my @annotate_char_type; # Contains a type of those characters, specifically
1296                         # for the purposes of annotation.
1297 my $annotate_ranges;    # A map of ranges of code points that have the same
1298                         # name for the purposes of annoation.  They map to the
1299                         # upper edge of the range, so that the end point can
1300                         # be immediately found.  This is used to skip ahead to
1301                         # the end of a range, and avoid processing each
1302                         # individual code point in it.
1303 my $unassigned_sans_noncharacters; # A Range_List of the unassigned
1304                                    # characters, but excluding those which are
1305                                    # also noncharacter code points
1306
1307 # The annotation types are an extension of the regular range types, though
1308 # some of the latter are folded into one.  Make the new types negative to
1309 # avoid conflicting with the regular types
1310 my $SURROGATE_TYPE = -1;
1311 my $UNASSIGNED_TYPE = -2;
1312 my $PRIVATE_USE_TYPE = -3;
1313 my $NONCHARACTER_TYPE = -4;
1314 my $CONTROL_TYPE = -5;
1315 my $UNKNOWN_TYPE = -6;  # Used only if there is a bug in this program
1316
1317 sub populate_char_info ($) {
1318     # Used only with the $annotate option.  Populates the arrays with the
1319     # input code point's info that are needed for outputting more detailed
1320     # comments.  If calling context wants a return, it is the end point of
1321     # any contiguous range of characters that share essentially the same info
1322
1323     my $i = shift;
1324     Carp::carp_extra_args(\@_) if main::DEBUG && @_;
1325
1326     $viacode[$i] = $perl_charname->value_of($i) || "";
1327
1328     # A character is generally printable if Unicode says it is,
1329     # but below we make sure that most Unicode general category 'C' types
1330     # aren't.
1331     $printable[$i] = $print->contains($i);
1332
1333     $annotate_char_type[$i] = $perl_charname->type_of($i) || 0;
1334
1335     # Only these two regular types are treated specially for annotations
1336     # purposes
1337     $annotate_char_type[$i] = 0 if $annotate_char_type[$i] != $CP_IN_NAME
1338                                 && $annotate_char_type[$i] != $HANGUL_SYLLABLE;
1339
1340     # Give a generic name to all code points that don't have a real name.
1341     # We output ranges, if applicable, for these.  Also calculate the end
1342     # point of the range.
1343     my $end;
1344     if (! $viacode[$i]) {
1345         if ($gc-> table('Surrogate')->contains($i)) {
1346             $viacode[$i] = 'Surrogate';
1347             $annotate_char_type[$i] = $SURROGATE_TYPE;
1348             $printable[$i] = 0;
1349             $end = $gc->table('Surrogate')->containing_range($i)->end;
1350         }
1351         elsif ($gc-> table('Private_use')->contains($i)) {
1352             $viacode[$i] = 'Private Use';
1353             $annotate_char_type[$i] = $PRIVATE_USE_TYPE;
1354             $printable[$i] = 0;
1355             $end = $gc->table('Private_Use')->containing_range($i)->end;
1356         }
1357         elsif (Property::property_ref('Noncharacter_Code_Point')-> table('Y')->
1358                                                                 contains($i))
1359         {
1360             $viacode[$i] = 'Noncharacter';
1361             $annotate_char_type[$i] = $NONCHARACTER_TYPE;
1362             $printable[$i] = 0;
1363             $end = property_ref('Noncharacter_Code_Point')->table('Y')->
1364                                                     containing_range($i)->end;
1365         }
1366         elsif ($gc-> table('Control')->contains($i)) {
1367             $viacode[$i] = 'Control';
1368             $annotate_char_type[$i] = $CONTROL_TYPE;
1369             $printable[$i] = 0;
1370             $end = 0x81 if $i == 0x80;  # Hard-code this one known case
1371         }
1372         elsif ($gc-> table('Unassigned')->contains($i)) {
1373             $viacode[$i] = 'Unassigned, block=' . $block-> value_of($i);
1374             $annotate_char_type[$i] = $UNASSIGNED_TYPE;
1375             $printable[$i] = 0;
1376
1377             # Because we name the unassigned by the blocks they are in, it
1378             # can't go past the end of that block, and it also can't go past
1379             # the unassigned range it is in.  The special table makes sure
1380             # that the non-characters, which are unassigned, are separated
1381             # out.
1382             $end = min($block->containing_range($i)->end,
1383                        $unassigned_sans_noncharacters-> containing_range($i)->
1384                                                                          end);
1385         }
1386         else {
1387             Carp::my_carp_bug("Can't figure out how to annotate "
1388                               . sprintf("U+%04X", $i)
1389                               . ".  Proceeding anyway.");
1390             $viacode[$i] = 'UNKNOWN';
1391             $annotate_char_type[$i] = $UNKNOWN_TYPE;
1392             $printable[$i] = 0;
1393         }
1394     }
1395
1396     # Here, has a name, but if it's one in which the code point number is
1397     # appended to the name, do that.
1398     elsif ($annotate_char_type[$i] == $CP_IN_NAME) {
1399         $viacode[$i] .= sprintf("-%04X", $i);
1400         $end = $perl_charname->containing_range($i)->end;
1401     }
1402
1403     # And here, has a name, but if it's a hangul syllable one, replace it with
1404     # the correct name from the Unicode algorithm
1405     elsif ($annotate_char_type[$i] == $HANGUL_SYLLABLE) {
1406         use integer;
1407         my $SIndex = $i - $SBase;
1408         my $L = $LBase + $SIndex / $NCount;
1409         my $V = $VBase + ($SIndex % $NCount) / $TCount;
1410         my $T = $TBase + $SIndex % $TCount;
1411         $viacode[$i] = "HANGUL SYLLABLE $Jamo{$L}$Jamo{$V}";
1412         $viacode[$i] .= $Jamo{$T} if $T != $TBase;
1413         $end = $perl_charname->containing_range($i)->end;
1414     }
1415
1416     return if ! defined wantarray;
1417     return $i if ! defined $end;    # If not a range, return the input
1418
1419     # Save this whole range so can find the end point quickly
1420     $annotate_ranges->add_map($i, $end, $end);
1421
1422     return $end;
1423 }
1424
1425 # Commented code below should work on Perl 5.8.
1426 ## This 'require' doesn't necessarily work in miniperl, and even if it does,
1427 ## the native perl version of it (which is what would operate under miniperl)
1428 ## is extremely slow, as it does a string eval every call.
1429 #my $has_fast_scalar_util = $\18 !~ /miniperl/
1430 #                            && defined eval "require Scalar::Util";
1431 #
1432 #sub objaddr($) {
1433 #    # Returns the address of the blessed input object.  Uses the XS version if
1434 #    # available.  It doesn't check for blessedness because that would do a
1435 #    # string eval every call, and the program is structured so that this is
1436 #    # never called for a non-blessed object.
1437 #
1438 #    return Scalar::Util::refaddr($_[0]) if $has_fast_scalar_util;
1439 #
1440 #    # Check at least that is a ref.
1441 #    my $pkg = ref($_[0]) or return undef;
1442 #
1443 #    # Change to a fake package to defeat any overloaded stringify
1444 #    bless $_[0], 'main::Fake';
1445 #
1446 #    # Numifying a ref gives its address.
1447 #    my $addr = pack 'J', $_[0];
1448 #
1449 #    # Return to original class
1450 #    bless $_[0], $pkg;
1451 #    return $addr;
1452 #}
1453
1454 sub max ($$) {
1455     my $a = shift;
1456     my $b = shift;
1457     return $a if $a >= $b;
1458     return $b;
1459 }
1460
1461 sub min ($$) {
1462     my $a = shift;
1463     my $b = shift;
1464     return $a if $a <= $b;
1465     return $b;
1466 }
1467
1468 sub clarify_number ($) {
1469     # This returns the input number with underscores inserted every 3 digits
1470     # in large (5 digits or more) numbers.  Input must be entirely digits, not
1471     # checked.
1472
1473     my $number = shift;
1474     my $pos = length($number) - 3;
1475     return $number if $pos <= 1;
1476     while ($pos > 0) {
1477         substr($number, $pos, 0) = '_';
1478         $pos -= 3;
1479     }
1480     return $number;
1481 }
1482
1483
1484 package Carp;
1485
1486 # These routines give a uniform treatment of messages in this program.  They
1487 # are placed in the Carp package to cause the stack trace to not include them,
1488 # although an alternative would be to use another package and set @CARP_NOT
1489 # for it.
1490
1491 our $Verbose = 1 if main::DEBUG;  # Useful info when debugging
1492
1493 # This is a work-around suggested by Nicholas Clark to fix a problem with Carp
1494 # and overload trying to load Scalar:Util under miniperl.  See
1495 # http://www.xray.mpe.mpg.de/mailing-lists/perl5-porters/2009-11/msg01057.html
1496 undef $overload::VERSION;
1497
1498 sub my_carp {
1499     my $message = shift || "";
1500     my $nofold = shift || 0;
1501
1502     if ($message) {
1503         $message = main::join_lines($message);
1504         $message =~ s/^$0: *//;     # Remove initial program name
1505         $message =~ s/[.;,]+$//;    # Remove certain ending punctuation
1506         $message = "\n$0: $message;";
1507
1508         # Fold the message with program name, semi-colon end punctuation
1509         # (which looks good with the message that carp appends to it), and a
1510         # hanging indent for continuation lines.
1511         $message = main::simple_fold($message, "", 4) unless $nofold;
1512         $message =~ s/\n$//;        # Remove the trailing nl so what carp
1513                                     # appends is to the same line
1514     }
1515
1516     return $message if defined wantarray;   # If a caller just wants the msg
1517
1518     carp $message;
1519     return;
1520 }
1521
1522 sub my_carp_bug {
1523     # This is called when it is clear that the problem is caused by a bug in
1524     # this program.
1525
1526     my $message = shift;
1527     $message =~ s/^$0: *//;
1528     $message = my_carp("Bug in $0.  Please report it by running perlbug or if that is unavailable, by sending email to perbug\@perl.org:\n$message");
1529     carp $message;
1530     return;
1531 }
1532
1533 sub carp_too_few_args {
1534     if (@_ != 2) {
1535         my_carp_bug("Wrong number of arguments: to 'carp_too_few_arguments'.  No action taken.");
1536         return;
1537     }
1538
1539     my $args_ref = shift;
1540     my $count = shift;
1541
1542     my_carp_bug("Need at least $count arguments to "
1543         . (caller 1)[3]
1544         . ".  Instead got: '"
1545         . join ', ', @$args_ref
1546         . "'.  No action taken.");
1547     return;
1548 }
1549
1550 sub carp_extra_args {
1551     my $args_ref = shift;
1552     my_carp_bug("Too many arguments to 'carp_extra_args': (" . join(', ', @_) . ");  Extras ignored.") if @_;
1553
1554     unless (ref $args_ref) {
1555         my_carp_bug("Argument to 'carp_extra_args' ($args_ref) must be a ref.  Not checking arguments.");
1556         return;
1557     }
1558     my ($package, $file, $line) = caller;
1559     my $subroutine = (caller 1)[3];
1560
1561     my $list;
1562     if (ref $args_ref eq 'HASH') {
1563         foreach my $key (keys %$args_ref) {
1564             $args_ref->{$key} = $UNDEF unless defined $args_ref->{$key};
1565         }
1566         $list = join ', ', each %{$args_ref};
1567     }
1568     elsif (ref $args_ref eq 'ARRAY') {
1569         foreach my $arg (@$args_ref) {
1570             $arg = $UNDEF unless defined $arg;
1571         }
1572         $list = join ', ', @$args_ref;
1573     }
1574     else {
1575         my_carp_bug("Can't cope with ref "
1576                 . ref($args_ref)
1577                 . " . argument to 'carp_extra_args'.  Not checking arguments.");
1578         return;
1579     }
1580
1581     my_carp_bug("Unrecognized parameters in options: '$list' to $subroutine.  Skipped.");
1582     return;
1583 }
1584
1585 package main;
1586
1587 { # Closure
1588
1589     # This program uses the inside-out method for objects, as recommended in
1590     # "Perl Best Practices".  This closure aids in generating those.  There
1591     # are two routines.  setup_package() is called once per package to set
1592     # things up, and then set_access() is called for each hash representing a
1593     # field in the object.  These routines arrange for the object to be
1594     # properly destroyed when no longer used, and for standard accessor
1595     # functions to be generated.  If you need more complex accessors, just
1596     # write your own and leave those accesses out of the call to set_access().
1597     # More details below.
1598
1599     my %constructor_fields; # fields that are to be used in constructors; see
1600                             # below
1601
1602     # The values of this hash will be the package names as keys to other
1603     # hashes containing the name of each field in the package as keys, and
1604     # references to their respective hashes as values.
1605     my %package_fields;
1606
1607     sub setup_package {
1608         # Sets up the package, creating standard DESTROY and dump methods
1609         # (unless already defined).  The dump method is used in debugging by
1610         # simple_dumper().
1611         # The optional parameters are:
1612         #   a)  a reference to a hash, that gets populated by later
1613         #       set_access() calls with one of the accesses being
1614         #       'constructor'.  The caller can then refer to this, but it is
1615         #       not otherwise used by these two routines.
1616         #   b)  a reference to a callback routine to call during destruction
1617         #       of the object, before any fields are actually destroyed
1618
1619         my %args = @_;
1620         my $constructor_ref = delete $args{'Constructor_Fields'};
1621         my $destroy_callback = delete $args{'Destroy_Callback'};
1622         Carp::carp_extra_args(\@_) if main::DEBUG && %args;
1623
1624         my %fields;
1625         my $package = (caller)[0];
1626
1627         $package_fields{$package} = \%fields;
1628         $constructor_fields{$package} = $constructor_ref;
1629
1630         unless ($package->can('DESTROY')) {
1631             my $destroy_name = "${package}::DESTROY";
1632             no strict "refs";
1633
1634             # Use typeglob to give the anonymous subroutine the name we want
1635             *$destroy_name = sub {
1636                 my $self = shift;
1637                 my $addr = do { no overloading; pack 'J', $self; };
1638
1639                 $self->$destroy_callback if $destroy_callback;
1640                 foreach my $field (keys %{$package_fields{$package}}) {
1641                     #print STDERR __LINE__, ": Destroying ", ref $self, " ", sprintf("%04X", $addr), ": ", $field, "\n";
1642                     delete $package_fields{$package}{$field}{$addr};
1643                 }
1644                 return;
1645             }
1646         }
1647
1648         unless ($package->can('dump')) {
1649             my $dump_name = "${package}::dump";
1650             no strict "refs";
1651             *$dump_name = sub {
1652                 my $self = shift;
1653                 return dump_inside_out($self, $package_fields{$package}, @_);
1654             }
1655         }
1656         return;
1657     }
1658
1659     sub set_access {
1660         # Arrange for the input field to be garbage collected when no longer
1661         # needed.  Also, creates standard accessor functions for the field
1662         # based on the optional parameters-- none if none of these parameters:
1663         #   'addable'    creates an 'add_NAME()' accessor function.
1664         #   'readable' or 'readable_array'   creates a 'NAME()' accessor
1665         #                function.
1666         #   'settable'   creates a 'set_NAME()' accessor function.
1667         #   'constructor' doesn't create an accessor function, but adds the
1668         #                field to the hash that was previously passed to
1669         #                setup_package();
1670         # Any of the accesses can be abbreviated down, so that 'a', 'ad',
1671         # 'add' etc. all mean 'addable'.
1672         # The read accessor function will work on both array and scalar
1673         # values.  If another accessor in the parameter list is 'a', the read
1674         # access assumes an array.  You can also force it to be array access
1675         # by specifying 'readable_array' instead of 'readable'
1676         #
1677         # A sort-of 'protected' access can be set-up by preceding the addable,
1678         # readable or settable with some initial portion of 'protected_' (but,
1679         # the underscore is required), like 'p_a', 'pro_set', etc.  The
1680         # "protection" is only by convention.  All that happens is that the
1681         # accessor functions' names begin with an underscore.  So instead of
1682         # calling set_foo, the call is _set_foo.  (Real protection could be
1683         # accomplished by having a new subroutine, end_package, called at the
1684         # end of each package, and then storing the __LINE__ ranges and
1685         # checking them on every accessor.  But that is way overkill.)
1686
1687         # We create anonymous subroutines as the accessors and then use
1688         # typeglobs to assign them to the proper package and name
1689
1690         my $name = shift;   # Name of the field
1691         my $field = shift;  # Reference to the inside-out hash containing the
1692                             # field
1693
1694         my $package = (caller)[0];
1695
1696         if (! exists $package_fields{$package}) {
1697             croak "$0: Must call 'setup_package' before 'set_access'";
1698         }
1699
1700         # Stash the field so DESTROY can get it.
1701         $package_fields{$package}{$name} = $field;
1702
1703         # Remaining arguments are the accessors.  For each...
1704         foreach my $access (@_) {
1705             my $access = lc $access;
1706
1707             my $protected = "";
1708
1709             # Match the input as far as it goes.
1710             if ($access =~ /^(p[^_]*)_/) {
1711                 $protected = $1;
1712                 if (substr('protected_', 0, length $protected)
1713                     eq $protected)
1714                 {
1715
1716                     # Add 1 for the underscore not included in $protected
1717                     $access = substr($access, length($protected) + 1);
1718                     $protected = '_';
1719                 }
1720                 else {
1721                     $protected = "";
1722                 }
1723             }
1724
1725             if (substr('addable', 0, length $access) eq $access) {
1726                 my $subname = "${package}::${protected}add_$name";
1727                 no strict "refs";
1728
1729                 # add_ accessor.  Don't add if already there, which we
1730                 # determine using 'eq' for scalars and '==' otherwise.
1731                 *$subname = sub {
1732                     use strict "refs";
1733                     return Carp::carp_too_few_args(\@_, 2) if main::DEBUG && @_ < 2;
1734                     my $self = shift;
1735                     my $value = shift;
1736                     my $addr = do { no overloading; pack 'J', $self; };
1737                     Carp::carp_extra_args(\@_) if main::DEBUG && @_;
1738                     if (ref $value) {
1739                         return if grep { $value == $_ } @{$field->{$addr}};
1740                     }
1741                     else {
1742                         return if grep { $value eq $_ } @{$field->{$addr}};
1743                     }
1744                     push @{$field->{$addr}}, $value;
1745                     return;
1746                 }
1747             }
1748             elsif (substr('constructor', 0, length $access) eq $access) {
1749                 if ($protected) {
1750                     Carp::my_carp_bug("Can't set-up 'protected' constructors")
1751                 }
1752                 else {
1753                     $constructor_fields{$package}{$name} = $field;
1754                 }
1755             }
1756             elsif (substr('readable_array', 0, length $access) eq $access) {
1757
1758                 # Here has read access.  If one of the other parameters for
1759                 # access is array, or this one specifies array (by being more
1760                 # than just 'readable_'), then create a subroutine that
1761                 # assumes the data is an array.  Otherwise just a scalar
1762                 my $subname = "${package}::${protected}$name";
1763                 if (grep { /^a/i } @_
1764                     or length($access) > length('readable_'))
1765                 {
1766                     no strict "refs";
1767                     *$subname = sub {
1768                         use strict "refs";
1769                         Carp::carp_extra_args(\@_) if main::DEBUG && @_ > 1;
1770                         my $addr = do { no overloading; pack 'J', $_[0]; };
1771                         if (ref $field->{$addr} ne 'ARRAY') {
1772                             my $type = ref $field->{$addr};
1773                             $type = 'scalar' unless $type;
1774                             Carp::my_carp_bug("Trying to read $name as an array when it is a $type.  Big problems.");
1775                             return;
1776                         }
1777                         return scalar @{$field->{$addr}} unless wantarray;
1778
1779                         # Make a copy; had problems with caller modifying the
1780                         # original otherwise
1781                         my @return = @{$field->{$addr}};
1782                         return @return;
1783                     }
1784                 }
1785                 else {
1786
1787                     # Here not an array value, a simpler function.
1788                     no strict "refs";
1789                     *$subname = sub {
1790                         use strict "refs";
1791                         Carp::carp_extra_args(\@_) if main::DEBUG && @_ > 1;
1792                         no overloading;
1793                         return $field->{pack 'J', $_[0]};
1794                     }
1795                 }
1796             }
1797             elsif (substr('settable', 0, length $access) eq $access) {
1798                 my $subname = "${package}::${protected}set_$name";
1799                 no strict "refs";
1800                 *$subname = sub {
1801                     use strict "refs";
1802                     if (main::DEBUG) {
1803                         return Carp::carp_too_few_args(\@_, 2) if @_ < 2;
1804                         Carp::carp_extra_args(\@_) if @_ > 2;
1805                     }
1806                     # $self is $_[0]; $value is $_[1]
1807                     no overloading;
1808                     $field->{pack 'J', $_[0]} = $_[1];
1809                     return;
1810                 }
1811             }
1812             else {
1813                 Carp::my_carp_bug("Unknown accessor type $access.  No accessor set.");
1814             }
1815         }
1816         return;
1817     }
1818 }
1819
1820 package Input_file;
1821
1822 # All input files use this object, which stores various attributes about them,
1823 # and provides for convenient, uniform handling.  The run method wraps the
1824 # processing.  It handles all the bookkeeping of opening, reading, and closing
1825 # the file, returning only significant input lines.
1826 #
1827 # Each object gets a handler which processes the body of the file, and is
1828 # called by run().  Most should use the generic, default handler, which has
1829 # code scrubbed to handle things you might not expect.  A handler should
1830 # basically be a while(next_line()) {...} loop.
1831 #
1832 # You can also set up handlers to
1833 #   1) call before the first line is read for pre processing
1834 #   2) call to adjust each line of the input before the main handler gets them
1835 #   3) call upon EOF before the main handler exits its loop
1836 #   4) call at the end for post processing
1837 #
1838 # $_ is used to store the input line, and is to be filtered by the
1839 # each_line_handler()s.  So, if the format of the line is not in the desired
1840 # format for the main handler, these are used to do that adjusting.  They can
1841 # be stacked (by enclosing them in an [ anonymous array ] in the constructor,
1842 # so the $_ output of one is used as the input to the next.  None of the other
1843 # handlers are stackable, but could easily be changed to be so.
1844 #
1845 # Most of the handlers can call insert_lines() or insert_adjusted_lines()
1846 # which insert the parameters as lines to be processed before the next input
1847 # file line is read.  This allows the EOF handler to flush buffers, for
1848 # example.  The difference between the two routines is that the lines inserted
1849 # by insert_lines() are subjected to the each_line_handler()s.  (So if you
1850 # called it from such a handler, you would get infinite recursion.)  Lines
1851 # inserted by insert_adjusted_lines() go directly to the main handler without
1852 # any adjustments.  If the  post-processing handler calls any of these, there
1853 # will be no effect.  Some error checking for these conditions could be added,
1854 # but it hasn't been done.
1855 #
1856 # carp_bad_line() should be called to warn of bad input lines, which clears $_
1857 # to prevent further processing of the line.  This routine will output the
1858 # message as a warning once, and then keep a count of the lines that have the
1859 # same message, and output that count at the end of the file's processing.
1860 # This keeps the number of messages down to a manageable amount.
1861 #
1862 # get_missings() should be called to retrieve any @missing input lines.
1863 # Messages will be raised if this isn't done if the options aren't to ignore
1864 # missings.
1865
1866 sub trace { return main::trace(@_); }
1867
1868 { # Closure
1869     # Keep track of fields that are to be put into the constructor.
1870     my %constructor_fields;
1871
1872     main::setup_package(Constructor_Fields => \%constructor_fields);
1873
1874     my %file; # Input file name, required
1875     main::set_access('file', \%file, qw{ c r });
1876
1877     my %first_released; # Unicode version file was first released in, required
1878     main::set_access('first_released', \%first_released, qw{ c r });
1879
1880     my %handler;    # Subroutine to process the input file, defaults to
1881                     # 'process_generic_property_file'
1882     main::set_access('handler', \%handler, qw{ c });
1883
1884     my %property;
1885     # name of property this file is for.  defaults to none, meaning not
1886     # applicable, or is otherwise determinable, for example, from each line.
1887     main::set_access('property', \%property, qw{ c });
1888
1889     my %optional;
1890     # If this is true, the file is optional.  If not present, no warning is
1891     # output.  If it is present, the string given by this parameter is
1892     # evaluated, and if false the file is not processed.
1893     main::set_access('optional', \%optional, 'c', 'r');
1894
1895     my %non_skip;
1896     # This is used for debugging, to skip processing of all but a few input
1897     # files.  Add 'non_skip => 1' to the constructor for those files you want
1898     # processed when you set the $debug_skip global.
1899     main::set_access('non_skip', \%non_skip, 'c');
1900
1901     my %skip;
1902     # This is used to skip processing of this input file semi-permanently.
1903     # It is used for files that we aren't planning to process anytime soon,
1904     # but want to allow to be in the directory and not raise a message that we
1905     # are not handling.  Mostly for test files.  This is in contrast to the
1906     # non_skip element, which is supposed to be used very temporarily for
1907     # debugging.  Sets 'optional' to 1
1908     main::set_access('skip', \%skip, 'c');
1909
1910     my %each_line_handler;
1911     # list of subroutines to look at and filter each non-comment line in the
1912     # file.  defaults to none.  The subroutines are called in order, each is
1913     # to adjust $_ for the next one, and the final one adjusts it for
1914     # 'handler'
1915     main::set_access('each_line_handler', \%each_line_handler, 'c');
1916
1917     my %has_missings_defaults;
1918     # ? Are there lines in the file giving default values for code points
1919     # missing from it?.  Defaults to NO_DEFAULTS.  Otherwise NOT_IGNORED is
1920     # the norm, but IGNORED means it has such lines, but the handler doesn't
1921     # use them.  Having these three states allows us to catch changes to the
1922     # UCD that this program should track
1923     main::set_access('has_missings_defaults',
1924                                         \%has_missings_defaults, qw{ c r });
1925
1926     my %pre_handler;
1927     # Subroutine to call before doing anything else in the file.  If undef, no
1928     # such handler is called.
1929     main::set_access('pre_handler', \%pre_handler, qw{ c });
1930
1931     my %eof_handler;
1932     # Subroutine to call upon getting an EOF on the input file, but before
1933     # that is returned to the main handler.  This is to allow buffers to be
1934     # flushed.  The handler is expected to call insert_lines() or
1935     # insert_adjusted() with the buffered material
1936     main::set_access('eof_handler', \%eof_handler, qw{ c r });
1937
1938     my %post_handler;
1939     # Subroutine to call after all the lines of the file are read in and
1940     # processed.  If undef, no such handler is called.
1941     main::set_access('post_handler', \%post_handler, qw{ c });
1942
1943     my %progress_message;
1944     # Message to print to display progress in lieu of the standard one
1945     main::set_access('progress_message', \%progress_message, qw{ c });
1946
1947     my %handle;
1948     # cache open file handle, internal.  Is undef if file hasn't been
1949     # processed at all, empty if has;
1950     main::set_access('handle', \%handle);
1951
1952     my %added_lines;
1953     # cache of lines added virtually to the file, internal
1954     main::set_access('added_lines', \%added_lines);
1955
1956     my %errors;
1957     # cache of errors found, internal
1958     main::set_access('errors', \%errors);
1959
1960     my %missings;
1961     # storage of '@missing' defaults lines
1962     main::set_access('missings', \%missings);
1963
1964     sub new {
1965         my $class = shift;
1966
1967         my $self = bless \do{ my $anonymous_scalar }, $class;
1968         my $addr = do { no overloading; pack 'J', $self; };
1969
1970         # Set defaults
1971         $handler{$addr} = \&main::process_generic_property_file;
1972         $non_skip{$addr} = 0;
1973         $skip{$addr} = 0;
1974         $has_missings_defaults{$addr} = $NO_DEFAULTS;
1975         $handle{$addr} = undef;
1976         $added_lines{$addr} = [ ];
1977         $each_line_handler{$addr} = [ ];
1978         $errors{$addr} = { };
1979         $missings{$addr} = [ ];
1980
1981         # Two positional parameters.
1982         return Carp::carp_too_few_args(\@_, 2) if main::DEBUG && @_ < 2;
1983         $file{$addr} = main::internal_file_to_platform(shift);
1984         $first_released{$addr} = shift;
1985
1986         # The rest of the arguments are key => value pairs
1987         # %constructor_fields has been set up earlier to list all possible
1988         # ones.  Either set or push, depending on how the default has been set
1989         # up just above.
1990         my %args = @_;
1991         foreach my $key (keys %args) {
1992             my $argument = $args{$key};
1993
1994             # Note that the fields are the lower case of the constructor keys
1995             my $hash = $constructor_fields{lc $key};
1996             if (! defined $hash) {
1997                 Carp::my_carp_bug("Unrecognized parameters '$key => $argument' to new() for $self.  Skipped");
1998                 next;
1999             }
2000             if (ref $hash->{$addr} eq 'ARRAY') {
2001                 if (ref $argument eq 'ARRAY') {
2002                     foreach my $argument (@{$argument}) {
2003                         next if ! defined $argument;
2004                         push @{$hash->{$addr}}, $argument;
2005                     }
2006                 }
2007                 else {
2008                     push @{$hash->{$addr}}, $argument if defined $argument;
2009                 }
2010             }
2011             else {
2012                 $hash->{$addr} = $argument;
2013             }
2014             delete $args{$key};
2015         };
2016
2017         # If the file has a property for it, it means that the property is not
2018         # listed in the file's entries.  So add a handler to the list of line
2019         # handlers to insert the property name into the lines, to provide a
2020         # uniform interface to the final processing subroutine.
2021         # the final code doesn't have to worry about that.
2022         if ($property{$addr}) {
2023             push @{$each_line_handler{$addr}}, \&_insert_property_into_line;
2024         }
2025
2026         if ($non_skip{$addr} && ! $debug_skip && $verbosity) {
2027             print "Warning: " . __PACKAGE__ . " constructor for $file{$addr} has useless 'non_skip' in it\n";
2028         }
2029
2030         $optional{$addr} = 1 if $skip{$addr};
2031
2032         return $self;
2033     }
2034
2035
2036     use overload
2037         fallback => 0,
2038         qw("") => "_operator_stringify",
2039         "." => \&main::_operator_dot,
2040     ;
2041
2042     sub _operator_stringify {
2043         my $self = shift;
2044
2045         return __PACKAGE__ . " object for " . $self->file;
2046     }
2047
2048     # flag to make sure extracted files are processed early
2049     my $seen_non_extracted_non_age = 0;
2050
2051     sub run {
2052         # Process the input object $self.  This opens and closes the file and
2053         # calls all the handlers for it.  Currently,  this can only be called
2054         # once per file, as it destroy's the EOF handler
2055
2056         my $self = shift;
2057         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2058
2059         my $addr = do { no overloading; pack 'J', $self; };
2060
2061         my $file = $file{$addr};
2062
2063         # Don't process if not expecting this file (because released later
2064         # than this Unicode version), and isn't there.  This means if someone
2065         # copies it into an earlier version's directory, we will go ahead and
2066         # process it.
2067         return if $first_released{$addr} gt $v_version && ! -e $file;
2068
2069         # If in debugging mode and this file doesn't have the non-skip
2070         # flag set, and isn't one of the critical files, skip it.
2071         if ($debug_skip
2072             && $first_released{$addr} ne v0
2073             && ! $non_skip{$addr})
2074         {
2075             print "Skipping $file in debugging\n" if $verbosity;
2076             return;
2077         }
2078
2079         # File could be optional
2080         if ($optional{$addr}) {
2081             return unless -e $file;
2082             my $result = eval $optional{$addr};
2083             if (! defined $result) {
2084                 Carp::my_carp_bug("Got '$@' when tried to eval $optional{$addr}.  $file Skipped.");
2085                 return;
2086             }
2087             if (! $result) {
2088                 if ($verbosity) {
2089                     print STDERR "Skipping processing input file '$file' because '$optional{$addr}' is not true\n";
2090                 }
2091                 return;
2092             }
2093         }
2094
2095         if (! defined $file || ! -e $file) {
2096
2097             # If the file doesn't exist, see if have internal data for it
2098             # (based on first_released being 0).
2099             if ($first_released{$addr} eq v0) {
2100                 $handle{$addr} = 'pretend_is_open';
2101             }
2102             else {
2103                 if (! $optional{$addr}  # File could be optional
2104                     && $v_version ge $first_released{$addr})
2105                 {
2106                     print STDERR "Skipping processing input file '$file' because not found\n" if $v_version ge $first_released{$addr};
2107                 }
2108                 return;
2109             }
2110         }
2111         else {
2112
2113             # Here, the file exists.  Some platforms may change the case of
2114             # its name
2115             if ($seen_non_extracted_non_age) {
2116                 if ($file =~ /$EXTRACTED/i) {
2117                     Carp::my_carp_bug(join_lines(<<END
2118 $file should be processed just after the 'Prop...Alias' files, and before
2119 anything not in the $EXTRACTED_DIR directory.  Proceeding, but the results may
2120 have subtle problems
2121 END
2122                     ));
2123                 }
2124             }
2125             elsif ($EXTRACTED_DIR
2126                     && $first_released{$addr} ne v0
2127                     && $file !~ /$EXTRACTED/i
2128                     && lc($file) ne 'dage.txt')
2129             {
2130                 # We don't set this (by the 'if' above) if we have no
2131                 # extracted directory, so if running on an early version,
2132                 # this test won't work.  Not worth worrying about.
2133                 $seen_non_extracted_non_age = 1;
2134             }
2135
2136             # And mark the file as having being processed, and warn if it
2137             # isn't a file we are expecting.  As we process the files,
2138             # they are deleted from the hash, so any that remain at the
2139             # end of the program are files that we didn't process.
2140             my $fkey = File::Spec->rel2abs($file);
2141             my $expecting = delete $potential_files{$fkey};
2142             $expecting = delete $potential_files{lc($fkey)} unless defined $expecting;
2143             Carp::my_carp("Was not expecting '$file'.") if
2144                     ! $expecting
2145                     && ! defined $handle{$addr};
2146
2147             # Having deleted from expected files, we can quit if not to do
2148             # anything.  Don't print progress unless really want verbosity
2149             if ($skip{$addr}) {
2150                 print "Skipping $file.\n" if $verbosity >= $VERBOSE;
2151                 return;
2152             }
2153
2154             # Open the file, converting the slashes used in this program
2155             # into the proper form for the OS
2156             my $file_handle;
2157             if (not open $file_handle, "<", $file) {
2158                 Carp::my_carp("Can't open $file.  Skipping: $!");
2159                 return 0;
2160             }
2161             $handle{$addr} = $file_handle; # Cache the open file handle
2162         }
2163
2164         if ($verbosity >= $PROGRESS) {
2165             if ($progress_message{$addr}) {
2166                 print "$progress_message{$addr}\n";
2167             }
2168             else {
2169                 # If using a virtual file, say so.
2170                 print "Processing ", (-e $file)
2171                                        ? $file
2172                                        : "substitute $file",
2173                                      "\n";
2174             }
2175         }
2176
2177
2178         # Call any special handler for before the file.
2179         &{$pre_handler{$addr}}($self) if $pre_handler{$addr};
2180
2181         # Then the main handler
2182         &{$handler{$addr}}($self);
2183
2184         # Then any special post-file handler.
2185         &{$post_handler{$addr}}($self) if $post_handler{$addr};
2186
2187         # If any errors have been accumulated, output the counts (as the first
2188         # error message in each class was output when it was encountered).
2189         if ($errors{$addr}) {
2190             my $total = 0;
2191             my $types = 0;
2192             foreach my $error (keys %{$errors{$addr}}) {
2193                 $total += $errors{$addr}->{$error};
2194                 delete $errors{$addr}->{$error};
2195                 $types++;
2196             }
2197             if ($total > 1) {
2198                 my $message
2199                         = "A total of $total lines had errors in $file.  ";
2200
2201                 $message .= ($types == 1)
2202                             ? '(Only the first one was displayed.)'
2203                             : '(Only the first of each type was displayed.)';
2204                 Carp::my_carp($message);
2205             }
2206         }
2207
2208         if (@{$missings{$addr}}) {
2209             Carp::my_carp_bug("Handler for $file didn't look at all the \@missing lines.  Generated tables likely are wrong");
2210         }
2211
2212         # If a real file handle, close it.
2213         close $handle{$addr} or Carp::my_carp("Can't close $file: $!") if
2214                                                         ref $handle{$addr};
2215         $handle{$addr} = "";   # Uses empty to indicate that has already seen
2216                                # the file, as opposed to undef
2217         return;
2218     }
2219
2220     sub next_line {
2221         # Sets $_ to be the next logical input line, if any.  Returns non-zero
2222         # if such a line exists.  'logical' means that any lines that have
2223         # been added via insert_lines() will be returned in $_ before the file
2224         # is read again.
2225
2226         my $self = shift;
2227         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2228
2229         my $addr = do { no overloading; pack 'J', $self; };
2230
2231         # Here the file is open (or if the handle is not a ref, is an open
2232         # 'virtual' file).  Get the next line; any inserted lines get priority
2233         # over the file itself.
2234         my $adjusted;
2235
2236         LINE:
2237         while (1) { # Loop until find non-comment, non-empty line
2238             #local $to_trace = 1 if main::DEBUG;
2239             my $inserted_ref = shift @{$added_lines{$addr}};
2240             if (defined $inserted_ref) {
2241                 ($adjusted, $_) = @{$inserted_ref};
2242                 trace $adjusted, $_ if main::DEBUG && $to_trace;
2243                 return 1 if $adjusted;
2244             }
2245             else {
2246                 last if ! ref $handle{$addr}; # Don't read unless is real file
2247                 last if ! defined ($_ = readline $handle{$addr});
2248             }
2249             chomp;
2250             trace $_ if main::DEBUG && $to_trace;
2251
2252             # See if this line is the comment line that defines what property
2253             # value that code points that are not listed in the file should
2254             # have.  The format or existence of these lines is not guaranteed
2255             # by Unicode since they are comments, but the documentation says
2256             # that this was added for machine-readability, so probably won't
2257             # change.  This works starting in Unicode Version 5.0.  They look
2258             # like:
2259             #
2260             # @missing: 0000..10FFFF; Not_Reordered
2261             # @missing: 0000..10FFFF; Decomposition_Mapping; <code point>
2262             # @missing: 0000..10FFFF; ; NaN
2263             #
2264             # Save the line for a later get_missings() call.
2265             if (/$missing_defaults_prefix/) {
2266                 if ($has_missings_defaults{$addr} == $NO_DEFAULTS) {
2267                     $self->carp_bad_line("Unexpected \@missing line.  Assuming no missing entries");
2268                 }
2269                 elsif ($has_missings_defaults{$addr} == $NOT_IGNORED) {
2270                     my @defaults = split /\s* ; \s*/x, $_;
2271
2272                     # The first field is the @missing, which ends in a
2273                     # semi-colon, so can safely shift.
2274                     shift @defaults;
2275
2276                     # Some of these lines may have empty field placeholders
2277                     # which get in the way.  An example is:
2278                     # @missing: 0000..10FFFF; ; NaN
2279                     # Remove them.  Process starting from the top so the
2280                     # splice doesn't affect things still to be looked at.
2281                     for (my $i = @defaults - 1; $i >= 0; $i--) {
2282                         next if $defaults[$i] ne "";
2283                         splice @defaults, $i, 1;
2284                     }
2285
2286                     # What's left should be just the property (maybe) and the
2287                     # default.  Having only one element means it doesn't have
2288                     # the property.
2289                     my $default;
2290                     my $property;
2291                     if (@defaults >= 1) {
2292                         if (@defaults == 1) {
2293                             $default = $defaults[0];
2294                         }
2295                         else {
2296                             $property = $defaults[0];
2297                             $default = $defaults[1];
2298                         }
2299                     }
2300
2301                     if (@defaults < 1
2302                         || @defaults > 2
2303                         || ($default =~ /^</
2304                             && $default !~ /^<code *point>$/i
2305                             && $default !~ /^<none>$/i))
2306                     {
2307                         $self->carp_bad_line("Unrecognized \@missing line: $_.  Assuming no missing entries");
2308                     }
2309                     else {
2310
2311                         # If the property is missing from the line, it should
2312                         # be the one for the whole file
2313                         $property = $property{$addr} if ! defined $property;
2314
2315                         # Change <none> to the null string, which is what it
2316                         # really means.  If the default is the code point
2317                         # itself, set it to <code point>, which is what
2318                         # Unicode uses (but sometimes they've forgotten the
2319                         # space)
2320                         if ($default =~ /^<none>$/i) {
2321                             $default = "";
2322                         }
2323                         elsif ($default =~ /^<code *point>$/i) {
2324                             $default = $CODE_POINT;
2325                         }
2326
2327                         # Store them as a sub-arrays with both components.
2328                         push @{$missings{$addr}}, [ $default, $property ];
2329                     }
2330                 }
2331
2332                 # There is nothing for the caller to process on this comment
2333                 # line.
2334                 next;
2335             }
2336
2337             # Remove comments and trailing space, and skip this line if the
2338             # result is empty
2339             s/#.*//;
2340             s/\s+$//;
2341             next if /^$/;
2342
2343             # Call any handlers for this line, and skip further processing of
2344             # the line if the handler sets the line to null.
2345             foreach my $sub_ref (@{$each_line_handler{$addr}}) {
2346                 &{$sub_ref}($self);
2347                 next LINE if /^$/;
2348             }
2349
2350             # Here the line is ok.  return success.
2351             return 1;
2352         } # End of looping through lines.
2353
2354         # If there is an EOF handler, call it (only once) and if it generates
2355         # more lines to process go back in the loop to handle them.
2356         if ($eof_handler{$addr}) {
2357             &{$eof_handler{$addr}}($self);
2358             $eof_handler{$addr} = "";   # Currently only get one shot at it.
2359             goto LINE if $added_lines{$addr};
2360         }
2361
2362         # Return failure -- no more lines.
2363         return 0;
2364
2365     }
2366
2367 #   Not currently used, not fully tested.
2368 #    sub peek {
2369 #        # Non-destructive look-ahead one non-adjusted, non-comment, non-blank
2370 #        # record.  Not callable from an each_line_handler(), nor does it call
2371 #        # an each_line_handler() on the line.
2372 #
2373 #        my $self = shift;
2374 #        my $addr = do { no overloading; pack 'J', $self; };
2375 #
2376 #        foreach my $inserted_ref (@{$added_lines{$addr}}) {
2377 #            my ($adjusted, $line) = @{$inserted_ref};
2378 #            next if $adjusted;
2379 #
2380 #            # Remove comments and trailing space, and return a non-empty
2381 #            # resulting line
2382 #            $line =~ s/#.*//;
2383 #            $line =~ s/\s+$//;
2384 #            return $line if $line ne "";
2385 #        }
2386 #
2387 #        return if ! ref $handle{$addr}; # Don't read unless is real file
2388 #        while (1) { # Loop until find non-comment, non-empty line
2389 #            local $to_trace = 1 if main::DEBUG;
2390 #            trace $_ if main::DEBUG && $to_trace;
2391 #            return if ! defined (my $line = readline $handle{$addr});
2392 #            chomp $line;
2393 #            push @{$added_lines{$addr}}, [ 0, $line ];
2394 #
2395 #            $line =~ s/#.*//;
2396 #            $line =~ s/\s+$//;
2397 #            return $line if $line ne "";
2398 #        }
2399 #
2400 #        return;
2401 #    }
2402
2403
2404     sub insert_lines {
2405         # Lines can be inserted so that it looks like they were in the input
2406         # file at the place it was when this routine is called.  See also
2407         # insert_adjusted_lines().  Lines inserted via this routine go through
2408         # any each_line_handler()
2409
2410         my $self = shift;
2411
2412         # Each inserted line is an array, with the first element being 0 to
2413         # indicate that this line hasn't been adjusted, and needs to be
2414         # processed.
2415         no overloading;
2416         push @{$added_lines{pack 'J', $self}}, map { [ 0, $_ ] } @_;
2417         return;
2418     }
2419
2420     sub insert_adjusted_lines {
2421         # Lines can be inserted so that it looks like they were in the input
2422         # file at the place it was when this routine is called.  See also
2423         # insert_lines().  Lines inserted via this routine are already fully
2424         # adjusted, ready to be processed; each_line_handler()s handlers will
2425         # not be called.  This means this is not a completely general
2426         # facility, as only the last each_line_handler on the stack should
2427         # call this.  It could be made more general, by passing to each of the
2428         # line_handlers their position on the stack, which they would pass on
2429         # to this routine, and that would replace the boolean first element in
2430         # the anonymous array pushed here, so that the next_line routine could
2431         # use that to call only those handlers whose index is after it on the
2432         # stack.  But this is overkill for what is needed now.
2433
2434         my $self = shift;
2435         trace $_[0] if main::DEBUG && $to_trace;
2436
2437         # Each inserted line is an array, with the first element being 1 to
2438         # indicate that this line has been adjusted
2439         no overloading;
2440         push @{$added_lines{pack 'J', $self}}, map { [ 1, $_ ] } @_;
2441         return;
2442     }
2443
2444     sub get_missings {
2445         # Returns the stored up @missings lines' values, and clears the list.
2446         # The values are in an array, consisting of the default in the first
2447         # element, and the property in the 2nd.  However, since these lines
2448         # can be stacked up, the return is an array of all these arrays.
2449
2450         my $self = shift;
2451         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2452
2453         my $addr = do { no overloading; pack 'J', $self; };
2454
2455         # If not accepting a list return, just return the first one.
2456         return shift @{$missings{$addr}} unless wantarray;
2457
2458         my @return = @{$missings{$addr}};
2459         undef @{$missings{$addr}};
2460         return @return;
2461     }
2462
2463     sub _insert_property_into_line {
2464         # Add a property field to $_, if this file requires it.
2465
2466         my $self = shift;
2467         my $addr = do { no overloading; pack 'J', $self; };
2468         my $property = $property{$addr};
2469         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2470
2471         $_ =~ s/(;|$)/; $property$1/;
2472         return;
2473     }
2474
2475     sub carp_bad_line {
2476         # Output consistent error messages, using either a generic one, or the
2477         # one given by the optional parameter.  To avoid gazillions of the
2478         # same message in case the syntax of a  file is way off, this routine
2479         # only outputs the first instance of each message, incrementing a
2480         # count so the totals can be output at the end of the file.
2481
2482         my $self = shift;
2483         my $message = shift;
2484         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2485
2486         my $addr = do { no overloading; pack 'J', $self; };
2487
2488         $message = 'Unexpected line' unless $message;
2489
2490         # No trailing punctuation so as to fit with our addenda.
2491         $message =~ s/[.:;,]$//;
2492
2493         # If haven't seen this exact message before, output it now.  Otherwise
2494         # increment the count of how many times it has occurred
2495         unless ($errors{$addr}->{$message}) {
2496             Carp::my_carp("$message in '$_' in "
2497                             . $file{$addr}
2498                             . " at line $..  Skipping this line;");
2499             $errors{$addr}->{$message} = 1;
2500         }
2501         else {
2502             $errors{$addr}->{$message}++;
2503         }
2504
2505         # Clear the line to prevent any further (meaningful) processing of it.
2506         $_ = "";
2507
2508         return;
2509     }
2510 } # End closure
2511
2512 package Multi_Default;
2513
2514 # Certain properties in early versions of Unicode had more than one possible
2515 # default for code points missing from the files.  In these cases, one
2516 # default applies to everything left over after all the others are applied,
2517 # and for each of the others, there is a description of which class of code
2518 # points applies to it.  This object helps implement this by storing the
2519 # defaults, and for all but that final default, an eval string that generates
2520 # the class that it applies to.
2521
2522
2523 {   # Closure
2524
2525     main::setup_package();
2526
2527     my %class_defaults;
2528     # The defaults structure for the classes
2529     main::set_access('class_defaults', \%class_defaults);
2530
2531     my %other_default;
2532     # The default that applies to everything left over.
2533     main::set_access('other_default', \%other_default, 'r');
2534
2535
2536     sub new {
2537         # The constructor is called with default => eval pairs, terminated by
2538         # the left-over default. e.g.
2539         # Multi_Default->new(
2540         #        'T' => '$gc->table("Mn") + $gc->table("Cf") - 0x200C
2541         #               -  0x200D',
2542         #        'R' => 'some other expression that evaluates to code points',
2543         #        .
2544         #        .
2545         #        .
2546         #        'U'));
2547
2548         my $class = shift;
2549
2550         my $self = bless \do{my $anonymous_scalar}, $class;
2551         my $addr = do { no overloading; pack 'J', $self; };
2552
2553         while (@_ > 1) {
2554             my $default = shift;
2555             my $eval = shift;
2556             $class_defaults{$addr}->{$default} = $eval;
2557         }
2558
2559         $other_default{$addr} = shift;
2560
2561         return $self;
2562     }
2563
2564     sub get_next_defaults {
2565         # Iterates and returns the next class of defaults.
2566         my $self = shift;
2567         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2568
2569         my $addr = do { no overloading; pack 'J', $self; };
2570
2571         return each %{$class_defaults{$addr}};
2572     }
2573 }
2574
2575 package Alias;
2576
2577 # An alias is one of the names that a table goes by.  This class defines them
2578 # including some attributes.  Everything is currently setup in the
2579 # constructor.
2580
2581
2582 {   # Closure
2583
2584     main::setup_package();
2585
2586     my %name;
2587     main::set_access('name', \%name, 'r');
2588
2589     my %loose_match;
2590     # Determined by the constructor code if this name should match loosely or
2591     # not.  The constructor parameters can override this, but it isn't fully
2592     # implemented, as should have ability to override Unicode one's via
2593     # something like a set_loose_match()
2594     main::set_access('loose_match', \%loose_match, 'r');
2595
2596     my %make_pod_entry;
2597     # Some aliases should not get their own entries because they are covered
2598     # by a wild-card, and some we want to discourage use of.  Binary
2599     main::set_access('make_pod_entry', \%make_pod_entry, 'r');
2600
2601     my %status;
2602     # Aliases have a status, like deprecated, or even suppressed (which means
2603     # they don't appear in documentation).  Enum
2604     main::set_access('status', \%status, 'r');
2605
2606     my %externally_ok;
2607     # Similarly, some aliases should not be considered as usable ones for
2608     # external use, such as file names, or we don't want documentation to
2609     # recommend them.  Boolean
2610     main::set_access('externally_ok', \%externally_ok, 'r');
2611
2612     sub new {
2613         my $class = shift;
2614
2615         my $self = bless \do { my $anonymous_scalar }, $class;
2616         my $addr = do { no overloading; pack 'J', $self; };
2617
2618         $name{$addr} = shift;
2619         $loose_match{$addr} = shift;
2620         $make_pod_entry{$addr} = shift;
2621         $externally_ok{$addr} = shift;
2622         $status{$addr} = shift;
2623
2624         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2625
2626         # Null names are never ok externally
2627         $externally_ok{$addr} = 0 if $name{$addr} eq "";
2628
2629         return $self;
2630     }
2631 }
2632
2633 package Range;
2634
2635 # A range is the basic unit for storing code points, and is described in the
2636 # comments at the beginning of the program.  Each range has a starting code
2637 # point; an ending code point (not less than the starting one); a value
2638 # that applies to every code point in between the two end-points, inclusive;
2639 # and an enum type that applies to the value.  The type is for the user's
2640 # convenience, and has no meaning here, except that a non-zero type is
2641 # considered to not obey the normal Unicode rules for having standard forms.
2642 #
2643 # The same structure is used for both map and match tables, even though in the
2644 # latter, the value (and hence type) is irrelevant and could be used as a
2645 # comment.  In map tables, the value is what all the code points in the range
2646 # map to.  Type 0 values have the standardized version of the value stored as
2647 # well, so as to not have to recalculate it a lot.
2648
2649 sub trace { return main::trace(@_); }
2650
2651 {   # Closure
2652
2653     main::setup_package();
2654
2655     my %start;
2656     main::set_access('start', \%start, 'r', 's');
2657
2658     my %end;
2659     main::set_access('end', \%end, 'r', 's');
2660
2661     my %value;
2662     main::set_access('value', \%value, 'r');
2663
2664     my %type;
2665     main::set_access('type', \%type, 'r');
2666
2667     my %standard_form;
2668     # The value in internal standard form.  Defined only if the type is 0.
2669     main::set_access('standard_form', \%standard_form);
2670
2671     # Note that if these fields change, the dump() method should as well
2672
2673     sub new {
2674         return Carp::carp_too_few_args(\@_, 3) if main::DEBUG && @_ < 3;
2675         my $class = shift;
2676
2677         my $self = bless \do { my $anonymous_scalar }, $class;
2678         my $addr = do { no overloading; pack 'J', $self; };
2679
2680         $start{$addr} = shift;
2681         $end{$addr} = shift;
2682
2683         my %args = @_;
2684
2685         my $value = delete $args{'Value'};  # Can be 0
2686         $value = "" unless defined $value;
2687         $value{$addr} = $value;
2688
2689         $type{$addr} = delete $args{'Type'} || 0;
2690
2691         Carp::carp_extra_args(\%args) if main::DEBUG && %args;
2692
2693         if (! $type{$addr}) {
2694             $standard_form{$addr} = main::standardize($value);
2695         }
2696
2697         return $self;
2698     }
2699
2700     use overload
2701         fallback => 0,
2702         qw("") => "_operator_stringify",
2703         "." => \&main::_operator_dot,
2704     ;
2705
2706     sub _operator_stringify {
2707         my $self = shift;
2708         my $addr = do { no overloading; pack 'J', $self; };
2709
2710         # Output it like '0041..0065 (value)'
2711         my $return = sprintf("%04X", $start{$addr})
2712                         .  '..'
2713                         . sprintf("%04X", $end{$addr});
2714         my $value = $value{$addr};
2715         my $type = $type{$addr};
2716         $return .= ' (';
2717         $return .= "$value";
2718         $return .= ", Type=$type" if $type != 0;
2719         $return .= ')';
2720
2721         return $return;
2722     }
2723
2724     sub standard_form {
2725         # The standard form is the value itself if the standard form is
2726         # undefined (that is if the value is special)
2727
2728         my $self = shift;
2729         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2730
2731         my $addr = do { no overloading; pack 'J', $self; };
2732
2733         return $standard_form{$addr} if defined $standard_form{$addr};
2734         return $value{$addr};
2735     }
2736
2737     sub dump {
2738         # Human, not machine readable.  For machine readable, comment out this
2739         # entire routine and let the standard one take effect.
2740         my $self = shift;
2741         my $indent = shift;
2742         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2743
2744         my $addr = do { no overloading; pack 'J', $self; };
2745
2746         my $return = $indent
2747                     . sprintf("%04X", $start{$addr})
2748                     . '..'
2749                     . sprintf("%04X", $end{$addr})
2750                     . " '$value{$addr}';";
2751         if (! defined $standard_form{$addr}) {
2752             $return .= "(type=$type{$addr})";
2753         }
2754         elsif ($standard_form{$addr} ne $value{$addr}) {
2755             $return .= "(standard '$standard_form{$addr}')";
2756         }
2757         return $return;
2758     }
2759 } # End closure
2760
2761 package _Range_List_Base;
2762
2763 # Base class for range lists.  A range list is simply an ordered list of
2764 # ranges, so that the ranges with the lowest starting numbers are first in it.
2765 #
2766 # When a new range is added that is adjacent to an existing range that has the
2767 # same value and type, it merges with it to form a larger range.
2768 #
2769 # Ranges generally do not overlap, except that there can be multiple entries
2770 # of single code point ranges.  This is because of NameAliases.txt.
2771 #
2772 # In this program, there is a standard value such that if two different
2773 # values, have the same standard value, they are considered equivalent.  This
2774 # value was chosen so that it gives correct results on Unicode data
2775
2776 # There are a number of methods to manipulate range lists, and some operators
2777 # are overloaded to handle them.
2778
2779 sub trace { return main::trace(@_); }
2780
2781 { # Closure
2782
2783     our $addr;
2784
2785     main::setup_package();
2786
2787     my %ranges;
2788     # The list of ranges
2789     main::set_access('ranges', \%ranges, 'readable_array');
2790
2791     my %max;
2792     # The highest code point in the list.  This was originally a method, but
2793     # actual measurements said it was used a lot.
2794     main::set_access('max', \%max, 'r');
2795
2796     my %each_range_iterator;
2797     # Iterator position for each_range()
2798     main::set_access('each_range_iterator', \%each_range_iterator);
2799
2800     my %owner_name_of;
2801     # Name of parent this is attached to, if any.  Solely for better error
2802     # messages.
2803     main::set_access('owner_name_of', \%owner_name_of, 'p_r');
2804
2805     my %_search_ranges_cache;
2806     # A cache of the previous result from _search_ranges(), for better
2807     # performance
2808     main::set_access('_search_ranges_cache', \%_search_ranges_cache);
2809
2810     sub new {
2811         my $class = shift;
2812         my %args = @_;
2813
2814         # Optional initialization data for the range list.
2815         my $initialize = delete $args{'Initialize'};
2816
2817         my $self;
2818
2819         # Use _union() to initialize.  _union() returns an object of this
2820         # class, which means that it will call this constructor recursively.
2821         # But it won't have this $initialize parameter so that it won't
2822         # infinitely loop on this.
2823         return _union($class, $initialize, %args) if defined $initialize;
2824
2825         $self = bless \do { my $anonymous_scalar }, $class;
2826         my $addr = do { no overloading; pack 'J', $self; };
2827
2828         # Optional parent object, only for debug info.
2829         $owner_name_of{$addr} = delete $args{'Owner'};
2830         $owner_name_of{$addr} = "" if ! defined $owner_name_of{$addr};
2831
2832         # Stringify, in case it is an object.
2833         $owner_name_of{$addr} = "$owner_name_of{$addr}";
2834
2835         # This is used only for error messages, and so a colon is added
2836         $owner_name_of{$addr} .= ": " if $owner_name_of{$addr} ne "";
2837
2838         Carp::carp_extra_args(\%args) if main::DEBUG && %args;
2839
2840         # Max is initialized to a negative value that isn't adjacent to 0,
2841         # for simpler tests
2842         $max{$addr} = -2;
2843
2844         $_search_ranges_cache{$addr} = 0;
2845         $ranges{$addr} = [];
2846
2847         return $self;
2848     }
2849
2850     use overload
2851         fallback => 0,
2852         qw("") => "_operator_stringify",
2853         "." => \&main::_operator_dot,
2854     ;
2855
2856     sub _operator_stringify {
2857         my $self = shift;
2858         my $addr = do { no overloading; pack 'J', $self; };
2859
2860         return "Range_List attached to '$owner_name_of{$addr}'"
2861                                                 if $owner_name_of{$addr};
2862         return "anonymous Range_List " . \$self;
2863     }
2864
2865     sub _union {
2866         # Returns the union of the input code points.  It can be called as
2867         # either a constructor or a method.  If called as a method, the result
2868         # will be a new() instance of the calling object, containing the union
2869         # of that object with the other parameter's code points;  if called as
2870         # a constructor, the first parameter gives the class the new object
2871         # should be, and the second parameter gives the code points to go into
2872         # it.
2873         # In either case, there are two parameters looked at by this routine;
2874         # any additional parameters are passed to the new() constructor.
2875         #
2876         # The code points can come in the form of some object that contains
2877         # ranges, and has a conventionally named method to access them; or
2878         # they can be an array of individual code points (as integers); or
2879         # just a single code point.
2880         #
2881         # If they are ranges, this routine doesn't make any effort to preserve
2882         # the range values of one input over the other.  Therefore this base
2883         # class should not allow _union to be called from other than
2884         # initialization code, so as to prevent two tables from being added
2885         # together where the range values matter.  The general form of this
2886         # routine therefore belongs in a derived class, but it was moved here
2887         # to avoid duplication of code.  The failure to overload this in this
2888         # class keeps it safe.
2889         #
2890
2891         my $self;
2892         my @args;   # Arguments to pass to the constructor
2893
2894         my $class = shift;
2895
2896         # If a method call, will start the union with the object itself, and
2897         # the class of the new object will be the same as self.
2898         if (ref $class) {
2899             $self = $class;
2900             $class = ref $self;
2901             push @args, $self;
2902         }
2903
2904         # Add the other required parameter.
2905         push @args, shift;
2906         # Rest of parameters are passed on to the constructor
2907
2908         # Accumulate all records from both lists.
2909         my @records;
2910         for my $arg (@args) {
2911             #local $to_trace = 0 if main::DEBUG;
2912             trace "argument = $arg" if main::DEBUG && $to_trace;
2913             if (! defined $arg) {
2914                 my $message = "";
2915                 if (defined $self) {
2916                     no overloading;
2917                     $message .= $owner_name_of{pack 'J', $self};
2918                 }
2919                 Carp::my_carp_bug($message .= "Undefined argument to _union.  No union done.");
2920                 return;
2921             }
2922             $arg = [ $arg ] if ! ref $arg;
2923             my $type = ref $arg;
2924             if ($type eq 'ARRAY') {
2925                 foreach my $element (@$arg) {
2926                     push @records, Range->new($element, $element);
2927                 }
2928             }
2929             elsif ($arg->isa('Range')) {
2930                 push @records, $arg;
2931             }
2932             elsif ($arg->can('ranges')) {
2933                 push @records, $arg->ranges;
2934             }
2935             else {
2936                 my $message = "";
2937                 if (defined $self) {
2938                     no overloading;
2939                     $message .= $owner_name_of{pack 'J', $self};
2940                 }
2941                 Carp::my_carp_bug($message . "Cannot take the union of a $type.  No union done.");
2942                 return;
2943             }
2944         }
2945
2946         # Sort with the range containing the lowest ordinal first, but if
2947         # two ranges start at the same code point, sort with the bigger range
2948         # of the two first, because it takes fewer cycles.
2949         @records = sort { ($a->start <=> $b->start)
2950                                       or
2951                                     # if b is shorter than a, b->end will be
2952                                     # less than a->end, and we want to select
2953                                     # a, so want to return -1
2954                                     ($b->end <=> $a->end)
2955                                    } @records;
2956
2957         my $new = $class->new(@_);
2958
2959         # Fold in records so long as they add new information.
2960         for my $set (@records) {
2961             my $start = $set->start;
2962             my $end   = $set->end;
2963             my $value   = $set->value;
2964             if ($start > $new->max) {
2965                 $new->_add_delete('+', $start, $end, $value);
2966             }
2967             elsif ($end > $new->max) {
2968                 $new->_add_delete('+', $new->max +1, $end, $value);
2969             }
2970         }
2971
2972         return $new;
2973     }
2974
2975     sub range_count {        # Return the number of ranges in the range list
2976         my $self = shift;
2977         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2978
2979         no overloading;
2980         return scalar @{$ranges{pack 'J', $self}};
2981     }
2982
2983     sub min {
2984         # Returns the minimum code point currently in the range list, or if
2985         # the range list is empty, 2 beyond the max possible.  This is a
2986         # method because used so rarely, that not worth saving between calls,
2987         # and having to worry about changing it as ranges are added and
2988         # deleted.
2989
2990         my $self = shift;
2991         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2992
2993         my $addr = do { no overloading; pack 'J', $self; };
2994
2995         # If the range list is empty, return a large value that isn't adjacent
2996         # to any that could be in the range list, for simpler tests
2997         return $LAST_UNICODE_CODEPOINT + 2 unless scalar @{$ranges{$addr}};
2998         return $ranges{$addr}->[0]->start;
2999     }
3000
3001     sub contains {
3002         # Boolean: Is argument in the range list?  If so returns $i such that:
3003         #   range[$i]->end < $codepoint <= range[$i+1]->end
3004         # which is one beyond what you want; this is so that the 0th range
3005         # doesn't return false
3006         my $self = shift;
3007         my $codepoint = shift;
3008         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3009
3010         my $i = $self->_search_ranges($codepoint);
3011         return 0 unless defined $i;
3012
3013         # The search returns $i, such that
3014         #   range[$i-1]->end < $codepoint <= range[$i]->end
3015         # So is in the table if and only iff it is at least the start position
3016         # of range $i.
3017         no overloading;
3018         return 0 if $ranges{pack 'J', $self}->[$i]->start > $codepoint;
3019         return $i + 1;
3020     }
3021
3022     sub containing_range {
3023         # Returns the range object that contains the code point, undef if none
3024
3025         my $self = shift;
3026         my $codepoint = shift;
3027         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3028
3029         my $i = $self->contains($codepoint);
3030         return unless $i;
3031
3032         # contains() returns 1 beyond where we should look
3033         no overloading;
3034         return $ranges{pack 'J', $self}->[$i-1];
3035     }
3036
3037     sub value_of {
3038         # Returns the value associated with the code point, undef if none
3039
3040         my $self = shift;
3041         my $codepoint = shift;
3042         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3043
3044         my $range = $self->containing_range($codepoint);
3045         return unless defined $range;
3046
3047         return $range->value;
3048     }
3049
3050     sub type_of {
3051         # Returns the type of the range containing the code point, undef if
3052         # the code point is not in the table
3053
3054         my $self = shift;
3055         my $codepoint = shift;
3056         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3057
3058         my $range = $self->containing_range($codepoint);
3059         return unless defined $range;
3060
3061         return $range->type;
3062     }
3063
3064     sub _search_ranges {
3065         # Find the range in the list which contains a code point, or where it
3066         # should go if were to add it.  That is, it returns $i, such that:
3067         #   range[$i-1]->end < $codepoint <= range[$i]->end
3068         # Returns undef if no such $i is possible (e.g. at end of table), or
3069         # if there is an error.
3070
3071         my $self = shift;
3072         my $code_point = shift;
3073         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3074
3075         my $addr = do { no overloading; pack 'J', $self; };
3076
3077         return if $code_point > $max{$addr};
3078         my $r = $ranges{$addr};                # The current list of ranges
3079         my $range_list_size = scalar @$r;
3080         my $i;
3081
3082         use integer;        # want integer division
3083
3084         # Use the cached result as the starting guess for this one, because,
3085         # an experiment on 5.1 showed that 90% of the time the cache was the
3086         # same as the result on the next call (and 7% it was one less).
3087         $i = $_search_ranges_cache{$addr};
3088         $i = 0 if $i >= $range_list_size;   # Reset if no longer valid (prob.
3089                                             # from an intervening deletion
3090         #local $to_trace = 1 if main::DEBUG;
3091         trace "previous \$i is still valid: $i" if main::DEBUG && $to_trace && $code_point <= $r->[$i]->end && ($i == 0 || $r->[$i-1]->end < $code_point);
3092         return $i if $code_point <= $r->[$i]->end
3093                      && ($i == 0 || $r->[$i-1]->end < $code_point);
3094
3095         # Here the cache doesn't yield the correct $i.  Try adding 1.
3096         if ($i < $range_list_size - 1
3097             && $r->[$i]->end < $code_point &&
3098             $code_point <= $r->[$i+1]->end)
3099         {
3100             $i++;
3101             trace "next \$i is correct: $i" if main::DEBUG && $to_trace;
3102             $_search_ranges_cache{$addr} = $i;
3103             return $i;
3104         }
3105
3106         # Here, adding 1 also didn't work.  We do a binary search to
3107         # find the correct position, starting with current $i
3108         my $lower = 0;
3109         my $upper = $range_list_size - 1;
3110         while (1) {
3111             trace "top of loop i=$i:", sprintf("%04X", $r->[$lower]->start), "[$lower] .. ", sprintf("%04X", $r->[$i]->start), "[$i] .. ", sprintf("%04X", $r->[$upper]->start), "[$upper]" if main::DEBUG && $to_trace;
3112
3113             if ($code_point <= $r->[$i]->end) {
3114
3115                 # Here we have met the upper constraint.  We can quit if we
3116                 # also meet the lower one.
3117                 last if $i == 0 || $r->[$i-1]->end < $code_point;
3118
3119                 $upper = $i;        # Still too high.
3120
3121             }
3122             else {
3123
3124                 # Here, $r[$i]->end < $code_point, so look higher up.
3125                 $lower = $i;
3126             }
3127
3128             # Split search domain in half to try again.
3129             my $temp = ($upper + $lower) / 2;
3130
3131             # No point in continuing unless $i changes for next time
3132             # in the loop.
3133             if ($temp == $i) {
3134
3135                 # We can't reach the highest element because of the averaging.
3136                 # So if one below the upper edge, force it there and try one
3137                 # more time.
3138                 if ($i == $range_list_size - 2) {
3139
3140                     trace "Forcing to upper edge" if main::DEBUG && $to_trace;
3141                     $i = $range_list_size - 1;
3142
3143                     # Change $lower as well so if fails next time through,
3144                     # taking the average will yield the same $i, and we will
3145                     # quit with the error message just below.
3146                     $lower = $i;
3147                     next;
3148                 }
3149                 Carp::my_carp_bug("$owner_name_of{$addr}Can't find where the range ought to go.  No action taken.");
3150                 return;
3151             }
3152             $i = $temp;
3153         } # End of while loop
3154
3155         if (main::DEBUG && $to_trace) {
3156             trace 'i-1=[', $i-1, ']', $r->[$i-1] if $i;
3157             trace "i=  [ $i ]", $r->[$i];
3158             trace 'i+1=[', $i+1, ']', $r->[$i+1] if $i < $range_list_size - 1;
3159         }
3160
3161         # Here we have found the offset.  Cache it as a starting point for the
3162         # next call.
3163         $_search_ranges_cache{$addr} = $i;
3164         return $i;
3165     }
3166
3167     sub _add_delete {
3168         # Add, replace or delete ranges to or from a list.  The $type
3169         # parameter gives which:
3170         #   '+' => insert or replace a range, returning a list of any changed
3171         #          ranges.
3172         #   '-' => delete a range, returning a list of any deleted ranges.
3173         #
3174         # The next three parameters give respectively the start, end, and
3175         # value associated with the range.  'value' should be null unless the
3176         # operation is '+';
3177         #
3178         # The range list is kept sorted so that the range with the lowest
3179         # starting position is first in the list, and generally, adjacent
3180         # ranges with the same values are merged into a single larger one (see
3181         # exceptions below).
3182         #
3183         # There are more parameters; all are key => value pairs:
3184         #   Type    gives the type of the value.  It is only valid for '+'.
3185         #           All ranges have types; if this parameter is omitted, 0 is
3186         #           assumed.  Ranges with type 0 are assumed to obey the
3187         #           Unicode rules for casing, etc; ranges with other types are
3188         #           not.  Otherwise, the type is arbitrary, for the caller's
3189         #           convenience, and looked at only by this routine to keep
3190         #           adjacent ranges of different types from being merged into
3191         #           a single larger range, and when Replace =>
3192         #           $IF_NOT_EQUIVALENT is specified (see just below).
3193         #   Replace  determines what to do if the range list already contains
3194         #            ranges which coincide with all or portions of the input
3195         #            range.  It is only valid for '+':
3196         #       => $NO            means that the new value is not to replace
3197         #                         any existing ones, but any empty gaps of the
3198         #                         range list coinciding with the input range
3199         #                         will be filled in with the new value.
3200         #       => $UNCONDITIONALLY  means to replace the existing values with
3201         #                         this one unconditionally.  However, if the
3202         #                         new and old values are identical, the
3203         #                         replacement is skipped to save cycles
3204         #       => $IF_NOT_EQUIVALENT means to replace the existing values
3205         #                         with this one if they are not equivalent.
3206         #                         Ranges are equivalent if their types are the
3207         #                         same, and they are the same string; or if
3208         #                         both are type 0 ranges, if their Unicode
3209         #                         standard forms are identical.  In this last
3210         #                         case, the routine chooses the more "modern"
3211         #                         one to use.  This is because some of the
3212         #                         older files are formatted with values that
3213         #                         are, for example, ALL CAPs, whereas the
3214         #                         derived files have a more modern style,
3215         #                         which looks better.  By looking for this
3216         #                         style when the pre-existing and replacement
3217         #                         standard forms are the same, we can move to
3218         #                         the modern style
3219         #       => $MULTIPLE      means that if this range duplicates an
3220         #                         existing one, but has a different value,
3221         #                         don't replace the existing one, but insert
3222         #                         this, one so that the same range can occur
3223         #                         multiple times.  They are stored LIFO, so
3224         #                         that the final one inserted is the first one
3225         #                         returned in an ordered search of the table.
3226         #       => anything else  is the same as => $IF_NOT_EQUIVALENT
3227         #
3228         # "same value" means identical for non-type-0 ranges, and it means
3229         # having the same standard forms for type-0 ranges.
3230
3231         return Carp::carp_too_few_args(\@_, 5) if main::DEBUG && @_ < 5;
3232
3233         my $self = shift;
3234         my $operation = shift;   # '+' for add/replace; '-' for delete;
3235         my $start = shift;
3236         my $end   = shift;
3237         my $value = shift;
3238
3239         my %args = @_;
3240
3241         $value = "" if not defined $value;        # warning: $value can be "0"
3242
3243         my $replace = delete $args{'Replace'};
3244         $replace = $IF_NOT_EQUIVALENT unless defined $replace;
3245
3246         my $type = delete $args{'Type'};
3247         $type = 0 unless defined $type;
3248
3249         Carp::carp_extra_args(\%args) if main::DEBUG && %args;
3250
3251         my $addr = do { no overloading; pack 'J', $self; };
3252
3253         if ($operation ne '+' && $operation ne '-') {
3254             Carp::my_carp_bug("$owner_name_of{$addr}First parameter to _add_delete must be '+' or '-'.  No action taken.");
3255             return;
3256         }
3257         unless (defined $start && defined $end) {
3258             Carp::my_carp_bug("$owner_name_of{$addr}Undefined start and/or end to _add_delete.  No action taken.");
3259             return;
3260         }
3261         unless ($end >= $start) {
3262             Carp::my_carp_bug("$owner_name_of{$addr}End of range (" . sprintf("%04X", $end) . ") must not be before start (" . sprintf("%04X", $start) . ").  No action taken.");
3263             return;
3264         }
3265         #local $to_trace = 1 if main::DEBUG;
3266
3267         if ($operation eq '-') {
3268             if ($replace != $IF_NOT_EQUIVALENT) {
3269                 Carp::my_carp_bug("$owner_name_of{$addr}Replace => \$IF_NOT_EQUIVALENT is required when deleting a range from a range list.  Assuming Replace => \$IF_NOT_EQUIVALENT.");
3270                 $replace = $IF_NOT_EQUIVALENT;
3271             }
3272             if ($type) {
3273                 Carp::my_carp_bug("$owner_name_of{$addr}Type => 0 is required when deleting a range from a range list.  Assuming Type => 0.");
3274                 $type = 0;
3275             }
3276             if ($value ne "") {
3277                 Carp::my_carp_bug("$owner_name_of{$addr}Value => \"\" is required when deleting a range from a range list.  Assuming Value => \"\".");
3278                 $value = "";
3279             }
3280         }
3281
3282         my $r = $ranges{$addr};               # The current list of ranges
3283         my $range_list_size = scalar @$r;     # And its size
3284         my $max = $max{$addr};                # The current high code point in
3285                                               # the list of ranges
3286
3287         # Do a special case requiring fewer machine cycles when the new range
3288         # starts after the current highest point.  The Unicode input data is
3289         # structured so this is common.
3290         if ($start > $max) {
3291
3292             trace "$owner_name_of{$addr} $operation", sprintf("%04X", $start) . '..' . sprintf("%04X", $end) . " ($value) type=$type" if main::DEBUG && $to_trace;
3293             return if $operation eq '-'; # Deleting a non-existing range is a
3294                                          # no-op
3295
3296             # If the new range doesn't logically extend the current final one
3297             # in the range list, create a new range at the end of the range
3298             # list.  (max cleverly is initialized to a negative number not
3299             # adjacent to 0 if the range list is empty, so even adding a range
3300             # to an empty range list starting at 0 will have this 'if'
3301             # succeed.)
3302             if ($start > $max + 1        # non-adjacent means can't extend.
3303                 || @{$r}[-1]->value ne $value # values differ, can't extend.
3304                 || @{$r}[-1]->type != $type # types differ, can't extend.
3305             ) {
3306                 push @$r, Range->new($start, $end,
3307                                      Value => $value,
3308                                      Type => $type);
3309             }
3310             else {
3311
3312                 # Here, the new range starts just after the current highest in
3313                 # the range list, and they have the same type and value.
3314                 # Extend the current range to incorporate the new one.
3315                 @{$r}[-1]->set_end($end);
3316             }
3317
3318             # This becomes the new maximum.
3319             $max{$addr} = $end;
3320
3321             return;
3322         }
3323         #local $to_trace = 0 if main::DEBUG;
3324
3325         trace "$owner_name_of{$addr} $operation", sprintf("%04X", $start) . '..' . sprintf("%04X", $end) . " ($value) replace=$replace" if main::DEBUG && $to_trace;
3326
3327         # Here, the input range isn't after the whole rest of the range list.
3328         # Most likely 'splice' will be needed.  The rest of the routine finds
3329         # the needed splice parameters, and if necessary, does the splice.
3330         # First, find the offset parameter needed by the splice function for
3331         # the input range.  Note that the input range may span multiple
3332         # existing ones, but we'll worry about that later.  For now, just find
3333         # the beginning.  If the input range is to be inserted starting in a
3334         # position not currently in the range list, it must (obviously) come
3335         # just after the range below it, and just before the range above it.
3336         # Slightly less obviously, it will occupy the position currently
3337         # occupied by the range that is to come after it.  More formally, we
3338         # are looking for the position, $i, in the array of ranges, such that:
3339         #
3340         # r[$i-1]->start <= r[$i-1]->end < $start < r[$i]->start <= r[$i]->end
3341         #
3342         # (The ordered relationships within existing ranges are also shown in
3343         # the equation above).  However, if the start of the input range is
3344         # within an existing range, the splice offset should point to that
3345         # existing range's position in the list; that is $i satisfies a
3346         # somewhat different equation, namely:
3347         #
3348         #r[$i-1]->start <= r[$i-1]->end < r[$i]->start <= $start <= r[$i]->end
3349         #
3350         # More briefly, $start can come before or after r[$i]->start, and at
3351         # this point, we don't know which it will be.  However, these
3352         # two equations share these constraints:
3353         #
3354         #   r[$i-1]->end < $start <= r[$i]->end
3355         #
3356         # And that is good enough to find $i.
3357
3358         my $i = $self->_search_ranges($start);
3359         if (! defined $i) {
3360             Carp::my_carp_bug("Searching $self for range beginning with $start unexpectedly returned undefined.  Operation '$operation' not performed");
3361             return;
3362         }
3363
3364         # The search function returns $i such that:
3365         #
3366         # r[$i-1]->end < $start <= r[$i]->end
3367         #
3368         # That means that $i points to the first range in the range list
3369         # that could possibly be affected by this operation.  We still don't
3370         # know if the start of the input range is within r[$i], or if it
3371         # points to empty space between r[$i-1] and r[$i].
3372         trace "[$i] is the beginning splice point.  Existing range there is ", $r->[$i] if main::DEBUG && $to_trace;
3373
3374         # Special case the insertion of data that is not to replace any
3375         # existing data.
3376         if ($replace == $NO) {  # If $NO, has to be operation '+'
3377             #local $to_trace = 1 if main::DEBUG;
3378             trace "Doesn't replace" if main::DEBUG && $to_trace;
3379
3380             # Here, the new range is to take effect only on those code points
3381             # that aren't already in an existing range.  This can be done by
3382             # looking through the existing range list and finding the gaps in
3383             # the ranges that this new range affects, and then calling this
3384             # function recursively on each of those gaps, leaving untouched
3385             # anything already in the list.  Gather up a list of the changed
3386             # gaps first so that changes to the internal state as new ranges
3387             # are added won't be a problem.
3388             my @gap_list;
3389
3390             # First, if the starting point of the input range is outside an
3391             # existing one, there is a gap from there to the beginning of the
3392             # existing range -- add a span to fill the part that this new
3393             # range occupies
3394             if ($start < $r->[$i]->start) {
3395                 push @gap_list, Range->new($start,
3396                                            main::min($end,
3397                                                      $r->[$i]->start - 1),
3398                                            Type => $type);
3399                 trace "gap before $r->[$i] [$i], will add", $gap_list[-1] if main::DEBUG && $to_trace;
3400             }
3401
3402             # Then look through the range list for other gaps until we reach
3403             # the highest range affected by the input one.
3404             my $j;
3405             for ($j = $i+1; $j < $range_list_size; $j++) {
3406                 trace "j=[$j]", $r->[$j] if main::DEBUG && $to_trace;
3407                 last if $end < $r->[$j]->start;
3408
3409                 # If there is a gap between when this range starts and the
3410                 # previous one ends, add a span to fill it.  Note that just
3411                 # because there are two ranges doesn't mean there is a
3412                 # non-zero gap between them.  It could be that they have
3413                 # different values or types
3414                 if ($r->[$j-1]->end + 1 != $r->[$j]->start) {
3415                     push @gap_list,
3416                         Range->new($r->[$j-1]->end + 1,
3417                                    $r->[$j]->start - 1,
3418                                    Type => $type);
3419                     trace "gap between $r->[$j-1] and $r->[$j] [$j], will add: $gap_list[-1]" if main::DEBUG && $to_trace;
3420                 }
3421             }
3422
3423             # Here, we have either found an existing range in the range list,
3424             # beyond the area affected by the input one, or we fell off the
3425             # end of the loop because the input range affects the whole rest
3426             # of the range list.  In either case, $j is 1 higher than the
3427             # highest affected range.  If $j == $i, it means that there are no
3428             # affected ranges, that the entire insertion is in the gap between
3429             # r[$i-1], and r[$i], which we already have taken care of before
3430             # the loop.
3431             # On the other hand, if there are affected ranges, it might be
3432             # that there is a gap that needs filling after the final such
3433             # range to the end of the input range
3434             if ($r->[$j-1]->end < $end) {
3435                     push @gap_list, Range->new(main::max($start,
3436                                                          $r->[$j-1]->end + 1),
3437                                                $end,
3438                                                Type => $type);
3439                     trace "gap after $r->[$j-1], will add $gap_list[-1]" if main::DEBUG && $to_trace;
3440             }
3441
3442             # Call recursively to fill in all the gaps.
3443             foreach my $gap (@gap_list) {
3444                 $self->_add_delete($operation,
3445                                    $gap->start,
3446                                    $gap->end,
3447                                    $value,
3448                                    Type => $type);
3449             }
3450
3451             return;
3452         }
3453
3454         # Here, we have taken care of the case where $replace is $NO.
3455         # Remember that here, r[$i-1]->end < $start <= r[$i]->end
3456         # If inserting a multiple record, this is where it goes, before the
3457         # first (if any) existing one.  This implies an insertion, and no
3458         # change to any existing ranges.  Note that $i can be -1 if this new
3459         # range doesn't actually duplicate any existing, and comes at the
3460         # beginning of the list.
3461         if ($replace == $MULTIPLE) {
3462
3463             if ($start != $end) {
3464                 Carp::my_carp_bug("$owner_name_of{$addr}Can't cope with adding a multiple record when the range ($start..$end) contains more than one code point.  No action taken.");
3465                 return;
3466             }
3467
3468             # Don't add an exact duplicate, as it isn't really a multiple
3469             if ($end >= $r->[$i]->start) {
3470                 if ($r->[$i]->start != $r->[$i]->end) {
3471                     Carp::my_carp_bug("$owner_name_of{$addr}Can't cope with adding a multiple record when the other range ($r->[$i]) contains more than one code point.  No action taken.");
3472                     return;
3473                 }
3474                 return if $value eq $r->[$i]->value && $type eq $r->[$i]->type;
3475             }
3476
3477             trace "Adding multiple record at $i with $start..$end, $value" if main::DEBUG && $to_trace;
3478             my @return = splice @$r,
3479                                 $i,
3480                                 0,
3481                                 Range->new($start,
3482                                            $end,
3483                                            Value => $value,
3484                                            Type => $type);
3485             if (main::DEBUG && $to_trace) {
3486                 trace "After splice:";
3487                 trace 'i-2=[', $i-2, ']', $r->[$i-2] if $i >= 2;
3488                 trace 'i-1=[', $i-1, ']', $r->[$i-1] if $i >= 1;
3489                 trace "i  =[", $i, "]", $r->[$i] if $i >= 0;
3490                 trace 'i+1=[', $i+1, ']', $r->[$i+1] if $i < @$r - 1;
3491                 trace 'i+2=[', $i+2, ']', $r->[$i+2] if $i < @$r - 2;
3492                 trace 'i+3=[', $i+3, ']', $r->[$i+3] if $i < @$r - 3;
3493             }
3494             return @return;
3495         }
3496
3497         # Here, we have taken care of $NO and $MULTIPLE replaces.  This leaves
3498         # delete, insert, and replace either unconditionally or if not
3499         # equivalent.  $i still points to the first potential affected range.
3500         # Now find the highest range affected, which will determine the length
3501         # parameter to splice.  (The input range can span multiple existing
3502         # ones.)  If this isn't a deletion, while we are looking through the
3503         # range list, see also if this is a replacement rather than a clean
3504         # insertion; that is if it will change the values of at least one
3505         # existing range.  Start off assuming it is an insert, until find it
3506         # isn't.
3507         my $clean_insert = $operation eq '+';
3508         my $j;        # This will point to the highest affected range
3509
3510         # For non-zero types, the standard form is the value itself;
3511         my $standard_form = ($type) ? $value : main::standardize($value);
3512
3513         for ($j = $i; $j < $range_list_size; $j++) {
3514             trace "Looking for highest affected range; the one at $j is ", $r->[$j] if main::DEBUG && $to_trace;
3515
3516             # If find a range that it doesn't overlap into, we can stop
3517             # searching
3518             last if $end < $r->[$j]->start;
3519
3520             # Here, overlaps the range at $j.  If the values don't match,
3521             # and so far we think this is a clean insertion, it becomes a
3522             # non-clean insertion, i.e., a 'change' or 'replace' instead.
3523             if ($clean_insert) {
3524                 if ($r->[$j]->standard_form ne $standard_form) {
3525                     $clean_insert = 0;
3526                 }
3527                 else {
3528
3529                     # Here, the two values are essentially the same.  If the
3530                     # two are actually identical, replacing wouldn't change
3531                     # anything so skip it.
3532                     my $pre_existing = $r->[$j]->value;
3533                     if ($pre_existing ne $value) {
3534
3535                         # Here the new and old standardized values are the
3536                         # same, but the non-standardized values aren't.  If
3537                         # replacing unconditionally, then replace
3538                         if( $replace == $UNCONDITIONALLY) {
3539                             $clean_insert = 0;
3540                         }
3541                         else {
3542
3543                             # Here, are replacing conditionally.  Decide to
3544                             # replace or not based on which appears to look
3545                             # the "nicest".  If one is mixed case and the
3546                             # other isn't, choose the mixed case one.
3547                             my $new_mixed = $value =~ /[A-Z]/
3548                                             && $value =~ /[a-z]/;
3549                             my $old_mixed = $pre_existing =~ /[A-Z]/
3550                                             && $pre_existing =~ /[a-z]/;
3551
3552                             if ($old_mixed != $new_mixed) {
3553                                 $clean_insert = 0 if $new_mixed;
3554                                 if (main::DEBUG && $to_trace) {
3555                                     if ($clean_insert) {
3556                                         trace "Retaining $pre_existing over $value";
3557                                     }
3558                                     else {
3559                                         trace "Replacing $pre_existing with $value";
3560                                     }
3561                                 }
3562                             }
3563                             else {
3564
3565                                 # Here casing wasn't different between the two.
3566                                 # If one has hyphens or underscores and the
3567                                 # other doesn't, choose the one with the
3568                                 # punctuation.
3569                                 my $new_punct = $value =~ /[-_]/;
3570                                 my $old_punct = $pre_existing =~ /[-_]/;
3571
3572                                 if ($old_punct != $new_punct) {
3573                                     $clean_insert = 0 if $new_punct;
3574                                     if (main::DEBUG && $to_trace) {
3575                                         if ($clean_insert) {
3576                                             trace "Retaining $pre_existing over $value";
3577                                         }
3578                                         else {
3579                                             trace "Replacing $pre_existing with $value";
3580                                         }
3581                                     }
3582                                 }   # else existing one is just as "good";
3583                                     # retain it to save cycles.
3584                             }
3585                         }
3586                     }
3587                 }
3588             }
3589         } # End of loop looking for highest affected range.
3590
3591         # Here, $j points to one beyond the highest range that this insertion
3592         # affects (hence to beyond the range list if that range is the final
3593         # one in the range list).
3594
3595         # The splice length is all the affected ranges.  Get it before
3596         # subtracting, for efficiency, so we don't have to later add 1.
3597         my $length = $j - $i;
3598
3599         $j--;        # $j now points to the highest affected range.
3600         trace "Final affected range is $j: $r->[$j]" if main::DEBUG && $to_trace;
3601
3602         # Here, have taken care of $NO and $MULTIPLE replaces.
3603         # $j points to the highest affected range.  But it can be < $i or even
3604         # -1.  These happen only if the insertion is entirely in the gap
3605         # between r[$i-1] and r[$i].  Here's why: j < i means that the j loop
3606         # above exited first time through with $end < $r->[$i]->start.  (And
3607         # then we subtracted one from j)  This implies also that $start <
3608         # $r->[$i]->start, but we know from above that $r->[$i-1]->end <
3609         # $start, so the entire input range is in the gap.
3610         if ($j < $i) {
3611
3612             # Here the entire input range is in the gap before $i.
3613
3614             if (main::DEBUG && $to_trace) {
3615                 if ($i) {
3616                     trace "Entire range is between $r->[$i-1] and $r->[$i]";
3617                 }
3618                 else {
3619                     trace "Entire range is before $r->[$i]";
3620                 }
3621             }
3622             return if $operation ne '+'; # Deletion of a non-existent range is
3623                                          # a no-op
3624         }
3625         else {
3626
3627             # Here part of the input range is not in the gap before $i.  Thus,
3628             # there is at least one affected one, and $j points to the highest
3629             # such one.
3630
3631             # At this point, here is the situation:
3632             # This is not an insertion of a multiple, nor of tentative ($NO)
3633             # data.
3634             #   $i  points to the first element in the current range list that
3635             #            may be affected by this operation.  In fact, we know
3636             #            that the range at $i is affected because we are in
3637             #            the else branch of this 'if'
3638             #   $j  points to the highest affected range.
3639             # In other words,
3640             #   r[$i-1]->end < $start <= r[$i]->end
3641             # And:
3642             #   r[$i-1]->end < $start <= $end <= r[$j]->end
3643             #
3644             # Also:
3645             #   $clean_insert is a boolean which is set true if and only if
3646             #        this is a "clean insertion", i.e., not a change nor a
3647             #        deletion (multiple was handled above).
3648
3649             # We now have enough information to decide if this call is a no-op
3650             # or not.  It is a no-op if this is an insertion of already
3651             # existing data.
3652
3653             if (main::DEBUG && $to_trace && $clean_insert
3654                                          && $i == $j
3655                                          && $start >= $r->[$i]->start)
3656             {
3657                     trace "no-op";
3658             }
3659             return if $clean_insert
3660                       && $i == $j # more than one affected range => not no-op
3661
3662                       # Here, r[$i-1]->end < $start <= $end <= r[$i]->end
3663                       # Further, $start and/or $end is >= r[$i]->start
3664                       # The test below hence guarantees that
3665                       #     r[$i]->start < $start <= $end <= r[$i]->end
3666                       # This means the input range is contained entirely in
3667                       # the one at $i, so is a no-op
3668                       && $start >= $r->[$i]->start;
3669         }
3670
3671         # Here, we know that some action will have to be taken.  We have
3672         # calculated the offset and length (though adjustments may be needed)
3673         # for the splice.  Now start constructing the replacement list.
3674         my @replacement;
3675         my $splice_start = $i;
3676
3677         my $extends_below;
3678         my $extends_above;
3679
3680         # See if should extend any adjacent ranges.
3681         if ($operation eq '-') { # Don't extend deletions
3682             $extends_below = $extends_above = 0;
3683         }
3684         else {  # Here, should extend any adjacent ranges.  See if there are
3685                 # any.
3686             $extends_below = ($i > 0
3687                             # can't extend unless adjacent
3688                             && $r->[$i-1]->end == $start -1
3689                             # can't extend unless are same standard value
3690                             && $r->[$i-1]->standard_form eq $standard_form
3691                             # can't extend unless share type
3692                             && $r->[$i-1]->type == $type);
3693             $extends_above = ($j+1 < $range_list_size
3694                             && $r->[$j+1]->start == $end +1
3695                             && $r->[$j+1]->standard_form eq $standard_form
3696                             && $r->[$j+1]->type == $type);
3697         }
3698         if ($extends_below && $extends_above) { # Adds to both
3699             $splice_start--;     # start replace at element below
3700             $length += 2;        # will replace on both sides
3701             trace "Extends both below and above ranges" if main::DEBUG && $to_trace;
3702
3703             # The result will fill in any gap, replacing both sides, and
3704             # create one large range.
3705             @replacement = Range->new($r->[$i-1]->start,
3706                                       $r->[$j+1]->end,
3707                                       Value => $value,
3708                                       Type => $type);
3709         }
3710         else {
3711
3712             # Here we know that the result won't just be the conglomeration of
3713             # a new range with both its adjacent neighbors.  But it could
3714             # extend one of them.
3715
3716             if ($extends_below) {
3717
3718                 # Here the new element adds to the one below, but not to the
3719                 # one above.  If inserting, and only to that one range,  can
3720                 # just change its ending to include the new one.
3721                 if ($length == 0 && $clean_insert) {
3722                     $r->[$i-1]->set_end($end);
3723                     trace "inserted range extends range to below so it is now $r->[$i-1]" if main::DEBUG && $to_trace;
3724                     return;
3725                 }
3726                 else {
3727                     trace "Changing inserted range to start at ", sprintf("%04X",  $r->[$i-1]->start), " instead of ", sprintf("%04X", $start) if main::DEBUG && $to_trace;
3728                     $splice_start--;        # start replace at element below
3729                     $length++;              # will replace the element below
3730                     $start = $r->[$i-1]->start;
3731                 }
3732             }
3733             elsif ($extends_above) {
3734
3735                 # Here the new element adds to the one above, but not below.
3736                 # Mirror the code above
3737                 if ($length == 0 && $clean_insert) {
3738                     $r->[$j+1]->set_start($start);
3739                     trace "inserted range extends range to above so it is now $r->[$j+1]" if main::DEBUG && $to_trace;
3740                     return;
3741                 }
3742                 else {
3743                     trace "Changing inserted range to end at ", sprintf("%04X",  $r->[$j+1]->end), " instead of ", sprintf("%04X", $end) if main::DEBUG && $to_trace;
3744                     $length++;        # will replace the element above
3745                     $end = $r->[$j+1]->end;
3746                 }
3747             }
3748
3749             trace "Range at $i is $r->[$i]" if main::DEBUG && $to_trace;
3750
3751             # Finally, here we know there will have to be a splice.
3752             # If the change or delete affects only the highest portion of the
3753             # first affected range, the range will have to be split.  The
3754             # splice will remove the whole range, but will replace it by a new
3755             # range containing just the unaffected part.  So, in this case,
3756             # add to the replacement list just this unaffected portion.
3757             if (! $extends_below
3758                 && $start > $r->[$i]->start && $start <= $r->[$i]->end)
3759             {
3760                 push @replacement,
3761                     Range->new($r->[$i]->start,
3762                                $start - 1,
3763                                Value => $r->[$i]->value,
3764                                Type => $r->[$i]->type);
3765             }
3766
3767             # In the case of an insert or change, but not a delete, we have to
3768             # put in the new stuff;  this comes next.
3769             if ($operation eq '+') {
3770                 push @replacement, Range->new($start,
3771                                               $end,
3772                                               Value => $value,
3773                                               Type => $type);
3774             }
3775
3776             trace "Range at $j is $r->[$j]" if main::DEBUG && $to_trace && $j != $i;
3777             #trace "$end >=", $r->[$j]->start, " && $end <", $r->[$j]->end if main::DEBUG && $to_trace;
3778
3779             # And finally, if we're changing or deleting only a portion of the
3780             # highest affected range, it must be split, as the lowest one was.
3781             if (! $extends_above
3782                 && $j >= 0  # Remember that j can be -1 if before first
3783                             # current element
3784                 && $end >= $r->[$j]->start
3785                 && $end < $r->[$j]->end)
3786             {
3787                 push @replacement,
3788                     Range->new($end + 1,
3789                                $r->[$j]->end,
3790                                Value => $r->[$j]->value,
3791                                Type => $r->[$j]->type);
3792             }
3793         }
3794
3795         # And do the splice, as calculated above
3796         if (main::DEBUG && $to_trace) {
3797             trace "replacing $length element(s) at $i with ";
3798             foreach my $replacement (@replacement) {
3799                 trace "    $replacement";
3800             }
3801             trace "Before splice:";
3802             trace 'i-2=[', $i-2, ']', $r->[$i-2] if $i >= 2;
3803             trace 'i-1=[', $i-1, ']', $r->[$i-1] if $i >= 1;
3804             trace "i  =[", $i, "]", $r->[$i];
3805             trace 'i+1=[', $i+1, ']', $r->[$i+1] if $i < @$r - 1;
3806             trace 'i+2=[', $i+2, ']', $r->[$i+2] if $i < @$r - 2;
3807         }
3808
3809         my @return = splice @$r, $splice_start, $length, @replacement;
3810
3811         if (main::DEBUG && $to_trace) {
3812             trace "After splice:";
3813             trace 'i-2=[', $i-2, ']', $r->[$i-2] if $i >= 2;
3814             trace 'i-1=[', $i-1, ']', $r->[$i-1] if $i >= 1;
3815             trace "i  =[", $i, "]", $r->[$i];
3816             trace 'i+1=[', $i+1, ']', $r->[$i+1] if $i < @$r - 1;
3817             trace 'i+2=[', $i+2, ']', $r->[$i+2] if $i < @$r - 2;
3818             trace "removed @return";
3819         }
3820
3821         # An actual deletion could have changed the maximum in the list.
3822         # There was no deletion if the splice didn't return something, but
3823         # otherwise recalculate it.  This is done too rarely to worry about
3824         # performance.
3825         if ($operation eq '-' && @return) {
3826             $max{$addr} = $r->[-1]->end;
3827         }
3828         return @return;
3829     }
3830
3831     sub reset_each_range {  # reset the iterator for each_range();
3832         my $self = shift;
3833         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3834
3835         no overloading;
3836         undef $each_range_iterator{pack 'J', $self};
3837         return;
3838     }
3839
3840     sub each_range {
3841         # Iterate over each range in a range list.  Results are undefined if
3842         # the range list is changed during the iteration.
3843
3844         my $self = shift;
3845         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3846
3847         my $addr = do { no overloading; pack 'J', $self; };
3848
3849         return if $self->is_empty;
3850
3851         $each_range_iterator{$addr} = -1
3852                                 if ! defined $each_range_iterator{$addr};
3853         $each_range_iterator{$addr}++;
3854         return $ranges{$addr}->[$each_range_iterator{$addr}]
3855                         if $each_range_iterator{$addr} < @{$ranges{$addr}};
3856         undef $each_range_iterator{$addr};
3857         return;
3858     }
3859
3860     sub count {        # Returns count of code points in range list
3861         my $self = shift;
3862         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3863
3864         my $addr = do { no overloading; pack 'J', $self; };
3865
3866         my $count = 0;
3867         foreach my $range (@{$ranges{$addr}}) {
3868             $count += $range->end - $range->start + 1;
3869         }
3870         return $count;
3871     }
3872
3873     sub delete_range {    # Delete a range
3874         my $self = shift;
3875         my $start = shift;
3876         my $end = shift;
3877
3878         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3879
3880         return $self->_add_delete('-', $start, $end, "");
3881     }
3882
3883     sub is_empty { # Returns boolean as to if a range list is empty
3884         my $self = shift;
3885         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3886
3887         no overloading;
3888         return scalar @{$ranges{pack 'J', $self}} == 0;
3889     }
3890
3891     sub hash {
3892         # Quickly returns a scalar suitable for separating tables into
3893         # buckets, i.e. it is a hash function of the contents of a table, so
3894         # there are relatively few conflicts.
3895
3896         my $self = shift;
3897         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3898
3899         my $addr = do { no overloading; pack 'J', $self; };
3900
3901         # These are quickly computable.  Return looks like 'min..max;count'
3902         return $self->min . "..$max{$addr};" . scalar @{$ranges{$addr}};
3903     }
3904 } # End closure for _Range_List_Base
3905
3906 package Range_List;
3907 use base '_Range_List_Base';
3908
3909 # A Range_List is a range list for match tables; i.e. the range values are
3910 # not significant.  Thus a number of operations can be safely added to it,
3911 # such as inversion, intersection.  Note that union is also an unsafe
3912 # operation when range values are cared about, and that method is in the base
3913 # class, not here.  But things are set up so that that method is callable only
3914 # during initialization.  Only in this derived class, is there an operation
3915 # that combines two tables.  A Range_Map can thus be used to initialize a
3916 # Range_List, and its mappings will be in the list, but are not significant to
3917 # this class.
3918
3919 sub trace { return main::trace(@_); }
3920
3921 { # Closure
3922
3923     use overload
3924         fallback => 0,
3925         '+' => sub { my $self = shift;
3926                     my $other = shift;
3927
3928                     return $self->_union($other)
3929                 },
3930         '&' => sub { my $self = shift;
3931                     my $other = shift;
3932
3933                     return $self->_intersect($other, 0);
3934                 },
3935         '~' => "_invert",
3936         '-' => "_subtract",
3937     ;
3938
3939     sub _invert {
3940         # Returns a new Range_List that gives all code points not in $self.
3941
3942         my $self = shift;
3943
3944         my $new = Range_List->new;
3945
3946         # Go through each range in the table, finding the gaps between them
3947         my $max = -1;   # Set so no gap before range beginning at 0
3948         for my $range ($self->ranges) {
3949             my $start = $range->start;
3950             my $end   = $range->end;
3951
3952             # If there is a gap before this range, the inverse will contain
3953             # that gap.
3954             if ($start > $max + 1) {
3955                 $new->add_range($max + 1, $start - 1);
3956             }
3957             $max = $end;
3958         }
3959
3960         # And finally, add the gap from the end of the table to the max
3961         # possible code point
3962         if ($max < $LAST_UNICODE_CODEPOINT) {
3963             $new->add_range($max + 1, $LAST_UNICODE_CODEPOINT);
3964         }
3965         return $new;
3966     }
3967
3968     sub _subtract {
3969         # Returns a new Range_List with the argument deleted from it.  The
3970         # argument can be a single code point, a range, or something that has
3971         # a range, with the _range_list() method on it returning them
3972
3973         my $self = shift;
3974         my $other = shift;
3975         my $reversed = shift;
3976         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3977
3978         if ($reversed) {
3979             Carp::my_carp_bug("Can't cope with a "
3980              .  __PACKAGE__
3981              . " being the second parameter in a '-'.  Subtraction ignored.");
3982             return $self;
3983         }
3984
3985         my $new = Range_List->new(Initialize => $self);
3986
3987         if (! ref $other) { # Single code point
3988             $new->delete_range($other, $other);
3989         }
3990         elsif ($other->isa('Range')) {
3991             $new->delete_range($other->start, $other->end);
3992         }
3993         elsif ($other->can('_range_list')) {
3994             foreach my $range ($other->_range_list->ranges) {
3995                 $new->delete_range($range->start, $range->end);
3996             }
3997         }
3998         else {
3999             Carp::my_carp_bug("Can't cope with a "
4000                         . ref($other)
4001                         . " argument to '-'.  Subtraction ignored."
4002                         );
4003             return $self;
4004         }
4005
4006         return $new;
4007     }
4008
4009     sub _intersect {
4010         # Returns either a boolean giving whether the two inputs' range lists
4011         # intersect (overlap), or a new Range_List containing the intersection
4012         # of the two lists.  The optional final parameter being true indicates
4013         # to do the check instead of the intersection.
4014
4015         my $a_object = shift;
4016         my $b_object = shift;
4017         my $check_if_overlapping = shift;
4018         $check_if_overlapping = 0 unless defined $check_if_overlapping;