[patch] blead@25282 - VMS specific fixes. [2nd try]
[perl.git] / t / op / stat.t
1 #!./perl
2
3 BEGIN {
4     chdir 't' if -d 't';
5     @INC = '../lib';
6     require './test.pl';        # for which_perl() etc
7 }
8
9 use Config;
10 use File::Spec;
11
12 plan tests => 82;
13
14 my $Perl = which_perl();
15
16 $Is_Amiga   = $^O eq 'amigaos';
17 $Is_Cygwin  = $^O eq 'cygwin';
18 $Is_Darwin  = $^O eq 'darwin';
19 $Is_Dos     = $^O eq 'dos';
20 $Is_MacOS   = $^O eq 'MacOS';
21 $Is_MPE     = $^O eq 'mpeix';
22 $Is_MSWin32 = $^O eq 'MSWin32';
23 $Is_NetWare = $^O eq 'NetWare';
24 $Is_OS2     = $^O eq 'os2';
25 $Is_Solaris = $^O eq 'solaris';
26 $Is_VMS     = $^O eq 'VMS';
27 $Is_DGUX    = $^O eq 'dgux';
28 $Is_MPRAS   = $^O =~ /svr4/ && -f '/etc/.relid';
29 $Is_Rhapsody= $^O eq 'rhapsody';
30
31 $Is_Dosish  = $Is_Dos || $Is_OS2 || $Is_MSWin32 || $Is_NetWare || $Is_Cygwin;
32
33 $Is_UFS     = $Is_Darwin && (() = `df -t ufs .`) == 2;
34
35 my($DEV, $INO, $MODE, $NLINK, $UID, $GID, $RDEV, $SIZE,
36    $ATIME, $MTIME, $CTIME, $BLKSIZE, $BLOCKS) = (0..12);
37
38 my $Curdir = File::Spec->curdir;
39
40
41 my $tmpfile = 'Op_stat.tmp';
42 my $tmpfile_link = $tmpfile.'2';
43
44
45 1 while unlink $tmpfile;
46 open(FOO, ">$tmpfile") || DIE("Can't open temp test file: $!");
47 close FOO;
48
49 open(FOO, ">$tmpfile") || DIE("Can't open temp test file: $!");
50
51 my($nlink, $mtime, $ctime) = (stat(FOO))[$NLINK, $MTIME, $CTIME];
52
53 #VMS Fix-me: nlink should work on VMS if applicable link support configured.
54 SKIP: {
55     skip "No link count", 1 if $Is_VMS;
56
57     is($nlink, 1, 'nlink on regular file');
58 }
59
60 SKIP: {
61   skip "mtime and ctime not reliable", 2
62     if $Is_MSWin32 or $Is_NetWare or $Is_Cygwin or $Is_Dos or $Is_MacOS;
63
64   ok( $mtime,           'mtime' );
65   is( $mtime, $ctime,   'mtime == ctime' );
66 }
67
68
69 # Cygwin seems to have a 3 second granularity on its timestamps.
70 my $funky_FAT_timestamps = $Is_Cygwin;
71 sleep 3 if $funky_FAT_timestamps;
72
73 print FOO "Now is the time for all good men to come to.\n";
74 close(FOO);
75
76 sleep 2;
77
78
79 SKIP: {
80     unlink $tmpfile_link;
81     my $lnk_result = eval { link $tmpfile, $tmpfile_link };
82     skip "link() unimplemented", 6 if $@ =~ /unimplemented/;
83
84     is( $@, '',         'link() implemented' );
85     ok( $lnk_result,    'linked tmp testfile' );
86     ok( chmod(0644, $tmpfile),             'chmoded tmp testfile' );
87
88     my($nlink, $mtime, $ctime) = (stat($tmpfile))[$NLINK, $MTIME, $CTIME];
89
90     SKIP: {
91         skip "No link count", 1 if $Config{dont_use_nlink};
92         skip "Cygwin9X fakes hard links by copying", 1
93           if $Config{myuname} =~ /^cygwin_(?:9\d|me)\b/i;
94
95         is($nlink, 2,     'Link count on hard linked file' );
96     }
97
98     SKIP: {
99         my $cwd = File::Spec->rel2abs($Curdir);
100         skip "Solaris tmpfs has different mtime/ctime link semantics", 2
101                                      if $Is_Solaris and $cwd =~ m#^/tmp# and
102                                         $mtime && $mtime == $ctime;
103         skip "AFS has different mtime/ctime link semantics", 2
104                                      if $cwd =~ m#$Config{'afsroot'}/#;
105         skip "AmigaOS has different mtime/ctime link semantics", 2
106                                      if $Is_Amiga;
107         # Win32 could pass $mtime test but as FAT and NTFS have
108         # no ctime concept $ctime is ALWAYS == $mtime
109         # expect netware to be the same ...
110         skip "No ctime concept on this OS", 2
111                                      if $Is_MSWin32 || 
112                                         ($Is_Darwin && $Is_UFS);
113
114         if( !ok($mtime, 'hard link mtime') ||
115             !isnt($mtime, $ctime, 'hard link ctime != mtime') ) {
116             print STDERR <<DIAG;
117 # Check if you are on a tmpfs of some sort.  Building in /tmp sometimes
118 # has this problem.  Building on the ClearCase VOBS filesystem may also
119 # cause this failure.
120 #
121 # Darwin's UFS doesn't have a ctime concept, and thus is expected to fail
122 # this test.
123 DIAG
124         }
125     }
126
127 }
128
129 # truncate and touch $tmpfile.
130 open(F, ">$tmpfile") || DIE("Can't open temp test file: $!");
131 close F;
132
133 ok(-z $tmpfile,     '-z on empty file');
134 ok(! -s $tmpfile,   '   and -s');
135
136 open(F, ">$tmpfile") || DIE("Can't open temp test file: $!");
137 print F "hi\n";
138 close F;
139
140 ok(! -z $tmpfile,   '-z on non-empty file');
141 ok(-s $tmpfile,     '   and -s');
142
143
144 # Strip all access rights from the file.
145 ok( chmod(0000, $tmpfile),     'chmod 0000' );
146
147 SKIP: {
148     skip "-r, -w and -x have different meanings on VMS", 3 if $Is_VMS;
149
150     SKIP: {
151         # Going to try to switch away from root.  Might not work.
152         my $olduid = $>;
153         eval { $> = 1; };
154         skip "Can't test -r or -w meaningfully if you're superuser", 2
155           if $> == 0;
156
157         SKIP: {
158             skip "Can't test -r meaningfully?", 1 if $Is_Dos || $Is_Cygwin;
159             ok(!-r $tmpfile,    "   -r");
160         }
161
162         ok(!-w $tmpfile,    "   -w");
163
164         # switch uid back (may not be implemented)
165         eval { $> = $olduid; };
166     }
167
168     ok(! -x $tmpfile,   '   -x');
169 }
170
171
172
173 ok(chmod(0700,$tmpfile),    'chmod 0700');
174 ok(-r $tmpfile,     '   -r');
175 ok(-w $tmpfile,     '   -w');
176
177 SKIP: {
178     skip "-x simply determines if a file ends in an executable suffix", 1
179       if $Is_Dosish || $Is_MacOS;
180
181     ok(-x $tmpfile,     '   -x');
182 }
183
184 ok(  -f $tmpfile,   '   -f');
185 ok(! -d $tmpfile,   '   !-d');
186
187 # Is this portable?
188 ok(  -d $Curdir,          '-d cwd' );
189 ok(! -f $Curdir,          '!-f cwd' );
190
191
192 SKIP: {
193     unlink($tmpfile_link);
194     my $symlink_rslt = eval { symlink $tmpfile, $tmpfile_link };
195     skip "symlink not implemented", 3 if $@ =~ /unimplemented/;
196
197     is( $@, '',     'symlink() implemented' );
198     ok( $symlink_rslt,      'symlink() ok' );
199     ok(-l $tmpfile_link,    '-l');
200 }
201
202 ok(-o $tmpfile,     '-o');
203
204 ok(-e $tmpfile,     '-e');
205
206 unlink($tmpfile_link);
207 ok(! -e $tmpfile_link,  '   -e on unlinked file');
208
209 SKIP: {
210     skip "No character, socket or block special files", 6
211       if $Is_MSWin32 || $Is_NetWare || $Is_Dos;
212     skip "/dev isn't available to test against", 6
213       unless -d '/dev' && -r '/dev' && -x '/dev';
214     skip "Skipping: unexpected ls output in MP-RAS", 6
215       if $Is_MPRAS;
216
217     # VMS problem:  If GNV or other UNIX like tool is installed, then
218     # sometimes Perl will find /bin/ls, and will try to run it.
219     # But since Perl on VMS does not know to run it under Bash, it will
220     # try to run the DCL verb LS.  And if the VMS product Language
221     # Sensitive Editor is installed, or some other LS verb, that will
222     # be run instead.  So do not do this until we can teach Perl
223     # when to use BASH on VMS.
224     skip "ls command not available to Perl in OpenVMS right now.", 6
225       if $Is_VMS;
226
227     my $LS  = $Config{d_readlink} ? "ls -lL" : "ls -l";
228     my $CMD = "$LS /dev 2>/dev/null";
229     my $DEV = qx($CMD);
230
231     skip "$CMD failed", 6 if $DEV eq '';
232
233     my @DEV = do { my $dev; opendir($dev, "/dev") ? readdir($dev) : () };
234
235     skip "opendir failed: $!", 6 if @DEV == 0;
236
237     # /dev/stdout might be either character special or a named pipe,
238     # or a symlink, or a socket, depending on which OS and how are
239     # you running the test, so let's censor that one away.
240     # Similar remarks hold for stderr.
241     $DEV =~ s{^[cpls].+?\sstdout$}{}m;
242     @DEV =  grep { $_ ne 'stdout' } @DEV;
243     $DEV =~ s{^[cpls].+?\sstderr$}{}m;
244     @DEV =  grep { $_ ne 'stderr' } @DEV;
245
246     # /dev/printer is also naughty: in IRIX it shows up as
247     # Srwx-----, not srwx------.
248     $DEV =~ s{^.+?\sprinter$}{}m;
249     @DEV =  grep { $_ ne 'printer' } @DEV;
250
251     # If running as root, we will see .files in the ls result,
252     # and readdir() will see them always.  Potential for conflict,
253     # so let's weed them out.
254     $DEV =~ s{^.+?\s\..+?$}{}m;
255     @DEV =  grep { ! m{^\..+$} } @DEV;
256
257     # Irix ls -l marks sockets with 'S' while 's' is a 'XENIX semaphore'.
258     if ($^O eq 'irix') {
259         $DEV =~ s{^S(.+?)}{s$1}mg;
260     }
261
262     my $try = sub {
263         my @c1 = eval qq[\$DEV =~ /^$_[0].*/mg];
264         my @c2 = eval qq[grep { $_[1] "/dev/\$_" } \@DEV];
265         my $c1 = scalar @c1;
266         my $c2 = scalar @c2;
267         is($c1, $c2, "ls and $_[1] agreeing on /dev ($c1 $c2)");
268     };
269
270 SKIP: {
271     skip("DG/UX ls -L broken", 3) if $Is_DGUX;
272
273     $try->('b', '-b');
274     $try->('c', '-c');
275     $try->('s', '-S');
276
277 }
278
279 ok(! -b $Curdir,    '!-b cwd');
280 ok(! -c $Curdir,    '!-c cwd');
281 ok(! -S $Curdir,    '!-S cwd');
282
283 }
284
285 SKIP: {
286     my($cnt, $uid);
287     $cnt = $uid = 0;
288
289     # Find a set of directories that's very likely to have setuid files
290     # but not likely to be *all* setuid files.
291     my @bin = grep {-d && -r && -x} qw(/sbin /usr/sbin /bin /usr/bin);
292     skip "Can't find a setuid file to test with", 3 unless @bin;
293
294     for my $bin (@bin) {
295         opendir BIN, $bin or die "Can't opendir $bin: $!";
296         while (defined($_ = readdir BIN)) {
297             $_ = "$bin/$_";
298             $cnt++;
299             $uid++ if -u;
300             last if $uid && $uid < $cnt;
301         }
302     }
303     closedir BIN;
304
305     skip "No setuid programs", 3 if $uid == 0;
306
307     isnt($cnt, 0,    'found some programs');
308     isnt($uid, 0,    '  found some setuid programs');
309     ok($uid < $cnt,  "    they're not all setuid");
310 }
311
312
313 # To assist in automated testing when a controlling terminal (/dev/tty)
314 # may not be available (at, cron  rsh etc), the PERL_SKIP_TTY_TEST env var
315 # can be set to skip the tests that need a tty.
316 SKIP: {
317     skip "These tests require a TTY", 4 if $ENV{PERL_SKIP_TTY_TEST};
318
319     my $TTY = $Is_Rhapsody ? "/dev/ttyp0" : "/dev/tty";
320
321     SKIP: {
322         skip "Test uses unixisms", 2 if $Is_MSWin32 || $Is_NetWare;
323         skip "No TTY to test -t with", 2 unless -e $TTY;
324
325         open(TTY, $TTY) ||
326           warn "Can't open $TTY--run t/TEST outside of make.\n";
327         ok(-t TTY,  '-t');
328         ok(-c TTY,  'tty is -c');
329         close(TTY);
330     }
331     ok(! -t TTY,    '!-t on closed TTY filehandle');
332
333     {
334         local $TODO = 'STDIN not a tty when output is to pipe' if $Is_VMS;
335         ok(-t,          '-t on STDIN');
336     }
337 }
338
339 my $Null = File::Spec->devnull;
340 SKIP: {
341     skip "No null device to test with", 1 unless -e $Null;
342     skip "We know Win32 thinks '$Null' is a TTY", 1 if $Is_MSWin32;
343
344     open(NULL, $Null) or DIE("Can't open $Null: $!");
345     ok(! -t NULL,   'null device is not a TTY');
346     close(NULL);
347 }
348
349
350 # These aren't strictly "stat" calls, but so what?
351 my $statfile = File::Spec->catfile($Curdir, 'op', 'stat.t');
352 ok(  -T $statfile,    '-T');
353 ok(! -B $statfile,    '!-B');
354
355 SKIP: {
356      skip("DG/UX", 1) if $Is_DGUX;
357 ok(-B $Perl,      '-B');
358 }
359
360 ok(! -T $Perl,    '!-T');
361
362 open(FOO,$statfile);
363 SKIP: {
364     eval { -T FOO; };
365     skip "-T/B on filehandle not implemented", 15 if $@ =~ /not implemented/;
366
367     is( $@, '',     '-T on filehandle causes no errors' );
368
369     ok(-T FOO,      '   -T');
370     ok(! -B FOO,    '   !-B');
371
372     $_ = <FOO>;
373     like($_, qr/perl/, 'after readline');
374     ok(-T FOO,      '   still -T');
375     ok(! -B FOO,    '   still -B');
376     close(FOO);
377
378     open(FOO,$statfile);
379     $_ = <FOO>;
380     like($_, qr/perl/,      'reopened and after readline');
381     ok(-T FOO,      '   still -T');
382     ok(! -B FOO,    '   still !-B');
383
384     ok(seek(FOO,0,0),   'after seek');
385     ok(-T FOO,          '   still -T');
386     ok(! -B FOO,        '   still !-B');
387
388     # It's documented this way in perlfunc *shrug*
389     () = <FOO>;
390     ok(eof FOO,         'at EOF');
391     ok(-T FOO,          '   still -T');
392     ok(-B FOO,          '   now -B');
393 }
394 close(FOO);
395
396
397 SKIP: {
398     skip "No null device to test with", 2 unless -e $Null;
399
400     ok(-T $Null,  'null device is -T');
401     ok(-B $Null,  '    and -B');
402 }
403
404
405 # and now, a few parsing tests:
406 $_ = $tmpfile;
407 ok(-f,      'bare -f   uses $_');
408 ok(-f(),    '     -f() "');
409
410 unlink $tmpfile or print "# unlink failed: $!\n";
411
412 # bug id 20011101.069
413 my @r = \stat($Curdir);
414 is(scalar @r, 13,   'stat returns full 13 elements');
415
416 stat $0;
417 eval { lstat _ };
418 like( $@, qr/^The stat preceding lstat\(\) wasn't an lstat/,
419     'lstat _ croaks after stat' );
420 eval { -l _ };
421 like( $@, qr/^The stat preceding -l _ wasn't an lstat/,
422     '-l _ croaks after stat' );
423
424 lstat $0;
425 eval { lstat _ };
426 is( "$@", "", "lstat _ ok after lstat" );
427 eval { -l _ };
428 is( "$@", "", "-l _ ok after lstat" );
429   
430 SKIP: {
431     skip "No lstat", 2 unless $Config{d_lstat};
432
433     # bug id 20020124.004
434     # If we have d_lstat, we should have symlink()
435     my $linkname = 'dolzero';
436     symlink $0, $linkname or die "# Can't symlink $0: $!";
437     lstat $linkname;
438     -T _;
439     eval { lstat _ };
440     like( $@, qr/^The stat preceding lstat\(\) wasn't an lstat/,
441         'lstat croaks after -T _' );
442     eval { -l _ };
443     like( $@, qr/^The stat preceding -l _ wasn't an lstat/,
444         '-l _ croaks after -T _' );
445     unlink $linkname or print "# unlink $linkname failed: $!\n";
446 }
447
448 print "# Zzz...\n";
449 sleep(3);
450 my $f = 'tstamp.tmp';
451 unlink $f;
452 ok (open(S, "> $f"), 'can create tmp file');
453 close S or die;
454 my @a = stat $f;
455 print "# time=$^T, stat=(@a)\n";
456 my @b = (-M _, -A _, -C _);
457 print "# -MAC=(@b)\n";
458 ok( (-M _) < 0, 'negative -M works');
459 ok( (-A _) < 0, 'negative -A works');
460 ok( (-C _) < 0, 'negative -C works');
461 ok(unlink($f), 'unlink tmp file');
462
463 {
464     ok(open(F, ">", $tmpfile), 'can create temp file');
465     close F;
466     chmod 0077, $tmpfile;
467     my @a = stat($tmpfile);
468     my $s1 = -s _;
469     -T _;
470     my $s2 = -s _;
471     is($s1, $s2, q(-T _ doesn't break the statbuffer));
472     unlink $tmpfile;
473 }
474
475 END {
476     1 while unlink $tmpfile;
477 }