use ~1 instead of ^ for parent commit
[perl.git] / Porting / cmpVERSION.pl
1 #!/usr/bin/perl -w
2
3 #
4 # cmpVERSION - compare the current Perl source tree and a given tag
5 # for modules that have identical version numbers but different contents.
6 #
7 # with -d option, output the diffs too
8 # with -x option, exclude files from modules where blead is not upstream
9 #
10 # (after all, there are tools like core-cpan-diff that can already deal with
11 # them)
12 #
13 # Original by slaven@rezic.de, modified by jhi and matt.w.johnson@gmail.com.
14 # Adaptation to produce TAP by Abigail, folded back into this file by Nicholas
15
16 use strict;
17 use 5.006;
18
19 use ExtUtils::MakeMaker;
20 use File::Spec::Functions qw(devnull);
21 use Getopt::Long;
22
23 my ($diffs, $exclude_upstream, $tag_to_compare, $tap);
24 unless (GetOptions('diffs' => \$diffs,
25                    'exclude|x' => \$exclude_upstream,
26                    'tag=s' => \$tag_to_compare,
27                    'tap' => \$tap,
28                    ) && @ARGV == 0) {
29     die "usage: $0 [ -d -x --tag TAG --tap]";
30 }
31
32 die "$0: This does not look like a Perl directory\n"
33     unless -f "perl.h" && -d "Porting";
34 die "$0: 'This is a Perl directory but does not look like Git working directory\n"
35     unless (-d ".git" || (exists $ENV{GIT_DIR} && -d $ENV{GIT_DIR}));
36
37 my $null = devnull();
38
39 unless (defined $tag_to_compare) {
40     my $check = 'HEAD';
41     while(1) {
42         $check = `git describe --abbrev=0 $check 2>$null`;
43         chomp $check;
44         last unless $check =~ /-RC/;
45         $check .= '~1';
46     }
47     $tag_to_compare = $check;
48     # Thanks to David Golden for this suggestion.
49
50 }
51
52 unless (length $tag_to_compare) {
53     die "$0: Git found, but no Git tags found\n"
54         unless $tap;
55     print "1..0 # SKIP: Git found, but no Git tags found\n";
56     exit 0;
57 }
58
59 my $tag_exists = `git --no-pager tag -l $tag_to_compare 2>$null`;
60 chomp $tag_exists;
61
62 unless ($tag_exists eq $tag_to_compare) {
63     die "$0: '$tag_to_compare' is not a known Git tag\n" unless $tap;
64     print "1..0 # SKIP: '$tag_to_compare' is not a known Git tag\n";
65     exit 0;
66 }
67
68 my %upstream_files;
69 if ($exclude_upstream) {
70     unshift @INC, 'Porting';
71     require Maintainers;
72
73     for my $m (grep {!defined $Maintainers::Modules{$_}{UPSTREAM}
74                          or $Maintainers::Modules{$_}{UPSTREAM} ne 'blead'}
75                keys %Maintainers::Modules) {
76         $upstream_files{$_} = 1 for Maintainers::get_module_files($m);
77     }
78 }
79
80 # Files to skip from the check for one reason or another,
81 # usually because they pull in their version from some other file.
82 my %skip;
83 @skip{
84     'cpan/ExtUtils-MakeMaker/t/lib/MakeMaker/Test/Setup/BFD.pm', # just a test module
85     'cpan/ExtUtils-MakeMaker/t/lib/MakeMaker/Test/Setup/XS.pm',  # just a test module
86     'dist/Attribute-Handlers/demo/MyClass.pm', # it's just demonstration code
87     'dist/Exporter/lib/Exporter/Heavy.pm',
88     'lib/Carp/Heavy.pm',
89     'lib/Config.pm',            # no version number but contents will vary
90     'win32/FindExt.pm',
91 } = ();
92
93 # Files to skip just for particular version(s),
94 # usually due to some # mix-up
95
96 my %skip_versions = (
97            # 'some/sample/file.pm' => [ '1.23', '1.24' ],
98           );
99
100 my $skip_dirs = qr|^t/lib|;
101
102 sub pm_file_from_xs {
103     my $xs = shift;
104
105     foreach my $try (sub {
106                          # First try a .pm at the same level as the .xs file
107                          # with the same basename
108                          return shift =~ s/\.xs\z//r;
109                      },
110                      sub {
111                          # Try for a (different) .pm at the same level, based
112                          # on the directory name:
113                          my ($path) = shift =~ m!^(.*)/!;
114                          my ($last) = $path =~ m!([^-/]+)\z!;
115                          return "$path/$last";
116                      },
117                      sub {
118                          # Try to work out the extension's full package, and
119                          # look for a .pm in lib/ based on that:
120                          my ($path) = shift =~ m!^(.*)/!;
121                          my ($last) = $path =~ m!([^/]+)\z!;
122                          $last = 'List-Util' if $last eq 'Scalar-List-Utils';
123                          $last =~ tr !-!/!;
124                          return "$path/lib/$last";
125                      }) {
126         # For all cases, first look to see if the .pm file is generated.
127         my $base = $try->($xs);
128         return "${base}_pm.PL" if -f "${base}_pm.PL";
129         return "${base}.pm" if -f "${base}.pm";
130     }
131
132     die "No idea which .pm file corresponds to '$xs', so aborting";
133 }
134
135 # Key is the .pm file from which we check the version.
136 # Value is a reference to an array of files to check for differences
137 # The trivial case is a pure perl module, where the array holds one element,
138 # the perl module's file. The "fun" comes with XS modules, and the real fun
139 # with XS modules with more than one XS file, and "interesting" layouts.
140
141 my %module_diffs;
142
143 foreach (`git --no-pager diff --name-only $tag_to_compare --diff-filter=ACMRTUXB`) {
144     chomp;
145     next unless m/^(.*)\//;
146     my $this_dir = $1;
147     next if $this_dir =~ $skip_dirs || exists $skip{$_};
148     next if exists $upstream_files{$_};
149     if (/\.pm\z/ || m|^lib/.*\.pl\z| || /_pm\.PL\z/) {
150         push @{$module_diffs{$_}}, $_;
151     } elsif (/\.xs\z/ && !/\bt\b/) {
152         push @{$module_diffs{pm_file_from_xs($_)}}, $_;
153     }
154 }
155
156 unless (%module_diffs) {
157     print "1..1\nok 1 - No difference found\n" if $tap;
158     exit;
159 }
160
161 printf "1..%d\n" => scalar keys %module_diffs if $tap;
162
163 my $count;
164 my $diff_cmd = "git --no-pager diff $tag_to_compare ";
165 my $q = ($^O eq 'MSWin32' || $^O eq 'NetWare' || $^O eq 'VMS') ? '"' : "'";
166 my (@diff);
167
168 foreach my $pm_file (sort keys %module_diffs) {
169     # git has already told us that the files differ, so no need to grab each as
170     # a blob from git, and do the comparison ourselves.
171     my $pm_version = eval {MM->parse_version($pm_file)};
172     my $orig_pm_content = get_file_from_git($pm_file, $tag_to_compare);
173     my $orig_pm_version = eval {MM->parse_version(\$orig_pm_content)};
174     ++$count;
175
176     if (!defined $orig_pm_version || $orig_pm_version eq 'undef') { # sigh
177         print "ok $count - SKIP Can't parse \$VERSION in $pm_file\n"
178           if $tap;
179     } elsif (!defined $pm_version || $pm_version eq 'undef') {
180         print "not ok $count - in $pm_file version was $orig_pm_version, now unparsable\n" if $tap;
181     } elsif ($pm_version ne $orig_pm_version) { # good
182         print "ok $count - $pm_file\n" if $tap;
183     } else {
184         if ($tap) {
185             foreach (sort @{$module_diffs{$pm_file}}) {
186                 print "# $_" for `$diff_cmd $q$_$q`;
187             }
188             if (exists $skip_versions{$pm_file}
189                 and grep $pm_version eq $_, @{$skip_versions{$pm_file}}) {
190                 print "ok $count - SKIP $pm_file version $pm_version\n";
191             } else {
192                 print "not ok $count - $pm_file version $pm_version\n";
193             }
194         } else {
195             push @diff, @{$module_diffs{$pm_file}};
196             print "$pm_file version $pm_version\n";
197         }
198     }
199 }
200
201 sub get_file_from_git {
202     my ($file, $tag) = @_;
203     local $/;
204
205     use open IN => ':raw';
206     return scalar `git --no-pager show $tag:$file 2>$null`;
207 }
208
209 if ($diffs) {
210     for (sort @diff) {
211         print "\n";
212         system "$diff_cmd $q$_$q";
213     }
214 }