Allow ~~ overloading on the left side, when the right side is a plain scalar
[perl.git] / lib / overload.pm
1 package overload;
2
3 our $VERSION = '1.07';
4
5 sub nil {}
6
7 sub OVERLOAD {
8   $package = shift;
9   my %arg = @_;
10   my ($sub, $fb);
11   $ {$package . "::OVERLOAD"}{dummy}++; # Register with magic by touching.
12   *{$package . "::()"} = \&nil; # Make it findable via fetchmethod.
13   for (keys %arg) {
14     if ($_ eq 'fallback') {
15       $fb = $arg{$_};
16     } else {
17       $sub = $arg{$_};
18       if (not ref $sub and $sub !~ /::/) {
19         $ {$package . "::(" . $_} = $sub;
20         $sub = \&nil;
21       }
22       #print STDERR "Setting `$ {'package'}::\cO$_' to \\&`$sub'.\n";
23       *{$package . "::(" . $_} = \&{ $sub };
24     }
25   }
26   ${$package . "::()"} = $fb; # Make it findable too (fallback only).
27 }
28
29 sub import {
30   $package = (caller())[0];
31   # *{$package . "::OVERLOAD"} = \&OVERLOAD;
32   shift;
33   $package->overload::OVERLOAD(@_);
34 }
35
36 sub unimport {
37   $package = (caller())[0];
38   ${$package . "::OVERLOAD"}{dummy}++; # Upgrade the table
39   shift;
40   for (@_) {
41     if ($_ eq 'fallback') {
42       undef $ {$package . "::()"};
43     } else {
44       delete $ {$package . "::"}{"(" . $_};
45     }
46   }
47 }
48
49 sub Overloaded {
50   my $package = shift;
51   $package = ref $package if ref $package;
52   $package->can('()');
53 }
54
55 sub ov_method {
56   my $globref = shift;
57   return undef unless $globref;
58   my $sub = \&{*$globref};
59   return $sub if $sub ne \&nil;
60   return shift->can($ {*$globref});
61 }
62
63 sub OverloadedStringify {
64   my $package = shift;
65   $package = ref $package if ref $package;
66   #$package->can('(""')
67   ov_method mycan($package, '(""'), $package
68     or ov_method mycan($package, '(0+'), $package
69     or ov_method mycan($package, '(bool'), $package
70     or ov_method mycan($package, '(nomethod'), $package;
71 }
72
73 sub Method {
74   my $package = shift;
75   if(ref $package) {
76     local $@;
77     local $!;
78     require Scalar::Util;
79     $package = Scalar::Util::blessed($package);
80     return undef if !defined $package;
81   }
82   #my $meth = $package->can('(' . shift);
83   ov_method mycan($package, '(' . shift), $package;
84   #return $meth if $meth ne \&nil;
85   #return $ {*{$meth}};
86 }
87
88 sub AddrRef {
89   my $package = ref $_[0];
90   return "$_[0]" unless $package;
91
92   local $@;
93   local $!;
94   require Scalar::Util;
95   my $class = Scalar::Util::blessed($_[0]);
96   my $class_prefix = defined($class) ? "$class=" : "";
97   my $type = Scalar::Util::reftype($_[0]);
98   my $addr = Scalar::Util::refaddr($_[0]);
99   return sprintf("$class_prefix$type(0x%x)", $addr);
100 }
101
102 *StrVal = *AddrRef;
103
104 sub mycan {                             # Real can would leave stubs.
105   my ($package, $meth) = @_;
106
107   local $@;
108   local $!;
109   require mro;
110
111   my $mro = mro::get_linear_isa($package);
112   foreach my $p (@$mro) {
113     my $fqmeth = $p . q{::} . $meth;
114     return \*{$fqmeth} if defined &{$fqmeth};
115   }
116
117   return undef;
118 }
119
120 %constants = (
121               'integer'   =>  0x1000, # HINT_NEW_INTEGER
122               'float'     =>  0x2000, # HINT_NEW_FLOAT
123               'binary'    =>  0x4000, # HINT_NEW_BINARY
124               'q'         =>  0x8000, # HINT_NEW_STRING
125               'qr'        => 0x10000, # HINT_NEW_RE
126              );
127
128 %ops = ( with_assign      => "+ - * / % ** << >> x .",
129          assign           => "+= -= *= /= %= **= <<= >>= x= .=",
130          num_comparison   => "< <= >  >= == !=",
131          '3way_comparison'=> "<=> cmp",
132          str_comparison   => "lt le gt ge eq ne",
133          binary           => '& &= | |= ^ ^=',
134          unary            => "neg ! ~",
135          mutators         => '++ --',
136          func             => "atan2 cos sin exp abs log sqrt int",
137          conversion       => 'bool "" 0+',
138          iterators        => '<>',
139          filetest         => "-X",
140          dereferencing    => '${} @{} %{} &{} *{}',
141          matching         => '~~',
142          special          => 'nomethod fallback =');
143
144 use warnings::register;
145 sub constant {
146   # Arguments: what, sub
147   while (@_) {
148     if (@_ == 1) {
149         warnings::warnif ("Odd number of arguments for overload::constant");
150         last;
151     }
152     elsif (!exists $constants {$_ [0]}) {
153         warnings::warnif ("`$_[0]' is not an overloadable type");
154     }
155     elsif (!ref $_ [1] || "$_[1]" !~ /(^|=)CODE\(0x[0-9a-f]+\)$/) {
156         # Can't use C<ref $_[1] eq "CODE"> above as code references can be
157         # blessed, and C<ref> would return the package the ref is blessed into.
158         if (warnings::enabled) {
159             $_ [1] = "undef" unless defined $_ [1];
160             warnings::warn ("`$_[1]' is not a code reference");
161         }
162     }
163     else {
164         $^H{$_[0]} = $_[1];
165         $^H |= $constants{$_[0]};
166     }
167     shift, shift;
168   }
169 }
170
171 sub remove_constant {
172   # Arguments: what, sub
173   while (@_) {
174     delete $^H{$_[0]};
175     $^H &= ~ $constants{$_[0]};
176     shift, shift;
177   }
178 }
179
180 1;
181
182 __END__
183
184 =head1 NAME
185
186 overload - Package for overloading Perl operations
187
188 =head1 SYNOPSIS
189
190     package SomeThing;
191
192     use overload
193         '+' => \&myadd,
194         '-' => \&mysub;
195         # etc
196     ...
197
198     package main;
199     $a = SomeThing->new( 57 );
200     $b=5+$a;
201     ...
202     if (overload::Overloaded $b) {...}
203     ...
204     $strval = overload::StrVal $b;
205
206 =head1 DESCRIPTION
207
208 This pragma allows overloading of Perl's operators for a class.
209 To overload built-in functions, see L<perlsub/Overriding Built-in Functions> instead.
210
211 =head2 Declaration of overloaded functions
212
213 The compilation directive
214
215     package Number;
216     use overload
217         "+" => \&add,
218         "*=" => "muas";
219
220 declares function Number::add() for addition, and method muas() in
221 the "class" C<Number> (or one of its base classes)
222 for the assignment form C<*=> of multiplication.
223
224 Arguments of this directive come in (key, value) pairs.  Legal values
225 are values legal inside a C<&{ ... }> call, so the name of a
226 subroutine, a reference to a subroutine, or an anonymous subroutine
227 will all work.  Note that values specified as strings are
228 interpreted as methods, not subroutines.  Legal keys are listed below.
229
230 The subroutine C<add> will be called to execute C<$a+$b> if $a
231 is a reference to an object blessed into the package C<Number>, or if $a is
232 not an object from a package with defined mathemagic addition, but $b is a
233 reference to a C<Number>.  It can also be called in other situations, like
234 C<$a+=7>, or C<$a++>.  See L<MAGIC AUTOGENERATION>.  (Mathemagical
235 methods refer to methods triggered by an overloaded mathematical
236 operator.)
237
238 Since overloading respects inheritance via the @ISA hierarchy, the
239 above declaration would also trigger overloading of C<+> and C<*=> in
240 all the packages which inherit from C<Number>.
241
242 =head2 Calling Conventions for Binary Operations
243
244 The functions specified in the C<use overload ...> directive are called
245 with three (in one particular case with four, see L<Last Resort>)
246 arguments.  If the corresponding operation is binary, then the first
247 two arguments are the two arguments of the operation.  However, due to
248 general object calling conventions, the first argument should always be
249 an object in the package, so in the situation of C<7+$a>, the
250 order of the arguments is interchanged.  It probably does not matter
251 when implementing the addition method, but whether the arguments
252 are reversed is vital to the subtraction method.  The method can
253 query this information by examining the third argument, which can take
254 three different values:
255
256 =over 7
257
258 =item FALSE
259
260 the order of arguments is as in the current operation.
261
262 =item TRUE
263
264 the arguments are reversed.
265
266 =item C<undef>
267
268 the current operation is an assignment variant (as in
269 C<$a+=7>), but the usual function is called instead.  This additional
270 information can be used to generate some optimizations.  Compare
271 L<Calling Conventions for Mutators>.
272
273 =back
274
275 =head2 Calling Conventions for Unary Operations
276
277 Unary operation are considered binary operations with the second
278 argument being C<undef>.  Thus the functions that overloads C<{"++"}>
279 is called with arguments C<($a,undef,'')> when $a++ is executed.
280
281 =head2 Calling Conventions for Mutators
282
283 Two types of mutators have different calling conventions:
284
285 =over
286
287 =item C<++> and C<-->
288
289 The routines which implement these operators are expected to actually
290 I<mutate> their arguments.  So, assuming that $obj is a reference to a
291 number,
292
293   sub incr { my $n = $ {$_[0]}; ++$n; $_[0] = bless \$n}
294
295 is an appropriate implementation of overloaded C<++>.  Note that
296
297   sub incr { ++$ {$_[0]} ; shift }
298
299 is OK if used with preincrement and with postincrement. (In the case
300 of postincrement a copying will be performed, see L<Copy Constructor>.)
301
302 =item C<x=> and other assignment versions
303
304 There is nothing special about these methods.  They may change the
305 value of their arguments, and may leave it as is.  The result is going
306 to be assigned to the value in the left-hand-side if different from
307 this value.
308
309 This allows for the same method to be used as overloaded C<+=> and
310 C<+>.  Note that this is I<allowed>, but not recommended, since by the
311 semantic of L<"Fallback"> Perl will call the method for C<+> anyway,
312 if C<+=> is not overloaded.
313
314 =back
315
316 B<Warning.>  Due to the presence of assignment versions of operations,
317 routines which may be called in assignment context may create
318 self-referential structures.  Currently Perl will not free self-referential
319 structures until cycles are C<explicitly> broken.  You may get problems
320 when traversing your structures too.
321
322 Say,
323
324   use overload '+' => sub { bless [ \$_[0], \$_[1] ] };
325
326 is asking for trouble, since for code C<$obj += $foo> the subroutine
327 is called as C<$obj = add($obj, $foo, undef)>, or C<$obj = [\$obj,
328 \$foo]>.  If using such a subroutine is an important optimization, one
329 can overload C<+=> explicitly by a non-"optimized" version, or switch
330 to non-optimized version if C<not defined $_[2]> (see
331 L<Calling Conventions for Binary Operations>).
332
333 Even if no I<explicit> assignment-variants of operators are present in
334 the script, they may be generated by the optimizer.  Say, C<",$obj,"> or
335 C<',' . $obj . ','> may be both optimized to
336
337   my $tmp = ',' . $obj;    $tmp .= ',';
338
339 =head2 Overloadable Operations
340
341 The following symbols can be specified in C<use overload> directive:
342
343 =over 5
344
345 =item * I<Arithmetic operations>
346
347     "+", "+=", "-", "-=", "*", "*=", "/", "/=", "%", "%=",
348     "**", "**=", "<<", "<<=", ">>", ">>=", "x", "x=", ".", ".=",
349
350 For these operations a substituted non-assignment variant can be called if
351 the assignment variant is not available.  Methods for operations C<+>,
352 C<->, C<+=>, and C<-=> can be called to automatically generate
353 increment and decrement methods.  The operation C<-> can be used to
354 autogenerate missing methods for unary minus or C<abs>.
355
356 See L<"MAGIC AUTOGENERATION">, L<"Calling Conventions for Mutators"> and
357 L<"Calling Conventions for Binary Operations">) for details of these
358 substitutions.
359
360 =item * I<Comparison operations>
361
362     "<",  "<=", ">",  ">=", "==", "!=", "<=>",
363     "lt", "le", "gt", "ge", "eq", "ne", "cmp",
364
365 If the corresponding "spaceship" variant is available, it can be
366 used to substitute for the missing operation.  During C<sort>ing
367 arrays, C<cmp> is used to compare values subject to C<use overload>.
368
369 =item * I<Bit operations>
370
371     "&", "&=", "^", "^=", "|", "|=", "neg", "!", "~",
372
373 C<neg> stands for unary minus.  If the method for C<neg> is not
374 specified, it can be autogenerated using the method for
375 subtraction. If the method for C<!> is not specified, it can be
376 autogenerated using the methods for C<bool>, or C<"">, or C<0+>.
377
378 The same remarks in L<"Arithmetic operations"> about
379 assignment-variants and autogeneration apply for
380 bit operations C<"&">, C<"^">, and C<"|"> as well.
381
382 =item * I<Increment and decrement>
383
384     "++", "--",
385
386 If undefined, addition and subtraction methods can be
387 used instead.  These operations are called both in prefix and
388 postfix form.
389
390 =item * I<Transcendental functions>
391
392     "atan2", "cos", "sin", "exp", "abs", "log", "sqrt", "int"
393
394 If C<abs> is unavailable, it can be autogenerated using methods
395 for "E<lt>" or "E<lt>=E<gt>" combined with either unary minus or subtraction.
396
397 Note that traditionally the Perl function L<int> rounds to 0, thus for
398 floating-point-like types one should follow the same semantic.  If
399 C<int> is unavailable, it can be autogenerated using the overloading of
400 C<0+>.
401
402 =item * I<Boolean, string and numeric conversion>
403
404     'bool', '""', '0+',
405
406 If one or two of these operations are not overloaded, the remaining ones can
407 be used instead.  C<bool> is used in the flow control operators
408 (like C<while>) and for the ternary C<?:> operation.  These functions can
409 return any arbitrary Perl value.  If the corresponding operation for this value
410 is overloaded too, that operation will be called again with this value.
411
412 As a special case if the overload returns the object itself then it will
413 be used directly. An overloaded conversion returning the object is
414 probably a bug, because you're likely to get something that looks like
415 C<YourPackage=HASH(0x8172b34)>.
416
417 =item * I<Iteration>
418
419     "<>"
420
421 If not overloaded, the argument will be converted to a filehandle or
422 glob (which may require a stringification).  The same overloading
423 happens both for the I<read-filehandle> syntax C<E<lt>$varE<gt>> and
424 I<globbing> syntax C<E<lt>${var}E<gt>>.
425
426 B<BUGS> Even in list context, the iterator is currently called only
427 once and with scalar context.
428
429 =item * I<File tests>
430
431     "-X"
432
433 This overload is used for all the filetest operators (C<-f>, C<-x> and
434 so on: see L<perlfunc/-X> for the full list). Even though these are
435 unary operators, the method will be called with a second argument which
436 is a single letter indicating which test was performed. Note that the
437 overload key is the literal string C<"-X">: you can't provide separate
438 overloads for the different tests.
439
440 Calling an overloaded filetest operator does not affect the stat value
441 associated with the special filehandle C<_>. It still refers to the
442 result of the last C<stat>, C<lstat> or unoverloaded filetest.
443
444 If not overloaded, these operators will fall back to the default
445 behaviour even without C<< fallback => 1 >>. This means that if the
446 object is a blessed glob or blessed IO ref it will be treated as a
447 filehandle, otherwise string overloading will be invoked and the result
448 treated as a filename.
449
450 This overload was introduced in perl 5.12.
451
452 =item * I<Matching>
453
454 The key C<"~~"> allows you to override the smart matching used by
455 the switch construct. See L<feature>.
456
457 =item * I<Dereferencing>
458
459     '${}', '@{}', '%{}', '&{}', '*{}'.
460
461 If not overloaded, the argument will be dereferenced I<as is>, thus
462 should be of correct type.  These functions should return a reference
463 of correct type, or another object with overloaded dereferencing.
464
465 As a special case if the overload returns the object itself then it
466 will be used directly (provided it is the correct type).
467
468 The dereference operators must be specified explicitly they will not be passed to
469 "nomethod".
470
471 =item * I<Special>
472
473     "nomethod", "fallback", "=".
474
475 see L<SPECIAL SYMBOLS FOR C<use overload>>.
476
477 =back
478
479 See L<"Fallback"> for an explanation of when a missing method can be
480 autogenerated.
481
482 A computer-readable form of the above table is available in the hash
483 %overload::ops, with values being space-separated lists of names:
484
485  with_assign      => '+ - * / % ** << >> x .',
486  assign           => '+= -= *= /= %= **= <<= >>= x= .=',
487  num_comparison   => '< <= > >= == !=',
488  '3way_comparison'=> '<=> cmp',
489  str_comparison   => 'lt le gt ge eq ne',
490  binary           => '& &= | |= ^ ^=',
491  unary            => 'neg ! ~',
492  mutators         => '++ --',
493  func             => 'atan2 cos sin exp abs log sqrt',
494  conversion       => 'bool "" 0+',
495  iterators        => '<>',
496  filetest         => '-X',
497  dereferencing    => '${} @{} %{} &{} *{}',
498  matching         => '~~',
499  special          => 'nomethod fallback ='
500
501 =head2 Inheritance and overloading
502
503 Inheritance interacts with overloading in two ways.
504
505 =over
506
507 =item Strings as values of C<use overload> directive
508
509 If C<value> in
510
511   use overload key => value;
512
513 is a string, it is interpreted as a method name.
514
515 =item Overloading of an operation is inherited by derived classes
516
517 Any class derived from an overloaded class is also overloaded.  The
518 set of overloaded methods is the union of overloaded methods of all
519 the ancestors. If some method is overloaded in several ancestor, then
520 which description will be used is decided by the usual inheritance
521 rules:
522
523 If C<A> inherits from C<B> and C<C> (in this order), C<B> overloads
524 C<+> with C<\&D::plus_sub>, and C<C> overloads C<+> by C<"plus_meth">,
525 then the subroutine C<D::plus_sub> will be called to implement
526 operation C<+> for an object in package C<A>.
527
528 =back
529
530 Note that since the value of the C<fallback> key is not a subroutine,
531 its inheritance is not governed by the above rules.  In the current
532 implementation, the value of C<fallback> in the first overloaded
533 ancestor is used, but this is accidental and subject to change.
534
535 =head1 SPECIAL SYMBOLS FOR C<use overload>
536
537 Three keys are recognized by Perl that are not covered by the above
538 description.
539
540 =head2 Last Resort
541
542 C<"nomethod"> should be followed by a reference to a function of four
543 parameters.  If defined, it is called when the overloading mechanism
544 cannot find a method for some operation.  The first three arguments of
545 this function coincide with the arguments for the corresponding method if
546 it were found, the fourth argument is the symbol
547 corresponding to the missing method.  If several methods are tried,
548 the last one is used.  Say, C<1-$a> can be equivalent to
549
550         &nomethodMethod($a,1,1,"-")
551
552 if the pair C<"nomethod" =E<gt> "nomethodMethod"> was specified in the
553 C<use overload> directive.
554
555 The C<"nomethod"> mechanism is I<not> used for the dereference operators
556 ( ${} @{} %{} &{} *{} ).
557
558
559 If some operation cannot be resolved, and there is no function
560 assigned to C<"nomethod">, then an exception will be raised via die()--
561 unless C<"fallback"> was specified as a key in C<use overload> directive.
562
563
564 =head2 Fallback
565
566 The key C<"fallback"> governs what to do if a method for a particular
567 operation is not found.  Three different cases are possible depending on
568 the value of C<"fallback">:
569
570 =over 16
571
572 =item * C<undef>
573
574 Perl tries to use a
575 substituted method (see L<MAGIC AUTOGENERATION>).  If this fails, it
576 then tries to calls C<"nomethod"> value; if missing, an exception
577 will be raised.
578
579 =item * TRUE
580
581 The same as for the C<undef> value, but no exception is raised.  Instead,
582 it silently reverts to what it would have done were there no C<use overload>
583 present.
584
585 =item * defined, but FALSE
586
587 No autogeneration is tried.  Perl tries to call
588 C<"nomethod"> value, and if this is missing, raises an exception.
589
590 =back
591
592 B<Note.> C<"fallback"> inheritance via @ISA is not carved in stone
593 yet, see L<"Inheritance and overloading">.
594
595 =head2 Copy Constructor
596
597 The value for C<"="> is a reference to a function with three
598 arguments, i.e., it looks like the other values in C<use
599 overload>. However, it does not overload the Perl assignment
600 operator. This would go against Camel hair.
601
602 This operation is called in the situations when a mutator is applied
603 to a reference that shares its object with some other reference, such
604 as
605
606         $a=$b;
607         ++$a;
608
609 To make this change $a and not change $b, a copy of C<$$a> is made,
610 and $a is assigned a reference to this new object.  This operation is
611 done during execution of the C<++$a>, and not during the assignment,
612 (so before the increment C<$$a> coincides with C<$$b>).  This is only
613 done if C<++> is expressed via a method for C<'++'> or C<'+='> (or
614 C<nomethod>).  Note that if this operation is expressed via C<'+'>
615 a nonmutator, i.e., as in
616
617         $a=$b;
618         $a=$a+1;
619
620 then C<$a> does not reference a new copy of C<$$a>, since $$a does not
621 appear as lvalue when the above code is executed.
622
623 If the copy constructor is required during the execution of some mutator,
624 but a method for C<'='> was not specified, it can be autogenerated as a
625 string copy if the object is a plain scalar or a simple assignment if it
626 is not.
627
628 =over 5
629
630 =item B<Example>
631
632 The actually executed code for
633
634         $a=$b;
635         Something else which does not modify $a or $b....
636         ++$a;
637
638 may be
639
640         $a=$b;
641         Something else which does not modify $a or $b....
642         $a = $a->clone(undef,"");
643         $a->incr(undef,"");
644
645 if $b was mathemagical, and C<'++'> was overloaded with C<\&incr>,
646 C<'='> was overloaded with C<\&clone>.
647
648 =back
649
650 Same behaviour is triggered by C<$b = $a++>, which is consider a synonym for
651 C<$b = $a; ++$a>.
652
653 =head1 MAGIC AUTOGENERATION
654
655 If a method for an operation is not found, and the value for  C<"fallback"> is
656 TRUE or undefined, Perl tries to autogenerate a substitute method for
657 the missing operation based on the defined operations.  Autogenerated method
658 substitutions are possible for the following operations:
659
660 =over 16
661
662 =item I<Assignment forms of arithmetic operations>
663
664 C<$a+=$b> can use the method for C<"+"> if the method for C<"+=">
665 is not defined.
666
667 =item I<Conversion operations>
668
669 String, numeric, and boolean conversion are calculated in terms of one
670 another if not all of them are defined.
671
672 =item I<Increment and decrement>
673
674 The C<++$a> operation can be expressed in terms of C<$a+=1> or C<$a+1>,
675 and C<$a--> in terms of C<$a-=1> and C<$a-1>.
676
677 =item C<abs($a)>
678
679 can be expressed in terms of C<$aE<lt>0> and C<-$a> (or C<0-$a>).
680
681 =item I<Unary minus>
682
683 can be expressed in terms of subtraction.
684
685 =item I<Negation>
686
687 C<!> and C<not> can be expressed in terms of boolean conversion, or
688 string or numerical conversion.
689
690 =item I<Concatenation>
691
692 can be expressed in terms of string conversion.
693
694 =item I<Comparison operations>
695
696 can be expressed in terms of its "spaceship" counterpart: either
697 C<E<lt>=E<gt>> or C<cmp>:
698
699     <, >, <=, >=, ==, !=        in terms of <=>
700     lt, gt, le, ge, eq, ne      in terms of cmp
701
702 =item I<Iterator>
703
704     <>                          in terms of builtin operations
705
706 =item I<Dereferencing>
707
708     ${} @{} %{} &{} *{}         in terms of builtin operations
709
710 =item I<Copy operator>
711
712 can be expressed in terms of an assignment to the dereferenced value, if this
713 value is a scalar and not a reference, or simply a reference assignment
714 otherwise.
715
716 =back
717
718 =head1 Minimal set of overloaded operations
719
720 Since some operations can be automatically generated from others, there is
721 a minimal set of operations that need to be overloaded in order to have
722 the complete set of overloaded operations at one's disposal.
723 Of course, the autogenerated operations may not do exactly what the user
724 expects. See L<MAGIC AUTOGENERATION> above. The minimal set is:
725
726     + - * / % ** << >> x
727     <=> cmp
728     & | ^ ~
729     atan2 cos sin exp log sqrt int
730
731 Additionally, you need to define at least one of string, boolean or
732 numeric conversions because any one can be used to emulate the others.
733 The string conversion can also be used to emulate concatenation.
734
735 =head1 Losing overloading
736
737 The restriction for the comparison operation is that even if, for example,
738 `C<cmp>' should return a blessed reference, the autogenerated `C<lt>'
739 function will produce only a standard logical value based on the
740 numerical value of the result of `C<cmp>'.  In particular, a working
741 numeric conversion is needed in this case (possibly expressed in terms of
742 other conversions).
743
744 Similarly, C<.=>  and C<x=> operators lose their mathemagical properties
745 if the string conversion substitution is applied.
746
747 When you chop() a mathemagical object it is promoted to a string and its
748 mathemagical properties are lost.  The same can happen with other
749 operations as well.
750
751 =head1 Run-time Overloading
752
753 Since all C<use> directives are executed at compile-time, the only way to
754 change overloading during run-time is to
755
756     eval 'use overload "+" => \&addmethod';
757
758 You can also use
759
760     eval 'no overload "+", "--", "<="';
761
762 though the use of these constructs during run-time is questionable.
763
764 =head1 Public functions
765
766 Package C<overload.pm> provides the following public functions:
767
768 =over 5
769
770 =item overload::StrVal(arg)
771
772 Gives string value of C<arg> as in absence of stringify overloading. If you
773 are using this to get the address of a reference (useful for checking if two
774 references point to the same thing) then you may be better off using
775 C<Scalar::Util::refaddr()>, which is faster.
776
777 =item overload::Overloaded(arg)
778
779 Returns true if C<arg> is subject to overloading of some operations.
780
781 =item overload::Method(obj,op)
782
783 Returns C<undef> or a reference to the method that implements C<op>.
784
785 =back
786
787 =head1 Overloading constants
788
789 For some applications, the Perl parser mangles constants too much.
790 It is possible to hook into this process via C<overload::constant()>
791 and C<overload::remove_constant()> functions.
792
793 These functions take a hash as an argument.  The recognized keys of this hash
794 are:
795
796 =over 8
797
798 =item integer
799
800 to overload integer constants,
801
802 =item float
803
804 to overload floating point constants,
805
806 =item binary
807
808 to overload octal and hexadecimal constants,
809
810 =item q
811
812 to overload C<q>-quoted strings, constant pieces of C<qq>- and C<qx>-quoted
813 strings and here-documents,
814
815 =item qr
816
817 to overload constant pieces of regular expressions.
818
819 =back
820
821 The corresponding values are references to functions which take three arguments:
822 the first one is the I<initial> string form of the constant, the second one
823 is how Perl interprets this constant, the third one is how the constant is used.
824 Note that the initial string form does not
825 contain string delimiters, and has backslashes in backslash-delimiter
826 combinations stripped (thus the value of delimiter is not relevant for
827 processing of this string).  The return value of this function is how this
828 constant is going to be interpreted by Perl.  The third argument is undefined
829 unless for overloaded C<q>- and C<qr>- constants, it is C<q> in single-quote
830 context (comes from strings, regular expressions, and single-quote HERE
831 documents), it is C<tr> for arguments of C<tr>/C<y> operators,
832 it is C<s> for right-hand side of C<s>-operator, and it is C<qq> otherwise.
833
834 Since an expression C<"ab$cd,,"> is just a shortcut for C<'ab' . $cd . ',,'>,
835 it is expected that overloaded constant strings are equipped with reasonable
836 overloaded catenation operator, otherwise absurd results will result.
837 Similarly, negative numbers are considered as negations of positive constants.
838
839 Note that it is probably meaningless to call the functions overload::constant()
840 and overload::remove_constant() from anywhere but import() and unimport() methods.
841 From these methods they may be called as
842
843         sub import {
844           shift;
845           return unless @_;
846           die "unknown import: @_" unless @_ == 1 and $_[0] eq ':constant';
847           overload::constant integer => sub {Math::BigInt->new(shift)};
848         }
849
850 =head1 IMPLEMENTATION
851
852 What follows is subject to change RSN.
853
854 The table of methods for all operations is cached in magic for the
855 symbol table hash for the package.  The cache is invalidated during
856 processing of C<use overload>, C<no overload>, new function
857 definitions, and changes in @ISA. However, this invalidation remains
858 unprocessed until the next C<bless>ing into the package. Hence if you
859 want to change overloading structure dynamically, you'll need an
860 additional (fake) C<bless>ing to update the table.
861
862 (Every SVish thing has a magic queue, and magic is an entry in that
863 queue.  This is how a single variable may participate in multiple
864 forms of magic simultaneously.  For instance, environment variables
865 regularly have two forms at once: their %ENV magic and their taint
866 magic. However, the magic which implements overloading is applied to
867 the stashes, which are rarely used directly, thus should not slow down
868 Perl.)
869
870 If an object belongs to a package using overload, it carries a special
871 flag.  Thus the only speed penalty during arithmetic operations without
872 overloading is the checking of this flag.
873
874 In fact, if C<use overload> is not present, there is almost no overhead
875 for overloadable operations, so most programs should not suffer
876 measurable performance penalties.  A considerable effort was made to
877 minimize the overhead when overload is used in some package, but the
878 arguments in question do not belong to packages using overload.  When
879 in doubt, test your speed with C<use overload> and without it.  So far
880 there have been no reports of substantial speed degradation if Perl is
881 compiled with optimization turned on.
882
883 There is no size penalty for data if overload is not used. The only
884 size penalty if overload is used in some package is that I<all> the
885 packages acquire a magic during the next C<bless>ing into the
886 package. This magic is three-words-long for packages without
887 overloading, and carries the cache table if the package is overloaded.
888
889 Copying (C<$a=$b>) is shallow; however, a one-level-deep copying is
890 carried out before any operation that can imply an assignment to the
891 object $a (or $b) refers to, like C<$a++>.  You can override this
892 behavior by defining your own copy constructor (see L<"Copy Constructor">).
893
894 It is expected that arguments to methods that are not explicitly supposed
895 to be changed are constant (but this is not enforced).
896
897 =head1 Metaphor clash
898
899 One may wonder why the semantic of overloaded C<=> is so counter intuitive.
900 If it I<looks> counter intuitive to you, you are subject to a metaphor
901 clash.
902
903 Here is a Perl object metaphor:
904
905 I<  object is a reference to blessed data>
906
907 and an arithmetic metaphor:
908
909 I<  object is a thing by itself>.
910
911 The I<main> problem of overloading C<=> is the fact that these metaphors
912 imply different actions on the assignment C<$a = $b> if $a and $b are
913 objects.  Perl-think implies that $a becomes a reference to whatever
914 $b was referencing.  Arithmetic-think implies that the value of "object"
915 $a is changed to become the value of the object $b, preserving the fact
916 that $a and $b are separate entities.
917
918 The difference is not relevant in the absence of mutators.  After
919 a Perl-way assignment an operation which mutates the data referenced by $a
920 would change the data referenced by $b too.  Effectively, after
921 C<$a = $b> values of $a and $b become I<indistinguishable>.
922
923 On the other hand, anyone who has used algebraic notation knows the
924 expressive power of the arithmetic metaphor.  Overloading works hard
925 to enable this metaphor while preserving the Perlian way as far as
926 possible.  Since it is not possible to freely mix two contradicting
927 metaphors, overloading allows the arithmetic way to write things I<as
928 far as all the mutators are called via overloaded access only>.  The
929 way it is done is described in L<Copy Constructor>.
930
931 If some mutator methods are directly applied to the overloaded values,
932 one may need to I<explicitly unlink> other values which references the
933 same value:
934
935     $a = Data->new(23);
936     ...
937     $b = $a;            # $b is "linked" to $a
938     ...
939     $a = $a->clone;     # Unlink $b from $a
940     $a->increment_by(4);
941
942 Note that overloaded access makes this transparent:
943
944     $a = Data->new(23);
945     $b = $a;            # $b is "linked" to $a
946     $a += 4;            # would unlink $b automagically
947
948 However, it would not make
949
950     $a = Data->new(23);
951     $a = 4;             # Now $a is a plain 4, not 'Data'
952
953 preserve "objectness" of $a.  But Perl I<has> a way to make assignments
954 to an object do whatever you want.  It is just not the overload, but
955 tie()ing interface (see L<perlfunc/tie>).  Adding a FETCH() method
956 which returns the object itself, and STORE() method which changes the
957 value of the object, one can reproduce the arithmetic metaphor in its
958 completeness, at least for variables which were tie()d from the start.
959
960 (Note that a workaround for a bug may be needed, see L<"BUGS">.)
961
962 =head1 Cookbook
963
964 Please add examples to what follows!
965
966 =head2 Two-face scalars
967
968 Put this in F<two_face.pm> in your Perl library directory:
969
970   package two_face;             # Scalars with separate string and
971                                 # numeric values.
972   sub new { my $p = shift; bless [@_], $p }
973   use overload '""' => \&str, '0+' => \&num, fallback => 1;
974   sub num {shift->[1]}
975   sub str {shift->[0]}
976
977 Use it as follows:
978
979   require two_face;
980   my $seven = two_face->new("vii", 7);
981   printf "seven=$seven, seven=%d, eight=%d\n", $seven, $seven+1;
982   print "seven contains `i'\n" if $seven =~ /i/;
983
984 (The second line creates a scalar which has both a string value, and a
985 numeric value.)  This prints:
986
987   seven=vii, seven=7, eight=8
988   seven contains `i'
989
990 =head2 Two-face references
991
992 Suppose you want to create an object which is accessible as both an
993 array reference and a hash reference.
994
995   package two_refs;
996   use overload '%{}' => \&gethash, '@{}' => sub { $ {shift()} };
997   sub new {
998     my $p = shift;
999     bless \ [@_], $p;
1000   }
1001   sub gethash {
1002     my %h;
1003     my $self = shift;
1004     tie %h, ref $self, $self;
1005     \%h;
1006   }
1007
1008   sub TIEHASH { my $p = shift; bless \ shift, $p }
1009   my %fields;
1010   my $i = 0;
1011   $fields{$_} = $i++ foreach qw{zero one two three};
1012   sub STORE {
1013     my $self = ${shift()};
1014     my $key = $fields{shift()};
1015     defined $key or die "Out of band access";
1016     $$self->[$key] = shift;
1017   }
1018   sub FETCH {
1019     my $self = ${shift()};
1020     my $key = $fields{shift()};
1021     defined $key or die "Out of band access";
1022     $$self->[$key];
1023   }
1024
1025 Now one can access an object using both the array and hash syntax:
1026
1027   my $bar = two_refs->new(3,4,5,6);
1028   $bar->[2] = 11;
1029   $bar->{two} == 11 or die 'bad hash fetch';
1030
1031 Note several important features of this example.  First of all, the
1032 I<actual> type of $bar is a scalar reference, and we do not overload
1033 the scalar dereference.  Thus we can get the I<actual> non-overloaded
1034 contents of $bar by just using C<$$bar> (what we do in functions which
1035 overload dereference).  Similarly, the object returned by the
1036 TIEHASH() method is a scalar reference.
1037
1038 Second, we create a new tied hash each time the hash syntax is used.
1039 This allows us not to worry about a possibility of a reference loop,
1040 which would lead to a memory leak.
1041
1042 Both these problems can be cured.  Say, if we want to overload hash
1043 dereference on a reference to an object which is I<implemented> as a
1044 hash itself, the only problem one has to circumvent is how to access
1045 this I<actual> hash (as opposed to the I<virtual> hash exhibited by the
1046 overloaded dereference operator).  Here is one possible fetching routine:
1047
1048   sub access_hash {
1049     my ($self, $key) = (shift, shift);
1050     my $class = ref $self;
1051     bless $self, 'overload::dummy'; # Disable overloading of %{}
1052     my $out = $self->{$key};
1053     bless $self, $class;        # Restore overloading
1054     $out;
1055   }
1056
1057 To remove creation of the tied hash on each access, one may an extra
1058 level of indirection which allows a non-circular structure of references:
1059
1060   package two_refs1;
1061   use overload '%{}' => sub { ${shift()}->[1] },
1062                '@{}' => sub { ${shift()}->[0] };
1063   sub new {
1064     my $p = shift;
1065     my $a = [@_];
1066     my %h;
1067     tie %h, $p, $a;
1068     bless \ [$a, \%h], $p;
1069   }
1070   sub gethash {
1071     my %h;
1072     my $self = shift;
1073     tie %h, ref $self, $self;
1074     \%h;
1075   }
1076
1077   sub TIEHASH { my $p = shift; bless \ shift, $p }
1078   my %fields;
1079   my $i = 0;
1080   $fields{$_} = $i++ foreach qw{zero one two three};
1081   sub STORE {
1082     my $a = ${shift()};
1083     my $key = $fields{shift()};
1084     defined $key or die "Out of band access";
1085     $a->[$key] = shift;
1086   }
1087   sub FETCH {
1088     my $a = ${shift()};
1089     my $key = $fields{shift()};
1090     defined $key or die "Out of band access";
1091     $a->[$key];
1092   }
1093
1094 Now if $baz is overloaded like this, then C<$baz> is a reference to a
1095 reference to the intermediate array, which keeps a reference to an
1096 actual array, and the access hash.  The tie()ing object for the access
1097 hash is a reference to a reference to the actual array, so
1098
1099 =over
1100
1101 =item *
1102
1103 There are no loops of references.
1104
1105 =item *
1106
1107 Both "objects" which are blessed into the class C<two_refs1> are
1108 references to a reference to an array, thus references to a I<scalar>.
1109 Thus the accessor expression C<$$foo-E<gt>[$ind]> involves no
1110 overloaded operations.
1111
1112 =back
1113
1114 =head2 Symbolic calculator
1115
1116 Put this in F<symbolic.pm> in your Perl library directory:
1117
1118   package symbolic;             # Primitive symbolic calculator
1119   use overload nomethod => \&wrap;
1120
1121   sub new { shift; bless ['n', @_] }
1122   sub wrap {
1123     my ($obj, $other, $inv, $meth) = @_;
1124     ($obj, $other) = ($other, $obj) if $inv;
1125     bless [$meth, $obj, $other];
1126   }
1127
1128 This module is very unusual as overloaded modules go: it does not
1129 provide any usual overloaded operators, instead it provides the L<Last
1130 Resort> operator C<nomethod>.  In this example the corresponding
1131 subroutine returns an object which encapsulates operations done over
1132 the objects: C<< symbolic->new(3) >> contains C<['n', 3]>, C<< 2 +
1133 symbolic->new(3) >> contains C<['+', 2, ['n', 3]]>.
1134
1135 Here is an example of the script which "calculates" the side of
1136 circumscribed octagon using the above package:
1137
1138   require symbolic;
1139   my $iter = 1;                 # 2**($iter+2) = 8
1140   my $side = symbolic->new(1);
1141   my $cnt = $iter;
1142
1143   while ($cnt--) {
1144     $side = (sqrt(1 + $side**2) - 1)/$side;
1145   }
1146   print "OK\n";
1147
1148 The value of $side is
1149
1150   ['/', ['-', ['sqrt', ['+', 1, ['**', ['n', 1], 2]],
1151                        undef], 1], ['n', 1]]
1152
1153 Note that while we obtained this value using a nice little script,
1154 there is no simple way to I<use> this value.  In fact this value may
1155 be inspected in debugger (see L<perldebug>), but only if
1156 C<bareStringify> B<O>ption is set, and not via C<p> command.
1157
1158 If one attempts to print this value, then the overloaded operator
1159 C<""> will be called, which will call C<nomethod> operator.  The
1160 result of this operator will be stringified again, but this result is
1161 again of type C<symbolic>, which will lead to an infinite loop.
1162
1163 Add a pretty-printer method to the module F<symbolic.pm>:
1164
1165   sub pretty {
1166     my ($meth, $a, $b) = @{+shift};
1167     $a = 'u' unless defined $a;
1168     $b = 'u' unless defined $b;
1169     $a = $a->pretty if ref $a;
1170     $b = $b->pretty if ref $b;
1171     "[$meth $a $b]";
1172   }
1173
1174 Now one can finish the script by
1175
1176   print "side = ", $side->pretty, "\n";
1177
1178 The method C<pretty> is doing object-to-string conversion, so it
1179 is natural to overload the operator C<""> using this method.  However,
1180 inside such a method it is not necessary to pretty-print the
1181 I<components> $a and $b of an object.  In the above subroutine
1182 C<"[$meth $a $b]"> is a catenation of some strings and components $a
1183 and $b.  If these components use overloading, the catenation operator
1184 will look for an overloaded operator C<.>; if not present, it will
1185 look for an overloaded operator C<"">.  Thus it is enough to use
1186
1187   use overload nomethod => \&wrap, '""' => \&str;
1188   sub str {
1189     my ($meth, $a, $b) = @{+shift};
1190     $a = 'u' unless defined $a;
1191     $b = 'u' unless defined $b;
1192     "[$meth $a $b]";
1193   }
1194
1195 Now one can change the last line of the script to
1196
1197   print "side = $side\n";
1198
1199 which outputs
1200
1201   side = [/ [- [sqrt [+ 1 [** [n 1 u] 2]] u] 1] [n 1 u]]
1202
1203 and one can inspect the value in debugger using all the possible
1204 methods.
1205
1206 Something is still amiss: consider the loop variable $cnt of the
1207 script.  It was a number, not an object.  We cannot make this value of
1208 type C<symbolic>, since then the loop will not terminate.
1209
1210 Indeed, to terminate the cycle, the $cnt should become false.
1211 However, the operator C<bool> for checking falsity is overloaded (this
1212 time via overloaded C<"">), and returns a long string, thus any object
1213 of type C<symbolic> is true.  To overcome this, we need a way to
1214 compare an object to 0.  In fact, it is easier to write a numeric
1215 conversion routine.
1216
1217 Here is the text of F<symbolic.pm> with such a routine added (and
1218 slightly modified str()):
1219
1220   package symbolic;             # Primitive symbolic calculator
1221   use overload
1222     nomethod => \&wrap, '""' => \&str, '0+' => \&num;
1223
1224   sub new { shift; bless ['n', @_] }
1225   sub wrap {
1226     my ($obj, $other, $inv, $meth) = @_;
1227     ($obj, $other) = ($other, $obj) if $inv;
1228     bless [$meth, $obj, $other];
1229   }
1230   sub str {
1231     my ($meth, $a, $b) = @{+shift};
1232     $a = 'u' unless defined $a;
1233     if (defined $b) {
1234       "[$meth $a $b]";
1235     } else {
1236       "[$meth $a]";
1237     }
1238   }
1239   my %subr = ( n => sub {$_[0]},
1240                sqrt => sub {sqrt $_[0]},
1241                '-' => sub {shift() - shift()},
1242                '+' => sub {shift() + shift()},
1243                '/' => sub {shift() / shift()},
1244                '*' => sub {shift() * shift()},
1245                '**' => sub {shift() ** shift()},
1246              );
1247   sub num {
1248     my ($meth, $a, $b) = @{+shift};
1249     my $subr = $subr{$meth}
1250       or die "Do not know how to ($meth) in symbolic";
1251     $a = $a->num if ref $a eq __PACKAGE__;
1252     $b = $b->num if ref $b eq __PACKAGE__;
1253     $subr->($a,$b);
1254   }
1255
1256 All the work of numeric conversion is done in %subr and num().  Of
1257 course, %subr is not complete, it contains only operators used in the
1258 example below.  Here is the extra-credit question: why do we need an
1259 explicit recursion in num()?  (Answer is at the end of this section.)
1260
1261 Use this module like this:
1262
1263   require symbolic;
1264   my $iter = symbolic->new(2);  # 16-gon
1265   my $side = symbolic->new(1);
1266   my $cnt = $iter;
1267
1268   while ($cnt) {
1269     $cnt = $cnt - 1;            # Mutator `--' not implemented
1270     $side = (sqrt(1 + $side**2) - 1)/$side;
1271   }
1272   printf "%s=%f\n", $side, $side;
1273   printf "pi=%f\n", $side*(2**($iter+2));
1274
1275 It prints (without so many line breaks)
1276
1277   [/ [- [sqrt [+ 1 [** [/ [- [sqrt [+ 1 [** [n 1] 2]]] 1]
1278                           [n 1]] 2]]] 1]
1279      [/ [- [sqrt [+ 1 [** [n 1] 2]]] 1] [n 1]]]=0.198912
1280   pi=3.182598
1281
1282 The above module is very primitive.  It does not implement
1283 mutator methods (C<++>, C<-=> and so on), does not do deep copying
1284 (not required without mutators!), and implements only those arithmetic
1285 operations which are used in the example.
1286
1287 To implement most arithmetic operations is easy; one should just use
1288 the tables of operations, and change the code which fills %subr to
1289
1290   my %subr = ( 'n' => sub {$_[0]} );
1291   foreach my $op (split " ", $overload::ops{with_assign}) {
1292     $subr{$op} = $subr{"$op="} = eval "sub {shift() $op shift()}";
1293   }
1294   my @bins = qw(binary 3way_comparison num_comparison str_comparison);
1295   foreach my $op (split " ", "@overload::ops{ @bins }") {
1296     $subr{$op} = eval "sub {shift() $op shift()}";
1297   }
1298   foreach my $op (split " ", "@overload::ops{qw(unary func)}") {
1299     print "defining `$op'\n";
1300     $subr{$op} = eval "sub {$op shift()}";
1301   }
1302
1303 Due to L<Calling Conventions for Mutators>, we do not need anything
1304 special to make C<+=> and friends work, except filling C<+=> entry of
1305 %subr, and defining a copy constructor (needed since Perl has no
1306 way to know that the implementation of C<'+='> does not mutate
1307 the argument, compare L<Copy Constructor>).
1308
1309 To implement a copy constructor, add C<< '=' => \&cpy >> to C<use overload>
1310 line, and code (this code assumes that mutators change things one level
1311 deep only, so recursive copying is not needed):
1312
1313   sub cpy {
1314     my $self = shift;
1315     bless [@$self], ref $self;
1316   }
1317
1318 To make C<++> and C<--> work, we need to implement actual mutators,
1319 either directly, or in C<nomethod>.  We continue to do things inside
1320 C<nomethod>, thus add
1321
1322     if ($meth eq '++' or $meth eq '--') {
1323       @$obj = ($meth, (bless [@$obj]), 1); # Avoid circular reference
1324       return $obj;
1325     }
1326
1327 after the first line of wrap().  This is not a most effective
1328 implementation, one may consider
1329
1330   sub inc { $_[0] = bless ['++', shift, 1]; }
1331
1332 instead.
1333
1334 As a final remark, note that one can fill %subr by
1335
1336   my %subr = ( 'n' => sub {$_[0]} );
1337   foreach my $op (split " ", $overload::ops{with_assign}) {
1338     $subr{$op} = $subr{"$op="} = eval "sub {shift() $op shift()}";
1339   }
1340   my @bins = qw(binary 3way_comparison num_comparison str_comparison);
1341   foreach my $op (split " ", "@overload::ops{ @bins }") {
1342     $subr{$op} = eval "sub {shift() $op shift()}";
1343   }
1344   foreach my $op (split " ", "@overload::ops{qw(unary func)}") {
1345     $subr{$op} = eval "sub {$op shift()}";
1346   }
1347   $subr{'++'} = $subr{'+'};
1348   $subr{'--'} = $subr{'-'};
1349
1350 This finishes implementation of a primitive symbolic calculator in
1351 50 lines of Perl code.  Since the numeric values of subexpressions
1352 are not cached, the calculator is very slow.
1353
1354 Here is the answer for the exercise: In the case of str(), we need no
1355 explicit recursion since the overloaded C<.>-operator will fall back
1356 to an existing overloaded operator C<"">.  Overloaded arithmetic
1357 operators I<do not> fall back to numeric conversion if C<fallback> is
1358 not explicitly requested.  Thus without an explicit recursion num()
1359 would convert C<['+', $a, $b]> to C<$a + $b>, which would just rebuild
1360 the argument of num().
1361
1362 If you wonder why defaults for conversion are different for str() and
1363 num(), note how easy it was to write the symbolic calculator.  This
1364 simplicity is due to an appropriate choice of defaults.  One extra
1365 note: due to the explicit recursion num() is more fragile than sym():
1366 we need to explicitly check for the type of $a and $b.  If components
1367 $a and $b happen to be of some related type, this may lead to problems.
1368
1369 =head2 I<Really> symbolic calculator
1370
1371 One may wonder why we call the above calculator symbolic.  The reason
1372 is that the actual calculation of the value of expression is postponed
1373 until the value is I<used>.
1374
1375 To see it in action, add a method
1376
1377   sub STORE {
1378     my $obj = shift;
1379     $#$obj = 1;
1380     @$obj->[0,1] = ('=', shift);
1381   }
1382
1383 to the package C<symbolic>.  After this change one can do
1384
1385   my $a = symbolic->new(3);
1386   my $b = symbolic->new(4);
1387   my $c = sqrt($a**2 + $b**2);
1388
1389 and the numeric value of $c becomes 5.  However, after calling
1390
1391   $a->STORE(12);  $b->STORE(5);
1392
1393 the numeric value of $c becomes 13.  There is no doubt now that the module
1394 symbolic provides a I<symbolic> calculator indeed.
1395
1396 To hide the rough edges under the hood, provide a tie()d interface to the
1397 package C<symbolic> (compare with L<Metaphor clash>).  Add methods
1398
1399   sub TIESCALAR { my $pack = shift; $pack->new(@_) }
1400   sub FETCH { shift }
1401   sub nop {  }          # Around a bug
1402
1403 (the bug is described in L<"BUGS">).  One can use this new interface as
1404
1405   tie $a, 'symbolic', 3;
1406   tie $b, 'symbolic', 4;
1407   $a->nop;  $b->nop;    # Around a bug
1408
1409   my $c = sqrt($a**2 + $b**2);
1410
1411 Now numeric value of $c is 5.  After C<$a = 12; $b = 5> the numeric value
1412 of $c becomes 13.  To insulate the user of the module add a method
1413
1414   sub vars { my $p = shift; tie($_, $p), $_->nop foreach @_; }
1415
1416 Now
1417
1418   my ($a, $b);
1419   symbolic->vars($a, $b);
1420   my $c = sqrt($a**2 + $b**2);
1421
1422   $a = 3; $b = 4;
1423   printf "c5  %s=%f\n", $c, $c;
1424
1425   $a = 12; $b = 5;
1426   printf "c13  %s=%f\n", $c, $c;
1427
1428 shows that the numeric value of $c follows changes to the values of $a
1429 and $b.
1430
1431 =head1 AUTHOR
1432
1433 Ilya Zakharevich E<lt>F<ilya@math.mps.ohio-state.edu>E<gt>.
1434
1435 =head1 SEE ALSO
1436
1437 The L<overloading> pragma can be used to enable or disable overloaded
1438 operations within a lexical scope.
1439
1440 =head1 DIAGNOSTICS
1441
1442 When Perl is run with the B<-Do> switch or its equivalent, overloading
1443 induces diagnostic messages.
1444
1445 Using the C<m> command of Perl debugger (see L<perldebug>) one can
1446 deduce which operations are overloaded (and which ancestor triggers
1447 this overloading). Say, if C<eq> is overloaded, then the method C<(eq>
1448 is shown by debugger. The method C<()> corresponds to the C<fallback>
1449 key (in fact a presence of this method shows that this package has
1450 overloading enabled, and it is what is used by the C<Overloaded>
1451 function of module C<overload>).
1452
1453 The module might issue the following warnings:
1454
1455 =over 4
1456
1457 =item Odd number of arguments for overload::constant
1458
1459 (W) The call to overload::constant contained an odd number of arguments.
1460 The arguments should come in pairs.
1461
1462 =item `%s' is not an overloadable type
1463
1464 (W) You tried to overload a constant type the overload package is unaware of.
1465
1466 =item `%s' is not a code reference
1467
1468 (W) The second (fourth, sixth, ...) argument of overload::constant needs
1469 to be a code reference. Either an anonymous subroutine, or a reference
1470 to a subroutine.
1471
1472 =back
1473
1474 =head1 BUGS
1475
1476 Because it is used for overloading, the per-package hash %OVERLOAD now
1477 has a special meaning in Perl. The symbol table is filled with names
1478 looking like line-noise.
1479
1480 For the purpose of inheritance every overloaded package behaves as if
1481 C<fallback> is present (possibly undefined). This may create
1482 interesting effects if some package is not overloaded, but inherits
1483 from two overloaded packages.
1484
1485 Relation between overloading and tie()ing is broken.  Overloading is
1486 triggered or not basing on the I<previous> class of tie()d value.
1487
1488 This happens because the presence of overloading is checked too early,
1489 before any tie()d access is attempted.  If the FETCH()ed class of the
1490 tie()d value does not change, a simple workaround is to access the value
1491 immediately after tie()ing, so that after this call the I<previous> class
1492 coincides with the current one.
1493
1494 B<Needed:> a way to fix this without a speed penalty.
1495
1496 Barewords are not covered by overloaded string constants.
1497
1498 This document is confusing.  There are grammos and misleading language
1499 used in places.  It would seem a total rewrite is needed.
1500
1501 =cut
1502