Support one-parameter unpack(), which unpacks $_.
[perl.git] / installman
1 #!./perl -w
2 BEGIN { @INC = qw(lib) }
3 use strict;
4 use Config;
5 use Getopt::Long;
6 use File::Find;
7 use File::Copy;
8 use File::Path qw(mkpath);
9 use ExtUtils::Packlist;
10 use Pod::Man;
11 use subs qw(unlink chmod rename link);
12 use vars qw($packlist);
13
14 if ($Config{d_umask}) {
15     umask(022); # umasks like 077 aren't that useful for installations
16 }
17
18 $ENV{SHELL} = 'sh' if $^O eq 'os2';
19
20 my $ver = $Config{version};     # Not used presently.
21 my $release = substr($],0,3);   # Not used presently.
22 my $patchlevel = substr($],3,2);
23 die "Patchlevel of perl ($patchlevel)",
24     "and patchlevel of config.sh ($Config{'PERL_VERSION'}) don't match\n"
25         if $patchlevel != $Config{'PERL_VERSION'};
26
27 my $usage =
28 "Usage:  installman --man1dir=/usr/wherever --man1ext=1
29                    --man3dir=/usr/wherever --man3ext=3
30                    --batchlimit=40
31                    --notify --verbose --silent --help
32         Defaults are:
33         man1dir = $Config{'installman1dir'};
34         man1ext = $Config{'man1ext'};
35         man3dir = $Config{'installman3dir'};
36         man3ext = $Config{'man3ext'};
37         --notify  (or -n) just lists commands that would be executed.
38         --verbose (or -V) report all progress.
39         --silent  (or -S) be silent. Only report errors.\n";
40
41 my %opts;
42 GetOptions( \%opts,
43             qw( man1dir=s man1ext=s man3dir=s man3ext=s batchlimit=i
44                 notify n help silent S verbose V)) 
45         || die $usage;
46 die $usage if $opts{help};
47
48 $opts{man1dir} = $Config{'installman1dir'}
49     unless defined($opts{man1dir}); 
50 $opts{man1ext} = $Config{'man1ext'}
51     unless defined($opts{man1ext}); 
52 $opts{man3dir} = $Config{'installman3dir'}
53     unless defined($opts{man3dir}); 
54 $opts{man3ext} = $Config{'man3ext'}
55     unless defined($opts{man3ext}); 
56 $opts{silent} ||= $opts{S};
57 $opts{notify} ||= $opts{n};
58 $opts{verbose} ||= $opts{V} || $opts{notify};
59
60 #Sanity checks
61
62 -x  "./perl$Config{exe_ext}" 
63   or warn "./perl$Config{exe_ext} not found!  Have you run make?\n";
64 -d  $Config{'installprivlib'}
65         || warn "Perl library directory $Config{'installprivlib'} not found.
66                 Have you run make install?.  (Installing anyway.)\n";
67 -x "t/perl$Config{exe_ext}"             || warn "WARNING: You've never run 'make test'!!!",
68         "  (Installing anyway.)\n";
69
70 $packlist = ExtUtils::Packlist->new("$Config{installarchlib}/.packlist");
71
72
73 # Install the main pod pages.
74 pod2man('pod', $opts{man1dir}, $opts{man1ext});
75
76 # Install the pods for library modules.
77 pod2man('lib', $opts{man3dir}, $opts{man3ext});
78
79 # Install the pods embedded in the installed scripts
80 my $has_man1dir = $opts{man1dir} ne '' && -d $opts{man1dir};
81 open UTILS, "utils.lst" or die "Can't open 'utils.lst': $!";
82 while (<UTILS>) {
83     next if /^#/;
84     chomp;
85     $_ = $1 if /#.*pod\s*=\s*(\S+)/;
86     my ($where, $what) = m|^(\S*)/(\S+)|;
87     pod2man($where, $opts{man1dir}, $opts{man1ext}, $what);
88     if ($has_man1dir) {
89         if (my ($where2, $what2) = m|#.*link\s*=\s*(\S+)/(\S+)|) {
90             my $old = "$opts{man1dir}/$what.$opts{man1ext}";
91             my $new = "$opts{man1dir}/$what2.$opts{man1ext}";
92             unlink($new);
93             link($old, $new);
94         }
95     }
96 }
97
98 sub pod2man {
99     # @script is scripts names if we are installing manpages embedded 
100     # in scripts, () otherwise
101     my($poddir, $mandir, $manext, @script) = @_;
102     if ($mandir eq ' ' or $mandir eq '') {
103         if (@script) {
104             warn "Skipping installation of $poddir/$_ man page.\n"
105                 foreach @script;
106         } else {
107             warn "Skipping installation of $poddir man pages.\n";
108         }
109         return;
110     }
111
112     print "installing from $poddir\n" if $opts{verbose};
113
114     mkpath($mandir, $opts{verbose}, 0777) unless $opts{notify};  # In File::Path
115     # Make a list of all the .pm and .pod files in the directory.  We avoid
116     # chdir because we are running with @INC = '../lib', and modules may wish
117     # to dynamically require Carp::Heavy or other diagnostics warnings.
118     # Hash the names of files we find, keys are names relative to perl build
119     # dir ('.'), values are names relative to $poddir.
120     my %modpods;
121     if (@script) {
122         %modpods = (map {+"$poddir/$_", $_} @script);
123     }
124     else {
125         File::Find::find({no_chdir=>1,
126                           wanted => sub {
127                               # $_ is $File::Find::name when using no_chdir
128                               if (-f $_ and /\.p(?:m|od)$/) {
129                                   my $fullname = $_;
130                                   s!^\Q$poddir\E/!!;
131                                   $modpods{$fullname} = $_;
132                               }
133                           }},
134                          $poddir);
135     }
136     my @to_process;
137     foreach my $mod (sort keys %modpods) {
138         my $manpage = $modpods{$mod};
139         my $tmp;
140         # Skip .pm files that have corresponding .pod files, and Functions.pm.
141         next if (($tmp = $mod) =~ s/\.pm$/.pod/ && -f $tmp);
142         next if $mod =~ m:/t/:; # no pods from test directories 
143         next if ($manpage eq 'Pod/Functions.pm'); #### Used only by pod itself
144
145         # Convert name from  File/Basename.pm to File::Basename.3 format,
146         # if necessary.
147         $manpage =~ s#\.p(m|od)$##;
148         if ($^O eq 'os2' || $^O eq 'amigaos' || $^O eq 'uwin' || $^O eq 'cygwin') {
149           $manpage =~ s#/#.#g;
150         }
151         else {
152           $manpage =~ s#/#::#g;
153         }
154         $tmp = "${mandir}/${manpage}.tmp";
155         $manpage = "${mandir}/${manpage}.${manext}";
156         push @to_process, [$mod, $tmp, $manpage];
157     }
158
159     my $parser = Pod::Man->new( section => $manext,
160                                 official=> 1,
161                                 center  => 'Perl Programmers Reference Guide'
162                               );
163     foreach my $page (@to_process) {
164         my($pod, $tmp, $manpage) = @$page;
165
166         print "  $manpage\n";
167         if (!$opts{notify} && $parser->parse_from_file($pod, $tmp)) {
168             if (-s $tmp) {
169                 if (rename($tmp, $manpage)) {
170                     $packlist->{$manpage} = { type => 'file' };
171                     next;
172                 }
173             }
174             unlink($tmp);
175         }
176     }
177 }
178
179 $packlist->write() unless $opts{notify};
180 print "  Installation complete\n" if $opts{verbose};
181
182 exit 0;
183     
184
185 ###############################################################################
186 # Utility subroutines from installperl
187
188 sub unlink {
189     my(@names) = @_;
190     my $cnt = 0;
191
192     foreach my $name (@names) {
193         next unless -e $name;
194         chmod 0777, $name if $^O eq 'os2';
195         print "  unlink $name\n" if $opts{verbose};
196         ( CORE::unlink($name) and ++$cnt 
197             or warn "Couldn't unlink $name: $!\n" ) unless $opts{notify};
198     }
199     return $cnt;
200 }
201
202 sub link {
203     my($from,$to) = @_;
204     my($success) = 0;
205
206     print "  ln $from $to\n" if $opts{verbose};
207     eval {
208         CORE::link($from, $to)
209             ? $success++
210             : ($from =~ m#^/afs/# || $to =~ m#^/afs/#)
211               ? die "AFS"  # okay inside eval {}
212               : warn "Couldn't link $from to $to: $!\n"
213           unless $opts{notify};
214     };
215     if ($@) {
216         File::Copy::copy($from, $to)
217             ? $success++
218             : warn "Couldn't copy $from to $to: $!\n"
219           unless $opts{notify};
220     }
221     $success;
222 }
223
224 sub rename {
225     my($from,$to) = @_;
226     if (-f $to and not unlink($to)) {
227         my($i);
228         for ($i = 1; $i < 50; $i++) {
229             last if CORE::rename($to, "$to.$i");
230         }
231         warn("Cannot rename to `$to.$i': $!"), return 0 
232             if $i >= 50;        # Give up!
233     }
234     link($from,$to) || return 0;
235     unlink($from);
236 }
237
238 sub chmod {
239     my($mode,$name) = @_;
240
241     printf "  chmod %o %s\n", $mode, $name if $opts{verbose};
242     CORE::chmod($mode,$name) || warn sprintf("Couldn't chmod %o %s: $!\n",$mode,$name)
243         unless $opts{notify};
244 }
245
246 sub samepath {
247     my($p1, $p2) = @_;
248     my($dev1, $ino1, $dev2, $ino2);
249
250     if ($p1 ne $p2) {
251         ($dev1, $ino1) = stat($p1);
252         ($dev2, $ino2) = stat($p2);
253         ($dev1 == $dev2 && $ino1 == $ino2);
254     }
255     else {
256         1;
257     }
258 }