Upgrade to Tie::File 0.20.
[perl.git] / pod / perldata.pod
1 =head1 NAME
2
3 perldata - Perl data types
4
5 =head1 DESCRIPTION
6
7 =head2 Variable names
8
9 Perl has three built-in data types: scalars, arrays of scalars, and
10 associative arrays of scalars, known as "hashes".  Normal arrays
11 are ordered lists of scalars indexed by number, starting with 0 and with
12 negative subscripts counting from the end.  Hashes are unordered
13 collections of scalar values indexed by their associated string key.
14
15 Values are usually referred to by name, or through a named reference.
16 The first character of the name tells you to what sort of data
17 structure it refers.  The rest of the name tells you the particular
18 value to which it refers.  Usually this name is a single I<identifier>,
19 that is, a string beginning with a letter or underscore, and
20 containing letters, underscores, and digits.  In some cases, it may
21 be a chain of identifiers, separated by C<::> (or by the slightly
22 archaic C<'>); all but the last are interpreted as names of packages,
23 to locate the namespace in which to look up the final identifier
24 (see L<perlmod/Packages> for details).  It's possible to substitute
25 for a simple identifier, an expression that produces a reference
26 to the value at runtime.   This is described in more detail below
27 and in L<perlref>.
28
29 Perl also has its own built-in variables whose names don't follow
30 these rules.  They have strange names so they don't accidentally
31 collide with one of your normal variables.  Strings that match
32 parenthesized parts of a regular expression are saved under names
33 containing only digits after the C<$> (see L<perlop> and L<perlre>).
34 In addition, several special variables that provide windows into
35 the inner working of Perl have names containing punctuation characters
36 and control characters.  These are documented in L<perlvar>.
37
38 Scalar values are always named with '$', even when referring to a
39 scalar that is part of an array or a hash.  The '$' symbol works
40 semantically like the English word "the" in that it indicates a
41 single value is expected.
42
43     $days               # the simple scalar value "days"
44     $days[28]           # the 29th element of array @days
45     $days{'Feb'}        # the 'Feb' value from hash %days
46     $#days              # the last index of array @days
47
48 Entire arrays (and slices of arrays and hashes) are denoted by '@',
49 which works much like the word "these" or "those" does in English,
50 in that it indicates multiple values are expected.
51
52     @days               # ($days[0], $days[1],... $days[n])
53     @days[3,4,5]        # same as ($days[3],$days[4],$days[5])
54     @days{'a','c'}      # same as ($days{'a'},$days{'c'})
55
56 Entire hashes are denoted by '%':
57
58     %days               # (key1, val1, key2, val2 ...)
59
60 In addition, subroutines are named with an initial '&', though this
61 is optional when unambiguous, just as the word "do" is often redundant
62 in English.  Symbol table entries can be named with an initial '*',
63 but you don't really care about that yet (if ever :-).
64
65 Every variable type has its own namespace, as do several
66 non-variable identifiers.  This means that you can, without fear
67 of conflict, use the same name for a scalar variable, an array, or
68 a hash--or, for that matter, for a filehandle, a directory handle, a
69 subroutine name, a format name, or a label.  This means that $foo
70 and @foo are two different variables.  It also means that C<$foo[1]>
71 is a part of @foo, not a part of $foo.  This may seem a bit weird,
72 but that's okay, because it is weird.
73
74 Because variable references always start with '$', '@', or '%', the
75 "reserved" words aren't in fact reserved with respect to variable
76 names.  They I<are> reserved with respect to labels and filehandles,
77 however, which don't have an initial special character.  You can't
78 have a filehandle named "log", for instance.  Hint: you could say
79 C<open(LOG,'logfile')> rather than C<open(log,'logfile')>.  Using
80 uppercase filehandles also improves readability and protects you
81 from conflict with future reserved words.  Case I<is> significant--"FOO",
82 "Foo", and "foo" are all different names.  Names that start with a
83 letter or underscore may also contain digits and underscores.
84
85 It is possible to replace such an alphanumeric name with an expression
86 that returns a reference to the appropriate type.  For a description
87 of this, see L<perlref>.
88
89 Names that start with a digit may contain only more digits.  Names
90 that do not start with a letter, underscore, digit or a caret (i.e.
91 a control character) are limited to one character, e.g.,  C<$%> or
92 C<$$>.  (Most of these one character names have a predefined
93 significance to Perl.  For instance, C<$$> is the current process
94 id.)
95
96 =head2 Context
97
98 The interpretation of operations and values in Perl sometimes depends
99 on the requirements of the context around the operation or value.
100 There are two major contexts: list and scalar.  Certain operations
101 return list values in contexts wanting a list, and scalar values
102 otherwise.  If this is true of an operation it will be mentioned in
103 the documentation for that operation.  In other words, Perl overloads
104 certain operations based on whether the expected return value is
105 singular or plural.  Some words in English work this way, like "fish"
106 and "sheep".
107
108 In a reciprocal fashion, an operation provides either a scalar or a
109 list context to each of its arguments.  For example, if you say
110
111     int( <STDIN> )
112
113 the integer operation provides scalar context for the <>
114 operator, which responds by reading one line from STDIN and passing it
115 back to the integer operation, which will then find the integer value
116 of that line and return that.  If, on the other hand, you say
117
118     sort( <STDIN> )
119
120 then the sort operation provides list context for <>, which
121 will proceed to read every line available up to the end of file, and
122 pass that list of lines back to the sort routine, which will then
123 sort those lines and return them as a list to whatever the context
124 of the sort was.
125
126 Assignment is a little bit special in that it uses its left argument
127 to determine the context for the right argument.  Assignment to a
128 scalar evaluates the right-hand side in scalar context, while
129 assignment to an array or hash evaluates the righthand side in list
130 context.  Assignment to a list (or slice, which is just a list
131 anyway) also evaluates the righthand side in list context.
132
133 When you use the C<use warnings> pragma or Perl's B<-w> command-line 
134 option, you may see warnings
135 about useless uses of constants or functions in "void context".
136 Void context just means the value has been discarded, such as a
137 statement containing only C<"fred";> or C<getpwuid(0);>.  It still
138 counts as scalar context for functions that care whether or not
139 they're being called in list context.
140
141 User-defined subroutines may choose to care whether they are being
142 called in a void, scalar, or list context.  Most subroutines do not
143 need to bother, though.  That's because both scalars and lists are
144 automatically interpolated into lists.  See L<perlfunc/wantarray>
145 for how you would dynamically discern your function's calling
146 context.
147
148 =head2 Scalar values
149
150 All data in Perl is a scalar, an array of scalars, or a hash of
151 scalars.  A scalar may contain one single value in any of three
152 different flavors: a number, a string, or a reference.  In general,
153 conversion from one form to another is transparent.  Although a
154 scalar may not directly hold multiple values, it may contain a
155 reference to an array or hash which in turn contains multiple values.
156
157 Scalars aren't necessarily one thing or another.  There's no place
158 to declare a scalar variable to be of type "string", type "number",
159 type "reference", or anything else.  Because of the automatic
160 conversion of scalars, operations that return scalars don't need
161 to care (and in fact, cannot care) whether their caller is looking
162 for a string, a number, or a reference.  Perl is a contextually
163 polymorphic language whose scalars can be strings, numbers, or
164 references (which includes objects).  Although strings and numbers
165 are considered pretty much the same thing for nearly all purposes,
166 references are strongly-typed, uncastable pointers with builtin
167 reference-counting and destructor invocation.
168
169 A scalar value is interpreted as TRUE in the Boolean sense if it is not
170 the null string or the number 0 (or its string equivalent, "0").  The
171 Boolean context is just a special kind of scalar context where no 
172 conversion to a string or a number is ever performed.
173
174 There are actually two varieties of null strings (sometimes referred
175 to as "empty" strings), a defined one and an undefined one.  The
176 defined version is just a string of length zero, such as C<"">.
177 The undefined version is the value that indicates that there is
178 no real value for something, such as when there was an error, or
179 at end of file, or when you refer to an uninitialized variable or
180 element of an array or hash.  Although in early versions of Perl,
181 an undefined scalar could become defined when first used in a
182 place expecting a defined value, this no longer happens except for
183 rare cases of autovivification as explained in L<perlref>.  You can
184 use the defined() operator to determine whether a scalar value is
185 defined (this has no meaning on arrays or hashes), and the undef()
186 operator to produce an undefined value.
187
188 To find out whether a given string is a valid non-zero number, it's
189 sometimes enough to test it against both numeric 0 and also lexical
190 "0" (although this will cause B<-w> noises).  That's because strings
191 that aren't numbers count as 0, just as they do in B<awk>:
192
193     if ($str == 0 && $str ne "0")  {
194         warn "That doesn't look like a number";
195     }
196
197 That method may be best because otherwise you won't treat IEEE
198 notations like C<NaN> or C<Infinity> properly.  At other times, you
199 might prefer to determine whether string data can be used numerically
200 by calling the POSIX::strtod() function or by inspecting your string
201 with a regular expression (as documented in L<perlre>).
202
203     warn "has nondigits"        if     /\D/;
204     warn "not a natural number" unless /^\d+$/;             # rejects -3
205     warn "not an integer"       unless /^-?\d+$/;           # rejects +3
206     warn "not an integer"       unless /^[+-]?\d+$/;
207     warn "not a decimal number" unless /^-?\d+\.?\d*$/;     # rejects .2
208     warn "not a decimal number" unless /^-?(?:\d+(?:\.\d*)?|\.\d+)$/;
209     warn "not a C float"
210         unless /^([+-]?)(?=\d|\.\d)\d*(\.\d*)?([Ee]([+-]?\d+))?$/;
211
212 The length of an array is a scalar value.  You may find the length
213 of array @days by evaluating C<$#days>, as in B<csh>.  However, this
214 isn't the length of the array; it's the subscript of the last element,
215 which is a different value since there is ordinarily a 0th element.
216 Assigning to C<$#days> actually changes the length of the array.
217 Shortening an array this way destroys intervening values.  Lengthening
218 an array that was previously shortened does not recover values
219 that were in those elements.  (It used to do so in Perl 4, but we
220 had to break this to make sure destructors were called when expected.)
221
222 You can also gain some minuscule measure of efficiency by pre-extending
223 an array that is going to get big.  You can also extend an array
224 by assigning to an element that is off the end of the array.  You
225 can truncate an array down to nothing by assigning the null list
226 () to it.  The following are equivalent:
227
228     @whatever = ();
229     $#whatever = -1;
230
231 If you evaluate an array in scalar context, it returns the length
232 of the array.  (Note that this is not true of lists, which return
233 the last value, like the C comma operator, nor of built-in functions,
234 which return whatever they feel like returning.)  The following is
235 always true:
236
237     scalar(@whatever) == $#whatever - $[ + 1;
238
239 Version 5 of Perl changed the semantics of C<$[>: files that don't set
240 the value of C<$[> no longer need to worry about whether another
241 file changed its value.  (In other words, use of C<$[> is deprecated.)
242 So in general you can assume that
243
244     scalar(@whatever) == $#whatever + 1;
245
246 Some programmers choose to use an explicit conversion so as to 
247 leave nothing to doubt:
248
249     $element_count = scalar(@whatever);
250
251 If you evaluate a hash in scalar context, it returns false if the
252 hash is empty.  If there are any key/value pairs, it returns true;
253 more precisely, the value returned is a string consisting of the
254 number of used buckets and the number of allocated buckets, separated
255 by a slash.  This is pretty much useful only to find out whether
256 Perl's internal hashing algorithm is performing poorly on your data
257 set.  For example, you stick 10,000 things in a hash, but evaluating
258 %HASH in scalar context reveals C<"1/16">, which means only one out
259 of sixteen buckets has been touched, and presumably contains all
260 10,000 of your items.  This isn't supposed to happen.
261
262 You can preallocate space for a hash by assigning to the keys() function.
263 This rounds up the allocated buckets to the next power of two:
264
265     keys(%users) = 1000;                # allocate 1024 buckets
266
267 =head2 Scalar value constructors
268
269 Numeric literals are specified in any of the following floating point or
270 integer formats:
271
272     12345
273     12345.67
274     .23E-10             # a very small number
275     3.14_15_92          # a very important number
276     4_294_967_296       # underscore for legibility
277     0xff                # hex
278     0xdead_beef         # more hex   
279     0377                # octal
280     0b011011            # binary
281
282 You are allowed to use underscores (underbars) in numeric literals
283 between digits for legibility.  You could, for example, group binary
284 digits by threes (as for a Unix-style mode argument such as 0b110_100_100)
285 or by fours (to represent nibbles, as in 0b1010_0110) or in other groups.
286
287 String literals are usually delimited by either single or double
288 quotes.  They work much like quotes in the standard Unix shells:
289 double-quoted string literals are subject to backslash and variable
290 substitution; single-quoted strings are not (except for C<\'> and
291 C<\\>).  The usual C-style backslash rules apply for making
292 characters such as newline, tab, etc., as well as some more exotic
293 forms.  See L<perlop/"Quote and Quote-like Operators"> for a list.
294
295 Hexadecimal, octal, or binary, representations in string literals
296 (e.g. '0xff') are not automatically converted to their integer
297 representation.  The hex() and oct() functions make these conversions
298 for you.  See L<perlfunc/hex> and L<perlfunc/oct> for more details.
299
300 You can also embed newlines directly in your strings, i.e., they can end
301 on a different line than they begin.  This is nice, but if you forget
302 your trailing quote, the error will not be reported until Perl finds
303 another line containing the quote character, which may be much further
304 on in the script.  Variable substitution inside strings is limited to
305 scalar variables, arrays, and array or hash slices.  (In other words,
306 names beginning with $ or @, followed by an optional bracketed
307 expression as a subscript.)  The following code segment prints out "The
308 price is $Z<>100."
309
310     $Price = '$100';    # not interpreted
311     print "The price is $Price.\n";     # interpreted
312
313 As in some shells, you can enclose the variable name in braces to
314 disambiguate it from following alphanumerics (and underscores).
315 You must also do
316 this when interpolating a variable into a string to separate the
317 variable name from a following double-colon or an apostrophe, since
318 these would be otherwise treated as a package separator:
319
320     $who = "Larry";
321     print PASSWD "${who}::0:0:Superuser:/:/bin/perl\n";
322     print "We use ${who}speak when ${who}'s here.\n";
323
324 Without the braces, Perl would have looked for a $whospeak, a
325 C<$who::0>, and a C<$who's> variable.  The last two would be the
326 $0 and the $s variables in the (presumably) non-existent package
327 C<who>.
328
329 In fact, an identifier within such curlies is forced to be a string,
330 as is any simple identifier within a hash subscript.  Neither need
331 quoting.  Our earlier example, C<$days{'Feb'}> can be written as
332 C<$days{Feb}> and the quotes will be assumed automatically.  But
333 anything more complicated in the subscript will be interpreted as
334 an expression.
335
336 A literal of the form C<v1.20.300.4000> is parsed as a string composed
337 of characters with the specified ordinals.  This form, known as
338 v-strings, provides an alternative, more readable way to construct
339 strings, rather than use the somewhat less readable interpolation form
340 C<"\x{1}\x{14}\x{12c}\x{fa0}">.  This is useful for representing
341 Unicode strings, and for comparing version "numbers" using the string
342 comparison operators, C<cmp>, C<gt>, C<lt> etc.  If there are two or
343 more dots in the literal, the leading C<v> may be omitted.
344
345     print v9786;              # prints UTF-8 encoded SMILEY, "\x{263a}"
346     print v102.111.111;       # prints "foo"
347     print 102.111.111;        # same
348
349 Such literals are accepted by both C<require> and C<use> for
350 doing a version check.  The C<$^V> special variable also contains the
351 running Perl interpreter's version in this form.  See L<perlvar/$^V>.
352 Note that using the v-strings for IPv4 addresses is not portable unless
353 you also use the inet_aton()/inet_ntoa() routines of the Socket package.
354
355 The special literals __FILE__, __LINE__, and __PACKAGE__
356 represent the current filename, line number, and package name at that
357 point in your program.  They may be used only as separate tokens; they
358 will not be interpolated into strings.  If there is no current package
359 (due to an empty C<package;> directive), __PACKAGE__ is the undefined
360 value.
361
362 The two control characters ^D and ^Z, and the tokens __END__ and __DATA__
363 may be used to indicate the logical end of the script before the actual
364 end of file.  Any following text is ignored.
365
366 Text after __DATA__ but may be read via the filehandle C<PACKNAME::DATA>,
367 where C<PACKNAME> is the package that was current when the __DATA__
368 token was encountered.  The filehandle is left open pointing to the
369 contents after __DATA__.  It is the program's responsibility to
370 C<close DATA> when it is done reading from it.  For compatibility with
371 older scripts written before __DATA__ was introduced, __END__ behaves
372 like __DATA__ in the toplevel script (but not in files loaded with
373 C<require> or C<do>) and leaves the remaining contents of the
374 file accessible via C<main::DATA>.
375
376 See L<SelfLoader> for more description of __DATA__, and
377 an example of its use.  Note that you cannot read from the DATA
378 filehandle in a BEGIN block: the BEGIN block is executed as soon
379 as it is seen (during compilation), at which point the corresponding
380 __DATA__ (or __END__) token has not yet been seen.
381
382 A word that has no other interpretation in the grammar will
383 be treated as if it were a quoted string.  These are known as
384 "barewords".  As with filehandles and labels, a bareword that consists
385 entirely of lowercase letters risks conflict with future reserved
386 words, and if you use the C<use warnings> pragma or the B<-w> switch, 
387 Perl will warn you about any
388 such words.  Some people may wish to outlaw barewords entirely.  If you
389 say
390
391     use strict 'subs';
392
393 then any bareword that would NOT be interpreted as a subroutine call
394 produces a compile-time error instead.  The restriction lasts to the
395 end of the enclosing block.  An inner block may countermand this
396 by saying C<no strict 'subs'>.
397
398 Arrays and slices are interpolated into double-quoted strings
399 by joining the elements with the delimiter specified in the C<$">
400 variable (C<$LIST_SEPARATOR> in English), space by default.  The
401 following are equivalent:
402
403     $temp = join($", @ARGV);
404     system "echo $temp";
405
406     system "echo @ARGV";
407
408 Within search patterns (which also undergo double-quotish substitution)
409 there is an unfortunate ambiguity:  Is C</$foo[bar]/> to be interpreted as
410 C</${foo}[bar]/> (where C<[bar]> is a character class for the regular
411 expression) or as C</${foo[bar]}/> (where C<[bar]> is the subscript to array
412 @foo)?  If @foo doesn't otherwise exist, then it's obviously a
413 character class.  If @foo exists, Perl takes a good guess about C<[bar]>,
414 and is almost always right.  If it does guess wrong, or if you're just
415 plain paranoid, you can force the correct interpretation with curly
416 braces as above.
417
418 If you're looking for the information on how to use here-documents,
419 which used to be here, that's been moved to
420 L<perlop/Quote and Quote-like Operators>.
421
422 =head2 List value constructors
423
424 List values are denoted by separating individual values by commas
425 (and enclosing the list in parentheses where precedence requires it):
426
427     (LIST)
428
429 In a context not requiring a list value, the value of what appears
430 to be a list literal is simply the value of the final element, as
431 with the C comma operator.  For example,
432
433     @foo = ('cc', '-E', $bar);
434
435 assigns the entire list value to array @foo, but
436
437     $foo = ('cc', '-E', $bar);
438
439 assigns the value of variable $bar to the scalar variable $foo.
440 Note that the value of an actual array in scalar context is the
441 length of the array; the following assigns the value 3 to $foo:
442
443     @foo = ('cc', '-E', $bar);
444     $foo = @foo;                # $foo gets 3
445
446 You may have an optional comma before the closing parenthesis of a
447 list literal, so that you can say:
448
449     @foo = (
450         1,
451         2,
452         3,
453     );
454
455 To use a here-document to assign an array, one line per element,
456 you might use an approach like this:
457
458     @sauces = <<End_Lines =~ m/(\S.*\S)/g;
459         normal tomato
460         spicy tomato
461         green chile
462         pesto
463         white wine
464     End_Lines
465
466 LISTs do automatic interpolation of sublists.  That is, when a LIST is
467 evaluated, each element of the list is evaluated in list context, and
468 the resulting list value is interpolated into LIST just as if each
469 individual element were a member of LIST.  Thus arrays and hashes lose their
470 identity in a LIST--the list
471
472     (@foo,@bar,&SomeSub,%glarch)
473
474 contains all the elements of @foo followed by all the elements of @bar,
475 followed by all the elements returned by the subroutine named SomeSub 
476 called in list context, followed by the key/value pairs of %glarch.
477 To make a list reference that does I<NOT> interpolate, see L<perlref>.
478
479 The null list is represented by ().  Interpolating it in a list
480 has no effect.  Thus ((),(),()) is equivalent to ().  Similarly,
481 interpolating an array with no elements is the same as if no
482 array had been interpolated at that point.
483
484 This interpolation combines with the facts that the opening
485 and closing parentheses are optional (except when necessary for
486 precedence) and lists may end with an optional comma to mean that
487 multiple commas within lists are legal syntax. The list C<1,,3> is a
488 concatenation of two lists, C<1,> and C<3>, the first of which ends
489 with that optional comma.  C<1,,3> is C<(1,),(3)> is C<1,3> (And
490 similarly for C<1,,,3> is C<(1,),(,),3> is C<1,3> and so on.)  Not that
491 we'd advise you to use this obfuscation.
492
493 A list value may also be subscripted like a normal array.  You must
494 put the list in parentheses to avoid ambiguity.  For example:
495
496     # Stat returns list value.
497     $time = (stat($file))[8];
498
499     # SYNTAX ERROR HERE.
500     $time = stat($file)[8];  # OOPS, FORGOT PARENTHESES
501
502     # Find a hex digit.
503     $hexdigit = ('a','b','c','d','e','f')[$digit-10];
504
505     # A "reverse comma operator".
506     return (pop(@foo),pop(@foo))[0];
507
508 Lists may be assigned to only when each element of the list
509 is itself legal to assign to:
510
511     ($a, $b, $c) = (1, 2, 3);
512
513     ($map{'red'}, $map{'blue'}, $map{'green'}) = (0x00f, 0x0f0, 0xf00);
514
515 An exception to this is that you may assign to C<undef> in a list.
516 This is useful for throwing away some of the return values of a
517 function:
518
519     ($dev, $ino, undef, undef, $uid, $gid) = stat($file);
520
521 List assignment in scalar context returns the number of elements
522 produced by the expression on the right side of the assignment:
523
524     $x = (($foo,$bar) = (3,2,1));       # set $x to 3, not 2
525     $x = (($foo,$bar) = f());           # set $x to f()'s return count
526
527 This is handy when you want to do a list assignment in a Boolean
528 context, because most list functions return a null list when finished,
529 which when assigned produces a 0, which is interpreted as FALSE.
530
531 It's also the source of a useful idiom for executing a function or
532 performing an operation in list context and then counting the number of
533 return values, by assigning to an empty list and then using that
534 assignment in scalar context. For example, this code:
535
536     $count = () = $string =~ /\d+/g;
537
538 will place into $count the number of digit groups found in $string.
539 This happens because the pattern match is in list context (since it
540 is being assigned to the empty list), and will therefore return a list
541 of all matching parts of the string. The list assignment in scalar
542 context will translate that into the number of elements (here, the
543 number of times the pattern matched) and assign that to $count. Note
544 that simply using
545
546     $count = $string =~ /\d+/g;
547
548 would not have worked, since a pattern match in scalar context will
549 only return true or false, rather than a count of matches.
550
551 The final element of a list assignment may be an array or a hash:
552
553     ($a, $b, @rest) = split;
554     my($a, $b, %rest) = @_;
555
556 You can actually put an array or hash anywhere in the list, but the first one
557 in the list will soak up all the values, and anything after it will become
558 undefined.  This may be useful in a my() or local().
559
560 A hash can be initialized using a literal list holding pairs of
561 items to be interpreted as a key and a value:
562
563     # same as map assignment above
564     %map = ('red',0x00f,'blue',0x0f0,'green',0xf00);
565
566 While literal lists and named arrays are often interchangeable, that's
567 not the case for hashes.  Just because you can subscript a list value like
568 a normal array does not mean that you can subscript a list value as a
569 hash.  Likewise, hashes included as parts of other lists (including
570 parameters lists and return lists from functions) always flatten out into
571 key/value pairs.  That's why it's good to use references sometimes.
572
573 It is often more readable to use the C<< => >> operator between key/value
574 pairs.  The C<< => >> operator is mostly just a more visually distinctive
575 synonym for a comma, but it also arranges for its left-hand operand to be
576 interpreted as a string--if it's a bareword that would be a legal identifier.
577 This makes it nice for initializing hashes:
578
579     %map = (
580                  red   => 0x00f,
581                  blue  => 0x0f0,
582                  green => 0xf00,
583    );
584
585 or for initializing hash references to be used as records:
586
587     $rec = {
588                 witch => 'Mable the Merciless',
589                 cat   => 'Fluffy the Ferocious',
590                 date  => '10/31/1776',
591     };
592
593 or for using call-by-named-parameter to complicated functions:
594
595    $field = $query->radio_group(
596                name      => 'group_name',
597                values    => ['eenie','meenie','minie'],
598                default   => 'meenie',
599                linebreak => 'true',
600                labels    => \%labels
601    );
602
603 Note that just because a hash is initialized in that order doesn't
604 mean that it comes out in that order.  See L<perlfunc/sort> for examples
605 of how to arrange for an output ordering.
606
607 =head2 Slices
608
609 A common way to access an array or a hash is one scalar element at a
610 time.  You can also subscript a list to get a single element from it.
611
612     $whoami = $ENV{"USER"};             # one element from the hash
613     $parent = $ISA[0];                  # one element from the array
614     $dir    = (getpwnam("daemon"))[7];  # likewise, but with list
615
616 A slice accesses several elements of a list, an array, or a hash
617 simultaneously using a list of subscripts.  It's more convenient
618 than writing out the individual elements as a list of separate
619 scalar values.
620
621     ($him, $her)   = @folks[0,-1];              # array slice
622     @them          = @folks[0 .. 3];            # array slice
623     ($who, $home)  = @ENV{"USER", "HOME"};      # hash slice
624     ($uid, $dir)   = (getpwnam("daemon"))[2,7]; # list slice
625
626 Since you can assign to a list of variables, you can also assign to
627 an array or hash slice.
628
629     @days[3..5]    = qw/Wed Thu Fri/;
630     @colors{'red','blue','green'} 
631                    = (0xff0000, 0x0000ff, 0x00ff00);
632     @folks[0, -1]  = @folks[-1, 0];
633
634 The previous assignments are exactly equivalent to
635
636     ($days[3], $days[4], $days[5]) = qw/Wed Thu Fri/;
637     ($colors{'red'}, $colors{'blue'}, $colors{'green'})
638                    = (0xff0000, 0x0000ff, 0x00ff00);
639     ($folks[0], $folks[-1]) = ($folks[-1], $folks[0]);
640
641 Since changing a slice changes the original array or hash that it's
642 slicing, a C<foreach> construct will alter some--or even all--of the
643 values of the array or hash.
644
645     foreach (@array[ 4 .. 10 ]) { s/peter/paul/ } 
646
647     foreach (@hash{keys %hash}) {
648         s/^\s+//;           # trim leading whitespace
649         s/\s+$//;           # trim trailing whitespace
650         s/(\w+)/\u\L$1/g;   # "titlecase" words
651     }
652
653 A slice of an empty list is still an empty list.  Thus:
654
655     @a = ()[1,0];           # @a has no elements
656     @b = (@a)[0,1];         # @b has no elements
657     @c = (0,1)[2,3];        # @c has no elements
658
659 But:
660
661     @a = (1)[1,0];          # @a has two elements
662     @b = (1,undef)[1,0,2];  # @b has three elements
663
664 This makes it easy to write loops that terminate when a null list
665 is returned:
666
667     while ( ($home, $user) = (getpwent)[7,0]) {
668         printf "%-8s %s\n", $user, $home;
669     }
670
671 As noted earlier in this document, the scalar sense of list assignment
672 is the number of elements on the right-hand side of the assignment.
673 The null list contains no elements, so when the password file is
674 exhausted, the result is 0, not 2.
675
676 If you're confused about why you use an '@' there on a hash slice
677 instead of a '%', think of it like this.  The type of bracket (square
678 or curly) governs whether it's an array or a hash being looked at.
679 On the other hand, the leading symbol ('$' or '@') on the array or
680 hash indicates whether you are getting back a singular value (a
681 scalar) or a plural one (a list).
682
683 =head2 Typeglobs and Filehandles
684
685 Perl uses an internal type called a I<typeglob> to hold an entire
686 symbol table entry.  The type prefix of a typeglob is a C<*>, because
687 it represents all types.  This used to be the preferred way to
688 pass arrays and hashes by reference into a function, but now that
689 we have real references, this is seldom needed.  
690
691 The main use of typeglobs in modern Perl is create symbol table aliases.
692 This assignment:
693
694     *this = *that;
695
696 makes $this an alias for $that, @this an alias for @that, %this an alias
697 for %that, &this an alias for &that, etc.  Much safer is to use a reference.
698 This:
699
700     local *Here::blue = \$There::green;
701
702 temporarily makes $Here::blue an alias for $There::green, but doesn't
703 make @Here::blue an alias for @There::green, or %Here::blue an alias for
704 %There::green, etc.  See L<perlmod/"Symbol Tables"> for more examples
705 of this.  Strange though this may seem, this is the basis for the whole
706 module import/export system.
707
708 Another use for typeglobs is to pass filehandles into a function or
709 to create new filehandles.  If you need to use a typeglob to save away
710 a filehandle, do it this way:
711
712     $fh = *STDOUT;
713
714 or perhaps as a real reference, like this:
715
716     $fh = \*STDOUT;
717
718 See L<perlsub> for examples of using these as indirect filehandles
719 in functions.
720
721 Typeglobs are also a way to create a local filehandle using the local()
722 operator.  These last until their block is exited, but may be passed back.
723 For example:
724
725     sub newopen {
726         my $path = shift;
727         local  *FH;  # not my!
728         open   (FH, $path)          or  return undef;
729         return *FH;
730     }
731     $fh = newopen('/etc/passwd');
732
733 Now that we have the C<*foo{THING}> notation, typeglobs aren't used as much
734 for filehandle manipulations, although they're still needed to pass brand
735 new file and directory handles into or out of functions. That's because
736 C<*HANDLE{IO}> only works if HANDLE has already been used as a handle.
737 In other words, C<*FH> must be used to create new symbol table entries;
738 C<*foo{THING}> cannot.  When in doubt, use C<*FH>.
739
740 All functions that are capable of creating filehandles (open(),
741 opendir(), pipe(), socketpair(), sysopen(), socket(), and accept())
742 automatically create an anonymous filehandle if the handle passed to
743 them is an uninitialized scalar variable. This allows the constructs
744 such as C<open(my $fh, ...)> and C<open(local $fh,...)> to be used to
745 create filehandles that will conveniently be closed automatically when
746 the scope ends, provided there are no other references to them. This
747 largely eliminates the need for typeglobs when opening filehandles
748 that must be passed around, as in the following example:
749
750     sub myopen {
751         open my $fh, "@_"
752              or die "Can't open '@_': $!";
753         return $fh;
754     }
755
756     {
757         my $f = myopen("</etc/motd");
758         print <$f>;
759         # $f implicitly closed here
760     }
761
762 Note that if an initialized scalar variable is used instead the
763 result is different: C<my $fh='zzz'; open($fh, ...)> is equivalent
764 to C<open( *{'zzz'}, ...)>.
765 C<use strict 'refs'> forbids such practice.
766
767 Another way to create anonymous filehandles is with the Symbol
768 module or with the IO::Handle module and its ilk.  These modules
769 have the advantage of not hiding different types of the same name
770 during the local().  See the bottom of L<perlfunc/open()> for an
771 example.
772
773 =head1 SEE ALSO
774
775 See L<perlvar> for a description of Perl's built-in variables and
776 a discussion of legal variable names.  See L<perlref>, L<perlsub>,
777 and L<perlmod/"Symbol Tables"> for more discussion on typeglobs and
778 the C<*foo{THING}> syntax.