Create perldelta for 5.14.3
[perl.git] / pod / perlretut.pod
1 =head1 NAME
2
3 perlretut - Perl regular expressions tutorial
4
5 =head1 DESCRIPTION
6
7 This page provides a basic tutorial on understanding, creating and
8 using regular expressions in Perl.  It serves as a complement to the
9 reference page on regular expressions L<perlre>.  Regular expressions
10 are an integral part of the C<m//>, C<s///>, C<qr//> and C<split>
11 operators and so this tutorial also overlaps with
12 L<perlop/"Regexp Quote-Like Operators"> and L<perlfunc/split>.
13
14 Perl is widely renowned for excellence in text processing, and regular
15 expressions are one of the big factors behind this fame.  Perl regular
16 expressions display an efficiency and flexibility unknown in most
17 other computer languages.  Mastering even the basics of regular
18 expressions will allow you to manipulate text with surprising ease.
19
20 What is a regular expression?  A regular expression is simply a string
21 that describes a pattern.  Patterns are in common use these days;
22 examples are the patterns typed into a search engine to find web pages
23 and the patterns used to list files in a directory, e.g., C<ls *.txt>
24 or C<dir *.*>.  In Perl, the patterns described by regular expressions
25 are used to search strings, extract desired parts of strings, and to
26 do search and replace operations.
27
28 Regular expressions have the undeserved reputation of being abstract
29 and difficult to understand.  Regular expressions are constructed using
30 simple concepts like conditionals and loops and are no more difficult
31 to understand than the corresponding C<if> conditionals and C<while>
32 loops in the Perl language itself.  In fact, the main challenge in
33 learning regular expressions is just getting used to the terse
34 notation used to express these concepts.
35
36 This tutorial flattens the learning curve by discussing regular
37 expression concepts, along with their notation, one at a time and with
38 many examples.  The first part of the tutorial will progress from the
39 simplest word searches to the basic regular expression concepts.  If
40 you master the first part, you will have all the tools needed to solve
41 about 98% of your needs.  The second part of the tutorial is for those
42 comfortable with the basics and hungry for more power tools.  It
43 discusses the more advanced regular expression operators and
44 introduces the latest cutting-edge innovations.
45
46 A note: to save time, 'regular expression' is often abbreviated as
47 regexp or regex.  Regexp is a more natural abbreviation than regex, but
48 is harder to pronounce.  The Perl pod documentation is evenly split on
49 regexp vs regex; in Perl, there is more than one way to abbreviate it.
50 We'll use regexp in this tutorial.
51
52 =head1 Part 1: The basics
53
54 =head2 Simple word matching
55
56 The simplest regexp is simply a word, or more generally, a string of
57 characters.  A regexp consisting of a word matches any string that
58 contains that word:
59
60     "Hello World" =~ /World/;  # matches
61
62 What is this Perl statement all about? C<"Hello World"> is a simple
63 double-quoted string.  C<World> is the regular expression and the
64 C<//> enclosing C</World/> tells Perl to search a string for a match.
65 The operator C<=~> associates the string with the regexp match and
66 produces a true value if the regexp matched, or false if the regexp
67 did not match.  In our case, C<World> matches the second word in
68 C<"Hello World">, so the expression is true.  Expressions like this
69 are useful in conditionals:
70
71     if ("Hello World" =~ /World/) {
72         print "It matches\n";
73     }
74     else {
75         print "It doesn't match\n";
76     }
77
78 There are useful variations on this theme.  The sense of the match can
79 be reversed by using the C<!~> operator:
80
81     if ("Hello World" !~ /World/) {
82         print "It doesn't match\n";
83     }
84     else {
85         print "It matches\n";
86     }
87
88 The literal string in the regexp can be replaced by a variable:
89
90     $greeting = "World";
91     if ("Hello World" =~ /$greeting/) {
92         print "It matches\n";
93     }
94     else {
95         print "It doesn't match\n";
96     }
97
98 If you're matching against the special default variable C<$_>, the
99 C<$_ =~> part can be omitted:
100
101     $_ = "Hello World";
102     if (/World/) {
103         print "It matches\n";
104     }
105     else {
106         print "It doesn't match\n";
107     }
108
109 And finally, the C<//> default delimiters for a match can be changed
110 to arbitrary delimiters by putting an C<'m'> out front:
111
112     "Hello World" =~ m!World!;   # matches, delimited by '!'
113     "Hello World" =~ m{World};   # matches, note the matching '{}'
114     "/usr/bin/perl" =~ m"/perl"; # matches after '/usr/bin',
115                                  # '/' becomes an ordinary char
116
117 C</World/>, C<m!World!>, and C<m{World}> all represent the
118 same thing.  When, e.g., the quote (C<">) is used as a delimiter, the forward
119 slash C<'/'> becomes an ordinary character and can be used in this regexp
120 without trouble.
121
122 Let's consider how different regexps would match C<"Hello World">:
123
124     "Hello World" =~ /world/;  # doesn't match
125     "Hello World" =~ /o W/;    # matches
126     "Hello World" =~ /oW/;     # doesn't match
127     "Hello World" =~ /World /; # doesn't match
128
129 The first regexp C<world> doesn't match because regexps are
130 case-sensitive.  The second regexp matches because the substring
131 S<C<'o W'>> occurs in the string S<C<"Hello World">>.  The space
132 character ' ' is treated like any other character in a regexp and is
133 needed to match in this case.  The lack of a space character is the
134 reason the third regexp C<'oW'> doesn't match.  The fourth regexp
135 C<'World '> doesn't match because there is a space at the end of the
136 regexp, but not at the end of the string.  The lesson here is that
137 regexps must match a part of the string I<exactly> in order for the
138 statement to be true.
139
140 If a regexp matches in more than one place in the string, Perl will
141 always match at the earliest possible point in the string:
142
143     "Hello World" =~ /o/;       # matches 'o' in 'Hello'
144     "That hat is red" =~ /hat/; # matches 'hat' in 'That'
145
146 With respect to character matching, there are a few more points you
147 need to know about.   First of all, not all characters can be used 'as
148 is' in a match.  Some characters, called I<metacharacters>, are reserved
149 for use in regexp notation.  The metacharacters are
150
151     {}[]()^$.|*+?\
152
153 The significance of each of these will be explained
154 in the rest of the tutorial, but for now, it is important only to know
155 that a metacharacter can be matched by putting a backslash before it:
156
157     "2+2=4" =~ /2+2/;    # doesn't match, + is a metacharacter
158     "2+2=4" =~ /2\+2/;   # matches, \+ is treated like an ordinary +
159     "The interval is [0,1)." =~ /[0,1)./     # is a syntax error!
160     "The interval is [0,1)." =~ /\[0,1\)\./  # matches
161     "#!/usr/bin/perl" =~ /#!\/usr\/bin\/perl/;  # matches
162
163 In the last regexp, the forward slash C<'/'> is also backslashed,
164 because it is used to delimit the regexp.  This can lead to LTS
165 (leaning toothpick syndrome), however, and it is often more readable
166 to change delimiters.
167
168     "#!/usr/bin/perl" =~ m!#\!/usr/bin/perl!;  # easier to read
169
170 The backslash character C<'\'> is a metacharacter itself and needs to
171 be backslashed:
172
173     'C:\WIN32' =~ /C:\\WIN/;   # matches
174
175 In addition to the metacharacters, there are some ASCII characters
176 which don't have printable character equivalents and are instead
177 represented by I<escape sequences>.  Common examples are C<\t> for a
178 tab, C<\n> for a newline, C<\r> for a carriage return and C<\a> for a
179 bell (or alert).  If your string is better thought of as a sequence of arbitrary
180 bytes, the octal escape sequence, e.g., C<\033>, or hexadecimal escape
181 sequence, e.g., C<\x1B> may be a more natural representation for your
182 bytes.  Here are some examples of escapes:
183
184     "1000\t2000" =~ m(0\t2)   # matches
185     "1000\n2000" =~ /0\n20/   # matches
186     "1000\t2000" =~ /\000\t2/ # doesn't match, "0" ne "\000"
187     "cat"   =~ /\o{143}\x61\x74/ # matches in ASCII, but a weird way
188                                  # to spell cat
189
190 If you've been around Perl a while, all this talk of escape sequences
191 may seem familiar.  Similar escape sequences are used in double-quoted
192 strings and in fact the regexps in Perl are mostly treated as
193 double-quoted strings.  This means that variables can be used in
194 regexps as well.  Just like double-quoted strings, the values of the
195 variables in the regexp will be substituted in before the regexp is
196 evaluated for matching purposes.  So we have:
197
198     $foo = 'house';
199     'housecat' =~ /$foo/;      # matches
200     'cathouse' =~ /cat$foo/;   # matches
201     'housecat' =~ /${foo}cat/; # matches
202
203 So far, so good.  With the knowledge above you can already perform
204 searches with just about any literal string regexp you can dream up.
205 Here is a I<very simple> emulation of the Unix grep program:
206
207     % cat > simple_grep
208     #!/usr/bin/perl
209     $regexp = shift;
210     while (<>) {
211         print if /$regexp/;
212     }
213     ^D
214
215     % chmod +x simple_grep
216
217     % simple_grep abba /usr/dict/words
218     Babbage
219     cabbage
220     cabbages
221     sabbath
222     Sabbathize
223     Sabbathizes
224     sabbatical
225     scabbard
226     scabbards
227
228 This program is easy to understand.  C<#!/usr/bin/perl> is the standard
229 way to invoke a perl program from the shell.
230 S<C<$regexp = shift;>> saves the first command line argument as the
231 regexp to be used, leaving the rest of the command line arguments to
232 be treated as files.  S<C<< while (<>) >>> loops over all the lines in
233 all the files.  For each line, S<C<print if /$regexp/;>> prints the
234 line if the regexp matches the line.  In this line, both C<print> and
235 C</$regexp/> use the default variable C<$_> implicitly.
236
237 With all of the regexps above, if the regexp matched anywhere in the
238 string, it was considered a match.  Sometimes, however, we'd like to
239 specify I<where> in the string the regexp should try to match.  To do
240 this, we would use the I<anchor> metacharacters C<^> and C<$>.  The
241 anchor C<^> means match at the beginning of the string and the anchor
242 C<$> means match at the end of the string, or before a newline at the
243 end of the string.  Here is how they are used:
244
245     "housekeeper" =~ /keeper/;    # matches
246     "housekeeper" =~ /^keeper/;   # doesn't match
247     "housekeeper" =~ /keeper$/;   # matches
248     "housekeeper\n" =~ /keeper$/; # matches
249
250 The second regexp doesn't match because C<^> constrains C<keeper> to
251 match only at the beginning of the string, but C<"housekeeper"> has
252 keeper starting in the middle.  The third regexp does match, since the
253 C<$> constrains C<keeper> to match only at the end of the string.
254
255 When both C<^> and C<$> are used at the same time, the regexp has to
256 match both the beginning and the end of the string, i.e., the regexp
257 matches the whole string.  Consider
258
259     "keeper" =~ /^keep$/;      # doesn't match
260     "keeper" =~ /^keeper$/;    # matches
261     ""       =~ /^$/;          # ^$ matches an empty string
262
263 The first regexp doesn't match because the string has more to it than
264 C<keep>.  Since the second regexp is exactly the string, it
265 matches.  Using both C<^> and C<$> in a regexp forces the complete
266 string to match, so it gives you complete control over which strings
267 match and which don't.  Suppose you are looking for a fellow named
268 bert, off in a string by himself:
269
270     "dogbert" =~ /bert/;   # matches, but not what you want
271
272     "dilbert" =~ /^bert/;  # doesn't match, but ..
273     "bertram" =~ /^bert/;  # matches, so still not good enough
274
275     "bertram" =~ /^bert$/; # doesn't match, good
276     "dilbert" =~ /^bert$/; # doesn't match, good
277     "bert"    =~ /^bert$/; # matches, perfect
278
279 Of course, in the case of a literal string, one could just as easily
280 use the string comparison S<C<$string eq 'bert'>> and it would be
281 more efficient.   The  C<^...$> regexp really becomes useful when we
282 add in the more powerful regexp tools below.
283
284 =head2 Using character classes
285
286 Although one can already do quite a lot with the literal string
287 regexps above, we've only scratched the surface of regular expression
288 technology.  In this and subsequent sections we will introduce regexp
289 concepts (and associated metacharacter notations) that will allow a
290 regexp to represent not just a single character sequence, but a I<whole
291 class> of them.
292
293 One such concept is that of a I<character class>.  A character class
294 allows a set of possible characters, rather than just a single
295 character, to match at a particular point in a regexp.  Character
296 classes are denoted by brackets C<[...]>, with the set of characters
297 to be possibly matched inside.  Here are some examples:
298
299     /cat/;       # matches 'cat'
300     /[bcr]at/;   # matches 'bat, 'cat', or 'rat'
301     /item[0123456789]/;  # matches 'item0' or ... or 'item9'
302     "abc" =~ /[cab]/;    # matches 'a'
303
304 In the last statement, even though C<'c'> is the first character in
305 the class, C<'a'> matches because the first character position in the
306 string is the earliest point at which the regexp can match.
307
308     /[yY][eE][sS]/;      # match 'yes' in a case-insensitive way
309                          # 'yes', 'Yes', 'YES', etc.
310
311 This regexp displays a common task: perform a case-insensitive
312 match.  Perl provides a way of avoiding all those brackets by simply
313 appending an C<'i'> to the end of the match.  Then C</[yY][eE][sS]/;>
314 can be rewritten as C</yes/i;>.  The C<'i'> stands for
315 case-insensitive and is an example of a I<modifier> of the matching
316 operation.  We will meet other modifiers later in the tutorial.
317
318 We saw in the section above that there were ordinary characters, which
319 represented themselves, and special characters, which needed a
320 backslash C<\> to represent themselves.  The same is true in a
321 character class, but the sets of ordinary and special characters
322 inside a character class are different than those outside a character
323 class.  The special characters for a character class are C<-]\^$> (and
324 the pattern delimiter, whatever it is).
325 C<]> is special because it denotes the end of a character class.  C<$> is
326 special because it denotes a scalar variable.  C<\> is special because
327 it is used in escape sequences, just like above.  Here is how the
328 special characters C<]$\> are handled:
329
330    /[\]c]def/; # matches ']def' or 'cdef'
331    $x = 'bcr';
332    /[$x]at/;   # matches 'bat', 'cat', or 'rat'
333    /[\$x]at/;  # matches '$at' or 'xat'
334    /[\\$x]at/; # matches '\at', 'bat, 'cat', or 'rat'
335
336 The last two are a little tricky.  In C<[\$x]>, the backslash protects
337 the dollar sign, so the character class has two members C<$> and C<x>.
338 In C<[\\$x]>, the backslash is protected, so C<$x> is treated as a
339 variable and substituted in double quote fashion.
340
341 The special character C<'-'> acts as a range operator within character
342 classes, so that a contiguous set of characters can be written as a
343 range.  With ranges, the unwieldy C<[0123456789]> and C<[abc...xyz]>
344 become the svelte C<[0-9]> and C<[a-z]>.  Some examples are
345
346     /item[0-9]/;  # matches 'item0' or ... or 'item9'
347     /[0-9bx-z]aa/;  # matches '0aa', ..., '9aa',
348                     # 'baa', 'xaa', 'yaa', or 'zaa'
349     /[0-9a-fA-F]/;  # matches a hexadecimal digit
350     /[0-9a-zA-Z_]/; # matches a "word" character,
351                     # like those in a Perl variable name
352
353 If C<'-'> is the first or last character in a character class, it is
354 treated as an ordinary character; C<[-ab]>, C<[ab-]> and C<[a\-b]> are
355 all equivalent.
356
357 The special character C<^> in the first position of a character class
358 denotes a I<negated character class>, which matches any character but
359 those in the brackets.  Both C<[...]> and C<[^...]> must match a
360 character, or the match fails.  Then
361
362     /[^a]at/;  # doesn't match 'aat' or 'at', but matches
363                # all other 'bat', 'cat, '0at', '%at', etc.
364     /[^0-9]/;  # matches a non-numeric character
365     /[a^]at/;  # matches 'aat' or '^at'; here '^' is ordinary
366
367 Now, even C<[0-9]> can be a bother to write multiple times, so in the
368 interest of saving keystrokes and making regexps more readable, Perl
369 has several abbreviations for common character classes, as shown below.
370 Since the introduction of Unicode, unless the C<//a> modifier is in
371 effect, these character classes match more than just a few characters in
372 the ASCII range.
373
374 =over 4
375
376 =item *
377
378 \d matches a digit, not just [0-9] but also digits from non-roman scripts
379
380 =item *
381
382 \s matches a whitespace character, the set [\ \t\r\n\f] and others
383
384 =item *
385
386 \w matches a word character (alphanumeric or _), not just [0-9a-zA-Z_]
387 but also digits and characters from non-roman scripts
388
389 =item *
390
391 \D is a negated \d; it represents any other character than a digit, or [^\d]
392
393 =item *
394
395 \S is a negated \s; it represents any non-whitespace character [^\s]
396
397 =item *
398
399 \W is a negated \w; it represents any non-word character [^\w]
400
401 =item *
402
403 The period '.' matches any character but "\n" (unless the modifier C<//s> is
404 in effect, as explained below).
405
406 =item *
407
408 \N, like the period, matches any character but "\n", but it does so
409 regardless of whether the modifier C<//s> is in effect.
410
411 =back
412
413 The C<//a> modifier, available starting in Perl 5.14,  is used to
414 restrict the matches of \d, \s, and \w to just those in the ASCII range.
415 It is useful to keep your program from being needlessly exposed to full
416 Unicode (and its accompanying security considerations) when all you want
417 is to process English-like text.  (The "a" may be doubled, C<//aa>, to
418 provide even more restrictions, preventing case-insensitive matching of
419 ASCII with non-ASCII characters; otherwise a Unicode "Kelvin Sign"
420 would caselessly match a "k" or "K".)
421
422 The C<\d\s\w\D\S\W> abbreviations can be used both inside and outside
423 of character classes.  Here are some in use:
424
425     /\d\d:\d\d:\d\d/; # matches a hh:mm:ss time format
426     /[\d\s]/;         # matches any digit or whitespace character
427     /\w\W\w/;         # matches a word char, followed by a
428                       # non-word char, followed by a word char
429     /..rt/;           # matches any two chars, followed by 'rt'
430     /end\./;          # matches 'end.'
431     /end[.]/;         # same thing, matches 'end.'
432
433 Because a period is a metacharacter, it needs to be escaped to match
434 as an ordinary period. Because, for example, C<\d> and C<\w> are sets
435 of characters, it is incorrect to think of C<[^\d\w]> as C<[\D\W]>; in
436 fact C<[^\d\w]> is the same as C<[^\w]>, which is the same as
437 C<[\W]>. Think DeMorgan's laws.
438
439 An anchor useful in basic regexps is the I<word anchor>
440 C<\b>.  This matches a boundary between a word character and a non-word
441 character C<\w\W> or C<\W\w>:
442
443     $x = "Housecat catenates house and cat";
444     $x =~ /cat/;    # matches cat in 'housecat'
445     $x =~ /\bcat/;  # matches cat in 'catenates'
446     $x =~ /cat\b/;  # matches cat in 'housecat'
447     $x =~ /\bcat\b/;  # matches 'cat' at end of string
448
449 Note in the last example, the end of the string is considered a word
450 boundary.
451
452 You might wonder why C<'.'> matches everything but C<"\n"> - why not
453 every character? The reason is that often one is matching against
454 lines and would like to ignore the newline characters.  For instance,
455 while the string C<"\n"> represents one line, we would like to think
456 of it as empty.  Then
457
458     ""   =~ /^$/;    # matches
459     "\n" =~ /^$/;    # matches, $ anchors before "\n"
460
461     ""   =~ /./;      # doesn't match; it needs a char
462     ""   =~ /^.$/;    # doesn't match; it needs a char
463     "\n" =~ /^.$/;    # doesn't match; it needs a char other than "\n"
464     "a"  =~ /^.$/;    # matches
465     "a\n"  =~ /^.$/;  # matches, $ anchors before "\n"
466
467 This behavior is convenient, because we usually want to ignore
468 newlines when we count and match characters in a line.  Sometimes,
469 however, we want to keep track of newlines.  We might even want C<^>
470 and C<$> to anchor at the beginning and end of lines within the
471 string, rather than just the beginning and end of the string.  Perl
472 allows us to choose between ignoring and paying attention to newlines
473 by using the C<//s> and C<//m> modifiers.  C<//s> and C<//m> stand for
474 single line and multi-line and they determine whether a string is to
475 be treated as one continuous string, or as a set of lines.  The two
476 modifiers affect two aspects of how the regexp is interpreted: 1) how
477 the C<'.'> character class is defined, and 2) where the anchors C<^>
478 and C<$> are able to match.  Here are the four possible combinations:
479
480 =over 4
481
482 =item *
483
484 no modifiers (//): Default behavior.  C<'.'> matches any character
485 except C<"\n">.  C<^> matches only at the beginning of the string and
486 C<$> matches only at the end or before a newline at the end.
487
488 =item *
489
490 s modifier (//s): Treat string as a single long line.  C<'.'> matches
491 any character, even C<"\n">.  C<^> matches only at the beginning of
492 the string and C<$> matches only at the end or before a newline at the
493 end.
494
495 =item *
496
497 m modifier (//m): Treat string as a set of multiple lines.  C<'.'>
498 matches any character except C<"\n">.  C<^> and C<$> are able to match
499 at the start or end of I<any> line within the string.
500
501 =item *
502
503 both s and m modifiers (//sm): Treat string as a single long line, but
504 detect multiple lines.  C<'.'> matches any character, even
505 C<"\n">.  C<^> and C<$>, however, are able to match at the start or end
506 of I<any> line within the string.
507
508 =back
509
510 Here are examples of C<//s> and C<//m> in action:
511
512     $x = "There once was a girl\nWho programmed in Perl\n";
513
514     $x =~ /^Who/;   # doesn't match, "Who" not at start of string
515     $x =~ /^Who/s;  # doesn't match, "Who" not at start of string
516     $x =~ /^Who/m;  # matches, "Who" at start of second line
517     $x =~ /^Who/sm; # matches, "Who" at start of second line
518
519     $x =~ /girl.Who/;   # doesn't match, "." doesn't match "\n"
520     $x =~ /girl.Who/s;  # matches, "." matches "\n"
521     $x =~ /girl.Who/m;  # doesn't match, "." doesn't match "\n"
522     $x =~ /girl.Who/sm; # matches, "." matches "\n"
523
524 Most of the time, the default behavior is what is wanted, but C<//s> and
525 C<//m> are occasionally very useful.  If C<//m> is being used, the start
526 of the string can still be matched with C<\A> and the end of the string
527 can still be matched with the anchors C<\Z> (matches both the end and
528 the newline before, like C<$>), and C<\z> (matches only the end):
529
530     $x =~ /^Who/m;   # matches, "Who" at start of second line
531     $x =~ /\AWho/m;  # doesn't match, "Who" is not at start of string
532
533     $x =~ /girl$/m;  # matches, "girl" at end of first line
534     $x =~ /girl\Z/m; # doesn't match, "girl" is not at end of string
535
536     $x =~ /Perl\Z/m; # matches, "Perl" is at newline before end
537     $x =~ /Perl\z/m; # doesn't match, "Perl" is not at end of string
538
539 We now know how to create choices among classes of characters in a
540 regexp.  What about choices among words or character strings? Such
541 choices are described in the next section.
542
543 =head2 Matching this or that
544
545 Sometimes we would like our regexp to be able to match different
546 possible words or character strings.  This is accomplished by using
547 the I<alternation> metacharacter C<|>.  To match C<dog> or C<cat>, we
548 form the regexp C<dog|cat>.  As before, Perl will try to match the
549 regexp at the earliest possible point in the string.  At each
550 character position, Perl will first try to match the first
551 alternative, C<dog>.  If C<dog> doesn't match, Perl will then try the
552 next alternative, C<cat>.  If C<cat> doesn't match either, then the
553 match fails and Perl moves to the next position in the string.  Some
554 examples:
555
556     "cats and dogs" =~ /cat|dog|bird/;  # matches "cat"
557     "cats and dogs" =~ /dog|cat|bird/;  # matches "cat"
558
559 Even though C<dog> is the first alternative in the second regexp,
560 C<cat> is able to match earlier in the string.
561
562     "cats"          =~ /c|ca|cat|cats/; # matches "c"
563     "cats"          =~ /cats|cat|ca|c/; # matches "cats"
564
565 Here, all the alternatives match at the first string position, so the
566 first alternative is the one that matches.  If some of the
567 alternatives are truncations of the others, put the longest ones first
568 to give them a chance to match.
569
570     "cab" =~ /a|b|c/ # matches "c"
571                      # /a|b|c/ == /[abc]/
572
573 The last example points out that character classes are like
574 alternations of characters.  At a given character position, the first
575 alternative that allows the regexp match to succeed will be the one
576 that matches.
577
578 =head2 Grouping things and hierarchical matching
579
580 Alternation allows a regexp to choose among alternatives, but by
581 itself it is unsatisfying.  The reason is that each alternative is a whole
582 regexp, but sometime we want alternatives for just part of a
583 regexp.  For instance, suppose we want to search for housecats or
584 housekeepers.  The regexp C<housecat|housekeeper> fits the bill, but is
585 inefficient because we had to type C<house> twice.  It would be nice to
586 have parts of the regexp be constant, like C<house>, and some
587 parts have alternatives, like C<cat|keeper>.
588
589 The I<grouping> metacharacters C<()> solve this problem.  Grouping
590 allows parts of a regexp to be treated as a single unit.  Parts of a
591 regexp are grouped by enclosing them in parentheses.  Thus we could solve
592 the C<housecat|housekeeper> by forming the regexp as
593 C<house(cat|keeper)>.  The regexp C<house(cat|keeper)> means match
594 C<house> followed by either C<cat> or C<keeper>.  Some more examples
595 are
596
597     /(a|b)b/;    # matches 'ab' or 'bb'
598     /(ac|b)b/;   # matches 'acb' or 'bb'
599     /(^a|b)c/;   # matches 'ac' at start of string or 'bc' anywhere
600     /(a|[bc])d/; # matches 'ad', 'bd', or 'cd'
601
602     /house(cat|)/;  # matches either 'housecat' or 'house'
603     /house(cat(s|)|)/;  # matches either 'housecats' or 'housecat' or
604                         # 'house'.  Note groups can be nested.
605
606     /(19|20|)\d\d/;  # match years 19xx, 20xx, or the Y2K problem, xx
607     "20" =~ /(19|20|)\d\d/;  # matches the null alternative '()\d\d',
608                              # because '20\d\d' can't match
609
610 Alternations behave the same way in groups as out of them: at a given
611 string position, the leftmost alternative that allows the regexp to
612 match is taken.  So in the last example at the first string position,
613 C<"20"> matches the second alternative, but there is nothing left over
614 to match the next two digits C<\d\d>.  So Perl moves on to the next
615 alternative, which is the null alternative and that works, since
616 C<"20"> is two digits.
617
618 The process of trying one alternative, seeing if it matches, and
619 moving on to the next alternative, while going back in the string
620 from where the previous alternative was tried, if it doesn't, is called
621 I<backtracking>.  The term 'backtracking' comes from the idea that
622 matching a regexp is like a walk in the woods.  Successfully matching
623 a regexp is like arriving at a destination.  There are many possible
624 trailheads, one for each string position, and each one is tried in
625 order, left to right.  From each trailhead there may be many paths,
626 some of which get you there, and some which are dead ends.  When you
627 walk along a trail and hit a dead end, you have to backtrack along the
628 trail to an earlier point to try another trail.  If you hit your
629 destination, you stop immediately and forget about trying all the
630 other trails.  You are persistent, and only if you have tried all the
631 trails from all the trailheads and not arrived at your destination, do
632 you declare failure.  To be concrete, here is a step-by-step analysis
633 of what Perl does when it tries to match the regexp
634
635     "abcde" =~ /(abd|abc)(df|d|de)/;
636
637 =over 4
638
639 =item 0
640
641 Start with the first letter in the string 'a'.
642
643 =item 1
644
645 Try the first alternative in the first group 'abd'.
646
647 =item 2
648
649 Match 'a' followed by 'b'. So far so good.
650
651 =item 3
652
653 'd' in the regexp doesn't match 'c' in the string - a dead
654 end.  So backtrack two characters and pick the second alternative in
655 the first group 'abc'.
656
657 =item 4
658
659 Match 'a' followed by 'b' followed by 'c'.  We are on a roll
660 and have satisfied the first group. Set $1 to 'abc'.
661
662 =item 5
663
664 Move on to the second group and pick the first alternative
665 'df'.
666
667 =item 6
668
669 Match the 'd'.
670
671 =item 7
672
673 'f' in the regexp doesn't match 'e' in the string, so a dead
674 end.  Backtrack one character and pick the second alternative in the
675 second group 'd'.
676
677 =item 8
678
679 'd' matches. The second grouping is satisfied, so set $2 to
680 'd'.
681
682 =item 9
683
684 We are at the end of the regexp, so we are done! We have
685 matched 'abcd' out of the string "abcde".
686
687 =back
688
689 There are a couple of things to note about this analysis.  First, the
690 third alternative in the second group 'de' also allows a match, but we
691 stopped before we got to it - at a given character position, leftmost
692 wins.  Second, we were able to get a match at the first character
693 position of the string 'a'.  If there were no matches at the first
694 position, Perl would move to the second character position 'b' and
695 attempt the match all over again.  Only when all possible paths at all
696 possible character positions have been exhausted does Perl give
697 up and declare S<C<$string =~ /(abd|abc)(df|d|de)/;>> to be false.
698
699 Even with all this work, regexp matching happens remarkably fast.  To
700 speed things up, Perl compiles the regexp into a compact sequence of
701 opcodes that can often fit inside a processor cache.  When the code is
702 executed, these opcodes can then run at full throttle and search very
703 quickly.
704
705 =head2 Extracting matches
706
707 The grouping metacharacters C<()> also serve another completely
708 different function: they allow the extraction of the parts of a string
709 that matched.  This is very useful to find out what matched and for
710 text processing in general.  For each grouping, the part that matched
711 inside goes into the special variables C<$1>, C<$2>, etc.  They can be
712 used just as ordinary variables:
713
714     # extract hours, minutes, seconds
715     if ($time =~ /(\d\d):(\d\d):(\d\d)/) {    # match hh:mm:ss format
716         $hours = $1;
717         $minutes = $2;
718         $seconds = $3;
719     }
720
721 Now, we know that in scalar context,
722 S<C<$time =~ /(\d\d):(\d\d):(\d\d)/>> returns a true or false
723 value.  In list context, however, it returns the list of matched values
724 C<($1,$2,$3)>.  So we could write the code more compactly as
725
726     # extract hours, minutes, seconds
727     ($hours, $minutes, $second) = ($time =~ /(\d\d):(\d\d):(\d\d)/);
728
729 If the groupings in a regexp are nested, C<$1> gets the group with the
730 leftmost opening parenthesis, C<$2> the next opening parenthesis,
731 etc.  Here is a regexp with nested groups:
732
733     /(ab(cd|ef)((gi)|j))/;
734      1  2      34
735
736 If this regexp matches, C<$1> contains a string starting with
737 C<'ab'>, C<$2> is either set to C<'cd'> or C<'ef'>, C<$3> equals either
738 C<'gi'> or C<'j'>, and C<$4> is either set to C<'gi'>, just like C<$3>,
739 or it remains undefined.
740
741 For convenience, Perl sets C<$+> to the string held by the highest numbered
742 C<$1>, C<$2>,... that got assigned (and, somewhat related, C<$^N> to the
743 value of the C<$1>, C<$2>,... most-recently assigned; i.e. the C<$1>,
744 C<$2>,... associated with the rightmost closing parenthesis used in the
745 match).
746
747
748 =head2 Backreferences
749
750 Closely associated with the matching variables C<$1>, C<$2>, ... are
751 the I<backreferences> C<\g1>, C<\g2>,...  Backreferences are simply
752 matching variables that can be used I<inside> a regexp.  This is a
753 really nice feature; what matches later in a regexp is made to depend on
754 what matched earlier in the regexp.  Suppose we wanted to look
755 for doubled words in a text, like 'the the'.  The following regexp finds
756 all 3-letter doubles with a space in between:
757
758     /\b(\w\w\w)\s\g1\b/;
759
760 The grouping assigns a value to \g1, so that the same 3-letter sequence
761 is used for both parts.
762
763 A similar task is to find words consisting of two identical parts:
764
765     % simple_grep '^(\w\w\w\w|\w\w\w|\w\w|\w)\g1$' /usr/dict/words
766     beriberi
767     booboo
768     coco
769     mama
770     murmur
771     papa
772
773 The regexp has a single grouping which considers 4-letter
774 combinations, then 3-letter combinations, etc., and uses C<\g1> to look for
775 a repeat.  Although C<$1> and C<\g1> represent the same thing, care should be
776 taken to use matched variables C<$1>, C<$2>,... only I<outside> a regexp
777 and backreferences C<\g1>, C<\g2>,... only I<inside> a regexp; not doing
778 so may lead to surprising and unsatisfactory results.
779
780
781 =head2 Relative backreferences
782
783 Counting the opening parentheses to get the correct number for a
784 backreference is errorprone as soon as there is more than one
785 capturing group.  A more convenient technique became available
786 with Perl 5.10: relative backreferences. To refer to the immediately
787 preceding capture group one now may write C<\g{-1}>, the next but
788 last is available via C<\g{-2}>, and so on.
789
790 Another good reason in addition to readability and maintainability
791 for using relative backreferences is illustrated by the following example,
792 where a simple pattern for matching peculiar strings is used:
793
794     $a99a = '([a-z])(\d)\g2\g1';   # matches a11a, g22g, x33x, etc.
795
796 Now that we have this pattern stored as a handy string, we might feel
797 tempted to use it as a part of some other pattern:
798
799     $line = "code=e99e";
800     if ($line =~ /^(\w+)=$a99a$/){   # unexpected behavior!
801         print "$1 is valid\n";
802     } else {
803         print "bad line: '$line'\n";
804     }
805
806 But this doesn't match, at least not the way one might expect. Only
807 after inserting the interpolated C<$a99a> and looking at the resulting
808 full text of the regexp is it obvious that the backreferences have
809 backfired. The subexpression C<(\w+)> has snatched number 1 and
810 demoted the groups in C<$a99a> by one rank. This can be avoided by
811 using relative backreferences:
812
813     $a99a = '([a-z])(\d)\g{-1}\g{-2}';  # safe for being interpolated
814
815
816 =head2 Named backreferences
817
818 Perl 5.10 also introduced named capture groups and named backreferences.
819 To attach a name to a capturing group, you write either
820 C<< (?<name>...) >> or C<< (?'name'...) >>.  The backreference may
821 then be written as C<\g{name}>.  It is permissible to attach the
822 same name to more than one group, but then only the leftmost one of the
823 eponymous set can be referenced.  Outside of the pattern a named
824 capture group is accessible through the C<%+> hash.
825
826 Assuming that we have to match calendar dates which may be given in one
827 of the three formats yyyy-mm-dd, mm/dd/yyyy or dd.mm.yyyy, we can write
828 three suitable patterns where we use 'd', 'm' and 'y' respectively as the
829 names of the groups capturing the pertaining components of a date. The
830 matching operation combines the three patterns as alternatives:
831
832     $fmt1 = '(?<y>\d\d\d\d)-(?<m>\d\d)-(?<d>\d\d)';
833     $fmt2 = '(?<m>\d\d)/(?<d>\d\d)/(?<y>\d\d\d\d)';
834     $fmt3 = '(?<d>\d\d)\.(?<m>\d\d)\.(?<y>\d\d\d\d)';
835     for my $d qw( 2006-10-21 15.01.2007 10/31/2005 ){
836         if ( $d =~ m{$fmt1|$fmt2|$fmt3} ){
837             print "day=$+{d} month=$+{m} year=$+{y}\n";
838         }
839     }
840
841 If any of the alternatives matches, the hash C<%+> is bound to contain the
842 three key-value pairs.
843
844
845 =head2 Alternative capture group numbering
846
847 Yet another capturing group numbering technique (also as from Perl 5.10)
848 deals with the problem of referring to groups within a set of alternatives.
849 Consider a pattern for matching a time of the day, civil or military style:
850
851     if ( $time =~ /(\d\d|\d):(\d\d)|(\d\d)(\d\d)/ ){
852         # process hour and minute
853     }
854
855 Processing the results requires an additional if statement to determine
856 whether C<$1> and C<$2> or C<$3> and C<$4> contain the goodies. It would
857 be easier if we could use group numbers 1 and 2 in second alternative as
858 well, and this is exactly what the parenthesized construct C<(?|...)>,
859 set around an alternative achieves. Here is an extended version of the
860 previous pattern:
861
862     if ( $time =~ /(?|(\d\d|\d):(\d\d)|(\d\d)(\d\d))\s+([A-Z][A-Z][A-Z])/ ){
863         print "hour=$1 minute=$2 zone=$3\n";
864     }
865
866 Within the alternative numbering group, group numbers start at the same
867 position for each alternative. After the group, numbering continues
868 with one higher than the maximum reached across all the alternatives.
869
870 =head2 Position information
871
872 In addition to what was matched, Perl (since 5.6.0) also provides the
873 positions of what was matched as contents of the C<@-> and C<@+>
874 arrays. C<$-[0]> is the position of the start of the entire match and
875 C<$+[0]> is the position of the end. Similarly, C<$-[n]> is the
876 position of the start of the C<$n> match and C<$+[n]> is the position
877 of the end. If C<$n> is undefined, so are C<$-[n]> and C<$+[n]>. Then
878 this code
879
880     $x = "Mmm...donut, thought Homer";
881     $x =~ /^(Mmm|Yech)\.\.\.(donut|peas)/; # matches
882     foreach $expr (1..$#-) {
883         print "Match $expr: '${$expr}' at position ($-[$expr],$+[$expr])\n";
884     }
885
886 prints
887
888     Match 1: 'Mmm' at position (0,3)
889     Match 2: 'donut' at position (6,11)
890
891 Even if there are no groupings in a regexp, it is still possible to
892 find out what exactly matched in a string.  If you use them, Perl
893 will set C<$`> to the part of the string before the match, will set C<$&>
894 to the part of the string that matched, and will set C<$'> to the part
895 of the string after the match.  An example:
896
897     $x = "the cat caught the mouse";
898     $x =~ /cat/;  # $` = 'the ', $& = 'cat', $' = ' caught the mouse'
899     $x =~ /the/;  # $` = '', $& = 'the', $' = ' cat caught the mouse'
900
901 In the second match, C<$`> equals C<''> because the regexp matched at the
902 first character position in the string and stopped; it never saw the
903 second 'the'.  It is important to note that using C<$`> and C<$'>
904 slows down regexp matching quite a bit, while C<$&> slows it down to a
905 lesser extent, because if they are used in one regexp in a program,
906 they are generated for I<all> regexps in the program.  So if raw
907 performance is a goal of your application, they should be avoided.
908 If you need to extract the corresponding substrings, use C<@-> and
909 C<@+> instead:
910
911     $` is the same as substr( $x, 0, $-[0] )
912     $& is the same as substr( $x, $-[0], $+[0]-$-[0] )
913     $' is the same as substr( $x, $+[0] )
914
915 As of Perl 5.10, the C<${^PREMATCH}>, C<${^MATCH}> and C<${^POSTMATCH}>
916 variables may be used. These are only set if the C</p> modifier is present.
917 Consequently they do not penalize the rest of the program.
918
919 =head2 Non-capturing groupings
920
921 A group that is required to bundle a set of alternatives may or may not be
922 useful as a capturing group.  If it isn't, it just creates a superfluous
923 addition to the set of available capture group values, inside as well as
924 outside the regexp.  Non-capturing groupings, denoted by C<(?:regexp)>,
925 still allow the regexp to be treated as a single unit, but don't establish
926 a capturing group at the same time.  Both capturing and non-capturing
927 groupings are allowed to co-exist in the same regexp.  Because there is
928 no extraction, non-capturing groupings are faster than capturing
929 groupings.  Non-capturing groupings are also handy for choosing exactly
930 which parts of a regexp are to be extracted to matching variables:
931
932     # match a number, $1-$4 are set, but we only want $1
933     /([+-]?\ *(\d+(\.\d*)?|\.\d+)([eE][+-]?\d+)?)/;
934
935     # match a number faster , only $1 is set
936     /([+-]?\ *(?:\d+(?:\.\d*)?|\.\d+)(?:[eE][+-]?\d+)?)/;
937
938     # match a number, get $1 = whole number, $2 = exponent
939     /([+-]?\ *(?:\d+(?:\.\d*)?|\.\d+)(?:[eE]([+-]?\d+))?)/;
940
941 Non-capturing groupings are also useful for removing nuisance
942 elements gathered from a split operation where parentheses are
943 required for some reason:
944
945     $x = '12aba34ba5';
946     @num = split /(a|b)+/, $x;    # @num = ('12','a','34','a','5')
947     @num = split /(?:a|b)+/, $x;  # @num = ('12','34','5')
948
949
950 =head2 Matching repetitions
951
952 The examples in the previous section display an annoying weakness.  We
953 were only matching 3-letter words, or chunks of words of 4 letters or
954 less.  We'd like to be able to match words or, more generally, strings
955 of any length, without writing out tedious alternatives like
956 C<\w\w\w\w|\w\w\w|\w\w|\w>.
957
958 This is exactly the problem the I<quantifier> metacharacters C<?>,
959 C<*>, C<+>, and C<{}> were created for.  They allow us to delimit the
960 number of repeats for a portion of a regexp we consider to be a
961 match.  Quantifiers are put immediately after the character, character
962 class, or grouping that we want to specify.  They have the following
963 meanings:
964
965 =over 4
966
967 =item *
968
969 C<a?> means: match 'a' 1 or 0 times
970
971 =item *
972
973 C<a*> means: match 'a' 0 or more times, i.e., any number of times
974
975 =item *
976
977 C<a+> means: match 'a' 1 or more times, i.e., at least once
978
979 =item *
980
981 C<a{n,m}> means: match at least C<n> times, but not more than C<m>
982 times.
983
984 =item *
985
986 C<a{n,}> means: match at least C<n> or more times
987
988 =item *
989
990 C<a{n}> means: match exactly C<n> times
991
992 =back
993
994 Here are some examples:
995
996     /[a-z]+\s+\d*/;  # match a lowercase word, at least one space, and
997                      # any number of digits
998     /(\w+)\s+\g1/;    # match doubled words of arbitrary length
999     /y(es)?/i;       # matches 'y', 'Y', or a case-insensitive 'yes'
1000     $year =~ /^\d{2,4}$/;  # make sure year is at least 2 but not more
1001                            # than 4 digits
1002     $year =~ /^\d{4}$|^\d{2}$/;    # better match; throw out 3-digit dates
1003     $year =~ /^\d{2}(\d{2})?$/;  # same thing written differently. However,
1004                                  # this captures the last two digits in $1
1005                                  # and the other does not.
1006
1007     % simple_grep '^(\w+)\g1$' /usr/dict/words   # isn't this easier?
1008     beriberi
1009     booboo
1010     coco
1011     mama
1012     murmur
1013     papa
1014
1015 For all of these quantifiers, Perl will try to match as much of the
1016 string as possible, while still allowing the regexp to succeed.  Thus
1017 with C</a?.../>, Perl will first try to match the regexp with the C<a>
1018 present; if that fails, Perl will try to match the regexp without the
1019 C<a> present.  For the quantifier C<*>, we get the following:
1020
1021     $x = "the cat in the hat";
1022     $x =~ /^(.*)(cat)(.*)$/; # matches,
1023                              # $1 = 'the '
1024                              # $2 = 'cat'
1025                              # $3 = ' in the hat'
1026
1027 Which is what we might expect, the match finds the only C<cat> in the
1028 string and locks onto it.  Consider, however, this regexp:
1029
1030     $x =~ /^(.*)(at)(.*)$/; # matches,
1031                             # $1 = 'the cat in the h'
1032                             # $2 = 'at'
1033                             # $3 = ''   (0 characters match)
1034
1035 One might initially guess that Perl would find the C<at> in C<cat> and
1036 stop there, but that wouldn't give the longest possible string to the
1037 first quantifier C<.*>.  Instead, the first quantifier C<.*> grabs as
1038 much of the string as possible while still having the regexp match.  In
1039 this example, that means having the C<at> sequence with the final C<at>
1040 in the string.  The other important principle illustrated here is that,
1041 when there are two or more elements in a regexp, the I<leftmost>
1042 quantifier, if there is one, gets to grab as much of the string as
1043 possible, leaving the rest of the regexp to fight over scraps.  Thus in
1044 our example, the first quantifier C<.*> grabs most of the string, while
1045 the second quantifier C<.*> gets the empty string.   Quantifiers that
1046 grab as much of the string as possible are called I<maximal match> or
1047 I<greedy> quantifiers.
1048
1049 When a regexp can match a string in several different ways, we can use
1050 the principles above to predict which way the regexp will match:
1051
1052 =over 4
1053
1054 =item *
1055
1056 Principle 0: Taken as a whole, any regexp will be matched at the
1057 earliest possible position in the string.
1058
1059 =item *
1060
1061 Principle 1: In an alternation C<a|b|c...>, the leftmost alternative
1062 that allows a match for the whole regexp will be the one used.
1063
1064 =item *
1065
1066 Principle 2: The maximal matching quantifiers C<?>, C<*>, C<+> and
1067 C<{n,m}> will in general match as much of the string as possible while
1068 still allowing the whole regexp to match.
1069
1070 =item *
1071
1072 Principle 3: If there are two or more elements in a regexp, the
1073 leftmost greedy quantifier, if any, will match as much of the string
1074 as possible while still allowing the whole regexp to match.  The next
1075 leftmost greedy quantifier, if any, will try to match as much of the
1076 string remaining available to it as possible, while still allowing the
1077 whole regexp to match.  And so on, until all the regexp elements are
1078 satisfied.
1079
1080 =back
1081
1082 As we have seen above, Principle 0 overrides the others. The regexp
1083 will be matched as early as possible, with the other principles
1084 determining how the regexp matches at that earliest character
1085 position.
1086
1087 Here is an example of these principles in action:
1088
1089     $x = "The programming republic of Perl";
1090     $x =~ /^(.+)(e|r)(.*)$/;  # matches,
1091                               # $1 = 'The programming republic of Pe'
1092                               # $2 = 'r'
1093                               # $3 = 'l'
1094
1095 This regexp matches at the earliest string position, C<'T'>.  One
1096 might think that C<e>, being leftmost in the alternation, would be
1097 matched, but C<r> produces the longest string in the first quantifier.
1098
1099     $x =~ /(m{1,2})(.*)$/;  # matches,
1100                             # $1 = 'mm'
1101                             # $2 = 'ing republic of Perl'
1102
1103 Here, The earliest possible match is at the first C<'m'> in
1104 C<programming>. C<m{1,2}> is the first quantifier, so it gets to match
1105 a maximal C<mm>.
1106
1107     $x =~ /.*(m{1,2})(.*)$/;  # matches,
1108                               # $1 = 'm'
1109                               # $2 = 'ing republic of Perl'
1110
1111 Here, the regexp matches at the start of the string. The first
1112 quantifier C<.*> grabs as much as possible, leaving just a single
1113 C<'m'> for the second quantifier C<m{1,2}>.
1114
1115     $x =~ /(.?)(m{1,2})(.*)$/;  # matches,
1116                                 # $1 = 'a'
1117                                 # $2 = 'mm'
1118                                 # $3 = 'ing republic of Perl'
1119
1120 Here, C<.?> eats its maximal one character at the earliest possible
1121 position in the string, C<'a'> in C<programming>, leaving C<m{1,2}>
1122 the opportunity to match both C<m>'s. Finally,
1123
1124     "aXXXb" =~ /(X*)/; # matches with $1 = ''
1125
1126 because it can match zero copies of C<'X'> at the beginning of the
1127 string.  If you definitely want to match at least one C<'X'>, use
1128 C<X+>, not C<X*>.
1129
1130 Sometimes greed is not good.  At times, we would like quantifiers to
1131 match a I<minimal> piece of string, rather than a maximal piece.  For
1132 this purpose, Larry Wall created the I<minimal match> or
1133 I<non-greedy> quantifiers C<??>, C<*?>, C<+?>, and C<{}?>.  These are
1134 the usual quantifiers with a C<?> appended to them.  They have the
1135 following meanings:
1136
1137 =over 4
1138
1139 =item *
1140
1141 C<a??> means: match 'a' 0 or 1 times. Try 0 first, then 1.
1142
1143 =item *
1144
1145 C<a*?> means: match 'a' 0 or more times, i.e., any number of times,
1146 but as few times as possible
1147
1148 =item *
1149
1150 C<a+?> means: match 'a' 1 or more times, i.e., at least once, but
1151 as few times as possible
1152
1153 =item *
1154
1155 C<a{n,m}?> means: match at least C<n> times, not more than C<m>
1156 times, as few times as possible
1157
1158 =item *
1159
1160 C<a{n,}?> means: match at least C<n> times, but as few times as
1161 possible
1162
1163 =item *
1164
1165 C<a{n}?> means: match exactly C<n> times.  Because we match exactly
1166 C<n> times, C<a{n}?> is equivalent to C<a{n}> and is just there for
1167 notational consistency.
1168
1169 =back
1170
1171 Let's look at the example above, but with minimal quantifiers:
1172
1173     $x = "The programming republic of Perl";
1174     $x =~ /^(.+?)(e|r)(.*)$/; # matches,
1175                               # $1 = 'Th'
1176                               # $2 = 'e'
1177                               # $3 = ' programming republic of Perl'
1178
1179 The minimal string that will allow both the start of the string C<^>
1180 and the alternation to match is C<Th>, with the alternation C<e|r>
1181 matching C<e>.  The second quantifier C<.*> is free to gobble up the
1182 rest of the string.
1183
1184     $x =~ /(m{1,2}?)(.*?)$/;  # matches,
1185                               # $1 = 'm'
1186                               # $2 = 'ming republic of Perl'
1187
1188 The first string position that this regexp can match is at the first
1189 C<'m'> in C<programming>. At this position, the minimal C<m{1,2}?>
1190 matches just one C<'m'>.  Although the second quantifier C<.*?> would
1191 prefer to match no characters, it is constrained by the end-of-string
1192 anchor C<$> to match the rest of the string.
1193
1194     $x =~ /(.*?)(m{1,2}?)(.*)$/;  # matches,
1195                                   # $1 = 'The progra'
1196                                   # $2 = 'm'
1197                                   # $3 = 'ming republic of Perl'
1198
1199 In this regexp, you might expect the first minimal quantifier C<.*?>
1200 to match the empty string, because it is not constrained by a C<^>
1201 anchor to match the beginning of the word.  Principle 0 applies here,
1202 however.  Because it is possible for the whole regexp to match at the
1203 start of the string, it I<will> match at the start of the string.  Thus
1204 the first quantifier has to match everything up to the first C<m>.  The
1205 second minimal quantifier matches just one C<m> and the third
1206 quantifier matches the rest of the string.
1207
1208     $x =~ /(.??)(m{1,2})(.*)$/;  # matches,
1209                                  # $1 = 'a'
1210                                  # $2 = 'mm'
1211                                  # $3 = 'ing republic of Perl'
1212
1213 Just as in the previous regexp, the first quantifier C<.??> can match
1214 earliest at position C<'a'>, so it does.  The second quantifier is
1215 greedy, so it matches C<mm>, and the third matches the rest of the
1216 string.
1217
1218 We can modify principle 3 above to take into account non-greedy
1219 quantifiers:
1220
1221 =over 4
1222
1223 =item *
1224
1225 Principle 3: If there are two or more elements in a regexp, the
1226 leftmost greedy (non-greedy) quantifier, if any, will match as much
1227 (little) of the string as possible while still allowing the whole
1228 regexp to match.  The next leftmost greedy (non-greedy) quantifier, if
1229 any, will try to match as much (little) of the string remaining
1230 available to it as possible, while still allowing the whole regexp to
1231 match.  And so on, until all the regexp elements are satisfied.
1232
1233 =back
1234
1235 Just like alternation, quantifiers are also susceptible to
1236 backtracking.  Here is a step-by-step analysis of the example
1237
1238     $x = "the cat in the hat";
1239     $x =~ /^(.*)(at)(.*)$/; # matches,
1240                             # $1 = 'the cat in the h'
1241                             # $2 = 'at'
1242                             # $3 = ''   (0 matches)
1243
1244 =over 4
1245
1246 =item 0
1247
1248 Start with the first letter in the string 't'.
1249
1250 =item 1
1251
1252 The first quantifier '.*' starts out by matching the whole
1253 string 'the cat in the hat'.
1254
1255 =item 2
1256
1257 'a' in the regexp element 'at' doesn't match the end of the
1258 string.  Backtrack one character.
1259
1260 =item 3
1261
1262 'a' in the regexp element 'at' still doesn't match the last
1263 letter of the string 't', so backtrack one more character.
1264
1265 =item 4
1266
1267 Now we can match the 'a' and the 't'.
1268
1269 =item 5
1270
1271 Move on to the third element '.*'.  Since we are at the end of
1272 the string and '.*' can match 0 times, assign it the empty string.
1273
1274 =item 6
1275
1276 We are done!
1277
1278 =back
1279
1280 Most of the time, all this moving forward and backtracking happens
1281 quickly and searching is fast. There are some pathological regexps,
1282 however, whose execution time exponentially grows with the size of the
1283 string.  A typical structure that blows up in your face is of the form
1284
1285     /(a|b+)*/;
1286
1287 The problem is the nested indeterminate quantifiers.  There are many
1288 different ways of partitioning a string of length n between the C<+>
1289 and C<*>: one repetition with C<b+> of length n, two repetitions with
1290 the first C<b+> length k and the second with length n-k, m repetitions
1291 whose bits add up to length n, etc.  In fact there are an exponential
1292 number of ways to partition a string as a function of its length.  A
1293 regexp may get lucky and match early in the process, but if there is
1294 no match, Perl will try I<every> possibility before giving up.  So be
1295 careful with nested C<*>'s, C<{n,m}>'s, and C<+>'s.  The book
1296 I<Mastering Regular Expressions> by Jeffrey Friedl gives a wonderful
1297 discussion of this and other efficiency issues.
1298
1299
1300 =head2 Possessive quantifiers
1301
1302 Backtracking during the relentless search for a match may be a waste
1303 of time, particularly when the match is bound to fail.  Consider
1304 the simple pattern
1305
1306     /^\w+\s+\w+$/; # a word, spaces, a word
1307
1308 Whenever this is applied to a string which doesn't quite meet the
1309 pattern's expectations such as S<C<"abc  ">> or S<C<"abc  def ">>,
1310 the regex engine will backtrack, approximately once for each character
1311 in the string.  But we know that there is no way around taking I<all>
1312 of the initial word characters to match the first repetition, that I<all>
1313 spaces must be eaten by the middle part, and the same goes for the second
1314 word.
1315
1316 With the introduction of the I<possessive quantifiers> in Perl 5.10, we
1317 have a way of instructing the regex engine not to backtrack, with the
1318 usual quantifiers with a C<+> appended to them.  This makes them greedy as
1319 well as stingy; once they succeed they won't give anything back to permit
1320 another solution. They have the following meanings:
1321
1322 =over 4
1323
1324 =item *
1325
1326 C<a{n,m}+> means: match at least C<n> times, not more than C<m> times,
1327 as many times as possible, and don't give anything up. C<a?+> is short
1328 for C<a{0,1}+>
1329
1330 =item *
1331
1332 C<a{n,}+> means: match at least C<n> times, but as many times as possible,
1333 and don't give anything up. C<a*+> is short for C<a{0,}+> and C<a++> is
1334 short for C<a{1,}+>.
1335
1336 =item *
1337
1338 C<a{n}+> means: match exactly C<n> times.  It is just there for
1339 notational consistency.
1340
1341 =back
1342
1343 These possessive quantifiers represent a special case of a more general
1344 concept, the I<independent subexpression>, see below.
1345
1346 As an example where a possessive quantifier is suitable we consider
1347 matching a quoted string, as it appears in several programming languages.
1348 The backslash is used as an escape character that indicates that the
1349 next character is to be taken literally, as another character for the
1350 string.  Therefore, after the opening quote, we expect a (possibly
1351 empty) sequence of alternatives: either some character except an
1352 unescaped quote or backslash or an escaped character.
1353
1354     /"(?:[^"\\]++|\\.)*+"/;
1355
1356
1357 =head2 Building a regexp
1358
1359 At this point, we have all the basic regexp concepts covered, so let's
1360 give a more involved example of a regular expression.  We will build a
1361 regexp that matches numbers.
1362
1363 The first task in building a regexp is to decide what we want to match
1364 and what we want to exclude.  In our case, we want to match both
1365 integers and floating point numbers and we want to reject any string
1366 that isn't a number.
1367
1368 The next task is to break the problem down into smaller problems that
1369 are easily converted into a regexp.
1370
1371 The simplest case is integers.  These consist of a sequence of digits,
1372 with an optional sign in front.  The digits we can represent with
1373 C<\d+> and the sign can be matched with C<[+-]>.  Thus the integer
1374 regexp is
1375
1376     /[+-]?\d+/;  # matches integers
1377
1378 A floating point number potentially has a sign, an integral part, a
1379 decimal point, a fractional part, and an exponent.  One or more of these
1380 parts is optional, so we need to check out the different
1381 possibilities.  Floating point numbers which are in proper form include
1382 123., 0.345, .34, -1e6, and 25.4E-72.  As with integers, the sign out
1383 front is completely optional and can be matched by C<[+-]?>.  We can
1384 see that if there is no exponent, floating point numbers must have a
1385 decimal point, otherwise they are integers.  We might be tempted to
1386 model these with C<\d*\.\d*>, but this would also match just a single
1387 decimal point, which is not a number.  So the three cases of floating
1388 point number without exponent are
1389
1390    /[+-]?\d+\./;  # 1., 321., etc.
1391    /[+-]?\.\d+/;  # .1, .234, etc.
1392    /[+-]?\d+\.\d+/;  # 1.0, 30.56, etc.
1393
1394 These can be combined into a single regexp with a three-way alternation:
1395
1396    /[+-]?(\d+\.\d+|\d+\.|\.\d+)/;  # floating point, no exponent
1397
1398 In this alternation, it is important to put C<'\d+\.\d+'> before
1399 C<'\d+\.'>.  If C<'\d+\.'> were first, the regexp would happily match that
1400 and ignore the fractional part of the number.
1401
1402 Now consider floating point numbers with exponents.  The key
1403 observation here is that I<both> integers and numbers with decimal
1404 points are allowed in front of an exponent.  Then exponents, like the
1405 overall sign, are independent of whether we are matching numbers with
1406 or without decimal points, and can be 'decoupled' from the
1407 mantissa.  The overall form of the regexp now becomes clear:
1408
1409     /^(optional sign)(integer | f.p. mantissa)(optional exponent)$/;
1410
1411 The exponent is an C<e> or C<E>, followed by an integer.  So the
1412 exponent regexp is
1413
1414    /[eE][+-]?\d+/;  # exponent
1415
1416 Putting all the parts together, we get a regexp that matches numbers:
1417
1418    /^[+-]?(\d+\.\d+|\d+\.|\.\d+|\d+)([eE][+-]?\d+)?$/;  # Ta da!
1419
1420 Long regexps like this may impress your friends, but can be hard to
1421 decipher.  In complex situations like this, the C<//x> modifier for a
1422 match is invaluable.  It allows one to put nearly arbitrary whitespace
1423 and comments into a regexp without affecting their meaning.  Using it,
1424 we can rewrite our 'extended' regexp in the more pleasing form
1425
1426    /^
1427       [+-]?         # first, match an optional sign
1428       (             # then match integers or f.p. mantissas:
1429           \d+\.\d+  # mantissa of the form a.b
1430          |\d+\.     # mantissa of the form a.
1431          |\.\d+     # mantissa of the form .b
1432          |\d+       # integer of the form a
1433       )
1434       ([eE][+-]?\d+)?  # finally, optionally match an exponent
1435    $/x;
1436
1437 If whitespace is mostly irrelevant, how does one include space
1438 characters in an extended regexp? The answer is to backslash it
1439 S<C<'\ '>> or put it in a character class S<C<[ ]>>.  The same thing
1440 goes for pound signs: use C<\#> or C<[#]>.  For instance, Perl allows
1441 a space between the sign and the mantissa or integer, and we could add
1442 this to our regexp as follows:
1443
1444    /^
1445       [+-]?\ *      # first, match an optional sign *and space*
1446       (             # then match integers or f.p. mantissas:
1447           \d+\.\d+  # mantissa of the form a.b
1448          |\d+\.     # mantissa of the form a.
1449          |\.\d+     # mantissa of the form .b
1450          |\d+       # integer of the form a
1451       )
1452       ([eE][+-]?\d+)?  # finally, optionally match an exponent
1453    $/x;
1454
1455 In this form, it is easier to see a way to simplify the
1456 alternation.  Alternatives 1, 2, and 4 all start with C<\d+>, so it
1457 could be factored out:
1458
1459    /^
1460       [+-]?\ *      # first, match an optional sign
1461       (             # then match integers or f.p. mantissas:
1462           \d+       # start out with a ...
1463           (
1464               \.\d* # mantissa of the form a.b or a.
1465           )?        # ? takes care of integers of the form a
1466          |\.\d+     # mantissa of the form .b
1467       )
1468       ([eE][+-]?\d+)?  # finally, optionally match an exponent
1469    $/x;
1470
1471 or written in the compact form,
1472
1473     /^[+-]?\ *(\d+(\.\d*)?|\.\d+)([eE][+-]?\d+)?$/;
1474
1475 This is our final regexp.  To recap, we built a regexp by
1476
1477 =over 4
1478
1479 =item *
1480
1481 specifying the task in detail,
1482
1483 =item *
1484
1485 breaking down the problem into smaller parts,
1486
1487 =item *
1488
1489 translating the small parts into regexps,
1490
1491 =item *
1492
1493 combining the regexps,
1494
1495 =item *
1496
1497 and optimizing the final combined regexp.
1498
1499 =back
1500
1501 These are also the typical steps involved in writing a computer
1502 program.  This makes perfect sense, because regular expressions are
1503 essentially programs written in a little computer language that specifies
1504 patterns.
1505
1506 =head2 Using regular expressions in Perl
1507
1508 The last topic of Part 1 briefly covers how regexps are used in Perl
1509 programs.  Where do they fit into Perl syntax?
1510
1511 We have already introduced the matching operator in its default
1512 C</regexp/> and arbitrary delimiter C<m!regexp!> forms.  We have used
1513 the binding operator C<=~> and its negation C<!~> to test for string
1514 matches.  Associated with the matching operator, we have discussed the
1515 single line C<//s>, multi-line C<//m>, case-insensitive C<//i> and
1516 extended C<//x> modifiers.  There are a few more things you might
1517 want to know about matching operators.
1518
1519 =head3 Prohibiting substitution
1520
1521 If you change C<$pattern> after the first substitution happens, Perl
1522 will ignore it.  If you don't want any substitutions at all, use the
1523 special delimiter C<m''>:
1524
1525     @pattern = ('Seuss');
1526     while (<>) {
1527         print if m'@pattern';  # matches literal '@pattern', not 'Seuss'
1528     }
1529
1530 Similar to strings, C<m''> acts like apostrophes on a regexp; all other
1531 C<m> delimiters act like quotes.  If the regexp evaluates to the empty string,
1532 the regexp in the I<last successful match> is used instead.  So we have
1533
1534     "dog" =~ /d/;  # 'd' matches
1535     "dogbert =~ //;  # this matches the 'd' regexp used before
1536
1537
1538 =head3 Global matching
1539
1540 The final two modifiers we will disccuss here,
1541 C<//g> and C<//c>, concern multiple matches.
1542 The modifier C<//g> stands for global matching and allows the
1543 matching operator to match within a string as many times as possible.
1544 In scalar context, successive invocations against a string will have
1545 C<//g> jump from match to match, keeping track of position in the
1546 string as it goes along.  You can get or set the position with the
1547 C<pos()> function.
1548
1549 The use of C<//g> is shown in the following example.  Suppose we have
1550 a string that consists of words separated by spaces.  If we know how
1551 many words there are in advance, we could extract the words using
1552 groupings:
1553
1554     $x = "cat dog house"; # 3 words
1555     $x =~ /^\s*(\w+)\s+(\w+)\s+(\w+)\s*$/; # matches,
1556                                            # $1 = 'cat'
1557                                            # $2 = 'dog'
1558                                            # $3 = 'house'
1559
1560 But what if we had an indeterminate number of words? This is the sort
1561 of task C<//g> was made for.  To extract all words, form the simple
1562 regexp C<(\w+)> and loop over all matches with C</(\w+)/g>:
1563
1564     while ($x =~ /(\w+)/g) {
1565         print "Word is $1, ends at position ", pos $x, "\n";
1566     }
1567
1568 prints
1569
1570     Word is cat, ends at position 3
1571     Word is dog, ends at position 7
1572     Word is house, ends at position 13
1573
1574 A failed match or changing the target string resets the position.  If
1575 you don't want the position reset after failure to match, add the
1576 C<//c>, as in C</regexp/gc>.  The current position in the string is
1577 associated with the string, not the regexp.  This means that different
1578 strings have different positions and their respective positions can be
1579 set or read independently.
1580
1581 In list context, C<//g> returns a list of matched groupings, or if
1582 there are no groupings, a list of matches to the whole regexp.  So if
1583 we wanted just the words, we could use
1584
1585     @words = ($x =~ /(\w+)/g);  # matches,
1586                                 # $word[0] = 'cat'
1587                                 # $word[1] = 'dog'
1588                                 # $word[2] = 'house'
1589
1590 Closely associated with the C<//g> modifier is the C<\G> anchor.  The
1591 C<\G> anchor matches at the point where the previous C<//g> match left
1592 off.  C<\G> allows us to easily do context-sensitive matching:
1593
1594     $metric = 1;  # use metric units
1595     ...
1596     $x = <FILE>;  # read in measurement
1597     $x =~ /^([+-]?\d+)\s*/g;  # get magnitude
1598     $weight = $1;
1599     if ($metric) { # error checking
1600         print "Units error!" unless $x =~ /\Gkg\./g;
1601     }
1602     else {
1603         print "Units error!" unless $x =~ /\Glbs\./g;
1604     }
1605     $x =~ /\G\s+(widget|sprocket)/g;  # continue processing
1606
1607 The combination of C<//g> and C<\G> allows us to process the string a
1608 bit at a time and use arbitrary Perl logic to decide what to do next.
1609 Currently, the C<\G> anchor is only fully supported when used to anchor
1610 to the start of the pattern.
1611
1612 C<\G> is also invaluable in processing fixed-length records with
1613 regexps.  Suppose we have a snippet of coding region DNA, encoded as
1614 base pair letters C<ATCGTTGAAT...> and we want to find all the stop
1615 codons C<TGA>.  In a coding region, codons are 3-letter sequences, so
1616 we can think of the DNA snippet as a sequence of 3-letter records.  The
1617 naive regexp
1618
1619     # expanded, this is "ATC GTT GAA TGC AAA TGA CAT GAC"
1620     $dna = "ATCGTTGAATGCAAATGACATGAC";
1621     $dna =~ /TGA/;
1622
1623 doesn't work; it may match a C<TGA>, but there is no guarantee that
1624 the match is aligned with codon boundaries, e.g., the substring
1625 S<C<GTT GAA>> gives a match.  A better solution is
1626
1627     while ($dna =~ /(\w\w\w)*?TGA/g) {  # note the minimal *?
1628         print "Got a TGA stop codon at position ", pos $dna, "\n";
1629     }
1630
1631 which prints
1632
1633     Got a TGA stop codon at position 18
1634     Got a TGA stop codon at position 23
1635
1636 Position 18 is good, but position 23 is bogus.  What happened?
1637
1638 The answer is that our regexp works well until we get past the last
1639 real match.  Then the regexp will fail to match a synchronized C<TGA>
1640 and start stepping ahead one character position at a time, not what we
1641 want.  The solution is to use C<\G> to anchor the match to the codon
1642 alignment:
1643
1644     while ($dna =~ /\G(\w\w\w)*?TGA/g) {
1645         print "Got a TGA stop codon at position ", pos $dna, "\n";
1646     }
1647
1648 This prints
1649
1650     Got a TGA stop codon at position 18
1651
1652 which is the correct answer.  This example illustrates that it is
1653 important not only to match what is desired, but to reject what is not
1654 desired.
1655
1656 (There are other regexp modifiers that are available, such as
1657 C<//o>, C<//d>, and C<//l>, but their specialized uses are beyond the
1658 scope of this introduction.  )
1659
1660 =head3 Search and replace
1661
1662 Regular expressions also play a big role in I<search and replace>
1663 operations in Perl.  Search and replace is accomplished with the
1664 C<s///> operator.  The general form is
1665 C<s/regexp/replacement/modifiers>, with everything we know about
1666 regexps and modifiers applying in this case as well.  The
1667 C<replacement> is a Perl double-quoted string that replaces in the
1668 string whatever is matched with the C<regexp>.  The operator C<=~> is
1669 also used here to associate a string with C<s///>.  If matching
1670 against C<$_>, the S<C<$_ =~>> can be dropped.  If there is a match,
1671 C<s///> returns the number of substitutions made; otherwise it returns
1672 false.  Here are a few examples:
1673
1674     $x = "Time to feed the cat!";
1675     $x =~ s/cat/hacker/;   # $x contains "Time to feed the hacker!"
1676     if ($x =~ s/^(Time.*hacker)!$/$1 now!/) {
1677         $more_insistent = 1;
1678     }
1679     $y = "'quoted words'";
1680     $y =~ s/^'(.*)'$/$1/;  # strip single quotes,
1681                            # $y contains "quoted words"
1682
1683 In the last example, the whole string was matched, but only the part
1684 inside the single quotes was grouped.  With the C<s///> operator, the
1685 matched variables C<$1>, C<$2>, etc. are immediately available for use
1686 in the replacement expression, so we use C<$1> to replace the quoted
1687 string with just what was quoted.  With the global modifier, C<s///g>
1688 will search and replace all occurrences of the regexp in the string:
1689
1690     $x = "I batted 4 for 4";
1691     $x =~ s/4/four/;   # doesn't do it all:
1692                        # $x contains "I batted four for 4"
1693     $x = "I batted 4 for 4";
1694     $x =~ s/4/four/g;  # does it all:
1695                        # $x contains "I batted four for four"
1696
1697 If you prefer 'regex' over 'regexp' in this tutorial, you could use
1698 the following program to replace it:
1699
1700     % cat > simple_replace
1701     #!/usr/bin/perl
1702     $regexp = shift;
1703     $replacement = shift;
1704     while (<>) {
1705         s/$regexp/$replacement/g;
1706         print;
1707     }
1708     ^D
1709
1710     % simple_replace regexp regex perlretut.pod
1711
1712 In C<simple_replace> we used the C<s///g> modifier to replace all
1713 occurrences of the regexp on each line.  (Even though the regular
1714 expression appears in a loop, Perl is smart enough to compile it
1715 only once.)  As with C<simple_grep>, both the
1716 C<print> and the C<s/$regexp/$replacement/g> use C<$_> implicitly.
1717
1718 If you don't want C<s///> to change your original variable you can use
1719 the non-destructive substitute modifier, C<s///r>.  This changes the
1720 behavior so that C<s///r> returns the final substituted string
1721 (instead of the number of substitutions):
1722
1723     $x = "I like dogs.";
1724     $y = $x =~ s/dogs/cats/r;
1725     print "$x $y\n";
1726
1727 That example will print "I like dogs. I like cats". Notice the original
1728 C<$x> variable has not been affected. The overall
1729 result of the substitution is instead stored in C<$y>. If the
1730 substitution doesn't affect anything then the original string is
1731 returned:
1732
1733     $x = "I like dogs.";
1734     $y = $x =~ s/elephants/cougars/r;
1735     print "$x $y\n"; # prints "I like dogs. I like dogs."
1736
1737 One other interesting thing that the C<s///r> flag allows is chaining
1738 substitutions:
1739
1740     $x = "Cats are great.";
1741     print $x =~ s/Cats/Dogs/r =~ s/Dogs/Frogs/r =~ s/Frogs/Hedgehogs/r, "\n";
1742     # prints "Hedgehogs are great."
1743
1744 A modifier available specifically to search and replace is the
1745 C<s///e> evaluation modifier.  C<s///e> treats the
1746 replacement text as Perl code, rather than a double-quoted
1747 string.  The value that the code returns is substituted for the
1748 matched substring.  C<s///e> is useful if you need to do a bit of
1749 computation in the process of replacing text.  This example counts
1750 character frequencies in a line:
1751
1752     $x = "Bill the cat";
1753     $x =~ s/(.)/$chars{$1}++;$1/eg;  # final $1 replaces char with itself
1754     print "frequency of '$_' is $chars{$_}\n"
1755         foreach (sort {$chars{$b} <=> $chars{$a}} keys %chars);
1756
1757 This prints
1758
1759     frequency of ' ' is 2
1760     frequency of 't' is 2
1761     frequency of 'l' is 2
1762     frequency of 'B' is 1
1763     frequency of 'c' is 1
1764     frequency of 'e' is 1
1765     frequency of 'h' is 1
1766     frequency of 'i' is 1
1767     frequency of 'a' is 1
1768
1769 As with the match C<m//> operator, C<s///> can use other delimiters,
1770 such as C<s!!!> and C<s{}{}>, and even C<s{}//>.  If single quotes are
1771 used C<s'''>, then the regexp and replacement are
1772 treated as single-quoted strings and there are no
1773 variable substitutions.  C<s///> in list context
1774 returns the same thing as in scalar context, i.e., the number of
1775 matches.
1776
1777 =head3 The split function
1778
1779 The C<split()> function is another place where a regexp is used.
1780 C<split /regexp/, string, limit> separates the C<string> operand into
1781 a list of substrings and returns that list.  The regexp must be designed
1782 to match whatever constitutes the separators for the desired substrings.
1783 The C<limit>, if present, constrains splitting into no more than C<limit>
1784 number of strings.  For example, to split a string into words, use
1785
1786     $x = "Calvin and Hobbes";
1787     @words = split /\s+/, $x;  # $word[0] = 'Calvin'
1788                                # $word[1] = 'and'
1789                                # $word[2] = 'Hobbes'
1790
1791 If the empty regexp C<//> is used, the regexp always matches and
1792 the string is split into individual characters.  If the regexp has
1793 groupings, then the resulting list contains the matched substrings from the
1794 groupings as well.  For instance,
1795
1796     $x = "/usr/bin/perl";
1797     @dirs = split m!/!, $x;  # $dirs[0] = ''
1798                              # $dirs[1] = 'usr'
1799                              # $dirs[2] = 'bin'
1800                              # $dirs[3] = 'perl'
1801     @parts = split m!(/)!, $x;  # $parts[0] = ''
1802                                 # $parts[1] = '/'
1803                                 # $parts[2] = 'usr'
1804                                 # $parts[3] = '/'
1805                                 # $parts[4] = 'bin'
1806                                 # $parts[5] = '/'
1807                                 # $parts[6] = 'perl'
1808
1809 Since the first character of $x matched the regexp, C<split> prepended
1810 an empty initial element to the list.
1811
1812 If you have read this far, congratulations! You now have all the basic
1813 tools needed to use regular expressions to solve a wide range of text
1814 processing problems.  If this is your first time through the tutorial,
1815 why not stop here and play around with regexps a while....  S<Part 2>
1816 concerns the more esoteric aspects of regular expressions and those
1817 concepts certainly aren't needed right at the start.
1818
1819 =head1 Part 2: Power tools
1820
1821 OK, you know the basics of regexps and you want to know more.  If
1822 matching regular expressions is analogous to a walk in the woods, then
1823 the tools discussed in Part 1 are analogous to topo maps and a
1824 compass, basic tools we use all the time.  Most of the tools in part 2
1825 are analogous to flare guns and satellite phones.  They aren't used
1826 too often on a hike, but when we are stuck, they can be invaluable.
1827
1828 What follows are the more advanced, less used, or sometimes esoteric
1829 capabilities of Perl regexps.  In Part 2, we will assume you are
1830 comfortable with the basics and concentrate on the advanced features.
1831
1832 =head2 More on characters, strings, and character classes
1833
1834 There are a number of escape sequences and character classes that we
1835 haven't covered yet.
1836
1837 There are several escape sequences that convert characters or strings
1838 between upper and lower case, and they are also available within
1839 patterns.  C<\l> and C<\u> convert the next character to lower or
1840 upper case, respectively:
1841
1842     $x = "perl";
1843     $string =~ /\u$x/;  # matches 'Perl' in $string
1844     $x = "M(rs?|s)\\."; # note the double backslash
1845     $string =~ /\l$x/;  # matches 'mr.', 'mrs.', and 'ms.',
1846
1847 A C<\L> or C<\U> indicates a lasting conversion of case, until
1848 terminated by C<\E> or thrown over by another C<\U> or C<\L>:
1849
1850     $x = "This word is in lower case:\L SHOUT\E";
1851     $x =~ /shout/;       # matches
1852     $x = "I STILL KEYPUNCH CARDS FOR MY 360"
1853     $x =~ /\Ukeypunch/;  # matches punch card string
1854
1855 If there is no C<\E>, case is converted until the end of the
1856 string. The regexps C<\L\u$word> or C<\u\L$word> convert the first
1857 character of C<$word> to uppercase and the rest of the characters to
1858 lowercase.
1859
1860 Control characters can be escaped with C<\c>, so that a control-Z
1861 character would be matched with C<\cZ>.  The escape sequence
1862 C<\Q>...C<\E> quotes, or protects most non-alphabetic characters.   For
1863 instance,
1864
1865     $x = "\QThat !^*&%~& cat!";
1866     $x =~ /\Q!^*&%~&\E/;  # check for rough language
1867
1868 It does not protect C<$> or C<@>, so that variables can still be
1869 substituted.
1870
1871 C<\Q>, C<\L>, C<\l>, C<\U>, C<\u> and C<\E> are actually part of
1872 double-quotish syntax, and not part of regexp syntax proper.  They will
1873 work if they appear in a regular expression embeddded directly in a
1874 program, but not when contained in a string that is interpolated in a
1875 pattern.
1876
1877 With the advent of 5.6.0, Perl regexps can handle more than just the
1878 standard ASCII character set.  Perl now supports I<Unicode>, a standard
1879 for representing the alphabets from virtually all of the world's written
1880 languages, and a host of symbols.  Perl's text strings are Unicode strings, so
1881 they can contain characters with a value (codepoint or character number) higher
1882 than 255.
1883
1884 What does this mean for regexps? Well, regexp users don't need to know
1885 much about Perl's internal representation of strings.  But they do need
1886 to know 1) how to represent Unicode characters in a regexp and 2) that
1887 a matching operation will treat the string to be searched as a sequence
1888 of characters, not bytes.  The answer to 1) is that Unicode characters
1889 greater than C<chr(255)> are represented using the C<\x{hex}> notation, because
1890 \x hex (without curly braces) doesn't go further than 255.  (Starting in Perl
1891 5.14, if you're an octal fan, you can also use C<\o{oct}>.)
1892
1893     /\x{263a}/;  # match a Unicode smiley face :)
1894
1895 B<NOTE>: In Perl 5.6.0 it used to be that one needed to say C<use
1896 utf8> to use any Unicode features.  This is no more the case: for
1897 almost all Unicode processing, the explicit C<utf8> pragma is not
1898 needed.  (The only case where it matters is if your Perl script is in
1899 Unicode and encoded in UTF-8, then an explicit C<use utf8> is needed.)
1900
1901 Figuring out the hexadecimal sequence of a Unicode character you want
1902 or deciphering someone else's hexadecimal Unicode regexp is about as
1903 much fun as programming in machine code.  So another way to specify
1904 Unicode characters is to use the I<named character> escape
1905 sequence C<\N{I<name>}>.  I<name> is a name for the Unicode character, as
1906 specified in the Unicode standard.  For instance, if we wanted to
1907 represent or match the astrological sign for the planet Mercury, we
1908 could use
1909
1910     use charnames ":full"; # use named chars with Unicode full names
1911     $x = "abc\N{MERCURY}def";
1912     $x =~ /\N{MERCURY}/;   # matches
1913
1914 One can also use short names or restrict names to a certain alphabet:
1915
1916     use charnames ':full';
1917     print "\N{GREEK SMALL LETTER SIGMA} is called sigma.\n";
1918
1919     use charnames ":short";
1920     print "\N{greek:Sigma} is an upper-case sigma.\n";
1921
1922     use charnames qw(greek);
1923     print "\N{sigma} is Greek sigma\n";
1924
1925 A list of full names can be found in F<NamesList.txt> in the Unicode standard
1926 (available at L<http://www.unicode.org/Public/UNIDATA/>).
1927
1928 The answer to requirement 2), as of 5.6.0, is that a regexp (mostly)
1929 uses Unicode characters.  (For messy backward compatibility reasons,
1930 most but not all semantics of a match will assume Unicode, unless,
1931 starting in Perl 5.14, you tell it to use full Unicode.  You can do this
1932 explicitly by using the C<//u> modifier, or you can ask Perl to use the
1933 modifier implicitly for all regexes in a scope by using C<use 5.012> (or
1934 higher) or C<use feature 'unicode_strings'>.)  If you want to handle
1935 Unicode properly, you should ensure that one of these is the case.)
1936 Internally, this is encoded to bytes using either UTF-8 or a native 8
1937 bit encoding, depending on the history of the string, but conceptually
1938 it is a sequence of characters, not bytes. See L<perlunitut> for a
1939 tutorial about that.
1940
1941 Let us now discuss Unicode character classes.  Just as with Unicode
1942 characters, there are named Unicode character classes represented by the
1943 C<\p{name}> escape sequence.  Closely associated is the C<\P{name}>
1944 character class, which is the negation of the C<\p{name}> class.  For
1945 example, to match lower and uppercase characters,
1946
1947     use charnames ":full"; # use named chars with Unicode full names
1948     $x = "BOB";
1949     $x =~ /^\p{IsUpper}/;   # matches, uppercase char class
1950     $x =~ /^\P{IsUpper}/;   # doesn't match, char class sans uppercase
1951     $x =~ /^\p{IsLower}/;   # doesn't match, lowercase char class
1952     $x =~ /^\P{IsLower}/;   # matches, char class sans lowercase
1953
1954 (The "Is" is optional.)
1955
1956 Here is the association between some Perl named classes and the
1957 traditional Unicode classes:
1958
1959     Perl class name  Unicode class name or regular expression
1960
1961     IsAlpha          /^[LM]/
1962     IsAlnum          /^[LMN]/
1963     IsASCII          $code <= 127
1964     IsCntrl          /^C/
1965     IsBlank          $code =~ /^(0020|0009)$/ || /^Z[^lp]/
1966     IsDigit          Nd
1967     IsGraph          /^([LMNPS]|Co)/
1968     IsLower          Ll
1969     IsPrint          /^([LMNPS]|Co|Zs)/
1970     IsPunct          /^P/
1971     IsSpace          /^Z/ || ($code =~ /^(0009|000A|000B|000C|000D)$/
1972     IsSpacePerl      /^Z/ || ($code =~ /^(0009|000A|000C|000D|0085|2028|2029)$/
1973     IsUpper          /^L[ut]/
1974     IsWord           /^[LMN]/ || $code eq "005F"
1975     IsXDigit         $code =~ /^00(3[0-9]|[46][1-6])$/
1976
1977 You can also use the official Unicode class names with C<\p> and
1978 C<\P>, like C<\p{L}> for Unicode 'letters', C<\p{Lu}> for uppercase
1979 letters, or C<\P{Nd}> for non-digits.  If a C<name> is just one
1980 letter, the braces can be dropped.  For instance, C<\pM> is the
1981 character class of Unicode 'marks', for example accent marks.
1982 For the full list see L<perlunicode>.
1983
1984 Unicode has also been separated into various sets of characters
1985 which you can test with C<\p{...}> (in) and C<\P{...}> (not in).
1986 To test whether a character is (or is not) an element of a script
1987 you would use the script name, for example C<\p{Latin}>, C<\p{Greek}>,
1988 or C<\P{Katakana}>.
1989
1990 What we have described so far is the single form of the C<\p{...}> character
1991 classes.  There is also a compound form which you may run into.  These
1992 look like C<\p{name=value}> or C<\p{name:value}> (the equals sign and colon
1993 can be used interchangeably).  These are more general than the single form,
1994 and in fact most of the single forms are just Perl-defined shortcuts for common
1995 compound forms.  For example, the script examples in the previous paragraph
1996 could be written equivalently as C<\p{Script=Latin}>, C<\p{Script:Greek}>, and
1997 C<\P{script=katakana}> (case is irrelevant between the C<{}> braces).  You may
1998 never have to use the compound forms, but sometimes it is necessary, and their
1999 use can make your code easier to understand.
2000
2001 C<\X> is an abbreviation for a character class that comprises
2002 a Unicode I<extended grapheme cluster>.  This represents a "logical character":
2003 what appears to be a single character, but may be represented internally by more
2004 than one.  As an example, using the Unicode full names, e.g., S<C<A + COMBINING
2005 RING>> is a grapheme cluster with base character C<A> and combining character
2006 S<C<COMBINING RING>>, which translates in Danish to A with the circle atop it,
2007 as in the word Angstrom.
2008
2009 For the full and latest information about Unicode see the latest
2010 Unicode standard, or the Unicode Consortium's website L<http://www.unicode.org>
2011
2012 As if all those classes weren't enough, Perl also defines POSIX-style
2013 character classes.  These have the form C<[:name:]>, with C<name> the
2014 name of the POSIX class.  The POSIX classes are C<alpha>, C<alnum>,
2015 C<ascii>, C<cntrl>, C<digit>, C<graph>, C<lower>, C<print>, C<punct>,
2016 C<space>, C<upper>, and C<xdigit>, and two extensions, C<word> (a Perl
2017 extension to match C<\w>), and C<blank> (a GNU extension).  The C<//a>
2018 modifier restricts these to matching just in the ASCII range; otherwise
2019 they can match the same as their corresponding Perl Unicode classes:
2020 C<[:upper:]> is the same as C<\p{IsUpper}>, etc.  (There are some
2021 exceptions and gotchas with this; see L<perlrecharclass> for a full
2022 discussion.) The C<[:digit:]>, C<[:word:]>, and
2023 C<[:space:]> correspond to the familiar C<\d>, C<\w>, and C<\s>
2024 character classes.  To negate a POSIX class, put a C<^> in front of
2025 the name, so that, e.g., C<[:^digit:]> corresponds to C<\D> and, under
2026 Unicode, C<\P{IsDigit}>.  The Unicode and POSIX character classes can
2027 be used just like C<\d>, with the exception that POSIX character
2028 classes can only be used inside of a character class:
2029
2030     /\s+[abc[:digit:]xyz]\s*/;  # match a,b,c,x,y,z, or a digit
2031     /^=item\s[[:digit:]]/;      # match '=item',
2032                                 # followed by a space and a digit
2033     /\s+[abc\p{IsDigit}xyz]\s+/;  # match a,b,c,x,y,z, or a digit
2034     /^=item\s\p{IsDigit}/;        # match '=item',
2035                                   # followed by a space and a digit
2036
2037 Whew! That is all the rest of the characters and character classes.
2038
2039 =head2 Compiling and saving regular expressions
2040
2041 In Part 1 we mentioned that Perl compiles a regexp into a compact
2042 sequence of opcodes.  Thus, a compiled regexp is a data structure
2043 that can be stored once and used again and again.  The regexp quote
2044 C<qr//> does exactly that: C<qr/string/> compiles the C<string> as a
2045 regexp and transforms the result into a form that can be assigned to a
2046 variable:
2047
2048     $reg = qr/foo+bar?/;  # reg contains a compiled regexp
2049
2050 Then C<$reg> can be used as a regexp:
2051
2052     $x = "fooooba";
2053     $x =~ $reg;     # matches, just like /foo+bar?/
2054     $x =~ /$reg/;   # same thing, alternate form
2055
2056 C<$reg> can also be interpolated into a larger regexp:
2057
2058     $x =~ /(abc)?$reg/;  # still matches
2059
2060 As with the matching operator, the regexp quote can use different
2061 delimiters, e.g., C<qr!!>, C<qr{}> or C<qr~~>.  Apostrophes
2062 as delimiters (C<qr''>) inhibit any interpolation.
2063
2064 Pre-compiled regexps are useful for creating dynamic matches that
2065 don't need to be recompiled each time they are encountered.  Using
2066 pre-compiled regexps, we write a C<grep_step> program which greps
2067 for a sequence of patterns, advancing to the next pattern as soon
2068 as one has been satisfied.
2069
2070     % cat > grep_step
2071     #!/usr/bin/perl
2072     # grep_step - match <number> regexps, one after the other
2073     # usage: multi_grep <number> regexp1 regexp2 ... file1 file2 ...
2074
2075     $number = shift;
2076     $regexp[$_] = shift foreach (0..$number-1);
2077     @compiled = map qr/$_/, @regexp;
2078     while ($line = <>) {
2079         if ($line =~ /$compiled[0]/) {
2080             print $line;
2081             shift @compiled;
2082             last unless @compiled;
2083         }
2084     }
2085     ^D
2086
2087     % grep_step 3 shift print last grep_step
2088     $number = shift;
2089             print $line;
2090             last unless @compiled;
2091
2092 Storing pre-compiled regexps in an array C<@compiled> allows us to
2093 simply loop through the regexps without any recompilation, thus gaining
2094 flexibility without sacrificing speed.
2095
2096
2097 =head2 Composing regular expressions at runtime
2098
2099 Backtracking is more efficient than repeated tries with different regular
2100 expressions.  If there are several regular expressions and a match with
2101 any of them is acceptable, then it is possible to combine them into a set
2102 of alternatives.  If the individual expressions are input data, this
2103 can be done by programming a join operation.  We'll exploit this idea in
2104 an improved version of the C<simple_grep> program: a program that matches
2105 multiple patterns:
2106
2107     % cat > multi_grep
2108     #!/usr/bin/perl
2109     # multi_grep - match any of <number> regexps
2110     # usage: multi_grep <number> regexp1 regexp2 ... file1 file2 ...
2111
2112     $number = shift;
2113     $regexp[$_] = shift foreach (0..$number-1);
2114     $pattern = join '|', @regexp;
2115
2116     while ($line = <>) {
2117         print $line if $line =~ /$pattern/;
2118     }
2119     ^D
2120
2121     % multi_grep 2 shift for multi_grep
2122     $number = shift;
2123     $regexp[$_] = shift foreach (0..$number-1);
2124
2125 Sometimes it is advantageous to construct a pattern from the I<input>
2126 that is to be analyzed and use the permissible values on the left
2127 hand side of the matching operations.  As an example for this somewhat
2128 paradoxical situation, let's assume that our input contains a command
2129 verb which should match one out of a set of available command verbs,
2130 with the additional twist that commands may be abbreviated as long as
2131 the given string is unique. The program below demonstrates the basic
2132 algorithm.
2133
2134     % cat > keymatch
2135     #!/usr/bin/perl
2136     $kwds = 'copy compare list print';
2137     while( $command = <> ){
2138         $command =~ s/^\s+|\s+$//g;  # trim leading and trailing spaces
2139         if( ( @matches = $kwds =~ /\b$command\w*/g ) == 1 ){
2140             print "command: '@matches'\n";
2141         } elsif( @matches == 0 ){
2142             print "no such command: '$command'\n";
2143         } else {
2144             print "not unique: '$command' (could be one of: @matches)\n";
2145         }
2146     }
2147     ^D
2148
2149     % keymatch
2150     li
2151     command: 'list'
2152     co
2153     not unique: 'co' (could be one of: copy compare)
2154     printer
2155     no such command: 'printer'
2156
2157 Rather than trying to match the input against the keywords, we match the
2158 combined set of keywords against the input.  The pattern matching
2159 operation S<C<$kwds =~ /\b($command\w*)/g>> does several things at the
2160 same time. It makes sure that the given command begins where a keyword
2161 begins (C<\b>). It tolerates abbreviations due to the added C<\w*>. It
2162 tells us the number of matches (C<scalar @matches>) and all the keywords
2163 that were actually matched.  You could hardly ask for more.
2164
2165 =head2 Embedding comments and modifiers in a regular expression
2166
2167 Starting with this section, we will be discussing Perl's set of
2168 I<extended patterns>.  These are extensions to the traditional regular
2169 expression syntax that provide powerful new tools for pattern
2170 matching.  We have already seen extensions in the form of the minimal
2171 matching constructs C<??>, C<*?>, C<+?>, C<{n,m}?>, and C<{n,}?>.  Most
2172 of the extensions below have the form C<(?char...)>, where the
2173 C<char> is a character that determines the type of extension.
2174
2175 The first extension is an embedded comment C<(?#text)>.  This embeds a
2176 comment into the regular expression without affecting its meaning.  The
2177 comment should not have any closing parentheses in the text.  An
2178 example is
2179
2180     /(?# Match an integer:)[+-]?\d+/;
2181
2182 This style of commenting has been largely superseded by the raw,
2183 freeform commenting that is allowed with the C<//x> modifier.
2184
2185 Most modifiers, such as C<//i>, C<//m>, C<//s> and C<//x> (or any
2186 combination thereof) can also be embedded in
2187 a regexp using C<(?i)>, C<(?m)>, C<(?s)>, and C<(?x)>.  For instance,
2188
2189     /(?i)yes/;  # match 'yes' case insensitively
2190     /yes/i;     # same thing
2191     /(?x)(          # freeform version of an integer regexp
2192              [+-]?  # match an optional sign
2193              \d+    # match a sequence of digits
2194          )
2195     /x;
2196
2197 Embedded modifiers can have two important advantages over the usual
2198 modifiers.  Embedded modifiers allow a custom set of modifiers to
2199 I<each> regexp pattern.  This is great for matching an array of regexps
2200 that must have different modifiers:
2201
2202     $pattern[0] = '(?i)doctor';
2203     $pattern[1] = 'Johnson';
2204     ...
2205     while (<>) {
2206         foreach $patt (@pattern) {
2207             print if /$patt/;
2208         }
2209     }
2210
2211 The second advantage is that embedded modifiers (except C<//p>, which
2212 modifies the entire regexp) only affect the regexp
2213 inside the group the embedded modifier is contained in.  So grouping
2214 can be used to localize the modifier's effects:
2215
2216     /Answer: ((?i)yes)/;  # matches 'Answer: yes', 'Answer: YES', etc.
2217
2218 Embedded modifiers can also turn off any modifiers already present
2219 by using, e.g., C<(?-i)>.  Modifiers can also be combined into
2220 a single expression, e.g., C<(?s-i)> turns on single line mode and
2221 turns off case insensitivity.
2222
2223 Embedded modifiers may also be added to a non-capturing grouping.
2224 C<(?i-m:regexp)> is a non-capturing grouping that matches C<regexp>
2225 case insensitively and turns off multi-line mode.
2226
2227
2228 =head2 Looking ahead and looking behind
2229
2230 This section concerns the lookahead and lookbehind assertions.  First,
2231 a little background.
2232
2233 In Perl regular expressions, most regexp elements 'eat up' a certain
2234 amount of string when they match.  For instance, the regexp element
2235 C<[abc}]> eats up one character of the string when it matches, in the
2236 sense that Perl moves to the next character position in the string
2237 after the match.  There are some elements, however, that don't eat up
2238 characters (advance the character position) if they match.  The examples
2239 we have seen so far are the anchors.  The anchor C<^> matches the
2240 beginning of the line, but doesn't eat any characters.  Similarly, the
2241 word boundary anchor C<\b> matches wherever a character matching C<\w>
2242 is next to a character that doesn't, but it doesn't eat up any
2243 characters itself.  Anchors are examples of I<zero-width assertions>:
2244 zero-width, because they consume
2245 no characters, and assertions, because they test some property of the
2246 string.  In the context of our walk in the woods analogy to regexp
2247 matching, most regexp elements move us along a trail, but anchors have
2248 us stop a moment and check our surroundings.  If the local environment
2249 checks out, we can proceed forward.  But if the local environment
2250 doesn't satisfy us, we must backtrack.
2251
2252 Checking the environment entails either looking ahead on the trail,
2253 looking behind, or both.  C<^> looks behind, to see that there are no
2254 characters before.  C<$> looks ahead, to see that there are no
2255 characters after.  C<\b> looks both ahead and behind, to see if the
2256 characters on either side differ in their "word-ness".
2257
2258 The lookahead and lookbehind assertions are generalizations of the
2259 anchor concept.  Lookahead and lookbehind are zero-width assertions
2260 that let us specify which characters we want to test for.  The
2261 lookahead assertion is denoted by C<(?=regexp)> and the lookbehind
2262 assertion is denoted by C<< (?<=fixed-regexp) >>.  Some examples are
2263
2264     $x = "I catch the housecat 'Tom-cat' with catnip";
2265     $x =~ /cat(?=\s)/;   # matches 'cat' in 'housecat'
2266     @catwords = ($x =~ /(?<=\s)cat\w+/g);  # matches,
2267                                            # $catwords[0] = 'catch'
2268                                            # $catwords[1] = 'catnip'
2269     $x =~ /\bcat\b/;  # matches 'cat' in 'Tom-cat'
2270     $x =~ /(?<=\s)cat(?=\s)/; # doesn't match; no isolated 'cat' in
2271                               # middle of $x
2272
2273 Note that the parentheses in C<(?=regexp)> and C<< (?<=regexp) >> are
2274 non-capturing, since these are zero-width assertions.  Thus in the
2275 second regexp, the substrings captured are those of the whole regexp
2276 itself.  Lookahead C<(?=regexp)> can match arbitrary regexps, but
2277 lookbehind C<< (?<=fixed-regexp) >> only works for regexps of fixed
2278 width, i.e., a fixed number of characters long.  Thus
2279 C<< (?<=(ab|bc)) >> is fine, but C<< (?<=(ab)*) >> is not.  The
2280 negated versions of the lookahead and lookbehind assertions are
2281 denoted by C<(?!regexp)> and C<< (?<!fixed-regexp) >> respectively.
2282 They evaluate true if the regexps do I<not> match:
2283
2284     $x = "foobar";
2285     $x =~ /foo(?!bar)/;  # doesn't match, 'bar' follows 'foo'
2286     $x =~ /foo(?!baz)/;  # matches, 'baz' doesn't follow 'foo'
2287     $x =~ /(?<!\s)foo/;  # matches, there is no \s before 'foo'
2288
2289 The C<\C> is unsupported in lookbehind, because the already
2290 treacherous definition of C<\C> would become even more so
2291 when going backwards.
2292
2293 Here is an example where a string containing blank-separated words,
2294 numbers and single dashes is to be split into its components.
2295 Using C</\s+/> alone won't work, because spaces are not required between
2296 dashes, or a word or a dash. Additional places for a split are established
2297 by looking ahead and behind:
2298
2299     $str = "one two - --6-8";
2300     @toks = split / \s+              # a run of spaces
2301                   | (?<=\S) (?=-)    # any non-space followed by '-'
2302                   | (?<=-)  (?=\S)   # a '-' followed by any non-space
2303                   /x, $str;          # @toks = qw(one two - - - 6 - 8)
2304
2305
2306 =head2 Using independent subexpressions to prevent backtracking
2307
2308 I<Independent subexpressions> are regular expressions, in the
2309 context of a larger regular expression, that function independently of
2310 the larger regular expression.  That is, they consume as much or as
2311 little of the string as they wish without regard for the ability of
2312 the larger regexp to match.  Independent subexpressions are represented
2313 by C<< (?>regexp) >>.  We can illustrate their behavior by first
2314 considering an ordinary regexp:
2315
2316     $x = "ab";
2317     $x =~ /a*ab/;  # matches
2318
2319 This obviously matches, but in the process of matching, the
2320 subexpression C<a*> first grabbed the C<a>.  Doing so, however,
2321 wouldn't allow the whole regexp to match, so after backtracking, C<a*>
2322 eventually gave back the C<a> and matched the empty string.  Here, what
2323 C<a*> matched was I<dependent> on what the rest of the regexp matched.
2324
2325 Contrast that with an independent subexpression:
2326
2327     $x =~ /(?>a*)ab/;  # doesn't match!
2328
2329 The independent subexpression C<< (?>a*) >> doesn't care about the rest
2330 of the regexp, so it sees an C<a> and grabs it.  Then the rest of the
2331 regexp C<ab> cannot match.  Because C<< (?>a*) >> is independent, there
2332 is no backtracking and the independent subexpression does not give
2333 up its C<a>.  Thus the match of the regexp as a whole fails.  A similar
2334 behavior occurs with completely independent regexps:
2335
2336     $x = "ab";
2337     $x =~ /a*/g;   # matches, eats an 'a'
2338     $x =~ /\Gab/g; # doesn't match, no 'a' available
2339
2340 Here C<//g> and C<\G> create a 'tag team' handoff of the string from
2341 one regexp to the other.  Regexps with an independent subexpression are
2342 much like this, with a handoff of the string to the independent
2343 subexpression, and a handoff of the string back to the enclosing
2344 regexp.
2345
2346 The ability of an independent subexpression to prevent backtracking
2347 can be quite useful.  Suppose we want to match a non-empty string
2348 enclosed in parentheses up to two levels deep.  Then the following
2349 regexp matches:
2350
2351     $x = "abc(de(fg)h";  # unbalanced parentheses
2352     $x =~ /\( ( [^()]+ | \([^()]*\) )+ \)/x;
2353
2354 The regexp matches an open parenthesis, one or more copies of an
2355 alternation, and a close parenthesis.  The alternation is two-way, with
2356 the first alternative C<[^()]+> matching a substring with no
2357 parentheses and the second alternative C<\([^()]*\)>  matching a
2358 substring delimited by parentheses.  The problem with this regexp is
2359 that it is pathological: it has nested indeterminate quantifiers
2360 of the form C<(a+|b)+>.  We discussed in Part 1 how nested quantifiers
2361 like this could take an exponentially long time to execute if there
2362 was no match possible.  To prevent the exponential blowup, we need to
2363 prevent useless backtracking at some point.  This can be done by
2364 enclosing the inner quantifier as an independent subexpression:
2365
2366     $x =~ /\( ( (?>[^()]+) | \([^()]*\) )+ \)/x;
2367
2368 Here, C<< (?>[^()]+) >> breaks the degeneracy of string partitioning
2369 by gobbling up as much of the string as possible and keeping it.   Then
2370 match failures fail much more quickly.
2371
2372
2373 =head2 Conditional expressions
2374
2375 A I<conditional expression> is a form of if-then-else statement
2376 that allows one to choose which patterns are to be matched, based on
2377 some condition.  There are two types of conditional expression:
2378 C<(?(condition)yes-regexp)> and
2379 C<(?(condition)yes-regexp|no-regexp)>.  C<(?(condition)yes-regexp)> is
2380 like an S<C<'if () {}'>> statement in Perl.  If the C<condition> is true,
2381 the C<yes-regexp> will be matched.  If the C<condition> is false, the
2382 C<yes-regexp> will be skipped and Perl will move onto the next regexp
2383 element.  The second form is like an S<C<'if () {} else {}'>> statement
2384 in Perl.  If the C<condition> is true, the C<yes-regexp> will be
2385 matched, otherwise the C<no-regexp> will be matched.
2386
2387 The C<condition> can have several forms.  The first form is simply an
2388 integer in parentheses C<(integer)>.  It is true if the corresponding
2389 backreference C<\integer> matched earlier in the regexp.  The same
2390 thing can be done with a name associated with a capture group, written
2391 as C<< (<name>) >> or C<< ('name') >>.  The second form is a bare
2392 zero-width assertion C<(?...)>, either a lookahead, a lookbehind, or a
2393 code assertion (discussed in the next section).  The third set of forms
2394 provides tests that return true if the expression is executed within
2395 a recursion (C<(R)>) or is being called from some capturing group,
2396 referenced either by number (C<(R1)>, C<(R2)>,...) or by name
2397 (C<(R&name)>).
2398
2399 The integer or name form of the C<condition> allows us to choose,
2400 with more flexibility, what to match based on what matched earlier in the
2401 regexp. This searches for words of the form C<"$x$x"> or C<"$x$y$y$x">:
2402
2403     % simple_grep '^(\w+)(\w+)?(?(2)\g2\g1|\g1)$' /usr/dict/words
2404     beriberi
2405     coco
2406     couscous
2407     deed
2408     ...
2409     toot
2410     toto
2411     tutu
2412
2413 The lookbehind C<condition> allows, along with backreferences,
2414 an earlier part of the match to influence a later part of the
2415 match.  For instance,
2416
2417     /[ATGC]+(?(?<=AA)G|C)$/;
2418
2419 matches a DNA sequence such that it either ends in C<AAG>, or some
2420 other base pair combination and C<C>.  Note that the form is
2421 C<< (?(?<=AA)G|C) >> and not C<< (?((?<=AA))G|C) >>; for the
2422 lookahead, lookbehind or code assertions, the parentheses around the
2423 conditional are not needed.
2424
2425
2426 =head2 Defining named patterns
2427
2428 Some regular expressions use identical subpatterns in several places.
2429 Starting with Perl 5.10, it is possible to define named subpatterns in
2430 a section of the pattern so that they can be called up by name
2431 anywhere in the pattern.  This syntactic pattern for this definition
2432 group is C<< (?(DEFINE)(?<name>pattern)...) >>.  An insertion
2433 of a named pattern is written as C<(?&name)>.
2434
2435 The example below illustrates this feature using the pattern for
2436 floating point numbers that was presented earlier on.  The three
2437 subpatterns that are used more than once are the optional sign, the
2438 digit sequence for an integer and the decimal fraction.  The DEFINE
2439 group at the end of the pattern contains their definition.  Notice
2440 that the decimal fraction pattern is the first place where we can
2441 reuse the integer pattern.
2442
2443    /^ (?&osg)\ * ( (?&int)(?&dec)? | (?&dec) )
2444       (?: [eE](?&osg)(?&int) )?
2445     $
2446     (?(DEFINE)
2447       (?<osg>[-+]?)         # optional sign
2448       (?<int>\d++)          # integer
2449       (?<dec>\.(?&int))     # decimal fraction
2450     )/x
2451
2452
2453 =head2 Recursive patterns
2454
2455 This feature (introduced in Perl 5.10) significantly extends the
2456 power of Perl's pattern matching.  By referring to some other
2457 capture group anywhere in the pattern with the construct
2458 C<(?group-ref)>, the I<pattern> within the referenced group is used
2459 as an independent subpattern in place of the group reference itself.
2460 Because the group reference may be contained I<within> the group it
2461 refers to, it is now possible to apply pattern matching to tasks that
2462 hitherto required a recursive parser.
2463
2464 To illustrate this feature, we'll design a pattern that matches if
2465 a string contains a palindrome. (This is a word or a sentence that,
2466 while ignoring spaces, interpunctuation and case, reads the same backwards
2467 as forwards. We begin by observing that the empty string or a string
2468 containing just one word character is a palindrome. Otherwise it must
2469 have a word character up front and the same at its end, with another
2470 palindrome in between.
2471
2472     /(?: (\w) (?...Here be a palindrome...) \g{-1} | \w? )/x
2473
2474 Adding C<\W*> at either end to eliminate what is to be ignored, we already
2475 have the full pattern:
2476
2477     my $pp = qr/^(\W* (?: (\w) (?1) \g{-1} | \w? ) \W*)$/ix;
2478     for $s ( "saippuakauppias", "A man, a plan, a canal: Panama!" ){
2479         print "'$s' is a palindrome\n" if $s =~ /$pp/;
2480     }
2481
2482 In C<(?...)> both absolute and relative backreferences may be used.
2483 The entire pattern can be reinserted with C<(?R)> or C<(?0)>.
2484 If you prefer to name your groups, you can use C<(?&name)> to
2485 recurse into that group.
2486
2487
2488 =head2 A bit of magic: executing Perl code in a regular expression
2489
2490 Normally, regexps are a part of Perl expressions.
2491 I<Code evaluation> expressions turn that around by allowing
2492 arbitrary Perl code to be a part of a regexp.  A code evaluation
2493 expression is denoted C<(?{code})>, with I<code> a string of Perl
2494 statements.
2495
2496 Be warned that this feature is considered experimental, and may be
2497 changed without notice.
2498
2499 Code expressions are zero-width assertions, and the value they return
2500 depends on their environment.  There are two possibilities: either the
2501 code expression is used as a conditional in a conditional expression
2502 C<(?(condition)...)>, or it is not.  If the code expression is a
2503 conditional, the code is evaluated and the result (i.e., the result of
2504 the last statement) is used to determine truth or falsehood.  If the
2505 code expression is not used as a conditional, the assertion always
2506 evaluates true and the result is put into the special variable
2507 C<$^R>.  The variable C<$^R> can then be used in code expressions later
2508 in the regexp.  Here are some silly examples:
2509
2510     $x = "abcdef";
2511     $x =~ /abc(?{print "Hi Mom!";})def/; # matches,
2512                                          # prints 'Hi Mom!'
2513     $x =~ /aaa(?{print "Hi Mom!";})def/; # doesn't match,
2514                                          # no 'Hi Mom!'
2515
2516 Pay careful attention to the next example:
2517
2518     $x =~ /abc(?{print "Hi Mom!";})ddd/; # doesn't match,
2519                                          # no 'Hi Mom!'
2520                                          # but why not?
2521
2522 At first glance, you'd think that it shouldn't print, because obviously
2523 the C<ddd> isn't going to match the target string. But look at this
2524 example:
2525
2526     $x =~ /abc(?{print "Hi Mom!";})[dD]dd/; # doesn't match,
2527                                             # but _does_ print
2528
2529 Hmm. What happened here? If you've been following along, you know that
2530 the above pattern should be effectively (almost) the same as the last one;
2531 enclosing the C<d> in a character class isn't going to change what it
2532 matches. So why does the first not print while the second one does?
2533
2534 The answer lies in the optimizations the regex engine makes. In the first
2535 case, all the engine sees are plain old characters (aside from the
2536 C<?{}> construct). It's smart enough to realize that the string 'ddd'
2537 doesn't occur in our target string before actually running the pattern
2538 through. But in the second case, we've tricked it into thinking that our
2539 pattern is more complicated. It takes a look, sees our
2540 character class, and decides that it will have to actually run the
2541 pattern to determine whether or not it matches, and in the process of
2542 running it hits the print statement before it discovers that we don't
2543 have a match.
2544
2545 To take a closer look at how the engine does optimizations, see the
2546 section L<"Pragmas and debugging"> below.
2547
2548 More fun with C<?{}>:
2549
2550     $x =~ /(?{print "Hi Mom!";})/;       # matches,
2551                                          # prints 'Hi Mom!'
2552     $x =~ /(?{$c = 1;})(?{print "$c";})/;  # matches,
2553                                            # prints '1'
2554     $x =~ /(?{$c = 1;})(?{print "$^R";})/; # matches,
2555                                            # prints '1'
2556
2557 The bit of magic mentioned in the section title occurs when the regexp
2558 backtracks in the process of searching for a match.  If the regexp
2559 backtracks over a code expression and if the variables used within are
2560 localized using C<local>, the changes in the variables produced by the
2561 code expression are undone! Thus, if we wanted to count how many times
2562 a character got matched inside a group, we could use, e.g.,
2563
2564     $x = "aaaa";
2565     $count = 0;  # initialize 'a' count
2566     $c = "bob";  # test if $c gets clobbered
2567     $x =~ /(?{local $c = 0;})         # initialize count
2568            ( a                        # match 'a'
2569              (?{local $c = $c + 1;})  # increment count
2570            )*                         # do this any number of times,
2571            aa                         # but match 'aa' at the end
2572            (?{$count = $c;})          # copy local $c var into $count
2573           /x;
2574     print "'a' count is $count, \$c variable is '$c'\n";
2575
2576 This prints
2577
2578     'a' count is 2, $c variable is 'bob'
2579
2580 If we replace the S<C< (?{local $c = $c + 1;})>> with
2581 S<C< (?{$c = $c + 1;})>>, the variable changes are I<not> undone
2582 during backtracking, and we get
2583
2584     'a' count is 4, $c variable is 'bob'
2585
2586 Note that only localized variable changes are undone.  Other side
2587 effects of code expression execution are permanent.  Thus
2588
2589     $x = "aaaa";
2590     $x =~ /(a(?{print "Yow\n";}))*aa/;
2591
2592 produces
2593
2594    Yow
2595    Yow
2596    Yow
2597    Yow
2598
2599 The result C<$^R> is automatically localized, so that it will behave
2600 properly in the presence of backtracking.
2601
2602 This example uses a code expression in a conditional to match a
2603 definite article, either 'the' in English or 'der|die|das' in German:
2604
2605     $lang = 'DE';  # use German
2606     ...
2607     $text = "das";
2608     print "matched\n"
2609         if $text =~ /(?(?{
2610                           $lang eq 'EN'; # is the language English?
2611                          })
2612                        the |             # if so, then match 'the'
2613                        (der|die|das)     # else, match 'der|die|das'
2614                      )
2615                     /xi;
2616
2617 Note that the syntax here is C<(?(?{...})yes-regexp|no-regexp)>, not
2618 C<(?((?{...}))yes-regexp|no-regexp)>.  In other words, in the case of a
2619 code expression, we don't need the extra parentheses around the
2620 conditional.
2621
2622 If you try to use code expressions with interpolating variables, Perl
2623 may surprise you:
2624
2625     $bar = 5;
2626     $pat = '(?{ 1 })';
2627     /foo(?{ $bar })bar/; # compiles ok, $bar not interpolated
2628     /foo(?{ 1 })$bar/;   # compile error!
2629     /foo${pat}bar/;      # compile error!
2630
2631     $pat = qr/(?{ $foo = 1 })/;  # precompile code regexp
2632     /foo${pat}bar/;      # compiles ok
2633
2634 If a regexp has (1) code expressions and interpolating variables, or
2635 (2) a variable that interpolates a code expression, Perl treats the
2636 regexp as an error. If the code expression is precompiled into a
2637 variable, however, interpolating is ok. The question is, why is this
2638 an error?
2639
2640 The reason is that variable interpolation and code expressions
2641 together pose a security risk.  The combination is dangerous because
2642 many programmers who write search engines often take user input and
2643 plug it directly into a regexp:
2644
2645     $regexp = <>;       # read user-supplied regexp
2646     $chomp $regexp;     # get rid of possible newline
2647     $text =~ /$regexp/; # search $text for the $regexp
2648
2649 If the C<$regexp> variable contains a code expression, the user could
2650 then execute arbitrary Perl code.  For instance, some joker could
2651 search for S<C<system('rm -rf *');>> to erase your files.  In this
2652 sense, the combination of interpolation and code expressions I<taints>
2653 your regexp.  So by default, using both interpolation and code
2654 expressions in the same regexp is not allowed.  If you're not
2655 concerned about malicious users, it is possible to bypass this
2656 security check by invoking S<C<use re 'eval'>>:
2657
2658     use re 'eval';       # throw caution out the door
2659     $bar = 5;
2660     $pat = '(?{ 1 })';
2661     /foo(?{ 1 })$bar/;   # compiles ok
2662     /foo${pat}bar/;      # compiles ok
2663
2664 Another form of code expression is the I<pattern code expression>.
2665 The pattern code expression is like a regular code expression, except
2666 that the result of the code evaluation is treated as a regular
2667 expression and matched immediately.  A simple example is
2668
2669     $length = 5;
2670     $char = 'a';
2671     $x = 'aaaaabb';
2672     $x =~ /(??{$char x $length})/x; # matches, there are 5 of 'a'
2673
2674
2675 This final example contains both ordinary and pattern code
2676 expressions.  It detects whether a binary string C<1101010010001...> has a
2677 Fibonacci spacing 0,1,1,2,3,5,...  of the C<1>'s:
2678
2679     $x = "1101010010001000001";
2680     $z0 = ''; $z1 = '0';   # initial conditions
2681     print "It is a Fibonacci sequence\n"
2682         if $x =~ /^1         # match an initial '1'
2683                     (?:
2684                        ((??{ $z0 })) # match some '0'
2685                        1             # and then a '1'
2686                        (?{ $z0 = $z1; $z1 .= $^N; })
2687                     )+   # repeat as needed
2688                   $      # that is all there is
2689                  /x;
2690     printf "Largest sequence matched was %d\n", length($z1)-length($z0);
2691
2692 Remember that C<$^N> is set to whatever was matched by the last
2693 completed capture group. This prints
2694
2695     It is a Fibonacci sequence
2696     Largest sequence matched was 5
2697
2698 Ha! Try that with your garden variety regexp package...
2699
2700 Note that the variables C<$z0> and C<$z1> are not substituted when the
2701 regexp is compiled, as happens for ordinary variables outside a code
2702 expression.  Rather, the code expressions are evaluated when Perl
2703 encounters them during the search for a match.
2704
2705 The regexp without the C<//x> modifier is
2706
2707     /^1(?:((??{ $z0 }))1(?{ $z0 = $z1; $z1 .= $^N; }))+$/
2708
2709 which shows that spaces are still possible in the code parts. Nevertheless,
2710 when working with code and conditional expressions, the extended form of
2711 regexps is almost necessary in creating and debugging regexps.
2712
2713
2714 =head2 Backtracking control verbs
2715
2716 Perl 5.10 introduced a number of control verbs intended to provide
2717 detailed control over the backtracking process, by directly influencing
2718 the regexp engine and by providing monitoring techniques.  As all
2719 the features in this group are experimental and subject to change or
2720 removal in a future version of Perl, the interested reader is
2721 referred to L<perlre/"Special Backtracking Control Verbs"> for a
2722 detailed description.
2723
2724 Below is just one example, illustrating the control verb C<(*FAIL)>,
2725 which may be abbreviated as C<(*F)>. If this is inserted in a regexp
2726 it will cause it to fail, just as it would at some
2727 mismatch between the pattern and the string. Processing
2728 of the regexp continues as it would after any "normal"
2729 failure, so that, for instance, the next position in the string or another
2730 alternative will be tried. As failing to match doesn't preserve capture
2731 groups or produce results, it may be necessary to use this in
2732 combination with embedded code.
2733
2734    %count = ();
2735    "supercalifragilisticexpialidoceous" =~
2736        /([aeiou])(?{ $count{$1}++; })(*FAIL)/i;
2737    printf "%3d '%s'\n", $count{$_}, $_ for (sort keys %count);
2738
2739 The pattern begins with a class matching a subset of letters.  Whenever
2740 this matches, a statement like C<$count{'a'}++;> is executed, incrementing
2741 the letter's counter. Then C<(*FAIL)> does what it says, and
2742 the regexp engine proceeds according to the book: as long as the end of
2743 the string hasn't been reached, the position is advanced before looking
2744 for another vowel. Thus, match or no match makes no difference, and the
2745 regexp engine proceeds until the entire string has been inspected.
2746 (It's remarkable that an alternative solution using something like
2747
2748    $count{lc($_)}++ for split('', "supercalifragilisticexpialidoceous");
2749    printf "%3d '%s'\n", $count2{$_}, $_ for ( qw{ a e i o u } );
2750
2751 is considerably slower.)
2752
2753
2754 =head2 Pragmas and debugging
2755
2756 Speaking of debugging, there are several pragmas available to control
2757 and debug regexps in Perl.  We have already encountered one pragma in
2758 the previous section, S<C<use re 'eval';>>, that allows variable
2759 interpolation and code expressions to coexist in a regexp.  The other
2760 pragmas are
2761
2762     use re 'taint';
2763     $tainted = <>;
2764     @parts = ($tainted =~ /(\w+)\s+(\w+)/; # @parts is now tainted
2765
2766 The C<taint> pragma causes any substrings from a match with a tainted
2767 variable to be tainted as well.  This is not normally the case, as
2768 regexps are often used to extract the safe bits from a tainted
2769 variable.  Use C<taint> when you are not extracting safe bits, but are
2770 performing some other processing.  Both C<taint> and C<eval> pragmas
2771 are lexically scoped, which means they are in effect only until
2772 the end of the block enclosing the pragmas.
2773
2774     use re '/m';  # or any other flags
2775     $multiline_string =~ /^foo/; # /m is implied
2776
2777 The C<re '/flags'> pragma (introduced in Perl
2778 5.14) turns on the given regular expression flags
2779 until the end of the lexical scope.  See C<re/"'/flags' mode"> for more
2780 detail.
2781
2782     use re 'debug';
2783     /^(.*)$/s;       # output debugging info
2784
2785     use re 'debugcolor';
2786     /^(.*)$/s;       # output debugging info in living color
2787
2788 The global C<debug> and C<debugcolor> pragmas allow one to get
2789 detailed debugging info about regexp compilation and
2790 execution.  C<debugcolor> is the same as debug, except the debugging
2791 information is displayed in color on terminals that can display
2792 termcap color sequences.  Here is example output:
2793
2794     % perl -e 'use re "debug"; "abc" =~ /a*b+c/;'
2795     Compiling REx `a*b+c'
2796     size 9 first at 1
2797        1: STAR(4)
2798        2:   EXACT <a>(0)
2799        4: PLUS(7)
2800        5:   EXACT <b>(0)
2801        7: EXACT <c>(9)
2802        9: END(0)
2803     floating `bc' at 0..2147483647 (checking floating) minlen 2
2804     Guessing start of match, REx `a*b+c' against `abc'...
2805     Found floating substr `bc' at offset 1...
2806     Guessed: match at offset 0
2807     Matching REx `a*b+c' against `abc'
2808       Setting an EVAL scope, savestack=3
2809        0 <> <abc>             |  1:  STAR
2810                                EXACT <a> can match 1 times out of 32767...
2811       Setting an EVAL scope, savestack=3
2812        1 <a> <bc>             |  4:    PLUS
2813                                EXACT <b> can match 1 times out of 32767...
2814       Setting an EVAL scope, savestack=3
2815        2 <ab> <c>             |  7:      EXACT <c>
2816        3 <abc> <>             |  9:      END
2817     Match successful!
2818     Freeing REx: `a*b+c'
2819
2820 If you have gotten this far into the tutorial, you can probably guess
2821 what the different parts of the debugging output tell you.  The first
2822 part
2823
2824     Compiling REx `a*b+c'
2825     size 9 first at 1
2826        1: STAR(4)
2827        2:   EXACT <a>(0)
2828        4: PLUS(7)
2829        5:   EXACT <b>(0)
2830        7: EXACT <c>(9)
2831        9: END(0)
2832
2833 describes the compilation stage.  C<STAR(4)> means that there is a
2834 starred object, in this case C<'a'>, and if it matches, goto line 4,
2835 i.e., C<PLUS(7)>.  The middle lines describe some heuristics and
2836 optimizations performed before a match:
2837
2838     floating `bc' at 0..2147483647 (checking floating) minlen 2
2839     Guessing start of match, REx `a*b+c' against `abc'...
2840     Found floating substr `bc' at offset 1...
2841     Guessed: match at offset 0
2842
2843 Then the match is executed and the remaining lines describe the
2844 process:
2845
2846     Matching REx `a*b+c' against `abc'
2847       Setting an EVAL scope, savestack=3
2848        0 <> <abc>             |  1:  STAR
2849                                EXACT <a> can match 1 times out of 32767...
2850       Setting an EVAL scope, savestack=3
2851        1 <a> <bc>             |  4:    PLUS
2852                                EXACT <b> can match 1 times out of 32767...
2853       Setting an EVAL scope, savestack=3
2854        2 <ab> <c>             |  7:      EXACT <c>
2855        3 <abc> <>             |  9:      END
2856     Match successful!
2857     Freeing REx: `a*b+c'
2858
2859 Each step is of the form S<C<< n <x> <y> >>>, with C<< <x> >> the
2860 part of the string matched and C<< <y> >> the part not yet
2861 matched.  The S<C<< |  1:  STAR >>> says that Perl is at line number 1
2862 in the compilation list above.  See
2863 L<perldebguts/"Debugging Regular Expressions"> for much more detail.
2864
2865 An alternative method of debugging regexps is to embed C<print>
2866 statements within the regexp.  This provides a blow-by-blow account of
2867 the backtracking in an alternation:
2868
2869     "that this" =~ m@(?{print "Start at position ", pos, "\n";})
2870                      t(?{print "t1\n";})
2871                      h(?{print "h1\n";})
2872                      i(?{print "i1\n";})
2873                      s(?{print "s1\n";})
2874                          |
2875                      t(?{print "t2\n";})
2876                      h(?{print "h2\n";})
2877                      a(?{print "a2\n";})
2878                      t(?{print "t2\n";})
2879                      (?{print "Done at position ", pos, "\n";})
2880                     @x;
2881
2882 prints
2883
2884     Start at position 0
2885     t1
2886     h1
2887     t2
2888     h2
2889     a2
2890     t2
2891     Done at position 4
2892
2893 =head1 BUGS
2894
2895 Code expressions, conditional expressions, and independent expressions
2896 are I<experimental>.  Don't use them in production code.  Yet.
2897
2898 =head1 SEE ALSO
2899
2900 This is just a tutorial.  For the full story on Perl regular
2901 expressions, see the L<perlre> regular expressions reference page.
2902
2903 For more information on the matching C<m//> and substitution C<s///>
2904 operators, see L<perlop/"Regexp Quote-Like Operators">.  For
2905 information on the C<split> operation, see L<perlfunc/split>.
2906
2907 For an excellent all-around resource on the care and feeding of
2908 regular expressions, see the book I<Mastering Regular Expressions> by
2909 Jeffrey Friedl (published by O'Reilly, ISBN 1556592-257-3).
2910
2911 =head1 AUTHOR AND COPYRIGHT
2912
2913 Copyright (c) 2000 Mark Kvale
2914 All rights reserved.
2915
2916 This document may be distributed under the same terms as Perl itself.
2917
2918 =head2 Acknowledgments
2919
2920 The inspiration for the stop codon DNA example came from the ZIP
2921 code example in chapter 7 of I<Mastering Regular Expressions>.
2922
2923 The author would like to thank Jeff Pinyan, Andrew Johnson, Peter
2924 Haworth, Ronald J Kimball, and Joe Smith for all their helpful
2925 comments.
2926
2927 =cut
2928