Avoid a possible race condition where a parallel make might
[perl.git] / pod / perlfaq7.pod
1 =head1 NAME
2
3 perlfaq7 - General Perl Language Issues
4
5 =head1 DESCRIPTION
6
7 This section deals with general Perl language issues that don't
8 clearly fit into any of the other sections.
9
10 =head2 Can I get a BNF/yacc/RE for the Perl language?
11
12 There is no BNF, but you can paw your way through the yacc grammar in
13 perly.y in the source distribution if you're particularly brave.  The
14 grammar relies on very smart tokenizing code, so be prepared to
15 venture into toke.c as well.
16
17 In the words of Chaim Frenkel: "Perl's grammar can not be reduced to BNF.
18 The work of parsing perl is distributed between yacc, the lexer, smoke
19 and mirrors."
20
21 =head2 What are all these $@%&* punctuation signs, and how do I know when to use them?
22
23 They are type specifiers, as detailed in L<perldata>:
24
25         $ for scalar values (number, string or reference)
26         @ for arrays
27         % for hashes (associative arrays)
28         & for subroutines (aka functions, procedures, methods)
29         * for all types of that symbol name.  In version 4 you used them like
30           pointers, but in modern perls you can just use references.
31
32 There are couple of other symbols that you're likely to encounter that aren't
33 really type specifiers:
34
35         <> are used for inputting a record from a filehandle.
36         \  takes a reference to something.
37
38 Note that <FILE> is I<neither> the type specifier for files
39 nor the name of the handle.  It is the C<< <> >> operator applied
40 to the handle FILE.  It reads one line (well, record--see
41 L<perlvar/$E<sol>>) from the handle FILE in scalar context, or I<all> lines
42 in list context.  When performing open, close, or any other operation
43 besides C<< <> >> on files, or even when talking about the handle, do
44 I<not> use the brackets.  These are correct: C<eof(FH)>, C<seek(FH, 0,
45 2)> and "copying from STDIN to FILE".
46
47 =head2 Do I always/never have to quote my strings or use semicolons and commas?
48
49 Normally, a bareword doesn't need to be quoted, but in most cases
50 probably should be (and must be under C<use strict>).  But a hash key
51 consisting of a simple word (that isn't the name of a defined
52 subroutine) and the left-hand operand to the C<< => >> operator both
53 count as though they were quoted:
54
55         This                    is like this
56         ------------            ---------------
57         $foo{line}              $foo{'line'}
58         bar => stuff            'bar' => stuff
59
60 The final semicolon in a block is optional, as is the final comma in a
61 list.  Good style (see L<perlstyle>) says to put them in except for
62 one-liners:
63
64         if ($whoops) { exit 1 }
65         @nums = (1, 2, 3);
66
67         if ($whoops) {
68                 exit 1;
69         }
70
71         @lines = (
72         "There Beren came from mountains cold",
73         "And lost he wandered under leaves",
74         );
75
76 =head2 How do I skip some return values?
77
78 One way is to treat the return values as a list and index into it:
79
80         $dir = (getpwnam($user))[7];
81
82 Another way is to use undef as an element on the left-hand-side:
83
84         ($dev, $ino, undef, undef, $uid, $gid) = stat($file);
85
86 You can also use a list slice to select only the elements that
87 you need:
88
89         ($dev, $ino, $uid, $gid) = ( stat($file) )[0,1,4,5];
90
91 =head2 How do I temporarily block warnings?
92
93 If you are running Perl 5.6.0 or better, the C<use warnings> pragma
94 allows fine control of what warning are produced.
95 See L<perllexwarn> for more details.
96
97         {
98         no warnings;          # temporarily turn off warnings
99         $a = $b + $c;         # I know these might be undef
100         }
101
102 Additionally, you can enable and disable categories of warnings.
103 You turn off the categories you want to ignore and you can still
104 get other categories of warnings.  See L<perllexwarn> for the
105 complete details, including the category names and hierarchy.
106
107         {
108         no warnings 'uninitialized';
109         $a = $b + $c;
110         }
111
112 If you have an older version of Perl, the C<$^W> variable (documented
113 in L<perlvar>) controls runtime warnings for a block:
114
115         {
116         local $^W = 0;        # temporarily turn off warnings
117         $a = $b + $c;         # I know these might be undef
118         }
119
120 Note that like all the punctuation variables, you cannot currently
121 use my() on C<$^W>, only local().
122
123 =head2 What's an extension?
124
125 An extension is a way of calling compiled C code from Perl.  Reading
126 L<perlxstut> is a good place to learn more about extensions.
127
128 =head2 Why do Perl operators have different precedence than C operators?
129
130 Actually, they don't.  All C operators that Perl copies have the same
131 precedence in Perl as they do in C.  The problem is with operators that C
132 doesn't have, especially functions that give a list context to everything
133 on their right, eg. print, chmod, exec, and so on.  Such functions are
134 called "list operators" and appear as such in the precedence table in
135 L<perlop>.
136
137 A common mistake is to write:
138
139         unlink $file || die "snafu";
140
141 This gets interpreted as:
142
143         unlink ($file || die "snafu");
144
145 To avoid this problem, either put in extra parentheses or use the
146 super low precedence C<or> operator:
147
148         (unlink $file) || die "snafu";
149         unlink $file or die "snafu";
150
151 The "English" operators (C<and>, C<or>, C<xor>, and C<not>)
152 deliberately have precedence lower than that of list operators for
153 just such situations as the one above.
154
155 Another operator with surprising precedence is exponentiation.  It
156 binds more tightly even than unary minus, making C<-2**2> produce a
157 negative not a positive four.  It is also right-associating, meaning
158 that C<2**3**2> is two raised to the ninth power, not eight squared.
159
160 Although it has the same precedence as in C, Perl's C<?:> operator
161 produces an lvalue.  This assigns $x to either $a or $b, depending
162 on the trueness of $maybe:
163
164         ($maybe ? $a : $b) = $x;
165
166 =head2 How do I declare/create a structure?
167
168 In general, you don't "declare" a structure.  Just use a (probably
169 anonymous) hash reference.  See L<perlref> and L<perldsc> for details.
170 Here's an example:
171
172         $person = {};                   # new anonymous hash
173         $person->{AGE}  = 24;           # set field AGE to 24
174         $person->{NAME} = "Nat";        # set field NAME to "Nat"
175
176 If you're looking for something a bit more rigorous, try L<perltoot>.
177
178 =head2 How do I create a module?
179
180 (contributed by brian d foy)
181
182 L<perlmod>, L<perlmodlib>, L<perlmodstyle> explain modules
183 in all the gory details. L<perlnewmod> gives a brief
184 overview of the process along with a couple of suggestions
185 about style.
186
187 If you need to include C code or C library interfaces in
188 your module, you'll need h2xs.  h2xs will create the module
189 distribution structure and the initial interface files
190 you'll need.  L<perlxs> and L<perlxstut> explain the details.
191
192 If you don't need to use C code, other tools such as
193 ExtUtils::ModuleMaker and Module::Starter, can help you
194 create a skeleton module distribution.
195
196 You may also want to see Sam Tregar's "Writing Perl Modules
197 for CPAN" ( http://apress.com/book/bookDisplay.html?bID=14 )
198 which is the best hands-on guide to creating module
199 distributions.
200
201 =head2 How do I adopt or take over a module already on CPAN?
202
203 (contributed by brian d foy)
204
205 The easiest way to take over a module is to have the current
206 module maintainer either make you a co-maintainer or transfer
207 the module to you.
208
209 If you can't reach the author for some reason (e.g. email bounces),
210 the PAUSE admins at modules@perl.org can help. The PAUSE admins
211 treat each case individually.
212
213 =over 4
214
215 =item
216
217 Get a login for the Perl Authors Upload Server (PAUSE) if you don't
218 already have one: http://pause.perl.org
219
220 =item
221
222 Write to modules@perl.org explaining what you did to contact the
223 current maintainer. The PAUSE admins will also try to reach the
224 maintainer.
225
226 =item
227
228 Post a public message in a heavily trafficked site announcing your
229 intention to take over the module.
230
231 =item
232
233 Wait a bit. The PAUSE admins don't want to act too quickly in case
234 the current maintainer is on holiday. If there's no response to
235 private communication or the public post, a PAUSE admin can transfer
236 it to you.
237
238 =back
239
240 =head2 How do I create a class?
241 X<class, creation> X<package>
242
243 (contributed by brian d foy)
244
245 In Perl, a class is just a package, and methods are just subroutines.
246 Perl doesn't get more formal than that and lets you set up the package
247 just the way that you like it (that is, it doesn't set up anything for
248 you).
249
250 The Perl documentation has several tutorials that cover class
251 creation, including L<perlboot> (Barnyard Object Oriented Tutorial),
252 L<perltoot> (Tom's Object Oriented Tutorial), L<perlbot> (Bag o'
253 Object Tricks), and L<perlobj>.
254
255 =head2 How can I tell if a variable is tainted?
256
257 You can use the tainted() function of the Scalar::Util module, available
258 from CPAN (or included with Perl since release 5.8.0).
259 See also L<perlsec/"Laundering and Detecting Tainted Data">.
260
261 =head2 What's a closure?
262
263 Closures are documented in L<perlref>.
264
265 I<Closure> is a computer science term with a precise but
266 hard-to-explain meaning. Usually, closures are implemented in Perl as
267 anonymous subroutines with lasting references to lexical variables
268 outside their own scopes. These lexicals magically refer to the
269 variables that were around when the subroutine was defined (deep
270 binding).
271
272 Closures are most often used in programming languages where you can
273 have the return value of a function be itself a function, as you can
274 in Perl. Note that some languages provide anonymous functions but are
275 not capable of providing proper closures: the Python language, for
276 example.  For more information on closures, check out any textbook on
277 functional programming.  Scheme is a language that not only supports
278 but encourages closures.
279
280 Here's a classic non-closure function-generating function:
281
282         sub add_function_generator {
283                 return sub { shift() + shift() };
284                 }
285
286         $add_sub = add_function_generator();
287         $sum = $add_sub->(4,5);                # $sum is 9 now.
288
289 The anonymous subroutine returned by add_function_generator() isn't
290 technically a closure because it refers to no lexicals outside its own
291 scope.  Using a closure gives you a I<function template> with some
292 customization slots left out to be filled later.
293
294 Contrast this with the following make_adder() function, in which the
295 returned anonymous function contains a reference to a lexical variable
296 outside the scope of that function itself.  Such a reference requires
297 that Perl return a proper closure, thus locking in for all time the
298 value that the lexical had when the function was created.
299
300         sub make_adder {
301                 my $addpiece = shift;
302                 return sub { shift() + $addpiece };
303         }
304
305         $f1 = make_adder(20);
306         $f2 = make_adder(555);
307
308 Now C<&$f1($n)> is always 20 plus whatever $n you pass in, whereas
309 C<&$f2($n)> is always 555 plus whatever $n you pass in.  The $addpiece
310 in the closure sticks around.
311
312 Closures are often used for less esoteric purposes.  For example, when
313 you want to pass in a bit of code into a function:
314
315         my $line;
316         timeout( 30, sub { $line = <STDIN> } );
317
318 If the code to execute had been passed in as a string,
319 C<< '$line = <STDIN>' >>, there would have been no way for the
320 hypothetical timeout() function to access the lexical variable
321 $line back in its caller's scope.
322
323 Another use for a closure is to make a variable I<private> to a
324 named subroutine, e.g. a counter that gets initialized at creation
325 time of the sub and can only be modified from within the sub.
326 This is sometimes used with a BEGIN block in package files to make
327 sure a variable doesn't get meddled with during the lifetime of the
328 package:
329
330         BEGIN {
331                 my $id = 0;
332                 sub next_id { ++$id }
333         }
334
335 This is discussed in more detail in L<perlsub>, see the entry on
336 I<Persistent Private Variables>.
337
338 =head2 What is variable suicide and how can I prevent it?
339
340 This problem was fixed in perl 5.004_05, so preventing it means upgrading
341 your version of perl. ;)
342
343 Variable suicide is when you (temporarily or permanently) lose the value
344 of a variable.  It is caused by scoping through my() and local()
345 interacting with either closures or aliased foreach() iterator variables
346 and subroutine arguments.  It used to be easy to inadvertently lose a
347 variable's value this way, but now it's much harder.  Take this code:
348
349         my $f = 'foo';
350         sub T {
351                 while ($i++ < 3) { my $f = $f; $f .= "bar"; print $f, "\n" }
352                 }
353
354         T;
355         print "Finally $f\n";
356
357 If you are experiencing variable suicide, that C<my $f> in the subroutine
358 doesn't pick up a fresh copy of the C<$f> whose value is <foo>. The output
359 shows that inside the subroutine the value of C<$f> leaks through when it
360 shouldn't, as in this output:
361
362         foobar
363         foobarbar
364         foobarbarbar
365         Finally foo
366
367 The $f that has "bar" added to it three times should be a new C<$f>
368 C<my $f> should create a new lexical variable each time through the loop.
369 The expected output is:
370
371         foobar
372         foobar
373         foobar
374         Finally foo
375
376 =head2 How can I pass/return a {Function, FileHandle, Array, Hash, Method, Regex}?
377
378 With the exception of regexes, you need to pass references to these
379 objects.  See L<perlsub/"Pass by Reference"> for this particular
380 question, and L<perlref> for information on references.
381
382 See "Passing Regexes", later in L<perlfaq7>, for information on
383 passing regular expressions.
384
385 =over 4
386
387 =item Passing Variables and Functions
388
389 Regular variables and functions are quite easy to pass: just pass in a
390 reference to an existing or anonymous variable or function:
391
392         func( \$some_scalar );
393
394         func( \@some_array  );
395         func( [ 1 .. 10 ]   );
396
397         func( \%some_hash   );
398         func( { this => 10, that => 20 }   );
399
400         func( \&some_func   );
401         func( sub { $_[0] ** $_[1] }   );
402
403 =item Passing Filehandles
404
405 As of Perl 5.6, you can represent filehandles with scalar variables
406 which you treat as any other scalar.
407
408         open my $fh, $filename or die "Cannot open $filename! $!";
409         func( $fh );
410
411         sub func {
412                 my $passed_fh = shift;
413
414                 my $line = <$passed_fh>;
415                 }
416
417 Before Perl 5.6, you had to use the C<*FH> or C<\*FH> notations.
418 These are "typeglobs"--see L<perldata/"Typeglobs and Filehandles">
419 and especially L<perlsub/"Pass by Reference"> for more information.
420
421 =item Passing Regexes
422
423 To pass regexes around, you'll need to be using a release of Perl
424 sufficiently recent as to support the C<qr//> construct, pass around
425 strings and use an exception-trapping eval, or else be very, very clever.
426
427 Here's an example of how to pass in a string to be regex compared
428 using C<qr//>:
429
430         sub compare($$) {
431                 my ($val1, $regex) = @_;
432                 my $retval = $val1 =~ /$regex/;
433         return $retval;
434         }
435         $match = compare("old McDonald", qr/d.*D/i);
436
437 =item Passing Methods
438
439 To pass an object method into a subroutine, you can do this:
440
441         call_a_lot(10, $some_obj, "methname")
442         sub call_a_lot {
443                 my ($count, $widget, $trick) = @_;
444                 for (my $i = 0; $i < $count; $i++) {
445                         $widget->$trick();
446                 }
447         }
448
449 Or, you can use a closure to bundle up the object, its
450 method call, and arguments:
451
452         my $whatnot =  sub { $some_obj->obfuscate(@args) };
453         func($whatnot);
454         sub func {
455                 my $code = shift;
456                 &$code();
457         }
458
459 You could also investigate the can() method in the UNIVERSAL class
460 (part of the standard perl distribution).
461
462 =back
463
464 =head2 How do I create a static variable?
465
466 (contributed by brian d foy)
467
468 In Perl 5.10, declare the variable with C<state>. The C<state>
469 declaration creates the lexical variable that persists between calls
470 to the subroutine:
471
472         sub counter { state $count = 1; $counter++ }
473
474 You can fake a static variable by using a lexical variable which goes
475 out of scope. In this example, you define the subroutine C<counter>, and
476 it uses the lexical variable C<$count>. Since you wrap this in a BEGIN
477 block, C<$count> is defined at compile-time, but also goes out of
478 scope at the end of the BEGIN block. The BEGIN block also ensures that
479 the subroutine and the value it uses is defined at compile-time so the
480 subroutine is ready to use just like any other subroutine, and you can
481 put this code in the same place as other subroutines in the program
482 text (i.e. at the end of the code, typically). The subroutine
483 C<counter> still has a reference to the data, and is the only way you
484 can access the value (and each time you do, you increment the value).
485 The data in chunk of memory defined by C<$count> is private to
486 C<counter>.
487
488         BEGIN {
489                 my $count = 1;
490                 sub counter { $count++ }
491         }
492
493         my $start = counter();
494
495         .... # code that calls counter();
496
497         my $end = counter();
498
499 In the previous example, you created a function-private variable
500 because only one function remembered its reference. You could define
501 multiple functions while the variable is in scope, and each function
502 can share the "private" variable. It's not really "static" because you
503 can access it outside the function while the lexical variable is in
504 scope, and even create references to it. In this example,
505 C<increment_count> and C<return_count> share the variable. One
506 function adds to the value and the other simply returns the value.
507 They can both access C<$count>, and since it has gone out of scope,
508 there is no other way to access it.
509
510         BEGIN {
511                 my $count = 1;
512                 sub increment_count { $count++ }
513                 sub return_count    { $count }
514         }
515
516 To declare a file-private variable, you still use a lexical variable.
517 A file is also a scope, so a lexical variable defined in the file
518 cannot be seen from any other file.
519
520 See L<perlsub/"Persistent Private Variables"> for more information.
521 The discussion of closures in L<perlref> may help you even though we
522 did not use anonymous subroutines in this answer. See
523 L<perlsub/"Persistent Private Variables"> for details.
524
525 =head2 What's the difference between dynamic and lexical (static) scoping?  Between local() and my()?
526
527 C<local($x)> saves away the old value of the global variable C<$x>
528 and assigns a new value for the duration of the subroutine I<which is
529 visible in other functions called from that subroutine>.  This is done
530 at run-time, so is called dynamic scoping.  local() always affects global
531 variables, also called package variables or dynamic variables.
532
533 C<my($x)> creates a new variable that is only visible in the current
534 subroutine.  This is done at compile-time, so it is called lexical or
535 static scoping.  my() always affects private variables, also called
536 lexical variables or (improperly) static(ly scoped) variables.
537
538 For instance:
539
540         sub visible {
541                 print "var has value $var\n";
542                 }
543
544         sub dynamic {
545                 local $var = 'local';   # new temporary value for the still-global
546                 visible();              #   variable called $var
547                 }
548
549         sub lexical {
550                 my $var = 'private';    # new private variable, $var
551                 visible();              # (invisible outside of sub scope)
552                 }
553
554         $var = 'global';
555
556         visible();                      # prints global
557         dynamic();                      # prints local
558         lexical();                      # prints global
559
560 Notice how at no point does the value "private" get printed.  That's
561 because $var only has that value within the block of the lexical()
562 function, and it is hidden from called subroutine.
563
564 In summary, local() doesn't make what you think of as private, local
565 variables.  It gives a global variable a temporary value.  my() is
566 what you're looking for if you want private variables.
567
568 See L<perlsub/"Private Variables via my()"> and
569 L<perlsub/"Temporary Values via local()"> for excruciating details.
570
571 =head2 How can I access a dynamic variable while a similarly named lexical is in scope?
572
573 If you know your package, you can just mention it explicitly, as in
574 $Some_Pack::var. Note that the notation $::var is B<not> the dynamic $var
575 in the current package, but rather the one in the "main" package, as
576 though you had written $main::var.
577
578         use vars '$var';
579         local $var = "global";
580         my    $var = "lexical";
581
582         print "lexical is $var\n";
583         print "global  is $main::var\n";
584
585 Alternatively you can use the compiler directive our() to bring a
586 dynamic variable into the current lexical scope.
587
588         require 5.006; # our() did not exist before 5.6
589         use vars '$var';
590
591         local $var = "global";
592         my $var    = "lexical";
593
594         print "lexical is $var\n";
595
596         {
597                 our $var;
598                 print "global  is $var\n";
599         }
600
601 =head2 What's the difference between deep and shallow binding?
602
603 In deep binding, lexical variables mentioned in anonymous subroutines
604 are the same ones that were in scope when the subroutine was created.
605 In shallow binding, they are whichever variables with the same names
606 happen to be in scope when the subroutine is called.  Perl always uses
607 deep binding of lexical variables (i.e., those created with my()).
608 However, dynamic variables (aka global, local, or package variables)
609 are effectively shallowly bound.  Consider this just one more reason
610 not to use them.  See the answer to L<"What's a closure?">.
611
612 =head2 Why doesn't "my($foo) = E<lt>FILEE<gt>;" work right?
613
614 C<my()> and C<local()> give list context to the right hand side
615 of C<=>.  The <FH> read operation, like so many of Perl's
616 functions and operators, can tell which context it was called in and
617 behaves appropriately.  In general, the scalar() function can help.
618 This function does nothing to the data itself (contrary to popular myth)
619 but rather tells its argument to behave in whatever its scalar fashion is.
620 If that function doesn't have a defined scalar behavior, this of course
621 doesn't help you (such as with sort()).
622
623 To enforce scalar context in this particular case, however, you need
624 merely omit the parentheses:
625
626         local($foo) = <FILE>;       # WRONG
627         local($foo) = scalar(<FILE>);   # ok
628         local $foo  = <FILE>;       # right
629
630 You should probably be using lexical variables anyway, although the
631 issue is the same here:
632
633         my($foo) = <FILE>;      # WRONG
634         my $foo  = <FILE>;      # right
635
636 =head2 How do I redefine a builtin function, operator, or method?
637
638 Why do you want to do that? :-)
639
640 If you want to override a predefined function, such as open(),
641 then you'll have to import the new definition from a different
642 module.  See L<perlsub/"Overriding Built-in Functions">.  There's
643 also an example in L<perltoot/"Class::Template">.
644
645 If you want to overload a Perl operator, such as C<+> or C<**>,
646 then you'll want to use the C<use overload> pragma, documented
647 in L<overload>.
648
649 If you're talking about obscuring method calls in parent classes,
650 see L<perltoot/"Overridden Methods">.
651
652 =head2 What's the difference between calling a function as &foo and foo()?
653
654 (contributed by brian d foy)
655
656 Calling a subroutine as C<&foo> with no trailing parentheses ignores
657 the prototype of C<foo> and passes it the current value of the argument
658 list, C<@_>. Here's an example; the C<bar> subroutine calls C<&foo>,
659 which prints its argument list:
660
661         sub bar { &foo }
662
663         sub foo { print "Args in foo are: @_\n" }
664
665         bar( qw( a b c ) );
666
667 When you call C<bar> with arguments, you see that C<foo> got the same C<@_>:
668
669         Args in foo are: a b c
670
671 Calling the subroutine with trailing parentheses, with or without arguments,
672 does not use the current C<@_> and respects the subroutine prototype. Changing
673 the example to put parentheses after the call to C<foo> changes the program:
674
675         sub bar { &foo() }
676
677         sub foo { print "Args in foo are: @_\n" }
678
679         bar( qw( a b c ) );
680
681 Now the output shows that C<foo> doesn't get the C<@_> from its caller.
682
683         Args in foo are:
684
685 The main use of the C<@_> pass-through feature is to write subroutines
686 whose main job it is to call other subroutines for you. For further
687 details, see L<perlsub>.
688
689 =head2 How do I create a switch or case statement?
690
691 In Perl 5.10, use the C<given-when> construct described in L<perlsyn>:
692
693         use 5.010;
694
695         given ( $string ) {
696                 when( 'Fred' )        { say "I found Fred!" }
697                 when( 'Barney' )      { say "I found Barney!" }
698                 when( /Bamm-?Bamm/ )  { say "I found Bamm-Bamm!" }
699                 default               { say "I don't recognize the name!" }
700                 };
701
702 If one wants to use pure Perl and to be compatible with Perl versions
703 prior to 5.10, the general answer is to use C<if-elsif-else>:
704
705         for ($variable_to_test) {
706                 if    (/pat1/)  { }     # do something
707                 elsif (/pat2/)  { }     # do something else
708                 elsif (/pat3/)  { }     # do something else
709                 else            { }     # default
710                 }
711
712 Here's a simple example of a switch based on pattern matching,
713 lined up in a way to make it look more like a switch statement.
714 We'll do a multiway conditional based on the type of reference stored
715 in $whatchamacallit:
716
717     SWITCH: for (ref $whatchamacallit) {
718
719         /^$/            && die "not a reference";
720
721         /SCALAR/        && do {
722                                 print_scalar($$ref);
723                                 last SWITCH;
724                         };
725
726         /ARRAY/         && do {
727                                 print_array(@$ref);
728                                 last SWITCH;
729                         };
730
731         /HASH/          && do {
732                                 print_hash(%$ref);
733                                 last SWITCH;
734                         };
735
736         /CODE/          && do {
737                                 warn "can't print function ref";
738                                 last SWITCH;
739                         };
740
741         # DEFAULT
742
743         warn "User defined type skipped";
744
745     }
746
747 See L<perlsyn> for other examples in this style.
748
749 Sometimes you should change the positions of the constant and the variable.
750 For example, let's say you wanted to test which of many answers you were
751 given, but in a case-insensitive way that also allows abbreviations.
752 You can use the following technique if the strings all start with
753 different characters or if you want to arrange the matches so that
754 one takes precedence over another, as C<"SEND"> has precedence over
755 C<"STOP"> here:
756
757         chomp($answer = <>);
758         if    ("SEND"  =~ /^\Q$answer/i) { print "Action is send\n"  }
759         elsif ("STOP"  =~ /^\Q$answer/i) { print "Action is stop\n"  }
760         elsif ("ABORT" =~ /^\Q$answer/i) { print "Action is abort\n" }
761         elsif ("LIST"  =~ /^\Q$answer/i) { print "Action is list\n"  }
762         elsif ("EDIT"  =~ /^\Q$answer/i) { print "Action is edit\n"  }
763
764 A totally different approach is to create a hash of function references.
765
766         my %commands = (
767                 "happy" => \&joy,
768                 "sad",  => \&sullen,
769                 "done"  => sub { die "See ya!" },
770                 "mad"   => \&angry,
771         );
772
773         print "How are you? ";
774         chomp($string = <STDIN>);
775         if ($commands{$string}) {
776                 $commands{$string}->();
777         } else {
778                 print "No such command: $string\n";
779         }
780
781 Starting from Perl 5.8, a source filter module, C<Switch>, can also be
782 used to get switch and case. Its use is now discouraged, because it's
783 not fully compatible with the native switch of Perl 5.10, and because,
784 as it's implemented as a source filter, it doesn't always work as intended
785 when complex syntax is involved.
786
787 =head2 How can I catch accesses to undefined variables, functions, or methods?
788
789 The AUTOLOAD method, discussed in L<perlsub/"Autoloading"> and
790 L<perltoot/"AUTOLOAD: Proxy Methods">, lets you capture calls to
791 undefined functions and methods.
792
793 When it comes to undefined variables that would trigger a warning
794 under C<use warnings>, you can promote the warning to an error.
795
796         use warnings FATAL => qw(uninitialized);
797
798 =head2 Why can't a method included in this same file be found?
799
800 Some possible reasons: your inheritance is getting confused, you've
801 misspelled the method name, or the object is of the wrong type.  Check
802 out L<perltoot> for details about any of the above cases.  You may
803 also use C<print ref($object)> to find out the class C<$object> was
804 blessed into.
805
806 Another possible reason for problems is because you've used the
807 indirect object syntax (eg, C<find Guru "Samy">) on a class name
808 before Perl has seen that such a package exists.  It's wisest to make
809 sure your packages are all defined before you start using them, which
810 will be taken care of if you use the C<use> statement instead of
811 C<require>.  If not, make sure to use arrow notation (eg.,
812 C<< Guru->find("Samy") >>) instead.  Object notation is explained in
813 L<perlobj>.
814
815 Make sure to read about creating modules in L<perlmod> and
816 the perils of indirect objects in L<perlobj/"Method Invocation">.
817
818 =head2 How can I find out my current or calling package?
819
820 (contributed by brian d foy)
821
822 To find the package you are currently in, use the special literal
823 C<__PACKAGE__>, as documented in L<perldata>. You can only use the
824 special literals as separate tokens, so you can't interpolate them
825 into strings like you can with variables:
826
827         my $current_package = __PACKAGE__;
828         print "I am in package $current_package\n";
829
830 This is different from finding out the package an object is blessed
831 into, which might not be the current package. For that, use C<blessed>
832 from C<Scalar::Util>, part of the Standard Library since Perl 5.8:
833
834         use Scalar::Util qw(blessed);
835         my $object_package = blessed( $object );
836
837 Most of the time, you shouldn't care what package an object is blessed
838 into, however, as long as it claims to inherit from that class:
839
840         my $is_right_class = eval { $object->isa( $package ) }; # true or false
841
842 If you want to find the package calling your code, perhaps to give better
843 diagnostics as C<Carp> does, use the C<caller> built-in:
844
845         sub foo {
846                 my @args = ...;
847                 my( $package, $filename, $line ) = caller;
848
849                 print "I was called from package $package\n";
850                 );
851
852 By default, your program starts in package C<main>, so you should
853 always be in some package unless someone uses the C<package> built-in
854 with no namespace. See the C<package> entry in L<perlfunc> for the
855 details of empty packages.
856
857 =head2 How can I comment out a large block of Perl code?
858
859 (contributed by brian d foy)
860
861 The quick-and-dirty way to comment out more than one line of Perl is
862 to surround those lines with Pod directives. You have to put these
863 directives at the beginning of the line and somewhere where Perl
864 expects a new statement (so not in the middle of statements like the #
865 comments). You end the comment with C<=cut>, ending the Pod section:
866
867         =pod
868
869         my $object = NotGonnaHappen->new();
870
871         ignored_sub();
872
873         $wont_be_assigned = 37;
874
875         =cut
876
877 The quick-and-dirty method only works well when you don't plan to 
878 leave the commented code in the source. If a Pod parser comes along,
879 you're multiline comment is going to show up in the Pod translation.
880 A better way hides it from Pod parsers as well. 
881
882 The C<=begin> directive can mark a section for a particular purpose.
883 If the Pod parser doesn't want to handle it, it just ignores it. Label
884 the comments with C<comment>. End the comment using C<=end> with the
885 same label. You still need the C<=cut> to go back to Perl code from
886 the Pod comment:
887
888         =begin comment
889
890         my $object = NotGonnaHappen->new();
891
892         ignored_sub();
893
894         $wont_be_assigned = 37;
895
896         =end comment
897
898         =cut
899
900 For more information on Pod, check out L<perlpod> and L<perlpodspec>.
901
902 =head2 How do I clear a package?
903
904 Use this code, provided by Mark-Jason Dominus:
905
906         sub scrub_package {
907                 no strict 'refs';
908                 my $pack = shift;
909                 die "Shouldn't delete main package"
910                         if $pack eq "" || $pack eq "main";
911                 my $stash = *{$pack . '::'}{HASH};
912                 my $name;
913                 foreach $name (keys %$stash) {
914                         my $fullname = $pack . '::' . $name;
915                         # Get rid of everything with that name.
916                         undef $$fullname;
917                         undef @$fullname;
918                         undef %$fullname;
919                         undef &$fullname;
920                         undef *$fullname;
921         }
922         }
923
924 Or, if you're using a recent release of Perl, you can
925 just use the Symbol::delete_package() function instead.
926
927 =head2 How can I use a variable as a variable name?
928
929 Beginners often think they want to have a variable contain the name
930 of a variable.
931
932         $fred    = 23;
933         $varname = "fred";
934         ++$$varname;         # $fred now 24
935
936 This works I<sometimes>, but it is a very bad idea for two reasons.
937
938 The first reason is that this technique I<only works on global
939 variables>.  That means that if $fred is a lexical variable created
940 with my() in the above example, the code wouldn't work at all: you'd
941 accidentally access the global and skip right over the private lexical
942 altogether.  Global variables are bad because they can easily collide
943 accidentally and in general make for non-scalable and confusing code.
944
945 Symbolic references are forbidden under the C<use strict> pragma.
946 They are not true references and consequently are not reference counted
947 or garbage collected.
948
949 The other reason why using a variable to hold the name of another
950 variable is a bad idea is that the question often stems from a lack of
951 understanding of Perl data structures, particularly hashes.  By using
952 symbolic references, you are just using the package's symbol-table hash
953 (like C<%main::>) instead of a user-defined hash.  The solution is to
954 use your own hash or a real reference instead.
955
956         $USER_VARS{"fred"} = 23;
957         $varname = "fred";
958         $USER_VARS{$varname}++;  # not $$varname++
959
960 There we're using the %USER_VARS hash instead of symbolic references.
961 Sometimes this comes up in reading strings from the user with variable
962 references and wanting to expand them to the values of your perl
963 program's variables.  This is also a bad idea because it conflates the
964 program-addressable namespace and the user-addressable one.  Instead of
965 reading a string and expanding it to the actual contents of your program's
966 own variables:
967
968         $str = 'this has a $fred and $barney in it';
969         $str =~ s/(\$\w+)/$1/eeg;                 # need double eval
970
971 it would be better to keep a hash around like %USER_VARS and have
972 variable references actually refer to entries in that hash:
973
974         $str =~ s/\$(\w+)/$USER_VARS{$1}/g;   # no /e here at all
975
976 That's faster, cleaner, and safer than the previous approach.  Of course,
977 you don't need to use a dollar sign.  You could use your own scheme to
978 make it less confusing, like bracketed percent symbols, etc.
979
980         $str = 'this has a %fred% and %barney% in it';
981         $str =~ s/%(\w+)%/$USER_VARS{$1}/g;   # no /e here at all
982
983 Another reason that folks sometimes think they want a variable to
984 contain the name of a variable is because they don't know how to build
985 proper data structures using hashes.  For example, let's say they
986 wanted two hashes in their program: %fred and %barney, and that they
987 wanted to use another scalar variable to refer to those by name.
988
989         $name = "fred";
990         $$name{WIFE} = "wilma";     # set %fred
991
992         $name = "barney";
993         $$name{WIFE} = "betty"; # set %barney
994
995 This is still a symbolic reference, and is still saddled with the
996 problems enumerated above.  It would be far better to write:
997
998         $folks{"fred"}{WIFE}   = "wilma";
999         $folks{"barney"}{WIFE} = "betty";
1000
1001 And just use a multilevel hash to start with.
1002
1003 The only times that you absolutely I<must> use symbolic references are
1004 when you really must refer to the symbol table.  This may be because it's
1005 something that can't take a real reference to, such as a format name.
1006 Doing so may also be important for method calls, since these always go
1007 through the symbol table for resolution.
1008
1009 In those cases, you would turn off C<strict 'refs'> temporarily so you
1010 can play around with the symbol table.  For example:
1011
1012         @colors = qw(red blue green yellow orange purple violet);
1013         for my $name (@colors) {
1014                 no strict 'refs';  # renege for the block
1015                 *$name = sub { "<FONT COLOR='$name'>@_</FONT>" };
1016         }
1017
1018 All those functions (red(), blue(), green(), etc.) appear to be separate,
1019 but the real code in the closure actually was compiled only once.
1020
1021 So, sometimes you might want to use symbolic references to directly
1022 manipulate the symbol table.  This doesn't matter for formats, handles, and
1023 subroutines, because they are always global--you can't use my() on them.
1024 For scalars, arrays, and hashes, though--and usually for subroutines--
1025 you probably only want to use hard references.
1026
1027 =head2 What does "bad interpreter" mean?
1028
1029 (contributed by brian d foy)
1030
1031 The "bad interpreter" message comes from the shell, not perl.  The
1032 actual message may vary depending on your platform, shell, and locale
1033 settings.
1034
1035 If you see "bad interpreter - no such file or directory", the first
1036 line in your perl script (the "shebang" line) does not contain the
1037 right path to perl (or any other program capable of running scripts).
1038 Sometimes this happens when you move the script from one machine to
1039 another and each machine has a different path to perl--/usr/bin/perl
1040 versus /usr/local/bin/perl for instance. It may also indicate
1041 that the source machine has CRLF line terminators and the
1042 destination machine has LF only: the shell tries to find
1043 /usr/bin/perl<CR>, but can't.
1044
1045 If you see "bad interpreter: Permission denied", you need to make your
1046 script executable.
1047
1048 In either case, you should still be able to run the scripts with perl
1049 explicitly:
1050
1051         % perl script.pl
1052
1053 If you get a message like "perl: command not found", perl is not in
1054 your PATH, which might also mean that the location of perl is not
1055 where you expect it so you need to adjust your shebang line.
1056
1057 =head1 REVISION
1058
1059 Revision: $Revision$
1060
1061 Date: $Date$
1062
1063 See L<perlfaq> for source control details and availability.
1064
1065 =head1 AUTHOR AND COPYRIGHT
1066
1067 Copyright (c) 1997-2009 Tom Christiansen, Nathan Torkington, and
1068 other authors as noted. All rights reserved.
1069
1070 This documentation is free; you can redistribute it and/or modify it
1071 under the same terms as Perl itself.
1072
1073 Irrespective of its distribution, all code examples in this file
1074 are hereby placed into the public domain.  You are permitted and
1075 encouraged to use this code in your own programs for fun
1076 or for profit as you see fit.  A simple comment in the code giving
1077 credit would be courteous but is not required.
1078