Avoid a possible race condition where a parallel make might
[perl.git] / pod / perlfunc.pod
1 =head1 NAME
2 X<function>
3
4 perlfunc - Perl builtin functions
5
6 =head1 DESCRIPTION
7
8 The functions in this section can serve as terms in an expression.
9 They fall into two major categories: list operators and named unary
10 operators.  These differ in their precedence relationship with a
11 following comma.  (See the precedence table in L<perlop>.)  List
12 operators take more than one argument, while unary operators can never
13 take more than one argument.  Thus, a comma terminates the argument of
14 a unary operator, but merely separates the arguments of a list
15 operator.  A unary operator generally provides a scalar context to its
16 argument, while a list operator may provide either scalar or list
17 contexts for its arguments.  If it does both, the scalar arguments will
18 be first, and the list argument will follow.  (Note that there can ever
19 be only one such list argument.)  For instance, splice() has three scalar
20 arguments followed by a list, whereas gethostbyname() has four scalar
21 arguments.
22
23 In the syntax descriptions that follow, list operators that expect a
24 list (and provide list context for the elements of the list) are shown
25 with LIST as an argument.  Such a list may consist of any combination
26 of scalar arguments or list values; the list values will be included
27 in the list as if each individual element were interpolated at that
28 point in the list, forming a longer single-dimensional list value.
29 Commas should separate elements of the LIST.
30
31 Any function in the list below may be used either with or without
32 parentheses around its arguments.  (The syntax descriptions omit the
33 parentheses.)  If you use the parentheses, the simple (but occasionally
34 surprising) rule is this: It I<looks> like a function, therefore it I<is> a
35 function, and precedence doesn't matter.  Otherwise it's a list
36 operator or unary operator, and precedence does matter.  And whitespace
37 between the function and left parenthesis doesn't count--so you need to
38 be careful sometimes:
39
40     print 1+2+4;      # Prints 7.
41     print(1+2) + 4;   # Prints 3.
42     print (1+2)+4;    # Also prints 3!
43     print +(1+2)+4;   # Prints 7.
44     print ((1+2)+4);  # Prints 7.
45
46 If you run Perl with the B<-w> switch it can warn you about this.  For
47 example, the third line above produces:
48
49     print (...) interpreted as function at - line 1.
50     Useless use of integer addition in void context at - line 1.
51
52 A few functions take no arguments at all, and therefore work as neither
53 unary nor list operators.  These include such functions as C<time>
54 and C<endpwent>.  For example, C<time+86_400> always means
55 C<time() + 86_400>.
56
57 For functions that can be used in either a scalar or list context,
58 nonabortive failure is generally indicated in a scalar context by
59 returning the undefined value, and in a list context by returning the
60 null list.
61
62 Remember the following important rule: There is B<no rule> that relates
63 the behavior of an expression in list context to its behavior in scalar
64 context, or vice versa.  It might do two totally different things.
65 Each operator and function decides which sort of value it would be most
66 appropriate to return in scalar context.  Some operators return the
67 length of the list that would have been returned in list context.  Some
68 operators return the first value in the list.  Some operators return the
69 last value in the list.  Some operators return a count of successful
70 operations.  In general, they do what you want, unless you want
71 consistency.
72 X<context>
73
74 A named array in scalar context is quite different from what would at
75 first glance appear to be a list in scalar context.  You can't get a list
76 like C<(1,2,3)> into being in scalar context, because the compiler knows
77 the context at compile time.  It would generate the scalar comma operator
78 there, not the list construction version of the comma.  That means it
79 was never a list to start with.
80
81 In general, functions in Perl that serve as wrappers for system calls
82 of the same name (like chown(2), fork(2), closedir(2), etc.) all return
83 true when they succeed and C<undef> otherwise, as is usually mentioned
84 in the descriptions below.  This is different from the C interfaces,
85 which return C<-1> on failure.  Exceptions to this rule are C<wait>,
86 C<waitpid>, and C<syscall>.  System calls also set the special C<$!>
87 variable on failure.  Other functions do not, except accidentally.
88
89 Extension modules can also hook into the Perl parser to define new
90 kinds of keyword-headed expression.  These may look like functions, but
91 may also look completely different.  The syntax following the keyword
92 is defined entirely by the extension.  If you are an implementor, see
93 L<perlapi/PL_keyword_plugin> for the mechanism.  If you are using such
94 a module, see the module's documentation for details of the syntax that
95 it defines.
96
97 =head2 Perl Functions by Category
98 X<function>
99
100 Here are Perl's functions (including things that look like
101 functions, like some keywords and named operators)
102 arranged by category.  Some functions appear in more
103 than one place.
104
105 =over 4
106
107 =item Functions for SCALARs or strings
108 X<scalar> X<string> X<character>
109
110 C<chomp>, C<chop>, C<chr>, C<crypt>, C<hex>, C<index>, C<lc>, C<lcfirst>,
111 C<length>, C<oct>, C<ord>, C<pack>, C<q//>, C<qq//>, C<reverse>,
112 C<rindex>, C<sprintf>, C<substr>, C<tr///>, C<uc>, C<ucfirst>, C<y///>
113
114 =item Regular expressions and pattern matching
115 X<regular expression> X<regex> X<regexp>
116
117 C<m//>, C<pos>, C<quotemeta>, C<s///>, C<split>, C<study>, C<qr//>
118
119 =item Numeric functions
120 X<numeric> X<number> X<trigonometric> X<trigonometry>
121
122 C<abs>, C<atan2>, C<cos>, C<exp>, C<hex>, C<int>, C<log>, C<oct>, C<rand>,
123 C<sin>, C<sqrt>, C<srand>
124
125 =item Functions for real @ARRAYs
126 X<array>
127
128 C<pop>, C<push>, C<shift>, C<splice>, C<unshift>
129
130 =item Functions for list data
131 X<list>
132
133 C<grep>, C<join>, C<map>, C<qw//>, C<reverse>, C<sort>, C<unpack>
134
135 =item Functions for real %HASHes
136 X<hash>
137
138 C<delete>, C<each>, C<exists>, C<keys>, C<values>
139
140 =item Input and output functions
141 X<I/O> X<input> X<output> X<dbm>
142
143 C<binmode>, C<close>, C<closedir>, C<dbmclose>, C<dbmopen>, C<die>, C<eof>,
144 C<fileno>, C<flock>, C<format>, C<getc>, C<print>, C<printf>, C<read>,
145 C<readdir>, C<rewinddir>, C<say>, C<seek>, C<seekdir>, C<select>, C<syscall>,
146 C<sysread>, C<sysseek>, C<syswrite>, C<tell>, C<telldir>, C<truncate>,
147 C<warn>, C<write>
148
149 =item Functions for fixed length data or records
150
151 C<pack>, C<read>, C<syscall>, C<sysread>, C<syswrite>, C<unpack>, C<vec>
152
153 =item Functions for filehandles, files, or directories
154 X<file> X<filehandle> X<directory> X<pipe> X<link> X<symlink>
155
156 C<-I<X>>, C<chdir>, C<chmod>, C<chown>, C<chroot>, C<fcntl>, C<glob>,
157 C<ioctl>, C<link>, C<lstat>, C<mkdir>, C<open>, C<opendir>,
158 C<readlink>, C<rename>, C<rmdir>, C<stat>, C<symlink>, C<sysopen>,
159 C<umask>, C<unlink>, C<utime>
160
161 =item Keywords related to the control flow of your Perl program
162 X<control flow>
163
164 C<caller>, C<continue>, C<die>, C<do>, C<dump>, C<eval>, C<exit>,
165 C<goto>, C<last>, C<next>, C<redo>, C<return>, C<sub>, C<wantarray>
166
167 =item Keywords related to switch
168
169 C<break>, C<continue>, C<given>, C<when>, C<default>
170
171 (These are only available if you enable the "switch" feature.
172 See L<feature> and L<perlsyn/"Switch statements">.)
173
174 =item Keywords related to scoping
175
176 C<caller>, C<import>, C<local>, C<my>, C<our>, C<state>, C<package>,
177 C<use>
178
179 (C<state> is only available if the "state" feature is enabled. See
180 L<feature>.)
181
182 =item Miscellaneous functions
183
184 C<defined>, C<dump>, C<eval>, C<formline>, C<local>, C<my>, C<our>,
185 C<reset>, C<scalar>, C<state>, C<undef>, C<wantarray>
186
187 =item Functions for processes and process groups
188 X<process> X<pid> X<process id>
189
190 C<alarm>, C<exec>, C<fork>, C<getpgrp>, C<getppid>, C<getpriority>, C<kill>,
191 C<pipe>, C<qx//>, C<setpgrp>, C<setpriority>, C<sleep>, C<system>,
192 C<times>, C<wait>, C<waitpid>
193
194 =item Keywords related to perl modules
195 X<module>
196
197 C<do>, C<import>, C<no>, C<package>, C<require>, C<use>
198
199 =item Keywords related to classes and object-orientation
200 X<object> X<class> X<package>
201
202 C<bless>, C<dbmclose>, C<dbmopen>, C<package>, C<ref>, C<tie>, C<tied>,
203 C<untie>, C<use>
204
205 =item Low-level socket functions
206 X<socket> X<sock>
207
208 C<accept>, C<bind>, C<connect>, C<getpeername>, C<getsockname>,
209 C<getsockopt>, C<listen>, C<recv>, C<send>, C<setsockopt>, C<shutdown>,
210 C<socket>, C<socketpair>
211
212 =item System V interprocess communication functions
213 X<IPC> X<System V> X<semaphore> X<shared memory> X<memory> X<message>
214
215 C<msgctl>, C<msgget>, C<msgrcv>, C<msgsnd>, C<semctl>, C<semget>, C<semop>,
216 C<shmctl>, C<shmget>, C<shmread>, C<shmwrite>
217
218 =item Fetching user and group info
219 X<user> X<group> X<password> X<uid> X<gid>  X<passwd> X</etc/passwd>
220
221 C<endgrent>, C<endhostent>, C<endnetent>, C<endpwent>, C<getgrent>,
222 C<getgrgid>, C<getgrnam>, C<getlogin>, C<getpwent>, C<getpwnam>,
223 C<getpwuid>, C<setgrent>, C<setpwent>
224
225 =item Fetching network info
226 X<network> X<protocol> X<host> X<hostname> X<IP> X<address> X<service>
227
228 C<endprotoent>, C<endservent>, C<gethostbyaddr>, C<gethostbyname>,
229 C<gethostent>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
230 C<getprotobyname>, C<getprotobynumber>, C<getprotoent>,
231 C<getservbyname>, C<getservbyport>, C<getservent>, C<sethostent>,
232 C<setnetent>, C<setprotoent>, C<setservent>
233
234 =item Time-related functions
235 X<time> X<date>
236
237 C<gmtime>, C<localtime>, C<time>, C<times>
238
239 =item Functions new in perl5
240 X<perl5>
241
242 C<abs>, C<bless>, C<break>, C<chomp>, C<chr>, C<continue>, C<default>, 
243 C<exists>, C<formline>, C<given>, C<glob>, C<import>, C<lc>, C<lcfirst>,
244 C<lock>, C<map>, C<my>, C<no>, C<our>, C<prototype>, C<qr//>, C<qw//>, C<qx//>,
245 C<readline>, C<readpipe>, C<ref>, C<sub>*, C<sysopen>, C<tie>, C<tied>, C<uc>,
246 C<ucfirst>, C<untie>, C<use>, C<when>
247
248 * - C<sub> was a keyword in perl4, but in perl5 it is an
249 operator, which can be used in expressions.
250
251 =item Functions obsoleted in perl5
252
253 C<dbmclose>, C<dbmopen>
254
255 =back
256
257 =head2 Portability
258 X<portability> X<Unix> X<portable>
259
260 Perl was born in Unix and can therefore access all common Unix
261 system calls.  In non-Unix environments, the functionality of some
262 Unix system calls may not be available, or details of the available
263 functionality may differ slightly.  The Perl functions affected
264 by this are:
265
266 C<-X>, C<binmode>, C<chmod>, C<chown>, C<chroot>, C<crypt>,
267 C<dbmclose>, C<dbmopen>, C<dump>, C<endgrent>, C<endhostent>,
268 C<endnetent>, C<endprotoent>, C<endpwent>, C<endservent>, C<exec>,
269 C<fcntl>, C<flock>, C<fork>, C<getgrent>, C<getgrgid>, C<gethostbyname>,
270 C<gethostent>, C<getlogin>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
271 C<getppid>, C<getpgrp>, C<getpriority>, C<getprotobynumber>,
272 C<getprotoent>, C<getpwent>, C<getpwnam>, C<getpwuid>,
273 C<getservbyport>, C<getservent>, C<getsockopt>, C<glob>, C<ioctl>,
274 C<kill>, C<link>, C<lstat>, C<msgctl>, C<msgget>, C<msgrcv>,
275 C<msgsnd>, C<open>, C<pipe>, C<readlink>, C<rename>, C<select>, C<semctl>,
276 C<semget>, C<semop>, C<setgrent>, C<sethostent>, C<setnetent>,
277 C<setpgrp>, C<setpriority>, C<setprotoent>, C<setpwent>,
278 C<setservent>, C<setsockopt>, C<shmctl>, C<shmget>, C<shmread>,
279 C<shmwrite>, C<socket>, C<socketpair>,
280 C<stat>, C<symlink>, C<syscall>, C<sysopen>, C<system>,
281 C<times>, C<truncate>, C<umask>, C<unlink>,
282 C<utime>, C<wait>, C<waitpid>
283
284 For more information about the portability of these functions, see
285 L<perlport> and other available platform-specific documentation.
286
287 =head2 Alphabetical Listing of Perl Functions
288
289 =over 8
290
291 =item -X FILEHANDLE
292 X<-r>X<-w>X<-x>X<-o>X<-R>X<-W>X<-X>X<-O>X<-e>X<-z>X<-s>X<-f>X<-d>X<-l>X<-p>
293 X<-S>X<-b>X<-c>X<-t>X<-u>X<-g>X<-k>X<-T>X<-B>X<-M>X<-A>X<-C>
294
295 =item -X EXPR
296
297 =item -X DIRHANDLE
298
299 =item -X
300
301 A file test, where X is one of the letters listed below.  This unary
302 operator takes one argument, either a filename, a filehandle, or a dirhandle, 
303 and tests the associated file to see if something is true about it.  If the
304 argument is omitted, tests C<$_>, except for C<-t>, which tests STDIN.
305 Unless otherwise documented, it returns C<1> for true and C<''> for false, or
306 the undefined value if the file doesn't exist.  Despite the funny
307 names, precedence is the same as any other named unary operator.  The
308 operator may be any of:
309
310     -r  File is readable by effective uid/gid.
311     -w  File is writable by effective uid/gid.
312     -x  File is executable by effective uid/gid.
313     -o  File is owned by effective uid.
314
315     -R  File is readable by real uid/gid.
316     -W  File is writable by real uid/gid.
317     -X  File is executable by real uid/gid.
318     -O  File is owned by real uid.
319
320     -e  File exists.
321     -z  File has zero size (is empty).
322     -s  File has nonzero size (returns size in bytes).
323
324     -f  File is a plain file.
325     -d  File is a directory.
326     -l  File is a symbolic link.
327     -p  File is a named pipe (FIFO), or Filehandle is a pipe.
328     -S  File is a socket.
329     -b  File is a block special file.
330     -c  File is a character special file.
331     -t  Filehandle is opened to a tty.
332
333     -u  File has setuid bit set.
334     -g  File has setgid bit set.
335     -k  File has sticky bit set.
336
337     -T  File is an ASCII text file (heuristic guess).
338     -B  File is a "binary" file (opposite of -T).
339
340     -M  Script start time minus file modification time, in days.
341     -A  Same for access time.
342     -C  Same for inode change time (Unix, may differ for other platforms)
343
344 Example:
345
346     while (<>) {
347         chomp;
348         next unless -f $_;  # ignore specials
349         #...
350     }
351
352 The interpretation of the file permission operators C<-r>, C<-R>,
353 C<-w>, C<-W>, C<-x>, and C<-X> is by default based solely on the mode
354 of the file and the uids and gids of the user.  There may be other
355 reasons you can't actually read, write, or execute the file: for
356 example network filesystem access controls, ACLs (access control lists),
357 read-only filesystems, and unrecognized executable formats.  Note
358 that the use of these six specific operators to verify if some operation
359 is possible is usually a mistake, because it may be open to race
360 conditions.
361
362 Also note that, for the superuser on the local filesystems, the C<-r>,
363 C<-R>, C<-w>, and C<-W> tests always return 1, and C<-x> and C<-X> return 1
364 if any execute bit is set in the mode.  Scripts run by the superuser
365 may thus need to do a stat() to determine the actual mode of the file,
366 or temporarily set their effective uid to something else.
367
368 If you are using ACLs, there is a pragma called C<filetest> that may
369 produce more accurate results than the bare stat() mode bits.
370 When under the C<use filetest 'access'> the above-mentioned filetests
371 will test whether the permission can (not) be granted using the
372 access() family of system calls.  Also note that the C<-x> and C<-X> may
373 under this pragma return true even if there are no execute permission
374 bits set (nor any extra execute permission ACLs).  This strangeness is
375 due to the underlying system calls' definitions. Note also that, due to
376 the implementation of C<use filetest 'access'>, the C<_> special
377 filehandle won't cache the results of the file tests when this pragma is
378 in effect.  Read the documentation for the C<filetest> pragma for more
379 information.
380
381 Note that C<-s/a/b/> does not do a negated substitution.  Saying
382 C<-exp($foo)> still works as expected, however--only single letters
383 following a minus are interpreted as file tests.
384
385 The C<-T> and C<-B> switches work as follows.  The first block or so of the
386 file is examined for odd characters such as strange control codes or
387 characters with the high bit set.  If too many strange characters (>30%)
388 are found, it's a C<-B> file; otherwise it's a C<-T> file.  Also, any file
389 containing null in the first block is considered a binary file.  If C<-T>
390 or C<-B> is used on a filehandle, the current IO buffer is examined
391 rather than the first block.  Both C<-T> and C<-B> return true on a null
392 file, or a file at EOF when testing a filehandle.  Because you have to
393 read a file to do the C<-T> test, on most occasions you want to use a C<-f>
394 against the file first, as in C<next unless -f $file && -T $file>.
395
396 If any of the file tests (or either the C<stat> or C<lstat> operators) are given
397 the special filehandle consisting of a solitary underline, then the stat
398 structure of the previous file test (or stat operator) is used, saving
399 a system call.  (This doesn't work with C<-t>, and you need to remember
400 that lstat() and C<-l> will leave values in the stat structure for the
401 symbolic link, not the real file.)  (Also, if the stat buffer was filled by
402 an C<lstat> call, C<-T> and C<-B> will reset it with the results of C<stat _>).
403 Example:
404
405     print "Can do.\n" if -r $a || -w _ || -x _;
406
407     stat($filename);
408     print "Readable\n" if -r _;
409     print "Writable\n" if -w _;
410     print "Executable\n" if -x _;
411     print "Setuid\n" if -u _;
412     print "Setgid\n" if -g _;
413     print "Sticky\n" if -k _;
414     print "Text\n" if -T _;
415     print "Binary\n" if -B _;
416
417 As of Perl 5.9.1, as a form of purely syntactic sugar, you can stack file
418 test operators, in a way that C<-f -w -x $file> is equivalent to
419 C<-x $file && -w _ && -f _>. (This is only syntax fancy: if you use
420 the return value of C<-f $file> as an argument to another filetest
421 operator, no special magic will happen.)
422
423 =item abs VALUE
424 X<abs> X<absolute>
425
426 =item abs
427
428 Returns the absolute value of its argument.
429 If VALUE is omitted, uses C<$_>.
430
431 =item accept NEWSOCKET,GENERICSOCKET
432 X<accept>
433
434 Accepts an incoming socket connect, just as the accept(2) system call
435 does.  Returns the packed address if it succeeded, false otherwise.
436 See the example in L<perlipc/"Sockets: Client/Server Communication">.
437
438 On systems that support a close-on-exec flag on files, the flag will
439 be set for the newly opened file descriptor, as determined by the
440 value of $^F.  See L<perlvar/$^F>.
441
442 =item alarm SECONDS
443 X<alarm>
444 X<SIGALRM>
445 X<timer>
446
447 =item alarm
448
449 Arranges to have a SIGALRM delivered to this process after the
450 specified number of wallclock seconds has elapsed.  If SECONDS is not
451 specified, the value stored in C<$_> is used. (On some machines,
452 unfortunately, the elapsed time may be up to one second less or more
453 than you specified because of how seconds are counted, and process
454 scheduling may delay the delivery of the signal even further.)
455
456 Only one timer may be counting at once.  Each call disables the
457 previous timer, and an argument of C<0> may be supplied to cancel the
458 previous timer without starting a new one.  The returned value is the
459 amount of time remaining on the previous timer.
460
461 For delays of finer granularity than one second, the Time::HiRes module
462 (from CPAN, and starting from Perl 5.8 part of the standard
463 distribution) provides ualarm().  You may also use Perl's four-argument
464 version of select() leaving the first three arguments undefined, or you
465 might be able to use the C<syscall> interface to access setitimer(2) if
466 your system supports it. See L<perlfaq8> for details.
467
468 It is usually a mistake to intermix C<alarm> and C<sleep> calls.
469 (C<sleep> may be internally implemented in your system with C<alarm>)
470
471 If you want to use C<alarm> to time out a system call you need to use an
472 C<eval>/C<die> pair.  You can't rely on the alarm causing the system call to
473 fail with C<$!> set to C<EINTR> because Perl sets up signal handlers to
474 restart system calls on some systems.  Using C<eval>/C<die> always works,
475 modulo the caveats given in L<perlipc/"Signals">.
476
477     eval {
478         local $SIG{ALRM} = sub { die "alarm\n" }; # NB: \n required
479         alarm $timeout;
480         $nread = sysread SOCKET, $buffer, $size;
481         alarm 0;
482     };
483     if ($@) {
484         die unless $@ eq "alarm\n";   # propagate unexpected errors
485         # timed out
486     }
487     else {
488         # didn't
489     }
490
491 For more information see L<perlipc>.
492
493 =item atan2 Y,X
494 X<atan2> X<arctangent> X<tan> X<tangent>
495
496 Returns the arctangent of Y/X in the range -PI to PI.
497
498 For the tangent operation, you may use the C<Math::Trig::tan>
499 function, or use the familiar relation:
500
501     sub tan { sin($_[0]) / cos($_[0])  }
502
503 The return value for C<atan2(0,0)> is implementation-defined; consult
504 your atan2(3) manpage for more information.
505
506 =item bind SOCKET,NAME
507 X<bind>
508
509 Binds a network address to a socket, just as the bind system call
510 does.  Returns true if it succeeded, false otherwise.  NAME should be a
511 packed address of the appropriate type for the socket.  See the examples in
512 L<perlipc/"Sockets: Client/Server Communication">.
513
514 =item binmode FILEHANDLE, LAYER
515 X<binmode> X<binary> X<text> X<DOS> X<Windows>
516
517 =item binmode FILEHANDLE
518
519 Arranges for FILEHANDLE to be read or written in "binary" or "text"
520 mode on systems where the run-time libraries distinguish between
521 binary and text files.  If FILEHANDLE is an expression, the value is
522 taken as the name of the filehandle.  Returns true on success,
523 otherwise it returns C<undef> and sets C<$!> (errno).
524
525 On some systems (in general, DOS and Windows-based systems) binmode()
526 is necessary when you're not working with a text file.  For the sake
527 of portability it is a good idea to always use it when appropriate,
528 and to never use it when it isn't appropriate.  Also, people can
529 set their I/O to be by default UTF-8 encoded Unicode, not bytes.
530
531 In other words: regardless of platform, use binmode() on binary data,
532 like for example images.
533
534 If LAYER is present it is a single string, but may contain multiple
535 directives. The directives alter the behaviour of the file handle.
536 When LAYER is present using binmode on a text file makes sense.
537
538 If LAYER is omitted or specified as C<:raw> the filehandle is made
539 suitable for passing binary data. This includes turning off possible CRLF
540 translation and marking it as bytes (as opposed to Unicode characters).
541 Note that, despite what may be implied in I<"Programming Perl"> (the
542 Camel) or elsewhere, C<:raw> is I<not> simply the inverse of C<:crlf>
543 -- other layers which would affect the binary nature of the stream are
544 I<also> disabled. See L<PerlIO>, L<perlrun> and the discussion about the
545 PERLIO environment variable.
546
547 The C<:bytes>, C<:crlf>, and C<:utf8>, and any other directives of the
548 form C<:...>, are called I/O I<layers>.  The C<open> pragma can be used to
549 establish default I/O layers.  See L<open>.
550
551 I<The LAYER parameter of the binmode() function is described as "DISCIPLINE"
552 in "Programming Perl, 3rd Edition".  However, since the publishing of this
553 book, by many known as "Camel III", the consensus of the naming of this
554 functionality has moved from "discipline" to "layer".  All documentation
555 of this version of Perl therefore refers to "layers" rather than to
556 "disciplines".  Now back to the regularly scheduled documentation...>
557
558 To mark FILEHANDLE as UTF-8, use C<:utf8> or C<:encoding(utf8)>.
559 C<:utf8> just marks the data as UTF-8 without further checking,
560 while C<:encoding(utf8)> checks the data for actually being valid
561 UTF-8. More details can be found in L<PerlIO::encoding>.
562
563 In general, binmode() should be called after open() but before any I/O
564 is done on the filehandle.  Calling binmode() will normally flush any
565 pending buffered output data (and perhaps pending input data) on the
566 handle.  An exception to this is the C<:encoding> layer that
567 changes the default character encoding of the handle, see L<open>.
568 The C<:encoding> layer sometimes needs to be called in
569 mid-stream, and it doesn't flush the stream.  The C<:encoding>
570 also implicitly pushes on top of itself the C<:utf8> layer because
571 internally Perl will operate on UTF-8 encoded Unicode characters.
572
573 The operating system, device drivers, C libraries, and Perl run-time
574 system all work together to let the programmer treat a single
575 character (C<\n>) as the line terminator, irrespective of the external
576 representation.  On many operating systems, the native text file
577 representation matches the internal representation, but on some
578 platforms the external representation of C<\n> is made up of more than
579 one character.
580
581 Mac OS, all variants of Unix, and Stream_LF files on VMS use a single
582 character to end each line in the external representation of text (even
583 though that single character is CARRIAGE RETURN on Mac OS and LINE FEED
584 on Unix and most VMS files). In other systems like OS/2, DOS and the
585 various flavors of MS-Windows your program sees a C<\n> as a simple C<\cJ>,
586 but what's stored in text files are the two characters C<\cM\cJ>.  That
587 means that, if you don't use binmode() on these systems, C<\cM\cJ>
588 sequences on disk will be converted to C<\n> on input, and any C<\n> in
589 your program will be converted back to C<\cM\cJ> on output.  This is what
590 you want for text files, but it can be disastrous for binary files.
591
592 Another consequence of using binmode() (on some systems) is that
593 special end-of-file markers will be seen as part of the data stream.
594 For systems from the Microsoft family this means that if your binary
595 data contains C<\cZ>, the I/O subsystem will regard it as the end of
596 the file, unless you use binmode().
597
598 binmode() is not only important for readline() and print() operations,
599 but also when using read(), seek(), sysread(), syswrite() and tell()
600 (see L<perlport> for more details).  See the C<$/> and C<$\> variables
601 in L<perlvar> for how to manually set your input and output
602 line-termination sequences.
603
604 =item bless REF,CLASSNAME
605 X<bless>
606
607 =item bless REF
608
609 This function tells the thingy referenced by REF that it is now an object
610 in the CLASSNAME package.  If CLASSNAME is omitted, the current package
611 is used.  Because a C<bless> is often the last thing in a constructor,
612 it returns the reference for convenience.  Always use the two-argument
613 version if a derived class might inherit the function doing the blessing.
614 See L<perltoot> and L<perlobj> for more about the blessing (and blessings)
615 of objects.
616
617 Consider always blessing objects in CLASSNAMEs that are mixed case.
618 Namespaces with all lowercase names are considered reserved for
619 Perl pragmata.  Builtin types have all uppercase names. To prevent
620 confusion, you may wish to avoid such package names as well.  Make sure
621 that CLASSNAME is a true value.
622
623 See L<perlmod/"Perl Modules">.
624
625 =item break
626
627 Break out of a C<given()> block.
628
629 This keyword is enabled by the "switch" feature: see L<feature>
630 for more information.
631
632 =item caller EXPR
633 X<caller> X<call stack> X<stack> X<stack trace>
634
635 =item caller
636
637 Returns the context of the current subroutine call.  In scalar context,
638 returns the caller's package name if there is a caller, that is, if
639 we're in a subroutine or C<eval> or C<require>, and the undefined value
640 otherwise.  In list context, returns
641
642     # 0         1          2
643     ($package, $filename, $line) = caller;
644
645 With EXPR, it returns some extra information that the debugger uses to
646 print a stack trace.  The value of EXPR indicates how many call frames
647 to go back before the current one.
648
649     #  0         1          2      3            4
650     ($package, $filename, $line, $subroutine, $hasargs,
651
652     #  5          6          7            8       9         10
653     $wantarray, $evaltext, $is_require, $hints, $bitmask, $hinthash)
654      = caller($i);
655
656 Here $subroutine may be C<(eval)> if the frame is not a subroutine
657 call, but an C<eval>.  In such a case additional elements $evaltext and
658 C<$is_require> are set: C<$is_require> is true if the frame is created by a
659 C<require> or C<use> statement, $evaltext contains the text of the
660 C<eval EXPR> statement.  In particular, for an C<eval BLOCK> statement,
661 $subroutine is C<(eval)>, but $evaltext is undefined.  (Note also that
662 each C<use> statement creates a C<require> frame inside an C<eval EXPR>
663 frame.)  $subroutine may also be C<(unknown)> if this particular
664 subroutine happens to have been deleted from the symbol table.
665 C<$hasargs> is true if a new instance of C<@_> was set up for the frame.
666 C<$hints> and C<$bitmask> contain pragmatic hints that the caller was
667 compiled with.  The C<$hints> and C<$bitmask> values are subject to change
668 between versions of Perl, and are not meant for external use.
669
670 C<$hinthash> is a reference to a hash containing the value of C<%^H> when the
671 caller was compiled, or C<undef> if C<%^H> was empty. Do not modify the values
672 of this hash, as they are the actual values stored in the optree.
673
674 Furthermore, when called from within the DB package, caller returns more
675 detailed information: it sets the list variable C<@DB::args> to be the
676 arguments with which the subroutine was invoked.
677
678 Be aware that the optimizer might have optimized call frames away before
679 C<caller> had a chance to get the information.  That means that C<caller(N)>
680 might not return information about the call frame you expect it do, for
681 C<< N > 1 >>.  In particular, C<@DB::args> might have information from the
682 previous time C<caller> was called.
683
684 =item chdir EXPR
685 X<chdir>
686 X<cd>
687 X<directory, change>
688
689 =item chdir FILEHANDLE
690
691 =item chdir DIRHANDLE
692
693 =item chdir
694
695 Changes the working directory to EXPR, if possible. If EXPR is omitted,
696 changes to the directory specified by C<$ENV{HOME}>, if set; if not,
697 changes to the directory specified by C<$ENV{LOGDIR}>. (Under VMS, the
698 variable C<$ENV{SYS$LOGIN}> is also checked, and used if it is set.) If
699 neither is set, C<chdir> does nothing. It returns true upon success,
700 false otherwise. See the example under C<die>.
701
702 On systems that support fchdir, you might pass a file handle or
703 directory handle as argument.  On systems that don't support fchdir,
704 passing handles produces a fatal error at run time.
705
706 =item chmod LIST
707 X<chmod> X<permission> X<mode>
708
709 Changes the permissions of a list of files.  The first element of the
710 list must be the numerical mode, which should probably be an octal
711 number, and which definitely should I<not> be a string of octal digits:
712 C<0644> is okay, C<'0644'> is not.  Returns the number of files
713 successfully changed.  See also L</oct>, if all you have is a string.
714
715     $cnt = chmod 0755, 'foo', 'bar';
716     chmod 0755, @executables;
717     $mode = '0644'; chmod $mode, 'foo';      # !!! sets mode to
718                                              # --w----r-T
719     $mode = '0644'; chmod oct($mode), 'foo'; # this is better
720     $mode = 0644;   chmod $mode, 'foo';      # this is best
721
722 On systems that support fchmod, you might pass file handles among the
723 files.  On systems that don't support fchmod, passing file handles
724 produces a fatal error at run time.   The file handles must be passed
725 as globs or references to be recognized.  Barewords are considered
726 file names.
727
728     open(my $fh, "<", "foo");
729     my $perm = (stat $fh)[2] & 07777;
730     chmod($perm | 0600, $fh);
731
732 You can also import the symbolic C<S_I*> constants from the Fcntl
733 module:
734
735     use Fcntl ':mode';
736
737     chmod S_IRWXU|S_IRGRP|S_IXGRP|S_IROTH|S_IXOTH, @executables;
738     # This is identical to the chmod 0755 of the above example.
739
740 =item chomp VARIABLE
741 X<chomp> X<INPUT_RECORD_SEPARATOR> X<$/> X<newline> X<eol>
742
743 =item chomp( LIST )
744
745 =item chomp
746
747 This safer version of L</chop> removes any trailing string
748 that corresponds to the current value of C<$/> (also known as
749 $INPUT_RECORD_SEPARATOR in the C<English> module).  It returns the total
750 number of characters removed from all its arguments.  It's often used to
751 remove the newline from the end of an input record when you're worried
752 that the final record may be missing its newline.  When in paragraph
753 mode (C<$/ = "">), it removes all trailing newlines from the string.
754 When in slurp mode (C<$/ = undef>) or fixed-length record mode (C<$/> is
755 a reference to an integer or the like, see L<perlvar>) chomp() won't
756 remove anything.
757 If VARIABLE is omitted, it chomps C<$_>.  Example:
758
759     while (<>) {
760         chomp;  # avoid \n on last field
761         @array = split(/:/);
762         # ...
763     }
764
765 If VARIABLE is a hash, it chomps the hash's values, but not its keys.
766
767 You can actually chomp anything that's an lvalue, including an assignment:
768
769     chomp($cwd = `pwd`);
770     chomp($answer = <STDIN>);
771
772 If you chomp a list, each element is chomped, and the total number of
773 characters removed is returned.
774
775 Note that parentheses are necessary when you're chomping anything
776 that is not a simple variable.  This is because C<chomp $cwd = `pwd`;>
777 is interpreted as C<(chomp $cwd) = `pwd`;>, rather than as
778 C<chomp( $cwd = `pwd` )> which you might expect.  Similarly,
779 C<chomp $a, $b> is interpreted as C<chomp($a), $b> rather than
780 as C<chomp($a, $b)>.
781
782 =item chop VARIABLE
783 X<chop>
784
785 =item chop( LIST )
786
787 =item chop
788
789 Chops off the last character of a string and returns the character
790 chopped.  It is much more efficient than C<s/.$//s> because it neither
791 scans nor copies the string.  If VARIABLE is omitted, chops C<$_>.
792 If VARIABLE is a hash, it chops the hash's values, but not its keys.
793
794 You can actually chop anything that's an lvalue, including an assignment.
795
796 If you chop a list, each element is chopped.  Only the value of the
797 last C<chop> is returned.
798
799 Note that C<chop> returns the last character.  To return all but the last
800 character, use C<substr($string, 0, -1)>.
801
802 See also L</chomp>.
803
804 =item chown LIST
805 X<chown> X<owner> X<user> X<group>
806
807 Changes the owner (and group) of a list of files.  The first two
808 elements of the list must be the I<numeric> uid and gid, in that
809 order.  A value of -1 in either position is interpreted by most
810 systems to leave that value unchanged.  Returns the number of files
811 successfully changed.
812
813     $cnt = chown $uid, $gid, 'foo', 'bar';
814     chown $uid, $gid, @filenames;
815
816 On systems that support fchown, you might pass file handles among the
817 files.  On systems that don't support fchown, passing file handles
818 produces a fatal error at run time.  The file handles must be passed
819 as globs or references to be recognized.  Barewords are considered
820 file names.
821
822 Here's an example that looks up nonnumeric uids in the passwd file:
823
824     print "User: ";
825     chomp($user = <STDIN>);
826     print "Files: ";
827     chomp($pattern = <STDIN>);
828
829     ($login,$pass,$uid,$gid) = getpwnam($user)
830         or die "$user not in passwd file";
831
832     @ary = glob($pattern);  # expand filenames
833     chown $uid, $gid, @ary;
834
835 On most systems, you are not allowed to change the ownership of the
836 file unless you're the superuser, although you should be able to change
837 the group to any of your secondary groups.  On insecure systems, these
838 restrictions may be relaxed, but this is not a portable assumption.
839 On POSIX systems, you can detect this condition this way:
840
841     use POSIX qw(sysconf _PC_CHOWN_RESTRICTED);
842     $can_chown_giveaway = not sysconf(_PC_CHOWN_RESTRICTED);
843
844 =item chr NUMBER
845 X<chr> X<character> X<ASCII> X<Unicode>
846
847 =item chr
848
849 Returns the character represented by that NUMBER in the character set.
850 For example, C<chr(65)> is C<"A"> in either ASCII or Unicode, and
851 chr(0x263a) is a Unicode smiley face.  
852
853 Negative values give the Unicode replacement character (chr(0xfffd)),
854 except under the L<bytes> pragma, where low eight bits of the value
855 (truncated to an integer) are used.
856
857 If NUMBER is omitted, uses C<$_>.
858
859 For the reverse, use L</ord>.
860
861 Note that characters from 128 to 255 (inclusive) are by default
862 internally not encoded as UTF-8 for backward compatibility reasons.
863
864 See L<perlunicode> for more about Unicode.
865
866 =item chroot FILENAME
867 X<chroot> X<root>
868
869 =item chroot
870
871 This function works like the system call by the same name: it makes the
872 named directory the new root directory for all further pathnames that
873 begin with a C</> by your process and all its children.  (It doesn't
874 change your current working directory, which is unaffected.)  For security
875 reasons, this call is restricted to the superuser.  If FILENAME is
876 omitted, does a C<chroot> to C<$_>.
877
878 =item close FILEHANDLE
879 X<close>
880
881 =item close
882
883 Closes the file or pipe associated with the file handle, flushes the IO
884 buffers, and closes the system file descriptor.  Returns true if those
885 operations have succeeded and if no error was reported by any PerlIO
886 layer.  Closes the currently selected filehandle if the argument is
887 omitted.
888
889 You don't have to close FILEHANDLE if you are immediately going to do
890 another C<open> on it, because C<open> will close it for you.  (See
891 C<open>.)  However, an explicit C<close> on an input file resets the line
892 counter (C<$.>), while the implicit close done by C<open> does not.
893
894 If the file handle came from a piped open, C<close> will additionally
895 return false if one of the other system calls involved fails, or if the
896 program exits with non-zero status.  (If the only problem was that the
897 program exited non-zero, C<$!> will be set to C<0>.)  Closing a pipe
898 also waits for the process executing on the pipe to complete, in case you
899 want to look at the output of the pipe afterwards, and
900 implicitly puts the exit status value of that command into C<$?> and
901 C<${^CHILD_ERROR_NATIVE}>.
902
903 Prematurely closing the read end of a pipe (i.e. before the process
904 writing to it at the other end has closed it) will result in a
905 SIGPIPE being delivered to the writer.  If the other end can't
906 handle that, be sure to read all the data before closing the pipe.
907
908 Example:
909
910     open(OUTPUT, '|sort >foo')  # pipe to sort
911         or die "Can't start sort: $!";
912     #...                        # print stuff to output
913     close OUTPUT                # wait for sort to finish
914         or warn $! ? "Error closing sort pipe: $!"
915                    : "Exit status $? from sort";
916     open(INPUT, 'foo')          # get sort's results
917         or die "Can't open 'foo' for input: $!";
918
919 FILEHANDLE may be an expression whose value can be used as an indirect
920 filehandle, usually the real filehandle name.
921
922 =item closedir DIRHANDLE
923 X<closedir>
924
925 Closes a directory opened by C<opendir> and returns the success of that
926 system call.
927
928 =item connect SOCKET,NAME
929 X<connect>
930
931 Attempts to connect to a remote socket, just as the connect system call
932 does.  Returns true if it succeeded, false otherwise.  NAME should be a
933 packed address of the appropriate type for the socket.  See the examples in
934 L<perlipc/"Sockets: Client/Server Communication">.
935
936 =item continue BLOCK
937 X<continue>
938
939 =item continue
940
941 C<continue> is actually a flow control statement rather than a function.  If
942 there is a C<continue> BLOCK attached to a BLOCK (typically in a C<while> or
943 C<foreach>), it is always executed just before the conditional is about to
944 be evaluated again, just like the third part of a C<for> loop in C.  Thus
945 it can be used to increment a loop variable, even when the loop has been
946 continued via the C<next> statement (which is similar to the C C<continue>
947 statement).
948
949 C<last>, C<next>, or C<redo> may appear within a C<continue>
950 block.  C<last> and C<redo> will behave as if they had been executed within
951 the main block.  So will C<next>, but since it will execute a C<continue>
952 block, it may be more entertaining.
953
954     while (EXPR) {
955         ### redo always comes here
956         do_something;
957     } continue {
958         ### next always comes here
959         do_something_else;
960         # then back the top to re-check EXPR
961     }
962     ### last always comes here
963
964 Omitting the C<continue> section is semantically equivalent to using an
965 empty one, logically enough.  In that case, C<next> goes directly back
966 to check the condition at the top of the loop.
967
968 If the "switch" feature is enabled, C<continue> is also a
969 function that will break out of the current C<when> or C<default>
970 block, and fall through to the next case. See L<feature> and
971 L<perlsyn/"Switch statements"> for more information.
972
973
974 =item cos EXPR
975 X<cos> X<cosine> X<acos> X<arccosine>
976
977 =item cos
978
979 Returns the cosine of EXPR (expressed in radians).  If EXPR is omitted,
980 takes cosine of C<$_>.
981
982 For the inverse cosine operation, you may use the C<Math::Trig::acos()>
983 function, or use this relation:
984
985     sub acos { atan2( sqrt(1 - $_[0] * $_[0]), $_[0] ) }
986
987 =item crypt PLAINTEXT,SALT
988 X<crypt> X<digest> X<hash> X<salt> X<plaintext> X<password>
989 X<decrypt> X<cryptography> X<passwd> X<encrypt>
990
991 Creates a digest string exactly like the crypt(3) function in the C
992 library (assuming that you actually have a version there that has not
993 been extirpated as a potential munition).
994
995 crypt() is a one-way hash function.  The PLAINTEXT and SALT is turned
996 into a short string, called a digest, which is returned.  The same
997 PLAINTEXT and SALT will always return the same string, but there is no
998 (known) way to get the original PLAINTEXT from the hash.  Small
999 changes in the PLAINTEXT or SALT will result in large changes in the
1000 digest.
1001
1002 There is no decrypt function.  This function isn't all that useful for
1003 cryptography (for that, look for F<Crypt> modules on your nearby CPAN
1004 mirror) and the name "crypt" is a bit of a misnomer.  Instead it is
1005 primarily used to check if two pieces of text are the same without
1006 having to transmit or store the text itself.  An example is checking
1007 if a correct password is given.  The digest of the password is stored,
1008 not the password itself.  The user types in a password that is
1009 crypt()'d with the same salt as the stored digest.  If the two digests
1010 match the password is correct.
1011
1012 When verifying an existing digest string you should use the digest as
1013 the salt (like C<crypt($plain, $digest) eq $digest>).  The SALT used
1014 to create the digest is visible as part of the digest.  This ensures
1015 crypt() will hash the new string with the same salt as the digest.
1016 This allows your code to work with the standard L<crypt|/crypt> and
1017 with more exotic implementations.  In other words, do not assume
1018 anything about the returned string itself, or how many bytes in the
1019 digest matter.
1020
1021 Traditionally the result is a string of 13 bytes: two first bytes of
1022 the salt, followed by 11 bytes from the set C<[./0-9A-Za-z]>, and only
1023 the first eight bytes of PLAINTEXT mattered. But alternative
1024 hashing schemes (like MD5), higher level security schemes (like C2),
1025 and implementations on non-Unix platforms may produce different
1026 strings.
1027
1028 When choosing a new salt create a random two character string whose
1029 characters come from the set C<[./0-9A-Za-z]> (like C<join '', ('.',
1030 '/', 0..9, 'A'..'Z', 'a'..'z')[rand 64, rand 64]>).  This set of
1031 characters is just a recommendation; the characters allowed in
1032 the salt depend solely on your system's crypt library, and Perl can't
1033 restrict what salts C<crypt()> accepts.
1034
1035 Here's an example that makes sure that whoever runs this program knows
1036 their password:
1037
1038     $pwd = (getpwuid($<))[1];
1039
1040     system "stty -echo";
1041     print "Password: ";
1042     chomp($word = <STDIN>);
1043     print "\n";
1044     system "stty echo";
1045
1046     if (crypt($word, $pwd) ne $pwd) {
1047         die "Sorry...\n";
1048     } else {
1049         print "ok\n";
1050     }
1051
1052 Of course, typing in your own password to whoever asks you
1053 for it is unwise.
1054
1055 The L<crypt|/crypt> function is unsuitable for hashing large quantities
1056 of data, not least of all because you can't get the information
1057 back.  Look at the L<Digest> module for more robust algorithms.
1058
1059 If using crypt() on a Unicode string (which I<potentially> has
1060 characters with codepoints above 255), Perl tries to make sense
1061 of the situation by trying to downgrade (a copy of the string)
1062 the string back to an eight-bit byte string before calling crypt()
1063 (on that copy).  If that works, good.  If not, crypt() dies with
1064 C<Wide character in crypt>.
1065
1066 =item dbmclose HASH
1067 X<dbmclose>
1068
1069 [This function has been largely superseded by the C<untie> function.]
1070
1071 Breaks the binding between a DBM file and a hash.
1072
1073 =item dbmopen HASH,DBNAME,MASK
1074 X<dbmopen> X<dbm> X<ndbm> X<sdbm> X<gdbm>
1075
1076 [This function has been largely superseded by the C<tie> function.]
1077
1078 This binds a dbm(3), ndbm(3), sdbm(3), gdbm(3), or Berkeley DB file to a
1079 hash.  HASH is the name of the hash.  (Unlike normal C<open>, the first
1080 argument is I<not> a filehandle, even though it looks like one).  DBNAME
1081 is the name of the database (without the F<.dir> or F<.pag> extension if
1082 any).  If the database does not exist, it is created with protection
1083 specified by MASK (as modified by the C<umask>).  If your system supports
1084 only the older DBM functions, you may perform only one C<dbmopen> in your
1085 program.  In older versions of Perl, if your system had neither DBM nor
1086 ndbm, calling C<dbmopen> produced a fatal error; it now falls back to
1087 sdbm(3).
1088
1089 If you don't have write access to the DBM file, you can only read hash
1090 variables, not set them.  If you want to test whether you can write,
1091 either use file tests or try setting a dummy hash entry inside an C<eval>,
1092 which will trap the error.
1093
1094 Note that functions such as C<keys> and C<values> may return huge lists
1095 when used on large DBM files.  You may prefer to use the C<each>
1096 function to iterate over large DBM files.  Example:
1097
1098     # print out history file offsets
1099     dbmopen(%HIST,'/usr/lib/news/history',0666);
1100     while (($key,$val) = each %HIST) {
1101         print $key, ' = ', unpack('L',$val), "\n";
1102     }
1103     dbmclose(%HIST);
1104
1105 See also L<AnyDBM_File> for a more general description of the pros and
1106 cons of the various dbm approaches, as well as L<DB_File> for a particularly
1107 rich implementation.
1108
1109 You can control which DBM library you use by loading that library
1110 before you call dbmopen():
1111
1112     use DB_File;
1113     dbmopen(%NS_Hist, "$ENV{HOME}/.netscape/history.db")
1114         or die "Can't open netscape history file: $!";
1115
1116 =item defined EXPR
1117 X<defined> X<undef> X<undefined>
1118
1119 =item defined
1120
1121 Returns a Boolean value telling whether EXPR has a value other than
1122 the undefined value C<undef>.  If EXPR is not present, C<$_> will be
1123 checked.
1124
1125 Many operations return C<undef> to indicate failure, end of file,
1126 system error, uninitialized variable, and other exceptional
1127 conditions.  This function allows you to distinguish C<undef> from
1128 other values.  (A simple Boolean test will not distinguish among
1129 C<undef>, zero, the empty string, and C<"0">, which are all equally
1130 false.)  Note that since C<undef> is a valid scalar, its presence
1131 doesn't I<necessarily> indicate an exceptional condition: C<pop>
1132 returns C<undef> when its argument is an empty array, I<or> when the
1133 element to return happens to be C<undef>.
1134
1135 You may also use C<defined(&func)> to check whether subroutine C<&func>
1136 has ever been defined.  The return value is unaffected by any forward
1137 declarations of C<&func>.  Note that a subroutine which is not defined
1138 may still be callable: its package may have an C<AUTOLOAD> method that
1139 makes it spring into existence the first time that it is called -- see
1140 L<perlsub>.
1141
1142 Use of C<defined> on aggregates (hashes and arrays) is deprecated.  It
1143 used to report whether memory for that aggregate has ever been
1144 allocated.  This behavior may disappear in future versions of Perl.
1145 You should instead use a simple test for size:
1146
1147     if (@an_array) { print "has array elements\n" }
1148     if (%a_hash)   { print "has hash members\n"   }
1149
1150 When used on a hash element, it tells you whether the value is defined,
1151 not whether the key exists in the hash.  Use L</exists> for the latter
1152 purpose.
1153
1154 Examples:
1155
1156     print if defined $switch{'D'};
1157     print "$val\n" while defined($val = pop(@ary));
1158     die "Can't readlink $sym: $!"
1159         unless defined($value = readlink $sym);
1160     sub foo { defined &$bar ? &$bar(@_) : die "No bar"; }
1161     $debugging = 0 unless defined $debugging;
1162
1163 Note:  Many folks tend to overuse C<defined>, and then are surprised to
1164 discover that the number C<0> and C<""> (the zero-length string) are, in fact,
1165 defined values.  For example, if you say
1166
1167     "ab" =~ /a(.*)b/;
1168
1169 The pattern match succeeds, and C<$1> is defined, despite the fact that it
1170 matched "nothing".  It didn't really fail to match anything.  Rather, it
1171 matched something that happened to be zero characters long.  This is all
1172 very above-board and honest.  When a function returns an undefined value,
1173 it's an admission that it couldn't give you an honest answer.  So you
1174 should use C<defined> only when you're questioning the integrity of what
1175 you're trying to do.  At other times, a simple comparison to C<0> or C<""> is
1176 what you want.
1177
1178 See also L</undef>, L</exists>, L</ref>.
1179
1180 =item delete EXPR
1181 X<delete>
1182
1183 Given an expression that specifies a hash element, array element, hash slice,
1184 or array slice, deletes the specified element(s) from the hash or array.
1185 In the case of an array, if the array elements happen to be at the end,
1186 the size of the array will shrink to the highest element that tests
1187 true for exists() (or 0 if no such element exists).
1188
1189 Returns a list with the same number of elements as the number of elements
1190 for which deletion was attempted.  Each element of that list consists of
1191 either the value of the element deleted, or the undefined value.  In scalar
1192 context, this means that you get the value of the last element deleted (or
1193 the undefined value if that element did not exist).
1194
1195     %hash = (foo => 11, bar => 22, baz => 33);
1196     $scalar = delete $hash{foo};             # $scalar is 11
1197     $scalar = delete @hash{qw(foo bar)};     # $scalar is 22
1198     @array  = delete @hash{qw(foo bar baz)}; # @array  is (undef,undef,33)
1199
1200 Deleting from C<%ENV> modifies the environment.  Deleting from
1201 a hash tied to a DBM file deletes the entry from the DBM file.  Deleting
1202 from a C<tie>d hash or array may not necessarily return anything.
1203
1204 Deleting an array element effectively returns that position of the array
1205 to its initial, uninitialized state.  Subsequently testing for the same
1206 element with exists() will return false.  Also, deleting array elements
1207 in the middle of an array will not shift the index of the elements
1208 after them down.  Use splice() for that.  See L</exists>.
1209
1210 The following (inefficiently) deletes all the values of %HASH and @ARRAY:
1211
1212     foreach $key (keys %HASH) {
1213         delete $HASH{$key};
1214     }
1215
1216     foreach $index (0 .. $#ARRAY) {
1217         delete $ARRAY[$index];
1218     }
1219
1220 And so do these:
1221
1222     delete @HASH{keys %HASH};
1223
1224     delete @ARRAY[0 .. $#ARRAY];
1225
1226 But both of these are slower than just assigning the empty list
1227 or undefining %HASH or @ARRAY:
1228
1229     %HASH = ();     # completely empty %HASH
1230     undef %HASH;    # forget %HASH ever existed
1231
1232     @ARRAY = ();    # completely empty @ARRAY
1233     undef @ARRAY;   # forget @ARRAY ever existed
1234
1235 Note that the EXPR can be arbitrarily complicated as long as the final
1236 operation is a hash element, array element,  hash slice, or array slice
1237 lookup:
1238
1239     delete $ref->[$x][$y]{$key};
1240     delete @{$ref->[$x][$y]}{$key1, $key2, @morekeys};
1241
1242     delete $ref->[$x][$y][$index];
1243     delete @{$ref->[$x][$y]}[$index1, $index2, @moreindices];
1244
1245 The C<delete local EXPR> construct can also be used to localize the deletion
1246 of array/hash elements to the current block.
1247 See L<perlsub/"Localized deletion of elements of composite types">.
1248
1249 =item die LIST
1250 X<die> X<throw> X<exception> X<raise> X<$@> X<abort>
1251
1252 Outside an C<eval>, prints the value of LIST to C<STDERR> and
1253 exits with the current value of C<$!> (errno).  If C<$!> is C<0>,
1254 exits with the value of C<<< ($? >> 8) >>> (backtick `command`
1255 status).  If C<<< ($? >> 8) >>> is C<0>, exits with C<255>.  Inside
1256 an C<eval(),> the error message is stuffed into C<$@> and the
1257 C<eval> is terminated with the undefined value.  This makes
1258 C<die> the way to raise an exception.
1259
1260 Equivalent examples:
1261
1262     die "Can't cd to spool: $!\n" unless chdir '/usr/spool/news';
1263     chdir '/usr/spool/news' or die "Can't cd to spool: $!\n"
1264
1265 If the last element of LIST does not end in a newline, the current
1266 script line number and input line number (if any) are also printed,
1267 and a newline is supplied.  Note that the "input line number" (also
1268 known as "chunk") is subject to whatever notion of "line" happens to
1269 be currently in effect, and is also available as the special variable
1270 C<$.>.  See L<perlvar/"$/"> and L<perlvar/"$.">.
1271
1272 Hint: sometimes appending C<", stopped"> to your message will cause it
1273 to make better sense when the string C<"at foo line 123"> is appended.
1274 Suppose you are running script "canasta".
1275
1276     die "/etc/games is no good";
1277     die "/etc/games is no good, stopped";
1278
1279 produce, respectively
1280
1281     /etc/games is no good at canasta line 123.
1282     /etc/games is no good, stopped at canasta line 123.
1283
1284 See also exit(), warn(), and the Carp module.
1285
1286 If the output is empty and C<$@> already contains a value (typically from a
1287 previous eval) that value is reused after appending C<"\t...propagated">.
1288 This is useful for propagating exceptions:
1289
1290     eval { ... };
1291     die unless $@ =~ /Expected exception/;
1292
1293 If the output is empty and C<$@> contains an object reference that has a
1294 C<PROPAGATE> method, that method will be called with additional file
1295 and line number parameters.  The return value replaces the value in
1296 C<$@>.  i.e. as if C<< $@ = eval { $@->PROPAGATE(__FILE__, __LINE__) }; >>
1297 were called.
1298
1299 If C<$@> is empty then the string C<"Died"> is used.
1300
1301 die() can also be called with a reference argument.  If this happens to be
1302 trapped within an eval(), $@ contains the reference.  This behavior permits
1303 a more elaborate exception handling implementation using objects that
1304 maintain arbitrary state about the nature of the exception.  Such a scheme
1305 is sometimes preferable to matching particular string values of $@ using
1306 regular expressions.  Because $@ is a global variable, and eval() may be
1307 used within object implementations, care must be taken that analyzing the
1308 error object doesn't replace the reference in the global variable.  The
1309 easiest solution is to make a local copy of the reference before doing
1310 other manipulations.  Here's an example:
1311
1312     use Scalar::Util 'blessed';
1313
1314     eval { ... ; die Some::Module::Exception->new( FOO => "bar" ) };
1315     if (my $ev_err = $@) {
1316         if (blessed($ev_err) && $ev_err->isa("Some::Module::Exception")) {
1317             # handle Some::Module::Exception
1318         }
1319         else {
1320             # handle all other possible exceptions
1321         }
1322     }
1323
1324 Because perl will stringify uncaught exception messages before displaying
1325 them, you may want to overload stringification operations on such custom
1326 exception objects.  See L<overload> for details about that.
1327
1328 You can arrange for a callback to be run just before the C<die>
1329 does its deed, by setting the C<$SIG{__DIE__}> hook.  The associated
1330 handler will be called with the error text and can change the error
1331 message, if it sees fit, by calling C<die> again.  See
1332 L<perlvar/$SIG{expr}> for details on setting C<%SIG> entries, and
1333 L<"eval BLOCK"> for some examples.  Although this feature was 
1334 to be run only right before your program was to exit, this is not
1335 currently the case--the C<$SIG{__DIE__}> hook is currently called
1336 even inside eval()ed blocks/strings!  If one wants the hook to do
1337 nothing in such situations, put
1338
1339     die @_ if $^S;
1340
1341 as the first line of the handler (see L<perlvar/$^S>).  Because
1342 this promotes strange action at a distance, this counterintuitive
1343 behavior may be fixed in a future release.
1344
1345 =item do BLOCK
1346 X<do> X<block>
1347
1348 Not really a function.  Returns the value of the last command in the
1349 sequence of commands indicated by BLOCK.  When modified by the C<while> or
1350 C<until> loop modifier, executes the BLOCK once before testing the loop
1351 condition. (On other statements the loop modifiers test the conditional
1352 first.)
1353
1354 C<do BLOCK> does I<not> count as a loop, so the loop control statements
1355 C<next>, C<last>, or C<redo> cannot be used to leave or restart the block.
1356 See L<perlsyn> for alternative strategies.
1357
1358 =item do SUBROUTINE(LIST)
1359 X<do>
1360
1361 This form of subroutine call is deprecated.  See L<perlsub>.
1362
1363 =item do EXPR
1364 X<do>
1365
1366 Uses the value of EXPR as a filename and executes the contents of the
1367 file as a Perl script.
1368
1369     do 'stat.pl';
1370
1371 is just like
1372
1373     eval `cat stat.pl`;
1374
1375 except that it's more efficient and concise, keeps track of the current
1376 filename for error messages, searches the @INC directories, and updates
1377 C<%INC> if the file is found.  See L<perlvar/Predefined Names> for these
1378 variables.  It also differs in that code evaluated with C<do FILENAME>
1379 cannot see lexicals in the enclosing scope; C<eval STRING> does.  It's the
1380 same, however, in that it does reparse the file every time you call it,
1381 so you probably don't want to do this inside a loop.
1382
1383 If C<do> cannot read the file, it returns undef and sets C<$!> to the
1384 error.  If C<do> can read the file but cannot compile it, it
1385 returns undef and sets an error message in C<$@>.   If the file is
1386 successfully compiled, C<do> returns the value of the last expression
1387 evaluated.
1388
1389 Note that inclusion of library modules is better done with the
1390 C<use> and C<require> operators, which also do automatic error checking
1391 and raise an exception if there's a problem.
1392
1393 You might like to use C<do> to read in a program configuration
1394 file.  Manual error checking can be done this way:
1395
1396     # read in config files: system first, then user
1397     for $file ("/share/prog/defaults.rc",
1398                "$ENV{HOME}/.someprogrc")
1399     {
1400         unless ($return = do $file) {
1401             warn "couldn't parse $file: $@" if $@;
1402             warn "couldn't do $file: $!"    unless defined $return;
1403             warn "couldn't run $file"       unless $return;
1404         }
1405     }
1406
1407 =item dump LABEL
1408 X<dump> X<core> X<undump>
1409
1410 =item dump
1411
1412 This function causes an immediate core dump.  See also the B<-u>
1413 command-line switch in L<perlrun>, which does the same thing.
1414 Primarily this is so that you can use the B<undump> program (not
1415 supplied) to turn your core dump into an executable binary after
1416 having initialized all your variables at the beginning of the
1417 program.  When the new binary is executed it will begin by executing
1418 a C<goto LABEL> (with all the restrictions that C<goto> suffers).
1419 Think of it as a goto with an intervening core dump and reincarnation.
1420 If C<LABEL> is omitted, restarts the program from the top.
1421
1422 B<WARNING>: Any files opened at the time of the dump will I<not>
1423 be open any more when the program is reincarnated, with possible
1424 resulting confusion on the part of Perl.
1425
1426 This function is now largely obsolete, mostly because it's very hard to
1427 convert a core file into an executable. That's why you should now invoke
1428 it as C<CORE::dump()>, if you don't want to be warned against a possible
1429 typo.
1430
1431 =item each HASH
1432 X<each> X<hash, iterator>
1433
1434 =item each ARRAY
1435 X<array, iterator>
1436
1437 When called in list context, returns a 2-element list consisting of the
1438 key and value for the next element of a hash, or the index and value for
1439 the next element of an array, so that you can iterate over it.  When called
1440 in scalar context, returns only the key for the next element in the hash
1441 (or the index for an array).
1442
1443 Hash entries are returned in an apparently random order.  The actual random
1444 order is subject to change in future versions of perl, but it is
1445 guaranteed to be in the same order as either the C<keys> or C<values>
1446 function would produce on the same (unmodified) hash.  Since Perl
1447 5.8.2 the ordering can be different even between different runs of Perl
1448 for security reasons (see L<perlsec/"Algorithmic Complexity Attacks">).
1449
1450 When the hash or array is entirely read, a null array is returned in list
1451 context (which when assigned produces a false (C<0>) value), and C<undef> in
1452 scalar context.  The next call to C<each> after that will start iterating
1453 again.  There is a single iterator for each hash or array, shared by all
1454 C<each>, C<keys>, and C<values> function calls in the program; it can be
1455 reset by reading all the elements from the hash or array, or by evaluating
1456 C<keys HASH>, C<values HASH>, C<keys ARRAY>, or C<values ARRAY>.  If you add
1457 or delete elements of a hash while you're
1458 iterating over it, you may get entries skipped or duplicated, so
1459 don't.  Exception: It is always safe to delete the item most recently
1460 returned by C<each()>, which means that the following code will work:
1461
1462         while (($key, $value) = each %hash) {
1463           print $key, "\n";
1464           delete $hash{$key};   # This is safe
1465         }
1466
1467 The following prints out your environment like the printenv(1) program,
1468 only in a different order:
1469
1470     while (($key,$value) = each %ENV) {
1471         print "$key=$value\n";
1472     }
1473
1474 See also C<keys>, C<values> and C<sort>.
1475
1476 =item eof FILEHANDLE
1477 X<eof>
1478 X<end of file>
1479 X<end-of-file>
1480
1481 =item eof ()
1482
1483 =item eof
1484
1485 Returns 1 if the next read on FILEHANDLE will return end of file, or if
1486 FILEHANDLE is not open.  FILEHANDLE may be an expression whose value
1487 gives the real filehandle.  (Note that this function actually
1488 reads a character and then C<ungetc>s it, so isn't very useful in an
1489 interactive context.)  Do not read from a terminal file (or call
1490 C<eof(FILEHANDLE)> on it) after end-of-file is reached.  File types such
1491 as terminals may lose the end-of-file condition if you do.
1492
1493 An C<eof> without an argument uses the last file read.  Using C<eof()>
1494 with empty parentheses is very different.  It refers to the pseudo file
1495 formed from the files listed on the command line and accessed via the
1496 C<< <> >> operator.  Since C<< <> >> isn't explicitly opened,
1497 as a normal filehandle is, an C<eof()> before C<< <> >> has been
1498 used will cause C<@ARGV> to be examined to determine if input is
1499 available.   Similarly, an C<eof()> after C<< <> >> has returned
1500 end-of-file will assume you are processing another C<@ARGV> list,
1501 and if you haven't set C<@ARGV>, will read input from C<STDIN>;
1502 see L<perlop/"I/O Operators">.
1503
1504 In a C<< while (<>) >> loop, C<eof> or C<eof(ARGV)> can be used to
1505 detect the end of each file, C<eof()> will only detect the end of the
1506 last file.  Examples:
1507
1508     # reset line numbering on each input file
1509     while (<>) {
1510         next if /^\s*#/;  # skip comments
1511         print "$.\t$_";
1512     } continue {
1513         close ARGV if eof;  # Not eof()!
1514     }
1515
1516     # insert dashes just before last line of last file
1517     while (<>) {
1518         if (eof()) {  # check for end of last file
1519             print "--------------\n";
1520         }
1521         print;
1522         last if eof();          # needed if we're reading from a terminal
1523     }
1524
1525 Practical hint: you almost never need to use C<eof> in Perl, because the
1526 input operators typically return C<undef> when they run out of data, or if
1527 there was an error.
1528
1529 =item eval EXPR
1530 X<eval> X<try> X<catch> X<evaluate> X<parse> X<execute>
1531 X<error, handling> X<exception, handling>
1532
1533 =item eval BLOCK
1534
1535 =item eval
1536
1537 In the first form, the return value of EXPR is parsed and executed as if it
1538 were a little Perl program.  The value of the expression (which is itself
1539 determined within scalar context) is first parsed, and if there weren't any
1540 errors, executed in the lexical context of the current Perl program, so
1541 that any variable settings or subroutine and format definitions remain
1542 afterwards.  Note that the value is parsed every time the C<eval> executes.
1543 If EXPR is omitted, evaluates C<$_>.  This form is typically used to
1544 delay parsing and subsequent execution of the text of EXPR until run time.
1545
1546 In the second form, the code within the BLOCK is parsed only once--at the
1547 same time the code surrounding the C<eval> itself was parsed--and executed
1548 within the context of the current Perl program.  This form is typically
1549 used to trap exceptions more efficiently than the first (see below), while
1550 also providing the benefit of checking the code within BLOCK at compile
1551 time.
1552
1553 The final semicolon, if any, may be omitted from the value of EXPR or within
1554 the BLOCK.
1555
1556 In both forms, the value returned is the value of the last expression
1557 evaluated inside the mini-program; a return statement may be also used, just
1558 as with subroutines.  The expression providing the return value is evaluated
1559 in void, scalar, or list context, depending on the context of the C<eval> 
1560 itself.  See L</wantarray> for more on how the evaluation context can be 
1561 determined.
1562
1563 If there is a syntax error or runtime error, or a C<die> statement is
1564 executed, C<eval> returns an undefined value in scalar context
1565 or an empty list in list context, and C<$@> is set to the
1566 error message.  If there was no error, C<$@> is guaranteed to be a null
1567 string.  Beware that using C<eval> neither silences perl from printing
1568 warnings to STDERR, nor does it stuff the text of warning messages into C<$@>.
1569 To do either of those, you have to use the C<$SIG{__WARN__}> facility, or
1570 turn off warnings inside the BLOCK or EXPR using S<C<no warnings 'all'>>.
1571 See L</warn>, L<perlvar>, L<warnings> and L<perllexwarn>.
1572
1573 Note that, because C<eval> traps otherwise-fatal errors, it is useful for
1574 determining whether a particular feature (such as C<socket> or C<symlink>)
1575 is implemented.  It is also Perl's exception trapping mechanism, where
1576 the die operator is used to raise exceptions.
1577
1578 If you want to trap errors when loading an XS module, some problems with
1579 the binary interface (such as Perl version skew) may be fatal even with
1580 C<eval> unless C<$ENV{PERL_DL_NONLAZY}> is set. See L<perlrun>.
1581
1582 If the code to be executed doesn't vary, you may use the eval-BLOCK
1583 form to trap run-time errors without incurring the penalty of
1584 recompiling each time.  The error, if any, is still returned in C<$@>.
1585 Examples:
1586
1587     # make divide-by-zero nonfatal
1588     eval { $answer = $a / $b; }; warn $@ if $@;
1589
1590     # same thing, but less efficient
1591     eval '$answer = $a / $b'; warn $@ if $@;
1592
1593     # a compile-time error
1594     eval { $answer = }; # WRONG
1595
1596     # a run-time error
1597     eval '$answer =';   # sets $@
1598
1599 Using the C<eval{}> form as an exception trap in libraries does have some
1600 issues.  Due to the current arguably broken state of C<__DIE__> hooks, you
1601 may wish not to trigger any C<__DIE__> hooks that user code may have installed.
1602 You can use the C<local $SIG{__DIE__}> construct for this purpose,
1603 as shown in this example:
1604
1605     # a very private exception trap for divide-by-zero
1606     eval { local $SIG{'__DIE__'}; $answer = $a / $b; };
1607     warn $@ if $@;
1608
1609 This is especially significant, given that C<__DIE__> hooks can call
1610 C<die> again, which has the effect of changing their error messages:
1611
1612     # __DIE__ hooks may modify error messages
1613     {
1614        local $SIG{'__DIE__'} =
1615               sub { (my $x = $_[0]) =~ s/foo/bar/g; die $x };
1616        eval { die "foo lives here" };
1617        print $@ if $@;                # prints "bar lives here"
1618     }
1619
1620 Because this promotes action at a distance, this counterintuitive behavior
1621 may be fixed in a future release.
1622
1623 With an C<eval>, you should be especially careful to remember what's
1624 being looked at when:
1625
1626     eval $x;        # CASE 1
1627     eval "$x";      # CASE 2
1628
1629     eval '$x';      # CASE 3
1630     eval { $x };    # CASE 4
1631
1632     eval "\$$x++";  # CASE 5
1633     $$x++;          # CASE 6
1634
1635 Cases 1 and 2 above behave identically: they run the code contained in
1636 the variable $x.  (Although case 2 has misleading double quotes making
1637 the reader wonder what else might be happening (nothing is).)  Cases 3
1638 and 4 likewise behave in the same way: they run the code C<'$x'>, which
1639 does nothing but return the value of $x.  (Case 4 is preferred for
1640 purely visual reasons, but it also has the advantage of compiling at
1641 compile-time instead of at run-time.)  Case 5 is a place where
1642 normally you I<would> like to use double quotes, except that in this
1643 particular situation, you can just use symbolic references instead, as
1644 in case 6.
1645
1646 The assignment to C<$@> occurs before restoration of localised variables,
1647 which means a temporary is required if you want to mask some but not all
1648 errors:
1649
1650     # alter $@ on nefarious repugnancy only
1651     {
1652        my $e;
1653        {
1654           local $@; # protect existing $@
1655           eval { test_repugnancy() };
1656           # $@ =~ /nefarious/ and die $@; # DOES NOT WORK
1657           $@ =~ /nefarious/ and $e = $@;
1658        }
1659        die $e if defined $e
1660     }
1661
1662 C<eval BLOCK> does I<not> count as a loop, so the loop control statements
1663 C<next>, C<last>, or C<redo> cannot be used to leave or restart the block.
1664
1665 Note that as a very special case, an C<eval ''> executed within the C<DB>
1666 package doesn't see the usual surrounding lexical scope, but rather the
1667 scope of the first non-DB piece of code that called it. You don't normally
1668 need to worry about this unless you are writing a Perl debugger.
1669
1670 =item exec LIST
1671 X<exec> X<execute>
1672
1673 =item exec PROGRAM LIST
1674
1675 The C<exec> function executes a system command I<and never returns>--
1676 use C<system> instead of C<exec> if you want it to return.  It fails and
1677 returns false only if the command does not exist I<and> it is executed
1678 directly instead of via your system's command shell (see below).
1679
1680 Since it's a common mistake to use C<exec> instead of C<system>, Perl
1681 warns you if there is a following statement which isn't C<die>, C<warn>,
1682 or C<exit> (if C<-w> is set  -  but you always do that).   If you
1683 I<really> want to follow an C<exec> with some other statement, you
1684 can use one of these styles to avoid the warning:
1685
1686     exec ('foo')   or print STDERR "couldn't exec foo: $!";
1687     { exec ('foo') }; print STDERR "couldn't exec foo: $!";
1688
1689 If there is more than one argument in LIST, or if LIST is an array
1690 with more than one value, calls execvp(3) with the arguments in LIST.
1691 If there is only one scalar argument or an array with one element in it,
1692 the argument is checked for shell metacharacters, and if there are any,
1693 the entire argument is passed to the system's command shell for parsing
1694 (this is C</bin/sh -c> on Unix platforms, but varies on other platforms).
1695 If there are no shell metacharacters in the argument, it is split into
1696 words and passed directly to C<execvp>, which is more efficient.
1697 Examples:
1698
1699     exec '/bin/echo', 'Your arguments are: ', @ARGV;
1700     exec "sort $outfile | uniq";
1701
1702 If you don't really want to execute the first argument, but want to lie
1703 to the program you are executing about its own name, you can specify
1704 the program you actually want to run as an "indirect object" (without a
1705 comma) in front of the LIST.  (This always forces interpretation of the
1706 LIST as a multivalued list, even if there is only a single scalar in
1707 the list.)  Example:
1708
1709     $shell = '/bin/csh';
1710     exec $shell '-sh';    # pretend it's a login shell
1711
1712 or, more directly,
1713
1714     exec {'/bin/csh'} '-sh';  # pretend it's a login shell
1715
1716 When the arguments get executed via the system shell, results will
1717 be subject to its quirks and capabilities.  See L<perlop/"`STRING`">
1718 for details.
1719
1720 Using an indirect object with C<exec> or C<system> is also more
1721 secure.  This usage (which also works fine with system()) forces
1722 interpretation of the arguments as a multivalued list, even if the
1723 list had just one argument.  That way you're safe from the shell
1724 expanding wildcards or splitting up words with whitespace in them.
1725
1726     @args = ( "echo surprise" );
1727
1728     exec @args;               # subject to shell escapes
1729                                 # if @args == 1
1730     exec { $args[0] } @args;  # safe even with one-arg list
1731
1732 The first version, the one without the indirect object, ran the I<echo>
1733 program, passing it C<"surprise"> an argument.  The second version
1734 didn't--it tried to run a program literally called I<"echo surprise">,
1735 didn't find it, and set C<$?> to a non-zero value indicating failure.
1736
1737 Beginning with v5.6.0, Perl will attempt to flush all files opened for
1738 output before the exec, but this may not be supported on some platforms
1739 (see L<perlport>).  To be safe, you may need to set C<$|> ($AUTOFLUSH
1740 in English) or call the C<autoflush()> method of C<IO::Handle> on any
1741 open handles in order to avoid lost output.
1742
1743 Note that C<exec> will not call your C<END> blocks, nor will it call
1744 any C<DESTROY> methods in your objects.
1745
1746 =item exists EXPR
1747 X<exists> X<autovivification>
1748
1749 Given an expression that specifies a hash element or array element,
1750 returns true if the specified element in the hash or array has ever
1751 been initialized, even if the corresponding value is undefined.
1752
1753     print "Exists\n"    if exists $hash{$key};
1754     print "Defined\n"   if defined $hash{$key};
1755     print "True\n"      if $hash{$key};
1756
1757     print "Exists\n"    if exists $array[$index];
1758     print "Defined\n"   if defined $array[$index];
1759     print "True\n"      if $array[$index];
1760
1761 A hash or array element can be true only if it's defined, and defined if
1762 it exists, but the reverse doesn't necessarily hold true.
1763
1764 Given an expression that specifies the name of a subroutine,
1765 returns true if the specified subroutine has ever been declared, even
1766 if it is undefined.  Mentioning a subroutine name for exists or defined
1767 does not count as declaring it.  Note that a subroutine which does not
1768 exist may still be callable: its package may have an C<AUTOLOAD>
1769 method that makes it spring into existence the first time that it is
1770 called -- see L<perlsub>.
1771
1772     print "Exists\n"  if exists &subroutine;
1773     print "Defined\n" if defined &subroutine;
1774
1775 Note that the EXPR can be arbitrarily complicated as long as the final
1776 operation is a hash or array key lookup or subroutine name:
1777
1778     if (exists $ref->{A}->{B}->{$key})  { }
1779     if (exists $hash{A}{B}{$key})       { }
1780
1781     if (exists $ref->{A}->{B}->[$ix])   { }
1782     if (exists $hash{A}{B}[$ix])        { }
1783
1784     if (exists &{$ref->{A}{B}{$key}})   { }
1785
1786 Although the deepest nested array or hash will not spring into existence
1787 just because its existence was tested, any intervening ones will.
1788 Thus C<< $ref->{"A"} >> and C<< $ref->{"A"}->{"B"} >> will spring
1789 into existence due to the existence test for the $key element above.
1790 This happens anywhere the arrow operator is used, including even:
1791
1792     undef $ref;
1793     if (exists $ref->{"Some key"})    { }
1794     print $ref;  # prints HASH(0x80d3d5c)
1795
1796 This surprising autovivification in what does not at first--or even
1797 second--glance appear to be an lvalue context may be fixed in a future
1798 release.
1799
1800 Use of a subroutine call, rather than a subroutine name, as an argument
1801 to exists() is an error.
1802
1803     exists &sub;    # OK
1804     exists &sub();  # Error
1805
1806 =item exit EXPR
1807 X<exit> X<terminate> X<abort>
1808
1809 =item exit
1810
1811 Evaluates EXPR and exits immediately with that value.    Example:
1812
1813     $ans = <STDIN>;
1814     exit 0 if $ans =~ /^[Xx]/;
1815
1816 See also C<die>.  If EXPR is omitted, exits with C<0> status.  The only
1817 universally recognized values for EXPR are C<0> for success and C<1>
1818 for error; other values are subject to interpretation depending on the
1819 environment in which the Perl program is running.  For example, exiting
1820 69 (EX_UNAVAILABLE) from a I<sendmail> incoming-mail filter will cause
1821 the mailer to return the item undelivered, but that's not true everywhere.
1822
1823 Don't use C<exit> to abort a subroutine if there's any chance that
1824 someone might want to trap whatever error happened.  Use C<die> instead,
1825 which can be trapped by an C<eval>.
1826
1827 The exit() function does not always exit immediately.  It calls any
1828 defined C<END> routines first, but these C<END> routines may not
1829 themselves abort the exit.  Likewise any object destructors that need to
1830 be called are called before the real exit.  If this is a problem, you
1831 can call C<POSIX:_exit($status)> to avoid END and destructor processing.
1832 See L<perlmod> for details.
1833
1834 =item exp EXPR
1835 X<exp> X<exponential> X<antilog> X<antilogarithm> X<e>
1836
1837 =item exp
1838
1839 Returns I<e> (the natural logarithm base) to the power of EXPR.
1840 If EXPR is omitted, gives C<exp($_)>.
1841
1842 =item fcntl FILEHANDLE,FUNCTION,SCALAR
1843 X<fcntl>
1844
1845 Implements the fcntl(2) function.  You'll probably have to say
1846
1847     use Fcntl;
1848
1849 first to get the correct constant definitions.  Argument processing and
1850 value return works just like C<ioctl> below.
1851 For example:
1852
1853     use Fcntl;
1854     fcntl($filehandle, F_GETFL, $packed_return_buffer)
1855         or die "can't fcntl F_GETFL: $!";
1856
1857 You don't have to check for C<defined> on the return from C<fcntl>.
1858 Like C<ioctl>, it maps a C<0> return from the system call into
1859 C<"0 but true"> in Perl.  This string is true in boolean context and C<0>
1860 in numeric context.  It is also exempt from the normal B<-w> warnings
1861 on improper numeric conversions.
1862
1863 Note that C<fcntl> will produce a fatal error if used on a machine that
1864 doesn't implement fcntl(2).  See the Fcntl module or your fcntl(2)
1865 manpage to learn what functions are available on your system.
1866
1867 Here's an example of setting a filehandle named C<REMOTE> to be
1868 non-blocking at the system level.  You'll have to negotiate C<$|>
1869 on your own, though.
1870
1871     use Fcntl qw(F_GETFL F_SETFL O_NONBLOCK);
1872
1873     $flags = fcntl(REMOTE, F_GETFL, 0)
1874                 or die "Can't get flags for the socket: $!\n";
1875
1876     $flags = fcntl(REMOTE, F_SETFL, $flags | O_NONBLOCK)
1877                 or die "Can't set flags for the socket: $!\n";
1878
1879 =item fileno FILEHANDLE
1880 X<fileno>
1881
1882 Returns the file descriptor for a filehandle, or undefined if the
1883 filehandle is not open.  This is mainly useful for constructing
1884 bitmaps for C<select> and low-level POSIX tty-handling operations.
1885 If FILEHANDLE is an expression, the value is taken as an indirect
1886 filehandle, generally its name.
1887
1888 You can use this to find out whether two handles refer to the
1889 same underlying descriptor:
1890
1891     if (fileno(THIS) == fileno(THAT)) {
1892         print "THIS and THAT are dups\n";
1893     }
1894
1895 (Filehandles connected to memory objects via new features of C<open> may
1896 return undefined even though they are open.)
1897
1898
1899 =item flock FILEHANDLE,OPERATION
1900 X<flock> X<lock> X<locking>
1901
1902 Calls flock(2), or an emulation of it, on FILEHANDLE.  Returns true
1903 for success, false on failure.  Produces a fatal error if used on a
1904 machine that doesn't implement flock(2), fcntl(2) locking, or lockf(3).
1905 C<flock> is Perl's portable file locking interface, although it locks
1906 only entire files, not records.
1907
1908 Two potentially non-obvious but traditional C<flock> semantics are
1909 that it waits indefinitely until the lock is granted, and that its locks
1910 B<merely advisory>.  Such discretionary locks are more flexible, but offer
1911 fewer guarantees.  This means that programs that do not also use C<flock>
1912 may modify files locked with C<flock>.  See L<perlport>, 
1913 your port's specific documentation, or your system-specific local manpages
1914 for details.  It's best to assume traditional behavior if you're writing
1915 portable programs.  (But if you're not, you should as always feel perfectly
1916 free to write for your own system's idiosyncrasies (sometimes called
1917 "features").  Slavish adherence to portability concerns shouldn't get
1918 in the way of your getting your job done.)
1919
1920 OPERATION is one of LOCK_SH, LOCK_EX, or LOCK_UN, possibly combined with
1921 LOCK_NB.  These constants are traditionally valued 1, 2, 8 and 4, but
1922 you can use the symbolic names if you import them from the Fcntl module,
1923 either individually, or as a group using the ':flock' tag.  LOCK_SH
1924 requests a shared lock, LOCK_EX requests an exclusive lock, and LOCK_UN
1925 releases a previously requested lock.  If LOCK_NB is bitwise-or'ed with
1926 LOCK_SH or LOCK_EX then C<flock> will return immediately rather than blocking
1927 waiting for the lock (check the return status to see if you got it).
1928
1929 To avoid the possibility of miscoordination, Perl now flushes FILEHANDLE
1930 before locking or unlocking it.
1931
1932 Note that the emulation built with lockf(3) doesn't provide shared
1933 locks, and it requires that FILEHANDLE be open with write intent.  These
1934 are the semantics that lockf(3) implements.  Most if not all systems
1935 implement lockf(3) in terms of fcntl(2) locking, though, so the
1936 differing semantics shouldn't bite too many people.
1937
1938 Note that the fcntl(2) emulation of flock(3) requires that FILEHANDLE
1939 be open with read intent to use LOCK_SH and requires that it be open
1940 with write intent to use LOCK_EX.
1941
1942 Note also that some versions of C<flock> cannot lock things over the
1943 network; you would need to use the more system-specific C<fcntl> for
1944 that.  If you like you can force Perl to ignore your system's flock(2)
1945 function, and so provide its own fcntl(2)-based emulation, by passing
1946 the switch C<-Ud_flock> to the F<Configure> program when you configure
1947 perl.
1948
1949 Here's a mailbox appender for BSD systems.
1950
1951     use Fcntl qw(:flock SEEK_END); # import LOCK_* and SEEK_END constants
1952
1953     sub lock {
1954         my ($fh) = @_;
1955         flock($fh, LOCK_EX) or die "Cannot lock mailbox - $!\n";
1956
1957         # and, in case someone appended while we were waiting...
1958         seek($fh, 0, SEEK_END) or die "Cannot seek - $!\n";
1959     }
1960
1961     sub unlock {
1962         my ($fh) = @_;
1963         flock($fh, LOCK_UN) or die "Cannot unlock mailbox - $!\n";
1964     }
1965
1966     open(my $mbox, ">>", "/usr/spool/mail/$ENV{'USER'}")
1967         or die "Can't open mailbox: $!";
1968
1969     lock($mbox);
1970     print $mbox $msg,"\n\n";
1971     unlock($mbox);
1972
1973 On systems that support a real flock(), locks are inherited across fork()
1974 calls, whereas those that must resort to the more capricious fcntl()
1975 function lose the locks, making it harder to write servers.
1976
1977 See also L<DB_File> for other flock() examples.
1978
1979 =item fork
1980 X<fork> X<child> X<parent>
1981
1982 Does a fork(2) system call to create a new process running the
1983 same program at the same point.  It returns the child pid to the
1984 parent process, C<0> to the child process, or C<undef> if the fork is
1985 unsuccessful.  File descriptors (and sometimes locks on those descriptors)
1986 are shared, while everything else is copied.  On most systems supporting
1987 fork(), great care has gone into making it extremely efficient (for
1988 example, using copy-on-write technology on data pages), making it the
1989 dominant paradigm for multitasking over the last few decades.
1990
1991 Beginning with v5.6.0, Perl will attempt to flush all files opened for
1992 output before forking the child process, but this may not be supported
1993 on some platforms (see L<perlport>).  To be safe, you may need to set
1994 C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method of
1995 C<IO::Handle> on any open handles in order to avoid duplicate output.
1996
1997 If you C<fork> without ever waiting on your children, you will
1998 accumulate zombies.  On some systems, you can avoid this by setting
1999 C<$SIG{CHLD}> to C<"IGNORE">.  See also L<perlipc> for more examples of
2000 forking and reaping moribund children.
2001
2002 Note that if your forked child inherits system file descriptors like
2003 STDIN and STDOUT that are actually connected by a pipe or socket, even
2004 if you exit, then the remote server (such as, say, a CGI script or a
2005 backgrounded job launched from a remote shell) won't think you're done.
2006 You should reopen those to F</dev/null> if it's any issue.
2007
2008 =item format
2009 X<format>
2010
2011 Declare a picture format for use by the C<write> function.  For
2012 example:
2013
2014     format Something =
2015         Test: @<<<<<<<< @||||| @>>>>>
2016               $str,     $%,    '$' . int($num)
2017     .
2018
2019     $str = "widget";
2020     $num = $cost/$quantity;
2021     $~ = 'Something';
2022     write;
2023
2024 See L<perlform> for many details and examples.
2025
2026 =item formline PICTURE,LIST
2027 X<formline>
2028
2029 This is an internal function used by C<format>s, though you may call it,
2030 too.  It formats (see L<perlform>) a list of values according to the
2031 contents of PICTURE, placing the output into the format output
2032 accumulator, C<$^A> (or C<$ACCUMULATOR> in English).
2033 Eventually, when a C<write> is done, the contents of
2034 C<$^A> are written to some filehandle.  You could also read C<$^A>
2035 and then set C<$^A> back to C<"">.  Note that a format typically
2036 does one C<formline> per line of form, but the C<formline> function itself
2037 doesn't care how many newlines are embedded in the PICTURE.  This means
2038 that the C<~> and C<~~> tokens will treat the entire PICTURE as a single line.
2039 You may therefore need to use multiple formlines to implement a single
2040 record format, just like the format compiler.
2041
2042 Be careful if you put double quotes around the picture, because an C<@>
2043 character may be taken to mean the beginning of an array name.
2044 C<formline> always returns true.  See L<perlform> for other examples.
2045
2046 =item getc FILEHANDLE
2047 X<getc> X<getchar> X<character> X<file, read>
2048
2049 =item getc
2050
2051 Returns the next character from the input file attached to FILEHANDLE,
2052 or the undefined value at end of file, or if there was an error (in
2053 the latter case C<$!> is set).  If FILEHANDLE is omitted, reads from
2054 STDIN.  This is not particularly efficient.  However, it cannot be
2055 used by itself to fetch single characters without waiting for the user
2056 to hit enter.  For that, try something more like:
2057
2058     if ($BSD_STYLE) {
2059         system "stty cbreak </dev/tty >/dev/tty 2>&1";
2060     }
2061     else {
2062         system "stty", '-icanon', 'eol', "\001";
2063     }
2064
2065     $key = getc(STDIN);
2066
2067     if ($BSD_STYLE) {
2068         system "stty -cbreak </dev/tty >/dev/tty 2>&1";
2069     }
2070     else {
2071         system "stty", 'icanon', 'eol', '^@'; # ASCII null
2072     }
2073     print "\n";
2074
2075 Determination of whether $BSD_STYLE should be set
2076 is left as an exercise to the reader.
2077
2078 The C<POSIX::getattr> function can do this more portably on
2079 systems purporting POSIX compliance.  See also the C<Term::ReadKey>
2080 module from your nearest CPAN site; details on CPAN can be found on
2081 L<perlmodlib/CPAN>.
2082
2083 =item getlogin
2084 X<getlogin> X<login>
2085
2086 This implements the C library function of the same name, which on most
2087 systems returns the current login from F</etc/utmp>, if any.  If null,
2088 use C<getpwuid>.
2089
2090     $login = getlogin || getpwuid($<) || "Kilroy";
2091
2092 Do not consider C<getlogin> for authentication: it is not as
2093 secure as C<getpwuid>.
2094
2095 =item getpeername SOCKET
2096 X<getpeername> X<peer>
2097
2098 Returns the packed sockaddr address of other end of the SOCKET connection.
2099
2100     use Socket;
2101     $hersockaddr    = getpeername(SOCK);
2102     ($port, $iaddr) = sockaddr_in($hersockaddr);
2103     $herhostname    = gethostbyaddr($iaddr, AF_INET);
2104     $herstraddr     = inet_ntoa($iaddr);
2105
2106 =item getpgrp PID
2107 X<getpgrp> X<group>
2108
2109 Returns the current process group for the specified PID.  Use
2110 a PID of C<0> to get the current process group for the
2111 current process.  Will raise an exception if used on a machine that
2112 doesn't implement getpgrp(2).  If PID is omitted, returns process
2113 group of current process.  Note that the POSIX version of C<getpgrp>
2114 does not accept a PID argument, so only C<PID==0> is truly portable.
2115
2116 =item getppid
2117 X<getppid> X<parent> X<pid>
2118
2119 Returns the process id of the parent process.
2120
2121 Note for Linux users: on Linux, the C functions C<getpid()> and
2122 C<getppid()> return different values from different threads. In order to
2123 be portable, this behavior is not reflected by the perl-level function
2124 C<getppid()>, that returns a consistent value across threads. If you want
2125 to call the underlying C<getppid()>, you may use the CPAN module
2126 C<Linux::Pid>.
2127
2128 =item getpriority WHICH,WHO
2129 X<getpriority> X<priority> X<nice>
2130
2131 Returns the current priority for a process, a process group, or a user.
2132 (See C<getpriority(2)>.)  Will raise a fatal exception if used on a
2133 machine that doesn't implement getpriority(2).
2134
2135 =item getpwnam NAME
2136 X<getpwnam> X<getgrnam> X<gethostbyname> X<getnetbyname> X<getprotobyname>
2137 X<getpwuid> X<getgrgid> X<getservbyname> X<gethostbyaddr> X<getnetbyaddr>
2138 X<getprotobynumber> X<getservbyport> X<getpwent> X<getgrent> X<gethostent>
2139 X<getnetent> X<getprotoent> X<getservent> X<setpwent> X<setgrent> X<sethostent>
2140 X<setnetent> X<setprotoent> X<setservent> X<endpwent> X<endgrent> X<endhostent>
2141 X<endnetent> X<endprotoent> X<endservent> 
2142
2143 =item getgrnam NAME
2144
2145 =item gethostbyname NAME
2146
2147 =item getnetbyname NAME
2148
2149 =item getprotobyname NAME
2150
2151 =item getpwuid UID
2152
2153 =item getgrgid GID
2154
2155 =item getservbyname NAME,PROTO
2156
2157 =item gethostbyaddr ADDR,ADDRTYPE
2158
2159 =item getnetbyaddr ADDR,ADDRTYPE
2160
2161 =item getprotobynumber NUMBER
2162
2163 =item getservbyport PORT,PROTO
2164
2165 =item getpwent
2166
2167 =item getgrent
2168
2169 =item gethostent
2170
2171 =item getnetent
2172
2173 =item getprotoent
2174
2175 =item getservent
2176
2177 =item setpwent
2178
2179 =item setgrent
2180
2181 =item sethostent STAYOPEN
2182
2183 =item setnetent STAYOPEN
2184
2185 =item setprotoent STAYOPEN
2186
2187 =item setservent STAYOPEN
2188
2189 =item endpwent
2190
2191 =item endgrent
2192
2193 =item endhostent
2194
2195 =item endnetent
2196
2197 =item endprotoent
2198
2199 =item endservent
2200
2201 These routines perform the same functions as their counterparts in the
2202 system library.  In list context, the return values from the
2203 various get routines are as follows:
2204
2205     ($name,$passwd,$uid,$gid,
2206        $quota,$comment,$gcos,$dir,$shell,$expire) = getpw*
2207     ($name,$passwd,$gid,$members) = getgr*
2208     ($name,$aliases,$addrtype,$length,@addrs) = gethost*
2209     ($name,$aliases,$addrtype,$net) = getnet*
2210     ($name,$aliases,$proto) = getproto*
2211     ($name,$aliases,$port,$proto) = getserv*
2212
2213 (If the entry doesn't exist you get a null list.)
2214
2215 The exact meaning of the $gcos field varies but it usually contains
2216 the real name of the user (as opposed to the login name) and other
2217 information pertaining to the user.  Beware, however, that in many
2218 system users are able to change this information and therefore it
2219 cannot be trusted and therefore the $gcos is tainted (see
2220 L<perlsec>).  The $passwd and $shell, user's encrypted password and
2221 login shell, are also tainted, because of the same reason.
2222
2223 In scalar context, you get the name, unless the function was a
2224 lookup by name, in which case you get the other thing, whatever it is.
2225 (If the entry doesn't exist you get the undefined value.)  For example:
2226
2227     $uid   = getpwnam($name);
2228     $name  = getpwuid($num);
2229     $name  = getpwent();
2230     $gid   = getgrnam($name);
2231     $name  = getgrgid($num);
2232     $name  = getgrent();
2233     #etc.
2234
2235 In I<getpw*()> the fields $quota, $comment, and $expire are special
2236 cases in the sense that in many systems they are unsupported.  If the
2237 $quota is unsupported, it is an empty scalar.  If it is supported, it
2238 usually encodes the disk quota.  If the $comment field is unsupported,
2239 it is an empty scalar.  If it is supported it usually encodes some
2240 administrative comment about the user.  In some systems the $quota
2241 field may be $change or $age, fields that have to do with password
2242 aging.  In some systems the $comment field may be $class.  The $expire
2243 field, if present, encodes the expiration period of the account or the
2244 password.  For the availability and the exact meaning of these fields
2245 in your system, please consult your getpwnam(3) documentation and your
2246 F<pwd.h> file.  You can also find out from within Perl what your
2247 $quota and $comment fields mean and whether you have the $expire field
2248 by using the C<Config> module and the values C<d_pwquota>, C<d_pwage>,
2249 C<d_pwchange>, C<d_pwcomment>, and C<d_pwexpire>.  Shadow password
2250 files are only supported if your vendor has implemented them in the
2251 intuitive fashion that calling the regular C library routines gets the
2252 shadow versions if you're running under privilege or if there exists
2253 the shadow(3) functions as found in System V (this includes Solaris
2254 and Linux.)  Those systems that implement a proprietary shadow password
2255 facility are unlikely to be supported.
2256
2257 The $members value returned by I<getgr*()> is a space separated list of
2258 the login names of the members of the group.
2259
2260 For the I<gethost*()> functions, if the C<h_errno> variable is supported in
2261 C, it will be returned to you via C<$?> if the function call fails.  The
2262 C<@addrs> value returned by a successful call is a list of the raw
2263 addresses returned by the corresponding system library call.  In the
2264 Internet domain, each address is four bytes long and you can unpack it
2265 by saying something like:
2266
2267     ($a,$b,$c,$d) = unpack('W4',$addr[0]);
2268
2269 The Socket library makes this slightly easier:
2270
2271     use Socket;
2272     $iaddr = inet_aton("127.1"); # or whatever address
2273     $name  = gethostbyaddr($iaddr, AF_INET);
2274
2275     # or going the other way
2276     $straddr = inet_ntoa($iaddr);
2277
2278 In the opposite way, to resolve a hostname to the IP address
2279 you can write this:
2280
2281     use Socket;
2282     $packed_ip = gethostbyname("www.perl.org");
2283     if (defined $packed_ip) {
2284         $ip_address = inet_ntoa($packed_ip);
2285     }
2286
2287 Make sure <gethostbyname()> is called in SCALAR context and that
2288 its return value is checked for definedness.
2289
2290 If you get tired of remembering which element of the return list
2291 contains which return value, by-name interfaces are provided
2292 in standard modules: C<File::stat>, C<Net::hostent>, C<Net::netent>,
2293 C<Net::protoent>, C<Net::servent>, C<Time::gmtime>, C<Time::localtime>,
2294 and C<User::grent>.  These override the normal built-ins, supplying
2295 versions that return objects with the appropriate names
2296 for each field.  For example:
2297
2298    use File::stat;
2299    use User::pwent;
2300    $is_his = (stat($filename)->uid == pwent($whoever)->uid);
2301
2302 Even though it looks like they're the same method calls (uid),
2303 they aren't, because a C<File::stat> object is different from
2304 a C<User::pwent> object.
2305
2306 =item getsockname SOCKET
2307 X<getsockname>
2308
2309 Returns the packed sockaddr address of this end of the SOCKET connection,
2310 in case you don't know the address because you have several different
2311 IPs that the connection might have come in on.
2312
2313     use Socket;
2314     $mysockaddr = getsockname(SOCK);
2315     ($port, $myaddr) = sockaddr_in($mysockaddr);
2316     printf "Connect to %s [%s]\n",
2317        scalar gethostbyaddr($myaddr, AF_INET),
2318        inet_ntoa($myaddr);
2319
2320 =item getsockopt SOCKET,LEVEL,OPTNAME
2321 X<getsockopt>
2322
2323 Queries the option named OPTNAME associated with SOCKET at a given LEVEL.
2324 Options may exist at multiple protocol levels depending on the socket
2325 type, but at least the uppermost socket level SOL_SOCKET (defined in the
2326 C<Socket> module) will exist. To query options at another level the
2327 protocol number of the appropriate protocol controlling the option
2328 should be supplied. For example, to indicate that an option is to be
2329 interpreted by the TCP protocol, LEVEL should be set to the protocol
2330 number of TCP, which you can get using getprotobyname.
2331
2332 The call returns a packed string representing the requested socket option,
2333 or C<undef> if there is an error (the error reason will be in $!). What
2334 exactly is in the packed string depends in the LEVEL and OPTNAME, consult
2335 your system documentation for details. A very common case however is that
2336 the option is an integer, in which case the result will be a packed
2337 integer which you can decode using unpack with the C<i> (or C<I>) format.
2338
2339 An example testing if Nagle's algorithm is turned on on a socket:
2340
2341     use Socket qw(:all);
2342
2343     defined(my $tcp = getprotobyname("tcp"))
2344         or die "Could not determine the protocol number for tcp";
2345     # my $tcp = IPPROTO_TCP; # Alternative
2346     my $packed = getsockopt($socket, $tcp, TCP_NODELAY)
2347         or die "Could not query TCP_NODELAY socket option: $!";
2348     my $nodelay = unpack("I", $packed);
2349     print "Nagle's algorithm is turned ", $nodelay ? "off\n" : "on\n";
2350
2351
2352 =item glob EXPR
2353 X<glob> X<wildcard> X<filename, expansion> X<expand>
2354
2355 =item glob
2356
2357 In list context, returns a (possibly empty) list of filename expansions on
2358 the value of EXPR such as the standard Unix shell F</bin/csh> would do. In
2359 scalar context, glob iterates through such filename expansions, returning
2360 undef when the list is exhausted. This is the internal function
2361 implementing the C<< <*.c> >> operator, but you can use it directly. If
2362 EXPR is omitted, C<$_> is used.  The C<< <*.c> >> operator is discussed in
2363 more detail in L<perlop/"I/O Operators">.
2364
2365 Note that C<glob> will split its arguments on whitespace, treating
2366 each segment as separate pattern.  As such, C<glob('*.c *.h')> would
2367 match all files with a F<.c> or F<.h> extension.  The expression
2368 C<glob('.* *')> would match all files in the current working directory.
2369
2370 Beginning with v5.6.0, this operator is implemented using the standard
2371 C<File::Glob> extension.  See L<File::Glob> for details, including
2372 C<bsd_glob> which does not treat whitespace as a pattern separator.
2373
2374 =item gmtime EXPR
2375 X<gmtime> X<UTC> X<Greenwich>
2376
2377 =item gmtime
2378
2379 Works just like L<localtime> but the returned values are
2380 localized for the standard Greenwich time zone.
2381
2382 Note: when called in list context, $isdst, the last value
2383 returned by gmtime is always C<0>.  There is no
2384 Daylight Saving Time in GMT.
2385
2386 See L<perlport/gmtime> for portability concerns.
2387
2388 =item goto LABEL
2389 X<goto> X<jump> X<jmp>
2390
2391 =item goto EXPR
2392
2393 =item goto &NAME
2394
2395 The C<goto-LABEL> form finds the statement labeled with LABEL and
2396 resumes execution there. It can't be used to get out of a block or
2397 subroutine given to C<sort>.  It can be used to go almost anywhere
2398 else within the dynamic scope, including out of subroutines, but it's
2399 usually better to use some other construct such as C<last> or C<die>.
2400 The author of Perl has never felt the need to use this form of C<goto>
2401 (in Perl, that is--C is another matter).  (The difference being that C
2402 does not offer named loops combined with loop control.  Perl does, and
2403 this replaces most structured uses of C<goto> in other languages.)
2404
2405 The C<goto-EXPR> form expects a label name, whose scope will be resolved
2406 dynamically.  This allows for computed C<goto>s per FORTRAN, but isn't
2407 necessarily recommended if you're optimizing for maintainability:
2408
2409     goto ("FOO", "BAR", "GLARCH")[$i];
2410
2411 Use of C<goto-LABEL> or C<goto-EXPR> to jump into a construct is
2412 deprecated and will issue a warning.  Even then, it may not be used to
2413 go into any construct that requires initialization, such as a
2414 subroutine or a C<foreach> loop.  It also can't be used to go into a
2415 construct that is optimized away.
2416
2417 The C<goto-&NAME> form is quite different from the other forms of
2418 C<goto>.  In fact, it isn't a goto in the normal sense at all, and
2419 doesn't have the stigma associated with other gotos.  Instead, it
2420 exits the current subroutine (losing any changes set by local()) and
2421 immediately calls in its place the named subroutine using the current
2422 value of @_.  This is used by C<AUTOLOAD> subroutines that wish to
2423 load another subroutine and then pretend that the other subroutine had
2424 been called in the first place (except that any modifications to C<@_>
2425 in the current subroutine are propagated to the other subroutine.)
2426 After the C<goto>, not even C<caller> will be able to tell that this
2427 routine was called first.
2428
2429 NAME needn't be the name of a subroutine; it can be a scalar variable
2430 containing a code reference, or a block that evaluates to a code
2431 reference.
2432
2433 =item grep BLOCK LIST
2434 X<grep>
2435
2436 =item grep EXPR,LIST
2437
2438 This is similar in spirit to, but not the same as, grep(1) and its
2439 relatives.  In particular, it is not limited to using regular expressions.
2440
2441 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
2442 C<$_> to each element) and returns the list value consisting of those
2443 elements for which the expression evaluated to true.  In scalar
2444 context, returns the number of times the expression was true.
2445
2446     @foo = grep(!/^#/, @bar);    # weed out comments
2447
2448 or equivalently,
2449
2450     @foo = grep {!/^#/} @bar;    # weed out comments
2451
2452 Note that C<$_> is an alias to the list value, so it can be used to
2453 modify the elements of the LIST.  While this is useful and supported,
2454 it can cause bizarre results if the elements of LIST are not variables.
2455 Similarly, grep returns aliases into the original list, much as a for
2456 loop's index variable aliases the list elements.  That is, modifying an
2457 element of a list returned by grep (for example, in a C<foreach>, C<map>
2458 or another C<grep>) actually modifies the element in the original list.
2459 This is usually something to be avoided when writing clear code.
2460
2461 If C<$_> is lexical in the scope where the C<grep> appears (because it has
2462 been declared with C<my $_>) then, in addition to being locally aliased to
2463 the list elements, C<$_> keeps being lexical inside the block; i.e. it
2464 can't be seen from the outside, avoiding any potential side-effects.
2465
2466 See also L</map> for a list composed of the results of the BLOCK or EXPR.
2467
2468 =item hex EXPR
2469 X<hex> X<hexadecimal>
2470
2471 =item hex
2472
2473 Interprets EXPR as a hex string and returns the corresponding value.
2474 (To convert strings that might start with either C<0>, C<0x>, or C<0b>, see
2475 L</oct>.)  If EXPR is omitted, uses C<$_>.
2476
2477     print hex '0xAf'; # prints '175'
2478     print hex 'aF';   # same
2479
2480 Hex strings may only represent integers.  Strings that would cause
2481 integer overflow trigger a warning.  Leading whitespace is not stripped,
2482 unlike oct(). To present something as hex, look into L</printf>,
2483 L</sprintf>, or L</unpack>.
2484
2485 =item import LIST
2486 X<import>
2487
2488 There is no builtin C<import> function.  It is just an ordinary
2489 method (subroutine) defined (or inherited) by modules that wish to export
2490 names to another module.  The C<use> function calls the C<import> method
2491 for the package used.  See also L</use>, L<perlmod>, and L<Exporter>.
2492
2493 =item index STR,SUBSTR,POSITION
2494 X<index> X<indexOf> X<InStr>
2495
2496 =item index STR,SUBSTR
2497
2498 The index function searches for one string within another, but without
2499 the wildcard-like behavior of a full regular-expression pattern match.
2500 It returns the position of the first occurrence of SUBSTR in STR at
2501 or after POSITION.  If POSITION is omitted, starts searching from the
2502 beginning of the string.  POSITION before the beginning of the string
2503 or after its end is treated as if it were the beginning or the end,
2504 respectively.  POSITION and the return value are based at C<0> (or whatever
2505 you've set the C<$[> variable to--but don't do that).  If the substring
2506 is not found, C<index> returns one less than the base, ordinarily C<-1>.
2507
2508 =item int EXPR
2509 X<int> X<integer> X<truncate> X<trunc> X<floor>
2510
2511 =item int
2512
2513 Returns the integer portion of EXPR.  If EXPR is omitted, uses C<$_>.
2514 You should not use this function for rounding: one because it truncates
2515 towards C<0>, and two because machine representations of floating point
2516 numbers can sometimes produce counterintuitive results.  For example,
2517 C<int(-6.725/0.025)> produces -268 rather than the correct -269; that's
2518 because it's really more like -268.99999999999994315658 instead.  Usually,
2519 the C<sprintf>, C<printf>, or the C<POSIX::floor> and C<POSIX::ceil>
2520 functions will serve you better than will int().
2521
2522 =item ioctl FILEHANDLE,FUNCTION,SCALAR
2523 X<ioctl>
2524
2525 Implements the ioctl(2) function.  You'll probably first have to say
2526
2527     require "sys/ioctl.ph";  # probably in $Config{archlib}/sys/ioctl.ph
2528
2529 to get the correct function definitions.  If F<sys/ioctl.ph> doesn't
2530 exist or doesn't have the correct definitions you'll have to roll your
2531 own, based on your C header files such as F<< <sys/ioctl.h> >>.
2532 (There is a Perl script called B<h2ph> that comes with the Perl kit that
2533 may help you in this, but it's nontrivial.)  SCALAR will be read and/or
2534 written depending on the FUNCTION--a pointer to the string value of SCALAR
2535 will be passed as the third argument of the actual C<ioctl> call.  (If SCALAR
2536 has no string value but does have a numeric value, that value will be
2537 passed rather than a pointer to the string value.  To guarantee this to be
2538 true, add a C<0> to the scalar before using it.)  The C<pack> and C<unpack>
2539 functions may be needed to manipulate the values of structures used by
2540 C<ioctl>.
2541
2542 The return value of C<ioctl> (and C<fcntl>) is as follows:
2543
2544     if OS returns:      then Perl returns:
2545         -1               undefined value
2546          0              string "0 but true"
2547     anything else           that number
2548
2549 Thus Perl returns true on success and false on failure, yet you can
2550 still easily determine the actual value returned by the operating
2551 system:
2552
2553     $retval = ioctl(...) || -1;
2554     printf "System returned %d\n", $retval;
2555
2556 The special string C<"0 but true"> is exempt from B<-w> complaints
2557 about improper numeric conversions.
2558
2559 =item join EXPR,LIST
2560 X<join>
2561
2562 Joins the separate strings of LIST into a single string with fields
2563 separated by the value of EXPR, and returns that new string.  Example:
2564
2565     $rec = join(':', $login,$passwd,$uid,$gid,$gcos,$home,$shell);
2566
2567 Beware that unlike C<split>, C<join> doesn't take a pattern as its
2568 first argument.  Compare L</split>.
2569
2570 =item keys HASH
2571 X<keys> X<key>
2572
2573 =item keys ARRAY
2574
2575 Returns a list consisting of all the keys of the named hash, or the indices
2576 of an array. (In scalar context, returns the number of keys or indices.)
2577
2578 The keys of a hash are returned in an apparently random order.  The actual
2579 random order is subject to change in future versions of perl, but it
2580 is guaranteed to be the same order as either the C<values> or C<each>
2581 function produces (given that the hash has not been modified).  Since
2582 Perl 5.8.1 the ordering is different even between different runs of
2583 Perl for security reasons (see L<perlsec/"Algorithmic Complexity
2584 Attacks">).
2585
2586 As a side effect, calling keys() resets the HASH or ARRAY's internal iterator
2587 (see L</each>).  In particular, calling keys() in void context resets
2588 the iterator with no other overhead.
2589
2590 Here is yet another way to print your environment:
2591
2592     @keys = keys %ENV;
2593     @values = values %ENV;
2594     while (@keys) {
2595         print pop(@keys), '=', pop(@values), "\n";
2596     }
2597
2598 or how about sorted by key:
2599
2600     foreach $key (sort(keys %ENV)) {
2601         print $key, '=', $ENV{$key}, "\n";
2602     }
2603
2604 The returned values are copies of the original keys in the hash, so
2605 modifying them will not affect the original hash.  Compare L</values>.
2606
2607 To sort a hash by value, you'll need to use a C<sort> function.
2608 Here's a descending numeric sort of a hash by its values:
2609
2610     foreach $key (sort { $hash{$b} <=> $hash{$a} } keys %hash) {
2611         printf "%4d %s\n", $hash{$key}, $key;
2612     }
2613
2614 As an lvalue C<keys> allows you to increase the number of hash buckets
2615 allocated for the given hash.  This can gain you a measure of efficiency if
2616 you know the hash is going to get big.  (This is similar to pre-extending
2617 an array by assigning a larger number to $#array.)  If you say
2618
2619     keys %hash = 200;
2620
2621 then C<%hash> will have at least 200 buckets allocated for it--256 of them,
2622 in fact, since it rounds up to the next power of two.  These
2623 buckets will be retained even if you do C<%hash = ()>, use C<undef
2624 %hash> if you want to free the storage while C<%hash> is still in scope.
2625 You can't shrink the number of buckets allocated for the hash using
2626 C<keys> in this way (but you needn't worry about doing this by accident,
2627 as trying has no effect). C<keys @array> in an lvalue context is a syntax
2628 error.
2629
2630 See also C<each>, C<values> and C<sort>.
2631
2632 =item kill SIGNAL, LIST
2633 X<kill> X<signal>
2634
2635 Sends a signal to a list of processes.  Returns the number of
2636 processes successfully signaled (which is not necessarily the
2637 same as the number actually killed).
2638
2639     $cnt = kill 1, $child1, $child2;
2640     kill 9, @goners;
2641
2642 If SIGNAL is zero, no signal is sent to the process, but the kill(2)
2643 system call will check whether it's possible to send a signal to it (that
2644 means, to be brief, that the process is owned by the same user, or we are
2645 the super-user).  This is a useful way to check that a child process is
2646 alive (even if only as a zombie) and hasn't changed its UID.  See
2647 L<perlport> for notes on the portability of this construct.
2648
2649 Unlike in the shell, if SIGNAL is negative, it kills process groups instead
2650 of processes. That means you usually want to use positive not negative signals.
2651 You may also use a signal name in quotes.
2652
2653 The behavior of kill when a I<PROCESS> number is zero or negative depends on
2654 the operating system.  For example, on POSIX-conforming systems, zero will
2655 signal the current process group and -1 will signal all processes.
2656
2657 See L<perlipc/"Signals"> for more details.
2658
2659 =item last LABEL
2660 X<last> X<break>
2661
2662 =item last
2663
2664 The C<last> command is like the C<break> statement in C (as used in
2665 loops); it immediately exits the loop in question.  If the LABEL is
2666 omitted, the command refers to the innermost enclosing loop.  The
2667 C<continue> block, if any, is not executed:
2668
2669     LINE: while (<STDIN>) {
2670         last LINE if /^$/;  # exit when done with header
2671         #...
2672     }
2673
2674 C<last> cannot be used to exit a block which returns a value such as
2675 C<eval {}>, C<sub {}> or C<do {}>, and should not be used to exit
2676 a grep() or map() operation.
2677
2678 Note that a block by itself is semantically identical to a loop
2679 that executes once.  Thus C<last> can be used to effect an early
2680 exit out of such a block.
2681
2682 See also L</continue> for an illustration of how C<last>, C<next>, and
2683 C<redo> work.
2684
2685 =item lc EXPR
2686 X<lc> X<lowercase>
2687
2688 =item lc
2689
2690 Returns a lowercased version of EXPR.  This is the internal function
2691 implementing the C<\L> escape in double-quoted strings.
2692
2693 If EXPR is omitted, uses C<$_>.
2694
2695 What gets returned depends on several factors:
2696
2697 =over
2698
2699 =item If C<use bytes> is in effect:
2700
2701 =over
2702
2703 =item On EBCDIC platforms
2704
2705 The results are what the C language system call C<tolower()> returns.
2706
2707 =item On ASCII platforms
2708
2709 The results follow ASCII semantics.  Only characters C<A-Z> change, to C<a-z>
2710 respectively.
2711
2712 =back
2713
2714 =item Otherwise, If EXPR has the UTF8 flag set
2715
2716 If the current package has a subroutine named C<ToLower>, it will be used to
2717 change the case (See L<perlunicode/User-Defined Case Mappings>.)
2718 Otherwise Unicode semantics are used for the case change.
2719
2720 =item Otherwise, if C<use locale> is in effect
2721
2722 Respects current LC_CTYPE locale.  See L<perllocale>.
2723
2724 =item Otherwise, if C<use feature 'unicode_strings'> is in effect:
2725
2726 Unicode semantics are used for the case change.  Any subroutine named
2727 C<ToLower> will not be used.
2728
2729 =item Otherwise:
2730
2731 =over
2732
2733 =item On EBCDIC platforms
2734
2735 The results are what the C language system call C<tolower()> returns.
2736
2737 =item On ASCII platforms
2738
2739 ASCII semantics are used for the case change.  The lowercase of any character
2740 outside the ASCII range is the character itself.
2741
2742 =back
2743
2744 =back
2745
2746 =item lcfirst EXPR
2747 X<lcfirst> X<lowercase>
2748
2749 =item lcfirst
2750
2751 Returns the value of EXPR with the first character lowercased.  This
2752 is the internal function implementing the C<\l> escape in
2753 double-quoted strings.
2754
2755 If EXPR is omitted, uses C<$_>.
2756
2757 This function behaves the same way under various pragma, such as in a locale,
2758 as L</lc> does.
2759
2760 =item length EXPR
2761 X<length> X<size>
2762
2763 =item length
2764
2765 Returns the length in I<characters> of the value of EXPR.  If EXPR is
2766 omitted, returns length of C<$_>.  If EXPR is undefined, returns C<undef>.
2767 Note that this cannot be used on an entire array or hash to find out how
2768 many elements these have. For that, use C<scalar @array> and C<scalar keys
2769 %hash> respectively.
2770
2771 Note the I<characters>: if the EXPR is in Unicode, you will get the
2772 number of characters, not the number of bytes.  To get the length
2773 of the internal string in bytes, use C<bytes::length(EXPR)>, see
2774 L<bytes>.  Note that the internal encoding is variable, and the number
2775 of bytes usually meaningless.  To get the number of bytes that the
2776 string would have when encoded as UTF-8, use
2777 C<length(Encoding::encode_utf8(EXPR))>.
2778
2779 =item link OLDFILE,NEWFILE
2780 X<link>
2781
2782 Creates a new filename linked to the old filename.  Returns true for
2783 success, false otherwise.
2784
2785 =item listen SOCKET,QUEUESIZE
2786 X<listen>
2787
2788 Does the same thing that the listen system call does.  Returns true if
2789 it succeeded, false otherwise.  See the example in
2790 L<perlipc/"Sockets: Client/Server Communication">.
2791
2792 =item local EXPR
2793 X<local>
2794
2795 You really probably want to be using C<my> instead, because C<local> isn't
2796 what most people think of as "local".  See
2797 L<perlsub/"Private Variables via my()"> for details.
2798
2799 A local modifies the listed variables to be local to the enclosing
2800 block, file, or eval.  If more than one value is listed, the list must
2801 be placed in parentheses.  See L<perlsub/"Temporary Values via local()">
2802 for details, including issues with tied arrays and hashes.
2803
2804 The C<delete local EXPR> construct can also be used to localize the deletion
2805 of array/hash elements to the current block.
2806 See L<perlsub/"Localized deletion of elements of composite types">.
2807
2808 =item localtime EXPR
2809 X<localtime> X<ctime>
2810
2811 =item localtime
2812
2813 Converts a time as returned by the time function to a 9-element list
2814 with the time analyzed for the local time zone.  Typically used as
2815 follows:
2816
2817     #  0    1    2     3     4    5     6     7     8
2818     ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst) =
2819                                                 localtime(time);
2820
2821 All list elements are numeric, and come straight out of the C `struct
2822 tm'.  C<$sec>, C<$min>, and C<$hour> are the seconds, minutes, and hours
2823 of the specified time.
2824
2825 C<$mday> is the day of the month, and C<$mon> is the month itself, in
2826 the range C<0..11> with 0 indicating January and 11 indicating December.
2827 This makes it easy to get a month name from a list:
2828
2829     my @abbr = qw( Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec );
2830     print "$abbr[$mon] $mday";
2831     # $mon=9, $mday=18 gives "Oct 18"
2832
2833 C<$year> is the number of years since 1900, not just the last two digits
2834 of the year.  That is, C<$year> is C<123> in year 2023.  The proper way
2835 to get a complete 4-digit year is simply:
2836
2837     $year += 1900;
2838
2839 Otherwise you create non-Y2K-compliant programs--and you wouldn't want
2840 to do that, would you?
2841
2842 To get the last two digits of the year (e.g., '01' in 2001) do:
2843
2844     $year = sprintf("%02d", $year % 100);
2845
2846 C<$wday> is the day of the week, with 0 indicating Sunday and 3 indicating
2847 Wednesday.  C<$yday> is the day of the year, in the range C<0..364>
2848 (or C<0..365> in leap years.)
2849
2850 C<$isdst> is true if the specified time occurs during Daylight Saving
2851 Time, false otherwise.
2852
2853 If EXPR is omitted, C<localtime()> uses the current time (as returned
2854 by time(3)).
2855
2856 In scalar context, C<localtime()> returns the ctime(3) value:
2857
2858     $now_string = localtime;  # e.g., "Thu Oct 13 04:54:34 1994"
2859
2860 This scalar value is B<not> locale dependent but is a Perl builtin. For GMT
2861 instead of local time use the L</gmtime> builtin. See also the
2862 C<Time::Local> module (to convert the second, minutes, hours, ... back to
2863 the integer value returned by time()), and the L<POSIX> module's strftime(3)
2864 and mktime(3) functions.
2865
2866 To get somewhat similar but locale dependent date strings, set up your
2867 locale environment variables appropriately (please see L<perllocale>) and
2868 try for example:
2869
2870     use POSIX qw(strftime);
2871     $now_string = strftime "%a %b %e %H:%M:%S %Y", localtime;
2872     # or for GMT formatted appropriately for your locale:
2873     $now_string = strftime "%a %b %e %H:%M:%S %Y", gmtime;
2874
2875 Note that the C<%a> and C<%b>, the short forms of the day of the week
2876 and the month of the year, may not necessarily be three characters wide.
2877
2878 See L<perlport/localtime> for portability concerns.
2879
2880 The L<Time::gmtime> and L<Time::localtime> modules provides a convenient,
2881 by-name access mechanism to the gmtime() and localtime() functions,
2882 respectively.
2883
2884 For a comprehensive date and time representation look at the
2885 L<DateTime> module on CPAN.
2886
2887 =item lock THING
2888 X<lock>
2889
2890 This function places an advisory lock on a shared variable, or referenced
2891 object contained in I<THING> until the lock goes out of scope.
2892
2893 lock() is a "weak keyword" : this means that if you've defined a function
2894 by this name (before any calls to it), that function will be called
2895 instead. (However, if you've said C<use threads>, lock() is always a
2896 keyword.) See L<threads>.
2897
2898 =item log EXPR
2899 X<log> X<logarithm> X<e> X<ln> X<base>
2900
2901 =item log
2902
2903 Returns the natural logarithm (base I<e>) of EXPR.  If EXPR is omitted,
2904 returns log of C<$_>.  To get the log of another base, use basic algebra:
2905 The base-N log of a number is equal to the natural log of that number
2906 divided by the natural log of N.  For example:
2907
2908     sub log10 {
2909         my $n = shift;
2910         return log($n)/log(10);
2911     }
2912
2913 See also L</exp> for the inverse operation.
2914
2915 =item lstat EXPR
2916 X<lstat>
2917
2918 =item lstat
2919
2920 Does the same thing as the C<stat> function (including setting the
2921 special C<_> filehandle) but stats a symbolic link instead of the file
2922 the symbolic link points to.  If symbolic links are unimplemented on
2923 your system, a normal C<stat> is done.  For much more detailed
2924 information, please see the documentation for C<stat>.
2925
2926 If EXPR is omitted, stats C<$_>.
2927
2928 =item m//
2929
2930 The match operator.  See L<perlop/"Regexp Quote-Like Operators">.
2931
2932 =item map BLOCK LIST
2933 X<map>
2934
2935 =item map EXPR,LIST
2936
2937 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
2938 C<$_> to each element) and returns the list value composed of the
2939 results of each such evaluation.  In scalar context, returns the
2940 total number of elements so generated.  Evaluates BLOCK or EXPR in
2941 list context, so each element of LIST may produce zero, one, or
2942 more elements in the returned value.
2943
2944     @chars = map(chr, @nums);
2945
2946 translates a list of numbers to the corresponding characters.  And
2947
2948     %hash = map { get_a_key_for($_) => $_ } @array;
2949
2950 is just a funny way to write
2951
2952     %hash = ();
2953     foreach (@array) {
2954         $hash{get_a_key_for($_)} = $_;
2955     }
2956
2957 Note that C<$_> is an alias to the list value, so it can be used to
2958 modify the elements of the LIST.  While this is useful and supported,
2959 it can cause bizarre results if the elements of LIST are not variables.
2960 Using a regular C<foreach> loop for this purpose would be clearer in
2961 most cases.  See also L</grep> for an array composed of those items of
2962 the original list for which the BLOCK or EXPR evaluates to true.
2963
2964 If C<$_> is lexical in the scope where the C<map> appears (because it has
2965 been declared with C<my $_>), then, in addition to being locally aliased to
2966 the list elements, C<$_> keeps being lexical inside the block; that is, it
2967 can't be seen from the outside, avoiding any potential side-effects.
2968
2969 C<{> starts both hash references and blocks, so C<map { ...> could be either
2970 the start of map BLOCK LIST or map EXPR, LIST. Because perl doesn't look
2971 ahead for the closing C<}> it has to take a guess at which its dealing with
2972 based what it finds just after the C<{>. Usually it gets it right, but if it
2973 doesn't it won't realize something is wrong until it gets to the C<}> and
2974 encounters the missing (or unexpected) comma. The syntax error will be
2975 reported close to the C<}> but you'll need to change something near the C<{>
2976 such as using a unary C<+> to give perl some help:
2977
2978     %hash = map {  "\L$_", 1  } @array  # perl guesses EXPR.  wrong
2979     %hash = map { +"\L$_", 1  } @array  # perl guesses BLOCK. right
2980     %hash = map { ("\L$_", 1) } @array  # this also works
2981     %hash = map {  lc($_), 1  } @array  # as does this.
2982     %hash = map +( lc($_), 1 ), @array  # this is EXPR and works!
2983
2984     %hash = map  ( lc($_), 1 ), @array  # evaluates to (1, @array)
2985
2986 or to force an anon hash constructor use C<+{>:
2987
2988    @hashes = map +{ lc($_), 1 }, @array # EXPR, so needs , at end
2989
2990 and you get list of anonymous hashes each with only 1 entry.
2991
2992 =item mkdir FILENAME,MASK
2993 X<mkdir> X<md> X<directory, create>
2994
2995 =item mkdir FILENAME
2996
2997 =item mkdir
2998
2999 Creates the directory specified by FILENAME, with permissions
3000 specified by MASK (as modified by C<umask>).  If it succeeds it
3001 returns true, otherwise it returns false and sets C<$!> (errno).
3002 If omitted, MASK defaults to 0777. If omitted, FILENAME defaults
3003 to C<$_>.
3004
3005 In general, it is better to create directories with permissive MASK,
3006 and let the user modify that with their C<umask>, than it is to supply
3007 a restrictive MASK and give the user no way to be more permissive.
3008 The exceptions to this rule are when the file or directory should be
3009 kept private (mail files, for instance).  The perlfunc(1) entry on
3010 C<umask> discusses the choice of MASK in more detail.
3011
3012 Note that according to the POSIX 1003.1-1996 the FILENAME may have any
3013 number of trailing slashes.  Some operating and filesystems do not get
3014 this right, so Perl automatically removes all trailing slashes to keep
3015 everyone happy.
3016
3017 In order to recursively create a directory structure look at
3018 the C<mkpath> function of the L<File::Path> module.
3019
3020 =item msgctl ID,CMD,ARG
3021 X<msgctl>
3022
3023 Calls the System V IPC function msgctl(2).  You'll probably have to say
3024
3025     use IPC::SysV;
3026
3027 first to get the correct constant definitions.  If CMD is C<IPC_STAT>,
3028 then ARG must be a variable that will hold the returned C<msqid_ds>
3029 structure.  Returns like C<ioctl>: the undefined value for error,
3030 C<"0 but true"> for zero, or the actual return value otherwise.  See also
3031 L<perlipc/"SysV IPC">, C<IPC::SysV>, and C<IPC::Semaphore> documentation.
3032
3033 =item msgget KEY,FLAGS
3034 X<msgget>
3035
3036 Calls the System V IPC function msgget(2).  Returns the message queue
3037 id, or the undefined value if there is an error.  See also
3038 L<perlipc/"SysV IPC"> and C<IPC::SysV> and C<IPC::Msg> documentation.
3039
3040 =item msgrcv ID,VAR,SIZE,TYPE,FLAGS
3041 X<msgrcv>
3042
3043 Calls the System V IPC function msgrcv to receive a message from
3044 message queue ID into variable VAR with a maximum message size of
3045 SIZE.  Note that when a message is received, the message type as a
3046 native long integer will be the first thing in VAR, followed by the
3047 actual message.  This packing may be opened with C<unpack("l! a*")>.
3048 Taints the variable.  Returns true if successful, or false if there is
3049 an error.  See also L<perlipc/"SysV IPC">, C<IPC::SysV>, and
3050 C<IPC::SysV::Msg> documentation.
3051
3052 =item msgsnd ID,MSG,FLAGS
3053 X<msgsnd>
3054
3055 Calls the System V IPC function msgsnd to send the message MSG to the
3056 message queue ID.  MSG must begin with the native long integer message
3057 type, and be followed by the length of the actual message, and finally
3058 the message itself.  This kind of packing can be achieved with
3059 C<pack("l! a*", $type, $message)>.  Returns true if successful,
3060 or false if there is an error.  See also C<IPC::SysV>
3061 and C<IPC::SysV::Msg> documentation.
3062
3063 =item my EXPR
3064 X<my>
3065
3066 =item my TYPE EXPR
3067
3068 =item my EXPR : ATTRS
3069
3070 =item my TYPE EXPR : ATTRS
3071
3072 A C<my> declares the listed variables to be local (lexically) to the
3073 enclosing block, file, or C<eval>.  If more than one value is listed,
3074 the list must be placed in parentheses.
3075
3076 The exact semantics and interface of TYPE and ATTRS are still
3077 evolving.  TYPE is currently bound to the use of C<fields> pragma,
3078 and attributes are handled using the C<attributes> pragma, or starting
3079 from Perl 5.8.0 also via the C<Attribute::Handlers> module.  See
3080 L<perlsub/"Private Variables via my()"> for details, and L<fields>,
3081 L<attributes>, and L<Attribute::Handlers>.
3082
3083 =item next LABEL
3084 X<next> X<continue>
3085
3086 =item next
3087
3088 The C<next> command is like the C<continue> statement in C; it starts
3089 the next iteration of the loop:
3090
3091     LINE: while (<STDIN>) {
3092         next LINE if /^#/;  # discard comments
3093         #...
3094     }
3095
3096 Note that if there were a C<continue> block on the above, it would get
3097 executed even on discarded lines.  If the LABEL is omitted, the command
3098 refers to the innermost enclosing loop.
3099
3100 C<next> cannot be used to exit a block which returns a value such as
3101 C<eval {}>, C<sub {}> or C<do {}>, and should not be used to exit
3102 a grep() or map() operation.
3103
3104 Note that a block by itself is semantically identical to a loop
3105 that executes once.  Thus C<next> will exit such a block early.
3106
3107 See also L</continue> for an illustration of how C<last>, C<next>, and
3108 C<redo> work.
3109
3110 =item no Module VERSION LIST
3111 X<no>
3112
3113 =item no Module VERSION
3114
3115 =item no Module LIST
3116
3117 =item no Module
3118
3119 =item no VERSION
3120
3121 See the C<use> function, of which C<no> is the opposite.
3122
3123 =item oct EXPR
3124 X<oct> X<octal> X<hex> X<hexadecimal> X<binary> X<bin>
3125
3126 =item oct
3127
3128 Interprets EXPR as an octal string and returns the corresponding
3129 value.  (If EXPR happens to start off with C<0x>, interprets it as a
3130 hex string.  If EXPR starts off with C<0b>, it is interpreted as a
3131 binary string.  Leading whitespace is ignored in all three cases.)
3132 The following will handle decimal, binary, octal, and hex in the standard
3133 Perl or C notation:
3134
3135     $val = oct($val) if $val =~ /^0/;
3136
3137 If EXPR is omitted, uses C<$_>.   To go the other way (produce a number
3138 in octal), use sprintf() or printf():
3139
3140     $perms = (stat("filename"))[2] & 07777;
3141     $oct_perms = sprintf "%lo", $perms;
3142
3143 The oct() function is commonly used when a string such as C<644> needs
3144 to be converted into a file mode, for example. (Although perl will
3145 automatically convert strings into numbers as needed, this automatic
3146 conversion assumes base 10.)
3147
3148 =item open FILEHANDLE,EXPR
3149 X<open> X<pipe> X<file, open> X<fopen>
3150
3151 =item open FILEHANDLE,MODE,EXPR
3152
3153 =item open FILEHANDLE,MODE,EXPR,LIST
3154
3155 =item open FILEHANDLE,MODE,REFERENCE
3156
3157 =item open FILEHANDLE
3158
3159 Opens the file whose filename is given by EXPR, and associates it with
3160 FILEHANDLE.
3161
3162 Simple examples to open a file for reading:
3163
3164     open(my $fh, '<', "input.txt") or die $!;
3165
3166 and for writing:
3167
3168     open(my $fh, '>', "output.txt") or die $!;
3169
3170 (The following is a comprehensive reference to open(): for a gentler
3171 introduction you may consider L<perlopentut>.)
3172
3173 If FILEHANDLE is an undefined scalar variable (or array or hash element)
3174 the variable is assigned a reference to a new anonymous filehandle,
3175 otherwise if FILEHANDLE is an expression, its value is used as the name of
3176 the real filehandle wanted.  (This is considered a symbolic reference, so
3177 C<use strict 'refs'> should I<not> be in effect.)
3178
3179 If EXPR is omitted, the scalar variable of the same name as the
3180 FILEHANDLE contains the filename.  (Note that lexical variables--those
3181 declared with C<my>--will not work for this purpose; so if you're
3182 using C<my>, specify EXPR in your call to open.)
3183
3184 If three or more arguments are specified then the mode of opening and
3185 the file name are separate. If MODE is C<< '<' >> or nothing, the file
3186 is opened for input.  If MODE is C<< '>' >>, the file is truncated and
3187 opened for output, being created if necessary.  If MODE is C<<< '>>' >>>,
3188 the file is opened for appending, again being created if necessary.
3189
3190 You can put a C<'+'> in front of the C<< '>' >> or C<< '<' >> to
3191 indicate that you want both read and write access to the file; thus
3192 C<< '+<' >> is almost always preferred for read/write updates--the C<<
3193 '+>' >> mode would clobber the file first.  You can't usually use
3194 either read-write mode for updating textfiles, since they have
3195 variable length records.  See the B<-i> switch in L<perlrun> for a
3196 better approach.  The file is created with permissions of C<0666>
3197 modified by the process's C<umask> value.
3198
3199 These various prefixes correspond to the fopen(3) modes of C<'r'>,
3200 C<'r+'>, C<'w'>, C<'w+'>, C<'a'>, and C<'a+'>.
3201
3202 In the 2-arguments (and 1-argument) form of the call the mode and
3203 filename should be concatenated (in this order), possibly separated by
3204 spaces.  It is possible to omit the mode in these forms if the mode is
3205 C<< '<' >>.
3206
3207 If the filename begins with C<'|'>, the filename is interpreted as a
3208 command to which output is to be piped, and if the filename ends with a
3209 C<'|'>, the filename is interpreted as a command which pipes output to
3210 us.  See L<perlipc/"Using open() for IPC">
3211 for more examples of this.  (You are not allowed to C<open> to a command
3212 that pipes both in I<and> out, but see L<IPC::Open2>, L<IPC::Open3>,
3213 and L<perlipc/"Bidirectional Communication with Another Process">
3214 for alternatives.)
3215
3216 For three or more arguments if MODE is C<'|-'>, the filename is
3217 interpreted as a command to which output is to be piped, and if MODE
3218 is C<'-|'>, the filename is interpreted as a command which pipes
3219 output to us.  In the 2-arguments (and 1-argument) form one should
3220 replace dash (C<'-'>) with the command.
3221 See L<perlipc/"Using open() for IPC"> for more examples of this.
3222 (You are not allowed to C<open> to a command that pipes both in I<and>
3223 out, but see L<IPC::Open2>, L<IPC::Open3>, and
3224 L<perlipc/"Bidirectional Communication"> for alternatives.)
3225
3226 In the three-or-more argument form of pipe opens, if LIST is specified
3227 (extra arguments after the command name) then LIST becomes arguments
3228 to the command invoked if the platform supports it.  The meaning of
3229 C<open> with more than three arguments for non-pipe modes is not yet
3230 specified. Experimental "layers" may give extra LIST arguments
3231 meaning.
3232
3233 In the 2-arguments (and 1-argument) form opening C<'-'> opens STDIN
3234 and opening C<< '>-' >> opens STDOUT.
3235
3236 You may use the three-argument form of open to specify IO "layers"
3237 (sometimes also referred to as "disciplines") to be applied to the handle
3238 that affect how the input and output are processed (see L<open> and
3239 L<PerlIO> for more details). For example
3240
3241   open(my $fh, "<:encoding(UTF-8)", "file")
3242
3243 will open the UTF-8 encoded file containing Unicode characters,
3244 see L<perluniintro>. Note that if layers are specified in the
3245 three-arg form then default layers stored in ${^OPEN} (see L<perlvar>;
3246 usually set by the B<open> pragma or the switch B<-CioD>) are ignored.
3247
3248 Open returns nonzero upon success, the undefined value otherwise.  If
3249 the C<open> involved a pipe, the return value happens to be the pid of
3250 the subprocess.
3251
3252 If you're running Perl on a system that distinguishes between text
3253 files and binary files, then you should check out L</binmode> for tips
3254 for dealing with this.  The key distinction between systems that need
3255 C<binmode> and those that don't is their text file formats.  Systems
3256 like Unix, Mac OS, and Plan 9, which delimit lines with a single
3257 character, and which encode that character in C as C<"\n">, do not
3258 need C<binmode>.  The rest need it.
3259
3260 When opening a file, it's usually a bad idea to continue normal execution
3261 if the request failed, so C<open> is frequently used in connection with
3262 C<die>.  Even if C<die> won't do what you want (say, in a CGI script,
3263 where you want to make a nicely formatted error message (but there are
3264 modules that can help with that problem)) you should always check
3265 the return value from opening a file.  The infrequent exception is when
3266 working with an unopened filehandle is actually what you want to do.
3267
3268 As a special case the 3-arg form with a read/write mode and the third
3269 argument being C<undef>:
3270
3271     open(my $tmp, "+>", undef) or die ...
3272
3273 opens a filehandle to an anonymous temporary file.  Also using "+<"
3274 works for symmetry, but you really should consider writing something
3275 to the temporary file first.  You will need to seek() to do the
3276 reading.
3277
3278 Since v5.8.0, perl has built using PerlIO by default.  Unless you've
3279 changed this (i.e. Configure -Uuseperlio), you can open file handles to
3280 "in memory" files held in Perl scalars via:
3281
3282     open($fh, '>', \$variable) || ..
3283
3284 Though if you try to re-open C<STDOUT> or C<STDERR> as an "in memory"
3285 file, you have to close it first:
3286
3287     close STDOUT;
3288     open STDOUT, '>', \$variable or die "Can't open STDOUT: $!";
3289
3290 Examples:
3291
3292     $ARTICLE = 100;
3293     open ARTICLE or die "Can't find article $ARTICLE: $!\n";
3294     while (<ARTICLE>) {...
3295
3296     open(LOG, '>>/usr/spool/news/twitlog');  # (log is reserved)
3297     # if the open fails, output is discarded
3298
3299     open(my $dbase, '+<', 'dbase.mine')      # open for update
3300         or die "Can't open 'dbase.mine' for update: $!";
3301
3302     open(my $dbase, '+<dbase.mine')          # ditto
3303         or die "Can't open 'dbase.mine' for update: $!";
3304
3305     open(ARTICLE, '-|', "caesar <$article")  # decrypt article
3306         or die "Can't start caesar: $!";
3307
3308     open(ARTICLE, "caesar <$article |")      # ditto
3309         or die "Can't start caesar: $!";
3310
3311     open(EXTRACT, "|sort >Tmp$$")            # $$ is our process id
3312         or die "Can't start sort: $!";
3313
3314     # in memory files
3315     open(MEMORY,'>', \$var)
3316         or die "Can't open memory file: $!";
3317     print MEMORY "foo!\n";                   # output will end up in $var
3318
3319     # process argument list of files along with any includes
3320
3321     foreach $file (@ARGV) {
3322         process($file, 'fh00');
3323     }
3324
3325     sub process {
3326         my($filename, $input) = @_;
3327         $input++;    # this is a string increment
3328         unless (open($input, $filename)) {
3329             print STDERR "Can't open $filename: $!\n";
3330             return;
3331         }
3332
3333         local $_;
3334         while (<$input>) {    # note use of indirection
3335             if (/^#include "(.*)"/) {
3336                 process($1, $input);
3337                 next;
3338             }
3339             #...          # whatever
3340         }
3341     }
3342
3343 See L<perliol> for detailed info on PerlIO.
3344
3345 You may also, in the Bourne shell tradition, specify an EXPR beginning
3346 with C<< '>&' >>, in which case the rest of the string is interpreted
3347 as the name of a filehandle (or file descriptor, if numeric) to be
3348 duped (as C<dup(2)>) and opened.  You may use C<&> after C<< > >>,
3349 C<<< >> >>>, C<< < >>, C<< +> >>, C<<< +>> >>>, and C<< +< >>.
3350 The mode you specify should match the mode of the original filehandle.
3351 (Duping a filehandle does not take into account any existing contents
3352 of IO buffers.) If you use the 3-arg form then you can pass either a
3353 number, the name of a filehandle or the normal "reference to a glob".
3354
3355 Here is a script that saves, redirects, and restores C<STDOUT> and
3356 C<STDERR> using various methods:
3357
3358     #!/usr/bin/perl
3359     open my $oldout, ">&STDOUT"     or die "Can't dup STDOUT: $!";
3360     open OLDERR,     ">&", \*STDERR or die "Can't dup STDERR: $!";
3361
3362     open STDOUT, '>', "foo.out" or die "Can't redirect STDOUT: $!";
3363     open STDERR, ">&STDOUT"     or die "Can't dup STDOUT: $!";
3364
3365     select STDERR; $| = 1;  # make unbuffered
3366     select STDOUT; $| = 1;  # make unbuffered
3367
3368     print STDOUT "stdout 1\n";  # this works for
3369     print STDERR "stderr 1\n";  # subprocesses too
3370
3371     open STDOUT, ">&", $oldout or die "Can't dup \$oldout: $!";
3372     open STDERR, ">&OLDERR"    or die "Can't dup OLDERR: $!";
3373
3374     print STDOUT "stdout 2\n";
3375     print STDERR "stderr 2\n";
3376
3377 If you specify C<< '<&=X' >>, where C<X> is a file descriptor number
3378 or a filehandle, then Perl will do an equivalent of C's C<fdopen> of
3379 that file descriptor (and not call C<dup(2)>); this is more
3380 parsimonious of file descriptors.  For example:
3381
3382     # open for input, reusing the fileno of $fd
3383     open(FILEHANDLE, "<&=$fd")
3384
3385 or
3386
3387     open(FILEHANDLE, "<&=", $fd)
3388
3389 or
3390
3391     # open for append, using the fileno of OLDFH
3392     open(FH, ">>&=", OLDFH)
3393
3394 or
3395
3396     open(FH, ">>&=OLDFH")
3397
3398 Being parsimonious on filehandles is also useful (besides being
3399 parsimonious) for example when something is dependent on file
3400 descriptors, like for example locking using flock().  If you do just
3401 C<< open(A, '>>&B') >>, the filehandle A will not have the same file
3402 descriptor as B, and therefore flock(A) will not flock(B), and vice
3403 versa.  But with C<< open(A, '>>&=B') >> the filehandles will share
3404 the same file descriptor.
3405
3406 Note that if you are using Perls older than 5.8.0, Perl will be using
3407 the standard C libraries' fdopen() to implement the "=" functionality.
3408 On many Unix systems fdopen() fails when file descriptors exceed a
3409 certain value, typically 255.  For Perls 5.8.0 and later, PerlIO is
3410 most often the default.
3411
3412 You can see whether Perl has been compiled with PerlIO or not by
3413 running C<perl -V> and looking for C<useperlio=> line.  If C<useperlio>
3414 is C<define>, you have PerlIO, otherwise you don't.
3415
3416 If you open a pipe on the command C<'-'>, i.e., either C<'|-'> or C<'-|'>
3417 with 2-arguments (or 1-argument) form of open(), then
3418 there is an implicit fork done, and the return value of open is the pid
3419 of the child within the parent process, and C<0> within the child
3420 process.  (Use C<defined($pid)> to determine whether the open was successful.)
3421 The filehandle behaves normally for the parent, but i/o to that
3422 filehandle is piped from/to the STDOUT/STDIN of the child process.
3423 In the child process the filehandle isn't opened--i/o happens from/to
3424 the new STDOUT or STDIN.  Typically this is used like the normal
3425 piped open when you want to exercise more control over just how the
3426 pipe command gets executed, such as when you are running setuid, and
3427 don't want to have to scan shell commands for metacharacters.
3428 The following triples are more or less equivalent:
3429
3430     open(FOO, "|tr '[a-z]' '[A-Z]'");
3431     open(FOO, '|-', "tr '[a-z]' '[A-Z]'");
3432     open(FOO, '|-') || exec 'tr', '[a-z]', '[A-Z]';
3433     open(FOO, '|-', "tr", '[a-z]', '[A-Z]');
3434
3435     open(FOO, "cat -n '$file'|");
3436     open(FOO, '-|', "cat -n '$file'");
3437     open(FOO, '-|') || exec 'cat', '-n', $file;
3438     open(FOO, '-|', "cat", '-n', $file);
3439
3440 The last example in each block shows the pipe as "list form", which is
3441 not yet supported on all platforms.  A good rule of thumb is that if
3442 your platform has true C<fork()> (in other words, if your platform is
3443 Unix) you can use the list form.
3444
3445 See L<perlipc/"Safe Pipe Opens"> for more examples of this.
3446
3447 Beginning with v5.6.0, Perl will attempt to flush all files opened for
3448 output before any operation that may do a fork, but this may not be
3449 supported on some platforms (see L<perlport>).  To be safe, you may need
3450 to set C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method
3451 of C<IO::Handle> on any open handles.
3452
3453 On systems that support a close-on-exec flag on files, the flag will
3454 be set for the newly opened file descriptor as determined by the value
3455 of $^F.  See L<perlvar/$^F>.
3456
3457 Closing any piped filehandle causes the parent process to wait for the
3458 child to finish, and returns the status value in C<$?> and
3459 C<${^CHILD_ERROR_NATIVE}>.
3460
3461 The filename passed to 2-argument (or 1-argument) form of open() will
3462 have leading and trailing whitespace deleted, and the normal
3463 redirection characters honored.  This property, known as "magic open",
3464 can often be used to good effect.  A user could specify a filename of
3465 F<"rsh cat file |">, or you could change certain filenames as needed:
3466
3467     $filename =~ s/(.*\.gz)\s*$/gzip -dc < $1|/;
3468     open(FH, $filename) or die "Can't open $filename: $!";
3469
3470 Use 3-argument form to open a file with arbitrary weird characters in it,
3471
3472     open(FOO, '<', $file);
3473
3474 otherwise it's necessary to protect any leading and trailing whitespace:
3475
3476     $file =~ s#^(\s)#./$1#;
3477     open(FOO, "< $file\0");
3478
3479 (this may not work on some bizarre filesystems).  One should
3480 conscientiously choose between the I<magic> and 3-arguments form
3481 of open():
3482
3483     open IN, $ARGV[0];
3484
3485 will allow the user to specify an argument of the form C<"rsh cat file |">,
3486 but will not work on a filename which happens to have a trailing space, while
3487
3488     open IN, '<', $ARGV[0];
3489
3490 will have exactly the opposite restrictions.
3491
3492 If you want a "real" C C<open> (see C<open(2)> on your system), then you
3493 should use the C<sysopen> function, which involves no such magic (but
3494 may use subtly different filemodes than Perl open(), which is mapped
3495 to C fopen()).  This is
3496 another way to protect your filenames from interpretation.  For example:
3497
3498     use IO::Handle;
3499     sysopen(HANDLE, $path, O_RDWR|O_CREAT|O_EXCL)
3500         or die "sysopen $path: $!";
3501     $oldfh = select(HANDLE); $| = 1; select($oldfh);
3502     print HANDLE "stuff $$\n";
3503     seek(HANDLE, 0, 0);
3504     print "File contains: ", <HANDLE>;
3505
3506 Using the constructor from the C<IO::Handle> package (or one of its
3507 subclasses, such as C<IO::File> or C<IO::Socket>), you can generate anonymous
3508 filehandles that have the scope of whatever variables hold references to
3509 them, and automatically close whenever and however you leave that scope:
3510
3511     use IO::File;
3512     #...
3513     sub read_myfile_munged {
3514         my $ALL = shift;
3515         my $handle = IO::File->new;
3516         open($handle, "myfile") or die "myfile: $!";
3517         $first = <$handle>
3518             or return ();     # Automatically closed here.
3519         mung $first or die "mung failed";  # Or here.
3520         return $first, <$handle> if $ALL;  # Or here.
3521         $first;          # Or here.
3522     }
3523
3524 See L</seek> for some details about mixing reading and writing.
3525
3526 =item opendir DIRHANDLE,EXPR
3527 X<opendir>
3528
3529 Opens a directory named EXPR for processing by C<readdir>, C<telldir>,
3530 C<seekdir>, C<rewinddir>, and C<closedir>.  Returns true if successful.
3531 DIRHANDLE may be an expression whose value can be used as an indirect
3532 dirhandle, usually the real dirhandle name.  If DIRHANDLE is an undefined
3533 scalar variable (or array or hash element), the variable is assigned a
3534 reference to a new anonymous dirhandle.
3535 DIRHANDLEs have their own namespace separate from FILEHANDLEs.
3536
3537 See example at C<readdir>.
3538
3539 =item ord EXPR
3540 X<ord> X<encoding>
3541
3542 =item ord
3543
3544 Returns the numeric (the native 8-bit encoding, like ASCII or EBCDIC,
3545 or Unicode) value of the first character of EXPR.  If EXPR is omitted,
3546 uses C<$_>.
3547
3548 For the reverse, see L</chr>.
3549 See L<perlunicode> for more about Unicode.
3550
3551 =item our EXPR
3552 X<our> X<global>
3553
3554 =item our TYPE EXPR
3555
3556 =item our EXPR : ATTRS
3557
3558 =item our TYPE EXPR : ATTRS
3559
3560 C<our> associates a simple name with a package variable in the current
3561 package for use within the current scope.  When C<use strict 'vars'> is in
3562 effect, C<our> lets you use declared global variables without qualifying
3563 them with package names, within the lexical scope of the C<our> declaration.
3564 In this way C<our> differs from C<use vars>, which is package scoped.
3565
3566 Unlike C<my>, which both allocates storage for a variable and associates
3567 a simple name with that storage for use within the current scope, C<our>
3568 associates a simple name with a package variable in the current package,
3569 for use within the current scope.  In other words, C<our> has the same
3570 scoping rules as C<my>, but does not necessarily create a
3571 variable.
3572
3573 If more than one value is listed, the list must be placed
3574 in parentheses.
3575
3576     our $foo;
3577     our($bar, $baz);
3578
3579 An C<our> declaration declares a global variable that will be visible
3580 across its entire lexical scope, even across package boundaries.  The
3581 package in which the variable is entered is determined at the point
3582 of the declaration, not at the point of use.  This means the following
3583 behavior holds:
3584
3585     package Foo;
3586     our $bar;      # declares $Foo::bar for rest of lexical scope
3587     $bar = 20;
3588
3589     package Bar;
3590     print $bar;    # prints 20, as it refers to $Foo::bar
3591
3592 Multiple C<our> declarations with the same name in the same lexical
3593 scope are allowed if they are in different packages.  If they happen
3594 to be in the same package, Perl will emit warnings if you have asked
3595 for them, just like multiple C<my> declarations.  Unlike a second
3596 C<my> declaration, which will bind the name to a fresh variable, a
3597 second C<our> declaration in the same package, in the same scope, is
3598 merely redundant.
3599
3600     use warnings;
3601     package Foo;
3602     our $bar;      # declares $Foo::bar for rest of lexical scope
3603     $bar = 20;
3604
3605     package Bar;
3606     our $bar = 30; # declares $Bar::bar for rest of lexical scope
3607     print $bar;    # prints 30
3608
3609     our $bar;      # emits warning but has no other effect
3610     print $bar;    # still prints 30
3611
3612 An C<our> declaration may also have a list of attributes associated
3613 with it.
3614
3615 The exact semantics and interface of TYPE and ATTRS are still
3616 evolving.  TYPE is currently bound to the use of C<fields> pragma,
3617 and attributes are handled using the C<attributes> pragma, or starting
3618 from Perl 5.8.0 also via the C<Attribute::Handlers> module.  See
3619 L<perlsub/"Private Variables via my()"> for details, and L<fields>,
3620 L<attributes>, and L<Attribute::Handlers>.
3621
3622 =item pack TEMPLATE,LIST
3623 X<pack>
3624
3625 Takes a LIST of values and converts it into a string using the rules
3626 given by the TEMPLATE.  The resulting string is the concatenation of
3627 the converted values.  Typically, each converted value looks
3628 like its machine-level representation.  For example, on 32-bit machines
3629 an integer may be represented by a sequence of 4 bytes that will be 
3630 converted to a sequence of 4 characters.
3631
3632 See L<perlpacktut> for an introduction to this function.
3633
3634 The TEMPLATE is a sequence of characters that give the order and type
3635 of values, as follows:
3636
3637     a  A string with arbitrary binary data, will be null padded.
3638     A  A text (ASCII) string, will be space padded.
3639     Z  A null terminated (ASCIZ) string, will be null padded.
3640
3641     b  A bit string (ascending bit order inside each byte, like vec()).
3642     B  A bit string (descending bit order inside each byte).
3643     h  A hex string (low nybble first).
3644     H  A hex string (high nybble first).
3645
3646     c  A signed char (8-bit) value.
3647     C  An unsigned char (octet) value.
3648     W   An unsigned char value (can be greater than 255).
3649
3650     s  A signed short (16-bit) value.
3651     S  An unsigned short value.
3652
3653     l  A signed long (32-bit) value.
3654     L  An unsigned long value.
3655
3656     q  A signed quad (64-bit) value.
3657     Q  An unsigned quad value.
3658       (Quads are available only if your system supports 64-bit
3659        integer values _and_ if Perl has been compiled to support those.
3660            Causes a fatal error otherwise.)
3661
3662     i  A signed integer value.
3663     I  A unsigned integer value.
3664       (This 'integer' is _at_least_ 32 bits wide.  Its exact
3665            size depends on what a local C compiler calls 'int'.)
3666
3667     n  An unsigned short (16-bit) in "network" (big-endian) order.
3668     N  An unsigned long (32-bit) in "network" (big-endian) order.
3669     v  An unsigned short (16-bit) in "VAX" (little-endian) order.
3670     V  An unsigned long (32-bit) in "VAX" (little-endian) order.
3671
3672     j   A Perl internal signed integer value (IV).
3673     J   A Perl internal unsigned integer value (UV).
3674
3675     f  A single-precision float in the native format.
3676     d  A double-precision float in the native format.
3677
3678     F  A Perl internal floating point value (NV) in the native format
3679     D  A long double-precision float in the native format.
3680       (Long doubles are available only if your system supports long
3681        double values _and_ if Perl has been compiled to support those.
3682            Causes a fatal error otherwise.)
3683
3684     p  A pointer to a null-terminated string.
3685     P  A pointer to a structure (fixed-length string).
3686
3687     u  A uuencoded string.
3688     U  A Unicode character number.  Encodes to a character in character mode
3689         and UTF-8 (or UTF-EBCDIC in EBCDIC platforms) in byte mode.
3690
3691     w  A BER compressed integer (not an ASN.1 BER, see perlpacktut for
3692     details).  Its bytes represent an unsigned integer in base 128,
3693     most significant digit first, with as few digits as possible.  Bit
3694     eight (the high bit) is set on each byte except the last.
3695
3696     x  A null byte.
3697     X  Back up a byte.
3698     @  Null fill or truncate to absolute position, counted from the
3699         start of the innermost ()-group.
3700     .   Null fill or truncate to absolute position specified by value.
3701     (  Start of a ()-group.
3702
3703 One or more of the modifiers below may optionally follow some letters in the
3704 TEMPLATE (the second column lists the letters for which the modifier is
3705 valid):
3706
3707     !   sSlLiI     Forces native (short, long, int) sizes instead
3708                    of fixed (16-/32-bit) sizes.
3709
3710         xX         Make x and X act as alignment commands.
3711
3712         nNvV       Treat integers as signed instead of unsigned.
3713
3714         @.         Specify position as byte offset in the internal
3715                    representation of the packed string. Efficient but
3716                    dangerous.
3717
3718     >   sSiIlLqQ   Force big-endian byte-order on the type.
3719         jJfFdDpP   (The "big end" touches the construct.)
3720
3721     <   sSiIlLqQ   Force little-endian byte-order on the type.
3722         jJfFdDpP   (The "little end" touches the construct.)
3723
3724 The C<E<gt>> and C<E<lt>> modifiers can also be used on C<()>-groups,
3725 in which case they force a certain byte-order on all components of
3726 that group, including subgroups.
3727
3728 The following rules apply:
3729
3730 =over 8
3731
3732 =item *
3733
3734 Each letter may optionally be followed by a number giving a repeat
3735 count.  With all types except C<a>, C<A>, C<Z>, C<b>, C<B>, C<h>,
3736 C<H>, C<@>, C<.>, C<x>, C<X> and C<P> the pack function will gobble up
3737 that many values from the LIST.  A C<*> for the repeat count means to
3738 use however many items are left, except for C<@>, C<x>, C<X>, where it
3739 is equivalent to C<0>, for <.> where it means relative to string start
3740 and C<u>, where it is equivalent to 1 (or 45, which is the same).
3741 A numeric repeat count may optionally be enclosed in brackets, as in
3742 C<pack 'C[80]', @arr>.
3743
3744 One can replace the numeric repeat count by a template enclosed in brackets;
3745 then the packed length of this template in bytes is used as a count.
3746 For example, C<x[L]> skips a long (it skips the number of bytes in a long);
3747 the template C<$t X[$t] $t> unpack()s twice what $t unpacks.
3748 If the template in brackets contains alignment commands (such as C<x![d]>),
3749 its packed length is calculated as if the start of the template has the maximal
3750 possible alignment.
3751
3752 When used with C<Z>, C<*> results in the addition of a trailing null
3753 byte (so the packed result will be one longer than the byte C<length>
3754 of the item).
3755
3756 When used with C<@>, the repeat count represents an offset from the start
3757 of the innermost () group.
3758
3759 When used with C<.>, the repeat count is used to determine the starting
3760 position from where the value offset is calculated. If the repeat count
3761 is 0, it's relative to the current position. If the repeat count is C<*>,
3762 the offset is relative to the start of the packed string. And if its an
3763 integer C<n> the offset is relative to the start of the n-th innermost
3764 () group (or the start of the string if C<n> is bigger then the group
3765 level).
3766
3767 The repeat count for C<u> is interpreted as the maximal number of bytes
3768 to encode per line of output, with 0, 1 and 2 replaced by 45. The repeat 
3769 count should not be more than 65.
3770
3771 =item *
3772
3773 The C<a>, C<A>, and C<Z> types gobble just one value, but pack it as a
3774 string of length count, padding with nulls or spaces as necessary.  When
3775 unpacking, C<A> strips trailing whitespace and nulls, C<Z> strips everything
3776 after the first null, and C<a> returns data verbatim.
3777
3778 If the value-to-pack is too long, it is truncated.  If too long and an
3779 explicit count is provided, C<Z> packs only C<$count-1> bytes, followed
3780 by a null byte.  Thus C<Z> always packs a trailing null (except when the
3781 count is 0).
3782
3783 =item *
3784
3785 Likewise, the C<b> and C<B> fields pack a string that many bits long.
3786 Each character of the input field of pack() generates 1 bit of the result.
3787 Each result bit is based on the least-significant bit of the corresponding
3788 input character, i.e., on C<ord($char)%2>.  In particular, characters C<"0">
3789 and C<"1"> generate bits 0 and 1, as do characters C<"\0"> and C<"\1">.
3790
3791 Starting from the beginning of the input string of pack(), each 8-tuple
3792 of characters is converted to 1 character of output.  With format C<b>
3793 the first character of the 8-tuple determines the least-significant bit of a
3794 character, and with format C<B> it determines the most-significant bit of
3795 a character.
3796
3797 If the length of the input string is not exactly divisible by 8, the
3798 remainder is packed as if the input string were padded by null characters
3799 at the end.  Similarly, during unpack()ing the "extra" bits are ignored.
3800
3801 If the input string of pack() is longer than needed, extra characters are 
3802 ignored. A C<*> for the repeat count of pack() means to use all the 
3803 characters of the input field.  On unpack()ing the bits are converted to a 
3804 string of C<"0">s and C<"1">s.
3805
3806 =item *
3807
3808 The C<h> and C<H> fields pack a string that many nybbles (4-bit groups,
3809 representable as hexadecimal digits, 0-9a-f) long.
3810
3811 Each character of the input field of pack() generates 4 bits of the result.
3812 For non-alphabetical characters the result is based on the 4 least-significant
3813 bits of the input character, i.e., on C<ord($char)%16>.  In particular,
3814 characters C<"0"> and C<"1"> generate nybbles 0 and 1, as do bytes
3815 C<"\0"> and C<"\1">.  For characters C<"a".."f"> and C<"A".."F"> the result
3816 is compatible with the usual hexadecimal digits, so that C<"a"> and
3817 C<"A"> both generate the nybble C<0xa==10>.  The result for characters
3818 C<"g".."z"> and C<"G".."Z"> is not well-defined.
3819
3820 Starting from the beginning of the input string of pack(), each pair
3821 of characters is converted to 1 character of output.  With format C<h> the
3822 first character of the pair determines the least-significant nybble of the
3823 output character, and with format C<H> it determines the most-significant
3824 nybble.
3825
3826 If the length of the input string is not even, it behaves as if padded
3827 by a null character at the end.  Similarly, during unpack()ing the "extra"
3828 nybbles are ignored.
3829
3830 If the input string of pack() is longer than needed, extra characters are
3831 ignored.
3832 A C<*> for the repeat count of pack() means to use all the characters of
3833 the input field.  On unpack()ing the nybbles are converted to a string
3834 of hexadecimal digits.
3835
3836 =item *
3837
3838 The C<p> type packs a pointer to a null-terminated string.  You are
3839 responsible for ensuring the string is not a temporary value (which can
3840 potentially get deallocated before you get around to using the packed result).
3841 The C<P> type packs a pointer to a structure of the size indicated by the
3842 length.  A NULL pointer is created if the corresponding value for C<p> or
3843 C<P> is C<undef>, similarly for unpack().
3844
3845 If your system has a strange pointer size (i.e. a pointer is neither as
3846 big as an int nor as big as a long), it may not be possible to pack or
3847 unpack pointers in big- or little-endian byte order.  Attempting to do
3848 so will result in a fatal error.
3849
3850 =item *
3851
3852 The C</> template character allows packing and unpacking of a sequence of
3853 items where the packed structure contains a packed item count followed by 
3854 the packed items themselves.
3855
3856 For C<pack> you write I<length-item>C</>I<sequence-item> and the
3857 I<length-item> describes how the length value is packed. The ones likely
3858 to be of most use are integer-packing ones like C<n> (for Java strings),
3859 C<w> (for ASN.1 or SNMP) and C<N> (for Sun XDR).
3860
3861 For C<pack>, the I<sequence-item> may have a repeat count, in which case
3862 the minimum of that and the number of available items is used as argument
3863 for the I<length-item>. If it has no repeat count or uses a '*', the number
3864 of available items is used.
3865
3866 For C<unpack> an internal stack of integer arguments unpacked so far is
3867 used. You write C</>I<sequence-item> and the repeat count is obtained by
3868 popping off the last element from the stack. The I<sequence-item> must not
3869 have a repeat count.
3870
3871 If the I<sequence-item> refers to a string type (C<"A">, C<"a"> or C<"Z">),
3872 the I<length-item> is a string length, not a number of strings. If there is
3873 an explicit repeat count for pack, the packed string will be adjusted to that
3874 given length.
3875
3876     unpack 'W/a', "\04Gurusamy";            gives ('Guru')
3877     unpack 'a3/A A*', '007 Bond  J ';       gives (' Bond', 'J')
3878     unpack 'a3 x2 /A A*', '007: Bond, J.';  gives ('Bond, J', '.')
3879     pack 'n/a* w/a','hello,','world';       gives "\000\006hello,\005world"
3880     pack 'a/W2', ord('a') .. ord('z');      gives '2ab'
3881
3882 The I<length-item> is not returned explicitly from C<unpack>.
3883
3884 Adding a count to the I<length-item> letter is unlikely to do anything
3885 useful, unless that letter is C<A>, C<a> or C<Z>.  Packing with a
3886 I<length-item> of C<a> or C<Z> may introduce C<"\000"> characters,
3887 which Perl does not regard as legal in numeric strings.
3888
3889 =item *
3890
3891 The integer types C<s>, C<S>, C<l>, and C<L> may be
3892 followed by a C<!> modifier to signify native shorts or
3893 longs--as you can see from above for example a bare C<l> does mean
3894 exactly 32 bits, the native C<long> (as seen by the local C compiler)
3895 may be larger.  This is an issue mainly in 64-bit platforms.  You can
3896 see whether using C<!> makes any difference by
3897
3898     print length(pack("s")), " ", length(pack("s!")), "\n";
3899     print length(pack("l")), " ", length(pack("l!")), "\n";
3900
3901 C<i!> and C<I!> also work but only because of completeness;
3902 they are identical to C<i> and C<I>.
3903
3904 The actual sizes (in bytes) of native shorts, ints, longs, and long
3905 longs on the platform where Perl was built are also available via
3906 L<Config>:
3907
3908        use Config;
3909        print $Config{shortsize},    "\n";
3910        print $Config{intsize},      "\n";
3911        print $Config{longsize},     "\n";
3912        print $Config{longlongsize}, "\n";
3913
3914 (The C<$Config{longlongsize}> will be undefined if your system does
3915 not support long longs.)
3916
3917 =item *
3918
3919 The integer formats C<s>, C<S>, C<i>, C<I>, C<l>, C<L>, C<j>, and C<J>
3920 are inherently non-portable between processors and operating systems
3921 because they obey the native byteorder and endianness.  For example a
3922 4-byte integer 0x12345678 (305419896 decimal) would be ordered natively
3923 (arranged in and handled by the CPU registers) into bytes as
3924
3925     0x12 0x34 0x56 0x78  # big-endian
3926     0x78 0x56 0x34 0x12  # little-endian
3927
3928 Basically, the Intel and VAX CPUs are little-endian, while everybody
3929 else, for example Motorola m68k/88k, PPC, Sparc, HP PA, Power, and
3930 Cray are big-endian.  Alpha and MIPS can be either: Digital/Compaq
3931 used/uses them in little-endian mode; SGI/Cray uses them in big-endian
3932 mode.
3933
3934 The names `big-endian' and `little-endian' are comic references to
3935 the classic "Gulliver's Travels" (via the paper "On Holy Wars and a
3936 Plea for Peace" by Danny Cohen, USC/ISI IEN 137, April 1, 1980) and
3937 the egg-eating habits of the Lilliputians.
3938
3939 Some systems may have even weirder byte orders such as
3940
3941    0x56 0x78 0x12 0x34
3942    0x34 0x12 0x78 0x56
3943
3944 You can see your system's preference with
3945
3946    print join(" ", map { sprintf "%#02x", $_ }
3947                             unpack("W*",pack("L",0x12345678))), "\n";
3948
3949 The byteorder on the platform where Perl was built is also available
3950 via L<Config>:
3951
3952     use Config;
3953     print $Config{byteorder}, "\n";
3954
3955 Byteorders C<'1234'> and C<'12345678'> are little-endian, C<'4321'>
3956 and C<'87654321'> are big-endian.
3957
3958 If you want portable packed integers you can either use the formats
3959 C<n>, C<N>, C<v>, and C<V>, or you can use the C<E<gt>> and C<E<lt>>
3960 modifiers.  These modifiers are only available as of perl 5.9.2.
3961 See also L<perlport>.
3962
3963 =item *
3964
3965 All integer and floating point formats as well as C<p> and C<P> and
3966 C<()>-groups may be followed by the C<E<gt>> or C<E<lt>> modifiers
3967 to force big- or little- endian byte-order, respectively.
3968 This is especially useful, since C<n>, C<N>, C<v> and C<V> don't cover
3969 signed integers, 64-bit integers and floating point values.  However,
3970 there are some things to keep in mind.
3971
3972 Exchanging signed integers between different platforms only works
3973 if all platforms store them in the same format.  Most platforms store
3974 signed integers in two's complement, so usually this is not an issue.
3975
3976 The C<E<gt>> or C<E<lt>> modifiers can only be used on floating point
3977 formats on big- or little-endian machines.  Otherwise, attempting to
3978 do so will result in a fatal error.
3979
3980 Forcing big- or little-endian byte-order on floating point values for
3981 data exchange can only work if all platforms are using the same
3982 binary representation (e.g. IEEE floating point format).  Even if all
3983 platforms are using IEEE, there may be subtle differences.  Being able
3984 to use C<E<gt>> or C<E<lt>> on floating point values can be very useful,
3985 but also very dangerous if you don't know exactly what you're doing.
3986 It is definitely not a general way to portably store floating point
3987 values.
3988
3989 When using C<E<gt>> or C<E<lt>> on an C<()>-group, this will affect
3990 all types inside the group that accept the byte-order modifiers,
3991 including all subgroups.  It will silently be ignored for all other
3992 types.  You are not allowed to override the byte-order within a group
3993 that already has a byte-order modifier suffix.
3994
3995 =item *
3996
3997 Real numbers (floats and doubles) are in the native machine format only;
3998 due to the multiplicity of floating formats around, and the lack of a
3999 standard "network" representation, no facility for interchange has been
4000 made.  This means that packed floating point data written on one machine
4001 may not be readable on another - even if both use IEEE floating point
4002 arithmetic (as the endian-ness of the memory representation is not part
4003 of the IEEE spec).  See also L<perlport>.
4004
4005 If you know exactly what you're doing, you can use the C<E<gt>> or C<E<lt>>
4006 modifiers to force big- or little-endian byte-order on floating point values.
4007
4008 Note that Perl uses doubles (or long doubles, if configured) internally for
4009 all numeric calculation, and converting from double into float and thence back
4010 to double again will lose precision (i.e., C<unpack("f", pack("f", $foo)>)
4011 will not in general equal $foo).
4012
4013 =item *
4014
4015 Pack and unpack can operate in two modes, character mode (C<C0> mode) where
4016 the packed string is processed per character and UTF-8 mode (C<U0> mode)
4017 where the packed string is processed in its UTF-8-encoded Unicode form on
4018 a byte by byte basis. Character mode is the default unless the format string 
4019 starts with an C<U>. You can switch mode at any moment with an explicit 
4020 C<C0> or C<U0> in the format. A mode is in effect until the next mode switch 
4021 or until the end of the ()-group in which it was entered.
4022
4023 =item *
4024
4025 You must yourself do any alignment or padding by inserting for example
4026 enough C<'x'>es while packing.  There is no way to pack() and unpack()
4027 could know where the characters are going to or coming from.  Therefore
4028 C<pack> (and C<unpack>) handle their output and input as flat
4029 sequences of characters.
4030
4031 =item *
4032
4033 A ()-group is a sub-TEMPLATE enclosed in parentheses.  A group may
4034 take a repeat count, both as postfix, and for unpack() also via the C</>
4035 template character. Within each repetition of a group, positioning with
4036 C<@> starts again at 0. Therefore, the result of
4037
4038     pack( '@1A((@2A)@3A)', 'a', 'b', 'c' )
4039
4040 is the string "\0a\0\0bc".
4041
4042 =item *
4043
4044 C<x> and C<X> accept C<!> modifier.  In this case they act as
4045 alignment commands: they jump forward/back to the closest position
4046 aligned at a multiple of C<count> characters. For example, to pack() or
4047 unpack() C's C<struct {char c; double d; char cc[2]}> one may need to
4048 use the template C<W x![d] d W[2]>; this assumes that doubles must be
4049 aligned on the double's size.
4050
4051 For alignment commands C<count> of 0 is equivalent to C<count> of 1;
4052 both result in no-ops.
4053
4054 =item *
4055
4056 C<n>, C<N>, C<v> and C<V> accept the C<!> modifier. In this case they
4057 will represent signed 16-/32-bit integers in big-/little-endian order.
4058 This is only portable if all platforms sharing the packed data use the
4059 same binary representation for signed integers (e.g. all platforms are
4060 using two's complement representation).
4061
4062 =item *
4063
4064 A comment in a TEMPLATE starts with C<#> and goes to the end of line.
4065 White space may be used to separate pack codes from each other, but
4066 modifiers and a repeat count must follow immediately.
4067
4068 =item *
4069
4070 If TEMPLATE requires more arguments to pack() than actually given, pack()
4071 assumes additional C<""> arguments.  If TEMPLATE requires fewer arguments
4072 to pack() than actually given, extra arguments are ignored.
4073
4074 =back
4075
4076 Examples:
4077
4078     $foo = pack("WWWW",65,66,67,68);
4079     # foo eq "ABCD"
4080     $foo = pack("W4",65,66,67,68);
4081     # same thing
4082     $foo = pack("W4",0x24b6,0x24b7,0x24b8,0x24b9);
4083     # same thing with Unicode circled letters.
4084     $foo = pack("U4",0x24b6,0x24b7,0x24b8,0x24b9);
4085     # same thing with Unicode circled letters. You don't get the UTF-8
4086     # bytes because the U at the start of the format caused a switch to
4087     # U0-mode, so the UTF-8 bytes get joined into characters
4088     $foo = pack("C0U4",0x24b6,0x24b7,0x24b8,0x24b9);
4089     # foo eq "\xe2\x92\xb6\xe2\x92\xb7\xe2\x92\xb8\xe2\x92\xb9"
4090     # This is the UTF-8 encoding of the string in the previous example
4091
4092     $foo = pack("ccxxcc",65,66,67,68);
4093     # foo eq "AB\0\0CD"
4094
4095     # note: the above examples featuring "W" and "c" are true
4096     # only on ASCII and ASCII-derived systems such as ISO Latin 1
4097     # and UTF-8.  In EBCDIC the first example would be
4098     # $foo = pack("WWWW",193,194,195,196);
4099
4100     $foo = pack("s2",1,2);
4101     # "\1\0\2\0" on little-endian
4102     # "\0\1\0\2" on big-endian
4103
4104     $foo = pack("a4","abcd","x","y","z");
4105     # "abcd"
4106
4107     $foo = pack("aaaa","abcd","x","y","z");
4108     # "axyz"
4109
4110     $foo = pack("a14","abcdefg");
4111     # "abcdefg\0\0\0\0\0\0\0"
4112
4113     $foo = pack("i9pl", gmtime);
4114     # a real struct tm (on my system anyway)
4115
4116     $utmp_template = "Z8 Z8 Z16 L";
4117     $utmp = pack($utmp_template, @utmp1);
4118     # a struct utmp (BSDish)
4119
4120     @utmp2 = unpack($utmp_template, $utmp);
4121     # "@utmp1" eq "@utmp2"
4122
4123     sub bintodec {
4124         unpack("N", pack("B32", substr("0" x 32 . shift, -32)));
4125     }
4126
4127     $foo = pack('sx2l', 12, 34);
4128     # short 12, two zero bytes padding, long 34
4129     $bar = pack('s@4l', 12, 34);
4130     # short 12, zero fill to position 4, long 34
4131     # $foo eq $bar
4132     $baz = pack('s.l', 12, 4, 34);
4133     # short 12, zero fill to position 4, long 34
4134
4135     $foo = pack('nN', 42, 4711);
4136     # pack big-endian 16- and 32-bit unsigned integers
4137     $foo = pack('S>L>', 42, 4711);
4138     # exactly the same
4139     $foo = pack('s<l<', -42, 4711);
4140     # pack little-endian 16- and 32-bit signed integers
4141     $foo = pack('(sl)<', -42, 4711);
4142     # exactly the same
4143
4144 The same template may generally also be used in unpack().
4145
4146 =item package NAMESPACE VERSION
4147 X<package> X<module> X<namespace> X<version>
4148
4149 =item package NAMESPACE
4150
4151 Declares the compilation unit as being in the given namespace.  The scope
4152 of the package declaration is from the declaration itself through the end
4153 of the enclosing block, file, or eval (the same as the C<my> operator).
4154 All further unqualified dynamic identifiers will be in this namespace.
4155 A package statement affects only dynamic variables--including those
4156 you've used C<local> on--but I<not> lexical variables, which are created
4157 with C<my>.  Typically it would be the first declaration in a file to
4158 be included by the C<require> or C<use> operator.  You can switch into a
4159 package in more than one place; it merely influences which symbol table
4160 is used by the compiler for the rest of that block.  You can refer to
4161 variables and filehandles in other packages by prefixing the identifier
4162 with the package name and a double colon:  C<$Package::Variable>.
4163 If the package name is null, the C<main> package as assumed.  That is,
4164 C<$::sail> is equivalent to C<$main::sail> (as well as to C<$main'sail>,
4165 still seen in older code).
4166
4167 If VERSION is provided, C<package> also sets the C<$VERSION> variable in the
4168 given namespace.  VERSION must be a numeric literal or v-string; it is
4169 parsed exactly the same way as a VERSION argument to C<use MODULE VERSION>.
4170 C<$VERSION> should only be set once per package.
4171
4172 See L<perlmod/"Packages"> for more information about packages, modules,
4173 and classes.  See L<perlsub> for other scoping issues.
4174
4175 =item pipe READHANDLE,WRITEHANDLE
4176 X<pipe>
4177
4178 Opens a pair of connected pipes like the corresponding system call.
4179 Note that if you set up a loop of piped processes, deadlock can occur
4180 unless you are very careful.  In addition, note that Perl's pipes use
4181 IO buffering, so you may need to set C<$|> to flush your WRITEHANDLE
4182 after each command, depending on the application.
4183
4184 See L<IPC::Open2>, L<IPC::Open3>, and L<perlipc/"Bidirectional Communication">
4185 for examples of such things.
4186
4187 On systems that support a close-on-exec flag on files, the flag will be set
4188 for the newly opened file descriptors as determined by the value of $^F.
4189 See L<perlvar/$^F>.
4190
4191 =item pop ARRAY
4192 X<pop> X<stack>
4193
4194 =item pop
4195
4196 Pops and returns the last value of the array, shortening the array by
4197 one element.
4198
4199 If there are no elements in the array, returns the undefined value
4200 (although this may happen at other times as well).  If ARRAY is
4201 omitted, pops the C<@ARGV> array in the main program, and the C<@_>
4202 array in subroutines, just like C<shift>.
4203
4204 =item pos SCALAR
4205 X<pos> X<match, position>
4206
4207 =item pos
4208
4209 Returns the offset of where the last C<m//g> search left off for the variable
4210 in question (C<$_> is used when the variable is not specified).  Note that
4211 0 is a valid match offset.  C<undef> indicates that the search position
4212 is reset (usually due to match failure, but can also be because no match has
4213 yet been performed on the scalar). C<pos> directly accesses the location used
4214 by the regexp engine to store the offset, so assigning to C<pos> will change
4215 that offset, and so will also influence the C<\G> zero-width assertion in
4216 regular expressions. Because a failed C<m//gc> match doesn't reset the offset,
4217 the return from C<pos> won't change either in this case.  See L<perlre> and
4218 L<perlop>.
4219
4220 =item print FILEHANDLE LIST
4221 X<print>
4222
4223 =item print LIST
4224
4225 =item print
4226
4227 Prints a string or a list of strings.  Returns true if successful.
4228 FILEHANDLE may be a scalar variable name, in which case the variable
4229 contains the name of or a reference to the filehandle, thus introducing
4230 one level of indirection.  (NOTE: If FILEHANDLE is a variable and
4231 the next token is a term, it may be misinterpreted as an operator
4232 unless you interpose a C<+> or put parentheses around the arguments.)
4233 If FILEHANDLE is omitted, prints by default to standard output (or
4234 to the last selected output channel--see L</select>).  If LIST is
4235 also omitted, prints C<$_> to the currently selected output channel.
4236 To set the default output channel to something other than STDOUT
4237 use the select operation.  The current value of C<$,> (if any) is
4238 printed between each LIST item.  The current value of C<$\> (if
4239 any) is printed after the entire LIST has been printed.  Because
4240 print takes a LIST, anything in the LIST is evaluated in list
4241 context, and any subroutine that you call will have one or more of
4242 its expressions evaluated in list context.  Also be careful not to
4243 follow the print keyword with a left parenthesis unless you want
4244 the corresponding right parenthesis to terminate the arguments to
4245 the print--interpose a C<+> or put parentheses around all the
4246 arguments.
4247
4248 Note that if you're storing FILEHANDLEs in an array, or if you're using
4249 any other expression more complex than a scalar variable to retrieve it,
4250 you will have to use a block returning the filehandle value instead:
4251
4252     print { $files[$i] } "stuff\n";
4253     print { $OK ? STDOUT : STDERR } "stuff\n";
4254
4255 Printing to a closed pipe or socket will generate a SIGPIPE signal.  See
4256 L<perlipc> for more on signal handling.
4257
4258 =item printf FILEHANDLE FORMAT, LIST
4259 X<printf>
4260
4261 =item printf FORMAT, LIST
4262
4263 Equivalent to C<print FILEHANDLE sprintf(FORMAT, LIST)>, except that C<$\>
4264 (the output record separator) is not appended.  The first argument
4265 of the list will be interpreted as the C<printf> format. See C<sprintf>
4266 for an explanation of the format argument.  If C<use locale> is in effect,
4267 and POSIX::setlocale() has been called, the character used for the decimal
4268 separator in formatted floating point numbers is affected by the LC_NUMERIC
4269 locale.  See L<perllocale> and L<POSIX>.
4270
4271 Don't fall into the trap of using a C<printf> when a simple
4272 C<print> would do.  The C<print> is more efficient and less
4273 error prone.
4274
4275 =item prototype FUNCTION
4276 X<prototype>
4277
4278 Returns the prototype of a function as a string (or C<undef> if the
4279 function has no prototype).  FUNCTION is a reference to, or the name of,
4280 the function whose prototype you want to retrieve.
4281
4282 If FUNCTION is a string starting with C<CORE::>, the rest is taken as a
4283 name for a Perl builtin.  If the builtin is not I<overridable> (such as
4284 C<qw//>) or if its arguments cannot be adequately expressed by a prototype
4285 (such as C<system>), prototype() returns C<undef>, because the builtin
4286 does not really behave like a Perl function.  Otherwise, the string
4287 describing the equivalent prototype is returned.
4288
4289 =item push ARRAY,LIST
4290 X<push> X<stack>
4291
4292 Treats ARRAY as a stack, and pushes the values of LIST
4293 onto the end of ARRAY.  The length of ARRAY increases by the length of
4294 LIST.  Has the same effect as
4295
4296     for $value (LIST) {
4297         $ARRAY[++$#ARRAY] = $value;
4298     }
4299
4300 but is more efficient.  Returns the number of elements in the array following
4301 the completed C<push>.
4302
4303 =item q/STRING/
4304
4305 =item qq/STRING/
4306
4307 =item qx/STRING/
4308
4309 =item qw/STRING/
4310
4311 Generalized quotes.  See L<perlop/"Quote-Like Operators">.
4312
4313 =item qr/STRING/
4314
4315 Regexp-like quote.  See L<perlop/"Regexp Quote-Like Operators">.
4316
4317 =item quotemeta EXPR
4318 X<quotemeta> X<metacharacter>
4319
4320 =item quotemeta
4321
4322 Returns the value of EXPR with all non-"word"
4323 characters backslashed.  (That is, all characters not matching
4324 C</[A-Za-z_0-9]/> will be preceded by a backslash in the
4325 returned string, regardless of any locale settings.)
4326 This is the internal function implementing
4327 the C<\Q> escape in double-quoted strings.
4328
4329 If EXPR is omitted, uses C<$_>.
4330
4331 quotemeta (and C<\Q> ... C<\E>) are useful when interpolating strings into
4332 regular expressions, because by default an interpolated variable will be
4333 considered a mini-regular expression. For example:
4334
4335     my $sentence = 'The quick brown fox jumped over the lazy dog';
4336     my $substring = 'quick.*?fox';
4337     $sentence =~ s{$substring}{big bad wolf};
4338
4339 Will cause C<$sentence> to become C<'The big bad wolf jumped over...'>.
4340
4341 On the other hand:
4342
4343     my $sentence = 'The quick brown fox jumped over the lazy dog';
4344     my $substring = 'quick.*?fox';
4345     $sentence =~ s{\Q$substring\E}{big bad wolf};
4346
4347 Or:
4348
4349     my $sentence = 'The quick brown fox jumped over the lazy dog';
4350     my $substring = 'quick.*?fox';
4351     my $quoted_substring = quotemeta($substring);
4352     $sentence =~ s{$quoted_substring}{big bad wolf};
4353
4354 Will both leave the sentence as is. Normally, when accepting string input from
4355 the user, quotemeta() or C<\Q> must be used.
4356
4357 =item rand EXPR
4358 X<rand> X<random>
4359
4360 =item rand
4361
4362 Returns a random fractional number greater than or equal to C<0> and less
4363 than the value of EXPR.  (EXPR should be positive.)  If EXPR is
4364 omitted, the value C<1> is used.  Currently EXPR with the value C<0> is
4365 also special-cased as C<1> - this has not been documented before perl 5.8.0
4366 and is subject to change in future versions of perl.  Automatically calls
4367 C<srand> unless C<srand> has already been called.  See also C<srand>.
4368
4369 Apply C<int()> to the value returned by C<rand()> if you want random
4370 integers instead of random fractional numbers.  For example,
4371
4372     int(rand(10))
4373
4374 returns a random integer between C<0> and C<9>, inclusive.
4375
4376 (Note: If your rand function consistently returns numbers that are too
4377 large or too small, then your version of Perl was probably compiled
4378 with the wrong number of RANDBITS.)
4379
4380 =item read FILEHANDLE,SCALAR,LENGTH,OFFSET
4381 X<read> X<file, read>
4382
4383 =item read FILEHANDLE,SCALAR,LENGTH
4384
4385 Attempts to read LENGTH I<characters> of data into variable SCALAR
4386 from the specified FILEHANDLE.  Returns the number of characters
4387 actually read, C<0> at end of file, or undef if there was an error (in
4388 the latter case C<$!> is also set).  SCALAR will be grown or shrunk 
4389 so that the last character actually read is the last character of the
4390 scalar after the read.
4391
4392 An OFFSET may be specified to place the read data at some place in the
4393 string other than the beginning.  A negative OFFSET specifies
4394 placement at that many characters counting backwards from the end of
4395 the string.  A positive OFFSET greater than the length of SCALAR
4396 results in the string being padded to the required size with C<"\0">
4397 bytes before the result of the read is appended.
4398
4399 The call is actually implemented in terms of either Perl's or system's
4400 fread() call.  To get a true read(2) system call, see C<sysread>.
4401
4402 Note the I<characters>: depending on the status of the filehandle,
4403 either (8-bit) bytes or characters are read.  By default all
4404 filehandles operate on bytes, but for example if the filehandle has
4405 been opened with the C<:utf8> I/O layer (see L</open>, and the C<open>
4406 pragma, L<open>), the I/O will operate on UTF-8 encoded Unicode
4407 characters, not bytes.  Similarly for the C<:encoding> pragma:
4408 in that case pretty much any characters can be read.
4409
4410 =item readdir DIRHANDLE
4411 X<readdir>
4412
4413 Returns the next directory entry for a directory opened by C<opendir>.
4414 If used in list context, returns all the rest of the entries in the
4415 directory.  If there are no more entries, returns an undefined value in
4416 scalar context or a null list in list context.
4417
4418 If you're planning to filetest the return values out of a C<readdir>, you'd
4419 better prepend the directory in question.  Otherwise, because we didn't
4420 C<chdir> there, it would have been testing the wrong file.
4421
4422     opendir(my $dh, $some_dir) || die "can't opendir $some_dir: $!";
4423     @dots = grep { /^\./ && -f "$some_dir/$_" } readdir($dh);
4424     closedir $dh;
4425
4426 As of Perl 5.11.2 you can use a bare C<readdir> in a C<while> loop,
4427 which will set C<$_> on every iteration.
4428
4429     opendir(my $dh, $some_dir) || die;
4430     while(readdir $dh) {
4431         print "$some_dir/$_\n";
4432     }
4433     closedir $dh;
4434
4435 =item readline EXPR
4436
4437 =item readline
4438 X<readline> X<gets> X<fgets>
4439
4440 Reads from the filehandle whose typeglob is contained in EXPR (or from
4441 *ARGV if EXPR is not provided).  In scalar context, each call reads and
4442 returns the next line, until end-of-file is reached, whereupon the
4443 subsequent call returns C<undef>.  In list context, reads until end-of-file
4444 is reached and returns a list of lines.  Note that the notion of "line"
4445 used here is however you may have defined it with C<$/> or
4446 C<$INPUT_RECORD_SEPARATOR>).  See L<perlvar/"$/">.
4447
4448 When C<$/> is set to C<undef>, when C<readline> is in scalar
4449 context (i.e. file slurp mode), and when an empty file is read, it
4450 returns C<''> the first time, followed by C<undef> subsequently.
4451
4452 This is the internal function implementing the C<< <EXPR> >>
4453 operator, but you can use it directly.  The C<< <EXPR> >>
4454 operator is discussed in more detail in L<perlop/"I/O Operators">.
4455
4456     $line = <STDIN>;
4457     $line = readline(*STDIN);    # same thing
4458
4459 If C<readline> encounters an operating system error, C<$!> will be set
4460 with the corresponding error message.  It can be helpful to check
4461 C<$!> when you are reading from filehandles you don't trust, such as a
4462 tty or a socket.  The following example uses the operator form of
4463 C<readline> and dies if the result is not defined.
4464
4465     while ( ! eof($fh) ) {
4466         defined( $_ = <$fh> ) or die "readline failed: $!";
4467         ...
4468     }
4469
4470 Note that you have can't handle C<readline> errors that way with the
4471 C<ARGV> filehandle. In that case, you have to open each element of
4472 C<@ARGV> yourself since C<eof> handles C<ARGV> differently.
4473
4474     foreach my $arg (@ARGV) {
4475         open(my $fh, $arg) or warn "Can't open $arg: $!";
4476
4477         while ( ! eof($fh) ) {
4478             defined( $_ = <$fh> )
4479                 or die "readline failed for $arg: $!";
4480             ...
4481         }
4482     }
4483
4484 =item readlink EXPR
4485 X<readlink>
4486
4487 =item readlink
4488
4489 Returns the value of a symbolic link, if symbolic links are
4490 implemented.  If not, gives a fatal error.  If there is some system
4491 error, returns the undefined value and sets C<$!> (errno).  If EXPR is
4492 omitted, uses C<$_>.
4493
4494 =item readpipe EXPR
4495
4496 =item readpipe
4497 X<readpipe>
4498
4499 EXPR is executed as a system command.
4500 The collected standard output of the command is returned.
4501 In scalar context, it comes back as a single (potentially
4502 multi-line) string.  In list context, returns a list of lines
4503 (however you've defined lines with C<$/> or C<$INPUT_RECORD_SEPARATOR>).
4504 This is the internal function implementing the C<qx/EXPR/>
4505 operator, but you can use it directly.  The C<qx/EXPR/>
4506 operator is discussed in more detail in L<perlop/"I/O Operators">.
4507 If EXPR is omitted, uses C<$_>.
4508
4509 =item recv SOCKET,SCALAR,LENGTH,FLAGS
4510 X<recv>
4511
4512 Receives a message on a socket.  Attempts to receive LENGTH characters
4513 of data into variable SCALAR from the specified SOCKET filehandle.
4514 SCALAR will be grown or shrunk to the length actually read.  Takes the
4515 same flags as the system call of the same name.  Returns the address
4516 of the sender if SOCKET's protocol supports this; returns an empty
4517 string otherwise.  If there's an error, returns the undefined value.
4518 This call is actually implemented in terms of recvfrom(2) system call.
4519 See L<perlipc/"UDP: Message Passing"> for examples.
4520
4521 Note the I<characters>: depending on the status of the socket, either
4522 (8-bit) bytes or characters are received.  By default all sockets
4523 operate on bytes, but for example if the socket has been changed using
4524 binmode() to operate with the C<:encoding(utf8)> I/O layer (see the
4525 C<open> pragma, L<open>), the I/O will operate on UTF-8 encoded Unicode
4526 characters, not bytes.  Similarly for the C<:encoding> pragma: in that
4527 case pretty much any characters can be read.
4528
4529 =item redo LABEL
4530 X<redo>
4531
4532 =item redo
4533
4534 The C<redo> command restarts the loop block without evaluating the
4535 conditional again.  The C<continue> block, if any, is not executed.  If
4536 the LABEL is omitted, the command refers to the innermost enclosing
4537 loop.  Programs that want to lie to themselves about what was just input 
4538 normally use this command:
4539
4540     # a simpleminded Pascal comment stripper
4541     # (warning: assumes no { or } in strings)
4542     LINE: while (<STDIN>) {
4543         while (s|({.*}.*){.*}|$1 |) {}
4544         s|{.*}| |;
4545         if (s|{.*| |) {
4546             $front = $_;
4547             while (<STDIN>) {
4548                 if (/}/) {  # end of comment?
4549                     s|^|$front\{|;
4550                     redo LINE;
4551                 }
4552             }
4553         }
4554         print;
4555     }
4556
4557 C<redo> cannot be used to retry a block which returns a value such as
4558 C<eval {}>, C<sub {}> or C<do {}>, and should not be used to exit
4559 a grep() or map() operation.
4560
4561 Note that a block by itself is semantically identical to a loop
4562 that executes once.  Thus C<redo> inside such a block will effectively
4563 turn it into a looping construct.
4564
4565 See also L</continue> for an illustration of how C<last>, C<next>, and
4566 C<redo> work.
4567
4568 =item ref EXPR
4569 X<ref> X<reference>
4570
4571 =item ref
4572
4573 Returns a non-empty string if EXPR is a reference, the empty
4574 string otherwise. If EXPR
4575 is not specified, C<$_> will be used.  The value returned depends on the
4576 type of thing the reference is a reference to.
4577 Builtin types include:
4578
4579     SCALAR
4580     ARRAY
4581     HASH
4582     CODE
4583     REF
4584     GLOB
4585     LVALUE
4586     FORMAT
4587     IO
4588     VSTRING
4589     Regexp
4590
4591 If the referenced object has been blessed into a package, then that package
4592 name is returned instead.  You can think of C<ref> as a C<typeof> operator.
4593
4594     if (ref($r) eq "HASH") {
4595         print "r is a reference to a hash.\n";
4596     }
4597     unless (ref($r)) {
4598         print "r is not a reference at all.\n";
4599     }
4600
4601 The return value C<LVALUE> indicates a reference to an lvalue that is not
4602 a variable. You get this from taking the reference of function calls like
4603 C<pos()> or C<substr()>. C<VSTRING> is returned if the reference points
4604 to a L<version string|perldata/"Version Strings">.
4605
4606 The result C<Regexp> indicates that the argument is a regular expression
4607 resulting from C<qr//>.
4608
4609 See also L<perlref>.
4610
4611 =item rename OLDNAME,NEWNAME
4612 X<rename> X<move> X<mv> X<ren>
4613
4614 Changes the name of a file; an existing file NEWNAME will be
4615 clobbered.  Returns true for success, false otherwise.
4616
4617 Behavior of this function varies wildly depending on your system
4618 implementation.  For example, it will usually not work across file system
4619 boundaries, even though the system I<mv> command sometimes compensates
4620 for this.  Other restrictions include whether it works on directories,
4621 open files, or pre-existing files.  Check L<perlport> and either the
4622 rename(2) manpage or equivalent system documentation for details.
4623
4624 For a platform independent C<move> function look at the L<File::Copy>
4625 module.
4626
4627 =item require VERSION
4628 X<require>
4629
4630 =item require EXPR
4631
4632 =item require
4633
4634 Demands a version of Perl specified by VERSION, or demands some semantics
4635 specified by EXPR or by C<$_> if EXPR is not supplied.
4636
4637 VERSION may be either a numeric argument such as 5.006, which will be
4638 compared to C<$]>, or a literal of the form v5.6.1, which will be compared
4639 to C<$^V> (aka $PERL_VERSION).  A fatal error is produced at run time if
4640 VERSION is greater than the version of the current Perl interpreter.
4641 Compare with L</use>, which can do a similar check at compile time.
4642
4643 Specifying VERSION as a literal of the form v5.6.1 should generally be
4644 avoided, because it leads to misleading error messages under earlier
4645 versions of Perl that do not support this syntax.  The equivalent numeric
4646 version should be used instead.
4647
4648     require v5.6.1;     # run time version check
4649     require 5.6.1;      # ditto
4650     require 5.006_001;  # ditto; preferred for backwards compatibility
4651
4652 Otherwise, C<require> demands that a library file be included if it
4653 hasn't already been included.  The file is included via the do-FILE
4654 mechanism, which is essentially just a variety of C<eval> with the
4655 caveat that lexical variables in the invoking script will be invisible
4656 to the included code.  Has semantics similar to the following subroutine:
4657
4658     sub require {
4659        my ($filename) = @_;
4660        if (exists $INC{$filename}) {
4661            return 1 if $INC{$filename};
4662            die "Compilation failed in require";
4663        }
4664        my ($realfilename,$result);
4665        ITER: {
4666            foreach $prefix (@INC) {
4667                $realfilename = "$prefix/$filename";
4668                if (-f $realfilename) {
4669                    $INC{$filename} = $realfilename;
4670                    $result = do $realfilename;
4671                    last ITER;
4672                }
4673            }
4674            die "Can't find $filename in \@INC";
4675        }
4676        if ($@) {
4677            $INC{$filename} = undef;
4678            die $@;
4679        } elsif (!$result) {