Upgrade CPAN from version 2.05-TRIAL2 to 2.05
[perl.git] / lib / utf8_heavy.pl
1 package utf8;
2 use strict;
3 use warnings;
4 use re "/aa";  # So we won't even try to look at above Latin1, potentially
5                # resulting in a recursive call
6
7 sub DEBUG () { 0 }
8 $|=1 if DEBUG;
9
10 sub DESTROY {}
11
12 my %Cache;
13
14 sub croak { require Carp; Carp::croak(@_) }
15
16 sub _loose_name ($) {
17     # Given a lowercase property or property-value name, return its
18     # standardized version that is expected for look-up in the 'loose' hashes
19     # in Heavy.pl (hence, this depends on what mktables does).  This squeezes
20     # out blanks, underscores and dashes.  The complication stems from the
21     # grandfathered-in 'L_', which retains a single trailing underscore.
22
23     my $loose = $_[0] =~ s/[-\s_]//rg;
24
25     return $loose if $loose !~ / ^ (?: is | to )? l $/x;
26     return 'l_' if $_[0] =~ / l .* _ /x;    # If original had a trailing '_'
27     return $loose;
28 }
29
30 ##
31 ## "SWASH" == "SWATCH HASH". A "swatch" is a swatch of the Unicode landscape.
32 ## It's a data structure that encodes a set of Unicode characters.
33 ##
34
35 {
36     # If a floating point number is within this distance from the value of a
37     # fraction, it is considered to be that fraction, even if many more digits
38     # are specified that don't exactly match.
39     my $min_floating_slop;
40
41     # To guard against this program calling something that in turn ends up
42     # calling this program with the same inputs, and hence infinitely
43     # recursing, we keep a stack of the properties that are currently in
44     # progress, pushed upon entry, popped upon return.
45     my @recursed;
46
47     sub SWASHNEW {
48         my ($class, $type, $list, $minbits, $none) = @_;
49         my $user_defined = 0;
50         local $^D = 0 if $^D;
51
52         $class = "" unless defined $class;
53         print STDERR __LINE__, ": class=$class, type=$type, list=",
54                                 (defined $list) ? $list : ':undef:',
55                                 ", minbits=$minbits, none=$none\n" if DEBUG;
56
57         ##
58         ## Get the list of codepoints for the type.
59         ## Called from swash_init (see utf8.c) or SWASHNEW itself.
60         ##
61         ## Callers of swash_init:
62         ##     op.c:pmtrans             -- for tr/// and y///
63         ##     regexec.c:regclass_swash -- for /[]/, \p, and \P
64         ##     utf8.c:is_utf8_common    -- for common Unicode properties
65         ##     utf8.c:to_utf8_case      -- for lc, uc, ucfirst, etc. and //i
66         ##     Unicode::UCD::prop_invlist
67         ##     Unicode::UCD::prop_invmap
68         ##
69         ## Given a $type, our goal is to fill $list with the set of codepoint
70         ## ranges. If $type is false, $list passed is used.
71         ##
72         ## $minbits:
73         ##     For binary properties, $minbits must be 1.
74         ##     For character mappings (case and transliteration), $minbits must
75         ##     be a number except 1.
76         ##
77         ## $list (or that filled according to $type):
78         ##     Refer to perlunicode.pod, "User-Defined Character Properties."
79         ##     
80         ##     For binary properties, only characters with the property value
81         ##     of True should be listed. The 3rd column, if any, will be ignored
82         ##
83         ## $none is undocumented, so I'm (khw) trying to do some documentation
84         ## of it now.  It appears to be if there is a mapping in an input file
85         ## that maps to 'XXXX', then that is replaced by $none+1, expressed in
86         ## hexadecimal.  It is used somehow in tr///.
87         ##
88         ## To make the parsing of $type clear, this code takes the a rather
89         ## unorthodox approach of last'ing out of the block once we have the
90         ## info we need. Were this to be a subroutine, the 'last' would just
91         ## be a 'return'.
92         ##
93         #   If a problem is found $type is returned;
94         #   Upon success, a new (or cached) blessed object is returned with
95         #   keys TYPE, BITS, EXTRAS, LIST, and NONE with values having the
96         #   same meanings as the input parameters.
97         #   SPECIALS contains a reference to any special-treatment hash in the
98         #   INVERT_IT is non-zero if the result should be inverted before use
99         #   USER_DEFINED is non-zero if the result came from a user-defined
100         #       property.
101         my $file; ## file to load data from, and also part of the %Cache key.
102
103         # Change this to get a different set of Unicode tables
104         my $unicore_dir = 'unicore';
105         my $invert_it = 0;
106         my $list_is_from_mktables = 0;  # Is $list returned from a mktables
107                                         # generated file?  If so, we know it's
108                                         # well behaved.
109
110         if ($type)
111         {
112             # Verify that this isn't a recursive call for this property.
113             # Can't use croak, as it may try to recurse to here itself.
114             my $class_type = $class . "::$type";
115             if (grep { $_ eq $class_type } @recursed) {
116                 CORE::die "panic: Infinite recursion in SWASHNEW for '$type'\n";
117             }
118             push @recursed, $class_type;
119
120             $type =~ s/^\s+//;
121             $type =~ s/\s+$//;
122
123             # regcomp.c surrounds the property name with '__" and '_i' if this
124             # is to be caseless matching.
125             my $caseless = $type =~ s/^(.*)__(.*)_i$/$1$2/;
126
127             print STDERR __LINE__, ": type=$type, caseless=$caseless\n" if DEBUG;
128
129         GETFILE:
130             {
131                 ##
132                 ## It could be a user-defined property.  Look in current
133                 ## package if no package given
134                 ##
135
136
137                 my $caller0 = caller(0);
138                 my $caller1 = $type =~ s/(.+)::// ? $1 : $caller0 eq 'main' ?
139                 'main' : caller(1);
140
141                 if (defined $caller1 && $type =~ /^I[ns]\w+$/) {
142                     my $prop = "${caller1}::$type";
143                     if (exists &{$prop}) {
144                         # stolen from Scalar::Util::PP::tainted()
145                         my $tainted;
146                         {
147                             local($@, $SIG{__DIE__}, $SIG{__WARN__});
148                             local $^W = 0;
149                             no warnings;
150                             eval { kill 0 * $prop };
151                             $tainted = 1 if $@ =~ /^Insecure/;
152                         }
153                         die "Insecure user-defined property \\p{$prop}\n"
154                             if $tainted;
155                         no strict 'refs';
156                         $list = &{$prop}($caseless);
157                         $user_defined = 1;
158                         last GETFILE;
159                     }
160                 }
161
162                 # During Perl's compilation, this routine may be called before
163                 # the tables are constructed.  If so, we have a chicken/egg
164                 # problem.  If we die, the tables never get constructed, so
165                 # keep going, but return an empty table so only what the code
166                 # has compiled in internally (currently ASCII/Latin1 range
167                 # matching) will work.
168                 BEGIN {
169                     # Poor man's constant, to avoid a run-time check.
170                     $utf8::{miniperl}
171                         = \! defined &DynaLoader::boot_DynaLoader;
172                 }
173                 if (miniperl) {
174                     eval "require '$unicore_dir/Heavy.pl'";
175                     last GETFILE if $@;
176                 }
177                 else {
178                     require "$unicore_dir/Heavy.pl";
179                 }
180                 BEGIN { delete $utf8::{miniperl} }
181
182                 # All property names are matched caselessly
183                 my $property_and_table = CORE::lc $type;
184                 print STDERR __LINE__, ": $property_and_table\n" if DEBUG;
185
186                 # See if is of the compound form 'property=value', where the
187                 # value indicates the table we should use.
188                 my ($property, $table, @remainder) =
189                                     split /\s*[:=]\s*/, $property_and_table, -1;
190                 if (@remainder) {
191                     pop @recursed if @recursed;
192                     return $type;
193                 }
194
195                 my $prefix;
196                 if (! defined $table) {
197                         
198                     # Here, is the single form.  The property becomes empty, and
199                     # the whole value is the table.
200                     $table = $property;
201                     $prefix = $property = "";
202                 } else {
203                     print STDERR __LINE__, ": $property\n" if DEBUG;
204
205                     # Here it is the compound property=table form.  The property
206                     # name is always loosely matched, and always can have an
207                     # optional 'is' prefix (which isn't true in the single
208                     # form).
209                     $property = _loose_name($property) =~ s/^is//r;
210
211                     # And convert to canonical form.  Quit if not valid.
212                     $property = $utf8::loose_property_name_of{$property};
213                     if (! defined $property) {
214                         pop @recursed if @recursed;
215                         return $type;
216                     }
217
218                     $prefix = "$property=";
219
220                     # If the rhs looks like it is a number...
221                     print STDERR __LINE__, ": table=$table\n" if DEBUG;
222                     if ($table =~ qr{ ^ [ \s 0-9 _  + / . -]+ $ }x) {
223                         print STDERR __LINE__, ": table=$table\n" if DEBUG;
224
225                         # Don't allow leading nor trailing slashes 
226                         if ($table =~ / ^ \/ | \/ $ /x) {
227                             pop @recursed if @recursed;
228                             return $type;
229                         }
230
231                         # Split on slash, in case it is a rational, like \p{1/5}
232                         my @parts = split qr{ \s* / \s* }x, $table, -1;
233                         print __LINE__, ": $type\n" if @parts > 2 && DEBUG;
234
235                         # Can have maximum of one slash
236                         if (@parts > 2) {
237                             pop @recursed if @recursed;
238                             return $type;
239                         }
240
241                         foreach my $part (@parts) {
242                             print __LINE__, ": part=$part\n" if DEBUG;
243
244                             $part =~ s/^\+\s*//;    # Remove leading plus
245                             $part =~ s/^-\s*/-/;    # Remove blanks after unary
246                                                     # minus
247
248                             # Remove underscores between digits.
249                             $part =~ s/(?<= [0-9] ) _ (?= [0-9] ) //xg;
250
251                             # No leading zeros (but don't make a single '0'
252                             # into a null string)
253                             $part =~ s/ ^ ( -? ) 0+ /$1/x;
254                             $part .= '0' if $part eq '-' || $part eq "";
255
256                             # No trailing zeros after a decimal point
257                             $part =~ s/ ( \. .*? ) 0+ $ /$1/x;
258
259                             # Begin with a 0 if a leading decimal point
260                             $part =~ s/ ^ ( -? ) \. /${1}0./x;
261
262                             # Ensure not a trailing decimal point: turn into an
263                             # integer
264                             $part =~ s/ \. $ //x;
265
266                             print STDERR __LINE__, ": part=$part\n" if DEBUG;
267                             #return $type if $part eq "";
268                             
269                             # Result better look like a number.  (This test is
270                             # needed because, for example could have a plus in
271                             # the middle.)
272                             if ($part !~ / ^ -? [0-9]+ ( \. [0-9]+)? $ /x) {
273                                 pop @recursed if @recursed;
274                                 return $type;
275                             }
276                         }
277
278                         #  If a rational...
279                         if (@parts == 2) {
280
281                             # If denominator is negative, get rid of it, and ...
282                             if ($parts[1] =~ s/^-//) {
283
284                                 # If numerator is also negative, convert the
285                                 # whole thing to positive, or move the minus to
286                                 # the numerator
287                                 if ($parts[0] !~ s/^-//) {
288                                     $parts[0] = '-' . $parts[0];
289                                 }
290                             }
291                             $table = join '/', @parts;
292                         }
293                         elsif ($property ne 'nv' || $parts[0] !~ /\./) {
294
295                             # Here is not numeric value, or doesn't have a
296                             # decimal point.  No further manipulation is
297                             # necessary.  (Note the hard-coded property name.
298                             # This could fail if other properties eventually
299                             # had fractions as well; perhaps the cjk ones
300                             # could evolve to do that.  This hard-coding could
301                             # be fixed by mktables generating a list of
302                             # properties that could have fractions.)
303                             $table = $parts[0];
304                         } else {
305
306                             # Here is a floating point numeric_value.  Try to
307                             # convert to rational.  First see if is in the list
308                             # of known ones.
309                             if (exists $utf8::nv_floating_to_rational{$parts[0]}) {
310                                 $table = $utf8::nv_floating_to_rational{$parts[0]};
311                             } else {
312
313                                 # Here not in the list.  See if is close
314                                 # enough to something in the list.  First
315                                 # determine what 'close enough' means.  It has
316                                 # to be as tight as what mktables says is the
317                                 # maximum slop, and as tight as how many
318                                 # digits we were passed.  That is, if the user
319                                 # said .667, .6667, .66667, etc.  we match as
320                                 # many digits as they passed until get to
321                                 # where it doesn't matter any more due to the
322                                 # machine's precision.  If they said .6666668,
323                                 # we fail.
324                                 (my $fraction = $parts[0]) =~ s/^.*\.//;
325                                 my $epsilon = 10 ** - (length($fraction));
326                                 if ($epsilon > $utf8::max_floating_slop) {
327                                     $epsilon = $utf8::max_floating_slop;
328                                 }
329
330                                 # But it can't be tighter than the minimum
331                                 # precision for this machine.  If haven't
332                                 # already calculated that minimum, do so now.
333                                 if (! defined $min_floating_slop) {
334
335                                     # Keep going down an order of magnitude
336                                     # until find that adding this quantity to
337                                     # 1 remains 1; but put an upper limit on
338                                     # this so in case this algorithm doesn't
339                                     # work properly on some platform, that we
340                                     # won't loop forever.
341                                     my $count = 0;
342                                     $min_floating_slop = 1;
343                                     while (1+ $min_floating_slop != 1
344                                            && $count++ < 50)
345                                     {
346                                         my $next = $min_floating_slop / 10;
347                                         last if $next == 0; # If underflows,
348                                                             # use previous one
349                                         $min_floating_slop = $next;
350                                         print STDERR __LINE__, ": min_float_slop=$min_floating_slop\n" if DEBUG;
351                                     }
352
353                                     # Back off a couple orders of magnitude,
354                                     # just to be safe.
355                                     $min_floating_slop *= 100;
356                                 }
357                                     
358                                 if ($epsilon < $min_floating_slop) {
359                                     $epsilon = $min_floating_slop;
360                                 }
361                                 print STDERR __LINE__, ": fraction=.$fraction; epsilon=$epsilon\n" if DEBUG;
362
363                                 undef $table;
364
365                                 # And for each possible rational in the table,
366                                 # see if it is within epsilon of the input.
367                                 foreach my $official
368                                         (keys %utf8::nv_floating_to_rational)
369                                 {
370                                     print STDERR __LINE__, ": epsilon=$epsilon, official=$official, diff=", abs($parts[0] - $official), "\n" if DEBUG;
371                                     if (abs($parts[0] - $official) < $epsilon) {
372                                       $table =
373                                       $utf8::nv_floating_to_rational{$official};
374                                         last;
375                                     }
376                                 }
377
378                                 # Quit if didn't find one.
379                                 if (! defined $table) {
380                                     pop @recursed if @recursed;
381                                     return $type;
382                                 }
383                             }
384                         }
385                         print STDERR __LINE__, ": $property=$table\n" if DEBUG;
386                     }
387                 }
388
389                 # Combine lhs (if any) and rhs to get something that matches
390                 # the syntax of the lookups.
391                 $property_and_table = "$prefix$table";
392                 print STDERR __LINE__, ": $property_and_table\n" if DEBUG;
393
394                 # First try stricter matching.
395                 $file = $utf8::stricter_to_file_of{$property_and_table};
396
397                 # If didn't find it, try again with looser matching by editing
398                 # out the applicable characters on the rhs and looking up
399                 # again.
400                 if (! defined $file) {
401                     $table = _loose_name($table);
402                     $property_and_table = "$prefix$table";
403                     print STDERR __LINE__, ": $property_and_table\n" if DEBUG;
404                     $file = $utf8::loose_to_file_of{$property_and_table};
405                 }
406
407                 # Add the constant and go fetch it in.
408                 if (defined $file) {
409
410                     # If the file name contains a !, it means to invert.  The
411                     # 0+ makes sure result is numeric
412                     $invert_it = 0 + $file =~ s/!//;
413
414                     if ($utf8::why_deprecated{$file}) {
415                         warnings::warnif('deprecated', "Use of '$type' in \\p{} or \\P{} is deprecated because: $utf8::why_deprecated{$file};");
416                     }
417
418                     if ($caseless
419                         && exists $utf8::caseless_equivalent{$property_and_table})
420                     {
421                         $file = $utf8::caseless_equivalent{$property_and_table};
422                     }
423
424                     # The pseudo-directory '#' means that there really isn't a
425                     # file to read, the data is in-line as part of the string;
426                     # we extract it below.
427                     $file = "$unicore_dir/lib/$file.pl" unless $file =~ m!^#/!;
428                     last GETFILE;
429                 }
430                 print STDERR __LINE__, ": didn't find $property_and_table\n" if DEBUG;
431
432                 ##
433                 ## Last attempt -- see if it's a standard "To" name
434                 ## (e.g. "ToLower")  ToTitle is used by ucfirst().
435                 ## The user-level way to access ToDigit() and ToFold()
436                 ## is to use Unicode::UCD.
437                 ##
438                 # Only check if caller wants non-binary
439                 my $retried = 0;
440                 if ($minbits != 1 && $property_and_table =~ s/^to//) {{
441                     # Look input up in list of properties for which we have
442                     # mapping files.
443                     if (defined ($file =
444                           $utf8::loose_property_to_file_of{$property_and_table}))
445                     {
446                         $type = $utf8::file_to_swash_name{$file};
447                         print STDERR __LINE__, ": type set to $type\n" if DEBUG;
448                         $file = "$unicore_dir/$file.pl";
449                         last GETFILE;
450                     }   # If that fails see if there is a corresponding binary
451                         # property file
452                     elsif (defined ($file =
453                                    $utf8::loose_to_file_of{$property_and_table}))
454                     {
455
456                         # Here, there is no map file for the property we are
457                         # trying to get the map of, but this is a binary
458                         # property, and there is a file for it that can easily
459                         # be translated to a mapping.
460
461                         # In the case of properties that are forced to binary,
462                         # they are a combination.  We return the actual
463                         # mapping instead of the binary.  If the input is
464                         # something like 'Tocjkkiicore', it will be found in
465                         # %loose_property_to_file_of above as => 'To/kIICore'.
466                         # But the form like ToIskiicore won't be.  To fix
467                         # this, it was easiest to do it here.  These
468                         # properties are the complements of the default
469                         # property, so there is an entry in %loose_to_file_of
470                         # that is 'iskiicore' => '!kIICore/N', If we find such
471                         # an entry, strip off things and try again, which
472                         # should find the entry in %loose_property_to_file_of.
473                         # Actual binary properties that are of this form, such
474                         # as this entry: 'ishrkt' => '!Perl/Any' will also be
475                         # retried, but won't be in %loose_property_to_file_of,
476                         # and instead the next time through, it will find
477                         # 'hrkt' => '!Perl/Any' and proceed.
478                         redo if ! $retried
479                                 && $file =~ /^!/
480                                 && $property_and_table =~ s/^is//;
481
482                         # This is a binary property.  Setting this here causes
483                         # it to be stored as such in the cache, so if someone
484                         # comes along later looking for just a binary, they
485                         # get it.
486                         $minbits = 1;
487
488                         # The 0+ makes sure is numeric
489                         $invert_it = 0 + $file =~ s/!//;
490                         $file = "$unicore_dir/lib/$file.pl" unless $file =~ m!^#/!;
491                         last GETFILE;
492                     }
493                 } }
494
495                 ##
496                 ## If we reach this line, it's because we couldn't figure
497                 ## out what to do with $type. Ouch.
498                 ##
499
500                 pop @recursed if @recursed;
501                 return $type;
502             } # end of GETFILE block
503
504             if (defined $file) {
505                 print STDERR __LINE__, ": found it (file='$file')\n" if DEBUG;
506
507                 ##
508                 ## If we reach here, it was due to a 'last GETFILE' above
509                 ## (exception: user-defined properties and mappings), so we
510                 ## have a filename, so now we load it if we haven't already.
511
512                 # The pseudo-directory '#' means the result isn't really a
513                 # file, but is in-line, with semi-colons to be turned into
514                 # new-lines.  Since it is in-line there is no advantage to
515                 # caching the result
516                 if ($file =~ s!^#/!!) {
517                     $list = $utf8::inline_definitions[$file];
518                 }
519                 else {
520                     # Here, we have an actual file to read in and load, but it
521                     # may already have been read-in and cached.  The cache key
522                     # is the class and file to load, and whether the results
523                     # need to be inverted.
524                     my $found = $Cache{$class, $file, $invert_it};
525                     if ($found and ref($found) eq $class) {
526                         print STDERR __LINE__, ": Returning cached swash for '$class,$file,$invert_it' for \\p{$type}\n" if DEBUG;
527                         pop @recursed if @recursed;
528                         return $found;
529                     }
530
531                     local $@;
532                     local $!;
533                     $list = do $file; die $@ if $@;
534                 }
535
536                 $list_is_from_mktables = 1;
537             }
538         } # End of $type is non-null
539
540         # Here, either $type was null, or we found the requested property and
541         # read it into $list
542
543         my $extras = "";
544
545         my $bits = $minbits;
546
547         # mktables lists don't have extras, like '&utf8::prop', so don't need
548         # to separate them; also lists are already sorted, so don't need to do
549         # that.
550         if ($list && ! $list_is_from_mktables) {
551             my $taint = substr($list,0,0); # maintain taint
552
553             # Separate the extras from the code point list, and make sure
554             # user-defined properties and tr/// are well-behaved for
555             # downstream code.
556             if ($user_defined || $none) {
557                 my @tmp = split(/^/m, $list);
558                 my %seen;
559                 no warnings;
560
561                 # The extras are anything that doesn't begin with a hex digit.
562                 $extras = join '', $taint, grep /^[^0-9a-fA-F]/, @tmp;
563
564                 # Remove the extras, and sort the remaining entries by the
565                 # numeric value of their beginning hex digits, removing any
566                 # duplicates.
567                 $list = join '', $taint,
568                         map  { $_->[1] }
569                         sort { $a->[0] <=> $b->[0] }
570                         map  { /^([0-9a-fA-F]+)/; [ CORE::hex($1), $_ ] }
571                         grep { /^([0-9a-fA-F]+)/ and not $seen{$1}++ } @tmp; # XXX doesn't do ranges right
572             }
573             else {
574                 # mktables has gone to some trouble to make non-user defined
575                 # properties well-behaved, so we can skip the effort we do for
576                 # user-defined ones.  Any extras are at the very beginning of
577                 # the string.
578
579                 # This regex splits out the first lines of $list into $1 and
580                 # strips them off from $list, until we get one that begins
581                 # with a hex number, alone on the line, or followed by a tab.
582                 # Either portion may be empty.
583                 $list =~ s/ \A ( .*? )
584                             (?: \z | (?= ^ [0-9a-fA-F]+ (?: \t | $) ) )
585                           //msx;
586
587                 $extras = "$taint$1";
588             }
589         }
590
591         if ($none) {
592             my $hextra = sprintf "%04x", $none + 1;
593             $list =~ s/\tXXXX$/\t$hextra/mg;
594         }
595
596         if ($minbits != 1 && $minbits < 32) { # not binary property
597             my $top = 0;
598             while ($list =~ /^([0-9a-fA-F]+)(?:[\t]([0-9a-fA-F]+)?)(?:[ \t]([0-9a-fA-F]+))?/mg) {
599                 my $min = CORE::hex $1;
600                 my $max = defined $2 ? CORE::hex $2 : $min;
601                 my $val = defined $3 ? CORE::hex $3 : 0;
602                 $val += $max - $min if defined $3;
603                 $top = $val if $val > $top;
604             }
605             my $topbits =
606                 $top > 0xffff ? 32 :
607                 $top > 0xff ? 16 : 8;
608             $bits = $topbits if $bits < $topbits;
609         }
610
611         my @extras;
612         if ($extras) {
613             for my $x ($extras) {
614                 my $taint = substr($x,0,0); # maintain taint
615                 pos $x = 0;
616                 while ($x =~ /^([^0-9a-fA-F\n])(.*)/mg) {
617                     my $char = "$1$taint";
618                     my $name = "$2$taint";
619                     print STDERR __LINE__, ": char [$char] => name [$name]\n"
620                         if DEBUG;
621                     if ($char =~ /[-+!&]/) {
622                         my ($c,$t) = split(/::/, $name, 2);     # bogus use of ::, really
623                         my $subobj;
624                         if ($c eq 'utf8') {
625                             $subobj = utf8->SWASHNEW($t, "", $minbits, 0);
626                         }
627                         elsif (exists &$name) {
628                             $subobj = utf8->SWASHNEW($name, "", $minbits, 0);
629                         }
630                         elsif ($c =~ /^([0-9a-fA-F]+)/) {
631                             $subobj = utf8->SWASHNEW("", $c, $minbits, 0);
632                         }
633                         print STDERR __LINE__, ": returned from getting sub object for $name\n" if DEBUG;
634                         if (! ref $subobj) {
635                             pop @recursed if @recursed && $type;
636                             return $subobj;
637                         }
638                         push @extras, $name => $subobj;
639                         $bits = $subobj->{BITS} if $bits < $subobj->{BITS};
640                         $user_defined = $subobj->{USER_DEFINED}
641                                               if $subobj->{USER_DEFINED};
642                     }
643                 }
644             }
645         }
646
647         if (DEBUG) {
648             print STDERR __LINE__, ": CLASS = $class, TYPE => $type, BITS => $bits, NONE => $none, INVERT_IT => $invert_it, USER_DEFINED => $user_defined";
649             print STDERR "\nLIST =>\n$list" if defined $list;
650             print STDERR "\nEXTRAS =>\n$extras" if defined $extras;
651             print STDERR "\n";
652         }
653
654         my $SWASH = bless {
655             TYPE => $type,
656             BITS => $bits,
657             EXTRAS => $extras,
658             LIST => $list,
659             NONE => $none,
660             USER_DEFINED => $user_defined,
661             @extras,
662         } => $class;
663
664         if ($file) {
665             $Cache{$class, $file, $invert_it} = $SWASH;
666             if ($type
667                 && exists $utf8::SwashInfo{$type}
668                 && exists $utf8::SwashInfo{$type}{'specials_name'})
669             {
670                 my $specials_name = $utf8::SwashInfo{$type}{'specials_name'};
671                 no strict "refs";
672                 print STDERR "\nspecials_name => $specials_name\n" if DEBUG;
673                 $SWASH->{'SPECIALS'} = \%$specials_name;
674             }
675             $SWASH->{'INVERT_IT'} = $invert_it;
676         }
677
678         pop @recursed if @recursed && $type;
679
680         return $SWASH;
681     }
682 }
683
684 # Now SWASHGET is recasted into a C function S_swatch_get (see utf8.c).
685
686 1;