Deprecate spaces/comments in some regex tokens
[perl.git] / pod / perlre.pod
1 =head1 NAME
2 X<regular expression> X<regex> X<regexp>
3
4 perlre - Perl regular expressions
5
6 =head1 DESCRIPTION
7
8 This page describes the syntax of regular expressions in Perl.
9
10 If you haven't used regular expressions before, a quick-start
11 introduction is available in L<perlrequick>, and a longer tutorial
12 introduction is available in L<perlretut>.
13
14 For reference on how regular expressions are used in matching
15 operations, plus various examples of the same, see discussions of
16 C<m//>, C<s///>, C<qr//> and C<??> in L<perlop/"Regexp Quote-Like
17 Operators">.
18
19
20 =head2 Modifiers
21
22 Matching operations can have various modifiers.  Modifiers
23 that relate to the interpretation of the regular expression inside
24 are listed below.  Modifiers that alter the way a regular expression
25 is used by Perl are detailed in L<perlop/"Regexp Quote-Like Operators"> and
26 L<perlop/"Gory details of parsing quoted constructs">.
27
28 =over 4
29
30 =item m
31 X</m> X<regex, multiline> X<regexp, multiline> X<regular expression, multiline>
32
33 Treat string as multiple lines.  That is, change "^" and "$" from matching
34 the start or end of line only at the left and right ends of the string to
35 matching them anywhere within the string.
36
37 =item s
38 X</s> X<regex, single-line> X<regexp, single-line>
39 X<regular expression, single-line>
40
41 Treat string as single line.  That is, change "." to match any character
42 whatsoever, even a newline, which normally it would not match.
43
44 Used together, as C</ms>, they let the "." match any character whatsoever,
45 while still allowing "^" and "$" to match, respectively, just after
46 and just before newlines within the string.
47
48 =item i
49 X</i> X<regex, case-insensitive> X<regexp, case-insensitive>
50 X<regular expression, case-insensitive>
51
52 Do case-insensitive pattern matching.
53
54 If locale matching rules are in effect, the case map is taken from the
55 current
56 locale for code points less than 255, and from Unicode rules for larger
57 code points.  However, matches that would cross the Unicode
58 rules/non-Unicode rules boundary (ords 255/256) will not succeed.  See
59 L<perllocale>.
60
61 There are a number of Unicode characters that match multiple characters
62 under C</i>.  For example, C<LATIN SMALL LIGATURE FI>
63 should match the sequence C<fi>.  Perl is not
64 currently able to do this when the multiple characters are in the pattern and
65 are split between groupings, or when one or more are quantified.  Thus
66
67  "\N{LATIN SMALL LIGATURE FI}" =~ /fi/i;          # Matches
68  "\N{LATIN SMALL LIGATURE FI}" =~ /[fi][fi]/i;    # Doesn't match!
69  "\N{LATIN SMALL LIGATURE FI}" =~ /fi*/i;         # Doesn't match!
70
71  # The below doesn't match, and it isn't clear what $1 and $2 would
72  # be even if it did!!
73  "\N{LATIN SMALL LIGATURE FI}" =~ /(f)(i)/i;      # Doesn't match!
74
75 Perl doesn't match multiple characters in a bracketed
76 character class unless the character that maps to them is explicitly
77 mentioned, and it doesn't match them at all if the character class is
78 inverted, which otherwise could be highly confusing.  See
79 L<perlrecharclass/Bracketed Character Classes>, and
80 L<perlrecharclass/Negation>.
81
82 =item x
83 X</x>
84
85 Extend your pattern's legibility by permitting whitespace and comments.
86 Details in L</"/x">
87
88 =item p
89 X</p> X<regex, preserve> X<regexp, preserve>
90
91 Preserve the string matched such that ${^PREMATCH}, ${^MATCH}, and
92 ${^POSTMATCH} are available for use after matching.
93
94 In Perl 5.18 and higher this is ignored.  ${^PREMATCH}, ${^MATCH}, and
95 ${^POSTMATCH} will be available after the match regardless of the modifier.
96
97 =item g and c
98 X</g> X</c>
99
100 Global matching, and keep the Current position after failed matching.
101 Unlike i, m, s and x, these two flags affect the way the regex is used
102 rather than the regex itself. See
103 L<perlretut/"Using regular expressions in Perl"> for further explanation
104 of the g and c modifiers.
105
106 =item a, d, l and u
107 X</a> X</d> X</l> X</u>
108
109 These modifiers, all new in 5.14, affect which character-set semantics
110 (Unicode, etc.) are used, as described below in
111 L</Character set modifiers>.
112
113 =back
114
115 Regular expression modifiers are usually written in documentation
116 as e.g., "the C</x> modifier", even though the delimiter
117 in question might not really be a slash.  The modifiers C</imsxadlup>
118 may also be embedded within the regular expression itself using
119 the C<(?...)> construct, see L</Extended Patterns> below.
120
121 =head3 /x
122
123 C</x> tells
124 the regular expression parser to ignore most whitespace that is neither
125 backslashed nor within a character class.  You can use this to break up
126 your regular expression into (slightly) more readable parts.  The C<#>
127 character is also treated as a metacharacter introducing a comment,
128 just as in ordinary Perl code.  This also means that if you want real
129 whitespace or C<#> characters in the pattern (outside a character
130 class, where they are unaffected by C</x>), then you'll either have to
131 escape them (using backslashes or C<\Q...\E>) or encode them using octal,
132 hex, or C<\N{}> escapes.  Taken together, these features go a long way towards
133 making Perl's regular expressions more readable.  Note that you have to
134 be careful not to include the pattern delimiter in the comment--perl has
135 no way of knowing you did not intend to close the pattern early.  See
136 the C-comment deletion code in L<perlop>.  Also note that anything inside
137 a C<\Q...\E> stays unaffected by C</x>.  And note that C</x> doesn't affect
138 space interpretation within a single multi-character construct.  For
139 example in C<\x{...}>, regardless of the C</x> modifier, there can be no
140 spaces.  Same for a L<quantifier|/Quantifiers> such as C<{3}> or
141 C<{5,}>.  Similarly, C<(?:...)> can't have a space between the C<(>,
142 C<?>, and C<:>.  Within any delimiters for such a
143 construct, allowed spaces are not affected by C</x>, and depend on the
144 construct.  For example, C<\x{...}> can't have spaces because hexadecimal
145 numbers don't have spaces in them.  But, Unicode properties can have spaces, so
146 in C<\p{...}> there can be spaces that follow the Unicode rules, for which see
147 L<perluniprops/Properties accessible through \p{} and \P{}>.
148 X</x>
149
150 =head3 Character set modifiers
151
152 C</d>, C</u>, C</a>, and C</l>, available starting in 5.14, are called
153 the character set modifiers; they affect the character set semantics
154 used for the regular expression.
155
156 The C</d>, C</u>, and C</l> modifiers are not likely to be of much use
157 to you, and so you need not worry about them very much.  They exist for
158 Perl's internal use, so that complex regular expression data structures
159 can be automatically serialized and later exactly reconstituted,
160 including all their nuances.  But, since Perl can't keep a secret, and
161 there may be rare instances where they are useful, they are documented
162 here.
163
164 The C</a> modifier, on the other hand, may be useful.  Its purpose is to
165 allow code that is to work mostly on ASCII data to not have to concern
166 itself with Unicode.
167
168 Briefly, C</l> sets the character set to that of whatever B<L>ocale is in
169 effect at the time of the execution of the pattern match.
170
171 C</u> sets the character set to B<U>nicode.
172
173 C</a> also sets the character set to Unicode, BUT adds several
174 restrictions for B<A>SCII-safe matching.
175
176 C</d> is the old, problematic, pre-5.14 B<D>efault character set
177 behavior.  Its only use is to force that old behavior.
178
179 At any given time, exactly one of these modifiers is in effect.  Their
180 existence allows Perl to keep the originally compiled behavior of a
181 regular expression, regardless of what rules are in effect when it is
182 actually executed.  And if it is interpolated into a larger regex, the
183 original's rules continue to apply to it, and only it.
184
185 The C</l> and C</u> modifiers are automatically selected for
186 regular expressions compiled within the scope of various pragmas,
187 and we recommend that in general, you use those pragmas instead of
188 specifying these modifiers explicitly.  For one thing, the modifiers
189 affect only pattern matching, and do not extend to even any replacement
190 done, whereas using the pragmas give consistent results for all
191 appropriate operations within their scopes.  For example,
192
193  s/foo/\Ubar/il
194
195 will match "foo" using the locale's rules for case-insensitive matching,
196 but the C</l> does not affect how the C<\U> operates.  Most likely you
197 want both of them to use locale rules.  To do this, instead compile the
198 regular expression within the scope of C<use locale>.  This both
199 implicitly adds the C</l> and applies locale rules to the C<\U>.   The
200 lesson is to C<use locale> and not C</l> explicitly.
201
202 Similarly, it would be better to use C<use feature 'unicode_strings'>
203 instead of,
204
205  s/foo/\Lbar/iu
206
207 to get Unicode rules, as the C<\L> in the former (but not necessarily
208 the latter) would also use Unicode rules.
209
210 More detail on each of the modifiers follows.  Most likely you don't
211 need to know this detail for C</l>, C</u>, and C</d>, and can skip ahead
212 to L<E<sol>a|/E<sol>a (and E<sol>aa)>.
213
214 =head4 /l
215
216 means to use the current locale's rules (see L<perllocale>) when pattern
217 matching.  For example, C<\w> will match the "word" characters of that
218 locale, and C<"/i"> case-insensitive matching will match according to
219 the locale's case folding rules.  The locale used will be the one in
220 effect at the time of execution of the pattern match.  This may not be
221 the same as the compilation-time locale, and can differ from one match
222 to another if there is an intervening call of the
223 L<setlocale() function|perllocale/The setlocale function>.
224
225 Perl only supports single-byte locales.  This means that code points
226 above 255 are treated as Unicode no matter what locale is in effect.
227 Under Unicode rules, there are a few case-insensitive matches that cross
228 the 255/256 boundary.  These are disallowed under C</l>.  For example,
229 0xFF (on ASCII platforms) does not caselessly match the character at
230 0x178, C<LATIN CAPITAL LETTER Y WITH DIAERESIS>, because 0xFF may not be
231 C<LATIN SMALL LETTER Y WITH DIAERESIS> in the current locale, and Perl
232 has no way of knowing if that character even exists in the locale, much
233 less what code point it is.
234
235 This modifier may be specified to be the default by C<use locale>, but
236 see L</Which character set modifier is in effect?>.
237 X</l>
238
239 =head4 /u
240
241 means to use Unicode rules when pattern matching.  On ASCII platforms,
242 this means that the code points between 128 and 255 take on their
243 Latin-1 (ISO-8859-1) meanings (which are the same as Unicode's).
244 (Otherwise Perl considers their meanings to be undefined.)  Thus,
245 under this modifier, the ASCII platform effectively becomes a Unicode
246 platform; and hence, for example, C<\w> will match any of the more than
247 100_000 word characters in Unicode.
248
249 Unlike most locales, which are specific to a language and country pair,
250 Unicode classifies all the characters that are letters I<somewhere> in
251 the world as
252 C<\w>.  For example, your locale might not think that C<LATIN SMALL
253 LETTER ETH> is a letter (unless you happen to speak Icelandic), but
254 Unicode does.  Similarly, all the characters that are decimal digits
255 somewhere in the world will match C<\d>; this is hundreds, not 10,
256 possible matches.  And some of those digits look like some of the 10
257 ASCII digits, but mean a different number, so a human could easily think
258 a number is a different quantity than it really is.  For example,
259 C<BENGALI DIGIT FOUR> (U+09EA) looks very much like an
260 C<ASCII DIGIT EIGHT> (U+0038).  And, C<\d+>, may match strings of digits
261 that are a mixture from different writing systems, creating a security
262 issue.  L<Unicode::UCD/num()> can be used to sort
263 this out.  Or the C</a> modifier can be used to force C<\d> to match
264 just the ASCII 0 through 9.
265
266 Also, under this modifier, case-insensitive matching works on the full
267 set of Unicode
268 characters.  The C<KELVIN SIGN>, for example matches the letters "k" and
269 "K"; and C<LATIN SMALL LIGATURE FF> matches the sequence "ff", which,
270 if you're not prepared, might make it look like a hexadecimal constant,
271 presenting another potential security issue.  See
272 L<http://unicode.org/reports/tr36> for a detailed discussion of Unicode
273 security issues.
274
275 This modifier may be specified to be the default by C<use feature
276 'unicode_strings>, C<use locale ':not_characters'>, or
277 C<L<use 5.012|perlfunc/use VERSION>> (or higher),
278 but see L</Which character set modifier is in effect?>.
279 X</u>
280
281 =head4 /d
282
283 This modifier means to use the "Default" native rules of the platform
284 except when there is cause to use Unicode rules instead, as follows:
285
286 =over 4
287
288 =item 1
289
290 the target string is encoded in UTF-8; or
291
292 =item 2
293
294 the pattern is encoded in UTF-8; or
295
296 =item 3
297
298 the pattern explicitly mentions a code point that is above 255 (say by
299 C<\x{100}>); or
300
301 =item 4
302
303 the pattern uses a Unicode name (C<\N{...}>);  or
304
305 =item 5
306
307 the pattern uses a Unicode property (C<\p{...}>); or
308
309 =item 6
310
311 the pattern uses L</C<(?[ ])>>
312
313 =back
314
315 Another mnemonic for this modifier is "Depends", as the rules actually
316 used depend on various things, and as a result you can get unexpected
317 results.  See L<perlunicode/The "Unicode Bug">.  The Unicode Bug has
318 become rather infamous, leading to yet another (printable) name for this
319 modifier, "Dodgy".
320
321 Unless the pattern or string are encoded in UTF-8, only ASCII characters
322 can match positively.
323
324 Here are some examples of how that works on an ASCII platform:
325
326  $str =  "\xDF";      # $str is not in UTF-8 format.
327  $str =~ /^\w/;       # No match, as $str isn't in UTF-8 format.
328  $str .= "\x{0e0b}";  # Now $str is in UTF-8 format.
329  $str =~ /^\w/;       # Match! $str is now in UTF-8 format.
330  chop $str;
331  $str =~ /^\w/;       # Still a match! $str remains in UTF-8 format.
332
333 This modifier is automatically selected by default when none of the
334 others are, so yet another name for it is "Default".
335
336 Because of the unexpected behaviors associated with this modifier, you
337 probably should only use it to maintain weird backward compatibilities.
338
339 =head4 /a (and /aa)
340
341 This modifier stands for ASCII-restrict (or ASCII-safe).  This modifier,
342 unlike the others, may be doubled-up to increase its effect.
343
344 When it appears singly, it causes the sequences C<\d>, C<\s>, C<\w>, and
345 the Posix character classes to match only in the ASCII range.  They thus
346 revert to their pre-5.6, pre-Unicode meanings.  Under C</a>,  C<\d>
347 always means precisely the digits C<"0"> to C<"9">; C<\s> means the five
348 characters C<[ \f\n\r\t]>, and starting in Perl v5.18, experimentally,
349 the vertical tab; C<\w> means the 63 characters
350 C<[A-Za-z0-9_]>; and likewise, all the Posix classes such as
351 C<[[:print:]]> match only the appropriate ASCII-range characters.
352
353 This modifier is useful for people who only incidentally use Unicode,
354 and who do not wish to be burdened with its complexities and security
355 concerns.
356
357 With C</a>, one can write C<\d> with confidence that it will only match
358 ASCII characters, and should the need arise to match beyond ASCII, you
359 can instead use C<\p{Digit}> (or C<\p{Word}> for C<\w>).  There are
360 similar C<\p{...}> constructs that can match beyond ASCII both white
361 space (see L<perlrecharclass/Whitespace>), and Posix classes (see
362 L<perlrecharclass/POSIX Character Classes>).  Thus, this modifier
363 doesn't mean you can't use Unicode, it means that to get Unicode
364 matching you must explicitly use a construct (C<\p{}>, C<\P{}>) that
365 signals Unicode.
366
367 As you would expect, this modifier causes, for example, C<\D> to mean
368 the same thing as C<[^0-9]>; in fact, all non-ASCII characters match
369 C<\D>, C<\S>, and C<\W>.  C<\b> still means to match at the boundary
370 between C<\w> and C<\W>, using the C</a> definitions of them (similarly
371 for C<\B>).
372
373 Otherwise, C</a> behaves like the C</u> modifier, in that
374 case-insensitive matching uses Unicode semantics; for example, "k" will
375 match the Unicode C<\N{KELVIN SIGN}> under C</i> matching, and code
376 points in the Latin1 range, above ASCII will have Unicode rules when it
377 comes to case-insensitive matching.
378
379 To forbid ASCII/non-ASCII matches (like "k" with C<\N{KELVIN SIGN}>),
380 specify the "a" twice, for example C</aai> or C</aia>.  (The first
381 occurrence of "a" restricts the C<\d>, etc., and the second occurrence
382 adds the C</i> restrictions.)  But, note that code points outside the
383 ASCII range will use Unicode rules for C</i> matching, so the modifier
384 doesn't really restrict things to just ASCII; it just forbids the
385 intermixing of ASCII and non-ASCII.
386
387 To summarize, this modifier provides protection for applications that
388 don't wish to be exposed to all of Unicode.  Specifying it twice
389 gives added protection.
390
391 This modifier may be specified to be the default by C<use re '/a'>
392 or C<use re '/aa'>.  If you do so, you may actually have occasion to use
393 the C</u> modifier explictly if there are a few regular expressions
394 where you do want full Unicode rules (but even here, it's best if
395 everything were under feature C<"unicode_strings">, along with the
396 C<use re '/aa'>).  Also see L</Which character set modifier is in
397 effect?>.
398 X</a>
399 X</aa>
400
401 =head4 Which character set modifier is in effect?
402
403 Which of these modifiers is in effect at any given point in a regular
404 expression depends on a fairly complex set of interactions.  These have
405 been designed so that in general you don't have to worry about it, but
406 this section gives the gory details.  As
407 explained below in L</Extended Patterns> it is possible to explicitly
408 specify modifiers that apply only to portions of a regular expression.
409 The innermost always has priority over any outer ones, and one applying
410 to the whole expression has priority over any of the default settings that are
411 described in the remainder of this section.
412
413 The C<L<use re 'E<sol>foo'|re/"'/flags' mode">> pragma can be used to set
414 default modifiers (including these) for regular expressions compiled
415 within its scope.  This pragma has precedence over the other pragmas
416 listed below that also change the defaults.
417
418 Otherwise, C<L<use locale|perllocale>> sets the default modifier to C</l>;
419 and C<L<use feature 'unicode_strings|feature>>, or
420 C<L<use 5.012|perlfunc/use VERSION>> (or higher) set the default to
421 C</u> when not in the same scope as either C<L<use locale|perllocale>>
422 or C<L<use bytes|bytes>>.
423 (C<L<use locale ':not_characters'|perllocale/Unicode and UTF-8>> also
424 sets the default to C</u>, overriding any plain C<use locale>.)
425 Unlike the mechanisms mentioned above, these
426 affect operations besides regular expressions pattern matching, and so
427 give more consistent results with other operators, including using
428 C<\U>, C<\l>, etc. in substitution replacements.
429
430 If none of the above apply, for backwards compatibility reasons, the
431 C</d> modifier is the one in effect by default.  As this can lead to
432 unexpected results, it is best to specify which other rule set should be
433 used.
434
435 =head4 Character set modifier behavior prior to Perl 5.14
436
437 Prior to 5.14, there were no explicit modifiers, but C</l> was implied
438 for regexes compiled within the scope of C<use locale>, and C</d> was
439 implied otherwise.  However, interpolating a regex into a larger regex
440 would ignore the original compilation in favor of whatever was in effect
441 at the time of the second compilation.  There were a number of
442 inconsistencies (bugs) with the C</d> modifier, where Unicode rules
443 would be used when inappropriate, and vice versa.  C<\p{}> did not imply
444 Unicode rules, and neither did all occurrences of C<\N{}>, until 5.12.
445
446 =head2 Regular Expressions
447
448 =head3 Metacharacters
449
450 The patterns used in Perl pattern matching evolved from those supplied in
451 the Version 8 regex routines.  (The routines are derived
452 (distantly) from Henry Spencer's freely redistributable reimplementation
453 of the V8 routines.)  See L<Version 8 Regular Expressions> for
454 details.
455
456 In particular the following metacharacters have their standard I<egrep>-ish
457 meanings:
458 X<metacharacter>
459 X<\> X<^> X<.> X<$> X<|> X<(> X<()> X<[> X<[]>
460
461
462     \        Quote the next metacharacter
463     ^        Match the beginning of the line
464     .        Match any character (except newline)
465     $        Match the end of the line (or before newline at the end)
466     |        Alternation
467     ()       Grouping
468     []       Bracketed Character class
469
470 By default, the "^" character is guaranteed to match only the
471 beginning of the string, the "$" character only the end (or before the
472 newline at the end), and Perl does certain optimizations with the
473 assumption that the string contains only one line.  Embedded newlines
474 will not be matched by "^" or "$".  You may, however, wish to treat a
475 string as a multi-line buffer, such that the "^" will match after any
476 newline within the string (except if the newline is the last character in
477 the string), and "$" will match before any newline.  At the
478 cost of a little more overhead, you can do this by using the /m modifier
479 on the pattern match operator.  (Older programs did this by setting C<$*>,
480 but this option was removed in perl 5.10.)
481 X<^> X<$> X</m>
482
483 To simplify multi-line substitutions, the "." character never matches a
484 newline unless you use the C</s> modifier, which in effect tells Perl to pretend
485 the string is a single line--even if it isn't.
486 X<.> X</s>
487
488 =head3 Quantifiers
489
490 The following standard quantifiers are recognized:
491 X<metacharacter> X<quantifier> X<*> X<+> X<?> X<{n}> X<{n,}> X<{n,m}>
492
493     *           Match 0 or more times
494     +           Match 1 or more times
495     ?           Match 1 or 0 times
496     {n}         Match exactly n times
497     {n,}        Match at least n times
498     {n,m}       Match at least n but not more than m times
499
500 (If a curly bracket occurs in any other context and does not form part of
501 a backslashed sequence like C<\x{...}>, it is treated as a regular
502 character.  In particular, the lower quantifier bound is not optional,
503 and a typo in a quantifier silently causes it to be treated as the
504 literal characters.  For example,
505
506     /o{4,3}/
507
508 looks like a quantifier that matches 0 times, since 4 is greater than 3,
509 but it really means to match the sequence of six characters
510 S<C<"o { 4 , 3 }">>.  It is planned to eventually require literal uses
511 of curly brackets to be escaped, say by preceding them with a backslash
512 or enclosing them within square brackets, (C<"\{"> or C<"[{]">).  This
513 change will allow for future syntax extensions (like making the lower
514 bound of a quantifier optional), and better error checking.  In the
515 meantime, you should get in the habit of escaping all instances where
516 you mean a literal "{".)
517
518 The "*" quantifier is equivalent to C<{0,}>, the "+"
519 quantifier to C<{1,}>, and the "?" quantifier to C<{0,1}>.  n and m are limited
520 to non-negative integral values less than a preset limit defined when perl is built.
521 This is usually 32766 on the most common platforms.  The actual limit can
522 be seen in the error message generated by code such as this:
523
524     $_ **= $_ , / {$_} / for 2 .. 42;
525
526 By default, a quantified subpattern is "greedy", that is, it will match as
527 many times as possible (given a particular starting location) while still
528 allowing the rest of the pattern to match.  If you want it to match the
529 minimum number of times possible, follow the quantifier with a "?".  Note
530 that the meanings don't change, just the "greediness":
531 X<metacharacter> X<greedy> X<greediness>
532 X<?> X<*?> X<+?> X<??> X<{n}?> X<{n,}?> X<{n,m}?>
533
534     *?        Match 0 or more times, not greedily
535     +?        Match 1 or more times, not greedily
536     ??        Match 0 or 1 time, not greedily
537     {n}?      Match exactly n times, not greedily (redundant)
538     {n,}?     Match at least n times, not greedily
539     {n,m}?    Match at least n but not more than m times, not greedily
540
541 By default, when a quantified subpattern does not allow the rest of the
542 overall pattern to match, Perl will backtrack. However, this behaviour is
543 sometimes undesirable. Thus Perl provides the "possessive" quantifier form
544 as well.
545
546  *+     Match 0 or more times and give nothing back
547  ++     Match 1 or more times and give nothing back
548  ?+     Match 0 or 1 time and give nothing back
549  {n}+   Match exactly n times and give nothing back (redundant)
550  {n,}+  Match at least n times and give nothing back
551  {n,m}+ Match at least n but not more than m times and give nothing back
552
553 For instance,
554
555    'aaaa' =~ /a++a/
556
557 will never match, as the C<a++> will gobble up all the C<a>'s in the
558 string and won't leave any for the remaining part of the pattern. This
559 feature can be extremely useful to give perl hints about where it
560 shouldn't backtrack. For instance, the typical "match a double-quoted
561 string" problem can be most efficiently performed when written as:
562
563    /"(?:[^"\\]++|\\.)*+"/
564
565 as we know that if the final quote does not match, backtracking will not
566 help. See the independent subexpression
567 L</C<< (?>pattern) >>> for more details;
568 possessive quantifiers are just syntactic sugar for that construct. For
569 instance the above example could also be written as follows:
570
571    /"(?>(?:(?>[^"\\]+)|\\.)*)"/
572
573 =head3 Escape sequences
574
575 Because patterns are processed as double-quoted strings, the following
576 also work:
577
578  \t          tab                   (HT, TAB)
579  \n          newline               (LF, NL)
580  \r          return                (CR)
581  \f          form feed             (FF)
582  \a          alarm (bell)          (BEL)
583  \e          escape (think troff)  (ESC)
584  \cK         control char          (example: VT)
585  \x{}, \x00  character whose ordinal is the given hexadecimal number
586  \N{name}    named Unicode character or character sequence
587  \N{U+263D}  Unicode character     (example: FIRST QUARTER MOON)
588  \o{}, \000  character whose ordinal is the given octal number
589  \l          lowercase next char (think vi)
590  \u          uppercase next char (think vi)
591  \L          lowercase till \E (think vi)
592  \U          uppercase till \E (think vi)
593  \Q          quote (disable) pattern metacharacters till \E
594  \E          end either case modification or quoted section, think vi
595
596 Details are in L<perlop/Quote and Quote-like Operators>.
597
598 =head3 Character Classes and other Special Escapes
599
600 In addition, Perl defines the following:
601 X<\g> X<\k> X<\K> X<backreference>
602
603  Sequence   Note    Description
604   [...]     [1]  Match a character according to the rules of the
605                    bracketed character class defined by the "...".
606                    Example: [a-z] matches "a" or "b" or "c" ... or "z"
607   [[:...:]] [2]  Match a character according to the rules of the POSIX
608                    character class "..." within the outer bracketed
609                    character class.  Example: [[:upper:]] matches any
610                    uppercase character.
611   (?[...])  [8]  Extended bracketed character class
612   \w        [3]  Match a "word" character (alphanumeric plus "_", plus
613                    other connector punctuation chars plus Unicode
614                    marks)
615   \W        [3]  Match a non-"word" character
616   \s        [3]  Match a whitespace character
617   \S        [3]  Match a non-whitespace character
618   \d        [3]  Match a decimal digit character
619   \D        [3]  Match a non-digit character
620   \pP       [3]  Match P, named property.  Use \p{Prop} for longer names
621   \PP       [3]  Match non-P
622   \X        [4]  Match Unicode "eXtended grapheme cluster"
623   \C             Match a single C-language char (octet) even if that is
624                    part of a larger UTF-8 character.  Thus it breaks up
625                    characters into their UTF-8 bytes, so you may end up
626                    with malformed pieces of UTF-8.  Unsupported in
627                    lookbehind.
628   \1        [5]  Backreference to a specific capture group or buffer.
629                    '1' may actually be any positive integer.
630   \g1       [5]  Backreference to a specific or previous group,
631   \g{-1}    [5]  The number may be negative indicating a relative
632                    previous group and may optionally be wrapped in
633                    curly brackets for safer parsing.
634   \g{name}  [5]  Named backreference
635   \k<name>  [5]  Named backreference
636   \K        [6]  Keep the stuff left of the \K, don't include it in $&
637   \N        [7]  Any character but \n.  Not affected by /s modifier
638   \v        [3]  Vertical whitespace
639   \V        [3]  Not vertical whitespace
640   \h        [3]  Horizontal whitespace
641   \H        [3]  Not horizontal whitespace
642   \R        [4]  Linebreak
643
644 =over 4
645
646 =item [1]
647
648 See L<perlrecharclass/Bracketed Character Classes> for details.
649
650 =item [2]
651
652 See L<perlrecharclass/POSIX Character Classes> for details.
653
654 =item [3]
655
656 See L<perlrecharclass/Backslash sequences> for details.
657
658 =item [4]
659
660 See L<perlrebackslash/Misc> for details.
661
662 =item [5]
663
664 See L</Capture groups> below for details.
665
666 =item [6]
667
668 See L</Extended Patterns> below for details.
669
670 =item [7]
671
672 Note that C<\N> has two meanings.  When of the form C<\N{NAME}>, it matches the
673 character or character sequence whose name is C<NAME>; and similarly
674 when of the form C<\N{U+I<hex>}>, it matches the character whose Unicode
675 code point is I<hex>.  Otherwise it matches any character but C<\n>.
676
677 =item [8]
678
679 See L<perlrecharclass/Extended Bracketed Character Classes> for details.
680
681 =back
682
683 =head3 Assertions
684
685 Perl defines the following zero-width assertions:
686 X<zero-width assertion> X<assertion> X<regex, zero-width assertion>
687 X<regexp, zero-width assertion>
688 X<regular expression, zero-width assertion>
689 X<\b> X<\B> X<\A> X<\Z> X<\z> X<\G>
690
691     \b  Match a word boundary
692     \B  Match except at a word boundary
693     \A  Match only at beginning of string
694     \Z  Match only at end of string, or before newline at the end
695     \z  Match only at end of string
696     \G  Match only at pos() (e.g. at the end-of-match position
697         of prior m//g)
698
699 A word boundary (C<\b>) is a spot between two characters
700 that has a C<\w> on one side of it and a C<\W> on the other side
701 of it (in either order), counting the imaginary characters off the
702 beginning and end of the string as matching a C<\W>.  (Within
703 character classes C<\b> represents backspace rather than a word
704 boundary, just as it normally does in any double-quoted string.)
705 The C<\A> and C<\Z> are just like "^" and "$", except that they
706 won't match multiple times when the C</m> modifier is used, while
707 "^" and "$" will match at every internal line boundary.  To match
708 the actual end of the string and not ignore an optional trailing
709 newline, use C<\z>.
710 X<\b> X<\A> X<\Z> X<\z> X</m>
711
712 The C<\G> assertion can be used to chain global matches (using
713 C<m//g>), as described in L<perlop/"Regexp Quote-Like Operators">.
714 It is also useful when writing C<lex>-like scanners, when you have
715 several patterns that you want to match against consequent substrings
716 of your string; see the previous reference.  The actual location
717 where C<\G> will match can also be influenced by using C<pos()> as
718 an lvalue: see L<perlfunc/pos>. Note that the rule for zero-length
719 matches (see L</"Repeated Patterns Matching a Zero-length Substring">)
720 is modified somewhat, in that contents to the left of C<\G> are
721 not counted when determining the length of the match. Thus the following
722 will not match forever:
723 X<\G>
724
725      my $string = 'ABC';
726      pos($string) = 1;
727      while ($string =~ /(.\G)/g) {
728          print $1;
729      }
730
731 It will print 'A' and then terminate, as it considers the match to
732 be zero-width, and thus will not match at the same position twice in a
733 row.
734
735 It is worth noting that C<\G> improperly used can result in an infinite
736 loop. Take care when using patterns that include C<\G> in an alternation.
737
738 =head3 Capture groups
739
740 The bracketing construct C<( ... )> creates capture groups (also referred to as
741 capture buffers). To refer to the current contents of a group later on, within
742 the same pattern, use C<\g1> (or C<\g{1}>) for the first, C<\g2> (or C<\g{2}>)
743 for the second, and so on.
744 This is called a I<backreference>.
745 X<regex, capture buffer> X<regexp, capture buffer>
746 X<regex, capture group> X<regexp, capture group>
747 X<regular expression, capture buffer> X<backreference>
748 X<regular expression, capture group> X<backreference>
749 X<\g{1}> X<\g{-1}> X<\g{name}> X<relative backreference> X<named backreference>
750 X<named capture buffer> X<regular expression, named capture buffer>
751 X<named capture group> X<regular expression, named capture group>
752 X<%+> X<$+{name}> X<< \k<name> >>
753 There is no limit to the number of captured substrings that you may use.
754 Groups are numbered with the leftmost open parenthesis being number 1, etc.  If
755 a group did not match, the associated backreference won't match either. (This
756 can happen if the group is optional, or in a different branch of an
757 alternation.)
758 You can omit the C<"g">, and write C<"\1">, etc, but there are some issues with
759 this form, described below.
760
761 You can also refer to capture groups relatively, by using a negative number, so
762 that C<\g-1> and C<\g{-1}> both refer to the immediately preceding capture
763 group, and C<\g-2> and C<\g{-2}> both refer to the group before it.  For
764 example:
765
766         /
767          (Y)            # group 1
768          (              # group 2
769             (X)         # group 3
770             \g{-1}      # backref to group 3
771             \g{-3}      # backref to group 1
772          )
773         /x
774
775 would match the same as C</(Y) ( (X) \g3 \g1 )/x>.  This allows you to
776 interpolate regexes into larger regexes and not have to worry about the
777 capture groups being renumbered.
778
779 You can dispense with numbers altogether and create named capture groups.
780 The notation is C<(?E<lt>I<name>E<gt>...)> to declare and C<\g{I<name>}> to
781 reference.  (To be compatible with .Net regular expressions, C<\g{I<name>}> may
782 also be written as C<\k{I<name>}>, C<\kE<lt>I<name>E<gt>> or C<\k'I<name>'>.)
783 I<name> must not begin with a number, nor contain hyphens.
784 When different groups within the same pattern have the same name, any reference
785 to that name assumes the leftmost defined group.  Named groups count in
786 absolute and relative numbering, and so can also be referred to by those
787 numbers.
788 (It's possible to do things with named capture groups that would otherwise
789 require C<(??{})>.)
790
791 Capture group contents are dynamically scoped and available to you outside the
792 pattern until the end of the enclosing block or until the next successful
793 match, whichever comes first.  (See L<perlsyn/"Compound Statements">.)
794 You can refer to them by absolute number (using C<"$1"> instead of C<"\g1">,
795 etc); or by name via the C<%+> hash, using C<"$+{I<name>}">.
796
797 Braces are required in referring to named capture groups, but are optional for
798 absolute or relative numbered ones.  Braces are safer when creating a regex by
799 concatenating smaller strings.  For example if you have C<qr/$a$b/>, and C<$a>
800 contained C<"\g1">, and C<$b> contained C<"37">, you would get C</\g137/> which
801 is probably not what you intended.
802
803 The C<\g> and C<\k> notations were introduced in Perl 5.10.0.  Prior to that
804 there were no named nor relative numbered capture groups.  Absolute numbered
805 groups were referred to using C<\1>,
806 C<\2>, etc., and this notation is still
807 accepted (and likely always will be).  But it leads to some ambiguities if
808 there are more than 9 capture groups, as C<\10> could mean either the tenth
809 capture group, or the character whose ordinal in octal is 010 (a backspace in
810 ASCII).  Perl resolves this ambiguity by interpreting C<\10> as a backreference
811 only if at least 10 left parentheses have opened before it.  Likewise C<\11> is
812 a backreference only if at least 11 left parentheses have opened before it.
813 And so on.  C<\1> through C<\9> are always interpreted as backreferences.
814 There are several examples below that illustrate these perils.  You can avoid
815 the ambiguity by always using C<\g{}> or C<\g> if you mean capturing groups;
816 and for octal constants always using C<\o{}>, or for C<\077> and below, using 3
817 digits padded with leading zeros, since a leading zero implies an octal
818 constant.
819
820 The C<\I<digit>> notation also works in certain circumstances outside
821 the pattern.  See L</Warning on \1 Instead of $1> below for details.
822
823 Examples:
824
825     s/^([^ ]*) *([^ ]*)/$2 $1/;     # swap first two words
826
827     /(.)\g1/                        # find first doubled char
828          and print "'$1' is the first doubled character\n";
829
830     /(?<char>.)\k<char>/            # ... a different way
831          and print "'$+{char}' is the first doubled character\n";
832
833     /(?'char'.)\g1/                 # ... mix and match
834          and print "'$1' is the first doubled character\n";
835
836     if (/Time: (..):(..):(..)/) {   # parse out values
837         $hours = $1;
838         $minutes = $2;
839         $seconds = $3;
840     }
841
842     /(.)(.)(.)(.)(.)(.)(.)(.)(.)\g10/   # \g10 is a backreference
843     /(.)(.)(.)(.)(.)(.)(.)(.)(.)\10/    # \10 is octal
844     /((.)(.)(.)(.)(.)(.)(.)(.)(.))\10/  # \10 is a backreference
845     /((.)(.)(.)(.)(.)(.)(.)(.)(.))\010/ # \010 is octal
846
847     $a = '(.)\1';        # Creates problems when concatenated.
848     $b = '(.)\g{1}';     # Avoids the problems.
849     "aa" =~ /${a}/;      # True
850     "aa" =~ /${b}/;      # True
851     "aa0" =~ /${a}0/;    # False!
852     "aa0" =~ /${b}0/;    # True
853     "aa\x08" =~ /${a}0/;  # True!
854     "aa\x08" =~ /${b}0/;  # False
855
856 Several special variables also refer back to portions of the previous
857 match.  C<$+> returns whatever the last bracket match matched.
858 C<$&> returns the entire matched string.  (At one point C<$0> did
859 also, but now it returns the name of the program.)  C<$`> returns
860 everything before the matched string.  C<$'> returns everything
861 after the matched string. And C<$^N> contains whatever was matched by
862 the most-recently closed group (submatch). C<$^N> can be used in
863 extended patterns (see below), for example to assign a submatch to a
864 variable.
865 X<$+> X<$^N> X<$&> X<$`> X<$'>
866
867 These special variables, like the C<%+> hash and the numbered match variables
868 (C<$1>, C<$2>, C<$3>, etc.) are dynamically scoped
869 until the end of the enclosing block or until the next successful
870 match, whichever comes first.  (See L<perlsyn/"Compound Statements">.)
871 X<$+> X<$^N> X<$&> X<$`> X<$'>
872 X<$1> X<$2> X<$3> X<$4> X<$5> X<$6> X<$7> X<$8> X<$9>
873
874 B<NOTE>: Failed matches in Perl do not reset the match variables,
875 which makes it easier to write code that tests for a series of more
876 specific cases and remembers the best match.
877
878 B<WARNING>: If your code is to run on Perl 5.16 or earlier,
879 beware that once Perl sees that you need one of C<$&>, C<$`>, or
880 C<$'> anywhere in the program, it has to provide them for every
881 pattern match.  This may substantially slow your program.  (In Perl 5.18 a
882 more efficient mechanism is used, eliminating any slowdown.)  Perl
883 uses the same mechanism to produce C<$1>, C<$2>, etc, so you also pay a
884 price for each pattern that contains capturing parentheses.  (To
885 avoid this cost while retaining the grouping behaviour, use the
886 extended regular expression C<(?: ... )> instead.)  But if you never
887 use C<$&>, C<$`> or C<$'>, then patterns I<without> capturing
888 parentheses will not be penalized.  So avoid C<$&>, C<$'>, and C<$`>
889 if you can, but if you can't (and some algorithms really appreciate
890 them), once you've used them once, use them at will, because you've
891 already paid the price. 
892 X<$&> X<$`> X<$'>
893
894 As a workaround for this problem, Perl 5.10.0 introduced C<${^PREMATCH}>,
895 C<${^MATCH}> and C<${^POSTMATCH}>, which are equivalent to C<$`>, C<$&>
896 and C<$'>, B<except> that they are only guaranteed to be defined after a
897 successful match that was executed with the C</p> (preserve) modifier.
898 The use of these variables incurs no global performance penalty, unlike
899 their punctuation char equivalents, however at the trade-off that you
900 have to tell perl when you want to use them.  As of Perl 5.18, these three
901 variables are equivalent to C<$`>, C<$&> and C<$'>, and C</p> is ignored.
902 X</p> X<p modifier>
903
904 =head2 Quoting metacharacters
905
906 Backslashed metacharacters in Perl are alphanumeric, such as C<\b>,
907 C<\w>, C<\n>.  Unlike some other regular expression languages, there
908 are no backslashed symbols that aren't alphanumeric.  So anything
909 that looks like \\, \(, \), \[, \], \{, or \} is always
910 interpreted as a literal character, not a metacharacter.  This was
911 once used in a common idiom to disable or quote the special meanings
912 of regular expression metacharacters in a string that you want to
913 use for a pattern. Simply quote all non-"word" characters:
914
915     $pattern =~ s/(\W)/\\$1/g;
916
917 (If C<use locale> is set, then this depends on the current locale.)
918 Today it is more common to use the quotemeta() function or the C<\Q>
919 metaquoting escape sequence to disable all metacharacters' special
920 meanings like this:
921
922     /$unquoted\Q$quoted\E$unquoted/
923
924 Beware that if you put literal backslashes (those not inside
925 interpolated variables) between C<\Q> and C<\E>, double-quotish
926 backslash interpolation may lead to confusing results.  If you
927 I<need> to use literal backslashes within C<\Q...\E>,
928 consult L<perlop/"Gory details of parsing quoted constructs">.
929
930 C<quotemeta()> and C<\Q> are fully described in L<perlfunc/quotemeta>.
931
932 =head2 Extended Patterns
933
934 Perl also defines a consistent extension syntax for features not
935 found in standard tools like B<awk> and
936 B<lex>.  The syntax for most of these is a
937 pair of parentheses with a question mark as the first thing within
938 the parentheses.  The character after the question mark indicates
939 the extension.
940
941 The stability of these extensions varies widely.  Some have been
942 part of the core language for many years.  Others are experimental
943 and may change without warning or be completely removed.  Check
944 the documentation on an individual feature to verify its current
945 status.
946
947 A question mark was chosen for this and for the minimal-matching
948 construct because 1) question marks are rare in older regular
949 expressions, and 2) whenever you see one, you should stop and
950 "question" exactly what is going on.  That's psychology....
951
952 =over 4
953
954 =item C<(?#text)>
955 X<(?#)>
956
957 A comment.  The text is ignored.  If the C</x> modifier enables
958 whitespace formatting, a simple C<#> will suffice.  Note that Perl closes
959 the comment as soon as it sees a C<)>, so there is no way to put a literal
960 C<)> in the comment.
961
962 =item C<(?adlupimsx-imsx)>
963
964 =item C<(?^alupimsx)>
965 X<(?)> X<(?^)>
966
967 One or more embedded pattern-match modifiers, to be turned on (or
968 turned off, if preceded by C<->) for the remainder of the pattern or
969 the remainder of the enclosing pattern group (if any).
970
971 This is particularly useful for dynamic patterns, such as those read in from a
972 configuration file, taken from an argument, or specified in a table
973 somewhere.  Consider the case where some patterns want to be
974 case-sensitive and some do not:  The case-insensitive ones merely need to
975 include C<(?i)> at the front of the pattern.  For example:
976
977     $pattern = "foobar";
978     if ( /$pattern/i ) { }
979
980     # more flexible:
981
982     $pattern = "(?i)foobar";
983     if ( /$pattern/ ) { }
984
985 These modifiers are restored at the end of the enclosing group. For example,
986
987     ( (?i) blah ) \s+ \g1
988
989 will match C<blah> in any case, some spaces, and an exact (I<including the case>!)
990 repetition of the previous word, assuming the C</x> modifier, and no C</i>
991 modifier outside this group.
992
993 These modifiers do not carry over into named subpatterns called in the
994 enclosing group. In other words, a pattern such as C<((?i)(?&NAME))> does not
995 change the case-sensitivity of the "NAME" pattern.
996
997 Any of these modifiers can be set to apply globally to all regular
998 expressions compiled within the scope of a C<use re>.  See
999 L<re/"'/flags' mode">.
1000
1001 Starting in Perl 5.14, a C<"^"> (caret or circumflex accent) immediately
1002 after the C<"?"> is a shorthand equivalent to C<d-imsx>.  Flags (except
1003 C<"d">) may follow the caret to override it.
1004 But a minus sign is not legal with it.
1005
1006 Note that the C<a>, C<d>, C<l>, C<p>, and C<u> modifiers are special in
1007 that they can only be enabled, not disabled, and the C<a>, C<d>, C<l>, and
1008 C<u> modifiers are mutually exclusive: specifying one de-specifies the
1009 others, and a maximum of one (or two C<a>'s) may appear in the
1010 construct.  Thus, for
1011 example, C<(?-p)> will warn when compiled under C<use warnings>;
1012 C<(?-d:...)> and C<(?dl:...)> are fatal errors.
1013
1014 Note also that the C<p> modifier is special in that its presence
1015 anywhere in a pattern has a global effect.
1016
1017 =item C<(?:pattern)>
1018 X<(?:)>
1019
1020 =item C<(?adluimsx-imsx:pattern)>
1021
1022 =item C<(?^aluimsx:pattern)>
1023 X<(?^:)>
1024
1025 This is for clustering, not capturing; it groups subexpressions like
1026 "()", but doesn't make backreferences as "()" does.  So
1027
1028     @fields = split(/\b(?:a|b|c)\b/)
1029
1030 is like
1031
1032     @fields = split(/\b(a|b|c)\b/)
1033
1034 but doesn't spit out extra fields.  It's also cheaper not to capture
1035 characters if you don't need to.
1036
1037 Any letters between C<?> and C<:> act as flags modifiers as with
1038 C<(?adluimsx-imsx)>.  For example,
1039
1040     /(?s-i:more.*than).*million/i
1041
1042 is equivalent to the more verbose
1043
1044     /(?:(?s-i)more.*than).*million/i
1045
1046 Starting in Perl 5.14, a C<"^"> (caret or circumflex accent) immediately
1047 after the C<"?"> is a shorthand equivalent to C<d-imsx>.  Any positive
1048 flags (except C<"d">) may follow the caret, so
1049
1050     (?^x:foo)
1051
1052 is equivalent to
1053
1054     (?x-ims:foo)
1055
1056 The caret tells Perl that this cluster doesn't inherit the flags of any
1057 surrounding pattern, but uses the system defaults (C<d-imsx>),
1058 modified by any flags specified.
1059
1060 The caret allows for simpler stringification of compiled regular
1061 expressions.  These look like
1062
1063     (?^:pattern)
1064
1065 with any non-default flags appearing between the caret and the colon.
1066 A test that looks at such stringification thus doesn't need to have the
1067 system default flags hard-coded in it, just the caret.  If new flags are
1068 added to Perl, the meaning of the caret's expansion will change to include
1069 the default for those flags, so the test will still work, unchanged.
1070
1071 Specifying a negative flag after the caret is an error, as the flag is
1072 redundant.
1073
1074 Mnemonic for C<(?^...)>:  A fresh beginning since the usual use of a caret is
1075 to match at the beginning.
1076
1077 =item C<(?|pattern)>
1078 X<(?|)> X<Branch reset>
1079
1080 This is the "branch reset" pattern, which has the special property
1081 that the capture groups are numbered from the same starting point
1082 in each alternation branch. It is available starting from perl 5.10.0.
1083
1084 Capture groups are numbered from left to right, but inside this
1085 construct the numbering is restarted for each branch.
1086
1087 The numbering within each branch will be as normal, and any groups
1088 following this construct will be numbered as though the construct
1089 contained only one branch, that being the one with the most capture
1090 groups in it.
1091
1092 This construct is useful when you want to capture one of a
1093 number of alternative matches.
1094
1095 Consider the following pattern.  The numbers underneath show in
1096 which group the captured content will be stored.
1097
1098
1099     # before  ---------------branch-reset----------- after        
1100     / ( a )  (?| x ( y ) z | (p (q) r) | (t) u (v) ) ( z ) /x
1101     # 1            2         2  3        2     3     4  
1102
1103 Be careful when using the branch reset pattern in combination with 
1104 named captures. Named captures are implemented as being aliases to 
1105 numbered groups holding the captures, and that interferes with the
1106 implementation of the branch reset pattern. If you are using named
1107 captures in a branch reset pattern, it's best to use the same names,
1108 in the same order, in each of the alternations:
1109
1110    /(?|  (?<a> x ) (?<b> y )
1111       |  (?<a> z ) (?<b> w )) /x
1112
1113 Not doing so may lead to surprises:
1114
1115   "12" =~ /(?| (?<a> \d+ ) | (?<b> \D+))/x;
1116   say $+ {a};   # Prints '12'
1117   say $+ {b};   # *Also* prints '12'.
1118
1119 The problem here is that both the group named C<< a >> and the group
1120 named C<< b >> are aliases for the group belonging to C<< $1 >>.
1121
1122 =item Look-Around Assertions
1123 X<look-around assertion> X<lookaround assertion> X<look-around> X<lookaround>
1124
1125 Look-around assertions are zero-width patterns which match a specific
1126 pattern without including it in C<$&>. Positive assertions match when
1127 their subpattern matches, negative assertions match when their subpattern
1128 fails. Look-behind matches text up to the current match position,
1129 look-ahead matches text following the current match position.
1130
1131 =over 4
1132
1133 =item C<(?=pattern)>
1134 X<(?=)> X<look-ahead, positive> X<lookahead, positive>
1135
1136 A zero-width positive look-ahead assertion.  For example, C</\w+(?=\t)/>
1137 matches a word followed by a tab, without including the tab in C<$&>.
1138
1139 =item C<(?!pattern)>
1140 X<(?!)> X<look-ahead, negative> X<lookahead, negative>
1141
1142 A zero-width negative look-ahead assertion.  For example C</foo(?!bar)/>
1143 matches any occurrence of "foo" that isn't followed by "bar".  Note
1144 however that look-ahead and look-behind are NOT the same thing.  You cannot
1145 use this for look-behind.
1146
1147 If you are looking for a "bar" that isn't preceded by a "foo", C</(?!foo)bar/>
1148 will not do what you want.  That's because the C<(?!foo)> is just saying that
1149 the next thing cannot be "foo"--and it's not, it's a "bar", so "foobar" will
1150 match.  Use look-behind instead (see below).
1151
1152 =item C<(?<=pattern)> C<\K>
1153 X<(?<=)> X<look-behind, positive> X<lookbehind, positive> X<\K>
1154
1155 A zero-width positive look-behind assertion.  For example, C</(?<=\t)\w+/>
1156 matches a word that follows a tab, without including the tab in C<$&>.
1157 Works only for fixed-width look-behind.
1158
1159 There is a special form of this construct, called C<\K>, which causes the
1160 regex engine to "keep" everything it had matched prior to the C<\K> and
1161 not include it in C<$&>. This effectively provides variable-length
1162 look-behind. The use of C<\K> inside of another look-around assertion
1163 is allowed, but the behaviour is currently not well defined.
1164
1165 For various reasons C<\K> may be significantly more efficient than the
1166 equivalent C<< (?<=...) >> construct, and it is especially useful in
1167 situations where you want to efficiently remove something following
1168 something else in a string. For instance
1169
1170   s/(foo)bar/$1/g;
1171
1172 can be rewritten as the much more efficient
1173
1174   s/foo\Kbar//g;
1175
1176 =item C<(?<!pattern)>
1177 X<(?<!)> X<look-behind, negative> X<lookbehind, negative>
1178
1179 A zero-width negative look-behind assertion.  For example C</(?<!bar)foo/>
1180 matches any occurrence of "foo" that does not follow "bar".  Works
1181 only for fixed-width look-behind.
1182
1183 =back
1184
1185 =item C<(?'NAME'pattern)>
1186
1187 =item C<< (?<NAME>pattern) >>
1188 X<< (?<NAME>) >> X<(?'NAME')> X<named capture> X<capture>
1189
1190 A named capture group. Identical in every respect to normal capturing
1191 parentheses C<()> but for the additional fact that the group
1192 can be referred to by name in various regular expression
1193 constructs (like C<\g{NAME}>) and can be accessed by name
1194 after a successful match via C<%+> or C<%->. See L<perlvar>
1195 for more details on the C<%+> and C<%-> hashes.
1196
1197 If multiple distinct capture groups have the same name then the
1198 $+{NAME} will refer to the leftmost defined group in the match.
1199
1200 The forms C<(?'NAME'pattern)> and C<< (?<NAME>pattern) >> are equivalent.
1201
1202 B<NOTE:> While the notation of this construct is the same as the similar
1203 function in .NET regexes, the behavior is not. In Perl the groups are
1204 numbered sequentially regardless of being named or not. Thus in the
1205 pattern
1206
1207   /(x)(?<foo>y)(z)/
1208
1209 $+{foo} will be the same as $2, and $3 will contain 'z' instead of
1210 the opposite which is what a .NET regex hacker might expect.
1211
1212 Currently NAME is restricted to simple identifiers only.
1213 In other words, it must match C</^[_A-Za-z][_A-Za-z0-9]*\z/> or
1214 its Unicode extension (see L<utf8>),
1215 though it isn't extended by the locale (see L<perllocale>).
1216
1217 B<NOTE:> In order to make things easier for programmers with experience
1218 with the Python or PCRE regex engines, the pattern C<< (?PE<lt>NAMEE<gt>pattern) >>
1219 may be used instead of C<< (?<NAME>pattern) >>; however this form does not
1220 support the use of single quotes as a delimiter for the name.
1221
1222 =item C<< \k<NAME> >>
1223
1224 =item C<< \k'NAME' >>
1225
1226 Named backreference. Similar to numeric backreferences, except that
1227 the group is designated by name and not number. If multiple groups
1228 have the same name then it refers to the leftmost defined group in
1229 the current match.
1230
1231 It is an error to refer to a name not defined by a C<< (?<NAME>) >>
1232 earlier in the pattern.
1233
1234 Both forms are equivalent.
1235
1236 B<NOTE:> In order to make things easier for programmers with experience
1237 with the Python or PCRE regex engines, the pattern C<< (?P=NAME) >>
1238 may be used instead of C<< \k<NAME> >>.
1239
1240 =item C<(?{ code })>
1241 X<(?{})> X<regex, code in> X<regexp, code in> X<regular expression, code in>
1242
1243 B<WARNING>: This extended regular expression feature is considered
1244 experimental, and may be changed without notice. Code executed that
1245 has side effects may not perform identically from version to version
1246 due to the effect of future optimisations in the regex engine. The
1247 implementation of this feature was radically overhauled for the 5.18.0
1248 release, and its behaviour in earlier versions of perl was much buggier,
1249 especially in relation to parsing, lexical vars, scoping, recursion and
1250 reentrancy.
1251
1252 This zero-width assertion executes any embedded Perl code.  It always
1253 succeeds, and its return value is set as C<$^R>.
1254
1255 In literal patterns, the code is parsed at the same time as the
1256 surrounding code. While within the pattern, control is passed temporarily
1257 back to the perl parser, until the logically-balancing closing brace is
1258 encountered. This is similar to the way that an array index expression in
1259 a literal string is handled, for example
1260
1261     "abc$array[ 1 + f('[') + g()]def"
1262
1263 In particular, braces do not need to be balanced:
1264
1265     s/abc(?{ f('{'); })/def/
1266
1267 Even in a pattern that is interpolated and compiled at run-time, literal
1268 code blocks will be compiled once, at perl compile time; the following
1269 prints "ABCD":
1270
1271     print "D";
1272     my $qr = qr/(?{ BEGIN { print "A" } })/;
1273     my $foo = "foo";
1274     /$foo$qr(?{ BEGIN { print "B" } })/;
1275     BEGIN { print "C" }
1276
1277 In patterns where the text of the code is derived from run-time
1278 information rather than appearing literally in a source code /pattern/,
1279 the code is compiled at the same time that the pattern is compiled, and
1280 for reasons of security, C<use re 'eval'> must be in scope. This is to
1281 stop user-supplied patterns containing code snippets from being
1282 executable.
1283
1284 In situations where you need to enable this with C<use re 'eval'>, you should
1285 also have taint checking enabled.  Better yet, use the carefully
1286 constrained evaluation within a Safe compartment.  See L<perlsec> for
1287 details about both these mechanisms.
1288
1289 From the viewpoint of parsing, lexical variable scope and closures,
1290
1291     /AAA(?{ BBB })CCC/
1292
1293 behaves approximately like
1294
1295     /AAA/ && do { BBB } && /CCC/
1296
1297 Similarly,
1298
1299     qr/AAA(?{ BBB })CCC/
1300
1301 behaves approximately like
1302
1303     sub { /AAA/ && do { BBB } && /CCC/ }
1304
1305 In particular:
1306
1307     { my $i = 1; $r = qr/(?{ print $i })/ }
1308     my $i = 2;
1309     /$r/; # prints "1"
1310
1311 Inside a C<(?{...})> block, C<$_> refers to the string the regular
1312 expression is matching against. You can also use C<pos()> to know what is
1313 the current position of matching within this string.
1314
1315 The code block introduces a new scope from the perspective of lexical
1316 variable declarations, but B<not> from the perspective of C<local> and
1317 similar localizing behaviours. So later code blocks within the same
1318 pattern will still see the values which were localized in earlier blocks.
1319 These accumulated localizations are undone either at the end of a
1320 successful match, or if the assertion is backtracked (compare
1321 L<"Backtracking">). For example,
1322
1323   $_ = 'a' x 8;
1324   m<
1325      (?{ $cnt = 0 })               # Initialize $cnt.
1326      (
1327        a
1328        (?{
1329            local $cnt = $cnt + 1;  # Update $cnt,
1330                                    # backtracking-safe.
1331        })
1332      )*
1333      aaaa
1334      (?{ $res = $cnt })            # On success copy to
1335                                    # non-localized location.
1336    >x;
1337
1338 will initially increment C<$cnt> up to 8; then during backtracking, its
1339 value will be unwound back to 4, which is the value assigned to C<$res>.
1340 At the end of the regex execution, $cnt will be wound back to its initial
1341 value of 0.
1342
1343 This assertion may be used as the condition in a
1344
1345     (?(condition)yes-pattern|no-pattern)
1346
1347 switch.  If I<not> used in this way, the result of evaluation of C<code>
1348 is put into the special variable C<$^R>.  This happens immediately, so
1349 C<$^R> can be used from other C<(?{ code })> assertions inside the same
1350 regular expression.
1351
1352 The assignment to C<$^R> above is properly localized, so the old
1353 value of C<$^R> is restored if the assertion is backtracked; compare
1354 L<"Backtracking">.
1355
1356 Note that the special variable C<$^N>  is particularly useful with code
1357 blocks to capture the results of submatches in variables without having to
1358 keep track of the number of nested parentheses. For example:
1359
1360   $_ = "The brown fox jumps over the lazy dog";
1361   /the (\S+)(?{ $color = $^N }) (\S+)(?{ $animal = $^N })/i;
1362   print "color = $color, animal = $animal\n";
1363
1364
1365 =item C<(??{ code })>
1366 X<(??{})>
1367 X<regex, postponed> X<regexp, postponed> X<regular expression, postponed>
1368
1369 B<WARNING>: This extended regular expression feature is considered
1370 experimental, and may be changed without notice. Code executed that
1371 has side effects may not perform identically from version to version
1372 due to the effect of future optimisations in the regex engine.
1373
1374 This is a "postponed" regular subexpression.  It behaves in I<exactly> the
1375 same way as a C<(?{ code })> code block as described above, except that
1376 its return value, rather than being assigned to C<$^R>, is treated as a
1377 pattern, compiled if it's a string (or used as-is if its a qr// object),
1378 then matched as if it were inserted instead of this construct.
1379
1380 During the matching of this sub-pattern, it has its own set of
1381 captures which are valid during the sub-match, but are discarded once
1382 control returns to the main pattern. For example, the following matches,
1383 with the inner pattern capturing "B" and matching "BB", while the outer
1384 pattern captures "A";
1385
1386     my $inner = '(.)\1';
1387     "ABBA" =~ /^(.)(??{ $inner })\1/;
1388     print $1; # prints "A";
1389
1390 Note that this means that  there is no way for the inner pattern to refer
1391 to a capture group defined outside.  (The code block itself can use C<$1>,
1392 etc., to refer to the enclosing pattern's capture groups.)  Thus, although
1393
1394     ('a' x 100)=~/(??{'(.)' x 100})/
1395
1396 I<will> match, it will I<not> set $1 on exit.
1397
1398 The following pattern matches a parenthesized group:
1399
1400  $re = qr{
1401             \(
1402             (?:
1403                (?> [^()]+ )  # Non-parens without backtracking
1404              |
1405                (??{ $re })   # Group with matching parens
1406             )*
1407             \)
1408          }x;
1409
1410 See also
1411 L<C<(?I<PARNO>)>|/(?PARNO) (?-PARNO) (?+PARNO) (?R) (?0)>
1412 for a different, more efficient way to accomplish
1413 the same task.
1414
1415 Executing a postponed regular expression 50 times without consuming any
1416 input string will result in a fatal error.  The maximum depth is compiled
1417 into perl, so changing it requires a custom build.
1418
1419 =item C<(?I<PARNO>)> C<(?-I<PARNO>)> C<(?+I<PARNO>)> C<(?R)> C<(?0)>
1420 X<(?PARNO)> X<(?1)> X<(?R)> X<(?0)> X<(?-1)> X<(?+1)> X<(?-PARNO)> X<(?+PARNO)>
1421 X<regex, recursive> X<regexp, recursive> X<regular expression, recursive>
1422 X<regex, relative recursion>
1423
1424 Similar to C<(??{ code })> except that it does not involve executing any
1425 code or potentially compiling a returned pattern string; instead it treats
1426 the part of the current pattern contained within a specified capture group
1427 as an independent pattern that must match at the current position.
1428 Capture groups contained by the pattern will have the value as determined
1429 by the outermost recursion.
1430
1431 I<PARNO> is a sequence of digits (not starting with 0) whose value reflects
1432 the paren-number of the capture group to recurse to. C<(?R)> recurses to
1433 the beginning of the whole pattern. C<(?0)> is an alternate syntax for
1434 C<(?R)>. If I<PARNO> is preceded by a plus or minus sign then it is assumed
1435 to be relative, with negative numbers indicating preceding capture groups
1436 and positive ones following. Thus C<(?-1)> refers to the most recently
1437 declared group, and C<(?+1)> indicates the next group to be declared.
1438 Note that the counting for relative recursion differs from that of
1439 relative backreferences, in that with recursion unclosed groups B<are>
1440 included.
1441
1442 The following pattern matches a function foo() which may contain
1443 balanced parentheses as the argument.
1444
1445   $re = qr{ (                   # paren group 1 (full function)
1446               foo
1447               (                 # paren group 2 (parens)
1448                 \(
1449                   (             # paren group 3 (contents of parens)
1450                   (?:
1451                    (?> [^()]+ ) # Non-parens without backtracking
1452                   |
1453                    (?2)         # Recurse to start of paren group 2
1454                   )*
1455                   )
1456                 \)
1457               )
1458             )
1459           }x;
1460
1461 If the pattern was used as follows
1462
1463     'foo(bar(baz)+baz(bop))'=~/$re/
1464         and print "\$1 = $1\n",
1465                   "\$2 = $2\n",
1466                   "\$3 = $3\n";
1467
1468 the output produced should be the following:
1469
1470     $1 = foo(bar(baz)+baz(bop))
1471     $2 = (bar(baz)+baz(bop))
1472     $3 = bar(baz)+baz(bop)
1473
1474 If there is no corresponding capture group defined, then it is a
1475 fatal error.  Recursing deeper than 50 times without consuming any input
1476 string will also result in a fatal error.  The maximum depth is compiled
1477 into perl, so changing it requires a custom build.
1478
1479 The following shows how using negative indexing can make it
1480 easier to embed recursive patterns inside of a C<qr//> construct
1481 for later use:
1482
1483     my $parens = qr/(\((?:[^()]++|(?-1))*+\))/;
1484     if (/foo $parens \s+ \+ \s+ bar $parens/x) {
1485        # do something here...
1486     }
1487
1488 B<Note> that this pattern does not behave the same way as the equivalent
1489 PCRE or Python construct of the same form. In Perl you can backtrack into
1490 a recursed group, in PCRE and Python the recursed into group is treated
1491 as atomic. Also, modifiers are resolved at compile time, so constructs
1492 like (?i:(?1)) or (?:(?i)(?1)) do not affect how the sub-pattern will
1493 be processed.
1494
1495 =item C<(?&NAME)>
1496 X<(?&NAME)>
1497
1498 Recurse to a named subpattern. Identical to C<(?I<PARNO>)> except that the
1499 parenthesis to recurse to is determined by name. If multiple parentheses have
1500 the same name, then it recurses to the leftmost.
1501
1502 It is an error to refer to a name that is not declared somewhere in the
1503 pattern.
1504
1505 B<NOTE:> In order to make things easier for programmers with experience
1506 with the Python or PCRE regex engines the pattern C<< (?P>NAME) >>
1507 may be used instead of C<< (?&NAME) >>.
1508
1509 =item C<(?(condition)yes-pattern|no-pattern)>
1510 X<(?()>
1511
1512 =item C<(?(condition)yes-pattern)>
1513
1514 Conditional expression. Matches C<yes-pattern> if C<condition> yields
1515 a true value, matches C<no-pattern> otherwise. A missing pattern always
1516 matches.
1517
1518 C<(condition)> should be one of: 1) an integer in
1519 parentheses (which is valid if the corresponding pair of parentheses
1520 matched); 2) a look-ahead/look-behind/evaluate zero-width assertion; 3) a
1521 name in angle brackets or single quotes (which is valid if a group
1522 with the given name matched); or 4) the special symbol (R) (true when
1523 evaluated inside of recursion or eval). Additionally the R may be
1524 followed by a number, (which will be true when evaluated when recursing
1525 inside of the appropriate group), or by C<&NAME>, in which case it will
1526 be true only when evaluated during recursion in the named group.
1527
1528 Here's a summary of the possible predicates:
1529
1530 =over 4
1531
1532 =item (1) (2) ...
1533
1534 Checks if the numbered capturing group has matched something.
1535
1536 =item (<NAME>) ('NAME')
1537
1538 Checks if a group with the given name has matched something.
1539
1540 =item (?=...) (?!...) (?<=...) (?<!...)
1541
1542 Checks whether the pattern matches (or does not match, for the '!'
1543 variants).
1544
1545 =item (?{ CODE })
1546
1547 Treats the return value of the code block as the condition.
1548
1549 =item (R)
1550
1551 Checks if the expression has been evaluated inside of recursion.
1552
1553 =item (R1) (R2) ...
1554
1555 Checks if the expression has been evaluated while executing directly
1556 inside of the n-th capture group. This check is the regex equivalent of
1557
1558   if ((caller(0))[3] eq 'subname') { ... }
1559
1560 In other words, it does not check the full recursion stack.
1561
1562 =item (R&NAME)
1563
1564 Similar to C<(R1)>, this predicate checks to see if we're executing
1565 directly inside of the leftmost group with a given name (this is the same
1566 logic used by C<(?&NAME)> to disambiguate). It does not check the full
1567 stack, but only the name of the innermost active recursion.
1568
1569 =item (DEFINE)
1570
1571 In this case, the yes-pattern is never directly executed, and no
1572 no-pattern is allowed. Similar in spirit to C<(?{0})> but more efficient.
1573 See below for details.
1574
1575 =back
1576
1577 For example:
1578
1579     m{ ( \( )?
1580        [^()]+
1581        (?(1) \) )
1582      }x
1583
1584 matches a chunk of non-parentheses, possibly included in parentheses
1585 themselves.
1586
1587 A special form is the C<(DEFINE)> predicate, which never executes its
1588 yes-pattern directly, and does not allow a no-pattern. This allows one to
1589 define subpatterns which will be executed only by the recursion mechanism.
1590 This way, you can define a set of regular expression rules that can be
1591 bundled into any pattern you choose.
1592
1593 It is recommended that for this usage you put the DEFINE block at the
1594 end of the pattern, and that you name any subpatterns defined within it.
1595
1596 Also, it's worth noting that patterns defined this way probably will
1597 not be as efficient, as the optimiser is not very clever about
1598 handling them.
1599
1600 An example of how this might be used is as follows:
1601
1602   /(?<NAME>(?&NAME_PAT))(?<ADDR>(?&ADDRESS_PAT))
1603    (?(DEFINE)
1604      (?<NAME_PAT>....)
1605      (?<ADRESS_PAT>....)
1606    )/x
1607
1608 Note that capture groups matched inside of recursion are not accessible
1609 after the recursion returns, so the extra layer of capturing groups is
1610 necessary. Thus C<$+{NAME_PAT}> would not be defined even though
1611 C<$+{NAME}> would be.
1612
1613 Finally, keep in mind that subpatterns created inside a DEFINE block
1614 count towards the absolute and relative number of captures, so this:
1615
1616     my @captures = "a" =~ /(.)                  # First capture
1617                            (?(DEFINE)
1618                                (?<EXAMPLE> 1 )  # Second capture
1619                            )/x;
1620     say scalar @captures;
1621
1622 Will output 2, not 1. This is particularly important if you intend to
1623 compile the definitions with the C<qr//> operator, and later
1624 interpolate them in another pattern.
1625
1626 =item C<< (?>pattern) >>
1627 X<backtrack> X<backtracking> X<atomic> X<possessive>
1628
1629 An "independent" subexpression, one which matches the substring
1630 that a I<standalone> C<pattern> would match if anchored at the given
1631 position, and it matches I<nothing other than this substring>.  This
1632 construct is useful for optimizations of what would otherwise be
1633 "eternal" matches, because it will not backtrack (see L<"Backtracking">).
1634 It may also be useful in places where the "grab all you can, and do not
1635 give anything back" semantic is desirable.
1636
1637 For example: C<< ^(?>a*)ab >> will never match, since C<< (?>a*) >>
1638 (anchored at the beginning of string, as above) will match I<all>
1639 characters C<a> at the beginning of string, leaving no C<a> for
1640 C<ab> to match.  In contrast, C<a*ab> will match the same as C<a+b>,
1641 since the match of the subgroup C<a*> is influenced by the following
1642 group C<ab> (see L<"Backtracking">).  In particular, C<a*> inside
1643 C<a*ab> will match fewer characters than a standalone C<a*>, since
1644 this makes the tail match.
1645
1646 C<< (?>pattern) >> does not disable backtracking altogether once it has
1647 matched. It is still possible to backtrack past the construct, but not
1648 into it. So C<< ((?>a*)|(?>b*))ar >> will still match "bar".
1649
1650 An effect similar to C<< (?>pattern) >> may be achieved by writing
1651 C<(?=(pattern))\g{-1}>.  This matches the same substring as a standalone
1652 C<a+>, and the following C<\g{-1}> eats the matched string; it therefore
1653 makes a zero-length assertion into an analogue of C<< (?>...) >>.
1654 (The difference between these two constructs is that the second one
1655 uses a capturing group, thus shifting ordinals of backreferences
1656 in the rest of a regular expression.)
1657
1658 Consider this pattern:
1659
1660     m{ \(
1661           (
1662             [^()]+           # x+
1663           |
1664             \( [^()]* \)
1665           )+
1666        \)
1667      }x
1668
1669 That will efficiently match a nonempty group with matching parentheses
1670 two levels deep or less.  However, if there is no such group, it
1671 will take virtually forever on a long string.  That's because there
1672 are so many different ways to split a long string into several
1673 substrings.  This is what C<(.+)+> is doing, and C<(.+)+> is similar
1674 to a subpattern of the above pattern.  Consider how the pattern
1675 above detects no-match on C<((()aaaaaaaaaaaaaaaaaa> in several
1676 seconds, but that each extra letter doubles this time.  This
1677 exponential performance will make it appear that your program has
1678 hung.  However, a tiny change to this pattern
1679
1680     m{ \(
1681           (
1682             (?> [^()]+ )        # change x+ above to (?> x+ )
1683           |
1684             \( [^()]* \)
1685           )+
1686        \)
1687      }x
1688
1689 which uses C<< (?>...) >> matches exactly when the one above does (verifying
1690 this yourself would be a productive exercise), but finishes in a fourth
1691 the time when used on a similar string with 1000000 C<a>s.  Be aware,
1692 however, that, when this construct is followed by a
1693 quantifier, it currently triggers a warning message under
1694 the C<use warnings> pragma or B<-w> switch saying it
1695 C<"matches null string many times in regex">.
1696
1697 On simple groups, such as the pattern C<< (?> [^()]+ ) >>, a comparable
1698 effect may be achieved by negative look-ahead, as in C<[^()]+ (?! [^()] )>.
1699 This was only 4 times slower on a string with 1000000 C<a>s.
1700
1701 The "grab all you can, and do not give anything back" semantic is desirable
1702 in many situations where on the first sight a simple C<()*> looks like
1703 the correct solution.  Suppose we parse text with comments being delimited
1704 by C<#> followed by some optional (horizontal) whitespace.  Contrary to
1705 its appearance, C<#[ \t]*> I<is not> the correct subexpression to match
1706 the comment delimiter, because it may "give up" some whitespace if
1707 the remainder of the pattern can be made to match that way.  The correct
1708 answer is either one of these:
1709
1710     (?>#[ \t]*)
1711     #[ \t]*(?![ \t])
1712
1713 For example, to grab non-empty comments into $1, one should use either
1714 one of these:
1715
1716     / (?> \# [ \t]* ) (        .+ ) /x;
1717     /     \# [ \t]*   ( [^ \t] .* ) /x;
1718
1719 Which one you pick depends on which of these expressions better reflects
1720 the above specification of comments.
1721
1722 In some literature this construct is called "atomic matching" or
1723 "possessive matching".
1724
1725 Possessive quantifiers are equivalent to putting the item they are applied
1726 to inside of one of these constructs. The following equivalences apply:
1727
1728     Quantifier Form     Bracketing Form
1729     ---------------     ---------------
1730     PAT*+               (?>PAT*)
1731     PAT++               (?>PAT+)
1732     PAT?+               (?>PAT?)
1733     PAT{min,max}+       (?>PAT{min,max})
1734
1735 =item C<(?[ ])>
1736
1737 See L<perlrecharclass/Extended Bracketed Character Classes>.
1738
1739 =back
1740
1741 =head2 Special Backtracking Control Verbs
1742
1743 B<WARNING:> These patterns are experimental and subject to change or
1744 removal in a future version of Perl. Their usage in production code should
1745 be noted to avoid problems during upgrades.
1746
1747 These special patterns are generally of the form C<(*VERB:ARG)>. Unless
1748 otherwise stated the ARG argument is optional; in some cases, it is
1749 forbidden.
1750
1751 Any pattern containing a special backtracking verb that allows an argument
1752 has the special behaviour that when executed it sets the current package's
1753 C<$REGERROR> and C<$REGMARK> variables. When doing so the following
1754 rules apply:
1755
1756 On failure, the C<$REGERROR> variable will be set to the ARG value of the
1757 verb pattern, if the verb was involved in the failure of the match. If the
1758 ARG part of the pattern was omitted, then C<$REGERROR> will be set to the
1759 name of the last C<(*MARK:NAME)> pattern executed, or to TRUE if there was
1760 none. Also, the C<$REGMARK> variable will be set to FALSE.
1761
1762 On a successful match, the C<$REGERROR> variable will be set to FALSE, and
1763 the C<$REGMARK> variable will be set to the name of the last
1764 C<(*MARK:NAME)> pattern executed.  See the explanation for the
1765 C<(*MARK:NAME)> verb below for more details.
1766
1767 B<NOTE:> C<$REGERROR> and C<$REGMARK> are not magic variables like C<$1>
1768 and most other regex-related variables. They are not local to a scope, nor
1769 readonly, but instead are volatile package variables similar to C<$AUTOLOAD>.
1770 Use C<local> to localize changes to them to a specific scope if necessary.
1771
1772 If a pattern does not contain a special backtracking verb that allows an
1773 argument, then C<$REGERROR> and C<$REGMARK> are not touched at all.
1774
1775 =over 3
1776
1777 =item Verbs that take an argument
1778
1779 =over 4
1780
1781 =item C<(*PRUNE)> C<(*PRUNE:NAME)>
1782 X<(*PRUNE)> X<(*PRUNE:NAME)>
1783
1784 This zero-width pattern prunes the backtracking tree at the current point
1785 when backtracked into on failure. Consider the pattern C<A (*PRUNE) B>,
1786 where A and B are complex patterns. Until the C<(*PRUNE)> verb is reached,
1787 A may backtrack as necessary to match. Once it is reached, matching
1788 continues in B, which may also backtrack as necessary; however, should B
1789 not match, then no further backtracking will take place, and the pattern
1790 will fail outright at the current starting position.
1791
1792 The following example counts all the possible matching strings in a
1793 pattern (without actually matching any of them).
1794
1795     'aaab' =~ /a+b?(?{print "$&\n"; $count++})(*FAIL)/;
1796     print "Count=$count\n";
1797
1798 which produces:
1799
1800     aaab
1801     aaa
1802     aa
1803     a
1804     aab
1805     aa
1806     a
1807     ab
1808     a
1809     Count=9
1810
1811 If we add a C<(*PRUNE)> before the count like the following
1812
1813     'aaab' =~ /a+b?(*PRUNE)(?{print "$&\n"; $count++})(*FAIL)/;
1814     print "Count=$count\n";
1815
1816 we prevent backtracking and find the count of the longest matching string
1817 at each matching starting point like so:
1818
1819     aaab
1820     aab
1821     ab
1822     Count=3
1823
1824 Any number of C<(*PRUNE)> assertions may be used in a pattern.
1825
1826 See also C<< (?>pattern) >> and possessive quantifiers for other ways to
1827 control backtracking. In some cases, the use of C<(*PRUNE)> can be
1828 replaced with a C<< (?>pattern) >> with no functional difference; however,
1829 C<(*PRUNE)> can be used to handle cases that cannot be expressed using a
1830 C<< (?>pattern) >> alone.
1831
1832 =item C<(*SKIP)> C<(*SKIP:NAME)>
1833 X<(*SKIP)>
1834
1835 This zero-width pattern is similar to C<(*PRUNE)>, except that on
1836 failure it also signifies that whatever text that was matched leading up
1837 to the C<(*SKIP)> pattern being executed cannot be part of I<any> match
1838 of this pattern. This effectively means that the regex engine "skips" forward
1839 to this position on failure and tries to match again, (assuming that
1840 there is sufficient room to match).
1841
1842 The name of the C<(*SKIP:NAME)> pattern has special significance. If a
1843 C<(*MARK:NAME)> was encountered while matching, then it is that position
1844 which is used as the "skip point". If no C<(*MARK)> of that name was
1845 encountered, then the C<(*SKIP)> operator has no effect. When used
1846 without a name the "skip point" is where the match point was when
1847 executing the (*SKIP) pattern.
1848
1849 Compare the following to the examples in C<(*PRUNE)>; note the string
1850 is twice as long:
1851
1852  'aaabaaab' =~ /a+b?(*SKIP)(?{print "$&\n"; $count++})(*FAIL)/;
1853  print "Count=$count\n";
1854
1855 outputs
1856
1857     aaab
1858     aaab
1859     Count=2
1860
1861 Once the 'aaab' at the start of the string has matched, and the C<(*SKIP)>
1862 executed, the next starting point will be where the cursor was when the
1863 C<(*SKIP)> was executed.
1864
1865 =item C<(*MARK:NAME)> C<(*:NAME)>
1866 X<(*MARK)> X<(*MARK:NAME)> X<(*:NAME)>
1867
1868 This zero-width pattern can be used to mark the point reached in a string
1869 when a certain part of the pattern has been successfully matched. This
1870 mark may be given a name. A later C<(*SKIP)> pattern will then skip
1871 forward to that point if backtracked into on failure. Any number of
1872 C<(*MARK)> patterns are allowed, and the NAME portion may be duplicated.
1873
1874 In addition to interacting with the C<(*SKIP)> pattern, C<(*MARK:NAME)>
1875 can be used to "label" a pattern branch, so that after matching, the
1876 program can determine which branches of the pattern were involved in the
1877 match.
1878
1879 When a match is successful, the C<$REGMARK> variable will be set to the
1880 name of the most recently executed C<(*MARK:NAME)> that was involved
1881 in the match.
1882
1883 This can be used to determine which branch of a pattern was matched
1884 without using a separate capture group for each branch, which in turn
1885 can result in a performance improvement, as perl cannot optimize
1886 C</(?:(x)|(y)|(z))/> as efficiently as something like
1887 C</(?:x(*MARK:x)|y(*MARK:y)|z(*MARK:z))/>.
1888
1889 When a match has failed, and unless another verb has been involved in
1890 failing the match and has provided its own name to use, the C<$REGERROR>
1891 variable will be set to the name of the most recently executed
1892 C<(*MARK:NAME)>.
1893
1894 See L</(*SKIP)> for more details.
1895
1896 As a shortcut C<(*MARK:NAME)> can be written C<(*:NAME)>.
1897
1898 =item C<(*THEN)> C<(*THEN:NAME)>
1899
1900 This is similar to the "cut group" operator C<::> from Perl 6.  Like
1901 C<(*PRUNE)>, this verb always matches, and when backtracked into on
1902 failure, it causes the regex engine to try the next alternation in the
1903 innermost enclosing group (capturing or otherwise) that has alternations.
1904 The two branches of a C<(?(condition)yes-pattern|no-pattern)> do not
1905 count as an alternation, as far as C<(*THEN)> is concerned.
1906
1907 Its name comes from the observation that this operation combined with the
1908 alternation operator (C<|>) can be used to create what is essentially a
1909 pattern-based if/then/else block:
1910
1911   ( COND (*THEN) FOO | COND2 (*THEN) BAR | COND3 (*THEN) BAZ )
1912
1913 Note that if this operator is used and NOT inside of an alternation then
1914 it acts exactly like the C<(*PRUNE)> operator.
1915
1916   / A (*PRUNE) B /
1917
1918 is the same as
1919
1920   / A (*THEN) B /
1921
1922 but
1923
1924   / ( A (*THEN) B | C ) /
1925
1926 is not the same as
1927
1928   / ( A (*PRUNE) B | C ) /
1929
1930 as after matching the A but failing on the B the C<(*THEN)> verb will
1931 backtrack and try C; but the C<(*PRUNE)> verb will simply fail.
1932
1933 =back
1934
1935 =item Verbs without an argument
1936
1937 =over 4
1938
1939 =item C<(*COMMIT)>
1940 X<(*COMMIT)>
1941
1942 This is the Perl 6 "commit pattern" C<< <commit> >> or C<:::>. It's a
1943 zero-width pattern similar to C<(*SKIP)>, except that when backtracked
1944 into on failure it causes the match to fail outright. No further attempts
1945 to find a valid match by advancing the start pointer will occur again.
1946 For example,
1947
1948  'aaabaaab' =~ /a+b?(*COMMIT)(?{print "$&\n"; $count++})(*FAIL)/;
1949  print "Count=$count\n";
1950
1951 outputs
1952
1953     aaab
1954     Count=1
1955
1956 In other words, once the C<(*COMMIT)> has been entered, and if the pattern
1957 does not match, the regex engine will not try any further matching on the
1958 rest of the string.
1959
1960 =item C<(*FAIL)> C<(*F)>
1961 X<(*FAIL)> X<(*F)>
1962
1963 This pattern matches nothing and always fails. It can be used to force the
1964 engine to backtrack. It is equivalent to C<(?!)>, but easier to read. In
1965 fact, C<(?!)> gets optimised into C<(*FAIL)> internally.
1966
1967 It is probably useful only when combined with C<(?{})> or C<(??{})>.
1968
1969 =item C<(*ACCEPT)>
1970 X<(*ACCEPT)>
1971
1972 B<WARNING:> This feature is highly experimental. It is not recommended
1973 for production code.
1974
1975 This pattern matches nothing and causes the end of successful matching at
1976 the point at which the C<(*ACCEPT)> pattern was encountered, regardless of
1977 whether there is actually more to match in the string. When inside of a
1978 nested pattern, such as recursion, or in a subpattern dynamically generated
1979 via C<(??{})>, only the innermost pattern is ended immediately.
1980
1981 If the C<(*ACCEPT)> is inside of capturing groups then the groups are
1982 marked as ended at the point at which the C<(*ACCEPT)> was encountered.
1983 For instance:
1984
1985   'AB' =~ /(A (A|B(*ACCEPT)|C) D)(E)/x;
1986
1987 will match, and C<$1> will be C<AB> and C<$2> will be C<B>, C<$3> will not
1988 be set. If another branch in the inner parentheses was matched, such as in the
1989 string 'ACDE', then the C<D> and C<E> would have to be matched as well.
1990
1991 =back
1992
1993 =back
1994
1995 =head2 Backtracking
1996 X<backtrack> X<backtracking>
1997
1998 NOTE: This section presents an abstract approximation of regular
1999 expression behavior.  For a more rigorous (and complicated) view of
2000 the rules involved in selecting a match among possible alternatives,
2001 see L<Combining RE Pieces>.
2002
2003 A fundamental feature of regular expression matching involves the
2004 notion called I<backtracking>, which is currently used (when needed)
2005 by all regular non-possessive expression quantifiers, namely C<*>, C<*?>, C<+>,
2006 C<+?>, C<{n,m}>, and C<{n,m}?>.  Backtracking is often optimized
2007 internally, but the general principle outlined here is valid.
2008
2009 For a regular expression to match, the I<entire> regular expression must
2010 match, not just part of it.  So if the beginning of a pattern containing a
2011 quantifier succeeds in a way that causes later parts in the pattern to
2012 fail, the matching engine backs up and recalculates the beginning
2013 part--that's why it's called backtracking.
2014
2015 Here is an example of backtracking:  Let's say you want to find the
2016 word following "foo" in the string "Food is on the foo table.":
2017
2018     $_ = "Food is on the foo table.";
2019     if ( /\b(foo)\s+(\w+)/i ) {
2020         print "$2 follows $1.\n";
2021     }
2022
2023 When the match runs, the first part of the regular expression (C<\b(foo)>)
2024 finds a possible match right at the beginning of the string, and loads up
2025 $1 with "Foo".  However, as soon as the matching engine sees that there's
2026 no whitespace following the "Foo" that it had saved in $1, it realizes its
2027 mistake and starts over again one character after where it had the
2028 tentative match.  This time it goes all the way until the next occurrence
2029 of "foo". The complete regular expression matches this time, and you get
2030 the expected output of "table follows foo."
2031
2032 Sometimes minimal matching can help a lot.  Imagine you'd like to match
2033 everything between "foo" and "bar".  Initially, you write something
2034 like this:
2035
2036     $_ =  "The food is under the bar in the barn.";
2037     if ( /foo(.*)bar/ ) {
2038         print "got <$1>\n";
2039     }
2040
2041 Which perhaps unexpectedly yields:
2042
2043   got <d is under the bar in the >
2044
2045 That's because C<.*> was greedy, so you get everything between the
2046 I<first> "foo" and the I<last> "bar".  Here it's more effective
2047 to use minimal matching to make sure you get the text between a "foo"
2048 and the first "bar" thereafter.
2049
2050     if ( /foo(.*?)bar/ ) { print "got <$1>\n" }
2051   got <d is under the >
2052
2053 Here's another example. Let's say you'd like to match a number at the end
2054 of a string, and you also want to keep the preceding part of the match.
2055 So you write this:
2056
2057     $_ = "I have 2 numbers: 53147";
2058     if ( /(.*)(\d*)/ ) {                                # Wrong!
2059         print "Beginning is <$1>, number is <$2>.\n";
2060     }
2061
2062 That won't work at all, because C<.*> was greedy and gobbled up the
2063 whole string. As C<\d*> can match on an empty string the complete
2064 regular expression matched successfully.
2065
2066     Beginning is <I have 2 numbers: 53147>, number is <>.
2067
2068 Here are some variants, most of which don't work:
2069
2070     $_ = "I have 2 numbers: 53147";
2071     @pats = qw{
2072         (.*)(\d*)
2073         (.*)(\d+)
2074         (.*?)(\d*)
2075         (.*?)(\d+)
2076         (.*)(\d+)$
2077         (.*?)(\d+)$
2078         (.*)\b(\d+)$
2079         (.*\D)(\d+)$
2080     };
2081
2082     for $pat (@pats) {
2083         printf "%-12s ", $pat;
2084         if ( /$pat/ ) {
2085             print "<$1> <$2>\n";
2086         } else {
2087             print "FAIL\n";
2088         }
2089     }
2090
2091 That will print out:
2092
2093     (.*)(\d*)    <I have 2 numbers: 53147> <>
2094     (.*)(\d+)    <I have 2 numbers: 5314> <7>
2095     (.*?)(\d*)   <> <>
2096     (.*?)(\d+)   <I have > <2>
2097     (.*)(\d+)$   <I have 2 numbers: 5314> <7>
2098     (.*?)(\d+)$  <I have 2 numbers: > <53147>
2099     (.*)\b(\d+)$ <I have 2 numbers: > <53147>
2100     (.*\D)(\d+)$ <I have 2 numbers: > <53147>
2101
2102 As you see, this can be a bit tricky.  It's important to realize that a
2103 regular expression is merely a set of assertions that gives a definition
2104 of success.  There may be 0, 1, or several different ways that the
2105 definition might succeed against a particular string.  And if there are
2106 multiple ways it might succeed, you need to understand backtracking to
2107 know which variety of success you will achieve.
2108
2109 When using look-ahead assertions and negations, this can all get even
2110 trickier.  Imagine you'd like to find a sequence of non-digits not
2111 followed by "123".  You might try to write that as
2112
2113     $_ = "ABC123";
2114     if ( /^\D*(?!123)/ ) {                # Wrong!
2115         print "Yup, no 123 in $_\n";
2116     }
2117
2118 But that isn't going to match; at least, not the way you're hoping.  It
2119 claims that there is no 123 in the string.  Here's a clearer picture of
2120 why that pattern matches, contrary to popular expectations:
2121
2122     $x = 'ABC123';
2123     $y = 'ABC445';
2124
2125     print "1: got $1\n" if $x =~ /^(ABC)(?!123)/;
2126     print "2: got $1\n" if $y =~ /^(ABC)(?!123)/;
2127
2128     print "3: got $1\n" if $x =~ /^(\D*)(?!123)/;
2129     print "4: got $1\n" if $y =~ /^(\D*)(?!123)/;
2130
2131 This prints
2132
2133     2: got ABC
2134     3: got AB
2135     4: got ABC
2136
2137 You might have expected test 3 to fail because it seems to a more
2138 general purpose version of test 1.  The important difference between
2139 them is that test 3 contains a quantifier (C<\D*>) and so can use
2140 backtracking, whereas test 1 will not.  What's happening is
2141 that you've asked "Is it true that at the start of $x, following 0 or more
2142 non-digits, you have something that's not 123?"  If the pattern matcher had
2143 let C<\D*> expand to "ABC", this would have caused the whole pattern to
2144 fail.
2145
2146 The search engine will initially match C<\D*> with "ABC".  Then it will
2147 try to match C<(?!123)> with "123", which fails.  But because
2148 a quantifier (C<\D*>) has been used in the regular expression, the
2149 search engine can backtrack and retry the match differently
2150 in the hope of matching the complete regular expression.
2151
2152 The pattern really, I<really> wants to succeed, so it uses the
2153 standard pattern back-off-and-retry and lets C<\D*> expand to just "AB" this
2154 time.  Now there's indeed something following "AB" that is not
2155 "123".  It's "C123", which suffices.
2156
2157 We can deal with this by using both an assertion and a negation.
2158 We'll say that the first part in $1 must be followed both by a digit
2159 and by something that's not "123".  Remember that the look-aheads
2160 are zero-width expressions--they only look, but don't consume any
2161 of the string in their match.  So rewriting this way produces what
2162 you'd expect; that is, case 5 will fail, but case 6 succeeds:
2163
2164     print "5: got $1\n" if $x =~ /^(\D*)(?=\d)(?!123)/;
2165     print "6: got $1\n" if $y =~ /^(\D*)(?=\d)(?!123)/;
2166
2167     6: got ABC
2168
2169 In other words, the two zero-width assertions next to each other work as though
2170 they're ANDed together, just as you'd use any built-in assertions:  C</^$/>
2171 matches only if you're at the beginning of the line AND the end of the
2172 line simultaneously.  The deeper underlying truth is that juxtaposition in
2173 regular expressions always means AND, except when you write an explicit OR
2174 using the vertical bar.  C</ab/> means match "a" AND (then) match "b",
2175 although the attempted matches are made at different positions because "a"
2176 is not a zero-width assertion, but a one-width assertion.
2177
2178 B<WARNING>: Particularly complicated regular expressions can take
2179 exponential time to solve because of the immense number of possible
2180 ways they can use backtracking to try for a match.  For example, without
2181 internal optimizations done by the regular expression engine, this will
2182 take a painfully long time to run:
2183
2184     'aaaaaaaaaaaa' =~ /((a{0,5}){0,5})*[c]/
2185
2186 And if you used C<*>'s in the internal groups instead of limiting them
2187 to 0 through 5 matches, then it would take forever--or until you ran
2188 out of stack space.  Moreover, these internal optimizations are not
2189 always applicable.  For example, if you put C<{0,5}> instead of C<*>
2190 on the external group, no current optimization is applicable, and the
2191 match takes a long time to finish.
2192
2193 A powerful tool for optimizing such beasts is what is known as an
2194 "independent group",
2195 which does not backtrack (see L</C<< (?>pattern) >>>).  Note also that
2196 zero-length look-ahead/look-behind assertions will not backtrack to make
2197 the tail match, since they are in "logical" context: only
2198 whether they match is considered relevant.  For an example
2199 where side-effects of look-ahead I<might> have influenced the
2200 following match, see L</C<< (?>pattern) >>>.
2201
2202 =head2 Version 8 Regular Expressions
2203 X<regular expression, version 8> X<regex, version 8> X<regexp, version 8>
2204
2205 In case you're not familiar with the "regular" Version 8 regex
2206 routines, here are the pattern-matching rules not described above.
2207
2208 Any single character matches itself, unless it is a I<metacharacter>
2209 with a special meaning described here or above.  You can cause
2210 characters that normally function as metacharacters to be interpreted
2211 literally by prefixing them with a "\" (e.g., "\." matches a ".", not any
2212 character; "\\" matches a "\"). This escape mechanism is also required
2213 for the character used as the pattern delimiter.
2214
2215 A series of characters matches that series of characters in the target
2216 string, so the pattern C<blurfl> would match "blurfl" in the target
2217 string.
2218
2219 You can specify a character class, by enclosing a list of characters
2220 in C<[]>, which will match any character from the list.  If the
2221 first character after the "[" is "^", the class matches any character not
2222 in the list.  Within a list, the "-" character specifies a
2223 range, so that C<a-z> represents all characters between "a" and "z",
2224 inclusive.  If you want either "-" or "]" itself to be a member of a
2225 class, put it at the start of the list (possibly after a "^"), or
2226 escape it with a backslash.  "-" is also taken literally when it is
2227 at the end of the list, just before the closing "]".  (The
2228 following all specify the same class of three characters: C<[-az]>,
2229 C<[az-]>, and C<[a\-z]>.  All are different from C<[a-z]>, which
2230 specifies a class containing twenty-six characters, even on EBCDIC-based
2231 character sets.)  Also, if you try to use the character
2232 classes C<\w>, C<\W>, C<\s>, C<\S>, C<\d>, or C<\D> as endpoints of
2233 a range, the "-" is understood literally.
2234
2235 Note also that the whole range idea is rather unportable between
2236 character sets--and even within character sets they may cause results
2237 you probably didn't expect.  A sound principle is to use only ranges
2238 that begin from and end at either alphabetics of equal case ([a-e],
2239 [A-E]), or digits ([0-9]).  Anything else is unsafe.  If in doubt,
2240 spell out the character sets in full.
2241
2242 Characters may be specified using a metacharacter syntax much like that
2243 used in C: "\n" matches a newline, "\t" a tab, "\r" a carriage return,
2244 "\f" a form feed, etc.  More generally, \I<nnn>, where I<nnn> is a string
2245 of three octal digits, matches the character whose coded character set value
2246 is I<nnn>.  Similarly, \xI<nn>, where I<nn> are hexadecimal digits,
2247 matches the character whose ordinal is I<nn>. The expression \cI<x>
2248 matches the character control-I<x>.  Finally, the "." metacharacter
2249 matches any character except "\n" (unless you use C</s>).
2250
2251 You can specify a series of alternatives for a pattern using "|" to
2252 separate them, so that C<fee|fie|foe> will match any of "fee", "fie",
2253 or "foe" in the target string (as would C<f(e|i|o)e>).  The
2254 first alternative includes everything from the last pattern delimiter
2255 ("(", "(?:", etc. or the beginning of the pattern) up to the first "|", and
2256 the last alternative contains everything from the last "|" to the next
2257 closing pattern delimiter.  That's why it's common practice to include
2258 alternatives in parentheses: to minimize confusion about where they
2259 start and end.
2260
2261 Alternatives are tried from left to right, so the first
2262 alternative found for which the entire expression matches, is the one that
2263 is chosen. This means that alternatives are not necessarily greedy. For
2264 example: when matching C<foo|foot> against "barefoot", only the "foo"
2265 part will match, as that is the first alternative tried, and it successfully
2266 matches the target string. (This might not seem important, but it is
2267 important when you are capturing matched text using parentheses.)
2268
2269 Also remember that "|" is interpreted as a literal within square brackets,
2270 so if you write C<[fee|fie|foe]> you're really only matching C<[feio|]>.
2271
2272 Within a pattern, you may designate subpatterns for later reference
2273 by enclosing them in parentheses, and you may refer back to the
2274 I<n>th subpattern later in the pattern using the metacharacter
2275 \I<n> or \gI<n>.  Subpatterns are numbered based on the left to right order
2276 of their opening parenthesis.  A backreference matches whatever
2277 actually matched the subpattern in the string being examined, not
2278 the rules for that subpattern.  Therefore, C<(0|0x)\d*\s\g1\d*> will
2279 match "0x1234 0x4321", but not "0x1234 01234", because subpattern
2280 1 matched "0x", even though the rule C<0|0x> could potentially match
2281 the leading 0 in the second number.
2282
2283 =head2 Warning on \1 Instead of $1
2284
2285 Some people get too used to writing things like:
2286
2287     $pattern =~ s/(\W)/\\\1/g;
2288
2289 This is grandfathered (for \1 to \9) for the RHS of a substitute to avoid
2290 shocking the
2291 B<sed> addicts, but it's a dirty habit to get into.  That's because in
2292 PerlThink, the righthand side of an C<s///> is a double-quoted string.  C<\1> in
2293 the usual double-quoted string means a control-A.  The customary Unix
2294 meaning of C<\1> is kludged in for C<s///>.  However, if you get into the habit
2295 of doing that, you get yourself into trouble if you then add an C</e>
2296 modifier.
2297
2298     s/(\d+)/ \1 + 1 /eg;            # causes warning under -w
2299
2300 Or if you try to do
2301
2302     s/(\d+)/\1000/;
2303
2304 You can't disambiguate that by saying C<\{1}000>, whereas you can fix it with
2305 C<${1}000>.  The operation of interpolation should not be confused
2306 with the operation of matching a backreference.  Certainly they mean two
2307 different things on the I<left> side of the C<s///>.
2308
2309 =head2 Repeated Patterns Matching a Zero-length Substring
2310
2311 B<WARNING>: Difficult material (and prose) ahead.  This section needs a rewrite.
2312
2313 Regular expressions provide a terse and powerful programming language.  As
2314 with most other power tools, power comes together with the ability
2315 to wreak havoc.
2316
2317 A common abuse of this power stems from the ability to make infinite
2318 loops using regular expressions, with something as innocuous as:
2319
2320     'foo' =~ m{ ( o? )* }x;
2321
2322 The C<o?> matches at the beginning of C<'foo'>, and since the position
2323 in the string is not moved by the match, C<o?> would match again and again
2324 because of the C<*> quantifier.  Another common way to create a similar cycle
2325 is with the looping modifier C<//g>:
2326
2327     @matches = ( 'foo' =~ m{ o? }xg );
2328
2329 or
2330
2331     print "match: <$&>\n" while 'foo' =~ m{ o? }xg;
2332
2333 or the loop implied by split().
2334
2335 However, long experience has shown that many programming tasks may
2336 be significantly simplified by using repeated subexpressions that
2337 may match zero-length substrings.  Here's a simple example being:
2338
2339     @chars = split //, $string;           # // is not magic in split
2340     ($whitewashed = $string) =~ s/()/ /g; # parens avoid magic s// /
2341
2342 Thus Perl allows such constructs, by I<forcefully breaking
2343 the infinite loop>.  The rules for this are different for lower-level
2344 loops given by the greedy quantifiers C<*+{}>, and for higher-level
2345 ones like the C</g> modifier or split() operator.
2346
2347 The lower-level loops are I<interrupted> (that is, the loop is
2348 broken) when Perl detects that a repeated expression matched a
2349 zero-length substring.   Thus
2350
2351    m{ (?: NON_ZERO_LENGTH | ZERO_LENGTH )* }x;
2352
2353 is made equivalent to
2354
2355    m{ (?: NON_ZERO_LENGTH )* (?: ZERO_LENGTH )? }x;
2356
2357 For example, this program
2358
2359    #!perl -l
2360    "aaaaab" =~ /
2361      (?:
2362         a                 # non-zero
2363         |                 # or
2364        (?{print "hello"}) # print hello whenever this
2365                           #    branch is tried
2366        (?=(b))            # zero-width assertion
2367      )*  # any number of times
2368     /x;
2369    print $&;
2370    print $1;
2371
2372 prints
2373
2374    hello
2375    aaaaa
2376    b
2377
2378 Notice that "hello" is only printed once, as when Perl sees that the sixth
2379 iteration of the outermost C<(?:)*> matches a zero-length string, it stops
2380 the C<*>.
2381
2382 The higher-level loops preserve an additional state between iterations:
2383 whether the last match was zero-length.  To break the loop, the following
2384 match after a zero-length match is prohibited to have a length of zero.
2385 This prohibition interacts with backtracking (see L<"Backtracking">),
2386 and so the I<second best> match is chosen if the I<best> match is of
2387 zero length.
2388
2389 For example:
2390
2391     $_ = 'bar';
2392     s/\w??/<$&>/g;
2393
2394 results in C<< <><b><><a><><r><> >>.  At each position of the string the best
2395 match given by non-greedy C<??> is the zero-length match, and the I<second
2396 best> match is what is matched by C<\w>.  Thus zero-length matches
2397 alternate with one-character-long matches.
2398
2399 Similarly, for repeated C<m/()/g> the second-best match is the match at the
2400 position one notch further in the string.
2401
2402 The additional state of being I<matched with zero-length> is associated with
2403 the matched string, and is reset by each assignment to pos().
2404 Zero-length matches at the end of the previous match are ignored
2405 during C<split>.
2406
2407 =head2 Combining RE Pieces
2408
2409 Each of the elementary pieces of regular expressions which were described
2410 before (such as C<ab> or C<\Z>) could match at most one substring
2411 at the given position of the input string.  However, in a typical regular
2412 expression these elementary pieces are combined into more complicated
2413 patterns using combining operators C<ST>, C<S|T>, C<S*> etc.
2414 (in these examples C<S> and C<T> are regular subexpressions).
2415
2416 Such combinations can include alternatives, leading to a problem of choice:
2417 if we match a regular expression C<a|ab> against C<"abc">, will it match
2418 substring C<"a"> or C<"ab">?  One way to describe which substring is
2419 actually matched is the concept of backtracking (see L<"Backtracking">).
2420 However, this description is too low-level and makes you think
2421 in terms of a particular implementation.
2422
2423 Another description starts with notions of "better"/"worse".  All the
2424 substrings which may be matched by the given regular expression can be
2425 sorted from the "best" match to the "worst" match, and it is the "best"
2426 match which is chosen.  This substitutes the question of "what is chosen?"
2427 by the question of "which matches are better, and which are worse?".
2428
2429 Again, for elementary pieces there is no such question, since at most
2430 one match at a given position is possible.  This section describes the
2431 notion of better/worse for combining operators.  In the description
2432 below C<S> and C<T> are regular subexpressions.
2433
2434 =over 4
2435
2436 =item C<ST>
2437
2438 Consider two possible matches, C<AB> and C<A'B'>, C<A> and C<A'> are
2439 substrings which can be matched by C<S>, C<B> and C<B'> are substrings
2440 which can be matched by C<T>.
2441
2442 If C<A> is a better match for C<S> than C<A'>, C<AB> is a better
2443 match than C<A'B'>.
2444
2445 If C<A> and C<A'> coincide: C<AB> is a better match than C<AB'> if
2446 C<B> is a better match for C<T> than C<B'>.
2447
2448 =item C<S|T>
2449
2450 When C<S> can match, it is a better match than when only C<T> can match.
2451
2452 Ordering of two matches for C<S> is the same as for C<S>.  Similar for
2453 two matches for C<T>.
2454
2455 =item C<S{REPEAT_COUNT}>
2456
2457 Matches as C<SSS...S> (repeated as many times as necessary).
2458
2459 =item C<S{min,max}>
2460
2461 Matches as C<S{max}|S{max-1}|...|S{min+1}|S{min}>.
2462
2463 =item C<S{min,max}?>
2464
2465 Matches as C<S{min}|S{min+1}|...|S{max-1}|S{max}>.
2466
2467 =item C<S?>, C<S*>, C<S+>
2468
2469 Same as C<S{0,1}>, C<S{0,BIG_NUMBER}>, C<S{1,BIG_NUMBER}> respectively.
2470
2471 =item C<S??>, C<S*?>, C<S+?>
2472
2473 Same as C<S{0,1}?>, C<S{0,BIG_NUMBER}?>, C<S{1,BIG_NUMBER}?> respectively.
2474
2475 =item C<< (?>S) >>
2476
2477 Matches the best match for C<S> and only that.
2478
2479 =item C<(?=S)>, C<(?<=S)>
2480
2481 Only the best match for C<S> is considered.  (This is important only if
2482 C<S> has capturing parentheses, and backreferences are used somewhere
2483 else in the whole regular expression.)
2484
2485 =item C<(?!S)>, C<(?<!S)>
2486
2487 For this grouping operator there is no need to describe the ordering, since
2488 only whether or not C<S> can match is important.
2489
2490 =item C<(??{ EXPR })>, C<(?I<PARNO>)>
2491
2492 The ordering is the same as for the regular expression which is
2493 the result of EXPR, or the pattern contained by capture group I<PARNO>.
2494
2495 =item C<(?(condition)yes-pattern|no-pattern)>
2496
2497 Recall that which of C<yes-pattern> or C<no-pattern> actually matches is
2498 already determined.  The ordering of the matches is the same as for the
2499 chosen subexpression.
2500
2501 =back
2502
2503 The above recipes describe the ordering of matches I<at a given position>.
2504 One more rule is needed to understand how a match is determined for the
2505 whole regular expression: a match at an earlier position is always better
2506 than a match at a later position.
2507
2508 =head2 Creating Custom RE Engines
2509
2510 As of Perl 5.10.0, one can create custom regular expression engines.  This
2511 is not for the faint of heart, as they have to plug in at the C level.  See
2512 L<perlreapi> for more details.
2513
2514 As an alternative, overloaded constants (see L<overload>) provide a simple
2515 way to extend the functionality of the RE engine, by substituting one
2516 pattern for another.
2517
2518 Suppose that we want to enable a new RE escape-sequence C<\Y|> which
2519 matches at a boundary between whitespace characters and non-whitespace
2520 characters.  Note that C<(?=\S)(?<!\S)|(?!\S)(?<=\S)> matches exactly
2521 at these positions, so we want to have each C<\Y|> in the place of the
2522 more complicated version.  We can create a module C<customre> to do
2523 this:
2524
2525     package customre;
2526     use overload;
2527
2528     sub import {
2529       shift;
2530       die "No argument to customre::import allowed" if @_;
2531       overload::constant 'qr' => \&convert;
2532     }
2533
2534     sub invalid { die "/$_[0]/: invalid escape '\\$_[1]'"}
2535
2536     # We must also take care of not escaping the legitimate \\Y|
2537     # sequence, hence the presence of '\\' in the conversion rules.
2538     my %rules = ( '\\' => '\\\\',
2539                   'Y|' => qr/(?=\S)(?<!\S)|(?!\S)(?<=\S)/ );
2540     sub convert {
2541       my $re = shift;
2542       $re =~ s{
2543                 \\ ( \\ | Y . )
2544               }
2545               { $rules{$1} or invalid($re,$1) }sgex;
2546       return $re;
2547     }
2548
2549 Now C<use customre> enables the new escape in constant regular
2550 expressions, i.e., those without any runtime variable interpolations.
2551 As documented in L<overload>, this conversion will work only over
2552 literal parts of regular expressions.  For C<\Y|$re\Y|> the variable
2553 part of this regular expression needs to be converted explicitly
2554 (but only if the special meaning of C<\Y|> should be enabled inside $re):
2555
2556     use customre;
2557     $re = <>;
2558     chomp $re;
2559     $re = customre::convert $re;
2560     /\Y|$re\Y|/;
2561
2562 =head2 PCRE/Python Support
2563
2564 As of Perl 5.10.0, Perl supports several Python/PCRE-specific extensions
2565 to the regex syntax. While Perl programmers are encouraged to use the
2566 Perl-specific syntax, the following are also accepted:
2567
2568 =over 4
2569
2570 =item C<< (?PE<lt>NAMEE<gt>pattern) >>
2571
2572 Define a named capture group. Equivalent to C<< (?<NAME>pattern) >>.
2573
2574 =item C<< (?P=NAME) >>
2575
2576 Backreference to a named capture group. Equivalent to C<< \g{NAME} >>.
2577
2578 =item C<< (?P>NAME) >>
2579
2580 Subroutine call to a named capture group. Equivalent to C<< (?&NAME) >>.
2581
2582 =back
2583
2584 =head1 BUGS
2585
2586 Many regular expression constructs don't work on EBCDIC platforms.
2587
2588 There are a number of issues with regard to case-insensitive matching
2589 in Unicode rules.  See C<i> under L</Modifiers> above.
2590
2591 This document varies from difficult to understand to completely
2592 and utterly opaque.  The wandering prose riddled with jargon is
2593 hard to fathom in several places.
2594
2595 This document needs a rewrite that separates the tutorial content
2596 from the reference content.
2597
2598 =head1 SEE ALSO
2599
2600 L<perlrequick>.
2601
2602 L<perlretut>.
2603
2604 L<perlop/"Regexp Quote-Like Operators">.
2605
2606 L<perlop/"Gory details of parsing quoted constructs">.
2607
2608 L<perlfaq6>.
2609
2610 L<perlfunc/pos>.
2611
2612 L<perllocale>.
2613
2614 L<perlebcdic>.
2615
2616 I<Mastering Regular Expressions> by Jeffrey Friedl, published
2617 by O'Reilly and Associates.