Porting/corelist.pl can now update Module::CoreList directly
[perl.git] / installperl
1 #!./perl -w
2
3 BEGIN {
4     require 5.004;
5     chdir '..' if !-d 'lib' and -d '../lib';
6     @INC = 'lib';
7     $ENV{PERL5LIB} = 'lib';
8
9     # This needs to be at BEGIN time, before any use of Config
10     require './install_lib.pl';
11 }
12
13 use strict;
14 use vars qw($Is_VMS $Is_W32 $Is_OS2 $Is_Cygwin $Is_Darwin $Is_NetWare
15             %opts $packlist);
16 my ($dostrip, $versiononly, $force,
17     $otherperls, $archname, $nwinstall, $nopods);
18 # Not sure how easy it would be to refactor to remove the need for local $depth
19 # below
20 use vars qw /$depth/;
21
22 BEGIN {
23     if ($Is_VMS) { eval 'use VMS::Filespec;' }
24 }
25
26 my $scr_ext = ($Is_VMS ? '.Com' : $Is_W32 ? '.bat' : '');
27
28 use File::Find;
29 use File::Compare;
30 use File::Copy ();
31 use File::Path ();
32 use ExtUtils::Packlist;
33 use Cwd;
34
35 if ($Is_NetWare) {
36     $Is_W32 = 0;
37     $scr_ext = '.pl';
38 }
39
40 # override the ones in the rest of the script
41 sub mkpath {
42     File::Path::mkpath(@_) unless $opts{notify};
43 }
44
45 my $mainperldir = "/usr/bin";
46 my $exe_ext = $Config{exe_ext};
47
48 # Allow "make install PERLNAME=something_besides_perl":
49 my $perl = defined($ENV{PERLNAME}) ? $ENV{PERLNAME} : 'perl';
50
51 # This is the base used for versioned names, like "perl5.6.0".
52 # It's separate because a common use of $PERLNAME is to install
53 # perl as "perl5", if that's used as base for versioned files you
54 # get "perl55.6.0".
55 my $perl_verbase = defined($ENV{PERLNAME_VERBASE})
56                     ? $ENV{PERLNAME_VERBASE}
57                     : $perl;
58 my $dbg = '';
59 my $ndbg = '';
60 if ( $Is_VMS ) {
61     if ( defined $Config{usevmsdebug} ) {
62         if ( $Config{usevmsdebug} eq 'define' ) {
63             $dbg = 'dbg';
64             $ndbg = 'ndbg';
65         }
66     }
67 }
68
69 $otherperls = 1;
70 # This little hack simplifies making the code after the comment "Fetch some
71 # frequently-used items from %Config" warning free. With $opts{destdir} always
72 # defined, it's also possible to make the s/\Q$opts{destdir}\E unconditional.
73
74 $opts{destdir} = '';
75 # Consider refactoring this to use Getopt::Long once Getopt::Long's planned
76 # feature is implemented, to distinguish + and - options.
77 while (@ARGV) {
78     $opts{notify} = 1 if $ARGV[0] eq '-n';
79     $dostrip = 1 if $ARGV[0] eq '-s';
80     $versiononly = 1 if $ARGV[0] eq '-v';
81     $versiononly = 0 if $ARGV[0] eq '+v';
82     $opts{silent} = 1 if $ARGV[0] eq '-S';
83     $otherperls = 0 if $ARGV[0] eq '-o';
84     $force = 1 if $ARGV[0] eq '-f';
85     $opts{verbose} = 1 if $ARGV[0] eq '-V' || $ARGV [0] eq '-n';
86     $archname = 1 if $ARGV[0] eq '-A';
87     $nwinstall = 1 if $ARGV[0] eq '-netware';
88     $nopods = 1 if $ARGV[0] eq '-p';
89     $opts{destdir} = $1 if $ARGV[0] =~ /^-?-destdir=(.*)$/;
90     if ($ARGV[0] eq '-?' or $ARGV[0] =~ /^-?-h/) {
91         print <<"EOT";
92 Usage $0: [switches]
93   -n        Don't actually run any commands; just print them.
94   -s        Run strip on installed binaries.
95   -v        Only install perl as a binary with the version number in the name.
96             (Override whatever config.sh says)
97   +v        Install perl as "perl" and as a binary with the version number in
98             the name.  (Override whatever config.sh says)
99   -S        Silent mode.
100   -f        Force installation (don't check if same version is there)
101   -o        Skip checking for other copies of perl in your PATH.
102   -V        Verbose mode.
103   -A        Also install perl with the architecture's name in the perl binary's
104             name.
105   -p        Don't install the pod files. [This will break use diagnostics;]
106   -netware  Install correctly on a Netware server.
107   -destdir  Prefix installation directories by this string.
108 EOT
109         exit;
110     }
111     shift;
112 }
113
114 $versiononly = 1 if $Config{versiononly} && !defined $versiononly;
115 my (@scripts, @tolink);
116 open SCRIPTS, "utils.lst" or die "Can't open utils.lst: $!";
117 while (<SCRIPTS>) {
118     next if /^#/;
119     s/\s*#\s*pod\s*=.*//; # install script regardless of pod location
120     next if /a2p/; # a2p is binary, to be installed separately
121     chomp;
122     if (/(\S*)\s*#\s*link\s*=\s*(\S*)/) {
123         push @scripts, $1;
124         push @tolink, [$1, $2];
125     } else {
126         push @scripts, $_;
127     }
128 }
129 close SCRIPTS;
130
131 if ($scr_ext) { @scripts = map { "$_$scr_ext" } @scripts; }
132
133 my @pods = $nopods ? () : (<pod/*.pod>, 'x2p/a2p.pod');
134
135 # Specify here any .pm files that are actually architecture-dependent.
136 # (Those included with XS extensions under ext/ are automatically
137 # added later.)
138 # Now that the default privlib has the full perl version number included,
139 # we no longer have to play the trick of sticking version-specific .pm
140 # files under the archlib directory.
141 my %archpms = (
142     Config => 1,
143     lib => 1,
144     Cwd => 1,
145 );
146
147 if ($^O eq 'dos') {
148     push(@scripts,'djgpp/fixpmain');
149     $archpms{config} = $archpms{filehand} = 1;
150 }
151
152 if ((-e "testcompile") && (defined($ENV{'COMPILE'}))) {
153     push(@scripts, map("$_.exe", @scripts));
154 }
155
156 # Exclude nonxs extensions that are not architecture dependent
157 my @nonxs = grep(!/^Errno$/, split(' ', $Config{'nonxs_ext'}));
158
159 find(sub {
160     if (($File::Find::name =~ m{^ext\b(.*)/([^/]+)\.pm$}) &&
161         ! grep { (my $dir = $_) =~ s/\//-/g;
162                  $File::Find::name =~ /^ext\/$dir/ } @nonxs)
163     {
164         my($path, $modname) = ($1,$2);
165
166         # strip to optional "/lib", or remove trailing component
167         $path =~ s{.*/lib\b}{} or $path =~ s{/[^/]*$}{};
168
169         # strip any leading /
170         $path =~ s{^/}{};
171
172         # reconstitute canonical module name
173         $modname = "$path/$modname" if length $path;
174
175         # remember it
176         $archpms{$modname} = 1;
177     }
178 }, 'ext');
179
180 # print "[$_]\n" for sort keys %archpms;
181
182 my $ver = $Config{version};
183 my $release = substr($],0,3);   # Not used currently.
184 my $patchlevel = substr($],3,2);
185 die "Patchlevel of perl ($patchlevel)",
186     "and patchlevel of config.sh ($Config{'PERL_VERSION'}) don't match\n"
187         if $patchlevel != $Config{'PERL_VERSION'};
188
189 # Fetch some frequently-used items from %Config
190 my $installbin = "$opts{destdir}$Config{installbin}";
191 my $installscript = "$opts{destdir}$Config{installscript}";
192 my $installprivlib = "$opts{destdir}$Config{installprivlib}";
193 my $installarchlib = "$opts{destdir}$Config{installarchlib}";
194 my $installsitelib = "$opts{destdir}$Config{installsitelib}";
195 my $installsitearch = "$opts{destdir}$Config{installsitearch}";
196 my $installman1dir = "$opts{destdir}$Config{installman1dir}";
197 my $man1ext = $Config{man1ext};
198 my $libperl = $Config{libperl};
199 # Shared library and dynamic loading suffixes.
200 my $so = $Config{so};
201 my $dlext = $Config{dlext};
202 my $dlsrc = $Config{dlsrc};
203 if ($^O eq 'os390') {
204     my $pwd;
205     chomp($pwd=`pwd`);
206     my $archlibexp = $Config{archlibexp};
207     my $usedl = $Config{usedl};
208     if ($usedl eq 'define') {
209         `./$^X -pibak -e 's{$pwd\/libperl.x}{$archlibexp/CORE/libperl.x}' lib/Config.pm`;
210     }
211 }
212
213 if ($nwinstall) {
214     # This is required only if we are installing on a NetWare server
215     $installscript = $Config{installnwscripts};
216     $installprivlib = $Config{installnwlib};
217     $installarchlib = $Config{installnwlib};
218     $installsitelib = $Config{installnwlib};
219 }
220
221 my $d_dosuid = $Config{d_dosuid};
222 my $binexp = $Config{binexp};
223
224 if ($Is_VMS) {  # Hang in there until File::Spec hits the big time
225     foreach ( \$installbin,     \$installscript,  \$installprivlib,
226               \$installarchlib, \$installsitelib, \$installsitearch,
227               \$installman1dir ) {
228         $$_ = unixify($$_);  $$_ =~ s:/$::;
229     }
230 }
231
232 # Do some quick sanity checks.
233
234 if (!$opts{notify} && $d_dosuid && $>) { die "You must run as root to install suidperl\n"; }
235
236    $installbin          || die "No installbin directory in config.sh\n";
237 -d $installbin          || mkpath($installbin, $opts{verbose}, 0777);
238 -d $installbin          || $opts{notify} || die "$installbin is not a directory\n";
239 -w $installbin          || $opts{notify} || die "$installbin is not writable by you\n"
240         unless $installbin =~ m#^/afs/# || $opts{notify};
241
242 if (!$Is_NetWare) {
243 if (!$Is_VMS) {
244 -x 'perl' . $exe_ext    || die "perl isn't executable!\n";
245 }
246 else {
247 -x $ndbg . 'perl' . $exe_ext    || die "${ndbg}perl$exe_ext isn't executable!\n";
248     if ($dbg) {
249         -x $dbg . 'perl' . $exe_ext     || die "${dbg}perl$exe_ext isn't executable!\n";
250     }
251 }
252 -x 'suidperl' . $exe_ext|| die "suidperl isn't executable!\n" if $d_dosuid;
253
254 -f 't/rantests'         || $Is_W32
255                         || warn "WARNING: You've never run 'make test' or",
256                                 " some tests failed! (Installing anyway.)\n";
257 } #if (!$Is_NetWare)
258
259 # This will be used to store the packlist
260 $packlist = ExtUtils::Packlist->new("$installarchlib/.packlist");
261
262 if (($Is_W32 and ! $Is_NetWare) or $Is_Cygwin) {
263     my $perldll;
264
265     if ($Is_Cygwin) {
266         $perldll = $libperl;
267     } else {
268         $perldll = 'perl5'.$Config{patchlevel}.'.'.$dlext;
269     }
270
271     if ($dlsrc ne "dl_none.xs") {
272         -f $perldll || die "No perl DLL built\n";
273     }
274
275     # Install the DLL
276     safe_unlink("$installbin/$perldll");
277     copy("$perldll", "$installbin/$perldll");
278     chmod(0755, "$installbin/$perldll");
279     $packlist->{"$installbin/$perldll"} = { type => 'file' };
280 } # if (($Is_W32 and ! $Is_NetWare) or $Is_Cygwin)
281
282 # First we install the version-numbered executables.
283
284 if ($Is_VMS) {
285     safe_unlink("$installbin/perl_setup.com");
286     copy("perl_setup.com", "$installbin/perl_setup.com");
287     chmod(0755, "$installbin/perl_setup.com");
288     safe_unlink("$installbin/$dbg$perl$exe_ext");
289     copy("$dbg$perl$exe_ext", "$installbin/$dbg$perl$exe_ext");
290     chmod(0755, "$installbin/$dbg$perl$exe_ext");
291     safe_unlink("$installbin/$dbg${perl}shr$exe_ext");
292     copy("$dbg${perl}shr$exe_ext", "$installbin/$dbg${perl}shr$exe_ext");
293     chmod(0755, "$installbin/$dbg${perl}shr$exe_ext");
294     if ($ndbg) {
295         safe_unlink("$installbin/$ndbg$perl$exe_ext");
296         copy("$ndbg$perl$exe_ext", "$installbin/$ndbg$perl$exe_ext");
297         chmod(0755, "$installbin/$ndbg$perl$exe_ext");
298         safe_unlink("$installbin/${dbg}a2p$exe_ext");
299         copy("x2p/${dbg}a2p$exe_ext", "$installbin/${dbg}a2p$exe_ext");
300         chmod(0755, "$installbin/${dbg}a2p$exe_ext");
301     }
302 }
303 elsif ($^O eq 'mpeix') {
304     # MPE lacks hard links and requires that executables with special
305     # capabilities reside in the MPE namespace.
306     safe_unlink("$installbin/perl$ver$exe_ext", $Config{perlpath});
307     # Install the primary executable into the MPE namespace as perlpath.
308     copy("perl$exe_ext", $Config{perlpath});
309     chmod(0755, $Config{perlpath});
310     # Create a backup copy with the version number.
311     link($Config{perlpath}, "$installbin/perl$ver$exe_ext");
312 }
313 elsif ($^O ne 'dos') {
314     if (!$Is_NetWare) {
315         safe_unlink("$installbin/$perl_verbase$ver$exe_ext");
316         copy("perl$exe_ext", "$installbin/$perl_verbase$ver$exe_ext");
317         strip("$installbin/$perl_verbase$ver$exe_ext");
318         chmod(0755, "$installbin/$perl_verbase$ver$exe_ext");
319     }
320     else {
321         # If installing onto a NetWare server
322         if ($nwinstall) {
323             # Copy perl.nlm, echo.nlm, type.nlm, a2p.nlm & cgi2perl.nlm
324             mkpath($Config{installnwsystem}, 1, 0777);
325             copy("netware\\".$ENV{'MAKE_TYPE'}."\\perl.nlm", $Config{installnwsystem});
326             copy("netware\\testnlm\\echo\\echo.nlm", $Config{installnwsystem});
327             copy("netware\\testnlm\\type\\type.nlm", $Config{installnwsystem});
328             copy("x2p\\a2p.nlm", $Config{installnwsystem});
329             chmod(0755, "$Config{installnwsystem}\\perl.nlm");
330             mkpath($Config{installnwlcgi}, 1, 0777);
331             copy("lib\\auto\\cgi2perl\\cgi2perl.nlm", $Config{installnwlcgi});
332         }
333     } #if (!$Is_NetWare)
334 }
335 else {
336     safe_unlink("$installbin/$perl.exe");
337     copy("perl.exe", "$installbin/$perl.exe");
338 }
339
340 safe_unlink("$installbin/s$perl_verbase$ver$exe_ext");
341 if ($d_dosuid) {
342     copy("suidperl$exe_ext", "$installbin/s$perl_verbase$ver$exe_ext");
343     chmod(04711, "$installbin/s$perl_verbase$ver$exe_ext");
344 }
345
346 # Install library files.
347
348 my ($do_installarchlib, $do_installprivlib) = (0, 0);
349 my $vershort = ($Is_Cygwin and !$Config{usedevel}) ? substr($ver,0,-2) : $ver;
350
351 mkpath($installprivlib, $opts{verbose}, 0777);
352 mkpath($installarchlib, $opts{verbose}, 0777);
353 mkpath($installsitelib, $opts{verbose}, 0777) if ($installsitelib);
354 mkpath($installsitearch, $opts{verbose}, 0777) if ($installsitearch);
355
356 if (chdir "lib") {
357     $do_installarchlib = ! samepath($installarchlib, '.');
358     $do_installprivlib = ! samepath($installprivlib, '.');
359     $do_installprivlib = 0 if $versiononly && !($installprivlib =~ m/\Q$vershort/);
360
361     if ($do_installarchlib || $do_installprivlib) {
362         find(\&installlib, '.');
363     }
364     chdir ".." || die "Can't cd back to source directory: $!\n";
365 }
366 else {
367     warn "Can't cd to lib to install lib files: $!\n";
368 }
369
370 # Install header files and libraries.
371 mkpath("$installarchlib/CORE", $opts{verbose}, 0777);
372 my @corefiles;
373 if ($Is_VMS) {  # We did core file selection during build
374     my $coredir = "lib/$Config{archname}/$ver/CORE";
375     $coredir =~ tr/./_/;
376     map { s|^$coredir/||i; } @corefiles = <$coredir/*.*>;
377 }
378 elsif ($Is_Cygwin) { # On Cygwin symlink it to CORE to make Makefile happy
379     @corefiles = <*.h libperl*.* perl*$Config{lib_ext}>;
380     my $coredll = "$installarchlib/CORE/$libperl";
381     safe_unlink($coredll);
382     ( $Config{'d_link'} eq 'define' &&
383       eval {
384           CORE::link("$installbin/$libperl", $coredll);
385           $packlist->{$coredll} = { from => "$installbin/$libperl",
386                                     type => 'link' };
387       }
388     ) ||
389     eval {
390         symlink("$installbin/$libperl", $coredll);
391         $packlist->{$coredll} = { from => "$installbin/$libperl",
392                                   type => 'link' };
393     } ||
394     ( copy("$installbin/$libperl", $coredll) &&
395       push(@corefiles, $coredll)
396     )
397 } else {
398     # [als] hard-coded 'libperl' name... not good!
399     @corefiles = <*.h libperl*.* perl*$Config{lib_ext}>;
400
401     # AIX needs perl.exp installed as well.
402     push(@corefiles,'perl.exp') if $^O eq 'aix';
403     if ($^O eq 'mpeix') {
404         # MPE needs mpeixish.h installed as well.
405         mkpath("$installarchlib/CORE/mpeix", $opts{verbose}, 0777);
406         push(@corefiles,'mpeix/mpeixish.h');
407     }
408     # If they have built sperl.o...
409     push(@corefiles,'sperl.o') if -f 'sperl.o';
410 }
411 foreach my $file (@corefiles) {
412     # HP-UX (at least) needs to maintain execute permissions
413     # on dynamically-loadable libraries. So we do it for all.
414     if (copy_if_diff($file,"$installarchlib/CORE/$file")) {
415         if ($file =~ /\.(\Q$so\E|\Q$dlext\E)$/) {
416             strip("-S", "$installarchlib/CORE/$file") if $^O =~ /^(rhapsody|darwin)$/;
417             chmod(0555, "$installarchlib/CORE/$file");
418         } else {
419             chmod(0444, "$installarchlib/CORE/$file");
420         }
421     }
422 }
423
424 # Install main perl executables
425 # Make links to ordinary names if installbin directory isn't current directory.
426
427 if (! $versiononly && ! samepath($installbin, '.') && ($^O ne 'dos') && ! $Is_VMS && ! $Is_NetWare) {
428     safe_unlink("$installbin/$perl$exe_ext", "$installbin/suid$perl$exe_ext");
429     if ($^O eq 'mpeix') {
430         # MPE doesn't support hard links, so use a symlink.
431         # We don't want another cloned copy.
432         symlink($Config{perlpath}, "$installbin/perl$exe_ext");
433     } elsif ($^O eq 'vos') {
434         # VOS doesn't support hard links, so use a symlink.
435         symlink("$installbin/$perl_verbase$ver$exe_ext",
436                 "$installbin/$perl$exe_ext");
437     } else {
438         link("$installbin/$perl_verbase$ver$exe_ext",
439                 "$installbin/$perl$exe_ext");
440     }
441     link("$installbin/$perl_verbase$ver$exe_ext",
442             "$installbin/suid$perl$exe_ext")
443       if $d_dosuid;
444 }
445
446 # For development purposes it can be very useful to have multiple perls
447 # build for different "architectures" (eg threading or not) simultaneously.
448 if ($archname && ! samepath($installbin, '.') && ($^O ne 'dos') && ! $Is_VMS) {
449     my $archperl = "$perl_verbase$ver-$Config{archname}$exe_ext";
450     safe_unlink("$installbin/$archperl");
451     if ($^O eq 'mpeix') {
452         # MPE doesn't support hard links, so use a symlink.
453         # We don't want another cloned copy.
454         symlink($Config{perlpath}, "$installbin/$archperl");
455     } elsif ($^O eq 'vos') {
456         # VOS doesn't support hard links, so use a symlink.
457         symlink("$installbin/$perl_verbase$ver$exe_ext",
458                 "$installbin/$archperl");
459     } else {
460         link("$installbin/$perl_verbase$ver$exe_ext", "$installbin/$archperl");
461     }
462 }
463
464 # Offer to install perl in a "standard" location
465
466 my $mainperl_is_instperl = 0;
467
468 if ($Config{installusrbinperl} && $Config{installusrbinperl} eq 'define' &&
469     !$versiononly && !$opts{notify} && !$Is_W32 && !$Is_NetWare && !$Is_VMS && -t STDIN && -t STDERR
470         && -w $mainperldir && ! samepath($mainperldir, $installbin)) {
471     my($usrbinperl)     = "$mainperldir/$perl$exe_ext";
472     my($instperl)       = "$installbin/$perl$exe_ext";
473     my($expinstperl)    = "$binexp/$perl$exe_ext";
474
475     # First make sure $usrbinperl is not already the same as the perl we
476     # just installed.
477     if (-x $usrbinperl) {
478         # Try to be clever about mainperl being a symbolic link
479         # to binexp/perl if binexp and installbin are different.
480         $mainperl_is_instperl =
481             samepath($usrbinperl, $instperl) ||
482             samepath($usrbinperl, $expinstperl) ||
483              (($binexp ne $installbin) &&
484               (-l $usrbinperl) &&
485               ((readlink $usrbinperl) eq $expinstperl));
486     }
487     if (! $mainperl_is_instperl) {
488         unlink($usrbinperl);
489         ( $Config{'d_link'} eq 'define' &&
490           eval { CORE::link $instperl, $usrbinperl } )  ||
491         eval { symlink $expinstperl, $usrbinperl }      ||
492         copy($instperl, $usrbinperl);
493
494         $mainperl_is_instperl = 1;
495     }
496 }
497
498 # Make links to ordinary names if installbin directory isn't current directory.
499 if (!$Is_NetWare && $dbg eq '') {
500     if (! samepath($installbin, 'x2p')) {
501         my $base = 'a2p';
502         $base .= $ver if $versiononly;
503         safe_unlink("$installbin/$base$exe_ext");
504         copy("x2p/a2p$exe_ext", "$installbin/$base$exe_ext");
505         strip("$installbin/$base$exe_ext");
506         chmod(0755, "$installbin/$base$exe_ext");
507     }
508 }
509
510 # cppstdin is just a script, but it is architecture-dependent, so
511 # it can't safely be shared.  Place it in $installbin.
512 # Note that Configure doesn't build cppstin if it isn't needed, so
513 # we skip this if cppstdin doesn't exist.
514 if (! $versiononly && (-f 'cppstdin') && (! samepath($installbin, '.'))) {
515     safe_unlink("$installbin/cppstdin");
516     copy("cppstdin", "$installbin/cppstdin");
517     chmod(0755, "$installbin/cppstdin");
518 }
519
520 sub script_alias {
521     my ($installscript, $orig, $alias, $scr_ext) = @_;
522
523     safe_unlink("$installscript/$alias$scr_ext");
524     if ($^O eq 'dos' or $Is_VMS or $^O eq 'transit') {
525         copy("$installscript/$orig$scr_ext",
526              "$installscript/$alias$scr_ext");
527     } elsif ($^O eq 'vos') {
528         symlink("$installscript/$orig$scr_ext",
529                 "$installscript/$alias$scr_ext");
530     } else {
531         link("$installscript/$orig$scr_ext",
532              "$installscript/$alias$scr_ext");
533     }
534 }
535
536 # Install scripts.
537 mkpath($installscript, $opts{verbose}, 0777);
538 if ($versiononly) {
539     for (@scripts) {
540         (my $base = $_) =~ s#.*/##;
541         $base .= $ver;
542         copy($_,    "$installscript/$base");
543         chmod(0755, "$installscript/$base");
544     }
545
546     for (@tolink) {
547         my ($from, $to) = map { "$_$ver" } @$_;
548         (my $frbase = $from) =~ s#.*/##;
549         (my $tobase = $to) =~ s#.*/##;
550         script_alias($installscript, $frbase, $tobase, $scr_ext);
551     }
552 } else {
553     for (@scripts) {
554         (my $base = $_) =~ s#.*/##;
555         copy($_, "$installscript/$base");
556         chmod(0755, "$installscript/$base");
557     }
558
559     for (@tolink) {
560         my ($from, $to) = @$_;
561         (my $frbase = $from) =~ s#.*/##;
562         (my $tobase = $to) =~ s#.*/##;
563         script_alias($installscript, $frbase, $tobase, $scr_ext);
564     }
565 }
566
567 # Install pod pages.  Where? I guess in $installprivlib/pod
568 # ($installprivlib/pods for cygwin).
569
570 my $pod = ($Is_Cygwin || $Is_Darwin || $Is_VMS || $Is_W32) ? 'pods' : 'pod';
571 if ( !$versiononly || ($installprivlib =~ m/\Q$vershort/)) {
572     mkpath("${installprivlib}/$pod", $opts{verbose}, 0777);
573
574     # If Perl 5.003's perldiag.pod is there, rename it.
575     if (open POD, "${installprivlib}/$pod/perldiag.pod") {
576         read POD, $_, 4000;
577         close POD;
578         # Some of Perl 5.003's diagnostic messages ended with periods.
579         if (/^=.*\.$/m) {
580             my ($from, $to) = ("${installprivlib}/$pod/perldiag.pod",
581                                "${installprivlib}/$pod/perldiag-5.003.pod");
582             print "  rename $from $to";
583             rename($from, $to)
584                 or warn "Couldn't rename $from to $to: $!\n"
585                 unless $opts{notify};
586         }
587     }
588
589     for (@pods) {
590         # $_ is a name like  pod/perl.pod
591         (my $base = $_) =~ s#.*/##;
592         copy_if_diff($_, "${installprivlib}/$pod/${base}");
593     }
594
595 }
596
597 # Check to make sure there aren't other perls around in installer's
598 # path.  This is probably UNIX-specific.  Check all absolute directories
599 # in the path except for where public executables are supposed to live.
600 # Also skip $mainperl if the user opted to have it be a link to the
601 # installed perl.
602
603 if (!$versiononly && $otherperls) {
604     my ($path, @path);
605     my $dirsep = ($Is_OS2 || $Is_W32 || $Is_NetWare) ? ';' : ':' ;
606     ($path = $ENV{"PATH"}) =~ s:\\:/:g ;
607     @path = split(/$dirsep/, $path);
608     if ($Is_VMS) {
609         my $i = 0;
610         while (exists $ENV{'DCL$PATH' . $i}) {
611             my $dir = unixpath($ENV{'DCL$PATH' . $i});  $dir =~ s-/$--;
612             push(@path,$dir);
613         }
614     }
615     my @otherperls;
616     my %otherperls;
617     for (@path) {
618         next unless m,^/,;
619         # Use &samepath here because some systems have other dirs linked
620         # to $mainperldir (like SunOS)
621         next unless -d;
622         next if samepath($_, $binexp);
623         next if samepath($_, cwd());
624         next if ($mainperl_is_instperl && samepath($_, $mainperldir));
625         my $otherperl = "$_/$perl$exe_ext";
626         next if $otherperls{$otherperl}++;
627         push(@otherperls, $otherperl)
628             if (-x $otherperl && ! -d $otherperl);
629     }
630     if (@otherperls) {
631         warn "\nWarning: $perl appears in your path in the following " .
632             "locations beyond where\nwe just installed it:\n";
633         for (@otherperls) {
634             warn "    ", $_, "\n";
635         }
636         warn "\n";
637     }
638
639 }
640
641 $packlist->write() unless $opts{notify};
642 print "  Installation complete\n" if $opts{verbose};
643
644 exit 0;
645
646 ###############################################################################
647
648 # If these are needed elsewhere, move them into install_lib.pl rather than
649 # copying them.
650
651 sub yn {
652     my($prompt) = @_;
653     my($answer);
654     my($default) = $prompt =~ m/\[([yn])\]\s*$/i;
655     print STDERR $prompt;
656     chop($answer = <STDIN>);
657     $answer = $default if $answer =~ m/^\s*$/;
658     ($answer =~ m/^[yY]/);
659 }
660
661 sub safe_unlink {
662     return if $opts{notify} or $Is_VMS;
663     my @names = @_;
664     foreach my $name (@names) {
665         next unless -e $name;
666         chmod 0777, $name if ($Is_OS2 || $Is_W32 || $Is_NetWare);
667         print "  unlink $name\n" if $opts{verbose};
668         next if CORE::unlink($name);
669         warn "Couldn't unlink $name: $!\n";
670         if ($! =~ /busy/i) {
671             print "  mv $name $name.old\n" if $opts{verbose};
672             safe_rename($name, "$name.old")
673                 or warn "Couldn't rename $name: $!\n";
674         }
675     }
676 }
677
678 sub safe_rename {
679     my($from,$to) = @_;
680     if (-f $to and not unlink($to)) {
681         my($i);
682         for ($i = 1; $i < 50; $i++) {
683             last if rename($to, "$to.$i");
684         }
685         warn("Cannot rename to `$to.$i': $!"), return 0
686            if $i >= 50; # Give up!
687     }
688     link($from,$to) || return 0;
689     unlink($from);
690 }
691
692 sub copy {
693     my($from,$to) = @_;
694
695     my $xto = $to;
696     $xto =~ s/^\Q$opts{destdir}\E//;
697     print $opts{verbose} ? "  cp $from $xto\n" : "  $xto\n"
698         unless $opts{silent};
699     print "  creating new version of $xto\n"
700         if $Is_VMS and -e $to and !$opts{silent};
701     unless ($opts{notify} or File::Copy::copy($from, $to)) {
702         # Might have been that F::C::c can't overwrite the target
703         warn "Couldn't copy $from to $to: $!\n"
704             unless -f $to and (chmod(0666, $to), unlink $to)
705                    and File::Copy::copy($from, $to);
706     }
707     $packlist->{$xto} = { type => 'file' };
708 }
709
710 sub installlib {
711     my $dir = $File::Find::dir;
712     $dir =~ s#^\.(?![^/])/?##;
713     local($depth) = $dir ? "lib/$dir" : "lib";
714
715     my $name = $_;
716
717     # Ignore version control directories.
718     if ($name =~ /^(?:CVS|RCS|SCCS|\.svn)\z/ and -d $name) {
719         $File::Find::prune = 1;
720         return;
721     }
722
723     # ignore patch backups, RCS files, emacs backup & temp files and the
724     # .exists files, .PL files, and test files.
725     return if $name =~ m{\.orig$|\.rej$|~$|^#.+#$|,v$|^\.exists|\.PL$|\.plc$|\.t$|^test\.pl$|^dbm_filter_util.pl$} ||
726               $dir  =~ m{/t(?:/|$)};
727     # ignore the cpan script in lib/CPAN/bin, the instmodsh and xsubpp
728     # scripts in lib/ExtUtils, the prove script in lib/Test/Harness,
729     # the corelist script from lib/Module/CoreList/bin and ptar* in
730     # lib/Archive/Tar/bin, the config_data script in lib/Module/Build/scripts
731     # (they're installed later with other utils)
732     return if $name =~ /^(?:cpan|instmodsh|prove|corelist|ptar|cpan2dist|cpanp|cpanp-run-perl|ptardiff|config_data)\z/;
733     # ignore the Makefiles
734     return if $name =~ /^makefile$/i;
735     # ignore the test extensions
736     return if $dir =~ m{\bXS/(?:APItest|Typemap)\b};
737     return if $name =~ m{\b(?:APItest|Typemap)\.pm$};
738     # ignore the demo files
739     return if $dir =~ /\b(?:demos?|eg)\b/;
740
741     # ignore READMEs, MANIFESTs, INSTALL docs, META.ymls and change logs.
742     # Changes.e2x and README.e2x are needed by enc2xs.
743     return if $name =~ m{^(?:README(?:\.\w+)?)$} && $name ne 'README.e2x';
744     return if $name =~ m{^(?:MANIFEST|META\.yml)$};
745     return if $name =~ m{^(?:INSTALL|TODO|BUGS|CREDITS)$}i;
746     return if $name =~ m{^change(?:s|log)(?:\.libnet)?$}i;
747     return if $name =~ m{^(?:SIGNATURE|PAUSE200\d\.pub)$}; # CPAN files
748     return if $name =~ m{^(?:NOTES|PATCHING)$}; # ExtUtils files
749
750     # if using a shared perl library then ignore:
751     # - static library files [of statically linked extensions];
752     # - import library files and export library files (only present on Win32
753     #   anyway?) and empty bootstrap files [of dynamically linked extensions].
754     return if $Config{useshrplib} eq 'true' and
755              ($name =~ /$Config{_a}$/ or $name =~ /\.exp$/ or ($name =~ /\.bs$/ and -z $name));
756
757     $name = "$dir/$name" if $dir ne '';
758
759     return if $name eq 'ExtUtils/XSSymSet.pm' and !$Is_VMS;
760
761     my $installlib = $installprivlib;
762     if ($dir =~ /^auto\// ||
763           ($name =~ /^(.*)\.(?:pm|pod)$/ && $archpms{$1}) ||
764           ($name =~ /^(.*)\.(?:h|lib)$/i && ($Is_W32 || $Is_NetWare)) ||
765           $name=~/^Config_(heavy\|git)\.pl\z/
766        ) {
767         $installlib = $installarchlib;
768         return unless $do_installarchlib;
769     } else {
770         return unless $do_installprivlib;
771     }
772
773     if (-f $_) {
774         if (/\.(?:al|ix)$/ && !($dir =~ m[^auto/(.*)$])) {
775             $installlib = $installprivlib;
776             #We're installing *.al and *.ix files into $installprivlib,
777             #but we have to delete old *.al and *.ix files from the 5.000
778             #distribution:
779             #This might not work because $archname might have changed.
780             unlink("$installarchlib/$name");
781         }
782         my $xname = "$installlib/$name";
783         $xname =~ s/^\Q$opts{destdir}\E//;
784         $packlist->{$xname} = { type => 'file' };
785         if ($force || compare($_, "$installlib/$name") || $opts{notify}) {
786             unlink("$installlib/$name");
787             mkpath("$installlib/$dir", $opts{verbose}, 0777);
788             # HP-UX (at least) needs to maintain execute permissions
789             # on dynamically-loaded libraries.
790             if ($Is_NetWare && !$nwinstall) {
791                 # Don't copy .nlp,.nlm files, doesn't make sense on Windows and also
792                 # if copied will give problems when building new extensions.
793                 # Has to be copied if we are installing on a NetWare server and hence
794                 # the check !$nwinstall
795                 if (!(/\.(?:nlp|nlm|bs)$/)) {
796                     copy_if_diff($_, "$installlib/$name")
797                         and chmod($name =~ /\.(so|$dlext)$/o ? 0555 : 0444,
798                                   "$installlib/$name");
799                 }
800            } else {
801                 if (copy_if_diff($_, "$installlib/$name")) {
802                     if ($name =~ /\.(so|$dlext)$/o) {
803                         strip("-S", "$installlib/$name") if $^O =~ /^(rhapsody|darwin)$/;
804                         chmod(0555, "$installlib/$name");
805                     } else {
806                         strip("-S", "$installlib/$name")
807                             if ($name =~ /\.a$/o and $^O =~ /^(rhapsody|darwin)$/);
808                         chmod(0444, "$installlib/$name");
809                     }
810                 }
811             } #if ($Is_NetWare)
812         }
813     }
814 }
815
816 # Copy $from to $to, only if $from is different than $to.
817 # Also preserve modification times for .a libraries.
818 # On some systems, if you do
819 #   ranlib libperl.a
820 #   cp libperl.a /usr/local/lib/perl5/archlib/CORE/libperl.a
821 # and then try to link against the installed libperl.a, you might
822 # get an error message to the effect that the symbol table is older
823 # than the library.
824 # Return true if copying occurred.
825
826 sub copy_if_diff {
827     my($from,$to)=@_;
828     return 1 if (($^O eq 'VMS') && (-d $from));
829     my $xto = $to;
830     $xto =~ s/^\Q$opts{destdir}\E//;
831     my $perlpodbadsymlink;
832     if ($from =~ m!^pod/perl[\w-]+\.pod$! &&
833         -l $from &&
834         ! -e $from) {
835         # Some Linux implementations have problems traversing over
836         # multiple symlinks (when going over NFS?) and fail to read
837         # the symlink target.  Combine this with the fact that some
838         # of the pod files (the perl$OS.pod) are symlinks (to ../README.$OS),
839         # and you end up with those pods not getting installed.
840         $perlpodbadsymlink = 1;
841     }
842     -f $from || $perlpodbadsymlink || warn "$0: $from not found";
843     $packlist->{$xto} = { type => 'file' };
844     if ($force || compare($from, $to) || $opts{notify}) {
845         safe_unlink($to);   # In case we don't have write permissions.
846         if ($opts{notify}) {
847             $from = $depth . "/" . $from if $depth;
848         }
849         if ($perlpodbadsymlink && $from =~ m!^pod/perl(.+)\.pod$!) {
850             $from = "README.$1";
851         }
852         copy($from, $to);
853         # Restore timestamps if it's a .a library or for OS/2.
854         if (!$opts{notify} && ($Is_OS2 || $to =~ /\.a$/)) {
855             my ($atime, $mtime) = (stat $from)[8,9];
856             utime $atime, $mtime, $to;
857         }
858         1;
859     }
860 }
861
862 sub strip
863 {
864     my(@args) = @_;
865
866     return unless $dostrip;
867
868     my @opts;
869     while (@args && $args[0] =~ /^(-\w+)$/) {
870         push @opts, shift @args;
871     }
872
873     foreach my $file (@args) {
874         if (-f $file) {
875             if ($opts{verbose}) {
876                 print "  strip " . join(' ', @opts);
877                 print " " if (@opts);
878                 print "$file\n";
879             }
880             system("strip", @opts, $file);
881         } else {
882             print "# file '$file' skipped\n" if $opts{verbose};
883         }
884     }
885 }