Avoid a possible race condition where a parallel make might
[perl.git] / pod / perlvar.pod
1 =head1 NAME
2
3 perlvar - Perl predefined variables
4
5 =head1 DESCRIPTION
6
7 =head2 Predefined Names
8
9 The following names have special meaning to Perl.  Most 
10 punctuation names have reasonable mnemonics, or analogs in the
11 shells.  Nevertheless, if you wish to use long variable names,
12 you need only say
13
14     use English;
15
16 at the top of your program. This aliases all the short names to the long
17 names in the current package. Some even have medium names, generally
18 borrowed from B<awk>. In general, it's best to use the
19
20     use English '-no_match_vars';
21
22 invocation if you don't need $PREMATCH, $MATCH, or $POSTMATCH, as it avoids
23 a certain performance hit with the use of regular expressions. See
24 L<English>.
25
26 Variables that depend on the currently selected filehandle may be set by
27 calling an appropriate object method on the IO::Handle object, although
28 this is less efficient than using the regular built-in variables. (Summary
29 lines below for this contain the word HANDLE.) First you must say
30
31     use IO::Handle;
32
33 after which you may use either
34
35     method HANDLE EXPR
36
37 or more safely,
38
39     HANDLE->method(EXPR)
40
41 Each method returns the old value of the IO::Handle attribute.
42 The methods each take an optional EXPR, which, if supplied, specifies the
43 new value for the IO::Handle attribute in question.  If not supplied,
44 most methods do nothing to the current value--except for
45 autoflush(), which will assume a 1 for you, just to be different.
46
47 Because loading in the IO::Handle class is an expensive operation, you should
48 learn how to use the regular built-in variables.
49
50 A few of these variables are considered "read-only".  This means that if
51 you try to assign to this variable, either directly or indirectly through
52 a reference, you'll raise a run-time exception.
53
54 You should be very careful when modifying the default values of most
55 special variables described in this document. In most cases you want
56 to localize these variables before changing them, since if you don't,
57 the change may affect other modules which rely on the default values
58 of the special variables that you have changed. This is one of the
59 correct ways to read the whole file at once:
60
61     open my $fh, "<", "foo" or die $!;
62     local $/; # enable localized slurp mode
63     my $content = <$fh>;
64     close $fh;
65
66 But the following code is quite bad:
67
68     open my $fh, "<", "foo" or die $!;
69     undef $/; # enable slurp mode
70     my $content = <$fh>;
71     close $fh;
72
73 since some other module, may want to read data from some file in the
74 default "line mode", so if the code we have just presented has been
75 executed, the global value of C<$/> is now changed for any other code
76 running inside the same Perl interpreter.
77
78 Usually when a variable is localized you want to make sure that this
79 change affects the shortest scope possible. So unless you are already
80 inside some short C<{}> block, you should create one yourself. For
81 example:
82
83     my $content = '';
84     open my $fh, "<", "foo" or die $!;
85     {
86         local $/;
87         $content = <$fh>;
88     }
89     close $fh;
90
91 Here is an example of how your own code can go broken:
92
93     for (1..5){
94         nasty_break();
95         print "$_ ";
96     }
97     sub nasty_break {
98         $_ = 5;
99         # do something with $_
100     }
101
102 You probably expect this code to print:
103
104     1 2 3 4 5
105
106 but instead you get:
107
108     5 5 5 5 5
109
110 Why? Because nasty_break() modifies C<$_> without localizing it
111 first. The fix is to add local():
112
113         local $_ = 5;
114
115 It's easy to notice the problem in such a short example, but in more
116 complicated code you are looking for trouble if you don't localize
117 changes to the special variables.
118
119 The following list is ordered by scalar variables first, then the
120 arrays, then the hashes.
121
122 =over 8
123
124 =item $ARG
125
126 =item $_
127 X<$_> X<$ARG>
128
129 The default input and pattern-searching space.  The following pairs are
130 equivalent:
131
132     while (<>) {...}    # equivalent only in while!
133     while (defined($_ = <>)) {...}
134
135     /^Subject:/
136     $_ =~ /^Subject:/
137
138     tr/a-z/A-Z/
139     $_ =~ tr/a-z/A-Z/
140
141     chomp
142     chomp($_)
143
144 Here are the places where Perl will assume $_ even if you
145 don't use it:
146
147 =over 3
148
149 =item *
150
151 The following functions:
152
153 abs, alarm, chomp, chop, chr, chroot, cos, defined, eval, exp, glob,
154 hex, int, lc, lcfirst, length, log, lstat, mkdir, oct, ord, pos, print,
155 quotemeta, readlink, readpipe, ref, require, reverse (in scalar context only),
156 rmdir, sin, split (on its second argument), sqrt, stat, study, uc, ucfirst, 
157 unlink, unpack.
158
159 =item *
160
161 All file tests (C<-f>, C<-d>) except for C<-t>, which defaults to STDIN.
162 See L<perlfunc/-X>
163
164
165 =item *
166
167 The pattern matching operations C<m//>, C<s///> and C<tr///> (aka C<y///>)
168 when used without an C<=~> operator.
169
170 =item *
171
172 The default iterator variable in a C<foreach> loop if no other
173 variable is supplied.
174
175 =item *
176
177 The implicit iterator variable in the grep() and map() functions.
178
179 =item *
180
181 The implicit variable of given().
182
183 =item *
184
185 The default place to put an input record when a C<< <FH> >>
186 operation's result is tested by itself as the sole criterion of a C<while>
187 test.  Outside a C<while> test, this will not happen.
188
189 =back
190
191 As C<$_> is a global variable, this may lead in some cases to unwanted
192 side-effects.  As of perl 5.9.1, you can now use a lexical version of
193 C<$_> by declaring it in a file or in a block with C<my>.  Moreover,
194 declaring C<our $_> restores the global C<$_> in the current scope.
195
196 (Mnemonic: underline is understood in certain operations.)
197
198 =back
199
200 =over 8
201
202 =item $a
203
204 =item $b
205 X<$a> X<$b>
206
207 Special package variables when using sort(), see L<perlfunc/sort>.
208 Because of this specialness $a and $b don't need to be declared
209 (using use vars, or our()) even when using the C<strict 'vars'> pragma.
210 Don't lexicalize them with C<my $a> or C<my $b> if you want to be
211 able to use them in the sort() comparison block or function.
212
213 =back
214
215 =over 8
216
217 =item $<I<digits>> ($1, $2, ...)
218 X<$1> X<$2> X<$3>
219
220 Contains the subpattern from the corresponding set of capturing
221 parentheses from the last successful pattern match, not counting patterns
222 matched in nested blocks that have been exited already.  (Mnemonic:
223 like \digits.)  These variables are all read-only and dynamically
224 scoped to the current BLOCK.
225
226 =item $MATCH
227
228 =item $&
229 X<$&> X<$MATCH>
230
231 The string matched by the last successful pattern match (not counting
232 any matches hidden within a BLOCK or eval() enclosed by the current
233 BLOCK).  (Mnemonic: like & in some editors.)  This variable is read-only
234 and dynamically scoped to the current BLOCK.
235
236 The use of this variable anywhere in a program imposes a considerable
237 performance penalty on all regular expression matches.  See L</BUGS>.
238
239 See L</@-> for a replacement.
240
241 =item ${^MATCH}
242 X<${^MATCH}>
243
244 This is similar to C<$&> (C<$MATCH>) except that it does not incur the
245 performance penalty associated with that variable, and is only guaranteed
246 to return a defined value when the pattern was compiled or executed with
247 the C</p> modifier.
248
249 =item $PREMATCH
250
251 =item $`
252 X<$`> X<$PREMATCH>
253
254 The string preceding whatever was matched by the last successful
255 pattern match (not counting any matches hidden within a BLOCK or eval
256 enclosed by the current BLOCK).  (Mnemonic: C<`> often precedes a quoted
257 string.)  This variable is read-only.
258
259 The use of this variable anywhere in a program imposes a considerable
260 performance penalty on all regular expression matches.  See L</BUGS>.
261
262 See L</@-> for a replacement.
263
264 =item ${^PREMATCH}
265 X<${^PREMATCH}>
266
267 This is similar to C<$`> ($PREMATCH) except that it does not incur the
268 performance penalty associated with that variable, and is only guaranteed
269 to return a defined value when the pattern was compiled or executed with
270 the C</p> modifier.
271
272 =item $POSTMATCH
273
274 =item $'
275 X<$'> X<$POSTMATCH>
276
277 The string following whatever was matched by the last successful
278 pattern match (not counting any matches hidden within a BLOCK or eval()
279 enclosed by the current BLOCK).  (Mnemonic: C<'> often follows a quoted
280 string.)  Example:
281
282     local $_ = 'abcdefghi';
283     /def/;
284     print "$`:$&:$'\n";         # prints abc:def:ghi
285
286 This variable is read-only and dynamically scoped to the current BLOCK.
287
288 The use of this variable anywhere in a program imposes a considerable
289 performance penalty on all regular expression matches.  See L</BUGS>.
290
291 See L</@-> for a replacement.
292
293 =item ${^POSTMATCH}
294 X<${^POSTMATCH}>
295
296 This is similar to C<$'> (C<$POSTMATCH>) except that it does not incur the
297 performance penalty associated with that variable, and is only guaranteed
298 to return a defined value when the pattern was compiled or executed with
299 the C</p> modifier.
300
301 =item $LAST_PAREN_MATCH
302
303 =item $+
304 X<$+> X<$LAST_PAREN_MATCH>
305
306 The text matched by the last bracket of the last successful search pattern.
307 This is useful if you don't know which one of a set of alternative patterns
308 matched. For example:
309
310     /Version: (.*)|Revision: (.*)/ && ($rev = $+);
311
312 (Mnemonic: be positive and forward looking.)
313 This variable is read-only and dynamically scoped to the current BLOCK.
314
315 =item $LAST_SUBMATCH_RESULT
316
317 =item $^N
318 X<$^N>
319
320 The text matched by the used group most-recently closed (i.e. the group
321 with the rightmost closing parenthesis) of the last successful search
322 pattern.  (Mnemonic: the (possibly) Nested parenthesis that most
323 recently closed.)
324
325 This is primarily used inside C<(?{...})> blocks for examining text
326 recently matched. For example, to effectively capture text to a variable
327 (in addition to C<$1>, C<$2>, etc.), replace C<(...)> with
328
329      (?:(...)(?{ $var = $^N }))
330
331 By setting and then using C<$var> in this way relieves you from having to
332 worry about exactly which numbered set of parentheses they are.
333
334 This variable is dynamically scoped to the current BLOCK.
335
336 =item @LAST_MATCH_END
337
338 =item @+
339 X<@+> X<@LAST_MATCH_END>
340
341 This array holds the offsets of the ends of the last successful
342 submatches in the currently active dynamic scope.  C<$+[0]> is
343 the offset into the string of the end of the entire match.  This
344 is the same value as what the C<pos> function returns when called
345 on the variable that was matched against.  The I<n>th element
346 of this array holds the offset of the I<n>th submatch, so
347 C<$+[1]> is the offset past where $1 ends, C<$+[2]> the offset
348 past where $2 ends, and so on.  You can use C<$#+> to determine
349 how many subgroups were in the last successful match.  See the
350 examples given for the C<@-> variable.
351
352 =item %LAST_PAREN_MATCH
353
354 =item %+
355 X<%+>
356
357 Similar to C<@+>, the C<%+> hash allows access to the named capture
358 buffers, should they exist, in the last successful match in the
359 currently active dynamic scope.
360
361 For example, C<$+{foo}> is equivalent to C<$1> after the following match:
362
363   'foo' =~ /(?<foo>foo)/;
364
365 The keys of the C<%+> hash list only the names of buffers that have
366 captured (and that are thus associated to defined values).
367
368 The underlying behaviour of C<%+> is provided by the
369 L<Tie::Hash::NamedCapture> module.
370
371 B<Note:> C<%-> and C<%+> are tied views into a common internal hash
372 associated with the last successful regular expression. Therefore mixing
373 iterative access to them via C<each> may have unpredictable results.
374 Likewise, if the last successful match changes, then the results may be
375 surprising.
376
377 =item HANDLE->input_line_number(EXPR)
378
379 =item $INPUT_LINE_NUMBER
380
381 =item $NR
382
383 =item $.
384 X<$.> X<$NR> X<$INPUT_LINE_NUMBER> X<line number>
385
386 Current line number for the last filehandle accessed.
387
388 Each filehandle in Perl counts the number of lines that have been read
389 from it.  (Depending on the value of C<$/>, Perl's idea of what
390 constitutes a line may not match yours.)  When a line is read from a
391 filehandle (via readline() or C<< <> >>), or when tell() or seek() is
392 called on it, C<$.> becomes an alias to the line counter for that
393 filehandle.
394
395 You can adjust the counter by assigning to C<$.>, but this will not
396 actually move the seek pointer.  I<Localizing C<$.> will not localize
397 the filehandle's line count>.  Instead, it will localize perl's notion
398 of which filehandle C<$.> is currently aliased to.
399
400 C<$.> is reset when the filehandle is closed, but B<not> when an open
401 filehandle is reopened without an intervening close().  For more
402 details, see L<perlop/"IE<sol>O Operators">.  Because C<< <> >> never does
403 an explicit close, line numbers increase across ARGV files (but see
404 examples in L<perlfunc/eof>).
405
406 You can also use C<< HANDLE->input_line_number(EXPR) >> to access the
407 line counter for a given filehandle without having to worry about
408 which handle you last accessed.
409
410 (Mnemonic: many programs use "." to mean the current line number.)
411
412 =item IO::Handle->input_record_separator(EXPR)
413
414 =item $INPUT_RECORD_SEPARATOR
415
416 =item $RS
417
418 =item $/
419 X<$/> X<$RS> X<$INPUT_RECORD_SEPARATOR>
420
421 The input record separator, newline by default.  This 
422 influences Perl's idea of what a "line" is.  Works like B<awk>'s RS
423 variable, including treating empty lines as a terminator if set to
424 the null string.  (An empty line cannot contain any spaces
425 or tabs.)  You may set it to a multi-character string to match a
426 multi-character terminator, or to C<undef> to read through the end
427 of file.  Setting it to C<"\n\n"> means something slightly
428 different than setting to C<"">, if the file contains consecutive
429 empty lines.  Setting to C<""> will treat two or more consecutive
430 empty lines as a single empty line.  Setting to C<"\n\n"> will
431 blindly assume that the next input character belongs to the next
432 paragraph, even if it's a newline.  (Mnemonic: / delimits
433 line boundaries when quoting poetry.)
434
435     local $/;           # enable "slurp" mode
436     local $_ = <FH>;    # whole file now here
437     s/\n[ \t]+/ /g;
438
439 Remember: the value of C<$/> is a string, not a regex.  B<awk> has to be
440 better for something. :-)
441
442 Setting C<$/> to a reference to an integer, scalar containing an integer, or
443 scalar that's convertible to an integer will attempt to read records
444 instead of lines, with the maximum record size being the referenced
445 integer.  So this:
446
447     local $/ = \32768; # or \"32768", or \$var_containing_32768
448     open my $fh, "<", $myfile or die $!;
449     local $_ = <$fh>;
450
451 will read a record of no more than 32768 bytes from FILE.  If you're
452 not reading from a record-oriented file (or your OS doesn't have
453 record-oriented files), then you'll likely get a full chunk of data
454 with every read.  If a record is larger than the record size you've
455 set, you'll get the record back in pieces.  Trying to set the record
456 size to zero or less will cause reading in the (rest of the) whole file.
457
458 On VMS, record reads are done with the equivalent of C<sysread>,
459 so it's best not to mix record and non-record reads on the same
460 file.  (This is unlikely to be a problem, because any file you'd
461 want to read in record mode is probably unusable in line mode.)
462 Non-VMS systems do normal I/O, so it's safe to mix record and
463 non-record reads of a file.
464
465 See also L<perlport/"Newlines">.  Also see C<$.>.
466
467 =item HANDLE->autoflush(EXPR)
468
469 =item $OUTPUT_AUTOFLUSH
470
471 =item $|
472 X<$|> X<autoflush> X<flush> X<$OUTPUT_AUTOFLUSH>
473
474 If set to nonzero, forces a flush right away and after every write
475 or print on the currently selected output channel.  Default is 0
476 (regardless of whether the channel is really buffered by the
477 system or not; C<$|> tells you only whether you've asked Perl
478 explicitly to flush after each write).  STDOUT will
479 typically be line buffered if output is to the terminal and block
480 buffered otherwise.  Setting this variable is useful primarily when
481 you are outputting to a pipe or socket, such as when you are running
482 a Perl program under B<rsh> and want to see the output as it's
483 happening.  This has no effect on input buffering.  See L<perlfunc/getc>
484 for that.  See L<perldoc/select> on how to select the output channel. 
485 See also L<IO::Handle>. (Mnemonic: when you want your pipes to be piping hot.)
486
487 =item IO::Handle->output_field_separator EXPR
488
489 =item $OUTPUT_FIELD_SEPARATOR
490
491 =item $OFS
492
493 =item $,
494 X<$,> X<$OFS> X<$OUTPUT_FIELD_SEPARATOR>
495
496 The output field separator for the print operator.  If defined, this
497 value is printed between each of print's arguments.  Default is C<undef>.
498 (Mnemonic: what is printed when there is a "," in your print statement.)
499
500 =item IO::Handle->output_record_separator EXPR
501
502 =item $OUTPUT_RECORD_SEPARATOR
503
504 =item $ORS
505
506 =item $\
507 X<$\> X<$ORS> X<$OUTPUT_RECORD_SEPARATOR>
508
509 The output record separator for the print operator.  If defined, this
510 value is printed after the last of print's arguments.  Default is C<undef>.
511 (Mnemonic: you set C<$\> instead of adding "\n" at the end of the print.
512 Also, it's just like C<$/>, but it's what you get "back" from Perl.)
513
514 =item $LIST_SEPARATOR
515
516 =item $"
517 X<$"> X<$LIST_SEPARATOR>
518
519 This is like C<$,> except that it applies to array and slice values
520 interpolated into a double-quoted string (or similar interpreted
521 string).  Default is a space.  (Mnemonic: obvious, I think.)
522
523 =item $SUBSCRIPT_SEPARATOR
524
525 =item $SUBSEP
526
527 =item $;
528 X<$;> X<$SUBSEP> X<SUBSCRIPT_SEPARATOR>
529
530 The subscript separator for multidimensional array emulation.  If you
531 refer to a hash element as
532
533     $foo{$a,$b,$c}
534
535 it really means
536
537     $foo{join($;, $a, $b, $c)}
538
539 But don't put
540
541     @foo{$a,$b,$c}      # a slice--note the @
542
543 which means
544
545     ($foo{$a},$foo{$b},$foo{$c})
546
547 Default is "\034", the same as SUBSEP in B<awk>.  If your
548 keys contain binary data there might not be any safe value for C<$;>.
549 (Mnemonic: comma (the syntactic subscript separator) is a
550 semi-semicolon.  Yeah, I know, it's pretty lame, but C<$,> is already
551 taken for something more important.)
552
553 Consider using "real" multidimensional arrays as described
554 in L<perllol>.
555
556 =item HANDLE->format_page_number(EXPR)
557
558 =item $FORMAT_PAGE_NUMBER
559
560 =item $%
561 X<$%> X<$FORMAT_PAGE_NUMBER>
562
563 The current page number of the currently selected output channel.
564 Used with formats.
565 (Mnemonic: % is page number in B<nroff>.)
566
567 =item HANDLE->format_lines_per_page(EXPR)
568
569 =item $FORMAT_LINES_PER_PAGE
570
571 =item $=
572 X<$=> X<$FORMAT_LINES_PER_PAGE>
573
574 The current page length (printable lines) of the currently selected
575 output channel.  Default is 60.  
576 Used with formats.
577 (Mnemonic: = has horizontal lines.)
578
579 =item HANDLE->format_lines_left(EXPR)
580
581 =item $FORMAT_LINES_LEFT
582
583 =item $-
584 X<$-> X<$FORMAT_LINES_LEFT>
585
586 The number of lines left on the page of the currently selected output
587 channel.  
588 Used with formats.
589 (Mnemonic: lines_on_page - lines_printed.)
590
591 =item @LAST_MATCH_START
592
593 =item @-
594 X<@-> X<@LAST_MATCH_START>
595
596 $-[0] is the offset of the start of the last successful match.
597 C<$-[>I<n>C<]> is the offset of the start of the substring matched by
598 I<n>-th subpattern, or undef if the subpattern did not match.
599
600 Thus after a match against $_, $& coincides with C<substr $_, $-[0],
601 $+[0] - $-[0]>.  Similarly, $I<n> coincides with C<substr $_, $-[n],
602 $+[n] - $-[n]> if C<$-[n]> is defined, and $+ coincides with
603 C<substr $_, $-[$#-], $+[$#-] - $-[$#-]>.  One can use C<$#-> to find the last
604 matched subgroup in the last successful match.  Contrast with
605 C<$#+>, the number of subgroups in the regular expression.  Compare
606 with C<@+>.
607
608 This array holds the offsets of the beginnings of the last
609 successful submatches in the currently active dynamic scope.
610 C<$-[0]> is the offset into the string of the beginning of the
611 entire match.  The I<n>th element of this array holds the offset
612 of the I<n>th submatch, so C<$-[1]> is the offset where $1
613 begins, C<$-[2]> the offset where $2 begins, and so on.
614
615 After a match against some variable $var:
616
617 =over 5
618
619 =item C<$`> is the same as C<substr($var, 0, $-[0])>
620
621 =item C<$&> is the same as C<substr($var, $-[0], $+[0] - $-[0])>
622
623 =item C<$'> is the same as C<substr($var, $+[0])>
624
625 =item C<$1> is the same as C<substr($var, $-[1], $+[1] - $-[1])>  
626
627 =item C<$2> is the same as C<substr($var, $-[2], $+[2] - $-[2])>
628
629 =item C<$3> is the same as C<substr($var, $-[3], $+[3] - $-[3])>
630
631 =back
632
633 =item %-
634 X<%->
635
636 Similar to C<%+>, this variable allows access to the named capture buffers
637 in the last successful match in the currently active dynamic scope. To
638 each capture buffer name found in the regular expression, it associates a
639 reference to an array containing the list of values captured by all
640 buffers with that name (should there be several of them), in the order
641 where they appear.
642
643 Here's an example:
644
645     if ('1234' =~ /(?<A>1)(?<B>2)(?<A>3)(?<B>4)/) {
646         foreach my $bufname (sort keys %-) {
647             my $ary = $-{$bufname};
648             foreach my $idx (0..$#$ary) {
649                 print "\$-{$bufname}[$idx] : ",
650                       (defined($ary->[$idx]) ? "'$ary->[$idx]'" : "undef"),
651                       "\n";
652             }
653         }
654     }
655
656 would print out:
657
658     $-{A}[0] : '1'
659     $-{A}[1] : '3'
660     $-{B}[0] : '2'
661     $-{B}[1] : '4'
662
663 The keys of the C<%-> hash correspond to all buffer names found in
664 the regular expression.
665
666 The behaviour of C<%-> is implemented via the
667 L<Tie::Hash::NamedCapture> module.
668
669 B<Note:> C<%-> and C<%+> are tied views into a common internal hash
670 associated with the last successful regular expression. Therefore mixing
671 iterative access to them via C<each> may have unpredictable results.
672 Likewise, if the last successful match changes, then the results may be
673 surprising.
674
675 =item HANDLE->format_name(EXPR)
676
677 =item $FORMAT_NAME
678
679 =item $~
680 X<$~> X<$FORMAT_NAME>
681
682 The name of the current report format for the currently selected output
683 channel.  Default is the name of the filehandle.  (Mnemonic: brother to
684 C<$^>.)
685
686 =item HANDLE->format_top_name(EXPR)
687
688 =item $FORMAT_TOP_NAME
689
690 =item $^
691 X<$^> X<$FORMAT_TOP_NAME>
692
693 The name of the current top-of-page format for the currently selected
694 output channel.  Default is the name of the filehandle with _TOP
695 appended.  (Mnemonic: points to top of page.)
696
697 =item IO::Handle->format_line_break_characters EXPR
698
699 =item $FORMAT_LINE_BREAK_CHARACTERS
700
701 =item $:
702 X<$:> X<FORMAT_LINE_BREAK_CHARACTERS>
703
704 The current set of characters after which a string may be broken to
705 fill continuation fields (starting with ^) in a format.  Default is
706 S<" \n-">, to break on whitespace or hyphens.  (Mnemonic: a "colon" in
707 poetry is a part of a line.)
708
709 =item IO::Handle->format_formfeed EXPR
710
711 =item $FORMAT_FORMFEED
712
713 =item $^L
714 X<$^L> X<$FORMAT_FORMFEED>
715
716 What formats output as a form feed.  Default is \f.
717
718 =item $ACCUMULATOR
719
720 =item $^A
721 X<$^A> X<$ACCUMULATOR>
722
723 The current value of the write() accumulator for format() lines.  A format
724 contains formline() calls that put their result into C<$^A>.  After
725 calling its format, write() prints out the contents of C<$^A> and empties.
726 So you never really see the contents of C<$^A> unless you call
727 formline() yourself and then look at it.  See L<perlform> and
728 L<perlfunc/formline()>.
729
730 =item $CHILD_ERROR
731
732 =item $?
733 X<$?> X<$CHILD_ERROR>
734
735 The status returned by the last pipe close, backtick (C<``>) command,
736 successful call to wait() or waitpid(), or from the system()
737 operator.  This is just the 16-bit status word returned by the
738 traditional Unix wait() system call (or else is made up to look like it).  Thus, the
739 exit value of the subprocess is really (C<<< $? >> 8 >>>), and
740 C<$? & 127> gives which signal, if any, the process died from, and
741 C<$? & 128> reports whether there was a core dump.  (Mnemonic:
742 similar to B<sh> and B<ksh>.)
743
744 Additionally, if the C<h_errno> variable is supported in C, its value
745 is returned via $? if any C<gethost*()> function fails.
746
747 If you have installed a signal handler for C<SIGCHLD>, the
748 value of C<$?> will usually be wrong outside that handler.
749
750 Inside an C<END> subroutine C<$?> contains the value that is going to be
751 given to C<exit()>.  You can modify C<$?> in an C<END> subroutine to
752 change the exit status of your program.  For example:
753
754     END {
755         $? = 1 if $? == 255;  # die would make it 255
756     } 
757
758 Under VMS, the pragma C<use vmsish 'status'> makes C<$?> reflect the
759 actual VMS exit status, instead of the default emulation of POSIX
760 status; see L<perlvms/$?> for details.
761
762 Also see L<Error Indicators>.
763
764 =item ${^CHILD_ERROR_NATIVE}
765 X<$^CHILD_ERROR_NATIVE>
766
767 The native status returned by the last pipe close, backtick (C<``>)
768 command, successful call to wait() or waitpid(), or from the system()
769 operator.  On POSIX-like systems this value can be decoded with the
770 WIFEXITED, WEXITSTATUS, WIFSIGNALED, WTERMSIG, WIFSTOPPED, WSTOPSIG
771 and WIFCONTINUED functions provided by the L<POSIX> module.
772
773 Under VMS this reflects the actual VMS exit status; i.e. it is the same
774 as $? when the pragma C<use vmsish 'status'> is in effect.
775
776 =item ${^ENCODING}
777 X<$^ENCODING>
778
779 The I<object reference> to the Encode object that is used to convert
780 the source code to Unicode.  Thanks to this variable your perl script
781 does not have to be written in UTF-8.  Default is I<undef>.  The direct
782 manipulation of this variable is highly discouraged.
783
784 =item $OS_ERROR
785
786 =item $ERRNO
787
788 =item $!
789 X<$!> X<$ERRNO> X<$OS_ERROR>
790
791 If used numerically, yields the current value of the C C<errno>
792 variable, or in other words, if a system or library call fails, it
793 sets this variable.  This means that the value of C<$!> is meaningful
794 only I<immediately> after a B<failure>:
795
796     if (open my $fh, "<", $filename) {
797         # Here $! is meaningless.
798         ...
799     } else {
800         # ONLY here is $! meaningful.
801         ...
802         # Already here $! might be meaningless.
803     }
804     # Since here we might have either success or failure,
805     # here $! is meaningless.
806
807 In the above I<meaningless> stands for anything: zero, non-zero,
808 C<undef>.  A successful system or library call does B<not> set
809 the variable to zero.
810
811 If used as a string, yields the corresponding system error string.
812 You can assign a number to C<$!> to set I<errno> if, for instance,
813 you want C<"$!"> to return the string for error I<n>, or you want
814 to set the exit value for the die() operator.  (Mnemonic: What just
815 went bang?)
816
817 Also see L<Error Indicators>.
818
819 =item %OS_ERROR
820
821 =item %ERRNO
822
823 =item %!
824 X<%!>
825
826 Each element of C<%!> has a true value only if C<$!> is set to that
827 value.  For example, C<$!{ENOENT}> is true if and only if the current
828 value of C<$!> is C<ENOENT>; that is, if the most recent error was
829 "No such file or directory" (or its moral equivalent: not all operating
830 systems give that exact error, and certainly not all languages).
831 To check if a particular key is meaningful on your system, use
832 C<exists $!{the_key}>; for a list of legal keys, use C<keys %!>.
833 See L<Errno> for more information, and also see above for the
834 validity of C<$!>.
835
836 =item $EXTENDED_OS_ERROR
837
838 =item $^E
839 X<$^E> X<$EXTENDED_OS_ERROR>
840
841 Error information specific to the current operating system.  At
842 the moment, this differs from C<$!> under only VMS, OS/2, and Win32
843 (and for MacPerl).  On all other platforms, C<$^E> is always just
844 the same as C<$!>.
845
846 Under VMS, C<$^E> provides the VMS status value from the last
847 system error.  This is more specific information about the last
848 system error than that provided by C<$!>.  This is particularly
849 important when C<$!> is set to B<EVMSERR>.
850
851 Under OS/2, C<$^E> is set to the error code of the last call to
852 OS/2 API either via CRT, or directly from perl.
853
854 Under Win32, C<$^E> always returns the last error information
855 reported by the Win32 call C<GetLastError()> which describes
856 the last error from within the Win32 API.  Most Win32-specific
857 code will report errors via C<$^E>.  ANSI C and Unix-like calls
858 set C<errno> and so most portable Perl code will report errors
859 via C<$!>. 
860
861 Caveats mentioned in the description of C<$!> generally apply to
862 C<$^E>, also.  (Mnemonic: Extra error explanation.)
863
864 Also see L<Error Indicators>.
865
866 =item $EVAL_ERROR
867
868 =item $@
869 X<$@> X<$EVAL_ERROR>
870
871 The Perl syntax error message from the last eval() operator.
872 If $@ is the null string, the last eval() parsed and executed
873 correctly (although the operations you invoked may have failed in the
874 normal fashion).  (Mnemonic: Where was the syntax error "at"?)
875
876 Warning messages are not collected in this variable.  You can,
877 however, set up a routine to process warnings by setting C<$SIG{__WARN__}>
878 as described below.
879
880 Also see L<Error Indicators>.
881
882 =item $PROCESS_ID
883
884 =item $PID
885
886 =item $$
887 X<$$> X<$PID> X<$PROCESS_ID>
888
889 The process number of the Perl running this script.  You should
890 consider this variable read-only, although it will be altered
891 across fork() calls.  (Mnemonic: same as shells.)
892
893 Note for Linux users: on Linux, the C functions C<getpid()> and
894 C<getppid()> return different values from different threads. In order to
895 be portable, this behavior is not reflected by C<$$>, whose value remains
896 consistent across threads. If you want to call the underlying C<getpid()>,
897 you may use the CPAN module C<Linux::Pid>.
898
899 =item $REAL_USER_ID
900
901 =item $UID
902
903 =item $<
904 X<< $< >> X<$UID> X<$REAL_USER_ID>
905
906 The real uid of this process.  (Mnemonic: it's the uid you came I<from>,
907 if you're running setuid.)  You can change both the real uid and
908 the effective uid at the same time by using POSIX::setuid().  Since
909 changes to $< require a system call, check $! after a change attempt to 
910 detect any possible errors.
911
912 =item $EFFECTIVE_USER_ID
913
914 =item $EUID
915
916 =item $>
917 X<< $> >> X<$EUID> X<$EFFECTIVE_USER_ID>
918
919 The effective uid of this process.  Example:
920
921     $< = $>;            # set real to effective uid
922     ($<,$>) = ($>,$<);  # swap real and effective uid
923
924 You can change both the effective uid and the real uid at the same
925 time by using POSIX::setuid().  Changes to $> require a check to $!
926 to detect any possible errors after an attempted change. 
927
928 (Mnemonic: it's the uid you went I<to>, if you're running setuid.)
929 C<< $< >> and C<< $> >> can be swapped only on machines
930 supporting setreuid().
931
932 =item $REAL_GROUP_ID
933
934 =item $GID
935
936 =item $(
937 X<$(> X<$GID> X<$REAL_GROUP_ID>
938
939 The real gid of this process.  If you are on a machine that supports
940 membership in multiple groups simultaneously, gives a space separated
941 list of groups you are in.  The first number is the one returned by
942 getgid(), and the subsequent ones by getgroups(), one of which may be
943 the same as the first number.
944
945 However, a value assigned to C<$(> must be a single number used to
946 set the real gid.  So the value given by C<$(> should I<not> be assigned
947 back to C<$(> without being forced numeric, such as by adding zero. Note
948 that this is different to the effective gid (C<$)>) which does take a
949 list.
950
951 You can change both the real gid and the effective gid at the same
952 time by using POSIX::setgid().  Changes to $( require a check to $!
953 to detect any possible errors after an attempted change.
954
955 (Mnemonic: parentheses are used to I<group> things.  The real gid is the
956 group you I<left>, if you're running setgid.)
957
958 =item $EFFECTIVE_GROUP_ID
959
960 =item $EGID
961
962 =item $)
963 X<$)> X<$EGID> X<$EFFECTIVE_GROUP_ID>
964
965 The effective gid of this process.  If you are on a machine that
966 supports membership in multiple groups simultaneously, gives a space
967 separated list of groups you are in.  The first number is the one
968 returned by getegid(), and the subsequent ones by getgroups(), one of
969 which may be the same as the first number.
970
971 Similarly, a value assigned to C<$)> must also be a space-separated
972 list of numbers.  The first number sets the effective gid, and
973 the rest (if any) are passed to setgroups().  To get the effect of an
974 empty list for setgroups(), just repeat the new effective gid; that is,
975 to force an effective gid of 5 and an effectively empty setgroups()
976 list, say C< $) = "5 5" >.
977
978 You can change both the effective gid and the real gid at the same
979 time by using POSIX::setgid() (use only a single numeric argument).
980 Changes to $) require a check to $! to detect any possible errors
981 after an attempted change.
982
983 (Mnemonic: parentheses are used to I<group> things.  The effective gid
984 is the group that's I<right> for you, if you're running setgid.)
985
986 C<< $< >>, C<< $> >>, C<$(> and C<$)> can be set only on
987 machines that support the corresponding I<set[re][ug]id()> routine.  C<$(>
988 and C<$)> can be swapped only on machines supporting setregid().
989
990 =item $PROGRAM_NAME
991
992 =item $0
993 X<$0> X<$PROGRAM_NAME>
994
995 Contains the name of the program being executed.
996
997 On some (read: not all) operating systems assigning to C<$0> modifies
998 the argument area that the C<ps> program sees.  On some platforms you
999 may have to use special C<ps> options or a different C<ps> to see the
1000 changes.  Modifying the $0 is more useful as a way of indicating the
1001 current program state than it is for hiding the program you're
1002 running.  (Mnemonic: same as B<sh> and B<ksh>.)
1003
1004 Note that there are platform specific limitations on the maximum
1005 length of C<$0>.  In the most extreme case it may be limited to the
1006 space occupied by the original C<$0>.
1007
1008 In some platforms there may be arbitrary amount of padding, for
1009 example space characters, after the modified name as shown by C<ps>.
1010 In some platforms this padding may extend all the way to the original
1011 length of the argument area, no matter what you do (this is the case
1012 for example with Linux 2.2).
1013
1014 Note for BSD users: setting C<$0> does not completely remove "perl"
1015 from the ps(1) output.  For example, setting C<$0> to C<"foobar"> may
1016 result in C<"perl: foobar (perl)"> (whether both the C<"perl: "> prefix
1017 and the " (perl)" suffix are shown depends on your exact BSD variant
1018 and version).  This is an operating system feature, Perl cannot help it.
1019
1020 In multithreaded scripts Perl coordinates the threads so that any
1021 thread may modify its copy of the C<$0> and the change becomes visible
1022 to ps(1) (assuming the operating system plays along).  Note that
1023 the view of C<$0> the other threads have will not change since they
1024 have their own copies of it.
1025
1026 If the program has been given to perl via the switches C<-e> or C<-E>,
1027 C<$0> will contain the string C<"-e">.
1028
1029 =item $[
1030 X<$[>
1031
1032 The index of the first element in an array, and of the first character
1033 in a substring.  Default is 0, but you could theoretically set it
1034 to 1 to make Perl behave more like B<awk> (or Fortran) when
1035 subscripting and when evaluating the index() and substr() functions.
1036 (Mnemonic: [ begins subscripts.)
1037
1038 As of release 5 of Perl, assignment to C<$[> is treated as a compiler
1039 directive, and cannot influence the behavior of any other file.
1040 (That's why you can only assign compile-time constants to it.)  Its
1041 use is deprecated, and by default will trigger a warning.
1042
1043 Note that, unlike other compile-time directives (such as L<strict>),
1044 assignment to C<$[> can be seen from outer lexical scopes in the same file.
1045 However, you can use local() on it to strictly bind its value to a
1046 lexical block.
1047
1048 =item $]
1049 X<$]>
1050
1051 The version + patchlevel / 1000 of the Perl interpreter.  This variable
1052 can be used to determine whether the Perl interpreter executing a
1053 script is in the right range of versions.  (Mnemonic: Is this version
1054 of perl in the right bracket?)  Example:
1055
1056     warn "No checksumming!\n" if $] < 3.019;
1057
1058 See also the documentation of C<use VERSION> and C<require VERSION>
1059 for a convenient way to fail if the running Perl interpreter is too old.
1060
1061 The floating point representation can sometimes lead to inaccurate
1062 numeric comparisons.  See C<$^V> for a more modern representation of
1063 the Perl version that allows accurate string comparisons.
1064
1065 =item $COMPILING
1066
1067 =item $^C
1068 X<$^C> X<$COMPILING>
1069
1070 The current value of the flag associated with the B<-c> switch.
1071 Mainly of use with B<-MO=...> to allow code to alter its behavior
1072 when being compiled, such as for example to AUTOLOAD at compile
1073 time rather than normal, deferred loading.  Setting
1074 C<$^C = 1> is similar to calling C<B::minus_c>.
1075
1076 =item $DEBUGGING
1077
1078 =item $^D
1079 X<$^D> X<$DEBUGGING>
1080
1081 The current value of the debugging flags.  (Mnemonic: value of B<-D>
1082 switch.) May be read or set. Like its command-line equivalent, you can use
1083 numeric or symbolic values, eg C<$^D = 10> or C<$^D = "st">.
1084
1085 =item ${^RE_DEBUG_FLAGS}
1086
1087 The current value of the regex debugging flags. Set to 0 for no debug output
1088 even when the re 'debug' module is loaded. See L<re> for details.
1089
1090 =item ${^RE_TRIE_MAXBUF}
1091
1092 Controls how certain regex optimisations are applied and how much memory they
1093 utilize. This value by default is 65536 which corresponds to a 512kB temporary
1094 cache. Set this to a higher value to trade memory for speed when matching
1095 large alternations. Set it to a lower value if you want the optimisations to
1096 be as conservative of memory as possible but still occur, and set it to a
1097 negative value to prevent the optimisation and conserve the most memory.
1098 Under normal situations this variable should be of no interest to you.
1099
1100 =item $SYSTEM_FD_MAX
1101
1102 =item $^F
1103 X<$^F> X<$SYSTEM_FD_MAX>
1104
1105 The maximum system file descriptor, ordinarily 2.  System file
1106 descriptors are passed to exec()ed processes, while higher file
1107 descriptors are not.  Also, during an open(), system file descriptors are
1108 preserved even if the open() fails.  (Ordinary file descriptors are
1109 closed before the open() is attempted.)  The close-on-exec
1110 status of a file descriptor will be decided according to the value of
1111 C<$^F> when the corresponding file, pipe, or socket was opened, not the
1112 time of the exec().
1113
1114 =item $^H
1115
1116 WARNING: This variable is strictly for internal use only.  Its availability,
1117 behavior, and contents are subject to change without notice.
1118
1119 This variable contains compile-time hints for the Perl interpreter.  At the
1120 end of compilation of a BLOCK the value of this variable is restored to the
1121 value when the interpreter started to compile the BLOCK.
1122
1123 When perl begins to parse any block construct that provides a lexical scope
1124 (e.g., eval body, required file, subroutine body, loop body, or conditional
1125 block), the existing value of $^H is saved, but its value is left unchanged.
1126 When the compilation of the block is completed, it regains the saved value.
1127 Between the points where its value is saved and restored, code that
1128 executes within BEGIN blocks is free to change the value of $^H.
1129
1130 This behavior provides the semantic of lexical scoping, and is used in,
1131 for instance, the C<use strict> pragma.
1132
1133 The contents should be an integer; different bits of it are used for
1134 different pragmatic flags.  Here's an example:
1135
1136     sub add_100 { $^H |= 0x100 }
1137
1138     sub foo {
1139         BEGIN { add_100() }
1140         bar->baz($boon);
1141     }
1142
1143 Consider what happens during execution of the BEGIN block.  At this point
1144 the BEGIN block has already been compiled, but the body of foo() is still
1145 being compiled.  The new value of $^H will therefore be visible only while
1146 the body of foo() is being compiled.
1147
1148 Substitution of the above BEGIN block with:
1149
1150     BEGIN { require strict; strict->import('vars') }
1151
1152 demonstrates how C<use strict 'vars'> is implemented.  Here's a conditional
1153 version of the same lexical pragma:
1154
1155     BEGIN { require strict; strict->import('vars') if $condition }
1156
1157 =item %^H
1158
1159 The %^H hash provides the same scoping semantic as $^H.  This makes it
1160 useful for implementation of lexically scoped pragmas. See L<perlpragma>.
1161
1162 =item $INPLACE_EDIT
1163
1164 =item $^I
1165 X<$^I> X<$INPLACE_EDIT>
1166
1167 The current value of the inplace-edit extension.  Use C<undef> to disable
1168 inplace editing.  (Mnemonic: value of B<-i> switch.)
1169
1170 =item $^M
1171 X<$^M>
1172
1173 By default, running out of memory is an untrappable, fatal error.
1174 However, if suitably built, Perl can use the contents of C<$^M>
1175 as an emergency memory pool after die()ing.  Suppose that your Perl
1176 were compiled with C<-DPERL_EMERGENCY_SBRK> and used Perl's malloc.
1177 Then
1178
1179     $^M = 'a' x (1 << 16);
1180
1181 would allocate a 64K buffer for use in an emergency.  See the
1182 F<INSTALL> file in the Perl distribution for information on how to
1183 add custom C compilation flags when compiling perl.  To discourage casual
1184 use of this advanced feature, there is no L<English|English> long name for
1185 this variable.
1186
1187 =item $OSNAME
1188
1189 =item $^O
1190 X<$^O> X<$OSNAME>
1191
1192 The name of the operating system under which this copy of Perl was
1193 built, as determined during the configuration process.  The value
1194 is identical to C<$Config{'osname'}>.  See also L<Config> and the 
1195 B<-V> command-line switch documented in L<perlrun>.
1196
1197 In Windows platforms, $^O is not very helpful: since it is always
1198 C<MSWin32>, it doesn't tell the difference between
1199 95/98/ME/NT/2000/XP/CE/.NET.  Use Win32::GetOSName() or
1200 Win32::GetOSVersion() (see L<Win32> and L<perlport>) to distinguish
1201 between the variants.
1202
1203 =item ${^OPEN}
1204
1205 An internal variable used by PerlIO.  A string in two parts, separated
1206 by a C<\0> byte, the first part describes the input layers, the second
1207 part describes the output layers.
1208
1209 =item $PERLDB
1210
1211 =item $^P
1212 X<$^P> X<$PERLDB>
1213
1214 The internal variable for debugging support.  The meanings of the
1215 various bits are subject to change, but currently indicate:
1216
1217 =over 6
1218
1219 =item 0x01
1220
1221 Debug subroutine enter/exit.
1222
1223 =item 0x02
1224
1225 Line-by-line debugging. Causes DB::DB() subroutine to be called for each
1226 statement executed. Also causes saving source code lines (like 0x400).
1227
1228 =item 0x04
1229
1230 Switch off optimizations.
1231
1232 =item 0x08
1233
1234 Preserve more data for future interactive inspections.
1235
1236 =item 0x10
1237
1238 Keep info about source lines on which a subroutine is defined.
1239
1240 =item 0x20
1241
1242 Start with single-step on.
1243
1244 =item 0x40
1245
1246 Use subroutine address instead of name when reporting.
1247
1248 =item 0x80
1249
1250 Report C<goto &subroutine> as well.
1251
1252 =item 0x100
1253
1254 Provide informative "file" names for evals based on the place they were compiled.
1255
1256 =item 0x200
1257
1258 Provide informative names to anonymous subroutines based on the place they
1259 were compiled.
1260
1261 =item 0x400
1262
1263 Save source code lines into C<@{"_<$filename"}>.
1264
1265 =back
1266
1267 Some bits may be relevant at compile-time only, some at
1268 run-time only.  This is a new mechanism and the details may change.
1269 See also L<perldebguts>.
1270
1271 =item $LAST_REGEXP_CODE_RESULT
1272
1273 =item $^R
1274 X<$^R> X<$LAST_REGEXP_CODE_RESULT>
1275
1276 The result of evaluation of the last successful C<(?{ code })>
1277 regular expression assertion (see L<perlre>).  May be written to.
1278
1279 =item $EXCEPTIONS_BEING_CAUGHT
1280
1281 =item $^S
1282 X<$^S> X<$EXCEPTIONS_BEING_CAUGHT>
1283
1284 Current state of the interpreter.
1285
1286     $^S         State
1287     ---------   -------------------
1288     undef       Parsing module/eval
1289     true (1)    Executing an eval
1290     false (0)   Otherwise
1291
1292 The first state may happen in $SIG{__DIE__} and $SIG{__WARN__} handlers.
1293
1294 =item $BASETIME
1295
1296 =item $^T
1297 X<$^T> X<$BASETIME>
1298
1299 The time at which the program began running, in seconds since the
1300 epoch (beginning of 1970).  The values returned by the B<-M>, B<-A>,
1301 and B<-C> filetests are based on this value.
1302
1303 =item ${^TAINT}
1304
1305 Reflects if taint mode is on or off.  1 for on (the program was run with
1306 B<-T>), 0 for off, -1 when only taint warnings are enabled (i.e. with
1307 B<-t> or B<-TU>).  This variable is read-only.
1308
1309 =item ${^UNICODE}
1310
1311 Reflects certain Unicode settings of Perl.  See L<perlrun>
1312 documentation for the C<-C> switch for more information about
1313 the possible values. This variable is set during Perl startup
1314 and is thereafter read-only.
1315
1316 =item ${^UTF8CACHE}
1317
1318 This variable controls the state of the internal UTF-8 offset caching code.
1319 1 for on (the default), 0 for off, -1 to debug the caching code by checking
1320 all its results against linear scans, and panicking on any discrepancy.
1321
1322 =item ${^UTF8LOCALE}
1323
1324 This variable indicates whether an UTF-8 locale was detected by perl at
1325 startup. This information is used by perl when it's in
1326 adjust-utf8ness-to-locale mode (as when run with the C<-CL> command-line
1327 switch); see L<perlrun> for more info on this.
1328
1329 =item $PERL_VERSION
1330
1331 =item $^V
1332 X<$^V> X<$PERL_VERSION>
1333
1334 The revision, version, and subversion of the Perl interpreter, represented
1335 as a C<version> object.
1336
1337 This variable first appeared in perl 5.6.0; earlier versions of perl will
1338 see an undefined value. Before perl 5.10.0 $^V was represented as a v-string.
1339
1340 $^V can be used to determine whether the Perl interpreter executing a
1341 script is in the right range of versions.  (Mnemonic: use ^V for Version
1342 Control.)  Example:
1343
1344     warn "Hashes not randomized!\n" if !$^V or $^V lt v5.8.1
1345
1346 To convert C<$^V> into its string representation use sprintf()'s
1347 C<"%vd"> conversion:
1348
1349     printf "version is v%vd\n", $^V;  # Perl's version
1350
1351 See the documentation of C<use VERSION> and C<require VERSION>
1352 for a convenient way to fail if the running Perl interpreter is too old.
1353
1354 See also C<$]> for an older representation of the Perl version.
1355
1356 =item $WARNING
1357
1358 =item $^W
1359 X<$^W> X<$WARNING>
1360
1361 The current value of the warning switch, initially true if B<-w>
1362 was used, false otherwise, but directly modifiable.  (Mnemonic:
1363 related to the B<-w> switch.)  See also L<warnings>.
1364
1365 =item ${^WARNING_BITS}
1366
1367 The current set of warning checks enabled by the C<use warnings> pragma.
1368 See the documentation of C<warnings> for more details.
1369
1370 =item ${^WIN32_SLOPPY_STAT}
1371
1372 If this variable is set to a true value, then stat() on Windows will
1373 not try to open the file. This means that the link count cannot be
1374 determined and file attributes may be out of date if additional
1375 hardlinks to the file exist. On the other hand, not opening the file
1376 is considerably faster, especially for files on network drives.
1377
1378 This variable could be set in the F<sitecustomize.pl> file to
1379 configure the local Perl installation to use "sloppy" stat() by
1380 default.  See L<perlrun> for more information about site
1381 customization.
1382
1383 =item $EXECUTABLE_NAME
1384
1385 =item $^X
1386 X<$^X> X<$EXECUTABLE_NAME>
1387
1388 The name used to execute the current copy of Perl, from C's
1389 C<argv[0]> or (where supported) F</proc/self/exe>.
1390
1391 Depending on the host operating system, the value of $^X may be
1392 a relative or absolute pathname of the perl program file, or may
1393 be the string used to invoke perl but not the pathname of the
1394 perl program file.  Also, most operating systems permit invoking
1395 programs that are not in the PATH environment variable, so there
1396 is no guarantee that the value of $^X is in PATH.  For VMS, the
1397 value may or may not include a version number.
1398
1399 You usually can use the value of $^X to re-invoke an independent
1400 copy of the same perl that is currently running, e.g.,
1401
1402   @first_run = `$^X -le "print int rand 100 for 1..100"`;
1403
1404 But recall that not all operating systems support forking or
1405 capturing of the output of commands, so this complex statement
1406 may not be portable.
1407
1408 It is not safe to use the value of $^X as a path name of a file,
1409 as some operating systems that have a mandatory suffix on
1410 executable files do not require use of the suffix when invoking
1411 a command.  To convert the value of $^X to a path name, use the
1412 following statements:
1413
1414   # Build up a set of file names (not command names).
1415   use Config;
1416   $this_perl = $^X;
1417   if ($^O ne 'VMS')
1418      {$this_perl .= $Config{_exe}
1419           unless $this_perl =~ m/$Config{_exe}$/i;}
1420
1421 Because many operating systems permit anyone with read access to
1422 the Perl program file to make a copy of it, patch the copy, and
1423 then execute the copy, the security-conscious Perl programmer
1424 should take care to invoke the installed copy of perl, not the
1425 copy referenced by $^X.  The following statements accomplish
1426 this goal, and produce a pathname that can be invoked as a
1427 command or referenced as a file.
1428
1429   use Config;
1430   $secure_perl_path = $Config{perlpath};
1431   if ($^O ne 'VMS')
1432      {$secure_perl_path .= $Config{_exe}
1433           unless $secure_perl_path =~ m/$Config{_exe}$/i;}
1434
1435 =item ARGV
1436 X<ARGV>
1437
1438 The special filehandle that iterates over command-line filenames in
1439 C<@ARGV>. Usually written as the null filehandle in the angle operator
1440 C<< <> >>. Note that currently C<ARGV> only has its magical effect
1441 within the C<< <> >> operator; elsewhere it is just a plain filehandle
1442 corresponding to the last file opened by C<< <> >>. In particular,
1443 passing C<\*ARGV> as a parameter to a function that expects a filehandle
1444 may not cause your function to automatically read the contents of all the
1445 files in C<@ARGV>.
1446
1447 =item $ARGV
1448 X<$ARGV>
1449
1450 contains the name of the current file when reading from <>.
1451
1452 =item @ARGV
1453 X<@ARGV>
1454
1455 The array @ARGV contains the command-line arguments intended for
1456 the script.  C<$#ARGV> is generally the number of arguments minus
1457 one, because C<$ARGV[0]> is the first argument, I<not> the program's
1458 command name itself.  See C<$0> for the command name.
1459
1460 =item ARGVOUT
1461 X<ARGVOUT>
1462
1463 The special filehandle that points to the currently open output file
1464 when doing edit-in-place processing with B<-i>.  Useful when you have
1465 to do a lot of inserting and don't want to keep modifying $_.  See
1466 L<perlrun> for the B<-i> switch.
1467
1468 =item @F
1469 X<@F>
1470
1471 The array @F contains the fields of each line read in when autosplit
1472 mode is turned on.  See L<perlrun> for the B<-a> switch.  This array
1473 is package-specific, and must be declared or given a full package name
1474 if not in package main when running under C<strict 'vars'>.
1475
1476 =item @INC
1477 X<@INC>
1478
1479 The array @INC contains the list of places that the C<do EXPR>,
1480 C<require>, or C<use> constructs look for their library files.  It
1481 initially consists of the arguments to any B<-I> command-line
1482 switches, followed by the default Perl library, probably
1483 F</usr/local/lib/perl>, followed by ".", to represent the current
1484 directory.  ("." will not be appended if taint checks are enabled, either by
1485 C<-T> or by C<-t>.)  If you need to modify this at runtime, you should use
1486 the C<use lib> pragma to get the machine-dependent library properly
1487 loaded also:
1488
1489     use lib '/mypath/libdir/';
1490     use SomeMod;
1491
1492 You can also insert hooks into the file inclusion system by putting Perl
1493 code directly into @INC.  Those hooks may be subroutine references, array
1494 references or blessed objects.  See L<perlfunc/require> for details.
1495
1496 =item @ARG
1497
1498 =item @_
1499 X<@_> X<@ARG>
1500
1501 Within a subroutine the array @_ contains the parameters passed to that
1502 subroutine.  See L<perlsub>.
1503
1504 =item %INC
1505 X<%INC>
1506
1507 The hash %INC contains entries for each filename included via the
1508 C<do>, C<require>, or C<use> operators.  The key is the filename
1509 you specified (with module names converted to pathnames), and the
1510 value is the location of the file found.  The C<require>
1511 operator uses this hash to determine whether a particular file has
1512 already been included.
1513
1514 If the file was loaded via a hook (e.g. a subroutine reference, see
1515 L<perlfunc/require> for a description of these hooks), this hook is
1516 by default inserted into %INC in place of a filename.  Note, however,
1517 that the hook may have set the %INC entry by itself to provide some more
1518 specific info.
1519
1520 =item %ENV
1521
1522 =item $ENV{expr}
1523 X<%ENV>
1524
1525 The hash %ENV contains your current environment.  Setting a
1526 value in C<ENV> changes the environment for any child processes
1527 you subsequently fork() off.
1528
1529 =item %SIG
1530
1531 =item $SIG{expr}
1532 X<%SIG>
1533
1534 The hash C<%SIG> contains signal handlers for signals.  For example:
1535
1536     sub handler {       # 1st argument is signal name
1537         my($sig) = @_;
1538         print "Caught a SIG$sig--shutting down\n";
1539         close(LOG);
1540         exit(0);
1541     }
1542
1543     $SIG{'INT'}  = \&handler;
1544     $SIG{'QUIT'} = \&handler;
1545     ...
1546     $SIG{'INT'}  = 'DEFAULT';   # restore default action
1547     $SIG{'QUIT'} = 'IGNORE';    # ignore SIGQUIT
1548
1549 Using a value of C<'IGNORE'> usually has the effect of ignoring the
1550 signal, except for the C<CHLD> signal.  See L<perlipc> for more about
1551 this special case.
1552
1553 Here are some other examples:
1554
1555     $SIG{"PIPE"} = "Plumber";   # assumes main::Plumber (not recommended)
1556     $SIG{"PIPE"} = \&Plumber;   # just fine; assume current Plumber
1557     $SIG{"PIPE"} = *Plumber;    # somewhat esoteric
1558     $SIG{"PIPE"} = Plumber();   # oops, what did Plumber() return??
1559
1560 Be sure not to use a bareword as the name of a signal handler,
1561 lest you inadvertently call it. 
1562
1563 If your system has the sigaction() function then signal handlers are
1564 installed using it.  This means you get reliable signal handling.
1565
1566 The default delivery policy of signals changed in Perl 5.8.0 from 
1567 immediate (also known as "unsafe") to deferred, also known as 
1568 "safe signals".  See L<perlipc> for more information.
1569
1570 Certain internal hooks can be also set using the %SIG hash.  The
1571 routine indicated by C<$SIG{__WARN__}> is called when a warning message is
1572 about to be printed.  The warning message is passed as the first
1573 argument.  The presence of a C<__WARN__> hook causes the ordinary printing
1574 of warnings to C<STDERR> to be suppressed.  You can use this to save warnings
1575 in a variable, or turn warnings into fatal errors, like this:
1576
1577     local $SIG{__WARN__} = sub { die $_[0] };
1578     eval $proggie;
1579
1580 As the C<'IGNORE'> hook is not supported by C<__WARN__>, you can
1581 disable warnings using the empty subroutine:
1582
1583     local $SIG{__WARN__} = sub {};
1584
1585 The routine indicated by C<$SIG{__DIE__}> is called when a fatal exception
1586 is about to be thrown.  The error message is passed as the first
1587 argument.  When a C<__DIE__> hook routine returns, the exception
1588 processing continues as it would have in the absence of the hook,
1589 unless the hook routine itself exits via a C<goto>, a loop exit, or a C<die()>.
1590 The C<__DIE__> handler is explicitly disabled during the call, so that you
1591 can die from a C<__DIE__> handler.  Similarly for C<__WARN__>.
1592
1593 Due to an implementation glitch, the C<$SIG{__DIE__}> hook is called
1594 even inside an eval().  Do not use this to rewrite a pending exception
1595 in C<$@>, or as a bizarre substitute for overriding C<CORE::GLOBAL::die()>.
1596 This strange action at a distance may be fixed in a future release
1597 so that C<$SIG{__DIE__}> is only called if your program is about
1598 to exit, as was the original intent.  Any other use is deprecated.
1599
1600 C<__DIE__>/C<__WARN__> handlers are very special in one respect:
1601 they may be called to report (probable) errors found by the parser.
1602 In such a case the parser may be in inconsistent state, so any
1603 attempt to evaluate Perl code from such a handler will probably
1604 result in a segfault.  This means that warnings or errors that
1605 result from parsing Perl should be used with extreme caution, like
1606 this:
1607
1608     require Carp if defined $^S;
1609     Carp::confess("Something wrong") if defined &Carp::confess;
1610     die "Something wrong, but could not load Carp to give backtrace...
1611          To see backtrace try starting Perl with -MCarp switch";
1612
1613 Here the first line will load Carp I<unless> it is the parser who
1614 called the handler.  The second line will print backtrace and die if
1615 Carp was available.  The third line will be executed only if Carp was
1616 not available.
1617
1618 See L<perlfunc/die>, L<perlfunc/warn>, L<perlfunc/eval>, and
1619 L<warnings> for additional information.
1620
1621 =back
1622
1623 =head2 Error Indicators
1624 X<error> X<exception>
1625
1626 The variables C<$@>, C<$!>, C<$^E>, and C<$?> contain information
1627 about different types of error conditions that may appear during
1628 execution of a Perl program.  The variables are shown ordered by
1629 the "distance" between the subsystem which reported the error and
1630 the Perl process.  They correspond to errors detected by the Perl
1631 interpreter, C library, operating system, or an external program,
1632 respectively.
1633
1634 To illustrate the differences between these variables, consider the 
1635 following Perl expression, which uses a single-quoted string:
1636
1637     eval q{
1638         open my $pipe, "/cdrom/install |" or die $!;
1639         my @res = <$pipe>;
1640         close $pipe or die "bad pipe: $?, $!";
1641     };
1642
1643 After execution of this statement all 4 variables may have been set.  
1644
1645 C<$@> is set if the string to be C<eval>-ed did not compile (this
1646 may happen if C<open> or C<close> were imported with bad prototypes),
1647 or if Perl code executed during evaluation die()d .  In these cases
1648 the value of $@ is the compile error, or the argument to C<die>
1649 (which will interpolate C<$!> and C<$?>).  (See also L<Fatal>,
1650 though.)
1651
1652 When the eval() expression above is executed, open(), C<< <PIPE> >>,
1653 and C<close> are translated to calls in the C run-time library and
1654 thence to the operating system kernel.  C<$!> is set to the C library's
1655 C<errno> if one of these calls fails. 
1656
1657 Under a few operating systems, C<$^E> may contain a more verbose
1658 error indicator, such as in this case, "CDROM tray not closed."
1659 Systems that do not support extended error messages leave C<$^E>
1660 the same as C<$!>.
1661
1662 Finally, C<$?> may be set to non-0 value if the external program
1663 F</cdrom/install> fails.  The upper eight bits reflect specific
1664 error conditions encountered by the program (the program's exit()
1665 value).   The lower eight bits reflect mode of failure, like signal
1666 death and core dump information  See wait(2) for details.  In
1667 contrast to C<$!> and C<$^E>, which are set only if error condition
1668 is detected, the variable C<$?> is set on each C<wait> or pipe
1669 C<close>, overwriting the old value.  This is more like C<$@>, which
1670 on every eval() is always set on failure and cleared on success.
1671
1672 For more details, see the individual descriptions at C<$@>, C<$!>, C<$^E>,
1673 and C<$?>.
1674
1675 =head2 Technical Note on the Syntax of Variable Names
1676
1677 Variable names in Perl can have several formats.  Usually, they
1678 must begin with a letter or underscore, in which case they can be
1679 arbitrarily long (up to an internal limit of 251 characters) and
1680 may contain letters, digits, underscores, or the special sequence
1681 C<::> or C<'>.  In this case, the part before the last C<::> or
1682 C<'> is taken to be a I<package qualifier>; see L<perlmod>.
1683
1684 Perl variable names may also be a sequence of digits or a single
1685 punctuation or control character.  These names are all reserved for
1686 special uses by Perl; for example, the all-digits names are used
1687 to hold data captured by backreferences after a regular expression
1688 match.  Perl has a special syntax for the single-control-character
1689 names: It understands C<^X> (caret C<X>) to mean the control-C<X>
1690 character.  For example, the notation C<$^W> (dollar-sign caret
1691 C<W>) is the scalar variable whose name is the single character
1692 control-C<W>.  This is better than typing a literal control-C<W>
1693 into your program.
1694
1695 Finally, new in Perl 5.6, Perl variable names may be alphanumeric
1696 strings that begin with control characters (or better yet, a caret).
1697 These variables must be written in the form C<${^Foo}>; the braces
1698 are not optional.  C<${^Foo}> denotes the scalar variable whose
1699 name is a control-C<F> followed by two C<o>'s.  These variables are
1700 reserved for future special uses by Perl, except for the ones that
1701 begin with C<^_> (control-underscore or caret-underscore).  No
1702 control-character name that begins with C<^_> will acquire a special
1703 meaning in any future version of Perl; such names may therefore be
1704 used safely in programs.  C<$^_> itself, however, I<is> reserved.
1705
1706 Perl identifiers that begin with digits, control characters, or
1707 punctuation characters are exempt from the effects of the C<package>
1708 declaration and are always forced to be in package C<main>; they are
1709 also exempt from C<strict 'vars'> errors.  A few other names are also
1710 exempt in these ways:
1711
1712         ENV             STDIN
1713         INC             STDOUT
1714         ARGV            STDERR
1715         ARGVOUT         _
1716         SIG
1717
1718 In particular, the new special C<${^_XYZ}> variables are always taken
1719 to be in package C<main>, regardless of any C<package> declarations
1720 presently in scope.  
1721
1722 =head1 BUGS
1723
1724 Due to an unfortunate accident of Perl's implementation, C<use
1725 English> imposes a considerable performance penalty on all regular
1726 expression matches in a program, regardless of whether they occur
1727 in the scope of C<use English>.  For that reason, saying C<use
1728 English> in libraries is strongly discouraged.  See the
1729 Devel::SawAmpersand module documentation from CPAN
1730 ( http://www.cpan.org/modules/by-module/Devel/ )
1731 for more information. Writing C<use English '-no_match_vars';>
1732 avoids the performance penalty.
1733
1734 Having to even think about the C<$^S> variable in your exception
1735 handlers is simply wrong.  C<$SIG{__DIE__}> as currently implemented
1736 invites grievous and difficult to track down errors.  Avoid it
1737 and use an C<END{}> or CORE::GLOBAL::die override instead.