First steps to making corelist.pl understand the new world order
[perl.git] / Porting / corelist.pl
1 #!perl
2 # Generates info for Module::CoreList from this perl tree
3 # run this from the root of a perl tree
4 #
5 # Data is on STDOUT.
6 #
7 # With an optional arg specifying the root of a CPAN mirror, outputs the
8 # %upstream and %bug_tracker hashes too.
9
10 use strict;
11 use warnings;
12 use File::Find;
13 use ExtUtils::MM_Unix;
14 use version;
15 use lib "Porting";
16 use Maintainers qw(%Modules files_to_modules);
17 use File::Spec;
18 use Parse::CPAN::Meta;
19
20 my $corelist_file = 'dist/Module-CoreList/lib/Module/CoreList.pm';
21
22 my %lines;
23 my %module_to_file;
24 my %modlist;
25
26 die "usage: $0 [ cpan-mirror/ ] [ 5.x.y] \n" unless @ARGV <= 2;
27 my $cpan         = shift;
28 my $raw_version  = shift || $];
29 my $perl_version = version->parse("$raw_version");
30 my $perl_vnum    = $perl_version->numify;
31 my $perl_vstring = $perl_version->normal; # how do we get version.pm to not give us leading v?
32 $perl_vstring =~ s/^v//;
33
34 if ( !-f 'MANIFEST' ) {
35     die "Must be run from the root of a clean perl tree\n";
36 }
37
38 open( my $corelist_fh, '<', $corelist_file ) || die "Could not open $corelist_file: $!";
39 my $corelist = join( '', <$corelist_fh> );
40
41 if ($cpan) {
42     my $modlistfile = File::Spec->catfile( $cpan, 'modules', '02packages.details.txt' );
43     my $content;
44
45     my $fh;
46     if ( -e $modlistfile ) {
47         warn "Reading the module list from $modlistfile";
48         open $fh, '<', $modlistfile or die "Couldn't open $modlistfile: $!";
49     } elsif ( -e $modlistfile . ".gz" ) {
50         warn "Reading the module list from $modlistfile.gz";
51         open $fh, '-|', "gzcat $modlistfile.gz" or die "Couldn't zcat $modlistfile.gz: $!";
52     } else {
53         warn "About to fetch 02packages from ftp.funet.fi. This may take a few minutes\n";
54         $content = fetch_url('http://ftp.funet.fi/pub/CPAN/modules/02packages.details.txt');
55         unless ($content) {
56             die "Unable to read 02packages.details.txt from either your CPAN mirror or ftp.funet.fi";
57         }
58     }
59
60     if ( $fh and !$content ) {
61         local $/ = "\n";
62         $content = join( '', <$fh> );
63     }
64
65     die "Incompatible modlist format"
66         unless $content =~ /^Columns: +package name, version, path/m;
67
68     # Converting the file to a hash is about 5 times faster than a regexp flat
69     # lookup.
70     for ( split( qr/\n/, $content ) ) {
71         next unless /^([A-Za-z_:0-9]+) +[-0-9.undefHASHVERSIONvsetwhenloadingbogus]+ +(\S+)/;
72         $modlist{$1} = $2;
73     }
74 }
75
76 find(
77     sub {
78         /(\.pm|_pm\.PL)$/ or return;
79         /PPPort\.pm$/ and return;
80         my $module = $File::Find::name;
81                 warn $module;
82         $module =~ /\b(demo|t|private)\b/ and return;    # demo or test modules
83         my $version = MM->parse_version($_);
84         defined $version or $version = 'undef';
85         $version =~ /\d/ and $version = "'$version'";
86
87         # some heuristics to figure out the module name from the file name
88         $module =~ s{^(lib|dist|(win32/|vms/|symbian/)?ext)/}{}
89             and $1 ne 'lib'
90             and (
91             $module =~ s{\b(\w+)/\1\b}{$1},
92             $module =~ s{^B/O}{O},
93             $module =~ s{^Devel-PPPort}{Devel},
94             $module =~ s{^Encode/encoding}{encoding},
95             $module =~ s{^IPC-SysV/}{IPC/},
96             $module =~ s{^MIME-Base64/QuotedPrint}{MIME/QuotedPrint},
97             $module =~ s{^(?:DynaLoader|Errno|Opcode)/}{},
98             );
99         $module =~ s{/}{::}g;
100         $module =~ s{-}{::}g;
101         $module =~ s{^.*::lib::}{};
102         $module =~ s/(\.pm|_pm\.PL)$//;
103         $lines{$module}          = $version;
104         $module_to_file{$module} = $File::Find::name;
105     },
106     'lib',
107     'ext',
108         'dist',
109     'vms/ext',
110     'symbian/ext'
111 );
112
113 -e 'configpm' and $lines{Config} = 'undef';
114
115 if ( open my $ucdv, "<", "lib/unicore/version" ) {
116     chomp( my $ucd = <$ucdv> );
117     $lines{Unicode} = "'$ucd'";
118     close $ucdv;
119 }
120
121 my $versions_in_release = "    " . $perl_vnum . " => {\n";
122 foreach my $key ( sort keys %lines ) {
123     $versions_in_release .= sprintf "\t%-24s=> %s,\n", "'$key'", $lines{$key};
124 }
125 $versions_in_release .= "    },\n";
126
127 $corelist =~ s/^(%version\s*=\s*.*?)(^\);)$/$1$versions_in_release$2/xism;
128
129 exit unless %modlist;
130
131 # We have to go through this two stage lookup, given how Maintainers.pl keys its
132 # data by "Module", which is really a dist.
133 my $file_to_M = files_to_modules( values %module_to_file );
134
135 my %module_to_upstream;
136 my %module_to_dist;
137 my %dist_to_meta_YAML;
138 while ( my ( $module, $file ) = each %module_to_file ) {
139     my $M = $file_to_M->{$file};
140     next unless $M;
141     next if $Modules{$M}{MAINTAINER} eq 'p5p';
142     $module_to_upstream{$module} = $Modules{$M}{UPSTREAM};
143     next
144         if defined $module_to_upstream{$module}
145             && $module_to_upstream{$module} =~ /^(?:blead|first-come)$/;
146     my $dist = $modlist{$module};
147     unless ($dist) {
148         warn "Can't find a distribution for $module\n";
149         next;
150     }
151     $module_to_dist{$module} = $dist;
152
153     next if exists $dist_to_meta_YAML{$dist};
154
155     $dist_to_meta_YAML{$dist} = undef;
156
157     # Like it or lump it, this has to be Unix format.
158     my $meta_YAML_path = "authors/id/$dist";
159     $meta_YAML_path =~ s/(?:tar\.gz|zip)$/meta/ or die "$meta_YAML_path";
160     my $meta_YAML_url = 'http://ftp.funet.fi/pub/CPAN/' . $meta_YAML_path;
161
162     if ( -e "$cpan/$meta_YAML_path" ) {
163         $dist_to_meta_YAML{$dist} = Parse::CPAN::Meta::LoadFile( $cpan . "/" . $meta_YAML_path );
164     } elsif ( my $content = fetch_url($meta_YAML_url) ) {
165         unless ($content) {
166             warn "Failed to fetch $meta_YAML_url\n";
167             next;
168         }
169         eval { $dist_to_meta_YAML{$dist} = Parse::CPAN::Meta::Load($content); };
170         if ( my $err = $@ ) {
171             warn "$meta_YAML_path: ".$err;
172             next;
173         }
174     } else {
175         warn "$meta_YAML_path does not exist for $module\n";
176
177         # I tried code to open the tarballs with Archive::Tar to find and
178         # extract META.yml, but only Text-Tabs+Wrap-2006.1117.tar.gz had one,
179         # so it's not worth including.
180         next;
181     }
182 }
183
184 my $upstream_stanza = "%upstream = (\n";
185 foreach my $module ( sort keys %module_to_upstream ) {
186     my $upstream = defined $module_to_upstream{$module} ? "'$module_to_upstream{$module}'" : 'undef';
187     $upstream_stanza .= sprintf "    %-24s=> %s,\n", "'$module'", $upstream;
188 }
189 $upstream_stanza .= ");";
190
191 $corelist =~ s/^%upstream .*? ;$/$upstream_stanza/ismx;
192
193 my $tracker = "%bug_tracker = (\n";
194 foreach my $module ( sort keys %module_to_upstream ) {
195     my $upstream = defined $module_to_upstream{$module};
196     next
197         if defined $upstream
198             and $upstream eq 'blead' || $upstream eq 'first-come';
199
200     my $bug_tracker;
201
202     my $dist = $module_to_dist{$module};
203     $bug_tracker = $dist_to_meta_YAML{$dist}->{resources}{bugtracker}
204         if $dist;
205
206     $bug_tracker = defined $bug_tracker ? "'$bug_tracker'" : 'undef';
207     next if $bug_tracker eq "'http://rt.perl.org/perlbug/'";
208     $tracker .= sprintf "    %-24s=> %s,\n", "'$module'", $bug_tracker;
209 }
210 $tracker .= ");";
211
212 $corelist =~ s/^%bug_tracker .*? ;/$tracker/eismx;
213
214 unless ( $corelist =~ /and $perl_vstring releases of perl/ ) {
215     warn "Adding $perl_vstring to the list of perl versions covered by Module::CoreList\n";
216     $corelist =~ s/\s*and (.*?) releases of perl/, $1 and $perl_vstring releases of perl/ism;
217 }
218
219 unless (
220     $corelist =~ /^%released \s* = \s* \( 
221         .*? 
222         $perl_vnum => .*? 
223         \);/ismx
224     )
225 {
226     warn "Adding $perl_vnum to the list of released perl versions. Please consider adding a release date.\n";
227     $corelist =~ s/^(%released \s* = \s* .*?) ( \) )
228                 /$1 $perl_vnum => '????-??-??',\n  $2/ismx;
229 }
230
231 write_corelist($corelist);
232
233 warn "All done. Please check over $corelist_file carefully before committing. Thanks!\n";
234
235
236 sub write_corelist {
237     my $content = shift;
238     open (my $clfh, ">", $corelist_file) || die "Failed to open $corelist_file for writing: $!";
239     print $clfh $content || die "Failed to write the new CoreList.pm: $!";
240     close($clfh);
241 }
242
243 sub fetch_url {
244     my $url = shift;
245     eval { require LWP::Simple };
246     if ( LWP::Simple->can('get') ) {
247         return LWP::Simple->get($url);
248     } elsif (`which curl`) {
249         return `curl -s $url`;
250     } elsif (`which wget`) {
251         return `wget -q -O - $url`;
252     }
253 }