APIfy block_start/block_end/intro_my
[perl.git] / lib / charnames.pm
1 package charnames;
2 use strict;
3 use warnings;
4 our $VERSION = '1.41';
5 use unicore::Name;    # mktables-generated algorithmically-defined names
6 use _charnames ();    # The submodule for this where most of the work gets done
7
8 use bytes ();          # for $bytes::hint_bits
9 use re "/aa";          # Everything in here should be ASCII
10
11 # Translate between Unicode character names and their code points.
12 # This is a wrapper around the submodule C<_charnames>.  This design allows
13 # C<_charnames> to be autoloaded to enable use of \N{...}, but requires this
14 # module to be explicitly requested for the functions API.
15
16 $Carp::Internal{ (__PACKAGE__) } = 1;
17
18 sub import
19 {
20   shift; ## ignore class name
21   _charnames->import(@_);
22 }
23
24 # Cache of already looked-up values.  This is set to only contain
25 # official values, and user aliases can't override them, so scoping is
26 # not an issue.
27 my %viacode;
28
29 sub viacode {
30   return _charnames::viacode(@_);
31 }
32
33 sub vianame
34 {
35   if (@_ != 1) {
36     _charnames::carp "charnames::vianame() expects one name argument";
37     return ()
38   }
39
40   # Looks up the character name and returns its ordinal if
41   # found, undef otherwise.
42
43   my $arg = shift;
44
45   if ($arg =~ /^U\+([0-9a-fA-F]+)$/) {
46
47     # khw claims that this is poor interface design.  The function should
48     # return either a an ord or a chr for all inputs; not be bipolar.  But
49     # can't change it because of backward compatibility.  New code can use
50     # string_vianame() instead.
51     my $ord = CORE::hex $1;
52     return chr $ord if $ord <= 255 || ! ((caller 0)[8] & $bytes::hint_bits);
53     _charnames::carp _charnames::not_legal_use_bytes_msg($arg, chr $ord);
54     return;
55   }
56
57   # The first 1 arg means wants an ord returned; the second that we are in
58   # runtime, and this is the first level routine called from the user
59   return _charnames::lookup_name($arg, 1, 1);
60 } # vianame
61
62 sub string_vianame {
63
64   # Looks up the character name and returns its string representation if
65   # found, undef otherwise.
66
67   if (@_ != 1) {
68     _charnames::carp "charnames::string_vianame() expects one name argument";
69     return;
70   }
71
72   my $arg = shift;
73
74   if ($arg =~ /^U\+([0-9a-fA-F]+)$/) {
75
76     my $ord = CORE::hex $1;
77     return chr $ord if $ord <= 255 || ! ((caller 0)[8] & $bytes::hint_bits);
78
79     _charnames::carp _charnames::not_legal_use_bytes_msg($arg, chr $ord);
80     return;
81   }
82
83   # The 0 arg means wants a string returned; the 1 arg means that we are in
84   # runtime, and this is the first level routine called from the user
85   return _charnames::lookup_name($arg, 0, 1);
86 } # string_vianame
87
88 1;
89 __END__
90
91 =encoding utf8
92
93 =head1 NAME
94
95 charnames - access to Unicode character names and named character sequences; also define character names
96
97 =head1 SYNOPSIS
98
99  use charnames ':full';
100  print "\N{GREEK SMALL LETTER SIGMA} is called sigma.\n";
101  print "\N{LATIN CAPITAL LETTER E WITH VERTICAL LINE BELOW}",
102        " is an officially named sequence of two Unicode characters\n";
103
104  use charnames ':loose';
105  print "\N{Greek small-letter  sigma}",
106         "can be used to ignore case, underscores, most blanks,"
107         "and when you aren't sure if the official name has hyphens\n";
108
109  use charnames ':short';
110  print "\N{greek:Sigma} is an upper-case sigma.\n";
111
112  use charnames qw(cyrillic greek);
113  print "\N{sigma} is Greek sigma, and \N{be} is Cyrillic b.\n";
114
115  use utf8;
116  use charnames ":full", ":alias" => {
117    e_ACUTE => "LATIN SMALL LETTER E WITH ACUTE",
118    mychar => 0xE8000,  # Private use area
119    "自転車に乗る人" => "BICYCLIST"
120  };
121  print "\N{e_ACUTE} is a small letter e with an acute.\n";
122  print "\N{mychar} allows me to name private use characters.\n";
123  print "And I can create synonyms in other languages,",
124        " such as \N{自転車に乗る人} for "BICYCLIST (U+1F6B4)\n";
125
126  use charnames ();
127  print charnames::viacode(0x1234); # prints "ETHIOPIC SYLLABLE SEE"
128  printf "%04X", charnames::vianame("GOTHIC LETTER AHSA"); # prints
129                                                           # "10330"
130  print charnames::vianame("LATIN CAPITAL LETTER A"); # prints 65 on
131                                                      # ASCII platforms;
132                                                      # 193 on EBCDIC
133  print charnames::string_vianame("LATIN CAPITAL LETTER A"); # prints "A"
134
135 =head1 DESCRIPTION
136
137 Pragma C<use charnames> is used to gain access to the names of the
138 Unicode characters and named character sequences, and to allow you to define
139 your own character and character sequence names.
140
141 All forms of the pragma enable use of the following 3 functions:
142
143 =over
144
145 =item *
146
147 L</charnames::string_vianame(I<name>)> for run-time lookup of a
148 either a character name or a named character sequence, returning its string
149 representation
150
151 =item *
152
153 L</charnames::vianame(I<name>)> for run-time lookup of a
154 character name (but not a named character sequence) to get its ordinal value
155 (code point)
156
157 =item *
158
159 L</charnames::viacode(I<code>)> for run-time lookup of a code point to get its
160 Unicode name.
161
162 =back
163
164 Starting in Perl v5.16, any occurrence of C<\N{I<CHARNAME>}> sequences
165 in a double-quotish string automatically loads this module with arguments
166 C<:full> and C<:short> (described below) if it hasn't already been loaded with
167 different arguments, in order to compile the named Unicode character into
168 position in the string.  Prior to v5.16, an explicit S<C<use charnames>> was
169 required to enable this usage.  (However, prior to v5.16, the form C<S<"use
170 charnames ();">> did not enable C<\N{I<CHARNAME>}>.)
171
172 Note that C<\N{U+I<...>}>, where the I<...> is a hexadecimal number,
173 also inserts a character into a string.
174 The character it inserts is the one whose Unicode code point
175 (ordinal value) is equal to the number.  For example, C<"\N{U+263a}"> is
176 the Unicode (white background, black foreground) smiley face
177 equivalent to C<"\N{WHITE SMILING FACE}">.
178 Also note, C<\N{I<...>}> can mean a regex quantifier instead of a character
179 name, when the I<...> is a number (or comma separated pair of numbers
180 (see L<perlreref/QUANTIFIERS>), and is not related to this pragma.
181
182 The C<charnames> pragma supports arguments C<:full>, C<:loose>, C<:short>,
183 script names and L<customized aliases|/CUSTOM ALIASES>.
184
185 If C<:full> is present, for expansion of
186 C<\N{I<CHARNAME>}>, the string I<CHARNAME> is first looked up in the list of
187 standard Unicode character names.
188
189 C<:loose> is a variant of C<:full> which allows I<CHARNAME> to be less
190 precisely specified.  Details are in L</LOOSE MATCHES>.
191
192 If C<:short> is present, and
193 I<CHARNAME> has the form C<I<SCRIPT>:I<CNAME>>, then I<CNAME> is looked up
194 as a letter in script I<SCRIPT>, as described in the next paragraph.
195 Or, if C<use charnames> is used
196 with script name arguments, then for C<\N{I<CHARNAME>}> the name
197 I<CHARNAME> is looked up as a letter in the given scripts (in the
198 specified order). Customized aliases can override these, and are explained in
199 L</CUSTOM ALIASES>.
200
201 For lookup of I<CHARNAME> inside a given script I<SCRIPTNAME>,
202 this pragma looks in the table of standard Unicode names for the names
203
204   SCRIPTNAME CAPITAL LETTER CHARNAME
205   SCRIPTNAME SMALL LETTER CHARNAME
206   SCRIPTNAME LETTER CHARNAME
207
208 If I<CHARNAME> is all lowercase,
209 then the C<CAPITAL> variant is ignored, otherwise the C<SMALL> variant
210 is ignored, and both I<CHARNAME> and I<SCRIPTNAME> are converted to all
211 uppercase for look-up.  Other than that, both of them follow L<loose|/LOOSE
212 MATCHES> rules if C<:loose> is also specified; strict otherwise.
213
214 Note that C<\N{...}> is compile-time; it's a special form of string
215 constant used inside double-quotish strings; this means that you cannot
216 use variables inside the C<\N{...}>.  If you want similar run-time
217 functionality, use
218 L<charnames::string_vianame()|/charnames::string_vianame(I<name>)>.
219
220 Note, starting in Perl 5.18, the name C<BELL> refers to the Unicode character
221 U+1F514, instead of the traditional U+0007.  For the latter, use C<ALERT>
222 or C<BEL>.
223
224 It is a syntax error to use C<\N{NAME}> where C<NAME> is unknown.
225
226 For C<\N{NAME}>, it is a fatal error if C<use bytes> is in effect and the
227 input name is that of a character that won't fit into a byte (i.e., whose
228 ordinal is above 255).
229
230 Otherwise, any string that includes a C<\N{I<charname>}> or
231 C<S<\N{U+I<code point>}>> will automatically have Unicode rules (see
232 L<perlunicode/Byte and Character Semantics>).
233
234 =head1 LOOSE MATCHES
235
236 By specifying C<:loose>, Unicode's L<loose character name
237 matching|http://www.unicode.org/reports/tr44#Matching_Rules> rules are
238 selected instead of the strict exact match used otherwise.
239 That means that I<CHARNAME> doesn't have to be so precisely specified.
240 Upper/lower case doesn't matter (except with scripts as mentioned above), nor
241 do any underscores, and the only hyphens that matter are those at the
242 beginning or end of a word in the name (with one exception:  the hyphen in
243 U+1180 C<HANGUL JUNGSEONG O-E> does matter).
244 Also, blanks not adjacent to hyphens don't matter.
245 The official Unicode names are quite variable as to where they use hyphens
246 versus spaces to separate word-like units, and this option allows you to not
247 have to care as much.
248 The reason non-medial hyphens matter is because of cases like
249 U+0F60 C<TIBETAN LETTER -A> versus U+0F68 C<TIBETAN LETTER A>.
250 The hyphen here is significant, as is the space before it, and so both must be
251 included.
252
253 C<:loose> slows down look-ups by a factor of 2 to 3 versus
254 C<:full>, but the trade-off may be worth it to you.  Each individual look-up
255 takes very little time, and the results are cached, so the speed difference
256 would become a factor only in programs that do look-ups of many different
257 spellings, and probably only when those look-ups are through C<vianame()> and
258 C<string_vianame()>, since C<\N{...}> look-ups are done at compile time.
259
260 =head1 ALIASES
261
262 Starting in Unicode 6.1 and Perl v5.16, Unicode defines many abbreviations and
263 names that were formerly Perl extensions, and some additional ones that Perl
264 did not previously accept.  The list is getting too long to reproduce here,
265 but you can get the complete list from the Unicode web site:
266 L<http://www.unicode.org/Public/UNIDATA/NameAliases.txt>.
267
268 Earlier versions of Perl accepted almost all the 6.1 names.  These were most
269 extensively documented in the v5.14 version of this pod:
270 L<http://perldoc.perl.org/5.14.0/charnames.html#ALIASES>.
271
272 =head1 CUSTOM ALIASES
273
274 You can add customized aliases to standard (C<:full>) Unicode naming
275 conventions.  The aliases override any standard definitions, so, if
276 you're twisted enough, you can change C<"\N{LATIN CAPITAL LETTER A}"> to
277 mean C<"B">, etc.
278
279 Aliases must begin with a character that is alphabetic.  After that, each may
280 contain any combination of word (C<\w>) characters, SPACE (U+0020),
281 HYPHEN-MINUS (U+002D), LEFT PARENTHESIS (U+0028), RIGHT PARENTHESIS (U+0029),
282 and NO-BREAK SPACE (U+00A0).  These last three should never have been allowed
283 in names, and are retained for backwards compatibility only; NO-BREAK SPACE IS
284 currently deprecated and scheduled for removal in Perl v5.26; the other two
285 may also be
286 deprecated and removed in future releases of Perl, so don't use them for new
287 names.  (More precisely, the first character of a name you specify must be
288 something that matches all of C<\p{ID_Start}>, C<\p{Alphabetic}>, and
289 C<\p{Gc=Letter}>.  This makes sure it is what any reasonable person would view
290 as an alphabetic character.  And, the continuation characters that match C<\w>
291 must also match C<\p{ID_Continue}>.)  Starting with Perl v5.18, any Unicode
292 characters meeting the above criteria may be used; prior to that only
293 Latin1-range characters were acceptable.
294
295 An alias can map to either an official Unicode character name (not a loose
296 matched name) or to a
297 numeric code point (ordinal).  The latter is useful for assigning names
298 to code points in Unicode private use areas such as U+E800 through
299 U+F8FF.
300 A numeric code point must be a non-negative integer or a string beginning
301 with C<"U+"> or C<"0x"> with the remainder considered to be a
302 hexadecimal integer.  A literal numeric constant must be unsigned; it
303 will be interpreted as hex if it has a leading zero or contains
304 non-decimal hex digits; otherwise it will be interpreted as decimal.
305 If it begins with C<"U+">, it is interpreted as the Unicode code point;
306 otherwise it is interpreted as native.  (Only code points below 256 can
307 differ between Unicode and native.)  Thus C<U+41> is always the Latin letter
308 "A"; but C<0x41> can be "NO-BREAK SPACE" on EBCDIC platforms.
309
310 Aliases are added either by the use of anonymous hashes:
311
312     use charnames ":alias" => {
313         e_ACUTE => "LATIN SMALL LETTER E WITH ACUTE",
314         mychar1 => 0xE8000,
315         };
316     my $str = "\N{e_ACUTE}";
317
318 or by using a file containing aliases:
319
320     use charnames ":alias" => "pro";
321
322 This will try to read C<"unicore/pro_alias.pl"> from the C<@INC> path. This
323 file should return a list in plain perl:
324
325     (
326     A_GRAVE         => "LATIN CAPITAL LETTER A WITH GRAVE",
327     A_CIRCUM        => "LATIN CAPITAL LETTER A WITH CIRCUMFLEX",
328     A_DIAERES       => "LATIN CAPITAL LETTER A WITH DIAERESIS",
329     A_TILDE         => "LATIN CAPITAL LETTER A WITH TILDE",
330     A_BREVE         => "LATIN CAPITAL LETTER A WITH BREVE",
331     A_RING          => "LATIN CAPITAL LETTER A WITH RING ABOVE",
332     A_MACRON        => "LATIN CAPITAL LETTER A WITH MACRON",
333     mychar2         => "U+E8001",
334     );
335
336 Both these methods insert C<":full"> automatically as the first argument (if no
337 other argument is given), and you can give the C<":full"> explicitly as
338 well, like
339
340     use charnames ":full", ":alias" => "pro";
341
342 C<":loose"> has no effect with these.  Input names must match exactly, using
343 C<":full"> rules.
344
345 Also, both these methods currently allow only single characters to be named.
346 To name a sequence of characters, use a
347 L<custom translator|/CUSTOM TRANSLATORS> (described below).
348
349 =head1 charnames::string_vianame(I<name>)
350
351 This is a runtime equivalent to C<\N{...}>.  I<name> can be any expression
352 that evaluates to a name accepted by C<\N{...}> under the L<C<:full>
353 option|/DESCRIPTION> to C<charnames>.  In addition, any other options for the
354 controlling C<"use charnames"> in the same scope apply, like C<:loose> or any
355 L<script list, C<:short> option|/DESCRIPTION>, or L<custom aliases|/CUSTOM
356 ALIASES> you may have defined.
357
358 The only differences are due to the fact that C<string_vianame> is run-time
359 and C<\N{}> is compile time.  You can't interpolate inside a C<\N{}>, (so
360 C<\N{$variable}> doesn't work); and if the input name is unknown,
361 C<string_vianame> returns C<undef> instead of it being a syntax error.
362
363 =head1 charnames::vianame(I<name>)
364
365 This is similar to C<string_vianame>.  The main difference is that under most
366 circumstances, C<vianame> returns an ordinal code
367 point, whereas C<string_vianame> returns a string.  For example,
368
369    printf "U+%04X", charnames::vianame("FOUR TEARDROP-SPOKED ASTERISK");
370
371 prints "U+2722".
372
373 This leads to the other two differences.  Since a single code point is
374 returned, the function can't handle named character sequences, as these are
375 composed of multiple characters (it returns C<undef> for these.  And, the code
376 point can be that of any
377 character, even ones that aren't legal under the C<S<use bytes>> pragma,
378
379 See L</BUGS> for the circumstances in which the behavior differs
380 from  that described above.
381
382 =head1 charnames::viacode(I<code>)
383
384 Returns the full name of the character indicated by the numeric code.
385 For example,
386
387     print charnames::viacode(0x2722);
388
389 prints "FOUR TEARDROP-SPOKED ASTERISK".
390
391 The name returned is the "best" (defined below) official name or alias
392 for the code point, if
393 available; otherwise your custom alias for it, if defined; otherwise C<undef>.
394 This means that your alias will only be returned for code points that don't
395 have an official Unicode name (nor alias) such as private use code points.
396
397 If you define more than one name for the code point, it is indeterminate
398 which one will be returned.
399
400 As mentioned, the function returns C<undef> if no name is known for the code
401 point.  In Unicode the proper name for these is the empty string, which
402 C<undef> stringifies to.  (If you ask for a code point past the legal
403 Unicode maximum of U+10FFFF that you haven't assigned an alias to, you
404 get C<undef> plus a warning.)
405
406 The input number must be a non-negative integer, or a string beginning
407 with C<"U+"> or C<"0x"> with the remainder considered to be a
408 hexadecimal integer.  A literal numeric constant must be unsigned; it
409 will be interpreted as hex if it has a leading zero or contains
410 non-decimal hex digits; otherwise it will be interpreted as decimal.
411 If it begins with C<"U+">, it is interpreted as the Unicode code point;
412 otherwise it is interpreted as native.  (Only code points below 256 can
413 differ between Unicode and native.)  Thus C<U+41> is always the Latin letter
414 "A"; but C<0x41> can be "NO-BREAK SPACE" on EBCDIC platforms.
415
416 As mentioned above under L</ALIASES>, Unicode 6.1 defines extra names
417 (synonyms or aliases) for some code points, most of which were already
418 available as Perl extensions.  All these are accepted by C<\N{...}> and the
419 other functions in this module, but C<viacode> has to choose which one
420 name to return for a given input code point, so it returns the "best" name.
421 To understand how this works, it is helpful to know more about the Unicode
422 name properties.  All code points actually have only a single name, which
423 (starting in Unicode 2.0) can never change once a character has been assigned
424 to the code point.  But mistakes have been made in assigning names, for
425 example sometimes a clerical error was made during the publishing of the
426 Standard which caused words to be misspelled, and there was no way to correct
427 those.  The Name_Alias property was eventually created to handle these
428 situations.  If a name was wrong, a corrected synonym would be published for
429 it, using Name_Alias.  C<viacode> will return that corrected synonym as the
430 "best" name for a code point.  (It is even possible, though it hasn't happened
431 yet, that the correction itself will need to be corrected, and so another
432 Name_Alias can be created for that code point; C<viacode> will return the
433 most recent correction.)
434
435 The Unicode name for each of the control characters (such as LINE FEED) is the
436 empty string.  However almost all had names assigned by other standards, such
437 as the ASCII Standard, or were in common use.  C<viacode> returns these names
438 as the "best" ones available.  Unicode 6.1 has created Name_Aliases for each
439 of them, including alternate names, like NEW LINE.  C<viacode> uses the
440 original name, "LINE FEED" in preference to the alternate.  Similarly the
441 name returned for U+FEFF is "ZERO WIDTH NO-BREAK SPACE", not "BYTE ORDER
442 MARK".
443
444 Until Unicode 6.1, the 4 control characters U+0080, U+0081, U+0084, and U+0099
445 did not have names nor aliases.
446 To preserve backwards compatibility, any alias you define for these code
447 points will be returned by this function, in preference to the official name.
448
449 Some code points also have abbreviated names, such as "LF" or "NL".
450 C<viacode> never returns these.
451
452 Because a name correction may be added in future Unicode releases, the name
453 that C<viacode> returns may change as a result.  This is a rare event, but it
454 does happen.
455
456 =head1 CUSTOM TRANSLATORS
457
458 The mechanism of translation of C<\N{...}> escapes is general and not
459 hardwired into F<charnames.pm>.  A module can install custom
460 translations (inside the scope which C<use>s the module) with the
461 following magic incantation:
462
463     sub import {
464         shift;
465         $^H{charnames} = \&translator;
466     }
467
468 Here translator() is a subroutine which takes I<CHARNAME> as an
469 argument, and returns text to insert into the string instead of the
470 C<\N{I<CHARNAME>}> escape.
471
472 This is the only way you can create a custom named sequence of code points.
473
474 Since the text to insert should be different
475 in C<bytes> mode and out of it, the function should check the current
476 state of C<bytes>-flag as in:
477
478     use bytes ();                      # for $bytes::hint_bits
479     sub translator {
480         if ($^H & $bytes::hint_bits) {
481             return bytes_translator(@_);
482         }
483         else {
484             return utf8_translator(@_);
485         }
486     }
487
488 See L</CUSTOM ALIASES> above for restrictions on I<CHARNAME>.
489
490 Of course, C<vianame>, C<viacode>, and C<string_vianame> would need to be
491 overridden as well.
492
493 =head1 BUGS
494
495 vianame() normally returns an ordinal code point, but when the input name is of
496 the form C<U+...>, it returns a chr instead.  In this case, if C<use bytes> is
497 in effect and the character won't fit into a byte, it returns C<undef> and
498 raises a warning.
499
500 Since evaluation of the translation function (see L</CUSTOM
501 TRANSLATORS>) happens in the middle of compilation (of a string
502 literal), the translation function should not do any C<eval>s or
503 C<require>s.  This restriction should be lifted (but is low priority) in
504 a future version of Perl.
505
506 =cut
507
508 # ex: set ts=8 sts=2 sw=2 et: