Avoid a possible race condition where a parallel make might
[perl.git] / pod / perlre.pod
1 =head1 NAME
2 X<regular expression> X<regex> X<regexp>
3
4 perlre - Perl regular expressions
5
6 =head1 DESCRIPTION
7
8 This page describes the syntax of regular expressions in Perl.
9
10 If you haven't used regular expressions before, a quick-start
11 introduction is available in L<perlrequick>, and a longer tutorial
12 introduction is available in L<perlretut>.
13
14 For reference on how regular expressions are used in matching
15 operations, plus various examples of the same, see discussions of
16 C<m//>, C<s///>, C<qr//> and C<??> in L<perlop/"Regexp Quote-Like
17 Operators">.
18
19
20 =head2 Modifiers
21
22 Matching operations can have various modifiers.  Modifiers
23 that relate to the interpretation of the regular expression inside
24 are listed below.  Modifiers that alter the way a regular expression
25 is used by Perl are detailed in L<perlop/"Regexp Quote-Like Operators"> and
26 L<perlop/"Gory details of parsing quoted constructs">.
27
28 =over 4
29
30 =item m
31 X</m> X<regex, multiline> X<regexp, multiline> X<regular expression, multiline>
32
33 Treat string as multiple lines.  That is, change "^" and "$" from matching
34 the start or end of the string to matching the start or end of any
35 line anywhere within the string.
36
37 =item s
38 X</s> X<regex, single-line> X<regexp, single-line>
39 X<regular expression, single-line>
40
41 Treat string as single line.  That is, change "." to match any character
42 whatsoever, even a newline, which normally it would not match.
43
44 Used together, as /ms, they let the "." match any character whatsoever,
45 while still allowing "^" and "$" to match, respectively, just after
46 and just before newlines within the string.
47
48 =item i
49 X</i> X<regex, case-insensitive> X<regexp, case-insensitive>
50 X<regular expression, case-insensitive>
51
52 Do case-insensitive pattern matching.
53
54 If C<use locale> is in effect, the case map is taken from the current
55 locale.  See L<perllocale>.
56
57 =item x
58 X</x>
59
60 Extend your pattern's legibility by permitting whitespace and comments.
61
62 =item p
63 X</p> X<regex, preserve> X<regexp, preserve>
64
65 Preserve the string matched such that ${^PREMATCH}, ${^MATCH}, and
66 ${^POSTMATCH} are available for use after matching.
67
68 =item g and c
69 X</g> X</c>
70
71 Global matching, and keep the Current position after failed matching.
72 Unlike i, m, s and x, these two flags affect the way the regex is used
73 rather than the regex itself. See
74 L<perlretut/"Using regular expressions in Perl"> for further explanation
75 of the g and c modifiers.
76
77 =back
78
79 These are usually written as "the C</x> modifier", even though the delimiter
80 in question might not really be a slash.  Any of these
81 modifiers may also be embedded within the regular expression itself using
82 the C<(?...)> construct.  See below.
83
84 The C</x> modifier itself needs a little more explanation.  It tells
85 the regular expression parser to ignore whitespace that is neither
86 backslashed nor within a character class.  You can use this to break up
87 your regular expression into (slightly) more readable parts.  The C<#>
88 character is also treated as a metacharacter introducing a comment,
89 just as in ordinary Perl code.  This also means that if you want real
90 whitespace or C<#> characters in the pattern (outside a character
91 class, where they are unaffected by C</x>), then you'll either have to
92 escape them (using backslashes or C<\Q...\E>) or encode them using octal
93 or hex escapes.  Taken together, these features go a long way towards
94 making Perl's regular expressions more readable.  Note that you have to
95 be careful not to include the pattern delimiter in the comment--perl has
96 no way of knowing you did not intend to close the pattern early.  See
97 the C-comment deletion code in L<perlop>.  Also note that anything inside
98 a C<\Q...\E> stays unaffected by C</x>.
99 X</x>
100
101 =head2 Regular Expressions
102
103 =head3 Metacharacters
104
105 The patterns used in Perl pattern matching evolved from those supplied in
106 the Version 8 regex routines.  (The routines are derived
107 (distantly) from Henry Spencer's freely redistributable reimplementation
108 of the V8 routines.)  See L<Version 8 Regular Expressions> for
109 details.
110
111 In particular the following metacharacters have their standard I<egrep>-ish
112 meanings:
113 X<metacharacter>
114 X<\> X<^> X<.> X<$> X<|> X<(> X<()> X<[> X<[]>
115
116
117     \   Quote the next metacharacter
118     ^   Match the beginning of the line
119     .   Match any character (except newline)
120     $   Match the end of the line (or before newline at the end)
121     |   Alternation
122     ()  Grouping
123     []  Character class
124
125 By default, the "^" character is guaranteed to match only the
126 beginning of the string, the "$" character only the end (or before the
127 newline at the end), and Perl does certain optimizations with the
128 assumption that the string contains only one line.  Embedded newlines
129 will not be matched by "^" or "$".  You may, however, wish to treat a
130 string as a multi-line buffer, such that the "^" will match after any
131 newline within the string (except if the newline is the last character in
132 the string), and "$" will match before any newline.  At the
133 cost of a little more overhead, you can do this by using the /m modifier
134 on the pattern match operator.  (Older programs did this by setting C<$*>,
135 but this practice has been removed in perl 5.9.)
136 X<^> X<$> X</m>
137
138 To simplify multi-line substitutions, the "." character never matches a
139 newline unless you use the C</s> modifier, which in effect tells Perl to pretend
140 the string is a single line--even if it isn't.
141 X<.> X</s>
142
143 =head3 Quantifiers
144
145 The following standard quantifiers are recognized:
146 X<metacharacter> X<quantifier> X<*> X<+> X<?> X<{n}> X<{n,}> X<{n,m}>
147
148     *      Match 0 or more times
149     +      Match 1 or more times
150     ?      Match 1 or 0 times
151     {n}    Match exactly n times
152     {n,}   Match at least n times
153     {n,m}  Match at least n but not more than m times
154
155 (If a curly bracket occurs in any other context, it is treated
156 as a regular character.  In particular, the lower bound
157 is not optional.)  The "*" quantifier is equivalent to C<{0,}>, the "+"
158 quantifier to C<{1,}>, and the "?" quantifier to C<{0,1}>.  n and m are limited
159 to integral values less than a preset limit defined when perl is built.
160 This is usually 32766 on the most common platforms.  The actual limit can
161 be seen in the error message generated by code such as this:
162
163     $_ **= $_ , / {$_} / for 2 .. 42;
164
165 By default, a quantified subpattern is "greedy", that is, it will match as
166 many times as possible (given a particular starting location) while still
167 allowing the rest of the pattern to match.  If you want it to match the
168 minimum number of times possible, follow the quantifier with a "?".  Note
169 that the meanings don't change, just the "greediness":
170 X<metacharacter> X<greedy> X<greediness>
171 X<?> X<*?> X<+?> X<??> X<{n}?> X<{n,}?> X<{n,m}?>
172
173     *?     Match 0 or more times, not greedily
174     +?     Match 1 or more times, not greedily
175     ??     Match 0 or 1 time, not greedily
176     {n}?   Match exactly n times, not greedily
177     {n,}?  Match at least n times, not greedily
178     {n,m}? Match at least n but not more than m times, not greedily
179
180 By default, when a quantified subpattern does not allow the rest of the
181 overall pattern to match, Perl will backtrack. However, this behaviour is
182 sometimes undesirable. Thus Perl provides the "possessive" quantifier form
183 as well.
184
185     *+     Match 0 or more times and give nothing back
186     ++     Match 1 or more times and give nothing back
187     ?+     Match 0 or 1 time and give nothing back
188     {n}+   Match exactly n times and give nothing back (redundant)
189     {n,}+  Match at least n times and give nothing back
190     {n,m}+ Match at least n but not more than m times and give nothing back
191
192 For instance,
193
194    'aaaa' =~ /a++a/
195
196 will never match, as the C<a++> will gobble up all the C<a>'s in the
197 string and won't leave any for the remaining part of the pattern. This
198 feature can be extremely useful to give perl hints about where it
199 shouldn't backtrack. For instance, the typical "match a double-quoted
200 string" problem can be most efficiently performed when written as:
201
202    /"(?:[^"\\]++|\\.)*+"/
203
204 as we know that if the final quote does not match, backtracking will not
205 help. See the independent subexpression C<< (?>...) >> for more details;
206 possessive quantifiers are just syntactic sugar for that construct. For
207 instance the above example could also be written as follows:
208
209    /"(?>(?:(?>[^"\\]+)|\\.)*)"/
210
211 =head3 Escape sequences
212
213 Because patterns are processed as double quoted strings, the following
214 also work:
215 X<\t> X<\n> X<\r> X<\f> X<\e> X<\a> X<\l> X<\u> X<\L> X<\U> X<\E> X<\Q>
216 X<\0> X<\c> X<\N> X<\x>
217
218     \t          tab                   (HT, TAB)
219     \n          newline               (LF, NL)
220     \r          return                (CR)
221     \f          form feed             (FF)
222     \a          alarm (bell)          (BEL)
223     \e          escape (think troff)  (ESC)
224     \033        octal char            (example: ESC)
225     \x1B        hex char              (example: ESC)
226     \x{263a}    long hex char         (example: Unicode SMILEY)
227     \cK         control char          (example: VT)
228     \N{name}    named Unicode character
229     \l          lowercase next char (think vi)
230     \u          uppercase next char (think vi)
231     \L          lowercase till \E (think vi)
232     \U          uppercase till \E (think vi)
233     \E          end case modification (think vi)
234     \Q          quote (disable) pattern metacharacters till \E
235
236 If C<use locale> is in effect, the case map used by C<\l>, C<\L>, C<\u>
237 and C<\U> is taken from the current locale.  See L<perllocale>.  For
238 documentation of C<\N{name}>, see L<charnames>.
239
240 You cannot include a literal C<$> or C<@> within a C<\Q> sequence.
241 An unescaped C<$> or C<@> interpolates the corresponding variable,
242 while escaping will cause the literal string C<\$> to be matched.
243 You'll need to write something like C<m/\Quser\E\@\Qhost/>.
244
245 =head3 Character Classes and other Special Escapes
246
247 In addition, Perl defines the following:
248 X<\w> X<\W> X<\s> X<\S> X<\d> X<\D> X<\X> X<\p> X<\P> X<\C>
249 X<\g> X<\k> X<\N> X<\K> X<\v> X<\V> X<\h> X<\H>
250 X<word> X<whitespace> X<character class> X<backreference>
251
252     \w       Match a "word" character (alphanumeric plus "_")
253     \W       Match a non-"word" character
254     \s       Match a whitespace character
255     \S       Match a non-whitespace character
256     \d       Match a digit character
257     \D       Match a non-digit character
258     \pP      Match P, named property.  Use \p{Prop} for longer names.
259     \PP      Match non-P
260     \X       Match Unicode "eXtended grapheme cluster"
261     \C       Match a single C char (octet) even under Unicode.
262              NOTE: breaks up characters into their UTF-8 bytes,
263              so you may end up with malformed pieces of UTF-8.
264              Unsupported in lookbehind.
265     \1       Backreference to a specific group.
266              '1' may actually be any positive integer.
267     \g1      Backreference to a specific or previous group,
268     \g{-1}   number may be negative indicating a previous buffer and may
269              optionally be wrapped in curly brackets for safer parsing.
270     \g{name} Named backreference
271     \k<name> Named backreference
272     \K       Keep the stuff left of the \K, don't include it in $&
273     \N       Any character but \n
274     \v       Vertical whitespace
275     \V       Not vertical whitespace
276     \h       Horizontal whitespace
277     \H       Not horizontal whitespace
278     \R       Linebreak
279
280 A C<\w> matches a single alphanumeric character (an alphabetic
281 character, or a decimal digit) or C<_>, not a whole word.  Use C<\w+>
282 to match a string of Perl-identifier characters (which isn't the same
283 as matching an English word).  If C<use locale> is in effect, the list
284 of alphabetic characters generated by C<\w> is taken from the current
285 locale.  See L<perllocale>.  You may use C<\w>, C<\W>, C<\s>, C<\S>,
286 C<\d>, and C<\D> within character classes, but they aren't usable
287 as either end of a range. If any of them precedes or follows a "-",
288 the "-" is understood literally. If Unicode is in effect, C<\s> matches
289 also "\x{85}", "\x{2028}", and "\x{2029}". See L<perlunicode> for more
290 details about C<\pP>, C<\PP>, C<\X> and the possibility of defining
291 your own C<\p> and C<\P> properties, and L<perluniintro> about Unicode
292 in general.
293 X<\w> X<\W> X<word>
294
295 C<\R> will atomically match a linebreak, including the network line-ending
296 "\x0D\x0A".  Specifically, X<\R> is exactly equivalent to
297
298   (?>\x0D\x0A?|[\x0A-\x0C\x85\x{2028}\x{2029}])
299
300 B<Note:> C<\R> has no special meaning inside of a character class;
301 use C<\v> instead (vertical whitespace).
302 X<\R>
303
304 The POSIX character class syntax
305 X<character class>
306
307     [:class:]
308
309 is also available.  Note that the C<[> and C<]> brackets are I<literal>;
310 they must always be used within a character class expression.
311
312     # this is correct:
313     $string =~ /[[:alpha:]]/;
314
315     # this is not, and will generate a warning:
316     $string =~ /[:alpha:]/;
317
318 The following table shows the mapping of POSIX character class
319 names, common escapes, literal escape sequences and their equivalent
320 Unicode style property names.
321 X<character class> X<\p> X<\p{}>
322 X<alpha> X<alnum> X<ascii> X<blank> X<cntrl> X<digit> X<graph>
323 X<lower> X<print> X<punct> X<space> X<upper> X<word> X<xdigit>
324
325 B<Note:> up to Perl 5.10 the property names used were shared with
326 standard Unicode properties, this was changed in Perl 5.11, see
327 L<perl5110delta> for details.
328
329     POSIX  Esc  Class               Property            Note
330     --------------------------------------------------------
331     alnum       [0-9A-Za-z]         IsPosixAlnum
332     alpha       [A-Za-z]            IsPosixAlpha
333     ascii       [\000-\177]         IsASCII
334     blank       [\011 ]             IsPosixBlank        [1]
335     cntrl       [\0-\37\177]        IsPosixCntrl
336     digit   \d  [0-9]               IsPosixDigit
337     graph       [!-~]               IsPosixGraph
338     lower       [a-z]               IsPosixLower
339     print       [ -~]               IsPosixPrint
340     punct       [!-/:-@[-`{-~]      IsPosixPunct
341     space       [\11-\15 ]          IsPosixSpace        [2]
342             \s  [\11\12\14\15 ]     IsPerlSpace         [2]
343     upper       [A-Z]               IsPosixUpper
344     word    \w  [0-9A-Z_a-z]        IsPerlWord          [3]
345     xdigit      [0-9A-Fa-f]         IsXDigit
346
347 =over
348
349 =item [1]
350
351 A GNU extension equivalent to C<[ \t]>, "all horizontal whitespace".
352
353 =item [2]
354
355 Note that C<\s> and C<[[:space:]]> are B<not> equivalent as C<[[:space:]]>
356 includes also the (very rare) "vertical tabulator", "\cK" or chr(11) in
357 ASCII.
358
359 =item [3]
360
361 A Perl extension, see above.
362
363 =back
364
365 For example use C<[:upper:]> to match all the uppercase characters.
366 Note that the C<[]> are part of the C<[::]> construct, not part of the
367 whole character class.  For example:
368
369     [01[:alpha:]%]
370
371 matches zero, one, any alphabetic character, and the percent sign.
372
373 =over 4
374
375 =item C<$>
376
377 Currency symbol
378
379 =item C<+> C<< < >> C<=> C<< > >> C<|> C<~>
380
381 Mathematical symbols
382
383 =item C<^> C<`>
384
385 Modifier symbols (accents)
386
387
388 =back
389
390 The other named classes are:
391
392 =over 4
393
394 =item cntrl
395 X<cntrl>
396
397 Any control character.  Usually characters that don't produce output as
398 such but instead control the terminal somehow: for example newline and
399 backspace are control characters.  All characters with ord() less than
400 32 are usually classified as control characters (assuming ASCII,
401 the ISO Latin character sets, and Unicode), as is the character with
402 the ord() value of 127 (C<DEL>).
403
404 =item graph
405 X<graph>
406
407 Any alphanumeric or punctuation (special) character.
408
409 =item print
410 X<print>
411
412 Any alphanumeric or punctuation (special) character or the space character.
413
414 =item punct
415 X<punct>
416
417 Any punctuation (special) character.
418
419 =item xdigit
420 X<xdigit>
421
422 Any hexadecimal digit.  Though this may feel silly ([0-9A-Fa-f] would
423 work just fine) it is included for completeness.
424
425 =back
426
427 You can negate the [::] character classes by prefixing the class name
428 with a '^'. This is a Perl extension.  For example:
429 X<character class, negation>
430
431     POSIX         traditional  Unicode
432
433     [[:^digit:]]    \D         \P{IsPosixDigit}
434     [[:^space:]]    \S         \P{IsPosixSpace}
435     [[:^word:]]     \W         \P{IsPerlWord}
436
437 Perl respects the POSIX standard in that POSIX character classes are
438 only supported within a character class.  The POSIX character classes
439 [.cc.] and [=cc=] are recognized but B<not> supported and trying to
440 use them will cause an error.
441
442 =head3 Assertions
443
444 Perl defines the following zero-width assertions:
445 X<zero-width assertion> X<assertion> X<regex, zero-width assertion>
446 X<regexp, zero-width assertion>
447 X<regular expression, zero-width assertion>
448 X<\b> X<\B> X<\A> X<\Z> X<\z> X<\G>
449
450     \b  Match a word boundary
451     \B  Match except at a word boundary
452     \A  Match only at beginning of string
453     \Z  Match only at end of string, or before newline at the end
454     \z  Match only at end of string
455     \G  Match only at pos() (e.g. at the end-of-match position
456         of prior m//g)
457
458 A word boundary (C<\b>) is a spot between two characters
459 that has a C<\w> on one side of it and a C<\W> on the other side
460 of it (in either order), counting the imaginary characters off the
461 beginning and end of the string as matching a C<\W>.  (Within
462 character classes C<\b> represents backspace rather than a word
463 boundary, just as it normally does in any double-quoted string.)
464 The C<\A> and C<\Z> are just like "^" and "$", except that they
465 won't match multiple times when the C</m> modifier is used, while
466 "^" and "$" will match at every internal line boundary.  To match
467 the actual end of the string and not ignore an optional trailing
468 newline, use C<\z>.
469 X<\b> X<\A> X<\Z> X<\z> X</m>
470
471 The C<\G> assertion can be used to chain global matches (using
472 C<m//g>), as described in L<perlop/"Regexp Quote-Like Operators">.
473 It is also useful when writing C<lex>-like scanners, when you have
474 several patterns that you want to match against consequent substrings
475 of your string, see the previous reference.  The actual location
476 where C<\G> will match can also be influenced by using C<pos()> as
477 an lvalue: see L<perlfunc/pos>. Note that the rule for zero-length
478 matches is modified somewhat, in that contents to the left of C<\G> is
479 not counted when determining the length of the match. Thus the following
480 will not match forever:
481 X<\G>
482
483     $str = 'ABC';
484     pos($str) = 1;
485     while (/.\G/g) {
486         print $&;
487     }
488
489 It will print 'A' and then terminate, as it considers the match to
490 be zero-width, and thus will not match at the same position twice in a
491 row.
492
493 It is worth noting that C<\G> improperly used can result in an infinite
494 loop. Take care when using patterns that include C<\G> in an alternation.
495
496 =head3 Capture buffers
497
498 The bracketing construct C<( ... )> creates capture buffers. To refer
499 to the current contents of a buffer later on, within the same pattern,
500 use \1 for the first, \2 for the second, and so on.
501 Outside the match use "$" instead of "\".  (The
502 \<digit> notation works in certain circumstances outside
503 the match.  See the warning below about \1 vs $1 for details.)
504 Referring back to another part of the match is called a
505 I<backreference>.
506 X<regex, capture buffer> X<regexp, capture buffer>
507 X<regular expression, capture buffer> X<backreference>
508
509 There is no limit to the number of captured substrings that you may
510 use.  However Perl also uses \10, \11, etc. as aliases for \010,
511 \011, etc.  (Recall that 0 means octal, so \011 is the character at
512 number 9 in your coded character set; which would be the 10th character,
513 a horizontal tab under ASCII.)  Perl resolves this
514 ambiguity by interpreting \10 as a backreference only if at least 10
515 left parentheses have opened before it.  Likewise \11 is a
516 backreference only if at least 11 left parentheses have opened
517 before it.  And so on.  \1 through \9 are always interpreted as
518 backreferences.
519 If the bracketing group did not match, the associated backreference won't
520 match either. (This can happen if the bracketing group is optional, or
521 in a different branch of an alternation.)
522
523 X<\g{1}> X<\g{-1}> X<\g{name}> X<relative backreference> X<named backreference>
524 In order to provide a safer and easier way to construct patterns using
525 backreferences, Perl provides the C<\g{N}> notation (starting with perl
526 5.10.0). The curly brackets are optional, however omitting them is less
527 safe as the meaning of the pattern can be changed by text (such as digits)
528 following it. When N is a positive integer the C<\g{N}> notation is
529 exactly equivalent to using normal backreferences. When N is a negative
530 integer then it is a relative backreference referring to the previous N'th
531 capturing group. When the bracket form is used and N is not an integer, it
532 is treated as a reference to a named buffer.
533
534 Thus C<\g{-1}> refers to the last buffer, C<\g{-2}> refers to the
535 buffer before that. For example:
536
537         /
538          (Y)            # buffer 1
539          (              # buffer 2
540             (X)         # buffer 3
541             \g{-1}      # backref to buffer 3
542             \g{-3}      # backref to buffer 1
543          )
544         /x
545
546 and would match the same as C</(Y) ( (X) \3 \1 )/x>.
547
548 Additionally, as of Perl 5.10.0 you may use named capture buffers and named
549 backreferences. The notation is C<< (?<name>...) >> to declare and C<< \k<name> >>
550 to reference. You may also use apostrophes instead of angle brackets to delimit the
551 name; and you may use the bracketed C<< \g{name} >> backreference syntax.
552 It's possible to refer to a named capture buffer by absolute and relative number as well.
553 Outside the pattern, a named capture buffer is available via the C<%+> hash.
554 When different buffers within the same pattern have the same name, C<$+{name}>
555 and C<< \k<name> >> refer to the leftmost defined group. (Thus it's possible
556 to do things with named capture buffers that would otherwise require C<(??{})>
557 code to accomplish.)
558 X<named capture buffer> X<regular expression, named capture buffer>
559 X<%+> X<$+{name}> X<< \k<name> >>
560
561 Examples:
562
563     s/^([^ ]*) *([^ ]*)/$2 $1/;     # swap first two words
564
565     /(.)\1/                         # find first doubled char
566          and print "'$1' is the first doubled character\n";
567
568     /(?<char>.)\k<char>/            # ... a different way
569          and print "'$+{char}' is the first doubled character\n";
570
571     /(?'char'.)\1/                  # ... mix and match
572          and print "'$1' is the first doubled character\n";
573
574     if (/Time: (..):(..):(..)/) {   # parse out values
575         $hours = $1;
576         $minutes = $2;
577         $seconds = $3;
578     }
579
580 Several special variables also refer back to portions of the previous
581 match.  C<$+> returns whatever the last bracket match matched.
582 C<$&> returns the entire matched string.  (At one point C<$0> did
583 also, but now it returns the name of the program.)  C<$`> returns
584 everything before the matched string.  C<$'> returns everything
585 after the matched string. And C<$^N> contains whatever was matched by
586 the most-recently closed group (submatch). C<$^N> can be used in
587 extended patterns (see below), for example to assign a submatch to a
588 variable.
589 X<$+> X<$^N> X<$&> X<$`> X<$'>
590
591 The numbered match variables ($1, $2, $3, etc.) and the related punctuation
592 set (C<$+>, C<$&>, C<$`>, C<$'>, and C<$^N>) are all dynamically scoped
593 until the end of the enclosing block or until the next successful
594 match, whichever comes first.  (See L<perlsyn/"Compound Statements">.)
595 X<$+> X<$^N> X<$&> X<$`> X<$'>
596 X<$1> X<$2> X<$3> X<$4> X<$5> X<$6> X<$7> X<$8> X<$9>
597
598
599 B<NOTE>: Failed matches in Perl do not reset the match variables,
600 which makes it easier to write code that tests for a series of more
601 specific cases and remembers the best match.
602
603 B<WARNING>: Once Perl sees that you need one of C<$&>, C<$`>, or
604 C<$'> anywhere in the program, it has to provide them for every
605 pattern match.  This may substantially slow your program.  Perl
606 uses the same mechanism to produce $1, $2, etc, so you also pay a
607 price for each pattern that contains capturing parentheses.  (To
608 avoid this cost while retaining the grouping behaviour, use the
609 extended regular expression C<(?: ... )> instead.)  But if you never
610 use C<$&>, C<$`> or C<$'>, then patterns I<without> capturing
611 parentheses will not be penalized.  So avoid C<$&>, C<$'>, and C<$`>
612 if you can, but if you can't (and some algorithms really appreciate
613 them), once you've used them once, use them at will, because you've
614 already paid the price.  As of 5.005, C<$&> is not so costly as the
615 other two.
616 X<$&> X<$`> X<$'>
617
618 As a workaround for this problem, Perl 5.10.0 introduces C<${^PREMATCH}>,
619 C<${^MATCH}> and C<${^POSTMATCH}>, which are equivalent to C<$`>, C<$&>
620 and C<$'>, B<except> that they are only guaranteed to be defined after a
621 successful match that was executed with the C</p> (preserve) modifier.
622 The use of these variables incurs no global performance penalty, unlike
623 their punctuation char equivalents, however at the trade-off that you
624 have to tell perl when you want to use them.
625 X</p> X<p modifier>
626
627 Backslashed metacharacters in Perl are alphanumeric, such as C<\b>,
628 C<\w>, C<\n>.  Unlike some other regular expression languages, there
629 are no backslashed symbols that aren't alphanumeric.  So anything
630 that looks like \\, \(, \), \<, \>, \{, or \} is always
631 interpreted as a literal character, not a metacharacter.  This was
632 once used in a common idiom to disable or quote the special meanings
633 of regular expression metacharacters in a string that you want to
634 use for a pattern. Simply quote all non-"word" characters:
635
636     $pattern =~ s/(\W)/\\$1/g;
637
638 (If C<use locale> is set, then this depends on the current locale.)
639 Today it is more common to use the quotemeta() function or the C<\Q>
640 metaquoting escape sequence to disable all metacharacters' special
641 meanings like this:
642
643     /$unquoted\Q$quoted\E$unquoted/
644
645 Beware that if you put literal backslashes (those not inside
646 interpolated variables) between C<\Q> and C<\E>, double-quotish
647 backslash interpolation may lead to confusing results.  If you
648 I<need> to use literal backslashes within C<\Q...\E>,
649 consult L<perlop/"Gory details of parsing quoted constructs">.
650
651 =head2 Extended Patterns
652
653 Perl also defines a consistent extension syntax for features not
654 found in standard tools like B<awk> and B<lex>.  The syntax is a
655 pair of parentheses with a question mark as the first thing within
656 the parentheses.  The character after the question mark indicates
657 the extension.
658
659 The stability of these extensions varies widely.  Some have been
660 part of the core language for many years.  Others are experimental
661 and may change without warning or be completely removed.  Check
662 the documentation on an individual feature to verify its current
663 status.
664
665 A question mark was chosen for this and for the minimal-matching
666 construct because 1) question marks are rare in older regular
667 expressions, and 2) whenever you see one, you should stop and
668 "question" exactly what is going on.  That's psychology...
669
670 =over 10
671
672 =item C<(?#text)>
673 X<(?#)>
674
675 A comment.  The text is ignored.  If the C</x> modifier enables
676 whitespace formatting, a simple C<#> will suffice.  Note that Perl closes
677 the comment as soon as it sees a C<)>, so there is no way to put a literal
678 C<)> in the comment.
679
680 =item C<(?pimsx-imsx)>
681 X<(?)>
682
683 One or more embedded pattern-match modifiers, to be turned on (or
684 turned off, if preceded by C<->) for the remainder of the pattern or
685 the remainder of the enclosing pattern group (if any). This is
686 particularly useful for dynamic patterns, such as those read in from a
687 configuration file, taken from an argument, or specified in a table
688 somewhere.  Consider the case where some patterns want to be case
689 sensitive and some do not:  The case insensitive ones merely need to
690 include C<(?i)> at the front of the pattern.  For example:
691
692     $pattern = "foobar";
693     if ( /$pattern/i ) { }
694
695     # more flexible:
696
697     $pattern = "(?i)foobar";
698     if ( /$pattern/ ) { }
699
700 These modifiers are restored at the end of the enclosing group. For example,
701
702     ( (?i) blah ) \s+ \1
703
704 will match C<blah> in any case, some spaces, and an exact (I<including the case>!)
705 repetition of the previous word, assuming the C</x> modifier, and no C</i>
706 modifier outside this group.
707
708 These modifiers do not carry over into named subpatterns called in the
709 enclosing group. In other words, a pattern such as C<((?i)(&NAME))> does not
710 change the case-sensitivity of the "NAME" pattern.
711
712 Note that the C<p> modifier is special in that it can only be enabled,
713 not disabled, and that its presence anywhere in a pattern has a global
714 effect. Thus C<(?-p)> and C<(?-p:...)> are meaningless and will warn
715 when executed under C<use warnings>.
716
717 =item C<(?:pattern)>
718 X<(?:)>
719
720 =item C<(?imsx-imsx:pattern)>
721
722 This is for clustering, not capturing; it groups subexpressions like
723 "()", but doesn't make backreferences as "()" does.  So
724
725     @fields = split(/\b(?:a|b|c)\b/)
726
727 is like
728
729     @fields = split(/\b(a|b|c)\b/)
730
731 but doesn't spit out extra fields.  It's also cheaper not to capture
732 characters if you don't need to.
733
734 Any letters between C<?> and C<:> act as flags modifiers as with
735 C<(?imsx-imsx)>.  For example,
736
737     /(?s-i:more.*than).*million/i
738
739 is equivalent to the more verbose
740
741     /(?:(?s-i)more.*than).*million/i
742
743 =item C<(?|pattern)>
744 X<(?|)> X<Branch reset>
745
746 This is the "branch reset" pattern, which has the special property
747 that the capture buffers are numbered from the same starting point
748 in each alternation branch. It is available starting from perl 5.10.0.
749
750 Capture buffers are numbered from left to right, but inside this
751 construct the numbering is restarted for each branch.
752
753 The numbering within each branch will be as normal, and any buffers
754 following this construct will be numbered as though the construct
755 contained only one branch, that being the one with the most capture
756 buffers in it.
757
758 This construct will be useful when you want to capture one of a
759 number of alternative matches.
760
761 Consider the following pattern.  The numbers underneath show in
762 which buffer the captured content will be stored.
763
764
765     # before  ---------------branch-reset----------- after        
766     / ( a )  (?| x ( y ) z | (p (q) r) | (t) u (v) ) ( z ) /x
767     # 1            2         2  3        2     3     4  
768
769 Be careful when using the branch reset pattern in combination with 
770 named captures. Named captures are implemented as being aliases to 
771 numbered buffers holding the captures, and that interferes with the
772 implementation of the branch reset pattern. If you are using named
773 captures in a branch reset pattern, it's best to use the same names,
774 in the same order, in each of the alternations:
775
776    /(?|  (?<a> x ) (?<b> y )
777       |  (?<a> z ) (?<b> w )) /x
778
779 Not doing so may lead to surprises:
780
781   "12" =~ /(?| (?<a> \d+ ) | (?<b> \D+))/x;
782   say $+ {a};   # Prints '12'
783   say $+ {b};   # *Also* prints '12'.
784
785 The problem here is that both the buffer named C<< a >> and the buffer
786 named C<< b >> are aliases for the buffer belonging to C<< $1 >>.
787
788 =item Look-Around Assertions
789 X<look-around assertion> X<lookaround assertion> X<look-around> X<lookaround>
790
791 Look-around assertions are zero width patterns which match a specific
792 pattern without including it in C<$&>. Positive assertions match when
793 their subpattern matches, negative assertions match when their subpattern
794 fails. Look-behind matches text up to the current match position,
795 look-ahead matches text following the current match position.
796
797 =over 4
798
799 =item C<(?=pattern)>
800 X<(?=)> X<look-ahead, positive> X<lookahead, positive>
801
802 A zero-width positive look-ahead assertion.  For example, C</\w+(?=\t)/>
803 matches a word followed by a tab, without including the tab in C<$&>.
804
805 =item C<(?!pattern)>
806 X<(?!)> X<look-ahead, negative> X<lookahead, negative>
807
808 A zero-width negative look-ahead assertion.  For example C</foo(?!bar)/>
809 matches any occurrence of "foo" that isn't followed by "bar".  Note
810 however that look-ahead and look-behind are NOT the same thing.  You cannot
811 use this for look-behind.
812
813 If you are looking for a "bar" that isn't preceded by a "foo", C</(?!foo)bar/>
814 will not do what you want.  That's because the C<(?!foo)> is just saying that
815 the next thing cannot be "foo"--and it's not, it's a "bar", so "foobar" will
816 match.  You would have to do something like C</(?!foo)...bar/> for that.   We
817 say "like" because there's the case of your "bar" not having three characters
818 before it.  You could cover that this way: C</(?:(?!foo)...|^.{0,2})bar/>.
819 Sometimes it's still easier just to say:
820
821     if (/bar/ && $` !~ /foo$/)
822
823 For look-behind see below.
824
825 =item C<(?<=pattern)> C<\K>
826 X<(?<=)> X<look-behind, positive> X<lookbehind, positive> X<\K>
827
828 A zero-width positive look-behind assertion.  For example, C</(?<=\t)\w+/>
829 matches a word that follows a tab, without including the tab in C<$&>.
830 Works only for fixed-width look-behind.
831
832 There is a special form of this construct, called C<\K>, which causes the
833 regex engine to "keep" everything it had matched prior to the C<\K> and
834 not include it in C<$&>. This effectively provides variable length
835 look-behind. The use of C<\K> inside of another look-around assertion
836 is allowed, but the behaviour is currently not well defined.
837
838 For various reasons C<\K> may be significantly more efficient than the
839 equivalent C<< (?<=...) >> construct, and it is especially useful in
840 situations where you want to efficiently remove something following
841 something else in a string. For instance
842
843   s/(foo)bar/$1/g;
844
845 can be rewritten as the much more efficient
846
847   s/foo\Kbar//g;
848
849 =item C<(?<!pattern)>
850 X<(?<!)> X<look-behind, negative> X<lookbehind, negative>
851
852 A zero-width negative look-behind assertion.  For example C</(?<!bar)foo/>
853 matches any occurrence of "foo" that does not follow "bar".  Works
854 only for fixed-width look-behind.
855
856 =back
857
858 =item C<(?'NAME'pattern)>
859
860 =item C<< (?<NAME>pattern) >>
861 X<< (?<NAME>) >> X<(?'NAME')> X<named capture> X<capture>
862
863 A named capture buffer. Identical in every respect to normal capturing
864 parentheses C<()> but for the additional fact that C<%+> or C<%-> may be
865 used after a successful match to refer to a named buffer. See C<perlvar>
866 for more details on the C<%+> and C<%-> hashes.
867
868 If multiple distinct capture buffers have the same name then the
869 $+{NAME} will refer to the leftmost defined buffer in the match.
870
871 The forms C<(?'NAME'pattern)> and C<< (?<NAME>pattern) >> are equivalent.
872
873 B<NOTE:> While the notation of this construct is the same as the similar
874 function in .NET regexes, the behavior is not. In Perl the buffers are
875 numbered sequentially regardless of being named or not. Thus in the
876 pattern
877
878   /(x)(?<foo>y)(z)/
879
880 $+{foo} will be the same as $2, and $3 will contain 'z' instead of
881 the opposite which is what a .NET regex hacker might expect.
882
883 Currently NAME is restricted to simple identifiers only.
884 In other words, it must match C</^[_A-Za-z][_A-Za-z0-9]*\z/> or
885 its Unicode extension (see L<utf8>),
886 though it isn't extended by the locale (see L<perllocale>).
887
888 B<NOTE:> In order to make things easier for programmers with experience
889 with the Python or PCRE regex engines, the pattern C<< (?PE<lt>NAMEE<gt>pattern) >>
890 may be used instead of C<< (?<NAME>pattern) >>; however this form does not
891 support the use of single quotes as a delimiter for the name.
892
893 =item C<< \k<NAME> >>
894
895 =item C<< \k'NAME' >>
896
897 Named backreference. Similar to numeric backreferences, except that
898 the group is designated by name and not number. If multiple groups
899 have the same name then it refers to the leftmost defined group in
900 the current match.
901
902 It is an error to refer to a name not defined by a C<< (?<NAME>) >>
903 earlier in the pattern.
904
905 Both forms are equivalent.
906
907 B<NOTE:> In order to make things easier for programmers with experience
908 with the Python or PCRE regex engines, the pattern C<< (?P=NAME) >>
909 may be used instead of C<< \k<NAME> >>.
910
911 =item C<(?{ code })>
912 X<(?{})> X<regex, code in> X<regexp, code in> X<regular expression, code in>
913
914 B<WARNING>: This extended regular expression feature is considered
915 experimental, and may be changed without notice. Code executed that
916 has side effects may not perform identically from version to version
917 due to the effect of future optimisations in the regex engine.
918
919 This zero-width assertion evaluates any embedded Perl code.  It
920 always succeeds, and its C<code> is not interpolated.  Currently,
921 the rules to determine where the C<code> ends are somewhat convoluted.
922
923 This feature can be used together with the special variable C<$^N> to
924 capture the results of submatches in variables without having to keep
925 track of the number of nested parentheses. For example:
926
927   $_ = "The brown fox jumps over the lazy dog";
928   /the (\S+)(?{ $color = $^N }) (\S+)(?{ $animal = $^N })/i;
929   print "color = $color, animal = $animal\n";
930
931 Inside the C<(?{...})> block, C<$_> refers to the string the regular
932 expression is matching against. You can also use C<pos()> to know what is
933 the current position of matching within this string.
934
935 The C<code> is properly scoped in the following sense: If the assertion
936 is backtracked (compare L<"Backtracking">), all changes introduced after
937 C<local>ization are undone, so that
938
939   $_ = 'a' x 8;
940   m<
941      (?{ $cnt = 0 })                    # Initialize $cnt.
942      (
943        a
944        (?{
945            local $cnt = $cnt + 1;       # Update $cnt, backtracking-safe.
946        })
947      )*
948      aaaa
949      (?{ $res = $cnt })                 # On success copy to non-localized
950                                         # location.
951    >x;
952
953 will set C<$res = 4>.  Note that after the match, C<$cnt> returns to the globally
954 introduced value, because the scopes that restrict C<local> operators
955 are unwound.
956
957 This assertion may be used as a C<(?(condition)yes-pattern|no-pattern)>
958 switch.  If I<not> used in this way, the result of evaluation of
959 C<code> is put into the special variable C<$^R>.  This happens
960 immediately, so C<$^R> can be used from other C<(?{ code })> assertions
961 inside the same regular expression.
962
963 The assignment to C<$^R> above is properly localized, so the old
964 value of C<$^R> is restored if the assertion is backtracked; compare
965 L<"Backtracking">.
966
967 For reasons of security, this construct is forbidden if the regular
968 expression involves run-time interpolation of variables, unless the
969 perilous C<use re 'eval'> pragma has been used (see L<re>), or the
970 variables contain results of C<qr//> operator (see
971 L<perlop/"qr/STRING/imosx">).
972
973 This restriction is due to the wide-spread and remarkably convenient
974 custom of using run-time determined strings as patterns.  For example:
975
976     $re = <>;
977     chomp $re;
978     $string =~ /$re/;
979
980 Before Perl knew how to execute interpolated code within a pattern,
981 this operation was completely safe from a security point of view,
982 although it could raise an exception from an illegal pattern.  If
983 you turn on the C<use re 'eval'>, though, it is no longer secure,
984 so you should only do so if you are also using taint checking.
985 Better yet, use the carefully constrained evaluation within a Safe
986 compartment.  See L<perlsec> for details about both these mechanisms.
987
988 B<WARNING>: Use of lexical (C<my>) variables in these blocks is
989 broken. The result is unpredictable and will make perl unstable. The
990 workaround is to use global (C<our>) variables.
991
992 B<WARNING>: Because Perl's regex engine is currently not re-entrant,
993 interpolated code may not invoke the regex engine either directly with
994 C<m//> or C<s///>), or indirectly with functions such as
995 C<split>. Invoking the regex engine in these blocks will make perl
996 unstable.
997
998 =item C<(??{ code })>
999 X<(??{})>
1000 X<regex, postponed> X<regexp, postponed> X<regular expression, postponed>
1001
1002 B<WARNING>: This extended regular expression feature is considered
1003 experimental, and may be changed without notice. Code executed that
1004 has side effects may not perform identically from version to version
1005 due to the effect of future optimisations in the regex engine.
1006
1007 This is a "postponed" regular subexpression.  The C<code> is evaluated
1008 at run time, at the moment this subexpression may match.  The result
1009 of evaluation is considered as a regular expression and matched as
1010 if it were inserted instead of this construct.  Note that this means
1011 that the contents of capture buffers defined inside an eval'ed pattern
1012 are not available outside of the pattern, and vice versa, there is no
1013 way for the inner pattern to refer to a capture buffer defined outside.
1014 Thus,
1015
1016     ('a' x 100)=~/(??{'(.)' x 100})/
1017
1018 B<will> match, it will B<not> set $1.
1019
1020 The C<code> is not interpolated.  As before, the rules to determine
1021 where the C<code> ends are currently somewhat convoluted.
1022
1023 The following pattern matches a parenthesized group:
1024
1025   $re = qr{
1026              \(
1027              (?:
1028                 (?> [^()]+ )    # Non-parens without backtracking
1029               |
1030                 (??{ $re })     # Group with matching parens
1031              )*
1032              \)
1033           }x;
1034
1035 See also C<(?PARNO)> for a different, more efficient way to accomplish
1036 the same task.
1037
1038 Because perl's regex engine is not currently re-entrant, delayed
1039 code may not invoke the regex engine either directly with C<m//> or C<s///>),
1040 or indirectly with functions such as C<split>.
1041
1042 Recursing deeper than 50 times without consuming any input string will
1043 result in a fatal error.  The maximum depth is compiled into perl, so
1044 changing it requires a custom build.
1045
1046 =item C<(?PARNO)> C<(?-PARNO)> C<(?+PARNO)> C<(?R)> C<(?0)>
1047 X<(?PARNO)> X<(?1)> X<(?R)> X<(?0)> X<(?-1)> X<(?+1)> X<(?-PARNO)> X<(?+PARNO)>
1048 X<regex, recursive> X<regexp, recursive> X<regular expression, recursive>
1049 X<regex, relative recursion>
1050
1051 Similar to C<(??{ code })> except it does not involve compiling any code,
1052 instead it treats the contents of a capture buffer as an independent
1053 pattern that must match at the current position.  Capture buffers
1054 contained by the pattern will have the value as determined by the
1055 outermost recursion.
1056
1057 PARNO is a sequence of digits (not starting with 0) whose value reflects
1058 the paren-number of the capture buffer to recurse to. C<(?R)> recurses to
1059 the beginning of the whole pattern. C<(?0)> is an alternate syntax for
1060 C<(?R)>. If PARNO is preceded by a plus or minus sign then it is assumed
1061 to be relative, with negative numbers indicating preceding capture buffers
1062 and positive ones following. Thus C<(?-1)> refers to the most recently
1063 declared buffer, and C<(?+1)> indicates the next buffer to be declared.
1064 Note that the counting for relative recursion differs from that of
1065 relative backreferences, in that with recursion unclosed buffers B<are>
1066 included.
1067
1068 The following pattern matches a function foo() which may contain
1069 balanced parentheses as the argument.
1070
1071   $re = qr{ (                    # paren group 1 (full function)
1072               foo
1073               (                  # paren group 2 (parens)
1074                 \(
1075                   (              # paren group 3 (contents of parens)
1076                   (?:
1077                    (?> [^()]+ )  # Non-parens without backtracking
1078                   |
1079                    (?2)          # Recurse to start of paren group 2
1080                   )*
1081                   )
1082                 \)
1083               )
1084             )
1085           }x;
1086
1087 If the pattern was used as follows
1088
1089     'foo(bar(baz)+baz(bop))'=~/$re/
1090         and print "\$1 = $1\n",
1091                   "\$2 = $2\n",
1092                   "\$3 = $3\n";
1093
1094 the output produced should be the following:
1095
1096     $1 = foo(bar(baz)+baz(bop))
1097     $2 = (bar(baz)+baz(bop))
1098     $3 = bar(baz)+baz(bop)
1099
1100 If there is no corresponding capture buffer defined, then it is a
1101 fatal error.  Recursing deeper than 50 times without consuming any input
1102 string will also result in a fatal error.  The maximum depth is compiled
1103 into perl, so changing it requires a custom build.
1104
1105 The following shows how using negative indexing can make it
1106 easier to embed recursive patterns inside of a C<qr//> construct
1107 for later use:
1108
1109     my $parens = qr/(\((?:[^()]++|(?-1))*+\))/;
1110     if (/foo $parens \s+ + \s+ bar $parens/x) {
1111        # do something here...
1112     }
1113
1114 B<Note> that this pattern does not behave the same way as the equivalent
1115 PCRE or Python construct of the same form. In Perl you can backtrack into
1116 a recursed group, in PCRE and Python the recursed into group is treated
1117 as atomic. Also, modifiers are resolved at compile time, so constructs
1118 like (?i:(?1)) or (?:(?i)(?1)) do not affect how the sub-pattern will
1119 be processed.
1120
1121 =item C<(?&NAME)>
1122 X<(?&NAME)>
1123
1124 Recurse to a named subpattern. Identical to C<(?PARNO)> except that the
1125 parenthesis to recurse to is determined by name. If multiple parentheses have
1126 the same name, then it recurses to the leftmost.
1127
1128 It is an error to refer to a name that is not declared somewhere in the
1129 pattern.
1130
1131 B<NOTE:> In order to make things easier for programmers with experience
1132 with the Python or PCRE regex engines the pattern C<< (?P>NAME) >>
1133 may be used instead of C<< (?&NAME) >>.
1134
1135 =item C<(?(condition)yes-pattern|no-pattern)>
1136 X<(?()>
1137
1138 =item C<(?(condition)yes-pattern)>
1139
1140 Conditional expression.  C<(condition)> should be either an integer in
1141 parentheses (which is valid if the corresponding pair of parentheses
1142 matched), a look-ahead/look-behind/evaluate zero-width assertion, a
1143 name in angle brackets or single quotes (which is valid if a buffer
1144 with the given name matched), or the special symbol (R) (true when
1145 evaluated inside of recursion or eval). Additionally the R may be
1146 followed by a number, (which will be true when evaluated when recursing
1147 inside of the appropriate group), or by C<&NAME>, in which case it will
1148 be true only when evaluated during recursion in the named group.
1149
1150 Here's a summary of the possible predicates:
1151
1152 =over 4
1153
1154 =item (1) (2) ...
1155
1156 Checks if the numbered capturing buffer has matched something.
1157
1158 =item (<NAME>) ('NAME')
1159
1160 Checks if a buffer with the given name has matched something.
1161
1162 =item (?{ CODE })
1163
1164 Treats the code block as the condition.
1165
1166 =item (R)
1167
1168 Checks if the expression has been evaluated inside of recursion.
1169
1170 =item (R1) (R2) ...
1171
1172 Checks if the expression has been evaluated while executing directly
1173 inside of the n-th capture group. This check is the regex equivalent of
1174
1175   if ((caller(0))[3] eq 'subname') { ... }
1176
1177 In other words, it does not check the full recursion stack.
1178
1179 =item (R&NAME)
1180
1181 Similar to C<(R1)>, this predicate checks to see if we're executing
1182 directly inside of the leftmost group with a given name (this is the same
1183 logic used by C<(?&NAME)> to disambiguate). It does not check the full
1184 stack, but only the name of the innermost active recursion.
1185
1186 =item (DEFINE)
1187
1188 In this case, the yes-pattern is never directly executed, and no
1189 no-pattern is allowed. Similar in spirit to C<(?{0})> but more efficient.
1190 See below for details.
1191
1192 =back
1193
1194 For example:
1195
1196     m{ ( \( )?
1197        [^()]+
1198        (?(1) \) )
1199      }x
1200
1201 matches a chunk of non-parentheses, possibly included in parentheses
1202 themselves.
1203
1204 A special form is the C<(DEFINE)> predicate, which never executes directly
1205 its yes-pattern, and does not allow a no-pattern. This allows to define
1206 subpatterns which will be executed only by using the recursion mechanism.
1207 This way, you can define a set of regular expression rules that can be
1208 bundled into any pattern you choose.
1209
1210 It is recommended that for this usage you put the DEFINE block at the
1211 end of the pattern, and that you name any subpatterns defined within it.
1212
1213 Also, it's worth noting that patterns defined this way probably will
1214 not be as efficient, as the optimiser is not very clever about
1215 handling them.
1216
1217 An example of how this might be used is as follows:
1218
1219   /(?<NAME>(?&NAME_PAT))(?<ADDR>(?&ADDRESS_PAT))
1220    (?(DEFINE)
1221      (?<NAME_PAT>....)
1222      (?<ADRESS_PAT>....)
1223    )/x
1224
1225 Note that capture buffers matched inside of recursion are not accessible
1226 after the recursion returns, so the extra layer of capturing buffers is
1227 necessary. Thus C<$+{NAME_PAT}> would not be defined even though
1228 C<$+{NAME}> would be.
1229
1230 =item C<< (?>pattern) >>
1231 X<backtrack> X<backtracking> X<atomic> X<possessive>
1232
1233 An "independent" subexpression, one which matches the substring
1234 that a I<standalone> C<pattern> would match if anchored at the given
1235 position, and it matches I<nothing other than this substring>.  This
1236 construct is useful for optimizations of what would otherwise be
1237 "eternal" matches, because it will not backtrack (see L<"Backtracking">).
1238 It may also be useful in places where the "grab all you can, and do not
1239 give anything back" semantic is desirable.
1240
1241 For example: C<< ^(?>a*)ab >> will never match, since C<< (?>a*) >>
1242 (anchored at the beginning of string, as above) will match I<all>
1243 characters C<a> at the beginning of string, leaving no C<a> for
1244 C<ab> to match.  In contrast, C<a*ab> will match the same as C<a+b>,
1245 since the match of the subgroup C<a*> is influenced by the following
1246 group C<ab> (see L<"Backtracking">).  In particular, C<a*> inside
1247 C<a*ab> will match fewer characters than a standalone C<a*>, since
1248 this makes the tail match.
1249
1250 An effect similar to C<< (?>pattern) >> may be achieved by writing
1251 C<(?=(pattern))\1>.  This matches the same substring as a standalone
1252 C<a+>, and the following C<\1> eats the matched string; it therefore
1253 makes a zero-length assertion into an analogue of C<< (?>...) >>.
1254 (The difference between these two constructs is that the second one
1255 uses a capturing group, thus shifting ordinals of backreferences
1256 in the rest of a regular expression.)
1257
1258 Consider this pattern:
1259
1260     m{ \(
1261           (
1262             [^()]+              # x+
1263           |
1264             \( [^()]* \)
1265           )+
1266        \)
1267      }x
1268
1269 That will efficiently match a nonempty group with matching parentheses
1270 two levels deep or less.  However, if there is no such group, it
1271 will take virtually forever on a long string.  That's because there
1272 are so many different ways to split a long string into several
1273 substrings.  This is what C<(.+)+> is doing, and C<(.+)+> is similar
1274 to a subpattern of the above pattern.  Consider how the pattern
1275 above detects no-match on C<((()aaaaaaaaaaaaaaaaaa> in several
1276 seconds, but that each extra letter doubles this time.  This
1277 exponential performance will make it appear that your program has
1278 hung.  However, a tiny change to this pattern
1279
1280     m{ \(
1281           (
1282             (?> [^()]+ )        # change x+ above to (?> x+ )
1283           |
1284             \( [^()]* \)
1285           )+
1286        \)
1287      }x
1288
1289 which uses C<< (?>...) >> matches exactly when the one above does (verifying
1290 this yourself would be a productive exercise), but finishes in a fourth
1291 the time when used on a similar string with 1000000 C<a>s.  Be aware,
1292 however, that this pattern currently triggers a warning message under
1293 the C<use warnings> pragma or B<-w> switch saying it
1294 C<"matches null string many times in regex">.
1295
1296 On simple groups, such as the pattern C<< (?> [^()]+ ) >>, a comparable
1297 effect may be achieved by negative look-ahead, as in C<[^()]+ (?! [^()] )>.
1298 This was only 4 times slower on a string with 1000000 C<a>s.
1299
1300 The "grab all you can, and do not give anything back" semantic is desirable
1301 in many situations where on the first sight a simple C<()*> looks like
1302 the correct solution.  Suppose we parse text with comments being delimited
1303 by C<#> followed by some optional (horizontal) whitespace.  Contrary to
1304 its appearance, C<#[ \t]*> I<is not> the correct subexpression to match
1305 the comment delimiter, because it may "give up" some whitespace if
1306 the remainder of the pattern can be made to match that way.  The correct
1307 answer is either one of these:
1308
1309     (?>#[ \t]*)
1310     #[ \t]*(?![ \t])
1311
1312 For example, to grab non-empty comments into $1, one should use either
1313 one of these:
1314
1315     / (?> \# [ \t]* ) (        .+ ) /x;
1316     /     \# [ \t]*   ( [^ \t] .* ) /x;
1317
1318 Which one you pick depends on which of these expressions better reflects
1319 the above specification of comments.
1320
1321 In some literature this construct is called "atomic matching" or
1322 "possessive matching".
1323
1324 Possessive quantifiers are equivalent to putting the item they are applied
1325 to inside of one of these constructs. The following equivalences apply:
1326
1327     Quantifier Form     Bracketing Form
1328     ---------------     ---------------
1329     PAT*+               (?>PAT*)
1330     PAT++               (?>PAT+)
1331     PAT?+               (?>PAT?)
1332     PAT{min,max}+       (?>PAT{min,max})
1333
1334 =back
1335
1336 =head2 Special Backtracking Control Verbs
1337
1338 B<WARNING:> These patterns are experimental and subject to change or
1339 removal in a future version of Perl. Their usage in production code should
1340 be noted to avoid problems during upgrades.
1341
1342 These special patterns are generally of the form C<(*VERB:ARG)>. Unless
1343 otherwise stated the ARG argument is optional; in some cases, it is
1344 forbidden.
1345
1346 Any pattern containing a special backtracking verb that allows an argument
1347 has the special behaviour that when executed it sets the current package's
1348 C<$REGERROR> and C<$REGMARK> variables. When doing so the following
1349 rules apply:
1350
1351 On failure, the C<$REGERROR> variable will be set to the ARG value of the
1352 verb pattern, if the verb was involved in the failure of the match. If the
1353 ARG part of the pattern was omitted, then C<$REGERROR> will be set to the
1354 name of the last C<(*MARK:NAME)> pattern executed, or to TRUE if there was
1355 none. Also, the C<$REGMARK> variable will be set to FALSE.
1356
1357 On a successful match, the C<$REGERROR> variable will be set to FALSE, and
1358 the C<$REGMARK> variable will be set to the name of the last
1359 C<(*MARK:NAME)> pattern executed.  See the explanation for the
1360 C<(*MARK:NAME)> verb below for more details.
1361
1362 B<NOTE:> C<$REGERROR> and C<$REGMARK> are not magic variables like C<$1>
1363 and most other regex related variables. They are not local to a scope, nor
1364 readonly, but instead are volatile package variables similar to C<$AUTOLOAD>.
1365 Use C<local> to localize changes to them to a specific scope if necessary.
1366
1367 If a pattern does not contain a special backtracking verb that allows an
1368 argument, then C<$REGERROR> and C<$REGMARK> are not touched at all.
1369
1370 =over 4
1371
1372 =item Verbs that take an argument
1373
1374 =over 4
1375
1376 =item C<(*PRUNE)> C<(*PRUNE:NAME)>
1377 X<(*PRUNE)> X<(*PRUNE:NAME)>
1378
1379 This zero-width pattern prunes the backtracking tree at the current point
1380 when backtracked into on failure. Consider the pattern C<A (*PRUNE) B>,
1381 where A and B are complex patterns. Until the C<(*PRUNE)> verb is reached,
1382 A may backtrack as necessary to match. Once it is reached, matching
1383 continues in B, which may also backtrack as necessary; however, should B
1384 not match, then no further backtracking will take place, and the pattern
1385 will fail outright at the current starting position.
1386
1387 The following example counts all the possible matching strings in a
1388 pattern (without actually matching any of them).
1389
1390     'aaab' =~ /a+b?(?{print "$&\n"; $count++})(*FAIL)/;
1391     print "Count=$count\n";
1392
1393 which produces:
1394
1395     aaab
1396     aaa
1397     aa
1398     a
1399     aab
1400     aa
1401     a
1402     ab
1403     a
1404     Count=9
1405
1406 If we add a C<(*PRUNE)> before the count like the following
1407
1408     'aaab' =~ /a+b?(*PRUNE)(?{print "$&\n"; $count++})(*FAIL)/;
1409     print "Count=$count\n";
1410
1411 we prevent backtracking and find the count of the longest matching
1412 at each matching starting point like so:
1413
1414     aaab
1415     aab
1416     ab
1417     Count=3
1418
1419 Any number of C<(*PRUNE)> assertions may be used in a pattern.
1420
1421 See also C<< (?>pattern) >> and possessive quantifiers for other ways to
1422 control backtracking. In some cases, the use of C<(*PRUNE)> can be
1423 replaced with a C<< (?>pattern) >> with no functional difference; however,
1424 C<(*PRUNE)> can be used to handle cases that cannot be expressed using a
1425 C<< (?>pattern) >> alone.
1426
1427
1428 =item C<(*SKIP)> C<(*SKIP:NAME)>
1429 X<(*SKIP)>
1430
1431 This zero-width pattern is similar to C<(*PRUNE)>, except that on
1432 failure it also signifies that whatever text that was matched leading up
1433 to the C<(*SKIP)> pattern being executed cannot be part of I<any> match
1434 of this pattern. This effectively means that the regex engine "skips" forward
1435 to this position on failure and tries to match again, (assuming that
1436 there is sufficient room to match).
1437
1438 The name of the C<(*SKIP:NAME)> pattern has special significance. If a
1439 C<(*MARK:NAME)> was encountered while matching, then it is that position
1440 which is used as the "skip point". If no C<(*MARK)> of that name was
1441 encountered, then the C<(*SKIP)> operator has no effect. When used
1442 without a name the "skip point" is where the match point was when
1443 executing the (*SKIP) pattern.
1444
1445 Compare the following to the examples in C<(*PRUNE)>, note the string
1446 is twice as long:
1447
1448     'aaabaaab' =~ /a+b?(*SKIP)(?{print "$&\n"; $count++})(*FAIL)/;
1449     print "Count=$count\n";
1450
1451 outputs
1452
1453     aaab
1454     aaab
1455     Count=2
1456
1457 Once the 'aaab' at the start of the string has matched, and the C<(*SKIP)>
1458 executed, the next starting point will be where the cursor was when the
1459 C<(*SKIP)> was executed.
1460
1461 =item C<(*MARK:NAME)> C<(*:NAME)>
1462 X<(*MARK)> C<(*MARK:NAME)> C<(*:NAME)>
1463
1464 This zero-width pattern can be used to mark the point reached in a string
1465 when a certain part of the pattern has been successfully matched. This
1466 mark may be given a name. A later C<(*SKIP)> pattern will then skip
1467 forward to that point if backtracked into on failure. Any number of
1468 C<(*MARK)> patterns are allowed, and the NAME portion is optional and may
1469 be duplicated.
1470
1471 In addition to interacting with the C<(*SKIP)> pattern, C<(*MARK:NAME)>
1472 can be used to "label" a pattern branch, so that after matching, the
1473 program can determine which branches of the pattern were involved in the
1474 match.
1475
1476 When a match is successful, the C<$REGMARK> variable will be set to the
1477 name of the most recently executed C<(*MARK:NAME)> that was involved
1478 in the match.
1479
1480 This can be used to determine which branch of a pattern was matched
1481 without using a separate capture buffer for each branch, which in turn
1482 can result in a performance improvement, as perl cannot optimize
1483 C</(?:(x)|(y)|(z))/> as efficiently as something like
1484 C</(?:x(*MARK:x)|y(*MARK:y)|z(*MARK:z))/>.
1485
1486 When a match has failed, and unless another verb has been involved in
1487 failing the match and has provided its own name to use, the C<$REGERROR>
1488 variable will be set to the name of the most recently executed
1489 C<(*MARK:NAME)>.
1490
1491 See C<(*SKIP)> for more details.
1492
1493 As a shortcut C<(*MARK:NAME)> can be written C<(*:NAME)>.
1494
1495 =item C<(*THEN)> C<(*THEN:NAME)>
1496
1497 This is similar to the "cut group" operator C<::> from Perl 6. Like
1498 C<(*PRUNE)>, this verb always matches, and when backtracked into on
1499 failure, it causes the regex engine to try the next alternation in the
1500 innermost enclosing group (capturing or otherwise).
1501
1502 Its name comes from the observation that this operation combined with the
1503 alternation operator (C<|>) can be used to create what is essentially a
1504 pattern-based if/then/else block:
1505
1506   ( COND (*THEN) FOO | COND2 (*THEN) BAR | COND3 (*THEN) BAZ )
1507
1508 Note that if this operator is used and NOT inside of an alternation then
1509 it acts exactly like the C<(*PRUNE)> operator.
1510
1511   / A (*PRUNE) B /
1512
1513 is the same as
1514
1515   / A (*THEN) B /
1516
1517 but
1518
1519   / ( A (*THEN) B | C (*THEN) D ) /
1520
1521 is not the same as
1522
1523   / ( A (*PRUNE) B | C (*PRUNE) D ) /
1524
1525 as after matching the A but failing on the B the C<(*THEN)> verb will
1526 backtrack and try C; but the C<(*PRUNE)> verb will simply fail.
1527
1528 =item C<(*COMMIT)>
1529 X<(*COMMIT)>
1530
1531 This is the Perl 6 "commit pattern" C<< <commit> >> or C<:::>. It's a
1532 zero-width pattern similar to C<(*SKIP)>, except that when backtracked
1533 into on failure it causes the match to fail outright. No further attempts
1534 to find a valid match by advancing the start pointer will occur again.
1535 For example,
1536
1537     'aaabaaab' =~ /a+b?(*COMMIT)(?{print "$&\n"; $count++})(*FAIL)/;
1538     print "Count=$count\n";
1539
1540 outputs
1541
1542     aaab
1543     Count=1
1544
1545 In other words, once the C<(*COMMIT)> has been entered, and if the pattern
1546 does not match, the regex engine will not try any further matching on the
1547 rest of the string.
1548
1549 =back
1550
1551 =item Verbs without an argument
1552
1553 =over 4
1554
1555 =item C<(*FAIL)> C<(*F)>
1556 X<(*FAIL)> X<(*F)>
1557
1558 This pattern matches nothing and always fails. It can be used to force the
1559 engine to backtrack. It is equivalent to C<(?!)>, but easier to read. In
1560 fact, C<(?!)> gets optimised into C<(*FAIL)> internally.
1561
1562 It is probably useful only when combined with C<(?{})> or C<(??{})>.
1563
1564 =item C<(*ACCEPT)>
1565 X<(*ACCEPT)>
1566
1567 B<WARNING:> This feature is highly experimental. It is not recommended
1568 for production code.
1569
1570 This pattern matches nothing and causes the end of successful matching at
1571 the point at which the C<(*ACCEPT)> pattern was encountered, regardless of
1572 whether there is actually more to match in the string. When inside of a
1573 nested pattern, such as recursion, or in a subpattern dynamically generated
1574 via C<(??{})>, only the innermost pattern is ended immediately.
1575
1576 If the C<(*ACCEPT)> is inside of capturing buffers then the buffers are
1577 marked as ended at the point at which the C<(*ACCEPT)> was encountered.
1578 For instance:
1579
1580   'AB' =~ /(A (A|B(*ACCEPT)|C) D)(E)/x;
1581
1582 will match, and C<$1> will be C<AB> and C<$2> will be C<B>, C<$3> will not
1583 be set. If another branch in the inner parentheses were matched, such as in the
1584 string 'ACDE', then the C<D> and C<E> would have to be matched as well.
1585
1586 =back
1587
1588 =back
1589
1590 =head2 Backtracking
1591 X<backtrack> X<backtracking>
1592
1593 NOTE: This section presents an abstract approximation of regular
1594 expression behavior.  For a more rigorous (and complicated) view of
1595 the rules involved in selecting a match among possible alternatives,
1596 see L<Combining RE Pieces>.
1597
1598 A fundamental feature of regular expression matching involves the
1599 notion called I<backtracking>, which is currently used (when needed)
1600 by all regular non-possessive expression quantifiers, namely C<*>, C<*?>, C<+>,
1601 C<+?>, C<{n,m}>, and C<{n,m}?>.  Backtracking is often optimized
1602 internally, but the general principle outlined here is valid.
1603
1604 For a regular expression to match, the I<entire> regular expression must
1605 match, not just part of it.  So if the beginning of a pattern containing a
1606 quantifier succeeds in a way that causes later parts in the pattern to
1607 fail, the matching engine backs up and recalculates the beginning
1608 part--that's why it's called backtracking.
1609
1610 Here is an example of backtracking:  Let's say you want to find the
1611 word following "foo" in the string "Food is on the foo table.":
1612
1613     $_ = "Food is on the foo table.";
1614     if ( /\b(foo)\s+(\w+)/i ) {
1615         print "$2 follows $1.\n";
1616     }
1617
1618 When the match runs, the first part of the regular expression (C<\b(foo)>)
1619 finds a possible match right at the beginning of the string, and loads up
1620 $1 with "Foo".  However, as soon as the matching engine sees that there's
1621 no whitespace following the "Foo" that it had saved in $1, it realizes its
1622 mistake and starts over again one character after where it had the
1623 tentative match.  This time it goes all the way until the next occurrence
1624 of "foo". The complete regular expression matches this time, and you get
1625 the expected output of "table follows foo."
1626
1627 Sometimes minimal matching can help a lot.  Imagine you'd like to match
1628 everything between "foo" and "bar".  Initially, you write something
1629 like this:
1630
1631     $_ =  "The food is under the bar in the barn.";
1632     if ( /foo(.*)bar/ ) {
1633         print "got <$1>\n";
1634     }
1635
1636 Which perhaps unexpectedly yields:
1637
1638   got <d is under the bar in the >
1639
1640 That's because C<.*> was greedy, so you get everything between the
1641 I<first> "foo" and the I<last> "bar".  Here it's more effective
1642 to use minimal matching to make sure you get the text between a "foo"
1643 and the first "bar" thereafter.
1644
1645     if ( /foo(.*?)bar/ ) { print "got <$1>\n" }
1646   got <d is under the >
1647
1648 Here's another example. Let's say you'd like to match a number at the end
1649 of a string, and you also want to keep the preceding part of the match.
1650 So you write this:
1651
1652     $_ = "I have 2 numbers: 53147";
1653     if ( /(.*)(\d*)/ ) {                                # Wrong!
1654         print "Beginning is <$1>, number is <$2>.\n";
1655     }
1656
1657 That won't work at all, because C<.*> was greedy and gobbled up the
1658 whole string. As C<\d*> can match on an empty string the complete
1659 regular expression matched successfully.
1660
1661     Beginning is <I have 2 numbers: 53147>, number is <>.
1662
1663 Here are some variants, most of which don't work:
1664
1665     $_ = "I have 2 numbers: 53147";
1666     @pats = qw{
1667         (.*)(\d*)
1668         (.*)(\d+)
1669         (.*?)(\d*)
1670         (.*?)(\d+)
1671         (.*)(\d+)$
1672         (.*?)(\d+)$
1673         (.*)\b(\d+)$
1674         (.*\D)(\d+)$
1675     };
1676
1677     for $pat (@pats) {
1678         printf "%-12s ", $pat;
1679         if ( /$pat/ ) {
1680             print "<$1> <$2>\n";
1681         } else {
1682             print "FAIL\n";
1683         }
1684     }
1685
1686 That will print out:
1687
1688     (.*)(\d*)    <I have 2 numbers: 53147> <>
1689     (.*)(\d+)    <I have 2 numbers: 5314> <7>
1690     (.*?)(\d*)   <> <>
1691     (.*?)(\d+)   <I have > <2>
1692     (.*)(\d+)$   <I have 2 numbers: 5314> <7>
1693     (.*?)(\d+)$  <I have 2 numbers: > <53147>
1694     (.*)\b(\d+)$ <I have 2 numbers: > <53147>
1695     (.*\D)(\d+)$ <I have 2 numbers: > <53147>
1696
1697 As you see, this can be a bit tricky.  It's important to realize that a
1698 regular expression is merely a set of assertions that gives a definition
1699 of success.  There may be 0, 1, or several different ways that the
1700 definition might succeed against a particular string.  And if there are
1701 multiple ways it might succeed, you need to understand backtracking to
1702 know which variety of success you will achieve.
1703
1704 When using look-ahead assertions and negations, this can all get even
1705 trickier.  Imagine you'd like to find a sequence of non-digits not
1706 followed by "123".  You might try to write that as
1707
1708     $_ = "ABC123";
1709     if ( /^\D*(?!123)/ ) {              # Wrong!
1710         print "Yup, no 123 in $_\n";
1711     }
1712
1713 But that isn't going to match; at least, not the way you're hoping.  It
1714 claims that there is no 123 in the string.  Here's a clearer picture of
1715 why that pattern matches, contrary to popular expectations:
1716
1717     $x = 'ABC123';
1718     $y = 'ABC445';
1719
1720     print "1: got $1\n" if $x =~ /^(ABC)(?!123)/;
1721     print "2: got $1\n" if $y =~ /^(ABC)(?!123)/;
1722
1723     print "3: got $1\n" if $x =~ /^(\D*)(?!123)/;
1724     print "4: got $1\n" if $y =~ /^(\D*)(?!123)/;
1725
1726 This prints
1727
1728     2: got ABC
1729     3: got AB
1730     4: got ABC
1731
1732 You might have expected test 3 to fail because it seems to a more
1733 general purpose version of test 1.  The important difference between
1734 them is that test 3 contains a quantifier (C<\D*>) and so can use
1735 backtracking, whereas test 1 will not.  What's happening is
1736 that you've asked "Is it true that at the start of $x, following 0 or more
1737 non-digits, you have something that's not 123?"  If the pattern matcher had
1738 let C<\D*> expand to "ABC", this would have caused the whole pattern to
1739 fail.
1740
1741 The search engine will initially match C<\D*> with "ABC".  Then it will
1742 try to match C<(?!123> with "123", which fails.  But because
1743 a quantifier (C<\D*>) has been used in the regular expression, the
1744 search engine can backtrack and retry the match differently
1745 in the hope of matching the complete regular expression.
1746
1747 The pattern really, I<really> wants to succeed, so it uses the
1748 standard pattern back-off-and-retry and lets C<\D*> expand to just "AB" this
1749 time.  Now there's indeed something following "AB" that is not
1750 "123".  It's "C123", which suffices.
1751
1752 We can deal with this by using both an assertion and a negation.
1753 We'll say that the first part in $1 must be followed both by a digit
1754 and by something that's not "123".  Remember that the look-aheads
1755 are zero-width expressions--they only look, but don't consume any
1756 of the string in their match.  So rewriting this way produces what
1757 you'd expect; that is, case 5 will fail, but case 6 succeeds:
1758
1759     print "5: got $1\n" if $x =~ /^(\D*)(?=\d)(?!123)/;
1760     print "6: got $1\n" if $y =~ /^(\D*)(?=\d)(?!123)/;
1761
1762     6: got ABC
1763
1764 In other words, the two zero-width assertions next to each other work as though
1765 they're ANDed together, just as you'd use any built-in assertions:  C</^$/>
1766 matches only if you're at the beginning of the line AND the end of the
1767 line simultaneously.  The deeper underlying truth is that juxtaposition in
1768 regular expressions always means AND, except when you write an explicit OR
1769 using the vertical bar.  C</ab/> means match "a" AND (then) match "b",
1770 although the attempted matches are made at different positions because "a"
1771 is not a zero-width assertion, but a one-width assertion.
1772
1773 B<WARNING>: Particularly complicated regular expressions can take
1774 exponential time to solve because of the immense number of possible
1775 ways they can use backtracking to try for a match.  For example, without
1776 internal optimizations done by the regular expression engine, this will
1777 take a painfully long time to run:
1778
1779     'aaaaaaaaaaaa' =~ /((a{0,5}){0,5})*[c]/
1780
1781 And if you used C<*>'s in the internal groups instead of limiting them
1782 to 0 through 5 matches, then it would take forever--or until you ran
1783 out of stack space.  Moreover, these internal optimizations are not
1784 always applicable.  For example, if you put C<{0,5}> instead of C<*>
1785 on the external group, no current optimization is applicable, and the
1786 match takes a long time to finish.
1787
1788 A powerful tool for optimizing such beasts is what is known as an
1789 "independent group",
1790 which does not backtrack (see L<C<< (?>pattern) >>>).  Note also that
1791 zero-length look-ahead/look-behind assertions will not backtrack to make
1792 the tail match, since they are in "logical" context: only
1793 whether they match is considered relevant.  For an example
1794 where side-effects of look-ahead I<might> have influenced the
1795 following match, see L<C<< (?>pattern) >>>.
1796
1797 =head2 Version 8 Regular Expressions
1798 X<regular expression, version 8> X<regex, version 8> X<regexp, version 8>
1799
1800 In case you're not familiar with the "regular" Version 8 regex
1801 routines, here are the pattern-matching rules not described above.
1802
1803 Any single character matches itself, unless it is a I<metacharacter>
1804 with a special meaning described here or above.  You can cause
1805 characters that normally function as metacharacters to be interpreted
1806 literally by prefixing them with a "\" (e.g., "\." matches a ".", not any
1807 character; "\\" matches a "\"). This escape mechanism is also required
1808 for the character used as the pattern delimiter.
1809
1810 A series of characters matches that series of characters in the target
1811 string, so the pattern  C<blurfl> would match "blurfl" in the target
1812 string.
1813
1814 You can specify a character class, by enclosing a list of characters
1815 in C<[]>, which will match any character from the list.  If the
1816 first character after the "[" is "^", the class matches any character not
1817 in the list.  Within a list, the "-" character specifies a
1818 range, so that C<a-z> represents all characters between "a" and "z",
1819 inclusive.  If you want either "-" or "]" itself to be a member of a
1820 class, put it at the start of the list (possibly after a "^"), or
1821 escape it with a backslash.  "-" is also taken literally when it is
1822 at the end of the list, just before the closing "]".  (The
1823 following all specify the same class of three characters: C<[-az]>,
1824 C<[az-]>, and C<[a\-z]>.  All are different from C<[a-z]>, which
1825 specifies a class containing twenty-six characters, even on EBCDIC-based
1826 character sets.)  Also, if you try to use the character
1827 classes C<\w>, C<\W>, C<\s>, C<\S>, C<\d>, or C<\D> as endpoints of
1828 a range, the "-" is understood literally.
1829
1830 Note also that the whole range idea is rather unportable between
1831 character sets--and even within character sets they may cause results
1832 you probably didn't expect.  A sound principle is to use only ranges
1833 that begin from and end at either alphabetics of equal case ([a-e],
1834 [A-E]), or digits ([0-9]).  Anything else is unsafe.  If in doubt,
1835 spell out the character sets in full.
1836
1837 Characters may be specified using a metacharacter syntax much like that
1838 used in C: "\n" matches a newline, "\t" a tab, "\r" a carriage return,
1839 "\f" a form feed, etc.  More generally, \I<nnn>, where I<nnn> is a string
1840 of octal digits, matches the character whose coded character set value
1841 is I<nnn>.  Similarly, \xI<nn>, where I<nn> are hexadecimal digits,
1842 matches the character whose numeric value is I<nn>. The expression \cI<x>
1843 matches the character control-I<x>.  Finally, the "." metacharacter
1844 matches any character except "\n" (unless you use C</s>).
1845
1846 You can specify a series of alternatives for a pattern using "|" to
1847 separate them, so that C<fee|fie|foe> will match any of "fee", "fie",
1848 or "foe" in the target string (as would C<f(e|i|o)e>).  The
1849 first alternative includes everything from the last pattern delimiter
1850 ("(", "[", or the beginning of the pattern) up to the first "|", and
1851 the last alternative contains everything from the last "|" to the next
1852 pattern delimiter.  That's why it's common practice to include
1853 alternatives in parentheses: to minimize confusion about where they
1854 start and end.
1855
1856 Alternatives are tried from left to right, so the first
1857 alternative found for which the entire expression matches, is the one that
1858 is chosen. This means that alternatives are not necessarily greedy. For
1859 example: when matching C<foo|foot> against "barefoot", only the "foo"
1860 part will match, as that is the first alternative tried, and it successfully
1861 matches the target string. (This might not seem important, but it is
1862 important when you are capturing matched text using parentheses.)
1863
1864 Also remember that "|" is interpreted as a literal within square brackets,
1865 so if you write C<[fee|fie|foe]> you're really only matching C<[feio|]>.
1866
1867 Within a pattern, you may designate subpatterns for later reference
1868 by enclosing them in parentheses, and you may refer back to the
1869 I<n>th subpattern later in the pattern using the metacharacter
1870 \I<n>.  Subpatterns are numbered based on the left to right order
1871 of their opening parenthesis.  A backreference matches whatever
1872 actually matched the subpattern in the string being examined, not
1873 the rules for that subpattern.  Therefore, C<(0|0x)\d*\s\1\d*> will
1874 match "0x1234 0x4321", but not "0x1234 01234", because subpattern
1875 1 matched "0x", even though the rule C<0|0x> could potentially match
1876 the leading 0 in the second number.
1877
1878 =head2 Warning on \1 Instead of $1
1879
1880 Some people get too used to writing things like:
1881
1882     $pattern =~ s/(\W)/\\\1/g;
1883
1884 This is grandfathered for the RHS of a substitute to avoid shocking the
1885 B<sed> addicts, but it's a dirty habit to get into.  That's because in
1886 PerlThink, the righthand side of an C<s///> is a double-quoted string.  C<\1> in
1887 the usual double-quoted string means a control-A.  The customary Unix
1888 meaning of C<\1> is kludged in for C<s///>.  However, if you get into the habit
1889 of doing that, you get yourself into trouble if you then add an C</e>
1890 modifier.
1891
1892     s/(\d+)/ \1 + 1 /eg;        # causes warning under -w
1893
1894 Or if you try to do
1895
1896     s/(\d+)/\1000/;
1897
1898 You can't disambiguate that by saying C<\{1}000>, whereas you can fix it with
1899 C<${1}000>.  The operation of interpolation should not be confused
1900 with the operation of matching a backreference.  Certainly they mean two
1901 different things on the I<left> side of the C<s///>.
1902
1903 =head2 Repeated Patterns Matching a Zero-length Substring
1904
1905 B<WARNING>: Difficult material (and prose) ahead.  This section needs a rewrite.
1906
1907 Regular expressions provide a terse and powerful programming language.  As
1908 with most other power tools, power comes together with the ability
1909 to wreak havoc.
1910
1911 A common abuse of this power stems from the ability to make infinite
1912 loops using regular expressions, with something as innocuous as:
1913
1914     'foo' =~ m{ ( o? )* }x;
1915
1916 The C<o?> matches at the beginning of C<'foo'>, and since the position
1917 in the string is not moved by the match, C<o?> would match again and again
1918 because of the C<*> quantifier.  Another common way to create a similar cycle
1919 is with the looping modifier C<//g>:
1920
1921     @matches = ( 'foo' =~ m{ o? }xg );
1922
1923 or
1924
1925     print "match: <$&>\n" while 'foo' =~ m{ o? }xg;
1926
1927 or the loop implied by split().
1928
1929 However, long experience has shown that many programming tasks may
1930 be significantly simplified by using repeated subexpressions that
1931 may match zero-length substrings.  Here's a simple example being:
1932
1933     @chars = split //, $string;           # // is not magic in split
1934     ($whitewashed = $string) =~ s/()/ /g; # parens avoid magic s// /
1935
1936 Thus Perl allows such constructs, by I<forcefully breaking
1937 the infinite loop>.  The rules for this are different for lower-level
1938 loops given by the greedy quantifiers C<*+{}>, and for higher-level
1939 ones like the C</g> modifier or split() operator.
1940
1941 The lower-level loops are I<interrupted> (that is, the loop is
1942 broken) when Perl detects that a repeated expression matched a
1943 zero-length substring.   Thus
1944
1945    m{ (?: NON_ZERO_LENGTH | ZERO_LENGTH )* }x;
1946
1947 is made equivalent to
1948
1949    m{   (?: NON_ZERO_LENGTH )*
1950       |
1951         (?: ZERO_LENGTH )?
1952     }x;
1953
1954 The higher level-loops preserve an additional state between iterations:
1955 whether the last match was zero-length.  To break the loop, the following
1956 match after a zero-length match is prohibited to have a length of zero.
1957 This prohibition interacts with backtracking (see L<"Backtracking">),
1958 and so the I<second best> match is chosen if the I<best> match is of
1959 zero length.
1960
1961 For example:
1962
1963     $_ = 'bar';
1964     s/\w??/<$&>/g;
1965
1966 results in C<< <><b><><a><><r><> >>.  At each position of the string the best
1967 match given by non-greedy C<??> is the zero-length match, and the I<second
1968 best> match is what is matched by C<\w>.  Thus zero-length matches
1969 alternate with one-character-long matches.
1970
1971 Similarly, for repeated C<m/()/g> the second-best match is the match at the
1972 position one notch further in the string.
1973
1974 The additional state of being I<matched with zero-length> is associated with
1975 the matched string, and is reset by each assignment to pos().
1976 Zero-length matches at the end of the previous match are ignored
1977 during C<split>.
1978
1979 =head2 Combining RE Pieces
1980
1981 Each of the elementary pieces of regular expressions which were described
1982 before (such as C<ab> or C<\Z>) could match at most one substring
1983 at the given position of the input string.  However, in a typical regular
1984 expression these elementary pieces are combined into more complicated
1985 patterns using combining operators C<ST>, C<S|T>, C<S*> etc
1986 (in these examples C<S> and C<T> are regular subexpressions).
1987
1988 Such combinations can include alternatives, leading to a problem of choice:
1989 if we match a regular expression C<a|ab> against C<"abc">, will it match
1990 substring C<"a"> or C<"ab">?  One way to describe which substring is
1991 actually matched is the concept of backtracking (see L<"Backtracking">).
1992 However, this description is too low-level and makes you think
1993 in terms of a particular implementation.
1994
1995 Another description starts with notions of "better"/"worse".  All the
1996 substrings which may be matched by the given regular expression can be
1997 sorted from the "best" match to the "worst" match, and it is the "best"
1998 match which is chosen.  This substitutes the question of "what is chosen?"
1999 by the question of "which matches are better, and which are worse?".
2000
2001 Again, for elementary pieces there is no such question, since at most
2002 one match at a given position is possible.  This section describes the
2003 notion of better/worse for combining operators.  In the description
2004 below C<S> and C<T> are regular subexpressions.
2005
2006 =over 4
2007
2008 =item C<ST>
2009
2010 Consider two possible matches, C<AB> and C<A'B'>, C<A> and C<A'> are
2011 substrings which can be matched by C<S>, C<B> and C<B'> are substrings
2012 which can be matched by C<T>.
2013
2014 If C<A> is better match for C<S> than C<A'>, C<AB> is a better
2015 match than C<A'B'>.
2016
2017 If C<A> and C<A'> coincide: C<AB> is a better match than C<AB'> if
2018 C<B> is better match for C<T> than C<B'>.
2019
2020 =item C<S|T>
2021
2022 When C<S> can match, it is a better match than when only C<T> can match.
2023
2024 Ordering of two matches for C<S> is the same as for C<S>.  Similar for
2025 two matches for C<T>.
2026
2027 =item C<S{REPEAT_COUNT}>
2028
2029 Matches as C<SSS...S> (repeated as many times as necessary).
2030
2031 =item C<S{min,max}>
2032
2033 Matches as C<S{max}|S{max-1}|...|S{min+1}|S{min}>.
2034
2035 =item C<S{min,max}?>
2036
2037 Matches as C<S{min}|S{min+1}|...|S{max-1}|S{max}>.
2038
2039 =item C<S?>, C<S*>, C<S+>
2040
2041 Same as C<S{0,1}>, C<S{0,BIG_NUMBER}>, C<S{1,BIG_NUMBER}> respectively.
2042
2043 =item C<S??>, C<S*?>, C<S+?>
2044
2045 Same as C<S{0,1}?>, C<S{0,BIG_NUMBER}?>, C<S{1,BIG_NUMBER}?> respectively.
2046
2047 =item C<< (?>S) >>
2048
2049 Matches the best match for C<S> and only that.
2050
2051 =item C<(?=S)>, C<(?<=S)>
2052
2053 Only the best match for C<S> is considered.  (This is important only if
2054 C<S> has capturing parentheses, and backreferences are used somewhere
2055 else in the whole regular expression.)
2056
2057 =item C<(?!S)>, C<(?<!S)>
2058
2059 For this grouping operator there is no need to describe the ordering, since
2060 only whether or not C<S> can match is important.
2061
2062 =item C<(??{ EXPR })>, C<(?PARNO)>
2063
2064 The ordering is the same as for the regular expression which is
2065 the result of EXPR, or the pattern contained by capture buffer PARNO.
2066
2067 =item C<(?(condition)yes-pattern|no-pattern)>
2068
2069 Recall that which of C<yes-pattern> or C<no-pattern> actually matches is
2070 already determined.  The ordering of the matches is the same as for the
2071 chosen subexpression.
2072
2073 =back
2074
2075 The above recipes describe the ordering of matches I<at a given position>.
2076 One more rule is needed to understand how a match is determined for the
2077 whole regular expression: a match at an earlier position is always better
2078 than a match at a later position.
2079
2080 =head2 Creating Custom RE Engines
2081
2082 Overloaded constants (see L<overload>) provide a simple way to extend
2083 the functionality of the RE engine.
2084
2085 Suppose that we want to enable a new RE escape-sequence C<\Y|> which
2086 matches at a boundary between whitespace characters and non-whitespace
2087 characters.  Note that C<(?=\S)(?<!\S)|(?!\S)(?<=\S)> matches exactly
2088 at these positions, so we want to have each C<\Y|> in the place of the
2089 more complicated version.  We can create a module C<customre> to do
2090 this:
2091
2092     package customre;
2093     use overload;
2094
2095     sub import {
2096       shift;
2097       die "No argument to customre::import allowed" if @_;
2098       overload::constant 'qr' => \&convert;
2099     }
2100
2101     sub invalid { die "/$_[0]/: invalid escape '\\$_[1]'"}
2102
2103     # We must also take care of not escaping the legitimate \\Y|
2104     # sequence, hence the presence of '\\' in the conversion rules.
2105     my %rules = ( '\\' => '\\\\',
2106                   'Y|' => qr/(?=\S)(?<!\S)|(?!\S)(?<=\S)/ );
2107     sub convert {
2108       my $re = shift;
2109       $re =~ s{
2110                 \\ ( \\ | Y . )
2111               }
2112               { $rules{$1} or invalid($re,$1) }sgex;
2113       return $re;
2114     }
2115
2116 Now C<use customre> enables the new escape in constant regular
2117 expressions, i.e., those without any runtime variable interpolations.
2118 As documented in L<overload>, this conversion will work only over
2119 literal parts of regular expressions.  For C<\Y|$re\Y|> the variable
2120 part of this regular expression needs to be converted explicitly
2121 (but only if the special meaning of C<\Y|> should be enabled inside $re):
2122
2123     use customre;
2124     $re = <>;
2125     chomp $re;
2126     $re = customre::convert $re;
2127     /\Y|$re\Y|/;
2128
2129 =head1 PCRE/Python Support
2130
2131 As of Perl 5.10.0, Perl supports several Python/PCRE specific extensions
2132 to the regex syntax. While Perl programmers are encouraged to use the
2133 Perl specific syntax, the following are also accepted:
2134
2135 =over 4
2136
2137 =item C<< (?PE<lt>NAMEE<gt>pattern) >>
2138
2139 Define a named capture buffer. Equivalent to C<< (?<NAME>pattern) >>.
2140
2141 =item C<< (?P=NAME) >>
2142
2143 Backreference to a named capture buffer. Equivalent to C<< \g{NAME} >>.
2144
2145 =item C<< (?P>NAME) >>
2146
2147 Subroutine call to a named capture buffer. Equivalent to C<< (?&NAME) >>.
2148
2149 =back
2150
2151 =head1 BUGS
2152
2153 This document varies from difficult to understand to completely
2154 and utterly opaque.  The wandering prose riddled with jargon is
2155 hard to fathom in several places.
2156
2157 This document needs a rewrite that separates the tutorial content
2158 from the reference content.
2159
2160 =head1 SEE ALSO
2161
2162 L<perlrequick>.
2163
2164 L<perlretut>.
2165
2166 L<perlop/"Regexp Quote-Like Operators">.
2167
2168 L<perlop/"Gory details of parsing quoted constructs">.
2169
2170 L<perlfaq6>.
2171
2172 L<perlfunc/pos>.
2173
2174 L<perllocale>.
2175
2176 L<perlebcdic>.
2177
2178 I<Mastering Regular Expressions> by Jeffrey Friedl, published
2179 by O'Reilly and Associates.