perlfunc: sort no longer dies on undef retval
[perl.git] / pod / perlfunc.pod
1 =head1 NAME
2 X<function>
3
4 perlfunc - Perl builtin functions
5
6 =head1 DESCRIPTION
7
8 The functions in this section can serve as terms in an expression.
9 They fall into two major categories: list operators and named unary
10 operators.  These differ in their precedence relationship with a
11 following comma.  (See the precedence table in L<perlop>.)  List
12 operators take more than one argument, while unary operators can never
13 take more than one argument.  Thus, a comma terminates the argument of
14 a unary operator, but merely separates the arguments of a list
15 operator.  A unary operator generally provides scalar context to its
16 argument, while a list operator may provide either scalar or list
17 contexts for its arguments.  If it does both, scalar arguments 
18 come first and list argument follow, and there can only ever
19 be one such list argument.  For instance, splice() has three scalar
20 arguments followed by a list, whereas gethostbyname() has four scalar
21 arguments.
22
23 In the syntax descriptions that follow, list operators that expect a
24 list (and provide list context for elements of the list) are shown
25 with LIST as an argument.  Such a list may consist of any combination
26 of scalar arguments or list values; the list values will be included
27 in the list as if each individual element were interpolated at that
28 point in the list, forming a longer single-dimensional list value.
29 Commas should separate literal elements of the LIST.
30
31 Any function in the list below may be used either with or without
32 parentheses around its arguments.  (The syntax descriptions omit the
33 parentheses.)  If you use parentheses, the simple but occasionally 
34 surprising rule is this: It I<looks> like a function, therefore it I<is> a
35 function, and precedence doesn't matter.  Otherwise it's a list
36 operator or unary operator, and precedence does matter.  Whitespace
37 between the function and left parenthesis doesn't count, so sometimes
38 you need to be careful:
39
40     print 1+2+4;      # Prints 7.
41     print(1+2) + 4;   # Prints 3.
42     print (1+2)+4;    # Also prints 3!
43     print +(1+2)+4;   # Prints 7.
44     print ((1+2)+4);  # Prints 7.
45
46 If you run Perl with the B<-w> switch it can warn you about this.  For
47 example, the third line above produces:
48
49     print (...) interpreted as function at - line 1.
50     Useless use of integer addition in void context at - line 1.
51
52 A few functions take no arguments at all, and therefore work as neither
53 unary nor list operators.  These include such functions as C<time>
54 and C<endpwent>.  For example, C<time+86_400> always means
55 C<time() + 86_400>.
56
57 For functions that can be used in either a scalar or list context,
58 nonabortive failure is generally indicated in scalar context by
59 returning the undefined value, and in list context by returning the
60 empty list.
61
62 Remember the following important rule: There is B<no rule> that relates
63 the behavior of an expression in list context to its behavior in scalar
64 context, or vice versa.  It might do two totally different things.
65 Each operator and function decides which sort of value would be most
66 appropriate to return in scalar context.  Some operators return the
67 length of the list that would have been returned in list context.  Some
68 operators return the first value in the list.  Some operators return the
69 last value in the list.  Some operators return a count of successful
70 operations.  In general, they do what you want, unless you want
71 consistency.
72 X<context>
73
74 A named array in scalar context is quite different from what would at
75 first glance appear to be a list in scalar context.  You can't get a list
76 like C<(1,2,3)> into being in scalar context, because the compiler knows
77 the context at compile time.  It would generate the scalar comma operator
78 there, not the list construction version of the comma.  That means it
79 was never a list to start with.
80
81 In general, functions in Perl that serve as wrappers for system calls ("syscalls")
82 of the same name (like chown(2), fork(2), closedir(2), etc.) return
83 true when they succeed and C<undef> otherwise, as is usually mentioned
84 in the descriptions below.  This is different from the C interfaces,
85 which return C<-1> on failure.  Exceptions to this rule include C<wait>,
86 C<waitpid>, and C<syscall>.  System calls also set the special C<$!>
87 variable on failure.  Other functions do not, except accidentally.
88
89 Extension modules can also hook into the Perl parser to define new
90 kinds of keyword-headed expression.  These may look like functions, but
91 may also look completely different.  The syntax following the keyword
92 is defined entirely by the extension.  If you are an implementor, see
93 L<perlapi/PL_keyword_plugin> for the mechanism.  If you are using such
94 a module, see the module's documentation for details of the syntax that
95 it defines.
96
97 =head2 Perl Functions by Category
98 X<function>
99
100 Here are Perl's functions (including things that look like
101 functions, like some keywords and named operators)
102 arranged by category.  Some functions appear in more
103 than one place.
104
105 =over 4
106
107 =item Functions for SCALARs or strings
108 X<scalar> X<string> X<character>
109
110 C<chomp>, C<chop>, C<chr>, C<crypt>, C<hex>, C<index>, C<lc>, C<lcfirst>,
111 C<length>, C<oct>, C<ord>, C<pack>, C<q//>, C<qq//>, C<reverse>,
112 C<rindex>, C<sprintf>, C<substr>, C<tr///>, C<uc>, C<ucfirst>, C<y///>
113
114 =item Regular expressions and pattern matching
115 X<regular expression> X<regex> X<regexp>
116
117 C<m//>, C<pos>, C<quotemeta>, C<s///>, C<split>, C<study>, C<qr//>
118
119 =item Numeric functions
120 X<numeric> X<number> X<trigonometric> X<trigonometry>
121
122 C<abs>, C<atan2>, C<cos>, C<exp>, C<hex>, C<int>, C<log>, C<oct>, C<rand>,
123 C<sin>, C<sqrt>, C<srand>
124
125 =item Functions for real @ARRAYs
126 X<array>
127
128 C<each>, C<keys>, C<pop>, C<push>, C<shift>, C<splice>, C<unshift>, C<values>
129
130 =item Functions for list data
131 X<list>
132
133 C<grep>, C<join>, C<map>, C<qw//>, C<reverse>, C<sort>, C<unpack>
134
135 =item Functions for real %HASHes
136 X<hash>
137
138 C<delete>, C<each>, C<exists>, C<keys>, C<values>
139
140 =item Input and output functions
141 X<I/O> X<input> X<output> X<dbm>
142
143 C<binmode>, C<close>, C<closedir>, C<dbmclose>, C<dbmopen>, C<die>, C<eof>,
144 C<fileno>, C<flock>, C<format>, C<getc>, C<print>, C<printf>, C<read>,
145 C<readdir>, C<rewinddir>, C<say>, C<seek>, C<seekdir>, C<select>, C<syscall>,
146 C<sysread>, C<sysseek>, C<syswrite>, C<tell>, C<telldir>, C<truncate>,
147 C<warn>, C<write>
148
149 =item Functions for fixed-length data or records
150
151 C<pack>, C<read>, C<syscall>, C<sysread>, C<syswrite>, C<unpack>, C<vec>
152
153 =item Functions for filehandles, files, or directories
154 X<file> X<filehandle> X<directory> X<pipe> X<link> X<symlink>
155
156 C<-I<X>>, C<chdir>, C<chmod>, C<chown>, C<chroot>, C<fcntl>, C<glob>,
157 C<ioctl>, C<link>, C<lstat>, C<mkdir>, C<open>, C<opendir>,
158 C<readlink>, C<rename>, C<rmdir>, C<stat>, C<symlink>, C<sysopen>,
159 C<umask>, C<unlink>, C<utime>
160
161 =item Keywords related to the control flow of your Perl program
162 X<control flow>
163
164 C<caller>, C<continue>, C<die>, C<do>, C<dump>, C<eval>, C<exit>,
165 C<__FILE__>, C<goto>, C<last>, C<__LINE__>, C<next>, C<__PACKAGE__>,
166 C<redo>, C<return>, C<sub>, C<wantarray>,
167
168 =item Keywords related to the switch feature
169
170 C<break>, C<continue>, C<default>, C<given>, C<when>
171
172 Except for C<continue>, these are available only if you enable the
173 C<"switch"> feature or use the C<CORE::> prefix.
174 See L<feature> and L<perlsyn/"Switch statements">.  
175 Alternately, include a C<use v5.10> or later to the current scope.  In Perl
176 5.14 and earlier, C<continue> required the C<"switch"> feature, like the
177 other keywords.
178
179 =item Keywords related to scoping
180
181 C<caller>, C<import>, C<local>, C<my>, C<our>, C<package>, C<state>, C<use>
182
183 C<state> is available only if the C<"state"> feature
184 is enabled or if it is prefixed with C<CORE::>. See
185 L<feature>.  Alternately, include a C<use v5.10> or later to the current scope.
186
187 =item Miscellaneous functions
188
189 C<defined>, C<dump>, C<eval>, C<formline>, C<local>, C<my>, C<our>,
190 C<reset>, C<scalar>, C<state>, C<undef>, C<wantarray>
191
192 =item Functions for processes and process groups
193 X<process> X<pid> X<process id>
194
195 C<alarm>, C<exec>, C<fork>, C<getpgrp>, C<getppid>, C<getpriority>, C<kill>,
196 C<pipe>, C<qx//>, C<setpgrp>, C<setpriority>, C<sleep>, C<system>,
197 C<times>, C<wait>, C<waitpid>
198
199 =item Keywords related to Perl modules
200 X<module>
201
202 C<do>, C<import>, C<no>, C<package>, C<require>, C<use>
203
204 =item Keywords related to classes and object-orientation
205 X<object> X<class> X<package>
206
207 C<bless>, C<dbmclose>, C<dbmopen>, C<package>, C<ref>, C<tie>, C<tied>,
208 C<untie>, C<use>
209
210 =item Low-level socket functions
211 X<socket> X<sock>
212
213 C<accept>, C<bind>, C<connect>, C<getpeername>, C<getsockname>,
214 C<getsockopt>, C<listen>, C<recv>, C<send>, C<setsockopt>, C<shutdown>,
215 C<socket>, C<socketpair>
216
217 =item System V interprocess communication functions
218 X<IPC> X<System V> X<semaphore> X<shared memory> X<memory> X<message>
219
220 C<msgctl>, C<msgget>, C<msgrcv>, C<msgsnd>, C<semctl>, C<semget>, C<semop>,
221 C<shmctl>, C<shmget>, C<shmread>, C<shmwrite>
222
223 =item Fetching user and group info
224 X<user> X<group> X<password> X<uid> X<gid>  X<passwd> X</etc/passwd>
225
226 C<endgrent>, C<endhostent>, C<endnetent>, C<endpwent>, C<getgrent>,
227 C<getgrgid>, C<getgrnam>, C<getlogin>, C<getpwent>, C<getpwnam>,
228 C<getpwuid>, C<setgrent>, C<setpwent>
229
230 =item Fetching network info
231 X<network> X<protocol> X<host> X<hostname> X<IP> X<address> X<service>
232
233 C<endprotoent>, C<endservent>, C<gethostbyaddr>, C<gethostbyname>,
234 C<gethostent>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
235 C<getprotobyname>, C<getprotobynumber>, C<getprotoent>,
236 C<getservbyname>, C<getservbyport>, C<getservent>, C<sethostent>,
237 C<setnetent>, C<setprotoent>, C<setservent>
238
239 =item Time-related functions
240 X<time> X<date>
241
242 C<gmtime>, C<localtime>, C<time>, C<times>
243
244 =item Functions new in perl5
245 X<perl5>
246
247 C<abs>, C<bless>, C<break>, C<chomp>, C<chr>, C<continue>, C<default>, 
248 C<exists>, C<formline>, C<given>, C<glob>, C<import>, C<lc>, C<lcfirst>,
249 C<lock>, C<map>, C<my>, C<no>, C<our>, C<prototype>, C<qr//>, C<qw//>, C<qx//>,
250 C<readline>, C<readpipe>, C<ref>, C<sub>*, C<sysopen>, C<tie>, C<tied>, C<uc>,
251 C<ucfirst>, C<untie>, C<use>, C<when>
252
253 * C<sub> was a keyword in Perl 4, but in Perl 5 it is an
254 operator, which can be used in expressions.
255
256 =item Functions obsoleted in perl5
257
258 C<dbmclose>, C<dbmopen>
259
260 =back
261
262 =head2 Portability
263 X<portability> X<Unix> X<portable>
264
265 Perl was born in Unix and can therefore access all common Unix
266 system calls.  In non-Unix environments, the functionality of some
267 Unix system calls may not be available or details of the available
268 functionality may differ slightly.  The Perl functions affected
269 by this are:
270
271 C<-X>, C<binmode>, C<chmod>, C<chown>, C<chroot>, C<crypt>,
272 C<dbmclose>, C<dbmopen>, C<dump>, C<endgrent>, C<endhostent>,
273 C<endnetent>, C<endprotoent>, C<endpwent>, C<endservent>, C<exec>,
274 C<fcntl>, C<flock>, C<fork>, C<getgrent>, C<getgrgid>, C<gethostbyname>,
275 C<gethostent>, C<getlogin>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
276 C<getppid>, C<getpgrp>, C<getpriority>, C<getprotobynumber>,
277 C<getprotoent>, C<getpwent>, C<getpwnam>, C<getpwuid>,
278 C<getservbyport>, C<getservent>, C<getsockopt>, C<glob>, C<ioctl>,
279 C<kill>, C<link>, C<lstat>, C<msgctl>, C<msgget>, C<msgrcv>,
280 C<msgsnd>, C<open>, C<pipe>, C<readlink>, C<rename>, C<select>, C<semctl>,
281 C<semget>, C<semop>, C<setgrent>, C<sethostent>, C<setnetent>,
282 C<setpgrp>, C<setpriority>, C<setprotoent>, C<setpwent>,
283 C<setservent>, C<setsockopt>, C<shmctl>, C<shmget>, C<shmread>,
284 C<shmwrite>, C<socket>, C<socketpair>,
285 C<stat>, C<symlink>, C<syscall>, C<sysopen>, C<system>,
286 C<times>, C<truncate>, C<umask>, C<unlink>,
287 C<utime>, C<wait>, C<waitpid>
288
289 For more information about the portability of these functions, see
290 L<perlport> and other available platform-specific documentation.
291
292 =head2 Alphabetical Listing of Perl Functions
293
294 =over 
295
296 =item -X FILEHANDLE
297 X<-r>X<-w>X<-x>X<-o>X<-R>X<-W>X<-X>X<-O>X<-e>X<-z>X<-s>X<-f>X<-d>X<-l>X<-p>
298 X<-S>X<-b>X<-c>X<-t>X<-u>X<-g>X<-k>X<-T>X<-B>X<-M>X<-A>X<-C>
299
300 =item -X EXPR
301
302 =item -X DIRHANDLE
303
304 =item -X
305
306 A file test, where X is one of the letters listed below.  This unary
307 operator takes one argument, either a filename, a filehandle, or a dirhandle, 
308 and tests the associated file to see if something is true about it.  If the
309 argument is omitted, tests C<$_>, except for C<-t>, which tests STDIN.
310 Unless otherwise documented, it returns C<1> for true and C<''> for false, or
311 the undefined value if the file doesn't exist.  Despite the funny
312 names, precedence is the same as any other named unary operator.  The
313 operator may be any of:
314
315     -r  File is readable by effective uid/gid.
316     -w  File is writable by effective uid/gid.
317     -x  File is executable by effective uid/gid.
318     -o  File is owned by effective uid.
319
320     -R  File is readable by real uid/gid.
321     -W  File is writable by real uid/gid.
322     -X  File is executable by real uid/gid.
323     -O  File is owned by real uid.
324
325     -e  File exists.
326     -z  File has zero size (is empty).
327     -s  File has nonzero size (returns size in bytes).
328
329     -f  File is a plain file.
330     -d  File is a directory.
331     -l  File is a symbolic link.
332     -p  File is a named pipe (FIFO), or Filehandle is a pipe.
333     -S  File is a socket.
334     -b  File is a block special file.
335     -c  File is a character special file.
336     -t  Filehandle is opened to a tty.
337
338     -u  File has setuid bit set.
339     -g  File has setgid bit set.
340     -k  File has sticky bit set.
341
342     -T  File is an ASCII text file (heuristic guess).
343     -B  File is a "binary" file (opposite of -T).
344
345     -M  Script start time minus file modification time, in days.
346     -A  Same for access time.
347     -C  Same for inode change time (Unix, may differ for other platforms)
348
349 Example:
350
351     while (<>) {
352         chomp;
353         next unless -f $_;  # ignore specials
354         #...
355     }
356
357 Note that C<-s/a/b/> does not do a negated substitution.  Saying
358 C<-exp($foo)> still works as expected, however: only single letters
359 following a minus are interpreted as file tests.
360
361 These operators are exempt from the "looks like a function rule" described
362 above.  That is, an opening parenthesis after the operator does not affect
363 how much of the following code constitutes the argument.  Put the opening
364 parentheses before the operator to separate it from code that follows (this
365 applies only to operators with higher precedence than unary operators, of
366 course):
367
368     -s($file) + 1024   # probably wrong; same as -s($file + 1024)
369     (-s $file) + 1024  # correct
370
371 The interpretation of the file permission operators C<-r>, C<-R>,
372 C<-w>, C<-W>, C<-x>, and C<-X> is by default based solely on the mode
373 of the file and the uids and gids of the user.  There may be other
374 reasons you can't actually read, write, or execute the file: for
375 example network filesystem access controls, ACLs (access control lists),
376 read-only filesystems, and unrecognized executable formats.  Note
377 that the use of these six specific operators to verify if some operation
378 is possible is usually a mistake, because it may be open to race
379 conditions.
380
381 Also note that, for the superuser on the local filesystems, the C<-r>,
382 C<-R>, C<-w>, and C<-W> tests always return 1, and C<-x> and C<-X> return 1
383 if any execute bit is set in the mode.  Scripts run by the superuser
384 may thus need to do a stat() to determine the actual mode of the file,
385 or temporarily set their effective uid to something else.
386
387 If you are using ACLs, there is a pragma called C<filetest> that may
388 produce more accurate results than the bare stat() mode bits.
389 When under C<use filetest 'access'> the above-mentioned filetests
390 test whether the permission can(not) be granted using the
391 access(2) family of system calls.  Also note that the C<-x> and C<-X> may
392 under this pragma return true even if there are no execute permission
393 bits set (nor any extra execute permission ACLs).  This strangeness is
394 due to the underlying system calls' definitions. Note also that, due to
395 the implementation of C<use filetest 'access'>, the C<_> special
396 filehandle won't cache the results of the file tests when this pragma is
397 in effect.  Read the documentation for the C<filetest> pragma for more
398 information.
399
400 The C<-T> and C<-B> switches work as follows.  The first block or so of the
401 file is examined for odd characters such as strange control codes or
402 characters with the high bit set.  If too many strange characters (>30%)
403 are found, it's a C<-B> file; otherwise it's a C<-T> file.  Also, any file
404 containing a zero byte in the first block is considered a binary file.  If C<-T>
405 or C<-B> is used on a filehandle, the current IO buffer is examined
406 rather than the first block.  Both C<-T> and C<-B> return true on an empty
407 file, or a file at EOF when testing a filehandle.  Because you have to
408 read a file to do the C<-T> test, on most occasions you want to use a C<-f>
409 against the file first, as in C<next unless -f $file && -T $file>.
410
411 If any of the file tests (or either the C<stat> or C<lstat> operator) is given
412 the special filehandle consisting of a solitary underline, then the stat
413 structure of the previous file test (or stat operator) is used, saving
414 a system call.  (This doesn't work with C<-t>, and you need to remember
415 that lstat() and C<-l> leave values in the stat structure for the
416 symbolic link, not the real file.)  (Also, if the stat buffer was filled by
417 an C<lstat> call, C<-T> and C<-B> will reset it with the results of C<stat _>).
418 Example:
419
420     print "Can do.\n" if -r $a || -w _ || -x _;
421
422     stat($filename);
423     print "Readable\n" if -r _;
424     print "Writable\n" if -w _;
425     print "Executable\n" if -x _;
426     print "Setuid\n" if -u _;
427     print "Setgid\n" if -g _;
428     print "Sticky\n" if -k _;
429     print "Text\n" if -T _;
430     print "Binary\n" if -B _;
431
432 As of Perl 5.9.1, as a form of purely syntactic sugar, you can stack file
433 test operators, in a way that C<-f -w -x $file> is equivalent to
434 C<-x $file && -w _ && -f _>. (This is only fancy fancy: if you use
435 the return value of C<-f $file> as an argument to another filetest
436 operator, no special magic will happen.)
437
438 Portability issues: L<perlport/-X>.
439
440 =item abs VALUE
441 X<abs> X<absolute>
442
443 =item abs
444
445 Returns the absolute value of its argument.
446 If VALUE is omitted, uses C<$_>.
447
448 =item accept NEWSOCKET,GENERICSOCKET
449 X<accept>
450
451 Accepts an incoming socket connect, just as accept(2) 
452 does.  Returns the packed address if it succeeded, false otherwise.
453 See the example in L<perlipc/"Sockets: Client/Server Communication">.
454
455 On systems that support a close-on-exec flag on files, the flag will
456 be set for the newly opened file descriptor, as determined by the
457 value of $^F.  See L<perlvar/$^F>.
458
459 =item alarm SECONDS
460 X<alarm>
461 X<SIGALRM>
462 X<timer>
463
464 =item alarm
465
466 Arranges to have a SIGALRM delivered to this process after the
467 specified number of wallclock seconds has elapsed.  If SECONDS is not
468 specified, the value stored in C<$_> is used. (On some machines,
469 unfortunately, the elapsed time may be up to one second less or more
470 than you specified because of how seconds are counted, and process
471 scheduling may delay the delivery of the signal even further.)
472
473 Only one timer may be counting at once.  Each call disables the
474 previous timer, and an argument of C<0> may be supplied to cancel the
475 previous timer without starting a new one.  The returned value is the
476 amount of time remaining on the previous timer.
477
478 For delays of finer granularity than one second, the Time::HiRes module
479 (from CPAN, and starting from Perl 5.8 part of the standard
480 distribution) provides ualarm().  You may also use Perl's four-argument
481 version of select() leaving the first three arguments undefined, or you
482 might be able to use the C<syscall> interface to access setitimer(2) if
483 your system supports it. See L<perlfaq8> for details.
484
485 It is usually a mistake to intermix C<alarm> and C<sleep> calls, because
486 C<sleep> may be internally implemented on your system with C<alarm>.
487
488 If you want to use C<alarm> to time out a system call you need to use an
489 C<eval>/C<die> pair.  You can't rely on the alarm causing the system call to
490 fail with C<$!> set to C<EINTR> because Perl sets up signal handlers to
491 restart system calls on some systems.  Using C<eval>/C<die> always works,
492 modulo the caveats given in L<perlipc/"Signals">.
493
494     eval {
495         local $SIG{ALRM} = sub { die "alarm\n" }; # NB: \n required
496         alarm $timeout;
497         $nread = sysread SOCKET, $buffer, $size;
498         alarm 0;
499     };
500     if ($@) {
501         die unless $@ eq "alarm\n";   # propagate unexpected errors
502         # timed out
503     }
504     else {
505         # didn't
506     }
507
508 For more information see L<perlipc>.
509
510 Portability issues: L<perlport/alarm>.
511
512 =item atan2 Y,X
513 X<atan2> X<arctangent> X<tan> X<tangent>
514
515 Returns the arctangent of Y/X in the range -PI to PI.
516
517 For the tangent operation, you may use the C<Math::Trig::tan>
518 function, or use the familiar relation:
519
520     sub tan { sin($_[0]) / cos($_[0])  }
521
522 The return value for C<atan2(0,0)> is implementation-defined; consult
523 your atan2(3) manpage for more information.
524
525 Portability issues: L<perlport/atan2>.
526
527 =item bind SOCKET,NAME
528 X<bind>
529
530 Binds a network address to a socket, just as bind(2)
531 does.  Returns true if it succeeded, false otherwise.  NAME should be a
532 packed address of the appropriate type for the socket.  See the examples in
533 L<perlipc/"Sockets: Client/Server Communication">.
534
535 =item binmode FILEHANDLE, LAYER
536 X<binmode> X<binary> X<text> X<DOS> X<Windows>
537
538 =item binmode FILEHANDLE
539
540 Arranges for FILEHANDLE to be read or written in "binary" or "text"
541 mode on systems where the run-time libraries distinguish between
542 binary and text files.  If FILEHANDLE is an expression, the value is
543 taken as the name of the filehandle.  Returns true on success,
544 otherwise it returns C<undef> and sets C<$!> (errno).
545
546 On some systems (in general, DOS- and Windows-based systems) binmode()
547 is necessary when you're not working with a text file.  For the sake
548 of portability it is a good idea always to use it when appropriate,
549 and never to use it when it isn't appropriate.  Also, people can
550 set their I/O to be by default UTF8-encoded Unicode, not bytes.
551
552 In other words: regardless of platform, use binmode() on binary data,
553 like images, for example.
554
555 If LAYER is present it is a single string, but may contain multiple
556 directives. The directives alter the behaviour of the filehandle.
557 When LAYER is present, using binmode on a text file makes sense.
558
559 If LAYER is omitted or specified as C<:raw> the filehandle is made
560 suitable for passing binary data. This includes turning off possible CRLF
561 translation and marking it as bytes (as opposed to Unicode characters).
562 Note that, despite what may be implied in I<"Programming Perl"> (the
563 Camel, 3rd edition) or elsewhere, C<:raw> is I<not> simply the inverse of C<:crlf>.
564 Other layers that would affect the binary nature of the stream are
565 I<also> disabled. See L<PerlIO>, L<perlrun>, and the discussion about the
566 PERLIO environment variable.
567
568 The C<:bytes>, C<:crlf>, C<:utf8>, and any other directives of the
569 form C<:...>, are called I/O I<layers>.  The C<open> pragma can be used to
570 establish default I/O layers.  See L<open>.
571
572 I<The LAYER parameter of the binmode() function is described as "DISCIPLINE"
573 in "Programming Perl, 3rd Edition".  However, since the publishing of this
574 book, by many known as "Camel III", the consensus of the naming of this
575 functionality has moved from "discipline" to "layer".  All documentation
576 of this version of Perl therefore refers to "layers" rather than to
577 "disciplines".  Now back to the regularly scheduled documentation...>
578
579 To mark FILEHANDLE as UTF-8, use C<:utf8> or C<:encoding(UTF-8)>.
580 C<:utf8> just marks the data as UTF-8 without further checking,
581 while C<:encoding(UTF-8)> checks the data for actually being valid
582 UTF-8. More details can be found in L<PerlIO::encoding>.
583
584 In general, binmode() should be called after open() but before any I/O
585 is done on the filehandle.  Calling binmode() normally flushes any
586 pending buffered output data (and perhaps pending input data) on the
587 handle.  An exception to this is the C<:encoding> layer that
588 changes the default character encoding of the handle; see L</open>.
589 The C<:encoding> layer sometimes needs to be called in
590 mid-stream, and it doesn't flush the stream.  The C<:encoding>
591 also implicitly pushes on top of itself the C<:utf8> layer because
592 internally Perl operates on UTF8-encoded Unicode characters.
593
594 The operating system, device drivers, C libraries, and Perl run-time
595 system all conspire to let the programmer treat a single
596 character (C<\n>) as the line terminator, irrespective of external
597 representation.  On many operating systems, the native text file
598 representation matches the internal representation, but on some
599 platforms the external representation of C<\n> is made up of more than
600 one character.
601
602 All variants of Unix, Mac OS (old and new), and Stream_LF files on VMS use
603 a single character to end each line in the external representation of text
604 (even though that single character is CARRIAGE RETURN on old, pre-Darwin
605 flavors of Mac OS, and is LINE FEED on Unix and most VMS files). In other
606 systems like OS/2, DOS, and the various flavors of MS-Windows, your program
607 sees a C<\n> as a simple C<\cJ>, but what's stored in text files are the
608 two characters C<\cM\cJ>.  That means that if you don't use binmode() on
609 these systems, C<\cM\cJ> sequences on disk will be converted to C<\n> on
610 input, and any C<\n> in your program will be converted back to C<\cM\cJ> on
611 output.  This is what you want for text files, but it can be disastrous for
612 binary files.
613
614 Another consequence of using binmode() (on some systems) is that
615 special end-of-file markers will be seen as part of the data stream.
616 For systems from the Microsoft family this means that, if your binary
617 data contain C<\cZ>, the I/O subsystem will regard it as the end of
618 the file, unless you use binmode().
619
620 binmode() is important not only for readline() and print() operations,
621 but also when using read(), seek(), sysread(), syswrite() and tell()
622 (see L<perlport> for more details).  See the C<$/> and C<$\> variables
623 in L<perlvar> for how to manually set your input and output
624 line-termination sequences.
625
626 Portability issues: L<perlport/binmode>.
627
628 =item bless REF,CLASSNAME
629 X<bless>
630
631 =item bless REF
632
633 This function tells the thingy referenced by REF that it is now an object
634 in the CLASSNAME package.  If CLASSNAME is omitted, the current package
635 is used.  Because a C<bless> is often the last thing in a constructor,
636 it returns the reference for convenience.  Always use the two-argument
637 version if a derived class might inherit the function doing the blessing.
638 SeeL<perlobj> for more about the blessing (and blessings) of objects.
639
640 Consider always blessing objects in CLASSNAMEs that are mixed case.
641 Namespaces with all lowercase names are considered reserved for
642 Perl pragmata.  Builtin types have all uppercase names. To prevent
643 confusion, you may wish to avoid such package names as well.  Make sure
644 that CLASSNAME is a true value.
645
646 See L<perlmod/"Perl Modules">.
647
648 =item break
649
650 Break out of a C<given()> block.
651
652 This keyword is enabled by the C<"switch"> feature: see
653 L<feature> for more information.  You can also access it by
654 prefixing it with C<CORE::>.  Alternately, include a C<use
655 v5.10> or later to the current scope.
656
657 =item caller EXPR
658 X<caller> X<call stack> X<stack> X<stack trace>
659
660 =item caller
661
662 Returns the context of the current subroutine call.  In scalar context,
663 returns the caller's package name if there I<is> a caller (that is, if
664 we're in a subroutine or C<eval> or C<require>) and the undefined value
665 otherwise.  In list context, returns
666
667     # 0         1          2
668     ($package, $filename, $line) = caller;
669
670 With EXPR, it returns some extra information that the debugger uses to
671 print a stack trace.  The value of EXPR indicates how many call frames
672 to go back before the current one.
673
674     #  0         1          2      3            4
675     ($package, $filename, $line, $subroutine, $hasargs,
676
677     #  5          6          7            8       9         10
678     $wantarray, $evaltext, $is_require, $hints, $bitmask, $hinthash)
679      = caller($i);
680
681 Here $subroutine may be C<(eval)> if the frame is not a subroutine
682 call, but an C<eval>.  In such a case additional elements $evaltext and
683 C<$is_require> are set: C<$is_require> is true if the frame is created by a
684 C<require> or C<use> statement, $evaltext contains the text of the
685 C<eval EXPR> statement.  In particular, for an C<eval BLOCK> statement,
686 $subroutine is C<(eval)>, but $evaltext is undefined.  (Note also that
687 each C<use> statement creates a C<require> frame inside an C<eval EXPR>
688 frame.)  $subroutine may also be C<(unknown)> if this particular
689 subroutine happens to have been deleted from the symbol table.
690 C<$hasargs> is true if a new instance of C<@_> was set up for the frame.
691 C<$hints> and C<$bitmask> contain pragmatic hints that the caller was
692 compiled with.  The C<$hints> and C<$bitmask> values are subject to change
693 between versions of Perl, and are not meant for external use.
694
695 C<$hinthash> is a reference to a hash containing the value of C<%^H> when the
696 caller was compiled, or C<undef> if C<%^H> was empty. Do not modify the values
697 of this hash, as they are the actual values stored in the optree.
698
699 Furthermore, when called from within the DB package, caller returns more
700 detailed information: it sets the list variable C<@DB::args> to be the
701 arguments with which the subroutine was invoked.
702
703 Be aware that the optimizer might have optimized call frames away before
704 C<caller> had a chance to get the information.  That means that C<caller(N)>
705 might not return information about the call frame you expect it to, for
706 C<< N > 1 >>.  In particular, C<@DB::args> might have information from the
707 previous time C<caller> was called.
708
709 Be aware that setting C<@DB::args> is I<best effort>, intended for
710 debugging or generating backtraces, and should not be relied upon. In
711 particular, as C<@_> contains aliases to the caller's arguments, Perl does
712 not take a copy of C<@_>, so C<@DB::args> will contain modifications the
713 subroutine makes to C<@_> or its contents, not the original values at call
714 time. C<@DB::args>, like C<@_>, does not hold explicit references to its
715 elements, so under certain cases its elements may have become freed and
716 reallocated for other variables or temporary values. Finally, a side effect
717 of the current implementation is that the effects of C<shift @_> can
718 I<normally> be undone (but not C<pop @_> or other splicing, I<and> not if a
719 reference to C<@_> has been taken, I<and> subject to the caveat about reallocated
720 elements), so C<@DB::args> is actually a hybrid of the current state and
721 initial state of C<@_>. Buyer beware.
722
723 =item chdir EXPR
724 X<chdir>
725 X<cd>
726 X<directory, change>
727
728 =item chdir FILEHANDLE
729
730 =item chdir DIRHANDLE
731
732 =item chdir
733
734 Changes the working directory to EXPR, if possible. If EXPR is omitted,
735 changes to the directory specified by C<$ENV{HOME}>, if set; if not,
736 changes to the directory specified by C<$ENV{LOGDIR}>. (Under VMS, the
737 variable C<$ENV{SYS$LOGIN}> is also checked, and used if it is set.) If
738 neither is set, C<chdir> does nothing. It returns true on success,
739 false otherwise. See the example under C<die>.
740
741 On systems that support fchdir(2), you may pass a filehandle or
742 directory handle as the argument.  On systems that don't support fchdir(2),
743 passing handles raises an exception.
744
745 =item chmod LIST
746 X<chmod> X<permission> X<mode>
747
748 Changes the permissions of a list of files.  The first element of the
749 list must be the numeric mode, which should probably be an octal
750 number, and which definitely should I<not> be a string of octal digits:
751 C<0644> is okay, but C<"0644"> is not.  Returns the number of files
752 successfully changed.  See also L</oct> if all you have is a string.
753
754     $cnt = chmod 0755, "foo", "bar";
755     chmod 0755, @executables;
756     $mode = "0644"; chmod $mode, "foo";      # !!! sets mode to
757                                              # --w----r-T
758     $mode = "0644"; chmod oct($mode), "foo"; # this is better
759     $mode = 0644;   chmod $mode, "foo";      # this is best
760
761 On systems that support fchmod(2), you may pass filehandles among the
762 files.  On systems that don't support fchmod(2), passing filehandles raises
763 an exception.  Filehandles must be passed as globs or glob references to be
764 recognized; barewords are considered filenames.
765
766     open(my $fh, "<", "foo");
767     my $perm = (stat $fh)[2] & 07777;
768     chmod($perm | 0600, $fh);
769
770 You can also import the symbolic C<S_I*> constants from the C<Fcntl>
771 module:
772
773     use Fcntl qw( :mode );
774     chmod S_IRWXU|S_IRGRP|S_IXGRP|S_IROTH|S_IXOTH, @executables;
775     # Identical to the chmod 0755 of the example above.
776
777 Portability issues: L<perlport/chmod>.
778
779 =item chomp VARIABLE
780 X<chomp> X<INPUT_RECORD_SEPARATOR> X<$/> X<newline> X<eol>
781
782 =item chomp( LIST )
783
784 =item chomp
785
786 This safer version of L</chop> removes any trailing string
787 that corresponds to the current value of C<$/> (also known as
788 $INPUT_RECORD_SEPARATOR in the C<English> module).  It returns the total
789 number of characters removed from all its arguments.  It's often used to
790 remove the newline from the end of an input record when you're worried
791 that the final record may be missing its newline.  When in paragraph
792 mode (C<$/ = "">), it removes all trailing newlines from the string.
793 When in slurp mode (C<$/ = undef>) or fixed-length record mode (C<$/> is
794 a reference to an integer or the like; see L<perlvar>) chomp() won't
795 remove anything.
796 If VARIABLE is omitted, it chomps C<$_>.  Example:
797
798     while (<>) {
799         chomp;  # avoid \n on last field
800         @array = split(/:/);
801         # ...
802     }
803
804 If VARIABLE is a hash, it chomps the hash's values, but not its keys.
805
806 You can actually chomp anything that's an lvalue, including an assignment:
807
808     chomp($cwd = `pwd`);
809     chomp($answer = <STDIN>);
810
811 If you chomp a list, each element is chomped, and the total number of
812 characters removed is returned.
813
814 Note that parentheses are necessary when you're chomping anything
815 that is not a simple variable.  This is because C<chomp $cwd = `pwd`;>
816 is interpreted as C<(chomp $cwd) = `pwd`;>, rather than as
817 C<chomp( $cwd = `pwd` )> which you might expect.  Similarly,
818 C<chomp $a, $b> is interpreted as C<chomp($a), $b> rather than
819 as C<chomp($a, $b)>.
820
821 =item chop VARIABLE
822 X<chop>
823
824 =item chop( LIST )
825
826 =item chop
827
828 Chops off the last character of a string and returns the character
829 chopped.  It is much more efficient than C<s/.$//s> because it neither
830 scans nor copies the string.  If VARIABLE is omitted, chops C<$_>.
831 If VARIABLE is a hash, it chops the hash's values, but not its keys.
832
833 You can actually chop anything that's an lvalue, including an assignment.
834
835 If you chop a list, each element is chopped.  Only the value of the
836 last C<chop> is returned.
837
838 Note that C<chop> returns the last character.  To return all but the last
839 character, use C<substr($string, 0, -1)>.
840
841 See also L</chomp>.
842
843 =item chown LIST
844 X<chown> X<owner> X<user> X<group>
845
846 Changes the owner (and group) of a list of files.  The first two
847 elements of the list must be the I<numeric> uid and gid, in that
848 order.  A value of -1 in either position is interpreted by most
849 systems to leave that value unchanged.  Returns the number of files
850 successfully changed.
851
852     $cnt = chown $uid, $gid, 'foo', 'bar';
853     chown $uid, $gid, @filenames;
854
855 On systems that support fchown(2), you may pass filehandles among the
856 files.  On systems that don't support fchown(2), passing filehandles raises
857 an exception.  Filehandles must be passed as globs or glob references to be
858 recognized; barewords are considered filenames.
859
860 Here's an example that looks up nonnumeric uids in the passwd file:
861
862     print "User: ";
863     chomp($user = <STDIN>);
864     print "Files: ";
865     chomp($pattern = <STDIN>);
866
867     ($login,$pass,$uid,$gid) = getpwnam($user)
868         or die "$user not in passwd file";
869
870     @ary = glob($pattern);  # expand filenames
871     chown $uid, $gid, @ary;
872
873 On most systems, you are not allowed to change the ownership of the
874 file unless you're the superuser, although you should be able to change
875 the group to any of your secondary groups.  On insecure systems, these
876 restrictions may be relaxed, but this is not a portable assumption.
877 On POSIX systems, you can detect this condition this way:
878
879     use POSIX qw(sysconf _PC_CHOWN_RESTRICTED);
880     $can_chown_giveaway = not sysconf(_PC_CHOWN_RESTRICTED);
881
882 Portability issues: L<perlport/chmod>.
883
884 =item chr NUMBER
885 X<chr> X<character> X<ASCII> X<Unicode>
886
887 =item chr
888
889 Returns the character represented by that NUMBER in the character set.
890 For example, C<chr(65)> is C<"A"> in either ASCII or Unicode, and
891 chr(0x263a) is a Unicode smiley face.  
892
893 Negative values give the Unicode replacement character (chr(0xfffd)),
894 except under the L<bytes> pragma, where the low eight bits of the value
895 (truncated to an integer) are used.
896
897 If NUMBER is omitted, uses C<$_>.
898
899 For the reverse, use L</ord>.
900
901 Note that characters from 128 to 255 (inclusive) are by default
902 internally not encoded as UTF-8 for backward compatibility reasons.
903
904 See L<perlunicode> for more about Unicode.
905
906 =item chroot FILENAME
907 X<chroot> X<root>
908
909 =item chroot
910
911 This function works like the system call by the same name: it makes the
912 named directory the new root directory for all further pathnames that
913 begin with a C</> by your process and all its children.  (It doesn't
914 change your current working directory, which is unaffected.)  For security
915 reasons, this call is restricted to the superuser.  If FILENAME is
916 omitted, does a C<chroot> to C<$_>.
917
918 Portability issues: L<perlport/chroot>.
919
920 =item close FILEHANDLE
921 X<close>
922
923 =item close
924
925 Closes the file or pipe associated with the filehandle, flushes the IO
926 buffers, and closes the system file descriptor.  Returns true if those
927 operations succeed and if no error was reported by any PerlIO
928 layer.  Closes the currently selected filehandle if the argument is
929 omitted.
930
931 You don't have to close FILEHANDLE if you are immediately going to do
932 another C<open> on it, because C<open> closes it for you.  (See
933 L<open|/open FILEHANDLE>.)  However, an explicit C<close> on an input file resets the line
934 counter (C<$.>), while the implicit close done by C<open> does not.
935
936 If the filehandle came from a piped open, C<close> returns false if one of
937 the other syscalls involved fails or if its program exits with non-zero
938 status.  If the only problem was that the program exited non-zero, C<$!>
939 will be set to C<0>.  Closing a pipe also waits for the process executing
940 on the pipe to exit--in case you wish to look at the output of the pipe
941 afterwards--and implicitly puts the exit status value of that command into
942 C<$?> and C<${^CHILD_ERROR_NATIVE}>.
943
944 If there are multiple threads running, C<close> on a filehandle from a
945 piped open returns true without waiting for the child process to terminate,
946 if the filehandle is still open in another thread.
947
948 Closing the read end of a pipe before the process writing to it at the
949 other end is done writing results in the writer receiving a SIGPIPE.  If
950 the other end can't handle that, be sure to read all the data before
951 closing the pipe.
952
953 Example:
954
955     open(OUTPUT, '|sort >foo')  # pipe to sort
956         or die "Can't start sort: $!";
957     #...                        # print stuff to output
958     close OUTPUT                # wait for sort to finish
959         or warn $! ? "Error closing sort pipe: $!"
960                    : "Exit status $? from sort";
961     open(INPUT, 'foo')          # get sort's results
962         or die "Can't open 'foo' for input: $!";
963
964 FILEHANDLE may be an expression whose value can be used as an indirect
965 filehandle, usually the real filehandle name or an autovivified handle.
966
967 =item closedir DIRHANDLE
968 X<closedir>
969
970 Closes a directory opened by C<opendir> and returns the success of that
971 system call.
972
973 =item connect SOCKET,NAME
974 X<connect>
975
976 Attempts to connect to a remote socket, just like connect(2).
977 Returns true if it succeeded, false otherwise.  NAME should be a
978 packed address of the appropriate type for the socket.  See the examples in
979 L<perlipc/"Sockets: Client/Server Communication">.
980
981 =item continue BLOCK
982 X<continue>
983
984 =item continue
985
986 When followed by a BLOCK, C<continue> is actually a
987 flow control statement rather than a function.  If
988 there is a C<continue> BLOCK attached to a BLOCK (typically in a C<while> or
989 C<foreach>), it is always executed just before the conditional is about to
990 be evaluated again, just like the third part of a C<for> loop in C.  Thus
991 it can be used to increment a loop variable, even when the loop has been
992 continued via the C<next> statement (which is similar to the C C<continue>
993 statement).
994
995 C<last>, C<next>, or C<redo> may appear within a C<continue>
996 block; C<last> and C<redo> behave as if they had been executed within
997 the main block.  So will C<next>, but since it will execute a C<continue>
998 block, it may be more entertaining.
999
1000     while (EXPR) {
1001         ### redo always comes here
1002         do_something;
1003     } continue {
1004         ### next always comes here
1005         do_something_else;
1006         # then back the top to re-check EXPR
1007     }
1008     ### last always comes here
1009
1010 Omitting the C<continue> section is equivalent to using an
1011 empty one, logically enough, so C<next> goes directly back
1012 to check the condition at the top of the loop.
1013
1014 When there is no BLOCK, C<continue> is a function that
1015 falls through the current C<when> or C<default> block instead of iterating
1016 a dynamically enclosing C<foreach> or exiting a lexically enclosing C<given>.
1017 In Perl 5.14 and earlier, this form of C<continue> was
1018 only available when the C<"switch"> feature was enabled.
1019 See L<feature> and L<perlsyn/"Switch statements"> for more
1020 information.
1021
1022 =item cos EXPR
1023 X<cos> X<cosine> X<acos> X<arccosine>
1024
1025 =item cos
1026
1027 Returns the cosine of EXPR (expressed in radians).  If EXPR is omitted,
1028 takes the cosine of C<$_>.
1029
1030 For the inverse cosine operation, you may use the C<Math::Trig::acos()>
1031 function, or use this relation:
1032
1033     sub acos { atan2( sqrt(1 - $_[0] * $_[0]), $_[0] ) }
1034
1035 =item crypt PLAINTEXT,SALT
1036 X<crypt> X<digest> X<hash> X<salt> X<plaintext> X<password>
1037 X<decrypt> X<cryptography> X<passwd> X<encrypt>
1038
1039 Creates a digest string exactly like the crypt(3) function in the C
1040 library (assuming that you actually have a version there that has not
1041 been extirpated as a potential munition).
1042
1043 crypt() is a one-way hash function.  The PLAINTEXT and SALT are turned
1044 into a short string, called a digest, which is returned.  The same
1045 PLAINTEXT and SALT will always return the same string, but there is no
1046 (known) way to get the original PLAINTEXT from the hash.  Small
1047 changes in the PLAINTEXT or SALT will result in large changes in the
1048 digest.
1049
1050 There is no decrypt function.  This function isn't all that useful for
1051 cryptography (for that, look for F<Crypt> modules on your nearby CPAN
1052 mirror) and the name "crypt" is a bit of a misnomer.  Instead it is
1053 primarily used to check if two pieces of text are the same without
1054 having to transmit or store the text itself.  An example is checking
1055 if a correct password is given.  The digest of the password is stored,
1056 not the password itself.  The user types in a password that is
1057 crypt()'d with the same salt as the stored digest.  If the two digests
1058 match, the password is correct.
1059
1060 When verifying an existing digest string you should use the digest as
1061 the salt (like C<crypt($plain, $digest) eq $digest>).  The SALT used
1062 to create the digest is visible as part of the digest.  This ensures
1063 crypt() will hash the new string with the same salt as the digest.
1064 This allows your code to work with the standard L<crypt|/crypt> and
1065 with more exotic implementations.  In other words, assume
1066 nothing about the returned string itself nor about how many bytes 
1067 of SALT may matter.
1068
1069 Traditionally the result is a string of 13 bytes: two first bytes of
1070 the salt, followed by 11 bytes from the set C<[./0-9A-Za-z]>, and only
1071 the first eight bytes of PLAINTEXT mattered. But alternative
1072 hashing schemes (like MD5), higher level security schemes (like C2),
1073 and implementations on non-Unix platforms may produce different
1074 strings.
1075
1076 When choosing a new salt create a random two character string whose
1077 characters come from the set C<[./0-9A-Za-z]> (like C<join '', ('.',
1078 '/', 0..9, 'A'..'Z', 'a'..'z')[rand 64, rand 64]>).  This set of
1079 characters is just a recommendation; the characters allowed in
1080 the salt depend solely on your system's crypt library, and Perl can't
1081 restrict what salts C<crypt()> accepts.
1082
1083 Here's an example that makes sure that whoever runs this program knows
1084 their password:
1085
1086     $pwd = (getpwuid($<))[1];
1087
1088     system "stty -echo";
1089     print "Password: ";
1090     chomp($word = <STDIN>);
1091     print "\n";
1092     system "stty echo";
1093
1094     if (crypt($word, $pwd) ne $pwd) {
1095         die "Sorry...\n";
1096     } else {
1097         print "ok\n";
1098     }
1099
1100 Of course, typing in your own password to whoever asks you
1101 for it is unwise.
1102
1103 The L<crypt|/crypt> function is unsuitable for hashing large quantities
1104 of data, not least of all because you can't get the information
1105 back.  Look at the L<Digest> module for more robust algorithms.
1106
1107 If using crypt() on a Unicode string (which I<potentially> has
1108 characters with codepoints above 255), Perl tries to make sense
1109 of the situation by trying to downgrade (a copy of)
1110 the string back to an eight-bit byte string before calling crypt()
1111 (on that copy).  If that works, good.  If not, crypt() dies with
1112 C<Wide character in crypt>.
1113
1114 Portability issues: L<perlport/crypt>.
1115
1116 =item dbmclose HASH
1117 X<dbmclose>
1118
1119 [This function has been largely superseded by the C<untie> function.]
1120
1121 Breaks the binding between a DBM file and a hash.
1122
1123 Portability issues: L<perlport/dbmclose>.
1124
1125 =item dbmopen HASH,DBNAME,MASK
1126 X<dbmopen> X<dbm> X<ndbm> X<sdbm> X<gdbm>
1127
1128 [This function has been largely superseded by the
1129 L<tie|/tie VARIABLE,CLASSNAME,LIST> function.]
1130
1131 This binds a dbm(3), ndbm(3), sdbm(3), gdbm(3), or Berkeley DB file to a
1132 hash.  HASH is the name of the hash.  (Unlike normal C<open>, the first
1133 argument is I<not> a filehandle, even though it looks like one).  DBNAME
1134 is the name of the database (without the F<.dir> or F<.pag> extension if
1135 any).  If the database does not exist, it is created with protection
1136 specified by MASK (as modified by the C<umask>).  If your system supports
1137 only the older DBM functions, you may make only one C<dbmopen> call in your
1138 program.  In older versions of Perl, if your system had neither DBM nor
1139 ndbm, calling C<dbmopen> produced a fatal error; it now falls back to
1140 sdbm(3).
1141
1142 If you don't have write access to the DBM file, you can only read hash
1143 variables, not set them.  If you want to test whether you can write,
1144 either use file tests or try setting a dummy hash entry inside an C<eval> 
1145 to trap the error.
1146
1147 Note that functions such as C<keys> and C<values> may return huge lists
1148 when used on large DBM files.  You may prefer to use the C<each>
1149 function to iterate over large DBM files.  Example:
1150
1151     # print out history file offsets
1152     dbmopen(%HIST,'/usr/lib/news/history',0666);
1153     while (($key,$val) = each %HIST) {
1154         print $key, ' = ', unpack('L',$val), "\n";
1155     }
1156     dbmclose(%HIST);
1157
1158 See also L<AnyDBM_File> for a more general description of the pros and
1159 cons of the various dbm approaches, as well as L<DB_File> for a particularly
1160 rich implementation.
1161
1162 You can control which DBM library you use by loading that library
1163 before you call dbmopen():
1164
1165     use DB_File;
1166     dbmopen(%NS_Hist, "$ENV{HOME}/.netscape/history.db")
1167         or die "Can't open netscape history file: $!";
1168
1169 Portability issues: L<perlport/dbmopen>.
1170
1171 =item default BLOCK
1172
1173 Within a C<foreach> or a C<given>, a C<default> BLOCK acts like a C<when>
1174 that's always true.  Only available after Perl 5.10, and only if the
1175 C<switch> feature has been requested or if the keyword is prefixed with
1176 C<CORE::>.  See L</when>.
1177
1178 =item defined EXPR
1179 X<defined> X<undef> X<undefined>
1180
1181 =item defined
1182
1183 Returns a Boolean value telling whether EXPR has a value other than
1184 the undefined value C<undef>.  If EXPR is not present, C<$_> is
1185 checked.
1186
1187 Many operations return C<undef> to indicate failure, end of file,
1188 system error, uninitialized variable, and other exceptional
1189 conditions.  This function allows you to distinguish C<undef> from
1190 other values.  (A simple Boolean test will not distinguish among
1191 C<undef>, zero, the empty string, and C<"0">, which are all equally
1192 false.)  Note that since C<undef> is a valid scalar, its presence
1193 doesn't I<necessarily> indicate an exceptional condition: C<pop>
1194 returns C<undef> when its argument is an empty array, I<or> when the
1195 element to return happens to be C<undef>.
1196
1197 You may also use C<defined(&func)> to check whether subroutine C<&func>
1198 has ever been defined.  The return value is unaffected by any forward
1199 declarations of C<&func>.  A subroutine that is not defined
1200 may still be callable: its package may have an C<AUTOLOAD> method that
1201 makes it spring into existence the first time that it is called; see
1202 L<perlsub>.
1203
1204 Use of C<defined> on aggregates (hashes and arrays) is deprecated.  It
1205 used to report whether memory for that aggregate had ever been
1206 allocated.  This behavior may disappear in future versions of Perl.
1207 You should instead use a simple test for size:
1208
1209     if (@an_array) { print "has array elements\n" }
1210     if (%a_hash)   { print "has hash members\n"   }
1211
1212 When used on a hash element, it tells you whether the value is defined,
1213 not whether the key exists in the hash.  Use L</exists> for the latter
1214 purpose.
1215
1216 Examples:
1217
1218     print if defined $switch{D};
1219     print "$val\n" while defined($val = pop(@ary));
1220     die "Can't readlink $sym: $!"
1221         unless defined($value = readlink $sym);
1222     sub foo { defined &$bar ? &$bar(@_) : die "No bar"; }
1223     $debugging = 0 unless defined $debugging;
1224
1225 Note:  Many folks tend to overuse C<defined> and are then surprised to
1226 discover that the number C<0> and C<""> (the zero-length string) are, in fact,
1227 defined values.  For example, if you say
1228
1229     "ab" =~ /a(.*)b/;
1230
1231 The pattern match succeeds and C<$1> is defined, although it
1232 matched "nothing".  It didn't really fail to match anything.  Rather, it
1233 matched something that happened to be zero characters long.  This is all
1234 very above-board and honest.  When a function returns an undefined value,
1235 it's an admission that it couldn't give you an honest answer.  So you
1236 should use C<defined> only when questioning the integrity of what
1237 you're trying to do.  At other times, a simple comparison to C<0> or C<""> is
1238 what you want.
1239
1240 See also L</undef>, L</exists>, L</ref>.
1241
1242 =item delete EXPR
1243 X<delete>
1244
1245 Given an expression that specifies an element or slice of a hash, C<delete>
1246 deletes the specified elements from that hash so that exists() on that element
1247 no longer returns true.  Setting a hash element to the undefined value does
1248 not remove its key, but deleting it does; see L</exists>.
1249
1250 In list context, returns the value or values deleted, or the last such
1251 element in scalar context.  The return list's length always matches that of
1252 the argument list: deleting non-existent elements returns the undefined value
1253 in their corresponding positions.
1254
1255 delete() may also be used on arrays and array slices, but its behavior is less
1256 straightforward.  Although exists() will return false for deleted entries,
1257 deleting array elements never changes indices of existing values; use shift()
1258 or splice() for that.  However, if all deleted elements fall at the end of an
1259 array, the array's size shrinks to the position of the highest element that
1260 still tests true for exists(), or to 0 if none do.
1261
1262 B<WARNING:> Calling delete on array values is deprecated and likely to
1263 be removed in a future version of Perl.
1264
1265 Deleting from C<%ENV> modifies the environment.  Deleting from a hash tied to
1266 a DBM file deletes the entry from the DBM file.  Deleting from a C<tied> hash
1267 or array may not necessarily return anything; it depends on the implementation
1268 of the C<tied> package's DELETE method, which may do whatever it pleases.
1269
1270 The C<delete local EXPR> construct localizes the deletion to the current
1271 block at run time.  Until the block exits, elements locally deleted
1272 temporarily no longer exist.  See L<perlsub/"Localized deletion of elements
1273 of composite types">.
1274
1275     %hash = (foo => 11, bar => 22, baz => 33);
1276     $scalar = delete $hash{foo};             # $scalar is 11
1277     $scalar = delete @hash{qw(foo bar)};     # $scalar is 22
1278     @array  = delete @hash{qw(foo bar baz)}; # @array  is (undef,undef,33)
1279
1280 The following (inefficiently) deletes all the values of %HASH and @ARRAY:
1281
1282     foreach $key (keys %HASH) {
1283         delete $HASH{$key};
1284     }
1285
1286     foreach $index (0 .. $#ARRAY) {
1287         delete $ARRAY[$index];
1288     }
1289
1290 And so do these:
1291
1292     delete @HASH{keys %HASH};
1293
1294     delete @ARRAY[0 .. $#ARRAY];
1295
1296 But both are slower than assigning the empty list
1297 or undefining %HASH or @ARRAY, which is the customary 
1298 way to empty out an aggregate:
1299
1300     %HASH = ();     # completely empty %HASH
1301     undef %HASH;    # forget %HASH ever existed
1302
1303     @ARRAY = ();    # completely empty @ARRAY
1304     undef @ARRAY;   # forget @ARRAY ever existed
1305
1306 The EXPR can be arbitrarily complicated provided its
1307 final operation is an element or slice of an aggregate:
1308
1309     delete $ref->[$x][$y]{$key};
1310     delete @{$ref->[$x][$y]}{$key1, $key2, @morekeys};
1311
1312     delete $ref->[$x][$y][$index];
1313     delete @{$ref->[$x][$y]}[$index1, $index2, @moreindices];
1314
1315 =item die LIST
1316 X<die> X<throw> X<exception> X<raise> X<$@> X<abort>
1317
1318 C<die> raises an exception. Inside an C<eval> the error message is stuffed
1319 into C<$@> and the C<eval> is terminated with the undefined value.
1320 If the exception is outside of all enclosing C<eval>s, then the uncaught
1321 exception prints LIST to C<STDERR> and exits with a non-zero value. If you
1322 need to exit the process with a specific exit code, see L</exit>.
1323
1324 Equivalent examples:
1325
1326     die "Can't cd to spool: $!\n" unless chdir '/usr/spool/news';
1327     chdir '/usr/spool/news' or die "Can't cd to spool: $!\n"
1328
1329 If the last element of LIST does not end in a newline, the current
1330 script line number and input line number (if any) are also printed,
1331 and a newline is supplied.  Note that the "input line number" (also
1332 known as "chunk") is subject to whatever notion of "line" happens to
1333 be currently in effect, and is also available as the special variable
1334 C<$.>.  See L<perlvar/"$/"> and L<perlvar/"$.">.
1335
1336 Hint: sometimes appending C<", stopped"> to your message will cause it
1337 to make better sense when the string C<"at foo line 123"> is appended.
1338 Suppose you are running script "canasta".
1339
1340     die "/etc/games is no good";
1341     die "/etc/games is no good, stopped";
1342
1343 produce, respectively
1344
1345     /etc/games is no good at canasta line 123.
1346     /etc/games is no good, stopped at canasta line 123.
1347
1348 If the output is empty and C<$@> already contains a value (typically from a
1349 previous eval) that value is reused after appending C<"\t...propagated">.
1350 This is useful for propagating exceptions:
1351
1352     eval { ... };
1353     die unless $@ =~ /Expected exception/;
1354
1355 If the output is empty and C<$@> contains an object reference that has a
1356 C<PROPAGATE> method, that method will be called with additional file
1357 and line number parameters.  The return value replaces the value in
1358 C<$@>;  i.e., as if C<< $@ = eval { $@->PROPAGATE(__FILE__, __LINE__) }; >>
1359 were called.
1360
1361 If C<$@> is empty then the string C<"Died"> is used.
1362
1363 If an uncaught exception results in interpreter exit, the exit code is
1364 determined from the values of C<$!> and C<$?> with this pseudocode:
1365
1366     exit $! if $!;              # errno
1367     exit $? >> 8 if $? >> 8;    # child exit status
1368     exit 255;                   # last resort
1369
1370 The intent is to squeeze as much possible information about the likely cause
1371 into the limited space of the system exit code. However, as C<$!> is the value
1372 of C's C<errno>, which can be set by any system call, this means that the value
1373 of the exit code used by C<die> can be non-predictable, so should not be relied
1374 upon, other than to be non-zero.
1375
1376 You can also call C<die> with a reference argument, and if this is trapped
1377 within an C<eval>, C<$@> contains that reference.  This permits more
1378 elaborate exception handling using objects that maintain arbitrary state
1379 about the exception.  Such a scheme is sometimes preferable to matching
1380 particular string values of C<$@> with regular expressions.  Because C<$@> 
1381 is a global variable and C<eval> may be used within object implementations,
1382 be careful that analyzing the error object doesn't replace the reference in
1383 the global variable.  It's easiest to make a local copy of the reference
1384 before any manipulations.  Here's an example:
1385
1386     use Scalar::Util "blessed";
1387
1388     eval { ... ; die Some::Module::Exception->new( FOO => "bar" ) };
1389     if (my $ev_err = $@) {
1390         if (blessed($ev_err) && $ev_err->isa("Some::Module::Exception")) {
1391             # handle Some::Module::Exception
1392         }
1393         else {
1394             # handle all other possible exceptions
1395         }
1396     }
1397
1398 Because Perl stringifies uncaught exception messages before display,
1399 you'll probably want to overload stringification operations on
1400 exception objects.  See L<overload> for details about that.
1401
1402 You can arrange for a callback to be run just before the C<die>
1403 does its deed, by setting the C<$SIG{__DIE__}> hook.  The associated
1404 handler is called with the error text and can change the error
1405 message, if it sees fit, by calling C<die> again.  See
1406 L<perlvar/%SIG> for details on setting C<%SIG> entries, and
1407 L<"eval BLOCK"> for some examples.  Although this feature was 
1408 to be run only right before your program was to exit, this is not
1409 currently so: the C<$SIG{__DIE__}> hook is currently called
1410 even inside eval()ed blocks/strings!  If one wants the hook to do
1411 nothing in such situations, put
1412
1413     die @_ if $^S;
1414
1415 as the first line of the handler (see L<perlvar/$^S>).  Because
1416 this promotes strange action at a distance, this counterintuitive
1417 behavior may be fixed in a future release.
1418
1419 See also exit(), warn(), and the Carp module.
1420
1421 =item do BLOCK
1422 X<do> X<block>
1423
1424 Not really a function.  Returns the value of the last command in the
1425 sequence of commands indicated by BLOCK.  When modified by the C<while> or
1426 C<until> loop modifier, executes the BLOCK once before testing the loop
1427 condition. (On other statements the loop modifiers test the conditional
1428 first.)
1429
1430 C<do BLOCK> does I<not> count as a loop, so the loop control statements
1431 C<next>, C<last>, or C<redo> cannot be used to leave or restart the block.
1432 See L<perlsyn> for alternative strategies.
1433
1434 =item do SUBROUTINE(LIST)
1435 X<do>
1436
1437 This form of subroutine call is deprecated.  SUBROUTINE can be a bareword,
1438 a scalar variable or a subroutine beginning with C<&>.
1439
1440 =item do EXPR
1441 X<do>
1442
1443 Uses the value of EXPR as a filename and executes the contents of the
1444 file as a Perl script.
1445
1446     do 'stat.pl';
1447
1448 is just like
1449
1450     eval `cat stat.pl`;
1451
1452 except that it's more efficient and concise, keeps track of the current
1453 filename for error messages, searches the C<@INC> directories, and updates
1454 C<%INC> if the file is found.  See L<perlvar/@INC> and L<perlvar/%INC> for
1455 these variables.  It also differs in that code evaluated with C<do FILENAME>
1456 cannot see lexicals in the enclosing scope; C<eval STRING> does.  It's the
1457 same, however, in that it does reparse the file every time you call it,
1458 so you probably don't want to do this inside a loop.
1459
1460 If C<do> can read the file but cannot compile it, it returns C<undef> and sets
1461 an error message in C<$@>.  If C<do> cannot read the file, it returns undef
1462 and sets C<$!> to the error.  Always check C<$@> first, as compilation
1463 could fail in a way that also sets C<$!>.  If the file is successfully
1464 compiled, C<do> returns the value of the last expression evaluated.
1465
1466 Inclusion of library modules is better done with the
1467 C<use> and C<require> operators, which also do automatic error checking
1468 and raise an exception if there's a problem.
1469
1470 You might like to use C<do> to read in a program configuration
1471 file.  Manual error checking can be done this way:
1472
1473     # read in config files: system first, then user
1474     for $file ("/share/prog/defaults.rc",
1475                "$ENV{HOME}/.someprogrc")
1476     {
1477         unless ($return = do $file) {
1478             warn "couldn't parse $file: $@" if $@;
1479             warn "couldn't do $file: $!"    unless defined $return;
1480             warn "couldn't run $file"       unless $return;
1481         }
1482     }
1483
1484 =item dump LABEL
1485 X<dump> X<core> X<undump>
1486
1487 =item dump
1488
1489 This function causes an immediate core dump.  See also the B<-u>
1490 command-line switch in L<perlrun>, which does the same thing.
1491 Primarily this is so that you can use the B<undump> program (not
1492 supplied) to turn your core dump into an executable binary after
1493 having initialized all your variables at the beginning of the
1494 program.  When the new binary is executed it will begin by executing
1495 a C<goto LABEL> (with all the restrictions that C<goto> suffers).
1496 Think of it as a goto with an intervening core dump and reincarnation.
1497 If C<LABEL> is omitted, restarts the program from the top.
1498
1499 B<WARNING>: Any files opened at the time of the dump will I<not>
1500 be open any more when the program is reincarnated, with possible
1501 resulting confusion by Perl.
1502
1503 This function is now largely obsolete, mostly because it's very hard to
1504 convert a core file into an executable. That's why you should now invoke
1505 it as C<CORE::dump()>, if you don't want to be warned against a possible
1506 typo.
1507
1508 Portability issues: L<perlport/dump>.
1509
1510 =item each HASH
1511 X<each> X<hash, iterator>
1512
1513 =item each ARRAY
1514 X<array, iterator>
1515
1516 =item each EXPR
1517
1518 When called in list context, returns a 2-element list consisting of the key
1519 and value for the next element of a hash, or the index and value for the
1520 next element of an array, so that you can iterate over it.  When called in
1521 scalar context, returns only the key (not the value) in a hash, or the index
1522 in an array.
1523
1524 Hash entries are returned in an apparently random order.  The actual random
1525 order is subject to change in future versions of Perl, but it is
1526 guaranteed to be in the same order as either the C<keys> or C<values>
1527 function would produce on the same (unmodified) hash.  Since Perl
1528 5.8.2 the ordering can be different even between different runs of Perl
1529 for security reasons (see L<perlsec/"Algorithmic Complexity Attacks">).
1530
1531 After C<each> has returned all entries from the hash or array, the next
1532 call to C<each> returns the empty list in list context and C<undef> in
1533 scalar context.  The next call following that one restarts iteration.  Each
1534 hash or array has its own internal iterator, accessed by C<each>, C<keys>,
1535 and C<values>.  The iterator is implicitly reset when C<each> has reached
1536 the end as just described; it can be explicitly reset by calling C<keys> or
1537 C<values> on the hash or array.  If you add or delete a hash's elements
1538 while iterating over it, entries may be skipped or duplicated--so don't do
1539 that.  Exception: It is always safe to delete the item most recently
1540 returned by C<each()>, so the following code works properly:
1541
1542         while (($key, $value) = each %hash) {
1543           print $key, "\n";
1544           delete $hash{$key};   # This is safe
1545         }
1546
1547 This prints out your environment like the printenv(1) program,
1548 but in a different order:
1549
1550     while (($key,$value) = each %ENV) {
1551         print "$key=$value\n";
1552     }
1553
1554 Starting with Perl 5.14, C<each> can take a scalar EXPR, which must hold
1555 reference to an unblessed hash or array.  The argument will be dereferenced
1556 automatically.  This aspect of C<each> is considered highly experimental.
1557 The exact behaviour may change in a future version of Perl.
1558
1559     while (($key,$value) = each $hashref) { ... }
1560
1561 See also C<keys>, C<values>, and C<sort>.
1562
1563 =item eof FILEHANDLE
1564 X<eof>
1565 X<end of file>
1566 X<end-of-file>
1567
1568 =item eof ()
1569
1570 =item eof
1571
1572 Returns 1 if the next read on FILEHANDLE will return end of file I<or> if
1573 FILEHANDLE is not open.  FILEHANDLE may be an expression whose value
1574 gives the real filehandle.  (Note that this function actually
1575 reads a character and then C<ungetc>s it, so isn't useful in an
1576 interactive context.)  Do not read from a terminal file (or call
1577 C<eof(FILEHANDLE)> on it) after end-of-file is reached.  File types such
1578 as terminals may lose the end-of-file condition if you do.
1579
1580 An C<eof> without an argument uses the last file read.  Using C<eof()>
1581 with empty parentheses is different.  It refers to the pseudo file
1582 formed from the files listed on the command line and accessed via the
1583 C<< <> >> operator.  Since C<< <> >> isn't explicitly opened,
1584 as a normal filehandle is, an C<eof()> before C<< <> >> has been
1585 used will cause C<@ARGV> to be examined to determine if input is
1586 available.   Similarly, an C<eof()> after C<< <> >> has returned
1587 end-of-file will assume you are processing another C<@ARGV> list,
1588 and if you haven't set C<@ARGV>, will read input from C<STDIN>;
1589 see L<perlop/"I/O Operators">.
1590
1591 In a C<< while (<>) >> loop, C<eof> or C<eof(ARGV)> can be used to
1592 detect the end of each file, whereas C<eof()> will detect the end 
1593 of the very last file only.  Examples:
1594
1595     # reset line numbering on each input file
1596     while (<>) {
1597         next if /^\s*#/;  # skip comments
1598         print "$.\t$_";
1599     } continue {
1600         close ARGV if eof;  # Not eof()!
1601     }
1602
1603     # insert dashes just before last line of last file
1604     while (<>) {
1605         if (eof()) {  # check for end of last file
1606             print "--------------\n";
1607         }
1608         print;
1609         last if eof();      # needed if we're reading from a terminal
1610     }
1611
1612 Practical hint: you almost never need to use C<eof> in Perl, because the
1613 input operators typically return C<undef> when they run out of data or 
1614 encounter an error.
1615
1616 =item eval EXPR
1617 X<eval> X<try> X<catch> X<evaluate> X<parse> X<execute>
1618 X<error, handling> X<exception, handling>
1619
1620 =item eval BLOCK
1621
1622 =item eval
1623
1624 In the first form, the return value of EXPR is parsed and executed as if it
1625 were a little Perl program.  The value of the expression (which is itself
1626 determined within scalar context) is first parsed, and if there were no
1627 errors, executed as a block within the lexical context of the current Perl
1628 program.  This means, that in particular, any outer lexical variables are
1629 visible to it, and any package variable settings or subroutine and format
1630 definitions remain afterwards.
1631
1632 Note that the value is parsed every time the C<eval> executes.
1633 If EXPR is omitted, evaluates C<$_>.  This form is typically used to
1634 delay parsing and subsequent execution of the text of EXPR until run time.
1635
1636 In the second form, the code within the BLOCK is parsed only once--at the
1637 same time the code surrounding the C<eval> itself was parsed--and executed
1638 within the context of the current Perl program.  This form is typically
1639 used to trap exceptions more efficiently than the first (see below), while
1640 also providing the benefit of checking the code within BLOCK at compile
1641 time.
1642
1643 The final semicolon, if any, may be omitted from the value of EXPR or within
1644 the BLOCK.
1645
1646 In both forms, the value returned is the value of the last expression
1647 evaluated inside the mini-program; a return statement may be also used, just
1648 as with subroutines.  The expression providing the return value is evaluated
1649 in void, scalar, or list context, depending on the context of the C<eval> 
1650 itself.  See L</wantarray> for more on how the evaluation context can be 
1651 determined.
1652
1653 If there is a syntax error or runtime error, or a C<die> statement is
1654 executed, C<eval> returns C<undef> in scalar context
1655 or an empty list--or, for syntax errors, a list containing a single
1656 undefined value--in list context, and C<$@> is set to the error
1657 message.  The discrepancy in the return values in list context is
1658 considered a bug by some, and will probably be fixed in a future
1659 release.  If there was no error, C<$@> is set to the empty string.  A
1660 control flow operator like C<last> or C<goto> can bypass the setting of
1661 C<$@>.  Beware that using C<eval> neither silences Perl from printing
1662 warnings to STDERR, nor does it stuff the text of warning messages into C<$@>.
1663 To do either of those, you have to use the C<$SIG{__WARN__}> facility, or
1664 turn off warnings inside the BLOCK or EXPR using S<C<no warnings 'all'>>.
1665 See L</warn>, L<perlvar>, L<warnings> and L<perllexwarn>.
1666
1667 Note that, because C<eval> traps otherwise-fatal errors, it is useful for
1668 determining whether a particular feature (such as C<socket> or C<symlink>)
1669 is implemented.  It is also Perl's exception-trapping mechanism, where
1670 the die operator is used to raise exceptions.
1671
1672 If you want to trap errors when loading an XS module, some problems with
1673 the binary interface (such as Perl version skew) may be fatal even with
1674 C<eval> unless C<$ENV{PERL_DL_NONLAZY}> is set.  See L<perlrun>.
1675
1676 If the code to be executed doesn't vary, you may use the eval-BLOCK
1677 form to trap run-time errors without incurring the penalty of
1678 recompiling each time.  The error, if any, is still returned in C<$@>.
1679 Examples:
1680
1681     # make divide-by-zero nonfatal
1682     eval { $answer = $a / $b; }; warn $@ if $@;
1683
1684     # same thing, but less efficient
1685     eval '$answer = $a / $b'; warn $@ if $@;
1686
1687     # a compile-time error
1688     eval { $answer = }; # WRONG
1689
1690     # a run-time error
1691     eval '$answer =';   # sets $@
1692
1693 Using the C<eval{}> form as an exception trap in libraries does have some
1694 issues.  Due to the current arguably broken state of C<__DIE__> hooks, you
1695 may wish not to trigger any C<__DIE__> hooks that user code may have installed.
1696 You can use the C<local $SIG{__DIE__}> construct for this purpose,
1697 as this example shows:
1698
1699     # a private exception trap for divide-by-zero
1700     eval { local $SIG{'__DIE__'}; $answer = $a / $b; };
1701     warn $@ if $@;
1702
1703 This is especially significant, given that C<__DIE__> hooks can call
1704 C<die> again, which has the effect of changing their error messages:
1705
1706     # __DIE__ hooks may modify error messages
1707     {
1708        local $SIG{'__DIE__'} =
1709               sub { (my $x = $_[0]) =~ s/foo/bar/g; die $x };
1710        eval { die "foo lives here" };
1711        print $@ if $@;                # prints "bar lives here"
1712     }
1713
1714 Because this promotes action at a distance, this counterintuitive behavior
1715 may be fixed in a future release.
1716
1717 With an C<eval>, you should be especially careful to remember what's
1718 being looked at when:
1719
1720     eval $x;        # CASE 1
1721     eval "$x";      # CASE 2
1722
1723     eval '$x';      # CASE 3
1724     eval { $x };    # CASE 4
1725
1726     eval "\$$x++";  # CASE 5
1727     $$x++;          # CASE 6
1728
1729 Cases 1 and 2 above behave identically: they run the code contained in
1730 the variable $x.  (Although case 2 has misleading double quotes making
1731 the reader wonder what else might be happening (nothing is).)  Cases 3
1732 and 4 likewise behave in the same way: they run the code C<'$x'>, which
1733 does nothing but return the value of $x.  (Case 4 is preferred for
1734 purely visual reasons, but it also has the advantage of compiling at
1735 compile-time instead of at run-time.)  Case 5 is a place where
1736 normally you I<would> like to use double quotes, except that in this
1737 particular situation, you can just use symbolic references instead, as
1738 in case 6.
1739
1740 Before Perl 5.14, the assignment to C<$@> occurred before restoration 
1741 of localised variables, which means that for your code to run on older
1742 versions, a temporary is required if you want to mask some but not all
1743 errors:
1744
1745     # alter $@ on nefarious repugnancy only
1746     {
1747        my $e;
1748        {
1749           local $@; # protect existing $@
1750           eval { test_repugnancy() };
1751           # $@ =~ /nefarious/ and die $@; # Perl 5.14 and higher only
1752           $@ =~ /nefarious/ and $e = $@;
1753        }
1754        die $e if defined $e
1755     }
1756
1757 C<eval BLOCK> does I<not> count as a loop, so the loop control statements
1758 C<next>, C<last>, or C<redo> cannot be used to leave or restart the block.
1759
1760 An C<eval ''> executed within the C<DB> package doesn't see the usual
1761 surrounding lexical scope, but rather the scope of the first non-DB piece
1762 of code that called it.  You don't normally need to worry about this unless
1763 you are writing a Perl debugger.
1764
1765 =item exec LIST
1766 X<exec> X<execute>
1767
1768 =item exec PROGRAM LIST
1769
1770 The C<exec> function executes a system command I<and never returns>;
1771 use C<system> instead of C<exec> if you want it to return.  It fails and
1772 returns false only if the command does not exist I<and> it is executed
1773 directly instead of via your system's command shell (see below).
1774
1775 Since it's a common mistake to use C<exec> instead of C<system>, Perl
1776 warns you if there is a following statement that isn't C<die>, C<warn>,
1777 or C<exit> (if C<-w> is set--but you always do that, right?).   If you
1778 I<really> want to follow an C<exec> with some other statement, you
1779 can use one of these styles to avoid the warning:
1780
1781     exec ('foo')   or print STDERR "couldn't exec foo: $!";
1782     { exec ('foo') }; print STDERR "couldn't exec foo: $!";
1783
1784 If there is more than one argument in LIST, or if LIST is an array
1785 with more than one value, calls execvp(3) with the arguments in LIST.
1786 If there is only one scalar argument or an array with one element in it,
1787 the argument is checked for shell metacharacters, and if there are any,
1788 the entire argument is passed to the system's command shell for parsing
1789 (this is C</bin/sh -c> on Unix platforms, but varies on other platforms).
1790 If there are no shell metacharacters in the argument, it is split into
1791 words and passed directly to C<execvp>, which is more efficient.
1792 Examples:
1793
1794     exec '/bin/echo', 'Your arguments are: ', @ARGV;
1795     exec "sort $outfile | uniq";
1796
1797 If you don't really want to execute the first argument, but want to lie
1798 to the program you are executing about its own name, you can specify
1799 the program you actually want to run as an "indirect object" (without a
1800 comma) in front of the LIST.  (This always forces interpretation of the
1801 LIST as a multivalued list, even if there is only a single scalar in
1802 the list.)  Example:
1803
1804     $shell = '/bin/csh';
1805     exec $shell '-sh';    # pretend it's a login shell
1806
1807 or, more directly,
1808
1809     exec {'/bin/csh'} '-sh';  # pretend it's a login shell
1810
1811 When the arguments get executed via the system shell, results are
1812 subject to its quirks and capabilities.  See L<perlop/"`STRING`">
1813 for details.
1814
1815 Using an indirect object with C<exec> or C<system> is also more
1816 secure.  This usage (which also works fine with system()) forces
1817 interpretation of the arguments as a multivalued list, even if the
1818 list had just one argument.  That way you're safe from the shell
1819 expanding wildcards or splitting up words with whitespace in them.
1820
1821     @args = ( "echo surprise" );
1822
1823     exec @args;               # subject to shell escapes
1824                                 # if @args == 1
1825     exec { $args[0] } @args;  # safe even with one-arg list
1826
1827 The first version, the one without the indirect object, ran the I<echo>
1828 program, passing it C<"surprise"> an argument.  The second version didn't;
1829 it tried to run a program named I<"echo surprise">, didn't find it, and set
1830 C<$?> to a non-zero value indicating failure.
1831
1832 Beginning with v5.6.0, Perl attempts to flush all files opened for
1833 output before the exec, but this may not be supported on some platforms
1834 (see L<perlport>).  To be safe, you may need to set C<$|> ($AUTOFLUSH
1835 in English) or call the C<autoflush()> method of C<IO::Handle> on any
1836 open handles to avoid lost output.
1837
1838 Note that C<exec> will not call your C<END> blocks, nor will it invoke
1839 C<DESTROY> methods on your objects.
1840
1841 Portability issues: L<perlport/exec>.
1842
1843 =item exists EXPR
1844 X<exists> X<autovivification>
1845
1846 Given an expression that specifies an element of a hash, returns true if the
1847 specified element in the hash has ever been initialized, even if the
1848 corresponding value is undefined.
1849
1850     print "Exists\n"    if exists $hash{$key};
1851     print "Defined\n"   if defined $hash{$key};
1852     print "True\n"      if $hash{$key};
1853
1854 exists may also be called on array elements, but its behavior is much less
1855 obvious and is strongly tied to the use of L</delete> on arrays.  B<Be aware>
1856 that calling exists on array values is deprecated and likely to be removed in
1857 a future version of Perl.
1858
1859     print "Exists\n"    if exists $array[$index];
1860     print "Defined\n"   if defined $array[$index];
1861     print "True\n"      if $array[$index];
1862
1863 A hash or array element can be true only if it's defined and defined only if
1864 it exists, but the reverse doesn't necessarily hold true.
1865
1866 Given an expression that specifies the name of a subroutine,
1867 returns true if the specified subroutine has ever been declared, even
1868 if it is undefined.  Mentioning a subroutine name for exists or defined
1869 does not count as declaring it.  Note that a subroutine that does not
1870 exist may still be callable: its package may have an C<AUTOLOAD>
1871 method that makes it spring into existence the first time that it is
1872 called; see L<perlsub>.
1873
1874     print "Exists\n"  if exists &subroutine;
1875     print "Defined\n" if defined &subroutine;
1876
1877 Note that the EXPR can be arbitrarily complicated as long as the final
1878 operation is a hash or array key lookup or subroutine name:
1879
1880     if (exists $ref->{A}->{B}->{$key})  { }
1881     if (exists $hash{A}{B}{$key})       { }
1882
1883     if (exists $ref->{A}->{B}->[$ix])   { }
1884     if (exists $hash{A}{B}[$ix])        { }
1885
1886     if (exists &{$ref->{A}{B}{$key}})   { }
1887
1888 Although the mostly deeply nested array or hash will not spring into
1889 existence just because its existence was tested, any intervening ones will.
1890 Thus C<< $ref->{"A"} >> and C<< $ref->{"A"}->{"B"} >> will spring
1891 into existence due to the existence test for the $key element above.
1892 This happens anywhere the arrow operator is used, including even here:
1893
1894     undef $ref;
1895     if (exists $ref->{"Some key"})    { }
1896     print $ref;  # prints HASH(0x80d3d5c)
1897
1898 This surprising autovivification in what does not at first--or even
1899 second--glance appear to be an lvalue context may be fixed in a future
1900 release.
1901
1902 Use of a subroutine call, rather than a subroutine name, as an argument
1903 to exists() is an error.
1904
1905     exists &sub;    # OK
1906     exists &sub();  # Error
1907
1908 =item exit EXPR
1909 X<exit> X<terminate> X<abort>
1910
1911 =item exit
1912
1913 Evaluates EXPR and exits immediately with that value.    Example:
1914
1915     $ans = <STDIN>;
1916     exit 0 if $ans =~ /^[Xx]/;
1917
1918 See also C<die>.  If EXPR is omitted, exits with C<0> status.  The only
1919 universally recognized values for EXPR are C<0> for success and C<1>
1920 for error; other values are subject to interpretation depending on the
1921 environment in which the Perl program is running.  For example, exiting
1922 69 (EX_UNAVAILABLE) from a I<sendmail> incoming-mail filter will cause
1923 the mailer to return the item undelivered, but that's not true everywhere.
1924
1925 Don't use C<exit> to abort a subroutine if there's any chance that
1926 someone might want to trap whatever error happened.  Use C<die> instead,
1927 which can be trapped by an C<eval>.
1928
1929 The exit() function does not always exit immediately.  It calls any
1930 defined C<END> routines first, but these C<END> routines may not
1931 themselves abort the exit.  Likewise any object destructors that need to
1932 be called are called before the real exit.  C<END> routines and destructors
1933 can change the exit status by modifying C<$?>. If this is a problem, you
1934 can call C<POSIX:_exit($status)> to avoid END and destructor processing.
1935 See L<perlmod> for details.
1936
1937 Portability issues: L<perlport/exit>.
1938
1939 =item exp EXPR
1940 X<exp> X<exponential> X<antilog> X<antilogarithm> X<e>
1941
1942 =item exp
1943
1944 Returns I<e> (the natural logarithm base) to the power of EXPR.
1945 If EXPR is omitted, gives C<exp($_)>.
1946
1947 =item fcntl FILEHANDLE,FUNCTION,SCALAR
1948 X<fcntl>
1949
1950 Implements the fcntl(2) function.  You'll probably have to say
1951
1952     use Fcntl;
1953
1954 first to get the correct constant definitions.  Argument processing and
1955 value returned work just like C<ioctl> below.
1956 For example:
1957
1958     use Fcntl;
1959     fcntl($filehandle, F_GETFL, $packed_return_buffer)
1960         or die "can't fcntl F_GETFL: $!";
1961
1962 You don't have to check for C<defined> on the return from C<fcntl>.
1963 Like C<ioctl>, it maps a C<0> return from the system call into
1964 C<"0 but true"> in Perl.  This string is true in boolean context and C<0>
1965 in numeric context.  It is also exempt from the normal B<-w> warnings
1966 on improper numeric conversions.
1967
1968 Note that C<fcntl> raises an exception if used on a machine that
1969 doesn't implement fcntl(2).  See the Fcntl module or your fcntl(2)
1970 manpage to learn what functions are available on your system.
1971
1972 Here's an example of setting a filehandle named C<REMOTE> to be
1973 non-blocking at the system level.  You'll have to negotiate C<$|>
1974 on your own, though.
1975
1976     use Fcntl qw(F_GETFL F_SETFL O_NONBLOCK);
1977
1978     $flags = fcntl(REMOTE, F_GETFL, 0)
1979                 or die "Can't get flags for the socket: $!\n";
1980
1981     $flags = fcntl(REMOTE, F_SETFL, $flags | O_NONBLOCK)
1982                 or die "Can't set flags for the socket: $!\n";
1983
1984 Portability issues: L<perlport/fcntl>.
1985
1986 =item __FILE__
1987 X<__FILE__>
1988
1989 A special token that returns the name of the file in which it occurs.
1990
1991 =item fileno FILEHANDLE
1992 X<fileno>
1993
1994 Returns the file descriptor for a filehandle, or undefined if the
1995 filehandle is not open.  If there is no real file descriptor at the OS
1996 level, as can happen with filehandles connected to memory objects via
1997 C<open> with a reference for the third argument, -1 is returned.
1998
1999 This is mainly useful for constructing
2000 bitmaps for C<select> and low-level POSIX tty-handling operations.
2001 If FILEHANDLE is an expression, the value is taken as an indirect
2002 filehandle, generally its name.
2003
2004 You can use this to find out whether two handles refer to the
2005 same underlying descriptor:
2006
2007     if (fileno(THIS) == fileno(THAT)) {
2008         print "THIS and THAT are dups\n";
2009     }
2010
2011 =item flock FILEHANDLE,OPERATION
2012 X<flock> X<lock> X<locking>
2013
2014 Calls flock(2), or an emulation of it, on FILEHANDLE.  Returns true
2015 for success, false on failure.  Produces a fatal error if used on a
2016 machine that doesn't implement flock(2), fcntl(2) locking, or lockf(3).
2017 C<flock> is Perl's portable file-locking interface, although it locks
2018 entire files only, not records.
2019
2020 Two potentially non-obvious but traditional C<flock> semantics are
2021 that it waits indefinitely until the lock is granted, and that its locks
2022 are B<merely advisory>.  Such discretionary locks are more flexible, but
2023 offer fewer guarantees.  This means that programs that do not also use
2024 C<flock> may modify files locked with C<flock>.  See L<perlport>, 
2025 your port's specific documentation, and your system-specific local manpages
2026 for details.  It's best to assume traditional behavior if you're writing
2027 portable programs.  (But if you're not, you should as always feel perfectly
2028 free to write for your own system's idiosyncrasies (sometimes called
2029 "features").  Slavish adherence to portability concerns shouldn't get
2030 in the way of your getting your job done.)
2031
2032 OPERATION is one of LOCK_SH, LOCK_EX, or LOCK_UN, possibly combined with
2033 LOCK_NB.  These constants are traditionally valued 1, 2, 8 and 4, but
2034 you can use the symbolic names if you import them from the L<Fcntl> module,
2035 either individually, or as a group using the C<:flock> tag.  LOCK_SH
2036 requests a shared lock, LOCK_EX requests an exclusive lock, and LOCK_UN
2037 releases a previously requested lock.  If LOCK_NB is bitwise-or'ed with
2038 LOCK_SH or LOCK_EX, then C<flock> returns immediately rather than blocking
2039 waiting for the lock; check the return status to see if you got it.
2040
2041 To avoid the possibility of miscoordination, Perl now flushes FILEHANDLE
2042 before locking or unlocking it.
2043
2044 Note that the emulation built with lockf(3) doesn't provide shared
2045 locks, and it requires that FILEHANDLE be open with write intent.  These
2046 are the semantics that lockf(3) implements.  Most if not all systems
2047 implement lockf(3) in terms of fcntl(2) locking, though, so the
2048 differing semantics shouldn't bite too many people.
2049
2050 Note that the fcntl(2) emulation of flock(3) requires that FILEHANDLE
2051 be open with read intent to use LOCK_SH and requires that it be open
2052 with write intent to use LOCK_EX.
2053
2054 Note also that some versions of C<flock> cannot lock things over the
2055 network; you would need to use the more system-specific C<fcntl> for
2056 that.  If you like you can force Perl to ignore your system's flock(2)
2057 function, and so provide its own fcntl(2)-based emulation, by passing
2058 the switch C<-Ud_flock> to the F<Configure> program when you configure
2059 and build a new Perl.
2060
2061 Here's a mailbox appender for BSD systems.
2062
2063     use Fcntl qw(:flock SEEK_END); # import LOCK_* and SEEK_END constants
2064
2065     sub lock {
2066         my ($fh) = @_;
2067         flock($fh, LOCK_EX) or die "Cannot lock mailbox - $!\n";
2068
2069         # and, in case someone appended while we were waiting...
2070         seek($fh, 0, SEEK_END) or die "Cannot seek - $!\n";
2071     }
2072
2073     sub unlock {
2074         my ($fh) = @_;
2075         flock($fh, LOCK_UN) or die "Cannot unlock mailbox - $!\n";
2076     }
2077
2078     open(my $mbox, ">>", "/usr/spool/mail/$ENV{'USER'}")
2079         or die "Can't open mailbox: $!";
2080
2081     lock($mbox);
2082     print $mbox $msg,"\n\n";
2083     unlock($mbox);
2084
2085 On systems that support a real flock(2), locks are inherited across fork()
2086 calls, whereas those that must resort to the more capricious fcntl(2)
2087 function lose their locks, making it seriously harder to write servers.
2088
2089 See also L<DB_File> for other flock() examples.
2090
2091 Portability issues: L<perlport/flock>.
2092
2093 =item fork
2094 X<fork> X<child> X<parent>
2095
2096 Does a fork(2) system call to create a new process running the
2097 same program at the same point.  It returns the child pid to the
2098 parent process, C<0> to the child process, or C<undef> if the fork is
2099 unsuccessful.  File descriptors (and sometimes locks on those descriptors)
2100 are shared, while everything else is copied.  On most systems supporting
2101 fork(), great care has gone into making it extremely efficient (for
2102 example, using copy-on-write technology on data pages), making it the
2103 dominant paradigm for multitasking over the last few decades.
2104
2105 Beginning with v5.6.0, Perl attempts to flush all files opened for
2106 output before forking the child process, but this may not be supported
2107 on some platforms (see L<perlport>).  To be safe, you may need to set
2108 C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method of
2109 C<IO::Handle> on any open handles to avoid duplicate output.
2110
2111 If you C<fork> without ever waiting on your children, you will
2112 accumulate zombies.  On some systems, you can avoid this by setting
2113 C<$SIG{CHLD}> to C<"IGNORE">.  See also L<perlipc> for more examples of
2114 forking and reaping moribund children.
2115
2116 Note that if your forked child inherits system file descriptors like
2117 STDIN and STDOUT that are actually connected by a pipe or socket, even
2118 if you exit, then the remote server (such as, say, a CGI script or a
2119 backgrounded job launched from a remote shell) won't think you're done.
2120 You should reopen those to F</dev/null> if it's any issue.
2121
2122 On some platforms such as Windows, where the fork() system call is not available,
2123 Perl can be built to emulate fork() in the Perl interpreter. The emulation is designed to,
2124 at the level of the Perl program, be as compatible as possible with the "Unix" fork().
2125 However it has limitations that have to be considered in code intended to be portable.
2126 See L<perlfork> for more details.
2127
2128 Portability issues: L<perlport/fork>.
2129
2130 =item format
2131 X<format>
2132
2133 Declare a picture format for use by the C<write> function.  For
2134 example:
2135
2136     format Something =
2137         Test: @<<<<<<<< @||||| @>>>>>
2138               $str,     $%,    '$' . int($num)
2139     .
2140
2141     $str = "widget";
2142     $num = $cost/$quantity;
2143     $~ = 'Something';
2144     write;
2145
2146 See L<perlform> for many details and examples.
2147
2148 =item formline PICTURE,LIST
2149 X<formline>
2150
2151 This is an internal function used by C<format>s, though you may call it,
2152 too.  It formats (see L<perlform>) a list of values according to the
2153 contents of PICTURE, placing the output into the format output
2154 accumulator, C<$^A> (or C<$ACCUMULATOR> in English).
2155 Eventually, when a C<write> is done, the contents of
2156 C<$^A> are written to some filehandle.  You could also read C<$^A>
2157 and then set C<$^A> back to C<"">.  Note that a format typically
2158 does one C<formline> per line of form, but the C<formline> function itself
2159 doesn't care how many newlines are embedded in the PICTURE.  This means
2160 that the C<~> and C<~~> tokens treat the entire PICTURE as a single line.
2161 You may therefore need to use multiple formlines to implement a single
2162 record format, just like the C<format> compiler.
2163
2164 Be careful if you put double quotes around the picture, because an C<@>
2165 character may be taken to mean the beginning of an array name.
2166 C<formline> always returns true.  See L<perlform> for other examples.
2167
2168 If you are trying to use this instead of C<write> to capture the output,
2169 you may find it easier to open a filehandle to a scalar
2170 (C<< open $fh, ">", \$output >>) and write to that instead.
2171
2172 =item getc FILEHANDLE
2173 X<getc> X<getchar> X<character> X<file, read>
2174
2175 =item getc
2176
2177 Returns the next character from the input file attached to FILEHANDLE,
2178 or the undefined value at end of file or if there was an error (in
2179 the latter case C<$!> is set).  If FILEHANDLE is omitted, reads from
2180 STDIN.  This is not particularly efficient.  However, it cannot be
2181 used by itself to fetch single characters without waiting for the user
2182 to hit enter.  For that, try something more like:
2183
2184     if ($BSD_STYLE) {
2185         system "stty cbreak </dev/tty >/dev/tty 2>&1";
2186     }
2187     else {
2188         system "stty", '-icanon', 'eol', "\001";
2189     }
2190
2191     $key = getc(STDIN);
2192
2193     if ($BSD_STYLE) {
2194         system "stty -cbreak </dev/tty >/dev/tty 2>&1";
2195     }
2196     else {
2197         system 'stty', 'icanon', 'eol', '^@'; # ASCII NUL
2198     }
2199     print "\n";
2200
2201 Determination of whether $BSD_STYLE should be set
2202 is left as an exercise to the reader.
2203
2204 The C<POSIX::getattr> function can do this more portably on
2205 systems purporting POSIX compliance.  See also the C<Term::ReadKey>
2206 module from your nearest CPAN site; details on CPAN can be found under
2207 L<perlmodlib/CPAN>.
2208
2209 =item getlogin
2210 X<getlogin> X<login>
2211
2212 This implements the C library function of the same name, which on most
2213 systems returns the current login from F</etc/utmp>, if any.  If it
2214 returns the empty string, use C<getpwuid>.
2215
2216     $login = getlogin || getpwuid($<) || "Kilroy";
2217
2218 Do not consider C<getlogin> for authentication: it is not as
2219 secure as C<getpwuid>.
2220
2221 Portability issues: L<perlport/getlogin>.
2222
2223 =item getpeername SOCKET
2224 X<getpeername> X<peer>
2225
2226 Returns the packed sockaddr address of the other end of the SOCKET
2227 connection.
2228
2229     use Socket;
2230     $hersockaddr    = getpeername(SOCK);
2231     ($port, $iaddr) = sockaddr_in($hersockaddr);
2232     $herhostname    = gethostbyaddr($iaddr, AF_INET);
2233     $herstraddr     = inet_ntoa($iaddr);
2234
2235 =item getpgrp PID
2236 X<getpgrp> X<group>
2237
2238 Returns the current process group for the specified PID.  Use
2239 a PID of C<0> to get the current process group for the
2240 current process.  Will raise an exception if used on a machine that
2241 doesn't implement getpgrp(2).  If PID is omitted, returns the process
2242 group of the current process.  Note that the POSIX version of C<getpgrp>
2243 does not accept a PID argument, so only C<PID==0> is truly portable.
2244
2245 Portability issues: L<perlport/getpgrp>.
2246
2247 =item getppid
2248 X<getppid> X<parent> X<pid>
2249
2250 Returns the process id of the parent process.
2251
2252 Note for Linux users: on Linux, the C functions C<getpid()> and
2253 C<getppid()> return different values from different threads. In order to
2254 be portable, this behavior is not reflected by the Perl-level function
2255 C<getppid()>, that returns a consistent value across threads. If you want
2256 to call the underlying C<getppid()>, you may use the CPAN module
2257 C<Linux::Pid>.
2258
2259 Portability issues: L<perlport/getppid>.
2260
2261 =item getpriority WHICH,WHO
2262 X<getpriority> X<priority> X<nice>
2263
2264 Returns the current priority for a process, a process group, or a user.
2265 (See L<getpriority(2)>.)  Will raise a fatal exception if used on a
2266 machine that doesn't implement getpriority(2).
2267
2268 Portability issues: L<perlport/getpriority>.
2269
2270 =item getpwnam NAME
2271 X<getpwnam> X<getgrnam> X<gethostbyname> X<getnetbyname> X<getprotobyname>
2272 X<getpwuid> X<getgrgid> X<getservbyname> X<gethostbyaddr> X<getnetbyaddr>
2273 X<getprotobynumber> X<getservbyport> X<getpwent> X<getgrent> X<gethostent>
2274 X<getnetent> X<getprotoent> X<getservent> X<setpwent> X<setgrent> X<sethostent>
2275 X<setnetent> X<setprotoent> X<setservent> X<endpwent> X<endgrent> X<endhostent>
2276 X<endnetent> X<endprotoent> X<endservent> 
2277
2278 =item getgrnam NAME
2279
2280 =item gethostbyname NAME
2281
2282 =item getnetbyname NAME
2283
2284 =item getprotobyname NAME
2285
2286 =item getpwuid UID
2287
2288 =item getgrgid GID
2289
2290 =item getservbyname NAME,PROTO
2291
2292 =item gethostbyaddr ADDR,ADDRTYPE
2293
2294 =item getnetbyaddr ADDR,ADDRTYPE
2295
2296 =item getprotobynumber NUMBER
2297
2298 =item getservbyport PORT,PROTO
2299
2300 =item getpwent
2301
2302 =item getgrent
2303
2304 =item gethostent
2305
2306 =item getnetent
2307
2308 =item getprotoent
2309
2310 =item getservent
2311
2312 =item setpwent
2313
2314 =item setgrent
2315
2316 =item sethostent STAYOPEN
2317
2318 =item setnetent STAYOPEN
2319
2320 =item setprotoent STAYOPEN
2321
2322 =item setservent STAYOPEN
2323
2324 =item endpwent
2325
2326 =item endgrent
2327
2328 =item endhostent
2329
2330 =item endnetent
2331
2332 =item endprotoent
2333
2334 =item endservent
2335
2336 These routines are the same as their counterparts in the
2337 system C library.  In list context, the return values from the
2338 various get routines are as follows:
2339
2340     ($name,$passwd,$uid,$gid,
2341        $quota,$comment,$gcos,$dir,$shell,$expire) = getpw*
2342     ($name,$passwd,$gid,$members) = getgr*
2343     ($name,$aliases,$addrtype,$length,@addrs) = gethost*
2344     ($name,$aliases,$addrtype,$net) = getnet*
2345     ($name,$aliases,$proto) = getproto*
2346     ($name,$aliases,$port,$proto) = getserv*
2347
2348 (If the entry doesn't exist you get an empty list.)
2349
2350 The exact meaning of the $gcos field varies but it usually contains
2351 the real name of the user (as opposed to the login name) and other
2352 information pertaining to the user.  Beware, however, that in many
2353 system users are able to change this information and therefore it
2354 cannot be trusted and therefore the $gcos is tainted (see
2355 L<perlsec>).  The $passwd and $shell, user's encrypted password and
2356 login shell, are also tainted, for the same reason.
2357
2358 In scalar context, you get the name, unless the function was a
2359 lookup by name, in which case you get the other thing, whatever it is.
2360 (If the entry doesn't exist you get the undefined value.)  For example:
2361
2362     $uid   = getpwnam($name);
2363     $name  = getpwuid($num);
2364     $name  = getpwent();
2365     $gid   = getgrnam($name);
2366     $name  = getgrgid($num);
2367     $name  = getgrent();
2368     #etc.
2369
2370 In I<getpw*()> the fields $quota, $comment, and $expire are special
2371 in that they are unsupported on many systems.  If the
2372 $quota is unsupported, it is an empty scalar.  If it is supported, it
2373 usually encodes the disk quota.  If the $comment field is unsupported,
2374 it is an empty scalar.  If it is supported it usually encodes some
2375 administrative comment about the user.  In some systems the $quota
2376 field may be $change or $age, fields that have to do with password
2377 aging.  In some systems the $comment field may be $class.  The $expire
2378 field, if present, encodes the expiration period of the account or the
2379 password.  For the availability and the exact meaning of these fields
2380 in your system, please consult getpwnam(3) and your system's 
2381 F<pwd.h> file.  You can also find out from within Perl what your
2382 $quota and $comment fields mean and whether you have the $expire field
2383 by using the C<Config> module and the values C<d_pwquota>, C<d_pwage>,
2384 C<d_pwchange>, C<d_pwcomment>, and C<d_pwexpire>.  Shadow password
2385 files are supported only if your vendor has implemented them in the
2386 intuitive fashion that calling the regular C library routines gets the
2387 shadow versions if you're running under privilege or if there exists
2388 the shadow(3) functions as found in System V (this includes Solaris
2389 and Linux).  Those systems that implement a proprietary shadow password
2390 facility are unlikely to be supported.
2391
2392 The $members value returned by I<getgr*()> is a space-separated list of
2393 the login names of the members of the group.
2394
2395 For the I<gethost*()> functions, if the C<h_errno> variable is supported in
2396 C, it will be returned to you via C<$?> if the function call fails.  The
2397 C<@addrs> value returned by a successful call is a list of raw
2398 addresses returned by the corresponding library call.  In the
2399 Internet domain, each address is four bytes long; you can unpack it
2400 by saying something like:
2401
2402     ($a,$b,$c,$d) = unpack('W4',$addr[0]);
2403
2404 The Socket library makes this slightly easier:
2405
2406     use Socket;
2407     $iaddr = inet_aton("127.1"); # or whatever address
2408     $name  = gethostbyaddr($iaddr, AF_INET);
2409
2410     # or going the other way
2411     $straddr = inet_ntoa($iaddr);
2412
2413 In the opposite way, to resolve a hostname to the IP address
2414 you can write this:
2415
2416     use Socket;
2417     $packed_ip = gethostbyname("www.perl.org");
2418     if (defined $packed_ip) {
2419         $ip_address = inet_ntoa($packed_ip);
2420     }
2421
2422 Make sure C<gethostbyname()> is called in SCALAR context and that
2423 its return value is checked for definedness.
2424
2425 The C<getprotobynumber> function, even though it only takes one argument,
2426 has the precedence of a list operator, so beware:
2427
2428     getprotobynumber $number eq 'icmp'   # WRONG
2429     getprotobynumber($number eq 'icmp')  # actually means this
2430     getprotobynumber($number) eq 'icmp'  # better this way
2431
2432 If you get tired of remembering which element of the return list
2433 contains which return value, by-name interfaces are provided
2434 in standard modules: C<File::stat>, C<Net::hostent>, C<Net::netent>,
2435 C<Net::protoent>, C<Net::servent>, C<Time::gmtime>, C<Time::localtime>,
2436 and C<User::grent>.  These override the normal built-ins, supplying
2437 versions that return objects with the appropriate names
2438 for each field.  For example:
2439
2440    use File::stat;
2441    use User::pwent;
2442    $is_his = (stat($filename)->uid == pwent($whoever)->uid);
2443
2444 Even though it looks as though they're the same method calls (uid),
2445 they aren't, because a C<File::stat> object is different from
2446 a C<User::pwent> object.
2447
2448 Portability issues: L<perlport/getpwnam> to L<perlport/endservent>.
2449
2450 =item getsockname SOCKET
2451 X<getsockname>
2452
2453 Returns the packed sockaddr address of this end of the SOCKET connection,
2454 in case you don't know the address because you have several different
2455 IPs that the connection might have come in on.
2456
2457     use Socket;
2458     $mysockaddr = getsockname(SOCK);
2459     ($port, $myaddr) = sockaddr_in($mysockaddr);
2460     printf "Connect to %s [%s]\n",
2461        scalar gethostbyaddr($myaddr, AF_INET),
2462        inet_ntoa($myaddr);
2463
2464 =item getsockopt SOCKET,LEVEL,OPTNAME
2465 X<getsockopt>
2466
2467 Queries the option named OPTNAME associated with SOCKET at a given LEVEL.
2468 Options may exist at multiple protocol levels depending on the socket
2469 type, but at least the uppermost socket level SOL_SOCKET (defined in the
2470 C<Socket> module) will exist. To query options at another level the
2471 protocol number of the appropriate protocol controlling the option
2472 should be supplied. For example, to indicate that an option is to be
2473 interpreted by the TCP protocol, LEVEL should be set to the protocol
2474 number of TCP, which you can get using C<getprotobyname>.
2475
2476 The function returns a packed string representing the requested socket
2477 option, or C<undef> on error, with the reason for the error placed in
2478 C<$!>. Just what is in the packed string depends on LEVEL and OPTNAME;
2479 consult getsockopt(2) for details.  A common case is that the option is an
2480 integer, in which case the result is a packed integer, which you can decode
2481 using C<unpack> with the C<i> (or C<I>) format.
2482
2483 Here's an example to test whether Nagle's algorithm is enabled on a socket:
2484
2485     use Socket qw(:all);
2486
2487     defined(my $tcp = getprotobyname("tcp"))
2488         or die "Could not determine the protocol number for tcp";
2489     # my $tcp = IPPROTO_TCP; # Alternative
2490     my $packed = getsockopt($socket, $tcp, TCP_NODELAY)
2491         or die "getsockopt TCP_NODELAY: $!";
2492     my $nodelay = unpack("I", $packed);
2493     print "Nagle's algorithm is turned ", $nodelay ? "off\n" : "on\n";
2494
2495 Portability issues: L<perlport/getsockopt>.
2496
2497 =item given EXPR BLOCK
2498 X<given>
2499
2500 =item given BLOCK
2501
2502 C<given> is analogous to the C<switch> keyword in other languages. C<given>
2503 and C<when> are used in Perl to implement C<switch>/C<case> like statements.
2504 Only available after Perl 5.10.  For example:
2505
2506     use v5.10;
2507     given ($fruit) {
2508         when (/apples?/) {
2509             print "I like apples."
2510         }
2511         when (/oranges?/) {
2512             print "I don't like oranges."
2513         }
2514         default {
2515             print "I don't like anything"
2516         }
2517     }
2518
2519 See L<perlsyn/"Switch statements"> for detailed information.
2520
2521 =item glob EXPR
2522 X<glob> X<wildcard> X<filename, expansion> X<expand>
2523
2524 =item glob
2525
2526 In list context, returns a (possibly empty) list of filename expansions on
2527 the value of EXPR such as the standard Unix shell F</bin/csh> would do. In
2528 scalar context, glob iterates through such filename expansions, returning
2529 undef when the list is exhausted. This is the internal function
2530 implementing the C<< <*.c> >> operator, but you can use it directly. If
2531 EXPR is omitted, C<$_> is used.  The C<< <*.c> >> operator is discussed in
2532 more detail in L<perlop/"I/O Operators">.
2533
2534 Note that C<glob> splits its arguments on whitespace and treats
2535 each segment as separate pattern.  As such, C<glob("*.c *.h")> 
2536 matches all files with a F<.c> or F<.h> extension.  The expression
2537 C<glob(".* *")> matches all files in the current working directory.
2538
2539 If non-empty braces are the only wildcard characters used in the
2540 C<glob>, no filenames are matched, but potentially many strings
2541 are returned.  For example, this produces nine strings, one for
2542 each pairing of fruits and colors:
2543
2544     @many =  glob "{apple,tomato,cherry}={green,yellow,red}";
2545
2546 Beginning with v5.6.0, this operator is implemented using the standard
2547 C<File::Glob> extension.  See L<File::Glob> for details, including
2548 C<bsd_glob> which does not treat whitespace as a pattern separator.
2549
2550 Portability issues: L<perlport/glob>.
2551
2552 =item gmtime EXPR
2553 X<gmtime> X<UTC> X<Greenwich>
2554
2555 =item gmtime
2556
2557 Works just like L</localtime> but the returned values are
2558 localized for the standard Greenwich time zone.
2559
2560 Note: When called in list context, $isdst, the last value
2561 returned by gmtime, is always C<0>.  There is no
2562 Daylight Saving Time in GMT.
2563
2564 Portability issues: L<perlport/gmtime>.
2565
2566 =item goto LABEL
2567 X<goto> X<jump> X<jmp>
2568
2569 =item goto EXPR
2570
2571 =item goto &NAME
2572
2573 The C<goto-LABEL> form finds the statement labeled with LABEL and
2574 resumes execution there. It can't be used to get out of a block or
2575 subroutine given to C<sort>.  It can be used to go almost anywhere
2576 else within the dynamic scope, including out of subroutines, but it's
2577 usually better to use some other construct such as C<last> or C<die>.
2578 The author of Perl has never felt the need to use this form of C<goto>
2579 (in Perl, that is; C is another matter).  (The difference is that C
2580 does not offer named loops combined with loop control.  Perl does, and
2581 this replaces most structured uses of C<goto> in other languages.)
2582
2583 The C<goto-EXPR> form expects a label name, whose scope will be resolved
2584 dynamically.  This allows for computed C<goto>s per FORTRAN, but isn't
2585 necessarily recommended if you're optimizing for maintainability:
2586
2587     goto ("FOO", "BAR", "GLARCH")[$i];
2588
2589 As shown in this example, C<goto-EXPR> is exempt from the "looks like a
2590 function" rule. A pair of parentheses following it does not (necessarily)
2591 delimit its argument. C<goto("NE")."XT"> is equivalent to C<goto NEXT>.
2592
2593 Use of C<goto-LABEL> or C<goto-EXPR> to jump into a construct is
2594 deprecated and will issue a warning.  Even then, it may not be used to
2595 go into any construct that requires initialization, such as a
2596 subroutine or a C<foreach> loop.  It also can't be used to go into a
2597 construct that is optimized away.
2598
2599 The C<goto-&NAME> form is quite different from the other forms of
2600 C<goto>.  In fact, it isn't a goto in the normal sense at all, and
2601 doesn't have the stigma associated with other gotos.  Instead, it
2602 exits the current subroutine (losing any changes set by local()) and
2603 immediately calls in its place the named subroutine using the current
2604 value of @_.  This is used by C<AUTOLOAD> subroutines that wish to
2605 load another subroutine and then pretend that the other subroutine had
2606 been called in the first place (except that any modifications to C<@_>
2607 in the current subroutine are propagated to the other subroutine.)
2608 After the C<goto>, not even C<caller> will be able to tell that this
2609 routine was called first.
2610
2611 NAME needn't be the name of a subroutine; it can be a scalar variable
2612 containing a code reference or a block that evaluates to a code
2613 reference.
2614
2615 =item grep BLOCK LIST
2616 X<grep>
2617
2618 =item grep EXPR,LIST
2619
2620 This is similar in spirit to, but not the same as, grep(1) and its
2621 relatives.  In particular, it is not limited to using regular expressions.
2622
2623 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
2624 C<$_> to each element) and returns the list value consisting of those
2625 elements for which the expression evaluated to true.  In scalar
2626 context, returns the number of times the expression was true.
2627
2628     @foo = grep(!/^#/, @bar);    # weed out comments
2629
2630 or equivalently,
2631
2632     @foo = grep {!/^#/} @bar;    # weed out comments
2633
2634 Note that C<$_> is an alias to the list value, so it can be used to
2635 modify the elements of the LIST.  While this is useful and supported,
2636 it can cause bizarre results if the elements of LIST are not variables.
2637 Similarly, grep returns aliases into the original list, much as a for
2638 loop's index variable aliases the list elements.  That is, modifying an
2639 element of a list returned by grep (for example, in a C<foreach>, C<map>
2640 or another C<grep>) actually modifies the element in the original list.
2641 This is usually something to be avoided when writing clear code.
2642
2643 If C<$_> is lexical in the scope where the C<grep> appears (because it has
2644 been declared with C<my $_>) then, in addition to being locally aliased to
2645 the list elements, C<$_> keeps being lexical inside the block; i.e., it
2646 can't be seen from the outside, avoiding any potential side-effects.
2647
2648 See also L</map> for a list composed of the results of the BLOCK or EXPR.
2649
2650 =item hex EXPR
2651 X<hex> X<hexadecimal>
2652
2653 =item hex
2654
2655 Interprets EXPR as a hex string and returns the corresponding value.
2656 (To convert strings that might start with either C<0>, C<0x>, or C<0b>, see
2657 L</oct>.)  If EXPR is omitted, uses C<$_>.
2658
2659     print hex '0xAf'; # prints '175'
2660     print hex 'aF';   # same
2661
2662 Hex strings may only represent integers.  Strings that would cause
2663 integer overflow trigger a warning.  Leading whitespace is not stripped,
2664 unlike oct(). To present something as hex, look into L</printf>,
2665 L</sprintf>, and L</unpack>.
2666
2667 =item import LIST
2668 X<import>
2669
2670 There is no builtin C<import> function.  It is just an ordinary
2671 method (subroutine) defined (or inherited) by modules that wish to export
2672 names to another module.  The C<use> function calls the C<import> method
2673 for the package used.  See also L</use>, L<perlmod>, and L<Exporter>.
2674
2675 =item index STR,SUBSTR,POSITION
2676 X<index> X<indexOf> X<InStr>
2677
2678 =item index STR,SUBSTR
2679
2680 The index function searches for one string within another, but without
2681 the wildcard-like behavior of a full regular-expression pattern match.
2682 It returns the position of the first occurrence of SUBSTR in STR at
2683 or after POSITION.  If POSITION is omitted, starts searching from the
2684 beginning of the string.  POSITION before the beginning of the string
2685 or after its end is treated as if it were the beginning or the end,
2686 respectively.  POSITION and the return value are based at zero.
2687 If the substring is not found, C<index> returns -1.
2688
2689 =item int EXPR
2690 X<int> X<integer> X<truncate> X<trunc> X<floor>
2691
2692 =item int
2693
2694 Returns the integer portion of EXPR.  If EXPR is omitted, uses C<$_>.
2695 You should not use this function for rounding: one because it truncates
2696 towards C<0>, and two because machine representations of floating-point
2697 numbers can sometimes produce counterintuitive results.  For example,
2698 C<int(-6.725/0.025)> produces -268 rather than the correct -269; that's
2699 because it's really more like -268.99999999999994315658 instead.  Usually,
2700 the C<sprintf>, C<printf>, or the C<POSIX::floor> and C<POSIX::ceil>
2701 functions will serve you better than will int().
2702
2703 =item ioctl FILEHANDLE,FUNCTION,SCALAR
2704 X<ioctl>
2705
2706 Implements the ioctl(2) function.  You'll probably first have to say
2707
2708     require "sys/ioctl.ph";  # probably in $Config{archlib}/sys/ioctl.ph
2709
2710 to get the correct function definitions.  If F<sys/ioctl.ph> doesn't
2711 exist or doesn't have the correct definitions you'll have to roll your
2712 own, based on your C header files such as F<< <sys/ioctl.h> >>.
2713 (There is a Perl script called B<h2ph> that comes with the Perl kit that
2714 may help you in this, but it's nontrivial.)  SCALAR will be read and/or
2715 written depending on the FUNCTION; a C pointer to the string value of SCALAR
2716 will be passed as the third argument of the actual C<ioctl> call.  (If SCALAR
2717 has no string value but does have a numeric value, that value will be
2718 passed rather than a pointer to the string value.  To guarantee this to be
2719 true, add a C<0> to the scalar before using it.)  The C<pack> and C<unpack>
2720 functions may be needed to manipulate the values of structures used by
2721 C<ioctl>.
2722
2723 The return value of C<ioctl> (and C<fcntl>) is as follows:
2724
2725     if OS returns:      then Perl returns:
2726         -1               undefined value
2727          0              string "0 but true"
2728     anything else           that number
2729
2730 Thus Perl returns true on success and false on failure, yet you can
2731 still easily determine the actual value returned by the operating
2732 system:
2733
2734     $retval = ioctl(...) || -1;
2735     printf "System returned %d\n", $retval;
2736
2737 The special string C<"0 but true"> is exempt from B<-w> complaints
2738 about improper numeric conversions.
2739
2740 Portability issues: L<perlport/ioctl>.
2741
2742 =item join EXPR,LIST
2743 X<join>
2744
2745 Joins the separate strings of LIST into a single string with fields
2746 separated by the value of EXPR, and returns that new string.  Example:
2747
2748     $rec = join(':', $login,$passwd,$uid,$gid,$gcos,$home,$shell);
2749
2750 Beware that unlike C<split>, C<join> doesn't take a pattern as its
2751 first argument.  Compare L</split>.
2752
2753 =item keys HASH
2754 X<keys> X<key>
2755
2756 =item keys ARRAY
2757
2758 =item keys EXPR
2759
2760 Returns a list consisting of all the keys of the named hash, or the indices
2761 of an array. (In scalar context, returns the number of keys or indices.)
2762
2763 The keys of a hash are returned in an apparently random order.  The actual
2764 random order is subject to change in future versions of Perl, but it
2765 is guaranteed to be the same order as either the C<values> or C<each>
2766 function produces (given that the hash has not been modified).  Since
2767 Perl 5.8.1 the ordering can be different even between different runs of
2768 Perl for security reasons (see L<perlsec/"Algorithmic Complexity
2769 Attacks">).
2770
2771 As a side effect, calling keys() resets the internal interator of the HASH or ARRAY
2772 (see L</each>).  In particular, calling keys() in void context resets
2773 the iterator with no other overhead.
2774
2775 Here is yet another way to print your environment:
2776
2777     @keys = keys %ENV;
2778     @values = values %ENV;
2779     while (@keys) {
2780         print pop(@keys), '=', pop(@values), "\n";
2781     }
2782
2783 or how about sorted by key:
2784
2785     foreach $key (sort(keys %ENV)) {
2786         print $key, '=', $ENV{$key}, "\n";
2787     }
2788
2789 The returned values are copies of the original keys in the hash, so
2790 modifying them will not affect the original hash.  Compare L</values>.
2791
2792 To sort a hash by value, you'll need to use a C<sort> function.
2793 Here's a descending numeric sort of a hash by its values:
2794
2795     foreach $key (sort { $hash{$b} <=> $hash{$a} } keys %hash) {
2796         printf "%4d %s\n", $hash{$key}, $key;
2797     }
2798
2799 Used as an lvalue, C<keys> allows you to increase the number of hash buckets
2800 allocated for the given hash.  This can gain you a measure of efficiency if
2801 you know the hash is going to get big.  (This is similar to pre-extending
2802 an array by assigning a larger number to $#array.)  If you say
2803
2804     keys %hash = 200;
2805
2806 then C<%hash> will have at least 200 buckets allocated for it--256 of them,
2807 in fact, since it rounds up to the next power of two.  These
2808 buckets will be retained even if you do C<%hash = ()>, use C<undef
2809 %hash> if you want to free the storage while C<%hash> is still in scope.
2810 You can't shrink the number of buckets allocated for the hash using
2811 C<keys> in this way (but you needn't worry about doing this by accident,
2812 as trying has no effect). C<keys @array> in an lvalue context is a syntax
2813 error.
2814
2815 Starting with Perl 5.14, C<keys> can take a scalar EXPR, which must contain
2816 a reference to an unblessed hash or array.  The argument will be
2817 dereferenced automatically.  This aspect of C<keys> is considered highly
2818 experimental.  The exact behaviour may change in a future version of Perl.
2819
2820     for (keys $hashref) { ... }
2821     for (keys $obj->get_arrayref) { ... }
2822
2823 See also C<each>, C<values>, and C<sort>.
2824
2825 =item kill SIGNAL, LIST
2826 X<kill> X<signal>
2827
2828 Sends a signal to a list of processes.  Returns the number of
2829 processes successfully signaled (which is not necessarily the
2830 same as the number actually killed).
2831
2832     $cnt = kill 1, $child1, $child2;
2833     kill 9, @goners;
2834
2835 If SIGNAL is zero, no signal is sent to the process, but C<kill>
2836 checks whether it's I<possible> to send a signal to it (that
2837 means, to be brief, that the process is owned by the same user, or we are
2838 the super-user).  This is useful to check that a child process is still
2839 alive (even if only as a zombie) and hasn't changed its UID.  See
2840 L<perlport> for notes on the portability of this construct.
2841
2842 Unlike in the shell, if SIGNAL is negative, it kills process groups instead
2843 of processes. That means you usually want to use positive not negative signals.
2844 You may also use a signal name in quotes.
2845
2846 The behavior of kill when a I<PROCESS> number is zero or negative depends on
2847 the operating system.  For example, on POSIX-conforming systems, zero will
2848 signal the current process group and -1 will signal all processes.
2849
2850 See L<perlipc/"Signals"> for more details.
2851
2852 On some platforms such as Windows where the fork() system call is not available.
2853 Perl can be built to emulate fork() at the interpreter level.
2854 This emulation has limitations related to kill that have to be considered,
2855 for code running on Windows and in code intended to be portable.
2856
2857 See L<perlfork> for more details.
2858
2859 Portability issues: L<perlport/kill>.
2860
2861 =item last LABEL
2862 X<last> X<break>
2863
2864 =item last
2865
2866 The C<last> command is like the C<break> statement in C (as used in
2867 loops); it immediately exits the loop in question.  If the LABEL is
2868 omitted, the command refers to the innermost enclosing loop.  The
2869 C<continue> block, if any, is not executed:
2870
2871     LINE: while (<STDIN>) {
2872         last LINE if /^$/;  # exit when done with header
2873         #...
2874     }
2875
2876 C<last> cannot be used to exit a block that returns a value such as
2877 C<eval {}>, C<sub {}>, or C<do {}>, and should not be used to exit
2878 a grep() or map() operation.
2879
2880 Note that a block by itself is semantically identical to a loop
2881 that executes once.  Thus C<last> can be used to effect an early
2882 exit out of such a block.
2883
2884 See also L</continue> for an illustration of how C<last>, C<next>, and
2885 C<redo> work.
2886
2887 =item lc EXPR
2888 X<lc> X<lowercase>
2889
2890 =item lc
2891
2892 Returns a lowercased version of EXPR.  This is the internal function
2893 implementing the C<\L> escape in double-quoted strings.
2894
2895 If EXPR is omitted, uses C<$_>.
2896
2897 What gets returned depends on several factors:
2898
2899 =over
2900
2901 =item If C<use bytes> is in effect:
2902
2903 =over
2904
2905 =item On EBCDIC platforms
2906
2907 The results are what the C language system call C<tolower()> returns.
2908
2909 =item On ASCII platforms
2910
2911 The results follow ASCII semantics.  Only characters C<A-Z> change, to C<a-z>
2912 respectively.
2913
2914 =back
2915
2916 =item Otherwise, If EXPR has the UTF8 flag set
2917
2918 Unicode semantics are used for the case change.
2919
2920 =item Otherwise, if C<use locale> is in effect
2921
2922 Respects current LC_CTYPE locale.  See L<perllocale>.
2923
2924 =item Otherwise, if C<use feature 'unicode_strings'> is in effect:
2925
2926 Unicode semantics are used for the case change.
2927
2928 =item Otherwise:
2929
2930 =over
2931
2932 =item On EBCDIC platforms
2933
2934 The results are what the C language system call C<tolower()> returns.
2935
2936 =item On ASCII platforms
2937
2938 ASCII semantics are used for the case change.  The lowercase of any character
2939 outside the ASCII range is the character itself.
2940
2941 =back
2942
2943 =back
2944
2945 =item lcfirst EXPR
2946 X<lcfirst> X<lowercase>
2947
2948 =item lcfirst
2949
2950 Returns the value of EXPR with the first character lowercased.  This
2951 is the internal function implementing the C<\l> escape in
2952 double-quoted strings.
2953
2954 If EXPR is omitted, uses C<$_>.
2955
2956 This function behaves the same way under various pragmata, such as in a locale,
2957 as L</lc> does.
2958
2959 =item length EXPR
2960 X<length> X<size>
2961
2962 =item length
2963
2964 Returns the length in I<characters> of the value of EXPR.  If EXPR is
2965 omitted, returns the length of C<$_>.  If EXPR is undefined, returns
2966 C<undef>.
2967
2968 This function cannot be used on an entire array or hash to find out how
2969 many elements these have.  For that, use C<scalar @array> and C<scalar keys
2970 %hash>, respectively.
2971
2972 Like all Perl character operations, length() normally deals in logical
2973 characters, not physical bytes.  For how many bytes a string encoded as
2974 UTF-8 would take up, use C<length(Encode::encode_utf8(EXPR))> (you'll have
2975 to C<use Encode> first).  See L<Encode> and L<perlunicode>.
2976
2977 =item __LINE__
2978 X<__LINE__>
2979
2980 A special token that compiles to the current line number.
2981
2982 =item link OLDFILE,NEWFILE
2983 X<link>
2984
2985 Creates a new filename linked to the old filename.  Returns true for
2986 success, false otherwise.
2987
2988 Portability issues: L<perlport/link>.
2989
2990 =item listen SOCKET,QUEUESIZE
2991 X<listen>
2992
2993 Does the same thing that the listen(2) system call does.  Returns true if
2994 it succeeded, false otherwise.  See the example in
2995 L<perlipc/"Sockets: Client/Server Communication">.
2996
2997 =item local EXPR
2998 X<local>
2999
3000 You really probably want to be using C<my> instead, because C<local> isn't
3001 what most people think of as "local".  See
3002 L<perlsub/"Private Variables via my()"> for details.
3003
3004 A local modifies the listed variables to be local to the enclosing
3005 block, file, or eval.  If more than one value is listed, the list must
3006 be placed in parentheses.  See L<perlsub/"Temporary Values via local()">
3007 for details, including issues with tied arrays and hashes.
3008
3009 The C<delete local EXPR> construct can also be used to localize the deletion
3010 of array/hash elements to the current block.
3011 See L<perlsub/"Localized deletion of elements of composite types">.
3012
3013 =item localtime EXPR
3014 X<localtime> X<ctime>
3015
3016 =item localtime
3017
3018 Converts a time as returned by the time function to a 9-element list
3019 with the time analyzed for the local time zone.  Typically used as
3020 follows:
3021
3022     #  0    1    2     3     4    5     6     7     8
3023     ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst) =
3024                                                 localtime(time);
3025
3026 All list elements are numeric and come straight out of the C `struct
3027 tm'.  C<$sec>, C<$min>, and C<$hour> are the seconds, minutes, and hours
3028 of the specified time.
3029
3030 C<$mday> is the day of the month and C<$mon> the month in
3031 the range C<0..11>, with 0 indicating January and 11 indicating December.
3032 This makes it easy to get a month name from a list:
3033
3034     my @abbr = qw( Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec );
3035     print "$abbr[$mon] $mday";
3036     # $mon=9, $mday=18 gives "Oct 18"
3037
3038 C<$year> is the number of years since 1900, B<not> just the last two digits
3039 of the year.  That is, C<$year> is C<123> in year 2023.  The proper way
3040 to get a 4-digit year is simply:
3041
3042     $year += 1900;
3043
3044 Otherwise you create non-Y2K-compliant programs--and you wouldn't want
3045 to do that, would you?
3046
3047 To get the last two digits of the year (e.g., "01" in 2001) do:
3048
3049     $year = sprintf("%02d", $year % 100);
3050
3051 C<$wday> is the day of the week, with 0 indicating Sunday and 3 indicating
3052 Wednesday.  C<$yday> is the day of the year, in the range C<0..364>
3053 (or C<0..365> in leap years.)
3054
3055 C<$isdst> is true if the specified time occurs during Daylight Saving
3056 Time, false otherwise.
3057
3058 If EXPR is omitted, C<localtime()> uses the current time (as returned
3059 by time(3)).
3060
3061 In scalar context, C<localtime()> returns the ctime(3) value:
3062
3063     $now_string = localtime;  # e.g., "Thu Oct 13 04:54:34 1994"
3064
3065 This scalar value is B<not> locale-dependent but is a Perl builtin. For GMT
3066 instead of local time use the L</gmtime> builtin. See also the
3067 C<Time::Local> module (for converting seconds, minutes, hours, and such back to
3068 the integer value returned by time()), and the L<POSIX> module's strftime(3)
3069 and mktime(3) functions.
3070
3071 To get somewhat similar but locale-dependent date strings, set up your
3072 locale environment variables appropriately (please see L<perllocale>) and
3073 try for example:
3074
3075     use POSIX qw(strftime);
3076     $now_string = strftime "%a %b %e %H:%M:%S %Y", localtime;
3077     # or for GMT formatted appropriately for your locale:
3078     $now_string = strftime "%a %b %e %H:%M:%S %Y", gmtime;
3079
3080 Note that the C<%a> and C<%b>, the short forms of the day of the week
3081 and the month of the year, may not necessarily be three characters wide.
3082
3083 The L<Time::gmtime> and L<Time::localtime> modules provide a convenient,
3084 by-name access mechanism to the gmtime() and localtime() functions,
3085 respectively.
3086
3087 For a comprehensive date and time representation look at the
3088 L<DateTime> module on CPAN.
3089
3090 Portability issues: L<perlport/localtime>.
3091
3092 =item lock THING
3093 X<lock>
3094
3095 This function places an advisory lock on a shared variable or referenced
3096 object contained in I<THING> until the lock goes out of scope.
3097
3098 The value returned is the scalar itself, if the argument is a scalar, or a
3099 reference, if the argument is a hash, array or subroutine.
3100
3101 lock() is a "weak keyword" : this means that if you've defined a function
3102 by this name (before any calls to it), that function will be called
3103 instead.  If you are not under C<use threads::shared> this does nothing.
3104 See L<threads::shared>.
3105
3106 =item log EXPR
3107 X<log> X<logarithm> X<e> X<ln> X<base>
3108
3109 =item log
3110
3111 Returns the natural logarithm (base I<e>) of EXPR.  If EXPR is omitted,
3112 returns the log of C<$_>.  To get the
3113 log of another base, use basic algebra:
3114 The base-N log of a number is equal to the natural log of that number
3115 divided by the natural log of N.  For example:
3116
3117     sub log10 {
3118         my $n = shift;
3119         return log($n)/log(10);
3120     }
3121
3122 See also L</exp> for the inverse operation.
3123
3124 =item lstat FILEHANDLE
3125 X<lstat>
3126
3127 =item lstat EXPR
3128
3129 =item lstat DIRHANDLE
3130
3131 =item lstat
3132
3133 Does the same thing as the C<stat> function (including setting the
3134 special C<_> filehandle) but stats a symbolic link instead of the file
3135 the symbolic link points to.  If symbolic links are unimplemented on
3136 your system, a normal C<stat> is done.  For much more detailed
3137 information, please see the documentation for C<stat>.
3138
3139 If EXPR is omitted, stats C<$_>.
3140
3141 Portability issues: L<perlport/lstat>.
3142
3143 =item m//
3144
3145 The match operator.  See L<perlop/"Regexp Quote-Like Operators">.
3146
3147 =item map BLOCK LIST
3148 X<map>
3149
3150 =item map EXPR,LIST
3151
3152 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
3153 C<$_> to each element) and returns the list value composed of the
3154 results of each such evaluation.  In scalar context, returns the
3155 total number of elements so generated.  Evaluates BLOCK or EXPR in
3156 list context, so each element of LIST may produce zero, one, or
3157 more elements in the returned value.
3158
3159     @chars = map(chr, @numbers);
3160
3161 translates a list of numbers to the corresponding characters.
3162
3163     my @squares = map { $_ * $_ } @numbers;
3164
3165 translates a list of numbers to their squared values.
3166
3167     my @squares = map { $_ > 5 ? ($_ * $_) : () } @numbers;
3168
3169 shows that number of returned elements can differ from the number of
3170 input elements. To omit an element, return an empty list ().
3171 This could also be achieved by writing
3172
3173     my @squares = map { $_ * $_ } grep { $_ > 5 } @numbers;
3174
3175 which makes the intention more clear.
3176
3177 Map always returns a list, which can be
3178 assigned to a hash such that the elements
3179 become key/value pairs. See L<perldata> for more details.
3180
3181     %hash = map { get_a_key_for($_) => $_ } @array;
3182
3183 is just a funny way to write
3184
3185     %hash = ();
3186     foreach (@array) {
3187         $hash{get_a_key_for($_)} = $_;
3188     }
3189
3190 Note that C<$_> is an alias to the list value, so it can be used to
3191 modify the elements of the LIST.  While this is useful and supported,
3192 it can cause bizarre results if the elements of LIST are not variables.
3193 Using a regular C<foreach> loop for this purpose would be clearer in
3194 most cases.  See also L</grep> for an array composed of those items of
3195 the original list for which the BLOCK or EXPR evaluates to true.
3196
3197 If C<$_> is lexical in the scope where the C<map> appears (because it has
3198 been declared with C<my $_>), then, in addition to being locally aliased to
3199 the list elements, C<$_> keeps being lexical inside the block; that is, it
3200 can't be seen from the outside, avoiding any potential side-effects.
3201
3202 C<{> starts both hash references and blocks, so C<map { ...> could be either
3203 the start of map BLOCK LIST or map EXPR, LIST. Because Perl doesn't look
3204 ahead for the closing C<}> it has to take a guess at which it's dealing with
3205 based on what it finds just after the C<{>. Usually it gets it right, but if it
3206 doesn't it won't realize something is wrong until it gets to the C<}> and
3207 encounters the missing (or unexpected) comma. The syntax error will be
3208 reported close to the C<}>, but you'll need to change something near the C<{>
3209 such as using a unary C<+> to give Perl some help:
3210
3211     %hash = map {  "\L$_" => 1  } @array  # perl guesses EXPR.  wrong
3212     %hash = map { +"\L$_" => 1  } @array  # perl guesses BLOCK. right
3213     %hash = map { ("\L$_" => 1) } @array  # this also works
3214     %hash = map {  lc($_) => 1  } @array  # as does this.
3215     %hash = map +( lc($_) => 1 ), @array  # this is EXPR and works!
3216
3217     %hash = map  ( lc($_), 1 ),   @array  # evaluates to (1, @array)
3218
3219 or to force an anon hash constructor use C<+{>:
3220
3221    @hashes = map +{ lc($_) => 1 }, @array # EXPR, so needs comma at end
3222
3223 to get a list of anonymous hashes each with only one entry apiece.
3224
3225 =item mkdir FILENAME,MASK
3226 X<mkdir> X<md> X<directory, create>
3227
3228 =item mkdir FILENAME
3229
3230 =item mkdir
3231
3232 Creates the directory specified by FILENAME, with permissions
3233 specified by MASK (as modified by C<umask>).  If it succeeds it
3234 returns true; otherwise it returns false and sets C<$!> (errno).
3235 MASK defaults to 0777 if omitted, and FILENAME defaults
3236 to C<$_> if omitted.
3237
3238 In general, it is better to create directories with a permissive MASK
3239 and let the user modify that with their C<umask> than it is to supply
3240 a restrictive MASK and give the user no way to be more permissive.
3241 The exceptions to this rule are when the file or directory should be
3242 kept private (mail files, for instance).  The perlfunc(1) entry on
3243 C<umask> discusses the choice of MASK in more detail.
3244
3245 Note that according to the POSIX 1003.1-1996 the FILENAME may have any
3246 number of trailing slashes.  Some operating and filesystems do not get
3247 this right, so Perl automatically removes all trailing slashes to keep
3248 everyone happy.
3249
3250 To recursively create a directory structure, look at
3251 the C<mkpath> function of the L<File::Path> module.
3252
3253 =item msgctl ID,CMD,ARG
3254 X<msgctl>
3255
3256 Calls the System V IPC function msgctl(2).  You'll probably have to say
3257
3258     use IPC::SysV;
3259
3260 first to get the correct constant definitions.  If CMD is C<IPC_STAT>,
3261 then ARG must be a variable that will hold the returned C<msqid_ds>
3262 structure.  Returns like C<ioctl>: the undefined value for error,
3263 C<"0 but true"> for zero, or the actual return value otherwise.  See also
3264 L<perlipc/"SysV IPC"> and the documentation for C<IPC::SysV> and
3265 C<IPC::Semaphore>.
3266
3267 Portability issues: L<perlport/msgctl>.
3268
3269 =item msgget KEY,FLAGS
3270 X<msgget>
3271
3272 Calls the System V IPC function msgget(2).  Returns the message queue
3273 id, or C<undef> on error.  See also
3274 L<perlipc/"SysV IPC"> and the documentation for C<IPC::SysV> and
3275 C<IPC::Msg>.
3276
3277 Portability issues: L<perlport/msgget>.
3278
3279 =item msgrcv ID,VAR,SIZE,TYPE,FLAGS
3280 X<msgrcv>
3281
3282 Calls the System V IPC function msgrcv to receive a message from
3283 message queue ID into variable VAR with a maximum message size of
3284 SIZE.  Note that when a message is received, the message type as a
3285 native long integer will be the first thing in VAR, followed by the
3286 actual message.  This packing may be opened with C<unpack("l! a*")>.
3287 Taints the variable.  Returns true if successful, false 
3288 on error.  See also L<perlipc/"SysV IPC"> and the documentation for
3289 C<IPC::SysV> and C<IPC::SysV::Msg>.
3290
3291 Portability issues: L<perlport/msgrcv>.
3292
3293 =item msgsnd ID,MSG,FLAGS
3294 X<msgsnd>
3295
3296 Calls the System V IPC function msgsnd to send the message MSG to the
3297 message queue ID.  MSG must begin with the native long integer message
3298 type, be followed by the length of the actual message, and then finally
3299 the message itself.  This kind of packing can be achieved with
3300 C<pack("l! a*", $type, $message)>.  Returns true if successful,
3301 false on error.  See also the C<IPC::SysV>
3302 and C<IPC::SysV::Msg> documentation.
3303
3304 Portability issues: L<perlport/msgsnd>.
3305
3306 =item my EXPR
3307 X<my>
3308
3309 =item my TYPE EXPR
3310
3311 =item my EXPR : ATTRS
3312
3313 =item my TYPE EXPR : ATTRS
3314
3315 A C<my> declares the listed variables to be local (lexically) to the
3316 enclosing block, file, or C<eval>.  If more than one value is listed,
3317 the list must be placed in parentheses.
3318
3319 The exact semantics and interface of TYPE and ATTRS are still
3320 evolving.  TYPE is currently bound to the use of the C<fields> pragma,
3321 and attributes are handled using the C<attributes> pragma, or starting
3322 from Perl 5.8.0 also via the C<Attribute::Handlers> module.  See
3323 L<perlsub/"Private Variables via my()"> for details, and L<fields>,
3324 L<attributes>, and L<Attribute::Handlers>.
3325
3326 =item next LABEL
3327 X<next> X<continue>
3328
3329 =item next
3330
3331 The C<next> command is like the C<continue> statement in C; it starts
3332 the next iteration of the loop:
3333
3334     LINE: while (<STDIN>) {
3335         next LINE if /^#/;  # discard comments
3336         #...
3337     }
3338
3339 Note that if there were a C<continue> block on the above, it would get
3340 executed even on discarded lines.  If LABEL is omitted, the command
3341 refers to the innermost enclosing loop.
3342
3343 C<next> cannot be used to exit a block which returns a value such as
3344 C<eval {}>, C<sub {}>, or C<do {}>, and should not be used to exit
3345 a grep() or map() operation.
3346
3347 Note that a block by itself is semantically identical to a loop
3348 that executes once.  Thus C<next> will exit such a block early.
3349
3350 See also L</continue> for an illustration of how C<last>, C<next>, and
3351 C<redo> work.
3352
3353 =item no MODULE VERSION LIST
3354 X<no declarations>
3355 X<unimporting>
3356
3357 =item no MODULE VERSION
3358
3359 =item no MODULE LIST
3360
3361 =item no MODULE
3362
3363 =item no VERSION
3364
3365 See the C<use> function, of which C<no> is the opposite.
3366
3367 =item oct EXPR
3368 X<oct> X<octal> X<hex> X<hexadecimal> X<binary> X<bin>
3369
3370 =item oct
3371
3372 Interprets EXPR as an octal string and returns the corresponding
3373 value.  (If EXPR happens to start off with C<0x>, interprets it as a
3374 hex string.  If EXPR starts off with C<0b>, it is interpreted as a
3375 binary string.  Leading whitespace is ignored in all three cases.)
3376 The following will handle decimal, binary, octal, and hex in standard
3377 Perl notation:
3378
3379     $val = oct($val) if $val =~ /^0/;
3380
3381 If EXPR is omitted, uses C<$_>.   To go the other way (produce a number
3382 in octal), use sprintf() or printf():
3383
3384     $dec_perms = (stat("filename"))[2] & 07777;
3385     $oct_perm_str = sprintf "%o", $perms;
3386
3387 The oct() function is commonly used when a string such as C<644> needs
3388 to be converted into a file mode, for example.  Although Perl 
3389 automatically converts strings into numbers as needed, this automatic
3390 conversion assumes base 10.
3391
3392 Leading white space is ignored without warning, as too are any trailing 
3393 non-digits, such as a decimal point (C<oct> only handles non-negative
3394 integers, not negative integers or floating point).
3395
3396 =item open FILEHANDLE,EXPR
3397 X<open> X<pipe> X<file, open> X<fopen>
3398
3399 =item open FILEHANDLE,MODE,EXPR
3400
3401 =item open FILEHANDLE,MODE,EXPR,LIST
3402
3403 =item open FILEHANDLE,MODE,REFERENCE
3404
3405 =item open FILEHANDLE
3406
3407 Opens the file whose filename is given by EXPR, and associates it with
3408 FILEHANDLE.
3409
3410 Simple examples to open a file for reading:
3411
3412     open(my $fh, "<", "input.txt") 
3413         or die "cannot open < input.txt: $!";
3414
3415 and for writing:
3416
3417     open(my $fh, ">", "output.txt") 
3418         or die "cannot open > output.txt: $!";
3419
3420 (The following is a comprehensive reference to open(): for a gentler
3421 introduction you may consider L<perlopentut>.)
3422
3423 If FILEHANDLE is an undefined scalar variable (or array or hash element), a
3424 new filehandle is autovivified, meaning that the variable is assigned a
3425 reference to a newly allocated anonymous filehandle.  Otherwise if
3426 FILEHANDLE is an expression, its value is the real filehandle.  (This is
3427 considered a symbolic reference, so C<use strict "refs"> should I<not> be
3428 in effect.)
3429
3430 If EXPR is omitted, the global (package) scalar variable of the same
3431 name as the FILEHANDLE contains the filename.  (Note that lexical 
3432 variables--those declared with C<my> or C<state>--will not work for this
3433 purpose; so if you're using C<my> or C<state>, specify EXPR in your
3434 call to open.)
3435
3436 If three (or more) arguments are specified, the open mode (including
3437 optional encoding) in the second argument are distinct from the filename in
3438 the third.  If MODE is C<< < >> or nothing, the file is opened for input.
3439 If MODE is C<< > >>, the file is opened for output, with existing files
3440 first being truncated ("clobbered") and nonexisting files newly created.
3441 If MODE is C<<< >> >>>, the file is opened for appending, again being
3442 created if necessary.
3443
3444 You can put a C<+> in front of the C<< > >> or C<< < >> to
3445 indicate that you want both read and write access to the file; thus
3446 C<< +< >> is almost always preferred for read/write updates--the 
3447 C<< +> >> mode would clobber the file first.  You cant usually use
3448 either read-write mode for updating textfiles, since they have
3449 variable-length records.  See the B<-i> switch in L<perlrun> for a
3450 better approach.  The file is created with permissions of C<0666>
3451 modified by the process's C<umask> value.
3452
3453 These various prefixes correspond to the fopen(3) modes of C<r>,
3454 C<r+>, C<w>, C<w+>, C<a>, and C<a+>.
3455
3456 In the one- and two-argument forms of the call, the mode and filename
3457 should be concatenated (in that order), preferably separated by white
3458 space.  You can--but shouldn't--omit the mode in these forms when that mode
3459 is C<< < >>.  It is always safe to use the two-argument form of C<open> if
3460 the filename argument is a known literal.
3461
3462 For three or more arguments if MODE is C<|->, the filename is
3463 interpreted as a command to which output is to be piped, and if MODE
3464 is C<-|>, the filename is interpreted as a command that pipes
3465 output to us.  In the two-argument (and one-argument) form, one should
3466 replace dash (C<->) with the command.
3467 See L<perlipc/"Using open() for IPC"> for more examples of this.
3468 (You are not allowed to C<open> to a command that pipes both in I<and>
3469 out, but see L<IPC::Open2>, L<IPC::Open3>, and
3470 L<perlipc/"Bidirectional Communication with Another Process"> for
3471 alternatives.)
3472
3473 In the form of pipe opens taking three or more arguments, if LIST is specified
3474 (extra arguments after the command name) then LIST becomes arguments
3475 to the command invoked if the platform supports it.  The meaning of
3476 C<open> with more than three arguments for non-pipe modes is not yet
3477 defined, but experimental "layers" may give extra LIST arguments
3478 meaning.
3479
3480 In the two-argument (and one-argument) form, opening C<< <- >> 
3481 or C<-> opens STDIN and opening C<< >- >> opens STDOUT.
3482
3483 You may (and usually should) use the three-argument form of open to specify
3484 I/O layers (sometimes referred to as "disciplines") to apply to the handle
3485 that affect how the input and output are processed (see L<open> and
3486 L<PerlIO> for more details). For example:
3487
3488   open(my $fh, "<:encoding(UTF-8)", "filename")
3489     || die "can't open UTF-8 encoded filename: $!";
3490
3491 opens the UTF8-encoded file containing Unicode characters;
3492 see L<perluniintro>. Note that if layers are specified in the
3493 three-argument form, then default layers stored in ${^OPEN} (see L<perlvar>;
3494 usually set by the B<open> pragma or the switch B<-CioD>) are ignored.
3495 Those layers will also be ignored if you specifying a colon with no name
3496 following it.  In that case the default layer for the operating system
3497 (:raw on Unix, :crlf on Windows) is used.
3498
3499 Open returns nonzero on success, the undefined value otherwise.  If
3500 the C<open> involved a pipe, the return value happens to be the pid of
3501 the subprocess.
3502
3503 If you're running Perl on a system that distinguishes between text
3504 files and binary files, then you should check out L</binmode> for tips
3505 for dealing with this.  The key distinction between systems that need
3506 C<binmode> and those that don't is their text file formats.  Systems
3507 like Unix, Mac OS, and Plan 9, that end lines with a single
3508 character and encode that character in C as C<"\n"> do not
3509 need C<binmode>.  The rest need it.
3510
3511 When opening a file, it's seldom a good idea to continue 
3512 if the request failed, so C<open> is frequently used with
3513 C<die>.  Even if C<die> won't do what you want (say, in a CGI script,
3514 where you want to format a suitable error message (but there are
3515 modules that can help with that problem)) always check
3516 the return value from opening a file.  
3517
3518 As a special case the three-argument form with a read/write mode and the third
3519 argument being C<undef>:
3520
3521     open(my $tmp, "+>", undef) or die ...
3522
3523 opens a filehandle to an anonymous temporary file.  Also using C<< +< >>
3524 works for symmetry, but you really should consider writing something
3525 to the temporary file first.  You will need to seek() to do the
3526 reading.
3527
3528 Since v5.8.0, Perl has built using PerlIO by default.  Unless you've
3529 changed this (such as building Perl with C<Configure -Uuseperlio>), you can
3530 open filehandles directly to Perl scalars via:
3531
3532     open($fh, ">", \$variable) || ..
3533
3534 To (re)open C<STDOUT> or C<STDERR> as an in-memory file, close it first:
3535
3536     close STDOUT;
3537     open(STDOUT, ">", \$variable)
3538         or die "Can't open STDOUT: $!";
3539
3540 General examples:
3541
3542     $ARTICLE = 100;
3543     open(ARTICLE) or die "Can't find article $ARTICLE: $!\n";
3544     while (<ARTICLE>) {...
3545
3546     open(LOG, ">>/usr/spool/news/twitlog");  # (log is reserved)
3547     # if the open fails, output is discarded
3548
3549     open(my $dbase, "+<", "dbase.mine")      # open for update
3550         or die "Can't open 'dbase.mine' for update: $!";
3551
3552     open(my $dbase, "+<dbase.mine")          # ditto
3553         or die "Can't open 'dbase.mine' for update: $!";
3554
3555     open(ARTICLE, "-|", "caesar <$article")  # decrypt article
3556         or die "Can't start caesar: $!";
3557
3558     open(ARTICLE, "caesar <$article |")      # ditto
3559         or die "Can't start caesar: $!";
3560
3561     open(EXTRACT, "|sort >Tmp$$")            # $$ is our process id
3562         or die "Can't start sort: $!";
3563
3564     # in-memory files
3565     open(MEMORY, ">", \$var)
3566         or die "Can't open memory file: $!";
3567     print MEMORY "foo!\n";                   # output will appear in $var
3568
3569     # process argument list of files along with any includes
3570
3571     foreach $file (@ARGV) {
3572         process($file, "fh00");
3573     }
3574
3575     sub process {
3576         my($filename, $input) = @_;
3577         $input++;    # this is a string increment
3578         unless (open($input, "<", $filename)) {
3579             print STDERR "Can't open $filename: $!\n";
3580             return;
3581         }
3582
3583         local $_;
3584         while (<$input>) {    # note use of indirection
3585             if (/^#include "(.*)"/) {
3586                 process($1, $input);
3587                 next;
3588             }
3589             #...          # whatever
3590         }
3591     }
3592
3593 See L<perliol> for detailed info on PerlIO.
3594
3595 You may also, in the Bourne shell tradition, specify an EXPR beginning
3596 with C<< >& >>, in which case the rest of the string is interpreted
3597 as the name of a filehandle (or file descriptor, if numeric) to be
3598 duped (as C<dup(2)>) and opened.  You may use C<&> after C<< > >>,
3599 C<<< >> >>>, C<< < >>, C<< +> >>, C<<< +>> >>>, and C<< +< >>.
3600 The mode you specify should match the mode of the original filehandle.
3601 (Duping a filehandle does not take into account any existing contents
3602 of IO buffers.) If you use the three-argument form, then you can pass either a
3603 number, the name of a filehandle, or the normal "reference to a glob".
3604
3605 Here is a script that saves, redirects, and restores C<STDOUT> and
3606 C<STDERR> using various methods:
3607
3608     #!/usr/bin/perl
3609     open(my $oldout, ">&STDOUT")     or die "Can't dup STDOUT: $!";
3610     open(OLDERR,     ">&", \*STDERR) or die "Can't dup STDERR: $!";
3611
3612     open(STDOUT, '>', "foo.out") or die "Can't redirect STDOUT: $!";
3613     open(STDERR, ">&STDOUT")     or die "Can't dup STDOUT: $!";
3614
3615     select STDERR; $| = 1;  # make unbuffered
3616     select STDOUT; $| = 1;  # make unbuffered
3617
3618     print STDOUT "stdout 1\n";  # this works for
3619     print STDERR "stderr 1\n";  # subprocesses too
3620
3621     open(STDOUT, ">&", $oldout) or die "Can't dup \$oldout: $!";
3622     open(STDERR, ">&OLDERR")    or die "Can't dup OLDERR: $!";
3623
3624     print STDOUT "stdout 2\n";
3625     print STDERR "stderr 2\n";
3626
3627 If you specify C<< '<&=X' >>, where C<X> is a file descriptor number
3628 or a filehandle, then Perl will do an equivalent of C's C<fdopen> of
3629 that file descriptor (and not call C<dup(2)>); this is more
3630 parsimonious of file descriptors.  For example:
3631
3632     # open for input, reusing the fileno of $fd
3633     open(FILEHANDLE, "<&=$fd")
3634
3635 or
3636
3637     open(FILEHANDLE, "<&=", $fd)
3638
3639 or
3640
3641     # open for append, using the fileno of OLDFH
3642     open(FH, ">>&=", OLDFH)
3643
3644 or
3645
3646     open(FH, ">>&=OLDFH")
3647
3648 Being parsimonious on filehandles is also useful (besides being
3649 parsimonious) for example when something is dependent on file
3650 descriptors, like for example locking using flock().  If you do just
3651 C<< open(A, ">>&B") >>, the filehandle A will not have the same file
3652 descriptor as B, and therefore flock(A) will not flock(B) nor vice
3653 versa.  But with C<< open(A, ">>&=B") >>, the filehandles will share
3654 the same underlying system file descriptor.
3655
3656 Note that under Perls older than 5.8.0, Perl uses the standard C library's'
3657 fdopen() to implement the C<=> functionality.  On many Unix systems,
3658 fdopen() fails when file descriptors exceed a certain value, typically 255.
3659 For Perls 5.8.0 and later, PerlIO is (most often) the default.
3660
3661 You can see whether your Perl was built with PerlIO by running C<perl -V>
3662 and looking for the C<useperlio=> line.  If C<useperlio> is C<define>, you
3663 have PerlIO; otherwise you don't.
3664
3665 If you open a pipe on the command C<-> (that is, specify either C<|-> or C<-|>
3666 with the one- or two-argument forms of C<open>), 
3667 an implicit C<fork> is done, so C<open> returns twice: in the parent
3668 process it returns the pid
3669 of the child process, and in the child process it returns (a defined) C<0>.
3670 Use C<defined($pid)> or C<//> to determine whether the open was successful.
3671
3672 For example, use either
3673
3674     $child_pid = open(FROM_KID, "-|")   // die "can't fork: $!";
3675
3676 or
3677     $child_pid = open(TO_KID,   "|-")   // die "can't fork: $!";
3678
3679 followed by 
3680
3681     if ($child_pid) {
3682         # am the parent:
3683         # either write TO_KID or else read FROM_KID
3684         ...
3685         wait $child_pid;
3686     } else {
3687         # am the child; use STDIN/STDOUT normally
3688         ...
3689         exit;
3690     } 
3691
3692 The filehandle behaves normally for the parent, but I/O to that
3693 filehandle is piped from/to the STDOUT/STDIN of the child process.
3694 In the child process, the filehandle isn't opened--I/O happens from/to
3695 the new STDOUT/STDIN.  Typically this is used like the normal
3696 piped open when you want to exercise more control over just how the
3697 pipe command gets executed, such as when running setuid and
3698 you don't want to have to scan shell commands for metacharacters.
3699
3700 The following blocks are more or less equivalent:
3701
3702     open(FOO, "|tr '[a-z]' '[A-Z]'");
3703     open(FOO, "|-", "tr '[a-z]' '[A-Z]'");
3704     open(FOO, "|-") || exec 'tr', '[a-z]', '[A-Z]';
3705     open(FOO, "|-", "tr", '[a-z]', '[A-Z]');
3706
3707     open(FOO, "cat -n '$file'|");
3708     open(FOO, "-|", "cat -n '$file'");
3709     open(FOO, "-|") || exec "cat", "-n", $file;
3710     open(FOO, "-|", "cat", "-n", $file);
3711
3712 The last two examples in each block show the pipe as "list form", which is
3713 not yet supported on all platforms.  A good rule of thumb is that if
3714 your platform has a real C<fork()> (in other words, if your platform is
3715 Unix, including Linux and MacOS X), you can use the list form.  You would 
3716 want to use the list form of the pipe so you can pass literal arguments
3717 to the command without risk of the shell interpreting any shell metacharacters
3718 in them.  However, this also bars you from opening pipes to commands
3719 that intentionally contain shell metacharacters, such as:
3720
3721     open(FOO, "|cat -n | expand -4 | lpr")
3722         // die "Can't open pipeline to lpr: $!";
3723
3724 See L<perlipc/"Safe Pipe Opens"> for more examples of this.
3725
3726 Beginning with v5.6.0, Perl will attempt to flush all files opened for
3727 output before any operation that may do a fork, but this may not be
3728 supported on some platforms (see L<perlport>).  To be safe, you may need
3729 to set C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method
3730 of C<IO::Handle> on any open handles.
3731
3732 On systems that support a close-on-exec flag on files, the flag will
3733 be set for the newly opened file descriptor as determined by the value
3734 of C<$^F>.  See L<perlvar/$^F>.
3735
3736 Closing any piped filehandle causes the parent process to wait for the
3737 child to finish, then returns the status value in C<$?> and
3738 C<${^CHILD_ERROR_NATIVE}>.
3739
3740 The filename passed to the one- and two-argument forms of open() will
3741 have leading and trailing whitespace deleted and normal
3742 redirection characters honored.  This property, known as "magic open",
3743 can often be used to good effect.  A user could specify a filename of
3744 F<"rsh cat file |">, or you could change certain filenames as needed:
3745
3746     $filename =~ s/(.*\.gz)\s*$/gzip -dc < $1|/;
3747     open(FH, $filename) or die "Can't open $filename: $!";
3748
3749 Use the three-argument form to open a file with arbitrary weird characters in it,
3750
3751     open(FOO, "<", $file)
3752         || die "can't open < $file: $!";
3753
3754 otherwise it's necessary to protect any leading and trailing whitespace:
3755
3756     $file =~ s#^(\s)#./$1#;
3757     open(FOO, "< $file\0")
3758         || die "open failed: $!";
3759
3760 (this may not work on some bizarre filesystems).  One should
3761 conscientiously choose between the I<magic> and I<three-argument> form
3762 of open():
3763
3764     open(IN, $ARGV[0]) || die "can't open $ARGV[0]: $!";
3765
3766 will allow the user to specify an argument of the form C<"rsh cat file |">,
3767 but will not work on a filename that happens to have a trailing space, while
3768
3769     open(IN, "<", $ARGV[0])
3770         || die "can't open < $ARGV[0]: $!";
3771
3772 will have exactly the opposite restrictions.
3773
3774 If you want a "real" C C<open> (see L<open(2)> on your system), then you
3775 should use the C<sysopen> function, which involves no such magic (but may
3776 use subtly different filemodes than Perl open(), which is mapped to C
3777 fopen()).  This is another way to protect your filenames from
3778 interpretation.  For example:
3779
3780     use IO::Handle;
3781     sysopen(HANDLE, $path, O_RDWR|O_CREAT|O_EXCL)
3782         or die "sysopen $path: $!";
3783     $oldfh = select(HANDLE); $| = 1; select($oldfh);
3784     print HANDLE "stuff $$\n";
3785     seek(HANDLE, 0, 0);
3786     print "File contains: ", <HANDLE>;
3787
3788 Using the constructor from the C<IO::Handle> package (or one of its
3789 subclasses, such as C<IO::File> or C<IO::Socket>), you can generate anonymous
3790 filehandles that have the scope of the variables used to hold them, then
3791 automatically (but silently) close once their reference counts become
3792 zero, typically at scope exit:
3793
3794     use IO::File;
3795     #...
3796     sub read_myfile_munged {
3797         my $ALL = shift;
3798         # or just leave it undef to autoviv
3799         my $handle = IO::File->new;
3800         open($handle, "<", "myfile") or die "myfile: $!";
3801         $first = <$handle>
3802             or return ();     # Automatically closed here.
3803         mung($first) or die "mung failed";  # Or here.
3804         return (first, <$handle>) if $ALL;  # Or here.
3805         return $first;                      # Or here.
3806     }
3807
3808 B<WARNING:> The previous example has a bug because the automatic
3809 close that happens when the refcount on C<handle> does not
3810 properly detect and report failures.  I<Always> close the handle
3811 yourself and inspect the return value.
3812
3813     close($handle) 
3814         || warn "close failed: $!";
3815
3816 See L</seek> for some details about mixing reading and writing.
3817
3818 Portability issues: L<perlport/open>.
3819
3820 =item opendir DIRHANDLE,EXPR
3821 X<opendir>
3822
3823 Opens a directory named EXPR for processing by C<readdir>, C<telldir>,
3824 C<seekdir>, C<rewinddir>, and C<closedir>.  Returns true if successful.
3825 DIRHANDLE may be an expression whose value can be used as an indirect
3826 dirhandle, usually the real dirhandle name.  If DIRHANDLE is an undefined
3827 scalar variable (or array or hash element), the variable is assigned a
3828 reference to a new anonymous dirhandle; that is, it's autovivified.
3829 DIRHANDLEs have their own namespace separate from FILEHANDLEs.
3830
3831 See the example at C<readdir>.
3832
3833 =item ord EXPR
3834 X<ord> X<encoding>
3835
3836 =item ord
3837
3838 Returns the numeric value of the first character of EXPR.
3839 If EXPR is an empty string, returns 0.  If EXPR is omitted, uses C<$_>.
3840 (Note I<character>, not byte.)
3841
3842 For the reverse, see L</chr>.
3843 See L<perlunicode> for more about Unicode.
3844
3845 =item our EXPR
3846 X<our> X<global>
3847
3848 =item our TYPE EXPR
3849
3850 =item our EXPR : ATTRS
3851
3852 =item our TYPE EXPR : ATTRS
3853
3854 C<our> associates a simple name with a package variable in the current
3855 package for use within the current scope.  When C<use strict 'vars'> is in
3856 effect, C<our> lets you use declared global variables without qualifying
3857 them with package names, within the lexical scope of the C<our> declaration.
3858 In this way C<our> differs from C<use vars>, which is package-scoped.
3859
3860 Unlike C<my> or C<state>, which allocates storage for a variable and
3861 associates a simple name with that storage for use within the current
3862 scope, C<our> associates a simple name with a package (read: global)
3863 variable in the current package, for use within the current lexical scope.
3864 In other words, C<our> has the same scoping rules as C<my> or C<state>, but
3865 does not necessarily create a variable.
3866
3867 If more than one value is listed, the list must be placed
3868 in parentheses.
3869
3870     our $foo;
3871     our($bar, $baz);
3872
3873 An C<our> declaration declares a global variable that will be visible
3874 across its entire lexical scope, even across package boundaries.  The
3875 package in which the variable is entered is determined at the point
3876 of the declaration, not at the point of use.  This means the following
3877 behavior holds:
3878
3879     package Foo;
3880     our $bar;      # declares $Foo::bar for rest of lexical scope
3881     $bar = 20;
3882
3883     package Bar;
3884     print $bar;    # prints 20, as it refers to $Foo::bar
3885
3886 Multiple C<our> declarations with the same name in the same lexical
3887 scope are allowed if they are in different packages.  If they happen
3888 to be in the same package, Perl will emit warnings if you have asked
3889 for them, just like multiple C<my> declarations.  Unlike a second
3890 C<my> declaration, which will bind the name to a fresh variable, a
3891 second C<our> declaration in the same package, in the same scope, is
3892 merely redundant.
3893
3894     use warnings;
3895     package Foo;
3896     our $bar;      # declares $Foo::bar for rest of lexical scope
3897     $bar = 20;
3898
3899     package Bar;
3900     our $bar = 30; # declares $Bar::bar for rest of lexical scope
3901     print $bar;    # prints 30
3902
3903     our $bar;      # emits warning but has no other effect
3904     print $bar;    # still prints 30
3905
3906 An C<our> declaration may also have a list of attributes associated
3907 with it.
3908
3909 The exact semantics and interface of TYPE and ATTRS are still
3910 evolving.  TYPE is currently bound to the use of C<fields> pragma,
3911 and attributes are handled using the C<attributes> pragma, or starting
3912 from Perl 5.8.0 also via the C<Attribute::Handlers> module.  See
3913 L<perlsub/"Private Variables via my()"> for details, and L<fields>,
3914 L<attributes>, and L<Attribute::Handlers>.
3915
3916 =item pack TEMPLATE,LIST
3917 X<pack>
3918
3919 Takes a LIST of values and converts it into a string using the rules
3920 given by the TEMPLATE.  The resulting string is the concatenation of
3921 the converted values.  Typically, each converted value looks
3922 like its machine-level representation.  For example, on 32-bit machines
3923 an integer may be represented by a sequence of 4 bytes, which  will in
3924 Perl be presented as a string that's 4 characters long. 
3925
3926 See L<perlpacktut> for an introduction to this function.
3927
3928 The TEMPLATE is a sequence of characters that give the order and type
3929 of values, as follows:
3930
3931     a  A string with arbitrary binary data, will be null padded.
3932     A  A text (ASCII) string, will be space padded.
3933     Z  A null-terminated (ASCIZ) string, will be null padded.
3934
3935     b  A bit string (ascending bit order inside each byte,
3936        like vec()).
3937     B  A bit string (descending bit order inside each byte).
3938     h  A hex string (low nybble first).
3939     H  A hex string (high nybble first).
3940
3941     c  A signed char (8-bit) value.
3942     C  An unsigned char (octet) value.
3943     W  An unsigned char value (can be greater than 255).
3944
3945     s  A signed short (16-bit) value.
3946     S  An unsigned short value.
3947
3948     l  A signed long (32-bit) value.
3949     L  An unsigned long value.
3950
3951     q  A signed quad (64-bit) value.
3952     Q  An unsigned quad value.
3953          (Quads are available only if your system supports 64-bit
3954           integer values _and_ if Perl has been compiled to support
3955           those.  Raises an exception otherwise.)
3956
3957     i  A signed integer value.
3958     I  A unsigned integer value.
3959          (This 'integer' is _at_least_ 32 bits wide.  Its exact
3960           size depends on what a local C compiler calls 'int'.)
3961
3962     n  An unsigned short (16-bit) in "network" (big-endian) order.
3963     N  An unsigned long (32-bit) in "network" (big-endian) order.
3964     v  An unsigned short (16-bit) in "VAX" (little-endian) order.
3965     V  An unsigned long (32-bit) in "VAX" (little-endian) order.
3966
3967     j  A Perl internal signed integer value (IV).
3968     J  A Perl internal unsigned integer value (UV).
3969
3970     f  A single-precision float in native format.
3971     d  A double-precision float in native format.
3972
3973     F  A Perl internal floating-point value (NV) in native format
3974     D  A float of long-double precision in native format.
3975          (Long doubles are available only if your system supports
3976           long double values _and_ if Perl has been compiled to
3977           support those.  Raises an exception otherwise.)
3978
3979     p  A pointer to a null-terminated string.
3980     P  A pointer to a structure (fixed-length string).
3981
3982     u  A uuencoded string.
3983     U  A Unicode character number.  Encodes to a character in char-
3984        acter mode and UTF-8 (or UTF-EBCDIC in EBCDIC platforms) in
3985        byte mode.
3986
3987     w  A BER compressed integer (not an ASN.1 BER, see perlpacktut
3988        for details).  Its bytes represent an unsigned integer in
3989        base 128, most significant digit first, with as few digits
3990        as possible.  Bit eight (the high bit) is set on each byte
3991        except the last.
3992
3993     x  A null byte (a.k.a ASCII NUL, "\000", chr(0))
3994     X  Back up a byte.
3995     @  Null-fill or truncate to absolute position, counted from the
3996        start of the innermost ()-group.
3997     .  Null-fill or truncate to absolute position specified by
3998        the value.
3999     (  Start of a ()-group.
4000
4001 One or more modifiers below may optionally follow certain letters in the
4002 TEMPLATE (the second column lists letters for which the modifier is valid):
4003
4004     !   sSlLiI     Forces native (short, long, int) sizes instead
4005                    of fixed (16-/32-bit) sizes.
4006
4007         xX         Make x and X act as alignment commands.
4008
4009         nNvV       Treat integers as signed instead of unsigned.
4010
4011         @.         Specify position as byte offset in the internal
4012                    representation of the packed string. Efficient but
4013                    dangerous.
4014
4015     >   sSiIlLqQ   Force big-endian byte-order on the type.
4016         jJfFdDpP   (The "big end" touches the construct.)
4017
4018     <   sSiIlLqQ   Force little-endian byte-order on the type.
4019         jJfFdDpP   (The "little end" touches the construct.)
4020
4021 The C<< > >> and C<< < >> modifiers can also be used on C<()> groups 
4022 to force a particular byte-order on all components in that group, 
4023 including all its subgroups.
4024
4025 The following rules apply:
4026
4027 =over 
4028
4029 =item *
4030
4031 Each letter may optionally be followed by a number indicating the repeat
4032 count.  A numeric repeat count may optionally be enclosed in brackets, as
4033 in C<pack("C[80]", @arr)>.  The repeat count gobbles that many values from
4034 the LIST when used with all format types other than C<a>, C<A>, C<Z>, C<b>,
4035 C<B>, C<h>, C<H>, C<@>, C<.>, C<x>, C<X>, and C<P>, where it means
4036 something else, described below.  Supplying a C<*> for the repeat count
4037 instead of a number means to use however many items are left, except for:
4038
4039 =over 
4040
4041 =item * 
4042
4043 C<@>, C<x>, and C<X>, where it is equivalent to C<0>.
4044
4045 =item * 
4046
4047 <.>, where it means relative to the start of the string.
4048
4049 =item * 
4050
4051 C<u>, where it is equivalent to 1 (or 45, which here is equivalent).
4052
4053 =back 
4054
4055 One can replace a numeric repeat count with a template letter enclosed in
4056 brackets to use the packed byte length of the bracketed template for the
4057 repeat count.
4058
4059 For example, the template C<x[L]> skips as many bytes as in a packed long,
4060 and the template C<"$t X[$t] $t"> unpacks twice whatever $t (when
4061 variable-expanded) unpacks.  If the template in brackets contains alignment
4062 commands (such as C<x![d]>), its packed length is calculated as if the
4063 start of the template had the maximal possible alignment.
4064
4065 When used with C<Z>, a C<*> as the repeat count is guaranteed to add a
4066 trailing null byte, so the resulting string is always one byte longer than
4067 the byte length of the item itself.
4068
4069 When used with C<@>, the repeat count represents an offset from the start
4070 of the innermost C<()> group.
4071
4072 When used with C<.>, the repeat count determines the starting position to
4073 calculate the value offset as follows:
4074
4075 =over 
4076
4077 =item *
4078
4079 If the repeat count is C<0>, it's relative to the current position.
4080
4081 =item *
4082
4083 If the repeat count is C<*>, the offset is relative to the start of the
4084 packed string.
4085
4086 =item *
4087
4088 And if it's an integer I<n>, the offset is relative to the start of the
4089 I<n>th innermost C<( )> group, or to the start of the string if I<n> is
4090 bigger then the group level.
4091
4092 =back
4093
4094 The repeat count for C<u> is interpreted as the maximal number of bytes
4095 to encode per line of output, with 0, 1 and 2 replaced by 45. The repeat 
4096 count should not be more than 65.
4097
4098 =item *
4099
4100 The C<a>, C<A>, and C<Z> types gobble just one value, but pack it as a
4101 string of length count, padding with nulls or spaces as needed.  When
4102 unpacking, C<A> strips trailing whitespace and nulls, C<Z> strips everything
4103 after the first null, and C<a> returns data with no stripping at all.
4104
4105 If the value to pack is too long, the result is truncated.  If it's too
4106 long and an explicit count is provided, C<Z> packs only C<$count-1> bytes,
4107 followed by a null byte.  Thus C<Z> always packs a trailing null, except
4108 when the count is 0.
4109
4110 =item *
4111
4112 Likewise, the C<b> and C<B> formats pack a string that's that many bits long.
4113 Each such format generates 1 bit of the result.  These are typically followed
4114 by a repeat count like C<B8> or C<B64>.
4115
4116 Each result bit is based on the least-significant bit of the corresponding
4117 input character, i.e., on C<ord($char)%2>.  In particular, characters C<"0">
4118 and C<"1"> generate bits 0 and 1, as do characters C<"\000"> and C<"\001">.
4119
4120 Starting from the beginning of the input string, each 8-tuple
4121 of characters is converted to 1 character of output.  With format C<b>,
4122 the first character of the 8-tuple determines the least-significant bit of a
4123 character; with format C<B>, it determines the most-significant bit of
4124 a character.
4125
4126 If the length of the input string is not evenly divisible by 8, the
4127 remainder is packed as if the input string were padded by null characters
4128 at the end.  Similarly during unpacking, "extra" bits are ignored.
4129
4130 If the input string is longer than needed, remaining characters are ignored.
4131
4132 A C<*> for the repeat count uses all characters of the input field.  
4133 On unpacking, bits are converted to a string of C<0>s and C<1>s.
4134
4135 =item *
4136
4137 The C<h> and C<H> formats pack a string that many nybbles (4-bit groups,
4138 representable as hexadecimal digits, C<"0".."9"> C<"a".."f">) long.
4139
4140 For each such format, pack() generates 4 bits of result.
4141 With non-alphabetical characters, the result is based on the 4 least-significant
4142 bits of the input character, i.e., on C<ord($char)%16>.  In particular,
4143 characters C<"0"> and C<"1"> generate nybbles 0 and 1, as do bytes
4144 C<"\000"> and C<"\001">.  For characters C<"a".."f"> and C<"A".."F">, the result
4145 is compatible with the usual hexadecimal digits, so that C<"a"> and
4146 C<"A"> both generate the nybble C<0xA==10>.  Use only these specific hex 
4147 characters with this format.
4148
4149 Starting from the beginning of the template to pack(), each pair
4150 of characters is converted to 1 character of output.  With format C<h>, the
4151 first character of the pair determines the least-significant nybble of the
4152 output character; with format C<H>, it determines the most-significant
4153 nybble.
4154
4155 If the length of the input string is not even, it behaves as if padded by
4156 a null character at the end.  Similarly, "extra" nybbles are ignored during
4157 unpacking.
4158
4159 If the input string is longer than needed, extra characters are ignored.
4160
4161 A C<*> for the repeat count uses all characters of the input field.  For
4162 unpack(), nybbles are converted to a string of hexadecimal digits.
4163
4164 =item *
4165
4166 The C<p> format packs a pointer to a null-terminated string.  You are
4167 responsible for ensuring that the string is not a temporary value, as that
4168 could potentially get deallocated before you got around to using the packed
4169 result.  The C<P> format packs a pointer to a structure of the size indicated
4170 by the length.  A null pointer is created if the corresponding value for
4171 C<p> or C<P> is C<undef>; similarly with unpack(), where a null pointer
4172 unpacks into C<undef>.
4173
4174 If your system has a strange pointer size--meaning a pointer is neither as
4175 big as an int nor as big as a long--it may not be possible to pack or
4176 unpack pointers in big- or little-endian byte order.  Attempting to do
4177 so raises an exception.
4178
4179 =item *
4180
4181 The C</> template character allows packing and unpacking of a sequence of
4182 items where the packed structure contains a packed item count followed by
4183 the packed items themselves.  This is useful when the structure you're
4184 unpacking has encoded the sizes or repeat counts for some of its fields
4185 within the structure itself as separate fields.
4186
4187 For C<pack>, you write I<length-item>C</>I<sequence-item>, and the
4188 I<length-item> describes how the length value is packed. Formats likely
4189 to be of most use are integer-packing ones like C<n> for Java strings,
4190 C<w> for ASN.1 or SNMP, and C<N> for Sun XDR.
4191
4192 For C<pack>, I<sequence-item> may have a repeat count, in which case
4193 the minimum of that and the number of available items is used as the argument
4194 for I<length-item>. If it has no repeat count or uses a '*', the number
4195 of available items is used.
4196
4197 For C<unpack>, an internal stack of integer arguments unpacked so far is
4198 used. You write C</>I<sequence-item> and the repeat count is obtained by
4199 popping off the last element from the stack. The I<sequence-item> must not
4200 have a repeat count.
4201
4202 If I<sequence-item> refers to a string type (C<"A">, C<"a">, or C<"Z">),
4203 the I<length-item> is the string length, not the number of strings.  With
4204 an explicit repeat count for pack, the packed string is adjusted to that
4205 length.  For example:
4206
4207  This code:                              gives this result:
4208  
4209   unpack("W/a", "\004Gurusamy")          ("Guru")
4210   unpack("a3/A A*", "007 Bond  J ")      (" Bond", "J")
4211   unpack("a3 x2 /A A*", "007: Bond, J.") ("Bond, J", ".")
4212
4213   pack("n/a* w/a","hello,","world")     "\000\006hello,\005world"
4214   pack("a/W2", ord("a") .. ord("z"))    "2ab"
4215
4216 The I<length-item> is not returned explicitly from C<unpack>.
4217
4218 Supplying a count to the I<length-item> format letter is only useful with
4219 C<A>, C<a>, or C<Z>.  Packing with a I<length-item> of C<a> or C<Z> may
4220 introduce C<"\000"> characters, which Perl does not regard as legal in
4221 numeric strings.
4222
4223 =item *
4224
4225 The integer types C<s>, C<S>, C<l>, and C<L> may be
4226 followed by a C<!> modifier to specify native shorts or
4227 longs.  As shown in the example above, a bare C<l> means
4228 exactly 32 bits, although the native C<long> as seen by the local C compiler
4229 may be larger.  This is mainly an issue on 64-bit platforms.  You can
4230 see whether using C<!> makes any difference this way:
4231
4232     printf "format s is %d, s! is %d\n", 
4233         length pack("s"), length pack("s!");
4234
4235     printf "format l is %d, l! is %d\n", 
4236         length pack("l"), length pack("l!");
4237
4238
4239 C<i!> and C<I!> are also allowed, but only for completeness' sake:
4240 they are identical to C<i> and C<I>.
4241
4242 The actual sizes (in bytes) of native shorts, ints, longs, and long
4243 longs on the platform where Perl was built are also available from
4244 the command line:
4245
4246     $ perl -V:{short,int,long{,long}}size
4247     shortsize='2';
4248     intsize='4';
4249     longsize='4';
4250     longlongsize='8';
4251
4252 or programmatically via the C<Config> module:
4253
4254        use Config;
4255        print $Config{shortsize},    "\n";
4256        print $Config{intsize},      "\n";
4257        print $Config{longsize},     "\n";
4258        print $Config{longlongsize}, "\n";
4259
4260 C<$Config{longlongsize}> is undefined on systems without 
4261 long long support.
4262
4263 =item *
4264
4265 The integer formats C<s>, C<S>, C<i>, C<I>, C<l>, C<L>, C<j>, and C<J> are
4266 inherently non-portable between processors and operating systems because
4267 they obey native byteorder and endianness.  For example, a 4-byte integer
4268 0x12345678 (305419896 decimal) would be ordered natively (arranged in and
4269 handled by the CPU registers) into bytes as
4270
4271     0x12 0x34 0x56 0x78  # big-endian
4272     0x78 0x56 0x34 0x12  # little-endian
4273
4274 Basically, Intel and VAX CPUs are little-endian, while everybody else,
4275 including Motorola m68k/88k, PPC, Sparc, HP PA, Power, and Cray, are
4276 big-endian.  Alpha and MIPS can be either: Digital/Compaq uses (well, used) 
4277 them in little-endian mode, but SGI/Cray uses them in big-endian mode.
4278
4279 The names I<big-endian> and I<little-endian> are comic references to the
4280 egg-eating habits of the little-endian Lilliputians and the big-endian
4281 Blefuscudians from the classic Jonathan Swift satire, I<Gulliver's Travels>.
4282 This entered computer lingo via the paper "On Holy Wars and a Plea for
4283 Peace" by Danny Cohen, USC/ISI IEN 137, April 1, 1980.
4284
4285 Some systems may have even weirder byte orders such as
4286
4287    0x56 0x78 0x12 0x34
4288    0x34 0x12 0x78 0x56
4289
4290 You can determine your system endianness with this incantation:
4291
4292    printf("%#02x ", $_) for unpack("W*", pack L=>0x12345678); 
4293
4294 The byteorder on the platform where Perl was built is also available
4295 via L<Config>:
4296
4297     use Config;
4298     print "$Config{byteorder}\n";
4299
4300 or from the command line:
4301
4302     $ perl -V:byteorder
4303
4304 Byteorders C<"1234"> and C<"12345678"> are little-endian; C<"4321">
4305 and C<"87654321"> are big-endian.
4306
4307 For portably packed integers, either use the formats C<n>, C<N>, C<v>, 
4308 and C<V> or else use the C<< > >> and C<< < >> modifiers described
4309 immediately below.  See also L<perlport>.
4310
4311 =item *
4312
4313 Starting with Perl 5.9.2, integer and floating-point formats, along with
4314 the C<p> and C<P> formats and C<()> groups, may all be followed by the 
4315 C<< > >> or C<< < >> endianness modifiers to respectively enforce big-
4316 or little-endian byte-order.  These modifiers are especially useful 
4317 given how C<n>, C<N>, C<v>, and C<V> don't cover signed integers, 
4318 64-bit integers, or floating-point values.
4319
4320 Here are some concerns to keep in mind when using an endianness modifier:
4321
4322 =over
4323
4324 =item * 
4325
4326 Exchanging signed integers between different platforms works only 
4327 when all platforms store them in the same format.  Most platforms store
4328 signed integers in two's-complement notation, so usually this is not an issue.
4329
4330 =item * 
4331
4332 The C<< > >> or C<< < >> modifiers can only be used on floating-point
4333 formats on big- or little-endian machines.  Otherwise, attempting to
4334 use them raises an exception.
4335
4336 =item * 
4337
4338 Forcing big- or little-endian byte-order on floating-point values for
4339 data exchange can work only if all platforms use the same
4340 binary representation such as IEEE floating-point.  Even if all
4341 platforms are using IEEE, there may still be subtle differences.  Being able
4342 to use C<< > >> or C<< < >> on floating-point values can be useful,
4343 but also dangerous if you don't know exactly what you're doing.
4344 It is not a general way to portably store floating-point values.
4345
4346 =item * 
4347
4348 When using C<< > >> or C<< < >> on a C<()> group, this affects
4349 all types inside the group that accept byte-order modifiers,
4350 including all subgroups.  It is silently ignored for all other
4351 types.  You are not allowed to override the byte-order within a group
4352 that already has a byte-order modifier suffix.
4353
4354 =back
4355
4356 =item *
4357
4358 Real numbers (floats and doubles) are in native machine format only.
4359 Due to the multiplicity of floating-point formats and the lack of a
4360 standard "network" representation for them, no facility for interchange has been
4361 made.  This means that packed floating-point data written on one machine
4362 may not be readable on another, even if both use IEEE floating-point
4363 arithmetic (because the endianness of the memory representation is not part
4364 of the IEEE spec).  See also L<perlport>.
4365
4366 If you know I<exactly> what you're doing, you can use the C<< > >> or C<< < >>
4367 modifiers to force big- or little-endian byte-order on floating-point values.
4368
4369 Because Perl uses doubles (or long doubles, if configured) internally for
4370 all numeric calculation, converting from double into float and thence 
4371 to double again loses precision, so C<unpack("f", pack("f", $foo)>)
4372 will not in general equal $foo.
4373
4374 =item *
4375
4376 Pack and unpack can operate in two modes: character mode (C<C0> mode) where
4377 the packed string is processed per character, and UTF-8 mode (C<U0> mode)
4378 where the packed string is processed in its UTF-8-encoded Unicode form on
4379 a byte-by-byte basis. Character mode is the default unless the format string 
4380 starts with C<U>. You can always switch mode mid-format with an explicit 
4381 C<C0> or C<U0> in the format.  This mode remains in effect until the next 
4382 mode change, or until the end of the C<()> group it (directly) applies to.
4383
4384 Using C<C0> to get Unicode characters while using C<U0> to get I<non>-Unicode 
4385 bytes is not necessarily obvious.   Probably only the first of these
4386 is what you want:
4387
4388     $ perl -CS -E 'say "\x{3B1}\x{3C9}"' | 
4389       perl -CS -ne 'printf "%v04X\n", $_ for unpack("C0A*", $_)'
4390     03B1.03C9
4391     $ perl -CS -E 'say "\x{3B1}\x{3C9}"' | 
4392       perl -CS -ne 'printf "%v02X\n", $_ for unpack("U0A*", $_)'
4393     CE.B1.CF.89
4394     $ perl -CS -E 'say "\x{3B1}\x{3C9}"' | 
4395       perl -C0 -ne 'printf "%v02X\n", $_ for unpack("C0A*", $_)'
4396     CE.B1.CF.89
4397     $ perl -CS -E 'say "\x{3B1}\x{3C9}"' | 
4398       perl -C0 -ne 'printf "%v02X\n", $_ for unpack("U0A*", $_)'
4399     C3.8E.C2.B1.C3.8F.C2.89
4400
4401 Those examples also illustrate that you should not try to use
4402 C<pack>/C<unpack> as a substitute for the L<Encode> module.
4403
4404 =item *
4405
4406 You must yourself do any alignment or padding by inserting, for example,
4407 enough C<"x">es while packing.  There is no way for pack() and unpack()
4408 to know where characters are going to or coming from, so they 
4409 handle their output and input as flat sequences of characters.
4410
4411 =item *
4412
4413 A C<()> group is a sub-TEMPLATE enclosed in parentheses.  A group may
4414 take a repeat count either as postfix, or for unpack(), also via the C</>
4415 template character.  Within each repetition of a group, positioning with
4416 C<@> starts over at 0. Therefore, the result of
4417
4418     pack("@1A((@2A)@3A)", qw[X Y Z])
4419
4420 is the string C<"\0X\0\0YZ">.
4421
4422 =item *
4423
4424 C<x> and C<X> accept the C<!> modifier to act as alignment commands: they
4425 jump forward or back to the closest position aligned at a multiple of C<count>
4426 characters. For example, to pack() or unpack() a C structure like
4427
4428     struct {
4429         char   c;    /* one signed, 8-bit character */
4430         double d; 
4431         char   cc[2];
4432     }
4433
4434 one may need to use the template C<c x![d] d c[2]>.  This assumes that
4435 doubles must be aligned to the size of double.
4436
4437 For alignment commands, a C<count> of 0 is equivalent to a C<count> of 1;
4438 both are no-ops.
4439
4440 =item *
4441
4442 C<n>, C<N>, C<v> and C<V> accept the C<!> modifier to
4443 represent signed 16-/32-bit integers in big-/little-endian order.
4444 This is portable only when all platforms sharing packed data use the
4445 same binary representation for signed integers; for example, when all
4446 platforms use two's-complement representation.
4447
4448 =item *
4449
4450 Comments can be embedded in a TEMPLATE using C<#> through the end of line.
4451 White space can separate pack codes from each other, but modifiers and
4452 repeat counts must follow immediately.  Breaking complex templates into
4453 individual line-by-line components, suitably annotated, can do as much to
4454 improve legibility and maintainability of pack/unpack formats as C</x> can
4455 for complicated pattern matches.
4456
4457 =item *
4458
4459 If TEMPLATE requires more arguments than pack() is given, pack()
4460 assumes additional C<""> arguments.  If TEMPLATE requires fewer arguments
4461 than given, extra arguments are ignored.
4462
4463 =back
4464
4465 Examples:
4466
4467     $foo = pack("WWWW",65,66,67,68);
4468     # foo eq "ABCD"
4469     $foo = pack("W4",65,66,67,68);
4470     # same thing
4471     $foo = pack("W4",0x24b6,0x24b7,0x24b8,0x24b9);
4472     # same thing with Unicode circled letters.
4473     $foo = pack("U4",0x24b6,0x24b7,0x24b8,0x24b9);
4474     # same thing with Unicode circled letters. You don't get the
4475     # UTF-8 bytes because the U at the start of the format caused
4476     # a switch to U0-mode, so the UTF-8 bytes get joined into
4477     # characters
4478     $foo = pack("C0U4",0x24b6,0x24b7,0x24b8,0x24b9);
4479     # foo eq "\xe2\x92\xb6\xe2\x92\xb7\xe2\x92\xb8\xe2\x92\xb9"
4480     # This is the UTF-8 encoding of the string in the
4481     # previous example
4482
4483     $foo = pack("ccxxcc",65,66,67,68);
4484     # foo eq "AB\0\0CD"
4485
4486     # NOTE: The examples above featuring "W" and "c" are true
4487     # only on ASCII and ASCII-derived systems such as ISO Latin 1
4488     # and UTF-8.  On EBCDIC systems, the first example would be
4489     #      $foo = pack("WWWW",193,194,195,196);
4490
4491     $foo = pack("s2",1,2);
4492     # "\001\000\002\000" on little-endian
4493     # "\000\001\000\002" on big-endian
4494
4495     $foo = pack("a4","abcd","x","y","z");
4496     # "abcd"
4497
4498     $foo = pack("aaaa","abcd","x","y","z");
4499     # "axyz"
4500
4501     $foo = pack("a14","abcdefg");
4502     # "abcdefg\0\0\0\0\0\0\0"
4503
4504     $foo = pack("i9pl", gmtime);
4505     # a real struct tm (on my system anyway)
4506
4507     $utmp_template = "Z8 Z8 Z16 L";
4508     $utmp = pack($utmp_template, @utmp1);
4509     # a struct utmp (BSDish)
4510
4511     @utmp2 = unpack($utmp_template, $utmp);
4512     # "@utmp1" eq "@utmp2"
4513
4514     sub bintodec {
4515         unpack("N", pack("B32", substr("0" x 32 . shift, -32)));
4516     }
4517
4518     $foo = pack('sx2l', 12, 34);
4519     # short 12, two zero bytes padding, long 34
4520     $bar = pack('s@4l', 12, 34);
4521     # short 12, zero fill to position 4, long 34
4522     # $foo eq $bar
4523     $baz = pack('s.l', 12, 4, 34);
4524     # short 12, zero fill to position 4, long 34
4525
4526     $foo = pack('nN', 42, 4711);
4527     # pack big-endian 16- and 32-bit unsigned integers
4528     $foo = pack('S>L>', 42, 4711);
4529     # exactly the same
4530     $foo = pack('s<l<', -42, 4711);
4531     # pack little-endian 16- and 32-bit signed integers
4532     $foo = pack('(sl)<', -42, 4711);
4533     # exactly the same
4534
4535 The same template may generally also be used in unpack().
4536
4537 =item package NAMESPACE
4538
4539 =item package NAMESPACE VERSION
4540 X<package> X<module> X<namespace> X<version>
4541
4542 =item package NAMESPACE BLOCK
4543
4544 =item package NAMESPACE VERSION BLOCK
4545 X<package> X<module> X<namespace> X<version>
4546
4547 Declares the BLOCK or the rest of the compilation unit as being in the
4548 given namespace.  The scope of the package declaration is either the
4549 supplied code BLOCK or, in the absence of a BLOCK, from the declaration
4550 itself through the end of current scope (the enclosing block, file, or
4551 C<eval>).  That is, the forms without a BLOCK are operative through the end
4552 of the current scope, just like the C<my>, C<state>, and C<our> operators.
4553 All unqualified dynamic identifiers in this scope will be in the given
4554 namespace, except where overridden by another C<package> declaration or
4555 when they're one of the special identifiers that qualify into C<main::>,
4556 like C<STDOUT>, C<ARGV>, C<ENV>, and the punctuation variables.
4557
4558 A package statement affects dynamic variables only, including those
4559 you've used C<local> on, but I<not> lexical variables, which are created
4560 with C<my>, C<state>, or C<our>.  Typically it would be the first 
4561 declaration in a file included by C<require> or C<use>.  You can switch into a
4562 package in more than one place, since this only determines which default 
4563 symbol table the compiler uses for the rest of that block.  You can refer to
4564 identifiers in other packages than the current one by prefixing the identifier
4565 with the package name and a double colon, as in C<$SomePack::var>
4566 or C<ThatPack::INPUT_HANDLE>.  If package name is omitted, the C<main>
4567 package as assumed.  That is, C<$::sail> is equivalent to
4568 C<$main::sail> (as well as to C<$main'sail>, still seen in ancient
4569 code, mostly from Perl 4).
4570
4571 If VERSION is provided, C<package> sets the C<$VERSION> variable in the given
4572 namespace to a L<version> object with the VERSION provided.  VERSION must be a
4573 "strict" style version number as defined by the L<version> module: a positive
4574 decimal number (integer or decimal-fraction) without exponentiation or else a
4575 dotted-decimal v-string with a leading 'v' character and at least three
4576 components.  You should set C<$VERSION> only once per package.
4577
4578 See L<perlmod/"Packages"> for more information about packages, modules,
4579 and classes.  See L<perlsub> for other scoping issues.
4580
4581 =item pipe READHANDLE,WRITEHANDLE
4582 X<pipe>
4583
4584 Opens a pair of connected pipes like the corresponding system call.
4585 Note that if you set up a loop of piped processes, deadlock can occur
4586 unless you are very careful.  In addition, note that Perl's pipes use
4587 IO buffering, so you may need to set C<$|> to flush your WRITEHANDLE
4588 after each command, depending on the application.
4589
4590 See L<IPC::Open2>, L<IPC::Open3>, and
4591 L<perlipc/"Bidirectional Communication with Another Process">
4592 for examples of such things.
4593
4594 On systems that support a close-on-exec flag on files, that flag is set
4595 on all newly opened file descriptors whose C<fileno>s are I<higher> than 
4596 the current value of $^F (by default 2 for C<STDERR>).  See L<perlvar/$^F>.
4597
4598 =item __PACKAGE__
4599 X<__PACKAGE__>
4600
4601 A special token that returns the name of the package in which it occurs.
4602
4603 =item pop ARRAY
4604 X<pop> X<stack>
4605
4606 =item pop EXPR
4607
4608 =item pop
4609
4610 Pops and returns the last value of the array, shortening the array by
4611 one element.
4612
4613 Returns the undefined value if the array is empty, although this may also
4614 happen at other times.  If ARRAY is omitted, pops the C<@ARGV> array in the
4615 main program, but the C<@_> array in subroutines, just like C<shift>.
4616
4617 Starting with Perl 5.14, C<pop> can take a scalar EXPR, which must hold a
4618 reference to an unblessed array.  The argument will be dereferenced
4619 automatically.  This aspect of C<pop> is considered highly experimental.
4620 The exact behaviour may change in a future version of Perl.
4621
4622 =item pos SCALAR
4623 X<pos> X<match, position>
4624
4625 =item pos
4626
4627 Returns the offset of where the last C<m//g> search left off for the
4628 variable in question (C<$_> is used when the variable is not
4629 specified). Note that 0 is a valid match offset. C<undef> indicates
4630 that the search position is reset (usually due to match failure, but
4631 can also be because no match has yet been run on the scalar).
4632
4633 C<pos> directly accesses the location used by the regexp engine to
4634 store the offset, so assigning to C<pos> will change that offset, and
4635 so will also influence the C<\G> zero-width assertion in regular
4636 expressions. Both of these effects take place for the next match, so
4637 you can't affect the position with C<pos> during the current match,
4638 such as in C<(?{pos() = 5})> or C<s//pos() = 5/e>.
4639
4640 Setting C<pos> also resets the I<matched with zero-length> flag, described
4641 under L<perlre/"Repeated Patterns Matching a Zero-length Substring">.
4642
4643 Because a failed C<m//gc> match doesn't reset the offset, the return
4644 from C<pos> won't change either in this case.  See L<perlre> and
4645 L<perlop>.
4646
4647 =item print FILEHANDLE LIST
4648 X<print>
4649
4650 =item print FILEHANDLE
4651
4652 =item print LIST
4653
4654 =item print
4655
4656 Prints a string or a list of strings.  Returns true if successful.
4657 FILEHANDLE may be a scalar variable containing the name of or a reference
4658 to the filehandle, thus introducing one level of indirection.  (NOTE: If
4659 FILEHANDLE is a variable and the next token is a term, it may be
4660 misinterpreted as an operator unless you interpose a C<+> or put
4661 parentheses around the arguments.) If FILEHANDLE is omitted, prints to the
4662 last selected (see L</select>) output handle.  If LIST is omitted, prints
4663 C<$_> to the currently selected output handle.  To use FILEHANDLE alone to
4664 print the content of C<$_> to it, you must use a real filehandle like
4665 C<FH>, not an indirect one like C<$fh>.  To set the default output handle
4666 to something other than STDOUT, use the select operation.
4667
4668 The current value of C<$,> (if any) is printed between each LIST item.  The
4669 current value of C<$\> (if any) is printed after the entire LIST has been
4670 printed.  Because print takes a LIST, anything in the LIST is evaluated in
4671 list context, including any subroutines whose return lists you pass to
4672 C<print>.  Be careful not to follow the print keyword with a left
4673 parenthesis unless you want the corresponding right parenthesis to
4674 terminate the arguments to the print; put parentheses around all arguments
4675 (or interpose a C<+>, but that doesn't look as good).
4676
4677 If you're storing handles in an array or hash, or in general whenever
4678 you're using any expression more complex than a bareword handle or a plain,
4679 unsubscripted scalar variable to retrieve it, you will have to use a block
4680 returning the filehandle value instead, in which case the LIST may not be
4681 omitted:
4682
4683     print { $files[$i] } "stuff\n";
4684     print { $OK ? STDOUT : STDERR } "stuff\n";
4685
4686 Printing to a closed pipe or socket will generate a SIGPIPE signal.  See
4687 L<perlipc> for more on signal handling.
4688
4689 =item printf FILEHANDLE FORMAT, LIST
4690 X<printf>
4691
4692 =item printf FILEHANDLE
4693
4694