Create perldelta for 5.14.3
[perl.git] / pod / perlsub.pod
1 =head1 NAME
2 X<subroutine> X<function>
3
4 perlsub - Perl subroutines
5
6 =head1 SYNOPSIS
7
8 To declare subroutines:
9 X<subroutine, declaration> X<sub>
10
11     sub NAME;                     # A "forward" declaration.
12     sub NAME(PROTO);              #  ditto, but with prototypes
13     sub NAME : ATTRS;             #  with attributes
14     sub NAME(PROTO) : ATTRS;      #  with attributes and prototypes
15
16     sub NAME BLOCK                # A declaration and a definition.
17     sub NAME(PROTO) BLOCK         #  ditto, but with prototypes
18     sub NAME : ATTRS BLOCK        #  with attributes
19     sub NAME(PROTO) : ATTRS BLOCK #  with prototypes and attributes
20
21 To define an anonymous subroutine at runtime:
22 X<subroutine, anonymous>
23
24     $subref = sub BLOCK;                 # no proto
25     $subref = sub (PROTO) BLOCK;         # with proto
26     $subref = sub : ATTRS BLOCK;         # with attributes
27     $subref = sub (PROTO) : ATTRS BLOCK; # with proto and attributes
28
29 To import subroutines:
30 X<import>
31
32     use MODULE qw(NAME1 NAME2 NAME3);
33
34 To call subroutines:
35 X<subroutine, call> X<call>
36
37     NAME(LIST);    # & is optional with parentheses.
38     NAME LIST;     # Parentheses optional if predeclared/imported.
39     &NAME(LIST);   # Circumvent prototypes.
40     &NAME;         # Makes current @_ visible to called subroutine.
41
42 =head1 DESCRIPTION
43
44 Like many languages, Perl provides for user-defined subroutines.
45 These may be located anywhere in the main program, loaded in from
46 other files via the C<do>, C<require>, or C<use> keywords, or
47 generated on the fly using C<eval> or anonymous subroutines.
48 You can even call a function indirectly using a variable containing
49 its name or a CODE reference.
50
51 The Perl model for function call and return values is simple: all
52 functions are passed as parameters one single flat list of scalars, and
53 all functions likewise return to their caller one single flat list of
54 scalars.  Any arrays or hashes in these call and return lists will
55 collapse, losing their identities--but you may always use
56 pass-by-reference instead to avoid this.  Both call and return lists may
57 contain as many or as few scalar elements as you'd like.  (Often a
58 function without an explicit return statement is called a subroutine, but
59 there's really no difference from Perl's perspective.)
60 X<subroutine, parameter> X<parameter>
61
62 Any arguments passed in show up in the array C<@_>.  Therefore, if
63 you called a function with two arguments, those would be stored in
64 C<$_[0]> and C<$_[1]>.  The array C<@_> is a local array, but its
65 elements are aliases for the actual scalar parameters.  In particular,
66 if an element C<$_[0]> is updated, the corresponding argument is
67 updated (or an error occurs if it is not updatable).  If an argument
68 is an array or hash element which did not exist when the function
69 was called, that element is created only when (and if) it is modified
70 or a reference to it is taken.  (Some earlier versions of Perl
71 created the element whether or not the element was assigned to.)
72 Assigning to the whole array C<@_> removes that aliasing, and does
73 not update any arguments.
74 X<subroutine, argument> X<argument> X<@_>
75
76 A C<return> statement may be used to exit a subroutine, optionally
77 specifying the returned value, which will be evaluated in the
78 appropriate context (list, scalar, or void) depending on the context of
79 the subroutine call.  If you specify no return value, the subroutine
80 returns an empty list in list context, the undefined value in scalar
81 context, or nothing in void context.  If you return one or more
82 aggregates (arrays and hashes), these will be flattened together into
83 one large indistinguishable list.
84
85 If no C<return> is found and if the last statement is an expression, its
86 value is returned. If the last statement is a loop control structure
87 like a C<foreach> or a C<while>, the returned value is unspecified. The
88 empty sub returns the empty list.
89 X<subroutine, return value> X<return value> X<return>
90
91 Perl does not have named formal parameters.  In practice all you
92 do is assign to a C<my()> list of these.  Variables that aren't
93 declared to be private are global variables.  For gory details
94 on creating private variables, see L<"Private Variables via my()">
95 and L<"Temporary Values via local()">.  To create protected
96 environments for a set of functions in a separate package (and
97 probably a separate file), see L<perlmod/"Packages">.
98 X<formal parameter> X<parameter, formal>
99
100 Example:
101
102     sub max {
103         my $max = shift(@_);
104         foreach $foo (@_) {
105             $max = $foo if $max < $foo;
106         }
107         return $max;
108     }
109     $bestday = max($mon,$tue,$wed,$thu,$fri);
110
111 Example:
112
113     # get a line, combining continuation lines
114     #  that start with whitespace
115
116     sub get_line {
117         $thisline = $lookahead;  # global variables!
118         LINE: while (defined($lookahead = <STDIN>)) {
119             if ($lookahead =~ /^[ \t]/) {
120                 $thisline .= $lookahead;
121             }
122             else {
123                 last LINE;
124             }
125         }
126         return $thisline;
127     }
128
129     $lookahead = <STDIN>;       # get first line
130     while (defined($line = get_line())) {
131         ...
132     }
133
134 Assigning to a list of private variables to name your arguments:
135
136     sub maybeset {
137         my($key, $value) = @_;
138         $Foo{$key} = $value unless $Foo{$key};
139     }
140
141 Because the assignment copies the values, this also has the effect
142 of turning call-by-reference into call-by-value.  Otherwise a
143 function is free to do in-place modifications of C<@_> and change
144 its caller's values.
145 X<call-by-reference> X<call-by-value>
146
147     upcase_in($v1, $v2);  # this changes $v1 and $v2
148     sub upcase_in {
149         for (@_) { tr/a-z/A-Z/ }
150     }
151
152 You aren't allowed to modify constants in this way, of course.  If an
153 argument were actually literal and you tried to change it, you'd take a
154 (presumably fatal) exception.   For example, this won't work:
155 X<call-by-reference> X<call-by-value>
156
157     upcase_in("frederick");
158
159 It would be much safer if the C<upcase_in()> function
160 were written to return a copy of its parameters instead
161 of changing them in place:
162
163     ($v3, $v4) = upcase($v1, $v2);  # this doesn't change $v1 and $v2
164     sub upcase {
165         return unless defined wantarray;  # void context, do nothing
166         my @parms = @_;
167         for (@parms) { tr/a-z/A-Z/ }
168         return wantarray ? @parms : $parms[0];
169     }
170
171 Notice how this (unprototyped) function doesn't care whether it was
172 passed real scalars or arrays.  Perl sees all arguments as one big,
173 long, flat parameter list in C<@_>.  This is one area where
174 Perl's simple argument-passing style shines.  The C<upcase()>
175 function would work perfectly well without changing the C<upcase()>
176 definition even if we fed it things like this:
177
178     @newlist   = upcase(@list1, @list2);
179     @newlist   = upcase( split /:/, $var );
180
181 Do not, however, be tempted to do this:
182
183     (@a, @b)   = upcase(@list1, @list2);
184
185 Like the flattened incoming parameter list, the return list is also
186 flattened on return.  So all you have managed to do here is stored
187 everything in C<@a> and made C<@b> empty.  See 
188 L<Pass by Reference> for alternatives.
189
190 A subroutine may be called using an explicit C<&> prefix.  The
191 C<&> is optional in modern Perl, as are parentheses if the
192 subroutine has been predeclared.  The C<&> is I<not> optional
193 when just naming the subroutine, such as when it's used as
194 an argument to defined() or undef().  Nor is it optional when you
195 want to do an indirect subroutine call with a subroutine name or
196 reference using the C<&$subref()> or C<&{$subref}()> constructs,
197 although the C<< $subref->() >> notation solves that problem.
198 See L<perlref> for more about all that.
199 X<&>
200
201 Subroutines may be called recursively.  If a subroutine is called
202 using the C<&> form, the argument list is optional, and if omitted,
203 no C<@_> array is set up for the subroutine: the C<@_> array at the
204 time of the call is visible to subroutine instead.  This is an
205 efficiency mechanism that new users may wish to avoid.
206 X<recursion>
207
208     &foo(1,2,3);        # pass three arguments
209     foo(1,2,3);         # the same
210
211     foo();              # pass a null list
212     &foo();             # the same
213
214     &foo;               # foo() get current args, like foo(@_) !!
215     foo;                # like foo() IFF sub foo predeclared, else "foo"
216
217 Not only does the C<&> form make the argument list optional, it also
218 disables any prototype checking on arguments you do provide.  This
219 is partly for historical reasons, and partly for having a convenient way
220 to cheat if you know what you're doing.  See L<Prototypes> below.
221 X<&>
222
223 Subroutines whose names are in all upper case are reserved to the Perl
224 core, as are modules whose names are in all lower case.  A subroutine in
225 all capitals is a loosely-held convention meaning it will be called
226 indirectly by the run-time system itself, usually due to a triggered event.
227 Subroutines that do special, pre-defined things include C<AUTOLOAD>, C<CLONE>,
228 C<DESTROY> plus all functions mentioned in L<perltie> and L<PerlIO::via>.
229
230 The C<BEGIN>, C<UNITCHECK>, C<CHECK>, C<INIT> and C<END> subroutines
231 are not so much subroutines as named special code blocks, of which you
232 can have more than one in a package, and which you can B<not> call
233 explicitly.  See L<perlmod/"BEGIN, UNITCHECK, CHECK, INIT and END">
234
235 =head2 Private Variables via my()
236 X<my> X<variable, lexical> X<lexical> X<lexical variable> X<scope, lexical>
237 X<lexical scope> X<attributes, my>
238
239 Synopsis:
240
241     my $foo;            # declare $foo lexically local
242     my (@wid, %get);    # declare list of variables local
243     my $foo = "flurp";  # declare $foo lexical, and init it
244     my @oof = @bar;     # declare @oof lexical, and init it
245     my $x : Foo = $y;   # similar, with an attribute applied
246
247 B<WARNING>: The use of attribute lists on C<my> declarations is still
248 evolving.  The current semantics and interface are subject to change.
249 See L<attributes> and L<Attribute::Handlers>.
250
251 The C<my> operator declares the listed variables to be lexically
252 confined to the enclosing block, conditional (C<if/unless/elsif/else>),
253 loop (C<for/foreach/while/until/continue>), subroutine, C<eval>,
254 or C<do/require/use>'d file.  If more than one value is listed, the
255 list must be placed in parentheses.  All listed elements must be
256 legal lvalues.  Only alphanumeric identifiers may be lexically
257 scoped--magical built-ins like C<$/> must currently be C<local>ized
258 with C<local> instead.
259
260 Unlike dynamic variables created by the C<local> operator, lexical
261 variables declared with C<my> are totally hidden from the outside
262 world, including any called subroutines.  This is true if it's the
263 same subroutine called from itself or elsewhere--every call gets
264 its own copy.
265 X<local>
266
267 This doesn't mean that a C<my> variable declared in a statically
268 enclosing lexical scope would be invisible.  Only dynamic scopes
269 are cut off.   For example, the C<bumpx()> function below has access
270 to the lexical $x variable because both the C<my> and the C<sub>
271 occurred at the same scope, presumably file scope.
272
273     my $x = 10;
274     sub bumpx { $x++ } 
275
276 An C<eval()>, however, can see lexical variables of the scope it is
277 being evaluated in, so long as the names aren't hidden by declarations within
278 the C<eval()> itself.  See L<perlref>.
279 X<eval, scope of>
280
281 The parameter list to my() may be assigned to if desired, which allows you
282 to initialize your variables.  (If no initializer is given for a
283 particular variable, it is created with the undefined value.)  Commonly
284 this is used to name input parameters to a subroutine.  Examples:
285
286     $arg = "fred";        # "global" variable
287     $n = cube_root(27);
288     print "$arg thinks the root is $n\n";
289  fred thinks the root is 3
290
291     sub cube_root {
292         my $arg = shift;  # name doesn't matter
293         $arg **= 1/3;
294         return $arg;
295     }
296
297 The C<my> is simply a modifier on something you might assign to.  So when
298 you do assign to variables in its argument list, C<my> doesn't
299 change whether those variables are viewed as a scalar or an array.  So
300
301     my ($foo) = <STDIN>;                # WRONG?
302     my @FOO = <STDIN>;
303
304 both supply a list context to the right-hand side, while
305
306     my $foo = <STDIN>;
307
308 supplies a scalar context.  But the following declares only one variable:
309
310     my $foo, $bar = 1;                  # WRONG
311
312 That has the same effect as
313
314     my $foo;
315     $bar = 1;
316
317 The declared variable is not introduced (is not visible) until after
318 the current statement.  Thus,
319
320     my $x = $x;
321
322 can be used to initialize a new $x with the value of the old $x, and
323 the expression
324
325     my $x = 123 and $x == 123
326
327 is false unless the old $x happened to have the value C<123>.
328
329 Lexical scopes of control structures are not bounded precisely by the
330 braces that delimit their controlled blocks; control expressions are
331 part of that scope, too.  Thus in the loop
332
333     while (my $line = <>) {
334         $line = lc $line;
335     } continue {
336         print $line;
337     }
338
339 the scope of $line extends from its declaration throughout the rest of
340 the loop construct (including the C<continue> clause), but not beyond
341 it.  Similarly, in the conditional
342
343     if ((my $answer = <STDIN>) =~ /^yes$/i) {
344         user_agrees();
345     } elsif ($answer =~ /^no$/i) {
346         user_disagrees();
347     } else {
348         chomp $answer;
349         die "'$answer' is neither 'yes' nor 'no'";
350     }
351
352 the scope of $answer extends from its declaration through the rest
353 of that conditional, including any C<elsif> and C<else> clauses, 
354 but not beyond it.  See L<perlsyn/"Simple Statements"> for information
355 on the scope of variables in statements with modifiers.
356
357 The C<foreach> loop defaults to scoping its index variable dynamically
358 in the manner of C<local>.  However, if the index variable is
359 prefixed with the keyword C<my>, or if there is already a lexical
360 by that name in scope, then a new lexical is created instead.  Thus
361 in the loop
362 X<foreach> X<for>
363
364     for my $i (1, 2, 3) {
365         some_function();
366     }
367
368 the scope of $i extends to the end of the loop, but not beyond it,
369 rendering the value of $i inaccessible within C<some_function()>.
370 X<foreach> X<for>
371
372 Some users may wish to encourage the use of lexically scoped variables.
373 As an aid to catching implicit uses to package variables,
374 which are always global, if you say
375
376     use strict 'vars';
377
378 then any variable mentioned from there to the end of the enclosing
379 block must either refer to a lexical variable, be predeclared via
380 C<our> or C<use vars>, or else must be fully qualified with the package name.
381 A compilation error results otherwise.  An inner block may countermand
382 this with C<no strict 'vars'>.
383
384 A C<my> has both a compile-time and a run-time effect.  At compile
385 time, the compiler takes notice of it.  The principal usefulness
386 of this is to quiet C<use strict 'vars'>, but it is also essential
387 for generation of closures as detailed in L<perlref>.  Actual
388 initialization is delayed until run time, though, so it gets executed
389 at the appropriate time, such as each time through a loop, for
390 example.
391
392 Variables declared with C<my> are not part of any package and are therefore
393 never fully qualified with the package name.  In particular, you're not
394 allowed to try to make a package variable (or other global) lexical:
395
396     my $pack::var;      # ERROR!  Illegal syntax
397
398 In fact, a dynamic variable (also known as package or global variables)
399 are still accessible using the fully qualified C<::> notation even while a
400 lexical of the same name is also visible:
401
402     package main;
403     local $x = 10;
404     my    $x = 20;
405     print "$x and $::x\n";
406
407 That will print out C<20> and C<10>.
408
409 You may declare C<my> variables at the outermost scope of a file
410 to hide any such identifiers from the world outside that file.  This
411 is similar in spirit to C's static variables when they are used at
412 the file level.  To do this with a subroutine requires the use of
413 a closure (an anonymous function that accesses enclosing lexicals).
414 If you want to create a private subroutine that cannot be called
415 from outside that block, it can declare a lexical variable containing
416 an anonymous sub reference:
417
418     my $secret_version = '1.001-beta';
419     my $secret_sub = sub { print $secret_version };
420     &$secret_sub();
421
422 As long as the reference is never returned by any function within the
423 module, no outside module can see the subroutine, because its name is not in
424 any package's symbol table.  Remember that it's not I<REALLY> called
425 C<$some_pack::secret_version> or anything; it's just $secret_version,
426 unqualified and unqualifiable.
427
428 This does not work with object methods, however; all object methods
429 have to be in the symbol table of some package to be found.  See
430 L<perlref/"Function Templates"> for something of a work-around to
431 this.
432
433 =head2 Persistent Private Variables
434 X<state> X<state variable> X<static> X<variable, persistent> X<variable, static> X<closure>
435
436 There are two ways to build persistent private variables in Perl 5.10.
437 First, you can simply use the C<state> feature. Or, you can use closures,
438 if you want to stay compatible with releases older than 5.10.
439
440 =head3 Persistent variables via state()
441
442 Beginning with perl 5.9.4, you can declare variables with the C<state>
443 keyword in place of C<my>. For that to work, though, you must have
444 enabled that feature beforehand, either by using the C<feature> pragma, or
445 by using C<-E> on one-liners. (see L<feature>)
446
447 For example, the following code maintains a private counter, incremented
448 each time the gimme_another() function is called:
449
450     use feature 'state';
451     sub gimme_another { state $x; return ++$x }
452
453 Also, since C<$x> is lexical, it can't be reached or modified by any Perl
454 code outside.
455
456 When combined with variable declaration, simple scalar assignment to C<state>
457 variables (as in C<state $x = 42>) is executed only the first time.  When such
458 statements are evaluated subsequent times, the assignment is ignored.  The
459 behavior of this sort of assignment to non-scalar variables is undefined.
460
461 =head3 Persistent variables with closures
462
463 Just because a lexical variable is lexically (also called statically)
464 scoped to its enclosing block, C<eval>, or C<do> FILE, this doesn't mean that
465 within a function it works like a C static.  It normally works more
466 like a C auto, but with implicit garbage collection.  
467
468 Unlike local variables in C or C++, Perl's lexical variables don't
469 necessarily get recycled just because their scope has exited.
470 If something more permanent is still aware of the lexical, it will
471 stick around.  So long as something else references a lexical, that
472 lexical won't be freed--which is as it should be.  You wouldn't want
473 memory being free until you were done using it, or kept around once you
474 were done.  Automatic garbage collection takes care of this for you.
475
476 This means that you can pass back or save away references to lexical
477 variables, whereas to return a pointer to a C auto is a grave error.
478 It also gives us a way to simulate C's function statics.  Here's a
479 mechanism for giving a function private variables with both lexical
480 scoping and a static lifetime.  If you do want to create something like
481 C's static variables, just enclose the whole function in an extra block,
482 and put the static variable outside the function but in the block.
483
484     {
485         my $secret_val = 0;
486         sub gimme_another {
487             return ++$secret_val;
488         }
489     }
490     # $secret_val now becomes unreachable by the outside
491     # world, but retains its value between calls to gimme_another
492
493 If this function is being sourced in from a separate file
494 via C<require> or C<use>, then this is probably just fine.  If it's
495 all in the main program, you'll need to arrange for the C<my>
496 to be executed early, either by putting the whole block above
497 your main program, or more likely, placing merely a C<BEGIN>
498 code block around it to make sure it gets executed before your program
499 starts to run:
500
501     BEGIN {
502         my $secret_val = 0;
503         sub gimme_another {
504             return ++$secret_val;
505         }
506     }
507
508 See L<perlmod/"BEGIN, UNITCHECK, CHECK, INIT and END"> about the
509 special triggered code blocks, C<BEGIN>, C<UNITCHECK>, C<CHECK>,
510 C<INIT> and C<END>.
511
512 If declared at the outermost scope (the file scope), then lexicals
513 work somewhat like C's file statics.  They are available to all
514 functions in that same file declared below them, but are inaccessible
515 from outside that file.  This strategy is sometimes used in modules
516 to create private variables that the whole module can see.
517
518 =head2 Temporary Values via local()
519 X<local> X<scope, dynamic> X<dynamic scope> X<variable, local>
520 X<variable, temporary>
521
522 B<WARNING>: In general, you should be using C<my> instead of C<local>, because
523 it's faster and safer.  Exceptions to this include the global punctuation
524 variables, global filehandles and formats, and direct manipulation of the
525 Perl symbol table itself.  C<local> is mostly used when the current value
526 of a variable must be visible to called subroutines.
527
528 Synopsis:
529
530     # localization of values
531
532     local $foo;                 # make $foo dynamically local
533     local (@wid, %get);         # make list of variables local
534     local $foo = "flurp";       # make $foo dynamic, and init it
535     local @oof = @bar;          # make @oof dynamic, and init it
536
537     local $hash{key} = "val";   # sets a local value for this hash entry
538     delete local $hash{key};    # delete this entry for the current block
539     local ($cond ? $v1 : $v2);  # several types of lvalues support
540                                 # localization
541
542     # localization of symbols
543
544     local *FH;                  # localize $FH, @FH, %FH, &FH  ...
545     local *merlyn = *randal;    # now $merlyn is really $randal, plus
546                                 #     @merlyn is really @randal, etc
547     local *merlyn = 'randal';   # SAME THING: promote 'randal' to *randal
548     local *merlyn = \$randal;   # just alias $merlyn, not @merlyn etc
549
550 A C<local> modifies its listed variables to be "local" to the
551 enclosing block, C<eval>, or C<do FILE>--and to I<any subroutine
552 called from within that block>.  A C<local> just gives temporary
553 values to global (meaning package) variables.  It does I<not> create
554 a local variable.  This is known as dynamic scoping.  Lexical scoping
555 is done with C<my>, which works more like C's auto declarations.
556
557 Some types of lvalues can be localized as well : hash and array elements
558 and slices, conditionals (provided that their result is always
559 localizable), and symbolic references.  As for simple variables, this
560 creates new, dynamically scoped values.
561
562 If more than one variable or expression is given to C<local>, they must be
563 placed in parentheses.  This operator works
564 by saving the current values of those variables in its argument list on a
565 hidden stack and restoring them upon exiting the block, subroutine, or
566 eval.  This means that called subroutines can also reference the local
567 variable, but not the global one.  The argument list may be assigned to if
568 desired, which allows you to initialize your local variables.  (If no
569 initializer is given for a particular variable, it is created with an
570 undefined value.)
571
572 Because C<local> is a run-time operator, it gets executed each time
573 through a loop.  Consequently, it's more efficient to localize your
574 variables outside the loop.
575
576 =head3 Grammatical note on local()
577 X<local, context>
578
579 A C<local> is simply a modifier on an lvalue expression.  When you assign to
580 a C<local>ized variable, the C<local> doesn't change whether its list is viewed
581 as a scalar or an array.  So
582
583     local($foo) = <STDIN>;
584     local @FOO = <STDIN>;
585
586 both supply a list context to the right-hand side, while
587
588     local $foo = <STDIN>;
589
590 supplies a scalar context.
591
592 =head3 Localization of special variables
593 X<local, special variable>
594
595 If you localize a special variable, you'll be giving a new value to it,
596 but its magic won't go away.  That means that all side-effects related
597 to this magic still work with the localized value.
598
599 This feature allows code like this to work :
600
601     # Read the whole contents of FILE in $slurp
602     { local $/ = undef; $slurp = <FILE>; }
603
604 Note, however, that this restricts localization of some values ; for
605 example, the following statement dies, as of perl 5.9.0, with an error
606 I<Modification of a read-only value attempted>, because the $1 variable is
607 magical and read-only :
608
609     local $1 = 2;
610
611 One exception is the default scalar variable: starting with perl 5.14
612 C<local($_)> will always strip all magic from $_, to make it possible
613 to safely reuse $_ in a subroutine.
614
615 B<WARNING>: Localization of tied arrays and hashes does not currently
616 work as described.
617 This will be fixed in a future release of Perl; in the meantime, avoid
618 code that relies on any particular behaviour of localising tied arrays
619 or hashes (localising individual elements is still okay).
620 See L<perl58delta/"Localising Tied Arrays and Hashes Is Broken"> for more
621 details.
622 X<local, tie>
623
624 =head3 Localization of globs
625 X<local, glob> X<glob>
626
627 The construct
628
629     local *name;
630
631 creates a whole new symbol table entry for the glob C<name> in the
632 current package.  That means that all variables in its glob slot ($name,
633 @name, %name, &name, and the C<name> filehandle) are dynamically reset.
634
635 This implies, among other things, that any magic eventually carried by
636 those variables is locally lost.  In other words, saying C<local */>
637 will not have any effect on the internal value of the input record
638 separator.
639
640 =head3 Localization of elements of composite types
641 X<local, composite type element> X<local, array element> X<local, hash element>
642
643 It's also worth taking a moment to explain what happens when you
644 C<local>ize a member of a composite type (i.e. an array or hash element).
645 In this case, the element is C<local>ized I<by name>. This means that
646 when the scope of the C<local()> ends, the saved value will be
647 restored to the hash element whose key was named in the C<local()>, or
648 the array element whose index was named in the C<local()>.  If that
649 element was deleted while the C<local()> was in effect (e.g. by a
650 C<delete()> from a hash or a C<shift()> of an array), it will spring
651 back into existence, possibly extending an array and filling in the
652 skipped elements with C<undef>.  For instance, if you say
653
654     %hash = ( 'This' => 'is', 'a' => 'test' );
655     @ary  = ( 0..5 );
656     {
657          local($ary[5]) = 6;
658          local($hash{'a'}) = 'drill';
659          while (my $e = pop(@ary)) {
660              print "$e . . .\n";
661              last unless $e > 3;
662          }
663          if (@ary) {
664              $hash{'only a'} = 'test';
665              delete $hash{'a'};
666          }
667     }
668     print join(' ', map { "$_ $hash{$_}" } sort keys %hash),".\n";
669     print "The array has ",scalar(@ary)," elements: ",
670           join(', ', map { defined $_ ? $_ : 'undef' } @ary),"\n";
671
672 Perl will print
673
674     6 . . .
675     4 . . .
676     3 . . .
677     This is a test only a test.
678     The array has 6 elements: 0, 1, 2, undef, undef, 5
679
680 The behavior of local() on non-existent members of composite
681 types is subject to change in future.
682
683 =head3 Localized deletion of elements of composite types
684 X<delete> X<local, composite type element> X<local, array element> X<local, hash element>
685
686 You can use the C<delete local $array[$idx]> and C<delete local $hash{key}>
687 constructs to delete a composite type entry for the current block and restore
688 it when it ends. They return the array/hash value before the localization,
689 which means that they are respectively equivalent to
690
691     do {
692         my $val = $array[$idx];
693         local  $array[$idx];
694         delete $array[$idx];
695         $val
696     }
697
698 and
699
700     do {
701         my $val = $hash{key};
702         local  $hash{key};
703         delete $hash{key};
704         $val
705     }
706
707 except that for those the C<local> is scoped to the C<do> block. Slices are
708 also accepted.
709
710     my %hash = (
711      a => [ 7, 8, 9 ],
712      b => 1,
713     )
714
715     {
716      my $a = delete local $hash{a};
717      # $a is [ 7, 8, 9 ]
718      # %hash is (b => 1)
719
720      {
721       my @nums = delete local @$a[0, 2]
722       # @nums is (7, 9)
723       # $a is [ undef, 8 ]
724
725       $a[0] = 999; # will be erased when the scope ends
726      }
727      # $a is back to [ 7, 8, 9 ]
728
729     }
730     # %hash is back to its original state
731
732 =head2 Lvalue subroutines
733 X<lvalue> X<subroutine, lvalue>
734
735 B<WARNING>: Lvalue subroutines are still experimental and the
736 implementation may change in future versions of Perl.
737
738 It is possible to return a modifiable value from a subroutine.
739 To do this, you have to declare the subroutine to return an lvalue.
740
741     my $val;
742     sub canmod : lvalue {
743         # return $val; this doesn't work, don't say "return"
744         $val;
745     }
746     sub nomod {
747         $val;
748     }
749
750     canmod() = 5;   # assigns to $val
751     nomod()  = 5;   # ERROR
752
753 The scalar/list context for the subroutine and for the right-hand
754 side of assignment is determined as if the subroutine call is replaced
755 by a scalar. For example, consider:
756
757     data(2,3) = get_data(3,4);
758
759 Both subroutines here are called in a scalar context, while in:
760
761     (data(2,3)) = get_data(3,4);
762
763 and in:
764
765     (data(2),data(3)) = get_data(3,4);
766
767 all the subroutines are called in a list context.
768
769 =over 4
770
771 =item Lvalue subroutines are EXPERIMENTAL
772
773 They appear to be convenient, but there are several reasons to be
774 circumspect.
775
776 You can't use the return keyword, you must pass out the value before
777 falling out of subroutine scope. (see comment in example above).  This
778 is usually not a problem, but it disallows an explicit return out of a
779 deeply nested loop, which is sometimes a nice way out.
780
781 They violate encapsulation.  A normal mutator can check the supplied
782 argument before setting the attribute it is protecting, an lvalue
783 subroutine never gets that chance.  Consider;
784
785     my $some_array_ref = [];    # protected by mutators ??
786
787     sub set_arr {               # normal mutator
788         my $val = shift;
789         die("expected array, you supplied ", ref $val)
790            unless ref $val eq 'ARRAY';
791         $some_array_ref = $val;
792     }
793     sub set_arr_lv : lvalue {   # lvalue mutator
794         $some_array_ref;
795     }
796
797     # set_arr_lv cannot stop this !
798     set_arr_lv() = { a => 1 };
799
800 =back
801
802 =head2 Passing Symbol Table Entries (typeglobs)
803 X<typeglob> X<*>
804
805 B<WARNING>: The mechanism described in this section was originally
806 the only way to simulate pass-by-reference in older versions of
807 Perl.  While it still works fine in modern versions, the new reference
808 mechanism is generally easier to work with.  See below.
809
810 Sometimes you don't want to pass the value of an array to a subroutine
811 but rather the name of it, so that the subroutine can modify the global
812 copy of it rather than working with a local copy.  In perl you can
813 refer to all objects of a particular name by prefixing the name
814 with a star: C<*foo>.  This is often known as a "typeglob", because the
815 star on the front can be thought of as a wildcard match for all the
816 funny prefix characters on variables and subroutines and such.
817
818 When evaluated, the typeglob produces a scalar value that represents
819 all the objects of that name, including any filehandle, format, or
820 subroutine.  When assigned to, it causes the name mentioned to refer to
821 whatever C<*> value was assigned to it.  Example:
822
823     sub doubleary {
824         local(*someary) = @_;
825         foreach $elem (@someary) {
826             $elem *= 2;
827         }
828     }
829     doubleary(*foo);
830     doubleary(*bar);
831
832 Scalars are already passed by reference, so you can modify
833 scalar arguments without using this mechanism by referring explicitly
834 to C<$_[0]> etc.  You can modify all the elements of an array by passing
835 all the elements as scalars, but you have to use the C<*> mechanism (or
836 the equivalent reference mechanism) to C<push>, C<pop>, or change the size of
837 an array.  It will certainly be faster to pass the typeglob (or reference).
838
839 Even if you don't want to modify an array, this mechanism is useful for
840 passing multiple arrays in a single LIST, because normally the LIST
841 mechanism will merge all the array values so that you can't extract out
842 the individual arrays.  For more on typeglobs, see
843 L<perldata/"Typeglobs and Filehandles">.
844
845 =head2 When to Still Use local()
846 X<local> X<variable, local>
847
848 Despite the existence of C<my>, there are still three places where the
849 C<local> operator still shines.  In fact, in these three places, you
850 I<must> use C<local> instead of C<my>.
851
852 =over 4
853
854 =item 1.
855
856 You need to give a global variable a temporary value, especially $_.
857
858 The global variables, like C<@ARGV> or the punctuation variables, must be 
859 C<local>ized with C<local()>.  This block reads in F</etc/motd>, and splits
860 it up into chunks separated by lines of equal signs, which are placed
861 in C<@Fields>.
862
863     {
864         local @ARGV = ("/etc/motd");
865         local $/ = undef;
866         local $_ = <>;  
867         @Fields = split /^\s*=+\s*$/;
868     } 
869
870 It particular, it's important to C<local>ize $_ in any routine that assigns
871 to it.  Look out for implicit assignments in C<while> conditionals.
872
873 =item 2.
874
875 You need to create a local file or directory handle or a local function.
876
877 A function that needs a filehandle of its own must use
878 C<local()> on a complete typeglob.   This can be used to create new symbol
879 table entries:
880
881     sub ioqueue {
882         local  (*READER, *WRITER);    # not my!
883         pipe    (READER,  WRITER)     or die "pipe: $!";
884         return (*READER, *WRITER);
885     }
886     ($head, $tail) = ioqueue();
887
888 See the Symbol module for a way to create anonymous symbol table
889 entries.
890
891 Because assignment of a reference to a typeglob creates an alias, this
892 can be used to create what is effectively a local function, or at least,
893 a local alias.
894
895     {
896         local *grow = \&shrink; # only until this block exists
897         grow();                 # really calls shrink()
898         move();                 # if move() grow()s, it shrink()s too
899     }
900     grow();                     # get the real grow() again
901
902 See L<perlref/"Function Templates"> for more about manipulating
903 functions by name in this way.
904
905 =item 3.
906
907 You want to temporarily change just one element of an array or hash.
908
909 You can C<local>ize just one element of an aggregate.  Usually this
910 is done on dynamics:
911
912     {
913         local $SIG{INT} = 'IGNORE';
914         funct();                            # uninterruptible
915     } 
916     # interruptibility automatically restored here
917
918 But it also works on lexically declared aggregates.  Prior to 5.005,
919 this operation could on occasion misbehave.
920
921 =back
922
923 =head2 Pass by Reference
924 X<pass by reference> X<pass-by-reference> X<reference>
925
926 If you want to pass more than one array or hash into a function--or
927 return them from it--and have them maintain their integrity, then
928 you're going to have to use an explicit pass-by-reference.  Before you
929 do that, you need to understand references as detailed in L<perlref>.
930 This section may not make much sense to you otherwise.
931
932 Here are a few simple examples.  First, let's pass in several arrays
933 to a function and have it C<pop> all of then, returning a new list
934 of all their former last elements:
935
936     @tailings = popmany ( \@a, \@b, \@c, \@d );
937
938     sub popmany {
939         my $aref;
940         my @retlist = ();
941         foreach $aref ( @_ ) {
942             push @retlist, pop @$aref;
943         }
944         return @retlist;
945     }
946
947 Here's how you might write a function that returns a
948 list of keys occurring in all the hashes passed to it:
949
950     @common = inter( \%foo, \%bar, \%joe );
951     sub inter {
952         my ($k, $href, %seen); # locals
953         foreach $href (@_) {
954             while ( $k = each %$href ) {
955                 $seen{$k}++;
956             }
957         }
958         return grep { $seen{$_} == @_ } keys %seen;
959     }
960
961 So far, we're using just the normal list return mechanism.
962 What happens if you want to pass or return a hash?  Well,
963 if you're using only one of them, or you don't mind them
964 concatenating, then the normal calling convention is ok, although
965 a little expensive.
966
967 Where people get into trouble is here:
968
969     (@a, @b) = func(@c, @d);
970 or
971     (%a, %b) = func(%c, %d);
972
973 That syntax simply won't work.  It sets just C<@a> or C<%a> and
974 clears the C<@b> or C<%b>.  Plus the function didn't get passed
975 into two separate arrays or hashes: it got one long list in C<@_>,
976 as always.
977
978 If you can arrange for everyone to deal with this through references, it's
979 cleaner code, although not so nice to look at.  Here's a function that
980 takes two array references as arguments, returning the two array elements
981 in order of how many elements they have in them:
982
983     ($aref, $bref) = func(\@c, \@d);
984     print "@$aref has more than @$bref\n";
985     sub func {
986         my ($cref, $dref) = @_;
987         if (@$cref > @$dref) {
988             return ($cref, $dref);
989         } else {
990             return ($dref, $cref);
991         }
992     }
993
994 It turns out that you can actually do this also:
995
996     (*a, *b) = func(\@c, \@d);
997     print "@a has more than @b\n";
998     sub func {
999         local (*c, *d) = @_;
1000         if (@c > @d) {
1001             return (\@c, \@d);
1002         } else {
1003             return (\@d, \@c);
1004         }
1005     }
1006
1007 Here we're using the typeglobs to do symbol table aliasing.  It's
1008 a tad subtle, though, and also won't work if you're using C<my>
1009 variables, because only globals (even in disguise as C<local>s)
1010 are in the symbol table.
1011
1012 If you're passing around filehandles, you could usually just use the bare
1013 typeglob, like C<*STDOUT>, but typeglobs references work, too.
1014 For example:
1015
1016     splutter(\*STDOUT);
1017     sub splutter {
1018         my $fh = shift;
1019         print $fh "her um well a hmmm\n";
1020     }
1021
1022     $rec = get_rec(\*STDIN);
1023     sub get_rec {
1024         my $fh = shift;
1025         return scalar <$fh>;
1026     }
1027
1028 If you're planning on generating new filehandles, you could do this.
1029 Notice to pass back just the bare *FH, not its reference.
1030
1031     sub openit {
1032         my $path = shift;
1033         local *FH;
1034         return open (FH, $path) ? *FH : undef;
1035     }
1036
1037 =head2 Prototypes
1038 X<prototype> X<subroutine, prototype>
1039
1040 Perl supports a very limited kind of compile-time argument checking
1041 using function prototyping.  If you declare
1042
1043     sub mypush (+@)
1044
1045 then C<mypush()> takes arguments exactly like C<push()> does.  The
1046 function declaration must be visible at compile time.  The prototype
1047 affects only interpretation of new-style calls to the function,
1048 where new-style is defined as not using the C<&> character.  In
1049 other words, if you call it like a built-in function, then it behaves
1050 like a built-in function.  If you call it like an old-fashioned
1051 subroutine, then it behaves like an old-fashioned subroutine.  It
1052 naturally falls out from this rule that prototypes have no influence
1053 on subroutine references like C<\&foo> or on indirect subroutine
1054 calls like C<&{$subref}> or C<< $subref->() >>.
1055
1056 Method calls are not influenced by prototypes either, because the
1057 function to be called is indeterminate at compile time, since
1058 the exact code called depends on inheritance.
1059
1060 Because the intent of this feature is primarily to let you define
1061 subroutines that work like built-in functions, here are prototypes
1062 for some other functions that parse almost exactly like the
1063 corresponding built-in.
1064
1065     Declared as                 Called as
1066
1067     sub mylink ($$)          mylink $old, $new
1068     sub myvec ($$$)          myvec $var, $offset, 1
1069     sub myindex ($$;$)       myindex &getstring, "substr"
1070     sub mysyswrite ($$$;$)   mysyswrite $buf, 0, length($buf) - $off, $off
1071     sub myreverse (@)        myreverse $a, $b, $c
1072     sub myjoin ($@)          myjoin ":", $a, $b, $c
1073     sub mypop (+)            mypop @array
1074     sub mysplice (+$$@)      mysplice @array, 0, 2, @pushme
1075     sub mykeys (+)           mykeys %{$hashref}
1076     sub myopen (*;$)         myopen HANDLE, $name
1077     sub mypipe (**)          mypipe READHANDLE, WRITEHANDLE
1078     sub mygrep (&@)          mygrep { /foo/ } $a, $b, $c
1079     sub myrand (;$)          myrand 42
1080     sub mytime ()            mytime
1081
1082 Any backslashed prototype character represents an actual argument
1083 that must start with that character (optionally preceded by C<my>,
1084 C<our> or C<local>), with the exception of C<$>, which will accept a
1085 hash or array element even without a dollar sign, such as
1086 C<< my_function()->[0] >>. The value passed as part of C<@_> will be a
1087 reference to the actual argument given in the subroutine call,
1088 obtained by applying C<\> to that argument.
1089
1090 You can use the C<\[]> backslash group notation to specify more than one
1091 allowed argument type. For example:
1092
1093     sub myref (\[$@%&*])
1094
1095 will allow calling myref() as
1096
1097     myref $var
1098     myref @array
1099     myref %hash
1100     myref &sub
1101     myref *glob
1102
1103 and the first argument of myref() will be a reference to
1104 a scalar, an array, a hash, a code, or a glob.
1105
1106 Unbackslashed prototype characters have special meanings.  Any
1107 unbackslashed C<@> or C<%> eats all remaining arguments, and forces
1108 list context.  An argument represented by C<$> forces scalar context.  An
1109 C<&> requires an anonymous subroutine, which, if passed as the first
1110 argument, does not require the C<sub> keyword or a subsequent comma.
1111
1112 A C<*> allows the subroutine to accept a bareword, constant, scalar expression,
1113 typeglob, or a reference to a typeglob in that slot.  The value will be
1114 available to the subroutine either as a simple scalar, or (in the latter
1115 two cases) as a reference to the typeglob.  If you wish to always convert
1116 such arguments to a typeglob reference, use Symbol::qualify_to_ref() as
1117 follows:
1118
1119     use Symbol 'qualify_to_ref';
1120
1121     sub foo (*) {
1122         my $fh = qualify_to_ref(shift, caller);
1123         ...
1124     }
1125
1126 The C<+> prototype is a special alternative to C<$> that will act like
1127 C<\[@%]> when given a literal array or hash variable, but will otherwise
1128 force scalar context on the argument.  This is useful for functions which
1129 should accept either a literal array or an array reference as the argument:
1130
1131     sub mypush (+@) {
1132         my $aref = shift;
1133         die "Not an array or arrayref" unless ref $aref eq 'ARRAY';
1134         push @$aref, @_;
1135     }
1136
1137 When using the C<+> prototype, your function must check that the argument
1138 is of an acceptable type.
1139
1140 A semicolon (C<;>) separates mandatory arguments from optional arguments.
1141 It is redundant before C<@> or C<%>, which gobble up everything else.
1142
1143 As the last character of a prototype, or just before a semicolon, you can
1144 use C<_> in place of C<$>: if this argument is not provided, C<$_> will be
1145 used instead.
1146
1147 Note how the last three examples in the table above are treated
1148 specially by the parser.  C<mygrep()> is parsed as a true list
1149 operator, C<myrand()> is parsed as a true unary operator with unary
1150 precedence the same as C<rand()>, and C<mytime()> is truly without
1151 arguments, just like C<time()>.  That is, if you say
1152
1153     mytime +2;
1154
1155 you'll get C<mytime() + 2>, not C<mytime(2)>, which is how it would be parsed
1156 without a prototype.
1157
1158 The interesting thing about C<&> is that you can generate new syntax with it,
1159 provided it's in the initial position:
1160 X<&>
1161
1162     sub try (&@) {
1163         my($try,$catch) = @_;
1164         eval { &$try };
1165         if ($@) {
1166             local $_ = $@;
1167             &$catch;
1168         }
1169     }
1170     sub catch (&) { $_[0] }
1171
1172     try {
1173         die "phooey";
1174     } catch {
1175         /phooey/ and print "unphooey\n";
1176     };
1177
1178 That prints C<"unphooey">.  (Yes, there are still unresolved
1179 issues having to do with visibility of C<@_>.  I'm ignoring that
1180 question for the moment.  (But note that if we make C<@_> lexically
1181 scoped, those anonymous subroutines can act like closures... (Gee,
1182 is this sounding a little Lispish?  (Never mind.))))
1183
1184 And here's a reimplementation of the Perl C<grep> operator:
1185 X<grep>
1186
1187     sub mygrep (&@) {
1188         my $code = shift;
1189         my @result;
1190         foreach $_ (@_) {
1191             push(@result, $_) if &$code;
1192         }
1193         @result;
1194     }
1195
1196 Some folks would prefer full alphanumeric prototypes.  Alphanumerics have
1197 been intentionally left out of prototypes for the express purpose of
1198 someday in the future adding named, formal parameters.  The current
1199 mechanism's main goal is to let module writers provide better diagnostics
1200 for module users.  Larry feels the notation quite understandable to Perl
1201 programmers, and that it will not intrude greatly upon the meat of the
1202 module, nor make it harder to read.  The line noise is visually
1203 encapsulated into a small pill that's easy to swallow.
1204
1205 If you try to use an alphanumeric sequence in a prototype you will
1206 generate an optional warning - "Illegal character in prototype...".
1207 Unfortunately earlier versions of Perl allowed the prototype to be
1208 used as long as its prefix was a valid prototype.  The warning may be
1209 upgraded to a fatal error in a future version of Perl once the
1210 majority of offending code is fixed.
1211
1212 It's probably best to prototype new functions, not retrofit prototyping
1213 into older ones.  That's because you must be especially careful about
1214 silent impositions of differing list versus scalar contexts.  For example,
1215 if you decide that a function should take just one parameter, like this:
1216
1217     sub func ($) {
1218         my $n = shift;
1219         print "you gave me $n\n";
1220     }
1221
1222 and someone has been calling it with an array or expression
1223 returning a list:
1224
1225     func(@foo);
1226     func( split /:/ );
1227
1228 Then you've just supplied an automatic C<scalar> in front of their
1229 argument, which can be more than a bit surprising.  The old C<@foo>
1230 which used to hold one thing doesn't get passed in.  Instead,
1231 C<func()> now gets passed in a C<1>; that is, the number of elements
1232 in C<@foo>.  And the C<split> gets called in scalar context so it
1233 starts scribbling on your C<@_> parameter list.  Ouch!
1234
1235 This is all very powerful, of course, and should be used only in moderation
1236 to make the world a better place.
1237
1238 =head2 Constant Functions
1239 X<constant>
1240
1241 Functions with a prototype of C<()> are potential candidates for
1242 inlining.  If the result after optimization and constant folding
1243 is either a constant or a lexically-scoped scalar which has no other
1244 references, then it will be used in place of function calls made
1245 without C<&>.  Calls made using C<&> are never inlined.  (See
1246 F<constant.pm> for an easy way to declare most constants.)
1247
1248 The following functions would all be inlined:
1249
1250     sub pi ()           { 3.14159 }             # Not exact, but close.
1251     sub PI ()           { 4 * atan2 1, 1 }      # As good as it gets,
1252                                                 # and it's inlined, too!
1253     sub ST_DEV ()       { 0 }
1254     sub ST_INO ()       { 1 }
1255
1256     sub FLAG_FOO ()     { 1 << 8 }
1257     sub FLAG_BAR ()     { 1 << 9 }
1258     sub FLAG_MASK ()    { FLAG_FOO | FLAG_BAR }
1259
1260     sub OPT_BAZ ()      { not (0x1B58 & FLAG_MASK) }
1261
1262     sub N () { int(OPT_BAZ) / 3 }
1263
1264     sub FOO_SET () { 1 if FLAG_MASK & FLAG_FOO }
1265
1266 Be aware that these will not be inlined; as they contain inner scopes,
1267 the constant folding doesn't reduce them to a single constant:
1268
1269     sub foo_set () { if (FLAG_MASK & FLAG_FOO) { 1 } }
1270
1271     sub baz_val () {
1272         if (OPT_BAZ) {
1273             return 23;
1274         }
1275         else {
1276             return 42;
1277         }
1278     }
1279
1280 If you redefine a subroutine that was eligible for inlining, you'll get
1281 a mandatory warning.  (You can use this warning to tell whether or not a
1282 particular subroutine is considered constant.)  The warning is
1283 considered severe enough not to be optional because previously compiled
1284 invocations of the function will still be using the old value of the
1285 function.  If you need to be able to redefine the subroutine, you need to
1286 ensure that it isn't inlined, either by dropping the C<()> prototype
1287 (which changes calling semantics, so beware) or by thwarting the
1288 inlining mechanism in some other way, such as
1289
1290     sub not_inlined () {
1291         23 if $];
1292     }
1293
1294 =head2 Overriding Built-in Functions
1295 X<built-in> X<override> X<CORE> X<CORE::GLOBAL>
1296
1297 Many built-in functions may be overridden, though this should be tried
1298 only occasionally and for good reason.  Typically this might be
1299 done by a package attempting to emulate missing built-in functionality
1300 on a non-Unix system.
1301
1302 Overriding may be done only by importing the name from a module at
1303 compile time--ordinary predeclaration isn't good enough.  However, the
1304 C<use subs> pragma lets you, in effect, predeclare subs
1305 via the import syntax, and these names may then override built-in ones:
1306
1307     use subs 'chdir', 'chroot', 'chmod', 'chown';
1308     chdir $somewhere;
1309     sub chdir { ... }
1310
1311 To unambiguously refer to the built-in form, precede the
1312 built-in name with the special package qualifier C<CORE::>.  For example,
1313 saying C<CORE::open()> always refers to the built-in C<open()>, even
1314 if the current package has imported some other subroutine called
1315 C<&open()> from elsewhere.  Even though it looks like a regular
1316 function call, it isn't: you can't take a reference to it, such as
1317 the incorrect C<\&CORE::open> might appear to produce.
1318
1319 Library modules should not in general export built-in names like C<open>
1320 or C<chdir> as part of their default C<@EXPORT> list, because these may
1321 sneak into someone else's namespace and change the semantics unexpectedly.
1322 Instead, if the module adds that name to C<@EXPORT_OK>, then it's
1323 possible for a user to import the name explicitly, but not implicitly.
1324 That is, they could say
1325
1326     use Module 'open';
1327
1328 and it would import the C<open> override.  But if they said
1329
1330     use Module;
1331
1332 they would get the default imports without overrides.
1333
1334 The foregoing mechanism for overriding built-in is restricted, quite
1335 deliberately, to the package that requests the import.  There is a second
1336 method that is sometimes applicable when you wish to override a built-in
1337 everywhere, without regard to namespace boundaries.  This is achieved by
1338 importing a sub into the special namespace C<CORE::GLOBAL::>.  Here is an
1339 example that quite brazenly replaces the C<glob> operator with something
1340 that understands regular expressions.
1341
1342     package REGlob;
1343     require Exporter;
1344     @ISA = 'Exporter';
1345     @EXPORT_OK = 'glob';
1346
1347     sub import {
1348         my $pkg = shift;
1349         return unless @_;
1350         my $sym = shift;
1351         my $where = ($sym =~ s/^GLOBAL_// ? 'CORE::GLOBAL' : caller(0));
1352         $pkg->export($where, $sym, @_);
1353     }
1354
1355     sub glob {
1356         my $pat = shift;
1357         my @got;
1358         if (opendir my $d, '.') { 
1359             @got = grep /$pat/, readdir $d; 
1360             closedir $d;   
1361         }
1362         return @got;
1363     }
1364     1;
1365
1366 And here's how it could be (ab)used:
1367
1368     #use REGlob 'GLOBAL_glob';      # override glob() in ALL namespaces
1369     package Foo;
1370     use REGlob 'glob';              # override glob() in Foo:: only
1371     print for <^[a-z_]+\.pm\$>;     # show all pragmatic modules
1372
1373 The initial comment shows a contrived, even dangerous example.
1374 By overriding C<glob> globally, you would be forcing the new (and
1375 subversive) behavior for the C<glob> operator for I<every> namespace,
1376 without the complete cognizance or cooperation of the modules that own
1377 those namespaces.  Naturally, this should be done with extreme caution--if
1378 it must be done at all.
1379
1380 The C<REGlob> example above does not implement all the support needed to
1381 cleanly override perl's C<glob> operator.  The built-in C<glob> has
1382 different behaviors depending on whether it appears in a scalar or list
1383 context, but our C<REGlob> doesn't.  Indeed, many perl built-in have such
1384 context sensitive behaviors, and these must be adequately supported by
1385 a properly written override.  For a fully functional example of overriding
1386 C<glob>, study the implementation of C<File::DosGlob> in the standard
1387 library.
1388
1389 When you override a built-in, your replacement should be consistent (if
1390 possible) with the built-in native syntax.  You can achieve this by using
1391 a suitable prototype.  To get the prototype of an overridable built-in,
1392 use the C<prototype> function with an argument of C<"CORE::builtin_name">
1393 (see L<perlfunc/prototype>).
1394
1395 Note however that some built-ins can't have their syntax expressed by a
1396 prototype (such as C<system> or C<chomp>).  If you override them you won't
1397 be able to fully mimic their original syntax.
1398
1399 The built-ins C<do>, C<require> and C<glob> can also be overridden, but due
1400 to special magic, their original syntax is preserved, and you don't have
1401 to define a prototype for their replacements.  (You can't override the
1402 C<do BLOCK> syntax, though).
1403
1404 C<require> has special additional dark magic: if you invoke your
1405 C<require> replacement as C<require Foo::Bar>, it will actually receive
1406 the argument C<"Foo/Bar.pm"> in @_.  See L<perlfunc/require>.
1407
1408 And, as you'll have noticed from the previous example, if you override
1409 C<glob>, the C<< <*> >> glob operator is overridden as well.
1410
1411 In a similar fashion, overriding the C<readline> function also overrides
1412 the equivalent I/O operator C<< <FILEHANDLE> >>. Also, overriding
1413 C<readpipe> also overrides the operators C<``> and C<qx//>.
1414
1415 Finally, some built-ins (e.g. C<exists> or C<grep>) can't be overridden.
1416
1417 =head2 Autoloading
1418 X<autoloading> X<AUTOLOAD>
1419
1420 If you call a subroutine that is undefined, you would ordinarily
1421 get an immediate, fatal error complaining that the subroutine doesn't
1422 exist.  (Likewise for subroutines being used as methods, when the
1423 method doesn't exist in any base class of the class's package.)
1424 However, if an C<AUTOLOAD> subroutine is defined in the package or
1425 packages used to locate the original subroutine, then that
1426 C<AUTOLOAD> subroutine is called with the arguments that would have
1427 been passed to the original subroutine.  The fully qualified name
1428 of the original subroutine magically appears in the global $AUTOLOAD
1429 variable of the same package as the C<AUTOLOAD> routine.  The name
1430 is not passed as an ordinary argument because, er, well, just
1431 because, that's why.  (As an exception, a method call to a nonexistent
1432 C<import> or C<unimport> method is just skipped instead.  Also, if
1433 the AUTOLOAD subroutine is an XSUB, C<$AUTOLOAD> is not populated;
1434 instead, you should call L<< C<SvPVX>E<sol>C<SvCUR>|perlapi >> on the
1435 C<CV> for C<AUTOLOAD> to retrieve the method name.)
1436
1437
1438 Many C<AUTOLOAD> routines load in a definition for the requested
1439 subroutine using eval(), then execute that subroutine using a special
1440 form of goto() that erases the stack frame of the C<AUTOLOAD> routine
1441 without a trace.  (See the source to the standard module documented
1442 in L<AutoLoader>, for example.)  But an C<AUTOLOAD> routine can
1443 also just emulate the routine and never define it.   For example,
1444 let's pretend that a function that wasn't defined should just invoke
1445 C<system> with those arguments.  All you'd do is:
1446
1447     sub AUTOLOAD {
1448         my $program = $AUTOLOAD;
1449         $program =~ s/.*:://;
1450         system($program, @_);
1451     }
1452     date();
1453     who('am', 'i');
1454     ls('-l');
1455
1456 In fact, if you predeclare functions you want to call that way, you don't
1457 even need parentheses:
1458
1459     use subs qw(date who ls);
1460     date;
1461     who "am", "i";
1462     ls '-l';
1463
1464 A more complete example of this is the standard Shell module, which
1465 can treat undefined subroutine calls as calls to external programs.
1466
1467 Mechanisms are available to help modules writers split their modules
1468 into autoloadable files.  See the standard AutoLoader module
1469 described in L<AutoLoader> and in L<AutoSplit>, the standard
1470 SelfLoader modules in L<SelfLoader>, and the document on adding C
1471 functions to Perl code in L<perlxs>.
1472
1473 =head2 Subroutine Attributes
1474 X<attribute> X<subroutine, attribute> X<attrs>
1475
1476 A subroutine declaration or definition may have a list of attributes
1477 associated with it.  If such an attribute list is present, it is
1478 broken up at space or colon boundaries and treated as though a
1479 C<use attributes> had been seen.  See L<attributes> for details
1480 about what attributes are currently supported.
1481 Unlike the limitation with the obsolescent C<use attrs>, the
1482 C<sub : ATTRLIST> syntax works to associate the attributes with
1483 a pre-declaration, and not just with a subroutine definition.
1484
1485 The attributes must be valid as simple identifier names (without any
1486 punctuation other than the '_' character).  They may have a parameter
1487 list appended, which is only checked for whether its parentheses ('(',')')
1488 nest properly.
1489
1490 Examples of valid syntax (even though the attributes are unknown):
1491
1492     sub fnord (&\%) : switch(10,foo(7,3))  :  expensive;
1493     sub plugh () : Ugly('\(") :Bad;
1494     sub xyzzy : _5x5 { ... }
1495
1496 Examples of invalid syntax:
1497
1498     sub fnord : switch(10,foo(); # ()-string not balanced
1499     sub snoid : Ugly('(');        # ()-string not balanced
1500     sub xyzzy : 5x5;              # "5x5" not a valid identifier
1501     sub plugh : Y2::north;        # "Y2::north" not a simple identifier
1502     sub snurt : foo + bar;        # "+" not a colon or space
1503
1504 The attribute list is passed as a list of constant strings to the code
1505 which associates them with the subroutine.  In particular, the second example
1506 of valid syntax above currently looks like this in terms of how it's
1507 parsed and invoked:
1508
1509     use attributes __PACKAGE__, \&plugh, q[Ugly('\(")], 'Bad';
1510
1511 For further details on attribute lists and their manipulation,
1512 see L<attributes> and L<Attribute::Handlers>.
1513
1514 =head1 SEE ALSO
1515
1516 See L<perlref/"Function Templates"> for more about references and closures.
1517 See L<perlxs> if you'd like to learn about calling C subroutines from Perl.  
1518 See L<perlembed> if you'd like to learn about calling Perl subroutines from C.  
1519 See L<perlmod> to learn about bundling up your functions in separate files.
1520 See L<perlmodlib> to learn what library modules come standard on your system.
1521 See L<perltoot> to learn how to make object method calls.