Create perldelta for 5.14.3
[perl.git] / pod / perlvar.pod
1 =head1 NAME
2
3 perlvar - Perl predefined variables
4
5 =head1 DESCRIPTION
6
7 =head2 The Syntax of Variable Names
8
9 Variable names in Perl can have several formats. Usually, they
10 must begin with a letter or underscore, in which case they can be
11 arbitrarily long (up to an internal limit of 251 characters) and
12 may contain letters, digits, underscores, or the special sequence
13 C<::> or C<'>. In this case, the part before the last C<::> or
14 C<'> is taken to be a I<package qualifier>; see L<perlmod>.
15
16 Perl variable names may also be a sequence of digits or a single
17 punctuation or control character. These names are all reserved for
18 special uses by Perl; for example, the all-digits names are used
19 to hold data captured by backreferences after a regular expression
20 match. Perl has a special syntax for the single-control-character
21 names: It understands C<^X> (caret C<X>) to mean the control-C<X>
22 character. For example, the notation C<$^W> (dollar-sign caret
23 C<W>) is the scalar variable whose name is the single character
24 control-C<W>. This is better than typing a literal control-C<W>
25 into your program.
26
27 Since Perl 5.6, Perl variable names may be alphanumeric
28 strings that begin with control characters (or better yet, a caret).
29 These variables must be written in the form C<${^Foo}>; the braces
30 are not optional. C<${^Foo}> denotes the scalar variable whose
31 name is a control-C<F> followed by two C<o>'s. These variables are
32 reserved for future special uses by Perl, except for the ones that
33 begin with C<^_> (control-underscore or caret-underscore). No
34 control-character name that begins with C<^_> will acquire a special
35 meaning in any future version of Perl; such names may therefore be
36 used safely in programs. C<$^_> itself, however, I<is> reserved.
37
38 Perl identifiers that begin with digits, control characters, or
39 punctuation characters are exempt from the effects of the C<package>
40 declaration and are always forced to be in package C<main>; they are
41 also exempt from C<strict 'vars'> errors. A few other names are also
42 exempt in these ways:
43
44         ENV      STDIN
45         INC      STDOUT
46         ARGV     STDERR
47         ARGVOUT
48         SIG
49
50 In particular, the special C<${^_XYZ}> variables are always taken
51 to be in package C<main>, regardless of any C<package> declarations
52 presently in scope.
53
54 =head1 SPECIAL VARIABLES
55
56 The following names have special meaning to Perl. Most punctuation
57 names have reasonable mnemonics, or analogs in the shells.
58 Nevertheless, if you wish to use long variable names, you need only say:
59
60         use English;
61
62 at the top of your program. This aliases all the short names to the long
63 names in the current package. Some even have medium names, generally
64 borrowed from B<awk>. To avoid a performance hit, if you don't need the
65 C<$PREMATCH>, C<$MATCH>, or C<$POSTMATCH> it's best to use the C<English>
66 module without them:
67
68         use English '-no_match_vars';
69
70 Before you continue, note the sort order for variables. In general, we
71 first list the variables in case-insensitive, almost-lexigraphical
72 order (ignoring the C<{> or C<^> preceding words, as in C<${^UNICODE}>
73 or C<$^T>), although C<$_> and C<@_> move up to the top of the pile.
74 For variables with the same identifier, we list it in order of scalar,
75 array, hash, and bareword.
76
77 =head2 General Variables
78
79 =over 8
80
81 =item $ARG
82
83 =item $_
84 X<$_> X<$ARG>
85
86 The default input and pattern-searching space. The following pairs are
87 equivalent:
88
89         while (<>) {...}    # equivalent only in while!
90         while (defined($_ = <>)) {...}
91
92         /^Subject:/
93         $_ =~ /^Subject:/
94
95         tr/a-z/A-Z/
96         $_ =~ tr/a-z/A-Z/
97
98         chomp
99         chomp($_)
100
101 Here are the places where Perl will assume C<$_> even if you don't use it:
102
103 =over 3
104
105 =item *
106
107 The following functions use C<$_> as a default argument:
108
109 abs, alarm, chomp, chop, chr, chroot, cos, defined, eval, exp, glob,
110 hex, int, lc, lcfirst, length, log, lstat, mkdir, oct, ord, pos, print,
111 quotemeta, readlink, readpipe, ref, require, reverse (in scalar context only),
112 rmdir, sin, split (on its second argument), sqrt, stat, study, uc, ucfirst,
113 unlink, unpack.
114
115 =item *
116
117 All file tests (C<-f>, C<-d>) except for C<-t>, which defaults to STDIN.
118 See L<perlfunc/-X>
119
120 =item *
121
122 The pattern matching operations C<m//>, C<s///> and C<tr///> (aka C<y///>)
123 when used without an C<=~> operator.
124
125 =item *
126
127 The default iterator variable in a C<foreach> loop if no other
128 variable is supplied.
129
130 =item *
131
132 The implicit iterator variable in the C<grep()> and C<map()> functions.
133
134 =item *
135
136 The implicit variable of C<given()>.
137
138 =item *
139
140 The default place to put an input record when a C<< <FH> >>
141 operation's result is tested by itself as the sole criterion of a C<while>
142 test. Outside a C<while> test, this will not happen.
143
144 =back
145
146 As C<$_> is a global variable, this may lead in some cases to unwanted
147 side-effects. As of perl 5.9.1, you can now use a lexical version of
148 C<$_> by declaring it in a file or in a block with C<my>. Moreover,
149 declaring C<our $_> restores the global C<$_> in the current scope.
150
151 Mnemonic: underline is understood in certain operations.
152
153 =item @ARG
154
155 =item @_
156 X<@_> X<@ARG>
157
158 Within a subroutine the array C<@_> contains the parameters passed to
159 that subroutine. Inside a subroutine, C<@_> is the default array for
160 the array operators C<push>, C<pop>, C<shift>, and C<unshift>.
161
162 See L<perlsub>.
163
164 =item $LIST_SEPARATOR
165
166 =item $"
167 X<$"> X<$LIST_SEPARATOR>
168
169 When an array or an array slice is interpolated into a double-quoted
170 string or a similar context such as C</.../>, its elements are
171 separated by this value. Default is a space. For example, this:
172
173         print "The array is: @array\n";
174
175 is equivalent to this:
176
177         print "The array is: " . join($", @array) . "\n";
178
179 Mnemonic: works in double-quoted context.
180
181 =item $PROCESS_ID
182
183 =item $PID
184
185 =item $$
186 X<$$> X<$PID> X<$PROCESS_ID>
187
188 The process number of the Perl running this script. You should
189 consider this variable read-only, although it will be altered
190 across C<fork()> calls.
191
192 Note for Linux users: on Linux, the C functions C<getpid()> and
193 C<getppid()> return different values from different threads. In order to
194 be portable, this behavior is not reflected by C<$$>, whose value remains
195 consistent across threads. If you want to call the underlying C<getpid()>,
196 you may use the CPAN module C<Linux::Pid>.
197
198 Mnemonic: same as shells.
199
200 =item $REAL_GROUP_ID
201
202 =item $GID
203
204 =item $(
205 X<$(> X<$GID> X<$REAL_GROUP_ID>
206
207 The real gid of this process. If you are on a machine that supports
208 membership in multiple groups simultaneously, gives a space separated
209 list of groups you are in. The first number is the one returned by
210 C<getgid()>, and the subsequent ones by C<getgroups()>, one of which may be
211 the same as the first number.
212
213 However, a value assigned to C<$(> must be a single number used to
214 set the real gid. So the value given by C<$(> should I<not> be assigned
215 back to C<$(> without being forced numeric, such as by adding zero. Note
216 that this is different to the effective gid (C<$)>) which does take a
217 list.
218
219 You can change both the real gid and the effective gid at the same
220 time by using C<POSIX::setgid()>. Changes to C<$(> require a check to C<$!>
221 to detect any possible errors after an attempted change.
222
223 Mnemonic: parentheses are used to I<group> things. The real gid is the
224 group you I<left>, if you're running setgid.
225
226 =item $EFFECTIVE_GROUP_ID
227
228 =item $EGID
229
230 =item $)
231 X<$)> X<$EGID> X<$EFFECTIVE_GROUP_ID>
232
233 The effective gid of this process. If you are on a machine that
234 supports membership in multiple groups simultaneously, gives a space
235 separated list of groups you are in. The first number is the one
236 returned by C<getegid()>, and the subsequent ones by C<getgroups()>,
237 one of which may be the same as the first number.
238
239 Similarly, a value assigned to C<$)> must also be a space-separated
240 list of numbers. The first number sets the effective gid, and
241 the rest (if any) are passed to C<setgroups()>. To get the effect of an
242 empty list for C<setgroups()>, just repeat the new effective gid; that is,
243 to force an effective gid of 5 and an effectively empty C<setgroups()>
244 list, say C< $) = "5 5" >.
245
246 You can change both the effective gid and the real gid at the same
247 time by using C<POSIX::setgid()> (use only a single numeric argument).
248 Changes to C<$)> require a check to C<$!> to detect any possible errors
249 after an attempted change.
250
251 C<< $< >>, C<< $> >>, C<$(> and C<$)> can be set only on
252 machines that support the corresponding I<set[re][ug]id()> routine. C<$(>
253 and C<$)> can be swapped only on machines supporting C<setregid()>.
254
255 Mnemonic: parentheses are used to I<group> things. The effective gid
256 is the group that's I<right> for you, if you're running setgid.
257
258 =item $PROGRAM_NAME
259
260 =item $0
261 X<$0> X<$PROGRAM_NAME>
262
263 Contains the name of the program being executed.
264
265 On some (but not all) operating systems assigning to C<$0> modifies
266 the argument area that the C<ps> program sees. On some platforms you
267 may have to use special C<ps> options or a different C<ps> to see the
268 changes. Modifying the C<$0> is more useful as a way of indicating the
269 current program state than it is for hiding the program you're
270 running.
271
272 Note that there are platform-specific limitations on the maximum
273 length of C<$0>. In the most extreme case it may be limited to the
274 space occupied by the original C<$0>.
275
276 In some platforms there may be arbitrary amount of padding, for
277 example space characters, after the modified name as shown by C<ps>.
278 In some platforms this padding may extend all the way to the original
279 length of the argument area, no matter what you do (this is the case
280 for example with Linux 2.2).
281
282 Note for BSD users: setting C<$0> does not completely remove "perl"
283 from the ps(1) output. For example, setting C<$0> to C<"foobar"> may
284 result in C<"perl: foobar (perl)"> (whether both the C<"perl: "> prefix
285 and the " (perl)" suffix are shown depends on your exact BSD variant
286 and version). This is an operating system feature, Perl cannot help it.
287
288 In multithreaded scripts Perl coordinates the threads so that any
289 thread may modify its copy of the C<$0> and the change becomes visible
290 to ps(1) (assuming the operating system plays along). Note that
291 the view of C<$0> the other threads have will not change since they
292 have their own copies of it.
293
294 If the program has been given to perl via the switches C<-e> or C<-E>,
295 C<$0> will contain the string C<"-e">.
296
297 On Linux as of perl 5.14 the legacy process name will be set with
298 C<prctl(2)>, in addition to altering the POSIX name via C<argv[0]> as
299 perl has done since version 4.000. Now system utilities that read the
300 legacy process name such as ps, top and killall will recognize the
301 name you set when assigning to C<$0>. The string you supply will be
302 cut off at 16 bytes, this is a limitation imposed by Linux.
303
304 Mnemonic: same as B<sh> and B<ksh>.
305
306 =item $SUBSCRIPT_SEPARATOR
307
308 =item $SUBSEP
309
310 =item $;
311 X<$;> X<$SUBSEP> X<SUBSCRIPT_SEPARATOR>
312
313 The subscript separator for multidimensional array emulation. If you
314 refer to a hash element as
315
316         $foo{$a,$b,$c}
317
318 it really means
319
320         $foo{join($;, $a, $b, $c)}
321
322 But don't put
323
324         @foo{$a,$b,$c}  # a slice--note the @
325
326 which means
327
328         ($foo{$a},$foo{$b},$foo{$c})
329
330 Default is "\034", the same as SUBSEP in B<awk>. If your keys contain
331 binary data there might not be any safe value for C<$;>.
332
333 Consider using "real" multidimensional arrays as described
334 in L<perllol>.
335
336 Mnemonic: comma (the syntactic subscript separator) is a semi-semicolon.
337
338 =item $REAL_USER_ID
339
340 =item $UID
341
342 =item $<
343 X<< $< >> X<$UID> X<$REAL_USER_ID>
344
345 The real uid of this process. You can change both the real uid and the
346 effective uid at the same time by using C<POSIX::setuid()>. Since
347 changes to C<< $< >> require a system call, check C<$!> after a change
348 attempt to detect any possible errors.
349
350 Mnemonic: it's the uid you came I<from>, if you're running setuid.
351
352 =item $EFFECTIVE_USER_ID
353
354 =item $EUID
355
356 =item $>
357 X<< $> >> X<$EUID> X<$EFFECTIVE_USER_ID>
358
359 The effective uid of this process. For example:
360
361         $< = $>;            # set real to effective uid
362         ($<,$>) = ($>,$<);  # swap real and effective uids
363
364 You can change both the effective uid and the real uid at the same
365 time by using C<POSIX::setuid()>. Changes to C<< $> >> require a check
366 to C<$!> to detect any possible errors after an attempted change.
367
368 C<< $< >> and C<< $> >> can be swapped only on machines
369 supporting C<setreuid()>.
370
371 Mnemonic: it's the uid you went I<to>, if you're running setuid.
372
373 =item $a
374
375 =item $b
376 X<$a> X<$b>
377
378 Special package variables when using C<sort()>, see L<perlfunc/sort>.
379 Because of this specialness C<$a> and C<$b> don't need to be declared
380 (using C<use vars>, or C<our()>) even when using the C<strict 'vars'>
381 pragma. Don't lexicalize them with C<my $a> or C<my $b> if you want to
382 be able to use them in the C<sort()> comparison block or function.
383
384 =item $COMPILING
385
386 =item $^C
387 X<$^C> X<$COMPILING>
388
389 The current value of the flag associated with the B<-c> switch.
390 Mainly of use with B<-MO=...> to allow code to alter its behavior
391 when being compiled, such as for example to C<AUTOLOAD> at compile
392 time rather than normal, deferred loading. Setting
393 C<$^C = 1> is similar to calling C<B::minus_c>.
394
395 This variable was added in Perl 5.6.
396
397 =item $DEBUGGING
398
399 =item $^D
400 X<$^D> X<$DEBUGGING>
401
402 The current value of the debugging flags. May be read or set. Like its
403 command-line equivalent, you can use numeric or symbolic values, eg
404 C<$^D = 10> or C<$^D = "st">.
405
406 Mnemonic: value of B<-D> switch.
407
408 =item ${^ENCODING}
409 X<${^ENCODING}>
410
411 The I<object reference> to the C<Encode> object that is used to convert
412 the source code to Unicode. Thanks to this variable your Perl script
413 does not have to be written in UTF-8. Default is I<undef>. The direct
414 manipulation of this variable is highly discouraged.
415
416 This variable was added in Perl 5.8.2.
417
418 =item %ENV
419 X<%ENV>
420
421 The hash C<%ENV> contains your current environment. Setting a
422 value in C<ENV> changes the environment for any child processes
423 you subsequently C<fork()> off.
424
425 =item $SYSTEM_FD_MAX
426
427 =item $^F
428 X<$^F> X<$SYSTEM_FD_MAX>
429
430 The maximum system file descriptor, ordinarily 2. System file
431 descriptors are passed to C<exec()>ed processes, while higher file
432 descriptors are not. Also, during an C<open()>, system file descriptors are
433 preserved even if the C<open()> fails (ordinary file descriptors are
434 closed before the C<open()> is attempted). The close-on-exec
435 status of a file descriptor will be decided according to the value of
436 C<$^F> when the corresponding file, pipe, or socket was opened, not the
437 time of the C<exec()>.
438
439 =item @F
440 X<@F>
441
442 The array C<@F> contains the fields of each line read in when autosplit
443 mode is turned on. See L<perlrun> for the B<-a> switch. This array
444 is package-specific, and must be declared or given a full package name
445 if not in package main when running under C<strict 'vars'>.
446
447 =item ${^GLOBAL_PHASE}
448 X<${^GLOBAL_PHASE}>
449
450 The current phase of the perl interpreter.
451
452 Possible values are:
453
454 =over 8
455
456 =item CONSTRUCT
457
458 The C<PerlInterpreter*> is being constructed via C<perl_construct>. This
459 value is mostly there for completeness and for use via the
460 underlying C variable C<PL_phase>. It's not really possible for Perl
461 code to be executed unless construction of the interpreter is
462 finished.
463
464 =item START
465
466 This is the global compile-time. That includes, basically, every
467 C<BEGIN> block executed directly or indirectly from during the
468 compile-time of the top-level program.
469
470 This phase is not called "BEGIN" to avoid confusion with
471 C<BEGIN>-blocks, as those are executed during compile-time of any
472 compilation unit, not just the top-level program. A new, localised
473 compile-time entered at run-time, for example by constructs as
474 C<eval "use SomeModule"> are not global interpreter phases, and
475 therefore aren't reflected by C<${^GLOBAL_PHASE}>.
476
477 =item CHECK
478
479 Execution of any C<CHECK> blocks.
480
481 =item INIT
482
483 Similar to "CHECK", but for C<INIT>-blocks, not C<CHECK> blocks.
484
485 =item RUN
486
487 The main run-time, i.e. the execution of C<PL_main_root>.
488
489 =item END
490
491 Execution of any C<END> blocks.
492
493 =item DESTRUCT
494
495 Global destruction.
496
497 =back
498
499 Also note that there's no value for UNITCHECK-blocks. That's because
500 those are run for each compilation unit individually, and therefore is
501 not a global interpreter phase.
502
503 Not every program has to go through each of the possible phases, but
504 transition from one phase to another can only happen in the order
505 described in the above list.
506
507 An example of all of the phases Perl code can see:
508
509     BEGIN { print "compile-time: ${^GLOBAL_PHASE}\n" }
510
511     INIT  { print "init-time: ${^GLOBAL_PHASE}\n" }
512
513     CHECK { print "check-time: ${^GLOBAL_PHASE}\n" }
514
515     {
516         package Print::Phase;
517
518         sub new {
519             my ($class, $time) = @_;
520             return bless \$time, $class;
521         }
522
523         sub DESTROY {
524             my $self = shift;
525             print "$$self: ${^GLOBAL_PHASE}\n";
526         }
527     }
528
529     print "run-time: ${^GLOBAL_PHASE}\n";
530
531     my $runtime = Print::Phase->new(
532         "lexical variables are garbage collected before END"
533     );
534
535     END   { print "end-time: ${^GLOBAL_PHASE}\n" }
536
537     our $destruct = Print::Phase->new(
538         "package variables are garbage collected after END"
539     );
540
541 This will print out
542
543     compile-time: START
544     check-time: CHECK
545     init-time: INIT
546     run-time: RUN
547     lexical variables are garbage collected before END: RUN
548     end-time: END
549     package variables are garbage collected after END: DESTRUCT
550
551 This variable was added in Perl 5.14.0.
552
553 =item $^H
554 X<$^H>
555
556 WARNING: This variable is strictly for internal use only. Its availability,
557 behavior, and contents are subject to change without notice.
558
559 This variable contains compile-time hints for the Perl interpreter. At the
560 end of compilation of a BLOCK the value of this variable is restored to the
561 value when the interpreter started to compile the BLOCK.
562
563 When perl begins to parse any block construct that provides a lexical scope
564 (e.g., eval body, required file, subroutine body, loop body, or conditional
565 block), the existing value of C<$^H> is saved, but its value is left unchanged.
566 When the compilation of the block is completed, it regains the saved value.
567 Between the points where its value is saved and restored, code that
568 executes within BEGIN blocks is free to change the value of C<$^H>.
569
570 This behavior provides the semantic of lexical scoping, and is used in,
571 for instance, the C<use strict> pragma.
572
573 The contents should be an integer; different bits of it are used for
574 different pragmatic flags. Here's an example:
575
576         sub add_100 { $^H |= 0x100 }
577
578         sub foo {
579                 BEGIN { add_100() }
580                 bar->baz($boon);
581         }
582
583 Consider what happens during execution of the BEGIN block. At this point
584 the BEGIN block has already been compiled, but the body of C<foo()> is still
585 being compiled. The new value of C<$^H> will therefore be visible only while
586 the body of C<foo()> is being compiled.
587
588 Substitution of C<BEGIN { add_100() }> block with:
589
590         BEGIN { require strict; strict->import('vars') }
591
592 demonstrates how C<use strict 'vars'> is implemented. Here's a conditional
593 version of the same lexical pragma:
594
595         BEGIN { require strict; strict->import('vars') if $condition }
596
597 This variable was added in Perl 5.003.
598
599 =item %^H
600 X<%^H>
601
602 The C<%^H> hash provides the same scoping semantic as C<$^H>. This makes it
603 useful for implementation of lexically scoped pragmas. See L<perlpragma>.
604
605 This variable was added in Perl 5.6.
606
607 =item @INC
608 X<@INC>
609
610 The array C<@INC> contains the list of places that the C<do EXPR>,
611 C<require>, or C<use> constructs look for their library files. It
612 initially consists of the arguments to any B<-I> command-line
613 switches, followed by the default Perl library, probably
614 F</usr/local/lib/perl>, followed by ".", to represent the current
615 directory. ("." will not be appended if taint checks are enabled,
616 either by C<-T> or by C<-t>.)  If you need to modify this at runtime,
617 you should use the C<use lib> pragma to get the machine-dependent
618 library properly loaded also:
619
620         use lib '/mypath/libdir/';
621         use SomeMod;
622
623 You can also insert hooks into the file inclusion system by putting Perl
624 code directly into C<@INC>. Those hooks may be subroutine references, array
625 references or blessed objects. See L<perlfunc/require> for details.
626
627 =item %INC
628 X<%INC>
629
630 The hash C<%INC> contains entries for each filename included via the
631 C<do>, C<require>, or C<use> operators. The key is the filename
632 you specified (with module names converted to pathnames), and the
633 value is the location of the file found. The C<require>
634 operator uses this hash to determine whether a particular file has
635 already been included.
636
637 If the file was loaded via a hook (e.g. a subroutine reference, see
638 L<perlfunc/require> for a description of these hooks), this hook is
639 by default inserted into C<%INC> in place of a filename. Note, however,
640 that the hook may have set the C<%INC> entry by itself to provide some more
641 specific info.
642
643 =item $INPLACE_EDIT
644
645 =item $^I
646 X<$^I> X<$INPLACE_EDIT>
647
648 The current value of the inplace-edit extension. Use C<undef> to disable
649 inplace editing.
650
651 Mnemonic: value of B<-i> switch.
652
653 =item $^M
654 X<$^M>
655
656 By default, running out of memory is an untrappable, fatal error.
657 However, if suitably built, Perl can use the contents of C<$^M>
658 as an emergency memory pool after C<die()>ing. Suppose that your Perl
659 were compiled with C<-DPERL_EMERGENCY_SBRK> and used Perl's malloc.
660 Then
661
662         $^M = 'a' x (1 << 16);
663
664 would allocate a 64K buffer for use in an emergency. See the
665 F<INSTALL> file in the Perl distribution for information on how to
666 add custom C compilation flags when compiling perl. To discourage casual
667 use of this advanced feature, there is no L<English|English> long name for
668 this variable.
669
670 This variable was added in Perl 5.004.
671
672 =item $OSNAME
673
674 =item $^O
675 X<$^O> X<$OSNAME>
676
677 The name of the operating system under which this copy of Perl was
678 built, as determined during the configuration process. For examples
679 see L<perlport/PLATFORMS>.
680
681 The value is identical to C<$Config{'osname'}>. See also L<Config>
682 and the B<-V> command-line switch documented in L<perlrun>.
683
684 In Windows platforms, C<$^O> is not very helpful: since it is always
685 C<MSWin32>, it doesn't tell the difference between
686 95/98/ME/NT/2000/XP/CE/.NET. Use C<Win32::GetOSName()> or
687 Win32::GetOSVersion() (see L<Win32> and L<perlport>) to distinguish
688 between the variants.
689
690 This variable was added in Perl 5.003.
691
692 =item ${^OPEN}
693 X<${^OPEN}>
694
695 An internal variable used by PerlIO. A string in two parts, separated
696 by a C<\0> byte, the first part describes the input layers, the second
697 part describes the output layers.
698
699 This variable was added in Perl 5.8.2.
700
701 =item $PERLDB
702
703 =item $^P
704 X<$^P> X<$PERLDB>
705
706 The internal variable for debugging support. The meanings of the
707 various bits are subject to change, but currently indicate:
708
709 =over 6
710
711 =item 0x01
712
713 Debug subroutine enter/exit.
714
715 =item 0x02
716
717 Line-by-line debugging. Causes C<DB::DB()> subroutine to be called for each
718 statement executed. Also causes saving source code lines (like 0x400).
719
720 =item 0x04
721
722 Switch off optimizations.
723
724 =item 0x08
725
726 Preserve more data for future interactive inspections.
727
728 =item 0x10
729
730 Keep info about source lines on which a subroutine is defined.
731
732 =item 0x20
733
734 Start with single-step on.
735
736 =item 0x40
737
738 Use subroutine address instead of name when reporting.
739
740 =item 0x80
741
742 Report C<goto &subroutine> as well.
743
744 =item 0x100
745
746 Provide informative "file" names for evals based on the place they were compiled.
747
748 =item 0x200
749
750 Provide informative names to anonymous subroutines based on the place they
751 were compiled.
752
753 =item 0x400
754
755 Save source code lines into C<@{"_<$filename"}>.
756
757 =back
758
759 Some bits may be relevant at compile-time only, some at
760 run-time only. This is a new mechanism and the details may change.
761 See also L<perldebguts>.
762
763 =item %SIG
764 X<%SIG>
765
766 The hash C<%SIG> contains signal handlers for signals. For example:
767
768         sub handler {   # 1st argument is signal name
769                 my($sig) = @_;
770                 print "Caught a SIG$sig--shutting down\n";
771                 close(LOG);
772                 exit(0);
773                 }
774
775         $SIG{'INT'}  = \&handler;
776         $SIG{'QUIT'} = \&handler;
777         ...
778         $SIG{'INT'}  = 'DEFAULT';   # restore default action
779         $SIG{'QUIT'} = 'IGNORE';    # ignore SIGQUIT
780
781 Using a value of C<'IGNORE'> usually has the effect of ignoring the
782 signal, except for the C<CHLD> signal. See L<perlipc> for more about
783 this special case.
784
785 Here are some other examples:
786
787         $SIG{"PIPE"} = "Plumber";   # assumes main::Plumber (not recommended)
788         $SIG{"PIPE"} = \&Plumber;   # just fine; assume current Plumber
789         $SIG{"PIPE"} = *Plumber;    # somewhat esoteric
790         $SIG{"PIPE"} = Plumber();   # oops, what did Plumber() return??
791
792 Be sure not to use a bareword as the name of a signal handler,
793 lest you inadvertently call it.
794
795 If your system has the C<sigaction()> function then signal handlers
796 are installed using it. This means you get reliable signal handling.
797
798 The default delivery policy of signals changed in Perl 5.8.0 from
799 immediate (also known as "unsafe") to deferred, also known as "safe
800 signals". See L<perlipc> for more information.
801
802 Certain internal hooks can be also set using the C<%SIG> hash. The
803 routine indicated by C<$SIG{__WARN__}> is called when a warning
804 message is about to be printed. The warning message is passed as the
805 first argument. The presence of a C<__WARN__> hook causes the
806 ordinary printing of warnings to C<STDERR> to be suppressed. You can
807 use this to save warnings in a variable, or turn warnings into fatal
808 errors, like this:
809
810         local $SIG{__WARN__} = sub { die $_[0] };
811         eval $proggie;
812
813 As the C<'IGNORE'> hook is not supported by C<__WARN__>, you can
814 disable warnings using the empty subroutine:
815
816         local $SIG{__WARN__} = sub {};
817
818 The routine indicated by C<$SIG{__DIE__}> is called when a fatal
819 exception is about to be thrown. The error message is passed as the
820 first argument. When a C<__DIE__> hook routine returns, the exception
821 processing continues as it would have in the absence of the hook,
822 unless the hook routine itself exits via a C<goto>, a loop exit, or a
823 C<die()>. The C<__DIE__> handler is explicitly disabled during the
824 call, so that you can die from a C<__DIE__> handler. Similarly for
825 C<__WARN__>.
826
827 Due to an implementation glitch, the C<$SIG{__DIE__}> hook is called
828 even inside an C<eval()>. Do not use this to rewrite a pending
829 exception in C<$@>, or as a bizarre substitute for overriding
830 C<CORE::GLOBAL::die()>. This strange action at a distance may be fixed
831 in a future release so that C<$SIG{__DIE__}> is only called if your
832 program is about to exit, as was the original intent. Any other use is
833 deprecated.
834
835 C<__DIE__>/C<__WARN__> handlers are very special in one respect: they
836 may be called to report (probable) errors found by the parser. In such
837 a case the parser may be in inconsistent state, so any attempt to
838 evaluate Perl code from such a handler will probably result in a
839 segfault. This means that warnings or errors that result from parsing
840 Perl should be used with extreme caution, like this:
841
842         require Carp if defined $^S;
843         Carp::confess("Something wrong") if defined &Carp::confess;
844         die "Something wrong, but could not load Carp to give backtrace...
845            To see backtrace try starting Perl with -MCarp switch";
846
847 Here the first line will load C<Carp> I<unless> it is the parser who
848 called the handler. The second line will print backtrace and die if
849 C<Carp> was available. The third line will be executed only if C<Carp> was
850 not available.
851
852 Having to even think about the C<$^S> variable in your exception
853 handlers is simply wrong. C<$SIG{__DIE__}> as currently implemented
854 invites grievous and difficult to track down errors. Avoid it
855 and use an C<END{}> or CORE::GLOBAL::die override instead.
856
857 See L<perlfunc/die>, L<perlfunc/warn>, L<perlfunc/eval>, and
858 L<warnings> for additional information.
859
860 =item $BASETIME
861
862 =item $^T
863 X<$^T> X<$BASETIME>
864
865 The time at which the program began running, in seconds since the
866 epoch (beginning of 1970). The values returned by the B<-M>, B<-A>,
867 and B<-C> filetests are based on this value.
868
869 =item ${^TAINT}
870 X<${^TAINT}>
871
872 Reflects if taint mode is on or off. 1 for on (the program was run with
873 B<-T>), 0 for off, -1 when only taint warnings are enabled (i.e. with
874 B<-t> or B<-TU>).
875
876 This variable is read-only.
877
878 This variable was added in Perl 5.8.
879
880 =item ${^UNICODE}
881 X<${^UNICODE}>
882
883 Reflects certain Unicode settings of Perl. See L<perlrun>
884 documentation for the C<-C> switch for more information about
885 the possible values.
886
887 This variable is set during Perl startup and is thereafter read-only.
888
889 This variable was added in Perl 5.8.2.
890
891 =item ${^UTF8CACHE}
892 X<${^UTF8CACHE}>
893
894 This variable controls the state of the internal UTF-8 offset caching code.
895 1 for on (the default), 0 for off, -1 to debug the caching code by checking
896 all its results against linear scans, and panicking on any discrepancy.
897
898 This variable was added in Perl 5.8.9.
899
900 =item ${^UTF8LOCALE}
901 X<${^UTF8LOCALE}>
902
903 This variable indicates whether a UTF-8 locale was detected by perl at
904 startup. This information is used by perl when it's in
905 adjust-utf8ness-to-locale mode (as when run with the C<-CL> command-line
906 switch); see L<perlrun> for more info on this.
907
908 This variable was added in Perl 5.8.8.
909
910 =item $PERL_VERSION
911
912 =item $^V
913 X<$^V> X<$PERL_VERSION>
914
915 The revision, version, and subversion of the Perl interpreter,
916 represented as a C<version> object.
917
918 This variable first appeared in perl 5.6.0; earlier versions of perl
919 will see an undefined value. Before perl 5.10.0 C<$^V> was represented
920 as a v-string.
921
922 C<$^V> can be used to determine whether the Perl interpreter executing
923 a script is in the right range of versions. For example:
924
925         warn "Hashes not randomized!\n" if !$^V or $^V lt v5.8.1
926
927 To convert C<$^V> into its string representation use C<sprintf()>'s
928 C<"%vd"> conversion:
929
930         printf "version is v%vd\n", $^V;  # Perl's version
931
932 See the documentation of C<use VERSION> and C<require VERSION>
933 for a convenient way to fail if the running Perl interpreter is too old.
934
935 See also C<$]> for an older representation of the Perl version.
936
937 This variable was added in Perl 5.6.
938
939 Mnemonic: use ^V for Version Control.
940
941 =item ${^WIN32_SLOPPY_STAT}
942 X<${^WIN32_SLOPPY_STAT}> X<sitecustomize> X<sitecustomize.pl>
943
944 If this variable is set to a true value, then C<stat()> on Windows will
945 not try to open the file. This means that the link count cannot be
946 determined and file attributes may be out of date if additional
947 hardlinks to the file exist. On the other hand, not opening the file
948 is considerably faster, especially for files on network drives.
949
950 This variable could be set in the F<sitecustomize.pl> file to
951 configure the local Perl installation to use "sloppy" C<stat()> by
952 default. See the documentation for B<-f> in
953 L<perlrun|perlrun/"Command Switches"> for more information about site
954 customization.
955
956 This variable was added in Perl 5.10.
957
958 =item $EXECUTABLE_NAME
959
960 =item $^X
961 X<$^X> X<$EXECUTABLE_NAME>
962
963 The name used to execute the current copy of Perl, from C's
964 C<argv[0]> or (where supported) F</proc/self/exe>.
965
966 Depending on the host operating system, the value of C<$^X> may be
967 a relative or absolute pathname of the perl program file, or may
968 be the string used to invoke perl but not the pathname of the
969 perl program file. Also, most operating systems permit invoking
970 programs that are not in the PATH environment variable, so there
971 is no guarantee that the value of C<$^X> is in PATH. For VMS, the
972 value may or may not include a version number.
973
974 You usually can use the value of C<$^X> to re-invoke an independent
975 copy of the same perl that is currently running, e.g.,
976
977         @first_run = `$^X -le "print int rand 100 for 1..100"`;
978
979 But recall that not all operating systems support forking or
980 capturing of the output of commands, so this complex statement
981 may not be portable.
982
983 It is not safe to use the value of C<$^X> as a path name of a file,
984 as some operating systems that have a mandatory suffix on
985 executable files do not require use of the suffix when invoking
986 a command. To convert the value of C<$^X> to a path name, use the
987 following statements:
988
989         # Build up a set of file names (not command names).
990         use Config;
991         my $this_perl = $^X;
992         if ($^O ne 'VMS') {
993                 $this_perl .= $Config{_exe}
994                   unless $this_perl =~ m/$Config{_exe}$/i;
995                 }
996
997 Because many operating systems permit anyone with read access to
998 the Perl program file to make a copy of it, patch the copy, and
999 then execute the copy, the security-conscious Perl programmer
1000 should take care to invoke the installed copy of perl, not the
1001 copy referenced by C<$^X>. The following statements accomplish
1002 this goal, and produce a pathname that can be invoked as a
1003 command or referenced as a file.
1004
1005         use Config;
1006         my $secure_perl_path = $Config{perlpath};
1007         if ($^O ne 'VMS') {
1008                 $secure_perl_path .= $Config{_exe}
1009                         unless $secure_perl_path =~ m/$Config{_exe}$/i;
1010                 }
1011
1012 =back
1013
1014 =head2 Variables related to regular expressions
1015
1016 Most of the special variables related to regular expressions are side
1017 effects. Perl sets these variables when it has a successful match, so
1018 you should check the match result before using them. For instance:
1019
1020         if( /P(A)TT(ER)N/ ) {
1021                 print "I found $1 and $2\n";
1022                 }
1023
1024 These variables are read-only and dynamically-scoped, unless we note
1025 otherwise.
1026
1027 The dynamic nature of the regular expression variables means that
1028 their value is limited to the block that they are in, as demonstrated
1029 by this bit of code:
1030
1031         my $outer = 'Wallace and Grommit';
1032         my $inner = 'Mutt and Jeff';
1033
1034         my $pattern = qr/(\S+) and (\S+)/;
1035
1036         sub show_n { print "\$1 is $1; \$2 is $2\n" }
1037
1038         {
1039         OUTER:
1040                 show_n() if $outer =~ m/$pattern/;
1041
1042                 INNER: {
1043                         show_n() if $inner =~ m/$pattern/;
1044                         }
1045
1046                 show_n();
1047         }
1048
1049 The output shows that while in the C<OUTER> block, the values of C<$1>
1050 and C<$2> are from the match against C<$outer>. Inside the C<INNER>
1051 block, the values of C<$1> and C<$2> are from the match against
1052 C<$inner>, but only until the end of the block (i.e. the dynamic
1053 scope). After the C<INNER> block completes, the values of C<$1> and
1054 C<$2> return to the values for the match against C<$outer> even though
1055 we have not made another match:
1056
1057         $1 is Wallace; $2 is Grommit
1058         $1 is Mutt; $2 is Jeff
1059         $1 is Wallace; $2 is Grommit
1060
1061 Due to an unfortunate accident of Perl's implementation, C<use
1062 English> imposes a considerable performance penalty on all regular
1063 expression matches in a program because it uses the C<$`>, C<$&>, and
1064 C<$'>, regardless of whether they occur in the scope of C<use
1065 English>. For that reason, saying C<use English> in libraries is
1066 strongly discouraged unless you import it without the match variables:
1067
1068         use English '-no_match_vars'
1069
1070 The C<Devel::NYTProf> and C<Devel::FindAmpersand>
1071 modules can help you find uses of these
1072 problematic match variables in your code.
1073
1074 Since Perl 5.10, you can use the C</p> match operator flag and the
1075 C<${^PREMATCH}>, C<${^MATCH}>, and C<${^POSTMATCH}> variables instead
1076 so you only suffer the performance penalties.
1077
1078 =over 8
1079
1080 =item $<I<digits>> ($1, $2, ...)
1081 X<$1> X<$2> X<$3>
1082
1083 Contains the subpattern from the corresponding set of capturing
1084 parentheses from the last successful pattern match, not counting patterns
1085 matched in nested blocks that have been exited already.
1086
1087 These variables are read-only and dynamically-scoped.
1088
1089 Mnemonic: like \digits.
1090
1091 =item $MATCH
1092
1093 =item $&
1094 X<$&> X<$MATCH>
1095
1096 The string matched by the last successful pattern match (not counting
1097 any matches hidden within a BLOCK or C<eval()> enclosed by the current
1098 BLOCK).
1099
1100 The use of this variable anywhere in a program imposes a considerable
1101 performance penalty on all regular expression matches. To avoid this
1102 penalty, you can extract the same substring by using L</@->. Starting
1103 with Perl 5.10, you can use the </p> match flag and the C<${^MATCH}>
1104 variable to do the same thing for particular match operations.
1105
1106 This variable is read-only and dynamically-scoped.
1107
1108 Mnemonic: like C<&> in some editors.
1109
1110 =item ${^MATCH}
1111 X<${^MATCH}>
1112
1113 This is similar to C<$&> (C<$MATCH>) except that it does not incur the
1114 performance penalty associated with that variable, and is only guaranteed
1115 to return a defined value when the pattern was compiled or executed with
1116 the C</p> modifier.
1117
1118 This variable was added in Perl 5.10.
1119
1120 This variable is read-only and dynamically-scoped.
1121
1122 =item $PREMATCH
1123
1124 =item $`
1125 X<$`> X<$PREMATCH> X<${^PREMATCH}>
1126
1127 The string preceding whatever was matched by the last successful
1128 pattern match, not counting any matches hidden within a BLOCK or C<eval>
1129 enclosed by the current BLOCK.
1130
1131 The use of this variable anywhere in a program imposes a considerable
1132 performance penalty on all regular expression matches. To avoid this
1133 penalty, you can extract the same substring by using L</@->. Starting
1134 with Perl 5.10, you can use the </p> match flag and the
1135 C<${^PREMATCH}> variable to do the same thing for particular match
1136 operations.
1137
1138 This variable is read-only and dynamically-scoped.
1139
1140 Mnemonic: C<`> often precedes a quoted string.
1141
1142 =item ${^PREMATCH}
1143 X<$`> X<${^PREMATCH}>
1144
1145 This is similar to C<$`> ($PREMATCH) except that it does not incur the
1146 performance penalty associated with that variable, and is only guaranteed
1147 to return a defined value when the pattern was compiled or executed with
1148 the C</p> modifier.
1149
1150 This variable was added in Perl 5.10
1151
1152 This variable is read-only and dynamically-scoped.
1153
1154 =item $POSTMATCH
1155
1156 =item $'
1157 X<$'> X<$POSTMATCH> X<${^POSTMATCH}> X<@->
1158
1159 The string following whatever was matched by the last successful
1160 pattern match (not counting any matches hidden within a BLOCK or C<eval()>
1161 enclosed by the current BLOCK). Example:
1162
1163         local $_ = 'abcdefghi';
1164         /def/;
1165         print "$`:$&:$'\n";     # prints abc:def:ghi
1166
1167 The use of this variable anywhere in a program imposes a considerable
1168 performance penalty on all regular expression matches.
1169 To avoid this penalty, you can extract the same substring by
1170 using L</@->. Starting with Perl 5.10, you can use the </p> match flag
1171 and the C<${^POSTMATCH}> variable to do the same thing for particular
1172 match operations.
1173
1174 This variable is read-only and dynamically-scoped.
1175
1176 Mnemonic: C<'> often follows a quoted string.
1177
1178 =item ${^POSTMATCH}
1179 X<${^POSTMATCH}> X<$'> X<$POSTMATCH>
1180
1181 This is similar to C<$'> (C<$POSTMATCH>) except that it does not incur the
1182 performance penalty associated with that variable, and is only guaranteed
1183 to return a defined value when the pattern was compiled or executed with
1184 the C</p> modifier.
1185
1186 This variable was added in Perl 5.10.
1187
1188 This variable is read-only and dynamically-scoped.
1189
1190 =item $LAST_PAREN_MATCH
1191
1192 =item $+
1193 X<$+> X<$LAST_PAREN_MATCH>
1194
1195 The text matched by the last bracket of the last successful search pattern.
1196 This is useful if you don't know which one of a set of alternative patterns
1197 matched. For example:
1198
1199         /Version: (.*)|Revision: (.*)/ && ($rev = $+);
1200
1201 This variable is read-only and dynamically-scoped.
1202
1203 Mnemonic: be positive and forward looking.
1204
1205 =item $LAST_SUBMATCH_RESULT
1206
1207 =item $^N
1208 X<$^N> X<$LAST_SUBMATCH_RESULT>
1209
1210 The text matched by the used group most-recently closed (i.e. the group
1211 with the rightmost closing parenthesis) of the last successful search
1212 pattern.
1213
1214 This is primarily used inside C<(?{...})> blocks for examining text
1215 recently matched. For example, to effectively capture text to a variable
1216 (in addition to C<$1>, C<$2>, etc.), replace C<(...)> with
1217
1218         (?:(...)(?{ $var = $^N }))
1219
1220 By setting and then using C<$var> in this way relieves you from having to
1221 worry about exactly which numbered set of parentheses they are.
1222
1223 This variable was added in Perl 5.8.
1224
1225 Mnemonic: the (possibly) Nested parenthesis that most recently closed.
1226
1227 =item @LAST_MATCH_END
1228
1229 =item @+
1230 X<@+> X<@LAST_MATCH_END>
1231
1232 This array holds the offsets of the ends of the last successful
1233 submatches in the currently active dynamic scope. C<$+[0]> is
1234 the offset into the string of the end of the entire match. This
1235 is the same value as what the C<pos> function returns when called
1236 on the variable that was matched against. The I<n>th element
1237 of this array holds the offset of the I<n>th submatch, so
1238 C<$+[1]> is the offset past where C<$1> ends, C<$+[2]> the offset
1239 past where C<$2> ends, and so on. You can use C<$#+> to determine
1240 how many subgroups were in the last successful match. See the
1241 examples given for the C<@-> variable.
1242
1243 This variable was added in Perl 5.6.
1244
1245 =item %LAST_PAREN_MATCH
1246
1247 =item %+
1248 X<%+> X<%LAST_PAREN_MATCH>
1249
1250 Similar to C<@+>, the C<%+> hash allows access to the named capture
1251 buffers, should they exist, in the last successful match in the
1252 currently active dynamic scope.
1253
1254 For example, C<$+{foo}> is equivalent to C<$1> after the following match:
1255
1256         'foo' =~ /(?<foo>foo)/;
1257
1258 The keys of the C<%+> hash list only the names of buffers that have
1259 captured (and that are thus associated to defined values).
1260
1261 The underlying behaviour of C<%+> is provided by the
1262 L<Tie::Hash::NamedCapture> module.
1263
1264 B<Note:> C<%-> and C<%+> are tied views into a common internal hash
1265 associated with the last successful regular expression. Therefore mixing
1266 iterative access to them via C<each> may have unpredictable results.
1267 Likewise, if the last successful match changes, then the results may be
1268 surprising.
1269
1270 This variable was added in Perl 5.10.
1271
1272 This variable is read-only and dynamically-scoped.
1273
1274 =item @LAST_MATCH_START
1275
1276 =item @-
1277 X<@-> X<@LAST_MATCH_START>
1278
1279 C<$-[0]> is the offset of the start of the last successful match.
1280 C<$-[>I<n>C<]> is the offset of the start of the substring matched by
1281 I<n>-th subpattern, or undef if the subpattern did not match.
1282
1283 Thus, after a match against C<$_>, C<$&> coincides with C<substr $_, $-[0],
1284 $+[0] - $-[0]>. Similarly, $I<n> coincides with C<substr $_, $-[n],
1285 $+[n] - $-[n]> if C<$-[n]> is defined, and $+ coincides with
1286 C<substr $_, $-[$#-], $+[$#-] - $-[$#-]>. One can use C<$#-> to find the last
1287 matched subgroup in the last successful match. Contrast with
1288 C<$#+>, the number of subgroups in the regular expression. Compare
1289 with C<@+>.
1290
1291 This array holds the offsets of the beginnings of the last
1292 successful submatches in the currently active dynamic scope.
1293 C<$-[0]> is the offset into the string of the beginning of the
1294 entire match. The I<n>th element of this array holds the offset
1295 of the I<n>th submatch, so C<$-[1]> is the offset where C<$1>
1296 begins, C<$-[2]> the offset where C<$2> begins, and so on.
1297
1298 After a match against some variable C<$var>:
1299
1300 =over 5
1301
1302 =item C<$`> is the same as C<substr($var, 0, $-[0])>
1303
1304 =item C<$&> is the same as C<substr($var, $-[0], $+[0] - $-[0])>
1305
1306 =item C<$'> is the same as C<substr($var, $+[0])>
1307
1308 =item C<$1> is the same as C<substr($var, $-[1], $+[1] - $-[1])>
1309
1310 =item C<$2> is the same as C<substr($var, $-[2], $+[2] - $-[2])>
1311
1312 =item C<$3> is the same as C<substr($var, $-[3], $+[3] - $-[3])>
1313
1314 =back
1315
1316 This variable was added in Perl 5.6.
1317
1318 =item %LAST_MATCH_START
1319
1320 =item %-
1321 X<%-> X<%LAST_MATCH_START>
1322
1323 Similar to C<%+>, this variable allows access to the named capture groups
1324 in the last successful match in the currently active dynamic scope. To
1325 each capture group name found in the regular expression, it associates a
1326 reference to an array containing the list of values captured by all
1327 buffers with that name (should there be several of them), in the order
1328 where they appear.
1329
1330 Here's an example:
1331
1332     if ('1234' =~ /(?<A>1)(?<B>2)(?<A>3)(?<B>4)/) {
1333         foreach my $bufname (sort keys %-) {
1334             my $ary = $-{$bufname};
1335             foreach my $idx (0..$#$ary) {
1336                 print "\$-{$bufname}[$idx] : ",
1337                       (defined($ary->[$idx]) ? "'$ary->[$idx]'" : "undef"),
1338                       "\n";
1339             }
1340         }
1341     }
1342
1343 would print out:
1344
1345         $-{A}[0] : '1'
1346         $-{A}[1] : '3'
1347         $-{B}[0] : '2'
1348         $-{B}[1] : '4'
1349
1350 The keys of the C<%-> hash correspond to all buffer names found in
1351 the regular expression.
1352
1353 The behaviour of C<%-> is implemented via the
1354 L<Tie::Hash::NamedCapture> module.
1355
1356 B<Note:> C<%-> and C<%+> are tied views into a common internal hash
1357 associated with the last successful regular expression. Therefore mixing
1358 iterative access to them via C<each> may have unpredictable results.
1359 Likewise, if the last successful match changes, then the results may be
1360 surprising.
1361
1362 This variable was added in Perl 5.10
1363
1364 This variable is read-only and dynamically-scoped.
1365
1366 =item $LAST_REGEXP_CODE_RESULT
1367
1368 =item $^R
1369 X<$^R> X<$LAST_REGEXP_CODE_RESULT>
1370
1371 The result of evaluation of the last successful C<(?{ code })>
1372 regular expression assertion (see L<perlre>). May be written to.
1373
1374 This variable was added in Perl 5.005.
1375
1376 =item ${^RE_DEBUG_FLAGS}
1377 X<${^RE_DEBUG_FLAGS}>
1378
1379 The current value of the regex debugging flags. Set to 0 for no debug output
1380 even when the C<re 'debug'> module is loaded. See L<re> for details.
1381
1382 This variable was added in Perl 5.10.
1383
1384 =item ${^RE_TRIE_MAXBUF}
1385 X<${^RE_TRIE_MAXBUF}>
1386
1387 Controls how certain regex optimisations are applied and how much memory they
1388 utilize. This value by default is 65536 which corresponds to a 512kB temporary
1389 cache. Set this to a higher value to trade memory for speed when matching
1390 large alternations. Set it to a lower value if you want the optimisations to
1391 be as conservative of memory as possible but still occur, and set it to a
1392 negative value to prevent the optimisation and conserve the most memory.
1393 Under normal situations this variable should be of no interest to you.
1394
1395 This variable was added in Perl 5.10.
1396
1397 =back
1398
1399 =head2 Variables related to filehandles
1400
1401 Variables that depend on the currently selected filehandle may be set
1402 by calling an appropriate object method on the C<IO::Handle> object,
1403 although this is less efficient than using the regular built-in
1404 variables. (Summary lines below for this contain the word HANDLE.)
1405 First you must say
1406
1407         use IO::Handle;
1408
1409 after which you may use either
1410
1411         method HANDLE EXPR
1412
1413 or more safely,
1414
1415         HANDLE->method(EXPR)
1416
1417 Each method returns the old value of the C<IO::Handle> attribute. The
1418 methods each take an optional EXPR, which, if supplied, specifies the
1419 new value for the C<IO::Handle> attribute in question. If not
1420 supplied, most methods do nothing to the current value--except for
1421 C<autoflush()>, which will assume a 1 for you, just to be different.
1422
1423 Because loading in the C<IO::Handle> class is an expensive operation,
1424 you should learn how to use the regular built-in variables.
1425
1426 A few of these variables are considered "read-only". This means that
1427 if you try to assign to this variable, either directly or indirectly
1428 through a reference, you'll raise a run-time exception.
1429
1430 You should be very careful when modifying the default values of most
1431 special variables described in this document. In most cases you want
1432 to localize these variables before changing them, since if you don't,
1433 the change may affect other modules which rely on the default values
1434 of the special variables that you have changed. This is one of the
1435 correct ways to read the whole file at once:
1436
1437         open my $fh, "<", "foo" or die $!;
1438         local $/; # enable localized slurp mode
1439         my $content = <$fh>;
1440         close $fh;
1441
1442 But the following code is quite bad:
1443
1444         open my $fh, "<", "foo" or die $!;
1445         undef $/; # enable slurp mode
1446         my $content = <$fh>;
1447         close $fh;
1448
1449 since some other module, may want to read data from some file in the
1450 default "line mode", so if the code we have just presented has been
1451 executed, the global value of C<$/> is now changed for any other code
1452 running inside the same Perl interpreter.
1453
1454 Usually when a variable is localized you want to make sure that this
1455 change affects the shortest scope possible. So unless you are already
1456 inside some short C<{}> block, you should create one yourself. For
1457 example:
1458
1459         my $content = '';
1460         open my $fh, "<", "foo" or die $!;
1461         {
1462                 local $/;
1463                 $content = <$fh>;
1464         }
1465         close $fh;
1466
1467 Here is an example of how your own code can go broken:
1468
1469         for ( 1..3 ){
1470                 $\ = "\r\n";
1471                 nasty_break();
1472                 print "$_";
1473         }
1474
1475         sub nasty_break {
1476         $\ = "\f";
1477         # do something with $_
1478         }
1479
1480 You probably expect this code to print the equivalent of
1481
1482     "1\r\n2\r\n3\r\n"
1483
1484 but instead you get:
1485
1486     "1\f2\f3\f"
1487
1488 Why? Because C<nasty_break()> modifies C<$\> without localizing it
1489 first. The value you set in  C<nasty_break()> is still there when you
1490 return. The fix is to add C<local()> so the value doesn't leak out of
1491 C<nasty_break()>:
1492
1493         local $\ = "\f";
1494
1495 It's easy to notice the problem in such a short example, but in more
1496 complicated code you are looking for trouble if you don't localize
1497 changes to the special variables.
1498
1499 =over 8
1500
1501 =item $ARGV
1502 X<$ARGV>
1503
1504 Contains the name of the current file when reading from C<< <> >>.
1505
1506 =item @ARGV
1507 X<@ARGV>
1508
1509 The array C<@ARGV> contains the command-line arguments intended for
1510 the script. C<$#ARGV> is generally the number of arguments minus
1511 one, because C<$ARGV[0]> is the first argument, I<not> the program's
1512 command name itself. See C<$0> for the command name.
1513
1514 =item ARGV
1515 X<ARGV>
1516
1517 The special filehandle that iterates over command-line filenames in
1518 C<@ARGV>. Usually written as the null filehandle in the angle operator
1519 C<< <> >>. Note that currently C<ARGV> only has its magical effect
1520 within the C<< <> >> operator; elsewhere it is just a plain filehandle
1521 corresponding to the last file opened by C<< <> >>. In particular,
1522 passing C<\*ARGV> as a parameter to a function that expects a filehandle
1523 may not cause your function to automatically read the contents of all the
1524 files in C<@ARGV>.
1525
1526 =item ARGVOUT
1527 X<ARGVOUT>
1528
1529 The special filehandle that points to the currently open output file
1530 when doing edit-in-place processing with B<-i>. Useful when you have
1531 to do a lot of inserting and don't want to keep modifying C<$_>. See
1532 L<perlrun> for the B<-i> switch.
1533
1534 =item Handle->output_field_separator( EXPR )
1535
1536 =item $OUTPUT_FIELD_SEPARATOR
1537
1538 =item $OFS
1539
1540 =item $,
1541 X<$,> X<$OFS> X<$OUTPUT_FIELD_SEPARATOR>
1542
1543 The output field separator for the print operator. If defined, this
1544 value is printed between each of print's arguments. Default is C<undef>.
1545
1546 Mnemonic: what is printed when there is a "," in your print statement.
1547
1548 =item HANDLE->input_line_number( EXPR )
1549
1550 =item $INPUT_LINE_NUMBER
1551
1552 =item $NR
1553
1554 =item $.
1555 X<$.> X<$NR> X<$INPUT_LINE_NUMBER> X<line number>
1556
1557 Current line number for the last filehandle accessed.
1558
1559 Each filehandle in Perl counts the number of lines that have been read
1560 from it. (Depending on the value of C<$/>, Perl's idea of what
1561 constitutes a line may not match yours.)  When a line is read from a
1562 filehandle (via C<readline()> or C<< <> >>), or when C<tell()> or
1563 C<seek()> is called on it, C<$.> becomes an alias to the line counter
1564 for that filehandle.
1565
1566 You can adjust the counter by assigning to C<$.>, but this will not
1567 actually move the seek pointer. I<Localizing C<$.> will not localize
1568 the filehandle's line count>. Instead, it will localize perl's notion
1569 of which filehandle C<$.> is currently aliased to.
1570
1571 C<$.> is reset when the filehandle is closed, but B<not> when an open
1572 filehandle is reopened without an intervening C<close()>. For more
1573 details, see L<perlop/"IE<sol>O Operators">. Because C<< <> >> never does
1574 an explicit close, line numbers increase across C<ARGV> files (but see
1575 examples in L<perlfunc/eof>).
1576
1577 You can also use C<< HANDLE->input_line_number(EXPR) >> to access the
1578 line counter for a given filehandle without having to worry about
1579 which handle you last accessed.
1580
1581 Mnemonic: many programs use "." to mean the current line number.
1582
1583 =item HANDLE->input_record_separator( EXPR )
1584
1585 =item $INPUT_RECORD_SEPARATOR
1586
1587 =item $RS
1588
1589 =item $/
1590 X<$/> X<$RS> X<$INPUT_RECORD_SEPARATOR>
1591
1592 The input record separator, newline by default. This influences Perl's
1593 idea of what a "line" is. Works like B<awk>'s RS variable, including
1594 treating empty lines as a terminator if set to the null string (an
1595 empty line cannot contain any spaces or tabs). You may set it to a
1596 multi-character string to match a multi-character terminator, or to
1597 C<undef> to read through the end of file. Setting it to C<"\n\n">
1598 means something slightly different than setting to C<"">, if the file
1599 contains consecutive empty lines. Setting to C<""> will treat two or
1600 more consecutive empty lines as a single empty line. Setting to
1601 C<"\n\n"> will blindly assume that the next input character belongs to
1602 the next paragraph, even if it's a newline.
1603
1604     local $/;           # enable "slurp" mode
1605     local $_ = <FH>;    # whole file now here
1606     s/\n[ \t]+/ /g;
1607
1608 Remember: the value of C<$/> is a string, not a regex. B<awk> has to
1609 be better for something. :-)
1610
1611 Setting C<$/> to a reference to an integer, scalar containing an
1612 integer, or scalar that's convertible to an integer will attempt to
1613 read records instead of lines, with the maximum record size being the
1614 referenced integer. So this:
1615
1616     local $/ = \32768; # or \"32768", or \$var_containing_32768
1617     open my $fh, "<", $myfile or die $!;
1618     local $_ = <$fh>;
1619
1620 will read a record of no more than 32768 bytes from FILE. If you're
1621 not reading from a record-oriented file (or your OS doesn't have
1622 record-oriented files), then you'll likely get a full chunk of data
1623 with every read. If a record is larger than the record size you've
1624 set, you'll get the record back in pieces. Trying to set the record
1625 size to zero or less will cause reading in the (rest of the) whole file.
1626
1627 On VMS, record reads are done with the equivalent of C<sysread>,
1628 so it's best not to mix record and non-record reads on the same
1629 file. (This is unlikely to be a problem, because any file you'd
1630 want to read in record mode is probably unusable in line mode.)
1631 Non-VMS systems do normal I/O, so it's safe to mix record and
1632 non-record reads of a file.
1633
1634 See also L<perlport/"Newlines">. Also see C<$.>.
1635
1636 Mnemonic: / delimits line boundaries when quoting poetry.
1637
1638 =item Handle->output_record_separator( EXPR )
1639
1640 =item $OUTPUT_RECORD_SEPARATOR
1641
1642 =item $ORS
1643
1644 =item $\
1645 X<$\> X<$ORS> X<$OUTPUT_RECORD_SEPARATOR>
1646
1647 The output record separator for the print operator. If defined, this
1648 value is printed after the last of print's arguments. Default is C<undef>.
1649
1650 Mnemonic: you set C<$\> instead of adding "\n" at the end of the print.
1651 Also, it's just like C<$/>, but it's what you get "back" from Perl.
1652
1653 =item HANDLE->autoflush( EXPR )
1654
1655 =item $OUTPUT_AUTOFLUSH
1656
1657 =item $|
1658 X<$|> X<autoflush> X<flush> X<$OUTPUT_AUTOFLUSH>
1659
1660 If set to nonzero, forces a flush right away and after every write or
1661 print on the currently selected output channel. Default is 0
1662 (regardless of whether the channel is really buffered by the system or
1663 not; C<$|> tells you only whether you've asked Perl explicitly to
1664 flush after each write). STDOUT will typically be line buffered if
1665 output is to the terminal and block buffered otherwise. Setting this
1666 variable is useful primarily when you are outputting to a pipe or
1667 socket, such as when you are running a Perl program under B<rsh> and
1668 want to see the output as it's happening. This has no effect on input
1669 buffering. See L<perlfunc/getc> for that. See L<perlfunc/select> on
1670 how to select the output channel. See also L<IO::Handle>.
1671
1672 Mnemonic: when you want your pipes to be piping hot.
1673
1674 =back
1675
1676 =head3 Variables related to formats
1677
1678 The special variables for formats are a subset of those for
1679 filehandles. See L<perlform> for more information about Perl's
1680 formats.
1681
1682 =over 8
1683
1684 =item $ACCUMULATOR
1685
1686 =item $^A
1687 X<$^A> X<$ACCUMULATOR>
1688
1689 The current value of the C<write()> accumulator for C<format()> lines.
1690 A format contains C<formline()> calls that put their result into
1691 C<$^A>. After calling its format, C<write()> prints out the contents
1692 of C<$^A> and empties. So you never really see the contents of C<$^A>
1693 unless you call C<formline()> yourself and then look at it. See
1694 L<perlform> and L<perlfunc/"formline PICTURE,LIST">.
1695
1696 =item HANDLE->format_formfeed(EXPR)
1697
1698 =item $FORMAT_FORMFEED
1699
1700 =item $^L
1701 X<$^L> X<$FORMAT_FORMFEED>
1702
1703 What formats output as a form feed. The default is C<\f>.
1704
1705 =item HANDLE->format_page_number(EXPR)
1706
1707 =item $FORMAT_PAGE_NUMBER
1708
1709 =item $%
1710 X<$%> X<$FORMAT_PAGE_NUMBER>
1711
1712 The current page number of the currently selected output channel.
1713
1714 Mnemonic: C<%> is page number in B<nroff>.
1715
1716 =item HANDLE->format_lines_left(EXPR)
1717
1718 =item $FORMAT_LINES_LEFT
1719
1720 =item $-
1721 X<$-> X<$FORMAT_LINES_LEFT>
1722
1723 The number of lines left on the page of the currently selected output
1724 channel.
1725
1726 Mnemonic: lines_on_page - lines_printed.
1727
1728 =item Handle->format_line_break_characters EXPR
1729
1730 =item $FORMAT_LINE_BREAK_CHARACTERS
1731
1732 =item $:
1733 X<$:> X<FORMAT_LINE_BREAK_CHARACTERS>
1734
1735 The current set of characters after which a string may be broken to
1736 fill continuation fields (starting with C<^>) in a format. The default is
1737 S<" \n-">, to break on a space, newline, or a hyphen.
1738
1739 Mnemonic: a "colon" in poetry is a part of a line.
1740
1741 =item HANDLE->format_lines_per_page(EXPR)
1742
1743 =item $FORMAT_LINES_PER_PAGE
1744
1745 =item $=
1746 X<$=> X<$FORMAT_LINES_PER_PAGE>
1747
1748 The current page length (printable lines) of the currently selected
1749 output channel. The default is 60.
1750
1751 Mnemonic: = has horizontal lines.
1752
1753 =item HANDLE->format_top_name(EXPR)
1754
1755 =item $FORMAT_TOP_NAME
1756
1757 =item $^
1758 X<$^> X<$FORMAT_TOP_NAME>
1759
1760 The name of the current top-of-page format for the currently selected
1761 output channel. The default is the name of the filehandle with C<_TOP>
1762 appended. For example, the default format top name for the C<STDOUT>
1763 filehanlde is C<STDOUT_TOP>.
1764
1765 Mnemonic: points to top of page.
1766
1767 =item HANDLE->format_name(EXPR)
1768
1769 =item $FORMAT_NAME
1770
1771 =item $~
1772 X<$~> X<$FORMAT_NAME>
1773
1774 The name of the current report format for the currently selected
1775 output channel. The default format name is the same as the filehandle
1776 name. For example, the default format name for the C<STDOUT>
1777 filehandle is just C<STDOUT>.
1778
1779 Mnemonic: brother to C<$^>.
1780
1781 =back
1782
1783 =head2 Error Variables
1784 X<error> X<exception>
1785
1786 The variables C<$@>, C<$!>, C<$^E>, and C<$?> contain information
1787 about different types of error conditions that may appear during
1788 execution of a Perl program. The variables are shown ordered by
1789 the "distance" between the subsystem which reported the error and
1790 the Perl process. They correspond to errors detected by the Perl
1791 interpreter, C library, operating system, or an external program,
1792 respectively.
1793
1794 To illustrate the differences between these variables, consider the
1795 following Perl expression, which uses a single-quoted string. After
1796 execution of this statement, perl may have set all four special error
1797 variables:
1798
1799         eval q{
1800                 open my $pipe, "/cdrom/install |" or die $!;
1801                 my @res = <$pipe>;
1802                 close $pipe or die "bad pipe: $?, $!";
1803             };
1804
1805 When perl executes the C<eval()> expression, it translates the
1806 C<open()>, C<< <PIPE> >>, and C<close> calls in the C run-time library
1807 and thence to the operating system kernel. perl sets C<$!> to
1808 the C library's C<errno> if one of these calls fails.
1809
1810 C<$@> is set if the string to be C<eval>-ed did not compile (this may
1811 happen if C<open> or C<close> were imported with bad prototypes), or
1812 if Perl code executed during evaluation C<die()>d. In these cases the
1813 value of C<$@> is the compile error, or the argument to C<die> (which
1814 will interpolate C<$!> and C<$?>). (See also L<Fatal>, though.)
1815
1816 Under a few operating systems, C<$^E> may contain a more verbose error
1817 indicator, such as in this case, "CDROM tray not closed." Systems that
1818 do not support extended error messages leave C<$^E> the same as C<$!>.
1819
1820 Finally, C<$?> may be set to non-0 value if the external program
1821 F</cdrom/install> fails. The upper eight bits reflect specific error
1822 conditions encountered by the program (the program's C<exit()> value).
1823 The lower eight bits reflect mode of failure, like signal death and
1824 core dump information. See C<wait(2)> for details. In contrast to
1825 C<$!> and C<$^E>, which are set only if error condition is detected,
1826 the variable C<$?> is set on each C<wait> or pipe C<close>,
1827 overwriting the old value. This is more like C<$@>, which on every
1828 C<eval()> is always set on failure and cleared on success.
1829
1830 For more details, see the individual descriptions at C<$@>, C<$!>,
1831 C<$^E>, and C<$?>.
1832
1833 =over 8
1834
1835 =item ${^CHILD_ERROR_NATIVE}
1836 X<$^CHILD_ERROR_NATIVE>
1837
1838 The native status returned by the last pipe close, backtick (C<``>)
1839 command, successful call to C<wait()> or C<waitpid()>, or from the
1840 C<system()> operator. On POSIX-like systems this value can be decoded
1841 with the WIFEXITED, WEXITSTATUS, WIFSIGNALED, WTERMSIG, WIFSTOPPED,
1842 WSTOPSIG and WIFCONTINUED functions provided by the L<POSIX> module.
1843
1844 Under VMS this reflects the actual VMS exit status; i.e. it is the
1845 same as C<$?> when the pragma C<use vmsish 'status'> is in effect.
1846
1847 This variable was added in Perl 5.8.9.
1848
1849 =item $EXTENDED_OS_ERROR
1850
1851 =item $^E
1852 X<$^E> X<$EXTENDED_OS_ERROR>
1853
1854 Error information specific to the current operating system. At the
1855 moment, this differs from C<$!> under only VMS, OS/2, and Win32 (and
1856 for MacPerl). On all other platforms, C<$^E> is always just the same
1857 as C<$!>.
1858
1859 Under VMS, C<$^E> provides the VMS status value from the last system
1860 error. This is more specific information about the last system error
1861 than that provided by C<$!>. This is particularly important when C<$!>
1862 is set to B<EVMSERR>.
1863
1864 Under OS/2, C<$^E> is set to the error code of the last call to OS/2
1865 API either via CRT, or directly from perl.
1866
1867 Under Win32, C<$^E> always returns the last error information reported
1868 by the Win32 call C<GetLastError()> which describes the last error
1869 from within the Win32 API. Most Win32-specific code will report errors
1870 via C<$^E>. ANSI C and Unix-like calls set C<errno> and so most
1871 portable Perl code will report errors via C<$!>.
1872
1873 Caveats mentioned in the description of C<$!> generally apply to
1874 C<$^E>, also.
1875
1876 This variable was added in Perl 5.003.
1877
1878 Mnemonic: Extra error explanation.
1879
1880 =item $EXCEPTIONS_BEING_CAUGHT
1881
1882 =item $^S
1883 X<$^S> X<$EXCEPTIONS_BEING_CAUGHT>
1884
1885 Current state of the interpreter.
1886
1887         $^S         State
1888         ---------   -------------------
1889         undef       Parsing module/eval
1890         true (1)    Executing an eval
1891         false (0)   Otherwise
1892
1893 The first state may happen in C<$SIG{__DIE__}> and C<$SIG{__WARN__}>
1894 handlers.
1895
1896 This variable was added in Perl 5.004.
1897
1898 =item $WARNING
1899
1900 =item $^W
1901 X<$^W> X<$WARNING>
1902
1903 The current value of the warning switch, initially true if B<-w> was
1904 used, false otherwise, but directly modifiable.
1905
1906 See also L<warnings>.
1907
1908 Mnemonic: related to the B<-w> switch.
1909
1910 =item ${^WARNING_BITS}
1911 X<${^WARNING_BITS}>
1912
1913 The current set of warning checks enabled by the C<use warnings> pragma.
1914 See the documentation of C<warnings> for more details.
1915
1916 This variable was added in Perl 5.10.
1917
1918 =item $OS_ERROR
1919
1920 =item $ERRNO
1921
1922 =item $!
1923 X<$!> X<$ERRNO> X<$OS_ERROR>
1924
1925 If used numerically, yields the current value of the C C<errno>
1926 variable, or in other words, if a system or library call fails, it
1927 sets this variable. This means that the value of C<$!> is meaningful
1928 only I<immediately> after a B<failure>:
1929
1930         if (open my $fh, "<", $filename) {
1931                 # Here $! is meaningless.
1932                 ...
1933     }
1934     else {
1935                 # ONLY here is $! meaningful.
1936                 ...
1937                 # Already here $! might be meaningless.
1938     }
1939     # Since here we might have either success or failure,
1940     # here $! is meaningless.
1941
1942 The I<meaningless> stands for anything: zero, non-zero,
1943 C<undef>. A successful system or library call does B<not> set the
1944 variable to zero.
1945
1946 If used as a string, yields the corresponding system error string. You
1947 can assign a number to C<$!> to set I<errno> if, for instance, you
1948 want C<"$!"> to return the string for error I<n>, or you want to set
1949 the exit value for the C<die()> operator.
1950
1951 Mnemonic: What just went bang?
1952
1953 =item %OS_ERROR
1954
1955 =item %ERRNO
1956
1957 =item %!
1958 X<%!> X<%OS_ERROR> X<%ERRNO>
1959
1960 Each element of C<%!> has a true value only if C<$!> is set to that
1961 value. For example, C<$!{ENOENT}> is true if and only if the current
1962 value of C<$!> is C<ENOENT>; that is, if the most recent error was "No
1963 such file or directory" (or its moral equivalent: not all operating
1964 systems give that exact error, and certainly not all languages). To
1965 check if a particular key is meaningful on your system, use C<exists
1966 $!{the_key}>; for a list of legal keys, use C<keys %!>. See L<Errno>
1967 for more information, and also see L</$!>.
1968
1969 This variable was added in Perl 5.005.
1970
1971 =item $CHILD_ERROR
1972
1973 =item $?
1974 X<$?> X<$CHILD_ERROR>
1975
1976 The status returned by the last pipe close, backtick (C<``>) command,
1977 successful call to C<wait()> or C<waitpid()>, or from the C<system()>
1978 operator. This is just the 16-bit status word returned by the
1979 traditional Unix C<wait()> system call (or else is made up to look
1980 like it). Thus, the exit value of the subprocess is really (C<<< $? >>
1981 8 >>>), and C<$? & 127> gives which signal, if any, the process died
1982 from, and C<$? & 128> reports whether there was a core dump.
1983
1984 Additionally, if the C<h_errno> variable is supported in C, its value
1985 is returned via C<$?> if any C<gethost*()> function fails.
1986
1987 If you have installed a signal handler for C<SIGCHLD>, the
1988 value of C<$?> will usually be wrong outside that handler.
1989
1990 Inside an C<END> subroutine C<$?> contains the value that is going to be
1991 given to C<exit()>. You can modify C<$?> in an C<END> subroutine to
1992 change the exit status of your program. For example:
1993
1994     END {
1995         $? = 1 if $? == 255;  # die would make it 255
1996     }
1997
1998 Under VMS, the pragma C<use vmsish 'status'> makes C<$?> reflect the
1999 actual VMS exit status, instead of the default emulation of POSIX
2000 status; see L<perlvms/$?> for details.
2001
2002 Mnemonic: similar to B<sh> and B<ksh>.
2003
2004 =item $EVAL_ERROR
2005
2006 =item $@
2007 X<$@> X<$EVAL_ERROR>
2008
2009 The Perl syntax error message from the last C<eval()> operator. If C<$@> is
2010 the null string, the last C<eval()> parsed and executed correctly
2011 (although the operations you invoked may have failed in the normal
2012 fashion).
2013
2014 Warning messages are not collected in this variable. You can, however,
2015 set up a routine to process warnings by setting C<$SIG{__WARN__}> as
2016 described in L</%SIG>.
2017
2018 Mnemonic: Where was the syntax error "at"?
2019
2020 =back
2021
2022 =head2 Deprecated and removed variables
2023
2024 Deprecating a variable announces the intent of the perl maintainers to
2025 eventually remove the variable from the langauge. It may still be
2026 available despite its status. Using a deprecated variable triggers
2027 a warning.
2028
2029 Once a variable is removed, its use triggers an error telling you
2030 the variable is unsupported.
2031
2032 See L<perldiag> for details about error messages.
2033
2034 =over 8
2035
2036 =item $OFMT
2037
2038 =item $#
2039 X<$#> X<$OFMT>
2040
2041 C<$#> was a variable that you could be use to format printed numbers.
2042 After a deprecation cycle, its magic was removed in Perl 5.10 and
2043 using it now triggers a warning: C<$# is no longer supported>.
2044
2045 This is not the sigil you use in front of an array name to get the
2046 last index, like C<$#array>. That's still how you get the last index
2047 of an array in Perl. The two have nothing to do with each other.
2048
2049 Deprecated in Perl 5.
2050
2051 Removed in Perl 5.10.
2052
2053 =item $*
2054 X<$*>
2055
2056 C<$*> was a variable that you could use to enable multiline matching.
2057 After a deprecation cycle, its magic was removed in Perl 5.10.
2058 Using it now triggers a warning: C<$* is no longer supported>.
2059 You should use the C</s> and C</m> regexp modifiers instead.
2060
2061 Deprecated in Perl 5.
2062
2063 Removed in Perl 5.10.
2064
2065 =item $ARRAY_BASE
2066
2067 =item $[
2068 X<$[> X<$ARRAY_BASE>
2069
2070 This variable stores the index of the first element in an array, and
2071 of the first character in a substring. The default is 0, but you could
2072 theoretically set it to 1 to make Perl behave more like B<awk> (or Fortran)
2073 when subscripting and when evaluating the index() and substr() functions.
2074
2075 As of release 5 of Perl, assignment to C<$[> is treated as a compiler
2076 directive, and cannot influence the behavior of any other file.
2077 (That's why you can only assign compile-time constants to it.)
2078 Its use is highly discouraged.
2079
2080 Prior to Perl 5.10, assignment to C<$[> could be seen from outer lexical
2081 scopes in the same file, unlike other compile-time directives (such as
2082 L<strict>). Using local() on it would bind its value strictly to a lexical
2083 block. Now it is always lexically scoped.
2084
2085 Mnemonic: [ begins subscripts.
2086
2087 Deprecated in Perl 5.12.
2088
2089 =item $OLD_PERL_VERSION
2090
2091 =item $]
2092 X<$]> X<$OLD_PERL_VERSION>
2093
2094 See C<$^V> for a more modern representation of the Perl version that allows
2095 accurate string comparisons.
2096
2097 The version + patchlevel / 1000 of the Perl interpreter. This variable
2098 can be used to determine whether the Perl interpreter executing a
2099 script is in the right range of versions:
2100
2101     warn "No checksumming!\n" if $] < 3.019;
2102
2103 The floating point representation can sometimes lead to inaccurate
2104 numeric comparisons.
2105
2106 See also the documentation of C<use VERSION> and C<require VERSION>
2107 for a convenient way to fail if the running Perl interpreter is too old.
2108
2109 Mnemonic: Is this version of perl in the right bracket?
2110
2111 Deprecated in Perl 5.6.
2112
2113 =back
2114
2115 =cut