perl5133delta.pod: editorial changes and cleanup
[perl.git] / pod / perlunicode.pod
1 =head1 NAME
2
3 perlunicode - Unicode support in Perl
4
5 =head1 DESCRIPTION
6
7 =head2 Important Caveats
8
9 Unicode support is an extensive requirement. While Perl does not
10 implement the Unicode standard or the accompanying technical reports
11 from cover to cover, Perl does support many Unicode features.
12
13 People who want to learn to use Unicode in Perl, should probably read
14 the L<Perl Unicode tutorial, perlunitut|perlunitut>, before reading
15 this reference document.
16
17 Also, the use of Unicode may present security issues that aren't obvious.
18 Read L<Unicode Security Considerations|http://www.unicode.org/reports/tr36>.
19
20 =over 4
21
22 =item Input and Output Layers
23
24 Perl knows when a filehandle uses Perl's internal Unicode encodings
25 (UTF-8, or UTF-EBCDIC if in EBCDIC) if the filehandle is opened with
26 the ":utf8" layer.  Other encodings can be converted to Perl's
27 encoding on input or from Perl's encoding on output by use of the
28 ":encoding(...)"  layer.  See L<open>.
29
30 To indicate that Perl source itself is in UTF-8, use C<use utf8;>.
31
32 =item Regular Expressions
33
34 The regular expression compiler produces polymorphic opcodes.  That is,
35 the pattern adapts to the data and automatically switches to the Unicode
36 character scheme when presented with data that is internally encoded in
37 UTF-8, or instead uses a traditional byte scheme when presented with
38 byte data.
39
40 =item C<use utf8> still needed to enable UTF-8/UTF-EBCDIC in scripts
41
42 As a compatibility measure, the C<use utf8> pragma must be explicitly
43 included to enable recognition of UTF-8 in the Perl scripts themselves
44 (in string or regular expression literals, or in identifier names) on
45 ASCII-based machines or to recognize UTF-EBCDIC on EBCDIC-based
46 machines.  B<These are the only times when an explicit C<use utf8>
47 is needed.>  See L<utf8>.
48
49 =item BOM-marked scripts and UTF-16 scripts autodetected
50
51 If a Perl script begins marked with the Unicode BOM (UTF-16LE, UTF16-BE,
52 or UTF-8), or if the script looks like non-BOM-marked UTF-16 of either
53 endianness, Perl will correctly read in the script as Unicode.
54 (BOMless UTF-8 cannot be effectively recognized or differentiated from
55 ISO 8859-1 or other eight-bit encodings.)
56
57 =item C<use encoding> needed to upgrade non-Latin-1 byte strings
58
59 By default, there is a fundamental asymmetry in Perl's Unicode model:
60 implicit upgrading from byte strings to Unicode strings assumes that
61 they were encoded in I<ISO 8859-1 (Latin-1)>, but Unicode strings are
62 downgraded with UTF-8 encoding.  This happens because the first 256
63 codepoints in Unicode happens to agree with Latin-1.
64
65 See L</"Byte and Character Semantics"> for more details.
66
67 =back
68
69 =head2 Byte and Character Semantics
70
71 Beginning with version 5.6, Perl uses logically-wide characters to
72 represent strings internally.
73
74 In future, Perl-level operations will be expected to work with
75 characters rather than bytes.
76
77 However, as an interim compatibility measure, Perl aims to
78 provide a safe migration path from byte semantics to character
79 semantics for programs.  For operations where Perl can unambiguously
80 decide that the input data are characters, Perl switches to
81 character semantics.  For operations where this determination cannot
82 be made without additional information from the user, Perl decides in
83 favor of compatibility and chooses to use byte semantics.
84
85 Under byte semantics, when C<use locale> is in effect, Perl uses the
86 semantics associated with the current locale.  Absent a C<use locale>, and
87 absent a C<use feature 'unicode_strings'> pragma, Perl currently uses US-ASCII
88 (or Basic Latin in Unicode terminology) byte semantics, meaning that characters
89 whose ordinal numbers are in the range 128 - 255 are undefined except for their
90 ordinal numbers.  This means that none have case (upper and lower), nor are any
91 a member of character classes, like C<[:alpha:]> or C<\w>.  (But all do belong
92 to the C<\W> class or the Perl regular expression extension C<[:^alpha:]>.)
93
94 This behavior preserves compatibility with earlier versions of Perl,
95 which allowed byte semantics in Perl operations only if
96 none of the program's inputs were marked as being a source of Unicode
97 character data.  Such data may come from filehandles, from calls to
98 external programs, from information provided by the system (such as %ENV),
99 or from literals and constants in the source text.
100
101 The C<bytes> pragma will always, regardless of platform, force byte
102 semantics in a particular lexical scope.  See L<bytes>.
103
104 The C<use feature 'unicode_strings'> pragma is intended to always, regardless
105 of platform, force character (Unicode) semantics in a particular lexical scope.
106 In release 5.12, it is partially implemented, applying only to case changes.
107 See L</The "Unicode Bug"> below.
108
109 The C<utf8> pragma is primarily a compatibility device that enables
110 recognition of UTF-(8|EBCDIC) in literals encountered by the parser.
111 Note that this pragma is only required while Perl defaults to byte
112 semantics; when character semantics become the default, this pragma
113 may become a no-op.  See L<utf8>.
114
115 Unless explicitly stated, Perl operators use character semantics
116 for Unicode data and byte semantics for non-Unicode data.
117 The decision to use character semantics is made transparently.  If
118 input data comes from a Unicode source--for example, if a character
119 encoding layer is added to a filehandle or a literal Unicode
120 string constant appears in a program--character semantics apply.
121 Otherwise, byte semantics are in effect.  The C<bytes> pragma should
122 be used to force byte semantics on Unicode data, and the C<use feature
123 'unicode_strings'> pragma to force Unicode semantics on byte data (though in
124 5.12 it isn't fully implemented).
125
126 If strings operating under byte semantics and strings with Unicode
127 character data are concatenated, the new string will have
128 character semantics.  This can cause surprises: See L</BUGS>, below.
129 You can choose to be warned when this happens.  See L<encoding::warnings>.
130
131 Under character semantics, many operations that formerly operated on
132 bytes now operate on characters. A character in Perl is
133 logically just a number ranging from 0 to 2**31 or so. Larger
134 characters may encode into longer sequences of bytes internally, but
135 this internal detail is mostly hidden for Perl code.
136 See L<perluniintro> for more.
137
138 =head2 Effects of Character Semantics
139
140 Character semantics have the following effects:
141
142 =over 4
143
144 =item *
145
146 Strings--including hash keys--and regular expression patterns may
147 contain characters that have an ordinal value larger than 255.
148
149 If you use a Unicode editor to edit your program, Unicode characters may
150 occur directly within the literal strings in UTF-8 encoding, or UTF-16.
151 (The former requires a BOM or C<use utf8>, the latter requires a BOM.)
152
153 Unicode characters can also be added to a string by using the C<\N{U+...}>
154 notation.  The Unicode code for the desired character, in hexadecimal,
155 should be placed in the braces, after the C<U>. For instance, a smiley face is
156 C<\N{U+263A}>.
157
158 Alternatively, you can use the C<\x{...}> notation for characters 0x100 and
159 above.  For characters below 0x100 you may get byte semantics instead of
160 character semantics;  see L</The "Unicode Bug">.  On EBCDIC machines there is
161 the additional problem that the value for such characters gives the EBCDIC
162 character rather than the Unicode one.
163
164 Additionally, if you
165
166    use charnames ':full';
167
168 you can use the C<\N{...}> notation and put the official Unicode
169 character name within the braces, such as C<\N{WHITE SMILING FACE}>.
170 See L<charnames>.
171
172 =item *
173
174 If an appropriate L<encoding> is specified, identifiers within the
175 Perl script may contain Unicode alphanumeric characters, including
176 ideographs.  Perl does not currently attempt to canonicalize variable
177 names.
178
179 =item *
180
181 Regular expressions match characters instead of bytes.  "." matches
182 a character instead of a byte.
183
184 =item *
185
186 Bracketed character classes in regular expressions match characters instead of
187 bytes and match against the character properties specified in the
188 Unicode properties database.  C<\w> can be used to match a Japanese
189 ideograph, for instance.
190
191 =item *
192
193 Named Unicode properties, scripts, and block ranges may be used (like bracketed
194 character classes) by using the C<\p{}> "matches property" construct and
195 the C<\P{}> negation, "doesn't match property".
196 See L</"Unicode Character Properties"> for more details.
197
198 You can define your own character properties and use them
199 in the regular expression with the C<\p{}> or C<\P{}> construct.
200 See L</"User-Defined Character Properties"> for more details.
201
202 =item *
203
204 The special pattern C<\X> matches a logical character, an "extended grapheme
205 cluster" in Standardese.  In Unicode what appears to the user to be a single
206 character, for example an accented C<G>, may in fact be composed of a sequence
207 of characters, in this case a C<G> followed by an accent character.  C<\X>
208 will match the entire sequence.
209
210 =item *
211
212 The C<tr///> operator translates characters instead of bytes.  Note
213 that the C<tr///CU> functionality has been removed.  For similar
214 functionality see pack('U0', ...) and pack('C0', ...).
215
216 =item *
217
218 Case translation operators use the Unicode case translation tables
219 when character input is provided.  Note that C<uc()>, or C<\U> in
220 interpolated strings, translates to uppercase, while C<ucfirst>,
221 or C<\u> in interpolated strings, translates to titlecase in languages
222 that make the distinction (which is equivalent to uppercase in languages
223 without the distinction).
224
225 =item *
226
227 Most operators that deal with positions or lengths in a string will
228 automatically switch to using character positions, including
229 C<chop()>, C<chomp()>, C<substr()>, C<pos()>, C<index()>, C<rindex()>,
230 C<sprintf()>, C<write()>, and C<length()>.  An operator that
231 specifically does not switch is C<vec()>.  Operators that really don't
232 care include operators that treat strings as a bucket of bits such as
233 C<sort()>, and operators dealing with filenames.
234
235 =item *
236
237 The C<pack()>/C<unpack()> letter C<C> does I<not> change, since it is often
238 used for byte-oriented formats.  Again, think C<char> in the C language.
239
240 There is a new C<U> specifier that converts between Unicode characters
241 and code points. There is also a C<W> specifier that is the equivalent of
242 C<chr>/C<ord> and properly handles character values even if they are above 255.
243
244 =item *
245
246 The C<chr()> and C<ord()> functions work on characters, similar to
247 C<pack("W")> and C<unpack("W")>, I<not> C<pack("C")> and
248 C<unpack("C")>.  C<pack("C")> and C<unpack("C")> are methods for
249 emulating byte-oriented C<chr()> and C<ord()> on Unicode strings.
250 While these methods reveal the internal encoding of Unicode strings,
251 that is not something one normally needs to care about at all.
252
253 =item *
254
255 The bit string operators, C<& | ^ ~>, can operate on character data.
256 However, for backward compatibility, such as when using bit string
257 operations when characters are all less than 256 in ordinal value, one
258 should not use C<~> (the bit complement) with characters of both
259 values less than 256 and values greater than 256.  Most importantly,
260 DeMorgan's laws (C<~($x|$y) eq ~$x&~$y> and C<~($x&$y) eq ~$x|~$y>)
261 will not hold.  The reason for this mathematical I<faux pas> is that
262 the complement cannot return B<both> the 8-bit (byte-wide) bit
263 complement B<and> the full character-wide bit complement.
264
265 =item *
266
267 You can define your own mappings to be used in C<lc()>,
268 C<lcfirst()>, C<uc()>, and C<ucfirst()> (or their double-quoted string inlined
269 versions such as C<\U>).
270 See L</"User-Defined Case Mappings"> for more details.
271
272 =back
273
274 =over 4
275
276 =item *
277
278 And finally, C<scalar reverse()> reverses by character rather than by byte.
279
280 =back
281
282 =head2 Unicode Character Properties
283
284 Most Unicode character properties are accessible by using regular expressions.
285 They are used (like bracketed character classes) by using the C<\p{}> "matches
286 property" construct and the C<\P{}> negation, "doesn't match property".
287
288 Note that the only time that Perl considers a sequence of individual code
289 points as a single logical character is in the C<\X> construct, already
290 mentioned above.   Therefore "character" in this discussion means a single
291 Unicode code point.
292
293 For instance, C<\p{Uppercase}> matches any single character with the Unicode
294 "Uppercase" property, while C<\p{L}> matches any character with a
295 General_Category of "L" (letter) property.  Brackets are not
296 required for single letter property names, so C<\p{L}> is equivalent to C<\pL>.
297
298 More formally, C<\p{Uppercase}> matches any single character whose Unicode
299 Uppercase property value is True, and C<\P{Uppercase}> matches any character
300 whose Uppercase property value is False, and they could have been written as
301 C<\p{Uppercase=True}> and C<\p{Uppercase=False}>, respectively.
302
303 This formality is needed when properties are not binary, that is if they can
304 take on more values than just True and False.  For example, the Bidi_Class (see
305 L</"Bidirectional Character Types"> below), can take on a number of different
306 values, such as Left, Right, Whitespace, and others.  To match these, one needs
307 to specify the property name (Bidi_Class), and the value being matched against
308 (Left, Right, etc.).  This is done, as in the examples above, by having the
309 two components separated by an equal sign (or interchangeably, a colon), like
310 C<\p{Bidi_Class: Left}>.
311
312 All Unicode-defined character properties may be written in these compound forms
313 of C<\p{property=value}> or C<\p{property:value}>, but Perl provides some
314 additional properties that are written only in the single form, as well as
315 single-form short-cuts for all binary properties and certain others described
316 below, in which you may omit the property name and the equals or colon
317 separator.
318
319 Most Unicode character properties have at least two synonyms (or aliases if you
320 prefer), a short one that is easier to type, and a longer one which is more
321 descriptive and hence it is easier to understand what it means.  Thus the "L"
322 and "Letter" above are equivalent and can be used interchangeably.  Likewise,
323 "Upper" is a synonym for "Uppercase", and we could have written
324 C<\p{Uppercase}> equivalently as C<\p{Upper}>.  Also, there are typically
325 various synonyms for the values the property can be.   For binary properties,
326 "True" has 3 synonyms: "T", "Yes", and "Y"; and "False has correspondingly "F",
327 "No", and "N".  But be careful.  A short form of a value for one property may
328 not mean the same thing as the same short form for another.  Thus, for the
329 General_Category property, "L" means "Letter", but for the Bidi_Class property,
330 "L" means "Left".  A complete list of properties and synonyms is in
331 L<perluniprops>.
332
333 Upper/lower case differences in the property names and values are irrelevant,
334 thus C<\p{Upper}> means the same thing as C<\p{upper}> or even C<\p{UpPeR}>.
335 Similarly, you can add or subtract underscores anywhere in the middle of a
336 word, so that these are also equivalent to C<\p{U_p_p_e_r}>.  And white space
337 is irrelevant adjacent to non-word characters, such as the braces and the equals
338 or colon separators so C<\p{   Upper  }> and C<\p{ Upper_case : Y }> are
339 equivalent to these as well.  In fact, in most cases, white space and even
340 hyphens can be added or deleted anywhere.  So even C<\p{ Up-per case = Yes}> is
341 equivalent.  All this is called "loose-matching" by Unicode.  The few places
342 where stricter matching is employed is in the middle of numbers, and the Perl
343 extension properties that begin or end with an underscore.  Stricter matching
344 cares about white space (except adjacent to the non-word characters) and
345 hyphens, and non-interior underscores.
346
347 You can also use negation in both C<\p{}> and C<\P{}> by introducing a caret
348 (^) between the first brace and the property name: C<\p{^Tamil}> is
349 equal to C<\P{Tamil}>.
350
351 =head3 B<General_Category>
352
353 Every Unicode character is assigned a general category, which is the "most
354 usual categorization of a character" (from
355 L<http://www.unicode.org/reports/tr44>).
356
357 The compound way of writing these is like C<\p{General_Category=Number}>
358 (short, C<\p{gc:n}>).  But Perl furnishes shortcuts in which everything up
359 through the equal or colon separator is omitted.  So you can instead just write
360 C<\pN>.
361
362 Here are the short and long forms of the General Category properties:
363
364     Short       Long
365
366     L           Letter
367     LC, L&      Cased_Letter (that is: [\p{Ll}\p{Lu}\p{Lt}])
368     Lu          Uppercase_Letter
369     Ll          Lowercase_Letter
370     Lt          Titlecase_Letter
371     Lm          Modifier_Letter
372     Lo          Other_Letter
373
374     M           Mark
375     Mn          Nonspacing_Mark
376     Mc          Spacing_Mark
377     Me          Enclosing_Mark
378
379     N           Number
380     Nd          Decimal_Number (also Digit)
381     Nl          Letter_Number
382     No          Other_Number
383
384     P           Punctuation (also Punct)
385     Pc          Connector_Punctuation
386     Pd          Dash_Punctuation
387     Ps          Open_Punctuation
388     Pe          Close_Punctuation
389     Pi          Initial_Punctuation
390                 (may behave like Ps or Pe depending on usage)
391     Pf          Final_Punctuation
392                 (may behave like Ps or Pe depending on usage)
393     Po          Other_Punctuation
394
395     S           Symbol
396     Sm          Math_Symbol
397     Sc          Currency_Symbol
398     Sk          Modifier_Symbol
399     So          Other_Symbol
400
401     Z           Separator
402     Zs          Space_Separator
403     Zl          Line_Separator
404     Zp          Paragraph_Separator
405
406     C           Other
407     Cc          Control (also Cntrl)
408     Cf          Format
409     Cs          Surrogate   (not usable)
410     Co          Private_Use
411     Cn          Unassigned
412
413 Single-letter properties match all characters in any of the
414 two-letter sub-properties starting with the same letter.
415 C<LC> and C<L&> are special cases, which are both aliases for the set consisting of everything matched by C<Ll>, C<Lu>, and C<Lt>.
416
417 Because Perl hides the need for the user to understand the internal
418 representation of Unicode characters, there is no need to implement
419 the somewhat messy concept of surrogates. C<Cs> is therefore not
420 supported.
421
422 =head3 B<Bidirectional Character Types>
423
424 Because scripts differ in their directionality (Hebrew is
425 written right to left, for example) Unicode supplies these properties in
426 the Bidi_Class class:
427
428     Property    Meaning
429
430     L           Left-to-Right
431     LRE         Left-to-Right Embedding
432     LRO         Left-to-Right Override
433     R           Right-to-Left
434     AL          Arabic Letter
435     RLE         Right-to-Left Embedding
436     RLO         Right-to-Left Override
437     PDF         Pop Directional Format
438     EN          European Number
439     ES          European Separator
440     ET          European Terminator
441     AN          Arabic Number
442     CS          Common Separator
443     NSM         Non-Spacing Mark
444     BN          Boundary Neutral
445     B           Paragraph Separator
446     S           Segment Separator
447     WS          Whitespace
448     ON          Other Neutrals
449
450 This property is always written in the compound form.
451 For example, C<\p{Bidi_Class:R}> matches characters that are normally
452 written right to left.
453
454 =head3 B<Scripts>
455
456 The world's languages are written in a number of scripts.  This sentence
457 (unless you're reading it in translation) is written in Latin, while Russian is
458 written in Cyrllic, and Greek is written in, well, Greek; Japanese mainly in
459 Hiragana or Katakana.  There are many more.
460
461 The Unicode Script property gives what script a given character is in,
462 and the property can be specified with the compound form like
463 C<\p{Script=Hebrew}> (short: C<\p{sc=hebr}>).  Perl furnishes shortcuts for all
464 script names.  You can omit everything up through the equals (or colon), and
465 simply write C<\p{Latin}> or C<\P{Cyrillic}>.
466
467 A complete list of scripts and their shortcuts is in L<perluniprops>.
468
469 =head3 B<Use of "Is" Prefix>
470
471 For backward compatibility (with Perl 5.6), all properties mentioned
472 so far may have C<Is> or C<Is_> prepended to their name, so C<\P{Is_Lu}>, for
473 example, is equal to C<\P{Lu}>, and C<\p{IsScript:Arabic}> is equal to
474 C<\p{Arabic}>.
475
476 =head3 B<Blocks>
477
478 In addition to B<scripts>, Unicode also defines B<blocks> of
479 characters.  The difference between scripts and blocks is that the
480 concept of scripts is closer to natural languages, while the concept
481 of blocks is more of an artificial grouping based on groups of Unicode
482 characters with consecutive ordinal values. For example, the "Basic Latin"
483 block is all characters whose ordinals are between 0 and 127, inclusive, in
484 other words, the ASCII characters.  The "Latin" script contains some letters
485 from this block as well as several more, like "Latin-1 Supplement",
486 "Latin Extended-A", etc., but it does not contain all the characters from
487 those blocks. It does not, for example, contain digits, because digits are
488 shared across many scripts. Digits and similar groups, like punctuation, are in
489 the script called C<Common>.  There is also a script called C<Inherited> for
490 characters that modify other characters, and inherit the script value of the
491 controlling character.
492
493 For more about scripts versus blocks, see UAX#24 "Unicode Script Property":
494 L<http://www.unicode.org/reports/tr24>
495
496 The Script property is likely to be the one you want to use when processing
497 natural language; the Block property may be useful in working with the nuts and
498 bolts of Unicode.
499
500 Block names are matched in the compound form, like C<\p{Block: Arrows}> or
501 C<\p{Blk=Hebrew}>.  Unlike most other properties only a few block names have a
502 Unicode-defined short name.  But Perl does provide a (slight) shortcut:  You
503 can say, for example C<\p{In_Arrows}> or C<\p{In_Hebrew}>.  For backwards
504 compatibility, the C<In> prefix may be omitted if there is no naming conflict
505 with a script or any other property, and you can even use an C<Is> prefix
506 instead in those cases.  But it is not a good idea to do this, for a couple
507 reasons:
508
509 =over 4
510
511 =item 1
512
513 It is confusing.  There are many naming conflicts, and you may forget some.
514 For example, C<\p{Hebrew}> means the I<script> Hebrew, and NOT the I<block>
515 Hebrew.  But would you remember that 6 months from now?
516
517 =item 2
518
519 It is unstable.  A new version of Unicode may pre-empt the current meaning by
520 creating a property with the same name.  There was a time in very early Unicode
521 releases when C<\p{Hebrew}> would have matched the I<block> Hebrew; now it
522 doesn't.
523
524 =back
525
526 Some people just prefer to always use C<\p{Block: foo}> and C<\p{Script: bar}>
527 instead of the shortcuts, for clarity, and because they can't remember the
528 difference between 'In' and 'Is' anyway (or aren't confident that those who
529 eventually will read their code will know).
530
531 A complete list of blocks and their shortcuts is in L<perluniprops>.
532
533 =head3 B<Other Properties>
534
535 There are many more properties than the very basic ones described here.
536 A complete list is in L<perluniprops>.
537
538 Unicode defines all its properties in the compound form, so all single-form
539 properties are Perl extensions.  A number of these are just synonyms for the
540 Unicode ones, but some are genunine extensions, including a couple that are in
541 the compound form.  And quite a few of these are actually recommended by Unicode
542 (in L<http://www.unicode.org/reports/tr18>).
543
544 This section gives some details on all the extensions that aren't synonyms for
545 compound-form Unicode properties (for those, you'll have to refer to the
546 L<Unicode Standard|http://www.unicode.org/reports/tr44>.
547
548 =over
549
550 =item B<C<\p{All}>>
551
552 This matches any of the 1_114_112 Unicode code points.  It is a synonym for
553 C<\p{Any}>.
554
555 =item B<C<\p{Alnum}>>
556
557 This matches any C<\p{Alphabetic}> or C<\p{Decimal_Number}> character.
558
559 =item B<C<\p{Any}>>
560
561 This matches any of the 1_114_112 Unicode code points.  It is a synonym for
562 C<\p{All}>.
563
564 =item B<C<\p{Assigned}>>
565
566 This matches any assigned code point; that is, any code point whose general
567 category is not Unassigned (or equivalently, not Cn).
568
569 =item B<C<\p{Blank}>>
570
571 This is the same as C<\h> and C<\p{HorizSpace}>:  A character that changes the
572 spacing horizontally.
573
574 =item B<C<\p{Decomposition_Type: Non_Canonical}>>    (Short: C<\p{Dt=NonCanon}>)
575
576 Matches a character that has a non-canonical decomposition.
577
578 To understand the use of this rarely used property=value combination, it is
579 necessary to know some basics about decomposition.
580 Consider a character, say H.  It could appear with various marks around it,
581 such as an acute accent, or a circumflex, or various hooks, circles, arrows,
582 I<etc.>, above, below, to one side and/or the other, etc.  There are many
583 possibilities among the world's languages.  The number of combinations is
584 astronomical, and if there were a character for each combination, it would
585 soon exhaust Unicode's more than a million possible characters.  So Unicode
586 took a different approach: there is a character for the base H, and a
587 character for each of the possible marks, and they can be combined variously
588 to get a final logical character.  So a logical character--what appears to be a
589 single character--can be a sequence of more than one individual characters.
590 This is called an "extended grapheme cluster".  (Perl furnishes the C<\X>
591 construct to match such sequences.)
592
593 But Unicode's intent is to unify the existing character set standards and
594 practices, and a number of pre-existing standards have single characters that
595 mean the same thing as some of these combinations.  An example is ISO-8859-1,
596 which has quite a few of these in the Latin-1 range, an example being "LATIN
597 CAPITAL LETTER E WITH ACUTE".  Because this character was in this pre-existing
598 standard, Unicode added it to its repertoire.  But this character is considered
599 by Unicode to be equivalent to the sequence consisting of first the character
600 "LATIN CAPITAL LETTER E", then the character "COMBINING ACUTE ACCENT".
601
602 "LATIN CAPITAL LETTER E WITH ACUTE" is called a "pre-composed" character, and
603 the equivalence with the sequence is called canonical equivalence.  All
604 pre-composed characters are said to have a decomposition (into the equivalent
605 sequence) and the decomposition type is also called canonical.
606
607 However, many more characters have a different type of decomposition, a
608 "compatible" or "non-canonical" decomposition.  The sequences that form these
609 decompositions are not considered canonically equivalent to the pre-composed
610 character.  An example, again in the Latin-1 range, is the "SUPERSCRIPT ONE".
611 It is kind of like a regular digit 1, but not exactly; its decomposition
612 into the digit 1 is called a "compatible" decomposition, specifically a
613 "super" decomposition.  There are several such compatibility
614 decompositions (see L<http://www.unicode.org/reports/tr44>), including one
615 called "compat" which means some miscellaneous type of decomposition
616 that doesn't fit into the decomposition categories that Unicode has chosen. 
617
618 Note that most Unicode characters don't have a decomposition, so their
619 decomposition type is "None".
620
621 Perl has added the C<Non_Canonical> type, for your convenience, to mean any of
622 the compatibility decompositions.
623
624 =item B<C<\p{Graph}>>
625
626 Matches any character that is graphic.  Theoretically, this means a character
627 that on a printer would cause ink to be used.
628
629 =item B<C<\p{HorizSpace}>>
630
631 This is the same as C<\h> and C<\p{Blank}>:  A character that changes the
632 spacing horizontally.
633
634 =item B<C<\p{In=*}>> 
635
636 This is a synonym for C<\p{Present_In=*}>
637
638 =item B<C<\p{PerlSpace}>>
639
640 This is the same as C<\s>, restricted to ASCII, namely C<S<[ \f\n\r\t]>>.
641
642 Mnemonic: Perl's (original) space
643
644 =item B<C<\p{PerlWord}>>
645
646 This is the same as C<\w>, restricted to ASCII, namely C<[A-Za-z0-9_]>
647
648 Mnemonic: Perl's (original) word.
649
650 =item B<C<\p{PosixAlnum}>>
651
652 This matches any alphanumeric character in the ASCII range, namely
653 C<[A-Za-z0-9]>.
654
655 =item B<C<\p{PosixAlpha}>>
656
657 This matches any alphabetic character in the ASCII range, namely C<[A-Za-z]>.
658
659 =item B<C<\p{PosixBlank}>>
660
661 This matches any blank character in the ASCII range, namely C<S<[ \t]>>.
662
663 =item B<C<\p{PosixCntrl}>>
664
665 This matches any control character in the ASCII range, namely C<[\x00-\x1F\x7F]>
666
667 =item B<C<\p{PosixDigit}>>
668
669 This matches any digit character in the ASCII range, namely C<[0-9]>.
670
671 =item B<C<\p{PosixGraph}>>
672
673 This matches any graphical character in the ASCII range, namely C<[\x21-\x7E]>.
674
675 =item B<C<\p{PosixLower}>>
676
677 This matches any lowercase character in the ASCII range, namely C<[a-z]>.
678
679 =item B<C<\p{PosixPrint}>>
680
681 This matches any printable character in the ASCII range, namely C<[\x20-\x7E]>.
682 These are the graphical characters plus SPACE.
683
684 =item B<C<\p{PosixPunct}>>
685
686 This matches any punctuation character in the ASCII range, namely
687 C<[\x21-\x2F\x3A-\x40\x5B-\x60\x7B-\x7E]>.  These are the
688 graphical characters that aren't word characters.  Note that the Posix standard
689 includes in its definition of punctuation, those characters that Unicode calls
690 "symbols."
691
692 =item B<C<\p{PosixSpace}>>
693
694 This matches any space character in the ASCII range, namely
695 C<S<[ \f\n\r\t\x0B]>> (the last being a vertical tab).
696
697 =item B<C<\p{PosixUpper}>>
698
699 This matches any uppercase character in the ASCII range, namely C<[A-Z]>.
700
701 =item B<C<\p{Present_In: *}>>    (Short: C<\p{In=*}>)
702
703 This property is used when you need to know in what Unicode version(s) a
704 character is.
705
706 The "*" above stands for some two digit Unicode version number, such as
707 C<1.1> or C<4.0>; or the "*" can also be C<Unassigned>.  This property will
708 match the code points whose final disposition has been settled as of the
709 Unicode release given by the version number; C<\p{Present_In: Unassigned}>
710 will match those code points whose meaning has yet to be assigned.
711
712 For example, C<U+0041> "LATIN CAPITAL LETTER A" was present in the very first
713 Unicode release available, which is C<1.1>, so this property is true for all
714 valid "*" versions.  On the other hand, C<U+1EFF> was not assigned until version
715 5.1 when it became "LATIN SMALL LETTER Y WITH LOOP", so the only "*" that
716 would match it are 5.1, 5.2, and later.
717
718 Unicode furnishes the C<Age> property from which this is derived.  The problem
719 with Age is that a strict interpretation of it (which Perl takes) has it
720 matching the precise release a code point's meaning is introduced in.  Thus
721 C<U+0041> would match only 1.1; and C<U+1EFF> only 5.1.  This is not usually what
722 you want.
723
724 Some non-Perl implementations of the Age property may change its meaning to be
725 the same as the Perl Present_In property; just be aware of that.
726
727 Another confusion with both these properties is that the definition is not
728 that the code point has been assigned, but that the meaning of the code point
729 has been determined.  This is because 66 code points will always be
730 unassigned, and, so the Age for them is the Unicode version the decision to
731 make them so was made in.  For example, C<U+FDD0> is to be permanently
732 unassigned to a character, and the decision to do that was made in version 3.1,
733 so C<\p{Age=3.1}> matches this character and C<\p{Present_In: 3.1}> and up
734 matches as well.
735
736 =item B<C<\p{Print}>>
737
738 This matches any character that is graphical or blank, except controls.
739
740 =item B<C<\p{SpacePerl}>>
741
742 This is the same as C<\s>, including beyond ASCII.
743
744 Mnemonic: Space, as modified by Perl.  (It doesn't include the vertical tab
745 which both the Posix standard and Unicode consider to be space.)
746
747 =item B<C<\p{VertSpace}>>
748
749 This is the same as C<\v>:  A character that changes the spacing vertically.
750
751 =item B<C<\p{Word}>>
752
753 This is the same as C<\w>, including beyond ASCII.
754
755 =back
756
757 =head2 User-Defined Character Properties
758
759 You can define your own binary character properties by defining subroutines
760 whose names begin with "In" or "Is".  The subroutines can be defined in any
761 package.  The user-defined properties can be used in the regular expression
762 C<\p> and C<\P> constructs; if you are using a user-defined property from a
763 package other than the one you are in, you must specify its package in the
764 C<\p> or C<\P> construct.
765
766     # assuming property Is_Foreign defined in Lang::
767     package main;  # property package name required
768     if ($txt =~ /\p{Lang::IsForeign}+/) { ... }
769
770     package Lang;  # property package name not required
771     if ($txt =~ /\p{IsForeign}+/) { ... }
772
773
774 Note that the effect is compile-time and immutable once defined.
775
776 The subroutines must return a specially-formatted string, with one
777 or more newline-separated lines.  Each line must be one of the following:
778
779 =over 4
780
781 =item *
782
783 A single hexadecimal number denoting a Unicode code point to include.
784
785 =item *
786
787 Two hexadecimal numbers separated by horizontal whitespace (space or
788 tabular characters) denoting a range of Unicode code points to include.
789
790 =item *
791
792 Something to include, prefixed by "+": a built-in character
793 property (prefixed by "utf8::") or a user-defined character property,
794 to represent all the characters in that property; two hexadecimal code
795 points for a range; or a single hexadecimal code point.
796
797 =item *
798
799 Something to exclude, prefixed by "-": an existing character
800 property (prefixed by "utf8::") or a user-defined character property,
801 to represent all the characters in that property; two hexadecimal code
802 points for a range; or a single hexadecimal code point.
803
804 =item *
805
806 Something to negate, prefixed "!": an existing character
807 property (prefixed by "utf8::") or a user-defined character property,
808 to represent all the characters in that property; two hexadecimal code
809 points for a range; or a single hexadecimal code point.
810
811 =item *
812
813 Something to intersect with, prefixed by "&": an existing character
814 property (prefixed by "utf8::") or a user-defined character property,
815 for all the characters except the characters in the property; two
816 hexadecimal code points for a range; or a single hexadecimal code point.
817
818 =back
819
820 For example, to define a property that covers both the Japanese
821 syllabaries (hiragana and katakana), you can define
822
823     sub InKana {
824         return <<END;
825     3040\t309F
826     30A0\t30FF
827     END
828     }
829
830 Imagine that the here-doc end marker is at the beginning of the line.
831 Now you can use C<\p{InKana}> and C<\P{InKana}>.
832
833 You could also have used the existing block property names:
834
835     sub InKana {
836         return <<'END';
837     +utf8::InHiragana
838     +utf8::InKatakana
839     END
840     }
841
842 Suppose you wanted to match only the allocated characters,
843 not the raw block ranges: in other words, you want to remove
844 the non-characters:
845
846     sub InKana {
847         return <<'END';
848     +utf8::InHiragana
849     +utf8::InKatakana
850     -utf8::IsCn
851     END
852     }
853
854 The negation is useful for defining (surprise!) negated classes.
855
856     sub InNotKana {
857         return <<'END';
858     !utf8::InHiragana
859     -utf8::InKatakana
860     +utf8::IsCn
861     END
862     }
863
864 Intersection is useful for getting the common characters matched by
865 two (or more) classes.
866
867     sub InFooAndBar {
868         return <<'END';
869     +main::Foo
870     &main::Bar
871     END
872     }
873
874 It's important to remember not to use "&" for the first set; that
875 would be intersecting with nothing (resulting in an empty set).
876
877 =head2 User-Defined Case Mappings
878
879 You can also define your own mappings to be used in C<lc()>,
880 C<lcfirst()>, C<uc()>, and C<ucfirst()> (or their string-inlined versions,
881 C<\L>, C<\l>, C<\U>, and C<\u>).
882 The principle is similar to that of user-defined character
883 properties: to define subroutines
884 with names C<ToLower> (for C<lc()> and C<lcfirst()>); C<ToTitle> (for
885 C<ucfirst()>); and C<ToUpper> (for C<uc()>).
886
887 The string returned by the subroutines needs to be two hexadecimal numbers
888 separated by two tabulators: the two numbers being, respectively, the source
889 code point and the destination code point.  For example:
890
891     sub ToUpper {
892         return <<END;
893     0061\t\t0041
894     END
895     }
896
897 defines a mapping for C<uc()> (and C<\U>) that causes only the character "a"
898 to be mapped to "A"; all other characters will remain unchanged.
899
900 (For serious hackers only)  The above means you have to furnish a complete
901 mapping; you can't just override a couple of characters and leave the rest
902 unchanged.  You can find all the official mappings in the directory
903 C<$Config{privlib}>F</unicore/To/>.  The mapping data is returned as the
904 here-document.  The C<utf8::ToSpecI<Foo>> hashes in those files are special
905 exception mappings derived from
906 C<$Config{privlib}>F</unicore/SpecialCasing.txt>.  (The "Digit" and
907 "Fold" mappings that one can see in the directory are not directly
908 user-accessible, one can use either the L<Unicode::UCD> module, or just match
909 case-insensitively, which is what uses the "Fold" mapping.  Neither are user
910 overridable.)
911
912 If you have many mappings to change, you can take the official mapping data,
913 change by hand the affected code points, and place the whole thing into your
914 subroutine.  But this will only be valid on Perls that use the same Unicode
915 version.  Another option would be to have your subroutine read the official
916 mapping file(s) and overwrite the affected code points.
917
918 If you have only a few mappings to change, starting in 5.14 you can use the
919 following trick, here illustrated for Turkish.
920
921     use Config;
922
923     sub ToUpper {
924         my $official = do "$Config{privlib}/unicore/To/Upper.pl";
925         $utf8::ToSpecUpper{'i'} = 
926                            "\N{LATIN CAPITAL LETTER I WITH DOT ABOVE}";
927         return $official;
928     }
929
930 This takes the official mappings and overrides just one, for "LATIN SMALL
931 LETTER I".  The keys to the hash must be in UTF-8 (or on EBCDIC platforms,
932 UTF-EBCDIC), as illustrated by the inverse function.
933
934     sub ToLower {
935         my $official = do $lower;
936         $utf8::ToSpecLower{"\xc4\xb0"} = "i";
937         return $official;
938     }
939
940 This example is for an ASCII platform, and C<\xc4\xb0> is the UTF-8 string that 
941 represents C<\N{LATIN CAPITAL LETTER I WITH DOT ABOVE}>, C<U+0130>.
942
943 (The trick illustrated here does work in earlier releases, but only if all the
944 characters you want to override have ordinal values of 256 or higher.)
945
946 The mappings are in effect only for the package they are defined in, and only
947 on scalars that have been marked as having Unicode characters, for example by
948 using C<utf8::upgrade()>.  You can get around the latter restriction in the
949 scope of a C<S<use subs>>:
950
951     use subs qw(uc ucfirst lc lcfirst);
952
953     sub uc($) {
954         my $string = shift;
955         utf8::upgrade($string);
956         return CORE::uc($string);
957     }
958
959     sub lc($) {
960         my $string = shift;
961         utf8::upgrade($string);
962
963         # Unless an I is before a dot_above, it turns into a dotless i.
964         $string =~ 
965               s/I (?! [^\p{ccc=0}\p{ccc=Above}]* \x{0307} )/\x{131}/gx;
966
967         # But when the I is followed by a dot_above, remove the
968         # dot_above so the end result will be i.
969         $string =~ s/I ([^\p{ccc=0}\p{ccc=Above}]* ) \x{0307}/i$1/gx;
970         return CORE::lc($string);
971     }
972
973 These examples (also for Turkish) make sure the input is in UTF-8, and then
974 call the corresponding official function, which will use the C<ToUpper()> and
975 C<ToLower()> functions you have defined in the package.  The C<lc()> example
976 shows how you can add context-dependent casing.  (For Turkish, there other
977 required functions: C<ucfirst>, C<lcfirst>, and C<ToTitle>.  These are very
978 similar to the ones given above.)
979
980 =head2 Character Encodings for Input and Output
981
982 See L<Encode>.
983
984 =head2 Unicode Regular Expression Support Level
985
986 The following list of Unicode support for regular expressions describes
987 all the features currently supported.  The references to "Level N"
988 and the section numbers refer to the Unicode Technical Standard #18,
989 "Unicode Regular Expressions", version 11, in May 2005.
990
991 =over 4
992
993 =item *
994
995 Level 1 - Basic Unicode Support
996
997         RL1.1   Hex Notation                     - done          [1]
998         RL1.2   Properties                       - done          [2][3]
999         RL1.2a  Compatibility Properties         - done          [4]
1000         RL1.3   Subtraction and Intersection     - MISSING       [5]
1001         RL1.4   Simple Word Boundaries           - done          [6]
1002         RL1.5   Simple Loose Matches             - done          [7]
1003         RL1.6   Line Boundaries                  - MISSING       [8]
1004         RL1.7   Supplementary Code Points        - done          [9]
1005
1006         [1]  \x{...}
1007         [2]  \p{...} \P{...}
1008         [3]  supports not only minimal list, but all Unicode character
1009              properties (see L</Unicode Character Properties>)
1010         [4]  \d \D \s \S \w \W \X [:prop:] [:^prop:]
1011         [5]  can use regular expression look-ahead [a] or
1012              user-defined character properties [b] to emulate set
1013              operations
1014         [6]  \b \B
1015         [7]  note that Perl does Full case-folding in matching (but with
1016              bugs), not Simple: for example U+1F88 is equivalent to
1017              U+1F00 U+03B9, not with 1F80.  This difference matters
1018              mainly for certain Greek capital letters with certain
1019              modifiers: the Full case-folding decomposes the letter,
1020              while the Simple case-folding would map it to a single
1021              character.
1022         [8]  should do ^ and $ also on U+000B (\v in C), FF (\f), CR
1023              (\r), CRLF (\r\n), NEL (U+0085), LS (U+2028), and PS
1024              (U+2029); should also affect <>, $., and script line
1025              numbers; should not split lines within CRLF [c] (i.e. there
1026              is no empty line between \r and \n)
1027         [9]  UTF-8/UTF-EBDDIC used in perl allows not only U+10000 to
1028              U+10FFFF but also beyond U+10FFFF [d]
1029
1030 [a] You can mimic class subtraction using lookahead.
1031 For example, what UTS#18 might write as
1032
1033     [{Greek}-[{UNASSIGNED}]]
1034
1035 in Perl can be written as:
1036
1037     (?!\p{Unassigned})\p{InGreekAndCoptic}
1038     (?=\p{Assigned})\p{InGreekAndCoptic}
1039
1040 But in this particular example, you probably really want
1041
1042     \p{GreekAndCoptic}
1043
1044 which will match assigned characters known to be part of the Greek script.
1045
1046 Also see the Unicode::Regex::Set module, it does implement the full
1047 UTS#18 grouping, intersection, union, and removal (subtraction) syntax.
1048
1049 [b] '+' for union, '-' for removal (set-difference), '&' for intersection
1050 (see L</"User-Defined Character Properties">)
1051
1052 [c] Try the C<:crlf> layer (see L<PerlIO>).
1053
1054 [d] U+FFFF will currently generate a warning message if 'utf8' warnings are
1055     enabled
1056
1057 =item *
1058
1059 Level 2 - Extended Unicode Support
1060
1061         RL2.1   Canonical Equivalents           - MISSING       [10][11]
1062         RL2.2   Default Grapheme Clusters       - MISSING       [12]
1063         RL2.3   Default Word Boundaries         - MISSING       [14]
1064         RL2.4   Default Loose Matches           - MISSING       [15]
1065         RL2.5   Name Properties                 - MISSING       [16]
1066         RL2.6   Wildcard Properties             - MISSING
1067
1068         [10] see UAX#15 "Unicode Normalization Forms"
1069         [11] have Unicode::Normalize but not integrated to regexes
1070         [12] have \X but we don't have a "Grapheme Cluster Mode"
1071         [14] see UAX#29, Word Boundaries
1072         [15] see UAX#21 "Case Mappings"
1073         [16] have \N{...} but neither compute names of CJK Ideographs
1074              and Hangul Syllables nor use a loose match [e]
1075
1076 [e] C<\N{...}> allows namespaces (see L<charnames>).
1077
1078 =item *
1079
1080 Level 3 - Tailored Support
1081
1082         RL3.1   Tailored Punctuation            - MISSING
1083         RL3.2   Tailored Grapheme Clusters      - MISSING       [17][18]
1084         RL3.3   Tailored Word Boundaries        - MISSING
1085         RL3.4   Tailored Loose Matches          - MISSING
1086         RL3.5   Tailored Ranges                 - MISSING
1087         RL3.6   Context Matching                - MISSING       [19]
1088         RL3.7   Incremental Matches             - MISSING
1089       ( RL3.8   Unicode Set Sharing )
1090         RL3.9   Possible Match Sets             - MISSING
1091         RL3.10  Folded Matching                 - MISSING       [20]
1092         RL3.11  Submatchers                     - MISSING
1093
1094         [17] see UAX#10 "Unicode Collation Algorithms"
1095         [18] have Unicode::Collate but not integrated to regexes
1096         [19] have (?<=x) and (?=x), but look-aheads or look-behinds
1097              should see outside of the target substring
1098         [20] need insensitive matching for linguistic features other
1099              than case; for example, hiragana to katakana, wide and
1100              narrow, simplified Han to traditional Han (see UTR#30
1101              "Character Foldings")
1102
1103 =back
1104
1105 =head2 Unicode Encodings
1106
1107 Unicode characters are assigned to I<code points>, which are abstract
1108 numbers.  To use these numbers, various encodings are needed.
1109
1110 =over 4
1111
1112 =item *
1113
1114 UTF-8
1115
1116 UTF-8 is a variable-length (1 to 6 bytes, current character allocations
1117 require 4 bytes), byte-order independent encoding. For ASCII (and we
1118 really do mean 7-bit ASCII, not another 8-bit encoding), UTF-8 is
1119 transparent.
1120
1121 The following table is from Unicode 3.2.
1122
1123  Code Points            1st Byte  2nd Byte  3rd Byte  4th Byte
1124
1125    U+0000..U+007F       00..7F
1126    U+0080..U+07FF     * C2..DF    80..BF
1127    U+0800..U+0FFF       E0      * A0..BF    80..BF
1128    U+1000..U+CFFF       E1..EC    80..BF    80..BF
1129    U+D000..U+D7FF       ED        80..9F    80..BF
1130    U+D800..U+DFFF       +++++++ utf16 surrogates, not legal utf8 +++++++
1131    U+E000..U+FFFF       EE..EF    80..BF    80..BF
1132   U+10000..U+3FFFF      F0      * 90..BF    80..BF    80..BF
1133   U+40000..U+FFFFF      F1..F3    80..BF    80..BF    80..BF
1134  U+100000..U+10FFFF     F4        80..8F    80..BF    80..BF
1135
1136 Note the gaps before several of the byte entries above marked by '*'.  These are
1137 caused by legal UTF-8 avoiding non-shortest encodings: it is technically
1138 possible to UTF-8-encode a single code point in different ways, but that is
1139 explicitly forbidden, and the shortest possible encoding should always be used
1140 (and that is what Perl does).
1141
1142 Another way to look at it is via bits:
1143
1144  Code Points                    1st Byte   2nd Byte  3rd Byte  4th Byte
1145
1146                     0aaaaaaa     0aaaaaaa
1147             00000bbbbbaaaaaa     110bbbbb  10aaaaaa
1148             ccccbbbbbbaaaaaa     1110cccc  10bbbbbb  10aaaaaa
1149   00000dddccccccbbbbbbaaaaaa     11110ddd  10cccccc  10bbbbbb  10aaaaaa
1150
1151 As you can see, the continuation bytes all begin with "10", and the
1152 leading bits of the start byte tell how many bytes there are in the
1153 encoded character.
1154
1155 =item *
1156
1157 UTF-EBCDIC
1158
1159 Like UTF-8 but EBCDIC-safe, in the way that UTF-8 is ASCII-safe.
1160
1161 =item *
1162
1163 UTF-16, UTF-16BE, UTF-16LE, Surrogates, and BOMs (Byte Order Marks)
1164
1165 The followings items are mostly for reference and general Unicode
1166 knowledge, Perl doesn't use these constructs internally.
1167
1168 UTF-16 is a 2 or 4 byte encoding.  The Unicode code points
1169 C<U+0000..U+FFFF> are stored in a single 16-bit unit, and the code
1170 points C<U+10000..U+10FFFF> in two 16-bit units.  The latter case is
1171 using I<surrogates>, the first 16-bit unit being the I<high
1172 surrogate>, and the second being the I<low surrogate>.
1173
1174 Surrogates are code points set aside to encode the C<U+10000..U+10FFFF>
1175 range of Unicode code points in pairs of 16-bit units.  The I<high
1176 surrogates> are the range C<U+D800..U+DBFF> and the I<low surrogates>
1177 are the range C<U+DC00..U+DFFF>.  The surrogate encoding is
1178
1179     $hi = ($uni - 0x10000) / 0x400 + 0xD800;
1180     $lo = ($uni - 0x10000) % 0x400 + 0xDC00;
1181
1182 and the decoding is
1183
1184     $uni = 0x10000 + ($hi - 0xD800) * 0x400 + ($lo - 0xDC00);
1185
1186 If you try to generate surrogates (for example by using chr()), you
1187 will get a warning, if warnings are turned on, because those code
1188 points are not valid for a Unicode character.
1189
1190 Because of the 16-bitness, UTF-16 is byte-order dependent.  UTF-16
1191 itself can be used for in-memory computations, but if storage or
1192 transfer is required either UTF-16BE (big-endian) or UTF-16LE
1193 (little-endian) encodings must be chosen.
1194
1195 This introduces another problem: what if you just know that your data
1196 is UTF-16, but you don't know which endianness?  Byte Order Marks, or
1197 BOMs, are a solution to this.  A special character has been reserved
1198 in Unicode to function as a byte order marker: the character with the
1199 code point C<U+FEFF> is the BOM.
1200
1201 The trick is that if you read a BOM, you will know the byte order,
1202 since if it was written on a big-endian platform, you will read the
1203 bytes C<0xFE 0xFF>, but if it was written on a little-endian platform,
1204 you will read the bytes C<0xFF 0xFE>.  (And if the originating platform
1205 was writing in UTF-8, you will read the bytes C<0xEF 0xBB 0xBF>.)
1206
1207 The way this trick works is that the character with the code point
1208 C<U+FFFE> is guaranteed not to be a valid Unicode character, so the
1209 sequence of bytes C<0xFF 0xFE> is unambiguously "BOM, represented in
1210 little-endian format" and cannot be C<U+FFFE>, represented in big-endian
1211 format".  (Actually, C<U+FFFE> is legal for use by your program, even for
1212 input/output, but better not use it if you need a BOM.  But it is "illegal for
1213 interchange", so that an unsuspecting program won't get confused.)
1214
1215 =item *
1216
1217 UTF-32, UTF-32BE, UTF-32LE
1218
1219 The UTF-32 family is pretty much like the UTF-16 family, expect that
1220 the units are 32-bit, and therefore the surrogate scheme is not
1221 needed.  The BOM signatures will be C<0x00 0x00 0xFE 0xFF> for BE and
1222 C<0xFF 0xFE 0x00 0x00> for LE.
1223
1224 =item *
1225
1226 UCS-2, UCS-4
1227
1228 Encodings defined by the ISO 10646 standard.  UCS-2 is a 16-bit
1229 encoding.  Unlike UTF-16, UCS-2 is not extensible beyond C<U+FFFF>,
1230 because it does not use surrogates.  UCS-4 is a 32-bit encoding,
1231 functionally identical to UTF-32.
1232
1233 =item *
1234
1235 UTF-7
1236
1237 A seven-bit safe (non-eight-bit) encoding, which is useful if the
1238 transport or storage is not eight-bit safe.  Defined by RFC 2152.
1239
1240 =back
1241
1242 =head2 Security Implications of Unicode
1243
1244 Read L<Unicode Security Considerations|http://www.unicode.org/reports/tr36>.
1245 Also, note the following:
1246
1247 =over 4
1248
1249 =item *
1250
1251 Malformed UTF-8
1252
1253 Unfortunately, the specification of UTF-8 leaves some room for
1254 interpretation of how many bytes of encoded output one should generate
1255 from one input Unicode character.  Strictly speaking, the shortest
1256 possible sequence of UTF-8 bytes should be generated,
1257 because otherwise there is potential for an input buffer overflow at
1258 the receiving end of a UTF-8 connection.  Perl always generates the
1259 shortest length UTF-8, and with warnings on, Perl will warn about
1260 non-shortest length UTF-8 along with other malformations, such as the
1261 surrogates, which are not real Unicode code points.
1262
1263 =item *
1264
1265 Regular expressions behave slightly differently between byte data and
1266 character (Unicode) data.  For example, the "word character" character
1267 class C<\w> will work differently depending on if data is eight-bit bytes
1268 or Unicode.
1269
1270 In the first case, the set of C<\w> characters is either small--the
1271 default set of alphabetic characters, digits, and the "_"--or, if you
1272 are using a locale (see L<perllocale>), the C<\w> might contain a few
1273 more letters according to your language and country.
1274
1275 In the second case, the C<\w> set of characters is much, much larger.
1276 Most importantly, even in the set of the first 256 characters, it will
1277 probably match different characters: unlike most locales, which are
1278 specific to a language and country pair, Unicode classifies all the
1279 characters that are letters I<somewhere> as C<\w>.  For example, your
1280 locale might not think that LATIN SMALL LETTER ETH is a letter (unless
1281 you happen to speak Icelandic), but Unicode does.
1282
1283 As discussed elsewhere, Perl has one foot (two hooves?) planted in
1284 each of two worlds: the old world of bytes and the new world of
1285 characters, upgrading from bytes to characters when necessary.
1286 If your legacy code does not explicitly use Unicode, no automatic
1287 switch-over to characters should happen.  Characters shouldn't get
1288 downgraded to bytes, either.  It is possible to accidentally mix bytes
1289 and characters, however (see L<perluniintro>), in which case C<\w> in
1290 regular expressions might start behaving differently.  Review your
1291 code.  Use warnings and the C<strict> pragma.
1292
1293 =back
1294
1295 =head2 Unicode in Perl on EBCDIC
1296
1297 The way Unicode is handled on EBCDIC platforms is still
1298 experimental.  On such platforms, references to UTF-8 encoding in this
1299 document and elsewhere should be read as meaning the UTF-EBCDIC
1300 specified in Unicode Technical Report 16, unless ASCII vs. EBCDIC issues
1301 are specifically discussed. There is no C<utfebcdic> pragma or
1302 ":utfebcdic" layer; rather, "utf8" and ":utf8" are reused to mean
1303 the platform's "natural" 8-bit encoding of Unicode. See L<perlebcdic>
1304 for more discussion of the issues.
1305
1306 =head2 Locales
1307
1308 Usually locale settings and Unicode do not affect each other, but
1309 there are a couple of exceptions:
1310
1311 =over 4
1312
1313 =item *
1314
1315 You can enable automatic UTF-8-ification of your standard file
1316 handles, default C<open()> layer, and C<@ARGV> by using either
1317 the C<-C> command line switch or the C<PERL_UNICODE> environment
1318 variable, see L<perlrun> for the documentation of the C<-C> switch.
1319
1320 =item *
1321
1322 Perl tries really hard to work both with Unicode and the old
1323 byte-oriented world. Most often this is nice, but sometimes Perl's
1324 straddling of the proverbial fence causes problems.
1325
1326 =back
1327
1328 =head2 When Unicode Does Not Happen
1329
1330 While Perl does have extensive ways to input and output in Unicode,
1331 and few other 'entry points' like the @ARGV which can be interpreted
1332 as Unicode (UTF-8), there still are many places where Unicode (in some
1333 encoding or another) could be given as arguments or received as
1334 results, or both, but it is not.
1335
1336 The following are such interfaces.  Also, see L</The "Unicode Bug">.
1337 For all of these interfaces Perl
1338 currently (as of 5.8.3) simply assumes byte strings both as arguments
1339 and results, or UTF-8 strings if the C<encoding> pragma has been used.
1340
1341 One reason why Perl does not attempt to resolve the role of Unicode in
1342 these cases is that the answers are highly dependent on the operating
1343 system and the file system(s).  For example, whether filenames can be
1344 in Unicode, and in exactly what kind of encoding, is not exactly a
1345 portable concept.  Similarly for the qx and system: how well will the
1346 'command line interface' (and which of them?) handle Unicode?
1347
1348 =over 4
1349
1350 =item *
1351
1352 chdir, chmod, chown, chroot, exec, link, lstat, mkdir,
1353 rename, rmdir, stat, symlink, truncate, unlink, utime, -X
1354
1355 =item *
1356
1357 %ENV
1358
1359 =item *
1360
1361 glob (aka the <*>)
1362
1363 =item *
1364
1365 open, opendir, sysopen
1366
1367 =item *
1368
1369 qx (aka the backtick operator), system
1370
1371 =item *
1372
1373 readdir, readlink
1374
1375 =back
1376
1377 =head2 The "Unicode Bug"
1378
1379 The term, the "Unicode bug" has been applied to an inconsistency with the
1380 Unicode characters whose ordinals are in the Latin-1 Supplement block, that
1381 is, between 128 and 255.  Without a locale specified, unlike all other
1382 characters or code points, these characters have very different semantics in
1383 byte semantics versus character semantics.
1384
1385 In character semantics they are interpreted as Unicode code points, which means
1386 they have the same semantics as Latin-1 (ISO-8859-1).
1387
1388 In byte semantics, they are considered to be unassigned characters, meaning
1389 that the only semantics they have is their ordinal numbers, and that they are
1390 not members of various character classes.  None are considered to match C<\w>
1391 for example, but all match C<\W>.  (On EBCDIC platforms, the behavior may
1392 be different from this, depending on the underlying C language library
1393 functions.)
1394
1395 The behavior is known to have effects on these areas:
1396
1397 =over 4
1398
1399 =item *
1400
1401 Changing the case of a scalar, that is, using C<uc()>, C<ucfirst()>, C<lc()>,
1402 and C<lcfirst()>, or C<\L>, C<\U>, C<\u> and C<\l> in regular expression
1403 substitutions.
1404
1405 =item *
1406
1407 Using caseless (C</i>) regular expression matching
1408
1409 =item *
1410
1411 Matching a number of properties in regular expressions, such as C<\w>
1412
1413 =item *
1414
1415 User-defined case change mappings.  You can create a C<ToUpper()> function, for
1416 example, which overrides Perl's built-in case mappings.  The scalar must be
1417 encoded in utf8 for your function to actually be invoked.
1418
1419 =back
1420
1421 This behavior can lead to unexpected results in which a string's semantics
1422 suddenly change if a code point above 255 is appended to or removed from it,
1423 which changes the string's semantics from byte to character or vice versa.  As
1424 an example, consider the following program and its output:
1425
1426  $ perl -le'
1427      $s1 = "\xC2";
1428      $s2 = "\x{2660}";
1429      for ($s1, $s2, $s1.$s2) {
1430          print /\w/ || 0;
1431      }
1432  '
1433  0
1434  0
1435  1
1436
1437 If there's no C<\w> in C<s1> or in C<s2>, why does their concatenation have one?
1438
1439 This anomaly stems from Perl's attempt to not disturb older programs that
1440 didn't use Unicode, and hence had no semantics for characters outside of the
1441 ASCII range (except in a locale), along with Perl's desire to add Unicode
1442 support seamlessly.  The result wasn't seamless: these characters were
1443 orphaned.
1444
1445 Work is being done to correct this, but only some of it was complete in time
1446 for the 5.12 release.  What has been finished is the important part of the case
1447 changing component.  Due to concerns, and some evidence, that older code might
1448 have come to rely on the existing behavior, the new behavior must be explicitly
1449 enabled by the feature C<unicode_strings> in the L<feature> pragma, even though
1450 no new syntax is involved.
1451
1452 See L<perlfunc/lc> for details on how this pragma works in combination with
1453 various others for casing.  Even though the pragma only affects casing
1454 operations in the 5.12 release, it is planned to have it affect all the
1455 problematic behaviors in later releases: you can't have one without them all.
1456
1457 In the meantime, a workaround is to always call utf8::upgrade($string), or to
1458 use the standard module L<Encode>.   Also, a scalar that has any characters
1459 whose ordinal is above 0x100, or which were specified using either of the
1460 C<\N{...}> notations will automatically have character semantics.
1461
1462 =head2 Forcing Unicode in Perl (Or Unforcing Unicode in Perl)
1463
1464 Sometimes (see L</"When Unicode Does Not Happen"> or L</The "Unicode Bug">)
1465 there are situations where you simply need to force a byte
1466 string into UTF-8, or vice versa.  The low-level calls
1467 utf8::upgrade($bytestring) and utf8::downgrade($utf8string[, FAIL_OK]) are
1468 the answers.
1469
1470 Note that utf8::downgrade() can fail if the string contains characters
1471 that don't fit into a byte.
1472
1473 Calling either function on a string that already is in the desired state is a
1474 no-op.
1475
1476 =head2 Using Unicode in XS
1477
1478 If you want to handle Perl Unicode in XS extensions, you may find the
1479 following C APIs useful.  See also L<perlguts/"Unicode Support"> for an
1480 explanation about Unicode at the XS level, and L<perlapi> for the API
1481 details.
1482
1483 =over 4
1484
1485 =item *
1486
1487 C<DO_UTF8(sv)> returns true if the C<UTF8> flag is on and the bytes
1488 pragma is not in effect.  C<SvUTF8(sv)> returns true if the C<UTF8>
1489 flag is on; the bytes pragma is ignored.  The C<UTF8> flag being on
1490 does B<not> mean that there are any characters of code points greater
1491 than 255 (or 127) in the scalar or that there are even any characters
1492 in the scalar.  What the C<UTF8> flag means is that the sequence of
1493 octets in the representation of the scalar is the sequence of UTF-8
1494 encoded code points of the characters of a string.  The C<UTF8> flag
1495 being off means that each octet in this representation encodes a
1496 single character with code point 0..255 within the string.  Perl's
1497 Unicode model is not to use UTF-8 until it is absolutely necessary.
1498
1499 =item *
1500
1501 C<uvchr_to_utf8(buf, chr)> writes a Unicode character code point into
1502 a buffer encoding the code point as UTF-8, and returns a pointer
1503 pointing after the UTF-8 bytes.  It works appropriately on EBCDIC machines.
1504
1505 =item *
1506
1507 C<utf8_to_uvchr(buf, lenp)> reads UTF-8 encoded bytes from a buffer and
1508 returns the Unicode character code point and, optionally, the length of
1509 the UTF-8 byte sequence.  It works appropriately on EBCDIC machines.
1510
1511 =item *
1512
1513 C<utf8_length(start, end)> returns the length of the UTF-8 encoded buffer
1514 in characters.  C<sv_len_utf8(sv)> returns the length of the UTF-8 encoded
1515 scalar.
1516
1517 =item *
1518
1519 C<sv_utf8_upgrade(sv)> converts the string of the scalar to its UTF-8
1520 encoded form.  C<sv_utf8_downgrade(sv)> does the opposite, if
1521 possible.  C<sv_utf8_encode(sv)> is like sv_utf8_upgrade except that
1522 it does not set the C<UTF8> flag.  C<sv_utf8_decode()> does the
1523 opposite of C<sv_utf8_encode()>.  Note that none of these are to be
1524 used as general-purpose encoding or decoding interfaces: C<use Encode>
1525 for that.  C<sv_utf8_upgrade()> is affected by the encoding pragma
1526 but C<sv_utf8_downgrade()> is not (since the encoding pragma is
1527 designed to be a one-way street).
1528
1529 =item *
1530
1531 C<is_utf8_char(s)> returns true if the pointer points to a valid UTF-8
1532 character.
1533
1534 =item *
1535
1536 C<is_utf8_string(buf, len)> returns true if C<len> bytes of the buffer
1537 are valid UTF-8.
1538
1539 =item *
1540
1541 C<UTF8SKIP(buf)> will return the number of bytes in the UTF-8 encoded
1542 character in the buffer.  C<UNISKIP(chr)> will return the number of bytes
1543 required to UTF-8-encode the Unicode character code point.  C<UTF8SKIP()>
1544 is useful for example for iterating over the characters of a UTF-8
1545 encoded buffer; C<UNISKIP()> is useful, for example, in computing
1546 the size required for a UTF-8 encoded buffer.
1547
1548 =item *
1549
1550 C<utf8_distance(a, b)> will tell the distance in characters between the
1551 two pointers pointing to the same UTF-8 encoded buffer.
1552
1553 =item *
1554
1555 C<utf8_hop(s, off)> will return a pointer to a UTF-8 encoded buffer
1556 that is C<off> (positive or negative) Unicode characters displaced
1557 from the UTF-8 buffer C<s>.  Be careful not to overstep the buffer:
1558 C<utf8_hop()> will merrily run off the end or the beginning of the
1559 buffer if told to do so.
1560
1561 =item *
1562
1563 C<pv_uni_display(dsv, spv, len, pvlim, flags)> and
1564 C<sv_uni_display(dsv, ssv, pvlim, flags)> are useful for debugging the
1565 output of Unicode strings and scalars.  By default they are useful
1566 only for debugging--they display B<all> characters as hexadecimal code
1567 points--but with the flags C<UNI_DISPLAY_ISPRINT>,
1568 C<UNI_DISPLAY_BACKSLASH>, and C<UNI_DISPLAY_QQ> you can make the
1569 output more readable.
1570
1571 =item *
1572
1573 C<ibcmp_utf8(s1, pe1, l1, u1, s2, pe2, l2, u2)> can be used to
1574 compare two strings case-insensitively in Unicode.  For case-sensitive
1575 comparisons you can just use C<memEQ()> and C<memNE()> as usual.
1576
1577 =back
1578
1579 For more information, see L<perlapi>, and F<utf8.c> and F<utf8.h>
1580 in the Perl source code distribution.
1581
1582 =head2 Hacking Perl to work on earlier Unicode versions (for very serious hackers only)
1583
1584 Perl by default comes with the latest supported Unicode version built in, but
1585 you can change to use any earlier one.
1586
1587 Download the files in the version of Unicode that you want from the Unicode web
1588 site L<http://www.unicode.org>).  These should replace the existing files in
1589 C<\$Config{privlib}>/F<unicore>.  (C<\%Config> is available from the Config
1590 module.)  Follow the instructions in F<README.perl> in that directory to change
1591 some of their names, and then run F<make>.
1592
1593 It is even possible to download them to a different directory, and then change
1594 F<utf8_heavy.pl> in the directory C<\$Config{privlib}> to point to the new
1595 directory, or maybe make a copy of that directory before making the change, and
1596 using C<@INC> or the C<-I> run-time flag to switch between versions at will
1597 (but because of caching, not in the middle of a process), but all this is
1598 beyond the scope of these instructions.
1599
1600 =head1 BUGS
1601
1602 =head2 Interaction with Locales
1603
1604 Use of locales with Unicode data may lead to odd results.  Currently,
1605 Perl attempts to attach 8-bit locale info to characters in the range
1606 0..255, but this technique is demonstrably incorrect for locales that
1607 use characters above that range when mapped into Unicode.  Perl's
1608 Unicode support will also tend to run slower.  Use of locales with
1609 Unicode is discouraged.
1610
1611 =head2 Problems with characters in the Latin-1 Supplement range
1612
1613 See L</The "Unicode Bug">
1614
1615 =head2 Problems with case-insensitive regular expression matching
1616
1617 There are problems with case-insensitive matches, including those involving
1618 character classes (enclosed in [square brackets]), characters whose fold
1619 is to multiple characters (such as the single character LATIN SMALL LIGATURE
1620 FFL matches case-insensitively with the 3-character string C<ffl>), and
1621 characters in the Latin-1 Supplement.
1622
1623 =head2 Interaction with Extensions
1624
1625 When Perl exchanges data with an extension, the extension should be
1626 able to understand the UTF8 flag and act accordingly. If the
1627 extension doesn't know about the flag, it's likely that the extension
1628 will return incorrectly-flagged data.
1629
1630 So if you're working with Unicode data, consult the documentation of
1631 every module you're using if there are any issues with Unicode data
1632 exchange. If the documentation does not talk about Unicode at all,
1633 suspect the worst and probably look at the source to learn how the
1634 module is implemented. Modules written completely in Perl shouldn't
1635 cause problems. Modules that directly or indirectly access code written
1636 in other programming languages are at risk.
1637
1638 For affected functions, the simple strategy to avoid data corruption is
1639 to always make the encoding of the exchanged data explicit. Choose an
1640 encoding that you know the extension can handle. Convert arguments passed
1641 to the extensions to that encoding and convert results back from that
1642 encoding. Write wrapper functions that do the conversions for you, so
1643 you can later change the functions when the extension catches up.
1644
1645 To provide an example, let's say the popular Foo::Bar::escape_html
1646 function doesn't deal with Unicode data yet. The wrapper function
1647 would convert the argument to raw UTF-8 and convert the result back to
1648 Perl's internal representation like so:
1649
1650     sub my_escape_html ($) {
1651         my($what) = shift;
1652         return unless defined $what;
1653         Encode::decode_utf8(Foo::Bar::escape_html(
1654                                          Encode::encode_utf8($what)));
1655     }
1656
1657 Sometimes, when the extension does not convert data but just stores
1658 and retrieves them, you will be in a position to use the otherwise
1659 dangerous Encode::_utf8_on() function. Let's say the popular
1660 C<Foo::Bar> extension, written in C, provides a C<param> method that
1661 lets you store and retrieve data according to these prototypes:
1662
1663     $self->param($name, $value);            # set a scalar
1664     $value = $self->param($name);           # retrieve a scalar
1665
1666 If it does not yet provide support for any encoding, one could write a
1667 derived class with such a C<param> method:
1668
1669     sub param {
1670       my($self,$name,$value) = @_;
1671       utf8::upgrade($name);     # make sure it is UTF-8 encoded
1672       if (defined $value) {
1673         utf8::upgrade($value);  # make sure it is UTF-8 encoded
1674         return $self->SUPER::param($name,$value);
1675       } else {
1676         my $ret = $self->SUPER::param($name);
1677         Encode::_utf8_on($ret); # we know, it is UTF-8 encoded
1678         return $ret;
1679       }
1680     }
1681
1682 Some extensions provide filters on data entry/exit points, such as
1683 DB_File::filter_store_key and family. Look out for such filters in
1684 the documentation of your extensions, they can make the transition to
1685 Unicode data much easier.
1686
1687 =head2 Speed
1688
1689 Some functions are slower when working on UTF-8 encoded strings than
1690 on byte encoded strings.  All functions that need to hop over
1691 characters such as length(), substr() or index(), or matching regular
1692 expressions can work B<much> faster when the underlying data are
1693 byte-encoded.
1694
1695 In Perl 5.8.0 the slowness was often quite spectacular; in Perl 5.8.1
1696 a caching scheme was introduced which will hopefully make the slowness
1697 somewhat less spectacular, at least for some operations.  In general,
1698 operations with UTF-8 encoded strings are still slower. As an example,
1699 the Unicode properties (character classes) like C<\p{Nd}> are known to
1700 be quite a bit slower (5-20 times) than their simpler counterparts
1701 like C<\d> (then again, there 268 Unicode characters matching C<Nd>
1702 compared with the 10 ASCII characters matching C<d>).
1703
1704 =head2 Problems on EBCDIC platforms
1705
1706 There are a number of known problems with Perl on EBCDIC platforms.  If you
1707 want to use Perl there, send email to perlbug@perl.org.
1708
1709 In earlier versions, when byte and character data were concatenated,
1710 the new string was sometimes created by
1711 decoding the byte strings as I<ISO 8859-1 (Latin-1)>, even if the
1712 old Unicode string used EBCDIC.
1713
1714 If you find any of these, please report them as bugs.
1715
1716 =head2 Porting code from perl-5.6.X
1717
1718 Perl 5.8 has a different Unicode model from 5.6. In 5.6 the programmer
1719 was required to use the C<utf8> pragma to declare that a given scope
1720 expected to deal with Unicode data and had to make sure that only
1721 Unicode data were reaching that scope. If you have code that is
1722 working with 5.6, you will need some of the following adjustments to
1723 your code. The examples are written such that the code will continue
1724 to work under 5.6, so you should be safe to try them out.
1725
1726 =over 4
1727
1728 =item *
1729
1730 A filehandle that should read or write UTF-8
1731
1732   if ($] > 5.007) {
1733     binmode $fh, ":encoding(utf8)";
1734   }
1735
1736 =item *
1737
1738 A scalar that is going to be passed to some extension
1739
1740 Be it Compress::Zlib, Apache::Request or any extension that has no
1741 mention of Unicode in the manpage, you need to make sure that the
1742 UTF8 flag is stripped off. Note that at the time of this writing
1743 (October 2002) the mentioned modules are not UTF-8-aware. Please
1744 check the documentation to verify if this is still true.
1745
1746   if ($] > 5.007) {
1747     require Encode;
1748     $val = Encode::encode_utf8($val); # make octets
1749   }
1750
1751 =item *
1752
1753 A scalar we got back from an extension
1754
1755 If you believe the scalar comes back as UTF-8, you will most likely
1756 want the UTF8 flag restored:
1757
1758   if ($] > 5.007) {
1759     require Encode;
1760     $val = Encode::decode_utf8($val);
1761   }
1762
1763 =item *
1764
1765 Same thing, if you are really sure it is UTF-8
1766
1767   if ($] > 5.007) {
1768     require Encode;
1769     Encode::_utf8_on($val);
1770   }
1771
1772 =item *
1773
1774 A wrapper for fetchrow_array and fetchrow_hashref
1775
1776 When the database contains only UTF-8, a wrapper function or method is
1777 a convenient way to replace all your fetchrow_array and
1778 fetchrow_hashref calls. A wrapper function will also make it easier to
1779 adapt to future enhancements in your database driver. Note that at the
1780 time of this writing (October 2002), the DBI has no standardized way
1781 to deal with UTF-8 data. Please check the documentation to verify if
1782 that is still true.
1783
1784   sub fetchrow {
1785     # $what is one of fetchrow_{array,hashref}
1786     my($self, $sth, $what) = @_;
1787     if ($] < 5.007) {
1788       return $sth->$what;
1789     } else {
1790       require Encode;
1791       if (wantarray) {
1792         my @arr = $sth->$what;
1793         for (@arr) {
1794           defined && /[^\000-\177]/ && Encode::_utf8_on($_);
1795         }
1796         return @arr;
1797       } else {
1798         my $ret = $sth->$what;
1799         if (ref $ret) {
1800           for my $k (keys %$ret) {
1801             defined
1802             && /[^\000-\177]/
1803             && Encode::_utf8_on($_) for $ret->{$k};
1804           }
1805           return $ret;
1806         } else {
1807           defined && /[^\000-\177]/ && Encode::_utf8_on($_) for $ret;
1808           return $ret;
1809         }
1810       }
1811     }
1812   }
1813
1814
1815 =item *
1816
1817 A large scalar that you know can only contain ASCII
1818
1819 Scalars that contain only ASCII and are marked as UTF-8 are sometimes
1820 a drag to your program. If you recognize such a situation, just remove
1821 the UTF8 flag:
1822
1823   utf8::downgrade($val) if $] > 5.007;
1824
1825 =back
1826
1827 =head1 SEE ALSO
1828
1829 L<perlunitut>, L<perluniintro>, L<perluniprops>, L<Encode>, L<open>, L<utf8>, L<bytes>,
1830 L<perlretut>, L<perlvar/"${^UNICODE}">
1831 L<http://www.unicode.org/reports/tr44>).
1832
1833 =cut