Upgrade to Tie::File 0.20.
[perl.git] / pod / perltrap.pod
1 =head1 NAME
2
3 perltrap - Perl traps for the unwary
4
5 =head1 DESCRIPTION
6
7 The biggest trap of all is forgetting to C<use warnings> or use the B<-w>
8 switch; see L<perllexwarn> and L<perlrun>. The second biggest trap is not
9 making your entire program runnable under C<use strict>.  The third biggest
10 trap is not reading the list of changes in this version of Perl; see
11 L<perldelta>.
12
13 =head2 Awk Traps
14
15 Accustomed B<awk> users should take special note of the following:
16
17 =over 4
18
19 =item *
20
21 The English module, loaded via
22
23     use English;
24
25 allows you to refer to special variables (like C<$/>) with names (like
26 $RS), as though they were in B<awk>; see L<perlvar> for details.
27
28 =item *
29
30 Semicolons are required after all simple statements in Perl (except
31 at the end of a block).  Newline is not a statement delimiter.
32
33 =item *
34
35 Curly brackets are required on C<if>s and C<while>s.
36
37 =item *
38
39 Variables begin with "$", "@" or "%" in Perl.
40
41 =item *
42
43 Arrays index from 0.  Likewise string positions in substr() and
44 index().
45
46 =item *
47
48 You have to decide whether your array has numeric or string indices.
49
50 =item *
51
52 Hash values do not spring into existence upon mere reference.
53
54 =item *
55
56 You have to decide whether you want to use string or numeric
57 comparisons.
58
59 =item *
60
61 Reading an input line does not split it for you.  You get to split it
62 to an array yourself.  And the split() operator has different
63 arguments than B<awk>'s.
64
65 =item *
66
67 The current input line is normally in $_, not $0.  It generally does
68 not have the newline stripped.  ($0 is the name of the program
69 executed.)  See L<perlvar>.
70
71 =item *
72
73 $<I<digit>> does not refer to fields--it refers to substrings matched
74 by the last match pattern.
75
76 =item *
77
78 The print() statement does not add field and record separators unless
79 you set C<$,> and C<$\>.  You can set $OFS and $ORS if you're using
80 the English module.
81
82 =item *
83
84 You must open your files before you print to them.
85
86 =item *
87
88 The range operator is "..", not comma.  The comma operator works as in
89 C.
90
91 =item *
92
93 The match operator is "=~", not "~".  ("~" is the one's complement
94 operator, as in C.)
95
96 =item *
97
98 The exponentiation operator is "**", not "^".  "^" is the XOR
99 operator, as in C.  (You know, one could get the feeling that B<awk> is
100 basically incompatible with C.)
101
102 =item *
103
104 The concatenation operator is ".", not the null string.  (Using the
105 null string would render C</pat/ /pat/> unparsable, because the third slash
106 would be interpreted as a division operator--the tokenizer is in fact
107 slightly context sensitive for operators like "/", "?", and ">".
108 And in fact, "." itself can be the beginning of a number.)
109
110 =item *
111
112 The C<next>, C<exit>, and C<continue> keywords work differently.
113
114 =item *
115
116
117 The following variables work differently:
118
119       Awk       Perl
120       ARGC      scalar @ARGV (compare with $#ARGV)
121       ARGV[0]   $0
122       FILENAME  $ARGV
123       FNR       $. - something
124       FS        (whatever you like)
125       NF        $#Fld, or some such
126       NR        $.
127       OFMT      $#
128       OFS       $,
129       ORS       $\
130       RLENGTH   length($&)
131       RS        $/
132       RSTART    length($`)
133       SUBSEP    $;
134
135 =item *
136
137 You cannot set $RS to a pattern, only a string.
138
139 =item *
140
141 When in doubt, run the B<awk> construct through B<a2p> and see what it
142 gives you.
143
144 =back
145
146 =head2 C Traps
147
148 Cerebral C programmers should take note of the following:
149
150 =over 4
151
152 =item *
153
154 Curly brackets are required on C<if>'s and C<while>'s.
155
156 =item *
157
158 You must use C<elsif> rather than C<else if>.
159
160 =item *
161
162 The C<break> and C<continue> keywords from C become in
163 Perl C<last> and C<next>, respectively.
164 Unlike in C, these do I<not> work within a C<do { } while> construct.
165
166 =item *
167
168 There's no switch statement.  (But it's easy to build one on the fly.)
169
170 =item *
171
172 Variables begin with "$", "@" or "%" in Perl.
173
174 =item *
175
176 Comments begin with "#", not "/*".
177
178 =item *
179
180 You can't take the address of anything, although a similar operator
181 in Perl is the backslash, which creates a reference.
182
183 =item *
184
185 C<ARGV> must be capitalized.  C<$ARGV[0]> is C's C<argv[1]>, and C<argv[0]>
186 ends up in C<$0>.
187
188 =item *
189
190 System calls such as link(), unlink(), rename(), etc. return nonzero for
191 success, not 0. (system(), however, returns zero for success.)
192
193 =item *
194
195 Signal handlers deal with signal names, not numbers.  Use C<kill -l>
196 to find their names on your system.
197
198 =back
199
200 =head2 Sed Traps
201
202 Seasoned B<sed> programmers should take note of the following:
203
204 =over 4
205
206 =item *
207
208 Backreferences in substitutions use "$" rather than "\".
209
210 =item *
211
212 The pattern matching metacharacters "(", ")", and "|" do not have backslashes
213 in front.
214
215 =item *
216
217 The range operator is C<...>, rather than comma.
218
219 =back
220
221 =head2 Shell Traps
222
223 Sharp shell programmers should take note of the following:
224
225 =over 4
226
227 =item *
228
229 The backtick operator does variable interpolation without regard to
230 the presence of single quotes in the command.
231
232 =item *
233
234 The backtick operator does no translation of the return value, unlike B<csh>.
235
236 =item *
237
238 Shells (especially B<csh>) do several levels of substitution on each
239 command line.  Perl does substitution in only certain constructs
240 such as double quotes, backticks, angle brackets, and search patterns.
241
242 =item *
243
244 Shells interpret scripts a little bit at a time.  Perl compiles the
245 entire program before executing it (except for C<BEGIN> blocks, which
246 execute at compile time).
247
248 =item *
249
250 The arguments are available via @ARGV, not $1, $2, etc.
251
252 =item *
253
254 The environment is not automatically made available as separate scalar
255 variables.
256
257 =back
258
259 =head2 Perl Traps
260
261 Practicing Perl Programmers should take note of the following:
262
263 =over 4
264
265 =item *
266
267 Remember that many operations behave differently in a list
268 context than they do in a scalar one.  See L<perldata> for details.
269
270 =item *
271
272 Avoid barewords if you can, especially all lowercase ones.
273 You can't tell by just looking at it whether a bareword is
274 a function or a string.  By using quotes on strings and
275 parentheses on function calls, you won't ever get them confused.
276
277 =item *
278
279 You cannot discern from mere inspection which builtins
280 are unary operators (like chop() and chdir())
281 and which are list operators (like print() and unlink()).
282 (Unless prototyped, user-defined subroutines can B<only> be list
283 operators, never unary ones.)  See L<perlop> and L<perlsub>.
284
285 =item *
286
287 People have a hard time remembering that some functions
288 default to $_, or @ARGV, or whatever, but that others which
289 you might expect to do not.
290
291 =item *
292
293 The <FH> construct is not the name of the filehandle, it is a readline
294 operation on that handle.  The data read is assigned to $_ only if the
295 file read is the sole condition in a while loop:
296
297     while (<FH>)      { }
298     while (defined($_ = <FH>)) { }..
299     <FH>;  # data discarded!
300
301 =item *
302
303 Remember not to use C<=> when you need C<=~>;
304 these two constructs are quite different:
305
306     $x =  /foo/;
307     $x =~ /foo/;
308
309 =item *
310
311 The C<do {}> construct isn't a real loop that you can use
312 loop control on.
313
314 =item *
315
316 Use C<my()> for local variables whenever you can get away with
317 it (but see L<perlform> for where you can't).
318 Using C<local()> actually gives a local value to a global
319 variable, which leaves you open to unforeseen side-effects
320 of dynamic scoping.
321
322 =item *
323
324 If you localize an exported variable in a module, its exported value will
325 not change.  The local name becomes an alias to a new value but the
326 external name is still an alias for the original.
327
328 =back
329
330 =head2 Perl4 to Perl5 Traps
331
332 Practicing Perl4 Programmers should take note of the following
333 Perl4-to-Perl5 specific traps.
334
335 They're crudely ordered according to the following list:
336
337 =over 4
338
339 =item Discontinuance, Deprecation, and BugFix traps
340
341 Anything that's been fixed as a perl4 bug, removed as a perl4 feature
342 or deprecated as a perl4 feature with the intent to encourage usage of
343 some other perl5 feature.
344
345 =item Parsing Traps
346
347 Traps that appear to stem from the new parser.
348
349 =item Numerical Traps
350
351 Traps having to do with numerical or mathematical operators.
352
353 =item General data type traps
354
355 Traps involving perl standard data types.
356
357 =item Context Traps - scalar, list contexts
358
359 Traps related to context within lists, scalar statements/declarations.
360
361 =item Precedence Traps
362
363 Traps related to the precedence of parsing, evaluation, and execution of
364 code.
365
366 =item General Regular Expression Traps using s///, etc.
367
368 Traps related to the use of pattern matching.
369
370 =item Subroutine, Signal, Sorting Traps
371
372 Traps related to the use of signals and signal handlers, general subroutines,
373 and sorting, along with sorting subroutines.
374
375 =item OS Traps
376
377 OS-specific traps.
378
379 =item DBM Traps
380
381 Traps specific to the use of C<dbmopen()>, and specific dbm implementations.
382
383 =item Unclassified Traps
384
385 Everything else.
386
387 =back
388
389 If you find an example of a conversion trap that is not listed here,
390 please submit it to <F<perlbug@perl.org>> for inclusion.
391 Also note that at least some of these can be caught with the
392 C<use warnings> pragma or the B<-w> switch.
393
394 =head2 Discontinuance, Deprecation, and BugFix traps
395
396 Anything that has been discontinued, deprecated, or fixed as
397 a bug from perl4.
398
399 =over 4
400
401 =item * Discontinuance
402
403 Symbols starting with "_" are no longer forced into package main, except
404 for C<$_> itself (and C<@_>, etc.).
405
406     package test;
407     $_legacy = 1;
408
409     package main;
410     print "\$_legacy is ",$_legacy,"\n";
411
412     # perl4 prints: $_legacy is 1
413     # perl5 prints: $_legacy is
414
415 =item * Deprecation
416
417 Double-colon is now a valid package separator in a variable name.  Thus these
418 behave differently in perl4 vs. perl5, because the packages don't exist.
419
420     $a=1;$b=2;$c=3;$var=4;
421     print "$a::$b::$c ";
422     print "$var::abc::xyz\n";
423
424     # perl4 prints: 1::2::3 4::abc::xyz
425     # perl5 prints: 3
426
427 Given that C<::> is now the preferred package delimiter, it is debatable
428 whether this should be classed as a bug or not.
429 (The older package delimiter, ' ,is used here)
430
431     $x = 10 ;
432     print "x=${'x}\n" ;
433
434     # perl4 prints: x=10
435     # perl5 prints: Can't find string terminator "'" anywhere before EOF
436
437 You can avoid this problem, and remain compatible with perl4, if you
438 always explicitly include the package name:
439
440     $x = 10 ;
441     print "x=${main'x}\n" ;
442
443 Also see precedence traps, for parsing C<$:>.
444
445 =item * BugFix
446
447 The second and third arguments of C<splice()> are now evaluated in scalar
448 context (as the Camel says) rather than list context.
449
450     sub sub1{return(0,2) }          # return a 2-element list
451     sub sub2{ return(1,2,3)}        # return a 3-element list
452     @a1 = ("a","b","c","d","e");
453     @a2 = splice(@a1,&sub1,&sub2);
454     print join(' ',@a2),"\n";
455
456     # perl4 prints: a b
457     # perl5 prints: c d e
458
459 =item * Discontinuance
460
461 You can't do a C<goto> into a block that is optimized away.  Darn.
462
463     goto marker1;
464
465     for(1){
466     marker1:
467         print "Here I is!\n";
468     }
469
470     # perl4 prints: Here I is!
471     # perl5 errors: Can't "goto" into the middle of a foreach loop
472
473 =item * Discontinuance
474
475 It is no longer syntactically legal to use whitespace as the name
476 of a variable, or as a delimiter for any kind of quote construct.
477 Double darn.
478
479     $a = ("foo bar");
480     $b = q baz ;
481     print "a is $a, b is $b\n";
482
483     # perl4 prints: a is foo bar, b is baz
484     # perl5 errors: Bareword found where operator expected
485
486 =item * Discontinuance
487
488 The archaic while/if BLOCK BLOCK syntax is no longer supported.
489
490     if { 1 } {
491         print "True!";
492     }
493     else {
494         print "False!";
495     }
496
497     # perl4 prints: True!
498     # perl5 errors: syntax error at test.pl line 1, near "if {"
499
500 =item * BugFix
501
502 The C<**> operator now binds more tightly than unary minus.
503 It was documented to work this way before, but didn't.
504
505     print -4**2,"\n";
506
507     # perl4 prints: 16
508     # perl5 prints: -16
509
510 =item * Discontinuance
511
512 The meaning of C<foreach{}> has changed slightly when it is iterating over a
513 list which is not an array.  This used to assign the list to a
514 temporary array, but no longer does so (for efficiency).  This means
515 that you'll now be iterating over the actual values, not over copies of
516 the values.  Modifications to the loop variable can change the original
517 values.
518
519     @list = ('ab','abc','bcd','def');
520     foreach $var (grep(/ab/,@list)){
521         $var = 1;
522     }
523     print (join(':',@list));
524
525     # perl4 prints: ab:abc:bcd:def
526     # perl5 prints: 1:1:bcd:def
527
528 To retain Perl4 semantics you need to assign your list
529 explicitly to a temporary array and then iterate over that.  For
530 example, you might need to change
531
532     foreach $var (grep(/ab/,@list)){
533
534 to
535
536     foreach $var (@tmp = grep(/ab/,@list)){
537
538 Otherwise changing $var will clobber the values of @list.  (This most often
539 happens when you use C<$_> for the loop variable, and call subroutines in
540 the loop that don't properly localize C<$_>.)
541
542 =item * Discontinuance
543
544 C<split> with no arguments now behaves like C<split ' '> (which doesn't
545 return an initial null field if $_ starts with whitespace), it used to
546 behave like C<split /\s+/> (which does).
547
548     $_ = ' hi mom';
549     print join(':', split);
550
551     # perl4 prints: :hi:mom
552     # perl5 prints: hi:mom
553
554 =item * BugFix
555
556 Perl 4 would ignore any text which was attached to an B<-e> switch,
557 always taking the code snippet from the following arg.  Additionally, it
558 would silently accept an B<-e> switch without a following arg.  Both of
559 these behaviors have been fixed.
560
561     perl -e'print "attached to -e"' 'print "separate arg"'
562
563     # perl4 prints: separate arg
564     # perl5 prints: attached to -e
565
566     perl -e
567
568     # perl4 prints:
569     # perl5 dies: No code specified for -e.
570
571 =item * Discontinuance
572
573 In Perl 4 the return value of C<push> was undocumented, but it was
574 actually the last value being pushed onto the target list.  In Perl 5
575 the return value of C<push> is documented, but has changed, it is the
576 number of elements in the resulting list.
577
578     @x = ('existing');
579     print push(@x, 'first new', 'second new');
580
581     # perl4 prints: second new
582     # perl5 prints: 3
583
584 =item * Deprecation
585
586 Some error messages will be different.
587
588 =item * Discontinuance
589
590 In Perl 4, if in list context the delimiters to the first argument of
591 C<split()> were C<??>, the result would be placed in C<@_> as well as
592 being returned.   Perl 5 has more respect for your subroutine arguments.
593
594 =item * Discontinuance
595
596 Some bugs may have been inadvertently removed.  :-)
597
598 =back
599
600 =head2 Parsing Traps
601
602 Perl4-to-Perl5 traps from having to do with parsing.
603
604 =over 4
605
606 =item * Parsing
607
608 Note the space between . and =
609
610     $string . = "more string";
611     print $string;
612
613     # perl4 prints: more string
614     # perl5 prints: syntax error at - line 1, near ". ="
615
616 =item * Parsing
617
618 Better parsing in perl 5
619
620     sub foo {}
621     &foo
622     print("hello, world\n");
623
624     # perl4 prints: hello, world
625     # perl5 prints: syntax error
626
627 =item * Parsing
628
629 "if it looks like a function, it is a function" rule.
630
631   print
632     ($foo == 1) ? "is one\n" : "is zero\n";
633
634     # perl4 prints: is zero
635     # perl5 warns: "Useless use of a constant in void context" if using -w
636
637 =item * Parsing
638
639 String interpolation of the C<$#array> construct differs when braces
640 are to used around the name.
641
642     @a = (1..3);
643     print "${#a}";
644
645     # perl4 prints: 2
646     # perl5 fails with syntax error
647
648     @ = (1..3);
649     print "$#{a}";
650
651     # perl4 prints: {a}
652     # perl5 prints: 2
653
654 =item * Parsing
655
656 When perl sees C<map {> (or C<grep {>), it has to guess whether the C<{>
657 starts a BLOCK or a hash reference. If it guesses wrong, it will report
658 a syntax error near the C<}> and the missing (or unexpected) comma.
659
660 Use unary C<+> before C<{> on a hash reference, and unary C<+> applied
661 to the first thing in a BLOCK (after C<{>), for perl to guess right all
662 the time. (See L<perlfunc/map>.)
663
664 =back
665
666 =head2 Numerical Traps
667
668 Perl4-to-Perl5 traps having to do with numerical operators,
669 operands, or output from same.
670
671 =over 5
672
673 =item * Numerical
674
675 Formatted output and significant digits
676
677     print 7.373504 - 0, "\n";
678     printf "%20.18f\n", 7.373504 - 0;
679
680     # Perl4 prints:
681     7.375039999999996141
682     7.37503999999999614
683
684     # Perl5 prints:
685     7.373504
686     7.37503999999999614
687
688 =item * Numerical
689
690 This specific item has been deleted.  It demonstrated how the auto-increment
691 operator would not catch when a number went over the signed int limit.  Fixed
692 in version 5.003_04.  But always be wary when using large integers.
693 If in doubt:
694
695    use Math::BigInt;
696
697 =item * Numerical
698
699 Assignment of return values from numeric equality tests
700 does not work in perl5 when the test evaluates to false (0).
701 Logical tests now return a null, instead of 0
702
703     $p = ($test == 1);
704     print $p,"\n";
705
706     # perl4 prints: 0
707     # perl5 prints:
708
709 Also see L<"General Regular Expression Traps using s///, etc.">
710 for another example of this new feature...
711
712 =item * Bitwise string ops
713
714 When bitwise operators which can operate upon either numbers or
715 strings (C<& | ^ ~>) are given only strings as arguments, perl4 would
716 treat the operands as bitstrings so long as the program contained a call
717 to the C<vec()> function. perl5 treats the string operands as bitstrings.
718 (See L<perlop/Bitwise String Operators> for more details.)
719
720     $fred = "10";
721     $barney = "12";
722     $betty = $fred & $barney;
723     print "$betty\n";
724     # Uncomment the next line to change perl4's behavior
725     # ($dummy) = vec("dummy", 0, 0);
726
727     # Perl4 prints:
728     8
729
730     # Perl5 prints:
731     10
732
733     # If vec() is used anywhere in the program, both print:
734     10
735
736 =back
737
738 =head2 General data type traps
739
740 Perl4-to-Perl5 traps involving most data-types, and their usage
741 within certain expressions and/or context.
742
743 =over 5
744
745 =item * (Arrays)
746
747 Negative array subscripts now count from the end of the array.
748
749     @a = (1, 2, 3, 4, 5);
750     print "The third element of the array is $a[3] also expressed as $a[-2] \n";
751
752     # perl4 prints: The third element of the array is 4 also expressed as
753     # perl5 prints: The third element of the array is 4 also expressed as 4
754
755 =item * (Arrays)
756
757 Setting C<$#array> lower now discards array elements, and makes them
758 impossible to recover.
759
760     @a = (a,b,c,d,e);
761     print "Before: ",join('',@a);
762     $#a =1;
763     print ", After: ",join('',@a);
764     $#a =3;
765     print ", Recovered: ",join('',@a),"\n";
766
767     # perl4 prints: Before: abcde, After: ab, Recovered: abcd
768     # perl5 prints: Before: abcde, After: ab, Recovered: ab
769
770 =item * (Hashes)
771
772 Hashes get defined before use
773
774     local($s,@a,%h);
775     die "scalar \$s defined" if defined($s);
776     die "array \@a defined" if defined(@a);
777     die "hash \%h defined" if defined(%h);
778
779     # perl4 prints:
780     # perl5 dies: hash %h defined
781
782 Perl will now generate a warning when it sees defined(@a) and
783 defined(%h).
784
785 =item * (Globs)
786
787 glob assignment from variable to variable will fail if the assigned
788 variable is localized subsequent to the assignment
789
790     @a = ("This is Perl 4");
791     *b = *a;
792     local(@a);
793     print @b,"\n";
794
795     # perl4 prints: This is Perl 4
796     # perl5 prints:
797
798 =item * (Globs)
799
800 Assigning C<undef> to a glob has no effect in Perl 5.   In Perl 4
801 it undefines the associated scalar (but may have other side effects
802 including SEGVs). Perl 5 will also warn if C<undef> is assigned to a
803 typeglob. (Note that assigning C<undef> to a typeglob is different
804 than calling the C<undef> function on a typeglob (C<undef *foo>), which
805 has quite a few effects.
806
807     $foo = "bar";
808     *foo = undef;
809     print $foo;
810
811     # perl4 prints:
812     # perl4 warns: "Use of uninitialized variable" if using -w
813     # perl5 prints: bar
814     # perl5 warns: "Undefined value assigned to typeglob" if using -w
815
816 =item * (Scalar String)
817
818 Changes in unary negation (of strings)
819 This change effects both the return value and what it
820 does to auto(magic)increment.
821
822     $x = "aaa";
823     print ++$x," : ";
824     print -$x," : ";
825     print ++$x,"\n";
826
827     # perl4 prints: aab : -0 : 1
828     # perl5 prints: aab : -aab : aac
829
830 =item * (Constants)
831
832 perl 4 lets you modify constants:
833
834     $foo = "x";
835     &mod($foo);
836     for ($x = 0; $x < 3; $x++) {
837         &mod("a");
838     }
839     sub mod {
840         print "before: $_[0]";
841         $_[0] = "m";
842         print "  after: $_[0]\n";
843     }
844
845     # perl4:
846     # before: x  after: m
847     # before: a  after: m
848     # before: m  after: m
849     # before: m  after: m
850
851     # Perl5:
852     # before: x  after: m
853     # Modification of a read-only value attempted at foo.pl line 12.
854     # before: a
855
856 =item * (Scalars)
857
858 The behavior is slightly different for:
859
860     print "$x", defined $x
861
862     # perl 4: 1
863     # perl 5: <no output, $x is not called into existence>
864
865 =item * (Variable Suicide)
866
867 Variable suicide behavior is more consistent under Perl 5.
868 Perl5 exhibits the same behavior for hashes and scalars,
869 that perl4 exhibits for only scalars.
870
871     $aGlobal{ "aKey" } = "global value";
872     print "MAIN:", $aGlobal{"aKey"}, "\n";
873     $GlobalLevel = 0;
874     &test( *aGlobal );
875
876     sub test {
877         local( *theArgument ) = @_;
878         local( %aNewLocal ); # perl 4 != 5.001l,m
879         $aNewLocal{"aKey"} = "this should never appear";
880         print "SUB: ", $theArgument{"aKey"}, "\n";
881         $aNewLocal{"aKey"} = "level $GlobalLevel";   # what should print
882         $GlobalLevel++;
883         if( $GlobalLevel<4 ) {
884             &test( *aNewLocal );
885         }
886     }
887
888     # Perl4:
889     # MAIN:global value
890     # SUB: global value
891     # SUB: level 0
892     # SUB: level 1
893     # SUB: level 2
894
895     # Perl5:
896     # MAIN:global value
897     # SUB: global value
898     # SUB: this should never appear
899     # SUB: this should never appear
900     # SUB: this should never appear
901
902 =back
903
904 =head2 Context Traps - scalar, list contexts
905
906 =over 5
907
908 =item * (list context)
909
910 The elements of argument lists for formats are now evaluated in list
911 context.  This means you can interpolate list values now.
912
913     @fmt = ("foo","bar","baz");
914     format STDOUT=
915     @<<<<< @||||| @>>>>>
916     @fmt;
917     .
918     write;
919
920     # perl4 errors:  Please use commas to separate fields in file
921     # perl5 prints: foo     bar      baz
922
923 =item * (scalar context)
924
925 The C<caller()> function now returns a false value in a scalar context
926 if there is no caller.  This lets library files determine if they're
927 being required.
928
929     caller() ? (print "You rang?\n") : (print "Got a 0\n");
930
931     # perl4 errors: There is no caller
932     # perl5 prints: Got a 0
933
934 =item * (scalar context)
935
936 The comma operator in a scalar context is now guaranteed to give a
937 scalar context to its arguments.
938
939     @y= ('a','b','c');
940     $x = (1, 2, @y);
941     print "x = $x\n";
942
943     # Perl4 prints:  x = c   # Thinks list context interpolates list
944     # Perl5 prints:  x = 3   # Knows scalar uses length of list
945
946 =item * (list, builtin)
947
948 C<sprintf()> is prototyped as ($;@), so its first argument is given scalar
949 context. Thus, if passed an array, it will probably not do what you want,
950 unlike Perl 4:
951
952     @z = ('%s%s', 'foo', 'bar');
953     $x = sprintf(@z);
954     print $x;
955
956     # perl4 prints: foobar
957     # perl5 prints: 3
958
959 C<printf()> works the same as it did in Perl 4, though:
960
961     @z = ('%s%s', 'foo', 'bar');
962     printf STDOUT (@z);
963
964     # perl4 prints: foobar
965     # perl5 prints: foobar
966
967 =back
968
969 =head2 Precedence Traps
970
971 Perl4-to-Perl5 traps involving precedence order.
972
973 Perl 4 has almost the same precedence rules as Perl 5 for the operators
974 that they both have.  Perl 4 however, seems to have had some
975 inconsistencies that made the behavior differ from what was documented.
976
977 =over 5
978
979 =item * Precedence
980
981 LHS vs. RHS of any assignment operator.  LHS is evaluated first
982 in perl4, second in perl5; this can affect the relationship
983 between side-effects in sub-expressions.
984
985     @arr = ( 'left', 'right' );
986     $a{shift @arr} = shift @arr;
987     print join( ' ', keys %a );
988
989     # perl4 prints: left
990     # perl5 prints: right
991
992 =item * Precedence
993
994 These are now semantic errors because of precedence:
995
996     @list = (1,2,3,4,5);
997     %map = ("a",1,"b",2,"c",3,"d",4);
998     $n = shift @list + 2;   # first item in list plus 2
999     print "n is $n, ";
1000     $m = keys %map + 2;     # number of items in hash plus 2
1001     print "m is $m\n";
1002
1003     # perl4 prints: n is 3, m is 6
1004     # perl5 errors and fails to compile
1005
1006 =item * Precedence
1007
1008 The precedence of assignment operators is now the same as the precedence
1009 of assignment.  Perl 4 mistakenly gave them the precedence of the associated
1010 operator.  So you now must parenthesize them in expressions like
1011
1012     /foo/ ? ($a += 2) : ($a -= 2);
1013
1014 Otherwise
1015
1016     /foo/ ? $a += 2 : $a -= 2
1017
1018 would be erroneously parsed as
1019
1020     (/foo/ ? $a += 2 : $a) -= 2;
1021
1022 On the other hand,
1023
1024     $a += /foo/ ? 1 : 2;
1025
1026 now works as a C programmer would expect.
1027
1028 =item * Precedence
1029
1030     open FOO || die;
1031
1032 is now incorrect.  You need parentheses around the filehandle.
1033 Otherwise, perl5 leaves the statement as its default precedence:
1034
1035     open(FOO || die);
1036
1037     # perl4 opens or dies
1038     # perl5 opens FOO, dying only if 'FOO' is false, i.e. never
1039
1040 =item * Precedence
1041
1042 perl4 gives the special variable, C<$:> precedence, where perl5
1043 treats C<$::> as main C<package>
1044
1045     $a = "x"; print "$::a";
1046
1047     # perl 4 prints: -:a
1048     # perl 5 prints: x
1049
1050 =item * Precedence
1051
1052 perl4 had buggy precedence for the file test operators vis-a-vis
1053 the assignment operators.  Thus, although the precedence table
1054 for perl4 leads one to believe C<-e $foo .= "q"> should parse as
1055 C<((-e $foo) .= "q")>, it actually parses as C<(-e ($foo .= "q"))>.
1056 In perl5, the precedence is as documented.
1057
1058     -e $foo .= "q"
1059
1060     # perl4 prints: no output
1061     # perl5 prints: Can't modify -e in concatenation
1062
1063 =item * Precedence
1064
1065 In perl4, keys(), each() and values() were special high-precedence operators
1066 that operated on a single hash, but in perl5, they are regular named unary
1067 operators.  As documented, named unary operators have lower precedence
1068 than the arithmetic and concatenation operators C<+ - .>, but the perl4
1069 variants of these operators actually bind tighter than C<+ - .>.
1070 Thus, for:
1071
1072     %foo = 1..10;
1073     print keys %foo - 1
1074
1075     # perl4 prints: 4
1076     # perl5 prints: Type of arg 1 to keys must be hash (not subtraction)
1077
1078 The perl4 behavior was probably more useful, if less consistent.
1079
1080 =back
1081
1082 =head2 General Regular Expression Traps using s///, etc.
1083
1084 All types of RE traps.
1085
1086 =over 5
1087
1088 =item * Regular Expression
1089
1090 C<s'$lhs'$rhs'> now does no interpolation on either side.  It used to
1091 interpolate $lhs but not $rhs.  (And still does not match a literal
1092 '$' in string)
1093
1094     $a=1;$b=2;
1095     $string = '1 2 $a $b';
1096     $string =~ s'$a'$b';
1097     print $string,"\n";
1098
1099     # perl4 prints: $b 2 $a $b
1100     # perl5 prints: 1 2 $a $b
1101
1102 =item * Regular Expression
1103
1104 C<m//g> now attaches its state to the searched string rather than the
1105 regular expression.  (Once the scope of a block is left for the sub, the
1106 state of the searched string is lost)
1107
1108     $_ = "ababab";
1109     while(m/ab/g){
1110         &doit("blah");
1111     }
1112     sub doit{local($_) = shift; print "Got $_ "}
1113
1114     # perl4 prints: Got blah Got blah Got blah Got blah
1115     # perl5 prints: infinite loop blah...
1116
1117 =item * Regular Expression
1118
1119 Currently, if you use the C<m//o> qualifier on a regular expression
1120 within an anonymous sub, I<all> closures generated from that anonymous
1121 sub will use the regular expression as it was compiled when it was used
1122 the very first time in any such closure.  For instance, if you say
1123
1124     sub build_match {
1125         my($left,$right) = @_;
1126         return sub { $_[0] =~ /$left stuff $right/o; };
1127     }
1128     $good = build_match('foo','bar');
1129     $bad = build_match('baz','blarch');
1130     print $good->('foo stuff bar') ? "ok\n" : "not ok\n";
1131     print $bad->('baz stuff blarch') ? "ok\n" : "not ok\n";
1132     print $bad->('foo stuff bar') ? "not ok\n" : "ok\n";
1133
1134 For most builds of Perl5, this will print:
1135 ok
1136 not ok
1137 not ok
1138
1139 build_match() will always return a sub which matches the contents of
1140 $left and $right as they were the I<first> time that build_match()
1141 was called, not as they are in the current call.
1142
1143 =item * Regular Expression
1144
1145 If no parentheses are used in a match, Perl4 sets C<$+> to
1146 the whole match, just like C<$&>. Perl5 does not.
1147
1148     "abcdef" =~ /b.*e/;
1149     print "\$+ = $+\n";
1150
1151     # perl4 prints: bcde
1152     # perl5 prints:
1153
1154 =item * Regular Expression
1155
1156 substitution now returns the null string if it fails
1157
1158     $string = "test";
1159     $value = ($string =~ s/foo//);
1160     print $value, "\n";
1161
1162     # perl4 prints: 0
1163     # perl5 prints:
1164
1165 Also see L<Numerical Traps> for another example of this new feature.
1166
1167 =item * Regular Expression
1168
1169 C<s`lhs`rhs`> (using backticks) is now a normal substitution, with no
1170 backtick expansion
1171
1172     $string = "";
1173     $string =~ s`^`hostname`;
1174     print $string, "\n";
1175
1176     # perl4 prints: <the local hostname>
1177     # perl5 prints: hostname
1178
1179 =item * Regular Expression
1180
1181 Stricter parsing of variables used in regular expressions
1182
1183     s/^([^$grpc]*$grpc[$opt$plus$rep]?)//o;
1184
1185     # perl4: compiles w/o error
1186     # perl5: with Scalar found where operator expected ..., near "$opt$plus"
1187
1188 an added component of this example, apparently from the same script, is
1189 the actual value of the s'd string after the substitution.
1190 C<[$opt]> is a character class in perl4 and an array subscript in perl5
1191
1192     $grpc = 'a';
1193     $opt  = 'r';
1194     $_ = 'bar';
1195     s/^([^$grpc]*$grpc[$opt]?)/foo/;
1196     print ;
1197
1198     # perl4 prints: foo
1199     # perl5 prints: foobar
1200
1201 =item * Regular Expression
1202
1203 Under perl5, C<m?x?> matches only once, like C<?x?>. Under perl4, it matched
1204 repeatedly, like C</x/> or C<m!x!>.
1205
1206     $test = "once";
1207     sub match { $test =~ m?once?; }
1208     &match();
1209     if( &match() ) {
1210         # m?x? matches more then once
1211         print "perl4\n";
1212     } else {
1213         # m?x? matches only once
1214         print "perl5\n";
1215     }
1216
1217     # perl4 prints: perl4
1218     # perl5 prints: perl5
1219
1220
1221 =back
1222
1223 =head2 Subroutine, Signal, Sorting Traps
1224
1225 The general group of Perl4-to-Perl5 traps having to do with
1226 Signals, Sorting, and their related subroutines, as well as
1227 general subroutine traps.  Includes some OS-Specific traps.
1228
1229 =over 5
1230
1231 =item * (Signals)
1232
1233 Barewords that used to look like strings to Perl will now look like subroutine
1234 calls if a subroutine by that name is defined before the compiler sees them.
1235
1236     sub SeeYa { warn"Hasta la vista, baby!" }
1237     $SIG{'TERM'} = SeeYa;
1238     print "SIGTERM is now $SIG{'TERM'}\n";
1239
1240     # perl4 prints: SIGTERM is now main'SeeYa
1241     # perl5 prints: SIGTERM is now main::1 (and warns "Hasta la vista, baby!")
1242
1243 Use B<-w> to catch this one
1244
1245 =item * (Sort Subroutine)
1246
1247 reverse is no longer allowed as the name of a sort subroutine.
1248
1249     sub reverse{ print "yup "; $a <=> $b }
1250     print sort reverse (2,1,3);
1251
1252     # perl4 prints: yup yup 123
1253     # perl5 prints: 123
1254     # perl5 warns (if using -w): Ambiguous call resolved as CORE::reverse()
1255
1256 =item * warn() won't let you specify a filehandle.
1257
1258 Although it _always_ printed to STDERR, warn() would let you specify a
1259 filehandle in perl4.  With perl5 it does not.
1260
1261     warn STDERR "Foo!";
1262
1263     # perl4 prints: Foo!
1264     # perl5 prints: String found where operator expected
1265
1266 =back
1267
1268 =head2 OS Traps
1269
1270 =over 5
1271
1272 =item * (SysV)
1273
1274 Under HPUX, and some other SysV OSes, one had to reset any signal handler,
1275 within  the signal handler function, each time a signal was handled with
1276 perl4.  With perl5, the reset is now done correctly.  Any code relying
1277 on the handler _not_ being reset will have to be reworked.
1278
1279 Since version 5.002, Perl uses sigaction() under SysV.
1280
1281     sub gotit {
1282         print "Got @_... ";
1283     }
1284     $SIG{'INT'} = 'gotit';
1285
1286     $| = 1;
1287     $pid = fork;
1288     if ($pid) {
1289         kill('INT', $pid);
1290         sleep(1);
1291         kill('INT', $pid);
1292     } else {
1293         while (1) {sleep(10);}
1294     }
1295
1296     # perl4 (HPUX) prints: Got INT...
1297     # perl5 (HPUX) prints: Got INT... Got INT...
1298
1299 =item * (SysV)
1300
1301 Under SysV OSes, C<seek()> on a file opened to append C<<< >> >>> now does
1302 the right thing w.r.t. the fopen() manpage. e.g., - When a file is opened
1303 for append,  it  is  impossible to overwrite information already in
1304 the file.
1305
1306     open(TEST,">>seek.test");
1307     $start = tell TEST ;
1308     foreach(1 .. 9){
1309         print TEST "$_ ";
1310     }
1311     $end = tell TEST ;
1312     seek(TEST,$start,0);
1313     print TEST "18 characters here";
1314
1315     # perl4 (solaris) seek.test has: 18 characters here
1316     # perl5 (solaris) seek.test has: 1 2 3 4 5 6 7 8 9 18 characters here
1317
1318
1319
1320 =back
1321
1322 =head2 Interpolation Traps
1323
1324 Perl4-to-Perl5 traps having to do with how things get interpolated
1325 within certain expressions, statements, contexts, or whatever.
1326
1327 =over 5
1328
1329 =item * Interpolation
1330
1331 @ now always interpolates an array in double-quotish strings.
1332
1333     print "To: someone@somewhere.com\n";
1334
1335     # perl4 prints: To:someone@somewhere.com
1336     # perl < 5.6.1, error : In string, @somewhere now must be written as \@somewhere
1337     # perl >= 5.6.1, warning : Possible unintended interpolation of @somewhere in string
1338
1339 =item * Interpolation
1340
1341 Double-quoted strings may no longer end with an unescaped $ or @.
1342
1343     $foo = "foo$";
1344     $bar = "bar@";
1345     print "foo is $foo, bar is $bar\n";
1346
1347     # perl4 prints: foo is foo$, bar is bar@
1348     # perl5 errors: Final $ should be \$ or $name
1349
1350 Note: perl5 DOES NOT error on the terminating @ in $bar
1351
1352 =item * Interpolation
1353
1354 Perl now sometimes evaluates arbitrary expressions inside braces that occur
1355 within double quotes (usually when the opening brace is preceded by C<$>
1356 or C<@>).
1357
1358     @www = "buz";
1359     $foo = "foo";
1360     $bar = "bar";
1361     sub foo { return "bar" };
1362     print "|@{w.w.w}|${main'foo}|";
1363
1364     # perl4 prints: |@{w.w.w}|foo|
1365     # perl5 prints: |buz|bar|
1366
1367 Note that you can C<use strict;> to ward off such trappiness under perl5.
1368
1369 =item * Interpolation
1370
1371 The construct "this is $$x" used to interpolate the pid at that point, but
1372 now tries to dereference $x.  C<$$> by itself still works fine, however.
1373
1374     $s = "a reference";
1375     $x = *s;
1376     print "this is $$x\n";
1377
1378     # perl4 prints: this is XXXx   (XXX is the current pid)
1379     # perl5 prints: this is a reference
1380
1381 =item * Interpolation
1382
1383 Creation of hashes on the fly with C<eval "EXPR"> now requires either both
1384 C<$>'s to be protected in the specification of the hash name, or both curlies
1385 to be protected.  If both curlies are protected, the result will be compatible
1386 with perl4 and perl5.  This is a very common practice, and should be changed
1387 to use the block form of C<eval{}>  if possible.
1388
1389     $hashname = "foobar";
1390     $key = "baz";
1391     $value = 1234;
1392     eval "\$$hashname{'$key'} = q|$value|";
1393     (defined($foobar{'baz'})) ?  (print "Yup") : (print "Nope");
1394
1395     # perl4 prints: Yup
1396     # perl5 prints: Nope
1397
1398 Changing
1399
1400     eval "\$$hashname{'$key'} = q|$value|";
1401
1402 to
1403
1404     eval "\$\$hashname{'$key'} = q|$value|";
1405
1406 causes the following result:
1407
1408     # perl4 prints: Nope
1409     # perl5 prints: Yup
1410
1411 or, changing to
1412
1413     eval "\$$hashname\{'$key'\} = q|$value|";
1414
1415 causes the following result:
1416
1417     # perl4 prints: Yup
1418     # perl5 prints: Yup
1419     # and is compatible for both versions
1420
1421
1422 =item * Interpolation
1423
1424 perl4 programs which unconsciously rely on the bugs in earlier perl versions.
1425
1426     perl -e '$bar=q/not/; print "This is $foo{$bar} perl5"'
1427
1428     # perl4 prints: This is not perl5
1429     # perl5 prints: This is perl5
1430
1431 =item * Interpolation
1432
1433 You also have to be careful about array references.
1434
1435     print "$foo{"
1436
1437     perl 4 prints: {
1438     perl 5 prints: syntax error
1439
1440 =item * Interpolation
1441
1442 Similarly, watch out for:
1443
1444     $foo = "baz";
1445     print "\$$foo{bar}\n";
1446
1447     # perl4 prints: $baz{bar}
1448     # perl5 prints: $
1449
1450 Perl 5 is looking for C<$foo{bar}> which doesn't exist, but perl 4 is
1451 happy just to expand $foo to "baz" by itself.  Watch out for this
1452 especially in C<eval>'s.
1453
1454 =item * Interpolation
1455
1456 C<qq()> string passed to C<eval>
1457
1458     eval qq(
1459         foreach \$y (keys %\$x\) {
1460             \$count++;
1461         }
1462     );
1463
1464     # perl4 runs this ok
1465     # perl5 prints: Can't find string terminator ")"
1466
1467 =back
1468
1469 =head2 DBM Traps
1470
1471 General DBM traps.
1472
1473 =over 5
1474
1475 =item * DBM
1476
1477 Existing dbm databases created under perl4 (or any other dbm/ndbm tool)
1478 may cause the same script, run under perl5, to fail.  The build of perl5
1479 must have been linked with the same dbm/ndbm as the default for C<dbmopen()>
1480 to function properly without C<tie>'ing to an extension dbm implementation.
1481
1482     dbmopen (%dbm, "file", undef);
1483     print "ok\n";
1484
1485     # perl4 prints: ok
1486     # perl5 prints: ok (IFF linked with -ldbm or -lndbm)
1487
1488
1489 =item * DBM
1490
1491 Existing dbm databases created under perl4 (or any other dbm/ndbm tool)
1492 may cause the same script, run under perl5, to fail.  The error generated
1493 when exceeding the limit on the key/value size will cause perl5 to exit
1494 immediately.
1495
1496     dbmopen(DB, "testdb",0600) || die "couldn't open db! $!";
1497     $DB{'trap'} = "x" x 1024;  # value too large for most dbm/ndbm
1498     print "YUP\n";
1499
1500     # perl4 prints:
1501     dbm store returned -1, errno 28, key "trap" at - line 3.
1502     YUP
1503
1504     # perl5 prints:
1505     dbm store returned -1, errno 28, key "trap" at - line 3.
1506
1507 =back
1508
1509 =head2 Unclassified Traps
1510
1511 Everything else.
1512
1513 =over 5
1514
1515 =item * C<require>/C<do> trap using returned value
1516
1517 If the file doit.pl has:
1518
1519     sub foo {
1520         $rc = do "./do.pl";
1521         return 8;
1522     }
1523     print &foo, "\n";
1524
1525 And the do.pl file has the following single line:
1526
1527     return 3;
1528
1529 Running doit.pl gives the following:
1530
1531     # perl 4 prints: 3 (aborts the subroutine early)
1532     # perl 5 prints: 8
1533
1534 Same behavior if you replace C<do> with C<require>.
1535
1536 =item * C<split> on empty string with LIMIT specified
1537
1538     $string = '';
1539     @list = split(/foo/, $string, 2)
1540
1541 Perl4 returns a one element list containing the empty string but Perl5
1542 returns an empty list.
1543
1544 =back
1545
1546 As always, if any of these are ever officially declared as bugs,
1547 they'll be fixed and removed.
1548