Avoid a possible race condition where a parallel make might
[perl.git] / pod / perlfaq8.pod
1 =head1 NAME
2
3 perlfaq8 - System Interaction
4
5 =head1 DESCRIPTION
6
7 This section of the Perl FAQ covers questions involving operating
8 system interaction.  Topics include interprocess communication (IPC),
9 control over the user-interface (keyboard, screen and pointing
10 devices), and most anything else not related to data manipulation.
11
12 Read the FAQs and documentation specific to the port of perl to your
13 operating system (eg, L<perlvms>, L<perlplan9>, ...).  These should
14 contain more detailed information on the vagaries of your perl.
15
16 =head2 How do I find out which operating system I'm running under?
17
18 The C<$^O> variable (C<$OSNAME> if you use C<English>) contains an indication of
19 the name of the operating system (not its release number) that your perl
20 binary was built for.
21
22 =head2 How come exec() doesn't return?
23 X<exec> X<system> X<fork> X<open> X<pipe>
24
25 (contributed by brian d foy)
26
27 The C<exec> function's job is to turn your process into another
28 command and never to return. If that's not what you want to do, don't
29 use C<exec>. :)
30
31 If you want to run an external command and still keep your Perl process
32 going, look at a piped C<open>, C<fork>, or C<system>.
33
34 =head2 How do I do fancy stuff with the keyboard/screen/mouse?
35
36 How you access/control keyboards, screens, and pointing devices
37 ("mice") is system-dependent.  Try the following modules:
38
39 =over 4
40
41 =item Keyboard
42
43         Term::Cap               Standard perl distribution
44         Term::ReadKey           CPAN
45         Term::ReadLine::Gnu     CPAN
46         Term::ReadLine::Perl    CPAN
47         Term::Screen            CPAN
48
49 =item Screen
50
51         Term::Cap               Standard perl distribution
52         Curses                  CPAN
53         Term::ANSIColor         CPAN
54
55 =item Mouse
56
57         Tk                      CPAN
58
59 =back
60
61 Some of these specific cases are shown as examples in other answers
62 in this section of the perlfaq.
63
64 =head2 How do I print something out in color?
65
66 In general, you don't, because you don't know whether
67 the recipient has a color-aware display device.  If you
68 know that they have an ANSI terminal that understands
69 color, you can use the C<Term::ANSIColor> module from CPAN:
70
71         use Term::ANSIColor;
72         print color("red"), "Stop!\n", color("reset");
73         print color("green"), "Go!\n", color("reset");
74
75 Or like this:
76
77         use Term::ANSIColor qw(:constants);
78         print RED, "Stop!\n", RESET;
79         print GREEN, "Go!\n", RESET;
80
81 =head2 How do I read just one key without waiting for a return key?
82
83 Controlling input buffering is a remarkably system-dependent matter.
84 On many systems, you can just use the B<stty> command as shown in
85 L<perlfunc/getc>, but as you see, that's already getting you into
86 portability snags.
87
88         open(TTY, "+</dev/tty") or die "no tty: $!";
89         system "stty  cbreak </dev/tty >/dev/tty 2>&1";
90         $key = getc(TTY);               # perhaps this works
91         # OR ELSE
92         sysread(TTY, $key, 1);  # probably this does
93         system "stty -cbreak </dev/tty >/dev/tty 2>&1";
94
95 The C<Term::ReadKey> module from CPAN offers an easy-to-use interface that
96 should be more efficient than shelling out to B<stty> for each key.
97 It even includes limited support for Windows.
98
99         use Term::ReadKey;
100         ReadMode('cbreak');
101         $key = ReadKey(0);
102         ReadMode('normal');
103
104 However, using the code requires that you have a working C compiler
105 and can use it to build and install a CPAN module.  Here's a solution
106 using the standard C<POSIX> module, which is already on your system
107 (assuming your system supports POSIX).
108
109         use HotKey;
110         $key = readkey();
111
112 And here's the C<HotKey> module, which hides the somewhat mystifying calls
113 to manipulate the POSIX termios structures.
114
115         # HotKey.pm
116         package HotKey;
117
118         @ISA = qw(Exporter);
119         @EXPORT = qw(cbreak cooked readkey);
120
121         use strict;
122         use POSIX qw(:termios_h);
123         my ($term, $oterm, $echo, $noecho, $fd_stdin);
124
125         $fd_stdin = fileno(STDIN);
126         $term     = POSIX::Termios->new();
127         $term->getattr($fd_stdin);
128         $oterm     = $term->getlflag();
129
130         $echo     = ECHO | ECHOK | ICANON;
131         $noecho   = $oterm & ~$echo;
132
133         sub cbreak {
134                 $term->setlflag($noecho);  # ok, so i don't want echo either
135                 $term->setcc(VTIME, 1);
136                 $term->setattr($fd_stdin, TCSANOW);
137         }
138
139         sub cooked {
140                 $term->setlflag($oterm);
141                 $term->setcc(VTIME, 0);
142                 $term->setattr($fd_stdin, TCSANOW);
143         }
144
145         sub readkey {
146                 my $key = '';
147                 cbreak();
148                 sysread(STDIN, $key, 1);
149                 cooked();
150                 return $key;
151         }
152
153         END { cooked() }
154
155         1;
156
157 =head2 How do I check whether input is ready on the keyboard?
158
159 The easiest way to do this is to read a key in nonblocking mode with the
160 C<Term::ReadKey> module from CPAN, passing it an argument of -1 to indicate
161 not to block:
162
163         use Term::ReadKey;
164
165         ReadMode('cbreak');
166
167         if (defined ($char = ReadKey(-1)) ) {
168                 # input was waiting and it was $char
169         } else {
170                 # no input was waiting
171         }
172
173         ReadMode('normal');                  # restore normal tty settings
174
175 =head2 How do I clear the screen?
176
177 (contributed by brian d foy)
178
179 To clear the screen, you just have to print the special sequence
180 that tells the terminal to clear the screen. Once you have that
181 sequence, output it when you want to clear the screen.
182
183 You can use the C<Term::ANSIScreen> module to get the special
184 sequence. Import the C<cls> function (or the C<:screen> tag):
185
186         use Term::ANSIScreen qw(cls);
187         my $clear_screen = cls();
188
189         print $clear_screen;
190
191 The C<Term::Cap> module can also get the special sequence if you want
192 to deal with the low-level details of terminal control. The C<Tputs>
193 method returns the string for the given capability:
194
195         use Term::Cap;
196
197         $terminal = Term::Cap->Tgetent( { OSPEED => 9600 } );
198         $clear_string = $terminal->Tputs('cl');
199
200         print $clear_screen;
201
202 On Windows, you can use the C<Win32::Console> module. After creating
203 an object for the output filehandle you want to affect, call the
204 C<Cls> method:
205
206         Win32::Console;
207
208         $OUT = Win32::Console->new(STD_OUTPUT_HANDLE);
209         my $clear_string = $OUT->Cls;
210
211         print $clear_screen;
212
213 If you have a command-line program that does the job, you can call
214 it in backticks to capture whatever it outputs so you can use it
215 later:
216
217         $clear_string = `clear`;
218
219         print $clear_string;
220
221 =head2 How do I get the screen size?
222
223 If you have C<Term::ReadKey> module installed from CPAN,
224 you can use it to fetch the width and height in characters
225 and in pixels:
226
227         use Term::ReadKey;
228         ($wchar, $hchar, $wpixels, $hpixels) = GetTerminalSize();
229
230 This is more portable than the raw C<ioctl>, but not as
231 illustrative:
232
233         require 'sys/ioctl.ph';
234         die "no TIOCGWINSZ " unless defined &TIOCGWINSZ;
235         open(TTY, "+</dev/tty")                     or die "No tty: $!";
236         unless (ioctl(TTY, &TIOCGWINSZ, $winsize='')) {
237                 die sprintf "$0: ioctl TIOCGWINSZ (%08x: $!)\n", &TIOCGWINSZ;
238         }
239         ($row, $col, $xpixel, $ypixel) = unpack('S4', $winsize);
240         print "(row,col) = ($row,$col)";
241         print "  (xpixel,ypixel) = ($xpixel,$ypixel)" if $xpixel || $ypixel;
242         print "\n";
243
244 =head2 How do I ask the user for a password?
245
246 (This question has nothing to do with the web.  See a different
247 FAQ for that.)
248
249 There's an example of this in L<perlfunc/crypt>).  First, you put the
250 terminal into "no echo" mode, then just read the password normally.
251 You may do this with an old-style C<ioctl()> function, POSIX terminal
252 control (see L<POSIX> or its documentation the Camel Book), or a call
253 to the B<stty> program, with varying degrees of portability.
254
255 You can also do this for most systems using the C<Term::ReadKey> module
256 from CPAN, which is easier to use and in theory more portable.
257
258         use Term::ReadKey;
259
260         ReadMode('noecho');
261         $password = ReadLine(0);
262
263 =head2 How do I read and write the serial port?
264
265 This depends on which operating system your program is running on.  In
266 the case of Unix, the serial ports will be accessible through files in
267 /dev; on other systems, device names will doubtless differ.
268 Several problem areas common to all device interaction are the
269 following:
270
271 =over 4
272
273 =item lockfiles
274
275 Your system may use lockfiles to control multiple access.  Make sure
276 you follow the correct protocol.  Unpredictable behavior can result
277 from multiple processes reading from one device.
278
279 =item open mode
280
281 If you expect to use both read and write operations on the device,
282 you'll have to open it for update (see L<perlfunc/"open"> for
283 details).  You may wish to open it without running the risk of
284 blocking by using C<sysopen()> and C<O_RDWR|O_NDELAY|O_NOCTTY> from the
285 C<Fcntl> module (part of the standard perl distribution).  See
286 L<perlfunc/"sysopen"> for more on this approach.
287
288 =item end of line
289
290 Some devices will be expecting a "\r" at the end of each line rather
291 than a "\n".  In some ports of perl, "\r" and "\n" are different from
292 their usual (Unix) ASCII values of "\012" and "\015".  You may have to
293 give the numeric values you want directly, using octal ("\015"), hex
294 ("0x0D"), or as a control-character specification ("\cM").
295
296         print DEV "atv1\012";   # wrong, for some devices
297         print DEV "atv1\015";   # right, for some devices
298
299 Even though with normal text files a "\n" will do the trick, there is
300 still no unified scheme for terminating a line that is portable
301 between Unix, DOS/Win, and Macintosh, except to terminate I<ALL> line
302 ends with "\015\012", and strip what you don't need from the output.
303 This applies especially to socket I/O and autoflushing, discussed
304 next.
305
306 =item flushing output
307
308 If you expect characters to get to your device when you C<print()> them,
309 you'll want to autoflush that filehandle.  You can use C<select()>
310 and the C<$|> variable to control autoflushing (see L<perlvar/$E<verbar>>
311 and L<perlfunc/select>, or L<perlfaq5>, "How do I flush/unbuffer an
312 output filehandle?  Why must I do this?"):
313
314         $oldh = select(DEV);
315         $| = 1;
316         select($oldh);
317
318 You'll also see code that does this without a temporary variable, as in
319
320         select((select(DEV), $| = 1)[0]);
321
322 Or if you don't mind pulling in a few thousand lines
323 of code just because you're afraid of a little C<$|> variable:
324
325         use IO::Handle;
326         DEV->autoflush(1);
327
328 As mentioned in the previous item, this still doesn't work when using
329 socket I/O between Unix and Macintosh.  You'll need to hard code your
330 line terminators, in that case.
331
332 =item non-blocking input
333
334 If you are doing a blocking C<read()> or C<sysread()>, you'll have to
335 arrange for an alarm handler to provide a timeout (see
336 L<perlfunc/alarm>).  If you have a non-blocking open, you'll likely
337 have a non-blocking read, which means you may have to use a 4-arg
338 C<select()> to determine whether I/O is ready on that device (see
339 L<perlfunc/"select">.
340
341 =back
342
343 While trying to read from his caller-id box, the notorious Jamie Zawinski
344 C<< <jwz@netscape.com> >>, after much gnashing of teeth and fighting with C<sysread>,
345 C<sysopen>, POSIX's C<tcgetattr> business, and various other functions that
346 go bump in the night, finally came up with this:
347
348         sub open_modem {
349                 use IPC::Open2;
350                 my $stty = `/bin/stty -g`;
351                 open2( \*MODEM_IN, \*MODEM_OUT, "cu -l$modem_device -s2400 2>&1");
352                 # starting cu hoses /dev/tty's stty settings, even when it has
353                 # been opened on a pipe...
354                 system("/bin/stty $stty");
355                 $_ = <MODEM_IN>;
356                 chomp;
357                 if ( !m/^Connected/ ) {
358                         print STDERR "$0: cu printed `$_' instead of `Connected'\n";
359                 }
360         }
361
362 =head2 How do I decode encrypted password files?
363
364 You spend lots and lots of money on dedicated hardware, but this is
365 bound to get you talked about.
366
367 Seriously, you can't if they are Unix password files--the Unix
368 password system employs one-way encryption.  It's more like hashing
369 than encryption.  The best you can do is check whether something else
370 hashes to the same string.  You can't turn a hash back into the
371 original string. Programs like Crack can forcibly (and intelligently)
372 try to guess passwords, but don't (can't) guarantee quick success.
373
374 If you're worried about users selecting bad passwords, you should
375 proactively check when they try to change their password (by modifying
376 passwd(1), for example).
377
378 =head2 How do I start a process in the background?
379
380 (contributed by brian d foy)
381
382 There's not a single way to run code in the background so you don't
383 have to wait for it to finish before your program moves on to other
384 tasks. Process management depends on your particular operating system,
385 and many of the techniques are in L<perlipc>.
386
387 Several CPAN modules may be able to help, including C<IPC::Open2> or
388 C<IPC::Open3>, C<IPC::Run>, C<Parallel::Jobs>, C<Parallel::ForkManager>, C<POE>,
389 C<Proc::Background>, and C<Win32::Process>. There are many other modules you
390 might use, so check those namespaces for other options too.
391
392 If you are on a Unix-like system, you might be able to get away with a
393 system call where you put an C<&> on the end of the command:
394
395         system("cmd &")
396
397 You can also try using C<fork>, as described in L<perlfunc> (although
398 this is the same thing that many of the modules will do for you).
399
400 =over 4
401
402 =item STDIN, STDOUT, and STDERR are shared
403
404 Both the main process and the backgrounded one (the "child" process)
405 share the same STDIN, STDOUT and STDERR filehandles.  If both try to
406 access them at once, strange things can happen.  You may want to close
407 or reopen these for the child.  You can get around this with
408 C<open>ing a pipe (see L<perlfunc/"open">) but on some systems this
409 means that the child process cannot outlive the parent.
410
411 =item Signals
412
413 You'll have to catch the SIGCHLD signal, and possibly SIGPIPE too.
414 SIGCHLD is sent when the backgrounded process finishes.  SIGPIPE is
415 sent when you write to a filehandle whose child process has closed (an
416 untrapped SIGPIPE can cause your program to silently die).  This is
417 not an issue with C<system("cmd&")>.
418
419 =item Zombies
420
421 You have to be prepared to "reap" the child process when it finishes.
422
423         $SIG{CHLD} = sub { wait };
424
425         $SIG{CHLD} = 'IGNORE';
426
427 You can also use a double fork. You immediately C<wait()> for your
428 first child, and the init daemon will C<wait()> for your grandchild once
429 it exits.
430
431         unless ($pid = fork) {
432             unless (fork) {
433                 exec "what you really wanna do";
434                 die "exec failed!";
435             }
436             exit 0;
437         }
438         waitpid($pid, 0);
439
440 See L<perlipc/"Signals"> for other examples of code to do this.
441 Zombies are not an issue with C<system("prog &")>.
442
443 =back
444
445 =head2 How do I trap control characters/signals?
446
447 You don't actually "trap" a control character.  Instead, that character
448 generates a signal which is sent to your terminal's currently
449 foregrounded process group, which you then trap in your process.
450 Signals are documented in L<perlipc/"Signals"> and the
451 section on "Signals" in the Camel.
452
453 You can set the values of the C<%SIG> hash to be the functions you want
454 to handle the signal.  After perl catches the signal, it looks in C<%SIG>
455 for a key with the same name as the signal, then calls the subroutine
456 value for that key.
457
458         # as an anonymous subroutine
459
460         $SIG{INT} = sub { syswrite(STDERR, "ouch\n", 5 ) };
461
462         # or a reference to a function
463
464         $SIG{INT} = \&ouch;
465
466         # or the name of the function as a string
467
468         $SIG{INT} = "ouch";
469
470 Perl versions before 5.8 had in its C source code signal handlers which
471 would catch the signal and possibly run a Perl function that you had set
472 in C<%SIG>.  This violated the rules of signal handling at that level
473 causing perl to dump core. Since version 5.8.0, perl looks at C<%SIG>
474 B<after> the signal has been caught, rather than while it is being caught.
475 Previous versions of this answer were incorrect.
476
477 =head2 How do I modify the shadow password file on a Unix system?
478
479 If perl was installed correctly and your shadow library was written
480 properly, the C<getpw*()> functions described in L<perlfunc> should in
481 theory provide (read-only) access to entries in the shadow password
482 file.  To change the file, make a new shadow password file (the format
483 varies from system to system--see L<passwd> for specifics) and use
484 C<pwd_mkdb(8)> to install it (see L<pwd_mkdb> for more details).
485
486 =head2 How do I set the time and date?
487
488 Assuming you're running under sufficient permissions, you should be
489 able to set the system-wide date and time by running the C<date(1)>
490 program.  (There is no way to set the time and date on a per-process
491 basis.)  This mechanism will work for Unix, MS-DOS, Windows, and NT;
492 the VMS equivalent is C<set time>.
493
494 However, if all you want to do is change your time zone, you can
495 probably get away with setting an environment variable:
496
497         $ENV{TZ} = "MST7MDT";              # Unixish
498         $ENV{'SYS$TIMEZONE_DIFFERENTIAL'}="-5" # vms
499         system "trn comp.lang.perl.misc";
500
501 =head2 How can I sleep() or alarm() for under a second?
502 X<Time::HiRes> X<BSD::Itimer> X<sleep> X<select>
503
504 If you want finer granularity than the 1 second that the C<sleep()>
505 function provides, the easiest way is to use the C<select()> function as
506 documented in L<perlfunc/"select">.  Try the C<Time::HiRes> and
507 the C<BSD::Itimer> modules (available from CPAN, and starting from
508 Perl 5.8 C<Time::HiRes> is part of the standard distribution).
509
510 =head2 How can I measure time under a second?
511 X<Time::HiRes> X<BSD::Itimer> X<sleep> X<select>
512
513 (contributed by brian d foy)
514
515 The C<Time::HiRes> module (part of the standard distribution as of
516 Perl 5.8) measures time with the C<gettimeofday()> system call, which
517 returns the time in microseconds since the epoch. If you can't install
518 C<Time::HiRes> for older Perls and you are on a Unixish system, you
519 may be able to call C<gettimeofday(2)> directly. See
520 L<perlfunc/syscall>.
521
522 =head2 How can I do an atexit() or setjmp()/longjmp()? (Exception handling)
523
524 Release 5 of Perl added the END block, which can be used to simulate
525 C<atexit()>.  Each package's END block is called when the program or
526 thread ends (see L<perlmod> manpage for more details).
527
528 For example, you can use this to make sure your filter program
529 managed to finish its output without filling up the disk:
530
531         END {
532                 close(STDOUT) || die "stdout close failed: $!";
533         }
534
535 The C<END> block isn't called when untrapped signals kill the program,
536 though, so if you use C<END> blocks you should also use
537
538         use sigtrap qw(die normal-signals);
539
540 Perl's exception-handling mechanism is its C<eval()> operator.  You can
541 use C<eval()> as C<setjmp> and C<die()> as C<longjmp>.  For details of this, see
542 the section on signals, especially the time-out handler for a blocking
543 C<flock()> in L<perlipc/"Signals"> or the section on "Signals" in
544 the Camel Book.
545
546 If exception handling is all you're interested in, try the
547 C<exceptions.pl> library (part of the standard perl distribution).
548
549 If you want the atexit() syntax (and an rmexit() as well), try the
550 AtExit module available from CPAN.
551
552 =head2 Why doesn't my sockets program work under System V (Solaris)?  What does the error message "Protocol not supported" mean?
553
554 Some Sys-V based systems, notably Solaris 2.X, redefined some of the
555 standard socket constants.  Since these were constant across all
556 architectures, they were often hardwired into perl code.  The proper
557 way to deal with this is to "use Socket" to get the correct values.
558
559 Note that even though SunOS and Solaris are binary compatible, these
560 values are different.  Go figure.
561
562 =head2 How can I call my system's unique C functions from Perl?
563
564 In most cases, you write an external module to do it--see the answer
565 to "Where can I learn about linking C with Perl? [h2xs, xsubpp]".
566 However, if the function is a system call, and your system supports
567 C<syscall()>, you can use the C<syscall> function (documented in
568 L<perlfunc>).
569
570 Remember to check the modules that came with your distribution, and
571 CPAN as well--someone may already have written a module to do it. On
572 Windows, try C<Win32::API>.  On Macs, try C<Mac::Carbon>.  If no module
573 has an interface to the C function, you can inline a bit of C in your
574 Perl source with C<Inline::C>.
575
576 =head2 Where do I get the include files to do ioctl() or syscall()?
577
578 Historically, these would be generated by the C<h2ph> tool, part of the
579 standard perl distribution.  This program converts C<cpp(1)> directives
580 in C header files to files containing subroutine definitions, like
581 C<&SYS_getitimer>, which you can use as arguments to your functions.
582 It doesn't work perfectly, but it usually gets most of the job done.
583 Simple files like F<errno.h>, F<syscall.h>, and F<socket.h> were fine,
584 but the hard ones like F<ioctl.h> nearly always need to be hand-edited.
585 Here's how to install the *.ph files:
586
587         1.  become super-user
588         2.  cd /usr/include
589         3.  h2ph *.h */*.h
590
591 If your system supports dynamic loading, for reasons of portability and
592 sanity you probably ought to use C<h2xs> (also part of the standard perl
593 distribution).  This tool converts C header files to Perl extensions.
594 See L<perlxstut> for how to get started with C<h2xs>.
595
596 If your system doesn't support dynamic loading, you still probably
597 ought to use C<h2xs>.  See L<perlxstut> and L<ExtUtils::MakeMaker> for
598 more information (in brief, just use B<make perl> instead of a plain
599 B<make> to rebuild perl with a new static extension).
600
601 =head2 Why do setuid perl scripts complain about kernel problems?
602
603 Some operating systems have bugs in the kernel that make setuid
604 scripts inherently insecure.  Perl gives you a number of options
605 (described in L<perlsec>) to work around such systems.
606
607 =head2 How can I open a pipe both to and from a command?
608
609 The C<IPC::Open2> module (part of the standard perl distribution) is an
610 easy-to-use approach that internally uses C<pipe()>, C<fork()>, and C<exec()>
611 to do the job.  Make sure you read the deadlock warnings in its documentation,
612 though (see L<IPC::Open2>).  See
613 L<perlipc/"Bidirectional Communication with Another Process"> and
614 L<perlipc/"Bidirectional Communication with Yourself">
615
616 You may also use the C<IPC::Open3> module (part of the standard perl
617 distribution), but be warned that it has a different order of
618 arguments from C<IPC::Open2> (see L<IPC::Open3>).
619
620 =head2 Why can't I get the output of a command with system()?
621
622 You're confusing the purpose of C<system()> and backticks (``).  C<system()>
623 runs a command and returns exit status information (as a 16 bit value:
624 the low 7 bits are the signal the process died from, if any, and
625 the high 8 bits are the actual exit value).  Backticks (``) run a
626 command and return what it sent to STDOUT.
627
628         $exit_status   = system("mail-users");
629         $output_string = `ls`;
630
631 =head2 How can I capture STDERR from an external command?
632
633 There are three basic ways of running external commands:
634
635         system $cmd;            # using system()
636         $output = `$cmd`;               # using backticks (``)
637         open (PIPE, "cmd |");   # using open()
638
639 With C<system()>, both STDOUT and STDERR will go the same place as the
640 script's STDOUT and STDERR, unless the C<system()> command redirects them.
641 Backticks and C<open()> read B<only> the STDOUT of your command.
642
643 You can also use the C<open3()> function from C<IPC::Open3>.  Benjamin
644 Goldberg provides some sample code:
645
646 To capture a program's STDOUT, but discard its STDERR:
647
648         use IPC::Open3;
649         use File::Spec;
650         use Symbol qw(gensym);
651         open(NULL, ">", File::Spec->devnull);
652         my $pid = open3(gensym, \*PH, ">&NULL", "cmd");
653         while( <PH> ) { }
654         waitpid($pid, 0);
655
656 To capture a program's STDERR, but discard its STDOUT:
657
658         use IPC::Open3;
659         use File::Spec;
660         use Symbol qw(gensym);
661         open(NULL, ">", File::Spec->devnull);
662         my $pid = open3(gensym, ">&NULL", \*PH, "cmd");
663         while( <PH> ) { }
664         waitpid($pid, 0);
665
666 To capture a program's STDERR, and let its STDOUT go to our own STDERR:
667
668         use IPC::Open3;
669         use Symbol qw(gensym);
670         my $pid = open3(gensym, ">&STDERR", \*PH, "cmd");
671         while( <PH> ) { }
672         waitpid($pid, 0);
673
674 To read both a command's STDOUT and its STDERR separately, you can
675 redirect them to temp files, let the command run, then read the temp
676 files:
677
678         use IPC::Open3;
679         use Symbol qw(gensym);
680         use IO::File;
681         local *CATCHOUT = IO::File->new_tmpfile;
682         local *CATCHERR = IO::File->new_tmpfile;
683         my $pid = open3(gensym, ">&CATCHOUT", ">&CATCHERR", "cmd");
684         waitpid($pid, 0);
685         seek $_, 0, 0 for \*CATCHOUT, \*CATCHERR;
686         while( <CATCHOUT> ) {}
687         while( <CATCHERR> ) {}
688
689 But there's no real need for B<both> to be tempfiles... the following
690 should work just as well, without deadlocking:
691
692         use IPC::Open3;
693         use Symbol qw(gensym);
694         use IO::File;
695         local *CATCHERR = IO::File->new_tmpfile;
696         my $pid = open3(gensym, \*CATCHOUT, ">&CATCHERR", "cmd");
697         while( <CATCHOUT> ) {}
698         waitpid($pid, 0);
699         seek CATCHERR, 0, 0;
700         while( <CATCHERR> ) {}
701
702 And it'll be faster, too, since we can begin processing the program's
703 stdout immediately, rather than waiting for the program to finish.
704
705 With any of these, you can change file descriptors before the call:
706
707         open(STDOUT, ">logfile");
708         system("ls");
709
710 or you can use Bourne shell file-descriptor redirection:
711
712         $output = `$cmd 2>some_file`;
713         open (PIPE, "cmd 2>some_file |");
714
715 You can also use file-descriptor redirection to make STDERR a
716 duplicate of STDOUT:
717
718         $output = `$cmd 2>&1`;
719         open (PIPE, "cmd 2>&1 |");
720
721 Note that you I<cannot> simply open STDERR to be a dup of STDOUT
722 in your Perl program and avoid calling the shell to do the redirection.
723 This doesn't work:
724
725         open(STDERR, ">&STDOUT");
726         $alloutput = `cmd args`;  # stderr still escapes
727
728 This fails because the C<open()> makes STDERR go to where STDOUT was
729 going at the time of the C<open()>.  The backticks then make STDOUT go to
730 a string, but don't change STDERR (which still goes to the old
731 STDOUT).
732
733 Note that you I<must> use Bourne shell (C<sh(1)>) redirection syntax in
734 backticks, not C<csh(1)>!  Details on why Perl's C<system()> and backtick
735 and pipe opens all use the Bourne shell are in the
736 F<versus/csh.whynot> article in the "Far More Than You Ever Wanted To
737 Know" collection in http://www.cpan.org/misc/olddoc/FMTEYEWTK.tgz .  To
738 capture a command's STDERR and STDOUT together:
739
740         $output = `cmd 2>&1`;                       # either with backticks
741         $pid = open(PH, "cmd 2>&1 |");              # or with an open pipe
742         while (<PH>) { }                            #    plus a read
743
744 To capture a command's STDOUT but discard its STDERR:
745
746         $output = `cmd 2>/dev/null`;                # either with backticks
747         $pid = open(PH, "cmd 2>/dev/null |");       # or with an open pipe
748         while (<PH>) { }                            #    plus a read
749
750 To capture a command's STDERR but discard its STDOUT:
751
752         $output = `cmd 2>&1 1>/dev/null`;           # either with backticks
753         $pid = open(PH, "cmd 2>&1 1>/dev/null |");  # or with an open pipe
754         while (<PH>) { }                            #    plus a read
755
756 To exchange a command's STDOUT and STDERR in order to capture the STDERR
757 but leave its STDOUT to come out our old STDERR:
758
759         $output = `cmd 3>&1 1>&2 2>&3 3>&-`;        # either with backticks
760         $pid = open(PH, "cmd 3>&1 1>&2 2>&3 3>&-|");# or with an open pipe
761         while (<PH>) { }                            #    plus a read
762
763 To read both a command's STDOUT and its STDERR separately, it's easiest
764 to redirect them separately to files, and then read from those files
765 when the program is done:
766
767         system("program args 1>program.stdout 2>program.stderr");
768
769 Ordering is important in all these examples.  That's because the shell
770 processes file descriptor redirections in strictly left to right order.
771
772         system("prog args 1>tmpfile 2>&1");
773         system("prog args 2>&1 1>tmpfile");
774
775 The first command sends both standard out and standard error to the
776 temporary file.  The second command sends only the old standard output
777 there, and the old standard error shows up on the old standard out.
778
779 =head2 Why doesn't open() return an error when a pipe open fails?
780
781 If the second argument to a piped C<open()> contains shell
782 metacharacters, perl C<fork()>s, then C<exec()>s a shell to decode the
783 metacharacters and eventually run the desired program.  If the program
784 couldn't be run, it's the shell that gets the message, not Perl. All
785 your Perl program can find out is whether the shell itself could be
786 successfully started.  You can still capture the shell's STDERR and
787 check it for error messages.  See L<"How can I capture STDERR from an
788 external command?"> elsewhere in this document, or use the
789 C<IPC::Open3> module.
790
791 If there are no shell metacharacters in the argument of C<open()>, Perl
792 runs the command directly, without using the shell, and can correctly
793 report whether the command started.
794
795 =head2 What's wrong with using backticks in a void context?
796
797 Strictly speaking, nothing.  Stylistically speaking, it's not a good
798 way to write maintainable code.  Perl has several operators for
799 running external commands.  Backticks are one; they collect the output
800 from the command for use in your program.  The C<system> function is
801 another; it doesn't do this.
802
803 Writing backticks in your program sends a clear message to the readers
804 of your code that you wanted to collect the output of the command.
805 Why send a clear message that isn't true?
806
807 Consider this line:
808
809         `cat /etc/termcap`;
810
811 You forgot to check C<$?> to see whether the program even ran
812 correctly.  Even if you wrote
813
814         print `cat /etc/termcap`;
815
816 this code could and probably should be written as
817
818         system("cat /etc/termcap") == 0
819         or die "cat program failed!";
820
821 which will echo the cat command's output as it is generated, instead
822 of waiting until the program has completed to print it out. It also
823 checks the return value.
824
825 C<system> also provides direct control over whether shell wildcard
826 processing may take place, whereas backticks do not.
827
828 =head2 How can I call backticks without shell processing?
829
830 This is a bit tricky.  You can't simply write the command
831 like this:
832
833         @ok = `grep @opts '$search_string' @filenames`;
834
835 As of Perl 5.8.0, you can use C<open()> with multiple arguments.
836 Just like the list forms of C<system()> and C<exec()>, no shell
837 escapes happen.
838
839         open( GREP, "-|", 'grep', @opts, $search_string, @filenames );
840         chomp(@ok = <GREP>);
841         close GREP;
842
843 You can also:
844
845         my @ok = ();
846         if (open(GREP, "-|")) {
847                 while (<GREP>) {
848                         chomp;
849                         push(@ok, $_);
850                 }
851                 close GREP;
852         } else {
853                 exec 'grep', @opts, $search_string, @filenames;
854         }
855
856 Just as with C<system()>, no shell escapes happen when you C<exec()> a
857 list. Further examples of this can be found in L<perlipc/"Safe Pipe
858 Opens">.
859
860 Note that if you're using Windows, no solution to this vexing issue is
861 even possible.  Even if Perl were to emulate C<fork()>, you'd still be
862 stuck, because Windows does not have an argc/argv-style API.
863
864 =head2 Why can't my script read from STDIN after I gave it EOF (^D on Unix, ^Z on MS-DOS)?
865
866 This happens only if your perl is compiled to use stdio instead of
867 perlio, which is the default. Some (maybe all?) stdios set error and
868 eof flags that you may need to clear. The C<POSIX> module defines
869 C<clearerr()> that you can use.  That is the technically correct way to
870 do it.  Here are some less reliable workarounds:
871
872 =over 4
873
874 =item 1
875
876 Try keeping around the seekpointer and go there, like this:
877
878         $where = tell(LOG);
879         seek(LOG, $where, 0);
880
881 =item 2
882
883 If that doesn't work, try seeking to a different part of the file and
884 then back.
885
886 =item 3
887
888 If that doesn't work, try seeking to a different part of
889 the file, reading something, and then seeking back.
890
891 =item 4
892
893 If that doesn't work, give up on your stdio package and use sysread.
894
895 =back
896
897 =head2 How can I convert my shell script to perl?
898
899 Learn Perl and rewrite it.  Seriously, there's no simple converter.
900 Things that are awkward to do in the shell are easy to do in Perl, and
901 this very awkwardness is what would make a shell->perl converter
902 nigh-on impossible to write.  By rewriting it, you'll think about what
903 you're really trying to do, and hopefully will escape the shell's
904 pipeline datastream paradigm, which while convenient for some matters,
905 causes many inefficiencies.
906
907 =head2 Can I use perl to run a telnet or ftp session?
908
909 Try the C<Net::FTP>, C<TCP::Client>, and C<Net::Telnet> modules (available from
910 CPAN).  http://www.cpan.org/scripts/netstuff/telnet.emul.shar
911 will also help for emulating the telnet protocol, but C<Net::Telnet> is
912 quite probably easier to use.
913
914 If all you want to do is pretend to be telnet but don't need
915 the initial telnet handshaking, then the standard dual-process
916 approach will suffice:
917
918         use IO::Socket;             # new in 5.004
919         $handle = IO::Socket::INET->new('www.perl.com:80')
920             or die "can't connect to port 80 on www.perl.com: $!";
921         $handle->autoflush(1);
922         if (fork()) {               # XXX: undef means failure
923             select($handle);
924             print while <STDIN>;    # everything from stdin to socket
925         } else {
926             print while <$handle>;  # everything from socket to stdout
927         }
928         close $handle;
929         exit;
930
931 =head2 How can I write expect in Perl?
932
933 Once upon a time, there was a library called L<chat2.pl> (part of the
934 standard perl distribution), which never really got finished.  If you
935 find it somewhere, I<don't use it>.  These days, your best bet is to
936 look at the Expect module available from CPAN, which also requires two
937 other modules from CPAN, C<IO::Pty> and C<IO::Stty>.
938
939 =head2 Is there a way to hide perl's command line from programs such as "ps"?
940
941 First of all note that if you're doing this for security reasons (to
942 avoid people seeing passwords, for example) then you should rewrite
943 your program so that critical information is never given as an
944 argument.  Hiding the arguments won't make your program completely
945 secure.
946
947 To actually alter the visible command line, you can assign to the
948 variable $0 as documented in L<perlvar>.  This won't work on all
949 operating systems, though.  Daemon programs like sendmail place their
950 state there, as in:
951
952         $0 = "orcus [accepting connections]";
953
954 =head2 I {changed directory, modified my environment} in a perl script.  How come the change disappeared when I exited the script?  How do I get my changes to be visible?
955
956 =over 4
957
958 =item Unix
959
960 In the strictest sense, it can't be done--the script executes as a
961 different process from the shell it was started from.  Changes to a
962 process are not reflected in its parent--only in any children
963 created after the change.  There is shell magic that may allow you to
964 fake it by C<eval()>ing the script's output in your shell; check out the
965 comp.unix.questions FAQ for details.
966
967 =back
968
969 =head2 How do I close a process's filehandle without waiting for it to complete?
970
971 Assuming your system supports such things, just send an appropriate signal
972 to the process (see L<perlfunc/"kill">).  It's common to first send a TERM
973 signal, wait a little bit, and then send a KILL signal to finish it off.
974
975 =head2 How do I fork a daemon process?
976
977 If by daemon process you mean one that's detached (disassociated from
978 its tty), then the following process is reported to work on most
979 Unixish systems.  Non-Unix users should check their Your_OS::Process
980 module for other solutions.
981
982 =over 4
983
984 =item *
985
986 Open /dev/tty and use the TIOCNOTTY ioctl on it.  See L<tty>
987 for details.  Or better yet, you can just use the C<POSIX::setsid()>
988 function, so you don't have to worry about process groups.
989
990 =item *
991
992 Change directory to /
993
994 =item *
995
996 Reopen STDIN, STDOUT, and STDERR so they're not connected to the old
997 tty.
998
999 =item *
1000
1001 Background yourself like this:
1002
1003         fork && exit;
1004
1005 =back
1006
1007 The C<Proc::Daemon> module, available from CPAN, provides a function to
1008 perform these actions for you.
1009
1010 =head2 How do I find out if I'm running interactively or not?
1011
1012 (contributed by brian d foy)
1013
1014 This is a difficult question to answer, and the best answer is 
1015 only a guess. What do you really want to know? If you merely 
1016 want to know if one of your filehandles is connected to a terminal,
1017 you can try the C<-t> file test:
1018
1019         if( -t STDOUT ) {
1020                 print "I'm connected to a terminal!\n";
1021                 }
1022                 
1023 However, you might be out of luck if you expect that means there is a
1024 real person on the other side. With the C<Expect> module, another
1025 program can pretend to be a person. The program might even come close
1026 to passing the Turing test.
1027
1028 The C<IO::Interactive> module does the best it can to give you an
1029 answer. Its C<is_interactive> function returns an output filehandle;
1030 that filehandle points to standard output if the module thinks the
1031 session is interactive. Otherwise, the filehandle is a null handle
1032 that simply discards the output:
1033
1034         use IO::Interactive;
1035         
1036         print { is_interactive } "I might go to standard output!\n";
1037
1038 This still doesn't guarantee that a real person is answering your
1039 prompts or reading your output.
1040
1041 If you want to know how to handle automated testing for your
1042 distribution, you can check the environment. The CPAN
1043 Testers, for instance, set the value of C<AUTOMATED_TESTING>:
1044
1045         unless( $ENV{AUTOMATED_TESTING} ) {
1046                 print "Hello interactive tester!\n";
1047                 }
1048
1049 =head2 How do I timeout a slow event?
1050
1051 Use the C<alarm()> function, probably in conjunction with a signal
1052 handler, as documented in L<perlipc/"Signals"> and the section on
1053 "Signals" in the Camel.  You may instead use the more flexible
1054 C<Sys::AlarmCall> module available from CPAN.
1055
1056 The C<alarm()> function is not implemented on all versions of Windows.
1057 Check the documentation for your specific version of Perl.
1058
1059 =head2 How do I set CPU limits?
1060 X<BSD::Resource> X<limit> X<CPU>
1061
1062 (contributed by Xho)
1063
1064 Use the C<BSD::Resource> module from CPAN. As an example:
1065
1066         use BSD::Resource;
1067         setrlimit(RLIMIT_CPU,10,20) or die $!;
1068
1069 This sets the soft and hard limits to 10 and 20 seconds, respectively.
1070 After 10 seconds of time spent running on the CPU (not "wall" time),
1071 the process will be sent a signal (XCPU on some systems) which, if not
1072 trapped, will cause the process to terminate.  If that signal is
1073 trapped, then after 10 more seconds (20 seconds in total) the process
1074 will be killed with a non-trappable signal.
1075
1076 See the C<BSD::Resource> and your systems documentation for the gory
1077 details.
1078
1079 =head2 How do I avoid zombies on a Unix system?
1080
1081 Use the reaper code from L<perlipc/"Signals"> to call C<wait()> when a
1082 SIGCHLD is received, or else use the double-fork technique described
1083 in L<perlfaq8/"How do I start a process in the background?">.
1084
1085 =head2 How do I use an SQL database?
1086
1087 The C<DBI> module provides an abstract interface to most database
1088 servers and types, including Oracle, DB2, Sybase, mysql, Postgresql,
1089 ODBC, and flat files.  The DBI module accesses each database type
1090 through a database driver, or DBD.  You can see a complete list of
1091 available drivers on CPAN: http://www.cpan.org/modules/by-module/DBD/ .
1092 You can read more about DBI on http://dbi.perl.org .
1093
1094 Other modules provide more specific access: C<Win32::ODBC>, C<Alzabo>, C<iodbc>,
1095 and others found on CPAN Search: http://search.cpan.org .
1096
1097 =head2 How do I make a system() exit on control-C?
1098
1099 You can't.  You need to imitate the C<system()> call (see L<perlipc> for
1100 sample code) and then have a signal handler for the INT signal that
1101 passes the signal on to the subprocess.  Or you can check for it:
1102
1103         $rc = system($cmd);
1104         if ($rc & 127) { die "signal death" }
1105
1106 =head2 How do I open a file without blocking?
1107
1108 If you're lucky enough to be using a system that supports
1109 non-blocking reads (most Unixish systems do), you need only to use the
1110 C<O_NDELAY> or C<O_NONBLOCK> flag from the C<Fcntl> module in conjunction with
1111 C<sysopen()>:
1112
1113         use Fcntl;
1114         sysopen(FH, "/foo/somefile", O_WRONLY|O_NDELAY|O_CREAT, 0644)
1115                 or die "can't open /foo/somefile: $!":
1116
1117 =head2 How do I tell the difference between errors from the shell and perl?
1118
1119 (answer contributed by brian d foy)
1120
1121 When you run a Perl script, something else is running the script for you,
1122 and that something else may output error messages.  The script might
1123 emit its own warnings and error messages.  Most of the time you cannot
1124 tell who said what.
1125
1126 You probably cannot fix the thing that runs perl, but you can change how
1127 perl outputs its warnings by defining a custom warning and die functions.
1128
1129 Consider this script, which has an error you may not notice immediately.
1130
1131         #!/usr/locl/bin/perl
1132
1133         print "Hello World\n";
1134
1135 I get an error when I run this from my shell (which happens to be
1136 bash).  That may look like perl forgot it has a C<print()> function,
1137 but my shebang line is not the path to perl, so the shell runs the
1138 script, and I get the error.
1139
1140         $ ./test
1141         ./test: line 3: print: command not found
1142
1143 A quick and dirty fix involves a little bit of code, but this may be all
1144 you need to figure out the problem.
1145
1146         #!/usr/bin/perl -w
1147
1148         BEGIN {
1149         $SIG{__WARN__} = sub{ print STDERR "Perl: ", @_; };
1150         $SIG{__DIE__}  = sub{ print STDERR "Perl: ", @_; exit 1};
1151         }
1152
1153         $a = 1 + undef;
1154         $x / 0;
1155         __END__
1156
1157 The perl message comes out with "Perl" in front.  The C<BEGIN> block
1158 works at compile time so all of the compilation errors and warnings
1159 get the "Perl:" prefix too.
1160
1161         Perl: Useless use of division (/) in void context at ./test line 9.
1162         Perl: Name "main::a" used only once: possible typo at ./test line 8.
1163         Perl: Name "main::x" used only once: possible typo at ./test line 9.
1164         Perl: Use of uninitialized value in addition (+) at ./test line 8.
1165         Perl: Use of uninitialized value in division (/) at ./test line 9.
1166         Perl: Illegal division by zero at ./test line 9.
1167         Perl: Illegal division by zero at -e line 3.
1168
1169 If I don't see that "Perl:", it's not from perl.
1170
1171 You could also just know all the perl errors, and although there are
1172 some people who may know all of them, you probably don't.  However, they
1173 all should be in the L<perldiag> manpage. If you don't find the error in
1174 there, it probably isn't a perl error.
1175
1176 Looking up every message is not the easiest way, so let perl to do it
1177 for you.  Use the diagnostics pragma with turns perl's normal messages
1178 into longer discussions on the topic.
1179
1180         use diagnostics;
1181
1182 If you don't get a paragraph or two of expanded discussion, it
1183 might not be perl's message.
1184
1185 =head2 How do I install a module from CPAN?
1186
1187 (contributed by brian d foy)
1188
1189 The easiest way is to have a module also named CPAN do it for you by using
1190 the C<cpan> command the comes with Perl. You can give it a list of modules
1191 to install:
1192
1193         $ cpan IO::Interactive Getopt::Whatever
1194
1195 If you prefer C<CPANPLUS>, it's just as easy:
1196
1197         $ cpanp i IO::Interactive Getopt::Whatever
1198         
1199 If you want to install a distribution from the current directory, you can
1200 tell C<CPAN.pm> to install C<.> (the full stop):
1201
1202         $ cpan .
1203
1204 See the documentation for either of those commands to see what else
1205 you can do.
1206
1207 If you want to try to install a distribution by yourself, resolving
1208 all dependencies on your own, you follow one of two possible build
1209 paths.
1210
1211 For distributions that use I<Makefile.PL>:
1212
1213         $ perl Makefile.PL
1214         $ make test install
1215         
1216 For distributions that use I<Build.PL>:
1217
1218         $ perl Build.PL
1219         $ ./Build test
1220         $ ./Build install
1221
1222 Some distributions may need to link to libraries or other third-party
1223 code and their build and installation sequences may be more complicated.
1224 Check any I<README> or I<INSTALL> files that you may find.
1225
1226 =head2 What's the difference between require and use?
1227
1228 (contributed by brian d foy)
1229
1230 Perl runs C<require> statement at run-time. Once Perl loads, compiles,
1231 and runs the file, it doesn't do anything else. The C<use> statement
1232 is the same as a C<require> run at compile-time, but Perl also calls the
1233 C<import> method for the loaded package. These two are the same:
1234
1235         use MODULE qw(import list);
1236
1237         BEGIN {
1238                 require MODULE;
1239                 MODULE->import(import list);
1240                 }
1241
1242 However, you can suppress the C<import> by using an explicit, empty
1243 import list. Both of these still happen at compile-time:
1244
1245         use MODULE ();
1246
1247         BEGIN {
1248                 require MODULE;
1249                 }
1250
1251 Since C<use> will also call the C<import> method, the actual value
1252 for C<MODULE> must be a bareword. That is, C<use> cannot load files
1253 by name, although C<require> can:
1254
1255         require "$ENV{HOME}/lib/Foo.pm"; # no @INC searching!
1256
1257 See the entry for C<use> in L<perlfunc> for more details.
1258
1259 =head2 How do I keep my own module/library directory?
1260
1261 When you build modules, tell Perl where to install the modules.
1262
1263 For C<Makefile.PL>-based distributions, use the INSTALL_BASE option
1264 when generating Makefiles:
1265
1266         perl Makefile.PL INSTALL_BASE=/mydir/perl
1267
1268 You can set this in your C<CPAN.pm> configuration so modules automatically install
1269 in your private library directory when you use the CPAN.pm shell:
1270
1271         % cpan
1272         cpan> o conf makepl_arg INSTALL_BASE=/mydir/perl
1273         cpan> o conf commit
1274
1275 For C<Build.PL>-based distributions, use the --install_base option:
1276
1277         perl Build.PL --install_base /mydir/perl
1278
1279 You can configure C<CPAN.pm> to automatically use this option too:
1280
1281         % cpan
1282         cpan> o conf mbuild_arg --install_base /mydir/perl
1283         cpan> o conf commit
1284
1285 INSTALL_BASE tells these tools to put your modules into
1286 F</mydir/perl/lib/perl5>.  See L<How do I add a directory to my
1287 include path (@INC) at runtime?> for details on how to run your newly
1288 installed modules.
1289
1290 There is one caveat with INSTALL_BASE, though, since it acts
1291 differently than the PREFIX and LIB settings that older versions of
1292 C<ExtUtils::MakeMaker> advocated. INSTALL_BASE does not support
1293 installing modules for multiple versions of Perl or different
1294 architectures under the same directory. You should consider if you
1295 really want that , and if you do, use the older PREFIX and LIB
1296 settings. See the C<ExtUtils::Makemaker> documentation for more details.
1297
1298 =head2 How do I add the directory my program lives in to the module/library search path?
1299
1300 (contributed by brian d foy)
1301
1302 If you know the directory already, you can add it to C<@INC> as you would
1303 for any other directory. You might <use lib> if you know the directory
1304 at compile time:
1305
1306         use lib $directory;
1307
1308 The trick in this task is to find the directory. Before your script does
1309 anything else (such as a C<chdir>), you can get the current working
1310 directory with the C<Cwd> module, which comes with Perl:
1311
1312         BEGIN {
1313                 use Cwd;
1314                 our $directory = cwd;
1315                 }
1316
1317         use lib $directory;
1318
1319 You can do a similar thing with the value of C<$0>, which holds the
1320 script name. That might hold a relative path, but C<rel2abs> can turn
1321 it into an absolute path. Once you have the
1322
1323         BEGIN {
1324                 use File::Spec::Functions qw(rel2abs);
1325                 use File::Basename qw(dirname);
1326
1327                 my $path   = rel2abs( $0 );
1328                 our $directory = dirname( $path );
1329                 }
1330
1331         use lib $directory;
1332
1333 The C<FindBin> module, which comes with Perl, might work. It finds the
1334 directory of the currently running script and puts it in C<$Bin>, which
1335 you can then use to construct the right library path:
1336
1337         use FindBin qw($Bin);
1338
1339 =head2 How do I add a directory to my include path (@INC) at runtime?
1340
1341 Here are the suggested ways of modifying your include path, including
1342 environment variables, run-time switches, and in-code statements:
1343
1344 =over 4
1345
1346 =item the PERLLIB environment variable
1347
1348         $ export PERLLIB=/path/to/my/dir
1349         $ perl program.pl
1350
1351 =item the PERL5LIB environment variable
1352
1353         $ export PERL5LIB=/path/to/my/dir
1354         $ perl program.pl
1355
1356 =item the perl -Idir command line flag
1357
1358         $ perl -I/path/to/my/dir program.pl
1359
1360 =item the use lib pragma:
1361
1362         use lib "$ENV{HOME}/myown_perllib";
1363
1364 =back
1365
1366 The last is particularly useful because it knows about machine
1367 dependent architectures.  The C<lib.pm> pragmatic module was first
1368 included with the 5.002 release of Perl.
1369
1370 =head2 What is socket.ph and where do I get it?
1371
1372 It's a Perl 4 style file defining values for system networking
1373 constants.  Sometimes it is built using C<h2ph> when Perl is installed,
1374 but other times it is not.  Modern programs C<use Socket;> instead.
1375
1376 =head1 REVISION
1377
1378 Revision: $Revision$
1379
1380 Date: $Date$
1381
1382 See L<perlfaq> for source control details and availability.
1383
1384 =head1 AUTHOR AND COPYRIGHT
1385
1386 Copyright (c) 1997-2009 Tom Christiansen, Nathan Torkington, and
1387 other authors as noted. All rights reserved.
1388
1389 This documentation is free; you can redistribute it and/or modify it
1390 under the same terms as Perl itself.
1391
1392 Irrespective of its distribution, all code examples in this file
1393 are hereby placed into the public domain.  You are permitted and
1394 encouraged to use this code in your own programs for fun
1395 or for profit as you see fit.  A simple comment in the code giving
1396 credit would be courteous but is not required.