Avoid a possible race condition where a parallel make might
[perl.git] / pod / perlmod.pod
1 =head1 NAME
2
3 perlmod - Perl modules (packages and symbol tables)
4
5 =head1 DESCRIPTION
6
7 =head2 Packages
8 X<package> X<namespace> X<variable, global> X<global variable> X<global>
9
10 Perl provides a mechanism for alternative namespaces to protect
11 packages from stomping on each other's variables.  In fact, there's
12 really no such thing as a global variable in Perl.  The package
13 statement declares the compilation unit as being in the given
14 namespace.  The scope of the package declaration is from the
15 declaration itself through the end of the enclosing block, C<eval>,
16 or file, whichever comes first (the same scope as the my() and
17 local() operators).  Unqualified dynamic identifiers will be in
18 this namespace, except for those few identifiers that if unqualified,
19 default to the main package instead of the current one as described
20 below.  A package statement affects only dynamic variables--including
21 those you've used local() on--but I<not> lexical variables created
22 with my().  Typically it would be the first declaration in a file
23 included by the C<do>, C<require>, or C<use> operators.  You can
24 switch into a package in more than one place; it merely influences
25 which symbol table is used by the compiler for the rest of that
26 block.  You can refer to variables and filehandles in other packages
27 by prefixing the identifier with the package name and a double
28 colon: C<$Package::Variable>.  If the package name is null, the
29 C<main> package is assumed.  That is, C<$::sail> is equivalent to
30 C<$main::sail>.
31
32 The old package delimiter was a single quote, but double colon is now the
33 preferred delimiter, in part because it's more readable to humans, and
34 in part because it's more readable to B<emacs> macros.  It also makes C++
35 programmers feel like they know what's going on--as opposed to using the
36 single quote as separator, which was there to make Ada programmers feel
37 like they knew what was going on.  Because the old-fashioned syntax is still
38 supported for backwards compatibility, if you try to use a string like
39 C<"This is $owner's house">, you'll be accessing C<$owner::s>; that is,
40 the $s variable in package C<owner>, which is probably not what you meant.
41 Use braces to disambiguate, as in C<"This is ${owner}'s house">.
42 X<::> X<'>
43
44 Packages may themselves contain package separators, as in
45 C<$OUTER::INNER::var>.  This implies nothing about the order of
46 name lookups, however.  There are no relative packages: all symbols
47 are either local to the current package, or must be fully qualified
48 from the outer package name down.  For instance, there is nowhere
49 within package C<OUTER> that C<$INNER::var> refers to
50 C<$OUTER::INNER::var>.  C<INNER> refers to a totally
51 separate global package.
52
53 Only identifiers starting with letters (or underscore) are stored
54 in a package's symbol table.  All other symbols are kept in package
55 C<main>, including all punctuation variables, like $_.  In addition,
56 when unqualified, the identifiers STDIN, STDOUT, STDERR, ARGV,
57 ARGVOUT, ENV, INC, and SIG are forced to be in package C<main>,
58 even when used for other purposes than their built-in ones.  If you
59 have a package called C<m>, C<s>, or C<y>, then you can't use the
60 qualified form of an identifier because it would be instead interpreted
61 as a pattern match, a substitution, or a transliteration.
62 X<variable, punctuation> 
63
64 Variables beginning with underscore used to be forced into package
65 main, but we decided it was more useful for package writers to be able
66 to use leading underscore to indicate private variables and method names.
67 However, variables and functions named with a single C<_>, such as
68 $_ and C<sub _>, are still forced into the package C<main>.  See also
69 L<perlvar/"Technical Note on the Syntax of Variable Names">.
70
71 C<eval>ed strings are compiled in the package in which the eval() was
72 compiled.  (Assignments to C<$SIG{}>, however, assume the signal
73 handler specified is in the C<main> package.  Qualify the signal handler
74 name if you wish to have a signal handler in a package.)  For an
75 example, examine F<perldb.pl> in the Perl library.  It initially switches
76 to the C<DB> package so that the debugger doesn't interfere with variables
77 in the program you are trying to debug.  At various points, however, it
78 temporarily switches back to the C<main> package to evaluate various
79 expressions in the context of the C<main> package (or wherever you came
80 from).  See L<perldebug>.
81
82 The special symbol C<__PACKAGE__> contains the current package, but cannot
83 (easily) be used to construct variable names.
84
85 See L<perlsub> for other scoping issues related to my() and local(),
86 and L<perlref> regarding closures.
87
88 =head2 Symbol Tables
89 X<symbol table> X<stash> X<%::> X<%main::> X<typeglob> X<glob> X<alias>
90
91 The symbol table for a package happens to be stored in the hash of that
92 name with two colons appended.  The main symbol table's name is thus
93 C<%main::>, or C<%::> for short.  Likewise the symbol table for the nested
94 package mentioned earlier is named C<%OUTER::INNER::>.
95
96 The value in each entry of the hash is what you are referring to when you
97 use the C<*name> typeglob notation.
98
99     local *main::foo    = *main::bar;
100
101 You can use this to print out all the variables in a package, for
102 instance.  The standard but antiquated F<dumpvar.pl> library and
103 the CPAN module Devel::Symdump make use of this.
104
105 Assignment to a typeglob performs an aliasing operation, i.e.,
106
107     *dick = *richard;
108
109 causes variables, subroutines, formats, and file and directory handles
110 accessible via the identifier C<richard> also to be accessible via the
111 identifier C<dick>.  If you want to alias only a particular variable or
112 subroutine, assign a reference instead:
113
114     *dick = \$richard;
115
116 Which makes $richard and $dick the same variable, but leaves
117 @richard and @dick as separate arrays.  Tricky, eh?
118
119 There is one subtle difference between the following statements:
120
121     *foo = *bar;
122     *foo = \$bar;
123
124 C<*foo = *bar> makes the typeglobs themselves synonymous while
125 C<*foo = \$bar> makes the SCALAR portions of two distinct typeglobs
126 refer to the same scalar value. This means that the following code:
127
128     $bar = 1;
129     *foo = \$bar;       # Make $foo an alias for $bar
130
131     {
132         local $bar = 2; # Restrict changes to block
133         print $foo;     # Prints '1'!
134     }
135
136 Would print '1', because C<$foo> holds a reference to the I<original>
137 C<$bar> -- the one that was stuffed away by C<local()> and which will be
138 restored when the block ends. Because variables are accessed through the
139 typeglob, you can use C<*foo = *bar> to create an alias which can be
140 localized. (But be aware that this means you can't have a separate
141 C<@foo> and C<@bar>, etc.)
142
143 What makes all of this important is that the Exporter module uses glob
144 aliasing as the import/export mechanism. Whether or not you can properly
145 localize a variable that has been exported from a module depends on how
146 it was exported:
147
148     @EXPORT = qw($FOO); # Usual form, can't be localized
149     @EXPORT = qw(*FOO); # Can be localized
150
151 You can work around the first case by using the fully qualified name
152 (C<$Package::FOO>) where you need a local value, or by overriding it
153 by saying C<*FOO = *Package::FOO> in your script.
154
155 The C<*x = \$y> mechanism may be used to pass and return cheap references
156 into or from subroutines if you don't want to copy the whole
157 thing.  It only works when assigning to dynamic variables, not
158 lexicals.
159
160     %some_hash = ();                    # can't be my()
161     *some_hash = fn( \%another_hash );
162     sub fn {
163         local *hashsym = shift;
164         # now use %hashsym normally, and you
165         # will affect the caller's %another_hash
166         my %nhash = (); # do what you want
167         return \%nhash;
168     }
169
170 On return, the reference will overwrite the hash slot in the
171 symbol table specified by the *some_hash typeglob.  This
172 is a somewhat tricky way of passing around references cheaply
173 when you don't want to have to remember to dereference variables
174 explicitly.
175
176 Another use of symbol tables is for making "constant" scalars.
177 X<constant> X<scalar, constant>
178
179     *PI = \3.14159265358979;
180
181 Now you cannot alter C<$PI>, which is probably a good thing all in all.
182 This isn't the same as a constant subroutine, which is subject to
183 optimization at compile-time.  A constant subroutine is one prototyped
184 to take no arguments and to return a constant expression.  See
185 L<perlsub> for details on these.  The C<use constant> pragma is a
186 convenient shorthand for these.
187
188 You can say C<*foo{PACKAGE}> and C<*foo{NAME}> to find out what name and
189 package the *foo symbol table entry comes from.  This may be useful
190 in a subroutine that gets passed typeglobs as arguments:
191
192     sub identify_typeglob {
193         my $glob = shift;
194         print 'You gave me ', *{$glob}{PACKAGE}, '::', *{$glob}{NAME}, "\n";
195     }
196     identify_typeglob *foo;
197     identify_typeglob *bar::baz;
198
199 This prints
200
201     You gave me main::foo
202     You gave me bar::baz
203
204 The C<*foo{THING}> notation can also be used to obtain references to the
205 individual elements of *foo.  See L<perlref>.
206
207 Subroutine definitions (and declarations, for that matter) need
208 not necessarily be situated in the package whose symbol table they
209 occupy.  You can define a subroutine outside its package by
210 explicitly qualifying the name of the subroutine:
211
212     package main;
213     sub Some_package::foo { ... }   # &foo defined in Some_package
214
215 This is just a shorthand for a typeglob assignment at compile time:
216
217     BEGIN { *Some_package::foo = sub { ... } }
218
219 and is I<not> the same as writing:
220
221     {
222         package Some_package;
223         sub foo { ... }
224     }
225
226 In the first two versions, the body of the subroutine is
227 lexically in the main package, I<not> in Some_package. So
228 something like this:
229
230     package main;
231
232     $Some_package::name = "fred";
233     $main::name = "barney";
234
235     sub Some_package::foo {
236         print "in ", __PACKAGE__, ": \$name is '$name'\n";
237     }
238
239     Some_package::foo();
240
241 prints:
242
243     in main: $name is 'barney'
244
245 rather than:
246
247     in Some_package: $name is 'fred'
248
249 This also has implications for the use of the SUPER:: qualifier
250 (see L<perlobj>).
251
252 =head2 BEGIN, UNITCHECK, CHECK, INIT and END
253 X<BEGIN> X<UNITCHECK> X<CHECK> X<INIT> X<END>
254
255 Five specially named code blocks are executed at the beginning and at
256 the end of a running Perl program.  These are the C<BEGIN>,
257 C<UNITCHECK>, C<CHECK>, C<INIT>, and C<END> blocks.
258
259 These code blocks can be prefixed with C<sub> to give the appearance of a
260 subroutine (although this is not considered good style).  One should note
261 that these code blocks don't really exist as named subroutines (despite
262 their appearance). The thing that gives this away is the fact that you can
263 have B<more than one> of these code blocks in a program, and they will get
264 B<all> executed at the appropriate moment.  So you can't execute any of
265 these code blocks by name.
266
267 A C<BEGIN> code block is executed as soon as possible, that is, the moment
268 it is completely defined, even before the rest of the containing file (or
269 string) is parsed.  You may have multiple C<BEGIN> blocks within a file (or
270 eval'ed string) -- they will execute in order of definition.  Because a C<BEGIN>
271 code block executes immediately, it can pull in definitions of subroutines
272 and such from other files in time to be visible to the rest of the compile
273 and run time.  Once a C<BEGIN> has run, it is immediately undefined and any
274 code it used is returned to Perl's memory pool.
275
276 An C<END> code block is executed as late as possible, that is, after
277 perl has finished running the program and just before the interpreter
278 is being exited, even if it is exiting as a result of a die() function.
279 (But not if it's morphing into another program via C<exec>, or
280 being blown out of the water by a signal--you have to trap that yourself
281 (if you can).)  You may have multiple C<END> blocks within a file--they
282 will execute in reverse order of definition; that is: last in, first
283 out (LIFO).  C<END> blocks are not executed when you run perl with the
284 C<-c> switch, or if compilation fails.
285
286 Note that C<END> code blocks are B<not> executed at the end of a string
287 C<eval()>: if any C<END> code blocks are created in a string C<eval()>,
288 they will be executed just as any other C<END> code block of that package
289 in LIFO order just before the interpreter is being exited.
290
291 Inside an C<END> code block, C<$?> contains the value that the program is
292 going to pass to C<exit()>.  You can modify C<$?> to change the exit
293 value of the program.  Beware of changing C<$?> by accident (e.g. by
294 running something via C<system>).
295 X<$?>
296
297 C<UNITCHECK>, C<CHECK> and C<INIT> code blocks are useful to catch the
298 transition between the compilation phase and the execution phase of
299 the main program.
300
301 C<UNITCHECK> blocks are run just after the unit which defined them has
302 been compiled.  The main program file and each module it loads are
303 compilation units, as are string C<eval>s, code compiled using the
304 C<(?{ })> construct in a regex, calls to C<do FILE>, C<require FILE>,
305 and code after the C<-e> switch on the command line.
306
307 C<CHECK> code blocks are run just after the B<initial> Perl compile phase ends
308 and before the run time begins, in LIFO order.  C<CHECK> code blocks are used
309 in the Perl compiler suite to save the compiled state of the program.
310
311 C<INIT> blocks are run just before the Perl runtime begins execution, in
312 "first in, first out" (FIFO) order.
313
314 The C<CHECK> and C<INIT> code blocks will not be executed inside a string
315 eval(), if that eval() happens after the end of the main compilation
316 phase; that can be a problem in mod_perl and other persistent environments
317 which use C<eval STRING> to load code at runtime.
318
319 When you use the B<-n> and B<-p> switches to Perl, C<BEGIN> and
320 C<END> work just as they do in B<awk>, as a degenerate case.
321 Both C<BEGIN> and C<CHECK> blocks are run when you use the B<-c>
322 switch for a compile-only syntax check, although your main code
323 is not.
324
325 The B<begincheck> program makes it all clear, eventually:
326
327   #!/usr/bin/perl
328
329   # begincheck
330
331   print         "10. Ordinary code runs at runtime.\n";
332
333   END { print   "16.   So this is the end of the tale.\n" }
334   INIT { print  " 7. INIT blocks run FIFO just before runtime.\n" }
335   UNITCHECK {
336     print       " 4.   And therefore before any CHECK blocks.\n"
337   }
338   CHECK { print " 6.   So this is the sixth line.\n" }
339
340   print         "11.   It runs in order, of course.\n";
341
342   BEGIN { print " 1. BEGIN blocks run FIFO during compilation.\n" }
343   END { print   "15.   Read perlmod for the rest of the story.\n" }
344   CHECK { print " 5. CHECK blocks run LIFO after all compilation.\n" }
345   INIT { print  " 8.   Run this again, using Perl's -c switch.\n" }
346
347   print         "12.   This is anti-obfuscated code.\n";
348
349   END { print   "14. END blocks run LIFO at quitting time.\n" }
350   BEGIN { print " 2.   So this line comes out second.\n" }
351   UNITCHECK {
352    print " 3. UNITCHECK blocks run LIFO after each file is compiled.\n"
353   }
354   INIT { print  " 9.   You'll see the difference right away.\n" }
355
356   print         "13.   It merely _looks_ like it should be confusing.\n";
357
358   __END__
359
360 =head2 Perl Classes
361 X<class> X<@ISA>
362
363 There is no special class syntax in Perl, but a package may act
364 as a class if it provides subroutines to act as methods.  Such a
365 package may also derive some of its methods from another class (package)
366 by listing the other package name(s) in its global @ISA array (which
367 must be a package global, not a lexical).
368
369 For more on this, see L<perltoot> and L<perlobj>.
370
371 =head2 Perl Modules
372 X<module>
373
374 A module is just a set of related functions in a library file, i.e.,
375 a Perl package with the same name as the file.  It is specifically
376 designed to be reusable by other modules or programs.  It may do this
377 by providing a mechanism for exporting some of its symbols into the
378 symbol table of any package using it, or it may function as a class
379 definition and make its semantics available implicitly through
380 method calls on the class and its objects, without explicitly
381 exporting anything.  Or it can do a little of both.
382
383 For example, to start a traditional, non-OO module called Some::Module,
384 create a file called F<Some/Module.pm> and start with this template:
385
386     package Some::Module;  # assumes Some/Module.pm
387
388     use strict;
389     use warnings;
390
391     BEGIN {
392         use Exporter   ();
393         our ($VERSION, @ISA, @EXPORT, @EXPORT_OK, %EXPORT_TAGS);
394
395         # set the version for version checking
396         $VERSION     = 1.00;
397         # if using RCS/CVS, this may be preferred
398         $VERSION = sprintf "%d.%03d", q$Revision: 1.1 $ =~ /(\d+)/g;
399
400         @ISA         = qw(Exporter);
401         @EXPORT      = qw(&func1 &func2 &func4);
402         %EXPORT_TAGS = ( );     # eg: TAG => [ qw!name1 name2! ],
403
404         # your exported package globals go here,
405         # as well as any optionally exported functions
406         @EXPORT_OK   = qw($Var1 %Hashit &func3);
407     }
408     our @EXPORT_OK;
409
410     # exported package globals go here
411     our $Var1;
412     our %Hashit;
413
414     # non-exported package globals go here
415     our @more;
416     our $stuff;
417
418     # initialize package globals, first exported ones
419     $Var1   = '';
420     %Hashit = ();
421
422     # then the others (which are still accessible as $Some::Module::stuff)
423     $stuff  = '';
424     @more   = ();
425
426     # all file-scoped lexicals must be created before
427     # the functions below that use them.
428
429     # file-private lexicals go here
430     my $priv_var    = '';
431     my %secret_hash = ();
432
433     # here's a file-private function as a closure,
434     # callable as &$priv_func;  it cannot be prototyped.
435     my $priv_func = sub {
436         # stuff goes here.
437     };
438
439     # make all your functions, whether exported or not;
440     # remember to put something interesting in the {} stubs
441     sub func1      {}    # no prototype
442     sub func2()    {}    # proto'd void
443     sub func3($$)  {}    # proto'd to 2 scalars
444
445     # this one isn't exported, but could be called!
446     sub func4(\%)  {}    # proto'd to 1 hash ref
447
448     END { }       # module clean-up code here (global destructor)
449
450     ## YOUR CODE GOES HERE
451
452     1;  # don't forget to return a true value from the file
453
454 Then go on to declare and use your variables in functions without
455 any qualifications.  See L<Exporter> and the L<perlmodlib> for
456 details on mechanics and style issues in module creation.
457
458 Perl modules are included into your program by saying
459
460     use Module;
461
462 or
463
464     use Module LIST;
465
466 This is exactly equivalent to
467
468     BEGIN { require Module; import Module; }
469
470 or
471
472     BEGIN { require Module; import Module LIST; }
473
474 As a special case
475
476     use Module ();
477
478 is exactly equivalent to
479
480     BEGIN { require Module; }
481
482 All Perl module files have the extension F<.pm>.  The C<use> operator
483 assumes this so you don't have to spell out "F<Module.pm>" in quotes.
484 This also helps to differentiate new modules from old F<.pl> and
485 F<.ph> files.  Module names are also capitalized unless they're
486 functioning as pragmas; pragmas are in effect compiler directives,
487 and are sometimes called "pragmatic modules" (or even "pragmata"
488 if you're a classicist).
489
490 The two statements:
491
492     require SomeModule;
493     require "SomeModule.pm";
494
495 differ from each other in two ways.  In the first case, any double
496 colons in the module name, such as C<Some::Module>, are translated
497 into your system's directory separator, usually "/".   The second
498 case does not, and would have to be specified literally.  The other
499 difference is that seeing the first C<require> clues in the compiler
500 that uses of indirect object notation involving "SomeModule", as
501 in C<$ob = purge SomeModule>, are method calls, not function calls.
502 (Yes, this really can make a difference.)
503
504 Because the C<use> statement implies a C<BEGIN> block, the importing
505 of semantics happens as soon as the C<use> statement is compiled,
506 before the rest of the file is compiled.  This is how it is able
507 to function as a pragma mechanism, and also how modules are able to
508 declare subroutines that are then visible as list or unary operators for
509 the rest of the current file.  This will not work if you use C<require>
510 instead of C<use>.  With C<require> you can get into this problem:
511
512     require Cwd;                # make Cwd:: accessible
513     $here = Cwd::getcwd();
514
515     use Cwd;                    # import names from Cwd::
516     $here = getcwd();
517
518     require Cwd;                # make Cwd:: accessible
519     $here = getcwd();           # oops! no main::getcwd()
520
521 In general, C<use Module ()> is recommended over C<require Module>,
522 because it determines module availability at compile time, not in the
523 middle of your program's execution.  An exception would be if two modules
524 each tried to C<use> each other, and each also called a function from
525 that other module.  In that case, it's easy to use C<require> instead.
526
527 Perl packages may be nested inside other package names, so we can have
528 package names containing C<::>.  But if we used that package name
529 directly as a filename it would make for unwieldy or impossible
530 filenames on some systems.  Therefore, if a module's name is, say,
531 C<Text::Soundex>, then its definition is actually found in the library
532 file F<Text/Soundex.pm>.
533
534 Perl modules always have a F<.pm> file, but there may also be
535 dynamically linked executables (often ending in F<.so>) or autoloaded
536 subroutine definitions (often ending in F<.al>) associated with the
537 module.  If so, these will be entirely transparent to the user of
538 the module.  It is the responsibility of the F<.pm> file to load
539 (or arrange to autoload) any additional functionality.  For example,
540 although the POSIX module happens to do both dynamic loading and
541 autoloading, the user can say just C<use POSIX> to get it all.
542
543 =head2 Making your module threadsafe
544 X<threadsafe> X<thread safe>
545 X<module, threadsafe> X<module, thread safe>
546 X<CLONE> X<CLONE_SKIP> X<thread> X<threads> X<ithread>
547
548 Since 5.6.0, Perl has had support for a new type of threads called
549 interpreter threads (ithreads). These threads can be used explicitly
550 and implicitly.
551
552 Ithreads work by cloning the data tree so that no data is shared
553 between different threads. These threads can be used by using the C<threads>
554 module or by doing fork() on win32 (fake fork() support). When a
555 thread is cloned all Perl data is cloned, however non-Perl data cannot
556 be cloned automatically.  Perl after 5.7.2 has support for the C<CLONE>
557 special subroutine.  In C<CLONE> you can do whatever
558 you need to do,
559 like for example handle the cloning of non-Perl data, if necessary.
560 C<CLONE> will be called once as a class method for every package that has it
561 defined (or inherits it).  It will be called in the context of the new thread,
562 so all modifications are made in the new area.  Currently CLONE is called with
563 no parameters other than the invocant package name, but code should not assume
564 that this will remain unchanged, as it is likely that in future extra parameters
565 will be passed in to give more information about the state of cloning.
566
567 If you want to CLONE all objects you will need to keep track of them per
568 package. This is simply done using a hash and Scalar::Util::weaken().
569
570 Perl after 5.8.7 has support for the C<CLONE_SKIP> special subroutine.
571 Like C<CLONE>, C<CLONE_SKIP> is called once per package; however, it is
572 called just before cloning starts, and in the context of the parent
573 thread. If it returns a true value, then no objects of that class will
574 be cloned; or rather, they will be copied as unblessed, undef values.
575 For example: if in the parent there are two references to a single blessed
576 hash, then in the child there will be two references to a single undefined
577 scalar value instead.
578 This provides a simple mechanism for making a module threadsafe; just add
579 C<sub CLONE_SKIP { 1 }> at the top of the class, and C<DESTROY()> will be
580 now only be called once per object. Of course, if the child thread needs
581 to make use of the objects, then a more sophisticated approach is
582 needed.
583
584 Like C<CLONE>, C<CLONE_SKIP> is currently called with no parameters other
585 than the invocant package name, although that may change. Similarly, to
586 allow for future expansion, the return value should be a single C<0> or
587 C<1> value.
588
589 =head1 SEE ALSO
590
591 See L<perlmodlib> for general style issues related to building Perl
592 modules and classes, as well as descriptions of the standard library
593 and CPAN, L<Exporter> for how Perl's standard import/export mechanism
594 works, L<perltoot> and L<perltooc> for an in-depth tutorial on
595 creating classes, L<perlobj> for a hard-core reference document on
596 objects, L<perlsub> for an explanation of functions and scoping,
597 and L<perlxstut> and L<perlguts> for more information on writing
598 extension modules.