Create perldelta for 5.14.3
[perl.git] / pod / perlfunc.pod
1 =head1 NAME
2 X<function>
3
4 perlfunc - Perl builtin functions
5
6 =head1 DESCRIPTION
7
8 The functions in this section can serve as terms in an expression.
9 They fall into two major categories: list operators and named unary
10 operators.  These differ in their precedence relationship with a
11 following comma.  (See the precedence table in L<perlop>.)  List
12 operators take more than one argument, while unary operators can never
13 take more than one argument.  Thus, a comma terminates the argument of
14 a unary operator, but merely separates the arguments of a list
15 operator.  A unary operator generally provides scalar context to its
16 argument, while a list operator may provide either scalar or list
17 contexts for its arguments.  If it does both, scalar arguments 
18 come first and list argument follow, and there can only ever
19 be one such list argument.  For instance, splice() has three scalar
20 arguments followed by a list, whereas gethostbyname() has four scalar
21 arguments.
22
23 In the syntax descriptions that follow, list operators that expect a
24 list (and provide list context for elements of the list) are shown
25 with LIST as an argument.  Such a list may consist of any combination
26 of scalar arguments or list values; the list values will be included
27 in the list as if each individual element were interpolated at that
28 point in the list, forming a longer single-dimensional list value.
29 Commas should separate literal elements of the LIST.
30
31 Any function in the list below may be used either with or without
32 parentheses around its arguments.  (The syntax descriptions omit the
33 parentheses.)  If you use parentheses, the simple but occasionally 
34 surprising rule is this: It I<looks> like a function, therefore it I<is> a
35 function, and precedence doesn't matter.  Otherwise it's a list
36 operator or unary operator, and precedence does matter.  Whitespace
37 between the function and left parenthesis doesn't count, so sometimes
38 you need to be careful:
39
40     print 1+2+4;      # Prints 7.
41     print(1+2) + 4;   # Prints 3.
42     print (1+2)+4;    # Also prints 3!
43     print +(1+2)+4;   # Prints 7.
44     print ((1+2)+4);  # Prints 7.
45
46 If you run Perl with the B<-w> switch it can warn you about this.  For
47 example, the third line above produces:
48
49     print (...) interpreted as function at - line 1.
50     Useless use of integer addition in void context at - line 1.
51
52 A few functions take no arguments at all, and therefore work as neither
53 unary nor list operators.  These include such functions as C<time>
54 and C<endpwent>.  For example, C<time+86_400> always means
55 C<time() + 86_400>.
56
57 For functions that can be used in either a scalar or list context,
58 nonabortive failure is generally indicated in scalar context by
59 returning the undefined value, and in list context by returning the
60 empty list.
61
62 Remember the following important rule: There is B<no rule> that relates
63 the behavior of an expression in list context to its behavior in scalar
64 context, or vice versa.  It might do two totally different things.
65 Each operator and function decides which sort of value would be most
66 appropriate to return in scalar context.  Some operators return the
67 length of the list that would have been returned in list context.  Some
68 operators return the first value in the list.  Some operators return the
69 last value in the list.  Some operators return a count of successful
70 operations.  In general, they do what you want, unless you want
71 consistency.
72 X<context>
73
74 A named array in scalar context is quite different from what would at
75 first glance appear to be a list in scalar context.  You can't get a list
76 like C<(1,2,3)> into being in scalar context, because the compiler knows
77 the context at compile time.  It would generate the scalar comma operator
78 there, not the list construction version of the comma.  That means it
79 was never a list to start with.
80
81 In general, functions in Perl that serve as wrappers for system calls ("syscalls")
82 of the same name (like chown(2), fork(2), closedir(2), etc.) return
83 true when they succeed and C<undef> otherwise, as is usually mentioned
84 in the descriptions below.  This is different from the C interfaces,
85 which return C<-1> on failure.  Exceptions to this rule include C<wait>,
86 C<waitpid>, and C<syscall>.  System calls also set the special C<$!>
87 variable on failure.  Other functions do not, except accidentally.
88
89 Extension modules can also hook into the Perl parser to define new
90 kinds of keyword-headed expression.  These may look like functions, but
91 may also look completely different.  The syntax following the keyword
92 is defined entirely by the extension.  If you are an implementor, see
93 L<perlapi/PL_keyword_plugin> for the mechanism.  If you are using such
94 a module, see the module's documentation for details of the syntax that
95 it defines.
96
97 =head2 Perl Functions by Category
98 X<function>
99
100 Here are Perl's functions (including things that look like
101 functions, like some keywords and named operators)
102 arranged by category.  Some functions appear in more
103 than one place.
104
105 =over 4
106
107 =item Functions for SCALARs or strings
108 X<scalar> X<string> X<character>
109
110 C<chomp>, C<chop>, C<chr>, C<crypt>, C<hex>, C<index>, C<lc>, C<lcfirst>,
111 C<length>, C<oct>, C<ord>, C<pack>, C<q//>, C<qq//>, C<reverse>,
112 C<rindex>, C<sprintf>, C<substr>, C<tr///>, C<uc>, C<ucfirst>, C<y///>
113
114 =item Regular expressions and pattern matching
115 X<regular expression> X<regex> X<regexp>
116
117 C<m//>, C<pos>, C<quotemeta>, C<s///>, C<split>, C<study>, C<qr//>
118
119 =item Numeric functions
120 X<numeric> X<number> X<trigonometric> X<trigonometry>
121
122 C<abs>, C<atan2>, C<cos>, C<exp>, C<hex>, C<int>, C<log>, C<oct>, C<rand>,
123 C<sin>, C<sqrt>, C<srand>
124
125 =item Functions for real @ARRAYs
126 X<array>
127
128 C<each>, C<keys>, C<pop>, C<push>, C<shift>, C<splice>, C<unshift>, C<values>
129
130 =item Functions for list data
131 X<list>
132
133 C<grep>, C<join>, C<map>, C<qw//>, C<reverse>, C<sort>, C<unpack>
134
135 =item Functions for real %HASHes
136 X<hash>
137
138 C<delete>, C<each>, C<exists>, C<keys>, C<values>
139
140 =item Input and output functions
141 X<I/O> X<input> X<output> X<dbm>
142
143 C<binmode>, C<close>, C<closedir>, C<dbmclose>, C<dbmopen>, C<die>, C<eof>,
144 C<fileno>, C<flock>, C<format>, C<getc>, C<print>, C<printf>, C<read>,
145 C<readdir>, C<rewinddir>, C<say>, C<seek>, C<seekdir>, C<select>, C<syscall>,
146 C<sysread>, C<sysseek>, C<syswrite>, C<tell>, C<telldir>, C<truncate>,
147 C<warn>, C<write>
148
149 =item Functions for fixed-length data or records
150
151 C<pack>, C<read>, C<syscall>, C<sysread>, C<syswrite>, C<unpack>, C<vec>
152
153 =item Functions for filehandles, files, or directories
154 X<file> X<filehandle> X<directory> X<pipe> X<link> X<symlink>
155
156 C<-I<X>>, C<chdir>, C<chmod>, C<chown>, C<chroot>, C<fcntl>, C<glob>,
157 C<ioctl>, C<link>, C<lstat>, C<mkdir>, C<open>, C<opendir>,
158 C<readlink>, C<rename>, C<rmdir>, C<stat>, C<symlink>, C<sysopen>,
159 C<umask>, C<unlink>, C<utime>
160
161 =item Keywords related to the control flow of your Perl program
162 X<control flow>
163
164 C<caller>, C<continue>, C<die>, C<do>, C<dump>, C<eval>, C<exit>,
165 C<goto>, C<last>, C<next>, C<redo>, C<return>, C<sub>, C<wantarray>
166
167 =item Keywords related to the switch feature
168
169 C<break>, C<continue>, C<default, >C<given>, C<when>
170
171 These are available only if you enable the C<"switch"> feature.
172 See L<feature> and L<perlsyn/"Switch statements">.  
173 Alternately, include a C<use v5.10> or later to the current scope.
174
175 =item Keywords related to scoping
176
177 C<caller>, C<import>, C<local>, C<my>, C<our>, C<package>, C<state>, C<use>
178
179 C<state> is available only if the C<"state"> feature is enabled. See
180 L<feature>.  Alternately, include a C<use v5.10> or later to the current scope.
181
182 =item Miscellaneous functions
183
184 C<defined>, C<dump>, C<eval>, C<formline>, C<local>, C<my>, C<our>,
185 C<reset>, C<scalar>, C<state>, C<undef>, C<wantarray>
186
187 =item Functions for processes and process groups
188 X<process> X<pid> X<process id>
189
190 C<alarm>, C<exec>, C<fork>, C<getpgrp>, C<getppid>, C<getpriority>, C<kill>,
191 C<pipe>, C<qx//>, C<setpgrp>, C<setpriority>, C<sleep>, C<system>,
192 C<times>, C<wait>, C<waitpid>
193
194 =item Keywords related to Perl modules
195 X<module>
196
197 C<do>, C<import>, C<no>, C<package>, C<require>, C<use>
198
199 =item Keywords related to classes and object-orientation
200 X<object> X<class> X<package>
201
202 C<bless>, C<dbmclose>, C<dbmopen>, C<package>, C<ref>, C<tie>, C<tied>,
203 C<untie>, C<use>
204
205 =item Low-level socket functions
206 X<socket> X<sock>
207
208 C<accept>, C<bind>, C<connect>, C<getpeername>, C<getsockname>,
209 C<getsockopt>, C<listen>, C<recv>, C<send>, C<setsockopt>, C<shutdown>,
210 C<socket>, C<socketpair>
211
212 =item System V interprocess communication functions
213 X<IPC> X<System V> X<semaphore> X<shared memory> X<memory> X<message>
214
215 C<msgctl>, C<msgget>, C<msgrcv>, C<msgsnd>, C<semctl>, C<semget>, C<semop>,
216 C<shmctl>, C<shmget>, C<shmread>, C<shmwrite>
217
218 =item Fetching user and group info
219 X<user> X<group> X<password> X<uid> X<gid>  X<passwd> X</etc/passwd>
220
221 C<endgrent>, C<endhostent>, C<endnetent>, C<endpwent>, C<getgrent>,
222 C<getgrgid>, C<getgrnam>, C<getlogin>, C<getpwent>, C<getpwnam>,
223 C<getpwuid>, C<setgrent>, C<setpwent>
224
225 =item Fetching network info
226 X<network> X<protocol> X<host> X<hostname> X<IP> X<address> X<service>
227
228 C<endprotoent>, C<endservent>, C<gethostbyaddr>, C<gethostbyname>,
229 C<gethostent>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
230 C<getprotobyname>, C<getprotobynumber>, C<getprotoent>,
231 C<getservbyname>, C<getservbyport>, C<getservent>, C<sethostent>,
232 C<setnetent>, C<setprotoent>, C<setservent>
233
234 =item Time-related functions
235 X<time> X<date>
236
237 C<gmtime>, C<localtime>, C<time>, C<times>
238
239 =item Functions new in perl5
240 X<perl5>
241
242 C<abs>, C<bless>, C<break>, C<chomp>, C<chr>, C<continue>, C<default>, 
243 C<exists>, C<formline>, C<given>, C<glob>, C<import>, C<lc>, C<lcfirst>,
244 C<lock>, C<map>, C<my>, C<no>, C<our>, C<prototype>, C<qr//>, C<qw//>, C<qx//>,
245 C<readline>, C<readpipe>, C<ref>, C<sub>*, C<sysopen>, C<tie>, C<tied>, C<uc>,
246 C<ucfirst>, C<untie>, C<use>, C<when>
247
248 * C<sub> was a keyword in Perl 4, but in Perl 5 it is an
249 operator, which can be used in expressions.
250
251 =item Functions obsoleted in perl5
252
253 C<dbmclose>, C<dbmopen>
254
255 =back
256
257 =head2 Portability
258 X<portability> X<Unix> X<portable>
259
260 Perl was born in Unix and can therefore access all common Unix
261 system calls.  In non-Unix environments, the functionality of some
262 Unix system calls may not be available or details of the available
263 functionality may differ slightly.  The Perl functions affected
264 by this are:
265
266 C<-X>, C<binmode>, C<chmod>, C<chown>, C<chroot>, C<crypt>,
267 C<dbmclose>, C<dbmopen>, C<dump>, C<endgrent>, C<endhostent>,
268 C<endnetent>, C<endprotoent>, C<endpwent>, C<endservent>, C<exec>,
269 C<fcntl>, C<flock>, C<fork>, C<getgrent>, C<getgrgid>, C<gethostbyname>,
270 C<gethostent>, C<getlogin>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
271 C<getppid>, C<getpgrp>, C<getpriority>, C<getprotobynumber>,
272 C<getprotoent>, C<getpwent>, C<getpwnam>, C<getpwuid>,
273 C<getservbyport>, C<getservent>, C<getsockopt>, C<glob>, C<ioctl>,
274 C<kill>, C<link>, C<lstat>, C<msgctl>, C<msgget>, C<msgrcv>,
275 C<msgsnd>, C<open>, C<pipe>, C<readlink>, C<rename>, C<select>, C<semctl>,
276 C<semget>, C<semop>, C<setgrent>, C<sethostent>, C<setnetent>,
277 C<setpgrp>, C<setpriority>, C<setprotoent>, C<setpwent>,
278 C<setservent>, C<setsockopt>, C<shmctl>, C<shmget>, C<shmread>,
279 C<shmwrite>, C<socket>, C<socketpair>,
280 C<stat>, C<symlink>, C<syscall>, C<sysopen>, C<system>,
281 C<times>, C<truncate>, C<umask>, C<unlink>,
282 C<utime>, C<wait>, C<waitpid>
283
284 For more information about the portability of these functions, see
285 L<perlport> and other available platform-specific documentation.
286
287 =head2 Alphabetical Listing of Perl Functions
288
289 =over 
290
291 =item -X FILEHANDLE
292 X<-r>X<-w>X<-x>X<-o>X<-R>X<-W>X<-X>X<-O>X<-e>X<-z>X<-s>X<-f>X<-d>X<-l>X<-p>
293 X<-S>X<-b>X<-c>X<-t>X<-u>X<-g>X<-k>X<-T>X<-B>X<-M>X<-A>X<-C>
294
295 =item -X EXPR
296
297 =item -X DIRHANDLE
298
299 =item -X
300
301 A file test, where X is one of the letters listed below.  This unary
302 operator takes one argument, either a filename, a filehandle, or a dirhandle, 
303 and tests the associated file to see if something is true about it.  If the
304 argument is omitted, tests C<$_>, except for C<-t>, which tests STDIN.
305 Unless otherwise documented, it returns C<1> for true and C<''> for false, or
306 the undefined value if the file doesn't exist.  Despite the funny
307 names, precedence is the same as any other named unary operator.  The
308 operator may be any of:
309
310     -r  File is readable by effective uid/gid.
311     -w  File is writable by effective uid/gid.
312     -x  File is executable by effective uid/gid.
313     -o  File is owned by effective uid.
314
315     -R  File is readable by real uid/gid.
316     -W  File is writable by real uid/gid.
317     -X  File is executable by real uid/gid.
318     -O  File is owned by real uid.
319
320     -e  File exists.
321     -z  File has zero size (is empty).
322     -s  File has nonzero size (returns size in bytes).
323
324     -f  File is a plain file.
325     -d  File is a directory.
326     -l  File is a symbolic link.
327     -p  File is a named pipe (FIFO), or Filehandle is a pipe.
328     -S  File is a socket.
329     -b  File is a block special file.
330     -c  File is a character special file.
331     -t  Filehandle is opened to a tty.
332
333     -u  File has setuid bit set.
334     -g  File has setgid bit set.
335     -k  File has sticky bit set.
336
337     -T  File is an ASCII text file (heuristic guess).
338     -B  File is a "binary" file (opposite of -T).
339
340     -M  Script start time minus file modification time, in days.
341     -A  Same for access time.
342     -C  Same for inode change time (Unix, may differ for other platforms)
343
344 Example:
345
346     while (<>) {
347         chomp;
348         next unless -f $_;  # ignore specials
349         #...
350     }
351
352 Note that C<-s/a/b/> does not do a negated substitution.  Saying
353 C<-exp($foo)> still works as expected, however: only single letters
354 following a minus are interpreted as file tests.
355
356 These operators are exempt from the "looks like a function rule" described
357 above. That is, an opening parenthesis after the operator does not affect
358 how much of the following code constitutes the argument. Put the opening
359 parentheses before the operator to separate it from code that follows (this
360 applies only to operators with higher precedence than unary operators, of
361 course):
362
363     -s($file) + 1024   # probably wrong; same as -s($file + 1024)
364     (-s $file) + 1024  # correct
365
366 The interpretation of the file permission operators C<-r>, C<-R>,
367 C<-w>, C<-W>, C<-x>, and C<-X> is by default based solely on the mode
368 of the file and the uids and gids of the user.  There may be other
369 reasons you can't actually read, write, or execute the file: for
370 example network filesystem access controls, ACLs (access control lists),
371 read-only filesystems, and unrecognized executable formats.  Note
372 that the use of these six specific operators to verify if some operation
373 is possible is usually a mistake, because it may be open to race
374 conditions.
375
376 Also note that, for the superuser on the local filesystems, the C<-r>,
377 C<-R>, C<-w>, and C<-W> tests always return 1, and C<-x> and C<-X> return 1
378 if any execute bit is set in the mode.  Scripts run by the superuser
379 may thus need to do a stat() to determine the actual mode of the file,
380 or temporarily set their effective uid to something else.
381
382 If you are using ACLs, there is a pragma called C<filetest> that may
383 produce more accurate results than the bare stat() mode bits.
384 When under C<use filetest 'access'> the above-mentioned filetests
385 test whether the permission can(not) be granted using the
386 access(2) family of system calls.  Also note that the C<-x> and C<-X> may
387 under this pragma return true even if there are no execute permission
388 bits set (nor any extra execute permission ACLs).  This strangeness is
389 due to the underlying system calls' definitions. Note also that, due to
390 the implementation of C<use filetest 'access'>, the C<_> special
391 filehandle won't cache the results of the file tests when this pragma is
392 in effect.  Read the documentation for the C<filetest> pragma for more
393 information.
394
395 The C<-T> and C<-B> switches work as follows.  The first block or so of the
396 file is examined for odd characters such as strange control codes or
397 characters with the high bit set.  If too many strange characters (>30%)
398 are found, it's a C<-B> file; otherwise it's a C<-T> file.  Also, any file
399 containing a zero byte in the first block is considered a binary file.  If C<-T>
400 or C<-B> is used on a filehandle, the current IO buffer is examined
401 rather than the first block.  Both C<-T> and C<-B> return true on an empty
402 file, or a file at EOF when testing a filehandle.  Because you have to
403 read a file to do the C<-T> test, on most occasions you want to use a C<-f>
404 against the file first, as in C<next unless -f $file && -T $file>.
405
406 If any of the file tests (or either the C<stat> or C<lstat> operator) is given
407 the special filehandle consisting of a solitary underline, then the stat
408 structure of the previous file test (or stat operator) is used, saving
409 a system call.  (This doesn't work with C<-t>, and you need to remember
410 that lstat() and C<-l> leave values in the stat structure for the
411 symbolic link, not the real file.)  (Also, if the stat buffer was filled by
412 an C<lstat> call, C<-T> and C<-B> will reset it with the results of C<stat _>).
413 Example:
414
415     print "Can do.\n" if -r $a || -w _ || -x _;
416
417     stat($filename);
418     print "Readable\n" if -r _;
419     print "Writable\n" if -w _;
420     print "Executable\n" if -x _;
421     print "Setuid\n" if -u _;
422     print "Setgid\n" if -g _;
423     print "Sticky\n" if -k _;
424     print "Text\n" if -T _;
425     print "Binary\n" if -B _;
426
427 As of Perl 5.9.1, as a form of purely syntactic sugar, you can stack file
428 test operators, in a way that C<-f -w -x $file> is equivalent to
429 C<-x $file && -w _ && -f _>. (This is only fancy fancy: if you use
430 the return value of C<-f $file> as an argument to another filetest
431 operator, no special magic will happen.)
432
433 =item abs VALUE
434 X<abs> X<absolute>
435
436 =item abs
437
438 Returns the absolute value of its argument.
439 If VALUE is omitted, uses C<$_>.
440
441 =item accept NEWSOCKET,GENERICSOCKET
442 X<accept>
443
444 Accepts an incoming socket connect, just as accept(2) 
445 does.  Returns the packed address if it succeeded, false otherwise.
446 See the example in L<perlipc/"Sockets: Client/Server Communication">.
447
448 On systems that support a close-on-exec flag on files, the flag will
449 be set for the newly opened file descriptor, as determined by the
450 value of $^F.  See L<perlvar/$^F>.
451
452 =item alarm SECONDS
453 X<alarm>
454 X<SIGALRM>
455 X<timer>
456
457 =item alarm
458
459 Arranges to have a SIGALRM delivered to this process after the
460 specified number of wallclock seconds has elapsed.  If SECONDS is not
461 specified, the value stored in C<$_> is used. (On some machines,
462 unfortunately, the elapsed time may be up to one second less or more
463 than you specified because of how seconds are counted, and process
464 scheduling may delay the delivery of the signal even further.)
465
466 Only one timer may be counting at once.  Each call disables the
467 previous timer, and an argument of C<0> may be supplied to cancel the
468 previous timer without starting a new one.  The returned value is the
469 amount of time remaining on the previous timer.
470
471 For delays of finer granularity than one second, the Time::HiRes module
472 (from CPAN, and starting from Perl 5.8 part of the standard
473 distribution) provides ualarm().  You may also use Perl's four-argument
474 version of select() leaving the first three arguments undefined, or you
475 might be able to use the C<syscall> interface to access setitimer(2) if
476 your system supports it. See L<perlfaq8> for details.
477
478 It is usually a mistake to intermix C<alarm> and C<sleep> calls, because
479 C<sleep> may be internally implemented on your system with C<alarm>.
480
481 If you want to use C<alarm> to time out a system call you need to use an
482 C<eval>/C<die> pair.  You can't rely on the alarm causing the system call to
483 fail with C<$!> set to C<EINTR> because Perl sets up signal handlers to
484 restart system calls on some systems.  Using C<eval>/C<die> always works,
485 modulo the caveats given in L<perlipc/"Signals">.
486
487     eval {
488         local $SIG{ALRM} = sub { die "alarm\n" }; # NB: \n required
489         alarm $timeout;
490         $nread = sysread SOCKET, $buffer, $size;
491         alarm 0;
492     };
493     if ($@) {
494         die unless $@ eq "alarm\n";   # propagate unexpected errors
495         # timed out
496     }
497     else {
498         # didn't
499     }
500
501 For more information see L<perlipc>.
502
503 =item atan2 Y,X
504 X<atan2> X<arctangent> X<tan> X<tangent>
505
506 Returns the arctangent of Y/X in the range -PI to PI.
507
508 For the tangent operation, you may use the C<Math::Trig::tan>
509 function, or use the familiar relation:
510
511     sub tan { sin($_[0]) / cos($_[0])  }
512
513 The return value for C<atan2(0,0)> is implementation-defined; consult
514 your atan2(3) manpage for more information.
515
516 =item bind SOCKET,NAME
517 X<bind>
518
519 Binds a network address to a socket, just as bind(2)
520 does.  Returns true if it succeeded, false otherwise.  NAME should be a
521 packed address of the appropriate type for the socket.  See the examples in
522 L<perlipc/"Sockets: Client/Server Communication">.
523
524 =item binmode FILEHANDLE, LAYER
525 X<binmode> X<binary> X<text> X<DOS> X<Windows>
526
527 =item binmode FILEHANDLE
528
529 Arranges for FILEHANDLE to be read or written in "binary" or "text"
530 mode on systems where the run-time libraries distinguish between
531 binary and text files.  If FILEHANDLE is an expression, the value is
532 taken as the name of the filehandle.  Returns true on success,
533 otherwise it returns C<undef> and sets C<$!> (errno).
534
535 On some systems (in general, DOS- and Windows-based systems) binmode()
536 is necessary when you're not working with a text file.  For the sake
537 of portability it is a good idea always to use it when appropriate,
538 and never to use it when it isn't appropriate.  Also, people can
539 set their I/O to be by default UTF8-encoded Unicode, not bytes.
540
541 In other words: regardless of platform, use binmode() on binary data,
542 like images, for example.
543
544 If LAYER is present it is a single string, but may contain multiple
545 directives. The directives alter the behaviour of the filehandle.
546 When LAYER is present, using binmode on a text file makes sense.
547
548 If LAYER is omitted or specified as C<:raw> the filehandle is made
549 suitable for passing binary data. This includes turning off possible CRLF
550 translation and marking it as bytes (as opposed to Unicode characters).
551 Note that, despite what may be implied in I<"Programming Perl"> (the
552 Camel, 3rd edition) or elsewhere, C<:raw> is I<not> simply the inverse of C<:crlf>.
553 Other layers that would affect the binary nature of the stream are
554 I<also> disabled. See L<PerlIO>, L<perlrun>, and the discussion about the
555 PERLIO environment variable.
556
557 The C<:bytes>, C<:crlf>, C<:utf8>, and any other directives of the
558 form C<:...>, are called I/O I<layers>.  The C<open> pragma can be used to
559 establish default I/O layers.  See L<open>.
560
561 I<The LAYER parameter of the binmode() function is described as "DISCIPLINE"
562 in "Programming Perl, 3rd Edition".  However, since the publishing of this
563 book, by many known as "Camel III", the consensus of the naming of this
564 functionality has moved from "discipline" to "layer".  All documentation
565 of this version of Perl therefore refers to "layers" rather than to
566 "disciplines".  Now back to the regularly scheduled documentation...>
567
568 To mark FILEHANDLE as UTF-8, use C<:utf8> or C<:encoding(UTF-8)>.
569 C<:utf8> just marks the data as UTF-8 without further checking,
570 while C<:encoding(UTF-8)> checks the data for actually being valid
571 UTF-8. More details can be found in L<PerlIO::encoding>.
572
573 In general, binmode() should be called after open() but before any I/O
574 is done on the filehandle.  Calling binmode() normally flushes any
575 pending buffered output data (and perhaps pending input data) on the
576 handle.  An exception to this is the C<:encoding> layer that
577 changes the default character encoding of the handle; see L</open>.
578 The C<:encoding> layer sometimes needs to be called in
579 mid-stream, and it doesn't flush the stream.  The C<:encoding>
580 also implicitly pushes on top of itself the C<:utf8> layer because
581 internally Perl operates on UTF8-encoded Unicode characters.
582
583 The operating system, device drivers, C libraries, and Perl run-time
584 system all conspire to let the programmer treat a single
585 character (C<\n>) as the line terminator, irrespective of external
586 representation.  On many operating systems, the native text file
587 representation matches the internal representation, but on some
588 platforms the external representation of C<\n> is made up of more than
589 one character.
590
591 All variants of Unix, Mac OS (old and new), and Stream_LF files on VMS use
592 a single character to end each line in the external representation of text
593 (even though that single character is CARRIAGE RETURN on old, pre-Darwin
594 flavors of Mac OS, and is LINE FEED on Unix and most VMS files). In other
595 systems like OS/2, DOS, and the various flavors of MS-Windows, your program
596 sees a C<\n> as a simple C<\cJ>, but what's stored in text files are the
597 two characters C<\cM\cJ>.  That means that if you don't use binmode() on
598 these systems, C<\cM\cJ> sequences on disk will be converted to C<\n> on
599 input, and any C<\n> in your program will be converted back to C<\cM\cJ> on
600 output.  This is what you want for text files, but it can be disastrous for
601 binary files.
602
603 Another consequence of using binmode() (on some systems) is that
604 special end-of-file markers will be seen as part of the data stream.
605 For systems from the Microsoft family this means that, if your binary
606 data contain C<\cZ>, the I/O subsystem will regard it as the end of
607 the file, unless you use binmode().
608
609 binmode() is important not only for readline() and print() operations,
610 but also when using read(), seek(), sysread(), syswrite() and tell()
611 (see L<perlport> for more details).  See the C<$/> and C<$\> variables
612 in L<perlvar> for how to manually set your input and output
613 line-termination sequences.
614
615 =item bless REF,CLASSNAME
616 X<bless>
617
618 =item bless REF
619
620 This function tells the thingy referenced by REF that it is now an object
621 in the CLASSNAME package.  If CLASSNAME is omitted, the current package
622 is used.  Because a C<bless> is often the last thing in a constructor,
623 it returns the reference for convenience.  Always use the two-argument
624 version if a derived class might inherit the function doing the blessing.
625 See L<perltoot> and L<perlobj> for more about the blessing (and blessings)
626 of objects.
627
628 Consider always blessing objects in CLASSNAMEs that are mixed case.
629 Namespaces with all lowercase names are considered reserved for
630 Perl pragmata.  Builtin types have all uppercase names. To prevent
631 confusion, you may wish to avoid such package names as well.  Make sure
632 that CLASSNAME is a true value.
633
634 See L<perlmod/"Perl Modules">.
635
636 =item break
637
638 Break out of a C<given()> block.
639
640 This keyword is enabled by the C<"switch"> feature: see
641 L<feature> for more information.  Alternately, include a C<use
642 v5.10> or later to the current scope.
643
644 =item caller EXPR
645 X<caller> X<call stack> X<stack> X<stack trace>
646
647 =item caller
648
649 Returns the context of the current subroutine call.  In scalar context,
650 returns the caller's package name if there I<is> a caller (that is, if
651 we're in a subroutine or C<eval> or C<require>) and the undefined value
652 otherwise.  In list context, returns
653
654     # 0         1          2
655     ($package, $filename, $line) = caller;
656
657 With EXPR, it returns some extra information that the debugger uses to
658 print a stack trace.  The value of EXPR indicates how many call frames
659 to go back before the current one.
660
661     #  0         1          2      3            4
662     ($package, $filename, $line, $subroutine, $hasargs,
663
664     #  5          6          7            8       9         10
665     $wantarray, $evaltext, $is_require, $hints, $bitmask, $hinthash)
666      = caller($i);
667
668 Here $subroutine may be C<(eval)> if the frame is not a subroutine
669 call, but an C<eval>.  In such a case additional elements $evaltext and
670 C<$is_require> are set: C<$is_require> is true if the frame is created by a
671 C<require> or C<use> statement, $evaltext contains the text of the
672 C<eval EXPR> statement.  In particular, for an C<eval BLOCK> statement,
673 $subroutine is C<(eval)>, but $evaltext is undefined.  (Note also that
674 each C<use> statement creates a C<require> frame inside an C<eval EXPR>
675 frame.)  $subroutine may also be C<(unknown)> if this particular
676 subroutine happens to have been deleted from the symbol table.
677 C<$hasargs> is true if a new instance of C<@_> was set up for the frame.
678 C<$hints> and C<$bitmask> contain pragmatic hints that the caller was
679 compiled with.  The C<$hints> and C<$bitmask> values are subject to change
680 between versions of Perl, and are not meant for external use.
681
682 C<$hinthash> is a reference to a hash containing the value of C<%^H> when the
683 caller was compiled, or C<undef> if C<%^H> was empty. Do not modify the values
684 of this hash, as they are the actual values stored in the optree.
685
686 Furthermore, when called from within the DB package, caller returns more
687 detailed information: it sets the list variable C<@DB::args> to be the
688 arguments with which the subroutine was invoked.
689
690 Be aware that the optimizer might have optimized call frames away before
691 C<caller> had a chance to get the information.  That means that C<caller(N)>
692 might not return information about the call frame you expect it to, for
693 C<< N > 1 >>.  In particular, C<@DB::args> might have information from the
694 previous time C<caller> was called.
695
696 Be aware that setting C<@DB::args> is I<best effort>, intended for
697 debugging or generating backtraces, and should not be relied upon. In
698 particular, as C<@_> contains aliases to the caller's arguments, Perl does
699 not take a copy of C<@_>, so C<@DB::args> will contain modifications the
700 subroutine makes to C<@_> or its contents, not the original values at call
701 time. C<@DB::args>, like C<@_>, does not hold explicit references to its
702 elements, so under certain cases its elements may have become freed and
703 reallocated for other variables or temporary values. Finally, a side effect
704 of the current implementation is that the effects of C<shift @_> can
705 I<normally> be undone (but not C<pop @_> or other splicing, I<and> not if a
706 reference to C<@_> has been taken, I<and> subject to the caveat about reallocated
707 elements), so C<@DB::args> is actually a hybrid of the current state and
708 initial state of C<@_>. Buyer beware.
709
710 =item chdir EXPR
711 X<chdir>
712 X<cd>
713 X<directory, change>
714
715 =item chdir FILEHANDLE
716
717 =item chdir DIRHANDLE
718
719 =item chdir
720
721 Changes the working directory to EXPR, if possible. If EXPR is omitted,
722 changes to the directory specified by C<$ENV{HOME}>, if set; if not,
723 changes to the directory specified by C<$ENV{LOGDIR}>. (Under VMS, the
724 variable C<$ENV{SYS$LOGIN}> is also checked, and used if it is set.) If
725 neither is set, C<chdir> does nothing. It returns true on success,
726 false otherwise. See the example under C<die>.
727
728 On systems that support fchdir(2), you may pass a filehandle or
729 directory handle as the argument.  On systems that don't support fchdir(2),
730 passing handles raises an exception.
731
732 =item chmod LIST
733 X<chmod> X<permission> X<mode>
734
735 Changes the permissions of a list of files.  The first element of the
736 list must be the numeric mode, which should probably be an octal
737 number, and which definitely should I<not> be a string of octal digits:
738 C<0644> is okay, but C<"0644"> is not.  Returns the number of files
739 successfully changed.  See also L</oct> if all you have is a string.
740
741     $cnt = chmod 0755, "foo", "bar";
742     chmod 0755, @executables;
743     $mode = "0644"; chmod $mode, "foo";      # !!! sets mode to
744                                              # --w----r-T
745     $mode = "0644"; chmod oct($mode), "foo"; # this is better
746     $mode = 0644;   chmod $mode, "foo";      # this is best
747
748 On systems that support fchmod(2), you may pass filehandles among the
749 files.  On systems that don't support fchmod(2), passing filehandles raises
750 an exception.  Filehandles must be passed as globs or glob references to be
751 recognized; barewords are considered filenames.
752
753     open(my $fh, "<", "foo");
754     my $perm = (stat $fh)[2] & 07777;
755     chmod($perm | 0600, $fh);
756
757 You can also import the symbolic C<S_I*> constants from the C<Fcntl>
758 module:
759
760     use Fcntl qw( :mode );
761     chmod S_IRWXU|S_IRGRP|S_IXGRP|S_IROTH|S_IXOTH, @executables;
762     # Identical to the chmod 0755 of the example above.
763
764 =item chomp VARIABLE
765 X<chomp> X<INPUT_RECORD_SEPARATOR> X<$/> X<newline> X<eol>
766
767 =item chomp( LIST )
768
769 =item chomp
770
771 This safer version of L</chop> removes any trailing string
772 that corresponds to the current value of C<$/> (also known as
773 $INPUT_RECORD_SEPARATOR in the C<English> module).  It returns the total
774 number of characters removed from all its arguments.  It's often used to
775 remove the newline from the end of an input record when you're worried
776 that the final record may be missing its newline.  When in paragraph
777 mode (C<$/ = "">), it removes all trailing newlines from the string.
778 When in slurp mode (C<$/ = undef>) or fixed-length record mode (C<$/> is
779 a reference to an integer or the like; see L<perlvar>) chomp() won't
780 remove anything.
781 If VARIABLE is omitted, it chomps C<$_>.  Example:
782
783     while (<>) {
784         chomp;  # avoid \n on last field
785         @array = split(/:/);
786         # ...
787     }
788
789 If VARIABLE is a hash, it chomps the hash's values, but not its keys.
790
791 You can actually chomp anything that's an lvalue, including an assignment:
792
793     chomp($cwd = `pwd`);
794     chomp($answer = <STDIN>);
795
796 If you chomp a list, each element is chomped, and the total number of
797 characters removed is returned.
798
799 Note that parentheses are necessary when you're chomping anything
800 that is not a simple variable.  This is because C<chomp $cwd = `pwd`;>
801 is interpreted as C<(chomp $cwd) = `pwd`;>, rather than as
802 C<chomp( $cwd = `pwd` )> which you might expect.  Similarly,
803 C<chomp $a, $b> is interpreted as C<chomp($a), $b> rather than
804 as C<chomp($a, $b)>.
805
806 =item chop VARIABLE
807 X<chop>
808
809 =item chop( LIST )
810
811 =item chop
812
813 Chops off the last character of a string and returns the character
814 chopped.  It is much more efficient than C<s/.$//s> because it neither
815 scans nor copies the string.  If VARIABLE is omitted, chops C<$_>.
816 If VARIABLE is a hash, it chops the hash's values, but not its keys.
817
818 You can actually chop anything that's an lvalue, including an assignment.
819
820 If you chop a list, each element is chopped.  Only the value of the
821 last C<chop> is returned.
822
823 Note that C<chop> returns the last character.  To return all but the last
824 character, use C<substr($string, 0, -1)>.
825
826 See also L</chomp>.
827
828 =item chown LIST
829 X<chown> X<owner> X<user> X<group>
830
831 Changes the owner (and group) of a list of files.  The first two
832 elements of the list must be the I<numeric> uid and gid, in that
833 order.  A value of -1 in either position is interpreted by most
834 systems to leave that value unchanged.  Returns the number of files
835 successfully changed.
836
837     $cnt = chown $uid, $gid, 'foo', 'bar';
838     chown $uid, $gid, @filenames;
839
840 On systems that support fchown(2), you may pass filehandles among the
841 files.  On systems that don't support fchown(2), passing filehandles raises
842 an exception.  Filehandles must be passed as globs or glob references to be
843 recognized; barewords are considered filenames.
844
845 Here's an example that looks up nonnumeric uids in the passwd file:
846
847     print "User: ";
848     chomp($user = <STDIN>);
849     print "Files: ";
850     chomp($pattern = <STDIN>);
851
852     ($login,$pass,$uid,$gid) = getpwnam($user)
853         or die "$user not in passwd file";
854
855     @ary = glob($pattern);  # expand filenames
856     chown $uid, $gid, @ary;
857
858 On most systems, you are not allowed to change the ownership of the
859 file unless you're the superuser, although you should be able to change
860 the group to any of your secondary groups.  On insecure systems, these
861 restrictions may be relaxed, but this is not a portable assumption.
862 On POSIX systems, you can detect this condition this way:
863
864     use POSIX qw(sysconf _PC_CHOWN_RESTRICTED);
865     $can_chown_giveaway = not sysconf(_PC_CHOWN_RESTRICTED);
866
867 =item chr NUMBER
868 X<chr> X<character> X<ASCII> X<Unicode>
869
870 =item chr
871
872 Returns the character represented by that NUMBER in the character set.
873 For example, C<chr(65)> is C<"A"> in either ASCII or Unicode, and
874 chr(0x263a) is a Unicode smiley face.  
875
876 Negative values give the Unicode replacement character (chr(0xfffd)),
877 except under the L<bytes> pragma, where the low eight bits of the value
878 (truncated to an integer) are used.
879
880 If NUMBER is omitted, uses C<$_>.
881
882 For the reverse, use L</ord>.
883
884 Note that characters from 128 to 255 (inclusive) are by default
885 internally not encoded as UTF-8 for backward compatibility reasons.
886
887 See L<perlunicode> for more about Unicode.
888
889 =item chroot FILENAME
890 X<chroot> X<root>
891
892 =item chroot
893
894 This function works like the system call by the same name: it makes the
895 named directory the new root directory for all further pathnames that
896 begin with a C</> by your process and all its children.  (It doesn't
897 change your current working directory, which is unaffected.)  For security
898 reasons, this call is restricted to the superuser.  If FILENAME is
899 omitted, does a C<chroot> to C<$_>.
900
901 =item close FILEHANDLE
902 X<close>
903
904 =item close
905
906 Closes the file or pipe associated with the filehandle, flushes the IO
907 buffers, and closes the system file descriptor.  Returns true if those
908 operations succeed and if no error was reported by any PerlIO
909 layer.  Closes the currently selected filehandle if the argument is
910 omitted.
911
912 You don't have to close FILEHANDLE if you are immediately going to do
913 another C<open> on it, because C<open> closes it for you.  (See
914 C<open>.)  However, an explicit C<close> on an input file resets the line
915 counter (C<$.>), while the implicit close done by C<open> does not.
916
917 If the filehandle came from a piped open, C<close> returns false if one of
918 the other syscalls involved fails or if its program exits with non-zero
919 status.  If the only problem was that the program exited non-zero, C<$!>
920 will be set to C<0>.  Closing a pipe also waits for the process executing
921 on the pipe to exit--in case you wish to look at the output of the pipe
922 afterwards--and implicitly puts the exit status value of that command into
923 C<$?> and C<${^CHILD_ERROR_NATIVE}>.
924
925 If there are multiple threads running, C<close> on a filehandle from a
926 piped open returns true without waiting for the child process to terminate,
927 if the filehandle is still open in another thread.
928
929 Closing the read end of a pipe before the process writing to it at the
930 other end is done writing results in the writer receiving a SIGPIPE.  If
931 the other end can't handle that, be sure to read all the data before
932 closing the pipe.
933
934 Example:
935
936     open(OUTPUT, '|sort >foo')  # pipe to sort
937         or die "Can't start sort: $!";
938     #...                        # print stuff to output
939     close OUTPUT                # wait for sort to finish
940         or warn $! ? "Error closing sort pipe: $!"
941                    : "Exit status $? from sort";
942     open(INPUT, 'foo')          # get sort's results
943         or die "Can't open 'foo' for input: $!";
944
945 FILEHANDLE may be an expression whose value can be used as an indirect
946 filehandle, usually the real filehandle name or an autovivified handle.
947
948 =item closedir DIRHANDLE
949 X<closedir>
950
951 Closes a directory opened by C<opendir> and returns the success of that
952 system call.
953
954 =item connect SOCKET,NAME
955 X<connect>
956
957 Attempts to connect to a remote socket, just like connect(2).
958 Returns true if it succeeded, false otherwise.  NAME should be a
959 packed address of the appropriate type for the socket.  See the examples in
960 L<perlipc/"Sockets: Client/Server Communication">.
961
962 =item continue BLOCK
963 X<continue>
964
965 =item continue
966
967 C<continue> is actually a flow control statement rather than a function.  If
968 there is a C<continue> BLOCK attached to a BLOCK (typically in a C<while> or
969 C<foreach>), it is always executed just before the conditional is about to
970 be evaluated again, just like the third part of a C<for> loop in C.  Thus
971 it can be used to increment a loop variable, even when the loop has been
972 continued via the C<next> statement (which is similar to the C C<continue>
973 statement).
974
975 C<last>, C<next>, or C<redo> may appear within a C<continue>
976 block; C<last> and C<redo> behave as if they had been executed within
977 the main block.  So will C<next>, but since it will execute a C<continue>
978 block, it may be more entertaining.
979
980     while (EXPR) {
981         ### redo always comes here
982         do_something;
983     } continue {
984         ### next always comes here
985         do_something_else;
986         # then back the top to re-check EXPR
987     }
988     ### last always comes here
989
990 Omitting the C<continue> section is equivalent to using an
991 empty one, logically enough, so C<next> goes directly back
992 to check the condition at the top of the loop.
993
994 If the C<"switch"> feature is enabled, C<continue> is also a function that
995 falls through the current C<when> or C<default> block instead of iterating
996 a dynamically enclosing C<foreach> or exiting a lexically enclosing C<given>.
997 See L<feature> and L<perlsyn/"Switch statements"> for more
998 information.
999
1000 =item cos EXPR
1001 X<cos> X<cosine> X<acos> X<arccosine>
1002
1003 =item cos
1004
1005 Returns the cosine of EXPR (expressed in radians).  If EXPR is omitted,
1006 takes the cosine of C<$_>.
1007
1008 For the inverse cosine operation, you may use the C<Math::Trig::acos()>
1009 function, or use this relation:
1010
1011     sub acos { atan2( sqrt(1 - $_[0] * $_[0]), $_[0] ) }
1012
1013 =item crypt PLAINTEXT,SALT
1014 X<crypt> X<digest> X<hash> X<salt> X<plaintext> X<password>
1015 X<decrypt> X<cryptography> X<passwd> X<encrypt>
1016
1017 Creates a digest string exactly like the crypt(3) function in the C
1018 library (assuming that you actually have a version there that has not
1019 been extirpated as a potential munition).
1020
1021 crypt() is a one-way hash function.  The PLAINTEXT and SALT are turned
1022 into a short string, called a digest, which is returned.  The same
1023 PLAINTEXT and SALT will always return the same string, but there is no
1024 (known) way to get the original PLAINTEXT from the hash.  Small
1025 changes in the PLAINTEXT or SALT will result in large changes in the
1026 digest.
1027
1028 There is no decrypt function.  This function isn't all that useful for
1029 cryptography (for that, look for F<Crypt> modules on your nearby CPAN
1030 mirror) and the name "crypt" is a bit of a misnomer.  Instead it is
1031 primarily used to check if two pieces of text are the same without
1032 having to transmit or store the text itself.  An example is checking
1033 if a correct password is given.  The digest of the password is stored,
1034 not the password itself.  The user types in a password that is
1035 crypt()'d with the same salt as the stored digest.  If the two digests
1036 match, the password is correct.
1037
1038 When verifying an existing digest string you should use the digest as
1039 the salt (like C<crypt($plain, $digest) eq $digest>).  The SALT used
1040 to create the digest is visible as part of the digest.  This ensures
1041 crypt() will hash the new string with the same salt as the digest.
1042 This allows your code to work with the standard L<crypt|/crypt> and
1043 with more exotic implementations.  In other words, assume
1044 nothing about the returned string itself nor about how many bytes 
1045 of SALT may matter.
1046
1047 Traditionally the result is a string of 13 bytes: two first bytes of
1048 the salt, followed by 11 bytes from the set C<[./0-9A-Za-z]>, and only
1049 the first eight bytes of PLAINTEXT mattered. But alternative
1050 hashing schemes (like MD5), higher level security schemes (like C2),
1051 and implementations on non-Unix platforms may produce different
1052 strings.
1053
1054 When choosing a new salt create a random two character string whose
1055 characters come from the set C<[./0-9A-Za-z]> (like C<join '', ('.',
1056 '/', 0..9, 'A'..'Z', 'a'..'z')[rand 64, rand 64]>).  This set of
1057 characters is just a recommendation; the characters allowed in
1058 the salt depend solely on your system's crypt library, and Perl can't
1059 restrict what salts C<crypt()> accepts.
1060
1061 Here's an example that makes sure that whoever runs this program knows
1062 their password:
1063
1064     $pwd = (getpwuid($<))[1];
1065
1066     system "stty -echo";
1067     print "Password: ";
1068     chomp($word = <STDIN>);
1069     print "\n";
1070     system "stty echo";
1071
1072     if (crypt($word, $pwd) ne $pwd) {
1073         die "Sorry...\n";
1074     } else {
1075         print "ok\n";
1076     }
1077
1078 Of course, typing in your own password to whoever asks you
1079 for it is unwise.
1080
1081 The L<crypt|/crypt> function is unsuitable for hashing large quantities
1082 of data, not least of all because you can't get the information
1083 back.  Look at the L<Digest> module for more robust algorithms.
1084
1085 If using crypt() on a Unicode string (which I<potentially> has
1086 characters with codepoints above 255), Perl tries to make sense
1087 of the situation by trying to downgrade (a copy of)
1088 the string back to an eight-bit byte string before calling crypt()
1089 (on that copy).  If that works, good.  If not, crypt() dies with
1090 C<Wide character in crypt>.
1091
1092 =item dbmclose HASH
1093 X<dbmclose>
1094
1095 [This function has been largely superseded by the C<untie> function.]
1096
1097 Breaks the binding between a DBM file and a hash.
1098
1099 =item dbmopen HASH,DBNAME,MASK
1100 X<dbmopen> X<dbm> X<ndbm> X<sdbm> X<gdbm>
1101
1102 [This function has been largely superseded by the C<tie> function.]
1103
1104 This binds a dbm(3), ndbm(3), sdbm(3), gdbm(3), or Berkeley DB file to a
1105 hash.  HASH is the name of the hash.  (Unlike normal C<open>, the first
1106 argument is I<not> a filehandle, even though it looks like one).  DBNAME
1107 is the name of the database (without the F<.dir> or F<.pag> extension if
1108 any).  If the database does not exist, it is created with protection
1109 specified by MASK (as modified by the C<umask>).  If your system supports
1110 only the older DBM functions, you may make only one C<dbmopen> call in your
1111 program.  In older versions of Perl, if your system had neither DBM nor
1112 ndbm, calling C<dbmopen> produced a fatal error; it now falls back to
1113 sdbm(3).
1114
1115 If you don't have write access to the DBM file, you can only read hash
1116 variables, not set them.  If you want to test whether you can write,
1117 either use file tests or try setting a dummy hash entry inside an C<eval> 
1118 to trap the error.
1119
1120 Note that functions such as C<keys> and C<values> may return huge lists
1121 when used on large DBM files.  You may prefer to use the C<each>
1122 function to iterate over large DBM files.  Example:
1123
1124     # print out history file offsets
1125     dbmopen(%HIST,'/usr/lib/news/history',0666);
1126     while (($key,$val) = each %HIST) {
1127         print $key, ' = ', unpack('L',$val), "\n";
1128     }
1129     dbmclose(%HIST);
1130
1131 See also L<AnyDBM_File> for a more general description of the pros and
1132 cons of the various dbm approaches, as well as L<DB_File> for a particularly
1133 rich implementation.
1134
1135 You can control which DBM library you use by loading that library
1136 before you call dbmopen():
1137
1138     use DB_File;
1139     dbmopen(%NS_Hist, "$ENV{HOME}/.netscape/history.db")
1140         or die "Can't open netscape history file: $!";
1141
1142 =item default BLOCK
1143
1144 Within a C<foreach> or a C<given>, a C<default> BLOCK acts like a C<when>
1145 that's always true.  Only available after Perl 5.10, and only if the
1146 C<switch> feature has been requested.  See L</when>.
1147
1148 =item defined EXPR
1149 X<defined> X<undef> X<undefined>
1150
1151 =item defined
1152
1153 Returns a Boolean value telling whether EXPR has a value other than
1154 the undefined value C<undef>.  If EXPR is not present, C<$_> is
1155 checked.
1156
1157 Many operations return C<undef> to indicate failure, end of file,
1158 system error, uninitialized variable, and other exceptional
1159 conditions.  This function allows you to distinguish C<undef> from
1160 other values.  (A simple Boolean test will not distinguish among
1161 C<undef>, zero, the empty string, and C<"0">, which are all equally
1162 false.)  Note that since C<undef> is a valid scalar, its presence
1163 doesn't I<necessarily> indicate an exceptional condition: C<pop>
1164 returns C<undef> when its argument is an empty array, I<or> when the
1165 element to return happens to be C<undef>.
1166
1167 You may also use C<defined(&func)> to check whether subroutine C<&func>
1168 has ever been defined.  The return value is unaffected by any forward
1169 declarations of C<&func>.  A subroutine that is not defined
1170 may still be callable: its package may have an C<AUTOLOAD> method that
1171 makes it spring into existence the first time that it is called; see
1172 L<perlsub>.
1173
1174 Use of C<defined> on aggregates (hashes and arrays) is deprecated.  It
1175 used to report whether memory for that aggregate had ever been
1176 allocated.  This behavior may disappear in future versions of Perl.
1177 You should instead use a simple test for size:
1178
1179     if (@an_array) { print "has array elements\n" }
1180     if (%a_hash)   { print "has hash members\n"   }
1181
1182 When used on a hash element, it tells you whether the value is defined,
1183 not whether the key exists in the hash.  Use L</exists> for the latter
1184 purpose.
1185
1186 Examples:
1187
1188     print if defined $switch{D};
1189     print "$val\n" while defined($val = pop(@ary));
1190     die "Can't readlink $sym: $!"
1191         unless defined($value = readlink $sym);
1192     sub foo { defined &$bar ? &$bar(@_) : die "No bar"; }
1193     $debugging = 0 unless defined $debugging;
1194
1195 Note:  Many folks tend to overuse C<defined> and are then surprised to
1196 discover that the number C<0> and C<""> (the zero-length string) are, in fact,
1197 defined values.  For example, if you say
1198
1199     "ab" =~ /a(.*)b/;
1200
1201 The pattern match succeeds and C<$1> is defined, although it
1202 matched "nothing".  It didn't really fail to match anything.  Rather, it
1203 matched something that happened to be zero characters long.  This is all
1204 very above-board and honest.  When a function returns an undefined value,
1205 it's an admission that it couldn't give you an honest answer.  So you
1206 should use C<defined> only when questioning the integrity of what
1207 you're trying to do.  At other times, a simple comparison to C<0> or C<""> is
1208 what you want.
1209
1210 See also L</undef>, L</exists>, L</ref>.
1211
1212 =item delete EXPR
1213 X<delete>
1214
1215 Given an expression that specifies an element or slice of a hash, C<delete>
1216 deletes the specified elements from that hash so that exists() on that element
1217 no longer returns true.  Setting a hash element to the undefined value does
1218 not remove its key, but deleting it does; see L</exists>.
1219
1220 In list context, returns the value or values deleted, or the last such
1221 element in scalar context.  The return list's length always matches that of
1222 the argument list: deleting non-existent elements returns the undefined value
1223 in their corresponding positions.
1224
1225 delete() may also be used on arrays and array slices, but its behavior is less
1226 straightforward.  Although exists() will return false for deleted entries,
1227 deleting array elements never changes indices of existing values; use shift()
1228 or splice() for that.  However, if all deleted elements fall at the end of an
1229 array, the array's size shrinks to the position of the highest element that
1230 still tests true for exists(), or to 0 if none do.
1231
1232 B<WARNING:> Calling delete on array values is deprecated and likely to
1233 be removed in a future version of Perl.
1234
1235 Deleting from C<%ENV> modifies the environment.  Deleting from a hash tied to
1236 a DBM file deletes the entry from the DBM file.  Deleting from a C<tied> hash
1237 or array may not necessarily return anything; it depends on the implementation
1238 of the C<tied> package's DELETE method, which may do whatever it pleases.
1239
1240 The C<delete local EXPR> construct localizes the deletion to the current
1241 block at run time.  Until the block exits, elements locally deleted
1242 temporarily no longer exist.  See L<perlsub/"Localized deletion of elements
1243 of composite types">.
1244
1245     %hash = (foo => 11, bar => 22, baz => 33);
1246     $scalar = delete $hash{foo};             # $scalar is 11
1247     $scalar = delete @hash{qw(foo bar)};     # $scalar is 22
1248     @array  = delete @hash{qw(foo bar baz)}; # @array  is (undef,undef,33)
1249
1250 The following (inefficiently) deletes all the values of %HASH and @ARRAY:
1251
1252     foreach $key (keys %HASH) {
1253         delete $HASH{$key};
1254     }
1255
1256     foreach $index (0 .. $#ARRAY) {
1257         delete $ARRAY[$index];
1258     }
1259
1260 And so do these:
1261
1262     delete @HASH{keys %HASH};
1263
1264     delete @ARRAY[0 .. $#ARRAY];
1265
1266 But both are slower than assigning the empty list
1267 or undefining %HASH or @ARRAY, which is the customary 
1268 way to empty out an aggregate:
1269
1270     %HASH = ();     # completely empty %HASH
1271     undef %HASH;    # forget %HASH ever existed
1272
1273     @ARRAY = ();    # completely empty @ARRAY
1274     undef @ARRAY;   # forget @ARRAY ever existed
1275
1276 The EXPR can be arbitrarily complicated provided its
1277 final operation is an element or slice of an aggregate:
1278
1279     delete $ref->[$x][$y]{$key};
1280     delete @{$ref->[$x][$y]}{$key1, $key2, @morekeys};
1281
1282     delete $ref->[$x][$y][$index];
1283     delete @{$ref->[$x][$y]}[$index1, $index2, @moreindices];
1284
1285 =item die LIST
1286 X<die> X<throw> X<exception> X<raise> X<$@> X<abort>
1287
1288 C<die> raises an exception. Inside an C<eval> the error message is stuffed
1289 into C<$@> and the C<eval> is terminated with the undefined value.
1290 If the exception is outside of all enclosing C<eval>s, then the uncaught
1291 exception prints LIST to C<STDERR> and exits with a non-zero value. If you
1292 need to exit the process with a specific exit code, see L</exit>.
1293
1294 Equivalent examples:
1295
1296     die "Can't cd to spool: $!\n" unless chdir '/usr/spool/news';
1297     chdir '/usr/spool/news' or die "Can't cd to spool: $!\n"
1298
1299 If the last element of LIST does not end in a newline, the current
1300 script line number and input line number (if any) are also printed,
1301 and a newline is supplied.  Note that the "input line number" (also
1302 known as "chunk") is subject to whatever notion of "line" happens to
1303 be currently in effect, and is also available as the special variable
1304 C<$.>.  See L<perlvar/"$/"> and L<perlvar/"$.">.
1305
1306 Hint: sometimes appending C<", stopped"> to your message will cause it
1307 to make better sense when the string C<"at foo line 123"> is appended.
1308 Suppose you are running script "canasta".
1309
1310     die "/etc/games is no good";
1311     die "/etc/games is no good, stopped";
1312
1313 produce, respectively
1314
1315     /etc/games is no good at canasta line 123.
1316     /etc/games is no good, stopped at canasta line 123.
1317
1318 If the output is empty and C<$@> already contains a value (typically from a
1319 previous eval) that value is reused after appending C<"\t...propagated">.
1320 This is useful for propagating exceptions:
1321
1322     eval { ... };
1323     die unless $@ =~ /Expected exception/;
1324
1325 If the output is empty and C<$@> contains an object reference that has a
1326 C<PROPAGATE> method, that method will be called with additional file
1327 and line number parameters.  The return value replaces the value in
1328 C<$@>;  i.e., as if C<< $@ = eval { $@->PROPAGATE(__FILE__, __LINE__) }; >>
1329 were called.
1330
1331 If C<$@> is empty then the string C<"Died"> is used.
1332
1333 If an uncaught exception results in interpreter exit, the exit code is
1334 determined from the values of C<$!> and C<$?> with this pseudocode:
1335
1336     exit $! if $!;              # errno
1337     exit $? >> 8 if $? >> 8;    # child exit status
1338     exit 255;                   # last resort
1339
1340 The intent is to squeeze as much possible information about the likely cause
1341 into the limited space of the system exit code. However, as C<$!> is the value
1342 of C's C<errno>, which can be set by any system call, this means that the value
1343 of the exit code used by C<die> can be non-predictable, so should not be relied
1344 upon, other than to be non-zero.
1345
1346 You can also call C<die> with a reference argument, and if this is trapped
1347 within an C<eval>, C<$@> contains that reference.  This permits more
1348 elaborate exception handling using objects that maintain arbitrary state
1349 about the exception.  Such a scheme is sometimes preferable to matching
1350 particular string values of C<$@> with regular expressions.  Because C<$@> 
1351 is a global variable and C<eval> may be used within object implementations,
1352 be careful that analyzing the error object doesn't replace the reference in
1353 the global variable.  It's easiest to make a local copy of the reference
1354 before any manipulations.  Here's an example:
1355
1356     use Scalar::Util "blessed";
1357
1358     eval { ... ; die Some::Module::Exception->new( FOO => "bar" ) };
1359     if (my $ev_err = $@) {
1360         if (blessed($ev_err) && $ev_err->isa("Some::Module::Exception")) {
1361             # handle Some::Module::Exception
1362         }
1363         else {
1364             # handle all other possible exceptions
1365         }
1366     }
1367
1368 Because Perl stringifies uncaught exception messages before display,
1369 you'll probably want to overload stringification operations on
1370 exception objects.  See L<overload> for details about that.
1371
1372 You can arrange for a callback to be run just before the C<die>
1373 does its deed, by setting the C<$SIG{__DIE__}> hook.  The associated
1374 handler is called with the error text and can change the error
1375 message, if it sees fit, by calling C<die> again.  See
1376 L<perlvar/%SIG> for details on setting C<%SIG> entries, and
1377 L<"eval BLOCK"> for some examples.  Although this feature was 
1378 to be run only right before your program was to exit, this is not
1379 currently so: the C<$SIG{__DIE__}> hook is currently called
1380 even inside eval()ed blocks/strings!  If one wants the hook to do
1381 nothing in such situations, put
1382
1383     die @_ if $^S;
1384
1385 as the first line of the handler (see L<perlvar/$^S>).  Because
1386 this promotes strange action at a distance, this counterintuitive
1387 behavior may be fixed in a future release.
1388
1389 See also exit(), warn(), and the Carp module.
1390
1391 =item do BLOCK
1392 X<do> X<block>
1393
1394 Not really a function.  Returns the value of the last command in the
1395 sequence of commands indicated by BLOCK.  When modified by the C<while> or
1396 C<until> loop modifier, executes the BLOCK once before testing the loop
1397 condition. (On other statements the loop modifiers test the conditional
1398 first.)
1399
1400 C<do BLOCK> does I<not> count as a loop, so the loop control statements
1401 C<next>, C<last>, or C<redo> cannot be used to leave or restart the block.
1402 See L<perlsyn> for alternative strategies.
1403
1404 =item do SUBROUTINE(LIST)
1405 X<do>
1406
1407 This form of subroutine call is deprecated.  SUBROUTINE can be a bareword,
1408 a scalar variable or a subroutine beginning with C<&>.
1409
1410 =item do EXPR
1411 X<do>
1412
1413 Uses the value of EXPR as a filename and executes the contents of the
1414 file as a Perl script.
1415
1416     do 'stat.pl';
1417
1418 is just like
1419
1420     eval `cat stat.pl`;
1421
1422 except that it's more efficient and concise, keeps track of the current
1423 filename for error messages, searches the C<@INC> directories, and updates
1424 C<%INC> if the file is found.  See L<perlvar/@INC> and L<perlvar/%INC> for
1425 these variables.  It also differs in that code evaluated with C<do FILENAME>
1426 cannot see lexicals in the enclosing scope; C<eval STRING> does.  It's the
1427 same, however, in that it does reparse the file every time you call it,
1428 so you probably don't want to do this inside a loop.
1429
1430 If C<do> can read the file but cannot compile it, it returns C<undef> and sets
1431 an error message in C<$@>.  If C<do> cannot read the file, it returns undef
1432 and sets C<$!> to the error.  Always check C<$@> first, as compilation
1433 could fail in a way that also sets C<$!>.  If the file is successfully
1434 compiled, C<do> returns the value of the last expression evaluated.
1435
1436 Inclusion of library modules is better done with the
1437 C<use> and C<require> operators, which also do automatic error checking
1438 and raise an exception if there's a problem.
1439
1440 You might like to use C<do> to read in a program configuration
1441 file.  Manual error checking can be done this way:
1442
1443     # read in config files: system first, then user
1444     for $file ("/share/prog/defaults.rc",
1445                "$ENV{HOME}/.someprogrc")
1446     {
1447         unless ($return = do $file) {
1448             warn "couldn't parse $file: $@" if $@;
1449             warn "couldn't do $file: $!"    unless defined $return;
1450             warn "couldn't run $file"       unless $return;
1451         }
1452     }
1453
1454 =item dump LABEL
1455 X<dump> X<core> X<undump>
1456
1457 =item dump
1458
1459 This function causes an immediate core dump.  See also the B<-u>
1460 command-line switch in L<perlrun>, which does the same thing.
1461 Primarily this is so that you can use the B<undump> program (not
1462 supplied) to turn your core dump into an executable binary after
1463 having initialized all your variables at the beginning of the
1464 program.  When the new binary is executed it will begin by executing
1465 a C<goto LABEL> (with all the restrictions that C<goto> suffers).
1466 Think of it as a goto with an intervening core dump and reincarnation.
1467 If C<LABEL> is omitted, restarts the program from the top.
1468
1469 B<WARNING>: Any files opened at the time of the dump will I<not>
1470 be open any more when the program is reincarnated, with possible
1471 resulting confusion by Perl.
1472
1473 This function is now largely obsolete, mostly because it's very hard to
1474 convert a core file into an executable. That's why you should now invoke
1475 it as C<CORE::dump()>, if you don't want to be warned against a possible
1476 typo.
1477
1478 =item each HASH
1479 X<each> X<hash, iterator>
1480
1481 =item each ARRAY
1482 X<array, iterator>
1483
1484 =item each EXPR
1485
1486 When called in list context, returns a 2-element list consisting of the key
1487 and value for the next element of a hash, or the index and value for the
1488 next element of an array, so that you can iterate over it.  When called in
1489 scalar context, returns only the key (not the value) in a hash, or the index
1490 in an array.
1491
1492 Hash entries are returned in an apparently random order.  The actual random
1493 order is subject to change in future versions of Perl, but it is
1494 guaranteed to be in the same order as either the C<keys> or C<values>
1495 function would produce on the same (unmodified) hash.  Since Perl
1496 5.8.2 the ordering can be different even between different runs of Perl
1497 for security reasons (see L<perlsec/"Algorithmic Complexity Attacks">).
1498
1499 After C<each> has returned all entries from the hash or array, the next
1500 call to C<each> returns the empty list in list context and C<undef> in
1501 scalar context.  The next call following that one restarts iteration.  Each
1502 hash or array has its own internal iterator, accessed by C<each>, C<keys>,
1503 and C<values>.  The iterator is implicitly reset when C<each> has reached
1504 the end as just described; it can be explicitly reset by calling C<keys> or
1505 C<values> on the hash or array.  If you add or delete a hash's elements
1506 while iterating over it, entries may be skipped or duplicated--so don't do
1507 that.  Exception: It is always safe to delete the item most recently
1508 returned by C<each()>, so the following code works properly:
1509
1510         while (($key, $value) = each %hash) {
1511           print $key, "\n";
1512           delete $hash{$key};   # This is safe
1513         }
1514
1515 This prints out your environment like the printenv(1) program,
1516 but in a different order:
1517
1518     while (($key,$value) = each %ENV) {
1519         print "$key=$value\n";
1520     }
1521
1522 Starting with Perl 5.14, C<each> can take a scalar EXPR, which must hold
1523 reference to an unblessed hash or array.  The argument will be dereferenced
1524 automatically.  This aspect of C<each> is considered highly experimental.
1525 The exact behaviour may change in a future version of Perl.
1526
1527     while (($key,$value) = each $hashref) { ... }
1528
1529 See also C<keys>, C<values>, and C<sort>.
1530
1531 =item eof FILEHANDLE
1532 X<eof>
1533 X<end of file>
1534 X<end-of-file>
1535
1536 =item eof ()
1537
1538 =item eof
1539
1540 Returns 1 if the next read on FILEHANDLE will return end of file I<or> if
1541 FILEHANDLE is not open.  FILEHANDLE may be an expression whose value
1542 gives the real filehandle.  (Note that this function actually
1543 reads a character and then C<ungetc>s it, so isn't useful in an
1544 interactive context.)  Do not read from a terminal file (or call
1545 C<eof(FILEHANDLE)> on it) after end-of-file is reached.  File types such
1546 as terminals may lose the end-of-file condition if you do.
1547
1548 An C<eof> without an argument uses the last file read.  Using C<eof()>
1549 with empty parentheses is different.  It refers to the pseudo file
1550 formed from the files listed on the command line and accessed via the
1551 C<< <> >> operator.  Since C<< <> >> isn't explicitly opened,
1552 as a normal filehandle is, an C<eof()> before C<< <> >> has been
1553 used will cause C<@ARGV> to be examined to determine if input is
1554 available.   Similarly, an C<eof()> after C<< <> >> has returned
1555 end-of-file will assume you are processing another C<@ARGV> list,
1556 and if you haven't set C<@ARGV>, will read input from C<STDIN>;
1557 see L<perlop/"I/O Operators">.
1558
1559 In a C<< while (<>) >> loop, C<eof> or C<eof(ARGV)> can be used to
1560 detect the end of each file, whereas C<eof()> will detect the end 
1561 of the very last file only.  Examples:
1562
1563     # reset line numbering on each input file
1564     while (<>) {
1565         next if /^\s*#/;  # skip comments
1566         print "$.\t$_";
1567     } continue {
1568         close ARGV if eof;  # Not eof()!
1569     }
1570
1571     # insert dashes just before last line of last file
1572     while (<>) {
1573         if (eof()) {  # check for end of last file
1574             print "--------------\n";
1575         }
1576         print;
1577         last if eof();          # needed if we're reading from a terminal
1578     }
1579
1580 Practical hint: you almost never need to use C<eof> in Perl, because the
1581 input operators typically return C<undef> when they run out of data or 
1582 encounter an error.
1583
1584 =item eval EXPR
1585 X<eval> X<try> X<catch> X<evaluate> X<parse> X<execute>
1586 X<error, handling> X<exception, handling>
1587
1588 =item eval BLOCK
1589
1590 =item eval
1591
1592 In the first form, the return value of EXPR is parsed and executed as if it
1593 were a little Perl program.  The value of the expression (which is itself
1594 determined within scalar context) is first parsed, and if there were no
1595 errors, executed in the lexical context of the current Perl program, so
1596 that any variable settings or subroutine and format definitions remain
1597 afterwards.  Note that the value is parsed every time the C<eval> executes.
1598 If EXPR is omitted, evaluates C<$_>.  This form is typically used to
1599 delay parsing and subsequent execution of the text of EXPR until run time.
1600
1601 In the second form, the code within the BLOCK is parsed only once--at the
1602 same time the code surrounding the C<eval> itself was parsed--and executed
1603 within the context of the current Perl program.  This form is typically
1604 used to trap exceptions more efficiently than the first (see below), while
1605 also providing the benefit of checking the code within BLOCK at compile
1606 time.
1607
1608 The final semicolon, if any, may be omitted from the value of EXPR or within
1609 the BLOCK.
1610
1611 In both forms, the value returned is the value of the last expression
1612 evaluated inside the mini-program; a return statement may be also used, just
1613 as with subroutines.  The expression providing the return value is evaluated
1614 in void, scalar, or list context, depending on the context of the C<eval> 
1615 itself.  See L</wantarray> for more on how the evaluation context can be 
1616 determined.
1617
1618 If there is a syntax error or runtime error, or a C<die> statement is
1619 executed, C<eval> returns C<undef> in scalar context
1620 or an empty list--or, for syntax errors, a list containing a single
1621 undefined value--in list context, and C<$@> is set to the error
1622 message.  The discrepancy in the return values in list context is
1623 considered a bug by some, and will probably be fixed in a future
1624 release.  If there was no error, C<$@> is guaranteed to be the empty
1625 string.  Beware that using C<eval> neither silences Perl from printing
1626 warnings to STDERR, nor does it stuff the text of warning messages into C<$@>.
1627 To do either of those, you have to use the C<$SIG{__WARN__}> facility, or
1628 turn off warnings inside the BLOCK or EXPR using S<C<no warnings 'all'>>.
1629 See L</warn>, L<perlvar>, L<warnings> and L<perllexwarn>.
1630
1631 Note that, because C<eval> traps otherwise-fatal errors, it is useful for
1632 determining whether a particular feature (such as C<socket> or C<symlink>)
1633 is implemented.  It is also Perl's exception-trapping mechanism, where
1634 the die operator is used to raise exceptions.
1635
1636 If you want to trap errors when loading an XS module, some problems with
1637 the binary interface (such as Perl version skew) may be fatal even with
1638 C<eval> unless C<$ENV{PERL_DL_NONLAZY}> is set. See L<perlrun>.
1639
1640 If the code to be executed doesn't vary, you may use the eval-BLOCK
1641 form to trap run-time errors without incurring the penalty of
1642 recompiling each time.  The error, if any, is still returned in C<$@>.
1643 Examples:
1644
1645     # make divide-by-zero nonfatal
1646     eval { $answer = $a / $b; }; warn $@ if $@;
1647
1648     # same thing, but less efficient
1649     eval '$answer = $a / $b'; warn $@ if $@;
1650
1651     # a compile-time error
1652     eval { $answer = }; # WRONG
1653
1654     # a run-time error
1655     eval '$answer =';   # sets $@
1656
1657 Using the C<eval{}> form as an exception trap in libraries does have some
1658 issues.  Due to the current arguably broken state of C<__DIE__> hooks, you
1659 may wish not to trigger any C<__DIE__> hooks that user code may have installed.
1660 You can use the C<local $SIG{__DIE__}> construct for this purpose,
1661 as this example shows:
1662
1663     # a private exception trap for divide-by-zero
1664     eval { local $SIG{'__DIE__'}; $answer = $a / $b; };
1665     warn $@ if $@;
1666
1667 This is especially significant, given that C<__DIE__> hooks can call
1668 C<die> again, which has the effect of changing their error messages:
1669
1670     # __DIE__ hooks may modify error messages
1671     {
1672        local $SIG{'__DIE__'} =
1673               sub { (my $x = $_[0]) =~ s/foo/bar/g; die $x };
1674        eval { die "foo lives here" };
1675        print $@ if $@;                # prints "bar lives here"
1676     }
1677
1678 Because this promotes action at a distance, this counterintuitive behavior
1679 may be fixed in a future release.
1680
1681 With an C<eval>, you should be especially careful to remember what's
1682 being looked at when:
1683
1684     eval $x;        # CASE 1
1685     eval "$x";      # CASE 2
1686
1687     eval '$x';      # CASE 3
1688     eval { $x };    # CASE 4
1689
1690     eval "\$$x++";  # CASE 5
1691     $$x++;          # CASE 6
1692
1693 Cases 1 and 2 above behave identically: they run the code contained in
1694 the variable $x.  (Although case 2 has misleading double quotes making
1695 the reader wonder what else might be happening (nothing is).)  Cases 3
1696 and 4 likewise behave in the same way: they run the code C<'$x'>, which
1697 does nothing but return the value of $x.  (Case 4 is preferred for
1698 purely visual reasons, but it also has the advantage of compiling at
1699 compile-time instead of at run-time.)  Case 5 is a place where
1700 normally you I<would> like to use double quotes, except that in this
1701 particular situation, you can just use symbolic references instead, as
1702 in case 6.
1703
1704 Before Perl 5.14, the assignment to C<$@> occurred before restoration 
1705 of localised variables, which means that for your code to run on older
1706 versions, a temporary is required if you want to mask some but not all
1707 errors:
1708
1709     # alter $@ on nefarious repugnancy only
1710     {
1711        my $e;
1712        {
1713           local $@; # protect existing $@
1714           eval { test_repugnancy() };
1715           # $@ =~ /nefarious/ and die $@; # Perl 5.14 and higher only
1716           $@ =~ /nefarious/ and $e = $@;
1717        }
1718        die $e if defined $e
1719     }
1720
1721 C<eval BLOCK> does I<not> count as a loop, so the loop control statements
1722 C<next>, C<last>, or C<redo> cannot be used to leave or restart the block.
1723
1724 An C<eval ''> executed within the C<DB> package doesn't see the usual
1725 surrounding lexical scope, but rather the scope of the first non-DB piece
1726 of code that called it. You don't normally need to worry about this unless
1727 you are writing a Perl debugger.
1728
1729 =item exec LIST
1730 X<exec> X<execute>
1731
1732 =item exec PROGRAM LIST
1733
1734 The C<exec> function executes a system command I<and never returns>;
1735 use C<system> instead of C<exec> if you want it to return.  It fails and
1736 returns false only if the command does not exist I<and> it is executed
1737 directly instead of via your system's command shell (see below).
1738
1739 Since it's a common mistake to use C<exec> instead of C<system>, Perl
1740 warns you if there is a following statement that isn't C<die>, C<warn>,
1741 or C<exit> (if C<-w> is set--but you always do that, right?).   If you
1742 I<really> want to follow an C<exec> with some other statement, you
1743 can use one of these styles to avoid the warning:
1744
1745     exec ('foo')   or print STDERR "couldn't exec foo: $!";
1746     { exec ('foo') }; print STDERR "couldn't exec foo: $!";
1747
1748 If there is more than one argument in LIST, or if LIST is an array
1749 with more than one value, calls execvp(3) with the arguments in LIST.
1750 If there is only one scalar argument or an array with one element in it,
1751 the argument is checked for shell metacharacters, and if there are any,
1752 the entire argument is passed to the system's command shell for parsing
1753 (this is C</bin/sh -c> on Unix platforms, but varies on other platforms).
1754 If there are no shell metacharacters in the argument, it is split into
1755 words and passed directly to C<execvp>, which is more efficient.
1756 Examples:
1757
1758     exec '/bin/echo', 'Your arguments are: ', @ARGV;
1759     exec "sort $outfile | uniq";
1760
1761 If you don't really want to execute the first argument, but want to lie
1762 to the program you are executing about its own name, you can specify
1763 the program you actually want to run as an "indirect object" (without a
1764 comma) in front of the LIST.  (This always forces interpretation of the
1765 LIST as a multivalued list, even if there is only a single scalar in
1766 the list.)  Example:
1767
1768     $shell = '/bin/csh';
1769     exec $shell '-sh';    # pretend it's a login shell
1770
1771 or, more directly,
1772
1773     exec {'/bin/csh'} '-sh';  # pretend it's a login shell
1774
1775 When the arguments get executed via the system shell, results are
1776 subject to its quirks and capabilities.  See L<perlop/"`STRING`">
1777 for details.
1778
1779 Using an indirect object with C<exec> or C<system> is also more
1780 secure.  This usage (which also works fine with system()) forces
1781 interpretation of the arguments as a multivalued list, even if the
1782 list had just one argument.  That way you're safe from the shell
1783 expanding wildcards or splitting up words with whitespace in them.
1784
1785     @args = ( "echo surprise" );
1786
1787     exec @args;               # subject to shell escapes
1788                                 # if @args == 1
1789     exec { $args[0] } @args;  # safe even with one-arg list
1790
1791 The first version, the one without the indirect object, ran the I<echo>
1792 program, passing it C<"surprise"> an argument.  The second version didn't;
1793 it tried to run a program named I<"echo surprise">, didn't find it, and set
1794 C<$?> to a non-zero value indicating failure.
1795
1796 Beginning with v5.6.0, Perl attempts to flush all files opened for
1797 output before the exec, but this may not be supported on some platforms
1798 (see L<perlport>).  To be safe, you may need to set C<$|> ($AUTOFLUSH
1799 in English) or call the C<autoflush()> method of C<IO::Handle> on any
1800 open handles to avoid lost output.
1801
1802 Note that C<exec> will not call your C<END> blocks, nor will it invoke
1803 C<DESTROY> methods on your objects.
1804
1805 =item exists EXPR
1806 X<exists> X<autovivification>
1807
1808 Given an expression that specifies an element of a hash, returns true if the
1809 specified element in the hash has ever been initialized, even if the
1810 corresponding value is undefined.
1811
1812     print "Exists\n"    if exists $hash{$key};
1813     print "Defined\n"   if defined $hash{$key};
1814     print "True\n"      if $hash{$key};
1815
1816 exists may also be called on array elements, but its behavior is much less
1817 obvious and is strongly tied to the use of L</delete> on arrays.  B<Be aware>
1818 that calling exists on array values is deprecated and likely to be removed in
1819 a future version of Perl.
1820
1821     print "Exists\n"    if exists $array[$index];
1822     print "Defined\n"   if defined $array[$index];
1823     print "True\n"      if $array[$index];
1824
1825 A hash or array element can be true only if it's defined and defined only if
1826 it exists, but the reverse doesn't necessarily hold true.
1827
1828 Given an expression that specifies the name of a subroutine,
1829 returns true if the specified subroutine has ever been declared, even
1830 if it is undefined.  Mentioning a subroutine name for exists or defined
1831 does not count as declaring it.  Note that a subroutine that does not
1832 exist may still be callable: its package may have an C<AUTOLOAD>
1833 method that makes it spring into existence the first time that it is
1834 called; see L<perlsub>.
1835
1836     print "Exists\n"  if exists &subroutine;
1837     print "Defined\n" if defined &subroutine;
1838
1839 Note that the EXPR can be arbitrarily complicated as long as the final
1840 operation is a hash or array key lookup or subroutine name:
1841
1842     if (exists $ref->{A}->{B}->{$key})  { }
1843     if (exists $hash{A}{B}{$key})       { }
1844
1845     if (exists $ref->{A}->{B}->[$ix])   { }
1846     if (exists $hash{A}{B}[$ix])        { }
1847
1848     if (exists &{$ref->{A}{B}{$key}})   { }
1849
1850 Although the mostly deeply nested array or hash will not spring into
1851 existence just because its existence was tested, any intervening ones will.
1852 Thus C<< $ref->{"A"} >> and C<< $ref->{"A"}->{"B"} >> will spring
1853 into existence due to the existence test for the $key element above.
1854 This happens anywhere the arrow operator is used, including even here:
1855
1856     undef $ref;
1857     if (exists $ref->{"Some key"})    { }
1858     print $ref;  # prints HASH(0x80d3d5c)
1859
1860 This surprising autovivification in what does not at first--or even
1861 second--glance appear to be an lvalue context may be fixed in a future
1862 release.
1863
1864 Use of a subroutine call, rather than a subroutine name, as an argument
1865 to exists() is an error.
1866
1867     exists &sub;    # OK
1868     exists &sub();  # Error
1869
1870 =item exit EXPR
1871 X<exit> X<terminate> X<abort>
1872
1873 =item exit
1874
1875 Evaluates EXPR and exits immediately with that value.    Example:
1876
1877     $ans = <STDIN>;
1878     exit 0 if $ans =~ /^[Xx]/;
1879
1880 See also C<die>.  If EXPR is omitted, exits with C<0> status.  The only
1881 universally recognized values for EXPR are C<0> for success and C<1>
1882 for error; other values are subject to interpretation depending on the
1883 environment in which the Perl program is running.  For example, exiting
1884 69 (EX_UNAVAILABLE) from a I<sendmail> incoming-mail filter will cause
1885 the mailer to return the item undelivered, but that's not true everywhere.
1886
1887 Don't use C<exit> to abort a subroutine if there's any chance that
1888 someone might want to trap whatever error happened.  Use C<die> instead,
1889 which can be trapped by an C<eval>.
1890
1891 The exit() function does not always exit immediately.  It calls any
1892 defined C<END> routines first, but these C<END> routines may not
1893 themselves abort the exit.  Likewise any object destructors that need to
1894 be called are called before the real exit.  C<END> routines and destructors
1895 can change the exit status by modifying C<$?>. If this is a problem, you
1896 can call C<POSIX:_exit($status)> to avoid END and destructor processing.
1897 See L<perlmod> for details.
1898
1899 =item exp EXPR
1900 X<exp> X<exponential> X<antilog> X<antilogarithm> X<e>
1901
1902 =item exp
1903
1904 Returns I<e> (the natural logarithm base) to the power of EXPR.
1905 If EXPR is omitted, gives C<exp($_)>.
1906
1907 =item fcntl FILEHANDLE,FUNCTION,SCALAR
1908 X<fcntl>
1909
1910 Implements the fcntl(2) function.  You'll probably have to say
1911
1912     use Fcntl;
1913
1914 first to get the correct constant definitions.  Argument processing and
1915 value returned work just like C<ioctl> below.
1916 For example:
1917
1918     use Fcntl;
1919     fcntl($filehandle, F_GETFL, $packed_return_buffer)
1920         or die "can't fcntl F_GETFL: $!";
1921
1922 You don't have to check for C<defined> on the return from C<fcntl>.
1923 Like C<ioctl>, it maps a C<0> return from the system call into
1924 C<"0 but true"> in Perl.  This string is true in boolean context and C<0>
1925 in numeric context.  It is also exempt from the normal B<-w> warnings
1926 on improper numeric conversions.
1927
1928 Note that C<fcntl> raises an exception if used on a machine that
1929 doesn't implement fcntl(2).  See the Fcntl module or your fcntl(2)
1930 manpage to learn what functions are available on your system.
1931
1932 Here's an example of setting a filehandle named C<REMOTE> to be
1933 non-blocking at the system level.  You'll have to negotiate C<$|>
1934 on your own, though.
1935
1936     use Fcntl qw(F_GETFL F_SETFL O_NONBLOCK);
1937
1938     $flags = fcntl(REMOTE, F_GETFL, 0)
1939                 or die "Can't get flags for the socket: $!\n";
1940
1941     $flags = fcntl(REMOTE, F_SETFL, $flags | O_NONBLOCK)
1942                 or die "Can't set flags for the socket: $!\n";
1943
1944 =item fileno FILEHANDLE
1945 X<fileno>
1946
1947 Returns the file descriptor for a filehandle, or undefined if the
1948 filehandle is not open.  If there is no real file descriptor at the OS
1949 level, as can happen with filehandles connected to memory objects via
1950 C<open> with a reference for the third argument, -1 is returned.
1951
1952 This is mainly useful for constructing
1953 bitmaps for C<select> and low-level POSIX tty-handling operations.
1954 If FILEHANDLE is an expression, the value is taken as an indirect
1955 filehandle, generally its name.
1956
1957 You can use this to find out whether two handles refer to the
1958 same underlying descriptor:
1959
1960     if (fileno(THIS) == fileno(THAT)) {
1961         print "THIS and THAT are dups\n";
1962     }
1963
1964 =item flock FILEHANDLE,OPERATION
1965 X<flock> X<lock> X<locking>
1966
1967 Calls flock(2), or an emulation of it, on FILEHANDLE.  Returns true
1968 for success, false on failure.  Produces a fatal error if used on a
1969 machine that doesn't implement flock(2), fcntl(2) locking, or lockf(3).
1970 C<flock> is Perl's portable file-locking interface, although it locks
1971 entire files only, not records.
1972
1973 Two potentially non-obvious but traditional C<flock> semantics are
1974 that it waits indefinitely until the lock is granted, and that its locks
1975 are B<merely advisory>.  Such discretionary locks are more flexible, but
1976 offer fewer guarantees.  This means that programs that do not also use
1977 C<flock> may modify files locked with C<flock>.  See L<perlport>, 
1978 your port's specific documentation, and your system-specific local manpages
1979 for details.  It's best to assume traditional behavior if you're writing
1980 portable programs.  (But if you're not, you should as always feel perfectly
1981 free to write for your own system's idiosyncrasies (sometimes called
1982 "features").  Slavish adherence to portability concerns shouldn't get
1983 in the way of your getting your job done.)
1984
1985 OPERATION is one of LOCK_SH, LOCK_EX, or LOCK_UN, possibly combined with
1986 LOCK_NB.  These constants are traditionally valued 1, 2, 8 and 4, but
1987 you can use the symbolic names if you import them from the L<Fcntl> module,
1988 either individually, or as a group using the C<:flock> tag.  LOCK_SH
1989 requests a shared lock, LOCK_EX requests an exclusive lock, and LOCK_UN
1990 releases a previously requested lock.  If LOCK_NB is bitwise-or'ed with
1991 LOCK_SH or LOCK_EX, then C<flock> returns immediately rather than blocking
1992 waiting for the lock; check the return status to see if you got it.
1993
1994 To avoid the possibility of miscoordination, Perl now flushes FILEHANDLE
1995 before locking or unlocking it.
1996
1997 Note that the emulation built with lockf(3) doesn't provide shared
1998 locks, and it requires that FILEHANDLE be open with write intent.  These
1999 are the semantics that lockf(3) implements.  Most if not all systems
2000 implement lockf(3) in terms of fcntl(2) locking, though, so the
2001 differing semantics shouldn't bite too many people.
2002
2003 Note that the fcntl(2) emulation of flock(3) requires that FILEHANDLE
2004 be open with read intent to use LOCK_SH and requires that it be open
2005 with write intent to use LOCK_EX.
2006
2007 Note also that some versions of C<flock> cannot lock things over the
2008 network; you would need to use the more system-specific C<fcntl> for
2009 that.  If you like you can force Perl to ignore your system's flock(2)
2010 function, and so provide its own fcntl(2)-based emulation, by passing
2011 the switch C<-Ud_flock> to the F<Configure> program when you configure
2012 and build a new Perl.
2013
2014 Here's a mailbox appender for BSD systems.
2015
2016     use Fcntl qw(:flock SEEK_END); # import LOCK_* and SEEK_END constants
2017
2018     sub lock {
2019         my ($fh) = @_;
2020         flock($fh, LOCK_EX) or die "Cannot lock mailbox - $!\n";
2021
2022         # and, in case someone appended while we were waiting...
2023         seek($fh, 0, SEEK_END) or die "Cannot seek - $!\n";
2024     }
2025
2026     sub unlock {
2027         my ($fh) = @_;
2028         flock($fh, LOCK_UN) or die "Cannot unlock mailbox - $!\n";
2029     }
2030
2031     open(my $mbox, ">>", "/usr/spool/mail/$ENV{'USER'}")
2032         or die "Can't open mailbox: $!";
2033
2034     lock($mbox);
2035     print $mbox $msg,"\n\n";
2036     unlock($mbox);
2037
2038 On systems that support a real flock(2), locks are inherited across fork()
2039 calls, whereas those that must resort to the more capricious fcntl(2)
2040 function lose their locks, making it seriously harder to write servers.
2041
2042 See also L<DB_File> for other flock() examples.
2043
2044 =item fork
2045 X<fork> X<child> X<parent>
2046
2047 Does a fork(2) system call to create a new process running the
2048 same program at the same point.  It returns the child pid to the
2049 parent process, C<0> to the child process, or C<undef> if the fork is
2050 unsuccessful.  File descriptors (and sometimes locks on those descriptors)
2051 are shared, while everything else is copied.  On most systems supporting
2052 fork(), great care has gone into making it extremely efficient (for
2053 example, using copy-on-write technology on data pages), making it the
2054 dominant paradigm for multitasking over the last few decades.
2055
2056 Beginning with v5.6.0, Perl attempts to flush all files opened for
2057 output before forking the child process, but this may not be supported
2058 on some platforms (see L<perlport>).  To be safe, you may need to set
2059 C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method of
2060 C<IO::Handle> on any open handles to avoid duplicate output.
2061
2062 If you C<fork> without ever waiting on your children, you will
2063 accumulate zombies.  On some systems, you can avoid this by setting
2064 C<$SIG{CHLD}> to C<"IGNORE">.  See also L<perlipc> for more examples of
2065 forking and reaping moribund children.
2066
2067 Note that if your forked child inherits system file descriptors like
2068 STDIN and STDOUT that are actually connected by a pipe or socket, even
2069 if you exit, then the remote server (such as, say, a CGI script or a
2070 backgrounded job launched from a remote shell) won't think you're done.
2071 You should reopen those to F</dev/null> if it's any issue.
2072
2073 =item format
2074 X<format>
2075
2076 Declare a picture format for use by the C<write> function.  For
2077 example:
2078
2079     format Something =
2080         Test: @<<<<<<<< @||||| @>>>>>
2081               $str,     $%,    '$' . int($num)
2082     .
2083
2084     $str = "widget";
2085     $num = $cost/$quantity;
2086     $~ = 'Something';
2087     write;
2088
2089 See L<perlform> for many details and examples.
2090
2091 =item formline PICTURE,LIST
2092 X<formline>
2093
2094 This is an internal function used by C<format>s, though you may call it,
2095 too.  It formats (see L<perlform>) a list of values according to the
2096 contents of PICTURE, placing the output into the format output
2097 accumulator, C<$^A> (or C<$ACCUMULATOR> in English).
2098 Eventually, when a C<write> is done, the contents of
2099 C<$^A> are written to some filehandle.  You could also read C<$^A>
2100 and then set C<$^A> back to C<"">.  Note that a format typically
2101 does one C<formline> per line of form, but the C<formline> function itself
2102 doesn't care how many newlines are embedded in the PICTURE.  This means
2103 that the C<~> and C<~~> tokens treat the entire PICTURE as a single line.
2104 You may therefore need to use multiple formlines to implement a single
2105 record format, just like the C<format> compiler.
2106
2107 Be careful if you put double quotes around the picture, because an C<@>
2108 character may be taken to mean the beginning of an array name.
2109 C<formline> always returns true.  See L<perlform> for other examples.
2110
2111 If you are trying to use this instead of C<write> to capture the output,
2112 you may find it easier to open a filehandle to a scalar
2113 (C<< open $fh, ">", \$output >>) and write to that instead.
2114
2115 =item getc FILEHANDLE
2116 X<getc> X<getchar> X<character> X<file, read>
2117
2118 =item getc
2119
2120 Returns the next character from the input file attached to FILEHANDLE,
2121 or the undefined value at end of file or if there was an error (in
2122 the latter case C<$!> is set).  If FILEHANDLE is omitted, reads from
2123 STDIN.  This is not particularly efficient.  However, it cannot be
2124 used by itself to fetch single characters without waiting for the user
2125 to hit enter.  For that, try something more like:
2126
2127     if ($BSD_STYLE) {
2128         system "stty cbreak </dev/tty >/dev/tty 2>&1";
2129     }
2130     else {
2131         system "stty", '-icanon', 'eol', "\001";
2132     }
2133
2134     $key = getc(STDIN);
2135
2136     if ($BSD_STYLE) {
2137         system "stty -cbreak </dev/tty >/dev/tty 2>&1";
2138     }
2139     else {
2140         system 'stty', 'icanon', 'eol', '^@'; # ASCII NUL
2141     }
2142     print "\n";
2143
2144 Determination of whether $BSD_STYLE should be set
2145 is left as an exercise to the reader.
2146
2147 The C<POSIX::getattr> function can do this more portably on
2148 systems purporting POSIX compliance.  See also the C<Term::ReadKey>
2149 module from your nearest CPAN site; details on CPAN can be found under
2150 L<perlmodlib/CPAN>.
2151
2152 =item getlogin
2153 X<getlogin> X<login>
2154
2155 This implements the C library function of the same name, which on most
2156 systems returns the current login from F</etc/utmp>, if any.  If it
2157 returns the empty string, use C<getpwuid>.
2158
2159     $login = getlogin || getpwuid($<) || "Kilroy";
2160
2161 Do not consider C<getlogin> for authentication: it is not as
2162 secure as C<getpwuid>.
2163
2164 =item getpeername SOCKET
2165 X<getpeername> X<peer>
2166
2167 Returns the packed sockaddr address of the other end of the SOCKET
2168 connection.
2169
2170     use Socket;
2171     $hersockaddr    = getpeername(SOCK);
2172     ($port, $iaddr) = sockaddr_in($hersockaddr);
2173     $herhostname    = gethostbyaddr($iaddr, AF_INET);
2174     $herstraddr     = inet_ntoa($iaddr);
2175
2176 =item getpgrp PID
2177 X<getpgrp> X<group>
2178
2179 Returns the current process group for the specified PID.  Use
2180 a PID of C<0> to get the current process group for the
2181 current process.  Will raise an exception if used on a machine that
2182 doesn't implement getpgrp(2).  If PID is omitted, returns the process
2183 group of the current process.  Note that the POSIX version of C<getpgrp>
2184 does not accept a PID argument, so only C<PID==0> is truly portable.
2185
2186 =item getppid
2187 X<getppid> X<parent> X<pid>
2188
2189 Returns the process id of the parent process.
2190
2191 Note for Linux users: on Linux, the C functions C<getpid()> and
2192 C<getppid()> return different values from different threads. In order to
2193 be portable, this behavior is not reflected by the Perl-level function
2194 C<getppid()>, that returns a consistent value across threads. If you want
2195 to call the underlying C<getppid()>, you may use the CPAN module
2196 C<Linux::Pid>.
2197
2198 =item getpriority WHICH,WHO
2199 X<getpriority> X<priority> X<nice>
2200
2201 Returns the current priority for a process, a process group, or a user.
2202 (See C<getpriority(2)>.)  Will raise a fatal exception if used on a
2203 machine that doesn't implement getpriority(2).
2204
2205 =item getpwnam NAME
2206 X<getpwnam> X<getgrnam> X<gethostbyname> X<getnetbyname> X<getprotobyname>
2207 X<getpwuid> X<getgrgid> X<getservbyname> X<gethostbyaddr> X<getnetbyaddr>
2208 X<getprotobynumber> X<getservbyport> X<getpwent> X<getgrent> X<gethostent>
2209 X<getnetent> X<getprotoent> X<getservent> X<setpwent> X<setgrent> X<sethostent>
2210 X<setnetent> X<setprotoent> X<setservent> X<endpwent> X<endgrent> X<endhostent>
2211 X<endnetent> X<endprotoent> X<endservent> 
2212
2213 =item getgrnam NAME
2214
2215 =item gethostbyname NAME
2216
2217 =item getnetbyname NAME
2218
2219 =item getprotobyname NAME
2220
2221 =item getpwuid UID
2222
2223 =item getgrgid GID
2224
2225 =item getservbyname NAME,PROTO
2226
2227 =item gethostbyaddr ADDR,ADDRTYPE
2228
2229 =item getnetbyaddr ADDR,ADDRTYPE
2230
2231 =item getprotobynumber NUMBER
2232
2233 =item getservbyport PORT,PROTO
2234
2235 =item getpwent
2236
2237 =item getgrent
2238
2239 =item gethostent
2240
2241 =item getnetent
2242
2243 =item getprotoent
2244
2245 =item getservent
2246
2247 =item setpwent
2248
2249 =item setgrent
2250
2251 =item sethostent STAYOPEN
2252
2253 =item setnetent STAYOPEN
2254
2255 =item setprotoent STAYOPEN
2256
2257 =item setservent STAYOPEN
2258
2259 =item endpwent
2260
2261 =item endgrent
2262
2263 =item endhostent
2264
2265 =item endnetent
2266
2267 =item endprotoent
2268
2269 =item endservent
2270
2271 These routines are the same as their counterparts in the
2272 system C library.  In list context, the return values from the
2273 various get routines are as follows:
2274
2275     ($name,$passwd,$uid,$gid,
2276        $quota,$comment,$gcos,$dir,$shell,$expire) = getpw*
2277     ($name,$passwd,$gid,$members) = getgr*
2278     ($name,$aliases,$addrtype,$length,@addrs) = gethost*
2279     ($name,$aliases,$addrtype,$net) = getnet*
2280     ($name,$aliases,$proto) = getproto*
2281     ($name,$aliases,$port,$proto) = getserv*
2282
2283 (If the entry doesn't exist you get an empty list.)
2284
2285 The exact meaning of the $gcos field varies but it usually contains
2286 the real name of the user (as opposed to the login name) and other
2287 information pertaining to the user.  Beware, however, that in many
2288 system users are able to change this information and therefore it
2289 cannot be trusted and therefore the $gcos is tainted (see
2290 L<perlsec>).  The $passwd and $shell, user's encrypted password and
2291 login shell, are also tainted, for the same reason.
2292
2293 In scalar context, you get the name, unless the function was a
2294 lookup by name, in which case you get the other thing, whatever it is.
2295 (If the entry doesn't exist you get the undefined value.)  For example:
2296
2297     $uid   = getpwnam($name);
2298     $name  = getpwuid($num);
2299     $name  = getpwent();
2300     $gid   = getgrnam($name);
2301     $name  = getgrgid($num);
2302     $name  = getgrent();
2303     #etc.
2304
2305 In I<getpw*()> the fields $quota, $comment, and $expire are special
2306 in that they are unsupported on many systems.  If the
2307 $quota is unsupported, it is an empty scalar.  If it is supported, it
2308 usually encodes the disk quota.  If the $comment field is unsupported,
2309 it is an empty scalar.  If it is supported it usually encodes some
2310 administrative comment about the user.  In some systems the $quota
2311 field may be $change or $age, fields that have to do with password
2312 aging.  In some systems the $comment field may be $class.  The $expire
2313 field, if present, encodes the expiration period of the account or the
2314 password.  For the availability and the exact meaning of these fields
2315 in your system, please consult getpwnam(3) and your system's 
2316 F<pwd.h> file.  You can also find out from within Perl what your
2317 $quota and $comment fields mean and whether you have the $expire field
2318 by using the C<Config> module and the values C<d_pwquota>, C<d_pwage>,
2319 C<d_pwchange>, C<d_pwcomment>, and C<d_pwexpire>.  Shadow password
2320 files are supported only if your vendor has implemented them in the
2321 intuitive fashion that calling the regular C library routines gets the
2322 shadow versions if you're running under privilege or if there exists
2323 the shadow(3) functions as found in System V (this includes Solaris
2324 and Linux).  Those systems that implement a proprietary shadow password
2325 facility are unlikely to be supported.
2326
2327 The $members value returned by I<getgr*()> is a space-separated list of
2328 the login names of the members of the group.
2329
2330 For the I<gethost*()> functions, if the C<h_errno> variable is supported in
2331 C, it will be returned to you via C<$?> if the function call fails.  The
2332 C<@addrs> value returned by a successful call is a list of raw
2333 addresses returned by the corresponding library call.  In the
2334 Internet domain, each address is four bytes long; you can unpack it
2335 by saying something like:
2336
2337     ($a,$b,$c,$d) = unpack('W4',$addr[0]);
2338
2339 The Socket library makes this slightly easier:
2340
2341     use Socket;
2342     $iaddr = inet_aton("127.1"); # or whatever address
2343     $name  = gethostbyaddr($iaddr, AF_INET);
2344
2345     # or going the other way
2346     $straddr = inet_ntoa($iaddr);
2347
2348 In the opposite way, to resolve a hostname to the IP address
2349 you can write this:
2350
2351     use Socket;
2352     $packed_ip = gethostbyname("www.perl.org");
2353     if (defined $packed_ip) {
2354         $ip_address = inet_ntoa($packed_ip);
2355     }
2356
2357 Make sure <gethostbyname()> is called in SCALAR context and that
2358 its return value is checked for definedness.
2359
2360 If you get tired of remembering which element of the return list
2361 contains which return value, by-name interfaces are provided
2362 in standard modules: C<File::stat>, C<Net::hostent>, C<Net::netent>,
2363 C<Net::protoent>, C<Net::servent>, C<Time::gmtime>, C<Time::localtime>,
2364 and C<User::grent>.  These override the normal built-ins, supplying
2365 versions that return objects with the appropriate names
2366 for each field.  For example:
2367
2368    use File::stat;
2369    use User::pwent;
2370    $is_his = (stat($filename)->uid == pwent($whoever)->uid);
2371
2372 Even though it looks as though they're the same method calls (uid),
2373 they aren't, because a C<File::stat> object is different from
2374 a C<User::pwent> object.
2375
2376 =item getsockname SOCKET
2377 X<getsockname>
2378
2379 Returns the packed sockaddr address of this end of the SOCKET connection,
2380 in case you don't know the address because you have several different
2381 IPs that the connection might have come in on.
2382
2383     use Socket;
2384     $mysockaddr = getsockname(SOCK);
2385     ($port, $myaddr) = sockaddr_in($mysockaddr);
2386     printf "Connect to %s [%s]\n",
2387        scalar gethostbyaddr($myaddr, AF_INET),
2388        inet_ntoa($myaddr);
2389
2390 =item getsockopt SOCKET,LEVEL,OPTNAME
2391 X<getsockopt>
2392
2393 Queries the option named OPTNAME associated with SOCKET at a given LEVEL.
2394 Options may exist at multiple protocol levels depending on the socket
2395 type, but at least the uppermost socket level SOL_SOCKET (defined in the
2396 C<Socket> module) will exist. To query options at another level the
2397 protocol number of the appropriate protocol controlling the option
2398 should be supplied. For example, to indicate that an option is to be
2399 interpreted by the TCP protocol, LEVEL should be set to the protocol
2400 number of TCP, which you can get using C<getprotobyname>.
2401
2402 The function returns a packed string representing the requested socket
2403 option, or C<undef> on error, with the reason for the error placed in
2404 C<$!>. Just what is in the packed string depends on LEVEL and OPTNAME;
2405 consult getsockopt(2) for details.  A common case is that the option is an
2406 integer, in which case the result is a packed integer, which you can decode
2407 using C<unpack> with the C<i> (or C<I>) format.
2408
2409 Here's an example to test whether Nagle's algorithm is enabled on a socket:
2410
2411     use Socket qw(:all);
2412
2413     defined(my $tcp = getprotobyname("tcp"))
2414         or die "Could not determine the protocol number for tcp";
2415     # my $tcp = IPPROTO_TCP; # Alternative
2416     my $packed = getsockopt($socket, $tcp, TCP_NODELAY)
2417         or die "getsockopt TCP_NODELAY: $!";
2418     my $nodelay = unpack("I", $packed);
2419     print "Nagle's algorithm is turned ", $nodelay ? "off\n" : "on\n";
2420
2421
2422 =item given EXPR BLOCK
2423 X<given>
2424
2425 =item given BLOCK
2426
2427 C<given> is analogous to the C<switch> keyword in other languages. C<given>
2428 and C<when> are used in Perl to implement C<switch>/C<case> like statements.
2429 Only available after Perl 5.10.  For example:
2430
2431     use v5.10;
2432     given ($fruit) {
2433         when (/apples?/) {
2434             print "I like apples."
2435         }
2436         when (/oranges?/) {
2437             print "I don't like oranges."
2438         }
2439         default {
2440             print "I don't like anything"
2441         }
2442     }
2443
2444 See L<perlsyn/"Switch statements"> for detailed information.
2445
2446 =item glob EXPR
2447 X<glob> X<wildcard> X<filename, expansion> X<expand>
2448
2449 =item glob
2450
2451 In list context, returns a (possibly empty) list of filename expansions on
2452 the value of EXPR such as the standard Unix shell F</bin/csh> would do. In
2453 scalar context, glob iterates through such filename expansions, returning
2454 undef when the list is exhausted. This is the internal function
2455 implementing the C<< <*.c> >> operator, but you can use it directly. If
2456 EXPR is omitted, C<$_> is used.  The C<< <*.c> >> operator is discussed in
2457 more detail in L<perlop/"I/O Operators">.
2458
2459 Note that C<glob> splits its arguments on whitespace and treats
2460 each segment as separate pattern.  As such, C<glob("*.c *.h")> 
2461 matches all files with a F<.c> or F<.h> extension.  The expression
2462 C<glob(".* *")> matches all files in the current working directory.
2463
2464 If non-empty braces are the only wildcard characters used in the
2465 C<glob>, no filenames are matched, but potentially many strings
2466 are returned.  For example, this produces nine strings, one for
2467 each pairing of fruits and colors:
2468
2469     @many =  glob "{apple,tomato,cherry}={green,yellow,red}";
2470
2471 Beginning with v5.6.0, this operator is implemented using the standard
2472 C<File::Glob> extension.  See L<File::Glob> for details, including
2473 C<bsd_glob> which does not treat whitespace as a pattern separator.
2474
2475 =item gmtime EXPR
2476 X<gmtime> X<UTC> X<Greenwich>
2477
2478 =item gmtime
2479
2480 Works just like L<localtime> but the returned values are
2481 localized for the standard Greenwich time zone.
2482
2483 Note: When called in list context, $isdst, the last value
2484 returned by gmtime, is always C<0>.  There is no
2485 Daylight Saving Time in GMT.
2486
2487 See L<perlport/gmtime> for portability concerns.
2488
2489 =item goto LABEL
2490 X<goto> X<jump> X<jmp>
2491
2492 =item goto EXPR
2493
2494 =item goto &NAME
2495
2496 The C<goto-LABEL> form finds the statement labeled with LABEL and
2497 resumes execution there. It can't be used to get out of a block or
2498 subroutine given to C<sort>.  It can be used to go almost anywhere
2499 else within the dynamic scope, including out of subroutines, but it's
2500 usually better to use some other construct such as C<last> or C<die>.
2501 The author of Perl has never felt the need to use this form of C<goto>
2502 (in Perl, that is; C is another matter).  (The difference is that C
2503 does not offer named loops combined with loop control.  Perl does, and
2504 this replaces most structured uses of C<goto> in other languages.)
2505
2506 The C<goto-EXPR> form expects a label name, whose scope will be resolved
2507 dynamically.  This allows for computed C<goto>s per FORTRAN, but isn't
2508 necessarily recommended if you're optimizing for maintainability:
2509
2510     goto ("FOO", "BAR", "GLARCH")[$i];
2511
2512 As shown in this example, C<goto-EXPR> is exempt from the "looks like a
2513 function" rule. A pair of parentheses following it does not (necessarily)
2514 delimit its argument. C<goto("NE")."XT"> is equivalent to C<goto NEXT>.
2515
2516 Use of C<goto-LABEL> or C<goto-EXPR> to jump into a construct is
2517 deprecated and will issue a warning.  Even then, it may not be used to
2518 go into any construct that requires initialization, such as a
2519 subroutine or a C<foreach> loop.  It also can't be used to go into a
2520 construct that is optimized away.
2521
2522 The C<goto-&NAME> form is quite different from the other forms of
2523 C<goto>.  In fact, it isn't a goto in the normal sense at all, and
2524 doesn't have the stigma associated with other gotos.  Instead, it
2525 exits the current subroutine (losing any changes set by local()) and
2526 immediately calls in its place the named subroutine using the current
2527 value of @_.  This is used by C<AUTOLOAD> subroutines that wish to
2528 load another subroutine and then pretend that the other subroutine had
2529 been called in the first place (except that any modifications to C<@_>
2530 in the current subroutine are propagated to the other subroutine.)
2531 After the C<goto>, not even C<caller> will be able to tell that this
2532 routine was called first.
2533
2534 NAME needn't be the name of a subroutine; it can be a scalar variable
2535 containing a code reference or a block that evaluates to a code
2536 reference.
2537
2538 =item grep BLOCK LIST
2539 X<grep>
2540
2541 =item grep EXPR,LIST
2542
2543 This is similar in spirit to, but not the same as, grep(1) and its
2544 relatives.  In particular, it is not limited to using regular expressions.
2545
2546 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
2547 C<$_> to each element) and returns the list value consisting of those
2548 elements for which the expression evaluated to true.  In scalar
2549 context, returns the number of times the expression was true.
2550
2551     @foo = grep(!/^#/, @bar);    # weed out comments
2552
2553 or equivalently,
2554
2555     @foo = grep {!/^#/} @bar;    # weed out comments
2556
2557 Note that C<$_> is an alias to the list value, so it can be used to
2558 modify the elements of the LIST.  While this is useful and supported,
2559 it can cause bizarre results if the elements of LIST are not variables.
2560 Similarly, grep returns aliases into the original list, much as a for
2561 loop's index variable aliases the list elements.  That is, modifying an
2562 element of a list returned by grep (for example, in a C<foreach>, C<map>
2563 or another C<grep>) actually modifies the element in the original list.
2564 This is usually something to be avoided when writing clear code.
2565
2566 If C<$_> is lexical in the scope where the C<grep> appears (because it has
2567 been declared with C<my $_>) then, in addition to being locally aliased to
2568 the list elements, C<$_> keeps being lexical inside the block; i.e., it
2569 can't be seen from the outside, avoiding any potential side-effects.
2570
2571 See also L</map> for a list composed of the results of the BLOCK or EXPR.
2572
2573 =item hex EXPR
2574 X<hex> X<hexadecimal>
2575
2576 =item hex
2577
2578 Interprets EXPR as a hex string and returns the corresponding value.
2579 (To convert strings that might start with either C<0>, C<0x>, or C<0b>, see
2580 L</oct>.)  If EXPR is omitted, uses C<$_>.
2581
2582     print hex '0xAf'; # prints '175'
2583     print hex 'aF';   # same
2584
2585 Hex strings may only represent integers.  Strings that would cause
2586 integer overflow trigger a warning.  Leading whitespace is not stripped,
2587 unlike oct(). To present something as hex, look into L</printf>,
2588 L</sprintf>, and L</unpack>.
2589
2590 =item import LIST
2591 X<import>
2592
2593 There is no builtin C<import> function.  It is just an ordinary
2594 method (subroutine) defined (or inherited) by modules that wish to export
2595 names to another module.  The C<use> function calls the C<import> method
2596 for the package used.  See also L</use>, L<perlmod>, and L<Exporter>.
2597
2598 =item index STR,SUBSTR,POSITION
2599 X<index> X<indexOf> X<InStr>
2600
2601 =item index STR,SUBSTR
2602
2603 The index function searches for one string within another, but without
2604 the wildcard-like behavior of a full regular-expression pattern match.
2605 It returns the position of the first occurrence of SUBSTR in STR at
2606 or after POSITION.  If POSITION is omitted, starts searching from the
2607 beginning of the string.  POSITION before the beginning of the string
2608 or after its end is treated as if it were the beginning or the end,
2609 respectively.  POSITION and the return value are based at C<0> (or whatever
2610 you've set the C<$[> variable to--but don't do that).  If the substring
2611 is not found, C<index> returns one less than the base, ordinarily C<-1>.
2612
2613 =item int EXPR
2614 X<int> X<integer> X<truncate> X<trunc> X<floor>
2615
2616 =item int
2617
2618 Returns the integer portion of EXPR.  If EXPR is omitted, uses C<$_>.
2619 You should not use this function for rounding: one because it truncates
2620 towards C<0>, and two because machine representations of floating-point
2621 numbers can sometimes produce counterintuitive results.  For example,
2622 C<int(-6.725/0.025)> produces -268 rather than the correct -269; that's
2623 because it's really more like -268.99999999999994315658 instead.  Usually,
2624 the C<sprintf>, C<printf>, or the C<POSIX::floor> and C<POSIX::ceil>
2625 functions will serve you better than will int().
2626
2627 =item ioctl FILEHANDLE,FUNCTION,SCALAR
2628 X<ioctl>
2629
2630 Implements the ioctl(2) function.  You'll probably first have to say
2631
2632     require "sys/ioctl.ph";  # probably in $Config{archlib}/sys/ioctl.ph
2633
2634 to get the correct function definitions.  If F<sys/ioctl.ph> doesn't
2635 exist or doesn't have the correct definitions you'll have to roll your
2636 own, based on your C header files such as F<< <sys/ioctl.h> >>.
2637 (There is a Perl script called B<h2ph> that comes with the Perl kit that
2638 may help you in this, but it's nontrivial.)  SCALAR will be read and/or
2639 written depending on the FUNCTION; a C pointer to the string value of SCALAR
2640 will be passed as the third argument of the actual C<ioctl> call.  (If SCALAR
2641 has no string value but does have a numeric value, that value will be
2642 passed rather than a pointer to the string value.  To guarantee this to be
2643 true, add a C<0> to the scalar before using it.)  The C<pack> and C<unpack>
2644 functions may be needed to manipulate the values of structures used by
2645 C<ioctl>.
2646
2647 The return value of C<ioctl> (and C<fcntl>) is as follows:
2648
2649     if OS returns:      then Perl returns:
2650         -1               undefined value
2651          0              string "0 but true"
2652     anything else           that number
2653
2654 Thus Perl returns true on success and false on failure, yet you can
2655 still easily determine the actual value returned by the operating
2656 system:
2657
2658     $retval = ioctl(...) || -1;
2659     printf "System returned %d\n", $retval;
2660
2661 The special string C<"0 but true"> is exempt from B<-w> complaints
2662 about improper numeric conversions.
2663
2664 =item join EXPR,LIST
2665 X<join>
2666
2667 Joins the separate strings of LIST into a single string with fields
2668 separated by the value of EXPR, and returns that new string.  Example:
2669
2670     $rec = join(':', $login,$passwd,$uid,$gid,$gcos,$home,$shell);
2671
2672 Beware that unlike C<split>, C<join> doesn't take a pattern as its
2673 first argument.  Compare L</split>.
2674
2675 =item keys HASH
2676 X<keys> X<key>
2677
2678 =item keys ARRAY
2679
2680 =item keys EXPR
2681
2682 Returns a list consisting of all the keys of the named hash, or the indices
2683 of an array. (In scalar context, returns the number of keys or indices.)
2684
2685 The keys of a hash are returned in an apparently random order.  The actual
2686 random order is subject to change in future versions of Perl, but it
2687 is guaranteed to be the same order as either the C<values> or C<each>
2688 function produces (given that the hash has not been modified).  Since
2689 Perl 5.8.1 the ordering can be different even between different runs of
2690 Perl for security reasons (see L<perlsec/"Algorithmic Complexity
2691 Attacks">).
2692
2693 As a side effect, calling keys() resets the internal interator of the HASH or ARRAY
2694 (see L</each>).  In particular, calling keys() in void context resets
2695 the iterator with no other overhead.
2696
2697 Here is yet another way to print your environment:
2698
2699     @keys = keys %ENV;
2700     @values = values %ENV;
2701     while (@keys) {
2702         print pop(@keys), '=', pop(@values), "\n";
2703     }
2704
2705 or how about sorted by key:
2706
2707     foreach $key (sort(keys %ENV)) {
2708         print $key, '=', $ENV{$key}, "\n";
2709     }
2710
2711 The returned values are copies of the original keys in the hash, so
2712 modifying them will not affect the original hash.  Compare L</values>.
2713
2714 To sort a hash by value, you'll need to use a C<sort> function.
2715 Here's a descending numeric sort of a hash by its values:
2716
2717     foreach $key (sort { $hash{$b} <=> $hash{$a} } keys %hash) {
2718         printf "%4d %s\n", $hash{$key}, $key;
2719     }
2720
2721 Used as an lvalue, C<keys> allows you to increase the number of hash buckets
2722 allocated for the given hash.  This can gain you a measure of efficiency if
2723 you know the hash is going to get big.  (This is similar to pre-extending
2724 an array by assigning a larger number to $#array.)  If you say
2725
2726     keys %hash = 200;
2727
2728 then C<%hash> will have at least 200 buckets allocated for it--256 of them,
2729 in fact, since it rounds up to the next power of two.  These
2730 buckets will be retained even if you do C<%hash = ()>, use C<undef
2731 %hash> if you want to free the storage while C<%hash> is still in scope.
2732 You can't shrink the number of buckets allocated for the hash using
2733 C<keys> in this way (but you needn't worry about doing this by accident,
2734 as trying has no effect). C<keys @array> in an lvalue context is a syntax
2735 error.
2736
2737 Starting with Perl 5.14, C<keys> can take a scalar EXPR, which must contain
2738 a reference to an unblessed hash or array.  The argument will be
2739 dereferenced automatically.  This aspect of C<keys> is considered highly
2740 experimental.  The exact behaviour may change in a future version of Perl.
2741
2742     for (keys $hashref) { ... }
2743     for (keys $obj->get_arrayref) { ... }
2744
2745 See also C<each>, C<values>, and C<sort>.
2746
2747 =item kill SIGNAL, LIST
2748 X<kill> X<signal>
2749
2750 Sends a signal to a list of processes.  Returns the number of
2751 processes successfully signaled (which is not necessarily the
2752 same as the number actually killed).
2753
2754     $cnt = kill 1, $child1, $child2;
2755     kill 9, @goners;
2756
2757 If SIGNAL is zero, no signal is sent to the process, but C<kill>
2758 checks whether it's I<possible> to send a signal to it (that
2759 means, to be brief, that the process is owned by the same user, or we are
2760 the super-user).  This is useful to check that a child process is still
2761 alive (even if only as a zombie) and hasn't changed its UID.  See
2762 L<perlport> for notes on the portability of this construct.
2763
2764 Unlike in the shell, if SIGNAL is negative, it kills process groups instead
2765 of processes. That means you usually want to use positive not negative signals.
2766 You may also use a signal name in quotes.
2767
2768 The behavior of kill when a I<PROCESS> number is zero or negative depends on
2769 the operating system.  For example, on POSIX-conforming systems, zero will
2770 signal the current process group and -1 will signal all processes.
2771
2772 See L<perlipc/"Signals"> for more details.
2773
2774 =item last LABEL
2775 X<last> X<break>
2776
2777 =item last
2778
2779 The C<last> command is like the C<break> statement in C (as used in
2780 loops); it immediately exits the loop in question.  If the LABEL is
2781 omitted, the command refers to the innermost enclosing loop.  The
2782 C<continue> block, if any, is not executed:
2783
2784     LINE: while (<STDIN>) {
2785         last LINE if /^$/;  # exit when done with header
2786         #...
2787     }
2788
2789 C<last> cannot be used to exit a block that returns a value such as
2790 C<eval {}>, C<sub {}>, or C<do {}>, and should not be used to exit
2791 a grep() or map() operation.
2792
2793 Note that a block by itself is semantically identical to a loop
2794 that executes once.  Thus C<last> can be used to effect an early
2795 exit out of such a block.
2796
2797 See also L</continue> for an illustration of how C<last>, C<next>, and
2798 C<redo> work.
2799
2800 =item lc EXPR
2801 X<lc> X<lowercase>
2802
2803 =item lc
2804
2805 Returns a lowercased version of EXPR.  This is the internal function
2806 implementing the C<\L> escape in double-quoted strings.
2807
2808 If EXPR is omitted, uses C<$_>.
2809
2810 What gets returned depends on several factors:
2811
2812 =over
2813
2814 =item If C<use bytes> is in effect:
2815
2816 =over
2817
2818 =item On EBCDIC platforms
2819
2820 The results are what the C language system call C<tolower()> returns.
2821
2822 =item On ASCII platforms
2823
2824 The results follow ASCII semantics.  Only characters C<A-Z> change, to C<a-z>
2825 respectively.
2826
2827 =back
2828
2829 =item Otherwise, If EXPR has the UTF8 flag set
2830
2831 If the current package has a subroutine named C<ToLower>, it will be used to
2832 change the case
2833 (See L<perlunicode/"User-Defined Case Mappings (for serious hackers only)">.)
2834 Otherwise Unicode semantics are used for the case change.
2835
2836 =item Otherwise, if C<use locale> is in effect
2837
2838 Respects current LC_CTYPE locale.  See L<perllocale>.
2839
2840 =item Otherwise, if C<use feature 'unicode_strings'> is in effect:
2841
2842 Unicode semantics are used for the case change.  Any subroutine named
2843 C<ToLower> will be ignored.
2844
2845 =item Otherwise:
2846
2847 =over
2848
2849 =item On EBCDIC platforms
2850
2851 The results are what the C language system call C<tolower()> returns.
2852
2853 =item On ASCII platforms
2854
2855 ASCII semantics are used for the case change.  The lowercase of any character
2856 outside the ASCII range is the character itself.
2857
2858 =back
2859
2860 =back
2861
2862 =item lcfirst EXPR
2863 X<lcfirst> X<lowercase>
2864
2865 =item lcfirst
2866
2867 Returns the value of EXPR with the first character lowercased.  This
2868 is the internal function implementing the C<\l> escape in
2869 double-quoted strings.
2870
2871 If EXPR is omitted, uses C<$_>.
2872
2873 This function behaves the same way under various pragmata, such as in a locale,
2874 as L</lc> does.
2875
2876 =item length EXPR
2877 X<length> X<size>
2878
2879 =item length
2880
2881 Returns the length in I<characters> of the value of EXPR.  If EXPR is
2882 omitted, returns the length of C<$_>.  If EXPR is undefined, returns
2883 C<undef>.
2884
2885 This function cannot be used on an entire array or hash to find out how
2886 many elements these have.  For that, use C<scalar @array> and C<scalar keys
2887 %hash>, respectively.
2888
2889 Like all Perl character operations, length() normally deals in logical
2890 characters, not physical bytes.  For how many bytes a string encoded as
2891 UTF-8 would take up, use C<length(Encode::encode_utf8(EXPR))> (you'll have
2892 to C<use Encode> first).  See L<Encode> and L<perlunicode>.
2893
2894 =item link OLDFILE,NEWFILE
2895 X<link>
2896
2897 Creates a new filename linked to the old filename.  Returns true for
2898 success, false otherwise.
2899
2900 =item listen SOCKET,QUEUESIZE
2901 X<listen>
2902
2903 Does the same thing that the listen(2) system call does.  Returns true if
2904 it succeeded, false otherwise.  See the example in
2905 L<perlipc/"Sockets: Client/Server Communication">.
2906
2907 =item local EXPR
2908 X<local>
2909
2910 You really probably want to be using C<my> instead, because C<local> isn't
2911 what most people think of as "local".  See
2912 L<perlsub/"Private Variables via my()"> for details.
2913
2914 A local modifies the listed variables to be local to the enclosing
2915 block, file, or eval.  If more than one value is listed, the list must
2916 be placed in parentheses.  See L<perlsub/"Temporary Values via local()">
2917 for details, including issues with tied arrays and hashes.
2918
2919 The C<delete local EXPR> construct can also be used to localize the deletion
2920 of array/hash elements to the current block.
2921 See L<perlsub/"Localized deletion of elements of composite types">.
2922
2923 =item localtime EXPR
2924 X<localtime> X<ctime>
2925
2926 =item localtime
2927
2928 Converts a time as returned by the time function to a 9-element list
2929 with the time analyzed for the local time zone.  Typically used as
2930 follows:
2931
2932     #  0    1    2     3     4    5     6     7     8
2933     ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst) =
2934                                                 localtime(time);
2935
2936 All list elements are numeric and come straight out of the C `struct
2937 tm'.  C<$sec>, C<$min>, and C<$hour> are the seconds, minutes, and hours
2938 of the specified time.
2939
2940 C<$mday> is the day of the month and C<$mon> the month in
2941 the range C<0..11>, with 0 indicating January and 11 indicating December.
2942 This makes it easy to get a month name from a list:
2943
2944     my @abbr = qw( Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec );
2945     print "$abbr[$mon] $mday";
2946     # $mon=9, $mday=18 gives "Oct 18"
2947
2948 C<$year> is the number of years since 1900, B<not> just the last two digits
2949 of the year.  That is, C<$year> is C<123> in year 2023.  The proper way
2950 to get a 4-digit year is simply:
2951
2952     $year += 1900;
2953
2954 Otherwise you create non-Y2K-compliant programs--and you wouldn't want
2955 to do that, would you?
2956
2957 To get the last two digits of the year (e.g., "01" in 2001) do:
2958
2959     $year = sprintf("%02d", $year % 100);
2960
2961 C<$wday> is the day of the week, with 0 indicating Sunday and 3 indicating
2962 Wednesday.  C<$yday> is the day of the year, in the range C<0..364>
2963 (or C<0..365> in leap years.)
2964
2965 C<$isdst> is true if the specified time occurs during Daylight Saving
2966 Time, false otherwise.
2967
2968 If EXPR is omitted, C<localtime()> uses the current time (as returned
2969 by time(3)).
2970
2971 In scalar context, C<localtime()> returns the ctime(3) value:
2972
2973     $now_string = localtime;  # e.g., "Thu Oct 13 04:54:34 1994"
2974
2975 This scalar value is B<not> locale-dependent but is a Perl builtin. For GMT
2976 instead of local time use the L</gmtime> builtin. See also the
2977 C<Time::Local> module (for converting seconds, minutes, hours, and such back to
2978 the integer value returned by time()), and the L<POSIX> module's strftime(3)
2979 and mktime(3) functions.
2980
2981 To get somewhat similar but locale-dependent date strings, set up your
2982 locale environment variables appropriately (please see L<perllocale>) and
2983 try for example:
2984
2985     use POSIX qw(strftime);
2986     $now_string = strftime "%a %b %e %H:%M:%S %Y", localtime;
2987     # or for GMT formatted appropriately for your locale:
2988     $now_string = strftime "%a %b %e %H:%M:%S %Y", gmtime;
2989
2990 Note that the C<%a> and C<%b>, the short forms of the day of the week
2991 and the month of the year, may not necessarily be three characters wide.
2992
2993 See L<perlport/localtime> for portability concerns.
2994
2995 The L<Time::gmtime> and L<Time::localtime> modules provide a convenient,
2996 by-name access mechanism to the gmtime() and localtime() functions,
2997 respectively.
2998
2999 For a comprehensive date and time representation look at the
3000 L<DateTime> module on CPAN.
3001
3002 =item lock THING
3003 X<lock>
3004
3005 This function places an advisory lock on a shared variable or referenced
3006 object contained in I<THING> until the lock goes out of scope.
3007
3008 lock() is a "weak keyword" : this means that if you've defined a function
3009 by this name (before any calls to it), that function will be called
3010 instead.  If you are not under C<use threads::shared> this does nothing.
3011 See L<threads::shared>.
3012
3013 =item log EXPR
3014 X<log> X<logarithm> X<e> X<ln> X<base>
3015
3016 =item log
3017
3018 Returns the natural logarithm (base I<e>) of EXPR.  If EXPR is omitted,
3019 returns the log of C<$_>.  To get the
3020 log of another base, use basic algebra:
3021 The base-N log of a number is equal to the natural log of that number
3022 divided by the natural log of N.  For example:
3023
3024     sub log10 {
3025         my $n = shift;
3026         return log($n)/log(10);
3027     }
3028
3029 See also L</exp> for the inverse operation.
3030
3031 =item lstat EXPR
3032 X<lstat>
3033
3034 =item lstat
3035
3036 Does the same thing as the C<stat> function (including setting the
3037 special C<_> filehandle) but stats a symbolic link instead of the file
3038 the symbolic link points to.  If symbolic links are unimplemented on
3039 your system, a normal C<stat> is done.  For much more detailed
3040 information, please see the documentation for C<stat>.
3041
3042 If EXPR is omitted, stats C<$_>.
3043
3044 =item m//
3045
3046 The match operator.  See L<perlop/"Regexp Quote-Like Operators">.
3047
3048 =item map BLOCK LIST
3049 X<map>
3050
3051 =item map EXPR,LIST
3052
3053 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
3054 C<$_> to each element) and returns the list value composed of the
3055 results of each such evaluation.  In scalar context, returns the
3056 total number of elements so generated.  Evaluates BLOCK or EXPR in
3057 list context, so each element of LIST may produce zero, one, or
3058 more elements in the returned value.
3059
3060     @chars = map(chr, @numbers);
3061
3062 translates a list of numbers to the corresponding characters.
3063
3064     my @squares = map { $_ * $_ } @numbers;
3065
3066 translates a list of numbers to their squared values.
3067
3068     my @squares = map { $_ > 5 ? ($_ * $_) : () } @numbers;
3069
3070 shows that number of returned elements can differ from the number of
3071 input elements. To omit an element, return an empty list ().
3072 This could also be achieved by writing
3073
3074     my @squares = map { $_ * $_ } grep { $_ > 5 } @numbers;
3075
3076 which makes the intention more clear.
3077
3078 Map always returns a list, which can be
3079 assigned to a hash such that the elements
3080 become key/value pairs. See L<perldata> for more details.
3081
3082     %hash = map { get_a_key_for($_) => $_ } @array;
3083
3084 is just a funny way to write
3085
3086     %hash = ();
3087     foreach (@array) {
3088         $hash{get_a_key_for($_)} = $_;
3089     }
3090
3091 Note that C<$_> is an alias to the list value, so it can be used to
3092 modify the elements of the LIST.  While this is useful and supported,
3093 it can cause bizarre results if the elements of LIST are not variables.
3094 Using a regular C<foreach> loop for this purpose would be clearer in
3095 most cases.  See also L</grep> for an array composed of those items of
3096 the original list for which the BLOCK or EXPR evaluates to true.
3097
3098 If C<$_> is lexical in the scope where the C<map> appears (because it has
3099 been declared with C<my $_>), then, in addition to being locally aliased to
3100 the list elements, C<$_> keeps being lexical inside the block; that is, it
3101 can't be seen from the outside, avoiding any potential side-effects.
3102
3103 C<{> starts both hash references and blocks, so C<map { ...> could be either
3104 the start of map BLOCK LIST or map EXPR, LIST. Because Perl doesn't look
3105 ahead for the closing C<}> it has to take a guess at which it's dealing with
3106 based on what it finds just after the C<{>. Usually it gets it right, but if it
3107 doesn't it won't realize something is wrong until it gets to the C<}> and
3108 encounters the missing (or unexpected) comma. The syntax error will be
3109 reported close to the C<}>, but you'll need to change something near the C<{>
3110 such as using a unary C<+> to give Perl some help:
3111
3112     %hash = map {  "\L$_" => 1  } @array  # perl guesses EXPR.  wrong
3113     %hash = map { +"\L$_" => 1  } @array  # perl guesses BLOCK. right
3114     %hash = map { ("\L$_" => 1) } @array  # this also works
3115     %hash = map {  lc($_) => 1  } @array  # as does this.
3116     %hash = map +( lc($_) => 1 ), @array  # this is EXPR and works!
3117
3118     %hash = map  ( lc($_), 1 ),   @array  # evaluates to (1, @array)
3119
3120 or to force an anon hash constructor use C<+{>:
3121
3122    @hashes = map +{ lc($_) => 1 }, @array # EXPR, so needs comma at end
3123
3124 to get a list of anonymous hashes each with only one entry apiece.
3125
3126 =item mkdir FILENAME,MASK
3127 X<mkdir> X<md> X<directory, create>
3128
3129 =item mkdir FILENAME
3130
3131 =item mkdir
3132
3133 Creates the directory specified by FILENAME, with permissions
3134 specified by MASK (as modified by C<umask>).  If it succeeds it
3135 returns true; otherwise it returns false and sets C<$!> (errno).
3136 MASK defaults to 0777 if omitted, and FILENAME defaults
3137 to C<$_> if omitted.
3138
3139 In general, it is better to create directories with a permissive MASK
3140 and let the user modify that with their C<umask> than it is to supply
3141 a restrictive MASK and give the user no way to be more permissive.
3142 The exceptions to this rule are when the file or directory should be
3143 kept private (mail files, for instance).  The perlfunc(1) entry on
3144 C<umask> discusses the choice of MASK in more detail.
3145
3146 Note that according to the POSIX 1003.1-1996 the FILENAME may have any
3147 number of trailing slashes.  Some operating and filesystems do not get
3148 this right, so Perl automatically removes all trailing slashes to keep
3149 everyone happy.
3150
3151 To recursively create a directory structure, look at
3152 the C<mkpath> function of the L<File::Path> module.
3153
3154 =item msgctl ID,CMD,ARG
3155 X<msgctl>
3156
3157 Calls the System V IPC function msgctl(2).  You'll probably have to say
3158
3159     use IPC::SysV;
3160
3161 first to get the correct constant definitions.  If CMD is C<IPC_STAT>,
3162 then ARG must be a variable that will hold the returned C<msqid_ds>
3163 structure.  Returns like C<ioctl>: the undefined value for error,
3164 C<"0 but true"> for zero, or the actual return value otherwise.  See also
3165 L<perlipc/"SysV IPC"> and the documentation for C<IPC::SysV> and
3166 C<IPC::Semaphore>.
3167
3168 =item msgget KEY,FLAGS
3169 X<msgget>
3170
3171 Calls the System V IPC function msgget(2).  Returns the message queue
3172 id, or C<undef> on error.  See also
3173 L<perlipc/"SysV IPC"> and the documentation for C<IPC::SysV> and
3174 C<IPC::Msg>.
3175
3176 =item msgrcv ID,VAR,SIZE,TYPE,FLAGS
3177 X<msgrcv>
3178
3179 Calls the System V IPC function msgrcv to receive a message from
3180 message queue ID into variable VAR with a maximum message size of
3181 SIZE.  Note that when a message is received, the message type as a
3182 native long integer will be the first thing in VAR, followed by the
3183 actual message.  This packing may be opened with C<unpack("l! a*")>.
3184 Taints the variable.  Returns true if successful, false 
3185 on error.  See also L<perlipc/"SysV IPC"> and the documentation for
3186 C<IPC::SysV> and C<IPC::SysV::Msg>.
3187
3188 =item msgsnd ID,MSG,FLAGS
3189 X<msgsnd>
3190
3191 Calls the System V IPC function msgsnd to send the message MSG to the
3192 message queue ID.  MSG must begin with the native long integer message
3193 type, be followed by the length of the actual message, and then finally
3194 the message itself.  This kind of packing can be achieved with
3195 C<pack("l! a*", $type, $message)>.  Returns true if successful,
3196 false on error.  See also the C<IPC::SysV>
3197 and C<IPC::SysV::Msg> documentation.
3198
3199 =item my EXPR
3200 X<my>
3201
3202 =item my TYPE EXPR
3203
3204 =item my EXPR : ATTRS
3205
3206 =item my TYPE EXPR : ATTRS
3207
3208 A C<my> declares the listed variables to be local (lexically) to the
3209 enclosing block, file, or C<eval>.  If more than one value is listed,
3210 the list must be placed in parentheses.
3211
3212 The exact semantics and interface of TYPE and ATTRS are still
3213 evolving.  TYPE is currently bound to the use of the C<fields> pragma,
3214 and attributes are handled using the C<attributes> pragma, or starting
3215 from Perl 5.8.0 also via the C<Attribute::Handlers> module.  See
3216 L<perlsub/"Private Variables via my()"> for details, and L<fields>,
3217 L<attributes>, and L<Attribute::Handlers>.
3218
3219 =item next LABEL
3220 X<next> X<continue>
3221
3222 =item next
3223
3224 The C<next> command is like the C<continue> statement in C; it starts
3225 the next iteration of the loop:
3226
3227     LINE: while (<STDIN>) {
3228         next LINE if /^#/;  # discard comments
3229         #...
3230     }
3231
3232 Note that if there were a C<continue> block on the above, it would get
3233 executed even on discarded lines.  If LABEL is omitted, the command
3234 refers to the innermost enclosing loop.
3235
3236 C<next> cannot be used to exit a block which returns a value such as
3237 C<eval {}>, C<sub {}>, or C<do {}>, and should not be used to exit
3238 a grep() or map() operation.
3239
3240 Note that a block by itself is semantically identical to a loop
3241 that executes once.  Thus C<next> will exit such a block early.
3242
3243 See also L</continue> for an illustration of how C<last>, C<next>, and
3244 C<redo> work.
3245
3246 =item no MODULE VERSION LIST
3247 X<no declarations>
3248 X<unimporting>
3249
3250 =item no MODULE VERSION
3251
3252 =item no MODULE LIST
3253
3254 =item no MODULE
3255
3256 =item no VERSION
3257
3258 See the C<use> function, of which C<no> is the opposite.
3259
3260 =item oct EXPR
3261 X<oct> X<octal> X<hex> X<hexadecimal> X<binary> X<bin>
3262
3263 =item oct
3264
3265 Interprets EXPR as an octal string and returns the corresponding
3266 value.  (If EXPR happens to start off with C<0x>, interprets it as a
3267 hex string.  If EXPR starts off with C<0b>, it is interpreted as a
3268 binary string.  Leading whitespace is ignored in all three cases.)
3269 The following will handle decimal, binary, octal, and hex in standard
3270 Perl notation:
3271
3272     $val = oct($val) if $val =~ /^0/;
3273
3274 If EXPR is omitted, uses C<$_>.   To go the other way (produce a number
3275 in octal), use sprintf() or printf():
3276
3277     $dec_perms = (stat("filename"))[2] & 07777;
3278     $oct_perm_str = sprintf "%o", $perms;
3279
3280 The oct() function is commonly used when a string such as C<644> needs
3281 to be converted into a file mode, for example.  Although Perl 
3282 automatically converts strings into numbers as needed, this automatic
3283 conversion assumes base 10.
3284
3285 Leading white space is ignored without warning, as too are any trailing 
3286 non-digits, such as a decimal point (C<oct> only handles non-negative
3287 integers, not negative integers or floating point).
3288
3289 =item open FILEHANDLE,EXPR
3290 X<open> X<pipe> X<file, open> X<fopen>
3291
3292 =item open FILEHANDLE,MODE,EXPR
3293
3294 =item open FILEHANDLE,MODE,EXPR,LIST
3295
3296 =item open FILEHANDLE,MODE,REFERENCE
3297
3298 =item open FILEHANDLE
3299
3300 Opens the file whose filename is given by EXPR, and associates it with
3301 FILEHANDLE.
3302
3303 Simple examples to open a file for reading:
3304
3305     open(my $fh, "<", "input.txt") 
3306         or die "cannot open < input.txt: $!";
3307
3308 and for writing:
3309
3310     open(my $fh, ">", "output.txt") 
3311         or die "cannot open > output.txt: $!";
3312
3313 (The following is a comprehensive reference to open(): for a gentler
3314 introduction you may consider L<perlopentut>.)
3315
3316 If FILEHANDLE is an undefined scalar variable (or array or hash element), a
3317 new filehandle is autovivified, meaning that the variable is assigned a
3318 reference to a newly allocated anonymous filehandle.  Otherwise if
3319 FILEHANDLE is an expression, its value is the real filehandle.  (This is
3320 considered a symbolic reference, so C<use strict "refs"> should I<not> be
3321 in effect.)
3322
3323 If EXPR is omitted, the global (package) scalar variable of the same
3324 name as the FILEHANDLE contains the filename.  (Note that lexical 
3325 variables--those declared with C<my> or C<state>--will not work for this
3326 purpose; so if you're using C<my> or C<state>, specify EXPR in your
3327 call to open.)
3328
3329 If three (or more) arguments are specified, the open mode (including
3330 optional encoding) in the second argument are distinct from the filename in
3331 the third.  If MODE is C<< < >> or nothing, the file is opened for input.
3332 If MODE is C<< > >>, the file is opened for output, with existing files
3333 first being truncated ("clobbered") and nonexisting files newly created.
3334 If MODE is C<<< >> >>>, the file is opened for appending, again being
3335 created if necessary.
3336
3337 You can put a C<+> in front of the C<< > >> or C<< < >> to
3338 indicate that you want both read and write access to the file; thus
3339 C<< +< >> is almost always preferred for read/write updates--the 
3340 C<< +> >> mode would clobber the file first.  You cant usually use
3341 either read-write mode for updating textfiles, since they have
3342 variable-length records.  See the B<-i> switch in L<perlrun> for a
3343 better approach.  The file is created with permissions of C<0666>
3344 modified by the process's C<umask> value.
3345
3346 These various prefixes correspond to the fopen(3) modes of C<r>,
3347 C<r+>, C<w>, C<w+>, C<a>, and C<a+>.
3348
3349 In the one- and two-argument forms of the call, the mode and filename
3350 should be concatenated (in that order), preferably separated by white
3351 space.  You can--but shouldn't--omit the mode in these forms when that mode
3352 is C<< < >>.  It is always safe to use the two-argument form of C<open> if
3353 the filename argument is a known literal.
3354
3355 For three or more arguments if MODE is C<|->, the filename is
3356 interpreted as a command to which output is to be piped, and if MODE
3357 is C<-|>, the filename is interpreted as a command that pipes
3358 output to us.  In the two-argument (and one-argument) form, one should
3359 replace dash (C<->) with the command.
3360 See L<perlipc/"Using open() for IPC"> for more examples of this.
3361 (You are not allowed to C<open> to a command that pipes both in I<and>
3362 out, but see L<IPC::Open2>, L<IPC::Open3>, and
3363 L<perlipc/"Bidirectional Communication with Another Process"> for
3364 alternatives.)
3365
3366 In the form of pipe opens taking three or more arguments, if LIST is specified
3367 (extra arguments after the command name) then LIST becomes arguments
3368 to the command invoked if the platform supports it.  The meaning of
3369 C<open> with more than three arguments for non-pipe modes is not yet
3370 defined, but experimental "layers" may give extra LIST arguments
3371 meaning.
3372
3373 In the two-argument (and one-argument) form, opening C<< <- >> 
3374 or C<-> opens STDIN and opening C<< >- >> opens STDOUT.
3375
3376 You may (and usually should) use the three-argument form of open to specify
3377 I/O layers (sometimes referred to as "disciplines") to apply to the handle
3378 that affect how the input and output are processed (see L<open> and
3379 L<PerlIO> for more details). For example:
3380
3381   open(my $fh, "<:encoding(UTF-8)", "filename")
3382     || die "can't open UTF-8 encoded filename: $!";
3383
3384 opens the UTF8-encoded file containing Unicode characters;
3385 see L<perluniintro>. Note that if layers are specified in the
3386 three-argument form, then default layers stored in ${^OPEN} (see L<perlvar>;
3387 usually set by the B<open> pragma or the switch B<-CioD>) are ignored.
3388
3389 Open returns nonzero on success, the undefined value otherwise.  If
3390 the C<open> involved a pipe, the return value happens to be the pid of
3391 the subprocess.
3392
3393 If you're running Perl on a system that distinguishes between text
3394 files and binary files, then you should check out L</binmode> for tips
3395 for dealing with this.  The key distinction between systems that need
3396 C<binmode> and those that don't is their text file formats.  Systems
3397 like Unix, Mac OS, and Plan 9, that end lines with a single
3398 character and encode that character in C as C<"\n"> do not
3399 need C<binmode>.  The rest need it.
3400
3401 When opening a file, it's seldom a good idea to continue 
3402 if the request failed, so C<open> is frequently used with
3403 C<die>.  Even if C<die> won't do what you want (say, in a CGI script,
3404 where you want to format a suitable error message (but there are
3405 modules that can help with that problem)) always check
3406 the return value from opening a file.  
3407
3408 As a special case the three-argument form with a read/write mode and the third
3409 argument being C<undef>:
3410
3411     open(my $tmp, "+>", undef) or die ...
3412
3413 opens a filehandle to an anonymous temporary file.  Also using C<< +< >>
3414 works for symmetry, but you really should consider writing something
3415 to the temporary file first.  You will need to seek() to do the
3416 reading.
3417
3418 Since v5.8.0, Perl has built using PerlIO by default.  Unless you've
3419 changed this (such as building Perl with C<Configure -Uuseperlio>), you can
3420 open filehandles directly to Perl scalars via:
3421
3422     open($fh, ">", \$variable) || ..
3423
3424 To (re)open C<STDOUT> or C<STDERR> as an in-memory file, close it first:
3425
3426     close STDOUT;
3427     open(STDOUT, ">", \$variable)
3428         or die "Can't open STDOUT: $!";
3429
3430 General examples:
3431
3432     $ARTICLE = 100;
3433     open(ARTICLE) or die "Can't find article $ARTICLE: $!\n";
3434     while (<ARTICLE>) {...
3435
3436     open(LOG, ">>/usr/spool/news/twitlog");  # (log is reserved)
3437     # if the open fails, output is discarded
3438
3439     open(my $dbase, "+<", "dbase.mine")      # open for update
3440         or die "Can't open 'dbase.mine' for update: $!";
3441
3442     open(my $dbase, "+<dbase.mine")          # ditto
3443         or die "Can't open 'dbase.mine' for update: $!";
3444
3445     open(ARTICLE, "-|", "caesar <$article")  # decrypt article
3446         or die "Can't start caesar: $!";
3447
3448     open(ARTICLE, "caesar <$article |")      # ditto
3449         or die "Can't start caesar: $!";
3450
3451     open(EXTRACT, "|sort >Tmp$$")            # $$ is our process id
3452         or die "Can't start sort: $!";
3453
3454     # in-memory files
3455     open(MEMORY, ">", \$var)
3456         or die "Can't open memory file: $!";
3457     print MEMORY "foo!\n";                   # output will appear in $var
3458
3459     # process argument list of files along with any includes
3460
3461     foreach $file (@ARGV) {
3462         process($file, "fh00");
3463     }
3464
3465     sub process {
3466         my($filename, $input) = @_;
3467         $input++;    # this is a string increment
3468         unless (open($input, "<", $filename)) {
3469             print STDERR "Can't open $filename: $!\n";
3470             return;
3471         }
3472
3473         local $_;
3474         while (<$input>) {    # note use of indirection
3475             if (/^#include "(.*)"/) {
3476                 process($1, $input);
3477                 next;
3478             }
3479             #...          # whatever
3480         }
3481     }
3482
3483 See L<perliol> for detailed info on PerlIO.
3484
3485 You may also, in the Bourne shell tradition, specify an EXPR beginning
3486 with C<< >& >>, in which case the rest of the string is interpreted
3487 as the name of a filehandle (or file descriptor, if numeric) to be
3488 duped (as C<dup(2)>) and opened.  You may use C<&> after C<< > >>,
3489 C<<< >> >>>, C<< < >>, C<< +> >>, C<<< +>> >>>, and C<< +< >>.
3490 The mode you specify should match the mode of the original filehandle.
3491 (Duping a filehandle does not take into account any existing contents
3492 of IO buffers.) If you use the three-argument form, then you can pass either a
3493 number, the name of a filehandle, or the normal "reference to a glob".
3494
3495 Here is a script that saves, redirects, and restores C<STDOUT> and
3496 C<STDERR> using various methods:
3497
3498     #!/usr/bin/perl
3499     open(my $oldout, ">&STDOUT")     or die "Can't dup STDOUT: $!";
3500     open(OLDERR,     ">&", \*STDERR) or die "Can't dup STDERR: $!";
3501
3502     open(STDOUT, '>', "foo.out") or die "Can't redirect STDOUT: $!";
3503     open(STDERR, ">&STDOUT")     or die "Can't dup STDOUT: $!";
3504
3505     select STDERR; $| = 1;  # make unbuffered
3506     select STDOUT; $| = 1;  # make unbuffered
3507
3508     print STDOUT "stdout 1\n";  # this works for
3509     print STDERR "stderr 1\n";  # subprocesses too
3510
3511     open(STDOUT, ">&", $oldout) or die "Can't dup \$oldout: $!";
3512     open(STDERR, ">&OLDERR")    or die "Can't dup OLDERR: $!";
3513
3514     print STDOUT "stdout 2\n";
3515     print STDERR "stderr 2\n";
3516
3517 If you specify C<< '<&=X' >>, where C<X> is a file descriptor number
3518 or a filehandle, then Perl will do an equivalent of C's C<fdopen> of
3519 that file descriptor (and not call C<dup(2)>); this is more
3520 parsimonious of file descriptors.  For example:
3521
3522     # open for input, reusing the fileno of $fd
3523     open(FILEHANDLE, "<&=$fd")
3524
3525 or
3526
3527     open(FILEHANDLE, "<&=", $fd)
3528
3529 or
3530
3531     # open for append, using the fileno of OLDFH
3532     open(FH, ">>&=", OLDFH)
3533
3534 or
3535
3536     open(FH, ">>&=OLDFH")
3537
3538 Being parsimonious on filehandles is also useful (besides being
3539 parsimonious) for example when something is dependent on file
3540 descriptors, like for example locking using flock().  If you do just
3541 C<< open(A, ">>&B") >>, the filehandle A will not have the same file
3542 descriptor as B, and therefore flock(A) will not flock(B) nor vice
3543 versa.  But with C<< open(A, ">>&=B") >>, the filehandles will share
3544 the same underlying system file descriptor.
3545
3546 Note that under Perls older than 5.8.0, Perl uses the standard C library's'
3547 fdopen() to implement the C<=> functionality.  On many Unix systems,
3548 fdopen() fails when file descriptors exceed a certain value, typically 255.
3549 For Perls 5.8.0 and later, PerlIO is (most often) the default.
3550
3551 You can see whether your Perl was built with PerlIO by running C<perl -V>
3552 and looking for the C<useperlio=> line.  If C<useperlio> is C<define>, you
3553 have PerlIO; otherwise you don't.
3554
3555 If you open a pipe on the command C<-> (that is, specify either C<|-> or C<-|>
3556 with the one- or two-argument forms of C<open>), 
3557 an implicit C<fork> is done, so C<open> returns twice: in the parent
3558 process it returns the pid
3559 of the child process, and in the child process it returns (a defined) C<0>.
3560 Use C<defined($pid)> or C<//> to determine whether the open was successful.
3561
3562 For example, use either
3563
3564     $child_pid = open(FROM_KID, "|-")   // die "can't fork: $!";
3565
3566 or
3567     $child_pid = open(TO_KID,   "|-")   // die "can't fork: $!";
3568
3569 followed by 
3570
3571     if ($child_pid) {
3572         # am the parent:
3573         # either write TO_KID or else read FROM_KID
3574         ...
3575         wait $child_pid;
3576     } else {
3577         # am the child; use STDIN/STDOUT normally
3578         ...
3579         exit;
3580     } 
3581
3582 The filehandle behaves normally for the parent, but I/O to that
3583 filehandle is piped from/to the STDOUT/STDIN of the child process.
3584 In the child process, the filehandle isn't opened--I/O happens from/to
3585 the new STDOUT/STDIN.  Typically this is used like the normal
3586 piped open when you want to exercise more control over just how the
3587 pipe command gets executed, such as when running setuid and
3588 you don't want to have to scan shell commands for metacharacters.
3589
3590 The following blocks are more or less equivalent:
3591
3592     open(FOO, "|tr '[a-z]' '[A-Z]'");
3593     open(FOO, "|-", "tr '[a-z]' '[A-Z]'");
3594     open(FOO, "|-") || exec 'tr', '[a-z]', '[A-Z]';
3595     open(FOO, "|-", "tr", '[a-z]', '[A-Z]');
3596
3597     open(FOO, "cat -n '$file'|");
3598     open(FOO, "-|", "cat -n '$file'");
3599     open(FOO, "-|") || exec "cat", "-n", $file;
3600     open(FOO, "-|", "cat", "-n", $file);
3601
3602 The last two examples in each block show the pipe as "list form", which is
3603 not yet supported on all platforms.  A good rule of thumb is that if
3604 your platform has a real C<fork()> (in other words, if your platform is
3605 Unix, including Linux and MacOS X), you can use the list form.  You would 
3606 want to use the list form of the pipe so you can pass literal arguments
3607 to the command without risk of the shell interpreting any shell metacharacters
3608 in them.  However, this also bars you from opening pipes to commands
3609 that intentionally contain shell metacharacters, such as:
3610
3611     open(FOO, "|cat -n | expand -4 | lpr")
3612         // die "Can't open pipeline to lpr: $!";
3613
3614 See L<perlipc/"Safe Pipe Opens"> for more examples of this.
3615
3616 Beginning with v5.6.0, Perl will attempt to flush all files opened for
3617 output before any operation that may do a fork, but this may not be
3618 supported on some platforms (see L<perlport>).  To be safe, you may need
3619 to set C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method
3620 of C<IO::Handle> on any open handles.
3621
3622 On systems that support a close-on-exec flag on files, the flag will
3623 be set for the newly opened file descriptor as determined by the value
3624 of C<$^F>.  See L<perlvar/$^F>.
3625
3626 Closing any piped filehandle causes the parent process to wait for the
3627 child to finish, then returns the status value in C<$?> and
3628 C<${^CHILD_ERROR_NATIVE}>.
3629
3630 The filename passed to the one- and two-argument forms of open() will
3631 have leading and trailing whitespace deleted and normal
3632 redirection characters honored.  This property, known as "magic open",
3633 can often be used to good effect.  A user could specify a filename of
3634 F<"rsh cat file |">, or you could change certain filenames as needed:
3635
3636     $filename =~ s/(.*\.gz)\s*$/gzip -dc < $1|/;
3637     open(FH, $filename) or die "Can't open $filename: $!";
3638
3639 Use the three-argument form to open a file with arbitrary weird characters in it,
3640
3641     open(FOO, "<", $file)
3642         || die "can't open < $file: $!";
3643
3644 otherwise it's necessary to protect any leading and trailing whitespace:
3645
3646     $file =~ s#^(\s)#./$1#;
3647     open(FOO, "< $file\0")
3648         || die "open failed: $!";
3649
3650 (this may not work on some bizarre filesystems).  One should
3651 conscientiously choose between the I<magic> and I<three-argument> form
3652 of open():
3653
3654     open(IN, $ARGV[0]) || die "can't open $ARGV[0]: $!";
3655
3656 will allow the user to specify an argument of the form C<"rsh cat file |">,
3657 but will not work on a filename that happens to have a trailing space, while
3658
3659     open(IN, "<", $ARGV[0])
3660         || die "can't open < $ARGV[0]: $!";
3661
3662 will have exactly the opposite restrictions.
3663
3664 If you want a "real" C C<open> (see C<open(2)> on your system), then you
3665 should use the C<sysopen> function, which involves no such magic (but may
3666 use subtly different filemodes than Perl open(), which is mapped to C
3667 fopen()).  This is another way to protect your filenames from
3668 interpretation.  For example:
3669
3670     use IO::Handle;
3671     sysopen(HANDLE, $path, O_RDWR|O_CREAT|O_EXCL)
3672         or die "sysopen $path: $!";
3673     $oldfh = select(HANDLE); $| = 1; select($oldfh);
3674     print HANDLE "stuff $$\n";
3675     seek(HANDLE, 0, 0);
3676     print "File contains: ", <HANDLE>;
3677
3678 Using the constructor from the C<IO::Handle> package (or one of its
3679 subclasses, such as C<IO::File> or C<IO::Socket>), you can generate anonymous
3680 filehandles that have the scope of the variables used to hold them, then
3681 automatically (but silently) close once their reference counts become
3682 zero, typically at scope exit:
3683
3684     use IO::File;
3685     #...
3686     sub read_myfile_munged {
3687         my $ALL = shift;
3688         # or just leave it undef to autoviv
3689         my $handle = IO::File->new;
3690         open($handle, "<", "myfile") or die "myfile: $!";
3691         $first = <$handle>
3692             or return ();     # Automatically closed here.
3693         mung($first) or die "mung failed";  # Or here.
3694         return (first, <$handle>) if $ALL;  # Or here.
3695         return $first;                      # Or here.
3696     }
3697
3698 B<WARNING:> The previous example has a bug because the automatic
3699 close that happens when the refcount on C<handle> does not
3700 properly detect and report failures.  I<Always> close the handle
3701 yourself and inspect the return value.
3702
3703     close($handle) 
3704         || warn "close failed: $!";
3705
3706 See L</seek> for some details about mixing reading and writing.
3707
3708 =item opendir DIRHANDLE,EXPR
3709 X<opendir>
3710
3711 Opens a directory named EXPR for processing by C<readdir>, C<telldir>,
3712 C<seekdir>, C<rewinddir>, and C<closedir>.  Returns true if successful.
3713 DIRHANDLE may be an expression whose value can be used as an indirect
3714 dirhandle, usually the real dirhandle name.  If DIRHANDLE is an undefined
3715 scalar variable (or array or hash element), the variable is assigned a
3716 reference to a new anonymous dirhandle; that is, it's autovivified.
3717 DIRHANDLEs have their own namespace separate from FILEHANDLEs.
3718
3719 See the example at C<readdir>.
3720
3721 =item ord EXPR
3722 X<ord> X<encoding>
3723
3724 =item ord
3725
3726 Returns the numeric (the native 8-bit encoding, like ASCII or EBCDIC,
3727 or Unicode) value of the first character of EXPR.  
3728 If EXPR is an empty string, returns 0.  If EXPR is omitted, uses C<$_>.
3729 (Note I<character>, not byte.)
3730
3731 For the reverse, see L</chr>.
3732 See L<perlunicode> for more about Unicode.
3733
3734 =item our EXPR
3735 X<our> X<global>
3736
3737 =item our TYPE EXPR
3738
3739 =item our EXPR : ATTRS
3740
3741 =item our TYPE EXPR : ATTRS
3742
3743 C<our> associates a simple name with a package variable in the current
3744 package for use within the current scope.  When C<use strict 'vars'> is in
3745 effect, C<our> lets you use declared global variables without qualifying
3746 them with package names, within the lexical scope of the C<our> declaration.
3747 In this way C<our> differs from C<use vars>, which is package-scoped.
3748
3749 Unlike C<my> or C<state>, which allocates storage for a variable and
3750 associates a simple name with that storage for use within the current
3751 scope, C<our> associates a simple name with a package (read: global)
3752 variable in the current package, for use within the current lexical scope.
3753 In other words, C<our> has the same scoping rules as C<my> or C<state>, but
3754 does not necessarily create a variable.
3755
3756 If more than one value is listed, the list must be placed
3757 in parentheses.
3758
3759     our $foo;
3760     our($bar, $baz);
3761
3762 An C<our> declaration declares a global variable that will be visible
3763 across its entire lexical scope, even across package boundaries.  The
3764 package in which the variable is entered is determined at the point
3765 of the declaration, not at the point of use.  This means the following
3766 behavior holds:
3767
3768     package Foo;
3769     our $bar;      # declares $Foo::bar for rest of lexical scope
3770     $bar = 20;
3771
3772     package Bar;
3773     print $bar;    # prints 20, as it refers to $Foo::bar
3774
3775 Multiple C<our> declarations with the same name in the same lexical
3776 scope are allowed if they are in different packages.  If they happen
3777 to be in the same package, Perl will emit warnings if you have asked
3778 for them, just like multiple C<my> declarations.  Unlike a second
3779 C<my> declaration, which will bind the name to a fresh variable, a
3780 second C<our> declaration in the same package, in the same scope, is
3781 merely redundant.
3782
3783     use warnings;
3784     package Foo;
3785     our $bar;      # declares $Foo::bar for rest of lexical scope
3786     $bar = 20;
3787
3788     package Bar;
3789     our $bar = 30; # declares $Bar::bar for rest of lexical scope
3790     print $bar;    # prints 30
3791
3792     our $bar;      # emits warning but has no other effect
3793     print $bar;    # still prints 30
3794
3795 An C<our> declaration may also have a list of attributes associated
3796 with it.
3797
3798 The exact semantics and interface of TYPE and ATTRS are still
3799 evolving.  TYPE is currently bound to the use of C<fields> pragma,
3800 and attributes are handled using the C<attributes> pragma, or starting
3801 from Perl 5.8.0 also via the C<Attribute::Handlers> module.  See
3802 L<perlsub/"Private Variables via my()"> for details, and L<fields>,
3803 L<attributes>, and L<Attribute::Handlers>.
3804
3805 =item pack TEMPLATE,LIST
3806 X<pack>
3807
3808 Takes a LIST of values and converts it into a string using the rules
3809 given by the TEMPLATE.  The resulting string is the concatenation of
3810 the converted values.  Typically, each converted value looks
3811 like its machine-level representation.  For example, on 32-bit machines
3812 an integer may be represented by a sequence of 4 bytes, which  will in
3813 Perl be presented as a string that's 4 characters long. 
3814
3815 See L<perlpacktut> for an introduction to this function.
3816
3817 The TEMPLATE is a sequence of characters that give the order and type
3818 of values, as follows:
3819
3820     a  A string with arbitrary binary data, will be null padded.
3821     A  A text (ASCII) string, will be space padded.
3822     Z  A null-terminated (ASCIZ) string, will be null padded.
3823
3824     b  A bit string (ascending bit order inside each byte, like vec()).
3825     B  A bit string (descending bit order inside each byte).
3826     h  A hex string (low nybble first).
3827     H  A hex string (high nybble first).
3828
3829     c  A signed char (8-bit) value.
3830     C  An unsigned char (octet) value.
3831     W  An unsigned char value (can be greater than 255).
3832
3833     s  A signed short (16-bit) value.
3834     S  An unsigned short value.
3835
3836     l  A signed long (32-bit) value.
3837     L  An unsigned long value.
3838
3839     q  A signed quad (64-bit) value.
3840     Q  An unsigned quad value.
3841       (Quads are available only if your system supports 64-bit
3842        integer values _and_ if Perl has been compiled to support those.
3843            Raises an exception otherwise.)
3844
3845     i  A signed integer value.
3846     I  A unsigned integer value.
3847       (This 'integer' is _at_least_ 32 bits wide.  Its exact
3848            size depends on what a local C compiler calls 'int'.)
3849
3850     n  An unsigned short (16-bit) in "network" (big-endian) order.
3851     N  An unsigned long (32-bit) in "network" (big-endian) order.
3852     v  An unsigned short (16-bit) in "VAX" (little-endian) order.
3853     V  An unsigned long (32-bit) in "VAX" (little-endian) order.
3854
3855     j   A Perl internal signed integer value (IV).
3856     J   A Perl internal unsigned integer value (UV).
3857
3858     f  A single-precision float in native format.
3859     d  A double-precision float in native format.
3860
3861     F  A Perl internal floating-point value (NV) in native format
3862     D  A float of long-double precision in native format.
3863       (Long doubles are available only if your system supports long
3864        double values _and_ if Perl has been compiled to support those.
3865            Raises an exception otherwise.)
3866
3867     p  A pointer to a null-terminated string.
3868     P  A pointer to a structure (fixed-length string).
3869
3870     u  A uuencoded string.
3871     U  A Unicode character number.  Encodes to a character in character mode
3872         and UTF-8 (or UTF-EBCDIC in EBCDIC platforms) in byte mode.
3873
3874     w  A BER compressed integer (not an ASN.1 BER, see perlpacktut for
3875        details).  Its bytes represent an unsigned integer in base 128,
3876        most significant digit first, with as few digits as possible.  Bit
3877        eight (the high bit) is set on each byte except the last.
3878
3879     x  A null byte (a.k.a ASCII NUL, "\000", chr(0))
3880     X  Back up a byte.
3881     @  Null-fill or truncate to absolute position, counted from the
3882        start of the innermost ()-group.
3883     .  Null-fill or truncate to absolute position specified by the value.
3884     (  Start of a ()-group.
3885
3886 One or more modifiers below may optionally follow certain letters in the
3887 TEMPLATE (the second column lists letters for which the modifier is valid):
3888
3889     !   sSlLiI     Forces native (short, long, int) sizes instead
3890                    of fixed (16-/32-bit) sizes.
3891
3892         xX         Make x and X act as alignment commands.
3893
3894         nNvV       Treat integers as signed instead of unsigned.
3895
3896         @.         Specify position as byte offset in the internal
3897                    representation of the packed string. Efficient but
3898                    dangerous.
3899
3900     >   sSiIlLqQ   Force big-endian byte-order on the type.
3901         jJfFdDpP   (The "big end" touches the construct.)
3902
3903     <   sSiIlLqQ   Force little-endian byte-order on the type.
3904         jJfFdDpP   (The "little end" touches the construct.)
3905
3906 The C<< > >> and C<< < >> modifiers can also be used on C<()> groups 
3907 to force a particular byte-order on all components in that group, 
3908 including all its subgroups.
3909
3910 The following rules apply:
3911
3912 =over 
3913
3914 =item *
3915
3916 Each letter may optionally be followed by a number indicating the repeat
3917 count.  A numeric repeat count may optionally be enclosed in brackets, as
3918 in C<pack("C[80]", @arr)>.  The repeat count gobbles that many values from
3919 the LIST when used with all format types other than C<a>, C<A>, C<Z>, C<b>,
3920 C<B>, C<h>, C<H>, C<@>, C<.>, C<x>, C<X>, and C<P>, where it means
3921 something else, dscribed below.  Supplying a C<*> for the repeat count
3922 instead of a number means to use however many items are left, except for:
3923
3924 =over 
3925
3926 =item * 
3927
3928 C<@>, C<x>, and C<X>, where it is equivalent to C<0>.
3929
3930 =item * 
3931
3932 <.>, where it means relative to the start of the string.
3933
3934 =item * 
3935
3936 C<u>, where it is equivalent to 1 (or 45, which here is equivalent).
3937
3938 =back 
3939
3940 One can replace a numeric repeat count with a template letter enclosed in
3941 brackets to use the packed byte length of the bracketed template for the
3942 repeat count.
3943
3944 For example, the template C<x[L]> skips as many bytes as in a packed long,
3945 and the template C<"$t X[$t] $t"> unpacks twice whatever $t (when
3946 variable-expanded) unpacks.  If the template in brackets contains alignment
3947 commands (such as C<x![d]>), its packed length is calculated as if the
3948 start of the template had the maximal possible alignment.
3949
3950 When used with C<Z>, a C<*> as the repeat count is guaranteed to add a
3951 trailing null byte, so the resulting string is always one byte longer than
3952 the byte length of the item itself.
3953
3954 When used with C<@>, the repeat count represents an offset from the start
3955 of the innermost C<()> group.
3956
3957 When used with C<.>, the repeat count determines the starting position to
3958 calculate the value offset as follows:
3959
3960 =over 
3961
3962 =item *
3963
3964 If the repeat count is C<0>, it's relative to the current position.
3965
3966 =item *
3967
3968 If the repeat count is C<*>, the offset is relative to the start of the
3969 packed string.
3970
3971 =item *
3972
3973 And if it's an integer I<n>, the offset is relative to the start of the
3974 I<n>th innermost C<( )> group, or to the start of the string if I<n> is
3975 bigger then the group level.
3976
3977 =back
3978
3979 The repeat count for C<u> is interpreted as the maximal number of bytes
3980 to encode per line of output, with 0, 1 and 2 replaced by 45. The repeat 
3981 count should not be more than 65.
3982
3983 =item *
3984
3985 The C<a>, C<A>, and C<Z> types gobble just one value, but pack it as a
3986 string of length count, padding with nulls or spaces as needed.  When
3987 unpacking, C<A> strips trailing whitespace and nulls, C<Z> strips everything
3988 after the first null, and C<a> returns data with no stripping at all.
3989
3990 If the value to pack is too long, the result is truncated.  If it's too
3991 long and an explicit count is provided, C<Z> packs only C<$count-1> bytes,
3992 followed by a null byte.  Thus C<Z> always packs a trailing null, except
3993 when the count is 0.
3994
3995 =item *
3996
3997 Likewise, the C<b> and C<B> formats pack a string that's that many bits long.
3998 Each such format generates 1 bit of the result.  These are typically followed
3999 by a repeat count like C<B8> or C<B64>.
4000
4001 Each result bit is based on the least-significant bit of the corresponding
4002 input character, i.e., on C<ord($char)%2>.  In particular, characters C<"0">
4003 and C<"1"> generate bits 0 and 1, as do characters C<"\000"> and C<"\001">.
4004
4005 Starting from the beginning of the input string, each 8-tuple
4006 of characters is converted to 1 character of output.  With format C<b>,
4007 the first character of the 8-tuple determines the least-significant bit of a
4008 character; with format C<B>, it determines the most-significant bit of
4009 a character.
4010
4011 If the length of the input string is not evenly divisible by 8, the
4012 remainder is packed as if the input string were padded by null characters
4013 at the end.  Similarly during unpacking, "extra" bits are ignored.
4014
4015 If the input string is longer than needed, remaining characters are ignored.
4016
4017 A C<*> for the repeat count uses all characters of the input field.  
4018 On unpacking, bits are converted to a string of C<0>s and C<1>s.
4019
4020 =item *
4021
4022 The C<h> and C<H> formats pack a string that many nybbles (4-bit groups,
4023 representable as hexadecimal digits, C<"0".."9"> C<"a".."f">) long.
4024
4025 For each such format, pack() generates 4 bits of result.
4026 With non-alphabetical characters, the result is based on the 4 least-significant
4027 bits of the input character, i.e., on C<ord($char)%16>.  In particular,
4028 characters C<"0"> and C<"1"> generate nybbles 0 and 1, as do bytes
4029 C<"\000"> and C<"\001">.  For characters C<"a".."f"> and C<"A".."F">, the result
4030 is compatible with the usual hexadecimal digits, so that C<"a"> and
4031 C<"A"> both generate the nybble C<0xA==10>.  Use only these specific hex 
4032 characters with this format.
4033
4034 Starting from the beginning of the template to pack(), each pair
4035 of characters is converted to 1 character of output.  With format C<h>, the
4036 first character of the pair determines the least-significant nybble of the
4037 output character; with format C<H>, it determines the most-significant
4038 nybble.
4039
4040 If the length of the input string is not even, it behaves as if padded by
4041 a null character at the end.  Similarly, "extra" nybbles are ignored during
4042 unpacking.
4043
4044 If the input string is longer than needed, extra characters are ignored.
4045
4046 A C<*> for the repeat count uses all characters of the input field.  For
4047 unpack(), nybbles are converted to a string of hexadecimal digits.
4048
4049 =item *
4050
4051 The C<p> format packs a pointer to a null-terminated string.  You are
4052 responsible for ensuring that the string is not a temporary value, as that
4053 could potentially get deallocated before you got around to using the packed
4054 result.  The C<P> format packs a pointer to a structure of the size indicated
4055 by the length.  A null pointer is created if the corresponding value for
4056 C<p> or C<P> is C<undef>; similarly with unpack(), where a null pointer
4057 unpacks into C<undef>.
4058
4059 If your system has a strange pointer size--meaning a pointer is neither as
4060 big as an int nor as big as a long--it may not be possible to pack or
4061 unpack pointers in big- or little-endian byte order.  Attempting to do
4062 so raises an exception.
4063
4064 =item *
4065
4066 The C</> template character allows packing and unpacking of a sequence of
4067 items where the packed structure contains a packed item count followed by
4068 the packed items themselves.  This is useful when the structure you're
4069 unpacking has encoded the sizes or repeat counts for some of its fields
4070 within the structure itself as separate fields.
4071
4072 For C<pack>, you write I<length-item>C</>I<sequence-item>, and the
4073 I<length-item> describes how the length value is packed. Formats likely
4074 to be of most use are integer-packing ones like C<n> for Java strings,
4075 C<w> for ASN.1 or SNMP, and C<N> for Sun XDR.
4076
4077 For C<pack>, I<sequence-item> may have a repeat count, in which case
4078 the minimum of that and the number of available items is used as the argument
4079 for I<length-item>. If it has no repeat count or uses a '*', the number
4080 of available items is used.
4081
4082 For C<unpack>, an internal stack of integer arguments unpacked so far is
4083 used. You write C</>I<sequence-item> and the repeat count is obtained by
4084 popping off the last element from the stack. The I<sequence-item> must not
4085 have a repeat count.
4086
4087 If I<sequence-item> refers to a string type (C<"A">, C<"a">, or C<"Z">),
4088 the I<length-item> is the string length, not the number of strings.  With
4089 an explicit repeat count for pack, the packed string is adjusted to that
4090 length.  For example:
4091
4092     unpack("W/a", "\004Gurusamy")           gives ("Guru")
4093     unpack("a3/A A*", "007 Bond  J ")       gives (" Bond", "J")
4094     unpack("a3 x2 /A A*", "007: Bond, J.")  gives ("Bond, J", ".")
4095
4096     pack("n/a* w/a","hello,","world")       gives "\000\006hello,\005world"
4097     pack("a/W2", ord("a") .. ord("z"))      gives "2ab"
4098
4099 The I<length-item> is not returned explicitly from C<unpack>.
4100
4101 Supplying a count to the I<length-item> format letter is only useful with
4102 C<A>, C<a>, or C<Z>.  Packing with a I<length-item> of C<a> or C<Z> may
4103 introduce C<"\000"> characters, which Perl does not regard as legal in
4104 numeric strings.
4105
4106 =item *
4107
4108 The integer types C<s>, C<S>, C<l>, and C<L> may be
4109 followed by a C<!> modifier to specify native shorts or
4110 longs.  As shown in the example above, a bare C<l> means
4111 exactly 32 bits, although the native C<long> as seen by the local C compiler
4112 may be larger.  This is mainly an issue on 64-bit platforms.  You can
4113 see whether using C<!> makes any difference this way:
4114
4115     printf "format s is %d, s! is %d\n", 
4116         length pack("s"), length pack("s!");
4117
4118     printf "format l is %d, l! is %d\n", 
4119         length pack("l"), length pack("l!");
4120
4121
4122 C<i!> and C<I!> are also allowed, but only for completeness' sake:
4123 they are identical to C<i> and C<I>.
4124
4125 The actual sizes (in bytes) of native shorts, ints, longs, and long
4126 longs on the platform where Perl was built are also available from
4127 the command line:
4128
4129     $ perl -V:{short,int,long{,long}}size
4130     shortsize='2';
4131     intsize='4';
4132     longsize='4';
4133     longlongsize='8';
4134
4135 or programmatically via the C<Config> module:
4136
4137        use Config;
4138        print $Config{shortsize},    "\n";
4139        print $Config{intsize},      "\n";
4140        print $Config{longsize},     "\n";
4141        print $Config{longlongsize}, "\n";
4142
4143 C<$Config{longlongsize}> is undefined on systems without 
4144 long long support.
4145
4146 =item *
4147
4148 The integer formats C<s>, C<S>, C<i>, C<I>, C<l>, C<L>, C<j>, and C<J> are
4149 inherently non-portable between processors and operating systems because
4150 they obey native byteorder and endianness.  For example, a 4-byte integer
4151 0x12345678 (305419896 decimal) would be ordered natively (arranged in and
4152 handled by the CPU registers) into bytes as
4153
4154     0x12 0x34 0x56 0x78  # big-endian
4155     0x78 0x56 0x34 0x12  # little-endian
4156
4157 Basically, Intel and VAX CPUs are little-endian, while everybody else,
4158 including Motorola m68k/88k, PPC, Sparc, HP PA, Power, and Cray, are
4159 big-endian.  Alpha and MIPS can be either: Digital/Compaq uses (well, used) 
4160 them in little-endian mode, but SGI/Cray uses them in big-endian mode.
4161
4162 The names I<big-endian> and I<little-endian> are comic references to the
4163 egg-eating habits of the little-endian Lilliputians and the big-endian
4164 Blefuscudians from the classic Jonathan Swift satire, I<Gulliver's Travels>.
4165 This entered computer lingo via the paper "On Holy Wars and a Plea for
4166 Peace" by Danny Cohen, USC/ISI IEN 137, April 1, 1980.
4167
4168 Some systems may have even weirder byte orders such as
4169
4170    0x56 0x78 0x12 0x34
4171    0x34 0x12 0x78 0x56
4172
4173 You can determine your system endianness with this incantation:
4174
4175    printf("%#02x ", $_) for unpack("W*", pack L=>0x12345678); 
4176
4177 The byteorder on the platform where Perl was built is also available
4178 via L<Config>:
4179
4180     use Config;
4181     print "$Config{byteorder}\n";
4182
4183 or from the command line:
4184
4185     $ perl -V:byteorder
4186
4187 Byteorders C<"1234"> and C<"12345678"> are little-endian; C<"4321">
4188 and C<"87654321"> are big-endian.
4189
4190 For portably packed integers, either use the formats C<n>, C<N>, C<v>, 
4191 and C<V> or else use the C<< > >> and C<< < >> modifiers described
4192 immediately below.  See also L<perlport>.
4193
4194 =item *
4195
4196 Starting with Perl 5.9.2, integer and floating-point formats, along with
4197 the C<p> and C<P> formats and C<()> groups, may all be followed by the 
4198 C<< > >> or C<< < >> endianness modifiers to respectively enforce big-
4199 or little-endian byte-order.  These modifiers are especially useful 
4200 given how C<n>, C<N>, C<v>, and C<V> don't cover signed integers, 
4201 64-bit integers, or floating-point values.
4202
4203 Here are some concerns to keep in mind when using an endianness modifier:
4204
4205 =over
4206
4207 =item * 
4208
4209 Exchanging signed integers between different platforms works only 
4210 when all platforms store them in the same format.  Most platforms store
4211 signed integers in two's-complement notation, so usually this is not an issue.
4212
4213 =item * 
4214
4215 The C<< > >> or C<< < >> modifiers can only be used on floating-point
4216 formats on big- or little-endian machines.  Otherwise, attempting to
4217 use them raises an exception.
4218
4219 =item * 
4220
4221 Forcing big- or little-endian byte-order on floating-point values for
4222 data exchange can work only if all platforms use the same
4223 binary representation such as IEEE floating-point.  Even if all
4224 platforms are using IEEE, there may still be subtle differences.  Being able
4225 to use C<< > >> or C<< < >> on floating-point values can be useful,
4226 but also dangerous if you don't know exactly what you're doing.
4227 It is not a general way to portably store floating-point values.
4228
4229 =item * 
4230
4231 When using C<< > >> or C<< < >> on a C<()> group, this affects
4232 all types inside the group that accept byte-order modifiers,
4233 including all subgroups.  It is silently ignored for all other
4234 types.  You are not allowed to override the byte-order within a group
4235 that already has a byte-order modifier suffix.
4236
4237 =back
4238
4239 =item *
4240
4241 Real numbers (floats and doubles) are in native machine format only.
4242 Due to the multiplicity of floating-point formats and the lack of a
4243 standard "network" representation for them, no facility for interchange has been
4244 made.  This means that packed floating-point data written on one machine
4245 may not be readable on another, even if both use IEEE floating-point
4246 arithmetic (because the endianness of the memory representation is not part
4247 of the IEEE spec).  See also L<perlport>.
4248
4249 If you know I<exactly> what you're doing, you can use the C<< > >> or C<< < >>
4250 modifiers to force big- or little-endian byte-order on floating-point values.
4251
4252 Because Perl uses doubles (or long doubles, if configured) internally for
4253 all numeric calculation, converting from double into float and thence 
4254 to double again loses precision, so C<unpack("f", pack("f", $foo)>)
4255 will not in general equal $foo.
4256
4257 =item *
4258
4259 Pack and unpack can operate in two modes: character mode (C<C0> mode) where
4260 the packed string is processed per character, and UTF-8 mode (C<U0> mode)
4261 where the packed string is processed in its UTF-8-encoded Unicode form on
4262 a byte-by-byte basis. Character mode is the default unless the format string 
4263 starts with C<U>. You can always switch mode mid-format with an explicit 
4264 C<C0> or C<U0> in the format.  This mode remains in effect until the next 
4265 mode change, or until the end of the C<()> group it (directly) applies to.
4266
4267 Using C<C0> to get Unicode characters while using C<U0> to get I<non>-Unicode 
4268 bytes is not necessarily obvious.   Probably only the first of these
4269 is what you want:
4270
4271     $ perl -CS -E 'say "\x{3B1}\x{3C9}"' | 
4272       perl -CS -ne 'printf "%v04X\n", $_ for unpack("C0A*", $_)'
4273     03B1.03C9
4274     $ perl -CS -E 'say "\x{3B1}\x{3C9}"' | 
4275       perl -CS -ne 'printf "%v02X\n", $_ for unpack("U0A*", $_)'
4276     CE.B1.CF.89
4277     $ perl -CS -E 'say "\x{3B1}\x{3C9}"' | 
4278       perl -C0 -ne 'printf "%v02X\n", $_ for unpack("C0A*", $_)'
4279     CE.B1.CF.89
4280     $ perl -CS -E 'say "\x{3B1}\x{3C9}"' | 
4281       perl -C0 -ne 'printf "%v02X\n", $_ for unpack("U0A*", $_)'
4282     C3.8E.C2.B1.C3.8F.C2.89
4283
4284 Those examples also illustrate that you should not try to use
4285 C<pack>/C<unpack> as a substitute for the L<Encode> module.
4286
4287 =item *
4288
4289 You must yourself do any alignment or padding by inserting, for example,
4290 enough C<"x">es while packing.  There is no way for pack() and unpack()
4291 to know where characters are going to or coming from, so they 
4292 handle their output and input as flat sequences of characters.
4293
4294 =item *
4295
4296 A C<()> group is a sub-TEMPLATE enclosed in parentheses.  A group may
4297 take a repeat count either as postfix, or for unpack(), also via the C</>
4298 template character.  Within each repetition of a group, positioning with
4299 C<@> starts over at 0. Therefore, the result of
4300
4301     pack("@1A((@2A)@3A)", qw[X Y Z])
4302
4303 is the string C<"\0X\0\0YZ">.
4304
4305 =item *
4306
4307 C<x> and C<X> accept the C<!> modifier to act as alignment commands: they
4308 jump forward or back to the closest position aligned at a multiple of C<count>
4309 characters. For example, to pack() or unpack() a C structure like
4310
4311     struct {
4312         char   c;    /* one signed, 8-bit character */
4313         double d; 
4314         char   cc[2];
4315     }
4316
4317 one may need to use the template C<c x![d] d c[2]>.  This assumes that
4318 doubles must be aligned to the size of double.
4319
4320 For alignment commands, a C<count> of 0 is equivalent to a C<count> of 1;
4321 both are no-ops.
4322
4323 =item *
4324
4325 C<n>, C<N>, C<v> and C<V> accept the C<!> modifier to
4326 represent signed 16-/32-bit integers in big-/little-endian order.
4327 This is portable only when all platforms sharing packed data use the
4328 same binary representation for signed integers; for example, when all
4329 platforms use two's-complement representation.
4330
4331 =item *
4332
4333 Comments can be embedded in a TEMPLATE using C<#> through the end of line.
4334 White space can separate pack codes from each other, but modifiers and
4335 repeat counts must follow immediately.  Breaking complex templates into
4336 individual line-by-line components, suitably annotated, can do as much to
4337 improve legibility and maintainability of pack/unpack formats as C</x> can
4338 for complicated pattern matches.
4339
4340 =item *
4341
4342 If TEMPLATE requires more arguments than pack() is given, pack()
4343 assumes additional C<""> arguments.  If TEMPLATE requires fewer arguments
4344 than given, extra arguments are ignored.
4345
4346 =back
4347
4348 Examples:
4349
4350     $foo = pack("WWWW",65,66,67,68);
4351     # foo eq "ABCD"
4352     $foo = pack("W4",65,66,67,68);
4353     # same thing
4354     $foo = pack("W4",0x24b6,0x24b7,0x24b8,0x24b9);
4355     # same thing with Unicode circled letters.
4356     $foo = pack("U4",0x24b6,0x24b7,0x24b8,0x24b9);
4357     # same thing with Unicode circled letters. You don't get the UTF-8
4358     # bytes because the U at the start of the format caused a switch to
4359     # U0-mode, so the UTF-8 bytes get joined into characters
4360     $foo = pack("C0U4",0x24b6,0x24b7,0x24b8,0x24b9);
4361     # foo eq "\xe2\x92\xb6\xe2\x92\xb7\xe2\x92\xb8\xe2\x92\xb9"
4362     # This is the UTF-8 encoding of the string in the previous example
4363
4364     $foo = pack("ccxxcc",65,66,67,68);
4365     # foo eq "AB\0\0CD"
4366
4367     # NOTE: The examples above featuring "W" and "c" are true
4368     # only on ASCII and ASCII-derived systems such as ISO Latin 1
4369     # and UTF-8.  On EBCDIC systems, the first example would be
4370     #      $foo = pack("WWWW",193,194,195,196);
4371
4372     $foo = pack("s2",1,2);
4373     # "\001\000\002\000" on little-endian
4374     # "\000\001\000\002" on big-endian
4375
4376     $foo = pack("a4","abcd","x","y","z");
4377     # "abcd"
4378
4379     $foo = pack("aaaa","abcd","x","y","z");
4380     # "axyz"
4381
4382     $foo = pack("a14","abcdefg");
4383     # "abcdefg\0\0\0\0\0\0\0"
4384
4385     $foo = pack("i9pl", gmtime);
4386     # a real struct tm (on my system anyway)
4387
4388     $utmp_template = "Z8 Z8 Z16 L";
4389     $utmp = pack($utmp_template, @utmp1);
4390     # a struct utmp (BSDish)
4391
4392     @utmp2 = unpack($utmp_template, $utmp);
4393     # "@utmp1" eq "@utmp2"
4394
4395     sub bintodec {
4396         unpack("N", pack("B32", substr("0" x 32 . shift, -32)));
4397     }
4398
4399     $foo = pack('sx2l', 12, 34);
4400     # short 12, two zero bytes padding, long 34
4401     $bar = pack('s@4l', 12, 34);
4402     # short 12, zero fill to position 4, long 34
4403     # $foo eq $bar
4404     $baz = pack('s.l', 12, 4, 34);
4405     # short 12, zero fill to position 4, long 34
4406
4407     $foo = pack('nN', 42, 4711);
4408     # pack big-endian 16- and 32-bit unsigned integers
4409     $foo = pack('S>L>', 42, 4711);
4410     # exactly the same
4411     $foo = pack('s<l<', -42, 4711);
4412     # pack little-endian 16- and 32-bit signed integers
4413     $foo = pack('(sl)<', -42, 4711);
4414     # exactly the same
4415
4416 The same template may generally also be used in unpack().
4417
4418 =item package NAMESPACE
4419
4420 =item package NAMESPACE VERSION
4421 X<package> X<module> X<namespace> X<version>
4422
4423 =item package NAMESPACE BLOCK
4424
4425 =item package NAMESPACE VERSION BLOCK
4426 X<package> X<module> X<namespace> X<version>
4427
4428 Declares the BLOCK or the rest of the compilation unit as being in the
4429 given namespace.  The scope of the package declaration is either the
4430 supplied code BLOCK or, in the absence of a BLOCK, from the declaration
4431 itself through the end of current scope (the enclosing block, file, or
4432 C<eval>).  That is, the forms without a BLOCK are operative through the end
4433 of the current scope, just like the C<my>, C<state>, and C<our> operators.
4434 All unqualified dynamic identifiers in this scope will be in the given
4435 namespace, except where overridden by another C<package> declaration or
4436 when they're one of the special identifiers that qualify into C<main::>,
4437 like C<STDOUT>, C<ARGV>, C<ENV>, and the punctuation variables.
4438
4439 A package statement affects dynamic variables only, including those
4440 you've used C<local> on, but I<not> lexical variables, which are created
4441 with C<my>, C<state>, or C<our>.  Typically it would be the first 
4442 declaration in a file included by C<require> or C<use>.  You can switch into a
4443 package in more than one place, since this only determines which default 
4444 symbol table the compiler uses for the rest of that block.  You can refer to
4445 identifiers in other packages than the current one by prefixing the identifier
4446 with the package name and a double colon, as in C<$SomePack::var>
4447 or C<ThatPack::INPUT_HANDLE>.  If package name is omitted, the C<main>
4448 package as assumed.  That is, C<$::sail> is equivalent to
4449 C<$main::sail> (as well as to C<$main'sail>, still seen in ancient
4450 code, mostly from Perl 4).
4451
4452 If VERSION is provided, C<package> sets the C<$VERSION> variable in the given
4453 namespace to a L<version> object with the VERSION provided.  VERSION must be a
4454 "strict" style version number as defined by the L<version> module: a positive
4455 decimal number (integer or decimal-fraction) without exponentiation or else a
4456 dotted-decimal v-string with a leading 'v' character and at least three
4457 components.  You should set C<$VERSION> only once per package.
4458
4459 See L<perlmod/"Packages"> for more information about packages, modules,
4460 and classes.  See L<perlsub> for other scoping issues.
4461
4462 =item pipe READHANDLE,WRITEHANDLE
4463 X<pipe>
4464
4465 Opens a pair of connected pipes like the corresponding system call.
4466 Note that if you set up a loop of piped processes, deadlock can occur
4467 unless you are very careful.  In addition, note that Perl's pipes use
4468 IO buffering, so you may need to set C<$|> to flush your WRITEHANDLE
4469 after each command, depending on the application.
4470
4471 See L<IPC::Open2>, L<IPC::Open3>, and
4472 L<perlipc/"Bidirectional Communication with Another Process">
4473 for examples of such things.
4474
4475 On systems that support a close-on-exec flag on files, that flag is set
4476 on all newly opened file descriptors whose C<fileno>s are I<higher> than 
4477 the current value of $^F (by default 2 for C<STDERR>).  See L<perlvar/$^F>.
4478
4479 =item pop ARRAY
4480 X<pop> X<stack>
4481
4482 =item pop EXPR
4483
4484 =item pop
4485
4486 Pops and returns the last value of the array, shortening the array by
4487 one element.
4488
4489 Returns the undefined value if the array is empty, although this may also
4490 happen at other times.  If ARRAY is omitted, pops the C<@ARGV> array in the
4491 main program, but the C<@_> array in subroutines, just like C<shift>.
4492
4493 Starting with Perl 5.14, C<pop> can take a scalar EXPR, which must hold a
4494 reference to an unblessed array.  The argument will be dereferenced
4495 automatically.  This aspect of C<pop> is considered highly experimental.
4496 The exact behaviour may change in a future version of Perl.
4497
4498 =item pos SCALAR
4499 X<pos> X<match, position>
4500
4501 =item pos
4502
4503 Returns the offset of where the last C<m//g> search left off for the
4504 variable in question (C<$_> is used when the variable is not
4505 specified). Note that 0 is a valid match offset. C<undef> indicates
4506 that the search position is reset (usually due to match failure, but
4507 can also be because no match has yet been run on the scalar).
4508
4509 C<pos> directly accesses the location used by the regexp engine to
4510 store the offset, so assigning to C<pos> will change that offset, and
4511 so will also influence the C<\G> zero-width assertion in regular
4512 expressions. Both of these effects take place for the next match, so
4513 you can't affect the position with C<pos> during the current match,
4514 such as in C<(?{pos() = 5})> or C<s//pos() = 5/e>.
4515
4516 Setting C<pos> also resets the I<matched with zero-length> flag, described
4517 under L<perlre/"Repeated Patterns Matching a Zero-length Substring">.
4518
4519 Because a failed C<m//gc> match doesn't reset the offset, the return
4520 from C<pos> won't change either in this case.  See L<perlre> and
4521 L<perlop>.
4522
4523 =item print FILEHANDLE LIST
4524 X<print>
4525
4526 =item print FILEHANDLE
4527
4528 =item print LIST
4529
4530 =item print
4531
4532 Prints a string or a list of strings.  Returns true if successful.
4533 FILEHANDLE may be a scalar variable containing the name of or a reference
4534 to the filehandle, thus introducing one level of indirection.  (NOTE: If
4535 FILEHANDLE is a variable and the next token is a term, it may be
4536 misinterpreted as an operator unless you interpose a C<+> or put
4537 parentheses around the arguments.) If FILEHANDLE is omitted, prints to the
4538 last selected (see L</select>) output handle.  If LIST is omitted, prints
4539 C<$_> to the currently selected output handle.  To use FILEHANDLE alone to
4540 print the content of C<$_> to it, you must use a real filehandle like
4541 C<FH>, not an indirect one like C<$fh>.  To set the default output handle
4542 to something other than STDOUT, use the select operation.
4543
4544 The current value of C<$,> (if any) is printed between each LIST item.  The
4545 current value of C<$\> (if any) is printed after the entire LIST has been
4546 printed.  Because print takes a LIST, anything in the LIST is evaluated in
4547 list context, including any subroutines whose return lists you pass to
4548 C<print>.  Be careful not to follow the print keyword with a left
4549 parenthesis unless you want the corresponding right parenthesis to
4550 terminate the arguments to the print; put parentheses around all arguments
4551 (or interpose a C<+>, but that doesn't look as good).
4552
4553 If you're storing handles in an array or hash, or in general whenever
4554 you're using any expression more complex than a bareword handle or a plain,
4555 unsubscripted scalar variable to retrieve it, you will have to use a block
4556 returning the filehandle value instead, in which case the LIST may not be
4557 omitted:
4558
4559     print { $files[$i] } "stuff\n";
4560     print { $OK ? STDOUT : STDERR } "stuff\n";
4561
4562 Printing to a closed pipe or socket will generate a SIGPIPE signal.  See
4563 L<perlipc> for more on signal handling.
4564
4565 =item printf FILEHANDLE FORMAT, LIST
4566 X<printf>
4567
4568 =item printf FILEHANDLE
4569
4570 =item printf FORMAT, LIST
4571
4572 =item printf
4573
4574 Equivalent to C<print FILEHANDLE sprintf(FORMAT, LIST)>, except that C<$\>
4575 (the output record separator) is not appended.  The first argument of the
4576 list will be interpreted as the C<printf> format. See C<sprintf> for an
4577 explanation of the format argument.    If you omit the LIST, C<$_> is used;
4578 to use FILEHANDLE without a LIST, you must use a real filehandle like
4579 C<FH>, not an indirect one like C<$fh>.  If C<use locale> is in effect and
4580 POSIX::setlocale() has been called, the character used for the decimal
4581 separator in formatted floating-point numbers is affected by the LC_NUMERIC
4582 locale setting.  See L<perllocale> and L<POSIX>.
4583
4584 Don't fall into the trap of using a C<printf> when a simple
4585 C<print> would do.  The C<print> is more efficient and less
4586 error prone.
4587
4588 =item prototype FUNCTION
4589 X<prototype>
4590
4591 Returns the prototype of a function as a string (or C<undef> if the
4592 function has no prototype).  FUNCTION is a reference to, or the name of,
4593 the function whose prototype you want to retrieve.
4594
4595 If FUNCTION is a string starting with C<CORE::>, the rest is taken as a
4596 name for a Perl builtin.  If the builtin is not I<overridable> (such as
4597 C<qw//>) or if its arguments cannot be adequately expressed by a prototype
4598 (such as C<system>), prototype() returns C<undef>, because the builtin
4599 does not really behave like a Perl function.  Otherwise, the string
4600 describing the equivalent prototype is returned.
4601
4602 =item push ARRAY,LIST
4603 X<push> X<stack>
4604
4605 =item push EXPR,LIST
4606
4607 Treats ARRAY as a stack by appending the values of LIST to the end of
4608 ARRAY.  The length of ARRAY increases by the length of LIST.  Has the same
4609 effect as
4610
4611     for $value (LIST) {
4612         $ARRAY[++$#ARRAY] = $value;
4613     }
4614
4615 but is more efficient.  Returns the number of elements in the array following
4616 the completed C<push>.
4617
4618 Starting with Perl 5.14, C<push> can take a scalar EXPR, which must hold a
4619 reference to an unblessed array.  The argument will be dereferenced
4620 automatically.  This aspect of C<push> is considered highly experimental.
4621 The exact behaviour may change in a future version of Perl.
4622
4623 =item q/STRING/
4624
4625 =item qq/STRING/
4626
4627 =item qx/STRING/
4628
4629 =item qw/STRING/
4630
4631 Generalized quotes.  See L<perlop/"Quote-Like Operators">.
4632
4633 =item qr/STRING/
4634
4635 Regexp-like quote.  See L<perlop/"Regexp Quote-Like Operators">.
4636
4637 =item quotemeta EXPR
4638 X<quotemeta> X<metacharacter>
4639
4640 =item quotemeta
4641
4642 Returns the value of EXPR with all non-"word"
4643 characters backslashed.  (That is, all characters not matching
4644 C</[A-Za-z_0-9]/> will be preceded by a backslash in the
4645 returned string, regardless of any locale settings.)
4646 This is the internal function implementing
4647 the C<\Q> escape in double-quoted strings.
4648
4649 If EXPR is omitted, uses C<$_>.
4650
4651 quotemeta (and C<\Q> ... C<\E>) are useful when interpolating strings into
4652 regular expressions, because by default an interpolated variable will be
4653 considered a mini-regular expression. For example:
4654
4655     my $sentence = 'The quick brown fox jumped over the lazy dog';
4656     my $substring = 'quick.*?fox';
4657     $sentence =~ s{$substring}{big bad wolf};
4658
4659 Will cause C<$sentence> to become C<'The big bad wolf jumped over...'>.
4660
4661 On the other hand:
4662
4663     my $sentence = 'The quick brown fox jumped over the lazy dog';
4664     my $substring = 'quick.*?fox';
4665     $sentence =~ s{\Q$substring\E}{big bad wolf};
4666
4667 Or:
4668
4669     my $sentence = 'The quick brown fox jumped over the lazy dog';
4670     my $substring = 'quick.*?fox';
4671     my $quoted_substring = quotemeta($substring);
4672     $sentence =~ s{$quoted_substring}{big bad wolf};
4673
4674 Will both leave the sentence as is. Normally, when accepting literal string
4675 input from the user, quotemeta() or C<\Q> must be used.
4676
4677 In Perl 5.14, all characters whose code points are above 127 are not
4678 quoted in UTF8-encoded strings, but all are quoted in UTF-8 strings.
4679 It is planned to change this behavior in 5.16, but the exact rules
4680 haven't been determined yet.
4681
4682 =item rand EXPR
4683 X<rand> X<random>