VMS also should search for extensions in cpan/ as well as ext/
[perl.git] / installperl
1 #!./perl -w
2
3 BEGIN {
4     require 5.004;
5     chdir '..' if !-d 'lib' and -d '../lib';
6     @INC = 'lib';
7     $ENV{PERL5LIB} = 'lib';
8
9     # This needs to be at BEGIN time, before any use of Config
10     require './install_lib.pl';
11 }
12
13 use strict;
14 use vars qw($Is_VMS $Is_W32 $Is_OS2 $Is_Cygwin $Is_Darwin $Is_NetWare
15             %opts $packlist);
16 my ($dostrip, $versiononly, $force,
17     $otherperls, $archname, $nwinstall, $nopods);
18 # Not sure how easy it would be to refactor to remove the need for local $depth
19 # below
20 use vars qw /$depth/;
21
22 BEGIN {
23     if ($Is_VMS) { eval 'use VMS::Filespec;' }
24 }
25
26 my $scr_ext = ($Is_VMS ? '.Com' : $Is_W32 ? '.bat' : '');
27
28 use File::Find;
29 use File::Compare;
30 use File::Copy ();
31 use File::Path ();
32 use ExtUtils::Packlist;
33 use Cwd;
34
35 if ($Is_NetWare) {
36     $Is_W32 = 0;
37     $scr_ext = '.pl';
38 }
39
40 # override the ones in the rest of the script
41 sub mkpath {
42     File::Path::mkpath(@_) unless $opts{notify};
43 }
44
45 my $mainperldir = "/usr/bin";
46 my $exe_ext = $Config{exe_ext};
47
48 # Allow "make install PERLNAME=something_besides_perl":
49 my $perl = defined($ENV{PERLNAME}) ? $ENV{PERLNAME} : 'perl';
50
51 # This is the base used for versioned names, like "perl5.6.0".
52 # It's separate because a common use of $PERLNAME is to install
53 # perl as "perl5", if that's used as base for versioned files you
54 # get "perl55.6.0".
55 my $perl_verbase = defined($ENV{PERLNAME_VERBASE})
56                     ? $ENV{PERLNAME_VERBASE}
57                     : $perl;
58 my $dbg = '';
59 my $ndbg = '';
60 if ( $Is_VMS ) {
61     if ( defined $Config{usevmsdebug} ) {
62         if ( $Config{usevmsdebug} eq 'define' ) {
63             $dbg = 'dbg';
64             $ndbg = 'ndbg';
65         }
66     }
67 }
68
69 $otherperls = 1;
70 # This little hack simplifies making the code after the comment "Fetch some
71 # frequently-used items from %Config" warning free. With $opts{destdir} always
72 # defined, it's also possible to make the s/\Q$opts{destdir}\E unconditional.
73
74 $opts{destdir} = '';
75 # Consider refactoring this to use Getopt::Long once Getopt::Long's planned
76 # feature is implemented, to distinguish + and - options.
77 while (@ARGV) {
78     $opts{notify} = 1 if $ARGV[0] eq '-n';
79     $dostrip = 1 if $ARGV[0] eq '-s';
80     $versiononly = 1 if $ARGV[0] eq '-v';
81     $versiononly = 0 if $ARGV[0] eq '+v';
82     $opts{silent} = 1 if $ARGV[0] eq '-S';
83     $otherperls = 0 if $ARGV[0] eq '-o';
84     $force = 1 if $ARGV[0] eq '-f';
85     $opts{verbose} = 1 if $ARGV[0] eq '-V' || $ARGV [0] eq '-n';
86     $archname = 1 if $ARGV[0] eq '-A';
87     $nwinstall = 1 if $ARGV[0] eq '-netware';
88     $nopods = 1 if $ARGV[0] eq '-p';
89     $opts{destdir} = $1 if $ARGV[0] =~ /^-?-destdir=(.*)$/;
90     if ($ARGV[0] eq '-?' or $ARGV[0] =~ /^-?-h/) {
91         print <<"EOT";
92 Usage $0: [switches]
93   -n        Don't actually run any commands; just print them.
94   -s        Run strip on installed binaries.
95   -v        Only install perl as a binary with the version number in the name.
96             (Override whatever config.sh says)
97   +v        Install perl as "perl" and as a binary with the version number in
98             the name.  (Override whatever config.sh says)
99   -S        Silent mode.
100   -f        Force installation (don't check if same version is there)
101   -o        Skip checking for other copies of perl in your PATH.
102   -V        Verbose mode.
103   -A        Also install perl with the architecture's name in the perl binary's
104             name.
105   -p        Don't install the pod files. [This will break use diagnostics;]
106   -netware  Install correctly on a Netware server.
107   -destdir  Prefix installation directories by this string.
108 EOT
109         exit;
110     }
111     shift;
112 }
113
114 $versiononly = 1 if $Config{versiononly} && !defined $versiononly;
115 my (@scripts, @tolink);
116 open SCRIPTS, "utils.lst" or die "Can't open utils.lst: $!";
117 while (<SCRIPTS>) {
118     next if /^#/;
119     s/\s*#\s*pod\s*=.*//; # install script regardless of pod location
120     next if /a2p/; # a2p is binary, to be installed separately
121     chomp;
122     if (/(\S*)\s*#\s*link\s*=\s*(\S*)/) {
123         push @scripts, $1;
124         push @tolink, [$1, $2];
125     } else {
126         push @scripts, $_;
127     }
128 }
129 close SCRIPTS;
130
131 if ($scr_ext) { @scripts = map { "$_$scr_ext" } @scripts; }
132
133 my @pods = $nopods ? () : (<pod/*.pod>, 'x2p/a2p.pod');
134
135 # Specify here any .pm files that are actually architecture-dependent.
136 # (Those included with XS extensions under ext/ are automatically
137 # added later.)
138 # Now that the default privlib has the full perl version number included,
139 # we no longer have to play the trick of sticking version-specific .pm
140 # files under the archlib directory.
141 my %archpms = (
142     Config => 1,
143     lib => 1,
144     Cwd => 1,
145 );
146
147 if ($^O eq 'dos') {
148     push(@scripts,'djgpp/fixpmain');
149     $archpms{config} = $archpms{filehand} = 1;
150 }
151
152 if ((-e "testcompile") && (defined($ENV{'COMPILE'}))) {
153     push(@scripts, map("$_.exe", @scripts));
154 }
155
156 # Exclude nonxs extensions that are not architecture dependent
157 my @nonxs = grep(!/^Errno$/, split(' ', $Config{'nonxs_ext'}));
158
159 find(sub {
160     if (($File::Find::name =~ m{^ext\b(.*)/([^/]+)\.pm$}) &&
161         ! grep { (my $dir = $_) =~ s/\//-/g;
162                  $File::Find::name =~ /^ext\/$dir/ } @nonxs)
163     {
164         my($path, $modname) = ($1,$2);
165
166         # Change hypenated name like Filter-Util-Call to nested
167         # directory name Filter/Util/Call
168         $path =~ s{-}{/}g;
169
170         # strip to optional "/lib", or remove trailing component
171         $path =~ s{.*/lib\b}{} or $path =~ s{/[^/]*$}{};
172
173         # strip any leading /
174         $path =~ s{^/}{};
175
176         # reconstitute canonical module name
177         $modname = "$path/$modname" if length $path;
178
179         # remember it
180         $archpms{$modname} = 1;
181     }
182 }, 'ext');
183
184 # print "[$_]\n" for sort keys %archpms;
185
186 my $ver = $Config{version};
187 my $release = substr($],0,3);   # Not used currently.
188 my $patchlevel = substr($],3,2);
189 die "Patchlevel of perl ($patchlevel)",
190     "and patchlevel of config.sh ($Config{'PERL_VERSION'}) don't match\n"
191         if $patchlevel != $Config{'PERL_VERSION'};
192
193 # Fetch some frequently-used items from %Config
194 my $installbin = "$opts{destdir}$Config{installbin}";
195 my $installscript = "$opts{destdir}$Config{installscript}";
196 my $installprivlib = "$opts{destdir}$Config{installprivlib}";
197 my $installarchlib = "$opts{destdir}$Config{installarchlib}";
198 my $installsitelib = "$opts{destdir}$Config{installsitelib}";
199 my $installsitearch = "$opts{destdir}$Config{installsitearch}";
200 my $installman1dir = "$opts{destdir}$Config{installman1dir}";
201 my $man1ext = $Config{man1ext};
202 my $libperl = $Config{libperl};
203 # Shared library and dynamic loading suffixes.
204 my $so = $Config{so};
205 my $dlext = $Config{dlext};
206 my $dlsrc = $Config{dlsrc};
207 if ($^O eq 'os390') {
208     my $pwd;
209     chomp($pwd=`pwd`);
210     my $archlibexp = $Config{archlibexp};
211     my $usedl = $Config{usedl};
212     if ($usedl eq 'define') {
213         `./$^X -pibak -e 's{$pwd\/libperl.x}{$archlibexp/CORE/libperl.x}' lib/Config.pm`;
214     }
215 }
216
217 if ($nwinstall) {
218     # This is required only if we are installing on a NetWare server
219     $installscript = $Config{installnwscripts};
220     $installprivlib = $Config{installnwlib};
221     $installarchlib = $Config{installnwlib};
222     $installsitelib = $Config{installnwlib};
223 }
224
225 my $binexp = $Config{binexp};
226
227 if ($Is_VMS) {  # Hang in there until File::Spec hits the big time
228     foreach ( \$installbin,     \$installscript,  \$installprivlib,
229               \$installarchlib, \$installsitelib, \$installsitearch,
230               \$installman1dir ) {
231         $$_ = unixify($$_);  $$_ =~ s:/$::;
232     }
233 }
234
235 # Do some quick sanity checks.
236
237    $installbin          || die "No installbin directory in config.sh\n";
238 -d $installbin          || mkpath($installbin, $opts{verbose}, 0777);
239 -d $installbin          || $opts{notify} || die "$installbin is not a directory\n";
240 -w $installbin          || $opts{notify} || die "$installbin is not writable by you\n"
241         unless $installbin =~ m#^/afs/# || $opts{notify};
242
243 if (!$Is_NetWare) {
244 if (!$Is_VMS) {
245 -x 'perl' . $exe_ext    || die "perl isn't executable!\n";
246 }
247 else {
248 -x $ndbg . 'perl' . $exe_ext    || die "${ndbg}perl$exe_ext isn't executable!\n";
249     if ($dbg) {
250         -x $dbg . 'perl' . $exe_ext     || die "${dbg}perl$exe_ext isn't executable!\n";
251     }
252 }
253
254 -f 't/rantests'         || $Is_W32
255                         || warn "WARNING: You've never run 'make test' or",
256                                 " some tests failed! (Installing anyway.)\n";
257 } #if (!$Is_NetWare)
258
259 # This will be used to store the packlist
260 $packlist = ExtUtils::Packlist->new("$installarchlib/.packlist");
261
262 if (($Is_W32 and ! $Is_NetWare) or $Is_Cygwin) {
263     my $perldll;
264
265     if ($Is_Cygwin) {
266         $perldll = $libperl;
267     } else {
268         $perldll = 'perl5'.$Config{patchlevel}.'.'.$dlext;
269     }
270
271     if ($dlsrc ne "dl_none.xs") {
272         -f $perldll || die "No perl DLL built\n";
273     }
274
275     # Install the DLL
276     safe_unlink("$installbin/$perldll");
277     copy("$perldll", "$installbin/$perldll");
278     chmod(0755, "$installbin/$perldll");
279     $packlist->{"$installbin/$perldll"} = { type => 'file' };
280 } # if (($Is_W32 and ! $Is_NetWare) or $Is_Cygwin)
281
282 # First we install the version-numbered executables.
283
284 if ($Is_VMS) {
285     safe_unlink("$installbin/perl_setup.com");
286     copy("perl_setup.com", "$installbin/perl_setup.com");
287     chmod(0755, "$installbin/perl_setup.com");
288     safe_unlink("$installbin/$dbg$perl$exe_ext");
289     copy("$dbg$perl$exe_ext", "$installbin/$dbg$perl$exe_ext");
290     chmod(0755, "$installbin/$dbg$perl$exe_ext");
291     safe_unlink("$installbin/$dbg${perl}shr$exe_ext");
292     copy("$dbg${perl}shr$exe_ext", "$installbin/$dbg${perl}shr$exe_ext");
293     chmod(0755, "$installbin/$dbg${perl}shr$exe_ext");
294     if ($ndbg) {
295         safe_unlink("$installbin/$ndbg$perl$exe_ext");
296         copy("$ndbg$perl$exe_ext", "$installbin/$ndbg$perl$exe_ext");
297         chmod(0755, "$installbin/$ndbg$perl$exe_ext");
298         safe_unlink("$installbin/${dbg}a2p$exe_ext");
299         copy("x2p/${dbg}a2p$exe_ext", "$installbin/${dbg}a2p$exe_ext");
300         chmod(0755, "$installbin/${dbg}a2p$exe_ext");
301     }
302 }
303 elsif ($^O eq 'mpeix') {
304     # MPE lacks hard links and requires that executables with special
305     # capabilities reside in the MPE namespace.
306     safe_unlink("$installbin/perl$ver$exe_ext", $Config{perlpath});
307     # Install the primary executable into the MPE namespace as perlpath.
308     copy("perl$exe_ext", $Config{perlpath});
309     chmod(0755, $Config{perlpath});
310     # Create a backup copy with the version number.
311     link($Config{perlpath}, "$installbin/perl$ver$exe_ext");
312 }
313 elsif ($^O ne 'dos') {
314     if (!$Is_NetWare) {
315         safe_unlink("$installbin/$perl_verbase$ver$exe_ext");
316         copy("perl$exe_ext", "$installbin/$perl_verbase$ver$exe_ext");
317         strip("$installbin/$perl_verbase$ver$exe_ext");
318         chmod(0755, "$installbin/$perl_verbase$ver$exe_ext");
319     }
320     else {
321         # If installing onto a NetWare server
322         if ($nwinstall) {
323             # Copy perl.nlm, echo.nlm, type.nlm, a2p.nlm & cgi2perl.nlm
324             mkpath($Config{installnwsystem}, 1, 0777);
325             copy("netware\\".$ENV{'MAKE_TYPE'}."\\perl.nlm", $Config{installnwsystem});
326             copy("netware\\testnlm\\echo\\echo.nlm", $Config{installnwsystem});
327             copy("netware\\testnlm\\type\\type.nlm", $Config{installnwsystem});
328             copy("x2p\\a2p.nlm", $Config{installnwsystem});
329             chmod(0755, "$Config{installnwsystem}\\perl.nlm");
330             mkpath($Config{installnwlcgi}, 1, 0777);
331             copy("lib\\auto\\cgi2perl\\cgi2perl.nlm", $Config{installnwlcgi});
332         }
333     } #if (!$Is_NetWare)
334 }
335 else {
336     safe_unlink("$installbin/$perl.exe");
337     copy("perl.exe", "$installbin/$perl.exe");
338 }
339
340 # Install library files.
341
342 my ($do_installarchlib, $do_installprivlib) = (0, 0);
343 my $vershort = ($Is_Cygwin and !$Config{usedevel}) ? substr($ver,0,-2) : $ver;
344
345 mkpath($installprivlib, $opts{verbose}, 0777);
346 mkpath($installarchlib, $opts{verbose}, 0777);
347 mkpath($installsitelib, $opts{verbose}, 0777) if ($installsitelib);
348 mkpath($installsitearch, $opts{verbose}, 0777) if ($installsitearch);
349
350 if (chdir "lib") {
351     $do_installarchlib = ! samepath($installarchlib, '.');
352     $do_installprivlib = ! samepath($installprivlib, '.');
353     $do_installprivlib = 0 if $versiononly && !($installprivlib =~ m/\Q$vershort/);
354
355     if ($do_installarchlib || $do_installprivlib) {
356         find(\&installlib, '.');
357     }
358     chdir ".." || die "Can't cd back to source directory: $!\n";
359 }
360 else {
361     warn "Can't cd to lib to install lib files: $!\n";
362 }
363
364 # Install header files and libraries.
365 mkpath("$installarchlib/CORE", $opts{verbose}, 0777);
366 my @corefiles;
367 if ($Is_VMS) {  # We did core file selection during build
368     my $coredir = "lib/$Config{archname}/$ver/CORE";
369     $coredir =~ tr/./_/;
370     map { s|^$coredir/||i; } @corefiles = <$coredir/*.*>;
371 }
372 elsif ($Is_Cygwin) { # On Cygwin symlink it to CORE to make Makefile happy
373     @corefiles = <*.h libperl*.* perl*$Config{lib_ext}>;
374     my $coredll = "$installarchlib/CORE/$libperl";
375     safe_unlink($coredll);
376     ( $Config{'d_link'} eq 'define' &&
377       eval {
378           CORE::link("$installbin/$libperl", $coredll);
379           $packlist->{$coredll} = { from => "$installbin/$libperl",
380                                     type => 'link' };
381       }
382     ) ||
383     eval {
384         symlink("$installbin/$libperl", $coredll);
385         $packlist->{$coredll} = { from => "$installbin/$libperl",
386                                   type => 'link' };
387     } ||
388     ( copy("$installbin/$libperl", $coredll) &&
389       push(@corefiles, $coredll)
390     )
391 } else {
392     # [als] hard-coded 'libperl' name... not good!
393     @corefiles = <*.h libperl*.* perl*$Config{lib_ext}>;
394
395     # AIX needs perl.exp installed as well.
396     push(@corefiles,'perl.exp') if $^O eq 'aix';
397     if ($^O eq 'mpeix') {
398         # MPE needs mpeixish.h installed as well.
399         mkpath("$installarchlib/CORE/mpeix", $opts{verbose}, 0777);
400         push(@corefiles,'mpeix/mpeixish.h');
401     }
402     # If they have built sperl.o...
403     push(@corefiles,'sperl.o') if -f 'sperl.o';
404 }
405 foreach my $file (@corefiles) {
406     # HP-UX (at least) needs to maintain execute permissions
407     # on dynamically-loadable libraries. So we do it for all.
408     if (copy_if_diff($file,"$installarchlib/CORE/$file")) {
409         if ($file =~ /\.(\Q$so\E|\Q$dlext\E)$/) {
410             strip("-S", "$installarchlib/CORE/$file") if $^O =~ /^(rhapsody|darwin)$/;
411             chmod(0555, "$installarchlib/CORE/$file");
412         } else {
413             chmod(0444, "$installarchlib/CORE/$file");
414         }
415     }
416 }
417
418 # Install main perl executables
419 # Make links to ordinary names if installbin directory isn't current directory.
420
421 if (! $versiononly && ! samepath($installbin, '.') && ($^O ne 'dos') && ! $Is_VMS && ! $Is_NetWare) {
422     safe_unlink("$installbin/$perl$exe_ext", "$installbin/suid$perl$exe_ext");
423     if ($^O eq 'mpeix') {
424         # MPE doesn't support hard links, so use a symlink.
425         # We don't want another cloned copy.
426         symlink($Config{perlpath}, "$installbin/perl$exe_ext");
427     } elsif ($^O eq 'vos') {
428         # VOS doesn't support hard links, so use a symlink.
429         symlink("$installbin/$perl_verbase$ver$exe_ext",
430                 "$installbin/$perl$exe_ext");
431     } else {
432         link("$installbin/$perl_verbase$ver$exe_ext",
433                 "$installbin/$perl$exe_ext");
434     }
435 }
436
437 # For development purposes it can be very useful to have multiple perls
438 # build for different "architectures" (eg threading or not) simultaneously.
439 if ($archname && ! samepath($installbin, '.') && ($^O ne 'dos') && ! $Is_VMS) {
440     my $archperl = "$perl_verbase$ver-$Config{archname}$exe_ext";
441     safe_unlink("$installbin/$archperl");
442     if ($^O eq 'mpeix') {
443         # MPE doesn't support hard links, so use a symlink.
444         # We don't want another cloned copy.
445         symlink($Config{perlpath}, "$installbin/$archperl");
446     } elsif ($^O eq 'vos') {
447         # VOS doesn't support hard links, so use a symlink.
448         symlink("$installbin/$perl_verbase$ver$exe_ext",
449                 "$installbin/$archperl");
450     } else {
451         link("$installbin/$perl_verbase$ver$exe_ext", "$installbin/$archperl");
452     }
453 }
454
455 # Offer to install perl in a "standard" location
456
457 my $mainperl_is_instperl = 0;
458
459 if ($Config{installusrbinperl} && $Config{installusrbinperl} eq 'define' &&
460     !$versiononly && !$opts{notify} && !$Is_W32 && !$Is_NetWare && !$Is_VMS && -t STDIN && -t STDERR
461         && -w $mainperldir && ! samepath($mainperldir, $installbin)) {
462     my($usrbinperl)     = "$mainperldir/$perl$exe_ext";
463     my($instperl)       = "$installbin/$perl$exe_ext";
464     my($expinstperl)    = "$binexp/$perl$exe_ext";
465
466     # First make sure $usrbinperl is not already the same as the perl we
467     # just installed.
468     if (-x $usrbinperl) {
469         # Try to be clever about mainperl being a symbolic link
470         # to binexp/perl if binexp and installbin are different.
471         $mainperl_is_instperl =
472             samepath($usrbinperl, $instperl) ||
473             samepath($usrbinperl, $expinstperl) ||
474              (($binexp ne $installbin) &&
475               (-l $usrbinperl) &&
476               ((readlink $usrbinperl) eq $expinstperl));
477     }
478     if (! $mainperl_is_instperl) {
479         unlink($usrbinperl);
480         ( $Config{'d_link'} eq 'define' &&
481           eval { CORE::link $instperl, $usrbinperl } )  ||
482         eval { symlink $expinstperl, $usrbinperl }      ||
483         copy($instperl, $usrbinperl);
484
485         $mainperl_is_instperl = 1;
486     }
487 }
488
489 # Make links to ordinary names if installbin directory isn't current directory.
490 if (!$Is_NetWare && $dbg eq '') {
491     if (! samepath($installbin, 'x2p')) {
492         my $base = 'a2p';
493         $base .= $ver if $versiononly;
494         safe_unlink("$installbin/$base$exe_ext");
495         copy("x2p/a2p$exe_ext", "$installbin/$base$exe_ext");
496         strip("$installbin/$base$exe_ext");
497         chmod(0755, "$installbin/$base$exe_ext");
498     }
499 }
500
501 # cppstdin is just a script, but it is architecture-dependent, so
502 # it can't safely be shared.  Place it in $installbin.
503 # Note that Configure doesn't build cppstin if it isn't needed, so
504 # we skip this if cppstdin doesn't exist.
505 if (! $versiononly && (-f 'cppstdin') && (! samepath($installbin, '.'))) {
506     safe_unlink("$installbin/cppstdin");
507     copy("cppstdin", "$installbin/cppstdin");
508     chmod(0755, "$installbin/cppstdin");
509 }
510
511 sub script_alias {
512     my ($installscript, $orig, $alias, $scr_ext) = @_;
513
514     safe_unlink("$installscript/$alias$scr_ext");
515     if ($^O eq 'dos' or $Is_VMS or $^O eq 'transit') {
516         copy("$installscript/$orig$scr_ext",
517              "$installscript/$alias$scr_ext");
518     } elsif ($^O eq 'vos') {
519         symlink("$installscript/$orig$scr_ext",
520                 "$installscript/$alias$scr_ext");
521     } else {
522         link("$installscript/$orig$scr_ext",
523              "$installscript/$alias$scr_ext");
524     }
525 }
526
527 # Install scripts.
528 mkpath($installscript, $opts{verbose}, 0777);
529 if ($versiononly) {
530     for (@scripts) {
531         (my $base = $_) =~ s#.*/##;
532         $base .= $ver;
533         copy($_,    "$installscript/$base");
534         chmod(0755, "$installscript/$base");
535     }
536
537     for (@tolink) {
538         my ($from, $to) = map { "$_$ver" } @$_;
539         (my $frbase = $from) =~ s#.*/##;
540         (my $tobase = $to) =~ s#.*/##;
541         script_alias($installscript, $frbase, $tobase, $scr_ext);
542     }
543 } else {
544     for (@scripts) {
545         (my $base = $_) =~ s#.*/##;
546         copy($_, "$installscript/$base");
547         chmod(0755, "$installscript/$base");
548     }
549
550     for (@tolink) {
551         my ($from, $to) = @$_;
552         (my $frbase = $from) =~ s#.*/##;
553         (my $tobase = $to) =~ s#.*/##;
554         script_alias($installscript, $frbase, $tobase, $scr_ext);
555     }
556 }
557
558 # Install pod pages.  Where? I guess in $installprivlib/pod
559 # ($installprivlib/pods for cygwin).
560
561 my $pod = ($Is_Cygwin || $Is_Darwin || $Is_VMS || $Is_W32) ? 'pods' : 'pod';
562 if ( !$versiononly || ($installprivlib =~ m/\Q$vershort/)) {
563     mkpath("${installprivlib}/$pod", $opts{verbose}, 0777);
564
565     # If Perl 5.003's perldiag.pod is there, rename it.
566     if (open POD, "${installprivlib}/$pod/perldiag.pod") {
567         read POD, $_, 4000;
568         close POD;
569         # Some of Perl 5.003's diagnostic messages ended with periods.
570         if (/^=.*\.$/m) {
571             my ($from, $to) = ("${installprivlib}/$pod/perldiag.pod",
572                                "${installprivlib}/$pod/perldiag-5.003.pod");
573             print "  rename $from $to";
574             rename($from, $to)
575                 or warn "Couldn't rename $from to $to: $!\n"
576                 unless $opts{notify};
577         }
578     }
579
580     for (@pods) {
581         # $_ is a name like  pod/perl.pod
582         (my $base = $_) =~ s#.*/##;
583         copy_if_diff($_, "${installprivlib}/$pod/${base}");
584     }
585
586 }
587
588 # Check to make sure there aren't other perls around in installer's
589 # path.  This is probably UNIX-specific.  Check all absolute directories
590 # in the path except for where public executables are supposed to live.
591 # Also skip $mainperl if the user opted to have it be a link to the
592 # installed perl.
593
594 if (!$versiononly && $otherperls) {
595     my ($path, @path);
596     my $dirsep = ($Is_OS2 || $Is_W32 || $Is_NetWare) ? ';' : ':' ;
597     ($path = $ENV{"PATH"}) =~ s:\\:/:g ;
598     @path = split(/$dirsep/, $path);
599     if ($Is_VMS) {
600         my $i = 0;
601         while (exists $ENV{'DCL$PATH' . $i}) {
602             my $dir = unixpath($ENV{'DCL$PATH' . $i});  $dir =~ s-/$--;
603             push(@path,$dir);
604         }
605     }
606     my @otherperls;
607     my %otherperls;
608     for (@path) {
609         next unless m,^/,;
610         # Use &samepath here because some systems have other dirs linked
611         # to $mainperldir (like SunOS)
612         next unless -d;
613         next if samepath($_, $binexp);
614         next if samepath($_, cwd());
615         next if ($mainperl_is_instperl && samepath($_, $mainperldir));
616         my $otherperl = "$_/$perl$exe_ext";
617         next if $otherperls{$otherperl}++;
618         push(@otherperls, $otherperl)
619             if (-x $otherperl && ! -d $otherperl);
620     }
621     if (@otherperls) {
622         warn "\nWarning: $perl appears in your path in the following " .
623             "locations beyond where\nwe just installed it:\n";
624         for (@otherperls) {
625             warn "    ", $_, "\n";
626         }
627         warn "\n";
628     }
629
630 }
631
632 $packlist->write() unless $opts{notify};
633 print "  Installation complete\n" if $opts{verbose};
634
635 exit 0;
636
637 ###############################################################################
638
639 # If these are needed elsewhere, move them into install_lib.pl rather than
640 # copying them.
641
642 sub yn {
643     my($prompt) = @_;
644     my($answer);
645     my($default) = $prompt =~ m/\[([yn])\]\s*$/i;
646     print STDERR $prompt;
647     chop($answer = <STDIN>);
648     $answer = $default if $answer =~ m/^\s*$/;
649     ($answer =~ m/^[yY]/);
650 }
651
652 sub safe_unlink {
653     return if $opts{notify} or $Is_VMS;
654     my @names = @_;
655     foreach my $name (@names) {
656         next unless -e $name;
657         chmod 0777, $name if ($Is_OS2 || $Is_W32 || $Is_NetWare);
658         print "  unlink $name\n" if $opts{verbose};
659         next if CORE::unlink($name);
660         warn "Couldn't unlink $name: $!\n";
661         if ($! =~ /busy/i) {
662             print "  mv $name $name.old\n" if $opts{verbose};
663             safe_rename($name, "$name.old")
664                 or warn "Couldn't rename $name: $!\n";
665         }
666     }
667 }
668
669 sub safe_rename {
670     my($from,$to) = @_;
671     if (-f $to and not unlink($to)) {
672         my($i);
673         for ($i = 1; $i < 50; $i++) {
674             last if rename($to, "$to.$i");
675         }
676         warn("Cannot rename to `$to.$i': $!"), return 0
677            if $i >= 50; # Give up!
678     }
679     link($from,$to) || return 0;
680     unlink($from);
681 }
682
683 sub copy {
684     my($from,$to) = @_;
685
686     my $xto = $to;
687     $xto =~ s/^\Q$opts{destdir}\E//;
688     print $opts{verbose} ? "  cp $from $xto\n" : "  $xto\n"
689         unless $opts{silent};
690     print "  creating new version of $xto\n"
691         if $Is_VMS and -e $to and !$opts{silent};
692     unless ($opts{notify} or File::Copy::copy($from, $to)) {
693         # Might have been that F::C::c can't overwrite the target
694         warn "Couldn't copy $from to $to: $!\n"
695             unless -f $to and (chmod(0666, $to), unlink $to)
696                    and File::Copy::copy($from, $to);
697     }
698     $packlist->{$xto} = { type => 'file' };
699 }
700
701 sub installlib {
702     my $dir = $File::Find::dir;
703     $dir =~ s#^\.(?![^/])/?##;
704     local($depth) = $dir ? "lib/$dir" : "lib";
705
706     my $name = $_;
707
708     # Ignore version control directories.
709     if ($name =~ /^(?:CVS|RCS|SCCS|\.svn)\z/ and -d $name) {
710         $File::Find::prune = 1;
711         return;
712     }
713
714     # ignore patch backups, RCS files, emacs backup & temp files and the
715     # .exists files, .PL files, and test files.
716     return if $name =~ m{\.orig$|\.rej$|~$|^#.+#$|,v$|^\.exists|\.PL$|\.plc$|\.t$|^test\.pl$|^dbm_filter_util.pl$|^\.gitignore$} ||
717               $dir  =~ m{/t(?:/|$)};
718     # ignore the cpan script in lib/CPAN/bin, the instmodsh and xsubpp
719     # scripts in lib/ExtUtils, the prove script in lib/Test/Harness,
720     # the corelist script from lib/Module/CoreList/bin and ptar* in
721     # lib/Archive/Tar/bin, the config_data script in lib/Module/Build/scripts
722     # (they're installed later with other utils)
723     return if $name =~ /^(?:cpan|instmodsh|prove|corelist|ptar|cpan2dist|cpanp|cpanp-run-perl|ptardiff|config_data)\z/;
724     # ignore the Makefiles
725     return if $name =~ /^makefile$/i;
726     # ignore the test extensions
727     return if $dir =~ m{\bXS/(?:APItest|Typemap)\b};
728     return if $name =~ m{\b(?:APItest|Typemap)\.pm$};
729     # ignore the demo files
730     return if $dir =~ /\b(?:demos?|eg)\b/;
731
732     # ignore READMEs, MANIFESTs, INSTALL docs, META.ymls and change logs.
733     # Changes.e2x and README.e2x are needed by enc2xs.
734     return if $name =~ m{^(?:README(?:\.\w+)?)$} && $name ne 'README.e2x';
735     return if $name =~ m{^(?:MANIFEST|META\.yml)$};
736     return if $name =~ m{^(?:INSTALL|TODO|BUGS|CREDITS)$}i;
737     return if $name =~ m{^change(?:s|log)(?:\.libnet)?$}i;
738     return if $name =~ m{^(?:SIGNATURE|PAUSE200\d\.pub)$}; # CPAN files
739     return if $name =~ m{^(?:NOTES|PATCHING)$}; # ExtUtils files
740
741     # if using a shared perl library then ignore:
742     # - static library files [of statically linked extensions];
743     # - import library files and export library files (only present on Win32
744     #   anyway?) and empty bootstrap files [of dynamically linked extensions].
745     return if $Config{useshrplib} eq 'true' and
746              ($name =~ /$Config{_a}$/ or $name =~ /\.exp$/ or ($name =~ /\.bs$/ and -z $name));
747
748     $name = "$dir/$name" if $dir ne '';
749
750     return if $name eq 'ExtUtils/XSSymSet.pm' and !$Is_VMS;
751
752     my $installlib = $installprivlib;
753     if ($dir =~ /^auto\// ||
754           ($name =~ /^(.*)\.(?:pm|pod)$/ && $archpms{$1}) ||
755           ($name =~ /^(.*)\.(?:h|lib)$/i && ($Is_W32 || $Is_NetWare)) ||
756           $name=~/^Config_(heavy|git)\.pl\z/
757        ) {
758         $installlib = $installarchlib;
759         return unless $do_installarchlib;
760     } else {
761         return unless $do_installprivlib;
762     }
763
764     if (-f $_) {
765         if (/\.(?:al|ix)$/ && !($dir =~ m[^auto/(.*)$])) {
766             $installlib = $installprivlib;
767             #We're installing *.al and *.ix files into $installprivlib,
768             #but we have to delete old *.al and *.ix files from the 5.000
769             #distribution:
770             #This might not work because $archname might have changed.
771             unlink("$installarchlib/$name");
772         }
773         my $xname = "$installlib/$name";
774         $xname =~ s/^\Q$opts{destdir}\E//;
775         $packlist->{$xname} = { type => 'file' };
776         if ($force || compare($_, "$installlib/$name") || $opts{notify}) {
777             unlink("$installlib/$name");
778             mkpath("$installlib/$dir", $opts{verbose}, 0777);
779             # HP-UX (at least) needs to maintain execute permissions
780             # on dynamically-loaded libraries.
781             if ($Is_NetWare && !$nwinstall) {
782                 # Don't copy .nlp,.nlm files, doesn't make sense on Windows and also
783                 # if copied will give problems when building new extensions.
784                 # Has to be copied if we are installing on a NetWare server and hence
785                 # the check !$nwinstall
786                 if (!(/\.(?:nlp|nlm|bs)$/)) {
787                     copy_if_diff($_, "$installlib/$name")
788                         and chmod($name =~ /\.(so|$dlext)$/o ? 0555 : 0444,
789                                   "$installlib/$name");
790                 }
791            } else {
792                 if (copy_if_diff($_, "$installlib/$name")) {
793                     if ($name =~ /\.(so|$dlext)$/o) {
794                         strip("-S", "$installlib/$name") if $^O =~ /^(rhapsody|darwin)$/;
795                         chmod(0555, "$installlib/$name");
796                     } else {
797                         strip("-S", "$installlib/$name")
798                             if ($name =~ /\.a$/o and $^O =~ /^(rhapsody|darwin)$/);
799                         chmod(0444, "$installlib/$name");
800                     }
801                 }
802             } #if ($Is_NetWare)
803         }
804     }
805 }
806
807 # Copy $from to $to, only if $from is different than $to.
808 # Also preserve modification times for .a libraries.
809 # On some systems, if you do
810 #   ranlib libperl.a
811 #   cp libperl.a /usr/local/lib/perl5/archlib/CORE/libperl.a
812 # and then try to link against the installed libperl.a, you might
813 # get an error message to the effect that the symbol table is older
814 # than the library.
815 # Return true if copying occurred.
816
817 sub copy_if_diff {
818     my($from,$to)=@_;
819     return 1 if (($^O eq 'VMS') && (-d $from));
820     my $xto = $to;
821     $xto =~ s/^\Q$opts{destdir}\E//;
822     my $perlpodbadsymlink;
823     if ($from =~ m!^pod/perl[\w-]+\.pod$! &&
824         -l $from &&
825         ! -e $from) {
826         # Some Linux implementations have problems traversing over
827         # multiple symlinks (when going over NFS?) and fail to read
828         # the symlink target.  Combine this with the fact that some
829         # of the pod files (the perl$OS.pod) are symlinks (to ../README.$OS),
830         # and you end up with those pods not getting installed.
831         $perlpodbadsymlink = 1;
832     }
833     -f $from || $perlpodbadsymlink || warn "$0: $from not found";
834     $packlist->{$xto} = { type => 'file' };
835     if ($force || compare($from, $to) || $opts{notify}) {
836         safe_unlink($to);   # In case we don't have write permissions.
837         if ($opts{notify}) {
838             $from = $depth . "/" . $from if $depth;
839         }
840         if ($perlpodbadsymlink && $from =~ m!^pod/perl(.+)\.pod$!) {
841             $from = "README.$1";
842         }
843         copy($from, $to);
844         # Restore timestamps if it's a .a library or for OS/2.
845         if (!$opts{notify} && ($Is_OS2 || $to =~ /\.a$/)) {
846             my ($atime, $mtime) = (stat $from)[8,9];
847             utime $atime, $mtime, $to;
848         }
849         1;
850     }
851 }
852
853 sub strip
854 {
855     my(@args) = @_;
856
857     return unless $dostrip;
858
859     my @opts;
860     while (@args && $args[0] =~ /^(-\w+)$/) {
861         push @opts, shift @args;
862     }
863
864     foreach my $file (@args) {
865         if (-f $file) {
866             if ($opts{verbose}) {
867                 print "  strip " . join(' ', @opts);
868                 print " " if (@opts);
869                 print "$file\n";
870             }
871             system("strip", @opts, $file);
872         } else {
873             print "# file '$file' skipped\n" if $opts{verbose};
874         }
875     }
876 }