Create perldelta for 5.14.3
[perl.git] / pod / perlfork.pod
1 =head1 NAME
2
3 perlfork - Perl's fork() emulation
4
5 =head1 SYNOPSIS
6
7     NOTE:  As of the 5.8.0 release, fork() emulation has considerably
8     matured.  However, there are still a few known bugs and differences
9     from real fork() that might affect you.  See the "BUGS" and
10     "CAVEATS AND LIMITATIONS" sections below.
11
12 Perl provides a fork() keyword that corresponds to the Unix system call
13 of the same name.  On most Unix-like platforms where the fork() system
14 call is available, Perl's fork() simply calls it.
15
16 On some platforms such as Windows where the fork() system call is not
17 available, Perl can be built to emulate fork() at the interpreter level.
18 While the emulation is designed to be as compatible as possible with the
19 real fork() at the level of the Perl program, there are certain
20 important differences that stem from the fact that all the pseudo child
21 "processes" created this way live in the same real process as far as the
22 operating system is concerned.
23
24 This document provides a general overview of the capabilities and
25 limitations of the fork() emulation.  Note that the issues discussed here
26 are not applicable to platforms where a real fork() is available and Perl
27 has been configured to use it.
28
29 =head1 DESCRIPTION
30
31 The fork() emulation is implemented at the level of the Perl interpreter.
32 What this means in general is that running fork() will actually clone the
33 running interpreter and all its state, and run the cloned interpreter in
34 a separate thread, beginning execution in the new thread just after the
35 point where the fork() was called in the parent.  We will refer to the
36 thread that implements this child "process" as the pseudo-process.
37
38 To the Perl program that called fork(), all this is designed to be
39 transparent.  The parent returns from the fork() with a pseudo-process
40 ID that can be subsequently used in any process-manipulation functions;
41 the child returns from the fork() with a value of C<0> to signify that
42 it is the child pseudo-process.
43
44 =head2 Behavior of other Perl features in forked pseudo-processes
45
46 Most Perl features behave in a natural way within pseudo-processes.
47
48 =over 8
49
50 =item $$ or $PROCESS_ID
51
52 This special variable is correctly set to the pseudo-process ID.
53 It can be used to identify pseudo-processes within a particular
54 session.  Note that this value is subject to recycling if any
55 pseudo-processes are launched after others have been wait()-ed on.
56
57 =item %ENV
58
59 Each pseudo-process maintains its own virtual environment.  Modifications
60 to %ENV affect the virtual environment, and are only visible within that
61 pseudo-process, and in any processes (or pseudo-processes) launched from
62 it.
63
64 =item chdir() and all other builtins that accept filenames
65
66 Each pseudo-process maintains its own virtual idea of the current directory.
67 Modifications to the current directory using chdir() are only visible within
68 that pseudo-process, and in any processes (or pseudo-processes) launched from
69 it.  All file and directory accesses from the pseudo-process will correctly
70 map the virtual working directory to the real working directory appropriately.
71
72 =item wait() and waitpid()
73
74 wait() and waitpid() can be passed a pseudo-process ID returned by fork().
75 These calls will properly wait for the termination of the pseudo-process
76 and return its status.
77
78 =item kill()
79
80 C<kill('KILL', ...)> can be used to terminate a pseudo-process by
81 passing it the ID returned by fork().  This should not be used except
82 under dire circumstances, because the operating system may not
83 guarantee integrity of the process resources when a running thread is
84 terminated.  Note that using C<kill('KILL', ...)> on a
85 pseudo-process() may typically cause memory leaks, because the thread
86 that implements the pseudo-process does not get a chance to clean up
87 its resources.
88
89 C<kill('TERM', ...)> can also be used on pseudo-processes, but the
90 signal will not be delivered while the pseudo-process is blocked by a
91 system call, e.g. waiting for a socket to connect, or trying to read
92 from a socket with no data available.  Starting in Perl 5.14 the
93 parent process will not wait for children to exit once they have been
94 signalled with C<kill('TERM', ...)> to avoid deadlock during process
95 exit.  You will have to explicitly call waitpid() to make sure the
96 child has time to clean-up itself, but you are then also responsible
97 that the child is not blocking on I/O either.
98
99 =item exec()
100
101 Calling exec() within a pseudo-process actually spawns the requested
102 executable in a separate process and waits for it to complete before
103 exiting with the same exit status as that process.  This means that the
104 process ID reported within the running executable will be different from
105 what the earlier Perl fork() might have returned.  Similarly, any process
106 manipulation functions applied to the ID returned by fork() will affect the
107 waiting pseudo-process that called exec(), not the real process it is
108 waiting for after the exec().
109
110 When exec() is called inside a pseudo-process then DESTROY methods and
111 END blocks will still be called after the external process returns.
112
113 =item exit()
114
115 exit() always exits just the executing pseudo-process, after automatically
116 wait()-ing for any outstanding child pseudo-processes.  Note that this means
117 that the process as a whole will not exit unless all running pseudo-processes
118 have exited.  See below for some limitations with open filehandles.
119
120 =item Open handles to files, directories and network sockets
121
122 All open handles are dup()-ed in pseudo-processes, so that closing
123 any handles in one process does not affect the others.  See below for
124 some limitations.
125
126 =back
127
128 =head2 Resource limits
129
130 In the eyes of the operating system, pseudo-processes created via the fork()
131 emulation are simply threads in the same process.  This means that any
132 process-level limits imposed by the operating system apply to all
133 pseudo-processes taken together.  This includes any limits imposed by the
134 operating system on the number of open file, directory and socket handles,
135 limits on disk space usage, limits on memory size, limits on CPU utilization
136 etc.
137
138 =head2 Killing the parent process
139
140 If the parent process is killed (either using Perl's kill() builtin, or
141 using some external means) all the pseudo-processes are killed as well,
142 and the whole process exits.
143
144 =head2 Lifetime of the parent process and pseudo-processes
145
146 During the normal course of events, the parent process and every
147 pseudo-process started by it will wait for their respective pseudo-children
148 to complete before they exit.  This means that the parent and every
149 pseudo-child created by it that is also a pseudo-parent will only exit
150 after their pseudo-children have exited.
151
152 Starting with Perl 5.14 a parent will not wait() automatically
153 for any child that has been signalled with C<sig('TERM', ...)>
154 to avoid a deadlock in case the child is blocking on I/O and
155 never receives the signal.
156
157 =head1 CAVEATS AND LIMITATIONS
158
159 =over 8
160
161 =item BEGIN blocks
162
163 The fork() emulation will not work entirely correctly when called from
164 within a BEGIN block.  The forked copy will run the contents of the
165 BEGIN block, but will not continue parsing the source stream after the
166 BEGIN block.  For example, consider the following code:
167
168     BEGIN {
169         fork and exit;          # fork child and exit the parent
170         print "inner\n";
171     }
172     print "outer\n";
173
174 This will print:
175
176     inner
177
178 rather than the expected:
179
180     inner
181     outer
182
183 This limitation arises from fundamental technical difficulties in
184 cloning and restarting the stacks used by the Perl parser in the
185 middle of a parse.
186
187 =item Open filehandles
188
189 Any filehandles open at the time of the fork() will be dup()-ed.  Thus,
190 the files can be closed independently in the parent and child, but beware
191 that the dup()-ed handles will still share the same seek pointer.  Changing
192 the seek position in the parent will change it in the child and vice-versa.
193 One can avoid this by opening files that need distinct seek pointers
194 separately in the child.
195
196 On some operating systems, notably Solaris and Unixware, calling C<exit()>
197 from a child process will flush and close open filehandles in the parent,
198 thereby corrupting the filehandles.  On these systems, calling C<_exit()>
199 is suggested instead.  C<_exit()> is available in Perl through the 
200 C<POSIX> module.  Please consult your system's manpages for more information
201 on this.
202
203 =item Open directory handles
204
205 Perl will completely read from all open directory handles until they
206 reach the end of the stream.  It will then seekdir() back to the
207 original location and all future readdir() requests will be fulfilled
208 from the cache buffer.  That means that neither the directory handle held
209 by the parent process nor the one held by the child process will see
210 any changes made to the directory after the fork() call.
211
212 Note that rewinddir() has a similar limitation on Windows and will not
213 force readdir() to read the directory again either.  Only a newly
214 opened directory handle will reflect changes to the directory.
215
216 =item Forking pipe open() not yet implemented
217
218 The C<open(FOO, "|-")> and C<open(BAR, "-|")> constructs are not yet
219 implemented.  This limitation can be easily worked around in new code
220 by creating a pipe explicitly.  The following example shows how to
221 write to a forked child:
222
223     # simulate open(FOO, "|-")
224     sub pipe_to_fork ($) {
225         my $parent = shift;
226         pipe my $child, $parent or die;
227         my $pid = fork();
228         die "fork() failed: $!" unless defined $pid;
229         if ($pid) {
230             close $child;
231         }
232         else {
233             close $parent;
234             open(STDIN, "<&=" . fileno($child)) or die;
235         }
236         $pid;
237     }
238
239     if (pipe_to_fork('FOO')) {
240         # parent
241         print FOO "pipe_to_fork\n";
242         close FOO;
243     }
244     else {
245         # child
246         while (<STDIN>) { print; }
247         exit(0);
248     }
249
250 And this one reads from the child:
251
252     # simulate open(FOO, "-|")
253     sub pipe_from_fork ($) {
254         my $parent = shift;
255         pipe $parent, my $child or die;
256         my $pid = fork();
257         die "fork() failed: $!" unless defined $pid;
258         if ($pid) {
259             close $child;
260         }
261         else {
262             close $parent;
263             open(STDOUT, ">&=" . fileno($child)) or die;
264         }
265         $pid;
266     }
267
268     if (pipe_from_fork('BAR')) {
269         # parent
270         while (<BAR>) { print; }
271         close BAR;
272     }
273     else {
274         # child
275         print "pipe_from_fork\n";
276         exit(0);
277     }
278
279 Forking pipe open() constructs will be supported in future.
280
281 =item Global state maintained by XSUBs 
282
283 External subroutines (XSUBs) that maintain their own global state may
284 not work correctly.  Such XSUBs will either need to maintain locks to
285 protect simultaneous access to global data from different pseudo-processes,
286 or maintain all their state on the Perl symbol table, which is copied
287 naturally when fork() is called.  A callback mechanism that provides
288 extensions an opportunity to clone their state will be provided in the
289 near future.
290
291 =item Interpreter embedded in larger application
292
293 The fork() emulation may not behave as expected when it is executed in an
294 application which embeds a Perl interpreter and calls Perl APIs that can
295 evaluate bits of Perl code.  This stems from the fact that the emulation
296 only has knowledge about the Perl interpreter's own data structures and
297 knows nothing about the containing application's state.  For example, any
298 state carried on the application's own call stack is out of reach.
299
300 =item Thread-safety of extensions
301
302 Since the fork() emulation runs code in multiple threads, extensions
303 calling into non-thread-safe libraries may not work reliably when
304 calling fork().  As Perl's threading support gradually becomes more
305 widely adopted even on platforms with a native fork(), such extensions
306 are expected to be fixed for thread-safety.
307
308 =back
309
310 =head1 BUGS
311
312 =over 8
313
314 =item *
315
316 Having pseudo-process IDs be negative integers breaks down for the integer
317 C<-1> because the wait() and waitpid() functions treat this number as
318 being special.  The tacit assumption in the current implementation is that
319 the system never allocates a thread ID of C<1> for user threads.  A better
320 representation for pseudo-process IDs will be implemented in future.
321
322 =item *
323
324 In certain cases, the OS-level handles created by the pipe(), socket(),
325 and accept() operators are apparently not duplicated accurately in
326 pseudo-processes.  This only happens in some situations, but where it
327 does happen, it may result in deadlocks between the read and write ends
328 of pipe handles, or inability to send or receive data across socket
329 handles.
330
331 =item *
332
333 This document may be incomplete in some respects.
334
335 =back
336
337 =head1 AUTHOR
338
339 Support for concurrent interpreters and the fork() emulation was implemented
340 by ActiveState, with funding from Microsoft Corporation.
341
342 This document is authored and maintained by Gurusamy Sarathy
343 E<lt>gsar@activestate.comE<gt>.
344
345 =head1 SEE ALSO
346
347 L<perlfunc/"fork">, L<perlipc>
348
349 =cut