Document the fact that keys() and values() are optimized
[perl.git] / pod / perlfunc.pod
1 =head1 NAME
2
3 perlfunc - Perl builtin functions
4
5 =head1 DESCRIPTION
6
7 The functions in this section can serve as terms in an expression.
8 They fall into two major categories: list operators and named unary
9 operators.  These differ in their precedence relationship with a
10 following comma.  (See the precedence table in L<perlop>.)  List
11 operators take more than one argument, while unary operators can never
12 take more than one argument.  Thus, a comma terminates the argument of
13 a unary operator, but merely separates the arguments of a list
14 operator.  A unary operator generally provides a scalar context to its
15 argument, while a list operator may provide either scalar or list
16 contexts for its arguments.  If it does both, the scalar arguments will
17 be first, and the list argument will follow.  (Note that there can ever
18 be only one such list argument.)  For instance, splice() has three scalar
19 arguments followed by a list, whereas gethostbyname() has four scalar
20 arguments.
21
22 In the syntax descriptions that follow, list operators that expect a
23 list (and provide list context for the elements of the list) are shown
24 with LIST as an argument.  Such a list may consist of any combination
25 of scalar arguments or list values; the list values will be included
26 in the list as if each individual element were interpolated at that
27 point in the list, forming a longer single-dimensional list value.
28 Elements of the LIST should be separated by commas.
29
30 Any function in the list below may be used either with or without
31 parentheses around its arguments.  (The syntax descriptions omit the
32 parentheses.)  If you use the parentheses, the simple (but occasionally
33 surprising) rule is this: It I<looks> like a function, therefore it I<is> a
34 function, and precedence doesn't matter.  Otherwise it's a list
35 operator or unary operator, and precedence does matter.  And whitespace
36 between the function and left parenthesis doesn't count--so you need to
37 be careful sometimes:
38
39     print 1+2+4;        # Prints 7.
40     print(1+2) + 4;     # Prints 3.
41     print (1+2)+4;      # Also prints 3!
42     print +(1+2)+4;     # Prints 7.
43     print ((1+2)+4);    # Prints 7.
44
45 If you run Perl with the B<-w> switch it can warn you about this.  For
46 example, the third line above produces:
47
48     print (...) interpreted as function at - line 1.
49     Useless use of integer addition in void context at - line 1.
50
51 A few functions take no arguments at all, and therefore work as neither
52 unary nor list operators.  These include such functions as C<time>
53 and C<endpwent>.  For example, C<time+86_400> always means
54 C<time() + 86_400>.
55
56 For functions that can be used in either a scalar or list context,
57 nonabortive failure is generally indicated in a scalar context by
58 returning the undefined value, and in a list context by returning the
59 null list.
60
61 Remember the following important rule: There is B<no rule> that relates
62 the behavior of an expression in list context to its behavior in scalar
63 context, or vice versa.  It might do two totally different things.
64 Each operator and function decides which sort of value it would be most
65 appropriate to return in scalar context.  Some operators return the
66 length of the list that would have been returned in list context.  Some
67 operators return the first value in the list.  Some operators return the
68 last value in the list.  Some operators return a count of successful
69 operations.  In general, they do what you want, unless you want
70 consistency.
71
72 A named array in scalar context is quite different from what would at
73 first glance appear to be a list in scalar context.  You can't get a list
74 like C<(1,2,3)> into being in scalar context, because the compiler knows
75 the context at compile time.  It would generate the scalar comma operator
76 there, not the list construction version of the comma.  That means it
77 was never a list to start with.
78
79 In general, functions in Perl that serve as wrappers for system calls
80 of the same name (like chown(2), fork(2), closedir(2), etc.) all return
81 true when they succeed and C<undef> otherwise, as is usually mentioned
82 in the descriptions below.  This is different from the C interfaces,
83 which return C<-1> on failure.  Exceptions to this rule are C<wait>,
84 C<waitpid>, and C<syscall>.  System calls also set the special C<$!>
85 variable on failure.  Other functions do not, except accidentally.
86
87 =head2 Perl Functions by Category
88
89 Here are Perl's functions (including things that look like
90 functions, like some keywords and named operators)
91 arranged by category.  Some functions appear in more
92 than one place.
93
94 =over 4
95
96 =item Functions for SCALARs or strings
97
98 C<chomp>, C<chop>, C<chr>, C<crypt>, C<hex>, C<index>, C<lc>, C<lcfirst>,
99 C<length>, C<oct>, C<ord>, C<pack>, C<q/STRING/>, C<qq/STRING/>, C<reverse>,
100 C<rindex>, C<sprintf>, C<substr>, C<tr///>, C<uc>, C<ucfirst>, C<y///>
101
102 =item Regular expressions and pattern matching
103
104 C<m//>, C<pos>, C<quotemeta>, C<s///>, C<split>, C<study>, C<qr//>
105
106 =item Numeric functions
107
108 C<abs>, C<atan2>, C<cos>, C<exp>, C<hex>, C<int>, C<log>, C<oct>, C<rand>,
109 C<sin>, C<sqrt>, C<srand>
110
111 =item Functions for real @ARRAYs
112
113 C<pop>, C<push>, C<shift>, C<splice>, C<unshift>
114
115 =item Functions for list data
116
117 C<grep>, C<join>, C<map>, C<qw/STRING/>, C<reverse>, C<sort>, C<unpack>
118
119 =item Functions for real %HASHes
120
121 C<delete>, C<each>, C<exists>, C<keys>, C<values>
122
123 =item Input and output functions
124
125 C<binmode>, C<close>, C<closedir>, C<dbmclose>, C<dbmopen>, C<die>, C<eof>,
126 C<fileno>, C<flock>, C<format>, C<getc>, C<print>, C<printf>, C<read>,
127 C<readdir>, C<rewinddir>, C<seek>, C<seekdir>, C<select>, C<syscall>,
128 C<sysread>, C<sysseek>, C<syswrite>, C<tell>, C<telldir>, C<truncate>,
129 C<warn>, C<write>
130
131 =item Functions for fixed length data or records
132
133 C<pack>, C<read>, C<syscall>, C<sysread>, C<syswrite>, C<unpack>, C<vec>
134
135 =item Functions for filehandles, files, or directories
136
137 C<-I<X>>, C<chdir>, C<chmod>, C<chown>, C<chroot>, C<fcntl>, C<glob>,
138 C<ioctl>, C<link>, C<lstat>, C<mkdir>, C<open>, C<opendir>,
139 C<readlink>, C<rename>, C<rmdir>, C<stat>, C<symlink>, C<sysopen>,
140 C<umask>, C<unlink>, C<utime>
141
142 =item Keywords related to the control flow of your perl program
143
144 C<caller>, C<continue>, C<die>, C<do>, C<dump>, C<eval>, C<exit>,
145 C<goto>, C<last>, C<next>, C<redo>, C<return>, C<sub>, C<wantarray>
146
147 =item Keywords related to scoping
148
149 C<caller>, C<import>, C<local>, C<my>, C<our>, C<package>, C<use>
150
151 =item Miscellaneous functions
152
153 C<defined>, C<dump>, C<eval>, C<formline>, C<local>, C<my>, C<our>, C<reset>,
154 C<scalar>, C<undef>, C<wantarray>
155
156 =item Functions for processes and process groups
157
158 C<alarm>, C<exec>, C<fork>, C<getpgrp>, C<getppid>, C<getpriority>, C<kill>,
159 C<pipe>, C<qx/STRING/>, C<setpgrp>, C<setpriority>, C<sleep>, C<system>,
160 C<times>, C<wait>, C<waitpid>
161
162 =item Keywords related to perl modules
163
164 C<do>, C<import>, C<no>, C<package>, C<require>, C<use>
165
166 =item Keywords related to classes and object-orientedness
167
168 C<bless>, C<dbmclose>, C<dbmopen>, C<package>, C<ref>, C<tie>, C<tied>,
169 C<untie>, C<use>
170
171 =item Low-level socket functions
172
173 C<accept>, C<bind>, C<connect>, C<getpeername>, C<getsockname>,
174 C<getsockopt>, C<listen>, C<recv>, C<send>, C<setsockopt>, C<shutdown>,
175 C<socket>, C<socketpair>
176
177 =item System V interprocess communication functions
178
179 C<msgctl>, C<msgget>, C<msgrcv>, C<msgsnd>, C<semctl>, C<semget>, C<semop>,
180 C<shmctl>, C<shmget>, C<shmread>, C<shmwrite>
181
182 =item Fetching user and group info
183
184 C<endgrent>, C<endhostent>, C<endnetent>, C<endpwent>, C<getgrent>,
185 C<getgrgid>, C<getgrnam>, C<getlogin>, C<getpwent>, C<getpwnam>,
186 C<getpwuid>, C<setgrent>, C<setpwent>
187
188 =item Fetching network info
189
190 C<endprotoent>, C<endservent>, C<gethostbyaddr>, C<gethostbyname>,
191 C<gethostent>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
192 C<getprotobyname>, C<getprotobynumber>, C<getprotoent>,
193 C<getservbyname>, C<getservbyport>, C<getservent>, C<sethostent>,
194 C<setnetent>, C<setprotoent>, C<setservent>
195
196 =item Time-related functions
197
198 C<gmtime>, C<localtime>, C<time>, C<times>
199
200 =item Functions new in perl5
201
202 C<abs>, C<bless>, C<chomp>, C<chr>, C<exists>, C<formline>, C<glob>,
203 C<import>, C<lc>, C<lcfirst>, C<map>, C<my>, C<no>, C<our>, C<prototype>,
204 C<qx>, C<qw>, C<readline>, C<readpipe>, C<ref>, C<sub*>, C<sysopen>, C<tie>,
205 C<tied>, C<uc>, C<ucfirst>, C<untie>, C<use>
206
207 * - C<sub> was a keyword in perl4, but in perl5 it is an
208 operator, which can be used in expressions.
209
210 =item Functions obsoleted in perl5
211
212 C<dbmclose>, C<dbmopen>
213
214 =back
215
216 =head2 Portability
217
218 Perl was born in Unix and can therefore access all common Unix
219 system calls.  In non-Unix environments, the functionality of some
220 Unix system calls may not be available, or details of the available
221 functionality may differ slightly.  The Perl functions affected
222 by this are:
223
224 C<-X>, C<binmode>, C<chmod>, C<chown>, C<chroot>, C<crypt>,
225 C<dbmclose>, C<dbmopen>, C<dump>, C<endgrent>, C<endhostent>,
226 C<endnetent>, C<endprotoent>, C<endpwent>, C<endservent>, C<exec>,
227 C<fcntl>, C<flock>, C<fork>, C<getgrent>, C<getgrgid>, C<gethostbyname>,
228 C<gethostent>, C<getlogin>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
229 C<getppid>, C<getprgp>, C<getpriority>, C<getprotobynumber>,
230 C<getprotoent>, C<getpwent>, C<getpwnam>, C<getpwuid>,
231 C<getservbyport>, C<getservent>, C<getsockopt>, C<glob>, C<ioctl>,
232 C<kill>, C<link>, C<lstat>, C<msgctl>, C<msgget>, C<msgrcv>,
233 C<msgsnd>, C<open>, C<pipe>, C<readlink>, C<rename>, C<select>, C<semctl>,
234 C<semget>, C<semop>, C<setgrent>, C<sethostent>, C<setnetent>,
235 C<setpgrp>, C<setpriority>, C<setprotoent>, C<setpwent>,
236 C<setservent>, C<setsockopt>, C<shmctl>, C<shmget>, C<shmread>,
237 C<shmwrite>, C<socket>, C<socketpair>,
238 C<stat>, C<symlink>, C<syscall>, C<sysopen>, C<system>,
239 C<times>, C<truncate>, C<umask>, C<unlink>,
240 C<utime>, C<wait>, C<waitpid>
241
242 For more information about the portability of these functions, see
243 L<perlport> and other available platform-specific documentation.
244
245 =head2 Alphabetical Listing of Perl Functions
246
247 =over 8
248
249 =item -X FILEHANDLE
250
251 =item -X EXPR
252
253 =item -X
254
255 A file test, where X is one of the letters listed below.  This unary
256 operator takes one argument, either a filename or a filehandle, and
257 tests the associated file to see if something is true about it.  If the
258 argument is omitted, tests C<$_>, except for C<-t>, which tests STDIN.
259 Unless otherwise documented, it returns C<1> for true and C<''> for false, or
260 the undefined value if the file doesn't exist.  Despite the funny
261 names, precedence is the same as any other named unary operator, and
262 the argument may be parenthesized like any other unary operator.  The
263 operator may be any of:
264 X<-r>X<-w>X<-x>X<-o>X<-R>X<-W>X<-X>X<-O>X<-e>X<-z>X<-s>X<-f>X<-d>X<-l>X<-p>
265 X<-S>X<-b>X<-c>X<-t>X<-u>X<-g>X<-k>X<-T>X<-B>X<-M>X<-A>X<-C>
266
267     -r  File is readable by effective uid/gid.
268     -w  File is writable by effective uid/gid.
269     -x  File is executable by effective uid/gid.
270     -o  File is owned by effective uid.
271
272     -R  File is readable by real uid/gid.
273     -W  File is writable by real uid/gid.
274     -X  File is executable by real uid/gid.
275     -O  File is owned by real uid.
276
277     -e  File exists.
278     -z  File has zero size (is empty).
279     -s  File has nonzero size (returns size in bytes).
280
281     -f  File is a plain file.
282     -d  File is a directory.
283     -l  File is a symbolic link.
284     -p  File is a named pipe (FIFO), or Filehandle is a pipe.
285     -S  File is a socket.
286     -b  File is a block special file.
287     -c  File is a character special file.
288     -t  Filehandle is opened to a tty.
289
290     -u  File has setuid bit set.
291     -g  File has setgid bit set.
292     -k  File has sticky bit set.
293
294     -T  File is an ASCII text file (heuristic guess).
295     -B  File is a "binary" file (opposite of -T).
296
297     -M  Script start time minus file modification time, in days.
298     -A  Same for access time.
299     -C  Same for inode change time (Unix, may differ for other platforms)
300
301 Example:
302
303     while (<>) {
304         chomp;
305         next unless -f $_;      # ignore specials
306         #...
307     }
308
309 The interpretation of the file permission operators C<-r>, C<-R>,
310 C<-w>, C<-W>, C<-x>, and C<-X> is by default based solely on the mode
311 of the file and the uids and gids of the user.  There may be other
312 reasons you can't actually read, write, or execute the file.  Such
313 reasons may be for example network filesystem access controls, ACLs
314 (access control lists), read-only filesystems, and unrecognized
315 executable formats.
316
317 Also note that, for the superuser on the local filesystems, the C<-r>,
318 C<-R>, C<-w>, and C<-W> tests always return 1, and C<-x> and C<-X> return 1
319 if any execute bit is set in the mode.  Scripts run by the superuser
320 may thus need to do a stat() to determine the actual mode of the file,
321 or temporarily set their effective uid to something else.
322
323 If you are using ACLs, there is a pragma called C<filetest> that may
324 produce more accurate results than the bare stat() mode bits.
325 When under the C<use filetest 'access'> the above-mentioned filetests
326 will test whether the permission can (not) be granted using the
327 access() family of system calls.  Also note that the C<-x> and C<-X> may
328 under this pragma return true even if there are no execute permission
329 bits set (nor any extra execute permission ACLs).  This strangeness is
330 due to the underlying system calls' definitions.  Read the
331 documentation for the C<filetest> pragma for more information.
332
333 Note that C<-s/a/b/> does not do a negated substitution.  Saying
334 C<-exp($foo)> still works as expected, however--only single letters
335 following a minus are interpreted as file tests.
336
337 The C<-T> and C<-B> switches work as follows.  The first block or so of the
338 file is examined for odd characters such as strange control codes or
339 characters with the high bit set.  If too many strange characters (>30%)
340 are found, it's a C<-B> file, otherwise it's a C<-T> file.  Also, any file
341 containing null in the first block is considered a binary file.  If C<-T>
342 or C<-B> is used on a filehandle, the current IO buffer is examined
343 rather than the first block.  Both C<-T> and C<-B> return true on a null
344 file, or a file at EOF when testing a filehandle.  Because you have to
345 read a file to do the C<-T> test, on most occasions you want to use a C<-f>
346 against the file first, as in C<next unless -f $file && -T $file>.
347
348 If any of the file tests (or either the C<stat> or C<lstat> operators) are given
349 the special filehandle consisting of a solitary underline, then the stat
350 structure of the previous file test (or stat operator) is used, saving
351 a system call.  (This doesn't work with C<-t>, and you need to remember
352 that lstat() and C<-l> will leave values in the stat structure for the
353 symbolic link, not the real file.)  (Also, if the stat buffer was filled by
354 a C<lstat> call, C<-T> and C<-B> will reset it with the results of C<stat _>).
355 Example:
356
357     print "Can do.\n" if -r $a || -w _ || -x _;
358
359     stat($filename);
360     print "Readable\n" if -r _;
361     print "Writable\n" if -w _;
362     print "Executable\n" if -x _;
363     print "Setuid\n" if -u _;
364     print "Setgid\n" if -g _;
365     print "Sticky\n" if -k _;
366     print "Text\n" if -T _;
367     print "Binary\n" if -B _;
368
369 =item abs VALUE
370
371 =item abs
372
373 Returns the absolute value of its argument.
374 If VALUE is omitted, uses C<$_>.
375
376 =item accept NEWSOCKET,GENERICSOCKET
377
378 Accepts an incoming socket connect, just as the accept(2) system call
379 does.  Returns the packed address if it succeeded, false otherwise.
380 See the example in L<perlipc/"Sockets: Client/Server Communication">.
381
382 On systems that support a close-on-exec flag on files, the flag will
383 be set for the newly opened file descriptor, as determined by the
384 value of $^F.  See L<perlvar/$^F>.
385
386 =item alarm SECONDS
387
388 =item alarm
389
390 Arranges to have a SIGALRM delivered to this process after the
391 specified number of wallclock seconds have elapsed.  If SECONDS is not
392 specified, the value stored in C<$_> is used. (On some machines,
393 unfortunately, the elapsed time may be up to one second less or more
394 than you specified because of how seconds are counted, and process
395 scheduling may delay the delivery of the signal even further.)
396
397 Only one timer may be counting at once.  Each call disables the
398 previous timer, and an argument of C<0> may be supplied to cancel the
399 previous timer without starting a new one.  The returned value is the
400 amount of time remaining on the previous timer.
401
402 For delays of finer granularity than one second, you may use Perl's
403 four-argument version of select() leaving the first three arguments
404 undefined, or you might be able to use the C<syscall> interface to
405 access setitimer(2) if your system supports it.  The Time::HiRes
406 module (from CPAN, and starting from Perl 5.8 part of the standard
407 distribution) may also prove useful.
408
409 It is usually a mistake to intermix C<alarm> and C<sleep> calls.
410 (C<sleep> may be internally implemented in your system with C<alarm>)
411
412 If you want to use C<alarm> to time out a system call you need to use an
413 C<eval>/C<die> pair.  You can't rely on the alarm causing the system call to
414 fail with C<$!> set to C<EINTR> because Perl sets up signal handlers to
415 restart system calls on some systems.  Using C<eval>/C<die> always works,
416 modulo the caveats given in L<perlipc/"Signals">.
417
418     eval {
419         local $SIG{ALRM} = sub { die "alarm\n" }; # NB: \n required
420         alarm $timeout;
421         $nread = sysread SOCKET, $buffer, $size;
422         alarm 0;
423     };
424     if ($@) {
425         die unless $@ eq "alarm\n";   # propagate unexpected errors
426         # timed out
427     }
428     else {
429         # didn't
430     }
431
432 For more information see L<perlipc>.
433
434 =item atan2 Y,X
435
436 Returns the arctangent of Y/X in the range -PI to PI.
437
438 For the tangent operation, you may use the C<Math::Trig::tan>
439 function, or use the familiar relation:
440
441     sub tan { sin($_[0]) / cos($_[0])  }
442
443 =item bind SOCKET,NAME
444
445 Binds a network address to a socket, just as the bind system call
446 does.  Returns true if it succeeded, false otherwise.  NAME should be a
447 packed address of the appropriate type for the socket.  See the examples in
448 L<perlipc/"Sockets: Client/Server Communication">.
449
450 =item binmode FILEHANDLE, LAYER
451
452 =item binmode FILEHANDLE
453
454 Arranges for FILEHANDLE to be read or written in "binary" or "text"
455 mode on systems where the run-time libraries distinguish between
456 binary and text files.  If FILEHANDLE is an expression, the value is
457 taken as the name of the filehandle.  Returns true on success,
458 otherwise it returns C<undef> and sets C<$!> (errno).
459
460 On some systems (in general, DOS and Windows-based systems) binmode()
461 is necessary when you're not working with a text file.  For the sake
462 of portability it is a good idea to always use it when appropriate,
463 and to never use it when it isn't appropriate.  Also, people can
464 set their I/O to be by default UTF-8 encoded Unicode, not bytes.
465
466 In other words: regardless of platform, use binmode() on binary data,
467 like for example images.
468
469 If LAYER is present it is a single string, but may contain multiple
470 directives. The directives alter the behaviour of the file handle.
471 When LAYER is present using binmode on text file makes sense.
472
473 If LAYER is omitted or specified as C<:raw> the filehandle is made
474 suitable for passing binary data. This includes turning off possible CRLF
475 translation and marking it as bytes (as opposed to Unicode characters).
476 Note that, despite what may be implied in I<"Programming Perl"> (the
477 Camel) or elsewhere, C<:raw> is I<not> the simply inverse of C<:crlf>
478 -- other layers which would affect binary nature of the stream are
479 I<also> disabled. See L<PerlIO>, L<perlrun> and the discussion about the
480 PERLIO environment variable.
481
482 The C<:bytes>, C<:crlf>, and C<:utf8>, and any other directives of the
483 form C<:...>, are called I/O I<layers>.  The C<open> pragma can be used to
484 establish default I/O layers.  See L<open>.
485
486 I<The LAYER parameter of the binmode() function is described as "DISCIPLINE"
487 in "Programming Perl, 3rd Edition".  However, since the publishing of this
488 book, by many known as "Camel III", the consensus of the naming of this
489 functionality has moved from "discipline" to "layer".  All documentation
490 of this version of Perl therefore refers to "layers" rather than to
491 "disciplines".  Now back to the regularly scheduled documentation...>
492
493 To mark FILEHANDLE as UTF-8, use C<:utf8>.
494
495 In general, binmode() should be called after open() but before any I/O
496 is done on the filehandle.  Calling binmode() will normally flush any
497 pending buffered output data (and perhaps pending input data) on the
498 handle.  An exception to this is the C<:encoding> layer that
499 changes the default character encoding of the handle, see L<open>.
500 The C<:encoding> layer sometimes needs to be called in
501 mid-stream, and it doesn't flush the stream.  The C<:encoding>
502 also implicitly pushes on top of itself the C<:utf8> layer because
503 internally Perl will operate on UTF-8 encoded Unicode characters.
504
505 The operating system, device drivers, C libraries, and Perl run-time
506 system all work together to let the programmer treat a single
507 character (C<\n>) as the line terminator, irrespective of the external
508 representation.  On many operating systems, the native text file
509 representation matches the internal representation, but on some
510 platforms the external representation of C<\n> is made up of more than
511 one character.
512
513 Mac OS, all variants of Unix, and Stream_LF files on VMS use a single
514 character to end each line in the external representation of text (even
515 though that single character is CARRIAGE RETURN on Mac OS and LINE FEED
516 on Unix and most VMS files). In other systems like OS/2, DOS and the
517 various flavors of MS-Windows your program sees a C<\n> as a simple C<\cJ>,
518 but what's stored in text files are the two characters C<\cM\cJ>.  That
519 means that, if you don't use binmode() on these systems, C<\cM\cJ>
520 sequences on disk will be converted to C<\n> on input, and any C<\n> in
521 your program will be converted back to C<\cM\cJ> on output.  This is what
522 you want for text files, but it can be disastrous for binary files.
523
524 Another consequence of using binmode() (on some systems) is that
525 special end-of-file markers will be seen as part of the data stream.
526 For systems from the Microsoft family this means that if your binary
527 data contains C<\cZ>, the I/O subsystem will regard it as the end of
528 the file, unless you use binmode().
529
530 binmode() is not only important for readline() and print() operations,
531 but also when using read(), seek(), sysread(), syswrite() and tell()
532 (see L<perlport> for more details).  See the C<$/> and C<$\> variables
533 in L<perlvar> for how to manually set your input and output
534 line-termination sequences.
535
536 =item bless REF,CLASSNAME
537
538 =item bless REF
539
540 This function tells the thingy referenced by REF that it is now an object
541 in the CLASSNAME package.  If CLASSNAME is omitted, the current package
542 is used.  Because a C<bless> is often the last thing in a constructor,
543 it returns the reference for convenience.  Always use the two-argument
544 version if the function doing the blessing might be inherited by a
545 derived class.  See L<perltoot> and L<perlobj> for more about the blessing
546 (and blessings) of objects.
547
548 Consider always blessing objects in CLASSNAMEs that are mixed case.
549 Namespaces with all lowercase names are considered reserved for
550 Perl pragmata.  Builtin types have all uppercase names, so to prevent
551 confusion, you may wish to avoid such package names as well.  Make sure
552 that CLASSNAME is a true value.
553
554 See L<perlmod/"Perl Modules">.
555
556 =item caller EXPR
557
558 =item caller
559
560 Returns the context of the current subroutine call.  In scalar context,
561 returns the caller's package name if there is a caller, that is, if
562 we're in a subroutine or C<eval> or C<require>, and the undefined value
563 otherwise.  In list context, returns
564
565     ($package, $filename, $line) = caller;
566
567 With EXPR, it returns some extra information that the debugger uses to
568 print a stack trace.  The value of EXPR indicates how many call frames
569 to go back before the current one.
570
571     ($package, $filename, $line, $subroutine, $hasargs,
572     $wantarray, $evaltext, $is_require, $hints, $bitmask) = caller($i);
573
574 Here $subroutine may be C<(eval)> if the frame is not a subroutine
575 call, but an C<eval>.  In such a case additional elements $evaltext and
576 C<$is_require> are set: C<$is_require> is true if the frame is created by a
577 C<require> or C<use> statement, $evaltext contains the text of the
578 C<eval EXPR> statement.  In particular, for an C<eval BLOCK> statement,
579 $filename is C<(eval)>, but $evaltext is undefined.  (Note also that
580 each C<use> statement creates a C<require> frame inside an C<eval EXPR>
581 frame.)  $subroutine may also be C<(unknown)> if this particular
582 subroutine happens to have been deleted from the symbol table.
583 C<$hasargs> is true if a new instance of C<@_> was set up for the frame.
584 C<$hints> and C<$bitmask> contain pragmatic hints that the caller was
585 compiled with.  The C<$hints> and C<$bitmask> values are subject to change
586 between versions of Perl, and are not meant for external use.
587
588 Furthermore, when called from within the DB package, caller returns more
589 detailed information: it sets the list variable C<@DB::args> to be the
590 arguments with which the subroutine was invoked.
591
592 Be aware that the optimizer might have optimized call frames away before
593 C<caller> had a chance to get the information.  That means that C<caller(N)>
594 might not return information about the call frame you expect it do, for
595 C<< N > 1 >>.  In particular, C<@DB::args> might have information from the
596 previous time C<caller> was called.
597
598 =item chdir EXPR
599
600 Changes the working directory to EXPR, if possible. If EXPR is omitted,
601 changes to the directory specified by C<$ENV{HOME}>, if set; if not,
602 changes to the directory specified by C<$ENV{LOGDIR}>. (Under VMS, the
603 variable C<$ENV{SYS$LOGIN}> is also checked, and used if it is set.) If
604 neither is set, C<chdir> does nothing. It returns true upon success,
605 false otherwise. See the example under C<die>.
606
607 =item chmod LIST
608
609 Changes the permissions of a list of files.  The first element of the
610 list must be the numerical mode, which should probably be an octal
611 number, and which definitely should I<not> a string of octal digits:
612 C<0644> is okay, C<'0644'> is not.  Returns the number of files
613 successfully changed.  See also L</oct>, if all you have is a string.
614
615     $cnt = chmod 0755, 'foo', 'bar';
616     chmod 0755, @executables;
617     $mode = '0644'; chmod $mode, 'foo';      # !!! sets mode to
618                                              # --w----r-T
619     $mode = '0644'; chmod oct($mode), 'foo'; # this is better
620     $mode = 0644;   chmod $mode, 'foo';      # this is best
621
622 You can also import the symbolic C<S_I*> constants from the Fcntl
623 module:
624
625     use Fcntl ':mode';
626
627     chmod S_IRWXU|S_IRGRP|S_IXGRP|S_IROTH|S_IXOTH, @executables;
628     # This is identical to the chmod 0755 of the above example.
629
630 =item chomp VARIABLE
631
632 =item chomp( LIST )
633
634 =item chomp
635
636 This safer version of L</chop> removes any trailing string
637 that corresponds to the current value of C<$/> (also known as
638 $INPUT_RECORD_SEPARATOR in the C<English> module).  It returns the total
639 number of characters removed from all its arguments.  It's often used to
640 remove the newline from the end of an input record when you're worried
641 that the final record may be missing its newline.  When in paragraph
642 mode (C<$/ = "">), it removes all trailing newlines from the string.
643 When in slurp mode (C<$/ = undef>) or fixed-length record mode (C<$/> is
644 a reference to an integer or the like, see L<perlvar>) chomp() won't
645 remove anything.
646 If VARIABLE is omitted, it chomps C<$_>.  Example:
647
648     while (<>) {
649         chomp;  # avoid \n on last field
650         @array = split(/:/);
651         # ...
652     }
653
654 If VARIABLE is a hash, it chomps the hash's values, but not its keys.
655
656 You can actually chomp anything that's an lvalue, including an assignment:
657
658     chomp($cwd = `pwd`);
659     chomp($answer = <STDIN>);
660
661 If you chomp a list, each element is chomped, and the total number of
662 characters removed is returned.
663
664 Note that parentheses are necessary when you're chomping anything
665 that is not a simple variable.  This is because C<chomp $cwd = `pwd`;>
666 is interpreted as C<(chomp $cwd) = `pwd`;>, rather than as
667 C<chomp( $cwd = `pwd` )> which you might expect.  Similarly,
668 C<chomp $a, $b> is interpreted as C<chomp($a), $b> rather than
669 as C<chomp($a, $b)>.
670
671 =item chop VARIABLE
672
673 =item chop( LIST )
674
675 =item chop
676
677 Chops off the last character of a string and returns the character
678 chopped.  It is much more efficient than C<s/.$//s> because it neither
679 scans nor copies the string.  If VARIABLE is omitted, chops C<$_>.
680 If VARIABLE is a hash, it chops the hash's values, but not its keys.
681
682 You can actually chop anything that's an lvalue, including an assignment.
683
684 If you chop a list, each element is chopped.  Only the value of the
685 last C<chop> is returned.
686
687 Note that C<chop> returns the last character.  To return all but the last
688 character, use C<substr($string, 0, -1)>.
689
690 See also L</chomp>.
691
692 =item chown LIST
693
694 Changes the owner (and group) of a list of files.  The first two
695 elements of the list must be the I<numeric> uid and gid, in that
696 order.  A value of -1 in either position is interpreted by most
697 systems to leave that value unchanged.  Returns the number of files
698 successfully changed.
699
700     $cnt = chown $uid, $gid, 'foo', 'bar';
701     chown $uid, $gid, @filenames;
702
703 Here's an example that looks up nonnumeric uids in the passwd file:
704
705     print "User: ";
706     chomp($user = <STDIN>);
707     print "Files: ";
708     chomp($pattern = <STDIN>);
709
710     ($login,$pass,$uid,$gid) = getpwnam($user)
711         or die "$user not in passwd file";
712
713     @ary = glob($pattern);      # expand filenames
714     chown $uid, $gid, @ary;
715
716 On most systems, you are not allowed to change the ownership of the
717 file unless you're the superuser, although you should be able to change
718 the group to any of your secondary groups.  On insecure systems, these
719 restrictions may be relaxed, but this is not a portable assumption.
720 On POSIX systems, you can detect this condition this way:
721
722     use POSIX qw(sysconf _PC_CHOWN_RESTRICTED);
723     $can_chown_giveaway = not sysconf(_PC_CHOWN_RESTRICTED);
724
725 =item chr NUMBER
726
727 =item chr
728
729 Returns the character represented by that NUMBER in the character set.
730 For example, C<chr(65)> is C<"A"> in either ASCII or Unicode, and
731 chr(0x263a) is a Unicode smiley face.  Note that characters from 128
732 to 255 (inclusive) are by default not encoded in UTF-8 Unicode for
733 backward compatibility reasons (but see L<encoding>).
734
735 If NUMBER is omitted, uses C<$_>.
736
737 For the reverse, use L</ord>.
738
739 Note that under the C<bytes> pragma the NUMBER is masked to
740 the low eight bits.
741
742 See L<perlunicode> and L<encoding> for more about Unicode.
743
744 =item chroot FILENAME
745
746 =item chroot
747
748 This function works like the system call by the same name: it makes the
749 named directory the new root directory for all further pathnames that
750 begin with a C</> by your process and all its children.  (It doesn't
751 change your current working directory, which is unaffected.)  For security
752 reasons, this call is restricted to the superuser.  If FILENAME is
753 omitted, does a C<chroot> to C<$_>.
754
755 =item close FILEHANDLE
756
757 =item close
758
759 Closes the file or pipe associated with the file handle, returning
760 true only if IO buffers are successfully flushed and closes the system
761 file descriptor.  Closes the currently selected filehandle if the
762 argument is omitted.
763
764 You don't have to close FILEHANDLE if you are immediately going to do
765 another C<open> on it, because C<open> will close it for you.  (See
766 C<open>.)  However, an explicit C<close> on an input file resets the line
767 counter (C<$.>), while the implicit close done by C<open> does not.
768
769 If the file handle came from a piped open C<close> will additionally
770 return false if one of the other system calls involved fails or if the
771 program exits with non-zero status.  (If the only problem was that the
772 program exited non-zero C<$!> will be set to C<0>.)  Closing a pipe
773 also waits for the process executing on the pipe to complete, in case you
774 want to look at the output of the pipe afterwards, and
775 implicitly puts the exit status value of that command into C<$?>.
776
777 Prematurely closing the read end of a pipe (i.e. before the process
778 writing to it at the other end has closed it) will result in a
779 SIGPIPE being delivered to the writer.  If the other end can't
780 handle that, be sure to read all the data before closing the pipe.
781
782 Example:
783
784     open(OUTPUT, '|sort >foo')  # pipe to sort
785         or die "Can't start sort: $!";
786     #...                        # print stuff to output
787     close OUTPUT                # wait for sort to finish
788         or warn $! ? "Error closing sort pipe: $!"
789                    : "Exit status $? from sort";
790     open(INPUT, 'foo')          # get sort's results
791         or die "Can't open 'foo' for input: $!";
792
793 FILEHANDLE may be an expression whose value can be used as an indirect
794 filehandle, usually the real filehandle name.
795
796 =item closedir DIRHANDLE
797
798 Closes a directory opened by C<opendir> and returns the success of that
799 system call.
800
801 =item connect SOCKET,NAME
802
803 Attempts to connect to a remote socket, just as the connect system call
804 does.  Returns true if it succeeded, false otherwise.  NAME should be a
805 packed address of the appropriate type for the socket.  See the examples in
806 L<perlipc/"Sockets: Client/Server Communication">.
807
808 =item continue BLOCK
809
810 Actually a flow control statement rather than a function.  If there is a
811 C<continue> BLOCK attached to a BLOCK (typically in a C<while> or
812 C<foreach>), it is always executed just before the conditional is about to
813 be evaluated again, just like the third part of a C<for> loop in C.  Thus
814 it can be used to increment a loop variable, even when the loop has been
815 continued via the C<next> statement (which is similar to the C C<continue>
816 statement).
817
818 C<last>, C<next>, or C<redo> may appear within a C<continue>
819 block.  C<last> and C<redo> will behave as if they had been executed within
820 the main block.  So will C<next>, but since it will execute a C<continue>
821 block, it may be more entertaining.
822
823     while (EXPR) {
824         ### redo always comes here
825         do_something;
826     } continue {
827         ### next always comes here
828         do_something_else;
829         # then back the top to re-check EXPR
830     }
831     ### last always comes here
832
833 Omitting the C<continue> section is semantically equivalent to using an
834 empty one, logically enough.  In that case, C<next> goes directly back
835 to check the condition at the top of the loop.
836
837 =item cos EXPR
838
839 =item cos
840
841 Returns the cosine of EXPR (expressed in radians).  If EXPR is omitted,
842 takes cosine of C<$_>.
843
844 For the inverse cosine operation, you may use the C<Math::Trig::acos()>
845 function, or use this relation:
846
847     sub acos { atan2( sqrt(1 - $_[0] * $_[0]), $_[0] ) }
848
849 =item crypt PLAINTEXT,SALT
850
851 Encrypts a string exactly like the crypt(3) function in the C library
852 (assuming that you actually have a version there that has not been
853 extirpated as a potential munition).  This can prove useful for checking
854 the password file for lousy passwords, amongst other things.  Only the
855 guys wearing white hats should do this.
856
857 Note that L<crypt|/crypt> is intended to be a one-way function, much like
858 breaking eggs to make an omelette.  There is no (known) corresponding
859 decrypt function (in other words, the crypt() is a one-way hash
860 function).  As a result, this function isn't all that useful for
861 cryptography.  (For that, see your nearby CPAN mirror.)
862
863 When verifying an existing encrypted string you should use the
864 encrypted text as the salt (like C<crypt($plain, $crypted) eq
865 $crypted>).  This allows your code to work with the standard L<crypt|/crypt>
866 and with more exotic implementations.  In other words, do not assume
867 anything about the returned string itself, or how many bytes in
868 the encrypted string matter.
869
870 Traditionally the result is a string of 13 bytes: two first bytes of
871 the salt, followed by 11 bytes from the set C<[./0-9A-Za-z]>, and only
872 the first eight bytes of the encrypted string mattered, but
873 alternative hashing schemes (like MD5), higher level security schemes
874 (like C2), and implementations on non-UNIX platforms may produce
875 different strings.
876
877 When choosing a new salt create a random two character string whose
878 characters come from the set C<[./0-9A-Za-z]> (like C<join '', ('.',
879 '/', 0..9, 'A'..'Z', 'a'..'z')[rand 64, rand 64]>).  This set of
880 characters is just a recommendation; the characters allowed in
881 the salt depend solely on your system's crypt library, and Perl can't
882 restrict what salts C<crypt()> accepts.
883
884 Here's an example that makes sure that whoever runs this program knows
885 their own password:
886
887     $pwd = (getpwuid($<))[1];
888
889     system "stty -echo";
890     print "Password: ";
891     chomp($word = <STDIN>);
892     print "\n";
893     system "stty echo";
894
895     if (crypt($word, $pwd) ne $pwd) {
896         die "Sorry...\n";
897     } else {
898         print "ok\n";
899     }
900
901 Of course, typing in your own password to whoever asks you
902 for it is unwise.
903
904 The L<crypt|/crypt> function is unsuitable for encrypting large quantities
905 of data, not least of all because you can't get the information
906 back.  Look at the F<by-module/Crypt> and F<by-module/PGP> directories
907 on your favorite CPAN mirror for a slew of potentially useful
908 modules.
909
910 If using crypt() on a Unicode string (which I<potentially> has
911 characters with codepoints above 255), Perl tries to make sense
912 of the situation by trying to downgrade (a copy of the string)
913 the string back to an eight-bit byte string before calling crypt()
914 (on that copy).  If that works, good.  If not, crypt() dies with
915 C<Wide character in crypt>.
916
917 =item dbmclose HASH
918
919 [This function has been largely superseded by the C<untie> function.]
920
921 Breaks the binding between a DBM file and a hash.
922
923 =item dbmopen HASH,DBNAME,MASK
924
925 [This function has been largely superseded by the C<tie> function.]
926
927 This binds a dbm(3), ndbm(3), sdbm(3), gdbm(3), or Berkeley DB file to a
928 hash.  HASH is the name of the hash.  (Unlike normal C<open>, the first
929 argument is I<not> a filehandle, even though it looks like one).  DBNAME
930 is the name of the database (without the F<.dir> or F<.pag> extension if
931 any).  If the database does not exist, it is created with protection
932 specified by MASK (as modified by the C<umask>).  If your system supports
933 only the older DBM functions, you may perform only one C<dbmopen> in your
934 program.  In older versions of Perl, if your system had neither DBM nor
935 ndbm, calling C<dbmopen> produced a fatal error; it now falls back to
936 sdbm(3).
937
938 If you don't have write access to the DBM file, you can only read hash
939 variables, not set them.  If you want to test whether you can write,
940 either use file tests or try setting a dummy hash entry inside an C<eval>,
941 which will trap the error.
942
943 Note that functions such as C<keys> and C<values> may return huge lists
944 when used on large DBM files.  You may prefer to use the C<each>
945 function to iterate over large DBM files.  Example:
946
947     # print out history file offsets
948     dbmopen(%HIST,'/usr/lib/news/history',0666);
949     while (($key,$val) = each %HIST) {
950         print $key, ' = ', unpack('L',$val), "\n";
951     }
952     dbmclose(%HIST);
953
954 See also L<AnyDBM_File> for a more general description of the pros and
955 cons of the various dbm approaches, as well as L<DB_File> for a particularly
956 rich implementation.
957
958 You can control which DBM library you use by loading that library
959 before you call dbmopen():
960
961     use DB_File;
962     dbmopen(%NS_Hist, "$ENV{HOME}/.netscape/history.db")
963         or die "Can't open netscape history file: $!";
964
965 =item defined EXPR
966
967 =item defined
968
969 Returns a Boolean value telling whether EXPR has a value other than
970 the undefined value C<undef>.  If EXPR is not present, C<$_> will be
971 checked.
972
973 Many operations return C<undef> to indicate failure, end of file,
974 system error, uninitialized variable, and other exceptional
975 conditions.  This function allows you to distinguish C<undef> from
976 other values.  (A simple Boolean test will not distinguish among
977 C<undef>, zero, the empty string, and C<"0">, which are all equally
978 false.)  Note that since C<undef> is a valid scalar, its presence
979 doesn't I<necessarily> indicate an exceptional condition: C<pop>
980 returns C<undef> when its argument is an empty array, I<or> when the
981 element to return happens to be C<undef>.
982
983 You may also use C<defined(&func)> to check whether subroutine C<&func>
984 has ever been defined.  The return value is unaffected by any forward
985 declarations of C<&func>.  Note that a subroutine which is not defined
986 may still be callable: its package may have an C<AUTOLOAD> method that
987 makes it spring into existence the first time that it is called -- see
988 L<perlsub>.
989
990 Use of C<defined> on aggregates (hashes and arrays) is deprecated.  It
991 used to report whether memory for that aggregate has ever been
992 allocated.  This behavior may disappear in future versions of Perl.
993 You should instead use a simple test for size:
994
995     if (@an_array) { print "has array elements\n" }
996     if (%a_hash)   { print "has hash members\n"   }
997
998 When used on a hash element, it tells you whether the value is defined,
999 not whether the key exists in the hash.  Use L</exists> for the latter
1000 purpose.
1001
1002 Examples:
1003
1004     print if defined $switch{'D'};
1005     print "$val\n" while defined($val = pop(@ary));
1006     die "Can't readlink $sym: $!"
1007         unless defined($value = readlink $sym);
1008     sub foo { defined &$bar ? &$bar(@_) : die "No bar"; }
1009     $debugging = 0 unless defined $debugging;
1010
1011 Note:  Many folks tend to overuse C<defined>, and then are surprised to
1012 discover that the number C<0> and C<""> (the zero-length string) are, in fact,
1013 defined values.  For example, if you say
1014
1015     "ab" =~ /a(.*)b/;
1016
1017 The pattern match succeeds, and C<$1> is defined, despite the fact that it
1018 matched "nothing".  But it didn't really match nothing--rather, it
1019 matched something that happened to be zero characters long.  This is all
1020 very above-board and honest.  When a function returns an undefined value,
1021 it's an admission that it couldn't give you an honest answer.  So you
1022 should use C<defined> only when you're questioning the integrity of what
1023 you're trying to do.  At other times, a simple comparison to C<0> or C<""> is
1024 what you want.
1025
1026 See also L</undef>, L</exists>, L</ref>.
1027
1028 =item delete EXPR
1029
1030 Given an expression that specifies a hash element, array element, hash slice,
1031 or array slice, deletes the specified element(s) from the hash or array.
1032 In the case of an array, if the array elements happen to be at the end,
1033 the size of the array will shrink to the highest element that tests
1034 true for exists() (or 0 if no such element exists).
1035
1036 Returns each element so deleted or the undefined value if there was no such
1037 element.  Deleting from C<$ENV{}> modifies the environment.  Deleting from
1038 a hash tied to a DBM file deletes the entry from the DBM file.  Deleting
1039 from a C<tie>d hash or array may not necessarily return anything.
1040
1041 Deleting an array element effectively returns that position of the array
1042 to its initial, uninitialized state.  Subsequently testing for the same
1043 element with exists() will return false.  Note that deleting array
1044 elements in the middle of an array will not shift the index of the ones
1045 after them down--use splice() for that.  See L</exists>.
1046
1047 The following (inefficiently) deletes all the values of %HASH and @ARRAY:
1048
1049     foreach $key (keys %HASH) {
1050         delete $HASH{$key};
1051     }
1052
1053     foreach $index (0 .. $#ARRAY) {
1054         delete $ARRAY[$index];
1055     }
1056
1057 And so do these:
1058
1059     delete @HASH{keys %HASH};
1060
1061     delete @ARRAY[0 .. $#ARRAY];
1062
1063 But both of these are slower than just assigning the empty list
1064 or undefining %HASH or @ARRAY:
1065
1066     %HASH = ();         # completely empty %HASH
1067     undef %HASH;        # forget %HASH ever existed
1068
1069     @ARRAY = ();        # completely empty @ARRAY
1070     undef @ARRAY;       # forget @ARRAY ever existed
1071
1072 Note that the EXPR can be arbitrarily complicated as long as the final
1073 operation is a hash element, array element,  hash slice, or array slice
1074 lookup:
1075
1076     delete $ref->[$x][$y]{$key};
1077     delete @{$ref->[$x][$y]}{$key1, $key2, @morekeys};
1078
1079     delete $ref->[$x][$y][$index];
1080     delete @{$ref->[$x][$y]}[$index1, $index2, @moreindices];
1081
1082 =item die LIST
1083
1084 Outside an C<eval>, prints the value of LIST to C<STDERR> and
1085 exits with the current value of C<$!> (errno).  If C<$!> is C<0>,
1086 exits with the value of C<<< ($? >> 8) >>> (backtick `command`
1087 status).  If C<<< ($? >> 8) >>> is C<0>, exits with C<255>.  Inside
1088 an C<eval(),> the error message is stuffed into C<$@> and the
1089 C<eval> is terminated with the undefined value.  This makes
1090 C<die> the way to raise an exception.
1091
1092 Equivalent examples:
1093
1094     die "Can't cd to spool: $!\n" unless chdir '/usr/spool/news';
1095     chdir '/usr/spool/news' or die "Can't cd to spool: $!\n"
1096
1097 If the last element of LIST does not end in a newline, the current
1098 script line number and input line number (if any) are also printed,
1099 and a newline is supplied.  Note that the "input line number" (also
1100 known as "chunk") is subject to whatever notion of "line" happens to
1101 be currently in effect, and is also available as the special variable
1102 C<$.>.  See L<perlvar/"$/"> and L<perlvar/"$.">.
1103
1104 Hint: sometimes appending C<", stopped"> to your message will cause it
1105 to make better sense when the string C<"at foo line 123"> is appended.
1106 Suppose you are running script "canasta".
1107
1108     die "/etc/games is no good";
1109     die "/etc/games is no good, stopped";
1110
1111 produce, respectively
1112
1113     /etc/games is no good at canasta line 123.
1114     /etc/games is no good, stopped at canasta line 123.
1115
1116 See also exit(), warn(), and the Carp module.
1117
1118 If LIST is empty and C<$@> already contains a value (typically from a
1119 previous eval) that value is reused after appending C<"\t...propagated">.
1120 This is useful for propagating exceptions:
1121
1122     eval { ... };
1123     die unless $@ =~ /Expected exception/;
1124
1125 If LIST is empty and C<$@> contains an object reference that has a
1126 C<PROPAGATE> method, that method will be called with additional file
1127 and line number parameters.  The return value replaces the value in
1128 C<$@>.  ie. as if C<< $@ = eval { $@->PROPAGATE(__FILE__, __LINE__) }; >>
1129 were called.
1130
1131 If C<$@> is empty then the string C<"Died"> is used.
1132
1133 die() can also be called with a reference argument.  If this happens to be
1134 trapped within an eval(), $@ contains the reference.  This behavior permits
1135 a more elaborate exception handling implementation using objects that
1136 maintain arbitrary state about the nature of the exception.  Such a scheme
1137 is sometimes preferable to matching particular string values of $@ using
1138 regular expressions.  Here's an example:
1139
1140     eval { ... ; die Some::Module::Exception->new( FOO => "bar" ) };
1141     if ($@) {
1142         if (ref($@) && UNIVERSAL::isa($@,"Some::Module::Exception")) {
1143             # handle Some::Module::Exception
1144         }
1145         else {
1146             # handle all other possible exceptions
1147         }
1148     }
1149
1150 Because perl will stringify uncaught exception messages before displaying
1151 them, you may want to overload stringification operations on such custom
1152 exception objects.  See L<overload> for details about that.
1153
1154 You can arrange for a callback to be run just before the C<die>
1155 does its deed, by setting the C<$SIG{__DIE__}> hook.  The associated
1156 handler will be called with the error text and can change the error
1157 message, if it sees fit, by calling C<die> again.  See
1158 L<perlvar/$SIG{expr}> for details on setting C<%SIG> entries, and
1159 L<"eval BLOCK"> for some examples.  Although this feature was meant
1160 to be run only right before your program was to exit, this is not
1161 currently the case--the C<$SIG{__DIE__}> hook is currently called
1162 even inside eval()ed blocks/strings!  If one wants the hook to do
1163 nothing in such situations, put
1164
1165         die @_ if $^S;
1166
1167 as the first line of the handler (see L<perlvar/$^S>).  Because
1168 this promotes strange action at a distance, this counterintuitive
1169 behavior may be fixed in a future release.
1170
1171 =item do BLOCK
1172
1173 Not really a function.  Returns the value of the last command in the
1174 sequence of commands indicated by BLOCK.  When modified by a loop
1175 modifier, executes the BLOCK once before testing the loop condition.
1176 (On other statements the loop modifiers test the conditional first.)
1177
1178 C<do BLOCK> does I<not> count as a loop, so the loop control statements
1179 C<next>, C<last>, or C<redo> cannot be used to leave or restart the block.
1180 See L<perlsyn> for alternative strategies.
1181
1182 =item do SUBROUTINE(LIST)
1183
1184 A deprecated form of subroutine call.  See L<perlsub>.
1185
1186 =item do EXPR
1187
1188 Uses the value of EXPR as a filename and executes the contents of the
1189 file as a Perl script.  Its primary use is to include subroutines
1190 from a Perl subroutine library.
1191
1192     do 'stat.pl';
1193
1194 is just like
1195
1196     eval `cat stat.pl`;
1197
1198 except that it's more efficient and concise, keeps track of the current
1199 filename for error messages, searches the @INC libraries, and updates
1200 C<%INC> if the file is found.  See L<perlvar/Predefined Names> for these
1201 variables.  It also differs in that code evaluated with C<do FILENAME>
1202 cannot see lexicals in the enclosing scope; C<eval STRING> does.  It's the
1203 same, however, in that it does reparse the file every time you call it,
1204 so you probably don't want to do this inside a loop.
1205
1206 If C<do> cannot read the file, it returns undef and sets C<$!> to the
1207 error.  If C<do> can read the file but cannot compile it, it
1208 returns undef and sets an error message in C<$@>.   If the file is
1209 successfully compiled, C<do> returns the value of the last expression
1210 evaluated.
1211
1212 Note that inclusion of library modules is better done with the
1213 C<use> and C<require> operators, which also do automatic error checking
1214 and raise an exception if there's a problem.
1215
1216 You might like to use C<do> to read in a program configuration
1217 file.  Manual error checking can be done this way:
1218
1219     # read in config files: system first, then user
1220     for $file ("/share/prog/defaults.rc",
1221                "$ENV{HOME}/.someprogrc")
1222    {
1223         unless ($return = do $file) {
1224             warn "couldn't parse $file: $@" if $@;
1225             warn "couldn't do $file: $!"    unless defined $return;
1226             warn "couldn't run $file"       unless $return;
1227         }
1228     }
1229
1230 =item dump LABEL
1231
1232 =item dump
1233
1234 This function causes an immediate core dump.  See also the B<-u>
1235 command-line switch in L<perlrun>, which does the same thing.
1236 Primarily this is so that you can use the B<undump> program (not
1237 supplied) to turn your core dump into an executable binary after
1238 having initialized all your variables at the beginning of the
1239 program.  When the new binary is executed it will begin by executing
1240 a C<goto LABEL> (with all the restrictions that C<goto> suffers).
1241 Think of it as a goto with an intervening core dump and reincarnation.
1242 If C<LABEL> is omitted, restarts the program from the top.
1243
1244 B<WARNING>: Any files opened at the time of the dump will I<not>
1245 be open any more when the program is reincarnated, with possible
1246 resulting confusion on the part of Perl.
1247
1248 This function is now largely obsolete, partly because it's very
1249 hard to convert a core file into an executable, and because the
1250 real compiler backends for generating portable bytecode and compilable
1251 C code have superseded it.  That's why you should now invoke it as
1252 C<CORE::dump()>, if you don't want to be warned against a possible
1253 typo.
1254
1255 If you're looking to use L<dump> to speed up your program, consider
1256 generating bytecode or native C code as described in L<perlcc>.  If
1257 you're just trying to accelerate a CGI script, consider using the
1258 C<mod_perl> extension to B<Apache>, or the CPAN module, CGI::Fast.
1259 You might also consider autoloading or selfloading, which at least
1260 make your program I<appear> to run faster.
1261
1262 =item each HASH
1263
1264 When called in list context, returns a 2-element list consisting of the
1265 key and value for the next element of a hash, so that you can iterate over
1266 it.  When called in scalar context, returns only the key for the next
1267 element in the hash.
1268
1269 Entries are returned in an apparently random order.  The actual random
1270 order is subject to change in future versions of perl, but it is
1271 guaranteed to be in the same order as either the C<keys> or C<values>
1272 function would produce on the same (unmodified) hash.  Since Perl
1273 5.8.1 the ordering is different even between different runs of Perl
1274 for security reasons (see L<perlsec/"Algorithmic Complexity Attacks">).
1275
1276 When the hash is entirely read, a null array is returned in list context
1277 (which when assigned produces a false (C<0>) value), and C<undef> in
1278 scalar context.  The next call to C<each> after that will start iterating
1279 again.  There is a single iterator for each hash, shared by all C<each>,
1280 C<keys>, and C<values> function calls in the program; it can be reset by
1281 reading all the elements from the hash, or by evaluating C<keys HASH> or
1282 C<values HASH>.  If you add or delete elements of a hash while you're
1283 iterating over it, you may get entries skipped or duplicated, so
1284 don't.  Exception: It is always safe to delete the item most recently
1285 returned by C<each()>, which means that the following code will work:
1286
1287         while (($key, $value) = each %hash) {
1288           print $key, "\n";
1289           delete $hash{$key};   # This is safe
1290         }
1291
1292 The following prints out your environment like the printenv(1) program,
1293 only in a different order:
1294
1295     while (($key,$value) = each %ENV) {
1296         print "$key=$value\n";
1297     }
1298
1299 See also C<keys>, C<values> and C<sort>.
1300
1301 =item eof FILEHANDLE
1302
1303 =item eof ()
1304
1305 =item eof
1306
1307 Returns 1 if the next read on FILEHANDLE will return end of file, or if
1308 FILEHANDLE is not open.  FILEHANDLE may be an expression whose value
1309 gives the real filehandle.  (Note that this function actually
1310 reads a character and then C<ungetc>s it, so isn't very useful in an
1311 interactive context.)  Do not read from a terminal file (or call
1312 C<eof(FILEHANDLE)> on it) after end-of-file is reached.  File types such
1313 as terminals may lose the end-of-file condition if you do.
1314
1315 An C<eof> without an argument uses the last file read.  Using C<eof()>
1316 with empty parentheses is very different.  It refers to the pseudo file
1317 formed from the files listed on the command line and accessed via the
1318 C<< <> >> operator.  Since C<< <> >> isn't explicitly opened,
1319 as a normal filehandle is, an C<eof()> before C<< <> >> has been
1320 used will cause C<@ARGV> to be examined to determine if input is
1321 available.   Similarly, an C<eof()> after C<< <> >> has returned
1322 end-of-file will assume you are processing another C<@ARGV> list,
1323 and if you haven't set C<@ARGV>, will read input from C<STDIN>;
1324 see L<perlop/"I/O Operators">.
1325
1326 In a C<< while (<>) >> loop, C<eof> or C<eof(ARGV)> can be used to
1327 detect the end of each file, C<eof()> will only detect the end of the
1328 last file.  Examples:
1329
1330     # reset line numbering on each input file
1331     while (<>) {
1332         next if /^\s*#/;        # skip comments
1333         print "$.\t$_";
1334     } continue {
1335         close ARGV  if eof;     # Not eof()!
1336     }
1337
1338     # insert dashes just before last line of last file
1339     while (<>) {
1340         if (eof()) {            # check for end of last file
1341             print "--------------\n";
1342         }
1343         print;
1344         last if eof();          # needed if we're reading from a terminal
1345     }
1346
1347 Practical hint: you almost never need to use C<eof> in Perl, because the
1348 input operators typically return C<undef> when they run out of data, or if
1349 there was an error.
1350
1351 =item eval EXPR
1352
1353 =item eval BLOCK
1354
1355 In the first form, the return value of EXPR is parsed and executed as if it
1356 were a little Perl program.  The value of the expression (which is itself
1357 determined within scalar context) is first parsed, and if there weren't any
1358 errors, executed in the lexical context of the current Perl program, so
1359 that any variable settings or subroutine and format definitions remain
1360 afterwards.  Note that the value is parsed every time the eval executes.
1361 If EXPR is omitted, evaluates C<$_>.  This form is typically used to
1362 delay parsing and subsequent execution of the text of EXPR until run time.
1363
1364 In the second form, the code within the BLOCK is parsed only once--at the
1365 same time the code surrounding the eval itself was parsed--and executed
1366 within the context of the current Perl program.  This form is typically
1367 used to trap exceptions more efficiently than the first (see below), while
1368 also providing the benefit of checking the code within BLOCK at compile
1369 time.
1370
1371 The final semicolon, if any, may be omitted from the value of EXPR or within
1372 the BLOCK.
1373
1374 In both forms, the value returned is the value of the last expression
1375 evaluated inside the mini-program; a return statement may be also used, just
1376 as with subroutines.  The expression providing the return value is evaluated
1377 in void, scalar, or list context, depending on the context of the eval itself.
1378 See L</wantarray> for more on how the evaluation context can be determined.
1379
1380 If there is a syntax error or runtime error, or a C<die> statement is
1381 executed, an undefined value is returned by C<eval>, and C<$@> is set to the
1382 error message.  If there was no error, C<$@> is guaranteed to be a null
1383 string.  Beware that using C<eval> neither silences perl from printing
1384 warnings to STDERR, nor does it stuff the text of warning messages into C<$@>.
1385 To do either of those, you have to use the C<$SIG{__WARN__}> facility, or
1386 turn off warnings inside the BLOCK or EXPR using S<C<no warnings 'all'>>.
1387 See L</warn>, L<perlvar>, L<warnings> and L<perllexwarn>.
1388
1389 Note that, because C<eval> traps otherwise-fatal errors, it is useful for
1390 determining whether a particular feature (such as C<socket> or C<symlink>)
1391 is implemented.  It is also Perl's exception trapping mechanism, where
1392 the die operator is used to raise exceptions.
1393
1394 If the code to be executed doesn't vary, you may use the eval-BLOCK
1395 form to trap run-time errors without incurring the penalty of
1396 recompiling each time.  The error, if any, is still returned in C<$@>.
1397 Examples:
1398
1399     # make divide-by-zero nonfatal
1400     eval { $answer = $a / $b; }; warn $@ if $@;
1401
1402     # same thing, but less efficient
1403     eval '$answer = $a / $b'; warn $@ if $@;
1404
1405     # a compile-time error
1406     eval { $answer = };                 # WRONG
1407
1408     # a run-time error
1409     eval '$answer =';   # sets $@
1410
1411 Due to the current arguably broken state of C<__DIE__> hooks, when using
1412 the C<eval{}> form as an exception trap in libraries, you may wish not
1413 to trigger any C<__DIE__> hooks that user code may have installed.
1414 You can use the C<local $SIG{__DIE__}> construct for this purpose,
1415 as shown in this example:
1416
1417     # a very private exception trap for divide-by-zero
1418     eval { local $SIG{'__DIE__'}; $answer = $a / $b; };
1419     warn $@ if $@;
1420
1421 This is especially significant, given that C<__DIE__> hooks can call
1422 C<die> again, which has the effect of changing their error messages:
1423
1424     # __DIE__ hooks may modify error messages
1425     {
1426        local $SIG{'__DIE__'} =
1427               sub { (my $x = $_[0]) =~ s/foo/bar/g; die $x };
1428        eval { die "foo lives here" };
1429        print $@ if $@;                # prints "bar lives here"
1430     }
1431
1432 Because this promotes action at a distance, this counterintuitive behavior
1433 may be fixed in a future release.
1434
1435 With an C<eval>, you should be especially careful to remember what's
1436 being looked at when:
1437
1438     eval $x;            # CASE 1
1439     eval "$x";          # CASE 2
1440
1441     eval '$x';          # CASE 3
1442     eval { $x };        # CASE 4
1443
1444     eval "\$$x++";      # CASE 5
1445     $$x++;              # CASE 6
1446
1447 Cases 1 and 2 above behave identically: they run the code contained in
1448 the variable $x.  (Although case 2 has misleading double quotes making
1449 the reader wonder what else might be happening (nothing is).)  Cases 3
1450 and 4 likewise behave in the same way: they run the code C<'$x'>, which
1451 does nothing but return the value of $x.  (Case 4 is preferred for
1452 purely visual reasons, but it also has the advantage of compiling at
1453 compile-time instead of at run-time.)  Case 5 is a place where
1454 normally you I<would> like to use double quotes, except that in this
1455 particular situation, you can just use symbolic references instead, as
1456 in case 6.
1457
1458 C<eval BLOCK> does I<not> count as a loop, so the loop control statements
1459 C<next>, C<last>, or C<redo> cannot be used to leave or restart the block.
1460
1461 Note that as a very special case, an C<eval ''> executed within the C<DB>
1462 package doesn't see the usual surrounding lexical scope, but rather the
1463 scope of the first non-DB piece of code that called it. You don't normally
1464 need to worry about this unless you are writing a Perl debugger.
1465
1466 =item exec LIST
1467
1468 =item exec PROGRAM LIST
1469
1470 The C<exec> function executes a system command I<and never returns>--
1471 use C<system> instead of C<exec> if you want it to return.  It fails and
1472 returns false only if the command does not exist I<and> it is executed
1473 directly instead of via your system's command shell (see below).
1474
1475 Since it's a common mistake to use C<exec> instead of C<system>, Perl
1476 warns you if there is a following statement which isn't C<die>, C<warn>,
1477 or C<exit> (if C<-w> is set  -  but you always do that).   If you
1478 I<really> want to follow an C<exec> with some other statement, you
1479 can use one of these styles to avoid the warning:
1480
1481     exec ('foo')   or print STDERR "couldn't exec foo: $!";
1482     { exec ('foo') }; print STDERR "couldn't exec foo: $!";
1483
1484 If there is more than one argument in LIST, or if LIST is an array
1485 with more than one value, calls execvp(3) with the arguments in LIST.
1486 If there is only one scalar argument or an array with one element in it,
1487 the argument is checked for shell metacharacters, and if there are any,
1488 the entire argument is passed to the system's command shell for parsing
1489 (this is C</bin/sh -c> on Unix platforms, but varies on other platforms).
1490 If there are no shell metacharacters in the argument, it is split into
1491 words and passed directly to C<execvp>, which is more efficient.
1492 Examples:
1493
1494     exec '/bin/echo', 'Your arguments are: ', @ARGV;
1495     exec "sort $outfile | uniq";
1496
1497 If you don't really want to execute the first argument, but want to lie
1498 to the program you are executing about its own name, you can specify
1499 the program you actually want to run as an "indirect object" (without a
1500 comma) in front of the LIST.  (This always forces interpretation of the
1501 LIST as a multivalued list, even if there is only a single scalar in
1502 the list.)  Example:
1503
1504     $shell = '/bin/csh';
1505     exec $shell '-sh';          # pretend it's a login shell
1506
1507 or, more directly,
1508
1509     exec {'/bin/csh'} '-sh';    # pretend it's a login shell
1510
1511 When the arguments get executed via the system shell, results will
1512 be subject to its quirks and capabilities.  See L<perlop/"`STRING`">
1513 for details.
1514
1515 Using an indirect object with C<exec> or C<system> is also more
1516 secure.  This usage (which also works fine with system()) forces
1517 interpretation of the arguments as a multivalued list, even if the
1518 list had just one argument.  That way you're safe from the shell
1519 expanding wildcards or splitting up words with whitespace in them.
1520
1521     @args = ( "echo surprise" );
1522
1523     exec @args;               # subject to shell escapes
1524                                 # if @args == 1
1525     exec { $args[0] } @args;  # safe even with one-arg list
1526
1527 The first version, the one without the indirect object, ran the I<echo>
1528 program, passing it C<"surprise"> an argument.  The second version
1529 didn't--it tried to run a program literally called I<"echo surprise">,
1530 didn't find it, and set C<$?> to a non-zero value indicating failure.
1531
1532 Beginning with v5.6.0, Perl will attempt to flush all files opened for
1533 output before the exec, but this may not be supported on some platforms
1534 (see L<perlport>).  To be safe, you may need to set C<$|> ($AUTOFLUSH
1535 in English) or call the C<autoflush()> method of C<IO::Handle> on any
1536 open handles in order to avoid lost output.
1537
1538 Note that C<exec> will not call your C<END> blocks, nor will it call
1539 any C<DESTROY> methods in your objects.
1540
1541 =item exists EXPR
1542
1543 Given an expression that specifies a hash element or array element,
1544 returns true if the specified element in the hash or array has ever
1545 been initialized, even if the corresponding value is undefined.  The
1546 element is not autovivified if it doesn't exist.
1547
1548     print "Exists\n"    if exists $hash{$key};
1549     print "Defined\n"   if defined $hash{$key};
1550     print "True\n"      if $hash{$key};
1551
1552     print "Exists\n"    if exists $array[$index];
1553     print "Defined\n"   if defined $array[$index];
1554     print "True\n"      if $array[$index];
1555
1556 A hash or array element can be true only if it's defined, and defined if
1557 it exists, but the reverse doesn't necessarily hold true.
1558
1559 Given an expression that specifies the name of a subroutine,
1560 returns true if the specified subroutine has ever been declared, even
1561 if it is undefined.  Mentioning a subroutine name for exists or defined
1562 does not count as declaring it.  Note that a subroutine which does not
1563 exist may still be callable: its package may have an C<AUTOLOAD>
1564 method that makes it spring into existence the first time that it is
1565 called -- see L<perlsub>.
1566
1567     print "Exists\n"    if exists &subroutine;
1568     print "Defined\n"   if defined &subroutine;
1569
1570 Note that the EXPR can be arbitrarily complicated as long as the final
1571 operation is a hash or array key lookup or subroutine name:
1572
1573     if (exists $ref->{A}->{B}->{$key})  { }
1574     if (exists $hash{A}{B}{$key})       { }
1575
1576     if (exists $ref->{A}->{B}->[$ix])   { }
1577     if (exists $hash{A}{B}[$ix])        { }
1578
1579     if (exists &{$ref->{A}{B}{$key}})   { }
1580
1581 Although the deepest nested array or hash will not spring into existence
1582 just because its existence was tested, any intervening ones will.
1583 Thus C<< $ref->{"A"} >> and C<< $ref->{"A"}->{"B"} >> will spring
1584 into existence due to the existence test for the $key element above.
1585 This happens anywhere the arrow operator is used, including even:
1586
1587     undef $ref;
1588     if (exists $ref->{"Some key"})      { }
1589     print $ref;             # prints HASH(0x80d3d5c)
1590
1591 This surprising autovivification in what does not at first--or even
1592 second--glance appear to be an lvalue context may be fixed in a future
1593 release.
1594
1595 Use of a subroutine call, rather than a subroutine name, as an argument
1596 to exists() is an error.
1597
1598     exists &sub;        # OK
1599     exists &sub();      # Error
1600
1601 =item exit EXPR
1602
1603 Evaluates EXPR and exits immediately with that value.    Example:
1604
1605     $ans = <STDIN>;
1606     exit 0 if $ans =~ /^[Xx]/;
1607
1608 See also C<die>.  If EXPR is omitted, exits with C<0> status.  The only
1609 universally recognized values for EXPR are C<0> for success and C<1>
1610 for error; other values are subject to interpretation depending on the
1611 environment in which the Perl program is running.  For example, exiting
1612 69 (EX_UNAVAILABLE) from a I<sendmail> incoming-mail filter will cause
1613 the mailer to return the item undelivered, but that's not true everywhere.
1614
1615 Don't use C<exit> to abort a subroutine if there's any chance that
1616 someone might want to trap whatever error happened.  Use C<die> instead,
1617 which can be trapped by an C<eval>.
1618
1619 The exit() function does not always exit immediately.  It calls any
1620 defined C<END> routines first, but these C<END> routines may not
1621 themselves abort the exit.  Likewise any object destructors that need to
1622 be called are called before the real exit.  If this is a problem, you
1623 can call C<POSIX:_exit($status)> to avoid END and destructor processing.
1624 See L<perlmod> for details.
1625
1626 =item exp EXPR
1627
1628 =item exp
1629
1630 Returns I<e> (the natural logarithm base) to the power of EXPR.
1631 If EXPR is omitted, gives C<exp($_)>.
1632
1633 =item fcntl FILEHANDLE,FUNCTION,SCALAR
1634
1635 Implements the fcntl(2) function.  You'll probably have to say
1636
1637     use Fcntl;
1638
1639 first to get the correct constant definitions.  Argument processing and
1640 value return works just like C<ioctl> below.
1641 For example:
1642
1643     use Fcntl;
1644     fcntl($filehandle, F_GETFL, $packed_return_buffer)
1645         or die "can't fcntl F_GETFL: $!";
1646
1647 You don't have to check for C<defined> on the return from C<fcntl>.
1648 Like C<ioctl>, it maps a C<0> return from the system call into
1649 C<"0 but true"> in Perl.  This string is true in boolean context and C<0>
1650 in numeric context.  It is also exempt from the normal B<-w> warnings
1651 on improper numeric conversions.
1652
1653 Note that C<fcntl> will produce a fatal error if used on a machine that
1654 doesn't implement fcntl(2).  See the Fcntl module or your fcntl(2)
1655 manpage to learn what functions are available on your system.
1656
1657 Here's an example of setting a filehandle named C<REMOTE> to be
1658 non-blocking at the system level.  You'll have to negotiate C<$|>
1659 on your own, though.
1660
1661     use Fcntl qw(F_GETFL F_SETFL O_NONBLOCK);
1662
1663     $flags = fcntl(REMOTE, F_GETFL, 0)
1664                 or die "Can't get flags for the socket: $!\n";
1665
1666     $flags = fcntl(REMOTE, F_SETFL, $flags | O_NONBLOCK)
1667                 or die "Can't set flags for the socket: $!\n";
1668
1669 =item fileno FILEHANDLE
1670
1671 Returns the file descriptor for a filehandle, or undefined if the
1672 filehandle is not open.  This is mainly useful for constructing
1673 bitmaps for C<select> and low-level POSIX tty-handling operations.
1674 If FILEHANDLE is an expression, the value is taken as an indirect
1675 filehandle, generally its name.
1676
1677 You can use this to find out whether two handles refer to the
1678 same underlying descriptor:
1679
1680     if (fileno(THIS) == fileno(THAT)) {
1681         print "THIS and THAT are dups\n";
1682     }
1683
1684 (Filehandles connected to memory objects via new features of C<open> may
1685 return undefined even though they are open.)
1686
1687
1688 =item flock FILEHANDLE,OPERATION
1689
1690 Calls flock(2), or an emulation of it, on FILEHANDLE.  Returns true
1691 for success, false on failure.  Produces a fatal error if used on a
1692 machine that doesn't implement flock(2), fcntl(2) locking, or lockf(3).
1693 C<flock> is Perl's portable file locking interface, although it locks
1694 only entire files, not records.
1695
1696 Two potentially non-obvious but traditional C<flock> semantics are
1697 that it waits indefinitely until the lock is granted, and that its locks
1698 B<merely advisory>.  Such discretionary locks are more flexible, but offer
1699 fewer guarantees.  This means that files locked with C<flock> may be
1700 modified by programs that do not also use C<flock>.  See L<perlport>,
1701 your port's specific documentation, or your system-specific local manpages
1702 for details.  It's best to assume traditional behavior if you're writing
1703 portable programs.  (But if you're not, you should as always feel perfectly
1704 free to write for your own system's idiosyncrasies (sometimes called
1705 "features").  Slavish adherence to portability concerns shouldn't get
1706 in the way of your getting your job done.)
1707
1708 OPERATION is one of LOCK_SH, LOCK_EX, or LOCK_UN, possibly combined with
1709 LOCK_NB.  These constants are traditionally valued 1, 2, 8 and 4, but
1710 you can use the symbolic names if you import them from the Fcntl module,
1711 either individually, or as a group using the ':flock' tag.  LOCK_SH
1712 requests a shared lock, LOCK_EX requests an exclusive lock, and LOCK_UN
1713 releases a previously requested lock.  If LOCK_NB is bitwise-or'ed with
1714 LOCK_SH or LOCK_EX then C<flock> will return immediately rather than blocking
1715 waiting for the lock (check the return status to see if you got it).
1716
1717 To avoid the possibility of miscoordination, Perl now flushes FILEHANDLE
1718 before locking or unlocking it.
1719
1720 Note that the emulation built with lockf(3) doesn't provide shared
1721 locks, and it requires that FILEHANDLE be open with write intent.  These
1722 are the semantics that lockf(3) implements.  Most if not all systems
1723 implement lockf(3) in terms of fcntl(2) locking, though, so the
1724 differing semantics shouldn't bite too many people.
1725
1726 Note that the fcntl(2) emulation of flock(3) requires that FILEHANDLE
1727 be open with read intent to use LOCK_SH and requires that it be open
1728 with write intent to use LOCK_EX.
1729
1730 Note also that some versions of C<flock> cannot lock things over the
1731 network; you would need to use the more system-specific C<fcntl> for
1732 that.  If you like you can force Perl to ignore your system's flock(2)
1733 function, and so provide its own fcntl(2)-based emulation, by passing
1734 the switch C<-Ud_flock> to the F<Configure> program when you configure
1735 perl.
1736
1737 Here's a mailbox appender for BSD systems.
1738
1739     use Fcntl ':flock'; # import LOCK_* constants
1740
1741     sub lock {
1742         flock(MBOX,LOCK_EX);
1743         # and, in case someone appended
1744         # while we were waiting...
1745         seek(MBOX, 0, 2);
1746     }
1747
1748     sub unlock {
1749         flock(MBOX,LOCK_UN);
1750     }
1751
1752     open(MBOX, ">>/usr/spool/mail/$ENV{'USER'}")
1753             or die "Can't open mailbox: $!";
1754
1755     lock();
1756     print MBOX $msg,"\n\n";
1757     unlock();
1758
1759 On systems that support a real flock(), locks are inherited across fork()
1760 calls, whereas those that must resort to the more capricious fcntl()
1761 function lose the locks, making it harder to write servers.
1762
1763 See also L<DB_File> for other flock() examples.
1764
1765 =item fork
1766
1767 Does a fork(2) system call to create a new process running the
1768 same program at the same point.  It returns the child pid to the
1769 parent process, C<0> to the child process, or C<undef> if the fork is
1770 unsuccessful.  File descriptors (and sometimes locks on those descriptors)
1771 are shared, while everything else is copied.  On most systems supporting
1772 fork(), great care has gone into making it extremely efficient (for
1773 example, using copy-on-write technology on data pages), making it the
1774 dominant paradigm for multitasking over the last few decades.
1775
1776 Beginning with v5.6.0, Perl will attempt to flush all files opened for
1777 output before forking the child process, but this may not be supported
1778 on some platforms (see L<perlport>).  To be safe, you may need to set
1779 C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method of
1780 C<IO::Handle> on any open handles in order to avoid duplicate output.
1781
1782 If you C<fork> without ever waiting on your children, you will
1783 accumulate zombies.  On some systems, you can avoid this by setting
1784 C<$SIG{CHLD}> to C<"IGNORE">.  See also L<perlipc> for more examples of
1785 forking and reaping moribund children.
1786
1787 Note that if your forked child inherits system file descriptors like
1788 STDIN and STDOUT that are actually connected by a pipe or socket, even
1789 if you exit, then the remote server (such as, say, a CGI script or a
1790 backgrounded job launched from a remote shell) won't think you're done.
1791 You should reopen those to F</dev/null> if it's any issue.
1792
1793 =item format
1794
1795 Declare a picture format for use by the C<write> function.  For
1796 example:
1797
1798     format Something =
1799         Test: @<<<<<<<< @||||| @>>>>>
1800               $str,     $%,    '$' . int($num)
1801     .
1802
1803     $str = "widget";
1804     $num = $cost/$quantity;
1805     $~ = 'Something';
1806     write;
1807
1808 See L<perlform> for many details and examples.
1809
1810 =item formline PICTURE,LIST
1811
1812 This is an internal function used by C<format>s, though you may call it,
1813 too.  It formats (see L<perlform>) a list of values according to the
1814 contents of PICTURE, placing the output into the format output
1815 accumulator, C<$^A> (or C<$ACCUMULATOR> in English).
1816 Eventually, when a C<write> is done, the contents of
1817 C<$^A> are written to some filehandle, but you could also read C<$^A>
1818 yourself and then set C<$^A> back to C<"">.  Note that a format typically
1819 does one C<formline> per line of form, but the C<formline> function itself
1820 doesn't care how many newlines are embedded in the PICTURE.  This means
1821 that the C<~> and C<~~> tokens will treat the entire PICTURE as a single line.
1822 You may therefore need to use multiple formlines to implement a single
1823 record format, just like the format compiler.
1824
1825 Be careful if you put double quotes around the picture, because an C<@>
1826 character may be taken to mean the beginning of an array name.
1827 C<formline> always returns true.  See L<perlform> for other examples.
1828
1829 =item getc FILEHANDLE
1830
1831 =item getc
1832
1833 Returns the next character from the input file attached to FILEHANDLE,
1834 or the undefined value at end of file, or if there was an error (in
1835 the latter case C<$!> is set).  If FILEHANDLE is omitted, reads from
1836 STDIN.  This is not particularly efficient.  However, it cannot be
1837 used by itself to fetch single characters without waiting for the user
1838 to hit enter.  For that, try something more like:
1839
1840     if ($BSD_STYLE) {
1841         system "stty cbreak </dev/tty >/dev/tty 2>&1";
1842     }
1843     else {
1844         system "stty", '-icanon', 'eol', "\001";
1845     }
1846
1847     $key = getc(STDIN);
1848
1849     if ($BSD_STYLE) {
1850         system "stty -cbreak </dev/tty >/dev/tty 2>&1";
1851     }
1852     else {
1853         system "stty", 'icanon', 'eol', '^@'; # ASCII null
1854     }
1855     print "\n";
1856
1857 Determination of whether $BSD_STYLE should be set
1858 is left as an exercise to the reader.
1859
1860 The C<POSIX::getattr> function can do this more portably on
1861 systems purporting POSIX compliance.  See also the C<Term::ReadKey>
1862 module from your nearest CPAN site; details on CPAN can be found on
1863 L<perlmodlib/CPAN>.
1864
1865 =item getlogin
1866
1867 Implements the C library function of the same name, which on most
1868 systems returns the current login from F</etc/utmp>, if any.  If null,
1869 use C<getpwuid>.
1870
1871     $login = getlogin || getpwuid($<) || "Kilroy";
1872
1873 Do not consider C<getlogin> for authentication: it is not as
1874 secure as C<getpwuid>.
1875
1876 =item getpeername SOCKET
1877
1878 Returns the packed sockaddr address of other end of the SOCKET connection.
1879
1880     use Socket;
1881     $hersockaddr    = getpeername(SOCK);
1882     ($port, $iaddr) = sockaddr_in($hersockaddr);
1883     $herhostname    = gethostbyaddr($iaddr, AF_INET);
1884     $herstraddr     = inet_ntoa($iaddr);
1885
1886 =item getpgrp PID
1887
1888 Returns the current process group for the specified PID.  Use
1889 a PID of C<0> to get the current process group for the
1890 current process.  Will raise an exception if used on a machine that
1891 doesn't implement getpgrp(2).  If PID is omitted, returns process
1892 group of current process.  Note that the POSIX version of C<getpgrp>
1893 does not accept a PID argument, so only C<PID==0> is truly portable.
1894
1895 =item getppid
1896
1897 Returns the process id of the parent process.
1898
1899 Note for Linux users: on Linux, the C functions C<getpid()> and
1900 C<getppid()> return different values from different threads. In order to
1901 be portable, this behavior is not reflected by the perl-level function
1902 C<getppid()>, that returns a consistent value across threads. If you want
1903 to call the underlying C<getppid()>, you may use the CPAN module
1904 C<Linux::Pid>.
1905
1906 =item getpriority WHICH,WHO
1907
1908 Returns the current priority for a process, a process group, or a user.
1909 (See L<getpriority(2)>.)  Will raise a fatal exception if used on a
1910 machine that doesn't implement getpriority(2).
1911
1912 =item getpwnam NAME
1913
1914 =item getgrnam NAME
1915
1916 =item gethostbyname NAME
1917
1918 =item getnetbyname NAME
1919
1920 =item getprotobyname NAME
1921
1922 =item getpwuid UID
1923
1924 =item getgrgid GID
1925
1926 =item getservbyname NAME,PROTO
1927
1928 =item gethostbyaddr ADDR,ADDRTYPE
1929
1930 =item getnetbyaddr ADDR,ADDRTYPE
1931
1932 =item getprotobynumber NUMBER
1933
1934 =item getservbyport PORT,PROTO
1935
1936 =item getpwent
1937
1938 =item getgrent
1939
1940 =item gethostent
1941
1942 =item getnetent
1943
1944 =item getprotoent
1945
1946 =item getservent
1947
1948 =item setpwent
1949
1950 =item setgrent
1951
1952 =item sethostent STAYOPEN
1953
1954 =item setnetent STAYOPEN
1955
1956 =item setprotoent STAYOPEN
1957
1958 =item setservent STAYOPEN
1959
1960 =item endpwent
1961
1962 =item endgrent
1963
1964 =item endhostent
1965
1966 =item endnetent
1967
1968 =item endprotoent
1969
1970 =item endservent
1971
1972 These routines perform the same functions as their counterparts in the
1973 system library.  In list context, the return values from the
1974 various get routines are as follows:
1975
1976     ($name,$passwd,$uid,$gid,
1977        $quota,$comment,$gcos,$dir,$shell,$expire) = getpw*
1978     ($name,$passwd,$gid,$members) = getgr*
1979     ($name,$aliases,$addrtype,$length,@addrs) = gethost*
1980     ($name,$aliases,$addrtype,$net) = getnet*
1981     ($name,$aliases,$proto) = getproto*
1982     ($name,$aliases,$port,$proto) = getserv*
1983
1984 (If the entry doesn't exist you get a null list.)
1985
1986 The exact meaning of the $gcos field varies but it usually contains
1987 the real name of the user (as opposed to the login name) and other
1988 information pertaining to the user.  Beware, however, that in many
1989 system users are able to change this information and therefore it
1990 cannot be trusted and therefore the $gcos is tainted (see
1991 L<perlsec>).  The $passwd and $shell, user's encrypted password and
1992 login shell, are also tainted, because of the same reason.
1993
1994 In scalar context, you get the name, unless the function was a
1995 lookup by name, in which case you get the other thing, whatever it is.
1996 (If the entry doesn't exist you get the undefined value.)  For example:
1997
1998     $uid   = getpwnam($name);
1999     $name  = getpwuid($num);
2000     $name  = getpwent();
2001     $gid   = getgrnam($name);
2002     $name  = getgrgid($num);
2003     $name  = getgrent();
2004     #etc.
2005
2006 In I<getpw*()> the fields $quota, $comment, and $expire are special
2007 cases in the sense that in many systems they are unsupported.  If the
2008 $quota is unsupported, it is an empty scalar.  If it is supported, it
2009 usually encodes the disk quota.  If the $comment field is unsupported,
2010 it is an empty scalar.  If it is supported it usually encodes some
2011 administrative comment about the user.  In some systems the $quota
2012 field may be $change or $age, fields that have to do with password
2013 aging.  In some systems the $comment field may be $class.  The $expire
2014 field, if present, encodes the expiration period of the account or the
2015 password.  For the availability and the exact meaning of these fields
2016 in your system, please consult your getpwnam(3) documentation and your
2017 F<pwd.h> file.  You can also find out from within Perl what your
2018 $quota and $comment fields mean and whether you have the $expire field
2019 by using the C<Config> module and the values C<d_pwquota>, C<d_pwage>,
2020 C<d_pwchange>, C<d_pwcomment>, and C<d_pwexpire>.  Shadow password
2021 files are only supported if your vendor has implemented them in the
2022 intuitive fashion that calling the regular C library routines gets the
2023 shadow versions if you're running under privilege or if there exists
2024 the shadow(3) functions as found in System V ( this includes Solaris
2025 and Linux.)  Those systems which implement a proprietary shadow password
2026 facility are unlikely to be supported.
2027
2028 The $members value returned by I<getgr*()> is a space separated list of
2029 the login names of the members of the group.
2030
2031 For the I<gethost*()> functions, if the C<h_errno> variable is supported in
2032 C, it will be returned to you via C<$?> if the function call fails.  The
2033 C<@addrs> value returned by a successful call is a list of the raw
2034 addresses returned by the corresponding system library call.  In the
2035 Internet domain, each address is four bytes long and you can unpack it
2036 by saying something like:
2037
2038     ($a,$b,$c,$d) = unpack('C4',$addr[0]);
2039
2040 The Socket library makes this slightly easier:
2041
2042     use Socket;
2043     $iaddr = inet_aton("127.1"); # or whatever address
2044     $name  = gethostbyaddr($iaddr, AF_INET);
2045
2046     # or going the other way
2047     $straddr = inet_ntoa($iaddr);
2048
2049 If you get tired of remembering which element of the return list
2050 contains which return value, by-name interfaces are provided
2051 in standard modules: C<File::stat>, C<Net::hostent>, C<Net::netent>,
2052 C<Net::protoent>, C<Net::servent>, C<Time::gmtime>, C<Time::localtime>,
2053 and C<User::grent>.  These override the normal built-ins, supplying
2054 versions that return objects with the appropriate names
2055 for each field.  For example:
2056
2057    use File::stat;
2058    use User::pwent;
2059    $is_his = (stat($filename)->uid == pwent($whoever)->uid);
2060
2061 Even though it looks like they're the same method calls (uid),
2062 they aren't, because a C<File::stat> object is different from
2063 a C<User::pwent> object.
2064
2065 =item getsockname SOCKET
2066
2067 Returns the packed sockaddr address of this end of the SOCKET connection,
2068 in case you don't know the address because you have several different
2069 IPs that the connection might have come in on.
2070
2071     use Socket;
2072     $mysockaddr = getsockname(SOCK);
2073     ($port, $myaddr) = sockaddr_in($mysockaddr);
2074     printf "Connect to %s [%s]\n",
2075        scalar gethostbyaddr($myaddr, AF_INET),
2076        inet_ntoa($myaddr);
2077
2078 =item getsockopt SOCKET,LEVEL,OPTNAME
2079
2080 Returns the socket option requested, or undef if there is an error.
2081
2082 =item glob EXPR
2083
2084 =item glob
2085
2086 In list context, returns a (possibly empty) list of filename expansions on
2087 the value of EXPR such as the standard Unix shell F</bin/csh> would do. In
2088 scalar context, glob iterates through such filename expansions, returning
2089 undef when the list is exhausted. This is the internal function
2090 implementing the C<< <*.c> >> operator, but you can use it directly. If
2091 EXPR is omitted, C<$_> is used.  The C<< <*.c> >> operator is discussed in
2092 more detail in L<perlop/"I/O Operators">.
2093
2094 Beginning with v5.6.0, this operator is implemented using the standard
2095 C<File::Glob> extension.  See L<File::Glob> for details.
2096
2097 =item gmtime EXPR
2098
2099 Converts a time as returned by the time function to an 8-element list
2100 with the time localized for the standard Greenwich time zone.
2101 Typically used as follows:
2102
2103     #  0    1    2     3     4    5     6     7
2104     ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday) =
2105                                             gmtime(time);
2106
2107 All list elements are numeric, and come straight out of the C `struct
2108 tm'.  $sec, $min, and $hour are the seconds, minutes, and hours of the
2109 specified time.  $mday is the day of the month, and $mon is the month
2110 itself, in the range C<0..11> with 0 indicating January and 11
2111 indicating December.  $year is the number of years since 1900.  That
2112 is, $year is C<123> in year 2023.  $wday is the day of the week, with
2113 0 indicating Sunday and 3 indicating Wednesday.  $yday is the day of
2114 the year, in the range C<0..364> (or C<0..365> in leap years.)
2115
2116 Note that the $year element is I<not> simply the last two digits of
2117 the year.  If you assume it is, then you create non-Y2K-compliant
2118 programs--and you wouldn't want to do that, would you?
2119
2120 The proper way to get a complete 4-digit year is simply:
2121
2122         $year += 1900;
2123
2124 And to get the last two digits of the year (e.g., '01' in 2001) do:
2125
2126         $year = sprintf("%02d", $year % 100);
2127
2128 If EXPR is omitted, C<gmtime()> uses the current time (C<gmtime(time)>).
2129
2130 In scalar context, C<gmtime()> returns the ctime(3) value:
2131
2132     $now_string = gmtime;  # e.g., "Thu Oct 13 04:54:34 1994"
2133
2134 Also see the C<timegm> function provided by the C<Time::Local> module,
2135 and the strftime(3) function available via the POSIX module.
2136
2137 This scalar value is B<not> locale dependent (see L<perllocale>), but
2138 is instead a Perl builtin.  Also see the C<Time::Local> module, and the
2139 strftime(3) and mktime(3) functions available via the POSIX module.  To
2140 get somewhat similar but locale dependent date strings, set up your
2141 locale environment variables appropriately (please see L<perllocale>)
2142 and try for example:
2143
2144     use POSIX qw(strftime);
2145     $now_string = strftime "%a %b %e %H:%M:%S %Y", gmtime;
2146
2147 Note that the C<%a> and C<%b> escapes, which represent the short forms
2148 of the day of the week and the month of the year, may not necessarily
2149 be three characters wide in all locales.
2150
2151 =item goto LABEL
2152
2153 =item goto EXPR
2154
2155 =item goto &NAME
2156
2157 The C<goto-LABEL> form finds the statement labeled with LABEL and resumes
2158 execution there.  It may not be used to go into any construct that
2159 requires initialization, such as a subroutine or a C<foreach> loop.  It
2160 also can't be used to go into a construct that is optimized away,
2161 or to get out of a block or subroutine given to C<sort>.
2162 It can be used to go almost anywhere else within the dynamic scope,
2163 including out of subroutines, but it's usually better to use some other
2164 construct such as C<last> or C<die>.  The author of Perl has never felt the
2165 need to use this form of C<goto> (in Perl, that is--C is another matter).
2166 (The difference being that C does not offer named loops combined with
2167 loop control.  Perl does, and this replaces most structured uses of C<goto>
2168 in other languages.)
2169
2170 The C<goto-EXPR> form expects a label name, whose scope will be resolved
2171 dynamically.  This allows for computed C<goto>s per FORTRAN, but isn't
2172 necessarily recommended if you're optimizing for maintainability:
2173
2174     goto ("FOO", "BAR", "GLARCH")[$i];
2175
2176 The C<goto-&NAME> form is quite different from the other forms of
2177 C<goto>.  In fact, it isn't a goto in the normal sense at all, and
2178 doesn't have the stigma associated with other gotos.  Instead, it
2179 exits the current subroutine (losing any changes set by local()) and
2180 immediately calls in its place the named subroutine using the current
2181 value of @_.  This is used by C<AUTOLOAD> subroutines that wish to
2182 load another subroutine and then pretend that the other subroutine had
2183 been called in the first place (except that any modifications to C<@_>
2184 in the current subroutine are propagated to the other subroutine.)
2185 After the C<goto>, not even C<caller> will be able to tell that this
2186 routine was called first.
2187
2188 NAME needn't be the name of a subroutine; it can be a scalar variable
2189 containing a code reference, or a block which evaluates to a code
2190 reference.
2191
2192 =item grep BLOCK LIST
2193
2194 =item grep EXPR,LIST
2195
2196 This is similar in spirit to, but not the same as, grep(1) and its
2197 relatives.  In particular, it is not limited to using regular expressions.
2198
2199 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
2200 C<$_> to each element) and returns the list value consisting of those
2201 elements for which the expression evaluated to true.  In scalar
2202 context, returns the number of times the expression was true.
2203
2204     @foo = grep(!/^#/, @bar);    # weed out comments
2205
2206 or equivalently,
2207
2208     @foo = grep {!/^#/} @bar;    # weed out comments
2209
2210 Note that C<$_> is an alias to the list value, so it can be used to
2211 modify the elements of the LIST.  While this is useful and supported,
2212 it can cause bizarre results if the elements of LIST are not variables.
2213 Similarly, grep returns aliases into the original list, much as a for
2214 loop's index variable aliases the list elements.  That is, modifying an
2215 element of a list returned by grep (for example, in a C<foreach>, C<map>
2216 or another C<grep>) actually modifies the element in the original list.
2217 This is usually something to be avoided when writing clear code.
2218
2219 See also L</map> for a list composed of the results of the BLOCK or EXPR.
2220
2221 =item hex EXPR
2222
2223 =item hex
2224
2225 Interprets EXPR as a hex string and returns the corresponding value.
2226 (To convert strings that might start with either 0, 0x, or 0b, see
2227 L</oct>.)  If EXPR is omitted, uses C<$_>.
2228
2229     print hex '0xAf'; # prints '175'
2230     print hex 'aF';   # same
2231
2232 Hex strings may only represent integers.  Strings that would cause
2233 integer overflow trigger a warning.  Leading whitespace is not stripped,
2234 unlike oct().
2235
2236 =item import
2237
2238 There is no builtin C<import> function.  It is just an ordinary
2239 method (subroutine) defined (or inherited) by modules that wish to export
2240 names to another module.  The C<use> function calls the C<import> method
2241 for the package used.  See also L</use>, L<perlmod>, and L<Exporter>.
2242
2243 =item index STR,SUBSTR,POSITION
2244
2245 =item index STR,SUBSTR
2246
2247 The index function searches for one string within another, but without
2248 the wildcard-like behavior of a full regular-expression pattern match.
2249 It returns the position of the first occurrence of SUBSTR in STR at
2250 or after POSITION.  If POSITION is omitted, starts searching from the
2251 beginning of the string.  The return value is based at C<0> (or whatever
2252 you've set the C<$[> variable to--but don't do that).  If the substring
2253 is not found, returns one less than the base, ordinarily C<-1>.
2254
2255 =item int EXPR
2256
2257 =item int
2258
2259 Returns the integer portion of EXPR.  If EXPR is omitted, uses C<$_>.
2260 You should not use this function for rounding: one because it truncates
2261 towards C<0>, and two because machine representations of floating point
2262 numbers can sometimes produce counterintuitive results.  For example,
2263 C<int(-6.725/0.025)> produces -268 rather than the correct -269; that's
2264 because it's really more like -268.99999999999994315658 instead.  Usually,
2265 the C<sprintf>, C<printf>, or the C<POSIX::floor> and C<POSIX::ceil>
2266 functions will serve you better than will int().
2267
2268 =item ioctl FILEHANDLE,FUNCTION,SCALAR
2269
2270 Implements the ioctl(2) function.  You'll probably first have to say
2271
2272     require "ioctl.ph"; # probably in /usr/local/lib/perl/ioctl.ph
2273
2274 to get the correct function definitions.  If F<ioctl.ph> doesn't
2275 exist or doesn't have the correct definitions you'll have to roll your
2276 own, based on your C header files such as F<< <sys/ioctl.h> >>.
2277 (There is a Perl script called B<h2ph> that comes with the Perl kit that
2278 may help you in this, but it's nontrivial.)  SCALAR will be read and/or
2279 written depending on the FUNCTION--a pointer to the string value of SCALAR
2280 will be passed as the third argument of the actual C<ioctl> call.  (If SCALAR
2281 has no string value but does have a numeric value, that value will be
2282 passed rather than a pointer to the string value.  To guarantee this to be
2283 true, add a C<0> to the scalar before using it.)  The C<pack> and C<unpack>
2284 functions may be needed to manipulate the values of structures used by
2285 C<ioctl>.
2286
2287 The return value of C<ioctl> (and C<fcntl>) is as follows:
2288
2289         if OS returns:          then Perl returns:
2290             -1                    undefined value
2291              0                  string "0 but true"
2292         anything else               that number
2293
2294 Thus Perl returns true on success and false on failure, yet you can
2295 still easily determine the actual value returned by the operating
2296 system:
2297
2298     $retval = ioctl(...) || -1;
2299     printf "System returned %d\n", $retval;
2300
2301 The special string C<"0 but true"> is exempt from B<-w> complaints
2302 about improper numeric conversions.
2303
2304 =item join EXPR,LIST
2305
2306 Joins the separate strings of LIST into a single string with fields
2307 separated by the value of EXPR, and returns that new string.  Example:
2308
2309     $rec = join(':', $login,$passwd,$uid,$gid,$gcos,$home,$shell);
2310
2311 Beware that unlike C<split>, C<join> doesn't take a pattern as its
2312 first argument.  Compare L</split>.
2313
2314 =item keys HASH
2315
2316 Returns a list consisting of all the keys of the named hash.
2317 (In scalar context, returns the number of keys.)
2318
2319 The keys are returned in an apparently random order.  The actual
2320 random order is subject to change in future versions of perl, but it
2321 is guaranteed to be the same order as either the C<values> or C<each>
2322 function produces (given that the hash has not been modified).  Since
2323 Perl 5.8.1 the ordering is different even between different runs of
2324 Perl for security reasons (see L<perlsec/"Algorithmic Complexity
2325 Attacks">).
2326
2327 As a side effect, calling keys() resets the HASH's internal iterator,
2328 see L</each>. (In particular, calling keys() in void context resets
2329 the iterator with no other overhead.)
2330
2331 Here is yet another way to print your environment:
2332
2333     @keys = keys %ENV;
2334     @values = values %ENV;
2335     while (@keys) {
2336         print pop(@keys), '=', pop(@values), "\n";
2337     }
2338
2339 or how about sorted by key:
2340
2341     foreach $key (sort(keys %ENV)) {
2342         print $key, '=', $ENV{$key}, "\n";
2343     }
2344
2345 The returned values are copies of the original keys in the hash, so
2346 modifying them will not affect the original hash.  Compare L</values>.
2347
2348 To sort a hash by value, you'll need to use a C<sort> function.
2349 Here's a descending numeric sort of a hash by its values:
2350
2351     foreach $key (sort { $hash{$b} <=> $hash{$a} } keys %hash) {
2352         printf "%4d %s\n", $hash{$key}, $key;
2353     }
2354
2355 As an lvalue C<keys> allows you to increase the number of hash buckets
2356 allocated for the given hash.  This can gain you a measure of efficiency if
2357 you know the hash is going to get big.  (This is similar to pre-extending
2358 an array by assigning a larger number to $#array.)  If you say
2359
2360     keys %hash = 200;
2361
2362 then C<%hash> will have at least 200 buckets allocated for it--256 of them,
2363 in fact, since it rounds up to the next power of two.  These
2364 buckets will be retained even if you do C<%hash = ()>, use C<undef
2365 %hash> if you want to free the storage while C<%hash> is still in scope.
2366 You can't shrink the number of buckets allocated for the hash using
2367 C<keys> in this way (but you needn't worry about doing this by accident,
2368 as trying has no effect).
2369
2370 See also C<each>, C<values> and C<sort>.
2371
2372 =item kill SIGNAL, LIST
2373
2374 Sends a signal to a list of processes.  Returns the number of
2375 processes successfully signaled (which is not necessarily the
2376 same as the number actually killed).
2377
2378     $cnt = kill 1, $child1, $child2;
2379     kill 9, @goners;
2380
2381 If SIGNAL is zero, no signal is sent to the process.  This is a
2382 useful way to check that a child process is alive and hasn't changed
2383 its UID.  See L<perlport> for notes on the portability of this
2384 construct.
2385
2386 Unlike in the shell, if SIGNAL is negative, it kills
2387 process groups instead of processes.  (On System V, a negative I<PROCESS>
2388 number will also kill process groups, but that's not portable.)  That
2389 means you usually want to use positive not negative signals.  You may also
2390 use a signal name in quotes.
2391
2392 See L<perlipc/"Signals"> for more details.
2393
2394 =item last LABEL
2395
2396 =item last
2397
2398 The C<last> command is like the C<break> statement in C (as used in
2399 loops); it immediately exits the loop in question.  If the LABEL is
2400 omitted, the command refers to the innermost enclosing loop.  The
2401 C<continue> block, if any, is not executed:
2402
2403     LINE: while (<STDIN>) {
2404         last LINE if /^$/;      # exit when done with header
2405         #...
2406     }
2407
2408 C<last> cannot be used to exit a block which returns a value such as
2409 C<eval {}>, C<sub {}> or C<do {}>, and should not be used to exit
2410 a grep() or map() operation.
2411
2412 Note that a block by itself is semantically identical to a loop
2413 that executes once.  Thus C<last> can be used to effect an early
2414 exit out of such a block.
2415
2416 See also L</continue> for an illustration of how C<last>, C<next>, and
2417 C<redo> work.
2418
2419 =item lc EXPR
2420
2421 =item lc
2422
2423 Returns a lowercased version of EXPR.  This is the internal function
2424 implementing the C<\L> escape in double-quoted strings.  Respects
2425 current LC_CTYPE locale if C<use locale> in force.  See L<perllocale>
2426 and L<perlunicode> for more details about locale and Unicode support.
2427
2428 If EXPR is omitted, uses C<$_>.
2429
2430 =item lcfirst EXPR
2431
2432 =item lcfirst
2433
2434 Returns the value of EXPR with the first character lowercased.  This
2435 is the internal function implementing the C<\l> escape in
2436 double-quoted strings.  Respects current LC_CTYPE locale if C<use
2437 locale> in force.  See L<perllocale> and L<perlunicode> for more
2438 details about locale and Unicode support.
2439
2440 If EXPR is omitted, uses C<$_>.
2441
2442 =item length EXPR
2443
2444 =item length
2445
2446 Returns the length in I<characters> of the value of EXPR.  If EXPR is
2447 omitted, returns length of C<$_>.  Note that this cannot be used on
2448 an entire array or hash to find out how many elements these have.
2449 For that, use C<scalar @array> and C<scalar keys %hash> respectively.
2450
2451 Note the I<characters>: if the EXPR is in Unicode, you will get the
2452 number of characters, not the number of bytes.  To get the length
2453 in bytes, use C<do { use bytes; length(EXPR) }>, see L<bytes>.
2454
2455 =item link OLDFILE,NEWFILE
2456
2457 Creates a new filename linked to the old filename.  Returns true for
2458 success, false otherwise.
2459
2460 =item listen SOCKET,QUEUESIZE
2461
2462 Does the same thing that the listen system call does.  Returns true if
2463 it succeeded, false otherwise.  See the example in
2464 L<perlipc/"Sockets: Client/Server Communication">.
2465
2466 =item local EXPR
2467
2468 You really probably want to be using C<my> instead, because C<local> isn't
2469 what most people think of as "local".  See
2470 L<perlsub/"Private Variables via my()"> for details.
2471
2472 A local modifies the listed variables to be local to the enclosing
2473 block, file, or eval.  If more than one value is listed, the list must
2474 be placed in parentheses.  See L<perlsub/"Temporary Values via local()">
2475 for details, including issues with tied arrays and hashes.
2476
2477 =item localtime EXPR
2478
2479 Converts a time as returned by the time function to a 9-element list
2480 with the time analyzed for the local time zone.  Typically used as
2481 follows:
2482
2483     #  0    1    2     3     4    5     6     7     8
2484     ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst) =
2485                                                 localtime(time);
2486
2487 All list elements are numeric, and come straight out of the C `struct
2488 tm'.  $sec, $min, and $hour are the seconds, minutes, and hours of the
2489 specified time.  $mday is the day of the month, and $mon is the month
2490 itself, in the range C<0..11> with 0 indicating January and 11
2491 indicating December.  $year is the number of years since 1900.  That
2492 is, $year is C<123> in year 2023.  $wday is the day of the week, with
2493 0 indicating Sunday and 3 indicating Wednesday.  $yday is the day of
2494 the year, in the range C<0..364> (or C<0..365> in leap years.)  $isdst
2495 is true if the specified time occurs during daylight savings time,
2496 false otherwise.
2497
2498 Note that the $year element is I<not> simply the last two digits of
2499 the year.  If you assume it is, then you create non-Y2K-compliant
2500 programs--and you wouldn't want to do that, would you?
2501
2502 The proper way to get a complete 4-digit year is simply:
2503
2504         $year += 1900;
2505
2506 And to get the last two digits of the year (e.g., '01' in 2001) do:
2507
2508         $year = sprintf("%02d", $year % 100);
2509
2510 If EXPR is omitted, C<localtime()> uses the current time (C<localtime(time)>).
2511
2512 In scalar context, C<localtime()> returns the ctime(3) value:
2513
2514     $now_string = localtime;  # e.g., "Thu Oct 13 04:54:34 1994"
2515
2516 This scalar value is B<not> locale dependent, see L<perllocale>, but
2517 instead a Perl builtin.  Also see the C<Time::Local> module
2518 (to convert the second, minutes, hours, ... back to seconds since the
2519 stroke of midnight the 1st of January 1970, the value returned by
2520 time()), and the strftime(3) and mktime(3) functions available via the
2521 POSIX module.  To get somewhat similar but locale dependent date
2522 strings, set up your locale environment variables appropriately
2523 (please see L<perllocale>) and try for example:
2524
2525     use POSIX qw(strftime);
2526     $now_string = strftime "%a %b %e %H:%M:%S %Y", localtime;
2527
2528 Note that the C<%a> and C<%b>, the short forms of the day of the week
2529 and the month of the year, may not necessarily be three characters wide.
2530
2531 =item lock THING
2532
2533 This function places an advisory lock on a shared variable, or referenced
2534 object contained in I<THING> until the lock goes out of scope.
2535
2536 lock() is a "weak keyword" : this means that if you've defined a function
2537 by this name (before any calls to it), that function will be called
2538 instead. (However, if you've said C<use threads>, lock() is always a
2539 keyword.) See L<threads>.
2540
2541 =item log EXPR
2542
2543 =item log
2544
2545 Returns the natural logarithm (base I<e>) of EXPR.  If EXPR is omitted,
2546 returns log of C<$_>.  To get the log of another base, use basic algebra:
2547 The base-N log of a number is equal to the natural log of that number
2548 divided by the natural log of N.  For example:
2549
2550     sub log10 {
2551         my $n = shift;
2552         return log($n)/log(10);
2553     }
2554
2555 See also L</exp> for the inverse operation.
2556
2557 =item lstat EXPR
2558
2559 =item lstat
2560
2561 Does the same thing as the C<stat> function (including setting the
2562 special C<_> filehandle) but stats a symbolic link instead of the file
2563 the symbolic link points to.  If symbolic links are unimplemented on
2564 your system, a normal C<stat> is done.  For much more detailed
2565 information, please see the documentation for C<stat>.
2566
2567 If EXPR is omitted, stats C<$_>.
2568
2569 =item m//
2570
2571 The match operator.  See L<perlop>.
2572
2573 =item map BLOCK LIST
2574
2575 =item map EXPR,LIST
2576
2577 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
2578 C<$_> to each element) and returns the list value composed of the
2579 results of each such evaluation.  In scalar context, returns the
2580 total number of elements so generated.  Evaluates BLOCK or EXPR in
2581 list context, so each element of LIST may produce zero, one, or
2582 more elements in the returned value.
2583
2584     @chars = map(chr, @nums);
2585
2586 translates a list of numbers to the corresponding characters.  And
2587
2588     %hash = map { getkey($_) => $_ } @array;
2589
2590 is just a funny way to write
2591
2592     %hash = ();
2593     foreach $_ (@array) {
2594         $hash{getkey($_)} = $_;
2595     }
2596
2597 Note that C<$_> is an alias to the list value, so it can be used to
2598 modify the elements of the LIST.  While this is useful and supported,
2599 it can cause bizarre results if the elements of LIST are not variables.
2600 Using a regular C<foreach> loop for this purpose would be clearer in
2601 most cases.  See also L</grep> for an array composed of those items of
2602 the original list for which the BLOCK or EXPR evaluates to true.
2603
2604 C<{> starts both hash references and blocks, so C<map { ...> could be either
2605 the start of map BLOCK LIST or map EXPR, LIST. Because perl doesn't look
2606 ahead for the closing C<}> it has to take a guess at which its dealing with
2607 based what it finds just after the C<{>. Usually it gets it right, but if it
2608 doesn't it won't realize something is wrong until it gets to the C<}> and
2609 encounters the missing (or unexpected) comma. The syntax error will be
2610 reported close to the C<}> but you'll need to change something near the C<{>
2611 such as using a unary C<+> to give perl some help:
2612
2613     %hash = map {  "\L$_", 1  } @array  # perl guesses EXPR.  wrong
2614     %hash = map { +"\L$_", 1  } @array  # perl guesses BLOCK. right
2615     %hash = map { ("\L$_", 1) } @array  # this also works
2616     %hash = map {  lc($_), 1  } @array  # as does this.
2617     %hash = map +( lc($_), 1 ), @array  # this is EXPR and works!
2618
2619     %hash = map  ( lc($_), 1 ), @array  # evaluates to (1, @array)
2620
2621 or to force an anon hash constructor use C<+{>
2622
2623    @hashes = map +{ lc($_), 1 }, @array # EXPR, so needs , at end
2624
2625 and you get list of anonymous hashes each with only 1 entry.
2626
2627 =item mkdir FILENAME,MASK
2628
2629 =item mkdir FILENAME
2630
2631 Creates the directory specified by FILENAME, with permissions
2632 specified by MASK (as modified by C<umask>).  If it succeeds it
2633 returns true, otherwise it returns false and sets C<$!> (errno).
2634 If omitted, MASK defaults to 0777.
2635
2636 In general, it is better to create directories with permissive MASK,
2637 and let the user modify that with their C<umask>, than it is to supply
2638 a restrictive MASK and give the user no way to be more permissive.
2639 The exceptions to this rule are when the file or directory should be
2640 kept private (mail files, for instance).  The perlfunc(1) entry on
2641 C<umask> discusses the choice of MASK in more detail.
2642
2643 Note that according to the POSIX 1003.1-1996 the FILENAME may have any
2644 number of trailing slashes.  Some operating and filesystems do not get
2645 this right, so Perl automatically removes all trailing slashes to keep
2646 everyone happy.
2647
2648 =item msgctl ID,CMD,ARG
2649
2650 Calls the System V IPC function msgctl(2).  You'll probably have to say
2651
2652     use IPC::SysV;
2653
2654 first to get the correct constant definitions.  If CMD is C<IPC_STAT>,
2655 then ARG must be a variable which will hold the returned C<msqid_ds>
2656 structure.  Returns like C<ioctl>: the undefined value for error,
2657 C<"0 but true"> for zero, or the actual return value otherwise.  See also
2658 L<perlipc/"SysV IPC">, C<IPC::SysV>, and C<IPC::Semaphore> documentation.
2659
2660 =item msgget KEY,FLAGS
2661
2662 Calls the System V IPC function msgget(2).  Returns the message queue
2663 id, or the undefined value if there is an error.  See also
2664 L<perlipc/"SysV IPC"> and C<IPC::SysV> and C<IPC::Msg> documentation.
2665
2666 =item msgrcv ID,VAR,SIZE,TYPE,FLAGS
2667
2668 Calls the System V IPC function msgrcv to receive a message from
2669 message queue ID into variable VAR with a maximum message size of
2670 SIZE.  Note that when a message is received, the message type as a
2671 native long integer will be the first thing in VAR, followed by the
2672 actual message.  This packing may be opened with C<unpack("l! a*")>.
2673 Taints the variable.  Returns true if successful, or false if there is
2674 an error.  See also L<perlipc/"SysV IPC">, C<IPC::SysV>, and
2675 C<IPC::SysV::Msg> documentation.
2676
2677 =item msgsnd ID,MSG,FLAGS
2678
2679 Calls the System V IPC function msgsnd to send the message MSG to the
2680 message queue ID.  MSG must begin with the native long integer message
2681 type, and be followed by the length of the actual message, and finally
2682 the message itself.  This kind of packing can be achieved with
2683 C<pack("l! a*", $type, $message)>.  Returns true if successful,
2684 or false if there is an error.  See also C<IPC::SysV>
2685 and C<IPC::SysV::Msg> documentation.
2686
2687 =item my EXPR
2688
2689 =item my TYPE EXPR
2690
2691 =item my EXPR : ATTRS
2692
2693 =item my TYPE EXPR : ATTRS
2694
2695 A C<my> declares the listed variables to be local (lexically) to the
2696 enclosing block, file, or C<eval>.  If more than one value is listed,
2697 the list must be placed in parentheses.
2698
2699 The exact semantics and interface of TYPE and ATTRS are still
2700 evolving.  TYPE is currently bound to the use of C<fields> pragma,
2701 and attributes are handled using the C<attributes> pragma, or starting
2702 from Perl 5.8.0 also via the C<Attribute::Handlers> module.  See
2703 L<perlsub/"Private Variables via my()"> for details, and L<fields>,
2704 L<attributes>, and L<Attribute::Handlers>.
2705
2706 =item next LABEL
2707
2708 =item next
2709
2710 The C<next> command is like the C<continue> statement in C; it starts
2711 the next iteration of the loop:
2712
2713     LINE: while (<STDIN>) {
2714         next LINE if /^#/;      # discard comments
2715         #...
2716     }
2717
2718 Note that if there were a C<continue> block on the above, it would get
2719 executed even on discarded lines.  If the LABEL is omitted, the command
2720 refers to the innermost enclosing loop.
2721
2722 C<next> cannot be used to exit a block which returns a value such as
2723 C<eval {}>, C<sub {}> or C<do {}>, and should not be used to exit
2724 a grep() or map() operation.
2725
2726 Note that a block by itself is semantically identical to a loop
2727 that executes once.  Thus C<next> will exit such a block early.
2728
2729 See also L</continue> for an illustration of how C<last>, C<next>, and
2730 C<redo> work.
2731
2732 =item no Module VERSION LIST
2733
2734 =item no Module VERSION
2735
2736 =item no Module LIST
2737
2738 =item no Module
2739
2740 See the C<use> function, of which C<no> is the opposite.
2741
2742 =item oct EXPR
2743
2744 =item oct
2745
2746 Interprets EXPR as an octal string and returns the corresponding
2747 value.  (If EXPR happens to start off with C<0x>, interprets it as a
2748 hex string.  If EXPR starts off with C<0b>, it is interpreted as a
2749 binary string.  Leading whitespace is ignored in all three cases.)
2750 The following will handle decimal, binary, octal, and hex in the standard
2751 Perl or C notation:
2752
2753     $val = oct($val) if $val =~ /^0/;
2754
2755 If EXPR is omitted, uses C<$_>.   To go the other way (produce a number
2756 in octal), use sprintf() or printf():
2757
2758     $perms = (stat("filename"))[2] & 07777;
2759     $oct_perms = sprintf "%lo", $perms;
2760
2761 The oct() function is commonly used when a string such as C<644> needs
2762 to be converted into a file mode, for example. (Although perl will
2763 automatically convert strings into numbers as needed, this automatic
2764 conversion assumes base 10.)
2765
2766 =item open FILEHANDLE,EXPR
2767
2768 =item open FILEHANDLE,MODE,EXPR
2769
2770 =item open FILEHANDLE,MODE,EXPR,LIST
2771
2772 =item open FILEHANDLE,MODE,REFERENCE
2773
2774 =item open FILEHANDLE
2775
2776 Opens the file whose filename is given by EXPR, and associates it with
2777 FILEHANDLE.
2778
2779 (The following is a comprehensive reference to open(): for a gentler
2780 introduction you may consider L<perlopentut>.)
2781
2782 If FILEHANDLE is an undefined scalar variable (or array or hash element)
2783 the variable is assigned a reference to a new anonymous filehandle,
2784 otherwise if FILEHANDLE is an expression, its value is used as the name of
2785 the real filehandle wanted.  (This is considered a symbolic reference, so
2786 C<use strict 'refs'> should I<not> be in effect.)
2787
2788 If EXPR is omitted, the scalar variable of the same name as the
2789 FILEHANDLE contains the filename.  (Note that lexical variables--those
2790 declared with C<my>--will not work for this purpose; so if you're
2791 using C<my>, specify EXPR in your call to open.)
2792
2793 If three or more arguments are specified then the mode of opening and
2794 the file name are separate. If MODE is C<< '<' >> or nothing, the file
2795 is opened for input.  If MODE is C<< '>' >>, the file is truncated and
2796 opened for output, being created if necessary.  If MODE is C<<< '>>' >>>,
2797 the file is opened for appending, again being created if necessary.
2798
2799 You can put a C<'+'> in front of the C<< '>' >> or C<< '<' >> to
2800 indicate that you want both read and write access to the file; thus
2801 C<< '+<' >> is almost always preferred for read/write updates--the C<<
2802 '+>' >> mode would clobber the file first.  You can't usually use
2803 either read-write mode for updating textfiles, since they have
2804 variable length records.  See the B<-i> switch in L<perlrun> for a
2805 better approach.  The file is created with permissions of C<0666>
2806 modified by the process' C<umask> value.
2807
2808 These various prefixes correspond to the fopen(3) modes of C<'r'>,
2809 C<'r+'>, C<'w'>, C<'w+'>, C<'a'>, and C<'a+'>.
2810
2811 In the 2-arguments (and 1-argument) form of the call the mode and
2812 filename should be concatenated (in this order), possibly separated by
2813 spaces.  It is possible to omit the mode in these forms if the mode is
2814 C<< '<' >>.
2815
2816 If the filename begins with C<'|'>, the filename is interpreted as a
2817 command to which output is to be piped, and if the filename ends with a
2818 C<'|'>, the filename is interpreted as a command which pipes output to
2819 us.  See L<perlipc/"Using open() for IPC">
2820 for more examples of this.  (You are not allowed to C<open> to a command
2821 that pipes both in I<and> out, but see L<IPC::Open2>, L<IPC::Open3>,
2822 and L<perlipc/"Bidirectional Communication with Another Process">
2823 for alternatives.)
2824
2825 For three or more arguments if MODE is C<'|-'>, the filename is
2826 interpreted as a command to which output is to be piped, and if MODE
2827 is C<'-|'>, the filename is interpreted as a command which pipes
2828 output to us.  In the 2-arguments (and 1-argument) form one should
2829 replace dash (C<'-'>) with the command.
2830 See L<perlipc/"Using open() for IPC"> for more examples of this.
2831 (You are not allowed to C<open> to a command that pipes both in I<and>
2832 out, but see L<IPC::Open2>, L<IPC::Open3>, and
2833 L<perlipc/"Bidirectional Communication"> for alternatives.)
2834
2835 In the three-or-more argument form of pipe opens, if LIST is specified
2836 (extra arguments after the command name) then LIST becomes arguments
2837 to the command invoked if the platform supports it.  The meaning of
2838 C<open> with more than three arguments for non-pipe modes is not yet
2839 specified. Experimental "layers" may give extra LIST arguments
2840 meaning.
2841
2842 In the 2-arguments (and 1-argument) form opening C<'-'> opens STDIN
2843 and opening C<< '>-' >> opens STDOUT.
2844
2845 You may use the three-argument form of open to specify IO "layers"
2846 (sometimes also referred to as "disciplines") to be applied to the handle
2847 that affect how the input and output are processed (see L<open> and
2848 L<PerlIO> for more details). For example
2849
2850   open(FH, "<:utf8", "file")
2851
2852 will open the UTF-8 encoded file containing Unicode characters,
2853 see L<perluniintro>. (Note that if layers are specified in the
2854 three-arg form then default layers set by the C<open> pragma are
2855 ignored.)
2856
2857 Open returns nonzero upon success, the undefined value otherwise.  If
2858 the C<open> involved a pipe, the return value happens to be the pid of
2859 the subprocess.
2860
2861 If you're running Perl on a system that distinguishes between text
2862 files and binary files, then you should check out L</binmode> for tips
2863 for dealing with this.  The key distinction between systems that need
2864 C<binmode> and those that don't is their text file formats.  Systems
2865 like Unix, Mac OS, and Plan 9, which delimit lines with a single
2866 character, and which encode that character in C as C<"\n">, do not
2867 need C<binmode>.  The rest need it.
2868
2869 When opening a file, it's usually a bad idea to continue normal execution
2870 if the request failed, so C<open> is frequently used in connection with
2871 C<die>.  Even if C<die> won't do what you want (say, in a CGI script,
2872 where you want to make a nicely formatted error message (but there are
2873 modules that can help with that problem)) you should always check
2874 the return value from opening a file.  The infrequent exception is when
2875 working with an unopened filehandle is actually what you want to do.
2876
2877 As a special case the 3 arg form with a read/write mode and the third
2878 argument being C<undef>:
2879
2880     open(TMP, "+>", undef) or die ...
2881
2882 opens a filehandle to an anonymous temporary file.  Also using "+<"
2883 works for symmetry, but you really should consider writing something
2884 to the temporary file first.  You will need to seek() to do the
2885 reading.
2886
2887 File handles can be opened to "in memory" files held in Perl scalars via:
2888
2889     open($fh, '>', \$variable) || ..
2890
2891 Though if you try to re-open C<STDOUT> or C<STDERR> as an "in memory"
2892 file, you have to close it first:
2893
2894     close STDOUT;
2895     open STDOUT, '>', \$variable or die "Can't open STDOUT: $!";
2896
2897 Examples:
2898
2899     $ARTICLE = 100;
2900     open ARTICLE or die "Can't find article $ARTICLE: $!\n";
2901     while (<ARTICLE>) {...
2902
2903     open(LOG, '>>/usr/spool/news/twitlog');     # (log is reserved)
2904     # if the open fails, output is discarded
2905
2906     open(DBASE, '+<', 'dbase.mine')             # open for update
2907         or die "Can't open 'dbase.mine' for update: $!";
2908
2909     open(DBASE, '+<dbase.mine')                 # ditto
2910         or die "Can't open 'dbase.mine' for update: $!";
2911
2912     open(ARTICLE, '-|', "caesar <$article")     # decrypt article
2913         or die "Can't start caesar: $!";
2914
2915     open(ARTICLE, "caesar <$article |")         # ditto
2916         or die "Can't start caesar: $!";
2917
2918     open(EXTRACT, "|sort >/tmp/Tmp$$")          # $$ is our process id
2919         or die "Can't start sort: $!";
2920
2921     # in memory files
2922     open(MEMORY,'>', \$var)
2923         or die "Can't open memory file: $!";
2924     print MEMORY "foo!\n";                      # output will end up in $var
2925
2926     # process argument list of files along with any includes
2927
2928     foreach $file (@ARGV) {
2929         process($file, 'fh00');
2930     }
2931
2932     sub process {
2933         my($filename, $input) = @_;
2934         $input++;               # this is a string increment
2935         unless (open($input, $filename)) {
2936             print STDERR "Can't open $filename: $!\n";
2937             return;
2938         }
2939
2940         local $_;
2941         while (<$input>) {              # note use of indirection
2942             if (/^#include "(.*)"/) {
2943                 process($1, $input);
2944                 next;
2945             }
2946             #...                # whatever
2947         }
2948     }
2949
2950 You may also, in the Bourne shell tradition, specify an EXPR beginning
2951 with C<< '>&' >>, in which case the rest of the string is interpreted
2952 as the name of a filehandle (or file descriptor, if numeric) to be
2953 duped (as L<dup(2)>) and opened.  You may use C<&> after C<< > >>,
2954 C<<< >> >>>, C<< < >>, C<< +> >>, C<<< +>> >>>, and C<< +< >>.
2955 The mode you specify should match the mode of the original filehandle.
2956 (Duping a filehandle does not take into account any existing contents
2957 of IO buffers.) If you use the 3 arg form then you can pass either a
2958 number, the name of a filehandle or the normal "reference to a glob".
2959
2960 Here is a script that saves, redirects, and restores C<STDOUT> and
2961 C<STDERR> using various methods:
2962
2963     #!/usr/bin/perl
2964     open my $oldout, ">&STDOUT"     or die "Can't dup STDOUT: $!";
2965     open OLDERR,     ">&", \*STDERR or die "Can't dup STDERR: $!";
2966
2967     open STDOUT, '>', "foo.out" or die "Can't redirect STDOUT: $!";
2968     open STDERR, ">&STDOUT"     or die "Can't dup STDOUT: $!";
2969
2970     select STDERR; $| = 1;      # make unbuffered
2971     select STDOUT; $| = 1;      # make unbuffered
2972
2973     print STDOUT "stdout 1\n";  # this works for
2974     print STDERR "stderr 1\n";  # subprocesses too
2975
2976     close STDOUT;
2977     close STDERR;
2978
2979     open STDOUT, ">&", $oldout or die "Can't dup \$oldout: $!";
2980     open STDERR, ">&OLDERR"    or die "Can't dup OLDERR: $!";
2981
2982     print STDOUT "stdout 2\n";
2983     print STDERR "stderr 2\n";
2984
2985 If you specify C<< '<&=X' >>, where C<X> is a file descriptor number
2986 or a filehandle, then Perl will do an equivalent of C's C<fdopen> of
2987 that file descriptor (and not call L<dup(2)>); this is more
2988 parsimonious of file descriptors.  For example:
2989
2990     # open for input, reusing the fileno of $fd
2991     open(FILEHANDLE, "<&=$fd")
2992
2993 or
2994
2995     open(FILEHANDLE, "<&=", $fd)
2996
2997 or
2998
2999     # open for append, using the fileno of OLDFH
3000     open(FH, ">>&=", OLDFH)
3001
3002 or
3003
3004     open(FH, ">>&=OLDFH")
3005
3006 Being parsimonious on filehandles is also useful (besides being
3007 parsimonious) for example when something is dependent on file
3008 descriptors, like for example locking using flock().  If you do just
3009 C<< open(A, '>>&B') >>, the filehandle A will not have the same file
3010 descriptor as B, and therefore flock(A) will not flock(B), and vice
3011 versa.  But with C<< open(A, '>>&=B') >> the filehandles will share
3012 the same file descriptor.
3013
3014 Note that if you are using Perls older than 5.8.0, Perl will be using
3015 the standard C libraries' fdopen() to implement the "=" functionality.
3016 On many UNIX systems fdopen() fails when file descriptors exceed a
3017 certain value, typically 255.  For Perls 5.8.0 and later, PerlIO is
3018 most often the default.
3019
3020 You can see whether Perl has been compiled with PerlIO or not by
3021 running C<perl -V> and looking for C<useperlio=> line.  If C<useperlio>
3022 is C<define>, you have PerlIO, otherwise you don't.
3023
3024 If you open a pipe on the command C<'-'>, i.e., either C<'|-'> or C<'-|'>
3025 with 2-arguments (or 1-argument) form of open(), then
3026 there is an implicit fork done, and the return value of open is the pid
3027 of the child within the parent process, and C<0> within the child
3028 process.  (Use C<defined($pid)> to determine whether the open was successful.)
3029 The filehandle behaves normally for the parent, but i/o to that
3030 filehandle is piped from/to the STDOUT/STDIN of the child process.
3031 In the child process the filehandle isn't opened--i/o happens from/to
3032 the new STDOUT or STDIN.  Typically this is used like the normal
3033 piped open when you want to exercise more control over just how the
3034 pipe command gets executed, such as when you are running setuid, and
3035 don't want to have to scan shell commands for metacharacters.
3036 The following triples are more or less equivalent:
3037
3038     open(FOO, "|tr '[a-z]' '[A-Z]'");
3039     open(FOO, '|-', "tr '[a-z]' '[A-Z]'");
3040     open(FOO, '|-') || exec 'tr', '[a-z]', '[A-Z]';
3041     open(FOO, '|-', "tr", '[a-z]', '[A-Z]');
3042
3043     open(FOO, "cat -n '$file'|");
3044     open(FOO, '-|', "cat -n '$file'");
3045     open(FOO, '-|') || exec 'cat', '-n', $file;
3046     open(FOO, '-|', "cat", '-n', $file);
3047
3048 The last example in each block shows the pipe as "list form", which is
3049 not yet supported on all platforms.  A good rule of thumb is that if
3050 your platform has true C<fork()> (in other words, if your platform is
3051 UNIX) you can use the list form.
3052
3053 See L<perlipc/"Safe Pipe Opens"> for more examples of this.
3054
3055 Beginning with v5.6.0, Perl will attempt to flush all files opened for
3056 output before any operation that may do a fork, but this may not be
3057 supported on some platforms (see L<perlport>).  To be safe, you may need
3058 to set C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method
3059 of C<IO::Handle> on any open handles.
3060
3061 On systems that support a close-on-exec flag on files, the flag will
3062 be set for the newly opened file descriptor as determined by the value
3063 of $^F.  See L<perlvar/$^F>.
3064
3065 Closing any piped filehandle causes the parent process to wait for the
3066 child to finish, and returns the status value in C<$?>.
3067
3068 The filename passed to 2-argument (or 1-argument) form of open() will
3069 have leading and trailing whitespace deleted, and the normal
3070 redirection characters honored.  This property, known as "magic open",
3071 can often be used to good effect.  A user could specify a filename of
3072 F<"rsh cat file |">, or you could change certain filenames as needed:
3073
3074     $filename =~ s/(.*\.gz)\s*$/gzip -dc < $1|/;
3075     open(FH, $filename) or die "Can't open $filename: $!";
3076
3077 Use 3-argument form to open a file with arbitrary weird characters in it,
3078
3079     open(FOO, '<', $file);
3080
3081 otherwise it's necessary to protect any leading and trailing whitespace:
3082
3083     $file =~ s#^(\s)#./$1#;
3084     open(FOO, "< $file\0");
3085
3086 (this may not work on some bizarre filesystems).  One should
3087 conscientiously choose between the I<magic> and 3-arguments form
3088 of open():
3089
3090     open IN, $ARGV[0];
3091
3092 will allow the user to specify an argument of the form C<"rsh cat file |">,
3093 but will not work on a filename which happens to have a trailing space, while
3094
3095     open IN, '<', $ARGV[0];
3096
3097 will have exactly the opposite restrictions.
3098
3099 If you want a "real" C C<open> (see L<open(2)> on your system), then you
3100 should use the C<sysopen> function, which involves no such magic (but
3101 may use subtly different filemodes than Perl open(), which is mapped
3102 to C fopen()).  This is
3103 another way to protect your filenames from interpretation.  For example:
3104
3105     use IO::Handle;
3106     sysopen(HANDLE, $path, O_RDWR|O_CREAT|O_EXCL)
3107         or die "sysopen $path: $!";
3108     $oldfh = select(HANDLE); $| = 1; select($oldfh);
3109     print HANDLE "stuff $$\n";
3110     seek(HANDLE, 0, 0);
3111     print "File contains: ", <HANDLE>;
3112
3113 Using the constructor from the C<IO::Handle> package (or one of its
3114 subclasses, such as C<IO::File> or C<IO::Socket>), you can generate anonymous
3115 filehandles that have the scope of whatever variables hold references to
3116 them, and automatically close whenever and however you leave that scope:
3117
3118     use IO::File;
3119     #...
3120     sub read_myfile_munged {
3121         my $ALL = shift;
3122         my $handle = new IO::File;
3123         open($handle, "myfile") or die "myfile: $!";
3124         $first = <$handle>
3125             or return ();     # Automatically closed here.
3126         mung $first or die "mung failed";       # Or here.
3127         return $first, <$handle> if $ALL;       # Or here.
3128         $first;                                 # Or here.
3129     }
3130
3131 See L</seek> for some details about mixing reading and writing.
3132
3133 =item opendir DIRHANDLE,EXPR
3134
3135 Opens a directory named EXPR for processing by C<readdir>, C<telldir>,
3136 C<seekdir>, C<rewinddir>, and C<closedir>.  Returns true if successful.
3137 DIRHANDLE may be an expression whose value can be used as an indirect
3138 dirhandle, usually the real dirhandle name.  If DIRHANDLE is an undefined
3139 scalar variable (or array or hash element), the variable is assigned a
3140 reference to a new anonymous dirhandle.
3141 DIRHANDLEs have their own namespace separate from FILEHANDLEs.
3142
3143 =item ord EXPR
3144
3145 =item ord
3146
3147 Returns the numeric (the native 8-bit encoding, like ASCII or EBCDIC,
3148 or Unicode) value of the first character of EXPR.  If EXPR is omitted,
3149 uses C<$_>.
3150
3151 For the reverse, see L</chr>.
3152 See L<perlunicode> and L<encoding> for more about Unicode.
3153
3154 =item our EXPR
3155
3156 =item our EXPR TYPE
3157
3158 =item our EXPR : ATTRS
3159
3160 =item our TYPE EXPR : ATTRS
3161
3162 An C<our> declares the listed variables to be valid globals within
3163 the enclosing block, file, or C<eval>.  That is, it has the same
3164 scoping rules as a "my" declaration, but does not create a local
3165 variable.  If more than one value is listed, the list must be placed
3166 in parentheses.  The C<our> declaration has no semantic effect unless
3167 "use strict vars" is in effect, in which case it lets you use the
3168 declared global variable without qualifying it with a package name.
3169 (But only within the lexical scope of the C<our> declaration.  In this
3170 it differs from "use vars", which is package scoped.)
3171
3172 An C<our> declaration declares a global variable that will be visible
3173 across its entire lexical scope, even across package boundaries.  The
3174 package in which the variable is entered is determined at the point
3175 of the declaration, not at the point of use.  This means the following
3176 behavior holds:
3177
3178     package Foo;
3179     our $bar;           # declares $Foo::bar for rest of lexical scope
3180     $bar = 20;
3181
3182     package Bar;
3183     print $bar;         # prints 20
3184
3185 Multiple C<our> declarations in the same lexical scope are allowed
3186 if they are in different packages.  If they happened to be in the same
3187 package, Perl will emit warnings if you have asked for them.
3188
3189     use warnings;
3190     package Foo;
3191     our $bar;           # declares $Foo::bar for rest of lexical scope
3192     $bar = 20;
3193
3194     package Bar;
3195     our $bar = 30;      # declares $Bar::bar for rest of lexical scope
3196     print $bar;         # prints 30
3197
3198     our $bar;           # emits warning
3199
3200 An C<our> declaration may also have a list of attributes associated
3201 with it.
3202
3203 The exact semantics and interface of TYPE and ATTRS are still
3204 evolving.  TYPE is currently bound to the use of C<fields> pragma,
3205 and attributes are handled using the C<attributes> pragma, or starting
3206 from Perl 5.8.0 also via the C<Attribute::Handlers> module.  See
3207 L<perlsub/"Private Variables via my()"> for details, and L<fields>,
3208 L<attributes>, and L<Attribute::Handlers>.
3209
3210 The only currently recognized C<our()> attribute is C<unique> which
3211 indicates that a single copy of the global is to be used by all
3212 interpreters should the program happen to be running in a
3213 multi-interpreter environment. (The default behaviour would be for
3214 each interpreter to have its own copy of the global.)  Examples:
3215
3216     our @EXPORT : unique = qw(foo);
3217     our %EXPORT_TAGS : unique = (bar => [qw(aa bb cc)]);
3218     our $VERSION : unique = "1.00";
3219
3220 Note that this attribute also has the effect of making the global
3221 readonly when the first new interpreter is cloned (for example,
3222 when the first new thread is created).
3223
3224 Multi-interpreter environments can come to being either through the
3225 fork() emulation on Windows platforms, or by embedding perl in a
3226 multi-threaded application.  The C<unique> attribute does nothing in
3227 all other environments.
3228
3229 =item pack TEMPLATE,LIST
3230
3231 Takes a LIST of values and converts it into a string using the rules
3232 given by the TEMPLATE.  The resulting string is the concatenation of
3233 the converted values.  Typically, each converted value looks
3234 like its machine-level representation.  For example, on 32-bit machines
3235 a converted integer may be represented by a sequence of 4 bytes.
3236
3237 The TEMPLATE is a sequence of characters that give the order and type
3238 of values, as follows:
3239
3240     a   A string with arbitrary binary data, will be null padded.
3241     A   A text (ASCII) string, will be space padded.
3242     Z   A null terminated (ASCIZ) string, will be null padded.
3243
3244     b   A bit string (ascending bit order inside each byte, like vec()).
3245     B   A bit string (descending bit order inside each byte).
3246     h   A hex string (low nybble first).
3247     H   A hex string (high nybble first).
3248
3249     c   A signed char value.
3250     C   An unsigned char value.  Only does bytes.  See U for Unicode.
3251
3252     s   A signed short value.
3253     S   An unsigned short value.
3254           (This 'short' is _exactly_ 16 bits, which may differ from
3255            what a local C compiler calls 'short'.  If you want
3256            native-length shorts, use the '!' suffix.)
3257
3258     i   A signed integer value.
3259     I   An unsigned integer value.
3260           (This 'integer' is _at_least_ 32 bits wide.  Its exact
3261            size depends on what a local C compiler calls 'int',
3262            and may even be larger than the 'long' described in
3263            the next item.)
3264
3265     l   A signed long value.
3266     L   An unsigned long value.
3267           (This 'long' is _exactly_ 32 bits, which may differ from
3268            what a local C compiler calls 'long'.  If you want
3269            native-length longs, use the '!' suffix.)
3270
3271     n   An unsigned short in "network" (big-endian) order.
3272     N   An unsigned long in "network" (big-endian) order.
3273     v   An unsigned short in "VAX" (little-endian) order.
3274     V   An unsigned long in "VAX" (little-endian) order.
3275           (These 'shorts' and 'longs' are _exactly_ 16 bits and
3276            _exactly_ 32 bits, respectively.)
3277
3278     q   A signed quad (64-bit) value.
3279     Q   An unsigned quad value.
3280           (Quads are available only if your system supports 64-bit
3281            integer values _and_ if Perl has been compiled to support those.
3282            Causes a fatal error otherwise.)
3283
3284     j   A signed integer value (a Perl internal integer, IV).
3285     J   An unsigned integer value (a Perl internal unsigned integer, UV).
3286
3287     f   A single-precision float in the native format.
3288     d   A double-precision float in the native format.
3289
3290     F   A floating point value in the native native format
3291            (a Perl internal floating point value, NV).
3292     D   A long double-precision float in the native format.
3293           (Long doubles are available only if your system supports long
3294            double values _and_ if Perl has been compiled to support those.
3295            Causes a fatal error otherwise.)
3296
3297     p   A pointer to a null-terminated string.
3298     P   A pointer to a structure (fixed-length string).
3299
3300     u   A uuencoded string.
3301     U   A Unicode character number.  Encodes to UTF-8 internally
3302         (or UTF-EBCDIC in EBCDIC platforms).
3303
3304     w   A BER compressed integer.  Its bytes represent an unsigned
3305         integer in base 128, most significant digit first, with as
3306         few digits as possible.  Bit eight (the high bit) is set
3307         on each byte except the last.
3308
3309     x   A null byte.
3310     X   Back up a byte.
3311     @   Null fill to absolute position, counted from the start of
3312         the innermost ()-group.
3313     (   Start of a ()-group.
3314
3315 The following rules apply:
3316
3317 =over 8
3318
3319 =item *
3320
3321 Each letter may optionally be followed by a number giving a repeat
3322 count.  With all types except C<a>, C<A>, C<Z>, C<b>, C<B>, C<h>,
3323 C<H>, C<@>, C<x>, C<X> and C<P> the pack function will gobble up that
3324 many values from the LIST.  A C<*> for the repeat count means to use
3325 however many items are left, except for C<@>, C<x>, C<X>, where it is
3326 equivalent to C<0>, and C<u>, where it is equivalent to 1 (or 45, what
3327 is the same).  A numeric repeat count may optionally be enclosed in
3328 brackets, as in C<pack 'C[80]', @arr>.
3329
3330 One can replace the numeric repeat count by a template enclosed in brackets;
3331 then the packed length of this template in bytes is used as a count.
3332 For example, C<x[L]> skips a long (it skips the number of bytes in a long);
3333 the template C<$t X[$t] $t> unpack()s twice what $t unpacks.
3334 If the template in brackets contains alignment commands (such as C<x![d]>),
3335 its packed length is calculated as if the start of the template has the maximal
3336 possible alignment.
3337
3338 When used with C<Z>, C<*> results in the addition of a trailing null
3339 byte (so the packed result will be one longer than the byte C<length>
3340 of the item).
3341
3342 The repeat count for C<u> is interpreted as the maximal number of bytes
3343 to encode per line of output, with 0 and 1 replaced by 45.
3344
3345 =item *
3346
3347 The C<a>, C<A>, and C<Z> types gobble just one value, but pack it as a
3348 string of length count, padding with nulls or spaces as necessary.  When
3349 unpacking, C<A> strips trailing spaces and nulls, C<Z> strips everything
3350 after the first null, and C<a> returns data verbatim.  When packing,
3351 C<a>, and C<Z> are equivalent.
3352
3353 If the value-to-pack is too long, it is truncated.  If too long and an
3354 explicit count is provided, C<Z> packs only C<$count-1> bytes, followed
3355 by a null byte.  Thus C<Z> always packs a trailing null byte under
3356 all circumstances.
3357
3358 =item *
3359
3360 Likewise, the C<b> and C<B> fields pack a string that many bits long.
3361 Each byte of the input field of pack() generates 1 bit of the result.
3362 Each result bit is based on the least-significant bit of the corresponding
3363 input byte, i.e., on C<ord($byte)%2>.  In particular, bytes C<"0"> and
3364 C<"1"> generate bits 0 and 1, as do bytes C<"\0"> and C<"\1">.
3365
3366 Starting from the beginning of the input string of pack(), each 8-tuple
3367 of bytes is converted to 1 byte of output.  With format C<b>
3368 the first byte of the 8-tuple determines the least-significant bit of a
3369 byte, and with format C<B> it determines the most-significant bit of
3370 a byte.
3371
3372 If the length of the input string is not exactly divisible by 8, the
3373 remainder is packed as if the input string were padded by null bytes
3374 at the end.  Similarly, during unpack()ing the "extra" bits are ignored.
3375
3376 If the input string of pack() is longer than needed, extra bytes are ignored.
3377 A C<*> for the repeat count of pack() means to use all the bytes of
3378 the input field.  On unpack()ing the bits are converted to a string
3379 of C<"0">s and C<"1">s.
3380
3381 =item *
3382
3383 The C<h> and C<H> fields pack a string that many nybbles (4-bit groups,
3384 representable as hexadecimal digits, 0-9a-f) long.
3385
3386 Each byte of the input field of pack() generates 4 bits of the result.
3387 For non-alphabetical bytes the result is based on the 4 least-significant
3388 bits of the input byte, i.e., on C<ord($byte)%16>.  In particular,
3389 bytes C<"0"> and C<"1"> generate nybbles 0 and 1, as do bytes
3390 C<"\0"> and C<"\1">.  For bytes C<"a".."f"> and C<"A".."F"> the result
3391 is compatible with the usual hexadecimal digits, so that C<"a"> and
3392 C<"A"> both generate the nybble C<0xa==10>.  The result for bytes
3393 C<"g".."z"> and C<"G".."Z"> is not well-defined.
3394
3395 Starting from the beginning of the input string of pack(), each pair
3396 of bytes is converted to 1 byte of output.  With format C<h> the
3397 first byte of the pair determines the least-significant nybble of the
3398 output byte, and with format C<H> it determines the most-significant
3399 nybble.
3400
3401 If the length of the input string is not even, it behaves as if padded
3402 by a null byte at the end.  Similarly, during unpack()ing the "extra"
3403 nybbles are ignored.
3404
3405 If the input string of pack() is longer than needed, extra bytes are ignored.
3406 A C<*> for the repeat count of pack() means to use all the bytes of
3407 the input field.  On unpack()ing the bits are converted to a string
3408 of hexadecimal digits.
3409
3410 =item *
3411
3412 The C<p> type packs a pointer to a null-terminated string.  You are
3413 responsible for ensuring the string is not a temporary value (which can
3414 potentially get deallocated before you get around to using the packed result).
3415 The C<P> type packs a pointer to a structure of the size indicated by the
3416 length.  A NULL pointer is created if the corresponding value for C<p> or
3417 C<P> is C<undef>, similarly for unpack().
3418
3419 =item *
3420
3421 The C</> template character allows packing and unpacking of strings where
3422 the packed structure contains a byte count followed by the string itself.
3423 You write I<length-item>C</>I<string-item>.
3424
3425 The I<length-item> can be any C<pack> template letter, and describes
3426 how the length value is packed.  The ones likely to be of most use are
3427 integer-packing ones like C<n> (for Java strings), C<w> (for ASN.1 or
3428 SNMP) and C<N> (for Sun XDR).
3429
3430 For C<pack>, the I<string-item> must, at present, be C<"A*">, C<"a*"> or
3431 C<"Z*">. For C<unpack> the length of the string is obtained from the
3432 I<length-item>, but if you put in the '*' it will be ignored. For all other
3433 codes, C<unpack> applies the length value to the next item, which must not
3434 have a repeat count.
3435
3436     unpack 'C/a', "\04Gurusamy";        gives 'Guru'
3437     unpack 'a3/A* A*', '007 Bond  J ';  gives (' Bond','J')
3438     pack 'n/a* w/a*','hello,','world';  gives "\000\006hello,\005world"
3439
3440 The I<length-item> is not returned explicitly from C<unpack>.
3441
3442 Adding a count to the I<length-item> letter is unlikely to do anything
3443 useful, unless that letter is C<A>, C<a> or C<Z>.  Packing with a
3444 I<length-item> of C<a> or C<Z> may introduce C<"\000"> characters,
3445 which Perl does not regard as legal in numeric strings.
3446
3447 =item *
3448
3449 The integer types C<s>, C<S>, C<l>, and C<L> may be
3450 immediately followed by a C<!> suffix to signify native shorts or
3451 longs--as you can see from above for example a bare C<l> does mean
3452 exactly 32 bits, the native C<long> (as seen by the local C compiler)
3453 may be larger.  This is an issue mainly in 64-bit platforms.  You can
3454 see whether using C<!> makes any difference by
3455
3456         print length(pack("s")), " ", length(pack("s!")), "\n";
3457         print length(pack("l")), " ", length(pack("l!")), "\n";
3458
3459 C<i!> and C<I!> also work but only because of completeness;
3460 they are identical to C<i> and C<I>.
3461
3462 The actual sizes (in bytes) of native shorts, ints, longs, and long
3463 longs on the platform where Perl was built are also available via
3464 L<Config>:
3465
3466        use Config;
3467        print $Config{shortsize},    "\n";
3468        print $Config{intsize},      "\n";
3469        print $Config{longsize},     "\n";
3470        print $Config{longlongsize}, "\n";
3471
3472 (The C<$Config{longlongsize}> will be undefined if your system does
3473 not support long longs.)
3474
3475 =item *
3476
3477 The integer formats C<s>, C<S>, C<i>, C<I>, C<l>, C<L>, C<j>, and C<J>
3478 are inherently non-portable between processors and operating systems
3479 because they obey the native byteorder and endianness.  For example a
3480 4-byte integer 0x12345678 (305419896 decimal) would be ordered natively
3481 (arranged in and handled by the CPU registers) into bytes as
3482
3483         0x12 0x34 0x56 0x78     # big-endian
3484         0x78 0x56 0x34 0x12     # little-endian
3485
3486 Basically, the Intel and VAX CPUs are little-endian, while everybody
3487 else, for example Motorola m68k/88k, PPC, Sparc, HP PA, Power, and
3488 Cray are big-endian.  Alpha and MIPS can be either: Digital/Compaq
3489 used/uses them in little-endian mode; SGI/Cray uses them in big-endian
3490 mode.
3491
3492 The names `big-endian' and `little-endian' are comic references to
3493 the classic "Gulliver's Travels" (via the paper "On Holy Wars and a
3494 Plea for Peace" by Danny Cohen, USC/ISI IEN 137, April 1, 1980) and
3495 the egg-eating habits of the Lilliputians.
3496
3497 Some systems may have even weirder byte orders such as
3498
3499         0x56 0x78 0x12 0x34
3500         0x34 0x12 0x78 0x56
3501
3502 You can see your system's preference with
3503
3504         print join(" ", map { sprintf "%#02x", $_ }
3505                             unpack("C*",pack("L",0x12345678))), "\n";
3506
3507 The byteorder on the platform where Perl was built is also available
3508 via L<Config>:
3509
3510         use Config;
3511         print $Config{byteorder}, "\n";
3512
3513 Byteorders C<'1234'> and C<'12345678'> are little-endian, C<'4321'>
3514 and C<'87654321'> are big-endian.
3515
3516 If you want portable packed integers use the formats C<n>, C<N>,
3517 C<v>, and C<V>, their byte endianness and size are known.
3518 See also L<perlport>.
3519
3520 =item *
3521
3522 Real numbers (floats and doubles) are in the native machine format only;
3523 due to the multiplicity of floating formats around, and the lack of a
3524 standard "network" representation, no facility for interchange has been
3525 made.  This means that packed floating point data written on one machine
3526 may not be readable on another - even if both use IEEE floating point
3527 arithmetic (as the endian-ness of the memory representation is not part
3528 of the IEEE spec).  See also L<perlport>.
3529
3530 Note that Perl uses doubles internally for all numeric calculation, and
3531 converting from double into float and thence back to double again will
3532 lose precision (i.e., C<unpack("f", pack("f", $foo)>) will not in general
3533 equal $foo).
3534
3535 =item *
3536
3537 If the pattern begins with a C<U>, the resulting string will be
3538 treated as UTF-8-encoded Unicode. You can force UTF-8 encoding on in a
3539 string with an initial C<U0>, and the bytes that follow will be
3540 interpreted as Unicode characters. If you don't want this to happen,
3541 you can begin your pattern with C<C0> (or anything else) to force Perl
3542 not to UTF-8 encode your string, and then follow this with a C<U*>
3543 somewhere in your pattern.
3544
3545 =item *
3546
3547 You must yourself do any alignment or padding by inserting for example
3548 enough C<'x'>es while packing.  There is no way to pack() and unpack()
3549 could know where the bytes are going to or coming from.  Therefore
3550 C<pack> (and C<unpack>) handle their output and input as flat
3551 sequences of bytes.
3552
3553 =item *
3554
3555 A ()-group is a sub-TEMPLATE enclosed in parentheses.  A group may
3556 take a repeat count, both as postfix, and for unpack() also via the C</>
3557 template character. Within each repetition of a group, positioning with
3558 C<@> starts again at 0. Therefore, the result of
3559
3560     pack( '@1A((@2A)@3A)', 'a', 'b', 'c' )
3561
3562 is the string "\0a\0\0bc".
3563
3564
3565 =item *
3566
3567 C<x> and C<X> accept C<!> modifier.  In this case they act as
3568 alignment commands: they jump forward/back to the closest position
3569 aligned at a multiple of C<count> bytes.  For example, to pack() or
3570 unpack() C's C<struct {char c; double d; char cc[2]}> one may need to
3571 use the template C<C x![d] d C[2]>; this assumes that doubles must be
3572 aligned on the double's size.
3573
3574 For alignment commands C<count> of 0 is equivalent to C<count> of 1;
3575 both result in no-ops.
3576
3577 =item *
3578
3579 A comment in a TEMPLATE starts with C<#> and goes to the end of line.
3580 White space may be used to separate pack codes from each other, but
3581 a C<!> modifier and a repeat count must follow immediately.
3582
3583 =item *
3584
3585 If TEMPLATE requires more arguments to pack() than actually given, pack()
3586 assumes additional C<""> arguments.  If TEMPLATE requires less arguments
3587 to pack() than actually given, extra arguments are ignored.
3588
3589 =back
3590
3591 Examples:
3592
3593     $foo = pack("CCCC",65,66,67,68);
3594     # foo eq "ABCD"
3595     $foo = pack("C4",65,66,67,68);
3596     # same thing
3597     $foo = pack("U4",0x24b6,0x24b7,0x24b8,0x24b9);
3598     # same thing with Unicode circled letters
3599
3600     $foo = pack("ccxxcc",65,66,67,68);
3601     # foo eq "AB\0\0CD"
3602
3603     # note: the above examples featuring "C" and "c" are true
3604     # only on ASCII and ASCII-derived systems such as ISO Latin 1
3605     # and UTF-8.  In EBCDIC the first example would be
3606     # $foo = pack("CCCC",193,194,195,196);
3607
3608     $foo = pack("s2",1,2);
3609     # "\1\0\2\0" on little-endian
3610     # "\0\1\0\2" on big-endian
3611
3612     $foo = pack("a4","abcd","x","y","z");
3613     # "abcd"
3614
3615     $foo = pack("aaaa","abcd","x","y","z");
3616     # "axyz"
3617
3618     $foo = pack("a14","abcdefg");
3619     # "abcdefg\0\0\0\0\0\0\0"
3620
3621     $foo = pack("i9pl", gmtime);
3622     # a real struct tm (on my system anyway)
3623
3624     $utmp_template = "Z8 Z8 Z16 L";
3625     $utmp = pack($utmp_template, @utmp1);
3626     # a struct utmp (BSDish)
3627
3628     @utmp2 = unpack($utmp_template, $utmp);
3629     # "@utmp1" eq "@utmp2"
3630
3631     sub bintodec {
3632         unpack("N", pack("B32", substr("0" x 32 . shift, -32)));
3633     }
3634
3635     $foo = pack('sx2l', 12, 34);
3636     # short 12, two zero bytes padding, long 34
3637     $bar = pack('s@4l', 12, 34);
3638     # short 12, zero fill to position 4, long 34
3639     # $foo eq $bar
3640
3641 The same template may generally also be used in unpack().
3642
3643 =item package NAMESPACE
3644
3645 =item package
3646
3647 Declares the compilation unit as being in the given namespace.  The scope
3648 of the package declaration is from the declaration itself through the end
3649 of the enclosing block, file, or eval (the same as the C<my> operator).
3650 All further unqualified dynamic identifiers will be in this namespace.
3651 A package statement affects only dynamic variables--including those
3652 you've used C<local> on--but I<not> lexical variables, which are created
3653 with C<my>.  Typically it would be the first declaration in a file to
3654 be included by the C<require> or C<use> operator.  You can switch into a
3655 package in more than one place; it merely influences which symbol table
3656 is used by the compiler for the rest of that block.  You can refer to
3657 variables and filehandles in other packages by prefixing the identifier
3658 with the package name and a double colon:  C<$Package::Variable>.
3659 If the package name is null, the C<main> package as assumed.  That is,
3660 C<$::sail> is equivalent to C<$main::sail> (as well as to C<$main'sail>,
3661 still seen in older code).
3662
3663 If NAMESPACE is omitted, then there is no current package, and all
3664 identifiers must be fully qualified or lexicals.  However, you are
3665 strongly advised not to make use of this feature. Its use can cause
3666 unexpected behaviour, even crashing some versions of Perl. It is
3667 deprecated, and will be removed from a future release.
3668
3669 See L<perlmod/"Packages"> for more information about packages, modules,
3670 and classes.  See L<perlsub> for other scoping issues.
3671
3672 =item pipe READHANDLE,WRITEHANDLE
3673
3674 Opens a pair of connected pipes like the corresponding system call.
3675 Note that if you set up a loop of piped processes, deadlock can occur
3676 unless you are very careful.  In addition, note that Perl's pipes use
3677 IO buffering, so you may need to set C<$|> to flush your WRITEHANDLE
3678 after each command, depending on the application.
3679
3680 See L<IPC::Open2>, L<IPC::Open3>, and L<perlipc/"Bidirectional Communication">
3681 for examples of such things.
3682
3683 On systems that support a close-on-exec flag on files, the flag will be set
3684 for the newly opened file descriptors as determined by the value of $^F.
3685 See L<perlvar/$^F>.
3686
3687 =item pop ARRAY
3688
3689 =item pop
3690
3691 Pops and returns the last value of the array, shortening the array by
3692 one element.  Has an effect similar to
3693
3694     $ARRAY[$#ARRAY--]
3695
3696 If there are no elements in the array, returns the undefined value
3697 (although this may happen at other times as well).  If ARRAY is
3698 omitted, pops the C<@ARGV> array in the main program, and the C<@_>
3699 array in subroutines, just like C<shift>.
3700
3701 =item pos SCALAR
3702
3703 =item pos
3704
3705 Returns the offset of where the last C<m//g> search left off for the variable
3706 in question (C<$_> is used when the variable is not specified).  May be
3707 modified to change that offset.  Such modification will also influence
3708 the C<\G> zero-width assertion in regular expressions.  See L<perlre> and
3709 L<perlop>.
3710
3711 =item print FILEHANDLE LIST
3712
3713 =item print LIST
3714
3715 =item print
3716
3717 Prints a string or a list of strings.  Returns true if successful.
3718 FILEHANDLE may be a scalar variable name, in which case the variable
3719 contains the name of or a reference to the filehandle, thus introducing
3720 one level of indirection.  (NOTE: If FILEHANDLE is a variable and
3721 the next token is a term, it may be misinterpreted as an operator
3722 unless you interpose a C<+> or put parentheses around the arguments.)
3723 If FILEHANDLE is omitted, prints by default to standard output (or
3724 to the last selected output channel--see L</select>).  If LIST is
3725 also omitted, prints C<$_> to the currently selected output channel.
3726 To set the default output channel to something other than STDOUT
3727 use the select operation.  The current value of C<$,> (if any) is
3728 printed between each LIST item.  The current value of C<$\> (if
3729 any) is printed after the entire LIST has been printed.  Because
3730 print takes a LIST, anything in the LIST is evaluated in list
3731 context, and any subroutine that you call will have one or more of
3732 its expressions evaluated in list context.  Also be careful not to
3733 follow the print keyword with a left parenthesis unless you want
3734 the corresponding right parenthesis to terminate the arguments to
3735 the print--interpose a C<+> or put parentheses around all the
3736 arguments.
3737
3738 Note that if you're storing FILEHANDLES in an array or other expression,
3739 you will have to use a block returning its value instead:
3740
3741     print { $files[$i] } "stuff\n";
3742     print { $OK ? STDOUT : STDERR } "stuff\n";
3743
3744 =item printf FILEHANDLE FORMAT, LIST
3745
3746 =item printf FORMAT, LIST
3747
3748 Equivalent to C<print FILEHANDLE sprintf(FORMAT, LIST)>, except that C<$\>
3749 (the output record separator) is not appended.  The first argument
3750 of the list will be interpreted as the C<printf> format. See C<sprintf>
3751 for an explanation of the format argument. If C<use locale> is in effect,
3752 the character used for the decimal point in formatted real numbers is
3753 affected by the LC_NUMERIC locale.  See L<perllocale>.
3754
3755 Don't fall into the trap of using a C<printf> when a simple
3756 C<print> would do.  The C<print> is more efficient and less
3757 error prone.
3758
3759 =item prototype FUNCTION
3760
3761 Returns the prototype of a function as a string (or C<undef> if the
3762 function has no prototype).  FUNCTION is a reference to, or the name of,
3763 the function whose prototype you want to retrieve.
3764
3765 If FUNCTION is a string starting with C<CORE::>, the rest is taken as a
3766 name for Perl builtin.  If the builtin is not I<overridable> (such as
3767 C<qw//>) or its arguments cannot be expressed by a prototype (such as
3768 C<system>) returns C<undef> because the builtin does not really behave
3769 like a Perl function.  Otherwise, the string describing the equivalent
3770 prototype is returned.
3771
3772 =item push ARRAY,LIST
3773
3774 Treats ARRAY as a stack, and pushes the values of LIST
3775 onto the end of ARRAY.  The length of ARRAY increases by the length of
3776 LIST.  Has the same effect as
3777
3778     for $value (LIST) {
3779         $ARRAY[++$#ARRAY] = $value;
3780     }
3781
3782 but is more efficient.  Returns the new number of elements in the array.
3783
3784 =item q/STRING/
3785
3786 =item qq/STRING/
3787
3788 =item qr/STRING/
3789
3790 =item qx/STRING/
3791
3792 =item qw/STRING/
3793
3794 Generalized quotes.  See L<perlop/"Regexp Quote-Like Operators">.
3795
3796 =item quotemeta EXPR
3797
3798 =item quotemeta
3799
3800 Returns the value of EXPR with all non-"word"
3801 characters backslashed.  (That is, all characters not matching
3802 C</[A-Za-z_0-9]/> will be preceded by a backslash in the
3803 returned string, regardless of any locale settings.)
3804 This is the internal function implementing
3805 the C<\Q> escape in double-quoted strings.
3806
3807 If EXPR is omitted, uses C<$_>.
3808
3809 =item rand EXPR
3810
3811 =item rand
3812
3813 Returns a random fractional number greater than or equal to C<0> and less
3814 than the value of EXPR.  (EXPR should be positive.)  If EXPR is
3815 omitted, the value C<1> is used.  Currently EXPR with the value C<0> is
3816 also special-cased as C<1> - this has not been documented before perl 5.8.0
3817 and is subject to change in future versions of perl.  Automatically calls
3818 C<srand> unless C<srand> has already been called.  See also C<srand>.
3819
3820 Apply C<int()> to the value returned by C<rand()> if you want random
3821 integers instead of random fractional numbers.  For example,
3822
3823     int(rand(10))
3824
3825 returns a random integer between C<0> and C<9>, inclusive.
3826
3827 (Note: If your rand function consistently returns numbers that are too
3828 large or too small, then your version of Perl was probably compiled
3829 with the wrong number of RANDBITS.)
3830
3831 =item read FILEHANDLE,SCALAR,LENGTH,OFFSET
3832
3833 =item read FILEHANDLE,SCALAR,LENGTH
3834
3835 Attempts to read LENGTH I<characters> of data into variable SCALAR
3836 from the specified FILEHANDLE.  Returns the number of characters
3837 actually read, C<0> at end of file, or undef if there was an error (in
3838 the latter case C<$!> is also set).  SCALAR will be grown or shrunk 
3839 so that the last character actually read is the last character of the
3840 scalar after the read.
3841
3842 An OFFSET may be specified to place the read data at some place in the
3843 string other than the beginning.  A negative OFFSET specifies
3844 placement at that many characters counting backwards from the end of
3845 the string.  A positive OFFSET greater than the length of SCALAR
3846 results in the string being padded to the required size with C<"\0">
3847 bytes before the result of the read is appended.
3848
3849 The call is actually implemented in terms of either Perl's or system's
3850 fread() call.  To get a true read(2) system call, see C<sysread>.
3851
3852 Note the I<characters>: depending on the status of the filehandle,
3853 either (8-bit) bytes or characters are read.  By default all
3854 filehandles operate on bytes, but for example if the filehandle has
3855 been opened with the C<:utf8> I/O layer (see L</open>, and the C<open>
3856 pragma, L<open>), the I/O will operate on UTF-8 encoded Unicode
3857 characters, not bytes.  Similarly for the C<:encoding> pragma:
3858 in that case pretty much any characters can be read.
3859
3860 =item readdir DIRHANDLE
3861
3862 Returns the next directory entry for a directory opened by C<opendir>.
3863 If used in list context, returns all the rest of the entries in the
3864 directory.  If there are no more entries, returns an undefined value in
3865 scalar context or a null list in list context.
3866
3867 If you're planning to filetest the return values out of a C<readdir>, you'd
3868 better prepend the directory in question.  Otherwise, because we didn't
3869 C<chdir> there, it would have been testing the wrong file.
3870
3871     opendir(DIR, $some_dir) || die "can't opendir $some_dir: $!";
3872     @dots = grep { /^\./ && -f "$some_dir/$_" } readdir(DIR);
3873     closedir DIR;
3874
3875 =item readline EXPR
3876
3877 Reads from the filehandle whose typeglob is contained in EXPR.  In scalar
3878 context, each call reads and returns the next line, until end-of-file is
3879 reached, whereupon the subsequent call returns undef.  In list context,
3880 reads until end-of-file is reached and returns a list of lines.  Note that
3881 the notion of "line" used here is however you may have defined it
3882 with C<$/> or C<$INPUT_RECORD_SEPARATOR>).  See L<perlvar/"$/">.
3883
3884 When C<$/> is set to C<undef>, when readline() is in scalar
3885 context (i.e. file slurp mode), and when an empty file is read, it
3886 returns C<''> the first time, followed by C<undef> subsequently.
3887
3888 This is the internal function implementing the C<< <EXPR> >>
3889 operator, but you can use it directly.  The C<< <EXPR> >>
3890 operator is discussed in more detail in L<perlop/"I/O Operators">.
3891
3892     $line = <STDIN>;
3893     $line = readline(*STDIN);           # same thing
3894
3895 If readline encounters an operating system error, C<$!> will be set with the
3896 corresponding error message.  It can be helpful to check C<$!> when you are
3897 reading from filehandles you don't trust, such as a tty or a socket.  The
3898 following example uses the operator form of C<readline>, and takes the necessary
3899 steps to ensure that C<readline> was successful.
3900
3901     for (;;) {
3902         undef $!;
3903         unless (defined( $line = <> )) {
3904             die $! if $!;
3905             last; # reached EOF
3906         }
3907         # ...
3908     }
3909
3910 =item readlink EXPR
3911
3912 =item readlink
3913
3914 Returns the value of a symbolic link, if symbolic links are
3915 implemented.  If not, gives a fatal error.  If there is some system
3916 error, returns the undefined value and sets C<$!> (errno).  If EXPR is
3917 omitted, uses C<$_>.
3918
3919 =item readpipe EXPR
3920
3921 EXPR is executed as a system command.
3922 The collected standard output of the command is returned.
3923 In scalar context, it comes back as a single (potentially
3924 multi-line) string.  In list context, returns a list of lines
3925 (however you've defined lines with C<$/> or C<$INPUT_RECORD_SEPARATOR>).
3926 This is the internal function implementing the C<qx/EXPR/>
3927 operator, but you can use it directly.  The C<qx/EXPR/>
3928 operator is discussed in more detail in L<perlop/"I/O Operators">.
3929
3930 =item recv SOCKET,SCALAR,LENGTH,FLAGS
3931
3932 Receives a message on a socket.  Attempts to receive LENGTH characters
3933 of data into variable SCALAR from the specified SOCKET filehandle.
3934 SCALAR will be grown or shrunk to the length actually read.  Takes the
3935 same flags as the system call of the same name.  Returns the address
3936 of the sender if SOCKET's protocol supports this; returns an empty
3937 string otherwise.  If there's an error, returns the undefined value.
3938 This call is actually implemented in terms of recvfrom(2) system call.
3939 See L<perlipc/"UDP: Message Passing"> for examples.
3940
3941 Note the I<characters>: depending on the status of the socket, either
3942 (8-bit) bytes or characters are received.  By default all sockets
3943 operate on bytes, but for example if the socket has been changed using
3944 binmode() to operate with the C<:utf8> I/O layer (see the C<open>
3945 pragma, L<open>), the I/O will operate on UTF-8 encoded Unicode
3946 characters, not bytes.  Similarly for the C<:encoding> pragma:
3947 in that case pretty much any characters can be read.
3948
3949 =item redo LABEL
3950
3951 =item redo
3952
3953 The C<redo> command restarts the loop block without evaluating the
3954 conditional again.  The C<continue> block, if any, is not executed.  If
3955 the LABEL is omitted, the command refers to the innermost enclosing
3956 loop.  This command is normally used by programs that want to lie to
3957 themselves about what was just input:
3958
3959     # a simpleminded Pascal comment stripper
3960     # (warning: assumes no { or } in strings)
3961     LINE: while (<STDIN>) {
3962         while (s|({.*}.*){.*}|$1 |) {}
3963         s|{.*}| |;
3964         if (s|{.*| |) {
3965             $front = $_;
3966             while (<STDIN>) {
3967                 if (/}/) {      # end of comment?
3968                     s|^|$front\{|;
3969                     redo LINE;
3970                 }
3971             }
3972         }
3973         print;
3974     }
3975
3976 C<redo> cannot be used to retry a block which returns a value such as
3977 C<eval {}>, C<sub {}> or C<do {}>, and should not be used to exit
3978 a grep() or map() operation.
3979
3980 Note that a block by itself is semantically identical to a loop
3981 that executes once.  Thus C<redo> inside such a block will effectively
3982 turn it into a looping construct.
3983
3984 See also L</continue> for an illustration of how C<last>, C<next>, and
3985 C<redo> work.
3986
3987 =item ref EXPR
3988
3989 =item ref
3990
3991 Returns a non-empty string if EXPR is a reference, the empty
3992 string otherwise. If EXPR
3993 is not specified, C<$_> will be used.  The value returned depends on the
3994 type of thing the reference is a reference to.
3995 Builtin types include:
3996
3997     SCALAR
3998     ARRAY
3999     HASH
4000     CODE
4001     REF
4002     GLOB
4003     LVALUE
4004
4005 If the referenced object has been blessed into a package, then that package
4006 name is returned instead.  You can think of C<ref> as a C<typeof> operator.
4007
4008     if (ref($r) eq "HASH") {
4009         print "r is a reference to a hash.\n";
4010     }
4011     unless (ref($r)) {
4012         print "r is not a reference at all.\n";
4013     }
4014     if (UNIVERSAL::isa($r, "HASH")) {  # for subclassing
4015         print "r is a reference to something that isa hash.\n";
4016     }
4017
4018 See also L<perlref>.
4019
4020 =item rename OLDNAME,NEWNAME
4021
4022 Changes the name of a file; an existing file NEWNAME will be
4023 clobbered.  Returns true for success, false otherwise.
4024
4025 Behavior of this function varies wildly depending on your system
4026 implementation.  For example, it will usually not work across file system
4027 boundaries, even though the system I<mv> command sometimes compensates
4028 for this.  Other restrictions include whether it works on directories,
4029 open files, or pre-existing files.  Check L<perlport> and either the
4030 rename(2) manpage or equivalent system documentation for details.
4031
4032 =item require VERSION
4033
4034 =item require EXPR
4035
4036 =item require
4037
4038 Demands a version of Perl specified by VERSION, or demands some semantics
4039 specified by EXPR or by C<$_> if EXPR is not supplied.
4040
4041 VERSION may be either a numeric argument such as 5.006, which will be
4042 compared to C<$]>, or a literal of the form v5.6.1, which will be compared
4043 to C<$^V> (aka $PERL_VERSION).  A fatal error is produced at run time if
4044 VERSION is greater than the version of the current Perl interpreter.
4045 Compare with L</use>, which can do a similar check at compile time.
4046
4047 Specifying VERSION as a literal of the form v5.6.1 should generally be
4048 avoided, because it leads to misleading error messages under earlier
4049 versions of Perl which do not support this syntax.  The equivalent numeric
4050 version should be used instead.
4051
4052     require v5.6.1;     # run time version check
4053     require 5.6.1;      # ditto
4054     require 5.006_001;  # ditto; preferred for backwards compatibility
4055
4056 Otherwise, demands that a library file be included if it hasn't already
4057 been included.  The file is included via the do-FILE mechanism, which is
4058 essentially just a variety of C<eval>.  Has semantics similar to the
4059 following subroutine:
4060
4061     sub require {
4062        my ($filename) = @_;
4063        if (exists $INC{$filename}) {
4064            return 1 if $INC{$filename};
4065            die "Compilation failed in require";
4066        }
4067        my ($realfilename,$result);
4068        ITER: {
4069            foreach $prefix (@INC) {
4070                $realfilename = "$prefix/$filename";
4071                if (-f $realfilename) {
4072                    $INC{$filename} = $realfilename;
4073                    $result = do $realfilename;
4074                    last ITER;
4075                }
4076            }
4077            die "Can't find $filename in \@INC";
4078        }
4079        if ($@) {
4080            $INC{$filename} = undef;
4081            die $@;
4082        } elsif (!$result) {
4083            delete $INC{$filename};
4084            die "$filename did not return true value";
4085        } else {
4086            return $result;
4087        }
4088     }
4089
4090 Note that the file will not be included twice under the same specified
4091 name.
4092
4093 The file must return true as the last statement to indicate
4094 successful execution of any initialization code, so it's customary to
4095 end such a file with C<1;> unless you're sure it'll return true
4096 otherwise.  But it's better just to put the C<1;>, in case you add more
4097 statements.
4098
4099 If EXPR is a bareword, the require assumes a "F<.pm>" extension and
4100 replaces "F<::>" with "F</>" in the filename for you,
4101 to make it easy to load standard modules.  This form of loading of
4102 modules does not risk altering your namespace.
4103
4104 In other words, if you try this:
4105
4106         require Foo::Bar;    # a splendid bareword
4107
4108 The require function will actually look for the "F<Foo/Bar.pm>" file in the
4109 directories specified in the C<@INC> array.
4110
4111 But if you try this:
4112
4113         $class = 'Foo::Bar';
4114         require $class;      # $class is not a bareword
4115     #or
4116         require "Foo::Bar";  # not a bareword because of the ""
4117
4118 The require function will look for the "F<Foo::Bar>" file in the @INC array and
4119 will complain about not finding "F<Foo::Bar>" there.  In this case you can do:
4120
4121         eval "require $class";
4122
4123 Now that you understand how C<require> looks for files in the case of
4124 a bareword argument, there is a little extra functionality going on
4125 behind the scenes.  Before C<require> looks for a "F<.pm>" extension,
4126 it will first look for a filename with a "F<.pmc>" extension.  A file
4127 with this extension is assumed to be Perl bytecode generated by
4128 L<B::Bytecode|B::Bytecode>.  If this file is found, and it's modification
4129 time is newer than a coinciding "F<.pm>" non-compiled file, it will be
4130 loaded in place of that non-compiled file ending in a "F<.pm>" extension.
4131
4132 You can also insert hooks into the import facility, by putting directly
4133 Perl code into the @INC array.  There are three forms of hooks: subroutine
4134 references, array references and blessed objects.
4135
4136 Subroutine references are the simplest case.  When the inclusion system
4137 walks through @INC and encounters a subroutine, this subroutine gets
4138 called with two parameters, the first being a reference to itself, and the
4139 second the name of the file to be included (e.g. "F<Foo/Bar.pm>").  The
4140 subroutine should return C<undef> or a filehandle, from which the file to
4141 include will be read.  If C<undef> is returned, C<require> will look at
4142 the remaining elements of @INC.
4143
4144 If the hook is an array reference, its first element must be a subroutine
4145 reference.  This subroutine is called as above, but the first parameter is
4146 the array reference.  This enables to pass indirectly some arguments to
4147 the subroutine.
4148
4149 In other words, you can write:
4150
4151     push @INC, \&my_sub;
4152     sub my_sub {
4153         my ($coderef, $filename) = @_;  # $coderef is \&my_sub
4154         ...
4155     }
4156
4157 or:
4158
4159     push @INC, [ \&my_sub, $x, $y, ... ];
4160     sub my_sub {
4161         my ($arrayref, $filename) = @_;
4162         # Retrieve $x, $y, ...
4163         my @parameters = @$arrayref[1..$#$arrayref];
4164         ...
4165     }
4166
4167 If the hook is an object, it must provide an INC method, that will be
4168 called as above, the first parameter being the object itself.  (Note that
4169 you must fully qualify the sub's name, as it is always forced into package
4170 C<main>.)  Here is a typical code layout:
4171
4172     # In Foo.pm
4173     package Foo;
4174     sub new { ... }
4175     sub Foo::INC {
4176         my ($self, $filename) = @_;
4177         ...
4178     }
4179
4180     # In the main program
4181     push @INC, new Foo(...);
4182
4183 Note that these hooks are also permitted to set the %INC entry
4184 corresponding to the files they have loaded. See L<perlvar/%INC>.
4185
4186 For a yet-more-powerful import facility, see L</use> and L<perlmod>.
4187
4188 =item reset EXPR
4189
4190 =item reset
4191
4192 Generally used in a C<continue> block at the end of a loop to clear
4193 variables and reset C<??> searches so that they work again.  The
4194 expression is interpreted as a list of single characters (hyphens
4195 allowed for ranges).  All variables and arrays beginning with one of
4196 those letters are reset to their pristine state.  If the expression is
4197 omitted, one-match searches (C<?pattern?>) are reset to match again.  Resets
4198 only variables or searches in the current package.  Always returns
4199 1.  Examples:
4200
4201     reset 'X';          # reset all X variables
4202     reset 'a-z';        # reset lower case variables
4203     reset;              # just reset ?one-time? searches
4204
4205 Resetting C<"A-Z"> is not recommended because you'll wipe out your
4206 C<@ARGV> and C<@INC> arrays and your C<%ENV> hash.  Resets only package
4207 variables--lexical variables are unaffected, but they clean themselves
4208 up on scope exit anyway, so you'll probably want to use them instead.
4209 See L</my>.
4210
4211 =item return EXPR
4212
4213 =item return
4214
4215 Returns from a subroutine, C<eval>, or C<do FILE> with the value
4216 given in EXPR.  Evaluation of EXPR may be in list, scalar, or void
4217 context, depending on how the return value will be used, and the context
4218 may vary from one execution to the next (see C<wantarray>).  If no EXPR
4219 is given, returns an empty list in list context, the undefined value in
4220 scalar context, and (of course) nothing at all in a void context.
4221
4222 (Note that in the absence of an explicit C<return>, a subroutine, eval,
4223 or do FILE will automatically return the value of the last expression
4224 evaluated.)
4225
4226 =item reverse LIST
4227
4228 In list context, returns a list value consisting of the elements
4229 of LIST in the opposite order.  In scalar context, concatenates the
4230 elements of LIST and returns a string value with all characters
4231 in the opposite order.
4232
4233     print reverse <>;           # line tac, last line first
4234
4235     undef $/;                   # for efficiency of <>
4236     print scalar reverse <>;    # character tac, last line tsrif
4237
4238 This operator is also handy for inverting a hash, although there are some
4239 caveats.  If a value is duplicated in the original hash, only one of those
4240 can be represented as a key in the inverted hash.  Also, this has to
4241 unwind one hash and build a whole new one, which may take some time
4242 on a large hash, such as from a DBM file.
4243
4244     %by_name = reverse %by_address;     # Invert the hash
4245
4246 =item rewinddir DIRHANDLE
4247
4248 Sets the current position to the beginning of the directory for the
4249 C<readdir> routine on DIRHANDLE.
4250
4251 =item rindex STR,SUBSTR,POSITION
4252
4253 =item rindex STR,SUBSTR
4254
4255 Works just like index() except that it returns the position of the LAST
4256 occurrence of SUBSTR in STR.  If POSITION is specified, returns the
4257 last occurrence at or before that position.
4258
4259 =item rmdir FILENAME
4260
4261 =item rmdir
4262
4263 Deletes the directory specified by FILENAME if that directory is
4264 empty.  If it succeeds it returns true, otherwise it returns false and
4265 sets C<$!> (errno).  If FILENAME is omitted, uses C<$_>.
4266
4267 =item s///
4268
4269 The substitution operator.  See L<perlop>.
4270
4271 =item scalar EXPR
4272
4273 Forces EXPR to be interpreted in scalar context and returns the value
4274 of EXPR.
4275
4276     @counts = ( scalar @a, scalar @b, scalar @c );
4277
4278 There is no equivalent operator to force an expression to
4279 be interpolated in list context because in practice, this is never
4280 needed.  If you really wanted to do so, however, you could use
4281 the construction C<@{[ (some expression) ]}>, but usually a simple
4282 C<(some expression)> suffices.
4283
4284 Because C<scalar> is unary operator, if you accidentally use for EXPR a
4285 parenthesized list, this behaves as a scalar comma expression, evaluating
4286 all but the last element in void context and returning the final element
4287 evaluated in scalar context.  This is seldom what you want.
4288
4289 The following single statement:
4290
4291         print uc(scalar(&foo,$bar)),$baz;
4292
4293 is the moral equivalent of these two:
4294
4295         &foo;
4296         print(uc($bar),$baz);
4297
4298 See L<perlop> for more details on unary operators and the comma operator.
4299
4300 =item seek FILEHANDLE,POSITION,WHENCE
4301
4302 Sets FILEHANDLE's position, just like the C<fseek> call of C<stdio>.
4303 FILEHANDLE may be an expression whose value gives the name of the
4304 filehandle.  The values for WHENCE are C<0> to set the new position
4305 I<in bytes> to POSITION, C<1> to set it to the current position plus
4306 POSITION, and C<2> to set it to EOF plus POSITION (typically
4307 negative).  For WHENCE you may use the constants C<SEEK_SET>,
4308 C<SEEK_CUR>, and C<SEEK_END> (start of the file, current position, end
4309 of the file) from the Fcntl module.  Returns C<1> upon success, C<0>
4310 otherwise.
4311
4312 Note the I<in bytes>: even if the filehandle has been set to
4313 operate on characters (for example by using the C<:utf8> open
4314 layer), tell() will return byte offsets, not character offsets
4315 (because implementing that would render seek() and tell() rather slow).
4316
4317 If you want to position file for C<sysread> or C<syswrite>, don't use
4318 C<seek>--buffering makes its effect on the file's system position
4319 unpredictable and non-portable.  Use C<sysseek> instead.
4320
4321 Due to the rules and rigors of ANSI C, on some systems you have to do a
4322 seek whenever you switch between reading and writing.  Amongst other
4323 things, this may have the effect of calling stdio's clearerr(3).
4324 A WHENCE of C<1> (C<SEEK_CUR>) is useful for not moving the file position:
4325
4326     seek(TEST,0,1);
4327
4328 This is also useful for applications emulating C<tail -f>.  Once you hit
4329 EOF on your read, and then sleep for a while, you might have to stick in a
4330 seek() to reset things.  The C<seek> doesn't change the current position,
4331 but it I<does> clear the end-of-file condition on the handle, so that the
4332 next C<< <FILE> >> makes Perl try again to read something.  We hope.
4333
4334 If that doesn't work (some IO implementations are particularly
4335 cantankerous), then you may need something more like this:
4336
4337     for (;;) {
4338         for ($curpos = tell(FILE); $_ = <FILE>;
4339              $curpos = tell(FILE)) {
4340             # search for some stuff and put it into files
4341         }
4342         sleep($for_a_while);
4343         seek(FILE, $curpos, 0);
4344     }
4345
4346 =item seekdir DIRHANDLE,POS
4347
4348 Sets the current position for the C<readdir> routine on DIRHANDLE.  POS
4349 must be a value returned by C<telldir>.  Has the same caveats about
4350 possible directory compaction as the corresponding system library
4351 routine.
4352
4353 =item select FILEHANDLE
4354
4355 =item select
4356
4357 Returns the currently selected filehandle.  Sets the current default
4358 filehandle for output, if FILEHANDLE is supplied.  This has two
4359 effects: first, a C<write> or a C<print> without a filehandle will
4360 default to this FILEHANDLE.  Second, references to variables related to
4361 output will refer to this output channel.  For example, if you have to
4362 set the top of form format for more than one output channel, you might
4363 do the following:
4364
4365     select(REPORT1);
4366     $^ = 'report1_top';
4367     select(REPORT2);
4368     $^ = 'report2_top';
4369
4370 FILEHANDLE may be an expression whose value gives the name of the
4371 actual filehandle.  Thus:
4372
4373     $oldfh = select(STDERR); $| = 1; select($oldfh);
4374
4375 Some programmers may prefer to think of filehandles as objects with
4376 methods, preferring to write the last example as:
4377
4378     use IO::Handle;
4379     STDERR->autoflush(1);
4380
4381 =item select RBITS,WBITS,EBITS,TIMEOUT
4382
4383 This calls the select(2) system call with the bit masks specified, which
4384 can be constructed using C<fileno> and C<vec>, along these lines:
4385
4386     $rin = $win = $ein = '';
4387     vec($rin,fileno(STDIN),1) = 1;
4388     vec($win,fileno(STDOUT),1) = 1;
4389     $ein = $rin | $win;
4390
4391 If you want to select on many filehandles you might wish to write a
4392 subroutine:
4393
4394     sub fhbits {
4395         my(@fhlist) = split(' ',$_[0]);
4396         my($bits);
4397         for (@fhlist) {
4398             vec($bits,fileno($_),1) = 1;
4399         }
4400         $bits;
4401     }
4402     $rin = fhbits('STDIN TTY SOCK');
4403
4404 The usual idiom is:
4405
4406     ($nfound,$timeleft) =
4407       select($rout=$rin, $wout=$win, $eout=$ein, $timeout);
4408
4409 or to block until something becomes ready just do this
4410
4411     $nfound = select($rout=$rin, $wout=$win, $eout=$ein, undef);
4412
4413 Most systems do not bother to return anything useful in $timeleft, so
4414 calling select() in scalar context just returns $nfound.
4415
4416 Any of the bit masks can also be undef.  The timeout, if specified, is
4417 in seconds, which may be fractional.  Note: not all implementations are
4418 capable of returning the $timeleft.  If not, they always return
4419 $timeleft equal to the supplied $timeout.
4420
4421 You can effect a sleep of 250 milliseconds this way:
4422
4423     select(undef, undef, undef, 0.25);
4424
4425 Note that whether C<select> gets restarted after signals (say, SIGALRM)
4426 is implementation-dependent.
4427
4428 B<WARNING>: One should not attempt to mix buffered I/O (like C<read>
4429 or <FH>) with C<select>, except as permitted by POSIX, and even
4430 then only on POSIX systems.  You have to use C<sysread> instead.
4431
4432 =item semctl ID,SEMNUM,CMD,ARG
4433
4434 Calls the System V IPC function C<semctl>.  You'll probably have to say
4435
4436     use IPC::SysV;
4437
4438 first to get the correct constant definitions.  If CMD is IPC_STAT or
4439 GETALL, then ARG must be a variable which will hold the returned
4440 semid_ds structure or semaphore value array.  Returns like C<ioctl>:
4441 the undefined value for error, "C<0 but true>" for zero, or the actual
4442 return value otherwise.  The ARG must consist of a vector of native
4443 short integers, which may be created with C<pack("s!",(0)x$nsem)>.
4444 See also L<perlipc/"SysV IPC">, C<IPC::SysV>, C<IPC::Semaphore>
4445 documentation.
4446
4447 =item semget KEY,NSEMS,FLAGS
4448
4449 Calls the System V IPC function semget.  Returns the semaphore id, or
4450 the undefined value if there is an error.  See also
4451 L<perlipc/"SysV IPC">, C<IPC::SysV>, C<IPC::SysV::Semaphore>
4452 documentation.
4453
4454 =item semop KEY,OPSTRING
4455
4456 Calls the System V IPC function semop to perform semaphore operations
4457 such as signalling and waiting.  OPSTRING must be a packed array of
4458 semop structures.  Each semop structure can be generated with
4459 C<pack("s!3", $semnum, $semop, $semflag)>.  The number of semaphore
4460 operations is implied by the length of OPSTRING.  Returns true if
4461 successful, or false if there is an error.  As an example, the
4462 following code waits on semaphore $semnum of semaphore id $semid:
4463
4464     $semop = pack("s!3", $semnum, -1, 0);
4465     die "Semaphore trouble: $!\n" unless semop($semid, $semop);
4466
4467 To signal the semaphore, replace C<-1> with C<1>.  See also
4468 L<perlipc/"SysV IPC">, C<IPC::SysV>, and C<IPC::SysV::Semaphore>
4469 documentation.
4470
4471 =item send SOCKET,MSG,FLAGS,TO
4472
4473 =item send SOCKET,MSG,FLAGS
4474
4475 Sends a message on a socket.  Attempts to send the scalar MSG to the
4476 SOCKET filehandle.  Takes the same flags as the system call of the
4477 same name.  On unconnected sockets you must specify a destination to
4478 send TO, in which case it does a C C<sendto>.  Returns the number of
4479 characters sent, or the undefined value if there is an error.  The C
4480 system call sendmsg(2) is currently unimplemented.  See
4481 L<perlipc/"UDP: Message Passing"> for examples.
4482
4483 Note the I<characters>: depending on the status of the socket, either
4484 (8-bit) bytes or characters are sent.  By default all sockets operate
4485 on bytes, but for example if the socket has been changed using
4486 binmode() to operate with the C<:utf8> I/O layer (see L</open>, or the
4487 C<open> pragma, L<open>), the I/O will operate on UTF-8 encoded
4488 Unicode characters, not bytes.  Similarly for the C<:encoding> pragma:
4489 in that case pretty much any characters can be sent.
4490
4491 =item setpgrp PID,PGRP
4492
4493 Sets the current process group for the specified PID, C<0> for the current
4494 process.  Will produce a fatal error if used on a machine that doesn't
4495 implement POSIX setpgid(2) or BSD setpgrp(2).  If the arguments are omitted,
4496 it defaults to C<0,0>.  Note that the BSD 4.2 version of C<setpgrp> does not
4497 accept any arguments, so only C<setpgrp(0,0)> is portable.  See also
4498 C<POSIX::setsid()>.
4499
4500 =item setpriority WHICH,WHO,PRIORITY
4501
4502 Sets the current priority for a process, a process group, or a user.
4503 (See setpriority(2).)  Will produce a fatal error if used on a machine
4504 that doesn't implement setpriority(2).
4505
4506 =item setsockopt SOCKET,LEVEL,OPTNAME,OPTVAL
4507
4508 Sets the socket option requested.  Returns undefined if there is an
4509 error.  OPTVAL may be specified as C<undef> if you don't want to pass an
4510 argument.
4511
4512 =item shift ARRAY
4513
4514 =item shift
4515
4516 Shifts the first value of the array off and returns it, shortening the
4517 array by 1 and moving everything down.  If there are no elements in the
4518 array, returns the undefined value.  If ARRAY is omitted, shifts the
4519 C<@_> array within the lexical scope of subroutines and formats, and the
4520 C<@ARGV> array at file scopes or within the lexical scopes established by
4521 the C<eval ''>, C<BEGIN {}>, C<INIT {}>, C<CHECK {}>, and C<END {}>
4522 constructs.
4523
4524 See also C<unshift>, C<push>, and C<pop>.  C<shift> and C<unshift> do the
4525 same thing to the left end of an array that C<pop> and C<push> do to the
4526 right end.
4527
4528 =item shmctl ID,CMD,ARG
4529
4530 Calls the System V IPC function shmctl.  You'll probably have to say
4531
4532     use IPC::SysV;
4533
4534 first to get the correct constant definitions.  If CMD is C<IPC_STAT>,
4535 then ARG must be a variable which will hold the returned C<shmid_ds>
4536 structure.  Returns like ioctl: the undefined value for error, "C<0> but
4537 true" for zero, or the actual return value otherwise.
4538 See also L<perlipc/"SysV IPC"> and C<IPC::SysV> documentation.
4539
4540 =item shmget KEY,SIZE,FLAGS
4541
4542 Calls the System V IPC function shmget.  Returns the shared memory
4543 segment id, or the undefined value if there is an error.
4544 See also L<perlipc/"SysV IPC"> and C<IPC::SysV> documentation.
4545
4546 =item shmread ID,VAR,POS,SIZE
4547
4548 =item shmwrite ID,STRING,POS,SIZE
4549
4550 Reads or writes the System V shared memory segment ID starting at
4551 position POS for size SIZE by attaching to it, copying in/out, and
4552 detaching from it.  When reading, VAR must be a variable that will
4553 hold the data read.  When writing, if STRING is too long, only SIZE
4554 bytes are used; if STRING is too short, nulls are written to fill out
4555 SIZE bytes.  Return true if successful, or false if there is an error.
4556 shmread() taints the variable. See also L<perlipc/"SysV IPC">,
4557 C<IPC::SysV> documentation, and the C<IPC::Shareable> module from CPAN.
4558
4559 =item shutdown SOCKET,HOW
4560
4561 Shuts down a socket connection in the manner indicated by HOW, which
4562 has the same interpretation as in the system call of the same name.
4563
4564     shutdown(SOCKET, 0);    # I/we have stopped reading data
4565     shutdown(SOCKET, 1);    # I/we have stopped writing data
4566     shutdown(SOCKET, 2);    # I/we have stopped using this socket
4567
4568 This is useful with sockets when you want to tell the other
4569 side you're done writing but not done reading, or vice versa.
4570 It's also a more insistent form of close because it also
4571 disables the file descriptor in any forked copies in other
4572 processes.
4573
4574 =item sin EXPR
4575
4576 =item sin
4577
4578 Returns the sine of EXPR (expressed in radians).  If EXPR is omitted,
4579 returns sine of C<$_>.
4580
4581 For the inverse sine operation, you may use the C<Math::Trig::asin>
4582 function, or use this relation:
4583
4584     sub asin { atan2($_[0], sqrt(1 - $_[0] * $_[0])) }
4585
4586 =item sleep EXPR
4587
4588 =item sleep
4589
4590 Causes the script to sleep for EXPR seconds, or forever if no EXPR.
4591 May be interrupted if the process receives a signal such as C<SIGALRM>.
4592 Returns the number of seconds actually slept.  You probably cannot
4593 mix C<alarm> and C<sleep> calls, because C<sleep> is often implemented
4594 using C<alarm>.
4595
4596 On some older systems, it may sleep up to a full second less than what
4597 you requested, depending on how it counts seconds.  Most modern systems
4598 always sleep the full amount.  They may appear to sleep longer than that,
4599 however, because your process might not be scheduled right away in a
4600 busy multitasking system.
4601
4602 For delays of finer granularity than one second, you may use Perl's
4603 C<syscall> interface to access setitimer(2) if your system supports
4604 it, or else see L</select> above.  The Time::HiRes module (from CPAN,
4605 and starting from Perl 5.8 part of the standard distribution) may also
4606 help.
4607
4608 See also the POSIX module's C<pause> function.
4609
4610 =item socket SOCKET,DOMAIN,TYPE,PROTOCOL
4611
4612 Opens a socket of the specified kind and attaches it to filehandle
4613 SOCKET.  DOMAIN, TYPE, and PROTOCOL are specified the same as for
4614 the system call of the same name.  You should C<use Socket> first
4615 to get the proper definitions imported.  See the examples in
4616 L<perlipc/"Sockets: Client/Server Communication">.
4617
4618 On systems that support a close-on-exec flag on files, the flag will
4619 be set for the newly opened file descriptor, as determined by the
4620 value of $^F.  See L<perlvar/$^F>.
4621
4622 =item socketpair SOCKET1,SOCKET2,DOMAIN,TYPE,PROTOCOL
4623
4624 Creates an unnamed pair of sockets in the specified domain, of the
4625 specified type.  DOMAIN, TYPE, and PROTOCOL are specified the same as
4626 for the system call of the same name.  If unimplemented, yields a fatal
4627 error.  Returns true if successful.
4628
4629 On systems that support a close-on-exec flag on files, the flag will
4630 be set for the newly opened file descriptors, as determined by the value
4631 of $^F.  See L<perlvar/$^F>.
4632
4633 Some systems defined C<pipe> in terms of C<socketpair>, in which a call
4634 to C<pipe(Rdr, Wtr)> is essentially:
4635
4636     use Socket;
4637     socketpair(Rdr, Wtr, AF_UNIX, SOCK_STREAM, PF_UNSPEC);
4638     shutdown(Rdr, 1);        # no more writing for reader
4639     shutdown(Wtr, 0);        # no more reading for writer
4640
4641 See L<perlipc> for an example of socketpair use.  Perl 5.8 and later will
4642 emulate socketpair using IP sockets to localhost if your system implements
4643 sockets but not socketpair.
4644
4645 =item sort SUBNAME LIST
4646
4647 =item sort BLOCK LIST
4648
4649 =item sort LIST
4650
4651 In list context, this sorts the LIST and returns the sorted list value.
4652 In scalar context, the behaviour of C<sort()> is undefined.
4653
4654 If SUBNAME or BLOCK is omitted, C<sort>s in standard string comparison
4655 order.  If SUBNAME is specified, it gives the name of a subroutine
4656 that returns an integer less than, equal to, or greater than C<0>,
4657 depending on how the elements of the list are to be ordered.  (The C<<
4658 <=> >> and C<cmp> operators are extremely useful in such routines.)
4659 SUBNAME may be a scalar variable name (unsubscripted), in which case
4660 the value provides the name of (or a reference to) the actual
4661 subroutine to use.  In place of a SUBNAME, you can provide a BLOCK as
4662 an anonymous, in-line sort subroutine.
4663
4664 If the subroutine's prototype is C<($$)>, the elements to be compared
4665 are passed by reference in C<@_>, as for a normal subroutine.  This is
4666 slower than unprototyped subroutines, where the elements to be
4667 compared are passed into the subroutine
4668 as the package global variables $a and $b (see example below).  Note that
4669 in the latter case, it is usually counter-productive to declare $a and
4670 $b as lexicals.
4671
4672 In either case, the subroutine may not be recursive.  The values to be
4673 compared are always passed by reference, so don't modify them.
4674
4675 You also cannot exit out of the sort block or subroutine using any of the
4676 loop control operators described in L<perlsyn> or with C<goto>.
4677
4678 When C<use locale> is in effect, C<sort LIST> sorts LIST according to the
4679 current collation locale.  See L<perllocale>.
4680
4681 Perl 5.6 and earlier used a quicksort algorithm to implement sort.
4682 That algorithm was not stable, and I<could> go quadratic.  (A I<stable> sort
4683 preserves the input order of elements that compare equal.  Although
4684 quicksort's run time is O(NlogN) when averaged over all arrays of
4685 length N, the time can be O(N**2), I<quadratic> behavior, for some
4686 inputs.)  In 5.7, the quicksort implementation was replaced with
4687 a stable mergesort algorithm whose worst case behavior is O(NlogN).
4688 But benchmarks indicated that for some inputs, on some platforms,
4689 the original quicksort was faster.  5.8 has a sort pragma for
4690 limited control of the sort.  Its rather blunt control of the
4691 underlying algorithm may not persist into future perls, but the
4692 ability to characterize the input or output in implementation
4693 independent ways quite probably will.  See L<sort>.
4694
4695 Examples:
4696
4697     # sort lexically
4698     @articles = sort @files;
4699
4700     # same thing, but with explicit sort routine
4701     @articles = sort {$a cmp $b} @files;
4702
4703     # now case-insensitively
4704     @articles = sort {uc($a) cmp uc($b)} @files;
4705
4706     # same thing in reversed order
4707     @articles = sort {$b cmp $a} @files;
4708
4709     # sort numerically ascending
4710     @articles = sort {$a <=> $b} @files;
4711
4712     # sort numerically descending
4713     @articles = sort {$b <=> $a} @files;
4714
4715     # this sorts the %age hash by value instead of key
4716     # using an in-line function
4717     @eldest = sort { $age{$b} <=> $age{$a} } keys %age;
4718
4719     # sort using explicit subroutine name
4720     sub byage {
4721         $age{$a} <=> $age{$b};  # presuming numeric
4722     }
4723     @sortedclass = sort byage @class;
4724
4725     sub backwards { $b cmp $a }
4726     @harry  = qw(dog cat x Cain Abel);
4727     @george = qw(gone chased yz Punished Axed);
4728     print sort @harry;
4729             # prints AbelCaincatdogx
4730     print sort backwards @harry;
4731             # prints xdogcatCainAbel
4732     print sort @george, 'to', @harry;
4733             # prints AbelAxedCainPunishedcatchaseddoggonetoxyz
4734
4735     # inefficiently sort by descending numeric compare using
4736     # the first integer after the first = sign, or the
4737     # whole record case-insensitively otherwise
4738
4739     @new = sort {
4740         ($b =~ /=(\d+)/)[0] <=> ($a =~ /=(\d+)/)[0]
4741                             ||
4742                     uc($a)  cmp  uc($b)
4743     } @old;
4744
4745     # same thing, but much more efficiently;
4746     # we'll build auxiliary indices instead
4747     # for speed
4748     @nums = @caps = ();
4749     for (@old) {
4750         push @nums, /=(\d+)/;
4751         push @caps, uc($_);
4752     }
4753
4754     @new = @old[ sort {
4755                         $nums[$b] <=> $nums[$a]
4756                                  ||
4757                         $caps[$a] cmp $caps[$b]
4758                        } 0..$#old
4759                ];
4760
4761     # same thing, but without any temps
4762     @new = map { $_->[0] }
4763            sort { $b->[1] <=> $a->[1]
4764                            ||
4765                   $a->[2] cmp $b->[2]
4766            } map { [$_, /=(\d+)/, uc($_)] } @old;
4767
4768     # using a prototype allows you to use any comparison subroutine
4769     # as a sort subroutine (including other package's subroutines)
4770     package other;
4771     sub backwards ($$) { $_[1] cmp $_[0]; }     # $a and $b are not set here
4772
4773     package main;
4774     @new = sort other::backwards @old;
4775
4776     # guarantee stability, regardless of algorithm
4777     use sort 'stable';
4778     @new = sort { substr($a, 3, 5) cmp substr($b, 3, 5) } @old;
4779
4780     # force use of mergesort (not portable outside Perl 5.8)
4781     use sort '_mergesort';  # note discouraging _
4782     @new = sort { substr($a, 3, 5) cmp substr($b, 3, 5) } @old;
4783
4784 If you're using strict, you I<must not> declare $a
4785 and $b as lexicals.  They are package globals.  That means
4786 if you're in the C<main> package and type
4787
4788     @articles = sort {$b <=> $a} @files;
4789
4790 then C<$a> and C<$b> are C<$main::a> and C<$main::b> (or C<$::a> and C<$::b>),
4791 but if you're in the C<FooPack> package, it's the same as typing
4792
4793     @articles = sort {$FooPack::b <=> $FooPack::a} @files;
4794
4795 The comparison function is required to behave.  If it returns
4796 inconsistent results (sometimes saying C<$x[1]> is less than C<$x[2]> and
4797 sometimes saying the opposite, for example) the results are not
4798 well-defined.
4799
4800 Because C<< <=> >> returns C<undef> when either operand is C<NaN>
4801 (not-a-number), and because C<sort> will trigger a fatal error unless the
4802 result of a comparison is defined, when sorting with a comparison function
4803 like C<< $a <=> $b >>, be careful about lists that might contain a C<NaN>.
4804 The following example takes advantage of the fact that C<NaN != NaN> to
4805 eliminate any C<NaN>s from the input.
4806
4807     @result = sort { $a <=> $b } grep { $_ == $_ } @input;
4808
4809 =item splice ARRAY,OFFSET,LENGTH,LIST
4810
4811 =item splice ARRAY,OFFSET,LENGTH
4812
4813 =item splice ARRAY,OFFSET
4814
4815 =item splice ARRAY
4816
4817 Removes the elements designated by OFFSET and LENGTH from an array, and
4818 replaces them with the elements of LIST, if any.  In list context,
4819 returns the elements removed from the array.  In scalar context,
4820 returns the last element removed, or C<undef> if no elements are
4821 removed.  The array grows or shrinks as necessary.
4822 If OFFSET is negative then it starts that far from the end of the array.
4823 If LENGTH is omitted, removes everything from OFFSET onward.
4824 If LENGTH is negative, removes the elements from OFFSET onward
4825 except for -LENGTH elements at the end of the array.
4826 If both OFFSET and LENGTH are omitted, removes everything. If OFFSET is
4827 past the end of the array, perl issues a warning, and splices at the
4828 end of the array.
4829
4830 The following equivalences hold (assuming C<< $[ == 0 and $#a >= $i >> )
4831
4832     push(@a,$x,$y)      splice(@a,@a,0,$x,$y)
4833     pop(@a)             splice(@a,-1)
4834     shift(@a)           splice(@a,0,1)
4835     unshift(@a,$x,$y)   splice(@a,0,0,$x,$y)
4836     $a[$i] = $y         splice(@a,$i,1,$y)
4837
4838 Example, assuming array lengths are passed before arrays:
4839
4840     sub aeq {   # compare two list values
4841         my(@a) = splice(@_,0,shift);
4842         my(@b) = splice(@_,0,shift);
4843         return 0 unless @a == @b;       # same len?
4844         while (@a) {
4845             return 0 if pop(@a) ne pop(@b);
4846         }
4847         return 1;
4848     }
4849     if (&aeq($len,@foo[1..$len],0+@bar,@bar)) { ... }
4850
4851 =item split /PATTERN/,EXPR,LIMIT
4852
4853 =item split /PATTERN/,EXPR
4854
4855 =item split /PATTERN/
4856
4857 =item split
4858
4859 Splits a string into a list of strings and returns that list.  By default,
4860 empty leading fields are preserved, and empty trailing ones are deleted.
4861
4862 In scalar context, returns the number of fields found and splits into
4863 the C<@_> array.  Use of split in scalar context is deprecated, however,
4864 because it clobbers your subroutine arguments.
4865
4866 If EXPR is omitted, splits the C<$_> string.  If PATTERN is also omitted,
4867 splits on whitespace (after skipping any leading whitespace).  Anything
4868 matching PATTERN is taken to be a delimiter separating the fields.  (Note
4869 that the delimiter may be longer than one character.)
4870
4871 If LIMIT is specified and positive, it represents the maximum number
4872 of fields the EXPR will be split into, though the actual number of
4873 fields returned depends on the number of times PATTERN matches within
4874 EXPR.  If LIMIT is unspecified or zero, trailing null fields are
4875 stripped (which potential users of C<pop> would do well to remember).
4876 If LIMIT is negative, it is treated as if an arbitrarily large LIMIT
4877 had been specified.  Note that splitting an EXPR that evaluates to the
4878 empty string always returns the empty list, regardless of the LIMIT
4879 specified.
4880
4881 A pattern matching the null string (not to be confused with
4882 a null pattern C<//>, which is just one member of the set of patterns
4883 matching a null string) will split the value of EXPR into separate
4884 characters at each point it matches that way.  For example:
4885
4886     print join(':', split(/ */, 'hi there'));
4887
4888 produces the output 'h:i:t:h:e:r:e'.
4889
4890 Using the empty pattern C<//> specifically matches the null string, and is
4891 not be confused with the use of C<//> to mean "the last successful pattern
4892 match".
4893
4894 Empty leading (or trailing) fields are produced when there are positive width
4895 matches at the beginning (or end) of the string; a zero-width match at the
4896 beginning (or end) of the string does not produce an empty field.  For
4897 example:
4898
4899    print join(':', split(/(?=\w)/, 'hi there!'));
4900
4901 produces the output 'h:i :t:h:e:r:e!'.
4902
4903 The LIMIT parameter can be used to split a line partially
4904
4905     ($login, $passwd, $remainder) = split(/:/, $_, 3);
4906
4907 When assigning to a list, if LIMIT is omitted, or zero, Perl supplies
4908 a LIMIT one larger than the number of variables in the list, to avoid
4909 unnecessary work.  For the list above LIMIT would have been 4 by
4910 default.  In time critical applications it behooves you not to split
4911 into more fields than you really need.
4912
4913 If the PATTERN contains parentheses, additional list elements are
4914 created from each matching substring in the delimiter.
4915
4916     split(/([,-])/, "1-10,20", 3);
4917
4918 produces the list value
4919
4920     (1, '-', 10, ',', 20)
4921
4922 If you had the entire header of a normal Unix email message in $header,
4923 you could split it up into fields and their values this way:
4924
4925     $header =~ s/\n\s+/ /g;  # fix continuation lines
4926     %hdrs   =  (UNIX_FROM => split /^(\S*?):\s*/m, $header);
4927
4928 The pattern C</PATTERN/> may be replaced with an expression to specify
4929 patterns that vary at runtime.  (To do runtime compilation only once,
4930 use C</$variable/o>.)
4931
4932 As a special case, specifying a PATTERN of space (S<C<' '>>) will split on
4933 white space just as C<split> with no arguments does.  Thus, S<C<split(' ')>> can
4934 be used to emulate B<awk>'s default behavior, whereas S<C<split(/ /)>>
4935 will give you as many null initial fields as there are leading spaces.
4936 A C<split> on C</\s+/> is like a S<C<split(' ')>> except that any leading
4937 whitespace produces a null first field.  A C<split> with no arguments
4938 really does a S<C<split(' ', $_)>> internally.
4939
4940 A PATTERN of C</^/> is treated as if it were C</^/m>, since it isn't
4941 much use otherwise.
4942
4943 Example:
4944
4945     open(PASSWD, '/etc/passwd');
4946     while (<PASSWD>) {
4947         chomp;
4948         ($login, $passwd, $uid, $gid,
4949          $gcos, $home, $shell) = split(/:/);
4950         #...
4951     }
4952
4953 As with regular pattern matching, any capturing parentheses that are not
4954 matched in a C<split()> will be set to C<undef> when returned:
4955
4956     @fields = split /(A)|B/, "1A2B3";
4957     # @fields is (1, 'A', 2, undef, 3)
4958
4959 =item sprintf FORMAT, LIST
4960
4961 Returns a string formatted by the usual C<printf> conventions of the C
4962 library function C<sprintf>.  See below for more details
4963 and see L<sprintf(3)> or L<printf(3)> on your system for an explanation of
4964 the general principles.
4965
4966 For example:
4967
4968         # Format number with up to 8 leading zeroes
4969         $result = sprintf("%08d", $number);
4970
4971         # Round number to 3 digits after decimal point
4972         $rounded = sprintf("%.3f", $number);
4973
4974 Perl does its own C<sprintf> formatting--it emulates the C
4975 function C<sprintf>, but it doesn't use it (except for floating-point
4976 numbers, and even then only the standard modifiers are allowed).  As a
4977 result, any non-standard extensions in your local C<sprintf> are not
4978 available from Perl.
4979
4980 Unlike C<printf>, C<sprintf> does not do what you probably mean when you
4981 pass it an array as your first argument. The array is given scalar context,
4982 and instead of using the 0th element of the array as the format, Perl will
4983 use the count of elements in the array as the format, which is almost never
4984 useful.
4985
4986 Perl's C<sprintf> permits the following universally-known conversions:
4987
4988    %%   a percent sign
4989    %c   a character with the given number
4990    %s   a string
4991    %d   a signed integer, in decimal
4992    %u   an unsigned integer, in decimal
4993    %o   an unsigned integer, in octal
4994    %x   an unsigned integer, in hexadecimal
4995    %e   a floating-point number, in scientific notation
4996    %f   a floating-point number, in fixed decimal notation
4997    %g   a floating-point number, in %e or %f notation
4998
4999 In addition, Perl permits the following widely-supported conversions:
5000
5001    %X   like %x, but using upper-case letters
5002    %E   like %e, but using an upper-case "E"
5003    %G   like %g, but with an upper-case "E" (if applicable)
5004    %b   an unsigned integer, in binary
5005    %p   a pointer (outputs the Perl value's address in hexadecimal)
5006    %n   special: *stores* the number of characters output so far
5007         into the next variable in the parameter list
5008
5009 Finally, for backward (and we do mean "backward") compatibility, Perl
5010 permits these unnecessary but widely-supported conversions:
5011
5012    %i   a synonym for %d
5013    %D   a synonym for %ld
5014    %U   a synonym for %lu
5015    %O   a synonym for %lo
5016    %F   a synonym for %f
5017
5018 Note that the number of exponent digits in the scientific notation produced
5019 by C<%e>, C<%E>, C<%g> and C<%G> for numbers with the modulus of the
5020 exponent less than 100 is system-dependent: it may be three or less
5021 (zero-padded as necessary).  In other words, 1.23 times ten to the
5022 99th may be either "1.23e99" or "1.23e099".
5023
5024 Between the C<%> and the format letter, you may specify a number of
5025 additional attributes controlling the interpretation of the format.
5026 In order, these are:
5027
5028 =over 4
5029
5030 =item format parameter index
5031
5032 An explicit format parameter index, such as C<2$>. By default sprintf
5033 will format the next unused argument in the list, but this allows you
5034 to take the arguments out of order. Eg:
5035
5036   printf '%2$d %1$d', 12, 34;      # prints "34 12"
5037   printf '%3$d %d %1$d', 1, 2, 3;  # prints "3 1 1"
5038
5039 =item flags
5040
5041 one or more of:
5042    space   prefix positive number with a space
5043    +       prefix positive number with a plus sign
5044    -       left-justify within the field
5045    0       use zeros, not spaces, to right-justify
5046    #       prefix non-zero octal with "0", non-zero hex with "0x",
5047            non-zero binary with "0b"
5048
5049 For example:
5050
5051   printf '<% d>', 12;   # prints "< 12>"
5052   printf '<%+d>', 12;   # prints "<+12>"
5053   printf '<%6s>', 12;   # prints "<    12>"
5054   printf '<%-6s>', 12;  # prints "<12    >"
5055   printf '<%06s>', 12;  # prints "<000012>"
5056   printf '<%#x>', 12;   # prints "<0xc>"
5057
5058 =item vector flag
5059
5060 The vector flag C<v>, optionally specifying the join string to use.
5061 This flag tells perl to interpret the supplied string as a vector
5062 of integers, one for each character in the string, separated by
5063 a given string (a dot C<.> by default). This can be useful for
5064 displaying ordinal values of characters in arbitrary strings:
5065
5066   printf "version is v%vd\n", $^V;     # Perl's version
5067
5068 Put an asterisk C<*> before the C<v> to override the string to
5069 use to separate the numbers:
5070
5071   printf "address is %*vX\n", ":", $addr;   # IPv6 address
5072   printf "bits are %0*v8b\n", " ", $bits;   # random bitstring
5073
5074 You can also explicitly specify the argument number to use for
5075 the join string using eg C<*2$v>:
5076
5077   printf '%*4$vX %*4$vX %*4$vX', @addr[1..3], ":";   # 3 IPv6 addresses
5078
5079 =item (minimum) width
5080
5081 Arguments are usually formatted to be only as wide as required to
5082 display the given value. You can override the width by putting
5083 a number here, or get the width from the next argument (with C<*>)
5084 or from a specified argument (with eg C<*2$>):
5085
5086   printf '<%s>', "a";       # prints "<a>"
5087   printf '<%6s>', "a";      # prints "<     a>"
5088   printf '<%*s>', 6, "a";   # prints "<     a>"
5089   printf '<%*2$s>', "a", 6; # prints "<     a>"
5090   printf '<%2s>', "long";   # prints "<long>" (does not truncate)
5091
5092 If a field width obtained through C<*> is negative, it has the same
5093 effect as the C<-> flag: left-justification.
5094
5095 =item precision, or maximum width
5096
5097 You can specify a precision (for numeric conversions) or a maximum
5098 width (for string conversions) by specifying a C<.> followed by a number.
5099 For floating point formats, with the exception of 'g' and 'G', this specifies
5100 the number of decimal places to show (the default being 6), eg:
5101
5102   # these examples are subject to system-specific variation
5103   printf '<%f>', 1;    # prints "<1.000000>"
5104   printf '<%.1f>', 1;  # prints "<1.0>"
5105   printf '<%.0f>', 1;  # prints "<1>"
5106   printf '<%e>', 10;   # prints "<1.000000e+01>"
5107   printf '<%.1e>', 10; # prints "<1.0e+01>"
5108
5109 For 'g' and 'G', this specifies the maximum number of digits to show,
5110 including prior to the decimal point as well as after it, eg:
5111
5112   # these examples are subject to system-specific variation
5113   printf '<%g>', 1;        # prints "<1>"
5114   printf '<%.10g>', 1;     # prints "<1>"
5115   printf '<%g>', 100;      # prints "<100>"
5116   printf '<%.1g>', 100;    # prints "<1e+02>"
5117   printf '<%.2g>', 100.01; # prints "<1e+02>"
5118   printf '<%.5g>', 100.01; # prints "<100.01>"
5119   printf '<%.4g>', 100.01; # prints "<100>"
5120
5121 For integer conversions, specifying a precision implies that the
5122 output of the number itself should be zero-padded to this width:
5123
5124   printf '<%.6x>', 1;      # prints "<000001>"
5125   printf '<%#.6x>', 1;     # prints "<0x000001>"
5126   printf '<%-10.6x>', 1;   # prints "<000001    >"
5127
5128 For string conversions, specifying a precision truncates the string
5129 to fit in the specified width:
5130
5131   printf '<%.5s>', "truncated";   # prints "<trunc>"
5132   printf '<%10.5s>', "truncated"; # prints "<     trunc>"
5133
5134 You can also get the precision from the next argument using C<.*>:
5135
5136   printf '<%.6x>', 1;       # prints "<000001>"
5137   printf '<%.*x>', 6, 1;    # prints "<000001>"
5138
5139 You cannot currently get the precision from a specified number,
5140 but it is intended that this will be possible in the future using
5141 eg C<.*2$>:
5142
5143   printf '<%.*2$x>', 1, 6;   # INVALID, but in future will print "<000001>"
5144
5145 =item size
5146
5147 For numeric conversions, you can specify the size to interpret the
5148 number as using C<l>, C<h>, C<V>, C<q>, C<L>, or C<ll>. For integer
5149 conversions (C<d u o x X b i D U O>), numbers are usually assumed to be
5150 whatever the default integer size is on your platform (usually 32 or 64
5151 bits), but you can override this to use instead one of the standard C types,
5152 as supported by the compiler used to build Perl:
5153
5154    l           interpret integer as C type "long" or "unsigned long"
5155    h           interpret integer as C type "short" or "unsigned short"
5156    q, L or ll  interpret integer as C type "long long", "unsigned long long".
5157                or "quads" (typically 64-bit integers)
5158
5159 The last will produce errors if Perl does not understand "quads" in your
5160 installation. (This requires that either the platform natively supports quads
5161 or Perl was specifically compiled to support quads.) You can find out
5162 whether your Perl supports quads via L<Config>:
5163
5164         use Config;
5165         ($Config{use64bitint} eq 'define' || $Config{longsize} >= 8) &&
5166                 print "quads\n";
5167
5168 For floating point conversions (C<e f g E F G>), numbers are usually assumed
5169 to be the default floating point size on your platform (double or long double),
5170 but you can force 'long double' with C<q>, C<L>, or C<ll> if your
5171 platform supports them. You can find out whether your Perl supports long
5172 doubles via L<Config>:
5173
5174         use Config;
5175         $Config{d_longdbl} eq 'define' && print "long doubles\n";
5176
5177 You can find out whether Perl considers 'long double' to be the default
5178 floating point size to use on your platform via L<Config>:
5179
5180         use Config;
5181         ($Config{uselongdouble} eq 'define') &&
5182                 print "long doubles by default\n";
5183
5184 It can also be the case that long doubles and doubles are the same thing:
5185
5186         use Config;
5187         ($Config{doublesize} == $Config{longdblsize}) &&
5188                 print "doubles are long doubles\n";
5189
5190 The size specifier C<V> has no effect for Perl code, but it is supported
5191 for compatibility with XS code; it means 'use the standard size for
5192 a Perl integer (or floating-point number)', which is already the
5193 default for Perl code.
5194
5195 =item order of arguments
5196
5197 Normally, sprintf takes the next unused argument as the value to
5198 format for each format specification. If the format specification
5199 uses C<*> to require additional arguments, these are consumed from
5200 the argument list in the order in which they appear in the format
5201 specification I<before> the value to format. Where an argument is
5202 specified using an explicit index, this does not affect the normal
5203 order for the arguments (even when the explicitly specified index
5204 would have been the next argument in any case).
5205
5206 So:
5207
5208   printf '<%*.*s>', $a, $b, $c;
5209
5210 would use C<$a> for the width, C<$b> for the precision and C<$c>
5211 as the value to format, while:
5212
5213   print '<%*1$.*s>', $a, $b;
5214
5215 would use C<$a> for the width and the precision, and C<$b> as the
5216 value to format.
5217
5218 Here are some more examples - beware that when using an explicit
5219 index, the C<$> may need to be escaped:
5220
5221   printf "%2\$d %d\n",    12, 34;               # will print "34 12\n"
5222   printf "%2\$d %d %d\n", 12, 34;               # will print "34 12 34\n"
5223   printf "%3\$d %d %d\n", 12, 34, 56;           # will print "56 12 34\n"
5224   printf "%2\$*3\$d %d\n", 12, 34, 3;           # will print " 34 12\n"
5225
5226 =back
5227
5228 If C<use locale> is in effect, the character used for the decimal
5229 point in formatted real numbers is affected by the LC_NUMERIC locale.
5230 See L<perllocale>.
5231
5232 =item sqrt EXPR
5233
5234 =item sqrt
5235
5236 Return the square root of EXPR.  If EXPR is omitted, returns square
5237 root of C<$_>.  Only works on non-negative operands, unless you've
5238 loaded the standard Math::Complex module.
5239
5240     use Math::Complex;
5241     print sqrt(-2);    # prints 1.4142135623731i
5242
5243 =item srand EXPR
5244
5245 =item srand
5246
5247 Sets the random number seed for the C<rand> operator.
5248
5249 The point of the function is to "seed" the C<rand> function so that
5250 C<rand> can produce a different sequence each time you run your
5251 program.
5252
5253 If srand() is not called explicitly, it is called implicitly at the
5254 first use of the C<rand> operator.  However, this was not the case in
5255 versions of Perl before 5.004, so if your script will run under older
5256 Perl versions, it should call C<srand>.
5257
5258 Most programs won't even call srand() at all, except those that
5259 need a cryptographically-strong starting point rather than the
5260 generally acceptable default, which is based on time of day,
5261 process ID, and memory allocation, or the F</dev/urandom> device,
5262 if available.
5263
5264 You can call srand($seed) with the same $seed to reproduce the
5265 I<same> sequence from rand(), but this is usually reserved for
5266 generating predictable results for testing or debugging.
5267 Otherwise, don't call srand() more than once in your program.
5268
5269 Do B<not> call srand() (i.e. without an argument) more than once in
5270 a script.  The internal state of the random number generator should
5271 contain more entropy than can be provided by any seed, so calling
5272 srand() again actually I<loses> randomness.
5273
5274 Most implementations of C<srand> take an integer and will silently
5275 truncate decimal numbers.  This means C<srand(42)> will usually
5276 produce the same results as C<srand(42.1)>.  To be safe, always pass
5277 C<srand> an integer.
5278
5279 In versions of Perl prior to 5.004 the default seed was just the
5280 current C<time>.  This isn't a particularly good seed, so many old
5281 programs supply their own seed value (often C<time ^ $$> or C<time ^
5282 ($$ + ($$ << 15))>), but that isn't necessary any more.
5283
5284 Note that you need something much more random than the default seed for
5285 cryptographic purposes.  Checksumming the compressed output of one or more
5286 rapidly changing operating system status programs is the usual method.  For
5287 example:
5288
5289     srand (time ^ $$ ^ unpack "%L*", `ps axww | gzip`);
5290
5291 If you're particularly concerned with this, see the C<Math::TrulyRandom>
5292 module in CPAN.
5293
5294 Frequently called programs (like CGI scripts) that simply use
5295
5296     time ^ $$
5297
5298 for a seed can fall prey to the mathematical property that
5299
5300     a^b == (a+1)^(b+1)
5301
5302 one-third of the time.  So don't do that.
5303
5304 =item stat FILEHANDLE
5305
5306 =item stat EXPR
5307
5308 =item stat
5309
5310 Returns a 13-element list giving the status info for a file, either
5311 the file opened via FILEHANDLE, or named by EXPR.  If EXPR is omitted,
5312 it stats C<$_>.  Returns a null list if the stat fails.  Typically used
5313 as follows:
5314
5315     ($dev,$ino,$mode,$nlink,$uid,$gid,$rdev,$size,
5316        $atime,$mtime,$ctime,$blksize,$blocks)
5317            = stat($filename);
5318
5319 Not all fields are supported on all filesystem types.  Here are the
5320 meaning of the fields:
5321
5322   0 dev      device number of filesystem
5323   1 ino      inode number
5324   2 mode     file mode  (type and permissions)
5325   3 nlink    number of (hard) links to the file
5326   4 uid      numeric user ID of file's owner
5327   5 gid      numeric group ID of file's owner
5328   6 rdev     the device identifier (special files only)
5329   7 size     total size of file, in bytes
5330   8 atime    last access time in seconds since the epoch
5331   9 mtime    last modify time in seconds since the epoch
5332  10 ctime    inode change time in seconds since the epoch (*)
5333  11 blksize  preferred block size for file system I/O
5334  12 blocks   actual number of blocks allocated
5335
5336 (The epoch was at 00:00 January 1, 1970 GMT.)
5337
5338 (*) The ctime field is non-portable, in particular you cannot expect
5339 it to be a "creation time", see L<perlport/"Files and Filesystems">
5340 for details.
5341
5342 If stat is passed the special filehandle consisting of an underline, no
5343 stat is done, but the current contents of the stat structure from the
5344 last stat or filetest are returned.  Example:
5345
5346     if (-x $file && (($d) = stat(_)) && $d < 0) {
5347         print "$file is executable NFS file\n";
5348     }
5349
5350 (This works on machines only for which the device number is negative
5351 under NFS.)
5352
5353 Because the mode contains both the file type and its permissions, you
5354 should mask off the file type portion and (s)printf using a C<"%o">
5355 if you want to see the real permissions.
5356
5357     $mode = (stat($filename))[2];
5358     printf "Permissions are %04o\n", $mode & 07777;
5359
5360 In scalar context, C<stat> returns a boolean value indicating success
5361 or failure, and, if successful, sets the information associated with
5362 the special filehandle C<_>.
5363
5364 The File::stat module provides a convenient, by-name access mechanism:
5365
5366     use File::stat;
5367     $sb = stat($filename);
5368     printf "File is %s, size is %s, perm %04o, mtime %s\n",
5369         $filename, $sb->size, $sb->mode & 07777,
5370         scalar localtime $sb->mtime;
5371
5372 You can import symbolic mode constants (C<S_IF*>) and functions
5373 (C<S_IS*>) from the Fcntl module:
5374
5375     use Fcntl ':mode';
5376
5377     $mode = (stat($filename))[2];
5378
5379     $user_rwx      = ($mode & S_IRWXU) >> 6;
5380     $group_read    = ($mode & S_IRGRP) >> 3;
5381     $other_execute =  $mode & S_IXOTH;
5382
5383     printf "Permissions are %04o\n", S_IMODE($mode), "\n";
5384
5385     $is_setuid     =  $mode & S_ISUID;
5386     $is_setgid     =  S_ISDIR($mode);
5387
5388 You could write the last two using the C<-u> and C<-d> operators.
5389 The commonly available S_IF* constants are
5390
5391     # Permissions: read, write, execute, for user, group, others.
5392
5393     S_IRWXU S_IRUSR S_IWUSR S_IXUSR
5394     S_IRWXG S_IRGRP S_IWGRP S_IXGRP
5395     S_IRWXO S_IROTH S_IWOTH S_IXOTH
5396
5397     # Setuid/Setgid/Stickiness/SaveText.
5398     # Note that the exact meaning of these is system dependent.
5399
5400     S_ISUID S_ISGID S_ISVTX S_ISTXT
5401
5402     # File types.  Not necessarily all are available on your system.
5403
5404     S_IFREG S_IFDIR S_IFLNK S_IFBLK S_ISCHR S_IFIFO S_IFSOCK S_IFWHT S_ENFMT
5405
5406     # The following are compatibility aliases for S_IRUSR, S_IWUSR, S_IXUSR.
5407
5408     S_IREAD S_IWRITE S_IEXEC
5409
5410 and the S_IF* functions are
5411
5412     S_IMODE($mode)      the part of $mode containing the permission bits
5413                         and the setuid/setgid/sticky bits
5414
5415     S_IFMT($mode)       the part of $mode containing the file type
5416                         which can be bit-anded with e.g. S_IFREG
5417                         or with the following functions
5418
5419     # The operators -f, -d, -l, -b, -c, -p, and -s.
5420
5421     S_ISREG($mode) S_ISDIR($mode) S_ISLNK($mode)
5422     S_ISBLK($mode) S_ISCHR($mode) S_ISFIFO($mode) S_ISSOCK($mode)
5423
5424     # No direct -X operator counterpart, but for the first one
5425     # the -g operator is often equivalent.  The ENFMT stands for
5426     # record flocking enforcement, a platform-dependent feature.
5427
5428     S_ISENFMT($mode) S_ISWHT($mode)
5429
5430 See your native chmod(2) and stat(2) documentation for more details
5431 about the S_* constants.  To get status info for a symbolic link
5432 instead of the target file behind the link, use the C<lstat> function.
5433
5434 =item study SCALAR
5435
5436 =item study
5437
5438 Takes extra time to study SCALAR (C<$_> if unspecified) in anticipation of
5439 doing many pattern matches on the string before it is next modified.
5440 This may or may not save time, depending on the nature and number of
5441 patterns you are searching on, and on the distribution of character
5442 frequencies in the string to be searched--you probably want to compare
5443 run times with and without it to see which runs faster.  Those loops
5444 which scan for many short constant strings (including the constant
5445 parts of more complex patterns) will benefit most.  You may have only
5446 one C<study> active at a time--if you study a different scalar the first
5447 is "unstudied".  (The way C<study> works is this: a linked list of every
5448 character in the string to be searched is made, so we know, for
5449 example, where all the C<'k'> characters are.  From each search string,
5450 the rarest character is selected, based on some static frequency tables
5451 constructed from some C programs and English text.  Only those places
5452 that contain this "rarest" character are examined.)
5453
5454 For example, here is a loop that inserts index producing entries
5455 before any line containing a certain pattern:
5456
5457     while (<>) {
5458         study;
5459         print ".IX foo\n"       if /\bfoo\b/;
5460         print ".IX bar\n"       if /\bbar\b/;
5461         print ".IX blurfl\n"    if /\bblurfl\b/;
5462         # ...
5463         print;
5464     }
5465
5466 In searching for C</\bfoo\b/>, only those locations in C<$_> that contain C<f>
5467 will be looked at, because C<f> is rarer than C<o>.  In general, this is
5468 a big win except in pathological cases.  The only question is whether
5469 it saves you more time than it took to build the linked list in the
5470 first place.
5471
5472 Note that if you have to look for strings that you don't know till
5473 runtime, you can build an entire loop as a string and C<eval> that to
5474 avoid recompiling all your patterns all the time.  Together with
5475 undefining C<$/> to input entire files as one record, this can be very
5476 fast, often faster than specialized programs like fgrep(1).  The following
5477 scans a list of files (C<@files>) for a list of words (C<@words>), and prints
5478 out the names of those files that contain a match:
5479
5480     $search = 'while (<>) { study;';
5481     foreach $word (@words) {
5482         $search .= "++\$seen{\$ARGV} if /\\b$word\\b/;\n";
5483     }
5484     $search .= "}";
5485     @ARGV = @files;
5486     undef $/;
5487     eval $search;               # this screams
5488     $/ = "\n";          # put back to normal input delimiter
5489     foreach $file (sort keys(%seen)) {
5490         print $file, "\n";
5491     }
5492
5493 =item sub NAME BLOCK
5494
5495 =item sub NAME (PROTO) BLOCK
5496
5497 =item sub NAME : ATTRS BLOCK
5498
5499 =item sub NAME (PROTO) : ATTRS BLOCK
5500
5501 This is subroutine definition, not a real function I<per se>.
5502 Without a BLOCK it's just a forward declaration.  Without a NAME,
5503 it's an anonymous function declaration, and does actually return
5504 a value: the CODE ref of the closure you just created.
5505
5506 See L<perlsub> and L<perlref> for details about subroutines and
5507 references, and L<attributes> and L<Attribute::Handlers> for more
5508 information about attributes.
5509
5510 =item substr EXPR,OFFSET,LENGTH,REPLACEMENT
5511
5512 =item substr EXPR,OFFSET,LENGTH
5513
5514 =item substr EXPR,OFFSET
5515
5516 Extracts a substring out of EXPR and returns it.  First character is at
5517 offset C<0>, or whatever you've set C<$[> to (but don't do that).
5518 If OFFSET is negative (or more precisely, less than C<$[>), starts
5519 that far from the end of the string.  If LENGTH is omitted, returns
5520 everything to the end of the string.  If LENGTH is negative, leaves that
5521 many characters off the end of the string.
5522
5523 You can use the substr() function as an lvalue, in which case EXPR
5524 must itself be an lvalue.  If you assign something shorter than LENGTH,
5525 the string will shrink, and if you assign something longer than LENGTH,
5526 the string will grow to accommodate it.  To keep the string the same
5527 length you may need to pad or chop your value using C<sprintf>.
5528
5529 If OFFSET and LENGTH specify a substring that is partly outside the
5530 string, only the part within the string is returned.  If the substring
5531 is beyond either end of the string, substr() returns the undefined
5532 value and produces a warning.  When used as an lvalue, specifying a
5533 substring that is entirely outside the string is a fatal error.
5534 Here's an example showing the behavior for boundary cases:
5535
5536     my $name = 'fred';
5537     substr($name, 4) = 'dy';            # $name is now 'freddy'
5538     my $null = substr $name, 6, 2;      # returns '' (no warning)
5539     my $oops = substr $name, 7;         # returns undef, with warning
5540     substr($name, 7) = 'gap';           # fatal error
5541
5542 An alternative to using substr() as an lvalue is to specify the
5543 replacement string as the 4th argument.  This allows you to replace
5544 parts of the EXPR and return what was there before in one operation,
5545 just as you can with splice().
5546
5547 If the lvalue returned by substr is used after the EXPR is changed in
5548 any way, the behaviour may not be as expected and is subject to change.
5549 This caveat includes code such as C<print(substr($foo,$a,$b)=$bar)> or
5550 C<(substr($foo,$a,$b)=$bar)=$fud> (where $foo is changed via the
5551 substring assignment, and then the substr is used again), or where a
5552 substr() is aliased via a C<foreach> loop or passed as a parameter or
5553 a reference to it is taken and then the alias, parameter, or deref'd
5554 reference either is used after the original EXPR has been changed or
5555 is assigned to and then used a second time.
5556
5557 =item symlink OLDFILE,NEWFILE
5558
5559 Creates a new filename symbolically linked to the old filename.
5560 Returns C<1> for success, C<0> otherwise.  On systems that don't support
5561 symbolic links, produces a fatal error at run time.  To check for that,
5562 use eval:
5563
5564     $symlink_exists = eval { symlink("",""); 1 };
5565
5566 =item syscall NUMBER, LIST
5567
5568 Calls the system call specified as the first element of the list,
5569 passing the remaining elements as arguments to the system call.  If
5570 unimplemented, produces a fatal error.  The arguments are interpreted
5571 as follows: if a given argument is numeric, the argument is passed as
5572 an int.  If not, the pointer to the string value is passed.  You are
5573 responsible to make sure a string is pre-extended long enough to
5574 receive any result that might be written into a string.  You can't use a
5575 string literal (or other read-only string) as an argument to C<syscall>
5576 because Perl has to assume that any string pointer might be written
5577 through.  If your
5578 integer arguments are not literals and have never been interpreted in a
5579 numeric context, you may need to add C<0> to them to force them to look
5580 like numbers.  This emulates the C<syswrite> function (or vice versa):
5581
5582     require 'syscall.ph';               # may need to run h2ph
5583     $s = "hi there\n";
5584     syscall(&SYS_write, fileno(STDOUT), $s, length $s);
5585
5586 Note that Perl supports passing of up to only 14 arguments to your system call,
5587 which in practice should usually suffice.
5588
5589 Syscall returns whatever value returned by the system call it calls.
5590 If the system call fails, C<syscall> returns C<-1> and sets C<$!> (errno).
5591 Note that some system calls can legitimately return C<-1>.  The proper
5592 way to handle such calls is to assign C<$!=0;> before the call and
5593 check the value of C<$!> if syscall returns C<-1>.
5594
5595 There's a problem with C<syscall(&SYS_pipe)>: it returns the file
5596 number of the read end of the pipe it creates.  There is no way
5597 to retrieve the file number of the other end.  You can avoid this
5598 problem by using C<pipe> instead.
5599
5600 =item sysopen FILEHANDLE,FILENAME,MODE
5601
5602 =item sysopen FILEHANDLE,FILENAME,MODE,PERMS
5603
5604 Opens the file whose filename is given by FILENAME, and associates it
5605 with FILEHANDLE.  If FILEHANDLE is an expression, its value is used as
5606 the name of the real filehandle wanted.  This function calls the
5607 underlying operating system's C<open> function with the parameters
5608 FILENAME, MODE, PERMS.
5609
5610 The possible values and flag bits of the MODE parameter are
5611 system-dependent; they are available via the standard module C<Fcntl>.
5612 See the documentation of your operating system's C<open> to see which
5613 values and flag bits are available.  You may combine several flags
5614 using the C<|>-operator.
5615
5616 Some of the most common values are C<O_RDONLY> for opening the file in
5617 read-only mode, C<O_WRONLY> for opening the file in write-only mode,
5618 and C<O_RDWR> for opening the file in read-write mode, and.
5619
5620 For historical reasons, some values work on almost every system
5621 supported by perl: zero means read-only, one means write-only, and two
5622 means read/write.  We know that these values do I<not> work under
5623 OS/390 & VM/ESA Unix and on the Macintosh; you probably don't want to
5624 use them in new code.
5625
5626 If the file named by FILENAME does not exist and the C<open> call creates
5627 it (typically because MODE includes the C<O_CREAT> flag), then the value of
5628 PERMS specifies the permissions of the newly created file.  If you omit
5629 the PERMS argument to C<sysopen>, Perl uses the octal value C<0666>.
5630 These permission values need to be in octal, and are modified by your
5631 process's current C<umask>.
5632
5633 In many systems the C<O_EXCL> flag is available for opening files in
5634 exclusive mode.  This is B<not> locking: exclusiveness means here that
5635 if the file already exists, sysopen() fails.  The C<O_EXCL> wins
5636 C<O_TRUNC>.
5637
5638 Sometimes you may want to truncate an already-existing file: C<O_TRUNC>.
5639
5640 You should seldom if ever use C<0644> as argument to C<sysopen>, because
5641 that takes away the user's option to have a more permissive umask.
5642 Better to omit it.  See the perlfunc(1) entry on C<umask> for more
5643 on this.
5644
5645 Note that C<sysopen> depends on the fdopen() C library function.
5646 On many UNIX systems, fdopen() is known to fail when file descriptors
5647 exceed a certain value, typically 255. If you need more file
5648 descriptors than that, consider rebuilding Perl to use the C<sfio>
5649 library, or perhaps using the POSIX::open() function.
5650
5651 See L<perlopentut> for a kinder, gentler explanation of opening files.
5652
5653 =item sysread FILEHANDLE,SCALAR,LENGTH,OFFSET
5654
5655 =item sysread FILEHANDLE,SCALAR,LENGTH
5656
5657 Attempts to read LENGTH bytes of data into variable SCALAR from the
5658 specified FILEHANDLE, using the system call read(2).  It bypasses
5659 buffered IO, so mixing this with other kinds of reads, C<print>,
5660 C<write>, C<seek>, C<tell>, or C<eof> can cause confusion because the
5661 perlio or stdio layers usually buffers data.  Returns the number of
5662 bytes actually read, C<0> at end of file, or undef if there was an
5663 error (in the latter case C<$!> is also set).  SCALAR will be grown or
5664 shrunk so that the last byte actually read is the last byte of the
5665 scalar after the read.
5666
5667 An OFFSET may be specified to place the read data at some place in the
5668 string other than the beginning.  A negative OFFSET specifies
5669 placement at that many characters counting backwards from the end of
5670 the string.  A positive OFFSET greater than the length of SCALAR
5671 results in the string being padded to the required size with C<"\0">
5672 bytes before the result of the read is appended.
5673
5674 There is no syseof() function, which is ok, since eof() doesn't work
5675 very well on device files (like ttys) anyway.  Use sysread() and check
5676 for a return value for 0 to decide whether you're done.
5677
5678 Note that if the filehandle has been marked as C<:utf8> Unicode
5679 characters are read instead of bytes (the LENGTH, OFFSET, and the
5680 return value of sysread() are in Unicode characters).
5681 The C<:encoding(...)> layer implicitly introduces the C<:utf8> layer.
5682 See L</binmode>, L</open>, and the C<open> pragma, L<open>.
5683
5684 =item sysseek FILEHANDLE,POSITION,WHENCE
5685
5686 Sets FILEHANDLE's system position in bytes using the system call
5687 lseek(2).  FILEHANDLE may be an expression whose value gives the name
5688 of the filehandle.  The values for WHENCE are C<0> to set the new
5689 position to POSITION, C<1> to set the it to the current position plus
5690 POSITION, and C<2> to set it to EOF plus POSITION (typically
5691 negative).
5692
5693 Note the I<in bytes>: even if the filehandle has been set to operate
5694 on characters (for example by using the C<:utf8> I/O layer), tell()
5695 will return byte offsets, not character offsets (because implementing
5696 that would render sysseek() very slow).
5697
5698 sysseek() bypasses normal buffered IO, so mixing this with reads (other
5699 than C<sysread>, for example &gt;&lt or read()) C<print>, C<write>,
5700 C<seek>, C<tell>, or C<eof> may cause confusion.
5701
5702 For WHENCE, you may also use the constants C<SEEK_SET>, C<SEEK_CUR>,
5703 and C<SEEK_END> (start of the file, current position, end of the file)
5704 from the Fcntl module.  Use of the constants is also more portable
5705 than relying on 0, 1, and 2.  For example to define a "systell" function:
5706
5707         use Fcntl 'SEEK_CUR';
5708         sub systell { sysseek($_[0], 0, SEEK_CUR) }
5709
5710 Returns the new position, or the undefined value on failure.  A position
5711 of zero is returned as the string C<"0 but true">; thus C<sysseek> returns
5712 true on success and false on failure, yet you can still easily determine
5713 the new position.
5714
5715 =item system LIST
5716
5717 =item system PROGRAM LIST
5718
5719 Does exactly the same thing as C<exec LIST>, except that a fork is
5720 done first, and the parent process waits for the child process to
5721 complete.  Note that argument processing varies depending on the
5722 number of arguments.  If there is more than one argument in LIST,
5723 or if LIST is an array with more than one value, starts the program
5724 given by the first element of the list with arguments given by the
5725 rest of the list.  If there is only one scalar argument, the argument
5726 is checked for shell metacharacters, and if there are any, the
5727 entire argument is passed to the system's command shell for parsing
5728 (this is C</bin/sh -c> on Unix platforms, but varies on other
5729 platforms).  If there are no shell metacharacters in the argument,
5730 it is split into words and passed directly to C<execvp>, which is
5731 more efficient.
5732
5733 Beginning with v5.6.0, Perl will attempt to flush all files opened for
5734 output before any operation that may do a fork, but this may not be
5735 supported on some platforms (see L<perlport>).  To be safe, you may need
5736 to set C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method
5737 of C<IO::Handle> on any open handles.
5738
5739 The return value is the exit status of the program as returned by the
5740 C<wait> call.  To get the actual exit value shift right by eight (see below).
5741 See also L</exec>.  This is I<not> what you want to use to capture
5742 the output from a command, for that you should use merely backticks or
5743 C<qx//>, as described in L<perlop/"`STRING`">.  Return value of -1
5744 indicates a failure to start the program (inspect $! for the reason).
5745
5746 Like C<exec>, C<system> allows you to lie to a program about its name if
5747 you use the C<system PROGRAM LIST> syntax.  Again, see L</exec>.
5748
5749 Because C<system> and backticks block C<SIGINT> and C<SIGQUIT>,
5750 killing the program they're running doesn't actually interrupt
5751 your program.
5752
5753     @args = ("command", "arg1", "arg2");
5754     system(@args) == 0
5755          or die "system @args failed: $?"
5756
5757 You can check all the failure possibilities by inspecting
5758 C<$?> like this:
5759
5760     if ($? == -1) {
5761         print "failed to execute: $!\n";
5762     }
5763     elsif ($? & 127) {
5764         printf "child died with signal %d, %s coredump\n",
5765             ($? & 127),  ($? & 128) ? 'with' : 'without';
5766     }
5767     else {
5768         printf "child exited with value %d\n", $? >> 8;
5769     }
5770
5771
5772 or more portably by using the W*() calls of the POSIX extension;
5773 see L<perlport> for more information.
5774
5775 When the arguments get executed via the system shell, results
5776 and return codes will be subject to its quirks and capabilities.
5777 See L<perlop/"`STRING`"> and L</exec> for details.
5778
5779 =item syswrite FILEHANDLE,SCALAR,LENGTH,OFFSET
5780
5781 =item syswrite FILEHANDLE,SCALAR,LENGTH
5782
5783 =item syswrite FILEHANDLE,SCALAR
5784
5785 Attempts to write LENGTH bytes of data from variable SCALAR to the
5786 specified FILEHANDLE, using the system call write(2).  If LENGTH is
5787 not specified, writes whole SCALAR.  It bypasses buffered IO, so
5788 mixing this with reads (other than C<sysread())>, C<print>, C<write>,
5789 C<seek>, C<tell>, or C<eof> may cause confusion because the perlio and
5790 stdio layers usually buffers data.  Returns the number of bytes
5791 actually written, or C<undef> if there was an error (in this case the
5792 errno variable C<$!> is also set).  If the LENGTH is greater than the
5793 available data in the SCALAR after the OFFSET, only as much data as is
5794 available will be written.
5795
5796 An OFFSET may be specified to write the data from some part of the
5797 string other than the beginning.  A negative OFFSET specifies writing
5798 that many characters counting backwards from the end of the string.
5799 In the case the SCALAR is empty you can use OFFSET but only zero offset.
5800
5801 Note that if the filehandle has been marked as C<:utf8>, Unicode
5802 characters are written instead of bytes (the LENGTH, OFFSET, and the
5803 return value of syswrite() are in UTF-8 encoded Unicode characters).
5804 The C<:encoding(...)> layer implicitly introduces the C<:utf8> layer.
5805 See L</binmode>, L</open>, and the C<open> pragma, L<open>.
5806
5807 =item tell FILEHANDLE
5808
5809 =item tell
5810
5811 Returns the current position I<in bytes> for FILEHANDLE, or -1 on
5812 error.  FILEHANDLE may be an expression whose value gives the name of
5813 the actual filehandle.  If FILEHANDLE is omitted, assumes the file
5814 last read.
5815
5816 Note the I<in bytes>: even if the filehandle has been set to
5817 operate on characters (for example by using the C<:utf8> open
5818 layer), tell() will return byte offsets, not character offsets
5819 (because that would render seek() and tell() rather slow).
5820
5821 The return value of tell() for the standard streams like the STDIN
5822 depends on the operating system: it may return -1 or something else.
5823 tell() on pipes, fifos, and sockets usually returns -1.
5824
5825 There is no C<systell> function.  Use C<sysseek(FH, 0, 1)> for that.
5826
5827 Do not use tell() on a filehandle that has been opened using
5828 sysopen(), use sysseek() for that as described above.  Why?  Because
5829 sysopen() creates unbuffered, "raw", filehandles, while open() creates
5830 buffered filehandles.  sysseek() make sense only on the first kind,
5831 tell() only makes sense on the second kind.
5832
5833 =item telldir DIRHANDLE
5834
5835 Returns the current position of the C<readdir> routines on DIRHANDLE.
5836 Value may be given to C<seekdir> to access a particular location in a
5837 directory.  Has the same caveats about possible directory compaction as
5838 the corresponding system library routine.
5839
5840 =item tie VARIABLE,CLASSNAME,LIST
5841
5842 This function binds a variable to a package class that will provide the
5843 implementation for the variable.  VARIABLE is the name of the variable
5844 to be enchanted.  CLASSNAME is the name of a class implementing objects
5845 of correct type.  Any additional arguments are passed to the C<new>
5846 method of the class (meaning C<TIESCALAR>, C<TIEHANDLE>, C<TIEARRAY>,
5847 or C<TIEHASH>).  Typically these are arguments such as might be passed
5848 to the C<dbm_open()> function of C.  The object returned by the C<new>
5849 method is also returned by the C<tie> function, which would be useful
5850 if you want to access other methods in CLASSNAME.
5851
5852 Note that functions such as C<keys> and C<values> may return huge lists
5853 when used on large objects, like DBM files.  You may prefer to use the
5854 C<each> function to iterate over such.  Example:
5855
5856     # print out history file offsets
5857     use NDBM_File;
5858     tie(%HIST, 'NDBM_File', '/usr/lib/news/history', 1, 0);
5859     while (($key,$val) = each %HIST) {
5860         print $key, ' = ', unpack('L',$val), "\n";
5861     }
5862     untie(%HIST);
5863
5864 A class implementing a hash should have the following methods:
5865
5866     TIEHASH classname, LIST
5867     FETCH this, key
5868     STORE this, key, value
5869     DELETE this, key
5870     CLEAR this
5871     EXISTS this, key
5872     FIRSTKEY this
5873     NEXTKEY this, lastkey
5874     DESTROY this
5875     UNTIE this
5876
5877 A class implementing an ordinary array should have the following methods:
5878
5879     TIEARRAY classname, LIST
5880     FETCH this, key
5881     STORE this, key, value
5882     FETCHSIZE this
5883     STORESIZE this, count
5884     CLEAR this
5885     PUSH this, LIST
5886     POP this
5887     SHIFT this
5888     UNSHIFT this, LIST
5889     SPLICE this, offset, length, LIST
5890     EXTEND this, count
5891     DESTROY this
5892     UNTIE this
5893
5894 A class implementing a file handle should have the following methods:
5895
5896     TIEHANDLE classname, LIST
5897     READ this, scalar, length, offset
5898     READLINE this
5899     GETC this
5900     WRITE this, scalar, length, offset
5901     PRINT this, LIST
5902     PRINTF this, format, LIST
5903     BINMODE this
5904     EOF this
5905     FILENO this
5906     SEEK this, position, whence
5907     TELL this
5908     OPEN this, mode, LIST
5909     CLOSE this
5910     DESTROY this
5911     UNTIE this
5912
5913 A class implementing a scalar should have the following methods:
5914
5915     TIESCALAR classname, LIST
5916     FETCH this,
5917     STORE this, value
5918     DESTROY this
5919     UNTIE this
5920
5921 Not all methods indicated above need be implemented.  See L<perltie>,
5922 L<Tie::Hash>, L<Tie::Array>, L<Tie::Scalar>, and L<Tie::Handle>.
5923
5924 Unlike C<dbmopen>, the C<tie> function will not use or require a module
5925 for you--you need to do that explicitly yourself.  See L<DB_File>
5926 or the F<Config> module for interesting C<tie> implementations.
5927
5928 For further details see L<perltie>, L<"tied VARIABLE">.
5929
5930 =item tied VARIABLE
5931
5932 Returns a reference to the object underlying VARIABLE (the same value
5933 that was originally returned by the C<tie> call that bound the variable
5934 to a package.)  Returns the undefined value if VARIABLE isn't tied to a
5935 package.
5936
5937 =item time
5938
5939 Returns the number of non-leap seconds since whatever time the system
5940 considers to be the epoch (that's 00:00:00, January 1, 1904 for Mac OS,
5941 and 00:00:00 UTC, January 1, 1970 for most other systems).
5942 Suitable for feeding to C<gmtime> and C<localtime>.
5943
5944 For measuring time in better granularity than one second,
5945 you may use either the Time::HiRes module (from CPAN, and starting from
5946 Perl 5.8 part of the standard distribution), or if you have
5947 gettimeofday(2), you may be able to use the C<syscall> interface of Perl.
5948 See L<perlfaq8> for details.
5949
5950 =item times
5951
5952 Returns a four-element list giving the user and system times, in
5953 seconds, for this process and the children of this process.
5954
5955     ($user,$system,$cuser,$csystem) = times;
5956
5957 In scalar context, C<times> returns C<$user>.
5958
5959 =item tr///
5960
5961 The transliteration operator.  Same as C<y///>.  See L<perlop>.
5962
5963 =item truncate FILEHANDLE,LENGTH
5964
5965 =item truncate EXPR,LENGTH
5966
5967 Truncates the file opened on FILEHANDLE, or named by EXPR, to the
5968 specified length.  Produces a fatal error if truncate isn't implemented
5969 on your system.  Returns true if successful, the undefined value
5970 otherwise.
5971
5972 The behavior is undefined if LENGTH is greater than the length of the
5973 file.
5974
5975 =item uc EXPR
5976
5977 =item uc
5978
5979 Returns an uppercased version of EXPR.  This is the internal function
5980 implementing the C<\U> escape in double-quoted strings.  Respects
5981 current LC_CTYPE locale if C<use locale> in force.  See L<perllocale>
5982 and L<perlunicode> for more details about locale and Unicode support.
5983 It does not attempt to do titlecase mapping on initial letters.  See
5984 C<ucfirst> for that.
5985
5986 If EXPR is omitted, uses C<$_>.
5987
5988 =item ucfirst EXPR
5989
5990 =item ucfirst
5991
5992 Returns the value of EXPR with the first character in uppercase
5993 (titlecase in Unicode).  This is the internal function implementing
5994 the C<\u> escape in double-quoted strings.  Respects current LC_CTYPE
5995 locale if C<use locale> in force.  See L<perllocale> and L<perlunicode>
5996 for more details about locale and Unicode support.
5997
5998 If EXPR is omitted, uses C<$_>.
5999
6000 =item umask EXPR
6001
6002 =item umask
6003
6004 Sets the umask for the process to EXPR and returns the previous value.
6005 If EXPR is omitted, merely returns the current umask.
6006
6007 The Unix permission C<rwxr-x---> is represented as three sets of three
6008 bits, or three octal digits: C<0750> (the leading 0 indicates octal
6009 and isn't one of the digits).  The C<umask> value is such a number
6010 representing disabled permissions bits.  The permission (or "mode")
6011 values you pass C<mkdir> or C<sysopen> are modified by your umask, so
6012 even if you tell C<sysopen> to create a file with permissions C<0777>,
6013 if your umask is C<0022> then the file will actually be created with
6014 permissions C<0755>.  If your C<umask> were C<0027> (group can't
6015 write; others can't read, write, or execute), then passing
6016 C<sysopen> C<0666> would create a file with mode C<0640> (C<0666 &~
6017 027> is C<0640>).
6018
6019 Here's some advice: supply a creation mode of C<0666> for regular
6020 files (in C<sysopen>) and one of C<0777> for directories (in
6021 C<mkdir>) and executable files.  This gives users the freedom of
6022 choice: if they want protected files, they might choose process umasks
6023 of C<022>, C<027>, or even the particularly antisocial mask of C<077>.
6024 Programs should rarely if ever make policy decisions better left to
6025 the user.  The exception to this is when writing files that should be
6026 kept private: mail files, web browser cookies, I<.rhosts> files, and
6027 so on.
6028
6029 If umask(2) is not implemented on your system and you are trying to
6030 restrict access for I<yourself> (i.e., (EXPR & 0700) > 0), produces a
6031 fatal error at run time.  If umask(2) is not implemented and you are
6032 not trying to restrict access for yourself, returns C<undef>.
6033
6034 Remember that a umask is a number, usually given in octal; it is I<not> a
6035 string of octal digits.  See also L</oct>, if all you have is a string.
6036
6037 =item undef EXPR
6038
6039 =item undef
6040
6041 Undefines the value of EXPR, which must be an lvalue.  Use only on a
6042 scalar value, an array (using C<@>), a hash (using C<%>), a subroutine
6043 (using C<&>), or a typeglob (using C<*>).  (Saying C<undef $hash{$key}>
6044 will probably not do what you expect on most predefined variables or
6045 DBM list values, so don't do that; see L<delete>.)  Always returns the
6046 undefined value.  You can omit the EXPR, in which case nothing is
6047 undefined, but you still get an undefined value that you could, for
6048 instance, return from a subroutine, assign to a variable or pass as a
6049 parameter.  Examples:
6050
6051     undef $foo;
6052     undef $bar{'blurfl'};      # Compare to: delete $bar{'blurfl'};
6053     undef @ary;
6054     undef %hash;
6055     undef &mysub;
6056     undef *xyz;       # destroys $xyz, @xyz, %xyz, &xyz, etc.
6057     return (wantarray ? (undef, $errmsg) : undef) if $they_blew_it;
6058     select undef, undef, undef, 0.25;
6059     ($a, $b, undef, $c) = &foo;       # Ignore third value returned
6060
6061 Note that this is a unary operator, not a list operator.
6062
6063 =item unlink LIST
6064
6065 =item unlink
6066
6067 Deletes a list of files.  Returns the number of files successfully
6068 deleted.
6069
6070     $cnt = unlink 'a', 'b', 'c';
6071     unlink @goners;
6072     unlink <*.bak>;
6073
6074 Note: C<unlink> will not delete directories unless you are superuser and
6075 the B<-U> flag is supplied to Perl.  Even if these conditions are
6076 met, be warned that unlinking a directory can inflict damage on your
6077 filesystem.  Use C<rmdir> instead.
6078
6079 If LIST is omitted, uses C<$_>.
6080
6081 =item unpack TEMPLATE,EXPR
6082
6083 =item unpack TEMPLATE
6084
6085 C<unpack> does the reverse of C<pack>: it takes a string
6086 and expands it out into a list of values.
6087 (In scalar context, it returns merely the first value produced.)
6088
6089 If EXPR is omitted, unpacks the C<$_> string.
6090
6091 The string is broken into chunks described by the TEMPLATE.  Each chunk
6092 is converted separately to a value.  Typically, either the string is a result
6093 of C<pack>, or the bytes of the string represent a C structure of some
6094 kind.
6095
6096 The TEMPLATE has the same format as in the C<pack> function.
6097 Here's a subroutine that does substring:
6098
6099     sub substr {
6100         my($what,$where,$howmuch) = @_;
6101         unpack("x$where a$howmuch", $what);
6102     }
6103
6104 and then there's
6105
6106     sub ordinal { unpack("c",$_[0]); } # same as ord()
6107
6108 In addition to fields allowed in pack(), you may prefix a field with
6109 a %<number> to indicate that
6110 you want a <number>-bit checksum of the items instead of the items
6111 themselves.  Default is a 16-bit checksum.  Checksum is calculated by
6112 summing numeric values of expanded values (for string fields the sum of
6113 C<ord($char)> is taken, for bit fields the sum of zeroes and ones).
6114
6115 For example, the following
6116 computes the same number as the System V sum program:
6117
6118     $checksum = do {
6119         local $/;  # slurp!
6120         unpack("%32C*",<>) % 65535;
6121     };
6122
6123 The following efficiently counts the number of set bits in a bit vector:
6124
6125     $setbits = unpack("%32b*", $selectmask);
6126
6127 The C<p> and C<P> formats should be used with care.  Since Perl
6128 has no way of checking whether the value passed to C<unpack()>
6129 corresponds to a valid memory location, passing a pointer value that's
6130 not known to be valid is likely to have disastrous consequences.
6131
6132 If there are more pack codes or if the repeat count of a field or a group
6133 is larger than what the remainder of the input string allows, the result
6134 is not well defined: in some cases, the repeat count is decreased, or
6135 C<unpack()> will produce null strings or zeroes, or terminate with an
6136 error. If the input string is longer than one described by the TEMPLATE,
6137 the rest is ignored.
6138
6139 See L</pack> for more examples and notes.
6140
6141 =item untie VARIABLE
6142
6143 Breaks the binding between a variable and a package.  (See C<tie>.)
6144 Has no effect if the variable is not tied.
6145
6146 =item unshift ARRAY,LIST
6147
6148 Does the opposite of a C<shift>.  Or the opposite of a C<push>,
6149 depending on how you look at it.  Prepends list to the front of the
6150 array, and returns the new number of elements in the array.
6151
6152     unshift(@ARGV, '-e') unless $ARGV[0] =~ /^-/;
6153
6154 Note the LIST is prepended whole, not one element at a time, so the
6155 prepended elements stay in the same order.  Use C<reverse> to do the
6156 reverse.
6157
6158 =item use Module VERSION LIST
6159
6160 =item use Module VERSION
6161
6162 =item use Module LIST
6163
6164 =item use Module
6165
6166 =item use VERSION
6167
6168 Imports some semantics into the current package from the named module,
6169 generally by aliasing certain subroutine or variable names into your
6170 package.  It is exactly equivalent to
6171
6172     BEGIN { require Module; import Module LIST; }
6173
6174 except that Module I<must> be a bareword.
6175
6176 VERSION may be either a numeric argument such as 5.006, which will be
6177 compared to C<$]>, or a literal of the form v5.6.1, which will be compared
6178 to C<$^V> (aka $PERL_VERSION.  A fatal error is produced if VERSION is
6179 greater than the version of the current Perl interpreter; Perl will not
6180 attempt to parse the rest of the file.  Compare with L</require>, which can
6181 do a similar check at run time.
6182
6183 Specifying VERSION as a literal of the form v5.6.1 should generally be
6184 avoided, because it leads to misleading error messages under earlier
6185 versions of Perl which do not support this syntax.  The equivalent numeric
6186 version should be used instead.
6187
6188     use v5.6.1;         # compile time version check
6189     use 5.6.1;          # ditto
6190     use 5.006_001;      # ditto; preferred for backwards compatibility
6191
6192 This is often useful if you need to check the current Perl version before
6193 C<use>ing library modules that have changed in incompatible ways from
6194 older versions of Perl.  (We try not to do this more than we have to.)
6195
6196 The C<BEGIN> forces the C<require> and C<import> to happen at compile time.  The
6197 C<require> makes sure the module is loaded into memory if it hasn't been
6198 yet.  The C<import> is not a builtin--it's just an ordinary static method
6199 call into the C<Module> package to tell the module to import the list of
6200 features back into the current package.  The module can implement its
6201 C<import> method any way it likes, though most modules just choose to
6202 derive their C<import> method via inheritance from the C<Exporter> class that
6203 is defined in the C<Exporter> module.  See L<Exporter>.  If no C<import>
6204 method can be found then the call is skipped, even if there is an AUTOLOAD
6205 method.
6206
6207 If you do not want to call the package's C<import> method (for instance,
6208 to stop your namespace from being altered), explicitly supply the empty list:
6209
6210     use Module ();
6211
6212 That is exactly equivalent to
6213
6214     BEGIN { require Module }
6215
6216 If the VERSION argument is present between Module and LIST, then the
6217 C<use> will call the VERSION method in class Module with the given
6218 version as an argument.  The default VERSION method, inherited from
6219 the UNIVERSAL class, croaks if the given version is larger than the
6220 value of the variable C<$Module::VERSION>.
6221
6222 Again, there is a distinction between omitting LIST (C<import> called
6223 with no arguments) and an explicit empty LIST C<()> (C<import> not
6224 called).  Note that there is no comma after VERSION!
6225
6226 Because this is a wide-open interface, pragmas (compiler directives)
6227 are also implemented this way.  Currently implemented pragmas are:
6228
6229     use constant;
6230     use diagnostics;
6231     use integer;
6232     use sigtrap  qw(SEGV BUS);
6233     use strict   qw(subs vars refs);
6234     use subs     qw(afunc blurfl);
6235     use warnings qw(all);
6236     use sort     qw(stable _quicksort _mergesort);
6237
6238 Some of these pseudo-modules import semantics into the current
6239 block scope (like C<strict> or C<integer>, unlike ordinary modules,
6240 which import symbols into the current package (which are effective
6241 through the end of the file).
6242
6243 There's a corresponding C<no> command that unimports meanings imported
6244 by C<use>, i.e., it calls C<unimport Module LIST> instead of C<import>.
6245 It behaves exactly as C<import> does with respect to VERSION, an
6246 omitted LIST, empty LIST, or no unimport method being found.
6247
6248     no integer;
6249     no strict 'refs';
6250     no warnings;
6251
6252 See L<perlmodlib> for a list of standard modules and pragmas.  See L<perlrun>
6253 for the C<-M> and C<-m> command-line options to perl that give C<use>
6254 functionality from the command-line.
6255
6256 =item utime LIST
6257
6258 Changes the access and modification times on each file of a list of
6259 files.  The first two elements of the list must be the NUMERICAL access
6260 and modification times, in that order.  Returns the number of files
6261 successfully changed.  The inode change time of each file is set
6262 to the current time.  For example, this code has the same effect as the
6263 Unix touch(1) command when the files I<already exist>.
6264
6265     #!/usr/bin/perl
6266     $atime = $mtime = time;
6267     utime $atime, $mtime, @ARGV;
6268
6269 Since perl 5.7.2, if the first two elements of the list are C<undef>, then
6270 the utime(2) function in the C library will be called with a null second
6271 argument. On most systems, this will set the file's access and
6272 modification times to the current time (i.e. equivalent to the example
6273 above.)
6274
6275     utime undef, undef, @ARGV;
6276
6277 Under NFS this will use the time of the NFS server, not the time of
6278 the local machine.  If there is a time synchronization problem, the
6279 NFS server and local machine will have different times.  The Unix
6280 touch(1) command will in fact normally use this form instead of the
6281 one shown in the first example.
6282
6283 Note that only passing one of the first two elements as C<undef> will
6284 be equivalent of passing it as 0 and will not have the same effect as
6285 described when they are both C<undef>.  This case will also trigger an
6286 uninitialized warning.
6287
6288 =item values HASH
6289
6290 Returns a list consisting of all the values of the named hash.
6291 (In a scalar context, returns the number of values.)
6292
6293 The values are returned in an apparently random order.  The actual
6294 random order is subject to change in future versions of perl, but it
6295 is guaranteed to be the same order as either the C<keys> or C<each>
6296 function would produce on the same (unmodified) hash.  Since Perl
6297 5.8.1 the ordering is different even between different runs of Perl
6298 for security reasons (see L<perlsec/"Algorithmic Complexity Attacks">).
6299
6300 As a side effect, calling values() resets the HASH's internal iterator,
6301 see L</each>. (In particular, calling values() in void context resets
6302 the iterator with no other overhead.)
6303
6304 Note that the values are not copied, which means modifying them will
6305 modify the contents of the hash:
6306
6307     for (values %hash)      { s/foo/bar/g }   # modifies %hash values
6308     for (@hash{keys %hash}) { s/foo/bar/g }   # same
6309
6310 See also C<keys>, C<each>, and C<sort>.
6311
6312 =item vec EXPR,OFFSET,BITS
6313
6314 Treats the string in EXPR as a bit vector made up of elements of
6315 width BITS, and returns the value of the element specified by OFFSET
6316 as an unsigned integer.  BITS therefore specifies the number of bits
6317 that are reserved for each element in the bit vector.  This must
6318 be a power of two from 1 to 32 (or 64, if your platform supports
6319 that).
6320
6321 If BITS is 8, "elements" coincide with bytes of the input string.
6322
6323 If BITS is 16 or more, bytes of the input string are grouped into chunks
6324 of size BITS/8, and each group is converted to a number as with
6325 pack()/unpack() with big-endian formats C<n>/C<N> (and analogously
6326 for BITS==64).  See L<"pack"> for details.
6327
6328 If bits is 4 or less, the string is broken into bytes, then the bits
6329 of each byte are broken into 8/BITS groups.  Bits of a byte are
6330 numbered in a little-endian-ish way, as in C<0x01>, C<0x02>,
6331 C<0x04>, C<0x08>, C<0x10>, C<0x20>, C<0x40>, C<0x80>.  For example,
6332 breaking the single input byte C<chr(0x36)> into two groups gives a list
6333 C<(0x6, 0x3)>; breaking it into 4 groups gives C<(0x2, 0x1, 0x3, 0x0)>.
6334
6335 C<vec> may also be assigned to, in which case parentheses are needed
6336 to give the expression the correct precedence as in
6337
6338     vec($image, $max_x * $x + $y, 8) = 3;
6339
6340 If the selected element is outside the string, the value 0 is returned.
6341 If an element off the end of the string is written to, Perl will first
6342 extend the string with sufficiently many zero bytes.   It is an error
6343 to try to write off the beginning of the string (i.e. negative OFFSET).
6344
6345 The string should not contain any character with the value > 255 (which
6346 can only happen if you're using UTF-8 encoding).  If it does, it will be
6347 treated as something which is not UTF-8 encoded.  When the C<vec> was
6348 assigned to, other parts of your program will also no longer consider the
6349 string to be UTF-8 encoded.  In other words, if you do have such characters
6350 in your string, vec() will operate on the actual byte string, and not the
6351 conceptual character string.
6352
6353 Strings created with C<vec> can also be manipulated with the logical
6354 operators C<|>, C<&>, C<^>, and C<~>.  These operators will assume a bit
6355 vector operation is desired when both operands are strings.
6356 See L<perlop/"Bitwise String Operators">.
6357
6358 The following code will build up an ASCII string saying C<'PerlPerlPerl'>.
6359 The comments show the string after each step.  Note that this code works
6360 in the same way on big-endian or little-endian machines.
6361
6362     my $foo = '';
6363     vec($foo,  0, 32) = 0x5065726C;     # 'Perl'
6364
6365     # $foo eq "Perl" eq "\x50\x65\x72\x6C", 32 bits
6366     print vec($foo, 0, 8);              # prints 80 == 0x50 == ord('P')
6367
6368     vec($foo,  2, 16) = 0x5065;         # 'PerlPe'
6369     vec($foo,  3, 16) = 0x726C;         # 'PerlPerl'
6370     vec($foo,  8,  8) = 0x50;           # 'PerlPerlP'
6371     vec($foo,  9,  8) = 0x65;           # 'PerlPerlPe'
6372     vec($foo, 20,  4) = 2;              # 'PerlPerlPe'   . "\x02"
6373     vec($foo, 21,  4) = 7;              # 'PerlPerlPer'
6374                                         # 'r' is "\x72"
6375     vec($foo, 45,  2) = 3;              # 'PerlPerlPer'  . "\x0c"
6376     vec($foo, 93,  1) = 1;              # 'PerlPerlPer'  . "\x2c"
6377     vec($foo, 94,  1) = 1;              # 'PerlPerlPerl'
6378                                         # 'l' is "\x6c"
6379
6380 To transform a bit vector into a string or list of 0's and 1's, use these:
6381
6382     $bits = unpack("b*", $vector);
6383     @bits = split(//, unpack("b*", $vector));
6384
6385 If you know the exact length in bits, it can be used in place of the C<*>.
6386
6387 Here is an example to illustrate how the bits actually fall in place:
6388
6389     #!/usr/bin/perl -wl
6390
6391     print <<'EOT';
6392                                       0         1         2         3
6393                        unpack("V",$_) 01234567890123456789012345678901
6394     ------------------------------------------------------------------
6395     EOT
6396
6397     for $w (0..3) {
6398         $width = 2**$w;
6399         for ($shift=0; $shift < $width; ++$shift) {
6400             for ($off=0; $off < 32/$width; ++$off) {
6401                 $str = pack("B*", "0"x32);
6402                 $bits = (1<<$shift);
6403                 vec($str, $off, $width) = $bits;
6404                 $res = unpack("b*",$str);
6405                 $val = unpack("V", $str);
6406                 write;
6407             }
6408         }
6409     }
6410
6411     format STDOUT =
6412     vec($_,@#,@#) = @<< == @######### @>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
6413     $off, $width, $bits, $val, $res
6414     .
6415     __END__
6416
6417 Regardless of the machine architecture on which it is run, the above
6418 example should print the following table:
6419
6420                                       0         1         2         3
6421                        unpack("V",$_) 01234567890123456789012345678901
6422     ------------------------------------------------------------------
6423     vec($_, 0, 1) = 1   ==          1 10000000000000000000000000000000
6424     vec($_, 1, 1) = 1   ==          2 01000000000000000000000000000000
6425     vec($_, 2, 1) = 1   ==          4 00100000000000000000000000000000
6426     vec($_, 3, 1) = 1   ==          8 00010000000000000000000000000000
6427     vec($_, 4, 1) = 1   ==         16 00001000000000000000000000000000
6428     vec($_, 5, 1) = 1   ==         32 00000100000000000000000000000000
6429     vec($_, 6, 1) = 1   ==         64 00000010000000000000000000000000
6430     vec($_, 7, 1) = 1   ==        128 00000001000000000000000000000000
6431     vec($_, 8, 1) = 1   ==        256 00000000100000000000000000000000
6432     vec($_, 9, 1) = 1   ==        512 00000000010000000000000000000000
6433     vec($_,10, 1) = 1   ==       1024 00000000001000000000000000000000
6434     vec($_,11, 1) = 1   ==       2048 00000000000100000000000000000000
6435     vec($_,12, 1) = 1   ==       4096 00000000000010000000000000000000
6436     vec($_,13, 1) = 1   ==       8192 00000000000001000000000000000000
6437     vec($_,14, 1) = 1   ==      16384 00000000000000100000000000000000
6438     vec($_,15, 1) = 1   ==      32768 00000000000000010000000000000000
6439     vec($_,16, 1) = 1   ==      65536 00000000000000001000000000000000
6440     vec($_,17, 1) = 1   ==     131072 00000000000000000100000000000000
6441     vec($_,18, 1) = 1   ==     262144 00000000000000000010000000000000
6442     vec($_,19, 1) = 1   ==     524288 00000000000000000001000000000000
6443     vec($_,20, 1) = 1   ==    1048576 00000000000000000000100000000000
6444     vec($_,21, 1) = 1   ==    2097152 00000000000000000000010000000000
6445     vec($_,22, 1) = 1   ==    4194304 00000000000000000000001000000000
6446     vec($_,23, 1) = 1   ==    8388608 00000000000000000000000100000000
6447     vec($_,24, 1) = 1   ==   16777216 00000000000000000000000010000000
6448     vec($_,25, 1) = 1   ==   33554432 00000000000000000000000001000000
6449     vec($_,26, 1) = 1   ==   67108864 00000000000000000000000000100000
6450     vec($_,27, 1) = 1   ==  134217728 00000000000000000000000000010000
6451     vec($_,28, 1) = 1   ==  268435456 00000000000000000000000000001000
6452     vec($_,29, 1) = 1   ==  536870912 00000000000000000000000000000100
6453     vec($_,30, 1) = 1   == 1073741824 00000000000000000000000000000010
6454     vec($_,31, 1) = 1   == 2147483648 00000000000000000000000000000001
6455     vec($_, 0, 2) = 1   ==          1 10000000000000000000000000000000
6456     vec($_, 1, 2) = 1   ==          4 00100000000000000000000000000000
6457     vec($_, 2, 2) = 1   ==         16 00001000000000000000000000000000
6458     vec($_, 3, 2) = 1   ==         64 00000010000000000000000000000000
6459     vec($_, 4, 2) = 1   ==        256 00000000100000000000000000000000
6460     vec($_, 5, 2) = 1   ==       1024 00000000001000000000000000000000
6461     vec($_, 6, 2) = 1   ==       4096 00000000000010000000000000000000
6462     vec($_, 7, 2) = 1   ==      16384 00000000000000100000000000000000
6463     vec($_, 8, 2) = 1   ==      65536 00000000000000001000000000000000
6464     vec($_, 9, 2) = 1   ==     262144 00000000000000000010000000000000
6465     vec($_,10, 2) = 1   ==    1048576 00000000000000000000100000000000
6466     vec($_,11, 2) = 1   ==    4194304 00000000000000000000001000000000
6467     vec($_,12, 2) = 1   ==   16777216 00000000000000000000000010000000
6468     vec($_,13, 2) = 1   ==   67108864 00000000000000000000000000100000
6469     vec($_,14, 2) = 1   ==  268435456 00000000000000000000000000001000
6470     vec($_,15, 2) = 1   == 1073741824 00000000000000000000000000000010
6471     vec($_, 0, 2) = 2   ==          2 01000000000000000000000000000000
6472     vec($_, 1, 2) = 2   ==          8 00010000000000000000000000000000
6473     vec($_, 2, 2) = 2   ==         32 00000100000000000000000000000000
6474     vec($_, 3, 2) = 2   ==        128 00000001000000000000000000000000
6475     vec($_, 4, 2) = 2   ==        512 00000000010000000000000000000000
6476     vec($_, 5, 2) = 2   ==       2048 00000000000100000000000000000000
6477     vec($_, 6, 2) = 2   ==       8192 00000000000001000000000000000000
6478     vec($_, 7, 2) = 2   ==      32768 00000000000000010000000000000000
6479     vec($_, 8, 2) = 2   ==     131072 00000000000000000100000000000000
6480     vec($_, 9, 2) = 2   ==     524288 00000000000000000001000000000000
6481     vec($_,10, 2) = 2   ==    2097152 00000000000000000000010000000000
6482     vec($_,11, 2) = 2   ==    8388608 00000000000000000000000100000000
6483     vec($_,12, 2) = 2   ==   33554432 00000000000000000000000001000000
6484     vec($_,13, 2) = 2   ==  134217728 00000000000000000000000000010000
6485     vec($_,14, 2) = 2   ==  536870912 00000000000000000000000000000100
6486     vec($_,15, 2) = 2   == 2147483648 00000000000000000000000000000001
6487     vec($_, 0, 4) = 1   ==          1 10000000000000000000000000000000
6488     vec($_, 1, 4) = 1   ==         16 00001000000000000000000000000000
6489     vec($_, 2, 4) = 1   ==        256 00000000100000000000000000000000
6490     vec($_, 3, 4) = 1   ==       4096 00000000000010000000000000000000
6491     vec($_, 4, 4) = 1   ==      65536 00000000000000001000000000000000
6492     vec($_, 5, 4) = 1   ==    1048576 00000000000000000000100000000000
6493     vec($_, 6, 4) = 1   ==   16777216 00000000000000000000000010000000
6494     vec($_, 7, 4) = 1   ==  268435456 00000000000000000000000000001000
6495     vec($_, 0, 4) = 2   ==          2 01000000000000000000000000000000
6496     vec($_, 1, 4) = 2   ==         32 00000100000000000000000000000000
6497     vec($_, 2, 4) = 2   ==        512 00000000010000000000000000000000
6498     vec($_, 3, 4) = 2   ==       8192 00000000000001000000000000000000
6499     vec($_, 4, 4) = 2   ==     131072 00000000000000000100000000000000
6500     vec($_, 5, 4) = 2   ==    2097152 00000000000000000000010000000000
6501     vec($_, 6, 4) = 2   ==   33554432 00000000000000000000000001000000
6502     vec($_, 7, 4) = 2   ==  536870912 00000000000000000000000000000100
6503     vec($_, 0, 4) = 4   ==          4 00100000000000000000000000000000
6504     vec($_, 1, 4) = 4   ==         64 00000010000000000000000000000000
6505     vec($_, 2, 4) = 4   ==       1024 00000000001000000000000000000000
6506     vec($_, 3, 4) = 4   ==      16384 00000000000000100000000000000000
6507     vec($_, 4, 4) = 4   ==     262144 00000000000000000010000000000000
6508     vec($_, 5, 4) = 4   ==    4194304 00000000000000000000001000000000
6509     vec($_, 6, 4) = 4   ==   67108864 00000000000000000000000000100000
6510     vec($_, 7, 4) = 4   == 1073741824 00000000000000000000000000000010
6511     vec($_, 0, 4) = 8   ==          8 00010000000000000000000000000000
6512     vec($_, 1, 4) = 8   ==        128 00000001000000000000000000000000
6513     vec($_, 2, 4) = 8   ==       2048 00000000000100000000000000000000
6514     vec($_, 3, 4) = 8   ==      32768 00000000000000010000000000000000
6515     vec($_, 4, 4) = 8   ==     524288 00000000000000000001000000000000
6516     vec($_, 5, 4) = 8   ==    8388608 00000000000000000000000100000000
6517     vec($_, 6, 4) = 8   ==  134217728 00000000000000000000000000010000
6518     vec($_, 7, 4) = 8   == 2147483648 00000000000000000000000000000001
6519     vec($_, 0, 8) = 1   ==          1 10000000000000000000000000000000
6520     vec($_, 1, 8) = 1   ==        256 00000000100000000000000000000000
6521     vec($_, 2, 8) = 1   ==      65536 00000000000000001000000000000000
6522     vec($_, 3, 8) = 1   ==   16777216 00000000000000000000000010000000
6523     vec($_, 0, 8) = 2   ==          2 01000000000000000000000000000000
6524     vec($_, 1, 8) = 2   ==        512 00000000010000000000000000000000
6525     vec($_, 2, 8) = 2   ==     131072 00000000000000000100000000000000
6526     vec($_, 3, 8) = 2   ==   33554432 00000000000000000000000001000000
6527     vec($_, 0, 8) = 4   ==          4 00100000000000000000000000000000
6528     vec($_, 1, 8) = 4   ==       1024 00000000001000000000000000000000
6529     vec($_, 2, 8) = 4   ==     262144 00000000000000000010000000000000
6530     vec($_, 3, 8) = 4   ==   67108864 00000000000000000000000000100000
6531     vec($_, 0, 8) = 8   ==          8 00010000000000000000000000000000
6532     vec($_, 1, 8) = 8   ==       2048 00000000000100000000000000000000
6533     vec($_, 2, 8) = 8   ==     524288 00000000000000000001000000000000
6534     vec($_, 3, 8) = 8   ==  134217728 00000000000000000000000000010000
6535     vec($_, 0, 8) = 16  ==         16 00001000000000000000000000000000
6536     vec($_, 1, 8) = 16  ==       4096 00000000000010000000000000000000
6537     vec($_, 2, 8) = 16  ==    1048576 00000000000000000000100000000000
6538     vec($_, 3, 8) = 16  ==  268435456 00000000000000000000000000001000
6539     vec($_, 0, 8) = 32  ==         32 00000100000000000000000000000000
6540     vec($_, 1, 8) = 32  ==       8192 00000000000001000000000000000000
6541     vec($_, 2, 8) = 32  ==    2097152 00000000000000000000010000000000
6542     vec($_, 3, 8) = 32  ==  536870912 00000000000000000000000000000100
6543     vec($_, 0, 8) = 64  ==         64 00000010000000000000000000000000
6544     vec($_, 1, 8) = 64  ==      16384 00000000000000100000000000000000
6545     vec($_, 2, 8) = 64  ==    4194304 00000000000000000000001000000000
6546     vec($_, 3, 8) = 64  == 1073741824 00000000000000000000000000000010
6547     vec($_, 0, 8) = 128 ==        128 00000001000000000000000000000000
6548     vec($_, 1, 8) = 128 ==      32768 00000000000000010000000000000000
6549     vec($_, 2, 8) = 128 ==    8388608 00000000000000000000000100000000
6550     vec($_, 3, 8) = 128 == 2147483648 00000000000000000000000000000001
6551
6552 =item wait
6553
6554 Behaves like the wait(2) system call on your system: it waits for a child
6555 process to terminate and returns the pid of the deceased process, or
6556 C<-1> if there are no child processes.  The status is returned in C<$?>.
6557 Note that a return value of C<-1> could mean that child processes are
6558 being automatically reaped, as described in L<perlipc>.
6559
6560 =item waitpid PID,FLAGS
6561
6562 Waits for a particular child process to terminate and returns the pid of
6563 the deceased process, or C<-1> if there is no such child process.  On some
6564 systems, a value of 0 indicates that there are processes still running.
6565 The status is returned in C<$?>.  If you say
6566
6567     use POSIX ":sys_wait_h";
6568     #...
6569     do {
6570         $kid = waitpid(-1, WNOHANG);
6571     } until $kid > 0;
6572
6573 then you can do a non-blocking wait for all pending zombie processes.
6574 Non-blocking wait is available on machines supporting either the
6575 waitpid(2) or wait4(2) system calls.  However, waiting for a particular
6576 pid with FLAGS of C<0> is implemented everywhere.  (Perl emulates the
6577 system call by remembering the status values of processes that have
6578 exited but have not been harvested by the Perl script yet.)
6579
6580 Note that on some systems, a return value of C<-1> could mean that child
6581 processes are being automatically reaped.  See L<perlipc> for details,
6582 and for other examples.
6583
6584 =item wantarray
6585
6586 Returns true if the context of the currently executing subroutine is
6587 looking for a list value.  Returns false if the context is looking
6588 for a scalar.  Returns the undefined value if the context is looking
6589 for no value (void context).
6590
6591     return unless defined wantarray;    # don't bother doing more
6592     my @a = complex_calculation();
6593     return wantarray ? @a : "@a";
6594
6595 This function should have been named wantlist() instead.
6596
6597 =item warn LIST
6598
6599 Produces a message on STDERR just like C<die>, but doesn't exit or throw
6600 an exception.
6601
6602 If LIST is empty and C<$@> already contains a value (typically from a
6603 previous eval) that value is used after appending C<"\t...caught">
6604 to C<$@>.  This is useful for staying almost, but not entirely similar to
6605 C<die>.
6606
6607 If C<$@> is empty then the string C<"Warning: Something's wrong"> is used.
6608
6609 No message is printed if there is a C<$SIG{__WARN__}> handler
6610 installed.  It is the handler's responsibility to deal with the message
6611 as it sees fit (like, for instance, converting it into a C<die>).  Most
6612 handlers must therefore make arrangements to actually display the
6613 warnings that they are not prepared to deal with, by calling C<warn>
6614 again in the handler.  Note that this is quite safe and will not
6615 produce an endless loop, since C<__WARN__> hooks are not called from
6616 inside one.
6617
6618 You will find this behavior is slightly different from that of
6619 C<$SIG{__DIE__}> handlers (which don't suppress the error text, but can
6620 instead call C<die> again to change it).
6621
6622 Using a C<__WARN__> handler provides a powerful way to silence all
6623 warnings (even the so-called mandatory ones).  An example:
6624
6625     # wipe out *all* compile-time warnings
6626     BEGIN { $SIG{'__WARN__'} = sub { warn $_[0] if $DOWARN } }
6627     my $foo = 10;
6628     my $foo = 20;          # no warning about duplicate my $foo,
6629                            # but hey, you asked for it!
6630     # no compile-time or run-time warnings before here
6631     $DOWARN = 1;
6632
6633     # run-time warnings enabled after here
6634     warn "\$foo is alive and $foo!";     # does show up
6635
6636 See L<perlvar> for details on setting C<%SIG> entries, and for more
6637 examples.  See the Carp module for other kinds of warnings using its
6638 carp() and cluck() functions.
6639
6640 =item write FILEHANDLE
6641
6642 =item write EXPR
6643
6644 =item write
6645
6646 Writes a formatted record (possibly multi-line) to the specified FILEHANDLE,
6647 using the format associated with that file.  By default the format for
6648 a file is the one having the same name as the filehandle, but the
6649 format for the current output channel (see the C<select> function) may be set
6650 explicitly by assigning the name of the format to the C<$~> variable.
6651
6652 Top of form processing is handled automatically:  if there is
6653 insufficient room on the current page for the formatted record, the
6654 page is advanced by writing a form feed, a special top-of-page format
6655 is used to format the new page header, and then the record is written.
6656 By default the top-of-page format is the name of the filehandle with
6657 "_TOP" appended, but it may be dynamically set to the format of your
6658 choice by assigning the name to the C<$^> variable while the filehandle is
6659 selected.  The number of lines remaining on the current page is in
6660 variable C<$->, which can be set to C<0> to force a new page.
6661
6662 If FILEHANDLE is unspecified, output goes to the current default output
6663 channel, which starts out as STDOUT but may be changed by the
6664 C<select> operator.  If the FILEHANDLE is an EXPR, then the expression
6665 is evaluated and the resulting string is used to look up the name of
6666 the FILEHANDLE at run time.  For more on formats, see L<perlform>.
6667
6668 Note that write is I<not> the opposite of C<read>.  Unfortunately.
6669
6670 =item y///
6671
6672 The transliteration operator.  Same as C<tr///>.  See L<perlop>.
6673
6674 =back